lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54
  55 BEGIN { require 5.008003; }
  56
  57 has stack => (is => 'ro', default => sub { [] });
  58 has state => (is => 'rw', default => 0);
  59 has stats => (is => 'rw');
  60 has action => (is => 'rw');
  61 has counter => (is => 'rw', default => sub { {} });
  62 has request => (
  63     is => 'rw',
  64     default => sub {
  65         my $self = shift;
  66         $self->request_class->new($self->_build_request_constructor_args);
  67     },
  68     lazy => 1,
  69 );
  70 sub _build_request_constructor_args {
  71     my $self = shift;
  72     my %p = ( _log => $self->log );
  73     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  74     $p{data_handlers} = {$self->registered_data_handlers};
  75     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  76       if $self->config->{use_hash_multivalue_in_request};
  77     \%p;
  78 }
  79
  80 has response => (
  81     is => 'rw',
  82     default => sub {
  83         my $self = shift;
  84         $self->response_class->new($self->_build_response_constructor_args);
  85     },
  86     lazy => 1,
  87 );
  88 sub _build_response_constructor_args {
  89     return +{
  90       _log => $_[0]->log,
  91       encoding => $_[0]->encoding,
  92     };
  93 }
  94
  95 has namespace => (is => 'rw');
  96
  97 sub depth { scalar @{ shift->stack || [] }; }
  98 sub comp { shift->component(@_) }
  99
 100 sub req {
 101     my $self = shift; return $self->request(@_);
 102 }
 103 sub res {
 104     my $self = shift; return $self->response(@_);
 105 }
 106
 107 # For backwards compatibility
 108 sub finalize_output { shift->finalize_body(@_) };
 109
 110 # For statistics
 111 our $COUNT     = 1;
 112 our $START     = time;
 113 our $RECURSION = 1000;
 114 our $DETACH    = Catalyst::Exception::Detach->new;
 115 our $GO        = Catalyst::Exception::Go->new;
 116
 117 #I imagine that very few of these really need to be class variables. if any.
 118 #maybe we should just make them attributes with a default?
 119 __PACKAGE__->mk_classdata($_)
 120   for qw/components arguments dispatcher engine log dispatcher_class
 121   engine_loader context_class request_class response_class stats_class
 122   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 123   _data_handlers _encoding _encode_check/;
 124
 125 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 126 __PACKAGE__->request_class('Catalyst::Request');
 127 __PACKAGE__->response_class('Catalyst::Response');
 128 __PACKAGE__->stats_class('Catalyst::Stats');
 129 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 130
 131 # Remember to update this in Catalyst::Runtime as well!
 132 our $VERSION = '5.90080_001';
 133 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 134
 135 sub import {
 136     my ( $class, @arguments ) = @_;
 137
 138     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 139     # callers @ISA.
 140     return unless $class eq 'Catalyst';
 141
 142     my $caller = caller();
 143     return if $caller eq 'main';
 144
 145     my $meta = Moose::Meta::Class->initialize($caller);
 146     unless ( $caller->isa('Catalyst') ) {
 147         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 148         $meta->superclasses(@superclasses);
 149     }
 150     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 151     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 152
 153     unless( $meta->has_method('meta') ){
 154         if ($Moose::VERSION >= 1.15) {
 155             $meta->_add_meta_method('meta');
 156         }
 157         else {
 158             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 159         }
 160     }
 161
 162     $caller->arguments( [@arguments] );
 163     $caller->setup_home;
 164 }
 165
 166 sub _application { $_[0] }
 167
 168 =encoding UTF-8
 169
 170 =head1 NAME
 171
 172 Catalyst - The Elegant MVC Web Application Framework
 173
 174 =head1 SYNOPSIS
 175
 176 See the L<Catalyst::Manual> distribution for comprehensive
 177 documentation and tutorials.
 178
 179     # Install Catalyst::Devel for helpers and other development tools
 180     # use the helper to create a new application
 181     catalyst.pl MyApp
 182
 183     # add models, views, controllers
 184     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 185     script/myapp_create.pl view MyTemplate TT
 186     script/myapp_create.pl controller Search
 187
 188     # built in testserver -- use -r to restart automatically on changes
 189     # --help to see all available options
 190     script/myapp_server.pl
 191
 192     # command line testing interface
 193     script/myapp_test.pl /yada
 194
 195     ### in lib/MyApp.pm
 196     use Catalyst qw/-Debug/; # include plugins here as well
 197
 198     ### In lib/MyApp/Controller/Root.pm (autocreated)
 199     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 200         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 201         $c->stash->{template} = 'foo.tt'; # set the template
 202         # lookup something from db -- stash vars are passed to TT
 203         $c->stash->{data} =
 204           $c->model('Database::Foo')->search( { country => $args[0] } );
 205         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 206             $c->forward( 'bar' ); # process another action
 207             # do something else after forward returns
 208         }
 209     }
 210
 211     # The foo.tt TT template can use the stash data from the database
 212     [% WHILE (item = data.next) %]
 213         [% item.foo %]
 214     [% END %]
 215
 216     # called for /bar/of/soap, /bar/of/soap/10, etc.
 217     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 218
 219     # called after all actions are finished
 220     sub end : Action {
 221         my ( $self, $c ) = @_;
 222         if ( scalar @{ $c->error } ) { ... } # handle errors
 223         return if $c->res->body; # already have a response
 224         $c->forward( 'MyApp::View::TT' ); # render template
 225     }
 226
 227 See L<Catalyst::Manual::Intro> for additional information.
 228
 229 =head1 DESCRIPTION
 230
 231 Catalyst is a modern framework for making web applications without the
 232 pain usually associated with this process. This document is a reference
 233 to the main Catalyst application. If you are a new user, we suggest you
 234 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 235
 236 See L<Catalyst::Manual> for more documentation.
 237
 238 Catalyst plugins can be loaded by naming them as arguments to the "use
 239 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 240 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 241 C<My::Module>.
 242
 243     use Catalyst qw/My::Module/;
 244
 245 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 246 fully qualify the name by using a unary plus:
 247
 248     use Catalyst qw/
 249         My::Module
 250         +Fully::Qualified::Plugin::Name
 251     /;
 252
 253 Special flags like C<-Debug> can also be specified as
 254 arguments when Catalyst is loaded:
 255
 256     use Catalyst qw/-Debug My::Module/;
 257
 258 The position of plugins and flags in the chain is important, because
 259 they are loaded in the order in which they appear.
 260
 261 The following flags are supported:
 262
 263 =head2 -Debug
 264
 265 Enables debug output. You can also force this setting from the system
 266 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 267 settings override the application, with <MYAPP>_DEBUG having the highest
 268 priority.
 269
 270 This sets the log level to 'debug' and enables full debug output on the
 271 error screen. If you only want the latter, see L<< $c->debug >>.
 272
 273 =head2 -Home
 274
 275 Forces Catalyst to use a specific home directory, e.g.:
 276
 277     use Catalyst qw[-Home=/usr/mst];
 278
 279 This can also be done in the shell environment by setting either the
 280 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 281 is replaced with the uppercased name of your application, any "::" in
 282 the name will be replaced with underscores, e.g. MyApp::Web should use
 283 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 284
 285 If none of these are set, Catalyst will attempt to automatically detect the
 286 home directory. If you are working in a development environment, Catalyst
 287 will try and find the directory containing either Makefile.PL, Build.PL,
 288 dist.ini, or cpanfile. If the application has been installed into the system
 289 (i.e. you have done C<make install>), then Catalyst will use the path to your
 290 application module, without the .pm extension (e.g., /foo/MyApp if your
 291 application was installed at /foo/MyApp.pm)
 292
 293 =head2 -Log
 294
 295     use Catalyst '-Log=warn,fatal,error';
 296
 297 Specifies a comma-delimited list of log levels.
 298
 299 =head2 -Stats
 300
 301 Enables statistics collection and reporting.
 302
 303    use Catalyst qw/-Stats=1/;
 304
 305 You can also force this setting from the system environment with CATALYST_STATS
 306 or <MYAPP>_STATS. The environment settings override the application, with
 307 <MYAPP>_STATS having the highest priority.
 308
 309 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 310
 311 =head1 METHODS
 312
 313 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 314
 315 =head2 $c->action
 316
 317 Returns a L<Catalyst::Action> object for the current action, which
 318 stringifies to the action name. See L<Catalyst::Action>.
 319
 320 =head2 $c->namespace
 321
 322 Returns the namespace of the current action, i.e., the URI prefix
 323 corresponding to the controller of the current action. For example:
 324
 325     # in Controller::Foo::Bar
 326     $c->namespace; # returns 'foo/bar';
 327
 328 =head2 $c->request
 329
 330 =head2 $c->req
 331
 332 Returns the current L<Catalyst::Request> object, giving access to
 333 information about the current client request (including parameters,
 334 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 335
 336 =head2 REQUEST FLOW HANDLING
 337
 338 =head2 $c->forward( $action [, \@arguments ] )
 339
 340 =head2 $c->forward( $class, $method, [, \@arguments ] )
 341
 342 This is one way of calling another action (method) in the same or
 343 a different controller. You can also use C<< $self->my_method($c, @args) >>
 344 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 345 in a different controller.
 346 The main difference is that 'forward' uses some of the Catalyst request
 347 cycle overhead, including debugging, which may be useful to you. On the
 348 other hand, there are some complications to using 'forward', restrictions
 349 on values returned from 'forward', and it may not handle errors as you prefer.
 350 Whether you use 'forward' or not is up to you; it is not considered superior to
 351 the other ways to call a method.
 352
 353 'forward' calls  another action, by its private name. If you give a
 354 class name but no method, C<process()> is called. You may also optionally
 355 pass arguments in an arrayref. The action will receive the arguments in
 356 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 357 C<< $c->req->args >> will be restored to the previous values.
 358
 359 Any data C<return>ed from the action forwarded to, will be returned by the
 360 call to forward.
 361
 362     my $foodata = $c->forward('/foo');
 363     $c->forward('index');
 364     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 365     $c->forward('View::TT');
 366
 367 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 368 an C<< eval { } >> around the call (actually
 369 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 370 exceptions thrown by the called action non-fatal and pushing them onto
 371 $c->error instead. If you want C<die> to propagate you need to do something
 372 like:
 373
 374     $c->forward('foo');
 375     die join "\n", @{ $c->error } if @{ $c->error };
 376
 377 Or make sure to always return true values from your actions and write
 378 your code like this:
 379
 380     $c->forward('foo') || return;
 381
 382 Another note is that C<< $c->forward >> always returns a scalar because it
 383 actually returns $c->state which operates in a scalar context.
 384 Thus, something like:
 385
 386     return @array;
 387
 388 in an action that is forwarded to is going to return a scalar,
 389 i.e. how many items are in that array, which is probably not what you want.
 390 If you need to return an array then return a reference to it,
 391 or stash it like so:
 392
 393     $c->stash->{array} = \@array;
 394
 395 and access it from the stash.
 396
 397 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 398
 399 =cut
 400
 401 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 402
 403 =head2 $c->detach( $action [, \@arguments ] )
 404
 405 =head2 $c->detach( $class, $method, [, \@arguments ] )
 406
 407 =head2 $c->detach()
 408
 409 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 410 doesn't return to the previous action when processing is finished.
 411
 412 When called with no arguments it escapes the processing chain entirely.
 413
 414 =cut
 415
 416 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 417
 418 =head2 $c->visit( $action [, \@arguments ] )
 419
 420 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 421
 422 =head2 $c->visit( $class, $method, [, \@arguments ] )
 423
 424 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 425
 426 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 427 but does a full dispatch, instead of just calling the new C<$action> /
 428 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 429 you go to are called, just like a new request.
 430
 431 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 432 This means, for example, that C<< $c->action >> methods such as
 433 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 434 L<reverse|Catalyst::Action/reverse> return information for the visited action
 435 when they are invoked within the visited action.  This is different from the
 436 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 437 continues to use the $c->action object from the caller action even when
 438 invoked from the called action.
 439
 440 C<< $c->stash >> is kept unchanged.
 441
 442 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 443 allows you to "wrap" another action, just as it would have been called by
 444 dispatching from a URL, while the analogous
 445 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 446 transfer control to another action as if it had been reached directly from a URL.
 447
 448 =cut
 449
 450 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 451
 452 =head2 $c->go( $action [, \@arguments ] )
 453
 454 =head2 $c->go( $action [, \@captures, \@arguments ] )
 455
 456 =head2 $c->go( $class, $method, [, \@arguments ] )
 457
 458 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 459
 460 The relationship between C<go> and
 461 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 462 the relationship between
 463 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 464 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 465 C<< $c->go >> will perform a full dispatch on the specified action or method,
 466 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 467 C<go> escapes the processing of the current request chain on completion, and
 468 does not return to its caller.
 469
 470 @arguments are arguments to the final destination of $action. @captures are
 471 arguments to the intermediate steps, if any, on the way to the final sub of
 472 $action.
 473
 474 =cut
 475
 476 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 477
 478 =head2 $c->response
 479
 480 =head2 $c->res
 481
 482 Returns the current L<Catalyst::Response> object, see there for details.
 483
 484 =head2 $c->stash
 485
 486 Returns a hashref to the stash, which may be used to store data and pass
 487 it between components during a request. You can also set hash keys by
 488 passing arguments. The stash is automatically sent to the view. The
 489 stash is cleared at the end of a request; it cannot be used for
 490 persistent storage (for this you must use a session; see
 491 L<Catalyst::Plugin::Session> for a complete system integrated with
 492 Catalyst).
 493
 494     $c->stash->{foo} = $bar;
 495     $c->stash( { moose => 'majestic', qux => 0 } );
 496     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 497
 498     # stash is automatically passed to the view for use in a template
 499     $c->forward( 'MyApp::View::TT' );
 500
 501 The stash hash is currently stored in the PSGI C<$env> and is managed by
 502 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 503 the stash can be accessed in sub applications mounted under your main
 504 L<Catalyst> application.  For example if you delegate the response of an
 505 action to another L<Catalyst> application, that sub application will have
 506 access to all the stash keys of the main one, and if can of course add
 507 more keys of its own.  However those new keys will not 'bubble' back up
 508 to the main application.
 509
 510 For more information the best thing to do is to review the test case:
 511 t/middleware-stash.t in the distribution /t directory.
 512
 513 =cut
 514
 515 sub stash {
 516   my $c = shift;
 517   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 518 }
 519
 520 =head2 $c->error
 521
 522 =head2 $c->error($error, ...)
 523
 524 =head2 $c->error($arrayref)
 525
 526 Returns an arrayref containing error messages.  If Catalyst encounters an
 527 error while processing a request, it stores the error in $c->error.  This
 528 method should only be used to store fatal error messages.
 529
 530     my @error = @{ $c->error };
 531
 532 Add a new error.
 533
 534     $c->error('Something bad happened');
 535
 536 =cut
 537
 538 sub error {
 539     my $c = shift;
 540     if ( $_[0] ) {
 541         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 542         croak @$error unless ref $c;
 543         push @{ $c->{error} }, @$error;
 544     }
 545     elsif ( defined $_[0] ) { $c->{error} = undef }
 546     return $c->{error} || [];
 547 }
 548
 549
 550 =head2 $c->state
 551
 552 Contains the return value of the last executed action.
 553 Note that << $c->state >> operates in a scalar context which means that all
 554 values it returns are scalar.
 555
 556 =head2 $c->clear_errors
 557
 558 Clear errors.  You probably don't want to clear the errors unless you are
 559 implementing a custom error screen.
 560
 561 This is equivalent to running
 562
 563     $c->error(0);
 564
 565 =cut
 566
 567 sub clear_errors {
 568     my $c = shift;
 569     $c->error(0);
 570 }
 571
 572 =head2 $c->has_errors
 573
 574 Returns true if you have errors
 575
 576 =cut
 577
 578 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 579
 580 sub _comp_search_prefixes {
 581     my $c = shift;
 582     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 583 }
 584
 585 # search components given a name and some prefixes
 586 sub _comp_names_search_prefixes {
 587     my ( $c, $name, @prefixes ) = @_;
 588     my $appclass = ref $c || $c;
 589     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 590     $filter = qr/$filter/; # Compile regex now rather than once per loop
 591
 592     # map the original component name to the sub part that we will search against
 593     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 594         grep { /$filter/ } keys %{ $c->components };
 595
 596     # undef for a name will return all
 597     return keys %eligible if !defined $name;
 598
 599     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 600     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 601
 602     return @result if @result;
 603
 604     # if we were given a regexp to search against, we're done.
 605     return if $name->$_isa('Regexp');
 606
 607     # skip regexp fallback if configured
 608     return
 609         if $appclass->config->{disable_component_resolution_regex_fallback};
 610
 611     # regexp fallback
 612     $query  = qr/$name/i;
 613     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 614
 615     # no results? try against full names
 616     if( !@result ) {
 617         @result = grep { m{$query} } keys %eligible;
 618     }
 619
 620     # don't warn if we didn't find any results, it just might not exist
 621     if( @result ) {
 622         # Disgusting hack to work out correct method name
 623         my $warn_for = lc $prefixes[0];
 624         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 625            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 626            "component resolution is unreliable and unsafe.";
 627         my $short = $result[0];
 628         # remove the component namespace prefix
 629         $short =~ s/.*?(Model|Controller|View):://;
 630         my $shortmess = Carp::shortmess('');
 631         if ($shortmess =~ m#Catalyst/Plugin#) {
 632            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 633               "plugin's config";
 634         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 635            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 636               "component's config";
 637         } else {
 638            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 639               "but if you really wanted to search, pass in a regexp as the argument " .
 640               "like so: \$c->${warn_for}(qr/${name}/)";
 641         }
 642         $c->log->warn( "${msg}$shortmess" );
 643     }
 644
 645     return @result;
 646 }
 647
 648 # Find possible names for a prefix
 649 sub _comp_names {
 650     my ( $c, @prefixes ) = @_;
 651     my $appclass = ref $c || $c;
 652
 653     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 654
 655     my @names = map { s{$filter}{}; $_; }
 656         $c->_comp_names_search_prefixes( undef, @prefixes );
 657
 658     return @names;
 659 }
 660
 661 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 662 sub _filter_component {
 663     my ( $c, $comp, @args ) = @_;
 664
 665     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 666         return $comp->ACCEPT_CONTEXT( $c, @args );
 667     }
 668
 669     return $comp;
 670 }
 671
 672 =head2 COMPONENT ACCESSORS
 673
 674 =head2 $c->controller($name)
 675
 676 Gets a L<Catalyst::Controller> instance by name.
 677
 678     $c->controller('Foo')->do_stuff;
 679
 680 If the name is omitted, will return the controller for the dispatched
 681 action.
 682
 683 If you want to search for controllers, pass in a regexp as the argument.
 684
 685     # find all controllers that start with Foo
 686     my @foo_controllers = $c->controller(qr{^Foo});
 687
 688
 689 =cut
 690
 691 sub controller {
 692     my ( $c, $name, @args ) = @_;
 693
 694     my $appclass = ref($c) || $c;
 695     if( $name ) {
 696         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 697             my $comps = $c->components;
 698             my $check = $appclass."::Controller::".$name;
 699             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 700         }
 701         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 702         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 703         return $c->_filter_component( $result[ 0 ], @args );
 704     }
 705
 706     return $c->component( $c->action->class );
 707 }
 708
 709 =head2 $c->model($name)
 710
 711 Gets a L<Catalyst::Model> instance by name.
 712
 713     $c->model('Foo')->do_stuff;
 714
 715 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 716
 717 If the name is omitted, it will look for
 718  - a model object in $c->stash->{current_model_instance}, then
 719  - a model name in $c->stash->{current_model}, then
 720  - a config setting 'default_model', or
 721  - check if there is only one model, and return it if that's the case.
 722
 723 If you want to search for models, pass in a regexp as the argument.
 724
 725     # find all models that start with Foo
 726     my @foo_models = $c->model(qr{^Foo});
 727
 728 =cut
 729
 730 sub model {
 731     my ( $c, $name, @args ) = @_;
 732     my $appclass = ref($c) || $c;
 733     if( $name ) {
 734         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 735             my $comps = $c->components;
 736             my $check = $appclass."::Model::".$name;
 737             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 738         }
 739         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 740         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 741         return $c->_filter_component( $result[ 0 ], @args );
 742     }
 743
 744     if (ref $c) {
 745         return $c->stash->{current_model_instance}
 746           if $c->stash->{current_model_instance};
 747         return $c->model( $c->stash->{current_model} )
 748           if $c->stash->{current_model};
 749     }
 750     return $c->model( $appclass->config->{default_model} )
 751       if $appclass->config->{default_model};
 752
 753     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 754
 755     if( $rest ) {
 756         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 757         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 758         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 759         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 760         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 761     }
 762
 763     return $c->_filter_component( $comp );
 764 }
 765
 766
 767 =head2 $c->view($name)
 768
 769 Gets a L<Catalyst::View> instance by name.
 770
 771     $c->view('Foo')->do_stuff;
 772
 773 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 774
 775 If the name is omitted, it will look for
 776  - a view object in $c->stash->{current_view_instance}, then
 777  - a view name in $c->stash->{current_view}, then
 778  - a config setting 'default_view', or
 779  - check if there is only one view, and return it if that's the case.
 780
 781 If you want to search for views, pass in a regexp as the argument.
 782
 783     # find all views that start with Foo
 784     my @foo_views = $c->view(qr{^Foo});
 785
 786 =cut
 787
 788 sub view {
 789     my ( $c, $name, @args ) = @_;
 790
 791     my $appclass = ref($c) || $c;
 792     if( $name ) {
 793         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 794             my $comps = $c->components;
 795             my $check = $appclass."::View::".$name;
 796             if( exists $comps->{$check} ) {
 797                 return $c->_filter_component( $comps->{$check}, @args );
 798             }
 799             else {
 800                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 801             }
 802         }
 803         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 804         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 805         return $c->_filter_component( $result[ 0 ], @args );
 806     }
 807
 808     if (ref $c) {
 809         return $c->stash->{current_view_instance}
 810           if $c->stash->{current_view_instance};
 811         return $c->view( $c->stash->{current_view} )
 812           if $c->stash->{current_view};
 813     }
 814     return $c->view( $appclass->config->{default_view} )
 815       if $appclass->config->{default_view};
 816
 817     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 818
 819     if( $rest ) {
 820         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 821         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 822         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 823         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 824         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 825     }
 826
 827     return $c->_filter_component( $comp );
 828 }
 829
 830 =head2 $c->controllers
 831
 832 Returns the available names which can be passed to $c->controller
 833
 834 =cut
 835
 836 sub controllers {
 837     my ( $c ) = @_;
 838     return $c->_comp_names(qw/Controller C/);
 839 }
 840
 841 =head2 $c->models
 842
 843 Returns the available names which can be passed to $c->model
 844
 845 =cut
 846
 847 sub models {
 848     my ( $c ) = @_;
 849     return $c->_comp_names(qw/Model M/);
 850 }
 851
 852
 853 =head2 $c->views
 854
 855 Returns the available names which can be passed to $c->view
 856
 857 =cut
 858
 859 sub views {
 860     my ( $c ) = @_;
 861     return $c->_comp_names(qw/View V/);
 862 }
 863
 864 =head2 $c->comp($name)
 865
 866 =head2 $c->component($name)
 867
 868 Gets a component object by name. This method is not recommended,
 869 unless you want to get a specific component by full
 870 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 871 should be used instead.
 872
 873 If C<$name> is a regexp, a list of components matched against the full
 874 component name will be returned.
 875
 876 If Catalyst can't find a component by name, it will fallback to regex
 877 matching by default. To disable this behaviour set
 878 disable_component_resolution_regex_fallback to a true value.
 879
 880     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 881
 882 =cut
 883
 884 sub component {
 885     my ( $c, $name, @args ) = @_;
 886
 887     if( $name ) {
 888         my $comps = $c->components;
 889
 890         if( !ref $name ) {
 891             # is it the exact name?
 892             return $c->_filter_component( $comps->{ $name }, @args )
 893                        if exists $comps->{ $name };
 894
 895             # perhaps we just omitted "MyApp"?
 896             my $composed = ( ref $c || $c ) . "::${name}";
 897             return $c->_filter_component( $comps->{ $composed }, @args )
 898                        if exists $comps->{ $composed };
 899
 900             # search all of the models, views and controllers
 901             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 902             return $c->_filter_component( $comp, @args ) if $comp;
 903         }
 904
 905         return
 906             if $c->config->{disable_component_resolution_regex_fallback};
 907
 908         # This is here so $c->comp( '::M::' ) works
 909         my $query = ref $name ? $name : qr{$name}i;
 910
 911         my @result = grep { m{$query} } keys %{ $c->components };
 912         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 913
 914         if( $result[ 0 ] ) {
 915             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 916             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 917             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 918             return $c->_filter_component( $result[ 0 ], @args );
 919         }
 920
 921         # I would expect to return an empty list here, but that breaks back-compat
 922     }
 923
 924     # fallback
 925     return sort keys %{ $c->components };
 926 }
 927
 928 =head2 CLASS DATA AND HELPER CLASSES
 929
 930 =head2 $c->config
 931
 932 Returns or takes a hashref containing the application's configuration.
 933
 934     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 935
 936 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 937 like C<myapp.conf> in your applications home directory. See
 938 L<Catalyst::Plugin::ConfigLoader>.
 939
 940 =head3 Cascading configuration
 941
 942 The config method is present on all Catalyst components, and configuration
 943 will be merged when an application is started. Configuration loaded with
 944 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 945 followed by configuration in your top level C<MyApp> class. These two
 946 configurations are merged, and then configuration data whose hash key matches a
 947 component name is merged with configuration for that component.
 948
 949 The configuration for a component is then passed to the C<new> method when a
 950 component is constructed.
 951
 952 For example:
 953
 954     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 955     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 956
 957 will mean that C<MyApp::Model::Foo> receives the following data when
 958 constructed:
 959
 960     MyApp::Model::Foo->new({
 961         bar => 'baz',
 962         quux => 'frob',
 963         overrides => 'me',
 964     });
 965
 966 It's common practice to use a Moose attribute
 967 on the receiving component to access the config value.
 968
 969     package MyApp::Model::Foo;
 970
 971     use Moose;
 972
 973     # this attr will receive 'baz' at construction time
 974     has 'bar' => (
 975         is  => 'rw',
 976         isa => 'Str',
 977     );
 978
 979 You can then get the value 'baz' by calling $c->model('Foo')->bar
 980 (or $self->bar inside code in the model).
 981
 982 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 983 as a way of reading config within your code, as this B<will not> give you the
 984 correctly merged config back. You B<MUST> take the config values supplied to
 985 the constructor and use those instead.
 986
 987 =cut
 988
 989 around config => sub {
 990     my $orig = shift;
 991     my $c = shift;
 992
 993     croak('Setting config after setup has been run is not allowed.')
 994         if ( @_ and $c->setup_finished );
 995
 996     $c->$orig(@_);
 997 };
 998
 999 =head2 $c->log
1000
1001 Returns the logging object instance. Unless it is already set, Catalyst
1002 sets this up with a L<Catalyst::Log> object. To use your own log class,
1003 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1004 C<< __PACKAGE__->setup >>.
1005
1006  __PACKAGE__->log( MyLogger->new );
1007  __PACKAGE__->setup;
1008
1009 And later:
1010
1011     $c->log->info( 'Now logging with my own logger!' );
1012
1013 Your log class should implement the methods described in
1014 L<Catalyst::Log>.
1015
1016 =head2 encoding
1017
1018 Sets or gets the application encoding.
1019
1020 =cut
1021
1022 sub encoding {
1023     my $c = shift;
1024     my $encoding;
1025
1026     if ( scalar @_ ) {
1027         # Let it be set to undef
1028         if (my $wanted = shift)  {
1029             $encoding = Encode::find_encoding($wanted)
1030               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1031             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1032         }
1033         else {
1034             binmode(STDERR);
1035         }
1036
1037         $encoding = ref $c
1038                   ? $c->{encoding} = $encoding
1039                   : $c->_encoding($encoding);
1040     } else {
1041       $encoding = ref $c && exists $c->{encoding}
1042                 ? $c->{encoding}
1043                 : $c->_encoding;
1044     }
1045
1046     return $encoding;
1047 }
1048
1049 =head2 $c->debug
1050
1051 Returns 1 if debug mode is enabled, 0 otherwise.
1052
1053 You can enable debug mode in several ways:
1054
1055 =over
1056
1057 =item By calling myapp_server.pl with the -d flag
1058
1059 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1060
1061 =item The -Debug option in your MyApp.pm
1062
1063 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1064
1065 =back
1066
1067 The first three also set the log level to 'debug'.
1068
1069 Calling C<< $c->debug(1) >> has no effect.
1070
1071 =cut
1072
1073 sub debug { 0 }
1074
1075 =head2 $c->dispatcher
1076
1077 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1078
1079 =head2 $c->engine
1080
1081 Returns the engine instance. See L<Catalyst::Engine>.
1082
1083
1084 =head2 UTILITY METHODS
1085
1086 =head2 $c->path_to(@path)
1087
1088 Merges C<@path> with C<< $c->config->{home} >> and returns a
1089 L<Path::Class::Dir> object. Note you can usually use this object as
1090 a filename, but sometimes you will have to explicitly stringify it
1091 yourself by calling the C<< ->stringify >> method.
1092
1093 For example:
1094
1095     $c->path_to( 'db', 'sqlite.db' );
1096
1097 =cut
1098
1099 sub path_to {
1100     my ( $c, @path ) = @_;
1101     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1102     if ( -d $path ) { return $path }
1103     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1104 }
1105
1106 sub plugin {
1107     my ( $class, $name, $plugin, @args ) = @_;
1108
1109     # See block comment in t/unit_core_plugin.t
1110     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1111
1112     $class->_register_plugin( $plugin, 1 );
1113
1114     eval { $plugin->import };
1115     $class->mk_classdata($name);
1116     my $obj;
1117     eval { $obj = $plugin->new(@args) };
1118
1119     if ($@) {
1120         Catalyst::Exception->throw( message =>
1121               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1122     }
1123
1124     $class->$name($obj);
1125     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1126       if $class->debug;
1127 }
1128
1129 =head2 MyApp->setup
1130
1131 Initializes the dispatcher and engine, loads any plugins, and loads the
1132 model, view, and controller components. You may also specify an array
1133 of plugins to load here, if you choose to not load them in the C<use
1134 Catalyst> line.
1135
1136     MyApp->setup;
1137     MyApp->setup( qw/-Debug/ );
1138
1139 B<Note:> You B<should not> wrap this method with method modifiers
1140 or bad things will happen - wrap the C<setup_finalize> method instead.
1141
1142 =cut
1143
1144 sub setup {
1145     my ( $class, @arguments ) = @_;
1146     croak('Running setup more than once')
1147         if ( $class->setup_finished );
1148
1149     unless ( $class->isa('Catalyst') ) {
1150
1151         Catalyst::Exception->throw(
1152             message => qq/'$class' does not inherit from Catalyst/ );
1153     }
1154
1155     if ( $class->arguments ) {
1156         @arguments = ( @arguments, @{ $class->arguments } );
1157     }
1158
1159     # Process options
1160     my $flags = {};
1161
1162     foreach (@arguments) {
1163
1164         if (/^-Debug$/) {
1165             $flags->{log} =
1166               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1167         }
1168         elsif (/^-(\w+)=?(.*)$/) {
1169             $flags->{ lc $1 } = $2;
1170         }
1171         else {
1172             push @{ $flags->{plugins} }, $_;
1173         }
1174     }
1175
1176     $class->setup_home( delete $flags->{home} );
1177
1178     $class->setup_log( delete $flags->{log} );
1179     $class->setup_plugins( delete $flags->{plugins} );
1180
1181     $class->setup_data_handlers();
1182     $class->setup_dispatcher( delete $flags->{dispatcher} );
1183     if (my $engine = delete $flags->{engine}) {
1184         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1185     }
1186     $class->setup_engine();
1187     $class->setup_stats( delete $flags->{stats} );
1188
1189     for my $flag ( sort keys %{$flags} ) {
1190
1191         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1192             &$code( $class, delete $flags->{$flag} );
1193         }
1194         else {
1195             $class->log->warn(qq/Unknown flag "$flag"/);
1196         }
1197     }
1198
1199     eval { require Catalyst::Devel; };
1200     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1201         $class->log->warn(<<"EOF");
1202 You are running an old script!
1203
1204   Please update by running (this will overwrite existing files):
1205     catalyst.pl -force -scripts $class
1206
1207   or (this will not overwrite existing files):
1208     catalyst.pl -scripts $class
1209
1210 EOF
1211     }
1212
1213     # Call plugins setup, this is stupid and evil.
1214     # Also screws C3 badly on 5.10, hack to avoid.
1215     {
1216         no warnings qw/redefine/;
1217         local *setup = sub { };
1218         $class->setup unless $Catalyst::__AM_RESTARTING;
1219     }
1220
1221     # If you are expecting configuration info as part of your setup, it needs
1222     # to get called here and below, since we need the above line to support
1223     # ConfigLoader based configs.
1224
1225     $class->setup_encoding();
1226     $class->setup_middleware();
1227
1228     # Initialize our data structure
1229     $class->components( {} );
1230
1231     $class->setup_components;
1232
1233     if ( $class->debug ) {
1234         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1235
1236         if (@plugins) {
1237             my $column_width = Catalyst::Utils::term_width() - 6;
1238             my $t = Text::SimpleTable->new($column_width);
1239             $t->row($_) for @plugins;
1240             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1241         }
1242
1243         my @middleware = map {
1244           ref $_ eq 'CODE' ?
1245             "Inline Coderef" :
1246               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1247                 || '')  } $class->registered_middlewares;
1248
1249         if (@middleware) {
1250             my $column_width = Catalyst::Utils::term_width() - 6;
1251             my $t = Text::SimpleTable->new($column_width);
1252             $t->row($_) for @middleware;
1253             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1254         }
1255
1256         my %dh = $class->registered_data_handlers;
1257         if (my @data_handlers = keys %dh) {
1258             my $column_width = Catalyst::Utils::term_width() - 6;
1259             my $t = Text::SimpleTable->new($column_width);
1260             $t->row($_) for @data_handlers;
1261             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1262         }
1263
1264         my $dispatcher = $class->dispatcher;
1265         my $engine     = $class->engine;
1266         my $home       = $class->config->{home};
1267
1268         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1269         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1270
1271         $home
1272           ? ( -d $home )
1273           ? $class->log->debug(qq/Found home "$home"/)
1274           : $class->log->debug(qq/Home "$home" doesn't exist/)
1275           : $class->log->debug(q/Couldn't find home/);
1276
1277         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1278         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1279         for my $comp ( sort keys %{ $class->components } ) {
1280             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1281             $t->row( $comp, $type );
1282         }
1283         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1284           if ( keys %{ $class->components } );
1285     }
1286
1287     # Add our self to components, since we are also a component
1288     if( $class->isa('Catalyst::Controller') ){
1289       $class->components->{$class} = $class;
1290     }
1291
1292     $class->setup_actions;
1293
1294     if ( $class->debug ) {
1295         my $name = $class->config->{name} || 'Application';
1296         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1297     }
1298
1299     if ($class->config->{case_sensitive}) {
1300         $class->log->warn($class . "->config->{case_sensitive} is set.");
1301         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1302     }
1303
1304     $class->setup_finalize;
1305
1306     # Flush the log for good measure (in case something turned off 'autoflush' early)
1307     $class->log->_flush() if $class->log->can('_flush');
1308
1309     return $class || 1; # Just in case someone named their Application 0...
1310 }
1311
1312 =head2 $app->setup_finalize
1313
1314 A hook to attach modifiers to. This method does not do anything except set the
1315 C<setup_finished> accessor.
1316
1317 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1318
1319 Example:
1320
1321     after setup_finalize => sub {
1322         my $app = shift;
1323
1324         ## do stuff here..
1325     };
1326
1327 =cut
1328
1329 sub setup_finalize {
1330     my ($class) = @_;
1331     $class->setup_finished(1);
1332 }
1333
1334 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1335
1336 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1337
1338 Constructs an absolute L<URI> object based on the application root, the
1339 provided path, and the additional arguments and query parameters provided.
1340 When used as a string, provides a textual URI.  If you need more flexibility
1341 than this (i.e. the option to provide relative URIs etc.) see
1342 L<Catalyst::Plugin::SmartURI>.
1343
1344 If no arguments are provided, the URI for the current action is returned.
1345 To return the current action and also provide @args, use
1346 C<< $c->uri_for( $c->action, @args ) >>.
1347
1348 If the first argument is a string, it is taken as a public URI path relative
1349 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1350 relative to the application root (if it does). It is then merged with
1351 C<< $c->request->base >>; any C<@args> are appended as additional path
1352 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1353
1354 If the first argument is a L<Catalyst::Action> it represents an action which
1355 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1356 optional C<\@captures> argument (an arrayref) allows passing the captured
1357 variables that are needed to fill in the paths of Chained and Regex actions;
1358 once the path is resolved, C<uri_for> continues as though a path was
1359 provided, appending any arguments or parameters and creating an absolute
1360 URI.
1361
1362 The captures for the current request can be found in
1363 C<< $c->request->captures >>, and actions can be resolved using
1364 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1365 path, use C<< $c->uri_for_action >> instead.
1366
1367   # Equivalent to $c->req->uri
1368   $c->uri_for($c->action, $c->req->captures,
1369       @{ $c->req->args }, $c->req->params);
1370
1371   # For the Foo action in the Bar controller
1372   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1373
1374   # Path to a static resource
1375   $c->uri_for('/static/images/logo.png');
1376
1377 =cut
1378
1379 sub uri_for {
1380     my ( $c, $path, @args ) = @_;
1381
1382     if ( $path->$_isa('Catalyst::Controller') ) {
1383         $path = $path->path_prefix;
1384         $path =~ s{/+\z}{};
1385         $path .= '/';
1386     }
1387
1388     undef($path) if (defined $path && $path eq '');
1389
1390     my $params =
1391       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1392
1393     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1394
1395     my @encoded_args = ();
1396     foreach my $arg (@args) {
1397       if(ref($arg)||'' eq 'ARRAY') {
1398         push @encoded_args, [map {
1399           my $encoded = encode_utf8 $_;
1400           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1401          $encoded;
1402         } @$arg];
1403       } else {
1404         push @encoded_args, do {
1405           my $encoded = encode_utf8 $arg;
1406           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1407           $encoded;
1408         }
1409       }
1410     }
1411
1412     if ( $path->$_isa('Catalyst::Action') ) { # action object
1413         s|/|%2F|g for @encoded_args;
1414         my $captures = [ map { s|/|%2F|g; $_; }
1415                         ( scalar @encoded_args && ref $encoded_args[0] eq 'ARRAY'
1416                          ? @{ shift(@encoded_args) }
1417                          : ()) ];
1418
1419         my $action = $path;
1420         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1421         if( !@encoded_args && $action->number_of_args ) {
1422             my $expanded_action = $c->dispatcher->expand_action( $action );
1423
1424             my $num_captures = $expanded_action->number_of_captures;
1425             unshift @encoded_args, splice @$captures, $num_captures;
1426         }
1427
1428        $path = $c->dispatcher->uri_for_action($action, $captures);
1429         if (not defined $path) {
1430             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1431                 if $c->debug;
1432             return undef;
1433         }
1434         $path = '/' if $path eq '';
1435     }
1436
1437     unshift(@encoded_args, $path);
1438
1439     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1440         my $namespace = $c->namespace;
1441         if (defined $path) { # cheesy hack to handle path '../foo'
1442            $namespace =~ s{(?:^|/)[^/]+$}{} while $encoded_args[0] =~ s{^\.\./}{};
1443         }
1444         unshift(@encoded_args, $namespace || '');
1445     }
1446
1447     # join args with '/', or a blank string
1448     my $args = join('/', grep { defined($_) } @encoded_args);
1449     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1450     $args =~ s!^/+!!;
1451
1452     my ($base, $class) = ('/', 'URI::_generic');
1453     if(blessed($c)) {
1454       $base = $c->req->base;
1455       $class = ref($base);
1456       $base =~ s{(?<!/)$}{/};
1457     }
1458
1459     my $query = '';
1460
1461     if (my @keys = keys %$params) {
1462       # somewhat lifted from URI::_query's query_form
1463       $query = '?'.join('&', map {
1464           my $val = $params->{$_};
1465           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1466           s/ /+/g;
1467           my $key = $_;
1468           $val = '' unless defined $val;
1469           (map {
1470               my $param = "$_";
1471               $param = encode_utf8($param);
1472               # using the URI::Escape pattern here so utf8 chars survive
1473               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1474               $param =~ s/ /+/g;
1475
1476               $key = encode_utf8($key);
1477               # using the URI::Escape pattern here so utf8 chars survive
1478               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1479               $key =~ s/ /+/g;
1480
1481               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1482       } @keys);
1483     }
1484
1485     my $res = bless(\"${base}${args}${query}", $class);
1486     $res;
1487 }
1488
1489 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1490
1491 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1492
1493 =over
1494
1495 =item $path
1496
1497 A private path to the Catalyst action you want to create a URI for.
1498
1499 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1500 >> and passing the resulting C<$action> and the remaining arguments to C<<
1501 $c->uri_for >>.
1502
1503 You can also pass in a Catalyst::Action object, in which case it is passed to
1504 C<< $c->uri_for >>.
1505
1506 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1507
1508 For example, if the action looks like:
1509
1510  package MyApp::Controller::Users;
1511
1512  sub lst : Path('the-list') {}
1513
1514 You can use:
1515
1516  $c->uri_for_action('/users/lst')
1517
1518 and it will create the URI /users/the-list.
1519
1520 =item \@captures_and_args?
1521
1522 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1523 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1524 to interpolate all the parameters in the URI.
1525
1526 =item @args?
1527
1528 Optional list of extra arguments - can be supplied in the
1529 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1530 code.
1531
1532 Your action can have zero, a fixed or a variable number of args (e.g.
1533 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1534
1535 =item \%query_values?
1536
1537 Optional array reference of query parameters to append. E.g.
1538
1539   { foo => 'bar' }
1540
1541 will generate
1542
1543   /rest/of/your/uri?foo=bar
1544
1545 =back
1546
1547 =cut
1548
1549 sub uri_for_action {
1550     my ( $c, $path, @args ) = @_;
1551     my $action = blessed($path)
1552       ? $path
1553       : $c->dispatcher->get_action_by_path($path);
1554     unless (defined $action) {
1555       croak "Can't find action for path '$path'";
1556     }
1557     return $c->uri_for( $action, @args );
1558 }
1559
1560 =head2 $c->welcome_message
1561
1562 Returns the Catalyst welcome HTML page.
1563
1564 =cut
1565
1566 sub welcome_message {
1567     my $c      = shift;
1568     my $name   = $c->config->{name};
1569     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1570     my $prefix = Catalyst::Utils::appprefix( ref $c );
1571     $c->response->content_type('text/html; charset=utf-8');
1572     return <<"EOF";
1573 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1574     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1575 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1576     <head>
1577     <meta http-equiv="Content-Language" content="en" />
1578     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1579         <title>$name on Catalyst $VERSION</title>
1580         <style type="text/css">
1581             body {
1582                 color: #000;
1583                 background-color: #eee;
1584             }
1585             div#content {
1586                 width: 640px;
1587                 margin-left: auto;
1588                 margin-right: auto;
1589                 margin-top: 10px;
1590                 margin-bottom: 10px;
1591                 text-align: left;
1592                 background-color: #ccc;
1593                 border: 1px solid #aaa;
1594             }
1595             p, h1, h2 {
1596                 margin-left: 20px;
1597                 margin-right: 20px;
1598                 font-family: verdana, tahoma, sans-serif;
1599             }
1600             a {
1601                 font-family: verdana, tahoma, sans-serif;
1602             }
1603             :link, :visited {
1604                     text-decoration: none;
1605                     color: #b00;
1606                     border-bottom: 1px dotted #bbb;
1607             }
1608             :link:hover, :visited:hover {
1609                     color: #555;
1610             }
1611             div#topbar {
1612                 margin: 0px;
1613             }
1614             pre {
1615                 margin: 10px;
1616                 padding: 8px;
1617             }
1618             div#answers {
1619                 padding: 8px;
1620                 margin: 10px;
1621                 background-color: #fff;
1622                 border: 1px solid #aaa;
1623             }
1624             h1 {
1625                 font-size: 0.9em;
1626                 font-weight: normal;
1627                 text-align: center;
1628             }
1629             h2 {
1630                 font-size: 1.0em;
1631             }
1632             p {
1633                 font-size: 0.9em;
1634             }
1635             p img {
1636                 float: right;
1637                 margin-left: 10px;
1638             }
1639             span#appname {
1640                 font-weight: bold;
1641                 font-size: 1.6em;
1642             }
1643         </style>
1644     </head>
1645     <body>
1646         <div id="content">
1647             <div id="topbar">
1648                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1649                     $VERSION</h1>
1650              </div>
1651              <div id="answers">
1652                  <p>
1653                  <img src="$logo" alt="Catalyst Logo" />
1654                  </p>
1655                  <p>Welcome to the  world of Catalyst.
1656                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1657                     framework will make web development something you had
1658                     never expected it to be: Fun, rewarding, and quick.</p>
1659                  <h2>What to do now?</h2>
1660                  <p>That really depends  on what <b>you</b> want to do.
1661                     We do, however, provide you with a few starting points.</p>
1662                  <p>If you want to jump right into web development with Catalyst
1663                     you might want to start with a tutorial.</p>
1664 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1665 </pre>
1666 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1667 <pre>
1668 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1669 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1670 </code></pre>
1671                  <h2>What to do next?</h2>
1672                  <p>Next it's time to write an actual application. Use the
1673                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1674                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1675                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1676                     they can save you a lot of work.</p>
1677                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1678                     <p>Also, be sure to check out the vast and growing
1679                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1680                     you are likely to find what you need there.
1681                     </p>
1682
1683                  <h2>Need help?</h2>
1684                  <p>Catalyst has a very active community. Here are the main places to
1685                     get in touch with us.</p>
1686                  <ul>
1687                      <li>
1688                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1689                      </li>
1690                      <li>
1691                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1692                      </li>
1693                      <li>
1694                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1695                      </li>
1696                  </ul>
1697                  <h2>In conclusion</h2>
1698                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1699                     as we enjoyed making it. Please contact us if you have ideas
1700                     for improvement or other feedback.</p>
1701              </div>
1702          </div>
1703     </body>
1704 </html>
1705 EOF
1706 }
1707
1708 =head2 run_options
1709
1710 Contains a hash of options passed from the application script, including
1711 the original ARGV the script received, the processed values from that
1712 ARGV and any extra arguments to the script which were not processed.
1713
1714 This can be used to add custom options to your application's scripts
1715 and setup your application differently depending on the values of these
1716 options.
1717
1718 =head1 INTERNAL METHODS
1719
1720 These methods are not meant to be used by end users.
1721
1722 =head2 $c->components
1723
1724 Returns a hash of components.
1725
1726 =head2 $c->context_class
1727
1728 Returns or sets the context class.
1729
1730 =head2 $c->counter
1731
1732 Returns a hashref containing coderefs and execution counts (needed for
1733 deep recursion detection).
1734
1735 =head2 $c->depth
1736
1737 Returns the number of actions on the current internal execution stack.
1738
1739 =head2 $c->dispatch
1740
1741 Dispatches a request to actions.
1742
1743 =cut
1744
1745 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1746
1747 =head2 $c->dispatcher_class
1748
1749 Returns or sets the dispatcher class.
1750
1751 =head2 $c->dump_these
1752
1753 Returns a list of 2-element array references (name, structure) pairs
1754 that will be dumped on the error page in debug mode.
1755
1756 =cut
1757
1758 sub dump_these {
1759     my $c = shift;
1760     [ Request => $c->req ],
1761     [ Response => $c->res ],
1762     [ Stash => $c->stash ],
1763     [ Config => $c->config ];
1764 }
1765
1766 =head2 $c->engine_class
1767
1768 Returns or sets the engine class.
1769
1770 =head2 $c->execute( $class, $coderef )
1771
1772 Execute a coderef in given class and catch exceptions. Errors are available
1773 via $c->error.
1774
1775 =cut
1776
1777 sub execute {
1778     my ( $c, $class, $code ) = @_;
1779     $class = $c->component($class) || $class;
1780     $c->state(0);
1781
1782     if ( $c->depth >= $RECURSION ) {
1783         my $action = $code->reverse();
1784         $action = "/$action" unless $action =~ /->/;
1785         my $error = qq/Deep recursion detected calling "${action}"/;
1786         $c->log->error($error);
1787         $c->error($error);
1788         $c->state(0);
1789         return $c->state;
1790     }
1791
1792     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1793
1794     push( @{ $c->stack }, $code );
1795
1796     no warnings 'recursion';
1797     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1798     #      I have no idea how, ergo $ret (which appears to fix the issue)
1799     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1800
1801     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1802
1803     my $last = pop( @{ $c->stack } );
1804
1805     if ( my $error = $@ ) {
1806         #rethow if this can be handled by middleware
1807         if(
1808           blessed $error && (
1809             $error->can('as_psgi') ||
1810             (
1811               $error->can('code') &&
1812               $error->code =~m/^[1-5][0-9][0-9]$/
1813             )
1814           )
1815         ) {
1816             foreach my $err (@{$c->error}) {
1817                 $c->log->error($err);
1818             }
1819             $c->clear_errors;
1820             $c->log->_flush if $c->log->can('_flush');
1821
1822             $error->can('rethrow') ? $error->rethrow : croak $error;
1823         }
1824         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1825             $error->rethrow if $c->depth > 1;
1826         }
1827         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1828             $error->rethrow if $c->depth > 0;
1829         }
1830         else {
1831             unless ( ref $error ) {
1832                 no warnings 'uninitialized';
1833                 chomp $error;
1834                 my $class = $last->class;
1835                 my $name  = $last->name;
1836                 $error = qq/Caught exception in $class->$name "$error"/;
1837             }
1838             $c->error($error);
1839         }
1840         $c->state(0);
1841     }
1842     return $c->state;
1843 }
1844
1845 sub _stats_start_execute {
1846     my ( $c, $code ) = @_;
1847     my $appclass = ref($c) || $c;
1848     return if ( ( $code->name =~ /^_.*/ )
1849         && ( !$appclass->config->{show_internal_actions} ) );
1850
1851     my $action_name = $code->reverse();
1852     $c->counter->{$action_name}++;
1853
1854     my $action = $action_name;
1855     $action = "/$action" unless $action =~ /->/;
1856
1857     # determine if the call was the result of a forward
1858     # this is done by walking up the call stack and looking for a calling
1859     # sub of Catalyst::forward before the eval
1860     my $callsub = q{};
1861     for my $index ( 2 .. 11 ) {
1862         last
1863         if ( ( caller($index) )[0] eq 'Catalyst'
1864             && ( caller($index) )[3] eq '(eval)' );
1865
1866         if ( ( caller($index) )[3] =~ /forward$/ ) {
1867             $callsub = ( caller($index) )[3];
1868             $action  = "-> $action";
1869             last;
1870         }
1871     }
1872
1873     my $uid = $action_name . $c->counter->{$action_name};
1874
1875     # is this a root-level call or a forwarded call?
1876     if ( $callsub =~ /forward$/ ) {
1877         my $parent = $c->stack->[-1];
1878
1879         # forward, locate the caller
1880         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1881             $c->stats->profile(
1882                 begin  => $action,
1883                 parent => "$parent" . $c->counter->{"$parent"},
1884                 uid    => $uid,
1885             );
1886         }
1887         else {
1888
1889             # forward with no caller may come from a plugin
1890             $c->stats->profile(
1891                 begin => $action,
1892                 uid   => $uid,
1893             );
1894         }
1895     }
1896     else {
1897
1898         # root-level call
1899         $c->stats->profile(
1900             begin => $action,
1901             uid   => $uid,
1902         );
1903     }
1904     return $action;
1905
1906 }
1907
1908 sub _stats_finish_execute {
1909     my ( $c, $info ) = @_;
1910     $c->stats->profile( end => $info );
1911 }
1912
1913 =head2 $c->finalize
1914
1915 Finalizes the request.
1916
1917 =cut
1918
1919 sub finalize {
1920     my $c = shift;
1921
1922     for my $error ( @{ $c->error } ) {
1923         $c->log->error($error);
1924     }
1925
1926     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1927     # stuff like cometd and websockets
1928
1929     if($c->request->_has_io_fh) {
1930       $c->log_response;
1931       return;
1932     }
1933
1934     # Allow engine to handle finalize flow (for POE)
1935     my $engine = $c->engine;
1936     if ( my $code = $engine->can('finalize') ) {
1937         $engine->$code($c);
1938     }
1939     else {
1940
1941         $c->finalize_uploads;
1942
1943         # Error
1944         if ( $#{ $c->error } >= 0 ) {
1945             $c->finalize_error;
1946         }
1947
1948         $c->finalize_encoding;
1949         $c->finalize_headers unless $c->response->finalized_headers;
1950         $c->finalize_body;
1951     }
1952
1953     $c->log_response;
1954
1955     if ($c->use_stats) {
1956         my $elapsed = $c->stats->elapsed;
1957         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1958         $c->log->info(
1959             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1960     }
1961
1962     return $c->response->status;
1963 }
1964
1965 =head2 $c->finalize_body
1966
1967 Finalizes body.
1968
1969 =cut
1970
1971 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1972
1973 =head2 $c->finalize_cookies
1974
1975 Finalizes cookies.
1976
1977 =cut
1978
1979 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1980
1981 =head2 $c->finalize_error
1982
1983 Finalizes error.  If there is only one error in L</error> and it is an object that
1984 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
1985 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
1986 return the default error page (production mode).
1987
1988 =cut
1989
1990 sub finalize_error {
1991     my $c = shift;
1992     if($#{$c->error} > 0) {
1993         $c->engine->finalize_error( $c, @_ );
1994     } else {
1995         my ($error) = @{$c->error};
1996         if(
1997           blessed $error &&
1998           ($error->can('as_psgi') || $error->can('code'))
1999         ) {
2000             # In the case where the error 'knows what it wants', becauses its PSGI
2001             # aware, just rethow and let middleware catch it
2002             $error->can('rethrow') ? $error->rethrow : croak $error;
2003         } else {
2004             $c->engine->finalize_error( $c, @_ )
2005         }
2006     }
2007 }
2008
2009 =head2 $c->finalize_headers
2010
2011 Finalizes headers.
2012
2013 =cut
2014
2015 sub finalize_headers {
2016     my $c = shift;
2017
2018     my $response = $c->response; #accessor calls can add up?
2019
2020     # Check if we already finalized headers
2021     return if $response->finalized_headers;
2022
2023     # Handle redirects
2024     if ( my $location = $response->redirect ) {
2025         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2026         $response->header( Location => $location );
2027     }
2028
2029     # Remove incorrectly added body and content related meta data when returning
2030     # an information response, or a response the is required to not include a body
2031
2032     $c->finalize_cookies;
2033
2034     $c->response->finalize_headers();
2035
2036     if(my $enc = $c->encoding) {
2037        my ($ct, $ct_enc) = $c->response->content_type;
2038
2039         # Only touch 'text-like' contents
2040         if($c->response->content_type =~ /^text|xml$|javascript$/) {
2041           if ($ct_enc && $ct_enc =~ /charset=([^;]*)/) {
2042             if (uc($1) ne uc($enc->mime_name)) {
2043               $c->log->debug("Catalyst encoding config is set to encode in '" .
2044                            $enc->mime_name .
2045                            "', content type is '$1', not encoding ");
2046             }
2047           } else {
2048             $c->res->content_type($c->res->content_type . "; charset=" . $enc->mime_name);
2049           }
2050         }
2051     }
2052
2053     # Done
2054     $response->finalized_headers(1);
2055 }
2056
2057 =head2 $c->finalize_encoding
2058
2059 Make sure your body is encoded properly IF you set an encoding.  By
2060 default the encoding is UTF-8 but you can disable it by explictly setting the
2061 encoding configuration value to undef.
2062
2063 See L</ENCODING>.
2064
2065 =cut
2066
2067 sub finalize_encoding {
2068     my $c = shift;
2069
2070     my $body = $c->response->body;
2071
2072     return unless defined($body);
2073
2074     my $enc = $c->encoding;
2075
2076     return unless $enc;
2077
2078     # Only touch 'text-like' contents
2079     if($c->response->content_type =~ /^text|xml$|javascript$/) {
2080       if (ref(\$body) eq 'SCALAR') {
2081         $c->response->body( $c->encoding->encode( $body, $c->_encode_check ) );
2082       }
2083     }
2084 }
2085
2086 =head2 $c->finalize_output
2087
2088 An alias for finalize_body.
2089
2090 =head2 $c->finalize_read
2091
2092 Finalizes the input after reading is complete.
2093
2094 =cut
2095
2096 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2097
2098 =head2 $c->finalize_uploads
2099
2100 Finalizes uploads. Cleans up any temporary files.
2101
2102 =cut
2103
2104 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2105
2106 =head2 $c->get_action( $action, $namespace )
2107
2108 Gets an action in a given namespace.
2109
2110 =cut
2111
2112 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2113
2114 =head2 $c->get_actions( $action, $namespace )
2115
2116 Gets all actions of a given name in a namespace and all parent
2117 namespaces.
2118
2119 =cut
2120
2121 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2122
2123 =head2 $app->handle_request( @arguments )
2124
2125 Called to handle each HTTP request.
2126
2127 =cut
2128
2129 sub handle_request {
2130     my ( $class, @arguments ) = @_;
2131
2132     # Always expect worst case!
2133     my $status = -1;
2134     try {
2135         if ($class->debug) {
2136             my $secs = time - $START || 1;
2137             my $av = sprintf '%.3f', $COUNT / $secs;
2138             my $time = localtime time;
2139             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2140         }
2141
2142         my $c = $class->prepare(@arguments);
2143         $c->dispatch;
2144         $status = $c->finalize;
2145     } catch {
2146         #rethow if this can be handled by middleware
2147         if(
2148           blessed($_) && (
2149             $_->can('as_psgi') ||
2150             (
2151               $_->can('code') &&
2152               $_->code =~m/^[1-5][0-9][0-9]$/
2153             )
2154           )
2155         ) {
2156             $_->can('rethrow') ? $_->rethrow : croak $_;
2157         }
2158         chomp(my $error = $_);
2159         $class->log->error(qq/Caught exception in engine "$error"/);
2160     };
2161
2162     $COUNT++;
2163
2164     if(my $coderef = $class->log->can('_flush')){
2165         $class->log->$coderef();
2166     }
2167     return $status;
2168 }
2169
2170 =head2 $class->prepare( @arguments )
2171
2172 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2173 etc.).
2174
2175 =cut
2176
2177 has _uploadtmp => (
2178     is => 'ro',
2179     predicate => '_has_uploadtmp',
2180 );
2181
2182 sub prepare {
2183     my ( $class, @arguments ) = @_;
2184
2185     # XXX
2186     # After the app/ctxt split, this should become an attribute based on something passed
2187     # into the application.
2188     $class->context_class( ref $class || $class ) unless $class->context_class;
2189
2190     my $uploadtmp = $class->config->{uploadtmp};
2191     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2192
2193     $c->response->_context($c);
2194
2195     #surely this is not the most efficient way to do things...
2196     $c->stats($class->stats_class->new)->enable($c->use_stats);
2197     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2198         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2199     }
2200
2201     try {
2202         # Allow engine to direct the prepare flow (for POE)
2203         if ( my $prepare = $c->engine->can('prepare') ) {
2204             $c->engine->$prepare( $c, @arguments );
2205         }
2206         else {
2207             $c->prepare_request(@arguments);
2208             $c->prepare_connection;
2209             $c->prepare_query_parameters;
2210             $c->prepare_headers; # Just hooks, no longer needed - they just
2211             $c->prepare_cookies; # cause the lazy attribute on req to build
2212             $c->prepare_path;
2213
2214             # Prepare the body for reading, either by prepare_body
2215             # or the user, if they are using $c->read
2216             $c->prepare_read;
2217
2218             # Parse the body unless the user wants it on-demand
2219             unless ( ref($c)->config->{parse_on_demand} ) {
2220                 $c->prepare_body;
2221             }
2222         }
2223         $c->prepare_action;
2224     }
2225     # VERY ugly and probably shouldn't rely on ->finalize actually working
2226     catch {
2227         # failed prepare is always due to an invalid request, right?
2228         $c->response->status(400);
2229         $c->response->content_type('text/plain');
2230         $c->response->body('Bad Request');
2231         # Note we call finalize and then die here, which escapes
2232         # finalize being called in the enclosing block..
2233         # It in fact couldn't be called, as we don't return $c..
2234         # This is a mess - but I'm unsure you can fix this without
2235         # breaking compat for people doing crazy things (we should set
2236         # the 400 and just return the ctx here IMO, letting finalize get called
2237         # above...
2238         $c->finalize;
2239         die $_;
2240     };
2241
2242     $c->log_request;
2243
2244     return $c;
2245 }
2246
2247 =head2 $c->prepare_action
2248
2249 Prepares action. See L<Catalyst::Dispatcher>.
2250
2251 =cut
2252
2253 sub prepare_action {
2254     my $c = shift;
2255     my $ret = $c->dispatcher->prepare_action( $c, @_);
2256
2257     if($c->encoding) {
2258         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2259           $_ = $c->_handle_param_unicode_decoding($_);
2260         }
2261     }
2262
2263     return $ret;
2264 }
2265
2266
2267 =head2 $c->prepare_body
2268
2269 Prepares message body.
2270
2271 =cut
2272
2273 sub prepare_body {
2274     my $c = shift;
2275
2276     return if $c->request->_has_body;
2277
2278     # Initialize on-demand data
2279     $c->engine->prepare_body( $c, @_ );
2280     $c->prepare_parameters;
2281     $c->prepare_uploads;
2282 }
2283
2284 =head2 $c->prepare_body_chunk( $chunk )
2285
2286 Prepares a chunk of data before sending it to L<HTTP::Body>.
2287
2288 See L<Catalyst::Engine>.
2289
2290 =cut
2291
2292 sub prepare_body_chunk {
2293     my $c = shift;
2294     $c->engine->prepare_body_chunk( $c, @_ );
2295 }
2296
2297 =head2 $c->prepare_body_parameters
2298
2299 Prepares body parameters.
2300
2301 =cut
2302
2303 sub prepare_body_parameters {
2304     my $c = shift;
2305     $c->request->prepare_body_parameters( $c, @_ );
2306 }
2307
2308 =head2 $c->prepare_connection
2309
2310 Prepares connection.
2311
2312 =cut
2313
2314 sub prepare_connection {
2315     my $c = shift;
2316     $c->request->prepare_connection($c);
2317 }
2318
2319 =head2 $c->prepare_cookies
2320
2321 Prepares cookies by ensuring that the attribute on the request
2322 object has been built.
2323
2324 =cut
2325
2326 sub prepare_cookies { my $c = shift; $c->request->cookies }
2327
2328 =head2 $c->prepare_headers
2329
2330 Prepares request headers by ensuring that the attribute on the request
2331 object has been built.
2332
2333 =cut
2334
2335 sub prepare_headers { my $c = shift; $c->request->headers }
2336
2337 =head2 $c->prepare_parameters
2338
2339 Prepares parameters.
2340
2341 =cut
2342
2343 sub prepare_parameters {
2344     my $c = shift;
2345     $c->prepare_body_parameters;
2346     $c->engine->prepare_parameters( $c, @_ );
2347 }
2348
2349 =head2 $c->prepare_path
2350
2351 Prepares path and base.
2352
2353 =cut
2354
2355 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2356
2357 =head2 $c->prepare_query_parameters
2358
2359 Prepares query parameters.
2360
2361 =cut
2362
2363 sub prepare_query_parameters {
2364     my $c = shift;
2365
2366     $c->engine->prepare_query_parameters( $c, @_ );
2367 }
2368
2369 =head2 $c->log_request
2370
2371 Writes information about the request to the debug logs.  This includes:
2372
2373 =over 4
2374
2375 =item * Request method, path, and remote IP address
2376
2377 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2378
2379 =item * Request parameters
2380
2381 =item * File uploads
2382
2383 =back
2384
2385 =cut
2386
2387 sub log_request {
2388     my $c = shift;
2389
2390     return unless $c->debug;
2391
2392     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2393     my $request = $dump->[1];
2394
2395     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2396     $method ||= '';
2397     $path = '/' unless length $path;
2398     $address ||= '';
2399
2400     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2401     $path = decode_utf8($path);
2402
2403     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2404
2405     $c->log_request_headers($request->headers);
2406
2407     if ( my $keywords = $request->query_keywords ) {
2408         $c->log->debug("Query keywords are: $keywords");
2409     }
2410
2411     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2412
2413     $c->log_request_uploads($request);
2414 }
2415
2416 =head2 $c->log_response
2417
2418 Writes information about the response to the debug logs by calling
2419 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2420
2421 =cut
2422
2423 sub log_response {
2424     my $c = shift;
2425
2426     return unless $c->debug;
2427
2428     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2429     my $response = $dump->[1];
2430
2431     $c->log_response_status_line($response);
2432     $c->log_response_headers($response->headers);
2433 }
2434
2435 =head2 $c->log_response_status_line($response)
2436
2437 Writes one line of information about the response to the debug logs.  This includes:
2438
2439 =over 4
2440
2441 =item * Response status code
2442
2443 =item * Content-Type header (if present)
2444
2445 =item * Content-Length header (if present)
2446
2447 =back
2448
2449 =cut
2450
2451 sub log_response_status_line {
2452     my ($c, $response) = @_;
2453
2454     $c->log->debug(
2455         sprintf(
2456             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2457             $response->status                            || 'unknown',
2458             $response->headers->header('Content-Type')   || 'unknown',
2459             $response->headers->header('Content-Length') || 'unknown'
2460         )
2461     );
2462 }
2463
2464 =head2 $c->log_response_headers($headers);
2465
2466 Hook method which can be wrapped by plugins to log the response headers.
2467 No-op in the default implementation.
2468
2469 =cut
2470
2471 sub log_response_headers {}
2472
2473 =head2 $c->log_request_parameters( query => {}, body => {} )
2474
2475 Logs request parameters to debug logs
2476
2477 =cut
2478
2479 sub log_request_parameters {
2480     my $c          = shift;
2481     my %all_params = @_;
2482
2483     return unless $c->debug;
2484
2485     my $column_width = Catalyst::Utils::term_width() - 44;
2486     foreach my $type (qw(query body)) {
2487         my $params = $all_params{$type};
2488         next if ! keys %$params;
2489         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2490         for my $key ( sort keys %$params ) {
2491             my $param = $params->{$key};
2492             my $value = defined($param) ? $param : '';
2493             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2494         }
2495         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2496     }
2497 }
2498
2499 =head2 $c->log_request_uploads
2500
2501 Logs file uploads included in the request to the debug logs.
2502 The parameter name, filename, file type, and file size are all included in
2503 the debug logs.
2504
2505 =cut
2506
2507 sub log_request_uploads {
2508     my $c = shift;
2509     my $request = shift;
2510     return unless $c->debug;
2511     my $uploads = $request->uploads;
2512     if ( keys %$uploads ) {
2513         my $t = Text::SimpleTable->new(
2514             [ 12, 'Parameter' ],
2515             [ 26, 'Filename' ],
2516             [ 18, 'Type' ],
2517             [ 9,  'Size' ]
2518         );
2519         for my $key ( sort keys %$uploads ) {
2520             my $upload = $uploads->{$key};
2521             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2522                 $t->row( $key, $u->filename, $u->type, $u->size );
2523             }
2524         }
2525         $c->log->debug( "File Uploads are:\n" . $t->draw );
2526     }
2527 }
2528
2529 =head2 $c->log_request_headers($headers);
2530
2531 Hook method which can be wrapped by plugins to log the request headers.
2532 No-op in the default implementation.
2533
2534 =cut
2535
2536 sub log_request_headers {}
2537
2538 =head2 $c->log_headers($type => $headers)
2539
2540 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2541
2542 =cut
2543
2544 sub log_headers {
2545     my $c       = shift;
2546     my $type    = shift;
2547     my $headers = shift;    # an HTTP::Headers instance
2548
2549     return unless $c->debug;
2550
2551     my $column_width = Catalyst::Utils::term_width() - 28;
2552     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2553     $headers->scan(
2554         sub {
2555             my ( $name, $value ) = @_;
2556             $t->row( $name, $value );
2557         }
2558     );
2559     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2560 }
2561
2562
2563 =head2 $c->prepare_read
2564
2565 Prepares the input for reading.
2566
2567 =cut
2568
2569 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2570
2571 =head2 $c->prepare_request
2572
2573 Prepares the engine request.
2574
2575 =cut
2576
2577 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2578
2579 =head2 $c->prepare_uploads
2580
2581 Prepares uploads.
2582
2583 =cut
2584
2585 sub prepare_uploads {
2586     my $c = shift;
2587     $c->engine->prepare_uploads( $c, @_ );
2588 }
2589
2590 =head2 $c->prepare_write
2591
2592 Prepares the output for writing.
2593
2594 =cut
2595
2596 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2597
2598 =head2 $c->request_class
2599
2600 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2601
2602 =head2 $c->response_class
2603
2604 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2605
2606 =head2 $c->read( [$maxlength] )
2607
2608 Reads a chunk of data from the request body. This method is designed to
2609 be used in a while loop, reading C<$maxlength> bytes on every call.
2610 C<$maxlength> defaults to the size of the request if not specified.
2611
2612 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2613 directly.
2614
2615 Warning: If you use read(), Catalyst will not process the body,
2616 so you will not be able to access POST parameters or file uploads via
2617 $c->request.  You must handle all body parsing yourself.
2618
2619 =cut
2620
2621 sub read { my $c = shift; return $c->request->read( @_ ) }
2622
2623 =head2 $c->run
2624
2625 Starts the engine.
2626
2627 =cut
2628
2629 sub run {
2630   my $app = shift;
2631   $app->_make_immutable_if_needed;
2632   $app->engine_loader->needs_psgi_engine_compat_hack ?
2633     $app->engine->run($app, @_) :
2634       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2635 }
2636
2637 sub _make_immutable_if_needed {
2638     my $class = shift;
2639     my $meta = find_meta($class);
2640     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2641     if (
2642         $meta->is_immutable
2643         && ! { $meta->immutable_options }->{replace_constructor}
2644         && $isa_ca
2645     ) {
2646         warn("You made your application class ($class) immutable, "
2647             . "but did not inline the\nconstructor. "
2648             . "This will break catalyst, as your app \@ISA "
2649             . "Class::Accessor(::Fast)?\nPlease pass "
2650             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2651     }
2652     unless ($meta->is_immutable) {
2653         # XXX - FIXME warning here as you should make your app immutable yourself.
2654         $meta->make_immutable(
2655             replace_constructor => 1,
2656         );
2657     }
2658 }
2659
2660 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2661
2662 Sets an action in a given namespace.
2663
2664 =cut
2665
2666 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2667
2668 =head2 $c->setup_actions($component)
2669
2670 Sets up actions for a component.
2671
2672 =cut
2673
2674 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2675
2676 =head2 $c->setup_components
2677
2678 This method is called internally to set up the application's components.
2679
2680 It finds modules by calling the L<locate_components> method, expands them to
2681 package names with the L<expand_component_module> method, and then installs
2682 each component into the application.
2683
2684 The C<setup_components> config option is passed to both of the above methods.
2685
2686 Installation of each component is performed by the L<setup_component> method,
2687 below.
2688
2689 =cut
2690
2691 sub setup_components {
2692     my $class = shift;
2693
2694     my $config  = $class->config->{ setup_components };
2695
2696     my @comps = $class->locate_components($config);
2697     my %comps = map { $_ => 1 } @comps;
2698
2699     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2700     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2701         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2702     ) if $deprecatedcatalyst_component_names;
2703
2704     for my $component ( @comps ) {
2705
2706         # We pass ignore_loaded here so that overlay files for (e.g.)
2707         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2708         # we know M::P::O found a file on disk so this is safe
2709
2710         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2711     }
2712
2713     for my $component (@comps) {
2714         my $instance = $class->components->{ $component } = $class->setup_component($component);
2715         my @expanded_components = $instance->can('expand_modules')
2716             ? $instance->expand_modules( $component, $config )
2717             : $class->expand_component_module( $component, $config );
2718         for my $component (@expanded_components) {
2719             next if $comps{$component};
2720             $class->components->{ $component } = $class->setup_component($component);
2721         }
2722     }
2723 }
2724
2725 =head2 $c->locate_components( $setup_component_config )
2726
2727 This method is meant to provide a list of component modules that should be
2728 setup for the application.  By default, it will use L<Module::Pluggable>.
2729
2730 Specify a C<setup_components> config option to pass additional options directly
2731 to L<Module::Pluggable>. To add additional search paths, specify a key named
2732 C<search_extra> as an array reference. Items in the array beginning with C<::>
2733 will have the application class name prepended to them.
2734
2735 =cut
2736
2737 sub locate_components {
2738     my $class  = shift;
2739     my $config = shift;
2740
2741     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
2742     my $extra   = delete $config->{ search_extra } || [];
2743
2744     unshift @paths, @$extra;
2745
2746     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
2747       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
2748       %$config
2749     )->plugins } @paths;
2750
2751     return @comps;
2752 }
2753
2754 =head2 $c->expand_component_module( $component, $setup_component_config )
2755
2756 Components found by C<locate_components> will be passed to this method, which
2757 is expected to return a list of component (package) names to be set up.
2758
2759 =cut
2760
2761 sub expand_component_module {
2762     my ($class, $module) = @_;
2763     return Devel::InnerPackage::list_packages( $module );
2764 }
2765
2766 =head2 $c->setup_component
2767
2768 =cut
2769
2770 sub setup_component {
2771     my( $class, $component ) = @_;
2772
2773     unless ( $component->can( 'COMPONENT' ) ) {
2774         return $component;
2775     }
2776
2777     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2778     my $config = $class->config->{ $suffix } || {};
2779     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2780     # methods also pass it. local to avoid pointlessly shitting in config
2781     # for the debug screen, as $component is already the key name.
2782     local $config->{catalyst_component_name} = $component;
2783
2784     my $instance = eval { $component->COMPONENT( $class, $config ); };
2785
2786     if ( my $error = $@ ) {
2787         chomp $error;
2788         Catalyst::Exception->throw(
2789             message => qq/Couldn't instantiate component "$component", "$error"/
2790         );
2791     }
2792
2793     unless (blessed $instance) {
2794         my $metaclass = Moose::Util::find_meta($component);
2795         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2796         my $component_method_from = $method_meta->associated_metaclass->name;
2797         my $value = defined($instance) ? $instance : 'undef';
2798         Catalyst::Exception->throw(
2799             message =>
2800             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2801         );
2802     }
2803     return $instance;
2804 }
2805
2806 =head2 $c->setup_dispatcher
2807
2808 Sets up dispatcher.
2809
2810 =cut
2811
2812 sub setup_dispatcher {
2813     my ( $class, $dispatcher ) = @_;
2814
2815     if ($dispatcher) {
2816         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2817     }
2818
2819     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2820         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2821     }
2822
2823     unless ($dispatcher) {
2824         $dispatcher = $class->dispatcher_class;
2825     }
2826
2827     load_class($dispatcher);
2828
2829     # dispatcher instance
2830     $class->dispatcher( $dispatcher->new );
2831 }
2832
2833 =head2 $c->setup_engine
2834
2835 Sets up engine.
2836
2837 =cut
2838
2839 sub engine_class {
2840     my ($class, $requested_engine) = @_;
2841
2842     if (!$class->engine_loader || $requested_engine) {
2843         $class->engine_loader(
2844             Catalyst::EngineLoader->new({
2845                 application_name => $class,
2846                 (defined $requested_engine
2847                      ? (catalyst_engine_class => $requested_engine) : ()),
2848             }),
2849         );
2850     }
2851
2852     $class->engine_loader->catalyst_engine_class;
2853 }
2854
2855 sub setup_engine {
2856     my ($class, $requested_engine) = @_;
2857
2858     my $engine = do {
2859         my $loader = $class->engine_loader;
2860
2861         if (!$loader || $requested_engine) {
2862             $loader = Catalyst::EngineLoader->new({
2863                 application_name => $class,
2864                 (defined $requested_engine
2865                      ? (requested_engine => $requested_engine) : ()),
2866             }),
2867
2868             $class->engine_loader($loader);
2869         }
2870
2871         $loader->catalyst_engine_class;
2872     };
2873
2874     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2875     return if $class->loading_psgi_file;
2876
2877     load_class($engine);
2878
2879     if ($ENV{MOD_PERL}) {
2880         my $apache = $class->engine_loader->auto;
2881
2882         my $meta = find_meta($class);
2883         my $was_immutable = $meta->is_immutable;
2884         my %immutable_options = $meta->immutable_options;
2885         $meta->make_mutable if $was_immutable;
2886
2887         $meta->add_method(handler => sub {
2888             my $r = shift;
2889             my $psgi_app = $class->_finalized_psgi_app;
2890             $apache->call_app($r, $psgi_app);
2891         });
2892
2893         $meta->make_immutable(%immutable_options) if $was_immutable;
2894     }
2895
2896     $class->engine( $engine->new );
2897
2898     return;
2899 }
2900
2901 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2902 ## build in server support (back compat support for pre psgi port behavior).
2903 ## This is so that we don't build a new psgi app for each request when using
2904 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2905
2906 sub _finalized_psgi_app {
2907     my ($app) = @_;
2908
2909     unless ($app->_psgi_app) {
2910         my $psgi_app = $app->_setup_psgi_app;
2911         $app->_psgi_app($psgi_app);
2912     }
2913
2914     return $app->_psgi_app;
2915 }
2916
2917 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2918 ## home directory and load that and return it (just assume it is doing the
2919 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2920 ## in default_middleware and return it ( this is for backward compatibility
2921 ## with pre psgi port behavior ).
2922
2923 sub _setup_psgi_app {
2924     my ($app) = @_;
2925
2926     for my $home (Path::Class::Dir->new($app->config->{home})) {
2927         my $psgi_file = $home->file(
2928             Catalyst::Utils::appprefix($app) . '.psgi',
2929         );
2930
2931         next unless -e $psgi_file;
2932
2933         # If $psgi_file calls ->setup_engine, it's doing so to load
2934         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2935         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2936         # anyway. So set a flag (ick) that tells setup_engine not to populate
2937         # $c->engine or do any other things we might regret.
2938
2939         $app->loading_psgi_file(1);
2940         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2941         $app->loading_psgi_file(0);
2942
2943         return $psgi_app
2944             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2945
2946         warn <<"EOW";
2947 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2948
2949 Its content has been ignored. Please consult the Catalyst::Upgrading
2950 documentation on how to upgrade from Catalyst::Engine::PSGI.
2951 EOW
2952     }
2953
2954     return $app->apply_default_middlewares($app->psgi_app);
2955 }
2956
2957 =head2 $c->apply_default_middlewares
2958
2959 Adds the following L<Plack> middlewares to your application, since they are
2960 useful and commonly needed:
2961
2962 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2963 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2964 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2965 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2966 applied since this middleware is smart enough to conditionally apply itself).
2967
2968 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2969 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2970 $ENV{SCRIPT_NAME}
2971
2972 =cut
2973
2974
2975 sub apply_default_middlewares {
2976     my ($app, $psgi_app) = @_;
2977
2978     $psgi_app = Plack::Middleware::Conditional->wrap(
2979         $psgi_app,
2980         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2981         condition => sub {
2982             my ($env) = @_;
2983             return if $app->config->{ignore_frontend_proxy};
2984             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2985                 || $app->config->{using_frontend_proxy};
2986         },
2987     );
2988
2989     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2990     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2991     $psgi_app = Plack::Middleware::Conditional->wrap(
2992         $psgi_app,
2993         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2994         condition => sub {
2995             my ($env) = @_;
2996             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2997             return unless $1 < 4.23;
2998             1;
2999         },
3000     );
3001
3002     # we're applying this unconditionally as the middleware itself already makes
3003     # sure it doesn't fuck things up if it's not running under one of the right
3004     # IIS versions
3005     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3006
3007     # And another IIS issue, this time with IIS7.
3008     $psgi_app = Plack::Middleware::Conditional->wrap(
3009         $psgi_app,
3010         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3011         condition => sub {
3012             my ($env) = @_;
3013             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3014         },
3015     );
3016
3017     return $psgi_app;
3018 }
3019
3020 =head2 App->psgi_app
3021
3022 =head2 App->to_app
3023
3024 Returns a PSGI application code reference for the catalyst application
3025 C<$c>. This is the bare application without any middlewares
3026 applied. C<${myapp}.psgi> is not taken into account.
3027
3028 This is what you want to be using to retrieve the PSGI application code
3029 reference of your Catalyst application for use in F<.psgi> files.
3030
3031 =cut
3032
3033 *to_app = \&psgi_app;
3034
3035 sub psgi_app {
3036     my ($app) = @_;
3037     my $psgi = $app->engine->build_psgi_app($app);
3038     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3039 }
3040
3041 =head2 $c->setup_home
3042
3043 Sets up the home directory.
3044
3045 =cut
3046
3047 sub setup_home {
3048     my ( $class, $home ) = @_;
3049
3050     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3051         $home = $env;
3052     }
3053
3054     $home ||= Catalyst::Utils::home($class);
3055
3056     if ($home) {
3057         #I remember recently being scolded for assigning config values like this
3058         $class->config->{home} ||= $home;
3059         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3060     }
3061 }
3062
3063 =head2 $c->setup_encoding
3064
3065 Sets up the input/output encoding.  See L<ENCODING>
3066
3067 =cut
3068
3069 sub setup_encoding {
3070     my $c = shift;
3071     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3072         # Ok, so the user has explicitly said "I don't want encoding..."
3073         return;
3074     } else {
3075       my $enc = defined($c->config->{encoding}) ?
3076         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3077       $c->encoding($enc);
3078     }
3079 }
3080
3081 =head2 handle_unicode_encoding_exception
3082
3083 Hook to let you customize how encoding errors are handled.  By default
3084 we just throw an exception.  Receives a hashref of debug information.
3085 Example:
3086
3087     $c->handle_unicode_encoding_exception({
3088         param_value => $value,
3089         error_msg => $_,
3090             encoding_step => 'params',
3091         });
3092
3093 =cut
3094
3095 sub handle_unicode_encoding_exception {
3096     my ( $self, $exception_ctx ) = @_;
3097     die $exception_ctx->{error_msg};
3098 }
3099
3100 # Some unicode helpers cargo culted from the old plugin.  These could likely
3101 # be neater.
3102
3103 sub _handle_unicode_decoding {
3104     my ( $self, $value ) = @_;
3105
3106     return unless defined $value;
3107
3108     ## I think this mess is to support the old nested
3109     if ( ref $value eq 'ARRAY' ) {
3110         foreach ( @$value ) {
3111             $_ = $self->_handle_unicode_decoding($_);
3112         }
3113         return $value;
3114     }
3115     elsif ( ref $value eq 'HASH' ) {
3116         foreach (keys %$value) {
3117             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3118             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3119
3120             # If the key was encoded we now have two (the original and current so
3121             # delete the original.
3122             delete $value->{$_} if $_ ne $encoded_key;
3123         }
3124         return $value;
3125     }
3126     else {
3127         return $self->_handle_param_unicode_decoding($value);
3128     }
3129 }
3130
3131 sub _handle_param_unicode_decoding {
3132     my ( $self, $value ) = @_;
3133     return unless defined $value; # not in love with just ignoring undefs - jnap
3134
3135     my $enc = $self->encoding;
3136     return try {
3137       $enc->decode( $value, $self->_encode_check );
3138     }
3139     catch {
3140         $self->handle_unicode_encoding_exception({
3141             param_value => $value,
3142             error_msg => $_,
3143             encoding_step => 'params',
3144         });
3145     };
3146 }
3147
3148 =head2 $c->setup_log
3149
3150 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3151 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3152 log to.
3153
3154 This method also installs a C<debug> method that returns a true value into the
3155 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3156 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3157
3158 Note that if the log has already been setup, by either a previous call to
3159 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3160 that this method won't actually set up the log object.
3161
3162 =cut
3163
3164 sub setup_log {
3165     my ( $class, $levels ) = @_;
3166
3167     $levels ||= '';
3168     $levels =~ s/^\s+//;
3169     $levels =~ s/\s+$//;
3170     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3171
3172     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3173     if ( defined $env_debug ) {
3174         $levels{debug} = 1 if $env_debug; # Ugly!
3175         delete($levels{debug}) unless $env_debug;
3176     }
3177
3178     unless ( $class->log ) {
3179         $class->log( Catalyst::Log->new(keys %levels) );
3180     }
3181
3182     if ( $levels{debug} ) {
3183         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3184         $class->log->debug('Debug messages enabled');
3185     }
3186 }
3187
3188 =head2 $c->setup_plugins
3189
3190 Sets up plugins.
3191
3192 =cut
3193
3194 =head2 $c->setup_stats
3195
3196 Sets up timing statistics class.
3197
3198 =cut
3199
3200 sub setup_stats {
3201     my ( $class, $stats ) = @_;
3202
3203     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3204
3205     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3206     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3207         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3208         $class->log->debug('Statistics enabled');
3209     }
3210 }
3211
3212
3213 =head2 $c->registered_plugins
3214
3215 Returns a sorted list of the plugins which have either been stated in the
3216 import list.
3217
3218 If passed a given plugin name, it will report a boolean value indicating
3219 whether or not that plugin is loaded.  A fully qualified name is required if
3220 the plugin name does not begin with C<Catalyst::Plugin::>.
3221
3222  if ($c->registered_plugins('Some::Plugin')) {
3223      ...
3224  }
3225
3226 =cut
3227
3228 {
3229
3230     sub registered_plugins {
3231         my $proto = shift;
3232         return sort keys %{ $proto->_plugins } unless @_;
3233         my $plugin = shift;
3234         return 1 if exists $proto->_plugins->{$plugin};
3235         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3236     }
3237
3238     sub _register_plugin {
3239         my ( $proto, $plugin, $instant ) = @_;
3240         my $class = ref $proto || $proto;
3241
3242         load_class( $plugin );
3243         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3244             if $plugin->isa( 'Catalyst::Component' );
3245         my $plugin_meta = Moose::Meta::Class->create($plugin);
3246         if (!$plugin_meta->has_method('new')
3247             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3248             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3249         }
3250         if (!$instant && !$proto->_plugins->{$plugin}) {
3251             my $meta = Class::MOP::get_metaclass_by_name($class);
3252             $meta->superclasses($plugin, $meta->superclasses);
3253         }
3254         $proto->_plugins->{$plugin} = 1;
3255         return $class;
3256     }
3257
3258     sub _default_plugins { return qw() }
3259
3260     sub setup_plugins {
3261         my ( $class, $plugins ) = @_;
3262
3263         $class->_plugins( {} ) unless $class->_plugins;
3264         $plugins = [ grep {
3265             m/Unicode::Encoding/ ? do {
3266                 $class->log->warn(
3267                     'Unicode::Encoding plugin is auto-applied,'
3268                     . ' please remove this from your appclass'
3269                     . ' and make sure to define "encoding" config'
3270                 );
3271                 unless (exists $class->config->{'encoding'}) {
3272                   $class->config->{'encoding'} = 'UTF-8';
3273                 }
3274                 () }
3275                 : $_
3276         } @$plugins ];
3277         push @$plugins, $class->_default_plugins;
3278         $plugins = Data::OptList::mkopt($plugins || []);
3279
3280         my @plugins = map {
3281             [ Catalyst::Utils::resolve_namespace(
3282                   $class . '::Plugin',
3283                   'Catalyst::Plugin', $_->[0]
3284               ),
3285               $_->[1],
3286             ]
3287          } @{ $plugins };
3288
3289         for my $plugin ( reverse @plugins ) {
3290             load_class($plugin->[0], $plugin->[1]);
3291             my $meta = find_meta($plugin->[0]);
3292             next if $meta && $meta->isa('Moose::Meta::Role');
3293
3294             $class->_register_plugin($plugin->[0]);
3295         }
3296
3297         my @roles =
3298             map  { $_->[0]->name, $_->[1] }
3299             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3300             map  { [find_meta($_->[0]), $_->[1]] }
3301             @plugins;
3302
3303         Moose::Util::apply_all_roles(
3304             $class => @roles
3305         ) if @roles;
3306     }
3307 }
3308
3309 =head2 registered_middlewares
3310
3311 Read only accessor that returns an array of all the middleware in the order
3312 that they were added (which is the REVERSE of the order they will be applied).
3313
3314 The values returned will be either instances of L<Plack::Middleware> or of a
3315 compatible interface, or a coderef, which is assumed to be inlined middleware
3316
3317 =head2 setup_middleware (?@middleware)
3318
3319 Read configuration information stored in configuration key C<psgi_middleware> or
3320 from passed @args.
3321
3322 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3323 to use it to enable L<Plack::Middleware>
3324
3325 This method is automatically called during 'setup' of your application, so
3326 you really don't need to invoke it.  However you may do so if you find the idea
3327 of loading middleware via configuration weird :).  For example:
3328
3329     package MyApp;
3330
3331     use Catalyst;
3332
3333     __PACKAGE__->setup_middleware('Head');
3334     __PACKAGE__->setup;
3335
3336 When we read middleware definitions from configuration, we reverse the list
3337 which sounds odd but is likely how you expect it to work if you have prior
3338 experience with L<Plack::Builder> or if you previously used the plugin
3339 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3340
3341 So basically your middleware handles an incoming request from the first
3342 registered middleware, down and handles the response from the last middleware
3343 up.
3344
3345 =cut
3346
3347 sub registered_middlewares {
3348     my $class = shift;
3349     if(my $middleware = $class->_psgi_middleware) {
3350         return (
3351           Catalyst::Middleware::Stash->new,
3352           Plack::Middleware::HTTPExceptions->new,
3353           Plack::Middleware::RemoveRedundantBody->new,
3354           Plack::Middleware::FixMissingBodyInRedirect->new,
3355           Plack::Middleware::ContentLength->new,
3356           Plack::Middleware::MethodOverride->new,
3357           Plack::Middleware::Head->new,
3358           @$middleware);
3359     } else {
3360         die "You cannot call ->registered_middlewares until middleware has been setup";
3361     }
3362 }
3363
3364 sub setup_middleware {
3365     my $class = shift;
3366     my @middleware_definitions = @_ ?
3367       reverse(@_) : reverse(@{$class->config->{'psgi_middleware'}||[]});
3368
3369     my @middleware = ();
3370     while(my $next = shift(@middleware_definitions)) {
3371         if(ref $next) {
3372             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3373                 push @middleware, $next;
3374             } elsif(ref $next eq 'CODE') {
3375                 push @middleware, $next;
3376             } elsif(ref $next eq 'HASH') {
3377                 my $namespace = shift @middleware_definitions;
3378                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3379                 push @middleware, $mw;
3380             } else {
3381               die "I can't handle middleware definition ${\ref $next}";
3382             }
3383         } else {
3384           my $mw = $class->Catalyst::Utils::build_middleware($next);
3385           push @middleware, $mw;
3386         }
3387     }
3388
3389     my @existing = @{$class->_psgi_middleware || []};
3390     $class->_psgi_middleware([@middleware,@existing,]);
3391 }
3392
3393 =head2 registered_data_handlers
3394
3395 A read only copy of registered Data Handlers returned as a Hash, where each key
3396 is a content type and each value is a subref that attempts to decode that content
3397 type.
3398
3399 =head2 setup_data_handlers (?@data_handler)
3400
3401 Read configuration information stored in configuration key C<data_handlers> or
3402 from passed @args.
3403
3404 See under L</CONFIGURATION> information regarding C<data_handlers>.
3405
3406 This method is automatically called during 'setup' of your application, so
3407 you really don't need to invoke it.
3408
3409 =head2 default_data_handlers
3410
3411 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3412 only two default data handlers, for 'application/json' and an alternative to
3413 'application/x-www-form-urlencoded' which supposed nested form parameters via
3414 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3415
3416 The 'application/json' data handler is used to parse incoming JSON into a Perl
3417 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3418 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3419 JSON decoder, and has the smallest dependency impact.
3420
3421 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3422 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3423 order to get the best performance.  You should add either to your dependency
3424 list (Makefile.PL, dist.ini, cpanfile, etc.)
3425
3426 =cut
3427
3428 sub registered_data_handlers {
3429     my $class = shift;
3430     if(my $data_handlers = $class->_data_handlers) {
3431         return %$data_handlers;
3432     } else {
3433         $class->setup_data_handlers;
3434         return $class->registered_data_handlers;
3435     }
3436 }
3437
3438 sub setup_data_handlers {
3439     my ($class, %data_handler_callbacks) = @_;
3440     %data_handler_callbacks = (
3441       %{$class->default_data_handlers},
3442       %{$class->config->{'data_handlers'}||+{}},
3443       %data_handler_callbacks);
3444
3445     $class->_data_handlers(\%data_handler_callbacks);
3446 }
3447
3448 sub default_data_handlers {
3449     my ($class) = @_;
3450     return +{
3451       'application/x-www-form-urlencoded' => sub {
3452           my ($fh, $req) = @_;
3453           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3454           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3455             ->can('build_cgi_struct')->($params);
3456       },
3457       'application/json' => sub {
3458           Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON')
3459             ->can('decode_json')->(do { local $/; $_->getline });
3460       },
3461     };
3462 }
3463
3464 =head2 $c->stack
3465
3466 Returns an arrayref of the internal execution stack (actions that are
3467 currently executing).
3468
3469 =head2 $c->stats
3470
3471 Returns the current timing statistics object. By default Catalyst uses
3472 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3473 L<< stats_class|/"$c->stats_class" >>.
3474
3475 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3476 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3477 profile explicitly, although MyApp.pm still won't profile nor output anything
3478 by itself.
3479
3480 =head2 $c->stats_class
3481
3482 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3483
3484 =head2 $c->use_stats
3485
3486 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3487
3488 Note that this is a static method, not an accessor and should be overridden
3489 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3490
3491 =cut
3492
3493 sub use_stats { 0 }
3494
3495
3496 =head2 $c->write( $data )
3497
3498 Writes $data to the output stream. When using this method directly, you
3499 will need to manually set the C<Content-Length> header to the length of
3500 your output data, if known.
3501
3502 =cut
3503
3504 sub write {
3505     my $c = shift;
3506
3507     # Finalize headers if someone manually writes output (for compat)
3508     $c->finalize_headers;
3509
3510     return $c->response->write( @_ );
3511 }
3512
3513 =head2 version
3514
3515 Returns the Catalyst version number. Mostly useful for "powered by"
3516 messages in template systems.
3517
3518 =cut
3519
3520 sub version { return $Catalyst::VERSION }
3521
3522 =head1 CONFIGURATION
3523
3524 There are a number of 'base' config variables which can be set:
3525
3526 =over
3527
3528 =item *
3529
3530 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3531
3532 =item *
3533
3534 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3535
3536 =item *
3537
3538 C<disable_component_resolution_regex_fallback> - Turns
3539 off the deprecated component resolution functionality so
3540 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3541 are called then regex search will not be attempted on string values and
3542 instead C<undef> will be returned.
3543
3544 =item *
3545
3546 C<home> - The application home directory. In an uninstalled application,
3547 this is the top level application directory. In an installed application,
3548 this will be the directory containing C<< MyApp.pm >>.
3549
3550 =item *
3551
3552 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3553
3554 =item *
3555
3556 C<name> - The name of the application in debug messages and the debug and
3557 welcome screens
3558
3559 =item *
3560
3561 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3562 until it is accessed. This allows you to (for example) check authentication (and reject
3563 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3564
3565 =item *
3566
3567 C<root> - The root directory for templates. Usually this is just a
3568 subdirectory of the home directory, but you can set it to change the
3569 templates to a different directory.
3570
3571 =item *
3572
3573 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3574 namespaces from which components will be loaded (and constructed and stored in
3575 C<< $c->components >>).
3576
3577 =item *
3578
3579 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3580 to be shown in hit debug tables in the test server.
3581
3582 =item *
3583
3584 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3585 variable should be used for determining the request path.
3586
3587 Most web server environments pass the requested path to the application using environment variables,
3588 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3589 exposed as C<< $c->request->base >>) and the request path below that base.
3590
3591 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3592 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3593
3594 =over
3595
3596 =item use_request_uri_for_path => 0
3597
3598 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3599 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3600 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3601 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3602
3603 However this method has the major disadvantage that it is impossible to correctly decode some elements
3604 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3605 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3606 can't distinguish / vs %2F in paths (in addition to other encoded values).
3607
3608 =item use_request_uri_for_path => 1
3609
3610 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3611 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3612 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3613
3614 Given that this method of path resolution is provably more correct, it is recommended that you use
3615 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3616 aware of the implications of not being able to handle encoded URI paths correctly.
3617
3618 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3619 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3620 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3621 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3622 C<< $c->request->base >> will be incorrect.
3623
3624 =back
3625
3626 =item *
3627
3628 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3629
3630 =item *
3631
3632 C<encoding> - See L</ENCODING>
3633
3634 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
3635 value to undef.
3636
3637 =item *
3638
3639 C<abort_chain_on_error_fix>
3640
3641 When there is an error in an action chain, the default behavior is to continue
3642 processing the remaining actions and then catch the error upon chain end.  This
3643 can lead to running actions when the application is in an unexpected state.  If
3644 you have this issue, setting this config value to true will promptly exit a
3645 chain when there is an error raised in any action (thus terminating the chain
3646 early.)
3647
3648 use like:
3649
3650     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3651
3652 In the future this might become the default behavior.
3653
3654 =item *
3655
3656 C<use_hash_multivalue_in_request>
3657
3658 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3659 and C<parameters> return a hashref where values might be scalar or an arrayref
3660 depending on the incoming data.  In many cases this can be undesirable as it
3661 leads one to writing defensive code like the following:
3662
3663     my ($val) = ref($c->req->parameters->{a}) ?
3664       @{$c->req->parameters->{a}} :
3665         $c->req->parameters->{a};
3666
3667 Setting this configuration item to true will make L<Catalyst> populate the
3668 attributes underlying these methods with an instance of L<Hash::MultiValue>
3669 which is used by L<Plack::Request> and others to solve this very issue.  You
3670 may prefer this behavior to the default, if so enable this option (be warned
3671 if you enable it in a legacy application we are not sure if it is completely
3672 backwardly compatible).
3673
3674 =item *
3675
3676 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3677
3678 =item *
3679
3680 C<data_handlers> - See L<DATA HANDLERS>.
3681
3682 =back
3683
3684 =head1 EXCEPTIONS
3685
3686 Generally when you throw an exception inside an Action (or somewhere in
3687 your stack, such as in a model that an Action is calling) that exception
3688 is caught by Catalyst and unless you either catch it yourself (via eval
3689 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
3690 will eventually reach L</finalize_errors> and return either the debugging
3691 error stack page, or the default error page.  However, if your exception
3692 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
3693 instead rethrow it so that it can be handled by that middleware (which
3694 is part of the default middleware).  For example this would allow
3695
3696     use HTTP::Throwable::Factory 'http_throw';
3697
3698     sub throws_exception :Local {
3699       my ($self, $c) = @_;
3700
3701       http_throw(SeeOther => { location =>
3702         $c->uri_for($self->action_for('redirect')) });
3703
3704     }
3705
3706 =head1 INTERNAL ACTIONS
3707
3708 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3709 C<_ACTION>, and C<_END>. These are by default not shown in the private
3710 action table, but you can make them visible with a config parameter.
3711
3712     MyApp->config(show_internal_actions => 1);
3713
3714 =head1 ON-DEMAND PARSER
3715
3716 The request body is usually parsed at the beginning of a request,
3717 but if you want to handle input yourself, you can enable on-demand
3718 parsing with a config parameter.
3719
3720     MyApp->config(parse_on_demand => 1);
3721
3722 =head1 PROXY SUPPORT
3723
3724 Many production servers operate using the common double-server approach,
3725 with a lightweight frontend web server passing requests to a larger
3726 backend server. An application running on the backend server must deal
3727 with two problems: the remote user always appears to be C<127.0.0.1> and
3728 the server's hostname will appear to be C<localhost> regardless of the
3729 virtual host that the user connected through.
3730
3731 Catalyst will automatically detect this situation when you are running
3732 the frontend and backend servers on the same machine. The following
3733 changes are made to the request.
3734
3735     $c->req->address is set to the user's real IP address, as read from
3736     the HTTP X-Forwarded-For header.
3737
3738     The host value for $c->req->base and $c->req->uri is set to the real
3739     host, as read from the HTTP X-Forwarded-Host header.
3740
3741 Additionally, you may be running your backend application on an insecure
3742 connection (port 80) while your frontend proxy is running under SSL.  If there
3743 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3744 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3745 be created properly.
3746
3747 In the case of passing in:
3748
3749     X-Forwarded-Port: 443
3750
3751 All calls to C<uri_for> will result in an https link, as is expected.
3752
3753 Obviously, your web server must support these headers for this to work.
3754
3755 In a more complex server farm environment where you may have your
3756 frontend proxy server(s) on different machines, you will need to set a
3757 configuration option to tell Catalyst to read the proxied data from the
3758 headers.
3759
3760     MyApp->config(using_frontend_proxy => 1);
3761
3762 If you do not wish to use the proxy support at all, you may set:
3763
3764     MyApp->config(ignore_frontend_proxy => 0);
3765
3766 =head2 Note about psgi files
3767
3768 Note that if you supply your own .psgi file, calling
3769 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3770
3771 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3772 in your psgi, for example:
3773
3774     builder {
3775         enable "Plack::Middleware::ReverseProxy";
3776         MyApp->psgi_app
3777     };
3778
3779 This will unconditionally add the ReverseProxy support, or you need to call
3780 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3781 apply the support depending upon your config).
3782
3783 See L<Catalyst::PSGI> for more information.
3784
3785 =head1 THREAD SAFETY
3786
3787 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3788 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3789 believe the Catalyst core to be thread-safe.
3790
3791 If you plan to operate in a threaded environment, remember that all other
3792 modules you are using must also be thread-safe. Some modules, most notably
3793 L<DBD::SQLite>, are not thread-safe.
3794
3795 =head1 DATA HANDLERS
3796
3797 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3798 form parameters and URL search query fields.  However it has become common
3799 for various alternative content types to be PUT or POSTed to your controllers
3800 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3801 XML and other content types when communicating with an application server.  In
3802 order to better support this use case, L<Catalyst> defines a global configuration
3803 option, C<data_handlers>, which lets you associate a content type with a coderef
3804 that parses that content type into something Perl can readily access.
3805
3806     package MyApp::Web;
3807
3808     use Catalyst;
3809     use JSON::Maybe;
3810
3811     __PACKAGE__->config(
3812       data_handlers => {
3813         'application/json' => sub { local $/; decode_json $_->getline },
3814       },
3815       ## Any other configuration.
3816     );
3817
3818     __PACKAGE__->setup;
3819
3820 By default L<Catalyst> comes with a generic JSON data handler similar to the
3821 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
3822 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
3823 it installed (if you want the faster XS parser, add it to you project Makefile.PL
3824 or dist.ini, cpanfile, etc.)
3825
3826 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
3827 (matched against the incoming request type using a regexp such as to be case
3828 insensitive) and whose values are coderefs that receive a localized version of
3829 C<$_> which is a filehandle object pointing to received body.
3830
3831 This feature is considered an early access release and we reserve the right
3832 to alter the interface in order to provide a performant and secure solution to
3833 alternative request body content.  Your reports welcomed!
3834
3835 =head1 PSGI MIDDLEWARE
3836
3837 You can define middleware, defined as L<Plack::Middleware> or a compatible
3838 interface in configuration.  Your middleware definitions are in the form of an
3839 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3840 with details to follow:
3841
3842     package MyApp::Web;
3843
3844     use Catalyst;
3845     use Plack::Middleware::StackTrace;
3846
3847     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3848
3849     __PACKAGE__->config(
3850       'psgi_middleware', [
3851         'Debug',
3852         '+MyApp::Custom',
3853         $stacktrace_middleware,
3854         'Session' => {store => 'File'},
3855         sub {
3856           my $app = shift;
3857           return sub {
3858             my $env = shift;
3859             $env->{myapp.customkey} = 'helloworld';
3860             $app->($env);
3861           },
3862         },
3863       ],
3864     );
3865
3866     __PACKAGE__->setup;
3867
3868 So the general form is:
3869
3870     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3871
3872 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3873 the order listed (to make it function similarly to L<Plack::Builder>:
3874
3875 Alternatively, you may also define middleware by calling the L</setup_middleware>
3876 package method:
3877
3878     package MyApp::Web;
3879
3880     use Catalyst;
3881
3882     __PACKAGE__->setup_middleware( \@middleware_definitions);
3883     __PACKAGE__->setup;
3884
3885 In the case where you do both (use 'setup_middleware' and configuration) the
3886 package call to setup_middleware will be applied earlier (in other words its
3887 middleware will wrap closer to the application).  Keep this in mind since in
3888 some cases the order of middleware is important.
3889
3890 The two approaches are not exclusive.
3891
3892 =over 4
3893
3894 =item Middleware Object
3895
3896 An already initialized object that conforms to the L<Plack::Middleware>
3897 specification:
3898
3899     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3900
3901     __PACKAGE__->config(
3902       'psgi_middleware', [
3903         $stacktrace_middleware,
3904       ]);
3905
3906
3907 =item coderef
3908
3909 A coderef that is an inlined middleware:
3910
3911     __PACKAGE__->config(
3912       'psgi_middleware', [
3913         sub {
3914           my $app = shift;
3915           return sub {
3916             my $env = shift;
3917             if($env->{PATH_INFO} =~m/forced/) {
3918               Plack::App::File
3919                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3920                 ->call($env);
3921             } else {
3922               return $app->($env);
3923             }
3924          },
3925       },
3926     ]);
3927
3928
3929
3930 =item a scalar
3931
3932 We assume the scalar refers to a namespace after normalizing it using the
3933 following rules:
3934
3935 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3936 is assumed to be 'as is', and we just install and use the middleware.
3937
3938 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3939 (the package name of your Catalyst application subclass), we also assume then
3940 that it is a full namespace, and use it.
3941
3942 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3943 resolve it first by looking for it under your application namespace (for example
3944 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3945 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3946 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3947 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3948 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3949 you find that a good idea.
3950
3951 Examples:
3952
3953     package MyApp::Web;
3954
3955     __PACKAGE__->config(
3956       'psgi_middleware', [
3957         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3958         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3959         '+MyApp::Custom',  ## MyApp::Custom->wrap
3960       ],
3961     );
3962
3963 =item a scalar followed by a hashref
3964
3965 Just like the previous, except the following C<HashRef> is used as arguments
3966 to initialize the middleware object.
3967
3968     __PACKAGE__->config(
3969       'psgi_middleware', [
3970          'Session' => {store => 'File'},
3971     ]);
3972
3973 =back
3974
3975 Please see L<PSGI> for more on middleware.
3976
3977 =head1 ENCODING
3978
3979 On request, decodes all params from encoding into a sequence of
3980 logical characters. On response, encodes body into encoding.
3981
3982 By default encoding is now 'UTF-8'.  You may turn it off by setting
3983 the encoding configuration to undef.
3984
3985 =head2 Methods
3986
3987 =over 4
3988
3989 =item encoding
3990
3991 Returns an instance of an C<Encode> encoding
3992
3993     print $c->encoding->name
3994
3995 =item handle_unicode_encoding_exception ($exception_context)
3996
3997 Method called when decoding process for a request fails.
3998
3999 An C<$exception_context> hashref is provided to allow you to override the
4000 behaviour of your application when given data with incorrect encodings.
4001
4002 The default method throws exceptions in the case of invalid request parameters
4003 (resulting in a 500 error), but ignores errors in upload filenames.
4004
4005 The keys passed in the C<$exception_context> hash are:
4006
4007 =over
4008
4009 =item param_value
4010
4011 The value which was not able to be decoded.
4012
4013 =item error_msg
4014
4015 The exception received from L<Encode>.
4016
4017 =item encoding_step
4018
4019 What type of data was being decoded. Valid values are (currently)
4020 C<params> - for request parameters / arguments / captures
4021 and C<uploads> - for request upload filenames.
4022
4023 =back
4024
4025 =back
4026
4027 =head1 SUPPORT
4028
4029 IRC:
4030
4031     Join #catalyst on irc.perl.org.
4032
4033 Mailing Lists:
4034
4035     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4036     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4037
4038 Web:
4039
4040     http://catalyst.perl.org
4041
4042 Wiki:
4043
4044     http://dev.catalyst.perl.org
4045
4046 =head1 SEE ALSO
4047
4048 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4049
4050 =head2 L<Catalyst::Manual> - The Catalyst Manual
4051
4052 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4053
4054 =head2 L<Catalyst::Engine> - Core engine
4055
4056 =head2 L<Catalyst::Log> - Log class.
4057
4058 =head2 L<Catalyst::Request> - Request object
4059
4060 =head2 L<Catalyst::Response> - Response object
4061
4062 =head2 L<Catalyst::Test> - The test suite.
4063
4064 =head1 PROJECT FOUNDER
4065
4066 sri: Sebastian Riedel <sri@cpan.org>
4067
4068 =head1 CONTRIBUTORS
4069
4070 abw: Andy Wardley
4071
4072 acme: Leon Brocard <leon@astray.com>
4073
4074 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4075
4076 Andrew Bramble
4077
4078 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4079
4080 Andrew Ruthven
4081
4082 andyg: Andy Grundman <andy@hybridized.org>
4083
4084 audreyt: Audrey Tang
4085
4086 bricas: Brian Cassidy <bricas@cpan.org>
4087
4088 Caelum: Rafael Kitover <rkitover@io.com>
4089
4090 chansen: Christian Hansen
4091
4092 chicks: Christopher Hicks
4093
4094 Chisel Wright C<pause@herlpacker.co.uk>
4095
4096 Danijel Milicevic C<me@danijel.de>
4097
4098 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4099
4100 David Naughton, C<naughton@umn.edu>
4101
4102 David E. Wheeler
4103
4104 dhoss: Devin Austin <dhoss@cpan.org>
4105
4106 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4107
4108 Drew Taylor
4109
4110 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4111
4112 esskar: Sascha Kiefer
4113
4114 fireartist: Carl Franks <cfranks@cpan.org>
4115
4116 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4117
4118 gabb: Danijel Milicevic
4119
4120 Gary Ashton Jones
4121
4122 Gavin Henry C<ghenry@perl.me.uk>
4123
4124 Geoff Richards
4125
4126 groditi: Guillermo Roditi <groditi@gmail.com>
4127
4128 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4129
4130 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4131
4132 jcamacho: Juan Camacho
4133
4134 jester: Jesse Sheidlower C<jester@panix.com>
4135
4136 jhannah: Jay Hannah <jay@jays.net>
4137
4138 Jody Belka
4139
4140 Johan Lindstrom
4141
4142 jon: Jon Schutz <jjschutz@cpan.org>
4143
4144 Jonathan Rockway C<< <jrockway@cpan.org> >>
4145
4146 Kieren Diment C<kd@totaldatasolution.com>
4147
4148 konobi: Scott McWhirter <konobi@cpan.org>
4149
4150 marcus: Marcus Ramberg <mramberg@cpan.org>
4151
4152 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4153
4154 mgrimes: Mark Grimes <mgrimes@cpan.org>
4155
4156 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4157
4158 mugwump: Sam Vilain
4159
4160 naughton: David Naughton
4161
4162 ningu: David Kamholz <dkamholz@cpan.org>
4163
4164 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4165
4166 numa: Dan Sully <daniel@cpan.org>
4167
4168 obra: Jesse Vincent
4169
4170 Octavian Rasnita
4171
4172 omega: Andreas Marienborg
4173
4174 Oleg Kostyuk <cub.uanic@gmail.com>
4175
4176 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4177
4178 rafl: Florian Ragwitz <rafl@debian.org>
4179
4180 random: Roland Lammel <lammel@cpan.org>
4181
4182 Robert Sedlacek C<< <rs@474.at> >>
4183
4184 SpiceMan: Marcel Montes
4185
4186 sky: Arthur Bergman
4187
4188 szbalint: Balint Szilakszi <szbalint@cpan.org>
4189
4190 t0m: Tomas Doran <bobtfish@bobtfish.net>
4191
4192 Ulf Edvinsson
4193
4194 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4195
4196 Viljo Marrandi C<vilts@yahoo.com>
4197
4198 Will Hawes C<info@whawes.co.uk>
4199
4200 willert: Sebastian Willert <willert@cpan.org>
4201
4202 wreis: Wallace Reis <wreis@cpan.org>
4203
4204 Yuval Kogman, C<nothingmuch@woobling.org>
4205
4206 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4207
4208 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4209
4210 Upasana <me@upasana.me>
4211
4212 =head1 COPYRIGHT
4213
4214 Copyright (c) 2005-2014, the above named PROJECT FOUNDER and CONTRIBUTORS.
4215
4216 =head1 LICENSE
4217
4218 This library is free software. You can redistribute it and/or modify it under
4219 the same terms as Perl itself.
4220
4221 =cut
4222
4223 no Moose;
4224
4225 __PACKAGE__->meta->make_immutable;
4226
4227 1;