lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Devel::InnerPackage ();
  18 use File::stat;
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use utf8;
  32 use Carp qw/croak carp shortmess/;
  33
  34 BEGIN { require 5.008004; }
  35
  36 has stack => (is => 'ro', default => sub { [] });
  37 has stash => (is => 'rw', default => sub { {} });
  38 has state => (is => 'rw', default => 0);
  39 has stats => (is => 'rw');
  40 has action => (is => 'rw');
  41 has counter => (is => 'rw', default => sub { {} });
  42 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  43 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  44 has namespace => (is => 'rw');
  45
  46 sub depth { scalar @{ shift->stack || [] }; }
  47 sub comp { shift->component(@_) }
  48
  49 sub req {
  50     my $self = shift; return $self->request(@_);
  51 }
  52 sub res {
  53     my $self = shift; return $self->response(@_);
  54 }
  55
  56 # For backwards compatibility
  57 sub finalize_output { shift->finalize_body(@_) };
  58
  59 # For statistics
  60 our $COUNT     = 1;
  61 our $START     = time;
  62 our $RECURSION = 1000;
  63 our $DETACH    = Catalyst::Exception::Detach->new;
  64 our $GO        = Catalyst::Exception::Go->new;
  65
  66 #I imagine that very few of these really need to be class variables. if any.
  67 #maybe we should just make them attributes with a default?
  68 __PACKAGE__->mk_classdata($_)
  69   for qw/components arguments dispatcher engine log dispatcher_class
  70   engine_class context_class request_class response_class stats_class
  71   setup_finished/;
  72
  73 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  74 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  75 __PACKAGE__->request_class('Catalyst::Request');
  76 __PACKAGE__->response_class('Catalyst::Response');
  77 __PACKAGE__->stats_class('Catalyst::Stats');
  78
  79 # Remember to update this in Catalyst::Runtime as well!
  80
  81 our $VERSION = '5.80020';
  82 $VERSION = eval $VERSION;
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 104     }
 105
 106     $caller->arguments( [@arguments] );
 107     $caller->setup_home;
 108 }
 109
 110 sub _application { $_[0] }
 111
 112 =head1 NAME
 113
 114 Catalyst - The Elegant MVC Web Application Framework
 115
 116 =head1 SYNOPSIS
 117
 118 See the L<Catalyst::Manual> distribution for comprehensive
 119 documentation and tutorials.
 120
 121     # Install Catalyst::Devel for helpers and other development tools
 122     # use the helper to create a new application
 123     catalyst.pl MyApp
 124
 125     # add models, views, controllers
 126     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 127     script/myapp_create.pl view MyTemplate TT
 128     script/myapp_create.pl controller Search
 129
 130     # built in testserver -- use -r to restart automatically on changes
 131     # --help to see all available options
 132     script/myapp_server.pl
 133
 134     # command line testing interface
 135     script/myapp_test.pl /yada
 136
 137     ### in lib/MyApp.pm
 138     use Catalyst qw/-Debug/; # include plugins here as well
 139
 140     ### In lib/MyApp/Controller/Root.pm (autocreated)
 141     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 142         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 143         $c->stash->{template} = 'foo.tt'; # set the template
 144         # lookup something from db -- stash vars are passed to TT
 145         $c->stash->{data} =
 146           $c->model('Database::Foo')->search( { country => $args[0] } );
 147         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 148             $c->forward( 'bar' ); # process another action
 149             # do something else after forward returns
 150         }
 151     }
 152
 153     # The foo.tt TT template can use the stash data from the database
 154     [% WHILE (item = data.next) %]
 155         [% item.foo %]
 156     [% END %]
 157
 158     # called for /bar/of/soap, /bar/of/soap/10, etc.
 159     sub bar : Path('/bar/of/soap') { ... }
 160
 161     # called for all actions, from the top-most controller downwards
 162     sub auto : Private {
 163         my ( $self, $c ) = @_;
 164         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 165             $c->res->redirect( '/login' ); # require login
 166             return 0; # abort request and go immediately to end()
 167         }
 168         return 1; # success; carry on to next action
 169     }
 170
 171     # called after all actions are finished
 172     sub end : Private {
 173         my ( $self, $c ) = @_;
 174         if ( scalar @{ $c->error } ) { ... } # handle errors
 175         return if $c->res->body; # already have a response
 176         $c->forward( 'MyApp::View::TT' ); # render template
 177     }
 178
 179     ### in MyApp/Controller/Foo.pm
 180     # called for /foo/bar
 181     sub bar : Local { ... }
 182
 183     # called for /blargle
 184     sub blargle : Global { ... }
 185
 186     # an index action matches /foo, but not /foo/1, etc.
 187     sub index : Private { ... }
 188
 189     ### in MyApp/Controller/Foo/Bar.pm
 190     # called for /foo/bar/baz
 191     sub baz : Local { ... }
 192
 193     # first Root auto is called, then Foo auto, then this
 194     sub auto : Private { ... }
 195
 196     # powerful regular expression paths are also possible
 197     sub details : Regex('^product/(\w+)/details$') {
 198         my ( $self, $c ) = @_;
 199         # extract the (\w+) from the URI
 200         my $product = $c->req->captures->[0];
 201     }
 202
 203 See L<Catalyst::Manual::Intro> for additional information.
 204
 205 =head1 DESCRIPTION
 206
 207 Catalyst is a modern framework for making web applications without the
 208 pain usually associated with this process. This document is a reference
 209 to the main Catalyst application. If you are a new user, we suggest you
 210 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 211
 212 See L<Catalyst::Manual> for more documentation.
 213
 214 Catalyst plugins can be loaded by naming them as arguments to the "use
 215 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 216 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 217 C<My::Module>.
 218
 219     use Catalyst qw/My::Module/;
 220
 221 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 222 fully qualify the name by using a unary plus:
 223
 224     use Catalyst qw/
 225         My::Module
 226         +Fully::Qualified::Plugin::Name
 227     /;
 228
 229 Special flags like C<-Debug> and C<-Engine> can also be specified as
 230 arguments when Catalyst is loaded:
 231
 232     use Catalyst qw/-Debug My::Module/;
 233
 234 The position of plugins and flags in the chain is important, because
 235 they are loaded in the order in which they appear.
 236
 237 The following flags are supported:
 238
 239 =head2 -Debug
 240
 241 Enables debug output. You can also force this setting from the system
 242 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 243 settings override the application, with <MYAPP>_DEBUG having the highest
 244 priority.
 245
 246 This sets the log level to 'debug' and enables full debug output on the
 247 error screen. If you only want the latter, see L<< $c->debug >>.
 248
 249 =head2 -Engine
 250
 251 Forces Catalyst to use a specific engine. Omit the
 252 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 253
 254     use Catalyst qw/-Engine=CGI/;
 255
 256 =head2 -Home
 257
 258 Forces Catalyst to use a specific home directory, e.g.:
 259
 260     use Catalyst qw[-Home=/usr/mst];
 261
 262 This can also be done in the shell environment by setting either the
 263 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 264 is replaced with the uppercased name of your application, any "::" in
 265 the name will be replaced with underscores, e.g. MyApp::Web should use
 266 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 267
 268 If none of these are set, Catalyst will attempt to automatically detect the
 269 home directory. If you are working in a development envirnoment, Catalyst
 270 will try and find the directory containing either Makefile.PL, Build.PL or
 271 dist.ini. If the application has been installed into the system (i.e.
 272 you have done C<make install>), then Catalyst will use the path to your
 273 application module, without the .pm extension (ie, /foo/MyApp if your
 274 application was installed at /foo/MyApp.pm)
 275
 276 =head2 -Log
 277
 278     use Catalyst '-Log=warn,fatal,error';
 279
 280 Specifies a comma-delimited list of log levels.
 281
 282 =head2 -Stats
 283
 284 Enables statistics collection and reporting. You can also force this setting
 285 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 286 environment settings override the application, with <MYAPP>_STATS having the
 287 highest priority.
 288
 289 e.g.
 290
 291    use Catalyst qw/-Stats=1/
 292
 293 =head1 METHODS
 294
 295 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 296
 297 =head2 $c->action
 298
 299 Returns a L<Catalyst::Action> object for the current action, which
 300 stringifies to the action name. See L<Catalyst::Action>.
 301
 302 =head2 $c->namespace
 303
 304 Returns the namespace of the current action, i.e., the URI prefix
 305 corresponding to the controller of the current action. For example:
 306
 307     # in Controller::Foo::Bar
 308     $c->namespace; # returns 'foo/bar';
 309
 310 =head2 $c->request
 311
 312 =head2 $c->req
 313
 314 Returns the current L<Catalyst::Request> object, giving access to
 315 information about the current client request (including parameters,
 316 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 317
 318 =head2 REQUEST FLOW HANDLING
 319
 320 =head2 $c->forward( $action [, \@arguments ] )
 321
 322 =head2 $c->forward( $class, $method, [, \@arguments ] )
 323
 324 Forwards processing to another action, by its private name. If you give a
 325 class name but no method, C<process()> is called. You may also optionally
 326 pass arguments in an arrayref. The action will receive the arguments in
 327 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 328 C<< $c->req->args >> will be restored to the previous values.
 329
 330 Any data C<return>ed from the action forwarded to, will be returned by the
 331 call to forward.
 332
 333     my $foodata = $c->forward('/foo');
 334     $c->forward('index');
 335     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 336     $c->forward('View::TT');
 337
 338 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 339 an C<< eval { } >> around the call (actually
 340 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 341 all 'dies' within the called action. If you want C<die> to propagate you
 342 need to do something like:
 343
 344     $c->forward('foo');
 345     die join "\n", @{ $c->error } if @{ $c->error };
 346
 347 Or make sure to always return true values from your actions and write
 348 your code like this:
 349
 350     $c->forward('foo') || return;
 351
 352 Another note is that C<< $c->forward >> always returns a scalar because it
 353 actually returns $c->state which operates in a scalar context.
 354 Thus, something like:
 355
 356     return @array;
 357
 358 in an action that is forwarded to is going to return a scalar,
 359 i.e. how many items are in that array, which is probably not what you want.
 360 If you need to return an array then return a reference to it,
 361 or stash it like so:
 362
 363     $c->stash->{array} = \@array;
 364
 365 and access it from the stash.
 366
 367 =cut
 368
 369 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 370
 371 =head2 $c->detach( $action [, \@arguments ] )
 372
 373 =head2 $c->detach( $class, $method, [, \@arguments ] )
 374
 375 =head2 $c->detach()
 376
 377 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 378 doesn't return to the previous action when processing is finished.
 379
 380 When called with no arguments it escapes the processing chain entirely.
 381
 382 =cut
 383
 384 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 385
 386 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 387
 388 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 389
 390 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 391 but does a full dispatch, instead of just calling the new C<$action> /
 392 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 393 you go to are called, just like a new request.
 394
 395 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 396 This means, for example, that C<< $c->action >> methods such as
 397 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 398 L<reverse|Catalyst::Action/reverse> return information for the visited action
 399 when they are invoked within the visited action.  This is different from the
 400 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 401 continues to use the $c->action object from the caller action even when
 402 invoked from the callee.
 403
 404 C<< $c->stash >> is kept unchanged.
 405
 406 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 407 allows you to "wrap" another action, just as it would have been called by
 408 dispatching from a URL, while the analogous
 409 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 410 transfer control to another action as if it had been reached directly from a URL.
 411
 412 =cut
 413
 414 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 415
 416 =head2 $c->go( $action [, \@captures, \@arguments ] )
 417
 418 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 419
 420 The relationship between C<go> and
 421 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 422 the relationship between
 423 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 424 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 425 C<< $c->go >> will perform a full dispatch on the specified action or method,
 426 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 427 C<go> escapes the processing of the current request chain on completion, and
 428 does not return to its caller.
 429
 430 =cut
 431
 432 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 433
 434 =head2 $c->response
 435
 436 =head2 $c->res
 437
 438 Returns the current L<Catalyst::Response> object, see there for details.
 439
 440 =head2 $c->stash
 441
 442 Returns a hashref to the stash, which may be used to store data and pass
 443 it between components during a request. You can also set hash keys by
 444 passing arguments. The stash is automatically sent to the view. The
 445 stash is cleared at the end of a request; it cannot be used for
 446 persistent storage (for this you must use a session; see
 447 L<Catalyst::Plugin::Session> for a complete system integrated with
 448 Catalyst).
 449
 450     $c->stash->{foo} = $bar;
 451     $c->stash( { moose => 'majestic', qux => 0 } );
 452     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 453
 454     # stash is automatically passed to the view for use in a template
 455     $c->forward( 'MyApp::View::TT' );
 456
 457 =cut
 458
 459 around stash => sub {
 460     my $orig = shift;
 461     my $c = shift;
 462     my $stash = $orig->($c);
 463     if (@_) {
 464         my $new_stash = @_ > 1 ? {@_} : $_[0];
 465         croak('stash takes a hash or hashref') unless ref $new_stash;
 466         foreach my $key ( keys %$new_stash ) {
 467           $stash->{$key} = $new_stash->{$key};
 468         }
 469     }
 470
 471     return $stash;
 472 };
 473
 474
 475 =head2 $c->error
 476
 477 =head2 $c->error($error, ...)
 478
 479 =head2 $c->error($arrayref)
 480
 481 Returns an arrayref containing error messages.  If Catalyst encounters an
 482 error while processing a request, it stores the error in $c->error.  This
 483 method should only be used to store fatal error messages.
 484
 485     my @error = @{ $c->error };
 486
 487 Add a new error.
 488
 489     $c->error('Something bad happened');
 490
 491 =cut
 492
 493 sub error {
 494     my $c = shift;
 495     if ( $_[0] ) {
 496         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 497         croak @$error unless ref $c;
 498         push @{ $c->{error} }, @$error;
 499     }
 500     elsif ( defined $_[0] ) { $c->{error} = undef }
 501     return $c->{error} || [];
 502 }
 503
 504
 505 =head2 $c->state
 506
 507 Contains the return value of the last executed action.
 508 Note that << $c->state >> operates in a scalar context which means that all
 509 values it returns are scalar.
 510
 511 =head2 $c->clear_errors
 512
 513 Clear errors.  You probably don't want to clear the errors unless you are
 514 implementing a custom error screen.
 515
 516 This is equivalent to running
 517
 518     $c->error(0);
 519
 520 =cut
 521
 522 sub clear_errors {
 523     my $c = shift;
 524     $c->error(0);
 525 }
 526
 527 sub _comp_search_prefixes {
 528     my $c = shift;
 529     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 530 }
 531
 532 # search components given a name and some prefixes
 533 sub _comp_names_search_prefixes {
 534     my ( $c, $name, @prefixes ) = @_;
 535     my $appclass = ref $c || $c;
 536     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 537     $filter = qr/$filter/; # Compile regex now rather than once per loop
 538
 539     # map the original component name to the sub part that we will search against
 540     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 541         grep { /$filter/ } keys %{ $c->components };
 542
 543     # undef for a name will return all
 544     return keys %eligible if !defined $name;
 545
 546     my $query  = ref $name ? $name : qr/^$name$/i;
 547     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 548
 549     return @result if @result;
 550
 551     # if we were given a regexp to search against, we're done.
 552     return if ref $name;
 553
 554     # skip regexp fallback if configured
 555     return
 556         if $appclass->config->{disable_component_resolution_regex_fallback};
 557
 558     # regexp fallback
 559     $query  = qr/$name/i;
 560     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 561
 562     # no results? try against full names
 563     if( !@result ) {
 564         @result = grep { m{$query} } keys %eligible;
 565     }
 566
 567     # don't warn if we didn't find any results, it just might not exist
 568     if( @result ) {
 569         # Disgusting hack to work out correct method name
 570         my $warn_for = lc $prefixes[0];
 571         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 572            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 573            "component resolution is unreliable and unsafe.";
 574         my $short = $result[0];
 575         # remove the component namespace prefix
 576         $short =~ s/.*?(Model|Controller|View):://;
 577         my $shortmess = Carp::shortmess('');
 578         if ($shortmess =~ m#Catalyst/Plugin#) {
 579            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 580               "plugin's config";
 581         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 582            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 583               "component's config";
 584         } else {
 585            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 586               "but if you really wanted to search, pass in a regexp as the argument " .
 587               "like so: \$c->${warn_for}(qr/${name}/)";
 588         }
 589         $c->log->warn( "${msg}$shortmess" );
 590     }
 591
 592     return @result;
 593 }
 594
 595 # Find possible names for a prefix
 596 sub _comp_names {
 597     my ( $c, @prefixes ) = @_;
 598     my $appclass = ref $c || $c;
 599
 600     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 601
 602     my @names = map { s{$filter}{}; $_; }
 603         $c->_comp_names_search_prefixes( undef, @prefixes );
 604
 605     return @names;
 606 }
 607
 608 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 609 sub _filter_component {
 610     my ( $c, $comp, @args ) = @_;
 611
 612     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 613         return $comp->ACCEPT_CONTEXT( $c, @args );
 614     }
 615
 616     return $comp;
 617 }
 618
 619 =head2 COMPONENT ACCESSORS
 620
 621 =head2 $c->controller($name)
 622
 623 Gets a L<Catalyst::Controller> instance by name.
 624
 625     $c->controller('Foo')->do_stuff;
 626
 627 If the name is omitted, will return the controller for the dispatched
 628 action.
 629
 630 If you want to search for controllers, pass in a regexp as the argument.
 631
 632     # find all controllers that start with Foo
 633     my @foo_controllers = $c->controller(qr{^Foo});
 634
 635
 636 =cut
 637
 638 sub controller {
 639     my ( $c, $name, @args ) = @_;
 640
 641     if( $name ) {
 642         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 643         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 644         return $c->_filter_component( $result[ 0 ], @args );
 645     }
 646
 647     return $c->component( $c->action->class );
 648 }
 649
 650 =head2 $c->model($name)
 651
 652 Gets a L<Catalyst::Model> instance by name.
 653
 654     $c->model('Foo')->do_stuff;
 655
 656 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 657
 658 If the name is omitted, it will look for
 659  - a model object in $c->stash->{current_model_instance}, then
 660  - a model name in $c->stash->{current_model}, then
 661  - a config setting 'default_model', or
 662  - check if there is only one model, and return it if that's the case.
 663
 664 If you want to search for models, pass in a regexp as the argument.
 665
 666     # find all models that start with Foo
 667     my @foo_models = $c->model(qr{^Foo});
 668
 669 =cut
 670
 671 sub model {
 672     my ( $c, $name, @args ) = @_;
 673     my $appclass = ref($c) || $c;
 674     if( $name ) {
 675         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 676         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 677         return $c->_filter_component( $result[ 0 ], @args );
 678     }
 679
 680     if (ref $c) {
 681         return $c->stash->{current_model_instance}
 682           if $c->stash->{current_model_instance};
 683         return $c->model( $c->stash->{current_model} )
 684           if $c->stash->{current_model};
 685     }
 686     return $c->model( $appclass->config->{default_model} )
 687       if $appclass->config->{default_model};
 688
 689     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 690
 691     if( $rest ) {
 692         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 693         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 694         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 695         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 696         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 697     }
 698
 699     return $c->_filter_component( $comp );
 700 }
 701
 702
 703 =head2 $c->view($name)
 704
 705 Gets a L<Catalyst::View> instance by name.
 706
 707     $c->view('Foo')->do_stuff;
 708
 709 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 710
 711 If the name is omitted, it will look for
 712  - a view object in $c->stash->{current_view_instance}, then
 713  - a view name in $c->stash->{current_view}, then
 714  - a config setting 'default_view', or
 715  - check if there is only one view, and return it if that's the case.
 716
 717 If you want to search for views, pass in a regexp as the argument.
 718
 719     # find all views that start with Foo
 720     my @foo_views = $c->view(qr{^Foo});
 721
 722 =cut
 723
 724 sub view {
 725     my ( $c, $name, @args ) = @_;
 726
 727     my $appclass = ref($c) || $c;
 728     if( $name ) {
 729         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 730         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 731         return $c->_filter_component( $result[ 0 ], @args );
 732     }
 733
 734     if (ref $c) {
 735         return $c->stash->{current_view_instance}
 736           if $c->stash->{current_view_instance};
 737         return $c->view( $c->stash->{current_view} )
 738           if $c->stash->{current_view};
 739     }
 740     return $c->view( $appclass->config->{default_view} )
 741       if $appclass->config->{default_view};
 742
 743     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 744
 745     if( $rest ) {
 746         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 747         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 748         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 749         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 750         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 751     }
 752
 753     return $c->_filter_component( $comp );
 754 }
 755
 756 =head2 $c->controllers
 757
 758 Returns the available names which can be passed to $c->controller
 759
 760 =cut
 761
 762 sub controllers {
 763     my ( $c ) = @_;
 764     return $c->_comp_names(qw/Controller C/);
 765 }
 766
 767 =head2 $c->models
 768
 769 Returns the available names which can be passed to $c->model
 770
 771 =cut
 772
 773 sub models {
 774     my ( $c ) = @_;
 775     return $c->_comp_names(qw/Model M/);
 776 }
 777
 778
 779 =head2 $c->views
 780
 781 Returns the available names which can be passed to $c->view
 782
 783 =cut
 784
 785 sub views {
 786     my ( $c ) = @_;
 787     return $c->_comp_names(qw/View V/);
 788 }
 789
 790 =head2 $c->comp($name)
 791
 792 =head2 $c->component($name)
 793
 794 Gets a component object by name. This method is not recommended,
 795 unless you want to get a specific component by full
 796 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 797 should be used instead.
 798
 799 If C<$name> is a regexp, a list of components matched against the full
 800 component name will be returned.
 801
 802 If Catalyst can't find a component by name, it will fallback to regex
 803 matching by default. To disable this behaviour set
 804 disable_component_resolution_regex_fallback to a true value.
 805
 806     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 807
 808 =cut
 809
 810 sub component {
 811     my ( $c, $name, @args ) = @_;
 812
 813     if( $name ) {
 814         my $comps = $c->components;
 815
 816         if( !ref $name ) {
 817             # is it the exact name?
 818             return $c->_filter_component( $comps->{ $name }, @args )
 819                        if exists $comps->{ $name };
 820
 821             # perhaps we just omitted "MyApp"?
 822             my $composed = ( ref $c || $c ) . "::${name}";
 823             return $c->_filter_component( $comps->{ $composed }, @args )
 824                        if exists $comps->{ $composed };
 825
 826             # search all of the models, views and controllers
 827             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 828             return $c->_filter_component( $comp, @args ) if $comp;
 829         }
 830
 831         # This is here so $c->comp( '::M::' ) works
 832         my $query = ref $name ? $name : qr{$name}i;
 833
 834         my @result = grep { m{$query} } keys %{ $c->components };
 835         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 836
 837         if( $result[ 0 ] ) {
 838             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 839             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 840             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 841             return $c->_filter_component( $result[ 0 ], @args );
 842         }
 843
 844         # I would expect to return an empty list here, but that breaks back-compat
 845     }
 846
 847     # fallback
 848     return sort keys %{ $c->components };
 849 }
 850
 851 =head2 CLASS DATA AND HELPER CLASSES
 852
 853 =head2 $c->config
 854
 855 Returns or takes a hashref containing the application's configuration.
 856
 857     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 858
 859 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 860 like C<myapp.conf> in your applications home directory. See
 861 L<Catalyst::Plugin::ConfigLoader>.
 862
 863 =head3 Cascading configuration
 864
 865 The config method is present on all Catalyst components, and configuration
 866 will be merged when an application is started. Configuration loaded with
 867 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 868 followed by configuration in your top level C<MyApp> class. These two
 869 configurations are merged, and then configuration data whose hash key matches a
 870 component name is merged with configuration for that component.
 871
 872 The configuration for a component is then passed to the C<new> method when a
 873 component is constructed.
 874
 875 For example:
 876
 877     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 878     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 879
 880 will mean that C<MyApp::Model::Foo> receives the following data when
 881 constructed:
 882
 883     MyApp::Model::Foo->new({
 884         bar => 'baz',
 885         quux => 'frob',
 886         overrides => 'me',
 887     });
 888
 889 =cut
 890
 891 around config => sub {
 892     my $orig = shift;
 893     my $c = shift;
 894
 895     croak('Setting config after setup has been run is not allowed.')
 896         if ( @_ and $c->setup_finished );
 897
 898     $c->$orig(@_);
 899 };
 900
 901 =head2 $c->log
 902
 903 Returns the logging object instance. Unless it is already set, Catalyst
 904 sets this up with a L<Catalyst::Log> object. To use your own log class,
 905 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 906 C<< __PACKAGE__->setup >>.
 907
 908  __PACKAGE__->log( MyLogger->new );
 909  __PACKAGE__->setup;
 910
 911 And later:
 912
 913     $c->log->info( 'Now logging with my own logger!' );
 914
 915 Your log class should implement the methods described in
 916 L<Catalyst::Log>.
 917
 918
 919 =head2 $c->debug
 920
 921 Returns 1 if debug mode is enabled, 0 otherwise.
 922
 923 You can enable debug mode in several ways:
 924
 925 =over
 926
 927 =item By calling myapp_server.pl with the -d flag
 928
 929 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 930
 931 =item The -Debug option in your MyApp.pm
 932
 933 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 934
 935 =back
 936
 937 The first three also set the log level to 'debug'.
 938
 939 Calling C<< $c->debug(1) >> has no effect.
 940
 941 =cut
 942
 943 sub debug { 0 }
 944
 945 =head2 $c->dispatcher
 946
 947 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 948
 949 =head2 $c->engine
 950
 951 Returns the engine instance. See L<Catalyst::Engine>.
 952
 953
 954 =head2 UTILITY METHODS
 955
 956 =head2 $c->path_to(@path)
 957
 958 Merges C<@path> with C<< $c->config->{home} >> and returns a
 959 L<Path::Class::Dir> object. Note you can usually use this object as
 960 a filename, but sometimes you will have to explicitly stringify it
 961 yourself by calling the C<< ->stringify >> method.
 962
 963 For example:
 964
 965     $c->path_to( 'db', 'sqlite.db' );
 966
 967 =cut
 968
 969 sub path_to {
 970     my ( $c, @path ) = @_;
 971     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 972     if ( -d $path ) { return $path }
 973     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 974 }
 975
 976 =head2 $c->plugin( $name, $class, @args )
 977
 978 Helper method for plugins. It creates a class data accessor/mutator and
 979 loads and instantiates the given class.
 980
 981     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 982
 983     $c->prototype->define_javascript_functions;
 984
 985 B<Note:> This method of adding plugins is deprecated. The ability
 986 to add plugins like this B<will be removed> in a Catalyst 5.81.
 987 Please do not use this functionality in new code.
 988
 989 =cut
 990
 991 sub plugin {
 992     my ( $class, $name, $plugin, @args ) = @_;
 993
 994     # See block comment in t/unit_core_plugin.t
 995     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 996
 997     $class->_register_plugin( $plugin, 1 );
 998
 999     eval { $plugin->import };
1000     $class->mk_classdata($name);
1001     my $obj;
1002     eval { $obj = $plugin->new(@args) };
1003
1004     if ($@) {
1005         Catalyst::Exception->throw( message =>
1006               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1007     }
1008
1009     $class->$name($obj);
1010     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1011       if $class->debug;
1012 }
1013
1014 =head2 MyApp->setup
1015
1016 Initializes the dispatcher and engine, loads any plugins, and loads the
1017 model, view, and controller components. You may also specify an array
1018 of plugins to load here, if you choose to not load them in the C<use
1019 Catalyst> line.
1020
1021     MyApp->setup;
1022     MyApp->setup( qw/-Debug/ );
1023
1024 =cut
1025
1026 sub setup {
1027     my ( $class, @arguments ) = @_;
1028     croak('Running setup more than once')
1029         if ( $class->setup_finished );
1030
1031     unless ( $class->isa('Catalyst') ) {
1032
1033         Catalyst::Exception->throw(
1034             message => qq/'$class' does not inherit from Catalyst/ );
1035     }
1036
1037     if ( $class->arguments ) {
1038         @arguments = ( @arguments, @{ $class->arguments } );
1039     }
1040
1041     # Process options
1042     my $flags = {};
1043
1044     foreach (@arguments) {
1045
1046         if (/^-Debug$/) {
1047             $flags->{log} =
1048               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1049         }
1050         elsif (/^-(\w+)=?(.*)$/) {
1051             $flags->{ lc $1 } = $2;
1052         }
1053         else {
1054             push @{ $flags->{plugins} }, $_;
1055         }
1056     }
1057
1058     $class->setup_home( delete $flags->{home} );
1059
1060     $class->setup_log( delete $flags->{log} );
1061     $class->setup_plugins( delete $flags->{plugins} );
1062     $class->setup_dispatcher( delete $flags->{dispatcher} );
1063     $class->setup_engine( delete $flags->{engine} );
1064     $class->setup_stats( delete $flags->{stats} );
1065
1066     for my $flag ( sort keys %{$flags} ) {
1067
1068         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1069             &$code( $class, delete $flags->{$flag} );
1070         }
1071         else {
1072             $class->log->warn(qq/Unknown flag "$flag"/);
1073         }
1074     }
1075
1076     eval { require Catalyst::Devel; };
1077     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1078         $class->log->warn(<<"EOF");
1079 You are running an old script!
1080
1081   Please update by running (this will overwrite existing files):
1082     catalyst.pl -force -scripts $class
1083
1084   or (this will not overwrite existing files):
1085     catalyst.pl -scripts $class
1086
1087 EOF
1088     }
1089
1090     if ( $class->debug ) {
1091         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1092
1093         if (@plugins) {
1094             my $column_width = Catalyst::Utils::term_width() - 6;
1095             my $t = Text::SimpleTable->new($column_width);
1096             $t->row($_) for @plugins;
1097             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1098         }
1099
1100         my $dispatcher = $class->dispatcher;
1101         my $engine     = $class->engine;
1102         my $home       = $class->config->{home};
1103
1104         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1105         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1106
1107         $home
1108           ? ( -d $home )
1109           ? $class->log->debug(qq/Found home "$home"/)
1110           : $class->log->debug(qq/Home "$home" doesn't exist/)
1111           : $class->log->debug(q/Couldn't find home/);
1112     }
1113
1114     # Call plugins setup, this is stupid and evil.
1115     # Also screws C3 badly on 5.10, hack to avoid.
1116     {
1117         no warnings qw/redefine/;
1118         local *setup = sub { };
1119         $class->setup unless $Catalyst::__AM_RESTARTING;
1120     }
1121
1122     # Initialize our data structure
1123     $class->components( {} );
1124
1125     $class->setup_components;
1126
1127     if ( $class->debug ) {
1128         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1129         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1130         for my $comp ( sort keys %{ $class->components } ) {
1131             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1132             $t->row( $comp, $type );
1133         }
1134         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1135           if ( keys %{ $class->components } );
1136     }
1137
1138     # Add our self to components, since we are also a component
1139     if( $class->isa('Catalyst::Controller') ){
1140       $class->components->{$class} = $class;
1141     }
1142
1143     $class->setup_actions;
1144
1145     if ( $class->debug ) {
1146         my $name = $class->config->{name} || 'Application';
1147         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1148     }
1149
1150     # Make sure that the application class becomes immutable at this point,
1151     B::Hooks::EndOfScope::on_scope_end {
1152         return if $@;
1153         my $meta = Class::MOP::get_metaclass_by_name($class);
1154         if (
1155             $meta->is_immutable
1156             && ! { $meta->immutable_options }->{replace_constructor}
1157             && (
1158                    $class->isa('Class::Accessor::Fast')
1159                 || $class->isa('Class::Accessor')
1160             )
1161         ) {
1162             warn "You made your application class ($class) immutable, "
1163                 . "but did not inline the\nconstructor. "
1164                 . "This will break catalyst, as your app \@ISA "
1165                 . "Class::Accessor(::Fast)?\nPlease pass "
1166                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1167         }
1168         $meta->make_immutable(
1169             replace_constructor => 1,
1170         ) unless $meta->is_immutable;
1171     };
1172
1173     if ($class->config->{case_sensitive}) {
1174         $class->log->warn($class . "->config->{case_sensitive} is set.");
1175         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1176     }
1177
1178     $class->setup_finalize;
1179     # Should be the last thing we do so that user things hooking
1180     # setup_finalize can log..
1181     $class->log->_flush() if $class->log->can('_flush');
1182     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1183 }
1184
1185 =head2 $app->setup_finalize
1186
1187 A hook to attach modifiers to. This method does not do anything except set the
1188 C<setup_finished> accessor.
1189
1190 Applying method modifiers to the C<setup> method doesn't work, because of quirky thingsdone for plugin setup.
1191
1192 Example:
1193
1194     after setup_finalize => sub {
1195         my $app = shift;
1196
1197         ## do stuff here..
1198     };
1199
1200 =cut
1201
1202 sub setup_finalize {
1203     my ($class) = @_;
1204     $class->setup_finished(1);
1205 }
1206
1207 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1208
1209 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1210
1211 Constructs an absolute L<URI> object based on the application root, the
1212 provided path, and the additional arguments and query parameters provided.
1213 When used as a string, provides a textual URI.
1214
1215 If no arguments are provided, the URI for the current action is returned.
1216 To return the current action and also provide @args, use
1217 C<< $c->uri_for( $c->action, @args ) >>.
1218
1219 If the first argument is a string, it is taken as a public URI path relative
1220 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1221 relative to the application root (if it does). It is then merged with
1222 C<< $c->request->base >>; any C<@args> are appended as additional path
1223 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1224
1225 If the first argument is a L<Catalyst::Action> it represents an action which
1226 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1227 optional C<\@captures> argument (an arrayref) allows passing the captured
1228 variables that are needed to fill in the paths of Chained and Regex actions;
1229 once the path is resolved, C<uri_for> continues as though a path was
1230 provided, appending any arguments or parameters and creating an absolute
1231 URI.
1232
1233 The captures for the current request can be found in
1234 C<< $c->request->captures >>, and actions can be resolved using
1235 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1236 path, use C<< $c->uri_for_action >> instead.
1237
1238   # Equivalent to $c->req->uri
1239   $c->uri_for($c->action, $c->req->captures,
1240       @{ $c->req->args }, $c->req->params);
1241
1242   # For the Foo action in the Bar controller
1243   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1244
1245   # Path to a static resource
1246   $c->uri_for('/static/images/logo.png');
1247
1248 =cut
1249
1250 sub uri_for {
1251     my ( $c, $path, @args ) = @_;
1252
1253     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1254         $path = $path->path_prefix;
1255         $path =~ s{/+\z}{};
1256         $path .= '/';
1257     }
1258
1259     undef($path) if (defined $path && $path eq '');
1260
1261     my $params =
1262       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1263
1264     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1265     foreach my $arg (@args) {
1266         utf8::encode($arg) if utf8::is_utf8($arg);
1267     }
1268     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1269     if (blessed $path) { # Action object only.
1270         s|/|%2F|g for @args;
1271     }
1272
1273     if ( blessed($path) ) { # action object
1274         my $captures = [ map { s|/|%2F|g; $_; }
1275                         ( scalar @args && ref $args[0] eq 'ARRAY'
1276                          ? @{ shift(@args) }
1277                          : ()) ];
1278
1279         foreach my $capture (@$captures) {
1280             utf8::encode($capture) if utf8::is_utf8($capture);
1281             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1282         }
1283
1284         my $action = $path;
1285         $path = $c->dispatcher->uri_for_action($action, $captures);
1286         if (not defined $path) {
1287             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1288                 if $c->debug;
1289             return undef;
1290         }
1291         $path = '/' if $path eq '';
1292     }
1293
1294     undef($path) if (defined $path && $path eq '');
1295
1296     unshift(@args, $path);
1297
1298     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1299         my $namespace = $c->namespace;
1300         if (defined $path) { # cheesy hack to handle path '../foo'
1301            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1302         }
1303         unshift(@args, $namespace || '');
1304     }
1305
1306     # join args with '/', or a blank string
1307     my $args = join('/', grep { defined($_) } @args);
1308     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1309     $args =~ s!^/+!!;
1310     my $base = $c->req->base;
1311     my $class = ref($base);
1312     $base =~ s{(?<!/)$}{/};
1313
1314     my $query = '';
1315
1316     if (my @keys = keys %$params) {
1317       # somewhat lifted from URI::_query's query_form
1318       $query = '?'.join('&', map {
1319           my $val = $params->{$_};
1320           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1321           s/ /+/g;
1322           my $key = $_;
1323           $val = '' unless defined $val;
1324           (map {
1325               my $param = "$_";
1326               utf8::encode( $param ) if utf8::is_utf8($param);
1327               # using the URI::Escape pattern here so utf8 chars survive
1328               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1329               $param =~ s/ /+/g;
1330               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1331       } @keys);
1332     }
1333
1334     my $res = bless(\"${base}${args}${query}", $class);
1335     $res;
1336 }
1337
1338 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1339
1340 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1341
1342 =over
1343
1344 =item $path
1345
1346 A private path to the Catalyst action you want to create a URI for.
1347
1348 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1349 >> and passing the resulting C<$action> and the remaining arguments to C<<
1350 $c->uri_for >>.
1351
1352 You can also pass in a Catalyst::Action object, in which case it is passed to
1353 C<< $c->uri_for >>.
1354
1355 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1356
1357 For example, if the action looks like:
1358
1359  package MyApp::Controller::Users;
1360
1361  sub lst : Path('the-list') {}
1362
1363 You can use:
1364
1365  $c->uri_for_action('/users/lst')
1366
1367 and it will create the URI /users/the-list.
1368
1369 =back
1370
1371 =cut
1372
1373 sub uri_for_action {
1374     my ( $c, $path, @args ) = @_;
1375     my $action = blessed($path)
1376       ? $path
1377       : $c->dispatcher->get_action_by_path($path);
1378     unless (defined $action) {
1379       croak "Can't find action for path '$path'";
1380     }
1381     return $c->uri_for( $action, @args );
1382 }
1383
1384 =head2 $c->welcome_message
1385
1386 Returns the Catalyst welcome HTML page.
1387
1388 =cut
1389
1390 sub welcome_message {
1391     my $c      = shift;
1392     my $name   = $c->config->{name};
1393     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1394     my $prefix = Catalyst::Utils::appprefix( ref $c );
1395     $c->response->content_type('text/html; charset=utf-8');
1396     return <<"EOF";
1397 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1398     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1399 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1400     <head>
1401     <meta http-equiv="Content-Language" content="en" />
1402     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1403         <title>$name on Catalyst $VERSION</title>
1404         <style type="text/css">
1405             body {
1406                 color: #000;
1407                 background-color: #eee;
1408             }
1409             div#content {
1410                 width: 640px;
1411                 margin-left: auto;
1412                 margin-right: auto;
1413                 margin-top: 10px;
1414                 margin-bottom: 10px;
1415                 text-align: left;
1416                 background-color: #ccc;
1417                 border: 1px solid #aaa;
1418             }
1419             p, h1, h2 {
1420                 margin-left: 20px;
1421                 margin-right: 20px;
1422                 font-family: verdana, tahoma, sans-serif;
1423             }
1424             a {
1425                 font-family: verdana, tahoma, sans-serif;
1426             }
1427             :link, :visited {
1428                     text-decoration: none;
1429                     color: #b00;
1430                     border-bottom: 1px dotted #bbb;
1431             }
1432             :link:hover, :visited:hover {
1433                     color: #555;
1434             }
1435             div#topbar {
1436                 margin: 0px;
1437             }
1438             pre {
1439                 margin: 10px;
1440                 padding: 8px;
1441             }
1442             div#answers {
1443                 padding: 8px;
1444                 margin: 10px;
1445                 background-color: #fff;
1446                 border: 1px solid #aaa;
1447             }
1448             h1 {
1449                 font-size: 0.9em;
1450                 font-weight: normal;
1451                 text-align: center;
1452             }
1453             h2 {
1454                 font-size: 1.0em;
1455             }
1456             p {
1457                 font-size: 0.9em;
1458             }
1459             p img {
1460                 float: right;
1461                 margin-left: 10px;
1462             }
1463             span#appname {
1464                 font-weight: bold;
1465                 font-size: 1.6em;
1466             }
1467         </style>
1468     </head>
1469     <body>
1470         <div id="content">
1471             <div id="topbar">
1472                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1473                     $VERSION</h1>
1474              </div>
1475              <div id="answers">
1476                  <p>
1477                  <img src="$logo" alt="Catalyst Logo" />
1478                  </p>
1479                  <p>Welcome to the  world of Catalyst.
1480                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1481                     framework will make web development something you had
1482                     never expected it to be: Fun, rewarding, and quick.</p>
1483                  <h2>What to do now?</h2>
1484                  <p>That really depends  on what <b>you</b> want to do.
1485                     We do, however, provide you with a few starting points.</p>
1486                  <p>If you want to jump right into web development with Catalyst
1487                     you might want to start with a tutorial.</p>
1488 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1489 </pre>
1490 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1491 <pre>
1492 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1493 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1494 </code></pre>
1495                  <h2>What to do next?</h2>
1496                  <p>Next it's time to write an actual application. Use the
1497                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1498                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1499                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1500                     they can save you a lot of work.</p>
1501                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1502                     <p>Also, be sure to check out the vast and growing
1503                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1504                     you are likely to find what you need there.
1505                     </p>
1506
1507                  <h2>Need help?</h2>
1508                  <p>Catalyst has a very active community. Here are the main places to
1509                     get in touch with us.</p>
1510                  <ul>
1511                      <li>
1512                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1513                      </li>
1514                      <li>
1515                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1516                      </li>
1517                      <li>
1518                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1519                      </li>
1520                  </ul>
1521                  <h2>In conclusion</h2>
1522                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1523                     as we enjoyed making it. Please contact us if you have ideas
1524                     for improvement or other feedback.</p>
1525              </div>
1526          </div>
1527     </body>
1528 </html>
1529 EOF
1530 }
1531
1532 =head1 INTERNAL METHODS
1533
1534 These methods are not meant to be used by end users.
1535
1536 =head2 $c->components
1537
1538 Returns a hash of components.
1539
1540 =head2 $c->context_class
1541
1542 Returns or sets the context class.
1543
1544 =head2 $c->counter
1545
1546 Returns a hashref containing coderefs and execution counts (needed for
1547 deep recursion detection).
1548
1549 =head2 $c->depth
1550
1551 Returns the number of actions on the current internal execution stack.
1552
1553 =head2 $c->dispatch
1554
1555 Dispatches a request to actions.
1556
1557 =cut
1558
1559 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1560
1561 =head2 $c->dispatcher_class
1562
1563 Returns or sets the dispatcher class.
1564
1565 =head2 $c->dump_these
1566
1567 Returns a list of 2-element array references (name, structure) pairs
1568 that will be dumped on the error page in debug mode.
1569
1570 =cut
1571
1572 sub dump_these {
1573     my $c = shift;
1574     [ Request => $c->req ],
1575     [ Response => $c->res ],
1576     [ Stash => $c->stash ],
1577     [ Config => $c->config ];
1578 }
1579
1580 =head2 $c->engine_class
1581
1582 Returns or sets the engine class.
1583
1584 =head2 $c->execute( $class, $coderef )
1585
1586 Execute a coderef in given class and catch exceptions. Errors are available
1587 via $c->error.
1588
1589 =cut
1590
1591 sub execute {
1592     my ( $c, $class, $code ) = @_;
1593     $class = $c->component($class) || $class;
1594     $c->state(0);
1595
1596     if ( $c->depth >= $RECURSION ) {
1597         my $action = $code->reverse();
1598         $action = "/$action" unless $action =~ /->/;
1599         my $error = qq/Deep recursion detected calling "${action}"/;
1600         $c->log->error($error);
1601         $c->error($error);
1602         $c->state(0);
1603         return $c->state;
1604     }
1605
1606     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1607
1608     push( @{ $c->stack }, $code );
1609
1610     no warnings 'recursion';
1611     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1612
1613     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1614
1615     my $last = pop( @{ $c->stack } );
1616
1617     if ( my $error = $@ ) {
1618         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1619             $error->rethrow if $c->depth > 1;
1620         }
1621         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1622             $error->rethrow if $c->depth > 0;
1623         }
1624         else {
1625             unless ( ref $error ) {
1626                 no warnings 'uninitialized';
1627                 chomp $error;
1628                 my $class = $last->class;
1629                 my $name  = $last->name;
1630                 $error = qq/Caught exception in $class->$name "$error"/;
1631             }
1632             $c->error($error);
1633             $c->state(0);
1634         }
1635     }
1636     return $c->state;
1637 }
1638
1639 sub _stats_start_execute {
1640     my ( $c, $code ) = @_;
1641     my $appclass = ref($c) || $c;
1642     return if ( ( $code->name =~ /^_.*/ )
1643         && ( !$appclass->config->{show_internal_actions} ) );
1644
1645     my $action_name = $code->reverse();
1646     $c->counter->{$action_name}++;
1647
1648     my $action = $action_name;
1649     $action = "/$action" unless $action =~ /->/;
1650
1651     # determine if the call was the result of a forward
1652     # this is done by walking up the call stack and looking for a calling
1653     # sub of Catalyst::forward before the eval
1654     my $callsub = q{};
1655     for my $index ( 2 .. 11 ) {
1656         last
1657         if ( ( caller($index) )[0] eq 'Catalyst'
1658             && ( caller($index) )[3] eq '(eval)' );
1659
1660         if ( ( caller($index) )[3] =~ /forward$/ ) {
1661             $callsub = ( caller($index) )[3];
1662             $action  = "-> $action";
1663             last;
1664         }
1665     }
1666
1667     my $uid = $action_name . $c->counter->{$action_name};
1668
1669     # is this a root-level call or a forwarded call?
1670     if ( $callsub =~ /forward$/ ) {
1671         my $parent = $c->stack->[-1];
1672
1673         # forward, locate the caller
1674         if ( exists $c->counter->{"$parent"} ) {
1675             $c->stats->profile(
1676                 begin  => $action,
1677                 parent => "$parent" . $c->counter->{"$parent"},
1678                 uid    => $uid,
1679             );
1680         }
1681         else {
1682
1683             # forward with no caller may come from a plugin
1684             $c->stats->profile(
1685                 begin => $action,
1686                 uid   => $uid,
1687             );
1688         }
1689     }
1690     else {
1691
1692         # root-level call
1693         $c->stats->profile(
1694             begin => $action,
1695             uid   => $uid,
1696         );
1697     }
1698     return $action;
1699
1700 }
1701
1702 sub _stats_finish_execute {
1703     my ( $c, $info ) = @_;
1704     $c->stats->profile( end => $info );
1705 }
1706
1707 =head2 $c->finalize
1708
1709 Finalizes the request.
1710
1711 =cut
1712
1713 sub finalize {
1714     my $c = shift;
1715
1716     for my $error ( @{ $c->error } ) {
1717         $c->log->error($error);
1718     }
1719
1720     # Allow engine to handle finalize flow (for POE)
1721     my $engine = $c->engine;
1722     if ( my $code = $engine->can('finalize') ) {
1723         $engine->$code($c);
1724     }
1725     else {
1726
1727         $c->finalize_uploads;
1728
1729         # Error
1730         if ( $#{ $c->error } >= 0 ) {
1731             $c->finalize_error;
1732         }
1733
1734         $c->finalize_headers;
1735
1736         # HEAD request
1737         if ( $c->request->method eq 'HEAD' ) {
1738             $c->response->body('');
1739         }
1740
1741         $c->finalize_body;
1742     }
1743
1744     if ($c->use_stats) {
1745         my $elapsed = sprintf '%f', $c->stats->elapsed;
1746         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1747         $c->log->info(
1748             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1749     }
1750
1751     return $c->response->status;
1752 }
1753
1754 =head2 $c->finalize_body
1755
1756 Finalizes body.
1757
1758 =cut
1759
1760 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1761
1762 =head2 $c->finalize_cookies
1763
1764 Finalizes cookies.
1765
1766 =cut
1767
1768 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1769
1770 =head2 $c->finalize_error
1771
1772 Finalizes error.
1773
1774 =cut
1775
1776 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1777
1778 =head2 $c->finalize_headers
1779
1780 Finalizes headers.
1781
1782 =cut
1783
1784 sub finalize_headers {
1785     my $c = shift;
1786
1787     my $response = $c->response; #accessor calls can add up?
1788
1789     # Check if we already finalized headers
1790     return if $response->finalized_headers;
1791
1792     # Handle redirects
1793     if ( my $location = $response->redirect ) {
1794         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1795         $response->header( Location => $location );
1796
1797         if ( !$response->has_body ) {
1798             # Add a default body if none is already present
1799             $response->body(
1800                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1801             );
1802         }
1803     }
1804
1805     # Content-Length
1806     if ( $response->body && !$response->content_length ) {
1807
1808         # get the length from a filehandle
1809         if ( blessed( $response->body ) && $response->body->can('read') )
1810         {
1811             my $stat = stat $response->body;
1812             if ( $stat && $stat->size > 0 ) {
1813                 $response->content_length( $stat->size );
1814             }
1815             else {
1816                 $c->log->warn('Serving filehandle without a content-length');
1817             }
1818         }
1819         else {
1820             # everything should be bytes at this point, but just in case
1821             $response->content_length( length( $response->body ) );
1822         }
1823     }
1824
1825     # Errors
1826     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1827         $response->headers->remove_header("Content-Length");
1828         $response->body('');
1829     }
1830
1831     $c->finalize_cookies;
1832
1833     $c->engine->finalize_headers( $c, @_ );
1834
1835     # Done
1836     $response->finalized_headers(1);
1837 }
1838
1839 =head2 $c->finalize_output
1840
1841 An alias for finalize_body.
1842
1843 =head2 $c->finalize_read
1844
1845 Finalizes the input after reading is complete.
1846
1847 =cut
1848
1849 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1850
1851 =head2 $c->finalize_uploads
1852
1853 Finalizes uploads. Cleans up any temporary files.
1854
1855 =cut
1856
1857 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1858
1859 =head2 $c->get_action( $action, $namespace )
1860
1861 Gets an action in a given namespace.
1862
1863 =cut
1864
1865 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1866
1867 =head2 $c->get_actions( $action, $namespace )
1868
1869 Gets all actions of a given name in a namespace and all parent
1870 namespaces.
1871
1872 =cut
1873
1874 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1875
1876 =head2 $c->handle_request( $class, @arguments )
1877
1878 Called to handle each HTTP request.
1879
1880 =cut
1881
1882 sub handle_request {
1883     my ( $class, @arguments ) = @_;
1884
1885     # Always expect worst case!
1886     my $status = -1;
1887     eval {
1888         if ($class->debug) {
1889             my $secs = time - $START || 1;
1890             my $av = sprintf '%.3f', $COUNT / $secs;
1891             my $time = localtime time;
1892             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1893         }
1894
1895         my $c = $class->prepare(@arguments);
1896         $c->dispatch;
1897         $status = $c->finalize;
1898     };
1899
1900     if ( my $error = $@ ) {
1901         chomp $error;
1902         $class->log->error(qq/Caught exception in engine "$error"/);
1903     }
1904
1905     $COUNT++;
1906
1907     if(my $coderef = $class->log->can('_flush')){
1908         $class->log->$coderef();
1909     }
1910     return $status;
1911 }
1912
1913 =head2 $c->prepare( @arguments )
1914
1915 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1916 etc.).
1917
1918 =cut
1919
1920 sub prepare {
1921     my ( $class, @arguments ) = @_;
1922
1923     # XXX
1924     # After the app/ctxt split, this should become an attribute based on something passed
1925     # into the application.
1926     $class->context_class( ref $class || $class ) unless $class->context_class;
1927
1928     my $c = $class->context_class->new({});
1929
1930     # For on-demand data
1931     $c->request->_context($c);
1932     $c->response->_context($c);
1933
1934     #surely this is not the most efficient way to do things...
1935     $c->stats($class->stats_class->new)->enable($c->use_stats);
1936     if ( $c->debug ) {
1937         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1938     }
1939
1940     #XXX reuse coderef from can
1941     # Allow engine to direct the prepare flow (for POE)
1942     if ( $c->engine->can('prepare') ) {
1943         $c->engine->prepare( $c, @arguments );
1944     }
1945     else {
1946         $c->prepare_request(@arguments);
1947         $c->prepare_connection;
1948         $c->prepare_query_parameters;
1949         $c->prepare_headers;
1950         $c->prepare_cookies;
1951         $c->prepare_path;
1952
1953         # Prepare the body for reading, either by prepare_body
1954         # or the user, if they are using $c->read
1955         $c->prepare_read;
1956
1957         # Parse the body unless the user wants it on-demand
1958         unless ( ref($c)->config->{parse_on_demand} ) {
1959             $c->prepare_body;
1960         }
1961     }
1962
1963     my $method  = $c->req->method  || '';
1964     my $path    = $c->req->path;
1965     $path       = '/' unless length $path;
1966     my $address = $c->req->address || '';
1967
1968     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1969       if $c->debug;
1970
1971     $c->prepare_action;
1972
1973     return $c;
1974 }
1975
1976 =head2 $c->prepare_action
1977
1978 Prepares action. See L<Catalyst::Dispatcher>.
1979
1980 =cut
1981
1982 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1983
1984 =head2 $c->prepare_body
1985
1986 Prepares message body.
1987
1988 =cut
1989
1990 sub prepare_body {
1991     my $c = shift;
1992
1993     return if $c->request->_has_body;
1994
1995     # Initialize on-demand data
1996     $c->engine->prepare_body( $c, @_ );
1997     $c->prepare_parameters;
1998     $c->prepare_uploads;
1999
2000     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
2001         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
2002         for my $key ( sort keys %{ $c->req->body_parameters } ) {
2003             my $param = $c->req->body_parameters->{$key};
2004             my $value = defined($param) ? $param : '';
2005             $t->row( $key,
2006                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2007         }
2008         $c->log->debug( "Body Parameters are:\n" . $t->draw );
2009     }
2010 }
2011
2012 =head2 $c->prepare_body_chunk( $chunk )
2013
2014 Prepares a chunk of data before sending it to L<HTTP::Body>.
2015
2016 See L<Catalyst::Engine>.
2017
2018 =cut
2019
2020 sub prepare_body_chunk {
2021     my $c = shift;
2022     $c->engine->prepare_body_chunk( $c, @_ );
2023 }
2024
2025 =head2 $c->prepare_body_parameters
2026
2027 Prepares body parameters.
2028
2029 =cut
2030
2031 sub prepare_body_parameters {
2032     my $c = shift;
2033     $c->engine->prepare_body_parameters( $c, @_ );
2034 }
2035
2036 =head2 $c->prepare_connection
2037
2038 Prepares connection.
2039
2040 =cut
2041
2042 sub prepare_connection {
2043     my $c = shift;
2044     $c->engine->prepare_connection( $c, @_ );
2045 }
2046
2047 =head2 $c->prepare_cookies
2048
2049 Prepares cookies.
2050
2051 =cut
2052
2053 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2054
2055 =head2 $c->prepare_headers
2056
2057 Prepares headers.
2058
2059 =cut
2060
2061 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2062
2063 =head2 $c->prepare_parameters
2064
2065 Prepares parameters.
2066
2067 =cut
2068
2069 sub prepare_parameters {
2070     my $c = shift;
2071     $c->prepare_body_parameters;
2072     $c->engine->prepare_parameters( $c, @_ );
2073 }
2074
2075 =head2 $c->prepare_path
2076
2077 Prepares path and base.
2078
2079 =cut
2080
2081 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2082
2083 =head2 $c->prepare_query_parameters
2084
2085 Prepares query parameters.
2086
2087 =cut
2088
2089 sub prepare_query_parameters {
2090     my $c = shift;
2091
2092     $c->engine->prepare_query_parameters( $c, @_ );
2093
2094     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
2095         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
2096         for my $key ( sort keys %{ $c->req->query_parameters } ) {
2097             my $param = $c->req->query_parameters->{$key};
2098             my $value = defined($param) ? $param : '';
2099             $t->row( $key,
2100                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2101         }
2102         $c->log->debug( "Query Parameters are:\n" . $t->draw );
2103     }
2104 }
2105
2106 =head2 $c->prepare_read
2107
2108 Prepares the input for reading.
2109
2110 =cut
2111
2112 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2113
2114 =head2 $c->prepare_request
2115
2116 Prepares the engine request.
2117
2118 =cut
2119
2120 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2121
2122 =head2 $c->prepare_uploads
2123
2124 Prepares uploads.
2125
2126 =cut
2127
2128 sub prepare_uploads {
2129     my $c = shift;
2130
2131     $c->engine->prepare_uploads( $c, @_ );
2132
2133     if ( $c->debug && keys %{ $c->request->uploads } ) {
2134         my $t = Text::SimpleTable->new(
2135             [ 12, 'Parameter' ],
2136             [ 26, 'Filename' ],
2137             [ 18, 'Type' ],
2138             [ 9,  'Size' ]
2139         );
2140         for my $key ( sort keys %{ $c->request->uploads } ) {
2141             my $upload = $c->request->uploads->{$key};
2142             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2143                 $t->row( $key, $u->filename, $u->type, $u->size );
2144             }
2145         }
2146         $c->log->debug( "File Uploads are:\n" . $t->draw );
2147     }
2148 }
2149
2150 =head2 $c->prepare_write
2151
2152 Prepares the output for writing.
2153
2154 =cut
2155
2156 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2157
2158 =head2 $c->request_class
2159
2160 Returns or sets the request class.
2161
2162 =head2 $c->response_class
2163
2164 Returns or sets the response class.
2165
2166 =head2 $c->read( [$maxlength] )
2167
2168 Reads a chunk of data from the request body. This method is designed to
2169 be used in a while loop, reading C<$maxlength> bytes on every call.
2170 C<$maxlength> defaults to the size of the request if not specified.
2171
2172 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2173 directly.
2174
2175 Warning: If you use read(), Catalyst will not process the body,
2176 so you will not be able to access POST parameters or file uploads via
2177 $c->request.  You must handle all body parsing yourself.
2178
2179 =cut
2180
2181 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2182
2183 =head2 $c->run
2184
2185 Starts the engine.
2186
2187 =cut
2188
2189 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2190
2191 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2192
2193 Sets an action in a given namespace.
2194
2195 =cut
2196
2197 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2198
2199 =head2 $c->setup_actions($component)
2200
2201 Sets up actions for a component.
2202
2203 =cut
2204
2205 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2206
2207 =head2 $c->setup_components
2208
2209 This method is called internally to set up the application's components.
2210
2211 It finds modules by calling the L<locate_components> method, expands them to
2212 package names with the L<expand_component_module> method, and then installs
2213 each component into the application.
2214
2215 The C<setup_components> config option is passed to both of the above methods.
2216
2217 Installation of each component is performed by the L<setup_component> method,
2218 below.
2219
2220 =cut
2221
2222 sub setup_components {
2223     my $class = shift;
2224
2225     my $config  = $class->config->{ setup_components };
2226
2227     my @comps = sort { length $a <=> length $b }
2228                 $class->locate_components($config);
2229     my %comps = map { $_ => 1 } @comps;
2230
2231     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2232     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2233         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2234     ) if $deprecatedcatalyst_component_names;
2235
2236     for my $component ( @comps ) {
2237
2238         # We pass ignore_loaded here so that overlay files for (e.g.)
2239         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2240         # we know M::P::O found a file on disk so this is safe
2241
2242         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2243
2244         # Needs to be done as soon as the component is loaded, as loading a sub-component
2245         # (next time round the loop) can cause us to get the wrong metaclass..
2246         $class->_controller_init_base_classes($component);
2247     }
2248
2249     for my $component (@comps) {
2250         my $instance = $class->components->{ $component } = $class->setup_component($component);
2251         my @expanded_components = $instance->can('expand_modules')
2252             ? $instance->expand_modules( $component, $config )
2253             : $class->expand_component_module( $component, $config );
2254         for my $component (@expanded_components) {
2255             next if $comps{$component};
2256             $class->_controller_init_base_classes($component); # Also cover inner packages
2257             $class->components->{ $component } = $class->setup_component($component);
2258         }
2259     }
2260 }
2261
2262 =head2 $c->locate_components( $setup_component_config )
2263
2264 This method is meant to provide a list of component modules that should be
2265 setup for the application.  By default, it will use L<Module::Pluggable>.
2266
2267 Specify a C<setup_components> config option to pass additional options directly
2268 to L<Module::Pluggable>. To add additional search paths, specify a key named
2269 C<search_extra> as an array reference. Items in the array beginning with C<::>
2270 will have the application class name prepended to them.
2271
2272 =cut
2273
2274 sub locate_components {
2275     my $class  = shift;
2276     my $config = shift;
2277
2278     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2279     my $extra   = delete $config->{ search_extra } || [];
2280
2281     push @paths, @$extra;
2282
2283     my $locator = Module::Pluggable::Object->new(
2284         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2285         %$config
2286     );
2287
2288     my @comps = $locator->plugins;
2289
2290     return @comps;
2291 }
2292
2293 =head2 $c->expand_component_module( $component, $setup_component_config )
2294
2295 Components found by C<locate_components> will be passed to this method, which
2296 is expected to return a list of component (package) names to be set up.
2297
2298 =cut
2299
2300 sub expand_component_module {
2301     my ($class, $module) = @_;
2302     return Devel::InnerPackage::list_packages( $module );
2303 }
2304
2305 =head2 $c->setup_component
2306
2307 =cut
2308
2309 # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2310 #         nearest to Catalyst::Controller first, no matter what order stuff happens
2311 #         to be loaded. There are TODO tests in Moose for this, see
2312 #         f2391d17574eff81d911b97be15ea51080500003
2313 sub _controller_init_base_classes {
2314     my ($app_class, $component) = @_;
2315     return unless $component->isa('Catalyst::Controller');
2316     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2317         Moose::Meta::Class->initialize( $class )
2318             unless find_meta($class);
2319     }
2320 }
2321
2322 sub setup_component {
2323     my( $class, $component ) = @_;
2324
2325     unless ( $component->can( 'COMPONENT' ) ) {
2326         return $component;
2327     }
2328
2329     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2330     my $config = $class->config->{ $suffix } || {};
2331     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2332     # methods also pass it. local to avoid pointlessly shitting in config
2333     # for the debug screen, as $component is already the key name.
2334     local $config->{catalyst_component_name} = $component;
2335
2336     my $instance = eval { $component->COMPONENT( $class, $config ); };
2337
2338     if ( my $error = $@ ) {
2339         chomp $error;
2340         Catalyst::Exception->throw(
2341             message => qq/Couldn't instantiate component "$component", "$error"/
2342         );
2343     }
2344
2345     unless (blessed $instance) {
2346         my $metaclass = Moose::Util::find_meta($component);
2347         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2348         my $component_method_from = $method_meta->associated_metaclass->name;
2349         my $value = defined($instance) ? $instance : 'undef';
2350         Catalyst::Exception->throw(
2351             message =>
2352             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2353         );
2354     }
2355     return $instance;
2356 }
2357
2358 =head2 $c->setup_dispatcher
2359
2360 Sets up dispatcher.
2361
2362 =cut
2363
2364 sub setup_dispatcher {
2365     my ( $class, $dispatcher ) = @_;
2366
2367     if ($dispatcher) {
2368         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2369     }
2370
2371     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2372         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2373     }
2374
2375     unless ($dispatcher) {
2376         $dispatcher = $class->dispatcher_class;
2377     }
2378
2379     Class::MOP::load_class($dispatcher);
2380
2381     # dispatcher instance
2382     $class->dispatcher( $dispatcher->new );
2383 }
2384
2385 =head2 $c->setup_engine
2386
2387 Sets up engine.
2388
2389 =cut
2390
2391 sub setup_engine {
2392     my ( $class, $engine ) = @_;
2393
2394     if ($engine) {
2395         $engine = 'Catalyst::Engine::' . $engine;
2396     }
2397
2398     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2399         $engine = 'Catalyst::Engine::' . $env;
2400     }
2401
2402     if ( $ENV{MOD_PERL} ) {
2403         my $meta = Class::MOP::get_metaclass_by_name($class);
2404
2405         # create the apache method
2406         $meta->add_method('apache' => sub { shift->engine->apache });
2407
2408         my ( $software, $version ) =
2409           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2410
2411         $version =~ s/_//g;
2412         $version =~ s/(\.[^.]+)\./$1/g;
2413
2414         if ( $software eq 'mod_perl' ) {
2415
2416             if ( !$engine ) {
2417
2418                 if ( $version >= 1.99922 ) {
2419                     $engine = 'Catalyst::Engine::Apache2::MP20';
2420                 }
2421
2422                 elsif ( $version >= 1.9901 ) {
2423                     $engine = 'Catalyst::Engine::Apache2::MP19';
2424                 }
2425
2426                 elsif ( $version >= 1.24 ) {
2427                     $engine = 'Catalyst::Engine::Apache::MP13';
2428                 }
2429
2430                 else {
2431                     Catalyst::Exception->throw( message =>
2432                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2433                 }
2434
2435             }
2436
2437             # install the correct mod_perl handler
2438             if ( $version >= 1.9901 ) {
2439                 *handler = sub  : method {
2440                     shift->handle_request(@_);
2441                 };
2442             }
2443             else {
2444                 *handler = sub ($$) { shift->handle_request(@_) };
2445             }
2446
2447         }
2448
2449         elsif ( $software eq 'Zeus-Perl' ) {
2450             $engine = 'Catalyst::Engine::Zeus';
2451         }
2452
2453         else {
2454             Catalyst::Exception->throw(
2455                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2456         }
2457     }
2458
2459     unless ($engine) {
2460         $engine = $class->engine_class;
2461     }
2462
2463     Class::MOP::load_class($engine);
2464
2465     # check for old engines that are no longer compatible
2466     my $old_engine;
2467     if ( $engine->isa('Catalyst::Engine::Apache')
2468         && !Catalyst::Engine::Apache->VERSION )
2469     {
2470         $old_engine = 1;
2471     }
2472
2473     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2474         && Catalyst::Engine::Server->VERSION le '0.02' )
2475     {
2476         $old_engine = 1;
2477     }
2478
2479     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2480         && $engine->VERSION eq '0.01' )
2481     {
2482         $old_engine = 1;
2483     }
2484
2485     elsif ($engine->isa('Catalyst::Engine::Zeus')
2486         && $engine->VERSION eq '0.01' )
2487     {
2488         $old_engine = 1;
2489     }
2490
2491     if ($old_engine) {
2492         Catalyst::Exception->throw( message =>
2493               qq/Engine "$engine" is not supported by this version of Catalyst/
2494         );
2495     }
2496
2497     # engine instance
2498     $class->engine( $engine->new );
2499 }
2500
2501 =head2 $c->setup_home
2502
2503 Sets up the home directory.
2504
2505 =cut
2506
2507 sub setup_home {
2508     my ( $class, $home ) = @_;
2509
2510     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2511         $home = $env;
2512     }
2513
2514     $home ||= Catalyst::Utils::home($class);
2515
2516     if ($home) {
2517         #I remember recently being scolded for assigning config values like this
2518         $class->config->{home} ||= $home;
2519         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2520     }
2521 }
2522
2523 =head2 $c->setup_log
2524
2525 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2526 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2527 log to.
2528
2529 This method also installs a C<debug> method that returns a true value into the
2530 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2531 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2532
2533 Note that if the log has already been setup, by either a previous call to
2534 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2535 that this method won't actually set up the log object.
2536
2537 =cut
2538
2539 sub setup_log {
2540     my ( $class, $levels ) = @_;
2541
2542     $levels ||= '';
2543     $levels =~ s/^\s+//;
2544     $levels =~ s/\s+$//;
2545     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2546
2547     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2548     if ( defined $env_debug ) {
2549         $levels{debug} = 1 if $env_debug; # Ugly!
2550         delete($levels{debug}) unless $env_debug;
2551     }
2552
2553     unless ( $class->log ) {
2554         $class->log( Catalyst::Log->new(keys %levels) );
2555     }
2556
2557     if ( $levels{debug} ) {
2558         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2559         $class->log->debug('Debug messages enabled');
2560     }
2561 }
2562
2563 =head2 $c->setup_plugins
2564
2565 Sets up plugins.
2566
2567 =cut
2568
2569 =head2 $c->setup_stats
2570
2571 Sets up timing statistics class.
2572
2573 =cut
2574
2575 sub setup_stats {
2576     my ( $class, $stats ) = @_;
2577
2578     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2579
2580     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2581     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2582         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2583         $class->log->debug('Statistics enabled');
2584     }
2585 }
2586
2587
2588 =head2 $c->registered_plugins
2589
2590 Returns a sorted list of the plugins which have either been stated in the
2591 import list or which have been added via C<< MyApp->plugin(@args); >>.
2592
2593 If passed a given plugin name, it will report a boolean value indicating
2594 whether or not that plugin is loaded.  A fully qualified name is required if
2595 the plugin name does not begin with C<Catalyst::Plugin::>.
2596
2597  if ($c->registered_plugins('Some::Plugin')) {
2598      ...
2599  }
2600
2601 =cut
2602
2603 {
2604
2605     sub registered_plugins {
2606         my $proto = shift;
2607         return sort keys %{ $proto->_plugins } unless @_;
2608         my $plugin = shift;
2609         return 1 if exists $proto->_plugins->{$plugin};
2610         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2611     }
2612
2613     sub _register_plugin {
2614         my ( $proto, $plugin, $instant ) = @_;
2615         my $class = ref $proto || $proto;
2616
2617         Class::MOP::load_class( $plugin );
2618         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2619             if $plugin->isa( 'Catalyst::Component' );
2620         $proto->_plugins->{$plugin} = 1;
2621         unless ($instant) {
2622             no strict 'refs';
2623             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2624               my @superclasses = ($plugin, $meta->superclasses );
2625               $meta->superclasses(@superclasses);
2626             } else {
2627               unshift @{"$class\::ISA"}, $plugin;
2628             }
2629         }
2630         return $class;
2631     }
2632
2633     sub setup_plugins {
2634         my ( $class, $plugins ) = @_;
2635
2636         $class->_plugins( {} ) unless $class->_plugins;
2637         $plugins ||= [];
2638
2639         my @plugins = Catalyst::Utils::resolve_namespace($class . '::Plugin', 'Catalyst::Plugin', @$plugins);
2640
2641         for my $plugin ( reverse @plugins ) {
2642             Class::MOP::load_class($plugin);
2643             my $meta = find_meta($plugin);
2644             next if $meta && $meta->isa('Moose::Meta::Role');
2645
2646             $class->_register_plugin($plugin);
2647         }
2648
2649         my @roles =
2650             map { $_->name }
2651             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2652             map { find_meta($_) }
2653             @plugins;
2654
2655         Moose::Util::apply_all_roles(
2656             $class => @roles
2657         ) if @roles;
2658     }
2659 }
2660
2661 =head2 $c->stack
2662
2663 Returns an arrayref of the internal execution stack (actions that are
2664 currently executing).
2665
2666 =head2 $c->stats_class
2667
2668 Returns or sets the stats (timing statistics) class.
2669
2670 =head2 $c->use_stats
2671
2672 Returns 1 when stats collection is enabled.  Stats collection is enabled
2673 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2674 environment variable is set.
2675
2676 Note that this is a static method, not an accessor and should be overridden
2677 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2678
2679 =cut
2680
2681 sub use_stats { 0 }
2682
2683
2684 =head2 $c->write( $data )
2685
2686 Writes $data to the output stream. When using this method directly, you
2687 will need to manually set the C<Content-Length> header to the length of
2688 your output data, if known.
2689
2690 =cut
2691
2692 sub write {
2693     my $c = shift;
2694
2695     # Finalize headers if someone manually writes output
2696     $c->finalize_headers;
2697
2698     return $c->engine->write( $c, @_ );
2699 }
2700
2701 =head2 version
2702
2703 Returns the Catalyst version number. Mostly useful for "powered by"
2704 messages in template systems.
2705
2706 =cut
2707
2708 sub version { return $Catalyst::VERSION }
2709
2710 =head1 CONFIGURATION
2711
2712 There are a number of 'base' config variables which can be set:
2713
2714 =over
2715
2716 =item *
2717
2718 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2719
2720 =item *
2721
2722 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2723
2724 =item *
2725
2726 C<disable_component_resolution_regex_fallback> - Turns
2727 off the deprecated component resolution functionality so
2728 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2729 are called then regex search will not be attempted on string values and
2730 instead C<undef> will be returned.
2731
2732 =item *
2733
2734 C<home> - The application home directory. In an uninstalled application,
2735 this is the top level application directory. In an installed application,
2736 this will be the directory containing C<< MyApp.pm >>.
2737
2738 =item *
2739
2740 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2741
2742 =item *
2743
2744 C<name> - The name of the application in debug messages and the debug and
2745 welcome screens
2746
2747 =item *
2748
2749 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2750 until it is accessed. This allows you to (for example) check authentication (and reject
2751 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2752
2753 =item *
2754
2755 C<root> - The root directory for templates. Usually this is just a
2756 subdirectory of the home directory, but you can set it to change the
2757 templates to a different directory.
2758
2759 =item *
2760
2761 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2762 namespaces from which components will be loaded (and constructed and stored in
2763 C<< $c->components >>).
2764
2765 =item *
2766
2767 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2768 to be shown in hit debug tables in the test server.
2769
2770 =item *
2771
2772 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2773
2774 =back
2775
2776 =head1 INTERNAL ACTIONS
2777
2778 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2779 C<_ACTION>, and C<_END>. These are by default not shown in the private
2780 action table, but you can make them visible with a config parameter.
2781
2782     MyApp->config(show_internal_actions => 1);
2783
2784 =head1 ON-DEMAND PARSER
2785
2786 The request body is usually parsed at the beginning of a request,
2787 but if you want to handle input yourself, you can enable on-demand
2788 parsing with a config parameter.
2789
2790     MyApp->config(parse_on_demand => 1);
2791
2792 =head1 PROXY SUPPORT
2793
2794 Many production servers operate using the common double-server approach,
2795 with a lightweight frontend web server passing requests to a larger
2796 backend server. An application running on the backend server must deal
2797 with two problems: the remote user always appears to be C<127.0.0.1> and
2798 the server's hostname will appear to be C<localhost> regardless of the
2799 virtual host that the user connected through.
2800
2801 Catalyst will automatically detect this situation when you are running
2802 the frontend and backend servers on the same machine. The following
2803 changes are made to the request.
2804
2805     $c->req->address is set to the user's real IP address, as read from
2806     the HTTP X-Forwarded-For header.
2807
2808     The host value for $c->req->base and $c->req->uri is set to the real
2809     host, as read from the HTTP X-Forwarded-Host header.
2810
2811 Additionally, you may be running your backend application on an insecure
2812 connection (port 80) while your frontend proxy is running under SSL.  If there
2813 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2814 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2815 be created properly.
2816
2817 In the case of passing in:
2818
2819     X-Forwarded-Port: 443
2820
2821 All calls to C<uri_for> will result in an https link, as is expected.
2822
2823 Obviously, your web server must support these headers for this to work.
2824
2825 In a more complex server farm environment where you may have your
2826 frontend proxy server(s) on different machines, you will need to set a
2827 configuration option to tell Catalyst to read the proxied data from the
2828 headers.
2829
2830     MyApp->config(using_frontend_proxy => 1);
2831
2832 If you do not wish to use the proxy support at all, you may set:
2833
2834     MyApp->config(ignore_frontend_proxy => 1);
2835
2836 =head1 THREAD SAFETY
2837
2838 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2839 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2840 believe the Catalyst core to be thread-safe.
2841
2842 If you plan to operate in a threaded environment, remember that all other
2843 modules you are using must also be thread-safe. Some modules, most notably
2844 L<DBD::SQLite>, are not thread-safe.
2845
2846 =head1 SUPPORT
2847
2848 IRC:
2849
2850     Join #catalyst on irc.perl.org.
2851
2852 Mailing Lists:
2853
2854     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2855     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2856
2857 Web:
2858
2859     http://catalyst.perl.org
2860
2861 Wiki:
2862
2863     http://dev.catalyst.perl.org
2864
2865 =head1 SEE ALSO
2866
2867 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2868
2869 =head2 L<Catalyst::Manual> - The Catalyst Manual
2870
2871 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2872
2873 =head2 L<Catalyst::Engine> - Core engine
2874
2875 =head2 L<Catalyst::Log> - Log class.
2876
2877 =head2 L<Catalyst::Request> - Request object
2878
2879 =head2 L<Catalyst::Response> - Response object
2880
2881 =head2 L<Catalyst::Test> - The test suite.
2882
2883 =head1 PROJECT FOUNDER
2884
2885 sri: Sebastian Riedel <sri@cpan.org>
2886
2887 =head1 CONTRIBUTORS
2888
2889 abw: Andy Wardley
2890
2891 acme: Leon Brocard <leon@astray.com>
2892
2893 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
2894
2895 Andrew Bramble
2896
2897 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
2898
2899 Andrew Ruthven
2900
2901 andyg: Andy Grundman <andy@hybridized.org>
2902
2903 audreyt: Audrey Tang
2904
2905 bricas: Brian Cassidy <bricas@cpan.org>
2906
2907 Caelum: Rafael Kitover <rkitover@io.com>
2908
2909 chansen: Christian Hansen
2910
2911 chicks: Christopher Hicks
2912
2913 Chisel Wright C<pause@herlpacker.co.uk>
2914
2915 Danijel Milicevic C<me@danijel.de>
2916
2917 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
2918
2919 David Naughton, C<naughton@umn.edu>
2920
2921 David E. Wheeler
2922
2923 dhoss: Devin Austin <dhoss@cpan.org>
2924
2925 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2926
2927 Drew Taylor
2928
2929 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2930
2931 esskar: Sascha Kiefer
2932
2933 fireartist: Carl Franks <cfranks@cpan.org>
2934
2935 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
2936
2937 gabb: Danijel Milicevic
2938
2939 Gary Ashton Jones
2940
2941 Gavin Henry C<ghenry@perl.me.uk>
2942
2943 Geoff Richards
2944
2945 groditi: Guillermo Roditi <groditi@gmail.com>
2946
2947 hobbs: Andrew Rodland <andrew@cleverdomain.org>
2948
2949 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2950
2951 jcamacho: Juan Camacho
2952
2953 jester: Jesse Sheidlower C<jester@panix.com>
2954
2955 jhannah: Jay Hannah <jay@jays.net>
2956
2957 Jody Belka
2958
2959 Johan Lindstrom
2960
2961 jon: Jon Schutz <jjschutz@cpan.org>
2962
2963 Jonathan Rockway C<< <jrockway@cpan.org> >>
2964
2965 Kieren Diment C<kd@totaldatasolution.com>
2966
2967 konobi: Scott McWhirter <konobi@cpan.org>
2968
2969 marcus: Marcus Ramberg <mramberg@cpan.org>
2970
2971 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2972
2973 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2974
2975 mugwump: Sam Vilain
2976
2977 naughton: David Naughton
2978
2979 ningu: David Kamholz <dkamholz@cpan.org>
2980
2981 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2982
2983 numa: Dan Sully <daniel@cpan.org>
2984
2985 obra: Jesse Vincent
2986
2987 Octavian Rasnita
2988
2989 omega: Andreas Marienborg
2990
2991 Oleg Kostyuk <cub.uanic@gmail.com>
2992
2993 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2994
2995 rafl: Florian Ragwitz <rafl@debian.org>
2996
2997 random: Roland Lammel <lammel@cpan.org>
2998
2999 Robert Sedlacek C<< <rs@474.at> >>
3000
3001 sky: Arthur Bergman
3002
3003 t0m: Tomas Doran <bobtfish@bobtfish.net>
3004
3005 Ulf Edvinsson
3006
3007 Viljo Marrandi C<vilts@yahoo.com>
3008
3009 Will Hawes C<info@whawes.co.uk>
3010
3011 willert: Sebastian Willert <willert@cpan.org>
3012
3013 Yuval Kogman, C<nothingmuch@woobling.org>
3014
3015 =head1 LICENSE
3016
3017 This library is free software. You can redistribute it and/or modify it under
3018 the same terms as Perl itself.
3019
3020 =cut
3021
3022 no Moose;
3023
3024 __PACKAGE__->meta->make_immutable;
3025
3026 1;