lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54 use Scalar::Util;
  55
  56 BEGIN { require 5.008003; }
  57
  58 has stack => (is => 'ro', default => sub { [] });
  59 has state => (is => 'rw', default => 0);
  60 has stats => (is => 'rw');
  61 has action => (is => 'rw');
  62 has counter => (is => 'rw', default => sub { {} });
  63 has request => (
  64     is => 'rw',
  65     default => sub {
  66         my $self = shift;
  67         my $class = ref $self;
  68         my $composed_request_class = $class->composed_request_class;
  69         return $composed_request_class->new( $self->_build_request_constructor_args);
  70     },
  71     lazy => 1,
  72 );
  73 sub _build_request_constructor_args {
  74     my $self = shift;
  75     my %p = ( _log => $self->log );
  76     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  77     $p{data_handlers} = {$self->registered_data_handlers};
  78     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  79       if $self->config->{use_hash_multivalue_in_request};
  80     \%p;
  81 }
  82
  83 sub composed_request_class {
  84   my $class = shift;
  85   return $class->_composed_request_class if $class->_composed_request_class;
  86
  87   my @traits = (@{$class->request_class_traits||[]}, @{$class->config->{request_class_traits}||[]});
  88
  89   # For each trait listed, figure out what the namespace is.  First we try the $trait
  90   # as it is in the config.  Then try $MyApp::TraitFor::Request:$trait. Last we try
  91   # Catalyst::TraitFor::Request::$trait.  If none load, throw error.
  92
  93   my $trait_ns = 'TraitFor::Request';
  94   my @normalized_traits = map {
  95     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
  96   } @traits;
  97
  98   if ($class->debug && scalar(@normalized_traits)) {
  99       my $column_width = Catalyst::Utils::term_width() - 6;
 100       my $t = Text::SimpleTable->new($column_width);
 101       $t->row($_) for @normalized_traits;
 102       $class->log->debug( "Composed Request Class Traits:\n" . $t->draw . "\n" );
 103   }
 104
 105   return $class->_composed_request_class(Moose::Util::with_traits($class->request_class, @normalized_traits));
 106 }
 107
 108 has response => (
 109     is => 'rw',
 110     default => sub {
 111         my $self = shift;
 112         my $class = ref $self;
 113         my $composed_response_class = $class->composed_response_class;
 114         return $composed_response_class->new( $self->_build_response_constructor_args);
 115     },
 116     lazy => 1,
 117 );
 118 sub _build_response_constructor_args {
 119     return +{
 120       _log => $_[0]->log,
 121       encoding => $_[0]->encoding,
 122     };
 123 }
 124
 125 sub composed_response_class {
 126   my $class = shift;
 127   return $class->_composed_response_class if $class->_composed_response_class;
 128
 129   my @traits = (@{$class->response_class_traits||[]}, @{$class->config->{response_class_traits}||[]});
 130
 131   my $trait_ns = 'TraitFor::Response';
 132   my @normalized_traits = map {
 133     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
 134   } @traits;
 135
 136   if ($class->debug && scalar(@normalized_traits)) {
 137       my $column_width = Catalyst::Utils::term_width() - 6;
 138       my $t = Text::SimpleTable->new($column_width);
 139       $t->row($_) for @normalized_traits;
 140       $class->log->debug( "Composed Response Class Traits:\n" . $t->draw . "\n" );
 141   }
 142
 143   return $class->_composed_response_class(Moose::Util::with_traits($class->response_class, @normalized_traits));
 144 }
 145
 146 has namespace => (is => 'rw');
 147
 148 sub depth { scalar @{ shift->stack || [] }; }
 149 sub comp { shift->component(@_) }
 150
 151 sub req {
 152     my $self = shift; return $self->request(@_);
 153 }
 154 sub res {
 155     my $self = shift; return $self->response(@_);
 156 }
 157
 158 # For backwards compatibility
 159 sub finalize_output { shift->finalize_body(@_) };
 160
 161 # For statistics
 162 our $COUNT     = 1;
 163 our $START     = time;
 164 our $RECURSION = 1000;
 165 our $DETACH    = Catalyst::Exception::Detach->new;
 166 our $GO        = Catalyst::Exception::Go->new;
 167
 168 #I imagine that very few of these really
 169 #need to be class variables. if any.
 170 #maybe we should just make them attributes with a default?
 171 __PACKAGE__->mk_classdata($_)
 172   for qw/components arguments dispatcher engine log dispatcher_class
 173   engine_loader context_class request_class response_class stats_class
 174   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 175   _data_handlers _encoding _encode_check finalized_default_middleware
 176   request_class_traits response_class_traits stats_class_traits
 177   _composed_request_class _composed_response_class _composed_stats_class/;
 178
 179 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 180 __PACKAGE__->request_class('Catalyst::Request');
 181 __PACKAGE__->response_class('Catalyst::Response');
 182 __PACKAGE__->stats_class('Catalyst::Stats');
 183
 184 sub composed_stats_class {
 185   my $class = shift;
 186   return $class->_composed_stats_class if $class->_composed_stats_class;
 187
 188   my @traits = (@{$class->stats_class_traits||[]}, @{$class->config->{stats_class_traits}||[]});
 189
 190   my $trait_ns = 'TraitFor::Stats';
 191   my @normalized_traits = map {
 192     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
 193   } @traits;
 194
 195   if ($class->debug && scalar(@normalized_traits)) {
 196       my $column_width = Catalyst::Utils::term_width() - 6;
 197       my $t = Text::SimpleTable->new($column_width);
 198       $t->row($_) for @normalized_traits;
 199       $class->log->debug( "Composed Stats Class Traits:\n" . $t->draw . "\n" );
 200   }
 201
 202   return $class->_composed_stats_class(Moose::Util::with_traits($class->stats_class, @normalized_traits));
 203 }
 204
 205 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 206
 207 # Remember to update this in Catalyst::Runtime as well!
 208 our $VERSION = '5.90114';
 209 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 210
 211 sub import {
 212     my ( $class, @arguments ) = @_;
 213
 214     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 215     # callers @ISA.
 216     return unless $class eq 'Catalyst';
 217
 218     my $caller = caller();
 219     return if $caller eq 'main';
 220
 221     my $meta = Moose::Meta::Class->initialize($caller);
 222     unless ( $caller->isa('Catalyst') ) {
 223         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 224         $meta->superclasses(@superclasses);
 225     }
 226     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 227     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 228
 229     unless( $meta->has_method('meta') ){
 230         if ($Moose::VERSION >= 1.15) {
 231             $meta->_add_meta_method('meta');
 232         }
 233         else {
 234             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 235         }
 236     }
 237
 238     $caller->arguments( [@arguments] );
 239     $caller->setup_home;
 240 }
 241
 242 sub _application { $_[0] }
 243
 244 =encoding UTF-8
 245
 246 =head1 NAME
 247
 248 Catalyst - The Elegant MVC Web Application Framework
 249
 250 =for html
 251 <a href="https://badge.fury.io/pl/Catalyst-Runtime"><img src="https://badge.fury.io/pl/Catalyst-Runtime.svg" alt="CPAN version" height="18"></a>
 252 <a href="https://travis-ci.org/perl-catalyst/catalyst-runtime/"><img src="https://api.travis-ci.org/perl-catalyst/catalyst-runtime.png" alt="Catalyst></a>
 253 <a href="http://cpants.cpanauthors.org/dist/Catalyst-Runtime"><img src="http://cpants.cpanauthors.org/dist/Catalyst-Runtime.png" alt='Kwalitee Score' /></a>
 254
 255 =head1 SYNOPSIS
 256
 257 See the L<Catalyst::Manual> distribution for comprehensive
 258 documentation and tutorials.
 259
 260     # Install Catalyst::Devel for helpers and other development tools
 261     # use the helper to create a new application
 262     catalyst.pl MyApp
 263
 264     # add models, views, controllers
 265     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 266     script/myapp_create.pl view MyTemplate TT
 267     script/myapp_create.pl controller Search
 268
 269     # built in testserver -- use -r to restart automatically on changes
 270     # --help to see all available options
 271     script/myapp_server.pl
 272
 273     # command line testing interface
 274     script/myapp_test.pl /yada
 275
 276     ### in lib/MyApp.pm
 277     use Catalyst qw/-Debug/; # include plugins here as well
 278
 279     ### In lib/MyApp/Controller/Root.pm (autocreated)
 280     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 281         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 282         $c->stash->{template} = 'foo.tt'; # set the template
 283         # lookup something from db -- stash vars are passed to TT
 284         $c->stash->{data} =
 285           $c->model('Database::Foo')->search( { country => $args[0] } );
 286         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 287             $c->forward( 'bar' ); # process another action
 288             # do something else after forward returns
 289         }
 290     }
 291
 292     # The foo.tt TT template can use the stash data from the database
 293     [% WHILE (item = data.next) %]
 294         [% item.foo %]
 295     [% END %]
 296
 297     # called for /bar/of/soap, /bar/of/soap/10, etc.
 298     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 299
 300     # called after all actions are finished
 301     sub end : Action {
 302         my ( $self, $c ) = @_;
 303         if ( scalar @{ $c->error } ) { ... } # handle errors
 304         return if $c->res->body; # already have a response
 305         $c->forward( 'MyApp::View::TT' ); # render template
 306     }
 307
 308 See L<Catalyst::Manual::Intro> for additional information.
 309
 310 =head1 DESCRIPTION
 311
 312 Catalyst is a modern framework for making web applications without the
 313 pain usually associated with this process. This document is a reference
 314 to the main Catalyst application. If you are a new user, we suggest you
 315 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 316
 317 See L<Catalyst::Manual> for more documentation.
 318
 319 Catalyst plugins can be loaded by naming them as arguments to the "use
 320 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 321 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 322 C<My::Module>.
 323
 324     use Catalyst qw/My::Module/;
 325
 326 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 327 fully qualify the name by using a unary plus:
 328
 329     use Catalyst qw/
 330         My::Module
 331         +Fully::Qualified::Plugin::Name
 332     /;
 333
 334 Special flags like C<-Debug> can also be specified as
 335 arguments when Catalyst is loaded:
 336
 337     use Catalyst qw/-Debug My::Module/;
 338
 339 The position of plugins and flags in the chain is important, because
 340 they are loaded in the order in which they appear.
 341
 342 The following flags are supported:
 343
 344 =head2 -Debug
 345
 346 Enables debug output. You can also force this setting from the system
 347 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 348 settings override the application, with <MYAPP>_DEBUG having the highest
 349 priority.
 350
 351 This sets the log level to 'debug' and enables full debug output on the
 352 error screen. If you only want the latter, see L<< $c->debug >>.
 353
 354 =head2 -Home
 355
 356 Forces Catalyst to use a specific home directory, e.g.:
 357
 358     use Catalyst qw[-Home=/usr/mst];
 359
 360 This can also be done in the shell environment by setting either the
 361 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 362 is replaced with the uppercased name of your application, any "::" in
 363 the name will be replaced with underscores, e.g. MyApp::Web should use
 364 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 365
 366 If none of these are set, Catalyst will attempt to automatically detect the
 367 home directory. If you are working in a development environment, Catalyst
 368 will try and find the directory containing either Makefile.PL, Build.PL,
 369 dist.ini, or cpanfile. If the application has been installed into the system
 370 (i.e. you have done C<make install>), then Catalyst will use the path to your
 371 application module, without the .pm extension (e.g., /foo/MyApp if your
 372 application was installed at /foo/MyApp.pm)
 373
 374 =head2 -Log
 375
 376     use Catalyst '-Log=warn,fatal,error';
 377
 378 Specifies a comma-delimited list of log levels.
 379
 380 =head2 -Stats
 381
 382 Enables statistics collection and reporting.
 383
 384    use Catalyst qw/-Stats=1/;
 385
 386 You can also force this setting from the system environment with CATALYST_STATS
 387 or <MYAPP>_STATS. The environment settings override the application, with
 388 <MYAPP>_STATS having the highest priority.
 389
 390 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 391
 392 =head1 METHODS
 393
 394 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 395
 396 =head2 $c->action
 397
 398 Returns a L<Catalyst::Action> object for the current action, which
 399 stringifies to the action name. See L<Catalyst::Action>.
 400
 401 =head2 $c->namespace
 402
 403 Returns the namespace of the current action, i.e., the URI prefix
 404 corresponding to the controller of the current action. For example:
 405
 406     # in Controller::Foo::Bar
 407     $c->namespace; # returns 'foo/bar';
 408
 409 =head2 $c->request
 410
 411 =head2 $c->req
 412
 413 Returns the current L<Catalyst::Request> object, giving access to
 414 information about the current client request (including parameters,
 415 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 416
 417 =head2 REQUEST FLOW HANDLING
 418
 419 =head2 $c->forward( $action [, \@arguments ] )
 420
 421 =head2 $c->forward( $class, $method, [, \@arguments ] )
 422
 423 This is one way of calling another action (method) in the same or
 424 a different controller. You can also use C<< $self->my_method($c, @args) >>
 425 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 426 in a different controller.
 427 The main difference is that 'forward' uses some of the Catalyst request
 428 cycle overhead, including debugging, which may be useful to you. On the
 429 other hand, there are some complications to using 'forward', restrictions
 430 on values returned from 'forward', and it may not handle errors as you prefer.
 431 Whether you use 'forward' or not is up to you; it is not considered superior to
 432 the other ways to call a method.
 433
 434 'forward' calls  another action, by its private name. If you give a
 435 class name but no method, C<process()> is called. You may also optionally
 436 pass arguments in an arrayref. The action will receive the arguments in
 437 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 438 C<< $c->req->args >> will be restored to the previous values.
 439
 440 Any data C<return>ed from the action forwarded to, will be returned by the
 441 call to forward.
 442
 443     my $foodata = $c->forward('/foo');
 444     $c->forward('index');
 445     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 446     $c->forward('View::TT');
 447
 448 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 449 an C<< eval { } >> around the call (actually
 450 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 451 exceptions thrown by the called action non-fatal and pushing them onto
 452 $c->error instead. If you want C<die> to propagate you need to do something
 453 like:
 454
 455     $c->forward('foo');
 456     die join "\n", @{ $c->error } if @{ $c->error };
 457
 458 Or make sure to always return true values from your actions and write
 459 your code like this:
 460
 461     $c->forward('foo') || return;
 462
 463 Another note is that C<< $c->forward >> always returns a scalar because it
 464 actually returns $c->state which operates in a scalar context.
 465 Thus, something like:
 466
 467     return @array;
 468
 469 in an action that is forwarded to is going to return a scalar,
 470 i.e. how many items are in that array, which is probably not what you want.
 471 If you need to return an array then return a reference to it,
 472 or stash it like so:
 473
 474     $c->stash->{array} = \@array;
 475
 476 and access it from the stash.
 477
 478 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 479
 480 =cut
 481
 482 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 483
 484 =head2 $c->detach( $action [, \@arguments ] )
 485
 486 =head2 $c->detach( $class, $method, [, \@arguments ] )
 487
 488 =head2 $c->detach()
 489
 490 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 491 doesn't return to the previous action when processing is finished.
 492
 493 When called with no arguments it escapes the processing chain entirely.
 494
 495 =cut
 496
 497 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 498
 499 =head2 $c->visit( $action [, \@arguments ] )
 500
 501 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 502
 503 =head2 $c->visit( $class, $method, [, \@arguments ] )
 504
 505 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 506
 507 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 508 but does a full dispatch, instead of just calling the new C<$action> /
 509 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 510 you go to are called, just like a new request.
 511
 512 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 513 This means, for example, that C<< $c->action >> methods such as
 514 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 515 L<reverse|Catalyst::Action/reverse> return information for the visited action
 516 when they are invoked within the visited action.  This is different from the
 517 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 518 continues to use the $c->action object from the caller action even when
 519 invoked from the called action.
 520
 521 C<< $c->stash >> is kept unchanged.
 522
 523 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 524 allows you to "wrap" another action, just as it would have been called by
 525 dispatching from a URL, while the analogous
 526 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 527 transfer control to another action as if it had been reached directly from a URL.
 528
 529 =cut
 530
 531 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 532
 533 =head2 $c->go( $action [, \@arguments ] )
 534
 535 =head2 $c->go( $action [, \@captures, \@arguments ] )
 536
 537 =head2 $c->go( $class, $method, [, \@arguments ] )
 538
 539 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 540
 541 The relationship between C<go> and
 542 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 543 the relationship between
 544 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 545 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 546 C<< $c->go >> will perform a full dispatch on the specified action or method,
 547 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 548 C<go> escapes the processing of the current request chain on completion, and
 549 does not return to its caller.
 550
 551 @arguments are arguments to the final destination of $action. @captures are
 552 arguments to the intermediate steps, if any, on the way to the final sub of
 553 $action.
 554
 555 =cut
 556
 557 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 558
 559 =head2 $c->response
 560
 561 =head2 $c->res
 562
 563 Returns the current L<Catalyst::Response> object, see there for details.
 564
 565 =head2 $c->stash
 566
 567 Returns a hashref to the stash, which may be used to store data and pass
 568 it between components during a request. You can also set hash keys by
 569 passing arguments. The stash is automatically sent to the view. The
 570 stash is cleared at the end of a request; it cannot be used for
 571 persistent storage (for this you must use a session; see
 572 L<Catalyst::Plugin::Session> for a complete system integrated with
 573 Catalyst).
 574
 575     $c->stash->{foo} = $bar;
 576     $c->stash( { moose => 'majestic', qux => 0 } );
 577     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 578
 579     # stash is automatically passed to the view for use in a template
 580     $c->forward( 'MyApp::View::TT' );
 581
 582 The stash hash is currently stored in the PSGI C<$env> and is managed by
 583 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 584 the stash can be accessed in sub applications mounted under your main
 585 L<Catalyst> application.  For example if you delegate the response of an
 586 action to another L<Catalyst> application, that sub application will have
 587 access to all the stash keys of the main one, and if can of course add
 588 more keys of its own.  However those new keys will not 'bubble' back up
 589 to the main application.
 590
 591 For more information the best thing to do is to review the test case:
 592 t/middleware-stash.t in the distribution /t directory.
 593
 594 =cut
 595
 596 sub stash {
 597   my $c = shift;
 598   $c->log->error("You are requesting the stash but you don't have a context") unless blessed $c;
 599   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 600 }
 601
 602 =head2 $c->error
 603
 604 =head2 $c->error($error, ...)
 605
 606 =head2 $c->error($arrayref)
 607
 608 Returns an arrayref containing error messages.  If Catalyst encounters an
 609 error while processing a request, it stores the error in $c->error.  This
 610 method should only be used to store fatal error messages.
 611
 612     my @error = @{ $c->error };
 613
 614 Add a new error.
 615
 616     $c->error('Something bad happened');
 617
 618 Calling this will always return an arrayref (if there are no errors it
 619 will be an empty arrayref.
 620
 621 =cut
 622
 623 sub error {
 624     my $c = shift;
 625     if ( $_[0] ) {
 626         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 627         croak @$error unless ref $c;
 628         push @{ $c->{error} }, @$error;
 629     }
 630     elsif ( defined $_[0] ) { $c->{error} = undef }
 631     return $c->{error} || [];
 632 }
 633
 634 =head2 $c->state
 635
 636 Contains the return value of the last executed action.
 637 Note that << $c->state >> operates in a scalar context which means that all
 638 values it returns are scalar.
 639
 640 Please note that if an action throws an exception, the value of state
 641 should no longer be considered the return if the last action.  It is generally
 642 going to be 0, which indicates an error state.  Examine $c->error for error
 643 details.
 644
 645 =head2 $c->clear_errors
 646
 647 Clear errors.  You probably don't want to clear the errors unless you are
 648 implementing a custom error screen.
 649
 650 This is equivalent to running
 651
 652     $c->error(0);
 653
 654 =cut
 655
 656 sub clear_errors {
 657     my $c = shift;
 658     $c->error(0);
 659 }
 660
 661 =head2 $c->has_errors
 662
 663 Returns true if you have errors
 664
 665 =cut
 666
 667 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 668
 669 =head2 $c->last_error
 670
 671 Returns the most recent error in the stack (the one most recently added...)
 672 or nothing if there are no errors.  This does not modify the contents of the
 673 error stack.
 674
 675 =cut
 676
 677 sub last_error {
 678   my (@errs) = @{shift->error};
 679   return scalar(@errs) ? $errs[-1]: undef;
 680 }
 681
 682 =head2 shift_errors
 683
 684 shifts the most recently added error off the error stack and returns it.  Returns
 685 nothing if there are no more errors.
 686
 687 =cut
 688
 689 sub shift_errors {
 690     my ($self) = @_;
 691     my @errors = @{$self->error};
 692     my $err = shift(@errors);
 693     $self->{error} = \@errors;
 694     return $err;
 695 }
 696
 697 =head2 pop_errors
 698
 699 pops the most recently added error off the error stack and returns it.  Returns
 700 nothing if there are no more errors.
 701
 702 =cut
 703
 704 sub pop_errors {
 705     my ($self) = @_;
 706     my @errors = @{$self->error};
 707     my $err = pop(@errors);
 708     $self->{error} = \@errors;
 709     return $err;
 710 }
 711
 712 sub _comp_search_prefixes {
 713     my $c = shift;
 714     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 715 }
 716
 717 # search components given a name and some prefixes
 718 sub _comp_names_search_prefixes {
 719     my ( $c, $name, @prefixes ) = @_;
 720     my $appclass = ref $c || $c;
 721     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 722     $filter = qr/$filter/; # Compile regex now rather than once per loop
 723
 724     # map the original component name to the sub part that we will search against
 725     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 726         grep { /$filter/ } keys %{ $c->components };
 727
 728     # undef for a name will return all
 729     return keys %eligible if !defined $name;
 730
 731     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 732     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 733
 734     return @result if @result;
 735
 736     # if we were given a regexp to search against, we're done.
 737     return if $name->$_isa('Regexp');
 738
 739     # skip regexp fallback if configured
 740     return
 741         if $appclass->config->{disable_component_resolution_regex_fallback};
 742
 743     # regexp fallback
 744     $query  = qr/$name/i;
 745     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 746
 747     # no results? try against full names
 748     if( !@result ) {
 749         @result = grep { m{$query} } keys %eligible;
 750     }
 751
 752     # don't warn if we didn't find any results, it just might not exist
 753     if( @result ) {
 754         # Disgusting hack to work out correct method name
 755         my $warn_for = lc $prefixes[0];
 756         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 757            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 758            "component resolution is unreliable and unsafe.";
 759         my $short = $result[0];
 760         # remove the component namespace prefix
 761         $short =~ s/.*?(Model|Controller|View):://;
 762         my $shortmess = Carp::shortmess('');
 763         if ($shortmess =~ m#Catalyst/Plugin#) {
 764            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 765               "plugin's config";
 766         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 767            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 768               "component's config";
 769         } else {
 770            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 771               "but if you really wanted to search, pass in a regexp as the argument " .
 772               "like so: \$c->${warn_for}(qr/${name}/)";
 773         }
 774         $c->log->warn( "${msg}$shortmess" );
 775     }
 776
 777     return @result;
 778 }
 779
 780 # Find possible names for a prefix
 781 sub _comp_names {
 782     my ( $c, @prefixes ) = @_;
 783     my $appclass = ref $c || $c;
 784
 785     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 786
 787     my @names = map { s{$filter}{}; $_; }
 788         $c->_comp_names_search_prefixes( undef, @prefixes );
 789
 790     return @names;
 791 }
 792
 793 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 794
 795 sub _filter_component {
 796     my ( $c, $comp, @args ) = @_;
 797
 798     if(ref $comp eq 'CODE') {
 799       $comp = $comp->();
 800     }
 801
 802     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 803       return $comp->ACCEPT_CONTEXT( $c, @args );
 804     }
 805
 806     $c->log->warn("You called component '${\$comp->catalyst_component_name}' with arguments [@args], but this component does not ACCEPT_CONTEXT, so args are ignored.") if scalar(@args) && $c->debug;
 807
 808     return $comp;
 809 }
 810
 811 =head2 COMPONENT ACCESSORS
 812
 813 =head2 $c->controller($name)
 814
 815 Gets a L<Catalyst::Controller> instance by name.
 816
 817     $c->controller('Foo')->do_stuff;
 818
 819 If the name is omitted, will return the controller for the dispatched
 820 action.
 821
 822 If you want to search for controllers, pass in a regexp as the argument.
 823
 824     # find all controllers that start with Foo
 825     my @foo_controllers = $c->controller(qr{^Foo});
 826
 827
 828 =cut
 829
 830 sub controller {
 831     my ( $c, $name, @args ) = @_;
 832
 833     my $appclass = ref($c) || $c;
 834     if( $name ) {
 835         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 836             my $comps = $c->components;
 837             my $check = $appclass."::Controller::".$name;
 838             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 839             foreach my $path (@{$appclass->config->{ setup_components }->{ search_extra }}) {
 840                 next unless $path =~ /.*::Controller/;
 841                 $check = $path."::".$name;
 842                 return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 843             }
 844         }
 845         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 846         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 847         return $c->_filter_component( $result[ 0 ], @args );
 848     }
 849
 850     return $c->component( $c->action->class );
 851 }
 852
 853 =head2 $c->model($name)
 854
 855 Gets a L<Catalyst::Model> instance by name.
 856
 857     $c->model('Foo')->do_stuff;
 858
 859 Any extra arguments are directly passed to ACCEPT_CONTEXT, if the model
 860 defines ACCEPT_CONTEXT.  If it does not, the args are discarded.
 861
 862 If the name is omitted, it will look for
 863  - a model object in $c->stash->{current_model_instance}, then
 864  - a model name in $c->stash->{current_model}, then
 865  - a config setting 'default_model', or
 866  - check if there is only one model, and return it if that's the case.
 867
 868 If you want to search for models, pass in a regexp as the argument.
 869
 870     # find all models that start with Foo
 871     my @foo_models = $c->model(qr{^Foo});
 872
 873 =cut
 874
 875 sub model {
 876     my ( $c, $name, @args ) = @_;
 877     my $appclass = ref($c) || $c;
 878     if( $name ) {
 879         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 880             my $comps = $c->components;
 881             my $check = $appclass."::Model::".$name;
 882             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 883             foreach my $path (@{$appclass->config->{ setup_components }->{ search_extra }}) {
 884                 next unless $path =~ /.*::Model/;
 885                 $check = $path."::".$name;
 886                 return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 887             }
 888         }
 889         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 890         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 891         return $c->_filter_component( $result[ 0 ], @args );
 892     }
 893
 894     if (ref $c) {
 895         return $c->stash->{current_model_instance}
 896           if $c->stash->{current_model_instance};
 897         return $c->model( $c->stash->{current_model} )
 898           if $c->stash->{current_model};
 899     }
 900     return $c->model( $appclass->config->{default_model} )
 901       if $appclass->config->{default_model};
 902
 903     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 904
 905     if( $rest ) {
 906         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 907         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 908         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 909         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 910         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 911     }
 912
 913     return $c->_filter_component( $comp );
 914 }
 915
 916
 917 =head2 $c->view($name)
 918
 919 Gets a L<Catalyst::View> instance by name.
 920
 921     $c->view('Foo')->do_stuff;
 922
 923 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 924
 925 If the name is omitted, it will look for
 926  - a view object in $c->stash->{current_view_instance}, then
 927  - a view name in $c->stash->{current_view}, then
 928  - a config setting 'default_view', or
 929  - check if there is only one view, and return it if that's the case.
 930
 931 If you want to search for views, pass in a regexp as the argument.
 932
 933     # find all views that start with Foo
 934     my @foo_views = $c->view(qr{^Foo});
 935
 936 =cut
 937
 938 sub view {
 939     my ( $c, $name, @args ) = @_;
 940
 941     my $appclass = ref($c) || $c;
 942     if( $name ) {
 943         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 944             my $comps = $c->components;
 945             my $check = $appclass."::View::".$name;
 946             if( exists $comps->{$check} ) {
 947                 return $c->_filter_component( $comps->{$check}, @args );
 948             }
 949             else {
 950                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 951             }
 952             foreach my $path (@{$appclass->config->{ setup_components }->{ search_extra }}) {
 953                 next unless $path =~ /.*::View/;
 954                 $check = $path."::".$name;
 955                 return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 956             }
 957         }
 958         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 959         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 960         return $c->_filter_component( $result[ 0 ], @args );
 961     }
 962
 963     if (ref $c) {
 964         return $c->stash->{current_view_instance}
 965           if $c->stash->{current_view_instance};
 966         return $c->view( $c->stash->{current_view} )
 967           if $c->stash->{current_view};
 968     }
 969     return $c->view( $appclass->config->{default_view} )
 970       if $appclass->config->{default_view};
 971
 972     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 973
 974     if( $rest ) {
 975         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 976         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 977         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 978         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 979         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 980     }
 981
 982     return $c->_filter_component( $comp );
 983 }
 984
 985 =head2 $c->controllers
 986
 987 Returns the available names which can be passed to $c->controller
 988
 989 =cut
 990
 991 sub controllers {
 992     my ( $c ) = @_;
 993     return $c->_comp_names(qw/Controller C/);
 994 }
 995
 996 =head2 $c->models
 997
 998 Returns the available names which can be passed to $c->model
 999
1000 =cut
1001
1002 sub models {
1003     my ( $c ) = @_;
1004     return $c->_comp_names(qw/Model M/);
1005 }
1006
1007
1008 =head2 $c->views
1009
1010 Returns the available names which can be passed to $c->view
1011
1012 =cut
1013
1014 sub views {
1015     my ( $c ) = @_;
1016     return $c->_comp_names(qw/View V/);
1017 }
1018
1019 =head2 $c->comp($name)
1020
1021 =head2 $c->component($name)
1022
1023 Gets a component object by name. This method is not recommended,
1024 unless you want to get a specific component by full
1025 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
1026 should be used instead.
1027
1028 If C<$name> is a regexp, a list of components matched against the full
1029 component name will be returned.
1030
1031 If Catalyst can't find a component by name, it will fallback to regex
1032 matching by default. To disable this behaviour set
1033 disable_component_resolution_regex_fallback to a true value.
1034
1035     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
1036
1037 =cut
1038
1039 sub component {
1040     my ( $c, $name, @args ) = @_;
1041
1042     if( $name ) {
1043         my $comps = $c->components;
1044
1045         if( !ref $name ) {
1046             # is it the exact name?
1047             return $c->_filter_component( $comps->{ $name }, @args )
1048                        if exists $comps->{ $name };
1049
1050             # perhaps we just omitted "MyApp"?
1051             my $composed = ( ref $c || $c ) . "::${name}";
1052             return $c->_filter_component( $comps->{ $composed }, @args )
1053                        if exists $comps->{ $composed };
1054
1055             # search all of the models, views and controllers
1056             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
1057             return $c->_filter_component( $comp, @args ) if $comp;
1058         }
1059
1060         return
1061             if $c->config->{disable_component_resolution_regex_fallback};
1062
1063         # This is here so $c->comp( '::M::' ) works
1064         my $query = ref $name ? $name : qr{$name}i;
1065
1066         my @result = grep { m{$query} } keys %{ $c->components };
1067         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
1068
1069         if( $result[ 0 ] ) {
1070             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
1071             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
1072             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
1073             return $c->_filter_component( $result[ 0 ], @args );
1074         }
1075
1076         # I would expect to return an empty list here, but that breaks back-compat
1077     }
1078
1079     # fallback
1080     return sort keys %{ $c->components };
1081 }
1082
1083 =head2 CLASS DATA AND HELPER CLASSES
1084
1085 =head2 $c->config
1086
1087 Returns or takes a hashref containing the application's configuration.
1088
1089     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
1090
1091 You can also use a C<YAML>, C<XML> or L<Config::General> config file
1092 like C<myapp.conf> in your applications home directory. See
1093 L<Catalyst::Plugin::ConfigLoader>.
1094
1095 =head3 Cascading configuration
1096
1097 The config method is present on all Catalyst components, and configuration
1098 will be merged when an application is started. Configuration loaded with
1099 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
1100 followed by configuration in your top level C<MyApp> class. These two
1101 configurations are merged, and then configuration data whose hash key matches a
1102 component name is merged with configuration for that component.
1103
1104 The configuration for a component is then passed to the C<new> method when a
1105 component is constructed.
1106
1107 For example:
1108
1109     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
1110     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
1111
1112 will mean that C<MyApp::Model::Foo> receives the following data when
1113 constructed:
1114
1115     MyApp::Model::Foo->new({
1116         bar => 'baz',
1117         quux => 'frob',
1118         overrides => 'me',
1119     });
1120
1121 It's common practice to use a Moose attribute
1122 on the receiving component to access the config value.
1123
1124     package MyApp::Model::Foo;
1125
1126     use Moose;
1127
1128     # this attr will receive 'baz' at construction time
1129     has 'bar' => (
1130         is  => 'rw',
1131         isa => 'Str',
1132     );
1133
1134 You can then get the value 'baz' by calling $c->model('Foo')->bar
1135 (or $self->bar inside code in the model).
1136
1137 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
1138 as a way of reading config within your code, as this B<will not> give you the
1139 correctly merged config back. You B<MUST> take the config values supplied to
1140 the constructor and use those instead.
1141
1142 =cut
1143
1144 around config => sub {
1145     my $orig = shift;
1146     my $c = shift;
1147
1148     croak('Setting config after setup has been run is not allowed.')
1149         if ( @_ and $c->setup_finished );
1150
1151     $c->$orig(@_);
1152 };
1153
1154 =head2 $c->log
1155
1156 Returns the logging object instance. Unless it is already set, Catalyst
1157 sets this up with a L<Catalyst::Log> object. To use your own log class,
1158 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1159 C<< __PACKAGE__->setup >>.
1160
1161  __PACKAGE__->log( MyLogger->new );
1162  __PACKAGE__->setup;
1163
1164 And later:
1165
1166     $c->log->info( 'Now logging with my own logger!' );
1167
1168 Your log class should implement the methods described in
1169 L<Catalyst::Log>.
1170
1171 =head2 has_encoding
1172
1173 Returned True if there's a valid encoding
1174
1175 =head2 clear_encoding
1176
1177 Clears the encoding for the current context
1178
1179 =head2 encoding
1180
1181 Sets or gets the application encoding.  Setting encoding takes either an
1182 Encoding object or a string that we try to resolve via L<Encode::find_encoding>.
1183
1184 You would expect to get the encoding object back if you attempt to set it.  If
1185 there is a failure you will get undef returned and an error message in the log.
1186
1187 =cut
1188
1189 sub has_encoding { shift->encoding ? 1:0 }
1190
1191 sub clear_encoding {
1192     my $c = shift;
1193     if(blessed $c) {
1194         $c->encoding(undef);
1195     } else {
1196         $c->log->error("You can't clear encoding on the application");
1197     }
1198 }
1199
1200 sub encoding {
1201     my $c = shift;
1202     my $encoding;
1203
1204     if ( scalar @_ ) {
1205
1206         # Don't let one change this once we are too far into the response
1207         if(blessed $c && $c->res->finalized_headers) {
1208           Carp::croak("You may not change the encoding once the headers are finalized");
1209           return;
1210         }
1211
1212         # Let it be set to undef
1213         if (my $wanted = shift)  {
1214             $encoding = Encode::find_encoding($wanted)
1215               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1216             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1217         }
1218         else {
1219             binmode(STDERR);
1220         }
1221
1222         $encoding = ref $c
1223                   ? $c->{encoding} = $encoding
1224                   : $c->_encoding($encoding);
1225     } else {
1226       $encoding = ref $c && exists $c->{encoding}
1227                 ? $c->{encoding}
1228                 : $c->_encoding;
1229     }
1230
1231     return $encoding;
1232 }
1233
1234 =head2 $c->debug
1235
1236 Returns 1 if debug mode is enabled, 0 otherwise.
1237
1238 You can enable debug mode in several ways:
1239
1240 =over
1241
1242 =item By calling myapp_server.pl with the -d flag
1243
1244 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1245
1246 =item The -Debug option in your MyApp.pm
1247
1248 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1249
1250 =back
1251
1252 The first three also set the log level to 'debug'.
1253
1254 Calling C<< $c->debug(1) >> has no effect.
1255
1256 =cut
1257
1258 sub debug { 0 }
1259
1260 =head2 $c->dispatcher
1261
1262 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1263
1264 =head2 $c->engine
1265
1266 Returns the engine instance. See L<Catalyst::Engine>.
1267
1268
1269 =head2 UTILITY METHODS
1270
1271 =head2 $c->path_to(@path)
1272
1273 Merges C<@path> with C<< $c->config->{home} >> and returns a
1274 L<Path::Class::Dir> object. Note you can usually use this object as
1275 a filename, but sometimes you will have to explicitly stringify it
1276 yourself by calling the C<< ->stringify >> method.
1277
1278 For example:
1279
1280     $c->path_to( 'db', 'sqlite.db' );
1281
1282 =cut
1283
1284 sub path_to {
1285     my ( $c, @path ) = @_;
1286     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1287     if ( -d $path ) { return $path }
1288     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1289 }
1290
1291 sub plugin {
1292     my ( $class, $name, $plugin, @args ) = @_;
1293
1294     # See block comment in t/unit_core_plugin.t
1295     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1296
1297     $class->_register_plugin( $plugin, 1 );
1298
1299     eval { $plugin->import };
1300     $class->mk_classdata($name);
1301     my $obj;
1302     eval { $obj = $plugin->new(@args) };
1303
1304     if ($@) {
1305         Catalyst::Exception->throw( message =>
1306               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1307     }
1308
1309     $class->$name($obj);
1310     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1311       if $class->debug;
1312 }
1313
1314 =head2 MyApp->setup
1315
1316 Initializes the dispatcher and engine, loads any plugins, and loads the
1317 model, view, and controller components. You may also specify an array
1318 of plugins to load here, if you choose to not load them in the C<use
1319 Catalyst> line.
1320
1321     MyApp->setup;
1322     MyApp->setup( qw/-Debug/ );
1323
1324 B<Note:> You B<should not> wrap this method with method modifiers
1325 or bad things will happen - wrap the C<setup_finalize> method instead.
1326
1327 B<Note:> You can create a custom setup stage that will execute when the
1328 application is starting.  Use this to customize setup.
1329
1330     MyApp->setup(-Custom=value);
1331
1332     sub setup_custom {
1333       my ($class, $value) = @_;
1334     }
1335
1336 Can be handy if you want to hook into the setup phase.
1337
1338 =cut
1339
1340 sub setup {
1341     my ( $class, @arguments ) = @_;
1342     croak('Running setup more than once')
1343         if ( $class->setup_finished );
1344
1345     unless ( $class->isa('Catalyst') ) {
1346
1347         Catalyst::Exception->throw(
1348             message => qq/'$class' does not inherit from Catalyst/ );
1349     }
1350
1351     if ( $class->arguments ) {
1352         @arguments = ( @arguments, @{ $class->arguments } );
1353     }
1354
1355     # Process options
1356     my $flags = {};
1357
1358     foreach (@arguments) {
1359
1360         if (/^-Debug$/) {
1361             $flags->{log} =
1362               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1363         }
1364         elsif (/^-(\w+)=?(.*)$/) {
1365             $flags->{ lc $1 } = $2;
1366         }
1367         else {
1368             push @{ $flags->{plugins} }, $_;
1369         }
1370     }
1371
1372     $class->setup_home( delete $flags->{home} );
1373
1374     $class->setup_log( delete $flags->{log} );
1375     $class->setup_plugins( delete $flags->{plugins} );
1376
1377     $class->setup_data_handlers();
1378     $class->setup_dispatcher( delete $flags->{dispatcher} );
1379     if (my $engine = delete $flags->{engine}) {
1380         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1381     }
1382     $class->setup_engine();
1383     $class->setup_stats( delete $flags->{stats} );
1384
1385     for my $flag ( sort keys %{$flags} ) {
1386
1387         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1388             &$code( $class, delete $flags->{$flag} );
1389         }
1390         else {
1391             $class->log->warn(qq/Unknown flag "$flag"/);
1392         }
1393     }
1394
1395     eval { require Catalyst::Devel; };
1396     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1397         $class->log->warn(<<"EOF");
1398 You are running an old script!
1399
1400   Please update by running (this will overwrite existing files):
1401     catalyst.pl -force -scripts $class
1402
1403   or (this will not overwrite existing files):
1404     catalyst.pl -scripts $class
1405
1406 EOF
1407     }
1408
1409     # Call plugins setup, this is stupid and evil.
1410     # Also screws C3 badly on 5.10, hack to avoid.
1411     {
1412         no warnings qw/redefine/;
1413         local *setup = sub { };
1414         $class->setup unless $Catalyst::__AM_RESTARTING;
1415     }
1416
1417     # If you are expecting configuration info as part of your setup, it needs
1418     # to get called here and below, since we need the above line to support
1419     # ConfigLoader based configs.
1420
1421     $class->setup_encoding();
1422     $class->setup_middleware();
1423
1424     # Initialize our data structure
1425     $class->components( {} );
1426
1427     $class->setup_components;
1428
1429     if ( $class->debug ) {
1430         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1431
1432         if (@plugins) {
1433             my $column_width = Catalyst::Utils::term_width() - 6;
1434             my $t = Text::SimpleTable->new($column_width);
1435             $t->row($_) for @plugins;
1436             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1437         }
1438
1439         my @middleware = map {
1440           ref $_ eq 'CODE' ?
1441             "Inline Coderef" :
1442               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1443                 || '')  } $class->registered_middlewares;
1444
1445         if (@middleware) {
1446             my $column_width = Catalyst::Utils::term_width() - 6;
1447             my $t = Text::SimpleTable->new($column_width);
1448             $t->row($_) for @middleware;
1449             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1450         }
1451
1452         my %dh = $class->registered_data_handlers;
1453         if (my @data_handlers = keys %dh) {
1454             my $column_width = Catalyst::Utils::term_width() - 6;
1455             my $t = Text::SimpleTable->new($column_width);
1456             $t->row($_) for @data_handlers;
1457             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1458         }
1459
1460         my $dispatcher = $class->dispatcher;
1461         my $engine     = $class->engine;
1462         my $home       = $class->config->{home};
1463
1464         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1465         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1466
1467         $home
1468           ? ( -d $home )
1469           ? $class->log->debug(qq/Found home "$home"/)
1470           : $class->log->debug(qq/Home "$home" doesn't exist/)
1471           : $class->log->debug(q/Couldn't find home/);
1472
1473         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1474
1475         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1476         for my $comp ( sort keys %{ $class->components } ) {
1477             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1478             $t->row( $comp, $type );
1479         }
1480         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1481           if ( keys %{ $class->components } );
1482     }
1483
1484     # Add our self to components, since we are also a component
1485     if( $class->isa('Catalyst::Controller') ){
1486       $class->components->{$class} = $class;
1487     }
1488
1489     $class->setup_actions;
1490
1491     if ( $class->debug ) {
1492         my $name = $class->config->{name} || 'Application';
1493         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1494     }
1495
1496     if ($class->config->{case_sensitive}) {
1497         $class->log->warn($class . "->config->{case_sensitive} is set.");
1498         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1499     }
1500
1501     # call these so we pre setup the composed classes
1502     $class->composed_request_class;
1503     $class->composed_response_class;
1504     $class->composed_stats_class;
1505
1506     $class->setup_finalize;
1507
1508     # Flush the log for good measure (in case something turned off 'autoflush' early)
1509     $class->log->_flush() if $class->log->can('_flush');
1510
1511     return $class || 1; # Just in case someone named their Application 0...
1512 }
1513
1514 =head2 $app->setup_finalize
1515
1516 A hook to attach modifiers to. This method does not do anything except set the
1517 C<setup_finished> accessor.
1518
1519 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1520
1521 Example:
1522
1523     after setup_finalize => sub {
1524         my $app = shift;
1525
1526         ## do stuff here..
1527     };
1528
1529 =cut
1530
1531 sub setup_finalize {
1532     my ($class) = @_;
1533     $class->setup_finished(1);
1534 }
1535
1536 =head2 $c->uri_for( $path?, @args?, \%query_values?, \$fragment? )
1537
1538 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values?, \$fragment? )
1539
1540 =head2 $c->uri_for( $action, [@captures, @args], \%query_values?, \$fragment? )
1541
1542 Constructs an absolute L<URI> object based on the application root, the
1543 provided path, and the additional arguments and query parameters provided.
1544 When used as a string, provides a textual URI.  If you need more flexibility
1545 than this (i.e. the option to provide relative URIs etc.) see
1546 L<Catalyst::Plugin::SmartURI>.
1547
1548 If no arguments are provided, the URI for the current action is returned.
1549 To return the current action and also provide @args, use
1550 C<< $c->uri_for( $c->action, @args ) >>.
1551
1552 If the first argument is a string, it is taken as a public URI path relative
1553 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1554 relative to the application root (if it does). It is then merged with
1555 C<< $c->request->base >>; any C<@args> are appended as additional path
1556 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1557
1558 B<NOTE> If you are using this 'stringy' first argument, we skip encoding and
1559 allow you to declare something like:
1560
1561     $c->uri_for('/foo/bar#baz')
1562
1563 Where 'baz' is a URI fragment.  We consider this first argument string to be
1564 'expert' mode where you are expected to create a valid URL and we for the most
1565 part just pass it through without a lot of internal effort to escape and encode.
1566
1567 If the first argument is a L<Catalyst::Action> it represents an action which
1568 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1569 optional C<\@captures> argument (an arrayref) allows passing the captured
1570 variables that are needed to fill in the paths of Chained and Regex actions;
1571 once the path is resolved, C<uri_for> continues as though a path was
1572 provided, appending any arguments or parameters and creating an absolute
1573 URI.
1574
1575 The captures for the current request can be found in
1576 C<< $c->request->captures >>, and actions can be resolved using
1577 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1578 path, use C<< $c->uri_for_action >> instead.
1579
1580   # Equivalent to $c->req->uri
1581   $c->uri_for($c->action, $c->req->captures,
1582       @{ $c->req->args }, $c->req->params);
1583
1584   # For the Foo action in the Bar controller
1585   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1586
1587   # Path to a static resource
1588   $c->uri_for('/static/images/logo.png');
1589
1590 In general the scheme of the generated URI object will follow the incoming request
1591 however if your targeted action or action chain has the Scheme attribute it will
1592 use that instead.
1593
1594 Also, if the targeted Action or Action chain declares Args/CaptureArgs that have
1595 type constraints, we will require that your proposed URL verify on those declared
1596 constraints.
1597
1598 =cut
1599
1600 sub uri_for {
1601     my ( $c, $path, @args ) = @_;
1602
1603     if ( $path->$_isa('Catalyst::Controller') ) {
1604         $path = $path->path_prefix;
1605         $path =~ s{/+\z}{};
1606         $path .= '/';
1607     }
1608
1609     my $fragment =  ((scalar(@args) && ref($args[-1]) eq 'SCALAR') ? pop @args : undef );
1610
1611     unless(blessed $path) {
1612       if (defined($path) and $path =~ s/#(.+)$//)  {
1613         if(defined($1) and $fragment) {
1614           carp "Abiguious fragment declaration: You cannot define a fragment in '$path' and as an argument '$fragment'";
1615         }
1616         if(defined($1)) {
1617           $fragment = $1;
1618         }
1619       }
1620     }
1621
1622     my $params =
1623       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1624
1625     undef($path) if (defined $path && $path eq '');
1626
1627     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1628
1629     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1630     if ( $path->$_isa('Catalyst::Action') ) { # action object
1631         s|/|%2F|g for @args;
1632         my $captures = [ map { s|/|%2F|g; $_; }
1633                         ( scalar @args && ref $args[0] eq 'ARRAY'
1634                          ? @{ shift(@args) }
1635                          : ()) ];
1636
1637         my $action = $path;
1638         my $expanded_action = $c->dispatcher->expand_action( $action );
1639         my $num_captures = $expanded_action->number_of_captures;
1640
1641         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1642         if( !@args && $action->number_of_args ) {
1643           unshift @args, splice @$captures, $num_captures;
1644         }
1645
1646         if($num_captures) {
1647           unless($expanded_action->match_captures_constraints($c, $captures)) {
1648             carp "captures [@{$captures}] do not match the type constraints in actionchain ending with '$expanded_action'";
1649             return;
1650           }
1651         }
1652
1653         $path = $c->dispatcher->uri_for_action($action, $captures);
1654         if (not defined $path) {
1655             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1656                 if $c->debug;
1657             return undef;
1658         }
1659         $path = '/' if $path eq '';
1660
1661         # At this point @encoded_args is the remaining Args (all captures removed).
1662         if($expanded_action->has_args_constraints) {
1663           unless($expanded_action->match_args($c,\@args)) {
1664              carp "args [@args] do not match the type constraints in action '$expanded_action'";
1665              return;
1666           }
1667         }
1668     }
1669
1670     unshift(@args, $path);
1671
1672     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1673         my $namespace = $c->namespace;
1674         if (defined $path) { # cheesy hack to handle path '../foo'
1675            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1676         }
1677         unshift(@args, $namespace || '');
1678     }
1679
1680     # join args with '/', or a blank string
1681     my $args = join('/', grep { defined($_) } @args);
1682     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1683     $args =~ s!^/+!!;
1684
1685     my ($base, $class) = ('/', 'URI::_generic');
1686     if(blessed($c)) {
1687       $base = $c->req->base;
1688       if($target_action) {
1689         $target_action = $c->dispatcher->expand_action($target_action);
1690         if(my $s = $target_action->scheme) {
1691           $s = lc($s);
1692           $class = "URI::$s";
1693           $base->scheme($s);
1694         } else {
1695           $class = ref($base);
1696         }
1697       } else {
1698         $class = ref($base);
1699       }
1700
1701       $base =~ s{(?<!/)$}{/};
1702     }
1703
1704     my $query = '';
1705     if (my @keys = keys %$params) {
1706       # somewhat lifted from URI::_query's query_form
1707       $query = '?'.join('&', map {
1708           my $val = $params->{$_};
1709           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1710           s/ /+/g;
1711           my $key = $_;
1712           $val = '' unless defined $val;
1713           (map {
1714               my $param = "$_";
1715               $param = encode_utf8($param);
1716               # using the URI::Escape pattern here so utf8 chars survive
1717               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1718               $param =~ s/ /+/g;
1719
1720               $key = encode_utf8($key);
1721               # using the URI::Escape pattern here so utf8 chars survive
1722               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1723               $key =~ s/ /+/g;
1724
1725               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1726       } @keys);
1727     }
1728
1729     $base = encode_utf8 $base;
1730     $base =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1731     $args = encode_utf8 $args;
1732     $args =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1733
1734     if(defined $fragment) {
1735       if(blessed $path) {
1736         $fragment = encode_utf8(${$fragment});
1737         $fragment =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1738         $fragment =~ s/ /+/g;
1739       }
1740       $query .= "#$fragment";
1741     }
1742
1743     my $res = bless(\"${base}${args}${query}", $class);
1744     $res;
1745 }
1746
1747 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1748
1749 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1750
1751 =over
1752
1753 =item $path
1754
1755 A private path to the Catalyst action you want to create a URI for.
1756
1757 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1758 >> and passing the resulting C<$action> and the remaining arguments to C<<
1759 $c->uri_for >>.
1760
1761 You can also pass in a Catalyst::Action object, in which case it is passed to
1762 C<< $c->uri_for >>.
1763
1764 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1765
1766 For example, if the action looks like:
1767
1768  package MyApp::Controller::Users;
1769
1770  sub lst : Path('the-list') {}
1771
1772 You can use:
1773
1774  $c->uri_for_action('/users/lst')
1775
1776 and it will create the URI /users/the-list.
1777
1778 =item \@captures_and_args?
1779
1780 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1781 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1782 to interpolate all the parameters in the URI.
1783
1784 =item @args?
1785
1786 Optional list of extra arguments - can be supplied in the
1787 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1788 code.
1789
1790 Your action can have zero, a fixed or a variable number of args (e.g.
1791 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1792
1793 =item \%query_values?
1794
1795 Optional array reference of query parameters to append. E.g.
1796
1797   { foo => 'bar' }
1798
1799 will generate
1800
1801   /rest/of/your/uri?foo=bar
1802
1803 =back
1804
1805 =cut
1806
1807 sub uri_for_action {
1808     my ( $c, $path, @args ) = @_;
1809     my $action = blessed($path)
1810       ? $path
1811       : $c->dispatcher->get_action_by_path($path);
1812     unless (defined $action) {
1813       croak "Can't find action for path '$path'";
1814     }
1815     return $c->uri_for( $action, @args );
1816 }
1817
1818 =head2 $c->welcome_message
1819
1820 Returns the Catalyst welcome HTML page.
1821
1822 =cut
1823
1824 sub welcome_message {
1825     my $c      = shift;
1826     my $name   = $c->config->{name};
1827     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1828     my $prefix = Catalyst::Utils::appprefix( ref $c );
1829     $c->response->content_type('text/html; charset=utf-8');
1830     return <<"EOF";
1831 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1832     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1833 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1834     <head>
1835     <meta http-equiv="Content-Language" content="en" />
1836     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1837         <title>$name on Catalyst $VERSION</title>
1838         <style type="text/css">
1839             body {
1840                 color: #000;
1841                 background-color: #eee;
1842             }
1843             div#content {
1844                 width: 640px;
1845                 margin-left: auto;
1846                 margin-right: auto;
1847                 margin-top: 10px;
1848                 margin-bottom: 10px;
1849                 text-align: left;
1850                 background-color: #ccc;
1851                 border: 1px solid #aaa;
1852             }
1853             p, h1, h2 {
1854                 margin-left: 20px;
1855                 margin-right: 20px;
1856                 font-family: verdana, tahoma, sans-serif;
1857             }
1858             a {
1859                 font-family: verdana, tahoma, sans-serif;
1860             }
1861             :link, :visited {
1862                     text-decoration: none;
1863                     color: #b00;
1864                     border-bottom: 1px dotted #bbb;
1865             }
1866             :link:hover, :visited:hover {
1867                     color: #555;
1868             }
1869             div#topbar {
1870                 margin: 0px;
1871             }
1872             pre {
1873                 margin: 10px;
1874                 padding: 8px;
1875             }
1876             div#answers {
1877                 padding: 8px;
1878                 margin: 10px;
1879                 background-color: #fff;
1880                 border: 1px solid #aaa;
1881             }
1882             h1 {
1883                 font-size: 0.9em;
1884                 font-weight: normal;
1885                 text-align: center;
1886             }
1887             h2 {
1888                 font-size: 1.0em;
1889             }
1890             p {
1891                 font-size: 0.9em;
1892             }
1893             p img {
1894                 float: right;
1895                 margin-left: 10px;
1896             }
1897             span#appname {
1898                 font-weight: bold;
1899                 font-size: 1.6em;
1900             }
1901         </style>
1902     </head>
1903     <body>
1904         <div id="content">
1905             <div id="topbar">
1906                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1907                     $VERSION</h1>
1908              </div>
1909              <div id="answers">
1910                  <p>
1911                  <img src="$logo" alt="Catalyst Logo" />
1912                  </p>
1913                  <p>Welcome to the  world of Catalyst.
1914                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1915                     framework will make web development something you had
1916                     never expected it to be: Fun, rewarding, and quick.</p>
1917                  <h2>What to do now?</h2>
1918                  <p>That really depends  on what <b>you</b> want to do.
1919                     We do, however, provide you with a few starting points.</p>
1920                  <p>If you want to jump right into web development with Catalyst
1921                     you might want to start with a tutorial.</p>
1922 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1923 </pre>
1924 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1925 <pre>
1926 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1927 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1928 </code></pre>
1929                  <h2>What to do next?</h2>
1930                  <p>Next it's time to write an actual application. Use the
1931                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1932                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1933                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1934                     they can save you a lot of work.</p>
1935                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1936                     <p>Also, be sure to check out the vast and growing
1937                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1938                     you are likely to find what you need there.
1939                     </p>
1940
1941                  <h2>Need help?</h2>
1942                  <p>Catalyst has a very active community. Here are the main places to
1943                     get in touch with us.</p>
1944                  <ul>
1945                      <li>
1946                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1947                      </li>
1948                      <li>
1949                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1950                      </li>
1951                      <li>
1952                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1953                      </li>
1954                  </ul>
1955                  <h2>In conclusion</h2>
1956                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1957                     as we enjoyed making it. Please contact us if you have ideas
1958                     for improvement or other feedback.</p>
1959              </div>
1960          </div>
1961     </body>
1962 </html>
1963 EOF
1964 }
1965
1966 =head2 run_options
1967
1968 Contains a hash of options passed from the application script, including
1969 the original ARGV the script received, the processed values from that
1970 ARGV and any extra arguments to the script which were not processed.
1971
1972 This can be used to add custom options to your application's scripts
1973 and setup your application differently depending on the values of these
1974 options.
1975
1976 =head1 INTERNAL METHODS
1977
1978 These methods are not meant to be used by end users.
1979
1980 =head2 $c->components
1981
1982 Returns a hash of components.
1983
1984 =head2 $c->context_class
1985
1986 Returns or sets the context class.
1987
1988 =head2 $c->counter
1989
1990 Returns a hashref containing coderefs and execution counts (needed for
1991 deep recursion detection).
1992
1993 =head2 $c->depth
1994
1995 Returns the number of actions on the current internal execution stack.
1996
1997 =head2 $c->dispatch
1998
1999 Dispatches a request to actions.
2000
2001 =cut
2002
2003 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
2004
2005 =head2 $c->dispatcher_class
2006
2007 Returns or sets the dispatcher class.
2008
2009 =head2 $c->dump_these
2010
2011 Returns a list of 2-element array references (name, structure) pairs
2012 that will be dumped on the error page in debug mode.
2013
2014 =cut
2015
2016 sub dump_these {
2017     my $c = shift;
2018     [ Request => $c->req ],
2019     [ Response => $c->res ],
2020     [ Stash => $c->stash ],
2021     [ Config => $c->config ];
2022 }
2023
2024 =head2 $c->engine_class
2025
2026 Returns or sets the engine class.
2027
2028 =head2 $c->execute( $class, $coderef )
2029
2030 Execute a coderef in given class and catch exceptions. Errors are available
2031 via $c->error.
2032
2033 =cut
2034
2035 sub execute {
2036     my ( $c, $class, $code ) = @_;
2037     $class = $c->component($class) || $class;
2038     #$c->state(0);
2039
2040     if ( $c->depth >= $RECURSION ) {
2041         my $action = $code->reverse();
2042         $action = "/$action" unless $action =~ /->/;
2043         my $error = qq/Deep recursion detected calling "${action}"/;
2044         $c->log->error($error);
2045         $c->error($error);
2046         $c->state(0);
2047         return $c->state;
2048     }
2049
2050     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
2051
2052     push( @{ $c->stack }, $code );
2053
2054     no warnings 'recursion';
2055     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
2056     #      I have no idea how, ergo $ret (which appears to fix the issue)
2057     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
2058
2059     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
2060
2061     my $last = pop( @{ $c->stack } );
2062
2063     if ( my $error = $@ ) {
2064         #rethow if this can be handled by middleware
2065         if ( $c->_handle_http_exception($error) ) {
2066             foreach my $err (@{$c->error}) {
2067                 $c->log->error($err);
2068             }
2069             $c->clear_errors;
2070             $c->log->_flush if $c->log->can('_flush');
2071
2072             $error->can('rethrow') ? $error->rethrow : croak $error;
2073         }
2074         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
2075             $error->rethrow if $c->depth > 1;
2076         }
2077         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
2078             $error->rethrow if $c->depth > 0;
2079         }
2080         else {
2081             unless ( ref $error ) {
2082                 no warnings 'uninitialized';
2083                 chomp $error;
2084                 my $class = $last->class;
2085                 my $name  = $last->name;
2086                 $error = qq/Caught exception in $class->$name "$error"/;
2087             }
2088             $c->error($error);
2089         }
2090         #$c->state(0);
2091     }
2092     return $c->state;
2093 }
2094
2095 sub _stats_start_execute {
2096     my ( $c, $code ) = @_;
2097     my $appclass = ref($c) || $c;
2098     return if ( ( $code->name =~ /^_.*/ )
2099         && ( !$appclass->config->{show_internal_actions} ) );
2100
2101     my $action_name = $code->reverse();
2102     $c->counter->{$action_name}++;
2103
2104     my $action = $action_name;
2105     $action = "/$action" unless $action =~ /->/;
2106
2107     # determine if the call was the result of a forward
2108     # this is done by walking up the call stack and looking for a calling
2109     # sub of Catalyst::forward before the eval
2110     my $callsub = q{};
2111     for my $index ( 2 .. 11 ) {
2112         last
2113         if ( ( caller($index) )[0] eq 'Catalyst'
2114             && ( caller($index) )[3] eq '(eval)' );
2115
2116         if ( ( caller($index) )[3] =~ /forward$/ ) {
2117             $callsub = ( caller($index) )[3];
2118             $action  = "-> $action";
2119             last;
2120         }
2121     }
2122
2123     my $uid = $action_name . $c->counter->{$action_name};
2124
2125     # is this a root-level call or a forwarded call?
2126     if ( $callsub =~ /forward$/ ) {
2127         my $parent = $c->stack->[-1];
2128
2129         # forward, locate the caller
2130         if ( defined $parent && exists $c->counter->{"$parent"} ) {
2131             $c->stats->profile(
2132                 begin  => $action,
2133                 parent => "$parent" . $c->counter->{"$parent"},
2134                 uid    => $uid,
2135             );
2136         }
2137         else {
2138
2139             # forward with no caller may come from a plugin
2140             $c->stats->profile(
2141                 begin => $action,
2142                 uid   => $uid,
2143             );
2144         }
2145     }
2146     else {
2147
2148         # root-level call
2149         $c->stats->profile(
2150             begin => $action,
2151             uid   => $uid,
2152         );
2153     }
2154     return $action;
2155
2156 }
2157
2158 sub _stats_finish_execute {
2159     my ( $c, $info ) = @_;
2160     $c->stats->profile( end => $info );
2161 }
2162
2163 =head2 $c->finalize
2164
2165 Finalizes the request.
2166
2167 =cut
2168
2169 sub finalize {
2170     my $c = shift;
2171
2172     for my $error ( @{ $c->error } ) {
2173         $c->log->error($error);
2174     }
2175
2176     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
2177     # stuff like cometd and websockets
2178
2179     if($c->request->_has_io_fh) {
2180       $c->log_response;
2181       return;
2182     }
2183
2184     # Allow engine to handle finalize flow (for POE)
2185     my $engine = $c->engine;
2186     if ( my $code = $engine->can('finalize') ) {
2187         $engine->$code($c);
2188     }
2189     else {
2190
2191         $c->finalize_uploads;
2192
2193         # Error
2194         if ( $#{ $c->error } >= 0 ) {
2195             $c->finalize_error;
2196         }
2197
2198         $c->finalize_encoding;
2199         $c->finalize_headers unless $c->response->finalized_headers;
2200         $c->finalize_body;
2201     }
2202
2203     $c->log_response;
2204
2205     if ($c->use_stats) {
2206         my $elapsed = $c->stats->elapsed;
2207         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
2208         $c->log->info(
2209             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
2210     }
2211
2212     return $c->response->status;
2213 }
2214
2215 =head2 $c->finalize_body
2216
2217 Finalizes body.
2218
2219 =cut
2220
2221 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
2222
2223 =head2 $c->finalize_cookies
2224
2225 Finalizes cookies.
2226
2227 =cut
2228
2229 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
2230
2231 =head2 $c->finalize_error
2232
2233 Finalizes error.  If there is only one error in L</error> and it is an object that
2234 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2235 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2236 return the default error page (production mode).
2237
2238 =cut
2239
2240 sub finalize_error {
2241     my $c = shift;
2242     if($#{$c->error} > 0) {
2243         $c->engine->finalize_error( $c, @_ );
2244     } else {
2245         my ($error) = @{$c->error};
2246         if ( $c->_handle_http_exception($error) ) {
2247             # In the case where the error 'knows what it wants', becauses its PSGI
2248             # aware, just rethow and let middleware catch it
2249             $error->can('rethrow') ? $error->rethrow : croak $error;
2250         } else {
2251             $c->engine->finalize_error( $c, @_ )
2252         }
2253     }
2254 }
2255
2256 =head2 $c->finalize_headers
2257
2258 Finalizes headers.
2259
2260 =cut
2261
2262 sub finalize_headers {
2263     my $c = shift;
2264
2265     my $response = $c->response; #accessor calls can add up?
2266
2267     # Check if we already finalized headers
2268     return if $response->finalized_headers;
2269
2270     # Handle redirects
2271     if ( my $location = $response->redirect ) {
2272         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2273         $response->header( Location => $location );
2274     }
2275
2276     # Remove incorrectly added body and content related meta data when returning
2277     # an information response, or a response the is required to not include a body
2278
2279     $c->finalize_cookies;
2280
2281     # This currently is a NOOP but I don't want to remove it since I guess people
2282     # might have Response subclasses that use it for something... (JNAP)
2283     $c->response->finalize_headers();
2284
2285     # Done
2286     $response->finalized_headers(1);
2287 }
2288
2289 =head2 $c->finalize_encoding
2290
2291 Make sure your body is encoded properly IF you set an encoding.  By
2292 default the encoding is UTF-8 but you can disable it by explicitly setting the
2293 encoding configuration value to undef.
2294
2295 We can only encode when the body is a scalar.  Methods for encoding via the
2296 streaming interfaces (such as C<write> and C<write_fh> on L<Catalyst::Response>
2297 are available).
2298
2299 See L</ENCODING>.
2300
2301 =cut
2302
2303 sub finalize_encoding {
2304     my $c = shift;
2305     my $res = $c->res || return;
2306
2307     # Warn if the set charset is different from the one you put into encoding.  We need
2308     # to do this early since encodable_response is false for this condition and we need
2309     # to match the debug output for backcompat (there's a test for this...) -JNAP
2310     if(
2311       $res->content_type_charset and $c->encoding and
2312       (uc($c->encoding->mime_name) ne uc($res->content_type_charset))
2313     ) {
2314         my $ct = lc($res->content_type_charset);
2315         $c->log->debug("Catalyst encoding config is set to encode in '" .
2316             $c->encoding->mime_name .
2317             "', content type is '$ct', not encoding ");
2318     }
2319
2320     if(
2321       ($res->encodable_response) and
2322       (defined($res->body)) and
2323       (ref(\$res->body) eq 'SCALAR')
2324     ) {
2325         $c->res->body( $c->encoding->encode( $c->res->body, $c->_encode_check ) );
2326
2327         # Set the charset if necessary.  This might be a bit bonkers since encodable response
2328         # is false when the set charset is not the same as the encoding mimetype (maybe
2329         # confusing action at a distance here..
2330         # Don't try to set the charset if one already exists or if headers are already finalized
2331         $c->res->content_type($c->res->content_type . "; charset=" . $c->encoding->mime_name)
2332           unless($c->res->content_type_charset ||
2333                 ($c->res->_context && $c->res->finalized_headers && !$c->res->_has_response_cb));
2334     }
2335 }
2336
2337 =head2 $c->finalize_output
2338
2339 An alias for finalize_body.
2340
2341 =head2 $c->finalize_read
2342
2343 Finalizes the input after reading is complete.
2344
2345 =cut
2346
2347 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2348
2349 =head2 $c->finalize_uploads
2350
2351 Finalizes uploads. Cleans up any temporary files.
2352
2353 =cut
2354
2355 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2356
2357 =head2 $c->get_action( $action, $namespace )
2358
2359 Gets an action in a given namespace.
2360
2361 =cut
2362
2363 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2364
2365 =head2 $c->get_actions( $action, $namespace )
2366
2367 Gets all actions of a given name in a namespace and all parent
2368 namespaces.
2369
2370 =cut
2371
2372 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2373
2374 =head2 $app->handle_request( @arguments )
2375
2376 Called to handle each HTTP request.
2377
2378 =cut
2379
2380 sub handle_request {
2381     my ( $class, @arguments ) = @_;
2382
2383     # Always expect worst case!
2384     my $status = -1;
2385     try {
2386         if ($class->debug) {
2387             my $secs = time - $START || 1;
2388             my $av = sprintf '%.3f', $COUNT / $secs;
2389             my $time = localtime time;
2390             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2391         }
2392
2393         my $c = $class->prepare(@arguments);
2394         $c->dispatch;
2395         $status = $c->finalize;
2396     } catch {
2397         #rethow if this can be handled by middleware
2398         if ( $class->_handle_http_exception($_) ) {
2399             $_->can('rethrow') ? $_->rethrow : croak $_;
2400         }
2401         chomp(my $error = $_);
2402         $class->log->error(qq/Caught exception in engine "$error"/);
2403     };
2404
2405     $COUNT++;
2406
2407     if(my $coderef = $class->log->can('_flush')){
2408         $class->log->$coderef();
2409     }
2410     return $status;
2411 }
2412
2413 =head2 $class->prepare( @arguments )
2414
2415 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2416 etc.).
2417
2418 =cut
2419
2420 has _uploadtmp => (
2421     is => 'ro',
2422     predicate => '_has_uploadtmp',
2423 );
2424
2425 sub prepare {
2426     my ( $class, @arguments ) = @_;
2427
2428     # XXX
2429     # After the app/ctxt split, this should become an attribute based on something passed
2430     # into the application.
2431     $class->context_class( ref $class || $class ) unless $class->context_class;
2432
2433     my $uploadtmp = $class->config->{uploadtmp};
2434     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2435
2436     $c->response->_context($c);
2437     $c->stats($class->stats_class->new)->enable($c->use_stats);
2438
2439     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2440         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2441     }
2442
2443     try {
2444         # Allow engine to direct the prepare flow (for POE)
2445         if ( my $prepare = $c->engine->can('prepare') ) {
2446             $c->engine->$prepare( $c, @arguments );
2447         }
2448         else {
2449             $c->prepare_request(@arguments);
2450             $c->prepare_connection;
2451             $c->prepare_query_parameters;
2452             $c->prepare_headers; # Just hooks, no longer needed - they just
2453             $c->prepare_cookies; # cause the lazy attribute on req to build
2454             $c->prepare_path;
2455
2456             # Prepare the body for reading, either by prepare_body
2457             # or the user, if they are using $c->read
2458             $c->prepare_read;
2459
2460             # Parse the body unless the user wants it on-demand
2461             unless ( ref($c)->config->{parse_on_demand} ) {
2462                 $c->prepare_body;
2463             }
2464         }
2465         $c->prepare_action;
2466     }
2467     # VERY ugly and probably shouldn't rely on ->finalize actually working
2468     catch {
2469         # failed prepare is always due to an invalid request, right?
2470         # Note we call finalize and then die here, which escapes
2471         # finalize being called in the enclosing block..
2472         # It in fact couldn't be called, as we don't return $c..
2473         # This is a mess - but I'm unsure you can fix this without
2474         # breaking compat for people doing crazy things (we should set
2475         # the 400 and just return the ctx here IMO, letting finalize get called
2476         # above...
2477         if ( $c->_handle_http_exception($_) ) {
2478             foreach my $err (@{$c->error}) {
2479                 $c->log->error($err);
2480             }
2481             $c->clear_errors;
2482             $c->log->_flush if $c->log->can('_flush');
2483             $_->can('rethrow') ? $_->rethrow : croak $_;
2484         } else {
2485             $c->response->status(400);
2486             $c->response->content_type('text/plain');
2487             $c->response->body('Bad Request');
2488             $c->finalize;
2489             die $_;
2490         }
2491     };
2492
2493     $c->log_request;
2494     $c->{stash} = $c->stash;
2495     Scalar::Util::weaken($c->{stash});
2496
2497     return $c;
2498 }
2499
2500 =head2 $c->prepare_action
2501
2502 Prepares action. See L<Catalyst::Dispatcher>.
2503
2504 =cut
2505
2506 sub prepare_action {
2507     my $c = shift;
2508     my $ret = $c->dispatcher->prepare_action( $c, @_);
2509
2510     if($c->encoding) {
2511         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2512           $_ = $c->_handle_param_unicode_decoding($_);
2513         }
2514     }
2515
2516     return $ret;
2517 }
2518
2519
2520 =head2 $c->prepare_body
2521
2522 Prepares message body.
2523
2524 =cut
2525
2526 sub prepare_body {
2527     my $c = shift;
2528
2529     return if $c->request->_has_body;
2530
2531     # Initialize on-demand data
2532     $c->engine->prepare_body( $c, @_ );
2533     $c->prepare_parameters;
2534     $c->prepare_uploads;
2535 }
2536
2537 =head2 $c->prepare_body_chunk( $chunk )
2538
2539 Prepares a chunk of data before sending it to L<HTTP::Body>.
2540
2541 See L<Catalyst::Engine>.
2542
2543 =cut
2544
2545 sub prepare_body_chunk {
2546     my $c = shift;
2547     $c->engine->prepare_body_chunk( $c, @_ );
2548 }
2549
2550 =head2 $c->prepare_body_parameters
2551
2552 Prepares body parameters.
2553
2554 =cut
2555
2556 sub prepare_body_parameters {
2557     my $c = shift;
2558     $c->request->prepare_body_parameters( $c, @_ );
2559 }
2560
2561 =head2 $c->prepare_connection
2562
2563 Prepares connection.
2564
2565 =cut
2566
2567 sub prepare_connection {
2568     my $c = shift;
2569     $c->request->prepare_connection($c);
2570 }
2571
2572 =head2 $c->prepare_cookies
2573
2574 Prepares cookies by ensuring that the attribute on the request
2575 object has been built.
2576
2577 =cut
2578
2579 sub prepare_cookies { my $c = shift; $c->request->cookies }
2580
2581 =head2 $c->prepare_headers
2582
2583 Prepares request headers by ensuring that the attribute on the request
2584 object has been built.
2585
2586 =cut
2587
2588 sub prepare_headers { my $c = shift; $c->request->headers }
2589
2590 =head2 $c->prepare_parameters
2591
2592 Prepares parameters.
2593
2594 =cut
2595
2596 sub prepare_parameters {
2597     my $c = shift;
2598     $c->prepare_body_parameters;
2599     $c->engine->prepare_parameters( $c, @_ );
2600 }
2601
2602 =head2 $c->prepare_path
2603
2604 Prepares path and base.
2605
2606 =cut
2607
2608 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2609
2610 =head2 $c->prepare_query_parameters
2611
2612 Prepares query parameters.
2613
2614 =cut
2615
2616 sub prepare_query_parameters {
2617     my $c = shift;
2618
2619     $c->engine->prepare_query_parameters( $c, @_ );
2620 }
2621
2622 =head2 $c->log_request
2623
2624 Writes information about the request to the debug logs.  This includes:
2625
2626 =over 4
2627
2628 =item * Request method, path, and remote IP address
2629
2630 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2631
2632 =item * Request parameters
2633
2634 =item * File uploads
2635
2636 =back
2637
2638 =cut
2639
2640 sub log_request {
2641     my $c = shift;
2642
2643     return unless $c->debug;
2644
2645     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2646     my $request = $dump->[1];
2647
2648     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2649     $method ||= '';
2650     $path = '/' unless length $path;
2651     $address ||= '';
2652
2653     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2654     $path = decode_utf8($path);
2655
2656     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2657
2658     $c->log_request_headers($request->headers);
2659
2660     if ( my $keywords = $request->query_keywords ) {
2661         $c->log->debug("Query keywords are: $keywords");
2662     }
2663
2664     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2665
2666     $c->log_request_uploads($request);
2667 }
2668
2669 =head2 $c->log_response
2670
2671 Writes information about the response to the debug logs by calling
2672 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2673
2674 =cut
2675
2676 sub log_response {
2677     my $c = shift;
2678
2679     return unless $c->debug;
2680
2681     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2682     my $response = $dump->[1];
2683
2684     $c->log_response_status_line($response);
2685     $c->log_response_headers($response->headers);
2686 }
2687
2688 =head2 $c->log_response_status_line($response)
2689
2690 Writes one line of information about the response to the debug logs.  This includes:
2691
2692 =over 4
2693
2694 =item * Response status code
2695
2696 =item * Content-Type header (if present)
2697
2698 =item * Content-Length header (if present)
2699
2700 =back
2701
2702 =cut
2703
2704 sub log_response_status_line {
2705     my ($c, $response) = @_;
2706
2707     $c->log->debug(
2708         sprintf(
2709             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2710             $response->status                            || 'unknown',
2711             $response->headers->header('Content-Type')   || 'unknown',
2712             $response->headers->header('Content-Length') || 'unknown'
2713         )
2714     );
2715 }
2716
2717 =head2 $c->log_response_headers($headers);
2718
2719 Hook method which can be wrapped by plugins to log the response headers.
2720 No-op in the default implementation.
2721
2722 =cut
2723
2724 sub log_response_headers {}
2725
2726 =head2 $c->log_request_parameters( query => {}, body => {} )
2727
2728 Logs request parameters to debug logs
2729
2730 =cut
2731
2732 sub log_request_parameters {
2733     my $c          = shift;
2734     my %all_params = @_;
2735
2736     return unless $c->debug;
2737
2738     my $column_width = Catalyst::Utils::term_width() - 44;
2739     foreach my $type (qw(query body)) {
2740         my $params = $all_params{$type};
2741         next if ! keys %$params;
2742         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2743         for my $key ( sort keys %$params ) {
2744             my @values = ();
2745             if(ref $params eq 'Hash::MultiValue') {
2746                 @values = $params->get_all($key);
2747             } else {
2748                 my $param = $params->{$key};
2749                 if( defined($param) ) {
2750                     @values = ref $param eq 'ARRAY' ? @$param : $param;
2751                 }
2752             }
2753             $t->row( $key.( scalar @values > 1 ? ' [multiple]' : ''), join(', ', @values) );
2754         }
2755         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2756     }
2757 }
2758
2759 =head2 $c->log_request_uploads
2760
2761 Logs file uploads included in the request to the debug logs.
2762 The parameter name, filename, file type, and file size are all included in
2763 the debug logs.
2764
2765 =cut
2766
2767 sub log_request_uploads {
2768     my $c = shift;
2769     my $request = shift;
2770     return unless $c->debug;
2771     my $uploads = $request->uploads;
2772     if ( keys %$uploads ) {
2773         my $t = Text::SimpleTable->new(
2774             [ 12, 'Parameter' ],
2775             [ 26, 'Filename' ],
2776             [ 18, 'Type' ],
2777             [ 9,  'Size' ]
2778         );
2779         for my $key ( sort keys %$uploads ) {
2780             my $upload = $uploads->{$key};
2781             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2782                 $t->row( $key, $u->filename, $u->type, $u->size );
2783             }
2784         }
2785         $c->log->debug( "File Uploads are:\n" . $t->draw );
2786     }
2787 }
2788
2789 =head2 $c->log_request_headers($headers);
2790
2791 Hook method which can be wrapped by plugins to log the request headers.
2792 No-op in the default implementation.
2793
2794 =cut
2795
2796 sub log_request_headers {}
2797
2798 =head2 $c->log_headers($type => $headers)
2799
2800 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2801
2802 =cut
2803
2804 sub log_headers {
2805     my $c       = shift;
2806     my $type    = shift;
2807     my $headers = shift;    # an HTTP::Headers instance
2808
2809     return unless $c->debug;
2810
2811     my $column_width = Catalyst::Utils::term_width() - 28;
2812     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2813     $headers->scan(
2814         sub {
2815             my ( $name, $value ) = @_;
2816             $t->row( $name, $value );
2817         }
2818     );
2819     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2820 }
2821
2822
2823 =head2 $c->prepare_read
2824
2825 Prepares the input for reading.
2826
2827 =cut
2828
2829 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2830
2831 =head2 $c->prepare_request
2832
2833 Prepares the engine request.
2834
2835 =cut
2836
2837 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2838
2839 =head2 $c->prepare_uploads
2840
2841 Prepares uploads.
2842
2843 =cut
2844
2845 sub prepare_uploads {
2846     my $c = shift;
2847     $c->engine->prepare_uploads( $c, @_ );
2848 }
2849
2850 =head2 $c->prepare_write
2851
2852 Prepares the output for writing.
2853
2854 =cut
2855
2856 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2857
2858 =head2 $c->request_class
2859
2860 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2861
2862 =head2 $app->request_class_traits
2863
2864 An arrayref of L<Moose::Role>s which are applied to the request class.  You can
2865 name the full namespace of the role, or a namespace suffix, which will then
2866 be tried against the following standard namespace prefixes.
2867
2868     $MyApp::TraitFor::Request::$trait_suffix
2869     Catalyst::TraitFor::Request::$trait_suffix
2870
2871 So for example if you set:
2872
2873     MyApp->request_class_traits(['Foo']);
2874
2875 We try each possible role in turn (and throw an error if none load)
2876
2877     Foo
2878     MyApp::TraitFor::Request::Foo
2879     Catalyst::TraitFor::Request::Foo
2880
2881 The namespace part 'TraitFor::Request' was chosen to assist in backwards
2882 compatibility with L<CatalystX::RoleApplicator> which previously provided
2883 these features in a stand alone package.
2884
2885 =head2 $app->composed_request_class
2886
2887 This is the request class which has been composed with any request_class_traits.
2888
2889 =head2 $c->response_class
2890
2891 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2892
2893 =head2 $app->response_class_traits
2894
2895 An arrayref of L<Moose::Role>s which are applied to the response class.  You can
2896 name the full namespace of the role, or a namespace suffix, which will then
2897 be tried against the following standard namespace prefixes.
2898
2899     $MyApp::TraitFor::Response::$trait_suffix
2900     Catalyst::TraitFor::Response::$trait_suffix
2901
2902 So for example if you set:
2903
2904     MyApp->response_class_traits(['Foo']);
2905
2906 We try each possible role in turn (and throw an error if none load)
2907
2908     Foo
2909     MyApp::TraitFor::Response::Foo
2910     Catalyst::TraitFor::Responset::Foo
2911
2912 The namespace part 'TraitFor::Response' was chosen to assist in backwards
2913 compatibility with L<CatalystX::RoleApplicator> which previously provided
2914 these features in a stand alone package.
2915
2916
2917 =head2 $app->composed_response_class
2918
2919 This is the request class which has been composed with any response_class_traits.
2920
2921 =head2 $c->read( [$maxlength] )
2922
2923 Reads a chunk of data from the request body. This method is designed to
2924 be used in a while loop, reading C<$maxlength> bytes on every call.
2925 C<$maxlength> defaults to the size of the request if not specified.
2926
2927 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2928 directly.
2929
2930 Warning: If you use read(), Catalyst will not process the body,
2931 so you will not be able to access POST parameters or file uploads via
2932 $c->request.  You must handle all body parsing yourself.
2933
2934 =cut
2935
2936 sub read { my $c = shift; return $c->request->read( @_ ) }
2937
2938 =head2 $c->run
2939
2940 Starts the engine.
2941
2942 =cut
2943
2944 sub run {
2945   my $app = shift;
2946   $app->_make_immutable_if_needed;
2947   $app->engine_loader->needs_psgi_engine_compat_hack ?
2948     $app->engine->run($app, @_) :
2949       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2950 }
2951
2952 sub _make_immutable_if_needed {
2953     my $class = shift;
2954     my $meta = find_meta($class);
2955     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2956     if (
2957         $meta->is_immutable
2958         && ! { $meta->immutable_options }->{replace_constructor}
2959         && $isa_ca
2960     ) {
2961         warn("You made your application class ($class) immutable, "
2962             . "but did not inline the\nconstructor. "
2963             . "This will break catalyst, as your app \@ISA "
2964             . "Class::Accessor(::Fast)?\nPlease pass "
2965             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2966     }
2967     unless ($meta->is_immutable) {
2968         # XXX - FIXME warning here as you should make your app immutable yourself.
2969         $meta->make_immutable(
2970             replace_constructor => 1,
2971         );
2972     }
2973 }
2974
2975 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2976
2977 Sets an action in a given namespace.
2978
2979 =cut
2980
2981 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2982
2983 =head2 $c->setup_actions($component)
2984
2985 Sets up actions for a component.
2986
2987 =cut
2988
2989 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2990
2991 =head2 $c->setup_components
2992
2993 This method is called internally to set up the application's components.
2994
2995 It finds modules by calling the L<locate_components> method, expands them to
2996 package names with the L<expand_component_module> method, and then installs
2997 each component into the application.
2998
2999 The C<setup_components> config option is passed to both of the above methods.
3000
3001 Installation of each component is performed by the L<setup_component> method,
3002 below.
3003
3004 =cut
3005
3006 sub setup_components {
3007     my $class = shift;
3008
3009     my $config  = $class->config->{ setup_components };
3010
3011     my @comps = $class->locate_components($config);
3012     my %comps = map { $_ => 1 } @comps;
3013
3014     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
3015     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
3016         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
3017     ) if $deprecatedcatalyst_component_names;
3018
3019     for my $component ( @comps ) {
3020
3021         # We pass ignore_loaded here so that overlay files for (e.g.)
3022         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
3023         # we know M::P::O found a file on disk so this is safe
3024
3025         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
3026     }
3027
3028     for my $component (@comps) {
3029         my $instance = $class->components->{ $component } = $class->delayed_setup_component($component);
3030     }
3031
3032     # Inject a component or wrap a stand alone class in an adaptor. This makes a list
3033     # of named components in the configuration that are not actually existing (not a
3034     # real file).
3035
3036     my @injected = $class->setup_injected_components;
3037
3038     # All components are registered, now we need to 'init' them.
3039     foreach my $component_name (@comps, @injected) {
3040       $class->components->{$component_name} = $class->components->{$component_name}->() if
3041         (ref($class->components->{$component_name}) || '') eq 'CODE';
3042     }
3043 }
3044
3045 =head2 $app->setup_injected_components
3046
3047 Called by setup_compoents to setup components that are injected.
3048
3049 =cut
3050
3051 sub setup_injected_components {
3052     my ($class) = @_;
3053     my @injected_components = keys %{$class->config->{inject_components} ||+{}};
3054
3055     foreach my $injected_comp_name(@injected_components) {
3056         $class->setup_injected_component(
3057           $injected_comp_name,
3058           $class->config->{inject_components}->{$injected_comp_name});
3059     }
3060
3061     return map { $class ."::" . $_ }
3062       @injected_components;
3063 }
3064
3065 =head2 $app->setup_injected_component( $injected_component_name, $config )
3066
3067 Setup a given injected component.
3068
3069 =cut
3070
3071 sub setup_injected_component {
3072     my ($class, $injected_comp_name, $config) = @_;
3073     if(my $component_class = $config->{from_component}) {
3074         my @roles = @{$config->{roles} ||[]};
3075         Catalyst::Utils::inject_component(
3076           into => $class,
3077           component => $component_class,
3078           (scalar(@roles) ? (traits => \@roles) : ()),
3079           as => $injected_comp_name);
3080     }
3081 }
3082
3083 =head2 $app->inject_component($MyApp_Component_name => \%args);
3084
3085 Add a component that is injected at setup:
3086
3087     MyApp->inject_component( 'Model::Foo' => { from_component => 'Common::Foo' } );
3088
3089 Must be called before ->setup.  Expects a component name for your
3090 current application and \%args where
3091
3092 =over 4
3093
3094 =item from_component
3095
3096 The target component being injected into your application
3097
3098 =item roles
3099
3100 An arrayref of L<Moose::Role>s that are applied to your component.
3101
3102 =back
3103
3104 Example
3105
3106     MyApp->inject_component(
3107       'Model::Foo' => {
3108         from_component => 'Common::Model::Foo',
3109         roles => ['Role1', 'Role2'],
3110       });
3111
3112 =head2 $app->inject_components
3113
3114 Inject a list of components:
3115
3116     MyApp->inject_components(
3117       'Model::FooOne' => {
3118         from_component => 'Common::Model::Foo',
3119         roles => ['Role1', 'Role2'],
3120       },
3121       'Model::FooTwo' => {
3122         from_component => 'Common::Model::Foo',
3123         roles => ['Role1', 'Role2'],
3124       });
3125
3126 =cut
3127
3128 sub inject_component {
3129   my ($app, $name, $args) = @_;
3130   die "Component $name exists" if
3131     $app->config->{inject_components}->{$name};
3132   $app->config->{inject_components}->{$name} = $args;
3133 }
3134
3135 sub inject_components {
3136   my $app = shift;
3137   while(@_) {
3138     $app->inject_component(shift, shift);
3139   }
3140 }
3141
3142 =head2 $c->locate_components( $setup_component_config )
3143
3144 This method is meant to provide a list of component modules that should be
3145 setup for the application.  By default, it will use L<Module::Pluggable>.
3146
3147 Specify a C<setup_components> config option to pass additional options directly
3148 to L<Module::Pluggable>. To add additional search paths, specify a key named
3149 C<search_extra> as an array reference. Items in the array beginning with C<::>
3150 will have the application class name prepended to them.
3151
3152 =cut
3153
3154 sub locate_components {
3155     my $class  = shift;
3156     my $config = shift;
3157
3158     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
3159     my $extra   = $config->{ search_extra } || [];
3160
3161     unshift @paths, @$extra;
3162
3163     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
3164       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
3165       %$config
3166     )->plugins } @paths;
3167
3168     return @comps;
3169 }
3170
3171 =head2 $c->expand_component_module( $component, $setup_component_config )
3172
3173 Components found by C<locate_components> will be passed to this method, which
3174 is expected to return a list of component (package) names to be set up.
3175
3176 =cut
3177
3178 sub expand_component_module {
3179     my ($class, $module) = @_;
3180     return Devel::InnerPackage::list_packages( $module );
3181 }
3182
3183 =head2 $app->delayed_setup_component
3184
3185 Returns a coderef that points to a setup_component instance.  Used
3186 internally for when you want to delay setup until the first time
3187 the component is called.
3188
3189 =cut
3190
3191 sub delayed_setup_component {
3192   my($class, $component, @more) = @_;
3193   return sub {
3194     return my $instance = $class->setup_component($component, @more);
3195   };
3196 }
3197
3198 =head2 $c->setup_component
3199
3200 =cut
3201
3202 sub setup_component {
3203     my( $class, $component ) = @_;
3204
3205     unless ( $component->can( 'COMPONENT' ) ) {
3206         return $component;
3207     }
3208
3209     my $config = $class->config_for($component);
3210     # Stash catalyst_component_name in the config here, so that custom COMPONENT
3211     # methods also pass it. local to avoid pointlessly shitting in config
3212     # for the debug screen, as $component is already the key name.
3213     local $config->{catalyst_component_name} = $component;
3214
3215     my $instance = eval {
3216       $component->COMPONENT( $class, $config );
3217     } || do {
3218       my $error = $@;
3219       chomp $error;
3220       Catalyst::Exception->throw(
3221         message => qq/Couldn't instantiate component "$component", "$error"/
3222       );
3223     };
3224
3225     unless (blessed $instance) {
3226         my $metaclass = Moose::Util::find_meta($component);
3227         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
3228         my $component_method_from = $method_meta->associated_metaclass->name;
3229         my $value = defined($instance) ? $instance : 'undef';
3230         Catalyst::Exception->throw(
3231             message =>
3232             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
3233         );
3234     }
3235
3236     my @expanded_components = $instance->can('expand_modules')
3237       ? $instance->expand_modules( $component, $config )
3238       : $class->expand_component_module( $component, $config );
3239     for my $component (@expanded_components) {
3240       next if $class->components->{ $component };
3241       $class->components->{ $component } = $class->setup_component($component);
3242     }
3243
3244     return $instance;
3245 }
3246
3247 =head2 $app->config_for( $component_name )
3248
3249 Return the application level configuration (which is not yet merged with any
3250 local component configuration, via $component_class->config) for the named
3251 component or component object. Example:
3252
3253     MyApp->config(
3254       'Model::Foo' => { a => 1, b => 2},
3255     );
3256
3257     my $config = MyApp->config_for('MyApp::Model::Foo');
3258
3259 In this case $config is the hashref C< {a=>1, b=>2} >.
3260
3261 This is also handy for looking up configuration for a plugin, to make sure you follow
3262 existing L<Catalyst> standards for where a plugin should put its configuration.
3263
3264 =cut
3265
3266 sub config_for {
3267     my ($class, $component_name) = @_;
3268     my $component_suffix = Catalyst::Utils::class2classsuffix($component_name);
3269     my $config = $class->config->{ $component_suffix } || {};
3270
3271     return $config;
3272 }
3273
3274 =head2 $c->setup_dispatcher
3275
3276 Sets up dispatcher.
3277
3278 =cut
3279
3280 sub setup_dispatcher {
3281     my ( $class, $dispatcher ) = @_;
3282
3283     if ($dispatcher) {
3284         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
3285     }
3286
3287     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
3288         $dispatcher = 'Catalyst::Dispatcher::' . $env;
3289     }
3290
3291     unless ($dispatcher) {
3292         $dispatcher = $class->dispatcher_class;
3293     }
3294
3295     load_class($dispatcher);
3296
3297     # dispatcher instance
3298     $class->dispatcher( $dispatcher->new );
3299 }
3300
3301 =head2 $c->setup_engine
3302
3303 Sets up engine.
3304
3305 =cut
3306
3307 sub engine_class {
3308     my ($class, $requested_engine) = @_;
3309
3310     if (!$class->engine_loader || $requested_engine) {
3311         $class->engine_loader(
3312             Catalyst::EngineLoader->new({
3313                 application_name => $class,
3314                 (defined $requested_engine
3315                      ? (catalyst_engine_class => $requested_engine) : ()),
3316             }),
3317         );
3318     }
3319
3320     $class->engine_loader->catalyst_engine_class;
3321 }
3322
3323 sub setup_engine {
3324     my ($class, $requested_engine) = @_;
3325
3326     my $engine = do {
3327         my $loader = $class->engine_loader;
3328
3329         if (!$loader || $requested_engine) {
3330             $loader = Catalyst::EngineLoader->new({
3331                 application_name => $class,
3332                 (defined $requested_engine
3333                      ? (requested_engine => $requested_engine) : ()),
3334             }),
3335
3336             $class->engine_loader($loader);
3337         }
3338
3339         $loader->catalyst_engine_class;
3340     };
3341
3342     # Don't really setup_engine -- see _setup_psgi_app for explanation.
3343     return if $class->loading_psgi_file;
3344
3345     load_class($engine);
3346
3347     if ($ENV{MOD_PERL}) {
3348         my $apache = $class->engine_loader->auto;
3349
3350         my $meta = find_meta($class);
3351         my $was_immutable = $meta->is_immutable;
3352         my %immutable_options = $meta->immutable_options;
3353         $meta->make_mutable if $was_immutable;
3354
3355         $meta->add_method(handler => sub {
3356             my $r = shift;
3357             my $psgi_app = $class->_finalized_psgi_app;
3358             $apache->call_app($r, $psgi_app);
3359         });
3360
3361         $meta->make_immutable(%immutable_options) if $was_immutable;
3362     }
3363
3364     $class->engine( $engine->new );
3365
3366     return;
3367 }
3368
3369 ## This exists just to supply a prebuild psgi app for mod_perl and for the
3370 ## build in server support (back compat support for pre psgi port behavior).
3371 ## This is so that we don't build a new psgi app for each request when using
3372 ## the mod_perl handler or the built in servers (http and fcgi, etc).
3373
3374 sub _finalized_psgi_app {
3375     my ($app) = @_;
3376
3377     unless ($app->_psgi_app) {
3378         my $psgi_app = $app->_setup_psgi_app;
3379         $app->_psgi_app($psgi_app);
3380     }
3381
3382     return $app->_psgi_app;
3383 }
3384
3385 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
3386 ## home directory and load that and return it (just assume it is doing the
3387 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
3388 ## in default_middleware and return it ( this is for backward compatibility
3389 ## with pre psgi port behavior ).
3390
3391 sub _setup_psgi_app {
3392     my ($app) = @_;
3393
3394     for my $home (Path::Class::Dir->new($app->config->{home})) {
3395         my $psgi_file = $home->file(
3396             Catalyst::Utils::appprefix($app) . '.psgi',
3397         );
3398
3399         next unless -e $psgi_file;
3400
3401         # If $psgi_file calls ->setup_engine, it's doing so to load
3402         # Catalyst::Engine::PSGI. But if it does that, we're only going to
3403         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
3404         # anyway. So set a flag (ick) that tells setup_engine not to populate
3405         # $c->engine or do any other things we might regret.
3406
3407         $app->loading_psgi_file(1);
3408         my $psgi_app = Plack::Util::load_psgi($psgi_file);
3409         $app->loading_psgi_file(0);
3410
3411         return $psgi_app
3412             unless $app->engine_loader->needs_psgi_engine_compat_hack;
3413
3414         warn <<"EOW";
3415 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
3416
3417 Its content has been ignored. Please consult the Catalyst::Upgrading
3418 documentation on how to upgrade from Catalyst::Engine::PSGI.
3419 EOW
3420     }
3421
3422     return $app->apply_default_middlewares($app->psgi_app);
3423 }
3424
3425 =head2 $c->apply_default_middlewares
3426
3427 Adds the following L<Plack> middlewares to your application, since they are
3428 useful and commonly needed:
3429
3430 L<Plack::Middleware::LighttpdScriptNameFix> (if you are using Lighttpd),
3431 L<Plack::Middleware::IIS6ScriptNameFix> (always applied since this middleware
3432 is smart enough to conditionally apply itself).
3433
3434 We will also automatically add L<Plack::Middleware::ReverseProxy> if we notice
3435 that your HTTP $env variable C<REMOTE_ADDR> is '127.0.0.1'.  This is usually
3436 an indication that your server is running behind a proxy frontend.  However in
3437 2014 this is often not the case.  We preserve this code for backwards compatibility
3438 however I B<highly> recommend that if you are running the server behind a front
3439 end proxy that you clearly indicate so with the C<using_frontend_proxy> configuration
3440 setting to true for your environment configurations that run behind a proxy.  This
3441 way if you change your front end proxy address someday your code would inexplicably
3442 stop working as expected.
3443
3444 Additionally if we detect we are using Nginx, we add a bit of custom middleware
3445 to solve some problems with the way that server handles $ENV{PATH_INFO} and
3446 $ENV{SCRIPT_NAME}.
3447
3448 Please B<NOTE> that if you do use C<using_frontend_proxy> the middleware is now
3449 adding via C<registered_middleware> rather than this method.
3450
3451 If you are using Lighttpd or IIS6 you may wish to apply these middlewares.  In
3452 general this is no longer a common case but we have this here for backward
3453 compatibility.
3454
3455 =cut
3456
3457
3458 sub apply_default_middlewares {
3459     my ($app, $psgi_app) = @_;
3460
3461     # Don't add this conditional IF we are explicitly saying we want the
3462     # frontend proxy support.  We don't need it here since if that is the
3463     # case it will be always loaded in the default_middleware.
3464
3465     unless($app->config->{using_frontend_proxy}) {
3466       $psgi_app = Plack::Middleware::Conditional->wrap(
3467           $psgi_app,
3468           builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
3469           condition => sub {
3470               my ($env) = @_;
3471               return if $app->config->{ignore_frontend_proxy};
3472               return $env->{REMOTE_ADDR} eq '127.0.0.1';
3473           },
3474       );
3475     }
3476
3477     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3478     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3479     $psgi_app = Plack::Middleware::Conditional->wrap(
3480         $psgi_app,
3481         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3482         condition => sub {
3483             my ($env) = @_;
3484             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3485             return unless $1 < 4.23;
3486             1;
3487         },
3488     );
3489
3490     # we're applying this unconditionally as the middleware itself already makes
3491     # sure it doesn't fuck things up if it's not running under one of the right
3492     # IIS versions
3493     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3494
3495     # And another IIS issue, this time with IIS7.
3496     $psgi_app = Plack::Middleware::Conditional->wrap(
3497         $psgi_app,
3498         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3499         condition => sub {
3500             my ($env) = @_;
3501             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3502         },
3503     );
3504
3505     return $psgi_app;
3506 }
3507
3508 =head2 App->psgi_app
3509
3510 =head2 App->to_app
3511
3512 Returns a PSGI application code reference for the catalyst application
3513 C<$c>. This is the bare application created without the C<apply_default_middlewares>
3514 method called.  We do however apply C<registered_middleware> since those are
3515 integral to how L<Catalyst> functions.  Also, unlike starting your application
3516 with a generated server script (via L<Catalyst::Devel> and C<catalyst.pl>) we do
3517 not attempt to return a valid L<PSGI> application using any existing C<${myapp}.psgi>
3518 scripts in your $HOME directory.
3519
3520 B<NOTE> C<apply_default_middlewares> was originally created when the first PSGI
3521 port was done for v5.90000.  These are middlewares that are added to achieve
3522 backward compatibility with older applications.  If you start your application
3523 using one of the supplied server scripts (generated with L<Catalyst::Devel> and
3524 the project skeleton script C<catalyst.pl>) we apply C<apply_default_middlewares>
3525 automatically.  This was done so that pre and post PSGI port applications would
3526 work the same way.
3527
3528 This is what you want to be using to retrieve the PSGI application code
3529 reference of your Catalyst application for use in a custom F<.psgi> or in your
3530 own created server modules.
3531
3532 =cut
3533
3534 *to_app = \&psgi_app;
3535
3536 sub psgi_app {
3537     my ($app) = @_;
3538     my $psgi = $app->engine->build_psgi_app($app);
3539     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3540 }
3541
3542 =head2 $c->setup_home
3543
3544 Sets up the home directory.
3545
3546 =cut
3547
3548 sub setup_home {
3549     my ( $class, $home ) = @_;
3550
3551     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3552         $home = $env;
3553     }
3554
3555     $home ||= Catalyst::Utils::home($class);
3556
3557     if ($home) {
3558         #I remember recently being scolded for assigning config values like this
3559         $class->config->{home} ||= $home;
3560         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3561     }
3562 }
3563
3564 =head2 $c->setup_encoding
3565
3566 Sets up the input/output encoding. See L<ENCODING>
3567
3568 =cut
3569
3570 sub setup_encoding {
3571     my $c = shift;
3572     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3573         # Ok, so the user has explicitly said "I don't want encoding..."
3574         return;
3575     } else {
3576       my $enc = defined($c->config->{encoding}) ?
3577         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3578       $c->encoding($enc);
3579     }
3580 }
3581
3582 =head2 handle_unicode_encoding_exception
3583
3584 Hook to let you customize how encoding errors are handled. By default
3585 we just throw an exception and the default error page will pick it up.
3586 Receives a hashref of debug information. Example of call (from the
3587 Catalyst internals):
3588
3589   my $decoded_after_fail = $c->handle_unicode_encoding_exception({
3590         param_value => $value,
3591         error_msg => $_,
3592         encoding_step => 'params',
3593    });
3594
3595 The calling code expects to receive a decoded string or an exception.
3596
3597 You can override this for custom handling of unicode errors. By
3598 default we just die. If you want a custom response here, one approach
3599 is to throw an HTTP style exception, instead of returning a decoded
3600 string or throwing a generic exception.
3601
3602     sub handle_unicode_encoding_exception {
3603       my ($c, $params) = @_;
3604       HTTP::Exception::BAD_REQUEST->throw(status_message=>$params->{error_msg});
3605     }
3606
3607 Alternatively you can 'catch' the error, stash it and write handling code later
3608 in your application:
3609
3610     sub handle_unicode_encoding_exception {
3611       my ($c, $params) = @_;
3612       $c->stash(BAD_UNICODE_DATA=>$params);
3613       # return a dummy string.
3614       return 1;
3615     }
3616
3617 <B>NOTE:</b> Please keep in mind that once an error like this occurs,
3618 the request setup is still ongoing, which means the state of C<$c> and
3619 related context parts like the request and response may not be setup
3620 up correctly (since we haven't finished the setup yet). If you throw
3621 an exception the setup is aborted.
3622
3623 =cut
3624
3625 sub handle_unicode_encoding_exception {
3626     my ( $self, $exception_ctx ) = @_;
3627     die $exception_ctx->{error_msg};
3628 }
3629
3630 # Some unicode helpers cargo culted from the old plugin.  These could likely
3631 # be neater.
3632
3633 sub _handle_unicode_decoding {
3634     my ( $self, $value ) = @_;
3635
3636     return unless defined $value;
3637
3638     ## I think this mess is to support the old nested
3639     if ( ref $value eq 'ARRAY' ) {
3640         foreach ( @$value ) {
3641             $_ = $self->_handle_unicode_decoding($_);
3642         }
3643         return $value;
3644     }
3645     elsif ( ref $value eq 'HASH' ) {
3646         foreach (keys %$value) {
3647             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3648             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3649
3650             # If the key was encoded we now have two (the original and current so
3651             # delete the original.
3652             delete $value->{$_} if $_ ne $encoded_key;
3653         }
3654         return $value;
3655     }
3656     else {
3657         return $self->_handle_param_unicode_decoding($value);
3658     }
3659 }
3660
3661 sub _handle_param_unicode_decoding {
3662     my ( $self, $value, $check ) = @_;
3663     return unless defined $value; # not in love with just ignoring undefs - jnap
3664     return $value if blessed($value); #don't decode when the value is an object.
3665
3666     my $enc = $self->encoding;
3667
3668     return $value unless $enc; # don't decode if no encoding is specified
3669
3670     $check ||= $self->_encode_check;
3671     return try {
3672       $enc->decode( $value, $check);
3673     }
3674     catch {
3675         return $self->handle_unicode_encoding_exception({
3676             param_value => $value,
3677             error_msg => $_,
3678             encoding_step => 'params',
3679         });
3680     };
3681 }
3682
3683 =head2 $c->setup_log
3684
3685 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3686 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3687 log to.
3688
3689 This method also installs a C<debug> method that returns a true value into the
3690 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3691 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3692
3693 Note that if the log has already been setup, by either a previous call to
3694 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3695 that this method won't actually set up the log object.
3696
3697 =cut
3698
3699 sub setup_log {
3700     my ( $class, $levels ) = @_;
3701
3702     $levels ||= '';
3703     $levels =~ s/^\s+//;
3704     $levels =~ s/\s+$//;
3705     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3706
3707     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3708     if ( defined $env_debug ) {
3709         $levels{debug} = 1 if $env_debug; # Ugly!
3710         delete($levels{debug}) unless $env_debug;
3711     }
3712
3713     unless ( $class->log ) {
3714         $class->log( Catalyst::Log->new(keys %levels) );
3715     }
3716
3717     if ( $levels{debug} ) {
3718         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3719         $class->log->debug('Debug messages enabled');
3720     }
3721 }
3722
3723 =head2 $c->setup_plugins
3724
3725 Sets up plugins.
3726
3727 =cut
3728
3729 =head2 $c->setup_stats
3730
3731 Sets up timing statistics class.
3732
3733 =cut
3734
3735 sub setup_stats {
3736     my ( $class, $stats ) = @_;
3737
3738     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3739
3740     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3741     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3742         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3743         $class->log->debug('Statistics enabled');
3744     }
3745 }
3746
3747
3748 =head2 $c->registered_plugins
3749
3750 Returns a sorted list of the plugins which have either been stated in the
3751 import list.
3752
3753 If passed a given plugin name, it will report a boolean value indicating
3754 whether or not that plugin is loaded.  A fully qualified name is required if
3755 the plugin name does not begin with C<Catalyst::Plugin::>.
3756
3757  if ($c->registered_plugins('Some::Plugin')) {
3758      ...
3759  }
3760
3761 =cut
3762
3763 {
3764
3765     sub registered_plugins {
3766         my $proto = shift;
3767         return sort keys %{ $proto->_plugins } unless @_;
3768         my $plugin = shift;
3769         return 1 if exists $proto->_plugins->{$plugin};
3770         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3771     }
3772
3773     sub _register_plugin {
3774         my ( $proto, $plugin, $instant ) = @_;
3775         my $class = ref $proto || $proto;
3776
3777         load_class( $plugin );
3778         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3779             if $plugin->isa( 'Catalyst::Component' );
3780         my $plugin_meta = Moose::Meta::Class->create($plugin);
3781         if (!$plugin_meta->has_method('new')
3782             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3783             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3784         }
3785         if (!$instant && !$proto->_plugins->{$plugin}) {
3786             my $meta = Class::MOP::get_metaclass_by_name($class);
3787             $meta->superclasses($plugin, $meta->superclasses);
3788         }
3789         $proto->_plugins->{$plugin} = 1;
3790         return $class;
3791     }
3792
3793     sub _default_plugins { return qw() }
3794
3795     sub setup_plugins {
3796         my ( $class, $plugins ) = @_;
3797
3798         $class->_plugins( {} ) unless $class->_plugins;
3799         $plugins = [ grep {
3800             m/Unicode::Encoding/ ? do {
3801                 $class->log->warn(
3802                     'Unicode::Encoding plugin is auto-applied,'
3803                     . ' please remove this from your appclass'
3804                     . ' and make sure to define "encoding" config'
3805                 );
3806                 unless (exists $class->config->{'encoding'}) {
3807                   $class->config->{'encoding'} = 'UTF-8';
3808                 }
3809                 () }
3810                 : $_
3811         } @$plugins ];
3812         push @$plugins, $class->_default_plugins;
3813         $plugins = Data::OptList::mkopt($plugins || []);
3814
3815         my @plugins = map {
3816             [ Catalyst::Utils::resolve_namespace(
3817                   $class . '::Plugin',
3818                   'Catalyst::Plugin', $_->[0]
3819               ),
3820               $_->[1],
3821             ]
3822          } @{ $plugins };
3823
3824         for my $plugin ( reverse @plugins ) {
3825             load_class($plugin->[0], $plugin->[1]);
3826             my $meta = find_meta($plugin->[0]);
3827             next if $meta && $meta->isa('Moose::Meta::Role');
3828
3829             $class->_register_plugin($plugin->[0]);
3830         }
3831
3832         my @roles =
3833             map  { $_->[0]->name, $_->[1] }
3834             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3835             map  { [find_meta($_->[0]), $_->[1]] }
3836             @plugins;
3837
3838         Moose::Util::apply_all_roles(
3839             $class => @roles
3840         ) if @roles;
3841     }
3842 }
3843
3844 =head2 default_middleware
3845
3846 Returns a list of instantiated PSGI middleware objects which is the default
3847 middleware that is active for this application (taking any configuration
3848 options into account, excluding your custom added middleware via the C<psgi_middleware>
3849 configuration option).  You can override this method if you wish to change
3850 the default middleware (although do so at risk since some middleware is vital
3851 to application function.)
3852
3853 The current default middleware list is:
3854
3855       Catalyst::Middleware::Stash
3856       Plack::Middleware::HTTPExceptions
3857       Plack::Middleware::RemoveRedundantBody
3858       Plack::Middleware::FixMissingBodyInRedirect
3859       Plack::Middleware::ContentLength
3860       Plack::Middleware::MethodOverride
3861       Plack::Middleware::Head
3862
3863 If the configuration setting C<using_frontend_proxy> is true we add:
3864
3865       Plack::Middleware::ReverseProxy
3866
3867 If the configuration setting C<using_frontend_proxy_path> is true we add:
3868
3869       Plack::Middleware::ReverseProxyPath
3870
3871 But B<NOTE> that L<Plack::Middleware::ReverseProxyPath> is not a dependency of the
3872 L<Catalyst> distribution so if you want to use this option you should add it to
3873 your project distribution file.
3874
3875 These middlewares will be added at L</setup_middleware> during the
3876 L</setup> phase of application startup.
3877
3878 =cut
3879
3880 sub default_middleware {
3881     my $class = shift;
3882     my @mw = (
3883       Catalyst::Middleware::Stash->new,
3884       Plack::Middleware::HTTPExceptions->new,
3885       Plack::Middleware::RemoveRedundantBody->new,
3886       Plack::Middleware::FixMissingBodyInRedirect->new,
3887       Plack::Middleware::ContentLength->new,
3888       Plack::Middleware::MethodOverride->new,
3889       Plack::Middleware::Head->new);
3890
3891     if($class->config->{using_frontend_proxy}) {
3892         push @mw, Plack::Middleware::ReverseProxy->new;
3893     }
3894
3895     if($class->config->{using_frontend_proxy_path}) {
3896         if(Class::Load::try_load_class('Plack::Middleware::ReverseProxyPath')) {
3897             push @mw, Plack::Middleware::ReverseProxyPath->new;
3898         } else {
3899           $class->log->error("Cannot use configuration 'using_frontend_proxy_path' because 'Plack::Middleware::ReverseProxyPath' is not installed");
3900         }
3901     }
3902
3903     return @mw;
3904 }
3905
3906 =head2 registered_middlewares
3907
3908 Read only accessor that returns an array of all the middleware in the order
3909 that they were added (which is the REVERSE of the order they will be applied).
3910
3911 The values returned will be either instances of L<Plack::Middleware> or of a
3912 compatible interface, or a coderef, which is assumed to be inlined middleware
3913
3914 =head2 setup_middleware (?@middleware)
3915
3916 Read configuration information stored in configuration key C<psgi_middleware> or
3917 from passed @args.
3918
3919 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3920 to use it to enable L<Plack::Middleware>
3921
3922 This method is automatically called during 'setup' of your application, so
3923 you really don't need to invoke it.  However you may do so if you find the idea
3924 of loading middleware via configuration weird :).  For example:
3925
3926     package MyApp;
3927
3928     use Catalyst;
3929
3930     __PACKAGE__->setup_middleware('Head');
3931     __PACKAGE__->setup;
3932
3933 When we read middleware definitions from configuration, we reverse the list
3934 which sounds odd but is likely how you expect it to work if you have prior
3935 experience with L<Plack::Builder> or if you previously used the plugin
3936 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3937
3938 So basically your middleware handles an incoming request from the first
3939 registered middleware, down and handles the response from the last middleware
3940 up.
3941
3942 =cut
3943
3944 sub registered_middlewares {
3945     my $class = shift;
3946     if(my $middleware = $class->_psgi_middleware) {
3947         my @mw = ($class->default_middleware, @$middleware);
3948
3949         if($class->config->{using_frontend_proxy}) {
3950           push @mw, Plack::Middleware::ReverseProxy->new;
3951         }
3952
3953         return @mw;
3954     } else {
3955         die "You cannot call ->registered_middlewares until middleware has been setup";
3956     }
3957 }
3958
3959 sub setup_middleware {
3960     my $class = shift;
3961     my @middleware_definitions;
3962
3963     # If someone calls this method you can add middleware with args.  However if its
3964     # called without an arg we need to setup the configuration middleware.
3965     if(@_) {
3966       @middleware_definitions = reverse(@_);
3967     } else {
3968       @middleware_definitions = reverse(@{$class->config->{'psgi_middleware'}||[]})
3969         unless $class->finalized_default_middleware;
3970       $class->finalized_default_middleware(1); # Only do this once, just in case some people call setup over and over...
3971     }
3972
3973     my @middleware = ();
3974     while(my $next = shift(@middleware_definitions)) {
3975         if(ref $next) {
3976             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3977                 push @middleware, $next;
3978             } elsif(ref $next eq 'CODE') {
3979                 push @middleware, $next;
3980             } elsif(ref $next eq 'HASH') {
3981                 my $namespace = shift @middleware_definitions;
3982                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3983                 push @middleware, $mw;
3984             } else {
3985               die "I can't handle middleware definition ${\ref $next}";
3986             }
3987         } else {
3988           my $mw = $class->Catalyst::Utils::build_middleware($next);
3989           push @middleware, $mw;
3990         }
3991     }
3992
3993     my @existing = @{$class->_psgi_middleware || []};
3994     $class->_psgi_middleware([@middleware,@existing,]);
3995 }
3996
3997 =head2 registered_data_handlers
3998
3999 A read only copy of registered Data Handlers returned as a Hash, where each key
4000 is a content type and each value is a subref that attempts to decode that content
4001 type.
4002
4003 =head2 setup_data_handlers (?@data_handler)
4004
4005 Read configuration information stored in configuration key C<data_handlers> or
4006 from passed @args.
4007
4008 See under L</CONFIGURATION> information regarding C<data_handlers>.
4009
4010 This method is automatically called during 'setup' of your application, so
4011 you really don't need to invoke it.
4012
4013 =head2 default_data_handlers
4014
4015 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
4016 only two default data handlers, for 'application/json' and an alternative to
4017 'application/x-www-form-urlencoded' which supposed nested form parameters via
4018 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
4019
4020 The 'application/json' data handler is used to parse incoming JSON into a Perl
4021 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
4022 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
4023 JSON decoder, and has the smallest dependency impact.
4024
4025 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
4026 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
4027 order to get the best performance.  You should add either to your dependency
4028 list (Makefile.PL, dist.ini, cpanfile, etc.)
4029
4030 =cut
4031
4032 sub registered_data_handlers {
4033     my $class = shift;
4034     if(my $data_handlers = $class->_data_handlers) {
4035         return %$data_handlers;
4036     } else {
4037         $class->setup_data_handlers;
4038         return $class->registered_data_handlers;
4039     }
4040 }
4041
4042 sub setup_data_handlers {
4043     my ($class, %data_handler_callbacks) = @_;
4044     %data_handler_callbacks = (
4045       %{$class->default_data_handlers},
4046       %{$class->config->{'data_handlers'}||+{}},
4047       %data_handler_callbacks);
4048
4049     $class->_data_handlers(\%data_handler_callbacks);
4050 }
4051
4052 sub default_data_handlers {
4053     my ($class) = @_;
4054     return +{
4055       'application/x-www-form-urlencoded' => sub {
4056           my ($fh, $req) = @_;
4057           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
4058           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
4059             ->can('build_cgi_struct')->($params);
4060       },
4061       'application/json' => sub {
4062           my ($fh, $req) = @_;
4063           my $parser = Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON');
4064           my $slurped;
4065           return eval {
4066             local $/;
4067             $slurped = $fh->getline;
4068             $parser->can("decode_json")->($slurped); # decode_json does utf8 decoding for us
4069           } || Catalyst::Exception->throw(sprintf "Error Parsing POST '%s', Error: %s", (defined($slurped) ? $slurped : 'undef') ,$@);
4070         },
4071     };
4072 }
4073
4074 sub _handle_http_exception {
4075     my ( $self, $error ) = @_;
4076     if (
4077            !$self->config->{always_catch_http_exceptions}
4078         && blessed $error
4079         && (
4080             $error->can('as_psgi')
4081             || (   $error->can('code')
4082                 && $error->code =~ m/^[1-5][0-9][0-9]$/ )
4083         )
4084       )
4085     {
4086         return 1;
4087     }
4088 }
4089
4090 =head2 $c->stack
4091
4092 Returns an arrayref of the internal execution stack (actions that are
4093 currently executing).
4094
4095 =head2 $c->stats
4096
4097 Returns the current timing statistics object. By default Catalyst uses
4098 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
4099 L<< stats_class|/"$c->stats_class" >>.
4100
4101 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
4102 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
4103 profile explicitly, although MyApp.pm still won't profile nor output anything
4104 by itself.
4105
4106 =head2 $c->stats_class
4107
4108 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
4109
4110 =head2 $app->stats_class_traits
4111
4112 A arrayref of L<Moose::Role>s that are applied to the stats_class before creating it.
4113
4114 =head2 $app->composed_stats_class
4115
4116 this is the stats_class composed with any 'stats_class_traits'.  You can
4117 name the full namespace of the role, or a namespace suffix, which will then
4118 be tried against the following standard namespace prefixes.
4119
4120     $MyApp::TraitFor::Stats::$trait_suffix
4121     Catalyst::TraitFor::Stats::$trait_suffix
4122
4123 So for example if you set:
4124
4125     MyApp->stats_class_traits(['Foo']);
4126
4127 We try each possible role in turn (and throw an error if none load)
4128
4129     Foo
4130     MyApp::TraitFor::Stats::Foo
4131     Catalyst::TraitFor::Stats::Foo
4132
4133 The namespace part 'TraitFor::Stats' was chosen to assist in backwards
4134 compatibility with L<CatalystX::RoleApplicator> which previously provided
4135 these features in a stand alone package.
4136
4137 =head2 $c->use_stats
4138
4139 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
4140
4141 Note that this is a static method, not an accessor and should be overridden
4142 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
4143
4144 =cut
4145
4146 sub use_stats { 0 }
4147
4148
4149 =head2 $c->write( $data )
4150
4151 Writes $data to the output stream. When using this method directly, you
4152 will need to manually set the C<Content-Length> header to the length of
4153 your output data, if known.
4154
4155 =cut
4156
4157 sub write {
4158     my $c = shift;
4159
4160     # Finalize headers if someone manually writes output (for compat)
4161     $c->finalize_headers;
4162
4163     return $c->response->write( @_ );
4164 }
4165
4166 =head2 version
4167
4168 Returns the Catalyst version number. Mostly useful for "powered by"
4169 messages in template systems.
4170
4171 =cut
4172
4173 sub version { return $Catalyst::VERSION }
4174
4175 =head1 CONFIGURATION
4176
4177 There are a number of 'base' config variables which can be set:
4178
4179 =over
4180
4181 =item *
4182
4183 C<always_catch_http_exceptions> - As of version 5.90060 Catalyst
4184 rethrows errors conforming to the interface described by
4185 L<Plack::Middleware::HTTPExceptions> and lets the middleware deal with it.
4186 Set true to get the deprecated behaviour and have Catalyst catch HTTP exceptions.
4187
4188 =item *
4189
4190 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
4191
4192 =item *
4193
4194 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
4195
4196 =item *
4197
4198 C<disable_component_resolution_regex_fallback> - Turns
4199 off the deprecated component resolution functionality so
4200 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
4201 are called then regex search will not be attempted on string values and
4202 instead C<undef> will be returned.
4203
4204 =item *
4205
4206 C<home> - The application home directory. In an uninstalled application,
4207 this is the top level application directory. In an installed application,
4208 this will be the directory containing C<< MyApp.pm >>.
4209
4210 =item *
4211
4212 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
4213
4214 =item *
4215
4216 C<name> - The name of the application in debug messages and the debug and
4217 welcome screens
4218
4219 =item *
4220
4221 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
4222 until it is accessed. This allows you to (for example) check authentication (and reject
4223 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
4224
4225 =item *
4226
4227 C<root> - The root directory for templates. Usually this is just a
4228 subdirectory of the home directory, but you can set it to change the
4229 templates to a different directory.
4230
4231 =item *
4232
4233 C<search_extra> - Array reference passed to Module::Pluggable to for additional
4234 namespaces from which components will be loaded (and constructed and stored in
4235 C<< $c->components >>).
4236
4237 =item *
4238
4239 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
4240 to be shown in hit debug tables in the test server.
4241
4242 =item *
4243
4244 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
4245 variable should be used for determining the request path.
4246
4247 Most web server environments pass the requested path to the application using environment variables,
4248 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
4249 exposed as C<< $c->request->base >>) and the request path below that base.
4250
4251 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
4252 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
4253
4254 =over
4255
4256 =item use_request_uri_for_path => 0
4257
4258 This is the default (and the) traditional method that Catalyst has used for determining the path information.
4259 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
4260 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
4261 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
4262
4263 However this method has the major disadvantage that it is impossible to correctly decode some elements
4264 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
4265 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
4266 can't distinguish / vs %2F in paths (in addition to other encoded values).
4267
4268 =item use_request_uri_for_path => 1
4269
4270 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
4271 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
4272 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
4273
4274 Given that this method of path resolution is provably more correct, it is recommended that you use
4275 this unless you have a specific need to deploy your application in a non-standard environment, and you are
4276 aware of the implications of not being able to handle encoded URI paths correctly.
4277
4278 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
4279 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
4280 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
4281 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
4282 C<< $c->request->base >> will be incorrect.
4283
4284 =back
4285
4286 =item *
4287
4288 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
4289
4290 =item *
4291
4292 C<using_frontend_proxy_path> - Enabled L<Plack::Middleware::ReverseProxyPath> on your application (if
4293 installed, otherwise log an error).  This is useful if your application is not running on the
4294 'root' (or /) of your host server.  B<NOTE> if you use this feature you should add the required
4295 middleware to your project dependency list since its not automatically a dependency of L<Catalyst>.
4296 This has been done since not all people need this feature and we wish to restrict the growth of
4297 L<Catalyst> dependencies.
4298
4299 =item *
4300
4301 C<encoding> - See L</ENCODING>
4302
4303 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
4304 value to undef.
4305
4306 =item *
4307
4308 C<abort_chain_on_error_fix>
4309
4310 When there is an error in an action chain, the default behavior is to continue
4311 processing the remaining actions and then catch the error upon chain end.  This
4312 can lead to running actions when the application is in an unexpected state.  If
4313 you have this issue, setting this config value to true will promptly exit a
4314 chain when there is an error raised in any action (thus terminating the chain
4315 early.)
4316
4317 use like:
4318
4319     __PACKAGE__->config(abort_chain_on_error_fix => 1);
4320
4321 In the future this might become the default behavior.
4322
4323 =item *
4324
4325 C<use_hash_multivalue_in_request>
4326
4327 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
4328 and C<parameters> return a hashref where values might be scalar or an arrayref
4329 depending on the incoming data.  In many cases this can be undesirable as it
4330 leads one to writing defensive code like the following:
4331
4332     my ($val) = ref($c->req->parameters->{a}) ?
4333       @{$c->req->parameters->{a}} :
4334         $c->req->parameters->{a};
4335
4336 Setting this configuration item to true will make L<Catalyst> populate the
4337 attributes underlying these methods with an instance of L<Hash::MultiValue>
4338 which is used by L<Plack::Request> and others to solve this very issue.  You
4339 may prefer this behavior to the default, if so enable this option (be warned
4340 if you enable it in a legacy application we are not sure if it is completely
4341 backwardly compatible).
4342
4343 =item *
4344
4345 C<skip_complex_post_part_handling>
4346
4347 When creating body parameters from a POST, if we run into a multipart POST
4348 that does not contain uploads, but instead contains inlined complex data
4349 (very uncommon) we cannot reliably convert that into field => value pairs.  So
4350 instead we create an instance of L<Catalyst::Request::PartData>.  If this causes
4351 issue for you, you can disable this by setting C<skip_complex_post_part_handling>
4352 to true (default is false).
4353
4354 =item *
4355
4356 C<skip_body_param_unicode_decoding>
4357
4358 Generally we decode incoming POST params based on your declared encoding (the
4359 default for this is to decode UTF-8).  If this is causing you trouble and you
4360 do not wish to turn all encoding support off (with the C<encoding> configuration
4361 parameter) you may disable this step atomically by setting this configuration
4362 parameter to true.
4363
4364 =item *
4365
4366 C<do_not_decode_query>
4367
4368 If true, then do not try to character decode any wide characters in your
4369 request URL query or keywords.  Most readings of the relevant specifications
4370 suggest these should be UTF-* encoded, which is the default that L<Catalyst>
4371 will use, however if you are creating a lot of URLs manually or have external
4372 evil clients, this might cause you trouble.  If you find the changes introduced
4373 in Catalyst version 5.90080+ break some of your query code, you may disable
4374 the UTF-8 decoding globally using this configuration.
4375
4376 This setting takes precedence over C<default_query_encoding>
4377
4378 =item *
4379
4380 C<do_not_check_query_encoding>
4381
4382 Catalyst versions 5.90080 - 5.90106 would decode query parts of an incoming
4383 request but would not raise an exception when the decoding failed due to
4384 incorrect unicode.  It now does, but if this change is giving you trouble
4385 you may disable it by setting this configuration to true.
4386
4387 =item *
4388
4389 C<default_query_encoding>
4390
4391 By default we decode query and keywords in your request URL using UTF-8, which
4392 is our reading of the relevant specifications.  This setting allows one to
4393 specify a fixed value for how to decode your query.  You might need this if
4394 you are doing a lot of custom encoding of your URLs and not using UTF-8.
4395
4396 =item *
4397
4398 C<use_chained_args_0_special_case>
4399
4400 In older versions of Catalyst, when more than one action matched the same path
4401 AND all those matching actions declared Args(0), we'd break the tie by choosing
4402 the first action defined.  We now normalized how Args(0) works so that it
4403 follows the same rule as Args(N), which is to say when we need to break a tie
4404 we choose the LAST action defined.  If this breaks your code and you don't
4405 have time to update to follow the new normalized approach, you may set this
4406 value to true and it will globally revert to the original chaining behavior.
4407
4408 =item *
4409
4410 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
4411
4412 =item *
4413
4414 C<data_handlers> - See L<DATA HANDLERS>.
4415
4416 =item *
4417
4418 C<stats_class_traits>
4419
4420 An arrayref of L<Moose::Role>s that get composed into your stats class.
4421
4422 =item *
4423
4424 C<request_class_traits>
4425
4426 An arrayref of L<Moose::Role>s that get composed into your request class.
4427
4428 =item *
4429
4430 C<response_class_traits>
4431
4432 An arrayref of L<Moose::Role>s that get composed into your response class.
4433
4434 =item *
4435
4436 C<inject_components>
4437
4438 A Hashref of L<Catalyst::Component> subclasses that are 'injected' into configuration.
4439 For example:
4440
4441     MyApp->config({
4442       inject_components => {
4443         'Controller::Err' => { from_component => 'Local::Controller::Errors' },
4444         'Model::Zoo' => { from_component => 'Local::Model::Foo' },
4445         'Model::Foo' => { from_component => 'Local::Model::Foo', roles => ['TestRole'] },
4446       },
4447       'Controller::Err' => { a => 100, b=>200, namespace=>'error' },
4448       'Model::Zoo' => { a => 2 },
4449       'Model::Foo' => { a => 100 },
4450     });
4451
4452 Generally L<Catalyst> looks for components in your Model/View or Controller directories.
4453 However for cases when you which to use an existing component and you don't need any
4454 customization (where for when you can apply a role to customize it) you may inject those
4455 components into your application.  Please note any configuration should be done 'in the
4456 normal way', with a key under configuration named after the component affix, as in the
4457 above example.
4458
4459 Using this type of injection allows you to construct significant amounts of your application
4460 with only configuration!.  This may or may not lead to increased code understanding.
4461
4462 Please not you may also call the ->inject_components application method as well, although
4463 you must do so BEFORE setup.
4464
4465 =back
4466
4467 =head1 EXCEPTIONS
4468
4469 Generally when you throw an exception inside an Action (or somewhere in
4470 your stack, such as in a model that an Action is calling) that exception
4471 is caught by Catalyst and unless you either catch it yourself (via eval
4472 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
4473 will eventually reach L</finalize_errors> and return either the debugging
4474 error stack page, or the default error page.  However, if your exception
4475 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
4476 instead rethrow it so that it can be handled by that middleware (which
4477 is part of the default middleware).  For example this would allow
4478
4479     use HTTP::Throwable::Factory 'http_throw';
4480
4481     sub throws_exception :Local {
4482       my ($self, $c) = @_;
4483
4484       http_throw(SeeOther => { location =>
4485         $c->uri_for($self->action_for('redirect')) });
4486
4487     }
4488
4489 =head1 INTERNAL ACTIONS
4490
4491 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
4492 C<_ACTION>, and C<_END>. These are by default not shown in the private
4493 action table, but you can make them visible with a config parameter.
4494
4495     MyApp->config(show_internal_actions => 1);
4496
4497 =head1 ON-DEMAND PARSER
4498
4499 The request body is usually parsed at the beginning of a request,
4500 but if you want to handle input yourself, you can enable on-demand
4501 parsing with a config parameter.
4502
4503     MyApp->config(parse_on_demand => 1);
4504
4505 =head1 PROXY SUPPORT
4506
4507 Many production servers operate using the common double-server approach,
4508 with a lightweight frontend web server passing requests to a larger
4509 backend server. An application running on the backend server must deal
4510 with two problems: the remote user always appears to be C<127.0.0.1> and
4511 the server's hostname will appear to be C<localhost> regardless of the
4512 virtual host that the user connected through.
4513
4514 Catalyst will automatically detect this situation when you are running
4515 the frontend and backend servers on the same machine. The following
4516 changes are made to the request.
4517
4518     $c->req->address is set to the user's real IP address, as read from
4519     the HTTP X-Forwarded-For header.
4520
4521     The host value for $c->req->base and $c->req->uri is set to the real
4522     host, as read from the HTTP X-Forwarded-Host header.
4523
4524 Additionally, you may be running your backend application on an insecure
4525 connection (port 80) while your frontend proxy is running under SSL.  If there
4526 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
4527 tell Catalyst what port the frontend listens on.  This will allow all URIs to
4528 be created properly.
4529
4530 In the case of passing in:
4531
4532     X-Forwarded-Port: 443
4533
4534 All calls to C<uri_for> will result in an https link, as is expected.
4535
4536 Obviously, your web server must support these headers for this to work.
4537
4538 In a more complex server farm environment where you may have your
4539 frontend proxy server(s) on different machines, you will need to set a
4540 configuration option to tell Catalyst to read the proxied data from the
4541 headers.
4542
4543     MyApp->config(using_frontend_proxy => 1);
4544
4545 If you do not wish to use the proxy support at all, you may set:
4546
4547     MyApp->config(ignore_frontend_proxy => 0);
4548
4549 =head2 Note about psgi files
4550
4551 Note that if you supply your own .psgi file, calling
4552 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
4553
4554 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
4555 in your psgi, for example:
4556
4557     builder {
4558         enable "Plack::Middleware::ReverseProxy";
4559         MyApp->psgi_app
4560     };
4561
4562 This will unconditionally add the ReverseProxy support, or you need to call
4563 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
4564 apply the support depending upon your config).
4565
4566 See L<Catalyst::PSGI> for more information.
4567
4568 =head1 THREAD SAFETY
4569
4570 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
4571 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
4572 believe the Catalyst core to be thread-safe.
4573
4574 If you plan to operate in a threaded environment, remember that all other
4575 modules you are using must also be thread-safe. Some modules, most notably
4576 L<DBD::SQLite>, are not thread-safe.
4577
4578 =head1 DATA HANDLERS
4579
4580 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
4581 form parameters and URL search query fields.  However it has become common
4582 for various alternative content types to be PUT or POSTed to your controllers
4583 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
4584 XML and other content types when communicating with an application server.  In
4585 order to better support this use case, L<Catalyst> defines a global configuration
4586 option, C<data_handlers>, which lets you associate a content type with a coderef
4587 that parses that content type into something Perl can readily access.
4588
4589     package MyApp::Web;
4590
4591     use Catalyst;
4592     use JSON::Maybe;
4593
4594     __PACKAGE__->config(
4595       data_handlers => {
4596         'application/json' => sub { local $/; decode_json $_->getline },
4597       },
4598       ## Any other configuration.
4599     );
4600
4601     __PACKAGE__->setup;
4602
4603 By default L<Catalyst> comes with a generic JSON data handler similar to the
4604 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
4605 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
4606 it installed (if you want the faster XS parser, add it to you project Makefile.PL
4607 or dist.ini, cpanfile, etc.)
4608
4609 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
4610 (matched against the incoming request type using a regexp such as to be case
4611 insensitive) and whose values are coderefs that receive a localized version of
4612 C<$_> which is a filehandle object pointing to received body.
4613
4614 This feature is considered an early access release and we reserve the right
4615 to alter the interface in order to provide a performant and secure solution to
4616 alternative request body content.  Your reports welcomed!
4617
4618 =head1 PSGI MIDDLEWARE
4619
4620 You can define middleware, defined as L<Plack::Middleware> or a compatible
4621 interface in configuration.  Your middleware definitions are in the form of an
4622 arrayref under the configuration key C<psgi_middleware>.  Here's an example
4623 with details to follow:
4624
4625     package MyApp::Web;
4626
4627     use Catalyst;
4628     use Plack::Middleware::StackTrace;
4629
4630     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4631
4632     __PACKAGE__->config(
4633       'psgi_middleware', [
4634         'Debug',
4635         '+MyApp::Custom',
4636         $stacktrace_middleware,
4637         'Session' => {store => 'File'},
4638         sub {
4639           my $app = shift;
4640           return sub {
4641             my $env = shift;
4642             $env->{myapp.customkey} = 'helloworld';
4643             $app->($env);
4644           },
4645         },
4646       ],
4647     );
4648
4649     __PACKAGE__->setup;
4650
4651 So the general form is:
4652
4653     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
4654
4655 Where C<@middleware> is one or more of the following, applied in the REVERSE of
4656 the order listed (to make it function similarly to L<Plack::Builder>:
4657
4658 Alternatively, you may also define middleware by calling the L</setup_middleware>
4659 package method:
4660
4661     package MyApp::Web;
4662
4663     use Catalyst;
4664
4665     __PACKAGE__->setup_middleware( \@middleware_definitions);
4666     __PACKAGE__->setup;
4667
4668 In the case where you do both (use 'setup_middleware' and configuration) the
4669 package call to setup_middleware will be applied earlier (in other words its
4670 middleware will wrap closer to the application).  Keep this in mind since in
4671 some cases the order of middleware is important.
4672
4673 The two approaches are not exclusive.
4674
4675 =over 4
4676
4677 =item Middleware Object
4678
4679 An already initialized object that conforms to the L<Plack::Middleware>
4680 specification:
4681
4682     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4683
4684     __PACKAGE__->config(
4685       'psgi_middleware', [
4686         $stacktrace_middleware,
4687       ]);
4688
4689
4690 =item coderef
4691
4692 A coderef that is an inlined middleware:
4693
4694     __PACKAGE__->config(
4695       'psgi_middleware', [
4696         sub {
4697           my $app = shift;
4698           return sub {
4699             my $env = shift;
4700             if($env->{PATH_INFO} =~m/forced/) {
4701               Plack::App::File
4702                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
4703                 ->call($env);
4704             } else {
4705               return $app->($env);
4706             }
4707          },
4708       },
4709     ]);
4710
4711
4712
4713 =item a scalar
4714
4715 We assume the scalar refers to a namespace after normalizing it using the
4716 following rules:
4717
4718 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
4719 is assumed to be 'as is', and we just install and use the middleware.
4720
4721 (2) If the scalar begins with "Plack::Middleware" or your application namespace
4722 (the package name of your Catalyst application subclass), we also assume then
4723 that it is a full namespace, and use it.
4724
4725 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
4726 resolve it first by looking for it under your application namespace (for example
4727 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
4728 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
4729 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
4730 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
4731 namespace first to let you 'override' common L<Plack::Middleware> locally, should
4732 you find that a good idea.
4733
4734 Examples:
4735
4736     package MyApp::Web;
4737
4738     __PACKAGE__->config(
4739       'psgi_middleware', [
4740         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
4741         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
4742         '+MyApp::Custom',  ## MyApp::Custom->wrap
4743       ],
4744     );
4745
4746 =item a scalar followed by a hashref
4747
4748 Just like the previous, except the following C<HashRef> is used as arguments
4749 to initialize the middleware object.
4750
4751     __PACKAGE__->config(
4752       'psgi_middleware', [
4753          'Session' => {store => 'File'},
4754     ]);
4755
4756 =back
4757
4758 Please see L<PSGI> for more on middleware.
4759
4760 =head1 ENCODING
4761
4762 Starting in L<Catalyst> version 5.90080 encoding is automatically enabled
4763 and set to encode all body responses to UTF8 when possible and applicable.
4764 Following is documentation on this process.  If you are using an older
4765 version of L<Catalyst> you should review documentation for that version since
4766 a lot has changed.
4767
4768 By default encoding is now 'UTF-8'.  You may turn it off by setting
4769 the encoding configuration to undef.
4770
4771     MyApp->config(encoding => undef);
4772
4773 This is recommended for temporary backwards compatibility only.
4774
4775 Encoding is automatically applied when the content-type is set to
4776 a type that can be encoded.  Currently we encode when the content type
4777 matches the following regular expression:
4778
4779     $content_type =~ /^text|xml$|javascript$/
4780
4781 Encoding is set on the application, but it is copied to the context object
4782 so that you can override it on a request basis.
4783
4784 Be default we don't automatically encode 'application/json' since the most
4785 common approaches to generating this type of response (Either via L<Catalyst::View::JSON>
4786 or L<Catalyst::Action::REST>) will do so already and we want to avoid double
4787 encoding issues.
4788
4789 If you are producing JSON response in an unconventional manner (such
4790 as via a template or manual strings) you should perform the UTF8 encoding
4791 manually as well such as to conform to the JSON specification.
4792
4793 NOTE: We also examine the value of $c->response->content_encoding.  If
4794 you set this (like for example 'gzip', and manually gzipping the body)
4795 we assume that you have done all the necessary encoding yourself, since
4796 we cannot encode the gzipped contents.  If you use a plugin like
4797 L<Catalyst::Plugin::Compress> you need to update to a modern version in order
4798 to have this function correctly  with the new UTF8 encoding code, or you
4799 can use L<Plack::Middleware::Deflater> or (probably best) do your compression on
4800 a front end proxy.
4801
4802 =head2 Methods
4803
4804 =over 4
4805
4806 =item encoding
4807
4808 Returns an instance of an C<Encode> encoding
4809
4810     print $c->encoding->name
4811
4812 =item handle_unicode_encoding_exception ($exception_context)
4813
4814 Method called when decoding process for a request fails.
4815
4816 An C<$exception_context> hashref is provided to allow you to override the
4817 behaviour of your application when given data with incorrect encodings.
4818
4819 The default method throws exceptions in the case of invalid request parameters
4820 (resulting in a 500 error), but ignores errors in upload filenames.
4821
4822 The keys passed in the C<$exception_context> hash are:
4823
4824 =over
4825
4826 =item param_value
4827
4828 The value which was not able to be decoded.
4829
4830 =item error_msg
4831
4832 The exception received from L<Encode>.
4833
4834 =item encoding_step
4835
4836 What type of data was being decoded. Valid values are (currently)
4837 C<params> - for request parameters / arguments / captures
4838 and C<uploads> - for request upload filenames.
4839
4840 =back
4841
4842 =back
4843
4844 =head1 SUPPORT
4845
4846 IRC:
4847
4848     Join #catalyst on irc.perl.org.
4849
4850 Mailing Lists:
4851
4852     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4853     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4854
4855 Web:
4856
4857     http://catalyst.perl.org
4858
4859 Wiki:
4860
4861     http://dev.catalyst.perl.org
4862
4863 =head1 SEE ALSO
4864
4865 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4866
4867 =head2 L<Catalyst::Manual> - The Catalyst Manual
4868
4869 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4870
4871 =head2 L<Catalyst::Engine> - Core engine
4872
4873 =head2 L<Catalyst::Log> - Log class.
4874
4875 =head2 L<Catalyst::Request> - Request object
4876
4877 =head2 L<Catalyst::Response> - Response object
4878
4879 =head2 L<Catalyst::Test> - The test suite.
4880
4881 =head1 PROJECT FOUNDER
4882
4883 sri: Sebastian Riedel <sri@cpan.org>
4884
4885 =head1 CONTRIBUTORS
4886
4887 abw: Andy Wardley
4888
4889 acme: Leon Brocard <leon@astray.com>
4890
4891 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4892
4893 andrewalker: André Walker <andre@cpan.org>
4894
4895 Andrew Bramble
4896
4897 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4898
4899 Andrew Ruthven
4900
4901 andyg: Andy Grundman <andy@hybridized.org>
4902
4903 audreyt: Audrey Tang
4904
4905 bricas: Brian Cassidy <bricas@cpan.org>
4906
4907 Caelum: Rafael Kitover <rkitover@io.com>
4908
4909 chansen: Christian Hansen
4910
4911 Chase Venters C<chase.venters@gmail.com>
4912
4913 chicks: Christopher Hicks
4914
4915 Chisel Wright C<pause@herlpacker.co.uk>
4916
4917 Danijel Milicevic C<me@danijel.de>
4918
4919 davewood: David Schmidt <davewood@cpan.org>
4920
4921 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4922
4923 David Naughton, C<naughton@umn.edu>
4924
4925 David E. Wheeler
4926
4927 dhoss: Devin Austin <dhoss@cpan.org>
4928
4929 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4930
4931 Drew Taylor
4932
4933 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4934
4935 esskar: Sascha Kiefer
4936
4937 fireartist: Carl Franks <cfranks@cpan.org>
4938
4939 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4940
4941 gabb: Danijel Milicevic
4942
4943 Gary Ashton Jones
4944
4945 Gavin Henry C<ghenry@perl.me.uk>
4946
4947 Geoff Richards
4948
4949 groditi: Guillermo Roditi <groditi@gmail.com>
4950
4951 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4952
4953 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4954
4955 jcamacho: Juan Camacho
4956
4957 jester: Jesse Sheidlower C<jester@panix.com>
4958
4959 jhannah: Jay Hannah <jay@jays.net>
4960
4961 Jody Belka
4962
4963 Johan Lindstrom
4964
4965 jon: Jon Schutz <jjschutz@cpan.org>
4966
4967 Jonathan Rockway C<< <jrockway@cpan.org> >>
4968
4969 Kieren Diment C<kd@totaldatasolution.com>
4970
4971 konobi: Scott McWhirter <konobi@cpan.org>
4972
4973 marcus: Marcus Ramberg <mramberg@cpan.org>
4974
4975 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4976
4977 mgrimes: Mark Grimes <mgrimes@cpan.org>
4978
4979 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4980
4981 mugwump: Sam Vilain
4982
4983 naughton: David Naughton
4984
4985 ningu: David Kamholz <dkamholz@cpan.org>
4986
4987 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4988
4989 numa: Dan Sully <daniel@cpan.org>
4990
4991 obra: Jesse Vincent
4992
4993 Octavian Rasnita
4994
4995 omega: Andreas Marienborg
4996
4997 Oleg Kostyuk <cub.uanic@gmail.com>
4998
4999 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
5000
5001 rafl: Florian Ragwitz <rafl@debian.org>
5002
5003 random: Roland Lammel <lammel@cpan.org>
5004
5005 Robert Sedlacek C<< <rs@474.at> >>
5006
5007 SpiceMan: Marcel Montes
5008
5009 sky: Arthur Bergman
5010
5011 szbalint: Balint Szilakszi <szbalint@cpan.org>
5012
5013 t0m: Tomas Doran <bobtfish@bobtfish.net>
5014
5015 Ulf Edvinsson
5016
5017 vanstyn: Henry Van Styn <vanstyn@cpan.org>
5018
5019 Viljo Marrandi C<vilts@yahoo.com>
5020
5021 Will Hawes C<info@whawes.co.uk>
5022
5023 willert: Sebastian Willert <willert@cpan.org>
5024
5025 wreis: Wallace Reis <wreis@cpan.org>
5026
5027 Yuval Kogman, C<nothingmuch@woobling.org>
5028
5029 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
5030
5031 dd070: Dhaval Dhanani <dhaval070@gmail.com>
5032
5033 Upasana <me@upasana.me>
5034
5035 John Napiorkowski (jnap) <jjnapiork@cpan.org>
5036
5037 =head1 COPYRIGHT
5038
5039 Copyright (c) 2005-2015, the above named PROJECT FOUNDER and CONTRIBUTORS.
5040
5041 =head1 LICENSE
5042
5043 This library is free software. You can redistribute it and/or modify it under
5044 the same terms as Perl itself.
5045
5046 =cut
5047
5048 no Moose;
5049
5050 __PACKAGE__->meta->make_immutable;
5051
5052 1;