lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/container components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80032';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub _application { $_[0] }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 This sets the log level to 'debug' and enables full debug output on the
 252 error screen. If you only want the latter, see L<< $c->debug >>.
 253
 254 =head2 -Engine
 255
 256 Forces Catalyst to use a specific engine. Omit the
 257 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 258
 259     use Catalyst qw/-Engine=CGI/;
 260
 261 =head2 -Home
 262
 263 Forces Catalyst to use a specific home directory, e.g.:
 264
 265     use Catalyst qw[-Home=/usr/mst];
 266
 267 This can also be done in the shell environment by setting either the
 268 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 269 is replaced with the uppercased name of your application, any "::" in
 270 the name will be replaced with underscores, e.g. MyApp::Web should use
 271 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 272
 273 If none of these are set, Catalyst will attempt to automatically detect the
 274 home directory. If you are working in a development envirnoment, Catalyst
 275 will try and find the directory containing either Makefile.PL, Build.PL or
 276 dist.ini. If the application has been installed into the system (i.e.
 277 you have done C<make install>), then Catalyst will use the path to your
 278 application module, without the .pm extension (ie, /foo/MyApp if your
 279 application was installed at /foo/MyApp.pm)
 280
 281 =head2 -Log
 282
 283     use Catalyst '-Log=warn,fatal,error';
 284
 285 Specifies a comma-delimited list of log levels.
 286
 287 =head2 -Stats
 288
 289 Enables statistics collection and reporting.
 290
 291    use Catalyst qw/-Stats=1/;
 292
 293 You can also force this setting from the system environment with CATALYST_STATS
 294 or <MYAPP>_STATS. The environment settings override the application, with
 295 <MYAPP>_STATS having the highest priority.
 296
 297 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 298
 299 =head1 METHODS
 300
 301 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 302
 303 =head2 $c->action
 304
 305 Returns a L<Catalyst::Action> object for the current action, which
 306 stringifies to the action name. See L<Catalyst::Action>.
 307
 308 =head2 $c->namespace
 309
 310 Returns the namespace of the current action, i.e., the URI prefix
 311 corresponding to the controller of the current action. For example:
 312
 313     # in Controller::Foo::Bar
 314     $c->namespace; # returns 'foo/bar';
 315
 316 =head2 $c->request
 317
 318 =head2 $c->req
 319
 320 Returns the current L<Catalyst::Request> object, giving access to
 321 information about the current client request (including parameters,
 322 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 323
 324 =head2 REQUEST FLOW HANDLING
 325
 326 =head2 $c->forward( $action [, \@arguments ] )
 327
 328 =head2 $c->forward( $class, $method, [, \@arguments ] )
 329
 330 Forwards processing to another action, by its private name. If you give a
 331 class name but no method, C<process()> is called. You may also optionally
 332 pass arguments in an arrayref. The action will receive the arguments in
 333 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 334 C<< $c->req->args >> will be restored to the previous values.
 335
 336 Any data C<return>ed from the action forwarded to, will be returned by the
 337 call to forward.
 338
 339     my $foodata = $c->forward('/foo');
 340     $c->forward('index');
 341     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 342     $c->forward('View::TT');
 343
 344 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 345 an C<< eval { } >> around the call (actually
 346 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 347 all 'dies' within the called action. If you want C<die> to propagate you
 348 need to do something like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 374
 375 =cut
 376
 377 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 378
 379 =head2 $c->detach( $action [, \@arguments ] )
 380
 381 =head2 $c->detach( $class, $method, [, \@arguments ] )
 382
 383 =head2 $c->detach()
 384
 385 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 386 doesn't return to the previous action when processing is finished.
 387
 388 When called with no arguments it escapes the processing chain entirely.
 389
 390 =cut
 391
 392 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 393
 394 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 397
 398 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 399 but does a full dispatch, instead of just calling the new C<$action> /
 400 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 401 you go to are called, just like a new request.
 402
 403 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 404 This means, for example, that C<< $c->action >> methods such as
 405 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 406 L<reverse|Catalyst::Action/reverse> return information for the visited action
 407 when they are invoked within the visited action.  This is different from the
 408 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 409 continues to use the $c->action object from the caller action even when
 410 invoked from the callee.
 411
 412 C<< $c->stash >> is kept unchanged.
 413
 414 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 415 allows you to "wrap" another action, just as it would have been called by
 416 dispatching from a URL, while the analogous
 417 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 418 transfer control to another action as if it had been reached directly from a URL.
 419
 420 =cut
 421
 422 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 423
 424 =head2 $c->go( $action [, \@captures, \@arguments ] )
 425
 426 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 427
 428 The relationship between C<go> and
 429 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 430 the relationship between
 431 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 432 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 433 C<< $c->go >> will perform a full dispatch on the specified action or method,
 434 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 435 C<go> escapes the processing of the current request chain on completion, and
 436 does not return to its caller.
 437
 438 @arguments are arguments to the final destination of $action. @captures are
 439 arguments to the intermediate steps, if any, on the way to the final sub of
 440 $action.
 441
 442 =cut
 443
 444 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 445
 446 =head2 $c->response
 447
 448 =head2 $c->res
 449
 450 Returns the current L<Catalyst::Response> object, see there for details.
 451
 452 =head2 $c->stash
 453
 454 Returns a hashref to the stash, which may be used to store data and pass
 455 it between components during a request. You can also set hash keys by
 456 passing arguments. The stash is automatically sent to the view. The
 457 stash is cleared at the end of a request; it cannot be used for
 458 persistent storage (for this you must use a session; see
 459 L<Catalyst::Plugin::Session> for a complete system integrated with
 460 Catalyst).
 461
 462     $c->stash->{foo} = $bar;
 463     $c->stash( { moose => 'majestic', qux => 0 } );
 464     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 465
 466     # stash is automatically passed to the view for use in a template
 467     $c->forward( 'MyApp::View::TT' );
 468
 469 =cut
 470
 471 around stash => sub {
 472     my $orig = shift;
 473     my $c = shift;
 474     my $stash = $orig->($c);
 475     if (@_) {
 476         my $new_stash = @_ > 1 ? {@_} : $_[0];
 477         croak('stash takes a hash or hashref') unless ref $new_stash;
 478         foreach my $key ( keys %$new_stash ) {
 479           $stash->{$key} = $new_stash->{$key};
 480         }
 481     }
 482
 483     return $stash;
 484 };
 485
 486
 487 =head2 $c->error
 488
 489 =head2 $c->error($error, ...)
 490
 491 =head2 $c->error($arrayref)
 492
 493 Returns an arrayref containing error messages.  If Catalyst encounters an
 494 error while processing a request, it stores the error in $c->error.  This
 495 method should only be used to store fatal error messages.
 496
 497     my @error = @{ $c->error };
 498
 499 Add a new error.
 500
 501     $c->error('Something bad happened');
 502
 503 =cut
 504
 505 sub error {
 506     my $c = shift;
 507     if ( $_[0] ) {
 508         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 509         croak @$error unless ref $c;
 510         push @{ $c->{error} }, @$error;
 511     }
 512     elsif ( defined $_[0] ) { $c->{error} = undef }
 513     return $c->{error} || [];
 514 }
 515
 516
 517 =head2 $c->state
 518
 519 Contains the return value of the last executed action.
 520 Note that << $c->state >> operates in a scalar context which means that all
 521 values it returns are scalar.
 522
 523 =head2 $c->clear_errors
 524
 525 Clear errors.  You probably don't want to clear the errors unless you are
 526 implementing a custom error screen.
 527
 528 This is equivalent to running
 529
 530     $c->error(0);
 531
 532 =cut
 533
 534 sub clear_errors {
 535     my $c = shift;
 536     $c->error(0);
 537 }
 538
 539 =head2 COMPONENT ACCESSORS
 540
 541 =head2 $c->controller($name)
 542
 543 Gets a L<Catalyst::Controller> instance by name.
 544
 545     $c->controller('Foo')->do_stuff;
 546
 547 If the name is omitted, will return the controller for the dispatched
 548 action.
 549
 550 If you want to search for controllers, pass in a regexp as the argument.
 551
 552     # find all controllers that start with Foo
 553     my @foo_controllers = $c->controller(qr{^Foo});
 554
 555
 556 =cut
 557
 558 sub controller {
 559     my ( $c, $name, @args ) = @_;
 560
 561 # FIXME: should this be a Catalyst::Utils method?
 562     if (!$name) {
 563         my $class  = $c->action->class;
 564
 565         my $prefix = length Catalyst::Utils::class2classprefix($class);
 566
 567         # MyApp::Controller::Foo becomes Foo
 568         # the + 2 is because of the ::
 569         $name = substr $class, $prefix + 2;
 570     }
 571
 572     return $c->container->get_component_from_sub_container( 'controller', $name, $c, @args);
 573 }
 574
 575 =head2 $c->model($name)
 576
 577 Gets a L<Catalyst::Model> instance by name.
 578
 579     $c->model('Foo')->do_stuff;
 580
 581 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 582
 583 If the name is omitted, it will look for
 584  - a model object in $c->stash->{current_model_instance}, then
 585  - a model name in $c->stash->{current_model}, then
 586  - a config setting 'default_model', or
 587  - check if there is only one model, and return it if that's the case.
 588
 589 If you want to search for models, pass in a regexp as the argument.
 590
 591     # find all models that start with Foo
 592     my @foo_models = $c->model(qr{^Foo});
 593
 594 =cut
 595
 596 sub model {
 597     my ( $c, $name, @args ) = @_;
 598
 599     if (ref $c && !$name) {
 600         return $c->stash->{current_model_instance}
 601             if $c->stash->{current_model_instance};
 602
 603         $name = $c->stash->{current_model}
 604             if $c->stash->{current_model};
 605     }
 606
 607     return $c->container->get_component_from_sub_container( 'model', $name, $c, @args);
 608 }
 609
 610
 611 =head2 $c->view($name)
 612
 613 Gets a L<Catalyst::View> instance by name.
 614
 615     $c->view('Foo')->do_stuff;
 616
 617 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 618
 619 If the name is omitted, it will look for
 620  - a view object in $c->stash->{current_view_instance}, then
 621  - a view name in $c->stash->{current_view}, then
 622  - a config setting 'default_view', or
 623  - check if there is only one view, and return it if that's the case.
 624
 625 If you want to search for views, pass in a regexp as the argument.
 626
 627     # find all views that start with Foo
 628     my @foo_views = $c->view(qr{^Foo});
 629
 630 =cut
 631
 632 sub view {
 633     my ( $c, $name, @args ) = @_;
 634
 635     if (ref $c && !$name) {
 636         return $c->stash->{current_view_instance}
 637             if $c->stash->{current_view_instance};
 638
 639         $name = $c->stash->{current_view}
 640             if $c->stash->{current_view};
 641     }
 642
 643     return $c->container->get_component_from_sub_container( 'view', $name, $c, @args);
 644 }
 645
 646 =head2 $c->controllers
 647
 648 Returns the available names which can be passed to $c->controller
 649
 650 =cut
 651
 652 sub controllers {
 653     my ( $c ) = @_;
 654     return $c->container->get_sub_container('controller')->get_service_list;
 655 }
 656
 657 =head2 $c->models
 658
 659 Returns the available names which can be passed to $c->model
 660
 661 =cut
 662
 663 sub models {
 664     my ( $c ) = @_;
 665     return $c->container->get_sub_container('model')->get_service_list;
 666 }
 667
 668
 669 =head2 $c->views
 670
 671 Returns the available names which can be passed to $c->view
 672
 673 =cut
 674
 675 sub views {
 676     my ( $c ) = @_;
 677     return $c->container->get_sub_container('view')->get_service_list;
 678 }
 679
 680 =head2 $c->comp($name)
 681
 682 =head2 $c->component($name)
 683
 684 Gets a component object by name. This method is not recommended,
 685 unless you want to get a specific component by full
 686 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 687 should be used instead.
 688
 689 If C<$name> is a regexp, a list of components matched against the full
 690 component name will be returned.
 691
 692 =cut
 693
 694 sub component {
 695     my ( $c, $component, @args ) = @_;
 696
 697     if ( $component ) {
 698         # FIXME: I probably shouldn't be doing this
 699         return $c->components->{$component}
 700             if exists $c->components->{$component};
 701
 702         my ($type, $name) = _get_component_type_name($component);
 703
 704         if ($type && $c->container->has_sub_container($type)) {
 705             my $container = $c->container->get_sub_container($type);
 706
 707             if( !ref $component && $container->has_service($name) ) {
 708                 return $container->get_component( $name, $c, @args );
 709             }
 710
 711             return $container->get_component_regexp( $name, $c, @args );
 712         }
 713
 714         if (ref $component) {
 715             for my $subcontainer_name (qw/model view controller/) {
 716                 my $subcontainer = $c->container->get_sub_container($subcontainer_name);
 717                 my @components   = $subcontainer->get_service_list;
 718                 my @result       = grep { m{$component} } @components;
 719
 720                 return map { $subcontainer->get_component( $_, $c, @args ) } @result;
 721             }
 722         }
 723
 724         $c->log->warn("Looking for '$component', but nothing was found.");
 725
 726         # I would expect to return an empty list here, but that breaks back-compat
 727     }
 728
 729     # fallback
 730     return sort keys %{ $c->components };
 731 }
 732
 733 =head2 CLASS DATA AND HELPER CLASSES
 734
 735 =head2 $c->config
 736
 737 Returns or takes a hashref containing the application's configuration.
 738
 739     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 740
 741 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 742 like C<myapp.conf> in your applications home directory. See
 743 L<Catalyst::Plugin::ConfigLoader>.
 744
 745 =head3 Cascading configuration
 746
 747 The config method is present on all Catalyst components, and configuration
 748 will be merged when an application is started. Configuration loaded with
 749 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 750 followed by configuration in your top level C<MyApp> class. These two
 751 configurations are merged, and then configuration data whose hash key matches a
 752 component name is merged with configuration for that component.
 753
 754 The configuration for a component is then passed to the C<new> method when a
 755 component is constructed.
 756
 757 For example:
 758
 759     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 760     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 761
 762 will mean that C<MyApp::Model::Foo> receives the following data when
 763 constructed:
 764
 765     MyApp::Model::Foo->new({
 766         bar => 'baz',
 767         quux => 'frob',
 768         overrides => 'me',
 769     });
 770
 771 It's common practice to use a Moose attribute
 772 on the receiving component to access the config value.
 773
 774     package MyApp::Model::Foo;
 775
 776     use Moose;
 777
 778     # this attr will receive 'baz' at construction time
 779     has 'bar' => (
 780         is  => 'rw',
 781         isa => 'Str',
 782     );
 783
 784 You can then get the value 'baz' by calling $c->model('Foo')->bar
 785 (or $self->bar inside code in the model).
 786
 787 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 788 as a way of reading config within your code, as this B<will not> give you the
 789 correctly merged config back. You B<MUST> take the config values supplied to
 790 the constructor and use those instead.
 791
 792 =cut
 793
 794 around config => sub {
 795     my $orig = shift;
 796     my $c = shift;
 797
 798     croak('Setting config after setup has been run is not allowed.')
 799         if ( @_ and $c->setup_finished );
 800
 801     $c->$orig(@_);
 802 };
 803
 804 =head2 $c->log
 805
 806 Returns the logging object instance. Unless it is already set, Catalyst
 807 sets this up with a L<Catalyst::Log> object. To use your own log class,
 808 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 809 C<< __PACKAGE__->setup >>.
 810
 811  __PACKAGE__->log( MyLogger->new );
 812  __PACKAGE__->setup;
 813
 814 And later:
 815
 816     $c->log->info( 'Now logging with my own logger!' );
 817
 818 Your log class should implement the methods described in
 819 L<Catalyst::Log>.
 820
 821
 822 =head2 $c->debug
 823
 824 Returns 1 if debug mode is enabled, 0 otherwise.
 825
 826 You can enable debug mode in several ways:
 827
 828 =over
 829
 830 =item By calling myapp_server.pl with the -d flag
 831
 832 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 833
 834 =item The -Debug option in your MyApp.pm
 835
 836 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 837
 838 =back
 839
 840 The first three also set the log level to 'debug'.
 841
 842 Calling C<< $c->debug(1) >> has no effect.
 843
 844 =cut
 845
 846 sub debug { 0 }
 847
 848 =head2 $c->dispatcher
 849
 850 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 851
 852 =head2 $c->engine
 853
 854 Returns the engine instance. See L<Catalyst::Engine>.
 855
 856
 857 =head2 UTILITY METHODS
 858
 859 =head2 $c->path_to(@path)
 860
 861 Merges C<@path> with C<< $c->config->{home} >> and returns a
 862 L<Path::Class::Dir> object. Note you can usually use this object as
 863 a filename, but sometimes you will have to explicitly stringify it
 864 yourself by calling the C<< ->stringify >> method.
 865
 866 For example:
 867
 868     $c->path_to( 'db', 'sqlite.db' );
 869
 870 =cut
 871
 872 sub path_to {
 873     my ( $c, @path ) = @_;
 874     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 875     if ( -d $path ) { return $path }
 876     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 877 }
 878
 879 =head2 $c->plugin( $name, $class, @args )
 880
 881 Helper method for plugins. It creates a class data accessor/mutator and
 882 loads and instantiates the given class.
 883
 884     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 885
 886     $c->prototype->define_javascript_functions;
 887
 888 B<Note:> This method of adding plugins is deprecated. The ability
 889 to add plugins like this B<will be removed> in a Catalyst 5.81.
 890 Please do not use this functionality in new code.
 891
 892 =cut
 893
 894 sub plugin {
 895     my ( $class, $name, $plugin, @args ) = @_;
 896
 897     # See block comment in t/unit_core_plugin.t
 898     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 899
 900     $class->_register_plugin( $plugin, 1 );
 901
 902     eval { $plugin->import };
 903     $class->mk_classdata($name);
 904     my $obj;
 905     eval { $obj = $plugin->new(@args) };
 906
 907     if ($@) {
 908         Catalyst::Exception->throw( message =>
 909               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 910     }
 911
 912     $class->$name($obj);
 913     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 914       if $class->debug;
 915 }
 916
 917 =head2 MyApp->setup
 918
 919 Initializes the dispatcher and engine, loads any plugins, and loads the
 920 model, view, and controller components. You may also specify an array
 921 of plugins to load here, if you choose to not load them in the C<use
 922 Catalyst> line.
 923
 924     MyApp->setup;
 925     MyApp->setup( qw/-Debug/ );
 926
 927 =cut
 928
 929 sub setup {
 930     my ( $class, @arguments ) = @_;
 931     croak('Running setup more than once')
 932         if ( $class->setup_finished );
 933
 934     unless ( $class->isa('Catalyst') ) {
 935
 936         Catalyst::Exception->throw(
 937             message => qq/'$class' does not inherit from Catalyst/ );
 938     }
 939
 940     if ( $class->arguments ) {
 941         @arguments = ( @arguments, @{ $class->arguments } );
 942     }
 943
 944     # Process options
 945     my $flags = {};
 946
 947     foreach (@arguments) {
 948
 949         if (/^-Debug$/) {
 950             $flags->{log} =
 951               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 952         }
 953         elsif (/^-(\w+)=?(.*)$/) {
 954             $flags->{ lc $1 } = $2;
 955         }
 956         else {
 957             push @{ $flags->{plugins} }, $_;
 958         }
 959     }
 960
 961     $class->setup_config();
 962     $class->setup_home( delete $flags->{home} );
 963
 964     $class->setup_log( delete $flags->{log} );
 965     $class->setup_plugins( delete $flags->{plugins} );
 966     $class->setup_dispatcher( delete $flags->{dispatcher} );
 967     $class->setup_engine( delete $flags->{engine} );
 968     $class->setup_stats( delete $flags->{stats} );
 969
 970     for my $flag ( sort keys %{$flags} ) {
 971
 972         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 973             &$code( $class, delete $flags->{$flag} );
 974         }
 975         else {
 976             $class->log->warn(qq/Unknown flag "$flag"/);
 977         }
 978     }
 979
 980     eval { require Catalyst::Devel; };
 981     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 982         $class->log->warn(<<"EOF");
 983 You are running an old script!
 984
 985   Please update by running (this will overwrite existing files):
 986     catalyst.pl -force -scripts $class
 987
 988   or (this will not overwrite existing files):
 989     catalyst.pl -scripts $class
 990
 991 EOF
 992     }
 993
 994     if ( $class->debug ) {
 995         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 996
 997         if (@plugins) {
 998             my $column_width = Catalyst::Utils::term_width() - 6;
 999             my $t = Text::SimpleTable->new($column_width);
1000             $t->row($_) for @plugins;
1001             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1002         }
1003
1004         my $dispatcher = $class->dispatcher;
1005         my $engine     = $class->engine;
1006         my $home       = $class->config->{home};
1007
1008         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1009         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1010
1011         $home
1012           ? ( -d $home )
1013           ? $class->log->debug(qq/Found home "$home"/)
1014           : $class->log->debug(qq/Home "$home" doesn't exist/)
1015           : $class->log->debug(q/Couldn't find home/);
1016     }
1017
1018     # Call plugins setup, this is stupid and evil.
1019     # Also screws C3 badly on 5.10, hack to avoid.
1020     {
1021         no warnings qw/redefine/;
1022         local *setup = sub { };
1023         $class->setup unless $Catalyst::__AM_RESTARTING;
1024     }
1025
1026     # Initialize our data structure
1027     $class->components( {} );
1028
1029     $class->setup_components;
1030
1031     if ( $class->debug ) {
1032         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1033         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1034         for my $comp ( sort keys %{ $class->components } ) {
1035             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1036             $t->row( $comp, $type );
1037         }
1038         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1039           if ( keys %{ $class->components } );
1040     }
1041
1042     # Add our self to components, since we are also a component
1043     if( $class->isa('Catalyst::Controller') ){
1044       $class->components->{$class} = $class;
1045     }
1046
1047     $class->setup_actions;
1048
1049     if ( $class->debug ) {
1050         my $name = $class->config->{name} || 'Application';
1051         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1052     }
1053
1054     # Make sure that the application class becomes immutable at this point,
1055     B::Hooks::EndOfScope::on_scope_end {
1056         return if $@;
1057         my $meta = Class::MOP::get_metaclass_by_name($class);
1058         if (
1059             $meta->is_immutable
1060             && ! { $meta->immutable_options }->{replace_constructor}
1061             && (
1062                    $class->isa('Class::Accessor::Fast')
1063                 || $class->isa('Class::Accessor')
1064             )
1065         ) {
1066             warn "You made your application class ($class) immutable, "
1067                 . "but did not inline the\nconstructor. "
1068                 . "This will break catalyst, as your app \@ISA "
1069                 . "Class::Accessor(::Fast)?\nPlease pass "
1070                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1071         }
1072         $meta->make_immutable(
1073             replace_constructor => 1,
1074         ) unless $meta->is_immutable;
1075     };
1076
1077     if ($class->config->{case_sensitive}) {
1078         $class->log->warn($class . "->config->{case_sensitive} is set.");
1079         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1080     }
1081
1082     $class->setup_finalize;
1083     # Should be the last thing we do so that user things hooking
1084     # setup_finalize can log..
1085     $class->log->_flush() if $class->log->can('_flush');
1086     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1087 }
1088
1089 =head2 $app->setup_finalize
1090
1091 A hook to attach modifiers to. This method does not do anything except set the
1092 C<setup_finished> accessor.
1093
1094 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1095
1096 Example:
1097
1098     after setup_finalize => sub {
1099         my $app = shift;
1100
1101         ## do stuff here..
1102     };
1103
1104 =cut
1105
1106 sub setup_finalize {
1107     my ($class) = @_;
1108     $class->setup_finished(1);
1109 }
1110
1111 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1112
1113 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1114
1115 Constructs an absolute L<URI> object based on the application root, the
1116 provided path, and the additional arguments and query parameters provided.
1117 When used as a string, provides a textual URI.  If you need more flexibility
1118 than this (i.e. the option to provide relative URIs etc.) see
1119 L<Catalyst::Plugin::SmartURI>.
1120
1121 If no arguments are provided, the URI for the current action is returned.
1122 To return the current action and also provide @args, use
1123 C<< $c->uri_for( $c->action, @args ) >>.
1124
1125 If the first argument is a string, it is taken as a public URI path relative
1126 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1127 relative to the application root (if it does). It is then merged with
1128 C<< $c->request->base >>; any C<@args> are appended as additional path
1129 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1130
1131 If the first argument is a L<Catalyst::Action> it represents an action which
1132 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1133 optional C<\@captures> argument (an arrayref) allows passing the captured
1134 variables that are needed to fill in the paths of Chained and Regex actions;
1135 once the path is resolved, C<uri_for> continues as though a path was
1136 provided, appending any arguments or parameters and creating an absolute
1137 URI.
1138
1139 The captures for the current request can be found in
1140 C<< $c->request->captures >>, and actions can be resolved using
1141 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1142 path, use C<< $c->uri_for_action >> instead.
1143
1144   # Equivalent to $c->req->uri
1145   $c->uri_for($c->action, $c->req->captures,
1146       @{ $c->req->args }, $c->req->params);
1147
1148   # For the Foo action in the Bar controller
1149   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1150
1151   # Path to a static resource
1152   $c->uri_for('/static/images/logo.png');
1153
1154 =cut
1155
1156 sub uri_for {
1157     my ( $c, $path, @args ) = @_;
1158
1159     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1160         $path = $path->path_prefix;
1161         $path =~ s{/+\z}{};
1162         $path .= '/';
1163     }
1164
1165     undef($path) if (defined $path && $path eq '');
1166
1167     my $params =
1168       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1169
1170     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1171     foreach my $arg (@args) {
1172         utf8::encode($arg) if utf8::is_utf8($arg);
1173         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1174     }
1175
1176     if ( blessed($path) ) { # action object
1177         s|/|%2F|g for @args;
1178         my $captures = [ map { s|/|%2F|g; $_; }
1179                         ( scalar @args && ref $args[0] eq 'ARRAY'
1180                          ? @{ shift(@args) }
1181                          : ()) ];
1182
1183         foreach my $capture (@$captures) {
1184             utf8::encode($capture) if utf8::is_utf8($capture);
1185             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1186         }
1187
1188         my $action = $path;
1189         $path = $c->dispatcher->uri_for_action($action, $captures);
1190         if (not defined $path) {
1191             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1192                 if $c->debug;
1193             return undef;
1194         }
1195         $path = '/' if $path eq '';
1196     }
1197
1198     unshift(@args, $path);
1199
1200     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1201         my $namespace = $c->namespace;
1202         if (defined $path) { # cheesy hack to handle path '../foo'
1203            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1204         }
1205         unshift(@args, $namespace || '');
1206     }
1207
1208     # join args with '/', or a blank string
1209     my $args = join('/', grep { defined($_) } @args);
1210     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1211     $args =~ s!^/+!!;
1212     my $base = $c->req->base;
1213     my $class = ref($base);
1214     $base =~ s{(?<!/)$}{/};
1215
1216     my $query = '';
1217
1218     if (my @keys = keys %$params) {
1219       # somewhat lifted from URI::_query's query_form
1220       $query = '?'.join('&', map {
1221           my $val = $params->{$_};
1222           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1223           s/ /+/g;
1224           my $key = $_;
1225           $val = '' unless defined $val;
1226           (map {
1227               my $param = "$_";
1228               utf8::encode( $param ) if utf8::is_utf8($param);
1229               # using the URI::Escape pattern here so utf8 chars survive
1230               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1231               $param =~ s/ /+/g;
1232               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1233       } @keys);
1234     }
1235
1236     my $res = bless(\"${base}${args}${query}", $class);
1237     $res;
1238 }
1239
1240 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1241
1242 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1243
1244 =over
1245
1246 =item $path
1247
1248 A private path to the Catalyst action you want to create a URI for.
1249
1250 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1251 >> and passing the resulting C<$action> and the remaining arguments to C<<
1252 $c->uri_for >>.
1253
1254 You can also pass in a Catalyst::Action object, in which case it is passed to
1255 C<< $c->uri_for >>.
1256
1257 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1258
1259 For example, if the action looks like:
1260
1261  package MyApp::Controller::Users;
1262
1263  sub lst : Path('the-list') {}
1264
1265 You can use:
1266
1267  $c->uri_for_action('/users/lst')
1268
1269 and it will create the URI /users/the-list.
1270
1271 =back
1272
1273 =cut
1274
1275 sub uri_for_action {
1276     my ( $c, $path, @args ) = @_;
1277     my $action = blessed($path)
1278       ? $path
1279       : $c->dispatcher->get_action_by_path($path);
1280     unless (defined $action) {
1281       croak "Can't find action for path '$path'";
1282     }
1283     return $c->uri_for( $action, @args );
1284 }
1285
1286 =head2 $c->welcome_message
1287
1288 Returns the Catalyst welcome HTML page.
1289
1290 =cut
1291
1292 sub welcome_message {
1293     my $c      = shift;
1294     my $name   = $c->config->{name};
1295     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1296     my $prefix = Catalyst::Utils::appprefix( ref $c );
1297     $c->response->content_type('text/html; charset=utf-8');
1298     return <<"EOF";
1299 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1300     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1301 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1302     <head>
1303     <meta http-equiv="Content-Language" content="en" />
1304     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1305         <title>$name on Catalyst $VERSION</title>
1306         <style type="text/css">
1307             body {
1308                 color: #000;
1309                 background-color: #eee;
1310             }
1311             div#content {
1312                 width: 640px;
1313                 margin-left: auto;
1314                 margin-right: auto;
1315                 margin-top: 10px;
1316                 margin-bottom: 10px;
1317                 text-align: left;
1318                 background-color: #ccc;
1319                 border: 1px solid #aaa;
1320             }
1321             p, h1, h2 {
1322                 margin-left: 20px;
1323                 margin-right: 20px;
1324                 font-family: verdana, tahoma, sans-serif;
1325             }
1326             a {
1327                 font-family: verdana, tahoma, sans-serif;
1328             }
1329             :link, :visited {
1330                     text-decoration: none;
1331                     color: #b00;
1332                     border-bottom: 1px dotted #bbb;
1333             }
1334             :link:hover, :visited:hover {
1335                     color: #555;
1336             }
1337             div#topbar {
1338                 margin: 0px;
1339             }
1340             pre {
1341                 margin: 10px;
1342                 padding: 8px;
1343             }
1344             div#answers {
1345                 padding: 8px;
1346                 margin: 10px;
1347                 background-color: #fff;
1348                 border: 1px solid #aaa;
1349             }
1350             h1 {
1351                 font-size: 0.9em;
1352                 font-weight: normal;
1353                 text-align: center;
1354             }
1355             h2 {
1356                 font-size: 1.0em;
1357             }
1358             p {
1359                 font-size: 0.9em;
1360             }
1361             p img {
1362                 float: right;
1363                 margin-left: 10px;
1364             }
1365             span#appname {
1366                 font-weight: bold;
1367                 font-size: 1.6em;
1368             }
1369         </style>
1370     </head>
1371     <body>
1372         <div id="content">
1373             <div id="topbar">
1374                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1375                     $VERSION</h1>
1376              </div>
1377              <div id="answers">
1378                  <p>
1379                  <img src="$logo" alt="Catalyst Logo" />
1380                  </p>
1381                  <p>Welcome to the  world of Catalyst.
1382                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1383                     framework will make web development something you had
1384                     never expected it to be: Fun, rewarding, and quick.</p>
1385                  <h2>What to do now?</h2>
1386                  <p>That really depends  on what <b>you</b> want to do.
1387                     We do, however, provide you with a few starting points.</p>
1388                  <p>If you want to jump right into web development with Catalyst
1389                     you might want to start with a tutorial.</p>
1390 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1391 </pre>
1392 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1393 <pre>
1394 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1395 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1396 </code></pre>
1397                  <h2>What to do next?</h2>
1398                  <p>Next it's time to write an actual application. Use the
1399                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1400                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1401                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1402                     they can save you a lot of work.</p>
1403                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1404                     <p>Also, be sure to check out the vast and growing
1405                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1406                     you are likely to find what you need there.
1407                     </p>
1408
1409                  <h2>Need help?</h2>
1410                  <p>Catalyst has a very active community. Here are the main places to
1411                     get in touch with us.</p>
1412                  <ul>
1413                      <li>
1414                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1415                      </li>
1416                      <li>
1417                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1418                      </li>
1419                      <li>
1420                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1421                      </li>
1422                  </ul>
1423                  <h2>In conclusion</h2>
1424                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1425                     as we enjoyed making it. Please contact us if you have ideas
1426                     for improvement or other feedback.</p>
1427              </div>
1428          </div>
1429     </body>
1430 </html>
1431 EOF
1432 }
1433
1434 =head1 INTERNAL METHODS
1435
1436 These methods are not meant to be used by end users.
1437
1438 =head2 $c->components
1439
1440 Returns a hash of components.
1441
1442 =cut
1443
1444 around components => sub {
1445     my $orig  = shift;
1446     my $class = shift;
1447     my $comps = shift;
1448
1449     return $class->$orig if ( !$comps );
1450
1451 # FIXME: should this ugly kludge exist?
1452     $class->setup_config unless defined $class->container;
1453
1454 # FIXME: should there be a warning here, not to use this accessor to create the components?
1455     my $components = {};
1456
1457     my $containers;
1458     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
1459
1460     for my $component ( keys %$comps ) {
1461         $components->{ $component } = $comps->{$component};
1462
1463         my ($type, $name) = _get_component_type_name($component);
1464
1465         $containers->{$type}->add_service(Catalyst::IOC::BlockInjection->new( name => $name, block => sub { return $class->setup_component($component) } ));
1466     }
1467
1468     return $class->$orig($components);
1469 };
1470
1471 =head2 $c->context_class
1472
1473 Returns or sets the context class.
1474
1475 =head2 $c->counter
1476
1477 Returns a hashref containing coderefs and execution counts (needed for
1478 deep recursion detection).
1479
1480 =head2 $c->depth
1481
1482 Returns the number of actions on the current internal execution stack.
1483
1484 =head2 $c->dispatch
1485
1486 Dispatches a request to actions.
1487
1488 =cut
1489
1490 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1491
1492 =head2 $c->dispatcher_class
1493
1494 Returns or sets the dispatcher class.
1495
1496 =head2 $c->dump_these
1497
1498 Returns a list of 2-element array references (name, structure) pairs
1499 that will be dumped on the error page in debug mode.
1500
1501 =cut
1502
1503 sub dump_these {
1504     my $c = shift;
1505     [ Request => $c->req ],
1506     [ Response => $c->res ],
1507     [ Stash => $c->stash ],
1508     [ Config => $c->config ];
1509 }
1510
1511 =head2 $c->engine_class
1512
1513 Returns or sets the engine class.
1514
1515 =head2 $c->execute( $class, $coderef )
1516
1517 Execute a coderef in given class and catch exceptions. Errors are available
1518 via $c->error.
1519
1520 =cut
1521
1522 sub execute {
1523     my ( $c, $class, $code ) = @_;
1524     $class = $c->component($class) || $class;
1525     $c->state(0);
1526
1527     if ( $c->depth >= $RECURSION ) {
1528         my $action = $code->reverse();
1529         $action = "/$action" unless $action =~ /->/;
1530         my $error = qq/Deep recursion detected calling "${action}"/;
1531         $c->log->error($error);
1532         $c->error($error);
1533         $c->state(0);
1534         return $c->state;
1535     }
1536
1537     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1538
1539     push( @{ $c->stack }, $code );
1540
1541     no warnings 'recursion';
1542     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1543     #      I have no idea how, ergo $ret (which appears to fix the issue)
1544     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1545
1546     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1547
1548     my $last = pop( @{ $c->stack } );
1549
1550     if ( my $error = $@ ) {
1551         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1552             $error->rethrow if $c->depth > 1;
1553         }
1554         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1555             $error->rethrow if $c->depth > 0;
1556         }
1557         else {
1558             unless ( ref $error ) {
1559                 no warnings 'uninitialized';
1560                 chomp $error;
1561                 my $class = $last->class;
1562                 my $name  = $last->name;
1563                 $error = qq/Caught exception in $class->$name "$error"/;
1564             }
1565             $c->error($error);
1566         }
1567         $c->state(0);
1568     }
1569     return $c->state;
1570 }
1571
1572 sub _stats_start_execute {
1573     my ( $c, $code ) = @_;
1574     my $appclass = ref($c) || $c;
1575     return if ( ( $code->name =~ /^_.*/ )
1576         && ( !$appclass->config->{show_internal_actions} ) );
1577
1578     my $action_name = $code->reverse();
1579     $c->counter->{$action_name}++;
1580
1581     my $action = $action_name;
1582     $action = "/$action" unless $action =~ /->/;
1583
1584     # determine if the call was the result of a forward
1585     # this is done by walking up the call stack and looking for a calling
1586     # sub of Catalyst::forward before the eval
1587     my $callsub = q{};
1588     for my $index ( 2 .. 11 ) {
1589         last
1590         if ( ( caller($index) )[0] eq 'Catalyst'
1591             && ( caller($index) )[3] eq '(eval)' );
1592
1593         if ( ( caller($index) )[3] =~ /forward$/ ) {
1594             $callsub = ( caller($index) )[3];
1595             $action  = "-> $action";
1596             last;
1597         }
1598     }
1599
1600     my $uid = $action_name . $c->counter->{$action_name};
1601
1602     # is this a root-level call or a forwarded call?
1603     if ( $callsub =~ /forward$/ ) {
1604         my $parent = $c->stack->[-1];
1605
1606         # forward, locate the caller
1607         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1608             $c->stats->profile(
1609                 begin  => $action,
1610                 parent => "$parent" . $c->counter->{"$parent"},
1611                 uid    => $uid,
1612             );
1613         }
1614         else {
1615
1616             # forward with no caller may come from a plugin
1617             $c->stats->profile(
1618                 begin => $action,
1619                 uid   => $uid,
1620             );
1621         }
1622     }
1623     else {
1624
1625         # root-level call
1626         $c->stats->profile(
1627             begin => $action,
1628             uid   => $uid,
1629         );
1630     }
1631     return $action;
1632
1633 }
1634
1635 sub _stats_finish_execute {
1636     my ( $c, $info ) = @_;
1637     $c->stats->profile( end => $info );
1638 }
1639
1640 =head2 $c->finalize
1641
1642 Finalizes the request.
1643
1644 =cut
1645
1646 sub finalize {
1647     my $c = shift;
1648
1649     for my $error ( @{ $c->error } ) {
1650         $c->log->error($error);
1651     }
1652
1653     # Allow engine to handle finalize flow (for POE)
1654     my $engine = $c->engine;
1655     if ( my $code = $engine->can('finalize') ) {
1656         $engine->$code($c);
1657     }
1658     else {
1659
1660         $c->finalize_uploads;
1661
1662         # Error
1663         if ( $#{ $c->error } >= 0 ) {
1664             $c->finalize_error;
1665         }
1666
1667         $c->finalize_headers;
1668
1669         # HEAD request
1670         if ( $c->request->method eq 'HEAD' ) {
1671             $c->response->body('');
1672         }
1673
1674         $c->finalize_body;
1675     }
1676
1677     $c->log_response;
1678
1679     if ($c->use_stats) {
1680         my $elapsed = sprintf '%f', $c->stats->elapsed;
1681         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1682         $c->log->info(
1683             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1684     }
1685
1686     return $c->response->status;
1687 }
1688
1689 =head2 $c->finalize_body
1690
1691 Finalizes body.
1692
1693 =cut
1694
1695 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1696
1697 =head2 $c->finalize_cookies
1698
1699 Finalizes cookies.
1700
1701 =cut
1702
1703 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1704
1705 =head2 $c->finalize_error
1706
1707 Finalizes error.
1708
1709 =cut
1710
1711 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1712
1713 =head2 $c->finalize_headers
1714
1715 Finalizes headers.
1716
1717 =cut
1718
1719 sub finalize_headers {
1720     my $c = shift;
1721
1722     my $response = $c->response; #accessor calls can add up?
1723
1724     # Check if we already finalized headers
1725     return if $response->finalized_headers;
1726
1727     # Handle redirects
1728     if ( my $location = $response->redirect ) {
1729         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1730         $response->header( Location => $location );
1731
1732         if ( !$response->has_body ) {
1733             # Add a default body if none is already present
1734             $response->body(
1735                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1736             );
1737         }
1738     }
1739
1740     # Content-Length
1741     if ( defined $response->body && length $response->body && !$response->content_length ) {
1742
1743         # get the length from a filehandle
1744         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1745         {
1746             my $stat = stat $response->body;
1747             if ( $stat && $stat->size > 0 ) {
1748                 $response->content_length( $stat->size );
1749             }
1750             else {
1751                 $c->log->warn('Serving filehandle without a content-length');
1752             }
1753         }
1754         else {
1755             # everything should be bytes at this point, but just in case
1756             $response->content_length( length( $response->body ) );
1757         }
1758     }
1759
1760     # Errors
1761     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1762         $response->headers->remove_header("Content-Length");
1763         $response->body('');
1764     }
1765
1766     $c->finalize_cookies;
1767
1768     $c->engine->finalize_headers( $c, @_ );
1769
1770     # Done
1771     $response->finalized_headers(1);
1772 }
1773
1774 =head2 $c->finalize_output
1775
1776 An alias for finalize_body.
1777
1778 =head2 $c->finalize_read
1779
1780 Finalizes the input after reading is complete.
1781
1782 =cut
1783
1784 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1785
1786 =head2 $c->finalize_uploads
1787
1788 Finalizes uploads. Cleans up any temporary files.
1789
1790 =cut
1791
1792 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1793
1794 =head2 $c->get_action( $action, $namespace )
1795
1796 Gets an action in a given namespace.
1797
1798 =cut
1799
1800 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1801
1802 =head2 $c->get_actions( $action, $namespace )
1803
1804 Gets all actions of a given name in a namespace and all parent
1805 namespaces.
1806
1807 =cut
1808
1809 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1810
1811 =head2 $app->handle_request( @arguments )
1812
1813 Called to handle each HTTP request.
1814
1815 =cut
1816
1817 sub handle_request {
1818     my ( $class, @arguments ) = @_;
1819
1820     # Always expect worst case!
1821     my $status = -1;
1822     eval {
1823         if ($class->debug) {
1824             my $secs = time - $START || 1;
1825             my $av = sprintf '%.3f', $COUNT / $secs;
1826             my $time = localtime time;
1827             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1828         }
1829
1830         my $c = $class->prepare(@arguments);
1831         $c->dispatch;
1832         $status = $c->finalize;
1833     };
1834
1835     if ( my $error = $@ ) {
1836         chomp $error;
1837         $class->log->error(qq/Caught exception in engine "$error"/);
1838     }
1839
1840     $COUNT++;
1841
1842     if(my $coderef = $class->log->can('_flush')){
1843         $class->log->$coderef();
1844     }
1845     return $status;
1846 }
1847
1848 =head2 $c->prepare( @arguments )
1849
1850 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1851 etc.).
1852
1853 =cut
1854
1855 sub prepare {
1856     my ( $class, @arguments ) = @_;
1857
1858     # XXX
1859     # After the app/ctxt split, this should become an attribute based on something passed
1860     # into the application.
1861     $class->context_class( ref $class || $class ) unless $class->context_class;
1862
1863     my $c = $class->context_class->new({});
1864
1865     # For on-demand data
1866     $c->request->_context($c);
1867     $c->response->_context($c);
1868
1869     #surely this is not the most efficient way to do things...
1870     $c->stats($class->stats_class->new)->enable($c->use_stats);
1871     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1872         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1873     }
1874
1875     #XXX reuse coderef from can
1876     # Allow engine to direct the prepare flow (for POE)
1877     if ( $c->engine->can('prepare') ) {
1878         $c->engine->prepare( $c, @arguments );
1879     }
1880     else {
1881         $c->prepare_request(@arguments);
1882         $c->prepare_connection;
1883         $c->prepare_query_parameters;
1884         $c->prepare_headers;
1885         $c->prepare_cookies;
1886         $c->prepare_path;
1887
1888         # Prepare the body for reading, either by prepare_body
1889         # or the user, if they are using $c->read
1890         $c->prepare_read;
1891
1892         # Parse the body unless the user wants it on-demand
1893         unless ( ref($c)->config->{parse_on_demand} ) {
1894             $c->prepare_body;
1895         }
1896     }
1897
1898     my $method  = $c->req->method  || '';
1899     my $path    = $c->req->path;
1900     $path       = '/' unless length $path;
1901     my $address = $c->req->address || '';
1902
1903     $c->log_request;
1904
1905     $c->prepare_action;
1906
1907     return $c;
1908 }
1909
1910 =head2 $c->prepare_action
1911
1912 Prepares action. See L<Catalyst::Dispatcher>.
1913
1914 =cut
1915
1916 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1917
1918 =head2 $c->prepare_body
1919
1920 Prepares message body.
1921
1922 =cut
1923
1924 sub prepare_body {
1925     my $c = shift;
1926
1927     return if $c->request->_has_body;
1928
1929     # Initialize on-demand data
1930     $c->engine->prepare_body( $c, @_ );
1931     $c->prepare_parameters;
1932     $c->prepare_uploads;
1933 }
1934
1935 =head2 $c->prepare_body_chunk( $chunk )
1936
1937 Prepares a chunk of data before sending it to L<HTTP::Body>.
1938
1939 See L<Catalyst::Engine>.
1940
1941 =cut
1942
1943 sub prepare_body_chunk {
1944     my $c = shift;
1945     $c->engine->prepare_body_chunk( $c, @_ );
1946 }
1947
1948 =head2 $c->prepare_body_parameters
1949
1950 Prepares body parameters.
1951
1952 =cut
1953
1954 sub prepare_body_parameters {
1955     my $c = shift;
1956     $c->engine->prepare_body_parameters( $c, @_ );
1957 }
1958
1959 =head2 $c->prepare_connection
1960
1961 Prepares connection.
1962
1963 =cut
1964
1965 sub prepare_connection {
1966     my $c = shift;
1967     $c->engine->prepare_connection( $c, @_ );
1968 }
1969
1970 =head2 $c->prepare_cookies
1971
1972 Prepares cookies.
1973
1974 =cut
1975
1976 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1977
1978 =head2 $c->prepare_headers
1979
1980 Prepares headers.
1981
1982 =cut
1983
1984 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1985
1986 =head2 $c->prepare_parameters
1987
1988 Prepares parameters.
1989
1990 =cut
1991
1992 sub prepare_parameters {
1993     my $c = shift;
1994     $c->prepare_body_parameters;
1995     $c->engine->prepare_parameters( $c, @_ );
1996 }
1997
1998 =head2 $c->prepare_path
1999
2000 Prepares path and base.
2001
2002 =cut
2003
2004 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2005
2006 =head2 $c->prepare_query_parameters
2007
2008 Prepares query parameters.
2009
2010 =cut
2011
2012 sub prepare_query_parameters {
2013     my $c = shift;
2014
2015     $c->engine->prepare_query_parameters( $c, @_ );
2016 }
2017
2018 =head2 $c->log_request
2019
2020 Writes information about the request to the debug logs.  This includes:
2021
2022 =over 4
2023
2024 =item * Request method, path, and remote IP address
2025
2026 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2027
2028 =item * Request parameters
2029
2030 =item * File uploads
2031
2032 =back
2033
2034 =cut
2035
2036 sub log_request {
2037     my $c = shift;
2038
2039     return unless $c->debug;
2040
2041     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2042     my $request = $dump->[1];
2043
2044     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2045     $method ||= '';
2046     $path = '/' unless length $path;
2047     $address ||= '';
2048     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2049
2050     $c->log_request_headers($request->headers);
2051
2052     if ( my $keywords = $request->query_keywords ) {
2053         $c->log->debug("Query keywords are: $keywords");
2054     }
2055
2056     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2057
2058     $c->log_request_uploads($request);
2059 }
2060
2061 =head2 $c->log_response
2062
2063 Writes information about the response to the debug logs by calling
2064 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2065
2066 =cut
2067
2068 sub log_response {
2069     my $c = shift;
2070
2071     return unless $c->debug;
2072
2073     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2074     my $response = $dump->[1];
2075
2076     $c->log_response_status_line($response);
2077     $c->log_response_headers($response->headers);
2078 }
2079
2080 =head2 $c->log_response_status_line($response)
2081
2082 Writes one line of information about the response to the debug logs.  This includes:
2083
2084 =over 4
2085
2086 =item * Response status code
2087
2088 =item * Content-Type header (if present)
2089
2090 =item * Content-Length header (if present)
2091
2092 =back
2093
2094 =cut
2095
2096 sub log_response_status_line {
2097     my ($c, $response) = @_;
2098
2099     $c->log->debug(
2100         sprintf(
2101             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2102             $response->status                            || 'unknown',
2103             $response->headers->header('Content-Type')   || 'unknown',
2104             $response->headers->header('Content-Length') || 'unknown'
2105         )
2106     );
2107 }
2108
2109 =head2 $c->log_response_headers($headers);
2110
2111 Hook method which can be wrapped by plugins to log the responseheaders.
2112 No-op in the default implementation.
2113
2114 =cut
2115
2116 sub log_response_headers {}
2117
2118 =head2 $c->log_request_parameters( query => {}, body => {} )
2119
2120 Logs request parameters to debug logs
2121
2122 =cut
2123
2124 sub log_request_parameters {
2125     my $c          = shift;
2126     my %all_params = @_;
2127
2128     return unless $c->debug;
2129
2130     my $column_width = Catalyst::Utils::term_width() - 44;
2131     foreach my $type (qw(query body)) {
2132         my $params = $all_params{$type};
2133         next if ! keys %$params;
2134         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2135         for my $key ( sort keys %$params ) {
2136             my $param = $params->{$key};
2137             my $value = defined($param) ? $param : '';
2138             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2139         }
2140         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2141     }
2142 }
2143
2144 =head2 $c->log_request_uploads
2145
2146 Logs file uploads included in the request to the debug logs.
2147 The parameter name, filename, file type, and file size are all included in
2148 the debug logs.
2149
2150 =cut
2151
2152 sub log_request_uploads {
2153     my $c = shift;
2154     my $request = shift;
2155     return unless $c->debug;
2156     my $uploads = $request->uploads;
2157     if ( keys %$uploads ) {
2158         my $t = Text::SimpleTable->new(
2159             [ 12, 'Parameter' ],
2160             [ 26, 'Filename' ],
2161             [ 18, 'Type' ],
2162             [ 9,  'Size' ]
2163         );
2164         for my $key ( sort keys %$uploads ) {
2165             my $upload = $uploads->{$key};
2166             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2167                 $t->row( $key, $u->filename, $u->type, $u->size );
2168             }
2169         }
2170         $c->log->debug( "File Uploads are:\n" . $t->draw );
2171     }
2172 }
2173
2174 =head2 $c->log_request_headers($headers);
2175
2176 Hook method which can be wrapped by plugins to log the request headers.
2177 No-op in the default implementation.
2178
2179 =cut
2180
2181 sub log_request_headers {}
2182
2183 =head2 $c->log_headers($type => $headers)
2184
2185 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2186
2187 =cut
2188
2189 sub log_headers {
2190     my $c       = shift;
2191     my $type    = shift;
2192     my $headers = shift;    # an HTTP::Headers instance
2193
2194     return unless $c->debug;
2195
2196     my $column_width = Catalyst::Utils::term_width() - 28;
2197     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2198     $headers->scan(
2199         sub {
2200             my ( $name, $value ) = @_;
2201             $t->row( $name, $value );
2202         }
2203     );
2204     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2205 }
2206
2207
2208 =head2 $c->prepare_read
2209
2210 Prepares the input for reading.
2211
2212 =cut
2213
2214 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2215
2216 =head2 $c->prepare_request
2217
2218 Prepares the engine request.
2219
2220 =cut
2221
2222 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2223
2224 =head2 $c->prepare_uploads
2225
2226 Prepares uploads.
2227
2228 =cut
2229
2230 sub prepare_uploads {
2231     my $c = shift;
2232
2233     $c->engine->prepare_uploads( $c, @_ );
2234 }
2235
2236 =head2 $c->prepare_write
2237
2238 Prepares the output for writing.
2239
2240 =cut
2241
2242 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2243
2244 =head2 $c->request_class
2245
2246 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2247
2248 =head2 $c->response_class
2249
2250 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2251
2252 =head2 $c->read( [$maxlength] )
2253
2254 Reads a chunk of data from the request body. This method is designed to
2255 be used in a while loop, reading C<$maxlength> bytes on every call.
2256 C<$maxlength> defaults to the size of the request if not specified.
2257
2258 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2259 directly.
2260
2261 Warning: If you use read(), Catalyst will not process the body,
2262 so you will not be able to access POST parameters or file uploads via
2263 $c->request.  You must handle all body parsing yourself.
2264
2265 =cut
2266
2267 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2268
2269 =head2 $c->run
2270
2271 Starts the engine.
2272
2273 =cut
2274
2275 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2276
2277 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2278
2279 Sets an action in a given namespace.
2280
2281 =cut
2282
2283 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2284
2285 =head2 $c->setup_actions($component)
2286
2287 Sets up actions for a component.
2288
2289 =cut
2290
2291 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2292
2293 =head2 $c->setup_config
2294
2295 =cut
2296
2297 sub setup_config {
2298     my $class = shift;
2299
2300     my %args = %{ $class->config || {} };
2301
2302     my @container_classes = ( "${class}::Container", 'Catalyst::IOC::Container');
2303     unshift @container_classes, delete $args{container_class} if exists $args{container_class};
2304
2305     my $container_class = Class::MOP::load_first_existing_class(@container_classes);
2306
2307     my $container = $container_class->new( %args, name => "$class" );
2308     $class->container($container);
2309
2310     my $config = $container->resolve(service => 'config');
2311     $class->config($config);
2312     $class->finalize_config; # back-compat
2313 }
2314
2315 =head2 $c->finalize_config
2316
2317 =cut
2318
2319 sub finalize_config { }
2320
2321 =head2 $c->setup_components
2322
2323 This method is called internally to set up the application's components.
2324
2325 It finds modules by calling the L<locate_components> method, expands them to
2326 package names with the L<expand_component_module> method, and then installs
2327 each component into the application.
2328
2329 The C<setup_components> config option is passed to both of the above methods.
2330
2331 Installation of each component is performed by the L<setup_component> method,
2332 below.
2333
2334 =cut
2335
2336 sub setup_components {
2337     my $class = shift;
2338
2339     my $config  = $class->config->{ setup_components };
2340
2341     my @comps = $class->locate_components($config);
2342     my %comps = map { $_ => 1 } @comps;
2343
2344     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2345     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2346         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2347     ) if $deprecatedcatalyst_component_names;
2348
2349     for my $component ( @comps ) {
2350
2351         # We pass ignore_loaded here so that overlay files for (e.g.)
2352         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2353         # we know M::P::O found a file on disk so this is safe
2354
2355         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2356     }
2357
2358     my $containers;
2359     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
2360
2361     for my $component (@comps) {
2362         my $instance = $class->components->{ $component } = $class->setup_component($component);
2363         if ( my ($type, $name) = _get_component_type_name($component) ) {
2364             $containers->{$type}->add_service(Catalyst::IOC::BlockInjection->new( name => $name, block => sub { return $instance } ));
2365         }
2366         my @expanded_components = $instance->can('expand_modules')
2367             ? $instance->expand_modules( $component, $config )
2368             : $class->expand_component_module( $component, $config );
2369         for my $component (@expanded_components) {
2370             next if $comps{$component};
2371
2372             $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @expanded_components;
2373             $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2374                 qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2375             ) if $deprecatedcatalyst_component_names;
2376
2377             if (my ($type, $name) = _get_component_type_name($component)) {
2378                 $containers->{$type}->add_service(Catalyst::IOC::BlockInjection->new( name => $name, block => sub { return $class->setup_component($component) } ));
2379             }
2380
2381             $class->components->{ $component } = $class->setup_component($component);
2382         }
2383     }
2384
2385     $containers->{model}->make_single_default;
2386     $containers->{view}->make_single_default;
2387 }
2388
2389 sub _get_component_type_name {
2390     my $component = shift;
2391     my @parts     = split /::/, $component;
2392
2393     while (my $type = shift @parts) {
2394         return ('controller', join '::', @parts)
2395             if $type =~ /^(c|controller)$/i;
2396
2397         return ('model', join '::', @parts)
2398             if $type =~ /^(m|model)$/i;
2399
2400         return ('view', join '::', @parts)
2401             if $type =~ /^(v|view)$/i;
2402     }
2403 }
2404
2405 =head2 $c->locate_components( $setup_component_config )
2406
2407 This method is meant to provide a list of component modules that should be
2408 setup for the application.  By default, it will use L<Module::Pluggable>.
2409
2410 Specify a C<setup_components> config option to pass additional options directly
2411 to L<Module::Pluggable>. To add additional search paths, specify a key named
2412 C<search_extra> as an array reference. Items in the array beginning with C<::>
2413 will have the application class name prepended to them.
2414
2415 =cut
2416
2417 sub locate_components {
2418     my $class  = shift;
2419     my $config = shift;
2420
2421     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2422     my $extra   = delete $config->{ search_extra } || [];
2423
2424     push @paths, @$extra;
2425
2426     my $locator = Module::Pluggable::Object->new(
2427         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2428         %$config
2429     );
2430
2431     # XXX think about ditching this sort entirely
2432     my @comps = sort { length $a <=> length $b } $locator->plugins;
2433
2434     return @comps;
2435 }
2436
2437 =head2 $c->expand_component_module( $component, $setup_component_config )
2438
2439 Components found by C<locate_components> will be passed to this method, which
2440 is expected to return a list of component (package) names to be set up.
2441
2442 =cut
2443
2444 sub expand_component_module {
2445     my ($class, $module) = @_;
2446     return Devel::InnerPackage::list_packages( $module );
2447 }
2448
2449 =head2 $c->setup_component
2450
2451 =cut
2452
2453 sub setup_component {
2454     my( $class, $component ) = @_;
2455
2456     unless ( $component->can( 'COMPONENT' ) ) {
2457         return $component;
2458     }
2459
2460     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2461     my $config = $class->config->{ $suffix } || {};
2462     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2463     # methods also pass it. local to avoid pointlessly shitting in config
2464     # for the debug screen, as $component is already the key name.
2465     local $config->{catalyst_component_name} = $component;
2466
2467     my $instance = eval { $component->COMPONENT( $class, $config ); };
2468
2469     if ( my $error = $@ ) {
2470         chomp $error;
2471         Catalyst::Exception->throw(
2472             message => qq/Couldn't instantiate component "$component", "$error"/
2473         );
2474     }
2475     elsif (!blessed $instance) {
2476         my $metaclass = Moose::Util::find_meta($component);
2477         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2478         my $component_method_from = $method_meta->associated_metaclass->name;
2479         my $value = defined($instance) ? $instance : 'undef';
2480         Catalyst::Exception->throw(
2481             message =>
2482             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2483         );
2484     }
2485
2486     return $instance;
2487 }
2488
2489 =head2 $c->setup_dispatcher
2490
2491 Sets up dispatcher.
2492
2493 =cut
2494
2495 sub setup_dispatcher {
2496     my ( $class, $dispatcher ) = @_;
2497
2498     if ($dispatcher) {
2499         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2500     }
2501
2502     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2503         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2504     }
2505
2506     unless ($dispatcher) {
2507         $dispatcher = $class->dispatcher_class;
2508     }
2509
2510     Class::MOP::load_class($dispatcher);
2511
2512     # dispatcher instance
2513     $class->dispatcher( $dispatcher->new );
2514 }
2515
2516 =head2 $c->setup_engine
2517
2518 Sets up engine.
2519
2520 =cut
2521
2522 sub setup_engine {
2523     my ( $class, $engine ) = @_;
2524
2525     if ($engine) {
2526         $engine = 'Catalyst::Engine::' . $engine;
2527     }
2528
2529     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2530         $engine = 'Catalyst::Engine::' . $env;
2531     }
2532
2533     if ( $ENV{MOD_PERL} ) {
2534         my $meta = Class::MOP::get_metaclass_by_name($class);
2535
2536         # create the apache method
2537         $meta->add_method('apache' => sub { shift->engine->apache });
2538
2539         my ( $software, $version ) =
2540           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2541
2542         $version =~ s/_//g;
2543         $version =~ s/(\.[^.]+)\./$1/g;
2544
2545         if ( $software eq 'mod_perl' ) {
2546
2547             if ( !$engine ) {
2548
2549                 if ( $version >= 1.99922 ) {
2550                     $engine = 'Catalyst::Engine::Apache2::MP20';
2551                 }
2552
2553                 elsif ( $version >= 1.9901 ) {
2554                     $engine = 'Catalyst::Engine::Apache2::MP19';
2555                 }
2556
2557                 elsif ( $version >= 1.24 ) {
2558                     $engine = 'Catalyst::Engine::Apache::MP13';
2559                 }
2560
2561                 else {
2562                     Catalyst::Exception->throw( message =>
2563                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2564                 }
2565
2566             }
2567
2568             # install the correct mod_perl handler
2569             if ( $version >= 1.9901 ) {
2570                 *handler = sub  : method {
2571                     shift->handle_request(@_);
2572                 };
2573             }
2574             else {
2575                 *handler = sub ($$) { shift->handle_request(@_) };
2576             }
2577
2578         }
2579
2580         elsif ( $software eq 'Zeus-Perl' ) {
2581             $engine = 'Catalyst::Engine::Zeus';
2582         }
2583
2584         else {
2585             Catalyst::Exception->throw(
2586                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2587         }
2588     }
2589
2590     unless ($engine) {
2591         $engine = $class->engine_class;
2592     }
2593
2594     Class::MOP::load_class($engine);
2595
2596     # check for old engines that are no longer compatible
2597     my $old_engine;
2598     if ( $engine->isa('Catalyst::Engine::Apache')
2599         && !Catalyst::Engine::Apache->VERSION )
2600     {
2601         $old_engine = 1;
2602     }
2603
2604     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2605         && Catalyst::Engine::Server->VERSION le '0.02' )
2606     {
2607         $old_engine = 1;
2608     }
2609
2610     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2611         && $engine->VERSION eq '0.01' )
2612     {
2613         $old_engine = 1;
2614     }
2615
2616     elsif ($engine->isa('Catalyst::Engine::Zeus')
2617         && $engine->VERSION eq '0.01' )
2618     {
2619         $old_engine = 1;
2620     }
2621
2622     if ($old_engine) {
2623         Catalyst::Exception->throw( message =>
2624               qq/Engine "$engine" is not supported by this version of Catalyst/
2625         );
2626     }
2627
2628     # engine instance
2629     $class->engine( $engine->new );
2630 }
2631
2632 =head2 $c->setup_home
2633
2634 Sets up the home directory.
2635
2636 =cut
2637
2638 sub setup_home {
2639     my ( $class, $home ) = @_;
2640
2641     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2642         $home = $env;
2643     }
2644
2645     $home ||= Catalyst::Utils::home($class);
2646
2647     if ($home) {
2648         #I remember recently being scolded for assigning config values like this
2649         $class->config->{home} ||= $home;
2650         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2651     }
2652 }
2653
2654 =head2 $c->setup_log
2655
2656 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2657 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2658 log to.
2659
2660 This method also installs a C<debug> method that returns a true value into the
2661 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2662 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2663
2664 Note that if the log has already been setup, by either a previous call to
2665 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2666 that this method won't actually set up the log object.
2667
2668 =cut
2669
2670 sub setup_log {
2671     my ( $class, $levels ) = @_;
2672
2673     $levels ||= '';
2674     $levels =~ s/^\s+//;
2675     $levels =~ s/\s+$//;
2676     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2677
2678     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2679     if ( defined $env_debug ) {
2680         $levels{debug} = 1 if $env_debug; # Ugly!
2681         delete($levels{debug}) unless $env_debug;
2682     }
2683
2684     unless ( $class->log ) {
2685         $class->log( Catalyst::Log->new(keys %levels) );
2686     }
2687
2688     if ( $levels{debug} ) {
2689         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2690         $class->log->debug('Debug messages enabled');
2691     }
2692 }
2693
2694 =head2 $c->setup_plugins
2695
2696 Sets up plugins.
2697
2698 =cut
2699
2700 =head2 $c->setup_stats
2701
2702 Sets up timing statistics class.
2703
2704 =cut
2705
2706 sub setup_stats {
2707     my ( $class, $stats ) = @_;
2708
2709     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2710
2711     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2712     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2713         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2714         $class->log->debug('Statistics enabled');
2715     }
2716 }
2717
2718
2719 =head2 $c->registered_plugins
2720
2721 Returns a sorted list of the plugins which have either been stated in the
2722 import list or which have been added via C<< MyApp->plugin(@args); >>.
2723
2724 If passed a given plugin name, it will report a boolean value indicating
2725 whether or not that plugin is loaded.  A fully qualified name is required if
2726 the plugin name does not begin with C<Catalyst::Plugin::>.
2727
2728  if ($c->registered_plugins('Some::Plugin')) {
2729      ...
2730  }
2731
2732 =cut
2733
2734 {
2735
2736     sub registered_plugins {
2737         my $proto = shift;
2738         return sort keys %{ $proto->_plugins } unless @_;
2739         my $plugin = shift;
2740         return 1 if exists $proto->_plugins->{$plugin};
2741         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2742     }
2743
2744     sub _register_plugin {
2745         my ( $proto, $plugin, $instant ) = @_;
2746         my $class = ref $proto || $proto;
2747
2748         Class::MOP::load_class( $plugin );
2749         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2750             if $plugin->isa( 'Catalyst::Component' );
2751         $proto->_plugins->{$plugin} = 1;
2752         unless ($instant) {
2753             my $meta = Class::MOP::get_metaclass_by_name($class);
2754             $meta->superclasses($plugin, $meta->superclasses);
2755         }
2756         return $class;
2757     }
2758
2759     sub setup_plugins {
2760         my ( $class, $plugins ) = @_;
2761
2762         $class->_plugins( {} ) unless $class->_plugins;
2763         $plugins = Data::OptList::mkopt($plugins || []);
2764
2765         my @plugins = map {
2766             [ Catalyst::Utils::resolve_namespace(
2767                   $class . '::Plugin',
2768                   'Catalyst::Plugin', $_->[0]
2769               ),
2770               $_->[1],
2771             ]
2772          } @{ $plugins };
2773
2774         for my $plugin ( reverse @plugins ) {
2775             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2776             my $meta = find_meta($plugin->[0]);
2777             next if $meta && $meta->isa('Moose::Meta::Role');
2778
2779             $class->_register_plugin($plugin->[0]);
2780         }
2781
2782         my @roles =
2783             map  { $_->[0]->name, $_->[1] }
2784             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2785             map  { [find_meta($_->[0]), $_->[1]] }
2786             @plugins;
2787
2788         Moose::Util::apply_all_roles(
2789             $class => @roles
2790         ) if @roles;
2791     }
2792 }
2793
2794 =head2 $c->stack
2795
2796 Returns an arrayref of the internal execution stack (actions that are
2797 currently executing).
2798
2799 =head2 $c->stats
2800
2801 Returns the current timing statistics object. By default Catalyst uses
2802 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2803 L<< stats_class|/"$c->stats_class" >>.
2804
2805 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2806 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2807 profile explicitly, although MyApp.pm still won't profile nor output anything
2808 by itself.
2809
2810 =head2 $c->stats_class
2811
2812 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2813
2814 =head2 $c->use_stats
2815
2816 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2817
2818 Note that this is a static method, not an accessor and should be overridden
2819 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2820
2821 =cut
2822
2823 sub use_stats { 0 }
2824
2825
2826 =head2 $c->write( $data )
2827
2828 Writes $data to the output stream. When using this method directly, you
2829 will need to manually set the C<Content-Length> header to the length of
2830 your output data, if known.
2831
2832 =cut
2833
2834 sub write {
2835     my $c = shift;
2836
2837     # Finalize headers if someone manually writes output
2838     $c->finalize_headers;
2839
2840     return $c->engine->write( $c, @_ );
2841 }
2842
2843 =head2 version
2844
2845 Returns the Catalyst version number. Mostly useful for "powered by"
2846 messages in template systems.
2847
2848 =cut
2849
2850 sub version { return $Catalyst::VERSION }
2851
2852 =head1 CONFIGURATION
2853
2854 There are a number of 'base' config variables which can be set:
2855
2856 =over
2857
2858 =item *
2859
2860 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2861
2862 =item *
2863
2864 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2865
2866 =item *
2867
2868 C<home> - The application home directory. In an uninstalled application,
2869 this is the top level application directory. In an installed application,
2870 this will be the directory containing C<< MyApp.pm >>.
2871
2872 =item *
2873
2874 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2875
2876 =item *
2877
2878 C<name> - The name of the application in debug messages and the debug and
2879 welcome screens
2880
2881 =item *
2882
2883 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2884 until it is accessed. This allows you to (for example) check authentication (and reject
2885 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2886
2887 =item *
2888
2889 C<root> - The root directory for templates. Usually this is just a
2890 subdirectory of the home directory, but you can set it to change the
2891 templates to a different directory.
2892
2893 =item *
2894
2895 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2896 namespaces from which components will be loaded (and constructed and stored in
2897 C<< $c->components >>).
2898
2899 =item *
2900
2901 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2902 to be shown in hit debug tables in the test server.
2903
2904 =item *
2905
2906 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
2907 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
2908 for more information.
2909
2910 =item *
2911
2912 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2913
2914 =back
2915
2916 =head1 INTERNAL ACTIONS
2917
2918 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2919 C<_ACTION>, and C<_END>. These are by default not shown in the private
2920 action table, but you can make them visible with a config parameter.
2921
2922     MyApp->config(show_internal_actions => 1);
2923
2924 =head1 ON-DEMAND PARSER
2925
2926 The request body is usually parsed at the beginning of a request,
2927 but if you want to handle input yourself, you can enable on-demand
2928 parsing with a config parameter.
2929
2930     MyApp->config(parse_on_demand => 1);
2931
2932 =head1 PROXY SUPPORT
2933
2934 Many production servers operate using the common double-server approach,
2935 with a lightweight frontend web server passing requests to a larger
2936 backend server. An application running on the backend server must deal
2937 with two problems: the remote user always appears to be C<127.0.0.1> and
2938 the server's hostname will appear to be C<localhost> regardless of the
2939 virtual host that the user connected through.
2940
2941 Catalyst will automatically detect this situation when you are running
2942 the frontend and backend servers on the same machine. The following
2943 changes are made to the request.
2944
2945     $c->req->address is set to the user's real IP address, as read from
2946     the HTTP X-Forwarded-For header.
2947
2948     The host value for $c->req->base and $c->req->uri is set to the real
2949     host, as read from the HTTP X-Forwarded-Host header.
2950
2951 Additionally, you may be running your backend application on an insecure
2952 connection (port 80) while your frontend proxy is running under SSL.  If there
2953 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2954 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2955 be created properly.
2956
2957 In the case of passing in:
2958
2959     X-Forwarded-Port: 443
2960
2961 All calls to C<uri_for> will result in an https link, as is expected.
2962
2963 Obviously, your web server must support these headers for this to work.
2964
2965 In a more complex server farm environment where you may have your
2966 frontend proxy server(s) on different machines, you will need to set a
2967 configuration option to tell Catalyst to read the proxied data from the
2968 headers.
2969
2970     MyApp->config(using_frontend_proxy => 1);
2971
2972 If you do not wish to use the proxy support at all, you may set:
2973
2974     MyApp->config(ignore_frontend_proxy => 1);
2975
2976 =head1 THREAD SAFETY
2977
2978 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2979 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2980 believe the Catalyst core to be thread-safe.
2981
2982 If you plan to operate in a threaded environment, remember that all other
2983 modules you are using must also be thread-safe. Some modules, most notably
2984 L<DBD::SQLite>, are not thread-safe.
2985
2986 =head1 SUPPORT
2987
2988 IRC:
2989
2990     Join #catalyst on irc.perl.org.
2991
2992 Mailing Lists:
2993
2994     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2995     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2996
2997 Web:
2998
2999     http://catalyst.perl.org
3000
3001 Wiki:
3002
3003     http://dev.catalyst.perl.org
3004
3005 =head1 SEE ALSO
3006
3007 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3008
3009 =head2 L<Catalyst::Manual> - The Catalyst Manual
3010
3011 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3012
3013 =head2 L<Catalyst::Engine> - Core engine
3014
3015 =head2 L<Catalyst::Log> - Log class.
3016
3017 =head2 L<Catalyst::Request> - Request object
3018
3019 =head2 L<Catalyst::Response> - Response object
3020
3021 =head2 L<Catalyst::Test> - The test suite.
3022
3023 =head1 PROJECT FOUNDER
3024
3025 sri: Sebastian Riedel <sri@cpan.org>
3026
3027 =head1 CONTRIBUTORS
3028
3029 abw: Andy Wardley
3030
3031 acme: Leon Brocard <leon@astray.com>
3032
3033 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3034
3035 Andrew Bramble
3036
3037 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3038
3039 Andrew Ruthven
3040
3041 André Walker
3042
3043 andyg: Andy Grundman <andy@hybridized.org>
3044
3045 audreyt: Audrey Tang
3046
3047 bricas: Brian Cassidy <bricas@cpan.org>
3048
3049 Caelum: Rafael Kitover <rkitover@io.com>
3050
3051 chansen: Christian Hansen
3052
3053 chicks: Christopher Hicks
3054
3055 Chisel Wright C<pause@herlpacker.co.uk>
3056
3057 Danijel Milicevic C<me@danijel.de>
3058
3059 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3060
3061 David Naughton, C<naughton@umn.edu>
3062
3063 David E. Wheeler
3064
3065 dhoss: Devin Austin <dhoss@cpan.org>
3066
3067 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3068
3069 Drew Taylor
3070
3071 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3072
3073 esskar: Sascha Kiefer
3074
3075 fireartist: Carl Franks <cfranks@cpan.org>
3076
3077 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3078
3079 gabb: Danijel Milicevic
3080
3081 Gary Ashton Jones
3082
3083 Gavin Henry C<ghenry@perl.me.uk>
3084
3085 Geoff Richards
3086
3087 groditi: Guillermo Roditi <groditi@gmail.com>
3088
3089 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3090
3091 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3092
3093 jcamacho: Juan Camacho
3094
3095 jester: Jesse Sheidlower C<jester@panix.com>
3096
3097 jhannah: Jay Hannah <jay@jays.net>
3098
3099 Jody Belka
3100
3101 Johan Lindstrom
3102
3103 jon: Jon Schutz <jjschutz@cpan.org>
3104
3105 Jonathan Rockway C<< <jrockway@cpan.org> >>
3106
3107 Kieren Diment C<kd@totaldatasolution.com>
3108
3109 konobi: Scott McWhirter <konobi@cpan.org>
3110
3111 marcus: Marcus Ramberg <mramberg@cpan.org>
3112
3113 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3114
3115 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3116
3117 mugwump: Sam Vilain
3118
3119 naughton: David Naughton
3120
3121 ningu: David Kamholz <dkamholz@cpan.org>
3122
3123 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3124
3125 numa: Dan Sully <daniel@cpan.org>
3126
3127 obra: Jesse Vincent
3128
3129 Octavian Rasnita
3130
3131 omega: Andreas Marienborg
3132
3133 Oleg Kostyuk <cub.uanic@gmail.com>
3134
3135 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3136
3137 rafl: Florian Ragwitz <rafl@debian.org>
3138
3139 random: Roland Lammel <lammel@cpan.org>
3140
3141 Robert Sedlacek C<< <rs@474.at> >>
3142
3143 SpiceMan: Marcel Montes
3144
3145 sky: Arthur Bergman
3146
3147 szbalint: Balint Szilakszi <szbalint@cpan.org>
3148
3149 t0m: Tomas Doran <bobtfish@bobtfish.net>
3150
3151 Ulf Edvinsson
3152
3153 Viljo Marrandi C<vilts@yahoo.com>
3154
3155 Will Hawes C<info@whawes.co.uk>
3156
3157 willert: Sebastian Willert <willert@cpan.org>
3158
3159 wreis: Wallace Reis <wallace@reis.org.br>
3160
3161 Yuval Kogman, C<nothingmuch@woobling.org>
3162
3163 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3164
3165 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3166
3167 =head1 COPYRIGHT
3168
3169 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3170
3171 =head1 LICENSE
3172
3173 This library is free software. You can redistribute it and/or modify it under
3174 the same terms as Perl itself.
3175
3176 =cut
3177
3178 no Moose;
3179
3180 __PACKAGE__->meta->make_immutable;
3181
3182 1;