lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use bytes;
   8 use B::Hooks::EndOfScope ();
   9 use Catalyst::Exception;
  10 use Catalyst::Exception::Detach;
  11 use Catalyst::Exception::Go;
  12 use Catalyst::Log;
  13 use Catalyst::Request;
  14 use Catalyst::Request::Upload;
  15 use Catalyst::Response;
  16 use Catalyst::Utils;
  17 use Catalyst::Controller;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80013';
  83
  84 {
  85     my $dev_version = $VERSION =~ /_\d{2}$/;
  86     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  87 }
  88
  89 $VERSION = eval $VERSION;
  90
  91 sub import {
  92     my ( $class, @arguments ) = @_;
  93
  94     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  95     # callers @ISA.
  96     return unless $class eq 'Catalyst';
  97
  98     my $caller = caller();
  99     return if $caller eq 'main';
 100
 101     # Kill Adopt::NEXT warnings if we're a non-RC version
 102     unless (_IS_DEVELOPMENT_VERSION()) {
 103         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 104     }
 105
 106     my $meta = Moose::Meta::Class->initialize($caller);
 107     unless ( $caller->isa('Catalyst') ) {
 108         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 109         $meta->superclasses(@superclasses);
 110     }
 111     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 112     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 113
 114     unless( $meta->has_method('meta') ){
 115         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 116     }
 117
 118     $caller->arguments( [@arguments] );
 119     $caller->setup_home;
 120 }
 121
 122 sub _application { $_[0] }
 123
 124 =head1 NAME
 125
 126 Catalyst - The Elegant MVC Web Application Framework
 127
 128 =head1 SYNOPSIS
 129
 130 See the L<Catalyst::Manual> distribution for comprehensive
 131 documentation and tutorials.
 132
 133     # Install Catalyst::Devel for helpers and other development tools
 134     # use the helper to create a new application
 135     catalyst.pl MyApp
 136
 137     # add models, views, controllers
 138     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 139     script/myapp_create.pl view MyTemplate TT
 140     script/myapp_create.pl controller Search
 141
 142     # built in testserver -- use -r to restart automatically on changes
 143     # --help to see all available options
 144     script/myapp_server.pl
 145
 146     # command line testing interface
 147     script/myapp_test.pl /yada
 148
 149     ### in lib/MyApp.pm
 150     use Catalyst qw/-Debug/; # include plugins here as well
 151
 152     ### In lib/MyApp/Controller/Root.pm (autocreated)
 153     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 154         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 155         $c->stash->{template} = 'foo.tt'; # set the template
 156         # lookup something from db -- stash vars are passed to TT
 157         $c->stash->{data} =
 158           $c->model('Database::Foo')->search( { country => $args[0] } );
 159         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 160             $c->forward( 'bar' ); # process another action
 161             # do something else after forward returns
 162         }
 163     }
 164
 165     # The foo.tt TT template can use the stash data from the database
 166     [% WHILE (item = data.next) %]
 167         [% item.foo %]
 168     [% END %]
 169
 170     # called for /bar/of/soap, /bar/of/soap/10, etc.
 171     sub bar : Path('/bar/of/soap') { ... }
 172
 173     # called for all actions, from the top-most controller downwards
 174     sub auto : Private {
 175         my ( $self, $c ) = @_;
 176         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 177             $c->res->redirect( '/login' ); # require login
 178             return 0; # abort request and go immediately to end()
 179         }
 180         return 1; # success; carry on to next action
 181     }
 182
 183     # called after all actions are finished
 184     sub end : Private {
 185         my ( $self, $c ) = @_;
 186         if ( scalar @{ $c->error } ) { ... } # handle errors
 187         return if $c->res->body; # already have a response
 188         $c->forward( 'MyApp::View::TT' ); # render template
 189     }
 190
 191     ### in MyApp/Controller/Foo.pm
 192     # called for /foo/bar
 193     sub bar : Local { ... }
 194
 195     # called for /blargle
 196     sub blargle : Global { ... }
 197
 198     # an index action matches /foo, but not /foo/1, etc.
 199     sub index : Private { ... }
 200
 201     ### in MyApp/Controller/Foo/Bar.pm
 202     # called for /foo/bar/baz
 203     sub baz : Local { ... }
 204
 205     # first Root auto is called, then Foo auto, then this
 206     sub auto : Private { ... }
 207
 208     # powerful regular expression paths are also possible
 209     sub details : Regex('^product/(\w+)/details$') {
 210         my ( $self, $c ) = @_;
 211         # extract the (\w+) from the URI
 212         my $product = $c->req->captures->[0];
 213     }
 214
 215 See L<Catalyst::Manual::Intro> for additional information.
 216
 217 =head1 DESCRIPTION
 218
 219 Catalyst is a modern framework for making web applications without the
 220 pain usually associated with this process. This document is a reference
 221 to the main Catalyst application. If you are a new user, we suggest you
 222 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 223
 224 See L<Catalyst::Manual> for more documentation.
 225
 226 Catalyst plugins can be loaded by naming them as arguments to the "use
 227 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 228 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 229 C<My::Module>.
 230
 231     use Catalyst qw/My::Module/;
 232
 233 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 234 fully qualify the name by using a unary plus:
 235
 236     use Catalyst qw/
 237         My::Module
 238         +Fully::Qualified::Plugin::Name
 239     /;
 240
 241 Special flags like C<-Debug> and C<-Engine> can also be specified as
 242 arguments when Catalyst is loaded:
 243
 244     use Catalyst qw/-Debug My::Module/;
 245
 246 The position of plugins and flags in the chain is important, because
 247 they are loaded in the order in which they appear.
 248
 249 The following flags are supported:
 250
 251 =head2 -Debug
 252
 253 Enables debug output. You can also force this setting from the system
 254 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 255 settings override the application, with <MYAPP>_DEBUG having the highest
 256 priority.
 257
 258 =head2 -Engine
 259
 260 Forces Catalyst to use a specific engine. Omit the
 261 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 262
 263     use Catalyst qw/-Engine=CGI/;
 264
 265 =head2 -Home
 266
 267 Forces Catalyst to use a specific home directory, e.g.:
 268
 269     use Catalyst qw[-Home=/usr/mst];
 270
 271 This can also be done in the shell environment by setting either the
 272 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 273 is replaced with the uppercased name of your application, any "::" in
 274 the name will be replaced with underscores, e.g. MyApp::Web should use
 275 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 276
 277 =head2 -Log
 278
 279     use Catalyst '-Log=warn,fatal,error';
 280
 281 Specifies a comma-delimited list of log levels.
 282
 283 =head2 -Stats
 284
 285 Enables statistics collection and reporting. You can also force this setting
 286 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 287 environment settings override the application, with <MYAPP>_STATS having the
 288 highest priority.
 289
 290 e.g.
 291
 292    use Catalyst qw/-Stats=1/
 293
 294 =head1 METHODS
 295
 296 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 297
 298 =head2 $c->action
 299
 300 Returns a L<Catalyst::Action> object for the current action, which
 301 stringifies to the action name. See L<Catalyst::Action>.
 302
 303 =head2 $c->namespace
 304
 305 Returns the namespace of the current action, i.e., the URI prefix
 306 corresponding to the controller of the current action. For example:
 307
 308     # in Controller::Foo::Bar
 309     $c->namespace; # returns 'foo/bar';
 310
 311 =head2 $c->request
 312
 313 =head2 $c->req
 314
 315 Returns the current L<Catalyst::Request> object, giving access to
 316 information about the current client request (including parameters,
 317 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 318
 319 =head2 REQUEST FLOW HANDLING
 320
 321 =head2 $c->forward( $action [, \@arguments ] )
 322
 323 =head2 $c->forward( $class, $method, [, \@arguments ] )
 324
 325 Forwards processing to another action, by its private name. If you give a
 326 class name but no method, C<process()> is called. You may also optionally
 327 pass arguments in an arrayref. The action will receive the arguments in
 328 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 329 C<< $c->req->args >> will be restored to the previous values.
 330
 331 Any data C<return>ed from the action forwarded to, will be returned by the
 332 call to forward.
 333
 334     my $foodata = $c->forward('/foo');
 335     $c->forward('index');
 336     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 337     $c->forward('MyApp::View::TT');
 338
 339 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 340 an C<< eval { } >> around the call (actually
 341 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 342 all 'dies' within the called action. If you want C<die> to propagate you
 343 need to do something like:
 344
 345     $c->forward('foo');
 346     die $c->error if $c->error;
 347
 348 Or make sure to always return true values from your actions and write
 349 your code like this:
 350
 351     $c->forward('foo') || return;
 352
 353 Another note is that C<< $c->forward >> always returns a scalar because it
 354 actually returns $c->state which operates in a scalar context.
 355 Thus, something like:
 356
 357     return @array;
 358
 359 in an action that is forwarded to is going to return a scalar,
 360 i.e. how many items are in that array, which is probably not what you want.
 361 If you need to return an array then return a reference to it,
 362 or stash it like so:
 363
 364     $c->stash->{array} = \@array;
 365
 366 and access it from the stash.
 367
 368 =cut
 369
 370 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 371
 372 =head2 $c->detach( $action [, \@arguments ] )
 373
 374 =head2 $c->detach( $class, $method, [, \@arguments ] )
 375
 376 =head2 $c->detach()
 377
 378 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 379 doesn't return to the previous action when processing is finished.
 380
 381 When called with no arguments it escapes the processing chain entirely.
 382
 383 =cut
 384
 385 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 386
 387 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 388
 389 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 390
 391 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 392 but does a full dispatch, instead of just calling the new C<$action> /
 393 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 394 you go to are called, just like a new request.
 395
 396 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 397 This means, for example, that C<< $c->action >> methods such as
 398 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 399 L<reverse|Catalyst::Action/reverse> return information for the visited action
 400 when they are invoked within the visited action.  This is different from the
 401 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 402 continues to use the $c->action object from the caller action even when
 403 invoked from the callee.
 404
 405 C<< $c->stash >> is kept unchanged.
 406
 407 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 408 allows you to "wrap" another action, just as it would have been called by
 409 dispatching from a URL, while the analogous
 410 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 411 transfer control to another action as if it had been reached directly from a URL.
 412
 413 =cut
 414
 415 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 416
 417 =head2 $c->go( $action [, \@captures, \@arguments ] )
 418
 419 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 420
 421 The relationship between C<go> and
 422 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 423 the relationship between
 424 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 425 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 426 C<< $c->go >> will perform a full dispatch on the specified action or method,
 427 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 428 C<go> escapes the processing of the current request chain on completion, and
 429 does not return to its caller.
 430
 431 =cut
 432
 433 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 434
 435 =head2 $c->response
 436
 437 =head2 $c->res
 438
 439 Returns the current L<Catalyst::Response> object, see there for details.
 440
 441 =head2 $c->stash
 442
 443 Returns a hashref to the stash, which may be used to store data and pass
 444 it between components during a request. You can also set hash keys by
 445 passing arguments. The stash is automatically sent to the view. The
 446 stash is cleared at the end of a request; it cannot be used for
 447 persistent storage (for this you must use a session; see
 448 L<Catalyst::Plugin::Session> for a complete system integrated with
 449 Catalyst).
 450
 451     $c->stash->{foo} = $bar;
 452     $c->stash( { moose => 'majestic', qux => 0 } );
 453     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 454
 455     # stash is automatically passed to the view for use in a template
 456     $c->forward( 'MyApp::View::TT' );
 457
 458 =cut
 459
 460 around stash => sub {
 461     my $orig = shift;
 462     my $c = shift;
 463     my $stash = $orig->($c);
 464     if (@_) {
 465         my $new_stash = @_ > 1 ? {@_} : $_[0];
 466         croak('stash takes a hash or hashref') unless ref $new_stash;
 467         foreach my $key ( keys %$new_stash ) {
 468           $stash->{$key} = $new_stash->{$key};
 469         }
 470     }
 471
 472     return $stash;
 473 };
 474
 475
 476 =head2 $c->error
 477
 478 =head2 $c->error($error, ...)
 479
 480 =head2 $c->error($arrayref)
 481
 482 Returns an arrayref containing error messages.  If Catalyst encounters an
 483 error while processing a request, it stores the error in $c->error.  This
 484 method should only be used to store fatal error messages.
 485
 486     my @error = @{ $c->error };
 487
 488 Add a new error.
 489
 490     $c->error('Something bad happened');
 491
 492 =cut
 493
 494 sub error {
 495     my $c = shift;
 496     if ( $_[0] ) {
 497         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 498         croak @$error unless ref $c;
 499         push @{ $c->{error} }, @$error;
 500     }
 501     elsif ( defined $_[0] ) { $c->{error} = undef }
 502     return $c->{error} || [];
 503 }
 504
 505
 506 =head2 $c->state
 507
 508 Contains the return value of the last executed action.
 509 Note that << $c->state >> operates in a scalar context which means that all
 510 values it returns are scalar.
 511
 512 =head2 $c->clear_errors
 513
 514 Clear errors.  You probably don't want to clear the errors unless you are
 515 implementing a custom error screen.
 516
 517 This is equivalent to running
 518
 519     $c->error(0);
 520
 521 =cut
 522
 523 sub clear_errors {
 524     my $c = shift;
 525     $c->error(0);
 526 }
 527
 528 sub _comp_search_prefixes {
 529     my $c = shift;
 530     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 531 }
 532
 533 # search components given a name and some prefixes
 534 sub _comp_names_search_prefixes {
 535     my ( $c, $name, @prefixes ) = @_;
 536     my $appclass = ref $c || $c;
 537     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 538     $filter = qr/$filter/; # Compile regex now rather than once per loop
 539
 540     # map the original component name to the sub part that we will search against
 541     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 542         grep { /$filter/ } keys %{ $c->components };
 543
 544     # undef for a name will return all
 545     return keys %eligible if !defined $name;
 546
 547     my $query  = ref $name ? $name : qr/^$name$/i;
 548     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 549
 550     return @result if @result;
 551
 552     # if we were given a regexp to search against, we're done.
 553     return if ref $name;
 554
 555     # skip regexp fallback if configured
 556     return
 557         if $appclass->config->{disable_component_resolution_regex_fallback};
 558
 559     # regexp fallback
 560     $query  = qr/$name/i;
 561     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 562
 563     # no results? try against full names
 564     if( !@result ) {
 565         @result = grep { m{$query} } keys %eligible;
 566     }
 567
 568     # don't warn if we didn't find any results, it just might not exist
 569     if( @result ) {
 570         # Disgusting hack to work out correct method name
 571         my $warn_for = lc $prefixes[0];
 572         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 573            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 574            "component resolution is unreliable and unsafe.";
 575         my $short = $result[0];
 576         # remove the component namespace prefix
 577         $short =~ s/.*?(Model|Controller|View):://;
 578         my $shortmess = Carp::shortmess('');
 579         if ($shortmess =~ m#Catalyst/Plugin#) {
 580            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 581               "plugin's config";
 582         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 583            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 584               "component's config";
 585         } else {
 586            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 587               "but if you really wanted to search, pass in a regexp as the argument " .
 588               "like so: \$c->${warn_for}(qr/${name}/)";
 589         }
 590         $c->log->warn( "${msg}$shortmess" );
 591     }
 592
 593     return @result;
 594 }
 595
 596 # Find possible names for a prefix
 597 sub _comp_names {
 598     my ( $c, @prefixes ) = @_;
 599     my $appclass = ref $c || $c;
 600
 601     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 602
 603     my @names = map { s{$filter}{}; $_; }
 604         $c->_comp_names_search_prefixes( undef, @prefixes );
 605
 606     return @names;
 607 }
 608
 609 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 610 sub _filter_component {
 611     my ( $c, $comp, @args ) = @_;
 612
 613     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 614         return $comp->ACCEPT_CONTEXT( $c, @args );
 615     }
 616
 617     return $comp;
 618 }
 619
 620 =head2 COMPONENT ACCESSORS
 621
 622 =head2 $c->controller($name)
 623
 624 Gets a L<Catalyst::Controller> instance by name.
 625
 626     $c->controller('Foo')->do_stuff;
 627
 628 If the name is omitted, will return the controller for the dispatched
 629 action.
 630
 631 If you want to search for controllers, pass in a regexp as the argument.
 632
 633     # find all controllers that start with Foo
 634     my @foo_controllers = $c->controller(qr{^Foo});
 635
 636
 637 =cut
 638
 639 sub controller {
 640     my ( $c, $name, @args ) = @_;
 641
 642     if( $name ) {
 643         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 644         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 645         return $c->_filter_component( $result[ 0 ], @args );
 646     }
 647
 648     return $c->component( $c->action->class );
 649 }
 650
 651 =head2 $c->model($name)
 652
 653 Gets a L<Catalyst::Model> instance by name.
 654
 655     $c->model('Foo')->do_stuff;
 656
 657 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 658
 659 If the name is omitted, it will look for
 660  - a model object in $c->stash->{current_model_instance}, then
 661  - a model name in $c->stash->{current_model}, then
 662  - a config setting 'default_model', or
 663  - check if there is only one model, and return it if that's the case.
 664
 665 If you want to search for models, pass in a regexp as the argument.
 666
 667     # find all models that start with Foo
 668     my @foo_models = $c->model(qr{^Foo});
 669
 670 =cut
 671
 672 sub model {
 673     my ( $c, $name, @args ) = @_;
 674     my $appclass = ref($c) || $c;
 675     if( $name ) {
 676         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 677         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 678         return $c->_filter_component( $result[ 0 ], @args );
 679     }
 680
 681     if (ref $c) {
 682         return $c->stash->{current_model_instance}
 683           if $c->stash->{current_model_instance};
 684         return $c->model( $c->stash->{current_model} )
 685           if $c->stash->{current_model};
 686     }
 687     return $c->model( $appclass->config->{default_model} )
 688       if $appclass->config->{default_model};
 689
 690     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 691
 692     if( $rest ) {
 693         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 694         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 695         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 696         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 697         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 698     }
 699
 700     return $c->_filter_component( $comp );
 701 }
 702
 703
 704 =head2 $c->view($name)
 705
 706 Gets a L<Catalyst::View> instance by name.
 707
 708     $c->view('Foo')->do_stuff;
 709
 710 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 711
 712 If the name is omitted, it will look for
 713  - a view object in $c->stash->{current_view_instance}, then
 714  - a view name in $c->stash->{current_view}, then
 715  - a config setting 'default_view', or
 716  - check if there is only one view, and return it if that's the case.
 717
 718 If you want to search for views, pass in a regexp as the argument.
 719
 720     # find all views that start with Foo
 721     my @foo_views = $c->view(qr{^Foo});
 722
 723 =cut
 724
 725 sub view {
 726     my ( $c, $name, @args ) = @_;
 727
 728     my $appclass = ref($c) || $c;
 729     if( $name ) {
 730         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 731         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 732         return $c->_filter_component( $result[ 0 ], @args );
 733     }
 734
 735     if (ref $c) {
 736         return $c->stash->{current_view_instance}
 737           if $c->stash->{current_view_instance};
 738         return $c->view( $c->stash->{current_view} )
 739           if $c->stash->{current_view};
 740     }
 741     return $c->view( $appclass->config->{default_view} )
 742       if $appclass->config->{default_view};
 743
 744     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 745
 746     if( $rest ) {
 747         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 748         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 749         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 750         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 751         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 752     }
 753
 754     return $c->_filter_component( $comp );
 755 }
 756
 757 =head2 $c->controllers
 758
 759 Returns the available names which can be passed to $c->controller
 760
 761 =cut
 762
 763 sub controllers {
 764     my ( $c ) = @_;
 765     return $c->_comp_names(qw/Controller C/);
 766 }
 767
 768 =head2 $c->models
 769
 770 Returns the available names which can be passed to $c->model
 771
 772 =cut
 773
 774 sub models {
 775     my ( $c ) = @_;
 776     return $c->_comp_names(qw/Model M/);
 777 }
 778
 779
 780 =head2 $c->views
 781
 782 Returns the available names which can be passed to $c->view
 783
 784 =cut
 785
 786 sub views {
 787     my ( $c ) = @_;
 788     return $c->_comp_names(qw/View V/);
 789 }
 790
 791 =head2 $c->comp($name)
 792
 793 =head2 $c->component($name)
 794
 795 Gets a component object by name. This method is not recommended,
 796 unless you want to get a specific component by full
 797 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 798 should be used instead.
 799
 800 If C<$name> is a regexp, a list of components matched against the full
 801 component name will be returned.
 802
 803 If Catalyst can't find a component by name, it will fallback to regex
 804 matching by default. To disable this behaviour set
 805 disable_component_resolution_regex_fallback to a true value.
 806
 807     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 808
 809 =cut
 810
 811 sub component {
 812     my ( $c, $name, @args ) = @_;
 813
 814     if( $name ) {
 815         my $comps = $c->components;
 816
 817         if( !ref $name ) {
 818             # is it the exact name?
 819             return $c->_filter_component( $comps->{ $name }, @args )
 820                        if exists $comps->{ $name };
 821
 822             # perhaps we just omitted "MyApp"?
 823             my $composed = ( ref $c || $c ) . "::${name}";
 824             return $c->_filter_component( $comps->{ $composed }, @args )
 825                        if exists $comps->{ $composed };
 826
 827             # search all of the models, views and controllers
 828             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 829             return $c->_filter_component( $comp, @args ) if $comp;
 830         }
 831
 832         # This is here so $c->comp( '::M::' ) works
 833         my $query = ref $name ? $name : qr{$name}i;
 834
 835         my @result = grep { m{$query} } keys %{ $c->components };
 836         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 837
 838         if( $result[ 0 ] ) {
 839             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 840             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 841             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 842             return $c->_filter_component( $result[ 0 ], @args );
 843         }
 844
 845         # I would expect to return an empty list here, but that breaks back-compat
 846     }
 847
 848     # fallback
 849     return sort keys %{ $c->components };
 850 }
 851
 852 =head2 CLASS DATA AND HELPER CLASSES
 853
 854 =head2 $c->config
 855
 856 Returns or takes a hashref containing the application's configuration.
 857
 858     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 859
 860 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 861 like C<myapp.conf> in your applications home directory. See
 862 L<Catalyst::Plugin::ConfigLoader>.
 863
 864 =head3 Cascading configuration
 865
 866 The config method is present on all Catalyst components, and configuration
 867 will be merged when an application is started. Configuration loaded with
 868 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 869 followed by configuration in your top level C<MyApp> class. These two
 870 configurations are merged, and then configuration data whose hash key matches a
 871 component name is merged with configuration for that component.
 872
 873 The configuration for a component is then passed to the C<new> method when a
 874 component is constructed.
 875
 876 For example:
 877
 878     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 879     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 880
 881 will mean that C<MyApp::Model::Foo> receives the following data when
 882 constructed:
 883
 884     MyApp::Model::Foo->new({
 885         bar => 'baz',
 886         quux => 'frob',
 887         overrides => 'me',
 888     });
 889
 890 =cut
 891
 892 around config => sub {
 893     my $orig = shift;
 894     my $c = shift;
 895
 896     croak('Setting config after setup has been run is not allowed.')
 897         if ( @_ and $c->setup_finished );
 898
 899     $c->$orig(@_);
 900 };
 901
 902 =head2 $c->log
 903
 904 Returns the logging object instance. Unless it is already set, Catalyst
 905 sets this up with a L<Catalyst::Log> object. To use your own log class,
 906 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 907 C<< __PACKAGE__->setup >>.
 908
 909  __PACKAGE__->log( MyLogger->new );
 910  __PACKAGE__->setup;
 911
 912 And later:
 913
 914     $c->log->info( 'Now logging with my own logger!' );
 915
 916 Your log class should implement the methods described in
 917 L<Catalyst::Log>.
 918
 919
 920 =head2 $c->debug
 921
 922 Returns 1 if debug mode is enabled, 0 otherwise.
 923
 924 You can enable debug mode in several ways:
 925
 926 =over
 927
 928 =item By calling myapp_server.pl with the -d flag
 929
 930 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 931
 932 =item The -Debug option in your MyApp.pm
 933
 934 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 935
 936 =back
 937
 938 Calling C<< $c->debug(1) >> has no effect.
 939
 940 =cut
 941
 942 sub debug { 0 }
 943
 944 =head2 $c->dispatcher
 945
 946 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 947
 948 =head2 $c->engine
 949
 950 Returns the engine instance. See L<Catalyst::Engine>.
 951
 952
 953 =head2 UTILITY METHODS
 954
 955 =head2 $c->path_to(@path)
 956
 957 Merges C<@path> with C<< $c->config->{home} >> and returns a
 958 L<Path::Class::Dir> object. Note you can usually use this object as
 959 a filename, but sometimes you will have to explicitly stringify it
 960 yourself by calling the C<< ->stringify >> method.
 961
 962 For example:
 963
 964     $c->path_to( 'db', 'sqlite.db' );
 965
 966 =cut
 967
 968 sub path_to {
 969     my ( $c, @path ) = @_;
 970     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 971     if ( -d $path ) { return $path }
 972     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 973 }
 974
 975 =head2 $c->plugin( $name, $class, @args )
 976
 977 Helper method for plugins. It creates a class data accessor/mutator and
 978 loads and instantiates the given class.
 979
 980     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 981
 982     $c->prototype->define_javascript_functions;
 983
 984 B<Note:> This method of adding plugins is deprecated. The ability
 985 to add plugins like this B<will be removed> in a Catalyst 5.81.
 986 Please do not use this functionality in new code.
 987
 988 =cut
 989
 990 sub plugin {
 991     my ( $class, $name, $plugin, @args ) = @_;
 992
 993     # See block comment in t/unit_core_plugin.t
 994     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 995
 996     $class->_register_plugin( $plugin, 1 );
 997
 998     eval { $plugin->import };
 999     $class->mk_classdata($name);
1000     my $obj;
1001     eval { $obj = $plugin->new(@args) };
1002
1003     if ($@) {
1004         Catalyst::Exception->throw( message =>
1005               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1006     }
1007
1008     $class->$name($obj);
1009     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1010       if $class->debug;
1011 }
1012
1013 =head2 MyApp->setup
1014
1015 Initializes the dispatcher and engine, loads any plugins, and loads the
1016 model, view, and controller components. You may also specify an array
1017 of plugins to load here, if you choose to not load them in the C<use
1018 Catalyst> line.
1019
1020     MyApp->setup;
1021     MyApp->setup( qw/-Debug/ );
1022
1023 =cut
1024
1025 sub setup {
1026     my ( $class, @arguments ) = @_;
1027     croak('Running setup more than once')
1028         if ( $class->setup_finished );
1029
1030     unless ( $class->isa('Catalyst') ) {
1031
1032         Catalyst::Exception->throw(
1033             message => qq/'$class' does not inherit from Catalyst/ );
1034     }
1035
1036     if ( $class->arguments ) {
1037         @arguments = ( @arguments, @{ $class->arguments } );
1038     }
1039
1040     # Process options
1041     my $flags = {};
1042
1043     foreach (@arguments) {
1044
1045         if (/^-Debug$/) {
1046             $flags->{log} =
1047               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1048         }
1049         elsif (/^-(\w+)=?(.*)$/) {
1050             $flags->{ lc $1 } = $2;
1051         }
1052         else {
1053             push @{ $flags->{plugins} }, $_;
1054         }
1055     }
1056
1057     $class->setup_home( delete $flags->{home} );
1058
1059     $class->setup_log( delete $flags->{log} );
1060     $class->setup_plugins( delete $flags->{plugins} );
1061     $class->setup_dispatcher( delete $flags->{dispatcher} );
1062     $class->setup_engine( delete $flags->{engine} );
1063     $class->setup_stats( delete $flags->{stats} );
1064
1065     for my $flag ( sort keys %{$flags} ) {
1066
1067         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1068             &$code( $class, delete $flags->{$flag} );
1069         }
1070         else {
1071             $class->log->warn(qq/Unknown flag "$flag"/);
1072         }
1073     }
1074
1075     eval { require Catalyst::Devel; };
1076     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1077         $class->log->warn(<<"EOF");
1078 You are running an old script!
1079
1080   Please update by running (this will overwrite existing files):
1081     catalyst.pl -force -scripts $class
1082
1083   or (this will not overwrite existing files):
1084     catalyst.pl -scripts $class
1085
1086 EOF
1087     }
1088
1089     if ( $class->debug ) {
1090         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1091
1092         if (@plugins) {
1093             my $column_width = Catalyst::Utils::term_width() - 6;
1094             my $t = Text::SimpleTable->new($column_width);
1095             $t->row($_) for @plugins;
1096             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1097         }
1098
1099         my $dispatcher = $class->dispatcher;
1100         my $engine     = $class->engine;
1101         my $home       = $class->config->{home};
1102
1103         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1104         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1105
1106         $home
1107           ? ( -d $home )
1108           ? $class->log->debug(qq/Found home "$home"/)
1109           : $class->log->debug(qq/Home "$home" doesn't exist/)
1110           : $class->log->debug(q/Couldn't find home/);
1111     }
1112
1113     # Call plugins setup, this is stupid and evil.
1114     # Also screws C3 badly on 5.10, hack to avoid.
1115     {
1116         no warnings qw/redefine/;
1117         local *setup = sub { };
1118         $class->setup unless $Catalyst::__AM_RESTARTING;
1119     }
1120
1121     # Initialize our data structure
1122     $class->components( {} );
1123
1124     $class->setup_components;
1125
1126     if ( $class->debug ) {
1127         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1128         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1129         for my $comp ( sort keys %{ $class->components } ) {
1130             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1131             $t->row( $comp, $type );
1132         }
1133         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1134           if ( keys %{ $class->components } );
1135     }
1136
1137     # Add our self to components, since we are also a component
1138     if( $class->isa('Catalyst::Controller') ){
1139       $class->components->{$class} = $class;
1140     }
1141
1142     $class->setup_actions;
1143
1144     if ( $class->debug ) {
1145         my $name = $class->config->{name} || 'Application';
1146         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1147     }
1148     $class->log->_flush() if $class->log->can('_flush');
1149
1150     # Make sure that the application class becomes immutable at this point,
1151     B::Hooks::EndOfScope::on_scope_end {
1152         return if $@;
1153         my $meta = Class::MOP::get_metaclass_by_name($class);
1154         if (
1155             $meta->is_immutable
1156             && ! { $meta->immutable_options }->{replace_constructor}
1157             && (
1158                    $class->isa('Class::Accessor::Fast')
1159                 || $class->isa('Class::Accessor')
1160             )
1161         ) {
1162             warn "You made your application class ($class) immutable, "
1163                 . "but did not inline the\nconstructor. "
1164                 . "This will break catalyst, as your app \@ISA "
1165                 . "Class::Accessor(::Fast)?\nPlease pass "
1166                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1167         }
1168         $meta->make_immutable(
1169             replace_constructor => 1,
1170         ) unless $meta->is_immutable;
1171     };
1172
1173     $class->setup_finalize;
1174 }
1175
1176
1177 =head2 $app->setup_finalize
1178
1179 A hook to attach modifiers to.
1180 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1181 Also better than C< setup_finished(); >, as that is a getter method.
1182
1183     sub setup_finalize {
1184
1185         my $app = shift;
1186
1187         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1188
1189         $app->next::method(@_);
1190
1191
1192     }
1193
1194 =cut
1195
1196 sub setup_finalize {
1197     my ($class) = @_;
1198     $class->setup_finished(1);
1199 }
1200
1201 =head2 $c->uri_for( $path, @args?, \%query_values? )
1202
1203 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1204
1205 Constructs an absolute L<URI> object based on the application root, the
1206 provided path, and the additional arguments and query parameters provided.
1207 When used as a string, provides a textual URI.
1208
1209 If the first argument is a string, it is taken as a public URI path relative
1210 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1211 relative to the application root (if it does). It is then merged with
1212 C<< $c->request->base >>; any C<@args> are appended as additional path
1213 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1214
1215 If the first argument is a L<Catalyst::Action> it represents an action which
1216 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1217 optional C<\@captures> argument (an arrayref) allows passing the captured
1218 variables that are needed to fill in the paths of Chained and Regex actions;
1219 once the path is resolved, C<uri_for> continues as though a path was
1220 provided, appending any arguments or parameters and creating an absolute
1221 URI.
1222
1223 The captures for the current request can be found in
1224 C<< $c->request->captures >>, and actions can be resolved using
1225 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1226 path, use C<< $c->uri_for_action >> instead.
1227
1228   # Equivalent to $c->req->uri
1229   $c->uri_for($c->action, $c->req->captures,
1230       @{ $c->req->args }, $c->req->params);
1231
1232   # For the Foo action in the Bar controller
1233   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1234
1235   # Path to a static resource
1236   $c->uri_for('/static/images/logo.png');
1237
1238 =cut
1239
1240 sub uri_for {
1241     my ( $c, $path, @args ) = @_;
1242
1243     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1244         $path = $path->path_prefix;
1245         $path =~ s{/+\z}{};
1246         $path .= '/';
1247     }
1248
1249     if ( blessed($path) ) { # action object
1250         my $captures = [ map { s|/|%2F|; $_; }
1251                         ( scalar @args && ref $args[0] eq 'ARRAY'
1252                          ? @{ shift(@args) }
1253                          : ()) ];
1254         my $action = $path;
1255         $path = $c->dispatcher->uri_for_action($action, $captures);
1256         if (not defined $path) {
1257             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1258                 if $c->debug;
1259             return undef;
1260         }
1261         $path = '/' if $path eq '';
1262     }
1263
1264     undef($path) if (defined $path && $path eq '');
1265
1266     my $params =
1267       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1268
1269     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1270     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1271     s|/|%2F| for @args;
1272
1273     unshift(@args, $path);
1274
1275     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1276         my $namespace = $c->namespace;
1277         if (defined $path) { # cheesy hack to handle path '../foo'
1278            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1279         }
1280         unshift(@args, $namespace || '');
1281     }
1282
1283     # join args with '/', or a blank string
1284     my $args = join('/', grep { defined($_) } @args);
1285     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1286     $args =~ s!^/+!!;
1287     my $base = $c->req->base;
1288     my $class = ref($base);
1289     $base =~ s{(?<!/)$}{/};
1290
1291     my $query = '';
1292
1293     if (my @keys = keys %$params) {
1294       # somewhat lifted from URI::_query's query_form
1295       $query = '?'.join('&', map {
1296           my $val = $params->{$_};
1297           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1298           s/ /+/g;
1299           my $key = $_;
1300           $val = '' unless defined $val;
1301           (map {
1302               my $param = "$_";
1303               utf8::encode( $param ) if utf8::is_utf8($param);
1304               # using the URI::Escape pattern here so utf8 chars survive
1305               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1306               $param =~ s/ /+/g;
1307               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1308       } @keys);
1309     }
1310
1311     my $res = bless(\"${base}${args}${query}", $class);
1312     $res;
1313 }
1314
1315 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1316
1317 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1318
1319 =over
1320
1321 =item $path
1322
1323 A private path to the Catalyst action you want to create a URI for.
1324
1325 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1326 >> and passing the resulting C<$action> and the remaining arguments to C<<
1327 $c->uri_for >>.
1328
1329 You can also pass in a Catalyst::Action object, in which case it is passed to
1330 C<< $c->uri_for >>.
1331
1332 =back
1333
1334 =cut
1335
1336 sub uri_for_action {
1337     my ( $c, $path, @args ) = @_;
1338     my $action = blessed($path)
1339       ? $path
1340       : $c->dispatcher->get_action_by_path($path);
1341     unless (defined $action) {
1342       croak "Can't find action for path '$path'";
1343     }
1344     return $c->uri_for( $action, @args );
1345 }
1346
1347 =head2 $c->welcome_message
1348
1349 Returns the Catalyst welcome HTML page.
1350
1351 =cut
1352
1353 sub welcome_message {
1354     my $c      = shift;
1355     my $name   = $c->config->{name};
1356     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1357     my $prefix = Catalyst::Utils::appprefix( ref $c );
1358     $c->response->content_type('text/html; charset=utf-8');
1359     return <<"EOF";
1360 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1361     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1362 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1363     <head>
1364     <meta http-equiv="Content-Language" content="en" />
1365     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1366         <title>$name on Catalyst $VERSION</title>
1367         <style type="text/css">
1368             body {
1369                 color: #000;
1370                 background-color: #eee;
1371             }
1372             div#content {
1373                 width: 640px;
1374                 margin-left: auto;
1375                 margin-right: auto;
1376                 margin-top: 10px;
1377                 margin-bottom: 10px;
1378                 text-align: left;
1379                 background-color: #ccc;
1380                 border: 1px solid #aaa;
1381             }
1382             p, h1, h2 {
1383                 margin-left: 20px;
1384                 margin-right: 20px;
1385                 font-family: verdana, tahoma, sans-serif;
1386             }
1387             a {
1388                 font-family: verdana, tahoma, sans-serif;
1389             }
1390             :link, :visited {
1391                     text-decoration: none;
1392                     color: #b00;
1393                     border-bottom: 1px dotted #bbb;
1394             }
1395             :link:hover, :visited:hover {
1396                     color: #555;
1397             }
1398             div#topbar {
1399                 margin: 0px;
1400             }
1401             pre {
1402                 margin: 10px;
1403                 padding: 8px;
1404             }
1405             div#answers {
1406                 padding: 8px;
1407                 margin: 10px;
1408                 background-color: #fff;
1409                 border: 1px solid #aaa;
1410             }
1411             h1 {
1412                 font-size: 0.9em;
1413                 font-weight: normal;
1414                 text-align: center;
1415             }
1416             h2 {
1417                 font-size: 1.0em;
1418             }
1419             p {
1420                 font-size: 0.9em;
1421             }
1422             p img {
1423                 float: right;
1424                 margin-left: 10px;
1425             }
1426             span#appname {
1427                 font-weight: bold;
1428                 font-size: 1.6em;
1429             }
1430         </style>
1431     </head>
1432     <body>
1433         <div id="content">
1434             <div id="topbar">
1435                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1436                     $VERSION</h1>
1437              </div>
1438              <div id="answers">
1439                  <p>
1440                  <img src="$logo" alt="Catalyst Logo" />
1441                  </p>
1442                  <p>Welcome to the  world of Catalyst.
1443                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1444                     framework will make web development something you had
1445                     never expected it to be: Fun, rewarding, and quick.</p>
1446                  <h2>What to do now?</h2>
1447                  <p>That really depends  on what <b>you</b> want to do.
1448                     We do, however, provide you with a few starting points.</p>
1449                  <p>If you want to jump right into web development with Catalyst
1450                     you might want to start with a tutorial.</p>
1451 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1452 </pre>
1453 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1454 <pre>
1455 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1456 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1457 </code></pre>
1458                  <h2>What to do next?</h2>
1459                  <p>Next it's time to write an actual application. Use the
1460                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1461                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1462                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1463                     they can save you a lot of work.</p>
1464                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1465                     <p>Also, be sure to check out the vast and growing
1466                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1467                     you are likely to find what you need there.
1468                     </p>
1469
1470                  <h2>Need help?</h2>
1471                  <p>Catalyst has a very active community. Here are the main places to
1472                     get in touch with us.</p>
1473                  <ul>
1474                      <li>
1475                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1476                      </li>
1477                      <li>
1478                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1479                      </li>
1480                      <li>
1481                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1482                      </li>
1483                  </ul>
1484                  <h2>In conclusion</h2>
1485                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1486                     as we enjoyed making it. Please contact us if you have ideas
1487                     for improvement or other feedback.</p>
1488              </div>
1489          </div>
1490     </body>
1491 </html>
1492 EOF
1493 }
1494
1495 =head1 INTERNAL METHODS
1496
1497 These methods are not meant to be used by end users.
1498
1499 =head2 $c->components
1500
1501 Returns a hash of components.
1502
1503 =head2 $c->context_class
1504
1505 Returns or sets the context class.
1506
1507 =head2 $c->counter
1508
1509 Returns a hashref containing coderefs and execution counts (needed for
1510 deep recursion detection).
1511
1512 =head2 $c->depth
1513
1514 Returns the number of actions on the current internal execution stack.
1515
1516 =head2 $c->dispatch
1517
1518 Dispatches a request to actions.
1519
1520 =cut
1521
1522 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1523
1524 =head2 $c->dispatcher_class
1525
1526 Returns or sets the dispatcher class.
1527
1528 =head2 $c->dump_these
1529
1530 Returns a list of 2-element array references (name, structure) pairs
1531 that will be dumped on the error page in debug mode.
1532
1533 =cut
1534
1535 sub dump_these {
1536     my $c = shift;
1537     [ Request => $c->req ],
1538     [ Response => $c->res ],
1539     [ Stash => $c->stash ],
1540     [ Config => $c->config ];
1541 }
1542
1543 =head2 $c->engine_class
1544
1545 Returns or sets the engine class.
1546
1547 =head2 $c->execute( $class, $coderef )
1548
1549 Execute a coderef in given class and catch exceptions. Errors are available
1550 via $c->error.
1551
1552 =cut
1553
1554 sub execute {
1555     my ( $c, $class, $code ) = @_;
1556     $class = $c->component($class) || $class;
1557     $c->state(0);
1558
1559     if ( $c->depth >= $RECURSION ) {
1560         my $action = $code->reverse();
1561         $action = "/$action" unless $action =~ /->/;
1562         my $error = qq/Deep recursion detected calling "${action}"/;
1563         $c->log->error($error);
1564         $c->error($error);
1565         $c->state(0);
1566         return $c->state;
1567     }
1568
1569     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1570
1571     push( @{ $c->stack }, $code );
1572
1573     no warnings 'recursion';
1574     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1575
1576     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1577
1578     my $last = pop( @{ $c->stack } );
1579
1580     if ( my $error = $@ ) {
1581         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1582             $error->rethrow if $c->depth > 1;
1583         }
1584         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1585             $error->rethrow if $c->depth > 0;
1586         }
1587         else {
1588             unless ( ref $error ) {
1589                 no warnings 'uninitialized';
1590                 chomp $error;
1591                 my $class = $last->class;
1592                 my $name  = $last->name;
1593                 $error = qq/Caught exception in $class->$name "$error"/;
1594             }
1595             $c->error($error);
1596             $c->state(0);
1597         }
1598     }
1599     return $c->state;
1600 }
1601
1602 sub _stats_start_execute {
1603     my ( $c, $code ) = @_;
1604     my $appclass = ref($c) || $c;
1605     return if ( ( $code->name =~ /^_.*/ )
1606         && ( !$appclass->config->{show_internal_actions} ) );
1607
1608     my $action_name = $code->reverse();
1609     $c->counter->{$action_name}++;
1610
1611     my $action = $action_name;
1612     $action = "/$action" unless $action =~ /->/;
1613
1614     # determine if the call was the result of a forward
1615     # this is done by walking up the call stack and looking for a calling
1616     # sub of Catalyst::forward before the eval
1617     my $callsub = q{};
1618     for my $index ( 2 .. 11 ) {
1619         last
1620         if ( ( caller($index) )[0] eq 'Catalyst'
1621             && ( caller($index) )[3] eq '(eval)' );
1622
1623         if ( ( caller($index) )[3] =~ /forward$/ ) {
1624             $callsub = ( caller($index) )[3];
1625             $action  = "-> $action";
1626             last;
1627         }
1628     }
1629
1630     my $uid = $action_name . $c->counter->{$action_name};
1631
1632     # is this a root-level call or a forwarded call?
1633     if ( $callsub =~ /forward$/ ) {
1634         my $parent = $c->stack->[-1];
1635
1636         # forward, locate the caller
1637         if ( exists $c->counter->{"$parent"} ) {
1638             $c->stats->profile(
1639                 begin  => $action,
1640                 parent => "$parent" . $c->counter->{"$parent"},
1641                 uid    => $uid,
1642             );
1643         }
1644         else {
1645
1646             # forward with no caller may come from a plugin
1647             $c->stats->profile(
1648                 begin => $action,
1649                 uid   => $uid,
1650             );
1651         }
1652     }
1653     else {
1654
1655         # root-level call
1656         $c->stats->profile(
1657             begin => $action,
1658             uid   => $uid,
1659         );
1660     }
1661     return $action;
1662
1663 }
1664
1665 sub _stats_finish_execute {
1666     my ( $c, $info ) = @_;
1667     $c->stats->profile( end => $info );
1668 }
1669
1670 =head2 $c->finalize
1671
1672 Finalizes the request.
1673
1674 =cut
1675
1676 sub finalize {
1677     my $c = shift;
1678
1679     for my $error ( @{ $c->error } ) {
1680         $c->log->error($error);
1681     }
1682
1683     # Allow engine to handle finalize flow (for POE)
1684     my $engine = $c->engine;
1685     if ( my $code = $engine->can('finalize') ) {
1686         $engine->$code($c);
1687     }
1688     else {
1689
1690         $c->finalize_uploads;
1691
1692         # Error
1693         if ( $#{ $c->error } >= 0 ) {
1694             $c->finalize_error;
1695         }
1696
1697         $c->finalize_headers;
1698
1699         # HEAD request
1700         if ( $c->request->method eq 'HEAD' ) {
1701             $c->response->body('');
1702         }
1703
1704         $c->finalize_body;
1705     }
1706
1707     if ($c->use_stats) {
1708         my $elapsed = sprintf '%f', $c->stats->elapsed;
1709         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1710         $c->log->info(
1711             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1712     }
1713
1714     return $c->response->status;
1715 }
1716
1717 =head2 $c->finalize_body
1718
1719 Finalizes body.
1720
1721 =cut
1722
1723 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1724
1725 =head2 $c->finalize_cookies
1726
1727 Finalizes cookies.
1728
1729 =cut
1730
1731 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1732
1733 =head2 $c->finalize_error
1734
1735 Finalizes error.
1736
1737 =cut
1738
1739 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1740
1741 =head2 $c->finalize_headers
1742
1743 Finalizes headers.
1744
1745 =cut
1746
1747 sub finalize_headers {
1748     my $c = shift;
1749
1750     my $response = $c->response; #accessor calls can add up?
1751
1752     # Check if we already finalized headers
1753     return if $response->finalized_headers;
1754
1755     # Handle redirects
1756     if ( my $location = $response->redirect ) {
1757         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1758         $response->header( Location => $location );
1759
1760         if ( !$response->has_body ) {
1761             # Add a default body if none is already present
1762             $response->body(
1763                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1764             );
1765         }
1766     }
1767
1768     # Content-Length
1769     if ( $response->body && !$response->content_length ) {
1770
1771         # get the length from a filehandle
1772         if ( blessed( $response->body ) && $response->body->can('read') )
1773         {
1774             my $stat = stat $response->body;
1775             if ( $stat && $stat->size > 0 ) {
1776                 $response->content_length( $stat->size );
1777             }
1778             else {
1779                 $c->log->warn('Serving filehandle without a content-length');
1780             }
1781         }
1782         else {
1783             # everything should be bytes at this point, but just in case
1784             $response->content_length( bytes::length( $response->body ) );
1785         }
1786     }
1787
1788     # Errors
1789     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1790         $response->headers->remove_header("Content-Length");
1791         $response->body('');
1792     }
1793
1794     $c->finalize_cookies;
1795
1796     $c->engine->finalize_headers( $c, @_ );
1797
1798     # Done
1799     $response->finalized_headers(1);
1800 }
1801
1802 =head2 $c->finalize_output
1803
1804 An alias for finalize_body.
1805
1806 =head2 $c->finalize_read
1807
1808 Finalizes the input after reading is complete.
1809
1810 =cut
1811
1812 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1813
1814 =head2 $c->finalize_uploads
1815
1816 Finalizes uploads. Cleans up any temporary files.
1817
1818 =cut
1819
1820 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1821
1822 =head2 $c->get_action( $action, $namespace )
1823
1824 Gets an action in a given namespace.
1825
1826 =cut
1827
1828 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1829
1830 =head2 $c->get_actions( $action, $namespace )
1831
1832 Gets all actions of a given name in a namespace and all parent
1833 namespaces.
1834
1835 =cut
1836
1837 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1838
1839 =head2 $c->handle_request( $class, @arguments )
1840
1841 Called to handle each HTTP request.
1842
1843 =cut
1844
1845 sub handle_request {
1846     my ( $class, @arguments ) = @_;
1847
1848     # Always expect worst case!
1849     my $status = -1;
1850     eval {
1851         if ($class->debug) {
1852             my $secs = time - $START || 1;
1853             my $av = sprintf '%.3f', $COUNT / $secs;
1854             my $time = localtime time;
1855             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1856         }
1857
1858         my $c = $class->prepare(@arguments);
1859         $c->dispatch;
1860         $status = $c->finalize;
1861     };
1862
1863     if ( my $error = $@ ) {
1864         chomp $error;
1865         $class->log->error(qq/Caught exception in engine "$error"/);
1866     }
1867
1868     $COUNT++;
1869
1870     if(my $coderef = $class->log->can('_flush')){
1871         $class->log->$coderef();
1872     }
1873     return $status;
1874 }
1875
1876 =head2 $c->prepare( @arguments )
1877
1878 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1879 etc.).
1880
1881 =cut
1882
1883 sub prepare {
1884     my ( $class, @arguments ) = @_;
1885
1886     # XXX
1887     # After the app/ctxt split, this should become an attribute based on something passed
1888     # into the application.
1889     $class->context_class( ref $class || $class ) unless $class->context_class;
1890
1891     my $c = $class->context_class->new({});
1892
1893     # For on-demand data
1894     $c->request->_context($c);
1895     $c->response->_context($c);
1896
1897     #surely this is not the most efficient way to do things...
1898     $c->stats($class->stats_class->new)->enable($c->use_stats);
1899     if ( $c->debug ) {
1900         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1901     }
1902
1903     #XXX reuse coderef from can
1904     # Allow engine to direct the prepare flow (for POE)
1905     if ( $c->engine->can('prepare') ) {
1906         $c->engine->prepare( $c, @arguments );
1907     }
1908     else {
1909         $c->prepare_request(@arguments);
1910         $c->prepare_connection;
1911         $c->prepare_query_parameters;
1912         $c->prepare_headers;
1913         $c->prepare_cookies;
1914         $c->prepare_path;
1915
1916         # Prepare the body for reading, either by prepare_body
1917         # or the user, if they are using $c->read
1918         $c->prepare_read;
1919
1920         # Parse the body unless the user wants it on-demand
1921         unless ( ref($c)->config->{parse_on_demand} ) {
1922             $c->prepare_body;
1923         }
1924     }
1925
1926     my $method  = $c->req->method  || '';
1927     my $path    = $c->req->path;
1928     $path       = '/' unless length $path;
1929     my $address = $c->req->address || '';
1930
1931     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1932       if $c->debug;
1933
1934     $c->prepare_action;
1935
1936     return $c;
1937 }
1938
1939 =head2 $c->prepare_action
1940
1941 Prepares action. See L<Catalyst::Dispatcher>.
1942
1943 =cut
1944
1945 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1946
1947 =head2 $c->prepare_body
1948
1949 Prepares message body.
1950
1951 =cut
1952
1953 sub prepare_body {
1954     my $c = shift;
1955
1956     return if $c->request->_has_body;
1957
1958     # Initialize on-demand data
1959     $c->engine->prepare_body( $c, @_ );
1960     $c->prepare_parameters;
1961     $c->prepare_uploads;
1962
1963     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1964         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1965         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1966             my $param = $c->req->body_parameters->{$key};
1967             my $value = defined($param) ? $param : '';
1968             $t->row( $key,
1969                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1970         }
1971         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1972     }
1973 }
1974
1975 =head2 $c->prepare_body_chunk( $chunk )
1976
1977 Prepares a chunk of data before sending it to L<HTTP::Body>.
1978
1979 See L<Catalyst::Engine>.
1980
1981 =cut
1982
1983 sub prepare_body_chunk {
1984     my $c = shift;
1985     $c->engine->prepare_body_chunk( $c, @_ );
1986 }
1987
1988 =head2 $c->prepare_body_parameters
1989
1990 Prepares body parameters.
1991
1992 =cut
1993
1994 sub prepare_body_parameters {
1995     my $c = shift;
1996     $c->engine->prepare_body_parameters( $c, @_ );
1997 }
1998
1999 =head2 $c->prepare_connection
2000
2001 Prepares connection.
2002
2003 =cut
2004
2005 sub prepare_connection {
2006     my $c = shift;
2007     $c->engine->prepare_connection( $c, @_ );
2008 }
2009
2010 =head2 $c->prepare_cookies
2011
2012 Prepares cookies.
2013
2014 =cut
2015
2016 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2017
2018 =head2 $c->prepare_headers
2019
2020 Prepares headers.
2021
2022 =cut
2023
2024 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2025
2026 =head2 $c->prepare_parameters
2027
2028 Prepares parameters.
2029
2030 =cut
2031
2032 sub prepare_parameters {
2033     my $c = shift;
2034     $c->prepare_body_parameters;
2035     $c->engine->prepare_parameters( $c, @_ );
2036 }
2037
2038 =head2 $c->prepare_path
2039
2040 Prepares path and base.
2041
2042 =cut
2043
2044 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2045
2046 =head2 $c->prepare_query_parameters
2047
2048 Prepares query parameters.
2049
2050 =cut
2051
2052 sub prepare_query_parameters {
2053     my $c = shift;
2054
2055     $c->engine->prepare_query_parameters( $c, @_ );
2056
2057     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
2058         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
2059         for my $key ( sort keys %{ $c->req->query_parameters } ) {
2060             my $param = $c->req->query_parameters->{$key};
2061             my $value = defined($param) ? $param : '';
2062             $t->row( $key,
2063                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2064         }
2065         $c->log->debug( "Query Parameters are:\n" . $t->draw );
2066     }
2067 }
2068
2069 =head2 $c->prepare_read
2070
2071 Prepares the input for reading.
2072
2073 =cut
2074
2075 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2076
2077 =head2 $c->prepare_request
2078
2079 Prepares the engine request.
2080
2081 =cut
2082
2083 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2084
2085 =head2 $c->prepare_uploads
2086
2087 Prepares uploads.
2088
2089 =cut
2090
2091 sub prepare_uploads {
2092     my $c = shift;
2093
2094     $c->engine->prepare_uploads( $c, @_ );
2095
2096     if ( $c->debug && keys %{ $c->request->uploads } ) {
2097         my $t = Text::SimpleTable->new(
2098             [ 12, 'Parameter' ],
2099             [ 26, 'Filename' ],
2100             [ 18, 'Type' ],
2101             [ 9,  'Size' ]
2102         );
2103         for my $key ( sort keys %{ $c->request->uploads } ) {
2104             my $upload = $c->request->uploads->{$key};
2105             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2106                 $t->row( $key, $u->filename, $u->type, $u->size );
2107             }
2108         }
2109         $c->log->debug( "File Uploads are:\n" . $t->draw );
2110     }
2111 }
2112
2113 =head2 $c->prepare_write
2114
2115 Prepares the output for writing.
2116
2117 =cut
2118
2119 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2120
2121 =head2 $c->request_class
2122
2123 Returns or sets the request class.
2124
2125 =head2 $c->response_class
2126
2127 Returns or sets the response class.
2128
2129 =head2 $c->read( [$maxlength] )
2130
2131 Reads a chunk of data from the request body. This method is designed to
2132 be used in a while loop, reading C<$maxlength> bytes on every call.
2133 C<$maxlength> defaults to the size of the request if not specified.
2134
2135 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2136 directly.
2137
2138 Warning: If you use read(), Catalyst will not process the body,
2139 so you will not be able to access POST parameters or file uploads via
2140 $c->request.  You must handle all body parsing yourself.
2141
2142 =cut
2143
2144 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2145
2146 =head2 $c->run
2147
2148 Starts the engine.
2149
2150 =cut
2151
2152 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2153
2154 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2155
2156 Sets an action in a given namespace.
2157
2158 =cut
2159
2160 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2161
2162 =head2 $c->setup_actions($component)
2163
2164 Sets up actions for a component.
2165
2166 =cut
2167
2168 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2169
2170 =head2 $c->setup_components
2171
2172 This method is called internally to set up the application's components.
2173
2174 It finds modules by calling the L<locate_components> method, expands them to
2175 package names with the L<expand_component_module> method, and then installs
2176 each component into the application.
2177
2178 The C<setup_components> config option is passed to both of the above methods.
2179
2180 Installation of each component is performed by the L<setup_component> method,
2181 below.
2182
2183 =cut
2184
2185 sub setup_components {
2186     my $class = shift;
2187
2188     my $config  = $class->config->{ setup_components };
2189
2190     my @comps = sort { length $a <=> length $b }
2191                 $class->locate_components($config);
2192     my %comps = map { $_ => 1 } @comps;
2193
2194     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2195     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2196         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2197     ) if $deprecatedcatalyst_component_names;
2198
2199     for my $component ( @comps ) {
2200
2201         # We pass ignore_loaded here so that overlay files for (e.g.)
2202         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2203         # we know M::P::O found a file on disk so this is safe
2204
2205         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2206
2207         # Needs to be done as soon as the component is loaded, as loading a sub-component
2208         # (next time round the loop) can cause us to get the wrong metaclass..
2209         $class->_controller_init_base_classes($component);
2210     }
2211
2212     for my $component (@comps) {
2213         $class->components->{ $component } = $class->setup_component($component);
2214         for my $component ($class->expand_component_module( $component, $config )) {
2215             next if $comps{$component};
2216             $class->_controller_init_base_classes($component); # Also cover inner packages
2217             $class->components->{ $component } = $class->setup_component($component);
2218         }
2219     }
2220 }
2221
2222 =head2 $c->locate_components( $setup_component_config )
2223
2224 This method is meant to provide a list of component modules that should be
2225 setup for the application.  By default, it will use L<Module::Pluggable>.
2226
2227 Specify a C<setup_components> config option to pass additional options directly
2228 to L<Module::Pluggable>. To add additional search paths, specify a key named
2229 C<search_extra> as an array reference. Items in the array beginning with C<::>
2230 will have the application class name prepended to them.
2231
2232 =cut
2233
2234 sub locate_components {
2235     my $class  = shift;
2236     my $config = shift;
2237
2238     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2239     my $extra   = delete $config->{ search_extra } || [];
2240
2241     push @paths, @$extra;
2242
2243     my $locator = Module::Pluggable::Object->new(
2244         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2245         %$config
2246     );
2247
2248     my @comps = $locator->plugins;
2249
2250     return @comps;
2251 }
2252
2253 =head2 $c->expand_component_module( $component, $setup_component_config )
2254
2255 Components found by C<locate_components> will be passed to this method, which
2256 is expected to return a list of component (package) names to be set up.
2257
2258 =cut
2259
2260 sub expand_component_module {
2261     my ($class, $module) = @_;
2262     return Devel::InnerPackage::list_packages( $module );
2263 }
2264
2265 =head2 $c->setup_component
2266
2267 =cut
2268
2269 # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2270 #         nearest to Catalyst::Controller first, no matter what order stuff happens
2271 #         to be loaded. There are TODO tests in Moose for this, see
2272 #         f2391d17574eff81d911b97be15ea51080500003
2273 sub _controller_init_base_classes {
2274     my ($app_class, $component) = @_;
2275     return unless $component->isa('Catalyst::Controller');
2276     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2277         Moose::Meta::Class->initialize( $class )
2278             unless find_meta($class);
2279     }
2280 }
2281
2282 sub setup_component {
2283     my( $class, $component ) = @_;
2284
2285     unless ( $component->can( 'COMPONENT' ) ) {
2286         return $component;
2287     }
2288
2289     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2290     my $config = $class->config->{ $suffix } || {};
2291     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2292     # methods also pass it. local to avoid pointlessly shitting in config
2293     # for the debug screen, as $component is already the key name.
2294     local $config->{catalyst_component_name} = $component;
2295
2296     my $instance = eval { $component->COMPONENT( $class, $config ); };
2297
2298     if ( my $error = $@ ) {
2299         chomp $error;
2300         Catalyst::Exception->throw(
2301             message => qq/Couldn't instantiate component "$component", "$error"/
2302         );
2303     }
2304
2305     unless (blessed $instance) {
2306         my $metaclass = Moose::Util::find_meta($component);
2307         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2308         my $component_method_from = $method_meta->associated_metaclass->name;
2309         my $value = defined($instance) ? $instance : 'undef';
2310         Catalyst::Exception->throw(
2311             message =>
2312             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2313         );
2314     }
2315     return $instance;
2316 }
2317
2318 =head2 $c->setup_dispatcher
2319
2320 Sets up dispatcher.
2321
2322 =cut
2323
2324 sub setup_dispatcher {
2325     my ( $class, $dispatcher ) = @_;
2326
2327     if ($dispatcher) {
2328         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2329     }
2330
2331     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2332         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2333     }
2334
2335     unless ($dispatcher) {
2336         $dispatcher = $class->dispatcher_class;
2337     }
2338
2339     Class::MOP::load_class($dispatcher);
2340
2341     # dispatcher instance
2342     $class->dispatcher( $dispatcher->new );
2343 }
2344
2345 =head2 $c->setup_engine
2346
2347 Sets up engine.
2348
2349 =cut
2350
2351 sub setup_engine {
2352     my ( $class, $engine ) = @_;
2353
2354     if ($engine) {
2355         $engine = 'Catalyst::Engine::' . $engine;
2356     }
2357
2358     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2359         $engine = 'Catalyst::Engine::' . $env;
2360     }
2361
2362     if ( $ENV{MOD_PERL} ) {
2363         my $meta = Class::MOP::get_metaclass_by_name($class);
2364
2365         # create the apache method
2366         $meta->add_method('apache' => sub { shift->engine->apache });
2367
2368         my ( $software, $version ) =
2369           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2370
2371         $version =~ s/_//g;
2372         $version =~ s/(\.[^.]+)\./$1/g;
2373
2374         if ( $software eq 'mod_perl' ) {
2375
2376             if ( !$engine ) {
2377
2378                 if ( $version >= 1.99922 ) {
2379                     $engine = 'Catalyst::Engine::Apache2::MP20';
2380                 }
2381
2382                 elsif ( $version >= 1.9901 ) {
2383                     $engine = 'Catalyst::Engine::Apache2::MP19';
2384                 }
2385
2386                 elsif ( $version >= 1.24 ) {
2387                     $engine = 'Catalyst::Engine::Apache::MP13';
2388                 }
2389
2390                 else {
2391                     Catalyst::Exception->throw( message =>
2392                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2393                 }
2394
2395             }
2396
2397             # install the correct mod_perl handler
2398             if ( $version >= 1.9901 ) {
2399                 *handler = sub  : method {
2400                     shift->handle_request(@_);
2401                 };
2402             }
2403             else {
2404                 *handler = sub ($$) { shift->handle_request(@_) };
2405             }
2406
2407         }
2408
2409         elsif ( $software eq 'Zeus-Perl' ) {
2410             $engine = 'Catalyst::Engine::Zeus';
2411         }
2412
2413         else {
2414             Catalyst::Exception->throw(
2415                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2416         }
2417     }
2418
2419     unless ($engine) {
2420         $engine = $class->engine_class;
2421     }
2422
2423     Class::MOP::load_class($engine);
2424
2425     # check for old engines that are no longer compatible
2426     my $old_engine;
2427     if ( $engine->isa('Catalyst::Engine::Apache')
2428         && !Catalyst::Engine::Apache->VERSION )
2429     {
2430         $old_engine = 1;
2431     }
2432
2433     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2434         && Catalyst::Engine::Server->VERSION le '0.02' )
2435     {
2436         $old_engine = 1;
2437     }
2438
2439     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2440         && $engine->VERSION eq '0.01' )
2441     {
2442         $old_engine = 1;
2443     }
2444
2445     elsif ($engine->isa('Catalyst::Engine::Zeus')
2446         && $engine->VERSION eq '0.01' )
2447     {
2448         $old_engine = 1;
2449     }
2450
2451     if ($old_engine) {
2452         Catalyst::Exception->throw( message =>
2453               qq/Engine "$engine" is not supported by this version of Catalyst/
2454         );
2455     }
2456
2457     # engine instance
2458     $class->engine( $engine->new );
2459 }
2460
2461 =head2 $c->setup_home
2462
2463 Sets up the home directory.
2464
2465 =cut
2466
2467 sub setup_home {
2468     my ( $class, $home ) = @_;
2469
2470     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2471         $home = $env;
2472     }
2473
2474     $home ||= Catalyst::Utils::home($class);
2475
2476     if ($home) {
2477         #I remember recently being scolded for assigning config values like this
2478         $class->config->{home} ||= $home;
2479         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2480     }
2481 }
2482
2483 =head2 $c->setup_log
2484
2485 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2486 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2487 log to.
2488
2489 This method also installs a C<debug> method that returns a true value into the
2490 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2491 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2492
2493 Note that if the log has already been setup, by either a previous call to
2494 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2495 that this method won't actually set up the log object.
2496
2497 =cut
2498
2499 sub setup_log {
2500     my ( $class, $levels ) = @_;
2501
2502     $levels ||= '';
2503     $levels =~ s/^\s+//;
2504     $levels =~ s/\s+$//;
2505     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2506
2507     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2508     if ( defined $env_debug ) {
2509         $levels{debug} = 1 if $env_debug; # Ugly!
2510         delete($levels{debug}) unless $env_debug;
2511     }
2512
2513     unless ( $class->log ) {
2514         $class->log( Catalyst::Log->new(keys %levels) );
2515     }
2516
2517     if ( $levels{debug} ) {
2518         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2519         $class->log->debug('Debug messages enabled');
2520     }
2521 }
2522
2523 =head2 $c->setup_plugins
2524
2525 Sets up plugins.
2526
2527 =cut
2528
2529 =head2 $c->setup_stats
2530
2531 Sets up timing statistics class.
2532
2533 =cut
2534
2535 sub setup_stats {
2536     my ( $class, $stats ) = @_;
2537
2538     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2539
2540     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2541     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2542         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2543         $class->log->debug('Statistics enabled');
2544     }
2545 }
2546
2547
2548 =head2 $c->registered_plugins
2549
2550 Returns a sorted list of the plugins which have either been stated in the
2551 import list or which have been added via C<< MyApp->plugin(@args); >>.
2552
2553 If passed a given plugin name, it will report a boolean value indicating
2554 whether or not that plugin is loaded.  A fully qualified name is required if
2555 the plugin name does not begin with C<Catalyst::Plugin::>.
2556
2557  if ($c->registered_plugins('Some::Plugin')) {
2558      ...
2559  }
2560
2561 =cut
2562
2563 {
2564
2565     sub registered_plugins {
2566         my $proto = shift;
2567         return sort keys %{ $proto->_plugins } unless @_;
2568         my $plugin = shift;
2569         return 1 if exists $proto->_plugins->{$plugin};
2570         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2571     }
2572
2573     sub _register_plugin {
2574         my ( $proto, $plugin, $instant ) = @_;
2575         my $class = ref $proto || $proto;
2576
2577         Class::MOP::load_class( $plugin );
2578
2579         $proto->_plugins->{$plugin} = 1;
2580         unless ($instant) {
2581             no strict 'refs';
2582             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2583               my @superclasses = ($plugin, $meta->superclasses );
2584               $meta->superclasses(@superclasses);
2585             } else {
2586               unshift @{"$class\::ISA"}, $plugin;
2587             }
2588         }
2589         return $class;
2590     }
2591
2592     sub setup_plugins {
2593         my ( $class, $plugins ) = @_;
2594
2595         $class->_plugins( {} ) unless $class->_plugins;
2596         $plugins ||= [];
2597
2598         my @plugins = Catalyst::Utils::resolve_namespace($class . '::Plugin', 'Catalyst::Plugin', @$plugins);
2599
2600         for my $plugin ( reverse @plugins ) {
2601             Class::MOP::load_class($plugin);
2602             my $meta = find_meta($plugin);
2603             next if $meta && $meta->isa('Moose::Meta::Role');
2604
2605             $class->_register_plugin($plugin);
2606         }
2607
2608         my @roles =
2609             map { $_->name }
2610             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2611             map { find_meta($_) }
2612             @plugins;
2613
2614         Moose::Util::apply_all_roles(
2615             $class => @roles
2616         ) if @roles;
2617     }
2618 }
2619
2620 =head2 $c->stack
2621
2622 Returns an arrayref of the internal execution stack (actions that are
2623 currently executing).
2624
2625 =head2 $c->stats_class
2626
2627 Returns or sets the stats (timing statistics) class.
2628
2629 =head2 $c->use_stats
2630
2631 Returns 1 when stats collection is enabled.  Stats collection is enabled
2632 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2633 environment variable is set.
2634
2635 Note that this is a static method, not an accessor and should be overridden
2636 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2637
2638 =cut
2639
2640 sub use_stats { 0 }
2641
2642
2643 =head2 $c->write( $data )
2644
2645 Writes $data to the output stream. When using this method directly, you
2646 will need to manually set the C<Content-Length> header to the length of
2647 your output data, if known.
2648
2649 =cut
2650
2651 sub write {
2652     my $c = shift;
2653
2654     # Finalize headers if someone manually writes output
2655     $c->finalize_headers;
2656
2657     return $c->engine->write( $c, @_ );
2658 }
2659
2660 =head2 version
2661
2662 Returns the Catalyst version number. Mostly useful for "powered by"
2663 messages in template systems.
2664
2665 =cut
2666
2667 sub version { return $Catalyst::VERSION }
2668
2669 =head1 CONFIGURATION
2670
2671 There are a number of 'base' config variables which can be set:
2672
2673 =over
2674
2675 =item *
2676
2677 C<case_sensitive> - Makes private paths case sensitive. See L</CASE SENSITIVITY>.
2678
2679 =item *
2680
2681 C<default_model> - The default model picked if you say C<< $c->model >>. See L</$c->model($name)>.
2682
2683 =item *
2684
2685 C<default_view> - The default view to be rendered or returned when C<< $c->view >>. See L</$c->view($name)>.
2686 is called.
2687
2688 =item *
2689
2690 C<disable_component_resolution_regex_fallback> - Turns
2691 off the deprecated component resolution functionality so
2692 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2693 are called then regex search will not be attempted on string values and
2694 instead C<undef> will be returned.
2695
2696 =item *
2697
2698 C<home> - The application home directory. In an uninstalled application,
2699 this is the top level application directory. In an installed application,
2700 this will be the directory containing C<< MyApp.pm >>.
2701
2702 =item *
2703
2704 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2705
2706 =item *
2707
2708 C<name> - The name of the application in debug messages and the debug and
2709 welcome screens
2710
2711 =item *
2712
2713 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2714 until it is accessed. This allows you to (for example) check authentication (and reject
2715 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2716
2717 =item *
2718
2719 C<root> - The root directory for templates. Usually this is just a
2720 subdirectory of the home directory, but you can set it to change the
2721 templates to a different directory.
2722
2723 =item *
2724
2725 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2726 namespaces from which components will be loaded (and constructed and stored in
2727 C<< $c->components >>).
2728
2729 =item *
2730
2731 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2732 to be shown in hit debug tables in the test server.
2733
2734 =item *
2735
2736 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2737
2738 =back
2739
2740 =head1 INTERNAL ACTIONS
2741
2742 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2743 C<_ACTION>, and C<_END>. These are by default not shown in the private
2744 action table, but you can make them visible with a config parameter.
2745
2746     MyApp->config(show_internal_actions => 1);
2747
2748 =head1 CASE SENSITIVITY
2749
2750 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2751 mapped to C</foo/bar>. You can activate case sensitivity with a config
2752 parameter.
2753
2754     MyApp->config(case_sensitive => 1);
2755
2756 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2757
2758 =head1 ON-DEMAND PARSER
2759
2760 The request body is usually parsed at the beginning of a request,
2761 but if you want to handle input yourself, you can enable on-demand
2762 parsing with a config parameter.
2763
2764     MyApp->config(parse_on_demand => 1);
2765
2766 =head1 PROXY SUPPORT
2767
2768 Many production servers operate using the common double-server approach,
2769 with a lightweight frontend web server passing requests to a larger
2770 backend server. An application running on the backend server must deal
2771 with two problems: the remote user always appears to be C<127.0.0.1> and
2772 the server's hostname will appear to be C<localhost> regardless of the
2773 virtual host that the user connected through.
2774
2775 Catalyst will automatically detect this situation when you are running
2776 the frontend and backend servers on the same machine. The following
2777 changes are made to the request.
2778
2779     $c->req->address is set to the user's real IP address, as read from
2780     the HTTP X-Forwarded-For header.
2781
2782     The host value for $c->req->base and $c->req->uri is set to the real
2783     host, as read from the HTTP X-Forwarded-Host header.
2784
2785 Additionally, you may be running your backend application on an insecure
2786 connection (port 80) while your frontend proxy is running under SSL.  If there
2787 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2788 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2789 be created properly.
2790
2791 In the case of passing in:
2792
2793     X-Forwarded-Port: 443
2794
2795 All calls to C<uri_for> will result in an https link, as is expected.
2796
2797 Obviously, your web server must support these headers for this to work.
2798
2799 In a more complex server farm environment where you may have your
2800 frontend proxy server(s) on different machines, you will need to set a
2801 configuration option to tell Catalyst to read the proxied data from the
2802 headers.
2803
2804     MyApp->config(using_frontend_proxy => 1);
2805
2806 If you do not wish to use the proxy support at all, you may set:
2807
2808     MyApp->config(ignore_frontend_proxy => 1);
2809
2810 =head1 THREAD SAFETY
2811
2812 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2813 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2814 believe the Catalyst core to be thread-safe.
2815
2816 If you plan to operate in a threaded environment, remember that all other
2817 modules you are using must also be thread-safe. Some modules, most notably
2818 L<DBD::SQLite>, are not thread-safe.
2819
2820 =head1 SUPPORT
2821
2822 IRC:
2823
2824     Join #catalyst on irc.perl.org.
2825
2826 Mailing Lists:
2827
2828     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2829     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2830
2831 Web:
2832
2833     http://catalyst.perl.org
2834
2835 Wiki:
2836
2837     http://dev.catalyst.perl.org
2838
2839 =head1 SEE ALSO
2840
2841 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2842
2843 =head2 L<Catalyst::Manual> - The Catalyst Manual
2844
2845 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2846
2847 =head2 L<Catalyst::Engine> - Core engine
2848
2849 =head2 L<Catalyst::Log> - Log class.
2850
2851 =head2 L<Catalyst::Request> - Request object
2852
2853 =head2 L<Catalyst::Response> - Response object
2854
2855 =head2 L<Catalyst::Test> - The test suite.
2856
2857 =head1 PROJECT FOUNDER
2858
2859 sri: Sebastian Riedel <sri@cpan.org>
2860
2861 =head1 CONTRIBUTORS
2862
2863 abw: Andy Wardley
2864
2865 acme: Leon Brocard <leon@astray.com>
2866
2867 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
2868
2869 Andrew Bramble
2870
2871 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
2872
2873 Andrew Ruthven
2874
2875 andyg: Andy Grundman <andy@hybridized.org>
2876
2877 audreyt: Audrey Tang
2878
2879 bricas: Brian Cassidy <bricas@cpan.org>
2880
2881 Caelum: Rafael Kitover <rkitover@io.com>
2882
2883 chansen: Christian Hansen
2884
2885 chicks: Christopher Hicks
2886
2887 Chisel Wright C<pause@herlpacker.co.uk>
2888
2889 Danijel Milicevic C<me@danijel.de>
2890
2891 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
2892
2893 David Naughton, C<naughton@umn.edu>
2894
2895 David E. Wheeler
2896
2897 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2898
2899 Drew Taylor
2900
2901 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2902
2903 esskar: Sascha Kiefer
2904
2905 fireartist: Carl Franks <cfranks@cpan.org>
2906
2907 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
2908
2909 gabb: Danijel Milicevic
2910
2911 Gary Ashton Jones
2912
2913 Gavin Henry C<ghenry@perl.me.uk>
2914
2915 Geoff Richards
2916
2917 groditi: Guillermo Roditi <groditi@gmail.com>
2918
2919 hobbs: Andrew Rodland <andrew@cleverdomain.org>
2920
2921 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2922
2923 jcamacho: Juan Camacho
2924
2925 jester: Jesse Sheidlower C<jester@panix.com>
2926
2927 jhannah: Jay Hannah <jay@jays.net>
2928
2929 Jody Belka
2930
2931 Johan Lindstrom
2932
2933 jon: Jon Schutz <jjschutz@cpan.org>
2934
2935 Jonathan Rockway C<< <jrockway@cpan.org> >>
2936
2937 Kieren Diment C<kd@totaldatasolution.com>
2938
2939 konobi: Scott McWhirter <konobi@cpan.org>
2940
2941 marcus: Marcus Ramberg <mramberg@cpan.org>
2942
2943 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2944
2945 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2946
2947 mugwump: Sam Vilain
2948
2949 naughton: David Naughton
2950
2951 ningu: David Kamholz <dkamholz@cpan.org>
2952
2953 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2954
2955 numa: Dan Sully <daniel@cpan.org>
2956
2957 obra: Jesse Vincent
2958
2959 omega: Andreas Marienborg
2960
2961 Oleg Kostyuk <cub.uanic@gmail.com>
2962
2963 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2964
2965 rafl: Florian Ragwitz <rafl@debian.org>
2966
2967 random: Roland Lammel <lammel@cpan.org>
2968
2969 Robert Sedlacek C<< <rs@474.at> >>
2970
2971 sky: Arthur Bergman
2972
2973 t0m: Tomas Doran <bobtfish@bobtfish.net>
2974
2975 Ulf Edvinsson
2976
2977 Viljo Marrandi C<vilts@yahoo.com>
2978
2979 Will Hawes C<info@whawes.co.uk>
2980
2981 willert: Sebastian Willert <willert@cpan.org>
2982
2983 Yuval Kogman, C<nothingmuch@woobling.org>
2984
2985 =head1 LICENSE
2986
2987 This library is free software. You can redistribute it and/or modify it under
2988 the same terms as Perl itself.
2989
2990 =cut
2991
2992 no Moose;
2993
2994 __PACKAGE__->meta->make_immutable;
2995
2996 1;