lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::Util qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54 use Scalar::Util;
  55
  56 BEGIN { require 5.008003; }
  57
  58 has stack => (is => 'ro', default => sub { [] });
  59 has state => (is => 'rw', default => 0);
  60 has stats => (is => 'rw');
  61 has action => (is => 'rw');
  62 has counter => (is => 'rw', default => sub { {} });
  63 has request => (
  64     is => 'rw',
  65     default => sub {
  66         my $self = shift;
  67         my $class = ref $self;
  68         my $composed_request_class = $class->composed_request_class;
  69         return $composed_request_class->new( $self->_build_request_constructor_args);
  70     },
  71     lazy => 1,
  72 );
  73 sub _build_request_constructor_args {
  74     my $self = shift;
  75     my %p = ( _log => $self->log );
  76     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  77     $p{data_handlers} = {$self->registered_data_handlers};
  78     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  79       if $self->config->{use_hash_multivalue_in_request};
  80     \%p;
  81 }
  82
  83 sub composed_request_class {
  84   my $class = shift;
  85   return $class->_composed_request_class if $class->_composed_request_class;
  86
  87   my @traits = (@{$class->request_class_traits||[]}, @{$class->config->{request_class_traits}||[]});
  88
  89   # For each trait listed, figure out what the namespace is.  First we try the $trait
  90   # as it is in the config.  Then try $MyApp::TraitFor::Request:$trait. Last we try
  91   # Catalyst::TraitFor::Request::$trait.  If none load, throw error.
  92
  93   my $trait_ns = 'TraitFor::Request';
  94   my @normalized_traits = map {
  95     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
  96   } @traits;
  97
  98   if ($class->debug && scalar(@normalized_traits)) {
  99       my $column_width = Catalyst::Utils::term_width() - 6;
 100       my $t = Text::SimpleTable->new($column_width);
 101       $t->row($_) for @normalized_traits;
 102       $class->log->debug( "Composed Request Class Traits:\n" . $t->draw . "\n" );
 103   }
 104
 105   return $class->_composed_request_class(Moose::Util::with_traits($class->request_class, @normalized_traits));
 106 }
 107
 108 has response => (
 109     is => 'rw',
 110     default => sub {
 111         my $self = shift;
 112         my $class = ref $self;
 113         my $composed_response_class = $class->composed_response_class;
 114         return $composed_response_class->new( $self->_build_response_constructor_args);
 115     },
 116     lazy => 1,
 117 );
 118 sub _build_response_constructor_args {
 119     return +{
 120       _log => $_[0]->log,
 121       encoding => $_[0]->encoding,
 122     };
 123 }
 124
 125 sub composed_response_class {
 126   my $class = shift;
 127   return $class->_composed_response_class if $class->_composed_response_class;
 128
 129   my @traits = (@{$class->response_class_traits||[]}, @{$class->config->{response_class_traits}||[]});
 130
 131   my $trait_ns = 'TraitFor::Response';
 132   my @normalized_traits = map {
 133     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
 134   } @traits;
 135
 136   if ($class->debug && scalar(@normalized_traits)) {
 137       my $column_width = Catalyst::Utils::term_width() - 6;
 138       my $t = Text::SimpleTable->new($column_width);
 139       $t->row($_) for @normalized_traits;
 140       $class->log->debug( "Composed Response Class Traits:\n" . $t->draw . "\n" );
 141   }
 142
 143   return $class->_composed_response_class(Moose::Util::with_traits($class->response_class, @normalized_traits));
 144 }
 145
 146 has namespace => (is => 'rw');
 147
 148 sub depth { scalar @{ shift->stack || [] }; }
 149 sub comp { shift->component(@_) }
 150
 151 sub req {
 152     my $self = shift; return $self->request(@_);
 153 }
 154 sub res {
 155     my $self = shift; return $self->response(@_);
 156 }
 157
 158 # For backwards compatibility
 159 sub finalize_output { shift->finalize_body(@_) };
 160
 161 # For statistics
 162 our $COUNT     = 1;
 163 our $START     = time;
 164 our $RECURSION = 1000;
 165 our $DETACH    = Catalyst::Exception::Detach->new;
 166 our $GO        = Catalyst::Exception::Go->new;
 167
 168 #I imagine that very few of these really
 169 #need to be class variables. if any.
 170 #maybe we should just make them attributes with a default?
 171 __PACKAGE__->mk_classdata($_)
 172   for qw/components arguments dispatcher engine log dispatcher_class
 173   engine_loader context_class request_class response_class stats_class
 174   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 175   _data_handlers _encoding _encode_check finalized_default_middleware
 176   request_class_traits response_class_traits stats_class_traits
 177   _composed_request_class _composed_response_class _composed_stats_class/;
 178
 179 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 180 __PACKAGE__->request_class('Catalyst::Request');
 181 __PACKAGE__->response_class('Catalyst::Response');
 182 __PACKAGE__->stats_class('Catalyst::Stats');
 183
 184 sub composed_stats_class {
 185   my $class = shift;
 186   return $class->_composed_stats_class if $class->_composed_stats_class;
 187
 188   my @traits = (@{$class->stats_class_traits||[]}, @{$class->config->{stats_class_traits}||[]});
 189
 190   my $trait_ns = 'TraitFor::Stats';
 191   my @normalized_traits = map {
 192     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
 193   } @traits;
 194
 195   if ($class->debug && scalar(@normalized_traits)) {
 196       my $column_width = Catalyst::Utils::term_width() - 6;
 197       my $t = Text::SimpleTable->new($column_width);
 198       $t->row($_) for @normalized_traits;
 199       $class->log->debug( "Composed Stats Class Traits:\n" . $t->draw . "\n" );
 200   }
 201
 202   return $class->_composed_stats_class(Moose::Util::with_traits($class->stats_class, @normalized_traits));
 203 }
 204
 205 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 206
 207 # Remember to update this in Catalyst::Runtime as well!
 208 our $VERSION = '5.90123';
 209 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 210
 211 sub import {
 212     my ( $class, @arguments ) = @_;
 213
 214     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 215     # callers @ISA.
 216     return unless $class eq 'Catalyst';
 217
 218     my $caller = caller();
 219     return if $caller eq 'main';
 220
 221     my $meta = Moose::Meta::Class->initialize($caller);
 222     unless ( $caller->isa('Catalyst') ) {
 223         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 224         $meta->superclasses(@superclasses);
 225     }
 226     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 227     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 228
 229     unless( $meta->has_method('meta') ){
 230         if ($Moose::VERSION >= 1.15) {
 231             $meta->_add_meta_method('meta');
 232         }
 233         else {
 234             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 235         }
 236     }
 237
 238     $caller->arguments( [@arguments] );
 239     $caller->setup_home;
 240 }
 241
 242 sub _application { $_[0] }
 243
 244 =encoding UTF-8
 245
 246 =head1 NAME
 247
 248 Catalyst - The Elegant MVC Web Application Framework
 249
 250 =head1 SYNOPSIS
 251
 252 See the L<Catalyst::Manual> distribution for comprehensive
 253 documentation and tutorials.
 254
 255     # Install Catalyst::Devel for helpers and other development tools
 256     # use the helper to create a new application
 257     catalyst.pl MyApp
 258
 259     # add models, views, controllers
 260     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 261     script/myapp_create.pl view MyTemplate TT
 262     script/myapp_create.pl controller Search
 263
 264     # built in testserver -- use -r to restart automatically on changes
 265     # --help to see all available options
 266     script/myapp_server.pl
 267
 268     # command line testing interface
 269     script/myapp_test.pl /yada
 270
 271     ### in lib/MyApp.pm
 272     use Catalyst qw/-Debug/; # include plugins here as well
 273
 274     ### In lib/MyApp/Controller/Root.pm (autocreated)
 275     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 276         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 277         $c->stash->{template} = 'foo.tt'; # set the template
 278         # lookup something from db -- stash vars are passed to TT
 279         $c->stash->{data} =
 280           $c->model('Database::Foo')->search( { country => $args[0] } );
 281         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 282             $c->forward( 'bar' ); # process another action
 283             # do something else after forward returns
 284         }
 285     }
 286
 287     # The foo.tt TT template can use the stash data from the database
 288     [% WHILE (item = data.next) %]
 289         [% item.foo %]
 290     [% END %]
 291
 292     # called for /bar/of/soap, /bar/of/soap/10, etc.
 293     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 294
 295     # called after all actions are finished
 296     sub end : Action {
 297         my ( $self, $c ) = @_;
 298         if ( scalar @{ $c->error } ) { ... } # handle errors
 299         return if $c->res->body; # already have a response
 300         $c->forward( 'MyApp::View::TT' ); # render template
 301     }
 302
 303 See L<Catalyst::Manual::Intro> for additional information.
 304
 305 =head1 DESCRIPTION
 306
 307 Catalyst is a modern framework for making web applications without the
 308 pain usually associated with this process. This document is a reference
 309 to the main Catalyst application. If you are a new user, we suggest you
 310 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 311
 312 See L<Catalyst::Manual> for more documentation.
 313
 314 Catalyst plugins can be loaded by naming them as arguments to the "use
 315 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 316 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 317 C<My::Module>.
 318
 319     use Catalyst qw/My::Module/;
 320
 321 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 322 fully qualify the name by using a unary plus:
 323
 324     use Catalyst qw/
 325         My::Module
 326         +Fully::Qualified::Plugin::Name
 327     /;
 328
 329 Special flags like C<-Debug> can also be specified as
 330 arguments when Catalyst is loaded:
 331
 332     use Catalyst qw/-Debug My::Module/;
 333
 334 The position of plugins and flags in the chain is important, because
 335 they are loaded in the order in which they appear.
 336
 337 The following flags are supported:
 338
 339 =head2 -Debug
 340
 341 Enables debug output. You can also force this setting from the system
 342 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 343 settings override the application, with <MYAPP>_DEBUG having the highest
 344 priority.
 345
 346 This sets the log level to 'debug' and enables full debug output on the
 347 error screen. If you only want the latter, see L<< $c->debug >>.
 348
 349 =head2 -Home
 350
 351 Forces Catalyst to use a specific home directory, e.g.:
 352
 353     use Catalyst qw[-Home=/usr/mst];
 354
 355 This can also be done in the shell environment by setting either the
 356 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 357 is replaced with the uppercased name of your application, any "::" in
 358 the name will be replaced with underscores, e.g. MyApp::Web should use
 359 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 360
 361 If none of these are set, Catalyst will attempt to automatically detect the
 362 home directory. If you are working in a development environment, Catalyst
 363 will try and find the directory containing either Makefile.PL, Build.PL,
 364 dist.ini, or cpanfile. If the application has been installed into the system
 365 (i.e. you have done C<make install>), then Catalyst will use the path to your
 366 application module, without the .pm extension (e.g., /foo/MyApp if your
 367 application was installed at /foo/MyApp.pm)
 368
 369 =head2 -Log
 370
 371     use Catalyst '-Log=warn,fatal,error';
 372
 373 Specifies a comma-delimited list of log levels.
 374
 375 =head2 -Stats
 376
 377 Enables statistics collection and reporting.
 378
 379    use Catalyst qw/-Stats=1/;
 380
 381 You can also force this setting from the system environment with CATALYST_STATS
 382 or <MYAPP>_STATS. The environment settings override the application, with
 383 <MYAPP>_STATS having the highest priority.
 384
 385 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 386
 387 =head1 METHODS
 388
 389 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 390
 391 =head2 $c->action
 392
 393 Returns a L<Catalyst::Action> object for the current action, which
 394 stringifies to the action name. See L<Catalyst::Action>.
 395
 396 =head2 $c->namespace
 397
 398 Returns the namespace of the current action, i.e., the URI prefix
 399 corresponding to the controller of the current action. For example:
 400
 401     # in Controller::Foo::Bar
 402     $c->namespace; # returns 'foo/bar';
 403
 404 =head2 $c->request
 405
 406 =head2 $c->req
 407
 408 Returns the current L<Catalyst::Request> object, giving access to
 409 information about the current client request (including parameters,
 410 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 411
 412 =head2 REQUEST FLOW HANDLING
 413
 414 =head2 $c->forward( $action [, \@arguments ] )
 415
 416 =head2 $c->forward( $class, $method, [, \@arguments ] )
 417
 418 This is one way of calling another action (method) in the same or
 419 a different controller. You can also use C<< $self->my_method($c, @args) >>
 420 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 421 in a different controller.
 422 The main difference is that 'forward' uses some of the Catalyst request
 423 cycle overhead, including debugging, which may be useful to you. On the
 424 other hand, there are some complications to using 'forward', restrictions
 425 on values returned from 'forward', and it may not handle errors as you prefer.
 426 Whether you use 'forward' or not is up to you; it is not considered superior to
 427 the other ways to call a method.
 428
 429 'forward' calls  another action, by its private name. If you give a
 430 class name but no method, C<process()> is called. You may also optionally
 431 pass arguments in an arrayref. The action will receive the arguments in
 432 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 433 C<< $c->req->args >> will be restored to the previous values.
 434
 435 Any data C<return>ed from the action forwarded to, will be returned by the
 436 call to forward.
 437
 438     my $foodata = $c->forward('/foo');
 439     $c->forward('index');
 440     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 441     $c->forward('View::TT');
 442
 443 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 444 an C<< eval { } >> around the call (actually
 445 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 446 exceptions thrown by the called action non-fatal and pushing them onto
 447 $c->error instead. If you want C<die> to propagate you need to do something
 448 like:
 449
 450     $c->forward('foo');
 451     die join "\n", @{ $c->error } if @{ $c->error };
 452
 453 Or make sure to always return true values from your actions and write
 454 your code like this:
 455
 456     $c->forward('foo') || return;
 457
 458 Another note is that C<< $c->forward >> always returns a scalar because it
 459 actually returns $c->state which operates in a scalar context.
 460 Thus, something like:
 461
 462     return @array;
 463
 464 in an action that is forwarded to is going to return a scalar,
 465 i.e. how many items are in that array, which is probably not what you want.
 466 If you need to return an array then return a reference to it,
 467 or stash it like so:
 468
 469     $c->stash->{array} = \@array;
 470
 471 and access it from the stash.
 472
 473 Keep in mind that the C<end> method used is that of the caller action. So a C<< $c->detach >> inside a forwarded action would run the C<end> method from the original action requested.
 474
 475 =cut
 476
 477 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 478
 479 =head2 $c->detach( $action [, \@arguments ] )
 480
 481 =head2 $c->detach( $class, $method, [, \@arguments ] )
 482
 483 =head2 $c->detach()
 484
 485 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 486 doesn't return to the previous action when processing is finished.
 487
 488 When called with no arguments it escapes the processing chain entirely.
 489
 490 =cut
 491
 492 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 493
 494 =head2 $c->visit( $action [, \@arguments ] )
 495
 496 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 497
 498 =head2 $c->visit( $class, $method, [, \@arguments ] )
 499
 500 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 501
 502 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 503 but does a full dispatch, instead of just calling the new C<$action> /
 504 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 505 you go to are called, just like a new request.
 506
 507 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 508 This means, for example, that C<< $c->action >> methods such as
 509 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 510 L<reverse|Catalyst::Action/reverse> return information for the visited action
 511 when they are invoked within the visited action.  This is different from the
 512 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 513 continues to use the $c->action object from the caller action even when
 514 invoked from the called action.
 515
 516 C<< $c->stash >> is kept unchanged.
 517
 518 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 519 allows you to "wrap" another action, just as it would have been called by
 520 dispatching from a URL, while the analogous
 521 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 522 transfer control to another action as if it had been reached directly from a URL.
 523
 524 =cut
 525
 526 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 527
 528 =head2 $c->go( $action [, \@arguments ] )
 529
 530 =head2 $c->go( $action [, \@captures, \@arguments ] )
 531
 532 =head2 $c->go( $class, $method, [, \@arguments ] )
 533
 534 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 535
 536 The relationship between C<go> and
 537 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 538 the relationship between
 539 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 540 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 541 C<< $c->go >> will perform a full dispatch on the specified action or method,
 542 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 543 C<go> escapes the processing of the current request chain on completion, and
 544 does not return to its caller.
 545
 546 @arguments are arguments to the final destination of $action. @captures are
 547 arguments to the intermediate steps, if any, on the way to the final sub of
 548 $action.
 549
 550 =cut
 551
 552 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 553
 554 =head2 $c->response
 555
 556 =head2 $c->res
 557
 558 Returns the current L<Catalyst::Response> object, see there for details.
 559
 560 =head2 $c->stash
 561
 562 Returns a hashref to the stash, which may be used to store data and pass
 563 it between components during a request. You can also set hash keys by
 564 passing arguments. The stash is automatically sent to the view. The
 565 stash is cleared at the end of a request; it cannot be used for
 566 persistent storage (for this you must use a session; see
 567 L<Catalyst::Plugin::Session> for a complete system integrated with
 568 Catalyst).
 569
 570     $c->stash->{foo} = $bar;
 571     $c->stash( { moose => 'majestic', qux => 0 } );
 572     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 573
 574     # stash is automatically passed to the view for use in a template
 575     $c->forward( 'MyApp::View::TT' );
 576
 577 The stash hash is currently stored in the PSGI C<$env> and is managed by
 578 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 579 the stash can be accessed in sub applications mounted under your main
 580 L<Catalyst> application.  For example if you delegate the response of an
 581 action to another L<Catalyst> application, that sub application will have
 582 access to all the stash keys of the main one, and if can of course add
 583 more keys of its own.  However those new keys will not 'bubble' back up
 584 to the main application.
 585
 586 For more information the best thing to do is to review the test case:
 587 t/middleware-stash.t in the distribution /t directory.
 588
 589 =cut
 590
 591 sub stash {
 592   my $c = shift;
 593   $c->log->error("You are requesting the stash but you don't have a context") unless blessed $c;
 594   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 595 }
 596
 597 =head2 $c->error
 598
 599 =head2 $c->error($error, ...)
 600
 601 =head2 $c->error($arrayref)
 602
 603 Returns an arrayref containing error messages.  If Catalyst encounters an
 604 error while processing a request, it stores the error in $c->error.  This
 605 method should only be used to store fatal error messages.
 606
 607     my @error = @{ $c->error };
 608
 609 Add a new error.
 610
 611     $c->error('Something bad happened');
 612
 613 Calling this will always return an arrayref (if there are no errors it
 614 will be an empty arrayref.
 615
 616 =cut
 617
 618 sub error {
 619     my $c = shift;
 620     if ( $_[0] ) {
 621         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 622         croak @$error unless ref $c;
 623         push @{ $c->{error} }, @$error;
 624     }
 625     elsif ( defined $_[0] ) { $c->{error} = undef }
 626     return $c->{error} || [];
 627 }
 628
 629 =head2 $c->state
 630
 631 Contains the return value of the last executed action.
 632 Note that << $c->state >> operates in a scalar context which means that all
 633 values it returns are scalar.
 634
 635 Please note that if an action throws an exception, the value of state
 636 should no longer be considered the return if the last action.  It is generally
 637 going to be 0, which indicates an error state.  Examine $c->error for error
 638 details.
 639
 640 =head2 $c->clear_errors
 641
 642 Clear errors.  You probably don't want to clear the errors unless you are
 643 implementing a custom error screen.
 644
 645 This is equivalent to running
 646
 647     $c->error(0);
 648
 649 =cut
 650
 651 sub clear_errors {
 652     my $c = shift;
 653     $c->error(0);
 654 }
 655
 656 =head2 $c->has_errors
 657
 658 Returns true if you have errors
 659
 660 =cut
 661
 662 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 663
 664 =head2 $c->last_error
 665
 666 Returns the most recent error in the stack (the one most recently added...)
 667 or nothing if there are no errors.  This does not modify the contents of the
 668 error stack.
 669
 670 =cut
 671
 672 sub last_error {
 673   my (@errs) = @{shift->error};
 674   return scalar(@errs) ? $errs[-1]: undef;
 675 }
 676
 677 =head2 shift_errors
 678
 679 shifts the most recently added error off the error stack and returns it.  Returns
 680 nothing if there are no more errors.
 681
 682 =cut
 683
 684 sub shift_errors {
 685     my ($self) = @_;
 686     my @errors = @{$self->error};
 687     my $err = shift(@errors);
 688     $self->{error} = \@errors;
 689     return $err;
 690 }
 691
 692 =head2 pop_errors
 693
 694 pops the most recently added error off the error stack and returns it.  Returns
 695 nothing if there are no more errors.
 696
 697 =cut
 698
 699 sub pop_errors {
 700     my ($self) = @_;
 701     my @errors = @{$self->error};
 702     my $err = pop(@errors);
 703     $self->{error} = \@errors;
 704     return $err;
 705 }
 706
 707 sub _comp_search_prefixes {
 708     my $c = shift;
 709     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 710 }
 711
 712 # search components given a name and some prefixes
 713 sub _comp_names_search_prefixes {
 714     my ( $c, $name, @prefixes ) = @_;
 715     my $appclass = ref $c || $c;
 716     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 717     $filter = qr/$filter/; # Compile regex now rather than once per loop
 718
 719     # map the original component name to the sub part that we will search against
 720     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 721         grep { /$filter/ } keys %{ $c->components };
 722
 723     # undef for a name will return all
 724     return keys %eligible if !defined $name;
 725
 726     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 727     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 728
 729     return @result if @result;
 730
 731     # if we were given a regexp to search against, we're done.
 732     return if $name->$_isa('Regexp');
 733
 734     # skip regexp fallback if configured
 735     return
 736         if $appclass->config->{disable_component_resolution_regex_fallback};
 737
 738     # regexp fallback
 739     $query  = qr/$name/i;
 740     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 741
 742     # no results? try against full names
 743     if( !@result ) {
 744         @result = grep { m{$query} } keys %eligible;
 745     }
 746
 747     # don't warn if we didn't find any results, it just might not exist
 748     if( @result ) {
 749         # Disgusting hack to work out correct method name
 750         my $warn_for = lc $prefixes[0];
 751         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 752            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 753            "component resolution is unreliable and unsafe.";
 754         my $short = $result[0];
 755         # remove the component namespace prefix
 756         $short =~ s/.*?(Model|Controller|View):://;
 757         my $shortmess = Carp::shortmess('');
 758         if ($shortmess =~ m#Catalyst/Plugin#) {
 759            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 760               "plugin's config";
 761         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 762            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 763               "component's config";
 764         } else {
 765            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 766               "but if you really wanted to search, pass in a regexp as the argument " .
 767               "like so: \$c->${warn_for}(qr/${name}/)";
 768         }
 769         $c->log->warn( "${msg}$shortmess" );
 770     }
 771
 772     return @result;
 773 }
 774
 775 # Find possible names for a prefix
 776 sub _comp_names {
 777     my ( $c, @prefixes ) = @_;
 778     my $appclass = ref $c || $c;
 779
 780     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 781
 782     my @names = map { s{$filter}{}; $_; }
 783         $c->_comp_names_search_prefixes( undef, @prefixes );
 784
 785     return @names;
 786 }
 787
 788 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 789
 790 sub _filter_component {
 791     my ( $c, $comp, @args ) = @_;
 792
 793     if(ref $comp eq 'CODE') {
 794       $comp = $comp->();
 795     }
 796
 797     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 798       return $comp->ACCEPT_CONTEXT( $c, @args );
 799     }
 800
 801     $c->log->warn("You called component '${\$comp->catalyst_component_name}' with arguments [@args], but this component does not ACCEPT_CONTEXT, so args are ignored.") if scalar(@args) && $c->debug;
 802
 803     return $comp;
 804 }
 805
 806 =head2 COMPONENT ACCESSORS
 807
 808 =head2 $c->controller($name)
 809
 810 Gets a L<Catalyst::Controller> instance by name.
 811
 812     $c->controller('Foo')->do_stuff;
 813
 814 If the name is omitted, will return the controller for the dispatched
 815 action.
 816
 817 If you want to search for controllers, pass in a regexp as the argument.
 818
 819     # find all controllers that start with Foo
 820     my @foo_controllers = $c->controller(qr{^Foo});
 821
 822
 823 =cut
 824
 825 sub controller {
 826     my ( $c, $name, @args ) = @_;
 827
 828     my $appclass = ref($c) || $c;
 829     if( $name ) {
 830         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 831             my $comps = $c->components;
 832             my $check = $appclass."::Controller::".$name;
 833             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 834             foreach my $path (@{$appclass->config->{ setup_components }->{ search_extra }}) {
 835                 next unless $path =~ /.*::Controller/;
 836                 $check = $path."::".$name;
 837                 return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 838             }
 839         }
 840         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 841         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 842         return $c->_filter_component( $result[ 0 ], @args );
 843     }
 844
 845     return $c->component( $c->action->class );
 846 }
 847
 848 =head2 $c->model($name)
 849
 850 Gets a L<Catalyst::Model> instance by name.
 851
 852     $c->model('Foo')->do_stuff;
 853
 854 Any extra arguments are directly passed to ACCEPT_CONTEXT, if the model
 855 defines ACCEPT_CONTEXT.  If it does not, the args are discarded.
 856
 857 If the name is omitted, it will look for
 858  - a model object in $c->stash->{current_model_instance}, then
 859  - a model name in $c->stash->{current_model}, then
 860  - a config setting 'default_model', or
 861  - check if there is only one model, and return it if that's the case.
 862
 863 If you want to search for models, pass in a regexp as the argument.
 864
 865     # find all models that start with Foo
 866     my @foo_models = $c->model(qr{^Foo});
 867
 868 =cut
 869
 870 sub model {
 871     my ( $c, $name, @args ) = @_;
 872     my $appclass = ref($c) || $c;
 873     if( $name ) {
 874         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 875             my $comps = $c->components;
 876             my $check = $appclass."::Model::".$name;
 877             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 878             foreach my $path (@{$appclass->config->{ setup_components }->{ search_extra }}) {
 879                 next unless $path =~ /.*::Model/;
 880                 $check = $path."::".$name;
 881                 return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 882             }
 883         }
 884         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 885         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 886         return $c->_filter_component( $result[ 0 ], @args );
 887     }
 888
 889     if (ref $c) {
 890         return $c->stash->{current_model_instance}
 891           if $c->stash->{current_model_instance};
 892         return $c->model( $c->stash->{current_model} )
 893           if $c->stash->{current_model};
 894     }
 895     return $c->model( $appclass->config->{default_model} )
 896       if $appclass->config->{default_model};
 897
 898     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 899
 900     if( $rest ) {
 901         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 902         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 903         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 904         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 905         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 906     }
 907
 908     return $c->_filter_component( $comp );
 909 }
 910
 911
 912 =head2 $c->view($name)
 913
 914 Gets a L<Catalyst::View> instance by name.
 915
 916     $c->view('Foo')->do_stuff;
 917
 918 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 919
 920 If the name is omitted, it will look for
 921  - a view object in $c->stash->{current_view_instance}, then
 922  - a view name in $c->stash->{current_view}, then
 923  - a config setting 'default_view', or
 924  - check if there is only one view, and return it if that's the case.
 925
 926 If you want to search for views, pass in a regexp as the argument.
 927
 928     # find all views that start with Foo
 929     my @foo_views = $c->view(qr{^Foo});
 930
 931 =cut
 932
 933 sub view {
 934     my ( $c, $name, @args ) = @_;
 935
 936     my $appclass = ref($c) || $c;
 937     if( $name ) {
 938         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 939             my $comps = $c->components;
 940             my $check = $appclass."::View::".$name;
 941             if( exists $comps->{$check} ) {
 942                 return $c->_filter_component( $comps->{$check}, @args );
 943             }
 944             else {
 945                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 946             }
 947             foreach my $path (@{$appclass->config->{ setup_components }->{ search_extra }}) {
 948                 next unless $path =~ /.*::View/;
 949                 $check = $path."::".$name;
 950                 return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 951             }
 952         }
 953         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 954         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 955         return $c->_filter_component( $result[ 0 ], @args );
 956     }
 957
 958     if (ref $c) {
 959         return $c->stash->{current_view_instance}
 960           if $c->stash->{current_view_instance};
 961         return $c->view( $c->stash->{current_view} )
 962           if $c->stash->{current_view};
 963     }
 964     return $c->view( $appclass->config->{default_view} )
 965       if $appclass->config->{default_view};
 966
 967     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 968
 969     if( $rest ) {
 970         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 971         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 972         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 973         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 974         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 975     }
 976
 977     return $c->_filter_component( $comp );
 978 }
 979
 980 =head2 $c->controllers
 981
 982 Returns the available names which can be passed to $c->controller
 983
 984 =cut
 985
 986 sub controllers {
 987     my ( $c ) = @_;
 988     return $c->_comp_names(qw/Controller C/);
 989 }
 990
 991 =head2 $c->models
 992
 993 Returns the available names which can be passed to $c->model
 994
 995 =cut
 996
 997 sub models {
 998     my ( $c ) = @_;
 999     return $c->_comp_names(qw/Model M/);
1000 }
1001
1002
1003 =head2 $c->views
1004
1005 Returns the available names which can be passed to $c->view
1006
1007 =cut
1008
1009 sub views {
1010     my ( $c ) = @_;
1011     return $c->_comp_names(qw/View V/);
1012 }
1013
1014 =head2 $c->comp($name)
1015
1016 =head2 $c->component($name)
1017
1018 Gets a component object by name. This method is not recommended,
1019 unless you want to get a specific component by full
1020 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
1021 should be used instead.
1022
1023 If C<$name> is a regexp, a list of components matched against the full
1024 component name will be returned.
1025
1026 If Catalyst can't find a component by name, it will fallback to regex
1027 matching by default. To disable this behaviour set
1028 disable_component_resolution_regex_fallback to a true value.
1029
1030     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
1031
1032 =cut
1033
1034 sub component {
1035     my ( $c, $name, @args ) = @_;
1036
1037     if( $name ) {
1038         my $comps = $c->components;
1039
1040         if( !ref $name ) {
1041             # is it the exact name?
1042             return $c->_filter_component( $comps->{ $name }, @args )
1043                        if exists $comps->{ $name };
1044
1045             # perhaps we just omitted "MyApp"?
1046             my $composed = ( ref $c || $c ) . "::${name}";
1047             return $c->_filter_component( $comps->{ $composed }, @args )
1048                        if exists $comps->{ $composed };
1049
1050             # search all of the models, views and controllers
1051             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
1052             return $c->_filter_component( $comp, @args ) if $comp;
1053         }
1054
1055         return
1056             if $c->config->{disable_component_resolution_regex_fallback};
1057
1058         # This is here so $c->comp( '::M::' ) works
1059         my $query = ref $name ? $name : qr{$name}i;
1060
1061         my @result = grep { m{$query} } keys %{ $c->components };
1062         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
1063
1064         if( $result[ 0 ] ) {
1065             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
1066             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
1067             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
1068             return $c->_filter_component( $result[ 0 ], @args );
1069         }
1070
1071         # I would expect to return an empty list here, but that breaks back-compat
1072     }
1073
1074     # fallback
1075     return sort keys %{ $c->components };
1076 }
1077
1078 =head2 CLASS DATA AND HELPER CLASSES
1079
1080 =head2 $c->config
1081
1082 Returns or takes a hashref containing the application's configuration.
1083
1084     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
1085
1086 You can also use a C<YAML>, C<XML> or L<Config::General> config file
1087 like C<myapp.conf> in your applications home directory. See
1088 L<Catalyst::Plugin::ConfigLoader>.
1089
1090 =head3 Cascading configuration
1091
1092 The config method is present on all Catalyst components, and configuration
1093 will be merged when an application is started. Configuration loaded with
1094 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
1095 followed by configuration in your top level C<MyApp> class. These two
1096 configurations are merged, and then configuration data whose hash key matches a
1097 component name is merged with configuration for that component.
1098
1099 The configuration for a component is then passed to the C<new> method when a
1100 component is constructed.
1101
1102 For example:
1103
1104     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
1105     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
1106
1107 will mean that C<MyApp::Model::Foo> receives the following data when
1108 constructed:
1109
1110     MyApp::Model::Foo->new({
1111         bar => 'baz',
1112         quux => 'frob',
1113         overrides => 'me',
1114     });
1115
1116 It's common practice to use a Moose attribute
1117 on the receiving component to access the config value.
1118
1119     package MyApp::Model::Foo;
1120
1121     use Moose;
1122
1123     # this attr will receive 'baz' at construction time
1124     has 'bar' => (
1125         is  => 'rw',
1126         isa => 'Str',
1127     );
1128
1129 You can then get the value 'baz' by calling $c->model('Foo')->bar
1130 (or $self->bar inside code in the model).
1131
1132 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
1133 as a way of reading config within your code, as this B<will not> give you the
1134 correctly merged config back. You B<MUST> take the config values supplied to
1135 the constructor and use those instead.
1136
1137 =cut
1138
1139 around config => sub {
1140     my $orig = shift;
1141     my $c = shift;
1142
1143     croak('Setting config after setup has been run is not allowed.')
1144         if ( @_ and $c->setup_finished );
1145
1146     $c->$orig(@_);
1147 };
1148
1149 =head2 $c->log
1150
1151 Returns the logging object instance. Unless it is already set, Catalyst
1152 sets this up with a L<Catalyst::Log> object. To use your own log class,
1153 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1154 C<< __PACKAGE__->setup >>.
1155
1156  __PACKAGE__->log( MyLogger->new );
1157  __PACKAGE__->setup;
1158
1159 And later:
1160
1161     $c->log->info( 'Now logging with my own logger!' );
1162
1163 Your log class should implement the methods described in
1164 L<Catalyst::Log>.
1165
1166 =head2 has_encoding
1167
1168 Returned True if there's a valid encoding
1169
1170 =head2 clear_encoding
1171
1172 Clears the encoding for the current context
1173
1174 =head2 encoding
1175
1176 Sets or gets the application encoding.  Setting encoding takes either an
1177 Encoding object or a string that we try to resolve via L<Encode::find_encoding>.
1178
1179 You would expect to get the encoding object back if you attempt to set it.  If
1180 there is a failure you will get undef returned and an error message in the log.
1181
1182 =cut
1183
1184 sub has_encoding { shift->encoding ? 1:0 }
1185
1186 sub clear_encoding {
1187     my $c = shift;
1188     if(blessed $c) {
1189         $c->encoding(undef);
1190     } else {
1191         $c->log->error("You can't clear encoding on the application");
1192     }
1193 }
1194
1195 sub encoding {
1196     my $c = shift;
1197     my $encoding;
1198
1199     if ( scalar @_ ) {
1200
1201         # Don't let one change this once we are too far into the response
1202         if(blessed $c && $c->res->finalized_headers) {
1203           Carp::croak("You may not change the encoding once the headers are finalized");
1204           return;
1205         }
1206
1207         # Let it be set to undef
1208         if (my $wanted = shift)  {
1209             $encoding = Encode::find_encoding($wanted)
1210               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1211             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1212         }
1213         else {
1214             binmode(STDERR);
1215         }
1216
1217         $encoding = ref $c
1218                   ? $c->{encoding} = $encoding
1219                   : $c->_encoding($encoding);
1220     } else {
1221       $encoding = ref $c && exists $c->{encoding}
1222                 ? $c->{encoding}
1223                 : $c->_encoding;
1224     }
1225
1226     return $encoding;
1227 }
1228
1229 =head2 $c->debug
1230
1231 Returns 1 if debug mode is enabled, 0 otherwise.
1232
1233 You can enable debug mode in several ways:
1234
1235 =over
1236
1237 =item By calling myapp_server.pl with the -d flag
1238
1239 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1240
1241 =item The -Debug option in your MyApp.pm
1242
1243 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1244
1245 =back
1246
1247 The first three also set the log level to 'debug'.
1248
1249 Calling C<< $c->debug(1) >> has no effect.
1250
1251 =cut
1252
1253 sub debug { 0 }
1254
1255 =head2 $c->dispatcher
1256
1257 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1258
1259 =head2 $c->engine
1260
1261 Returns the engine instance. See L<Catalyst::Engine>.
1262
1263
1264 =head2 UTILITY METHODS
1265
1266 =head2 $c->path_to(@path)
1267
1268 Merges C<@path> with C<< $c->config->{home} >> and returns a
1269 L<Path::Class::Dir> object. Note you can usually use this object as
1270 a filename, but sometimes you will have to explicitly stringify it
1271 yourself by calling the C<< ->stringify >> method.
1272
1273 For example:
1274
1275     $c->path_to( 'db', 'sqlite.db' );
1276
1277 =cut
1278
1279 sub path_to {
1280     my ( $c, @path ) = @_;
1281     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1282     if ( -d $path ) { return $path }
1283     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1284 }
1285
1286 sub plugin {
1287     my ( $class, $name, $plugin, @args ) = @_;
1288
1289     # See block comment in t/unit_core_plugin.t
1290     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1291
1292     $class->_register_plugin( $plugin, 1 );
1293
1294     eval { $plugin->import };
1295     $class->mk_classdata($name);
1296     my $obj;
1297     eval { $obj = $plugin->new(@args) };
1298
1299     if ($@) {
1300         Catalyst::Exception->throw( message =>
1301               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1302     }
1303
1304     $class->$name($obj);
1305     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1306       if $class->debug;
1307 }
1308
1309 =head2 MyApp->setup
1310
1311 Initializes the dispatcher and engine, loads any plugins, and loads the
1312 model, view, and controller components. You may also specify an array
1313 of plugins to load here, if you choose to not load them in the C<use
1314 Catalyst> line.
1315
1316     MyApp->setup;
1317     MyApp->setup( qw/-Debug/ );
1318
1319 B<Note:> You B<should not> wrap this method with method modifiers
1320 or bad things will happen - wrap the C<setup_finalize> method instead.
1321
1322 B<Note:> You can create a custom setup stage that will execute when the
1323 application is starting.  Use this to customize setup.
1324
1325     MyApp->setup(-Custom=value);
1326
1327     sub setup_custom {
1328       my ($class, $value) = @_;
1329     }
1330
1331 Can be handy if you want to hook into the setup phase.
1332
1333 =cut
1334
1335 sub setup {
1336     my ( $class, @arguments ) = @_;
1337     croak('Running setup more than once')
1338         if ( $class->setup_finished );
1339
1340     unless ( $class->isa('Catalyst') ) {
1341
1342         Catalyst::Exception->throw(
1343             message => qq/'$class' does not inherit from Catalyst/ );
1344     }
1345
1346     if ( $class->arguments ) {
1347         @arguments = ( @arguments, @{ $class->arguments } );
1348     }
1349
1350     # Process options
1351     my $flags = {};
1352
1353     foreach (@arguments) {
1354
1355         if (/^-Debug$/) {
1356             $flags->{log} =
1357               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1358         }
1359         elsif (/^-(\w+)=?(.*)$/) {
1360             $flags->{ lc $1 } = $2;
1361         }
1362         else {
1363             push @{ $flags->{plugins} }, $_;
1364         }
1365     }
1366
1367     $class->setup_home( delete $flags->{home} );
1368
1369     $class->setup_log( delete $flags->{log} );
1370     $class->setup_plugins( delete $flags->{plugins} );
1371
1372     $class->setup_data_handlers();
1373     $class->setup_dispatcher( delete $flags->{dispatcher} );
1374     if (my $engine = delete $flags->{engine}) {
1375         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1376     }
1377     $class->setup_engine();
1378     $class->setup_stats( delete $flags->{stats} );
1379
1380     for my $flag ( sort keys %{$flags} ) {
1381
1382         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1383             &$code( $class, delete $flags->{$flag} );
1384         }
1385         else {
1386             $class->log->warn(qq/Unknown flag "$flag"/);
1387         }
1388     }
1389
1390     eval { require Catalyst::Devel; };
1391     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1392         $class->log->warn(<<"EOF");
1393 You are running an old script!
1394
1395   Please update by running (this will overwrite existing files):
1396     catalyst.pl -force -scripts $class
1397
1398   or (this will not overwrite existing files):
1399     catalyst.pl -scripts $class
1400
1401 EOF
1402     }
1403
1404     # Call plugins setup, this is stupid and evil.
1405     # Also screws C3 badly on 5.10, hack to avoid.
1406     {
1407         no warnings qw/redefine/;
1408         local *setup = sub { };
1409         $class->setup unless $Catalyst::__AM_RESTARTING;
1410     }
1411
1412     # If you are expecting configuration info as part of your setup, it needs
1413     # to get called here and below, since we need the above line to support
1414     # ConfigLoader based configs.
1415
1416     $class->setup_encoding();
1417     $class->setup_middleware();
1418
1419     # Initialize our data structure
1420     $class->components( {} );
1421
1422     $class->setup_components;
1423
1424     if ( $class->debug ) {
1425         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1426
1427         if (@plugins) {
1428             my $column_width = Catalyst::Utils::term_width() - 6;
1429             my $t = Text::SimpleTable->new($column_width);
1430             $t->row($_) for @plugins;
1431             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1432         }
1433
1434         my @middleware = map {
1435           ref $_ eq 'CODE' ?
1436             "Inline Coderef" :
1437               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1438                 || '')  } $class->registered_middlewares;
1439
1440         if (@middleware) {
1441             my $column_width = Catalyst::Utils::term_width() - 6;
1442             my $t = Text::SimpleTable->new($column_width);
1443             $t->row($_) for @middleware;
1444             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1445         }
1446
1447         my %dh = $class->registered_data_handlers;
1448         if (my @data_handlers = keys %dh) {
1449             my $column_width = Catalyst::Utils::term_width() - 6;
1450             my $t = Text::SimpleTable->new($column_width);
1451             $t->row($_) for @data_handlers;
1452             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1453         }
1454
1455         my $dispatcher = $class->dispatcher;
1456         my $engine     = $class->engine;
1457         my $home       = $class->config->{home};
1458
1459         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1460         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1461
1462         $home
1463           ? ( -d $home )
1464           ? $class->log->debug(qq/Found home "$home"/)
1465           : $class->log->debug(qq/Home "$home" doesn't exist/)
1466           : $class->log->debug(q/Couldn't find home/);
1467
1468         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1469
1470         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1471         for my $comp ( sort keys %{ $class->components } ) {
1472             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1473             $t->row( $comp, $type );
1474         }
1475         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1476           if ( keys %{ $class->components } );
1477     }
1478
1479     # Add our self to components, since we are also a component
1480     if( $class->isa('Catalyst::Controller') ){
1481       $class->components->{$class} = $class;
1482     }
1483
1484     $class->setup_actions;
1485
1486     if ( $class->debug ) {
1487         my $name = $class->config->{name} || 'Application';
1488         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1489     }
1490
1491     if ($class->config->{case_sensitive}) {
1492         $class->log->warn($class . "->config->{case_sensitive} is set.");
1493         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1494     }
1495
1496     # call these so we pre setup the composed classes
1497     $class->composed_request_class;
1498     $class->composed_response_class;
1499     $class->composed_stats_class;
1500
1501     $class->setup_finalize;
1502
1503     # Flush the log for good measure (in case something turned off 'autoflush' early)
1504     $class->log->_flush() if $class->log->can('_flush');
1505
1506     return $class || 1; # Just in case someone named their Application 0...
1507 }
1508
1509 =head2 $app->setup_finalize
1510
1511 A hook to attach modifiers to. This method does not do anything except set the
1512 C<setup_finished> accessor.
1513
1514 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1515
1516 Example:
1517
1518     after setup_finalize => sub {
1519         my $app = shift;
1520
1521         ## do stuff here..
1522     };
1523
1524 =cut
1525
1526 sub setup_finalize {
1527     my ($class) = @_;
1528     $class->setup_finished(1);
1529 }
1530
1531 =head2 $c->uri_for( $path?, @args?, \%query_values?, \$fragment? )
1532
1533 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values?, \$fragment? )
1534
1535 =head2 $c->uri_for( $action, [@captures, @args], \%query_values?, \$fragment? )
1536
1537 Constructs an absolute L<URI> object based on the application root, the
1538 provided path, and the additional arguments and query parameters provided.
1539 When used as a string, provides a textual URI.  If you need more flexibility
1540 than this (i.e. the option to provide relative URIs etc.) see
1541 L<Catalyst::Plugin::SmartURI>.
1542
1543 If no arguments are provided, the URI for the current action is returned.
1544 To return the current action and also provide @args, use
1545 C<< $c->uri_for( $c->action, @args ) >>.
1546
1547 If the first argument is a string, it is taken as a public URI path relative
1548 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1549 relative to the application root (if it does). It is then merged with
1550 C<< $c->request->base >>; any C<@args> are appended as additional path
1551 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1552
1553 B<NOTE> If you are using this 'stringy' first argument, we skip encoding and
1554 allow you to declare something like:
1555
1556     $c->uri_for('/foo/bar#baz')
1557
1558 Where 'baz' is a URI fragment.  We consider this first argument string to be
1559 'expert' mode where you are expected to create a valid URL and we for the most
1560 part just pass it through without a lot of internal effort to escape and encode.
1561
1562 If the first argument is a L<Catalyst::Action> it represents an action which
1563 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1564 optional C<\@captures> argument (an arrayref) allows passing the captured
1565 variables that are needed to fill in the paths of Chained and Regex actions;
1566 once the path is resolved, C<uri_for> continues as though a path was
1567 provided, appending any arguments or parameters and creating an absolute
1568 URI.
1569
1570 The captures for the current request can be found in
1571 C<< $c->request->captures >>, and actions can be resolved using
1572 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1573 path, use C<< $c->uri_for_action >> instead.
1574
1575   # Equivalent to $c->req->uri
1576   $c->uri_for($c->action, $c->req->captures,
1577       @{ $c->req->args }, $c->req->params);
1578
1579   # For the Foo action in the Bar controller
1580   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1581
1582   # Path to a static resource
1583   $c->uri_for('/static/images/logo.png');
1584
1585 In general the scheme of the generated URI object will follow the incoming request
1586 however if your targeted action or action chain has the Scheme attribute it will
1587 use that instead.
1588
1589 Also, if the targeted Action or Action chain declares Args/CaptureArgs that have
1590 type constraints, we will require that your proposed URL verify on those declared
1591 constraints.
1592
1593 =cut
1594
1595 sub uri_for {
1596     my ( $c, $path, @args ) = @_;
1597
1598     if ( $path->$_isa('Catalyst::Controller') ) {
1599         $path = $path->path_prefix;
1600         $path =~ s{/+\z}{};
1601         $path .= '/';
1602     }
1603
1604     my $fragment =  ((scalar(@args) && ref($args[-1]) eq 'SCALAR') ? ${pop @args} : undef );
1605
1606     unless(blessed $path) {
1607       if (defined($path) and $path =~ s/#(.+)$//)  {
1608         if(defined($1) and defined $fragment) {
1609           carp "Abiguious fragment declaration: You cannot define a fragment in '$path' and as an argument '$fragment'";
1610         }
1611         if(defined($1)) {
1612           $fragment = $1;
1613         }
1614       }
1615     }
1616
1617     my $params =
1618       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1619
1620     undef($path) if (defined $path && $path eq '');
1621
1622     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1623
1624     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1625     if ( $path->$_isa('Catalyst::Action') ) { # action object
1626         s|/|%2F|g for @args;
1627         my $captures = [ map { s|/|%2F|g; $_; }
1628                         ( scalar @args && ref $args[0] eq 'ARRAY'
1629                          ? @{ shift(@args) }
1630                          : ()) ];
1631
1632         my $action = $path;
1633         my $expanded_action = $c->dispatcher->expand_action( $action );
1634         my $num_captures = $expanded_action->number_of_captures;
1635
1636         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1637         if( !@args && $action->number_of_args ) {
1638           unshift @args, splice @$captures, $num_captures;
1639         }
1640
1641         if($num_captures) {
1642           unless($expanded_action->match_captures_constraints($c, $captures)) {
1643             $c->log->debug("captures [@{$captures}] do not match the type constraints in actionchain ending with '$expanded_action'")
1644                 if $c->debug;
1645             return undef;
1646           }
1647         }
1648
1649         $path = $c->dispatcher->uri_for_action($action, $captures);
1650         if (not defined $path) {
1651             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1652                 if $c->debug;
1653             return undef;
1654         }
1655         $path = '/' if $path eq '';
1656
1657         # At this point @encoded_args is the remaining Args (all captures removed).
1658         if($expanded_action->has_args_constraints) {
1659           unless($expanded_action->match_args($c,\@args)) {
1660              $c->log->debug("args [@args] do not match the type constraints in action '$expanded_action'")
1661                 if $c->debug;
1662              return undef;
1663           }
1664         }
1665     }
1666
1667     unshift(@args, $path);
1668
1669     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1670         my $namespace = $c->namespace;
1671         if (defined $path) { # cheesy hack to handle path '../foo'
1672            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1673         }
1674         unshift(@args, $namespace || '');
1675     }
1676
1677     # join args with '/', or a blank string
1678     my $args = join('/', grep { defined($_) } @args);
1679     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1680     $args =~ s!^/+!!;
1681
1682     my ($base, $class) = ('/', 'URI::_generic');
1683     if(blessed($c)) {
1684       $base = $c->req->base;
1685       if($target_action) {
1686         $target_action = $c->dispatcher->expand_action($target_action);
1687         if(my $s = $target_action->scheme) {
1688           $s = lc($s);
1689           $class = "URI::$s";
1690           $base->scheme($s);
1691         } else {
1692           $class = ref($base);
1693         }
1694       } else {
1695         $class = ref($base);
1696       }
1697
1698       $base =~ s{(?<!/)$}{/};
1699     }
1700
1701     my $query = '';
1702     if (my @keys = keys %$params) {
1703       # somewhat lifted from URI::_query's query_form
1704       $query = '?'.join('&', map {
1705           my $val = $params->{$_};
1706           my $key = encode_utf8($_);
1707           # using the URI::Escape pattern here so utf8 chars survive
1708           $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1709           $key =~ s/ /+/g;
1710
1711           $val = '' unless defined $val;
1712           (map {
1713               my $param = encode_utf8($_);
1714               # using the URI::Escape pattern here so utf8 chars survive
1715               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1716               $param =~ s/ /+/g;
1717
1718               "${key}=$param";
1719           } ( ref $val eq 'ARRAY' ? @$val : $val ));
1720       } @keys);
1721     }
1722
1723     $base = encode_utf8 $base;
1724     $base =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1725     $args = encode_utf8 $args;
1726     $args =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1727
1728     if(defined $fragment) {
1729       if(blessed $path) {
1730         $fragment = encode_utf8($fragment);
1731         $fragment =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1732         $fragment =~ s/ /+/g;
1733       }
1734       $query .= "#$fragment";
1735     }
1736
1737     my $res = bless(\"${base}${args}${query}", $class);
1738     $res;
1739 }
1740
1741 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1742
1743 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1744
1745 =over
1746
1747 =item $path
1748
1749 A private path to the Catalyst action you want to create a URI for.
1750
1751 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1752 >> and passing the resulting C<$action> and the remaining arguments to C<<
1753 $c->uri_for >>.
1754
1755 You can also pass in a Catalyst::Action object, in which case it is passed to
1756 C<< $c->uri_for >>.
1757
1758 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1759
1760 For example, if the action looks like:
1761
1762  package MyApp::Controller::Users;
1763
1764  sub lst : Path('the-list') {}
1765
1766 You can use:
1767
1768  $c->uri_for_action('/users/lst')
1769
1770 and it will create the URI /users/the-list.
1771
1772 =item \@captures_and_args?
1773
1774 Optional array reference of Captures (i.e. C<CaptureArgs> or C<< $c->req->captures >>)
1775 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1776 to interpolate all the parameters in the URI.
1777
1778 =item @args?
1779
1780 Optional list of extra arguments - can be supplied in the
1781 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1782 code.
1783
1784 Your action can have zero, a fixed or a variable number of args (e.g.
1785 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1786
1787 =item \%query_values?
1788
1789 Optional array reference of query parameters to append. E.g.
1790
1791   { foo => 'bar' }
1792
1793 will generate
1794
1795   /rest/of/your/uri?foo=bar
1796
1797 =back
1798
1799 =cut
1800
1801 sub uri_for_action {
1802     my ( $c, $path, @args ) = @_;
1803     my $action = blessed($path)
1804       ? $path
1805       : $c->dispatcher->get_action_by_path($path);
1806     unless (defined $action) {
1807       croak "Can't find action for path '$path'";
1808     }
1809     return $c->uri_for( $action, @args );
1810 }
1811
1812 =head2 $c->welcome_message
1813
1814 Returns the Catalyst welcome HTML page.
1815
1816 =cut
1817
1818 sub welcome_message {
1819     my $c      = shift;
1820     my $name   = $c->config->{name};
1821     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1822     my $prefix = Catalyst::Utils::appprefix( ref $c );
1823     $c->response->content_type('text/html; charset=utf-8');
1824     return <<"EOF";
1825 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1826     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1827 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1828     <head>
1829     <meta http-equiv="Content-Language" content="en" />
1830     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1831         <title>$name on Catalyst $VERSION</title>
1832         <style type="text/css">
1833             body {
1834                 color: #000;
1835                 background-color: #eee;
1836             }
1837             div#content {
1838                 width: 640px;
1839                 margin-left: auto;
1840                 margin-right: auto;
1841                 margin-top: 10px;
1842                 margin-bottom: 10px;
1843                 text-align: left;
1844                 background-color: #ccc;
1845                 border: 1px solid #aaa;
1846             }
1847             p, h1, h2 {
1848                 margin-left: 20px;
1849                 margin-right: 20px;
1850                 font-family: verdana, tahoma, sans-serif;
1851             }
1852             a {
1853                 font-family: verdana, tahoma, sans-serif;
1854             }
1855             :link, :visited {
1856                     text-decoration: none;
1857                     color: #b00;
1858                     border-bottom: 1px dotted #bbb;
1859             }
1860             :link:hover, :visited:hover {
1861                     color: #555;
1862             }
1863             div#topbar {
1864                 margin: 0px;
1865             }
1866             pre {
1867                 margin: 10px;
1868                 padding: 8px;
1869             }
1870             div#answers {
1871                 padding: 8px;
1872                 margin: 10px;
1873                 background-color: #fff;
1874                 border: 1px solid #aaa;
1875             }
1876             h1 {
1877                 font-size: 0.9em;
1878                 font-weight: normal;
1879                 text-align: center;
1880             }
1881             h2 {
1882                 font-size: 1.0em;
1883             }
1884             p {
1885                 font-size: 0.9em;
1886             }
1887             p img {
1888                 float: right;
1889                 margin-left: 10px;
1890             }
1891             span#appname {
1892                 font-weight: bold;
1893                 font-size: 1.6em;
1894             }
1895         </style>
1896     </head>
1897     <body>
1898         <div id="content">
1899             <div id="topbar">
1900                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1901                     $VERSION</h1>
1902              </div>
1903              <div id="answers">
1904                  <p>
1905                  <img src="$logo" alt="Catalyst Logo" />
1906                  </p>
1907                  <p>Welcome to the  world of Catalyst.
1908                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1909                     framework will make web development something you had
1910                     never expected it to be: Fun, rewarding, and quick.</p>
1911                  <h2>What to do now?</h2>
1912                  <p>That really depends  on what <b>you</b> want to do.
1913                     We do, however, provide you with a few starting points.</p>
1914                  <p>If you want to jump right into web development with Catalyst
1915                     you might want to start with a tutorial.</p>
1916 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1917 </pre>
1918 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1919 <pre>
1920 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1921 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1922 </code></pre>
1923                  <h2>What to do next?</h2>
1924                  <p>Next it's time to write an actual application. Use the
1925                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1926                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1927                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1928                     they can save you a lot of work.</p>
1929                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1930                     <p>Also, be sure to check out the vast and growing
1931                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1932                     you are likely to find what you need there.
1933                     </p>
1934
1935                  <h2>Need help?</h2>
1936                  <p>Catalyst has a very active community. Here are the main places to
1937                     get in touch with us.</p>
1938                  <ul>
1939                      <li>
1940                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1941                      </li>
1942                      <li>
1943                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1944                      </li>
1945                      <li>
1946                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1947                      </li>
1948                  </ul>
1949                  <h2>In conclusion</h2>
1950                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1951                     as we enjoyed making it. Please contact us if you have ideas
1952                     for improvement or other feedback.</p>
1953              </div>
1954          </div>
1955     </body>
1956 </html>
1957 EOF
1958 }
1959
1960 =head2 run_options
1961
1962 Contains a hash of options passed from the application script, including
1963 the original ARGV the script received, the processed values from that
1964 ARGV and any extra arguments to the script which were not processed.
1965
1966 This can be used to add custom options to your application's scripts
1967 and setup your application differently depending on the values of these
1968 options.
1969
1970 =head1 INTERNAL METHODS
1971
1972 These methods are not meant to be used by end users.
1973
1974 =head2 $c->components
1975
1976 Returns a hash of components.
1977
1978 =head2 $c->context_class
1979
1980 Returns or sets the context class.
1981
1982 =head2 $c->counter
1983
1984 Returns a hashref containing coderefs and execution counts (needed for
1985 deep recursion detection).
1986
1987 =head2 $c->depth
1988
1989 Returns the number of actions on the current internal execution stack.
1990
1991 =head2 $c->dispatch
1992
1993 Dispatches a request to actions.
1994
1995 =cut
1996
1997 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1998
1999 =head2 $c->dispatcher_class
2000
2001 Returns or sets the dispatcher class.
2002
2003 =head2 $c->dump_these
2004
2005 Returns a list of 2-element array references (name, structure) pairs
2006 that will be dumped on the error page in debug mode.
2007
2008 =cut
2009
2010 sub dump_these {
2011     my $c = shift;
2012     [ Request => $c->req ],
2013     [ Response => $c->res ],
2014     [ Stash => $c->stash ],
2015     [ Config => $c->config ];
2016 }
2017
2018 =head2 $c->engine_class
2019
2020 Returns or sets the engine class.
2021
2022 =head2 $c->execute( $class, $coderef )
2023
2024 Execute a coderef in given class and catch exceptions. Errors are available
2025 via $c->error.
2026
2027 =cut
2028
2029 sub execute {
2030     my ( $c, $class, $code ) = @_;
2031     $class = $c->component($class) || $class;
2032     #$c->state(0);
2033
2034     if ( $c->depth >= $RECURSION ) {
2035         my $action = $code->reverse();
2036         $action = "/$action" unless $action =~ /->/;
2037         my $error = qq/Deep recursion detected calling "${action}"/;
2038         $c->log->error($error);
2039         $c->error($error);
2040         $c->state(0);
2041         return $c->state;
2042     }
2043
2044     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
2045
2046     push( @{ $c->stack }, $code );
2047
2048     no warnings 'recursion';
2049     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
2050     #      I have no idea how, ergo $ret (which appears to fix the issue)
2051     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
2052
2053     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
2054
2055     my $last = pop( @{ $c->stack } );
2056
2057     if ( my $error = $@ ) {
2058         #rethow if this can be handled by middleware
2059         if ( $c->_handle_http_exception($error) ) {
2060             foreach my $err (@{$c->error}) {
2061                 $c->log->error($err);
2062             }
2063             $c->clear_errors;
2064             $c->log->_flush if $c->log->can('_flush');
2065
2066             $error->can('rethrow') ? $error->rethrow : croak $error;
2067         }
2068         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
2069             $error->rethrow if $c->depth > 1;
2070         }
2071         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
2072             $error->rethrow if $c->depth > 0;
2073         }
2074         else {
2075             unless ( ref $error ) {
2076                 no warnings 'uninitialized';
2077                 chomp $error;
2078                 my $class = $last->class;
2079                 my $name  = $last->name;
2080                 $error = qq/Caught exception in $class->$name "$error"/;
2081             }
2082             $c->error($error);
2083         }
2084         #$c->state(0);
2085     }
2086     return $c->state;
2087 }
2088
2089 sub _stats_start_execute {
2090     my ( $c, $code ) = @_;
2091     my $appclass = ref($c) || $c;
2092     return if ( ( $code->name =~ /^_.*/ )
2093         && ( !$appclass->config->{show_internal_actions} ) );
2094
2095     my $action_name = $code->reverse();
2096     $c->counter->{$action_name}++;
2097
2098     my $action = $action_name;
2099     $action = "/$action" unless $action =~ /->/;
2100
2101     # determine if the call was the result of a forward
2102     # this is done by walking up the call stack and looking for a calling
2103     # sub of Catalyst::forward before the eval
2104     my $callsub = q{};
2105     for my $index ( 2 .. 11 ) {
2106         last
2107         if ( ( caller($index) )[0] eq 'Catalyst'
2108             && ( caller($index) )[3] eq '(eval)' );
2109
2110         if ( ( caller($index) )[3] =~ /forward$/ ) {
2111             $callsub = ( caller($index) )[3];
2112             $action  = "-> $action";
2113             last;
2114         }
2115     }
2116
2117     my $uid = $action_name . $c->counter->{$action_name};
2118
2119     # is this a root-level call or a forwarded call?
2120     if ( $callsub =~ /forward$/ ) {
2121         my $parent = $c->stack->[-1];
2122
2123         # forward, locate the caller
2124         if ( defined $parent && exists $c->counter->{"$parent"} ) {
2125             $c->stats->profile(
2126                 begin  => $action,
2127                 parent => "$parent" . $c->counter->{"$parent"},
2128                 uid    => $uid,
2129             );
2130         }
2131         else {
2132
2133             # forward with no caller may come from a plugin
2134             $c->stats->profile(
2135                 begin => $action,
2136                 uid   => $uid,
2137             );
2138         }
2139     }
2140     else {
2141
2142         # root-level call
2143         $c->stats->profile(
2144             begin => $action,
2145             uid   => $uid,
2146         );
2147     }
2148     return $action;
2149
2150 }
2151
2152 sub _stats_finish_execute {
2153     my ( $c, $info ) = @_;
2154     $c->stats->profile( end => $info );
2155 }
2156
2157 =head2 $c->finalize
2158
2159 Finalizes the request.
2160
2161 =cut
2162
2163 sub finalize {
2164     my $c = shift;
2165
2166     for my $error ( @{ $c->error } ) {
2167         $c->log->error($error);
2168     }
2169
2170     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
2171     # stuff like cometd and websockets
2172
2173     if($c->request->_has_io_fh) {
2174       $c->log_response;
2175       return;
2176     }
2177
2178     # Allow engine to handle finalize flow (for POE)
2179     my $engine = $c->engine;
2180     if ( my $code = $engine->can('finalize') ) {
2181         $engine->$code($c);
2182     }
2183     else {
2184
2185         $c->finalize_uploads;
2186
2187         # Error
2188         if ( $#{ $c->error } >= 0 ) {
2189             $c->finalize_error;
2190         }
2191
2192         $c->finalize_encoding;
2193         $c->finalize_headers unless $c->response->finalized_headers;
2194         $c->finalize_body;
2195     }
2196
2197     $c->log_response;
2198
2199     $c->log_stats if $c->use_stats;
2200
2201     return $c->response->status;
2202 }
2203
2204 =head2 $c->log_stats
2205
2206 Logs statistics.
2207
2208 =cut
2209
2210 sub log_stats {
2211     my $c = shift;
2212
2213     my $elapsed = $c->stats->elapsed;
2214     my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
2215     $c->log->info(
2216         "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
2217 }
2218
2219
2220 =head2 $c->finalize_body
2221
2222 Finalizes body.
2223
2224 =cut
2225
2226 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
2227
2228 =head2 $c->finalize_cookies
2229
2230 Finalizes cookies.
2231
2232 =cut
2233
2234 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
2235
2236 =head2 $c->finalize_error
2237
2238 Finalizes error.  If there is only one error in L</error> and it is an object that
2239 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2240 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2241 return the default error page (production mode).
2242
2243 =cut
2244
2245 sub finalize_error {
2246     my $c = shift;
2247     if($#{$c->error} > 0) {
2248         $c->engine->finalize_error( $c, @_ );
2249     } else {
2250         my ($error) = @{$c->error};
2251         if ( $c->_handle_http_exception($error) ) {
2252             # In the case where the error 'knows what it wants', becauses its PSGI
2253             # aware, just rethow and let middleware catch it
2254             $error->can('rethrow') ? $error->rethrow : croak $error;
2255         } else {
2256             $c->engine->finalize_error( $c, @_ )
2257         }
2258     }
2259 }
2260
2261 =head2 $c->finalize_headers
2262
2263 Finalizes headers.
2264
2265 =cut
2266
2267 sub finalize_headers {
2268     my $c = shift;
2269
2270     my $response = $c->response; #accessor calls can add up?
2271
2272     # Check if we already finalized headers
2273     return if $response->finalized_headers;
2274
2275     # Handle redirects
2276     if ( my $location = $response->redirect ) {
2277         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2278         $response->header( Location => $location );
2279     }
2280
2281     # Remove incorrectly added body and content related meta data when returning
2282     # an information response, or a response the is required to not include a body
2283
2284     $c->finalize_cookies;
2285
2286     # This currently is a NOOP but I don't want to remove it since I guess people
2287     # might have Response subclasses that use it for something... (JNAP)
2288     $c->response->finalize_headers();
2289
2290     # Done
2291     $response->finalized_headers(1);
2292 }
2293
2294 =head2 $c->finalize_encoding
2295
2296 Make sure your body is encoded properly IF you set an encoding.  By
2297 default the encoding is UTF-8 but you can disable it by explicitly setting the
2298 encoding configuration value to undef.
2299
2300 We can only encode when the body is a scalar.  Methods for encoding via the
2301 streaming interfaces (such as C<write> and C<write_fh> on L<Catalyst::Response>
2302 are available).
2303
2304 See L</ENCODING>.
2305
2306 =cut
2307
2308 sub finalize_encoding {
2309     my $c = shift;
2310     my $res = $c->res || return;
2311
2312     # Warn if the set charset is different from the one you put into encoding.  We need
2313     # to do this early since encodable_response is false for this condition and we need
2314     # to match the debug output for backcompat (there's a test for this...) -JNAP
2315     if(
2316       $res->content_type_charset and $c->encoding and
2317       (uc($c->encoding->mime_name) ne uc($res->content_type_charset))
2318     ) {
2319         my $ct = lc($res->content_type_charset);
2320         $c->log->debug("Catalyst encoding config is set to encode in '" .
2321             $c->encoding->mime_name .
2322             "', content type is '$ct', not encoding ");
2323     }
2324
2325     if(
2326       ($res->encodable_response) and
2327       (defined($res->body)) and
2328       (ref(\$res->body) eq 'SCALAR')
2329     ) {
2330         # if you are finding yourself here and your body is already encoded correctly
2331         # and you want to turn this off, use $c->clear_encoding to prevent encoding
2332         # at this step, or set encoding to undef in the config to do so for the whole
2333         # application.  See the ENCODING documentaiton for better notes.
2334         $c->res->body( $c->encoding->encode( $c->res->body, $c->_encode_check ) );
2335
2336         # Set the charset if necessary.  This might be a bit bonkers since encodable response
2337         # is false when the set charset is not the same as the encoding mimetype (maybe
2338         # confusing action at a distance here..
2339         # Don't try to set the charset if one already exists or if headers are already finalized
2340         $c->res->content_type($c->res->content_type . "; charset=" . $c->encoding->mime_name)
2341           unless($c->res->content_type_charset ||
2342                 ($c->res->_context && $c->res->finalized_headers && !$c->res->_has_response_cb));
2343     }
2344 }
2345
2346 =head2 $c->finalize_output
2347
2348 An alias for finalize_body.
2349
2350 =head2 $c->finalize_read
2351
2352 Finalizes the input after reading is complete.
2353
2354 =cut
2355
2356 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2357
2358 =head2 $c->finalize_uploads
2359
2360 Finalizes uploads. Cleans up any temporary files.
2361
2362 =cut
2363
2364 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2365
2366 =head2 $c->get_action( $action, $namespace )
2367
2368 Gets an action in a given namespace.
2369
2370 =cut
2371
2372 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2373
2374 =head2 $c->get_actions( $action, $namespace )
2375
2376 Gets all actions of a given name in a namespace and all parent
2377 namespaces.
2378
2379 =cut
2380
2381 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2382
2383 =head2 $app->handle_request( @arguments )
2384
2385 Called to handle each HTTP request.
2386
2387 =cut
2388
2389 sub handle_request {
2390     my ( $class, @arguments ) = @_;
2391
2392     # Always expect worst case!
2393     my $status = -1;
2394     try {
2395         if ($class->debug) {
2396             my $secs = time - $START || 1;
2397             my $av = sprintf '%.3f', $COUNT / $secs;
2398             my $time = localtime time;
2399             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2400         }
2401
2402         my $c = $class->prepare(@arguments);
2403         $c->dispatch;
2404         $status = $c->finalize;
2405     } catch {
2406         #rethow if this can be handled by middleware
2407         if ( $class->_handle_http_exception($_) ) {
2408             $_->can('rethrow') ? $_->rethrow : croak $_;
2409         }
2410         chomp(my $error = $_);
2411         $class->log->error(qq/Caught exception in engine "$error"/);
2412     };
2413
2414     $COUNT++;
2415
2416     if(my $coderef = $class->log->can('_flush')){
2417         $class->log->$coderef();
2418     }
2419     return $status;
2420 }
2421
2422 =head2 $class->prepare( @arguments )
2423
2424 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2425 etc.).
2426
2427 =cut
2428
2429 has _uploadtmp => (
2430     is => 'ro',
2431     predicate => '_has_uploadtmp',
2432 );
2433
2434 sub prepare {
2435     my ( $class, @arguments ) = @_;
2436
2437     # XXX
2438     # After the app/ctxt split, this should become an attribute based on something passed
2439     # into the application.
2440     $class->context_class( ref $class || $class ) unless $class->context_class;
2441
2442     my $uploadtmp = $class->config->{uploadtmp};
2443     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2444
2445     $c->response->_context($c);
2446     $c->stats($class->stats_class->new)->enable($c->use_stats);
2447
2448     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2449         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2450     }
2451
2452     try {
2453         # Allow engine to direct the prepare flow (for POE)
2454         if ( my $prepare = $c->engine->can('prepare') ) {
2455             $c->engine->$prepare( $c, @arguments );
2456         }
2457         else {
2458             $c->prepare_request(@arguments);
2459             $c->prepare_connection;
2460             $c->prepare_query_parameters;
2461             $c->prepare_headers; # Just hooks, no longer needed - they just
2462             $c->prepare_cookies; # cause the lazy attribute on req to build
2463             $c->prepare_path;
2464
2465             # Prepare the body for reading, either by prepare_body
2466             # or the user, if they are using $c->read
2467             $c->prepare_read;
2468
2469             # Parse the body unless the user wants it on-demand
2470             unless ( ref($c)->config->{parse_on_demand} ) {
2471                 $c->prepare_body;
2472             }
2473         }
2474         $c->prepare_action;
2475     }
2476     # VERY ugly and probably shouldn't rely on ->finalize actually working
2477     catch {
2478         # failed prepare is always due to an invalid request, right?
2479         # Note we call finalize and then die here, which escapes
2480         # finalize being called in the enclosing block..
2481         # It in fact couldn't be called, as we don't return $c..
2482         # This is a mess - but I'm unsure you can fix this without
2483         # breaking compat for people doing crazy things (we should set
2484         # the 400 and just return the ctx here IMO, letting finalize get called
2485         # above...
2486         if ( $c->_handle_http_exception($_) ) {
2487             foreach my $err (@{$c->error}) {
2488                 $c->log->error($err);
2489             }
2490             $c->clear_errors;
2491             $c->log->_flush if $c->log->can('_flush');
2492             $_->can('rethrow') ? $_->rethrow : croak $_;
2493         } else {
2494             $c->response->status(400);
2495             $c->response->content_type('text/plain');
2496             $c->response->body('Bad Request');
2497             $c->finalize;
2498             die $_;
2499         }
2500     };
2501
2502     $c->log_request;
2503     $c->{stash} = $c->stash;
2504     Scalar::Util::weaken($c->{stash});
2505
2506     return $c;
2507 }
2508
2509 =head2 $c->prepare_action
2510
2511 Prepares action. See L<Catalyst::Dispatcher>.
2512
2513 =cut
2514
2515 sub prepare_action {
2516     my $c = shift;
2517     my $ret = $c->dispatcher->prepare_action( $c, @_);
2518
2519     if($c->encoding) {
2520         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2521           $_ = $c->_handle_param_unicode_decoding($_);
2522         }
2523     }
2524
2525     return $ret;
2526 }
2527
2528
2529 =head2 $c->prepare_body
2530
2531 Prepares message body.
2532
2533 =cut
2534
2535 sub prepare_body {
2536     my $c = shift;
2537
2538     return if $c->request->_has_body;
2539
2540     # Initialize on-demand data
2541     $c->engine->prepare_body( $c, @_ );
2542     $c->prepare_parameters;
2543     $c->prepare_uploads;
2544 }
2545
2546 =head2 $c->prepare_body_chunk( $chunk )
2547
2548 Prepares a chunk of data before sending it to L<HTTP::Body>.
2549
2550 See L<Catalyst::Engine>.
2551
2552 =cut
2553
2554 sub prepare_body_chunk {
2555     my $c = shift;
2556     $c->engine->prepare_body_chunk( $c, @_ );
2557 }
2558
2559 =head2 $c->prepare_body_parameters
2560
2561 Prepares body parameters.
2562
2563 =cut
2564
2565 sub prepare_body_parameters {
2566     my $c = shift;
2567     $c->request->prepare_body_parameters( $c, @_ );
2568 }
2569
2570 =head2 $c->prepare_connection
2571
2572 Prepares connection.
2573
2574 =cut
2575
2576 sub prepare_connection {
2577     my $c = shift;
2578     $c->request->prepare_connection($c);
2579 }
2580
2581 =head2 $c->prepare_cookies
2582
2583 Prepares cookies by ensuring that the attribute on the request
2584 object has been built.
2585
2586 =cut
2587
2588 sub prepare_cookies { my $c = shift; $c->request->cookies }
2589
2590 =head2 $c->prepare_headers
2591
2592 Prepares request headers by ensuring that the attribute on the request
2593 object has been built.
2594
2595 =cut
2596
2597 sub prepare_headers { my $c = shift; $c->request->headers }
2598
2599 =head2 $c->prepare_parameters
2600
2601 Prepares parameters.
2602
2603 =cut
2604
2605 sub prepare_parameters {
2606     my $c = shift;
2607     $c->prepare_body_parameters;
2608     $c->engine->prepare_parameters( $c, @_ );
2609 }
2610
2611 =head2 $c->prepare_path
2612
2613 Prepares path and base.
2614
2615 =cut
2616
2617 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2618
2619 =head2 $c->prepare_query_parameters
2620
2621 Prepares query parameters.
2622
2623 =cut
2624
2625 sub prepare_query_parameters {
2626     my $c = shift;
2627
2628     $c->engine->prepare_query_parameters( $c, @_ );
2629 }
2630
2631 =head2 $c->log_request
2632
2633 Writes information about the request to the debug logs.  This includes:
2634
2635 =over 4
2636
2637 =item * Request method, path, and remote IP address
2638
2639 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2640
2641 =item * Request parameters
2642
2643 =item * File uploads
2644
2645 =back
2646
2647 =cut
2648
2649 sub log_request {
2650     my $c = shift;
2651
2652     return unless $c->debug;
2653
2654     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2655     my $request = $dump->[1];
2656
2657     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2658     $method ||= '';
2659     $path = '/' unless length $path;
2660     $address ||= '';
2661
2662     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2663     $path = decode_utf8($path);
2664
2665     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2666
2667     $c->log_request_headers($request->headers);
2668
2669     if ( my $keywords = $request->query_keywords ) {
2670         $c->log->debug("Query keywords are: $keywords");
2671     }
2672
2673     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2674
2675     $c->log_request_uploads($request);
2676 }
2677
2678 =head2 $c->log_response
2679
2680 Writes information about the response to the debug logs by calling
2681 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2682
2683 =cut
2684
2685 sub log_response {
2686     my $c = shift;
2687
2688     return unless $c->debug;
2689
2690     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2691     my $response = $dump->[1];
2692
2693     $c->log_response_status_line($response);
2694     $c->log_response_headers($response->headers);
2695 }
2696
2697 =head2 $c->log_response_status_line($response)
2698
2699 Writes one line of information about the response to the debug logs.  This includes:
2700
2701 =over 4
2702
2703 =item * Response status code
2704
2705 =item * Content-Type header (if present)
2706
2707 =item * Content-Length header (if present)
2708
2709 =back
2710
2711 =cut
2712
2713 sub log_response_status_line {
2714     my ($c, $response) = @_;
2715
2716     $c->log->debug(
2717         sprintf(
2718             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2719             $response->status                            || 'unknown',
2720             $response->headers->header('Content-Type')   || 'unknown',
2721             $response->headers->header('Content-Length') || 'unknown'
2722         )
2723     );
2724 }
2725
2726 =head2 $c->log_response_headers($headers);
2727
2728 Hook method which can be wrapped by plugins to log the response headers.
2729 No-op in the default implementation.
2730
2731 =cut
2732
2733 sub log_response_headers {}
2734
2735 =head2 $c->log_request_parameters( query => {}, body => {} )
2736
2737 Logs request parameters to debug logs
2738
2739 =cut
2740
2741 sub log_request_parameters {
2742     my $c          = shift;
2743     my %all_params = @_;
2744
2745     return unless $c->debug;
2746
2747     my $column_width = Catalyst::Utils::term_width() - 44;
2748     foreach my $type (qw(query body)) {
2749         my $params = $all_params{$type};
2750         next if ! keys %$params;
2751         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2752         for my $key ( sort keys %$params ) {
2753             my @values = ();
2754             if(ref $params eq 'Hash::MultiValue') {
2755                 @values = $params->get_all($key);
2756             } else {
2757                 my $param = $params->{$key};
2758                 if( defined($param) ) {
2759                     @values = ref $param eq 'ARRAY' ? @$param : $param;
2760                 }
2761             }
2762             $t->row( $key.( scalar @values > 1 ? ' [multiple]' : ''), join(', ', @values) );
2763         }
2764         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2765     }
2766 }
2767
2768 =head2 $c->log_request_uploads
2769
2770 Logs file uploads included in the request to the debug logs.
2771 The parameter name, filename, file type, and file size are all included in
2772 the debug logs.
2773
2774 =cut
2775
2776 sub log_request_uploads {
2777     my $c = shift;
2778     my $request = shift;
2779     return unless $c->debug;
2780     my $uploads = $request->uploads;
2781     if ( keys %$uploads ) {
2782         my $t = Text::SimpleTable->new(
2783             [ 12, 'Parameter' ],
2784             [ 26, 'Filename' ],
2785             [ 18, 'Type' ],
2786             [ 9,  'Size' ]
2787         );
2788         for my $key ( sort keys %$uploads ) {
2789             my $upload = $uploads->{$key};
2790             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2791                 $t->row( $key, $u->filename, $u->type, $u->size );
2792             }
2793         }
2794         $c->log->debug( "File Uploads are:\n" . $t->draw );
2795     }
2796 }
2797
2798 =head2 $c->log_request_headers($headers);
2799
2800 Hook method which can be wrapped by plugins to log the request headers.
2801 No-op in the default implementation.
2802
2803 =cut
2804
2805 sub log_request_headers {}
2806
2807 =head2 $c->log_headers($type => $headers)
2808
2809 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2810
2811 =cut
2812
2813 sub log_headers {
2814     my $c       = shift;
2815     my $type    = shift;
2816     my $headers = shift;    # an HTTP::Headers instance
2817
2818     return unless $c->debug;
2819
2820     my $column_width = Catalyst::Utils::term_width() - 28;
2821     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2822     $headers->scan(
2823         sub {
2824             my ( $name, $value ) = @_;
2825             $t->row( $name, $value );
2826         }
2827     );
2828     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2829 }
2830
2831
2832 =head2 $c->prepare_read
2833
2834 Prepares the input for reading.
2835
2836 =cut
2837
2838 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2839
2840 =head2 $c->prepare_request
2841
2842 Prepares the engine request.
2843
2844 =cut
2845
2846 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2847
2848 =head2 $c->prepare_uploads
2849
2850 Prepares uploads.
2851
2852 =cut
2853
2854 sub prepare_uploads {
2855     my $c = shift;
2856     $c->engine->prepare_uploads( $c, @_ );
2857 }
2858
2859 =head2 $c->prepare_write
2860
2861 Prepares the output for writing.
2862
2863 =cut
2864
2865 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2866
2867 =head2 $c->request_class
2868
2869 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2870
2871 =head2 $app->request_class_traits
2872
2873 An arrayref of L<Moose::Role>s which are applied to the request class.  You can
2874 name the full namespace of the role, or a namespace suffix, which will then
2875 be tried against the following standard namespace prefixes.
2876
2877     $MyApp::TraitFor::Request::$trait_suffix
2878     Catalyst::TraitFor::Request::$trait_suffix
2879
2880 So for example if you set:
2881
2882     MyApp->request_class_traits(['Foo']);
2883
2884 We try each possible role in turn (and throw an error if none load)
2885
2886     Foo
2887     MyApp::TraitFor::Request::Foo
2888     Catalyst::TraitFor::Request::Foo
2889
2890 The namespace part 'TraitFor::Request' was chosen to assist in backwards
2891 compatibility with L<CatalystX::RoleApplicator> which previously provided
2892 these features in a stand alone package.
2893
2894 =head2 $app->composed_request_class
2895
2896 This is the request class which has been composed with any request_class_traits.
2897
2898 =head2 $c->response_class
2899
2900 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2901
2902 =head2 $app->response_class_traits
2903
2904 An arrayref of L<Moose::Role>s which are applied to the response class.  You can
2905 name the full namespace of the role, or a namespace suffix, which will then
2906 be tried against the following standard namespace prefixes.
2907
2908     $MyApp::TraitFor::Response::$trait_suffix
2909     Catalyst::TraitFor::Response::$trait_suffix
2910
2911 So for example if you set:
2912
2913     MyApp->response_class_traits(['Foo']);
2914
2915 We try each possible role in turn (and throw an error if none load)
2916
2917     Foo
2918     MyApp::TraitFor::Response::Foo
2919     Catalyst::TraitFor::Responset::Foo
2920
2921 The namespace part 'TraitFor::Response' was chosen to assist in backwards
2922 compatibility with L<CatalystX::RoleApplicator> which previously provided
2923 these features in a stand alone package.
2924
2925
2926 =head2 $app->composed_response_class
2927
2928 This is the request class which has been composed with any response_class_traits.
2929
2930 =head2 $c->read( [$maxlength] )
2931
2932 Reads a chunk of data from the request body. This method is designed to
2933 be used in a while loop, reading C<$maxlength> bytes on every call.
2934 C<$maxlength> defaults to the size of the request if not specified.
2935
2936 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2937 directly.
2938
2939 Warning: If you use read(), Catalyst will not process the body,
2940 so you will not be able to access POST parameters or file uploads via
2941 $c->request.  You must handle all body parsing yourself.
2942
2943 =cut
2944
2945 sub read { my $c = shift; return $c->request->read( @_ ) }
2946
2947 =head2 $c->run
2948
2949 Starts the engine.
2950
2951 =cut
2952
2953 sub run {
2954   my $app = shift;
2955   $app->_make_immutable_if_needed;
2956   $app->engine_loader->needs_psgi_engine_compat_hack ?
2957     $app->engine->run($app, @_) :
2958       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2959 }
2960
2961 sub _make_immutable_if_needed {
2962     my $class = shift;
2963     my $meta = find_meta($class);
2964     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2965     if (
2966         $meta->is_immutable
2967         && ! { $meta->immutable_options }->{replace_constructor}
2968         && $isa_ca
2969     ) {
2970         warn("You made your application class ($class) immutable, "
2971             . "but did not inline the\nconstructor. "
2972             . "This will break catalyst, as your app \@ISA "
2973             . "Class::Accessor(::Fast)?\nPlease pass "
2974             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2975     }
2976     unless ($meta->is_immutable) {
2977         # XXX - FIXME warning here as you should make your app immutable yourself.
2978         $meta->make_immutable(
2979             replace_constructor => 1,
2980         );
2981     }
2982 }
2983
2984 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2985
2986 Sets an action in a given namespace.
2987
2988 =cut
2989
2990 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2991
2992 =head2 $c->setup_actions($component)
2993
2994 Sets up actions for a component.
2995
2996 =cut
2997
2998 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2999
3000 =head2 $c->setup_components
3001
3002 This method is called internally to set up the application's components.
3003
3004 It finds modules by calling the L<locate_components> method, expands them to
3005 package names with the L<expand_component_module> method, and then installs
3006 each component into the application.
3007
3008 The C<setup_components> config option is passed to both of the above methods.
3009
3010 Installation of each component is performed by the L<setup_component> method,
3011 below.
3012
3013 =cut
3014
3015 sub setup_components {
3016     my $class = shift;
3017
3018     my $config  = $class->config->{ setup_components };
3019
3020     my @comps = $class->locate_components($config);
3021     my %comps = map { $_ => 1 } @comps;
3022
3023     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
3024     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
3025         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
3026     ) if $deprecatedcatalyst_component_names;
3027
3028     for my $component ( @comps ) {
3029
3030         # We pass ignore_loaded here so that overlay files for (e.g.)
3031         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
3032         # we know M::P::O found a file on disk so this is safe
3033
3034         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
3035     }
3036
3037     for my $component (@comps) {
3038         my $instance = $class->components->{ $component } = $class->delayed_setup_component($component);
3039     }
3040
3041     # Inject a component or wrap a stand alone class in an adaptor. This makes a list
3042     # of named components in the configuration that are not actually existing (not a
3043     # real file).
3044
3045     my @injected = $class->setup_injected_components;
3046
3047     # All components are registered, now we need to 'init' them.
3048     foreach my $component_name (@comps, @injected) {
3049       $class->components->{$component_name} = $class->components->{$component_name}->() if
3050         (ref($class->components->{$component_name}) || '') eq 'CODE';
3051     }
3052 }
3053
3054 =head2 $app->setup_injected_components
3055
3056 Called by setup_compoents to setup components that are injected.
3057
3058 =cut
3059
3060 sub setup_injected_components {
3061     my ($class) = @_;
3062     my @injected_components = keys %{$class->config->{inject_components} ||+{}};
3063
3064     foreach my $injected_comp_name(@injected_components) {
3065         $class->setup_injected_component(
3066           $injected_comp_name,
3067           $class->config->{inject_components}->{$injected_comp_name});
3068     }
3069
3070     return map { $class ."::" . $_ }
3071       @injected_components;
3072 }
3073
3074 =head2 $app->setup_injected_component( $injected_component_name, $config )
3075
3076 Setup a given injected component.
3077
3078 =cut
3079
3080 sub setup_injected_component {
3081     my ($class, $injected_comp_name, $config) = @_;
3082     if(my $component_class = $config->{from_component}) {
3083         my @roles = @{$config->{roles} ||[]};
3084         Catalyst::Utils::inject_component(
3085           into => $class,
3086           component => $component_class,
3087           (scalar(@roles) ? (traits => \@roles) : ()),
3088           as => $injected_comp_name);
3089     }
3090 }
3091
3092 =head2 $app->inject_component($MyApp_Component_name => \%args);
3093
3094 Add a component that is injected at setup:
3095
3096     MyApp->inject_component( 'Model::Foo' => { from_component => 'Common::Foo' } );
3097
3098 Must be called before ->setup.  Expects a component name for your
3099 current application and \%args where
3100
3101 =over 4
3102
3103 =item from_component
3104
3105 The target component being injected into your application
3106
3107 =item roles
3108
3109 An arrayref of L<Moose::Role>s that are applied to your component.
3110
3111 =back
3112
3113 Example
3114
3115     MyApp->inject_component(
3116       'Model::Foo' => {
3117         from_component => 'Common::Model::Foo',
3118         roles => ['Role1', 'Role2'],
3119       });
3120
3121 =head2 $app->inject_components
3122
3123 Inject a list of components:
3124
3125     MyApp->inject_components(
3126       'Model::FooOne' => {
3127         from_component => 'Common::Model::Foo',
3128         roles => ['Role1', 'Role2'],
3129       },
3130       'Model::FooTwo' => {
3131         from_component => 'Common::Model::Foo',
3132         roles => ['Role1', 'Role2'],
3133       });
3134
3135 =cut
3136
3137 sub inject_component {
3138   my ($app, $name, $args) = @_;
3139   die "Component $name exists" if
3140     $app->config->{inject_components}->{$name};
3141   $app->config->{inject_components}->{$name} = $args;
3142 }
3143
3144 sub inject_components {
3145   my $app = shift;
3146   while(@_) {
3147     $app->inject_component(shift, shift);
3148   }
3149 }
3150
3151 =head2 $c->locate_components( $setup_component_config )
3152
3153 This method is meant to provide a list of component modules that should be
3154 setup for the application.  By default, it will use L<Module::Pluggable>.
3155
3156 Specify a C<setup_components> config option to pass additional options directly
3157 to L<Module::Pluggable>. To add additional search paths, specify a key named
3158 C<search_extra> as an array reference. Items in the array beginning with C<::>
3159 will have the application class name prepended to them.
3160
3161 =cut
3162
3163 sub locate_components {
3164     my $class  = shift;
3165     my $config = shift;
3166
3167     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
3168     my $extra   = $config->{ search_extra } || [];
3169
3170     unshift @paths, @$extra;
3171
3172     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
3173       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
3174       %$config
3175     )->plugins } @paths;
3176
3177     return @comps;
3178 }
3179
3180 =head2 $c->expand_component_module( $component, $setup_component_config )
3181
3182 Components found by C<locate_components> will be passed to this method, which
3183 is expected to return a list of component (package) names to be set up.
3184
3185 =cut
3186
3187 sub expand_component_module {
3188     my ($class, $module) = @_;
3189     return Devel::InnerPackage::list_packages( $module );
3190 }
3191
3192 =head2 $app->delayed_setup_component
3193
3194 Returns a coderef that points to a setup_component instance.  Used
3195 internally for when you want to delay setup until the first time
3196 the component is called.
3197
3198 =cut
3199
3200 sub delayed_setup_component {
3201   my($class, $component, @more) = @_;
3202   return sub {
3203     return my $instance = $class->setup_component($component, @more);
3204   };
3205 }
3206
3207 =head2 $c->setup_component
3208
3209 =cut
3210
3211 sub setup_component {
3212     my( $class, $component ) = @_;
3213
3214     unless ( $component->can( 'COMPONENT' ) ) {
3215         return $component;
3216     }
3217
3218     my $config = $class->config_for($component);
3219     # Stash catalyst_component_name in the config here, so that custom COMPONENT
3220     # methods also pass it. local to avoid pointlessly shitting in config
3221     # for the debug screen, as $component is already the key name.
3222     local $config->{catalyst_component_name} = $component;
3223
3224     my $instance = eval {
3225       $component->COMPONENT( $class, $config );
3226     } || do {
3227       my $error = $@;
3228       chomp $error;
3229       Catalyst::Exception->throw(
3230         message => qq/Couldn't instantiate component "$component", "$error"/
3231       );
3232     };
3233
3234     unless (blessed $instance) {
3235         my $metaclass = Moose::Util::find_meta($component);
3236         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
3237         my $component_method_from = $method_meta->associated_metaclass->name;
3238         my $value = defined($instance) ? $instance : 'undef';
3239         Catalyst::Exception->throw(
3240             message =>
3241             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
3242         );
3243     }
3244
3245     my @expanded_components = $instance->can('expand_modules')
3246       ? $instance->expand_modules( $component, $config )
3247       : $class->expand_component_module( $component, $config );
3248     for my $component (@expanded_components) {
3249       next if $class->components->{ $component };
3250       $class->components->{ $component } = $class->setup_component($component);
3251     }
3252
3253     return $instance;
3254 }
3255
3256 =head2 $app->config_for( $component_name )
3257
3258 Return the application level configuration (which is not yet merged with any
3259 local component configuration, via $component_class->config) for the named
3260 component or component object. Example:
3261
3262     MyApp->config(
3263       'Model::Foo' => { a => 1, b => 2},
3264     );
3265
3266     my $config = MyApp->config_for('MyApp::Model::Foo');
3267
3268 In this case $config is the hashref C<< {a=>1, b=>2} >>.
3269
3270 This is also handy for looking up configuration for a plugin, to make sure you follow
3271 existing L<Catalyst> standards for where a plugin should put its configuration.
3272
3273 =cut
3274
3275 sub config_for {
3276     my ($class, $component_name) = @_;
3277     my $component_suffix = Catalyst::Utils::class2classsuffix($component_name);
3278     my $config = $class->config->{ $component_suffix } || {};
3279
3280     return $config;
3281 }
3282
3283 =head2 $c->setup_dispatcher
3284
3285 Sets up dispatcher.
3286
3287 =cut
3288
3289 sub setup_dispatcher {
3290     my ( $class, $dispatcher ) = @_;
3291
3292     if ($dispatcher) {
3293         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
3294     }
3295
3296     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
3297         $dispatcher = 'Catalyst::Dispatcher::' . $env;
3298     }
3299
3300     unless ($dispatcher) {
3301         $dispatcher = $class->dispatcher_class;
3302     }
3303
3304     load_class($dispatcher);
3305
3306     # dispatcher instance
3307     $class->dispatcher( $dispatcher->new );
3308 }
3309
3310 =head2 $c->setup_engine
3311
3312 Sets up engine.
3313
3314 =cut
3315
3316 sub engine_class {
3317     my ($class, $requested_engine) = @_;
3318
3319     if (!$class->engine_loader || $requested_engine) {
3320         $class->engine_loader(
3321             Catalyst::EngineLoader->new({
3322                 application_name => $class,
3323                 (defined $requested_engine
3324                      ? (catalyst_engine_class => $requested_engine) : ()),
3325             }),
3326         );
3327     }
3328
3329     $class->engine_loader->catalyst_engine_class;
3330 }
3331
3332 sub setup_engine {
3333     my ($class, $requested_engine) = @_;
3334
3335     my $engine = do {
3336         my $loader = $class->engine_loader;
3337
3338         if (!$loader || $requested_engine) {
3339             $loader = Catalyst::EngineLoader->new({
3340                 application_name => $class,
3341                 (defined $requested_engine
3342                      ? (requested_engine => $requested_engine) : ()),
3343             }),
3344
3345             $class->engine_loader($loader);
3346         }
3347
3348         $loader->catalyst_engine_class;
3349     };
3350
3351     # Don't really setup_engine -- see _setup_psgi_app for explanation.
3352     return if $class->loading_psgi_file;
3353
3354     load_class($engine);
3355
3356     if ($ENV{MOD_PERL}) {
3357         my $apache = $class->engine_loader->auto;
3358
3359         my $meta = find_meta($class);
3360         my $was_immutable = $meta->is_immutable;
3361         my %immutable_options = $meta->immutable_options;
3362         $meta->make_mutable if $was_immutable;
3363
3364         $meta->add_method(handler => sub {
3365             my $r = shift;
3366             my $psgi_app = $class->_finalized_psgi_app;
3367             $apache->call_app($r, $psgi_app);
3368         });
3369
3370         $meta->make_immutable(%immutable_options) if $was_immutable;
3371     }
3372
3373     $class->engine( $engine->new );
3374
3375     return;
3376 }
3377
3378 ## This exists just to supply a prebuild psgi app for mod_perl and for the
3379 ## build in server support (back compat support for pre psgi port behavior).
3380 ## This is so that we don't build a new psgi app for each request when using
3381 ## the mod_perl handler or the built in servers (http and fcgi, etc).
3382
3383 sub _finalized_psgi_app {
3384     my ($app) = @_;
3385
3386     unless ($app->_psgi_app) {
3387         my $psgi_app = $app->_setup_psgi_app;
3388         $app->_psgi_app($psgi_app);
3389     }
3390
3391     return $app->_psgi_app;
3392 }
3393
3394 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
3395 ## home directory and load that and return it (just assume it is doing the
3396 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
3397 ## in default_middleware and return it ( this is for backward compatibility
3398 ## with pre psgi port behavior ).
3399
3400 sub _setup_psgi_app {
3401     my ($app) = @_;
3402
3403     for my $home (Path::Class::Dir->new($app->config->{home})) {
3404         my $psgi_file = $home->file(
3405             Catalyst::Utils::appprefix($app) . '.psgi',
3406         );
3407
3408         next unless -e $psgi_file;
3409
3410         # If $psgi_file calls ->setup_engine, it's doing so to load
3411         # Catalyst::Engine::PSGI. But if it does that, we're only going to
3412         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
3413         # anyway. So set a flag (ick) that tells setup_engine not to populate
3414         # $c->engine or do any other things we might regret.
3415
3416         $app->loading_psgi_file(1);
3417         my $psgi_app = Plack::Util::load_psgi($psgi_file);
3418         $app->loading_psgi_file(0);
3419
3420         return $psgi_app
3421             unless $app->engine_loader->needs_psgi_engine_compat_hack;
3422
3423         warn <<"EOW";
3424 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
3425
3426 Its content has been ignored. Please consult the Catalyst::Upgrading
3427 documentation on how to upgrade from Catalyst::Engine::PSGI.
3428 EOW
3429     }
3430
3431     return $app->apply_default_middlewares($app->psgi_app);
3432 }
3433
3434 =head2 $c->apply_default_middlewares
3435
3436 Adds the following L<Plack> middlewares to your application, since they are
3437 useful and commonly needed:
3438
3439 L<Plack::Middleware::LighttpdScriptNameFix> (if you are using Lighttpd),
3440 L<Plack::Middleware::IIS6ScriptNameFix> (always applied since this middleware
3441 is smart enough to conditionally apply itself).
3442
3443 We will also automatically add L<Plack::Middleware::ReverseProxy> if we notice
3444 that your HTTP $env variable C<REMOTE_ADDR> is '127.0.0.1'.  This is usually
3445 an indication that your server is running behind a proxy frontend.  However in
3446 2014 this is often not the case.  We preserve this code for backwards compatibility
3447 however I B<highly> recommend that if you are running the server behind a front
3448 end proxy that you clearly indicate so with the C<using_frontend_proxy> configuration
3449 setting to true for your environment configurations that run behind a proxy.  This
3450 way if you change your front end proxy address someday your code would inexplicably
3451 stop working as expected.
3452
3453 Additionally if we detect we are using Nginx, we add a bit of custom middleware
3454 to solve some problems with the way that server handles $ENV{PATH_INFO} and
3455 $ENV{SCRIPT_NAME}.
3456
3457 Please B<NOTE> that if you do use C<using_frontend_proxy> the middleware is now
3458 adding via C<registered_middleware> rather than this method.
3459
3460 If you are using Lighttpd or IIS6 you may wish to apply these middlewares.  In
3461 general this is no longer a common case but we have this here for backward
3462 compatibility.
3463
3464 =cut
3465
3466
3467 sub apply_default_middlewares {
3468     my ($app, $psgi_app) = @_;
3469
3470     # Don't add this conditional IF we are explicitly saying we want the
3471     # frontend proxy support.  We don't need it here since if that is the
3472     # case it will be always loaded in the default_middleware.
3473
3474     unless($app->config->{using_frontend_proxy}) {
3475       $psgi_app = Plack::Middleware::Conditional->wrap(
3476           $psgi_app,
3477           builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
3478           condition => sub {
3479               my ($env) = @_;
3480               return if $app->config->{ignore_frontend_proxy};
3481               return $env->{REMOTE_ADDR} && $env->{REMOTE_ADDR} eq '127.0.0.1';
3482           },
3483       );
3484     }
3485
3486     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3487     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3488     $psgi_app = Plack::Middleware::Conditional->wrap(
3489         $psgi_app,
3490         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3491         condition => sub {
3492             my ($env) = @_;
3493             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3494             return unless $1 < 4.23;
3495             1;
3496         },
3497     );
3498
3499     # we're applying this unconditionally as the middleware itself already makes
3500     # sure it doesn't fuck things up if it's not running under one of the right
3501     # IIS versions
3502     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3503
3504     # And another IIS issue, this time with IIS7.
3505     $psgi_app = Plack::Middleware::Conditional->wrap(
3506         $psgi_app,
3507         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3508         condition => sub {
3509             my ($env) = @_;
3510             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3511         },
3512     );
3513
3514     return $psgi_app;
3515 }
3516
3517 =head2 App->psgi_app
3518
3519 =head2 App->to_app
3520
3521 Returns a PSGI application code reference for the catalyst application
3522 C<$c>. This is the bare application created without the C<apply_default_middlewares>
3523 method called.  We do however apply C<registered_middleware> since those are
3524 integral to how L<Catalyst> functions.  Also, unlike starting your application
3525 with a generated server script (via L<Catalyst::Devel> and C<catalyst.pl>) we do
3526 not attempt to return a valid L<PSGI> application using any existing C<${myapp}.psgi>
3527 scripts in your $HOME directory.
3528
3529 B<NOTE> C<apply_default_middlewares> was originally created when the first PSGI
3530 port was done for v5.90000.  These are middlewares that are added to achieve
3531 backward compatibility with older applications.  If you start your application
3532 using one of the supplied server scripts (generated with L<Catalyst::Devel> and
3533 the project skeleton script C<catalyst.pl>) we apply C<apply_default_middlewares>
3534 automatically.  This was done so that pre and post PSGI port applications would
3535 work the same way.
3536
3537 This is what you want to be using to retrieve the PSGI application code
3538 reference of your Catalyst application for use in a custom F<.psgi> or in your
3539 own created server modules.
3540
3541 =cut
3542
3543 *to_app = \&psgi_app;
3544
3545 sub psgi_app {
3546     my ($app) = @_;
3547     my $psgi = $app->engine->build_psgi_app($app);
3548     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3549 }
3550
3551 =head2 $c->setup_home
3552
3553 Sets up the home directory.
3554
3555 =cut
3556
3557 sub setup_home {
3558     my ( $class, $home ) = @_;
3559
3560     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3561         $home = $env;
3562     }
3563
3564     $home ||= Catalyst::Utils::home($class);
3565
3566     if ($home) {
3567         #I remember recently being scolded for assigning config values like this
3568         $class->config->{home} ||= $home;
3569         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3570     }
3571 }
3572
3573 =head2 $c->setup_encoding
3574
3575 Sets up the input/output encoding. See L<ENCODING>
3576
3577 =cut
3578
3579 sub setup_encoding {
3580     my $c = shift;
3581     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3582         # Ok, so the user has explicitly said "I don't want encoding..."
3583         return;
3584     } else {
3585       my $enc = defined($c->config->{encoding}) ?
3586         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3587       $c->encoding($enc);
3588     }
3589 }
3590
3591 =head2 handle_unicode_encoding_exception
3592
3593 Hook to let you customize how encoding errors are handled. By default
3594 we just throw an exception and the default error page will pick it up.
3595 Receives a hashref of debug information. Example of call (from the
3596 Catalyst internals):
3597
3598   my $decoded_after_fail = $c->handle_unicode_encoding_exception({
3599         param_value => $value,
3600         error_msg => $_,
3601         encoding_step => 'params',
3602    });
3603
3604 The calling code expects to receive a decoded string or an exception.
3605
3606 You can override this for custom handling of unicode errors. By
3607 default we just die. If you want a custom response here, one approach
3608 is to throw an HTTP style exception, instead of returning a decoded
3609 string or throwing a generic exception.
3610
3611     sub handle_unicode_encoding_exception {
3612       my ($c, $params) = @_;
3613       HTTP::Exception::BAD_REQUEST->throw(status_message=>$params->{error_msg});
3614     }
3615
3616 Alternatively you can 'catch' the error, stash it and write handling code later
3617 in your application:
3618
3619     sub handle_unicode_encoding_exception {
3620       my ($c, $params) = @_;
3621       $c->stash(BAD_UNICODE_DATA=>$params);
3622       # return a dummy string.
3623       return 1;
3624     }
3625
3626 <B>NOTE:</b> Please keep in mind that once an error like this occurs,
3627 the request setup is still ongoing, which means the state of C<$c> and
3628 related context parts like the request and response may not be setup
3629 up correctly (since we haven't finished the setup yet). If you throw
3630 an exception the setup is aborted.
3631
3632 =cut
3633
3634 sub handle_unicode_encoding_exception {
3635     my ( $self, $exception_ctx ) = @_;
3636     die $exception_ctx->{error_msg};
3637 }
3638
3639 # Some unicode helpers cargo culted from the old plugin.  These could likely
3640 # be neater.
3641
3642 sub _handle_unicode_decoding {
3643     my ( $self, $value ) = @_;
3644
3645     return unless defined $value;
3646
3647     ## I think this mess is to support the old nested
3648     if ( ref $value eq 'ARRAY' ) {
3649         foreach ( @$value ) {
3650             $_ = $self->_handle_unicode_decoding($_);
3651         }
3652         return $value;
3653     }
3654     elsif ( ref $value eq 'HASH' ) {
3655         foreach (keys %$value) {
3656             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3657             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3658
3659             # If the key was encoded we now have two (the original and current so
3660             # delete the original.
3661             delete $value->{$_} if $_ ne $encoded_key;
3662         }
3663         return $value;
3664     }
3665     else {
3666         return $self->_handle_param_unicode_decoding($value);
3667     }
3668 }
3669
3670 sub _handle_param_unicode_decoding {
3671     my ( $self, $value, $check ) = @_;
3672     return unless defined $value; # not in love with just ignoring undefs - jnap
3673     return $value if blessed($value); #don't decode when the value is an object.
3674
3675     my $enc = $self->encoding;
3676
3677     return $value unless $enc; # don't decode if no encoding is specified
3678
3679     $check ||= $self->_encode_check;
3680     return try {
3681       $enc->decode( $value, $check);
3682     }
3683     catch {
3684         return $self->handle_unicode_encoding_exception({
3685             param_value => $value,
3686             error_msg => $_,
3687             encoding_step => 'params',
3688         });
3689     };
3690 }
3691
3692 =head2 $c->setup_log
3693
3694 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3695 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3696 log to.
3697
3698 This method also installs a C<debug> method that returns a true value into the
3699 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3700 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3701
3702 Note that if the log has already been setup, by either a previous call to
3703 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3704 that this method won't actually set up the log object.
3705
3706 =cut
3707
3708 sub setup_log {
3709     my ( $class, $levels ) = @_;
3710
3711     $levels ||= '';
3712     $levels =~ s/^\s+//;
3713     $levels =~ s/\s+$//;
3714     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3715
3716     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3717     if ( defined $env_debug ) {
3718         $levels{debug} = 1 if $env_debug; # Ugly!
3719         delete($levels{debug}) unless $env_debug;
3720     }
3721
3722     unless ( $class->log ) {
3723         $class->log( Catalyst::Log->new(keys %levels) );
3724     }
3725
3726     if ( $levels{debug} ) {
3727         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3728         $class->log->debug('Debug messages enabled');
3729     }
3730 }
3731
3732 =head2 $c->setup_plugins
3733
3734 Sets up plugins.
3735
3736 =cut
3737
3738 =head2 $c->setup_stats
3739
3740 Sets up timing statistics class.
3741
3742 =cut
3743
3744 sub setup_stats {
3745     my ( $class, $stats ) = @_;
3746
3747     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3748
3749     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3750     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3751         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3752         $class->log->debug('Statistics enabled');
3753     }
3754 }
3755
3756
3757 =head2 $c->registered_plugins
3758
3759 Returns a sorted list of the plugins which have either been stated in the
3760 import list.
3761
3762 If passed a given plugin name, it will report a boolean value indicating
3763 whether or not that plugin is loaded.  A fully qualified name is required if
3764 the plugin name does not begin with C<Catalyst::Plugin::>.
3765
3766  if ($c->registered_plugins('Some::Plugin')) {
3767      ...
3768  }
3769
3770 =cut
3771
3772 {
3773
3774     sub registered_plugins {
3775         my $proto = shift;
3776         return sort keys %{ $proto->_plugins } unless @_;
3777         my $plugin = shift;
3778         return 1 if exists $proto->_plugins->{$plugin};
3779         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3780     }
3781
3782     sub _register_plugin {
3783         my ( $proto, $plugin, $instant ) = @_;
3784         my $class = ref $proto || $proto;
3785
3786         load_class( $plugin );
3787         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3788             if $plugin->isa( 'Catalyst::Component' );
3789         my $plugin_meta = Moose::Meta::Class->create($plugin);
3790         if (!$plugin_meta->has_method('new')
3791             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3792             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3793         }
3794         if (!$instant && !$proto->_plugins->{$plugin}) {
3795             my $meta = Class::MOP::get_metaclass_by_name($class);
3796             $meta->superclasses($plugin, $meta->superclasses);
3797         }
3798         $proto->_plugins->{$plugin} = 1;
3799         return $class;
3800     }
3801
3802     sub _default_plugins { return qw() }
3803
3804     sub setup_plugins {
3805         my ( $class, $plugins ) = @_;
3806
3807         $class->_plugins( {} ) unless $class->_plugins;
3808         $plugins = [ grep {
3809             m/Unicode::Encoding/ ? do {
3810                 $class->log->warn(
3811                     'Unicode::Encoding plugin is auto-applied,'
3812                     . ' please remove this from your appclass'
3813                     . ' and make sure to define "encoding" config'
3814                 );
3815                 unless (exists $class->config->{'encoding'}) {
3816                   $class->config->{'encoding'} = 'UTF-8';
3817                 }
3818                 () }
3819                 : $_
3820         } @$plugins ];
3821         push @$plugins, $class->_default_plugins;
3822         $plugins = Data::OptList::mkopt($plugins || []);
3823
3824         my @plugins = map {
3825             [ Catalyst::Utils::resolve_namespace(
3826                   $class . '::Plugin',
3827                   'Catalyst::Plugin', $_->[0]
3828               ),
3829               $_->[1],
3830             ]
3831          } @{ $plugins };
3832
3833         for my $plugin ( reverse @plugins ) {
3834             load_class($plugin->[0], $plugin->[1]);
3835             my $meta = find_meta($plugin->[0]);
3836             next if $meta && $meta->isa('Moose::Meta::Role');
3837
3838             $class->_register_plugin($plugin->[0]);
3839         }
3840
3841         my @roles =
3842             map  { $_->[0]->name, $_->[1] }
3843             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3844             map  { [find_meta($_->[0]), $_->[1]] }
3845             @plugins;
3846
3847         Moose::Util::apply_all_roles(
3848             $class => @roles
3849         ) if @roles;
3850     }
3851 }
3852
3853 =head2 default_middleware
3854
3855 Returns a list of instantiated PSGI middleware objects which is the default
3856 middleware that is active for this application (taking any configuration
3857 options into account, excluding your custom added middleware via the C<psgi_middleware>
3858 configuration option).  You can override this method if you wish to change
3859 the default middleware (although do so at risk since some middleware is vital
3860 to application function.)
3861
3862 The current default middleware list is:
3863
3864       Catalyst::Middleware::Stash
3865       Plack::Middleware::HTTPExceptions
3866       Plack::Middleware::RemoveRedundantBody
3867       Plack::Middleware::FixMissingBodyInRedirect
3868       Plack::Middleware::ContentLength
3869       Plack::Middleware::MethodOverride
3870       Plack::Middleware::Head
3871
3872 If the configuration setting C<using_frontend_proxy> is true we add:
3873
3874       Plack::Middleware::ReverseProxy
3875
3876 If the configuration setting C<using_frontend_proxy_path> is true we add:
3877
3878       Plack::Middleware::ReverseProxyPath
3879
3880 But B<NOTE> that L<Plack::Middleware::ReverseProxyPath> is not a dependency of the
3881 L<Catalyst> distribution so if you want to use this option you should add it to
3882 your project distribution file.
3883
3884 These middlewares will be added at L</setup_middleware> during the
3885 L</setup> phase of application startup.
3886
3887 =cut
3888
3889 sub default_middleware {
3890     my $class = shift;
3891     my @mw = (
3892       Catalyst::Middleware::Stash->new,
3893       Plack::Middleware::HTTPExceptions->new,
3894       Plack::Middleware::RemoveRedundantBody->new,
3895       Plack::Middleware::FixMissingBodyInRedirect->new,
3896       Plack::Middleware::ContentLength->new,
3897       Plack::Middleware::MethodOverride->new,
3898       Plack::Middleware::Head->new);
3899
3900     if($class->config->{using_frontend_proxy}) {
3901         push @mw, Plack::Middleware::ReverseProxy->new;
3902     }
3903
3904     if($class->config->{using_frontend_proxy_path}) {
3905         if(Class::Load::try_load_class('Plack::Middleware::ReverseProxyPath')) {
3906             push @mw, Plack::Middleware::ReverseProxyPath->new;
3907         } else {
3908           $class->log->error("Cannot use configuration 'using_frontend_proxy_path' because 'Plack::Middleware::ReverseProxyPath' is not installed");
3909         }
3910     }
3911
3912     return @mw;
3913 }
3914
3915 =head2 registered_middlewares
3916
3917 Read only accessor that returns an array of all the middleware in the order
3918 that they were added (which is the REVERSE of the order they will be applied).
3919
3920 The values returned will be either instances of L<Plack::Middleware> or of a
3921 compatible interface, or a coderef, which is assumed to be inlined middleware
3922
3923 =head2 setup_middleware (?@middleware)
3924
3925 Read configuration information stored in configuration key C<psgi_middleware> or
3926 from passed @args.
3927
3928 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3929 to use it to enable L<Plack::Middleware>
3930
3931 This method is automatically called during 'setup' of your application, so
3932 you really don't need to invoke it.  However you may do so if you find the idea
3933 of loading middleware via configuration weird :).  For example:
3934
3935     package MyApp;
3936
3937     use Catalyst;
3938
3939     __PACKAGE__->setup_middleware('Head');
3940     __PACKAGE__->setup;
3941
3942 When we read middleware definitions from configuration, we reverse the list
3943 which sounds odd but is likely how you expect it to work if you have prior
3944 experience with L<Plack::Builder> or if you previously used the plugin
3945 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3946
3947 So basically your middleware handles an incoming request from the first
3948 registered middleware, down and handles the response from the last middleware
3949 up.
3950
3951 =cut
3952
3953 sub registered_middlewares {
3954     my $class = shift;
3955     if(my $middleware = $class->_psgi_middleware) {
3956         my @mw = ($class->default_middleware, @$middleware);
3957
3958         if($class->config->{using_frontend_proxy}) {
3959           push @mw, Plack::Middleware::ReverseProxy->new;
3960         }
3961
3962         return @mw;
3963     } else {
3964         die "You cannot call ->registered_middlewares until middleware has been setup";
3965     }
3966 }
3967
3968 sub setup_middleware {
3969     my $class = shift;
3970     my @middleware_definitions;
3971
3972     # If someone calls this method you can add middleware with args.  However if its
3973     # called without an arg we need to setup the configuration middleware.
3974     if(@_) {
3975       @middleware_definitions = reverse(@_);
3976     } else {
3977       @middleware_definitions = reverse(@{$class->config->{'psgi_middleware'}||[]})
3978         unless $class->finalized_default_middleware;
3979       $class->finalized_default_middleware(1); # Only do this once, just in case some people call setup over and over...
3980     }
3981
3982     my @middleware = ();
3983     while(my $next = shift(@middleware_definitions)) {
3984         if(ref $next) {
3985             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3986                 push @middleware, $next;
3987             } elsif(ref $next eq 'CODE') {
3988                 push @middleware, $next;
3989             } elsif(ref $next eq 'HASH') {
3990                 my $namespace = shift @middleware_definitions;
3991                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3992                 push @middleware, $mw;
3993             } else {
3994               die "I can't handle middleware definition ${\ref $next}";
3995             }
3996         } else {
3997           my $mw = $class->Catalyst::Utils::build_middleware($next);
3998           push @middleware, $mw;
3999         }
4000     }
4001
4002     my @existing = @{$class->_psgi_middleware || []};
4003     $class->_psgi_middleware([@middleware,@existing,]);
4004 }
4005
4006 =head2 registered_data_handlers
4007
4008 A read only copy of registered Data Handlers returned as a Hash, where each key
4009 is a content type and each value is a subref that attempts to decode that content
4010 type.
4011
4012 =head2 setup_data_handlers (?@data_handler)
4013
4014 Read configuration information stored in configuration key C<data_handlers> or
4015 from passed @args.
4016
4017 See under L</CONFIGURATION> information regarding C<data_handlers>.
4018
4019 This method is automatically called during 'setup' of your application, so
4020 you really don't need to invoke it.
4021
4022 =head2 default_data_handlers
4023
4024 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
4025 only two default data handlers, for 'application/json' and an alternative to
4026 'application/x-www-form-urlencoded' which supposed nested form parameters via
4027 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
4028
4029 The 'application/json' data handler is used to parse incoming JSON into a Perl
4030 data structure.  It uses L<JSON::MaybeXS>.  This allows you to fail back to
4031 L<JSON::PP>, which is a Pure Perl JSON decoder, and has the smallest dependency
4032 impact.
4033
4034 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
4035 use this new feature we recommend installing L<Cpanel::JSON::XS> in order to get
4036 the best performance.  You should add either to your dependency list
4037 (Makefile.PL, dist.ini, cpanfile, etc.)
4038
4039 =cut
4040
4041 sub registered_data_handlers {
4042     my $class = shift;
4043     if(my $data_handlers = $class->_data_handlers) {
4044         return %$data_handlers;
4045     } else {
4046         $class->setup_data_handlers;
4047         return $class->registered_data_handlers;
4048     }
4049 }
4050
4051 sub setup_data_handlers {
4052     my ($class, %data_handler_callbacks) = @_;
4053     %data_handler_callbacks = (
4054       %{$class->default_data_handlers},
4055       %{$class->config->{'data_handlers'}||+{}},
4056       %data_handler_callbacks);
4057
4058     $class->_data_handlers(\%data_handler_callbacks);
4059 }
4060
4061 sub default_data_handlers {
4062     my ($class) = @_;
4063     return +{
4064       'application/x-www-form-urlencoded' => sub {
4065           my ($fh, $req) = @_;
4066           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
4067           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
4068             ->can('build_cgi_struct')->($params);
4069       },
4070       'application/json' => sub {
4071           my ($fh, $req) = @_;
4072           require JSON::MaybeXS;
4073           my $slurped;
4074           return eval {
4075             local $/;
4076             $slurped = $fh->getline;
4077             JSON::MaybeXS::decode_json($slurped); # decode_json does utf8 decoding for us
4078           } || Catalyst::Exception->throw(sprintf "Error Parsing POST '%s', Error: %s", (defined($slurped) ? $slurped : 'undef') ,$@);
4079         },
4080     };
4081 }
4082
4083 sub _handle_http_exception {
4084     my ( $self, $error ) = @_;
4085     if (
4086            !$self->config->{always_catch_http_exceptions}
4087         && blessed $error
4088         && (
4089             $error->can('as_psgi')
4090             || (   $error->can('code')
4091                 && $error->code =~ m/^[1-5][0-9][0-9]$/ )
4092         )
4093       )
4094     {
4095         return 1;
4096     }
4097 }
4098
4099 =head2 $c->stack
4100
4101 Returns an arrayref of the internal execution stack (actions that are
4102 currently executing).
4103
4104 =head2 $c->stats
4105
4106 Returns the current timing statistics object. By default Catalyst uses
4107 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
4108 L<< stats_class|/"$c->stats_class" >>.
4109
4110 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
4111 available. By enabling it with C<< $c->stats->enabled(1) >>, it can be used to
4112 profile explicitly, although MyApp.pm still won't profile nor output anything
4113 by itself.
4114
4115 =head2 $c->stats_class
4116
4117 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
4118
4119 =head2 $app->stats_class_traits
4120
4121 A arrayref of L<Moose::Role>s that are applied to the stats_class before creating it.
4122
4123 =head2 $app->composed_stats_class
4124
4125 this is the stats_class composed with any 'stats_class_traits'.  You can
4126 name the full namespace of the role, or a namespace suffix, which will then
4127 be tried against the following standard namespace prefixes.
4128
4129     $MyApp::TraitFor::Stats::$trait_suffix
4130     Catalyst::TraitFor::Stats::$trait_suffix
4131
4132 So for example if you set:
4133
4134     MyApp->stats_class_traits(['Foo']);
4135
4136 We try each possible role in turn (and throw an error if none load)
4137
4138     Foo
4139     MyApp::TraitFor::Stats::Foo
4140     Catalyst::TraitFor::Stats::Foo
4141
4142 The namespace part 'TraitFor::Stats' was chosen to assist in backwards
4143 compatibility with L<CatalystX::RoleApplicator> which previously provided
4144 these features in a stand alone package.
4145
4146 =head2 $c->use_stats
4147
4148 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
4149
4150 Note that this is a static method, not an accessor and should be overridden
4151 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
4152
4153 =cut
4154
4155 sub use_stats { 0 }
4156
4157
4158 =head2 $c->write( $data )
4159
4160 Writes $data to the output stream. When using this method directly, you
4161 will need to manually set the C<Content-Length> header to the length of
4162 your output data, if known.
4163
4164 =cut
4165
4166 sub write {
4167     my $c = shift;
4168
4169     # Finalize headers if someone manually writes output (for compat)
4170     $c->finalize_headers;
4171
4172     return $c->response->write( @_ );
4173 }
4174
4175 =head2 version
4176
4177 Returns the Catalyst version number. Mostly useful for "powered by"
4178 messages in template systems.
4179
4180 =cut
4181
4182 sub version { return $Catalyst::VERSION }
4183
4184 =head1 CONFIGURATION
4185
4186 There are a number of 'base' config variables which can be set:
4187
4188 =over
4189
4190 =item *
4191
4192 C<always_catch_http_exceptions> - As of version 5.90060 Catalyst
4193 rethrows errors conforming to the interface described by
4194 L<Plack::Middleware::HTTPExceptions> and lets the middleware deal with it.
4195 Set true to get the deprecated behaviour and have Catalyst catch HTTP exceptions.
4196
4197 =item *
4198
4199 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
4200
4201 =item *
4202
4203 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
4204
4205 =item *
4206
4207 C<disable_component_resolution_regex_fallback> - Turns
4208 off the deprecated component resolution functionality so
4209 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
4210 are called then regex search will not be attempted on string values and
4211 instead C<undef> will be returned.
4212
4213 =item *
4214
4215 C<home> - The application home directory. In an uninstalled application,
4216 this is the top level application directory. In an installed application,
4217 this will be the directory containing C<< MyApp.pm >>.
4218
4219 =item *
4220
4221 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
4222
4223 =item *
4224
4225 C<name> - The name of the application in debug messages and the debug and
4226 welcome screens
4227
4228 =item *
4229
4230 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
4231 until it is accessed. This allows you to (for example) check authentication (and reject
4232 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
4233
4234 =item *
4235
4236 C<root> - The root directory for templates. Usually this is just a
4237 subdirectory of the home directory, but you can set it to change the
4238 templates to a different directory.
4239
4240 =item *
4241
4242 C<search_extra> - Array reference passed to Module::Pluggable to for additional
4243 namespaces from which components will be loaded (and constructed and stored in
4244 C<< $c->components >>).
4245
4246 =item *
4247
4248 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
4249 to be shown in hit debug tables in the test server.
4250
4251 =item *
4252
4253 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
4254 variable should be used for determining the request path.
4255
4256 Most web server environments pass the requested path to the application using environment variables,
4257 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
4258 exposed as C<< $c->request->base >>) and the request path below that base.
4259
4260 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
4261 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
4262
4263 =over
4264
4265 =item use_request_uri_for_path => 0
4266
4267 This is the default (and the) traditional method that Catalyst has used for determining the path information.
4268 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
4269 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
4270 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
4271
4272 However this method has the major disadvantage that it is impossible to correctly decode some elements
4273 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
4274 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
4275 can't distinguish / vs %2F in paths (in addition to other encoded values).
4276
4277 =item use_request_uri_for_path => 1
4278
4279 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
4280 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
4281 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
4282
4283 Given that this method of path resolution is provably more correct, it is recommended that you use
4284 this unless you have a specific need to deploy your application in a non-standard environment, and you are
4285 aware of the implications of not being able to handle encoded URI paths correctly.
4286
4287 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
4288 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
4289 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
4290 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
4291 C<< $c->request->base >> will be incorrect.
4292
4293 =back
4294
4295 =item *
4296
4297 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
4298
4299 =item *
4300
4301 C<using_frontend_proxy_path> - Enabled L<Plack::Middleware::ReverseProxyPath> on your application (if
4302 installed, otherwise log an error).  This is useful if your application is not running on the
4303 'root' (or /) of your host server.  B<NOTE> if you use this feature you should add the required
4304 middleware to your project dependency list since its not automatically a dependency of L<Catalyst>.
4305 This has been done since not all people need this feature and we wish to restrict the growth of
4306 L<Catalyst> dependencies.
4307
4308 =item *
4309
4310 C<encoding> - See L</ENCODING>
4311
4312 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
4313 value to undef.
4314
4315 =item *
4316
4317 C<abort_chain_on_error_fix>
4318
4319 Defaults to true.
4320
4321 When there is an error in an action chain, the default behavior is to
4322 abort the processing of the remaining actions to avoid running them
4323 when the application is in an unexpected state.
4324
4325 Before version 5.90070, the default used to be false. To keep the old
4326 behaviour, you can explicitly set the value to false. E.g.
4327
4328     __PACKAGE__->config(abort_chain_on_error_fix => 0);
4329
4330 If this setting is set to false, then the remaining actions are
4331 performed and the error is caught at the end of the chain.
4332
4333
4334 =item *
4335
4336 C<use_hash_multivalue_in_request>
4337
4338 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
4339 and C<parameters> return a hashref where values might be scalar or an arrayref
4340 depending on the incoming data.  In many cases this can be undesirable as it
4341 leads one to writing defensive code like the following:
4342
4343     my ($val) = ref($c->req->parameters->{a}) ?
4344       @{$c->req->parameters->{a}} :
4345         $c->req->parameters->{a};
4346
4347 Setting this configuration item to true will make L<Catalyst> populate the
4348 attributes underlying these methods with an instance of L<Hash::MultiValue>
4349 which is used by L<Plack::Request> and others to solve this very issue.  You
4350 may prefer this behavior to the default, if so enable this option (be warned
4351 if you enable it in a legacy application we are not sure if it is completely
4352 backwardly compatible).
4353
4354 =item *
4355
4356 C<skip_complex_post_part_handling>
4357
4358 When creating body parameters from a POST, if we run into a multipart POST
4359 that does not contain uploads, but instead contains inlined complex data
4360 (very uncommon) we cannot reliably convert that into field => value pairs.  So
4361 instead we create an instance of L<Catalyst::Request::PartData>.  If this causes
4362 issue for you, you can disable this by setting C<skip_complex_post_part_handling>
4363 to true (default is false).
4364
4365 =item *
4366
4367 C<skip_body_param_unicode_decoding>
4368
4369 Generally we decode incoming POST params based on your declared encoding (the
4370 default for this is to decode UTF-8).  If this is causing you trouble and you
4371 do not wish to turn all encoding support off (with the C<encoding> configuration
4372 parameter) you may disable this step atomically by setting this configuration
4373 parameter to true.
4374
4375 =item *
4376
4377 C<do_not_decode_query>
4378
4379 If true, then do not try to character decode any wide characters in your
4380 request URL query or keywords.  Most readings of the relevant specifications
4381 suggest these should be UTF-* encoded, which is the default that L<Catalyst>
4382 will use, however if you are creating a lot of URLs manually or have external
4383 evil clients, this might cause you trouble.  If you find the changes introduced
4384 in Catalyst version 5.90080+ break some of your query code, you may disable
4385 the UTF-8 decoding globally using this configuration.
4386
4387 This setting takes precedence over C<default_query_encoding>
4388
4389 =item *
4390
4391 C<do_not_check_query_encoding>
4392
4393 Catalyst versions 5.90080 - 5.90106 would decode query parts of an incoming
4394 request but would not raise an exception when the decoding failed due to
4395 incorrect unicode.  It now does, but if this change is giving you trouble
4396 you may disable it by setting this configuration to true.
4397
4398 =item *
4399
4400 C<default_query_encoding>
4401
4402 By default we decode query and keywords in your request URL using UTF-8, which
4403 is our reading of the relevant specifications.  This setting allows one to
4404 specify a fixed value for how to decode your query.  You might need this if
4405 you are doing a lot of custom encoding of your URLs and not using UTF-8.
4406
4407 =item *
4408
4409 C<use_chained_args_0_special_case>
4410
4411 In older versions of Catalyst, when more than one action matched the same path
4412 AND all those matching actions declared Args(0), we'd break the tie by choosing
4413 the first action defined.  We now normalized how Args(0) works so that it
4414 follows the same rule as Args(N), which is to say when we need to break a tie
4415 we choose the LAST action defined.  If this breaks your code and you don't
4416 have time to update to follow the new normalized approach, you may set this
4417 value to true and it will globally revert to the original chaining behavior.
4418
4419 =item *
4420
4421 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
4422
4423 =item *
4424
4425 C<data_handlers> - See L<DATA HANDLERS>.
4426
4427 =item *
4428
4429 C<stats_class_traits>
4430
4431 An arrayref of L<Moose::Role>s that get composed into your stats class.
4432
4433 =item *
4434
4435 C<request_class_traits>
4436
4437 An arrayref of L<Moose::Role>s that get composed into your request class.
4438
4439 =item *
4440
4441 C<response_class_traits>
4442
4443 An arrayref of L<Moose::Role>s that get composed into your response class.
4444
4445 =item *
4446
4447 C<inject_components>
4448
4449 A Hashref of L<Catalyst::Component> subclasses that are 'injected' into configuration.
4450 For example:
4451
4452     MyApp->config({
4453       inject_components => {
4454         'Controller::Err' => { from_component => 'Local::Controller::Errors' },
4455         'Model::Zoo' => { from_component => 'Local::Model::Foo' },
4456         'Model::Foo' => { from_component => 'Local::Model::Foo', roles => ['TestRole'] },
4457       },
4458       'Controller::Err' => { a => 100, b=>200, namespace=>'error' },
4459       'Model::Zoo' => { a => 2 },
4460       'Model::Foo' => { a => 100 },
4461     });
4462
4463 Generally L<Catalyst> looks for components in your Model/View or Controller directories.
4464 However for cases when you which to use an existing component and you don't need any
4465 customization (where for when you can apply a role to customize it) you may inject those
4466 components into your application.  Please note any configuration should be done 'in the
4467 normal way', with a key under configuration named after the component affix, as in the
4468 above example.
4469
4470 Using this type of injection allows you to construct significant amounts of your application
4471 with only configuration!.  This may or may not lead to increased code understanding.
4472
4473 Please not you may also call the ->inject_components application method as well, although
4474 you must do so BEFORE setup.
4475
4476 =back
4477
4478 =head1 EXCEPTIONS
4479
4480 Generally when you throw an exception inside an Action (or somewhere in
4481 your stack, such as in a model that an Action is calling) that exception
4482 is caught by Catalyst and unless you either catch it yourself (via eval
4483 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
4484 will eventually reach L</finalize_errors> and return either the debugging
4485 error stack page, or the default error page.  However, if your exception
4486 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
4487 instead rethrow it so that it can be handled by that middleware (which
4488 is part of the default middleware).  For example this would allow
4489
4490     use HTTP::Throwable::Factory 'http_throw';
4491
4492     sub throws_exception :Local {
4493       my ($self, $c) = @_;
4494
4495       http_throw(SeeOther => { location =>
4496         $c->uri_for($self->action_for('redirect')) });
4497
4498     }
4499
4500 =head1 INTERNAL ACTIONS
4501
4502 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
4503 C<_ACTION>, and C<_END>. These are by default not shown in the private
4504 action table, but you can make them visible with a config parameter.
4505
4506     MyApp->config(show_internal_actions => 1);
4507
4508 =head1 ON-DEMAND PARSER
4509
4510 The request body is usually parsed at the beginning of a request,
4511 but if you want to handle input yourself, you can enable on-demand
4512 parsing with a config parameter.
4513
4514     MyApp->config(parse_on_demand => 1);
4515
4516 =head1 PROXY SUPPORT
4517
4518 Many production servers operate using the common double-server approach,
4519 with a lightweight frontend web server passing requests to a larger
4520 backend server. An application running on the backend server must deal
4521 with two problems: the remote user always appears to be C<127.0.0.1> and
4522 the server's hostname will appear to be C<localhost> regardless of the
4523 virtual host that the user connected through.
4524
4525 Catalyst will automatically detect this situation when you are running
4526 the frontend and backend servers on the same machine. The following
4527 changes are made to the request.
4528
4529     $c->req->address is set to the user's real IP address, as read from
4530     the HTTP X-Forwarded-For header.
4531
4532     The host value for $c->req->base and $c->req->uri is set to the real
4533     host, as read from the HTTP X-Forwarded-Host header.
4534
4535 Additionally, you may be running your backend application on an insecure
4536 connection (port 80) while your frontend proxy is running under SSL.  If there
4537 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
4538 tell Catalyst what port the frontend listens on.  This will allow all URIs to
4539 be created properly.
4540
4541 In the case of passing in:
4542
4543     X-Forwarded-Port: 443
4544
4545 All calls to C<uri_for> will result in an https link, as is expected.
4546
4547 Obviously, your web server must support these headers for this to work.
4548
4549 In a more complex server farm environment where you may have your
4550 frontend proxy server(s) on different machines, you will need to set a
4551 configuration option to tell Catalyst to read the proxied data from the
4552 headers.
4553
4554     MyApp->config(using_frontend_proxy => 1);
4555
4556 If you do not wish to use the proxy support at all, you may set:
4557
4558     MyApp->config(ignore_frontend_proxy => 0);
4559
4560 =head2 Note about psgi files
4561
4562 Note that if you supply your own .psgi file, calling
4563 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
4564
4565 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
4566 in your psgi, for example:
4567
4568     builder {
4569         enable "Plack::Middleware::ReverseProxy";
4570         MyApp->psgi_app
4571     };
4572
4573 This will unconditionally add the ReverseProxy support, or you need to call
4574 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
4575 apply the support depending upon your config).
4576
4577 See L<Catalyst::PSGI> for more information.
4578
4579 =head1 THREAD SAFETY
4580
4581 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
4582 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
4583 believe the Catalyst core to be thread-safe.
4584
4585 If you plan to operate in a threaded environment, remember that all other
4586 modules you are using must also be thread-safe. Some modules, most notably
4587 L<DBD::SQLite>, are not thread-safe.
4588
4589 =head1 DATA HANDLERS
4590
4591 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
4592 form parameters and URL search query fields.  However it has become common
4593 for various alternative content types to be PUT or POSTed to your controllers
4594 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
4595 XML and other content types when communicating with an application server.  In
4596 order to better support this use case, L<Catalyst> defines a global configuration
4597 option, C<data_handlers>, which lets you associate a content type with a coderef
4598 that parses that content type into something Perl can readily access.
4599
4600     package MyApp::Web;
4601
4602     use Catalyst;
4603     use JSON::MaybeXS;
4604
4605     __PACKAGE__->config(
4606       data_handlers => {
4607         'application/json' => sub { local $/; decode_json $_->getline },
4608       },
4609       ## Any other configuration.
4610     );
4611
4612     __PACKAGE__->setup;
4613
4614 By default L<Catalyst> comes with a generic JSON data handler similar to the
4615 example given above, which uses L<JSON::MaybeXS> to provide either L<JSON::PP>
4616 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
4617 it installed (if you want the faster XS parser, add it to you project Makefile.PL
4618 or dist.ini, cpanfile, etc.)
4619
4620 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
4621 (matched against the incoming request type using a regexp such as to be case
4622 insensitive) and whose values are coderefs that receive a localized version of
4623 C<$_> which is a filehandle object pointing to received body.
4624
4625 This feature is considered an early access release and we reserve the right
4626 to alter the interface in order to provide a performant and secure solution to
4627 alternative request body content.  Your reports welcomed!
4628
4629 =head1 PSGI MIDDLEWARE
4630
4631 You can define middleware, defined as L<Plack::Middleware> or a compatible
4632 interface in configuration.  Your middleware definitions are in the form of an
4633 arrayref under the configuration key C<psgi_middleware>.  Here's an example
4634 with details to follow:
4635
4636     package MyApp::Web;
4637
4638     use Catalyst;
4639     use Plack::Middleware::StackTrace;
4640
4641     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4642
4643     __PACKAGE__->config(
4644       'psgi_middleware', [
4645         'Debug',
4646         '+MyApp::Custom',
4647         $stacktrace_middleware,
4648         'Session' => {store => 'File'},
4649         sub {
4650           my $app = shift;
4651           return sub {
4652             my $env = shift;
4653             $env->{myapp.customkey} = 'helloworld';
4654             $app->($env);
4655           },
4656         },
4657       ],
4658     );
4659
4660     __PACKAGE__->setup;
4661
4662 So the general form is:
4663
4664     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
4665
4666 Where C<@middleware> is one or more of the following, applied in the REVERSE of
4667 the order listed (to make it function similarly to L<Plack::Builder>:
4668
4669 Alternatively, you may also define middleware by calling the L</setup_middleware>
4670 package method:
4671
4672     package MyApp::Web;
4673
4674     use Catalyst;
4675
4676     __PACKAGE__->setup_middleware( \@middleware_definitions);
4677     __PACKAGE__->setup;
4678
4679 In the case where you do both (use 'setup_middleware' and configuration) the
4680 package call to setup_middleware will be applied earlier (in other words its
4681 middleware will wrap closer to the application).  Keep this in mind since in
4682 some cases the order of middleware is important.
4683
4684 The two approaches are not exclusive.
4685
4686 =over 4
4687
4688 =item Middleware Object
4689
4690 An already initialized object that conforms to the L<Plack::Middleware>
4691 specification:
4692
4693     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4694
4695     __PACKAGE__->config(
4696       'psgi_middleware', [
4697         $stacktrace_middleware,
4698       ]);
4699
4700
4701 =item coderef
4702
4703 A coderef that is an inlined middleware:
4704
4705     __PACKAGE__->config(
4706       'psgi_middleware', [
4707         sub {
4708           my $app = shift;
4709           return sub {
4710             my $env = shift;
4711             if($env->{PATH_INFO} =~m/forced/) {
4712               Plack::App::File
4713                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
4714                 ->call($env);
4715             } else {
4716               return $app->($env);
4717             }
4718          },
4719       },
4720     ]);
4721
4722
4723
4724 =item a scalar
4725
4726 We assume the scalar refers to a namespace after normalizing it using the
4727 following rules:
4728
4729 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
4730 is assumed to be 'as is', and we just install and use the middleware.
4731
4732 (2) If the scalar begins with "Plack::Middleware" or your application namespace
4733 (the package name of your Catalyst application subclass), we also assume then
4734 that it is a full namespace, and use it.
4735
4736 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
4737 resolve it first by looking for it under your application namespace (for example
4738 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
4739 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
4740 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
4741 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
4742 namespace first to let you 'override' common L<Plack::Middleware> locally, should
4743 you find that a good idea.
4744
4745 Examples:
4746
4747     package MyApp::Web;
4748
4749     __PACKAGE__->config(
4750       'psgi_middleware', [
4751         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
4752         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
4753         '+MyApp::Custom',  ## MyApp::Custom->wrap
4754       ],
4755     );
4756
4757 =item a scalar followed by a hashref
4758
4759 Just like the previous, except the following C<HashRef> is used as arguments
4760 to initialize the middleware object.
4761
4762     __PACKAGE__->config(
4763       'psgi_middleware', [
4764          'Session' => {store => 'File'},
4765     ]);
4766
4767 =back
4768
4769 Please see L<PSGI> for more on middleware.
4770
4771 =head1 ENCODING
4772
4773 Starting in L<Catalyst> version 5.90080 encoding is automatically enabled
4774 and set to encode all body responses to UTF8 when possible and applicable.
4775 Following is documentation on this process.  If you are using an older
4776 version of L<Catalyst> you should review documentation for that version since
4777 a lot has changed.
4778
4779 By default encoding is now 'UTF-8'.  You may turn it off by setting
4780 the encoding configuration to undef.
4781
4782     MyApp->config(encoding => undef);
4783
4784 This is recommended for temporary backwards compatibility only.
4785
4786 To turn it off for a single request use the L<clear_encoding>
4787 method to turn off encoding for this request.  This can be useful
4788 when you are setting the body to be an arbitrary block of bytes,
4789 especially if that block happens to be a block of UTF8 text.
4790
4791 Encoding is automatically applied when the content-type is set to
4792 a type that can be encoded.  Currently we encode when the content type
4793 matches the following regular expression:
4794
4795     $content_type =~ /^text|xml$|javascript$/
4796
4797 Encoding is set on the application, but it is copied to the context object
4798 so that you can override it on a request basis.
4799
4800 Be default we don't automatically encode 'application/json' since the most
4801 common approaches to generating this type of response (Either via L<Catalyst::View::JSON>
4802 or L<Catalyst::Action::REST>) will do so already and we want to avoid double
4803 encoding issues.
4804
4805 If you are producing JSON response in an unconventional manner (such
4806 as via a template or manual strings) you should perform the UTF8 encoding
4807 manually as well such as to conform to the JSON specification.
4808
4809 NOTE: We also examine the value of $c->response->content_encoding.  If
4810 you set this (like for example 'gzip', and manually gzipping the body)
4811 we assume that you have done all the necessary encoding yourself, since
4812 we cannot encode the gzipped contents.  If you use a plugin like
4813 L<Catalyst::Plugin::Compress> you need to update to a modern version in order
4814 to have this function correctly  with the new UTF8 encoding code, or you
4815 can use L<Plack::Middleware::Deflater> or (probably best) do your compression on
4816 a front end proxy.
4817
4818 =head2 Methods
4819
4820 =over 4
4821
4822 =item encoding
4823
4824 Returns an instance of an C<Encode> encoding
4825
4826     print $c->encoding->name
4827
4828 =item handle_unicode_encoding_exception ($exception_context)
4829
4830 Method called when decoding process for a request fails.
4831
4832 An C<$exception_context> hashref is provided to allow you to override the
4833 behaviour of your application when given data with incorrect encodings.
4834
4835 The default method throws exceptions in the case of invalid request parameters
4836 (resulting in a 500 error), but ignores errors in upload filenames.
4837
4838 The keys passed in the C<$exception_context> hash are:
4839
4840 =over
4841
4842 =item param_value
4843
4844 The value which was not able to be decoded.
4845
4846 =item error_msg
4847
4848 The exception received from L<Encode>.
4849
4850 =item encoding_step
4851
4852 What type of data was being decoded. Valid values are (currently)
4853 C<params> - for request parameters / arguments / captures
4854 and C<uploads> - for request upload filenames.
4855
4856 =back
4857
4858 =back
4859
4860 =head1 SUPPORT
4861
4862 IRC:
4863
4864     Join #catalyst on irc.perl.org.
4865
4866 Mailing Lists:
4867
4868     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4869     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4870
4871 Web:
4872
4873     http://catalyst.perl.org
4874
4875 Wiki:
4876
4877     http://dev.catalyst.perl.org
4878
4879 =head1 SEE ALSO
4880
4881 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4882
4883 =head2 L<Catalyst::Manual> - The Catalyst Manual
4884
4885 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4886
4887 =head2 L<Catalyst::Engine> - Core engine
4888
4889 =head2 L<Catalyst::Log> - Log class.
4890
4891 =head2 L<Catalyst::Request> - Request object
4892
4893 =head2 L<Catalyst::Response> - Response object
4894
4895 =head2 L<Catalyst::Test> - The test suite.
4896
4897 =head1 PROJECT FOUNDER
4898
4899 sri: Sebastian Riedel <sri@cpan.org>
4900
4901 =head1 CONTRIBUTORS
4902
4903 abw: Andy Wardley
4904
4905 acme: Leon Brocard <leon@astray.com>
4906
4907 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4908
4909 andrewalker: André Walker <andre@cpan.org>
4910
4911 Andrew Bramble
4912
4913 Andrew Ford <A.Ford@ford-mason.co.uk>
4914
4915 Andrew Ruthven
4916
4917 andyg: Andy Grundman <andy@hybridized.org>
4918
4919 audreyt: Audrey Tang
4920
4921 bricas: Brian Cassidy <bricas@cpan.org>
4922
4923 Caelum: Rafael Kitover <rkitover@io.com>
4924
4925 chansen: Christian Hansen
4926
4927 Chase Venters <chase.venters@gmail.com>
4928
4929 chicks: Christopher Hicks
4930
4931 Chisel Wright <pause@herlpacker.co.uk>
4932
4933 Danijel Milicevic <me@danijel.de>
4934
4935 davewood: David Schmidt <davewood@cpan.org>
4936
4937 David Kamholz <dkamholz@cpan.org>
4938
4939 David Naughton <naughton@umn.edu>
4940
4941 David E. Wheeler
4942
4943 dhoss: Devin Austin <dhoss@cpan.org>
4944
4945 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4946
4947 Drew Taylor
4948
4949 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4950
4951 esskar: Sascha Kiefer
4952
4953 fireartist: Carl Franks <cfranks@cpan.org>
4954
4955 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4956
4957 gabb: Danijel Milicevic
4958
4959 Gary Ashton Jones
4960
4961 Gavin Henry <ghenry@perl.me.uk>
4962
4963 Geoff Richards
4964
4965 groditi: Guillermo Roditi <groditi@gmail.com>
4966
4967 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4968
4969 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4970
4971 jcamacho: Juan Camacho
4972
4973 jester: Jesse Sheidlower <jester@panix.com>
4974
4975 jhannah: Jay Hannah <jay@jays.net>
4976
4977 Jody Belka
4978
4979 Johan Lindstrom
4980
4981 jon: Jon Schutz <jjschutz@cpan.org>
4982
4983 Jonathan Rockway <jrockway@cpan.org>
4984
4985 Kieren Diment <kd@totaldatasolution.com>
4986
4987 konobi: Scott McWhirter <konobi@cpan.org>
4988
4989 marcus: Marcus Ramberg <mramberg@cpan.org>
4990
4991 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4992
4993 mgrimes: Mark Grimes <mgrimes@cpan.org>
4994
4995 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4996
4997 mugwump: Sam Vilain
4998
4999 naughton: David Naughton
5000
5001 ningu: David Kamholz <dkamholz@cpan.org>
5002
5003 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
5004
5005 numa: Dan Sully <daniel@cpan.org>
5006
5007 obra: Jesse Vincent
5008
5009 Octavian Rasnita
5010
5011 omega: Andreas Marienborg
5012
5013 Oleg Kostyuk <cub.uanic@gmail.com>
5014
5015 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
5016
5017 rafl: Florian Ragwitz <rafl@debian.org>
5018
5019 random: Roland Lammel <lammel@cpan.org>
5020
5021 revmischa: Mischa Spiegelmock <revmischa@cpan.org>
5022
5023 Robert Sedlacek <rs@474.at>
5024
5025 rrwo: Robert Rothenberg <rrwo@cpan.org>
5026
5027 SpiceMan: Marcel Montes
5028
5029 sky: Arthur Bergman
5030
5031 szbalint: Balint Szilakszi <szbalint@cpan.org>
5032
5033 t0m: Tomas Doran <bobtfish@bobtfish.net>
5034
5035 Ulf Edvinsson
5036
5037 vanstyn: Henry Van Styn <vanstyn@cpan.org>
5038
5039 Viljo Marrandi <vilts@yahoo.com>
5040
5041 Will Hawes <info@whawes.co.uk>
5042
5043 willert: Sebastian Willert <willert@cpan.org>
5044
5045 wreis: Wallace Reis <wreis@cpan.org>
5046
5047 Yuval Kogman <nothingmuch@woobling.org>
5048
5049 rainboxx: Matthias Dietrich <perl@rainboxx.de>
5050
5051 dd070: Dhaval Dhanani <dhaval070@gmail.com>
5052
5053 Upasana <me@upasana.me>
5054
5055 John Napiorkowski (jnap) <jjnapiork@cpan.org>
5056
5057 =head1 COPYRIGHT
5058
5059 Copyright (c) 2005-2015, the above named PROJECT FOUNDER and CONTRIBUTORS.
5060
5061 =head1 LICENSE
5062
5063 This library is free software. You can redistribute it and/or modify it under
5064 the same terms as Perl itself.
5065
5066 =cut
5067
5068 no Moose;
5069
5070 __PACKAGE__->meta->make_immutable;
5071
5072 1;