lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/container components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80032';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub _application { $_[0] }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 This sets the log level to 'debug' and enables full debug output on the
 252 error screen. If you only want the latter, see L<< $c->debug >>.
 253
 254 =head2 -Engine
 255
 256 Forces Catalyst to use a specific engine. Omit the
 257 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 258
 259     use Catalyst qw/-Engine=CGI/;
 260
 261 =head2 -Home
 262
 263 Forces Catalyst to use a specific home directory, e.g.:
 264
 265     use Catalyst qw[-Home=/usr/mst];
 266
 267 This can also be done in the shell environment by setting either the
 268 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 269 is replaced with the uppercased name of your application, any "::" in
 270 the name will be replaced with underscores, e.g. MyApp::Web should use
 271 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 272
 273 If none of these are set, Catalyst will attempt to automatically detect the
 274 home directory. If you are working in a development envirnoment, Catalyst
 275 will try and find the directory containing either Makefile.PL, Build.PL or
 276 dist.ini. If the application has been installed into the system (i.e.
 277 you have done C<make install>), then Catalyst will use the path to your
 278 application module, without the .pm extension (ie, /foo/MyApp if your
 279 application was installed at /foo/MyApp.pm)
 280
 281 =head2 -Log
 282
 283     use Catalyst '-Log=warn,fatal,error';
 284
 285 Specifies a comma-delimited list of log levels.
 286
 287 =head2 -Stats
 288
 289 Enables statistics collection and reporting.
 290
 291    use Catalyst qw/-Stats=1/;
 292
 293 You can also force this setting from the system environment with CATALYST_STATS
 294 or <MYAPP>_STATS. The environment settings override the application, with
 295 <MYAPP>_STATS having the highest priority.
 296
 297 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 298
 299 =head1 METHODS
 300
 301 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 302
 303 =head2 $c->action
 304
 305 Returns a L<Catalyst::Action> object for the current action, which
 306 stringifies to the action name. See L<Catalyst::Action>.
 307
 308 =head2 $c->namespace
 309
 310 Returns the namespace of the current action, i.e., the URI prefix
 311 corresponding to the controller of the current action. For example:
 312
 313     # in Controller::Foo::Bar
 314     $c->namespace; # returns 'foo/bar';
 315
 316 =head2 $c->request
 317
 318 =head2 $c->req
 319
 320 Returns the current L<Catalyst::Request> object, giving access to
 321 information about the current client request (including parameters,
 322 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 323
 324 =head2 REQUEST FLOW HANDLING
 325
 326 =head2 $c->forward( $action [, \@arguments ] )
 327
 328 =head2 $c->forward( $class, $method, [, \@arguments ] )
 329
 330 Forwards processing to another action, by its private name. If you give a
 331 class name but no method, C<process()> is called. You may also optionally
 332 pass arguments in an arrayref. The action will receive the arguments in
 333 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 334 C<< $c->req->args >> will be restored to the previous values.
 335
 336 Any data C<return>ed from the action forwarded to, will be returned by the
 337 call to forward.
 338
 339     my $foodata = $c->forward('/foo');
 340     $c->forward('index');
 341     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 342     $c->forward('View::TT');
 343
 344 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 345 an C<< eval { } >> around the call (actually
 346 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 347 all 'dies' within the called action. If you want C<die> to propagate you
 348 need to do something like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 374
 375 =cut
 376
 377 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 378
 379 =head2 $c->detach( $action [, \@arguments ] )
 380
 381 =head2 $c->detach( $class, $method, [, \@arguments ] )
 382
 383 =head2 $c->detach()
 384
 385 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 386 doesn't return to the previous action when processing is finished.
 387
 388 When called with no arguments it escapes the processing chain entirely.
 389
 390 =cut
 391
 392 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 393
 394 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 397
 398 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 399 but does a full dispatch, instead of just calling the new C<$action> /
 400 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 401 you go to are called, just like a new request.
 402
 403 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 404 This means, for example, that C<< $c->action >> methods such as
 405 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 406 L<reverse|Catalyst::Action/reverse> return information for the visited action
 407 when they are invoked within the visited action.  This is different from the
 408 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 409 continues to use the $c->action object from the caller action even when
 410 invoked from the callee.
 411
 412 C<< $c->stash >> is kept unchanged.
 413
 414 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 415 allows you to "wrap" another action, just as it would have been called by
 416 dispatching from a URL, while the analogous
 417 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 418 transfer control to another action as if it had been reached directly from a URL.
 419
 420 =cut
 421
 422 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 423
 424 =head2 $c->go( $action [, \@captures, \@arguments ] )
 425
 426 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 427
 428 The relationship between C<go> and
 429 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 430 the relationship between
 431 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 432 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 433 C<< $c->go >> will perform a full dispatch on the specified action or method,
 434 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 435 C<go> escapes the processing of the current request chain on completion, and
 436 does not return to its caller.
 437
 438 @arguments are arguments to the final destination of $action. @captures are
 439 arguments to the intermediate steps, if any, on the way to the final sub of
 440 $action.
 441
 442 =cut
 443
 444 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 445
 446 =head2 $c->response
 447
 448 =head2 $c->res
 449
 450 Returns the current L<Catalyst::Response> object, see there for details.
 451
 452 =head2 $c->stash
 453
 454 Returns a hashref to the stash, which may be used to store data and pass
 455 it between components during a request. You can also set hash keys by
 456 passing arguments. The stash is automatically sent to the view. The
 457 stash is cleared at the end of a request; it cannot be used for
 458 persistent storage (for this you must use a session; see
 459 L<Catalyst::Plugin::Session> for a complete system integrated with
 460 Catalyst).
 461
 462     $c->stash->{foo} = $bar;
 463     $c->stash( { moose => 'majestic', qux => 0 } );
 464     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 465
 466     # stash is automatically passed to the view for use in a template
 467     $c->forward( 'MyApp::View::TT' );
 468
 469 =cut
 470
 471 around stash => sub {
 472     my $orig = shift;
 473     my $c = shift;
 474     my $stash = $orig->($c);
 475     if (@_) {
 476         my $new_stash = @_ > 1 ? {@_} : $_[0];
 477         croak('stash takes a hash or hashref') unless ref $new_stash;
 478         foreach my $key ( keys %$new_stash ) {
 479           $stash->{$key} = $new_stash->{$key};
 480         }
 481     }
 482
 483     return $stash;
 484 };
 485
 486
 487 =head2 $c->error
 488
 489 =head2 $c->error($error, ...)
 490
 491 =head2 $c->error($arrayref)
 492
 493 Returns an arrayref containing error messages.  If Catalyst encounters an
 494 error while processing a request, it stores the error in $c->error.  This
 495 method should only be used to store fatal error messages.
 496
 497     my @error = @{ $c->error };
 498
 499 Add a new error.
 500
 501     $c->error('Something bad happened');
 502
 503 =cut
 504
 505 sub error {
 506     my $c = shift;
 507     if ( $_[0] ) {
 508         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 509         croak @$error unless ref $c;
 510         push @{ $c->{error} }, @$error;
 511     }
 512     elsif ( defined $_[0] ) { $c->{error} = undef }
 513     return $c->{error} || [];
 514 }
 515
 516
 517 =head2 $c->state
 518
 519 Contains the return value of the last executed action.
 520 Note that << $c->state >> operates in a scalar context which means that all
 521 values it returns are scalar.
 522
 523 =head2 $c->clear_errors
 524
 525 Clear errors.  You probably don't want to clear the errors unless you are
 526 implementing a custom error screen.
 527
 528 This is equivalent to running
 529
 530     $c->error(0);
 531
 532 =cut
 533
 534 sub clear_errors {
 535     my $c = shift;
 536     $c->error(0);
 537 }
 538
 539 =head2 COMPONENT ACCESSORS
 540
 541 =head2 $c->controller($name)
 542
 543 Gets a L<Catalyst::Controller> instance by name.
 544
 545     $c->controller('Foo')->do_stuff;
 546
 547 If the name is omitted, will return the controller for the dispatched
 548 action.
 549
 550 If you want to search for controllers, pass in a regexp as the argument.
 551
 552     # find all controllers that start with Foo
 553     my @foo_controllers = $c->controller(qr{^Foo});
 554
 555
 556 =cut
 557
 558 sub controller {
 559     my ( $c, $name, @args ) = @_;
 560     my $container = $c->container->get_sub_container('controller');
 561     unshift @args, $c;
 562
 563     if( $name ) {
 564         # Direct component hash lookup to avoid costly regexps
 565         return $container->get_component($name, \@args)
 566             if $container->has_service($name) && !ref $name;
 567
 568         return $container->get_component_regexp( $c, $name, \@args );
 569     }
 570
 571     return $c->component( $c->action->class );
 572 }
 573
 574 =head2 $c->model($name)
 575
 576 Gets a L<Catalyst::Model> instance by name.
 577
 578     $c->model('Foo')->do_stuff;
 579
 580 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 581
 582 If the name is omitted, it will look for
 583  - a model object in $c->stash->{current_model_instance}, then
 584  - a model name in $c->stash->{current_model}, then
 585  - a config setting 'default_model', or
 586  - check if there is only one model, and return it if that's the case.
 587
 588 If you want to search for models, pass in a regexp as the argument.
 589
 590     # find all models that start with Foo
 591     my @foo_models = $c->model(qr{^Foo});
 592
 593 =cut
 594
 595 sub model {
 596     my ( $c, $name, @args ) = @_;
 597     my $appclass = ref($c) || $c;
 598     my $container = $c->container->get_sub_container('model');
 599     unshift @args, $c;
 600
 601     if( $name ) {
 602         # Direct component hash lookup to avoid costly regexps
 603         return $container->get_component($name, \@args)
 604             if $container->has_service($name) && !ref $name;
 605
 606         return $container->get_component_regexp( $c, $name, \@args );
 607     }
 608
 609     if (ref $c) {
 610         return $c->stash->{current_model_instance}
 611           if $c->stash->{current_model_instance};
 612         return $c->model( $c->stash->{current_model} )
 613           if $c->stash->{current_model};
 614     }
 615     return $c->model( $appclass->config->{default_model} )
 616       if $appclass->config->{default_model};
 617
 618 # FIXME: will this still be mantained?
 619     my( $comp, $rest ) = $container->get_service_list;
 620
 621     if( $rest ) {
 622         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 623         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 624         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 625         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 626         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 627     }
 628
 629     return $container->get_component( $comp, \@args );
 630 }
 631
 632
 633 =head2 $c->view($name)
 634
 635 Gets a L<Catalyst::View> instance by name.
 636
 637     $c->view('Foo')->do_stuff;
 638
 639 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 640
 641 If the name is omitted, it will look for
 642  - a view object in $c->stash->{current_view_instance}, then
 643  - a view name in $c->stash->{current_view}, then
 644  - a config setting 'default_view', or
 645  - check if there is only one view, and return it if that's the case.
 646
 647 If you want to search for views, pass in a regexp as the argument.
 648
 649     # find all views that start with Foo
 650     my @foo_views = $c->view(qr{^Foo});
 651
 652 =cut
 653
 654 sub view {
 655     my ( $c, $name, @args ) = @_;
 656     my $appclass = ref($c) || $c;
 657     my $container = $c->container->get_sub_container('view');
 658     unshift @args, $c;
 659
 660     if( $name ) {
 661         # Direct component hash lookup to avoid costly regexps
 662         return $container->get_component($name, \@args)
 663             if !ref $name && $container->has_service($name);
 664
 665         $c->log->warn( "Attempted to use view '$name', but does not exist" );
 666
 667         return $container->get_component_regexp( $c, $name, \@args );
 668     }
 669
 670     if (ref $c) {
 671         return $c->stash->{current_view_instance}
 672           if $c->stash->{current_view_instance};
 673         return $c->view( $c->stash->{current_view} )
 674           if $c->stash->{current_view};
 675     }
 676     return $c->view( $appclass->config->{default_view} )
 677       if $appclass->config->{default_view};
 678
 679     my( $comp, $rest ) = $container->get_service_list;
 680
 681     if( $rest ) {
 682         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 683         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 684         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 685         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 686         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 687     }
 688
 689     return $container->get_component( $comp, \@args );
 690 }
 691
 692 =head2 $c->controllers
 693
 694 Returns the available names which can be passed to $c->controller
 695
 696 =cut
 697
 698 sub controllers {
 699     my ( $c ) = @_;
 700     return $c->container->get_sub_container('controller')->get_service_list;
 701 }
 702
 703 =head2 $c->models
 704
 705 Returns the available names which can be passed to $c->model
 706
 707 =cut
 708
 709 sub models {
 710     my ( $c ) = @_;
 711     return $c->container->get_sub_container('model')->get_service_list;
 712 }
 713
 714
 715 =head2 $c->views
 716
 717 Returns the available names which can be passed to $c->view
 718
 719 =cut
 720
 721 sub views {
 722     my ( $c ) = @_;
 723     return $c->container->get_sub_container('view')->get_service_list;
 724 }
 725
 726 =head2 $c->comp($name)
 727
 728 =head2 $c->component($name)
 729
 730 Gets a component object by name. This method is not recommended,
 731 unless you want to get a specific component by full
 732 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 733 should be used instead.
 734
 735 If C<$name> is a regexp, a list of components matched against the full
 736 component name will be returned.
 737
 738 If Catalyst can't find a component by name, it will fallback to regex
 739 matching by default. To disable this behaviour set
 740 disable_component_resolution_regex_fallback to a true value.
 741
 742     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 743
 744 =cut
 745
 746 sub component {
 747     my ( $c, $component, @args ) = @_;
 748     unshift @args, $c;
 749
 750     if ( $component ) {
 751         my ($type, $name) = _get_component_type_name($component);
 752
 753         if ($type && $c->container->has_sub_container($type)) {
 754             my $container = $c->container->get_sub_container($type);
 755
 756             if( !ref $component && $container->has_service($name) ) {
 757                 return $container->get_component( $name, \@args );
 758             }
 759
 760             return $container->get_component_regexp( $c, $name, \@args );
 761         }
 762
 763         return
 764             if $c->config->{disable_component_resolution_regex_fallback} && !ref $component;
 765
 766         # This is here so $c->comp( '::M::' ) works
 767         my $query = ref $component ? $component : qr{$component}i;
 768
 769         for my $subcontainer_name (qw/model view controller/) {
 770             my $subcontainer = $c->container->get_sub_container($subcontainer_name);
 771             my @components   = $subcontainer->get_service_list;
 772             my @result       = grep { m{$query} } @components;
 773
 774             if (@result) {
 775                 return map { $subcontainer->get_component( $_, \@args ) } @result
 776                     if ref $component;
 777
 778                 $c->log->warn( Carp::shortmess(qq(Found results for "${component}" using regexp fallback)) );
 779                 $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 780                 $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 781
 782                 return $subcontainer->get_component( $result[0], \@args );
 783             }
 784         }
 785
 786         # I would expect to return an empty list here, but that breaks back-compat
 787     }
 788
 789     # fallback
 790     return sort keys %{ $c->components };
 791 }
 792
 793 =head2 CLASS DATA AND HELPER CLASSES
 794
 795 =head2 $c->config
 796
 797 Returns or takes a hashref containing the application's configuration.
 798
 799     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 800
 801 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 802 like C<myapp.conf> in your applications home directory. See
 803 L<Catalyst::Plugin::ConfigLoader>.
 804
 805 =head3 Cascading configuration
 806
 807 The config method is present on all Catalyst components, and configuration
 808 will be merged when an application is started. Configuration loaded with
 809 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 810 followed by configuration in your top level C<MyApp> class. These two
 811 configurations are merged, and then configuration data whose hash key matches a
 812 component name is merged with configuration for that component.
 813
 814 The configuration for a component is then passed to the C<new> method when a
 815 component is constructed.
 816
 817 For example:
 818
 819     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 820     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 821
 822 will mean that C<MyApp::Model::Foo> receives the following data when
 823 constructed:
 824
 825     MyApp::Model::Foo->new({
 826         bar => 'baz',
 827         quux => 'frob',
 828         overrides => 'me',
 829     });
 830
 831 It's common practice to use a Moose attribute
 832 on the receiving component to access the config value.
 833
 834     package MyApp::Model::Foo;
 835
 836     use Moose;
 837
 838     # this attr will receive 'baz' at construction time
 839     has 'bar' => (
 840         is  => 'rw',
 841         isa => 'Str',
 842     );
 843
 844 You can then get the value 'baz' by calling $c->model('Foo')->bar
 845 (or $self->bar inside code in the model).
 846
 847 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 848 as a way of reading config within your code, as this B<will not> give you the
 849 correctly merged config back. You B<MUST> take the config values supplied to
 850 the constructor and use those instead.
 851
 852 =cut
 853
 854 around config => sub {
 855     my $orig = shift;
 856     my $c = shift;
 857
 858     croak('Setting config after setup has been run is not allowed.')
 859         if ( @_ and $c->setup_finished );
 860
 861     $c->$orig(@_);
 862 };
 863
 864 =head2 $c->log
 865
 866 Returns the logging object instance. Unless it is already set, Catalyst
 867 sets this up with a L<Catalyst::Log> object. To use your own log class,
 868 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 869 C<< __PACKAGE__->setup >>.
 870
 871  __PACKAGE__->log( MyLogger->new );
 872  __PACKAGE__->setup;
 873
 874 And later:
 875
 876     $c->log->info( 'Now logging with my own logger!' );
 877
 878 Your log class should implement the methods described in
 879 L<Catalyst::Log>.
 880
 881
 882 =head2 $c->debug
 883
 884 Returns 1 if debug mode is enabled, 0 otherwise.
 885
 886 You can enable debug mode in several ways:
 887
 888 =over
 889
 890 =item By calling myapp_server.pl with the -d flag
 891
 892 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 893
 894 =item The -Debug option in your MyApp.pm
 895
 896 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 897
 898 =back
 899
 900 The first three also set the log level to 'debug'.
 901
 902 Calling C<< $c->debug(1) >> has no effect.
 903
 904 =cut
 905
 906 sub debug { 0 }
 907
 908 =head2 $c->dispatcher
 909
 910 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 911
 912 =head2 $c->engine
 913
 914 Returns the engine instance. See L<Catalyst::Engine>.
 915
 916
 917 =head2 UTILITY METHODS
 918
 919 =head2 $c->path_to(@path)
 920
 921 Merges C<@path> with C<< $c->config->{home} >> and returns a
 922 L<Path::Class::Dir> object. Note you can usually use this object as
 923 a filename, but sometimes you will have to explicitly stringify it
 924 yourself by calling the C<< ->stringify >> method.
 925
 926 For example:
 927
 928     $c->path_to( 'db', 'sqlite.db' );
 929
 930 =cut
 931
 932 sub path_to {
 933     my ( $c, @path ) = @_;
 934     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 935     if ( -d $path ) { return $path }
 936     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 937 }
 938
 939 =head2 $c->plugin( $name, $class, @args )
 940
 941 Helper method for plugins. It creates a class data accessor/mutator and
 942 loads and instantiates the given class.
 943
 944     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 945
 946     $c->prototype->define_javascript_functions;
 947
 948 B<Note:> This method of adding plugins is deprecated. The ability
 949 to add plugins like this B<will be removed> in a Catalyst 5.81.
 950 Please do not use this functionality in new code.
 951
 952 =cut
 953
 954 sub plugin {
 955     my ( $class, $name, $plugin, @args ) = @_;
 956
 957     # See block comment in t/unit_core_plugin.t
 958     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 959
 960     $class->_register_plugin( $plugin, 1 );
 961
 962     eval { $plugin->import };
 963     $class->mk_classdata($name);
 964     my $obj;
 965     eval { $obj = $plugin->new(@args) };
 966
 967     if ($@) {
 968         Catalyst::Exception->throw( message =>
 969               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 970     }
 971
 972     $class->$name($obj);
 973     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 974       if $class->debug;
 975 }
 976
 977 =head2 MyApp->setup
 978
 979 Initializes the dispatcher and engine, loads any plugins, and loads the
 980 model, view, and controller components. You may also specify an array
 981 of plugins to load here, if you choose to not load them in the C<use
 982 Catalyst> line.
 983
 984     MyApp->setup;
 985     MyApp->setup( qw/-Debug/ );
 986
 987 =cut
 988
 989 sub setup {
 990     my ( $class, @arguments ) = @_;
 991     croak('Running setup more than once')
 992         if ( $class->setup_finished );
 993
 994     unless ( $class->isa('Catalyst') ) {
 995
 996         Catalyst::Exception->throw(
 997             message => qq/'$class' does not inherit from Catalyst/ );
 998     }
 999
1000     if ( $class->arguments ) {
1001         @arguments = ( @arguments, @{ $class->arguments } );
1002     }
1003
1004     # Process options
1005     my $flags = {};
1006
1007     foreach (@arguments) {
1008
1009         if (/^-Debug$/) {
1010             $flags->{log} =
1011               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1012         }
1013         elsif (/^-(\w+)=?(.*)$/) {
1014             $flags->{ lc $1 } = $2;
1015         }
1016         else {
1017             push @{ $flags->{plugins} }, $_;
1018         }
1019     }
1020
1021     $class->setup_config();
1022     $class->setup_home( delete $flags->{home} );
1023
1024     $class->setup_log( delete $flags->{log} );
1025     $class->setup_plugins( delete $flags->{plugins} );
1026     $class->setup_dispatcher( delete $flags->{dispatcher} );
1027     $class->setup_engine( delete $flags->{engine} );
1028     $class->setup_stats( delete $flags->{stats} );
1029
1030     for my $flag ( sort keys %{$flags} ) {
1031
1032         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1033             &$code( $class, delete $flags->{$flag} );
1034         }
1035         else {
1036             $class->log->warn(qq/Unknown flag "$flag"/);
1037         }
1038     }
1039
1040     eval { require Catalyst::Devel; };
1041     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1042         $class->log->warn(<<"EOF");
1043 You are running an old script!
1044
1045   Please update by running (this will overwrite existing files):
1046     catalyst.pl -force -scripts $class
1047
1048   or (this will not overwrite existing files):
1049     catalyst.pl -scripts $class
1050
1051 EOF
1052     }
1053
1054     if ( $class->debug ) {
1055         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1056
1057         if (@plugins) {
1058             my $column_width = Catalyst::Utils::term_width() - 6;
1059             my $t = Text::SimpleTable->new($column_width);
1060             $t->row($_) for @plugins;
1061             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1062         }
1063
1064         my $dispatcher = $class->dispatcher;
1065         my $engine     = $class->engine;
1066         my $home       = $class->config->{home};
1067
1068         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1069         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1070
1071         $home
1072           ? ( -d $home )
1073           ? $class->log->debug(qq/Found home "$home"/)
1074           : $class->log->debug(qq/Home "$home" doesn't exist/)
1075           : $class->log->debug(q/Couldn't find home/);
1076     }
1077
1078     # Call plugins setup, this is stupid and evil.
1079     # Also screws C3 badly on 5.10, hack to avoid.
1080     {
1081         no warnings qw/redefine/;
1082         local *setup = sub { };
1083         $class->setup unless $Catalyst::__AM_RESTARTING;
1084     }
1085
1086     # Initialize our data structure
1087     $class->components( {} );
1088
1089     $class->setup_components;
1090
1091     if ( $class->debug ) {
1092         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1093         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1094         for my $comp ( sort keys %{ $class->components } ) {
1095             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1096             $t->row( $comp, $type );
1097         }
1098         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1099           if ( keys %{ $class->components } );
1100     }
1101
1102     # Add our self to components, since we are also a component
1103     if( $class->isa('Catalyst::Controller') ){
1104       $class->components->{$class} = $class;
1105     }
1106
1107     $class->setup_actions;
1108
1109     if ( $class->debug ) {
1110         my $name = $class->config->{name} || 'Application';
1111         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1112     }
1113
1114     # Make sure that the application class becomes immutable at this point,
1115     B::Hooks::EndOfScope::on_scope_end {
1116         return if $@;
1117         my $meta = Class::MOP::get_metaclass_by_name($class);
1118         if (
1119             $meta->is_immutable
1120             && ! { $meta->immutable_options }->{replace_constructor}
1121             && (
1122                    $class->isa('Class::Accessor::Fast')
1123                 || $class->isa('Class::Accessor')
1124             )
1125         ) {
1126             warn "You made your application class ($class) immutable, "
1127                 . "but did not inline the\nconstructor. "
1128                 . "This will break catalyst, as your app \@ISA "
1129                 . "Class::Accessor(::Fast)?\nPlease pass "
1130                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1131         }
1132         $meta->make_immutable(
1133             replace_constructor => 1,
1134         ) unless $meta->is_immutable;
1135     };
1136
1137     if ($class->config->{case_sensitive}) {
1138         $class->log->warn($class . "->config->{case_sensitive} is set.");
1139         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1140     }
1141
1142     $class->setup_finalize;
1143     # Should be the last thing we do so that user things hooking
1144     # setup_finalize can log..
1145     $class->log->_flush() if $class->log->can('_flush');
1146     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1147 }
1148
1149 =head2 $app->setup_finalize
1150
1151 A hook to attach modifiers to. This method does not do anything except set the
1152 C<setup_finished> accessor.
1153
1154 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1155
1156 Example:
1157
1158     after setup_finalize => sub {
1159         my $app = shift;
1160
1161         ## do stuff here..
1162     };
1163
1164 =cut
1165
1166 sub setup_finalize {
1167     my ($class) = @_;
1168     $class->setup_finished(1);
1169 }
1170
1171 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1172
1173 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1174
1175 Constructs an absolute L<URI> object based on the application root, the
1176 provided path, and the additional arguments and query parameters provided.
1177 When used as a string, provides a textual URI.  If you need more flexibility
1178 than this (i.e. the option to provide relative URIs etc.) see
1179 L<Catalyst::Plugin::SmartURI>.
1180
1181 If no arguments are provided, the URI for the current action is returned.
1182 To return the current action and also provide @args, use
1183 C<< $c->uri_for( $c->action, @args ) >>.
1184
1185 If the first argument is a string, it is taken as a public URI path relative
1186 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1187 relative to the application root (if it does). It is then merged with
1188 C<< $c->request->base >>; any C<@args> are appended as additional path
1189 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1190
1191 If the first argument is a L<Catalyst::Action> it represents an action which
1192 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1193 optional C<\@captures> argument (an arrayref) allows passing the captured
1194 variables that are needed to fill in the paths of Chained and Regex actions;
1195 once the path is resolved, C<uri_for> continues as though a path was
1196 provided, appending any arguments or parameters and creating an absolute
1197 URI.
1198
1199 The captures for the current request can be found in
1200 C<< $c->request->captures >>, and actions can be resolved using
1201 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1202 path, use C<< $c->uri_for_action >> instead.
1203
1204   # Equivalent to $c->req->uri
1205   $c->uri_for($c->action, $c->req->captures,
1206       @{ $c->req->args }, $c->req->params);
1207
1208   # For the Foo action in the Bar controller
1209   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1210
1211   # Path to a static resource
1212   $c->uri_for('/static/images/logo.png');
1213
1214 =cut
1215
1216 sub uri_for {
1217     my ( $c, $path, @args ) = @_;
1218
1219     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1220         $path = $path->path_prefix;
1221         $path =~ s{/+\z}{};
1222         $path .= '/';
1223     }
1224
1225     undef($path) if (defined $path && $path eq '');
1226
1227     my $params =
1228       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1229
1230     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1231     foreach my $arg (@args) {
1232         utf8::encode($arg) if utf8::is_utf8($arg);
1233         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1234     }
1235
1236     if ( blessed($path) ) { # action object
1237         s|/|%2F|g for @args;
1238         my $captures = [ map { s|/|%2F|g; $_; }
1239                         ( scalar @args && ref $args[0] eq 'ARRAY'
1240                          ? @{ shift(@args) }
1241                          : ()) ];
1242
1243         foreach my $capture (@$captures) {
1244             utf8::encode($capture) if utf8::is_utf8($capture);
1245             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1246         }
1247
1248         my $action = $path;
1249         $path = $c->dispatcher->uri_for_action($action, $captures);
1250         if (not defined $path) {
1251             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1252                 if $c->debug;
1253             return undef;
1254         }
1255         $path = '/' if $path eq '';
1256     }
1257
1258     unshift(@args, $path);
1259
1260     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1261         my $namespace = $c->namespace;
1262         if (defined $path) { # cheesy hack to handle path '../foo'
1263            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1264         }
1265         unshift(@args, $namespace || '');
1266     }
1267
1268     # join args with '/', or a blank string
1269     my $args = join('/', grep { defined($_) } @args);
1270     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1271     $args =~ s!^/+!!;
1272     my $base = $c->req->base;
1273     my $class = ref($base);
1274     $base =~ s{(?<!/)$}{/};
1275
1276     my $query = '';
1277
1278     if (my @keys = keys %$params) {
1279       # somewhat lifted from URI::_query's query_form
1280       $query = '?'.join('&', map {
1281           my $val = $params->{$_};
1282           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1283           s/ /+/g;
1284           my $key = $_;
1285           $val = '' unless defined $val;
1286           (map {
1287               my $param = "$_";
1288               utf8::encode( $param ) if utf8::is_utf8($param);
1289               # using the URI::Escape pattern here so utf8 chars survive
1290               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1291               $param =~ s/ /+/g;
1292               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1293       } @keys);
1294     }
1295
1296     my $res = bless(\"${base}${args}${query}", $class);
1297     $res;
1298 }
1299
1300 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1301
1302 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1303
1304 =over
1305
1306 =item $path
1307
1308 A private path to the Catalyst action you want to create a URI for.
1309
1310 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1311 >> and passing the resulting C<$action> and the remaining arguments to C<<
1312 $c->uri_for >>.
1313
1314 You can also pass in a Catalyst::Action object, in which case it is passed to
1315 C<< $c->uri_for >>.
1316
1317 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1318
1319 For example, if the action looks like:
1320
1321  package MyApp::Controller::Users;
1322
1323  sub lst : Path('the-list') {}
1324
1325 You can use:
1326
1327  $c->uri_for_action('/users/lst')
1328
1329 and it will create the URI /users/the-list.
1330
1331 =back
1332
1333 =cut
1334
1335 sub uri_for_action {
1336     my ( $c, $path, @args ) = @_;
1337     my $action = blessed($path)
1338       ? $path
1339       : $c->dispatcher->get_action_by_path($path);
1340     unless (defined $action) {
1341       croak "Can't find action for path '$path'";
1342     }
1343     return $c->uri_for( $action, @args );
1344 }
1345
1346 =head2 $c->welcome_message
1347
1348 Returns the Catalyst welcome HTML page.
1349
1350 =cut
1351
1352 sub welcome_message {
1353     my $c      = shift;
1354     my $name   = $c->config->{name};
1355     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1356     my $prefix = Catalyst::Utils::appprefix( ref $c );
1357     $c->response->content_type('text/html; charset=utf-8');
1358     return <<"EOF";
1359 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1360     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1361 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1362     <head>
1363     <meta http-equiv="Content-Language" content="en" />
1364     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1365         <title>$name on Catalyst $VERSION</title>
1366         <style type="text/css">
1367             body {
1368                 color: #000;
1369                 background-color: #eee;
1370             }
1371             div#content {
1372                 width: 640px;
1373                 margin-left: auto;
1374                 margin-right: auto;
1375                 margin-top: 10px;
1376                 margin-bottom: 10px;
1377                 text-align: left;
1378                 background-color: #ccc;
1379                 border: 1px solid #aaa;
1380             }
1381             p, h1, h2 {
1382                 margin-left: 20px;
1383                 margin-right: 20px;
1384                 font-family: verdana, tahoma, sans-serif;
1385             }
1386             a {
1387                 font-family: verdana, tahoma, sans-serif;
1388             }
1389             :link, :visited {
1390                     text-decoration: none;
1391                     color: #b00;
1392                     border-bottom: 1px dotted #bbb;
1393             }
1394             :link:hover, :visited:hover {
1395                     color: #555;
1396             }
1397             div#topbar {
1398                 margin: 0px;
1399             }
1400             pre {
1401                 margin: 10px;
1402                 padding: 8px;
1403             }
1404             div#answers {
1405                 padding: 8px;
1406                 margin: 10px;
1407                 background-color: #fff;
1408                 border: 1px solid #aaa;
1409             }
1410             h1 {
1411                 font-size: 0.9em;
1412                 font-weight: normal;
1413                 text-align: center;
1414             }
1415             h2 {
1416                 font-size: 1.0em;
1417             }
1418             p {
1419                 font-size: 0.9em;
1420             }
1421             p img {
1422                 float: right;
1423                 margin-left: 10px;
1424             }
1425             span#appname {
1426                 font-weight: bold;
1427                 font-size: 1.6em;
1428             }
1429         </style>
1430     </head>
1431     <body>
1432         <div id="content">
1433             <div id="topbar">
1434                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1435                     $VERSION</h1>
1436              </div>
1437              <div id="answers">
1438                  <p>
1439                  <img src="$logo" alt="Catalyst Logo" />
1440                  </p>
1441                  <p>Welcome to the  world of Catalyst.
1442                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1443                     framework will make web development something you had
1444                     never expected it to be: Fun, rewarding, and quick.</p>
1445                  <h2>What to do now?</h2>
1446                  <p>That really depends  on what <b>you</b> want to do.
1447                     We do, however, provide you with a few starting points.</p>
1448                  <p>If you want to jump right into web development with Catalyst
1449                     you might want to start with a tutorial.</p>
1450 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1451 </pre>
1452 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1453 <pre>
1454 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1455 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1456 </code></pre>
1457                  <h2>What to do next?</h2>
1458                  <p>Next it's time to write an actual application. Use the
1459                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1460                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1461                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1462                     they can save you a lot of work.</p>
1463                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1464                     <p>Also, be sure to check out the vast and growing
1465                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1466                     you are likely to find what you need there.
1467                     </p>
1468
1469                  <h2>Need help?</h2>
1470                  <p>Catalyst has a very active community. Here are the main places to
1471                     get in touch with us.</p>
1472                  <ul>
1473                      <li>
1474                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1475                      </li>
1476                      <li>
1477                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1478                      </li>
1479                      <li>
1480                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1481                      </li>
1482                  </ul>
1483                  <h2>In conclusion</h2>
1484                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1485                     as we enjoyed making it. Please contact us if you have ideas
1486                     for improvement or other feedback.</p>
1487              </div>
1488          </div>
1489     </body>
1490 </html>
1491 EOF
1492 }
1493
1494 =head1 INTERNAL METHODS
1495
1496 These methods are not meant to be used by end users.
1497
1498 =head2 $c->components
1499
1500 Returns a hash of components.
1501
1502 =cut
1503
1504 around components => sub {
1505     my $orig  = shift;
1506     my $class = shift;
1507     my $comps = shift;
1508
1509     return $class->$orig if ( !$comps );
1510
1511 # FIXME: should this ugly kludge exist?
1512     $class->setup_config unless defined $class->container;
1513
1514 # FIXME: should there be a warning here, not to use this accessor to create the components?
1515     my $components = {};
1516
1517     my $containers;
1518     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
1519
1520     for my $component ( keys %$comps ) {
1521         $components->{ $component } = $comps->{$component};
1522
1523         my ($type, $name) = _get_component_type_name($component);
1524
1525 # FIXME: shouldn't the service name be $name?
1526         $containers->{$type}->add_service(Catalyst::IOC::BlockInjection->new( name => $name, block => sub { return $class->setup_component($component) } ));
1527     }
1528
1529     return $class->$orig($components);
1530 };
1531
1532 =head2 $c->context_class
1533
1534 Returns or sets the context class.
1535
1536 =head2 $c->counter
1537
1538 Returns a hashref containing coderefs and execution counts (needed for
1539 deep recursion detection).
1540
1541 =head2 $c->depth
1542
1543 Returns the number of actions on the current internal execution stack.
1544
1545 =head2 $c->dispatch
1546
1547 Dispatches a request to actions.
1548
1549 =cut
1550
1551 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1552
1553 =head2 $c->dispatcher_class
1554
1555 Returns or sets the dispatcher class.
1556
1557 =head2 $c->dump_these
1558
1559 Returns a list of 2-element array references (name, structure) pairs
1560 that will be dumped on the error page in debug mode.
1561
1562 =cut
1563
1564 sub dump_these {
1565     my $c = shift;
1566     [ Request => $c->req ],
1567     [ Response => $c->res ],
1568     [ Stash => $c->stash ],
1569     [ Config => $c->config ];
1570 }
1571
1572 =head2 $c->engine_class
1573
1574 Returns or sets the engine class.
1575
1576 =head2 $c->execute( $class, $coderef )
1577
1578 Execute a coderef in given class and catch exceptions. Errors are available
1579 via $c->error.
1580
1581 =cut
1582
1583 sub execute {
1584     my ( $c, $class, $code ) = @_;
1585     $class = $c->component($class) || $class;
1586     $c->state(0);
1587
1588     if ( $c->depth >= $RECURSION ) {
1589         my $action = $code->reverse();
1590         $action = "/$action" unless $action =~ /->/;
1591         my $error = qq/Deep recursion detected calling "${action}"/;
1592         $c->log->error($error);
1593         $c->error($error);
1594         $c->state(0);
1595         return $c->state;
1596     }
1597
1598     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1599
1600     push( @{ $c->stack }, $code );
1601
1602     no warnings 'recursion';
1603     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1604     #      I have no idea how, ergo $ret (which appears to fix the issue)
1605     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1606
1607     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1608
1609     my $last = pop( @{ $c->stack } );
1610
1611     if ( my $error = $@ ) {
1612         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1613             $error->rethrow if $c->depth > 1;
1614         }
1615         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1616             $error->rethrow if $c->depth > 0;
1617         }
1618         else {
1619             unless ( ref $error ) {
1620                 no warnings 'uninitialized';
1621                 chomp $error;
1622                 my $class = $last->class;
1623                 my $name  = $last->name;
1624                 $error = qq/Caught exception in $class->$name "$error"/;
1625             }
1626             $c->error($error);
1627         }
1628         $c->state(0);
1629     }
1630     return $c->state;
1631 }
1632
1633 sub _stats_start_execute {
1634     my ( $c, $code ) = @_;
1635     my $appclass = ref($c) || $c;
1636     return if ( ( $code->name =~ /^_.*/ )
1637         && ( !$appclass->config->{show_internal_actions} ) );
1638
1639     my $action_name = $code->reverse();
1640     $c->counter->{$action_name}++;
1641
1642     my $action = $action_name;
1643     $action = "/$action" unless $action =~ /->/;
1644
1645     # determine if the call was the result of a forward
1646     # this is done by walking up the call stack and looking for a calling
1647     # sub of Catalyst::forward before the eval
1648     my $callsub = q{};
1649     for my $index ( 2 .. 11 ) {
1650         last
1651         if ( ( caller($index) )[0] eq 'Catalyst'
1652             && ( caller($index) )[3] eq '(eval)' );
1653
1654         if ( ( caller($index) )[3] =~ /forward$/ ) {
1655             $callsub = ( caller($index) )[3];
1656             $action  = "-> $action";
1657             last;
1658         }
1659     }
1660
1661     my $uid = $action_name . $c->counter->{$action_name};
1662
1663     # is this a root-level call or a forwarded call?
1664     if ( $callsub =~ /forward$/ ) {
1665         my $parent = $c->stack->[-1];
1666
1667         # forward, locate the caller
1668         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1669             $c->stats->profile(
1670                 begin  => $action,
1671                 parent => "$parent" . $c->counter->{"$parent"},
1672                 uid    => $uid,
1673             );
1674         }
1675         else {
1676
1677             # forward with no caller may come from a plugin
1678             $c->stats->profile(
1679                 begin => $action,
1680                 uid   => $uid,
1681             );
1682         }
1683     }
1684     else {
1685
1686         # root-level call
1687         $c->stats->profile(
1688             begin => $action,
1689             uid   => $uid,
1690         );
1691     }
1692     return $action;
1693
1694 }
1695
1696 sub _stats_finish_execute {
1697     my ( $c, $info ) = @_;
1698     $c->stats->profile( end => $info );
1699 }
1700
1701 =head2 $c->finalize
1702
1703 Finalizes the request.
1704
1705 =cut
1706
1707 sub finalize {
1708     my $c = shift;
1709
1710     for my $error ( @{ $c->error } ) {
1711         $c->log->error($error);
1712     }
1713
1714     # Allow engine to handle finalize flow (for POE)
1715     my $engine = $c->engine;
1716     if ( my $code = $engine->can('finalize') ) {
1717         $engine->$code($c);
1718     }
1719     else {
1720
1721         $c->finalize_uploads;
1722
1723         # Error
1724         if ( $#{ $c->error } >= 0 ) {
1725             $c->finalize_error;
1726         }
1727
1728         $c->finalize_headers;
1729
1730         # HEAD request
1731         if ( $c->request->method eq 'HEAD' ) {
1732             $c->response->body('');
1733         }
1734
1735         $c->finalize_body;
1736     }
1737
1738     $c->log_response;
1739
1740     if ($c->use_stats) {
1741         my $elapsed = sprintf '%f', $c->stats->elapsed;
1742         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1743         $c->log->info(
1744             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1745     }
1746
1747     return $c->response->status;
1748 }
1749
1750 =head2 $c->finalize_body
1751
1752 Finalizes body.
1753
1754 =cut
1755
1756 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1757
1758 =head2 $c->finalize_cookies
1759
1760 Finalizes cookies.
1761
1762 =cut
1763
1764 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1765
1766 =head2 $c->finalize_error
1767
1768 Finalizes error.
1769
1770 =cut
1771
1772 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1773
1774 =head2 $c->finalize_headers
1775
1776 Finalizes headers.
1777
1778 =cut
1779
1780 sub finalize_headers {
1781     my $c = shift;
1782
1783     my $response = $c->response; #accessor calls can add up?
1784
1785     # Check if we already finalized headers
1786     return if $response->finalized_headers;
1787
1788     # Handle redirects
1789     if ( my $location = $response->redirect ) {
1790         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1791         $response->header( Location => $location );
1792
1793         if ( !$response->has_body ) {
1794             # Add a default body if none is already present
1795             $response->body(
1796                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1797             );
1798         }
1799     }
1800
1801     # Content-Length
1802     if ( defined $response->body && length $response->body && !$response->content_length ) {
1803
1804         # get the length from a filehandle
1805         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1806         {
1807             my $stat = stat $response->body;
1808             if ( $stat && $stat->size > 0 ) {
1809                 $response->content_length( $stat->size );
1810             }
1811             else {
1812                 $c->log->warn('Serving filehandle without a content-length');
1813             }
1814         }
1815         else {
1816             # everything should be bytes at this point, but just in case
1817             $response->content_length( length( $response->body ) );
1818         }
1819     }
1820
1821     # Errors
1822     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1823         $response->headers->remove_header("Content-Length");
1824         $response->body('');
1825     }
1826
1827     $c->finalize_cookies;
1828
1829     $c->engine->finalize_headers( $c, @_ );
1830
1831     # Done
1832     $response->finalized_headers(1);
1833 }
1834
1835 =head2 $c->finalize_output
1836
1837 An alias for finalize_body.
1838
1839 =head2 $c->finalize_read
1840
1841 Finalizes the input after reading is complete.
1842
1843 =cut
1844
1845 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1846
1847 =head2 $c->finalize_uploads
1848
1849 Finalizes uploads. Cleans up any temporary files.
1850
1851 =cut
1852
1853 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1854
1855 =head2 $c->get_action( $action, $namespace )
1856
1857 Gets an action in a given namespace.
1858
1859 =cut
1860
1861 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1862
1863 =head2 $c->get_actions( $action, $namespace )
1864
1865 Gets all actions of a given name in a namespace and all parent
1866 namespaces.
1867
1868 =cut
1869
1870 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1871
1872 =head2 $app->handle_request( @arguments )
1873
1874 Called to handle each HTTP request.
1875
1876 =cut
1877
1878 sub handle_request {
1879     my ( $class, @arguments ) = @_;
1880
1881     # Always expect worst case!
1882     my $status = -1;
1883     eval {
1884         if ($class->debug) {
1885             my $secs = time - $START || 1;
1886             my $av = sprintf '%.3f', $COUNT / $secs;
1887             my $time = localtime time;
1888             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1889         }
1890
1891         my $c = $class->prepare(@arguments);
1892         $c->dispatch;
1893         $status = $c->finalize;
1894     };
1895
1896     if ( my $error = $@ ) {
1897         chomp $error;
1898         $class->log->error(qq/Caught exception in engine "$error"/);
1899     }
1900
1901     $COUNT++;
1902
1903     if(my $coderef = $class->log->can('_flush')){
1904         $class->log->$coderef();
1905     }
1906     return $status;
1907 }
1908
1909 =head2 $c->prepare( @arguments )
1910
1911 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1912 etc.).
1913
1914 =cut
1915
1916 sub prepare {
1917     my ( $class, @arguments ) = @_;
1918
1919     # XXX
1920     # After the app/ctxt split, this should become an attribute based on something passed
1921     # into the application.
1922     $class->context_class( ref $class || $class ) unless $class->context_class;
1923
1924     my $c = $class->context_class->new({});
1925
1926     # For on-demand data
1927     $c->request->_context($c);
1928     $c->response->_context($c);
1929
1930     #surely this is not the most efficient way to do things...
1931     $c->stats($class->stats_class->new)->enable($c->use_stats);
1932     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1933         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1934     }
1935
1936     #XXX reuse coderef from can
1937     # Allow engine to direct the prepare flow (for POE)
1938     if ( $c->engine->can('prepare') ) {
1939         $c->engine->prepare( $c, @arguments );
1940     }
1941     else {
1942         $c->prepare_request(@arguments);
1943         $c->prepare_connection;
1944         $c->prepare_query_parameters;
1945         $c->prepare_headers;
1946         $c->prepare_cookies;
1947         $c->prepare_path;
1948
1949         # Prepare the body for reading, either by prepare_body
1950         # or the user, if they are using $c->read
1951         $c->prepare_read;
1952
1953         # Parse the body unless the user wants it on-demand
1954         unless ( ref($c)->config->{parse_on_demand} ) {
1955             $c->prepare_body;
1956         }
1957     }
1958
1959     my $method  = $c->req->method  || '';
1960     my $path    = $c->req->path;
1961     $path       = '/' unless length $path;
1962     my $address = $c->req->address || '';
1963
1964     $c->log_request;
1965
1966     $c->prepare_action;
1967
1968     return $c;
1969 }
1970
1971 =head2 $c->prepare_action
1972
1973 Prepares action. See L<Catalyst::Dispatcher>.
1974
1975 =cut
1976
1977 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1978
1979 =head2 $c->prepare_body
1980
1981 Prepares message body.
1982
1983 =cut
1984
1985 sub prepare_body {
1986     my $c = shift;
1987
1988     return if $c->request->_has_body;
1989
1990     # Initialize on-demand data
1991     $c->engine->prepare_body( $c, @_ );
1992     $c->prepare_parameters;
1993     $c->prepare_uploads;
1994 }
1995
1996 =head2 $c->prepare_body_chunk( $chunk )
1997
1998 Prepares a chunk of data before sending it to L<HTTP::Body>.
1999
2000 See L<Catalyst::Engine>.
2001
2002 =cut
2003
2004 sub prepare_body_chunk {
2005     my $c = shift;
2006     $c->engine->prepare_body_chunk( $c, @_ );
2007 }
2008
2009 =head2 $c->prepare_body_parameters
2010
2011 Prepares body parameters.
2012
2013 =cut
2014
2015 sub prepare_body_parameters {
2016     my $c = shift;
2017     $c->engine->prepare_body_parameters( $c, @_ );
2018 }
2019
2020 =head2 $c->prepare_connection
2021
2022 Prepares connection.
2023
2024 =cut
2025
2026 sub prepare_connection {
2027     my $c = shift;
2028     $c->engine->prepare_connection( $c, @_ );
2029 }
2030
2031 =head2 $c->prepare_cookies
2032
2033 Prepares cookies.
2034
2035 =cut
2036
2037 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2038
2039 =head2 $c->prepare_headers
2040
2041 Prepares headers.
2042
2043 =cut
2044
2045 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2046
2047 =head2 $c->prepare_parameters
2048
2049 Prepares parameters.
2050
2051 =cut
2052
2053 sub prepare_parameters {
2054     my $c = shift;
2055     $c->prepare_body_parameters;
2056     $c->engine->prepare_parameters( $c, @_ );
2057 }
2058
2059 =head2 $c->prepare_path
2060
2061 Prepares path and base.
2062
2063 =cut
2064
2065 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2066
2067 =head2 $c->prepare_query_parameters
2068
2069 Prepares query parameters.
2070
2071 =cut
2072
2073 sub prepare_query_parameters {
2074     my $c = shift;
2075
2076     $c->engine->prepare_query_parameters( $c, @_ );
2077 }
2078
2079 =head2 $c->log_request
2080
2081 Writes information about the request to the debug logs.  This includes:
2082
2083 =over 4
2084
2085 =item * Request method, path, and remote IP address
2086
2087 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2088
2089 =item * Request parameters
2090
2091 =item * File uploads
2092
2093 =back
2094
2095 =cut
2096
2097 sub log_request {
2098     my $c = shift;
2099
2100     return unless $c->debug;
2101
2102     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2103     my $request = $dump->[1];
2104
2105     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2106     $method ||= '';
2107     $path = '/' unless length $path;
2108     $address ||= '';
2109     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2110
2111     $c->log_request_headers($request->headers);
2112
2113     if ( my $keywords = $request->query_keywords ) {
2114         $c->log->debug("Query keywords are: $keywords");
2115     }
2116
2117     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2118
2119     $c->log_request_uploads($request);
2120 }
2121
2122 =head2 $c->log_response
2123
2124 Writes information about the response to the debug logs by calling
2125 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2126
2127 =cut
2128
2129 sub log_response {
2130     my $c = shift;
2131
2132     return unless $c->debug;
2133
2134     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2135     my $response = $dump->[1];
2136
2137     $c->log_response_status_line($response);
2138     $c->log_response_headers($response->headers);
2139 }
2140
2141 =head2 $c->log_response_status_line($response)
2142
2143 Writes one line of information about the response to the debug logs.  This includes:
2144
2145 =over 4
2146
2147 =item * Response status code
2148
2149 =item * Content-Type header (if present)
2150
2151 =item * Content-Length header (if present)
2152
2153 =back
2154
2155 =cut
2156
2157 sub log_response_status_line {
2158     my ($c, $response) = @_;
2159
2160     $c->log->debug(
2161         sprintf(
2162             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2163             $response->status                            || 'unknown',
2164             $response->headers->header('Content-Type')   || 'unknown',
2165             $response->headers->header('Content-Length') || 'unknown'
2166         )
2167     );
2168 }
2169
2170 =head2 $c->log_response_headers($headers);
2171
2172 Hook method which can be wrapped by plugins to log the responseheaders.
2173 No-op in the default implementation.
2174
2175 =cut
2176
2177 sub log_response_headers {}
2178
2179 =head2 $c->log_request_parameters( query => {}, body => {} )
2180
2181 Logs request parameters to debug logs
2182
2183 =cut
2184
2185 sub log_request_parameters {
2186     my $c          = shift;
2187     my %all_params = @_;
2188
2189     return unless $c->debug;
2190
2191     my $column_width = Catalyst::Utils::term_width() - 44;
2192     foreach my $type (qw(query body)) {
2193         my $params = $all_params{$type};
2194         next if ! keys %$params;
2195         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2196         for my $key ( sort keys %$params ) {
2197             my $param = $params->{$key};
2198             my $value = defined($param) ? $param : '';
2199             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2200         }
2201         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2202     }
2203 }
2204
2205 =head2 $c->log_request_uploads
2206
2207 Logs file uploads included in the request to the debug logs.
2208 The parameter name, filename, file type, and file size are all included in
2209 the debug logs.
2210
2211 =cut
2212
2213 sub log_request_uploads {
2214     my $c = shift;
2215     my $request = shift;
2216     return unless $c->debug;
2217     my $uploads = $request->uploads;
2218     if ( keys %$uploads ) {
2219         my $t = Text::SimpleTable->new(
2220             [ 12, 'Parameter' ],
2221             [ 26, 'Filename' ],
2222             [ 18, 'Type' ],
2223             [ 9,  'Size' ]
2224         );
2225         for my $key ( sort keys %$uploads ) {
2226             my $upload = $uploads->{$key};
2227             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2228                 $t->row( $key, $u->filename, $u->type, $u->size );
2229             }
2230         }
2231         $c->log->debug( "File Uploads are:\n" . $t->draw );
2232     }
2233 }
2234
2235 =head2 $c->log_request_headers($headers);
2236
2237 Hook method which can be wrapped by plugins to log the request headers.
2238 No-op in the default implementation.
2239
2240 =cut
2241
2242 sub log_request_headers {}
2243
2244 =head2 $c->log_headers($type => $headers)
2245
2246 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2247
2248 =cut
2249
2250 sub log_headers {
2251     my $c       = shift;
2252     my $type    = shift;
2253     my $headers = shift;    # an HTTP::Headers instance
2254
2255     return unless $c->debug;
2256
2257     my $column_width = Catalyst::Utils::term_width() - 28;
2258     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2259     $headers->scan(
2260         sub {
2261             my ( $name, $value ) = @_;
2262             $t->row( $name, $value );
2263         }
2264     );
2265     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2266 }
2267
2268
2269 =head2 $c->prepare_read
2270
2271 Prepares the input for reading.
2272
2273 =cut
2274
2275 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2276
2277 =head2 $c->prepare_request
2278
2279 Prepares the engine request.
2280
2281 =cut
2282
2283 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2284
2285 =head2 $c->prepare_uploads
2286
2287 Prepares uploads.
2288
2289 =cut
2290
2291 sub prepare_uploads {
2292     my $c = shift;
2293
2294     $c->engine->prepare_uploads( $c, @_ );
2295 }
2296
2297 =head2 $c->prepare_write
2298
2299 Prepares the output for writing.
2300
2301 =cut
2302
2303 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2304
2305 =head2 $c->request_class
2306
2307 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2308
2309 =head2 $c->response_class
2310
2311 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2312
2313 =head2 $c->read( [$maxlength] )
2314
2315 Reads a chunk of data from the request body. This method is designed to
2316 be used in a while loop, reading C<$maxlength> bytes on every call.
2317 C<$maxlength> defaults to the size of the request if not specified.
2318
2319 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2320 directly.
2321
2322 Warning: If you use read(), Catalyst will not process the body,
2323 so you will not be able to access POST parameters or file uploads via
2324 $c->request.  You must handle all body parsing yourself.
2325
2326 =cut
2327
2328 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2329
2330 =head2 $c->run
2331
2332 Starts the engine.
2333
2334 =cut
2335
2336 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2337
2338 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2339
2340 Sets an action in a given namespace.
2341
2342 =cut
2343
2344 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2345
2346 =head2 $c->setup_actions($component)
2347
2348 Sets up actions for a component.
2349
2350 =cut
2351
2352 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2353
2354 =head2 $c->setup_config
2355
2356 =cut
2357
2358 sub setup_config {
2359     my $class = shift;
2360
2361     my %args = %{ $class->config || {} };
2362
2363     my @container_classes = ( "${class}::Container", 'Catalyst::IOC::Container');
2364     unshift @container_classes, delete $args{container_class} if exists $args{container_class};
2365
2366     my $container_class = Class::MOP::load_first_existing_class(@container_classes);
2367
2368     my $container = $container_class->new( %args, name => "$class" );
2369     $class->container($container);
2370
2371     my $config = $container->resolve(service => 'config');
2372     $class->config($config);
2373     $class->finalize_config; # back-compat
2374 }
2375
2376 =head2 $c->finalize_config
2377
2378 =cut
2379
2380 sub finalize_config { }
2381
2382 =head2 $c->setup_components
2383
2384 This method is called internally to set up the application's components.
2385
2386 It finds modules by calling the L<locate_components> method, expands them to
2387 package names with the L<expand_component_module> method, and then installs
2388 each component into the application.
2389
2390 The C<setup_components> config option is passed to both of the above methods.
2391
2392 Installation of each component is performed by the L<setup_component> method,
2393 below.
2394
2395 =cut
2396
2397 sub setup_components {
2398     my $class = shift;
2399
2400     my $config  = $class->config->{ setup_components };
2401
2402     my @comps = $class->locate_components($config);
2403     my %comps = map { $_ => 1 } @comps;
2404
2405     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2406     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2407         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2408     ) if $deprecatedcatalyst_component_names;
2409
2410     for my $component ( @comps ) {
2411
2412         # We pass ignore_loaded here so that overlay files for (e.g.)
2413         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2414         # we know M::P::O found a file on disk so this is safe
2415
2416         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2417     }
2418
2419     my $containers;
2420     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
2421
2422     for my $component (@comps) {
2423         my $instance = $class->components->{ $component } = $class->setup_component($component);
2424         if ( my ($type, $name) = _get_component_type_name($component) ) {
2425             $containers->{$type}->add_service(Catalyst::IOC::BlockInjection->new( name => $name, block => sub { return $instance } ));
2426         }
2427         my @expanded_components = $instance->can('expand_modules')
2428             ? $instance->expand_modules( $component, $config )
2429             : $class->expand_component_module( $component, $config );
2430         for my $component (@expanded_components) {
2431             next if $comps{$component};
2432
2433             $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @expanded_components;
2434             $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2435                 qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2436             ) if $deprecatedcatalyst_component_names;
2437
2438             if (my ($type, $name) = _get_component_type_name($component)) {
2439                 $containers->{$type}->add_service(Catalyst::IOC::BlockInjection->new( name => $name, block => sub { return $class->setup_component($component) } ));
2440             }
2441
2442             $class->components->{ $component } = $class->setup_component($component);
2443         }
2444     }
2445 }
2446
2447 sub _get_component_type_name {
2448     my $component = shift;
2449     my @parts     = split /::/, $component;
2450
2451     while (my $type = shift @parts) {
2452         return ('controller', join '::', @parts)
2453             if $type =~ /^(c|controller)$/i;
2454
2455         return ('model', join '::', @parts)
2456             if $type =~ /^(m|model)$/i;
2457
2458         return ('view', join '::', @parts)
2459             if $type =~ /^(v|view)$/i;
2460     }
2461 }
2462
2463 =head2 $c->locate_components( $setup_component_config )
2464
2465 This method is meant to provide a list of component modules that should be
2466 setup for the application.  By default, it will use L<Module::Pluggable>.
2467
2468 Specify a C<setup_components> config option to pass additional options directly
2469 to L<Module::Pluggable>. To add additional search paths, specify a key named
2470 C<search_extra> as an array reference. Items in the array beginning with C<::>
2471 will have the application class name prepended to them.
2472
2473 =cut
2474
2475 sub locate_components {
2476     my $class  = shift;
2477     my $config = shift;
2478
2479     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2480     my $extra   = delete $config->{ search_extra } || [];
2481
2482     push @paths, @$extra;
2483
2484     my $locator = Module::Pluggable::Object->new(
2485         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2486         %$config
2487     );
2488
2489     # XXX think about ditching this sort entirely
2490     my @comps = sort { length $a <=> length $b } $locator->plugins;
2491
2492     return @comps;
2493 }
2494
2495 =head2 $c->expand_component_module( $component, $setup_component_config )
2496
2497 Components found by C<locate_components> will be passed to this method, which
2498 is expected to return a list of component (package) names to be set up.
2499
2500 =cut
2501
2502 sub expand_component_module {
2503     my ($class, $module) = @_;
2504     return Devel::InnerPackage::list_packages( $module );
2505 }
2506
2507 =head2 $c->setup_component
2508
2509 =cut
2510
2511 sub setup_component {
2512     my( $class, $component ) = @_;
2513
2514     unless ( $component->can( 'COMPONENT' ) ) {
2515         return $component;
2516     }
2517
2518     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2519     my $config = $class->config->{ $suffix } || {};
2520     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2521     # methods also pass it. local to avoid pointlessly shitting in config
2522     # for the debug screen, as $component is already the key name.
2523     local $config->{catalyst_component_name} = $component;
2524
2525     my $instance = eval { $component->COMPONENT( $class, $config ); };
2526
2527     if ( my $error = $@ ) {
2528         chomp $error;
2529         Catalyst::Exception->throw(
2530             message => qq/Couldn't instantiate component "$component", "$error"/
2531         );
2532     }
2533     elsif (!blessed $instance) {
2534         my $metaclass = Moose::Util::find_meta($component);
2535         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2536         my $component_method_from = $method_meta->associated_metaclass->name;
2537         my $value = defined($instance) ? $instance : 'undef';
2538         Catalyst::Exception->throw(
2539             message =>
2540             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2541         );
2542     }
2543
2544     return $instance;
2545 }
2546
2547 =head2 $c->setup_dispatcher
2548
2549 Sets up dispatcher.
2550
2551 =cut
2552
2553 sub setup_dispatcher {
2554     my ( $class, $dispatcher ) = @_;
2555
2556     if ($dispatcher) {
2557         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2558     }
2559
2560     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2561         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2562     }
2563
2564     unless ($dispatcher) {
2565         $dispatcher = $class->dispatcher_class;
2566     }
2567
2568     Class::MOP::load_class($dispatcher);
2569
2570     # dispatcher instance
2571     $class->dispatcher( $dispatcher->new );
2572 }
2573
2574 =head2 $c->setup_engine
2575
2576 Sets up engine.
2577
2578 =cut
2579
2580 sub setup_engine {
2581     my ( $class, $engine ) = @_;
2582
2583     if ($engine) {
2584         $engine = 'Catalyst::Engine::' . $engine;
2585     }
2586
2587     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2588         $engine = 'Catalyst::Engine::' . $env;
2589     }
2590
2591     if ( $ENV{MOD_PERL} ) {
2592         my $meta = Class::MOP::get_metaclass_by_name($class);
2593
2594         # create the apache method
2595         $meta->add_method('apache' => sub { shift->engine->apache });
2596
2597         my ( $software, $version ) =
2598           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2599
2600         $version =~ s/_//g;
2601         $version =~ s/(\.[^.]+)\./$1/g;
2602
2603         if ( $software eq 'mod_perl' ) {
2604
2605             if ( !$engine ) {
2606
2607                 if ( $version >= 1.99922 ) {
2608                     $engine = 'Catalyst::Engine::Apache2::MP20';
2609                 }
2610
2611                 elsif ( $version >= 1.9901 ) {
2612                     $engine = 'Catalyst::Engine::Apache2::MP19';
2613                 }
2614
2615                 elsif ( $version >= 1.24 ) {
2616                     $engine = 'Catalyst::Engine::Apache::MP13';
2617                 }
2618
2619                 else {
2620                     Catalyst::Exception->throw( message =>
2621                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2622                 }
2623
2624             }
2625
2626             # install the correct mod_perl handler
2627             if ( $version >= 1.9901 ) {
2628                 *handler = sub  : method {
2629                     shift->handle_request(@_);
2630                 };
2631             }
2632             else {
2633                 *handler = sub ($$) { shift->handle_request(@_) };
2634             }
2635
2636         }
2637
2638         elsif ( $software eq 'Zeus-Perl' ) {
2639             $engine = 'Catalyst::Engine::Zeus';
2640         }
2641
2642         else {
2643             Catalyst::Exception->throw(
2644                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2645         }
2646     }
2647
2648     unless ($engine) {
2649         $engine = $class->engine_class;
2650     }
2651
2652     Class::MOP::load_class($engine);
2653
2654     # check for old engines that are no longer compatible
2655     my $old_engine;
2656     if ( $engine->isa('Catalyst::Engine::Apache')
2657         && !Catalyst::Engine::Apache->VERSION )
2658     {
2659         $old_engine = 1;
2660     }
2661
2662     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2663         && Catalyst::Engine::Server->VERSION le '0.02' )
2664     {
2665         $old_engine = 1;
2666     }
2667
2668     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2669         && $engine->VERSION eq '0.01' )
2670     {
2671         $old_engine = 1;
2672     }
2673
2674     elsif ($engine->isa('Catalyst::Engine::Zeus')
2675         && $engine->VERSION eq '0.01' )
2676     {
2677         $old_engine = 1;
2678     }
2679
2680     if ($old_engine) {
2681         Catalyst::Exception->throw( message =>
2682               qq/Engine "$engine" is not supported by this version of Catalyst/
2683         );
2684     }
2685
2686     # engine instance
2687     $class->engine( $engine->new );
2688 }
2689
2690 =head2 $c->setup_home
2691
2692 Sets up the home directory.
2693
2694 =cut
2695
2696 sub setup_home {
2697     my ( $class, $home ) = @_;
2698
2699     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2700         $home = $env;
2701     }
2702
2703     $home ||= Catalyst::Utils::home($class);
2704
2705     if ($home) {
2706         #I remember recently being scolded for assigning config values like this
2707         $class->config->{home} ||= $home;
2708         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2709     }
2710 }
2711
2712 =head2 $c->setup_log
2713
2714 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2715 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2716 log to.
2717
2718 This method also installs a C<debug> method that returns a true value into the
2719 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2720 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2721
2722 Note that if the log has already been setup, by either a previous call to
2723 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2724 that this method won't actually set up the log object.
2725
2726 =cut
2727
2728 sub setup_log {
2729     my ( $class, $levels ) = @_;
2730
2731     $levels ||= '';
2732     $levels =~ s/^\s+//;
2733     $levels =~ s/\s+$//;
2734     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2735
2736     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2737     if ( defined $env_debug ) {
2738         $levels{debug} = 1 if $env_debug; # Ugly!
2739         delete($levels{debug}) unless $env_debug;
2740     }
2741
2742     unless ( $class->log ) {
2743         $class->log( Catalyst::Log->new(keys %levels) );
2744     }
2745
2746     if ( $levels{debug} ) {
2747         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2748         $class->log->debug('Debug messages enabled');
2749     }
2750 }
2751
2752 =head2 $c->setup_plugins
2753
2754 Sets up plugins.
2755
2756 =cut
2757
2758 =head2 $c->setup_stats
2759
2760 Sets up timing statistics class.
2761
2762 =cut
2763
2764 sub setup_stats {
2765     my ( $class, $stats ) = @_;
2766
2767     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2768
2769     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2770     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2771         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2772         $class->log->debug('Statistics enabled');
2773     }
2774 }
2775
2776
2777 =head2 $c->registered_plugins
2778
2779 Returns a sorted list of the plugins which have either been stated in the
2780 import list or which have been added via C<< MyApp->plugin(@args); >>.
2781
2782 If passed a given plugin name, it will report a boolean value indicating
2783 whether or not that plugin is loaded.  A fully qualified name is required if
2784 the plugin name does not begin with C<Catalyst::Plugin::>.
2785
2786  if ($c->registered_plugins('Some::Plugin')) {
2787      ...
2788  }
2789
2790 =cut
2791
2792 {
2793
2794     sub registered_plugins {
2795         my $proto = shift;
2796         return sort keys %{ $proto->_plugins } unless @_;
2797         my $plugin = shift;
2798         return 1 if exists $proto->_plugins->{$plugin};
2799         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2800     }
2801
2802     sub _register_plugin {
2803         my ( $proto, $plugin, $instant ) = @_;
2804         my $class = ref $proto || $proto;
2805
2806         Class::MOP::load_class( $plugin );
2807         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2808             if $plugin->isa( 'Catalyst::Component' );
2809         $proto->_plugins->{$plugin} = 1;
2810         unless ($instant) {
2811             my $meta = Class::MOP::get_metaclass_by_name($class);
2812             $meta->superclasses($plugin, $meta->superclasses);
2813         }
2814         return $class;
2815     }
2816
2817     sub setup_plugins {
2818         my ( $class, $plugins ) = @_;
2819
2820         $class->_plugins( {} ) unless $class->_plugins;
2821         $plugins = Data::OptList::mkopt($plugins || []);
2822
2823         my @plugins = map {
2824             [ Catalyst::Utils::resolve_namespace(
2825                   $class . '::Plugin',
2826                   'Catalyst::Plugin', $_->[0]
2827               ),
2828               $_->[1],
2829             ]
2830          } @{ $plugins };
2831
2832         for my $plugin ( reverse @plugins ) {
2833             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2834             my $meta = find_meta($plugin->[0]);
2835             next if $meta && $meta->isa('Moose::Meta::Role');
2836
2837             $class->_register_plugin($plugin->[0]);
2838         }
2839
2840         my @roles =
2841             map  { $_->[0]->name, $_->[1] }
2842             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2843             map  { [find_meta($_->[0]), $_->[1]] }
2844             @plugins;
2845
2846         Moose::Util::apply_all_roles(
2847             $class => @roles
2848         ) if @roles;
2849     }
2850 }
2851
2852 =head2 $c->stack
2853
2854 Returns an arrayref of the internal execution stack (actions that are
2855 currently executing).
2856
2857 =head2 $c->stats
2858
2859 Returns the current timing statistics object. By default Catalyst uses
2860 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2861 L<< stats_class|/"$c->stats_class" >>.
2862
2863 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2864 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2865 profile explicitly, although MyApp.pm still won't profile nor output anything
2866 by itself.
2867
2868 =head2 $c->stats_class
2869
2870 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2871
2872 =head2 $c->use_stats
2873
2874 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2875
2876 Note that this is a static method, not an accessor and should be overridden
2877 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2878
2879 =cut
2880
2881 sub use_stats { 0 }
2882
2883
2884 =head2 $c->write( $data )
2885
2886 Writes $data to the output stream. When using this method directly, you
2887 will need to manually set the C<Content-Length> header to the length of
2888 your output data, if known.
2889
2890 =cut
2891
2892 sub write {
2893     my $c = shift;
2894
2895     # Finalize headers if someone manually writes output
2896     $c->finalize_headers;
2897
2898     return $c->engine->write( $c, @_ );
2899 }
2900
2901 =head2 version
2902
2903 Returns the Catalyst version number. Mostly useful for "powered by"
2904 messages in template systems.
2905
2906 =cut
2907
2908 sub version { return $Catalyst::VERSION }
2909
2910 =head1 CONFIGURATION
2911
2912 There are a number of 'base' config variables which can be set:
2913
2914 =over
2915
2916 =item *
2917
2918 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2919
2920 =item *
2921
2922 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2923
2924 =item *
2925
2926 C<disable_component_resolution_regex_fallback> - Turns
2927 off the deprecated component resolution functionality so
2928 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2929 are called then regex search will not be attempted on string values and
2930 instead C<undef> will be returned.
2931
2932 =item *
2933
2934 C<home> - The application home directory. In an uninstalled application,
2935 this is the top level application directory. In an installed application,
2936 this will be the directory containing C<< MyApp.pm >>.
2937
2938 =item *
2939
2940 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2941
2942 =item *
2943
2944 C<name> - The name of the application in debug messages and the debug and
2945 welcome screens
2946
2947 =item *
2948
2949 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2950 until it is accessed. This allows you to (for example) check authentication (and reject
2951 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2952
2953 =item *
2954
2955 C<root> - The root directory for templates. Usually this is just a
2956 subdirectory of the home directory, but you can set it to change the
2957 templates to a different directory.
2958
2959 =item *
2960
2961 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2962 namespaces from which components will be loaded (and constructed and stored in
2963 C<< $c->components >>).
2964
2965 =item *
2966
2967 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2968 to be shown in hit debug tables in the test server.
2969
2970 =item *
2971
2972 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
2973 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
2974 for more information.
2975
2976 =item *
2977
2978 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2979
2980 =back
2981
2982 =head1 INTERNAL ACTIONS
2983
2984 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2985 C<_ACTION>, and C<_END>. These are by default not shown in the private
2986 action table, but you can make them visible with a config parameter.
2987
2988     MyApp->config(show_internal_actions => 1);
2989
2990 =head1 ON-DEMAND PARSER
2991
2992 The request body is usually parsed at the beginning of a request,
2993 but if you want to handle input yourself, you can enable on-demand
2994 parsing with a config parameter.
2995
2996     MyApp->config(parse_on_demand => 1);
2997
2998 =head1 PROXY SUPPORT
2999
3000 Many production servers operate using the common double-server approach,
3001 with a lightweight frontend web server passing requests to a larger
3002 backend server. An application running on the backend server must deal
3003 with two problems: the remote user always appears to be C<127.0.0.1> and
3004 the server's hostname will appear to be C<localhost> regardless of the
3005 virtual host that the user connected through.
3006
3007 Catalyst will automatically detect this situation when you are running
3008 the frontend and backend servers on the same machine. The following
3009 changes are made to the request.
3010
3011     $c->req->address is set to the user's real IP address, as read from
3012     the HTTP X-Forwarded-For header.
3013
3014     The host value for $c->req->base and $c->req->uri is set to the real
3015     host, as read from the HTTP X-Forwarded-Host header.
3016
3017 Additionally, you may be running your backend application on an insecure
3018 connection (port 80) while your frontend proxy is running under SSL.  If there
3019 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3020 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3021 be created properly.
3022
3023 In the case of passing in:
3024
3025     X-Forwarded-Port: 443
3026
3027 All calls to C<uri_for> will result in an https link, as is expected.
3028
3029 Obviously, your web server must support these headers for this to work.
3030
3031 In a more complex server farm environment where you may have your
3032 frontend proxy server(s) on different machines, you will need to set a
3033 configuration option to tell Catalyst to read the proxied data from the
3034 headers.
3035
3036     MyApp->config(using_frontend_proxy => 1);
3037
3038 If you do not wish to use the proxy support at all, you may set:
3039
3040     MyApp->config(ignore_frontend_proxy => 1);
3041
3042 =head1 THREAD SAFETY
3043
3044 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3045 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3046 believe the Catalyst core to be thread-safe.
3047
3048 If you plan to operate in a threaded environment, remember that all other
3049 modules you are using must also be thread-safe. Some modules, most notably
3050 L<DBD::SQLite>, are not thread-safe.
3051
3052 =head1 SUPPORT
3053
3054 IRC:
3055
3056     Join #catalyst on irc.perl.org.
3057
3058 Mailing Lists:
3059
3060     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3061     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3062
3063 Web:
3064
3065     http://catalyst.perl.org
3066
3067 Wiki:
3068
3069     http://dev.catalyst.perl.org
3070
3071 =head1 SEE ALSO
3072
3073 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3074
3075 =head2 L<Catalyst::Manual> - The Catalyst Manual
3076
3077 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3078
3079 =head2 L<Catalyst::Engine> - Core engine
3080
3081 =head2 L<Catalyst::Log> - Log class.
3082
3083 =head2 L<Catalyst::Request> - Request object
3084
3085 =head2 L<Catalyst::Response> - Response object
3086
3087 =head2 L<Catalyst::Test> - The test suite.
3088
3089 =head1 PROJECT FOUNDER
3090
3091 sri: Sebastian Riedel <sri@cpan.org>
3092
3093 =head1 CONTRIBUTORS
3094
3095 abw: Andy Wardley
3096
3097 acme: Leon Brocard <leon@astray.com>
3098
3099 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3100
3101 Andrew Bramble
3102
3103 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3104
3105 Andrew Ruthven
3106
3107 André Walker
3108
3109 andyg: Andy Grundman <andy@hybridized.org>
3110
3111 audreyt: Audrey Tang
3112
3113 bricas: Brian Cassidy <bricas@cpan.org>
3114
3115 Caelum: Rafael Kitover <rkitover@io.com>
3116
3117 chansen: Christian Hansen
3118
3119 chicks: Christopher Hicks
3120
3121 Chisel Wright C<pause@herlpacker.co.uk>
3122
3123 Danijel Milicevic C<me@danijel.de>
3124
3125 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3126
3127 David Naughton, C<naughton@umn.edu>
3128
3129 David E. Wheeler
3130
3131 dhoss: Devin Austin <dhoss@cpan.org>
3132
3133 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3134
3135 Drew Taylor
3136
3137 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3138
3139 esskar: Sascha Kiefer
3140
3141 fireartist: Carl Franks <cfranks@cpan.org>
3142
3143 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3144
3145 gabb: Danijel Milicevic
3146
3147 Gary Ashton Jones
3148
3149 Gavin Henry C<ghenry@perl.me.uk>
3150
3151 Geoff Richards
3152
3153 groditi: Guillermo Roditi <groditi@gmail.com>
3154
3155 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3156
3157 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3158
3159 jcamacho: Juan Camacho
3160
3161 jester: Jesse Sheidlower C<jester@panix.com>
3162
3163 jhannah: Jay Hannah <jay@jays.net>
3164
3165 Jody Belka
3166
3167 Johan Lindstrom
3168
3169 jon: Jon Schutz <jjschutz@cpan.org>
3170
3171 Jonathan Rockway C<< <jrockway@cpan.org> >>
3172
3173 Kieren Diment C<kd@totaldatasolution.com>
3174
3175 konobi: Scott McWhirter <konobi@cpan.org>
3176
3177 marcus: Marcus Ramberg <mramberg@cpan.org>
3178
3179 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3180
3181 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3182
3183 mugwump: Sam Vilain
3184
3185 naughton: David Naughton
3186
3187 ningu: David Kamholz <dkamholz@cpan.org>
3188
3189 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3190
3191 numa: Dan Sully <daniel@cpan.org>
3192
3193 obra: Jesse Vincent
3194
3195 Octavian Rasnita
3196
3197 omega: Andreas Marienborg
3198
3199 Oleg Kostyuk <cub.uanic@gmail.com>
3200
3201 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3202
3203 rafl: Florian Ragwitz <rafl@debian.org>
3204
3205 random: Roland Lammel <lammel@cpan.org>
3206
3207 Robert Sedlacek C<< <rs@474.at> >>
3208
3209 SpiceMan: Marcel Montes
3210
3211 sky: Arthur Bergman
3212
3213 szbalint: Balint Szilakszi <szbalint@cpan.org>
3214
3215 t0m: Tomas Doran <bobtfish@bobtfish.net>
3216
3217 Ulf Edvinsson
3218
3219 Viljo Marrandi C<vilts@yahoo.com>
3220
3221 Will Hawes C<info@whawes.co.uk>
3222
3223 willert: Sebastian Willert <willert@cpan.org>
3224
3225 wreis: Wallace Reis <wallace@reis.org.br>
3226
3227 Yuval Kogman, C<nothingmuch@woobling.org>
3228
3229 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3230
3231 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3232
3233 =head1 COPYRIGHT
3234
3235 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3236
3237 =head1 LICENSE
3238
3239 This library is free software. You can redistribute it and/or modify it under
3240 the same terms as Perl itself.
3241
3242 =cut
3243
3244 no Moose;
3245
3246 __PACKAGE__->meta->make_immutable;
3247
3248 1;