lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54
  55 BEGIN { require 5.008003; }
  56
  57 has stack => (is => 'ro', default => sub { [] });
  58 has state => (is => 'rw', default => 0);
  59 has stats => (is => 'rw');
  60 has action => (is => 'rw');
  61 has counter => (is => 'rw', default => sub { {} });
  62 has request => (
  63     is => 'rw',
  64     default => sub {
  65         my $self = shift;
  66         my $class = ref $self;
  67         my $composed_request_class = $class->composed_request_class;
  68         return $composed_request_class->new( $self->_build_request_constructor_args);
  69     },
  70     lazy => 1,
  71 );
  72 sub _build_request_constructor_args {
  73     my $self = shift;
  74     my %p = ( _log => $self->log );
  75     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  76     $p{data_handlers} = {$self->registered_data_handlers};
  77     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  78       if $self->config->{use_hash_multivalue_in_request};
  79     \%p;
  80 }
  81
  82 sub composed_request_class {
  83   my $class = shift;
  84   my @traits = (@{$class->request_class_traits||[]}, @{$class->config->{request_class_traits}||[]});
  85
  86   # For each trait listed, figure out what the namespace is.  First we try the $trait
  87   # as it is in the config.  Then try $MyApp::TraitFor::Request:$trait. Last we try
  88   # Catalyst::TraitFor::Request::$trait.  If none load, throw error.
  89
  90   my $trait_ns = 'TraitFor::Request';
  91   my @normalized_traits = map {
  92     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
  93   } @traits;
  94
  95   return $class->_composed_request_class ||
  96     $class->_composed_request_class(Moose::Util::with_traits($class->request_class, @normalized_traits));
  97 }
  98
  99 has response => (
 100     is => 'rw',
 101     default => sub {
 102         my $self = shift;
 103         my $class = ref $self;
 104         my $composed_response_class = $class->composed_response_class;
 105         return $composed_response_class->new( $self->_build_response_constructor_args);
 106     },
 107     lazy => 1,
 108 );
 109 sub _build_response_constructor_args {
 110     return +{
 111       _log => $_[0]->log,
 112       encoding => $_[0]->encoding,
 113     };
 114 }
 115
 116 sub composed_response_class {
 117   my $class = shift;
 118   my @traits = (@{$class->response_class_traits||[]}, @{$class->config->{response_class_traits}||[]});
 119
 120   my $trait_ns = 'TraitFor::Response';
 121   my @normalized_traits = map {
 122     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
 123   } @traits;
 124
 125   return $class->_composed_response_class ||
 126     $class->_composed_response_class(Moose::Util::with_traits($class->response_class, @normalized_traits));
 127 }
 128
 129 has namespace => (is => 'rw');
 130
 131 sub depth { scalar @{ shift->stack || [] }; }
 132 sub comp { shift->component(@_) }
 133
 134 sub req {
 135     my $self = shift; return $self->request(@_);
 136 }
 137 sub res {
 138     my $self = shift; return $self->response(@_);
 139 }
 140
 141 # For backwards compatibility
 142 sub finalize_output { shift->finalize_body(@_) };
 143
 144 # For statistics
 145 our $COUNT     = 1;
 146 our $START     = time;
 147 our $RECURSION = 1000;
 148 our $DETACH    = Catalyst::Exception::Detach->new;
 149 our $GO        = Catalyst::Exception::Go->new;
 150
 151 #I imagine that very few of these really
 152 #need to be class variables. if any.
 153 #maybe we should just make them attributes with a default?
 154 __PACKAGE__->mk_classdata($_)
 155   for qw/components arguments dispatcher engine log dispatcher_class
 156   engine_loader context_class request_class response_class stats_class
 157   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 158   _data_handlers _encoding _encode_check finalized_default_middleware
 159   request_class_traits response_class_traits stats_class_traits
 160   _composed_request_class _composed_response_class _composed_stats_class/;
 161
 162 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 163 __PACKAGE__->request_class('Catalyst::Request');
 164 __PACKAGE__->response_class('Catalyst::Response');
 165 __PACKAGE__->stats_class('Catalyst::Stats');
 166
 167 sub composed_stats_class {
 168   my $class = shift;
 169   my @traits = (@{$class->stats_class_traits||[]}, @{$class->config->{stats_class_traits}||[]});
 170
 171   my $trait_ns = 'TraitFor::Stats';
 172   my @normalized_traits = map {
 173     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
 174   } @traits;
 175
 176   return $class->_composed_stats_class ||
 177     $class->_composed_stats_class(Moose::Util::with_traits($class->stats_class, @normalized_traits));
 178 }
 179
 180 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 181
 182 # Remember to update this in Catalyst::Runtime as well!
 183 our $VERSION = '5.90095';
 184 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 185
 186 sub import {
 187     my ( $class, @arguments ) = @_;
 188
 189     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 190     # callers @ISA.
 191     return unless $class eq 'Catalyst';
 192
 193     my $caller = caller();
 194     return if $caller eq 'main';
 195
 196     my $meta = Moose::Meta::Class->initialize($caller);
 197     unless ( $caller->isa('Catalyst') ) {
 198         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 199         $meta->superclasses(@superclasses);
 200     }
 201     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 202     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 203
 204     unless( $meta->has_method('meta') ){
 205         if ($Moose::VERSION >= 1.15) {
 206             $meta->_add_meta_method('meta');
 207         }
 208         else {
 209             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 210         }
 211     }
 212
 213     $caller->arguments( [@arguments] );
 214     $caller->setup_home;
 215 }
 216
 217 sub _application { $_[0] }
 218
 219 =encoding UTF-8
 220
 221 =head1 NAME
 222
 223 Catalyst - The Elegant MVC Web Application Framework
 224
 225 =for html
 226 <a href="https://badge.fury.io/pl/Catalyst-Runtime"><img src="https://badge.fury.io/pl/Catalyst-Runtime.svg" alt="CPAN version" height="18"></a>
 227 <a href="https://travis-ci.org/perl-catalyst/catalyst-runtime/"><img src="https://api.travis-ci.org/perl-catalyst/catalyst-runtime.png" alt="Catalyst></a>
 228 <a href="http://cpants.cpanauthors.org/dist/Catalyst-Runtime"><img src="http://cpants.cpanauthors.org/dist/Catalyst-Runtime.png" alt='Kwalitee Score' /></a>
 229
 230 =head1 SYNOPSIS
 231
 232 See the L<Catalyst::Manual> distribution for comprehensive
 233 documentation and tutorials.
 234
 235     # Install Catalyst::Devel for helpers and other development tools
 236     # use the helper to create a new application
 237     catalyst.pl MyApp
 238
 239     # add models, views, controllers
 240     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 241     script/myapp_create.pl view MyTemplate TT
 242     script/myapp_create.pl controller Search
 243
 244     # built in testserver -- use -r to restart automatically on changes
 245     # --help to see all available options
 246     script/myapp_server.pl
 247
 248     # command line testing interface
 249     script/myapp_test.pl /yada
 250
 251     ### in lib/MyApp.pm
 252     use Catalyst qw/-Debug/; # include plugins here as well
 253
 254     ### In lib/MyApp/Controller/Root.pm (autocreated)
 255     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 256         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 257         $c->stash->{template} = 'foo.tt'; # set the template
 258         # lookup something from db -- stash vars are passed to TT
 259         $c->stash->{data} =
 260           $c->model('Database::Foo')->search( { country => $args[0] } );
 261         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 262             $c->forward( 'bar' ); # process another action
 263             # do something else after forward returns
 264         }
 265     }
 266
 267     # The foo.tt TT template can use the stash data from the database
 268     [% WHILE (item = data.next) %]
 269         [% item.foo %]
 270     [% END %]
 271
 272     # called for /bar/of/soap, /bar/of/soap/10, etc.
 273     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 274
 275     # called after all actions are finished
 276     sub end : Action {
 277         my ( $self, $c ) = @_;
 278         if ( scalar @{ $c->error } ) { ... } # handle errors
 279         return if $c->res->body; # already have a response
 280         $c->forward( 'MyApp::View::TT' ); # render template
 281     }
 282
 283 See L<Catalyst::Manual::Intro> for additional information.
 284
 285 =head1 DESCRIPTION
 286
 287 Catalyst is a modern framework for making web applications without the
 288 pain usually associated with this process. This document is a reference
 289 to the main Catalyst application. If you are a new user, we suggest you
 290 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 291
 292 See L<Catalyst::Manual> for more documentation.
 293
 294 Catalyst plugins can be loaded by naming them as arguments to the "use
 295 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 296 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 297 C<My::Module>.
 298
 299     use Catalyst qw/My::Module/;
 300
 301 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 302 fully qualify the name by using a unary plus:
 303
 304     use Catalyst qw/
 305         My::Module
 306         +Fully::Qualified::Plugin::Name
 307     /;
 308
 309 Special flags like C<-Debug> can also be specified as
 310 arguments when Catalyst is loaded:
 311
 312     use Catalyst qw/-Debug My::Module/;
 313
 314 The position of plugins and flags in the chain is important, because
 315 they are loaded in the order in which they appear.
 316
 317 The following flags are supported:
 318
 319 =head2 -Debug
 320
 321 Enables debug output. You can also force this setting from the system
 322 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 323 settings override the application, with <MYAPP>_DEBUG having the highest
 324 priority.
 325
 326 This sets the log level to 'debug' and enables full debug output on the
 327 error screen. If you only want the latter, see L<< $c->debug >>.
 328
 329 =head2 -Home
 330
 331 Forces Catalyst to use a specific home directory, e.g.:
 332
 333     use Catalyst qw[-Home=/usr/mst];
 334
 335 This can also be done in the shell environment by setting either the
 336 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 337 is replaced with the uppercased name of your application, any "::" in
 338 the name will be replaced with underscores, e.g. MyApp::Web should use
 339 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 340
 341 If none of these are set, Catalyst will attempt to automatically detect the
 342 home directory. If you are working in a development environment, Catalyst
 343 will try and find the directory containing either Makefile.PL, Build.PL,
 344 dist.ini, or cpanfile. If the application has been installed into the system
 345 (i.e. you have done C<make install>), then Catalyst will use the path to your
 346 application module, without the .pm extension (e.g., /foo/MyApp if your
 347 application was installed at /foo/MyApp.pm)
 348
 349 =head2 -Log
 350
 351     use Catalyst '-Log=warn,fatal,error';
 352
 353 Specifies a comma-delimited list of log levels.
 354
 355 =head2 -Stats
 356
 357 Enables statistics collection and reporting.
 358
 359    use Catalyst qw/-Stats=1/;
 360
 361 You can also force this setting from the system environment with CATALYST_STATS
 362 or <MYAPP>_STATS. The environment settings override the application, with
 363 <MYAPP>_STATS having the highest priority.
 364
 365 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 366
 367 =head1 METHODS
 368
 369 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 370
 371 =head2 $c->action
 372
 373 Returns a L<Catalyst::Action> object for the current action, which
 374 stringifies to the action name. See L<Catalyst::Action>.
 375
 376 =head2 $c->namespace
 377
 378 Returns the namespace of the current action, i.e., the URI prefix
 379 corresponding to the controller of the current action. For example:
 380
 381     # in Controller::Foo::Bar
 382     $c->namespace; # returns 'foo/bar';
 383
 384 =head2 $c->request
 385
 386 =head2 $c->req
 387
 388 Returns the current L<Catalyst::Request> object, giving access to
 389 information about the current client request (including parameters,
 390 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 391
 392 =head2 REQUEST FLOW HANDLING
 393
 394 =head2 $c->forward( $action [, \@arguments ] )
 395
 396 =head2 $c->forward( $class, $method, [, \@arguments ] )
 397
 398 This is one way of calling another action (method) in the same or
 399 a different controller. You can also use C<< $self->my_method($c, @args) >>
 400 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 401 in a different controller.
 402 The main difference is that 'forward' uses some of the Catalyst request
 403 cycle overhead, including debugging, which may be useful to you. On the
 404 other hand, there are some complications to using 'forward', restrictions
 405 on values returned from 'forward', and it may not handle errors as you prefer.
 406 Whether you use 'forward' or not is up to you; it is not considered superior to
 407 the other ways to call a method.
 408
 409 'forward' calls  another action, by its private name. If you give a
 410 class name but no method, C<process()> is called. You may also optionally
 411 pass arguments in an arrayref. The action will receive the arguments in
 412 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 413 C<< $c->req->args >> will be restored to the previous values.
 414
 415 Any data C<return>ed from the action forwarded to, will be returned by the
 416 call to forward.
 417
 418     my $foodata = $c->forward('/foo');
 419     $c->forward('index');
 420     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 421     $c->forward('View::TT');
 422
 423 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 424 an C<< eval { } >> around the call (actually
 425 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 426 exceptions thrown by the called action non-fatal and pushing them onto
 427 $c->error instead. If you want C<die> to propagate you need to do something
 428 like:
 429
 430     $c->forward('foo');
 431     die join "\n", @{ $c->error } if @{ $c->error };
 432
 433 Or make sure to always return true values from your actions and write
 434 your code like this:
 435
 436     $c->forward('foo') || return;
 437
 438 Another note is that C<< $c->forward >> always returns a scalar because it
 439 actually returns $c->state which operates in a scalar context.
 440 Thus, something like:
 441
 442     return @array;
 443
 444 in an action that is forwarded to is going to return a scalar,
 445 i.e. how many items are in that array, which is probably not what you want.
 446 If you need to return an array then return a reference to it,
 447 or stash it like so:
 448
 449     $c->stash->{array} = \@array;
 450
 451 and access it from the stash.
 452
 453 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 454
 455 =cut
 456
 457 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 458
 459 =head2 $c->detach( $action [, \@arguments ] )
 460
 461 =head2 $c->detach( $class, $method, [, \@arguments ] )
 462
 463 =head2 $c->detach()
 464
 465 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 466 doesn't return to the previous action when processing is finished.
 467
 468 When called with no arguments it escapes the processing chain entirely.
 469
 470 =cut
 471
 472 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 473
 474 =head2 $c->visit( $action [, \@arguments ] )
 475
 476 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 477
 478 =head2 $c->visit( $class, $method, [, \@arguments ] )
 479
 480 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 481
 482 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 483 but does a full dispatch, instead of just calling the new C<$action> /
 484 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 485 you go to are called, just like a new request.
 486
 487 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 488 This means, for example, that C<< $c->action >> methods such as
 489 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 490 L<reverse|Catalyst::Action/reverse> return information for the visited action
 491 when they are invoked within the visited action.  This is different from the
 492 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 493 continues to use the $c->action object from the caller action even when
 494 invoked from the called action.
 495
 496 C<< $c->stash >> is kept unchanged.
 497
 498 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 499 allows you to "wrap" another action, just as it would have been called by
 500 dispatching from a URL, while the analogous
 501 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 502 transfer control to another action as if it had been reached directly from a URL.
 503
 504 =cut
 505
 506 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 507
 508 =head2 $c->go( $action [, \@arguments ] )
 509
 510 =head2 $c->go( $action [, \@captures, \@arguments ] )
 511
 512 =head2 $c->go( $class, $method, [, \@arguments ] )
 513
 514 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 515
 516 The relationship between C<go> and
 517 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 518 the relationship between
 519 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 520 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 521 C<< $c->go >> will perform a full dispatch on the specified action or method,
 522 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 523 C<go> escapes the processing of the current request chain on completion, and
 524 does not return to its caller.
 525
 526 @arguments are arguments to the final destination of $action. @captures are
 527 arguments to the intermediate steps, if any, on the way to the final sub of
 528 $action.
 529
 530 =cut
 531
 532 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 533
 534 =head2 $c->response
 535
 536 =head2 $c->res
 537
 538 Returns the current L<Catalyst::Response> object, see there for details.
 539
 540 =head2 $c->stash
 541
 542 Returns a hashref to the stash, which may be used to store data and pass
 543 it between components during a request. You can also set hash keys by
 544 passing arguments. The stash is automatically sent to the view. The
 545 stash is cleared at the end of a request; it cannot be used for
 546 persistent storage (for this you must use a session; see
 547 L<Catalyst::Plugin::Session> for a complete system integrated with
 548 Catalyst).
 549
 550     $c->stash->{foo} = $bar;
 551     $c->stash( { moose => 'majestic', qux => 0 } );
 552     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 553
 554     # stash is automatically passed to the view for use in a template
 555     $c->forward( 'MyApp::View::TT' );
 556
 557 The stash hash is currently stored in the PSGI C<$env> and is managed by
 558 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 559 the stash can be accessed in sub applications mounted under your main
 560 L<Catalyst> application.  For example if you delegate the response of an
 561 action to another L<Catalyst> application, that sub application will have
 562 access to all the stash keys of the main one, and if can of course add
 563 more keys of its own.  However those new keys will not 'bubble' back up
 564 to the main application.
 565
 566 For more information the best thing to do is to review the test case:
 567 t/middleware-stash.t in the distribution /t directory.
 568
 569 =cut
 570
 571 sub stash {
 572   my $c = shift;
 573   $c->log->error("You are requesting the stash but you don't have a context") unless blessed $c;
 574   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 575 }
 576
 577 =head2 $c->error
 578
 579 =head2 $c->error($error, ...)
 580
 581 =head2 $c->error($arrayref)
 582
 583 Returns an arrayref containing error messages.  If Catalyst encounters an
 584 error while processing a request, it stores the error in $c->error.  This
 585 method should only be used to store fatal error messages.
 586
 587     my @error = @{ $c->error };
 588
 589 Add a new error.
 590
 591     $c->error('Something bad happened');
 592
 593 Calling this will always return an arrayref (if there are no errors it
 594 will be an empty arrayref.
 595
 596 =cut
 597
 598 sub error {
 599     my $c = shift;
 600     if ( $_[0] ) {
 601         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 602         croak @$error unless ref $c;
 603         push @{ $c->{error} }, @$error;
 604     }
 605     elsif ( defined $_[0] ) { $c->{error} = undef }
 606     return $c->{error} || [];
 607 }
 608
 609
 610 =head2 $c->state
 611
 612 Contains the return value of the last executed action.
 613 Note that << $c->state >> operates in a scalar context which means that all
 614 values it returns are scalar.
 615
 616 =head2 $c->clear_errors
 617
 618 Clear errors.  You probably don't want to clear the errors unless you are
 619 implementing a custom error screen.
 620
 621 This is equivalent to running
 622
 623     $c->error(0);
 624
 625 =cut
 626
 627 sub clear_errors {
 628     my $c = shift;
 629     $c->error(0);
 630 }
 631
 632 =head2 $c->has_errors
 633
 634 Returns true if you have errors
 635
 636 =cut
 637
 638 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 639
 640 =head2 $c->last_error
 641
 642 Returns the most recent error in the stack (the one most recently added...)
 643 or nothing if there are no errors.  This does not modify the contents of the
 644 error stack.
 645
 646 =cut
 647
 648 sub last_error {
 649   my (@errs) = @{shift->error};
 650   return scalar(@errs) ? $errs[-1]: undef;
 651 }
 652
 653 =head2 shift_errors
 654
 655 shifts the most recently added error off the error stack and returns it.  Returns
 656 nothing if there are no more errors.
 657
 658 =cut
 659
 660 sub shift_errors {
 661     my ($self) = @_;
 662     my @errors = @{$self->error};
 663     my $err = shift(@errors);
 664     $self->{error} = \@errors;
 665     return $err;
 666 }
 667
 668 =head2 pop_errors
 669
 670 pops the most recently added error off the error stack and returns it.  Returns
 671 nothing if there are no more errors.
 672
 673 =cut
 674
 675 sub pop_errors {
 676     my ($self) = @_;
 677     my @errors = @{$self->error};
 678     my $err = pop(@errors);
 679     $self->{error} = \@errors;
 680     return $err;
 681 }
 682
 683 sub _comp_search_prefixes {
 684     my $c = shift;
 685     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 686 }
 687
 688 # search components given a name and some prefixes
 689 sub _comp_names_search_prefixes {
 690     my ( $c, $name, @prefixes ) = @_;
 691     my $appclass = ref $c || $c;
 692     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 693     $filter = qr/$filter/; # Compile regex now rather than once per loop
 694
 695     # map the original component name to the sub part that we will search against
 696     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 697         grep { /$filter/ } keys %{ $c->components };
 698
 699     # undef for a name will return all
 700     return keys %eligible if !defined $name;
 701
 702     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 703     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 704
 705     return @result if @result;
 706
 707     # if we were given a regexp to search against, we're done.
 708     return if $name->$_isa('Regexp');
 709
 710     # skip regexp fallback if configured
 711     return
 712         if $appclass->config->{disable_component_resolution_regex_fallback};
 713
 714     # regexp fallback
 715     $query  = qr/$name/i;
 716     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 717
 718     # no results? try against full names
 719     if( !@result ) {
 720         @result = grep { m{$query} } keys %eligible;
 721     }
 722
 723     # don't warn if we didn't find any results, it just might not exist
 724     if( @result ) {
 725         # Disgusting hack to work out correct method name
 726         my $warn_for = lc $prefixes[0];
 727         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 728            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 729            "component resolution is unreliable and unsafe.";
 730         my $short = $result[0];
 731         # remove the component namespace prefix
 732         $short =~ s/.*?(Model|Controller|View):://;
 733         my $shortmess = Carp::shortmess('');
 734         if ($shortmess =~ m#Catalyst/Plugin#) {
 735            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 736               "plugin's config";
 737         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 738            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 739               "component's config";
 740         } else {
 741            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 742               "but if you really wanted to search, pass in a regexp as the argument " .
 743               "like so: \$c->${warn_for}(qr/${name}/)";
 744         }
 745         $c->log->warn( "${msg}$shortmess" );
 746     }
 747
 748     return @result;
 749 }
 750
 751 # Find possible names for a prefix
 752 sub _comp_names {
 753     my ( $c, @prefixes ) = @_;
 754     my $appclass = ref $c || $c;
 755
 756     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 757
 758     my @names = map { s{$filter}{}; $_; }
 759         $c->_comp_names_search_prefixes( undef, @prefixes );
 760
 761     return @names;
 762 }
 763
 764 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 765
 766 sub _filter_component {
 767     my ( $c, $comp, @args ) = @_;
 768
 769     if(ref $comp eq 'CODE') {
 770       $comp = $comp->();
 771     }
 772
 773     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 774       return $comp->ACCEPT_CONTEXT( $c, @args );
 775     }
 776
 777     $c->log->warn("You called component '${\$comp->catalyst_component_name}' with arguments [@args], but this component does not ACCEPT_CONTEXT, so args are ignored.") if scalar(@args) && $c->debug;
 778
 779     return $comp;
 780 }
 781
 782 =head2 COMPONENT ACCESSORS
 783
 784 =head2 $c->controller($name)
 785
 786 Gets a L<Catalyst::Controller> instance by name.
 787
 788     $c->controller('Foo')->do_stuff;
 789
 790 If the name is omitted, will return the controller for the dispatched
 791 action.
 792
 793 If you want to search for controllers, pass in a regexp as the argument.
 794
 795     # find all controllers that start with Foo
 796     my @foo_controllers = $c->controller(qr{^Foo});
 797
 798
 799 =cut
 800
 801 sub controller {
 802     my ( $c, $name, @args ) = @_;
 803
 804     my $appclass = ref($c) || $c;
 805     if( $name ) {
 806         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 807             my $comps = $c->components;
 808             my $check = $appclass."::Controller::".$name;
 809             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 810         }
 811         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 812         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 813         return $c->_filter_component( $result[ 0 ], @args );
 814     }
 815
 816     return $c->component( $c->action->class );
 817 }
 818
 819 =head2 $c->model($name)
 820
 821 Gets a L<Catalyst::Model> instance by name.
 822
 823     $c->model('Foo')->do_stuff;
 824
 825 Any extra arguments are directly passed to ACCEPT_CONTEXT, if the model
 826 defines ACCEPT_CONTEXT.  If it does not, the args are discarded.
 827
 828 If the name is omitted, it will look for
 829  - a model object in $c->stash->{current_model_instance}, then
 830  - a model name in $c->stash->{current_model}, then
 831  - a config setting 'default_model', or
 832  - check if there is only one model, and return it if that's the case.
 833
 834 If you want to search for models, pass in a regexp as the argument.
 835
 836     # find all models that start with Foo
 837     my @foo_models = $c->model(qr{^Foo});
 838
 839 =cut
 840
 841 sub model {
 842     my ( $c, $name, @args ) = @_;
 843     my $appclass = ref($c) || $c;
 844     if( $name ) {
 845         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 846             my $comps = $c->components;
 847             my $check = $appclass."::Model::".$name;
 848             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 849         }
 850         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 851         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 852         return $c->_filter_component( $result[ 0 ], @args );
 853     }
 854
 855     if (ref $c) {
 856         return $c->stash->{current_model_instance}
 857           if $c->stash->{current_model_instance};
 858         return $c->model( $c->stash->{current_model} )
 859           if $c->stash->{current_model};
 860     }
 861     return $c->model( $appclass->config->{default_model} )
 862       if $appclass->config->{default_model};
 863
 864     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 865
 866     if( $rest ) {
 867         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 868         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 869         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 870         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 871         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 872     }
 873
 874     return $c->_filter_component( $comp );
 875 }
 876
 877
 878 =head2 $c->view($name)
 879
 880 Gets a L<Catalyst::View> instance by name.
 881
 882     $c->view('Foo')->do_stuff;
 883
 884 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 885
 886 If the name is omitted, it will look for
 887  - a view object in $c->stash->{current_view_instance}, then
 888  - a view name in $c->stash->{current_view}, then
 889  - a config setting 'default_view', or
 890  - check if there is only one view, and return it if that's the case.
 891
 892 If you want to search for views, pass in a regexp as the argument.
 893
 894     # find all views that start with Foo
 895     my @foo_views = $c->view(qr{^Foo});
 896
 897 =cut
 898
 899 sub view {
 900     my ( $c, $name, @args ) = @_;
 901
 902     my $appclass = ref($c) || $c;
 903     if( $name ) {
 904         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 905             my $comps = $c->components;
 906             my $check = $appclass."::View::".$name;
 907             if( exists $comps->{$check} ) {
 908                 return $c->_filter_component( $comps->{$check}, @args );
 909             }
 910             else {
 911                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 912             }
 913         }
 914         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 915         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 916         return $c->_filter_component( $result[ 0 ], @args );
 917     }
 918
 919     if (ref $c) {
 920         return $c->stash->{current_view_instance}
 921           if $c->stash->{current_view_instance};
 922         return $c->view( $c->stash->{current_view} )
 923           if $c->stash->{current_view};
 924     }
 925     return $c->view( $appclass->config->{default_view} )
 926       if $appclass->config->{default_view};
 927
 928     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 929
 930     if( $rest ) {
 931         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 932         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 933         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 934         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 935         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 936     }
 937
 938     return $c->_filter_component( $comp );
 939 }
 940
 941 =head2 $c->controllers
 942
 943 Returns the available names which can be passed to $c->controller
 944
 945 =cut
 946
 947 sub controllers {
 948     my ( $c ) = @_;
 949     return $c->_comp_names(qw/Controller C/);
 950 }
 951
 952 =head2 $c->models
 953
 954 Returns the available names which can be passed to $c->model
 955
 956 =cut
 957
 958 sub models {
 959     my ( $c ) = @_;
 960     return $c->_comp_names(qw/Model M/);
 961 }
 962
 963
 964 =head2 $c->views
 965
 966 Returns the available names which can be passed to $c->view
 967
 968 =cut
 969
 970 sub views {
 971     my ( $c ) = @_;
 972     return $c->_comp_names(qw/View V/);
 973 }
 974
 975 =head2 $c->comp($name)
 976
 977 =head2 $c->component($name)
 978
 979 Gets a component object by name. This method is not recommended,
 980 unless you want to get a specific component by full
 981 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 982 should be used instead.
 983
 984 If C<$name> is a regexp, a list of components matched against the full
 985 component name will be returned.
 986
 987 If Catalyst can't find a component by name, it will fallback to regex
 988 matching by default. To disable this behaviour set
 989 disable_component_resolution_regex_fallback to a true value.
 990
 991     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 992
 993 =cut
 994
 995 sub component {
 996     my ( $c, $name, @args ) = @_;
 997
 998     if( $name ) {
 999         my $comps = $c->components;
1000
1001         if( !ref $name ) {
1002             # is it the exact name?
1003             return $c->_filter_component( $comps->{ $name }, @args )
1004                        if exists $comps->{ $name };
1005
1006             # perhaps we just omitted "MyApp"?
1007             my $composed = ( ref $c || $c ) . "::${name}";
1008             return $c->_filter_component( $comps->{ $composed }, @args )
1009                        if exists $comps->{ $composed };
1010
1011             # search all of the models, views and controllers
1012             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
1013             return $c->_filter_component( $comp, @args ) if $comp;
1014         }
1015
1016         return
1017             if $c->config->{disable_component_resolution_regex_fallback};
1018
1019         # This is here so $c->comp( '::M::' ) works
1020         my $query = ref $name ? $name : qr{$name}i;
1021
1022         my @result = grep { m{$query} } keys %{ $c->components };
1023         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
1024
1025         if( $result[ 0 ] ) {
1026             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
1027             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
1028             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
1029             return $c->_filter_component( $result[ 0 ], @args );
1030         }
1031
1032         # I would expect to return an empty list here, but that breaks back-compat
1033     }
1034
1035     # fallback
1036     return sort keys %{ $c->components };
1037 }
1038
1039 =head2 CLASS DATA AND HELPER CLASSES
1040
1041 =head2 $c->config
1042
1043 Returns or takes a hashref containing the application's configuration.
1044
1045     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
1046
1047 You can also use a C<YAML>, C<XML> or L<Config::General> config file
1048 like C<myapp.conf> in your applications home directory. See
1049 L<Catalyst::Plugin::ConfigLoader>.
1050
1051 =head3 Cascading configuration
1052
1053 The config method is present on all Catalyst components, and configuration
1054 will be merged when an application is started. Configuration loaded with
1055 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
1056 followed by configuration in your top level C<MyApp> class. These two
1057 configurations are merged, and then configuration data whose hash key matches a
1058 component name is merged with configuration for that component.
1059
1060 The configuration for a component is then passed to the C<new> method when a
1061 component is constructed.
1062
1063 For example:
1064
1065     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
1066     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
1067
1068 will mean that C<MyApp::Model::Foo> receives the following data when
1069 constructed:
1070
1071     MyApp::Model::Foo->new({
1072         bar => 'baz',
1073         quux => 'frob',
1074         overrides => 'me',
1075     });
1076
1077 It's common practice to use a Moose attribute
1078 on the receiving component to access the config value.
1079
1080     package MyApp::Model::Foo;
1081
1082     use Moose;
1083
1084     # this attr will receive 'baz' at construction time
1085     has 'bar' => (
1086         is  => 'rw',
1087         isa => 'Str',
1088     );
1089
1090 You can then get the value 'baz' by calling $c->model('Foo')->bar
1091 (or $self->bar inside code in the model).
1092
1093 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
1094 as a way of reading config within your code, as this B<will not> give you the
1095 correctly merged config back. You B<MUST> take the config values supplied to
1096 the constructor and use those instead.
1097
1098 =cut
1099
1100 around config => sub {
1101     my $orig = shift;
1102     my $c = shift;
1103
1104     croak('Setting config after setup has been run is not allowed.')
1105         if ( @_ and $c->setup_finished );
1106
1107     $c->$orig(@_);
1108 };
1109
1110 =head2 $c->log
1111
1112 Returns the logging object instance. Unless it is already set, Catalyst
1113 sets this up with a L<Catalyst::Log> object. To use your own log class,
1114 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1115 C<< __PACKAGE__->setup >>.
1116
1117  __PACKAGE__->log( MyLogger->new );
1118  __PACKAGE__->setup;
1119
1120 And later:
1121
1122     $c->log->info( 'Now logging with my own logger!' );
1123
1124 Your log class should implement the methods described in
1125 L<Catalyst::Log>.
1126
1127 =head2 has_encoding
1128
1129 Returned True if there's a valid encoding
1130
1131 =head2 clear_encoding
1132
1133 Clears the encoding for the current context
1134
1135 =head2 encoding
1136
1137 Sets or gets the application encoding.  Setting encoding takes either an
1138 Encoding object or a string that we try to resolve via L<Encode::find_encoding>.
1139
1140 You would expect to get the encoding object back if you attempt to set it.  If
1141 there is a failure you will get undef returned and an error message in the log.
1142
1143 =cut
1144
1145 sub has_encoding { shift->encoding ? 1:0 }
1146
1147 sub clear_encoding {
1148     my $c = shift;
1149     if(blessed $c) {
1150         $c->encoding(undef);
1151     } else {
1152         $c->log->error("You can't clear encoding on the application");
1153     }
1154 }
1155
1156 sub encoding {
1157     my $c = shift;
1158     my $encoding;
1159
1160     if ( scalar @_ ) {
1161
1162         # Don't let one change this once we are too far into the response
1163         if(blessed $c && $c->res->finalized_headers) {
1164           Carp::croak("You may not change the encoding once the headers are finalized");
1165           return;
1166         }
1167
1168         # Let it be set to undef
1169         if (my $wanted = shift)  {
1170             $encoding = Encode::find_encoding($wanted)
1171               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1172             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1173         }
1174         else {
1175             binmode(STDERR);
1176         }
1177
1178         $encoding = ref $c
1179                   ? $c->{encoding} = $encoding
1180                   : $c->_encoding($encoding);
1181     } else {
1182       $encoding = ref $c && exists $c->{encoding}
1183                 ? $c->{encoding}
1184                 : $c->_encoding;
1185     }
1186
1187     return $encoding;
1188 }
1189
1190 =head2 $c->debug
1191
1192 Returns 1 if debug mode is enabled, 0 otherwise.
1193
1194 You can enable debug mode in several ways:
1195
1196 =over
1197
1198 =item By calling myapp_server.pl with the -d flag
1199
1200 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1201
1202 =item The -Debug option in your MyApp.pm
1203
1204 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1205
1206 =back
1207
1208 The first three also set the log level to 'debug'.
1209
1210 Calling C<< $c->debug(1) >> has no effect.
1211
1212 =cut
1213
1214 sub debug { 0 }
1215
1216 =head2 $c->dispatcher
1217
1218 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1219
1220 =head2 $c->engine
1221
1222 Returns the engine instance. See L<Catalyst::Engine>.
1223
1224
1225 =head2 UTILITY METHODS
1226
1227 =head2 $c->path_to(@path)
1228
1229 Merges C<@path> with C<< $c->config->{home} >> and returns a
1230 L<Path::Class::Dir> object. Note you can usually use this object as
1231 a filename, but sometimes you will have to explicitly stringify it
1232 yourself by calling the C<< ->stringify >> method.
1233
1234 For example:
1235
1236     $c->path_to( 'db', 'sqlite.db' );
1237
1238 =cut
1239
1240 sub path_to {
1241     my ( $c, @path ) = @_;
1242     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1243     if ( -d $path ) { return $path }
1244     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1245 }
1246
1247 sub plugin {
1248     my ( $class, $name, $plugin, @args ) = @_;
1249
1250     # See block comment in t/unit_core_plugin.t
1251     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1252
1253     $class->_register_plugin( $plugin, 1 );
1254
1255     eval { $plugin->import };
1256     $class->mk_classdata($name);
1257     my $obj;
1258     eval { $obj = $plugin->new(@args) };
1259
1260     if ($@) {
1261         Catalyst::Exception->throw( message =>
1262               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1263     }
1264
1265     $class->$name($obj);
1266     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1267       if $class->debug;
1268 }
1269
1270 =head2 MyApp->setup
1271
1272 Initializes the dispatcher and engine, loads any plugins, and loads the
1273 model, view, and controller components. You may also specify an array
1274 of plugins to load here, if you choose to not load them in the C<use
1275 Catalyst> line.
1276
1277     MyApp->setup;
1278     MyApp->setup( qw/-Debug/ );
1279
1280 B<Note:> You B<should not> wrap this method with method modifiers
1281 or bad things will happen - wrap the C<setup_finalize> method instead.
1282
1283 B<Note:> You can create a custom setup stage that will execute when the
1284 application is starting.  Use this to customize setup.
1285
1286     MyApp->setup(-Custom=value);
1287
1288     sub setup_custom {
1289       my ($class, $value) = @_;
1290     }
1291
1292 Can be handy if you want to hook into the setup phase.
1293
1294 =cut
1295
1296 sub setup {
1297     my ( $class, @arguments ) = @_;
1298     croak('Running setup more than once')
1299         if ( $class->setup_finished );
1300
1301     unless ( $class->isa('Catalyst') ) {
1302
1303         Catalyst::Exception->throw(
1304             message => qq/'$class' does not inherit from Catalyst/ );
1305     }
1306
1307     if ( $class->arguments ) {
1308         @arguments = ( @arguments, @{ $class->arguments } );
1309     }
1310
1311     # Process options
1312     my $flags = {};
1313
1314     foreach (@arguments) {
1315
1316         if (/^-Debug$/) {
1317             $flags->{log} =
1318               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1319         }
1320         elsif (/^-(\w+)=?(.*)$/) {
1321             $flags->{ lc $1 } = $2;
1322         }
1323         else {
1324             push @{ $flags->{plugins} }, $_;
1325         }
1326     }
1327
1328     $class->setup_home( delete $flags->{home} );
1329
1330     $class->setup_log( delete $flags->{log} );
1331     $class->setup_plugins( delete $flags->{plugins} );
1332
1333     $class->setup_data_handlers();
1334     $class->setup_dispatcher( delete $flags->{dispatcher} );
1335     if (my $engine = delete $flags->{engine}) {
1336         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1337     }
1338     $class->setup_engine();
1339     $class->setup_stats( delete $flags->{stats} );
1340
1341     for my $flag ( sort keys %{$flags} ) {
1342
1343         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1344             &$code( $class, delete $flags->{$flag} );
1345         }
1346         else {
1347             $class->log->warn(qq/Unknown flag "$flag"/);
1348         }
1349     }
1350
1351     eval { require Catalyst::Devel; };
1352     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1353         $class->log->warn(<<"EOF");
1354 You are running an old script!
1355
1356   Please update by running (this will overwrite existing files):
1357     catalyst.pl -force -scripts $class
1358
1359   or (this will not overwrite existing files):
1360     catalyst.pl -scripts $class
1361
1362 EOF
1363     }
1364
1365     # Call plugins setup, this is stupid and evil.
1366     # Also screws C3 badly on 5.10, hack to avoid.
1367     {
1368         no warnings qw/redefine/;
1369         local *setup = sub { };
1370         $class->setup unless $Catalyst::__AM_RESTARTING;
1371     }
1372
1373     # If you are expecting configuration info as part of your setup, it needs
1374     # to get called here and below, since we need the above line to support
1375     # ConfigLoader based configs.
1376
1377     $class->setup_encoding();
1378     $class->setup_middleware();
1379
1380     # Initialize our data structure
1381     $class->components( {} );
1382
1383     $class->setup_components;
1384
1385     if ( $class->debug ) {
1386         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1387
1388         if (@plugins) {
1389             my $column_width = Catalyst::Utils::term_width() - 6;
1390             my $t = Text::SimpleTable->new($column_width);
1391             $t->row($_) for @plugins;
1392             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1393         }
1394
1395         my @middleware = map {
1396           ref $_ eq 'CODE' ?
1397             "Inline Coderef" :
1398               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1399                 || '')  } $class->registered_middlewares;
1400
1401         if (@middleware) {
1402             my $column_width = Catalyst::Utils::term_width() - 6;
1403             my $t = Text::SimpleTable->new($column_width);
1404             $t->row($_) for @middleware;
1405             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1406         }
1407
1408         my %dh = $class->registered_data_handlers;
1409         if (my @data_handlers = keys %dh) {
1410             my $column_width = Catalyst::Utils::term_width() - 6;
1411             my $t = Text::SimpleTable->new($column_width);
1412             $t->row($_) for @data_handlers;
1413             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1414         }
1415
1416         my $dispatcher = $class->dispatcher;
1417         my $engine     = $class->engine;
1418         my $home       = $class->config->{home};
1419
1420         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1421         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1422
1423         $home
1424           ? ( -d $home )
1425           ? $class->log->debug(qq/Found home "$home"/)
1426           : $class->log->debug(qq/Home "$home" doesn't exist/)
1427           : $class->log->debug(q/Couldn't find home/);
1428
1429         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1430
1431         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1432         for my $comp ( sort keys %{ $class->components } ) {
1433             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1434             $t->row( $comp, $type );
1435         }
1436         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1437           if ( keys %{ $class->components } );
1438     }
1439
1440     # Add our self to components, since we are also a component
1441     if( $class->isa('Catalyst::Controller') ){
1442       $class->components->{$class} = $class;
1443     }
1444
1445     $class->setup_actions;
1446
1447     if ( $class->debug ) {
1448         my $name = $class->config->{name} || 'Application';
1449         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1450     }
1451
1452     if ($class->config->{case_sensitive}) {
1453         $class->log->warn($class . "->config->{case_sensitive} is set.");
1454         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1455     }
1456
1457     $class->setup_finalize;
1458
1459     # Flush the log for good measure (in case something turned off 'autoflush' early)
1460     $class->log->_flush() if $class->log->can('_flush');
1461
1462     return $class || 1; # Just in case someone named their Application 0...
1463 }
1464
1465 =head2 $app->setup_finalize
1466
1467 A hook to attach modifiers to. This method does not do anything except set the
1468 C<setup_finished> accessor.
1469
1470 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1471
1472 Example:
1473
1474     after setup_finalize => sub {
1475         my $app = shift;
1476
1477         ## do stuff here..
1478     };
1479
1480 =cut
1481
1482 sub setup_finalize {
1483     my ($class) = @_;
1484     $class->setup_finished(1);
1485 }
1486
1487 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1488
1489 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1490
1491 =head2 $c->uri_for( $action, [@captures, @args], \%query_values? )
1492
1493 Constructs an absolute L<URI> object based on the application root, the
1494 provided path, and the additional arguments and query parameters provided.
1495 When used as a string, provides a textual URI.  If you need more flexibility
1496 than this (i.e. the option to provide relative URIs etc.) see
1497 L<Catalyst::Plugin::SmartURI>.
1498
1499 If no arguments are provided, the URI for the current action is returned.
1500 To return the current action and also provide @args, use
1501 C<< $c->uri_for( $c->action, @args ) >>.
1502
1503 If the first argument is a string, it is taken as a public URI path relative
1504 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1505 relative to the application root (if it does). It is then merged with
1506 C<< $c->request->base >>; any C<@args> are appended as additional path
1507 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1508
1509 If the first argument is a L<Catalyst::Action> it represents an action which
1510 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1511 optional C<\@captures> argument (an arrayref) allows passing the captured
1512 variables that are needed to fill in the paths of Chained and Regex actions;
1513 once the path is resolved, C<uri_for> continues as though a path was
1514 provided, appending any arguments or parameters and creating an absolute
1515 URI.
1516
1517 The captures for the current request can be found in
1518 C<< $c->request->captures >>, and actions can be resolved using
1519 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1520 path, use C<< $c->uri_for_action >> instead.
1521
1522   # Equivalent to $c->req->uri
1523   $c->uri_for($c->action, $c->req->captures,
1524       @{ $c->req->args }, $c->req->params);
1525
1526   # For the Foo action in the Bar controller
1527   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1528
1529   # Path to a static resource
1530   $c->uri_for('/static/images/logo.png');
1531
1532 In general the scheme of the generated URI object will follow the incoming request
1533 however if your targeted action or action chain has the Scheme attribute it will
1534 use that instead.
1535
1536 Also, if the targeted Action or Action chain declares Args/CaptureArgs that have
1537 type constraints, we will require that your proposed URL verify on those declared
1538 constraints.
1539
1540 =cut
1541
1542 sub uri_for {
1543     my ( $c, $path, @args ) = @_;
1544
1545     if ( $path->$_isa('Catalyst::Controller') ) {
1546         $path = $path->path_prefix;
1547         $path =~ s{/+\z}{};
1548         $path .= '/';
1549     }
1550
1551     undef($path) if (defined $path && $path eq '');
1552
1553     my $params =
1554       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1555
1556     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1557
1558     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1559     if ( $path->$_isa('Catalyst::Action') ) { # action object
1560         s|/|%2F|g for @args;
1561         my $captures = [ map { s|/|%2F|g; $_; }
1562                         ( scalar @args && ref $args[0] eq 'ARRAY'
1563                          ? @{ shift(@args) }
1564                          : ()) ];
1565
1566         my $action = $path;
1567         my $expanded_action = $c->dispatcher->expand_action( $action );
1568         my $num_captures = $expanded_action->number_of_captures;
1569
1570         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1571         if( !@args && $action->number_of_args ) {
1572           unshift @args, splice @$captures, $num_captures;
1573         }
1574
1575         if($num_captures) {
1576           unless($expanded_action->match_captures_constraints($c, $captures)) {
1577             carp "captures [@{$captures}] do not match the type constraints in actionchain ending with '$expanded_action'";
1578             return;
1579           }
1580         }
1581
1582         $path = $c->dispatcher->uri_for_action($action, $captures);
1583         if (not defined $path) {
1584             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1585                 if $c->debug;
1586             return undef;
1587         }
1588         $path = '/' if $path eq '';
1589
1590         # At this point @encoded_args is the remaining Args (all captures removed).
1591         if($expanded_action->has_args_constraints) {
1592           unless($expanded_action->match_args($c,\@args)) {
1593              carp "args [@args] do not match the type constraints in action '$expanded_action'";
1594              return;
1595           }
1596         }
1597     }
1598
1599     unshift(@args, $path);
1600
1601     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1602         my $namespace = $c->namespace;
1603         if (defined $path) { # cheesy hack to handle path '../foo'
1604            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1605         }
1606         unshift(@args, $namespace || '');
1607     }
1608
1609     # join args with '/', or a blank string
1610     my $args = join('/', grep { defined($_) } @args);
1611     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1612     $args =~ s!^/+!!;
1613
1614     my ($base, $class) = ('/', 'URI::_generic');
1615     if(blessed($c)) {
1616       $base = $c->req->base;
1617       if($target_action) {
1618         $target_action = $c->dispatcher->expand_action($target_action);
1619         if(my $s = $target_action->scheme) {
1620           $s = lc($s);
1621           $class = "URI::$s";
1622           $base->scheme($s);
1623         } else {
1624           $class = ref($base);
1625         }
1626       } else {
1627         $class = ref($base);
1628       }
1629
1630       $base =~ s{(?<!/)$}{/};
1631     }
1632
1633     my $query = '';
1634
1635     # remove and save fragment if there is one
1636     my $fragment;
1637     if ($args =~ s/(#.+)$//) {
1638       $fragment = $1;
1639     }
1640
1641     if (my @keys = keys %$params) {
1642       # somewhat lifted from URI::_query's query_form
1643       $query = '?'.join('&', map {
1644           my $val = $params->{$_};
1645           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1646           s/ /+/g;
1647           my $key = $_;
1648           $val = '' unless defined $val;
1649           (map {
1650               my $param = "$_";
1651               $param = encode_utf8($param);
1652               # using the URI::Escape pattern here so utf8 chars survive
1653               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1654               $param =~ s/ /+/g;
1655
1656               $key = encode_utf8($key);
1657               # using the URI::Escape pattern here so utf8 chars survive
1658               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1659               $key =~ s/ /+/g;
1660
1661               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1662       } @keys);
1663     }
1664
1665     $base = encode_utf8 $base;
1666     $base =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1667     $args = encode_utf8 $args;
1668     $args =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1669
1670     # re-attach fragment on the end of everything after adding params
1671     $query .= $fragment if $fragment;
1672
1673     my $res = bless(\"${base}${args}${query}", $class);
1674     $res;
1675 }
1676
1677 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1678
1679 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1680
1681 =over
1682
1683 =item $path
1684
1685 A private path to the Catalyst action you want to create a URI for.
1686
1687 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1688 >> and passing the resulting C<$action> and the remaining arguments to C<<
1689 $c->uri_for >>.
1690
1691 You can also pass in a Catalyst::Action object, in which case it is passed to
1692 C<< $c->uri_for >>.
1693
1694 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1695
1696 For example, if the action looks like:
1697
1698  package MyApp::Controller::Users;
1699
1700  sub lst : Path('the-list') {}
1701
1702 You can use:
1703
1704  $c->uri_for_action('/users/lst')
1705
1706 and it will create the URI /users/the-list.
1707
1708 =item \@captures_and_args?
1709
1710 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1711 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1712 to interpolate all the parameters in the URI.
1713
1714 =item @args?
1715
1716 Optional list of extra arguments - can be supplied in the
1717 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1718 code.
1719
1720 Your action can have zero, a fixed or a variable number of args (e.g.
1721 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1722
1723 =item \%query_values?
1724
1725 Optional array reference of query parameters to append. E.g.
1726
1727   { foo => 'bar' }
1728
1729 will generate
1730
1731   /rest/of/your/uri?foo=bar
1732
1733 =back
1734
1735 =cut
1736
1737 sub uri_for_action {
1738     my ( $c, $path, @args ) = @_;
1739     my $action = blessed($path)
1740       ? $path
1741       : $c->dispatcher->get_action_by_path($path);
1742     unless (defined $action) {
1743       croak "Can't find action for path '$path'";
1744     }
1745     return $c->uri_for( $action, @args );
1746 }
1747
1748 =head2 $c->welcome_message
1749
1750 Returns the Catalyst welcome HTML page.
1751
1752 =cut
1753
1754 sub welcome_message {
1755     my $c      = shift;
1756     my $name   = $c->config->{name};
1757     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1758     my $prefix = Catalyst::Utils::appprefix( ref $c );
1759     $c->response->content_type('text/html; charset=utf-8');
1760     return <<"EOF";
1761 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1762     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1763 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1764     <head>
1765     <meta http-equiv="Content-Language" content="en" />
1766     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1767         <title>$name on Catalyst $VERSION</title>
1768         <style type="text/css">
1769             body {
1770                 color: #000;
1771                 background-color: #eee;
1772             }
1773             div#content {
1774                 width: 640px;
1775                 margin-left: auto;
1776                 margin-right: auto;
1777                 margin-top: 10px;
1778                 margin-bottom: 10px;
1779                 text-align: left;
1780                 background-color: #ccc;
1781                 border: 1px solid #aaa;
1782             }
1783             p, h1, h2 {
1784                 margin-left: 20px;
1785                 margin-right: 20px;
1786                 font-family: verdana, tahoma, sans-serif;
1787             }
1788             a {
1789                 font-family: verdana, tahoma, sans-serif;
1790             }
1791             :link, :visited {
1792                     text-decoration: none;
1793                     color: #b00;
1794                     border-bottom: 1px dotted #bbb;
1795             }
1796             :link:hover, :visited:hover {
1797                     color: #555;
1798             }
1799             div#topbar {
1800                 margin: 0px;
1801             }
1802             pre {
1803                 margin: 10px;
1804                 padding: 8px;
1805             }
1806             div#answers {
1807                 padding: 8px;
1808                 margin: 10px;
1809                 background-color: #fff;
1810                 border: 1px solid #aaa;
1811             }
1812             h1 {
1813                 font-size: 0.9em;
1814                 font-weight: normal;
1815                 text-align: center;
1816             }
1817             h2 {
1818                 font-size: 1.0em;
1819             }
1820             p {
1821                 font-size: 0.9em;
1822             }
1823             p img {
1824                 float: right;
1825                 margin-left: 10px;
1826             }
1827             span#appname {
1828                 font-weight: bold;
1829                 font-size: 1.6em;
1830             }
1831         </style>
1832     </head>
1833     <body>
1834         <div id="content">
1835             <div id="topbar">
1836                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1837                     $VERSION</h1>
1838              </div>
1839              <div id="answers">
1840                  <p>
1841                  <img src="$logo" alt="Catalyst Logo" />
1842                  </p>
1843                  <p>Welcome to the  world of Catalyst.
1844                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1845                     framework will make web development something you had
1846                     never expected it to be: Fun, rewarding, and quick.</p>
1847                  <h2>What to do now?</h2>
1848                  <p>That really depends  on what <b>you</b> want to do.
1849                     We do, however, provide you with a few starting points.</p>
1850                  <p>If you want to jump right into web development with Catalyst
1851                     you might want to start with a tutorial.</p>
1852 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1853 </pre>
1854 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1855 <pre>
1856 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1857 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1858 </code></pre>
1859                  <h2>What to do next?</h2>
1860                  <p>Next it's time to write an actual application. Use the
1861                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1862                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1863                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1864                     they can save you a lot of work.</p>
1865                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1866                     <p>Also, be sure to check out the vast and growing
1867                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1868                     you are likely to find what you need there.
1869                     </p>
1870
1871                  <h2>Need help?</h2>
1872                  <p>Catalyst has a very active community. Here are the main places to
1873                     get in touch with us.</p>
1874                  <ul>
1875                      <li>
1876                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1877                      </li>
1878                      <li>
1879                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1880                      </li>
1881                      <li>
1882                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1883                      </li>
1884                  </ul>
1885                  <h2>In conclusion</h2>
1886                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1887                     as we enjoyed making it. Please contact us if you have ideas
1888                     for improvement or other feedback.</p>
1889              </div>
1890          </div>
1891     </body>
1892 </html>
1893 EOF
1894 }
1895
1896 =head2 run_options
1897
1898 Contains a hash of options passed from the application script, including
1899 the original ARGV the script received, the processed values from that
1900 ARGV and any extra arguments to the script which were not processed.
1901
1902 This can be used to add custom options to your application's scripts
1903 and setup your application differently depending on the values of these
1904 options.
1905
1906 =head1 INTERNAL METHODS
1907
1908 These methods are not meant to be used by end users.
1909
1910 =head2 $c->components
1911
1912 Returns a hash of components.
1913
1914 =head2 $c->context_class
1915
1916 Returns or sets the context class.
1917
1918 =head2 $c->counter
1919
1920 Returns a hashref containing coderefs and execution counts (needed for
1921 deep recursion detection).
1922
1923 =head2 $c->depth
1924
1925 Returns the number of actions on the current internal execution stack.
1926
1927 =head2 $c->dispatch
1928
1929 Dispatches a request to actions.
1930
1931 =cut
1932
1933 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1934
1935 =head2 $c->dispatcher_class
1936
1937 Returns or sets the dispatcher class.
1938
1939 =head2 $c->dump_these
1940
1941 Returns a list of 2-element array references (name, structure) pairs
1942 that will be dumped on the error page in debug mode.
1943
1944 =cut
1945
1946 sub dump_these {
1947     my $c = shift;
1948     [ Request => $c->req ],
1949     [ Response => $c->res ],
1950     [ Stash => $c->stash ],
1951     [ Config => $c->config ];
1952 }
1953
1954 =head2 $c->engine_class
1955
1956 Returns or sets the engine class.
1957
1958 =head2 $c->execute( $class, $coderef )
1959
1960 Execute a coderef in given class and catch exceptions. Errors are available
1961 via $c->error.
1962
1963 =cut
1964
1965 sub execute {
1966     my ( $c, $class, $code ) = @_;
1967     $class = $c->component($class) || $class;
1968     $c->state(0);
1969
1970     if ( $c->depth >= $RECURSION ) {
1971         my $action = $code->reverse();
1972         $action = "/$action" unless $action =~ /->/;
1973         my $error = qq/Deep recursion detected calling "${action}"/;
1974         $c->log->error($error);
1975         $c->error($error);
1976         $c->state(0);
1977         return $c->state;
1978     }
1979
1980     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1981
1982     push( @{ $c->stack }, $code );
1983
1984     no warnings 'recursion';
1985     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1986     #      I have no idea how, ergo $ret (which appears to fix the issue)
1987     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1988
1989     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1990
1991     my $last = pop( @{ $c->stack } );
1992
1993     if ( my $error = $@ ) {
1994         #rethow if this can be handled by middleware
1995         if ( $c->_handle_http_exception($error) ) {
1996             foreach my $err (@{$c->error}) {
1997                 $c->log->error($err);
1998             }
1999             $c->clear_errors;
2000             $c->log->_flush if $c->log->can('_flush');
2001
2002             $error->can('rethrow') ? $error->rethrow : croak $error;
2003         }
2004         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
2005             $error->rethrow if $c->depth > 1;
2006         }
2007         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
2008             $error->rethrow if $c->depth > 0;
2009         }
2010         else {
2011             unless ( ref $error ) {
2012                 no warnings 'uninitialized';
2013                 chomp $error;
2014                 my $class = $last->class;
2015                 my $name  = $last->name;
2016                 $error = qq/Caught exception in $class->$name "$error"/;
2017             }
2018             $c->error($error);
2019         }
2020         $c->state(0);
2021     }
2022     return $c->state;
2023 }
2024
2025 sub _stats_start_execute {
2026     my ( $c, $code ) = @_;
2027     my $appclass = ref($c) || $c;
2028     return if ( ( $code->name =~ /^_.*/ )
2029         && ( !$appclass->config->{show_internal_actions} ) );
2030
2031     my $action_name = $code->reverse();
2032     $c->counter->{$action_name}++;
2033
2034     my $action = $action_name;
2035     $action = "/$action" unless $action =~ /->/;
2036
2037     # determine if the call was the result of a forward
2038     # this is done by walking up the call stack and looking for a calling
2039     # sub of Catalyst::forward before the eval
2040     my $callsub = q{};
2041     for my $index ( 2 .. 11 ) {
2042         last
2043         if ( ( caller($index) )[0] eq 'Catalyst'
2044             && ( caller($index) )[3] eq '(eval)' );
2045
2046         if ( ( caller($index) )[3] =~ /forward$/ ) {
2047             $callsub = ( caller($index) )[3];
2048             $action  = "-> $action";
2049             last;
2050         }
2051     }
2052
2053     my $uid = $action_name . $c->counter->{$action_name};
2054
2055     # is this a root-level call or a forwarded call?
2056     if ( $callsub =~ /forward$/ ) {
2057         my $parent = $c->stack->[-1];
2058
2059         # forward, locate the caller
2060         if ( defined $parent && exists $c->counter->{"$parent"} ) {
2061             $c->stats->profile(
2062                 begin  => $action,
2063                 parent => "$parent" . $c->counter->{"$parent"},
2064                 uid    => $uid,
2065             );
2066         }
2067         else {
2068
2069             # forward with no caller may come from a plugin
2070             $c->stats->profile(
2071                 begin => $action,
2072                 uid   => $uid,
2073             );
2074         }
2075     }
2076     else {
2077
2078         # root-level call
2079         $c->stats->profile(
2080             begin => $action,
2081             uid   => $uid,
2082         );
2083     }
2084     return $action;
2085
2086 }
2087
2088 sub _stats_finish_execute {
2089     my ( $c, $info ) = @_;
2090     $c->stats->profile( end => $info );
2091 }
2092
2093 =head2 $c->finalize
2094
2095 Finalizes the request.
2096
2097 =cut
2098
2099 sub finalize {
2100     my $c = shift;
2101
2102     for my $error ( @{ $c->error } ) {
2103         $c->log->error($error);
2104     }
2105
2106     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
2107     # stuff like cometd and websockets
2108
2109     if($c->request->_has_io_fh) {
2110       $c->log_response;
2111       return;
2112     }
2113
2114     # Allow engine to handle finalize flow (for POE)
2115     my $engine = $c->engine;
2116     if ( my $code = $engine->can('finalize') ) {
2117         $engine->$code($c);
2118     }
2119     else {
2120
2121         $c->finalize_uploads;
2122
2123         # Error
2124         if ( $#{ $c->error } >= 0 ) {
2125             $c->finalize_error;
2126         }
2127
2128         $c->finalize_encoding;
2129         $c->finalize_headers unless $c->response->finalized_headers;
2130         $c->finalize_body;
2131     }
2132
2133     $c->log_response;
2134
2135     if ($c->use_stats) {
2136         my $elapsed = $c->stats->elapsed;
2137         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
2138         $c->log->info(
2139             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
2140     }
2141
2142     return $c->response->status;
2143 }
2144
2145 =head2 $c->finalize_body
2146
2147 Finalizes body.
2148
2149 =cut
2150
2151 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
2152
2153 =head2 $c->finalize_cookies
2154
2155 Finalizes cookies.
2156
2157 =cut
2158
2159 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
2160
2161 =head2 $c->finalize_error
2162
2163 Finalizes error.  If there is only one error in L</error> and it is an object that
2164 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2165 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2166 return the default error page (production mode).
2167
2168 =cut
2169
2170 sub finalize_error {
2171     my $c = shift;
2172     if($#{$c->error} > 0) {
2173         $c->engine->finalize_error( $c, @_ );
2174     } else {
2175         my ($error) = @{$c->error};
2176         if ( $c->_handle_http_exception($error) ) {
2177             # In the case where the error 'knows what it wants', becauses its PSGI
2178             # aware, just rethow and let middleware catch it
2179             $error->can('rethrow') ? $error->rethrow : croak $error;
2180         } else {
2181             $c->engine->finalize_error( $c, @_ )
2182         }
2183     }
2184 }
2185
2186 =head2 $c->finalize_headers
2187
2188 Finalizes headers.
2189
2190 =cut
2191
2192 sub finalize_headers {
2193     my $c = shift;
2194
2195     my $response = $c->response; #accessor calls can add up?
2196
2197     # Check if we already finalized headers
2198     return if $response->finalized_headers;
2199
2200     # Handle redirects
2201     if ( my $location = $response->redirect ) {
2202         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2203         $response->header( Location => $location );
2204     }
2205
2206     # Remove incorrectly added body and content related meta data when returning
2207     # an information response, or a response the is required to not include a body
2208
2209     $c->finalize_cookies;
2210
2211     # This currently is a NOOP but I don't want to remove it since I guess people
2212     # might have Response subclasses that use it for something... (JNAP)
2213     $c->response->finalize_headers();
2214
2215     # Done
2216     $response->finalized_headers(1);
2217 }
2218
2219 =head2 $c->finalize_encoding
2220
2221 Make sure your body is encoded properly IF you set an encoding.  By
2222 default the encoding is UTF-8 but you can disable it by explicitly setting the
2223 encoding configuration value to undef.
2224
2225 We can only encode when the body is a scalar.  Methods for encoding via the
2226 streaming interfaces (such as C<write> and C<write_fh> on L<Catalyst::Response>
2227 are available).
2228
2229 See L</ENCODING>.
2230
2231 =cut
2232
2233 sub finalize_encoding {
2234     my $c = shift;
2235     my $res = $c->res || return;
2236
2237     # Warn if the set charset is different from the one you put into encoding.  We need
2238     # to do this early since encodable_response is false for this condition and we need
2239     # to match the debug output for backcompat (there's a test for this...) -JNAP
2240     if(
2241       $res->content_type_charset and $c->encoding and
2242       (uc($c->encoding->mime_name) ne uc($res->content_type_charset))
2243     ) {
2244         my $ct = lc($res->content_type_charset);
2245         $c->log->debug("Catalyst encoding config is set to encode in '" .
2246             $c->encoding->mime_name .
2247             "', content type is '$ct', not encoding ");
2248     }
2249
2250     if(
2251       ($res->encodable_response) and
2252       (defined($res->body)) and
2253       (ref(\$res->body) eq 'SCALAR')
2254     ) {
2255         $c->res->body( $c->encoding->encode( $c->res->body, $c->_encode_check ) );
2256
2257         # Set the charset if necessary.  This might be a bit bonkers since encodable response
2258         # is false when the set charset is not the same as the encoding mimetype (maybe
2259         # confusing action at a distance here..
2260         # Don't try to set the charset if one already exists or if headers are already finalized
2261         $c->res->content_type($c->res->content_type . "; charset=" . $c->encoding->mime_name)
2262           unless($c->res->content_type_charset ||
2263                 ($c->res->_context && $c->res->finalized_headers && !$c->res->_has_response_cb));
2264     }
2265 }
2266
2267 =head2 $c->finalize_output
2268
2269 An alias for finalize_body.
2270
2271 =head2 $c->finalize_read
2272
2273 Finalizes the input after reading is complete.
2274
2275 =cut
2276
2277 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2278
2279 =head2 $c->finalize_uploads
2280
2281 Finalizes uploads. Cleans up any temporary files.
2282
2283 =cut
2284
2285 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2286
2287 =head2 $c->get_action( $action, $namespace )
2288
2289 Gets an action in a given namespace.
2290
2291 =cut
2292
2293 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2294
2295 =head2 $c->get_actions( $action, $namespace )
2296
2297 Gets all actions of a given name in a namespace and all parent
2298 namespaces.
2299
2300 =cut
2301
2302 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2303
2304 =head2 $app->handle_request( @arguments )
2305
2306 Called to handle each HTTP request.
2307
2308 =cut
2309
2310 sub handle_request {
2311     my ( $class, @arguments ) = @_;
2312
2313     # Always expect worst case!
2314     my $status = -1;
2315     try {
2316         if ($class->debug) {
2317             my $secs = time - $START || 1;
2318             my $av = sprintf '%.3f', $COUNT / $secs;
2319             my $time = localtime time;
2320             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2321         }
2322
2323         my $c = $class->prepare(@arguments);
2324         $c->dispatch;
2325         $status = $c->finalize;
2326     } catch {
2327         #rethow if this can be handled by middleware
2328         if ( $class->_handle_http_exception($_) ) {
2329             $_->can('rethrow') ? $_->rethrow : croak $_;
2330         }
2331         chomp(my $error = $_);
2332         $class->log->error(qq/Caught exception in engine "$error"/);
2333     };
2334
2335     $COUNT++;
2336
2337     if(my $coderef = $class->log->can('_flush')){
2338         $class->log->$coderef();
2339     }
2340     return $status;
2341 }
2342
2343 =head2 $class->prepare( @arguments )
2344
2345 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2346 etc.).
2347
2348 =cut
2349
2350 has _uploadtmp => (
2351     is => 'ro',
2352     predicate => '_has_uploadtmp',
2353 );
2354
2355 sub prepare {
2356     my ( $class, @arguments ) = @_;
2357
2358     # XXX
2359     # After the app/ctxt split, this should become an attribute based on something passed
2360     # into the application.
2361     $class->context_class( ref $class || $class ) unless $class->context_class;
2362
2363     my $uploadtmp = $class->config->{uploadtmp};
2364     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2365
2366     $c->response->_context($c);
2367
2368     $c->stats($class->stats_class->new)->enable($c->use_stats);
2369
2370     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2371         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2372     }
2373
2374     try {
2375         # Allow engine to direct the prepare flow (for POE)
2376         if ( my $prepare = $c->engine->can('prepare') ) {
2377             $c->engine->$prepare( $c, @arguments );
2378         }
2379         else {
2380             $c->prepare_request(@arguments);
2381             $c->prepare_connection;
2382             $c->prepare_query_parameters;
2383             $c->prepare_headers; # Just hooks, no longer needed - they just
2384             $c->prepare_cookies; # cause the lazy attribute on req to build
2385             $c->prepare_path;
2386
2387             # Prepare the body for reading, either by prepare_body
2388             # or the user, if they are using $c->read
2389             $c->prepare_read;
2390
2391             # Parse the body unless the user wants it on-demand
2392             unless ( ref($c)->config->{parse_on_demand} ) {
2393                 $c->prepare_body;
2394             }
2395         }
2396         $c->prepare_action;
2397     }
2398     # VERY ugly and probably shouldn't rely on ->finalize actually working
2399     catch {
2400         # failed prepare is always due to an invalid request, right?
2401         $c->response->status(400);
2402         $c->response->content_type('text/plain');
2403         $c->response->body('Bad Request');
2404         # Note we call finalize and then die here, which escapes
2405         # finalize being called in the enclosing block..
2406         # It in fact couldn't be called, as we don't return $c..
2407         # This is a mess - but I'm unsure you can fix this without
2408         # breaking compat for people doing crazy things (we should set
2409         # the 400 and just return the ctx here IMO, letting finalize get called
2410         # above...
2411         $c->finalize;
2412         die $_;
2413     };
2414
2415     $c->log_request;
2416
2417     return $c;
2418 }
2419
2420 =head2 $c->prepare_action
2421
2422 Prepares action. See L<Catalyst::Dispatcher>.
2423
2424 =cut
2425
2426 sub prepare_action {
2427     my $c = shift;
2428     my $ret = $c->dispatcher->prepare_action( $c, @_);
2429
2430     if($c->encoding) {
2431         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2432           $_ = $c->_handle_param_unicode_decoding($_);
2433         }
2434     }
2435
2436     return $ret;
2437 }
2438
2439
2440 =head2 $c->prepare_body
2441
2442 Prepares message body.
2443
2444 =cut
2445
2446 sub prepare_body {
2447     my $c = shift;
2448
2449     return if $c->request->_has_body;
2450
2451     # Initialize on-demand data
2452     $c->engine->prepare_body( $c, @_ );
2453     $c->prepare_parameters;
2454     $c->prepare_uploads;
2455 }
2456
2457 =head2 $c->prepare_body_chunk( $chunk )
2458
2459 Prepares a chunk of data before sending it to L<HTTP::Body>.
2460
2461 See L<Catalyst::Engine>.
2462
2463 =cut
2464
2465 sub prepare_body_chunk {
2466     my $c = shift;
2467     $c->engine->prepare_body_chunk( $c, @_ );
2468 }
2469
2470 =head2 $c->prepare_body_parameters
2471
2472 Prepares body parameters.
2473
2474 =cut
2475
2476 sub prepare_body_parameters {
2477     my $c = shift;
2478     $c->request->prepare_body_parameters( $c, @_ );
2479 }
2480
2481 =head2 $c->prepare_connection
2482
2483 Prepares connection.
2484
2485 =cut
2486
2487 sub prepare_connection {
2488     my $c = shift;
2489     $c->request->prepare_connection($c);
2490 }
2491
2492 =head2 $c->prepare_cookies
2493
2494 Prepares cookies by ensuring that the attribute on the request
2495 object has been built.
2496
2497 =cut
2498
2499 sub prepare_cookies { my $c = shift; $c->request->cookies }
2500
2501 =head2 $c->prepare_headers
2502
2503 Prepares request headers by ensuring that the attribute on the request
2504 object has been built.
2505
2506 =cut
2507
2508 sub prepare_headers { my $c = shift; $c->request->headers }
2509
2510 =head2 $c->prepare_parameters
2511
2512 Prepares parameters.
2513
2514 =cut
2515
2516 sub prepare_parameters {
2517     my $c = shift;
2518     $c->prepare_body_parameters;
2519     $c->engine->prepare_parameters( $c, @_ );
2520 }
2521
2522 =head2 $c->prepare_path
2523
2524 Prepares path and base.
2525
2526 =cut
2527
2528 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2529
2530 =head2 $c->prepare_query_parameters
2531
2532 Prepares query parameters.
2533
2534 =cut
2535
2536 sub prepare_query_parameters {
2537     my $c = shift;
2538
2539     $c->engine->prepare_query_parameters( $c, @_ );
2540 }
2541
2542 =head2 $c->log_request
2543
2544 Writes information about the request to the debug logs.  This includes:
2545
2546 =over 4
2547
2548 =item * Request method, path, and remote IP address
2549
2550 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2551
2552 =item * Request parameters
2553
2554 =item * File uploads
2555
2556 =back
2557
2558 =cut
2559
2560 sub log_request {
2561     my $c = shift;
2562
2563     return unless $c->debug;
2564
2565     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2566     my $request = $dump->[1];
2567
2568     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2569     $method ||= '';
2570     $path = '/' unless length $path;
2571     $address ||= '';
2572
2573     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2574     $path = decode_utf8($path);
2575
2576     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2577
2578     $c->log_request_headers($request->headers);
2579
2580     if ( my $keywords = $request->query_keywords ) {
2581         $c->log->debug("Query keywords are: $keywords");
2582     }
2583
2584     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2585
2586     $c->log_request_uploads($request);
2587 }
2588
2589 =head2 $c->log_response
2590
2591 Writes information about the response to the debug logs by calling
2592 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2593
2594 =cut
2595
2596 sub log_response {
2597     my $c = shift;
2598
2599     return unless $c->debug;
2600
2601     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2602     my $response = $dump->[1];
2603
2604     $c->log_response_status_line($response);
2605     $c->log_response_headers($response->headers);
2606 }
2607
2608 =head2 $c->log_response_status_line($response)
2609
2610 Writes one line of information about the response to the debug logs.  This includes:
2611
2612 =over 4
2613
2614 =item * Response status code
2615
2616 =item * Content-Type header (if present)
2617
2618 =item * Content-Length header (if present)
2619
2620 =back
2621
2622 =cut
2623
2624 sub log_response_status_line {
2625     my ($c, $response) = @_;
2626
2627     $c->log->debug(
2628         sprintf(
2629             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2630             $response->status                            || 'unknown',
2631             $response->headers->header('Content-Type')   || 'unknown',
2632             $response->headers->header('Content-Length') || 'unknown'
2633         )
2634     );
2635 }
2636
2637 =head2 $c->log_response_headers($headers);
2638
2639 Hook method which can be wrapped by plugins to log the response headers.
2640 No-op in the default implementation.
2641
2642 =cut
2643
2644 sub log_response_headers {}
2645
2646 =head2 $c->log_request_parameters( query => {}, body => {} )
2647
2648 Logs request parameters to debug logs
2649
2650 =cut
2651
2652 sub log_request_parameters {
2653     my $c          = shift;
2654     my %all_params = @_;
2655
2656     return unless $c->debug;
2657
2658     my $column_width = Catalyst::Utils::term_width() - 44;
2659     foreach my $type (qw(query body)) {
2660         my $params = $all_params{$type};
2661         next if ! keys %$params;
2662         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2663         for my $key ( sort keys %$params ) {
2664             my $param = $params->{$key};
2665             my $value = defined($param) ? $param : '';
2666             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2667         }
2668         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2669     }
2670 }
2671
2672 =head2 $c->log_request_uploads
2673
2674 Logs file uploads included in the request to the debug logs.
2675 The parameter name, filename, file type, and file size are all included in
2676 the debug logs.
2677
2678 =cut
2679
2680 sub log_request_uploads {
2681     my $c = shift;
2682     my $request = shift;
2683     return unless $c->debug;
2684     my $uploads = $request->uploads;
2685     if ( keys %$uploads ) {
2686         my $t = Text::SimpleTable->new(
2687             [ 12, 'Parameter' ],
2688             [ 26, 'Filename' ],
2689             [ 18, 'Type' ],
2690             [ 9,  'Size' ]
2691         );
2692         for my $key ( sort keys %$uploads ) {
2693             my $upload = $uploads->{$key};
2694             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2695                 $t->row( $key, $u->filename, $u->type, $u->size );
2696             }
2697         }
2698         $c->log->debug( "File Uploads are:\n" . $t->draw );
2699     }
2700 }
2701
2702 =head2 $c->log_request_headers($headers);
2703
2704 Hook method which can be wrapped by plugins to log the request headers.
2705 No-op in the default implementation.
2706
2707 =cut
2708
2709 sub log_request_headers {}
2710
2711 =head2 $c->log_headers($type => $headers)
2712
2713 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2714
2715 =cut
2716
2717 sub log_headers {
2718     my $c       = shift;
2719     my $type    = shift;
2720     my $headers = shift;    # an HTTP::Headers instance
2721
2722     return unless $c->debug;
2723
2724     my $column_width = Catalyst::Utils::term_width() - 28;
2725     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2726     $headers->scan(
2727         sub {
2728             my ( $name, $value ) = @_;
2729             $t->row( $name, $value );
2730         }
2731     );
2732     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2733 }
2734
2735
2736 =head2 $c->prepare_read
2737
2738 Prepares the input for reading.
2739
2740 =cut
2741
2742 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2743
2744 =head2 $c->prepare_request
2745
2746 Prepares the engine request.
2747
2748 =cut
2749
2750 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2751
2752 =head2 $c->prepare_uploads
2753
2754 Prepares uploads.
2755
2756 =cut
2757
2758 sub prepare_uploads {
2759     my $c = shift;
2760     $c->engine->prepare_uploads( $c, @_ );
2761 }
2762
2763 =head2 $c->prepare_write
2764
2765 Prepares the output for writing.
2766
2767 =cut
2768
2769 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2770
2771 =head2 $c->request_class
2772
2773 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2774
2775 =head2 $app->request_class_traits
2776
2777 An arrayref of L<Moose::Role>s which are applied to the request class.  You can
2778 name the full namespace of the role, or a namespace suffix, which will then
2779 be tried against the following standard namespace prefixes.
2780
2781     $MyApp::TraitFor::Request::$trait_suffix
2782     Catalyst::TraitFor::Request::$trait_suffix
2783
2784 So for example if you set:
2785
2786     MyApp->request_class_traits(['Foo']);
2787
2788 We try each possible role in turn (and throw an error if none load)
2789
2790     Foo
2791     MyApp::TraitFor::Request::Foo
2792     Catalyst::TraitFor::Request::Foo
2793
2794 The namespace part 'TraitFor::Request' was choosen to assist in backwards
2795 compatibility with L<CatalystX::RoleApplicator> which previously provided
2796 these features in a stand alone package.
2797
2798 =head2 $app->composed_request_class
2799
2800 This is the request class which has been composed with any request_class_traits.
2801
2802 =head2 $c->response_class
2803
2804 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2805
2806 =head2 $app->response_class_traits
2807
2808 An arrayref of L<Moose::Role>s which are applied to the response class.  You can
2809 name the full namespace of the role, or a namespace suffix, which will then
2810 be tried against the following standard namespace prefixes.
2811
2812     $MyApp::TraitFor::Response::$trait_suffix
2813     Catalyst::TraitFor::Response::$trait_suffix
2814
2815 So for example if you set:
2816
2817     MyApp->response_class_traits(['Foo']);
2818
2819 We try each possible role in turn (and throw an error if none load)
2820
2821     Foo
2822     MyApp::TraitFor::Response::Foo
2823     Catalyst::TraitFor::Responset::Foo
2824
2825 The namespace part 'TraitFor::Response' was choosen to assist in backwards
2826 compatibility with L<CatalystX::RoleApplicator> which previously provided
2827 these features in a stand alone package.
2828
2829
2830 =head2 $app->composed_response_class
2831
2832 This is the request class which has been composed with any response_class_traits.
2833
2834 =head2 $c->read( [$maxlength] )
2835
2836 Reads a chunk of data from the request body. This method is designed to
2837 be used in a while loop, reading C<$maxlength> bytes on every call.
2838 C<$maxlength> defaults to the size of the request if not specified.
2839
2840 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2841 directly.
2842
2843 Warning: If you use read(), Catalyst will not process the body,
2844 so you will not be able to access POST parameters or file uploads via
2845 $c->request.  You must handle all body parsing yourself.
2846
2847 =cut
2848
2849 sub read { my $c = shift; return $c->request->read( @_ ) }
2850
2851 =head2 $c->run
2852
2853 Starts the engine.
2854
2855 =cut
2856
2857 sub run {
2858   my $app = shift;
2859   $app->_make_immutable_if_needed;
2860   $app->engine_loader->needs_psgi_engine_compat_hack ?
2861     $app->engine->run($app, @_) :
2862       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2863 }
2864
2865 sub _make_immutable_if_needed {
2866     my $class = shift;
2867     my $meta = find_meta($class);
2868     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2869     if (
2870         $meta->is_immutable
2871         && ! { $meta->immutable_options }->{replace_constructor}
2872         && $isa_ca
2873     ) {
2874         warn("You made your application class ($class) immutable, "
2875             . "but did not inline the\nconstructor. "
2876             . "This will break catalyst, as your app \@ISA "
2877             . "Class::Accessor(::Fast)?\nPlease pass "
2878             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2879     }
2880     unless ($meta->is_immutable) {
2881         # XXX - FIXME warning here as you should make your app immutable yourself.
2882         $meta->make_immutable(
2883             replace_constructor => 1,
2884         );
2885     }
2886 }
2887
2888 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2889
2890 Sets an action in a given namespace.
2891
2892 =cut
2893
2894 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2895
2896 =head2 $c->setup_actions($component)
2897
2898 Sets up actions for a component.
2899
2900 =cut
2901
2902 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2903
2904 =head2 $c->setup_components
2905
2906 This method is called internally to set up the application's components.
2907
2908 It finds modules by calling the L<locate_components> method, expands them to
2909 package names with the L<expand_component_module> method, and then installs
2910 each component into the application.
2911
2912 The C<setup_components> config option is passed to both of the above methods.
2913
2914 Installation of each component is performed by the L<setup_component> method,
2915 below.
2916
2917 =cut
2918
2919 sub setup_components {
2920     my $class = shift;
2921
2922     my $config  = $class->config->{ setup_components };
2923
2924     my @comps = $class->locate_components($config);
2925     my %comps = map { $_ => 1 } @comps;
2926
2927     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2928     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2929         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2930     ) if $deprecatedcatalyst_component_names;
2931
2932     for my $component ( @comps ) {
2933
2934         # We pass ignore_loaded here so that overlay files for (e.g.)
2935         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2936         # we know M::P::O found a file on disk so this is safe
2937
2938         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2939     }
2940
2941     for my $component (@comps) {
2942         my $instance = $class->components->{ $component } = $class->delayed_setup_component($component);
2943     }
2944
2945     # Inject a component or wrap a stand alone class in an adaptor. This makes a list
2946     # of named components in the configuration that are not actually existing (not a
2947     # real file).
2948
2949     my @injected = $class->setup_injected_components;
2950
2951     # All components are registered, now we need to 'init' them.
2952     foreach my $component_name (@comps, @injected) {
2953       $class->components->{$component_name} = $class->components->{$component_name}->() if
2954         (ref($class->components->{$component_name}) || '') eq 'CODE';
2955     }
2956 }
2957
2958 =head2 $app->setup_injected_components
2959
2960 Called by setup_compoents to setup components that are injected.
2961
2962 =cut
2963
2964 sub setup_injected_components {
2965     my ($class) = @_;
2966     my @injected_components = keys %{$class->config->{inject_components} ||+{}};
2967
2968     foreach my $injected_comp_name(@injected_components) {
2969         $class->setup_injected_component(
2970           $injected_comp_name,
2971           $class->config->{inject_components}->{$injected_comp_name});
2972     }
2973
2974     return map { $class ."::" . $_ }
2975       @injected_components;
2976 }
2977
2978 =head2 $app->setup_injected_component( $injected_component_name, $config )
2979
2980 Setup a given injected component.
2981
2982 =cut
2983
2984 sub setup_injected_component {
2985     my ($class, $injected_comp_name, $config) = @_;
2986     if(my $component_class = $config->{from_component}) {
2987         my @roles = @{$config->{roles} ||[]};
2988         Catalyst::Utils::inject_component(
2989           into => $class,
2990           component => $component_class,
2991           (scalar(@roles) ? (traits => \@roles) : ()),
2992           as => $injected_comp_name);
2993     }
2994 }
2995
2996 =head2 $app->inject_component($MyApp_Component_name => \%args);
2997
2998 Add a component that is injected at setup:
2999
3000     MyApp->inject_component( 'Model::Foo' => { from_component => 'Common::Foo' } );
3001
3002 Must be called before ->setup.  Expects a component name for your
3003 current application and \%args where
3004
3005 =over 4
3006
3007 =item from_component
3008
3009 The target component being injected into your application
3010
3011 =item roles
3012
3013 An arrayref of L<Moose::Role>s that are applied to your component.
3014
3015 =back
3016
3017 Example
3018
3019     MyApp->inject_component(
3020       'Model::Foo' => {
3021         from_component => 'Common::Model::Foo',
3022         roles => ['Role1', 'Role2'],
3023       });
3024
3025 =head2 $app->inject_components
3026
3027 Inject a list of components:
3028
3029     MyApp->inject_components(
3030       'Model::FooOne' => {
3031         from_component => 'Common::Model::Foo',
3032         roles => ['Role1', 'Role2'],
3033       },
3034       'Model::FooTwo' => {
3035         from_component => 'Common::Model::Foo',
3036         roles => ['Role1', 'Role2'],
3037       });
3038
3039 =cut
3040
3041 sub inject_component {
3042   my ($app, $name, $args) = @_;
3043   die "Component $name exists" if
3044     $app->config->{inject_components}->{$name};
3045   $app->config->{inject_components}->{$name} = $args;
3046 }
3047
3048 sub inject_components {
3049   my $app = shift;
3050   while(@_) {
3051     $app->inject_component(shift, shift);
3052   }
3053 }
3054
3055 =head2 $c->locate_components( $setup_component_config )
3056
3057 This method is meant to provide a list of component modules that should be
3058 setup for the application.  By default, it will use L<Module::Pluggable>.
3059
3060 Specify a C<setup_components> config option to pass additional options directly
3061 to L<Module::Pluggable>. To add additional search paths, specify a key named
3062 C<search_extra> as an array reference. Items in the array beginning with C<::>
3063 will have the application class name prepended to them.
3064
3065 =cut
3066
3067 sub locate_components {
3068     my $class  = shift;
3069     my $config = shift;
3070
3071     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
3072     my $extra   = delete $config->{ search_extra } || [];
3073
3074     unshift @paths, @$extra;
3075
3076     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
3077       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
3078       %$config
3079     )->plugins } @paths;
3080
3081     return @comps;
3082 }
3083
3084 =head2 $c->expand_component_module( $component, $setup_component_config )
3085
3086 Components found by C<locate_components> will be passed to this method, which
3087 is expected to return a list of component (package) names to be set up.
3088
3089 =cut
3090
3091 sub expand_component_module {
3092     my ($class, $module) = @_;
3093     return Devel::InnerPackage::list_packages( $module );
3094 }
3095
3096 =head2 $app->delayed_setup_component
3097
3098 Returns a coderef that points to a setup_component instance.  Used
3099 internally for when you want to delay setup until the first time
3100 the component is called.
3101
3102 =cut
3103
3104 sub delayed_setup_component {
3105   my($class, $component, @more) = @_;
3106   return sub {
3107     return my $instance = $class->setup_component($component, @more);
3108   };
3109 }
3110
3111 =head2 $c->setup_component
3112
3113 =cut
3114
3115 sub setup_component {
3116     my( $class, $component ) = @_;
3117
3118     unless ( $component->can( 'COMPONENT' ) ) {
3119         return $component;
3120     }
3121
3122     my $config = $class->config_for($component);
3123     # Stash catalyst_component_name in the config here, so that custom COMPONENT
3124     # methods also pass it. local to avoid pointlessly shitting in config
3125     # for the debug screen, as $component is already the key name.
3126     local $config->{catalyst_component_name} = $component;
3127
3128     my $instance = eval {
3129       $component->COMPONENT( $class, $config );
3130     } || do {
3131       my $error = $@;
3132       chomp $error;
3133       Catalyst::Exception->throw(
3134         message => qq/Couldn't instantiate component "$component", "$error"/
3135       );
3136     };
3137
3138     unless (blessed $instance) {
3139         my $metaclass = Moose::Util::find_meta($component);
3140         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
3141         my $component_method_from = $method_meta->associated_metaclass->name;
3142         my $value = defined($instance) ? $instance : 'undef';
3143         Catalyst::Exception->throw(
3144             message =>
3145             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
3146         );
3147     }
3148
3149     my @expanded_components = $instance->can('expand_modules')
3150       ? $instance->expand_modules( $component, $config )
3151       : $class->expand_component_module( $component, $config );
3152     for my $component (@expanded_components) {
3153       next if $class->components->{ $component };
3154       $class->components->{ $component } = $class->setup_component($component);
3155     }
3156
3157     return $instance;
3158 }
3159
3160 =head2 $app->config_for( $component_name )
3161
3162 Return the application level configuration (which is not yet merged with any
3163 local component configuration, via $component_class->config) for the named
3164 component or component object. Example:
3165
3166     MyApp->config(
3167       'Model::Foo' => { a => 1, b => 2},
3168     );
3169
3170     my $config = MyApp->config_for('MyApp::Model::Foo');
3171
3172 In this case $config is the hashref C< {a=>1, b=>2} >.
3173
3174 This is also handy for looking up configuration for a plugin, to make sure you follow
3175 existing L<Catalyst> standards for where a plugin should put its configuration.
3176
3177 =cut
3178
3179 sub config_for {
3180     my ($class, $component_name) = @_;
3181     my $component_suffix = Catalyst::Utils::class2classsuffix($component_name);
3182     my $config = $class->config->{ $component_suffix } || {};
3183
3184     return $config;
3185 }
3186
3187 =head2 $c->setup_dispatcher
3188
3189 Sets up dispatcher.
3190
3191 =cut
3192
3193 sub setup_dispatcher {
3194     my ( $class, $dispatcher ) = @_;
3195
3196     if ($dispatcher) {
3197         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
3198     }
3199
3200     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
3201         $dispatcher = 'Catalyst::Dispatcher::' . $env;
3202     }
3203
3204     unless ($dispatcher) {
3205         $dispatcher = $class->dispatcher_class;
3206     }
3207
3208     load_class($dispatcher);
3209
3210     # dispatcher instance
3211     $class->dispatcher( $dispatcher->new );
3212 }
3213
3214 =head2 $c->setup_engine
3215
3216 Sets up engine.
3217
3218 =cut
3219
3220 sub engine_class {
3221     my ($class, $requested_engine) = @_;
3222
3223     if (!$class->engine_loader || $requested_engine) {
3224         $class->engine_loader(
3225             Catalyst::EngineLoader->new({
3226                 application_name => $class,
3227                 (defined $requested_engine
3228                      ? (catalyst_engine_class => $requested_engine) : ()),
3229             }),
3230         );
3231     }
3232
3233     $class->engine_loader->catalyst_engine_class;
3234 }
3235
3236 sub setup_engine {
3237     my ($class, $requested_engine) = @_;
3238
3239     my $engine = do {
3240         my $loader = $class->engine_loader;
3241
3242         if (!$loader || $requested_engine) {
3243             $loader = Catalyst::EngineLoader->new({
3244                 application_name => $class,
3245                 (defined $requested_engine
3246                      ? (requested_engine => $requested_engine) : ()),
3247             }),
3248
3249             $class->engine_loader($loader);
3250         }
3251
3252         $loader->catalyst_engine_class;
3253     };
3254
3255     # Don't really setup_engine -- see _setup_psgi_app for explanation.
3256     return if $class->loading_psgi_file;
3257
3258     load_class($engine);
3259
3260     if ($ENV{MOD_PERL}) {
3261         my $apache = $class->engine_loader->auto;
3262
3263         my $meta = find_meta($class);
3264         my $was_immutable = $meta->is_immutable;
3265         my %immutable_options = $meta->immutable_options;
3266         $meta->make_mutable if $was_immutable;
3267
3268         $meta->add_method(handler => sub {
3269             my $r = shift;
3270             my $psgi_app = $class->_finalized_psgi_app;
3271             $apache->call_app($r, $psgi_app);
3272         });
3273
3274         $meta->make_immutable(%immutable_options) if $was_immutable;
3275     }
3276
3277     $class->engine( $engine->new );
3278
3279     return;
3280 }
3281
3282 ## This exists just to supply a prebuild psgi app for mod_perl and for the
3283 ## build in server support (back compat support for pre psgi port behavior).
3284 ## This is so that we don't build a new psgi app for each request when using
3285 ## the mod_perl handler or the built in servers (http and fcgi, etc).
3286
3287 sub _finalized_psgi_app {
3288     my ($app) = @_;
3289
3290     unless ($app->_psgi_app) {
3291         my $psgi_app = $app->_setup_psgi_app;
3292         $app->_psgi_app($psgi_app);
3293     }
3294
3295     return $app->_psgi_app;
3296 }
3297
3298 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
3299 ## home directory and load that and return it (just assume it is doing the
3300 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
3301 ## in default_middleware and return it ( this is for backward compatibility
3302 ## with pre psgi port behavior ).
3303
3304 sub _setup_psgi_app {
3305     my ($app) = @_;
3306
3307     for my $home (Path::Class::Dir->new($app->config->{home})) {
3308         my $psgi_file = $home->file(
3309             Catalyst::Utils::appprefix($app) . '.psgi',
3310         );
3311
3312         next unless -e $psgi_file;
3313
3314         # If $psgi_file calls ->setup_engine, it's doing so to load
3315         # Catalyst::Engine::PSGI. But if it does that, we're only going to
3316         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
3317         # anyway. So set a flag (ick) that tells setup_engine not to populate
3318         # $c->engine or do any other things we might regret.
3319
3320         $app->loading_psgi_file(1);
3321         my $psgi_app = Plack::Util::load_psgi($psgi_file);
3322         $app->loading_psgi_file(0);
3323
3324         return $psgi_app
3325             unless $app->engine_loader->needs_psgi_engine_compat_hack;
3326
3327         warn <<"EOW";
3328 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
3329
3330 Its content has been ignored. Please consult the Catalyst::Upgrading
3331 documentation on how to upgrade from Catalyst::Engine::PSGI.
3332 EOW
3333     }
3334
3335     return $app->apply_default_middlewares($app->psgi_app);
3336 }
3337
3338 =head2 $c->apply_default_middlewares
3339
3340 Adds the following L<Plack> middlewares to your application, since they are
3341 useful and commonly needed:
3342
3343 L<Plack::Middleware::LighttpdScriptNameFix> (if you are using Lighttpd),
3344 L<Plack::Middleware::IIS6ScriptNameFix> (always applied since this middleware
3345 is smart enough to conditionally apply itself).
3346
3347 We will also automatically add L<Plack::Middleware::ReverseProxy> if we notice
3348 that your HTTP $env variable C<REMOTE_ADDR> is '127.0.0.1'.  This is usually
3349 an indication that your server is running behind a proxy frontend.  However in
3350 2014 this is often not the case.  We preserve this code for backwards compatibility
3351 however I B<highly> recommend that if you are running the server behind a front
3352 end proxy that you clearly indicate so with the C<using_frontend_proxy> configuration
3353 setting to true for your environment configurations that run behind a proxy.  This
3354 way if you change your front end proxy address someday your code would inexplicably
3355 stop working as expected.
3356
3357 Additionally if we detect we are using Nginx, we add a bit of custom middleware
3358 to solve some problems with the way that server handles $ENV{PATH_INFO} and
3359 $ENV{SCRIPT_NAME}.
3360
3361 Please B<NOTE> that if you do use C<using_frontend_proxy> the middleware is now
3362 adding via C<registered_middleware> rather than this method.
3363
3364 If you are using Lighttpd or IIS6 you may wish to apply these middlewares.  In
3365 general this is no longer a common case but we have this here for backward
3366 compatibility.
3367
3368 =cut
3369
3370
3371 sub apply_default_middlewares {
3372     my ($app, $psgi_app) = @_;
3373
3374     # Don't add this conditional IF we are explicitly saying we want the
3375     # frontend proxy support.  We don't need it here since if that is the
3376     # case it will be always loaded in the default_middleware.
3377
3378     unless($app->config->{using_frontend_proxy}) {
3379       $psgi_app = Plack::Middleware::Conditional->wrap(
3380           $psgi_app,
3381           builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
3382           condition => sub {
3383               my ($env) = @_;
3384               return if $app->config->{ignore_frontend_proxy};
3385               return $env->{REMOTE_ADDR} eq '127.0.0.1';
3386           },
3387       );
3388     }
3389
3390     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3391     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3392     $psgi_app = Plack::Middleware::Conditional->wrap(
3393         $psgi_app,
3394         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3395         condition => sub {
3396             my ($env) = @_;
3397             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3398             return unless $1 < 4.23;
3399             1;
3400         },
3401     );
3402
3403     # we're applying this unconditionally as the middleware itself already makes
3404     # sure it doesn't fuck things up if it's not running under one of the right
3405     # IIS versions
3406     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3407
3408     # And another IIS issue, this time with IIS7.
3409     $psgi_app = Plack::Middleware::Conditional->wrap(
3410         $psgi_app,
3411         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3412         condition => sub {
3413             my ($env) = @_;
3414             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3415         },
3416     );
3417
3418     return $psgi_app;
3419 }
3420
3421 =head2 App->psgi_app
3422
3423 =head2 App->to_app
3424
3425 Returns a PSGI application code reference for the catalyst application
3426 C<$c>. This is the bare application created without the C<apply_default_middlewares>
3427 method called.  We do however apply C<registered_middleware> since those are
3428 integral to how L<Catalyst> functions.  Also, unlike starting your application
3429 with a generated server script (via L<Catalyst::Devel> and C<catalyst.pl>) we do
3430 not attempt to return a valid L<PSGI> application using any existing C<${myapp}.psgi>
3431 scripts in your $HOME directory.
3432
3433 B<NOTE> C<apply_default_middlewares> was originally created when the first PSGI
3434 port was done for v5.90000.  These are middlewares that are added to achieve
3435 backward compatibility with older applications.  If you start your application
3436 using one of the supplied server scripts (generated with L<Catalyst::Devel> and
3437 the project skeleton script C<catalyst.pl>) we apply C<apply_default_middlewares>
3438 automatically.  This was done so that pre and post PSGI port applications would
3439 work the same way.
3440
3441 This is what you want to be using to retrieve the PSGI application code
3442 reference of your Catalyst application for use in a custom F<.psgi> or in your
3443 own created server modules.
3444
3445 =cut
3446
3447 *to_app = \&psgi_app;
3448
3449 sub psgi_app {
3450     my ($app) = @_;
3451     my $psgi = $app->engine->build_psgi_app($app);
3452     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3453 }
3454
3455 =head2 $c->setup_home
3456
3457 Sets up the home directory.
3458
3459 =cut
3460
3461 sub setup_home {
3462     my ( $class, $home ) = @_;
3463
3464     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3465         $home = $env;
3466     }
3467
3468     $home ||= Catalyst::Utils::home($class);
3469
3470     if ($home) {
3471         #I remember recently being scolded for assigning config values like this
3472         $class->config->{home} ||= $home;
3473         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3474     }
3475 }
3476
3477 =head2 $c->setup_encoding
3478
3479 Sets up the input/output encoding. See L<ENCODING>
3480
3481 =cut
3482
3483 sub setup_encoding {
3484     my $c = shift;
3485     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3486         # Ok, so the user has explicitly said "I don't want encoding..."
3487         return;
3488     } else {
3489       my $enc = defined($c->config->{encoding}) ?
3490         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3491       $c->encoding($enc);
3492     }
3493 }
3494
3495 =head2 handle_unicode_encoding_exception
3496
3497 Hook to let you customize how encoding errors are handled.  By default
3498 we just throw an exception.  Receives a hashref of debug information.
3499 Example:
3500
3501     $c->handle_unicode_encoding_exception({
3502         param_value => $value,
3503         error_msg => $_,
3504             encoding_step => 'params',
3505         });
3506
3507 =cut
3508
3509 sub handle_unicode_encoding_exception {
3510     my ( $self, $exception_ctx ) = @_;
3511     die $exception_ctx->{error_msg};
3512 }
3513
3514 # Some unicode helpers cargo culted from the old plugin.  These could likely
3515 # be neater.
3516
3517 sub _handle_unicode_decoding {
3518     my ( $self, $value ) = @_;
3519
3520     return unless defined $value;
3521
3522     ## I think this mess is to support the old nested
3523     if ( ref $value eq 'ARRAY' ) {
3524         foreach ( @$value ) {
3525             $_ = $self->_handle_unicode_decoding($_);
3526         }
3527         return $value;
3528     }
3529     elsif ( ref $value eq 'HASH' ) {
3530         foreach (keys %$value) {
3531             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3532             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3533
3534             # If the key was encoded we now have two (the original and current so
3535             # delete the original.
3536             delete $value->{$_} if $_ ne $encoded_key;
3537         }
3538         return $value;
3539     }
3540     else {
3541         return $self->_handle_param_unicode_decoding($value);
3542     }
3543 }
3544
3545 sub _handle_param_unicode_decoding {
3546     my ( $self, $value ) = @_;
3547     return unless defined $value; # not in love with just ignoring undefs - jnap
3548     return $value if blessed($value); #don't decode when the value is an object.
3549
3550     my $enc = $self->encoding;
3551     return try {
3552       $enc->decode( $value, $self->_encode_check );
3553     }
3554     catch {
3555         $self->handle_unicode_encoding_exception({
3556             param_value => $value,
3557             error_msg => $_,
3558             encoding_step => 'params',
3559         });
3560     };
3561 }
3562
3563 =head2 $c->setup_log
3564
3565 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3566 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3567 log to.
3568
3569 This method also installs a C<debug> method that returns a true value into the
3570 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3571 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3572
3573 Note that if the log has already been setup, by either a previous call to
3574 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3575 that this method won't actually set up the log object.
3576
3577 =cut
3578
3579 sub setup_log {
3580     my ( $class, $levels ) = @_;
3581
3582     $levels ||= '';
3583     $levels =~ s/^\s+//;
3584     $levels =~ s/\s+$//;
3585     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3586
3587     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3588     if ( defined $env_debug ) {
3589         $levels{debug} = 1 if $env_debug; # Ugly!
3590         delete($levels{debug}) unless $env_debug;
3591     }
3592
3593     unless ( $class->log ) {
3594         $class->log( Catalyst::Log->new(keys %levels) );
3595     }
3596
3597     if ( $levels{debug} ) {
3598         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3599         $class->log->debug('Debug messages enabled');
3600     }
3601 }
3602
3603 =head2 $c->setup_plugins
3604
3605 Sets up plugins.
3606
3607 =cut
3608
3609 =head2 $c->setup_stats
3610
3611 Sets up timing statistics class.
3612
3613 =cut
3614
3615 sub setup_stats {
3616     my ( $class, $stats ) = @_;
3617
3618     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3619
3620     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3621     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3622         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3623         $class->log->debug('Statistics enabled');
3624     }
3625 }
3626
3627
3628 =head2 $c->registered_plugins
3629
3630 Returns a sorted list of the plugins which have either been stated in the
3631 import list.
3632
3633 If passed a given plugin name, it will report a boolean value indicating
3634 whether or not that plugin is loaded.  A fully qualified name is required if
3635 the plugin name does not begin with C<Catalyst::Plugin::>.
3636
3637  if ($c->registered_plugins('Some::Plugin')) {
3638      ...
3639  }
3640
3641 =cut
3642
3643 {
3644
3645     sub registered_plugins {
3646         my $proto = shift;
3647         return sort keys %{ $proto->_plugins } unless @_;
3648         my $plugin = shift;
3649         return 1 if exists $proto->_plugins->{$plugin};
3650         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3651     }
3652
3653     sub _register_plugin {
3654         my ( $proto, $plugin, $instant ) = @_;
3655         my $class = ref $proto || $proto;
3656
3657         load_class( $plugin );
3658         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3659             if $plugin->isa( 'Catalyst::Component' );
3660         my $plugin_meta = Moose::Meta::Class->create($plugin);
3661         if (!$plugin_meta->has_method('new')
3662             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3663             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3664         }
3665         if (!$instant && !$proto->_plugins->{$plugin}) {
3666             my $meta = Class::MOP::get_metaclass_by_name($class);
3667             $meta->superclasses($plugin, $meta->superclasses);
3668         }
3669         $proto->_plugins->{$plugin} = 1;
3670         return $class;
3671     }
3672
3673     sub _default_plugins { return qw() }
3674
3675     sub setup_plugins {
3676         my ( $class, $plugins ) = @_;
3677
3678         $class->_plugins( {} ) unless $class->_plugins;
3679         $plugins = [ grep {
3680             m/Unicode::Encoding/ ? do {
3681                 $class->log->warn(
3682                     'Unicode::Encoding plugin is auto-applied,'
3683                     . ' please remove this from your appclass'
3684                     . ' and make sure to define "encoding" config'
3685                 );
3686                 unless (exists $class->config->{'encoding'}) {
3687                   $class->config->{'encoding'} = 'UTF-8';
3688                 }
3689                 () }
3690                 : $_
3691         } @$plugins ];
3692         push @$plugins, $class->_default_plugins;
3693         $plugins = Data::OptList::mkopt($plugins || []);
3694
3695         my @plugins = map {
3696             [ Catalyst::Utils::resolve_namespace(
3697                   $class . '::Plugin',
3698                   'Catalyst::Plugin', $_->[0]
3699               ),
3700               $_->[1],
3701             ]
3702          } @{ $plugins };
3703
3704         for my $plugin ( reverse @plugins ) {
3705             load_class($plugin->[0], $plugin->[1]);
3706             my $meta = find_meta($plugin->[0]);
3707             next if $meta && $meta->isa('Moose::Meta::Role');
3708
3709             $class->_register_plugin($plugin->[0]);
3710         }
3711
3712         my @roles =
3713             map  { $_->[0]->name, $_->[1] }
3714             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3715             map  { [find_meta($_->[0]), $_->[1]] }
3716             @plugins;
3717
3718         Moose::Util::apply_all_roles(
3719             $class => @roles
3720         ) if @roles;
3721     }
3722 }
3723
3724 =head2 default_middleware
3725
3726 Returns a list of instantiated PSGI middleware objects which is the default
3727 middleware that is active for this application (taking any configuration
3728 options into account, excluding your custom added middleware via the C<psgi_middleware>
3729 configuration option).  You can override this method if you wish to change
3730 the default middleware (although do so at risk since some middleware is vital
3731 to application function.)
3732
3733 The current default middleware list is:
3734
3735       Catalyst::Middleware::Stash
3736       Plack::Middleware::HTTPExceptions
3737       Plack::Middleware::RemoveRedundantBody
3738       Plack::Middleware::FixMissingBodyInRedirect
3739       Plack::Middleware::ContentLength
3740       Plack::Middleware::MethodOverride
3741       Plack::Middleware::Head
3742
3743 If the configuration setting C<using_frontend_proxy> is true we add:
3744
3745       Plack::Middleware::ReverseProxy
3746
3747 If the configuration setting C<using_frontend_proxy_path> is true we add:
3748
3749       Plack::Middleware::ReverseProxyPath
3750
3751 But B<NOTE> that L<Plack::Middleware::ReverseProxyPath> is not a dependency of the
3752 L<Catalyst> distribution so if you want to use this option you should add it to
3753 your project distribution file.
3754
3755 These middlewares will be added at L</setup_middleware> during the
3756 L</setup> phase of application startup.
3757
3758 =cut
3759
3760 sub default_middleware {
3761     my $class = shift;
3762     my @mw = (
3763       Catalyst::Middleware::Stash->new,
3764       Plack::Middleware::HTTPExceptions->new,
3765       Plack::Middleware::RemoveRedundantBody->new,
3766       Plack::Middleware::FixMissingBodyInRedirect->new,
3767       Plack::Middleware::ContentLength->new,
3768       Plack::Middleware::MethodOverride->new,
3769       Plack::Middleware::Head->new);
3770
3771     if($class->config->{using_frontend_proxy}) {
3772         push @mw, Plack::Middleware::ReverseProxy->new;
3773     }
3774
3775     if($class->config->{using_frontend_proxy_path}) {
3776         if(Class::Load::try_load_class('Plack::Middleware::ReverseProxyPath')) {
3777             push @mw, Plack::Middleware::ReverseProxyPath->new;
3778         } else {
3779           $class->log->error("Cannot use configuration 'using_frontend_proxy_path' because 'Plack::Middleware::ReverseProxyPath' is not installed");
3780         }
3781     }
3782
3783     return @mw;
3784 }
3785
3786 =head2 registered_middlewares
3787
3788 Read only accessor that returns an array of all the middleware in the order
3789 that they were added (which is the REVERSE of the order they will be applied).
3790
3791 The values returned will be either instances of L<Plack::Middleware> or of a
3792 compatible interface, or a coderef, which is assumed to be inlined middleware
3793
3794 =head2 setup_middleware (?@middleware)
3795
3796 Read configuration information stored in configuration key C<psgi_middleware> or
3797 from passed @args.
3798
3799 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3800 to use it to enable L<Plack::Middleware>
3801
3802 This method is automatically called during 'setup' of your application, so
3803 you really don't need to invoke it.  However you may do so if you find the idea
3804 of loading middleware via configuration weird :).  For example:
3805
3806     package MyApp;
3807
3808     use Catalyst;
3809
3810     __PACKAGE__->setup_middleware('Head');
3811     __PACKAGE__->setup;
3812
3813 When we read middleware definitions from configuration, we reverse the list
3814 which sounds odd but is likely how you expect it to work if you have prior
3815 experience with L<Plack::Builder> or if you previously used the plugin
3816 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3817
3818 So basically your middleware handles an incoming request from the first
3819 registered middleware, down and handles the response from the last middleware
3820 up.
3821
3822 =cut
3823
3824 sub registered_middlewares {
3825     my $class = shift;
3826     if(my $middleware = $class->_psgi_middleware) {
3827         my @mw = ($class->default_middleware, @$middleware);
3828
3829         if($class->config->{using_frontend_proxy}) {
3830           push @mw, Plack::Middleware::ReverseProxy->new;
3831         }
3832
3833         return @mw;
3834     } else {
3835         die "You cannot call ->registered_middlewares until middleware has been setup";
3836     }
3837 }
3838
3839 sub setup_middleware {
3840     my $class = shift;
3841     my @middleware_definitions;
3842
3843     # If someone calls this method you can add middleware with args.  However if its
3844     # called without an arg we need to setup the configuration middleware.
3845     if(@_) {
3846       @middleware_definitions = reverse(@_);
3847     } else {
3848       @middleware_definitions = reverse(@{$class->config->{'psgi_middleware'}||[]})
3849         unless $class->finalized_default_middleware;
3850       $class->finalized_default_middleware(1); # Only do this once, just in case some people call setup over and over...
3851     }
3852
3853     my @middleware = ();
3854     while(my $next = shift(@middleware_definitions)) {
3855         if(ref $next) {
3856             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3857                 push @middleware, $next;
3858             } elsif(ref $next eq 'CODE') {
3859                 push @middleware, $next;
3860             } elsif(ref $next eq 'HASH') {
3861                 my $namespace = shift @middleware_definitions;
3862                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3863                 push @middleware, $mw;
3864             } else {
3865               die "I can't handle middleware definition ${\ref $next}";
3866             }
3867         } else {
3868           my $mw = $class->Catalyst::Utils::build_middleware($next);
3869           push @middleware, $mw;
3870         }
3871     }
3872
3873     my @existing = @{$class->_psgi_middleware || []};
3874     $class->_psgi_middleware([@middleware,@existing,]);
3875 }
3876
3877 =head2 registered_data_handlers
3878
3879 A read only copy of registered Data Handlers returned as a Hash, where each key
3880 is a content type and each value is a subref that attempts to decode that content
3881 type.
3882
3883 =head2 setup_data_handlers (?@data_handler)
3884
3885 Read configuration information stored in configuration key C<data_handlers> or
3886 from passed @args.
3887
3888 See under L</CONFIGURATION> information regarding C<data_handlers>.
3889
3890 This method is automatically called during 'setup' of your application, so
3891 you really don't need to invoke it.
3892
3893 =head2 default_data_handlers
3894
3895 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3896 only two default data handlers, for 'application/json' and an alternative to
3897 'application/x-www-form-urlencoded' which supposed nested form parameters via
3898 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3899
3900 The 'application/json' data handler is used to parse incoming JSON into a Perl
3901 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3902 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3903 JSON decoder, and has the smallest dependency impact.
3904
3905 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3906 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3907 order to get the best performance.  You should add either to your dependency
3908 list (Makefile.PL, dist.ini, cpanfile, etc.)
3909
3910 =cut
3911
3912 sub registered_data_handlers {
3913     my $class = shift;
3914     if(my $data_handlers = $class->_data_handlers) {
3915         return %$data_handlers;
3916     } else {
3917         $class->setup_data_handlers;
3918         return $class->registered_data_handlers;
3919     }
3920 }
3921
3922 sub setup_data_handlers {
3923     my ($class, %data_handler_callbacks) = @_;
3924     %data_handler_callbacks = (
3925       %{$class->default_data_handlers},
3926       %{$class->config->{'data_handlers'}||+{}},
3927       %data_handler_callbacks);
3928
3929     $class->_data_handlers(\%data_handler_callbacks);
3930 }
3931
3932 sub default_data_handlers {
3933     my ($class) = @_;
3934     return +{
3935       'application/x-www-form-urlencoded' => sub {
3936           my ($fh, $req) = @_;
3937           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3938           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3939             ->can('build_cgi_struct')->($params);
3940       },
3941       'application/json' => sub {
3942           my ($fh, $req) = @_;
3943           my $parser = Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON');
3944           my $slurped;
3945           return eval {
3946             local $/;
3947             $slurped = $fh->getline;
3948             $parser->can("decode_json")->($slurped); # decode_json does utf8 decoding for us
3949           } || Catalyst::Exception->throw(sprintf "Error Parsing POST '%s', Error: %s", (defined($slurped) ? $slurped : 'undef') ,$@);
3950         },
3951     };
3952 }
3953
3954 sub _handle_http_exception {
3955     my ( $self, $error ) = @_;
3956     if (
3957            !$self->config->{always_catch_http_exceptions}
3958         && blessed $error
3959         && (
3960             $error->can('as_psgi')
3961             || (   $error->can('code')
3962                 && $error->code =~ m/^[1-5][0-9][0-9]$/ )
3963         )
3964       )
3965     {
3966         return 1;
3967     }
3968 }
3969
3970 =head2 $c->stack
3971
3972 Returns an arrayref of the internal execution stack (actions that are
3973 currently executing).
3974
3975 =head2 $c->stats
3976
3977 Returns the current timing statistics object. By default Catalyst uses
3978 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3979 L<< stats_class|/"$c->stats_class" >>.
3980
3981 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3982 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3983 profile explicitly, although MyApp.pm still won't profile nor output anything
3984 by itself.
3985
3986 =head2 $c->stats_class
3987
3988 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3989
3990 =head2 $app->stats_class_traits
3991
3992 A arrayref of L<Moose::Role>s that are applied to the stats_class before creating it.
3993
3994 =head2 $app->composed_stats_class
3995
3996 this is the stats_class composed with any 'stats_class_traits'.  You can
3997 name the full namespace of the role, or a namespace suffix, which will then
3998 be tried against the following standard namespace prefixes.
3999
4000     $MyApp::TraitFor::Stats::$trait_suffix
4001     Catalyst::TraitFor::Stats::$trait_suffix
4002
4003 So for example if you set:
4004
4005     MyApp->stats_class_traits(['Foo']);
4006
4007 We try each possible role in turn (and throw an error if none load)
4008
4009     Foo
4010     MyApp::TraitFor::Stats::Foo
4011     Catalyst::TraitFor::Stats::Foo
4012
4013 The namespace part 'TraitFor::Stats' was choosen to assist in backwards
4014 compatibility with L<CatalystX::RoleApplicator> which previously provided
4015 these features in a stand alone package.
4016
4017 =head2 $c->use_stats
4018
4019 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
4020
4021 Note that this is a static method, not an accessor and should be overridden
4022 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
4023
4024 =cut
4025
4026 sub use_stats { 0 }
4027
4028
4029 =head2 $c->write( $data )
4030
4031 Writes $data to the output stream. When using this method directly, you
4032 will need to manually set the C<Content-Length> header to the length of
4033 your output data, if known.
4034
4035 =cut
4036
4037 sub write {
4038     my $c = shift;
4039
4040     # Finalize headers if someone manually writes output (for compat)
4041     $c->finalize_headers;
4042
4043     return $c->response->write( @_ );
4044 }
4045
4046 =head2 version
4047
4048 Returns the Catalyst version number. Mostly useful for "powered by"
4049 messages in template systems.
4050
4051 =cut
4052
4053 sub version { return $Catalyst::VERSION }
4054
4055 =head1 CONFIGURATION
4056
4057 There are a number of 'base' config variables which can be set:
4058
4059 =over
4060
4061 =item *
4062
4063 C<always_catch_http_exceptions> - As of version 5.90060 Catalyst
4064 rethrows errors conforming to the interface described by
4065 L<Plack::Middleware::HTTPExceptions> and lets the middleware deal with it.
4066 Set true to get the deprecated behaviour and have Catalyst catch HTTP exceptions.
4067
4068 =item *
4069
4070 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
4071
4072 =item *
4073
4074 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
4075
4076 =item *
4077
4078 C<disable_component_resolution_regex_fallback> - Turns
4079 off the deprecated component resolution functionality so
4080 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
4081 are called then regex search will not be attempted on string values and
4082 instead C<undef> will be returned.
4083
4084 =item *
4085
4086 C<home> - The application home directory. In an uninstalled application,
4087 this is the top level application directory. In an installed application,
4088 this will be the directory containing C<< MyApp.pm >>.
4089
4090 =item *
4091
4092 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
4093
4094 =item *
4095
4096 C<name> - The name of the application in debug messages and the debug and
4097 welcome screens
4098
4099 =item *
4100
4101 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
4102 until it is accessed. This allows you to (for example) check authentication (and reject
4103 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
4104
4105 =item *
4106
4107 C<root> - The root directory for templates. Usually this is just a
4108 subdirectory of the home directory, but you can set it to change the
4109 templates to a different directory.
4110
4111 =item *
4112
4113 C<search_extra> - Array reference passed to Module::Pluggable to for additional
4114 namespaces from which components will be loaded (and constructed and stored in
4115 C<< $c->components >>).
4116
4117 =item *
4118
4119 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
4120 to be shown in hit debug tables in the test server.
4121
4122 =item *
4123
4124 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
4125 variable should be used for determining the request path.
4126
4127 Most web server environments pass the requested path to the application using environment variables,
4128 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
4129 exposed as C<< $c->request->base >>) and the request path below that base.
4130
4131 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
4132 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
4133
4134 =over
4135
4136 =item use_request_uri_for_path => 0
4137
4138 This is the default (and the) traditional method that Catalyst has used for determining the path information.
4139 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
4140 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
4141 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
4142
4143 However this method has the major disadvantage that it is impossible to correctly decode some elements
4144 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
4145 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
4146 can't distinguish / vs %2F in paths (in addition to other encoded values).
4147
4148 =item use_request_uri_for_path => 1
4149
4150 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
4151 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
4152 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
4153
4154 Given that this method of path resolution is provably more correct, it is recommended that you use
4155 this unless you have a specific need to deploy your application in a non-standard environment, and you are
4156 aware of the implications of not being able to handle encoded URI paths correctly.
4157
4158 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
4159 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
4160 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
4161 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
4162 C<< $c->request->base >> will be incorrect.
4163
4164 =back
4165
4166 =item *
4167
4168 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
4169
4170 =item *
4171
4172 C<using_frontend_proxy_path> - Enabled L<Plack::Middleware::ReverseProxyPath> on your application (if
4173 installed, otherwise log an error).  This is useful if your application is not running on the
4174 'root' (or /) of your host server.  B<NOTE> if you use this feature you should add the required
4175 middleware to your project dependency list since its not automatically a dependency of L<Catalyst>.
4176 This has been done since not all people need this feature and we wish to restrict the growth of
4177 L<Catalyst> dependencies.
4178
4179 =item *
4180
4181 C<encoding> - See L</ENCODING>
4182
4183 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
4184 value to undef.
4185
4186 =item *
4187
4188 C<abort_chain_on_error_fix>
4189
4190 When there is an error in an action chain, the default behavior is to continue
4191 processing the remaining actions and then catch the error upon chain end.  This
4192 can lead to running actions when the application is in an unexpected state.  If
4193 you have this issue, setting this config value to true will promptly exit a
4194 chain when there is an error raised in any action (thus terminating the chain
4195 early.)
4196
4197 use like:
4198
4199     __PACKAGE__->config(abort_chain_on_error_fix => 1);
4200
4201 In the future this might become the default behavior.
4202
4203 =item *
4204
4205 C<use_hash_multivalue_in_request>
4206
4207 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
4208 and C<parameters> return a hashref where values might be scalar or an arrayref
4209 depending on the incoming data.  In many cases this can be undesirable as it
4210 leads one to writing defensive code like the following:
4211
4212     my ($val) = ref($c->req->parameters->{a}) ?
4213       @{$c->req->parameters->{a}} :
4214         $c->req->parameters->{a};
4215
4216 Setting this configuration item to true will make L<Catalyst> populate the
4217 attributes underlying these methods with an instance of L<Hash::MultiValue>
4218 which is used by L<Plack::Request> and others to solve this very issue.  You
4219 may prefer this behavior to the default, if so enable this option (be warned
4220 if you enable it in a legacy application we are not sure if it is completely
4221 backwardly compatible).
4222
4223 =item *
4224
4225 C<skip_complex_post_part_handling>
4226
4227 When creating body parameters from a POST, if we run into a multpart POST
4228 that does not contain uploads, but instead contains inlined complex data
4229 (very uncommon) we cannot reliably convert that into field => value pairs.  So
4230 instead we create an instance of L<Catalyst::Request::PartData>.  If this causes
4231 issue for you, you can disable this by setting C<skip_complex_post_part_handling>
4232 to true (default is false).
4233
4234 =item *
4235
4236 C<skip_body_param_unicode_decoding>
4237
4238 Generally we decode incoming POST params based on your declared encoding (the
4239 default for this is to decode UTF-8).  If this is causing you trouble and you
4240 do not wish to turn all encoding support off (with the C<encoding> configuration
4241 parameter) you may disable this step atomically by setting this configuration
4242 parameter to true.
4243
4244 =item *
4245
4246 C<do_not_decode_query>
4247
4248 If true, then do not try to character decode any wide characters in your
4249 request URL query or keywords.  Most readings of the relevent specifications
4250 suggest these should be UTF-* encoded, which is the default that L<Catalyst>
4251 will use, hwoever if you are creating a lot of URLs manually or have external
4252 evil clients, this might cause you trouble.  If you find the changes introduced
4253 in Catalyst version 5.90080+ break some of your query code, you may disable
4254 the UTF-8 decoding globally using this configuration.
4255
4256 This setting takes precedence over C<default_query_encoding> and
4257 C<decode_query_using_global_encoding>
4258
4259 =item *
4260
4261 C<default_query_encoding>
4262
4263 By default we decode query and keywords in your request URL using UTF-8, which
4264 is our reading of the relevent specifications.  This setting allows one to
4265 specify a fixed value for how to decode your query.  You might need this if
4266 you are doing a lot of custom encoding of your URLs and not using UTF-8.
4267
4268 This setting take precedence over C<decode_query_using_global_encoding>.
4269
4270 =item *
4271
4272 C<decode_query_using_global_encoding>
4273
4274 Setting this to true will default your query decoding to whatever your
4275 general global encoding is (the default is UTF-8).
4276
4277 =item *
4278
4279 C<use_chained_args_0_special_case>
4280
4281 In older versions of Catalyst, when more than one action matched the same path
4282 AND all those matching actions declared Args(0), we'd break the tie by choosing
4283 the first action defined.  We now normalized how Args(0) works so that it
4284 follows the same rule as Args(N), which is to say when we need to break a tie
4285 we choose the LAST action defined.  If this breaks your code and you don't
4286 have time to update to follow the new normalized approach, you may set this
4287 value to true and it will globally revert to the original chaining behavior.
4288
4289 =item *
4290
4291 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
4292
4293 =item *
4294
4295 C<data_handlers> - See L<DATA HANDLERS>.
4296
4297 =item *
4298
4299 C<stats_class_traits>
4300
4301 An arrayref of L<Moose::Role>s that get componsed into your stats class.
4302
4303 =item *
4304
4305 C<request_class_traits>
4306
4307 An arrayref of L<Moose::Role>s that get componsed into your request class.
4308
4309 =item *
4310
4311 C<response_class_traits>
4312
4313 An arrayref of L<Moose::Role>s that get componsed into your response class.
4314
4315 =item *
4316
4317 C<inject_components>
4318
4319 A Hashref of L<Catalyst::Component> subclasses that are 'injected' into configuration.
4320 For example:
4321
4322     MyApp->config({
4323       inject_components => {
4324         'Controller::Err' => { from_component => 'Local::Controller::Errors' },
4325         'Model::Zoo' => { from_component => 'Local::Model::Foo' },
4326         'Model::Foo' => { from_component => 'Local::Model::Foo', roles => ['TestRole'] },
4327       },
4328       'Controller::Err' => { a => 100, b=>200, namespace=>'error' },
4329       'Model::Zoo' => { a => 2 },
4330       'Model::Foo' => { a => 100 },
4331     });
4332
4333 Generally L<Catalyst> looks for components in your Model/View or Controller directories.
4334 However for cases when you which to use an existing component and you don't need any
4335 customization (where for when you can apply a role to customize it) you may inject those
4336 components into your application.  Please note any configuration should be done 'in the
4337 normal way', with a key under configuration named after the component affix, as in the
4338 above example.
4339
4340 Using this type of injection allows you to construct significant amounts of your application
4341 with only configuration!.  This may or may not lead to increased code understanding.
4342
4343 Please not you may also call the ->inject_components application method as well, although
4344 you must do so BEFORE setup.
4345
4346 =back
4347
4348 =head1 EXCEPTIONS
4349
4350 Generally when you throw an exception inside an Action (or somewhere in
4351 your stack, such as in a model that an Action is calling) that exception
4352 is caught by Catalyst and unless you either catch it yourself (via eval
4353 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
4354 will eventually reach L</finalize_errors> and return either the debugging
4355 error stack page, or the default error page.  However, if your exception
4356 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
4357 instead rethrow it so that it can be handled by that middleware (which
4358 is part of the default middleware).  For example this would allow
4359
4360     use HTTP::Throwable::Factory 'http_throw';
4361
4362     sub throws_exception :Local {
4363       my ($self, $c) = @_;
4364
4365       http_throw(SeeOther => { location =>
4366         $c->uri_for($self->action_for('redirect')) });
4367
4368     }
4369
4370 =head1 INTERNAL ACTIONS
4371
4372 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
4373 C<_ACTION>, and C<_END>. These are by default not shown in the private
4374 action table, but you can make them visible with a config parameter.
4375
4376     MyApp->config(show_internal_actions => 1);
4377
4378 =head1 ON-DEMAND PARSER
4379
4380 The request body is usually parsed at the beginning of a request,
4381 but if you want to handle input yourself, you can enable on-demand
4382 parsing with a config parameter.
4383
4384     MyApp->config(parse_on_demand => 1);
4385
4386 =head1 PROXY SUPPORT
4387
4388 Many production servers operate using the common double-server approach,
4389 with a lightweight frontend web server passing requests to a larger
4390 backend server. An application running on the backend server must deal
4391 with two problems: the remote user always appears to be C<127.0.0.1> and
4392 the server's hostname will appear to be C<localhost> regardless of the
4393 virtual host that the user connected through.
4394
4395 Catalyst will automatically detect this situation when you are running
4396 the frontend and backend servers on the same machine. The following
4397 changes are made to the request.
4398
4399     $c->req->address is set to the user's real IP address, as read from
4400     the HTTP X-Forwarded-For header.
4401
4402     The host value for $c->req->base and $c->req->uri is set to the real
4403     host, as read from the HTTP X-Forwarded-Host header.
4404
4405 Additionally, you may be running your backend application on an insecure
4406 connection (port 80) while your frontend proxy is running under SSL.  If there
4407 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
4408 tell Catalyst what port the frontend listens on.  This will allow all URIs to
4409 be created properly.
4410
4411 In the case of passing in:
4412
4413     X-Forwarded-Port: 443
4414
4415 All calls to C<uri_for> will result in an https link, as is expected.
4416
4417 Obviously, your web server must support these headers for this to work.
4418
4419 In a more complex server farm environment where you may have your
4420 frontend proxy server(s) on different machines, you will need to set a
4421 configuration option to tell Catalyst to read the proxied data from the
4422 headers.
4423
4424     MyApp->config(using_frontend_proxy => 1);
4425
4426 If you do not wish to use the proxy support at all, you may set:
4427
4428     MyApp->config(ignore_frontend_proxy => 0);
4429
4430 =head2 Note about psgi files
4431
4432 Note that if you supply your own .psgi file, calling
4433 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
4434
4435 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
4436 in your psgi, for example:
4437
4438     builder {
4439         enable "Plack::Middleware::ReverseProxy";
4440         MyApp->psgi_app
4441     };
4442
4443 This will unconditionally add the ReverseProxy support, or you need to call
4444 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
4445 apply the support depending upon your config).
4446
4447 See L<Catalyst::PSGI> for more information.
4448
4449 =head1 THREAD SAFETY
4450
4451 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
4452 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
4453 believe the Catalyst core to be thread-safe.
4454
4455 If you plan to operate in a threaded environment, remember that all other
4456 modules you are using must also be thread-safe. Some modules, most notably
4457 L<DBD::SQLite>, are not thread-safe.
4458
4459 =head1 DATA HANDLERS
4460
4461 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
4462 form parameters and URL search query fields.  However it has become common
4463 for various alternative content types to be PUT or POSTed to your controllers
4464 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
4465 XML and other content types when communicating with an application server.  In
4466 order to better support this use case, L<Catalyst> defines a global configuration
4467 option, C<data_handlers>, which lets you associate a content type with a coderef
4468 that parses that content type into something Perl can readily access.
4469
4470     package MyApp::Web;
4471
4472     use Catalyst;
4473     use JSON::Maybe;
4474
4475     __PACKAGE__->config(
4476       data_handlers => {
4477         'application/json' => sub { local $/; decode_json $_->getline },
4478       },
4479       ## Any other configuration.
4480     );
4481
4482     __PACKAGE__->setup;
4483
4484 By default L<Catalyst> comes with a generic JSON data handler similar to the
4485 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
4486 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
4487 it installed (if you want the faster XS parser, add it to you project Makefile.PL
4488 or dist.ini, cpanfile, etc.)
4489
4490 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
4491 (matched against the incoming request type using a regexp such as to be case
4492 insensitive) and whose values are coderefs that receive a localized version of
4493 C<$_> which is a filehandle object pointing to received body.
4494
4495 This feature is considered an early access release and we reserve the right
4496 to alter the interface in order to provide a performant and secure solution to
4497 alternative request body content.  Your reports welcomed!
4498
4499 =head1 PSGI MIDDLEWARE
4500
4501 You can define middleware, defined as L<Plack::Middleware> or a compatible
4502 interface in configuration.  Your middleware definitions are in the form of an
4503 arrayref under the configuration key C<psgi_middleware>.  Here's an example
4504 with details to follow:
4505
4506     package MyApp::Web;
4507
4508     use Catalyst;
4509     use Plack::Middleware::StackTrace;
4510
4511     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4512
4513     __PACKAGE__->config(
4514       'psgi_middleware', [
4515         'Debug',
4516         '+MyApp::Custom',
4517         $stacktrace_middleware,
4518         'Session' => {store => 'File'},
4519         sub {
4520           my $app = shift;
4521           return sub {
4522             my $env = shift;
4523             $env->{myapp.customkey} = 'helloworld';
4524             $app->($env);
4525           },
4526         },
4527       ],
4528     );
4529
4530     __PACKAGE__->setup;
4531
4532 So the general form is:
4533
4534     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
4535
4536 Where C<@middleware> is one or more of the following, applied in the REVERSE of
4537 the order listed (to make it function similarly to L<Plack::Builder>:
4538
4539 Alternatively, you may also define middleware by calling the L</setup_middleware>
4540 package method:
4541
4542     package MyApp::Web;
4543
4544     use Catalyst;
4545
4546     __PACKAGE__->setup_middleware( \@middleware_definitions);
4547     __PACKAGE__->setup;
4548
4549 In the case where you do both (use 'setup_middleware' and configuration) the
4550 package call to setup_middleware will be applied earlier (in other words its
4551 middleware will wrap closer to the application).  Keep this in mind since in
4552 some cases the order of middleware is important.
4553
4554 The two approaches are not exclusive.
4555
4556 =over 4
4557
4558 =item Middleware Object
4559
4560 An already initialized object that conforms to the L<Plack::Middleware>
4561 specification:
4562
4563     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4564
4565     __PACKAGE__->config(
4566       'psgi_middleware', [
4567         $stacktrace_middleware,
4568       ]);
4569
4570
4571 =item coderef
4572
4573 A coderef that is an inlined middleware:
4574
4575     __PACKAGE__->config(
4576       'psgi_middleware', [
4577         sub {
4578           my $app = shift;
4579           return sub {
4580             my $env = shift;
4581             if($env->{PATH_INFO} =~m/forced/) {
4582               Plack::App::File
4583                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
4584                 ->call($env);
4585             } else {
4586               return $app->($env);
4587             }
4588          },
4589       },
4590     ]);
4591
4592
4593
4594 =item a scalar
4595
4596 We assume the scalar refers to a namespace after normalizing it using the
4597 following rules:
4598
4599 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
4600 is assumed to be 'as is', and we just install and use the middleware.
4601
4602 (2) If the scalar begins with "Plack::Middleware" or your application namespace
4603 (the package name of your Catalyst application subclass), we also assume then
4604 that it is a full namespace, and use it.
4605
4606 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
4607 resolve it first by looking for it under your application namespace (for example
4608 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
4609 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
4610 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
4611 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
4612 namespace first to let you 'override' common L<Plack::Middleware> locally, should
4613 you find that a good idea.
4614
4615 Examples:
4616
4617     package MyApp::Web;
4618
4619     __PACKAGE__->config(
4620       'psgi_middleware', [
4621         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
4622         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
4623         '+MyApp::Custom',  ## MyApp::Custom->wrap
4624       ],
4625     );
4626
4627 =item a scalar followed by a hashref
4628
4629 Just like the previous, except the following C<HashRef> is used as arguments
4630 to initialize the middleware object.
4631
4632     __PACKAGE__->config(
4633       'psgi_middleware', [
4634          'Session' => {store => 'File'},
4635     ]);
4636
4637 =back
4638
4639 Please see L<PSGI> for more on middleware.
4640
4641 =head1 ENCODING
4642
4643 Starting in L<Catalyst> version 5.90080 encoding is automatically enabled
4644 and set to encode all body responses to UTF8 when possible and applicable.
4645 Following is documentation on this process.  If you are using an older
4646 version of L<Catalyst> you should review documentation for that version since
4647 a lot has changed.
4648
4649 By default encoding is now 'UTF-8'.  You may turn it off by setting
4650 the encoding configuration to undef.
4651
4652     MyApp->config(encoding => undef);
4653
4654 This is recommended for temporary backwards compatibility only.
4655
4656 Encoding is automatically applied when the content-type is set to
4657 a type that can be encoded.  Currently we encode when the content type
4658 matches the following regular expression:
4659
4660     $content_type =~ /^text|xml$|javascript$/
4661
4662 Encoding is set on the application, but it is copied to the context object
4663 so that you can override it on a request basis.
4664
4665 Be default we don't automatically encode 'application/json' since the most
4666 common approaches to generating this type of response (Either via L<Catalyst::View::JSON>
4667 or L<Catalyst::Action::REST>) will do so already and we want to avoid double
4668 encoding issues.
4669
4670 If you are producing JSON response in an unconventional manner (such
4671 as via a template or manual strings) you should perform the UTF8 encoding
4672 manually as well such as to conform to the JSON specification.
4673
4674 NOTE: We also examine the value of $c->response->content_encoding.  If
4675 you set this (like for example 'gzip', and manually gzipping the body)
4676 we assume that you have done all the necessary encoding yourself, since
4677 we cannot encode the gzipped contents.  If you use a plugin like
4678 L<Catalyst::Plugin::Compress> you need to update to a modern version in order
4679 to have this function correctly  with the new UTF8 encoding code, or you
4680 can use L<Plack::Middleware::Deflater> or (probably best) do your compression on
4681 a front end proxy.
4682
4683 =head2 Methods
4684
4685 =over 4
4686
4687 =item encoding
4688
4689 Returns an instance of an C<Encode> encoding
4690
4691     print $c->encoding->name
4692
4693 =item handle_unicode_encoding_exception ($exception_context)
4694
4695 Method called when decoding process for a request fails.
4696
4697 An C<$exception_context> hashref is provided to allow you to override the
4698 behaviour of your application when given data with incorrect encodings.
4699
4700 The default method throws exceptions in the case of invalid request parameters
4701 (resulting in a 500 error), but ignores errors in upload filenames.
4702
4703 The keys passed in the C<$exception_context> hash are:
4704
4705 =over
4706
4707 =item param_value
4708
4709 The value which was not able to be decoded.
4710
4711 =item error_msg
4712
4713 The exception received from L<Encode>.
4714
4715 =item encoding_step
4716
4717 What type of data was being decoded. Valid values are (currently)
4718 C<params> - for request parameters / arguments / captures
4719 and C<uploads> - for request upload filenames.
4720
4721 =back
4722
4723 =back
4724
4725 =head1 SUPPORT
4726
4727 IRC:
4728
4729     Join #catalyst on irc.perl.org.
4730
4731 Mailing Lists:
4732
4733     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4734     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4735
4736 Web:
4737
4738     http://catalyst.perl.org
4739
4740 Wiki:
4741
4742     http://dev.catalyst.perl.org
4743
4744 =head1 SEE ALSO
4745
4746 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4747
4748 =head2 L<Catalyst::Manual> - The Catalyst Manual
4749
4750 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4751
4752 =head2 L<Catalyst::Engine> - Core engine
4753
4754 =head2 L<Catalyst::Log> - Log class.
4755
4756 =head2 L<Catalyst::Request> - Request object
4757
4758 =head2 L<Catalyst::Response> - Response object
4759
4760 =head2 L<Catalyst::Test> - The test suite.
4761
4762 =head1 PROJECT FOUNDER
4763
4764 sri: Sebastian Riedel <sri@cpan.org>
4765
4766 =head1 CONTRIBUTORS
4767
4768 abw: Andy Wardley
4769
4770 acme: Leon Brocard <leon@astray.com>
4771
4772 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4773
4774 andrewalker: André Walker <andre@cpan.org>
4775
4776 Andrew Bramble
4777
4778 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4779
4780 Andrew Ruthven
4781
4782 andyg: Andy Grundman <andy@hybridized.org>
4783
4784 audreyt: Audrey Tang
4785
4786 bricas: Brian Cassidy <bricas@cpan.org>
4787
4788 Caelum: Rafael Kitover <rkitover@io.com>
4789
4790 chansen: Christian Hansen
4791
4792 chicks: Christopher Hicks
4793
4794 Chisel Wright C<pause@herlpacker.co.uk>
4795
4796 Danijel Milicevic C<me@danijel.de>
4797
4798 davewood: David Schmidt <davewood@cpan.org>
4799
4800 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4801
4802 David Naughton, C<naughton@umn.edu>
4803
4804 David E. Wheeler
4805
4806 dhoss: Devin Austin <dhoss@cpan.org>
4807
4808 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4809
4810 Drew Taylor
4811
4812 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4813
4814 esskar: Sascha Kiefer
4815
4816 fireartist: Carl Franks <cfranks@cpan.org>
4817
4818 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4819
4820 gabb: Danijel Milicevic
4821
4822 Gary Ashton Jones
4823
4824 Gavin Henry C<ghenry@perl.me.uk>
4825
4826 Geoff Richards
4827
4828 groditi: Guillermo Roditi <groditi@gmail.com>
4829
4830 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4831
4832 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4833
4834 jcamacho: Juan Camacho
4835
4836 jester: Jesse Sheidlower C<jester@panix.com>
4837
4838 jhannah: Jay Hannah <jay@jays.net>
4839
4840 Jody Belka
4841
4842 Johan Lindstrom
4843
4844 jon: Jon Schutz <jjschutz@cpan.org>
4845
4846 Jonathan Rockway C<< <jrockway@cpan.org> >>
4847
4848 Kieren Diment C<kd@totaldatasolution.com>
4849
4850 konobi: Scott McWhirter <konobi@cpan.org>
4851
4852 marcus: Marcus Ramberg <mramberg@cpan.org>
4853
4854 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4855
4856 mgrimes: Mark Grimes <mgrimes@cpan.org>
4857
4858 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4859
4860 mugwump: Sam Vilain
4861
4862 naughton: David Naughton
4863
4864 ningu: David Kamholz <dkamholz@cpan.org>
4865
4866 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4867
4868 numa: Dan Sully <daniel@cpan.org>
4869
4870 obra: Jesse Vincent
4871
4872 Octavian Rasnita
4873
4874 omega: Andreas Marienborg
4875
4876 Oleg Kostyuk <cub.uanic@gmail.com>
4877
4878 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4879
4880 rafl: Florian Ragwitz <rafl@debian.org>
4881
4882 random: Roland Lammel <lammel@cpan.org>
4883
4884 Robert Sedlacek C<< <rs@474.at> >>
4885
4886 SpiceMan: Marcel Montes
4887
4888 sky: Arthur Bergman
4889
4890 szbalint: Balint Szilakszi <szbalint@cpan.org>
4891
4892 t0m: Tomas Doran <bobtfish@bobtfish.net>
4893
4894 Ulf Edvinsson
4895
4896 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4897
4898 Viljo Marrandi C<vilts@yahoo.com>
4899
4900 Will Hawes C<info@whawes.co.uk>
4901
4902 willert: Sebastian Willert <willert@cpan.org>
4903
4904 wreis: Wallace Reis <wreis@cpan.org>
4905
4906 Yuval Kogman, C<nothingmuch@woobling.org>
4907
4908 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4909
4910 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4911
4912 Upasana <me@upasana.me>
4913
4914 John Napiorkowski (jnap) <jjnapiork@cpan.org>
4915
4916 =head1 COPYRIGHT
4917
4918 Copyright (c) 2005-2015, the above named PROJECT FOUNDER and CONTRIBUTORS.
4919
4920 =head1 LICENSE
4921
4922 This library is free software. You can redistribute it and/or modify it under
4923 the same terms as Perl itself.
4924
4925 =cut
4926
4927 no Moose;
4928
4929 __PACKAGE__->meta->make_immutable;
4930
4931 1;