lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/container components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80032';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub _application { $_[0] }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 This sets the log level to 'debug' and enables full debug output on the
 252 error screen. If you only want the latter, see L<< $c->debug >>.
 253
 254 =head2 -Engine
 255
 256 Forces Catalyst to use a specific engine. Omit the
 257 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 258
 259     use Catalyst qw/-Engine=CGI/;
 260
 261 =head2 -Home
 262
 263 Forces Catalyst to use a specific home directory, e.g.:
 264
 265     use Catalyst qw[-Home=/usr/mst];
 266
 267 This can also be done in the shell environment by setting either the
 268 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 269 is replaced with the uppercased name of your application, any "::" in
 270 the name will be replaced with underscores, e.g. MyApp::Web should use
 271 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 272
 273 If none of these are set, Catalyst will attempt to automatically detect the
 274 home directory. If you are working in a development envirnoment, Catalyst
 275 will try and find the directory containing either Makefile.PL, Build.PL or
 276 dist.ini. If the application has been installed into the system (i.e.
 277 you have done C<make install>), then Catalyst will use the path to your
 278 application module, without the .pm extension (ie, /foo/MyApp if your
 279 application was installed at /foo/MyApp.pm)
 280
 281 =head2 -Log
 282
 283     use Catalyst '-Log=warn,fatal,error';
 284
 285 Specifies a comma-delimited list of log levels.
 286
 287 =head2 -Stats
 288
 289 Enables statistics collection and reporting.
 290
 291    use Catalyst qw/-Stats=1/;
 292
 293 You can also force this setting from the system environment with CATALYST_STATS
 294 or <MYAPP>_STATS. The environment settings override the application, with
 295 <MYAPP>_STATS having the highest priority.
 296
 297 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 298
 299 =head1 METHODS
 300
 301 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 302
 303 =head2 $c->action
 304
 305 Returns a L<Catalyst::Action> object for the current action, which
 306 stringifies to the action name. See L<Catalyst::Action>.
 307
 308 =head2 $c->namespace
 309
 310 Returns the namespace of the current action, i.e., the URI prefix
 311 corresponding to the controller of the current action. For example:
 312
 313     # in Controller::Foo::Bar
 314     $c->namespace; # returns 'foo/bar';
 315
 316 =head2 $c->request
 317
 318 =head2 $c->req
 319
 320 Returns the current L<Catalyst::Request> object, giving access to
 321 information about the current client request (including parameters,
 322 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 323
 324 =head2 REQUEST FLOW HANDLING
 325
 326 =head2 $c->forward( $action [, \@arguments ] )
 327
 328 =head2 $c->forward( $class, $method, [, \@arguments ] )
 329
 330 Forwards processing to another action, by its private name. If you give a
 331 class name but no method, C<process()> is called. You may also optionally
 332 pass arguments in an arrayref. The action will receive the arguments in
 333 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 334 C<< $c->req->args >> will be restored to the previous values.
 335
 336 Any data C<return>ed from the action forwarded to, will be returned by the
 337 call to forward.
 338
 339     my $foodata = $c->forward('/foo');
 340     $c->forward('index');
 341     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 342     $c->forward('View::TT');
 343
 344 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 345 an C<< eval { } >> around the call (actually
 346 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 347 all 'dies' within the called action. If you want C<die> to propagate you
 348 need to do something like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 374
 375 =cut
 376
 377 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 378
 379 =head2 $c->detach( $action [, \@arguments ] )
 380
 381 =head2 $c->detach( $class, $method, [, \@arguments ] )
 382
 383 =head2 $c->detach()
 384
 385 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 386 doesn't return to the previous action when processing is finished.
 387
 388 When called with no arguments it escapes the processing chain entirely.
 389
 390 =cut
 391
 392 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 393
 394 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 397
 398 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 399 but does a full dispatch, instead of just calling the new C<$action> /
 400 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 401 you go to are called, just like a new request.
 402
 403 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 404 This means, for example, that C<< $c->action >> methods such as
 405 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 406 L<reverse|Catalyst::Action/reverse> return information for the visited action
 407 when they are invoked within the visited action.  This is different from the
 408 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 409 continues to use the $c->action object from the caller action even when
 410 invoked from the callee.
 411
 412 C<< $c->stash >> is kept unchanged.
 413
 414 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 415 allows you to "wrap" another action, just as it would have been called by
 416 dispatching from a URL, while the analogous
 417 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 418 transfer control to another action as if it had been reached directly from a URL.
 419
 420 =cut
 421
 422 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 423
 424 =head2 $c->go( $action [, \@captures, \@arguments ] )
 425
 426 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 427
 428 The relationship between C<go> and
 429 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 430 the relationship between
 431 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 432 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 433 C<< $c->go >> will perform a full dispatch on the specified action or method,
 434 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 435 C<go> escapes the processing of the current request chain on completion, and
 436 does not return to its caller.
 437
 438 @arguments are arguments to the final destination of $action. @captures are
 439 arguments to the intermediate steps, if any, on the way to the final sub of
 440 $action.
 441
 442 =cut
 443
 444 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 445
 446 =head2 $c->response
 447
 448 =head2 $c->res
 449
 450 Returns the current L<Catalyst::Response> object, see there for details.
 451
 452 =head2 $c->stash
 453
 454 Returns a hashref to the stash, which may be used to store data and pass
 455 it between components during a request. You can also set hash keys by
 456 passing arguments. The stash is automatically sent to the view. The
 457 stash is cleared at the end of a request; it cannot be used for
 458 persistent storage (for this you must use a session; see
 459 L<Catalyst::Plugin::Session> for a complete system integrated with
 460 Catalyst).
 461
 462     $c->stash->{foo} = $bar;
 463     $c->stash( { moose => 'majestic', qux => 0 } );
 464     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 465
 466     # stash is automatically passed to the view for use in a template
 467     $c->forward( 'MyApp::View::TT' );
 468
 469 =cut
 470
 471 around stash => sub {
 472     my $orig = shift;
 473     my $c = shift;
 474     my $stash = $orig->($c);
 475     if (@_) {
 476         my $new_stash = @_ > 1 ? {@_} : $_[0];
 477         croak('stash takes a hash or hashref') unless ref $new_stash;
 478         foreach my $key ( keys %$new_stash ) {
 479           $stash->{$key} = $new_stash->{$key};
 480         }
 481     }
 482
 483     return $stash;
 484 };
 485
 486
 487 =head2 $c->error
 488
 489 =head2 $c->error($error, ...)
 490
 491 =head2 $c->error($arrayref)
 492
 493 Returns an arrayref containing error messages.  If Catalyst encounters an
 494 error while processing a request, it stores the error in $c->error.  This
 495 method should only be used to store fatal error messages.
 496
 497     my @error = @{ $c->error };
 498
 499 Add a new error.
 500
 501     $c->error('Something bad happened');
 502
 503 =cut
 504
 505 sub error {
 506     my $c = shift;
 507     if ( $_[0] ) {
 508         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 509         croak @$error unless ref $c;
 510         push @{ $c->{error} }, @$error;
 511     }
 512     elsif ( defined $_[0] ) { $c->{error} = undef }
 513     return $c->{error} || [];
 514 }
 515
 516
 517 =head2 $c->state
 518
 519 Contains the return value of the last executed action.
 520 Note that << $c->state >> operates in a scalar context which means that all
 521 values it returns are scalar.
 522
 523 =head2 $c->clear_errors
 524
 525 Clear errors.  You probably don't want to clear the errors unless you are
 526 implementing a custom error screen.
 527
 528 This is equivalent to running
 529
 530     $c->error(0);
 531
 532 =cut
 533
 534 sub clear_errors {
 535     my $c = shift;
 536     $c->error(0);
 537 }
 538
 539 sub _comp_search_prefixes {
 540     my $c = shift;
 541     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 542 }
 543
 544 # search components given a name and some prefixes
 545 sub _comp_names_search_prefixes {
 546     my ( $c, $name, @prefixes ) = @_;
 547     my $appclass = ref $c || $c;
 548     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 549     $filter = qr/$filter/; # Compile regex now rather than once per loop
 550
 551     my @components = map { $c->container->get_sub_container($_)->get_service_list } qw(controller view model);
 552
 553     # map the original component name to the sub part that we will search against
 554     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 555         grep { /$filter/ } @components;
 556
 557     # undef for a name will return all
 558     return keys %eligible if !defined $name;
 559
 560     my $query  = ref $name ? $name : qr/^$name$/i;
 561     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 562
 563     return @result if @result;
 564
 565     # if we were given a regexp to search against, we're done.
 566     return if ref $name;
 567
 568     # skip regexp fallback if configured
 569     return
 570         if $appclass->config->{disable_component_resolution_regex_fallback};
 571
 572     # regexp fallback
 573     $query  = qr/$name/i;
 574     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 575
 576     # no results? try against full names
 577     if( !@result ) {
 578         @result = grep { m{$query} } keys %eligible;
 579     }
 580
 581     # don't warn if we didn't find any results, it just might not exist
 582     if( @result ) {
 583         # Disgusting hack to work out correct method name
 584         my $warn_for = lc $prefixes[0];
 585         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 586            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 587            "component resolution is unreliable and unsafe.";
 588         my $short = $result[0];
 589         # remove the component namespace prefix
 590         $short =~ s/.*?(Model|Controller|View):://;
 591         my $shortmess = Carp::shortmess('');
 592         if ($shortmess =~ m#Catalyst/Plugin#) {
 593            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 594               "plugin's config";
 595         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 596            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 597               "component's config";
 598         } else {
 599            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 600               "but if you really wanted to search, pass in a regexp as the argument " .
 601               "like so: \$c->${warn_for}(qr/${name}/)";
 602         }
 603         $c->log->warn( "${msg}$shortmess" );
 604     }
 605
 606     return @result;
 607 }
 608
 609 # Find possible names for a prefix
 610 sub _comp_names {
 611     my ( $c, @prefixes ) = @_;
 612     my $appclass = ref $c || $c;
 613
 614     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 615
 616     my @names = map { s{$filter}{}; $_; }
 617         $c->_comp_names_search_prefixes( undef, @prefixes );
 618
 619     return @names;
 620 }
 621
 622 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 623 sub _filter_component {
 624     my ( $c, $comp, @args ) = @_;
 625
 626     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 627         return $comp->ACCEPT_CONTEXT( $c, @args );
 628     }
 629
 630     return $comp;
 631 }
 632
 633 =head2 COMPONENT ACCESSORS
 634
 635 =head2 $c->controller($name)
 636
 637 Gets a L<Catalyst::Controller> instance by name.
 638
 639     $c->controller('Foo')->do_stuff;
 640
 641 If the name is omitted, will return the controller for the dispatched
 642 action.
 643
 644 If you want to search for controllers, pass in a regexp as the argument.
 645
 646     # find all controllers that start with Foo
 647     my @foo_controllers = $c->controller(qr{^Foo});
 648
 649
 650 =cut
 651
 652 sub controller {
 653     my ( $c, $name, @args ) = @_;
 654     my $container = $c->container->get_sub_container('controller');
 655
 656     my $appclass = ref($c) || $c;
 657     if( $name ) {
 658         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 659             my $check = $appclass."::Controller::".$name;
 660             return $container->resolve(service => "$check", parameters => { context => \@args } )
 661                 if $container->has_service($check);
 662         }
 663         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 664         return map { $container->resolve(service => "$_", parameters => { context => \@args } ) } @result if ref $name;
 665     }
 666
 667     return $c->component( $c->action->class );
 668 }
 669
 670 =head2 $c->model($name)
 671
 672 Gets a L<Catalyst::Model> instance by name.
 673
 674     $c->model('Foo')->do_stuff;
 675
 676 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 677
 678 If the name is omitted, it will look for
 679  - a model object in $c->stash->{current_model_instance}, then
 680  - a model name in $c->stash->{current_model}, then
 681  - a config setting 'default_model', or
 682  - check if there is only one model, and return it if that's the case.
 683
 684 If you want to search for models, pass in a regexp as the argument.
 685
 686     # find all models that start with Foo
 687     my @foo_models = $c->model(qr{^Foo});
 688
 689 =cut
 690
 691 sub model {
 692     my ( $c, $name, @args ) = @_;
 693     my $appclass = ref($c) || $c;
 694     my $container = $c->container->get_sub_container('model');
 695
 696     if( $name ) {
 697         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 698             my $check = $appclass."::Model::".$name;
 699             return $container->resolve( service => "$check", parameters => { context => \@args } )
 700                 if $container->has_service($check);
 701         }
 702         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 703         return map { $container->resolve( service => "$_", parameters => { context => \@args } ) } @result if ref $name;
 704     }
 705
 706     if (ref $c) {
 707         return $c->stash->{current_model_instance}
 708           if $c->stash->{current_model_instance};
 709         return $c->model( $c->stash->{current_model} )
 710           if $c->stash->{current_model};
 711     }
 712     return $c->model( $appclass->config->{default_model} )
 713       if $appclass->config->{default_model};
 714
 715 # FIXME: will this still be mantained?
 716     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 717
 718     if( $rest ) {
 719         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 720         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 721         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 722         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 723         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 724     }
 725
 726     return $container->resolve( service => ref $comp, parameters => { context => \@args } );
 727 }
 728
 729
 730 =head2 $c->view($name)
 731
 732 Gets a L<Catalyst::View> instance by name.
 733
 734     $c->view('Foo')->do_stuff;
 735
 736 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 737
 738 If the name is omitted, it will look for
 739  - a view object in $c->stash->{current_view_instance}, then
 740  - a view name in $c->stash->{current_view}, then
 741  - a config setting 'default_view', or
 742  - check if there is only one view, and return it if that's the case.
 743
 744 If you want to search for views, pass in a regexp as the argument.
 745
 746     # find all views that start with Foo
 747     my @foo_views = $c->view(qr{^Foo});
 748
 749 =cut
 750
 751 sub view {
 752     my ( $c, $name, @args ) = @_;
 753     my $appclass = ref($c) || $c;
 754     my $container = $c->container->get_sub_container('view');
 755
 756     if( $name ) {
 757         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 758             my $check = $appclass."::View::".$name;
 759             if ($container->has_service($check)) {
 760                 return $container->resolve(service => $check, parameters => { context => \@args } );
 761             }
 762             else {
 763                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 764             }
 765         }
 766         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 767         return map { $container->resolve(service => "$_", parameters => { context => \@args } ) } @result if ref $name;
 768     }
 769
 770     if (ref $c) {
 771         return $c->stash->{current_view_instance}
 772           if $c->stash->{current_view_instance};
 773         return $c->view( $c->stash->{current_view} )
 774           if $c->stash->{current_view};
 775     }
 776     return $c->view( $appclass->config->{default_view} )
 777       if $appclass->config->{default_view};
 778
 779     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 780
 781     if( $rest ) {
 782         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 783         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 784         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 785         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 786         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 787     }
 788
 789     return $container->resolve( service => ref $comp, parameters => { context => \@args } );
 790 }
 791
 792 =head2 $c->controllers
 793
 794 Returns the available names which can be passed to $c->controller
 795
 796 =cut
 797
 798 sub controllers {
 799     my ( $c ) = @_;
 800     return $c->container->get_sub_container('controller')->get_service_list;
 801 }
 802
 803 =head2 $c->models
 804
 805 Returns the available names which can be passed to $c->model
 806
 807 =cut
 808
 809 sub models {
 810     my ( $c ) = @_;
 811     return $c->container->get_sub_container('model')->get_service_list;
 812 }
 813
 814
 815 =head2 $c->views
 816
 817 Returns the available names which can be passed to $c->view
 818
 819 =cut
 820
 821 sub views {
 822     my ( $c ) = @_;
 823     return $c->container->get_sub_container('view')->get_service_list;
 824 }
 825
 826 =head2 $c->comp($name)
 827
 828 =head2 $c->component($name)
 829
 830 Gets a component object by name. This method is not recommended,
 831 unless you want to get a specific component by full
 832 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 833 should be used instead.
 834
 835 If C<$name> is a regexp, a list of components matched against the full
 836 component name will be returned.
 837
 838 If Catalyst can't find a component by name, it will fallback to regex
 839 matching by default. To disable this behaviour set
 840 disable_component_resolution_regex_fallback to a true value.
 841
 842     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 843
 844 =cut
 845
 846 sub component {
 847     my ( $c, $name, @args ) = @_;
 848
 849     if( $name ) {
 850         my $comps = $c->components;
 851
 852         if( !ref $name ) {
 853             # is it the exact name?
 854             return $c->_filter_component( $comps->{ $name }, @args )
 855                        if exists $comps->{ $name };
 856
 857             # perhaps we just omitted "MyApp"?
 858             my $composed = ( ref $c || $c ) . "::${name}";
 859             return $c->_filter_component( $comps->{ $composed }, @args )
 860                        if exists $comps->{ $composed };
 861
 862             # search all of the models, views and controllers
 863             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 864             return $c->_filter_component( $comp, @args ) if $comp;
 865         }
 866
 867         return
 868             if $c->config->{disable_component_resolution_regex_fallback};
 869
 870         # This is here so $c->comp( '::M::' ) works
 871         my $query = ref $name ? $name : qr{$name}i;
 872
 873         my @result = grep { m{$query} } keys %{ $c->components };
 874         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 875
 876         if( $result[ 0 ] ) {
 877             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 878             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 879             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 880             return $c->_filter_component( $result[ 0 ], @args );
 881         }
 882
 883         # I would expect to return an empty list here, but that breaks back-compat
 884     }
 885
 886     # fallback
 887     return sort keys %{ $c->components };
 888 }
 889
 890 =head2 CLASS DATA AND HELPER CLASSES
 891
 892 =head2 $c->config
 893
 894 Returns or takes a hashref containing the application's configuration.
 895
 896     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 897
 898 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 899 like C<myapp.conf> in your applications home directory. See
 900 L<Catalyst::Plugin::ConfigLoader>.
 901
 902 =head3 Cascading configuration
 903
 904 The config method is present on all Catalyst components, and configuration
 905 will be merged when an application is started. Configuration loaded with
 906 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 907 followed by configuration in your top level C<MyApp> class. These two
 908 configurations are merged, and then configuration data whose hash key matches a
 909 component name is merged with configuration for that component.
 910
 911 The configuration for a component is then passed to the C<new> method when a
 912 component is constructed.
 913
 914 For example:
 915
 916     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 917     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 918
 919 will mean that C<MyApp::Model::Foo> receives the following data when
 920 constructed:
 921
 922     MyApp::Model::Foo->new({
 923         bar => 'baz',
 924         quux => 'frob',
 925         overrides => 'me',
 926     });
 927
 928 It's common practice to use a Moose attribute
 929 on the receiving component to access the config value.
 930
 931     package MyApp::Model::Foo;
 932
 933     use Moose;
 934
 935     # this attr will receive 'baz' at construction time
 936     has 'bar' => (
 937         is  => 'rw',
 938         isa => 'Str',
 939     );
 940
 941 You can then get the value 'baz' by calling $c->model('Foo')->bar
 942 (or $self->bar inside code in the model).
 943
 944 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 945 as a way of reading config within your code, as this B<will not> give you the
 946 correctly merged config back. You B<MUST> take the config values supplied to
 947 the constructor and use those instead.
 948
 949 =cut
 950
 951 around config => sub {
 952     my $orig = shift;
 953     my $c = shift;
 954
 955     croak('Setting config after setup has been run is not allowed.')
 956         if ( @_ and $c->setup_finished );
 957
 958     $c->$orig(@_);
 959 };
 960
 961 =head2 $c->log
 962
 963 Returns the logging object instance. Unless it is already set, Catalyst
 964 sets this up with a L<Catalyst::Log> object. To use your own log class,
 965 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 966 C<< __PACKAGE__->setup >>.
 967
 968  __PACKAGE__->log( MyLogger->new );
 969  __PACKAGE__->setup;
 970
 971 And later:
 972
 973     $c->log->info( 'Now logging with my own logger!' );
 974
 975 Your log class should implement the methods described in
 976 L<Catalyst::Log>.
 977
 978
 979 =head2 $c->debug
 980
 981 Returns 1 if debug mode is enabled, 0 otherwise.
 982
 983 You can enable debug mode in several ways:
 984
 985 =over
 986
 987 =item By calling myapp_server.pl with the -d flag
 988
 989 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 990
 991 =item The -Debug option in your MyApp.pm
 992
 993 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 994
 995 =back
 996
 997 The first three also set the log level to 'debug'.
 998
 999 Calling C<< $c->debug(1) >> has no effect.
1000
1001 =cut
1002
1003 sub debug { 0 }
1004
1005 =head2 $c->dispatcher
1006
1007 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1008
1009 =head2 $c->engine
1010
1011 Returns the engine instance. See L<Catalyst::Engine>.
1012
1013
1014 =head2 UTILITY METHODS
1015
1016 =head2 $c->path_to(@path)
1017
1018 Merges C<@path> with C<< $c->config->{home} >> and returns a
1019 L<Path::Class::Dir> object. Note you can usually use this object as
1020 a filename, but sometimes you will have to explicitly stringify it
1021 yourself by calling the C<< ->stringify >> method.
1022
1023 For example:
1024
1025     $c->path_to( 'db', 'sqlite.db' );
1026
1027 =cut
1028
1029 sub path_to {
1030     my ( $c, @path ) = @_;
1031     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1032     if ( -d $path ) { return $path }
1033     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1034 }
1035
1036 =head2 $c->plugin( $name, $class, @args )
1037
1038 Helper method for plugins. It creates a class data accessor/mutator and
1039 loads and instantiates the given class.
1040
1041     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1042
1043     $c->prototype->define_javascript_functions;
1044
1045 B<Note:> This method of adding plugins is deprecated. The ability
1046 to add plugins like this B<will be removed> in a Catalyst 5.81.
1047 Please do not use this functionality in new code.
1048
1049 =cut
1050
1051 sub plugin {
1052     my ( $class, $name, $plugin, @args ) = @_;
1053
1054     # See block comment in t/unit_core_plugin.t
1055     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1056
1057     $class->_register_plugin( $plugin, 1 );
1058
1059     eval { $plugin->import };
1060     $class->mk_classdata($name);
1061     my $obj;
1062     eval { $obj = $plugin->new(@args) };
1063
1064     if ($@) {
1065         Catalyst::Exception->throw( message =>
1066               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1067     }
1068
1069     $class->$name($obj);
1070     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1071       if $class->debug;
1072 }
1073
1074 =head2 MyApp->setup
1075
1076 Initializes the dispatcher and engine, loads any plugins, and loads the
1077 model, view, and controller components. You may also specify an array
1078 of plugins to load here, if you choose to not load them in the C<use
1079 Catalyst> line.
1080
1081     MyApp->setup;
1082     MyApp->setup( qw/-Debug/ );
1083
1084 =cut
1085
1086 sub setup {
1087     my ( $class, @arguments ) = @_;
1088     croak('Running setup more than once')
1089         if ( $class->setup_finished );
1090
1091     unless ( $class->isa('Catalyst') ) {
1092
1093         Catalyst::Exception->throw(
1094             message => qq/'$class' does not inherit from Catalyst/ );
1095     }
1096
1097     if ( $class->arguments ) {
1098         @arguments = ( @arguments, @{ $class->arguments } );
1099     }
1100
1101     # Process options
1102     my $flags = {};
1103
1104     foreach (@arguments) {
1105
1106         if (/^-Debug$/) {
1107             $flags->{log} =
1108               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1109         }
1110         elsif (/^-(\w+)=?(.*)$/) {
1111             $flags->{ lc $1 } = $2;
1112         }
1113         else {
1114             push @{ $flags->{plugins} }, $_;
1115         }
1116     }
1117
1118     $class->setup_config();
1119     $class->setup_home( delete $flags->{home} );
1120
1121     $class->setup_log( delete $flags->{log} );
1122     $class->setup_plugins( delete $flags->{plugins} );
1123     $class->setup_dispatcher( delete $flags->{dispatcher} );
1124     $class->setup_engine( delete $flags->{engine} );
1125     $class->setup_stats( delete $flags->{stats} );
1126
1127     for my $flag ( sort keys %{$flags} ) {
1128
1129         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1130             &$code( $class, delete $flags->{$flag} );
1131         }
1132         else {
1133             $class->log->warn(qq/Unknown flag "$flag"/);
1134         }
1135     }
1136
1137     eval { require Catalyst::Devel; };
1138     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1139         $class->log->warn(<<"EOF");
1140 You are running an old script!
1141
1142   Please update by running (this will overwrite existing files):
1143     catalyst.pl -force -scripts $class
1144
1145   or (this will not overwrite existing files):
1146     catalyst.pl -scripts $class
1147
1148 EOF
1149     }
1150
1151     if ( $class->debug ) {
1152         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1153
1154         if (@plugins) {
1155             my $column_width = Catalyst::Utils::term_width() - 6;
1156             my $t = Text::SimpleTable->new($column_width);
1157             $t->row($_) for @plugins;
1158             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1159         }
1160
1161         my $dispatcher = $class->dispatcher;
1162         my $engine     = $class->engine;
1163         my $home       = $class->config->{home};
1164
1165         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1166         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1167
1168         $home
1169           ? ( -d $home )
1170           ? $class->log->debug(qq/Found home "$home"/)
1171           : $class->log->debug(qq/Home "$home" doesn't exist/)
1172           : $class->log->debug(q/Couldn't find home/);
1173     }
1174
1175     # Call plugins setup, this is stupid and evil.
1176     # Also screws C3 badly on 5.10, hack to avoid.
1177     {
1178         no warnings qw/redefine/;
1179         local *setup = sub { };
1180         $class->setup unless $Catalyst::__AM_RESTARTING;
1181     }
1182
1183     # Initialize our data structure
1184     $class->components( {} );
1185
1186     $class->setup_components;
1187
1188     if ( $class->debug ) {
1189         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1190         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1191         for my $comp ( sort keys %{ $class->components } ) {
1192             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1193             $t->row( $comp, $type );
1194         }
1195         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1196           if ( keys %{ $class->components } );
1197     }
1198
1199     # Add our self to components, since we are also a component
1200     if( $class->isa('Catalyst::Controller') ){
1201       $class->components->{$class} = $class;
1202     }
1203
1204     $class->setup_actions;
1205
1206     if ( $class->debug ) {
1207         my $name = $class->config->{name} || 'Application';
1208         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1209     }
1210
1211     # Make sure that the application class becomes immutable at this point,
1212     B::Hooks::EndOfScope::on_scope_end {
1213         return if $@;
1214         my $meta = Class::MOP::get_metaclass_by_name($class);
1215         if (
1216             $meta->is_immutable
1217             && ! { $meta->immutable_options }->{replace_constructor}
1218             && (
1219                    $class->isa('Class::Accessor::Fast')
1220                 || $class->isa('Class::Accessor')
1221             )
1222         ) {
1223             warn "You made your application class ($class) immutable, "
1224                 . "but did not inline the\nconstructor. "
1225                 . "This will break catalyst, as your app \@ISA "
1226                 . "Class::Accessor(::Fast)?\nPlease pass "
1227                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1228         }
1229         $meta->make_immutable(
1230             replace_constructor => 1,
1231         ) unless $meta->is_immutable;
1232     };
1233
1234     if ($class->config->{case_sensitive}) {
1235         $class->log->warn($class . "->config->{case_sensitive} is set.");
1236         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1237     }
1238
1239     $class->setup_finalize;
1240     # Should be the last thing we do so that user things hooking
1241     # setup_finalize can log..
1242     $class->log->_flush() if $class->log->can('_flush');
1243     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1244 }
1245
1246 =head2 $app->setup_finalize
1247
1248 A hook to attach modifiers to. This method does not do anything except set the
1249 C<setup_finished> accessor.
1250
1251 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1252
1253 Example:
1254
1255     after setup_finalize => sub {
1256         my $app = shift;
1257
1258         ## do stuff here..
1259     };
1260
1261 =cut
1262
1263 sub setup_finalize {
1264     my ($class) = @_;
1265     $class->setup_finished(1);
1266 }
1267
1268 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1269
1270 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1271
1272 Constructs an absolute L<URI> object based on the application root, the
1273 provided path, and the additional arguments and query parameters provided.
1274 When used as a string, provides a textual URI.  If you need more flexibility
1275 than this (i.e. the option to provide relative URIs etc.) see
1276 L<Catalyst::Plugin::SmartURI>.
1277
1278 If no arguments are provided, the URI for the current action is returned.
1279 To return the current action and also provide @args, use
1280 C<< $c->uri_for( $c->action, @args ) >>.
1281
1282 If the first argument is a string, it is taken as a public URI path relative
1283 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1284 relative to the application root (if it does). It is then merged with
1285 C<< $c->request->base >>; any C<@args> are appended as additional path
1286 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1287
1288 If the first argument is a L<Catalyst::Action> it represents an action which
1289 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1290 optional C<\@captures> argument (an arrayref) allows passing the captured
1291 variables that are needed to fill in the paths of Chained and Regex actions;
1292 once the path is resolved, C<uri_for> continues as though a path was
1293 provided, appending any arguments or parameters and creating an absolute
1294 URI.
1295
1296 The captures for the current request can be found in
1297 C<< $c->request->captures >>, and actions can be resolved using
1298 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1299 path, use C<< $c->uri_for_action >> instead.
1300
1301   # Equivalent to $c->req->uri
1302   $c->uri_for($c->action, $c->req->captures,
1303       @{ $c->req->args }, $c->req->params);
1304
1305   # For the Foo action in the Bar controller
1306   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1307
1308   # Path to a static resource
1309   $c->uri_for('/static/images/logo.png');
1310
1311 =cut
1312
1313 sub uri_for {
1314     my ( $c, $path, @args ) = @_;
1315
1316     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1317         $path = $path->path_prefix;
1318         $path =~ s{/+\z}{};
1319         $path .= '/';
1320     }
1321
1322     undef($path) if (defined $path && $path eq '');
1323
1324     my $params =
1325       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1326
1327     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1328     foreach my $arg (@args) {
1329         utf8::encode($arg) if utf8::is_utf8($arg);
1330         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1331     }
1332
1333     if ( blessed($path) ) { # action object
1334         s|/|%2F|g for @args;
1335         my $captures = [ map { s|/|%2F|g; $_; }
1336                         ( scalar @args && ref $args[0] eq 'ARRAY'
1337                          ? @{ shift(@args) }
1338                          : ()) ];
1339
1340         foreach my $capture (@$captures) {
1341             utf8::encode($capture) if utf8::is_utf8($capture);
1342             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1343         }
1344
1345         my $action = $path;
1346         $path = $c->dispatcher->uri_for_action($action, $captures);
1347         if (not defined $path) {
1348             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1349                 if $c->debug;
1350             return undef;
1351         }
1352         $path = '/' if $path eq '';
1353     }
1354
1355     unshift(@args, $path);
1356
1357     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1358         my $namespace = $c->namespace;
1359         if (defined $path) { # cheesy hack to handle path '../foo'
1360            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1361         }
1362         unshift(@args, $namespace || '');
1363     }
1364
1365     # join args with '/', or a blank string
1366     my $args = join('/', grep { defined($_) } @args);
1367     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1368     $args =~ s!^/+!!;
1369     my $base = $c->req->base;
1370     my $class = ref($base);
1371     $base =~ s{(?<!/)$}{/};
1372
1373     my $query = '';
1374
1375     if (my @keys = keys %$params) {
1376       # somewhat lifted from URI::_query's query_form
1377       $query = '?'.join('&', map {
1378           my $val = $params->{$_};
1379           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1380           s/ /+/g;
1381           my $key = $_;
1382           $val = '' unless defined $val;
1383           (map {
1384               my $param = "$_";
1385               utf8::encode( $param ) if utf8::is_utf8($param);
1386               # using the URI::Escape pattern here so utf8 chars survive
1387               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1388               $param =~ s/ /+/g;
1389               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1390       } @keys);
1391     }
1392
1393     my $res = bless(\"${base}${args}${query}", $class);
1394     $res;
1395 }
1396
1397 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1398
1399 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1400
1401 =over
1402
1403 =item $path
1404
1405 A private path to the Catalyst action you want to create a URI for.
1406
1407 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1408 >> and passing the resulting C<$action> and the remaining arguments to C<<
1409 $c->uri_for >>.
1410
1411 You can also pass in a Catalyst::Action object, in which case it is passed to
1412 C<< $c->uri_for >>.
1413
1414 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1415
1416 For example, if the action looks like:
1417
1418  package MyApp::Controller::Users;
1419
1420  sub lst : Path('the-list') {}
1421
1422 You can use:
1423
1424  $c->uri_for_action('/users/lst')
1425
1426 and it will create the URI /users/the-list.
1427
1428 =back
1429
1430 =cut
1431
1432 sub uri_for_action {
1433     my ( $c, $path, @args ) = @_;
1434     my $action = blessed($path)
1435       ? $path
1436       : $c->dispatcher->get_action_by_path($path);
1437     unless (defined $action) {
1438       croak "Can't find action for path '$path'";
1439     }
1440     return $c->uri_for( $action, @args );
1441 }
1442
1443 =head2 $c->welcome_message
1444
1445 Returns the Catalyst welcome HTML page.
1446
1447 =cut
1448
1449 sub welcome_message {
1450     my $c      = shift;
1451     my $name   = $c->config->{name};
1452     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1453     my $prefix = Catalyst::Utils::appprefix( ref $c );
1454     $c->response->content_type('text/html; charset=utf-8');
1455     return <<"EOF";
1456 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1457     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1458 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1459     <head>
1460     <meta http-equiv="Content-Language" content="en" />
1461     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1462         <title>$name on Catalyst $VERSION</title>
1463         <style type="text/css">
1464             body {
1465                 color: #000;
1466                 background-color: #eee;
1467             }
1468             div#content {
1469                 width: 640px;
1470                 margin-left: auto;
1471                 margin-right: auto;
1472                 margin-top: 10px;
1473                 margin-bottom: 10px;
1474                 text-align: left;
1475                 background-color: #ccc;
1476                 border: 1px solid #aaa;
1477             }
1478             p, h1, h2 {
1479                 margin-left: 20px;
1480                 margin-right: 20px;
1481                 font-family: verdana, tahoma, sans-serif;
1482             }
1483             a {
1484                 font-family: verdana, tahoma, sans-serif;
1485             }
1486             :link, :visited {
1487                     text-decoration: none;
1488                     color: #b00;
1489                     border-bottom: 1px dotted #bbb;
1490             }
1491             :link:hover, :visited:hover {
1492                     color: #555;
1493             }
1494             div#topbar {
1495                 margin: 0px;
1496             }
1497             pre {
1498                 margin: 10px;
1499                 padding: 8px;
1500             }
1501             div#answers {
1502                 padding: 8px;
1503                 margin: 10px;
1504                 background-color: #fff;
1505                 border: 1px solid #aaa;
1506             }
1507             h1 {
1508                 font-size: 0.9em;
1509                 font-weight: normal;
1510                 text-align: center;
1511             }
1512             h2 {
1513                 font-size: 1.0em;
1514             }
1515             p {
1516                 font-size: 0.9em;
1517             }
1518             p img {
1519                 float: right;
1520                 margin-left: 10px;
1521             }
1522             span#appname {
1523                 font-weight: bold;
1524                 font-size: 1.6em;
1525             }
1526         </style>
1527     </head>
1528     <body>
1529         <div id="content">
1530             <div id="topbar">
1531                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1532                     $VERSION</h1>
1533              </div>
1534              <div id="answers">
1535                  <p>
1536                  <img src="$logo" alt="Catalyst Logo" />
1537                  </p>
1538                  <p>Welcome to the  world of Catalyst.
1539                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1540                     framework will make web development something you had
1541                     never expected it to be: Fun, rewarding, and quick.</p>
1542                  <h2>What to do now?</h2>
1543                  <p>That really depends  on what <b>you</b> want to do.
1544                     We do, however, provide you with a few starting points.</p>
1545                  <p>If you want to jump right into web development with Catalyst
1546                     you might want to start with a tutorial.</p>
1547 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1548 </pre>
1549 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1550 <pre>
1551 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1552 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1553 </code></pre>
1554                  <h2>What to do next?</h2>
1555                  <p>Next it's time to write an actual application. Use the
1556                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1557                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1558                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1559                     they can save you a lot of work.</p>
1560                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1561                     <p>Also, be sure to check out the vast and growing
1562                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1563                     you are likely to find what you need there.
1564                     </p>
1565
1566                  <h2>Need help?</h2>
1567                  <p>Catalyst has a very active community. Here are the main places to
1568                     get in touch with us.</p>
1569                  <ul>
1570                      <li>
1571                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1572                      </li>
1573                      <li>
1574                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1575                      </li>
1576                      <li>
1577                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1578                      </li>
1579                  </ul>
1580                  <h2>In conclusion</h2>
1581                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1582                     as we enjoyed making it. Please contact us if you have ideas
1583                     for improvement or other feedback.</p>
1584              </div>
1585          </div>
1586     </body>
1587 </html>
1588 EOF
1589 }
1590
1591 =head1 INTERNAL METHODS
1592
1593 These methods are not meant to be used by end users.
1594
1595 =head2 $c->components
1596
1597 Returns a hash of components.
1598
1599 =cut
1600
1601 around components => sub {
1602     my $orig  = shift;
1603     my $class = shift;
1604     my $comps = shift;
1605
1606     return $class->$orig if ( !$comps );
1607
1608 # FIXME: should this ugly kludge exist?
1609     $class->setup_config unless defined $class->container;
1610
1611 # FIXME: should there be a warning here, not to use this accessor to create the components?
1612     my $components = {};
1613
1614     my $containers;
1615     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
1616
1617     for my $component ( keys %$comps ) {
1618         $components->{ $component } = $comps->{$component};
1619
1620         my ($type, $name) = _get_component_type_name($component);
1621
1622 # FIXME: shouldn't the service name be $name?
1623         $containers->{$type}->add_service(Catalyst::BlockInjection->new( name => $component, block => sub { return $class->setup_component($component) } ));
1624     }
1625
1626     return $class->$orig($components);
1627 };
1628
1629 =head2 $c->context_class
1630
1631 Returns or sets the context class.
1632
1633 =head2 $c->counter
1634
1635 Returns a hashref containing coderefs and execution counts (needed for
1636 deep recursion detection).
1637
1638 =head2 $c->depth
1639
1640 Returns the number of actions on the current internal execution stack.
1641
1642 =head2 $c->dispatch
1643
1644 Dispatches a request to actions.
1645
1646 =cut
1647
1648 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1649
1650 =head2 $c->dispatcher_class
1651
1652 Returns or sets the dispatcher class.
1653
1654 =head2 $c->dump_these
1655
1656 Returns a list of 2-element array references (name, structure) pairs
1657 that will be dumped on the error page in debug mode.
1658
1659 =cut
1660
1661 sub dump_these {
1662     my $c = shift;
1663     [ Request => $c->req ],
1664     [ Response => $c->res ],
1665     [ Stash => $c->stash ],
1666     [ Config => $c->config ];
1667 }
1668
1669 =head2 $c->engine_class
1670
1671 Returns or sets the engine class.
1672
1673 =head2 $c->execute( $class, $coderef )
1674
1675 Execute a coderef in given class and catch exceptions. Errors are available
1676 via $c->error.
1677
1678 =cut
1679
1680 sub execute {
1681     my ( $c, $class, $code ) = @_;
1682     $class = $c->component($class) || $class;
1683     $c->state(0);
1684
1685     if ( $c->depth >= $RECURSION ) {
1686         my $action = $code->reverse();
1687         $action = "/$action" unless $action =~ /->/;
1688         my $error = qq/Deep recursion detected calling "${action}"/;
1689         $c->log->error($error);
1690         $c->error($error);
1691         $c->state(0);
1692         return $c->state;
1693     }
1694
1695     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1696
1697     push( @{ $c->stack }, $code );
1698
1699     no warnings 'recursion';
1700     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1701     #      I have no idea how, ergo $ret (which appears to fix the issue)
1702     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1703
1704     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1705
1706     my $last = pop( @{ $c->stack } );
1707
1708     if ( my $error = $@ ) {
1709         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1710             $error->rethrow if $c->depth > 1;
1711         }
1712         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1713             $error->rethrow if $c->depth > 0;
1714         }
1715         else {
1716             unless ( ref $error ) {
1717                 no warnings 'uninitialized';
1718                 chomp $error;
1719                 my $class = $last->class;
1720                 my $name  = $last->name;
1721                 $error = qq/Caught exception in $class->$name "$error"/;
1722             }
1723             $c->error($error);
1724         }
1725         $c->state(0);
1726     }
1727     return $c->state;
1728 }
1729
1730 sub _stats_start_execute {
1731     my ( $c, $code ) = @_;
1732     my $appclass = ref($c) || $c;
1733     return if ( ( $code->name =~ /^_.*/ )
1734         && ( !$appclass->config->{show_internal_actions} ) );
1735
1736     my $action_name = $code->reverse();
1737     $c->counter->{$action_name}++;
1738
1739     my $action = $action_name;
1740     $action = "/$action" unless $action =~ /->/;
1741
1742     # determine if the call was the result of a forward
1743     # this is done by walking up the call stack and looking for a calling
1744     # sub of Catalyst::forward before the eval
1745     my $callsub = q{};
1746     for my $index ( 2 .. 11 ) {
1747         last
1748         if ( ( caller($index) )[0] eq 'Catalyst'
1749             && ( caller($index) )[3] eq '(eval)' );
1750
1751         if ( ( caller($index) )[3] =~ /forward$/ ) {
1752             $callsub = ( caller($index) )[3];
1753             $action  = "-> $action";
1754             last;
1755         }
1756     }
1757
1758     my $uid = $action_name . $c->counter->{$action_name};
1759
1760     # is this a root-level call or a forwarded call?
1761     if ( $callsub =~ /forward$/ ) {
1762         my $parent = $c->stack->[-1];
1763
1764         # forward, locate the caller
1765         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1766             $c->stats->profile(
1767                 begin  => $action,
1768                 parent => "$parent" . $c->counter->{"$parent"},
1769                 uid    => $uid,
1770             );
1771         }
1772         else {
1773
1774             # forward with no caller may come from a plugin
1775             $c->stats->profile(
1776                 begin => $action,
1777                 uid   => $uid,
1778             );
1779         }
1780     }
1781     else {
1782
1783         # root-level call
1784         $c->stats->profile(
1785             begin => $action,
1786             uid   => $uid,
1787         );
1788     }
1789     return $action;
1790
1791 }
1792
1793 sub _stats_finish_execute {
1794     my ( $c, $info ) = @_;
1795     $c->stats->profile( end => $info );
1796 }
1797
1798 =head2 $c->finalize
1799
1800 Finalizes the request.
1801
1802 =cut
1803
1804 sub finalize {
1805     my $c = shift;
1806
1807     for my $error ( @{ $c->error } ) {
1808         $c->log->error($error);
1809     }
1810
1811     # Allow engine to handle finalize flow (for POE)
1812     my $engine = $c->engine;
1813     if ( my $code = $engine->can('finalize') ) {
1814         $engine->$code($c);
1815     }
1816     else {
1817
1818         $c->finalize_uploads;
1819
1820         # Error
1821         if ( $#{ $c->error } >= 0 ) {
1822             $c->finalize_error;
1823         }
1824
1825         $c->finalize_headers;
1826
1827         # HEAD request
1828         if ( $c->request->method eq 'HEAD' ) {
1829             $c->response->body('');
1830         }
1831
1832         $c->finalize_body;
1833     }
1834
1835     $c->log_response;
1836
1837     if ($c->use_stats) {
1838         my $elapsed = sprintf '%f', $c->stats->elapsed;
1839         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1840         $c->log->info(
1841             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1842     }
1843
1844     return $c->response->status;
1845 }
1846
1847 =head2 $c->finalize_body
1848
1849 Finalizes body.
1850
1851 =cut
1852
1853 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1854
1855 =head2 $c->finalize_cookies
1856
1857 Finalizes cookies.
1858
1859 =cut
1860
1861 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1862
1863 =head2 $c->finalize_error
1864
1865 Finalizes error.
1866
1867 =cut
1868
1869 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1870
1871 =head2 $c->finalize_headers
1872
1873 Finalizes headers.
1874
1875 =cut
1876
1877 sub finalize_headers {
1878     my $c = shift;
1879
1880     my $response = $c->response; #accessor calls can add up?
1881
1882     # Check if we already finalized headers
1883     return if $response->finalized_headers;
1884
1885     # Handle redirects
1886     if ( my $location = $response->redirect ) {
1887         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1888         $response->header( Location => $location );
1889
1890         if ( !$response->has_body ) {
1891             # Add a default body if none is already present
1892             $response->body(
1893                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1894             );
1895         }
1896     }
1897
1898     # Content-Length
1899     if ( defined $response->body && length $response->body && !$response->content_length ) {
1900
1901         # get the length from a filehandle
1902         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1903         {
1904             my $stat = stat $response->body;
1905             if ( $stat && $stat->size > 0 ) {
1906                 $response->content_length( $stat->size );
1907             }
1908             else {
1909                 $c->log->warn('Serving filehandle without a content-length');
1910             }
1911         }
1912         else {
1913             # everything should be bytes at this point, but just in case
1914             $response->content_length( length( $response->body ) );
1915         }
1916     }
1917
1918     # Errors
1919     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1920         $response->headers->remove_header("Content-Length");
1921         $response->body('');
1922     }
1923
1924     $c->finalize_cookies;
1925
1926     $c->engine->finalize_headers( $c, @_ );
1927
1928     # Done
1929     $response->finalized_headers(1);
1930 }
1931
1932 =head2 $c->finalize_output
1933
1934 An alias for finalize_body.
1935
1936 =head2 $c->finalize_read
1937
1938 Finalizes the input after reading is complete.
1939
1940 =cut
1941
1942 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1943
1944 =head2 $c->finalize_uploads
1945
1946 Finalizes uploads. Cleans up any temporary files.
1947
1948 =cut
1949
1950 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1951
1952 =head2 $c->get_action( $action, $namespace )
1953
1954 Gets an action in a given namespace.
1955
1956 =cut
1957
1958 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1959
1960 =head2 $c->get_actions( $action, $namespace )
1961
1962 Gets all actions of a given name in a namespace and all parent
1963 namespaces.
1964
1965 =cut
1966
1967 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1968
1969 =head2 $app->handle_request( @arguments )
1970
1971 Called to handle each HTTP request.
1972
1973 =cut
1974
1975 sub handle_request {
1976     my ( $class, @arguments ) = @_;
1977
1978     # Always expect worst case!
1979     my $status = -1;
1980     eval {
1981         if ($class->debug) {
1982             my $secs = time - $START || 1;
1983             my $av = sprintf '%.3f', $COUNT / $secs;
1984             my $time = localtime time;
1985             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1986         }
1987
1988         my $c = $class->prepare(@arguments);
1989         $c->dispatch;
1990         $status = $c->finalize;
1991     };
1992
1993     if ( my $error = $@ ) {
1994         chomp $error;
1995         $class->log->error(qq/Caught exception in engine "$error"/);
1996     }
1997
1998     $COUNT++;
1999
2000     if(my $coderef = $class->log->can('_flush')){
2001         $class->log->$coderef();
2002     }
2003     return $status;
2004 }
2005
2006 =head2 $c->prepare( @arguments )
2007
2008 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2009 etc.).
2010
2011 =cut
2012
2013 sub prepare {
2014     my ( $class, @arguments ) = @_;
2015
2016     # XXX
2017     # After the app/ctxt split, this should become an attribute based on something passed
2018     # into the application.
2019     $class->context_class( ref $class || $class ) unless $class->context_class;
2020
2021     my $c = $class->context_class->new({});
2022
2023     # For on-demand data
2024     $c->request->_context($c);
2025     $c->response->_context($c);
2026
2027     #surely this is not the most efficient way to do things...
2028     $c->stats($class->stats_class->new)->enable($c->use_stats);
2029     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2030         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2031     }
2032
2033     #XXX reuse coderef from can
2034     # Allow engine to direct the prepare flow (for POE)
2035     if ( $c->engine->can('prepare') ) {
2036         $c->engine->prepare( $c, @arguments );
2037     }
2038     else {
2039         $c->prepare_request(@arguments);
2040         $c->prepare_connection;
2041         $c->prepare_query_parameters;
2042         $c->prepare_headers;
2043         $c->prepare_cookies;
2044         $c->prepare_path;
2045
2046         # Prepare the body for reading, either by prepare_body
2047         # or the user, if they are using $c->read
2048         $c->prepare_read;
2049
2050         # Parse the body unless the user wants it on-demand
2051         unless ( ref($c)->config->{parse_on_demand} ) {
2052             $c->prepare_body;
2053         }
2054     }
2055
2056     my $method  = $c->req->method  || '';
2057     my $path    = $c->req->path;
2058     $path       = '/' unless length $path;
2059     my $address = $c->req->address || '';
2060
2061     $c->log_request;
2062
2063     $c->prepare_action;
2064
2065     return $c;
2066 }
2067
2068 =head2 $c->prepare_action
2069
2070 Prepares action. See L<Catalyst::Dispatcher>.
2071
2072 =cut
2073
2074 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2075
2076 =head2 $c->prepare_body
2077
2078 Prepares message body.
2079
2080 =cut
2081
2082 sub prepare_body {
2083     my $c = shift;
2084
2085     return if $c->request->_has_body;
2086
2087     # Initialize on-demand data
2088     $c->engine->prepare_body( $c, @_ );
2089     $c->prepare_parameters;
2090     $c->prepare_uploads;
2091 }
2092
2093 =head2 $c->prepare_body_chunk( $chunk )
2094
2095 Prepares a chunk of data before sending it to L<HTTP::Body>.
2096
2097 See L<Catalyst::Engine>.
2098
2099 =cut
2100
2101 sub prepare_body_chunk {
2102     my $c = shift;
2103     $c->engine->prepare_body_chunk( $c, @_ );
2104 }
2105
2106 =head2 $c->prepare_body_parameters
2107
2108 Prepares body parameters.
2109
2110 =cut
2111
2112 sub prepare_body_parameters {
2113     my $c = shift;
2114     $c->engine->prepare_body_parameters( $c, @_ );
2115 }
2116
2117 =head2 $c->prepare_connection
2118
2119 Prepares connection.
2120
2121 =cut
2122
2123 sub prepare_connection {
2124     my $c = shift;
2125     $c->engine->prepare_connection( $c, @_ );
2126 }
2127
2128 =head2 $c->prepare_cookies
2129
2130 Prepares cookies.
2131
2132 =cut
2133
2134 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2135
2136 =head2 $c->prepare_headers
2137
2138 Prepares headers.
2139
2140 =cut
2141
2142 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2143
2144 =head2 $c->prepare_parameters
2145
2146 Prepares parameters.
2147
2148 =cut
2149
2150 sub prepare_parameters {
2151     my $c = shift;
2152     $c->prepare_body_parameters;
2153     $c->engine->prepare_parameters( $c, @_ );
2154 }
2155
2156 =head2 $c->prepare_path
2157
2158 Prepares path and base.
2159
2160 =cut
2161
2162 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2163
2164 =head2 $c->prepare_query_parameters
2165
2166 Prepares query parameters.
2167
2168 =cut
2169
2170 sub prepare_query_parameters {
2171     my $c = shift;
2172
2173     $c->engine->prepare_query_parameters( $c, @_ );
2174 }
2175
2176 =head2 $c->log_request
2177
2178 Writes information about the request to the debug logs.  This includes:
2179
2180 =over 4
2181
2182 =item * Request method, path, and remote IP address
2183
2184 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2185
2186 =item * Request parameters
2187
2188 =item * File uploads
2189
2190 =back
2191
2192 =cut
2193
2194 sub log_request {
2195     my $c = shift;
2196
2197     return unless $c->debug;
2198
2199     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2200     my $request = $dump->[1];
2201
2202     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2203     $method ||= '';
2204     $path = '/' unless length $path;
2205     $address ||= '';
2206     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2207
2208     $c->log_request_headers($request->headers);
2209
2210     if ( my $keywords = $request->query_keywords ) {
2211         $c->log->debug("Query keywords are: $keywords");
2212     }
2213
2214     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2215
2216     $c->log_request_uploads($request);
2217 }
2218
2219 =head2 $c->log_response
2220
2221 Writes information about the response to the debug logs by calling
2222 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2223
2224 =cut
2225
2226 sub log_response {
2227     my $c = shift;
2228
2229     return unless $c->debug;
2230
2231     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2232     my $response = $dump->[1];
2233
2234     $c->log_response_status_line($response);
2235     $c->log_response_headers($response->headers);
2236 }
2237
2238 =head2 $c->log_response_status_line($response)
2239
2240 Writes one line of information about the response to the debug logs.  This includes:
2241
2242 =over 4
2243
2244 =item * Response status code
2245
2246 =item * Content-Type header (if present)
2247
2248 =item * Content-Length header (if present)
2249
2250 =back
2251
2252 =cut
2253
2254 sub log_response_status_line {
2255     my ($c, $response) = @_;
2256
2257     $c->log->debug(
2258         sprintf(
2259             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2260             $response->status                            || 'unknown',
2261             $response->headers->header('Content-Type')   || 'unknown',
2262             $response->headers->header('Content-Length') || 'unknown'
2263         )
2264     );
2265 }
2266
2267 =head2 $c->log_response_headers($headers);
2268
2269 Hook method which can be wrapped by plugins to log the responseheaders.
2270 No-op in the default implementation.
2271
2272 =cut
2273
2274 sub log_response_headers {}
2275
2276 =head2 $c->log_request_parameters( query => {}, body => {} )
2277
2278 Logs request parameters to debug logs
2279
2280 =cut
2281
2282 sub log_request_parameters {
2283     my $c          = shift;
2284     my %all_params = @_;
2285
2286     return unless $c->debug;
2287
2288     my $column_width = Catalyst::Utils::term_width() - 44;
2289     foreach my $type (qw(query body)) {
2290         my $params = $all_params{$type};
2291         next if ! keys %$params;
2292         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2293         for my $key ( sort keys %$params ) {
2294             my $param = $params->{$key};
2295             my $value = defined($param) ? $param : '';
2296             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2297         }
2298         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2299     }
2300 }
2301
2302 =head2 $c->log_request_uploads
2303
2304 Logs file uploads included in the request to the debug logs.
2305 The parameter name, filename, file type, and file size are all included in
2306 the debug logs.
2307
2308 =cut
2309
2310 sub log_request_uploads {
2311     my $c = shift;
2312     my $request = shift;
2313     return unless $c->debug;
2314     my $uploads = $request->uploads;
2315     if ( keys %$uploads ) {
2316         my $t = Text::SimpleTable->new(
2317             [ 12, 'Parameter' ],
2318             [ 26, 'Filename' ],
2319             [ 18, 'Type' ],
2320             [ 9,  'Size' ]
2321         );
2322         for my $key ( sort keys %$uploads ) {
2323             my $upload = $uploads->{$key};
2324             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2325                 $t->row( $key, $u->filename, $u->type, $u->size );
2326             }
2327         }
2328         $c->log->debug( "File Uploads are:\n" . $t->draw );
2329     }
2330 }
2331
2332 =head2 $c->log_request_headers($headers);
2333
2334 Hook method which can be wrapped by plugins to log the request headers.
2335 No-op in the default implementation.
2336
2337 =cut
2338
2339 sub log_request_headers {}
2340
2341 =head2 $c->log_headers($type => $headers)
2342
2343 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2344
2345 =cut
2346
2347 sub log_headers {
2348     my $c       = shift;
2349     my $type    = shift;
2350     my $headers = shift;    # an HTTP::Headers instance
2351
2352     return unless $c->debug;
2353
2354     my $column_width = Catalyst::Utils::term_width() - 28;
2355     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2356     $headers->scan(
2357         sub {
2358             my ( $name, $value ) = @_;
2359             $t->row( $name, $value );
2360         }
2361     );
2362     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2363 }
2364
2365
2366 =head2 $c->prepare_read
2367
2368 Prepares the input for reading.
2369
2370 =cut
2371
2372 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2373
2374 =head2 $c->prepare_request
2375
2376 Prepares the engine request.
2377
2378 =cut
2379
2380 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2381
2382 =head2 $c->prepare_uploads
2383
2384 Prepares uploads.
2385
2386 =cut
2387
2388 sub prepare_uploads {
2389     my $c = shift;
2390
2391     $c->engine->prepare_uploads( $c, @_ );
2392 }
2393
2394 =head2 $c->prepare_write
2395
2396 Prepares the output for writing.
2397
2398 =cut
2399
2400 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2401
2402 =head2 $c->request_class
2403
2404 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2405
2406 =head2 $c->response_class
2407
2408 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2409
2410 =head2 $c->read( [$maxlength] )
2411
2412 Reads a chunk of data from the request body. This method is designed to
2413 be used in a while loop, reading C<$maxlength> bytes on every call.
2414 C<$maxlength> defaults to the size of the request if not specified.
2415
2416 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2417 directly.
2418
2419 Warning: If you use read(), Catalyst will not process the body,
2420 so you will not be able to access POST parameters or file uploads via
2421 $c->request.  You must handle all body parsing yourself.
2422
2423 =cut
2424
2425 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2426
2427 =head2 $c->run
2428
2429 Starts the engine.
2430
2431 =cut
2432
2433 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2434
2435 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2436
2437 Sets an action in a given namespace.
2438
2439 =cut
2440
2441 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2442
2443 =head2 $c->setup_actions($component)
2444
2445 Sets up actions for a component.
2446
2447 =cut
2448
2449 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2450
2451 =head2 $c->setup_config
2452
2453 =cut
2454
2455 sub setup_config {
2456     my $class = shift;
2457
2458     my %args = %{ $class->config || {} };
2459
2460     my @container_classes = ( "${class}::Container", 'Catalyst::Container');
2461     unshift @container_classes, delete $args{container_class} if exists $args{container_class};
2462
2463     my $container_class = Class::MOP::load_first_existing_class(@container_classes);
2464
2465     my $container = $container_class->new( %args, name => "$class" );
2466     $class->container($container);
2467
2468     my $config = $container->resolve(service => 'config');
2469     $class->config($config);
2470     $class->finalize_config; # back-compat
2471 }
2472
2473 =head $c->finalize_config
2474
2475 =cut
2476
2477 sub finalize_config { }
2478
2479 =head2 $c->setup_components
2480
2481 This method is called internally to set up the application's components.
2482
2483 It finds modules by calling the L<locate_components> method, expands them to
2484 package names with the L<expand_component_module> method, and then installs
2485 each component into the application.
2486
2487 The C<setup_components> config option is passed to both of the above methods.
2488
2489 Installation of each component is performed by the L<setup_component> method,
2490 below.
2491
2492 =cut
2493
2494 sub setup_components {
2495     my $class = shift;
2496
2497     my $config  = $class->config->{ setup_components };
2498
2499     my @comps = $class->locate_components($config);
2500     my %comps = map { $_ => 1 } @comps;
2501
2502     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2503     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2504         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2505     ) if $deprecatedcatalyst_component_names;
2506
2507     for my $component ( @comps ) {
2508
2509         # We pass ignore_loaded here so that overlay files for (e.g.)
2510         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2511         # we know M::P::O found a file on disk so this is safe
2512
2513         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2514     }
2515
2516     my $containers;
2517     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
2518
2519     for my $component (@comps) {
2520         my $instance = $class->components->{ $component } = $class->setup_component($component);
2521         if ( my ($type, $name) = _get_component_type_name($component) ) {
2522 # FIXME: shouldn't the service name be $name?
2523             $containers->{$type}->add_service(Catalyst::BlockInjection->new( name => $component, block => sub { return $instance } ));
2524         }
2525         my @expanded_components = $instance->can('expand_modules')
2526             ? $instance->expand_modules( $component, $config )
2527             : $class->expand_component_module( $component, $config );
2528         for my $component (@expanded_components) {
2529             next if $comps{$component};
2530
2531             $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @expanded_components;
2532             $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2533                 qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2534             ) if $deprecatedcatalyst_component_names;
2535
2536             if (my ($type, $name) = _get_component_type_name($component)) {
2537                 $containers->{$type}->add_service(Catalyst::BlockInjection->new( name => $component, block => sub { return $class->setup_component($component) } ));
2538             }
2539
2540             $class->components->{ $component } = $class->setup_component($component);
2541         }
2542     }
2543 }
2544
2545 sub _get_component_type_name {
2546     my $component = shift;
2547     my @parts     = split /::/, $component;
2548
2549     while (my $type = shift @parts) {
2550         return ('controller', join '::', @parts)
2551             if $type =~ /^(c|controller)$/i;
2552
2553         return ('model', join '::', @parts)
2554             if $type =~ /^(m|model)$/i;
2555
2556         return ('view', join '::', @parts)
2557             if $type =~ /^(v|view)$/i;
2558     }
2559 }
2560
2561 =head2 $c->locate_components( $setup_component_config )
2562
2563 This method is meant to provide a list of component modules that should be
2564 setup for the application.  By default, it will use L<Module::Pluggable>.
2565
2566 Specify a C<setup_components> config option to pass additional options directly
2567 to L<Module::Pluggable>. To add additional search paths, specify a key named
2568 C<search_extra> as an array reference. Items in the array beginning with C<::>
2569 will have the application class name prepended to them.
2570
2571 =cut
2572
2573 sub locate_components {
2574     my $class  = shift;
2575     my $config = shift;
2576
2577     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2578     my $extra   = delete $config->{ search_extra } || [];
2579
2580     push @paths, @$extra;
2581
2582     my $locator = Module::Pluggable::Object->new(
2583         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2584         %$config
2585     );
2586
2587     # XXX think about ditching this sort entirely
2588     my @comps = sort { length $a <=> length $b } $locator->plugins;
2589
2590     return @comps;
2591 }
2592
2593 =head2 $c->expand_component_module( $component, $setup_component_config )
2594
2595 Components found by C<locate_components> will be passed to this method, which
2596 is expected to return a list of component (package) names to be set up.
2597
2598 =cut
2599
2600 sub expand_component_module {
2601     my ($class, $module) = @_;
2602     return Devel::InnerPackage::list_packages( $module );
2603 }
2604
2605 =head2 $c->setup_component
2606
2607 =cut
2608
2609 sub setup_component {
2610     my( $class, $component ) = @_;
2611
2612     unless ( $component->can( 'COMPONENT' ) ) {
2613         return $component;
2614     }
2615
2616     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2617     my $config = $class->config->{ $suffix } || {};
2618     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2619     # methods also pass it. local to avoid pointlessly shitting in config
2620     # for the debug screen, as $component is already the key name.
2621     local $config->{catalyst_component_name} = $component;
2622
2623     my $instance = eval { $component->COMPONENT( $class, $config ); };
2624
2625     if ( my $error = $@ ) {
2626         chomp $error;
2627         Catalyst::Exception->throw(
2628             message => qq/Couldn't instantiate component "$component", "$error"/
2629         );
2630     }
2631     elsif (!blessed $instance) {
2632         my $metaclass = Moose::Util::find_meta($component);
2633         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2634         my $component_method_from = $method_meta->associated_metaclass->name;
2635         my $value = defined($instance) ? $instance : 'undef';
2636         Catalyst::Exception->throw(
2637             message =>
2638             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2639         );
2640     }
2641
2642     return $instance;
2643 }
2644
2645 =head2 $c->setup_dispatcher
2646
2647 Sets up dispatcher.
2648
2649 =cut
2650
2651 sub setup_dispatcher {
2652     my ( $class, $dispatcher ) = @_;
2653
2654     if ($dispatcher) {
2655         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2656     }
2657
2658     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2659         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2660     }
2661
2662     unless ($dispatcher) {
2663         $dispatcher = $class->dispatcher_class;
2664     }
2665
2666     Class::MOP::load_class($dispatcher);
2667
2668     # dispatcher instance
2669     $class->dispatcher( $dispatcher->new );
2670 }
2671
2672 =head2 $c->setup_engine
2673
2674 Sets up engine.
2675
2676 =cut
2677
2678 sub setup_engine {
2679     my ( $class, $engine ) = @_;
2680
2681     if ($engine) {
2682         $engine = 'Catalyst::Engine::' . $engine;
2683     }
2684
2685     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2686         $engine = 'Catalyst::Engine::' . $env;
2687     }
2688
2689     if ( $ENV{MOD_PERL} ) {
2690         my $meta = Class::MOP::get_metaclass_by_name($class);
2691
2692         # create the apache method
2693         $meta->add_method('apache' => sub { shift->engine->apache });
2694
2695         my ( $software, $version ) =
2696           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2697
2698         $version =~ s/_//g;
2699         $version =~ s/(\.[^.]+)\./$1/g;
2700
2701         if ( $software eq 'mod_perl' ) {
2702
2703             if ( !$engine ) {
2704
2705                 if ( $version >= 1.99922 ) {
2706                     $engine = 'Catalyst::Engine::Apache2::MP20';
2707                 }
2708
2709                 elsif ( $version >= 1.9901 ) {
2710                     $engine = 'Catalyst::Engine::Apache2::MP19';
2711                 }
2712
2713                 elsif ( $version >= 1.24 ) {
2714                     $engine = 'Catalyst::Engine::Apache::MP13';
2715                 }
2716
2717                 else {
2718                     Catalyst::Exception->throw( message =>
2719                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2720                 }
2721
2722             }
2723
2724             # install the correct mod_perl handler
2725             if ( $version >= 1.9901 ) {
2726                 *handler = sub  : method {
2727                     shift->handle_request(@_);
2728                 };
2729             }
2730             else {
2731                 *handler = sub ($$) { shift->handle_request(@_) };
2732             }
2733
2734         }
2735
2736         elsif ( $software eq 'Zeus-Perl' ) {
2737             $engine = 'Catalyst::Engine::Zeus';
2738         }
2739
2740         else {
2741             Catalyst::Exception->throw(
2742                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2743         }
2744     }
2745
2746     unless ($engine) {
2747         $engine = $class->engine_class;
2748     }
2749
2750     Class::MOP::load_class($engine);
2751
2752     # check for old engines that are no longer compatible
2753     my $old_engine;
2754     if ( $engine->isa('Catalyst::Engine::Apache')
2755         && !Catalyst::Engine::Apache->VERSION )
2756     {
2757         $old_engine = 1;
2758     }
2759
2760     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2761         && Catalyst::Engine::Server->VERSION le '0.02' )
2762     {
2763         $old_engine = 1;
2764     }
2765
2766     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2767         && $engine->VERSION eq '0.01' )
2768     {
2769         $old_engine = 1;
2770     }
2771
2772     elsif ($engine->isa('Catalyst::Engine::Zeus')
2773         && $engine->VERSION eq '0.01' )
2774     {
2775         $old_engine = 1;
2776     }
2777
2778     if ($old_engine) {
2779         Catalyst::Exception->throw( message =>
2780               qq/Engine "$engine" is not supported by this version of Catalyst/
2781         );
2782     }
2783
2784     # engine instance
2785     $class->engine( $engine->new );
2786 }
2787
2788 =head2 $c->setup_home
2789
2790 Sets up the home directory.
2791
2792 =cut
2793
2794 sub setup_home {
2795     my ( $class, $home ) = @_;
2796
2797     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2798         $home = $env;
2799     }
2800
2801     $home ||= Catalyst::Utils::home($class);
2802
2803     if ($home) {
2804         #I remember recently being scolded for assigning config values like this
2805         $class->config->{home} ||= $home;
2806         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2807     }
2808 }
2809
2810 =head2 $c->setup_log
2811
2812 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2813 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2814 log to.
2815
2816 This method also installs a C<debug> method that returns a true value into the
2817 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2818 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2819
2820 Note that if the log has already been setup, by either a previous call to
2821 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2822 that this method won't actually set up the log object.
2823
2824 =cut
2825
2826 sub setup_log {
2827     my ( $class, $levels ) = @_;
2828
2829     $levels ||= '';
2830     $levels =~ s/^\s+//;
2831     $levels =~ s/\s+$//;
2832     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2833
2834     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2835     if ( defined $env_debug ) {
2836         $levels{debug} = 1 if $env_debug; # Ugly!
2837         delete($levels{debug}) unless $env_debug;
2838     }
2839
2840     unless ( $class->log ) {
2841         $class->log( Catalyst::Log->new(keys %levels) );
2842     }
2843
2844     if ( $levels{debug} ) {
2845         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2846         $class->log->debug('Debug messages enabled');
2847     }
2848 }
2849
2850 =head2 $c->setup_plugins
2851
2852 Sets up plugins.
2853
2854 =cut
2855
2856 =head2 $c->setup_stats
2857
2858 Sets up timing statistics class.
2859
2860 =cut
2861
2862 sub setup_stats {
2863     my ( $class, $stats ) = @_;
2864
2865     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2866
2867     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2868     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2869         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2870         $class->log->debug('Statistics enabled');
2871     }
2872 }
2873
2874
2875 =head2 $c->registered_plugins
2876
2877 Returns a sorted list of the plugins which have either been stated in the
2878 import list or which have been added via C<< MyApp->plugin(@args); >>.
2879
2880 If passed a given plugin name, it will report a boolean value indicating
2881 whether or not that plugin is loaded.  A fully qualified name is required if
2882 the plugin name does not begin with C<Catalyst::Plugin::>.
2883
2884  if ($c->registered_plugins('Some::Plugin')) {
2885      ...
2886  }
2887
2888 =cut
2889
2890 {
2891
2892     sub registered_plugins {
2893         my $proto = shift;
2894         return sort keys %{ $proto->_plugins } unless @_;
2895         my $plugin = shift;
2896         return 1 if exists $proto->_plugins->{$plugin};
2897         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2898     }
2899
2900     sub _register_plugin {
2901         my ( $proto, $plugin, $instant ) = @_;
2902         my $class = ref $proto || $proto;
2903
2904         Class::MOP::load_class( $plugin );
2905         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2906             if $plugin->isa( 'Catalyst::Component' );
2907         $proto->_plugins->{$plugin} = 1;
2908         unless ($instant) {
2909             my $meta = Class::MOP::get_metaclass_by_name($class);
2910             $meta->superclasses($plugin, $meta->superclasses);
2911         }
2912         return $class;
2913     }
2914
2915     sub setup_plugins {
2916         my ( $class, $plugins ) = @_;
2917
2918         $class->_plugins( {} ) unless $class->_plugins;
2919         $plugins = Data::OptList::mkopt($plugins || []);
2920
2921         my @plugins = map {
2922             [ Catalyst::Utils::resolve_namespace(
2923                   $class . '::Plugin',
2924                   'Catalyst::Plugin', $_->[0]
2925               ),
2926               $_->[1],
2927             ]
2928          } @{ $plugins };
2929
2930         for my $plugin ( reverse @plugins ) {
2931             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2932             my $meta = find_meta($plugin->[0]);
2933             next if $meta && $meta->isa('Moose::Meta::Role');
2934
2935             $class->_register_plugin($plugin->[0]);
2936         }
2937
2938         my @roles =
2939             map  { $_->[0]->name, $_->[1] }
2940             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2941             map  { [find_meta($_->[0]), $_->[1]] }
2942             @plugins;
2943
2944         Moose::Util::apply_all_roles(
2945             $class => @roles
2946         ) if @roles;
2947     }
2948 }
2949
2950 =head2 $c->stack
2951
2952 Returns an arrayref of the internal execution stack (actions that are
2953 currently executing).
2954
2955 =head2 $c->stats
2956
2957 Returns the current timing statistics object. By default Catalyst uses
2958 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2959 L<< stats_class|/"$c->stats_class" >>.
2960
2961 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2962 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2963 profile explicitly, although MyApp.pm still won't profile nor output anything
2964 by itself.
2965
2966 =head2 $c->stats_class
2967
2968 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2969
2970 =head2 $c->use_stats
2971
2972 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2973
2974 Note that this is a static method, not an accessor and should be overridden
2975 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2976
2977 =cut
2978
2979 sub use_stats { 0 }
2980
2981
2982 =head2 $c->write( $data )
2983
2984 Writes $data to the output stream. When using this method directly, you
2985 will need to manually set the C<Content-Length> header to the length of
2986 your output data, if known.
2987
2988 =cut
2989
2990 sub write {
2991     my $c = shift;
2992
2993     # Finalize headers if someone manually writes output
2994     $c->finalize_headers;
2995
2996     return $c->engine->write( $c, @_ );
2997 }
2998
2999 =head2 version
3000
3001 Returns the Catalyst version number. Mostly useful for "powered by"
3002 messages in template systems.
3003
3004 =cut
3005
3006 sub version { return $Catalyst::VERSION }
3007
3008 =head1 CONFIGURATION
3009
3010 There are a number of 'base' config variables which can be set:
3011
3012 =over
3013
3014 =item *
3015
3016 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3017
3018 =item *
3019
3020 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3021
3022 =item *
3023
3024 C<disable_component_resolution_regex_fallback> - Turns
3025 off the deprecated component resolution functionality so
3026 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3027 are called then regex search will not be attempted on string values and
3028 instead C<undef> will be returned.
3029
3030 =item *
3031
3032 C<home> - The application home directory. In an uninstalled application,
3033 this is the top level application directory. In an installed application,
3034 this will be the directory containing C<< MyApp.pm >>.
3035
3036 =item *
3037
3038 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3039
3040 =item *
3041
3042 C<name> - The name of the application in debug messages and the debug and
3043 welcome screens
3044
3045 =item *
3046
3047 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3048 until it is accessed. This allows you to (for example) check authentication (and reject
3049 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
3050
3051 =item *
3052
3053 C<root> - The root directory for templates. Usually this is just a
3054 subdirectory of the home directory, but you can set it to change the
3055 templates to a different directory.
3056
3057 =item *
3058
3059 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3060 namespaces from which components will be loaded (and constructed and stored in
3061 C<< $c->components >>).
3062
3063 =item *
3064
3065 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3066 to be shown in hit debug tables in the test server.
3067
3068 =item *
3069
3070 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
3071 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
3072 for more information.
3073
3074 =item *
3075
3076 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3077
3078 =back
3079
3080 =head1 INTERNAL ACTIONS
3081
3082 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3083 C<_ACTION>, and C<_END>. These are by default not shown in the private
3084 action table, but you can make them visible with a config parameter.
3085
3086     MyApp->config(show_internal_actions => 1);
3087
3088 =head1 ON-DEMAND PARSER
3089
3090 The request body is usually parsed at the beginning of a request,
3091 but if you want to handle input yourself, you can enable on-demand
3092 parsing with a config parameter.
3093
3094     MyApp->config(parse_on_demand => 1);
3095
3096 =head1 PROXY SUPPORT
3097
3098 Many production servers operate using the common double-server approach,
3099 with a lightweight frontend web server passing requests to a larger
3100 backend server. An application running on the backend server must deal
3101 with two problems: the remote user always appears to be C<127.0.0.1> and
3102 the server's hostname will appear to be C<localhost> regardless of the
3103 virtual host that the user connected through.
3104
3105 Catalyst will automatically detect this situation when you are running
3106 the frontend and backend servers on the same machine. The following
3107 changes are made to the request.
3108
3109     $c->req->address is set to the user's real IP address, as read from
3110     the HTTP X-Forwarded-For header.
3111
3112     The host value for $c->req->base and $c->req->uri is set to the real
3113     host, as read from the HTTP X-Forwarded-Host header.
3114
3115 Additionally, you may be running your backend application on an insecure
3116 connection (port 80) while your frontend proxy is running under SSL.  If there
3117 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3118 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3119 be created properly.
3120
3121 In the case of passing in:
3122
3123     X-Forwarded-Port: 443
3124
3125 All calls to C<uri_for> will result in an https link, as is expected.
3126
3127 Obviously, your web server must support these headers for this to work.
3128
3129 In a more complex server farm environment where you may have your
3130 frontend proxy server(s) on different machines, you will need to set a
3131 configuration option to tell Catalyst to read the proxied data from the
3132 headers.
3133
3134     MyApp->config(using_frontend_proxy => 1);
3135
3136 If you do not wish to use the proxy support at all, you may set:
3137
3138     MyApp->config(ignore_frontend_proxy => 1);
3139
3140 =head1 THREAD SAFETY
3141
3142 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3143 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3144 believe the Catalyst core to be thread-safe.
3145
3146 If you plan to operate in a threaded environment, remember that all other
3147 modules you are using must also be thread-safe. Some modules, most notably
3148 L<DBD::SQLite>, are not thread-safe.
3149
3150 =head1 SUPPORT
3151
3152 IRC:
3153
3154     Join #catalyst on irc.perl.org.
3155
3156 Mailing Lists:
3157
3158     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3159     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3160
3161 Web:
3162
3163     http://catalyst.perl.org
3164
3165 Wiki:
3166
3167     http://dev.catalyst.perl.org
3168
3169 =head1 SEE ALSO
3170
3171 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3172
3173 =head2 L<Catalyst::Manual> - The Catalyst Manual
3174
3175 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3176
3177 =head2 L<Catalyst::Engine> - Core engine
3178
3179 =head2 L<Catalyst::Log> - Log class.
3180
3181 =head2 L<Catalyst::Request> - Request object
3182
3183 =head2 L<Catalyst::Response> - Response object
3184
3185 =head2 L<Catalyst::Test> - The test suite.
3186
3187 =head1 PROJECT FOUNDER
3188
3189 sri: Sebastian Riedel <sri@cpan.org>
3190
3191 =head1 CONTRIBUTORS
3192
3193 abw: Andy Wardley
3194
3195 acme: Leon Brocard <leon@astray.com>
3196
3197 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3198
3199 Andrew Bramble
3200
3201 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3202
3203 Andrew Ruthven
3204
3205 andyg: Andy Grundman <andy@hybridized.org>
3206
3207 audreyt: Audrey Tang
3208
3209 bricas: Brian Cassidy <bricas@cpan.org>
3210
3211 Caelum: Rafael Kitover <rkitover@io.com>
3212
3213 chansen: Christian Hansen
3214
3215 chicks: Christopher Hicks
3216
3217 Chisel Wright C<pause@herlpacker.co.uk>
3218
3219 Danijel Milicevic C<me@danijel.de>
3220
3221 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3222
3223 David Naughton, C<naughton@umn.edu>
3224
3225 David E. Wheeler
3226
3227 dhoss: Devin Austin <dhoss@cpan.org>
3228
3229 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3230
3231 Drew Taylor
3232
3233 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3234
3235 esskar: Sascha Kiefer
3236
3237 fireartist: Carl Franks <cfranks@cpan.org>
3238
3239 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3240
3241 gabb: Danijel Milicevic
3242
3243 Gary Ashton Jones
3244
3245 Gavin Henry C<ghenry@perl.me.uk>
3246
3247 Geoff Richards
3248
3249 groditi: Guillermo Roditi <groditi@gmail.com>
3250
3251 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3252
3253 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3254
3255 jcamacho: Juan Camacho
3256
3257 jester: Jesse Sheidlower C<jester@panix.com>
3258
3259 jhannah: Jay Hannah <jay@jays.net>
3260
3261 Jody Belka
3262
3263 Johan Lindstrom
3264
3265 jon: Jon Schutz <jjschutz@cpan.org>
3266
3267 Jonathan Rockway C<< <jrockway@cpan.org> >>
3268
3269 Kieren Diment C<kd@totaldatasolution.com>
3270
3271 konobi: Scott McWhirter <konobi@cpan.org>
3272
3273 marcus: Marcus Ramberg <mramberg@cpan.org>
3274
3275 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3276
3277 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3278
3279 mugwump: Sam Vilain
3280
3281 naughton: David Naughton
3282
3283 ningu: David Kamholz <dkamholz@cpan.org>
3284
3285 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3286
3287 numa: Dan Sully <daniel@cpan.org>
3288
3289 obra: Jesse Vincent
3290
3291 Octavian Rasnita
3292
3293 omega: Andreas Marienborg
3294
3295 Oleg Kostyuk <cub.uanic@gmail.com>
3296
3297 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3298
3299 rafl: Florian Ragwitz <rafl@debian.org>
3300
3301 random: Roland Lammel <lammel@cpan.org>
3302
3303 Robert Sedlacek C<< <rs@474.at> >>
3304
3305 SpiceMan: Marcel Montes
3306
3307 sky: Arthur Bergman
3308
3309 szbalint: Balint Szilakszi <szbalint@cpan.org>
3310
3311 t0m: Tomas Doran <bobtfish@bobtfish.net>
3312
3313 Ulf Edvinsson
3314
3315 Viljo Marrandi C<vilts@yahoo.com>
3316
3317 Will Hawes C<info@whawes.co.uk>
3318
3319 willert: Sebastian Willert <willert@cpan.org>
3320
3321 wreis: Wallace Reis <wallace@reis.org.br>
3322
3323 Yuval Kogman, C<nothingmuch@woobling.org>
3324
3325 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3326
3327 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3328
3329 =head1 COPYRIGHT
3330
3331 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3332
3333 =head1 LICENSE
3334
3335 This library is free software. You can redistribute it and/or modify it under
3336 the same terms as Perl itself.
3337
3338 =cut
3339
3340 no Moose;
3341
3342 __PACKAGE__->meta->make_immutable;
3343
3344 1;