lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use File::stat;
  19 use Text::SimpleTable ();
  20 use Path::Class::Dir ();
  21 use Path::Class::File ();
  22 use URI ();
  23 use URI::http;
  24 use URI::https;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use Class::C3::Adopt::NEXT;
  28 use List::MoreUtils qw/uniq/;
  29 use attributes;
  30 use utf8;
  31 use Carp qw/croak carp shortmess/;
  32
  33 BEGIN { require 5.008004; }
  34
  35 has stack => (is => 'ro', default => sub { [] });
  36 has stash => (is => 'rw', default => sub { {} });
  37 has state => (is => 'rw', default => 0);
  38 has stats => (is => 'rw');
  39 has action => (is => 'rw');
  40 has counter => (is => 'rw', default => sub { {} });
  41 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  42 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  43 has namespace => (is => 'rw');
  44
  45 sub depth { scalar @{ shift->stack || [] }; }
  46 sub comp { shift->component(@_) }
  47
  48 sub req {
  49     my $self = shift; return $self->request(@_);
  50 }
  51 sub res {
  52     my $self = shift; return $self->response(@_);
  53 }
  54
  55 # For backwards compatibility
  56 sub finalize_output { shift->finalize_body(@_) };
  57
  58 # For statistics
  59 our $COUNT     = 1;
  60 our $START     = time;
  61 our $RECURSION = 1000;
  62 our $DETACH    = Catalyst::Exception::Detach->new;
  63 our $GO        = Catalyst::Exception::Go->new;
  64
  65 #I imagine that very few of these really need to be class variables. if any.
  66 #maybe we should just make them attributes with a default?
  67 __PACKAGE__->mk_classdata($_)
  68   for qw/container arguments dispatcher engine log dispatcher_class
  69   engine_class context_class request_class response_class stats_class
  70   setup_finished/;
  71
  72 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  73 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  74 __PACKAGE__->request_class('Catalyst::Request');
  75 __PACKAGE__->response_class('Catalyst::Response');
  76 __PACKAGE__->stats_class('Catalyst::Stats');
  77
  78 # Remember to update this in Catalyst::Runtime as well!
  79
  80 our $VERSION = '5.80033';
  81
  82 sub import {
  83     my ( $class, @arguments ) = @_;
  84
  85     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  86     # callers @ISA.
  87     return unless $class eq 'Catalyst';
  88
  89     my $caller = caller();
  90     return if $caller eq 'main';
  91
  92     my $meta = Moose::Meta::Class->initialize($caller);
  93
  94     unless ( $caller->isa('Catalyst') ) { # XXX - Remove!
  95         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Component'); # XXX - Remove!
  96         $meta->superclasses(@superclasses); # XXX - Remove!
  97     } # XXX - Remove!
  98
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub MODIFY_CODE_ATTRIBUTES {
 116     Catalyst::Exception->throw(
 117         "Catalyst applications (aka MyApp) cannot be controllers anymore. " .
 118         "That has been deprecated and removed. You should create a " .
 119         "controller class called Root.pm, and move relevant code to that class."
 120     );
 121 }
 122
 123
 124 sub _application { $_[0] }
 125
 126 =head1 NAME
 127
 128 Catalyst - The Elegant MVC Web Application Framework
 129
 130 =head1 SYNOPSIS
 131
 132 See the L<Catalyst::Manual> distribution for comprehensive
 133 documentation and tutorials.
 134
 135     # Install Catalyst::Devel for helpers and other development tools
 136     # use the helper to create a new application
 137     catalyst.pl MyApp
 138
 139     # add models, views, controllers
 140     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 141     script/myapp_create.pl view MyTemplate TT
 142     script/myapp_create.pl controller Search
 143
 144     # built in testserver -- use -r to restart automatically on changes
 145     # --help to see all available options
 146     script/myapp_server.pl
 147
 148     # command line testing interface
 149     script/myapp_test.pl /yada
 150
 151     ### in lib/MyApp.pm
 152     use Catalyst qw/-Debug/; # include plugins here as well
 153
 154     ### In lib/MyApp/Controller/Root.pm (autocreated)
 155     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 156         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 157         $c->stash->{template} = 'foo.tt'; # set the template
 158         # lookup something from db -- stash vars are passed to TT
 159         $c->stash->{data} =
 160           $c->model('Database::Foo')->search( { country => $args[0] } );
 161         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 162             $c->forward( 'bar' ); # process another action
 163             # do something else after forward returns
 164         }
 165     }
 166
 167     # The foo.tt TT template can use the stash data from the database
 168     [% WHILE (item = data.next) %]
 169         [% item.foo %]
 170     [% END %]
 171
 172     # called for /bar/of/soap, /bar/of/soap/10, etc.
 173     sub bar : Path('/bar/of/soap') { ... }
 174
 175     # called for all actions, from the top-most controller downwards
 176     sub auto : Private {
 177         my ( $self, $c ) = @_;
 178         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 179             $c->res->redirect( '/login' ); # require login
 180             return 0; # abort request and go immediately to end()
 181         }
 182         return 1; # success; carry on to next action
 183     }
 184
 185     # called after all actions are finished
 186     sub end : Private {
 187         my ( $self, $c ) = @_;
 188         if ( scalar @{ $c->error } ) { ... } # handle errors
 189         return if $c->res->body; # already have a response
 190         $c->forward( 'MyApp::View::TT' ); # render template
 191     }
 192
 193     ### in MyApp/Controller/Foo.pm
 194     # called for /foo/bar
 195     sub bar : Local { ... }
 196
 197     # called for /blargle
 198     sub blargle : Global { ... }
 199
 200     # an index action matches /foo, but not /foo/1, etc.
 201     sub index : Private { ... }
 202
 203     ### in MyApp/Controller/Foo/Bar.pm
 204     # called for /foo/bar/baz
 205     sub baz : Local { ... }
 206
 207     # first Root auto is called, then Foo auto, then this
 208     sub auto : Private { ... }
 209
 210     # powerful regular expression paths are also possible
 211     sub details : Regex('^product/(\w+)/details$') {
 212         my ( $self, $c ) = @_;
 213         # extract the (\w+) from the URI
 214         my $product = $c->req->captures->[0];
 215     }
 216
 217 See L<Catalyst::Manual::Intro> for additional information.
 218
 219 =head1 DESCRIPTION
 220
 221 Catalyst is a modern framework for making web applications without the
 222 pain usually associated with this process. This document is a reference
 223 to the main Catalyst application. If you are a new user, we suggest you
 224 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 225
 226 See L<Catalyst::Manual> for more documentation.
 227
 228 Catalyst plugins can be loaded by naming them as arguments to the "use
 229 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 230 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 231 C<My::Module>.
 232
 233     use Catalyst qw/My::Module/;
 234
 235 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 236 fully qualify the name by using a unary plus:
 237
 238     use Catalyst qw/
 239         My::Module
 240         +Fully::Qualified::Plugin::Name
 241     /;
 242
 243 Special flags like C<-Debug> and C<-Engine> can also be specified as
 244 arguments when Catalyst is loaded:
 245
 246     use Catalyst qw/-Debug My::Module/;
 247
 248 The position of plugins and flags in the chain is important, because
 249 they are loaded in the order in which they appear.
 250
 251 The following flags are supported:
 252
 253 =head2 -Debug
 254
 255 Enables debug output. You can also force this setting from the system
 256 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 257 settings override the application, with <MYAPP>_DEBUG having the highest
 258 priority.
 259
 260 This sets the log level to 'debug' and enables full debug output on the
 261 error screen. If you only want the latter, see L<< $c->debug >>.
 262
 263 =head2 -Engine
 264
 265 Forces Catalyst to use a specific engine. Omit the
 266 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 267
 268     use Catalyst qw/-Engine=CGI/;
 269
 270 =head2 -Home
 271
 272 Forces Catalyst to use a specific home directory, e.g.:
 273
 274     use Catalyst qw[-Home=/usr/mst];
 275
 276 This can also be done in the shell environment by setting either the
 277 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 278 is replaced with the uppercased name of your application, any "::" in
 279 the name will be replaced with underscores, e.g. MyApp::Web should use
 280 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 281
 282 If none of these are set, Catalyst will attempt to automatically detect the
 283 home directory. If you are working in a development envirnoment, Catalyst
 284 will try and find the directory containing either Makefile.PL, Build.PL or
 285 dist.ini. If the application has been installed into the system (i.e.
 286 you have done C<make install>), then Catalyst will use the path to your
 287 application module, without the .pm extension (ie, /foo/MyApp if your
 288 application was installed at /foo/MyApp.pm)
 289
 290 =head2 -Log
 291
 292     use Catalyst '-Log=warn,fatal,error';
 293
 294 Specifies a comma-delimited list of log levels.
 295
 296 =head2 -Stats
 297
 298 Enables statistics collection and reporting.
 299
 300    use Catalyst qw/-Stats=1/;
 301
 302 You can also force this setting from the system environment with CATALYST_STATS
 303 or <MYAPP>_STATS. The environment settings override the application, with
 304 <MYAPP>_STATS having the highest priority.
 305
 306 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 307
 308 =head1 METHODS
 309
 310 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 311
 312 =head2 $c->action
 313
 314 Returns a L<Catalyst::Action> object for the current action, which
 315 stringifies to the action name. See L<Catalyst::Action>.
 316
 317 =head2 $c->namespace
 318
 319 Returns the namespace of the current action, i.e., the URI prefix
 320 corresponding to the controller of the current action. For example:
 321
 322     # in Controller::Foo::Bar
 323     $c->namespace; # returns 'foo/bar';
 324
 325 =head2 $c->request
 326
 327 =head2 $c->req
 328
 329 Returns the current L<Catalyst::Request> object, giving access to
 330 information about the current client request (including parameters,
 331 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 332
 333 =head2 REQUEST FLOW HANDLING
 334
 335 =head2 $c->forward( $action [, \@arguments ] )
 336
 337 =head2 $c->forward( $class, $method, [, \@arguments ] )
 338
 339 Forwards processing to another action, by its private name. If you give a
 340 class name but no method, C<process()> is called. You may also optionally
 341 pass arguments in an arrayref. The action will receive the arguments in
 342 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 343 C<< $c->req->args >> will be restored to the previous values.
 344
 345 Any data C<return>ed from the action forwarded to, will be returned by the
 346 call to forward.
 347
 348     my $foodata = $c->forward('/foo');
 349     $c->forward('index');
 350     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 351     $c->forward('View::TT');
 352
 353 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 354 an C<< eval { } >> around the call (actually
 355 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 356 all 'dies' within the called action. If you want C<die> to propagate you
 357 need to do something like:
 358
 359     $c->forward('foo');
 360     die join "\n", @{ $c->error } if @{ $c->error };
 361
 362 Or make sure to always return true values from your actions and write
 363 your code like this:
 364
 365     $c->forward('foo') || return;
 366
 367 Another note is that C<< $c->forward >> always returns a scalar because it
 368 actually returns $c->state which operates in a scalar context.
 369 Thus, something like:
 370
 371     return @array;
 372
 373 in an action that is forwarded to is going to return a scalar,
 374 i.e. how many items are in that array, which is probably not what you want.
 375 If you need to return an array then return a reference to it,
 376 or stash it like so:
 377
 378     $c->stash->{array} = \@array;
 379
 380 and access it from the stash.
 381
 382 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 383
 384 =cut
 385
 386 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 387
 388 =head2 $c->detach( $action [, \@arguments ] )
 389
 390 =head2 $c->detach( $class, $method, [, \@arguments ] )
 391
 392 =head2 $c->detach()
 393
 394 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 395 doesn't return to the previous action when processing is finished.
 396
 397 When called with no arguments it escapes the processing chain entirely.
 398
 399 =cut
 400
 401 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 402
 403 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 404
 405 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 406
 407 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 408 but does a full dispatch, instead of just calling the new C<$action> /
 409 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 410 you go to are called, just like a new request.
 411
 412 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 413 This means, for example, that C<< $c->action >> methods such as
 414 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 415 L<reverse|Catalyst::Action/reverse> return information for the visited action
 416 when they are invoked within the visited action.  This is different from the
 417 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 418 continues to use the $c->action object from the caller action even when
 419 invoked from the callee.
 420
 421 C<< $c->stash >> is kept unchanged.
 422
 423 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 424 allows you to "wrap" another action, just as it would have been called by
 425 dispatching from a URL, while the analogous
 426 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 427 transfer control to another action as if it had been reached directly from a URL.
 428
 429 =cut
 430
 431 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 432
 433 =head2 $c->go( $action [, \@captures, \@arguments ] )
 434
 435 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 436
 437 The relationship between C<go> and
 438 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 439 the relationship between
 440 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 441 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 442 C<< $c->go >> will perform a full dispatch on the specified action or method,
 443 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 444 C<go> escapes the processing of the current request chain on completion, and
 445 does not return to its caller.
 446
 447 @arguments are arguments to the final destination of $action. @captures are
 448 arguments to the intermediate steps, if any, on the way to the final sub of
 449 $action.
 450
 451 =cut
 452
 453 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 454
 455 =head2 $c->response
 456
 457 =head2 $c->res
 458
 459 Returns the current L<Catalyst::Response> object, see there for details.
 460
 461 =head2 $c->stash
 462
 463 Returns a hashref to the stash, which may be used to store data and pass
 464 it between components during a request. You can also set hash keys by
 465 passing arguments. The stash is automatically sent to the view. The
 466 stash is cleared at the end of a request; it cannot be used for
 467 persistent storage (for this you must use a session; see
 468 L<Catalyst::Plugin::Session> for a complete system integrated with
 469 Catalyst).
 470
 471     $c->stash->{foo} = $bar;
 472     $c->stash( { moose => 'majestic', qux => 0 } );
 473     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 474
 475     # stash is automatically passed to the view for use in a template
 476     $c->forward( 'MyApp::View::TT' );
 477
 478 =cut
 479
 480 around stash => sub {
 481     my $orig = shift;
 482     my $c = shift;
 483     my $stash = $orig->($c);
 484     if (@_) {
 485         my $new_stash = @_ > 1 ? {@_} : $_[0];
 486         croak('stash takes a hash or hashref') unless ref $new_stash;
 487         foreach my $key ( keys %$new_stash ) {
 488           $stash->{$key} = $new_stash->{$key};
 489         }
 490     }
 491
 492     return $stash;
 493 };
 494
 495
 496 =head2 $c->error
 497
 498 =head2 $c->error($error, ...)
 499
 500 =head2 $c->error($arrayref)
 501
 502 Returns an arrayref containing error messages.  If Catalyst encounters an
 503 error while processing a request, it stores the error in $c->error.  This
 504 method should only be used to store fatal error messages.
 505
 506     my @error = @{ $c->error };
 507
 508 Add a new error.
 509
 510     $c->error('Something bad happened');
 511
 512 =cut
 513
 514 sub error {
 515     my $c = shift;
 516     if ( $_[0] ) {
 517         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 518         croak @$error unless ref $c;
 519         push @{ $c->{error} }, @$error;
 520     }
 521     elsif ( defined $_[0] ) { $c->{error} = undef }
 522     return $c->{error} || [];
 523 }
 524
 525
 526 =head2 $c->state
 527
 528 Contains the return value of the last executed action.
 529 Note that << $c->state >> operates in a scalar context which means that all
 530 values it returns are scalar.
 531
 532 =head2 $c->clear_errors
 533
 534 Clear errors.  You probably don't want to clear the errors unless you are
 535 implementing a custom error screen.
 536
 537 This is equivalent to running
 538
 539     $c->error(0);
 540
 541 =cut
 542
 543 sub clear_errors {
 544     my $c = shift;
 545     $c->error(0);
 546 }
 547
 548 =head2 COMPONENT ACCESSORS
 549
 550 =head2 $c->controller($name)
 551
 552 Gets a L<Catalyst::Controller> instance by name.
 553
 554     $c->controller('Foo')->do_stuff;
 555
 556 If the name is omitted, will return the controller for the dispatched
 557 action.
 558
 559 If you want to search for controllers, pass in a regexp as the argument.
 560
 561     # find all controllers that start with Foo
 562     my @foo_controllers = $c->controller(qr{^Foo});
 563
 564
 565 =cut
 566
 567 sub controller { shift->_lookup_mvc('controller', @_) }
 568
 569 =head2 $c->model($name)
 570
 571 Gets a L<Catalyst::Model> instance by name.
 572
 573     $c->model('Foo')->do_stuff;
 574
 575 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 576
 577 If the name is omitted, it will look for
 578  - a model object in $c->stash->{current_model_instance}, then
 579  - a model name in $c->stash->{current_model}, then
 580  - a config setting 'default_model', or
 581  - check if there is only one model, and return it if that's the case.
 582
 583 If you want to search for models, pass in a regexp as the argument.
 584
 585     # find all models that start with Foo
 586     my @foo_models = $c->model(qr{^Foo});
 587
 588 =cut
 589
 590 sub model { shift->_lookup_mvc('model', @_) }
 591
 592 =head2 $c->view($name)
 593
 594 Gets a L<Catalyst::View> instance by name.
 595
 596     $c->view('Foo')->do_stuff;
 597
 598 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 599
 600 If the name is omitted, it will look for
 601  - a view object in $c->stash->{current_view_instance}, then
 602  - a view name in $c->stash->{current_view}, then
 603  - a config setting 'default_view', or
 604  - check if there is only one view, and return it if that's the case.
 605
 606 If you want to search for views, pass in a regexp as the argument.
 607
 608     # find all views that start with Foo
 609     my @foo_views = $c->view(qr{^Foo});
 610
 611 =cut
 612
 613 sub view { shift->_lookup_mvc('view', @_) }
 614
 615 sub _lookup_mvc {
 616     my ( $c, $type, $name, @args ) = @_;
 617
 618     if (ref $c && !$name) {
 619         my $current_instance = $c->stash->{"current_${type}_instance"};
 620         return $current_instance
 621             if $current_instance && $type ne 'controller';
 622
 623         $name = $type eq 'controller'
 624               ? Catalyst::Utils::class2classshortsuffix($c->action->class)
 625               : $c->stash->{"current_${type}"}
 626               ;
 627     }
 628
 629     return $c->container->get_component_from_sub_container($type, $name, $c, @args);
 630 }
 631
 632 =head2 $c->controllers
 633
 634 Returns the available names which can be passed to $c->controller
 635
 636 =cut
 637
 638 sub controllers {
 639     my ( $c ) = @_;
 640     return $c->container->get_sub_container('controller')->get_service_list;
 641 }
 642
 643 =head2 $c->models
 644
 645 Returns the available names which can be passed to $c->model
 646
 647 =cut
 648
 649 sub models {
 650     my ( $c ) = @_;
 651     return $c->container->get_sub_container('model')->get_service_list;
 652 }
 653
 654
 655 =head2 $c->views
 656
 657 Returns the available names which can be passed to $c->view
 658
 659 =cut
 660
 661 sub views {
 662     my ( $c ) = @_;
 663     return $c->container->get_sub_container('view')->get_service_list;
 664 }
 665
 666 =head2 $c->comp($name)
 667
 668 =head2 $c->component($name)
 669
 670 Gets a component object by name. This method is not recommended,
 671 unless you want to get a specific component by full
 672 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 673 should be used instead.
 674
 675 If C<$name> is a regexp, a list of components matched against the full
 676 component name will be returned.
 677
 678 =cut
 679
 680 sub component {
 681     my ( $c, $component, @args ) = @_;
 682
 683     unless ($component) {
 684         $c->log->warn('Calling $c->component with no args is deprecated and ');
 685         $c->log->warn('will be removed in a future release.');
 686         $c->log->warn('Use $c->component_list instead.');
 687         return $c->component_list;
 688     }
 689
 690     my @result = $c->container->find_component( $component, $c, @args );
 691
 692     # list context for regexp searches
 693     return @result if ref $component;
 694
 695     # only one component (if it's found) for string searches
 696     return shift @result if @result;
 697
 698     if (ref $c eq $component) {
 699         $c->log->warn('You are calling $c->comp("MyApp"). This behaviour is');
 700         $c->log->warn('deprecated, and will be removed in a future release.');
 701         return $c;
 702     }
 703
 704     $c->log->warn("Looking for '$component', but nothing was found.");
 705
 706     # I would expect to return an empty list here, but that breaks back-compat
 707     $c->log->warn('Component not found, returning the list of existing');
 708     $c->log->warn('components. This behavior is deprecated and will be');
 709     $c->log->warn('removed in a future release. Use $c->component_list');
 710     $c->log->warn('instead.');
 711
 712     return $c->component_list;
 713 }
 714
 715 =head2 $c->component_list
 716
 717 Returns the sorted list of the component names of the application.
 718
 719 =cut
 720
 721 sub component_list { sort keys %{ shift->components } }
 722
 723 =head2 CLASS DATA AND HELPER CLASSES
 724
 725 =head2 $c->config
 726
 727 Returns or takes a hashref containing the application's configuration.
 728
 729     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 730
 731 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 732 like C<myapp.conf> in your applications home directory. See
 733 L<Catalyst::Plugin::ConfigLoader>.
 734
 735 =head3 Cascading configuration
 736
 737 The config method is present on all Catalyst components, and configuration
 738 will be merged when an application is started. Configuration loaded with
 739 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 740 followed by configuration in your top level C<MyApp> class. These two
 741 configurations are merged, and then configuration data whose hash key matches a
 742 component name is merged with configuration for that component.
 743
 744 The configuration for a component is then passed to the C<new> method when a
 745 component is constructed.
 746
 747 For example:
 748
 749     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 750     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 751
 752 will mean that C<MyApp::Model::Foo> receives the following data when
 753 constructed:
 754
 755     MyApp::Model::Foo->new({
 756         bar => 'baz',
 757         quux => 'frob',
 758         overrides => 'me',
 759     });
 760
 761 It's common practice to use a Moose attribute
 762 on the receiving component to access the config value.
 763
 764     package MyApp::Model::Foo;
 765
 766     use Moose;
 767
 768     # this attr will receive 'baz' at construction time
 769     has 'bar' => (
 770         is  => 'rw',
 771         isa => 'Str',
 772     );
 773
 774 You can then get the value 'baz' by calling $c->model('Foo')->bar
 775 (or $self->bar inside code in the model).
 776
 777 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 778 as a way of reading config within your code, as this B<will not> give you the
 779 correctly merged config back. You B<MUST> take the config values supplied to
 780 the constructor and use those instead.
 781
 782 =cut
 783
 784 around config => sub {
 785     my $orig = shift;
 786     my $c = shift;
 787
 788     croak('Setting config after setup has been run is not allowed.')
 789         if ( @_ and $c->setup_finished );
 790
 791     $c->$orig(@_);
 792 };
 793
 794 =head2 $c->log
 795
 796 Returns the logging object instance. Unless it is already set, Catalyst
 797 sets this up with a L<Catalyst::Log> object. To use your own log class,
 798 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 799 C<< __PACKAGE__->setup >>.
 800
 801  __PACKAGE__->log( MyLogger->new );
 802  __PACKAGE__->setup;
 803
 804 And later:
 805
 806     $c->log->info( 'Now logging with my own logger!' );
 807
 808 Your log class should implement the methods described in
 809 L<Catalyst::Log>.
 810
 811
 812 =head2 $c->debug
 813
 814 Returns 1 if debug mode is enabled, 0 otherwise.
 815
 816 You can enable debug mode in several ways:
 817
 818 =over
 819
 820 =item By calling myapp_server.pl with the -d flag
 821
 822 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 823
 824 =item The -Debug option in your MyApp.pm
 825
 826 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 827
 828 =back
 829
 830 The first three also set the log level to 'debug'.
 831
 832 Calling C<< $c->debug(1) >> has no effect.
 833
 834 =cut
 835
 836 sub debug { 0 }
 837
 838 =head2 $c->dispatcher
 839
 840 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 841
 842 =head2 $c->engine
 843
 844 Returns the engine instance. See L<Catalyst::Engine>.
 845
 846
 847 =head2 UTILITY METHODS
 848
 849 =head2 $c->path_to(@path)
 850
 851 Merges C<@path> with C<< $c->config->{home} >> and returns a
 852 L<Path::Class::Dir> object. Note you can usually use this object as
 853 a filename, but sometimes you will have to explicitly stringify it
 854 yourself by calling the C<< ->stringify >> method.
 855
 856 For example:
 857
 858     $c->path_to( 'db', 'sqlite.db' );
 859
 860 =cut
 861
 862 sub path_to {
 863     my ( $c, @path ) = @_;
 864     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 865     if ( -d $path ) { return $path }
 866     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 867 }
 868
 869 =head2 $c->plugin( $name, $class, @args )
 870
 871 Helper method for plugins. It creates a class data accessor/mutator and
 872 loads and instantiates the given class.
 873
 874     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 875
 876     $c->prototype->define_javascript_functions;
 877
 878 B<Note:> This method of adding plugins is deprecated. The ability
 879 to add plugins like this B<will be removed> in a Catalyst 5.81.
 880 Please do not use this functionality in new code.
 881
 882 =cut
 883
 884 sub plugin {
 885     my ( $class, $name, $plugin, @args ) = @_;
 886
 887     # See block comment in t/aggregate/unit_core_plugin.t
 888     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 889
 890     $class->_register_plugin( $plugin, 1 );
 891
 892     eval { $plugin->import };
 893     $class->mk_classdata($name);
 894     my $obj;
 895     eval { $obj = $plugin->new(@args) };
 896
 897     if ($@) {
 898         Catalyst::Exception->throw( message =>
 899               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 900     }
 901
 902     $class->$name($obj);
 903     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 904       if $class->debug;
 905 }
 906
 907 =head2 MyApp->setup
 908
 909 Initializes the dispatcher and engine, loads any plugins, and loads the
 910 model, view, and controller components. You may also specify an array
 911 of plugins to load here, if you choose to not load them in the C<use
 912 Catalyst> line.
 913
 914     MyApp->setup;
 915     MyApp->setup( qw/-Debug/ );
 916
 917 =cut
 918
 919 sub setup {
 920     my ( $class, @arguments ) = @_;
 921     croak('Running setup more than once')
 922         if ( $class->setup_finished );
 923
 924     unless ( $class->isa('Catalyst') ) {
 925
 926         Catalyst::Exception->throw(
 927             message => qq/'$class' does not inherit from Catalyst/ );
 928     }
 929
 930     if ( $class->arguments ) {
 931         @arguments = ( @arguments, @{ $class->arguments } );
 932     }
 933
 934     # Process options
 935     my $flags = {};
 936
 937     foreach (@arguments) {
 938
 939         if (/^-Debug$/) {
 940             $flags->{log} =
 941               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 942         }
 943         elsif (/^-(\w+)=?(.*)$/) {
 944             $flags->{ lc $1 } = $2;
 945         }
 946         else {
 947             push @{ $flags->{plugins} }, $_;
 948         }
 949     }
 950
 951     $class->setup_config();
 952     $class->setup_home( delete $flags->{home} );
 953
 954     $class->setup_log( delete $flags->{log} );
 955     $class->setup_plugins( delete $flags->{plugins} );
 956     $class->setup_dispatcher( delete $flags->{dispatcher} );
 957     $class->setup_engine( delete $flags->{engine} );
 958     $class->setup_stats( delete $flags->{stats} );
 959
 960     for my $flag ( sort keys %{$flags} ) {
 961
 962         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 963             &$code( $class, delete $flags->{$flag} );
 964         }
 965         else {
 966             $class->log->warn(qq/Unknown flag "$flag"/);
 967         }
 968     }
 969
 970     eval { require Catalyst::Devel; };
 971     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 972         $class->log->warn(<<"EOF");
 973 You are running an old script!
 974
 975   Please update by running (this will overwrite existing files):
 976     catalyst.pl -force -scripts $class
 977
 978   or (this will not overwrite existing files):
 979     catalyst.pl -scripts $class
 980
 981 EOF
 982     }
 983
 984     if ( $class->debug ) {
 985         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 986
 987         if (@plugins) {
 988             my $column_width = Catalyst::Utils::term_width() - 6;
 989             my $t = Text::SimpleTable->new($column_width);
 990             $t->row($_) for @plugins;
 991             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 992         }
 993
 994         my $dispatcher = $class->dispatcher;
 995         my $engine     = $class->engine;
 996         my $home       = $class->config->{home};
 997
 998         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
 999         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1000
1001         $home
1002           ? ( -d $home )
1003           ? $class->log->debug(qq/Found home "$home"/)
1004           : $class->log->debug(qq/Home "$home" doesn't exist/)
1005           : $class->log->debug(q/Couldn't find home/);
1006     }
1007
1008     # Call plugins setup, this is stupid and evil.
1009     # Also screws C3 badly on 5.10, hack to avoid.
1010     {
1011         no warnings qw/redefine/;
1012         local *setup = sub { };
1013         $class->setup unless $Catalyst::__AM_RESTARTING;
1014     }
1015
1016     $class->setup_components;
1017
1018     if (
1019         $class->debug and
1020         my %comps = $class->container->get_all_components
1021     ) {
1022         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1023         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1024         $t->row( $_ => ref($comps{$_}) ? 'instance' : 'class' ) for keys %comps;
1025
1026         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" );
1027     }
1028
1029     $class->setup_actions;
1030
1031     if ( $class->debug ) {
1032         my $name = $class->config->{name} || 'Application';
1033         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1034     }
1035
1036     # Make sure that the application class becomes immutable at this point,
1037     B::Hooks::EndOfScope::on_scope_end {
1038         return if $@;
1039         my $meta = Class::MOP::get_metaclass_by_name($class);
1040         if (
1041             $meta->is_immutable
1042             && ! { $meta->immutable_options }->{replace_constructor}
1043             && (
1044                    $class->isa('Class::Accessor::Fast')
1045                 || $class->isa('Class::Accessor')
1046             )
1047         ) {
1048             warn "You made your application class ($class) immutable, "
1049                 . "but did not inline the\nconstructor. "
1050                 . "This will break catalyst, as your app \@ISA "
1051                 . "Class::Accessor(::Fast)?\nPlease pass "
1052                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1053         }
1054         $meta->make_immutable(
1055             replace_constructor => 1,
1056         ) unless $meta->is_immutable;
1057     };
1058
1059     if ($class->config->{case_sensitive}) {
1060         $class->log->warn($class . "->config->{case_sensitive} is set.");
1061         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1062     }
1063
1064     $class->setup_finalize;
1065     # Should be the last thing we do so that user things hooking
1066     # setup_finalize can log..
1067     $class->log->_flush() if $class->log->can('_flush');
1068     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1069 }
1070
1071 =head2 $app->setup_finalize
1072
1073 A hook to attach modifiers to. This method does not do anything except set the
1074 C<setup_finished> accessor.
1075
1076 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1077
1078 Example:
1079
1080     after setup_finalize => sub {
1081         my $app = shift;
1082
1083         ## do stuff here..
1084     };
1085
1086 =cut
1087
1088 sub setup_finalize {
1089     my ($class) = @_;
1090     $class->setup_finished(1);
1091 }
1092
1093 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1094
1095 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1096
1097 Constructs an absolute L<URI> object based on the application root, the
1098 provided path, and the additional arguments and query parameters provided.
1099 When used as a string, provides a textual URI.  If you need more flexibility
1100 than this (i.e. the option to provide relative URIs etc.) see
1101 L<Catalyst::Plugin::SmartURI>.
1102
1103 If no arguments are provided, the URI for the current action is returned.
1104 To return the current action and also provide @args, use
1105 C<< $c->uri_for( $c->action, @args ) >>.
1106
1107 If the first argument is a string, it is taken as a public URI path relative
1108 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1109 relative to the application root (if it does). It is then merged with
1110 C<< $c->request->base >>; any C<@args> are appended as additional path
1111 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1112
1113 If the first argument is a L<Catalyst::Action> it represents an action which
1114 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1115 optional C<\@captures> argument (an arrayref) allows passing the captured
1116 variables that are needed to fill in the paths of Chained and Regex actions;
1117 once the path is resolved, C<uri_for> continues as though a path was
1118 provided, appending any arguments or parameters and creating an absolute
1119 URI.
1120
1121 The captures for the current request can be found in
1122 C<< $c->request->captures >>, and actions can be resolved using
1123 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1124 path, use C<< $c->uri_for_action >> instead.
1125
1126   # Equivalent to $c->req->uri
1127   $c->uri_for($c->action, $c->req->captures,
1128       @{ $c->req->args }, $c->req->params);
1129
1130   # For the Foo action in the Bar controller
1131   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1132
1133   # Path to a static resource
1134   $c->uri_for('/static/images/logo.png');
1135
1136 =cut
1137
1138 sub uri_for {
1139     my ( $c, $path, @args ) = @_;
1140
1141     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1142         $path = $path->path_prefix;
1143         $path =~ s{/+\z}{};
1144         $path .= '/';
1145     }
1146
1147     undef($path) if (defined $path && $path eq '');
1148
1149     my $params =
1150       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1151
1152     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1153     foreach my $arg (@args) {
1154         utf8::encode($arg) if utf8::is_utf8($arg);
1155         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1156     }
1157
1158     if ( blessed($path) ) { # action object
1159         s|/|%2F|g for @args;
1160         my $captures = [ map { s|/|%2F|g; $_; }
1161                         ( scalar @args && ref $args[0] eq 'ARRAY'
1162                          ? @{ shift(@args) }
1163                          : ()) ];
1164
1165         foreach my $capture (@$captures) {
1166             utf8::encode($capture) if utf8::is_utf8($capture);
1167             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1168         }
1169
1170         my $action = $path;
1171         $path = $c->dispatcher->uri_for_action($action, $captures);
1172         if (not defined $path) {
1173             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1174                 if $c->debug;
1175             return undef;
1176         }
1177         $path = '/' if $path eq '';
1178     }
1179
1180     unshift(@args, $path);
1181
1182     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1183         my $namespace = $c->namespace;
1184         if (defined $path) { # cheesy hack to handle path '../foo'
1185            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1186         }
1187         unshift(@args, $namespace || '');
1188     }
1189
1190     # join args with '/', or a blank string
1191     my $args = join('/', grep { defined($_) } @args);
1192     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1193     $args =~ s!^/+!!;
1194     my $base = $c->req->base;
1195     my $class = ref($base);
1196     $base =~ s{(?<!/)$}{/};
1197
1198     my $query = '';
1199
1200     if (my @keys = keys %$params) {
1201       # somewhat lifted from URI::_query's query_form
1202       $query = '?'.join('&', map {
1203           my $val = $params->{$_};
1204           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1205           s/ /+/g;
1206           my $key = $_;
1207           $val = '' unless defined $val;
1208           (map {
1209               my $param = "$_";
1210               utf8::encode( $param ) if utf8::is_utf8($param);
1211               # using the URI::Escape pattern here so utf8 chars survive
1212               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1213               $param =~ s/ /+/g;
1214               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1215       } @keys);
1216     }
1217
1218     my $res = bless(\"${base}${args}${query}", $class);
1219     $res;
1220 }
1221
1222 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1223
1224 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1225
1226 =over
1227
1228 =item $path
1229
1230 A private path to the Catalyst action you want to create a URI for.
1231
1232 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1233 >> and passing the resulting C<$action> and the remaining arguments to C<<
1234 $c->uri_for >>.
1235
1236 You can also pass in a Catalyst::Action object, in which case it is passed to
1237 C<< $c->uri_for >>.
1238
1239 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1240
1241 For example, if the action looks like:
1242
1243  package MyApp::Controller::Users;
1244
1245  sub lst : Path('the-list') {}
1246
1247 You can use:
1248
1249  $c->uri_for_action('/users/lst')
1250
1251 and it will create the URI /users/the-list.
1252
1253 =back
1254
1255 =cut
1256
1257 sub uri_for_action {
1258     my ( $c, $path, @args ) = @_;
1259     my $action = blessed($path)
1260       ? $path
1261       : $c->dispatcher->get_action_by_path($path);
1262     unless (defined $action) {
1263       croak "Can't find action for path '$path'";
1264     }
1265     return $c->uri_for( $action, @args );
1266 }
1267
1268 =head2 $c->welcome_message
1269
1270 Returns the Catalyst welcome HTML page.
1271
1272 =cut
1273
1274 sub welcome_message {
1275     my $c      = shift;
1276     my $name   = $c->config->{name};
1277     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1278     my $prefix = Catalyst::Utils::appprefix( ref $c );
1279     $c->response->content_type('text/html; charset=utf-8');
1280     return <<"EOF";
1281 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1282     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1283 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1284     <head>
1285     <meta http-equiv="Content-Language" content="en" />
1286     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1287         <title>$name on Catalyst $VERSION</title>
1288         <style type="text/css">
1289             body {
1290                 color: #000;
1291                 background-color: #eee;
1292             }
1293             div#content {
1294                 width: 640px;
1295                 margin-left: auto;
1296                 margin-right: auto;
1297                 margin-top: 10px;
1298                 margin-bottom: 10px;
1299                 text-align: left;
1300                 background-color: #ccc;
1301                 border: 1px solid #aaa;
1302             }
1303             p, h1, h2 {
1304                 margin-left: 20px;
1305                 margin-right: 20px;
1306                 font-family: verdana, tahoma, sans-serif;
1307             }
1308             a {
1309                 font-family: verdana, tahoma, sans-serif;
1310             }
1311             :link, :visited {
1312                     text-decoration: none;
1313                     color: #b00;
1314                     border-bottom: 1px dotted #bbb;
1315             }
1316             :link:hover, :visited:hover {
1317                     color: #555;
1318             }
1319             div#topbar {
1320                 margin: 0px;
1321             }
1322             pre {
1323                 margin: 10px;
1324                 padding: 8px;
1325             }
1326             div#answers {
1327                 padding: 8px;
1328                 margin: 10px;
1329                 background-color: #fff;
1330                 border: 1px solid #aaa;
1331             }
1332             h1 {
1333                 font-size: 0.9em;
1334                 font-weight: normal;
1335                 text-align: center;
1336             }
1337             h2 {
1338                 font-size: 1.0em;
1339             }
1340             p {
1341                 font-size: 0.9em;
1342             }
1343             p img {
1344                 float: right;
1345                 margin-left: 10px;
1346             }
1347             span#appname {
1348                 font-weight: bold;
1349                 font-size: 1.6em;
1350             }
1351         </style>
1352     </head>
1353     <body>
1354         <div id="content">
1355             <div id="topbar">
1356                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1357                     $VERSION</h1>
1358              </div>
1359              <div id="answers">
1360                  <p>
1361                  <img src="$logo" alt="Catalyst Logo" />
1362                  </p>
1363                  <p>Welcome to the  world of Catalyst.
1364                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1365                     framework will make web development something you had
1366                     never expected it to be: Fun, rewarding, and quick.</p>
1367                  <h2>What to do now?</h2>
1368                  <p>That really depends  on what <b>you</b> want to do.
1369                     We do, however, provide you with a few starting points.</p>
1370                  <p>If you want to jump right into web development with Catalyst
1371                     you might want to start with a tutorial.</p>
1372 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1373 </pre>
1374 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1375 <pre>
1376 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1377 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1378 </code></pre>
1379                  <h2>What to do next?</h2>
1380                  <p>Next it's time to write an actual application. Use the
1381                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1382                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1383                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1384                     they can save you a lot of work.</p>
1385                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1386                     <p>Also, be sure to check out the vast and growing
1387                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1388                     you are likely to find what you need there.
1389                     </p>
1390
1391                  <h2>Need help?</h2>
1392                  <p>Catalyst has a very active community. Here are the main places to
1393                     get in touch with us.</p>
1394                  <ul>
1395                      <li>
1396                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1397                      </li>
1398                      <li>
1399                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1400                      </li>
1401                      <li>
1402                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1403                      </li>
1404                  </ul>
1405                  <h2>In conclusion</h2>
1406                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1407                     as we enjoyed making it. Please contact us if you have ideas
1408                     for improvement or other feedback.</p>
1409              </div>
1410          </div>
1411     </body>
1412 </html>
1413 EOF
1414 }
1415
1416 =head1 INTERNAL METHODS
1417
1418 These methods are not meant to be used by end users.
1419
1420 =head2 $c->components
1421
1422 Returns a hash of components.
1423
1424 =cut
1425
1426 sub components {
1427     my ( $class, $comps ) = @_;
1428
1429     # people create components calling this sub directly, before setup
1430     $class->setup_config unless $class->container;
1431
1432     my $container = $class->container;
1433
1434     if ( $comps ) {
1435         $container->add_component( $_ ) for keys %$comps;
1436     }
1437
1438     return $container->get_all_components();
1439 }
1440
1441 =head2 $c->context_class
1442
1443 Returns or sets the context class.
1444
1445 =head2 $c->counter
1446
1447 Returns a hashref containing coderefs and execution counts (needed for
1448 deep recursion detection).
1449
1450 =head2 $c->depth
1451
1452 Returns the number of actions on the current internal execution stack.
1453
1454 =head2 $c->dispatch
1455
1456 Dispatches a request to actions.
1457
1458 =cut
1459
1460 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1461
1462 =head2 $c->dispatcher_class
1463
1464 Returns or sets the dispatcher class.
1465
1466 =head2 $c->dump_these
1467
1468 Returns a list of 2-element array references (name, structure) pairs
1469 that will be dumped on the error page in debug mode.
1470
1471 =cut
1472
1473 sub dump_these {
1474     my $c = shift;
1475     [ Request => $c->req ],
1476     [ Response => $c->res ],
1477     [ Stash => $c->stash ],
1478     [ Config => $c->config ];
1479 }
1480
1481 =head2 $c->engine_class
1482
1483 Returns or sets the engine class.
1484
1485 =head2 $c->execute( $class, $coderef )
1486
1487 Execute a coderef in given class and catch exceptions. Errors are available
1488 via $c->error.
1489
1490 =cut
1491
1492 sub execute {
1493     my ( $c, $class, $code ) = @_;
1494     $class = $c->component($class) || $class;
1495     $c->state(0);
1496
1497     if ( $c->depth >= $RECURSION ) {
1498         my $action = $code->reverse();
1499         $action = "/$action" unless $action =~ /->/;
1500         my $error = qq/Deep recursion detected calling "${action}"/;
1501         $c->log->error($error);
1502         $c->error($error);
1503         $c->state(0);
1504         return $c->state;
1505     }
1506
1507     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1508
1509     push( @{ $c->stack }, $code );
1510
1511     no warnings 'recursion';
1512     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1513     #      I have no idea how, ergo $ret (which appears to fix the issue)
1514     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1515
1516     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1517
1518     my $last = pop( @{ $c->stack } );
1519
1520     if ( my $error = $@ ) {
1521         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1522             $error->rethrow if $c->depth > 1;
1523         }
1524         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1525             $error->rethrow if $c->depth > 0;
1526         }
1527         else {
1528             unless ( ref $error ) {
1529                 no warnings 'uninitialized';
1530                 chomp $error;
1531                 my $class = $last->class;
1532                 my $name  = $last->name;
1533                 $error = qq/Caught exception in $class->$name "$error"/;
1534             }
1535             $c->error($error);
1536         }
1537         $c->state(0);
1538     }
1539     return $c->state;
1540 }
1541
1542 sub _stats_start_execute {
1543     my ( $c, $code ) = @_;
1544     my $appclass = ref($c) || $c;
1545     return if ( ( $code->name =~ /^_.*/ )
1546         && ( !$appclass->config->{show_internal_actions} ) );
1547
1548     my $action_name = $code->reverse();
1549     $c->counter->{$action_name}++;
1550
1551     my $action = $action_name;
1552     $action = "/$action" unless $action =~ /->/;
1553
1554     # determine if the call was the result of a forward
1555     # this is done by walking up the call stack and looking for a calling
1556     # sub of Catalyst::forward before the eval
1557     my $callsub = q{};
1558     for my $index ( 2 .. 11 ) {
1559         last
1560         if ( ( caller($index) )[0] eq 'Catalyst'
1561             && ( caller($index) )[3] eq '(eval)' );
1562
1563         if ( ( caller($index) )[3] =~ /forward$/ ) {
1564             $callsub = ( caller($index) )[3];
1565             $action  = "-> $action";
1566             last;
1567         }
1568     }
1569
1570     my $uid = $action_name . $c->counter->{$action_name};
1571
1572     # is this a root-level call or a forwarded call?
1573     if ( $callsub =~ /forward$/ ) {
1574         my $parent = $c->stack->[-1];
1575
1576         # forward, locate the caller
1577         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1578             $c->stats->profile(
1579                 begin  => $action,
1580                 parent => "$parent" . $c->counter->{"$parent"},
1581                 uid    => $uid,
1582             );
1583         }
1584         else {
1585
1586             # forward with no caller may come from a plugin
1587             $c->stats->profile(
1588                 begin => $action,
1589                 uid   => $uid,
1590             );
1591         }
1592     }
1593     else {
1594
1595         # root-level call
1596         $c->stats->profile(
1597             begin => $action,
1598             uid   => $uid,
1599         );
1600     }
1601     return $action;
1602
1603 }
1604
1605 sub _stats_finish_execute {
1606     my ( $c, $info ) = @_;
1607     $c->stats->profile( end => $info );
1608 }
1609
1610 =head2 $c->finalize
1611
1612 Finalizes the request.
1613
1614 =cut
1615
1616 sub finalize {
1617     my $c = shift;
1618
1619     for my $error ( @{ $c->error } ) {
1620         $c->log->error($error);
1621     }
1622
1623     # Allow engine to handle finalize flow (for POE)
1624     my $engine = $c->engine;
1625     if ( my $code = $engine->can('finalize') ) {
1626         $engine->$code($c);
1627     }
1628     else {
1629
1630         $c->finalize_uploads;
1631
1632         # Error
1633         if ( $#{ $c->error } >= 0 ) {
1634             $c->finalize_error;
1635         }
1636
1637         $c->finalize_headers;
1638
1639         # HEAD request
1640         if ( $c->request->method eq 'HEAD' ) {
1641             $c->response->body('');
1642         }
1643
1644         $c->finalize_body;
1645     }
1646
1647     $c->finalize_ioc;
1648
1649     $c->log_response;
1650
1651     if ($c->use_stats) {
1652         my $elapsed = sprintf '%f', $c->stats->elapsed;
1653         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1654         $c->log->info(
1655             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1656     }
1657
1658     return $c->response->status;
1659 }
1660
1661 =head2 $c->finalize_body
1662
1663 Finalizes body.
1664
1665 =cut
1666
1667 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1668
1669 =head2 $c->finalize_cookies
1670
1671 Finalizes cookies.
1672
1673 =cut
1674
1675 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1676
1677 =head2 $c->finalize_error
1678
1679 Finalizes error.
1680
1681 =cut
1682
1683 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1684
1685 =head2 $c->finalize_headers
1686
1687 Finalizes headers.
1688
1689 =cut
1690
1691 sub finalize_headers {
1692     my $c = shift;
1693
1694     my $response = $c->response; #accessor calls can add up?
1695
1696     # Check if we already finalized headers
1697     return if $response->finalized_headers;
1698
1699     # Handle redirects
1700     if ( my $location = $response->redirect ) {
1701         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1702         $response->header( Location => $location );
1703
1704         if ( !$response->has_body ) {
1705             # Add a default body if none is already present
1706             $response->body(
1707                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1708             );
1709         }
1710     }
1711
1712     # Content-Length
1713     if ( defined $response->body && length $response->body && !$response->content_length ) {
1714
1715         # get the length from a filehandle
1716         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1717         {
1718             my $stat = stat $response->body;
1719             if ( $stat && $stat->size > 0 ) {
1720                 $response->content_length( $stat->size );
1721             }
1722             else {
1723                 $c->log->warn('Serving filehandle without a content-length');
1724             }
1725         }
1726         else {
1727             # everything should be bytes at this point, but just in case
1728             $response->content_length( length( $response->body ) );
1729         }
1730     }
1731
1732     # Errors
1733     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1734         $response->headers->remove_header("Content-Length");
1735         $response->body('');
1736     }
1737
1738     $c->finalize_cookies;
1739
1740     $c->engine->finalize_headers( $c, @_ );
1741
1742     # Done
1743     $response->finalized_headers(1);
1744 }
1745
1746 =head2 $c->finalize_output
1747
1748 An alias for finalize_body.
1749
1750 =head2 $c->finalize_read
1751
1752 Finalizes the input after reading is complete.
1753
1754 =cut
1755
1756 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1757
1758 =head2 $c->finalize_uploads
1759
1760 Finalizes uploads. Cleans up any temporary files.
1761
1762 =cut
1763
1764 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1765
1766 =head2 $c->finalize_ioc
1767
1768 Flushes all services with Request lifecycle.
1769
1770 =cut
1771
1772 sub finalize_ioc { shift->container->flush_request_services() }
1773
1774 =head2 $c->get_action( $action, $namespace )
1775
1776 Gets an action in a given namespace.
1777
1778 =cut
1779
1780 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1781
1782 =head2 $c->get_actions( $action, $namespace )
1783
1784 Gets all actions of a given name in a namespace and all parent
1785 namespaces.
1786
1787 =cut
1788
1789 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1790
1791 =head2 $app->handle_request( @arguments )
1792
1793 Called to handle each HTTP request.
1794
1795 =cut
1796
1797 sub handle_request {
1798     my ( $class, @arguments ) = @_;
1799
1800     # Always expect worst case!
1801     my $status = -1;
1802     eval {
1803         if ($class->debug) {
1804             my $secs = time - $START || 1;
1805             my $av = sprintf '%.3f', $COUNT / $secs;
1806             my $time = localtime time;
1807             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1808         }
1809
1810         my $c = $class->prepare(@arguments);
1811         $c->dispatch;
1812         $status = $c->finalize;
1813     };
1814
1815     if ( my $error = $@ ) {
1816         chomp $error;
1817         $class->log->error(qq/Caught exception in engine "$error"/);
1818     }
1819
1820     $COUNT++;
1821
1822     if(my $coderef = $class->log->can('_flush')){
1823         $class->log->$coderef();
1824     }
1825     return $status;
1826 }
1827
1828 =head2 $c->prepare( @arguments )
1829
1830 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1831 etc.).
1832
1833 =cut
1834
1835 sub prepare {
1836     my ( $class, @arguments ) = @_;
1837
1838     # XXX
1839     # After the app/ctxt split, this should become an attribute based on something passed
1840     # into the application.
1841     $class->context_class( ref $class || $class ) unless $class->context_class;
1842
1843     my $c = $class->context_class->new({});
1844
1845     # For on-demand data
1846     $c->request->_context($c);
1847     $c->response->_context($c);
1848
1849     #surely this is not the most efficient way to do things...
1850     $c->stats($class->stats_class->new)->enable($c->use_stats);
1851     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1852         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1853     }
1854
1855     #XXX reuse coderef from can
1856     # Allow engine to direct the prepare flow (for POE)
1857     if ( $c->engine->can('prepare') ) {
1858         $c->engine->prepare( $c, @arguments );
1859     }
1860     else {
1861         $c->prepare_request(@arguments);
1862         $c->prepare_connection;
1863         $c->prepare_query_parameters;
1864         $c->prepare_headers;
1865         $c->prepare_cookies;
1866         $c->prepare_path;
1867
1868         # Prepare the body for reading, either by prepare_body
1869         # or the user, if they are using $c->read
1870         $c->prepare_read;
1871
1872         # Parse the body unless the user wants it on-demand
1873         unless ( ref($c)->config->{parse_on_demand} ) {
1874             $c->prepare_body;
1875         }
1876     }
1877
1878     my $method  = $c->req->method  || '';
1879     my $path    = $c->req->path;
1880     $path       = '/' unless length $path;
1881     my $address = $c->req->address || '';
1882
1883     $c->log_request;
1884
1885     $c->prepare_action;
1886
1887     return $c;
1888 }
1889
1890 =head2 $c->prepare_action
1891
1892 Prepares action. See L<Catalyst::Dispatcher>.
1893
1894 =cut
1895
1896 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1897
1898 =head2 $c->prepare_body
1899
1900 Prepares message body.
1901
1902 =cut
1903
1904 sub prepare_body {
1905     my $c = shift;
1906
1907     return if $c->request->_has_body;
1908
1909     # Initialize on-demand data
1910     $c->engine->prepare_body( $c, @_ );
1911     $c->prepare_parameters;
1912     $c->prepare_uploads;
1913 }
1914
1915 =head2 $c->prepare_body_chunk( $chunk )
1916
1917 Prepares a chunk of data before sending it to L<HTTP::Body>.
1918
1919 See L<Catalyst::Engine>.
1920
1921 =cut
1922
1923 sub prepare_body_chunk {
1924     my $c = shift;
1925     $c->engine->prepare_body_chunk( $c, @_ );
1926 }
1927
1928 =head2 $c->prepare_body_parameters
1929
1930 Prepares body parameters.
1931
1932 =cut
1933
1934 sub prepare_body_parameters {
1935     my $c = shift;
1936     $c->engine->prepare_body_parameters( $c, @_ );
1937 }
1938
1939 =head2 $c->prepare_connection
1940
1941 Prepares connection.
1942
1943 =cut
1944
1945 sub prepare_connection {
1946     my $c = shift;
1947     $c->engine->prepare_connection( $c, @_ );
1948 }
1949
1950 =head2 $c->prepare_cookies
1951
1952 Prepares cookies.
1953
1954 =cut
1955
1956 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1957
1958 =head2 $c->prepare_headers
1959
1960 Prepares headers.
1961
1962 =cut
1963
1964 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1965
1966 =head2 $c->prepare_parameters
1967
1968 Prepares parameters.
1969
1970 =cut
1971
1972 sub prepare_parameters {
1973     my $c = shift;
1974     $c->prepare_body_parameters;
1975     $c->engine->prepare_parameters( $c, @_ );
1976 }
1977
1978 =head2 $c->prepare_path
1979
1980 Prepares path and base.
1981
1982 =cut
1983
1984 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1985
1986 =head2 $c->prepare_query_parameters
1987
1988 Prepares query parameters.
1989
1990 =cut
1991
1992 sub prepare_query_parameters {
1993     my $c = shift;
1994
1995     $c->engine->prepare_query_parameters( $c, @_ );
1996 }
1997
1998 =head2 $c->log_request
1999
2000 Writes information about the request to the debug logs.  This includes:
2001
2002 =over 4
2003
2004 =item * Request method, path, and remote IP address
2005
2006 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2007
2008 =item * Request parameters
2009
2010 =item * File uploads
2011
2012 =back
2013
2014 =cut
2015
2016 sub log_request {
2017     my $c = shift;
2018
2019     return unless $c->debug;
2020
2021     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2022     my $request = $dump->[1];
2023
2024     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2025     $method ||= '';
2026     $path = '/' unless length $path;
2027     $address ||= '';
2028     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2029
2030     $c->log_request_headers($request->headers);
2031
2032     if ( my $keywords = $request->query_keywords ) {
2033         $c->log->debug("Query keywords are: $keywords");
2034     }
2035
2036     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2037
2038     $c->log_request_uploads($request);
2039 }
2040
2041 =head2 $c->log_response
2042
2043 Writes information about the response to the debug logs by calling
2044 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2045
2046 =cut
2047
2048 sub log_response {
2049     my $c = shift;
2050
2051     return unless $c->debug;
2052
2053     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2054     my $response = $dump->[1];
2055
2056     $c->log_response_status_line($response);
2057     $c->log_response_headers($response->headers);
2058 }
2059
2060 =head2 $c->log_response_status_line($response)
2061
2062 Writes one line of information about the response to the debug logs.  This includes:
2063
2064 =over 4
2065
2066 =item * Response status code
2067
2068 =item * Content-Type header (if present)
2069
2070 =item * Content-Length header (if present)
2071
2072 =back
2073
2074 =cut
2075
2076 sub log_response_status_line {
2077     my ($c, $response) = @_;
2078
2079     $c->log->debug(
2080         sprintf(
2081             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2082             $response->status                            || 'unknown',
2083             $response->headers->header('Content-Type')   || 'unknown',
2084             $response->headers->header('Content-Length') || 'unknown'
2085         )
2086     );
2087 }
2088
2089 =head2 $c->log_response_headers($headers);
2090
2091 Hook method which can be wrapped by plugins to log the responseheaders.
2092 No-op in the default implementation.
2093
2094 =cut
2095
2096 sub log_response_headers {}
2097
2098 =head2 $c->log_request_parameters( query => {}, body => {} )
2099
2100 Logs request parameters to debug logs
2101
2102 =cut
2103
2104 sub log_request_parameters {
2105     my $c          = shift;
2106     my %all_params = @_;
2107
2108     return unless $c->debug;
2109
2110     my $column_width = Catalyst::Utils::term_width() - 44;
2111     foreach my $type (qw(query body)) {
2112         my $params = $all_params{$type};
2113         next if ! keys %$params;
2114         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2115         for my $key ( sort keys %$params ) {
2116             my $param = $params->{$key};
2117             my $value = defined($param) ? $param : '';
2118             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2119         }
2120         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2121     }
2122 }
2123
2124 =head2 $c->log_request_uploads
2125
2126 Logs file uploads included in the request to the debug logs.
2127 The parameter name, filename, file type, and file size are all included in
2128 the debug logs.
2129
2130 =cut
2131
2132 sub log_request_uploads {
2133     my $c = shift;
2134     my $request = shift;
2135     return unless $c->debug;
2136     my $uploads = $request->uploads;
2137     if ( keys %$uploads ) {
2138         my $t = Text::SimpleTable->new(
2139             [ 12, 'Parameter' ],
2140             [ 26, 'Filename' ],
2141             [ 18, 'Type' ],
2142             [ 9,  'Size' ]
2143         );
2144         for my $key ( sort keys %$uploads ) {
2145             my $upload = $uploads->{$key};
2146             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2147                 $t->row( $key, $u->filename, $u->type, $u->size );
2148             }
2149         }
2150         $c->log->debug( "File Uploads are:\n" . $t->draw );
2151     }
2152 }
2153
2154 =head2 $c->log_request_headers($headers);
2155
2156 Hook method which can be wrapped by plugins to log the request headers.
2157 No-op in the default implementation.
2158
2159 =cut
2160
2161 sub log_request_headers {}
2162
2163 =head2 $c->log_headers($type => $headers)
2164
2165 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2166
2167 =cut
2168
2169 sub log_headers {
2170     my $c       = shift;
2171     my $type    = shift;
2172     my $headers = shift;    # an HTTP::Headers instance
2173
2174     return unless $c->debug;
2175
2176     my $column_width = Catalyst::Utils::term_width() - 28;
2177     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2178     $headers->scan(
2179         sub {
2180             my ( $name, $value ) = @_;
2181             $t->row( $name, $value );
2182         }
2183     );
2184     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2185 }
2186
2187
2188 =head2 $c->prepare_read
2189
2190 Prepares the input for reading.
2191
2192 =cut
2193
2194 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2195
2196 =head2 $c->prepare_request
2197
2198 Prepares the engine request.
2199
2200 =cut
2201
2202 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2203
2204 =head2 $c->prepare_uploads
2205
2206 Prepares uploads.
2207
2208 =cut
2209
2210 sub prepare_uploads {
2211     my $c = shift;
2212
2213     $c->engine->prepare_uploads( $c, @_ );
2214 }
2215
2216 =head2 $c->prepare_write
2217
2218 Prepares the output for writing.
2219
2220 =cut
2221
2222 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2223
2224 =head2 $c->request_class
2225
2226 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2227
2228 =head2 $c->response_class
2229
2230 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2231
2232 =head2 $c->read( [$maxlength] )
2233
2234 Reads a chunk of data from the request body. This method is designed to
2235 be used in a while loop, reading C<$maxlength> bytes on every call.
2236 C<$maxlength> defaults to the size of the request if not specified.
2237
2238 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2239 directly.
2240
2241 Warning: If you use read(), Catalyst will not process the body,
2242 so you will not be able to access POST parameters or file uploads via
2243 $c->request.  You must handle all body parsing yourself.
2244
2245 =cut
2246
2247 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2248
2249 =head2 $c->run
2250
2251 Starts the engine.
2252
2253 =cut
2254
2255 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2256
2257 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2258
2259 Sets an action in a given namespace.
2260
2261 =cut
2262
2263 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2264
2265 =head2 $c->setup_actions($component)
2266
2267 Sets up actions for a component.
2268
2269 =cut
2270
2271 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2272
2273 =head2 $c->setup_config
2274
2275 =cut
2276
2277 sub setup_config {
2278     my $class = shift;
2279
2280     my %args = %{ $class->config || {} };
2281
2282     my @container_classes = ( "${class}::Container", 'Catalyst::IOC::Container');
2283     unshift @container_classes, delete $args{container_class} if exists $args{container_class};
2284
2285     my $container_class = Class::MOP::load_first_existing_class(@container_classes);
2286
2287     my $container = $container_class->new( %args, application_name => "$class", name => "$class" );
2288     $class->container($container);
2289
2290     my $config = $container->resolve( service => 'config' );
2291     $class->config($config);
2292     $class->finalize_config; # back-compat
2293 }
2294
2295 =head2 $c->finalize_config
2296
2297 =cut
2298
2299 sub finalize_config { }
2300
2301 =head2 $c->setup_components
2302
2303 This method is called internally to set up the application's components.
2304
2305 It finds modules by calling the L<locate_components> method, expands them to
2306 package names with the $container->expand_component_module method, and then
2307 installs each component into the application.
2308
2309 The C<setup_components> config option is passed to both of the above methods.
2310
2311 =cut
2312
2313 sub setup_components {
2314     shift->container->setup_components();
2315 }
2316
2317 =head2 locate_components
2318
2319 =cut
2320
2321 # FIXME - removed locate_components
2322 # don't people mess with this method directly?
2323 # what to do with that?
2324
2325 sub locate_components {
2326     my $class = shift;
2327
2328     $class->log->warn('The locate_components method has been deprecated.');
2329     $class->log->warn('Please read Catalyst::IOC::Container documentation to');
2330     $class->log->warn('update your application.');
2331
2332     # XXX think about ditching this sort entirely
2333     return sort { length $a <=> length $b }
2334         @{ $class->container->resolve( service => 'locate_components' ) };
2335 }
2336
2337
2338 =head2 $c->setup_dispatcher
2339
2340 Sets up dispatcher.
2341
2342 =cut
2343
2344 sub setup_dispatcher {
2345     my ( $class, $dispatcher ) = @_;
2346
2347     if ($dispatcher) {
2348         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2349     }
2350
2351     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2352         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2353     }
2354
2355     unless ($dispatcher) {
2356         $dispatcher = $class->dispatcher_class;
2357     }
2358
2359     Class::MOP::load_class($dispatcher);
2360
2361     # dispatcher instance
2362     $class->dispatcher( $dispatcher->new );
2363 }
2364
2365 =head2 $c->setup_engine
2366
2367 Sets up engine.
2368
2369 =cut
2370
2371 sub setup_engine {
2372     my ( $class, $engine ) = @_;
2373
2374     if ($engine) {
2375         $engine = 'Catalyst::Engine::' . $engine;
2376     }
2377
2378     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2379         $engine = 'Catalyst::Engine::' . $env;
2380     }
2381
2382     if ( $ENV{MOD_PERL} ) {
2383         my $meta = Class::MOP::get_metaclass_by_name($class);
2384
2385         # create the apache method
2386         $meta->add_method('apache' => sub { shift->engine->apache });
2387
2388         my ( $software, $version ) =
2389           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2390
2391         $version =~ s/_//g;
2392         $version =~ s/(\.[^.]+)\./$1/g;
2393
2394         if ( $software eq 'mod_perl' ) {
2395
2396             if ( !$engine ) {
2397
2398                 if ( $version >= 1.99922 ) {
2399                     $engine = 'Catalyst::Engine::Apache2::MP20';
2400                 }
2401
2402                 elsif ( $version >= 1.9901 ) {
2403                     $engine = 'Catalyst::Engine::Apache2::MP19';
2404                 }
2405
2406                 elsif ( $version >= 1.24 ) {
2407                     $engine = 'Catalyst::Engine::Apache::MP13';
2408                 }
2409
2410                 else {
2411                     Catalyst::Exception->throw( message =>
2412                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2413                 }
2414
2415             }
2416
2417             # install the correct mod_perl handler
2418             if ( $version >= 1.9901 ) {
2419                 *handler = sub  : method {
2420                     shift->handle_request(@_);
2421                 };
2422             }
2423             else {
2424                 *handler = sub ($$) { shift->handle_request(@_) };
2425             }
2426
2427         }
2428
2429         elsif ( $software eq 'Zeus-Perl' ) {
2430             $engine = 'Catalyst::Engine::Zeus';
2431         }
2432
2433         else {
2434             Catalyst::Exception->throw(
2435                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2436         }
2437     }
2438
2439     unless ($engine) {
2440         $engine = $class->engine_class;
2441     }
2442
2443     Class::MOP::load_class($engine);
2444
2445     # check for old engines that are no longer compatible
2446     my $old_engine;
2447     if ( $engine->isa('Catalyst::Engine::Apache')
2448         && !Catalyst::Engine::Apache->VERSION )
2449     {
2450         $old_engine = 1;
2451     }
2452
2453     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2454         && Catalyst::Engine::Server->VERSION le '0.02' )
2455     {
2456         $old_engine = 1;
2457     }
2458
2459     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2460         && $engine->VERSION eq '0.01' )
2461     {
2462         $old_engine = 1;
2463     }
2464
2465     elsif ($engine->isa('Catalyst::Engine::Zeus')
2466         && $engine->VERSION eq '0.01' )
2467     {
2468         $old_engine = 1;
2469     }
2470
2471     if ($old_engine) {
2472         Catalyst::Exception->throw( message =>
2473               qq/Engine "$engine" is not supported by this version of Catalyst/
2474         );
2475     }
2476
2477     # engine instance
2478     $class->engine( $engine->new );
2479 }
2480
2481 =head2 $c->setup_home
2482
2483 Sets up the home directory.
2484
2485 =cut
2486
2487 sub setup_home {
2488     my ( $class, $home ) = @_;
2489
2490     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2491         $home = $env;
2492     }
2493
2494     $home ||= Catalyst::Utils::home($class);
2495
2496     if ($home) {
2497         #I remember recently being scolded for assigning config values like this
2498         $class->config->{home} ||= $home;
2499         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2500     }
2501 }
2502
2503 =head2 $c->setup_log
2504
2505 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2506 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2507 log to.
2508
2509 This method also installs a C<debug> method that returns a true value into the
2510 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2511 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2512
2513 Note that if the log has already been setup, by either a previous call to
2514 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2515 that this method won't actually set up the log object.
2516
2517 =cut
2518
2519 sub setup_log {
2520     my ( $class, $levels ) = @_;
2521
2522     $levels ||= '';
2523     $levels =~ s/^\s+//;
2524     $levels =~ s/\s+$//;
2525     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2526
2527     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2528     if ( defined $env_debug ) {
2529         $levels{debug} = 1 if $env_debug; # Ugly!
2530         delete($levels{debug}) unless $env_debug;
2531     }
2532
2533     unless ( $class->log ) {
2534         $class->log( Catalyst::Log->new(keys %levels) );
2535     }
2536
2537     if ( $levels{debug} ) {
2538         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2539         $class->log->debug('Debug messages enabled');
2540     }
2541 }
2542
2543 =head2 $c->setup_plugins
2544
2545 Sets up plugins.
2546
2547 =cut
2548
2549 =head2 $c->setup_stats
2550
2551 Sets up timing statistics class.
2552
2553 =cut
2554
2555 sub setup_stats {
2556     my ( $class, $stats ) = @_;
2557
2558     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2559
2560     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2561     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2562         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2563         $class->log->debug('Statistics enabled');
2564     }
2565 }
2566
2567
2568 =head2 $c->registered_plugins
2569
2570 Returns a sorted list of the plugins which have either been stated in the
2571 import list or which have been added via C<< MyApp->plugin(@args); >>.
2572
2573 If passed a given plugin name, it will report a boolean value indicating
2574 whether or not that plugin is loaded.  A fully qualified name is required if
2575 the plugin name does not begin with C<Catalyst::Plugin::>.
2576
2577  if ($c->registered_plugins('Some::Plugin')) {
2578      ...
2579  }
2580
2581 =cut
2582
2583 {
2584
2585     sub registered_plugins {
2586         my $proto = shift;
2587         return sort keys %{ $proto->_plugins } unless @_;
2588         my $plugin = shift;
2589         return 1 if exists $proto->_plugins->{$plugin};
2590         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2591     }
2592
2593     sub _register_plugin {
2594         my ( $proto, $plugin, $instant ) = @_;
2595         my $class = ref $proto || $proto;
2596
2597         Class::MOP::load_class( $plugin );
2598         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2599             if $plugin->isa( 'Catalyst::Component' );
2600         $proto->_plugins->{$plugin} = 1;
2601         unless ($instant) {
2602             my $meta = Class::MOP::get_metaclass_by_name($class);
2603             $meta->superclasses($plugin, $meta->superclasses);
2604         }
2605         return $class;
2606     }
2607
2608     sub setup_plugins {
2609         my ( $class, $plugins ) = @_;
2610
2611         $class->_plugins( {} ) unless $class->_plugins;
2612         $plugins = Data::OptList::mkopt($plugins || []);
2613
2614         my @plugins = map {
2615             [ Catalyst::Utils::resolve_namespace(
2616                   $class . '::Plugin',
2617                   'Catalyst::Plugin', $_->[0]
2618               ),
2619               $_->[1],
2620             ]
2621          } @{ $plugins };
2622
2623         for my $plugin ( reverse @plugins ) {
2624             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2625             my $meta = find_meta($plugin->[0]);
2626             next if $meta && $meta->isa('Moose::Meta::Role');
2627
2628             $class->_register_plugin($plugin->[0]);
2629         }
2630
2631         my @roles =
2632             map  { $_->[0]->name, $_->[1] }
2633             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2634             map  { [find_meta($_->[0]), $_->[1]] }
2635             @plugins;
2636
2637         Moose::Util::apply_all_roles(
2638             $class => @roles
2639         ) if @roles;
2640     }
2641 }
2642
2643 =head2 $c->stack
2644
2645 Returns an arrayref of the internal execution stack (actions that are
2646 currently executing).
2647
2648 =head2 $c->stats
2649
2650 Returns the current timing statistics object. By default Catalyst uses
2651 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2652 L<< stats_class|/"$c->stats_class" >>.
2653
2654 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2655 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2656 profile explicitly, although MyApp.pm still won't profile nor output anything
2657 by itself.
2658
2659 =head2 $c->stats_class
2660
2661 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2662
2663 =head2 $c->use_stats
2664
2665 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2666
2667 Note that this is a static method, not an accessor and should be overridden
2668 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2669
2670 =cut
2671
2672 sub use_stats { 0 }
2673
2674
2675 =head2 $c->write( $data )
2676
2677 Writes $data to the output stream. When using this method directly, you
2678 will need to manually set the C<Content-Length> header to the length of
2679 your output data, if known.
2680
2681 =cut
2682
2683 sub write {
2684     my $c = shift;
2685
2686     # Finalize headers if someone manually writes output
2687     $c->finalize_headers;
2688
2689     return $c->engine->write( $c, @_ );
2690 }
2691
2692 =head2 version
2693
2694 Returns the Catalyst version number. Mostly useful for "powered by"
2695 messages in template systems.
2696
2697 =cut
2698
2699 sub version { return $Catalyst::VERSION }
2700
2701 =head1 CONFIGURATION
2702
2703 There are a number of 'base' config variables which can be set:
2704
2705 =over
2706
2707 =item *
2708
2709 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2710
2711 =item *
2712
2713 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2714
2715 =item *
2716
2717 C<home> - The application home directory. In an uninstalled application,
2718 this is the top level application directory. In an installed application,
2719 this will be the directory containing C<< MyApp.pm >>.
2720
2721 =item *
2722
2723 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2724
2725 =item *
2726
2727 C<name> - The name of the application in debug messages and the debug and
2728 welcome screens
2729
2730 =item *
2731
2732 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2733 until it is accessed. This allows you to (for example) check authentication (and reject
2734 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2735
2736 =item *
2737
2738 C<root> - The root directory for templates. Usually this is just a
2739 subdirectory of the home directory, but you can set it to change the
2740 templates to a different directory.
2741
2742 =item *
2743
2744 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2745 to be shown in hit debug tables in the test server.
2746
2747 =item *
2748
2749 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
2750 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
2751 for more information.
2752
2753 =item *
2754
2755 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2756
2757 =back
2758
2759 =head1 INTERNAL ACTIONS
2760
2761 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2762 C<_ACTION>, and C<_END>. These are by default not shown in the private
2763 action table, but you can make them visible with a config parameter.
2764
2765     MyApp->config(show_internal_actions => 1);
2766
2767 =head1 ON-DEMAND PARSER
2768
2769 The request body is usually parsed at the beginning of a request,
2770 but if you want to handle input yourself, you can enable on-demand
2771 parsing with a config parameter.
2772
2773     MyApp->config(parse_on_demand => 1);
2774
2775 =head1 PROXY SUPPORT
2776
2777 Many production servers operate using the common double-server approach,
2778 with a lightweight frontend web server passing requests to a larger
2779 backend server. An application running on the backend server must deal
2780 with two problems: the remote user always appears to be C<127.0.0.1> and
2781 the server's hostname will appear to be C<localhost> regardless of the
2782 virtual host that the user connected through.
2783
2784 Catalyst will automatically detect this situation when you are running
2785 the frontend and backend servers on the same machine. The following
2786 changes are made to the request.
2787
2788     $c->req->address is set to the user's real IP address, as read from
2789     the HTTP X-Forwarded-For header.
2790
2791     The host value for $c->req->base and $c->req->uri is set to the real
2792     host, as read from the HTTP X-Forwarded-Host header.
2793
2794 Additionally, you may be running your backend application on an insecure
2795 connection (port 80) while your frontend proxy is running under SSL.  If there
2796 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2797 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2798 be created properly.
2799
2800 In the case of passing in:
2801
2802     X-Forwarded-Port: 443
2803
2804 All calls to C<uri_for> will result in an https link, as is expected.
2805
2806 Obviously, your web server must support these headers for this to work.
2807
2808 In a more complex server farm environment where you may have your
2809 frontend proxy server(s) on different machines, you will need to set a
2810 configuration option to tell Catalyst to read the proxied data from the
2811 headers.
2812
2813     MyApp->config(using_frontend_proxy => 1);
2814
2815 If you do not wish to use the proxy support at all, you may set:
2816
2817     MyApp->config(ignore_frontend_proxy => 1);
2818
2819 =head1 THREAD SAFETY
2820
2821 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2822 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2823 believe the Catalyst core to be thread-safe.
2824
2825 If you plan to operate in a threaded environment, remember that all other
2826 modules you are using must also be thread-safe. Some modules, most notably
2827 L<DBD::SQLite>, are not thread-safe.
2828
2829 =head1 SUPPORT
2830
2831 IRC:
2832
2833     Join #catalyst on irc.perl.org.
2834
2835 Mailing Lists:
2836
2837     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2838     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2839
2840 Web:
2841
2842     http://catalyst.perl.org
2843
2844 Wiki:
2845
2846     http://dev.catalyst.perl.org
2847
2848 =head1 SEE ALSO
2849
2850 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2851
2852 =head2 L<Catalyst::Manual> - The Catalyst Manual
2853
2854 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2855
2856 =head2 L<Catalyst::Engine> - Core engine
2857
2858 =head2 L<Catalyst::Log> - Log class.
2859
2860 =head2 L<Catalyst::Request> - Request object
2861
2862 =head2 L<Catalyst::Response> - Response object
2863
2864 =head2 L<Catalyst::Test> - The test suite.
2865
2866 =head1 PROJECT FOUNDER
2867
2868 sri: Sebastian Riedel <sri@cpan.org>
2869
2870 =head1 CONTRIBUTORS
2871
2872 abw: Andy Wardley
2873
2874 acme: Leon Brocard <leon@astray.com>
2875
2876 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
2877
2878 Andrew Bramble
2879
2880 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
2881
2882 Andrew Ruthven
2883
2884 André Walker
2885
2886 andyg: Andy Grundman <andy@hybridized.org>
2887
2888 audreyt: Audrey Tang
2889
2890 bricas: Brian Cassidy <bricas@cpan.org>
2891
2892 Caelum: Rafael Kitover <rkitover@io.com>
2893
2894 chansen: Christian Hansen
2895
2896 chicks: Christopher Hicks
2897
2898 Chisel Wright C<pause@herlpacker.co.uk>
2899
2900 Danijel Milicevic C<me@danijel.de>
2901
2902 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
2903
2904 David Naughton, C<naughton@umn.edu>
2905
2906 David E. Wheeler
2907
2908 dhoss: Devin Austin <dhoss@cpan.org>
2909
2910 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2911
2912 Drew Taylor
2913
2914 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2915
2916 esskar: Sascha Kiefer
2917
2918 fireartist: Carl Franks <cfranks@cpan.org>
2919
2920 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
2921
2922 gabb: Danijel Milicevic
2923
2924 Gary Ashton Jones
2925
2926 Gavin Henry C<ghenry@perl.me.uk>
2927
2928 Geoff Richards
2929
2930 groditi: Guillermo Roditi <groditi@gmail.com>
2931
2932 hobbs: Andrew Rodland <andrew@cleverdomain.org>
2933
2934 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2935
2936 jcamacho: Juan Camacho
2937
2938 jester: Jesse Sheidlower C<jester@panix.com>
2939
2940 jhannah: Jay Hannah <jay@jays.net>
2941
2942 Jody Belka
2943
2944 Johan Lindstrom
2945
2946 jon: Jon Schutz <jjschutz@cpan.org>
2947
2948 Jonathan Rockway C<< <jrockway@cpan.org> >>
2949
2950 Kieren Diment C<kd@totaldatasolution.com>
2951
2952 konobi: Scott McWhirter <konobi@cpan.org>
2953
2954 marcus: Marcus Ramberg <mramberg@cpan.org>
2955
2956 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2957
2958 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2959
2960 mugwump: Sam Vilain
2961
2962 naughton: David Naughton
2963
2964 ningu: David Kamholz <dkamholz@cpan.org>
2965
2966 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2967
2968 numa: Dan Sully <daniel@cpan.org>
2969
2970 obra: Jesse Vincent
2971
2972 Octavian Rasnita
2973
2974 omega: Andreas Marienborg
2975
2976 Oleg Kostyuk <cub.uanic@gmail.com>
2977
2978 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2979
2980 rafl: Florian Ragwitz <rafl@debian.org>
2981
2982 random: Roland Lammel <lammel@cpan.org>
2983
2984 Robert Sedlacek C<< <rs@474.at> >>
2985
2986 SpiceMan: Marcel Montes
2987
2988 sky: Arthur Bergman
2989
2990 szbalint: Balint Szilakszi <szbalint@cpan.org>
2991
2992 t0m: Tomas Doran <bobtfish@bobtfish.net>
2993
2994 Ulf Edvinsson
2995
2996 Viljo Marrandi C<vilts@yahoo.com>
2997
2998 Will Hawes C<info@whawes.co.uk>
2999
3000 willert: Sebastian Willert <willert@cpan.org>
3001
3002 wreis: Wallace Reis <wallace@reis.org.br>
3003
3004 Yuval Kogman, C<nothingmuch@woobling.org>
3005
3006 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3007
3008 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3009
3010 =head1 COPYRIGHT
3011
3012 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3013
3014 =head1 LICENSE
3015
3016 This library is free software. You can redistribute it and/or modify it under
3017 the same terms as Perl itself.
3018
3019 =cut
3020
3021 no Moose;
3022
3023 __PACKAGE__->meta->make_immutable;
3024
3025 1;