lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54
  55 BEGIN { require 5.008003; }
  56
  57 has stack => (is => 'ro', default => sub { [] });
  58 has state => (is => 'rw', default => 0);
  59 has stats => (is => 'rw');
  60 has action => (is => 'rw');
  61 has counter => (is => 'rw', default => sub { {} });
  62 has request => (
  63     is => 'rw',
  64     default => sub {
  65         my $self = shift;
  66         $self->request_class->new($self->_build_request_constructor_args);
  67     },
  68     lazy => 1,
  69 );
  70 sub _build_request_constructor_args {
  71     my $self = shift;
  72     my %p = ( _log => $self->log );
  73     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  74     $p{data_handlers} = {$self->registered_data_handlers};
  75     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  76       if $self->config->{use_hash_multivalue_in_request};
  77     \%p;
  78 }
  79
  80 has response => (
  81     is => 'rw',
  82     default => sub {
  83         my $self = shift;
  84         $self->response_class->new($self->_build_response_constructor_args);
  85     },
  86     lazy => 1,
  87 );
  88 sub _build_response_constructor_args {
  89     return +{
  90       _log => $_[0]->log,
  91       encoding => $_[0]->encoding,
  92     };
  93 }
  94
  95 has namespace => (is => 'rw');
  96
  97 sub depth { scalar @{ shift->stack || [] }; }
  98 sub comp { shift->component(@_) }
  99
 100 sub req {
 101     my $self = shift; return $self->request(@_);
 102 }
 103 sub res {
 104     my $self = shift; return $self->response(@_);
 105 }
 106
 107 # For backwards compatibility
 108 sub finalize_output { shift->finalize_body(@_) };
 109
 110 # For statistics
 111 our $COUNT     = 1;
 112 our $START     = time;
 113 our $RECURSION = 1000;
 114 our $DETACH    = Catalyst::Exception::Detach->new;
 115 our $GO        = Catalyst::Exception::Go->new;
 116
 117 #I imagine that very few of these really need to be class variables. if any.
 118 #maybe we should just make them attributes with a default?
 119 __PACKAGE__->mk_classdata($_)
 120   for qw/components arguments dispatcher engine log dispatcher_class
 121   engine_loader context_class request_class response_class stats_class
 122   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 123   _data_handlers _encoding _encode_check finalized_default_middleware/;
 124
 125 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 126 __PACKAGE__->request_class('Catalyst::Request');
 127 __PACKAGE__->response_class('Catalyst::Response');
 128 __PACKAGE__->stats_class('Catalyst::Stats');
 129 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 130
 131 # Remember to update this in Catalyst::Runtime as well!
 132 our $VERSION = '5.90089_001';
 133 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 134
 135 sub import {
 136     my ( $class, @arguments ) = @_;
 137
 138     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 139     # callers @ISA.
 140     return unless $class eq 'Catalyst';
 141
 142     my $caller = caller();
 143     return if $caller eq 'main';
 144
 145     my $meta = Moose::Meta::Class->initialize($caller);
 146     unless ( $caller->isa('Catalyst') ) {
 147         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 148         $meta->superclasses(@superclasses);
 149     }
 150     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 151     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 152
 153     unless( $meta->has_method('meta') ){
 154         if ($Moose::VERSION >= 1.15) {
 155             $meta->_add_meta_method('meta');
 156         }
 157         else {
 158             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 159         }
 160     }
 161
 162     $caller->arguments( [@arguments] );
 163     $caller->setup_home;
 164 }
 165
 166 sub _application { $_[0] }
 167
 168 =encoding UTF-8
 169
 170 =head1 NAME
 171
 172 Catalyst - The Elegant MVC Web Application Framework
 173
 174 =head1 SYNOPSIS
 175
 176 See the L<Catalyst::Manual> distribution for comprehensive
 177 documentation and tutorials.
 178
 179     # Install Catalyst::Devel for helpers and other development tools
 180     # use the helper to create a new application
 181     catalyst.pl MyApp
 182
 183     # add models, views, controllers
 184     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 185     script/myapp_create.pl view MyTemplate TT
 186     script/myapp_create.pl controller Search
 187
 188     # built in testserver -- use -r to restart automatically on changes
 189     # --help to see all available options
 190     script/myapp_server.pl
 191
 192     # command line testing interface
 193     script/myapp_test.pl /yada
 194
 195     ### in lib/MyApp.pm
 196     use Catalyst qw/-Debug/; # include plugins here as well
 197
 198     ### In lib/MyApp/Controller/Root.pm (autocreated)
 199     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 200         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 201         $c->stash->{template} = 'foo.tt'; # set the template
 202         # lookup something from db -- stash vars are passed to TT
 203         $c->stash->{data} =
 204           $c->model('Database::Foo')->search( { country => $args[0] } );
 205         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 206             $c->forward( 'bar' ); # process another action
 207             # do something else after forward returns
 208         }
 209     }
 210
 211     # The foo.tt TT template can use the stash data from the database
 212     [% WHILE (item = data.next) %]
 213         [% item.foo %]
 214     [% END %]
 215
 216     # called for /bar/of/soap, /bar/of/soap/10, etc.
 217     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 218
 219     # called after all actions are finished
 220     sub end : Action {
 221         my ( $self, $c ) = @_;
 222         if ( scalar @{ $c->error } ) { ... } # handle errors
 223         return if $c->res->body; # already have a response
 224         $c->forward( 'MyApp::View::TT' ); # render template
 225     }
 226
 227 See L<Catalyst::Manual::Intro> for additional information.
 228
 229 =head1 DESCRIPTION
 230
 231 Catalyst is a modern framework for making web applications without the
 232 pain usually associated with this process. This document is a reference
 233 to the main Catalyst application. If you are a new user, we suggest you
 234 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 235
 236 See L<Catalyst::Manual> for more documentation.
 237
 238 Catalyst plugins can be loaded by naming them as arguments to the "use
 239 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 240 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 241 C<My::Module>.
 242
 243     use Catalyst qw/My::Module/;
 244
 245 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 246 fully qualify the name by using a unary plus:
 247
 248     use Catalyst qw/
 249         My::Module
 250         +Fully::Qualified::Plugin::Name
 251     /;
 252
 253 Special flags like C<-Debug> can also be specified as
 254 arguments when Catalyst is loaded:
 255
 256     use Catalyst qw/-Debug My::Module/;
 257
 258 The position of plugins and flags in the chain is important, because
 259 they are loaded in the order in which they appear.
 260
 261 The following flags are supported:
 262
 263 =head2 -Debug
 264
 265 Enables debug output. You can also force this setting from the system
 266 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 267 settings override the application, with <MYAPP>_DEBUG having the highest
 268 priority.
 269
 270 This sets the log level to 'debug' and enables full debug output on the
 271 error screen. If you only want the latter, see L<< $c->debug >>.
 272
 273 =head2 -Home
 274
 275 Forces Catalyst to use a specific home directory, e.g.:
 276
 277     use Catalyst qw[-Home=/usr/mst];
 278
 279 This can also be done in the shell environment by setting either the
 280 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 281 is replaced with the uppercased name of your application, any "::" in
 282 the name will be replaced with underscores, e.g. MyApp::Web should use
 283 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 284
 285 If none of these are set, Catalyst will attempt to automatically detect the
 286 home directory. If you are working in a development environment, Catalyst
 287 will try and find the directory containing either Makefile.PL, Build.PL,
 288 dist.ini, or cpanfile. If the application has been installed into the system
 289 (i.e. you have done C<make install>), then Catalyst will use the path to your
 290 application module, without the .pm extension (e.g., /foo/MyApp if your
 291 application was installed at /foo/MyApp.pm)
 292
 293 =head2 -Log
 294
 295     use Catalyst '-Log=warn,fatal,error';
 296
 297 Specifies a comma-delimited list of log levels.
 298
 299 =head2 -Stats
 300
 301 Enables statistics collection and reporting.
 302
 303    use Catalyst qw/-Stats=1/;
 304
 305 You can also force this setting from the system environment with CATALYST_STATS
 306 or <MYAPP>_STATS. The environment settings override the application, with
 307 <MYAPP>_STATS having the highest priority.
 308
 309 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 310
 311 =head1 METHODS
 312
 313 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 314
 315 =head2 $c->action
 316
 317 Returns a L<Catalyst::Action> object for the current action, which
 318 stringifies to the action name. See L<Catalyst::Action>.
 319
 320 =head2 $c->namespace
 321
 322 Returns the namespace of the current action, i.e., the URI prefix
 323 corresponding to the controller of the current action. For example:
 324
 325     # in Controller::Foo::Bar
 326     $c->namespace; # returns 'foo/bar';
 327
 328 =head2 $c->request
 329
 330 =head2 $c->req
 331
 332 Returns the current L<Catalyst::Request> object, giving access to
 333 information about the current client request (including parameters,
 334 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 335
 336 =head2 REQUEST FLOW HANDLING
 337
 338 =head2 $c->forward( $action [, \@arguments ] )
 339
 340 =head2 $c->forward( $class, $method, [, \@arguments ] )
 341
 342 This is one way of calling another action (method) in the same or
 343 a different controller. You can also use C<< $self->my_method($c, @args) >>
 344 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 345 in a different controller.
 346 The main difference is that 'forward' uses some of the Catalyst request
 347 cycle overhead, including debugging, which may be useful to you. On the
 348 other hand, there are some complications to using 'forward', restrictions
 349 on values returned from 'forward', and it may not handle errors as you prefer.
 350 Whether you use 'forward' or not is up to you; it is not considered superior to
 351 the other ways to call a method.
 352
 353 'forward' calls  another action, by its private name. If you give a
 354 class name but no method, C<process()> is called. You may also optionally
 355 pass arguments in an arrayref. The action will receive the arguments in
 356 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 357 C<< $c->req->args >> will be restored to the previous values.
 358
 359 Any data C<return>ed from the action forwarded to, will be returned by the
 360 call to forward.
 361
 362     my $foodata = $c->forward('/foo');
 363     $c->forward('index');
 364     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 365     $c->forward('View::TT');
 366
 367 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 368 an C<< eval { } >> around the call (actually
 369 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 370 exceptions thrown by the called action non-fatal and pushing them onto
 371 $c->error instead. If you want C<die> to propagate you need to do something
 372 like:
 373
 374     $c->forward('foo');
 375     die join "\n", @{ $c->error } if @{ $c->error };
 376
 377 Or make sure to always return true values from your actions and write
 378 your code like this:
 379
 380     $c->forward('foo') || return;
 381
 382 Another note is that C<< $c->forward >> always returns a scalar because it
 383 actually returns $c->state which operates in a scalar context.
 384 Thus, something like:
 385
 386     return @array;
 387
 388 in an action that is forwarded to is going to return a scalar,
 389 i.e. how many items are in that array, which is probably not what you want.
 390 If you need to return an array then return a reference to it,
 391 or stash it like so:
 392
 393     $c->stash->{array} = \@array;
 394
 395 and access it from the stash.
 396
 397 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 398
 399 =cut
 400
 401 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 402
 403 =head2 $c->detach( $action [, \@arguments ] )
 404
 405 =head2 $c->detach( $class, $method, [, \@arguments ] )
 406
 407 =head2 $c->detach()
 408
 409 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 410 doesn't return to the previous action when processing is finished.
 411
 412 When called with no arguments it escapes the processing chain entirely.
 413
 414 =cut
 415
 416 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 417
 418 =head2 $c->visit( $action [, \@arguments ] )
 419
 420 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 421
 422 =head2 $c->visit( $class, $method, [, \@arguments ] )
 423
 424 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 425
 426 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 427 but does a full dispatch, instead of just calling the new C<$action> /
 428 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 429 you go to are called, just like a new request.
 430
 431 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 432 This means, for example, that C<< $c->action >> methods such as
 433 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 434 L<reverse|Catalyst::Action/reverse> return information for the visited action
 435 when they are invoked within the visited action.  This is different from the
 436 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 437 continues to use the $c->action object from the caller action even when
 438 invoked from the called action.
 439
 440 C<< $c->stash >> is kept unchanged.
 441
 442 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 443 allows you to "wrap" another action, just as it would have been called by
 444 dispatching from a URL, while the analogous
 445 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 446 transfer control to another action as if it had been reached directly from a URL.
 447
 448 =cut
 449
 450 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 451
 452 =head2 $c->go( $action [, \@arguments ] )
 453
 454 =head2 $c->go( $action [, \@captures, \@arguments ] )
 455
 456 =head2 $c->go( $class, $method, [, \@arguments ] )
 457
 458 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 459
 460 The relationship between C<go> and
 461 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 462 the relationship between
 463 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 464 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 465 C<< $c->go >> will perform a full dispatch on the specified action or method,
 466 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 467 C<go> escapes the processing of the current request chain on completion, and
 468 does not return to its caller.
 469
 470 @arguments are arguments to the final destination of $action. @captures are
 471 arguments to the intermediate steps, if any, on the way to the final sub of
 472 $action.
 473
 474 =cut
 475
 476 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 477
 478 =head2 $c->response
 479
 480 =head2 $c->res
 481
 482 Returns the current L<Catalyst::Response> object, see there for details.
 483
 484 =head2 $c->stash
 485
 486 Returns a hashref to the stash, which may be used to store data and pass
 487 it between components during a request. You can also set hash keys by
 488 passing arguments. The stash is automatically sent to the view. The
 489 stash is cleared at the end of a request; it cannot be used for
 490 persistent storage (for this you must use a session; see
 491 L<Catalyst::Plugin::Session> for a complete system integrated with
 492 Catalyst).
 493
 494     $c->stash->{foo} = $bar;
 495     $c->stash( { moose => 'majestic', qux => 0 } );
 496     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 497
 498     # stash is automatically passed to the view for use in a template
 499     $c->forward( 'MyApp::View::TT' );
 500
 501 The stash hash is currently stored in the PSGI C<$env> and is managed by
 502 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 503 the stash can be accessed in sub applications mounted under your main
 504 L<Catalyst> application.  For example if you delegate the response of an
 505 action to another L<Catalyst> application, that sub application will have
 506 access to all the stash keys of the main one, and if can of course add
 507 more keys of its own.  However those new keys will not 'bubble' back up
 508 to the main application.
 509
 510 For more information the best thing to do is to review the test case:
 511 t/middleware-stash.t in the distribution /t directory.
 512
 513 =cut
 514
 515 sub stash {
 516   my $c = shift;
 517   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 518 }
 519
 520 =head2 $c->error
 521
 522 =head2 $c->error($error, ...)
 523
 524 =head2 $c->error($arrayref)
 525
 526 Returns an arrayref containing error messages.  If Catalyst encounters an
 527 error while processing a request, it stores the error in $c->error.  This
 528 method should only be used to store fatal error messages.
 529
 530     my @error = @{ $c->error };
 531
 532 Add a new error.
 533
 534     $c->error('Something bad happened');
 535
 536 Calling this will always return an arrayref (if there are no errors it
 537 will be an empty arrayref.
 538
 539 =cut
 540
 541 sub error {
 542     my $c = shift;
 543     if ( $_[0] ) {
 544         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 545         croak @$error unless ref $c;
 546         push @{ $c->{error} }, @$error;
 547     }
 548     elsif ( defined $_[0] ) { $c->{error} = undef }
 549     return $c->{error} || [];
 550 }
 551
 552
 553 =head2 $c->state
 554
 555 Contains the return value of the last executed action.
 556 Note that << $c->state >> operates in a scalar context which means that all
 557 values it returns are scalar.
 558
 559 =head2 $c->clear_errors
 560
 561 Clear errors.  You probably don't want to clear the errors unless you are
 562 implementing a custom error screen.
 563
 564 This is equivalent to running
 565
 566     $c->error(0);
 567
 568 =cut
 569
 570 sub clear_errors {
 571     my $c = shift;
 572     $c->error(0);
 573 }
 574
 575 =head2 $c->has_errors
 576
 577 Returns true if you have errors
 578
 579 =cut
 580
 581 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 582
 583 =head2 $c->last_error
 584
 585 Returns the most recent error in the stack (the one most recently added...)
 586 or nothing if there are no errors.
 587
 588 =cut
 589
 590 sub last_error { my ($err, @errs) = @{shift->error}; return $err }
 591
 592 =head2 shift_errors
 593
 594 shifts the most recently added error off the error stack and returns if.  Returns
 595 nothing if there are no more errors.
 596
 597 =cut
 598
 599 sub shift_errors {
 600     my ($self) = @_;
 601     my ($err, @errors) = @{$self->error};
 602     $self->{error} = \@errors;
 603     return $err;
 604 }
 605
 606 sub _comp_search_prefixes {
 607     my $c = shift;
 608     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 609 }
 610
 611 # search components given a name and some prefixes
 612 sub _comp_names_search_prefixes {
 613     my ( $c, $name, @prefixes ) = @_;
 614     my $appclass = ref $c || $c;
 615     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 616     $filter = qr/$filter/; # Compile regex now rather than once per loop
 617
 618     # map the original component name to the sub part that we will search against
 619     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 620         grep { /$filter/ } keys %{ $c->components };
 621
 622     # undef for a name will return all
 623     return keys %eligible if !defined $name;
 624
 625     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 626     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 627
 628     return @result if @result;
 629
 630     # if we were given a regexp to search against, we're done.
 631     return if $name->$_isa('Regexp');
 632
 633     # skip regexp fallback if configured
 634     return
 635         if $appclass->config->{disable_component_resolution_regex_fallback};
 636
 637     # regexp fallback
 638     $query  = qr/$name/i;
 639     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 640
 641     # no results? try against full names
 642     if( !@result ) {
 643         @result = grep { m{$query} } keys %eligible;
 644     }
 645
 646     # don't warn if we didn't find any results, it just might not exist
 647     if( @result ) {
 648         # Disgusting hack to work out correct method name
 649         my $warn_for = lc $prefixes[0];
 650         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 651            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 652            "component resolution is unreliable and unsafe.";
 653         my $short = $result[0];
 654         # remove the component namespace prefix
 655         $short =~ s/.*?(Model|Controller|View):://;
 656         my $shortmess = Carp::shortmess('');
 657         if ($shortmess =~ m#Catalyst/Plugin#) {
 658            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 659               "plugin's config";
 660         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 661            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 662               "component's config";
 663         } else {
 664            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 665               "but if you really wanted to search, pass in a regexp as the argument " .
 666               "like so: \$c->${warn_for}(qr/${name}/)";
 667         }
 668         $c->log->warn( "${msg}$shortmess" );
 669     }
 670
 671     return @result;
 672 }
 673
 674 # Find possible names for a prefix
 675 sub _comp_names {
 676     my ( $c, @prefixes ) = @_;
 677     my $appclass = ref $c || $c;
 678
 679     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 680
 681     my @names = map { s{$filter}{}; $_; }
 682         $c->_comp_names_search_prefixes( undef, @prefixes );
 683
 684     return @names;
 685 }
 686
 687 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 688 sub _filter_component {
 689     my ( $c, $comp, @args ) = @_;
 690
 691     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 692         return $comp->ACCEPT_CONTEXT( $c, @args );
 693     }
 694
 695     return $comp;
 696 }
 697
 698 =head2 COMPONENT ACCESSORS
 699
 700 =head2 $c->controller($name)
 701
 702 Gets a L<Catalyst::Controller> instance by name.
 703
 704     $c->controller('Foo')->do_stuff;
 705
 706 If the name is omitted, will return the controller for the dispatched
 707 action.
 708
 709 If you want to search for controllers, pass in a regexp as the argument.
 710
 711     # find all controllers that start with Foo
 712     my @foo_controllers = $c->controller(qr{^Foo});
 713
 714
 715 =cut
 716
 717 sub controller {
 718     my ( $c, $name, @args ) = @_;
 719
 720     my $appclass = ref($c) || $c;
 721     if( $name ) {
 722         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 723             my $comps = $c->components;
 724             my $check = $appclass."::Controller::".$name;
 725             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 726         }
 727         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 728         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 729         return $c->_filter_component( $result[ 0 ], @args );
 730     }
 731
 732     return $c->component( $c->action->class );
 733 }
 734
 735 =head2 $c->model($name)
 736
 737 Gets a L<Catalyst::Model> instance by name.
 738
 739     $c->model('Foo')->do_stuff;
 740
 741 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 742
 743 If the name is omitted, it will look for
 744  - a model object in $c->stash->{current_model_instance}, then
 745  - a model name in $c->stash->{current_model}, then
 746  - a config setting 'default_model', or
 747  - check if there is only one model, and return it if that's the case.
 748
 749 If you want to search for models, pass in a regexp as the argument.
 750
 751     # find all models that start with Foo
 752     my @foo_models = $c->model(qr{^Foo});
 753
 754 =cut
 755
 756 sub model {
 757     my ( $c, $name, @args ) = @_;
 758     my $appclass = ref($c) || $c;
 759     if( $name ) {
 760         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 761             my $comps = $c->components;
 762             my $check = $appclass."::Model::".$name;
 763             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 764         }
 765         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 766         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 767         return $c->_filter_component( $result[ 0 ], @args );
 768     }
 769
 770     if (ref $c) {
 771         return $c->stash->{current_model_instance}
 772           if $c->stash->{current_model_instance};
 773         return $c->model( $c->stash->{current_model} )
 774           if $c->stash->{current_model};
 775     }
 776     return $c->model( $appclass->config->{default_model} )
 777       if $appclass->config->{default_model};
 778
 779     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 780
 781     if( $rest ) {
 782         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 783         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 784         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 785         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 786         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 787     }
 788
 789     return $c->_filter_component( $comp );
 790 }
 791
 792
 793 =head2 $c->view($name)
 794
 795 Gets a L<Catalyst::View> instance by name.
 796
 797     $c->view('Foo')->do_stuff;
 798
 799 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 800
 801 If the name is omitted, it will look for
 802  - a view object in $c->stash->{current_view_instance}, then
 803  - a view name in $c->stash->{current_view}, then
 804  - a config setting 'default_view', or
 805  - check if there is only one view, and return it if that's the case.
 806
 807 If you want to search for views, pass in a regexp as the argument.
 808
 809     # find all views that start with Foo
 810     my @foo_views = $c->view(qr{^Foo});
 811
 812 =cut
 813
 814 sub view {
 815     my ( $c, $name, @args ) = @_;
 816
 817     my $appclass = ref($c) || $c;
 818     if( $name ) {
 819         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 820             my $comps = $c->components;
 821             my $check = $appclass."::View::".$name;
 822             if( exists $comps->{$check} ) {
 823                 return $c->_filter_component( $comps->{$check}, @args );
 824             }
 825             else {
 826                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 827             }
 828         }
 829         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 830         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 831         return $c->_filter_component( $result[ 0 ], @args );
 832     }
 833
 834     if (ref $c) {
 835         return $c->stash->{current_view_instance}
 836           if $c->stash->{current_view_instance};
 837         return $c->view( $c->stash->{current_view} )
 838           if $c->stash->{current_view};
 839     }
 840     return $c->view( $appclass->config->{default_view} )
 841       if $appclass->config->{default_view};
 842
 843     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 844
 845     if( $rest ) {
 846         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 847         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 848         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 849         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 850         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 851     }
 852
 853     return $c->_filter_component( $comp );
 854 }
 855
 856 =head2 $c->controllers
 857
 858 Returns the available names which can be passed to $c->controller
 859
 860 =cut
 861
 862 sub controllers {
 863     my ( $c ) = @_;
 864     return $c->_comp_names(qw/Controller C/);
 865 }
 866
 867 =head2 $c->models
 868
 869 Returns the available names which can be passed to $c->model
 870
 871 =cut
 872
 873 sub models {
 874     my ( $c ) = @_;
 875     return $c->_comp_names(qw/Model M/);
 876 }
 877
 878
 879 =head2 $c->views
 880
 881 Returns the available names which can be passed to $c->view
 882
 883 =cut
 884
 885 sub views {
 886     my ( $c ) = @_;
 887     return $c->_comp_names(qw/View V/);
 888 }
 889
 890 =head2 $c->comp($name)
 891
 892 =head2 $c->component($name)
 893
 894 Gets a component object by name. This method is not recommended,
 895 unless you want to get a specific component by full
 896 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 897 should be used instead.
 898
 899 If C<$name> is a regexp, a list of components matched against the full
 900 component name will be returned.
 901
 902 If Catalyst can't find a component by name, it will fallback to regex
 903 matching by default. To disable this behaviour set
 904 disable_component_resolution_regex_fallback to a true value.
 905
 906     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 907
 908 =cut
 909
 910 sub component {
 911     my ( $c, $name, @args ) = @_;
 912
 913     if( $name ) {
 914         my $comps = $c->components;
 915
 916         if( !ref $name ) {
 917             # is it the exact name?
 918             return $c->_filter_component( $comps->{ $name }, @args )
 919                        if exists $comps->{ $name };
 920
 921             # perhaps we just omitted "MyApp"?
 922             my $composed = ( ref $c || $c ) . "::${name}";
 923             return $c->_filter_component( $comps->{ $composed }, @args )
 924                        if exists $comps->{ $composed };
 925
 926             # search all of the models, views and controllers
 927             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 928             return $c->_filter_component( $comp, @args ) if $comp;
 929         }
 930
 931         return
 932             if $c->config->{disable_component_resolution_regex_fallback};
 933
 934         # This is here so $c->comp( '::M::' ) works
 935         my $query = ref $name ? $name : qr{$name}i;
 936
 937         my @result = grep { m{$query} } keys %{ $c->components };
 938         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 939
 940         if( $result[ 0 ] ) {
 941             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 942             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 943             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 944             return $c->_filter_component( $result[ 0 ], @args );
 945         }
 946
 947         # I would expect to return an empty list here, but that breaks back-compat
 948     }
 949
 950     # fallback
 951     return sort keys %{ $c->components };
 952 }
 953
 954 =head2 CLASS DATA AND HELPER CLASSES
 955
 956 =head2 $c->config
 957
 958 Returns or takes a hashref containing the application's configuration.
 959
 960     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 961
 962 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 963 like C<myapp.conf> in your applications home directory. See
 964 L<Catalyst::Plugin::ConfigLoader>.
 965
 966 =head3 Cascading configuration
 967
 968 The config method is present on all Catalyst components, and configuration
 969 will be merged when an application is started. Configuration loaded with
 970 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 971 followed by configuration in your top level C<MyApp> class. These two
 972 configurations are merged, and then configuration data whose hash key matches a
 973 component name is merged with configuration for that component.
 974
 975 The configuration for a component is then passed to the C<new> method when a
 976 component is constructed.
 977
 978 For example:
 979
 980     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 981     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 982
 983 will mean that C<MyApp::Model::Foo> receives the following data when
 984 constructed:
 985
 986     MyApp::Model::Foo->new({
 987         bar => 'baz',
 988         quux => 'frob',
 989         overrides => 'me',
 990     });
 991
 992 It's common practice to use a Moose attribute
 993 on the receiving component to access the config value.
 994
 995     package MyApp::Model::Foo;
 996
 997     use Moose;
 998
 999     # this attr will receive 'baz' at construction time
1000     has 'bar' => (
1001         is  => 'rw',
1002         isa => 'Str',
1003     );
1004
1005 You can then get the value 'baz' by calling $c->model('Foo')->bar
1006 (or $self->bar inside code in the model).
1007
1008 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
1009 as a way of reading config within your code, as this B<will not> give you the
1010 correctly merged config back. You B<MUST> take the config values supplied to
1011 the constructor and use those instead.
1012
1013 =cut
1014
1015 around config => sub {
1016     my $orig = shift;
1017     my $c = shift;
1018
1019     croak('Setting config after setup has been run is not allowed.')
1020         if ( @_ and $c->setup_finished );
1021
1022     $c->$orig(@_);
1023 };
1024
1025 =head2 $c->log
1026
1027 Returns the logging object instance. Unless it is already set, Catalyst
1028 sets this up with a L<Catalyst::Log> object. To use your own log class,
1029 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1030 C<< __PACKAGE__->setup >>.
1031
1032  __PACKAGE__->log( MyLogger->new );
1033  __PACKAGE__->setup;
1034
1035 And later:
1036
1037     $c->log->info( 'Now logging with my own logger!' );
1038
1039 Your log class should implement the methods described in
1040 L<Catalyst::Log>.
1041
1042 =head2 has_encoding
1043
1044 Returned True if there's a valid encoding
1045
1046 =head2 clear_encoding
1047
1048 Clears the encoding for the current context
1049
1050 =head2 encoding
1051
1052 Sets or gets the application encoding.  Setting encoding takes either an
1053 Encoding object or a string that we try to resolve via L<Encode::find_encoding>.
1054
1055 You would expect to get the encoding object back if you attempt to set it.  If
1056 there is a failure you will get undef returned and an error message in the log.
1057
1058 =cut
1059
1060 sub has_encoding { shift->encoding ? 1:0 }
1061
1062 sub clear_encoding {
1063     my $c = shift;
1064     if(blessed $c) {
1065         $c->encoding(undef);
1066     } else {
1067         $c->log->error("You can't clear encoding on the application");
1068     }
1069 }
1070
1071 sub encoding {
1072     my $c = shift;
1073     my $encoding;
1074
1075     if ( scalar @_ ) {
1076
1077         # Don't let one change this once we are too far into the response
1078         if(blessed $c && $c->res->finalized_headers) {
1079           Carp::croak("You may not change the encoding once the headers are finalized");
1080           return;
1081         }
1082
1083         # Let it be set to undef
1084         if (my $wanted = shift)  {
1085             $encoding = Encode::find_encoding($wanted)
1086               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1087             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1088         }
1089         else {
1090             binmode(STDERR);
1091         }
1092
1093         $encoding = ref $c
1094                   ? $c->{encoding} = $encoding
1095                   : $c->_encoding($encoding);
1096     } else {
1097       $encoding = ref $c && exists $c->{encoding}
1098                 ? $c->{encoding}
1099                 : $c->_encoding;
1100     }
1101
1102     return $encoding;
1103 }
1104
1105 =head2 $c->debug
1106
1107 Returns 1 if debug mode is enabled, 0 otherwise.
1108
1109 You can enable debug mode in several ways:
1110
1111 =over
1112
1113 =item By calling myapp_server.pl with the -d flag
1114
1115 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1116
1117 =item The -Debug option in your MyApp.pm
1118
1119 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1120
1121 =back
1122
1123 The first three also set the log level to 'debug'.
1124
1125 Calling C<< $c->debug(1) >> has no effect.
1126
1127 =cut
1128
1129 sub debug { 0 }
1130
1131 =head2 $c->dispatcher
1132
1133 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1134
1135 =head2 $c->engine
1136
1137 Returns the engine instance. See L<Catalyst::Engine>.
1138
1139
1140 =head2 UTILITY METHODS
1141
1142 =head2 $c->path_to(@path)
1143
1144 Merges C<@path> with C<< $c->config->{home} >> and returns a
1145 L<Path::Class::Dir> object. Note you can usually use this object as
1146 a filename, but sometimes you will have to explicitly stringify it
1147 yourself by calling the C<< ->stringify >> method.
1148
1149 For example:
1150
1151     $c->path_to( 'db', 'sqlite.db' );
1152
1153 =cut
1154
1155 sub path_to {
1156     my ( $c, @path ) = @_;
1157     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1158     if ( -d $path ) { return $path }
1159     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1160 }
1161
1162 sub plugin {
1163     my ( $class, $name, $plugin, @args ) = @_;
1164
1165     # See block comment in t/unit_core_plugin.t
1166     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1167
1168     $class->_register_plugin( $plugin, 1 );
1169
1170     eval { $plugin->import };
1171     $class->mk_classdata($name);
1172     my $obj;
1173     eval { $obj = $plugin->new(@args) };
1174
1175     if ($@) {
1176         Catalyst::Exception->throw( message =>
1177               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1178     }
1179
1180     $class->$name($obj);
1181     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1182       if $class->debug;
1183 }
1184
1185 =head2 MyApp->setup
1186
1187 Initializes the dispatcher and engine, loads any plugins, and loads the
1188 model, view, and controller components. You may also specify an array
1189 of plugins to load here, if you choose to not load them in the C<use
1190 Catalyst> line.
1191
1192     MyApp->setup;
1193     MyApp->setup( qw/-Debug/ );
1194
1195 B<Note:> You B<should not> wrap this method with method modifiers
1196 or bad things will happen - wrap the C<setup_finalize> method instead.
1197
1198 B<Note:> You can create a custom setup stage that will execute when the
1199 application is starting.  Use this to customize setup.
1200
1201     MyApp->setup(-Custom=value);
1202
1203     sub setup_custom {
1204       my ($class, $value) = @_;
1205     }
1206
1207 Can be handy if you want to hook into the setup phase.
1208
1209 =cut
1210
1211 sub setup {
1212     my ( $class, @arguments ) = @_;
1213     croak('Running setup more than once')
1214         if ( $class->setup_finished );
1215
1216     unless ( $class->isa('Catalyst') ) {
1217
1218         Catalyst::Exception->throw(
1219             message => qq/'$class' does not inherit from Catalyst/ );
1220     }
1221
1222     if ( $class->arguments ) {
1223         @arguments = ( @arguments, @{ $class->arguments } );
1224     }
1225
1226     # Process options
1227     my $flags = {};
1228
1229     foreach (@arguments) {
1230
1231         if (/^-Debug$/) {
1232             $flags->{log} =
1233               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1234         }
1235         elsif (/^-(\w+)=?(.*)$/) {
1236             $flags->{ lc $1 } = $2;
1237         }
1238         else {
1239             push @{ $flags->{plugins} }, $_;
1240         }
1241     }
1242
1243     $class->setup_home( delete $flags->{home} );
1244
1245     $class->setup_log( delete $flags->{log} );
1246     $class->setup_plugins( delete $flags->{plugins} );
1247
1248     $class->setup_data_handlers();
1249     $class->setup_dispatcher( delete $flags->{dispatcher} );
1250     if (my $engine = delete $flags->{engine}) {
1251         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1252     }
1253     $class->setup_engine();
1254     $class->setup_stats( delete $flags->{stats} );
1255
1256     for my $flag ( sort keys %{$flags} ) {
1257
1258         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1259             &$code( $class, delete $flags->{$flag} );
1260         }
1261         else {
1262             $class->log->warn(qq/Unknown flag "$flag"/);
1263         }
1264     }
1265
1266     eval { require Catalyst::Devel; };
1267     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1268         $class->log->warn(<<"EOF");
1269 You are running an old script!
1270
1271   Please update by running (this will overwrite existing files):
1272     catalyst.pl -force -scripts $class
1273
1274   or (this will not overwrite existing files):
1275     catalyst.pl -scripts $class
1276
1277 EOF
1278     }
1279
1280     # Call plugins setup, this is stupid and evil.
1281     # Also screws C3 badly on 5.10, hack to avoid.
1282     {
1283         no warnings qw/redefine/;
1284         local *setup = sub { };
1285         $class->setup unless $Catalyst::__AM_RESTARTING;
1286     }
1287
1288     # If you are expecting configuration info as part of your setup, it needs
1289     # to get called here and below, since we need the above line to support
1290     # ConfigLoader based configs.
1291
1292     $class->setup_encoding();
1293     $class->setup_middleware();
1294
1295     # Initialize our data structure
1296     $class->components( {} );
1297
1298     $class->setup_components;
1299
1300     if ( $class->debug ) {
1301         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1302
1303         if (@plugins) {
1304             my $column_width = Catalyst::Utils::term_width() - 6;
1305             my $t = Text::SimpleTable->new($column_width);
1306             $t->row($_) for @plugins;
1307             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1308         }
1309
1310         my @middleware = map {
1311           ref $_ eq 'CODE' ?
1312             "Inline Coderef" :
1313               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1314                 || '')  } $class->registered_middlewares;
1315
1316         if (@middleware) {
1317             my $column_width = Catalyst::Utils::term_width() - 6;
1318             my $t = Text::SimpleTable->new($column_width);
1319             $t->row($_) for @middleware;
1320             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1321         }
1322
1323         my %dh = $class->registered_data_handlers;
1324         if (my @data_handlers = keys %dh) {
1325             my $column_width = Catalyst::Utils::term_width() - 6;
1326             my $t = Text::SimpleTable->new($column_width);
1327             $t->row($_) for @data_handlers;
1328             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1329         }
1330
1331         my $dispatcher = $class->dispatcher;
1332         my $engine     = $class->engine;
1333         my $home       = $class->config->{home};
1334
1335         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1336         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1337
1338         $home
1339           ? ( -d $home )
1340           ? $class->log->debug(qq/Found home "$home"/)
1341           : $class->log->debug(qq/Home "$home" doesn't exist/)
1342           : $class->log->debug(q/Couldn't find home/);
1343
1344         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1345         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1346         for my $comp ( sort keys %{ $class->components } ) {
1347             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1348             $t->row( $comp, $type );
1349         }
1350         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1351           if ( keys %{ $class->components } );
1352     }
1353
1354     # Add our self to components, since we are also a component
1355     if( $class->isa('Catalyst::Controller') ){
1356       $class->components->{$class} = $class;
1357     }
1358
1359     $class->setup_actions;
1360
1361     if ( $class->debug ) {
1362         my $name = $class->config->{name} || 'Application';
1363         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1364     }
1365
1366     if ($class->config->{case_sensitive}) {
1367         $class->log->warn($class . "->config->{case_sensitive} is set.");
1368         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1369     }
1370
1371     $class->setup_finalize;
1372
1373     # Flush the log for good measure (in case something turned off 'autoflush' early)
1374     $class->log->_flush() if $class->log->can('_flush');
1375
1376     return $class || 1; # Just in case someone named their Application 0...
1377 }
1378
1379 =head2 $app->setup_finalize
1380
1381 A hook to attach modifiers to. This method does not do anything except set the
1382 C<setup_finished> accessor.
1383
1384 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1385
1386 Example:
1387
1388     after setup_finalize => sub {
1389         my $app = shift;
1390
1391         ## do stuff here..
1392     };
1393
1394 =cut
1395
1396 sub setup_finalize {
1397     my ($class) = @_;
1398     $class->setup_finished(1);
1399 }
1400
1401 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1402
1403 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1404
1405 =head2 $c->uri_for( $action, [@captures, @args], \%query_values? )
1406
1407 Constructs an absolute L<URI> object based on the application root, the
1408 provided path, and the additional arguments and query parameters provided.
1409 When used as a string, provides a textual URI.  If you need more flexibility
1410 than this (i.e. the option to provide relative URIs etc.) see
1411 L<Catalyst::Plugin::SmartURI>.
1412
1413 If no arguments are provided, the URI for the current action is returned.
1414 To return the current action and also provide @args, use
1415 C<< $c->uri_for( $c->action, @args ) >>.
1416
1417 If the first argument is a string, it is taken as a public URI path relative
1418 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1419 relative to the application root (if it does). It is then merged with
1420 C<< $c->request->base >>; any C<@args> are appended as additional path
1421 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1422
1423 If the first argument is a L<Catalyst::Action> it represents an action which
1424 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1425 optional C<\@captures> argument (an arrayref) allows passing the captured
1426 variables that are needed to fill in the paths of Chained and Regex actions;
1427 once the path is resolved, C<uri_for> continues as though a path was
1428 provided, appending any arguments or parameters and creating an absolute
1429 URI.
1430
1431 The captures for the current request can be found in
1432 C<< $c->request->captures >>, and actions can be resolved using
1433 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1434 path, use C<< $c->uri_for_action >> instead.
1435
1436   # Equivalent to $c->req->uri
1437   $c->uri_for($c->action, $c->req->captures,
1438       @{ $c->req->args }, $c->req->params);
1439
1440   # For the Foo action in the Bar controller
1441   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1442
1443   # Path to a static resource
1444   $c->uri_for('/static/images/logo.png');
1445
1446 In general the scheme of the generated URI object will follow the incoming request
1447 however if your targeted action or action chain has the Scheme attribute it will
1448 use that instead.
1449
1450 Also, if the targeted Action or Action chain declares Args/CaptureArgs that have
1451 type constraints, we will require that your proposed URL verify on those declared
1452 constraints.
1453
1454 =cut
1455
1456 sub uri_for {
1457     my ( $c, $path, @args ) = @_;
1458
1459     if ( $path->$_isa('Catalyst::Controller') ) {
1460         $path = $path->path_prefix;
1461         $path =~ s{/+\z}{};
1462         $path .= '/';
1463     }
1464
1465     undef($path) if (defined $path && $path eq '');
1466
1467     my $params =
1468       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1469
1470     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1471
1472     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1473     if ( $path->$_isa('Catalyst::Action') ) { # action object
1474         s|/|%2F|g for @args;
1475         my $captures = [ map { s|/|%2F|g; $_; }
1476                         ( scalar @args && ref $args[0] eq 'ARRAY'
1477                          ? @{ shift(@args) }
1478                          : ()) ];
1479
1480         my $action = $path;
1481         my $expanded_action = $c->dispatcher->expand_action( $action );
1482         my $num_captures = $expanded_action->number_of_captures;
1483
1484         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1485         if( !@args && $action->number_of_args ) {
1486           unshift @args, splice @$captures, $num_captures;
1487         }
1488
1489         if($num_captures) {
1490           unless($expanded_action->match_captures($c, $captures)) {
1491             carp "captures [@{$captures}] do not match the type constraints in actionchain ending with '$action'";
1492             return;
1493           }
1494         }
1495
1496         $path = $c->dispatcher->uri_for_action($action, $captures);
1497         if (not defined $path) {
1498             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1499                 if $c->debug;
1500             return undef;
1501         }
1502         $path = '/' if $path eq '';
1503
1504         # At this point @encoded_args is the remaining Args (all captures removed).
1505         if($expanded_action->has_args_constraints) {
1506           unless($expanded_action->match_args($c,\@args)) {
1507              carp "args [@args] do not match the type constraints in action '$expanded_action'";
1508              return;
1509           }
1510         }
1511     }
1512
1513     unshift(@args, $path);
1514
1515     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1516         my $namespace = $c->namespace;
1517         if (defined $path) { # cheesy hack to handle path '../foo'
1518            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1519         }
1520         unshift(@args, $namespace || '');
1521     }
1522
1523     # join args with '/', or a blank string
1524     my $args = join('/', grep { defined($_) } @args);
1525     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1526     $args =~ s!^/+!!;
1527
1528     my ($base, $class) = ('/', 'URI::_generic');
1529     if(blessed($c)) {
1530       $base = $c->req->base;
1531       if($target_action) {
1532         $target_action = $c->dispatcher->expand_action($target_action);
1533         if(my $s = $target_action->scheme) {
1534           $s = lc($s);
1535           $class = "URI::$s";
1536           $base->scheme($s);
1537         } else {
1538           $class = ref($base);
1539         }
1540       } else {
1541         $class = ref($base);
1542       }
1543
1544       $base =~ s{(?<!/)$}{/};
1545     }
1546
1547     my $query = '';
1548
1549     if (my @keys = keys %$params) {
1550       # somewhat lifted from URI::_query's query_form
1551       $query = '?'.join('&', map {
1552           my $val = $params->{$_};
1553           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1554           s/ /+/g;
1555           my $key = $_;
1556           $val = '' unless defined $val;
1557           (map {
1558               my $param = "$_";
1559               $param = encode_utf8($param);
1560               # using the URI::Escape pattern here so utf8 chars survive
1561               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1562               $param =~ s/ /+/g;
1563
1564               $key = encode_utf8($key);
1565               # using the URI::Escape pattern here so utf8 chars survive
1566               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1567               $key =~ s/ /+/g;
1568
1569               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1570       } @keys);
1571     }
1572
1573     $base = encode_utf8 $base;
1574     $base =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1575     $args = encode_utf8 $args;
1576     $args =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1577
1578     my $res = bless(\"${base}${args}${query}", $class);
1579     $res;
1580 }
1581
1582 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1583
1584 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1585
1586 =over
1587
1588 =item $path
1589
1590 A private path to the Catalyst action you want to create a URI for.
1591
1592 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1593 >> and passing the resulting C<$action> and the remaining arguments to C<<
1594 $c->uri_for >>.
1595
1596 You can also pass in a Catalyst::Action object, in which case it is passed to
1597 C<< $c->uri_for >>.
1598
1599 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1600
1601 For example, if the action looks like:
1602
1603  package MyApp::Controller::Users;
1604
1605  sub lst : Path('the-list') {}
1606
1607 You can use:
1608
1609  $c->uri_for_action('/users/lst')
1610
1611 and it will create the URI /users/the-list.
1612
1613 =item \@captures_and_args?
1614
1615 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1616 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1617 to interpolate all the parameters in the URI.
1618
1619 =item @args?
1620
1621 Optional list of extra arguments - can be supplied in the
1622 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1623 code.
1624
1625 Your action can have zero, a fixed or a variable number of args (e.g.
1626 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1627
1628 =item \%query_values?
1629
1630 Optional array reference of query parameters to append. E.g.
1631
1632   { foo => 'bar' }
1633
1634 will generate
1635
1636   /rest/of/your/uri?foo=bar
1637
1638 =back
1639
1640 =cut
1641
1642 sub uri_for_action {
1643     my ( $c, $path, @args ) = @_;
1644     my $action = blessed($path)
1645       ? $path
1646       : $c->dispatcher->get_action_by_path($path);
1647     unless (defined $action) {
1648       croak "Can't find action for path '$path'";
1649     }
1650     return $c->uri_for( $action, @args );
1651 }
1652
1653 =head2 $c->welcome_message
1654
1655 Returns the Catalyst welcome HTML page.
1656
1657 =cut
1658
1659 sub welcome_message {
1660     my $c      = shift;
1661     my $name   = $c->config->{name};
1662     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1663     my $prefix = Catalyst::Utils::appprefix( ref $c );
1664     $c->response->content_type('text/html; charset=utf-8');
1665     return <<"EOF";
1666 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1667     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1668 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1669     <head>
1670     <meta http-equiv="Content-Language" content="en" />
1671     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1672         <title>$name on Catalyst $VERSION</title>
1673         <style type="text/css">
1674             body {
1675                 color: #000;
1676                 background-color: #eee;
1677             }
1678             div#content {
1679                 width: 640px;
1680                 margin-left: auto;
1681                 margin-right: auto;
1682                 margin-top: 10px;
1683                 margin-bottom: 10px;
1684                 text-align: left;
1685                 background-color: #ccc;
1686                 border: 1px solid #aaa;
1687             }
1688             p, h1, h2 {
1689                 margin-left: 20px;
1690                 margin-right: 20px;
1691                 font-family: verdana, tahoma, sans-serif;
1692             }
1693             a {
1694                 font-family: verdana, tahoma, sans-serif;
1695             }
1696             :link, :visited {
1697                     text-decoration: none;
1698                     color: #b00;
1699                     border-bottom: 1px dotted #bbb;
1700             }
1701             :link:hover, :visited:hover {
1702                     color: #555;
1703             }
1704             div#topbar {
1705                 margin: 0px;
1706             }
1707             pre {
1708                 margin: 10px;
1709                 padding: 8px;
1710             }
1711             div#answers {
1712                 padding: 8px;
1713                 margin: 10px;
1714                 background-color: #fff;
1715                 border: 1px solid #aaa;
1716             }
1717             h1 {
1718                 font-size: 0.9em;
1719                 font-weight: normal;
1720                 text-align: center;
1721             }
1722             h2 {
1723                 font-size: 1.0em;
1724             }
1725             p {
1726                 font-size: 0.9em;
1727             }
1728             p img {
1729                 float: right;
1730                 margin-left: 10px;
1731             }
1732             span#appname {
1733                 font-weight: bold;
1734                 font-size: 1.6em;
1735             }
1736         </style>
1737     </head>
1738     <body>
1739         <div id="content">
1740             <div id="topbar">
1741                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1742                     $VERSION</h1>
1743              </div>
1744              <div id="answers">
1745                  <p>
1746                  <img src="$logo" alt="Catalyst Logo" />
1747                  </p>
1748                  <p>Welcome to the  world of Catalyst.
1749                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1750                     framework will make web development something you had
1751                     never expected it to be: Fun, rewarding, and quick.</p>
1752                  <h2>What to do now?</h2>
1753                  <p>That really depends  on what <b>you</b> want to do.
1754                     We do, however, provide you with a few starting points.</p>
1755                  <p>If you want to jump right into web development with Catalyst
1756                     you might want to start with a tutorial.</p>
1757 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1758 </pre>
1759 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1760 <pre>
1761 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1762 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1763 </code></pre>
1764                  <h2>What to do next?</h2>
1765                  <p>Next it's time to write an actual application. Use the
1766                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1767                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1768                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1769                     they can save you a lot of work.</p>
1770                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1771                     <p>Also, be sure to check out the vast and growing
1772                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1773                     you are likely to find what you need there.
1774                     </p>
1775
1776                  <h2>Need help?</h2>
1777                  <p>Catalyst has a very active community. Here are the main places to
1778                     get in touch with us.</p>
1779                  <ul>
1780                      <li>
1781                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1782                      </li>
1783                      <li>
1784                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1785                      </li>
1786                      <li>
1787                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1788                      </li>
1789                  </ul>
1790                  <h2>In conclusion</h2>
1791                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1792                     as we enjoyed making it. Please contact us if you have ideas
1793                     for improvement or other feedback.</p>
1794              </div>
1795          </div>
1796     </body>
1797 </html>
1798 EOF
1799 }
1800
1801 =head2 run_options
1802
1803 Contains a hash of options passed from the application script, including
1804 the original ARGV the script received, the processed values from that
1805 ARGV and any extra arguments to the script which were not processed.
1806
1807 This can be used to add custom options to your application's scripts
1808 and setup your application differently depending on the values of these
1809 options.
1810
1811 =head1 INTERNAL METHODS
1812
1813 These methods are not meant to be used by end users.
1814
1815 =head2 $c->components
1816
1817 Returns a hash of components.
1818
1819 =head2 $c->context_class
1820
1821 Returns or sets the context class.
1822
1823 =head2 $c->counter
1824
1825 Returns a hashref containing coderefs and execution counts (needed for
1826 deep recursion detection).
1827
1828 =head2 $c->depth
1829
1830 Returns the number of actions on the current internal execution stack.
1831
1832 =head2 $c->dispatch
1833
1834 Dispatches a request to actions.
1835
1836 =cut
1837
1838 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1839
1840 =head2 $c->dispatcher_class
1841
1842 Returns or sets the dispatcher class.
1843
1844 =head2 $c->dump_these
1845
1846 Returns a list of 2-element array references (name, structure) pairs
1847 that will be dumped on the error page in debug mode.
1848
1849 =cut
1850
1851 sub dump_these {
1852     my $c = shift;
1853     [ Request => $c->req ],
1854     [ Response => $c->res ],
1855     [ Stash => $c->stash ],
1856     [ Config => $c->config ];
1857 }
1858
1859 =head2 $c->engine_class
1860
1861 Returns or sets the engine class.
1862
1863 =head2 $c->execute( $class, $coderef )
1864
1865 Execute a coderef in given class and catch exceptions. Errors are available
1866 via $c->error.
1867
1868 =cut
1869
1870 sub execute {
1871     my ( $c, $class, $code ) = @_;
1872     $class = $c->component($class) || $class;
1873     $c->state(0);
1874
1875     if ( $c->depth >= $RECURSION ) {
1876         my $action = $code->reverse();
1877         $action = "/$action" unless $action =~ /->/;
1878         my $error = qq/Deep recursion detected calling "${action}"/;
1879         $c->log->error($error);
1880         $c->error($error);
1881         $c->state(0);
1882         return $c->state;
1883     }
1884
1885     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1886
1887     push( @{ $c->stack }, $code );
1888
1889     no warnings 'recursion';
1890     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1891     #      I have no idea how, ergo $ret (which appears to fix the issue)
1892     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1893
1894     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1895
1896     my $last = pop( @{ $c->stack } );
1897
1898     if ( my $error = $@ ) {
1899         #rethow if this can be handled by middleware
1900         if ( $c->_handle_http_exception($error) ) {
1901             foreach my $err (@{$c->error}) {
1902                 $c->log->error($err);
1903             }
1904             $c->clear_errors;
1905             $c->log->_flush if $c->log->can('_flush');
1906
1907             $error->can('rethrow') ? $error->rethrow : croak $error;
1908         }
1909         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1910             $error->rethrow if $c->depth > 1;
1911         }
1912         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1913             $error->rethrow if $c->depth > 0;
1914         }
1915         else {
1916             unless ( ref $error ) {
1917                 no warnings 'uninitialized';
1918                 chomp $error;
1919                 my $class = $last->class;
1920                 my $name  = $last->name;
1921                 $error = qq/Caught exception in $class->$name "$error"/;
1922             }
1923             $c->error($error);
1924         }
1925         $c->state(0);
1926     }
1927     return $c->state;
1928 }
1929
1930 sub _stats_start_execute {
1931     my ( $c, $code ) = @_;
1932     my $appclass = ref($c) || $c;
1933     return if ( ( $code->name =~ /^_.*/ )
1934         && ( !$appclass->config->{show_internal_actions} ) );
1935
1936     my $action_name = $code->reverse();
1937     $c->counter->{$action_name}++;
1938
1939     my $action = $action_name;
1940     $action = "/$action" unless $action =~ /->/;
1941
1942     # determine if the call was the result of a forward
1943     # this is done by walking up the call stack and looking for a calling
1944     # sub of Catalyst::forward before the eval
1945     my $callsub = q{};
1946     for my $index ( 2 .. 11 ) {
1947         last
1948         if ( ( caller($index) )[0] eq 'Catalyst'
1949             && ( caller($index) )[3] eq '(eval)' );
1950
1951         if ( ( caller($index) )[3] =~ /forward$/ ) {
1952             $callsub = ( caller($index) )[3];
1953             $action  = "-> $action";
1954             last;
1955         }
1956     }
1957
1958     my $uid = $action_name . $c->counter->{$action_name};
1959
1960     # is this a root-level call or a forwarded call?
1961     if ( $callsub =~ /forward$/ ) {
1962         my $parent = $c->stack->[-1];
1963
1964         # forward, locate the caller
1965         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1966             $c->stats->profile(
1967                 begin  => $action,
1968                 parent => "$parent" . $c->counter->{"$parent"},
1969                 uid    => $uid,
1970             );
1971         }
1972         else {
1973
1974             # forward with no caller may come from a plugin
1975             $c->stats->profile(
1976                 begin => $action,
1977                 uid   => $uid,
1978             );
1979         }
1980     }
1981     else {
1982
1983         # root-level call
1984         $c->stats->profile(
1985             begin => $action,
1986             uid   => $uid,
1987         );
1988     }
1989     return $action;
1990
1991 }
1992
1993 sub _stats_finish_execute {
1994     my ( $c, $info ) = @_;
1995     $c->stats->profile( end => $info );
1996 }
1997
1998 =head2 $c->finalize
1999
2000 Finalizes the request.
2001
2002 =cut
2003
2004 sub finalize {
2005     my $c = shift;
2006
2007     for my $error ( @{ $c->error } ) {
2008         $c->log->error($error);
2009     }
2010
2011     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
2012     # stuff like cometd and websockets
2013
2014     if($c->request->_has_io_fh) {
2015       $c->log_response;
2016       return;
2017     }
2018
2019     # Allow engine to handle finalize flow (for POE)
2020     my $engine = $c->engine;
2021     if ( my $code = $engine->can('finalize') ) {
2022         $engine->$code($c);
2023     }
2024     else {
2025
2026         $c->finalize_uploads;
2027
2028         # Error
2029         if ( $#{ $c->error } >= 0 ) {
2030             $c->finalize_error;
2031         }
2032
2033         $c->finalize_encoding;
2034         $c->finalize_headers unless $c->response->finalized_headers;
2035         $c->finalize_body;
2036     }
2037
2038     $c->log_response;
2039
2040     if ($c->use_stats) {
2041         my $elapsed = $c->stats->elapsed;
2042         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
2043         $c->log->info(
2044             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
2045     }
2046
2047     return $c->response->status;
2048 }
2049
2050 =head2 $c->finalize_body
2051
2052 Finalizes body.
2053
2054 =cut
2055
2056 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
2057
2058 =head2 $c->finalize_cookies
2059
2060 Finalizes cookies.
2061
2062 =cut
2063
2064 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
2065
2066 =head2 $c->finalize_error
2067
2068 Finalizes error.  If there is only one error in L</error> and it is an object that
2069 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2070 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2071 return the default error page (production mode).
2072
2073 =cut
2074
2075 sub finalize_error {
2076     my $c = shift;
2077     if($#{$c->error} > 0) {
2078         $c->engine->finalize_error( $c, @_ );
2079     } else {
2080         my ($error) = @{$c->error};
2081         if ( $c->_handle_http_exception($error) ) {
2082             # In the case where the error 'knows what it wants', becauses its PSGI
2083             # aware, just rethow and let middleware catch it
2084             $error->can('rethrow') ? $error->rethrow : croak $error;
2085         } else {
2086             $c->engine->finalize_error( $c, @_ )
2087         }
2088     }
2089 }
2090
2091 =head2 $c->finalize_headers
2092
2093 Finalizes headers.
2094
2095 =cut
2096
2097 sub finalize_headers {
2098     my $c = shift;
2099
2100     my $response = $c->response; #accessor calls can add up?
2101
2102     # Check if we already finalized headers
2103     return if $response->finalized_headers;
2104
2105     # Handle redirects
2106     if ( my $location = $response->redirect ) {
2107         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2108         $response->header( Location => $location );
2109     }
2110
2111     # Remove incorrectly added body and content related meta data when returning
2112     # an information response, or a response the is required to not include a body
2113
2114     $c->finalize_cookies;
2115
2116     # This currently is a NOOP but I don't want to remove it since I guess people
2117     # might have Response subclasses that use it for something... (JNAP)
2118     $c->response->finalize_headers();
2119
2120     # Done
2121     $response->finalized_headers(1);
2122 }
2123
2124 =head2 $c->finalize_encoding
2125
2126 Make sure your body is encoded properly IF you set an encoding.  By
2127 default the encoding is UTF-8 but you can disable it by explicitly setting the
2128 encoding configuration value to undef.
2129
2130 We can only encode when the body is a scalar.  Methods for encoding via the
2131 streaming interfaces (such as C<write> and C<write_fh> on L<Catalyst::Response>
2132 are available).
2133
2134 See L</ENCODING>.
2135
2136 =cut
2137
2138 sub finalize_encoding {
2139     my $c = shift;
2140     my $res = $c->res || return;
2141
2142     # Warn if the set charset is different from the one you put into encoding.  We need
2143     # to do this early since encodable_response is false for this condition and we need
2144     # to match the debug output for backcompat (there's a test for this...) -JNAP
2145     if(
2146       $res->content_type_charset and $c->encoding and
2147       (uc($c->encoding->mime_name) ne uc($res->content_type_charset))
2148     ) {
2149         my $ct = lc($res->content_type_charset);
2150         $c->log->debug("Catalyst encoding config is set to encode in '" .
2151             $c->encoding->mime_name .
2152             "', content type is '$ct', not encoding ");
2153     }
2154
2155     if(
2156       ($res->encodable_response) and
2157       (defined($res->body)) and
2158       (ref(\$res->body) eq 'SCALAR')
2159     ) {
2160         $c->res->body( $c->encoding->encode( $c->res->body, $c->_encode_check ) );
2161
2162         # Set the charset if necessary.  This might be a bit bonkers since encodable response
2163         # is false when the set charset is not the same as the encoding mimetype (maybe
2164         # confusing action at a distance here..
2165         # Don't try to set the charset if one already exists
2166         $c->res->content_type($c->res->content_type . "; charset=" . $c->encoding->mime_name)
2167           unless($c->res->content_type_charset);
2168     }
2169 }
2170
2171 =head2 $c->finalize_output
2172
2173 An alias for finalize_body.
2174
2175 =head2 $c->finalize_read
2176
2177 Finalizes the input after reading is complete.
2178
2179 =cut
2180
2181 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2182
2183 =head2 $c->finalize_uploads
2184
2185 Finalizes uploads. Cleans up any temporary files.
2186
2187 =cut
2188
2189 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2190
2191 =head2 $c->get_action( $action, $namespace )
2192
2193 Gets an action in a given namespace.
2194
2195 =cut
2196
2197 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2198
2199 =head2 $c->get_actions( $action, $namespace )
2200
2201 Gets all actions of a given name in a namespace and all parent
2202 namespaces.
2203
2204 =cut
2205
2206 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2207
2208 =head2 $app->handle_request( @arguments )
2209
2210 Called to handle each HTTP request.
2211
2212 =cut
2213
2214 sub handle_request {
2215     my ( $class, @arguments ) = @_;
2216
2217     # Always expect worst case!
2218     my $status = -1;
2219     try {
2220         if ($class->debug) {
2221             my $secs = time - $START || 1;
2222             my $av = sprintf '%.3f', $COUNT / $secs;
2223             my $time = localtime time;
2224             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2225         }
2226
2227         my $c = $class->prepare(@arguments);
2228         $c->dispatch;
2229         $status = $c->finalize;
2230     } catch {
2231         #rethow if this can be handled by middleware
2232         if ( $class->_handle_http_exception($_) ) {
2233             $_->can('rethrow') ? $_->rethrow : croak $_;
2234         }
2235         chomp(my $error = $_);
2236         $class->log->error(qq/Caught exception in engine "$error"/);
2237     };
2238
2239     $COUNT++;
2240
2241     if(my $coderef = $class->log->can('_flush')){
2242         $class->log->$coderef();
2243     }
2244     return $status;
2245 }
2246
2247 =head2 $class->prepare( @arguments )
2248
2249 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2250 etc.).
2251
2252 =cut
2253
2254 has _uploadtmp => (
2255     is => 'ro',
2256     predicate => '_has_uploadtmp',
2257 );
2258
2259 sub prepare {
2260     my ( $class, @arguments ) = @_;
2261
2262     # XXX
2263     # After the app/ctxt split, this should become an attribute based on something passed
2264     # into the application.
2265     $class->context_class( ref $class || $class ) unless $class->context_class;
2266
2267     my $uploadtmp = $class->config->{uploadtmp};
2268     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2269
2270     $c->response->_context($c);
2271
2272     #surely this is not the most efficient way to do things...
2273     $c->stats($class->stats_class->new)->enable($c->use_stats);
2274     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2275         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2276     }
2277
2278     try {
2279         # Allow engine to direct the prepare flow (for POE)
2280         if ( my $prepare = $c->engine->can('prepare') ) {
2281             $c->engine->$prepare( $c, @arguments );
2282         }
2283         else {
2284             $c->prepare_request(@arguments);
2285             $c->prepare_connection;
2286             $c->prepare_query_parameters;
2287             $c->prepare_headers; # Just hooks, no longer needed - they just
2288             $c->prepare_cookies; # cause the lazy attribute on req to build
2289             $c->prepare_path;
2290
2291             # Prepare the body for reading, either by prepare_body
2292             # or the user, if they are using $c->read
2293             $c->prepare_read;
2294
2295             # Parse the body unless the user wants it on-demand
2296             unless ( ref($c)->config->{parse_on_demand} ) {
2297                 $c->prepare_body;
2298             }
2299         }
2300         $c->prepare_action;
2301     }
2302     # VERY ugly and probably shouldn't rely on ->finalize actually working
2303     catch {
2304         # failed prepare is always due to an invalid request, right?
2305         $c->response->status(400);
2306         $c->response->content_type('text/plain');
2307         $c->response->body('Bad Request');
2308         # Note we call finalize and then die here, which escapes
2309         # finalize being called in the enclosing block..
2310         # It in fact couldn't be called, as we don't return $c..
2311         # This is a mess - but I'm unsure you can fix this without
2312         # breaking compat for people doing crazy things (we should set
2313         # the 400 and just return the ctx here IMO, letting finalize get called
2314         # above...
2315         $c->finalize;
2316         die $_;
2317     };
2318
2319     $c->log_request;
2320
2321     return $c;
2322 }
2323
2324 =head2 $c->prepare_action
2325
2326 Prepares action. See L<Catalyst::Dispatcher>.
2327
2328 =cut
2329
2330 sub prepare_action {
2331     my $c = shift;
2332     my $ret = $c->dispatcher->prepare_action( $c, @_);
2333
2334     if($c->encoding) {
2335         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2336           $_ = $c->_handle_param_unicode_decoding($_);
2337         }
2338     }
2339
2340     return $ret;
2341 }
2342
2343
2344 =head2 $c->prepare_body
2345
2346 Prepares message body.
2347
2348 =cut
2349
2350 sub prepare_body {
2351     my $c = shift;
2352
2353     return if $c->request->_has_body;
2354
2355     # Initialize on-demand data
2356     $c->engine->prepare_body( $c, @_ );
2357     $c->prepare_parameters;
2358     $c->prepare_uploads;
2359 }
2360
2361 =head2 $c->prepare_body_chunk( $chunk )
2362
2363 Prepares a chunk of data before sending it to L<HTTP::Body>.
2364
2365 See L<Catalyst::Engine>.
2366
2367 =cut
2368
2369 sub prepare_body_chunk {
2370     my $c = shift;
2371     $c->engine->prepare_body_chunk( $c, @_ );
2372 }
2373
2374 =head2 $c->prepare_body_parameters
2375
2376 Prepares body parameters.
2377
2378 =cut
2379
2380 sub prepare_body_parameters {
2381     my $c = shift;
2382     $c->request->prepare_body_parameters( $c, @_ );
2383 }
2384
2385 =head2 $c->prepare_connection
2386
2387 Prepares connection.
2388
2389 =cut
2390
2391 sub prepare_connection {
2392     my $c = shift;
2393     $c->request->prepare_connection($c);
2394 }
2395
2396 =head2 $c->prepare_cookies
2397
2398 Prepares cookies by ensuring that the attribute on the request
2399 object has been built.
2400
2401 =cut
2402
2403 sub prepare_cookies { my $c = shift; $c->request->cookies }
2404
2405 =head2 $c->prepare_headers
2406
2407 Prepares request headers by ensuring that the attribute on the request
2408 object has been built.
2409
2410 =cut
2411
2412 sub prepare_headers { my $c = shift; $c->request->headers }
2413
2414 =head2 $c->prepare_parameters
2415
2416 Prepares parameters.
2417
2418 =cut
2419
2420 sub prepare_parameters {
2421     my $c = shift;
2422     $c->prepare_body_parameters;
2423     $c->engine->prepare_parameters( $c, @_ );
2424 }
2425
2426 =head2 $c->prepare_path
2427
2428 Prepares path and base.
2429
2430 =cut
2431
2432 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2433
2434 =head2 $c->prepare_query_parameters
2435
2436 Prepares query parameters.
2437
2438 =cut
2439
2440 sub prepare_query_parameters {
2441     my $c = shift;
2442
2443     $c->engine->prepare_query_parameters( $c, @_ );
2444 }
2445
2446 =head2 $c->log_request
2447
2448 Writes information about the request to the debug logs.  This includes:
2449
2450 =over 4
2451
2452 =item * Request method, path, and remote IP address
2453
2454 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2455
2456 =item * Request parameters
2457
2458 =item * File uploads
2459
2460 =back
2461
2462 =cut
2463
2464 sub log_request {
2465     my $c = shift;
2466
2467     return unless $c->debug;
2468
2469     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2470     my $request = $dump->[1];
2471
2472     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2473     $method ||= '';
2474     $path = '/' unless length $path;
2475     $address ||= '';
2476
2477     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2478     $path = decode_utf8($path);
2479
2480     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2481
2482     $c->log_request_headers($request->headers);
2483
2484     if ( my $keywords = $request->query_keywords ) {
2485         $c->log->debug("Query keywords are: $keywords");
2486     }
2487
2488     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2489
2490     $c->log_request_uploads($request);
2491 }
2492
2493 =head2 $c->log_response
2494
2495 Writes information about the response to the debug logs by calling
2496 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2497
2498 =cut
2499
2500 sub log_response {
2501     my $c = shift;
2502
2503     return unless $c->debug;
2504
2505     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2506     my $response = $dump->[1];
2507
2508     $c->log_response_status_line($response);
2509     $c->log_response_headers($response->headers);
2510 }
2511
2512 =head2 $c->log_response_status_line($response)
2513
2514 Writes one line of information about the response to the debug logs.  This includes:
2515
2516 =over 4
2517
2518 =item * Response status code
2519
2520 =item * Content-Type header (if present)
2521
2522 =item * Content-Length header (if present)
2523
2524 =back
2525
2526 =cut
2527
2528 sub log_response_status_line {
2529     my ($c, $response) = @_;
2530
2531     $c->log->debug(
2532         sprintf(
2533             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2534             $response->status                            || 'unknown',
2535             $response->headers->header('Content-Type')   || 'unknown',
2536             $response->headers->header('Content-Length') || 'unknown'
2537         )
2538     );
2539 }
2540
2541 =head2 $c->log_response_headers($headers);
2542
2543 Hook method which can be wrapped by plugins to log the response headers.
2544 No-op in the default implementation.
2545
2546 =cut
2547
2548 sub log_response_headers {}
2549
2550 =head2 $c->log_request_parameters( query => {}, body => {} )
2551
2552 Logs request parameters to debug logs
2553
2554 =cut
2555
2556 sub log_request_parameters {
2557     my $c          = shift;
2558     my %all_params = @_;
2559
2560     return unless $c->debug;
2561
2562     my $column_width = Catalyst::Utils::term_width() - 44;
2563     foreach my $type (qw(query body)) {
2564         my $params = $all_params{$type};
2565         next if ! keys %$params;
2566         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2567         for my $key ( sort keys %$params ) {
2568             my $param = $params->{$key};
2569             my $value = defined($param) ? $param : '';
2570             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2571         }
2572         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2573     }
2574 }
2575
2576 =head2 $c->log_request_uploads
2577
2578 Logs file uploads included in the request to the debug logs.
2579 The parameter name, filename, file type, and file size are all included in
2580 the debug logs.
2581
2582 =cut
2583
2584 sub log_request_uploads {
2585     my $c = shift;
2586     my $request = shift;
2587     return unless $c->debug;
2588     my $uploads = $request->uploads;
2589     if ( keys %$uploads ) {
2590         my $t = Text::SimpleTable->new(
2591             [ 12, 'Parameter' ],
2592             [ 26, 'Filename' ],
2593             [ 18, 'Type' ],
2594             [ 9,  'Size' ]
2595         );
2596         for my $key ( sort keys %$uploads ) {
2597             my $upload = $uploads->{$key};
2598             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2599                 $t->row( $key, $u->filename, $u->type, $u->size );
2600             }
2601         }
2602         $c->log->debug( "File Uploads are:\n" . $t->draw );
2603     }
2604 }
2605
2606 =head2 $c->log_request_headers($headers);
2607
2608 Hook method which can be wrapped by plugins to log the request headers.
2609 No-op in the default implementation.
2610
2611 =cut
2612
2613 sub log_request_headers {}
2614
2615 =head2 $c->log_headers($type => $headers)
2616
2617 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2618
2619 =cut
2620
2621 sub log_headers {
2622     my $c       = shift;
2623     my $type    = shift;
2624     my $headers = shift;    # an HTTP::Headers instance
2625
2626     return unless $c->debug;
2627
2628     my $column_width = Catalyst::Utils::term_width() - 28;
2629     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2630     $headers->scan(
2631         sub {
2632             my ( $name, $value ) = @_;
2633             $t->row( $name, $value );
2634         }
2635     );
2636     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2637 }
2638
2639
2640 =head2 $c->prepare_read
2641
2642 Prepares the input for reading.
2643
2644 =cut
2645
2646 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2647
2648 =head2 $c->prepare_request
2649
2650 Prepares the engine request.
2651
2652 =cut
2653
2654 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2655
2656 =head2 $c->prepare_uploads
2657
2658 Prepares uploads.
2659
2660 =cut
2661
2662 sub prepare_uploads {
2663     my $c = shift;
2664     $c->engine->prepare_uploads( $c, @_ );
2665 }
2666
2667 =head2 $c->prepare_write
2668
2669 Prepares the output for writing.
2670
2671 =cut
2672
2673 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2674
2675 =head2 $c->request_class
2676
2677 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2678
2679 =head2 $c->response_class
2680
2681 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2682
2683 =head2 $c->read( [$maxlength] )
2684
2685 Reads a chunk of data from the request body. This method is designed to
2686 be used in a while loop, reading C<$maxlength> bytes on every call.
2687 C<$maxlength> defaults to the size of the request if not specified.
2688
2689 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2690 directly.
2691
2692 Warning: If you use read(), Catalyst will not process the body,
2693 so you will not be able to access POST parameters or file uploads via
2694 $c->request.  You must handle all body parsing yourself.
2695
2696 =cut
2697
2698 sub read { my $c = shift; return $c->request->read( @_ ) }
2699
2700 =head2 $c->run
2701
2702 Starts the engine.
2703
2704 =cut
2705
2706 sub run {
2707   my $app = shift;
2708   $app->_make_immutable_if_needed;
2709   $app->engine_loader->needs_psgi_engine_compat_hack ?
2710     $app->engine->run($app, @_) :
2711       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2712 }
2713
2714 sub _make_immutable_if_needed {
2715     my $class = shift;
2716     my $meta = find_meta($class);
2717     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2718     if (
2719         $meta->is_immutable
2720         && ! { $meta->immutable_options }->{replace_constructor}
2721         && $isa_ca
2722     ) {
2723         warn("You made your application class ($class) immutable, "
2724             . "but did not inline the\nconstructor. "
2725             . "This will break catalyst, as your app \@ISA "
2726             . "Class::Accessor(::Fast)?\nPlease pass "
2727             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2728     }
2729     unless ($meta->is_immutable) {
2730         # XXX - FIXME warning here as you should make your app immutable yourself.
2731         $meta->make_immutable(
2732             replace_constructor => 1,
2733         );
2734     }
2735 }
2736
2737 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2738
2739 Sets an action in a given namespace.
2740
2741 =cut
2742
2743 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2744
2745 =head2 $c->setup_actions($component)
2746
2747 Sets up actions for a component.
2748
2749 =cut
2750
2751 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2752
2753 =head2 $c->setup_components
2754
2755 This method is called internally to set up the application's components.
2756
2757 It finds modules by calling the L<locate_components> method, expands them to
2758 package names with the L<expand_component_module> method, and then installs
2759 each component into the application.
2760
2761 The C<setup_components> config option is passed to both of the above methods.
2762
2763 Installation of each component is performed by the L<setup_component> method,
2764 below.
2765
2766 =cut
2767
2768 sub setup_components {
2769     my $class = shift;
2770
2771     my $config  = $class->config->{ setup_components };
2772
2773     my @comps = $class->locate_components($config);
2774     my %comps = map { $_ => 1 } @comps;
2775
2776     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2777     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2778         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2779     ) if $deprecatedcatalyst_component_names;
2780
2781     for my $component ( @comps ) {
2782
2783         # We pass ignore_loaded here so that overlay files for (e.g.)
2784         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2785         # we know M::P::O found a file on disk so this is safe
2786
2787         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2788     }
2789
2790     for my $component (@comps) {
2791         my $instance = $class->components->{ $component } = $class->setup_component($component);
2792         my @expanded_components = $instance->can('expand_modules')
2793             ? $instance->expand_modules( $component, $config )
2794             : $class->expand_component_module( $component, $config );
2795         for my $component (@expanded_components) {
2796             next if $comps{$component};
2797             $class->components->{ $component } = $class->setup_component($component);
2798         }
2799     }
2800 }
2801
2802 =head2 $c->locate_components( $setup_component_config )
2803
2804 This method is meant to provide a list of component modules that should be
2805 setup for the application.  By default, it will use L<Module::Pluggable>.
2806
2807 Specify a C<setup_components> config option to pass additional options directly
2808 to L<Module::Pluggable>. To add additional search paths, specify a key named
2809 C<search_extra> as an array reference. Items in the array beginning with C<::>
2810 will have the application class name prepended to them.
2811
2812 =cut
2813
2814 sub locate_components {
2815     my $class  = shift;
2816     my $config = shift;
2817
2818     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
2819     my $extra   = delete $config->{ search_extra } || [];
2820
2821     unshift @paths, @$extra;
2822
2823     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
2824       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
2825       %$config
2826     )->plugins } @paths;
2827
2828     return @comps;
2829 }
2830
2831 =head2 $c->expand_component_module( $component, $setup_component_config )
2832
2833 Components found by C<locate_components> will be passed to this method, which
2834 is expected to return a list of component (package) names to be set up.
2835
2836 =cut
2837
2838 sub expand_component_module {
2839     my ($class, $module) = @_;
2840     return Devel::InnerPackage::list_packages( $module );
2841 }
2842
2843 =head2 $c->setup_component
2844
2845 =cut
2846
2847 sub setup_component {
2848     my( $class, $component ) = @_;
2849
2850     unless ( $component->can( 'COMPONENT' ) ) {
2851         return $component;
2852     }
2853
2854     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2855     my $config = $class->config->{ $suffix } || {};
2856     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2857     # methods also pass it. local to avoid pointlessly shitting in config
2858     # for the debug screen, as $component is already the key name.
2859     local $config->{catalyst_component_name} = $component;
2860
2861     my $instance = eval { $component->COMPONENT( $class, $config ); };
2862
2863     if ( my $error = $@ ) {
2864         chomp $error;
2865         Catalyst::Exception->throw(
2866             message => qq/Couldn't instantiate component "$component", "$error"/
2867         );
2868     }
2869
2870     unless (blessed $instance) {
2871         my $metaclass = Moose::Util::find_meta($component);
2872         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2873         my $component_method_from = $method_meta->associated_metaclass->name;
2874         my $value = defined($instance) ? $instance : 'undef';
2875         Catalyst::Exception->throw(
2876             message =>
2877             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2878         );
2879     }
2880     return $instance;
2881 }
2882
2883 =head2 $c->setup_dispatcher
2884
2885 Sets up dispatcher.
2886
2887 =cut
2888
2889 sub setup_dispatcher {
2890     my ( $class, $dispatcher ) = @_;
2891
2892     if ($dispatcher) {
2893         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2894     }
2895
2896     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2897         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2898     }
2899
2900     unless ($dispatcher) {
2901         $dispatcher = $class->dispatcher_class;
2902     }
2903
2904     load_class($dispatcher);
2905
2906     # dispatcher instance
2907     $class->dispatcher( $dispatcher->new );
2908 }
2909
2910 =head2 $c->setup_engine
2911
2912 Sets up engine.
2913
2914 =cut
2915
2916 sub engine_class {
2917     my ($class, $requested_engine) = @_;
2918
2919     if (!$class->engine_loader || $requested_engine) {
2920         $class->engine_loader(
2921             Catalyst::EngineLoader->new({
2922                 application_name => $class,
2923                 (defined $requested_engine
2924                      ? (catalyst_engine_class => $requested_engine) : ()),
2925             }),
2926         );
2927     }
2928
2929     $class->engine_loader->catalyst_engine_class;
2930 }
2931
2932 sub setup_engine {
2933     my ($class, $requested_engine) = @_;
2934
2935     my $engine = do {
2936         my $loader = $class->engine_loader;
2937
2938         if (!$loader || $requested_engine) {
2939             $loader = Catalyst::EngineLoader->new({
2940                 application_name => $class,
2941                 (defined $requested_engine
2942                      ? (requested_engine => $requested_engine) : ()),
2943             }),
2944
2945             $class->engine_loader($loader);
2946         }
2947
2948         $loader->catalyst_engine_class;
2949     };
2950
2951     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2952     return if $class->loading_psgi_file;
2953
2954     load_class($engine);
2955
2956     if ($ENV{MOD_PERL}) {
2957         my $apache = $class->engine_loader->auto;
2958
2959         my $meta = find_meta($class);
2960         my $was_immutable = $meta->is_immutable;
2961         my %immutable_options = $meta->immutable_options;
2962         $meta->make_mutable if $was_immutable;
2963
2964         $meta->add_method(handler => sub {
2965             my $r = shift;
2966             my $psgi_app = $class->_finalized_psgi_app;
2967             $apache->call_app($r, $psgi_app);
2968         });
2969
2970         $meta->make_immutable(%immutable_options) if $was_immutable;
2971     }
2972
2973     $class->engine( $engine->new );
2974
2975     return;
2976 }
2977
2978 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2979 ## build in server support (back compat support for pre psgi port behavior).
2980 ## This is so that we don't build a new psgi app for each request when using
2981 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2982
2983 sub _finalized_psgi_app {
2984     my ($app) = @_;
2985
2986     unless ($app->_psgi_app) {
2987         my $psgi_app = $app->_setup_psgi_app;
2988         $app->_psgi_app($psgi_app);
2989     }
2990
2991     return $app->_psgi_app;
2992 }
2993
2994 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2995 ## home directory and load that and return it (just assume it is doing the
2996 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2997 ## in default_middleware and return it ( this is for backward compatibility
2998 ## with pre psgi port behavior ).
2999
3000 sub _setup_psgi_app {
3001     my ($app) = @_;
3002
3003     for my $home (Path::Class::Dir->new($app->config->{home})) {
3004         my $psgi_file = $home->file(
3005             Catalyst::Utils::appprefix($app) . '.psgi',
3006         );
3007
3008         next unless -e $psgi_file;
3009
3010         # If $psgi_file calls ->setup_engine, it's doing so to load
3011         # Catalyst::Engine::PSGI. But if it does that, we're only going to
3012         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
3013         # anyway. So set a flag (ick) that tells setup_engine not to populate
3014         # $c->engine or do any other things we might regret.
3015
3016         $app->loading_psgi_file(1);
3017         my $psgi_app = Plack::Util::load_psgi($psgi_file);
3018         $app->loading_psgi_file(0);
3019
3020         return $psgi_app
3021             unless $app->engine_loader->needs_psgi_engine_compat_hack;
3022
3023         warn <<"EOW";
3024 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
3025
3026 Its content has been ignored. Please consult the Catalyst::Upgrading
3027 documentation on how to upgrade from Catalyst::Engine::PSGI.
3028 EOW
3029     }
3030
3031     return $app->apply_default_middlewares($app->psgi_app);
3032 }
3033
3034 =head2 $c->apply_default_middlewares
3035
3036 Adds the following L<Plack> middlewares to your application, since they are
3037 useful and commonly needed:
3038
3039 L<Plack::Middleware::LighttpdScriptNameFix> (if you are using Lighttpd),
3040 L<Plack::Middleware::IIS6ScriptNameFix> (always applied since this middleware
3041 is smart enough to conditionally apply itself).
3042
3043 We will also automatically add L<Plack::Middleware::ReverseProxy> if we notice
3044 that your HTTP $env variable C<REMOTE_ADDR> is '127.0.0.1'.  This is usually
3045 an indication that your server is running behind a proxy frontend.  However in
3046 2014 this is often not the case.  We preserve this code for backwards compatibility
3047 however I B<highly> recommend that if you are running the server behind a front
3048 end proxy that you clearly indicate so with the C<using_frontend_proxy> configuration
3049 setting to true for your environment configurations that run behind a proxy.  This
3050 way if you change your front end proxy address someday your code would inexplicably
3051 stop working as expected.
3052
3053 Additionally if we detect we are using Nginx, we add a bit of custom middleware
3054 to solve some problems with the way that server handles $ENV{PATH_INFO} and
3055 $ENV{SCRIPT_NAME}.
3056
3057 Please B<NOTE> that if you do use C<using_frontend_proxy> the middleware is now
3058 adding via C<registered_middleware> rather than this method.
3059
3060 If you are using Lighttpd or IIS6 you may wish to apply these middlewares.  In
3061 general this is no longer a common case but we have this here for backward
3062 compatibility.
3063
3064 =cut
3065
3066
3067 sub apply_default_middlewares {
3068     my ($app, $psgi_app) = @_;
3069
3070     # Don't add this conditional IF we are explicitly saying we want the
3071     # frontend proxy support.  We don't need it here since if that is the
3072     # case it will be always loaded in the default_middleware.
3073
3074     unless($app->config->{using_frontend_proxy}) {
3075       $psgi_app = Plack::Middleware::Conditional->wrap(
3076           $psgi_app,
3077           builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
3078           condition => sub {
3079               my ($env) = @_;
3080               return if $app->config->{ignore_frontend_proxy};
3081               return $env->{REMOTE_ADDR} eq '127.0.0.1';
3082           },
3083       );
3084     }
3085
3086     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3087     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3088     $psgi_app = Plack::Middleware::Conditional->wrap(
3089         $psgi_app,
3090         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3091         condition => sub {
3092             my ($env) = @_;
3093             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3094             return unless $1 < 4.23;
3095             1;
3096         },
3097     );
3098
3099     # we're applying this unconditionally as the middleware itself already makes
3100     # sure it doesn't fuck things up if it's not running under one of the right
3101     # IIS versions
3102     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3103
3104     # And another IIS issue, this time with IIS7.
3105     $psgi_app = Plack::Middleware::Conditional->wrap(
3106         $psgi_app,
3107         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3108         condition => sub {
3109             my ($env) = @_;
3110             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3111         },
3112     );
3113
3114     return $psgi_app;
3115 }
3116
3117 =head2 App->psgi_app
3118
3119 =head2 App->to_app
3120
3121 Returns a PSGI application code reference for the catalyst application
3122 C<$c>. This is the bare application created without the C<apply_default_middlewares>
3123 method called.  We do however apply C<registered_middleware> since those are
3124 integral to how L<Catalyst> functions.  Also, unlike starting your application
3125 with a generated server script (via L<Catalyst::Devel> and C<catalyst.pl>) we do
3126 not attempt to return a valid L<PSGI> application using any existing C<${myapp}.psgi>
3127 scripts in your $HOME directory.
3128
3129 B<NOTE> C<apply_default_middlewares> was originally created when the first PSGI
3130 port was done for v5.90000.  These are middlewares that are added to achieve
3131 backward compatibility with older applications.  If you start your application
3132 using one of the supplied server scripts (generated with L<Catalyst::Devel> and
3133 the project skeleton script C<catalyst.pl>) we apply C<apply_default_middlewares>
3134 automatically.  This was done so that pre and post PSGI port applications would
3135 work the same way.
3136
3137 This is what you want to be using to retrieve the PSGI application code
3138 reference of your Catalyst application for use in a custom F<.psgi> or in your
3139 own created server modules.
3140
3141 =cut
3142
3143 *to_app = \&psgi_app;
3144
3145 sub psgi_app {
3146     my ($app) = @_;
3147     my $psgi = $app->engine->build_psgi_app($app);
3148     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3149 }
3150
3151 =head2 $c->setup_home
3152
3153 Sets up the home directory.
3154
3155 =cut
3156
3157 sub setup_home {
3158     my ( $class, $home ) = @_;
3159
3160     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3161         $home = $env;
3162     }
3163
3164     $home ||= Catalyst::Utils::home($class);
3165
3166     if ($home) {
3167         #I remember recently being scolded for assigning config values like this
3168         $class->config->{home} ||= $home;
3169         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3170     }
3171 }
3172
3173 =head2 $c->setup_encoding
3174
3175 Sets up the input/output encoding. See L<ENCODING>
3176
3177 =cut
3178
3179 sub setup_encoding {
3180     my $c = shift;
3181     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3182         # Ok, so the user has explicitly said "I don't want encoding..."
3183         return;
3184     } else {
3185       my $enc = defined($c->config->{encoding}) ?
3186         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3187       $c->encoding($enc);
3188     }
3189 }
3190
3191 =head2 handle_unicode_encoding_exception
3192
3193 Hook to let you customize how encoding errors are handled.  By default
3194 we just throw an exception.  Receives a hashref of debug information.
3195 Example:
3196
3197     $c->handle_unicode_encoding_exception({
3198         param_value => $value,
3199         error_msg => $_,
3200             encoding_step => 'params',
3201         });
3202
3203 =cut
3204
3205 sub handle_unicode_encoding_exception {
3206     my ( $self, $exception_ctx ) = @_;
3207     die $exception_ctx->{error_msg};
3208 }
3209
3210 # Some unicode helpers cargo culted from the old plugin.  These could likely
3211 # be neater.
3212
3213 sub _handle_unicode_decoding {
3214     my ( $self, $value ) = @_;
3215
3216     return unless defined $value;
3217
3218     ## I think this mess is to support the old nested
3219     if ( ref $value eq 'ARRAY' ) {
3220         foreach ( @$value ) {
3221             $_ = $self->_handle_unicode_decoding($_);
3222         }
3223         return $value;
3224     }
3225     elsif ( ref $value eq 'HASH' ) {
3226         foreach (keys %$value) {
3227             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3228             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3229
3230             # If the key was encoded we now have two (the original and current so
3231             # delete the original.
3232             delete $value->{$_} if $_ ne $encoded_key;
3233         }
3234         return $value;
3235     }
3236     else {
3237         return $self->_handle_param_unicode_decoding($value);
3238     }
3239 }
3240
3241 sub _handle_param_unicode_decoding {
3242     my ( $self, $value ) = @_;
3243     return unless defined $value; # not in love with just ignoring undefs - jnap
3244     return $value if blessed($value); #don't decode when the value is an object.
3245
3246     my $enc = $self->encoding;
3247     return try {
3248       $enc->decode( $value, $self->_encode_check );
3249     }
3250     catch {
3251         $self->handle_unicode_encoding_exception({
3252             param_value => $value,
3253             error_msg => $_,
3254             encoding_step => 'params',
3255         });
3256     };
3257 }
3258
3259 =head2 $c->setup_log
3260
3261 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3262 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3263 log to.
3264
3265 This method also installs a C<debug> method that returns a true value into the
3266 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3267 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3268
3269 Note that if the log has already been setup, by either a previous call to
3270 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3271 that this method won't actually set up the log object.
3272
3273 =cut
3274
3275 sub setup_log {
3276     my ( $class, $levels ) = @_;
3277
3278     $levels ||= '';
3279     $levels =~ s/^\s+//;
3280     $levels =~ s/\s+$//;
3281     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3282
3283     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3284     if ( defined $env_debug ) {
3285         $levels{debug} = 1 if $env_debug; # Ugly!
3286         delete($levels{debug}) unless $env_debug;
3287     }
3288
3289     unless ( $class->log ) {
3290         $class->log( Catalyst::Log->new(keys %levels) );
3291     }
3292
3293     if ( $levels{debug} ) {
3294         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3295         $class->log->debug('Debug messages enabled');
3296     }
3297 }
3298
3299 =head2 $c->setup_plugins
3300
3301 Sets up plugins.
3302
3303 =cut
3304
3305 =head2 $c->setup_stats
3306
3307 Sets up timing statistics class.
3308
3309 =cut
3310
3311 sub setup_stats {
3312     my ( $class, $stats ) = @_;
3313
3314     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3315
3316     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3317     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3318         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3319         $class->log->debug('Statistics enabled');
3320     }
3321 }
3322
3323
3324 =head2 $c->registered_plugins
3325
3326 Returns a sorted list of the plugins which have either been stated in the
3327 import list.
3328
3329 If passed a given plugin name, it will report a boolean value indicating
3330 whether or not that plugin is loaded.  A fully qualified name is required if
3331 the plugin name does not begin with C<Catalyst::Plugin::>.
3332
3333  if ($c->registered_plugins('Some::Plugin')) {
3334      ...
3335  }
3336
3337 =cut
3338
3339 {
3340
3341     sub registered_plugins {
3342         my $proto = shift;
3343         return sort keys %{ $proto->_plugins } unless @_;
3344         my $plugin = shift;
3345         return 1 if exists $proto->_plugins->{$plugin};
3346         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3347     }
3348
3349     sub _register_plugin {
3350         my ( $proto, $plugin, $instant ) = @_;
3351         my $class = ref $proto || $proto;
3352
3353         load_class( $plugin );
3354         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3355             if $plugin->isa( 'Catalyst::Component' );
3356         my $plugin_meta = Moose::Meta::Class->create($plugin);
3357         if (!$plugin_meta->has_method('new')
3358             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3359             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3360         }
3361         if (!$instant && !$proto->_plugins->{$plugin}) {
3362             my $meta = Class::MOP::get_metaclass_by_name($class);
3363             $meta->superclasses($plugin, $meta->superclasses);
3364         }
3365         $proto->_plugins->{$plugin} = 1;
3366         return $class;
3367     }
3368
3369     sub _default_plugins { return qw() }
3370
3371     sub setup_plugins {
3372         my ( $class, $plugins ) = @_;
3373
3374         $class->_plugins( {} ) unless $class->_plugins;
3375         $plugins = [ grep {
3376             m/Unicode::Encoding/ ? do {
3377                 $class->log->warn(
3378                     'Unicode::Encoding plugin is auto-applied,'
3379                     . ' please remove this from your appclass'
3380                     . ' and make sure to define "encoding" config'
3381                 );
3382                 unless (exists $class->config->{'encoding'}) {
3383                   $class->config->{'encoding'} = 'UTF-8';
3384                 }
3385                 () }
3386                 : $_
3387         } @$plugins ];
3388         push @$plugins, $class->_default_plugins;
3389         $plugins = Data::OptList::mkopt($plugins || []);
3390
3391         my @plugins = map {
3392             [ Catalyst::Utils::resolve_namespace(
3393                   $class . '::Plugin',
3394                   'Catalyst::Plugin', $_->[0]
3395               ),
3396               $_->[1],
3397             ]
3398          } @{ $plugins };
3399
3400         for my $plugin ( reverse @plugins ) {
3401             load_class($plugin->[0], $plugin->[1]);
3402             my $meta = find_meta($plugin->[0]);
3403             next if $meta && $meta->isa('Moose::Meta::Role');
3404
3405             $class->_register_plugin($plugin->[0]);
3406         }
3407
3408         my @roles =
3409             map  { $_->[0]->name, $_->[1] }
3410             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3411             map  { [find_meta($_->[0]), $_->[1]] }
3412             @plugins;
3413
3414         Moose::Util::apply_all_roles(
3415             $class => @roles
3416         ) if @roles;
3417     }
3418 }
3419
3420 =head2 default_middleware
3421
3422 Returns a list of instantiated PSGI middleware objects which is the default
3423 middleware that is active for this application (taking any configuration
3424 options into account, excluding your custom added middleware via the C<psgi_middleware>
3425 configuration option).  You can override this method if you wish to change
3426 the default middleware (although do so at risk since some middleware is vital
3427 to application function.)
3428
3429 The current default middleware list is:
3430
3431       Catalyst::Middleware::Stash
3432       Plack::Middleware::HTTPExceptions
3433       Plack::Middleware::RemoveRedundantBody
3434       Plack::Middleware::FixMissingBodyInRedirect
3435       Plack::Middleware::ContentLength
3436       Plack::Middleware::MethodOverride
3437       Plack::Middleware::Head
3438
3439 If the configuration setting C<using_frontend_proxy> is true we add:
3440
3441       Plack::Middleware::ReverseProxy
3442
3443 If the configuration setting C<using_frontend_proxy_path> is true we add:
3444
3445       Plack::Middleware::ReverseProxyPath
3446
3447 But B<NOTE> that L<Plack::Middleware::ReverseProxyPath> is not a dependency of the
3448 L<Catalyst> distribution so if you want to use this option you should add it to
3449 your project distribution file.
3450
3451 These middlewares will be added at L</setup_middleware> during the
3452 L</setup> phase of application startup.
3453
3454 =cut
3455
3456 sub default_middleware {
3457     my $class = shift;
3458     my @mw = (
3459       Catalyst::Middleware::Stash->new,
3460       Plack::Middleware::HTTPExceptions->new,
3461       Plack::Middleware::RemoveRedundantBody->new,
3462       Plack::Middleware::FixMissingBodyInRedirect->new,
3463       Plack::Middleware::ContentLength->new,
3464       Plack::Middleware::MethodOverride->new,
3465       Plack::Middleware::Head->new);
3466
3467     if($class->config->{using_frontend_proxy}) {
3468         push @mw, Plack::Middleware::ReverseProxy->new;
3469     }
3470
3471     if($class->config->{using_frontend_proxy_path}) {
3472         if(Class::Load::try_load_class('Plack::Middleware::ReverseProxyPath')) {
3473             push @mw, Plack::Middleware::ReverseProxyPath->new;
3474         } else {
3475           $class->log->error("Cannot use configuration 'using_frontend_proxy_path' because 'Plack::Middleware::ReverseProxyPath' is not installed");
3476         }
3477     }
3478
3479     return @mw;
3480 }
3481
3482 =head2 registered_middlewares
3483
3484 Read only accessor that returns an array of all the middleware in the order
3485 that they were added (which is the REVERSE of the order they will be applied).
3486
3487 The values returned will be either instances of L<Plack::Middleware> or of a
3488 compatible interface, or a coderef, which is assumed to be inlined middleware
3489
3490 =head2 setup_middleware (?@middleware)
3491
3492 Read configuration information stored in configuration key C<psgi_middleware> or
3493 from passed @args.
3494
3495 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3496 to use it to enable L<Plack::Middleware>
3497
3498 This method is automatically called during 'setup' of your application, so
3499 you really don't need to invoke it.  However you may do so if you find the idea
3500 of loading middleware via configuration weird :).  For example:
3501
3502     package MyApp;
3503
3504     use Catalyst;
3505
3506     __PACKAGE__->setup_middleware('Head');
3507     __PACKAGE__->setup;
3508
3509 When we read middleware definitions from configuration, we reverse the list
3510 which sounds odd but is likely how you expect it to work if you have prior
3511 experience with L<Plack::Builder> or if you previously used the plugin
3512 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3513
3514 So basically your middleware handles an incoming request from the first
3515 registered middleware, down and handles the response from the last middleware
3516 up.
3517
3518 =cut
3519
3520 sub registered_middlewares {
3521     my $class = shift;
3522     if(my $middleware = $class->_psgi_middleware) {
3523         my @mw = ($class->default_middleware, @$middleware);
3524
3525         if($class->config->{using_frontend_proxy}) {
3526           push @mw, Plack::Middleware::ReverseProxy->new;
3527         }
3528
3529         return @mw;
3530     } else {
3531         die "You cannot call ->registered_middlewares until middleware has been setup";
3532     }
3533 }
3534
3535 sub setup_middleware {
3536     my $class = shift;
3537     my @middleware_definitions;
3538
3539     # If someone calls this method you can add middleware with args.  However if its
3540     # called without an arg we need to setup the configuration middleware.
3541     if(@_) {
3542       @middleware_definitions = reverse(@_);
3543     } else {
3544       @middleware_definitions = reverse(@{$class->config->{'psgi_middleware'}||[]})
3545         unless $class->finalized_default_middleware;
3546       $class->finalized_default_middleware(1); # Only do this once, just in case some people call setup over and over...
3547     }
3548
3549     my @middleware = ();
3550     while(my $next = shift(@middleware_definitions)) {
3551         if(ref $next) {
3552             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3553                 push @middleware, $next;
3554             } elsif(ref $next eq 'CODE') {
3555                 push @middleware, $next;
3556             } elsif(ref $next eq 'HASH') {
3557                 my $namespace = shift @middleware_definitions;
3558                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3559                 push @middleware, $mw;
3560             } else {
3561               die "I can't handle middleware definition ${\ref $next}";
3562             }
3563         } else {
3564           my $mw = $class->Catalyst::Utils::build_middleware($next);
3565           push @middleware, $mw;
3566         }
3567     }
3568
3569     my @existing = @{$class->_psgi_middleware || []};
3570     $class->_psgi_middleware([@middleware,@existing,]);
3571 }
3572
3573 =head2 registered_data_handlers
3574
3575 A read only copy of registered Data Handlers returned as a Hash, where each key
3576 is a content type and each value is a subref that attempts to decode that content
3577 type.
3578
3579 =head2 setup_data_handlers (?@data_handler)
3580
3581 Read configuration information stored in configuration key C<data_handlers> or
3582 from passed @args.
3583
3584 See under L</CONFIGURATION> information regarding C<data_handlers>.
3585
3586 This method is automatically called during 'setup' of your application, so
3587 you really don't need to invoke it.
3588
3589 =head2 default_data_handlers
3590
3591 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3592 only two default data handlers, for 'application/json' and an alternative to
3593 'application/x-www-form-urlencoded' which supposed nested form parameters via
3594 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3595
3596 The 'application/json' data handler is used to parse incoming JSON into a Perl
3597 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3598 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3599 JSON decoder, and has the smallest dependency impact.
3600
3601 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3602 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3603 order to get the best performance.  You should add either to your dependency
3604 list (Makefile.PL, dist.ini, cpanfile, etc.)
3605
3606 =cut
3607
3608 sub registered_data_handlers {
3609     my $class = shift;
3610     if(my $data_handlers = $class->_data_handlers) {
3611         return %$data_handlers;
3612     } else {
3613         $class->setup_data_handlers;
3614         return $class->registered_data_handlers;
3615     }
3616 }
3617
3618 sub setup_data_handlers {
3619     my ($class, %data_handler_callbacks) = @_;
3620     %data_handler_callbacks = (
3621       %{$class->default_data_handlers},
3622       %{$class->config->{'data_handlers'}||+{}},
3623       %data_handler_callbacks);
3624
3625     $class->_data_handlers(\%data_handler_callbacks);
3626 }
3627
3628 sub default_data_handlers {
3629     my ($class) = @_;
3630     return +{
3631       'application/x-www-form-urlencoded' => sub {
3632           my ($fh, $req) = @_;
3633           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3634           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3635             ->can('build_cgi_struct')->($params);
3636       },
3637       'application/json' => sub {
3638           my ($fh, $req) = @_;
3639           my $parser = Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON');
3640           my $slurped;
3641           return eval {
3642             local $/;
3643             $slurped = $fh->getline;
3644             $parser->can("decode_json")->($slurped); # decode_json does utf8 decoding for us
3645           } || Catalyst::Exception->throw(sprintf "Error Parsing POST '%s', Error: %s", (defined($slurped) ? $slurped : 'undef') ,$@);
3646         },
3647     };
3648 }
3649
3650 sub _handle_http_exception {
3651     my ( $self, $error ) = @_;
3652     if (
3653            !$self->config->{always_catch_http_exceptions}
3654         && blessed $error
3655         && (
3656             $error->can('as_psgi')
3657             || (   $error->can('code')
3658                 && $error->code =~ m/^[1-5][0-9][0-9]$/ )
3659         )
3660       )
3661     {
3662         return 1;
3663     }
3664 }
3665
3666 =head2 $c->stack
3667
3668 Returns an arrayref of the internal execution stack (actions that are
3669 currently executing).
3670
3671 =head2 $c->stats
3672
3673 Returns the current timing statistics object. By default Catalyst uses
3674 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3675 L<< stats_class|/"$c->stats_class" >>.
3676
3677 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3678 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3679 profile explicitly, although MyApp.pm still won't profile nor output anything
3680 by itself.
3681
3682 =head2 $c->stats_class
3683
3684 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3685
3686 =head2 $c->use_stats
3687
3688 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3689
3690 Note that this is a static method, not an accessor and should be overridden
3691 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3692
3693 =cut
3694
3695 sub use_stats { 0 }
3696
3697
3698 =head2 $c->write( $data )
3699
3700 Writes $data to the output stream. When using this method directly, you
3701 will need to manually set the C<Content-Length> header to the length of
3702 your output data, if known.
3703
3704 =cut
3705
3706 sub write {
3707     my $c = shift;
3708
3709     # Finalize headers if someone manually writes output (for compat)
3710     $c->finalize_headers;
3711
3712     return $c->response->write( @_ );
3713 }
3714
3715 =head2 version
3716
3717 Returns the Catalyst version number. Mostly useful for "powered by"
3718 messages in template systems.
3719
3720 =cut
3721
3722 sub version { return $Catalyst::VERSION }
3723
3724 =head1 CONFIGURATION
3725
3726 There are a number of 'base' config variables which can be set:
3727
3728 =over
3729
3730 =item *
3731
3732 C<always_catch_http_exceptions> - As of version 5.90060 Catalyst
3733 rethrows errors conforming to the interface described by
3734 L<Plack::Middleware::HTTPExceptions> and lets the middleware deal with it.
3735 Set true to get the deprecated behaviour and have Catalyst catch HTTP exceptions.
3736
3737 =item *
3738
3739 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3740
3741 =item *
3742
3743 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3744
3745 =item *
3746
3747 C<disable_component_resolution_regex_fallback> - Turns
3748 off the deprecated component resolution functionality so
3749 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3750 are called then regex search will not be attempted on string values and
3751 instead C<undef> will be returned.
3752
3753 =item *
3754
3755 C<home> - The application home directory. In an uninstalled application,
3756 this is the top level application directory. In an installed application,
3757 this will be the directory containing C<< MyApp.pm >>.
3758
3759 =item *
3760
3761 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3762
3763 =item *
3764
3765 C<name> - The name of the application in debug messages and the debug and
3766 welcome screens
3767
3768 =item *
3769
3770 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3771 until it is accessed. This allows you to (for example) check authentication (and reject
3772 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3773
3774 =item *
3775
3776 C<root> - The root directory for templates. Usually this is just a
3777 subdirectory of the home directory, but you can set it to change the
3778 templates to a different directory.
3779
3780 =item *
3781
3782 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3783 namespaces from which components will be loaded (and constructed and stored in
3784 C<< $c->components >>).
3785
3786 =item *
3787
3788 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3789 to be shown in hit debug tables in the test server.
3790
3791 =item *
3792
3793 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3794 variable should be used for determining the request path.
3795
3796 Most web server environments pass the requested path to the application using environment variables,
3797 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3798 exposed as C<< $c->request->base >>) and the request path below that base.
3799
3800 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3801 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3802
3803 =over
3804
3805 =item use_request_uri_for_path => 0
3806
3807 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3808 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3809 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3810 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3811
3812 However this method has the major disadvantage that it is impossible to correctly decode some elements
3813 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3814 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3815 can't distinguish / vs %2F in paths (in addition to other encoded values).
3816
3817 =item use_request_uri_for_path => 1
3818
3819 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3820 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3821 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3822
3823 Given that this method of path resolution is provably more correct, it is recommended that you use
3824 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3825 aware of the implications of not being able to handle encoded URI paths correctly.
3826
3827 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3828 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3829 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3830 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3831 C<< $c->request->base >> will be incorrect.
3832
3833 =back
3834
3835 =item *
3836
3837 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3838
3839 =item *
3840
3841 C<using_frontend_proxy_path> - Enabled L<Plack::Middleware::ReverseProxyPath> on your application (if
3842 installed, otherwise log an error).  This is useful if your application is not running on the
3843 'root' (or /) of your host server.  B<NOTE> if you use this feature you should add the required
3844 middleware to your project dependency list since its not automatically a dependency of L<Catalyst>.
3845 This has been done since not all people need this feature and we wish to restrict the growth of
3846 L<Catalyst> dependencies.
3847
3848 =item *
3849
3850 C<encoding> - See L</ENCODING>
3851
3852 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
3853 value to undef.
3854
3855 =item *
3856
3857 C<abort_chain_on_error_fix>
3858
3859 When there is an error in an action chain, the default behavior is to continue
3860 processing the remaining actions and then catch the error upon chain end.  This
3861 can lead to running actions when the application is in an unexpected state.  If
3862 you have this issue, setting this config value to true will promptly exit a
3863 chain when there is an error raised in any action (thus terminating the chain
3864 early.)
3865
3866 use like:
3867
3868     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3869
3870 In the future this might become the default behavior.
3871
3872 =item *
3873
3874 C<use_hash_multivalue_in_request>
3875
3876 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3877 and C<parameters> return a hashref where values might be scalar or an arrayref
3878 depending on the incoming data.  In many cases this can be undesirable as it
3879 leads one to writing defensive code like the following:
3880
3881     my ($val) = ref($c->req->parameters->{a}) ?
3882       @{$c->req->parameters->{a}} :
3883         $c->req->parameters->{a};
3884
3885 Setting this configuration item to true will make L<Catalyst> populate the
3886 attributes underlying these methods with an instance of L<Hash::MultiValue>
3887 which is used by L<Plack::Request> and others to solve this very issue.  You
3888 may prefer this behavior to the default, if so enable this option (be warned
3889 if you enable it in a legacy application we are not sure if it is completely
3890 backwardly compatible).
3891
3892 =item *
3893
3894 C<skip_complex_post_part_handling>
3895
3896 When creating body parameters from a POST, if we run into a multpart POST
3897 that does not contain uploads, but instead contains inlined complex data
3898 (very uncommon) we cannot reliably convert that into field => value pairs.  So
3899 instead we create an instance of L<Catalyst::Request::PartData>.  If this causes
3900 issue for you, you can disable this by setting C<skip_complex_post_part_handling>
3901 to true (default is false).
3902
3903 =item *
3904
3905 C<skip_body_param_unicode_decoding>
3906
3907 Generally we decode incoming POST params based on your declared encoding (the
3908 default for this is to decode UTF-8).  If this is causing you trouble and you
3909 do not wish to turn all encoding support off (with the C<encoding> configuration
3910 parameter) you may disable this step atomically by setting this configuration
3911 parameter to true.
3912
3913 =item *
3914
3915 C<do_not_decode_query>
3916
3917 If true, then do not try to character decode any wide characters in your
3918 request URL query or keywords.  Most readings of the relevent specifications
3919 suggest these should be UTF-* encoded, which is the default that L<Catalyst>
3920 will use, hwoever if you are creating a lot of URLs manually or have external
3921 evil clients, this might cause you trouble.  If you find the changes introduced
3922 in Catalyst version 5.90080+ break some of your query code, you may disable
3923 the UTF-8 decoding globally using this configuration.
3924
3925 This setting takes precedence over C<default_query_encoding> and
3926 C<decode_query_using_global_encoding>
3927
3928 =item *
3929
3930 C<default_query_encoding>
3931
3932 By default we decode query and keywords in your request URL using UTF-8, which
3933 is our reading of the relevent specifications.  This setting allows one to
3934 specify a fixed value for how to decode your query.  You might need this if
3935 you are doing a lot of custom encoding of your URLs and not using UTF-8.
3936
3937 This setting take precedence over C<decode_query_using_global_encoding>.
3938
3939 =item *
3940
3941 C<decode_query_using_global_encoding>
3942
3943 Setting this to true will default your query decoding to whatever your
3944 general global encoding is (the default is UTF-8).
3945
3946 =item *
3947
3948 C<use_chained_args_0_special_case>
3949
3950 In older versions of Catalyst, when more than one action matched the same path
3951 AND all those matching actions declared Args(0), we'd break the tie by choosing
3952 the first action defined.  We now normalized how Args(0) works so that it
3953 follows the same rule as Args(N), which is to say when we need to break a tie
3954 we choose the LAST action defined.  If this breaks your code and you don't
3955 have time to update to follow the new normalized approach, you may set this
3956 value to true and it will globally revert to the original chaining behavior.
3957
3958 =item *
3959
3960 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3961
3962 =item *
3963
3964 C<data_handlers> - See L<DATA HANDLERS>.
3965
3966 =back
3967
3968 =head1 EXCEPTIONS
3969
3970 Generally when you throw an exception inside an Action (or somewhere in
3971 your stack, such as in a model that an Action is calling) that exception
3972 is caught by Catalyst and unless you either catch it yourself (via eval
3973 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
3974 will eventually reach L</finalize_errors> and return either the debugging
3975 error stack page, or the default error page.  However, if your exception
3976 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
3977 instead rethrow it so that it can be handled by that middleware (which
3978 is part of the default middleware).  For example this would allow
3979
3980     use HTTP::Throwable::Factory 'http_throw';
3981
3982     sub throws_exception :Local {
3983       my ($self, $c) = @_;
3984
3985       http_throw(SeeOther => { location =>
3986         $c->uri_for($self->action_for('redirect')) });
3987
3988     }
3989
3990 =head1 INTERNAL ACTIONS
3991
3992 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3993 C<_ACTION>, and C<_END>. These are by default not shown in the private
3994 action table, but you can make them visible with a config parameter.
3995
3996     MyApp->config(show_internal_actions => 1);
3997
3998 =head1 ON-DEMAND PARSER
3999
4000 The request body is usually parsed at the beginning of a request,
4001 but if you want to handle input yourself, you can enable on-demand
4002 parsing with a config parameter.
4003
4004     MyApp->config(parse_on_demand => 1);
4005
4006 =head1 PROXY SUPPORT
4007
4008 Many production servers operate using the common double-server approach,
4009 with a lightweight frontend web server passing requests to a larger
4010 backend server. An application running on the backend server must deal
4011 with two problems: the remote user always appears to be C<127.0.0.1> and
4012 the server's hostname will appear to be C<localhost> regardless of the
4013 virtual host that the user connected through.
4014
4015 Catalyst will automatically detect this situation when you are running
4016 the frontend and backend servers on the same machine. The following
4017 changes are made to the request.
4018
4019     $c->req->address is set to the user's real IP address, as read from
4020     the HTTP X-Forwarded-For header.
4021
4022     The host value for $c->req->base and $c->req->uri is set to the real
4023     host, as read from the HTTP X-Forwarded-Host header.
4024
4025 Additionally, you may be running your backend application on an insecure
4026 connection (port 80) while your frontend proxy is running under SSL.  If there
4027 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
4028 tell Catalyst what port the frontend listens on.  This will allow all URIs to
4029 be created properly.
4030
4031 In the case of passing in:
4032
4033     X-Forwarded-Port: 443
4034
4035 All calls to C<uri_for> will result in an https link, as is expected.
4036
4037 Obviously, your web server must support these headers for this to work.
4038
4039 In a more complex server farm environment where you may have your
4040 frontend proxy server(s) on different machines, you will need to set a
4041 configuration option to tell Catalyst to read the proxied data from the
4042 headers.
4043
4044     MyApp->config(using_frontend_proxy => 1);
4045
4046 If you do not wish to use the proxy support at all, you may set:
4047
4048     MyApp->config(ignore_frontend_proxy => 0);
4049
4050 =head2 Note about psgi files
4051
4052 Note that if you supply your own .psgi file, calling
4053 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
4054
4055 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
4056 in your psgi, for example:
4057
4058     builder {
4059         enable "Plack::Middleware::ReverseProxy";
4060         MyApp->psgi_app
4061     };
4062
4063 This will unconditionally add the ReverseProxy support, or you need to call
4064 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
4065 apply the support depending upon your config).
4066
4067 See L<Catalyst::PSGI> for more information.
4068
4069 =head1 THREAD SAFETY
4070
4071 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
4072 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
4073 believe the Catalyst core to be thread-safe.
4074
4075 If you plan to operate in a threaded environment, remember that all other
4076 modules you are using must also be thread-safe. Some modules, most notably
4077 L<DBD::SQLite>, are not thread-safe.
4078
4079 =head1 DATA HANDLERS
4080
4081 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
4082 form parameters and URL search query fields.  However it has become common
4083 for various alternative content types to be PUT or POSTed to your controllers
4084 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
4085 XML and other content types when communicating with an application server.  In
4086 order to better support this use case, L<Catalyst> defines a global configuration
4087 option, C<data_handlers>, which lets you associate a content type with a coderef
4088 that parses that content type into something Perl can readily access.
4089
4090     package MyApp::Web;
4091
4092     use Catalyst;
4093     use JSON::Maybe;
4094
4095     __PACKAGE__->config(
4096       data_handlers => {
4097         'application/json' => sub { local $/; decode_json $_->getline },
4098       },
4099       ## Any other configuration.
4100     );
4101
4102     __PACKAGE__->setup;
4103
4104 By default L<Catalyst> comes with a generic JSON data handler similar to the
4105 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
4106 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
4107 it installed (if you want the faster XS parser, add it to you project Makefile.PL
4108 or dist.ini, cpanfile, etc.)
4109
4110 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
4111 (matched against the incoming request type using a regexp such as to be case
4112 insensitive) and whose values are coderefs that receive a localized version of
4113 C<$_> which is a filehandle object pointing to received body.
4114
4115 This feature is considered an early access release and we reserve the right
4116 to alter the interface in order to provide a performant and secure solution to
4117 alternative request body content.  Your reports welcomed!
4118
4119 =head1 PSGI MIDDLEWARE
4120
4121 You can define middleware, defined as L<Plack::Middleware> or a compatible
4122 interface in configuration.  Your middleware definitions are in the form of an
4123 arrayref under the configuration key C<psgi_middleware>.  Here's an example
4124 with details to follow:
4125
4126     package MyApp::Web;
4127
4128     use Catalyst;
4129     use Plack::Middleware::StackTrace;
4130
4131     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4132
4133     __PACKAGE__->config(
4134       'psgi_middleware', [
4135         'Debug',
4136         '+MyApp::Custom',
4137         $stacktrace_middleware,
4138         'Session' => {store => 'File'},
4139         sub {
4140           my $app = shift;
4141           return sub {
4142             my $env = shift;
4143             $env->{myapp.customkey} = 'helloworld';
4144             $app->($env);
4145           },
4146         },
4147       ],
4148     );
4149
4150     __PACKAGE__->setup;
4151
4152 So the general form is:
4153
4154     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
4155
4156 Where C<@middleware> is one or more of the following, applied in the REVERSE of
4157 the order listed (to make it function similarly to L<Plack::Builder>:
4158
4159 Alternatively, you may also define middleware by calling the L</setup_middleware>
4160 package method:
4161
4162     package MyApp::Web;
4163
4164     use Catalyst;
4165
4166     __PACKAGE__->setup_middleware( \@middleware_definitions);
4167     __PACKAGE__->setup;
4168
4169 In the case where you do both (use 'setup_middleware' and configuration) the
4170 package call to setup_middleware will be applied earlier (in other words its
4171 middleware will wrap closer to the application).  Keep this in mind since in
4172 some cases the order of middleware is important.
4173
4174 The two approaches are not exclusive.
4175
4176 =over 4
4177
4178 =item Middleware Object
4179
4180 An already initialized object that conforms to the L<Plack::Middleware>
4181 specification:
4182
4183     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4184
4185     __PACKAGE__->config(
4186       'psgi_middleware', [
4187         $stacktrace_middleware,
4188       ]);
4189
4190
4191 =item coderef
4192
4193 A coderef that is an inlined middleware:
4194
4195     __PACKAGE__->config(
4196       'psgi_middleware', [
4197         sub {
4198           my $app = shift;
4199           return sub {
4200             my $env = shift;
4201             if($env->{PATH_INFO} =~m/forced/) {
4202               Plack::App::File
4203                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
4204                 ->call($env);
4205             } else {
4206               return $app->($env);
4207             }
4208          },
4209       },
4210     ]);
4211
4212
4213
4214 =item a scalar
4215
4216 We assume the scalar refers to a namespace after normalizing it using the
4217 following rules:
4218
4219 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
4220 is assumed to be 'as is', and we just install and use the middleware.
4221
4222 (2) If the scalar begins with "Plack::Middleware" or your application namespace
4223 (the package name of your Catalyst application subclass), we also assume then
4224 that it is a full namespace, and use it.
4225
4226 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
4227 resolve it first by looking for it under your application namespace (for example
4228 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
4229 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
4230 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
4231 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
4232 namespace first to let you 'override' common L<Plack::Middleware> locally, should
4233 you find that a good idea.
4234
4235 Examples:
4236
4237     package MyApp::Web;
4238
4239     __PACKAGE__->config(
4240       'psgi_middleware', [
4241         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
4242         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
4243         '+MyApp::Custom',  ## MyApp::Custom->wrap
4244       ],
4245     );
4246
4247 =item a scalar followed by a hashref
4248
4249 Just like the previous, except the following C<HashRef> is used as arguments
4250 to initialize the middleware object.
4251
4252     __PACKAGE__->config(
4253       'psgi_middleware', [
4254          'Session' => {store => 'File'},
4255     ]);
4256
4257 =back
4258
4259 Please see L<PSGI> for more on middleware.
4260
4261 =head1 ENCODING
4262
4263 Starting in L<Catalyst> version 5.90080 encoding is automatically enabled
4264 and set to encode all body responses to UTF8 when possible and applicable.
4265 Following is documentation on this process.  If you are using an older
4266 version of L<Catalyst> you should review documentation for that version since
4267 a lot has changed.
4268
4269 By default encoding is now 'UTF-8'.  You may turn it off by setting
4270 the encoding configuration to undef.
4271
4272     MyApp->config(encoding => undef);
4273
4274 This is recommended for temporary backwards compatibility only.
4275
4276 Encoding is automatically applied when the content-type is set to
4277 a type that can be encoded.  Currently we encode when the content type
4278 matches the following regular expression:
4279
4280     $content_type =~ /^text|xml$|javascript$/
4281
4282 Encoding is set on the application, but it is copied to the context object
4283 so that you can override it on a request basis.
4284
4285 Be default we don't automatically encode 'application/json' since the most
4286 common approaches to generating this type of response (Either via L<Catalyst::View::JSON>
4287 or L<Catalyst::Action::REST>) will do so already and we want to avoid double
4288 encoding issues.
4289
4290 If you are producing JSON response in an unconventional manner (such
4291 as via a template or manual strings) you should perform the UTF8 encoding
4292 manually as well such as to conform to the JSON specification.
4293
4294 NOTE: We also examine the value of $c->response->content_encoding.  If
4295 you set this (like for example 'gzip', and manually gzipping the body)
4296 we assume that you have done all the necessary encoding yourself, since
4297 we cannot encode the gzipped contents.  If you use a plugin like
4298 L<Catalyst::Plugin::Compress> you need to update to a modern version in order
4299 to have this function correctly  with the new UTF8 encoding code, or you
4300 can use L<Plack::Middleware::Deflater> or (probably best) do your compression on
4301 a front end proxy.
4302
4303 =head2 Methods
4304
4305 =over 4
4306
4307 =item encoding
4308
4309 Returns an instance of an C<Encode> encoding
4310
4311     print $c->encoding->name
4312
4313 =item handle_unicode_encoding_exception ($exception_context)
4314
4315 Method called when decoding process for a request fails.
4316
4317 An C<$exception_context> hashref is provided to allow you to override the
4318 behaviour of your application when given data with incorrect encodings.
4319
4320 The default method throws exceptions in the case of invalid request parameters
4321 (resulting in a 500 error), but ignores errors in upload filenames.
4322
4323 The keys passed in the C<$exception_context> hash are:
4324
4325 =over
4326
4327 =item param_value
4328
4329 The value which was not able to be decoded.
4330
4331 =item error_msg
4332
4333 The exception received from L<Encode>.
4334
4335 =item encoding_step
4336
4337 What type of data was being decoded. Valid values are (currently)
4338 C<params> - for request parameters / arguments / captures
4339 and C<uploads> - for request upload filenames.
4340
4341 =back
4342
4343 =back
4344
4345 =head1 SUPPORT
4346
4347 IRC:
4348
4349     Join #catalyst on irc.perl.org.
4350
4351 Mailing Lists:
4352
4353     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4354     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4355
4356 Web:
4357
4358     http://catalyst.perl.org
4359
4360 Wiki:
4361
4362     http://dev.catalyst.perl.org
4363
4364 =head1 SEE ALSO
4365
4366 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4367
4368 =head2 L<Catalyst::Manual> - The Catalyst Manual
4369
4370 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4371
4372 =head2 L<Catalyst::Engine> - Core engine
4373
4374 =head2 L<Catalyst::Log> - Log class.
4375
4376 =head2 L<Catalyst::Request> - Request object
4377
4378 =head2 L<Catalyst::Response> - Response object
4379
4380 =head2 L<Catalyst::Test> - The test suite.
4381
4382 =head1 PROJECT FOUNDER
4383
4384 sri: Sebastian Riedel <sri@cpan.org>
4385
4386 =head1 CONTRIBUTORS
4387
4388 abw: Andy Wardley
4389
4390 acme: Leon Brocard <leon@astray.com>
4391
4392 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4393
4394 andrewalker: André Walker <andre@cpan.org>
4395
4396 Andrew Bramble
4397
4398 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4399
4400 Andrew Ruthven
4401
4402 andyg: Andy Grundman <andy@hybridized.org>
4403
4404 audreyt: Audrey Tang
4405
4406 bricas: Brian Cassidy <bricas@cpan.org>
4407
4408 Caelum: Rafael Kitover <rkitover@io.com>
4409
4410 chansen: Christian Hansen
4411
4412 chicks: Christopher Hicks
4413
4414 Chisel Wright C<pause@herlpacker.co.uk>
4415
4416 Danijel Milicevic C<me@danijel.de>
4417
4418 davewood: David Schmidt <davewood@cpan.org>
4419
4420 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4421
4422 David Naughton, C<naughton@umn.edu>
4423
4424 David E. Wheeler
4425
4426 dhoss: Devin Austin <dhoss@cpan.org>
4427
4428 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4429
4430 Drew Taylor
4431
4432 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4433
4434 esskar: Sascha Kiefer
4435
4436 fireartist: Carl Franks <cfranks@cpan.org>
4437
4438 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4439
4440 gabb: Danijel Milicevic
4441
4442 Gary Ashton Jones
4443
4444 Gavin Henry C<ghenry@perl.me.uk>
4445
4446 Geoff Richards
4447
4448 groditi: Guillermo Roditi <groditi@gmail.com>
4449
4450 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4451
4452 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4453
4454 jcamacho: Juan Camacho
4455
4456 jester: Jesse Sheidlower C<jester@panix.com>
4457
4458 jhannah: Jay Hannah <jay@jays.net>
4459
4460 Jody Belka
4461
4462 Johan Lindstrom
4463
4464 jon: Jon Schutz <jjschutz@cpan.org>
4465
4466 Jonathan Rockway C<< <jrockway@cpan.org> >>
4467
4468 Kieren Diment C<kd@totaldatasolution.com>
4469
4470 konobi: Scott McWhirter <konobi@cpan.org>
4471
4472 marcus: Marcus Ramberg <mramberg@cpan.org>
4473
4474 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4475
4476 mgrimes: Mark Grimes <mgrimes@cpan.org>
4477
4478 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4479
4480 mugwump: Sam Vilain
4481
4482 naughton: David Naughton
4483
4484 ningu: David Kamholz <dkamholz@cpan.org>
4485
4486 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4487
4488 numa: Dan Sully <daniel@cpan.org>
4489
4490 obra: Jesse Vincent
4491
4492 Octavian Rasnita
4493
4494 omega: Andreas Marienborg
4495
4496 Oleg Kostyuk <cub.uanic@gmail.com>
4497
4498 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4499
4500 rafl: Florian Ragwitz <rafl@debian.org>
4501
4502 random: Roland Lammel <lammel@cpan.org>
4503
4504 Robert Sedlacek C<< <rs@474.at> >>
4505
4506 SpiceMan: Marcel Montes
4507
4508 sky: Arthur Bergman
4509
4510 szbalint: Balint Szilakszi <szbalint@cpan.org>
4511
4512 t0m: Tomas Doran <bobtfish@bobtfish.net>
4513
4514 Ulf Edvinsson
4515
4516 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4517
4518 Viljo Marrandi C<vilts@yahoo.com>
4519
4520 Will Hawes C<info@whawes.co.uk>
4521
4522 willert: Sebastian Willert <willert@cpan.org>
4523
4524 wreis: Wallace Reis <wreis@cpan.org>
4525
4526 Yuval Kogman, C<nothingmuch@woobling.org>
4527
4528 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4529
4530 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4531
4532 Upasana <me@upasana.me>
4533
4534 John Napiorkowski (jnap) <jjnapiork@cpan.org>
4535
4536 =head1 COPYRIGHT
4537
4538 Copyright (c) 2005-2015, the above named PROJECT FOUNDER and CONTRIBUTORS.
4539
4540 =head1 LICENSE
4541
4542 This library is free software. You can redistribute it and/or modify it under
4543 the same terms as Perl itself.
4544
4545 =cut
4546
4547 no Moose;
4548
4549 __PACKAGE__->meta->make_immutable;
4550
4551 1;