make sure we still properly decode the part name
[catagits/Catalyst-Runtime.git] / lib / Catalyst.pm
1 package Catalyst;
2
3 use Moose;
4 use Moose::Meta::Class ();
5 extends 'Catalyst::Component';
6 use Moose::Util qw/find_meta/;
7 use namespace::clean -except => 'meta';
8 use Catalyst::Exception;
9 use Catalyst::Exception::Detach;
10 use Catalyst::Exception::Go;
11 use Catalyst::Log;
12 use Catalyst::Request;
13 use Catalyst::Request::Upload;
14 use Catalyst::Response;
15 use Catalyst::Utils;
16 use Catalyst::Controller;
17 use Data::OptList;
18 use Devel::InnerPackage ();
19 use Module::Pluggable::Object ();
20 use Text::SimpleTable ();
21 use Path::Class::Dir ();
22 use Path::Class::File ();
23 use URI ();
24 use URI::http;
25 use URI::https;
26 use HTML::Entities;
27 use Tree::Simple qw/use_weak_refs/;
28 use Tree::Simple::Visitor::FindByUID;
29 use Class::C3::Adopt::NEXT;
30 use List::MoreUtils qw/uniq/;
31 use attributes;
32 use String::RewritePrefix;
33 use Catalyst::EngineLoader;
34 use utf8;
35 use Carp qw/croak carp shortmess/;
36 use Try::Tiny;
37 use Safe::Isa;
38 use Moose::Util 'find_meta';
39 use Plack::Middleware::Conditional;
40 use Plack::Middleware::ReverseProxy;
41 use Plack::Middleware::IIS6ScriptNameFix;
42 use Plack::Middleware::IIS7KeepAliveFix;
43 use Plack::Middleware::LighttpdScriptNameFix;
44 use Plack::Middleware::ContentLength;
45 use Plack::Middleware::Head;
46 use Plack::Middleware::HTTPExceptions;
47 use Plack::Middleware::FixMissingBodyInRedirect;
48 use Plack::Middleware::MethodOverride;
49 use Plack::Middleware::RemoveRedundantBody;
50 use Catalyst::Middleware::Stash;
51 use Plack::Util;
52 use Class::Load 'load_class';
53 use Encode 2.21 'decode_utf8', 'encode_utf8';
54
55 BEGIN { require 5.008003; }
56
57 has stack => (is => 'ro', default => sub { [] });
58 has state => (is => 'rw', default => 0);
59 has stats => (is => 'rw');
60 has action => (is => 'rw');
61 has counter => (is => 'rw', default => sub { {} });
62 has request => (
63     is => 'rw',
64     default => sub {
65         my $self = shift;
66         $self->request_class->new($self->_build_request_constructor_args);
67     },
68     lazy => 1,
69 );
70 sub _build_request_constructor_args {
71     my $self = shift;
72     my %p = ( _log => $self->log );
73     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
74     $p{data_handlers} = {$self->registered_data_handlers};
75     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
76       if $self->config->{use_hash_multivalue_in_request};
77     \%p;
78 }
79
80 has response => (
81     is => 'rw',
82     default => sub {
83         my $self = shift;
84         $self->response_class->new($self->_build_response_constructor_args);
85     },
86     lazy => 1,
87 );
88 sub _build_response_constructor_args {
89     return +{
90       _log => $_[0]->log,
91       encoding => $_[0]->encoding,
92     };
93 }
94
95 has namespace => (is => 'rw');
96
97 sub depth { scalar @{ shift->stack || [] }; }
98 sub comp { shift->component(@_) }
99
100 sub req {
101     my $self = shift; return $self->request(@_);
102 }
103 sub res {
104     my $self = shift; return $self->response(@_);
105 }
106
107 # For backwards compatibility
108 sub finalize_output { shift->finalize_body(@_) };
109
110 # For statistics
111 our $COUNT     = 1;
112 our $START     = time;
113 our $RECURSION = 1000;
114 our $DETACH    = Catalyst::Exception::Detach->new;
115 our $GO        = Catalyst::Exception::Go->new;
116
117 #I imagine that very few of these really need to be class variables. if any.
118 #maybe we should just make them attributes with a default?
119 __PACKAGE__->mk_classdata($_)
120   for qw/components arguments dispatcher engine log dispatcher_class
121   engine_loader context_class request_class response_class stats_class
122   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
123   _data_handlers _encoding _encode_check finalized_default_middleware/;
124
125 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
126 __PACKAGE__->request_class('Catalyst::Request');
127 __PACKAGE__->response_class('Catalyst::Response');
128 __PACKAGE__->stats_class('Catalyst::Stats');
129 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
130
131 # Remember to update this in Catalyst::Runtime as well!
132 our $VERSION = '5.90084';
133 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
134
135 sub import {
136     my ( $class, @arguments ) = @_;
137
138     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
139     # callers @ISA.
140     return unless $class eq 'Catalyst';
141
142     my $caller = caller();
143     return if $caller eq 'main';
144
145     my $meta = Moose::Meta::Class->initialize($caller);
146     unless ( $caller->isa('Catalyst') ) {
147         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
148         $meta->superclasses(@superclasses);
149     }
150     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
151     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
152
153     unless( $meta->has_method('meta') ){
154         if ($Moose::VERSION >= 1.15) {
155             $meta->_add_meta_method('meta');
156         }
157         else {
158             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
159         }
160     }
161
162     $caller->arguments( [@arguments] );
163     $caller->setup_home;
164 }
165
166 sub _application { $_[0] }
167
168 =encoding UTF-8
169
170 =head1 NAME
171
172 Catalyst - The Elegant MVC Web Application Framework
173
174 =head1 SYNOPSIS
175
176 See the L<Catalyst::Manual> distribution for comprehensive
177 documentation and tutorials.
178
179     # Install Catalyst::Devel for helpers and other development tools
180     # use the helper to create a new application
181     catalyst.pl MyApp
182
183     # add models, views, controllers
184     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
185     script/myapp_create.pl view MyTemplate TT
186     script/myapp_create.pl controller Search
187
188     # built in testserver -- use -r to restart automatically on changes
189     # --help to see all available options
190     script/myapp_server.pl
191
192     # command line testing interface
193     script/myapp_test.pl /yada
194
195     ### in lib/MyApp.pm
196     use Catalyst qw/-Debug/; # include plugins here as well
197
198     ### In lib/MyApp/Controller/Root.pm (autocreated)
199     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
200         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
201         $c->stash->{template} = 'foo.tt'; # set the template
202         # lookup something from db -- stash vars are passed to TT
203         $c->stash->{data} =
204           $c->model('Database::Foo')->search( { country => $args[0] } );
205         if ( $c->req->params->{bar} ) { # access GET or POST parameters
206             $c->forward( 'bar' ); # process another action
207             # do something else after forward returns
208         }
209     }
210
211     # The foo.tt TT template can use the stash data from the database
212     [% WHILE (item = data.next) %]
213         [% item.foo %]
214     [% END %]
215
216     # called for /bar/of/soap, /bar/of/soap/10, etc.
217     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
218
219     # called after all actions are finished
220     sub end : Action {
221         my ( $self, $c ) = @_;
222         if ( scalar @{ $c->error } ) { ... } # handle errors
223         return if $c->res->body; # already have a response
224         $c->forward( 'MyApp::View::TT' ); # render template
225     }
226
227 See L<Catalyst::Manual::Intro> for additional information.
228
229 =head1 DESCRIPTION
230
231 Catalyst is a modern framework for making web applications without the
232 pain usually associated with this process. This document is a reference
233 to the main Catalyst application. If you are a new user, we suggest you
234 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
235
236 See L<Catalyst::Manual> for more documentation.
237
238 Catalyst plugins can be loaded by naming them as arguments to the "use
239 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
240 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
241 C<My::Module>.
242
243     use Catalyst qw/My::Module/;
244
245 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
246 fully qualify the name by using a unary plus:
247
248     use Catalyst qw/
249         My::Module
250         +Fully::Qualified::Plugin::Name
251     /;
252
253 Special flags like C<-Debug> can also be specified as
254 arguments when Catalyst is loaded:
255
256     use Catalyst qw/-Debug My::Module/;
257
258 The position of plugins and flags in the chain is important, because
259 they are loaded in the order in which they appear.
260
261 The following flags are supported:
262
263 =head2 -Debug
264
265 Enables debug output. You can also force this setting from the system
266 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
267 settings override the application, with <MYAPP>_DEBUG having the highest
268 priority.
269
270 This sets the log level to 'debug' and enables full debug output on the
271 error screen. If you only want the latter, see L<< $c->debug >>.
272
273 =head2 -Home
274
275 Forces Catalyst to use a specific home directory, e.g.:
276
277     use Catalyst qw[-Home=/usr/mst];
278
279 This can also be done in the shell environment by setting either the
280 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
281 is replaced with the uppercased name of your application, any "::" in
282 the name will be replaced with underscores, e.g. MyApp::Web should use
283 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
284
285 If none of these are set, Catalyst will attempt to automatically detect the
286 home directory. If you are working in a development environment, Catalyst
287 will try and find the directory containing either Makefile.PL, Build.PL,
288 dist.ini, or cpanfile. If the application has been installed into the system
289 (i.e. you have done C<make install>), then Catalyst will use the path to your
290 application module, without the .pm extension (e.g., /foo/MyApp if your
291 application was installed at /foo/MyApp.pm)
292
293 =head2 -Log
294
295     use Catalyst '-Log=warn,fatal,error';
296
297 Specifies a comma-delimited list of log levels.
298
299 =head2 -Stats
300
301 Enables statistics collection and reporting.
302
303    use Catalyst qw/-Stats=1/;
304
305 You can also force this setting from the system environment with CATALYST_STATS
306 or <MYAPP>_STATS. The environment settings override the application, with
307 <MYAPP>_STATS having the highest priority.
308
309 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
310
311 =head1 METHODS
312
313 =head2 INFORMATION ABOUT THE CURRENT REQUEST
314
315 =head2 $c->action
316
317 Returns a L<Catalyst::Action> object for the current action, which
318 stringifies to the action name. See L<Catalyst::Action>.
319
320 =head2 $c->namespace
321
322 Returns the namespace of the current action, i.e., the URI prefix
323 corresponding to the controller of the current action. For example:
324
325     # in Controller::Foo::Bar
326     $c->namespace; # returns 'foo/bar';
327
328 =head2 $c->request
329
330 =head2 $c->req
331
332 Returns the current L<Catalyst::Request> object, giving access to
333 information about the current client request (including parameters,
334 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
335
336 =head2 REQUEST FLOW HANDLING
337
338 =head2 $c->forward( $action [, \@arguments ] )
339
340 =head2 $c->forward( $class, $method, [, \@arguments ] )
341
342 This is one way of calling another action (method) in the same or
343 a different controller. You can also use C<< $self->my_method($c, @args) >>
344 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
345 in a different controller.
346 The main difference is that 'forward' uses some of the Catalyst request
347 cycle overhead, including debugging, which may be useful to you. On the
348 other hand, there are some complications to using 'forward', restrictions
349 on values returned from 'forward', and it may not handle errors as you prefer.
350 Whether you use 'forward' or not is up to you; it is not considered superior to
351 the other ways to call a method.
352
353 'forward' calls  another action, by its private name. If you give a
354 class name but no method, C<process()> is called. You may also optionally
355 pass arguments in an arrayref. The action will receive the arguments in
356 C<@_> and C<< $c->req->args >>. Upon returning from the function,
357 C<< $c->req->args >> will be restored to the previous values.
358
359 Any data C<return>ed from the action forwarded to, will be returned by the
360 call to forward.
361
362     my $foodata = $c->forward('/foo');
363     $c->forward('index');
364     $c->forward(qw/Model::DBIC::Foo do_stuff/);
365     $c->forward('View::TT');
366
367 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
368 an C<< eval { } >> around the call (actually
369 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
370 exceptions thrown by the called action non-fatal and pushing them onto
371 $c->error instead. If you want C<die> to propagate you need to do something
372 like:
373
374     $c->forward('foo');
375     die join "\n", @{ $c->error } if @{ $c->error };
376
377 Or make sure to always return true values from your actions and write
378 your code like this:
379
380     $c->forward('foo') || return;
381
382 Another note is that C<< $c->forward >> always returns a scalar because it
383 actually returns $c->state which operates in a scalar context.
384 Thus, something like:
385
386     return @array;
387
388 in an action that is forwarded to is going to return a scalar,
389 i.e. how many items are in that array, which is probably not what you want.
390 If you need to return an array then return a reference to it,
391 or stash it like so:
392
393     $c->stash->{array} = \@array;
394
395 and access it from the stash.
396
397 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
398
399 =cut
400
401 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
402
403 =head2 $c->detach( $action [, \@arguments ] )
404
405 =head2 $c->detach( $class, $method, [, \@arguments ] )
406
407 =head2 $c->detach()
408
409 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
410 doesn't return to the previous action when processing is finished.
411
412 When called with no arguments it escapes the processing chain entirely.
413
414 =cut
415
416 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
417
418 =head2 $c->visit( $action [, \@arguments ] )
419
420 =head2 $c->visit( $action [, \@captures, \@arguments ] )
421
422 =head2 $c->visit( $class, $method, [, \@arguments ] )
423
424 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
425
426 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
427 but does a full dispatch, instead of just calling the new C<$action> /
428 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
429 you go to are called, just like a new request.
430
431 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
432 This means, for example, that C<< $c->action >> methods such as
433 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
434 L<reverse|Catalyst::Action/reverse> return information for the visited action
435 when they are invoked within the visited action.  This is different from the
436 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
437 continues to use the $c->action object from the caller action even when
438 invoked from the called action.
439
440 C<< $c->stash >> is kept unchanged.
441
442 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
443 allows you to "wrap" another action, just as it would have been called by
444 dispatching from a URL, while the analogous
445 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
446 transfer control to another action as if it had been reached directly from a URL.
447
448 =cut
449
450 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
451
452 =head2 $c->go( $action [, \@arguments ] )
453
454 =head2 $c->go( $action [, \@captures, \@arguments ] )
455
456 =head2 $c->go( $class, $method, [, \@arguments ] )
457
458 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
459
460 The relationship between C<go> and
461 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
462 the relationship between
463 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
464 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
465 C<< $c->go >> will perform a full dispatch on the specified action or method,
466 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
467 C<go> escapes the processing of the current request chain on completion, and
468 does not return to its caller.
469
470 @arguments are arguments to the final destination of $action. @captures are
471 arguments to the intermediate steps, if any, on the way to the final sub of
472 $action.
473
474 =cut
475
476 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
477
478 =head2 $c->response
479
480 =head2 $c->res
481
482 Returns the current L<Catalyst::Response> object, see there for details.
483
484 =head2 $c->stash
485
486 Returns a hashref to the stash, which may be used to store data and pass
487 it between components during a request. You can also set hash keys by
488 passing arguments. The stash is automatically sent to the view. The
489 stash is cleared at the end of a request; it cannot be used for
490 persistent storage (for this you must use a session; see
491 L<Catalyst::Plugin::Session> for a complete system integrated with
492 Catalyst).
493
494     $c->stash->{foo} = $bar;
495     $c->stash( { moose => 'majestic', qux => 0 } );
496     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
497
498     # stash is automatically passed to the view for use in a template
499     $c->forward( 'MyApp::View::TT' );
500
501 The stash hash is currently stored in the PSGI C<$env> and is managed by
502 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
503 the stash can be accessed in sub applications mounted under your main
504 L<Catalyst> application.  For example if you delegate the response of an
505 action to another L<Catalyst> application, that sub application will have
506 access to all the stash keys of the main one, and if can of course add
507 more keys of its own.  However those new keys will not 'bubble' back up
508 to the main application.
509
510 For more information the best thing to do is to review the test case:
511 t/middleware-stash.t in the distribution /t directory.
512
513 =cut
514
515 sub stash {
516   my $c = shift;
517   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
518 }
519
520 =head2 $c->error
521
522 =head2 $c->error($error, ...)
523
524 =head2 $c->error($arrayref)
525
526 Returns an arrayref containing error messages.  If Catalyst encounters an
527 error while processing a request, it stores the error in $c->error.  This
528 method should only be used to store fatal error messages.
529
530     my @error = @{ $c->error };
531
532 Add a new error.
533
534     $c->error('Something bad happened');
535
536 Calling this will always return an arrayref (if there are no errors it
537 will be an empty arrayref.
538
539 =cut
540
541 sub error {
542     my $c = shift;
543     if ( $_[0] ) {
544         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
545         croak @$error unless ref $c;
546         push @{ $c->{error} }, @$error;
547     }
548     elsif ( defined $_[0] ) { $c->{error} = undef }
549     return $c->{error} || [];
550 }
551
552
553 =head2 $c->state
554
555 Contains the return value of the last executed action.
556 Note that << $c->state >> operates in a scalar context which means that all
557 values it returns are scalar.
558
559 =head2 $c->clear_errors
560
561 Clear errors.  You probably don't want to clear the errors unless you are
562 implementing a custom error screen.
563
564 This is equivalent to running
565
566     $c->error(0);
567
568 =cut
569
570 sub clear_errors {
571     my $c = shift;
572     $c->error(0);
573 }
574
575 =head2 $c->has_errors
576
577 Returns true if you have errors
578
579 =cut
580
581 sub has_errors { scalar(@{shift->error}) ? 1:0 }
582
583 =head2 $c->last_error
584
585 Returns the most recent error in the stack (the one most recently added...)
586 or nothing if there are no errors.
587
588 =cut
589
590 sub last_error { my ($err, @errs) = @{shift->error}; return $err }
591
592 =head2 shift_errors
593
594 shifts the most recently added error off the error stack and returns if.  Returns
595 nothing if there are no more errors.
596
597 =cut
598
599 sub shift_errors {
600     my ($self) = @_;
601     my ($err, @errors) = @{$self->error};
602     $self->{error} = \@errors;
603     return $err;
604 }
605
606 sub _comp_search_prefixes {
607     my $c = shift;
608     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
609 }
610
611 # search components given a name and some prefixes
612 sub _comp_names_search_prefixes {
613     my ( $c, $name, @prefixes ) = @_;
614     my $appclass = ref $c || $c;
615     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
616     $filter = qr/$filter/; # Compile regex now rather than once per loop
617
618     # map the original component name to the sub part that we will search against
619     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
620         grep { /$filter/ } keys %{ $c->components };
621
622     # undef for a name will return all
623     return keys %eligible if !defined $name;
624
625     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
626     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
627
628     return @result if @result;
629
630     # if we were given a regexp to search against, we're done.
631     return if $name->$_isa('Regexp');
632
633     # skip regexp fallback if configured
634     return
635         if $appclass->config->{disable_component_resolution_regex_fallback};
636
637     # regexp fallback
638     $query  = qr/$name/i;
639     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
640
641     # no results? try against full names
642     if( !@result ) {
643         @result = grep { m{$query} } keys %eligible;
644     }
645
646     # don't warn if we didn't find any results, it just might not exist
647     if( @result ) {
648         # Disgusting hack to work out correct method name
649         my $warn_for = lc $prefixes[0];
650         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
651            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
652            "component resolution is unreliable and unsafe.";
653         my $short = $result[0];
654         # remove the component namespace prefix
655         $short =~ s/.*?(Model|Controller|View):://;
656         my $shortmess = Carp::shortmess('');
657         if ($shortmess =~ m#Catalyst/Plugin#) {
658            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
659               "plugin's config";
660         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
661            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
662               "component's config";
663         } else {
664            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
665               "but if you really wanted to search, pass in a regexp as the argument " .
666               "like so: \$c->${warn_for}(qr/${name}/)";
667         }
668         $c->log->warn( "${msg}$shortmess" );
669     }
670
671     return @result;
672 }
673
674 # Find possible names for a prefix
675 sub _comp_names {
676     my ( $c, @prefixes ) = @_;
677     my $appclass = ref $c || $c;
678
679     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
680
681     my @names = map { s{$filter}{}; $_; }
682         $c->_comp_names_search_prefixes( undef, @prefixes );
683
684     return @names;
685 }
686
687 # Filter a component before returning by calling ACCEPT_CONTEXT if available
688 sub _filter_component {
689     my ( $c, $comp, @args ) = @_;
690
691     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
692         return $comp->ACCEPT_CONTEXT( $c, @args );
693     }
694
695     return $comp;
696 }
697
698 =head2 COMPONENT ACCESSORS
699
700 =head2 $c->controller($name)
701
702 Gets a L<Catalyst::Controller> instance by name.
703
704     $c->controller('Foo')->do_stuff;
705
706 If the name is omitted, will return the controller for the dispatched
707 action.
708
709 If you want to search for controllers, pass in a regexp as the argument.
710
711     # find all controllers that start with Foo
712     my @foo_controllers = $c->controller(qr{^Foo});
713
714
715 =cut
716
717 sub controller {
718     my ( $c, $name, @args ) = @_;
719
720     my $appclass = ref($c) || $c;
721     if( $name ) {
722         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
723             my $comps = $c->components;
724             my $check = $appclass."::Controller::".$name;
725             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
726         }
727         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
728         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
729         return $c->_filter_component( $result[ 0 ], @args );
730     }
731
732     return $c->component( $c->action->class );
733 }
734
735 =head2 $c->model($name)
736
737 Gets a L<Catalyst::Model> instance by name.
738
739     $c->model('Foo')->do_stuff;
740
741 Any extra arguments are directly passed to ACCEPT_CONTEXT.
742
743 If the name is omitted, it will look for
744  - a model object in $c->stash->{current_model_instance}, then
745  - a model name in $c->stash->{current_model}, then
746  - a config setting 'default_model', or
747  - check if there is only one model, and return it if that's the case.
748
749 If you want to search for models, pass in a regexp as the argument.
750
751     # find all models that start with Foo
752     my @foo_models = $c->model(qr{^Foo});
753
754 =cut
755
756 sub model {
757     my ( $c, $name, @args ) = @_;
758     my $appclass = ref($c) || $c;
759     if( $name ) {
760         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
761             my $comps = $c->components;
762             my $check = $appclass."::Model::".$name;
763             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
764         }
765         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
766         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
767         return $c->_filter_component( $result[ 0 ], @args );
768     }
769
770     if (ref $c) {
771         return $c->stash->{current_model_instance}
772           if $c->stash->{current_model_instance};
773         return $c->model( $c->stash->{current_model} )
774           if $c->stash->{current_model};
775     }
776     return $c->model( $appclass->config->{default_model} )
777       if $appclass->config->{default_model};
778
779     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
780
781     if( $rest ) {
782         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
783         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
784         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
785         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
786         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
787     }
788
789     return $c->_filter_component( $comp );
790 }
791
792
793 =head2 $c->view($name)
794
795 Gets a L<Catalyst::View> instance by name.
796
797     $c->view('Foo')->do_stuff;
798
799 Any extra arguments are directly passed to ACCEPT_CONTEXT.
800
801 If the name is omitted, it will look for
802  - a view object in $c->stash->{current_view_instance}, then
803  - a view name in $c->stash->{current_view}, then
804  - a config setting 'default_view', or
805  - check if there is only one view, and return it if that's the case.
806
807 If you want to search for views, pass in a regexp as the argument.
808
809     # find all views that start with Foo
810     my @foo_views = $c->view(qr{^Foo});
811
812 =cut
813
814 sub view {
815     my ( $c, $name, @args ) = @_;
816
817     my $appclass = ref($c) || $c;
818     if( $name ) {
819         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
820             my $comps = $c->components;
821             my $check = $appclass."::View::".$name;
822             if( exists $comps->{$check} ) {
823                 return $c->_filter_component( $comps->{$check}, @args );
824             }
825             else {
826                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
827             }
828         }
829         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
830         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
831         return $c->_filter_component( $result[ 0 ], @args );
832     }
833
834     if (ref $c) {
835         return $c->stash->{current_view_instance}
836           if $c->stash->{current_view_instance};
837         return $c->view( $c->stash->{current_view} )
838           if $c->stash->{current_view};
839     }
840     return $c->view( $appclass->config->{default_view} )
841       if $appclass->config->{default_view};
842
843     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
844
845     if( $rest ) {
846         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
847         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
848         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
849         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
850         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
851     }
852
853     return $c->_filter_component( $comp );
854 }
855
856 =head2 $c->controllers
857
858 Returns the available names which can be passed to $c->controller
859
860 =cut
861
862 sub controllers {
863     my ( $c ) = @_;
864     return $c->_comp_names(qw/Controller C/);
865 }
866
867 =head2 $c->models
868
869 Returns the available names which can be passed to $c->model
870
871 =cut
872
873 sub models {
874     my ( $c ) = @_;
875     return $c->_comp_names(qw/Model M/);
876 }
877
878
879 =head2 $c->views
880
881 Returns the available names which can be passed to $c->view
882
883 =cut
884
885 sub views {
886     my ( $c ) = @_;
887     return $c->_comp_names(qw/View V/);
888 }
889
890 =head2 $c->comp($name)
891
892 =head2 $c->component($name)
893
894 Gets a component object by name. This method is not recommended,
895 unless you want to get a specific component by full
896 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
897 should be used instead.
898
899 If C<$name> is a regexp, a list of components matched against the full
900 component name will be returned.
901
902 If Catalyst can't find a component by name, it will fallback to regex
903 matching by default. To disable this behaviour set
904 disable_component_resolution_regex_fallback to a true value.
905
906     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
907
908 =cut
909
910 sub component {
911     my ( $c, $name, @args ) = @_;
912
913     if( $name ) {
914         my $comps = $c->components;
915
916         if( !ref $name ) {
917             # is it the exact name?
918             return $c->_filter_component( $comps->{ $name }, @args )
919                        if exists $comps->{ $name };
920
921             # perhaps we just omitted "MyApp"?
922             my $composed = ( ref $c || $c ) . "::${name}";
923             return $c->_filter_component( $comps->{ $composed }, @args )
924                        if exists $comps->{ $composed };
925
926             # search all of the models, views and controllers
927             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
928             return $c->_filter_component( $comp, @args ) if $comp;
929         }
930
931         return
932             if $c->config->{disable_component_resolution_regex_fallback};
933
934         # This is here so $c->comp( '::M::' ) works
935         my $query = ref $name ? $name : qr{$name}i;
936
937         my @result = grep { m{$query} } keys %{ $c->components };
938         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
939
940         if( $result[ 0 ] ) {
941             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
942             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
943             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
944             return $c->_filter_component( $result[ 0 ], @args );
945         }
946
947         # I would expect to return an empty list here, but that breaks back-compat
948     }
949
950     # fallback
951     return sort keys %{ $c->components };
952 }
953
954 =head2 CLASS DATA AND HELPER CLASSES
955
956 =head2 $c->config
957
958 Returns or takes a hashref containing the application's configuration.
959
960     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
961
962 You can also use a C<YAML>, C<XML> or L<Config::General> config file
963 like C<myapp.conf> in your applications home directory. See
964 L<Catalyst::Plugin::ConfigLoader>.
965
966 =head3 Cascading configuration
967
968 The config method is present on all Catalyst components, and configuration
969 will be merged when an application is started. Configuration loaded with
970 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
971 followed by configuration in your top level C<MyApp> class. These two
972 configurations are merged, and then configuration data whose hash key matches a
973 component name is merged with configuration for that component.
974
975 The configuration for a component is then passed to the C<new> method when a
976 component is constructed.
977
978 For example:
979
980     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
981     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
982
983 will mean that C<MyApp::Model::Foo> receives the following data when
984 constructed:
985
986     MyApp::Model::Foo->new({
987         bar => 'baz',
988         quux => 'frob',
989         overrides => 'me',
990     });
991
992 It's common practice to use a Moose attribute
993 on the receiving component to access the config value.
994
995     package MyApp::Model::Foo;
996
997     use Moose;
998
999     # this attr will receive 'baz' at construction time
1000     has 'bar' => (
1001         is  => 'rw',
1002         isa => 'Str',
1003     );
1004
1005 You can then get the value 'baz' by calling $c->model('Foo')->bar
1006 (or $self->bar inside code in the model).
1007
1008 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
1009 as a way of reading config within your code, as this B<will not> give you the
1010 correctly merged config back. You B<MUST> take the config values supplied to
1011 the constructor and use those instead.
1012
1013 =cut
1014
1015 around config => sub {
1016     my $orig = shift;
1017     my $c = shift;
1018
1019     croak('Setting config after setup has been run is not allowed.')
1020         if ( @_ and $c->setup_finished );
1021
1022     $c->$orig(@_);
1023 };
1024
1025 =head2 $c->log
1026
1027 Returns the logging object instance. Unless it is already set, Catalyst
1028 sets this up with a L<Catalyst::Log> object. To use your own log class,
1029 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1030 C<< __PACKAGE__->setup >>.
1031
1032  __PACKAGE__->log( MyLogger->new );
1033  __PACKAGE__->setup;
1034
1035 And later:
1036
1037     $c->log->info( 'Now logging with my own logger!' );
1038
1039 Your log class should implement the methods described in
1040 L<Catalyst::Log>.
1041
1042 =head2 has_encoding
1043
1044 Returned True if there's a valid encoding
1045
1046 =head2 clear_encoding
1047
1048 Clears the encoding for the current context
1049
1050 =head2 encoding
1051
1052 Sets or gets the application encoding.  Setting encoding takes either an
1053 Encoding object or a string that we try to resolve via L<Encode::find_encoding>.
1054
1055 You would expect to get the encoding object back if you attempt to set it.  If
1056 there is a failure you will get undef returned and an error message in the log.
1057
1058 =cut
1059
1060 sub has_encoding { shift->encoding ? 1:0 }
1061
1062 sub clear_encoding {
1063     my $c = shift;
1064     if(blessed $c) {
1065         $c->encoding(undef);
1066     } else {
1067         $c->log->error("You can't clear encoding on the application");
1068     }
1069 }
1070
1071 sub encoding {
1072     my $c = shift;
1073     my $encoding;
1074
1075     if ( scalar @_ ) {
1076
1077         # Don't let one change this once we are too far into the response
1078         if(blessed $c && $c->res->finalized_headers) {
1079           Carp::croak("You may not change the encoding once the headers are finalized");
1080           return;
1081         }
1082
1083         # Let it be set to undef
1084         if (my $wanted = shift)  {
1085             $encoding = Encode::find_encoding($wanted)
1086               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1087             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1088         }
1089         else {
1090             binmode(STDERR);
1091         }
1092
1093         $encoding = ref $c
1094                   ? $c->{encoding} = $encoding
1095                   : $c->_encoding($encoding);
1096     } else {
1097       $encoding = ref $c && exists $c->{encoding}
1098                 ? $c->{encoding}
1099                 : $c->_encoding;
1100     }
1101
1102     return $encoding;
1103 }
1104
1105 =head2 $c->debug
1106
1107 Returns 1 if debug mode is enabled, 0 otherwise.
1108
1109 You can enable debug mode in several ways:
1110
1111 =over
1112
1113 =item By calling myapp_server.pl with the -d flag
1114
1115 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1116
1117 =item The -Debug option in your MyApp.pm
1118
1119 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1120
1121 =back
1122
1123 The first three also set the log level to 'debug'.
1124
1125 Calling C<< $c->debug(1) >> has no effect.
1126
1127 =cut
1128
1129 sub debug { 0 }
1130
1131 =head2 $c->dispatcher
1132
1133 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1134
1135 =head2 $c->engine
1136
1137 Returns the engine instance. See L<Catalyst::Engine>.
1138
1139
1140 =head2 UTILITY METHODS
1141
1142 =head2 $c->path_to(@path)
1143
1144 Merges C<@path> with C<< $c->config->{home} >> and returns a
1145 L<Path::Class::Dir> object. Note you can usually use this object as
1146 a filename, but sometimes you will have to explicitly stringify it
1147 yourself by calling the C<< ->stringify >> method.
1148
1149 For example:
1150
1151     $c->path_to( 'db', 'sqlite.db' );
1152
1153 =cut
1154
1155 sub path_to {
1156     my ( $c, @path ) = @_;
1157     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1158     if ( -d $path ) { return $path }
1159     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1160 }
1161
1162 sub plugin {
1163     my ( $class, $name, $plugin, @args ) = @_;
1164
1165     # See block comment in t/unit_core_plugin.t
1166     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1167
1168     $class->_register_plugin( $plugin, 1 );
1169
1170     eval { $plugin->import };
1171     $class->mk_classdata($name);
1172     my $obj;
1173     eval { $obj = $plugin->new(@args) };
1174
1175     if ($@) {
1176         Catalyst::Exception->throw( message =>
1177               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1178     }
1179
1180     $class->$name($obj);
1181     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1182       if $class->debug;
1183 }
1184
1185 =head2 MyApp->setup
1186
1187 Initializes the dispatcher and engine, loads any plugins, and loads the
1188 model, view, and controller components. You may also specify an array
1189 of plugins to load here, if you choose to not load them in the C<use
1190 Catalyst> line.
1191
1192     MyApp->setup;
1193     MyApp->setup( qw/-Debug/ );
1194
1195 B<Note:> You B<should not> wrap this method with method modifiers
1196 or bad things will happen - wrap the C<setup_finalize> method instead.
1197
1198 B<Note:> You can create a custom setup stage that will execute when the
1199 application is starting.  Use this to customize setup.
1200
1201     MyApp->setup(-Custom=value);
1202
1203     sub setup_custom {
1204       my ($class, $value) = @_;
1205     }
1206
1207 Can be handy if you want to hook into the setup phase.
1208
1209 =cut
1210
1211 sub setup {
1212     my ( $class, @arguments ) = @_;
1213     croak('Running setup more than once')
1214         if ( $class->setup_finished );
1215
1216     unless ( $class->isa('Catalyst') ) {
1217
1218         Catalyst::Exception->throw(
1219             message => qq/'$class' does not inherit from Catalyst/ );
1220     }
1221
1222     if ( $class->arguments ) {
1223         @arguments = ( @arguments, @{ $class->arguments } );
1224     }
1225
1226     # Process options
1227     my $flags = {};
1228
1229     foreach (@arguments) {
1230
1231         if (/^-Debug$/) {
1232             $flags->{log} =
1233               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1234         }
1235         elsif (/^-(\w+)=?(.*)$/) {
1236             $flags->{ lc $1 } = $2;
1237         }
1238         else {
1239             push @{ $flags->{plugins} }, $_;
1240         }
1241     }
1242
1243     $class->setup_home( delete $flags->{home} );
1244
1245     $class->setup_log( delete $flags->{log} );
1246     $class->setup_plugins( delete $flags->{plugins} );
1247
1248     $class->setup_data_handlers();
1249     $class->setup_dispatcher( delete $flags->{dispatcher} );
1250     if (my $engine = delete $flags->{engine}) {
1251         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1252     }
1253     $class->setup_engine();
1254     $class->setup_stats( delete $flags->{stats} );
1255
1256     for my $flag ( sort keys %{$flags} ) {
1257
1258         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1259             &$code( $class, delete $flags->{$flag} );
1260         }
1261         else {
1262             $class->log->warn(qq/Unknown flag "$flag"/);
1263         }
1264     }
1265
1266     eval { require Catalyst::Devel; };
1267     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1268         $class->log->warn(<<"EOF");
1269 You are running an old script!
1270
1271   Please update by running (this will overwrite existing files):
1272     catalyst.pl -force -scripts $class
1273
1274   or (this will not overwrite existing files):
1275     catalyst.pl -scripts $class
1276
1277 EOF
1278     }
1279
1280     # Call plugins setup, this is stupid and evil.
1281     # Also screws C3 badly on 5.10, hack to avoid.
1282     {
1283         no warnings qw/redefine/;
1284         local *setup = sub { };
1285         $class->setup unless $Catalyst::__AM_RESTARTING;
1286     }
1287
1288     # If you are expecting configuration info as part of your setup, it needs
1289     # to get called here and below, since we need the above line to support
1290     # ConfigLoader based configs.
1291
1292     $class->setup_encoding();
1293     $class->setup_middleware();
1294
1295     # Initialize our data structure
1296     $class->components( {} );
1297
1298     $class->setup_components;
1299
1300     if ( $class->debug ) {
1301         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1302
1303         if (@plugins) {
1304             my $column_width = Catalyst::Utils::term_width() - 6;
1305             my $t = Text::SimpleTable->new($column_width);
1306             $t->row($_) for @plugins;
1307             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1308         }
1309
1310         my @middleware = map {
1311           ref $_ eq 'CODE' ? 
1312             "Inline Coderef" : 
1313               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '') 
1314                 || '')  } $class->registered_middlewares;
1315
1316         if (@middleware) {
1317             my $column_width = Catalyst::Utils::term_width() - 6;
1318             my $t = Text::SimpleTable->new($column_width);
1319             $t->row($_) for @middleware;
1320             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1321         }
1322
1323         my %dh = $class->registered_data_handlers;
1324         if (my @data_handlers = keys %dh) {
1325             my $column_width = Catalyst::Utils::term_width() - 6;
1326             my $t = Text::SimpleTable->new($column_width);
1327             $t->row($_) for @data_handlers;
1328             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1329         }
1330
1331         my $dispatcher = $class->dispatcher;
1332         my $engine     = $class->engine;
1333         my $home       = $class->config->{home};
1334
1335         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1336         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1337
1338         $home
1339           ? ( -d $home )
1340           ? $class->log->debug(qq/Found home "$home"/)
1341           : $class->log->debug(qq/Home "$home" doesn't exist/)
1342           : $class->log->debug(q/Couldn't find home/);
1343
1344         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1345         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1346         for my $comp ( sort keys %{ $class->components } ) {
1347             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1348             $t->row( $comp, $type );
1349         }
1350         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1351           if ( keys %{ $class->components } );
1352     }
1353
1354     # Add our self to components, since we are also a component
1355     if( $class->isa('Catalyst::Controller') ){
1356       $class->components->{$class} = $class;
1357     }
1358
1359     $class->setup_actions;
1360
1361     if ( $class->debug ) {
1362         my $name = $class->config->{name} || 'Application';
1363         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1364     }
1365
1366     if ($class->config->{case_sensitive}) {
1367         $class->log->warn($class . "->config->{case_sensitive} is set.");
1368         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1369     }
1370
1371     $class->setup_finalize;
1372
1373     # Flush the log for good measure (in case something turned off 'autoflush' early)
1374     $class->log->_flush() if $class->log->can('_flush');
1375
1376     return $class || 1; # Just in case someone named their Application 0...
1377 }
1378
1379 =head2 $app->setup_finalize
1380
1381 A hook to attach modifiers to. This method does not do anything except set the
1382 C<setup_finished> accessor.
1383
1384 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1385
1386 Example:
1387
1388     after setup_finalize => sub {
1389         my $app = shift;
1390
1391         ## do stuff here..
1392     };
1393
1394 =cut
1395
1396 sub setup_finalize {
1397     my ($class) = @_;
1398     $class->setup_finished(1);
1399 }
1400
1401 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1402
1403 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1404
1405 =head2 $c->uri_for( $action, [@captures, @args], \%query_values? )
1406
1407 Constructs an absolute L<URI> object based on the application root, the
1408 provided path, and the additional arguments and query parameters provided.
1409 When used as a string, provides a textual URI.  If you need more flexibility
1410 than this (i.e. the option to provide relative URIs etc.) see
1411 L<Catalyst::Plugin::SmartURI>.
1412
1413 If no arguments are provided, the URI for the current action is returned.
1414 To return the current action and also provide @args, use
1415 C<< $c->uri_for( $c->action, @args ) >>.
1416
1417 If the first argument is a string, it is taken as a public URI path relative
1418 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1419 relative to the application root (if it does). It is then merged with
1420 C<< $c->request->base >>; any C<@args> are appended as additional path
1421 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1422
1423 If the first argument is a L<Catalyst::Action> it represents an action which
1424 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1425 optional C<\@captures> argument (an arrayref) allows passing the captured
1426 variables that are needed to fill in the paths of Chained and Regex actions;
1427 once the path is resolved, C<uri_for> continues as though a path was
1428 provided, appending any arguments or parameters and creating an absolute
1429 URI.
1430
1431 The captures for the current request can be found in
1432 C<< $c->request->captures >>, and actions can be resolved using
1433 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1434 path, use C<< $c->uri_for_action >> instead.
1435
1436   # Equivalent to $c->req->uri
1437   $c->uri_for($c->action, $c->req->captures,
1438       @{ $c->req->args }, $c->req->params);
1439
1440   # For the Foo action in the Bar controller
1441   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1442
1443   # Path to a static resource
1444   $c->uri_for('/static/images/logo.png');
1445
1446 In general the scheme of the generated URI object will follow the incoming request
1447 however if your targeted action or action chain has the Scheme attribute it will
1448 use that instead.
1449
1450 =cut
1451
1452 sub uri_for {
1453     my ( $c, $path, @args ) = @_;
1454
1455     if ( $path->$_isa('Catalyst::Controller') ) {
1456         $path = $path->path_prefix;
1457         $path =~ s{/+\z}{};
1458         $path .= '/';
1459     }
1460
1461     undef($path) if (defined $path && $path eq '');
1462
1463     my $params =
1464       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1465
1466     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1467
1468     my @encoded_args = ();
1469     foreach my $arg (@args) {
1470       if(ref($arg)||'' eq 'ARRAY') {
1471         push @encoded_args, [map {
1472           my $encoded = encode_utf8 $_;
1473           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1474          $encoded;
1475         } @$arg];
1476       } else {
1477         push @encoded_args, do {
1478           my $encoded = encode_utf8 $arg;
1479           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1480           $encoded;
1481         }
1482       }
1483     }
1484
1485     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1486     if ( $path->$_isa('Catalyst::Action') ) { # action object
1487         s|/|%2F|g for @encoded_args;
1488         my $captures = [ map { s|/|%2F|g; $_; }
1489                         ( scalar @encoded_args && ref $encoded_args[0] eq 'ARRAY'
1490                          ? @{ shift(@encoded_args) }
1491                          : ()) ];
1492
1493         my $action = $path;
1494         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1495         if( !@encoded_args && $action->number_of_args ) {
1496             my $expanded_action = $c->dispatcher->expand_action( $action );
1497             my $num_captures = $expanded_action->number_of_captures;
1498             unshift @encoded_args, splice @$captures, $num_captures;
1499         }
1500
1501        $path = $c->dispatcher->uri_for_action($action, $captures);
1502         if (not defined $path) {
1503             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1504                 if $c->debug;
1505             return undef;
1506         }
1507         $path = '/' if $path eq '';
1508     }
1509
1510     unshift(@encoded_args, $path);
1511
1512     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1513         my $namespace = $c->namespace;
1514         if (defined $path) { # cheesy hack to handle path '../foo'
1515            $namespace =~ s{(?:^|/)[^/]+$}{} while $encoded_args[0] =~ s{^\.\./}{};
1516         }
1517         unshift(@encoded_args, $namespace || '');
1518     }
1519
1520     # join args with '/', or a blank string
1521     my $args = join('/', grep { defined($_) } @encoded_args);
1522     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1523     $args =~ s!^/+!!;
1524
1525     my ($base, $class) = ('/', 'URI::_generic');
1526     if(blessed($c)) {
1527       $base = $c->req->base;
1528       if($target_action) {
1529         $target_action = $c->dispatcher->expand_action($target_action);
1530         if(my $s = $target_action->scheme) {
1531           $s = lc($s);
1532           $class = "URI::$s";
1533           $base->scheme($s);
1534         } else {
1535           $class = ref($base);
1536         }
1537       } else {
1538         $class = ref($base);
1539       }
1540
1541       $base =~ s{(?<!/)$}{/};
1542     }
1543
1544     my $query = '';
1545
1546     if (my @keys = keys %$params) {
1547       # somewhat lifted from URI::_query's query_form
1548       $query = '?'.join('&', map {
1549           my $val = $params->{$_};
1550           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1551           s/ /+/g;
1552           my $key = $_;
1553           $val = '' unless defined $val;
1554           (map {
1555               my $param = "$_";
1556               $param = encode_utf8($param);
1557               # using the URI::Escape pattern here so utf8 chars survive
1558               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1559               $param =~ s/ /+/g;
1560
1561               $key = encode_utf8($key);
1562               # using the URI::Escape pattern here so utf8 chars survive
1563               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1564               $key =~ s/ /+/g;
1565
1566               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1567       } @keys);
1568     }
1569
1570     my $res = bless(\"${base}${args}${query}", $class);
1571     $res;
1572 }
1573
1574 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1575
1576 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1577
1578 =over
1579
1580 =item $path
1581
1582 A private path to the Catalyst action you want to create a URI for.
1583
1584 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1585 >> and passing the resulting C<$action> and the remaining arguments to C<<
1586 $c->uri_for >>.
1587
1588 You can also pass in a Catalyst::Action object, in which case it is passed to
1589 C<< $c->uri_for >>.
1590
1591 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1592
1593 For example, if the action looks like:
1594
1595  package MyApp::Controller::Users;
1596
1597  sub lst : Path('the-list') {}
1598
1599 You can use:
1600
1601  $c->uri_for_action('/users/lst')
1602
1603 and it will create the URI /users/the-list.
1604
1605 =item \@captures_and_args?
1606
1607 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1608 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1609 to interpolate all the parameters in the URI.
1610
1611 =item @args?
1612
1613 Optional list of extra arguments - can be supplied in the
1614 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1615 code.
1616
1617 Your action can have zero, a fixed or a variable number of args (e.g.
1618 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1619
1620 =item \%query_values?
1621
1622 Optional array reference of query parameters to append. E.g.
1623
1624   { foo => 'bar' }
1625
1626 will generate
1627
1628   /rest/of/your/uri?foo=bar
1629
1630 =back
1631
1632 =cut
1633
1634 sub uri_for_action {
1635     my ( $c, $path, @args ) = @_;
1636     my $action = blessed($path)
1637       ? $path
1638       : $c->dispatcher->get_action_by_path($path);
1639     unless (defined $action) {
1640       croak "Can't find action for path '$path'";
1641     }
1642     return $c->uri_for( $action, @args );
1643 }
1644
1645 =head2 $c->welcome_message
1646
1647 Returns the Catalyst welcome HTML page.
1648
1649 =cut
1650
1651 sub welcome_message {
1652     my $c      = shift;
1653     my $name   = $c->config->{name};
1654     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1655     my $prefix = Catalyst::Utils::appprefix( ref $c );
1656     $c->response->content_type('text/html; charset=utf-8');
1657     return <<"EOF";
1658 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1659     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1660 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1661     <head>
1662     <meta http-equiv="Content-Language" content="en" />
1663     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1664         <title>$name on Catalyst $VERSION</title>
1665         <style type="text/css">
1666             body {
1667                 color: #000;
1668                 background-color: #eee;
1669             }
1670             div#content {
1671                 width: 640px;
1672                 margin-left: auto;
1673                 margin-right: auto;
1674                 margin-top: 10px;
1675                 margin-bottom: 10px;
1676                 text-align: left;
1677                 background-color: #ccc;
1678                 border: 1px solid #aaa;
1679             }
1680             p, h1, h2 {
1681                 margin-left: 20px;
1682                 margin-right: 20px;
1683                 font-family: verdana, tahoma, sans-serif;
1684             }
1685             a {
1686                 font-family: verdana, tahoma, sans-serif;
1687             }
1688             :link, :visited {
1689                     text-decoration: none;
1690                     color: #b00;
1691                     border-bottom: 1px dotted #bbb;
1692             }
1693             :link:hover, :visited:hover {
1694                     color: #555;
1695             }
1696             div#topbar {
1697                 margin: 0px;
1698             }
1699             pre {
1700                 margin: 10px;
1701                 padding: 8px;
1702             }
1703             div#answers {
1704                 padding: 8px;
1705                 margin: 10px;
1706                 background-color: #fff;
1707                 border: 1px solid #aaa;
1708             }
1709             h1 {
1710                 font-size: 0.9em;
1711                 font-weight: normal;
1712                 text-align: center;
1713             }
1714             h2 {
1715                 font-size: 1.0em;
1716             }
1717             p {
1718                 font-size: 0.9em;
1719             }
1720             p img {
1721                 float: right;
1722                 margin-left: 10px;
1723             }
1724             span#appname {
1725                 font-weight: bold;
1726                 font-size: 1.6em;
1727             }
1728         </style>
1729     </head>
1730     <body>
1731         <div id="content">
1732             <div id="topbar">
1733                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1734                     $VERSION</h1>
1735              </div>
1736              <div id="answers">
1737                  <p>
1738                  <img src="$logo" alt="Catalyst Logo" />
1739                  </p>
1740                  <p>Welcome to the  world of Catalyst.
1741                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1742                     framework will make web development something you had
1743                     never expected it to be: Fun, rewarding, and quick.</p>
1744                  <h2>What to do now?</h2>
1745                  <p>That really depends  on what <b>you</b> want to do.
1746                     We do, however, provide you with a few starting points.</p>
1747                  <p>If you want to jump right into web development with Catalyst
1748                     you might want to start with a tutorial.</p>
1749 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1750 </pre>
1751 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1752 <pre>
1753 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1754 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1755 </code></pre>
1756                  <h2>What to do next?</h2>
1757                  <p>Next it's time to write an actual application. Use the
1758                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1759                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1760                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1761                     they can save you a lot of work.</p>
1762                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1763                     <p>Also, be sure to check out the vast and growing
1764                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1765                     you are likely to find what you need there.
1766                     </p>
1767
1768                  <h2>Need help?</h2>
1769                  <p>Catalyst has a very active community. Here are the main places to
1770                     get in touch with us.</p>
1771                  <ul>
1772                      <li>
1773                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1774                      </li>
1775                      <li>
1776                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1777                      </li>
1778                      <li>
1779                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1780                      </li>
1781                  </ul>
1782                  <h2>In conclusion</h2>
1783                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1784                     as we enjoyed making it. Please contact us if you have ideas
1785                     for improvement or other feedback.</p>
1786              </div>
1787          </div>
1788     </body>
1789 </html>
1790 EOF
1791 }
1792
1793 =head2 run_options
1794
1795 Contains a hash of options passed from the application script, including
1796 the original ARGV the script received, the processed values from that
1797 ARGV and any extra arguments to the script which were not processed.
1798
1799 This can be used to add custom options to your application's scripts
1800 and setup your application differently depending on the values of these
1801 options.
1802
1803 =head1 INTERNAL METHODS
1804
1805 These methods are not meant to be used by end users.
1806
1807 =head2 $c->components
1808
1809 Returns a hash of components.
1810
1811 =head2 $c->context_class
1812
1813 Returns or sets the context class.
1814
1815 =head2 $c->counter
1816
1817 Returns a hashref containing coderefs and execution counts (needed for
1818 deep recursion detection).
1819
1820 =head2 $c->depth
1821
1822 Returns the number of actions on the current internal execution stack.
1823
1824 =head2 $c->dispatch
1825
1826 Dispatches a request to actions.
1827
1828 =cut
1829
1830 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1831
1832 =head2 $c->dispatcher_class
1833
1834 Returns or sets the dispatcher class.
1835
1836 =head2 $c->dump_these
1837
1838 Returns a list of 2-element array references (name, structure) pairs
1839 that will be dumped on the error page in debug mode.
1840
1841 =cut
1842
1843 sub dump_these {
1844     my $c = shift;
1845     [ Request => $c->req ],
1846     [ Response => $c->res ],
1847     [ Stash => $c->stash ],
1848     [ Config => $c->config ];
1849 }
1850
1851 =head2 $c->engine_class
1852
1853 Returns or sets the engine class.
1854
1855 =head2 $c->execute( $class, $coderef )
1856
1857 Execute a coderef in given class and catch exceptions. Errors are available
1858 via $c->error.
1859
1860 =cut
1861
1862 sub execute {
1863     my ( $c, $class, $code ) = @_;
1864     $class = $c->component($class) || $class;
1865     $c->state(0);
1866
1867     if ( $c->depth >= $RECURSION ) {
1868         my $action = $code->reverse();
1869         $action = "/$action" unless $action =~ /->/;
1870         my $error = qq/Deep recursion detected calling "${action}"/;
1871         $c->log->error($error);
1872         $c->error($error);
1873         $c->state(0);
1874         return $c->state;
1875     }
1876
1877     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1878
1879     push( @{ $c->stack }, $code );
1880
1881     no warnings 'recursion';
1882     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1883     #      I have no idea how, ergo $ret (which appears to fix the issue)
1884     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1885
1886     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1887
1888     my $last = pop( @{ $c->stack } );
1889
1890     if ( my $error = $@ ) {
1891         #rethow if this can be handled by middleware
1892         if ( $c->_handle_http_exception($error) ) {
1893             foreach my $err (@{$c->error}) {
1894                 $c->log->error($err);
1895             }
1896             $c->clear_errors;
1897             $c->log->_flush if $c->log->can('_flush');
1898
1899             $error->can('rethrow') ? $error->rethrow : croak $error;
1900         }
1901         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1902             $error->rethrow if $c->depth > 1;
1903         }
1904         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1905             $error->rethrow if $c->depth > 0;
1906         }
1907         else {
1908             unless ( ref $error ) {
1909                 no warnings 'uninitialized';
1910                 chomp $error;
1911                 my $class = $last->class;
1912                 my $name  = $last->name;
1913                 $error = qq/Caught exception in $class->$name "$error"/;
1914             }
1915             $c->error($error);
1916         }
1917         $c->state(0);
1918     }
1919     return $c->state;
1920 }
1921
1922 sub _stats_start_execute {
1923     my ( $c, $code ) = @_;
1924     my $appclass = ref($c) || $c;
1925     return if ( ( $code->name =~ /^_.*/ )
1926         && ( !$appclass->config->{show_internal_actions} ) );
1927
1928     my $action_name = $code->reverse();
1929     $c->counter->{$action_name}++;
1930
1931     my $action = $action_name;
1932     $action = "/$action" unless $action =~ /->/;
1933
1934     # determine if the call was the result of a forward
1935     # this is done by walking up the call stack and looking for a calling
1936     # sub of Catalyst::forward before the eval
1937     my $callsub = q{};
1938     for my $index ( 2 .. 11 ) {
1939         last
1940         if ( ( caller($index) )[0] eq 'Catalyst'
1941             && ( caller($index) )[3] eq '(eval)' );
1942
1943         if ( ( caller($index) )[3] =~ /forward$/ ) {
1944             $callsub = ( caller($index) )[3];
1945             $action  = "-> $action";
1946             last;
1947         }
1948     }
1949
1950     my $uid = $action_name . $c->counter->{$action_name};
1951
1952     # is this a root-level call or a forwarded call?
1953     if ( $callsub =~ /forward$/ ) {
1954         my $parent = $c->stack->[-1];
1955
1956         # forward, locate the caller
1957         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1958             $c->stats->profile(
1959                 begin  => $action,
1960                 parent => "$parent" . $c->counter->{"$parent"},
1961                 uid    => $uid,
1962             );
1963         }
1964         else {
1965
1966             # forward with no caller may come from a plugin
1967             $c->stats->profile(
1968                 begin => $action,
1969                 uid   => $uid,
1970             );
1971         }
1972     }
1973     else {
1974
1975         # root-level call
1976         $c->stats->profile(
1977             begin => $action,
1978             uid   => $uid,
1979         );
1980     }
1981     return $action;
1982
1983 }
1984
1985 sub _stats_finish_execute {
1986     my ( $c, $info ) = @_;
1987     $c->stats->profile( end => $info );
1988 }
1989
1990 =head2 $c->finalize
1991
1992 Finalizes the request.
1993
1994 =cut
1995
1996 sub finalize {
1997     my $c = shift;
1998
1999     for my $error ( @{ $c->error } ) {
2000         $c->log->error($error);
2001     }
2002
2003     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
2004     # stuff like cometd and websockets
2005
2006     if($c->request->_has_io_fh) {
2007       $c->log_response;
2008       return;
2009     }
2010
2011     # Allow engine to handle finalize flow (for POE)
2012     my $engine = $c->engine;
2013     if ( my $code = $engine->can('finalize') ) {
2014         $engine->$code($c);
2015     }
2016     else {
2017
2018         $c->finalize_uploads;
2019
2020         # Error
2021         if ( $#{ $c->error } >= 0 ) {
2022             $c->finalize_error;
2023         }
2024
2025         $c->finalize_encoding;
2026         $c->finalize_headers unless $c->response->finalized_headers;
2027         $c->finalize_body;
2028     }
2029
2030     $c->log_response;
2031
2032     if ($c->use_stats) {
2033         my $elapsed = $c->stats->elapsed;
2034         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
2035         $c->log->info(
2036             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
2037     }
2038
2039     return $c->response->status;
2040 }
2041
2042 =head2 $c->finalize_body
2043
2044 Finalizes body.
2045
2046 =cut
2047
2048 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
2049
2050 =head2 $c->finalize_cookies
2051
2052 Finalizes cookies.
2053
2054 =cut
2055
2056 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
2057
2058 =head2 $c->finalize_error
2059
2060 Finalizes error.  If there is only one error in L</error> and it is an object that
2061 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2062 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2063 return the default error page (production mode).
2064
2065 =cut
2066
2067 sub finalize_error {
2068     my $c = shift;
2069     if($#{$c->error} > 0) {
2070         $c->engine->finalize_error( $c, @_ );
2071     } else {
2072         my ($error) = @{$c->error};
2073         if ( $c->_handle_http_exception($error) ) {
2074             # In the case where the error 'knows what it wants', becauses its PSGI
2075             # aware, just rethow and let middleware catch it
2076             $error->can('rethrow') ? $error->rethrow : croak $error;
2077         } else {
2078             $c->engine->finalize_error( $c, @_ )
2079         }
2080     }
2081 }
2082
2083 =head2 $c->finalize_headers
2084
2085 Finalizes headers.
2086
2087 =cut
2088
2089 sub finalize_headers {
2090     my $c = shift;
2091
2092     my $response = $c->response; #accessor calls can add up?
2093
2094     # Check if we already finalized headers
2095     return if $response->finalized_headers;
2096
2097     # Handle redirects
2098     if ( my $location = $response->redirect ) {
2099         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2100         $response->header( Location => $location );
2101     }
2102
2103     # Remove incorrectly added body and content related meta data when returning
2104     # an information response, or a response the is required to not include a body
2105
2106     $c->finalize_cookies;
2107
2108     # This currently is a NOOP but I don't want to remove it since I guess people
2109     # might have Response subclasses that use it for something... (JNAP)
2110     $c->response->finalize_headers();
2111
2112     # Done
2113     $response->finalized_headers(1);
2114 }
2115
2116 =head2 $c->finalize_encoding
2117
2118 Make sure your body is encoded properly IF you set an encoding.  By
2119 default the encoding is UTF-8 but you can disable it by explicitly setting the
2120 encoding configuration value to undef.
2121
2122 We can only encode when the body is a scalar.  Methods for encoding via the
2123 streaming interfaces (such as C<write> and C<write_fh> on L<Catalyst::Response>
2124 are available).
2125
2126 See L</ENCODING>.
2127
2128 =cut
2129
2130 sub finalize_encoding {
2131     my $c = shift;
2132     my $res = $c->res || return;
2133
2134     # Warn if the set charset is different from the one you put into encoding.  We need
2135     # to do this early since encodable_response is false for this condition and we need
2136     # to match the debug output for backcompat (there's a test for this...) -JNAP
2137     if(
2138       $res->content_type_charset and $c->encoding and 
2139       (uc($c->encoding->mime_name) ne uc($res->content_type_charset))
2140     ) {
2141         my $ct = lc($res->content_type_charset);
2142         $c->log->debug("Catalyst encoding config is set to encode in '" .
2143             $c->encoding->mime_name .
2144             "', content type is '$ct', not encoding ");
2145     }
2146
2147     if(
2148       ($res->encodable_response) and
2149       (defined($res->body)) and
2150       (ref(\$res->body) eq 'SCALAR')
2151     ) {
2152         $c->res->body( $c->encoding->encode( $c->res->body, $c->_encode_check ) );
2153
2154         # Set the charset if necessary.  This might be a bit bonkers since encodable response
2155         # is false when the set charset is not the same as the encoding mimetype (maybe 
2156         # confusing action at a distance here..
2157         # Don't try to set the charset if one already exists
2158         $c->res->content_type($c->res->content_type . "; charset=" . $c->encoding->mime_name)
2159           unless($c->res->content_type_charset);
2160     }
2161 }
2162
2163 =head2 $c->finalize_output
2164
2165 An alias for finalize_body.
2166
2167 =head2 $c->finalize_read
2168
2169 Finalizes the input after reading is complete.
2170
2171 =cut
2172
2173 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2174
2175 =head2 $c->finalize_uploads
2176
2177 Finalizes uploads. Cleans up any temporary files.
2178
2179 =cut
2180
2181 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2182
2183 =head2 $c->get_action( $action, $namespace )
2184
2185 Gets an action in a given namespace.
2186
2187 =cut
2188
2189 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2190
2191 =head2 $c->get_actions( $action, $namespace )
2192
2193 Gets all actions of a given name in a namespace and all parent
2194 namespaces.
2195
2196 =cut
2197
2198 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2199
2200 =head2 $app->handle_request( @arguments )
2201
2202 Called to handle each HTTP request.
2203
2204 =cut
2205
2206 sub handle_request {
2207     my ( $class, @arguments ) = @_;
2208
2209     # Always expect worst case!
2210     my $status = -1;
2211     try {
2212         if ($class->debug) {
2213             my $secs = time - $START || 1;
2214             my $av = sprintf '%.3f', $COUNT / $secs;
2215             my $time = localtime time;
2216             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2217         }
2218
2219         my $c = $class->prepare(@arguments);
2220         $c->dispatch;
2221         $status = $c->finalize;
2222     } catch {
2223         #rethow if this can be handled by middleware
2224         if ( $class->_handle_http_exception($_) ) {
2225             $_->can('rethrow') ? $_->rethrow : croak $_;
2226         }
2227         chomp(my $error = $_);
2228         $class->log->error(qq/Caught exception in engine "$error"/);
2229     };
2230
2231     $COUNT++;
2232
2233     if(my $coderef = $class->log->can('_flush')){
2234         $class->log->$coderef();
2235     }
2236     return $status;
2237 }
2238
2239 =head2 $class->prepare( @arguments )
2240
2241 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2242 etc.).
2243
2244 =cut
2245
2246 has _uploadtmp => (
2247     is => 'ro',
2248     predicate => '_has_uploadtmp',
2249 );
2250
2251 sub prepare {
2252     my ( $class, @arguments ) = @_;
2253
2254     # XXX
2255     # After the app/ctxt split, this should become an attribute based on something passed
2256     # into the application.
2257     $class->context_class( ref $class || $class ) unless $class->context_class;
2258
2259     my $uploadtmp = $class->config->{uploadtmp};
2260     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2261
2262     $c->response->_context($c);
2263
2264     #surely this is not the most efficient way to do things...
2265     $c->stats($class->stats_class->new)->enable($c->use_stats);
2266     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2267         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2268     }
2269
2270     try {
2271         # Allow engine to direct the prepare flow (for POE)
2272         if ( my $prepare = $c->engine->can('prepare') ) {
2273             $c->engine->$prepare( $c, @arguments );
2274         }
2275         else {
2276             $c->prepare_request(@arguments);
2277             $c->prepare_connection;
2278             $c->prepare_query_parameters;
2279             $c->prepare_headers; # Just hooks, no longer needed - they just
2280             $c->prepare_cookies; # cause the lazy attribute on req to build
2281             $c->prepare_path;
2282
2283             # Prepare the body for reading, either by prepare_body
2284             # or the user, if they are using $c->read
2285             $c->prepare_read;
2286
2287             # Parse the body unless the user wants it on-demand
2288             unless ( ref($c)->config->{parse_on_demand} ) {
2289                 $c->prepare_body;
2290             }
2291         }
2292         $c->prepare_action;
2293     }
2294     # VERY ugly and probably shouldn't rely on ->finalize actually working
2295     catch {
2296         # failed prepare is always due to an invalid request, right?
2297         $c->response->status(400);
2298         $c->response->content_type('text/plain');
2299         $c->response->body('Bad Request');
2300         # Note we call finalize and then die here, which escapes
2301         # finalize being called in the enclosing block..
2302         # It in fact couldn't be called, as we don't return $c..
2303         # This is a mess - but I'm unsure you can fix this without
2304         # breaking compat for people doing crazy things (we should set
2305         # the 400 and just return the ctx here IMO, letting finalize get called
2306         # above...
2307         $c->finalize;
2308         die $_;
2309     };
2310
2311     $c->log_request;
2312
2313     return $c;
2314 }
2315
2316 =head2 $c->prepare_action
2317
2318 Prepares action. See L<Catalyst::Dispatcher>.
2319
2320 =cut
2321
2322 sub prepare_action {
2323     my $c = shift;
2324     my $ret = $c->dispatcher->prepare_action( $c, @_);
2325
2326     if($c->encoding) {
2327         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2328           $_ = $c->_handle_param_unicode_decoding($_);
2329         }
2330     }
2331
2332     return $ret;
2333 }
2334
2335
2336 =head2 $c->prepare_body
2337
2338 Prepares message body.
2339
2340 =cut
2341
2342 sub prepare_body {
2343     my $c = shift;
2344
2345     return if $c->request->_has_body;
2346
2347     # Initialize on-demand data
2348     $c->engine->prepare_body( $c, @_ );
2349     $c->prepare_parameters;
2350     $c->prepare_uploads;
2351 }
2352
2353 =head2 $c->prepare_body_chunk( $chunk )
2354
2355 Prepares a chunk of data before sending it to L<HTTP::Body>.
2356
2357 See L<Catalyst::Engine>.
2358
2359 =cut
2360
2361 sub prepare_body_chunk {
2362     my $c = shift;
2363     $c->engine->prepare_body_chunk( $c, @_ );
2364 }
2365
2366 =head2 $c->prepare_body_parameters
2367
2368 Prepares body parameters.
2369
2370 =cut
2371
2372 sub prepare_body_parameters {
2373     my $c = shift;
2374     $c->request->prepare_body_parameters( $c, @_ );
2375 }
2376
2377 =head2 $c->prepare_connection
2378
2379 Prepares connection.
2380
2381 =cut
2382
2383 sub prepare_connection {
2384     my $c = shift;
2385     $c->request->prepare_connection($c);
2386 }
2387
2388 =head2 $c->prepare_cookies
2389
2390 Prepares cookies by ensuring that the attribute on the request
2391 object has been built.
2392
2393 =cut
2394
2395 sub prepare_cookies { my $c = shift; $c->request->cookies }
2396
2397 =head2 $c->prepare_headers
2398
2399 Prepares request headers by ensuring that the attribute on the request
2400 object has been built.
2401
2402 =cut
2403
2404 sub prepare_headers { my $c = shift; $c->request->headers }
2405
2406 =head2 $c->prepare_parameters
2407
2408 Prepares parameters.
2409
2410 =cut
2411
2412 sub prepare_parameters {
2413     my $c = shift;
2414     $c->prepare_body_parameters;
2415     $c->engine->prepare_parameters( $c, @_ );
2416 }
2417
2418 =head2 $c->prepare_path
2419
2420 Prepares path and base.
2421
2422 =cut
2423
2424 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2425
2426 =head2 $c->prepare_query_parameters
2427
2428 Prepares query parameters.
2429
2430 =cut
2431
2432 sub prepare_query_parameters {
2433     my $c = shift;
2434
2435     $c->engine->prepare_query_parameters( $c, @_ );
2436 }
2437
2438 =head2 $c->log_request
2439
2440 Writes information about the request to the debug logs.  This includes:
2441
2442 =over 4
2443
2444 =item * Request method, path, and remote IP address
2445
2446 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2447
2448 =item * Request parameters
2449
2450 =item * File uploads
2451
2452 =back
2453
2454 =cut
2455
2456 sub log_request {
2457     my $c = shift;
2458
2459     return unless $c->debug;
2460
2461     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2462     my $request = $dump->[1];
2463
2464     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2465     $method ||= '';
2466     $path = '/' unless length $path;
2467     $address ||= '';
2468
2469     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2470     $path = decode_utf8($path);
2471
2472     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2473
2474     $c->log_request_headers($request->headers);
2475
2476     if ( my $keywords = $request->query_keywords ) {
2477         $c->log->debug("Query keywords are: $keywords");
2478     }
2479
2480     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2481
2482     $c->log_request_uploads($request);
2483 }
2484
2485 =head2 $c->log_response
2486
2487 Writes information about the response to the debug logs by calling
2488 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2489
2490 =cut
2491
2492 sub log_response {
2493     my $c = shift;
2494
2495     return unless $c->debug;
2496
2497     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2498     my $response = $dump->[1];
2499
2500     $c->log_response_status_line($response);
2501     $c->log_response_headers($response->headers);
2502 }
2503
2504 =head2 $c->log_response_status_line($response)
2505
2506 Writes one line of information about the response to the debug logs.  This includes:
2507
2508 =over 4
2509
2510 =item * Response status code
2511
2512 =item * Content-Type header (if present)
2513
2514 =item * Content-Length header (if present)
2515
2516 =back
2517
2518 =cut
2519
2520 sub log_response_status_line {
2521     my ($c, $response) = @_;
2522
2523     $c->log->debug(
2524         sprintf(
2525             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2526             $response->status                            || 'unknown',
2527             $response->headers->header('Content-Type')   || 'unknown',
2528             $response->headers->header('Content-Length') || 'unknown'
2529         )
2530     );
2531 }
2532
2533 =head2 $c->log_response_headers($headers);
2534
2535 Hook method which can be wrapped by plugins to log the response headers.
2536 No-op in the default implementation.
2537
2538 =cut
2539
2540 sub log_response_headers {}
2541
2542 =head2 $c->log_request_parameters( query => {}, body => {} )
2543
2544 Logs request parameters to debug logs
2545
2546 =cut
2547
2548 sub log_request_parameters {
2549     my $c          = shift;
2550     my %all_params = @_;
2551
2552     return unless $c->debug;
2553
2554     my $column_width = Catalyst::Utils::term_width() - 44;
2555     foreach my $type (qw(query body)) {
2556         my $params = $all_params{$type};
2557         next if ! keys %$params;
2558         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2559         for my $key ( sort keys %$params ) {
2560             my $param = $params->{$key};
2561             my $value = defined($param) ? $param : '';
2562             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2563         }
2564         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2565     }
2566 }
2567
2568 =head2 $c->log_request_uploads
2569
2570 Logs file uploads included in the request to the debug logs.
2571 The parameter name, filename, file type, and file size are all included in
2572 the debug logs.
2573
2574 =cut
2575
2576 sub log_request_uploads {
2577     my $c = shift;
2578     my $request = shift;
2579     return unless $c->debug;
2580     my $uploads = $request->uploads;
2581     if ( keys %$uploads ) {
2582         my $t = Text::SimpleTable->new(
2583             [ 12, 'Parameter' ],
2584             [ 26, 'Filename' ],
2585             [ 18, 'Type' ],
2586             [ 9,  'Size' ]
2587         );
2588         for my $key ( sort keys %$uploads ) {
2589             my $upload = $uploads->{$key};
2590             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2591                 $t->row( $key, $u->filename, $u->type, $u->size );
2592             }
2593         }
2594         $c->log->debug( "File Uploads are:\n" . $t->draw );
2595     }
2596 }
2597
2598 =head2 $c->log_request_headers($headers);
2599
2600 Hook method which can be wrapped by plugins to log the request headers.
2601 No-op in the default implementation.
2602
2603 =cut
2604
2605 sub log_request_headers {}
2606
2607 =head2 $c->log_headers($type => $headers)
2608
2609 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2610
2611 =cut
2612
2613 sub log_headers {
2614     my $c       = shift;
2615     my $type    = shift;
2616     my $headers = shift;    # an HTTP::Headers instance
2617
2618     return unless $c->debug;
2619
2620     my $column_width = Catalyst::Utils::term_width() - 28;
2621     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2622     $headers->scan(
2623         sub {
2624             my ( $name, $value ) = @_;
2625             $t->row( $name, $value );
2626         }
2627     );
2628     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2629 }
2630
2631
2632 =head2 $c->prepare_read
2633
2634 Prepares the input for reading.
2635
2636 =cut
2637
2638 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2639
2640 =head2 $c->prepare_request
2641
2642 Prepares the engine request.
2643
2644 =cut
2645
2646 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2647
2648 =head2 $c->prepare_uploads
2649
2650 Prepares uploads.
2651
2652 =cut
2653
2654 sub prepare_uploads {
2655     my $c = shift;
2656     $c->engine->prepare_uploads( $c, @_ );
2657 }
2658
2659 =head2 $c->prepare_write
2660
2661 Prepares the output for writing.
2662
2663 =cut
2664
2665 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2666
2667 =head2 $c->request_class
2668
2669 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2670
2671 =head2 $c->response_class
2672
2673 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2674
2675 =head2 $c->read( [$maxlength] )
2676
2677 Reads a chunk of data from the request body. This method is designed to
2678 be used in a while loop, reading C<$maxlength> bytes on every call.
2679 C<$maxlength> defaults to the size of the request if not specified.
2680
2681 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2682 directly.
2683
2684 Warning: If you use read(), Catalyst will not process the body,
2685 so you will not be able to access POST parameters or file uploads via
2686 $c->request.  You must handle all body parsing yourself.
2687
2688 =cut
2689
2690 sub read { my $c = shift; return $c->request->read( @_ ) }
2691
2692 =head2 $c->run
2693
2694 Starts the engine.
2695
2696 =cut
2697
2698 sub run {
2699   my $app = shift;
2700   $app->_make_immutable_if_needed;
2701   $app->engine_loader->needs_psgi_engine_compat_hack ?
2702     $app->engine->run($app, @_) :
2703       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2704 }
2705
2706 sub _make_immutable_if_needed {
2707     my $class = shift;
2708     my $meta = find_meta($class);
2709     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2710     if (
2711         $meta->is_immutable
2712         && ! { $meta->immutable_options }->{replace_constructor}
2713         && $isa_ca
2714     ) {
2715         warn("You made your application class ($class) immutable, "
2716             . "but did not inline the\nconstructor. "
2717             . "This will break catalyst, as your app \@ISA "
2718             . "Class::Accessor(::Fast)?\nPlease pass "
2719             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2720     }
2721     unless ($meta->is_immutable) {
2722         # XXX - FIXME warning here as you should make your app immutable yourself.
2723         $meta->make_immutable(
2724             replace_constructor => 1,
2725         );
2726     }
2727 }
2728
2729 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2730
2731 Sets an action in a given namespace.
2732
2733 =cut
2734
2735 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2736
2737 =head2 $c->setup_actions($component)
2738
2739 Sets up actions for a component.
2740
2741 =cut
2742
2743 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2744
2745 =head2 $c->setup_components
2746
2747 This method is called internally to set up the application's components.
2748
2749 It finds modules by calling the L<locate_components> method, expands them to
2750 package names with the L<expand_component_module> method, and then installs
2751 each component into the application.
2752
2753 The C<setup_components> config option is passed to both of the above methods.
2754
2755 Installation of each component is performed by the L<setup_component> method,
2756 below.
2757
2758 =cut
2759
2760 sub setup_components {
2761     my $class = shift;
2762
2763     my $config  = $class->config->{ setup_components };
2764
2765     my @comps = $class->locate_components($config);
2766     my %comps = map { $_ => 1 } @comps;
2767
2768     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2769     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2770         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2771     ) if $deprecatedcatalyst_component_names;
2772
2773     for my $component ( @comps ) {
2774
2775         # We pass ignore_loaded here so that overlay files for (e.g.)
2776         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2777         # we know M::P::O found a file on disk so this is safe
2778
2779         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2780     }
2781
2782     for my $component (@comps) {
2783         my $instance = $class->components->{ $component } = $class->setup_component($component);
2784         my @expanded_components = $instance->can('expand_modules')
2785             ? $instance->expand_modules( $component, $config )
2786             : $class->expand_component_module( $component, $config );
2787         for my $component (@expanded_components) {
2788             next if $comps{$component};
2789             $class->components->{ $component } = $class->setup_component($component);
2790         }
2791     }
2792 }
2793
2794 =head2 $c->locate_components( $setup_component_config )
2795
2796 This method is meant to provide a list of component modules that should be
2797 setup for the application.  By default, it will use L<Module::Pluggable>.
2798
2799 Specify a C<setup_components> config option to pass additional options directly
2800 to L<Module::Pluggable>. To add additional search paths, specify a key named
2801 C<search_extra> as an array reference. Items in the array beginning with C<::>
2802 will have the application class name prepended to them.
2803
2804 =cut
2805
2806 sub locate_components {
2807     my $class  = shift;
2808     my $config = shift;
2809
2810     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
2811     my $extra   = delete $config->{ search_extra } || [];
2812
2813     unshift @paths, @$extra;
2814
2815     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
2816       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
2817       %$config
2818     )->plugins } @paths;
2819
2820     return @comps;
2821 }
2822
2823 =head2 $c->expand_component_module( $component, $setup_component_config )
2824
2825 Components found by C<locate_components> will be passed to this method, which
2826 is expected to return a list of component (package) names to be set up.
2827
2828 =cut
2829
2830 sub expand_component_module {
2831     my ($class, $module) = @_;
2832     return Devel::InnerPackage::list_packages( $module );
2833 }
2834
2835 =head2 $c->setup_component
2836
2837 =cut
2838
2839 sub setup_component {
2840     my( $class, $component ) = @_;
2841
2842     unless ( $component->can( 'COMPONENT' ) ) {
2843         return $component;
2844     }
2845
2846     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2847     my $config = $class->config->{ $suffix } || {};
2848     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2849     # methods also pass it. local to avoid pointlessly shitting in config
2850     # for the debug screen, as $component is already the key name.
2851     local $config->{catalyst_component_name} = $component;
2852
2853     my $instance = eval { $component->COMPONENT( $class, $config ); };
2854
2855     if ( my $error = $@ ) {
2856         chomp $error;
2857         Catalyst::Exception->throw(
2858             message => qq/Couldn't instantiate component "$component", "$error"/
2859         );
2860     }
2861
2862     unless (blessed $instance) {
2863         my $metaclass = Moose::Util::find_meta($component);
2864         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2865         my $component_method_from = $method_meta->associated_metaclass->name;
2866         my $value = defined($instance) ? $instance : 'undef';
2867         Catalyst::Exception->throw(
2868             message =>
2869             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2870         );
2871     }
2872     return $instance;
2873 }
2874
2875 =head2 $c->setup_dispatcher
2876
2877 Sets up dispatcher.
2878
2879 =cut
2880
2881 sub setup_dispatcher {
2882     my ( $class, $dispatcher ) = @_;
2883
2884     if ($dispatcher) {
2885         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2886     }
2887
2888     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2889         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2890     }
2891
2892     unless ($dispatcher) {
2893         $dispatcher = $class->dispatcher_class;
2894     }
2895
2896     load_class($dispatcher);
2897
2898     # dispatcher instance
2899     $class->dispatcher( $dispatcher->new );
2900 }
2901
2902 =head2 $c->setup_engine
2903
2904 Sets up engine.
2905
2906 =cut
2907
2908 sub engine_class {
2909     my ($class, $requested_engine) = @_;
2910
2911     if (!$class->engine_loader || $requested_engine) {
2912         $class->engine_loader(
2913             Catalyst::EngineLoader->new({
2914                 application_name => $class,
2915                 (defined $requested_engine
2916                      ? (catalyst_engine_class => $requested_engine) : ()),
2917             }),
2918         );
2919     }
2920
2921     $class->engine_loader->catalyst_engine_class;
2922 }
2923
2924 sub setup_engine {
2925     my ($class, $requested_engine) = @_;
2926
2927     my $engine = do {
2928         my $loader = $class->engine_loader;
2929
2930         if (!$loader || $requested_engine) {
2931             $loader = Catalyst::EngineLoader->new({
2932                 application_name => $class,
2933                 (defined $requested_engine
2934                      ? (requested_engine => $requested_engine) : ()),
2935             }),
2936
2937             $class->engine_loader($loader);
2938         }
2939
2940         $loader->catalyst_engine_class;
2941     };
2942
2943     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2944     return if $class->loading_psgi_file;
2945
2946     load_class($engine);
2947
2948     if ($ENV{MOD_PERL}) {
2949         my $apache = $class->engine_loader->auto;
2950
2951         my $meta = find_meta($class);
2952         my $was_immutable = $meta->is_immutable;
2953         my %immutable_options = $meta->immutable_options;
2954         $meta->make_mutable if $was_immutable;
2955
2956         $meta->add_method(handler => sub {
2957             my $r = shift;
2958             my $psgi_app = $class->_finalized_psgi_app;
2959             $apache->call_app($r, $psgi_app);
2960         });
2961
2962         $meta->make_immutable(%immutable_options) if $was_immutable;
2963     }
2964
2965     $class->engine( $engine->new );
2966
2967     return;
2968 }
2969
2970 ## This exists just to supply a prebuild psgi app for mod_perl and for the 
2971 ## build in server support (back compat support for pre psgi port behavior).
2972 ## This is so that we don't build a new psgi app for each request when using
2973 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2974
2975 sub _finalized_psgi_app {
2976     my ($app) = @_;
2977
2978     unless ($app->_psgi_app) {
2979         my $psgi_app = $app->_setup_psgi_app;
2980         $app->_psgi_app($psgi_app);
2981     }
2982
2983     return $app->_psgi_app;
2984 }
2985
2986 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2987 ## home directory and load that and return it (just assume it is doing the 
2988 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2989 ## in default_middleware and return it ( this is for backward compatibility
2990 ## with pre psgi port behavior ).
2991
2992 sub _setup_psgi_app {
2993     my ($app) = @_;
2994
2995     for my $home (Path::Class::Dir->new($app->config->{home})) {
2996         my $psgi_file = $home->file(
2997             Catalyst::Utils::appprefix($app) . '.psgi',
2998         );
2999
3000         next unless -e $psgi_file;
3001
3002         # If $psgi_file calls ->setup_engine, it's doing so to load
3003         # Catalyst::Engine::PSGI. But if it does that, we're only going to
3004         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
3005         # anyway. So set a flag (ick) that tells setup_engine not to populate
3006         # $c->engine or do any other things we might regret.
3007
3008         $app->loading_psgi_file(1);
3009         my $psgi_app = Plack::Util::load_psgi($psgi_file);
3010         $app->loading_psgi_file(0);
3011
3012         return $psgi_app
3013             unless $app->engine_loader->needs_psgi_engine_compat_hack;
3014
3015         warn <<"EOW";
3016 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
3017
3018 Its content has been ignored. Please consult the Catalyst::Upgrading
3019 documentation on how to upgrade from Catalyst::Engine::PSGI.
3020 EOW
3021     }
3022
3023     return $app->apply_default_middlewares($app->psgi_app);
3024 }
3025
3026 =head2 $c->apply_default_middlewares
3027
3028 Adds the following L<Plack> middlewares to your application, since they are
3029 useful and commonly needed:
3030
3031 L<Plack::Middleware::LighttpdScriptNameFix> (if you are using Lighttpd),
3032 L<Plack::Middleware::IIS6ScriptNameFix> (always applied since this middleware
3033 is smart enough to conditionally apply itself).
3034
3035 We will also automatically add L<Plack::Middleware::ReverseProxy> if we notice
3036 that your HTTP $env variable C<REMOTE_ADDR> is '127.0.0.1'.  This is usually
3037 an indication that your server is running behind a proxy frontend.  However in
3038 2014 this is often not the case.  We preserve this code for backwards compatibility
3039 however I B<highly> recommend that if you are running the server behind a front
3040 end proxy that you clearly indicate so with the C<using_frontend_proxy> configuration
3041 setting to true for your environment configurations that run behind a proxy.  This
3042 way if you change your front end proxy address someday your code would inexplicably
3043 stop working as expected.
3044
3045 Additionally if we detect we are using Nginx, we add a bit of custom middleware
3046 to solve some problems with the way that server handles $ENV{PATH_INFO} and
3047 $ENV{SCRIPT_NAME}.
3048
3049 Please B<NOTE> that if you do use C<using_frontend_proxy> the middleware is now
3050 adding via C<registered_middleware> rather than this method.
3051
3052 If you are using Lighttpd or IIS6 you may wish to apply these middlewares.  In
3053 general this is no longer a common case but we have this here for backward
3054 compatibility.
3055
3056 =cut
3057
3058
3059 sub apply_default_middlewares {
3060     my ($app, $psgi_app) = @_;
3061
3062     # Don't add this conditional IF we are explicitly saying we want the
3063     # frontend proxy support.  We don't need it here since if that is the
3064     # case it will be always loaded in the default_middleware.
3065
3066     unless($app->config->{using_frontend_proxy}) {
3067       $psgi_app = Plack::Middleware::Conditional->wrap(
3068           $psgi_app,
3069           builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
3070           condition => sub {
3071               my ($env) = @_;
3072               return if $app->config->{ignore_frontend_proxy};
3073               return $env->{REMOTE_ADDR} eq '127.0.0.1';
3074           },
3075       );
3076     }
3077
3078     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3079     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3080     $psgi_app = Plack::Middleware::Conditional->wrap(
3081         $psgi_app,
3082         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3083         condition => sub {
3084             my ($env) = @_;
3085             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3086             return unless $1 < 4.23;
3087             1;
3088         },
3089     );
3090
3091     # we're applying this unconditionally as the middleware itself already makes
3092     # sure it doesn't fuck things up if it's not running under one of the right
3093     # IIS versions
3094     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3095
3096     # And another IIS issue, this time with IIS7.
3097     $psgi_app = Plack::Middleware::Conditional->wrap(
3098         $psgi_app,
3099         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3100         condition => sub {
3101             my ($env) = @_;
3102             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3103         },
3104     );
3105
3106     return $psgi_app;
3107 }
3108
3109 =head2 App->psgi_app
3110
3111 =head2 App->to_app
3112
3113 Returns a PSGI application code reference for the catalyst application
3114 C<$c>. This is the bare application created without the C<apply_default_middlewares>
3115 method called.  We do however apply C<registered_middleware> since those are
3116 integral to how L<Catalyst> functions.  Also, unlike starting your application
3117 with a generated server script (via L<Catalyst::Devel> and C<catalyst.pl>) we do
3118 not attempt to return a valid L<PSGI> application using any existing C<${myapp}.psgi>
3119 scripts in your $HOME directory.
3120
3121 B<NOTE> C<apply_default_middlewares> was originally created when the first PSGI
3122 port was done for v5.90000.  These are middlewares that are added to achieve
3123 backward compatibility with older applications.  If you start your application
3124 using one of the supplied server scripts (generated with L<Catalyst::Devel> and
3125 the project skeleton script C<catalyst.pl>) we apply C<apply_default_middlewares>
3126 automatically.  This was done so that pre and post PSGI port applications would
3127 work the same way.
3128
3129 This is what you want to be using to retrieve the PSGI application code
3130 reference of your Catalyst application for use in a custom F<.psgi> or in your
3131 own created server modules.
3132
3133 =cut
3134
3135 *to_app = \&psgi_app;
3136
3137 sub psgi_app {
3138     my ($app) = @_;
3139     my $psgi = $app->engine->build_psgi_app($app);
3140     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3141 }
3142
3143 =head2 $c->setup_home
3144
3145 Sets up the home directory.
3146
3147 =cut
3148
3149 sub setup_home {
3150     my ( $class, $home ) = @_;
3151
3152     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3153         $home = $env;
3154     }
3155
3156     $home ||= Catalyst::Utils::home($class);
3157
3158     if ($home) {
3159         #I remember recently being scolded for assigning config values like this
3160         $class->config->{home} ||= $home;
3161         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3162     }
3163 }
3164
3165 =head2 $c->setup_encoding
3166
3167 Sets up the input/output encoding. See L<ENCODING>
3168
3169 =cut
3170
3171 sub setup_encoding {
3172     my $c = shift;
3173     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3174         # Ok, so the user has explicitly said "I don't want encoding..."
3175         return;
3176     } else {
3177       my $enc = defined($c->config->{encoding}) ?
3178         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3179       $c->encoding($enc);
3180     }
3181 }
3182
3183 =head2 handle_unicode_encoding_exception
3184
3185 Hook to let you customize how encoding errors are handled.  By default
3186 we just throw an exception.  Receives a hashref of debug information.
3187 Example:
3188
3189     $c->handle_unicode_encoding_exception({
3190         param_value => $value,
3191         error_msg => $_,
3192             encoding_step => 'params',
3193         });
3194
3195 =cut
3196
3197 sub handle_unicode_encoding_exception {
3198     my ( $self, $exception_ctx ) = @_;
3199     die $exception_ctx->{error_msg};
3200 }
3201
3202 # Some unicode helpers cargo culted from the old plugin.  These could likely
3203 # be neater.
3204
3205 sub _handle_unicode_decoding {
3206     my ( $self, $value ) = @_;
3207
3208     return unless defined $value;
3209
3210     ## I think this mess is to support the old nested
3211     if ( ref $value eq 'ARRAY' ) {
3212         foreach ( @$value ) {
3213             $_ = $self->_handle_unicode_decoding($_);
3214         }
3215         return $value;
3216     }
3217     elsif ( ref $value eq 'HASH' ) {
3218         foreach (keys %$value) {
3219             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3220             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3221
3222             # If the key was encoded we now have two (the original and current so
3223             # delete the original.
3224             delete $value->{$_} if $_ ne $encoded_key;
3225         }
3226         return $value;
3227     }
3228     else {
3229         return $self->_handle_param_unicode_decoding($value);
3230     }
3231 }
3232
3233 sub _handle_param_unicode_decoding {
3234     my ( $self, $value ) = @_;
3235     return unless defined $value; # not in love with just ignoring undefs - jnap
3236     return $value if blessed($value); #don't decode when the value is an object.
3237
3238     my $enc = $self->encoding;
3239     return try {
3240       $enc->decode( $value, $self->_encode_check );
3241     }
3242     catch {
3243         $self->handle_unicode_encoding_exception({
3244             param_value => $value,
3245             error_msg => $_,
3246             encoding_step => 'params',
3247         });
3248     };
3249 }
3250
3251 =head2 $c->setup_log
3252
3253 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3254 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3255 log to.
3256
3257 This method also installs a C<debug> method that returns a true value into the
3258 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3259 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3260
3261 Note that if the log has already been setup, by either a previous call to
3262 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3263 that this method won't actually set up the log object.
3264
3265 =cut
3266
3267 sub setup_log {
3268     my ( $class, $levels ) = @_;
3269
3270     $levels ||= '';
3271     $levels =~ s/^\s+//;
3272     $levels =~ s/\s+$//;
3273     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3274
3275     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3276     if ( defined $env_debug ) {
3277         $levels{debug} = 1 if $env_debug; # Ugly!
3278         delete($levels{debug}) unless $env_debug;
3279     }
3280
3281     unless ( $class->log ) {
3282         $class->log( Catalyst::Log->new(keys %levels) );
3283     }
3284
3285     if ( $levels{debug} ) {
3286         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3287         $class->log->debug('Debug messages enabled');
3288     }
3289 }
3290
3291 =head2 $c->setup_plugins
3292
3293 Sets up plugins.
3294
3295 =cut
3296
3297 =head2 $c->setup_stats
3298
3299 Sets up timing statistics class.
3300
3301 =cut
3302
3303 sub setup_stats {
3304     my ( $class, $stats ) = @_;
3305
3306     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3307
3308     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3309     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3310         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3311         $class->log->debug('Statistics enabled');
3312     }
3313 }
3314
3315
3316 =head2 $c->registered_plugins
3317
3318 Returns a sorted list of the plugins which have either been stated in the
3319 import list.
3320
3321 If passed a given plugin name, it will report a boolean value indicating
3322 whether or not that plugin is loaded.  A fully qualified name is required if
3323 the plugin name does not begin with C<Catalyst::Plugin::>.
3324
3325  if ($c->registered_plugins('Some::Plugin')) {
3326      ...
3327  }
3328
3329 =cut
3330
3331 {
3332
3333     sub registered_plugins {
3334         my $proto = shift;
3335         return sort keys %{ $proto->_plugins } unless @_;
3336         my $plugin = shift;
3337         return 1 if exists $proto->_plugins->{$plugin};
3338         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3339     }
3340
3341     sub _register_plugin {
3342         my ( $proto, $plugin, $instant ) = @_;
3343         my $class = ref $proto || $proto;
3344
3345         load_class( $plugin );
3346         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3347             if $plugin->isa( 'Catalyst::Component' );
3348         my $plugin_meta = Moose::Meta::Class->create($plugin);
3349         if (!$plugin_meta->has_method('new')
3350             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3351             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3352         }
3353         if (!$instant && !$proto->_plugins->{$plugin}) {
3354             my $meta = Class::MOP::get_metaclass_by_name($class);
3355             $meta->superclasses($plugin, $meta->superclasses);
3356         }
3357         $proto->_plugins->{$plugin} = 1;
3358         return $class;
3359     }
3360
3361     sub _default_plugins { return qw() }
3362
3363     sub setup_plugins {
3364         my ( $class, $plugins ) = @_;
3365
3366         $class->_plugins( {} ) unless $class->_plugins;
3367         $plugins = [ grep {
3368             m/Unicode::Encoding/ ? do {
3369                 $class->log->warn(
3370                     'Unicode::Encoding plugin is auto-applied,'
3371                     . ' please remove this from your appclass'
3372                     . ' and make sure to define "encoding" config'
3373                 );
3374                 unless (exists $class->config->{'encoding'}) {
3375                   $class->config->{'encoding'} = 'UTF-8';
3376                 }
3377                 () }
3378                 : $_
3379         } @$plugins ];
3380         push @$plugins, $class->_default_plugins;
3381         $plugins = Data::OptList::mkopt($plugins || []);
3382
3383         my @plugins = map {
3384             [ Catalyst::Utils::resolve_namespace(
3385                   $class . '::Plugin',
3386                   'Catalyst::Plugin', $_->[0]
3387               ),
3388               $_->[1],
3389             ]
3390          } @{ $plugins };
3391
3392         for my $plugin ( reverse @plugins ) {
3393             load_class($plugin->[0], $plugin->[1]);
3394             my $meta = find_meta($plugin->[0]);
3395             next if $meta && $meta->isa('Moose::Meta::Role');
3396
3397             $class->_register_plugin($plugin->[0]);
3398         }
3399
3400         my @roles =
3401             map  { $_->[0]->name, $_->[1] }
3402             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3403             map  { [find_meta($_->[0]), $_->[1]] }
3404             @plugins;
3405
3406         Moose::Util::apply_all_roles(
3407             $class => @roles
3408         ) if @roles;
3409     }
3410 }
3411
3412 =head2 default_middleware
3413
3414 Returns a list of instantiated PSGI middleware objects which is the default
3415 middleware that is active for this application (taking any configuration
3416 options into account, excluding your custom added middleware via the C<psgi_middleware>
3417 configuration option).  You can override this method if you wish to change
3418 the default middleware (although do so at risk since some middleware is vital
3419 to application function.)
3420
3421 The current default middleware list is:
3422
3423       Catalyst::Middleware::Stash
3424       Plack::Middleware::HTTPExceptions
3425       Plack::Middleware::RemoveRedundantBody
3426       Plack::Middleware::FixMissingBodyInRedirect
3427       Plack::Middleware::ContentLength
3428       Plack::Middleware::MethodOverride
3429       Plack::Middleware::Head
3430
3431 If the configuration setting C<using_frontend_proxy> is true we add:
3432
3433       Plack::Middleware::ReverseProxy
3434
3435 If the configuration setting C<using_frontend_proxy_path> is true we add:
3436
3437       Plack::Middleware::ReverseProxyPath
3438
3439 But B<NOTE> that L<Plack::Middleware::ReverseProxyPath> is not a dependency of the
3440 L<Catalyst> distribution so if you want to use this option you should add it to
3441 your project distribution file.
3442
3443 These middlewares will be added at L</setup_middleware> during the
3444 L</setup> phase of application startup.
3445
3446 =cut
3447
3448 sub default_middleware {
3449     my $class = shift;
3450     my @mw = (
3451       Catalyst::Middleware::Stash->new,
3452       Plack::Middleware::HTTPExceptions->new,
3453       Plack::Middleware::RemoveRedundantBody->new,
3454       Plack::Middleware::FixMissingBodyInRedirect->new,
3455       Plack::Middleware::ContentLength->new,
3456       Plack::Middleware::MethodOverride->new,
3457       Plack::Middleware::Head->new);
3458
3459     if($class->config->{using_frontend_proxy}) {
3460         push @mw, Plack::Middleware::ReverseProxy->new;
3461     }
3462
3463     if($class->config->{using_frontend_proxy_path}) {
3464         if(Class::Load::try_load_class('Plack::Middleware::ReverseProxyPath')) {
3465             push @mw, Plack::Middleware::ReverseProxyPath->new;
3466         } else {
3467           $class->log->error("Cannot use configuration 'using_frontend_proxy_path' because 'Plack::Middleware::ReverseProxyPath' is not installed");
3468         }
3469     }
3470
3471     return @mw;
3472 }
3473
3474 =head2 registered_middlewares
3475
3476 Read only accessor that returns an array of all the middleware in the order
3477 that they were added (which is the REVERSE of the order they will be applied).
3478
3479 The values returned will be either instances of L<Plack::Middleware> or of a
3480 compatible interface, or a coderef, which is assumed to be inlined middleware
3481
3482 =head2 setup_middleware (?@middleware)
3483
3484 Read configuration information stored in configuration key C<psgi_middleware> or
3485 from passed @args.
3486
3487 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3488 to use it to enable L<Plack::Middleware>
3489
3490 This method is automatically called during 'setup' of your application, so
3491 you really don't need to invoke it.  However you may do so if you find the idea
3492 of loading middleware via configuration weird :).  For example:
3493
3494     package MyApp;
3495
3496     use Catalyst;
3497
3498     __PACKAGE__->setup_middleware('Head');
3499     __PACKAGE__->setup;
3500
3501 When we read middleware definitions from configuration, we reverse the list
3502 which sounds odd but is likely how you expect it to work if you have prior
3503 experience with L<Plack::Builder> or if you previously used the plugin
3504 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3505
3506 So basically your middleware handles an incoming request from the first
3507 registered middleware, down and handles the response from the last middleware
3508 up.
3509
3510 =cut
3511
3512 sub registered_middlewares {
3513     my $class = shift;
3514     if(my $middleware = $class->_psgi_middleware) {
3515         my @mw = ($class->default_middleware, @$middleware);
3516
3517         if($class->config->{using_frontend_proxy}) {
3518           push @mw, Plack::Middleware::ReverseProxy->new;
3519         }
3520
3521         return @mw;
3522     } else {
3523         die "You cannot call ->registered_middlewares until middleware has been setup";
3524     }
3525 }
3526
3527 sub setup_middleware {
3528     my $class = shift;
3529     my @middleware_definitions;
3530
3531     # If someone calls this method you can add middleware with args.  However if its
3532     # called without an arg we need to setup the configuration middleware.
3533     if(@_) {
3534       @middleware_definitions = reverse(@_);
3535     } else {
3536       @middleware_definitions = reverse(@{$class->config->{'psgi_middleware'}||[]})
3537         unless $class->finalized_default_middleware;
3538       $class->finalized_default_middleware(1); # Only do this once, just in case some people call setup over and over...
3539     }
3540
3541     my @middleware = ();
3542     while(my $next = shift(@middleware_definitions)) {
3543         if(ref $next) {
3544             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3545                 push @middleware, $next;
3546             } elsif(ref $next eq 'CODE') {
3547                 push @middleware, $next;
3548             } elsif(ref $next eq 'HASH') {
3549                 my $namespace = shift @middleware_definitions;
3550                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3551                 push @middleware, $mw;
3552             } else {
3553               die "I can't handle middleware definition ${\ref $next}";
3554             }
3555         } else {
3556           my $mw = $class->Catalyst::Utils::build_middleware($next);
3557           push @middleware, $mw;
3558         }
3559     }
3560
3561     my @existing = @{$class->_psgi_middleware || []};
3562     $class->_psgi_middleware([@middleware,@existing,]);
3563 }
3564
3565 =head2 registered_data_handlers
3566
3567 A read only copy of registered Data Handlers returned as a Hash, where each key
3568 is a content type and each value is a subref that attempts to decode that content
3569 type.
3570
3571 =head2 setup_data_handlers (?@data_handler)
3572
3573 Read configuration information stored in configuration key C<data_handlers> or
3574 from passed @args.
3575
3576 See under L</CONFIGURATION> information regarding C<data_handlers>.
3577
3578 This method is automatically called during 'setup' of your application, so
3579 you really don't need to invoke it.
3580
3581 =head2 default_data_handlers
3582
3583 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3584 only two default data handlers, for 'application/json' and an alternative to
3585 'application/x-www-form-urlencoded' which supposed nested form parameters via
3586 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3587
3588 The 'application/json' data handler is used to parse incoming JSON into a Perl
3589 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3590 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3591 JSON decoder, and has the smallest dependency impact.
3592
3593 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3594 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3595 order to get the best performance.  You should add either to your dependency
3596 list (Makefile.PL, dist.ini, cpanfile, etc.)
3597
3598 =cut
3599
3600 sub registered_data_handlers {
3601     my $class = shift;
3602     if(my $data_handlers = $class->_data_handlers) {
3603         return %$data_handlers;
3604     } else {
3605         $class->setup_data_handlers;
3606         return $class->registered_data_handlers;
3607     }
3608 }
3609
3610 sub setup_data_handlers {
3611     my ($class, %data_handler_callbacks) = @_;
3612     %data_handler_callbacks = (
3613       %{$class->default_data_handlers},
3614       %{$class->config->{'data_handlers'}||+{}},
3615       %data_handler_callbacks);
3616
3617     $class->_data_handlers(\%data_handler_callbacks);
3618 }
3619
3620 sub default_data_handlers {
3621     my ($class) = @_;
3622     return +{
3623       'application/x-www-form-urlencoded' => sub {
3624           my ($fh, $req) = @_;
3625           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3626           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3627             ->can('build_cgi_struct')->($params);
3628       },
3629       'application/json' => sub {
3630           my ($fh, $req) = @_;
3631           my $parser = Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON');
3632           my $slurped;
3633           return eval { 
3634             local $/;
3635             $slurped = $fh->getline;
3636             $parser->can("decode_json")->($slurped); # decode_json does utf8 decoding for us
3637           } || Catalyst::Exception->throw(sprintf "Error Parsing POST '%s', Error: %s", (defined($slurped) ? $slurped : 'undef') ,$@);
3638         },
3639     };
3640 }
3641
3642 sub _handle_http_exception {
3643     my ( $self, $error ) = @_;
3644     if (
3645            !$self->config->{always_catch_http_exceptions}
3646         && blessed $error
3647         && (
3648             $error->can('as_psgi')
3649             || (   $error->can('code')
3650                 && $error->code =~ m/^[1-5][0-9][0-9]$/ )
3651         )
3652       )
3653     {
3654         return 1;
3655     }
3656 }
3657
3658 =head2 $c->stack
3659
3660 Returns an arrayref of the internal execution stack (actions that are
3661 currently executing).
3662
3663 =head2 $c->stats
3664
3665 Returns the current timing statistics object. By default Catalyst uses
3666 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3667 L<< stats_class|/"$c->stats_class" >>.
3668
3669 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3670 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3671 profile explicitly, although MyApp.pm still won't profile nor output anything
3672 by itself.
3673
3674 =head2 $c->stats_class
3675
3676 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3677
3678 =head2 $c->use_stats
3679
3680 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3681
3682 Note that this is a static method, not an accessor and should be overridden
3683 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3684
3685 =cut
3686
3687 sub use_stats { 0 }
3688
3689
3690 =head2 $c->write( $data )
3691
3692 Writes $data to the output stream. When using this method directly, you
3693 will need to manually set the C<Content-Length> header to the length of
3694 your output data, if known.
3695
3696 =cut
3697
3698 sub write {
3699     my $c = shift;
3700
3701     # Finalize headers if someone manually writes output (for compat)
3702     $c->finalize_headers;
3703
3704     return $c->response->write( @_ );
3705 }
3706
3707 =head2 version
3708
3709 Returns the Catalyst version number. Mostly useful for "powered by"
3710 messages in template systems.
3711
3712 =cut
3713
3714 sub version { return $Catalyst::VERSION }
3715
3716 =head1 CONFIGURATION
3717
3718 There are a number of 'base' config variables which can be set:
3719
3720 =over
3721
3722 =item *
3723
3724 C<always_catch_http_exceptions> - As of version 5.90060 Catalyst
3725 rethrows errors conforming to the interface described by
3726 L<Plack::Middleware::HTTPExceptions> and lets the middleware deal with it.
3727 Set true to get the deprecated behaviour and have Catalyst catch HTTP exceptions.
3728
3729 =item *
3730
3731 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3732
3733 =item *
3734
3735 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3736
3737 =item *
3738
3739 C<disable_component_resolution_regex_fallback> - Turns
3740 off the deprecated component resolution functionality so
3741 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3742 are called then regex search will not be attempted on string values and
3743 instead C<undef> will be returned.
3744
3745 =item *
3746
3747 C<home> - The application home directory. In an uninstalled application,
3748 this is the top level application directory. In an installed application,
3749 this will be the directory containing C<< MyApp.pm >>.
3750
3751 =item *
3752
3753 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3754
3755 =item *
3756
3757 C<name> - The name of the application in debug messages and the debug and
3758 welcome screens
3759
3760 =item *
3761
3762 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3763 until it is accessed. This allows you to (for example) check authentication (and reject
3764 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3765
3766 =item *
3767
3768 C<root> - The root directory for templates. Usually this is just a
3769 subdirectory of the home directory, but you can set it to change the
3770 templates to a different directory.
3771
3772 =item *
3773
3774 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3775 namespaces from which components will be loaded (and constructed and stored in
3776 C<< $c->components >>).
3777
3778 =item *
3779
3780 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3781 to be shown in hit debug tables in the test server.
3782
3783 =item *
3784
3785 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3786 variable should be used for determining the request path.
3787
3788 Most web server environments pass the requested path to the application using environment variables,
3789 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3790 exposed as C<< $c->request->base >>) and the request path below that base.
3791
3792 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3793 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3794
3795 =over
3796
3797 =item use_request_uri_for_path => 0
3798
3799 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3800 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3801 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3802 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3803
3804 However this method has the major disadvantage that it is impossible to correctly decode some elements
3805 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3806 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3807 can't distinguish / vs %2F in paths (in addition to other encoded values).
3808
3809 =item use_request_uri_for_path => 1
3810
3811 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3812 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3813 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3814
3815 Given that this method of path resolution is provably more correct, it is recommended that you use
3816 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3817 aware of the implications of not being able to handle encoded URI paths correctly.
3818
3819 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3820 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3821 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3822 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3823 C<< $c->request->base >> will be incorrect.
3824
3825 =back
3826
3827 =item *
3828
3829 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3830
3831 =item *
3832
3833 C<using_frontend_proxy_path> - Enabled L<Plack::Middleware::ReverseProxyPath> on your application (if
3834 installed, otherwise log an error).  This is useful if your application is not running on the
3835 'root' (or /) of your host server.  B<NOTE> if you use this feature you should add the required
3836 middleware to your project dependency list since its not automatically a dependency of L<Catalyst>.
3837 This has been done since not all people need this feature and we wish to restrict the growth of
3838 L<Catalyst> dependencies.
3839
3840 =item *
3841
3842 C<encoding> - See L</ENCODING>
3843
3844 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
3845 value to undef.
3846
3847 =item *
3848
3849 C<abort_chain_on_error_fix>
3850
3851 When there is an error in an action chain, the default behavior is to continue
3852 processing the remaining actions and then catch the error upon chain end.  This
3853 can lead to running actions when the application is in an unexpected state.  If
3854 you have this issue, setting this config value to true will promptly exit a
3855 chain when there is an error raised in any action (thus terminating the chain
3856 early.)
3857
3858 use like:
3859
3860     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3861
3862 In the future this might become the default behavior.
3863
3864 =item *
3865
3866 C<use_hash_multivalue_in_request>
3867
3868 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3869 and C<parameters> return a hashref where values might be scalar or an arrayref
3870 depending on the incoming data.  In many cases this can be undesirable as it
3871 leads one to writing defensive code like the following:
3872
3873     my ($val) = ref($c->req->parameters->{a}) ?
3874       @{$c->req->parameters->{a}} :
3875         $c->req->parameters->{a};
3876
3877 Setting this configuration item to true will make L<Catalyst> populate the
3878 attributes underlying these methods with an instance of L<Hash::MultiValue>
3879 which is used by L<Plack::Request> and others to solve this very issue.  You
3880 may prefer this behavior to the default, if so enable this option (be warned
3881 if you enable it in a legacy application we are not sure if it is completely
3882 backwardly compatible).
3883
3884 =item *
3885
3886 C<skip_complex_post_part_handling>
3887
3888 When creating body parameters from a POST, if we run into a multpart POST
3889 that does not contain uploads, but instead contains inlined complex data
3890 (very uncommon) we cannot reliably convert that into field => value pairs.  So
3891 instead we create an instance of L<Catalyst::Request::PartData>.  If this causes
3892 issue for you, you can disable this by setting C<skip_complex_post_part_handling>
3893 to true (default is false).  
3894
3895 =item *
3896
3897 C<skip_body_param_unicode_decoding>
3898
3899 Generally we decode incoming POST params based on your declared encoding (the
3900 default for this is to decode UTF-8).  If this is causing you trouble and you
3901 do not wish to turn all encoding support off (with the C<encoding> configuration
3902 parameter) you may disable this step atomically by setting this configuration
3903 parameter to true.
3904
3905 =item *
3906
3907 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3908
3909 =item *
3910
3911 C<data_handlers> - See L<DATA HANDLERS>.
3912
3913 =back
3914
3915 =head1 EXCEPTIONS
3916
3917 Generally when you throw an exception inside an Action (or somewhere in
3918 your stack, such as in a model that an Action is calling) that exception
3919 is caught by Catalyst and unless you either catch it yourself (via eval
3920 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
3921 will eventually reach L</finalize_errors> and return either the debugging
3922 error stack page, or the default error page.  However, if your exception
3923 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
3924 instead rethrow it so that it can be handled by that middleware (which
3925 is part of the default middleware).  For example this would allow
3926
3927     use HTTP::Throwable::Factory 'http_throw';
3928
3929     sub throws_exception :Local {
3930       my ($self, $c) = @_;
3931
3932       http_throw(SeeOther => { location =>
3933         $c->uri_for($self->action_for('redirect')) });
3934
3935     }
3936
3937 =head1 INTERNAL ACTIONS
3938
3939 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3940 C<_ACTION>, and C<_END>. These are by default not shown in the private
3941 action table, but you can make them visible with a config parameter.
3942
3943     MyApp->config(show_internal_actions => 1);
3944
3945 =head1 ON-DEMAND PARSER
3946
3947 The request body is usually parsed at the beginning of a request,
3948 but if you want to handle input yourself, you can enable on-demand
3949 parsing with a config parameter.
3950
3951     MyApp->config(parse_on_demand => 1);
3952
3953 =head1 PROXY SUPPORT
3954
3955 Many production servers operate using the common double-server approach,
3956 with a lightweight frontend web server passing requests to a larger
3957 backend server. An application running on the backend server must deal
3958 with two problems: the remote user always appears to be C<127.0.0.1> and
3959 the server's hostname will appear to be C<localhost> regardless of the
3960 virtual host that the user connected through.
3961
3962 Catalyst will automatically detect this situation when you are running
3963 the frontend and backend servers on the same machine. The following
3964 changes are made to the request.
3965
3966     $c->req->address is set to the user's real IP address, as read from
3967     the HTTP X-Forwarded-For header.
3968
3969     The host value for $c->req->base and $c->req->uri is set to the real
3970     host, as read from the HTTP X-Forwarded-Host header.
3971
3972 Additionally, you may be running your backend application on an insecure
3973 connection (port 80) while your frontend proxy is running under SSL.  If there
3974 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3975 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3976 be created properly.
3977
3978 In the case of passing in:
3979
3980     X-Forwarded-Port: 443
3981
3982 All calls to C<uri_for> will result in an https link, as is expected.
3983
3984 Obviously, your web server must support these headers for this to work.
3985
3986 In a more complex server farm environment where you may have your
3987 frontend proxy server(s) on different machines, you will need to set a
3988 configuration option to tell Catalyst to read the proxied data from the
3989 headers.
3990
3991     MyApp->config(using_frontend_proxy => 1);
3992
3993 If you do not wish to use the proxy support at all, you may set:
3994
3995     MyApp->config(ignore_frontend_proxy => 0);
3996
3997 =head2 Note about psgi files
3998
3999 Note that if you supply your own .psgi file, calling
4000 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
4001
4002 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
4003 in your psgi, for example:
4004
4005     builder {
4006         enable "Plack::Middleware::ReverseProxy";
4007         MyApp->psgi_app
4008     };
4009
4010 This will unconditionally add the ReverseProxy support, or you need to call
4011 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
4012 apply the support depending upon your config).
4013
4014 See L<Catalyst::PSGI> for more information.
4015
4016 =head1 THREAD SAFETY
4017
4018 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
4019 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
4020 believe the Catalyst core to be thread-safe.
4021
4022 If you plan to operate in a threaded environment, remember that all other
4023 modules you are using must also be thread-safe. Some modules, most notably
4024 L<DBD::SQLite>, are not thread-safe.
4025
4026 =head1 DATA HANDLERS
4027
4028 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
4029 form parameters and URL search query fields.  However it has become common
4030 for various alternative content types to be PUT or POSTed to your controllers
4031 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
4032 XML and other content types when communicating with an application server.  In
4033 order to better support this use case, L<Catalyst> defines a global configuration
4034 option, C<data_handlers>, which lets you associate a content type with a coderef
4035 that parses that content type into something Perl can readily access.
4036
4037     package MyApp::Web;
4038  
4039     use Catalyst;
4040     use JSON::Maybe;
4041  
4042     __PACKAGE__->config(
4043       data_handlers => {
4044         'application/json' => sub { local $/; decode_json $_->getline },
4045       },
4046       ## Any other configuration.
4047     );
4048  
4049     __PACKAGE__->setup;
4050
4051 By default L<Catalyst> comes with a generic JSON data handler similar to the
4052 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
4053 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
4054 it installed (if you want the faster XS parser, add it to you project Makefile.PL
4055 or dist.ini, cpanfile, etc.)
4056
4057 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
4058 (matched against the incoming request type using a regexp such as to be case
4059 insensitive) and whose values are coderefs that receive a localized version of
4060 C<$_> which is a filehandle object pointing to received body.
4061
4062 This feature is considered an early access release and we reserve the right
4063 to alter the interface in order to provide a performant and secure solution to
4064 alternative request body content.  Your reports welcomed!
4065
4066 =head1 PSGI MIDDLEWARE
4067
4068 You can define middleware, defined as L<Plack::Middleware> or a compatible
4069 interface in configuration.  Your middleware definitions are in the form of an
4070 arrayref under the configuration key C<psgi_middleware>.  Here's an example
4071 with details to follow:
4072
4073     package MyApp::Web;
4074  
4075     use Catalyst;
4076     use Plack::Middleware::StackTrace;
4077  
4078     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4079  
4080     __PACKAGE__->config(
4081       'psgi_middleware', [
4082         'Debug',
4083         '+MyApp::Custom',
4084         $stacktrace_middleware,
4085         'Session' => {store => 'File'},
4086         sub {
4087           my $app = shift;
4088           return sub {
4089             my $env = shift;
4090             $env->{myapp.customkey} = 'helloworld';
4091             $app->($env);
4092           },
4093         },
4094       ],
4095     );
4096  
4097     __PACKAGE__->setup;
4098
4099 So the general form is:
4100
4101     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
4102
4103 Where C<@middleware> is one or more of the following, applied in the REVERSE of
4104 the order listed (to make it function similarly to L<Plack::Builder>:
4105
4106 Alternatively, you may also define middleware by calling the L</setup_middleware>
4107 package method:
4108
4109     package MyApp::Web;
4110
4111     use Catalyst;
4112
4113     __PACKAGE__->setup_middleware( \@middleware_definitions);
4114     __PACKAGE__->setup;
4115
4116 In the case where you do both (use 'setup_middleware' and configuration) the
4117 package call to setup_middleware will be applied earlier (in other words its
4118 middleware will wrap closer to the application).  Keep this in mind since in
4119 some cases the order of middleware is important.
4120
4121 The two approaches are not exclusive.
4122  
4123 =over 4
4124  
4125 =item Middleware Object
4126  
4127 An already initialized object that conforms to the L<Plack::Middleware>
4128 specification:
4129  
4130     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4131  
4132     __PACKAGE__->config(
4133       'psgi_middleware', [
4134         $stacktrace_middleware,
4135       ]);
4136  
4137  
4138 =item coderef
4139  
4140 A coderef that is an inlined middleware:
4141  
4142     __PACKAGE__->config(
4143       'psgi_middleware', [
4144         sub {
4145           my $app = shift;
4146           return sub {
4147             my $env = shift;
4148             if($env->{PATH_INFO} =~m/forced/) {
4149               Plack::App::File
4150                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
4151                 ->call($env);
4152             } else {
4153               return $app->($env);
4154             }
4155          },
4156       },
4157     ]);
4158  
4159  
4160  
4161 =item a scalar
4162  
4163 We assume the scalar refers to a namespace after normalizing it using the
4164 following rules:
4165
4166 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
4167 is assumed to be 'as is', and we just install and use the middleware.
4168
4169 (2) If the scalar begins with "Plack::Middleware" or your application namespace
4170 (the package name of your Catalyst application subclass), we also assume then
4171 that it is a full namespace, and use it.
4172
4173 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
4174 resolve it first by looking for it under your application namespace (for example
4175 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
4176 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
4177 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
4178 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
4179 namespace first to let you 'override' common L<Plack::Middleware> locally, should
4180 you find that a good idea.
4181
4182 Examples:
4183
4184     package MyApp::Web;
4185
4186     __PACKAGE__->config(
4187       'psgi_middleware', [
4188         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
4189         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
4190         '+MyApp::Custom',  ## MyApp::Custom->wrap
4191       ],
4192     );
4193  
4194 =item a scalar followed by a hashref
4195  
4196 Just like the previous, except the following C<HashRef> is used as arguments
4197 to initialize the middleware object.
4198  
4199     __PACKAGE__->config(
4200       'psgi_middleware', [
4201          'Session' => {store => 'File'},
4202     ]);
4203
4204 =back
4205
4206 Please see L<PSGI> for more on middleware.
4207
4208 =head1 ENCODING
4209
4210 Starting in L<Catalyst> version 5.90080 encoding is automatically enabled
4211 and set to encode all body responses to UTF8 when possible and applicable.
4212 Following is documentation on this process.  If you are using an older
4213 version of L<Catalyst> you should review documentation for that version since
4214 a lot has changed.
4215
4216 By default encoding is now 'UTF-8'.  You may turn it off by setting
4217 the encoding configuration to undef.
4218
4219     MyApp->config(encoding => undef);
4220
4221 This is recommended for temporary backwards compatibility only.
4222
4223 Encoding is automatically applied when the content-type is set to
4224 a type that can be encoded.  Currently we encode when the content type
4225 matches the following regular expression:
4226
4227     $content_type =~ /^text|xml$|javascript$/
4228
4229 Encoding is set on the application, but it is copied to the context object
4230 so that you can override it on a request basis.
4231
4232 Be default we don't automatically encode 'application/json' since the most
4233 common approaches to generating this type of response (Either via L<Catalyst::View::JSON>
4234 or L<Catalyst::Action::REST>) will do so already and we want to avoid double
4235 encoding issues.
4236
4237 If you are producing JSON response in an unconventional manner (such
4238 as via a template or manual strings) you should perform the UTF8 encoding
4239 manually as well such as to conform to the JSON specification.
4240
4241 NOTE: We also examine the value of $c->response->content_encoding.  If
4242 you set this (like for example 'gzip', and manually gzipping the body)
4243 we assume that you have done all the necessary encoding yourself, since
4244 we cannot encode the gzipped contents.  If you use a plugin like
4245 L<Catalyst::Plugin::Compress> you need to update to a modern version in order
4246 to have this function correctly  with the new UTF8 encoding code, or you
4247 can use L<Plack::Middleware::Deflater> or (probably best) do your compression on
4248 a front end proxy.
4249
4250 =head2 Methods
4251
4252 =over 4
4253
4254 =item encoding
4255
4256 Returns an instance of an C<Encode> encoding
4257
4258     print $c->encoding->name
4259
4260 =item handle_unicode_encoding_exception ($exception_context)
4261
4262 Method called when decoding process for a request fails.
4263
4264 An C<$exception_context> hashref is provided to allow you to override the
4265 behaviour of your application when given data with incorrect encodings.
4266
4267 The default method throws exceptions in the case of invalid request parameters
4268 (resulting in a 500 error), but ignores errors in upload filenames.
4269
4270 The keys passed in the C<$exception_context> hash are:
4271
4272 =over
4273
4274 =item param_value
4275
4276 The value which was not able to be decoded.
4277
4278 =item error_msg
4279
4280 The exception received from L<Encode>.
4281
4282 =item encoding_step
4283
4284 What type of data was being decoded. Valid values are (currently)
4285 C<params> - for request parameters / arguments / captures
4286 and C<uploads> - for request upload filenames.
4287
4288 =back
4289
4290 =back
4291
4292 =head1 SUPPORT
4293
4294 IRC:
4295
4296     Join #catalyst on irc.perl.org.
4297
4298 Mailing Lists:
4299
4300     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4301     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4302
4303 Web:
4304
4305     http://catalyst.perl.org
4306
4307 Wiki:
4308
4309     http://dev.catalyst.perl.org
4310
4311 =head1 SEE ALSO
4312
4313 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4314
4315 =head2 L<Catalyst::Manual> - The Catalyst Manual
4316
4317 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4318
4319 =head2 L<Catalyst::Engine> - Core engine
4320
4321 =head2 L<Catalyst::Log> - Log class.
4322
4323 =head2 L<Catalyst::Request> - Request object
4324
4325 =head2 L<Catalyst::Response> - Response object
4326
4327 =head2 L<Catalyst::Test> - The test suite.
4328
4329 =head1 PROJECT FOUNDER
4330
4331 sri: Sebastian Riedel <sri@cpan.org>
4332
4333 =head1 CONTRIBUTORS
4334
4335 abw: Andy Wardley
4336
4337 acme: Leon Brocard <leon@astray.com>
4338
4339 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4340
4341 andrewalker: André Walker <andre@cpan.org>
4342
4343 Andrew Bramble
4344
4345 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4346
4347 Andrew Ruthven
4348
4349 andyg: Andy Grundman <andy@hybridized.org>
4350
4351 audreyt: Audrey Tang
4352
4353 bricas: Brian Cassidy <bricas@cpan.org>
4354
4355 Caelum: Rafael Kitover <rkitover@io.com>
4356
4357 chansen: Christian Hansen
4358
4359 chicks: Christopher Hicks
4360
4361 Chisel Wright C<pause@herlpacker.co.uk>
4362
4363 Danijel Milicevic C<me@danijel.de>
4364
4365 davewood: David Schmidt <davewood@cpan.org>
4366
4367 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4368
4369 David Naughton, C<naughton@umn.edu>
4370
4371 David E. Wheeler
4372
4373 dhoss: Devin Austin <dhoss@cpan.org>
4374
4375 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4376
4377 Drew Taylor
4378
4379 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4380
4381 esskar: Sascha Kiefer
4382
4383 fireartist: Carl Franks <cfranks@cpan.org>
4384
4385 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4386
4387 gabb: Danijel Milicevic
4388
4389 Gary Ashton Jones
4390
4391 Gavin Henry C<ghenry@perl.me.uk>
4392
4393 Geoff Richards
4394
4395 groditi: Guillermo Roditi <groditi@gmail.com>
4396
4397 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4398
4399 ilmari: Dagfinn Ilmari MannsÃ¥ker <ilmari@ilmari.org>
4400
4401 jcamacho: Juan Camacho
4402
4403 jester: Jesse Sheidlower C<jester@panix.com>
4404
4405 jhannah: Jay Hannah <jay@jays.net>
4406
4407 Jody Belka
4408
4409 Johan Lindstrom
4410
4411 jon: Jon Schutz <jjschutz@cpan.org>
4412
4413 Jonathan Rockway C<< <jrockway@cpan.org> >>
4414
4415 Kieren Diment C<kd@totaldatasolution.com>
4416
4417 konobi: Scott McWhirter <konobi@cpan.org>
4418
4419 marcus: Marcus Ramberg <mramberg@cpan.org>
4420
4421 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4422
4423 mgrimes: Mark Grimes <mgrimes@cpan.org>
4424
4425 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4426
4427 mugwump: Sam Vilain
4428
4429 naughton: David Naughton
4430
4431 ningu: David Kamholz <dkamholz@cpan.org>
4432
4433 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4434
4435 numa: Dan Sully <daniel@cpan.org>
4436
4437 obra: Jesse Vincent
4438
4439 Octavian Rasnita
4440
4441 omega: Andreas Marienborg
4442
4443 Oleg Kostyuk <cub.uanic@gmail.com>
4444
4445 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4446
4447 rafl: Florian Ragwitz <rafl@debian.org>
4448
4449 random: Roland Lammel <lammel@cpan.org>
4450
4451 Robert Sedlacek C<< <rs@474.at> >>
4452
4453 SpiceMan: Marcel Montes
4454
4455 sky: Arthur Bergman
4456
4457 szbalint: Balint Szilakszi <szbalint@cpan.org>
4458
4459 t0m: Tomas Doran <bobtfish@bobtfish.net>
4460
4461 Ulf Edvinsson
4462
4463 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4464
4465 Viljo Marrandi C<vilts@yahoo.com>
4466
4467 Will Hawes C<info@whawes.co.uk>
4468
4469 willert: Sebastian Willert <willert@cpan.org>
4470
4471 wreis: Wallace Reis <wreis@cpan.org>
4472
4473 Yuval Kogman, C<nothingmuch@woobling.org>
4474
4475 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4476
4477 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4478
4479 Upasana <me@upasana.me>
4480
4481 John Napiorkowski (jnap) <jjnapiork@cpan.org>
4482
4483 =head1 COPYRIGHT
4484
4485 Copyright (c) 2005-2015, the above named PROJECT FOUNDER and CONTRIBUTORS.
4486
4487 =head1 LICENSE
4488
4489 This library is free software. You can redistribute it and/or modify it under
4490 the same terms as Perl itself.
4491
4492 =cut
4493
4494 no Moose;
4495
4496 __PACKAGE__->meta->make_immutable;
4497
4498 1;