lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::Util qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54 use Scalar::Util;
  55
  56 BEGIN { require 5.008003; }
  57
  58 has stack => (is => 'ro', default => sub { [] });
  59 has state => (is => 'rw', default => 0);
  60 has stats => (is => 'rw');
  61 has action => (is => 'rw');
  62 has counter => (is => 'rw', default => sub { {} });
  63 has request => (
  64     is => 'rw',
  65     default => sub {
  66         my $self = shift;
  67         my $class = ref $self;
  68         my $composed_request_class = $class->composed_request_class;
  69         return $composed_request_class->new( $self->_build_request_constructor_args);
  70     },
  71     lazy => 1,
  72 );
  73 sub _build_request_constructor_args {
  74     my $self = shift;
  75     my %p = ( _log => $self->log );
  76     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  77     $p{data_handlers} = {$self->registered_data_handlers};
  78     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  79       if $self->config->{use_hash_multivalue_in_request};
  80     \%p;
  81 }
  82
  83 sub composed_request_class {
  84   my $class = shift;
  85   return $class->_composed_request_class if $class->_composed_request_class;
  86
  87   my @traits = (@{$class->request_class_traits||[]}, @{$class->config->{request_class_traits}||[]});
  88
  89   # For each trait listed, figure out what the namespace is.  First we try the $trait
  90   # as it is in the config.  Then try $MyApp::TraitFor::Request:$trait. Last we try
  91   # Catalyst::TraitFor::Request::$trait.  If none load, throw error.
  92
  93   my $trait_ns = 'TraitFor::Request';
  94   my @normalized_traits = map {
  95     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
  96   } @traits;
  97
  98   if ($class->debug && scalar(@normalized_traits)) {
  99       my $column_width = Catalyst::Utils::term_width() - 6;
 100       my $t = Text::SimpleTable->new($column_width);
 101       $t->row($_) for @normalized_traits;
 102       $class->log->debug( "Composed Request Class Traits:\n" . $t->draw . "\n" );
 103   }
 104
 105   return $class->_composed_request_class(Moose::Util::with_traits($class->request_class, @normalized_traits));
 106 }
 107
 108 has response => (
 109     is => 'rw',
 110     default => sub {
 111         my $self = shift;
 112         my $class = ref $self;
 113         my $composed_response_class = $class->composed_response_class;
 114         return $composed_response_class->new( $self->_build_response_constructor_args);
 115     },
 116     lazy => 1,
 117 );
 118 sub _build_response_constructor_args {
 119     return +{
 120       _log => $_[0]->log,
 121       encoding => $_[0]->encoding,
 122     };
 123 }
 124
 125 sub composed_response_class {
 126   my $class = shift;
 127   return $class->_composed_response_class if $class->_composed_response_class;
 128
 129   my @traits = (@{$class->response_class_traits||[]}, @{$class->config->{response_class_traits}||[]});
 130
 131   my $trait_ns = 'TraitFor::Response';
 132   my @normalized_traits = map {
 133     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
 134   } @traits;
 135
 136   if ($class->debug && scalar(@normalized_traits)) {
 137       my $column_width = Catalyst::Utils::term_width() - 6;
 138       my $t = Text::SimpleTable->new($column_width);
 139       $t->row($_) for @normalized_traits;
 140       $class->log->debug( "Composed Response Class Traits:\n" . $t->draw . "\n" );
 141   }
 142
 143   return $class->_composed_response_class(Moose::Util::with_traits($class->response_class, @normalized_traits));
 144 }
 145
 146 has namespace => (is => 'rw');
 147
 148 sub depth { scalar @{ shift->stack || [] }; }
 149 sub comp { shift->component(@_) }
 150
 151 sub req {
 152     my $self = shift; return $self->request(@_);
 153 }
 154 sub res {
 155     my $self = shift; return $self->response(@_);
 156 }
 157
 158 # For backwards compatibility
 159 sub finalize_output { shift->finalize_body(@_) };
 160
 161 # For statistics
 162 our $COUNT     = 1;
 163 our $START     = time;
 164 our $RECURSION = 1000;
 165 our $DETACH    = Catalyst::Exception::Detach->new;
 166 our $GO        = Catalyst::Exception::Go->new;
 167
 168 #I imagine that very few of these really
 169 #need to be class variables. if any.
 170 #maybe we should just make them attributes with a default?
 171 __PACKAGE__->mk_classdata($_)
 172   for qw/components arguments dispatcher engine log dispatcher_class
 173   engine_loader context_class request_class response_class stats_class
 174   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 175   _data_handlers _encoding _encode_check finalized_default_middleware
 176   request_class_traits response_class_traits stats_class_traits
 177   _composed_request_class _composed_response_class _composed_stats_class/;
 178
 179 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 180 __PACKAGE__->request_class('Catalyst::Request');
 181 __PACKAGE__->response_class('Catalyst::Response');
 182 __PACKAGE__->stats_class('Catalyst::Stats');
 183
 184 sub composed_stats_class {
 185   my $class = shift;
 186   return $class->_composed_stats_class if $class->_composed_stats_class;
 187
 188   my @traits = (@{$class->stats_class_traits||[]}, @{$class->config->{stats_class_traits}||[]});
 189
 190   my $trait_ns = 'TraitFor::Stats';
 191   my @normalized_traits = map {
 192     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
 193   } @traits;
 194
 195   if ($class->debug && scalar(@normalized_traits)) {
 196       my $column_width = Catalyst::Utils::term_width() - 6;
 197       my $t = Text::SimpleTable->new($column_width);
 198       $t->row($_) for @normalized_traits;
 199       $class->log->debug( "Composed Stats Class Traits:\n" . $t->draw . "\n" );
 200   }
 201
 202   return $class->_composed_stats_class(Moose::Util::with_traits($class->stats_class, @normalized_traits));
 203 }
 204
 205 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 206
 207 # Remember to update this in Catalyst::Runtime as well!
 208 our $VERSION = '5.90117';
 209 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 210
 211 sub import {
 212     my ( $class, @arguments ) = @_;
 213
 214     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 215     # callers @ISA.
 216     return unless $class eq 'Catalyst';
 217
 218     my $caller = caller();
 219     return if $caller eq 'main';
 220
 221     my $meta = Moose::Meta::Class->initialize($caller);
 222     unless ( $caller->isa('Catalyst') ) {
 223         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 224         $meta->superclasses(@superclasses);
 225     }
 226     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 227     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 228
 229     unless( $meta->has_method('meta') ){
 230         if ($Moose::VERSION >= 1.15) {
 231             $meta->_add_meta_method('meta');
 232         }
 233         else {
 234             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 235         }
 236     }
 237
 238     $caller->arguments( [@arguments] );
 239     $caller->setup_home;
 240 }
 241
 242 sub _application { $_[0] }
 243
 244 =encoding UTF-8
 245
 246 =head1 NAME
 247
 248 Catalyst - The Elegant MVC Web Application Framework
 249
 250 =head1 SYNOPSIS
 251
 252 See the L<Catalyst::Manual> distribution for comprehensive
 253 documentation and tutorials.
 254
 255     # Install Catalyst::Devel for helpers and other development tools
 256     # use the helper to create a new application
 257     catalyst.pl MyApp
 258
 259     # add models, views, controllers
 260     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 261     script/myapp_create.pl view MyTemplate TT
 262     script/myapp_create.pl controller Search
 263
 264     # built in testserver -- use -r to restart automatically on changes
 265     # --help to see all available options
 266     script/myapp_server.pl
 267
 268     # command line testing interface
 269     script/myapp_test.pl /yada
 270
 271     ### in lib/MyApp.pm
 272     use Catalyst qw/-Debug/; # include plugins here as well
 273
 274     ### In lib/MyApp/Controller/Root.pm (autocreated)
 275     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 276         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 277         $c->stash->{template} = 'foo.tt'; # set the template
 278         # lookup something from db -- stash vars are passed to TT
 279         $c->stash->{data} =
 280           $c->model('Database::Foo')->search( { country => $args[0] } );
 281         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 282             $c->forward( 'bar' ); # process another action
 283             # do something else after forward returns
 284         }
 285     }
 286
 287     # The foo.tt TT template can use the stash data from the database
 288     [% WHILE (item = data.next) %]
 289         [% item.foo %]
 290     [% END %]
 291
 292     # called for /bar/of/soap, /bar/of/soap/10, etc.
 293     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 294
 295     # called after all actions are finished
 296     sub end : Action {
 297         my ( $self, $c ) = @_;
 298         if ( scalar @{ $c->error } ) { ... } # handle errors
 299         return if $c->res->body; # already have a response
 300         $c->forward( 'MyApp::View::TT' ); # render template
 301     }
 302
 303 See L<Catalyst::Manual::Intro> for additional information.
 304
 305 =head1 DESCRIPTION
 306
 307 Catalyst is a modern framework for making web applications without the
 308 pain usually associated with this process. This document is a reference
 309 to the main Catalyst application. If you are a new user, we suggest you
 310 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 311
 312 See L<Catalyst::Manual> for more documentation.
 313
 314 Catalyst plugins can be loaded by naming them as arguments to the "use
 315 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 316 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 317 C<My::Module>.
 318
 319     use Catalyst qw/My::Module/;
 320
 321 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 322 fully qualify the name by using a unary plus:
 323
 324     use Catalyst qw/
 325         My::Module
 326         +Fully::Qualified::Plugin::Name
 327     /;
 328
 329 Special flags like C<-Debug> can also be specified as
 330 arguments when Catalyst is loaded:
 331
 332     use Catalyst qw/-Debug My::Module/;
 333
 334 The position of plugins and flags in the chain is important, because
 335 they are loaded in the order in which they appear.
 336
 337 The following flags are supported:
 338
 339 =head2 -Debug
 340
 341 Enables debug output. You can also force this setting from the system
 342 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 343 settings override the application, with <MYAPP>_DEBUG having the highest
 344 priority.
 345
 346 This sets the log level to 'debug' and enables full debug output on the
 347 error screen. If you only want the latter, see L<< $c->debug >>.
 348
 349 =head2 -Home
 350
 351 Forces Catalyst to use a specific home directory, e.g.:
 352
 353     use Catalyst qw[-Home=/usr/mst];
 354
 355 This can also be done in the shell environment by setting either the
 356 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 357 is replaced with the uppercased name of your application, any "::" in
 358 the name will be replaced with underscores, e.g. MyApp::Web should use
 359 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 360
 361 If none of these are set, Catalyst will attempt to automatically detect the
 362 home directory. If you are working in a development environment, Catalyst
 363 will try and find the directory containing either Makefile.PL, Build.PL,
 364 dist.ini, or cpanfile. If the application has been installed into the system
 365 (i.e. you have done C<make install>), then Catalyst will use the path to your
 366 application module, without the .pm extension (e.g., /foo/MyApp if your
 367 application was installed at /foo/MyApp.pm)
 368
 369 =head2 -Log
 370
 371     use Catalyst '-Log=warn,fatal,error';
 372
 373 Specifies a comma-delimited list of log levels.
 374
 375 =head2 -Stats
 376
 377 Enables statistics collection and reporting.
 378
 379    use Catalyst qw/-Stats=1/;
 380
 381 You can also force this setting from the system environment with CATALYST_STATS
 382 or <MYAPP>_STATS. The environment settings override the application, with
 383 <MYAPP>_STATS having the highest priority.
 384
 385 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 386
 387 =head1 METHODS
 388
 389 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 390
 391 =head2 $c->action
 392
 393 Returns a L<Catalyst::Action> object for the current action, which
 394 stringifies to the action name. See L<Catalyst::Action>.
 395
 396 =head2 $c->namespace
 397
 398 Returns the namespace of the current action, i.e., the URI prefix
 399 corresponding to the controller of the current action. For example:
 400
 401     # in Controller::Foo::Bar
 402     $c->namespace; # returns 'foo/bar';
 403
 404 =head2 $c->request
 405
 406 =head2 $c->req
 407
 408 Returns the current L<Catalyst::Request> object, giving access to
 409 information about the current client request (including parameters,
 410 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 411
 412 =head2 REQUEST FLOW HANDLING
 413
 414 =head2 $c->forward( $action [, \@arguments ] )
 415
 416 =head2 $c->forward( $class, $method, [, \@arguments ] )
 417
 418 This is one way of calling another action (method) in the same or
 419 a different controller. You can also use C<< $self->my_method($c, @args) >>
 420 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 421 in a different controller.
 422 The main difference is that 'forward' uses some of the Catalyst request
 423 cycle overhead, including debugging, which may be useful to you. On the
 424 other hand, there are some complications to using 'forward', restrictions
 425 on values returned from 'forward', and it may not handle errors as you prefer.
 426 Whether you use 'forward' or not is up to you; it is not considered superior to
 427 the other ways to call a method.
 428
 429 'forward' calls  another action, by its private name. If you give a
 430 class name but no method, C<process()> is called. You may also optionally
 431 pass arguments in an arrayref. The action will receive the arguments in
 432 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 433 C<< $c->req->args >> will be restored to the previous values.
 434
 435 Any data C<return>ed from the action forwarded to, will be returned by the
 436 call to forward.
 437
 438     my $foodata = $c->forward('/foo');
 439     $c->forward('index');
 440     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 441     $c->forward('View::TT');
 442
 443 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 444 an C<< eval { } >> around the call (actually
 445 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 446 exceptions thrown by the called action non-fatal and pushing them onto
 447 $c->error instead. If you want C<die> to propagate you need to do something
 448 like:
 449
 450     $c->forward('foo');
 451     die join "\n", @{ $c->error } if @{ $c->error };
 452
 453 Or make sure to always return true values from your actions and write
 454 your code like this:
 455
 456     $c->forward('foo') || return;
 457
 458 Another note is that C<< $c->forward >> always returns a scalar because it
 459 actually returns $c->state which operates in a scalar context.
 460 Thus, something like:
 461
 462     return @array;
 463
 464 in an action that is forwarded to is going to return a scalar,
 465 i.e. how many items are in that array, which is probably not what you want.
 466 If you need to return an array then return a reference to it,
 467 or stash it like so:
 468
 469     $c->stash->{array} = \@array;
 470
 471 and access it from the stash.
 472
 473 Keep in mind that the C<end> method used is that of the caller action. So a C<< $c->detach >> inside a forwarded action would run the C<end> method from the original action requested.
 474
 475 =cut
 476
 477 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 478
 479 =head2 $c->detach( $action [, \@arguments ] )
 480
 481 =head2 $c->detach( $class, $method, [, \@arguments ] )
 482
 483 =head2 $c->detach()
 484
 485 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 486 doesn't return to the previous action when processing is finished.
 487
 488 When called with no arguments it escapes the processing chain entirely.
 489
 490 =cut
 491
 492 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 493
 494 =head2 $c->visit( $action [, \@arguments ] )
 495
 496 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 497
 498 =head2 $c->visit( $class, $method, [, \@arguments ] )
 499
 500 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 501
 502 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 503 but does a full dispatch, instead of just calling the new C<$action> /
 504 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 505 you go to are called, just like a new request.
 506
 507 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 508 This means, for example, that C<< $c->action >> methods such as
 509 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 510 L<reverse|Catalyst::Action/reverse> return information for the visited action
 511 when they are invoked within the visited action.  This is different from the
 512 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 513 continues to use the $c->action object from the caller action even when
 514 invoked from the called action.
 515
 516 C<< $c->stash >> is kept unchanged.
 517
 518 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 519 allows you to "wrap" another action, just as it would have been called by
 520 dispatching from a URL, while the analogous
 521 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 522 transfer control to another action as if it had been reached directly from a URL.
 523
 524 =cut
 525
 526 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 527
 528 =head2 $c->go( $action [, \@arguments ] )
 529
 530 =head2 $c->go( $action [, \@captures, \@arguments ] )
 531
 532 =head2 $c->go( $class, $method, [, \@arguments ] )
 533
 534 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 535
 536 The relationship between C<go> and
 537 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 538 the relationship between
 539 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 540 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 541 C<< $c->go >> will perform a full dispatch on the specified action or method,
 542 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 543 C<go> escapes the processing of the current request chain on completion, and
 544 does not return to its caller.
 545
 546 @arguments are arguments to the final destination of $action. @captures are
 547 arguments to the intermediate steps, if any, on the way to the final sub of
 548 $action.
 549
 550 =cut
 551
 552 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 553
 554 =head2 $c->response
 555
 556 =head2 $c->res
 557
 558 Returns the current L<Catalyst::Response> object, see there for details.
 559
 560 =head2 $c->stash
 561
 562 Returns a hashref to the stash, which may be used to store data and pass
 563 it between components during a request. You can also set hash keys by
 564 passing arguments. The stash is automatically sent to the view. The
 565 stash is cleared at the end of a request; it cannot be used for
 566 persistent storage (for this you must use a session; see
 567 L<Catalyst::Plugin::Session> for a complete system integrated with
 568 Catalyst).
 569
 570     $c->stash->{foo} = $bar;
 571     $c->stash( { moose => 'majestic', qux => 0 } );
 572     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 573
 574     # stash is automatically passed to the view for use in a template
 575     $c->forward( 'MyApp::View::TT' );
 576
 577 The stash hash is currently stored in the PSGI C<$env> and is managed by
 578 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 579 the stash can be accessed in sub applications mounted under your main
 580 L<Catalyst> application.  For example if you delegate the response of an
 581 action to another L<Catalyst> application, that sub application will have
 582 access to all the stash keys of the main one, and if can of course add
 583 more keys of its own.  However those new keys will not 'bubble' back up
 584 to the main application.
 585
 586 For more information the best thing to do is to review the test case:
 587 t/middleware-stash.t in the distribution /t directory.
 588
 589 =cut
 590
 591 sub stash {
 592   my $c = shift;
 593   $c->log->error("You are requesting the stash but you don't have a context") unless blessed $c;
 594   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 595 }
 596
 597 =head2 $c->error
 598
 599 =head2 $c->error($error, ...)
 600
 601 =head2 $c->error($arrayref)
 602
 603 Returns an arrayref containing error messages.  If Catalyst encounters an
 604 error while processing a request, it stores the error in $c->error.  This
 605 method should only be used to store fatal error messages.
 606
 607     my @error = @{ $c->error };
 608
 609 Add a new error.
 610
 611     $c->error('Something bad happened');
 612
 613 Calling this will always return an arrayref (if there are no errors it
 614 will be an empty arrayref.
 615
 616 =cut
 617
 618 sub error {
 619     my $c = shift;
 620     if ( $_[0] ) {
 621         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 622         croak @$error unless ref $c;
 623         push @{ $c->{error} }, @$error;
 624     }
 625     elsif ( defined $_[0] ) { $c->{error} = undef }
 626     return $c->{error} || [];
 627 }
 628
 629 =head2 $c->state
 630
 631 Contains the return value of the last executed action.
 632 Note that << $c->state >> operates in a scalar context which means that all
 633 values it returns are scalar.
 634
 635 Please note that if an action throws an exception, the value of state
 636 should no longer be considered the return if the last action.  It is generally
 637 going to be 0, which indicates an error state.  Examine $c->error for error
 638 details.
 639
 640 =head2 $c->clear_errors
 641
 642 Clear errors.  You probably don't want to clear the errors unless you are
 643 implementing a custom error screen.
 644
 645 This is equivalent to running
 646
 647     $c->error(0);
 648
 649 =cut
 650
 651 sub clear_errors {
 652     my $c = shift;
 653     $c->error(0);
 654 }
 655
 656 =head2 $c->has_errors
 657
 658 Returns true if you have errors
 659
 660 =cut
 661
 662 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 663
 664 =head2 $c->last_error
 665
 666 Returns the most recent error in the stack (the one most recently added...)
 667 or nothing if there are no errors.  This does not modify the contents of the
 668 error stack.
 669
 670 =cut
 671
 672 sub last_error {
 673   my (@errs) = @{shift->error};
 674   return scalar(@errs) ? $errs[-1]: undef;
 675 }
 676
 677 =head2 shift_errors
 678
 679 shifts the most recently added error off the error stack and returns it.  Returns
 680 nothing if there are no more errors.
 681
 682 =cut
 683
 684 sub shift_errors {
 685     my ($self) = @_;
 686     my @errors = @{$self->error};
 687     my $err = shift(@errors);
 688     $self->{error} = \@errors;
 689     return $err;
 690 }
 691
 692 =head2 pop_errors
 693
 694 pops the most recently added error off the error stack and returns it.  Returns
 695 nothing if there are no more errors.
 696
 697 =cut
 698
 699 sub pop_errors {
 700     my ($self) = @_;
 701     my @errors = @{$self->error};
 702     my $err = pop(@errors);
 703     $self->{error} = \@errors;
 704     return $err;
 705 }
 706
 707 sub _comp_search_prefixes {
 708     my $c = shift;
 709     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 710 }
 711
 712 # search components given a name and some prefixes
 713 sub _comp_names_search_prefixes {
 714     my ( $c, $name, @prefixes ) = @_;
 715     my $appclass = ref $c || $c;
 716     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 717     $filter = qr/$filter/; # Compile regex now rather than once per loop
 718
 719     # map the original component name to the sub part that we will search against
 720     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 721         grep { /$filter/ } keys %{ $c->components };
 722
 723     # undef for a name will return all
 724     return keys %eligible if !defined $name;
 725
 726     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 727     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 728
 729     return @result if @result;
 730
 731     # if we were given a regexp to search against, we're done.
 732     return if $name->$_isa('Regexp');
 733
 734     # skip regexp fallback if configured
 735     return
 736         if $appclass->config->{disable_component_resolution_regex_fallback};
 737
 738     # regexp fallback
 739     $query  = qr/$name/i;
 740     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 741
 742     # no results? try against full names
 743     if( !@result ) {
 744         @result = grep { m{$query} } keys %eligible;
 745     }
 746
 747     # don't warn if we didn't find any results, it just might not exist
 748     if( @result ) {
 749         # Disgusting hack to work out correct method name
 750         my $warn_for = lc $prefixes[0];
 751         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 752            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 753            "component resolution is unreliable and unsafe.";
 754         my $short = $result[0];
 755         # remove the component namespace prefix
 756         $short =~ s/.*?(Model|Controller|View):://;
 757         my $shortmess = Carp::shortmess('');
 758         if ($shortmess =~ m#Catalyst/Plugin#) {
 759            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 760               "plugin's config";
 761         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 762            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 763               "component's config";
 764         } else {
 765            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 766               "but if you really wanted to search, pass in a regexp as the argument " .
 767               "like so: \$c->${warn_for}(qr/${name}/)";
 768         }
 769         $c->log->warn( "${msg}$shortmess" );
 770     }
 771
 772     return @result;
 773 }
 774
 775 # Find possible names for a prefix
 776 sub _comp_names {
 777     my ( $c, @prefixes ) = @_;
 778     my $appclass = ref $c || $c;
 779
 780     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 781
 782     my @names = map { s{$filter}{}; $_; }
 783         $c->_comp_names_search_prefixes( undef, @prefixes );
 784
 785     return @names;
 786 }
 787
 788 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 789
 790 sub _filter_component {
 791     my ( $c, $comp, @args ) = @_;
 792
 793     if(ref $comp eq 'CODE') {
 794       $comp = $comp->();
 795     }
 796
 797     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 798       return $comp->ACCEPT_CONTEXT( $c, @args );
 799     }
 800
 801     $c->log->warn("You called component '${\$comp->catalyst_component_name}' with arguments [@args], but this component does not ACCEPT_CONTEXT, so args are ignored.") if scalar(@args) && $c->debug;
 802
 803     return $comp;
 804 }
 805
 806 =head2 COMPONENT ACCESSORS
 807
 808 =head2 $c->controller($name)
 809
 810 Gets a L<Catalyst::Controller> instance by name.
 811
 812     $c->controller('Foo')->do_stuff;
 813
 814 If the name is omitted, will return the controller for the dispatched
 815 action.
 816
 817 If you want to search for controllers, pass in a regexp as the argument.
 818
 819     # find all controllers that start with Foo
 820     my @foo_controllers = $c->controller(qr{^Foo});
 821
 822
 823 =cut
 824
 825 sub controller {
 826     my ( $c, $name, @args ) = @_;
 827
 828     my $appclass = ref($c) || $c;
 829     if( $name ) {
 830         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 831             my $comps = $c->components;
 832             my $check = $appclass."::Controller::".$name;
 833             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 834             foreach my $path (@{$appclass->config->{ setup_components }->{ search_extra }}) {
 835                 next unless $path =~ /.*::Controller/;
 836                 $check = $path."::".$name;
 837                 return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 838             }
 839         }
 840         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 841         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 842         return $c->_filter_component( $result[ 0 ], @args );
 843     }
 844
 845     return $c->component( $c->action->class );
 846 }
 847
 848 =head2 $c->model($name)
 849
 850 Gets a L<Catalyst::Model> instance by name.
 851
 852     $c->model('Foo')->do_stuff;
 853
 854 Any extra arguments are directly passed to ACCEPT_CONTEXT, if the model
 855 defines ACCEPT_CONTEXT.  If it does not, the args are discarded.
 856
 857 If the name is omitted, it will look for
 858  - a model object in $c->stash->{current_model_instance}, then
 859  - a model name in $c->stash->{current_model}, then
 860  - a config setting 'default_model', or
 861  - check if there is only one model, and return it if that's the case.
 862
 863 If you want to search for models, pass in a regexp as the argument.
 864
 865     # find all models that start with Foo
 866     my @foo_models = $c->model(qr{^Foo});
 867
 868 =cut
 869
 870 sub model {
 871     my ( $c, $name, @args ) = @_;
 872     my $appclass = ref($c) || $c;
 873     if( $name ) {
 874         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 875             my $comps = $c->components;
 876             my $check = $appclass."::Model::".$name;
 877             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 878             foreach my $path (@{$appclass->config->{ setup_components }->{ search_extra }}) {
 879                 next unless $path =~ /.*::Model/;
 880                 $check = $path."::".$name;
 881                 return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 882             }
 883         }
 884         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 885         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 886         return $c->_filter_component( $result[ 0 ], @args );
 887     }
 888
 889     if (ref $c) {
 890         return $c->stash->{current_model_instance}
 891           if $c->stash->{current_model_instance};
 892         return $c->model( $c->stash->{current_model} )
 893           if $c->stash->{current_model};
 894     }
 895     return $c->model( $appclass->config->{default_model} )
 896       if $appclass->config->{default_model};
 897
 898     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 899
 900     if( $rest ) {
 901         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 902         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 903         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 904         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 905         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 906     }
 907
 908     return $c->_filter_component( $comp );
 909 }
 910
 911
 912 =head2 $c->view($name)
 913
 914 Gets a L<Catalyst::View> instance by name.
 915
 916     $c->view('Foo')->do_stuff;
 917
 918 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 919
 920 If the name is omitted, it will look for
 921  - a view object in $c->stash->{current_view_instance}, then
 922  - a view name in $c->stash->{current_view}, then
 923  - a config setting 'default_view', or
 924  - check if there is only one view, and return it if that's the case.
 925
 926 If you want to search for views, pass in a regexp as the argument.
 927
 928     # find all views that start with Foo
 929     my @foo_views = $c->view(qr{^Foo});
 930
 931 =cut
 932
 933 sub view {
 934     my ( $c, $name, @args ) = @_;
 935
 936     my $appclass = ref($c) || $c;
 937     if( $name ) {
 938         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 939             my $comps = $c->components;
 940             my $check = $appclass."::View::".$name;
 941             if( exists $comps->{$check} ) {
 942                 return $c->_filter_component( $comps->{$check}, @args );
 943             }
 944             else {
 945                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 946             }
 947             foreach my $path (@{$appclass->config->{ setup_components }->{ search_extra }}) {
 948                 next unless $path =~ /.*::View/;
 949                 $check = $path."::".$name;
 950                 return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 951             }
 952         }
 953         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 954         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 955         return $c->_filter_component( $result[ 0 ], @args );
 956     }
 957
 958     if (ref $c) {
 959         return $c->stash->{current_view_instance}
 960           if $c->stash->{current_view_instance};
 961         return $c->view( $c->stash->{current_view} )
 962           if $c->stash->{current_view};
 963     }
 964     return $c->view( $appclass->config->{default_view} )
 965       if $appclass->config->{default_view};
 966
 967     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 968
 969     if( $rest ) {
 970         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 971         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 972         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 973         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 974         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 975     }
 976
 977     return $c->_filter_component( $comp );
 978 }
 979
 980 =head2 $c->controllers
 981
 982 Returns the available names which can be passed to $c->controller
 983
 984 =cut
 985
 986 sub controllers {
 987     my ( $c ) = @_;
 988     return $c->_comp_names(qw/Controller C/);
 989 }
 990
 991 =head2 $c->models
 992
 993 Returns the available names which can be passed to $c->model
 994
 995 =cut
 996
 997 sub models {
 998     my ( $c ) = @_;
 999     return $c->_comp_names(qw/Model M/);
1000 }
1001
1002
1003 =head2 $c->views
1004
1005 Returns the available names which can be passed to $c->view
1006
1007 =cut
1008
1009 sub views {
1010     my ( $c ) = @_;
1011     return $c->_comp_names(qw/View V/);
1012 }
1013
1014 =head2 $c->comp($name)
1015
1016 =head2 $c->component($name)
1017
1018 Gets a component object by name. This method is not recommended,
1019 unless you want to get a specific component by full
1020 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
1021 should be used instead.
1022
1023 If C<$name> is a regexp, a list of components matched against the full
1024 component name will be returned.
1025
1026 If Catalyst can't find a component by name, it will fallback to regex
1027 matching by default. To disable this behaviour set
1028 disable_component_resolution_regex_fallback to a true value.
1029
1030     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
1031
1032 =cut
1033
1034 sub component {
1035     my ( $c, $name, @args ) = @_;
1036
1037     if( $name ) {
1038         my $comps = $c->components;
1039
1040         if( !ref $name ) {
1041             # is it the exact name?
1042             return $c->_filter_component( $comps->{ $name }, @args )
1043                        if exists $comps->{ $name };
1044
1045             # perhaps we just omitted "MyApp"?
1046             my $composed = ( ref $c || $c ) . "::${name}";
1047             return $c->_filter_component( $comps->{ $composed }, @args )
1048                        if exists $comps->{ $composed };
1049
1050             # search all of the models, views and controllers
1051             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
1052             return $c->_filter_component( $comp, @args ) if $comp;
1053         }
1054
1055         return
1056             if $c->config->{disable_component_resolution_regex_fallback};
1057
1058         # This is here so $c->comp( '::M::' ) works
1059         my $query = ref $name ? $name : qr{$name}i;
1060
1061         my @result = grep { m{$query} } keys %{ $c->components };
1062         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
1063
1064         if( $result[ 0 ] ) {
1065             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
1066             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
1067             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
1068             return $c->_filter_component( $result[ 0 ], @args );
1069         }
1070
1071         # I would expect to return an empty list here, but that breaks back-compat
1072     }
1073
1074     # fallback
1075     return sort keys %{ $c->components };
1076 }
1077
1078 =head2 CLASS DATA AND HELPER CLASSES
1079
1080 =head2 $c->config
1081
1082 Returns or takes a hashref containing the application's configuration.
1083
1084     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
1085
1086 You can also use a C<YAML>, C<XML> or L<Config::General> config file
1087 like C<myapp.conf> in your applications home directory. See
1088 L<Catalyst::Plugin::ConfigLoader>.
1089
1090 =head3 Cascading configuration
1091
1092 The config method is present on all Catalyst components, and configuration
1093 will be merged when an application is started. Configuration loaded with
1094 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
1095 followed by configuration in your top level C<MyApp> class. These two
1096 configurations are merged, and then configuration data whose hash key matches a
1097 component name is merged with configuration for that component.
1098
1099 The configuration for a component is then passed to the C<new> method when a
1100 component is constructed.
1101
1102 For example:
1103
1104     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
1105     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
1106
1107 will mean that C<MyApp::Model::Foo> receives the following data when
1108 constructed:
1109
1110     MyApp::Model::Foo->new({
1111         bar => 'baz',
1112         quux => 'frob',
1113         overrides => 'me',
1114     });
1115
1116 It's common practice to use a Moose attribute
1117 on the receiving component to access the config value.
1118
1119     package MyApp::Model::Foo;
1120
1121     use Moose;
1122
1123     # this attr will receive 'baz' at construction time
1124     has 'bar' => (
1125         is  => 'rw',
1126         isa => 'Str',
1127     );
1128
1129 You can then get the value 'baz' by calling $c->model('Foo')->bar
1130 (or $self->bar inside code in the model).
1131
1132 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
1133 as a way of reading config within your code, as this B<will not> give you the
1134 correctly merged config back. You B<MUST> take the config values supplied to
1135 the constructor and use those instead.
1136
1137 =cut
1138
1139 around config => sub {
1140     my $orig = shift;
1141     my $c = shift;
1142
1143     croak('Setting config after setup has been run is not allowed.')
1144         if ( @_ and $c->setup_finished );
1145
1146     $c->$orig(@_);
1147 };
1148
1149 =head2 $c->log
1150
1151 Returns the logging object instance. Unless it is already set, Catalyst
1152 sets this up with a L<Catalyst::Log> object. To use your own log class,
1153 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1154 C<< __PACKAGE__->setup >>.
1155
1156  __PACKAGE__->log( MyLogger->new );
1157  __PACKAGE__->setup;
1158
1159 And later:
1160
1161     $c->log->info( 'Now logging with my own logger!' );
1162
1163 Your log class should implement the methods described in
1164 L<Catalyst::Log>.
1165
1166 =head2 has_encoding
1167
1168 Returned True if there's a valid encoding
1169
1170 =head2 clear_encoding
1171
1172 Clears the encoding for the current context
1173
1174 =head2 encoding
1175
1176 Sets or gets the application encoding.  Setting encoding takes either an
1177 Encoding object or a string that we try to resolve via L<Encode::find_encoding>.
1178
1179 You would expect to get the encoding object back if you attempt to set it.  If
1180 there is a failure you will get undef returned and an error message in the log.
1181
1182 =cut
1183
1184 sub has_encoding { shift->encoding ? 1:0 }
1185
1186 sub clear_encoding {
1187     my $c = shift;
1188     if(blessed $c) {
1189         $c->encoding(undef);
1190     } else {
1191         $c->log->error("You can't clear encoding on the application");
1192     }
1193 }
1194
1195 sub encoding {
1196     my $c = shift;
1197     my $encoding;
1198
1199     if ( scalar @_ ) {
1200
1201         # Don't let one change this once we are too far into the response
1202         if(blessed $c && $c->res->finalized_headers) {
1203           Carp::croak("You may not change the encoding once the headers are finalized");
1204           return;
1205         }
1206
1207         # Let it be set to undef
1208         if (my $wanted = shift)  {
1209             $encoding = Encode::find_encoding($wanted)
1210               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1211             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1212         }
1213         else {
1214             binmode(STDERR);
1215         }
1216
1217         $encoding = ref $c
1218                   ? $c->{encoding} = $encoding
1219                   : $c->_encoding($encoding);
1220     } else {
1221       $encoding = ref $c && exists $c->{encoding}
1222                 ? $c->{encoding}
1223                 : $c->_encoding;
1224     }
1225
1226     return $encoding;
1227 }
1228
1229 =head2 $c->debug
1230
1231 Returns 1 if debug mode is enabled, 0 otherwise.
1232
1233 You can enable debug mode in several ways:
1234
1235 =over
1236
1237 =item By calling myapp_server.pl with the -d flag
1238
1239 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1240
1241 =item The -Debug option in your MyApp.pm
1242
1243 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1244
1245 =back
1246
1247 The first three also set the log level to 'debug'.
1248
1249 Calling C<< $c->debug(1) >> has no effect.
1250
1251 =cut
1252
1253 sub debug { 0 }
1254
1255 =head2 $c->dispatcher
1256
1257 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1258
1259 =head2 $c->engine
1260
1261 Returns the engine instance. See L<Catalyst::Engine>.
1262
1263
1264 =head2 UTILITY METHODS
1265
1266 =head2 $c->path_to(@path)
1267
1268 Merges C<@path> with C<< $c->config->{home} >> and returns a
1269 L<Path::Class::Dir> object. Note you can usually use this object as
1270 a filename, but sometimes you will have to explicitly stringify it
1271 yourself by calling the C<< ->stringify >> method.
1272
1273 For example:
1274
1275     $c->path_to( 'db', 'sqlite.db' );
1276
1277 =cut
1278
1279 sub path_to {
1280     my ( $c, @path ) = @_;
1281     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1282     if ( -d $path ) { return $path }
1283     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1284 }
1285
1286 sub plugin {
1287     my ( $class, $name, $plugin, @args ) = @_;
1288
1289     # See block comment in t/unit_core_plugin.t
1290     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1291
1292     $class->_register_plugin( $plugin, 1 );
1293
1294     eval { $plugin->import };
1295     $class->mk_classdata($name);
1296     my $obj;
1297     eval { $obj = $plugin->new(@args) };
1298
1299     if ($@) {
1300         Catalyst::Exception->throw( message =>
1301               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1302     }
1303
1304     $class->$name($obj);
1305     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1306       if $class->debug;
1307 }
1308
1309 =head2 MyApp->setup
1310
1311 Initializes the dispatcher and engine, loads any plugins, and loads the
1312 model, view, and controller components. You may also specify an array
1313 of plugins to load here, if you choose to not load them in the C<use
1314 Catalyst> line.
1315
1316     MyApp->setup;
1317     MyApp->setup( qw/-Debug/ );
1318
1319 B<Note:> You B<should not> wrap this method with method modifiers
1320 or bad things will happen - wrap the C<setup_finalize> method instead.
1321
1322 B<Note:> You can create a custom setup stage that will execute when the
1323 application is starting.  Use this to customize setup.
1324
1325     MyApp->setup(-Custom=value);
1326
1327     sub setup_custom {
1328       my ($class, $value) = @_;
1329     }
1330
1331 Can be handy if you want to hook into the setup phase.
1332
1333 =cut
1334
1335 sub setup {
1336     my ( $class, @arguments ) = @_;
1337     croak('Running setup more than once')
1338         if ( $class->setup_finished );
1339
1340     unless ( $class->isa('Catalyst') ) {
1341
1342         Catalyst::Exception->throw(
1343             message => qq/'$class' does not inherit from Catalyst/ );
1344     }
1345
1346     if ( $class->arguments ) {
1347         @arguments = ( @arguments, @{ $class->arguments } );
1348     }
1349
1350     # Process options
1351     my $flags = {};
1352
1353     foreach (@arguments) {
1354
1355         if (/^-Debug$/) {
1356             $flags->{log} =
1357               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1358         }
1359         elsif (/^-(\w+)=?(.*)$/) {
1360             $flags->{ lc $1 } = $2;
1361         }
1362         else {
1363             push @{ $flags->{plugins} }, $_;
1364         }
1365     }
1366
1367     $class->setup_home( delete $flags->{home} );
1368
1369     $class->setup_log( delete $flags->{log} );
1370     $class->setup_plugins( delete $flags->{plugins} );
1371
1372     $class->setup_data_handlers();
1373     $class->setup_dispatcher( delete $flags->{dispatcher} );
1374     if (my $engine = delete $flags->{engine}) {
1375         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1376     }
1377     $class->setup_engine();
1378     $class->setup_stats( delete $flags->{stats} );
1379
1380     for my $flag ( sort keys %{$flags} ) {
1381
1382         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1383             &$code( $class, delete $flags->{$flag} );
1384         }
1385         else {
1386             $class->log->warn(qq/Unknown flag "$flag"/);
1387         }
1388     }
1389
1390     eval { require Catalyst::Devel; };
1391     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1392         $class->log->warn(<<"EOF");
1393 You are running an old script!
1394
1395   Please update by running (this will overwrite existing files):
1396     catalyst.pl -force -scripts $class
1397
1398   or (this will not overwrite existing files):
1399     catalyst.pl -scripts $class
1400
1401 EOF
1402     }
1403
1404     # Call plugins setup, this is stupid and evil.
1405     # Also screws C3 badly on 5.10, hack to avoid.
1406     {
1407         no warnings qw/redefine/;
1408         local *setup = sub { };
1409         $class->setup unless $Catalyst::__AM_RESTARTING;
1410     }
1411
1412     # If you are expecting configuration info as part of your setup, it needs
1413     # to get called here and below, since we need the above line to support
1414     # ConfigLoader based configs.
1415
1416     $class->setup_encoding();
1417     $class->setup_middleware();
1418
1419     # Initialize our data structure
1420     $class->components( {} );
1421
1422     $class->setup_components;
1423
1424     if ( $class->debug ) {
1425         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1426
1427         if (@plugins) {
1428             my $column_width = Catalyst::Utils::term_width() - 6;
1429             my $t = Text::SimpleTable->new($column_width);
1430             $t->row($_) for @plugins;
1431             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1432         }
1433
1434         my @middleware = map {
1435           ref $_ eq 'CODE' ?
1436             "Inline Coderef" :
1437               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1438                 || '')  } $class->registered_middlewares;
1439
1440         if (@middleware) {
1441             my $column_width = Catalyst::Utils::term_width() - 6;
1442             my $t = Text::SimpleTable->new($column_width);
1443             $t->row($_) for @middleware;
1444             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1445         }
1446
1447         my %dh = $class->registered_data_handlers;
1448         if (my @data_handlers = keys %dh) {
1449             my $column_width = Catalyst::Utils::term_width() - 6;
1450             my $t = Text::SimpleTable->new($column_width);
1451             $t->row($_) for @data_handlers;
1452             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1453         }
1454
1455         my $dispatcher = $class->dispatcher;
1456         my $engine     = $class->engine;
1457         my $home       = $class->config->{home};
1458
1459         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1460         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1461
1462         $home
1463           ? ( -d $home )
1464           ? $class->log->debug(qq/Found home "$home"/)
1465           : $class->log->debug(qq/Home "$home" doesn't exist/)
1466           : $class->log->debug(q/Couldn't find home/);
1467
1468         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1469
1470         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1471         for my $comp ( sort keys %{ $class->components } ) {
1472             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1473             $t->row( $comp, $type );
1474         }
1475         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1476           if ( keys %{ $class->components } );
1477     }
1478
1479     # Add our self to components, since we are also a component
1480     if( $class->isa('Catalyst::Controller') ){
1481       $class->components->{$class} = $class;
1482     }
1483
1484     $class->setup_actions;
1485
1486     if ( $class->debug ) {
1487         my $name = $class->config->{name} || 'Application';
1488         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1489     }
1490
1491     if ($class->config->{case_sensitive}) {
1492         $class->log->warn($class . "->config->{case_sensitive} is set.");
1493         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1494     }
1495
1496     # call these so we pre setup the composed classes
1497     $class->composed_request_class;
1498     $class->composed_response_class;
1499     $class->composed_stats_class;
1500
1501     $class->setup_finalize;
1502
1503     # Flush the log for good measure (in case something turned off 'autoflush' early)
1504     $class->log->_flush() if $class->log->can('_flush');
1505
1506     return $class || 1; # Just in case someone named their Application 0...
1507 }
1508
1509 =head2 $app->setup_finalize
1510
1511 A hook to attach modifiers to. This method does not do anything except set the
1512 C<setup_finished> accessor.
1513
1514 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1515
1516 Example:
1517
1518     after setup_finalize => sub {
1519         my $app = shift;
1520
1521         ## do stuff here..
1522     };
1523
1524 =cut
1525
1526 sub setup_finalize {
1527     my ($class) = @_;
1528     $class->setup_finished(1);
1529 }
1530
1531 =head2 $c->uri_for( $path?, @args?, \%query_values?, \$fragment? )
1532
1533 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values?, \$fragment? )
1534
1535 =head2 $c->uri_for( $action, [@captures, @args], \%query_values?, \$fragment? )
1536
1537 Constructs an absolute L<URI> object based on the application root, the
1538 provided path, and the additional arguments and query parameters provided.
1539 When used as a string, provides a textual URI.  If you need more flexibility
1540 than this (i.e. the option to provide relative URIs etc.) see
1541 L<Catalyst::Plugin::SmartURI>.
1542
1543 If no arguments are provided, the URI for the current action is returned.
1544 To return the current action and also provide @args, use
1545 C<< $c->uri_for( $c->action, @args ) >>.
1546
1547 If the first argument is a string, it is taken as a public URI path relative
1548 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1549 relative to the application root (if it does). It is then merged with
1550 C<< $c->request->base >>; any C<@args> are appended as additional path
1551 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1552
1553 B<NOTE> If you are using this 'stringy' first argument, we skip encoding and
1554 allow you to declare something like:
1555
1556     $c->uri_for('/foo/bar#baz')
1557
1558 Where 'baz' is a URI fragment.  We consider this first argument string to be
1559 'expert' mode where you are expected to create a valid URL and we for the most
1560 part just pass it through without a lot of internal effort to escape and encode.
1561
1562 If the first argument is a L<Catalyst::Action> it represents an action which
1563 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1564 optional C<\@captures> argument (an arrayref) allows passing the captured
1565 variables that are needed to fill in the paths of Chained and Regex actions;
1566 once the path is resolved, C<uri_for> continues as though a path was
1567 provided, appending any arguments or parameters and creating an absolute
1568 URI.
1569
1570 The captures for the current request can be found in
1571 C<< $c->request->captures >>, and actions can be resolved using
1572 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1573 path, use C<< $c->uri_for_action >> instead.
1574
1575   # Equivalent to $c->req->uri
1576   $c->uri_for($c->action, $c->req->captures,
1577       @{ $c->req->args }, $c->req->params);
1578
1579   # For the Foo action in the Bar controller
1580   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1581
1582   # Path to a static resource
1583   $c->uri_for('/static/images/logo.png');
1584
1585 In general the scheme of the generated URI object will follow the incoming request
1586 however if your targeted action or action chain has the Scheme attribute it will
1587 use that instead.
1588
1589 Also, if the targeted Action or Action chain declares Args/CaptureArgs that have
1590 type constraints, we will require that your proposed URL verify on those declared
1591 constraints.
1592
1593 =cut
1594
1595 sub uri_for {
1596     my ( $c, $path, @args ) = @_;
1597
1598     if ( $path->$_isa('Catalyst::Controller') ) {
1599         $path = $path->path_prefix;
1600         $path =~ s{/+\z}{};
1601         $path .= '/';
1602     }
1603
1604     my $fragment =  ((scalar(@args) && ref($args[-1]) eq 'SCALAR') ? pop @args : undef );
1605
1606     unless(blessed $path) {
1607       if (defined($path) and $path =~ s/#(.+)$//)  {
1608         if(defined($1) and $fragment) {
1609           carp "Abiguious fragment declaration: You cannot define a fragment in '$path' and as an argument '$fragment'";
1610         }
1611         if(defined($1)) {
1612           $fragment = $1;
1613         }
1614       }
1615     }
1616
1617     my $params =
1618       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1619
1620     undef($path) if (defined $path && $path eq '');
1621
1622     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1623
1624     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1625     if ( $path->$_isa('Catalyst::Action') ) { # action object
1626         s|/|%2F|g for @args;
1627         my $captures = [ map { s|/|%2F|g; $_; }
1628                         ( scalar @args && ref $args[0] eq 'ARRAY'
1629                          ? @{ shift(@args) }
1630                          : ()) ];
1631
1632         my $action = $path;
1633         my $expanded_action = $c->dispatcher->expand_action( $action );
1634         my $num_captures = $expanded_action->number_of_captures;
1635
1636         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1637         if( !@args && $action->number_of_args ) {
1638           unshift @args, splice @$captures, $num_captures;
1639         }
1640
1641         if($num_captures) {
1642           unless($expanded_action->match_captures_constraints($c, $captures)) {
1643             carp "captures [@{$captures}] do not match the type constraints in actionchain ending with '$expanded_action'";
1644             return;
1645           }
1646         }
1647
1648         $path = $c->dispatcher->uri_for_action($action, $captures);
1649         if (not defined $path) {
1650             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1651                 if $c->debug;
1652             return undef;
1653         }
1654         $path = '/' if $path eq '';
1655
1656         # At this point @encoded_args is the remaining Args (all captures removed).
1657         if($expanded_action->has_args_constraints) {
1658           unless($expanded_action->match_args($c,\@args)) {
1659              carp "args [@args] do not match the type constraints in action '$expanded_action'";
1660              return;
1661           }
1662         }
1663     }
1664
1665     unshift(@args, $path);
1666
1667     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1668         my $namespace = $c->namespace;
1669         if (defined $path) { # cheesy hack to handle path '../foo'
1670            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1671         }
1672         unshift(@args, $namespace || '');
1673     }
1674
1675     # join args with '/', or a blank string
1676     my $args = join('/', grep { defined($_) } @args);
1677     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1678     $args =~ s!^/+!!;
1679
1680     my ($base, $class) = ('/', 'URI::_generic');
1681     if(blessed($c)) {
1682       $base = $c->req->base;
1683       if($target_action) {
1684         $target_action = $c->dispatcher->expand_action($target_action);
1685         if(my $s = $target_action->scheme) {
1686           $s = lc($s);
1687           $class = "URI::$s";
1688           $base->scheme($s);
1689         } else {
1690           $class = ref($base);
1691         }
1692       } else {
1693         $class = ref($base);
1694       }
1695
1696       $base =~ s{(?<!/)$}{/};
1697     }
1698
1699     my $query = '';
1700     if (my @keys = keys %$params) {
1701       # somewhat lifted from URI::_query's query_form
1702       $query = '?'.join('&', map {
1703           my $val = $params->{$_};
1704           my $key = encode_utf8($_);
1705           # using the URI::Escape pattern here so utf8 chars survive
1706           $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1707           $key =~ s/ /+/g;
1708
1709           $val = '' unless defined $val;
1710           (map {
1711               my $param = encode_utf8($_);
1712               # using the URI::Escape pattern here so utf8 chars survive
1713               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1714               $param =~ s/ /+/g;
1715
1716               "${key}=$param";
1717           } ( ref $val eq 'ARRAY' ? @$val : $val ));
1718       } @keys);
1719     }
1720
1721     $base = encode_utf8 $base;
1722     $base =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1723     $args = encode_utf8 $args;
1724     $args =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1725
1726     if(defined $fragment) {
1727       if(blessed $path) {
1728         $fragment = encode_utf8(${$fragment});
1729         $fragment =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1730         $fragment =~ s/ /+/g;
1731       }
1732       $query .= "#$fragment";
1733     }
1734
1735     my $res = bless(\"${base}${args}${query}", $class);
1736     $res;
1737 }
1738
1739 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1740
1741 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1742
1743 =over
1744
1745 =item $path
1746
1747 A private path to the Catalyst action you want to create a URI for.
1748
1749 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1750 >> and passing the resulting C<$action> and the remaining arguments to C<<
1751 $c->uri_for >>.
1752
1753 You can also pass in a Catalyst::Action object, in which case it is passed to
1754 C<< $c->uri_for >>.
1755
1756 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1757
1758 For example, if the action looks like:
1759
1760  package MyApp::Controller::Users;
1761
1762  sub lst : Path('the-list') {}
1763
1764 You can use:
1765
1766  $c->uri_for_action('/users/lst')
1767
1768 and it will create the URI /users/the-list.
1769
1770 =item \@captures_and_args?
1771
1772 Optional array reference of Captures (i.e. C<CaptureArgs> or C<< $c->req->captures >>)
1773 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1774 to interpolate all the parameters in the URI.
1775
1776 =item @args?
1777
1778 Optional list of extra arguments - can be supplied in the
1779 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1780 code.
1781
1782 Your action can have zero, a fixed or a variable number of args (e.g.
1783 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1784
1785 =item \%query_values?
1786
1787 Optional array reference of query parameters to append. E.g.
1788
1789   { foo => 'bar' }
1790
1791 will generate
1792
1793   /rest/of/your/uri?foo=bar
1794
1795 =back
1796
1797 =cut
1798
1799 sub uri_for_action {
1800     my ( $c, $path, @args ) = @_;
1801     my $action = blessed($path)
1802       ? $path
1803       : $c->dispatcher->get_action_by_path($path);
1804     unless (defined $action) {
1805       croak "Can't find action for path '$path'";
1806     }
1807     return $c->uri_for( $action, @args );
1808 }
1809
1810 =head2 $c->welcome_message
1811
1812 Returns the Catalyst welcome HTML page.
1813
1814 =cut
1815
1816 sub welcome_message {
1817     my $c      = shift;
1818     my $name   = $c->config->{name};
1819     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1820     my $prefix = Catalyst::Utils::appprefix( ref $c );
1821     $c->response->content_type('text/html; charset=utf-8');
1822     return <<"EOF";
1823 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1824     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1825 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1826     <head>
1827     <meta http-equiv="Content-Language" content="en" />
1828     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1829         <title>$name on Catalyst $VERSION</title>
1830         <style type="text/css">
1831             body {
1832                 color: #000;
1833                 background-color: #eee;
1834             }
1835             div#content {
1836                 width: 640px;
1837                 margin-left: auto;
1838                 margin-right: auto;
1839                 margin-top: 10px;
1840                 margin-bottom: 10px;
1841                 text-align: left;
1842                 background-color: #ccc;
1843                 border: 1px solid #aaa;
1844             }
1845             p, h1, h2 {
1846                 margin-left: 20px;
1847                 margin-right: 20px;
1848                 font-family: verdana, tahoma, sans-serif;
1849             }
1850             a {
1851                 font-family: verdana, tahoma, sans-serif;
1852             }
1853             :link, :visited {
1854                     text-decoration: none;
1855                     color: #b00;
1856                     border-bottom: 1px dotted #bbb;
1857             }
1858             :link:hover, :visited:hover {
1859                     color: #555;
1860             }
1861             div#topbar {
1862                 margin: 0px;
1863             }
1864             pre {
1865                 margin: 10px;
1866                 padding: 8px;
1867             }
1868             div#answers {
1869                 padding: 8px;
1870                 margin: 10px;
1871                 background-color: #fff;
1872                 border: 1px solid #aaa;
1873             }
1874             h1 {
1875                 font-size: 0.9em;
1876                 font-weight: normal;
1877                 text-align: center;
1878             }
1879             h2 {
1880                 font-size: 1.0em;
1881             }
1882             p {
1883                 font-size: 0.9em;
1884             }
1885             p img {
1886                 float: right;
1887                 margin-left: 10px;
1888             }
1889             span#appname {
1890                 font-weight: bold;
1891                 font-size: 1.6em;
1892             }
1893         </style>
1894     </head>
1895     <body>
1896         <div id="content">
1897             <div id="topbar">
1898                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1899                     $VERSION</h1>
1900              </div>
1901              <div id="answers">
1902                  <p>
1903                  <img src="$logo" alt="Catalyst Logo" />
1904                  </p>
1905                  <p>Welcome to the  world of Catalyst.
1906                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1907                     framework will make web development something you had
1908                     never expected it to be: Fun, rewarding, and quick.</p>
1909                  <h2>What to do now?</h2>
1910                  <p>That really depends  on what <b>you</b> want to do.
1911                     We do, however, provide you with a few starting points.</p>
1912                  <p>If you want to jump right into web development with Catalyst
1913                     you might want to start with a tutorial.</p>
1914 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1915 </pre>
1916 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1917 <pre>
1918 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1919 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1920 </code></pre>
1921                  <h2>What to do next?</h2>
1922                  <p>Next it's time to write an actual application. Use the
1923                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1924                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1925                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1926                     they can save you a lot of work.</p>
1927                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1928                     <p>Also, be sure to check out the vast and growing
1929                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1930                     you are likely to find what you need there.
1931                     </p>
1932
1933                  <h2>Need help?</h2>
1934                  <p>Catalyst has a very active community. Here are the main places to
1935                     get in touch with us.</p>
1936                  <ul>
1937                      <li>
1938                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1939                      </li>
1940                      <li>
1941                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1942                      </li>
1943                      <li>
1944                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1945                      </li>
1946                  </ul>
1947                  <h2>In conclusion</h2>
1948                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1949                     as we enjoyed making it. Please contact us if you have ideas
1950                     for improvement or other feedback.</p>
1951              </div>
1952          </div>
1953     </body>
1954 </html>
1955 EOF
1956 }
1957
1958 =head2 run_options
1959
1960 Contains a hash of options passed from the application script, including
1961 the original ARGV the script received, the processed values from that
1962 ARGV and any extra arguments to the script which were not processed.
1963
1964 This can be used to add custom options to your application's scripts
1965 and setup your application differently depending on the values of these
1966 options.
1967
1968 =head1 INTERNAL METHODS
1969
1970 These methods are not meant to be used by end users.
1971
1972 =head2 $c->components
1973
1974 Returns a hash of components.
1975
1976 =head2 $c->context_class
1977
1978 Returns or sets the context class.
1979
1980 =head2 $c->counter
1981
1982 Returns a hashref containing coderefs and execution counts (needed for
1983 deep recursion detection).
1984
1985 =head2 $c->depth
1986
1987 Returns the number of actions on the current internal execution stack.
1988
1989 =head2 $c->dispatch
1990
1991 Dispatches a request to actions.
1992
1993 =cut
1994
1995 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1996
1997 =head2 $c->dispatcher_class
1998
1999 Returns or sets the dispatcher class.
2000
2001 =head2 $c->dump_these
2002
2003 Returns a list of 2-element array references (name, structure) pairs
2004 that will be dumped on the error page in debug mode.
2005
2006 =cut
2007
2008 sub dump_these {
2009     my $c = shift;
2010     [ Request => $c->req ],
2011     [ Response => $c->res ],
2012     [ Stash => $c->stash ],
2013     [ Config => $c->config ];
2014 }
2015
2016 =head2 $c->engine_class
2017
2018 Returns or sets the engine class.
2019
2020 =head2 $c->execute( $class, $coderef )
2021
2022 Execute a coderef in given class and catch exceptions. Errors are available
2023 via $c->error.
2024
2025 =cut
2026
2027 sub execute {
2028     my ( $c, $class, $code ) = @_;
2029     $class = $c->component($class) || $class;
2030     #$c->state(0);
2031
2032     if ( $c->depth >= $RECURSION ) {
2033         my $action = $code->reverse();
2034         $action = "/$action" unless $action =~ /->/;
2035         my $error = qq/Deep recursion detected calling "${action}"/;
2036         $c->log->error($error);
2037         $c->error($error);
2038         $c->state(0);
2039         return $c->state;
2040     }
2041
2042     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
2043
2044     push( @{ $c->stack }, $code );
2045
2046     no warnings 'recursion';
2047     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
2048     #      I have no idea how, ergo $ret (which appears to fix the issue)
2049     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
2050
2051     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
2052
2053     my $last = pop( @{ $c->stack } );
2054
2055     if ( my $error = $@ ) {
2056         #rethow if this can be handled by middleware
2057         if ( $c->_handle_http_exception($error) ) {
2058             foreach my $err (@{$c->error}) {
2059                 $c->log->error($err);
2060             }
2061             $c->clear_errors;
2062             $c->log->_flush if $c->log->can('_flush');
2063
2064             $error->can('rethrow') ? $error->rethrow : croak $error;
2065         }
2066         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
2067             $error->rethrow if $c->depth > 1;
2068         }
2069         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
2070             $error->rethrow if $c->depth > 0;
2071         }
2072         else {
2073             unless ( ref $error ) {
2074                 no warnings 'uninitialized';
2075                 chomp $error;
2076                 my $class = $last->class;
2077                 my $name  = $last->name;
2078                 $error = qq/Caught exception in $class->$name "$error"/;
2079             }
2080             $c->error($error);
2081         }
2082         #$c->state(0);
2083     }
2084     return $c->state;
2085 }
2086
2087 sub _stats_start_execute {
2088     my ( $c, $code ) = @_;
2089     my $appclass = ref($c) || $c;
2090     return if ( ( $code->name =~ /^_.*/ )
2091         && ( !$appclass->config->{show_internal_actions} ) );
2092
2093     my $action_name = $code->reverse();
2094     $c->counter->{$action_name}++;
2095
2096     my $action = $action_name;
2097     $action = "/$action" unless $action =~ /->/;
2098
2099     # determine if the call was the result of a forward
2100     # this is done by walking up the call stack and looking for a calling
2101     # sub of Catalyst::forward before the eval
2102     my $callsub = q{};
2103     for my $index ( 2 .. 11 ) {
2104         last
2105         if ( ( caller($index) )[0] eq 'Catalyst'
2106             && ( caller($index) )[3] eq '(eval)' );
2107
2108         if ( ( caller($index) )[3] =~ /forward$/ ) {
2109             $callsub = ( caller($index) )[3];
2110             $action  = "-> $action";
2111             last;
2112         }
2113     }
2114
2115     my $uid = $action_name . $c->counter->{$action_name};
2116
2117     # is this a root-level call or a forwarded call?
2118     if ( $callsub =~ /forward$/ ) {
2119         my $parent = $c->stack->[-1];
2120
2121         # forward, locate the caller
2122         if ( defined $parent && exists $c->counter->{"$parent"} ) {
2123             $c->stats->profile(
2124                 begin  => $action,
2125                 parent => "$parent" . $c->counter->{"$parent"},
2126                 uid    => $uid,
2127             );
2128         }
2129         else {
2130
2131             # forward with no caller may come from a plugin
2132             $c->stats->profile(
2133                 begin => $action,
2134                 uid   => $uid,
2135             );
2136         }
2137     }
2138     else {
2139
2140         # root-level call
2141         $c->stats->profile(
2142             begin => $action,
2143             uid   => $uid,
2144         );
2145     }
2146     return $action;
2147
2148 }
2149
2150 sub _stats_finish_execute {
2151     my ( $c, $info ) = @_;
2152     $c->stats->profile( end => $info );
2153 }
2154
2155 =head2 $c->finalize
2156
2157 Finalizes the request.
2158
2159 =cut
2160
2161 sub finalize {
2162     my $c = shift;
2163
2164     for my $error ( @{ $c->error } ) {
2165         $c->log->error($error);
2166     }
2167
2168     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
2169     # stuff like cometd and websockets
2170
2171     if($c->request->_has_io_fh) {
2172       $c->log_response;
2173       return;
2174     }
2175
2176     # Allow engine to handle finalize flow (for POE)
2177     my $engine = $c->engine;
2178     if ( my $code = $engine->can('finalize') ) {
2179         $engine->$code($c);
2180     }
2181     else {
2182
2183         $c->finalize_uploads;
2184
2185         # Error
2186         if ( $#{ $c->error } >= 0 ) {
2187             $c->finalize_error;
2188         }
2189
2190         $c->finalize_encoding;
2191         $c->finalize_headers unless $c->response->finalized_headers;
2192         $c->finalize_body;
2193     }
2194
2195     $c->log_response;
2196
2197     if ($c->use_stats) {
2198         my $elapsed = $c->stats->elapsed;
2199         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
2200         $c->log->info(
2201             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
2202     }
2203
2204     return $c->response->status;
2205 }
2206
2207 =head2 $c->finalize_body
2208
2209 Finalizes body.
2210
2211 =cut
2212
2213 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
2214
2215 =head2 $c->finalize_cookies
2216
2217 Finalizes cookies.
2218
2219 =cut
2220
2221 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
2222
2223 =head2 $c->finalize_error
2224
2225 Finalizes error.  If there is only one error in L</error> and it is an object that
2226 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2227 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2228 return the default error page (production mode).
2229
2230 =cut
2231
2232 sub finalize_error {
2233     my $c = shift;
2234     if($#{$c->error} > 0) {
2235         $c->engine->finalize_error( $c, @_ );
2236     } else {
2237         my ($error) = @{$c->error};
2238         if ( $c->_handle_http_exception($error) ) {
2239             # In the case where the error 'knows what it wants', becauses its PSGI
2240             # aware, just rethow and let middleware catch it
2241             $error->can('rethrow') ? $error->rethrow : croak $error;
2242         } else {
2243             $c->engine->finalize_error( $c, @_ )
2244         }
2245     }
2246 }
2247
2248 =head2 $c->finalize_headers
2249
2250 Finalizes headers.
2251
2252 =cut
2253
2254 sub finalize_headers {
2255     my $c = shift;
2256
2257     my $response = $c->response; #accessor calls can add up?
2258
2259     # Check if we already finalized headers
2260     return if $response->finalized_headers;
2261
2262     # Handle redirects
2263     if ( my $location = $response->redirect ) {
2264         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2265         $response->header( Location => $location );
2266     }
2267
2268     # Remove incorrectly added body and content related meta data when returning
2269     # an information response, or a response the is required to not include a body
2270
2271     $c->finalize_cookies;
2272
2273     # This currently is a NOOP but I don't want to remove it since I guess people
2274     # might have Response subclasses that use it for something... (JNAP)
2275     $c->response->finalize_headers();
2276
2277     # Done
2278     $response->finalized_headers(1);
2279 }
2280
2281 =head2 $c->finalize_encoding
2282
2283 Make sure your body is encoded properly IF you set an encoding.  By
2284 default the encoding is UTF-8 but you can disable it by explicitly setting the
2285 encoding configuration value to undef.
2286
2287 We can only encode when the body is a scalar.  Methods for encoding via the
2288 streaming interfaces (such as C<write> and C<write_fh> on L<Catalyst::Response>
2289 are available).
2290
2291 See L</ENCODING>.
2292
2293 =cut
2294
2295 sub finalize_encoding {
2296     my $c = shift;
2297     my $res = $c->res || return;
2298
2299     # Warn if the set charset is different from the one you put into encoding.  We need
2300     # to do this early since encodable_response is false for this condition and we need
2301     # to match the debug output for backcompat (there's a test for this...) -JNAP
2302     if(
2303       $res->content_type_charset and $c->encoding and
2304       (uc($c->encoding->mime_name) ne uc($res->content_type_charset))
2305     ) {
2306         my $ct = lc($res->content_type_charset);
2307         $c->log->debug("Catalyst encoding config is set to encode in '" .
2308             $c->encoding->mime_name .
2309             "', content type is '$ct', not encoding ");
2310     }
2311
2312     if(
2313       ($res->encodable_response) and
2314       (defined($res->body)) and
2315       (ref(\$res->body) eq 'SCALAR')
2316     ) {
2317         # if you are finding yourself here and your body is already encoded correctly
2318         # and you want to turn this off, use $c->clear_encoding to prevent encoding
2319         # at this step, or set encoding to undef in the config to do so for the whole
2320         # application.  See the ENCODING documentaiton for better notes.
2321         $c->res->body( $c->encoding->encode( $c->res->body, $c->_encode_check ) );
2322
2323         # Set the charset if necessary.  This might be a bit bonkers since encodable response
2324         # is false when the set charset is not the same as the encoding mimetype (maybe
2325         # confusing action at a distance here..
2326         # Don't try to set the charset if one already exists or if headers are already finalized
2327         $c->res->content_type($c->res->content_type . "; charset=" . $c->encoding->mime_name)
2328           unless($c->res->content_type_charset ||
2329                 ($c->res->_context && $c->res->finalized_headers && !$c->res->_has_response_cb));
2330     }
2331 }
2332
2333 =head2 $c->finalize_output
2334
2335 An alias for finalize_body.
2336
2337 =head2 $c->finalize_read
2338
2339 Finalizes the input after reading is complete.
2340
2341 =cut
2342
2343 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2344
2345 =head2 $c->finalize_uploads
2346
2347 Finalizes uploads. Cleans up any temporary files.
2348
2349 =cut
2350
2351 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2352
2353 =head2 $c->get_action( $action, $namespace )
2354
2355 Gets an action in a given namespace.
2356
2357 =cut
2358
2359 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2360
2361 =head2 $c->get_actions( $action, $namespace )
2362
2363 Gets all actions of a given name in a namespace and all parent
2364 namespaces.
2365
2366 =cut
2367
2368 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2369
2370 =head2 $app->handle_request( @arguments )
2371
2372 Called to handle each HTTP request.
2373
2374 =cut
2375
2376 sub handle_request {
2377     my ( $class, @arguments ) = @_;
2378
2379     # Always expect worst case!
2380     my $status = -1;
2381     try {
2382         if ($class->debug) {
2383             my $secs = time - $START || 1;
2384             my $av = sprintf '%.3f', $COUNT / $secs;
2385             my $time = localtime time;
2386             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2387         }
2388
2389         my $c = $class->prepare(@arguments);
2390         $c->dispatch;
2391         $status = $c->finalize;
2392     } catch {
2393         #rethow if this can be handled by middleware
2394         if ( $class->_handle_http_exception($_) ) {
2395             $_->can('rethrow') ? $_->rethrow : croak $_;
2396         }
2397         chomp(my $error = $_);
2398         $class->log->error(qq/Caught exception in engine "$error"/);
2399     };
2400
2401     $COUNT++;
2402
2403     if(my $coderef = $class->log->can('_flush')){
2404         $class->log->$coderef();
2405     }
2406     return $status;
2407 }
2408
2409 =head2 $class->prepare( @arguments )
2410
2411 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2412 etc.).
2413
2414 =cut
2415
2416 has _uploadtmp => (
2417     is => 'ro',
2418     predicate => '_has_uploadtmp',
2419 );
2420
2421 sub prepare {
2422     my ( $class, @arguments ) = @_;
2423
2424     # XXX
2425     # After the app/ctxt split, this should become an attribute based on something passed
2426     # into the application.
2427     $class->context_class( ref $class || $class ) unless $class->context_class;
2428
2429     my $uploadtmp = $class->config->{uploadtmp};
2430     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2431
2432     $c->response->_context($c);
2433     $c->stats($class->stats_class->new)->enable($c->use_stats);
2434
2435     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2436         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2437     }
2438
2439     try {
2440         # Allow engine to direct the prepare flow (for POE)
2441         if ( my $prepare = $c->engine->can('prepare') ) {
2442             $c->engine->$prepare( $c, @arguments );
2443         }
2444         else {
2445             $c->prepare_request(@arguments);
2446             $c->prepare_connection;
2447             $c->prepare_query_parameters;
2448             $c->prepare_headers; # Just hooks, no longer needed - they just
2449             $c->prepare_cookies; # cause the lazy attribute on req to build
2450             $c->prepare_path;
2451
2452             # Prepare the body for reading, either by prepare_body
2453             # or the user, if they are using $c->read
2454             $c->prepare_read;
2455
2456             # Parse the body unless the user wants it on-demand
2457             unless ( ref($c)->config->{parse_on_demand} ) {
2458                 $c->prepare_body;
2459             }
2460         }
2461         $c->prepare_action;
2462     }
2463     # VERY ugly and probably shouldn't rely on ->finalize actually working
2464     catch {
2465         # failed prepare is always due to an invalid request, right?
2466         # Note we call finalize and then die here, which escapes
2467         # finalize being called in the enclosing block..
2468         # It in fact couldn't be called, as we don't return $c..
2469         # This is a mess - but I'm unsure you can fix this without
2470         # breaking compat for people doing crazy things (we should set
2471         # the 400 and just return the ctx here IMO, letting finalize get called
2472         # above...
2473         if ( $c->_handle_http_exception($_) ) {
2474             foreach my $err (@{$c->error}) {
2475                 $c->log->error($err);
2476             }
2477             $c->clear_errors;
2478             $c->log->_flush if $c->log->can('_flush');
2479             $_->can('rethrow') ? $_->rethrow : croak $_;
2480         } else {
2481             $c->response->status(400);
2482             $c->response->content_type('text/plain');
2483             $c->response->body('Bad Request');
2484             $c->finalize;
2485             die $_;
2486         }
2487     };
2488
2489     $c->log_request;
2490     $c->{stash} = $c->stash;
2491     Scalar::Util::weaken($c->{stash});
2492
2493     return $c;
2494 }
2495
2496 =head2 $c->prepare_action
2497
2498 Prepares action. See L<Catalyst::Dispatcher>.
2499
2500 =cut
2501
2502 sub prepare_action {
2503     my $c = shift;
2504     my $ret = $c->dispatcher->prepare_action( $c, @_);
2505
2506     if($c->encoding) {
2507         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2508           $_ = $c->_handle_param_unicode_decoding($_);
2509         }
2510     }
2511
2512     return $ret;
2513 }
2514
2515
2516 =head2 $c->prepare_body
2517
2518 Prepares message body.
2519
2520 =cut
2521
2522 sub prepare_body {
2523     my $c = shift;
2524
2525     return if $c->request->_has_body;
2526
2527     # Initialize on-demand data
2528     $c->engine->prepare_body( $c, @_ );
2529     $c->prepare_parameters;
2530     $c->prepare_uploads;
2531 }
2532
2533 =head2 $c->prepare_body_chunk( $chunk )
2534
2535 Prepares a chunk of data before sending it to L<HTTP::Body>.
2536
2537 See L<Catalyst::Engine>.
2538
2539 =cut
2540
2541 sub prepare_body_chunk {
2542     my $c = shift;
2543     $c->engine->prepare_body_chunk( $c, @_ );
2544 }
2545
2546 =head2 $c->prepare_body_parameters
2547
2548 Prepares body parameters.
2549
2550 =cut
2551
2552 sub prepare_body_parameters {
2553     my $c = shift;
2554     $c->request->prepare_body_parameters( $c, @_ );
2555 }
2556
2557 =head2 $c->prepare_connection
2558
2559 Prepares connection.
2560
2561 =cut
2562
2563 sub prepare_connection {
2564     my $c = shift;
2565     $c->request->prepare_connection($c);
2566 }
2567
2568 =head2 $c->prepare_cookies
2569
2570 Prepares cookies by ensuring that the attribute on the request
2571 object has been built.
2572
2573 =cut
2574
2575 sub prepare_cookies { my $c = shift; $c->request->cookies }
2576
2577 =head2 $c->prepare_headers
2578
2579 Prepares request headers by ensuring that the attribute on the request
2580 object has been built.
2581
2582 =cut
2583
2584 sub prepare_headers { my $c = shift; $c->request->headers }
2585
2586 =head2 $c->prepare_parameters
2587
2588 Prepares parameters.
2589
2590 =cut
2591
2592 sub prepare_parameters {
2593     my $c = shift;
2594     $c->prepare_body_parameters;
2595     $c->engine->prepare_parameters( $c, @_ );
2596 }
2597
2598 =head2 $c->prepare_path
2599
2600 Prepares path and base.
2601
2602 =cut
2603
2604 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2605
2606 =head2 $c->prepare_query_parameters
2607
2608 Prepares query parameters.
2609
2610 =cut
2611
2612 sub prepare_query_parameters {
2613     my $c = shift;
2614
2615     $c->engine->prepare_query_parameters( $c, @_ );
2616 }
2617
2618 =head2 $c->log_request
2619
2620 Writes information about the request to the debug logs.  This includes:
2621
2622 =over 4
2623
2624 =item * Request method, path, and remote IP address
2625
2626 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2627
2628 =item * Request parameters
2629
2630 =item * File uploads
2631
2632 =back
2633
2634 =cut
2635
2636 sub log_request {
2637     my $c = shift;
2638
2639     return unless $c->debug;
2640
2641     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2642     my $request = $dump->[1];
2643
2644     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2645     $method ||= '';
2646     $path = '/' unless length $path;
2647     $address ||= '';
2648
2649     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2650     $path = decode_utf8($path);
2651
2652     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2653
2654     $c->log_request_headers($request->headers);
2655
2656     if ( my $keywords = $request->query_keywords ) {
2657         $c->log->debug("Query keywords are: $keywords");
2658     }
2659
2660     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2661
2662     $c->log_request_uploads($request);
2663 }
2664
2665 =head2 $c->log_response
2666
2667 Writes information about the response to the debug logs by calling
2668 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2669
2670 =cut
2671
2672 sub log_response {
2673     my $c = shift;
2674
2675     return unless $c->debug;
2676
2677     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2678     my $response = $dump->[1];
2679
2680     $c->log_response_status_line($response);
2681     $c->log_response_headers($response->headers);
2682 }
2683
2684 =head2 $c->log_response_status_line($response)
2685
2686 Writes one line of information about the response to the debug logs.  This includes:
2687
2688 =over 4
2689
2690 =item * Response status code
2691
2692 =item * Content-Type header (if present)
2693
2694 =item * Content-Length header (if present)
2695
2696 =back
2697
2698 =cut
2699
2700 sub log_response_status_line {
2701     my ($c, $response) = @_;
2702
2703     $c->log->debug(
2704         sprintf(
2705             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2706             $response->status                            || 'unknown',
2707             $response->headers->header('Content-Type')   || 'unknown',
2708             $response->headers->header('Content-Length') || 'unknown'
2709         )
2710     );
2711 }
2712
2713 =head2 $c->log_response_headers($headers);
2714
2715 Hook method which can be wrapped by plugins to log the response headers.
2716 No-op in the default implementation.
2717
2718 =cut
2719
2720 sub log_response_headers {}
2721
2722 =head2 $c->log_request_parameters( query => {}, body => {} )
2723
2724 Logs request parameters to debug logs
2725
2726 =cut
2727
2728 sub log_request_parameters {
2729     my $c          = shift;
2730     my %all_params = @_;
2731
2732     return unless $c->debug;
2733
2734     my $column_width = Catalyst::Utils::term_width() - 44;
2735     foreach my $type (qw(query body)) {
2736         my $params = $all_params{$type};
2737         next if ! keys %$params;
2738         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2739         for my $key ( sort keys %$params ) {
2740             my @values = ();
2741             if(ref $params eq 'Hash::MultiValue') {
2742                 @values = $params->get_all($key);
2743             } else {
2744                 my $param = $params->{$key};
2745                 if( defined($param) ) {
2746                     @values = ref $param eq 'ARRAY' ? @$param : $param;
2747                 }
2748             }
2749             $t->row( $key.( scalar @values > 1 ? ' [multiple]' : ''), join(', ', @values) );
2750         }
2751         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2752     }
2753 }
2754
2755 =head2 $c->log_request_uploads
2756
2757 Logs file uploads included in the request to the debug logs.
2758 The parameter name, filename, file type, and file size are all included in
2759 the debug logs.
2760
2761 =cut
2762
2763 sub log_request_uploads {
2764     my $c = shift;
2765     my $request = shift;
2766     return unless $c->debug;
2767     my $uploads = $request->uploads;
2768     if ( keys %$uploads ) {
2769         my $t = Text::SimpleTable->new(
2770             [ 12, 'Parameter' ],
2771             [ 26, 'Filename' ],
2772             [ 18, 'Type' ],
2773             [ 9,  'Size' ]
2774         );
2775         for my $key ( sort keys %$uploads ) {
2776             my $upload = $uploads->{$key};
2777             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2778                 $t->row( $key, $u->filename, $u->type, $u->size );
2779             }
2780         }
2781         $c->log->debug( "File Uploads are:\n" . $t->draw );
2782     }
2783 }
2784
2785 =head2 $c->log_request_headers($headers);
2786
2787 Hook method which can be wrapped by plugins to log the request headers.
2788 No-op in the default implementation.
2789
2790 =cut
2791
2792 sub log_request_headers {}
2793
2794 =head2 $c->log_headers($type => $headers)
2795
2796 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2797
2798 =cut
2799
2800 sub log_headers {
2801     my $c       = shift;
2802     my $type    = shift;
2803     my $headers = shift;    # an HTTP::Headers instance
2804
2805     return unless $c->debug;
2806
2807     my $column_width = Catalyst::Utils::term_width() - 28;
2808     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2809     $headers->scan(
2810         sub {
2811             my ( $name, $value ) = @_;
2812             $t->row( $name, $value );
2813         }
2814     );
2815     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2816 }
2817
2818
2819 =head2 $c->prepare_read
2820
2821 Prepares the input for reading.
2822
2823 =cut
2824
2825 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2826
2827 =head2 $c->prepare_request
2828
2829 Prepares the engine request.
2830
2831 =cut
2832
2833 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2834
2835 =head2 $c->prepare_uploads
2836
2837 Prepares uploads.
2838
2839 =cut
2840
2841 sub prepare_uploads {
2842     my $c = shift;
2843     $c->engine->prepare_uploads( $c, @_ );
2844 }
2845
2846 =head2 $c->prepare_write
2847
2848 Prepares the output for writing.
2849
2850 =cut
2851
2852 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2853
2854 =head2 $c->request_class
2855
2856 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2857
2858 =head2 $app->request_class_traits
2859
2860 An arrayref of L<Moose::Role>s which are applied to the request class.  You can
2861 name the full namespace of the role, or a namespace suffix, which will then
2862 be tried against the following standard namespace prefixes.
2863
2864     $MyApp::TraitFor::Request::$trait_suffix
2865     Catalyst::TraitFor::Request::$trait_suffix
2866
2867 So for example if you set:
2868
2869     MyApp->request_class_traits(['Foo']);
2870
2871 We try each possible role in turn (and throw an error if none load)
2872
2873     Foo
2874     MyApp::TraitFor::Request::Foo
2875     Catalyst::TraitFor::Request::Foo
2876
2877 The namespace part 'TraitFor::Request' was chosen to assist in backwards
2878 compatibility with L<CatalystX::RoleApplicator> which previously provided
2879 these features in a stand alone package.
2880
2881 =head2 $app->composed_request_class
2882
2883 This is the request class which has been composed with any request_class_traits.
2884
2885 =head2 $c->response_class
2886
2887 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2888
2889 =head2 $app->response_class_traits
2890
2891 An arrayref of L<Moose::Role>s which are applied to the response class.  You can
2892 name the full namespace of the role, or a namespace suffix, which will then
2893 be tried against the following standard namespace prefixes.
2894
2895     $MyApp::TraitFor::Response::$trait_suffix
2896     Catalyst::TraitFor::Response::$trait_suffix
2897
2898 So for example if you set:
2899
2900     MyApp->response_class_traits(['Foo']);
2901
2902 We try each possible role in turn (and throw an error if none load)
2903
2904     Foo
2905     MyApp::TraitFor::Response::Foo
2906     Catalyst::TraitFor::Responset::Foo
2907
2908 The namespace part 'TraitFor::Response' was chosen to assist in backwards
2909 compatibility with L<CatalystX::RoleApplicator> which previously provided
2910 these features in a stand alone package.
2911
2912
2913 =head2 $app->composed_response_class
2914
2915 This is the request class which has been composed with any response_class_traits.
2916
2917 =head2 $c->read( [$maxlength] )
2918
2919 Reads a chunk of data from the request body. This method is designed to
2920 be used in a while loop, reading C<$maxlength> bytes on every call.
2921 C<$maxlength> defaults to the size of the request if not specified.
2922
2923 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2924 directly.
2925
2926 Warning: If you use read(), Catalyst will not process the body,
2927 so you will not be able to access POST parameters or file uploads via
2928 $c->request.  You must handle all body parsing yourself.
2929
2930 =cut
2931
2932 sub read { my $c = shift; return $c->request->read( @_ ) }
2933
2934 =head2 $c->run
2935
2936 Starts the engine.
2937
2938 =cut
2939
2940 sub run {
2941   my $app = shift;
2942   $app->_make_immutable_if_needed;
2943   $app->engine_loader->needs_psgi_engine_compat_hack ?
2944     $app->engine->run($app, @_) :
2945       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2946 }
2947
2948 sub _make_immutable_if_needed {
2949     my $class = shift;
2950     my $meta = find_meta($class);
2951     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2952     if (
2953         $meta->is_immutable
2954         && ! { $meta->immutable_options }->{replace_constructor}
2955         && $isa_ca
2956     ) {
2957         warn("You made your application class ($class) immutable, "
2958             . "but did not inline the\nconstructor. "
2959             . "This will break catalyst, as your app \@ISA "
2960             . "Class::Accessor(::Fast)?\nPlease pass "
2961             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2962     }
2963     unless ($meta->is_immutable) {
2964         # XXX - FIXME warning here as you should make your app immutable yourself.
2965         $meta->make_immutable(
2966             replace_constructor => 1,
2967         );
2968     }
2969 }
2970
2971 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2972
2973 Sets an action in a given namespace.
2974
2975 =cut
2976
2977 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2978
2979 =head2 $c->setup_actions($component)
2980
2981 Sets up actions for a component.
2982
2983 =cut
2984
2985 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2986
2987 =head2 $c->setup_components
2988
2989 This method is called internally to set up the application's components.
2990
2991 It finds modules by calling the L<locate_components> method, expands them to
2992 package names with the L<expand_component_module> method, and then installs
2993 each component into the application.
2994
2995 The C<setup_components> config option is passed to both of the above methods.
2996
2997 Installation of each component is performed by the L<setup_component> method,
2998 below.
2999
3000 =cut
3001
3002 sub setup_components {
3003     my $class = shift;
3004
3005     my $config  = $class->config->{ setup_components };
3006
3007     my @comps = $class->locate_components($config);
3008     my %comps = map { $_ => 1 } @comps;
3009
3010     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
3011     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
3012         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
3013     ) if $deprecatedcatalyst_component_names;
3014
3015     for my $component ( @comps ) {
3016
3017         # We pass ignore_loaded here so that overlay files for (e.g.)
3018         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
3019         # we know M::P::O found a file on disk so this is safe
3020
3021         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
3022     }
3023
3024     for my $component (@comps) {
3025         my $instance = $class->components->{ $component } = $class->delayed_setup_component($component);
3026     }
3027
3028     # Inject a component or wrap a stand alone class in an adaptor. This makes a list
3029     # of named components in the configuration that are not actually existing (not a
3030     # real file).
3031
3032     my @injected = $class->setup_injected_components;
3033
3034     # All components are registered, now we need to 'init' them.
3035     foreach my $component_name (@comps, @injected) {
3036       $class->components->{$component_name} = $class->components->{$component_name}->() if
3037         (ref($class->components->{$component_name}) || '') eq 'CODE';
3038     }
3039 }
3040
3041 =head2 $app->setup_injected_components
3042
3043 Called by setup_compoents to setup components that are injected.
3044
3045 =cut
3046
3047 sub setup_injected_components {
3048     my ($class) = @_;
3049     my @injected_components = keys %{$class->config->{inject_components} ||+{}};
3050
3051     foreach my $injected_comp_name(@injected_components) {
3052         $class->setup_injected_component(
3053           $injected_comp_name,
3054           $class->config->{inject_components}->{$injected_comp_name});
3055     }
3056
3057     return map { $class ."::" . $_ }
3058       @injected_components;
3059 }
3060
3061 =head2 $app->setup_injected_component( $injected_component_name, $config )
3062
3063 Setup a given injected component.
3064
3065 =cut
3066
3067 sub setup_injected_component {
3068     my ($class, $injected_comp_name, $config) = @_;
3069     if(my $component_class = $config->{from_component}) {
3070         my @roles = @{$config->{roles} ||[]};
3071         Catalyst::Utils::inject_component(
3072           into => $class,
3073           component => $component_class,
3074           (scalar(@roles) ? (traits => \@roles) : ()),
3075           as => $injected_comp_name);
3076     }
3077 }
3078
3079 =head2 $app->inject_component($MyApp_Component_name => \%args);
3080
3081 Add a component that is injected at setup:
3082
3083     MyApp->inject_component( 'Model::Foo' => { from_component => 'Common::Foo' } );
3084
3085 Must be called before ->setup.  Expects a component name for your
3086 current application and \%args where
3087
3088 =over 4
3089
3090 =item from_component
3091
3092 The target component being injected into your application
3093
3094 =item roles
3095
3096 An arrayref of L<Moose::Role>s that are applied to your component.
3097
3098 =back
3099
3100 Example
3101
3102     MyApp->inject_component(
3103       'Model::Foo' => {
3104         from_component => 'Common::Model::Foo',
3105         roles => ['Role1', 'Role2'],
3106       });
3107
3108 =head2 $app->inject_components
3109
3110 Inject a list of components:
3111
3112     MyApp->inject_components(
3113       'Model::FooOne' => {
3114         from_component => 'Common::Model::Foo',
3115         roles => ['Role1', 'Role2'],
3116       },
3117       'Model::FooTwo' => {
3118         from_component => 'Common::Model::Foo',
3119         roles => ['Role1', 'Role2'],
3120       });
3121
3122 =cut
3123
3124 sub inject_component {
3125   my ($app, $name, $args) = @_;
3126   die "Component $name exists" if
3127     $app->config->{inject_components}->{$name};
3128   $app->config->{inject_components}->{$name} = $args;
3129 }
3130
3131 sub inject_components {
3132   my $app = shift;
3133   while(@_) {
3134     $app->inject_component(shift, shift);
3135   }
3136 }
3137
3138 =head2 $c->locate_components( $setup_component_config )
3139
3140 This method is meant to provide a list of component modules that should be
3141 setup for the application.  By default, it will use L<Module::Pluggable>.
3142
3143 Specify a C<setup_components> config option to pass additional options directly
3144 to L<Module::Pluggable>. To add additional search paths, specify a key named
3145 C<search_extra> as an array reference. Items in the array beginning with C<::>
3146 will have the application class name prepended to them.
3147
3148 =cut
3149
3150 sub locate_components {
3151     my $class  = shift;
3152     my $config = shift;
3153
3154     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
3155     my $extra   = $config->{ search_extra } || [];
3156
3157     unshift @paths, @$extra;
3158
3159     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
3160       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
3161       %$config
3162     )->plugins } @paths;
3163
3164     return @comps;
3165 }
3166
3167 =head2 $c->expand_component_module( $component, $setup_component_config )
3168
3169 Components found by C<locate_components> will be passed to this method, which
3170 is expected to return a list of component (package) names to be set up.
3171
3172 =cut
3173
3174 sub expand_component_module {
3175     my ($class, $module) = @_;
3176     return Devel::InnerPackage::list_packages( $module );
3177 }
3178
3179 =head2 $app->delayed_setup_component
3180
3181 Returns a coderef that points to a setup_component instance.  Used
3182 internally for when you want to delay setup until the first time
3183 the component is called.
3184
3185 =cut
3186
3187 sub delayed_setup_component {
3188   my($class, $component, @more) = @_;
3189   return sub {
3190     return my $instance = $class->setup_component($component, @more);
3191   };
3192 }
3193
3194 =head2 $c->setup_component
3195
3196 =cut
3197
3198 sub setup_component {
3199     my( $class, $component ) = @_;
3200
3201     unless ( $component->can( 'COMPONENT' ) ) {
3202         return $component;
3203     }
3204
3205     my $config = $class->config_for($component);
3206     # Stash catalyst_component_name in the config here, so that custom COMPONENT
3207     # methods also pass it. local to avoid pointlessly shitting in config
3208     # for the debug screen, as $component is already the key name.
3209     local $config->{catalyst_component_name} = $component;
3210
3211     my $instance = eval {
3212       $component->COMPONENT( $class, $config );
3213     } || do {
3214       my $error = $@;
3215       chomp $error;
3216       Catalyst::Exception->throw(
3217         message => qq/Couldn't instantiate component "$component", "$error"/
3218       );
3219     };
3220
3221     unless (blessed $instance) {
3222         my $metaclass = Moose::Util::find_meta($component);
3223         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
3224         my $component_method_from = $method_meta->associated_metaclass->name;
3225         my $value = defined($instance) ? $instance : 'undef';
3226         Catalyst::Exception->throw(
3227             message =>
3228             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
3229         );
3230     }
3231
3232     my @expanded_components = $instance->can('expand_modules')
3233       ? $instance->expand_modules( $component, $config )
3234       : $class->expand_component_module( $component, $config );
3235     for my $component (@expanded_components) {
3236       next if $class->components->{ $component };
3237       $class->components->{ $component } = $class->setup_component($component);
3238     }
3239
3240     return $instance;
3241 }
3242
3243 =head2 $app->config_for( $component_name )
3244
3245 Return the application level configuration (which is not yet merged with any
3246 local component configuration, via $component_class->config) for the named
3247 component or component object. Example:
3248
3249     MyApp->config(
3250       'Model::Foo' => { a => 1, b => 2},
3251     );
3252
3253     my $config = MyApp->config_for('MyApp::Model::Foo');
3254
3255 In this case $config is the hashref C<< {a=>1, b=>2} >>.
3256
3257 This is also handy for looking up configuration for a plugin, to make sure you follow
3258 existing L<Catalyst> standards for where a plugin should put its configuration.
3259
3260 =cut
3261
3262 sub config_for {
3263     my ($class, $component_name) = @_;
3264     my $component_suffix = Catalyst::Utils::class2classsuffix($component_name);
3265     my $config = $class->config->{ $component_suffix } || {};
3266
3267     return $config;
3268 }
3269
3270 =head2 $c->setup_dispatcher
3271
3272 Sets up dispatcher.
3273
3274 =cut
3275
3276 sub setup_dispatcher {
3277     my ( $class, $dispatcher ) = @_;
3278
3279     if ($dispatcher) {
3280         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
3281     }
3282
3283     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
3284         $dispatcher = 'Catalyst::Dispatcher::' . $env;
3285     }
3286
3287     unless ($dispatcher) {
3288         $dispatcher = $class->dispatcher_class;
3289     }
3290
3291     load_class($dispatcher);
3292
3293     # dispatcher instance
3294     $class->dispatcher( $dispatcher->new );
3295 }
3296
3297 =head2 $c->setup_engine
3298
3299 Sets up engine.
3300
3301 =cut
3302
3303 sub engine_class {
3304     my ($class, $requested_engine) = @_;
3305
3306     if (!$class->engine_loader || $requested_engine) {
3307         $class->engine_loader(
3308             Catalyst::EngineLoader->new({
3309                 application_name => $class,
3310                 (defined $requested_engine
3311                      ? (catalyst_engine_class => $requested_engine) : ()),
3312             }),
3313         );
3314     }
3315
3316     $class->engine_loader->catalyst_engine_class;
3317 }
3318
3319 sub setup_engine {
3320     my ($class, $requested_engine) = @_;
3321
3322     my $engine = do {
3323         my $loader = $class->engine_loader;
3324
3325         if (!$loader || $requested_engine) {
3326             $loader = Catalyst::EngineLoader->new({
3327                 application_name => $class,
3328                 (defined $requested_engine
3329                      ? (requested_engine => $requested_engine) : ()),
3330             }),
3331
3332             $class->engine_loader($loader);
3333         }
3334
3335         $loader->catalyst_engine_class;
3336     };
3337
3338     # Don't really setup_engine -- see _setup_psgi_app for explanation.
3339     return if $class->loading_psgi_file;
3340
3341     load_class($engine);
3342
3343     if ($ENV{MOD_PERL}) {
3344         my $apache = $class->engine_loader->auto;
3345
3346         my $meta = find_meta($class);
3347         my $was_immutable = $meta->is_immutable;
3348         my %immutable_options = $meta->immutable_options;
3349         $meta->make_mutable if $was_immutable;
3350
3351         $meta->add_method(handler => sub {
3352             my $r = shift;
3353             my $psgi_app = $class->_finalized_psgi_app;
3354             $apache->call_app($r, $psgi_app);
3355         });
3356
3357         $meta->make_immutable(%immutable_options) if $was_immutable;
3358     }
3359
3360     $class->engine( $engine->new );
3361
3362     return;
3363 }
3364
3365 ## This exists just to supply a prebuild psgi app for mod_perl and for the
3366 ## build in server support (back compat support for pre psgi port behavior).
3367 ## This is so that we don't build a new psgi app for each request when using
3368 ## the mod_perl handler or the built in servers (http and fcgi, etc).
3369
3370 sub _finalized_psgi_app {
3371     my ($app) = @_;
3372
3373     unless ($app->_psgi_app) {
3374         my $psgi_app = $app->_setup_psgi_app;
3375         $app->_psgi_app($psgi_app);
3376     }
3377
3378     return $app->_psgi_app;
3379 }
3380
3381 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
3382 ## home directory and load that and return it (just assume it is doing the
3383 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
3384 ## in default_middleware and return it ( this is for backward compatibility
3385 ## with pre psgi port behavior ).
3386
3387 sub _setup_psgi_app {
3388     my ($app) = @_;
3389
3390     for my $home (Path::Class::Dir->new($app->config->{home})) {
3391         my $psgi_file = $home->file(
3392             Catalyst::Utils::appprefix($app) . '.psgi',
3393         );
3394
3395         next unless -e $psgi_file;
3396
3397         # If $psgi_file calls ->setup_engine, it's doing so to load
3398         # Catalyst::Engine::PSGI. But if it does that, we're only going to
3399         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
3400         # anyway. So set a flag (ick) that tells setup_engine not to populate
3401         # $c->engine or do any other things we might regret.
3402
3403         $app->loading_psgi_file(1);
3404         my $psgi_app = Plack::Util::load_psgi($psgi_file);
3405         $app->loading_psgi_file(0);
3406
3407         return $psgi_app
3408             unless $app->engine_loader->needs_psgi_engine_compat_hack;
3409
3410         warn <<"EOW";
3411 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
3412
3413 Its content has been ignored. Please consult the Catalyst::Upgrading
3414 documentation on how to upgrade from Catalyst::Engine::PSGI.
3415 EOW
3416     }
3417
3418     return $app->apply_default_middlewares($app->psgi_app);
3419 }
3420
3421 =head2 $c->apply_default_middlewares
3422
3423 Adds the following L<Plack> middlewares to your application, since they are
3424 useful and commonly needed:
3425
3426 L<Plack::Middleware::LighttpdScriptNameFix> (if you are using Lighttpd),
3427 L<Plack::Middleware::IIS6ScriptNameFix> (always applied since this middleware
3428 is smart enough to conditionally apply itself).
3429
3430 We will also automatically add L<Plack::Middleware::ReverseProxy> if we notice
3431 that your HTTP $env variable C<REMOTE_ADDR> is '127.0.0.1'.  This is usually
3432 an indication that your server is running behind a proxy frontend.  However in
3433 2014 this is often not the case.  We preserve this code for backwards compatibility
3434 however I B<highly> recommend that if you are running the server behind a front
3435 end proxy that you clearly indicate so with the C<using_frontend_proxy> configuration
3436 setting to true for your environment configurations that run behind a proxy.  This
3437 way if you change your front end proxy address someday your code would inexplicably
3438 stop working as expected.
3439
3440 Additionally if we detect we are using Nginx, we add a bit of custom middleware
3441 to solve some problems with the way that server handles $ENV{PATH_INFO} and
3442 $ENV{SCRIPT_NAME}.
3443
3444 Please B<NOTE> that if you do use C<using_frontend_proxy> the middleware is now
3445 adding via C<registered_middleware> rather than this method.
3446
3447 If you are using Lighttpd or IIS6 you may wish to apply these middlewares.  In
3448 general this is no longer a common case but we have this here for backward
3449 compatibility.
3450
3451 =cut
3452
3453
3454 sub apply_default_middlewares {
3455     my ($app, $psgi_app) = @_;
3456
3457     # Don't add this conditional IF we are explicitly saying we want the
3458     # frontend proxy support.  We don't need it here since if that is the
3459     # case it will be always loaded in the default_middleware.
3460
3461     unless($app->config->{using_frontend_proxy}) {
3462       $psgi_app = Plack::Middleware::Conditional->wrap(
3463           $psgi_app,
3464           builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
3465           condition => sub {
3466               my ($env) = @_;
3467               return if $app->config->{ignore_frontend_proxy};
3468               return $env->{REMOTE_ADDR} eq '127.0.0.1';
3469           },
3470       );
3471     }
3472
3473     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3474     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3475     $psgi_app = Plack::Middleware::Conditional->wrap(
3476         $psgi_app,
3477         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3478         condition => sub {
3479             my ($env) = @_;
3480             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3481             return unless $1 < 4.23;
3482             1;
3483         },
3484     );
3485
3486     # we're applying this unconditionally as the middleware itself already makes
3487     # sure it doesn't fuck things up if it's not running under one of the right
3488     # IIS versions
3489     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3490
3491     # And another IIS issue, this time with IIS7.
3492     $psgi_app = Plack::Middleware::Conditional->wrap(
3493         $psgi_app,
3494         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3495         condition => sub {
3496             my ($env) = @_;
3497             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3498         },
3499     );
3500
3501     return $psgi_app;
3502 }
3503
3504 =head2 App->psgi_app
3505
3506 =head2 App->to_app
3507
3508 Returns a PSGI application code reference for the catalyst application
3509 C<$c>. This is the bare application created without the C<apply_default_middlewares>
3510 method called.  We do however apply C<registered_middleware> since those are
3511 integral to how L<Catalyst> functions.  Also, unlike starting your application
3512 with a generated server script (via L<Catalyst::Devel> and C<catalyst.pl>) we do
3513 not attempt to return a valid L<PSGI> application using any existing C<${myapp}.psgi>
3514 scripts in your $HOME directory.
3515
3516 B<NOTE> C<apply_default_middlewares> was originally created when the first PSGI
3517 port was done for v5.90000.  These are middlewares that are added to achieve
3518 backward compatibility with older applications.  If you start your application
3519 using one of the supplied server scripts (generated with L<Catalyst::Devel> and
3520 the project skeleton script C<catalyst.pl>) we apply C<apply_default_middlewares>
3521 automatically.  This was done so that pre and post PSGI port applications would
3522 work the same way.
3523
3524 This is what you want to be using to retrieve the PSGI application code
3525 reference of your Catalyst application for use in a custom F<.psgi> or in your
3526 own created server modules.
3527
3528 =cut
3529
3530 *to_app = \&psgi_app;
3531
3532 sub psgi_app {
3533     my ($app) = @_;
3534     my $psgi = $app->engine->build_psgi_app($app);
3535     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3536 }
3537
3538 =head2 $c->setup_home
3539
3540 Sets up the home directory.
3541
3542 =cut
3543
3544 sub setup_home {
3545     my ( $class, $home ) = @_;
3546
3547     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3548         $home = $env;
3549     }
3550
3551     $home ||= Catalyst::Utils::home($class);
3552
3553     if ($home) {
3554         #I remember recently being scolded for assigning config values like this
3555         $class->config->{home} ||= $home;
3556         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3557     }
3558 }
3559
3560 =head2 $c->setup_encoding
3561
3562 Sets up the input/output encoding. See L<ENCODING>
3563
3564 =cut
3565
3566 sub setup_encoding {
3567     my $c = shift;
3568     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3569         # Ok, so the user has explicitly said "I don't want encoding..."
3570         return;
3571     } else {
3572       my $enc = defined($c->config->{encoding}) ?
3573         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3574       $c->encoding($enc);
3575     }
3576 }
3577
3578 =head2 handle_unicode_encoding_exception
3579
3580 Hook to let you customize how encoding errors are handled. By default
3581 we just throw an exception and the default error page will pick it up.
3582 Receives a hashref of debug information. Example of call (from the
3583 Catalyst internals):
3584
3585   my $decoded_after_fail = $c->handle_unicode_encoding_exception({
3586         param_value => $value,
3587         error_msg => $_,
3588         encoding_step => 'params',
3589    });
3590
3591 The calling code expects to receive a decoded string or an exception.
3592
3593 You can override this for custom handling of unicode errors. By
3594 default we just die. If you want a custom response here, one approach
3595 is to throw an HTTP style exception, instead of returning a decoded
3596 string or throwing a generic exception.
3597
3598     sub handle_unicode_encoding_exception {
3599       my ($c, $params) = @_;
3600       HTTP::Exception::BAD_REQUEST->throw(status_message=>$params->{error_msg});
3601     }
3602
3603 Alternatively you can 'catch' the error, stash it and write handling code later
3604 in your application:
3605
3606     sub handle_unicode_encoding_exception {
3607       my ($c, $params) = @_;
3608       $c->stash(BAD_UNICODE_DATA=>$params);
3609       # return a dummy string.
3610       return 1;
3611     }
3612
3613 <B>NOTE:</b> Please keep in mind that once an error like this occurs,
3614 the request setup is still ongoing, which means the state of C<$c> and
3615 related context parts like the request and response may not be setup
3616 up correctly (since we haven't finished the setup yet). If you throw
3617 an exception the setup is aborted.
3618
3619 =cut
3620
3621 sub handle_unicode_encoding_exception {
3622     my ( $self, $exception_ctx ) = @_;
3623     die $exception_ctx->{error_msg};
3624 }
3625
3626 # Some unicode helpers cargo culted from the old plugin.  These could likely
3627 # be neater.
3628
3629 sub _handle_unicode_decoding {
3630     my ( $self, $value ) = @_;
3631
3632     return unless defined $value;
3633
3634     ## I think this mess is to support the old nested
3635     if ( ref $value eq 'ARRAY' ) {
3636         foreach ( @$value ) {
3637             $_ = $self->_handle_unicode_decoding($_);
3638         }
3639         return $value;
3640     }
3641     elsif ( ref $value eq 'HASH' ) {
3642         foreach (keys %$value) {
3643             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3644             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3645
3646             # If the key was encoded we now have two (the original and current so
3647             # delete the original.
3648             delete $value->{$_} if $_ ne $encoded_key;
3649         }
3650         return $value;
3651     }
3652     else {
3653         return $self->_handle_param_unicode_decoding($value);
3654     }
3655 }
3656
3657 sub _handle_param_unicode_decoding {
3658     my ( $self, $value, $check ) = @_;
3659     return unless defined $value; # not in love with just ignoring undefs - jnap
3660     return $value if blessed($value); #don't decode when the value is an object.
3661
3662     my $enc = $self->encoding;
3663
3664     return $value unless $enc; # don't decode if no encoding is specified
3665
3666     $check ||= $self->_encode_check;
3667     return try {
3668       $enc->decode( $value, $check);
3669     }
3670     catch {
3671         return $self->handle_unicode_encoding_exception({
3672             param_value => $value,
3673             error_msg => $_,
3674             encoding_step => 'params',
3675         });
3676     };
3677 }
3678
3679 =head2 $c->setup_log
3680
3681 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3682 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3683 log to.
3684
3685 This method also installs a C<debug> method that returns a true value into the
3686 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3687 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3688
3689 Note that if the log has already been setup, by either a previous call to
3690 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3691 that this method won't actually set up the log object.
3692
3693 =cut
3694
3695 sub setup_log {
3696     my ( $class, $levels ) = @_;
3697
3698     $levels ||= '';
3699     $levels =~ s/^\s+//;
3700     $levels =~ s/\s+$//;
3701     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3702
3703     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3704     if ( defined $env_debug ) {
3705         $levels{debug} = 1 if $env_debug; # Ugly!
3706         delete($levels{debug}) unless $env_debug;
3707     }
3708
3709     unless ( $class->log ) {
3710         $class->log( Catalyst::Log->new(keys %levels) );
3711     }
3712
3713     if ( $levels{debug} ) {
3714         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3715         $class->log->debug('Debug messages enabled');
3716     }
3717 }
3718
3719 =head2 $c->setup_plugins
3720
3721 Sets up plugins.
3722
3723 =cut
3724
3725 =head2 $c->setup_stats
3726
3727 Sets up timing statistics class.
3728
3729 =cut
3730
3731 sub setup_stats {
3732     my ( $class, $stats ) = @_;
3733
3734     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3735
3736     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3737     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3738         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3739         $class->log->debug('Statistics enabled');
3740     }
3741 }
3742
3743
3744 =head2 $c->registered_plugins
3745
3746 Returns a sorted list of the plugins which have either been stated in the
3747 import list.
3748
3749 If passed a given plugin name, it will report a boolean value indicating
3750 whether or not that plugin is loaded.  A fully qualified name is required if
3751 the plugin name does not begin with C<Catalyst::Plugin::>.
3752
3753  if ($c->registered_plugins('Some::Plugin')) {
3754      ...
3755  }
3756
3757 =cut
3758
3759 {
3760
3761     sub registered_plugins {
3762         my $proto = shift;
3763         return sort keys %{ $proto->_plugins } unless @_;
3764         my $plugin = shift;
3765         return 1 if exists $proto->_plugins->{$plugin};
3766         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3767     }
3768
3769     sub _register_plugin {
3770         my ( $proto, $plugin, $instant ) = @_;
3771         my $class = ref $proto || $proto;
3772
3773         load_class( $plugin );
3774         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3775             if $plugin->isa( 'Catalyst::Component' );
3776         my $plugin_meta = Moose::Meta::Class->create($plugin);
3777         if (!$plugin_meta->has_method('new')
3778             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3779             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3780         }
3781         if (!$instant && !$proto->_plugins->{$plugin}) {
3782             my $meta = Class::MOP::get_metaclass_by_name($class);
3783             $meta->superclasses($plugin, $meta->superclasses);
3784         }
3785         $proto->_plugins->{$plugin} = 1;
3786         return $class;
3787     }
3788
3789     sub _default_plugins { return qw() }
3790
3791     sub setup_plugins {
3792         my ( $class, $plugins ) = @_;
3793
3794         $class->_plugins( {} ) unless $class->_plugins;
3795         $plugins = [ grep {
3796             m/Unicode::Encoding/ ? do {
3797                 $class->log->warn(
3798                     'Unicode::Encoding plugin is auto-applied,'
3799                     . ' please remove this from your appclass'
3800                     . ' and make sure to define "encoding" config'
3801                 );
3802                 unless (exists $class->config->{'encoding'}) {
3803                   $class->config->{'encoding'} = 'UTF-8';
3804                 }
3805                 () }
3806                 : $_
3807         } @$plugins ];
3808         push @$plugins, $class->_default_plugins;
3809         $plugins = Data::OptList::mkopt($plugins || []);
3810
3811         my @plugins = map {
3812             [ Catalyst::Utils::resolve_namespace(
3813                   $class . '::Plugin',
3814                   'Catalyst::Plugin', $_->[0]
3815               ),
3816               $_->[1],
3817             ]
3818          } @{ $plugins };
3819
3820         for my $plugin ( reverse @plugins ) {
3821             load_class($plugin->[0], $plugin->[1]);
3822             my $meta = find_meta($plugin->[0]);
3823             next if $meta && $meta->isa('Moose::Meta::Role');
3824
3825             $class->_register_plugin($plugin->[0]);
3826         }
3827
3828         my @roles =
3829             map  { $_->[0]->name, $_->[1] }
3830             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3831             map  { [find_meta($_->[0]), $_->[1]] }
3832             @plugins;
3833
3834         Moose::Util::apply_all_roles(
3835             $class => @roles
3836         ) if @roles;
3837     }
3838 }
3839
3840 =head2 default_middleware
3841
3842 Returns a list of instantiated PSGI middleware objects which is the default
3843 middleware that is active for this application (taking any configuration
3844 options into account, excluding your custom added middleware via the C<psgi_middleware>
3845 configuration option).  You can override this method if you wish to change
3846 the default middleware (although do so at risk since some middleware is vital
3847 to application function.)
3848
3849 The current default middleware list is:
3850
3851       Catalyst::Middleware::Stash
3852       Plack::Middleware::HTTPExceptions
3853       Plack::Middleware::RemoveRedundantBody
3854       Plack::Middleware::FixMissingBodyInRedirect
3855       Plack::Middleware::ContentLength
3856       Plack::Middleware::MethodOverride
3857       Plack::Middleware::Head
3858
3859 If the configuration setting C<using_frontend_proxy> is true we add:
3860
3861       Plack::Middleware::ReverseProxy
3862
3863 If the configuration setting C<using_frontend_proxy_path> is true we add:
3864
3865       Plack::Middleware::ReverseProxyPath
3866
3867 But B<NOTE> that L<Plack::Middleware::ReverseProxyPath> is not a dependency of the
3868 L<Catalyst> distribution so if you want to use this option you should add it to
3869 your project distribution file.
3870
3871 These middlewares will be added at L</setup_middleware> during the
3872 L</setup> phase of application startup.
3873
3874 =cut
3875
3876 sub default_middleware {
3877     my $class = shift;
3878     my @mw = (
3879       Catalyst::Middleware::Stash->new,
3880       Plack::Middleware::HTTPExceptions->new,
3881       Plack::Middleware::RemoveRedundantBody->new,
3882       Plack::Middleware::FixMissingBodyInRedirect->new,
3883       Plack::Middleware::ContentLength->new,
3884       Plack::Middleware::MethodOverride->new,
3885       Plack::Middleware::Head->new);
3886
3887     if($class->config->{using_frontend_proxy}) {
3888         push @mw, Plack::Middleware::ReverseProxy->new;
3889     }
3890
3891     if($class->config->{using_frontend_proxy_path}) {
3892         if(Class::Load::try_load_class('Plack::Middleware::ReverseProxyPath')) {
3893             push @mw, Plack::Middleware::ReverseProxyPath->new;
3894         } else {
3895           $class->log->error("Cannot use configuration 'using_frontend_proxy_path' because 'Plack::Middleware::ReverseProxyPath' is not installed");
3896         }
3897     }
3898
3899     return @mw;
3900 }
3901
3902 =head2 registered_middlewares
3903
3904 Read only accessor that returns an array of all the middleware in the order
3905 that they were added (which is the REVERSE of the order they will be applied).
3906
3907 The values returned will be either instances of L<Plack::Middleware> or of a
3908 compatible interface, or a coderef, which is assumed to be inlined middleware
3909
3910 =head2 setup_middleware (?@middleware)
3911
3912 Read configuration information stored in configuration key C<psgi_middleware> or
3913 from passed @args.
3914
3915 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3916 to use it to enable L<Plack::Middleware>
3917
3918 This method is automatically called during 'setup' of your application, so
3919 you really don't need to invoke it.  However you may do so if you find the idea
3920 of loading middleware via configuration weird :).  For example:
3921
3922     package MyApp;
3923
3924     use Catalyst;
3925
3926     __PACKAGE__->setup_middleware('Head');
3927     __PACKAGE__->setup;
3928
3929 When we read middleware definitions from configuration, we reverse the list
3930 which sounds odd but is likely how you expect it to work if you have prior
3931 experience with L<Plack::Builder> or if you previously used the plugin
3932 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3933
3934 So basically your middleware handles an incoming request from the first
3935 registered middleware, down and handles the response from the last middleware
3936 up.
3937
3938 =cut
3939
3940 sub registered_middlewares {
3941     my $class = shift;
3942     if(my $middleware = $class->_psgi_middleware) {
3943         my @mw = ($class->default_middleware, @$middleware);
3944
3945         if($class->config->{using_frontend_proxy}) {
3946           push @mw, Plack::Middleware::ReverseProxy->new;
3947         }
3948
3949         return @mw;
3950     } else {
3951         die "You cannot call ->registered_middlewares until middleware has been setup";
3952     }
3953 }
3954
3955 sub setup_middleware {
3956     my $class = shift;
3957     my @middleware_definitions;
3958
3959     # If someone calls this method you can add middleware with args.  However if its
3960     # called without an arg we need to setup the configuration middleware.
3961     if(@_) {
3962       @middleware_definitions = reverse(@_);
3963     } else {
3964       @middleware_definitions = reverse(@{$class->config->{'psgi_middleware'}||[]})
3965         unless $class->finalized_default_middleware;
3966       $class->finalized_default_middleware(1); # Only do this once, just in case some people call setup over and over...
3967     }
3968
3969     my @middleware = ();
3970     while(my $next = shift(@middleware_definitions)) {
3971         if(ref $next) {
3972             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3973                 push @middleware, $next;
3974             } elsif(ref $next eq 'CODE') {
3975                 push @middleware, $next;
3976             } elsif(ref $next eq 'HASH') {
3977                 my $namespace = shift @middleware_definitions;
3978                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3979                 push @middleware, $mw;
3980             } else {
3981               die "I can't handle middleware definition ${\ref $next}";
3982             }
3983         } else {
3984           my $mw = $class->Catalyst::Utils::build_middleware($next);
3985           push @middleware, $mw;
3986         }
3987     }
3988
3989     my @existing = @{$class->_psgi_middleware || []};
3990     $class->_psgi_middleware([@middleware,@existing,]);
3991 }
3992
3993 =head2 registered_data_handlers
3994
3995 A read only copy of registered Data Handlers returned as a Hash, where each key
3996 is a content type and each value is a subref that attempts to decode that content
3997 type.
3998
3999 =head2 setup_data_handlers (?@data_handler)
4000
4001 Read configuration information stored in configuration key C<data_handlers> or
4002 from passed @args.
4003
4004 See under L</CONFIGURATION> information regarding C<data_handlers>.
4005
4006 This method is automatically called during 'setup' of your application, so
4007 you really don't need to invoke it.
4008
4009 =head2 default_data_handlers
4010
4011 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
4012 only two default data handlers, for 'application/json' and an alternative to
4013 'application/x-www-form-urlencoded' which supposed nested form parameters via
4014 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
4015
4016 The 'application/json' data handler is used to parse incoming JSON into a Perl
4017 data structure.  It uses L<JSON::MaybeXS>.  This allows you to fail back to
4018 L<JSON::PP>, which is a Pure Perl JSON decoder, and has the smallest dependency
4019 impact.
4020
4021 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
4022 use this new feature we recommend installing L<Cpanel::JSON::XS> in order to get
4023 the best performance.  You should add either to your dependency list
4024 (Makefile.PL, dist.ini, cpanfile, etc.)
4025
4026 =cut
4027
4028 sub registered_data_handlers {
4029     my $class = shift;
4030     if(my $data_handlers = $class->_data_handlers) {
4031         return %$data_handlers;
4032     } else {
4033         $class->setup_data_handlers;
4034         return $class->registered_data_handlers;
4035     }
4036 }
4037
4038 sub setup_data_handlers {
4039     my ($class, %data_handler_callbacks) = @_;
4040     %data_handler_callbacks = (
4041       %{$class->default_data_handlers},
4042       %{$class->config->{'data_handlers'}||+{}},
4043       %data_handler_callbacks);
4044
4045     $class->_data_handlers(\%data_handler_callbacks);
4046 }
4047
4048 sub default_data_handlers {
4049     my ($class) = @_;
4050     return +{
4051       'application/x-www-form-urlencoded' => sub {
4052           my ($fh, $req) = @_;
4053           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
4054           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
4055             ->can('build_cgi_struct')->($params);
4056       },
4057       'application/json' => sub {
4058           my ($fh, $req) = @_;
4059           require JSON::MaybeXS;
4060           my $slurped;
4061           return eval {
4062             local $/;
4063             $slurped = $fh->getline;
4064             JSON::MaybeXS::decode_json($slurped); # decode_json does utf8 decoding for us
4065           } || Catalyst::Exception->throw(sprintf "Error Parsing POST '%s', Error: %s", (defined($slurped) ? $slurped : 'undef') ,$@);
4066         },
4067     };
4068 }
4069
4070 sub _handle_http_exception {
4071     my ( $self, $error ) = @_;
4072     if (
4073            !$self->config->{always_catch_http_exceptions}
4074         && blessed $error
4075         && (
4076             $error->can('as_psgi')
4077             || (   $error->can('code')
4078                 && $error->code =~ m/^[1-5][0-9][0-9]$/ )
4079         )
4080       )
4081     {
4082         return 1;
4083     }
4084 }
4085
4086 =head2 $c->stack
4087
4088 Returns an arrayref of the internal execution stack (actions that are
4089 currently executing).
4090
4091 =head2 $c->stats
4092
4093 Returns the current timing statistics object. By default Catalyst uses
4094 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
4095 L<< stats_class|/"$c->stats_class" >>.
4096
4097 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
4098 available. By enabling it with C<< $c->stats->enabled(1) >>, it can be used to
4099 profile explicitly, although MyApp.pm still won't profile nor output anything
4100 by itself.
4101
4102 =head2 $c->stats_class
4103
4104 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
4105
4106 =head2 $app->stats_class_traits
4107
4108 A arrayref of L<Moose::Role>s that are applied to the stats_class before creating it.
4109
4110 =head2 $app->composed_stats_class
4111
4112 this is the stats_class composed with any 'stats_class_traits'.  You can
4113 name the full namespace of the role, or a namespace suffix, which will then
4114 be tried against the following standard namespace prefixes.
4115
4116     $MyApp::TraitFor::Stats::$trait_suffix
4117     Catalyst::TraitFor::Stats::$trait_suffix
4118
4119 So for example if you set:
4120
4121     MyApp->stats_class_traits(['Foo']);
4122
4123 We try each possible role in turn (and throw an error if none load)
4124
4125     Foo
4126     MyApp::TraitFor::Stats::Foo
4127     Catalyst::TraitFor::Stats::Foo
4128
4129 The namespace part 'TraitFor::Stats' was chosen to assist in backwards
4130 compatibility with L<CatalystX::RoleApplicator> which previously provided
4131 these features in a stand alone package.
4132
4133 =head2 $c->use_stats
4134
4135 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
4136
4137 Note that this is a static method, not an accessor and should be overridden
4138 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
4139
4140 =cut
4141
4142 sub use_stats { 0 }
4143
4144
4145 =head2 $c->write( $data )
4146
4147 Writes $data to the output stream. When using this method directly, you
4148 will need to manually set the C<Content-Length> header to the length of
4149 your output data, if known.
4150
4151 =cut
4152
4153 sub write {
4154     my $c = shift;
4155
4156     # Finalize headers if someone manually writes output (for compat)
4157     $c->finalize_headers;
4158
4159     return $c->response->write( @_ );
4160 }
4161
4162 =head2 version
4163
4164 Returns the Catalyst version number. Mostly useful for "powered by"
4165 messages in template systems.
4166
4167 =cut
4168
4169 sub version { return $Catalyst::VERSION }
4170
4171 =head1 CONFIGURATION
4172
4173 There are a number of 'base' config variables which can be set:
4174
4175 =over
4176
4177 =item *
4178
4179 C<always_catch_http_exceptions> - As of version 5.90060 Catalyst
4180 rethrows errors conforming to the interface described by
4181 L<Plack::Middleware::HTTPExceptions> and lets the middleware deal with it.
4182 Set true to get the deprecated behaviour and have Catalyst catch HTTP exceptions.
4183
4184 =item *
4185
4186 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
4187
4188 =item *
4189
4190 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
4191
4192 =item *
4193
4194 C<disable_component_resolution_regex_fallback> - Turns
4195 off the deprecated component resolution functionality so
4196 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
4197 are called then regex search will not be attempted on string values and
4198 instead C<undef> will be returned.
4199
4200 =item *
4201
4202 C<home> - The application home directory. In an uninstalled application,
4203 this is the top level application directory. In an installed application,
4204 this will be the directory containing C<< MyApp.pm >>.
4205
4206 =item *
4207
4208 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
4209
4210 =item *
4211
4212 C<name> - The name of the application in debug messages and the debug and
4213 welcome screens
4214
4215 =item *
4216
4217 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
4218 until it is accessed. This allows you to (for example) check authentication (and reject
4219 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
4220
4221 =item *
4222
4223 C<root> - The root directory for templates. Usually this is just a
4224 subdirectory of the home directory, but you can set it to change the
4225 templates to a different directory.
4226
4227 =item *
4228
4229 C<search_extra> - Array reference passed to Module::Pluggable to for additional
4230 namespaces from which components will be loaded (and constructed and stored in
4231 C<< $c->components >>).
4232
4233 =item *
4234
4235 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
4236 to be shown in hit debug tables in the test server.
4237
4238 =item *
4239
4240 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
4241 variable should be used for determining the request path.
4242
4243 Most web server environments pass the requested path to the application using environment variables,
4244 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
4245 exposed as C<< $c->request->base >>) and the request path below that base.
4246
4247 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
4248 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
4249
4250 =over
4251
4252 =item use_request_uri_for_path => 0
4253
4254 This is the default (and the) traditional method that Catalyst has used for determining the path information.
4255 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
4256 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
4257 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
4258
4259 However this method has the major disadvantage that it is impossible to correctly decode some elements
4260 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
4261 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
4262 can't distinguish / vs %2F in paths (in addition to other encoded values).
4263
4264 =item use_request_uri_for_path => 1
4265
4266 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
4267 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
4268 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
4269
4270 Given that this method of path resolution is provably more correct, it is recommended that you use
4271 this unless you have a specific need to deploy your application in a non-standard environment, and you are
4272 aware of the implications of not being able to handle encoded URI paths correctly.
4273
4274 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
4275 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
4276 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
4277 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
4278 C<< $c->request->base >> will be incorrect.
4279
4280 =back
4281
4282 =item *
4283
4284 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
4285
4286 =item *
4287
4288 C<using_frontend_proxy_path> - Enabled L<Plack::Middleware::ReverseProxyPath> on your application (if
4289 installed, otherwise log an error).  This is useful if your application is not running on the
4290 'root' (or /) of your host server.  B<NOTE> if you use this feature you should add the required
4291 middleware to your project dependency list since its not automatically a dependency of L<Catalyst>.
4292 This has been done since not all people need this feature and we wish to restrict the growth of
4293 L<Catalyst> dependencies.
4294
4295 =item *
4296
4297 C<encoding> - See L</ENCODING>
4298
4299 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
4300 value to undef.
4301
4302 =item *
4303
4304 C<abort_chain_on_error_fix>
4305
4306 Defaults to true.
4307
4308 When there is an error in an action chain, the default behavior is to
4309 abort the processing of the remaining actions to avoid running them
4310 when the application is in an unexpected state.
4311
4312 Before version 5.90070, the default used to be false. To keep the old
4313 behaviour, you can explicitly set the value to false. E.g.
4314
4315     __PACKAGE__->config(abort_chain_on_error_fix => 0);
4316
4317 If this setting is set to false, then the remaining actions are
4318 performed and the error is caught at the end of the chain.
4319
4320
4321 =item *
4322
4323 C<use_hash_multivalue_in_request>
4324
4325 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
4326 and C<parameters> return a hashref where values might be scalar or an arrayref
4327 depending on the incoming data.  In many cases this can be undesirable as it
4328 leads one to writing defensive code like the following:
4329
4330     my ($val) = ref($c->req->parameters->{a}) ?
4331       @{$c->req->parameters->{a}} :
4332         $c->req->parameters->{a};
4333
4334 Setting this configuration item to true will make L<Catalyst> populate the
4335 attributes underlying these methods with an instance of L<Hash::MultiValue>
4336 which is used by L<Plack::Request> and others to solve this very issue.  You
4337 may prefer this behavior to the default, if so enable this option (be warned
4338 if you enable it in a legacy application we are not sure if it is completely
4339 backwardly compatible).
4340
4341 =item *
4342
4343 C<skip_complex_post_part_handling>
4344
4345 When creating body parameters from a POST, if we run into a multipart POST
4346 that does not contain uploads, but instead contains inlined complex data
4347 (very uncommon) we cannot reliably convert that into field => value pairs.  So
4348 instead we create an instance of L<Catalyst::Request::PartData>.  If this causes
4349 issue for you, you can disable this by setting C<skip_complex_post_part_handling>
4350 to true (default is false).
4351
4352 =item *
4353
4354 C<skip_body_param_unicode_decoding>
4355
4356 Generally we decode incoming POST params based on your declared encoding (the
4357 default for this is to decode UTF-8).  If this is causing you trouble and you
4358 do not wish to turn all encoding support off (with the C<encoding> configuration
4359 parameter) you may disable this step atomically by setting this configuration
4360 parameter to true.
4361
4362 =item *
4363
4364 C<do_not_decode_query>
4365
4366 If true, then do not try to character decode any wide characters in your
4367 request URL query or keywords.  Most readings of the relevant specifications
4368 suggest these should be UTF-* encoded, which is the default that L<Catalyst>
4369 will use, however if you are creating a lot of URLs manually or have external
4370 evil clients, this might cause you trouble.  If you find the changes introduced
4371 in Catalyst version 5.90080+ break some of your query code, you may disable
4372 the UTF-8 decoding globally using this configuration.
4373
4374 This setting takes precedence over C<default_query_encoding>
4375
4376 =item *
4377
4378 C<do_not_check_query_encoding>
4379
4380 Catalyst versions 5.90080 - 5.90106 would decode query parts of an incoming
4381 request but would not raise an exception when the decoding failed due to
4382 incorrect unicode.  It now does, but if this change is giving you trouble
4383 you may disable it by setting this configuration to true.
4384
4385 =item *
4386
4387 C<default_query_encoding>
4388
4389 By default we decode query and keywords in your request URL using UTF-8, which
4390 is our reading of the relevant specifications.  This setting allows one to
4391 specify a fixed value for how to decode your query.  You might need this if
4392 you are doing a lot of custom encoding of your URLs and not using UTF-8.
4393
4394 =item *
4395
4396 C<use_chained_args_0_special_case>
4397
4398 In older versions of Catalyst, when more than one action matched the same path
4399 AND all those matching actions declared Args(0), we'd break the tie by choosing
4400 the first action defined.  We now normalized how Args(0) works so that it
4401 follows the same rule as Args(N), which is to say when we need to break a tie
4402 we choose the LAST action defined.  If this breaks your code and you don't
4403 have time to update to follow the new normalized approach, you may set this
4404 value to true and it will globally revert to the original chaining behavior.
4405
4406 =item *
4407
4408 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
4409
4410 =item *
4411
4412 C<data_handlers> - See L<DATA HANDLERS>.
4413
4414 =item *
4415
4416 C<stats_class_traits>
4417
4418 An arrayref of L<Moose::Role>s that get composed into your stats class.
4419
4420 =item *
4421
4422 C<request_class_traits>
4423
4424 An arrayref of L<Moose::Role>s that get composed into your request class.
4425
4426 =item *
4427
4428 C<response_class_traits>
4429
4430 An arrayref of L<Moose::Role>s that get composed into your response class.
4431
4432 =item *
4433
4434 C<inject_components>
4435
4436 A Hashref of L<Catalyst::Component> subclasses that are 'injected' into configuration.
4437 For example:
4438
4439     MyApp->config({
4440       inject_components => {
4441         'Controller::Err' => { from_component => 'Local::Controller::Errors' },
4442         'Model::Zoo' => { from_component => 'Local::Model::Foo' },
4443         'Model::Foo' => { from_component => 'Local::Model::Foo', roles => ['TestRole'] },
4444       },
4445       'Controller::Err' => { a => 100, b=>200, namespace=>'error' },
4446       'Model::Zoo' => { a => 2 },
4447       'Model::Foo' => { a => 100 },
4448     });
4449
4450 Generally L<Catalyst> looks for components in your Model/View or Controller directories.
4451 However for cases when you which to use an existing component and you don't need any
4452 customization (where for when you can apply a role to customize it) you may inject those
4453 components into your application.  Please note any configuration should be done 'in the
4454 normal way', with a key under configuration named after the component affix, as in the
4455 above example.
4456
4457 Using this type of injection allows you to construct significant amounts of your application
4458 with only configuration!.  This may or may not lead to increased code understanding.
4459
4460 Please not you may also call the ->inject_components application method as well, although
4461 you must do so BEFORE setup.
4462
4463 =back
4464
4465 =head1 EXCEPTIONS
4466
4467 Generally when you throw an exception inside an Action (or somewhere in
4468 your stack, such as in a model that an Action is calling) that exception
4469 is caught by Catalyst and unless you either catch it yourself (via eval
4470 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
4471 will eventually reach L</finalize_errors> and return either the debugging
4472 error stack page, or the default error page.  However, if your exception
4473 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
4474 instead rethrow it so that it can be handled by that middleware (which
4475 is part of the default middleware).  For example this would allow
4476
4477     use HTTP::Throwable::Factory 'http_throw';
4478
4479     sub throws_exception :Local {
4480       my ($self, $c) = @_;
4481
4482       http_throw(SeeOther => { location =>
4483         $c->uri_for($self->action_for('redirect')) });
4484
4485     }
4486
4487 =head1 INTERNAL ACTIONS
4488
4489 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
4490 C<_ACTION>, and C<_END>. These are by default not shown in the private
4491 action table, but you can make them visible with a config parameter.
4492
4493     MyApp->config(show_internal_actions => 1);
4494
4495 =head1 ON-DEMAND PARSER
4496
4497 The request body is usually parsed at the beginning of a request,
4498 but if you want to handle input yourself, you can enable on-demand
4499 parsing with a config parameter.
4500
4501     MyApp->config(parse_on_demand => 1);
4502
4503 =head1 PROXY SUPPORT
4504
4505 Many production servers operate using the common double-server approach,
4506 with a lightweight frontend web server passing requests to a larger
4507 backend server. An application running on the backend server must deal
4508 with two problems: the remote user always appears to be C<127.0.0.1> and
4509 the server's hostname will appear to be C<localhost> regardless of the
4510 virtual host that the user connected through.
4511
4512 Catalyst will automatically detect this situation when you are running
4513 the frontend and backend servers on the same machine. The following
4514 changes are made to the request.
4515
4516     $c->req->address is set to the user's real IP address, as read from
4517     the HTTP X-Forwarded-For header.
4518
4519     The host value for $c->req->base and $c->req->uri is set to the real
4520     host, as read from the HTTP X-Forwarded-Host header.
4521
4522 Additionally, you may be running your backend application on an insecure
4523 connection (port 80) while your frontend proxy is running under SSL.  If there
4524 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
4525 tell Catalyst what port the frontend listens on.  This will allow all URIs to
4526 be created properly.
4527
4528 In the case of passing in:
4529
4530     X-Forwarded-Port: 443
4531
4532 All calls to C<uri_for> will result in an https link, as is expected.
4533
4534 Obviously, your web server must support these headers for this to work.
4535
4536 In a more complex server farm environment where you may have your
4537 frontend proxy server(s) on different machines, you will need to set a
4538 configuration option to tell Catalyst to read the proxied data from the
4539 headers.
4540
4541     MyApp->config(using_frontend_proxy => 1);
4542
4543 If you do not wish to use the proxy support at all, you may set:
4544
4545     MyApp->config(ignore_frontend_proxy => 0);
4546
4547 =head2 Note about psgi files
4548
4549 Note that if you supply your own .psgi file, calling
4550 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
4551
4552 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
4553 in your psgi, for example:
4554
4555     builder {
4556         enable "Plack::Middleware::ReverseProxy";
4557         MyApp->psgi_app
4558     };
4559
4560 This will unconditionally add the ReverseProxy support, or you need to call
4561 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
4562 apply the support depending upon your config).
4563
4564 See L<Catalyst::PSGI> for more information.
4565
4566 =head1 THREAD SAFETY
4567
4568 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
4569 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
4570 believe the Catalyst core to be thread-safe.
4571
4572 If you plan to operate in a threaded environment, remember that all other
4573 modules you are using must also be thread-safe. Some modules, most notably
4574 L<DBD::SQLite>, are not thread-safe.
4575
4576 =head1 DATA HANDLERS
4577
4578 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
4579 form parameters and URL search query fields.  However it has become common
4580 for various alternative content types to be PUT or POSTed to your controllers
4581 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
4582 XML and other content types when communicating with an application server.  In
4583 order to better support this use case, L<Catalyst> defines a global configuration
4584 option, C<data_handlers>, which lets you associate a content type with a coderef
4585 that parses that content type into something Perl can readily access.
4586
4587     package MyApp::Web;
4588
4589     use Catalyst;
4590     use JSON::MaybeXS;
4591
4592     __PACKAGE__->config(
4593       data_handlers => {
4594         'application/json' => sub { local $/; decode_json $_->getline },
4595       },
4596       ## Any other configuration.
4597     );
4598
4599     __PACKAGE__->setup;
4600
4601 By default L<Catalyst> comes with a generic JSON data handler similar to the
4602 example given above, which uses L<JSON::MaybeXS> to provide either L<JSON::PP>
4603 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
4604 it installed (if you want the faster XS parser, add it to you project Makefile.PL
4605 or dist.ini, cpanfile, etc.)
4606
4607 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
4608 (matched against the incoming request type using a regexp such as to be case
4609 insensitive) and whose values are coderefs that receive a localized version of
4610 C<$_> which is a filehandle object pointing to received body.
4611
4612 This feature is considered an early access release and we reserve the right
4613 to alter the interface in order to provide a performant and secure solution to
4614 alternative request body content.  Your reports welcomed!
4615
4616 =head1 PSGI MIDDLEWARE
4617
4618 You can define middleware, defined as L<Plack::Middleware> or a compatible
4619 interface in configuration.  Your middleware definitions are in the form of an
4620 arrayref under the configuration key C<psgi_middleware>.  Here's an example
4621 with details to follow:
4622
4623     package MyApp::Web;
4624
4625     use Catalyst;
4626     use Plack::Middleware::StackTrace;
4627
4628     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4629
4630     __PACKAGE__->config(
4631       'psgi_middleware', [
4632         'Debug',
4633         '+MyApp::Custom',
4634         $stacktrace_middleware,
4635         'Session' => {store => 'File'},
4636         sub {
4637           my $app = shift;
4638           return sub {
4639             my $env = shift;
4640             $env->{myapp.customkey} = 'helloworld';
4641             $app->($env);
4642           },
4643         },
4644       ],
4645     );
4646
4647     __PACKAGE__->setup;
4648
4649 So the general form is:
4650
4651     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
4652
4653 Where C<@middleware> is one or more of the following, applied in the REVERSE of
4654 the order listed (to make it function similarly to L<Plack::Builder>:
4655
4656 Alternatively, you may also define middleware by calling the L</setup_middleware>
4657 package method:
4658
4659     package MyApp::Web;
4660
4661     use Catalyst;
4662
4663     __PACKAGE__->setup_middleware( \@middleware_definitions);
4664     __PACKAGE__->setup;
4665
4666 In the case where you do both (use 'setup_middleware' and configuration) the
4667 package call to setup_middleware will be applied earlier (in other words its
4668 middleware will wrap closer to the application).  Keep this in mind since in
4669 some cases the order of middleware is important.
4670
4671 The two approaches are not exclusive.
4672
4673 =over 4
4674
4675 =item Middleware Object
4676
4677 An already initialized object that conforms to the L<Plack::Middleware>
4678 specification:
4679
4680     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4681
4682     __PACKAGE__->config(
4683       'psgi_middleware', [
4684         $stacktrace_middleware,
4685       ]);
4686
4687
4688 =item coderef
4689
4690 A coderef that is an inlined middleware:
4691
4692     __PACKAGE__->config(
4693       'psgi_middleware', [
4694         sub {
4695           my $app = shift;
4696           return sub {
4697             my $env = shift;
4698             if($env->{PATH_INFO} =~m/forced/) {
4699               Plack::App::File
4700                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
4701                 ->call($env);
4702             } else {
4703               return $app->($env);
4704             }
4705          },
4706       },
4707     ]);
4708
4709
4710
4711 =item a scalar
4712
4713 We assume the scalar refers to a namespace after normalizing it using the
4714 following rules:
4715
4716 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
4717 is assumed to be 'as is', and we just install and use the middleware.
4718
4719 (2) If the scalar begins with "Plack::Middleware" or your application namespace
4720 (the package name of your Catalyst application subclass), we also assume then
4721 that it is a full namespace, and use it.
4722
4723 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
4724 resolve it first by looking for it under your application namespace (for example
4725 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
4726 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
4727 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
4728 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
4729 namespace first to let you 'override' common L<Plack::Middleware> locally, should
4730 you find that a good idea.
4731
4732 Examples:
4733
4734     package MyApp::Web;
4735
4736     __PACKAGE__->config(
4737       'psgi_middleware', [
4738         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
4739         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
4740         '+MyApp::Custom',  ## MyApp::Custom->wrap
4741       ],
4742     );
4743
4744 =item a scalar followed by a hashref
4745
4746 Just like the previous, except the following C<HashRef> is used as arguments
4747 to initialize the middleware object.
4748
4749     __PACKAGE__->config(
4750       'psgi_middleware', [
4751          'Session' => {store => 'File'},
4752     ]);
4753
4754 =back
4755
4756 Please see L<PSGI> for more on middleware.
4757
4758 =head1 ENCODING
4759
4760 Starting in L<Catalyst> version 5.90080 encoding is automatically enabled
4761 and set to encode all body responses to UTF8 when possible and applicable.
4762 Following is documentation on this process.  If you are using an older
4763 version of L<Catalyst> you should review documentation for that version since
4764 a lot has changed.
4765
4766 By default encoding is now 'UTF-8'.  You may turn it off by setting
4767 the encoding configuration to undef.
4768
4769     MyApp->config(encoding => undef);
4770
4771 This is recommended for temporary backwards compatibility only.
4772
4773 To turn it off for a single request use the L<clear_encoding>
4774 method to turn off encoding for this request.  This can be useful
4775 when you are setting the body to be an arbitrary block of bytes,
4776 especially if that block happens to be a block of UTF8 text.
4777
4778 Encoding is automatically applied when the content-type is set to
4779 a type that can be encoded.  Currently we encode when the content type
4780 matches the following regular expression:
4781
4782     $content_type =~ /^text|xml$|javascript$/
4783
4784 Encoding is set on the application, but it is copied to the context object
4785 so that you can override it on a request basis.
4786
4787 Be default we don't automatically encode 'application/json' since the most
4788 common approaches to generating this type of response (Either via L<Catalyst::View::JSON>
4789 or L<Catalyst::Action::REST>) will do so already and we want to avoid double
4790 encoding issues.
4791
4792 If you are producing JSON response in an unconventional manner (such
4793 as via a template or manual strings) you should perform the UTF8 encoding
4794 manually as well such as to conform to the JSON specification.
4795
4796 NOTE: We also examine the value of $c->response->content_encoding.  If
4797 you set this (like for example 'gzip', and manually gzipping the body)
4798 we assume that you have done all the necessary encoding yourself, since
4799 we cannot encode the gzipped contents.  If you use a plugin like
4800 L<Catalyst::Plugin::Compress> you need to update to a modern version in order
4801 to have this function correctly  with the new UTF8 encoding code, or you
4802 can use L<Plack::Middleware::Deflater> or (probably best) do your compression on
4803 a front end proxy.
4804
4805 =head2 Methods
4806
4807 =over 4
4808
4809 =item encoding
4810
4811 Returns an instance of an C<Encode> encoding
4812
4813     print $c->encoding->name
4814
4815 =item handle_unicode_encoding_exception ($exception_context)
4816
4817 Method called when decoding process for a request fails.
4818
4819 An C<$exception_context> hashref is provided to allow you to override the
4820 behaviour of your application when given data with incorrect encodings.
4821
4822 The default method throws exceptions in the case of invalid request parameters
4823 (resulting in a 500 error), but ignores errors in upload filenames.
4824
4825 The keys passed in the C<$exception_context> hash are:
4826
4827 =over
4828
4829 =item param_value
4830
4831 The value which was not able to be decoded.
4832
4833 =item error_msg
4834
4835 The exception received from L<Encode>.
4836
4837 =item encoding_step
4838
4839 What type of data was being decoded. Valid values are (currently)
4840 C<params> - for request parameters / arguments / captures
4841 and C<uploads> - for request upload filenames.
4842
4843 =back
4844
4845 =back
4846
4847 =head1 SUPPORT
4848
4849 IRC:
4850
4851     Join #catalyst on irc.perl.org.
4852
4853 Mailing Lists:
4854
4855     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4856     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4857
4858 Web:
4859
4860     http://catalyst.perl.org
4861
4862 Wiki:
4863
4864     http://dev.catalyst.perl.org
4865
4866 =head1 SEE ALSO
4867
4868 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4869
4870 =head2 L<Catalyst::Manual> - The Catalyst Manual
4871
4872 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4873
4874 =head2 L<Catalyst::Engine> - Core engine
4875
4876 =head2 L<Catalyst::Log> - Log class.
4877
4878 =head2 L<Catalyst::Request> - Request object
4879
4880 =head2 L<Catalyst::Response> - Response object
4881
4882 =head2 L<Catalyst::Test> - The test suite.
4883
4884 =head1 PROJECT FOUNDER
4885
4886 sri: Sebastian Riedel <sri@cpan.org>
4887
4888 =head1 CONTRIBUTORS
4889
4890 abw: Andy Wardley
4891
4892 acme: Leon Brocard <leon@astray.com>
4893
4894 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4895
4896 andrewalker: André Walker <andre@cpan.org>
4897
4898 Andrew Bramble
4899
4900 Andrew Ford <A.Ford@ford-mason.co.uk>
4901
4902 Andrew Ruthven
4903
4904 andyg: Andy Grundman <andy@hybridized.org>
4905
4906 audreyt: Audrey Tang
4907
4908 bricas: Brian Cassidy <bricas@cpan.org>
4909
4910 Caelum: Rafael Kitover <rkitover@io.com>
4911
4912 chansen: Christian Hansen
4913
4914 Chase Venters <chase.venters@gmail.com>
4915
4916 chicks: Christopher Hicks
4917
4918 Chisel Wright <pause@herlpacker.co.uk>
4919
4920 Danijel Milicevic <me@danijel.de>
4921
4922 davewood: David Schmidt <davewood@cpan.org>
4923
4924 David Kamholz <dkamholz@cpan.org>
4925
4926 David Naughton <naughton@umn.edu>
4927
4928 David E. Wheeler
4929
4930 dhoss: Devin Austin <dhoss@cpan.org>
4931
4932 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4933
4934 Drew Taylor
4935
4936 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4937
4938 esskar: Sascha Kiefer
4939
4940 fireartist: Carl Franks <cfranks@cpan.org>
4941
4942 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4943
4944 gabb: Danijel Milicevic
4945
4946 Gary Ashton Jones
4947
4948 Gavin Henry <ghenry@perl.me.uk>
4949
4950 Geoff Richards
4951
4952 groditi: Guillermo Roditi <groditi@gmail.com>
4953
4954 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4955
4956 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4957
4958 jcamacho: Juan Camacho
4959
4960 jester: Jesse Sheidlower <jester@panix.com>
4961
4962 jhannah: Jay Hannah <jay@jays.net>
4963
4964 Jody Belka
4965
4966 Johan Lindstrom
4967
4968 jon: Jon Schutz <jjschutz@cpan.org>
4969
4970 Jonathan Rockway <jrockway@cpan.org>
4971
4972 Kieren Diment <kd@totaldatasolution.com>
4973
4974 konobi: Scott McWhirter <konobi@cpan.org>
4975
4976 marcus: Marcus Ramberg <mramberg@cpan.org>
4977
4978 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4979
4980 mgrimes: Mark Grimes <mgrimes@cpan.org>
4981
4982 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4983
4984 mugwump: Sam Vilain
4985
4986 naughton: David Naughton
4987
4988 ningu: David Kamholz <dkamholz@cpan.org>
4989
4990 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4991
4992 numa: Dan Sully <daniel@cpan.org>
4993
4994 obra: Jesse Vincent
4995
4996 Octavian Rasnita
4997
4998 omega: Andreas Marienborg
4999
5000 Oleg Kostyuk <cub.uanic@gmail.com>
5001
5002 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
5003
5004 rafl: Florian Ragwitz <rafl@debian.org>
5005
5006 random: Roland Lammel <lammel@cpan.org>
5007
5008 revmischa: Mischa Spiegelmock <revmischa@cpan.org>
5009
5010 Robert Sedlacek <rs@474.at>
5011
5012 SpiceMan: Marcel Montes
5013
5014 sky: Arthur Bergman
5015
5016 szbalint: Balint Szilakszi <szbalint@cpan.org>
5017
5018 t0m: Tomas Doran <bobtfish@bobtfish.net>
5019
5020 Ulf Edvinsson
5021
5022 vanstyn: Henry Van Styn <vanstyn@cpan.org>
5023
5024 Viljo Marrandi <vilts@yahoo.com>
5025
5026 Will Hawes <info@whawes.co.uk>
5027
5028 willert: Sebastian Willert <willert@cpan.org>
5029
5030 wreis: Wallace Reis <wreis@cpan.org>
5031
5032 Yuval Kogman <nothingmuch@woobling.org>
5033
5034 rainboxx: Matthias Dietrich <perl@rainboxx.de>
5035
5036 dd070: Dhaval Dhanani <dhaval070@gmail.com>
5037
5038 Upasana <me@upasana.me>
5039
5040 John Napiorkowski (jnap) <jjnapiork@cpan.org>
5041
5042 =head1 COPYRIGHT
5043
5044 Copyright (c) 2005-2015, the above named PROJECT FOUNDER and CONTRIBUTORS.
5045
5046 =head1 LICENSE
5047
5048 This library is free software. You can redistribute it and/or modify it under
5049 the same terms as Perl itself.
5050
5051 =cut
5052
5053 no Moose;
5054
5055 __PACKAGE__->meta->make_immutable;
5056
5057 1;