lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use File::stat;
  19 use Text::SimpleTable ();
  20 use Path::Class::Dir ();
  21 use Path::Class::File ();
  22 use URI ();
  23 use URI::http;
  24 use URI::https;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use Class::C3::Adopt::NEXT;
  28 use List::MoreUtils qw/uniq/;
  29 use attributes;
  30 use String::RewritePrefix;
  31 use Catalyst::EngineLoader;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34 use Try::Tiny;
  35 use Safe::Isa;
  36 use Plack::Middleware::Conditional;
  37 use Plack::Middleware::ReverseProxy;
  38 use Plack::Middleware::IIS6ScriptNameFix;
  39 use Plack::Middleware::IIS7KeepAliveFix;
  40 use Plack::Middleware::LighttpdScriptNameFix;
  41
  42 BEGIN { require 5.008003; }
  43
  44 has stack => (is => 'ro', default => sub { [] });
  45 has stash => (is => 'rw', default => sub { {} });
  46 has state => (is => 'rw', default => 0);
  47 has stats => (is => 'rw');
  48 has action => (is => 'rw');
  49 has counter => (is => 'rw', default => sub { {} });
  50 has request => (
  51     is => 'rw',
  52     default => sub {
  53         my $self = shift;
  54         $self->request_class->new($self->_build_request_constructor_args);
  55     },
  56     lazy => 1,
  57 );
  58 sub _build_request_constructor_args {
  59     my $self = shift;
  60     my %p = ( _log => $self->log );
  61     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  62     \%p;
  63 }
  64
  65 has response => (
  66     is => 'rw',
  67     default => sub {
  68         my $self = shift;
  69         $self->response_class->new($self->_build_response_constructor_args);
  70     },
  71     lazy => 1,
  72 );
  73 sub _build_response_constructor_args {
  74     my $self = shift;
  75     { _log => $self->log };
  76 }
  77
  78 has namespace => (is => 'rw');
  79
  80 sub depth { scalar @{ shift->stack || [] }; }
  81 sub comp { shift->component(@_) }
  82
  83 sub req {
  84     my $self = shift; return $self->request(@_);
  85 }
  86 sub res {
  87     my $self = shift; return $self->response(@_);
  88 }
  89
  90 # For backwards compatibility
  91 sub finalize_output { shift->finalize_body(@_) };
  92
  93 # For statistics
  94 our $COUNT     = 1;
  95 our $START     = time;
  96 our $RECURSION = 1000;
  97 our $DETACH    = Catalyst::Exception::Detach->new;
  98 our $GO        = Catalyst::Exception::Go->new;
  99
 100 #I imagine that very few of these really need to be class variables. if any.
 101 #maybe we should just make them attributes with a default?
 102 __PACKAGE__->mk_classdata($_)
 103   for qw/container arguments dispatcher engine log dispatcher_class
 104   engine_loader context_class request_class response_class stats_class
 105   setup_finished _psgi_app loading_psgi_file run_options/;
 106
 107 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 108 __PACKAGE__->request_class('Catalyst::Request');
 109 __PACKAGE__->response_class('Catalyst::Response');
 110 __PACKAGE__->stats_class('Catalyst::Stats');
 111
 112 # Remember to update this in Catalyst::Runtime as well!
 113
 114 our $VERSION = '5.90017';
 115
 116 sub import {
 117     my ( $class, @arguments ) = @_;
 118
 119     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 120     # callers @ISA.
 121     return unless $class eq 'Catalyst';
 122
 123     my $caller = caller();
 124     return if $caller eq 'main';
 125
 126     my $meta = Moose::Meta::Class->initialize($caller);
 127
 128     unless ( $caller->isa('Catalyst') ) { # XXX - Remove!
 129         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Component'); # XXX - Remove!
 130         $meta->superclasses(@superclasses); # XXX - Remove!
 131     } # XXX - Remove!
 132
 133     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 134     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 135
 136     unless( $meta->has_method('meta') ){
 137         if ($Moose::VERSION >= 1.15) {
 138             $meta->_add_meta_method('meta');
 139         }
 140         else {
 141             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 142         }
 143     }
 144
 145     $caller->arguments( [@arguments] );
 146
 147     # FIXME
 148     # what is this for?
 149     # we call setup_home on import AND on ->setup
 150     # is there a reason for it?
 151     # anyway there is no point for setup_home without setup_config() so...
 152     $caller->setup_config;
 153     $caller->setup_home;
 154 }
 155
 156 sub MODIFY_CODE_ATTRIBUTES {
 157     Catalyst::Exception->throw(
 158         "Catalyst applications (aka MyApp) cannot be controllers anymore. " .
 159         "That has been deprecated and removed. You should create a " .
 160         "controller class called Root.pm, and move relevant code to that class."
 161     );
 162 }
 163
 164
 165 sub _application { $_[0] }
 166
 167 =encoding UTF-8
 168
 169 =head1 NAME
 170
 171 Catalyst - The Elegant MVC Web Application Framework
 172
 173 =head1 SYNOPSIS
 174
 175 See the L<Catalyst::Manual> distribution for comprehensive
 176 documentation and tutorials.
 177
 178     # Install Catalyst::Devel for helpers and other development tools
 179     # use the helper to create a new application
 180     catalyst.pl MyApp
 181
 182     # add models, views, controllers
 183     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 184     script/myapp_create.pl view MyTemplate TT
 185     script/myapp_create.pl controller Search
 186
 187     # built in testserver -- use -r to restart automatically on changes
 188     # --help to see all available options
 189     script/myapp_server.pl
 190
 191     # command line testing interface
 192     script/myapp_test.pl /yada
 193
 194     ### in lib/MyApp.pm
 195     use Catalyst qw/-Debug/; # include plugins here as well
 196
 197     ### In lib/MyApp/Controller/Root.pm (autocreated)
 198     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 199         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 200         $c->stash->{template} = 'foo.tt'; # set the template
 201         # lookup something from db -- stash vars are passed to TT
 202         $c->stash->{data} =
 203           $c->model('Database::Foo')->search( { country => $args[0] } );
 204         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 205             $c->forward( 'bar' ); # process another action
 206             # do something else after forward returns
 207         }
 208     }
 209
 210     # The foo.tt TT template can use the stash data from the database
 211     [% WHILE (item = data.next) %]
 212         [% item.foo %]
 213     [% END %]
 214
 215     # called for /bar/of/soap, /bar/of/soap/10, etc.
 216     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 217
 218     # called after all actions are finished
 219     sub end : Action {
 220         my ( $self, $c ) = @_;
 221         if ( scalar @{ $c->error } ) { ... } # handle errors
 222         return if $c->res->body; # already have a response
 223         $c->forward( 'MyApp::View::TT' ); # render template
 224     }
 225
 226 See L<Catalyst::Manual::Intro> for additional information.
 227
 228 =head1 DESCRIPTION
 229
 230 Catalyst is a modern framework for making web applications without the
 231 pain usually associated with this process. This document is a reference
 232 to the main Catalyst application. If you are a new user, we suggest you
 233 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 234
 235 See L<Catalyst::Manual> for more documentation.
 236
 237 Catalyst plugins can be loaded by naming them as arguments to the "use
 238 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 239 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 240 C<My::Module>.
 241
 242     use Catalyst qw/My::Module/;
 243
 244 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 245 fully qualify the name by using a unary plus:
 246
 247     use Catalyst qw/
 248         My::Module
 249         +Fully::Qualified::Plugin::Name
 250     /;
 251
 252 Special flags like C<-Debug> can also be specified as
 253 arguments when Catalyst is loaded:
 254
 255     use Catalyst qw/-Debug My::Module/;
 256
 257 The position of plugins and flags in the chain is important, because
 258 they are loaded in the order in which they appear.
 259
 260 The following flags are supported:
 261
 262 =head2 -Debug
 263
 264 Enables debug output. You can also force this setting from the system
 265 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 266 settings override the application, with <MYAPP>_DEBUG having the highest
 267 priority.
 268
 269 This sets the log level to 'debug' and enables full debug output on the
 270 error screen. If you only want the latter, see L<< $c->debug >>.
 271
 272 =head2 -Home
 273
 274 Forces Catalyst to use a specific home directory, e.g.:
 275
 276     use Catalyst qw[-Home=/usr/mst];
 277
 278 This can also be done in the shell environment by setting either the
 279 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 280 is replaced with the uppercased name of your application, any "::" in
 281 the name will be replaced with underscores, e.g. MyApp::Web should use
 282 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 283
 284 If none of these are set, Catalyst will attempt to automatically detect the
 285 home directory. If you are working in a development environment, Catalyst
 286 will try and find the directory containing either Makefile.PL, Build.PL or
 287 dist.ini. If the application has been installed into the system (i.e.
 288 you have done C<make install>), then Catalyst will use the path to your
 289 application module, without the .pm extension (e.g., /foo/MyApp if your
 290 application was installed at /foo/MyApp.pm)
 291
 292 =head2 -Log
 293
 294     use Catalyst '-Log=warn,fatal,error';
 295
 296 Specifies a comma-delimited list of log levels.
 297
 298 =head2 -Stats
 299
 300 Enables statistics collection and reporting.
 301
 302    use Catalyst qw/-Stats=1/;
 303
 304 You can also force this setting from the system environment with CATALYST_STATS
 305 or <MYAPP>_STATS. The environment settings override the application, with
 306 <MYAPP>_STATS having the highest priority.
 307
 308 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 309
 310 =head1 METHODS
 311
 312 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 313
 314 =head2 $c->action
 315
 316 Returns a L<Catalyst::Action> object for the current action, which
 317 stringifies to the action name. See L<Catalyst::Action>.
 318
 319 =head2 $c->namespace
 320
 321 Returns the namespace of the current action, i.e., the URI prefix
 322 corresponding to the controller of the current action. For example:
 323
 324     # in Controller::Foo::Bar
 325     $c->namespace; # returns 'foo/bar';
 326
 327 =head2 $c->request
 328
 329 =head2 $c->req
 330
 331 Returns the current L<Catalyst::Request> object, giving access to
 332 information about the current client request (including parameters,
 333 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 334
 335 =head2 REQUEST FLOW HANDLING
 336
 337 =head2 $c->forward( $action [, \@arguments ] )
 338
 339 =head2 $c->forward( $class, $method, [, \@arguments ] )
 340
 341 Forwards processing to another action, by its private name. If you give a
 342 class name but no method, C<process()> is called. You may also optionally
 343 pass arguments in an arrayref. The action will receive the arguments in
 344 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 345 C<< $c->req->args >> will be restored to the previous values.
 346
 347 Any data C<return>ed from the action forwarded to, will be returned by the
 348 call to forward.
 349
 350     my $foodata = $c->forward('/foo');
 351     $c->forward('index');
 352     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 353     $c->forward('View::TT');
 354
 355 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 356 an C<< eval { } >> around the call (actually
 357 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 358 exceptions thrown by the called action non-fatal and pushing them onto
 359 $c->error instead. If you want C<die> to propagate you need to do something
 360 like:
 361
 362     $c->forward('foo');
 363     die join "\n", @{ $c->error } if @{ $c->error };
 364
 365 Or make sure to always return true values from your actions and write
 366 your code like this:
 367
 368     $c->forward('foo') || return;
 369
 370 Another note is that C<< $c->forward >> always returns a scalar because it
 371 actually returns $c->state which operates in a scalar context.
 372 Thus, something like:
 373
 374     return @array;
 375
 376 in an action that is forwarded to is going to return a scalar,
 377 i.e. how many items are in that array, which is probably not what you want.
 378 If you need to return an array then return a reference to it,
 379 or stash it like so:
 380
 381     $c->stash->{array} = \@array;
 382
 383 and access it from the stash.
 384
 385 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 386
 387 =cut
 388
 389 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 390
 391 =head2 $c->detach( $action [, \@arguments ] )
 392
 393 =head2 $c->detach( $class, $method, [, \@arguments ] )
 394
 395 =head2 $c->detach()
 396
 397 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 398 doesn't return to the previous action when processing is finished.
 399
 400 When called with no arguments it escapes the processing chain entirely.
 401
 402 =cut
 403
 404 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 405
 406 =head2 $c->visit( $action [, \@arguments ] )
 407
 408 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 409
 410 =head2 $c->visit( $class, $method, [, \@arguments ] )
 411
 412 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 413
 414 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 415 but does a full dispatch, instead of just calling the new C<$action> /
 416 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 417 you go to are called, just like a new request.
 418
 419 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 420 This means, for example, that C<< $c->action >> methods such as
 421 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 422 L<reverse|Catalyst::Action/reverse> return information for the visited action
 423 when they are invoked within the visited action.  This is different from the
 424 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 425 continues to use the $c->action object from the caller action even when
 426 invoked from the called action.
 427
 428 C<< $c->stash >> is kept unchanged.
 429
 430 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 431 allows you to "wrap" another action, just as it would have been called by
 432 dispatching from a URL, while the analogous
 433 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 434 transfer control to another action as if it had been reached directly from a URL.
 435
 436 =cut
 437
 438 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 439
 440 =head2 $c->go( $action [, \@arguments ] )
 441
 442 =head2 $c->go( $action [, \@captures, \@arguments ] )
 443
 444 =head2 $c->go( $class, $method, [, \@arguments ] )
 445
 446 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 447
 448 The relationship between C<go> and
 449 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 450 the relationship between
 451 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 452 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 453 C<< $c->go >> will perform a full dispatch on the specified action or method,
 454 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 455 C<go> escapes the processing of the current request chain on completion, and
 456 does not return to its caller.
 457
 458 @arguments are arguments to the final destination of $action. @captures are
 459 arguments to the intermediate steps, if any, on the way to the final sub of
 460 $action.
 461
 462 =cut
 463
 464 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 465
 466 =head2 $c->response
 467
 468 =head2 $c->res
 469
 470 Returns the current L<Catalyst::Response> object, see there for details.
 471
 472 =head2 $c->stash
 473
 474 Returns a hashref to the stash, which may be used to store data and pass
 475 it between components during a request. You can also set hash keys by
 476 passing arguments. The stash is automatically sent to the view. The
 477 stash is cleared at the end of a request; it cannot be used for
 478 persistent storage (for this you must use a session; see
 479 L<Catalyst::Plugin::Session> for a complete system integrated with
 480 Catalyst).
 481
 482     $c->stash->{foo} = $bar;
 483     $c->stash( { moose => 'majestic', qux => 0 } );
 484     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 485
 486     # stash is automatically passed to the view for use in a template
 487     $c->forward( 'MyApp::View::TT' );
 488
 489 =cut
 490
 491 around stash => sub {
 492     my $orig = shift;
 493     my $c = shift;
 494     my $stash = $orig->($c);
 495     if (@_) {
 496         my $new_stash = @_ > 1 ? {@_} : $_[0];
 497         croak('stash takes a hash or hashref') unless ref $new_stash;
 498         foreach my $key ( keys %$new_stash ) {
 499           $stash->{$key} = $new_stash->{$key};
 500         }
 501     }
 502
 503     return $stash;
 504 };
 505
 506
 507 =head2 $c->error
 508
 509 =head2 $c->error($error, ...)
 510
 511 =head2 $c->error($arrayref)
 512
 513 Returns an arrayref containing error messages.  If Catalyst encounters an
 514 error while processing a request, it stores the error in $c->error.  This
 515 method should only be used to store fatal error messages.
 516
 517     my @error = @{ $c->error };
 518
 519 Add a new error.
 520
 521     $c->error('Something bad happened');
 522
 523 =cut
 524
 525 sub error {
 526     my $c = shift;
 527     if ( $_[0] ) {
 528         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 529         croak @$error unless ref $c;
 530         push @{ $c->{error} }, @$error;
 531     }
 532     elsif ( defined $_[0] ) { $c->{error} = undef }
 533     return $c->{error} || [];
 534 }
 535
 536
 537 =head2 $c->state
 538
 539 Contains the return value of the last executed action.
 540 Note that << $c->state >> operates in a scalar context which means that all
 541 values it returns are scalar.
 542
 543 =head2 $c->clear_errors
 544
 545 Clear errors.  You probably don't want to clear the errors unless you are
 546 implementing a custom error screen.
 547
 548 This is equivalent to running
 549
 550     $c->error(0);
 551
 552 =cut
 553
 554 sub clear_errors {
 555     my $c = shift;
 556     $c->error(0);
 557 }
 558
 559 =head2 COMPONENT ACCESSORS
 560
 561 =head2 $c->controller($name)
 562
 563 Gets a L<Catalyst::Controller> instance by name.
 564
 565     $c->controller('Foo')->do_stuff;
 566
 567 If the name is omitted, will return the controller for the dispatched
 568 action.
 569
 570 If you want to search for controllers, pass in a regexp as the argument.
 571
 572     # find all controllers that start with Foo
 573     my @foo_controllers = $c->controller(qr{^Foo});
 574
 575
 576 =cut
 577
 578 sub controller { shift->_lookup_mvc('controller', @_) }
 579
 580 =head2 $c->model($name)
 581
 582 Gets a L<Catalyst::Model> instance by name.
 583
 584     $c->model('Foo')->do_stuff;
 585
 586 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 587
 588 If the name is omitted, it will look for
 589  - a model object in $c->stash->{current_model_instance}, then
 590  - a model name in $c->stash->{current_model}, then
 591  - a config setting 'default_model', or
 592  - check if there is only one model, and return it if that's the case.
 593
 594 If you want to search for models, pass in a regexp as the argument.
 595
 596     # find all models that start with Foo
 597     my @foo_models = $c->model(qr{^Foo});
 598
 599 =cut
 600
 601 sub model { shift->_lookup_mvc('model', @_) }
 602
 603 =head2 $c->view($name)
 604
 605 Gets a L<Catalyst::View> instance by name.
 606
 607     $c->view('Foo')->do_stuff;
 608
 609 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 610
 611 If the name is omitted, it will look for
 612  - a view object in $c->stash->{current_view_instance}, then
 613  - a view name in $c->stash->{current_view}, then
 614  - a config setting 'default_view', or
 615  - check if there is only one view, and return it if that's the case.
 616
 617 If you want to search for views, pass in a regexp as the argument.
 618
 619     # find all views that start with Foo
 620     my @foo_views = $c->view(qr{^Foo});
 621
 622 =cut
 623
 624 sub view { shift->_lookup_mvc('view', @_) }
 625
 626 sub _lookup_mvc {
 627     my ( $c, $type, $name, @args ) = @_;
 628
 629     if (ref $c && !$name) {
 630         my $current_instance = $c->stash->{"current_${type}_instance"};
 631         return $current_instance
 632             if $current_instance && $type ne 'controller';
 633
 634         $name = $type eq 'controller'
 635               ? Catalyst::Utils::class2classshortsuffix($c->action->class)
 636               : $c->stash->{"current_${type}"}
 637               ;
 638     }
 639
 640     return $c->container->get_component_from_sub_container($type, $name, $c, @args);
 641 }
 642
 643 =head2 $c->controllers
 644
 645 Returns the available names which can be passed to $c->controller
 646
 647 =cut
 648
 649 sub controllers {
 650     my ( $c ) = @_;
 651     return $c->container->get_sub_container('controller')->get_service_list;
 652 }
 653
 654 =head2 $c->models
 655
 656 Returns the available names which can be passed to $c->model
 657
 658 =cut
 659
 660 sub models {
 661     my ( $c ) = @_;
 662     return $c->container->get_sub_container('model')->get_service_list;
 663 }
 664
 665
 666 =head2 $c->views
 667
 668 Returns the available names which can be passed to $c->view
 669
 670 =cut
 671
 672 sub views {
 673     my ( $c ) = @_;
 674     return $c->container->get_sub_container('view')->get_service_list;
 675 }
 676
 677 =head2 $c->comp($name)
 678
 679 =head2 $c->component($name)
 680
 681 Gets a component object by name. This method is not recommended,
 682 unless you want to get a specific component by full
 683 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 684 should be used instead.
 685
 686 If C<$name> is a regexp, a list of components matched against the full
 687 component name will be returned.
 688
 689 =cut
 690
 691 sub component {
 692     my ( $c, $component, @args ) = @_;
 693
 694     unless ($component) {
 695         $c->log->warn('Calling $c->component with no args is deprecated and ');
 696         $c->log->warn('will be removed in a future release.');
 697         $c->log->warn('Use $c->component_list instead.');
 698         return $c->component_list;
 699     }
 700
 701     my @result = $c->container->find_component( $component, $c, @args );
 702
 703     # list context for regexp searches
 704     return @result if ref $component;
 705
 706     # only one component (if it's found) for string searches
 707     return shift @result if @result;
 708
 709     if (ref $c eq $component) {
 710         $c->log->warn('You are calling $c->comp("MyApp"). This behaviour is');
 711         $c->log->warn('deprecated, and will be removed in a future release.');
 712         return $c;
 713     }
 714
 715     $c->log->warn("Looking for '$component', but nothing was found.");
 716
 717     # I would expect to return an empty list here, but that breaks back-compat
 718     $c->log->warn('Component not found, returning the list of existing');
 719     $c->log->warn('components. This behavior is deprecated and will be');
 720     $c->log->warn('removed in a future release. Use $c->component_list');
 721     $c->log->warn('instead.');
 722
 723     return $c->component_list;
 724 }
 725
 726 =head2 $c->component_list
 727
 728 Returns the sorted list of the component names of the application.
 729
 730 =cut
 731
 732 sub component_list { sort keys %{ shift->components } }
 733
 734 =head2 CLASS DATA AND HELPER CLASSES
 735
 736 =head2 $c->config
 737
 738 Returns or takes a hashref containing the application's configuration.
 739
 740     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 741
 742 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 743 like C<myapp.conf> in your applications home directory. See
 744 L<Catalyst::Plugin::ConfigLoader>.
 745
 746 =head3 Cascading configuration
 747
 748 The config method is present on all Catalyst components, and configuration
 749 will be merged when an application is started. Configuration loaded with
 750 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 751 followed by configuration in your top level C<MyApp> class. These two
 752 configurations are merged, and then configuration data whose hash key matches a
 753 component name is merged with configuration for that component.
 754
 755 The configuration for a component is then passed to the C<new> method when a
 756 component is constructed.
 757
 758 For example:
 759
 760     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 761     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 762
 763 will mean that C<MyApp::Model::Foo> receives the following data when
 764 constructed:
 765
 766     MyApp::Model::Foo->new({
 767         bar => 'baz',
 768         quux => 'frob',
 769         overrides => 'me',
 770     });
 771
 772 It's common practice to use a Moose attribute
 773 on the receiving component to access the config value.
 774
 775     package MyApp::Model::Foo;
 776
 777     use Moose;
 778
 779     # this attr will receive 'baz' at construction time
 780     has 'bar' => (
 781         is  => 'rw',
 782         isa => 'Str',
 783     );
 784
 785 You can then get the value 'baz' by calling $c->model('Foo')->bar
 786 (or $self->bar inside code in the model).
 787
 788 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 789 as a way of reading config within your code, as this B<will not> give you the
 790 correctly merged config back. You B<MUST> take the config values supplied to
 791 the constructor and use those instead.
 792
 793 =cut
 794
 795 around config => sub {
 796     my $orig = shift;
 797     my $c = shift;
 798
 799     croak('Setting config after setup has been run is not allowed.')
 800         if ( @_ and $c->setup_finished );
 801
 802     $c->$orig(@_);
 803 };
 804
 805 =head2 $c->log
 806
 807 Returns the logging object instance. Unless it is already set, Catalyst
 808 sets this up with a L<Catalyst::Log> object. To use your own log class,
 809 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 810 C<< __PACKAGE__->setup >>.
 811
 812  __PACKAGE__->log( MyLogger->new );
 813  __PACKAGE__->setup;
 814
 815 And later:
 816
 817     $c->log->info( 'Now logging with my own logger!' );
 818
 819 Your log class should implement the methods described in
 820 L<Catalyst::Log>.
 821
 822
 823 =head2 $c->debug
 824
 825 Returns 1 if debug mode is enabled, 0 otherwise.
 826
 827 You can enable debug mode in several ways:
 828
 829 =over
 830
 831 =item By calling myapp_server.pl with the -d flag
 832
 833 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 834
 835 =item The -Debug option in your MyApp.pm
 836
 837 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 838
 839 =back
 840
 841 The first three also set the log level to 'debug'.
 842
 843 Calling C<< $c->debug(1) >> has no effect.
 844
 845 =cut
 846
 847 sub debug { 0 }
 848
 849 =head2 $c->dispatcher
 850
 851 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 852
 853 =head2 $c->engine
 854
 855 Returns the engine instance. See L<Catalyst::Engine>.
 856
 857
 858 =head2 UTILITY METHODS
 859
 860 =head2 $c->path_to(@path)
 861
 862 Merges C<@path> with C<< $c->config->{home} >> and returns a
 863 L<Path::Class::Dir> object. Note you can usually use this object as
 864 a filename, but sometimes you will have to explicitly stringify it
 865 yourself by calling the C<< ->stringify >> method.
 866
 867 For example:
 868
 869     $c->path_to( 'db', 'sqlite.db' );
 870
 871 =cut
 872
 873 sub path_to {
 874     my ( $c, @path ) = @_;
 875     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 876     if ( -d $path ) { return $path }
 877     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 878 }
 879
 880 sub plugin {
 881     my ( $class, $name, $plugin, @args ) = @_;
 882
 883     # See block comment in t/aggregate/unit_core_plugin.t
 884     # See block comment in t/unit_core_plugin.t
 885     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
 886
 887     $class->_register_plugin( $plugin, 1 );
 888
 889     eval { $plugin->import };
 890     $class->mk_classdata($name);
 891     my $obj;
 892     eval { $obj = $plugin->new(@args) };
 893
 894     if ($@) {
 895         Catalyst::Exception->throw( message =>
 896               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 897     }
 898
 899     $class->$name($obj);
 900     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 901       if $class->debug;
 902 }
 903
 904 =head2 MyApp->setup
 905
 906 Initializes the dispatcher and engine, loads any plugins, and loads the
 907 model, view, and controller components. You may also specify an array
 908 of plugins to load here, if you choose to not load them in the C<use
 909 Catalyst> line.
 910
 911     MyApp->setup;
 912     MyApp->setup( qw/-Debug/ );
 913
 914 B<Note:> You B<should not> wrap this method with method modifiers
 915 or bad things will happen - wrap the C<setup_finalize> method instead.
 916
 917 =cut
 918
 919 sub setup {
 920     my ( $class, @arguments ) = @_;
 921     croak('Running setup more than once')
 922         if ( $class->setup_finished );
 923
 924     unless ( $class->isa('Catalyst') ) {
 925
 926         Catalyst::Exception->throw(
 927             message => qq/'$class' does not inherit from Catalyst/ );
 928     }
 929
 930     if ( $class->arguments ) {
 931         @arguments = ( @arguments, @{ $class->arguments } );
 932     }
 933
 934     # Process options
 935     my $flags = {};
 936
 937     foreach (@arguments) {
 938
 939         if (/^-Debug$/) {
 940             $flags->{log} =
 941               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 942         }
 943         elsif (/^-(\w+)=?(.*)$/) {
 944             $flags->{ lc $1 } = $2;
 945         }
 946         else {
 947             push @{ $flags->{plugins} }, $_;
 948         }
 949     }
 950
 951     $class->setup_config();
 952     $class->setup_home( delete $flags->{home} );
 953
 954     $class->setup_log( delete $flags->{log} );
 955     $class->setup_plugins( delete $flags->{plugins} );
 956     $class->setup_dispatcher( delete $flags->{dispatcher} );
 957     if (my $engine = delete $flags->{engine}) {
 958         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
 959     }
 960     $class->setup_engine();
 961     $class->setup_stats( delete $flags->{stats} );
 962
 963     for my $flag ( sort keys %{$flags} ) {
 964
 965         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 966             &$code( $class, delete $flags->{$flag} );
 967         }
 968         else {
 969             $class->log->warn(qq/Unknown flag "$flag"/);
 970         }
 971     }
 972
 973     eval { require Catalyst::Devel; };
 974     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 975         $class->log->warn(<<"EOF");
 976 You are running an old script!
 977
 978   Please update by running (this will overwrite existing files):
 979     catalyst.pl -force -scripts $class
 980
 981   or (this will not overwrite existing files):
 982     catalyst.pl -scripts $class
 983
 984 EOF
 985     }
 986
 987     if ( $class->debug ) {
 988         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 989
 990         if (@plugins) {
 991             my $column_width = Catalyst::Utils::term_width() - 6;
 992             my $t = Text::SimpleTable->new($column_width);
 993             $t->row($_) for @plugins;
 994             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 995         }
 996
 997         my $dispatcher = $class->dispatcher;
 998         my $engine     = $class->engine;
 999         my $home       = $class->config->{home};
1000
1001         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1002         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1003
1004         $home
1005           ? ( -d $home )
1006           ? $class->log->debug(qq/Found home "$home"/)
1007           : $class->log->debug(qq/Home "$home" doesn't exist/)
1008           : $class->log->debug(q/Couldn't find home/);
1009     }
1010
1011     # Call plugins setup, this is stupid and evil.
1012     # Also screws C3 badly on 5.10, hack to avoid.
1013     {
1014         no warnings qw/redefine/;
1015         local *setup = sub { };
1016         $class->setup unless $Catalyst::__AM_RESTARTING;
1017     }
1018
1019     $class->setup_components;
1020
1021     if (
1022         $class->debug and
1023         my $comps = $class->container->get_all_components($class)
1024     ) {
1025         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1026         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1027         $t->row( $_ => ref($comps->{$_}) ? 'instance' : 'class' ) for keys %$comps;
1028
1029         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" );
1030     }
1031
1032     $class->setup_actions;
1033
1034     if ( $class->debug ) {
1035         my $name = $class->config->{name} || 'Application';
1036         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1037     }
1038
1039     if ($class->config->{case_sensitive}) {
1040         $class->log->warn($class . "->config->{case_sensitive} is set.");
1041         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1042     }
1043
1044     $class->setup_finalize;
1045     # Should be the last thing we do so that user things hooking
1046     # setup_finalize can log..
1047     $class->log->_flush() if $class->log->can('_flush');
1048     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1049 }
1050
1051 =head2 $app->setup_finalize
1052
1053 A hook to attach modifiers to. This method does not do anything except set the
1054 C<setup_finished> accessor.
1055
1056 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1057
1058 Example:
1059
1060     after setup_finalize => sub {
1061         my $app = shift;
1062
1063         ## do stuff here..
1064     };
1065
1066 =cut
1067
1068 sub setup_finalize {
1069     my ($class) = @_;
1070     $class->setup_finished(1);
1071 }
1072
1073 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1074
1075 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1076
1077 Constructs an absolute L<URI> object based on the application root, the
1078 provided path, and the additional arguments and query parameters provided.
1079 When used as a string, provides a textual URI.  If you need more flexibility
1080 than this (i.e. the option to provide relative URIs etc.) see
1081 L<Catalyst::Plugin::SmartURI>.
1082
1083 If no arguments are provided, the URI for the current action is returned.
1084 To return the current action and also provide @args, use
1085 C<< $c->uri_for( $c->action, @args ) >>.
1086
1087 If the first argument is a string, it is taken as a public URI path relative
1088 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1089 relative to the application root (if it does). It is then merged with
1090 C<< $c->request->base >>; any C<@args> are appended as additional path
1091 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1092
1093 If the first argument is a L<Catalyst::Action> it represents an action which
1094 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1095 optional C<\@captures> argument (an arrayref) allows passing the captured
1096 variables that are needed to fill in the paths of Chained and Regex actions;
1097 once the path is resolved, C<uri_for> continues as though a path was
1098 provided, appending any arguments or parameters and creating an absolute
1099 URI.
1100
1101 The captures for the current request can be found in
1102 C<< $c->request->captures >>, and actions can be resolved using
1103 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1104 path, use C<< $c->uri_for_action >> instead.
1105
1106   # Equivalent to $c->req->uri
1107   $c->uri_for($c->action, $c->req->captures,
1108       @{ $c->req->args }, $c->req->params);
1109
1110   # For the Foo action in the Bar controller
1111   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1112
1113   # Path to a static resource
1114   $c->uri_for('/static/images/logo.png');
1115
1116 =cut
1117
1118 sub uri_for {
1119     my ( $c, $path, @args ) = @_;
1120
1121     if ( $path->$_isa('Catalyst::Controller') ) {
1122         $path = $path->path_prefix;
1123         $path =~ s{/+\z}{};
1124         $path .= '/';
1125     }
1126
1127     undef($path) if (defined $path && $path eq '');
1128
1129     my $params =
1130       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1131
1132     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1133     foreach my $arg (@args) {
1134         utf8::encode($arg) if utf8::is_utf8($arg);
1135         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1136     }
1137
1138     if ( $path->$_isa('Catalyst::Action') ) { # action object
1139         s|/|%2F|g for @args;
1140         my $captures = [ map { s|/|%2F|g; $_; }
1141                         ( scalar @args && ref $args[0] eq 'ARRAY'
1142                          ? @{ shift(@args) }
1143                          : ()) ];
1144
1145         foreach my $capture (@$captures) {
1146             utf8::encode($capture) if utf8::is_utf8($capture);
1147             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1148         }
1149
1150         my $action = $path;
1151         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1152         if( !@args && $action->number_of_args ) {
1153             my $expanded_action = $c->dispatcher->expand_action( $action );
1154
1155             my $num_captures = $expanded_action->number_of_captures;
1156             unshift @args, splice @$captures, $num_captures;
1157         }
1158
1159        $path = $c->dispatcher->uri_for_action($action, $captures);
1160         if (not defined $path) {
1161             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1162                 if $c->debug;
1163             return undef;
1164         }
1165         $path = '/' if $path eq '';
1166     }
1167
1168     unshift(@args, $path);
1169
1170     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1171         my $namespace = $c->namespace;
1172         if (defined $path) { # cheesy hack to handle path '../foo'
1173            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1174         }
1175         unshift(@args, $namespace || '');
1176     }
1177
1178     # join args with '/', or a blank string
1179     my $args = join('/', grep { defined($_) } @args);
1180     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1181     $args =~ s!^/+!!;
1182     my $base = $c->req->base;
1183     my $class = ref($base);
1184     $base =~ s{(?<!/)$}{/};
1185
1186     my $query = '';
1187
1188     if (my @keys = keys %$params) {
1189       # somewhat lifted from URI::_query's query_form
1190       $query = '?'.join('&', map {
1191           my $val = $params->{$_};
1192           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1193           s/ /+/g;
1194           my $key = $_;
1195           $val = '' unless defined $val;
1196           (map {
1197               my $param = "$_";
1198               utf8::encode( $param ) if utf8::is_utf8($param);
1199               # using the URI::Escape pattern here so utf8 chars survive
1200               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1201               $param =~ s/ /+/g;
1202               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1203       } @keys);
1204     }
1205
1206     my $res = bless(\"${base}${args}${query}", $class);
1207     $res;
1208 }
1209
1210 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1211
1212 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1213
1214 =over
1215
1216 =item $path
1217
1218 A private path to the Catalyst action you want to create a URI for.
1219
1220 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1221 >> and passing the resulting C<$action> and the remaining arguments to C<<
1222 $c->uri_for >>.
1223
1224 You can also pass in a Catalyst::Action object, in which case it is passed to
1225 C<< $c->uri_for >>.
1226
1227 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1228
1229 For example, if the action looks like:
1230
1231  package MyApp::Controller::Users;
1232
1233  sub lst : Path('the-list') {}
1234
1235 You can use:
1236
1237  $c->uri_for_action('/users/lst')
1238
1239 and it will create the URI /users/the-list.
1240
1241 =item \@captures_and_args?
1242
1243 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1244 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1245 to interpolate all the parameters in the URI.
1246
1247 =item @args?
1248
1249 Optional list of extra arguments - can be supplied in the
1250 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1251 code.
1252
1253 Your action can have zero, a fixed or a variable number of args (e.g.
1254 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1255
1256 =item \%query_values?
1257
1258 Optional array reference of query parameters to append. E.g.
1259
1260   { foo => 'bar' }
1261
1262 will generate
1263
1264   /rest/of/your/uri?foo=bar
1265
1266 =back
1267
1268 =cut
1269
1270 sub uri_for_action {
1271     my ( $c, $path, @args ) = @_;
1272     my $action = blessed($path)
1273       ? $path
1274       : $c->dispatcher->get_action_by_path($path);
1275     unless (defined $action) {
1276       croak "Can't find action for path '$path'";
1277     }
1278     return $c->uri_for( $action, @args );
1279 }
1280
1281 =head2 $c->welcome_message
1282
1283 Returns the Catalyst welcome HTML page.
1284
1285 =cut
1286
1287 sub welcome_message {
1288     my $c      = shift;
1289     my $name   = $c->config->{name};
1290     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1291     my $prefix = Catalyst::Utils::appprefix( ref $c );
1292     $c->response->content_type('text/html; charset=utf-8');
1293     return <<"EOF";
1294 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1295     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1296 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1297     <head>
1298     <meta http-equiv="Content-Language" content="en" />
1299     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1300         <title>$name on Catalyst $VERSION</title>
1301         <style type="text/css">
1302             body {
1303                 color: #000;
1304                 background-color: #eee;
1305             }
1306             div#content {
1307                 width: 640px;
1308                 margin-left: auto;
1309                 margin-right: auto;
1310                 margin-top: 10px;
1311                 margin-bottom: 10px;
1312                 text-align: left;
1313                 background-color: #ccc;
1314                 border: 1px solid #aaa;
1315             }
1316             p, h1, h2 {
1317                 margin-left: 20px;
1318                 margin-right: 20px;
1319                 font-family: verdana, tahoma, sans-serif;
1320             }
1321             a {
1322                 font-family: verdana, tahoma, sans-serif;
1323             }
1324             :link, :visited {
1325                     text-decoration: none;
1326                     color: #b00;
1327                     border-bottom: 1px dotted #bbb;
1328             }
1329             :link:hover, :visited:hover {
1330                     color: #555;
1331             }
1332             div#topbar {
1333                 margin: 0px;
1334             }
1335             pre {
1336                 margin: 10px;
1337                 padding: 8px;
1338             }
1339             div#answers {
1340                 padding: 8px;
1341                 margin: 10px;
1342                 background-color: #fff;
1343                 border: 1px solid #aaa;
1344             }
1345             h1 {
1346                 font-size: 0.9em;
1347                 font-weight: normal;
1348                 text-align: center;
1349             }
1350             h2 {
1351                 font-size: 1.0em;
1352             }
1353             p {
1354                 font-size: 0.9em;
1355             }
1356             p img {
1357                 float: right;
1358                 margin-left: 10px;
1359             }
1360             span#appname {
1361                 font-weight: bold;
1362                 font-size: 1.6em;
1363             }
1364         </style>
1365     </head>
1366     <body>
1367         <div id="content">
1368             <div id="topbar">
1369                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1370                     $VERSION</h1>
1371              </div>
1372              <div id="answers">
1373                  <p>
1374                  <img src="$logo" alt="Catalyst Logo" />
1375                  </p>
1376                  <p>Welcome to the  world of Catalyst.
1377                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1378                     framework will make web development something you had
1379                     never expected it to be: Fun, rewarding, and quick.</p>
1380                  <h2>What to do now?</h2>
1381                  <p>That really depends  on what <b>you</b> want to do.
1382                     We do, however, provide you with a few starting points.</p>
1383                  <p>If you want to jump right into web development with Catalyst
1384                     you might want to start with a tutorial.</p>
1385 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1386 </pre>
1387 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1388 <pre>
1389 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1390 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1391 </code></pre>
1392                  <h2>What to do next?</h2>
1393                  <p>Next it's time to write an actual application. Use the
1394                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1395                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1396                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1397                     they can save you a lot of work.</p>
1398                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1399                     <p>Also, be sure to check out the vast and growing
1400                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1401                     you are likely to find what you need there.
1402                     </p>
1403
1404                  <h2>Need help?</h2>
1405                  <p>Catalyst has a very active community. Here are the main places to
1406                     get in touch with us.</p>
1407                  <ul>
1408                      <li>
1409                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1410                      </li>
1411                      <li>
1412                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1413                      </li>
1414                      <li>
1415                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1416                      </li>
1417                  </ul>
1418                  <h2>In conclusion</h2>
1419                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1420                     as we enjoyed making it. Please contact us if you have ideas
1421                     for improvement or other feedback.</p>
1422              </div>
1423          </div>
1424     </body>
1425 </html>
1426 EOF
1427 }
1428
1429 =head2 run_options
1430
1431 Contains a hash of options passed from the application script, including
1432 the original ARGV the script received, the processed values from that
1433 ARGV and any extra arguments to the script which were not processed.
1434
1435 This can be used to add custom options to your application's scripts
1436 and setup your application differently depending on the values of these
1437 options.
1438
1439 =head1 INTERNAL METHODS
1440
1441 These methods are not meant to be used by end users.
1442
1443 =head2 $c->components
1444
1445 Returns a hash of components.
1446
1447 =cut
1448
1449 sub components {
1450     my ( $class, $comps ) = @_;
1451
1452     # people create components calling this sub directly, before setup
1453     $class->setup_config unless $class->container;
1454
1455     my $container = $class->container;
1456
1457     if ( $comps ) {
1458         $container->add_component( $_ ) for keys %$comps;
1459     }
1460
1461     return $container->get_all_components($class);
1462 }
1463
1464 =head2 $c->context_class
1465
1466 Returns or sets the context class.
1467
1468 =head2 $c->counter
1469
1470 Returns a hashref containing coderefs and execution counts (needed for
1471 deep recursion detection).
1472
1473 =head2 $c->depth
1474
1475 Returns the number of actions on the current internal execution stack.
1476
1477 =head2 $c->dispatch
1478
1479 Dispatches a request to actions.
1480
1481 =cut
1482
1483 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1484
1485 =head2 $c->dispatcher_class
1486
1487 Returns or sets the dispatcher class.
1488
1489 =head2 $c->dump_these
1490
1491 Returns a list of 2-element array references (name, structure) pairs
1492 that will be dumped on the error page in debug mode.
1493
1494 =cut
1495
1496 sub dump_these {
1497     my $c = shift;
1498     [ Request => $c->req ],
1499     [ Response => $c->res ],
1500     [ Stash => $c->stash ],
1501     [ Config => $c->config ];
1502 }
1503
1504 =head2 $c->engine_class
1505
1506 Returns or sets the engine class.
1507
1508 =head2 $c->execute( $class, $coderef )
1509
1510 Execute a coderef in given class and catch exceptions. Errors are available
1511 via $c->error.
1512
1513 =cut
1514
1515 sub execute {
1516     my ( $c, $class, $code ) = @_;
1517     $class = $c->component($class) || $class;
1518     $c->state(0);
1519
1520     if ( $c->depth >= $RECURSION ) {
1521         my $action = $code->reverse();
1522         $action = "/$action" unless $action =~ /->/;
1523         my $error = qq/Deep recursion detected calling "${action}"/;
1524         $c->log->error($error);
1525         $c->error($error);
1526         $c->state(0);
1527         return $c->state;
1528     }
1529
1530     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1531
1532     push( @{ $c->stack }, $code );
1533
1534     no warnings 'recursion';
1535     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1536     #      I have no idea how, ergo $ret (which appears to fix the issue)
1537     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1538
1539     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1540
1541     my $last = pop( @{ $c->stack } );
1542
1543     if ( my $error = $@ ) {
1544         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1545             $error->rethrow if $c->depth > 1;
1546         }
1547         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1548             $error->rethrow if $c->depth > 0;
1549         }
1550         else {
1551             unless ( ref $error ) {
1552                 no warnings 'uninitialized';
1553                 chomp $error;
1554                 my $class = $last->class;
1555                 my $name  = $last->name;
1556                 $error = qq/Caught exception in $class->$name "$error"/;
1557             }
1558             $c->error($error);
1559         }
1560         $c->state(0);
1561     }
1562     return $c->state;
1563 }
1564
1565 sub _stats_start_execute {
1566     my ( $c, $code ) = @_;
1567     my $appclass = ref($c) || $c;
1568     return if ( ( $code->name =~ /^_.*/ )
1569         && ( !$appclass->config->{show_internal_actions} ) );
1570
1571     my $action_name = $code->reverse();
1572     $c->counter->{$action_name}++;
1573
1574     my $action = $action_name;
1575     $action = "/$action" unless $action =~ /->/;
1576
1577     # determine if the call was the result of a forward
1578     # this is done by walking up the call stack and looking for a calling
1579     # sub of Catalyst::forward before the eval
1580     my $callsub = q{};
1581     for my $index ( 2 .. 11 ) {
1582         last
1583         if ( ( caller($index) )[0] eq 'Catalyst'
1584             && ( caller($index) )[3] eq '(eval)' );
1585
1586         if ( ( caller($index) )[3] =~ /forward$/ ) {
1587             $callsub = ( caller($index) )[3];
1588             $action  = "-> $action";
1589             last;
1590         }
1591     }
1592
1593     my $uid = $action_name . $c->counter->{$action_name};
1594
1595     # is this a root-level call or a forwarded call?
1596     if ( $callsub =~ /forward$/ ) {
1597         my $parent = $c->stack->[-1];
1598
1599         # forward, locate the caller
1600         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1601             $c->stats->profile(
1602                 begin  => $action,
1603                 parent => "$parent" . $c->counter->{"$parent"},
1604                 uid    => $uid,
1605             );
1606         }
1607         else {
1608
1609             # forward with no caller may come from a plugin
1610             $c->stats->profile(
1611                 begin => $action,
1612                 uid   => $uid,
1613             );
1614         }
1615     }
1616     else {
1617
1618         # root-level call
1619         $c->stats->profile(
1620             begin => $action,
1621             uid   => $uid,
1622         );
1623     }
1624     return $action;
1625
1626 }
1627
1628 sub _stats_finish_execute {
1629     my ( $c, $info ) = @_;
1630     $c->stats->profile( end => $info );
1631 }
1632
1633 =head2 $c->finalize
1634
1635 Finalizes the request.
1636
1637 =cut
1638
1639 sub finalize {
1640     my $c = shift;
1641
1642     for my $error ( @{ $c->error } ) {
1643         $c->log->error($error);
1644     }
1645
1646     # Allow engine to handle finalize flow (for POE)
1647     my $engine = $c->engine;
1648     if ( my $code = $engine->can('finalize') ) {
1649         $engine->$code($c);
1650     }
1651     else {
1652
1653         $c->finalize_uploads;
1654
1655         # Error
1656         if ( $#{ $c->error } >= 0 ) {
1657             $c->finalize_error;
1658         }
1659
1660         $c->finalize_headers unless $c->response->finalized_headers;
1661
1662         # HEAD request
1663         if ( $c->request->method eq 'HEAD' ) {
1664             $c->response->body('');
1665         }
1666
1667         $c->finalize_body;
1668     }
1669
1670     $c->log_response;
1671
1672     if ($c->use_stats) {
1673         my $elapsed = sprintf '%f', $c->stats->elapsed;
1674         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1675         $c->log->info(
1676             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1677     }
1678
1679     return $c->response->status;
1680 }
1681
1682 =head2 $c->finalize_body
1683
1684 Finalizes body.
1685
1686 =cut
1687
1688 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1689
1690 =head2 $c->finalize_cookies
1691
1692 Finalizes cookies.
1693
1694 =cut
1695
1696 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1697
1698 =head2 $c->finalize_error
1699
1700 Finalizes error.
1701
1702 =cut
1703
1704 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1705
1706 =head2 $c->finalize_headers
1707
1708 Finalizes headers.
1709
1710 =cut
1711
1712 sub finalize_headers {
1713     my $c = shift;
1714
1715     my $response = $c->response; #accessor calls can add up?
1716
1717     # Check if we already finalized headers
1718     return if $response->finalized_headers;
1719
1720     # Handle redirects
1721     if ( my $location = $response->redirect ) {
1722         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1723         $response->header( Location => $location );
1724
1725         if ( !$response->has_body ) {
1726             # Add a default body if none is already present
1727             $response->body(<<"EOF");
1728 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1729 <html xmlns="http://www.w3.org/1999/xhtml">
1730   <head>
1731     <title>Moved</title>
1732   </head>
1733   <body>
1734      <p>This item has moved <a href="$location">here</a>.</p>
1735   </body>
1736 </html>
1737 EOF
1738             $response->content_type('text/html; charset=utf-8');
1739         }
1740     }
1741
1742     # Content-Length
1743     if ( defined $response->body && length $response->body && !$response->content_length ) {
1744
1745         # get the length from a filehandle
1746         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1747         {
1748             my $size = -s $response->body;
1749             if ( $size ) {
1750                 $response->content_length( $size );
1751             }
1752             else {
1753                 $c->log->warn('Serving filehandle without a content-length');
1754             }
1755         }
1756         else {
1757             # everything should be bytes at this point, but just in case
1758             $response->content_length( length( $response->body ) );
1759         }
1760     }
1761
1762     # Errors
1763     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1764         $response->headers->remove_header("Content-Length");
1765         $response->body('');
1766     }
1767
1768     $c->finalize_cookies;
1769
1770     $c->response->finalize_headers();
1771
1772     # Done
1773     $response->finalized_headers(1);
1774 }
1775
1776 =head2 $c->finalize_output
1777
1778 An alias for finalize_body.
1779
1780 =head2 $c->finalize_read
1781
1782 Finalizes the input after reading is complete.
1783
1784 =cut
1785
1786 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1787
1788 =head2 $c->finalize_uploads
1789
1790 Finalizes uploads. Cleans up any temporary files.
1791
1792 =cut
1793
1794 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1795
1796 =head2 $c->get_action( $action, $namespace )
1797
1798 Gets an action in a given namespace.
1799
1800 =cut
1801
1802 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1803
1804 =head2 $c->get_actions( $action, $namespace )
1805
1806 Gets all actions of a given name in a namespace and all parent
1807 namespaces.
1808
1809 =cut
1810
1811 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1812
1813 =head2 $app->handle_request( @arguments )
1814
1815 Called to handle each HTTP request.
1816
1817 =cut
1818
1819 sub handle_request {
1820     my ( $class, @arguments ) = @_;
1821
1822     # Always expect worst case!
1823     my $status = -1;
1824     try {
1825         if ($class->debug) {
1826             my $secs = time - $START || 1;
1827             my $av = sprintf '%.3f', $COUNT / $secs;
1828             my $time = localtime time;
1829             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1830         }
1831
1832         my $c = $class->prepare(@arguments);
1833         $c->dispatch;
1834         $status = $c->finalize;
1835     }
1836     catch {
1837         chomp(my $error = $_);
1838         $class->log->error(qq/Caught exception in engine "$error"/);
1839     };
1840
1841     $COUNT++;
1842
1843     if(my $coderef = $class->log->can('_flush')){
1844         $class->log->$coderef();
1845     }
1846     return $status;
1847 }
1848
1849 =head2 $class->prepare( @arguments )
1850
1851 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1852 etc.).
1853
1854 =cut
1855
1856 has _uploadtmp => (
1857     is => 'ro',
1858     predicate => '_has_uploadtmp',
1859 );
1860
1861 sub prepare {
1862     my ( $class, @arguments ) = @_;
1863
1864     # XXX
1865     # After the app/ctxt split, this should become an attribute based on something passed
1866     # into the application.
1867     $class->context_class( ref $class || $class ) unless $class->context_class;
1868
1869     my $uploadtmp = $class->config->{uploadtmp};
1870     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
1871
1872     $c->response->_context($c);
1873
1874     #surely this is not the most efficient way to do things...
1875     $c->stats($class->stats_class->new)->enable($c->use_stats);
1876     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1877         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1878     }
1879
1880     try {
1881         # Allow engine to direct the prepare flow (for POE)
1882         if ( my $prepare = $c->engine->can('prepare') ) {
1883             $c->engine->$prepare( $c, @arguments );
1884         }
1885         else {
1886             $c->prepare_request(@arguments);
1887             $c->prepare_connection;
1888             $c->prepare_query_parameters;
1889             $c->prepare_headers; # Just hooks, no longer needed - they just
1890             $c->prepare_cookies; # cause the lazy attribute on req to build
1891             $c->prepare_path;
1892
1893             # Prepare the body for reading, either by prepare_body
1894             # or the user, if they are using $c->read
1895             $c->prepare_read;
1896
1897             # Parse the body unless the user wants it on-demand
1898             unless ( ref($c)->config->{parse_on_demand} ) {
1899                 $c->prepare_body;
1900             }
1901         }
1902         $c->prepare_action;
1903     }
1904     # VERY ugly and probably shouldn't rely on ->finalize actually working
1905     catch {
1906         # failed prepare is always due to an invalid request, right?
1907         $c->response->status(400);
1908         $c->response->content_type('text/plain');
1909         $c->response->body('Bad Request');
1910         # Note we call finalize and then die here, which escapes
1911         # finalize being called in the enclosing block..
1912         # It in fact couldn't be called, as we don't return $c..
1913         # This is a mess - but I'm unsure you can fix this without
1914         # breaking compat for people doing crazy things (we should set
1915         # the 400 and just return the ctx here IMO, letting finalize get called
1916         # above...
1917         $c->finalize;
1918         die $_;
1919     };
1920
1921     $c->log_request;
1922
1923     return $c;
1924 }
1925
1926 =head2 $c->prepare_action
1927
1928 Prepares action. See L<Catalyst::Dispatcher>.
1929
1930 =cut
1931
1932 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1933
1934 =head2 $c->prepare_body
1935
1936 Prepares message body.
1937
1938 =cut
1939
1940 sub prepare_body {
1941     my $c = shift;
1942
1943     return if $c->request->_has_body;
1944
1945     # Initialize on-demand data
1946     $c->engine->prepare_body( $c, @_ );
1947     $c->prepare_parameters;
1948     $c->prepare_uploads;
1949 }
1950
1951 =head2 $c->prepare_body_chunk( $chunk )
1952
1953 Prepares a chunk of data before sending it to L<HTTP::Body>.
1954
1955 See L<Catalyst::Engine>.
1956
1957 =cut
1958
1959 sub prepare_body_chunk {
1960     my $c = shift;
1961     $c->engine->prepare_body_chunk( $c, @_ );
1962 }
1963
1964 =head2 $c->prepare_body_parameters
1965
1966 Prepares body parameters.
1967
1968 =cut
1969
1970 sub prepare_body_parameters {
1971     my $c = shift;
1972     $c->engine->prepare_body_parameters( $c, @_ );
1973 }
1974
1975 =head2 $c->prepare_connection
1976
1977 Prepares connection.
1978
1979 =cut
1980
1981 sub prepare_connection {
1982     my $c = shift;
1983     # XXX - This is called on the engine (not the request) to maintain
1984     #       Engine::PSGI back compat.
1985     $c->engine->prepare_connection($c);
1986 }
1987
1988 =head2 $c->prepare_cookies
1989
1990 Prepares cookies by ensuring that the attribute on the request
1991 object has been built.
1992
1993 =cut
1994
1995 sub prepare_cookies { my $c = shift; $c->request->cookies }
1996
1997 =head2 $c->prepare_headers
1998
1999 Prepares request headers by ensuring that the attribute on the request
2000 object has been built.
2001
2002 =cut
2003
2004 sub prepare_headers { my $c = shift; $c->request->headers }
2005
2006 =head2 $c->prepare_parameters
2007
2008 Prepares parameters.
2009
2010 =cut
2011
2012 sub prepare_parameters {
2013     my $c = shift;
2014     $c->prepare_body_parameters;
2015     $c->engine->prepare_parameters( $c, @_ );
2016 }
2017
2018 =head2 $c->prepare_path
2019
2020 Prepares path and base.
2021
2022 =cut
2023
2024 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2025
2026 =head2 $c->prepare_query_parameters
2027
2028 Prepares query parameters.
2029
2030 =cut
2031
2032 sub prepare_query_parameters {
2033     my $c = shift;
2034
2035     $c->engine->prepare_query_parameters( $c, @_ );
2036 }
2037
2038 =head2 $c->log_request
2039
2040 Writes information about the request to the debug logs.  This includes:
2041
2042 =over 4
2043
2044 =item * Request method, path, and remote IP address
2045
2046 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2047
2048 =item * Request parameters
2049
2050 =item * File uploads
2051
2052 =back
2053
2054 =cut
2055
2056 sub log_request {
2057     my $c = shift;
2058
2059     return unless $c->debug;
2060
2061     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2062     my $request = $dump->[1];
2063
2064     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2065     $method ||= '';
2066     $path = '/' unless length $path;
2067     $address ||= '';
2068     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2069
2070     $c->log_request_headers($request->headers);
2071
2072     if ( my $keywords = $request->query_keywords ) {
2073         $c->log->debug("Query keywords are: $keywords");
2074     }
2075
2076     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2077
2078     $c->log_request_uploads($request);
2079 }
2080
2081 =head2 $c->log_response
2082
2083 Writes information about the response to the debug logs by calling
2084 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2085
2086 =cut
2087
2088 sub log_response {
2089     my $c = shift;
2090
2091     return unless $c->debug;
2092
2093     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2094     my $response = $dump->[1];
2095
2096     $c->log_response_status_line($response);
2097     $c->log_response_headers($response->headers);
2098 }
2099
2100 =head2 $c->log_response_status_line($response)
2101
2102 Writes one line of information about the response to the debug logs.  This includes:
2103
2104 =over 4
2105
2106 =item * Response status code
2107
2108 =item * Content-Type header (if present)
2109
2110 =item * Content-Length header (if present)
2111
2112 =back
2113
2114 =cut
2115
2116 sub log_response_status_line {
2117     my ($c, $response) = @_;
2118
2119     $c->log->debug(
2120         sprintf(
2121             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2122             $response->status                            || 'unknown',
2123             $response->headers->header('Content-Type')   || 'unknown',
2124             $response->headers->header('Content-Length') || 'unknown'
2125         )
2126     );
2127 }
2128
2129 =head2 $c->log_response_headers($headers);
2130
2131 Hook method which can be wrapped by plugins to log the response headers.
2132 No-op in the default implementation.
2133
2134 =cut
2135
2136 sub log_response_headers {}
2137
2138 =head2 $c->log_request_parameters( query => {}, body => {} )
2139
2140 Logs request parameters to debug logs
2141
2142 =cut
2143
2144 sub log_request_parameters {
2145     my $c          = shift;
2146     my %all_params = @_;
2147
2148     return unless $c->debug;
2149
2150     my $column_width = Catalyst::Utils::term_width() - 44;
2151     foreach my $type (qw(query body)) {
2152         my $params = $all_params{$type};
2153         next if ! keys %$params;
2154         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2155         for my $key ( sort keys %$params ) {
2156             my $param = $params->{$key};
2157             my $value = defined($param) ? $param : '';
2158             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2159         }
2160         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2161     }
2162 }
2163
2164 =head2 $c->log_request_uploads
2165
2166 Logs file uploads included in the request to the debug logs.
2167 The parameter name, filename, file type, and file size are all included in
2168 the debug logs.
2169
2170 =cut
2171
2172 sub log_request_uploads {
2173     my $c = shift;
2174     my $request = shift;
2175     return unless $c->debug;
2176     my $uploads = $request->uploads;
2177     if ( keys %$uploads ) {
2178         my $t = Text::SimpleTable->new(
2179             [ 12, 'Parameter' ],
2180             [ 26, 'Filename' ],
2181             [ 18, 'Type' ],
2182             [ 9,  'Size' ]
2183         );
2184         for my $key ( sort keys %$uploads ) {
2185             my $upload = $uploads->{$key};
2186             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2187                 $t->row( $key, $u->filename, $u->type, $u->size );
2188             }
2189         }
2190         $c->log->debug( "File Uploads are:\n" . $t->draw );
2191     }
2192 }
2193
2194 =head2 $c->log_request_headers($headers);
2195
2196 Hook method which can be wrapped by plugins to log the request headers.
2197 No-op in the default implementation.
2198
2199 =cut
2200
2201 sub log_request_headers {}
2202
2203 =head2 $c->log_headers($type => $headers)
2204
2205 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2206
2207 =cut
2208
2209 sub log_headers {
2210     my $c       = shift;
2211     my $type    = shift;
2212     my $headers = shift;    # an HTTP::Headers instance
2213
2214     return unless $c->debug;
2215
2216     my $column_width = Catalyst::Utils::term_width() - 28;
2217     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2218     $headers->scan(
2219         sub {
2220             my ( $name, $value ) = @_;
2221             $t->row( $name, $value );
2222         }
2223     );
2224     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2225 }
2226
2227
2228 =head2 $c->prepare_read
2229
2230 Prepares the input for reading.
2231
2232 =cut
2233
2234 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2235
2236 =head2 $c->prepare_request
2237
2238 Prepares the engine request.
2239
2240 =cut
2241
2242 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2243
2244 =head2 $c->prepare_uploads
2245
2246 Prepares uploads.
2247
2248 =cut
2249
2250 sub prepare_uploads {
2251     my $c = shift;
2252
2253     $c->engine->prepare_uploads( $c, @_ );
2254 }
2255
2256 =head2 $c->prepare_write
2257
2258 Prepares the output for writing.
2259
2260 =cut
2261
2262 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2263
2264 =head2 $c->request_class
2265
2266 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2267
2268 =head2 $c->response_class
2269
2270 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2271
2272 =head2 $c->read( [$maxlength] )
2273
2274 Reads a chunk of data from the request body. This method is designed to
2275 be used in a while loop, reading C<$maxlength> bytes on every call.
2276 C<$maxlength> defaults to the size of the request if not specified.
2277
2278 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2279 directly.
2280
2281 Warning: If you use read(), Catalyst will not process the body,
2282 so you will not be able to access POST parameters or file uploads via
2283 $c->request.  You must handle all body parsing yourself.
2284
2285 =cut
2286
2287 sub read { my $c = shift; return $c->request->read( @_ ) }
2288
2289 =head2 $c->run
2290
2291 Starts the engine.
2292
2293 =cut
2294
2295 sub run {
2296   my $app = shift;
2297   $app->_make_immutable_if_needed;
2298   $app->engine_loader->needs_psgi_engine_compat_hack ?
2299     $app->engine->run($app, @_) :
2300       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2301 }
2302
2303 sub _make_immutable_if_needed {
2304     my $class = shift;
2305     my $meta = Class::MOP::get_metaclass_by_name($class);
2306     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2307     if (
2308         $meta->is_immutable
2309         && ! { $meta->immutable_options }->{replace_constructor}
2310         && $isa_ca
2311     ) {
2312         warn("You made your application class ($class) immutable, "
2313             . "but did not inline the\nconstructor. "
2314             . "This will break catalyst, as your app \@ISA "
2315             . "Class::Accessor(::Fast)?\nPlease pass "
2316             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2317     }
2318     unless ($meta->is_immutable) {
2319         # XXX - FIXME warning here as you should make your app immutable yourself.
2320         $meta->make_immutable(
2321             replace_constructor => 1,
2322         );
2323     }
2324 }
2325
2326 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2327
2328 Sets an action in a given namespace.
2329
2330 =cut
2331
2332 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2333
2334 =head2 $c->setup_actions($component)
2335
2336 Sets up actions for a component.
2337
2338 =cut
2339
2340 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2341
2342 =head2 $c->setup_config
2343
2344 =cut
2345
2346 sub setup_config {
2347     my $class = shift;
2348
2349     my %args = %{ $class->config || {} };
2350
2351     my $container_class;
2352
2353     if ( exists $args{container_class} ) {
2354         $container_class = delete $args{container_class};
2355         Class::MOP::load_class($container_class);
2356     }
2357     else {
2358         $container_class = Class::MOP::load_first_existing_class("${class}::Container", 'Catalyst::IOC::Container');
2359     }
2360
2361     my $container = $container_class->new( %args, name => $class );
2362     $class->container($container);
2363
2364     my $config = $container->resolve( service => 'config' );
2365     $class->config($config);
2366     $class->finalize_config; # back-compat
2367 }
2368
2369 =head2 $c->finalize_config
2370
2371 =cut
2372
2373 sub finalize_config { }
2374
2375 =head2 $c->setup_components
2376
2377 This method is called internally to set up the application's components.
2378
2379 It finds modules by calling the L<locate_components> method, expands them to
2380 package names with the $container->expand_component_module method, and then
2381 installs each component into the application.
2382
2383 The C<setup_components> config option is passed to both of the above methods.
2384
2385 =cut
2386
2387 sub setup_components { shift->container->setup_components }
2388
2389 =head2 locate_components
2390
2391 =cut
2392
2393 sub locate_components {
2394     my $class = shift;
2395
2396     $class->log->warn('The locate_components method has been deprecated.');
2397     $class->log->warn('Please read Catalyst::IOC::Container documentation to');
2398     $class->log->warn('update your application.');
2399
2400     # XXX think about ditching this sort entirely
2401     return sort { length $a <=> length $b }
2402         @{ $class->container->resolve( service => 'locate_components' ) };
2403 }
2404
2405 =head2 $c->setup_dispatcher
2406
2407 Sets up dispatcher.
2408
2409 =cut
2410
2411 sub setup_dispatcher {
2412     my ( $class, $dispatcher ) = @_;
2413
2414     if ($dispatcher) {
2415         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2416     }
2417
2418     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2419         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2420     }
2421
2422     unless ($dispatcher) {
2423         $dispatcher = $class->dispatcher_class;
2424     }
2425
2426     Class::MOP::load_class($dispatcher);
2427
2428     # dispatcher instance
2429     $class->dispatcher( $dispatcher->new );
2430 }
2431
2432 =head2 $c->setup_engine
2433
2434 Sets up engine.
2435
2436 =cut
2437
2438 sub engine_class {
2439     my ($class, $requested_engine) = @_;
2440
2441     if (!$class->engine_loader || $requested_engine) {
2442         $class->engine_loader(
2443             Catalyst::EngineLoader->new({
2444                 application_name => $class,
2445                 (defined $requested_engine
2446                      ? (catalyst_engine_class => $requested_engine) : ()),
2447             }),
2448         );
2449     }
2450
2451     $class->engine_loader->catalyst_engine_class;
2452 }
2453
2454 sub setup_engine {
2455     my ($class, $requested_engine) = @_;
2456
2457     my $engine = do {
2458         my $loader = $class->engine_loader;
2459
2460         if (!$loader || $requested_engine) {
2461             $loader = Catalyst::EngineLoader->new({
2462                 application_name => $class,
2463                 (defined $requested_engine
2464                      ? (requested_engine => $requested_engine) : ()),
2465             }),
2466
2467             $class->engine_loader($loader);
2468         }
2469
2470         $loader->catalyst_engine_class;
2471     };
2472
2473     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2474     return if $class->loading_psgi_file;
2475
2476     Class::MOP::load_class($engine);
2477
2478     if ($ENV{MOD_PERL}) {
2479         my $apache = $class->engine_loader->auto;
2480
2481         my $meta = find_meta($class);
2482         my $was_immutable = $meta->is_immutable;
2483         my %immutable_options = $meta->immutable_options;
2484         $meta->make_mutable if $was_immutable;
2485
2486         $meta->add_method(handler => sub {
2487             my $r = shift;
2488             my $psgi_app = $class->_finalized_psgi_app;
2489             $apache->call_app($r, $psgi_app);
2490         });
2491
2492         $meta->make_immutable(%immutable_options) if $was_immutable;
2493     }
2494
2495     $class->engine( $engine->new );
2496
2497     return;
2498 }
2499
2500 sub _finalized_psgi_app {
2501     my ($app) = @_;
2502
2503     unless ($app->_psgi_app) {
2504         my $psgi_app = $app->_setup_psgi_app;
2505         $app->_psgi_app($psgi_app);
2506     }
2507
2508     return $app->_psgi_app;
2509 }
2510
2511 sub _setup_psgi_app {
2512     my ($app) = @_;
2513
2514     for my $home (Path::Class::Dir->new($app->config->{home})) {
2515         my $psgi_file = $home->file(
2516             Catalyst::Utils::appprefix($app) . '.psgi',
2517         );
2518
2519         next unless -e $psgi_file;
2520
2521         # If $psgi_file calls ->setup_engine, it's doing so to load
2522         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2523         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2524         # anyway. So set a flag (ick) that tells setup_engine not to populate
2525         # $c->engine or do any other things we might regret.
2526
2527         $app->loading_psgi_file(1);
2528         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2529         $app->loading_psgi_file(0);
2530
2531         return $psgi_app
2532             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2533
2534         warn <<"EOW";
2535 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2536
2537 Its content has been ignored. Please consult the Catalyst::Upgrading
2538 documentation on how to upgrade from Catalyst::Engine::PSGI.
2539 EOW
2540     }
2541
2542     return $app->apply_default_middlewares($app->psgi_app);
2543 }
2544
2545 =head2 $c->apply_default_middlewares
2546
2547 Adds the following L<Plack> middlewares to your application, since they are
2548 useful and commonly needed:
2549
2550 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2551 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2552 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2553 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2554 applied since this middleware is smart enough to conditionally apply itself).
2555
2556 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2557 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2558 $ENV{SCRIPT_NAME}
2559
2560 =cut
2561
2562
2563 sub apply_default_middlewares {
2564     my ($app, $psgi_app) = @_;
2565
2566     $psgi_app = Plack::Middleware::Conditional->wrap(
2567         $psgi_app,
2568         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2569         condition => sub {
2570             my ($env) = @_;
2571             return if $app->config->{ignore_frontend_proxy};
2572             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2573                 || $app->config->{using_frontend_proxy};
2574         },
2575     );
2576
2577     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2578     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2579     $psgi_app = Plack::Middleware::Conditional->wrap(
2580         $psgi_app,
2581         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2582         condition => sub {
2583             my ($env) = @_;
2584             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2585             return unless $1 < 4.23;
2586             1;
2587         },
2588     );
2589
2590     # we're applying this unconditionally as the middleware itself already makes
2591     # sure it doesn't fuck things up if it's not running under one of the right
2592     # IIS versions
2593     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2594
2595     # And another IIS issue, this time with IIS7.
2596     $psgi_app = Plack::Middleware::Conditional->wrap(
2597         $psgi_app,
2598         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2599         condition => sub {
2600             my ($env) = @_;
2601             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2602         },
2603     );
2604
2605     return $psgi_app;
2606 }
2607
2608 =head2 $c->psgi_app
2609
2610 Returns a PSGI application code reference for the catalyst application
2611 C<$c>. This is the bare application without any middlewares
2612 applied. C<${myapp}.psgi> is not taken into account.
2613
2614 This is what you want to be using to retrieve the PSGI application code
2615 reference of your Catalyst application for use in F<.psgi> files.
2616
2617 =cut
2618
2619 sub psgi_app {
2620     my ($app) = @_;
2621     return $app->engine->build_psgi_app($app);
2622 }
2623
2624 =head2 $c->setup_home
2625
2626 Sets up the home directory.
2627
2628 =cut
2629
2630 sub setup_home {
2631     my ( $class, $home_flag ) = @_;
2632
2633     my $home = $class->container->resolve(
2634         service    => 'home',
2635         parameters => {
2636             home_flag => $home_flag
2637         },
2638     );
2639
2640     if ($home) {
2641         #I remember recently being scolded for assigning config values like this
2642         $class->config->{home} ||= $home;
2643         $class->config->{root} ||= $class->container->resolve(service => 'root_dir');
2644     }
2645 }
2646
2647 =head2 $c->setup_log
2648
2649 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2650 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2651 log to.
2652
2653 This method also installs a C<debug> method that returns a true value into the
2654 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2655 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2656
2657 Note that if the log has already been setup, by either a previous call to
2658 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2659 that this method won't actually set up the log object.
2660
2661 =cut
2662
2663 sub setup_log {
2664     my ( $class, $levels ) = @_;
2665
2666     $levels ||= '';
2667     $levels =~ s/^\s+//;
2668     $levels =~ s/\s+$//;
2669     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2670
2671     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2672     if ( defined $env_debug ) {
2673         $levels{debug} = 1 if $env_debug; # Ugly!
2674         delete($levels{debug}) unless $env_debug;
2675     }
2676
2677     unless ( $class->log ) {
2678         $class->log( Catalyst::Log->new(keys %levels) );
2679     }
2680
2681     if ( $levels{debug} ) {
2682         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2683         $class->log->debug('Debug messages enabled');
2684     }
2685 }
2686
2687 =head2 $c->setup_plugins
2688
2689 Sets up plugins.
2690
2691 =cut
2692
2693 =head2 $c->setup_stats
2694
2695 Sets up timing statistics class.
2696
2697 =cut
2698
2699 sub setup_stats {
2700     my ( $class, $stats ) = @_;
2701
2702     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2703
2704     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2705     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2706         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2707         $class->log->debug('Statistics enabled');
2708     }
2709 }
2710
2711
2712 =head2 $c->registered_plugins
2713
2714 Returns a sorted list of the plugins which have either been stated in the
2715 import list.
2716
2717 If passed a given plugin name, it will report a boolean value indicating
2718 whether or not that plugin is loaded.  A fully qualified name is required if
2719 the plugin name does not begin with C<Catalyst::Plugin::>.
2720
2721  if ($c->registered_plugins('Some::Plugin')) {
2722      ...
2723  }
2724
2725 =cut
2726
2727 {
2728
2729     sub registered_plugins {
2730         my $proto = shift;
2731         return sort keys %{ $proto->_plugins } unless @_;
2732         my $plugin = shift;
2733         return 1 if exists $proto->_plugins->{$plugin};
2734         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2735     }
2736
2737     sub _register_plugin {
2738         my ( $proto, $plugin, $instant ) = @_;
2739         my $class = ref $proto || $proto;
2740
2741         Class::MOP::load_class( $plugin );
2742         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2743             if $plugin->isa( 'Catalyst::Component' );
2744         my $plugin_meta = Moose::Meta::Class->create($plugin);
2745         if (!$plugin_meta->has_method('new')
2746             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
2747             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
2748         }
2749         if (!$instant && !$proto->_plugins->{$plugin}) {
2750             my $meta = Class::MOP::get_metaclass_by_name($class);
2751             $meta->superclasses($plugin, $meta->superclasses);
2752         }
2753         $proto->_plugins->{$plugin} = 1;
2754         return $class;
2755     }
2756
2757     sub setup_plugins {
2758         my ( $class, $plugins ) = @_;
2759
2760         $class->_plugins( {} ) unless $class->_plugins;
2761         $plugins = Data::OptList::mkopt($plugins || []);
2762
2763         my @plugins = map {
2764             [ Catalyst::Utils::resolve_namespace(
2765                   $class . '::Plugin',
2766                   'Catalyst::Plugin', $_->[0]
2767               ),
2768               $_->[1],
2769             ]
2770          } @{ $plugins };
2771
2772         for my $plugin ( reverse @plugins ) {
2773             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2774             my $meta = find_meta($plugin->[0]);
2775             next if $meta && $meta->isa('Moose::Meta::Role');
2776
2777             $class->_register_plugin($plugin->[0]);
2778         }
2779
2780         my @roles =
2781             map  { $_->[0]->name, $_->[1] }
2782             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2783             map  { [find_meta($_->[0]), $_->[1]] }
2784             @plugins;
2785
2786         Moose::Util::apply_all_roles(
2787             $class => @roles
2788         ) if @roles;
2789     }
2790 }
2791
2792 =head2 $c->stack
2793
2794 Returns an arrayref of the internal execution stack (actions that are
2795 currently executing).
2796
2797 =head2 $c->stats
2798
2799 Returns the current timing statistics object. By default Catalyst uses
2800 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2801 L<< stats_class|/"$c->stats_class" >>.
2802
2803 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2804 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2805 profile explicitly, although MyApp.pm still won't profile nor output anything
2806 by itself.
2807
2808 =head2 $c->stats_class
2809
2810 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2811
2812 =head2 $c->use_stats
2813
2814 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2815
2816 Note that this is a static method, not an accessor and should be overridden
2817 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2818
2819 =cut
2820
2821 sub use_stats { 0 }
2822
2823
2824 =head2 $c->write( $data )
2825
2826 Writes $data to the output stream. When using this method directly, you
2827 will need to manually set the C<Content-Length> header to the length of
2828 your output data, if known.
2829
2830 =cut
2831
2832 sub write {
2833     my $c = shift;
2834
2835     # Finalize headers if someone manually writes output (for compat)
2836     $c->finalize_headers;
2837
2838     return $c->response->write( @_ );
2839 }
2840
2841 =head2 version
2842
2843 Returns the Catalyst version number. Mostly useful for "powered by"
2844 messages in template systems.
2845
2846 =cut
2847
2848 sub version { return $Catalyst::VERSION }
2849
2850 =head1 CONFIGURATION
2851
2852 There are a number of 'base' config variables which can be set:
2853
2854 =over
2855
2856 =item *
2857
2858 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2859
2860 =item *
2861
2862 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2863
2864 =item *
2865
2866 C<home> - The application home directory. In an uninstalled application,
2867 this is the top level application directory. In an installed application,
2868 this will be the directory containing C<< MyApp.pm >>.
2869
2870 =item *
2871
2872 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2873
2874 =item *
2875
2876 C<name> - The name of the application in debug messages and the debug and
2877 welcome screens
2878
2879 =item *
2880
2881 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2882 until it is accessed. This allows you to (for example) check authentication (and reject
2883 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
2884
2885 =item *
2886
2887 C<root> - The root directory for templates. Usually this is just a
2888 subdirectory of the home directory, but you can set it to change the
2889 templates to a different directory.
2890
2891 =item *
2892
2893 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2894 to be shown in hit debug tables in the test server.
2895
2896 =item *
2897
2898 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
2899 variable should be used for determining the request path.
2900
2901 Most web server environments pass the requested path to the application using environment variables,
2902 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
2903 exposed as C<< $c->request->base >>) and the request path below that base.
2904
2905 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
2906 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
2907
2908 =over
2909
2910 =item use_request_uri_for_path => 0
2911
2912 This is the default (and the) traditional method that Catalyst has used for determining the path information.
2913 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
2914 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
2915 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
2916
2917 However this method has the major disadvantage that it is impossible to correctly decode some elements
2918 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
2919 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
2920 can't distinguish / vs %2F in paths (in addition to other encoded values).
2921
2922 =item use_request_uri_for_path => 1
2923
2924 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
2925 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
2926 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
2927
2928 Given that this method of path resolution is provably more correct, it is recommended that you use
2929 this unless you have a specific need to deploy your application in a non-standard environment, and you are
2930 aware of the implications of not being able to handle encoded URI paths correctly.
2931
2932 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
2933 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
2934 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
2935 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
2936 C<< $c->request->base >> will be incorrect.
2937
2938 =back
2939
2940 =item *
2941
2942 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2943
2944 =back
2945
2946 =head1 INTERNAL ACTIONS
2947
2948 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2949 C<_ACTION>, and C<_END>. These are by default not shown in the private
2950 action table, but you can make them visible with a config parameter.
2951
2952     MyApp->config(show_internal_actions => 1);
2953
2954 =head1 ON-DEMAND PARSER
2955
2956 The request body is usually parsed at the beginning of a request,
2957 but if you want to handle input yourself, you can enable on-demand
2958 parsing with a config parameter.
2959
2960     MyApp->config(parse_on_demand => 1);
2961
2962 =head1 PROXY SUPPORT
2963
2964 Many production servers operate using the common double-server approach,
2965 with a lightweight frontend web server passing requests to a larger
2966 backend server. An application running on the backend server must deal
2967 with two problems: the remote user always appears to be C<127.0.0.1> and
2968 the server's hostname will appear to be C<localhost> regardless of the
2969 virtual host that the user connected through.
2970
2971 Catalyst will automatically detect this situation when you are running
2972 the frontend and backend servers on the same machine. The following
2973 changes are made to the request.
2974
2975     $c->req->address is set to the user's real IP address, as read from
2976     the HTTP X-Forwarded-For header.
2977
2978     The host value for $c->req->base and $c->req->uri is set to the real
2979     host, as read from the HTTP X-Forwarded-Host header.
2980
2981 Additionally, you may be running your backend application on an insecure
2982 connection (port 80) while your frontend proxy is running under SSL.  If there
2983 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2984 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2985 be created properly.
2986
2987 In the case of passing in:
2988
2989     X-Forwarded-Port: 443
2990
2991 All calls to C<uri_for> will result in an https link, as is expected.
2992
2993 Obviously, your web server must support these headers for this to work.
2994
2995 In a more complex server farm environment where you may have your
2996 frontend proxy server(s) on different machines, you will need to set a
2997 configuration option to tell Catalyst to read the proxied data from the
2998 headers.
2999
3000     MyApp->config(using_frontend_proxy => 1);
3001
3002 If you do not wish to use the proxy support at all, you may set:
3003
3004     MyApp->config(ignore_frontend_proxy => 0);
3005
3006 =head2 Note about psgi files
3007
3008 Note that if you supply your own .psgi file, calling
3009 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3010
3011 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3012 in your psgi, for example:
3013
3014     builder {
3015         enable "Plack::Middleware::ReverseProxy";
3016         MyApp->psgi_app
3017     };
3018
3019 This will unconditionally add the ReverseProxy support, or you need to call
3020 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3021 apply the support depending upon your config).
3022
3023 See L<Catalyst::PSGI> for more information.
3024
3025 =head1 THREAD SAFETY
3026
3027 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3028 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3029 believe the Catalyst core to be thread-safe.
3030
3031 If you plan to operate in a threaded environment, remember that all other
3032 modules you are using must also be thread-safe. Some modules, most notably
3033 L<DBD::SQLite>, are not thread-safe.
3034
3035 =head1 SUPPORT
3036
3037 IRC:
3038
3039     Join #catalyst on irc.perl.org.
3040
3041 Mailing Lists:
3042
3043     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3044     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3045
3046 Web:
3047
3048     http://catalyst.perl.org
3049
3050 Wiki:
3051
3052     http://dev.catalyst.perl.org
3053
3054 =head1 SEE ALSO
3055
3056 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3057
3058 =head2 L<Catalyst::Manual> - The Catalyst Manual
3059
3060 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3061
3062 =head2 L<Catalyst::Engine> - Core engine
3063
3064 =head2 L<Catalyst::Log> - Log class.
3065
3066 =head2 L<Catalyst::Request> - Request object
3067
3068 =head2 L<Catalyst::Response> - Response object
3069
3070 =head2 L<Catalyst::Test> - The test suite.
3071
3072 =head1 PROJECT FOUNDER
3073
3074 sri: Sebastian Riedel <sri@cpan.org>
3075
3076 =head1 CONTRIBUTORS
3077
3078 abw: Andy Wardley
3079
3080 acme: Leon Brocard <leon@astray.com>
3081
3082 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3083
3084 Andrew Bramble
3085
3086 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3087
3088 Andrew Ruthven
3089
3090 André Walker
3091
3092 andyg: Andy Grundman <andy@hybridized.org>
3093
3094 audreyt: Audrey Tang
3095
3096 bricas: Brian Cassidy <bricas@cpan.org>
3097
3098 Caelum: Rafael Kitover <rkitover@io.com>
3099
3100 chansen: Christian Hansen
3101
3102 chicks: Christopher Hicks
3103
3104 Chisel Wright C<pause@herlpacker.co.uk>
3105
3106 Danijel Milicevic C<me@danijel.de>
3107
3108 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3109
3110 David Naughton, C<naughton@umn.edu>
3111
3112 David E. Wheeler
3113
3114 dhoss: Devin Austin <dhoss@cpan.org>
3115
3116 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3117
3118 Drew Taylor
3119
3120 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3121
3122 esskar: Sascha Kiefer
3123
3124 fireartist: Carl Franks <cfranks@cpan.org>
3125
3126 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3127
3128 gabb: Danijel Milicevic
3129
3130 Gary Ashton Jones
3131
3132 Gavin Henry C<ghenry@perl.me.uk>
3133
3134 Geoff Richards
3135
3136 groditi: Guillermo Roditi <groditi@gmail.com>
3137
3138 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3139
3140 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3141
3142 jcamacho: Juan Camacho
3143
3144 jester: Jesse Sheidlower C<jester@panix.com>
3145
3146 jhannah: Jay Hannah <jay@jays.net>
3147
3148 Jody Belka
3149
3150 Johan Lindstrom
3151
3152 jon: Jon Schutz <jjschutz@cpan.org>
3153
3154 Jonathan Rockway C<< <jrockway@cpan.org> >>
3155
3156 Kieren Diment C<kd@totaldatasolution.com>
3157
3158 konobi: Scott McWhirter <konobi@cpan.org>
3159
3160 marcus: Marcus Ramberg <mramberg@cpan.org>
3161
3162 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3163
3164 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3165
3166 mugwump: Sam Vilain
3167
3168 naughton: David Naughton
3169
3170 ningu: David Kamholz <dkamholz@cpan.org>
3171
3172 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3173
3174 numa: Dan Sully <daniel@cpan.org>
3175
3176 obra: Jesse Vincent
3177
3178 Octavian Rasnita
3179
3180 omega: Andreas Marienborg
3181
3182 Oleg Kostyuk <cub.uanic@gmail.com>
3183
3184 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3185
3186 rafl: Florian Ragwitz <rafl@debian.org>
3187
3188 random: Roland Lammel <lammel@cpan.org>
3189
3190 Robert Sedlacek C<< <rs@474.at> >>
3191
3192 SpiceMan: Marcel Montes
3193
3194 sky: Arthur Bergman
3195
3196 szbalint: Balint Szilakszi <szbalint@cpan.org>
3197
3198 t0m: Tomas Doran <bobtfish@bobtfish.net>
3199
3200 Ulf Edvinsson
3201
3202 Viljo Marrandi C<vilts@yahoo.com>
3203
3204 Will Hawes C<info@whawes.co.uk>
3205
3206 willert: Sebastian Willert <willert@cpan.org>
3207
3208 wreis: Wallace Reis <wallace@reis.org.br>
3209
3210 Yuval Kogman, C<nothingmuch@woobling.org>
3211
3212 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3213
3214 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3215
3216 =head1 COPYRIGHT
3217
3218 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3219
3220 =head1 LICENSE
3221
3222 This library is free software. You can redistribute it and/or modify it under
3223 the same terms as Perl itself.
3224
3225 =cut
3226
3227 no Moose;
3228
3229 __PACKAGE__->meta->make_immutable;
3230
3231 1;