lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54
  55 BEGIN { require 5.008003; }
  56
  57 has stack => (is => 'ro', default => sub { [] });
  58 has state => (is => 'rw', default => 0);
  59 has stats => (is => 'rw');
  60 has action => (is => 'rw');
  61 has counter => (is => 'rw', default => sub { {} });
  62 has request => (
  63     is => 'rw',
  64     default => sub {
  65         my $self = shift;
  66         $self->request_class->new($self->_build_request_constructor_args);
  67     },
  68     lazy => 1,
  69 );
  70 sub _build_request_constructor_args {
  71     my $self = shift;
  72     my %p = ( _log => $self->log );
  73     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  74     $p{data_handlers} = {$self->registered_data_handlers};
  75     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  76       if $self->config->{use_hash_multivalue_in_request};
  77     \%p;
  78 }
  79
  80 has response => (
  81     is => 'rw',
  82     default => sub {
  83         my $self = shift;
  84         $self->response_class->new($self->_build_response_constructor_args);
  85     },
  86     lazy => 1,
  87 );
  88 sub _build_response_constructor_args {
  89     return +{
  90       _log => $_[0]->log,
  91       encoding => $_[0]->encoding,
  92     };
  93 }
  94
  95 has namespace => (is => 'rw');
  96
  97 sub depth { scalar @{ shift->stack || [] }; }
  98 sub comp { shift->component(@_) }
  99
 100 sub req {
 101     my $self = shift; return $self->request(@_);
 102 }
 103 sub res {
 104     my $self = shift; return $self->response(@_);
 105 }
 106
 107 # For backwards compatibility
 108 sub finalize_output { shift->finalize_body(@_) };
 109
 110 # For statistics
 111 our $COUNT     = 1;
 112 our $START     = time;
 113 our $RECURSION = 1000;
 114 our $DETACH    = Catalyst::Exception::Detach->new;
 115 our $GO        = Catalyst::Exception::Go->new;
 116
 117 #I imagine that very few of these really need to be class variables. if any.
 118 #maybe we should just make them attributes with a default?
 119 __PACKAGE__->mk_classdata($_)
 120   for qw/components arguments dispatcher engine log dispatcher_class
 121   engine_loader context_class request_class response_class stats_class
 122   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 123   _data_handlers _encoding _encode_check/;
 124
 125 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 126 __PACKAGE__->request_class('Catalyst::Request');
 127 __PACKAGE__->response_class('Catalyst::Response');
 128 __PACKAGE__->stats_class('Catalyst::Stats');
 129 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 130
 131 # Remember to update this in Catalyst::Runtime as well!
 132 our $VERSION = '5.90079_003';
 133 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 134
 135 sub import {
 136     my ( $class, @arguments ) = @_;
 137
 138     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 139     # callers @ISA.
 140     return unless $class eq 'Catalyst';
 141
 142     my $caller = caller();
 143     return if $caller eq 'main';
 144
 145     my $meta = Moose::Meta::Class->initialize($caller);
 146     unless ( $caller->isa('Catalyst') ) {
 147         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 148         $meta->superclasses(@superclasses);
 149     }
 150     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 151     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 152
 153     unless( $meta->has_method('meta') ){
 154         if ($Moose::VERSION >= 1.15) {
 155             $meta->_add_meta_method('meta');
 156         }
 157         else {
 158             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 159         }
 160     }
 161
 162     $caller->arguments( [@arguments] );
 163     $caller->setup_home;
 164 }
 165
 166 sub _application { $_[0] }
 167
 168 =encoding UTF-8
 169
 170 =head1 NAME
 171
 172 Catalyst - The Elegant MVC Web Application Framework
 173
 174 =head1 SYNOPSIS
 175
 176 See the L<Catalyst::Manual> distribution for comprehensive
 177 documentation and tutorials.
 178
 179     # Install Catalyst::Devel for helpers and other development tools
 180     # use the helper to create a new application
 181     catalyst.pl MyApp
 182
 183     # add models, views, controllers
 184     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 185     script/myapp_create.pl view MyTemplate TT
 186     script/myapp_create.pl controller Search
 187
 188     # built in testserver -- use -r to restart automatically on changes
 189     # --help to see all available options
 190     script/myapp_server.pl
 191
 192     # command line testing interface
 193     script/myapp_test.pl /yada
 194
 195     ### in lib/MyApp.pm
 196     use Catalyst qw/-Debug/; # include plugins here as well
 197
 198     ### In lib/MyApp/Controller/Root.pm (autocreated)
 199     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 200         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 201         $c->stash->{template} = 'foo.tt'; # set the template
 202         # lookup something from db -- stash vars are passed to TT
 203         $c->stash->{data} =
 204           $c->model('Database::Foo')->search( { country => $args[0] } );
 205         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 206             $c->forward( 'bar' ); # process another action
 207             # do something else after forward returns
 208         }
 209     }
 210
 211     # The foo.tt TT template can use the stash data from the database
 212     [% WHILE (item = data.next) %]
 213         [% item.foo %]
 214     [% END %]
 215
 216     # called for /bar/of/soap, /bar/of/soap/10, etc.
 217     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 218
 219     # called after all actions are finished
 220     sub end : Action {
 221         my ( $self, $c ) = @_;
 222         if ( scalar @{ $c->error } ) { ... } # handle errors
 223         return if $c->res->body; # already have a response
 224         $c->forward( 'MyApp::View::TT' ); # render template
 225     }
 226
 227 See L<Catalyst::Manual::Intro> for additional information.
 228
 229 =head1 DESCRIPTION
 230
 231 Catalyst is a modern framework for making web applications without the
 232 pain usually associated with this process. This document is a reference
 233 to the main Catalyst application. If you are a new user, we suggest you
 234 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 235
 236 See L<Catalyst::Manual> for more documentation.
 237
 238 Catalyst plugins can be loaded by naming them as arguments to the "use
 239 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 240 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 241 C<My::Module>.
 242
 243     use Catalyst qw/My::Module/;
 244
 245 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 246 fully qualify the name by using a unary plus:
 247
 248     use Catalyst qw/
 249         My::Module
 250         +Fully::Qualified::Plugin::Name
 251     /;
 252
 253 Special flags like C<-Debug> can also be specified as
 254 arguments when Catalyst is loaded:
 255
 256     use Catalyst qw/-Debug My::Module/;
 257
 258 The position of plugins and flags in the chain is important, because
 259 they are loaded in the order in which they appear.
 260
 261 The following flags are supported:
 262
 263 =head2 -Debug
 264
 265 Enables debug output. You can also force this setting from the system
 266 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 267 settings override the application, with <MYAPP>_DEBUG having the highest
 268 priority.
 269
 270 This sets the log level to 'debug' and enables full debug output on the
 271 error screen. If you only want the latter, see L<< $c->debug >>.
 272
 273 =head2 -Home
 274
 275 Forces Catalyst to use a specific home directory, e.g.:
 276
 277     use Catalyst qw[-Home=/usr/mst];
 278
 279 This can also be done in the shell environment by setting either the
 280 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 281 is replaced with the uppercased name of your application, any "::" in
 282 the name will be replaced with underscores, e.g. MyApp::Web should use
 283 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 284
 285 If none of these are set, Catalyst will attempt to automatically detect the
 286 home directory. If you are working in a development environment, Catalyst
 287 will try and find the directory containing either Makefile.PL, Build.PL,
 288 dist.ini, or cpanfile. If the application has been installed into the system
 289 (i.e. you have done C<make install>), then Catalyst will use the path to your
 290 application module, without the .pm extension (e.g., /foo/MyApp if your
 291 application was installed at /foo/MyApp.pm)
 292
 293 =head2 -Log
 294
 295     use Catalyst '-Log=warn,fatal,error';
 296
 297 Specifies a comma-delimited list of log levels.
 298
 299 =head2 -Stats
 300
 301 Enables statistics collection and reporting.
 302
 303    use Catalyst qw/-Stats=1/;
 304
 305 You can also force this setting from the system environment with CATALYST_STATS
 306 or <MYAPP>_STATS. The environment settings override the application, with
 307 <MYAPP>_STATS having the highest priority.
 308
 309 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 310
 311 =head1 METHODS
 312
 313 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 314
 315 =head2 $c->action
 316
 317 Returns a L<Catalyst::Action> object for the current action, which
 318 stringifies to the action name. See L<Catalyst::Action>.
 319
 320 =head2 $c->namespace
 321
 322 Returns the namespace of the current action, i.e., the URI prefix
 323 corresponding to the controller of the current action. For example:
 324
 325     # in Controller::Foo::Bar
 326     $c->namespace; # returns 'foo/bar';
 327
 328 =head2 $c->request
 329
 330 =head2 $c->req
 331
 332 Returns the current L<Catalyst::Request> object, giving access to
 333 information about the current client request (including parameters,
 334 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 335
 336 =head2 REQUEST FLOW HANDLING
 337
 338 =head2 $c->forward( $action [, \@arguments ] )
 339
 340 =head2 $c->forward( $class, $method, [, \@arguments ] )
 341
 342 This is one way of calling another action (method) in the same or
 343 a different controller. You can also use C<< $self->my_method($c, @args) >>
 344 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 345 in a different controller.
 346 The main difference is that 'forward' uses some of the Catalyst request
 347 cycle overhead, including debugging, which may be useful to you. On the
 348 other hand, there are some complications to using 'forward', restrictions
 349 on values returned from 'forward', and it may not handle errors as you prefer.
 350 Whether you use 'forward' or not is up to you; it is not considered superior to
 351 the other ways to call a method.
 352
 353 'forward' calls  another action, by its private name. If you give a
 354 class name but no method, C<process()> is called. You may also optionally
 355 pass arguments in an arrayref. The action will receive the arguments in
 356 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 357 C<< $c->req->args >> will be restored to the previous values.
 358
 359 Any data C<return>ed from the action forwarded to, will be returned by the
 360 call to forward.
 361
 362     my $foodata = $c->forward('/foo');
 363     $c->forward('index');
 364     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 365     $c->forward('View::TT');
 366
 367 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 368 an C<< eval { } >> around the call (actually
 369 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 370 exceptions thrown by the called action non-fatal and pushing them onto
 371 $c->error instead. If you want C<die> to propagate you need to do something
 372 like:
 373
 374     $c->forward('foo');
 375     die join "\n", @{ $c->error } if @{ $c->error };
 376
 377 Or make sure to always return true values from your actions and write
 378 your code like this:
 379
 380     $c->forward('foo') || return;
 381
 382 Another note is that C<< $c->forward >> always returns a scalar because it
 383 actually returns $c->state which operates in a scalar context.
 384 Thus, something like:
 385
 386     return @array;
 387
 388 in an action that is forwarded to is going to return a scalar,
 389 i.e. how many items are in that array, which is probably not what you want.
 390 If you need to return an array then return a reference to it,
 391 or stash it like so:
 392
 393     $c->stash->{array} = \@array;
 394
 395 and access it from the stash.
 396
 397 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 398
 399 =cut
 400
 401 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 402
 403 =head2 $c->detach( $action [, \@arguments ] )
 404
 405 =head2 $c->detach( $class, $method, [, \@arguments ] )
 406
 407 =head2 $c->detach()
 408
 409 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 410 doesn't return to the previous action when processing is finished.
 411
 412 When called with no arguments it escapes the processing chain entirely.
 413
 414 =cut
 415
 416 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 417
 418 =head2 $c->visit( $action [, \@arguments ] )
 419
 420 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 421
 422 =head2 $c->visit( $class, $method, [, \@arguments ] )
 423
 424 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 425
 426 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 427 but does a full dispatch, instead of just calling the new C<$action> /
 428 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 429 you go to are called, just like a new request.
 430
 431 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 432 This means, for example, that C<< $c->action >> methods such as
 433 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 434 L<reverse|Catalyst::Action/reverse> return information for the visited action
 435 when they are invoked within the visited action.  This is different from the
 436 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 437 continues to use the $c->action object from the caller action even when
 438 invoked from the called action.
 439
 440 C<< $c->stash >> is kept unchanged.
 441
 442 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 443 allows you to "wrap" another action, just as it would have been called by
 444 dispatching from a URL, while the analogous
 445 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 446 transfer control to another action as if it had been reached directly from a URL.
 447
 448 =cut
 449
 450 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 451
 452 =head2 $c->go( $action [, \@arguments ] )
 453
 454 =head2 $c->go( $action [, \@captures, \@arguments ] )
 455
 456 =head2 $c->go( $class, $method, [, \@arguments ] )
 457
 458 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 459
 460 The relationship between C<go> and
 461 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 462 the relationship between
 463 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 464 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 465 C<< $c->go >> will perform a full dispatch on the specified action or method,
 466 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 467 C<go> escapes the processing of the current request chain on completion, and
 468 does not return to its caller.
 469
 470 @arguments are arguments to the final destination of $action. @captures are
 471 arguments to the intermediate steps, if any, on the way to the final sub of
 472 $action.
 473
 474 =cut
 475
 476 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 477
 478 =head2 $c->response
 479
 480 =head2 $c->res
 481
 482 Returns the current L<Catalyst::Response> object, see there for details.
 483
 484 =head2 $c->stash
 485
 486 Returns a hashref to the stash, which may be used to store data and pass
 487 it between components during a request. You can also set hash keys by
 488 passing arguments. The stash is automatically sent to the view. The
 489 stash is cleared at the end of a request; it cannot be used for
 490 persistent storage (for this you must use a session; see
 491 L<Catalyst::Plugin::Session> for a complete system integrated with
 492 Catalyst).
 493
 494     $c->stash->{foo} = $bar;
 495     $c->stash( { moose => 'majestic', qux => 0 } );
 496     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 497
 498     # stash is automatically passed to the view for use in a template
 499     $c->forward( 'MyApp::View::TT' );
 500
 501 The stash hash is currently stored in the PSGI C<$env> and is managed by
 502 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 503 the stash can be accessed in sub applications mounted under your main
 504 L<Catalyst> application.  For example if you delegate the response of an
 505 action to another L<Catalyst> application, that sub application will have
 506 access to all the stash keys of the main one, and if can of course add
 507 more keys of its own.  However those new keys will not 'bubble' back up
 508 to the main application.
 509
 510 For more information the best thing to do is to review the test case:
 511 t/middleware-stash.t in the distribution /t directory.
 512
 513 =cut
 514
 515 sub stash {
 516   my $c = shift;
 517   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 518 }
 519
 520 =head2 $c->error
 521
 522 =head2 $c->error($error, ...)
 523
 524 =head2 $c->error($arrayref)
 525
 526 Returns an arrayref containing error messages.  If Catalyst encounters an
 527 error while processing a request, it stores the error in $c->error.  This
 528 method should only be used to store fatal error messages.
 529
 530     my @error = @{ $c->error };
 531
 532 Add a new error.
 533
 534     $c->error('Something bad happened');
 535
 536 =cut
 537
 538 sub error {
 539     my $c = shift;
 540     if ( $_[0] ) {
 541         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 542         croak @$error unless ref $c;
 543         push @{ $c->{error} }, @$error;
 544     }
 545     elsif ( defined $_[0] ) { $c->{error} = undef }
 546     return $c->{error} || [];
 547 }
 548
 549
 550 =head2 $c->state
 551
 552 Contains the return value of the last executed action.
 553 Note that << $c->state >> operates in a scalar context which means that all
 554 values it returns are scalar.
 555
 556 =head2 $c->clear_errors
 557
 558 Clear errors.  You probably don't want to clear the errors unless you are
 559 implementing a custom error screen.
 560
 561 This is equivalent to running
 562
 563     $c->error(0);
 564
 565 =cut
 566
 567 sub clear_errors {
 568     my $c = shift;
 569     $c->error(0);
 570 }
 571
 572 =head2 $c->has_errors
 573
 574 Returns true if you have errors
 575
 576 =cut
 577
 578 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 579
 580 sub _comp_search_prefixes {
 581     my $c = shift;
 582     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 583 }
 584
 585 # search components given a name and some prefixes
 586 sub _comp_names_search_prefixes {
 587     my ( $c, $name, @prefixes ) = @_;
 588     my $appclass = ref $c || $c;
 589     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 590     $filter = qr/$filter/; # Compile regex now rather than once per loop
 591
 592     # map the original component name to the sub part that we will search against
 593     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 594         grep { /$filter/ } keys %{ $c->components };
 595
 596     # undef for a name will return all
 597     return keys %eligible if !defined $name;
 598
 599     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 600     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 601
 602     return @result if @result;
 603
 604     # if we were given a regexp to search against, we're done.
 605     return if $name->$_isa('Regexp');
 606
 607     # skip regexp fallback if configured
 608     return
 609         if $appclass->config->{disable_component_resolution_regex_fallback};
 610
 611     # regexp fallback
 612     $query  = qr/$name/i;
 613     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 614
 615     # no results? try against full names
 616     if( !@result ) {
 617         @result = grep { m{$query} } keys %eligible;
 618     }
 619
 620     # don't warn if we didn't find any results, it just might not exist
 621     if( @result ) {
 622         # Disgusting hack to work out correct method name
 623         my $warn_for = lc $prefixes[0];
 624         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 625            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 626            "component resolution is unreliable and unsafe.";
 627         my $short = $result[0];
 628         # remove the component namespace prefix
 629         $short =~ s/.*?(Model|Controller|View):://;
 630         my $shortmess = Carp::shortmess('');
 631         if ($shortmess =~ m#Catalyst/Plugin#) {
 632            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 633               "plugin's config";
 634         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 635            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 636               "component's config";
 637         } else {
 638            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 639               "but if you really wanted to search, pass in a regexp as the argument " .
 640               "like so: \$c->${warn_for}(qr/${name}/)";
 641         }
 642         $c->log->warn( "${msg}$shortmess" );
 643     }
 644
 645     return @result;
 646 }
 647
 648 # Find possible names for a prefix
 649 sub _comp_names {
 650     my ( $c, @prefixes ) = @_;
 651     my $appclass = ref $c || $c;
 652
 653     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 654
 655     my @names = map { s{$filter}{}; $_; }
 656         $c->_comp_names_search_prefixes( undef, @prefixes );
 657
 658     return @names;
 659 }
 660
 661 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 662 sub _filter_component {
 663     my ( $c, $comp, @args ) = @_;
 664
 665     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 666         return $comp->ACCEPT_CONTEXT( $c, @args );
 667     }
 668
 669     return $comp;
 670 }
 671
 672 =head2 COMPONENT ACCESSORS
 673
 674 =head2 $c->controller($name)
 675
 676 Gets a L<Catalyst::Controller> instance by name.
 677
 678     $c->controller('Foo')->do_stuff;
 679
 680 If the name is omitted, will return the controller for the dispatched
 681 action.
 682
 683 If you want to search for controllers, pass in a regexp as the argument.
 684
 685     # find all controllers that start with Foo
 686     my @foo_controllers = $c->controller(qr{^Foo});
 687
 688
 689 =cut
 690
 691 sub controller {
 692     my ( $c, $name, @args ) = @_;
 693
 694     my $appclass = ref($c) || $c;
 695     if( $name ) {
 696         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 697             my $comps = $c->components;
 698             my $check = $appclass."::Controller::".$name;
 699             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 700         }
 701         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 702         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 703         return $c->_filter_component( $result[ 0 ], @args );
 704     }
 705
 706     return $c->component( $c->action->class );
 707 }
 708
 709 =head2 $c->model($name)
 710
 711 Gets a L<Catalyst::Model> instance by name.
 712
 713     $c->model('Foo')->do_stuff;
 714
 715 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 716
 717 If the name is omitted, it will look for
 718  - a model object in $c->stash->{current_model_instance}, then
 719  - a model name in $c->stash->{current_model}, then
 720  - a config setting 'default_model', or
 721  - check if there is only one model, and return it if that's the case.
 722
 723 If you want to search for models, pass in a regexp as the argument.
 724
 725     # find all models that start with Foo
 726     my @foo_models = $c->model(qr{^Foo});
 727
 728 =cut
 729
 730 sub model {
 731     my ( $c, $name, @args ) = @_;
 732     my $appclass = ref($c) || $c;
 733     if( $name ) {
 734         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 735             my $comps = $c->components;
 736             my $check = $appclass."::Model::".$name;
 737             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 738         }
 739         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 740         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 741         return $c->_filter_component( $result[ 0 ], @args );
 742     }
 743
 744     if (ref $c) {
 745         return $c->stash->{current_model_instance}
 746           if $c->stash->{current_model_instance};
 747         return $c->model( $c->stash->{current_model} )
 748           if $c->stash->{current_model};
 749     }
 750     return $c->model( $appclass->config->{default_model} )
 751       if $appclass->config->{default_model};
 752
 753     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 754
 755     if( $rest ) {
 756         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 757         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 758         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 759         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 760         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 761     }
 762
 763     return $c->_filter_component( $comp );
 764 }
 765
 766
 767 =head2 $c->view($name)
 768
 769 Gets a L<Catalyst::View> instance by name.
 770
 771     $c->view('Foo')->do_stuff;
 772
 773 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 774
 775 If the name is omitted, it will look for
 776  - a view object in $c->stash->{current_view_instance}, then
 777  - a view name in $c->stash->{current_view}, then
 778  - a config setting 'default_view', or
 779  - check if there is only one view, and return it if that's the case.
 780
 781 If you want to search for views, pass in a regexp as the argument.
 782
 783     # find all views that start with Foo
 784     my @foo_views = $c->view(qr{^Foo});
 785
 786 =cut
 787
 788 sub view {
 789     my ( $c, $name, @args ) = @_;
 790
 791     my $appclass = ref($c) || $c;
 792     if( $name ) {
 793         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 794             my $comps = $c->components;
 795             my $check = $appclass."::View::".$name;
 796             if( exists $comps->{$check} ) {
 797                 return $c->_filter_component( $comps->{$check}, @args );
 798             }
 799             else {
 800                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 801             }
 802         }
 803         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 804         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 805         return $c->_filter_component( $result[ 0 ], @args );
 806     }
 807
 808     if (ref $c) {
 809         return $c->stash->{current_view_instance}
 810           if $c->stash->{current_view_instance};
 811         return $c->view( $c->stash->{current_view} )
 812           if $c->stash->{current_view};
 813     }
 814     return $c->view( $appclass->config->{default_view} )
 815       if $appclass->config->{default_view};
 816
 817     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 818
 819     if( $rest ) {
 820         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 821         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 822         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 823         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 824         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 825     }
 826
 827     return $c->_filter_component( $comp );
 828 }
 829
 830 =head2 $c->controllers
 831
 832 Returns the available names which can be passed to $c->controller
 833
 834 =cut
 835
 836 sub controllers {
 837     my ( $c ) = @_;
 838     return $c->_comp_names(qw/Controller C/);
 839 }
 840
 841 =head2 $c->models
 842
 843 Returns the available names which can be passed to $c->model
 844
 845 =cut
 846
 847 sub models {
 848     my ( $c ) = @_;
 849     return $c->_comp_names(qw/Model M/);
 850 }
 851
 852
 853 =head2 $c->views
 854
 855 Returns the available names which can be passed to $c->view
 856
 857 =cut
 858
 859 sub views {
 860     my ( $c ) = @_;
 861     return $c->_comp_names(qw/View V/);
 862 }
 863
 864 =head2 $c->comp($name)
 865
 866 =head2 $c->component($name)
 867
 868 Gets a component object by name. This method is not recommended,
 869 unless you want to get a specific component by full
 870 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 871 should be used instead.
 872
 873 If C<$name> is a regexp, a list of components matched against the full
 874 component name will be returned.
 875
 876 If Catalyst can't find a component by name, it will fallback to regex
 877 matching by default. To disable this behaviour set
 878 disable_component_resolution_regex_fallback to a true value.
 879
 880     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 881
 882 =cut
 883
 884 sub component {
 885     my ( $c, $name, @args ) = @_;
 886
 887     if( $name ) {
 888         my $comps = $c->components;
 889
 890         if( !ref $name ) {
 891             # is it the exact name?
 892             return $c->_filter_component( $comps->{ $name }, @args )
 893                        if exists $comps->{ $name };
 894
 895             # perhaps we just omitted "MyApp"?
 896             my $composed = ( ref $c || $c ) . "::${name}";
 897             return $c->_filter_component( $comps->{ $composed }, @args )
 898                        if exists $comps->{ $composed };
 899
 900             # search all of the models, views and controllers
 901             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 902             return $c->_filter_component( $comp, @args ) if $comp;
 903         }
 904
 905         return
 906             if $c->config->{disable_component_resolution_regex_fallback};
 907
 908         # This is here so $c->comp( '::M::' ) works
 909         my $query = ref $name ? $name : qr{$name}i;
 910
 911         my @result = grep { m{$query} } keys %{ $c->components };
 912         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 913
 914         if( $result[ 0 ] ) {
 915             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 916             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 917             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 918             return $c->_filter_component( $result[ 0 ], @args );
 919         }
 920
 921         # I would expect to return an empty list here, but that breaks back-compat
 922     }
 923
 924     # fallback
 925     return sort keys %{ $c->components };
 926 }
 927
 928 =head2 CLASS DATA AND HELPER CLASSES
 929
 930 =head2 $c->config
 931
 932 Returns or takes a hashref containing the application's configuration.
 933
 934     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 935
 936 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 937 like C<myapp.conf> in your applications home directory. See
 938 L<Catalyst::Plugin::ConfigLoader>.
 939
 940 =head3 Cascading configuration
 941
 942 The config method is present on all Catalyst components, and configuration
 943 will be merged when an application is started. Configuration loaded with
 944 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 945 followed by configuration in your top level C<MyApp> class. These two
 946 configurations are merged, and then configuration data whose hash key matches a
 947 component name is merged with configuration for that component.
 948
 949 The configuration for a component is then passed to the C<new> method when a
 950 component is constructed.
 951
 952 For example:
 953
 954     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 955     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 956
 957 will mean that C<MyApp::Model::Foo> receives the following data when
 958 constructed:
 959
 960     MyApp::Model::Foo->new({
 961         bar => 'baz',
 962         quux => 'frob',
 963         overrides => 'me',
 964     });
 965
 966 It's common practice to use a Moose attribute
 967 on the receiving component to access the config value.
 968
 969     package MyApp::Model::Foo;
 970
 971     use Moose;
 972
 973     # this attr will receive 'baz' at construction time
 974     has 'bar' => (
 975         is  => 'rw',
 976         isa => 'Str',
 977     );
 978
 979 You can then get the value 'baz' by calling $c->model('Foo')->bar
 980 (or $self->bar inside code in the model).
 981
 982 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 983 as a way of reading config within your code, as this B<will not> give you the
 984 correctly merged config back. You B<MUST> take the config values supplied to
 985 the constructor and use those instead.
 986
 987 =cut
 988
 989 around config => sub {
 990     my $orig = shift;
 991     my $c = shift;
 992
 993     croak('Setting config after setup has been run is not allowed.')
 994         if ( @_ and $c->setup_finished );
 995
 996     $c->$orig(@_);
 997 };
 998
 999 =head2 $c->log
1000
1001 Returns the logging object instance. Unless it is already set, Catalyst
1002 sets this up with a L<Catalyst::Log> object. To use your own log class,
1003 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1004 C<< __PACKAGE__->setup >>.
1005
1006  __PACKAGE__->log( MyLogger->new );
1007  __PACKAGE__->setup;
1008
1009 And later:
1010
1011     $c->log->info( 'Now logging with my own logger!' );
1012
1013 Your log class should implement the methods described in
1014 L<Catalyst::Log>.
1015
1016 =head2 encoding
1017
1018 Sets or gets the application encoding.
1019
1020 =cut
1021
1022 sub encoding {
1023     my $c = shift;
1024     my $encoding;
1025
1026     if ( scalar @_ ) {
1027         # Let it be set to undef
1028         if (my $wanted = shift)  {
1029             $encoding = Encode::find_encoding($wanted)
1030               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1031             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1032         }
1033         else {
1034             binmode(STDERR);
1035         }
1036
1037         $encoding = ref $c
1038                   ? $c->{encoding} = $encoding
1039                   : $c->_encoding($encoding);
1040     } else {
1041       $encoding = ref $c && exists $c->{encoding}
1042                 ? $c->{encoding}
1043                 : $c->_encoding;
1044     }
1045
1046     return $encoding;
1047 }
1048
1049 =head2 $c->debug
1050
1051 Returns 1 if debug mode is enabled, 0 otherwise.
1052
1053 You can enable debug mode in several ways:
1054
1055 =over
1056
1057 =item By calling myapp_server.pl with the -d flag
1058
1059 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1060
1061 =item The -Debug option in your MyApp.pm
1062
1063 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1064
1065 =back
1066
1067 The first three also set the log level to 'debug'.
1068
1069 Calling C<< $c->debug(1) >> has no effect.
1070
1071 =cut
1072
1073 sub debug { 0 }
1074
1075 =head2 $c->dispatcher
1076
1077 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1078
1079 =head2 $c->engine
1080
1081 Returns the engine instance. See L<Catalyst::Engine>.
1082
1083
1084 =head2 UTILITY METHODS
1085
1086 =head2 $c->path_to(@path)
1087
1088 Merges C<@path> with C<< $c->config->{home} >> and returns a
1089 L<Path::Class::Dir> object. Note you can usually use this object as
1090 a filename, but sometimes you will have to explicitly stringify it
1091 yourself by calling the C<< ->stringify >> method.
1092
1093 For example:
1094
1095     $c->path_to( 'db', 'sqlite.db' );
1096
1097 =cut
1098
1099 sub path_to {
1100     my ( $c, @path ) = @_;
1101     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1102     if ( -d $path ) { return $path }
1103     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1104 }
1105
1106 sub plugin {
1107     my ( $class, $name, $plugin, @args ) = @_;
1108
1109     # See block comment in t/unit_core_plugin.t
1110     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1111
1112     $class->_register_plugin( $plugin, 1 );
1113
1114     eval { $plugin->import };
1115     $class->mk_classdata($name);
1116     my $obj;
1117     eval { $obj = $plugin->new(@args) };
1118
1119     if ($@) {
1120         Catalyst::Exception->throw( message =>
1121               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1122     }
1123
1124     $class->$name($obj);
1125     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1126       if $class->debug;
1127 }
1128
1129 =head2 MyApp->setup
1130
1131 Initializes the dispatcher and engine, loads any plugins, and loads the
1132 model, view, and controller components. You may also specify an array
1133 of plugins to load here, if you choose to not load them in the C<use
1134 Catalyst> line.
1135
1136     MyApp->setup;
1137     MyApp->setup( qw/-Debug/ );
1138
1139 B<Note:> You B<should not> wrap this method with method modifiers
1140 or bad things will happen - wrap the C<setup_finalize> method instead.
1141
1142 =cut
1143
1144 sub setup {
1145     my ( $class, @arguments ) = @_;
1146     croak('Running setup more than once')
1147         if ( $class->setup_finished );
1148
1149     unless ( $class->isa('Catalyst') ) {
1150
1151         Catalyst::Exception->throw(
1152             message => qq/'$class' does not inherit from Catalyst/ );
1153     }
1154
1155     if ( $class->arguments ) {
1156         @arguments = ( @arguments, @{ $class->arguments } );
1157     }
1158
1159     # Process options
1160     my $flags = {};
1161
1162     foreach (@arguments) {
1163
1164         if (/^-Debug$/) {
1165             $flags->{log} =
1166               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1167         }
1168         elsif (/^-(\w+)=?(.*)$/) {
1169             $flags->{ lc $1 } = $2;
1170         }
1171         else {
1172             push @{ $flags->{plugins} }, $_;
1173         }
1174     }
1175
1176     $class->setup_home( delete $flags->{home} );
1177
1178     $class->setup_log( delete $flags->{log} );
1179     $class->setup_plugins( delete $flags->{plugins} );
1180
1181     $class->setup_data_handlers();
1182     $class->setup_dispatcher( delete $flags->{dispatcher} );
1183     if (my $engine = delete $flags->{engine}) {
1184         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1185     }
1186     $class->setup_engine();
1187     $class->setup_stats( delete $flags->{stats} );
1188
1189     for my $flag ( sort keys %{$flags} ) {
1190
1191         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1192             &$code( $class, delete $flags->{$flag} );
1193         }
1194         else {
1195             $class->log->warn(qq/Unknown flag "$flag"/);
1196         }
1197     }
1198
1199     eval { require Catalyst::Devel; };
1200     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1201         $class->log->warn(<<"EOF");
1202 You are running an old script!
1203
1204   Please update by running (this will overwrite existing files):
1205     catalyst.pl -force -scripts $class
1206
1207   or (this will not overwrite existing files):
1208     catalyst.pl -scripts $class
1209
1210 EOF
1211     }
1212
1213     # Call plugins setup, this is stupid and evil.
1214     # Also screws C3 badly on 5.10, hack to avoid.
1215     {
1216         no warnings qw/redefine/;
1217         local *setup = sub { };
1218         $class->setup unless $Catalyst::__AM_RESTARTING;
1219     }
1220
1221     # If you are expecting configuration info as part of your setup, it needs
1222     # to get called here and below, since we need the above line to support
1223     # ConfigLoader based configs.
1224
1225     $class->setup_encoding();
1226     $class->setup_middleware();
1227
1228     # Initialize our data structure
1229     $class->components( {} );
1230
1231     $class->setup_components;
1232
1233     if ( $class->debug ) {
1234         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1235
1236         if (@plugins) {
1237             my $column_width = Catalyst::Utils::term_width() - 6;
1238             my $t = Text::SimpleTable->new($column_width);
1239             $t->row($_) for @plugins;
1240             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1241         }
1242
1243         my @middleware = map {
1244           ref $_ eq 'CODE' ?
1245             "Inline Coderef" :
1246               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1247                 || '')  } $class->registered_middlewares;
1248
1249         if (@middleware) {
1250             my $column_width = Catalyst::Utils::term_width() - 6;
1251             my $t = Text::SimpleTable->new($column_width);
1252             $t->row($_) for @middleware;
1253             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1254         }
1255
1256         my %dh = $class->registered_data_handlers;
1257         if (my @data_handlers = keys %dh) {
1258             my $column_width = Catalyst::Utils::term_width() - 6;
1259             my $t = Text::SimpleTable->new($column_width);
1260             $t->row($_) for @data_handlers;
1261             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1262         }
1263
1264         my $dispatcher = $class->dispatcher;
1265         my $engine     = $class->engine;
1266         my $home       = $class->config->{home};
1267
1268         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1269         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1270
1271         $home
1272           ? ( -d $home )
1273           ? $class->log->debug(qq/Found home "$home"/)
1274           : $class->log->debug(qq/Home "$home" doesn't exist/)
1275           : $class->log->debug(q/Couldn't find home/);
1276
1277         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1278         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1279         for my $comp ( sort keys %{ $class->components } ) {
1280             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1281             $t->row( $comp, $type );
1282         }
1283         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1284           if ( keys %{ $class->components } );
1285     }
1286
1287     # Add our self to components, since we are also a component
1288     if( $class->isa('Catalyst::Controller') ){
1289       $class->components->{$class} = $class;
1290     }
1291
1292     $class->setup_actions;
1293
1294     if ( $class->debug ) {
1295         my $name = $class->config->{name} || 'Application';
1296         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1297     }
1298
1299     if ($class->config->{case_sensitive}) {
1300         $class->log->warn($class . "->config->{case_sensitive} is set.");
1301         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1302     }
1303
1304     $class->setup_finalize;
1305
1306     # Flush the log for good measure (in case something turned off 'autoflush' early)
1307     $class->log->_flush() if $class->log->can('_flush');
1308
1309     return $class || 1; # Just in case someone named their Application 0...
1310 }
1311
1312 =head2 $app->setup_finalize
1313
1314 A hook to attach modifiers to. This method does not do anything except set the
1315 C<setup_finished> accessor.
1316
1317 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1318
1319 Example:
1320
1321     after setup_finalize => sub {
1322         my $app = shift;
1323
1324         ## do stuff here..
1325     };
1326
1327 =cut
1328
1329 sub setup_finalize {
1330     my ($class) = @_;
1331     $class->setup_finished(1);
1332 }
1333
1334 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1335
1336 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1337
1338 =head2 $c->uri_for( $action, [@captures, @args], \%query_values? )
1339
1340 Constructs an absolute L<URI> object based on the application root, the
1341 provided path, and the additional arguments and query parameters provided.
1342 When used as a string, provides a textual URI.  If you need more flexibility
1343 than this (i.e. the option to provide relative URIs etc.) see
1344 L<Catalyst::Plugin::SmartURI>.
1345
1346 If no arguments are provided, the URI for the current action is returned.
1347 To return the current action and also provide @args, use
1348 C<< $c->uri_for( $c->action, @args ) >>.
1349
1350 If the first argument is a string, it is taken as a public URI path relative
1351 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1352 relative to the application root (if it does). It is then merged with
1353 C<< $c->request->base >>; any C<@args> are appended as additional path
1354 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1355
1356 If the first argument is a L<Catalyst::Action> it represents an action which
1357 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1358 optional C<\@captures> argument (an arrayref) allows passing the captured
1359 variables that are needed to fill in the paths of Chained and Regex actions;
1360 once the path is resolved, C<uri_for> continues as though a path was
1361 provided, appending any arguments or parameters and creating an absolute
1362 URI.
1363
1364 The captures for the current request can be found in
1365 C<< $c->request->captures >>, and actions can be resolved using
1366 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1367 path, use C<< $c->uri_for_action >> instead.
1368
1369   # Equivalent to $c->req->uri
1370   $c->uri_for($c->action, $c->req->captures,
1371       @{ $c->req->args }, $c->req->params);
1372
1373   # For the Foo action in the Bar controller
1374   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1375
1376   # Path to a static resource
1377   $c->uri_for('/static/images/logo.png');
1378
1379 In general the scheme of the generated URI object will follow the incoming request
1380 however if your targeted action or action chain has the Scheme attribute it will
1381 use that instead.
1382
1383 =cut
1384
1385 sub uri_for {
1386     my ( $c, $path, @args ) = @_;
1387
1388     if ( $path->$_isa('Catalyst::Controller') ) {
1389         $path = $path->path_prefix;
1390         $path =~ s{/+\z}{};
1391         $path .= '/';
1392     }
1393
1394     undef($path) if (defined $path && $path eq '');
1395
1396     my $params =
1397       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1398
1399     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1400
1401     my @encoded_args = ();
1402     foreach my $arg (@args) {
1403       if(ref($arg)||'' eq 'ARRAY') {
1404         push @encoded_args, [map {
1405           my $encoded = encode_utf8 $_;
1406           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1407          $encoded;
1408         } @$arg];
1409       } else {
1410         push @encoded_args, do {
1411           my $encoded = encode_utf8 $arg;
1412           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1413           $encoded;
1414         }
1415       }
1416     }
1417
1418     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1419     if ( $path->$_isa('Catalyst::Action') ) { # action object
1420         s|/|%2F|g for @encoded_args;
1421         my $captures = [ map { s|/|%2F|g; $_; }
1422                         ( scalar @encoded_args && ref $encoded_args[0] eq 'ARRAY'
1423                          ? @{ shift(@encoded_args) }
1424                          : ()) ];
1425
1426         my $action = $path;
1427         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1428         if( !@encoded_args && $action->number_of_args ) {
1429             my $expanded_action = $c->dispatcher->expand_action( $action );
1430             my $num_captures = $expanded_action->number_of_captures;
1431             unshift @encoded_args, splice @$captures, $num_captures;
1432         }
1433
1434        $path = $c->dispatcher->uri_for_action($action, $captures);
1435         if (not defined $path) {
1436             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1437                 if $c->debug;
1438             return undef;
1439         }
1440         $path = '/' if $path eq '';
1441     }
1442
1443     unshift(@encoded_args, $path);
1444
1445     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1446         my $namespace = $c->namespace;
1447         if (defined $path) { # cheesy hack to handle path '../foo'
1448            $namespace =~ s{(?:^|/)[^/]+$}{} while $encoded_args[0] =~ s{^\.\./}{};
1449         }
1450         unshift(@encoded_args, $namespace || '');
1451     }
1452
1453     # join args with '/', or a blank string
1454     my $args = join('/', grep { defined($_) } @encoded_args);
1455     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1456     $args =~ s!^/+!!;
1457
1458     my ($base, $class) = ('/', 'URI::_generic');
1459     if(blessed($c)) {
1460       $base = $c->req->base;
1461       if($target_action) {
1462         $target_action = $c->dispatcher->expand_action($target_action);
1463         if(my $s = $target_action->scheme) {
1464           $s = lc($s);
1465           $class = "URI::$s";
1466           $base->scheme($s);
1467         } else {
1468           $class = ref($base);
1469         }
1470       } else {
1471         $class = ref($base);
1472       }
1473
1474       $base =~ s{(?<!/)$}{/};
1475     }
1476
1477     my $query = '';
1478
1479     if (my @keys = keys %$params) {
1480       # somewhat lifted from URI::_query's query_form
1481       $query = '?'.join('&', map {
1482           my $val = $params->{$_};
1483           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1484           s/ /+/g;
1485           my $key = $_;
1486           $val = '' unless defined $val;
1487           (map {
1488               my $param = "$_";
1489               $param = encode_utf8($param);
1490               # using the URI::Escape pattern here so utf8 chars survive
1491               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1492               $param =~ s/ /+/g;
1493
1494               $key = encode_utf8($key);
1495               # using the URI::Escape pattern here so utf8 chars survive
1496               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1497               $key =~ s/ /+/g;
1498
1499               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1500       } @keys);
1501     }
1502
1503     my $res = bless(\"${base}${args}${query}", $class);
1504     $res;
1505 }
1506
1507 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1508
1509 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1510
1511 =over
1512
1513 =item $path
1514
1515 A private path to the Catalyst action you want to create a URI for.
1516
1517 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1518 >> and passing the resulting C<$action> and the remaining arguments to C<<
1519 $c->uri_for >>.
1520
1521 You can also pass in a Catalyst::Action object, in which case it is passed to
1522 C<< $c->uri_for >>.
1523
1524 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1525
1526 For example, if the action looks like:
1527
1528  package MyApp::Controller::Users;
1529
1530  sub lst : Path('the-list') {}
1531
1532 You can use:
1533
1534  $c->uri_for_action('/users/lst')
1535
1536 and it will create the URI /users/the-list.
1537
1538 =item \@captures_and_args?
1539
1540 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1541 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1542 to interpolate all the parameters in the URI.
1543
1544 =item @args?
1545
1546 Optional list of extra arguments - can be supplied in the
1547 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1548 code.
1549
1550 Your action can have zero, a fixed or a variable number of args (e.g.
1551 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1552
1553 =item \%query_values?
1554
1555 Optional array reference of query parameters to append. E.g.
1556
1557   { foo => 'bar' }
1558
1559 will generate
1560
1561   /rest/of/your/uri?foo=bar
1562
1563 =back
1564
1565 =cut
1566
1567 sub uri_for_action {
1568     my ( $c, $path, @args ) = @_;
1569     my $action = blessed($path)
1570       ? $path
1571       : $c->dispatcher->get_action_by_path($path);
1572     unless (defined $action) {
1573       croak "Can't find action for path '$path'";
1574     }
1575     return $c->uri_for( $action, @args );
1576 }
1577
1578 =head2 $c->welcome_message
1579
1580 Returns the Catalyst welcome HTML page.
1581
1582 =cut
1583
1584 sub welcome_message {
1585     my $c      = shift;
1586     my $name   = $c->config->{name};
1587     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1588     my $prefix = Catalyst::Utils::appprefix( ref $c );
1589     $c->response->content_type('text/html; charset=utf-8');
1590     return <<"EOF";
1591 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1592     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1593 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1594     <head>
1595     <meta http-equiv="Content-Language" content="en" />
1596     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1597         <title>$name on Catalyst $VERSION</title>
1598         <style type="text/css">
1599             body {
1600                 color: #000;
1601                 background-color: #eee;
1602             }
1603             div#content {
1604                 width: 640px;
1605                 margin-left: auto;
1606                 margin-right: auto;
1607                 margin-top: 10px;
1608                 margin-bottom: 10px;
1609                 text-align: left;
1610                 background-color: #ccc;
1611                 border: 1px solid #aaa;
1612             }
1613             p, h1, h2 {
1614                 margin-left: 20px;
1615                 margin-right: 20px;
1616                 font-family: verdana, tahoma, sans-serif;
1617             }
1618             a {
1619                 font-family: verdana, tahoma, sans-serif;
1620             }
1621             :link, :visited {
1622                     text-decoration: none;
1623                     color: #b00;
1624                     border-bottom: 1px dotted #bbb;
1625             }
1626             :link:hover, :visited:hover {
1627                     color: #555;
1628             }
1629             div#topbar {
1630                 margin: 0px;
1631             }
1632             pre {
1633                 margin: 10px;
1634                 padding: 8px;
1635             }
1636             div#answers {
1637                 padding: 8px;
1638                 margin: 10px;
1639                 background-color: #fff;
1640                 border: 1px solid #aaa;
1641             }
1642             h1 {
1643                 font-size: 0.9em;
1644                 font-weight: normal;
1645                 text-align: center;
1646             }
1647             h2 {
1648                 font-size: 1.0em;
1649             }
1650             p {
1651                 font-size: 0.9em;
1652             }
1653             p img {
1654                 float: right;
1655                 margin-left: 10px;
1656             }
1657             span#appname {
1658                 font-weight: bold;
1659                 font-size: 1.6em;
1660             }
1661         </style>
1662     </head>
1663     <body>
1664         <div id="content">
1665             <div id="topbar">
1666                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1667                     $VERSION</h1>
1668              </div>
1669              <div id="answers">
1670                  <p>
1671                  <img src="$logo" alt="Catalyst Logo" />
1672                  </p>
1673                  <p>Welcome to the  world of Catalyst.
1674                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1675                     framework will make web development something you had
1676                     never expected it to be: Fun, rewarding, and quick.</p>
1677                  <h2>What to do now?</h2>
1678                  <p>That really depends  on what <b>you</b> want to do.
1679                     We do, however, provide you with a few starting points.</p>
1680                  <p>If you want to jump right into web development with Catalyst
1681                     you might want to start with a tutorial.</p>
1682 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1683 </pre>
1684 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1685 <pre>
1686 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1687 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1688 </code></pre>
1689                  <h2>What to do next?</h2>
1690                  <p>Next it's time to write an actual application. Use the
1691                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1692                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1693                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1694                     they can save you a lot of work.</p>
1695                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1696                     <p>Also, be sure to check out the vast and growing
1697                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1698                     you are likely to find what you need there.
1699                     </p>
1700
1701                  <h2>Need help?</h2>
1702                  <p>Catalyst has a very active community. Here are the main places to
1703                     get in touch with us.</p>
1704                  <ul>
1705                      <li>
1706                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1707                      </li>
1708                      <li>
1709                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1710                      </li>
1711                      <li>
1712                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1713                      </li>
1714                  </ul>
1715                  <h2>In conclusion</h2>
1716                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1717                     as we enjoyed making it. Please contact us if you have ideas
1718                     for improvement or other feedback.</p>
1719              </div>
1720          </div>
1721     </body>
1722 </html>
1723 EOF
1724 }
1725
1726 =head2 run_options
1727
1728 Contains a hash of options passed from the application script, including
1729 the original ARGV the script received, the processed values from that
1730 ARGV and any extra arguments to the script which were not processed.
1731
1732 This can be used to add custom options to your application's scripts
1733 and setup your application differently depending on the values of these
1734 options.
1735
1736 =head1 INTERNAL METHODS
1737
1738 These methods are not meant to be used by end users.
1739
1740 =head2 $c->components
1741
1742 Returns a hash of components.
1743
1744 =head2 $c->context_class
1745
1746 Returns or sets the context class.
1747
1748 =head2 $c->counter
1749
1750 Returns a hashref containing coderefs and execution counts (needed for
1751 deep recursion detection).
1752
1753 =head2 $c->depth
1754
1755 Returns the number of actions on the current internal execution stack.
1756
1757 =head2 $c->dispatch
1758
1759 Dispatches a request to actions.
1760
1761 =cut
1762
1763 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1764
1765 =head2 $c->dispatcher_class
1766
1767 Returns or sets the dispatcher class.
1768
1769 =head2 $c->dump_these
1770
1771 Returns a list of 2-element array references (name, structure) pairs
1772 that will be dumped on the error page in debug mode.
1773
1774 =cut
1775
1776 sub dump_these {
1777     my $c = shift;
1778     [ Request => $c->req ],
1779     [ Response => $c->res ],
1780     [ Stash => $c->stash ],
1781     [ Config => $c->config ];
1782 }
1783
1784 =head2 $c->engine_class
1785
1786 Returns or sets the engine class.
1787
1788 =head2 $c->execute( $class, $coderef )
1789
1790 Execute a coderef in given class and catch exceptions. Errors are available
1791 via $c->error.
1792
1793 =cut
1794
1795 sub execute {
1796     my ( $c, $class, $code ) = @_;
1797     $class = $c->component($class) || $class;
1798     $c->state(0);
1799
1800     if ( $c->depth >= $RECURSION ) {
1801         my $action = $code->reverse();
1802         $action = "/$action" unless $action =~ /->/;
1803         my $error = qq/Deep recursion detected calling "${action}"/;
1804         $c->log->error($error);
1805         $c->error($error);
1806         $c->state(0);
1807         return $c->state;
1808     }
1809
1810     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1811
1812     push( @{ $c->stack }, $code );
1813
1814     no warnings 'recursion';
1815     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1816     #      I have no idea how, ergo $ret (which appears to fix the issue)
1817     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1818
1819     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1820
1821     my $last = pop( @{ $c->stack } );
1822
1823     if ( my $error = $@ ) {
1824         #rethow if this can be handled by middleware
1825         if(
1826           blessed $error && (
1827             $error->can('as_psgi') ||
1828             (
1829               $error->can('code') &&
1830               $error->code =~m/^[1-5][0-9][0-9]$/
1831             )
1832           )
1833         ) {
1834             foreach my $err (@{$c->error}) {
1835                 $c->log->error($err);
1836             }
1837             $c->clear_errors;
1838             $c->log->_flush if $c->log->can('_flush');
1839
1840             $error->can('rethrow') ? $error->rethrow : croak $error;
1841         }
1842         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1843             $error->rethrow if $c->depth > 1;
1844         }
1845         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1846             $error->rethrow if $c->depth > 0;
1847         }
1848         else {
1849             unless ( ref $error ) {
1850                 no warnings 'uninitialized';
1851                 chomp $error;
1852                 my $class = $last->class;
1853                 my $name  = $last->name;
1854                 $error = qq/Caught exception in $class->$name "$error"/;
1855             }
1856             $c->error($error);
1857         }
1858         $c->state(0);
1859     }
1860     return $c->state;
1861 }
1862
1863 sub _stats_start_execute {
1864     my ( $c, $code ) = @_;
1865     my $appclass = ref($c) || $c;
1866     return if ( ( $code->name =~ /^_.*/ )
1867         && ( !$appclass->config->{show_internal_actions} ) );
1868
1869     my $action_name = $code->reverse();
1870     $c->counter->{$action_name}++;
1871
1872     my $action = $action_name;
1873     $action = "/$action" unless $action =~ /->/;
1874
1875     # determine if the call was the result of a forward
1876     # this is done by walking up the call stack and looking for a calling
1877     # sub of Catalyst::forward before the eval
1878     my $callsub = q{};
1879     for my $index ( 2 .. 11 ) {
1880         last
1881         if ( ( caller($index) )[0] eq 'Catalyst'
1882             && ( caller($index) )[3] eq '(eval)' );
1883
1884         if ( ( caller($index) )[3] =~ /forward$/ ) {
1885             $callsub = ( caller($index) )[3];
1886             $action  = "-> $action";
1887             last;
1888         }
1889     }
1890
1891     my $uid = $action_name . $c->counter->{$action_name};
1892
1893     # is this a root-level call or a forwarded call?
1894     if ( $callsub =~ /forward$/ ) {
1895         my $parent = $c->stack->[-1];
1896
1897         # forward, locate the caller
1898         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1899             $c->stats->profile(
1900                 begin  => $action,
1901                 parent => "$parent" . $c->counter->{"$parent"},
1902                 uid    => $uid,
1903             );
1904         }
1905         else {
1906
1907             # forward with no caller may come from a plugin
1908             $c->stats->profile(
1909                 begin => $action,
1910                 uid   => $uid,
1911             );
1912         }
1913     }
1914     else {
1915
1916         # root-level call
1917         $c->stats->profile(
1918             begin => $action,
1919             uid   => $uid,
1920         );
1921     }
1922     return $action;
1923
1924 }
1925
1926 sub _stats_finish_execute {
1927     my ( $c, $info ) = @_;
1928     $c->stats->profile( end => $info );
1929 }
1930
1931 =head2 $c->finalize
1932
1933 Finalizes the request.
1934
1935 =cut
1936
1937 sub finalize {
1938     my $c = shift;
1939
1940     for my $error ( @{ $c->error } ) {
1941         $c->log->error($error);
1942     }
1943
1944     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1945     # stuff like cometd and websockets
1946
1947     if($c->request->_has_io_fh) {
1948       $c->log_response;
1949       return;
1950     }
1951
1952     # Allow engine to handle finalize flow (for POE)
1953     my $engine = $c->engine;
1954     if ( my $code = $engine->can('finalize') ) {
1955         $engine->$code($c);
1956     }
1957     else {
1958
1959         $c->finalize_uploads;
1960
1961         # Error
1962         if ( $#{ $c->error } >= 0 ) {
1963             $c->finalize_error;
1964         }
1965
1966         $c->finalize_encoding;
1967         $c->finalize_headers unless $c->response->finalized_headers;
1968         $c->finalize_body;
1969     }
1970
1971     $c->log_response;
1972
1973     if ($c->use_stats) {
1974         my $elapsed = $c->stats->elapsed;
1975         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1976         $c->log->info(
1977             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1978     }
1979
1980     return $c->response->status;
1981 }
1982
1983 =head2 $c->finalize_body
1984
1985 Finalizes body.
1986
1987 =cut
1988
1989 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1990
1991 =head2 $c->finalize_cookies
1992
1993 Finalizes cookies.
1994
1995 =cut
1996
1997 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1998
1999 =head2 $c->finalize_error
2000
2001 Finalizes error.  If there is only one error in L</error> and it is an object that
2002 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2003 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2004 return the default error page (production mode).
2005
2006 =cut
2007
2008 sub finalize_error {
2009     my $c = shift;
2010     if($#{$c->error} > 0) {
2011         $c->engine->finalize_error( $c, @_ );
2012     } else {
2013         my ($error) = @{$c->error};
2014         if(
2015           blessed $error &&
2016           ($error->can('as_psgi') || $error->can('code'))
2017         ) {
2018             # In the case where the error 'knows what it wants', becauses its PSGI
2019             # aware, just rethow and let middleware catch it
2020             $error->can('rethrow') ? $error->rethrow : croak $error;
2021         } else {
2022             $c->engine->finalize_error( $c, @_ )
2023         }
2024     }
2025 }
2026
2027 =head2 $c->finalize_headers
2028
2029 Finalizes headers.
2030
2031 =cut
2032
2033 sub finalize_headers {
2034     my $c = shift;
2035
2036     my $response = $c->response; #accessor calls can add up?
2037
2038     # Check if we already finalized headers
2039     return if $response->finalized_headers;
2040
2041     # Handle redirects
2042     if ( my $location = $response->redirect ) {
2043         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2044         $response->header( Location => $location );
2045     }
2046
2047     # Remove incorrectly added body and content related meta data when returning
2048     # an information response, or a response the is required to not include a body
2049
2050     $c->finalize_cookies;
2051
2052     $c->response->finalize_headers();
2053
2054     if(my $enc = $c->encoding) {
2055        my ($ct, $ct_enc) = $c->response->content_type;
2056
2057         # Only touch 'text-like' contents
2058         if($c->response->content_type =~ /^text|xml$|javascript$/) {
2059           if ($ct_enc && $ct_enc =~ /charset=([^;]*)/) {
2060             if (uc($1) ne uc($enc->mime_name)) {
2061               $c->log->debug("Catalyst encoding config is set to encode in '" .
2062                            $enc->mime_name .
2063                            "', content type is '$1', not encoding ");
2064             }
2065           } else {
2066             $c->res->content_type($c->res->content_type . "; charset=" . $enc->mime_name);
2067           }
2068         }
2069     }
2070
2071     # Done
2072     $response->finalized_headers(1);
2073 }
2074
2075 =head2 $c->finalize_encoding
2076
2077 Make sure your body is encoded properly IF you set an encoding.  By
2078 default the encoding is UTF-8 but you can disable it by explictly setting the
2079 encoding configuration value to undef.
2080
2081 See L</ENCODING>.
2082
2083 =cut
2084
2085 sub finalize_encoding {
2086     my $c = shift;
2087
2088     my $body = $c->response->body;
2089
2090     return unless defined($body);
2091
2092     my $enc = $c->encoding;
2093
2094     return unless $enc;
2095
2096     # Only touch 'text-like' contents
2097     if($c->response->content_type =~ /^text|xml$|javascript$/) {
2098       if (ref(\$body) eq 'SCALAR') {
2099         $c->response->body( $c->encoding->encode( $body, $c->_encode_check ) );
2100       }
2101     }
2102 }
2103
2104 =head2 $c->finalize_output
2105
2106 An alias for finalize_body.
2107
2108 =head2 $c->finalize_read
2109
2110 Finalizes the input after reading is complete.
2111
2112 =cut
2113
2114 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2115
2116 =head2 $c->finalize_uploads
2117
2118 Finalizes uploads. Cleans up any temporary files.
2119
2120 =cut
2121
2122 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2123
2124 =head2 $c->get_action( $action, $namespace )
2125
2126 Gets an action in a given namespace.
2127
2128 =cut
2129
2130 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2131
2132 =head2 $c->get_actions( $action, $namespace )
2133
2134 Gets all actions of a given name in a namespace and all parent
2135 namespaces.
2136
2137 =cut
2138
2139 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2140
2141 =head2 $app->handle_request( @arguments )
2142
2143 Called to handle each HTTP request.
2144
2145 =cut
2146
2147 sub handle_request {
2148     my ( $class, @arguments ) = @_;
2149
2150     # Always expect worst case!
2151     my $status = -1;
2152     try {
2153         if ($class->debug) {
2154             my $secs = time - $START || 1;
2155             my $av = sprintf '%.3f', $COUNT / $secs;
2156             my $time = localtime time;
2157             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2158         }
2159
2160         my $c = $class->prepare(@arguments);
2161         $c->dispatch;
2162         $status = $c->finalize;
2163     } catch {
2164         #rethow if this can be handled by middleware
2165         if(
2166           blessed($_) && (
2167             $_->can('as_psgi') ||
2168             (
2169               $_->can('code') &&
2170               $_->code =~m/^[1-5][0-9][0-9]$/
2171             )
2172           )
2173         ) {
2174             $_->can('rethrow') ? $_->rethrow : croak $_;
2175         }
2176         chomp(my $error = $_);
2177         $class->log->error(qq/Caught exception in engine "$error"/);
2178     };
2179
2180     $COUNT++;
2181
2182     if(my $coderef = $class->log->can('_flush')){
2183         $class->log->$coderef();
2184     }
2185     return $status;
2186 }
2187
2188 =head2 $class->prepare( @arguments )
2189
2190 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2191 etc.).
2192
2193 =cut
2194
2195 has _uploadtmp => (
2196     is => 'ro',
2197     predicate => '_has_uploadtmp',
2198 );
2199
2200 sub prepare {
2201     my ( $class, @arguments ) = @_;
2202
2203     # XXX
2204     # After the app/ctxt split, this should become an attribute based on something passed
2205     # into the application.
2206     $class->context_class( ref $class || $class ) unless $class->context_class;
2207
2208     my $uploadtmp = $class->config->{uploadtmp};
2209     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2210
2211     $c->response->_context($c);
2212
2213     #surely this is not the most efficient way to do things...
2214     $c->stats($class->stats_class->new)->enable($c->use_stats);
2215     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2216         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2217     }
2218
2219     try {
2220         # Allow engine to direct the prepare flow (for POE)
2221         if ( my $prepare = $c->engine->can('prepare') ) {
2222             $c->engine->$prepare( $c, @arguments );
2223         }
2224         else {
2225             $c->prepare_request(@arguments);
2226             $c->prepare_connection;
2227             $c->prepare_query_parameters;
2228             $c->prepare_headers; # Just hooks, no longer needed - they just
2229             $c->prepare_cookies; # cause the lazy attribute on req to build
2230             $c->prepare_path;
2231
2232             # Prepare the body for reading, either by prepare_body
2233             # or the user, if they are using $c->read
2234             $c->prepare_read;
2235
2236             # Parse the body unless the user wants it on-demand
2237             unless ( ref($c)->config->{parse_on_demand} ) {
2238                 $c->prepare_body;
2239             }
2240         }
2241         $c->prepare_action;
2242     }
2243     # VERY ugly and probably shouldn't rely on ->finalize actually working
2244     catch {
2245         # failed prepare is always due to an invalid request, right?
2246         $c->response->status(400);
2247         $c->response->content_type('text/plain');
2248         $c->response->body('Bad Request');
2249         # Note we call finalize and then die here, which escapes
2250         # finalize being called in the enclosing block..
2251         # It in fact couldn't be called, as we don't return $c..
2252         # This is a mess - but I'm unsure you can fix this without
2253         # breaking compat for people doing crazy things (we should set
2254         # the 400 and just return the ctx here IMO, letting finalize get called
2255         # above...
2256         $c->finalize;
2257         die $_;
2258     };
2259
2260     $c->log_request;
2261
2262     return $c;
2263 }
2264
2265 =head2 $c->prepare_action
2266
2267 Prepares action. See L<Catalyst::Dispatcher>.
2268
2269 =cut
2270
2271 sub prepare_action {
2272     my $c = shift;
2273     my $ret = $c->dispatcher->prepare_action( $c, @_);
2274
2275     if($c->encoding) {
2276         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2277           $_ = $c->_handle_param_unicode_decoding($_);
2278         }
2279     }
2280
2281     return $ret;
2282 }
2283
2284
2285 =head2 $c->prepare_body
2286
2287 Prepares message body.
2288
2289 =cut
2290
2291 sub prepare_body {
2292     my $c = shift;
2293
2294     return if $c->request->_has_body;
2295
2296     # Initialize on-demand data
2297     $c->engine->prepare_body( $c, @_ );
2298     $c->prepare_parameters;
2299     $c->prepare_uploads;
2300 }
2301
2302 =head2 $c->prepare_body_chunk( $chunk )
2303
2304 Prepares a chunk of data before sending it to L<HTTP::Body>.
2305
2306 See L<Catalyst::Engine>.
2307
2308 =cut
2309
2310 sub prepare_body_chunk {
2311     my $c = shift;
2312     $c->engine->prepare_body_chunk( $c, @_ );
2313 }
2314
2315 =head2 $c->prepare_body_parameters
2316
2317 Prepares body parameters.
2318
2319 =cut
2320
2321 sub prepare_body_parameters {
2322     my $c = shift;
2323     $c->request->prepare_body_parameters( $c, @_ );
2324 }
2325
2326 =head2 $c->prepare_connection
2327
2328 Prepares connection.
2329
2330 =cut
2331
2332 sub prepare_connection {
2333     my $c = shift;
2334     $c->request->prepare_connection($c);
2335 }
2336
2337 =head2 $c->prepare_cookies
2338
2339 Prepares cookies by ensuring that the attribute on the request
2340 object has been built.
2341
2342 =cut
2343
2344 sub prepare_cookies { my $c = shift; $c->request->cookies }
2345
2346 =head2 $c->prepare_headers
2347
2348 Prepares request headers by ensuring that the attribute on the request
2349 object has been built.
2350
2351 =cut
2352
2353 sub prepare_headers { my $c = shift; $c->request->headers }
2354
2355 =head2 $c->prepare_parameters
2356
2357 Prepares parameters.
2358
2359 =cut
2360
2361 sub prepare_parameters {
2362     my $c = shift;
2363     $c->prepare_body_parameters;
2364     $c->engine->prepare_parameters( $c, @_ );
2365 }
2366
2367 =head2 $c->prepare_path
2368
2369 Prepares path and base.
2370
2371 =cut
2372
2373 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2374
2375 =head2 $c->prepare_query_parameters
2376
2377 Prepares query parameters.
2378
2379 =cut
2380
2381 sub prepare_query_parameters {
2382     my $c = shift;
2383
2384     $c->engine->prepare_query_parameters( $c, @_ );
2385 }
2386
2387 =head2 $c->log_request
2388
2389 Writes information about the request to the debug logs.  This includes:
2390
2391 =over 4
2392
2393 =item * Request method, path, and remote IP address
2394
2395 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2396
2397 =item * Request parameters
2398
2399 =item * File uploads
2400
2401 =back
2402
2403 =cut
2404
2405 sub log_request {
2406     my $c = shift;
2407
2408     return unless $c->debug;
2409
2410     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2411     my $request = $dump->[1];
2412
2413     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2414     $method ||= '';
2415     $path = '/' unless length $path;
2416     $address ||= '';
2417
2418     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2419     $path = decode_utf8($path);
2420
2421     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2422
2423     $c->log_request_headers($request->headers);
2424
2425     if ( my $keywords = $request->query_keywords ) {
2426         $c->log->debug("Query keywords are: $keywords");
2427     }
2428
2429     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2430
2431     $c->log_request_uploads($request);
2432 }
2433
2434 =head2 $c->log_response
2435
2436 Writes information about the response to the debug logs by calling
2437 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2438
2439 =cut
2440
2441 sub log_response {
2442     my $c = shift;
2443
2444     return unless $c->debug;
2445
2446     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2447     my $response = $dump->[1];
2448
2449     $c->log_response_status_line($response);
2450     $c->log_response_headers($response->headers);
2451 }
2452
2453 =head2 $c->log_response_status_line($response)
2454
2455 Writes one line of information about the response to the debug logs.  This includes:
2456
2457 =over 4
2458
2459 =item * Response status code
2460
2461 =item * Content-Type header (if present)
2462
2463 =item * Content-Length header (if present)
2464
2465 =back
2466
2467 =cut
2468
2469 sub log_response_status_line {
2470     my ($c, $response) = @_;
2471
2472     $c->log->debug(
2473         sprintf(
2474             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2475             $response->status                            || 'unknown',
2476             $response->headers->header('Content-Type')   || 'unknown',
2477             $response->headers->header('Content-Length') || 'unknown'
2478         )
2479     );
2480 }
2481
2482 =head2 $c->log_response_headers($headers);
2483
2484 Hook method which can be wrapped by plugins to log the response headers.
2485 No-op in the default implementation.
2486
2487 =cut
2488
2489 sub log_response_headers {}
2490
2491 =head2 $c->log_request_parameters( query => {}, body => {} )
2492
2493 Logs request parameters to debug logs
2494
2495 =cut
2496
2497 sub log_request_parameters {
2498     my $c          = shift;
2499     my %all_params = @_;
2500
2501     return unless $c->debug;
2502
2503     my $column_width = Catalyst::Utils::term_width() - 44;
2504     foreach my $type (qw(query body)) {
2505         my $params = $all_params{$type};
2506         next if ! keys %$params;
2507         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2508         for my $key ( sort keys %$params ) {
2509             my $param = $params->{$key};
2510             my $value = defined($param) ? $param : '';
2511             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2512         }
2513         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2514     }
2515 }
2516
2517 =head2 $c->log_request_uploads
2518
2519 Logs file uploads included in the request to the debug logs.
2520 The parameter name, filename, file type, and file size are all included in
2521 the debug logs.
2522
2523 =cut
2524
2525 sub log_request_uploads {
2526     my $c = shift;
2527     my $request = shift;
2528     return unless $c->debug;
2529     my $uploads = $request->uploads;
2530     if ( keys %$uploads ) {
2531         my $t = Text::SimpleTable->new(
2532             [ 12, 'Parameter' ],
2533             [ 26, 'Filename' ],
2534             [ 18, 'Type' ],
2535             [ 9,  'Size' ]
2536         );
2537         for my $key ( sort keys %$uploads ) {
2538             my $upload = $uploads->{$key};
2539             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2540                 $t->row( $key, $u->filename, $u->type, $u->size );
2541             }
2542         }
2543         $c->log->debug( "File Uploads are:\n" . $t->draw );
2544     }
2545 }
2546
2547 =head2 $c->log_request_headers($headers);
2548
2549 Hook method which can be wrapped by plugins to log the request headers.
2550 No-op in the default implementation.
2551
2552 =cut
2553
2554 sub log_request_headers {}
2555
2556 =head2 $c->log_headers($type => $headers)
2557
2558 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2559
2560 =cut
2561
2562 sub log_headers {
2563     my $c       = shift;
2564     my $type    = shift;
2565     my $headers = shift;    # an HTTP::Headers instance
2566
2567     return unless $c->debug;
2568
2569     my $column_width = Catalyst::Utils::term_width() - 28;
2570     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2571     $headers->scan(
2572         sub {
2573             my ( $name, $value ) = @_;
2574             $t->row( $name, $value );
2575         }
2576     );
2577     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2578 }
2579
2580
2581 =head2 $c->prepare_read
2582
2583 Prepares the input for reading.
2584
2585 =cut
2586
2587 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2588
2589 =head2 $c->prepare_request
2590
2591 Prepares the engine request.
2592
2593 =cut
2594
2595 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2596
2597 =head2 $c->prepare_uploads
2598
2599 Prepares uploads.
2600
2601 =cut
2602
2603 sub prepare_uploads {
2604     my $c = shift;
2605     $c->engine->prepare_uploads( $c, @_ );
2606 }
2607
2608 =head2 $c->prepare_write
2609
2610 Prepares the output for writing.
2611
2612 =cut
2613
2614 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2615
2616 =head2 $c->request_class
2617
2618 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2619
2620 =head2 $c->response_class
2621
2622 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2623
2624 =head2 $c->read( [$maxlength] )
2625
2626 Reads a chunk of data from the request body. This method is designed to
2627 be used in a while loop, reading C<$maxlength> bytes on every call.
2628 C<$maxlength> defaults to the size of the request if not specified.
2629
2630 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2631 directly.
2632
2633 Warning: If you use read(), Catalyst will not process the body,
2634 so you will not be able to access POST parameters or file uploads via
2635 $c->request.  You must handle all body parsing yourself.
2636
2637 =cut
2638
2639 sub read { my $c = shift; return $c->request->read( @_ ) }
2640
2641 =head2 $c->run
2642
2643 Starts the engine.
2644
2645 =cut
2646
2647 sub run {
2648   my $app = shift;
2649   $app->_make_immutable_if_needed;
2650   $app->engine_loader->needs_psgi_engine_compat_hack ?
2651     $app->engine->run($app, @_) :
2652       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2653 }
2654
2655 sub _make_immutable_if_needed {
2656     my $class = shift;
2657     my $meta = find_meta($class);
2658     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2659     if (
2660         $meta->is_immutable
2661         && ! { $meta->immutable_options }->{replace_constructor}
2662         && $isa_ca
2663     ) {
2664         warn("You made your application class ($class) immutable, "
2665             . "but did not inline the\nconstructor. "
2666             . "This will break catalyst, as your app \@ISA "
2667             . "Class::Accessor(::Fast)?\nPlease pass "
2668             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2669     }
2670     unless ($meta->is_immutable) {
2671         # XXX - FIXME warning here as you should make your app immutable yourself.
2672         $meta->make_immutable(
2673             replace_constructor => 1,
2674         );
2675     }
2676 }
2677
2678 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2679
2680 Sets an action in a given namespace.
2681
2682 =cut
2683
2684 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2685
2686 =head2 $c->setup_actions($component)
2687
2688 Sets up actions for a component.
2689
2690 =cut
2691
2692 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2693
2694 =head2 $c->setup_components
2695
2696 This method is called internally to set up the application's components.
2697
2698 It finds modules by calling the L<locate_components> method, expands them to
2699 package names with the L<expand_component_module> method, and then installs
2700 each component into the application.
2701
2702 The C<setup_components> config option is passed to both of the above methods.
2703
2704 Installation of each component is performed by the L<setup_component> method,
2705 below.
2706
2707 =cut
2708
2709 sub setup_components {
2710     my $class = shift;
2711
2712     my $config  = $class->config->{ setup_components };
2713
2714     my @comps = $class->locate_components($config);
2715     my %comps = map { $_ => 1 } @comps;
2716
2717     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2718     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2719         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2720     ) if $deprecatedcatalyst_component_names;
2721
2722     for my $component ( @comps ) {
2723
2724         # We pass ignore_loaded here so that overlay files for (e.g.)
2725         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2726         # we know M::P::O found a file on disk so this is safe
2727
2728         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2729     }
2730
2731     for my $component (@comps) {
2732         my $instance = $class->components->{ $component } = $class->setup_component($component);
2733         my @expanded_components = $instance->can('expand_modules')
2734             ? $instance->expand_modules( $component, $config )
2735             : $class->expand_component_module( $component, $config );
2736         for my $component (@expanded_components) {
2737             next if $comps{$component};
2738             $class->components->{ $component } = $class->setup_component($component);
2739         }
2740     }
2741 }
2742
2743 =head2 $c->locate_components( $setup_component_config )
2744
2745 This method is meant to provide a list of component modules that should be
2746 setup for the application.  By default, it will use L<Module::Pluggable>.
2747
2748 Specify a C<setup_components> config option to pass additional options directly
2749 to L<Module::Pluggable>. To add additional search paths, specify a key named
2750 C<search_extra> as an array reference. Items in the array beginning with C<::>
2751 will have the application class name prepended to them.
2752
2753 =cut
2754
2755 sub locate_components {
2756     my $class  = shift;
2757     my $config = shift;
2758
2759     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
2760     my $extra   = delete $config->{ search_extra } || [];
2761
2762     unshift @paths, @$extra;
2763
2764     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
2765       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
2766       %$config
2767     )->plugins } @paths;
2768
2769     return @comps;
2770 }
2771
2772 =head2 $c->expand_component_module( $component, $setup_component_config )
2773
2774 Components found by C<locate_components> will be passed to this method, which
2775 is expected to return a list of component (package) names to be set up.
2776
2777 =cut
2778
2779 sub expand_component_module {
2780     my ($class, $module) = @_;
2781     return Devel::InnerPackage::list_packages( $module );
2782 }
2783
2784 =head2 $c->setup_component
2785
2786 =cut
2787
2788 sub setup_component {
2789     my( $class, $component ) = @_;
2790
2791     unless ( $component->can( 'COMPONENT' ) ) {
2792         return $component;
2793     }
2794
2795     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2796     my $config = $class->config->{ $suffix } || {};
2797     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2798     # methods also pass it. local to avoid pointlessly shitting in config
2799     # for the debug screen, as $component is already the key name.
2800     local $config->{catalyst_component_name} = $component;
2801
2802     my $instance = eval { $component->COMPONENT( $class, $config ); };
2803
2804     if ( my $error = $@ ) {
2805         chomp $error;
2806         Catalyst::Exception->throw(
2807             message => qq/Couldn't instantiate component "$component", "$error"/
2808         );
2809     }
2810
2811     unless (blessed $instance) {
2812         my $metaclass = Moose::Util::find_meta($component);
2813         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2814         my $component_method_from = $method_meta->associated_metaclass->name;
2815         my $value = defined($instance) ? $instance : 'undef';
2816         Catalyst::Exception->throw(
2817             message =>
2818             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2819         );
2820     }
2821     return $instance;
2822 }
2823
2824 =head2 $c->setup_dispatcher
2825
2826 Sets up dispatcher.
2827
2828 =cut
2829
2830 sub setup_dispatcher {
2831     my ( $class, $dispatcher ) = @_;
2832
2833     if ($dispatcher) {
2834         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2835     }
2836
2837     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2838         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2839     }
2840
2841     unless ($dispatcher) {
2842         $dispatcher = $class->dispatcher_class;
2843     }
2844
2845     load_class($dispatcher);
2846
2847     # dispatcher instance
2848     $class->dispatcher( $dispatcher->new );
2849 }
2850
2851 =head2 $c->setup_engine
2852
2853 Sets up engine.
2854
2855 =cut
2856
2857 sub engine_class {
2858     my ($class, $requested_engine) = @_;
2859
2860     if (!$class->engine_loader || $requested_engine) {
2861         $class->engine_loader(
2862             Catalyst::EngineLoader->new({
2863                 application_name => $class,
2864                 (defined $requested_engine
2865                      ? (catalyst_engine_class => $requested_engine) : ()),
2866             }),
2867         );
2868     }
2869
2870     $class->engine_loader->catalyst_engine_class;
2871 }
2872
2873 sub setup_engine {
2874     my ($class, $requested_engine) = @_;
2875
2876     my $engine = do {
2877         my $loader = $class->engine_loader;
2878
2879         if (!$loader || $requested_engine) {
2880             $loader = Catalyst::EngineLoader->new({
2881                 application_name => $class,
2882                 (defined $requested_engine
2883                      ? (requested_engine => $requested_engine) : ()),
2884             }),
2885
2886             $class->engine_loader($loader);
2887         }
2888
2889         $loader->catalyst_engine_class;
2890     };
2891
2892     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2893     return if $class->loading_psgi_file;
2894
2895     load_class($engine);
2896
2897     if ($ENV{MOD_PERL}) {
2898         my $apache = $class->engine_loader->auto;
2899
2900         my $meta = find_meta($class);
2901         my $was_immutable = $meta->is_immutable;
2902         my %immutable_options = $meta->immutable_options;
2903         $meta->make_mutable if $was_immutable;
2904
2905         $meta->add_method(handler => sub {
2906             my $r = shift;
2907             my $psgi_app = $class->_finalized_psgi_app;
2908             $apache->call_app($r, $psgi_app);
2909         });
2910
2911         $meta->make_immutable(%immutable_options) if $was_immutable;
2912     }
2913
2914     $class->engine( $engine->new );
2915
2916     return;
2917 }
2918
2919 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2920 ## build in server support (back compat support for pre psgi port behavior).
2921 ## This is so that we don't build a new psgi app for each request when using
2922 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2923
2924 sub _finalized_psgi_app {
2925     my ($app) = @_;
2926
2927     unless ($app->_psgi_app) {
2928         my $psgi_app = $app->_setup_psgi_app;
2929         $app->_psgi_app($psgi_app);
2930     }
2931
2932     return $app->_psgi_app;
2933 }
2934
2935 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2936 ## home directory and load that and return it (just assume it is doing the
2937 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2938 ## in default_middleware and return it ( this is for backward compatibility
2939 ## with pre psgi port behavior ).
2940
2941 sub _setup_psgi_app {
2942     my ($app) = @_;
2943
2944     for my $home (Path::Class::Dir->new($app->config->{home})) {
2945         my $psgi_file = $home->file(
2946             Catalyst::Utils::appprefix($app) . '.psgi',
2947         );
2948
2949         next unless -e $psgi_file;
2950
2951         # If $psgi_file calls ->setup_engine, it's doing so to load
2952         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2953         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2954         # anyway. So set a flag (ick) that tells setup_engine not to populate
2955         # $c->engine or do any other things we might regret.
2956
2957         $app->loading_psgi_file(1);
2958         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2959         $app->loading_psgi_file(0);
2960
2961         return $psgi_app
2962             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2963
2964         warn <<"EOW";
2965 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2966
2967 Its content has been ignored. Please consult the Catalyst::Upgrading
2968 documentation on how to upgrade from Catalyst::Engine::PSGI.
2969 EOW
2970     }
2971
2972     return $app->apply_default_middlewares($app->psgi_app);
2973 }
2974
2975 =head2 $c->apply_default_middlewares
2976
2977 Adds the following L<Plack> middlewares to your application, since they are
2978 useful and commonly needed:
2979
2980 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2981 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2982 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2983 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2984 applied since this middleware is smart enough to conditionally apply itself).
2985
2986 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2987 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2988 $ENV{SCRIPT_NAME}
2989
2990 =cut
2991
2992
2993 sub apply_default_middlewares {
2994     my ($app, $psgi_app) = @_;
2995
2996     $psgi_app = Plack::Middleware::Conditional->wrap(
2997         $psgi_app,
2998         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2999         condition => sub {
3000             my ($env) = @_;
3001             return if $app->config->{ignore_frontend_proxy};
3002             return $env->{REMOTE_ADDR} eq '127.0.0.1'
3003                 || $app->config->{using_frontend_proxy};
3004         },
3005     );
3006
3007     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3008     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3009     $psgi_app = Plack::Middleware::Conditional->wrap(
3010         $psgi_app,
3011         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3012         condition => sub {
3013             my ($env) = @_;
3014             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3015             return unless $1 < 4.23;
3016             1;
3017         },
3018     );
3019
3020     # we're applying this unconditionally as the middleware itself already makes
3021     # sure it doesn't fuck things up if it's not running under one of the right
3022     # IIS versions
3023     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3024
3025     # And another IIS issue, this time with IIS7.
3026     $psgi_app = Plack::Middleware::Conditional->wrap(
3027         $psgi_app,
3028         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3029         condition => sub {
3030             my ($env) = @_;
3031             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3032         },
3033     );
3034
3035     return $psgi_app;
3036 }
3037
3038 =head2 App->psgi_app
3039
3040 =head2 App->to_app
3041
3042 Returns a PSGI application code reference for the catalyst application
3043 C<$c>. This is the bare application without any middlewares
3044 applied. C<${myapp}.psgi> is not taken into account.
3045
3046 This is what you want to be using to retrieve the PSGI application code
3047 reference of your Catalyst application for use in F<.psgi> files.
3048
3049 =cut
3050
3051 *to_app = \&psgi_app;
3052
3053 sub psgi_app {
3054     my ($app) = @_;
3055     my $psgi = $app->engine->build_psgi_app($app);
3056     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3057 }
3058
3059 =head2 $c->setup_home
3060
3061 Sets up the home directory.
3062
3063 =cut
3064
3065 sub setup_home {
3066     my ( $class, $home ) = @_;
3067
3068     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3069         $home = $env;
3070     }
3071
3072     $home ||= Catalyst::Utils::home($class);
3073
3074     if ($home) {
3075         #I remember recently being scolded for assigning config values like this
3076         $class->config->{home} ||= $home;
3077         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3078     }
3079 }
3080
3081 =head2 $c->setup_encoding
3082
3083 Sets up the input/output encoding.  See L<ENCODING>
3084
3085 =cut
3086
3087 sub setup_encoding {
3088     my $c = shift;
3089     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3090         # Ok, so the user has explicitly said "I don't want encoding..."
3091         return;
3092     } else {
3093       my $enc = defined($c->config->{encoding}) ?
3094         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3095       $c->encoding($enc);
3096     }
3097 }
3098
3099 =head2 handle_unicode_encoding_exception
3100
3101 Hook to let you customize how encoding errors are handled.  By default
3102 we just throw an exception.  Receives a hashref of debug information.
3103 Example:
3104
3105     $c->handle_unicode_encoding_exception({
3106         param_value => $value,
3107         error_msg => $_,
3108             encoding_step => 'params',
3109         });
3110
3111 =cut
3112
3113 sub handle_unicode_encoding_exception {
3114     my ( $self, $exception_ctx ) = @_;
3115     die $exception_ctx->{error_msg};
3116 }
3117
3118 # Some unicode helpers cargo culted from the old plugin.  These could likely
3119 # be neater.
3120
3121 sub _handle_unicode_decoding {
3122     my ( $self, $value ) = @_;
3123
3124     return unless defined $value;
3125
3126     ## I think this mess is to support the old nested
3127     if ( ref $value eq 'ARRAY' ) {
3128         foreach ( @$value ) {
3129             $_ = $self->_handle_unicode_decoding($_);
3130         }
3131         return $value;
3132     }
3133     elsif ( ref $value eq 'HASH' ) {
3134         foreach (keys %$value) {
3135             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3136             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3137
3138             # If the key was encoded we now have two (the original and current so
3139             # delete the original.
3140             delete $value->{$_} if $_ ne $encoded_key;
3141         }
3142         return $value;
3143     }
3144     else {
3145         return $self->_handle_param_unicode_decoding($value);
3146     }
3147 }
3148
3149 sub _handle_param_unicode_decoding {
3150     my ( $self, $value ) = @_;
3151     return unless defined $value; # not in love with just ignoring undefs - jnap
3152
3153     my $enc = $self->encoding;
3154     return try {
3155       $enc->decode( $value, $self->_encode_check );
3156     }
3157     catch {
3158         $self->handle_unicode_encoding_exception({
3159             param_value => $value,
3160             error_msg => $_,
3161             encoding_step => 'params',
3162         });
3163     };
3164 }
3165
3166 =head2 $c->setup_log
3167
3168 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3169 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3170 log to.
3171
3172 This method also installs a C<debug> method that returns a true value into the
3173 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3174 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3175
3176 Note that if the log has already been setup, by either a previous call to
3177 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3178 that this method won't actually set up the log object.
3179
3180 =cut
3181
3182 sub setup_log {
3183     my ( $class, $levels ) = @_;
3184
3185     $levels ||= '';
3186     $levels =~ s/^\s+//;
3187     $levels =~ s/\s+$//;
3188     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3189
3190     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3191     if ( defined $env_debug ) {
3192         $levels{debug} = 1 if $env_debug; # Ugly!
3193         delete($levels{debug}) unless $env_debug;
3194     }
3195
3196     unless ( $class->log ) {
3197         $class->log( Catalyst::Log->new(keys %levels) );
3198     }
3199
3200     if ( $levels{debug} ) {
3201         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3202         $class->log->debug('Debug messages enabled');
3203     }
3204 }
3205
3206 =head2 $c->setup_plugins
3207
3208 Sets up plugins.
3209
3210 =cut
3211
3212 =head2 $c->setup_stats
3213
3214 Sets up timing statistics class.
3215
3216 =cut
3217
3218 sub setup_stats {
3219     my ( $class, $stats ) = @_;
3220
3221     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3222
3223     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3224     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3225         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3226         $class->log->debug('Statistics enabled');
3227     }
3228 }
3229
3230
3231 =head2 $c->registered_plugins
3232
3233 Returns a sorted list of the plugins which have either been stated in the
3234 import list.
3235
3236 If passed a given plugin name, it will report a boolean value indicating
3237 whether or not that plugin is loaded.  A fully qualified name is required if
3238 the plugin name does not begin with C<Catalyst::Plugin::>.
3239
3240  if ($c->registered_plugins('Some::Plugin')) {
3241      ...
3242  }
3243
3244 =cut
3245
3246 {
3247
3248     sub registered_plugins {
3249         my $proto = shift;
3250         return sort keys %{ $proto->_plugins } unless @_;
3251         my $plugin = shift;
3252         return 1 if exists $proto->_plugins->{$plugin};
3253         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3254     }
3255
3256     sub _register_plugin {
3257         my ( $proto, $plugin, $instant ) = @_;
3258         my $class = ref $proto || $proto;
3259
3260         load_class( $plugin );
3261         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3262             if $plugin->isa( 'Catalyst::Component' );
3263         my $plugin_meta = Moose::Meta::Class->create($plugin);
3264         if (!$plugin_meta->has_method('new')
3265             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3266             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3267         }
3268         if (!$instant && !$proto->_plugins->{$plugin}) {
3269             my $meta = Class::MOP::get_metaclass_by_name($class);
3270             $meta->superclasses($plugin, $meta->superclasses);
3271         }
3272         $proto->_plugins->{$plugin} = 1;
3273         return $class;
3274     }
3275
3276     sub _default_plugins { return qw() }
3277
3278     sub setup_plugins {
3279         my ( $class, $plugins ) = @_;
3280
3281         $class->_plugins( {} ) unless $class->_plugins;
3282         $plugins = [ grep {
3283             m/Unicode::Encoding/ ? do {
3284                 $class->log->warn(
3285                     'Unicode::Encoding plugin is auto-applied,'
3286                     . ' please remove this from your appclass'
3287                     . ' and make sure to define "encoding" config'
3288                 );
3289                 unless (exists $class->config->{'encoding'}) {
3290                   $class->config->{'encoding'} = 'UTF-8';
3291                 }
3292                 () }
3293                 : $_
3294         } @$plugins ];
3295         push @$plugins, $class->_default_plugins;
3296         $plugins = Data::OptList::mkopt($plugins || []);
3297
3298         my @plugins = map {
3299             [ Catalyst::Utils::resolve_namespace(
3300                   $class . '::Plugin',
3301                   'Catalyst::Plugin', $_->[0]
3302               ),
3303               $_->[1],
3304             ]
3305          } @{ $plugins };
3306
3307         for my $plugin ( reverse @plugins ) {
3308             load_class($plugin->[0], $plugin->[1]);
3309             my $meta = find_meta($plugin->[0]);
3310             next if $meta && $meta->isa('Moose::Meta::Role');
3311
3312             $class->_register_plugin($plugin->[0]);
3313         }
3314
3315         my @roles =
3316             map  { $_->[0]->name, $_->[1] }
3317             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3318             map  { [find_meta($_->[0]), $_->[1]] }
3319             @plugins;
3320
3321         Moose::Util::apply_all_roles(
3322             $class => @roles
3323         ) if @roles;
3324     }
3325 }
3326
3327 =head2 registered_middlewares
3328
3329 Read only accessor that returns an array of all the middleware in the order
3330 that they were added (which is the REVERSE of the order they will be applied).
3331
3332 The values returned will be either instances of L<Plack::Middleware> or of a
3333 compatible interface, or a coderef, which is assumed to be inlined middleware
3334
3335 =head2 setup_middleware (?@middleware)
3336
3337 Read configuration information stored in configuration key C<psgi_middleware> or
3338 from passed @args.
3339
3340 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3341 to use it to enable L<Plack::Middleware>
3342
3343 This method is automatically called during 'setup' of your application, so
3344 you really don't need to invoke it.  However you may do so if you find the idea
3345 of loading middleware via configuration weird :).  For example:
3346
3347     package MyApp;
3348
3349     use Catalyst;
3350
3351     __PACKAGE__->setup_middleware('Head');
3352     __PACKAGE__->setup;
3353
3354 When we read middleware definitions from configuration, we reverse the list
3355 which sounds odd but is likely how you expect it to work if you have prior
3356 experience with L<Plack::Builder> or if you previously used the plugin
3357 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3358
3359 So basically your middleware handles an incoming request from the first
3360 registered middleware, down and handles the response from the last middleware
3361 up.
3362
3363 =cut
3364
3365 sub registered_middlewares {
3366     my $class = shift;
3367     if(my $middleware = $class->_psgi_middleware) {
3368         return (
3369           Catalyst::Middleware::Stash->new,
3370           Plack::Middleware::HTTPExceptions->new,
3371           Plack::Middleware::RemoveRedundantBody->new,
3372           Plack::Middleware::FixMissingBodyInRedirect->new,
3373           Plack::Middleware::ContentLength->new,
3374           Plack::Middleware::MethodOverride->new,
3375           Plack::Middleware::Head->new,
3376           @$middleware);
3377     } else {
3378         die "You cannot call ->registered_middlewares until middleware has been setup";
3379     }
3380 }
3381
3382 sub setup_middleware {
3383     my $class = shift;
3384     my @middleware_definitions = @_ ?
3385       reverse(@_) : reverse(@{$class->config->{'psgi_middleware'}||[]});
3386
3387     my @middleware = ();
3388     while(my $next = shift(@middleware_definitions)) {
3389         if(ref $next) {
3390             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3391                 push @middleware, $next;
3392             } elsif(ref $next eq 'CODE') {
3393                 push @middleware, $next;
3394             } elsif(ref $next eq 'HASH') {
3395                 my $namespace = shift @middleware_definitions;
3396                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3397                 push @middleware, $mw;
3398             } else {
3399               die "I can't handle middleware definition ${\ref $next}";
3400             }
3401         } else {
3402           my $mw = $class->Catalyst::Utils::build_middleware($next);
3403           push @middleware, $mw;
3404         }
3405     }
3406
3407     my @existing = @{$class->_psgi_middleware || []};
3408     $class->_psgi_middleware([@middleware,@existing,]);
3409 }
3410
3411 =head2 registered_data_handlers
3412
3413 A read only copy of registered Data Handlers returned as a Hash, where each key
3414 is a content type and each value is a subref that attempts to decode that content
3415 type.
3416
3417 =head2 setup_data_handlers (?@data_handler)
3418
3419 Read configuration information stored in configuration key C<data_handlers> or
3420 from passed @args.
3421
3422 See under L</CONFIGURATION> information regarding C<data_handlers>.
3423
3424 This method is automatically called during 'setup' of your application, so
3425 you really don't need to invoke it.
3426
3427 =head2 default_data_handlers
3428
3429 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3430 only two default data handlers, for 'application/json' and an alternative to
3431 'application/x-www-form-urlencoded' which supposed nested form parameters via
3432 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3433
3434 The 'application/json' data handler is used to parse incoming JSON into a Perl
3435 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3436 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3437 JSON decoder, and has the smallest dependency impact.
3438
3439 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3440 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3441 order to get the best performance.  You should add either to your dependency
3442 list (Makefile.PL, dist.ini, cpanfile, etc.)
3443
3444 =cut
3445
3446 sub registered_data_handlers {
3447     my $class = shift;
3448     if(my $data_handlers = $class->_data_handlers) {
3449         return %$data_handlers;
3450     } else {
3451         $class->setup_data_handlers;
3452         return $class->registered_data_handlers;
3453     }
3454 }
3455
3456 sub setup_data_handlers {
3457     my ($class, %data_handler_callbacks) = @_;
3458     %data_handler_callbacks = (
3459       %{$class->default_data_handlers},
3460       %{$class->config->{'data_handlers'}||+{}},
3461       %data_handler_callbacks);
3462
3463     $class->_data_handlers(\%data_handler_callbacks);
3464 }
3465
3466 sub default_data_handlers {
3467     my ($class) = @_;
3468     return +{
3469       'application/x-www-form-urlencoded' => sub {
3470           my ($fh, $req) = @_;
3471           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3472           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3473             ->can('build_cgi_struct')->($params);
3474       },
3475       'application/json' => sub {
3476           Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON')
3477             ->can('decode_json')->(do { local $/; $_->getline });
3478       },
3479     };
3480 }
3481
3482 =head2 $c->stack
3483
3484 Returns an arrayref of the internal execution stack (actions that are
3485 currently executing).
3486
3487 =head2 $c->stats
3488
3489 Returns the current timing statistics object. By default Catalyst uses
3490 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3491 L<< stats_class|/"$c->stats_class" >>.
3492
3493 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3494 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3495 profile explicitly, although MyApp.pm still won't profile nor output anything
3496 by itself.
3497
3498 =head2 $c->stats_class
3499
3500 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3501
3502 =head2 $c->use_stats
3503
3504 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3505
3506 Note that this is a static method, not an accessor and should be overridden
3507 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3508
3509 =cut
3510
3511 sub use_stats { 0 }
3512
3513
3514 =head2 $c->write( $data )
3515
3516 Writes $data to the output stream. When using this method directly, you
3517 will need to manually set the C<Content-Length> header to the length of
3518 your output data, if known.
3519
3520 =cut
3521
3522 sub write {
3523     my $c = shift;
3524
3525     # Finalize headers if someone manually writes output (for compat)
3526     $c->finalize_headers;
3527
3528     return $c->response->write( @_ );
3529 }
3530
3531 =head2 version
3532
3533 Returns the Catalyst version number. Mostly useful for "powered by"
3534 messages in template systems.
3535
3536 =cut
3537
3538 sub version { return $Catalyst::VERSION }
3539
3540 =head1 CONFIGURATION
3541
3542 There are a number of 'base' config variables which can be set:
3543
3544 =over
3545
3546 =item *
3547
3548 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3549
3550 =item *
3551
3552 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3553
3554 =item *
3555
3556 C<disable_component_resolution_regex_fallback> - Turns
3557 off the deprecated component resolution functionality so
3558 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3559 are called then regex search will not be attempted on string values and
3560 instead C<undef> will be returned.
3561
3562 =item *
3563
3564 C<home> - The application home directory. In an uninstalled application,
3565 this is the top level application directory. In an installed application,
3566 this will be the directory containing C<< MyApp.pm >>.
3567
3568 =item *
3569
3570 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3571
3572 =item *
3573
3574 C<name> - The name of the application in debug messages and the debug and
3575 welcome screens
3576
3577 =item *
3578
3579 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3580 until it is accessed. This allows you to (for example) check authentication (and reject
3581 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3582
3583 =item *
3584
3585 C<root> - The root directory for templates. Usually this is just a
3586 subdirectory of the home directory, but you can set it to change the
3587 templates to a different directory.
3588
3589 =item *
3590
3591 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3592 namespaces from which components will be loaded (and constructed and stored in
3593 C<< $c->components >>).
3594
3595 =item *
3596
3597 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3598 to be shown in hit debug tables in the test server.
3599
3600 =item *
3601
3602 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3603 variable should be used for determining the request path.
3604
3605 Most web server environments pass the requested path to the application using environment variables,
3606 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3607 exposed as C<< $c->request->base >>) and the request path below that base.
3608
3609 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3610 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3611
3612 =over
3613
3614 =item use_request_uri_for_path => 0
3615
3616 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3617 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3618 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3619 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3620
3621 However this method has the major disadvantage that it is impossible to correctly decode some elements
3622 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3623 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3624 can't distinguish / vs %2F in paths (in addition to other encoded values).
3625
3626 =item use_request_uri_for_path => 1
3627
3628 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3629 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3630 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3631
3632 Given that this method of path resolution is provably more correct, it is recommended that you use
3633 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3634 aware of the implications of not being able to handle encoded URI paths correctly.
3635
3636 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3637 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3638 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3639 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3640 C<< $c->request->base >> will be incorrect.
3641
3642 =back
3643
3644 =item *
3645
3646 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3647
3648 =item *
3649
3650 C<encoding> - See L</ENCODING>
3651
3652 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
3653 value to undef.
3654
3655 =item *
3656
3657 C<abort_chain_on_error_fix>
3658
3659 When there is an error in an action chain, the default behavior is to continue
3660 processing the remaining actions and then catch the error upon chain end.  This
3661 can lead to running actions when the application is in an unexpected state.  If
3662 you have this issue, setting this config value to true will promptly exit a
3663 chain when there is an error raised in any action (thus terminating the chain
3664 early.)
3665
3666 use like:
3667
3668     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3669
3670 In the future this might become the default behavior.
3671
3672 =item *
3673
3674 C<use_hash_multivalue_in_request>
3675
3676 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3677 and C<parameters> return a hashref where values might be scalar or an arrayref
3678 depending on the incoming data.  In many cases this can be undesirable as it
3679 leads one to writing defensive code like the following:
3680
3681     my ($val) = ref($c->req->parameters->{a}) ?
3682       @{$c->req->parameters->{a}} :
3683         $c->req->parameters->{a};
3684
3685 Setting this configuration item to true will make L<Catalyst> populate the
3686 attributes underlying these methods with an instance of L<Hash::MultiValue>
3687 which is used by L<Plack::Request> and others to solve this very issue.  You
3688 may prefer this behavior to the default, if so enable this option (be warned
3689 if you enable it in a legacy application we are not sure if it is completely
3690 backwardly compatible).
3691
3692 =item *
3693
3694 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3695
3696 =item *
3697
3698 C<data_handlers> - See L<DATA HANDLERS>.
3699
3700 =back
3701
3702 =head1 EXCEPTIONS
3703
3704 Generally when you throw an exception inside an Action (or somewhere in
3705 your stack, such as in a model that an Action is calling) that exception
3706 is caught by Catalyst and unless you either catch it yourself (via eval
3707 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
3708 will eventually reach L</finalize_errors> and return either the debugging
3709 error stack page, or the default error page.  However, if your exception
3710 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
3711 instead rethrow it so that it can be handled by that middleware (which
3712 is part of the default middleware).  For example this would allow
3713
3714     use HTTP::Throwable::Factory 'http_throw';
3715
3716     sub throws_exception :Local {
3717       my ($self, $c) = @_;
3718
3719       http_throw(SeeOther => { location =>
3720         $c->uri_for($self->action_for('redirect')) });
3721
3722     }
3723
3724 =head1 INTERNAL ACTIONS
3725
3726 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3727 C<_ACTION>, and C<_END>. These are by default not shown in the private
3728 action table, but you can make them visible with a config parameter.
3729
3730     MyApp->config(show_internal_actions => 1);
3731
3732 =head1 ON-DEMAND PARSER
3733
3734 The request body is usually parsed at the beginning of a request,
3735 but if you want to handle input yourself, you can enable on-demand
3736 parsing with a config parameter.
3737
3738     MyApp->config(parse_on_demand => 1);
3739
3740 =head1 PROXY SUPPORT
3741
3742 Many production servers operate using the common double-server approach,
3743 with a lightweight frontend web server passing requests to a larger
3744 backend server. An application running on the backend server must deal
3745 with two problems: the remote user always appears to be C<127.0.0.1> and
3746 the server's hostname will appear to be C<localhost> regardless of the
3747 virtual host that the user connected through.
3748
3749 Catalyst will automatically detect this situation when you are running
3750 the frontend and backend servers on the same machine. The following
3751 changes are made to the request.
3752
3753     $c->req->address is set to the user's real IP address, as read from
3754     the HTTP X-Forwarded-For header.
3755
3756     The host value for $c->req->base and $c->req->uri is set to the real
3757     host, as read from the HTTP X-Forwarded-Host header.
3758
3759 Additionally, you may be running your backend application on an insecure
3760 connection (port 80) while your frontend proxy is running under SSL.  If there
3761 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3762 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3763 be created properly.
3764
3765 In the case of passing in:
3766
3767     X-Forwarded-Port: 443
3768
3769 All calls to C<uri_for> will result in an https link, as is expected.
3770
3771 Obviously, your web server must support these headers for this to work.
3772
3773 In a more complex server farm environment where you may have your
3774 frontend proxy server(s) on different machines, you will need to set a
3775 configuration option to tell Catalyst to read the proxied data from the
3776 headers.
3777
3778     MyApp->config(using_frontend_proxy => 1);
3779
3780 If you do not wish to use the proxy support at all, you may set:
3781
3782     MyApp->config(ignore_frontend_proxy => 0);
3783
3784 =head2 Note about psgi files
3785
3786 Note that if you supply your own .psgi file, calling
3787 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3788
3789 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3790 in your psgi, for example:
3791
3792     builder {
3793         enable "Plack::Middleware::ReverseProxy";
3794         MyApp->psgi_app
3795     };
3796
3797 This will unconditionally add the ReverseProxy support, or you need to call
3798 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3799 apply the support depending upon your config).
3800
3801 See L<Catalyst::PSGI> for more information.
3802
3803 =head1 THREAD SAFETY
3804
3805 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3806 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3807 believe the Catalyst core to be thread-safe.
3808
3809 If you plan to operate in a threaded environment, remember that all other
3810 modules you are using must also be thread-safe. Some modules, most notably
3811 L<DBD::SQLite>, are not thread-safe.
3812
3813 =head1 DATA HANDLERS
3814
3815 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3816 form parameters and URL search query fields.  However it has become common
3817 for various alternative content types to be PUT or POSTed to your controllers
3818 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3819 XML and other content types when communicating with an application server.  In
3820 order to better support this use case, L<Catalyst> defines a global configuration
3821 option, C<data_handlers>, which lets you associate a content type with a coderef
3822 that parses that content type into something Perl can readily access.
3823
3824     package MyApp::Web;
3825
3826     use Catalyst;
3827     use JSON::Maybe;
3828
3829     __PACKAGE__->config(
3830       data_handlers => {
3831         'application/json' => sub { local $/; decode_json $_->getline },
3832       },
3833       ## Any other configuration.
3834     );
3835
3836     __PACKAGE__->setup;
3837
3838 By default L<Catalyst> comes with a generic JSON data handler similar to the
3839 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
3840 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
3841 it installed (if you want the faster XS parser, add it to you project Makefile.PL
3842 or dist.ini, cpanfile, etc.)
3843
3844 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
3845 (matched against the incoming request type using a regexp such as to be case
3846 insensitive) and whose values are coderefs that receive a localized version of
3847 C<$_> which is a filehandle object pointing to received body.
3848
3849 This feature is considered an early access release and we reserve the right
3850 to alter the interface in order to provide a performant and secure solution to
3851 alternative request body content.  Your reports welcomed!
3852
3853 =head1 PSGI MIDDLEWARE
3854
3855 You can define middleware, defined as L<Plack::Middleware> or a compatible
3856 interface in configuration.  Your middleware definitions are in the form of an
3857 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3858 with details to follow:
3859
3860     package MyApp::Web;
3861
3862     use Catalyst;
3863     use Plack::Middleware::StackTrace;
3864
3865     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3866
3867     __PACKAGE__->config(
3868       'psgi_middleware', [
3869         'Debug',
3870         '+MyApp::Custom',
3871         $stacktrace_middleware,
3872         'Session' => {store => 'File'},
3873         sub {
3874           my $app = shift;
3875           return sub {
3876             my $env = shift;
3877             $env->{myapp.customkey} = 'helloworld';
3878             $app->($env);
3879           },
3880         },
3881       ],
3882     );
3883
3884     __PACKAGE__->setup;
3885
3886 So the general form is:
3887
3888     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3889
3890 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3891 the order listed (to make it function similarly to L<Plack::Builder>:
3892
3893 Alternatively, you may also define middleware by calling the L</setup_middleware>
3894 package method:
3895
3896     package MyApp::Web;
3897
3898     use Catalyst;
3899
3900     __PACKAGE__->setup_middleware( \@middleware_definitions);
3901     __PACKAGE__->setup;
3902
3903 In the case where you do both (use 'setup_middleware' and configuration) the
3904 package call to setup_middleware will be applied earlier (in other words its
3905 middleware will wrap closer to the application).  Keep this in mind since in
3906 some cases the order of middleware is important.
3907
3908 The two approaches are not exclusive.
3909
3910 =over 4
3911
3912 =item Middleware Object
3913
3914 An already initialized object that conforms to the L<Plack::Middleware>
3915 specification:
3916
3917     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3918
3919     __PACKAGE__->config(
3920       'psgi_middleware', [
3921         $stacktrace_middleware,
3922       ]);
3923
3924
3925 =item coderef
3926
3927 A coderef that is an inlined middleware:
3928
3929     __PACKAGE__->config(
3930       'psgi_middleware', [
3931         sub {
3932           my $app = shift;
3933           return sub {
3934             my $env = shift;
3935             if($env->{PATH_INFO} =~m/forced/) {
3936               Plack::App::File
3937                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3938                 ->call($env);
3939             } else {
3940               return $app->($env);
3941             }
3942          },
3943       },
3944     ]);
3945
3946
3947
3948 =item a scalar
3949
3950 We assume the scalar refers to a namespace after normalizing it using the
3951 following rules:
3952
3953 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3954 is assumed to be 'as is', and we just install and use the middleware.
3955
3956 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3957 (the package name of your Catalyst application subclass), we also assume then
3958 that it is a full namespace, and use it.
3959
3960 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3961 resolve it first by looking for it under your application namespace (for example
3962 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3963 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3964 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3965 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3966 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3967 you find that a good idea.
3968
3969 Examples:
3970
3971     package MyApp::Web;
3972
3973     __PACKAGE__->config(
3974       'psgi_middleware', [
3975         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3976         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3977         '+MyApp::Custom',  ## MyApp::Custom->wrap
3978       ],
3979     );
3980
3981 =item a scalar followed by a hashref
3982
3983 Just like the previous, except the following C<HashRef> is used as arguments
3984 to initialize the middleware object.
3985
3986     __PACKAGE__->config(
3987       'psgi_middleware', [
3988          'Session' => {store => 'File'},
3989     ]);
3990
3991 =back
3992
3993 Please see L<PSGI> for more on middleware.
3994
3995 =head1 ENCODING
3996
3997 On request, decodes all params from encoding into a sequence of
3998 logical characters. On response, encodes body into encoding.
3999
4000 By default encoding is now 'UTF-8'.  You may turn it off by setting
4001 the encoding configuration to undef.
4002
4003 =head2 Methods
4004
4005 =over 4
4006
4007 =item encoding
4008
4009 Returns an instance of an C<Encode> encoding
4010
4011     print $c->encoding->name
4012
4013 =item handle_unicode_encoding_exception ($exception_context)
4014
4015 Method called when decoding process for a request fails.
4016
4017 An C<$exception_context> hashref is provided to allow you to override the
4018 behaviour of your application when given data with incorrect encodings.
4019
4020 The default method throws exceptions in the case of invalid request parameters
4021 (resulting in a 500 error), but ignores errors in upload filenames.
4022
4023 The keys passed in the C<$exception_context> hash are:
4024
4025 =over
4026
4027 =item param_value
4028
4029 The value which was not able to be decoded.
4030
4031 =item error_msg
4032
4033 The exception received from L<Encode>.
4034
4035 =item encoding_step
4036
4037 What type of data was being decoded. Valid values are (currently)
4038 C<params> - for request parameters / arguments / captures
4039 and C<uploads> - for request upload filenames.
4040
4041 =back
4042
4043 =back
4044
4045 =head1 SUPPORT
4046
4047 IRC:
4048
4049     Join #catalyst on irc.perl.org.
4050
4051 Mailing Lists:
4052
4053     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4054     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4055
4056 Web:
4057
4058     http://catalyst.perl.org
4059
4060 Wiki:
4061
4062     http://dev.catalyst.perl.org
4063
4064 =head1 SEE ALSO
4065
4066 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4067
4068 =head2 L<Catalyst::Manual> - The Catalyst Manual
4069
4070 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4071
4072 =head2 L<Catalyst::Engine> - Core engine
4073
4074 =head2 L<Catalyst::Log> - Log class.
4075
4076 =head2 L<Catalyst::Request> - Request object
4077
4078 =head2 L<Catalyst::Response> - Response object
4079
4080 =head2 L<Catalyst::Test> - The test suite.
4081
4082 =head1 PROJECT FOUNDER
4083
4084 sri: Sebastian Riedel <sri@cpan.org>
4085
4086 =head1 CONTRIBUTORS
4087
4088 abw: Andy Wardley
4089
4090 acme: Leon Brocard <leon@astray.com>
4091
4092 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4093
4094 Andrew Bramble
4095
4096 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4097
4098 Andrew Ruthven
4099
4100 andyg: Andy Grundman <andy@hybridized.org>
4101
4102 audreyt: Audrey Tang
4103
4104 bricas: Brian Cassidy <bricas@cpan.org>
4105
4106 Caelum: Rafael Kitover <rkitover@io.com>
4107
4108 chansen: Christian Hansen
4109
4110 chicks: Christopher Hicks
4111
4112 Chisel Wright C<pause@herlpacker.co.uk>
4113
4114 Danijel Milicevic C<me@danijel.de>
4115
4116 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4117
4118 David Naughton, C<naughton@umn.edu>
4119
4120 David E. Wheeler
4121
4122 dhoss: Devin Austin <dhoss@cpan.org>
4123
4124 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4125
4126 Drew Taylor
4127
4128 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4129
4130 esskar: Sascha Kiefer
4131
4132 fireartist: Carl Franks <cfranks@cpan.org>
4133
4134 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4135
4136 gabb: Danijel Milicevic
4137
4138 Gary Ashton Jones
4139
4140 Gavin Henry C<ghenry@perl.me.uk>
4141
4142 Geoff Richards
4143
4144 groditi: Guillermo Roditi <groditi@gmail.com>
4145
4146 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4147
4148 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4149
4150 jcamacho: Juan Camacho
4151
4152 jester: Jesse Sheidlower C<jester@panix.com>
4153
4154 jhannah: Jay Hannah <jay@jays.net>
4155
4156 Jody Belka
4157
4158 Johan Lindstrom
4159
4160 jon: Jon Schutz <jjschutz@cpan.org>
4161
4162 Jonathan Rockway C<< <jrockway@cpan.org> >>
4163
4164 Kieren Diment C<kd@totaldatasolution.com>
4165
4166 konobi: Scott McWhirter <konobi@cpan.org>
4167
4168 marcus: Marcus Ramberg <mramberg@cpan.org>
4169
4170 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4171
4172 mgrimes: Mark Grimes <mgrimes@cpan.org>
4173
4174 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4175
4176 mugwump: Sam Vilain
4177
4178 naughton: David Naughton
4179
4180 ningu: David Kamholz <dkamholz@cpan.org>
4181
4182 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4183
4184 numa: Dan Sully <daniel@cpan.org>
4185
4186 obra: Jesse Vincent
4187
4188 Octavian Rasnita
4189
4190 omega: Andreas Marienborg
4191
4192 Oleg Kostyuk <cub.uanic@gmail.com>
4193
4194 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4195
4196 rafl: Florian Ragwitz <rafl@debian.org>
4197
4198 random: Roland Lammel <lammel@cpan.org>
4199
4200 Robert Sedlacek C<< <rs@474.at> >>
4201
4202 SpiceMan: Marcel Montes
4203
4204 sky: Arthur Bergman
4205
4206 szbalint: Balint Szilakszi <szbalint@cpan.org>
4207
4208 t0m: Tomas Doran <bobtfish@bobtfish.net>
4209
4210 Ulf Edvinsson
4211
4212 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4213
4214 Viljo Marrandi C<vilts@yahoo.com>
4215
4216 Will Hawes C<info@whawes.co.uk>
4217
4218 willert: Sebastian Willert <willert@cpan.org>
4219
4220 wreis: Wallace Reis <wreis@cpan.org>
4221
4222 Yuval Kogman, C<nothingmuch@woobling.org>
4223
4224 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4225
4226 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4227
4228 Upasana <me@upasana.me>
4229
4230 =head1 COPYRIGHT
4231
4232 Copyright (c) 2005-2014, the above named PROJECT FOUNDER and CONTRIBUTORS.
4233
4234 =head1 LICENSE
4235
4236 This library is free software. You can redistribute it and/or modify it under
4237 the same terms as Perl itself.
4238
4239 =cut
4240
4241 no Moose;
4242
4243 __PACKAGE__->meta->make_immutable;
4244
4245 1;