lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54
  55 BEGIN { require 5.008003; }
  56
  57 has stack => (is => 'ro', default => sub { [] });
  58 has state => (is => 'rw', default => 0);
  59 has stats => (is => 'rw');
  60 has action => (is => 'rw');
  61 has counter => (is => 'rw', default => sub { {} });
  62 has request => (
  63     is => 'rw',
  64     default => sub {
  65         my $self = shift;
  66         my $class = ref $self;
  67         my $composed_request_class = $class->composed_request_class;
  68         return $composed_request_class->new( $self->_build_request_constructor_args);
  69     },
  70     lazy => 1,
  71 );
  72 sub _build_request_constructor_args {
  73     my $self = shift;
  74     my %p = ( _log => $self->log );
  75     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  76     $p{data_handlers} = {$self->registered_data_handlers};
  77     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  78       if $self->config->{use_hash_multivalue_in_request};
  79     \%p;
  80 }
  81
  82 sub composed_request_class {
  83   my $class = shift;
  84   my @traits = (@{$class->request_class_traits||[]}, @{$class->config->{request_class_traits}||[]});
  85
  86   # For each trait listed, figure out what the namespace is.  First we try the $trait
  87   # as it is in the config.  Then try $MyApp::TraitFor::Request:$trait. Last we try
  88   # Catalyst::TraitFor::Request::$trait.  If none load, throw error.
  89
  90   my $trait_ns = 'TraitFor::Request';
  91   my @normalized_traits = map {
  92     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
  93   } @traits;
  94
  95   return $class->_composed_request_class ||
  96     $class->_composed_request_class(Moose::Util::with_traits($class->request_class, @normalized_traits));
  97 }
  98
  99 has response => (
 100     is => 'rw',
 101     default => sub {
 102         my $self = shift;
 103         my $class = ref $self;
 104         my $composed_response_class = $class->composed_response_class;
 105         return $composed_response_class->new( $self->_build_response_constructor_args);
 106     },
 107     lazy => 1,
 108 );
 109 sub _build_response_constructor_args {
 110     return +{
 111       _log => $_[0]->log,
 112       encoding => $_[0]->encoding,
 113     };
 114 }
 115
 116 sub composed_response_class {
 117   my $class = shift;
 118   my @traits = (@{$class->response_class_traits||[]}, @{$class->config->{response_class_traits}||[]});
 119
 120   my $trait_ns = 'TraitFor::Response';
 121   my @normalized_traits = map {
 122     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
 123   } @traits;
 124
 125   return $class->_composed_response_class ||
 126     $class->_composed_response_class(Moose::Util::with_traits($class->response_class, @normalized_traits));
 127 }
 128
 129 has namespace => (is => 'rw');
 130
 131 sub depth { scalar @{ shift->stack || [] }; }
 132 sub comp { shift->component(@_) }
 133
 134 sub req {
 135     my $self = shift; return $self->request(@_);
 136 }
 137 sub res {
 138     my $self = shift; return $self->response(@_);
 139 }
 140
 141 # For backwards compatibility
 142 sub finalize_output { shift->finalize_body(@_) };
 143
 144 # For statistics
 145 our $COUNT     = 1;
 146 our $START     = time;
 147 our $RECURSION = 1000;
 148 our $DETACH    = Catalyst::Exception::Detach->new;
 149 our $GO        = Catalyst::Exception::Go->new;
 150
 151 #I imagine that very few of these really
 152 #need to be class variables. if any.
 153 #maybe we should just make them attributes with a default?
 154 __PACKAGE__->mk_classdata($_)
 155   for qw/components arguments dispatcher engine log dispatcher_class
 156   engine_loader context_class request_class response_class stats_class
 157   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 158   _data_handlers _encoding _encode_check finalized_default_middleware
 159   request_class_traits response_class_traits stats_class_traits
 160   _composed_request_class _composed_response_class _composed_stats_class/;
 161
 162 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 163 __PACKAGE__->request_class('Catalyst::Request');
 164 __PACKAGE__->response_class('Catalyst::Response');
 165 __PACKAGE__->stats_class('Catalyst::Stats');
 166
 167 sub composed_stats_class {
 168   my $class = shift;
 169   my @traits = (@{$class->stats_class_traits||[]}, @{$class->config->{stats_class_traits}||[]});
 170
 171   my $trait_ns = 'TraitFor::Stats';
 172   my @normalized_traits = map {
 173     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
 174   } @traits;
 175
 176   return $class->_composed_stats_class ||
 177     $class->_composed_stats_class(Moose::Util::with_traits($class->stats_class, @normalized_traits));
 178 }
 179
 180 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 181
 182 # Remember to update this in Catalyst::Runtime as well!
 183 our $VERSION = '5.90104';
 184 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 185
 186 sub import {
 187     my ( $class, @arguments ) = @_;
 188
 189     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 190     # callers @ISA.
 191     return unless $class eq 'Catalyst';
 192
 193     my $caller = caller();
 194     return if $caller eq 'main';
 195
 196     my $meta = Moose::Meta::Class->initialize($caller);
 197     unless ( $caller->isa('Catalyst') ) {
 198         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 199         $meta->superclasses(@superclasses);
 200     }
 201     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 202     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 203
 204     unless( $meta->has_method('meta') ){
 205         if ($Moose::VERSION >= 1.15) {
 206             $meta->_add_meta_method('meta');
 207         }
 208         else {
 209             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 210         }
 211     }
 212
 213     $caller->arguments( [@arguments] );
 214     $caller->setup_home;
 215 }
 216
 217 sub _application { $_[0] }
 218
 219 =encoding UTF-8
 220
 221 =head1 NAME
 222
 223 Catalyst - The Elegant MVC Web Application Framework
 224
 225 =for html
 226 <a href="https://badge.fury.io/pl/Catalyst-Runtime"><img src="https://badge.fury.io/pl/Catalyst-Runtime.svg" alt="CPAN version" height="18"></a>
 227 <a href="https://travis-ci.org/perl-catalyst/catalyst-runtime/"><img src="https://api.travis-ci.org/perl-catalyst/catalyst-runtime.png" alt="Catalyst></a>
 228 <a href="http://cpants.cpanauthors.org/dist/Catalyst-Runtime"><img src="http://cpants.cpanauthors.org/dist/Catalyst-Runtime.png" alt='Kwalitee Score' /></a>
 229
 230 =head1 SYNOPSIS
 231
 232 See the L<Catalyst::Manual> distribution for comprehensive
 233 documentation and tutorials.
 234
 235     # Install Catalyst::Devel for helpers and other development tools
 236     # use the helper to create a new application
 237     catalyst.pl MyApp
 238
 239     # add models, views, controllers
 240     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 241     script/myapp_create.pl view MyTemplate TT
 242     script/myapp_create.pl controller Search
 243
 244     # built in testserver -- use -r to restart automatically on changes
 245     # --help to see all available options
 246     script/myapp_server.pl
 247
 248     # command line testing interface
 249     script/myapp_test.pl /yada
 250
 251     ### in lib/MyApp.pm
 252     use Catalyst qw/-Debug/; # include plugins here as well
 253
 254     ### In lib/MyApp/Controller/Root.pm (autocreated)
 255     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 256         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 257         $c->stash->{template} = 'foo.tt'; # set the template
 258         # lookup something from db -- stash vars are passed to TT
 259         $c->stash->{data} =
 260           $c->model('Database::Foo')->search( { country => $args[0] } );
 261         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 262             $c->forward( 'bar' ); # process another action
 263             # do something else after forward returns
 264         }
 265     }
 266
 267     # The foo.tt TT template can use the stash data from the database
 268     [% WHILE (item = data.next) %]
 269         [% item.foo %]
 270     [% END %]
 271
 272     # called for /bar/of/soap, /bar/of/soap/10, etc.
 273     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 274
 275     # called after all actions are finished
 276     sub end : Action {
 277         my ( $self, $c ) = @_;
 278         if ( scalar @{ $c->error } ) { ... } # handle errors
 279         return if $c->res->body; # already have a response
 280         $c->forward( 'MyApp::View::TT' ); # render template
 281     }
 282
 283 See L<Catalyst::Manual::Intro> for additional information.
 284
 285 =head1 DESCRIPTION
 286
 287 Catalyst is a modern framework for making web applications without the
 288 pain usually associated with this process. This document is a reference
 289 to the main Catalyst application. If you are a new user, we suggest you
 290 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 291
 292 See L<Catalyst::Manual> for more documentation.
 293
 294 Catalyst plugins can be loaded by naming them as arguments to the "use
 295 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 296 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 297 C<My::Module>.
 298
 299     use Catalyst qw/My::Module/;
 300
 301 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 302 fully qualify the name by using a unary plus:
 303
 304     use Catalyst qw/
 305         My::Module
 306         +Fully::Qualified::Plugin::Name
 307     /;
 308
 309 Special flags like C<-Debug> can also be specified as
 310 arguments when Catalyst is loaded:
 311
 312     use Catalyst qw/-Debug My::Module/;
 313
 314 The position of plugins and flags in the chain is important, because
 315 they are loaded in the order in which they appear.
 316
 317 The following flags are supported:
 318
 319 =head2 -Debug
 320
 321 Enables debug output. You can also force this setting from the system
 322 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 323 settings override the application, with <MYAPP>_DEBUG having the highest
 324 priority.
 325
 326 This sets the log level to 'debug' and enables full debug output on the
 327 error screen. If you only want the latter, see L<< $c->debug >>.
 328
 329 =head2 -Home
 330
 331 Forces Catalyst to use a specific home directory, e.g.:
 332
 333     use Catalyst qw[-Home=/usr/mst];
 334
 335 This can also be done in the shell environment by setting either the
 336 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 337 is replaced with the uppercased name of your application, any "::" in
 338 the name will be replaced with underscores, e.g. MyApp::Web should use
 339 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 340
 341 If none of these are set, Catalyst will attempt to automatically detect the
 342 home directory. If you are working in a development environment, Catalyst
 343 will try and find the directory containing either Makefile.PL, Build.PL,
 344 dist.ini, or cpanfile. If the application has been installed into the system
 345 (i.e. you have done C<make install>), then Catalyst will use the path to your
 346 application module, without the .pm extension (e.g., /foo/MyApp if your
 347 application was installed at /foo/MyApp.pm)
 348
 349 =head2 -Log
 350
 351     use Catalyst '-Log=warn,fatal,error';
 352
 353 Specifies a comma-delimited list of log levels.
 354
 355 =head2 -Stats
 356
 357 Enables statistics collection and reporting.
 358
 359    use Catalyst qw/-Stats=1/;
 360
 361 You can also force this setting from the system environment with CATALYST_STATS
 362 or <MYAPP>_STATS. The environment settings override the application, with
 363 <MYAPP>_STATS having the highest priority.
 364
 365 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 366
 367 =head1 METHODS
 368
 369 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 370
 371 =head2 $c->action
 372
 373 Returns a L<Catalyst::Action> object for the current action, which
 374 stringifies to the action name. See L<Catalyst::Action>.
 375
 376 =head2 $c->namespace
 377
 378 Returns the namespace of the current action, i.e., the URI prefix
 379 corresponding to the controller of the current action. For example:
 380
 381     # in Controller::Foo::Bar
 382     $c->namespace; # returns 'foo/bar';
 383
 384 =head2 $c->request
 385
 386 =head2 $c->req
 387
 388 Returns the current L<Catalyst::Request> object, giving access to
 389 information about the current client request (including parameters,
 390 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 391
 392 =head2 REQUEST FLOW HANDLING
 393
 394 =head2 $c->forward( $action [, \@arguments ] )
 395
 396 =head2 $c->forward( $class, $method, [, \@arguments ] )
 397
 398 This is one way of calling another action (method) in the same or
 399 a different controller. You can also use C<< $self->my_method($c, @args) >>
 400 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 401 in a different controller.
 402 The main difference is that 'forward' uses some of the Catalyst request
 403 cycle overhead, including debugging, which may be useful to you. On the
 404 other hand, there are some complications to using 'forward', restrictions
 405 on values returned from 'forward', and it may not handle errors as you prefer.
 406 Whether you use 'forward' or not is up to you; it is not considered superior to
 407 the other ways to call a method.
 408
 409 'forward' calls  another action, by its private name. If you give a
 410 class name but no method, C<process()> is called. You may also optionally
 411 pass arguments in an arrayref. The action will receive the arguments in
 412 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 413 C<< $c->req->args >> will be restored to the previous values.
 414
 415 Any data C<return>ed from the action forwarded to, will be returned by the
 416 call to forward.
 417
 418     my $foodata = $c->forward('/foo');
 419     $c->forward('index');
 420     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 421     $c->forward('View::TT');
 422
 423 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 424 an C<< eval { } >> around the call (actually
 425 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 426 exceptions thrown by the called action non-fatal and pushing them onto
 427 $c->error instead. If you want C<die> to propagate you need to do something
 428 like:
 429
 430     $c->forward('foo');
 431     die join "\n", @{ $c->error } if @{ $c->error };
 432
 433 Or make sure to always return true values from your actions and write
 434 your code like this:
 435
 436     $c->forward('foo') || return;
 437
 438 Another note is that C<< $c->forward >> always returns a scalar because it
 439 actually returns $c->state which operates in a scalar context.
 440 Thus, something like:
 441
 442     return @array;
 443
 444 in an action that is forwarded to is going to return a scalar,
 445 i.e. how many items are in that array, which is probably not what you want.
 446 If you need to return an array then return a reference to it,
 447 or stash it like so:
 448
 449     $c->stash->{array} = \@array;
 450
 451 and access it from the stash.
 452
 453 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 454
 455 =cut
 456
 457 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 458
 459 =head2 $c->detach( $action [, \@arguments ] )
 460
 461 =head2 $c->detach( $class, $method, [, \@arguments ] )
 462
 463 =head2 $c->detach()
 464
 465 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 466 doesn't return to the previous action when processing is finished.
 467
 468 When called with no arguments it escapes the processing chain entirely.
 469
 470 =cut
 471
 472 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 473
 474 =head2 $c->visit( $action [, \@arguments ] )
 475
 476 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 477
 478 =head2 $c->visit( $class, $method, [, \@arguments ] )
 479
 480 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 481
 482 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 483 but does a full dispatch, instead of just calling the new C<$action> /
 484 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 485 you go to are called, just like a new request.
 486
 487 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 488 This means, for example, that C<< $c->action >> methods such as
 489 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 490 L<reverse|Catalyst::Action/reverse> return information for the visited action
 491 when they are invoked within the visited action.  This is different from the
 492 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 493 continues to use the $c->action object from the caller action even when
 494 invoked from the called action.
 495
 496 C<< $c->stash >> is kept unchanged.
 497
 498 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 499 allows you to "wrap" another action, just as it would have been called by
 500 dispatching from a URL, while the analogous
 501 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 502 transfer control to another action as if it had been reached directly from a URL.
 503
 504 =cut
 505
 506 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 507
 508 =head2 $c->go( $action [, \@arguments ] )
 509
 510 =head2 $c->go( $action [, \@captures, \@arguments ] )
 511
 512 =head2 $c->go( $class, $method, [, \@arguments ] )
 513
 514 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 515
 516 The relationship between C<go> and
 517 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 518 the relationship between
 519 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 520 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 521 C<< $c->go >> will perform a full dispatch on the specified action or method,
 522 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 523 C<go> escapes the processing of the current request chain on completion, and
 524 does not return to its caller.
 525
 526 @arguments are arguments to the final destination of $action. @captures are
 527 arguments to the intermediate steps, if any, on the way to the final sub of
 528 $action.
 529
 530 =cut
 531
 532 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 533
 534 =head2 $c->response
 535
 536 =head2 $c->res
 537
 538 Returns the current L<Catalyst::Response> object, see there for details.
 539
 540 =head2 $c->stash
 541
 542 Returns a hashref to the stash, which may be used to store data and pass
 543 it between components during a request. You can also set hash keys by
 544 passing arguments. The stash is automatically sent to the view. The
 545 stash is cleared at the end of a request; it cannot be used for
 546 persistent storage (for this you must use a session; see
 547 L<Catalyst::Plugin::Session> for a complete system integrated with
 548 Catalyst).
 549
 550     $c->stash->{foo} = $bar;
 551     $c->stash( { moose => 'majestic', qux => 0 } );
 552     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 553
 554     # stash is automatically passed to the view for use in a template
 555     $c->forward( 'MyApp::View::TT' );
 556
 557 The stash hash is currently stored in the PSGI C<$env> and is managed by
 558 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 559 the stash can be accessed in sub applications mounted under your main
 560 L<Catalyst> application.  For example if you delegate the response of an
 561 action to another L<Catalyst> application, that sub application will have
 562 access to all the stash keys of the main one, and if can of course add
 563 more keys of its own.  However those new keys will not 'bubble' back up
 564 to the main application.
 565
 566 For more information the best thing to do is to review the test case:
 567 t/middleware-stash.t in the distribution /t directory.
 568
 569 =cut
 570
 571 sub stash {
 572   my $c = shift;
 573   $c->log->error("You are requesting the stash but you don't have a context") unless blessed $c;
 574   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 575 }
 576
 577 =head2 $c->error
 578
 579 =head2 $c->error($error, ...)
 580
 581 =head2 $c->error($arrayref)
 582
 583 Returns an arrayref containing error messages.  If Catalyst encounters an
 584 error while processing a request, it stores the error in $c->error.  This
 585 method should only be used to store fatal error messages.
 586
 587     my @error = @{ $c->error };
 588
 589 Add a new error.
 590
 591     $c->error('Something bad happened');
 592
 593 Calling this will always return an arrayref (if there are no errors it
 594 will be an empty arrayref.
 595
 596 =cut
 597
 598 sub error {
 599     my $c = shift;
 600     if ( $_[0] ) {
 601         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 602         croak @$error unless ref $c;
 603         push @{ $c->{error} }, @$error;
 604     }
 605     elsif ( defined $_[0] ) { $c->{error} = undef }
 606     return $c->{error} || [];
 607 }
 608
 609 =head2 $c->state
 610
 611 Contains the return value of the last executed action.
 612 Note that << $c->state >> operates in a scalar context which means that all
 613 values it returns are scalar.
 614
 615 Please note that if an action throws an exception, the value of state
 616 should no longer be considered the return if the last action.  It is generally
 617 going to be 0, which indicates an error state.  Examine $c->error for error
 618 details.
 619
 620 =head2 $c->clear_errors
 621
 622 Clear errors.  You probably don't want to clear the errors unless you are
 623 implementing a custom error screen.
 624
 625 This is equivalent to running
 626
 627     $c->error(0);
 628
 629 =cut
 630
 631 sub clear_errors {
 632     my $c = shift;
 633     $c->error(0);
 634 }
 635
 636 =head2 $c->has_errors
 637
 638 Returns true if you have errors
 639
 640 =cut
 641
 642 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 643
 644 =head2 $c->last_error
 645
 646 Returns the most recent error in the stack (the one most recently added...)
 647 or nothing if there are no errors.  This does not modify the contents of the
 648 error stack.
 649
 650 =cut
 651
 652 sub last_error {
 653   my (@errs) = @{shift->error};
 654   return scalar(@errs) ? $errs[-1]: undef;
 655 }
 656
 657 =head2 shift_errors
 658
 659 shifts the most recently added error off the error stack and returns it.  Returns
 660 nothing if there are no more errors.
 661
 662 =cut
 663
 664 sub shift_errors {
 665     my ($self) = @_;
 666     my @errors = @{$self->error};
 667     my $err = shift(@errors);
 668     $self->{error} = \@errors;
 669     return $err;
 670 }
 671
 672 =head2 pop_errors
 673
 674 pops the most recently added error off the error stack and returns it.  Returns
 675 nothing if there are no more errors.
 676
 677 =cut
 678
 679 sub pop_errors {
 680     my ($self) = @_;
 681     my @errors = @{$self->error};
 682     my $err = pop(@errors);
 683     $self->{error} = \@errors;
 684     return $err;
 685 }
 686
 687 sub _comp_search_prefixes {
 688     my $c = shift;
 689     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 690 }
 691
 692 # search components given a name and some prefixes
 693 sub _comp_names_search_prefixes {
 694     my ( $c, $name, @prefixes ) = @_;
 695     my $appclass = ref $c || $c;
 696     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 697     $filter = qr/$filter/; # Compile regex now rather than once per loop
 698
 699     # map the original component name to the sub part that we will search against
 700     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 701         grep { /$filter/ } keys %{ $c->components };
 702
 703     # undef for a name will return all
 704     return keys %eligible if !defined $name;
 705
 706     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 707     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 708
 709     return @result if @result;
 710
 711     # if we were given a regexp to search against, we're done.
 712     return if $name->$_isa('Regexp');
 713
 714     # skip regexp fallback if configured
 715     return
 716         if $appclass->config->{disable_component_resolution_regex_fallback};
 717
 718     # regexp fallback
 719     $query  = qr/$name/i;
 720     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 721
 722     # no results? try against full names
 723     if( !@result ) {
 724         @result = grep { m{$query} } keys %eligible;
 725     }
 726
 727     # don't warn if we didn't find any results, it just might not exist
 728     if( @result ) {
 729         # Disgusting hack to work out correct method name
 730         my $warn_for = lc $prefixes[0];
 731         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 732            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 733            "component resolution is unreliable and unsafe.";
 734         my $short = $result[0];
 735         # remove the component namespace prefix
 736         $short =~ s/.*?(Model|Controller|View):://;
 737         my $shortmess = Carp::shortmess('');
 738         if ($shortmess =~ m#Catalyst/Plugin#) {
 739            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 740               "plugin's config";
 741         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 742            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 743               "component's config";
 744         } else {
 745            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 746               "but if you really wanted to search, pass in a regexp as the argument " .
 747               "like so: \$c->${warn_for}(qr/${name}/)";
 748         }
 749         $c->log->warn( "${msg}$shortmess" );
 750     }
 751
 752     return @result;
 753 }
 754
 755 # Find possible names for a prefix
 756 sub _comp_names {
 757     my ( $c, @prefixes ) = @_;
 758     my $appclass = ref $c || $c;
 759
 760     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 761
 762     my @names = map { s{$filter}{}; $_; }
 763         $c->_comp_names_search_prefixes( undef, @prefixes );
 764
 765     return @names;
 766 }
 767
 768 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 769
 770 sub _filter_component {
 771     my ( $c, $comp, @args ) = @_;
 772
 773     if(ref $comp eq 'CODE') {
 774       $comp = $comp->();
 775     }
 776
 777     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 778       return $comp->ACCEPT_CONTEXT( $c, @args );
 779     }
 780
 781     $c->log->warn("You called component '${\$comp->catalyst_component_name}' with arguments [@args], but this component does not ACCEPT_CONTEXT, so args are ignored.") if scalar(@args) && $c->debug;
 782
 783     return $comp;
 784 }
 785
 786 =head2 COMPONENT ACCESSORS
 787
 788 =head2 $c->controller($name)
 789
 790 Gets a L<Catalyst::Controller> instance by name.
 791
 792     $c->controller('Foo')->do_stuff;
 793
 794 If the name is omitted, will return the controller for the dispatched
 795 action.
 796
 797 If you want to search for controllers, pass in a regexp as the argument.
 798
 799     # find all controllers that start with Foo
 800     my @foo_controllers = $c->controller(qr{^Foo});
 801
 802
 803 =cut
 804
 805 sub controller {
 806     my ( $c, $name, @args ) = @_;
 807
 808     my $appclass = ref($c) || $c;
 809     if( $name ) {
 810         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 811             my $comps = $c->components;
 812             my $check = $appclass."::Controller::".$name;
 813             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 814             foreach my $path (@{$appclass->config->{ setup_components }->{ search_extra }}) {
 815                 next unless $path =~ /.*::Controller/;
 816                 $check = $path."::".$name;
 817                 return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 818             }
 819         }
 820         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 821         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 822         return $c->_filter_component( $result[ 0 ], @args );
 823     }
 824
 825     return $c->component( $c->action->class );
 826 }
 827
 828 =head2 $c->model($name)
 829
 830 Gets a L<Catalyst::Model> instance by name.
 831
 832     $c->model('Foo')->do_stuff;
 833
 834 Any extra arguments are directly passed to ACCEPT_CONTEXT, if the model
 835 defines ACCEPT_CONTEXT.  If it does not, the args are discarded.
 836
 837 If the name is omitted, it will look for
 838  - a model object in $c->stash->{current_model_instance}, then
 839  - a model name in $c->stash->{current_model}, then
 840  - a config setting 'default_model', or
 841  - check if there is only one model, and return it if that's the case.
 842
 843 If you want to search for models, pass in a regexp as the argument.
 844
 845     # find all models that start with Foo
 846     my @foo_models = $c->model(qr{^Foo});
 847
 848 =cut
 849
 850 sub model {
 851     my ( $c, $name, @args ) = @_;
 852     my $appclass = ref($c) || $c;
 853     if( $name ) {
 854         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 855             my $comps = $c->components;
 856             my $check = $appclass."::Model::".$name;
 857             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 858             foreach my $path (@{$appclass->config->{ setup_components }->{ search_extra }}) {
 859                 next unless $path =~ /.*::Model/;
 860                 $check = $path."::".$name;
 861                 return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 862             }
 863         }
 864         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 865         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 866         return $c->_filter_component( $result[ 0 ], @args );
 867     }
 868
 869     if (ref $c) {
 870         return $c->stash->{current_model_instance}
 871           if $c->stash->{current_model_instance};
 872         return $c->model( $c->stash->{current_model} )
 873           if $c->stash->{current_model};
 874     }
 875     return $c->model( $appclass->config->{default_model} )
 876       if $appclass->config->{default_model};
 877
 878     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 879
 880     if( $rest ) {
 881         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 882         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 883         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 884         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 885         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 886     }
 887
 888     return $c->_filter_component( $comp );
 889 }
 890
 891
 892 =head2 $c->view($name)
 893
 894 Gets a L<Catalyst::View> instance by name.
 895
 896     $c->view('Foo')->do_stuff;
 897
 898 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 899
 900 If the name is omitted, it will look for
 901  - a view object in $c->stash->{current_view_instance}, then
 902  - a view name in $c->stash->{current_view}, then
 903  - a config setting 'default_view', or
 904  - check if there is only one view, and return it if that's the case.
 905
 906 If you want to search for views, pass in a regexp as the argument.
 907
 908     # find all views that start with Foo
 909     my @foo_views = $c->view(qr{^Foo});
 910
 911 =cut
 912
 913 sub view {
 914     my ( $c, $name, @args ) = @_;
 915
 916     my $appclass = ref($c) || $c;
 917     if( $name ) {
 918         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 919             my $comps = $c->components;
 920             my $check = $appclass."::View::".$name;
 921             if( exists $comps->{$check} ) {
 922                 return $c->_filter_component( $comps->{$check}, @args );
 923             }
 924             else {
 925                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 926             }
 927             foreach my $path (@{$appclass->config->{ setup_components }->{ search_extra }}) {
 928                 next unless $path =~ /.*::View/;
 929                 $check = $path."::".$name;
 930                 return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 931             }
 932         }
 933         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 934         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 935         return $c->_filter_component( $result[ 0 ], @args );
 936     }
 937
 938     if (ref $c) {
 939         return $c->stash->{current_view_instance}
 940           if $c->stash->{current_view_instance};
 941         return $c->view( $c->stash->{current_view} )
 942           if $c->stash->{current_view};
 943     }
 944     return $c->view( $appclass->config->{default_view} )
 945       if $appclass->config->{default_view};
 946
 947     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 948
 949     if( $rest ) {
 950         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 951         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 952         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 953         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 954         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 955     }
 956
 957     return $c->_filter_component( $comp );
 958 }
 959
 960 =head2 $c->controllers
 961
 962 Returns the available names which can be passed to $c->controller
 963
 964 =cut
 965
 966 sub controllers {
 967     my ( $c ) = @_;
 968     return $c->_comp_names(qw/Controller C/);
 969 }
 970
 971 =head2 $c->models
 972
 973 Returns the available names which can be passed to $c->model
 974
 975 =cut
 976
 977 sub models {
 978     my ( $c ) = @_;
 979     return $c->_comp_names(qw/Model M/);
 980 }
 981
 982
 983 =head2 $c->views
 984
 985 Returns the available names which can be passed to $c->view
 986
 987 =cut
 988
 989 sub views {
 990     my ( $c ) = @_;
 991     return $c->_comp_names(qw/View V/);
 992 }
 993
 994 =head2 $c->comp($name)
 995
 996 =head2 $c->component($name)
 997
 998 Gets a component object by name. This method is not recommended,
 999 unless you want to get a specific component by full
1000 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
1001 should be used instead.
1002
1003 If C<$name> is a regexp, a list of components matched against the full
1004 component name will be returned.
1005
1006 If Catalyst can't find a component by name, it will fallback to regex
1007 matching by default. To disable this behaviour set
1008 disable_component_resolution_regex_fallback to a true value.
1009
1010     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
1011
1012 =cut
1013
1014 sub component {
1015     my ( $c, $name, @args ) = @_;
1016
1017     if( $name ) {
1018         my $comps = $c->components;
1019
1020         if( !ref $name ) {
1021             # is it the exact name?
1022             return $c->_filter_component( $comps->{ $name }, @args )
1023                        if exists $comps->{ $name };
1024
1025             # perhaps we just omitted "MyApp"?
1026             my $composed = ( ref $c || $c ) . "::${name}";
1027             return $c->_filter_component( $comps->{ $composed }, @args )
1028                        if exists $comps->{ $composed };
1029
1030             # search all of the models, views and controllers
1031             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
1032             return $c->_filter_component( $comp, @args ) if $comp;
1033         }
1034
1035         return
1036             if $c->config->{disable_component_resolution_regex_fallback};
1037
1038         # This is here so $c->comp( '::M::' ) works
1039         my $query = ref $name ? $name : qr{$name}i;
1040
1041         my @result = grep { m{$query} } keys %{ $c->components };
1042         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
1043
1044         if( $result[ 0 ] ) {
1045             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
1046             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
1047             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
1048             return $c->_filter_component( $result[ 0 ], @args );
1049         }
1050
1051         # I would expect to return an empty list here, but that breaks back-compat
1052     }
1053
1054     # fallback
1055     return sort keys %{ $c->components };
1056 }
1057
1058 =head2 CLASS DATA AND HELPER CLASSES
1059
1060 =head2 $c->config
1061
1062 Returns or takes a hashref containing the application's configuration.
1063
1064     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
1065
1066 You can also use a C<YAML>, C<XML> or L<Config::General> config file
1067 like C<myapp.conf> in your applications home directory. See
1068 L<Catalyst::Plugin::ConfigLoader>.
1069
1070 =head3 Cascading configuration
1071
1072 The config method is present on all Catalyst components, and configuration
1073 will be merged when an application is started. Configuration loaded with
1074 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
1075 followed by configuration in your top level C<MyApp> class. These two
1076 configurations are merged, and then configuration data whose hash key matches a
1077 component name is merged with configuration for that component.
1078
1079 The configuration for a component is then passed to the C<new> method when a
1080 component is constructed.
1081
1082 For example:
1083
1084     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
1085     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
1086
1087 will mean that C<MyApp::Model::Foo> receives the following data when
1088 constructed:
1089
1090     MyApp::Model::Foo->new({
1091         bar => 'baz',
1092         quux => 'frob',
1093         overrides => 'me',
1094     });
1095
1096 It's common practice to use a Moose attribute
1097 on the receiving component to access the config value.
1098
1099     package MyApp::Model::Foo;
1100
1101     use Moose;
1102
1103     # this attr will receive 'baz' at construction time
1104     has 'bar' => (
1105         is  => 'rw',
1106         isa => 'Str',
1107     );
1108
1109 You can then get the value 'baz' by calling $c->model('Foo')->bar
1110 (or $self->bar inside code in the model).
1111
1112 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
1113 as a way of reading config within your code, as this B<will not> give you the
1114 correctly merged config back. You B<MUST> take the config values supplied to
1115 the constructor and use those instead.
1116
1117 =cut
1118
1119 around config => sub {
1120     my $orig = shift;
1121     my $c = shift;
1122
1123     croak('Setting config after setup has been run is not allowed.')
1124         if ( @_ and $c->setup_finished );
1125
1126     $c->$orig(@_);
1127 };
1128
1129 =head2 $c->log
1130
1131 Returns the logging object instance. Unless it is already set, Catalyst
1132 sets this up with a L<Catalyst::Log> object. To use your own log class,
1133 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1134 C<< __PACKAGE__->setup >>.
1135
1136  __PACKAGE__->log( MyLogger->new );
1137  __PACKAGE__->setup;
1138
1139 And later:
1140
1141     $c->log->info( 'Now logging with my own logger!' );
1142
1143 Your log class should implement the methods described in
1144 L<Catalyst::Log>.
1145
1146 =head2 has_encoding
1147
1148 Returned True if there's a valid encoding
1149
1150 =head2 clear_encoding
1151
1152 Clears the encoding for the current context
1153
1154 =head2 encoding
1155
1156 Sets or gets the application encoding.  Setting encoding takes either an
1157 Encoding object or a string that we try to resolve via L<Encode::find_encoding>.
1158
1159 You would expect to get the encoding object back if you attempt to set it.  If
1160 there is a failure you will get undef returned and an error message in the log.
1161
1162 =cut
1163
1164 sub has_encoding { shift->encoding ? 1:0 }
1165
1166 sub clear_encoding {
1167     my $c = shift;
1168     if(blessed $c) {
1169         $c->encoding(undef);
1170     } else {
1171         $c->log->error("You can't clear encoding on the application");
1172     }
1173 }
1174
1175 sub encoding {
1176     my $c = shift;
1177     my $encoding;
1178
1179     if ( scalar @_ ) {
1180
1181         # Don't let one change this once we are too far into the response
1182         if(blessed $c && $c->res->finalized_headers) {
1183           Carp::croak("You may not change the encoding once the headers are finalized");
1184           return;
1185         }
1186
1187         # Let it be set to undef
1188         if (my $wanted = shift)  {
1189             $encoding = Encode::find_encoding($wanted)
1190               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1191             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1192         }
1193         else {
1194             binmode(STDERR);
1195         }
1196
1197         $encoding = ref $c
1198                   ? $c->{encoding} = $encoding
1199                   : $c->_encoding($encoding);
1200     } else {
1201       $encoding = ref $c && exists $c->{encoding}
1202                 ? $c->{encoding}
1203                 : $c->_encoding;
1204     }
1205
1206     return $encoding;
1207 }
1208
1209 =head2 $c->debug
1210
1211 Returns 1 if debug mode is enabled, 0 otherwise.
1212
1213 You can enable debug mode in several ways:
1214
1215 =over
1216
1217 =item By calling myapp_server.pl with the -d flag
1218
1219 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1220
1221 =item The -Debug option in your MyApp.pm
1222
1223 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1224
1225 =back
1226
1227 The first three also set the log level to 'debug'.
1228
1229 Calling C<< $c->debug(1) >> has no effect.
1230
1231 =cut
1232
1233 sub debug { 0 }
1234
1235 =head2 $c->dispatcher
1236
1237 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1238
1239 =head2 $c->engine
1240
1241 Returns the engine instance. See L<Catalyst::Engine>.
1242
1243
1244 =head2 UTILITY METHODS
1245
1246 =head2 $c->path_to(@path)
1247
1248 Merges C<@path> with C<< $c->config->{home} >> and returns a
1249 L<Path::Class::Dir> object. Note you can usually use this object as
1250 a filename, but sometimes you will have to explicitly stringify it
1251 yourself by calling the C<< ->stringify >> method.
1252
1253 For example:
1254
1255     $c->path_to( 'db', 'sqlite.db' );
1256
1257 =cut
1258
1259 sub path_to {
1260     my ( $c, @path ) = @_;
1261     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1262     if ( -d $path ) { return $path }
1263     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1264 }
1265
1266 sub plugin {
1267     my ( $class, $name, $plugin, @args ) = @_;
1268
1269     # See block comment in t/unit_core_plugin.t
1270     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1271
1272     $class->_register_plugin( $plugin, 1 );
1273
1274     eval { $plugin->import };
1275     $class->mk_classdata($name);
1276     my $obj;
1277     eval { $obj = $plugin->new(@args) };
1278
1279     if ($@) {
1280         Catalyst::Exception->throw( message =>
1281               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1282     }
1283
1284     $class->$name($obj);
1285     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1286       if $class->debug;
1287 }
1288
1289 =head2 MyApp->setup
1290
1291 Initializes the dispatcher and engine, loads any plugins, and loads the
1292 model, view, and controller components. You may also specify an array
1293 of plugins to load here, if you choose to not load them in the C<use
1294 Catalyst> line.
1295
1296     MyApp->setup;
1297     MyApp->setup( qw/-Debug/ );
1298
1299 B<Note:> You B<should not> wrap this method with method modifiers
1300 or bad things will happen - wrap the C<setup_finalize> method instead.
1301
1302 B<Note:> You can create a custom setup stage that will execute when the
1303 application is starting.  Use this to customize setup.
1304
1305     MyApp->setup(-Custom=value);
1306
1307     sub setup_custom {
1308       my ($class, $value) = @_;
1309     }
1310
1311 Can be handy if you want to hook into the setup phase.
1312
1313 =cut
1314
1315 sub setup {
1316     my ( $class, @arguments ) = @_;
1317     croak('Running setup more than once')
1318         if ( $class->setup_finished );
1319
1320     unless ( $class->isa('Catalyst') ) {
1321
1322         Catalyst::Exception->throw(
1323             message => qq/'$class' does not inherit from Catalyst/ );
1324     }
1325
1326     if ( $class->arguments ) {
1327         @arguments = ( @arguments, @{ $class->arguments } );
1328     }
1329
1330     # Process options
1331     my $flags = {};
1332
1333     foreach (@arguments) {
1334
1335         if (/^-Debug$/) {
1336             $flags->{log} =
1337               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1338         }
1339         elsif (/^-(\w+)=?(.*)$/) {
1340             $flags->{ lc $1 } = $2;
1341         }
1342         else {
1343             push @{ $flags->{plugins} }, $_;
1344         }
1345     }
1346
1347     $class->setup_home( delete $flags->{home} );
1348
1349     $class->setup_log( delete $flags->{log} );
1350     $class->setup_plugins( delete $flags->{plugins} );
1351
1352     $class->setup_data_handlers();
1353     $class->setup_dispatcher( delete $flags->{dispatcher} );
1354     if (my $engine = delete $flags->{engine}) {
1355         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1356     }
1357     $class->setup_engine();
1358     $class->setup_stats( delete $flags->{stats} );
1359
1360     for my $flag ( sort keys %{$flags} ) {
1361
1362         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1363             &$code( $class, delete $flags->{$flag} );
1364         }
1365         else {
1366             $class->log->warn(qq/Unknown flag "$flag"/);
1367         }
1368     }
1369
1370     eval { require Catalyst::Devel; };
1371     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1372         $class->log->warn(<<"EOF");
1373 You are running an old script!
1374
1375   Please update by running (this will overwrite existing files):
1376     catalyst.pl -force -scripts $class
1377
1378   or (this will not overwrite existing files):
1379     catalyst.pl -scripts $class
1380
1381 EOF
1382     }
1383
1384     # Call plugins setup, this is stupid and evil.
1385     # Also screws C3 badly on 5.10, hack to avoid.
1386     {
1387         no warnings qw/redefine/;
1388         local *setup = sub { };
1389         $class->setup unless $Catalyst::__AM_RESTARTING;
1390     }
1391
1392     # If you are expecting configuration info as part of your setup, it needs
1393     # to get called here and below, since we need the above line to support
1394     # ConfigLoader based configs.
1395
1396     $class->setup_encoding();
1397     $class->setup_middleware();
1398
1399     # Initialize our data structure
1400     $class->components( {} );
1401
1402     $class->setup_components;
1403
1404     if ( $class->debug ) {
1405         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1406
1407         if (@plugins) {
1408             my $column_width = Catalyst::Utils::term_width() - 6;
1409             my $t = Text::SimpleTable->new($column_width);
1410             $t->row($_) for @plugins;
1411             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1412         }
1413
1414         my @middleware = map {
1415           ref $_ eq 'CODE' ?
1416             "Inline Coderef" :
1417               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1418                 || '')  } $class->registered_middlewares;
1419
1420         if (@middleware) {
1421             my $column_width = Catalyst::Utils::term_width() - 6;
1422             my $t = Text::SimpleTable->new($column_width);
1423             $t->row($_) for @middleware;
1424             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1425         }
1426
1427         my %dh = $class->registered_data_handlers;
1428         if (my @data_handlers = keys %dh) {
1429             my $column_width = Catalyst::Utils::term_width() - 6;
1430             my $t = Text::SimpleTable->new($column_width);
1431             $t->row($_) for @data_handlers;
1432             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1433         }
1434
1435         my $dispatcher = $class->dispatcher;
1436         my $engine     = $class->engine;
1437         my $home       = $class->config->{home};
1438
1439         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1440         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1441
1442         $home
1443           ? ( -d $home )
1444           ? $class->log->debug(qq/Found home "$home"/)
1445           : $class->log->debug(qq/Home "$home" doesn't exist/)
1446           : $class->log->debug(q/Couldn't find home/);
1447
1448         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1449
1450         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1451         for my $comp ( sort keys %{ $class->components } ) {
1452             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1453             $t->row( $comp, $type );
1454         }
1455         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1456           if ( keys %{ $class->components } );
1457     }
1458
1459     # Add our self to components, since we are also a component
1460     if( $class->isa('Catalyst::Controller') ){
1461       $class->components->{$class} = $class;
1462     }
1463
1464     $class->setup_actions;
1465
1466     if ( $class->debug ) {
1467         my $name = $class->config->{name} || 'Application';
1468         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1469     }
1470
1471     if ($class->config->{case_sensitive}) {
1472         $class->log->warn($class . "->config->{case_sensitive} is set.");
1473         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1474     }
1475
1476     $class->setup_finalize;
1477
1478     # Flush the log for good measure (in case something turned off 'autoflush' early)
1479     $class->log->_flush() if $class->log->can('_flush');
1480
1481     return $class || 1; # Just in case someone named their Application 0...
1482 }
1483
1484 =head2 $app->setup_finalize
1485
1486 A hook to attach modifiers to. This method does not do anything except set the
1487 C<setup_finished> accessor.
1488
1489 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1490
1491 Example:
1492
1493     after setup_finalize => sub {
1494         my $app = shift;
1495
1496         ## do stuff here..
1497     };
1498
1499 =cut
1500
1501 sub setup_finalize {
1502     my ($class) = @_;
1503     $class->setup_finished(1);
1504 }
1505
1506 =head2 $c->uri_for( $path?, @args?, \%query_values?, \$fragment? )
1507
1508 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values?, \$fragment? )
1509
1510 =head2 $c->uri_for( $action, [@captures, @args], \%query_values?, \$fragment? )
1511
1512 Constructs an absolute L<URI> object based on the application root, the
1513 provided path, and the additional arguments and query parameters provided.
1514 When used as a string, provides a textual URI.  If you need more flexibility
1515 than this (i.e. the option to provide relative URIs etc.) see
1516 L<Catalyst::Plugin::SmartURI>.
1517
1518 If no arguments are provided, the URI for the current action is returned.
1519 To return the current action and also provide @args, use
1520 C<< $c->uri_for( $c->action, @args ) >>.
1521
1522 If the first argument is a string, it is taken as a public URI path relative
1523 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1524 relative to the application root (if it does). It is then merged with
1525 C<< $c->request->base >>; any C<@args> are appended as additional path
1526 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1527
1528 B<NOTE> If you are using this 'stringy' first argument, we skip encoding and
1529 allow you to declare something like:
1530
1531     $c->uri_for('/foo/bar#baz')
1532
1533 Where 'baz' is a URI fragment.  We consider this first argument string to be
1534 'expert' mode where you are expected to create a valid URL and we for the most
1535 part just pass it through without a lot of internal effort to escape and encode.
1536
1537 If the first argument is a L<Catalyst::Action> it represents an action which
1538 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1539 optional C<\@captures> argument (an arrayref) allows passing the captured
1540 variables that are needed to fill in the paths of Chained and Regex actions;
1541 once the path is resolved, C<uri_for> continues as though a path was
1542 provided, appending any arguments or parameters and creating an absolute
1543 URI.
1544
1545 The captures for the current request can be found in
1546 C<< $c->request->captures >>, and actions can be resolved using
1547 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1548 path, use C<< $c->uri_for_action >> instead.
1549
1550   # Equivalent to $c->req->uri
1551   $c->uri_for($c->action, $c->req->captures,
1552       @{ $c->req->args }, $c->req->params);
1553
1554   # For the Foo action in the Bar controller
1555   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1556
1557   # Path to a static resource
1558   $c->uri_for('/static/images/logo.png');
1559
1560 In general the scheme of the generated URI object will follow the incoming request
1561 however if your targeted action or action chain has the Scheme attribute it will
1562 use that instead.
1563
1564 Also, if the targeted Action or Action chain declares Args/CaptureArgs that have
1565 type constraints, we will require that your proposed URL verify on those declared
1566 constraints.
1567
1568 =cut
1569
1570 sub uri_for {
1571     my ( $c, $path, @args ) = @_;
1572
1573     if ( $path->$_isa('Catalyst::Controller') ) {
1574         $path = $path->path_prefix;
1575         $path =~ s{/+\z}{};
1576         $path .= '/';
1577     }
1578
1579     my $fragment =  ((scalar(@args) && ref($args[-1]) eq 'SCALAR') ? pop @args : undef );
1580
1581     unless(blessed $path) {
1582       if (defined($path) and $path =~ s/#(.+)$//)  {
1583         if(defined($1) and $fragment) {
1584           carp "Abiguious fragment declaration: You cannot define a fragment in '$path' and as an argument '$fragment'";
1585         }
1586         if(defined($1)) {
1587           $fragment = $1;
1588         }
1589       }
1590     }
1591
1592     my $params =
1593       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1594
1595     undef($path) if (defined $path && $path eq '');
1596
1597     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1598
1599     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1600     if ( $path->$_isa('Catalyst::Action') ) { # action object
1601         s|/|%2F|g for @args;
1602         my $captures = [ map { s|/|%2F|g; $_; }
1603                         ( scalar @args && ref $args[0] eq 'ARRAY'
1604                          ? @{ shift(@args) }
1605                          : ()) ];
1606
1607         my $action = $path;
1608         my $expanded_action = $c->dispatcher->expand_action( $action );
1609         my $num_captures = $expanded_action->number_of_captures;
1610
1611         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1612         if( !@args && $action->number_of_args ) {
1613           unshift @args, splice @$captures, $num_captures;
1614         }
1615
1616         if($num_captures) {
1617           unless($expanded_action->match_captures_constraints($c, $captures)) {
1618             carp "captures [@{$captures}] do not match the type constraints in actionchain ending with '$expanded_action'";
1619             return;
1620           }
1621         }
1622
1623         $path = $c->dispatcher->uri_for_action($action, $captures);
1624         if (not defined $path) {
1625             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1626                 if $c->debug;
1627             return undef;
1628         }
1629         $path = '/' if $path eq '';
1630
1631         # At this point @encoded_args is the remaining Args (all captures removed).
1632         if($expanded_action->has_args_constraints) {
1633           unless($expanded_action->match_args($c,\@args)) {
1634              carp "args [@args] do not match the type constraints in action '$expanded_action'";
1635              return;
1636           }
1637         }
1638     }
1639
1640     unshift(@args, $path);
1641
1642     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1643         my $namespace = $c->namespace;
1644         if (defined $path) { # cheesy hack to handle path '../foo'
1645            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1646         }
1647         unshift(@args, $namespace || '');
1648     }
1649
1650     # join args with '/', or a blank string
1651     my $args = join('/', grep { defined($_) } @args);
1652     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1653     $args =~ s!^/+!!;
1654
1655     my ($base, $class) = ('/', 'URI::_generic');
1656     if(blessed($c)) {
1657       $base = $c->req->base;
1658       if($target_action) {
1659         $target_action = $c->dispatcher->expand_action($target_action);
1660         if(my $s = $target_action->scheme) {
1661           $s = lc($s);
1662           $class = "URI::$s";
1663           $base->scheme($s);
1664         } else {
1665           $class = ref($base);
1666         }
1667       } else {
1668         $class = ref($base);
1669       }
1670
1671       $base =~ s{(?<!/)$}{/};
1672     }
1673
1674     my $query = '';
1675     if (my @keys = keys %$params) {
1676       # somewhat lifted from URI::_query's query_form
1677       $query = '?'.join('&', map {
1678           my $val = $params->{$_};
1679           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1680           s/ /+/g;
1681           my $key = $_;
1682           $val = '' unless defined $val;
1683           (map {
1684               my $param = "$_";
1685               $param = encode_utf8($param);
1686               # using the URI::Escape pattern here so utf8 chars survive
1687               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1688               $param =~ s/ /+/g;
1689
1690               $key = encode_utf8($key);
1691               # using the URI::Escape pattern here so utf8 chars survive
1692               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1693               $key =~ s/ /+/g;
1694
1695               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1696       } @keys);
1697     }
1698
1699     $base = encode_utf8 $base;
1700     $base =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1701     $args = encode_utf8 $args;
1702     $args =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1703
1704     if(defined $fragment) {
1705       if(blessed $path) {
1706         $fragment = encode_utf8(${$fragment});
1707         $fragment =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1708         $fragment =~ s/ /+/g;
1709       }
1710       $query .= "#$fragment";
1711     }
1712
1713     my $res = bless(\"${base}${args}${query}", $class);
1714     $res;
1715 }
1716
1717 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1718
1719 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1720
1721 =over
1722
1723 =item $path
1724
1725 A private path to the Catalyst action you want to create a URI for.
1726
1727 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1728 >> and passing the resulting C<$action> and the remaining arguments to C<<
1729 $c->uri_for >>.
1730
1731 You can also pass in a Catalyst::Action object, in which case it is passed to
1732 C<< $c->uri_for >>.
1733
1734 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1735
1736 For example, if the action looks like:
1737
1738  package MyApp::Controller::Users;
1739
1740  sub lst : Path('the-list') {}
1741
1742 You can use:
1743
1744  $c->uri_for_action('/users/lst')
1745
1746 and it will create the URI /users/the-list.
1747
1748 =item \@captures_and_args?
1749
1750 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1751 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1752 to interpolate all the parameters in the URI.
1753
1754 =item @args?
1755
1756 Optional list of extra arguments - can be supplied in the
1757 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1758 code.
1759
1760 Your action can have zero, a fixed or a variable number of args (e.g.
1761 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1762
1763 =item \%query_values?
1764
1765 Optional array reference of query parameters to append. E.g.
1766
1767   { foo => 'bar' }
1768
1769 will generate
1770
1771   /rest/of/your/uri?foo=bar
1772
1773 =back
1774
1775 =cut
1776
1777 sub uri_for_action {
1778     my ( $c, $path, @args ) = @_;
1779     my $action = blessed($path)
1780       ? $path
1781       : $c->dispatcher->get_action_by_path($path);
1782     unless (defined $action) {
1783       croak "Can't find action for path '$path'";
1784     }
1785     return $c->uri_for( $action, @args );
1786 }
1787
1788 =head2 $c->welcome_message
1789
1790 Returns the Catalyst welcome HTML page.
1791
1792 =cut
1793
1794 sub welcome_message {
1795     my $c      = shift;
1796     my $name   = $c->config->{name};
1797     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1798     my $prefix = Catalyst::Utils::appprefix( ref $c );
1799     $c->response->content_type('text/html; charset=utf-8');
1800     return <<"EOF";
1801 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1802     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1803 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1804     <head>
1805     <meta http-equiv="Content-Language" content="en" />
1806     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1807         <title>$name on Catalyst $VERSION</title>
1808         <style type="text/css">
1809             body {
1810                 color: #000;
1811                 background-color: #eee;
1812             }
1813             div#content {
1814                 width: 640px;
1815                 margin-left: auto;
1816                 margin-right: auto;
1817                 margin-top: 10px;
1818                 margin-bottom: 10px;
1819                 text-align: left;
1820                 background-color: #ccc;
1821                 border: 1px solid #aaa;
1822             }
1823             p, h1, h2 {
1824                 margin-left: 20px;
1825                 margin-right: 20px;
1826                 font-family: verdana, tahoma, sans-serif;
1827             }
1828             a {
1829                 font-family: verdana, tahoma, sans-serif;
1830             }
1831             :link, :visited {
1832                     text-decoration: none;
1833                     color: #b00;
1834                     border-bottom: 1px dotted #bbb;
1835             }
1836             :link:hover, :visited:hover {
1837                     color: #555;
1838             }
1839             div#topbar {
1840                 margin: 0px;
1841             }
1842             pre {
1843                 margin: 10px;
1844                 padding: 8px;
1845             }
1846             div#answers {
1847                 padding: 8px;
1848                 margin: 10px;
1849                 background-color: #fff;
1850                 border: 1px solid #aaa;
1851             }
1852             h1 {
1853                 font-size: 0.9em;
1854                 font-weight: normal;
1855                 text-align: center;
1856             }
1857             h2 {
1858                 font-size: 1.0em;
1859             }
1860             p {
1861                 font-size: 0.9em;
1862             }
1863             p img {
1864                 float: right;
1865                 margin-left: 10px;
1866             }
1867             span#appname {
1868                 font-weight: bold;
1869                 font-size: 1.6em;
1870             }
1871         </style>
1872     </head>
1873     <body>
1874         <div id="content">
1875             <div id="topbar">
1876                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1877                     $VERSION</h1>
1878              </div>
1879              <div id="answers">
1880                  <p>
1881                  <img src="$logo" alt="Catalyst Logo" />
1882                  </p>
1883                  <p>Welcome to the  world of Catalyst.
1884                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1885                     framework will make web development something you had
1886                     never expected it to be: Fun, rewarding, and quick.</p>
1887                  <h2>What to do now?</h2>
1888                  <p>That really depends  on what <b>you</b> want to do.
1889                     We do, however, provide you with a few starting points.</p>
1890                  <p>If you want to jump right into web development with Catalyst
1891                     you might want to start with a tutorial.</p>
1892 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1893 </pre>
1894 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1895 <pre>
1896 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1897 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1898 </code></pre>
1899                  <h2>What to do next?</h2>
1900                  <p>Next it's time to write an actual application. Use the
1901                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1902                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1903                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1904                     they can save you a lot of work.</p>
1905                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1906                     <p>Also, be sure to check out the vast and growing
1907                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1908                     you are likely to find what you need there.
1909                     </p>
1910
1911                  <h2>Need help?</h2>
1912                  <p>Catalyst has a very active community. Here are the main places to
1913                     get in touch with us.</p>
1914                  <ul>
1915                      <li>
1916                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1917                      </li>
1918                      <li>
1919                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1920                      </li>
1921                      <li>
1922                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1923                      </li>
1924                  </ul>
1925                  <h2>In conclusion</h2>
1926                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1927                     as we enjoyed making it. Please contact us if you have ideas
1928                     for improvement or other feedback.</p>
1929              </div>
1930          </div>
1931     </body>
1932 </html>
1933 EOF
1934 }
1935
1936 =head2 run_options
1937
1938 Contains a hash of options passed from the application script, including
1939 the original ARGV the script received, the processed values from that
1940 ARGV and any extra arguments to the script which were not processed.
1941
1942 This can be used to add custom options to your application's scripts
1943 and setup your application differently depending on the values of these
1944 options.
1945
1946 =head1 INTERNAL METHODS
1947
1948 These methods are not meant to be used by end users.
1949
1950 =head2 $c->components
1951
1952 Returns a hash of components.
1953
1954 =head2 $c->context_class
1955
1956 Returns or sets the context class.
1957
1958 =head2 $c->counter
1959
1960 Returns a hashref containing coderefs and execution counts (needed for
1961 deep recursion detection).
1962
1963 =head2 $c->depth
1964
1965 Returns the number of actions on the current internal execution stack.
1966
1967 =head2 $c->dispatch
1968
1969 Dispatches a request to actions.
1970
1971 =cut
1972
1973 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1974
1975 =head2 $c->dispatcher_class
1976
1977 Returns or sets the dispatcher class.
1978
1979 =head2 $c->dump_these
1980
1981 Returns a list of 2-element array references (name, structure) pairs
1982 that will be dumped on the error page in debug mode.
1983
1984 =cut
1985
1986 sub dump_these {
1987     my $c = shift;
1988     [ Request => $c->req ],
1989     [ Response => $c->res ],
1990     [ Stash => $c->stash ],
1991     [ Config => $c->config ];
1992 }
1993
1994 =head2 $c->engine_class
1995
1996 Returns or sets the engine class.
1997
1998 =head2 $c->execute( $class, $coderef )
1999
2000 Execute a coderef in given class and catch exceptions. Errors are available
2001 via $c->error.
2002
2003 =cut
2004
2005 sub execute {
2006     my ( $c, $class, $code ) = @_;
2007     $class = $c->component($class) || $class;
2008     #$c->state(0);
2009
2010     if ( $c->depth >= $RECURSION ) {
2011         my $action = $code->reverse();
2012         $action = "/$action" unless $action =~ /->/;
2013         my $error = qq/Deep recursion detected calling "${action}"/;
2014         $c->log->error($error);
2015         $c->error($error);
2016         $c->state(0);
2017         return $c->state;
2018     }
2019
2020     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
2021
2022     push( @{ $c->stack }, $code );
2023
2024     no warnings 'recursion';
2025     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
2026     #      I have no idea how, ergo $ret (which appears to fix the issue)
2027     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
2028
2029     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
2030
2031     my $last = pop( @{ $c->stack } );
2032
2033     if ( my $error = $@ ) {
2034         #rethow if this can be handled by middleware
2035         if ( $c->_handle_http_exception($error) ) {
2036             foreach my $err (@{$c->error}) {
2037                 $c->log->error($err);
2038             }
2039             $c->clear_errors;
2040             $c->log->_flush if $c->log->can('_flush');
2041
2042             $error->can('rethrow') ? $error->rethrow : croak $error;
2043         }
2044         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
2045             $error->rethrow if $c->depth > 1;
2046         }
2047         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
2048             $error->rethrow if $c->depth > 0;
2049         }
2050         else {
2051             unless ( ref $error ) {
2052                 no warnings 'uninitialized';
2053                 chomp $error;
2054                 my $class = $last->class;
2055                 my $name  = $last->name;
2056                 $error = qq/Caught exception in $class->$name "$error"/;
2057             }
2058             $c->error($error);
2059         }
2060         #$c->state(0);
2061     }
2062     return $c->state;
2063 }
2064
2065 sub _stats_start_execute {
2066     my ( $c, $code ) = @_;
2067     my $appclass = ref($c) || $c;
2068     return if ( ( $code->name =~ /^_.*/ )
2069         && ( !$appclass->config->{show_internal_actions} ) );
2070
2071     my $action_name = $code->reverse();
2072     $c->counter->{$action_name}++;
2073
2074     my $action = $action_name;
2075     $action = "/$action" unless $action =~ /->/;
2076
2077     # determine if the call was the result of a forward
2078     # this is done by walking up the call stack and looking for a calling
2079     # sub of Catalyst::forward before the eval
2080     my $callsub = q{};
2081     for my $index ( 2 .. 11 ) {
2082         last
2083         if ( ( caller($index) )[0] eq 'Catalyst'
2084             && ( caller($index) )[3] eq '(eval)' );
2085
2086         if ( ( caller($index) )[3] =~ /forward$/ ) {
2087             $callsub = ( caller($index) )[3];
2088             $action  = "-> $action";
2089             last;
2090         }
2091     }
2092
2093     my $uid = $action_name . $c->counter->{$action_name};
2094
2095     # is this a root-level call or a forwarded call?
2096     if ( $callsub =~ /forward$/ ) {
2097         my $parent = $c->stack->[-1];
2098
2099         # forward, locate the caller
2100         if ( defined $parent && exists $c->counter->{"$parent"} ) {
2101             $c->stats->profile(
2102                 begin  => $action,
2103                 parent => "$parent" . $c->counter->{"$parent"},
2104                 uid    => $uid,
2105             );
2106         }
2107         else {
2108
2109             # forward with no caller may come from a plugin
2110             $c->stats->profile(
2111                 begin => $action,
2112                 uid   => $uid,
2113             );
2114         }
2115     }
2116     else {
2117
2118         # root-level call
2119         $c->stats->profile(
2120             begin => $action,
2121             uid   => $uid,
2122         );
2123     }
2124     return $action;
2125
2126 }
2127
2128 sub _stats_finish_execute {
2129     my ( $c, $info ) = @_;
2130     $c->stats->profile( end => $info );
2131 }
2132
2133 =head2 $c->finalize
2134
2135 Finalizes the request.
2136
2137 =cut
2138
2139 sub finalize {
2140     my $c = shift;
2141
2142     for my $error ( @{ $c->error } ) {
2143         $c->log->error($error);
2144     }
2145
2146     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
2147     # stuff like cometd and websockets
2148
2149     if($c->request->_has_io_fh) {
2150       $c->log_response;
2151       return;
2152     }
2153
2154     # Allow engine to handle finalize flow (for POE)
2155     my $engine = $c->engine;
2156     if ( my $code = $engine->can('finalize') ) {
2157         $engine->$code($c);
2158     }
2159     else {
2160
2161         $c->finalize_uploads;
2162
2163         # Error
2164         if ( $#{ $c->error } >= 0 ) {
2165             $c->finalize_error;
2166         }
2167
2168         $c->finalize_encoding;
2169         $c->finalize_headers unless $c->response->finalized_headers;
2170         $c->finalize_body;
2171     }
2172
2173     $c->log_response;
2174
2175     if ($c->use_stats) {
2176         my $elapsed = $c->stats->elapsed;
2177         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
2178         $c->log->info(
2179             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
2180     }
2181
2182     return $c->response->status;
2183 }
2184
2185 =head2 $c->finalize_body
2186
2187 Finalizes body.
2188
2189 =cut
2190
2191 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
2192
2193 =head2 $c->finalize_cookies
2194
2195 Finalizes cookies.
2196
2197 =cut
2198
2199 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
2200
2201 =head2 $c->finalize_error
2202
2203 Finalizes error.  If there is only one error in L</error> and it is an object that
2204 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2205 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2206 return the default error page (production mode).
2207
2208 =cut
2209
2210 sub finalize_error {
2211     my $c = shift;
2212     if($#{$c->error} > 0) {
2213         $c->engine->finalize_error( $c, @_ );
2214     } else {
2215         my ($error) = @{$c->error};
2216         if ( $c->_handle_http_exception($error) ) {
2217             # In the case where the error 'knows what it wants', becauses its PSGI
2218             # aware, just rethow and let middleware catch it
2219             $error->can('rethrow') ? $error->rethrow : croak $error;
2220         } else {
2221             $c->engine->finalize_error( $c, @_ )
2222         }
2223     }
2224 }
2225
2226 =head2 $c->finalize_headers
2227
2228 Finalizes headers.
2229
2230 =cut
2231
2232 sub finalize_headers {
2233     my $c = shift;
2234
2235     my $response = $c->response; #accessor calls can add up?
2236
2237     # Check if we already finalized headers
2238     return if $response->finalized_headers;
2239
2240     # Handle redirects
2241     if ( my $location = $response->redirect ) {
2242         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2243         $response->header( Location => $location );
2244     }
2245
2246     # Remove incorrectly added body and content related meta data when returning
2247     # an information response, or a response the is required to not include a body
2248
2249     $c->finalize_cookies;
2250
2251     # This currently is a NOOP but I don't want to remove it since I guess people
2252     # might have Response subclasses that use it for something... (JNAP)
2253     $c->response->finalize_headers();
2254
2255     # Done
2256     $response->finalized_headers(1);
2257 }
2258
2259 =head2 $c->finalize_encoding
2260
2261 Make sure your body is encoded properly IF you set an encoding.  By
2262 default the encoding is UTF-8 but you can disable it by explicitly setting the
2263 encoding configuration value to undef.
2264
2265 We can only encode when the body is a scalar.  Methods for encoding via the
2266 streaming interfaces (such as C<write> and C<write_fh> on L<Catalyst::Response>
2267 are available).
2268
2269 See L</ENCODING>.
2270
2271 =cut
2272
2273 sub finalize_encoding {
2274     my $c = shift;
2275     my $res = $c->res || return;
2276
2277     # Warn if the set charset is different from the one you put into encoding.  We need
2278     # to do this early since encodable_response is false for this condition and we need
2279     # to match the debug output for backcompat (there's a test for this...) -JNAP
2280     if(
2281       $res->content_type_charset and $c->encoding and
2282       (uc($c->encoding->mime_name) ne uc($res->content_type_charset))
2283     ) {
2284         my $ct = lc($res->content_type_charset);
2285         $c->log->debug("Catalyst encoding config is set to encode in '" .
2286             $c->encoding->mime_name .
2287             "', content type is '$ct', not encoding ");
2288     }
2289
2290     if(
2291       ($res->encodable_response) and
2292       (defined($res->body)) and
2293       (ref(\$res->body) eq 'SCALAR')
2294     ) {
2295         $c->res->body( $c->encoding->encode( $c->res->body, $c->_encode_check ) );
2296
2297         # Set the charset if necessary.  This might be a bit bonkers since encodable response
2298         # is false when the set charset is not the same as the encoding mimetype (maybe
2299         # confusing action at a distance here..
2300         # Don't try to set the charset if one already exists or if headers are already finalized
2301         $c->res->content_type($c->res->content_type . "; charset=" . $c->encoding->mime_name)
2302           unless($c->res->content_type_charset ||
2303                 ($c->res->_context && $c->res->finalized_headers && !$c->res->_has_response_cb));
2304     }
2305 }
2306
2307 =head2 $c->finalize_output
2308
2309 An alias for finalize_body.
2310
2311 =head2 $c->finalize_read
2312
2313 Finalizes the input after reading is complete.
2314
2315 =cut
2316
2317 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2318
2319 =head2 $c->finalize_uploads
2320
2321 Finalizes uploads. Cleans up any temporary files.
2322
2323 =cut
2324
2325 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2326
2327 =head2 $c->get_action( $action, $namespace )
2328
2329 Gets an action in a given namespace.
2330
2331 =cut
2332
2333 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2334
2335 =head2 $c->get_actions( $action, $namespace )
2336
2337 Gets all actions of a given name in a namespace and all parent
2338 namespaces.
2339
2340 =cut
2341
2342 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2343
2344 =head2 $app->handle_request( @arguments )
2345
2346 Called to handle each HTTP request.
2347
2348 =cut
2349
2350 sub handle_request {
2351     my ( $class, @arguments ) = @_;
2352
2353     # Always expect worst case!
2354     my $status = -1;
2355     try {
2356         if ($class->debug) {
2357             my $secs = time - $START || 1;
2358             my $av = sprintf '%.3f', $COUNT / $secs;
2359             my $time = localtime time;
2360             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2361         }
2362
2363         my $c = $class->prepare(@arguments);
2364         $c->dispatch;
2365         $status = $c->finalize;
2366     } catch {
2367         #rethow if this can be handled by middleware
2368         if ( $class->_handle_http_exception($_) ) {
2369             $_->can('rethrow') ? $_->rethrow : croak $_;
2370         }
2371         chomp(my $error = $_);
2372         $class->log->error(qq/Caught exception in engine "$error"/);
2373     };
2374
2375     $COUNT++;
2376
2377     if(my $coderef = $class->log->can('_flush')){
2378         $class->log->$coderef();
2379     }
2380     return $status;
2381 }
2382
2383 =head2 $class->prepare( @arguments )
2384
2385 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2386 etc.).
2387
2388 =cut
2389
2390 has _uploadtmp => (
2391     is => 'ro',
2392     predicate => '_has_uploadtmp',
2393 );
2394
2395 sub prepare {
2396     my ( $class, @arguments ) = @_;
2397
2398     # XXX
2399     # After the app/ctxt split, this should become an attribute based on something passed
2400     # into the application.
2401     $class->context_class( ref $class || $class ) unless $class->context_class;
2402
2403     my $uploadtmp = $class->config->{uploadtmp};
2404     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2405
2406     $c->response->_context($c);
2407     $c->stats($class->stats_class->new)->enable($c->use_stats);
2408
2409     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2410         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2411     }
2412
2413     try {
2414         # Allow engine to direct the prepare flow (for POE)
2415         if ( my $prepare = $c->engine->can('prepare') ) {
2416             $c->engine->$prepare( $c, @arguments );
2417         }
2418         else {
2419             $c->prepare_request(@arguments);
2420             $c->prepare_connection;
2421             $c->prepare_query_parameters;
2422             $c->prepare_headers; # Just hooks, no longer needed - they just
2423             $c->prepare_cookies; # cause the lazy attribute on req to build
2424             $c->prepare_path;
2425
2426             # Prepare the body for reading, either by prepare_body
2427             # or the user, if they are using $c->read
2428             $c->prepare_read;
2429
2430             # Parse the body unless the user wants it on-demand
2431             unless ( ref($c)->config->{parse_on_demand} ) {
2432                 $c->prepare_body;
2433             }
2434         }
2435         $c->prepare_action;
2436     }
2437     # VERY ugly and probably shouldn't rely on ->finalize actually working
2438     catch {
2439         # failed prepare is always due to an invalid request, right?
2440         $c->response->status(400);
2441         $c->response->content_type('text/plain');
2442         $c->response->body('Bad Request');
2443         # Note we call finalize and then die here, which escapes
2444         # finalize being called in the enclosing block..
2445         # It in fact couldn't be called, as we don't return $c..
2446         # This is a mess - but I'm unsure you can fix this without
2447         # breaking compat for people doing crazy things (we should set
2448         # the 400 and just return the ctx here IMO, letting finalize get called
2449         # above...
2450         $c->finalize;
2451         die $_;
2452     };
2453
2454     $c->log_request;
2455
2456     return $c;
2457 }
2458
2459 =head2 $c->prepare_action
2460
2461 Prepares action. See L<Catalyst::Dispatcher>.
2462
2463 =cut
2464
2465 sub prepare_action {
2466     my $c = shift;
2467     my $ret = $c->dispatcher->prepare_action( $c, @_);
2468
2469     if($c->encoding) {
2470         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2471           $_ = $c->_handle_param_unicode_decoding($_);
2472         }
2473     }
2474
2475     return $ret;
2476 }
2477
2478
2479 =head2 $c->prepare_body
2480
2481 Prepares message body.
2482
2483 =cut
2484
2485 sub prepare_body {
2486     my $c = shift;
2487
2488     return if $c->request->_has_body;
2489
2490     # Initialize on-demand data
2491     $c->engine->prepare_body( $c, @_ );
2492     $c->prepare_parameters;
2493     $c->prepare_uploads;
2494 }
2495
2496 =head2 $c->prepare_body_chunk( $chunk )
2497
2498 Prepares a chunk of data before sending it to L<HTTP::Body>.
2499
2500 See L<Catalyst::Engine>.
2501
2502 =cut
2503
2504 sub prepare_body_chunk {
2505     my $c = shift;
2506     $c->engine->prepare_body_chunk( $c, @_ );
2507 }
2508
2509 =head2 $c->prepare_body_parameters
2510
2511 Prepares body parameters.
2512
2513 =cut
2514
2515 sub prepare_body_parameters {
2516     my $c = shift;
2517     $c->request->prepare_body_parameters( $c, @_ );
2518 }
2519
2520 =head2 $c->prepare_connection
2521
2522 Prepares connection.
2523
2524 =cut
2525
2526 sub prepare_connection {
2527     my $c = shift;
2528     $c->request->prepare_connection($c);
2529 }
2530
2531 =head2 $c->prepare_cookies
2532
2533 Prepares cookies by ensuring that the attribute on the request
2534 object has been built.
2535
2536 =cut
2537
2538 sub prepare_cookies { my $c = shift; $c->request->cookies }
2539
2540 =head2 $c->prepare_headers
2541
2542 Prepares request headers by ensuring that the attribute on the request
2543 object has been built.
2544
2545 =cut
2546
2547 sub prepare_headers { my $c = shift; $c->request->headers }
2548
2549 =head2 $c->prepare_parameters
2550
2551 Prepares parameters.
2552
2553 =cut
2554
2555 sub prepare_parameters {
2556     my $c = shift;
2557     $c->prepare_body_parameters;
2558     $c->engine->prepare_parameters( $c, @_ );
2559 }
2560
2561 =head2 $c->prepare_path
2562
2563 Prepares path and base.
2564
2565 =cut
2566
2567 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2568
2569 =head2 $c->prepare_query_parameters
2570
2571 Prepares query parameters.
2572
2573 =cut
2574
2575 sub prepare_query_parameters {
2576     my $c = shift;
2577
2578     $c->engine->prepare_query_parameters( $c, @_ );
2579 }
2580
2581 =head2 $c->log_request
2582
2583 Writes information about the request to the debug logs.  This includes:
2584
2585 =over 4
2586
2587 =item * Request method, path, and remote IP address
2588
2589 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2590
2591 =item * Request parameters
2592
2593 =item * File uploads
2594
2595 =back
2596
2597 =cut
2598
2599 sub log_request {
2600     my $c = shift;
2601
2602     return unless $c->debug;
2603
2604     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2605     my $request = $dump->[1];
2606
2607     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2608     $method ||= '';
2609     $path = '/' unless length $path;
2610     $address ||= '';
2611
2612     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2613     $path = decode_utf8($path);
2614
2615     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2616
2617     $c->log_request_headers($request->headers);
2618
2619     if ( my $keywords = $request->query_keywords ) {
2620         $c->log->debug("Query keywords are: $keywords");
2621     }
2622
2623     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2624
2625     $c->log_request_uploads($request);
2626 }
2627
2628 =head2 $c->log_response
2629
2630 Writes information about the response to the debug logs by calling
2631 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2632
2633 =cut
2634
2635 sub log_response {
2636     my $c = shift;
2637
2638     return unless $c->debug;
2639
2640     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2641     my $response = $dump->[1];
2642
2643     $c->log_response_status_line($response);
2644     $c->log_response_headers($response->headers);
2645 }
2646
2647 =head2 $c->log_response_status_line($response)
2648
2649 Writes one line of information about the response to the debug logs.  This includes:
2650
2651 =over 4
2652
2653 =item * Response status code
2654
2655 =item * Content-Type header (if present)
2656
2657 =item * Content-Length header (if present)
2658
2659 =back
2660
2661 =cut
2662
2663 sub log_response_status_line {
2664     my ($c, $response) = @_;
2665
2666     $c->log->debug(
2667         sprintf(
2668             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2669             $response->status                            || 'unknown',
2670             $response->headers->header('Content-Type')   || 'unknown',
2671             $response->headers->header('Content-Length') || 'unknown'
2672         )
2673     );
2674 }
2675
2676 =head2 $c->log_response_headers($headers);
2677
2678 Hook method which can be wrapped by plugins to log the response headers.
2679 No-op in the default implementation.
2680
2681 =cut
2682
2683 sub log_response_headers {}
2684
2685 =head2 $c->log_request_parameters( query => {}, body => {} )
2686
2687 Logs request parameters to debug logs
2688
2689 =cut
2690
2691 sub log_request_parameters {
2692     my $c          = shift;
2693     my %all_params = @_;
2694
2695     return unless $c->debug;
2696
2697     my $column_width = Catalyst::Utils::term_width() - 44;
2698     foreach my $type (qw(query body)) {
2699         my $params = $all_params{$type};
2700         next if ! keys %$params;
2701         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2702         for my $key ( sort keys %$params ) {
2703             my $param = $params->{$key};
2704             my $value = defined($param) ? $param : '';
2705             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2706         }
2707         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2708     }
2709 }
2710
2711 =head2 $c->log_request_uploads
2712
2713 Logs file uploads included in the request to the debug logs.
2714 The parameter name, filename, file type, and file size are all included in
2715 the debug logs.
2716
2717 =cut
2718
2719 sub log_request_uploads {
2720     my $c = shift;
2721     my $request = shift;
2722     return unless $c->debug;
2723     my $uploads = $request->uploads;
2724     if ( keys %$uploads ) {
2725         my $t = Text::SimpleTable->new(
2726             [ 12, 'Parameter' ],
2727             [ 26, 'Filename' ],
2728             [ 18, 'Type' ],
2729             [ 9,  'Size' ]
2730         );
2731         for my $key ( sort keys %$uploads ) {
2732             my $upload = $uploads->{$key};
2733             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2734                 $t->row( $key, $u->filename, $u->type, $u->size );
2735             }
2736         }
2737         $c->log->debug( "File Uploads are:\n" . $t->draw );
2738     }
2739 }
2740
2741 =head2 $c->log_request_headers($headers);
2742
2743 Hook method which can be wrapped by plugins to log the request headers.
2744 No-op in the default implementation.
2745
2746 =cut
2747
2748 sub log_request_headers {}
2749
2750 =head2 $c->log_headers($type => $headers)
2751
2752 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2753
2754 =cut
2755
2756 sub log_headers {
2757     my $c       = shift;
2758     my $type    = shift;
2759     my $headers = shift;    # an HTTP::Headers instance
2760
2761     return unless $c->debug;
2762
2763     my $column_width = Catalyst::Utils::term_width() - 28;
2764     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2765     $headers->scan(
2766         sub {
2767             my ( $name, $value ) = @_;
2768             $t->row( $name, $value );
2769         }
2770     );
2771     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2772 }
2773
2774
2775 =head2 $c->prepare_read
2776
2777 Prepares the input for reading.
2778
2779 =cut
2780
2781 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2782
2783 =head2 $c->prepare_request
2784
2785 Prepares the engine request.
2786
2787 =cut
2788
2789 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2790
2791 =head2 $c->prepare_uploads
2792
2793 Prepares uploads.
2794
2795 =cut
2796
2797 sub prepare_uploads {
2798     my $c = shift;
2799     $c->engine->prepare_uploads( $c, @_ );
2800 }
2801
2802 =head2 $c->prepare_write
2803
2804 Prepares the output for writing.
2805
2806 =cut
2807
2808 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2809
2810 =head2 $c->request_class
2811
2812 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2813
2814 =head2 $app->request_class_traits
2815
2816 An arrayref of L<Moose::Role>s which are applied to the request class.  You can
2817 name the full namespace of the role, or a namespace suffix, which will then
2818 be tried against the following standard namespace prefixes.
2819
2820     $MyApp::TraitFor::Request::$trait_suffix
2821     Catalyst::TraitFor::Request::$trait_suffix
2822
2823 So for example if you set:
2824
2825     MyApp->request_class_traits(['Foo']);
2826
2827 We try each possible role in turn (and throw an error if none load)
2828
2829     Foo
2830     MyApp::TraitFor::Request::Foo
2831     Catalyst::TraitFor::Request::Foo
2832
2833 The namespace part 'TraitFor::Request' was chosen to assist in backwards
2834 compatibility with L<CatalystX::RoleApplicator> which previously provided
2835 these features in a stand alone package.
2836
2837 =head2 $app->composed_request_class
2838
2839 This is the request class which has been composed with any request_class_traits.
2840
2841 =head2 $c->response_class
2842
2843 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2844
2845 =head2 $app->response_class_traits
2846
2847 An arrayref of L<Moose::Role>s which are applied to the response class.  You can
2848 name the full namespace of the role, or a namespace suffix, which will then
2849 be tried against the following standard namespace prefixes.
2850
2851     $MyApp::TraitFor::Response::$trait_suffix
2852     Catalyst::TraitFor::Response::$trait_suffix
2853
2854 So for example if you set:
2855
2856     MyApp->response_class_traits(['Foo']);
2857
2858 We try each possible role in turn (and throw an error if none load)
2859
2860     Foo
2861     MyApp::TraitFor::Response::Foo
2862     Catalyst::TraitFor::Responset::Foo
2863
2864 The namespace part 'TraitFor::Response' was chosen to assist in backwards
2865 compatibility with L<CatalystX::RoleApplicator> which previously provided
2866 these features in a stand alone package.
2867
2868
2869 =head2 $app->composed_response_class
2870
2871 This is the request class which has been composed with any response_class_traits.
2872
2873 =head2 $c->read( [$maxlength] )
2874
2875 Reads a chunk of data from the request body. This method is designed to
2876 be used in a while loop, reading C<$maxlength> bytes on every call.
2877 C<$maxlength> defaults to the size of the request if not specified.
2878
2879 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2880 directly.
2881
2882 Warning: If you use read(), Catalyst will not process the body,
2883 so you will not be able to access POST parameters or file uploads via
2884 $c->request.  You must handle all body parsing yourself.
2885
2886 =cut
2887
2888 sub read { my $c = shift; return $c->request->read( @_ ) }
2889
2890 =head2 $c->run
2891
2892 Starts the engine.
2893
2894 =cut
2895
2896 sub run {
2897   my $app = shift;
2898   $app->_make_immutable_if_needed;
2899   $app->engine_loader->needs_psgi_engine_compat_hack ?
2900     $app->engine->run($app, @_) :
2901       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2902 }
2903
2904 sub _make_immutable_if_needed {
2905     my $class = shift;
2906     my $meta = find_meta($class);
2907     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2908     if (
2909         $meta->is_immutable
2910         && ! { $meta->immutable_options }->{replace_constructor}
2911         && $isa_ca
2912     ) {
2913         warn("You made your application class ($class) immutable, "
2914             . "but did not inline the\nconstructor. "
2915             . "This will break catalyst, as your app \@ISA "
2916             . "Class::Accessor(::Fast)?\nPlease pass "
2917             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2918     }
2919     unless ($meta->is_immutable) {
2920         # XXX - FIXME warning here as you should make your app immutable yourself.
2921         $meta->make_immutable(
2922             replace_constructor => 1,
2923         );
2924     }
2925 }
2926
2927 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2928
2929 Sets an action in a given namespace.
2930
2931 =cut
2932
2933 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2934
2935 =head2 $c->setup_actions($component)
2936
2937 Sets up actions for a component.
2938
2939 =cut
2940
2941 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2942
2943 =head2 $c->setup_components
2944
2945 This method is called internally to set up the application's components.
2946
2947 It finds modules by calling the L<locate_components> method, expands them to
2948 package names with the L<expand_component_module> method, and then installs
2949 each component into the application.
2950
2951 The C<setup_components> config option is passed to both of the above methods.
2952
2953 Installation of each component is performed by the L<setup_component> method,
2954 below.
2955
2956 =cut
2957
2958 sub setup_components {
2959     my $class = shift;
2960
2961     my $config  = $class->config->{ setup_components };
2962
2963     my @comps = $class->locate_components($config);
2964     my %comps = map { $_ => 1 } @comps;
2965
2966     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2967     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2968         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2969     ) if $deprecatedcatalyst_component_names;
2970
2971     for my $component ( @comps ) {
2972
2973         # We pass ignore_loaded here so that overlay files for (e.g.)
2974         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2975         # we know M::P::O found a file on disk so this is safe
2976
2977         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2978     }
2979
2980     for my $component (@comps) {
2981         my $instance = $class->components->{ $component } = $class->delayed_setup_component($component);
2982     }
2983
2984     # Inject a component or wrap a stand alone class in an adaptor. This makes a list
2985     # of named components in the configuration that are not actually existing (not a
2986     # real file).
2987
2988     my @injected = $class->setup_injected_components;
2989
2990     # All components are registered, now we need to 'init' them.
2991     foreach my $component_name (@comps, @injected) {
2992       $class->components->{$component_name} = $class->components->{$component_name}->() if
2993         (ref($class->components->{$component_name}) || '') eq 'CODE';
2994     }
2995 }
2996
2997 =head2 $app->setup_injected_components
2998
2999 Called by setup_compoents to setup components that are injected.
3000
3001 =cut
3002
3003 sub setup_injected_components {
3004     my ($class) = @_;
3005     my @injected_components = keys %{$class->config->{inject_components} ||+{}};
3006
3007     foreach my $injected_comp_name(@injected_components) {
3008         $class->setup_injected_component(
3009           $injected_comp_name,
3010           $class->config->{inject_components}->{$injected_comp_name});
3011     }
3012
3013     return map { $class ."::" . $_ }
3014       @injected_components;
3015 }
3016
3017 =head2 $app->setup_injected_component( $injected_component_name, $config )
3018
3019 Setup a given injected component.
3020
3021 =cut
3022
3023 sub setup_injected_component {
3024     my ($class, $injected_comp_name, $config) = @_;
3025     if(my $component_class = $config->{from_component}) {
3026         my @roles = @{$config->{roles} ||[]};
3027         Catalyst::Utils::inject_component(
3028           into => $class,
3029           component => $component_class,
3030           (scalar(@roles) ? (traits => \@roles) : ()),
3031           as => $injected_comp_name);
3032     }
3033 }
3034
3035 =head2 $app->inject_component($MyApp_Component_name => \%args);
3036
3037 Add a component that is injected at setup:
3038
3039     MyApp->inject_component( 'Model::Foo' => { from_component => 'Common::Foo' } );
3040
3041 Must be called before ->setup.  Expects a component name for your
3042 current application and \%args where
3043
3044 =over 4
3045
3046 =item from_component
3047
3048 The target component being injected into your application
3049
3050 =item roles
3051
3052 An arrayref of L<Moose::Role>s that are applied to your component.
3053
3054 =back
3055
3056 Example
3057
3058     MyApp->inject_component(
3059       'Model::Foo' => {
3060         from_component => 'Common::Model::Foo',
3061         roles => ['Role1', 'Role2'],
3062       });
3063
3064 =head2 $app->inject_components
3065
3066 Inject a list of components:
3067
3068     MyApp->inject_components(
3069       'Model::FooOne' => {
3070         from_component => 'Common::Model::Foo',
3071         roles => ['Role1', 'Role2'],
3072       },
3073       'Model::FooTwo' => {
3074         from_component => 'Common::Model::Foo',
3075         roles => ['Role1', 'Role2'],
3076       });
3077
3078 =cut
3079
3080 sub inject_component {
3081   my ($app, $name, $args) = @_;
3082   die "Component $name exists" if
3083     $app->config->{inject_components}->{$name};
3084   $app->config->{inject_components}->{$name} = $args;
3085 }
3086
3087 sub inject_components {
3088   my $app = shift;
3089   while(@_) {
3090     $app->inject_component(shift, shift);
3091   }
3092 }
3093
3094 =head2 $c->locate_components( $setup_component_config )
3095
3096 This method is meant to provide a list of component modules that should be
3097 setup for the application.  By default, it will use L<Module::Pluggable>.
3098
3099 Specify a C<setup_components> config option to pass additional options directly
3100 to L<Module::Pluggable>. To add additional search paths, specify a key named
3101 C<search_extra> as an array reference. Items in the array beginning with C<::>
3102 will have the application class name prepended to them.
3103
3104 =cut
3105
3106 sub locate_components {
3107     my $class  = shift;
3108     my $config = shift;
3109
3110     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
3111     my $extra   = $config->{ search_extra } || [];
3112
3113     unshift @paths, @$extra;
3114
3115     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
3116       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
3117       %$config
3118     )->plugins } @paths;
3119
3120     return @comps;
3121 }
3122
3123 =head2 $c->expand_component_module( $component, $setup_component_config )
3124
3125 Components found by C<locate_components> will be passed to this method, which
3126 is expected to return a list of component (package) names to be set up.
3127
3128 =cut
3129
3130 sub expand_component_module {
3131     my ($class, $module) = @_;
3132     return Devel::InnerPackage::list_packages( $module );
3133 }
3134
3135 =head2 $app->delayed_setup_component
3136
3137 Returns a coderef that points to a setup_component instance.  Used
3138 internally for when you want to delay setup until the first time
3139 the component is called.
3140
3141 =cut
3142
3143 sub delayed_setup_component {
3144   my($class, $component, @more) = @_;
3145   return sub {
3146     return my $instance = $class->setup_component($component, @more);
3147   };
3148 }
3149
3150 =head2 $c->setup_component
3151
3152 =cut
3153
3154 sub setup_component {
3155     my( $class, $component ) = @_;
3156
3157     unless ( $component->can( 'COMPONENT' ) ) {
3158         return $component;
3159     }
3160
3161     my $config = $class->config_for($component);
3162     # Stash catalyst_component_name in the config here, so that custom COMPONENT
3163     # methods also pass it. local to avoid pointlessly shitting in config
3164     # for the debug screen, as $component is already the key name.
3165     local $config->{catalyst_component_name} = $component;
3166
3167     my $instance = eval {
3168       $component->COMPONENT( $class, $config );
3169     } || do {
3170       my $error = $@;
3171       chomp $error;
3172       Catalyst::Exception->throw(
3173         message => qq/Couldn't instantiate component "$component", "$error"/
3174       );
3175     };
3176
3177     unless (blessed $instance) {
3178         my $metaclass = Moose::Util::find_meta($component);
3179         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
3180         my $component_method_from = $method_meta->associated_metaclass->name;
3181         my $value = defined($instance) ? $instance : 'undef';
3182         Catalyst::Exception->throw(
3183             message =>
3184             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
3185         );
3186     }
3187
3188     my @expanded_components = $instance->can('expand_modules')
3189       ? $instance->expand_modules( $component, $config )
3190       : $class->expand_component_module( $component, $config );
3191     for my $component (@expanded_components) {
3192       next if $class->components->{ $component };
3193       $class->components->{ $component } = $class->setup_component($component);
3194     }
3195
3196     return $instance;
3197 }
3198
3199 =head2 $app->config_for( $component_name )
3200
3201 Return the application level configuration (which is not yet merged with any
3202 local component configuration, via $component_class->config) for the named
3203 component or component object. Example:
3204
3205     MyApp->config(
3206       'Model::Foo' => { a => 1, b => 2},
3207     );
3208
3209     my $config = MyApp->config_for('MyApp::Model::Foo');
3210
3211 In this case $config is the hashref C< {a=>1, b=>2} >.
3212
3213 This is also handy for looking up configuration for a plugin, to make sure you follow
3214 existing L<Catalyst> standards for where a plugin should put its configuration.
3215
3216 =cut
3217
3218 sub config_for {
3219     my ($class, $component_name) = @_;
3220     my $component_suffix = Catalyst::Utils::class2classsuffix($component_name);
3221     my $config = $class->config->{ $component_suffix } || {};
3222
3223     return $config;
3224 }
3225
3226 =head2 $c->setup_dispatcher
3227
3228 Sets up dispatcher.
3229
3230 =cut
3231
3232 sub setup_dispatcher {
3233     my ( $class, $dispatcher ) = @_;
3234
3235     if ($dispatcher) {
3236         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
3237     }
3238
3239     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
3240         $dispatcher = 'Catalyst::Dispatcher::' . $env;
3241     }
3242
3243     unless ($dispatcher) {
3244         $dispatcher = $class->dispatcher_class;
3245     }
3246
3247     load_class($dispatcher);
3248
3249     # dispatcher instance
3250     $class->dispatcher( $dispatcher->new );
3251 }
3252
3253 =head2 $c->setup_engine
3254
3255 Sets up engine.
3256
3257 =cut
3258
3259 sub engine_class {
3260     my ($class, $requested_engine) = @_;
3261
3262     if (!$class->engine_loader || $requested_engine) {
3263         $class->engine_loader(
3264             Catalyst::EngineLoader->new({
3265                 application_name => $class,
3266                 (defined $requested_engine
3267                      ? (catalyst_engine_class => $requested_engine) : ()),
3268             }),
3269         );
3270     }
3271
3272     $class->engine_loader->catalyst_engine_class;
3273 }
3274
3275 sub setup_engine {
3276     my ($class, $requested_engine) = @_;
3277
3278     my $engine = do {
3279         my $loader = $class->engine_loader;
3280
3281         if (!$loader || $requested_engine) {
3282             $loader = Catalyst::EngineLoader->new({
3283                 application_name => $class,
3284                 (defined $requested_engine
3285                      ? (requested_engine => $requested_engine) : ()),
3286             }),
3287
3288             $class->engine_loader($loader);
3289         }
3290
3291         $loader->catalyst_engine_class;
3292     };
3293
3294     # Don't really setup_engine -- see _setup_psgi_app for explanation.
3295     return if $class->loading_psgi_file;
3296
3297     load_class($engine);
3298
3299     if ($ENV{MOD_PERL}) {
3300         my $apache = $class->engine_loader->auto;
3301
3302         my $meta = find_meta($class);
3303         my $was_immutable = $meta->is_immutable;
3304         my %immutable_options = $meta->immutable_options;
3305         $meta->make_mutable if $was_immutable;
3306
3307         $meta->add_method(handler => sub {
3308             my $r = shift;
3309             my $psgi_app = $class->_finalized_psgi_app;
3310             $apache->call_app($r, $psgi_app);
3311         });
3312
3313         $meta->make_immutable(%immutable_options) if $was_immutable;
3314     }
3315
3316     $class->engine( $engine->new );
3317
3318     return;
3319 }
3320
3321 ## This exists just to supply a prebuild psgi app for mod_perl and for the
3322 ## build in server support (back compat support for pre psgi port behavior).
3323 ## This is so that we don't build a new psgi app for each request when using
3324 ## the mod_perl handler or the built in servers (http and fcgi, etc).
3325
3326 sub _finalized_psgi_app {
3327     my ($app) = @_;
3328
3329     unless ($app->_psgi_app) {
3330         my $psgi_app = $app->_setup_psgi_app;
3331         $app->_psgi_app($psgi_app);
3332     }
3333
3334     return $app->_psgi_app;
3335 }
3336
3337 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
3338 ## home directory and load that and return it (just assume it is doing the
3339 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
3340 ## in default_middleware and return it ( this is for backward compatibility
3341 ## with pre psgi port behavior ).
3342
3343 sub _setup_psgi_app {
3344     my ($app) = @_;
3345
3346     for my $home (Path::Class::Dir->new($app->config->{home})) {
3347         my $psgi_file = $home->file(
3348             Catalyst::Utils::appprefix($app) . '.psgi',
3349         );
3350
3351         next unless -e $psgi_file;
3352
3353         # If $psgi_file calls ->setup_engine, it's doing so to load
3354         # Catalyst::Engine::PSGI. But if it does that, we're only going to
3355         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
3356         # anyway. So set a flag (ick) that tells setup_engine not to populate
3357         # $c->engine or do any other things we might regret.
3358
3359         $app->loading_psgi_file(1);
3360         my $psgi_app = Plack::Util::load_psgi($psgi_file);
3361         $app->loading_psgi_file(0);
3362
3363         return $psgi_app
3364             unless $app->engine_loader->needs_psgi_engine_compat_hack;
3365
3366         warn <<"EOW";
3367 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
3368
3369 Its content has been ignored. Please consult the Catalyst::Upgrading
3370 documentation on how to upgrade from Catalyst::Engine::PSGI.
3371 EOW
3372     }
3373
3374     return $app->apply_default_middlewares($app->psgi_app);
3375 }
3376
3377 =head2 $c->apply_default_middlewares
3378
3379 Adds the following L<Plack> middlewares to your application, since they are
3380 useful and commonly needed:
3381
3382 L<Plack::Middleware::LighttpdScriptNameFix> (if you are using Lighttpd),
3383 L<Plack::Middleware::IIS6ScriptNameFix> (always applied since this middleware
3384 is smart enough to conditionally apply itself).
3385
3386 We will also automatically add L<Plack::Middleware::ReverseProxy> if we notice
3387 that your HTTP $env variable C<REMOTE_ADDR> is '127.0.0.1'.  This is usually
3388 an indication that your server is running behind a proxy frontend.  However in
3389 2014 this is often not the case.  We preserve this code for backwards compatibility
3390 however I B<highly> recommend that if you are running the server behind a front
3391 end proxy that you clearly indicate so with the C<using_frontend_proxy> configuration
3392 setting to true for your environment configurations that run behind a proxy.  This
3393 way if you change your front end proxy address someday your code would inexplicably
3394 stop working as expected.
3395
3396 Additionally if we detect we are using Nginx, we add a bit of custom middleware
3397 to solve some problems with the way that server handles $ENV{PATH_INFO} and
3398 $ENV{SCRIPT_NAME}.
3399
3400 Please B<NOTE> that if you do use C<using_frontend_proxy> the middleware is now
3401 adding via C<registered_middleware> rather than this method.
3402
3403 If you are using Lighttpd or IIS6 you may wish to apply these middlewares.  In
3404 general this is no longer a common case but we have this here for backward
3405 compatibility.
3406
3407 =cut
3408
3409
3410 sub apply_default_middlewares {
3411     my ($app, $psgi_app) = @_;
3412
3413     # Don't add this conditional IF we are explicitly saying we want the
3414     # frontend proxy support.  We don't need it here since if that is the
3415     # case it will be always loaded in the default_middleware.
3416
3417     unless($app->config->{using_frontend_proxy}) {
3418       $psgi_app = Plack::Middleware::Conditional->wrap(
3419           $psgi_app,
3420           builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
3421           condition => sub {
3422               my ($env) = @_;
3423               return if $app->config->{ignore_frontend_proxy};
3424               return $env->{REMOTE_ADDR} eq '127.0.0.1';
3425           },
3426       );
3427     }
3428
3429     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3430     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3431     $psgi_app = Plack::Middleware::Conditional->wrap(
3432         $psgi_app,
3433         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3434         condition => sub {
3435             my ($env) = @_;
3436             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3437             return unless $1 < 4.23;
3438             1;
3439         },
3440     );
3441
3442     # we're applying this unconditionally as the middleware itself already makes
3443     # sure it doesn't fuck things up if it's not running under one of the right
3444     # IIS versions
3445     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3446
3447     # And another IIS issue, this time with IIS7.
3448     $psgi_app = Plack::Middleware::Conditional->wrap(
3449         $psgi_app,
3450         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3451         condition => sub {
3452             my ($env) = @_;
3453             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3454         },
3455     );
3456
3457     return $psgi_app;
3458 }
3459
3460 =head2 App->psgi_app
3461
3462 =head2 App->to_app
3463
3464 Returns a PSGI application code reference for the catalyst application
3465 C<$c>. This is the bare application created without the C<apply_default_middlewares>
3466 method called.  We do however apply C<registered_middleware> since those are
3467 integral to how L<Catalyst> functions.  Also, unlike starting your application
3468 with a generated server script (via L<Catalyst::Devel> and C<catalyst.pl>) we do
3469 not attempt to return a valid L<PSGI> application using any existing C<${myapp}.psgi>
3470 scripts in your $HOME directory.
3471
3472 B<NOTE> C<apply_default_middlewares> was originally created when the first PSGI
3473 port was done for v5.90000.  These are middlewares that are added to achieve
3474 backward compatibility with older applications.  If you start your application
3475 using one of the supplied server scripts (generated with L<Catalyst::Devel> and
3476 the project skeleton script C<catalyst.pl>) we apply C<apply_default_middlewares>
3477 automatically.  This was done so that pre and post PSGI port applications would
3478 work the same way.
3479
3480 This is what you want to be using to retrieve the PSGI application code
3481 reference of your Catalyst application for use in a custom F<.psgi> or in your
3482 own created server modules.
3483
3484 =cut
3485
3486 *to_app = \&psgi_app;
3487
3488 sub psgi_app {
3489     my ($app) = @_;
3490     my $psgi = $app->engine->build_psgi_app($app);
3491     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3492 }
3493
3494 =head2 $c->setup_home
3495
3496 Sets up the home directory.
3497
3498 =cut
3499
3500 sub setup_home {
3501     my ( $class, $home ) = @_;
3502
3503     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3504         $home = $env;
3505     }
3506
3507     $home ||= Catalyst::Utils::home($class);
3508
3509     if ($home) {
3510         #I remember recently being scolded for assigning config values like this
3511         $class->config->{home} ||= $home;
3512         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3513     }
3514 }
3515
3516 =head2 $c->setup_encoding
3517
3518 Sets up the input/output encoding. See L<ENCODING>
3519
3520 =cut
3521
3522 sub setup_encoding {
3523     my $c = shift;
3524     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3525         # Ok, so the user has explicitly said "I don't want encoding..."
3526         return;
3527     } else {
3528       my $enc = defined($c->config->{encoding}) ?
3529         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3530       $c->encoding($enc);
3531     }
3532 }
3533
3534 =head2 handle_unicode_encoding_exception
3535
3536 Hook to let you customize how encoding errors are handled.  By default
3537 we just throw an exception.  Receives a hashref of debug information.
3538 Example:
3539
3540     $c->handle_unicode_encoding_exception({
3541         param_value => $value,
3542         error_msg => $_,
3543             encoding_step => 'params',
3544         });
3545
3546 =cut
3547
3548 sub handle_unicode_encoding_exception {
3549     my ( $self, $exception_ctx ) = @_;
3550     die $exception_ctx->{error_msg};
3551 }
3552
3553 # Some unicode helpers cargo culted from the old plugin.  These could likely
3554 # be neater.
3555
3556 sub _handle_unicode_decoding {
3557     my ( $self, $value ) = @_;
3558
3559     return unless defined $value;
3560
3561     ## I think this mess is to support the old nested
3562     if ( ref $value eq 'ARRAY' ) {
3563         foreach ( @$value ) {
3564             $_ = $self->_handle_unicode_decoding($_);
3565         }
3566         return $value;
3567     }
3568     elsif ( ref $value eq 'HASH' ) {
3569         foreach (keys %$value) {
3570             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3571             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3572
3573             # If the key was encoded we now have two (the original and current so
3574             # delete the original.
3575             delete $value->{$_} if $_ ne $encoded_key;
3576         }
3577         return $value;
3578     }
3579     else {
3580         return $self->_handle_param_unicode_decoding($value);
3581     }
3582 }
3583
3584 sub _handle_param_unicode_decoding {
3585     my ( $self, $value ) = @_;
3586     return unless defined $value; # not in love with just ignoring undefs - jnap
3587     return $value if blessed($value); #don't decode when the value is an object.
3588
3589     my $enc = $self->encoding;
3590     return try {
3591       $enc->decode( $value, $self->_encode_check );
3592     }
3593     catch {
3594         $self->handle_unicode_encoding_exception({
3595             param_value => $value,
3596             error_msg => $_,
3597             encoding_step => 'params',
3598         });
3599     };
3600 }
3601
3602 =head2 $c->setup_log
3603
3604 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3605 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3606 log to.
3607
3608 This method also installs a C<debug> method that returns a true value into the
3609 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3610 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3611
3612 Note that if the log has already been setup, by either a previous call to
3613 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3614 that this method won't actually set up the log object.
3615
3616 =cut
3617
3618 sub setup_log {
3619     my ( $class, $levels ) = @_;
3620
3621     $levels ||= '';
3622     $levels =~ s/^\s+//;
3623     $levels =~ s/\s+$//;
3624     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3625
3626     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3627     if ( defined $env_debug ) {
3628         $levels{debug} = 1 if $env_debug; # Ugly!
3629         delete($levels{debug}) unless $env_debug;
3630     }
3631
3632     unless ( $class->log ) {
3633         $class->log( Catalyst::Log->new(keys %levels) );
3634     }
3635
3636     if ( $levels{debug} ) {
3637         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3638         $class->log->debug('Debug messages enabled');
3639     }
3640 }
3641
3642 =head2 $c->setup_plugins
3643
3644 Sets up plugins.
3645
3646 =cut
3647
3648 =head2 $c->setup_stats
3649
3650 Sets up timing statistics class.
3651
3652 =cut
3653
3654 sub setup_stats {
3655     my ( $class, $stats ) = @_;
3656
3657     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3658
3659     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3660     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3661         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3662         $class->log->debug('Statistics enabled');
3663     }
3664 }
3665
3666
3667 =head2 $c->registered_plugins
3668
3669 Returns a sorted list of the plugins which have either been stated in the
3670 import list.
3671
3672 If passed a given plugin name, it will report a boolean value indicating
3673 whether or not that plugin is loaded.  A fully qualified name is required if
3674 the plugin name does not begin with C<Catalyst::Plugin::>.
3675
3676  if ($c->registered_plugins('Some::Plugin')) {
3677      ...
3678  }
3679
3680 =cut
3681
3682 {
3683
3684     sub registered_plugins {
3685         my $proto = shift;
3686         return sort keys %{ $proto->_plugins } unless @_;
3687         my $plugin = shift;
3688         return 1 if exists $proto->_plugins->{$plugin};
3689         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3690     }
3691
3692     sub _register_plugin {
3693         my ( $proto, $plugin, $instant ) = @_;
3694         my $class = ref $proto || $proto;
3695
3696         load_class( $plugin );
3697         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3698             if $plugin->isa( 'Catalyst::Component' );
3699         my $plugin_meta = Moose::Meta::Class->create($plugin);
3700         if (!$plugin_meta->has_method('new')
3701             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3702             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3703         }
3704         if (!$instant && !$proto->_plugins->{$plugin}) {
3705             my $meta = Class::MOP::get_metaclass_by_name($class);
3706             $meta->superclasses($plugin, $meta->superclasses);
3707         }
3708         $proto->_plugins->{$plugin} = 1;
3709         return $class;
3710     }
3711
3712     sub _default_plugins { return qw() }
3713
3714     sub setup_plugins {
3715         my ( $class, $plugins ) = @_;
3716
3717         $class->_plugins( {} ) unless $class->_plugins;
3718         $plugins = [ grep {
3719             m/Unicode::Encoding/ ? do {
3720                 $class->log->warn(
3721                     'Unicode::Encoding plugin is auto-applied,'
3722                     . ' please remove this from your appclass'
3723                     . ' and make sure to define "encoding" config'
3724                 );
3725                 unless (exists $class->config->{'encoding'}) {
3726                   $class->config->{'encoding'} = 'UTF-8';
3727                 }
3728                 () }
3729                 : $_
3730         } @$plugins ];
3731         push @$plugins, $class->_default_plugins;
3732         $plugins = Data::OptList::mkopt($plugins || []);
3733
3734         my @plugins = map {
3735             [ Catalyst::Utils::resolve_namespace(
3736                   $class . '::Plugin',
3737                   'Catalyst::Plugin', $_->[0]
3738               ),
3739               $_->[1],
3740             ]
3741          } @{ $plugins };
3742
3743         for my $plugin ( reverse @plugins ) {
3744             load_class($plugin->[0], $plugin->[1]);
3745             my $meta = find_meta($plugin->[0]);
3746             next if $meta && $meta->isa('Moose::Meta::Role');
3747
3748             $class->_register_plugin($plugin->[0]);
3749         }
3750
3751         my @roles =
3752             map  { $_->[0]->name, $_->[1] }
3753             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3754             map  { [find_meta($_->[0]), $_->[1]] }
3755             @plugins;
3756
3757         Moose::Util::apply_all_roles(
3758             $class => @roles
3759         ) if @roles;
3760     }
3761 }
3762
3763 =head2 default_middleware
3764
3765 Returns a list of instantiated PSGI middleware objects which is the default
3766 middleware that is active for this application (taking any configuration
3767 options into account, excluding your custom added middleware via the C<psgi_middleware>
3768 configuration option).  You can override this method if you wish to change
3769 the default middleware (although do so at risk since some middleware is vital
3770 to application function.)
3771
3772 The current default middleware list is:
3773
3774       Catalyst::Middleware::Stash
3775       Plack::Middleware::HTTPExceptions
3776       Plack::Middleware::RemoveRedundantBody
3777       Plack::Middleware::FixMissingBodyInRedirect
3778       Plack::Middleware::ContentLength
3779       Plack::Middleware::MethodOverride
3780       Plack::Middleware::Head
3781
3782 If the configuration setting C<using_frontend_proxy> is true we add:
3783
3784       Plack::Middleware::ReverseProxy
3785
3786 If the configuration setting C<using_frontend_proxy_path> is true we add:
3787
3788       Plack::Middleware::ReverseProxyPath
3789
3790 But B<NOTE> that L<Plack::Middleware::ReverseProxyPath> is not a dependency of the
3791 L<Catalyst> distribution so if you want to use this option you should add it to
3792 your project distribution file.
3793
3794 These middlewares will be added at L</setup_middleware> during the
3795 L</setup> phase of application startup.
3796
3797 =cut
3798
3799 sub default_middleware {
3800     my $class = shift;
3801     my @mw = (
3802       Catalyst::Middleware::Stash->new,
3803       Plack::Middleware::HTTPExceptions->new,
3804       Plack::Middleware::RemoveRedundantBody->new,
3805       Plack::Middleware::FixMissingBodyInRedirect->new,
3806       Plack::Middleware::ContentLength->new,
3807       Plack::Middleware::MethodOverride->new,
3808       Plack::Middleware::Head->new);
3809
3810     if($class->config->{using_frontend_proxy}) {
3811         push @mw, Plack::Middleware::ReverseProxy->new;
3812     }
3813
3814     if($class->config->{using_frontend_proxy_path}) {
3815         if(Class::Load::try_load_class('Plack::Middleware::ReverseProxyPath')) {
3816             push @mw, Plack::Middleware::ReverseProxyPath->new;
3817         } else {
3818           $class->log->error("Cannot use configuration 'using_frontend_proxy_path' because 'Plack::Middleware::ReverseProxyPath' is not installed");
3819         }
3820     }
3821
3822     return @mw;
3823 }
3824
3825 =head2 registered_middlewares
3826
3827 Read only accessor that returns an array of all the middleware in the order
3828 that they were added (which is the REVERSE of the order they will be applied).
3829
3830 The values returned will be either instances of L<Plack::Middleware> or of a
3831 compatible interface, or a coderef, which is assumed to be inlined middleware
3832
3833 =head2 setup_middleware (?@middleware)
3834
3835 Read configuration information stored in configuration key C<psgi_middleware> or
3836 from passed @args.
3837
3838 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3839 to use it to enable L<Plack::Middleware>
3840
3841 This method is automatically called during 'setup' of your application, so
3842 you really don't need to invoke it.  However you may do so if you find the idea
3843 of loading middleware via configuration weird :).  For example:
3844
3845     package MyApp;
3846
3847     use Catalyst;
3848
3849     __PACKAGE__->setup_middleware('Head');
3850     __PACKAGE__->setup;
3851
3852 When we read middleware definitions from configuration, we reverse the list
3853 which sounds odd but is likely how you expect it to work if you have prior
3854 experience with L<Plack::Builder> or if you previously used the plugin
3855 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3856
3857 So basically your middleware handles an incoming request from the first
3858 registered middleware, down and handles the response from the last middleware
3859 up.
3860
3861 =cut
3862
3863 sub registered_middlewares {
3864     my $class = shift;
3865     if(my $middleware = $class->_psgi_middleware) {
3866         my @mw = ($class->default_middleware, @$middleware);
3867
3868         if($class->config->{using_frontend_proxy}) {
3869           push @mw, Plack::Middleware::ReverseProxy->new;
3870         }
3871
3872         return @mw;
3873     } else {
3874         die "You cannot call ->registered_middlewares until middleware has been setup";
3875     }
3876 }
3877
3878 sub setup_middleware {
3879     my $class = shift;
3880     my @middleware_definitions;
3881
3882     # If someone calls this method you can add middleware with args.  However if its
3883     # called without an arg we need to setup the configuration middleware.
3884     if(@_) {
3885       @middleware_definitions = reverse(@_);
3886     } else {
3887       @middleware_definitions = reverse(@{$class->config->{'psgi_middleware'}||[]})
3888         unless $class->finalized_default_middleware;
3889       $class->finalized_default_middleware(1); # Only do this once, just in case some people call setup over and over...
3890     }
3891
3892     my @middleware = ();
3893     while(my $next = shift(@middleware_definitions)) {
3894         if(ref $next) {
3895             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3896                 push @middleware, $next;
3897             } elsif(ref $next eq 'CODE') {
3898                 push @middleware, $next;
3899             } elsif(ref $next eq 'HASH') {
3900                 my $namespace = shift @middleware_definitions;
3901                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3902                 push @middleware, $mw;
3903             } else {
3904               die "I can't handle middleware definition ${\ref $next}";
3905             }
3906         } else {
3907           my $mw = $class->Catalyst::Utils::build_middleware($next);
3908           push @middleware, $mw;
3909         }
3910     }
3911
3912     my @existing = @{$class->_psgi_middleware || []};
3913     $class->_psgi_middleware([@middleware,@existing,]);
3914 }
3915
3916 =head2 registered_data_handlers
3917
3918 A read only copy of registered Data Handlers returned as a Hash, where each key
3919 is a content type and each value is a subref that attempts to decode that content
3920 type.
3921
3922 =head2 setup_data_handlers (?@data_handler)
3923
3924 Read configuration information stored in configuration key C<data_handlers> or
3925 from passed @args.
3926
3927 See under L</CONFIGURATION> information regarding C<data_handlers>.
3928
3929 This method is automatically called during 'setup' of your application, so
3930 you really don't need to invoke it.
3931
3932 =head2 default_data_handlers
3933
3934 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3935 only two default data handlers, for 'application/json' and an alternative to
3936 'application/x-www-form-urlencoded' which supposed nested form parameters via
3937 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3938
3939 The 'application/json' data handler is used to parse incoming JSON into a Perl
3940 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3941 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3942 JSON decoder, and has the smallest dependency impact.
3943
3944 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3945 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3946 order to get the best performance.  You should add either to your dependency
3947 list (Makefile.PL, dist.ini, cpanfile, etc.)
3948
3949 =cut
3950
3951 sub registered_data_handlers {
3952     my $class = shift;
3953     if(my $data_handlers = $class->_data_handlers) {
3954         return %$data_handlers;
3955     } else {
3956         $class->setup_data_handlers;
3957         return $class->registered_data_handlers;
3958     }
3959 }
3960
3961 sub setup_data_handlers {
3962     my ($class, %data_handler_callbacks) = @_;
3963     %data_handler_callbacks = (
3964       %{$class->default_data_handlers},
3965       %{$class->config->{'data_handlers'}||+{}},
3966       %data_handler_callbacks);
3967
3968     $class->_data_handlers(\%data_handler_callbacks);
3969 }
3970
3971 sub default_data_handlers {
3972     my ($class) = @_;
3973     return +{
3974       'application/x-www-form-urlencoded' => sub {
3975           my ($fh, $req) = @_;
3976           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3977           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3978             ->can('build_cgi_struct')->($params);
3979       },
3980       'application/json' => sub {
3981           my ($fh, $req) = @_;
3982           my $parser = Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON');
3983           my $slurped;
3984           return eval {
3985             local $/;
3986             $slurped = $fh->getline;
3987             $parser->can("decode_json")->($slurped); # decode_json does utf8 decoding for us
3988           } || Catalyst::Exception->throw(sprintf "Error Parsing POST '%s', Error: %s", (defined($slurped) ? $slurped : 'undef') ,$@);
3989         },
3990     };
3991 }
3992
3993 sub _handle_http_exception {
3994     my ( $self, $error ) = @_;
3995     if (
3996            !$self->config->{always_catch_http_exceptions}
3997         && blessed $error
3998         && (
3999             $error->can('as_psgi')
4000             || (   $error->can('code')
4001                 && $error->code =~ m/^[1-5][0-9][0-9]$/ )
4002         )
4003       )
4004     {
4005         return 1;
4006     }
4007 }
4008
4009 =head2 $c->stack
4010
4011 Returns an arrayref of the internal execution stack (actions that are
4012 currently executing).
4013
4014 =head2 $c->stats
4015
4016 Returns the current timing statistics object. By default Catalyst uses
4017 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
4018 L<< stats_class|/"$c->stats_class" >>.
4019
4020 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
4021 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
4022 profile explicitly, although MyApp.pm still won't profile nor output anything
4023 by itself.
4024
4025 =head2 $c->stats_class
4026
4027 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
4028
4029 =head2 $app->stats_class_traits
4030
4031 A arrayref of L<Moose::Role>s that are applied to the stats_class before creating it.
4032
4033 =head2 $app->composed_stats_class
4034
4035 this is the stats_class composed with any 'stats_class_traits'.  You can
4036 name the full namespace of the role, or a namespace suffix, which will then
4037 be tried against the following standard namespace prefixes.
4038
4039     $MyApp::TraitFor::Stats::$trait_suffix
4040     Catalyst::TraitFor::Stats::$trait_suffix
4041
4042 So for example if you set:
4043
4044     MyApp->stats_class_traits(['Foo']);
4045
4046 We try each possible role in turn (and throw an error if none load)
4047
4048     Foo
4049     MyApp::TraitFor::Stats::Foo
4050     Catalyst::TraitFor::Stats::Foo
4051
4052 The namespace part 'TraitFor::Stats' was chosen to assist in backwards
4053 compatibility with L<CatalystX::RoleApplicator> which previously provided
4054 these features in a stand alone package.
4055
4056 =head2 $c->use_stats
4057
4058 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
4059
4060 Note that this is a static method, not an accessor and should be overridden
4061 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
4062
4063 =cut
4064
4065 sub use_stats { 0 }
4066
4067
4068 =head2 $c->write( $data )
4069
4070 Writes $data to the output stream. When using this method directly, you
4071 will need to manually set the C<Content-Length> header to the length of
4072 your output data, if known.
4073
4074 =cut
4075
4076 sub write {
4077     my $c = shift;
4078
4079     # Finalize headers if someone manually writes output (for compat)
4080     $c->finalize_headers;
4081
4082     return $c->response->write( @_ );
4083 }
4084
4085 =head2 version
4086
4087 Returns the Catalyst version number. Mostly useful for "powered by"
4088 messages in template systems.
4089
4090 =cut
4091
4092 sub version { return $Catalyst::VERSION }
4093
4094 =head1 CONFIGURATION
4095
4096 There are a number of 'base' config variables which can be set:
4097
4098 =over
4099
4100 =item *
4101
4102 C<always_catch_http_exceptions> - As of version 5.90060 Catalyst
4103 rethrows errors conforming to the interface described by
4104 L<Plack::Middleware::HTTPExceptions> and lets the middleware deal with it.
4105 Set true to get the deprecated behaviour and have Catalyst catch HTTP exceptions.
4106
4107 =item *
4108
4109 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
4110
4111 =item *
4112
4113 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
4114
4115 =item *
4116
4117 C<disable_component_resolution_regex_fallback> - Turns
4118 off the deprecated component resolution functionality so
4119 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
4120 are called then regex search will not be attempted on string values and
4121 instead C<undef> will be returned.
4122
4123 =item *
4124
4125 C<home> - The application home directory. In an uninstalled application,
4126 this is the top level application directory. In an installed application,
4127 this will be the directory containing C<< MyApp.pm >>.
4128
4129 =item *
4130
4131 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
4132
4133 =item *
4134
4135 C<name> - The name of the application in debug messages and the debug and
4136 welcome screens
4137
4138 =item *
4139
4140 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
4141 until it is accessed. This allows you to (for example) check authentication (and reject
4142 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
4143
4144 =item *
4145
4146 C<root> - The root directory for templates. Usually this is just a
4147 subdirectory of the home directory, but you can set it to change the
4148 templates to a different directory.
4149
4150 =item *
4151
4152 C<search_extra> - Array reference passed to Module::Pluggable to for additional
4153 namespaces from which components will be loaded (and constructed and stored in
4154 C<< $c->components >>).
4155
4156 =item *
4157
4158 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
4159 to be shown in hit debug tables in the test server.
4160
4161 =item *
4162
4163 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
4164 variable should be used for determining the request path.
4165
4166 Most web server environments pass the requested path to the application using environment variables,
4167 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
4168 exposed as C<< $c->request->base >>) and the request path below that base.
4169
4170 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
4171 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
4172
4173 =over
4174
4175 =item use_request_uri_for_path => 0
4176
4177 This is the default (and the) traditional method that Catalyst has used for determining the path information.
4178 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
4179 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
4180 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
4181
4182 However this method has the major disadvantage that it is impossible to correctly decode some elements
4183 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
4184 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
4185 can't distinguish / vs %2F in paths (in addition to other encoded values).
4186
4187 =item use_request_uri_for_path => 1
4188
4189 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
4190 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
4191 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
4192
4193 Given that this method of path resolution is provably more correct, it is recommended that you use
4194 this unless you have a specific need to deploy your application in a non-standard environment, and you are
4195 aware of the implications of not being able to handle encoded URI paths correctly.
4196
4197 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
4198 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
4199 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
4200 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
4201 C<< $c->request->base >> will be incorrect.
4202
4203 =back
4204
4205 =item *
4206
4207 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
4208
4209 =item *
4210
4211 C<using_frontend_proxy_path> - Enabled L<Plack::Middleware::ReverseProxyPath> on your application (if
4212 installed, otherwise log an error).  This is useful if your application is not running on the
4213 'root' (or /) of your host server.  B<NOTE> if you use this feature you should add the required
4214 middleware to your project dependency list since its not automatically a dependency of L<Catalyst>.
4215 This has been done since not all people need this feature and we wish to restrict the growth of
4216 L<Catalyst> dependencies.
4217
4218 =item *
4219
4220 C<encoding> - See L</ENCODING>
4221
4222 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
4223 value to undef.
4224
4225 =item *
4226
4227 C<abort_chain_on_error_fix>
4228
4229 When there is an error in an action chain, the default behavior is to continue
4230 processing the remaining actions and then catch the error upon chain end.  This
4231 can lead to running actions when the application is in an unexpected state.  If
4232 you have this issue, setting this config value to true will promptly exit a
4233 chain when there is an error raised in any action (thus terminating the chain
4234 early.)
4235
4236 use like:
4237
4238     __PACKAGE__->config(abort_chain_on_error_fix => 1);
4239
4240 In the future this might become the default behavior.
4241
4242 =item *
4243
4244 C<use_hash_multivalue_in_request>
4245
4246 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
4247 and C<parameters> return a hashref where values might be scalar or an arrayref
4248 depending on the incoming data.  In many cases this can be undesirable as it
4249 leads one to writing defensive code like the following:
4250
4251     my ($val) = ref($c->req->parameters->{a}) ?
4252       @{$c->req->parameters->{a}} :
4253         $c->req->parameters->{a};
4254
4255 Setting this configuration item to true will make L<Catalyst> populate the
4256 attributes underlying these methods with an instance of L<Hash::MultiValue>
4257 which is used by L<Plack::Request> and others to solve this very issue.  You
4258 may prefer this behavior to the default, if so enable this option (be warned
4259 if you enable it in a legacy application we are not sure if it is completely
4260 backwardly compatible).
4261
4262 =item *
4263
4264 C<skip_complex_post_part_handling>
4265
4266 When creating body parameters from a POST, if we run into a multipart POST
4267 that does not contain uploads, but instead contains inlined complex data
4268 (very uncommon) we cannot reliably convert that into field => value pairs.  So
4269 instead we create an instance of L<Catalyst::Request::PartData>.  If this causes
4270 issue for you, you can disable this by setting C<skip_complex_post_part_handling>
4271 to true (default is false).
4272
4273 =item *
4274
4275 C<skip_body_param_unicode_decoding>
4276
4277 Generally we decode incoming POST params based on your declared encoding (the
4278 default for this is to decode UTF-8).  If this is causing you trouble and you
4279 do not wish to turn all encoding support off (with the C<encoding> configuration
4280 parameter) you may disable this step atomically by setting this configuration
4281 parameter to true.
4282
4283 =item *
4284
4285 C<do_not_decode_query>
4286
4287 If true, then do not try to character decode any wide characters in your
4288 request URL query or keywords.  Most readings of the relevant specifications
4289 suggest these should be UTF-* encoded, which is the default that L<Catalyst>
4290 will use, however if you are creating a lot of URLs manually or have external
4291 evil clients, this might cause you trouble.  If you find the changes introduced
4292 in Catalyst version 5.90080+ break some of your query code, you may disable
4293 the UTF-8 decoding globally using this configuration.
4294
4295 This setting takes precedence over C<default_query_encoding> and
4296 C<decode_query_using_global_encoding>
4297
4298 =item *
4299
4300 C<default_query_encoding>
4301
4302 By default we decode query and keywords in your request URL using UTF-8, which
4303 is our reading of the relevant specifications.  This setting allows one to
4304 specify a fixed value for how to decode your query.  You might need this if
4305 you are doing a lot of custom encoding of your URLs and not using UTF-8.
4306
4307 This setting take precedence over C<decode_query_using_global_encoding>.
4308
4309 =item *
4310
4311 C<decode_query_using_global_encoding>
4312
4313 Setting this to true will default your query decoding to whatever your
4314 general global encoding is (the default is UTF-8).
4315
4316 =item *
4317
4318 C<use_chained_args_0_special_case>
4319
4320 In older versions of Catalyst, when more than one action matched the same path
4321 AND all those matching actions declared Args(0), we'd break the tie by choosing
4322 the first action defined.  We now normalized how Args(0) works so that it
4323 follows the same rule as Args(N), which is to say when we need to break a tie
4324 we choose the LAST action defined.  If this breaks your code and you don't
4325 have time to update to follow the new normalized approach, you may set this
4326 value to true and it will globally revert to the original chaining behavior.
4327
4328 =item *
4329
4330 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
4331
4332 =item *
4333
4334 C<data_handlers> - See L<DATA HANDLERS>.
4335
4336 =item *
4337
4338 C<stats_class_traits>
4339
4340 An arrayref of L<Moose::Role>s that get composed into your stats class.
4341
4342 =item *
4343
4344 C<request_class_traits>
4345
4346 An arrayref of L<Moose::Role>s that get composed into your request class.
4347
4348 =item *
4349
4350 C<response_class_traits>
4351
4352 An arrayref of L<Moose::Role>s that get composed into your response class.
4353
4354 =item *
4355
4356 C<inject_components>
4357
4358 A Hashref of L<Catalyst::Component> subclasses that are 'injected' into configuration.
4359 For example:
4360
4361     MyApp->config({
4362       inject_components => {
4363         'Controller::Err' => { from_component => 'Local::Controller::Errors' },
4364         'Model::Zoo' => { from_component => 'Local::Model::Foo' },
4365         'Model::Foo' => { from_component => 'Local::Model::Foo', roles => ['TestRole'] },
4366       },
4367       'Controller::Err' => { a => 100, b=>200, namespace=>'error' },
4368       'Model::Zoo' => { a => 2 },
4369       'Model::Foo' => { a => 100 },
4370     });
4371
4372 Generally L<Catalyst> looks for components in your Model/View or Controller directories.
4373 However for cases when you which to use an existing component and you don't need any
4374 customization (where for when you can apply a role to customize it) you may inject those
4375 components into your application.  Please note any configuration should be done 'in the
4376 normal way', with a key under configuration named after the component affix, as in the
4377 above example.
4378
4379 Using this type of injection allows you to construct significant amounts of your application
4380 with only configuration!.  This may or may not lead to increased code understanding.
4381
4382 Please not you may also call the ->inject_components application method as well, although
4383 you must do so BEFORE setup.
4384
4385 =back
4386
4387 =head1 EXCEPTIONS
4388
4389 Generally when you throw an exception inside an Action (or somewhere in
4390 your stack, such as in a model that an Action is calling) that exception
4391 is caught by Catalyst and unless you either catch it yourself (via eval
4392 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
4393 will eventually reach L</finalize_errors> and return either the debugging
4394 error stack page, or the default error page.  However, if your exception
4395 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
4396 instead rethrow it so that it can be handled by that middleware (which
4397 is part of the default middleware).  For example this would allow
4398
4399     use HTTP::Throwable::Factory 'http_throw';
4400
4401     sub throws_exception :Local {
4402       my ($self, $c) = @_;
4403
4404       http_throw(SeeOther => { location =>
4405         $c->uri_for($self->action_for('redirect')) });
4406
4407     }
4408
4409 =head1 INTERNAL ACTIONS
4410
4411 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
4412 C<_ACTION>, and C<_END>. These are by default not shown in the private
4413 action table, but you can make them visible with a config parameter.
4414
4415     MyApp->config(show_internal_actions => 1);
4416
4417 =head1 ON-DEMAND PARSER
4418
4419 The request body is usually parsed at the beginning of a request,
4420 but if you want to handle input yourself, you can enable on-demand
4421 parsing with a config parameter.
4422
4423     MyApp->config(parse_on_demand => 1);
4424
4425 =head1 PROXY SUPPORT
4426
4427 Many production servers operate using the common double-server approach,
4428 with a lightweight frontend web server passing requests to a larger
4429 backend server. An application running on the backend server must deal
4430 with two problems: the remote user always appears to be C<127.0.0.1> and
4431 the server's hostname will appear to be C<localhost> regardless of the
4432 virtual host that the user connected through.
4433
4434 Catalyst will automatically detect this situation when you are running
4435 the frontend and backend servers on the same machine. The following
4436 changes are made to the request.
4437
4438     $c->req->address is set to the user's real IP address, as read from
4439     the HTTP X-Forwarded-For header.
4440
4441     The host value for $c->req->base and $c->req->uri is set to the real
4442     host, as read from the HTTP X-Forwarded-Host header.
4443
4444 Additionally, you may be running your backend application on an insecure
4445 connection (port 80) while your frontend proxy is running under SSL.  If there
4446 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
4447 tell Catalyst what port the frontend listens on.  This will allow all URIs to
4448 be created properly.
4449
4450 In the case of passing in:
4451
4452     X-Forwarded-Port: 443
4453
4454 All calls to C<uri_for> will result in an https link, as is expected.
4455
4456 Obviously, your web server must support these headers for this to work.
4457
4458 In a more complex server farm environment where you may have your
4459 frontend proxy server(s) on different machines, you will need to set a
4460 configuration option to tell Catalyst to read the proxied data from the
4461 headers.
4462
4463     MyApp->config(using_frontend_proxy => 1);
4464
4465 If you do not wish to use the proxy support at all, you may set:
4466
4467     MyApp->config(ignore_frontend_proxy => 0);
4468
4469 =head2 Note about psgi files
4470
4471 Note that if you supply your own .psgi file, calling
4472 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
4473
4474 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
4475 in your psgi, for example:
4476
4477     builder {
4478         enable "Plack::Middleware::ReverseProxy";
4479         MyApp->psgi_app
4480     };
4481
4482 This will unconditionally add the ReverseProxy support, or you need to call
4483 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
4484 apply the support depending upon your config).
4485
4486 See L<Catalyst::PSGI> for more information.
4487
4488 =head1 THREAD SAFETY
4489
4490 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
4491 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
4492 believe the Catalyst core to be thread-safe.
4493
4494 If you plan to operate in a threaded environment, remember that all other
4495 modules you are using must also be thread-safe. Some modules, most notably
4496 L<DBD::SQLite>, are not thread-safe.
4497
4498 =head1 DATA HANDLERS
4499
4500 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
4501 form parameters and URL search query fields.  However it has become common
4502 for various alternative content types to be PUT or POSTed to your controllers
4503 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
4504 XML and other content types when communicating with an application server.  In
4505 order to better support this use case, L<Catalyst> defines a global configuration
4506 option, C<data_handlers>, which lets you associate a content type with a coderef
4507 that parses that content type into something Perl can readily access.
4508
4509     package MyApp::Web;
4510
4511     use Catalyst;
4512     use JSON::Maybe;
4513
4514     __PACKAGE__->config(
4515       data_handlers => {
4516         'application/json' => sub { local $/; decode_json $_->getline },
4517       },
4518       ## Any other configuration.
4519     );
4520
4521     __PACKAGE__->setup;
4522
4523 By default L<Catalyst> comes with a generic JSON data handler similar to the
4524 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
4525 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
4526 it installed (if you want the faster XS parser, add it to you project Makefile.PL
4527 or dist.ini, cpanfile, etc.)
4528
4529 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
4530 (matched against the incoming request type using a regexp such as to be case
4531 insensitive) and whose values are coderefs that receive a localized version of
4532 C<$_> which is a filehandle object pointing to received body.
4533
4534 This feature is considered an early access release and we reserve the right
4535 to alter the interface in order to provide a performant and secure solution to
4536 alternative request body content.  Your reports welcomed!
4537
4538 =head1 PSGI MIDDLEWARE
4539
4540 You can define middleware, defined as L<Plack::Middleware> or a compatible
4541 interface in configuration.  Your middleware definitions are in the form of an
4542 arrayref under the configuration key C<psgi_middleware>.  Here's an example
4543 with details to follow:
4544
4545     package MyApp::Web;
4546
4547     use Catalyst;
4548     use Plack::Middleware::StackTrace;
4549
4550     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4551
4552     __PACKAGE__->config(
4553       'psgi_middleware', [
4554         'Debug',
4555         '+MyApp::Custom',
4556         $stacktrace_middleware,
4557         'Session' => {store => 'File'},
4558         sub {
4559           my $app = shift;
4560           return sub {
4561             my $env = shift;
4562             $env->{myapp.customkey} = 'helloworld';
4563             $app->($env);
4564           },
4565         },
4566       ],
4567     );
4568
4569     __PACKAGE__->setup;
4570
4571 So the general form is:
4572
4573     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
4574
4575 Where C<@middleware> is one or more of the following, applied in the REVERSE of
4576 the order listed (to make it function similarly to L<Plack::Builder>:
4577
4578 Alternatively, you may also define middleware by calling the L</setup_middleware>
4579 package method:
4580
4581     package MyApp::Web;
4582
4583     use Catalyst;
4584
4585     __PACKAGE__->setup_middleware( \@middleware_definitions);
4586     __PACKAGE__->setup;
4587
4588 In the case where you do both (use 'setup_middleware' and configuration) the
4589 package call to setup_middleware will be applied earlier (in other words its
4590 middleware will wrap closer to the application).  Keep this in mind since in
4591 some cases the order of middleware is important.
4592
4593 The two approaches are not exclusive.
4594
4595 =over 4
4596
4597 =item Middleware Object
4598
4599 An already initialized object that conforms to the L<Plack::Middleware>
4600 specification:
4601
4602     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4603
4604     __PACKAGE__->config(
4605       'psgi_middleware', [
4606         $stacktrace_middleware,
4607       ]);
4608
4609
4610 =item coderef
4611
4612 A coderef that is an inlined middleware:
4613
4614     __PACKAGE__->config(
4615       'psgi_middleware', [
4616         sub {
4617           my $app = shift;
4618           return sub {
4619             my $env = shift;
4620             if($env->{PATH_INFO} =~m/forced/) {
4621               Plack::App::File
4622                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
4623                 ->call($env);
4624             } else {
4625               return $app->($env);
4626             }
4627          },
4628       },
4629     ]);
4630
4631
4632
4633 =item a scalar
4634
4635 We assume the scalar refers to a namespace after normalizing it using the
4636 following rules:
4637
4638 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
4639 is assumed to be 'as is', and we just install and use the middleware.
4640
4641 (2) If the scalar begins with "Plack::Middleware" or your application namespace
4642 (the package name of your Catalyst application subclass), we also assume then
4643 that it is a full namespace, and use it.
4644
4645 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
4646 resolve it first by looking for it under your application namespace (for example
4647 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
4648 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
4649 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
4650 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
4651 namespace first to let you 'override' common L<Plack::Middleware> locally, should
4652 you find that a good idea.
4653
4654 Examples:
4655
4656     package MyApp::Web;
4657
4658     __PACKAGE__->config(
4659       'psgi_middleware', [
4660         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
4661         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
4662         '+MyApp::Custom',  ## MyApp::Custom->wrap
4663       ],
4664     );
4665
4666 =item a scalar followed by a hashref
4667
4668 Just like the previous, except the following C<HashRef> is used as arguments
4669 to initialize the middleware object.
4670
4671     __PACKAGE__->config(
4672       'psgi_middleware', [
4673          'Session' => {store => 'File'},
4674     ]);
4675
4676 =back
4677
4678 Please see L<PSGI> for more on middleware.
4679
4680 =head1 ENCODING
4681
4682 Starting in L<Catalyst> version 5.90080 encoding is automatically enabled
4683 and set to encode all body responses to UTF8 when possible and applicable.
4684 Following is documentation on this process.  If you are using an older
4685 version of L<Catalyst> you should review documentation for that version since
4686 a lot has changed.
4687
4688 By default encoding is now 'UTF-8'.  You may turn it off by setting
4689 the encoding configuration to undef.
4690
4691     MyApp->config(encoding => undef);
4692
4693 This is recommended for temporary backwards compatibility only.
4694
4695 Encoding is automatically applied when the content-type is set to
4696 a type that can be encoded.  Currently we encode when the content type
4697 matches the following regular expression:
4698
4699     $content_type =~ /^text|xml$|javascript$/
4700
4701 Encoding is set on the application, but it is copied to the context object
4702 so that you can override it on a request basis.
4703
4704 Be default we don't automatically encode 'application/json' since the most
4705 common approaches to generating this type of response (Either via L<Catalyst::View::JSON>
4706 or L<Catalyst::Action::REST>) will do so already and we want to avoid double
4707 encoding issues.
4708
4709 If you are producing JSON response in an unconventional manner (such
4710 as via a template or manual strings) you should perform the UTF8 encoding
4711 manually as well such as to conform to the JSON specification.
4712
4713 NOTE: We also examine the value of $c->response->content_encoding.  If
4714 you set this (like for example 'gzip', and manually gzipping the body)
4715 we assume that you have done all the necessary encoding yourself, since
4716 we cannot encode the gzipped contents.  If you use a plugin like
4717 L<Catalyst::Plugin::Compress> you need to update to a modern version in order
4718 to have this function correctly  with the new UTF8 encoding code, or you
4719 can use L<Plack::Middleware::Deflater> or (probably best) do your compression on
4720 a front end proxy.
4721
4722 =head2 Methods
4723
4724 =over 4
4725
4726 =item encoding
4727
4728 Returns an instance of an C<Encode> encoding
4729
4730     print $c->encoding->name
4731
4732 =item handle_unicode_encoding_exception ($exception_context)
4733
4734 Method called when decoding process for a request fails.
4735
4736 An C<$exception_context> hashref is provided to allow you to override the
4737 behaviour of your application when given data with incorrect encodings.
4738
4739 The default method throws exceptions in the case of invalid request parameters
4740 (resulting in a 500 error), but ignores errors in upload filenames.
4741
4742 The keys passed in the C<$exception_context> hash are:
4743
4744 =over
4745
4746 =item param_value
4747
4748 The value which was not able to be decoded.
4749
4750 =item error_msg
4751
4752 The exception received from L<Encode>.
4753
4754 =item encoding_step
4755
4756 What type of data was being decoded. Valid values are (currently)
4757 C<params> - for request parameters / arguments / captures
4758 and C<uploads> - for request upload filenames.
4759
4760 =back
4761
4762 =back
4763
4764 =head1 SUPPORT
4765
4766 IRC:
4767
4768     Join #catalyst on irc.perl.org.
4769
4770 Mailing Lists:
4771
4772     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4773     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4774
4775 Web:
4776
4777     http://catalyst.perl.org
4778
4779 Wiki:
4780
4781     http://dev.catalyst.perl.org
4782
4783 =head1 SEE ALSO
4784
4785 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4786
4787 =head2 L<Catalyst::Manual> - The Catalyst Manual
4788
4789 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4790
4791 =head2 L<Catalyst::Engine> - Core engine
4792
4793 =head2 L<Catalyst::Log> - Log class.
4794
4795 =head2 L<Catalyst::Request> - Request object
4796
4797 =head2 L<Catalyst::Response> - Response object
4798
4799 =head2 L<Catalyst::Test> - The test suite.
4800
4801 =head1 PROJECT FOUNDER
4802
4803 sri: Sebastian Riedel <sri@cpan.org>
4804
4805 =head1 CONTRIBUTORS
4806
4807 abw: Andy Wardley
4808
4809 acme: Leon Brocard <leon@astray.com>
4810
4811 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4812
4813 andrewalker: André Walker <andre@cpan.org>
4814
4815 Andrew Bramble
4816
4817 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4818
4819 Andrew Ruthven
4820
4821 andyg: Andy Grundman <andy@hybridized.org>
4822
4823 audreyt: Audrey Tang
4824
4825 bricas: Brian Cassidy <bricas@cpan.org>
4826
4827 Caelum: Rafael Kitover <rkitover@io.com>
4828
4829 chansen: Christian Hansen
4830
4831 Chase Venters C<chase.venters@gmail.com>
4832
4833 chicks: Christopher Hicks
4834
4835 Chisel Wright C<pause@herlpacker.co.uk>
4836
4837 Danijel Milicevic C<me@danijel.de>
4838
4839 davewood: David Schmidt <davewood@cpan.org>
4840
4841 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4842
4843 David Naughton, C<naughton@umn.edu>
4844
4845 David E. Wheeler
4846
4847 dhoss: Devin Austin <dhoss@cpan.org>
4848
4849 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4850
4851 Drew Taylor
4852
4853 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4854
4855 esskar: Sascha Kiefer
4856
4857 fireartist: Carl Franks <cfranks@cpan.org>
4858
4859 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4860
4861 gabb: Danijel Milicevic
4862
4863 Gary Ashton Jones
4864
4865 Gavin Henry C<ghenry@perl.me.uk>
4866
4867 Geoff Richards
4868
4869 groditi: Guillermo Roditi <groditi@gmail.com>
4870
4871 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4872
4873 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4874
4875 jcamacho: Juan Camacho
4876
4877 jester: Jesse Sheidlower C<jester@panix.com>
4878
4879 jhannah: Jay Hannah <jay@jays.net>
4880
4881 Jody Belka
4882
4883 Johan Lindstrom
4884
4885 jon: Jon Schutz <jjschutz@cpan.org>
4886
4887 Jonathan Rockway C<< <jrockway@cpan.org> >>
4888
4889 Kieren Diment C<kd@totaldatasolution.com>
4890
4891 konobi: Scott McWhirter <konobi@cpan.org>
4892
4893 marcus: Marcus Ramberg <mramberg@cpan.org>
4894
4895 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4896
4897 mgrimes: Mark Grimes <mgrimes@cpan.org>
4898
4899 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4900
4901 mugwump: Sam Vilain
4902
4903 naughton: David Naughton
4904
4905 ningu: David Kamholz <dkamholz@cpan.org>
4906
4907 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4908
4909 numa: Dan Sully <daniel@cpan.org>
4910
4911 obra: Jesse Vincent
4912
4913 Octavian Rasnita
4914
4915 omega: Andreas Marienborg
4916
4917 Oleg Kostyuk <cub.uanic@gmail.com>
4918
4919 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4920
4921 rafl: Florian Ragwitz <rafl@debian.org>
4922
4923 random: Roland Lammel <lammel@cpan.org>
4924
4925 Robert Sedlacek C<< <rs@474.at> >>
4926
4927 SpiceMan: Marcel Montes
4928
4929 sky: Arthur Bergman
4930
4931 szbalint: Balint Szilakszi <szbalint@cpan.org>
4932
4933 t0m: Tomas Doran <bobtfish@bobtfish.net>
4934
4935 Ulf Edvinsson
4936
4937 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4938
4939 Viljo Marrandi C<vilts@yahoo.com>
4940
4941 Will Hawes C<info@whawes.co.uk>
4942
4943 willert: Sebastian Willert <willert@cpan.org>
4944
4945 wreis: Wallace Reis <wreis@cpan.org>
4946
4947 Yuval Kogman, C<nothingmuch@woobling.org>
4948
4949 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4950
4951 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4952
4953 Upasana <me@upasana.me>
4954
4955 John Napiorkowski (jnap) <jjnapiork@cpan.org>
4956
4957 =head1 COPYRIGHT
4958
4959 Copyright (c) 2005-2015, the above named PROJECT FOUNDER and CONTRIBUTORS.
4960
4961 =head1 LICENSE
4962
4963 This library is free software. You can redistribute it and/or modify it under
4964 the same terms as Perl itself.
4965
4966 =cut
4967
4968 no Moose;
4969
4970 __PACKAGE__->meta->make_immutable;
4971
4972 1;