lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Plack::Middleware::Conditional;
  39 use Plack::Middleware::ReverseProxy;
  40 use Plack::Middleware::IIS6ScriptNameFix;
  41 use Plack::Middleware::IIS7KeepAliveFix;
  42 use Plack::Middleware::LighttpdScriptNameFix;
  43 use Plack::Util;
  44 use Class::Load;
  45
  46 BEGIN { require 5.008003; }
  47
  48 has stack => (is => 'ro', default => sub { [] });
  49 has stash => (is => 'rw', default => sub { {} });
  50 has state => (is => 'rw', default => 0);
  51 has stats => (is => 'rw');
  52 has action => (is => 'rw');
  53 has counter => (is => 'rw', default => sub { {} });
  54 has request => (
  55     is => 'rw',
  56     default => sub {
  57         my $self = shift;
  58         $self->request_class->new($self->_build_request_constructor_args);
  59     },
  60     lazy => 1,
  61 );
  62 sub _build_request_constructor_args {
  63     my $self = shift;
  64     my %p = ( _log => $self->log );
  65     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  66     \%p;
  67 }
  68
  69 has response => (
  70     is => 'rw',
  71     default => sub {
  72         my $self = shift;
  73         $self->response_class->new($self->_build_response_constructor_args);
  74     },
  75     lazy => 1,
  76 );
  77 sub _build_response_constructor_args {
  78     my $self = shift;
  79     { _log => $self->log };
  80 }
  81
  82 has namespace => (is => 'rw');
  83
  84 sub depth { scalar @{ shift->stack || [] }; }
  85 sub comp { shift->component(@_) }
  86
  87 sub req {
  88     my $self = shift; return $self->request(@_);
  89 }
  90 sub res {
  91     my $self = shift; return $self->response(@_);
  92 }
  93
  94 # For backwards compatibility
  95 sub finalize_output { shift->finalize_body(@_) };
  96
  97 # For statistics
  98 our $COUNT     = 1;
  99 our $START     = time;
 100 our $RECURSION = 1000;
 101 our $DETACH    = Catalyst::Exception::Detach->new;
 102 our $GO        = Catalyst::Exception::Go->new;
 103
 104 #I imagine that very few of these really need to be class variables. if any.
 105 #maybe we should just make them attributes with a default?
 106 __PACKAGE__->mk_classdata($_)
 107   for qw/components arguments dispatcher engine log dispatcher_class
 108   engine_loader context_class request_class response_class stats_class
 109   setup_finished _psgi_app loading_psgi_file run_options/;
 110
 111 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 112 __PACKAGE__->request_class('Catalyst::Request');
 113 __PACKAGE__->response_class('Catalyst::Response');
 114 __PACKAGE__->stats_class('Catalyst::Stats');
 115
 116 # Remember to update this in Catalyst::Runtime as well!
 117
 118 our $VERSION = '5.90042';
 119
 120 sub import {
 121     my ( $class, @arguments ) = @_;
 122
 123     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 124     # callers @ISA.
 125     return unless $class eq 'Catalyst';
 126
 127     my $caller = caller();
 128     return if $caller eq 'main';
 129
 130     my $meta = Moose::Meta::Class->initialize($caller);
 131     unless ( $caller->isa('Catalyst') ) {
 132         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 133         $meta->superclasses(@superclasses);
 134     }
 135     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 136     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 137
 138     unless( $meta->has_method('meta') ){
 139         if ($Moose::VERSION >= 1.15) {
 140             $meta->_add_meta_method('meta');
 141         }
 142         else {
 143             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 144         }
 145     }
 146
 147     $caller->arguments( [@arguments] );
 148     $caller->setup_home;
 149 }
 150
 151 sub _application { $_[0] }
 152
 153 =encoding UTF-8
 154
 155 =head1 NAME
 156
 157 Catalyst - The Elegant MVC Web Application Framework
 158
 159 =head1 SYNOPSIS
 160
 161 See the L<Catalyst::Manual> distribution for comprehensive
 162 documentation and tutorials.
 163
 164     # Install Catalyst::Devel for helpers and other development tools
 165     # use the helper to create a new application
 166     catalyst.pl MyApp
 167
 168     # add models, views, controllers
 169     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 170     script/myapp_create.pl view MyTemplate TT
 171     script/myapp_create.pl controller Search
 172
 173     # built in testserver -- use -r to restart automatically on changes
 174     # --help to see all available options
 175     script/myapp_server.pl
 176
 177     # command line testing interface
 178     script/myapp_test.pl /yada
 179
 180     ### in lib/MyApp.pm
 181     use Catalyst qw/-Debug/; # include plugins here as well
 182
 183     ### In lib/MyApp/Controller/Root.pm (autocreated)
 184     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 185         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 186         $c->stash->{template} = 'foo.tt'; # set the template
 187         # lookup something from db -- stash vars are passed to TT
 188         $c->stash->{data} =
 189           $c->model('Database::Foo')->search( { country => $args[0] } );
 190         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 191             $c->forward( 'bar' ); # process another action
 192             # do something else after forward returns
 193         }
 194     }
 195
 196     # The foo.tt TT template can use the stash data from the database
 197     [% WHILE (item = data.next) %]
 198         [% item.foo %]
 199     [% END %]
 200
 201     # called for /bar/of/soap, /bar/of/soap/10, etc.
 202     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 203
 204     # called after all actions are finished
 205     sub end : Action {
 206         my ( $self, $c ) = @_;
 207         if ( scalar @{ $c->error } ) { ... } # handle errors
 208         return if $c->res->body; # already have a response
 209         $c->forward( 'MyApp::View::TT' ); # render template
 210     }
 211
 212 See L<Catalyst::Manual::Intro> for additional information.
 213
 214 =head1 DESCRIPTION
 215
 216 Catalyst is a modern framework for making web applications without the
 217 pain usually associated with this process. This document is a reference
 218 to the main Catalyst application. If you are a new user, we suggest you
 219 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 220
 221 See L<Catalyst::Manual> for more documentation.
 222
 223 Catalyst plugins can be loaded by naming them as arguments to the "use
 224 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 225 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 226 C<My::Module>.
 227
 228     use Catalyst qw/My::Module/;
 229
 230 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 231 fully qualify the name by using a unary plus:
 232
 233     use Catalyst qw/
 234         My::Module
 235         +Fully::Qualified::Plugin::Name
 236     /;
 237
 238 Special flags like C<-Debug> can also be specified as
 239 arguments when Catalyst is loaded:
 240
 241     use Catalyst qw/-Debug My::Module/;
 242
 243 The position of plugins and flags in the chain is important, because
 244 they are loaded in the order in which they appear.
 245
 246 The following flags are supported:
 247
 248 =head2 -Debug
 249
 250 Enables debug output. You can also force this setting from the system
 251 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 252 settings override the application, with <MYAPP>_DEBUG having the highest
 253 priority.
 254
 255 This sets the log level to 'debug' and enables full debug output on the
 256 error screen. If you only want the latter, see L<< $c->debug >>.
 257
 258 =head2 -Home
 259
 260 Forces Catalyst to use a specific home directory, e.g.:
 261
 262     use Catalyst qw[-Home=/usr/mst];
 263
 264 This can also be done in the shell environment by setting either the
 265 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 266 is replaced with the uppercased name of your application, any "::" in
 267 the name will be replaced with underscores, e.g. MyApp::Web should use
 268 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 269
 270 If none of these are set, Catalyst will attempt to automatically detect the
 271 home directory. If you are working in a development environment, Catalyst
 272 will try and find the directory containing either Makefile.PL, Build.PL,
 273 dist.ini, or cpanfile. If the application has been installed into the system
 274 (i.e. you have done C<make install>), then Catalyst will use the path to your
 275 application module, without the .pm extension (e.g., /foo/MyApp if your
 276 application was installed at /foo/MyApp.pm)
 277
 278 =head2 -Log
 279
 280     use Catalyst '-Log=warn,fatal,error';
 281
 282 Specifies a comma-delimited list of log levels.
 283
 284 =head2 -Stats
 285
 286 Enables statistics collection and reporting.
 287
 288    use Catalyst qw/-Stats=1/;
 289
 290 You can also force this setting from the system environment with CATALYST_STATS
 291 or <MYAPP>_STATS. The environment settings override the application, with
 292 <MYAPP>_STATS having the highest priority.
 293
 294 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 295
 296 =head1 METHODS
 297
 298 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 299
 300 =head2 $c->action
 301
 302 Returns a L<Catalyst::Action> object for the current action, which
 303 stringifies to the action name. See L<Catalyst::Action>.
 304
 305 =head2 $c->namespace
 306
 307 Returns the namespace of the current action, i.e., the URI prefix
 308 corresponding to the controller of the current action. For example:
 309
 310     # in Controller::Foo::Bar
 311     $c->namespace; # returns 'foo/bar';
 312
 313 =head2 $c->request
 314
 315 =head2 $c->req
 316
 317 Returns the current L<Catalyst::Request> object, giving access to
 318 information about the current client request (including parameters,
 319 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 320
 321 =head2 REQUEST FLOW HANDLING
 322
 323 =head2 $c->forward( $action [, \@arguments ] )
 324
 325 =head2 $c->forward( $class, $method, [, \@arguments ] )
 326
 327 Forwards processing to another action, by its private name. If you give a
 328 class name but no method, C<process()> is called. You may also optionally
 329 pass arguments in an arrayref. The action will receive the arguments in
 330 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 331 C<< $c->req->args >> will be restored to the previous values.
 332
 333 Any data C<return>ed from the action forwarded to, will be returned by the
 334 call to forward.
 335
 336     my $foodata = $c->forward('/foo');
 337     $c->forward('index');
 338     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 339     $c->forward('View::TT');
 340
 341 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 342 an C<< eval { } >> around the call (actually
 343 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 344 exceptions thrown by the called action non-fatal and pushing them onto
 345 $c->error instead. If you want C<die> to propagate you need to do something
 346 like:
 347
 348     $c->forward('foo');
 349     die join "\n", @{ $c->error } if @{ $c->error };
 350
 351 Or make sure to always return true values from your actions and write
 352 your code like this:
 353
 354     $c->forward('foo') || return;
 355
 356 Another note is that C<< $c->forward >> always returns a scalar because it
 357 actually returns $c->state which operates in a scalar context.
 358 Thus, something like:
 359
 360     return @array;
 361
 362 in an action that is forwarded to is going to return a scalar,
 363 i.e. how many items are in that array, which is probably not what you want.
 364 If you need to return an array then return a reference to it,
 365 or stash it like so:
 366
 367     $c->stash->{array} = \@array;
 368
 369 and access it from the stash.
 370
 371 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 372
 373 =cut
 374
 375 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 376
 377 =head2 $c->detach( $action [, \@arguments ] )
 378
 379 =head2 $c->detach( $class, $method, [, \@arguments ] )
 380
 381 =head2 $c->detach()
 382
 383 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 384 doesn't return to the previous action when processing is finished.
 385
 386 When called with no arguments it escapes the processing chain entirely.
 387
 388 =cut
 389
 390 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 391
 392 =head2 $c->visit( $action [, \@arguments ] )
 393
 394 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@arguments ] )
 397
 398 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 399
 400 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 401 but does a full dispatch, instead of just calling the new C<$action> /
 402 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 403 you go to are called, just like a new request.
 404
 405 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 406 This means, for example, that C<< $c->action >> methods such as
 407 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 408 L<reverse|Catalyst::Action/reverse> return information for the visited action
 409 when they are invoked within the visited action.  This is different from the
 410 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 411 continues to use the $c->action object from the caller action even when
 412 invoked from the called action.
 413
 414 C<< $c->stash >> is kept unchanged.
 415
 416 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 417 allows you to "wrap" another action, just as it would have been called by
 418 dispatching from a URL, while the analogous
 419 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 420 transfer control to another action as if it had been reached directly from a URL.
 421
 422 =cut
 423
 424 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 425
 426 =head2 $c->go( $action [, \@arguments ] )
 427
 428 =head2 $c->go( $action [, \@captures, \@arguments ] )
 429
 430 =head2 $c->go( $class, $method, [, \@arguments ] )
 431
 432 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 433
 434 The relationship between C<go> and
 435 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 436 the relationship between
 437 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 438 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 439 C<< $c->go >> will perform a full dispatch on the specified action or method,
 440 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 441 C<go> escapes the processing of the current request chain on completion, and
 442 does not return to its caller.
 443
 444 @arguments are arguments to the final destination of $action. @captures are
 445 arguments to the intermediate steps, if any, on the way to the final sub of
 446 $action.
 447
 448 =cut
 449
 450 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 451
 452 =head2 $c->response
 453
 454 =head2 $c->res
 455
 456 Returns the current L<Catalyst::Response> object, see there for details.
 457
 458 =head2 $c->stash
 459
 460 Returns a hashref to the stash, which may be used to store data and pass
 461 it between components during a request. You can also set hash keys by
 462 passing arguments. The stash is automatically sent to the view. The
 463 stash is cleared at the end of a request; it cannot be used for
 464 persistent storage (for this you must use a session; see
 465 L<Catalyst::Plugin::Session> for a complete system integrated with
 466 Catalyst).
 467
 468     $c->stash->{foo} = $bar;
 469     $c->stash( { moose => 'majestic', qux => 0 } );
 470     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 471
 472     # stash is automatically passed to the view for use in a template
 473     $c->forward( 'MyApp::View::TT' );
 474
 475 =cut
 476
 477 around stash => sub {
 478     my $orig = shift;
 479     my $c = shift;
 480     my $stash = $orig->($c);
 481     if (@_) {
 482         my $new_stash = @_ > 1 ? {@_} : $_[0];
 483         croak('stash takes a hash or hashref') unless ref $new_stash;
 484         foreach my $key ( keys %$new_stash ) {
 485           $stash->{$key} = $new_stash->{$key};
 486         }
 487     }
 488
 489     return $stash;
 490 };
 491
 492
 493 =head2 $c->error
 494
 495 =head2 $c->error($error, ...)
 496
 497 =head2 $c->error($arrayref)
 498
 499 Returns an arrayref containing error messages.  If Catalyst encounters an
 500 error while processing a request, it stores the error in $c->error.  This
 501 method should only be used to store fatal error messages.
 502
 503     my @error = @{ $c->error };
 504
 505 Add a new error.
 506
 507     $c->error('Something bad happened');
 508
 509 =cut
 510
 511 sub error {
 512     my $c = shift;
 513     if ( $_[0] ) {
 514         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 515         croak @$error unless ref $c;
 516         push @{ $c->{error} }, @$error;
 517     }
 518     elsif ( defined $_[0] ) { $c->{error} = undef }
 519     return $c->{error} || [];
 520 }
 521
 522
 523 =head2 $c->state
 524
 525 Contains the return value of the last executed action.
 526 Note that << $c->state >> operates in a scalar context which means that all
 527 values it returns are scalar.
 528
 529 =head2 $c->clear_errors
 530
 531 Clear errors.  You probably don't want to clear the errors unless you are
 532 implementing a custom error screen.
 533
 534 This is equivalent to running
 535
 536     $c->error(0);
 537
 538 =cut
 539
 540 sub clear_errors {
 541     my $c = shift;
 542     $c->error(0);
 543 }
 544
 545 sub _comp_search_prefixes {
 546     my $c = shift;
 547     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 548 }
 549
 550 # search components given a name and some prefixes
 551 sub _comp_names_search_prefixes {
 552     my ( $c, $name, @prefixes ) = @_;
 553     my $appclass = ref $c || $c;
 554     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 555     $filter = qr/$filter/; # Compile regex now rather than once per loop
 556
 557     # map the original component name to the sub part that we will search against
 558     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 559         grep { /$filter/ } keys %{ $c->components };
 560
 561     # undef for a name will return all
 562     return keys %eligible if !defined $name;
 563
 564     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 565     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 566
 567     return @result if @result;
 568
 569     # if we were given a regexp to search against, we're done.
 570     return if $name->$_isa('Regexp');
 571
 572     # skip regexp fallback if configured
 573     return
 574         if $appclass->config->{disable_component_resolution_regex_fallback};
 575
 576     # regexp fallback
 577     $query  = qr/$name/i;
 578     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 579
 580     # no results? try against full names
 581     if( !@result ) {
 582         @result = grep { m{$query} } keys %eligible;
 583     }
 584
 585     # don't warn if we didn't find any results, it just might not exist
 586     if( @result ) {
 587         # Disgusting hack to work out correct method name
 588         my $warn_for = lc $prefixes[0];
 589         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 590            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 591            "component resolution is unreliable and unsafe.";
 592         my $short = $result[0];
 593         # remove the component namespace prefix
 594         $short =~ s/.*?(Model|Controller|View):://;
 595         my $shortmess = Carp::shortmess('');
 596         if ($shortmess =~ m#Catalyst/Plugin#) {
 597            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 598               "plugin's config";
 599         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 600            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 601               "component's config";
 602         } else {
 603            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 604               "but if you really wanted to search, pass in a regexp as the argument " .
 605               "like so: \$c->${warn_for}(qr/${name}/)";
 606         }
 607         $c->log->warn( "${msg}$shortmess" );
 608     }
 609
 610     return @result;
 611 }
 612
 613 # Find possible names for a prefix
 614 sub _comp_names {
 615     my ( $c, @prefixes ) = @_;
 616     my $appclass = ref $c || $c;
 617
 618     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 619
 620     my @names = map { s{$filter}{}; $_; }
 621         $c->_comp_names_search_prefixes( undef, @prefixes );
 622
 623     return @names;
 624 }
 625
 626 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 627 sub _filter_component {
 628     my ( $c, $comp, @args ) = @_;
 629
 630     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 631         return $comp->ACCEPT_CONTEXT( $c, @args );
 632     }
 633
 634     return $comp;
 635 }
 636
 637 =head2 COMPONENT ACCESSORS
 638
 639 =head2 $c->controller($name)
 640
 641 Gets a L<Catalyst::Controller> instance by name.
 642
 643     $c->controller('Foo')->do_stuff;
 644
 645 If the name is omitted, will return the controller for the dispatched
 646 action.
 647
 648 If you want to search for controllers, pass in a regexp as the argument.
 649
 650     # find all controllers that start with Foo
 651     my @foo_controllers = $c->controller(qr{^Foo});
 652
 653
 654 =cut
 655
 656 sub controller {
 657     my ( $c, $name, @args ) = @_;
 658
 659     my $appclass = ref($c) || $c;
 660     if( $name ) {
 661         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 662             my $comps = $c->components;
 663             my $check = $appclass."::Controller::".$name;
 664             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 665         }
 666         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 667         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 668         return $c->_filter_component( $result[ 0 ], @args );
 669     }
 670
 671     return $c->component( $c->action->class );
 672 }
 673
 674 =head2 $c->model($name)
 675
 676 Gets a L<Catalyst::Model> instance by name.
 677
 678     $c->model('Foo')->do_stuff;
 679
 680 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 681
 682 If the name is omitted, it will look for
 683  - a model object in $c->stash->{current_model_instance}, then
 684  - a model name in $c->stash->{current_model}, then
 685  - a config setting 'default_model', or
 686  - check if there is only one model, and return it if that's the case.
 687
 688 If you want to search for models, pass in a regexp as the argument.
 689
 690     # find all models that start with Foo
 691     my @foo_models = $c->model(qr{^Foo});
 692
 693 =cut
 694
 695 sub model {
 696     my ( $c, $name, @args ) = @_;
 697     my $appclass = ref($c) || $c;
 698     if( $name ) {
 699         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 700             my $comps = $c->components;
 701             my $check = $appclass."::Model::".$name;
 702             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 703         }
 704         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 705         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 706         return $c->_filter_component( $result[ 0 ], @args );
 707     }
 708
 709     if (ref $c) {
 710         return $c->stash->{current_model_instance}
 711           if $c->stash->{current_model_instance};
 712         return $c->model( $c->stash->{current_model} )
 713           if $c->stash->{current_model};
 714     }
 715     return $c->model( $appclass->config->{default_model} )
 716       if $appclass->config->{default_model};
 717
 718     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 719
 720     if( $rest ) {
 721         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 722         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 723         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 724         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 725         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 726     }
 727
 728     return $c->_filter_component( $comp );
 729 }
 730
 731
 732 =head2 $c->view($name)
 733
 734 Gets a L<Catalyst::View> instance by name.
 735
 736     $c->view('Foo')->do_stuff;
 737
 738 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 739
 740 If the name is omitted, it will look for
 741  - a view object in $c->stash->{current_view_instance}, then
 742  - a view name in $c->stash->{current_view}, then
 743  - a config setting 'default_view', or
 744  - check if there is only one view, and return it if that's the case.
 745
 746 If you want to search for views, pass in a regexp as the argument.
 747
 748     # find all views that start with Foo
 749     my @foo_views = $c->view(qr{^Foo});
 750
 751 =cut
 752
 753 sub view {
 754     my ( $c, $name, @args ) = @_;
 755
 756     my $appclass = ref($c) || $c;
 757     if( $name ) {
 758         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 759             my $comps = $c->components;
 760             my $check = $appclass."::View::".$name;
 761             if( exists $comps->{$check} ) {
 762                 return $c->_filter_component( $comps->{$check}, @args );
 763             }
 764             else {
 765                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 766             }
 767         }
 768         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 769         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 770         return $c->_filter_component( $result[ 0 ], @args );
 771     }
 772
 773     if (ref $c) {
 774         return $c->stash->{current_view_instance}
 775           if $c->stash->{current_view_instance};
 776         return $c->view( $c->stash->{current_view} )
 777           if $c->stash->{current_view};
 778     }
 779     return $c->view( $appclass->config->{default_view} )
 780       if $appclass->config->{default_view};
 781
 782     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 783
 784     if( $rest ) {
 785         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 786         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 787         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 788         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 789         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 790     }
 791
 792     return $c->_filter_component( $comp );
 793 }
 794
 795 =head2 $c->controllers
 796
 797 Returns the available names which can be passed to $c->controller
 798
 799 =cut
 800
 801 sub controllers {
 802     my ( $c ) = @_;
 803     return $c->_comp_names(qw/Controller C/);
 804 }
 805
 806 =head2 $c->models
 807
 808 Returns the available names which can be passed to $c->model
 809
 810 =cut
 811
 812 sub models {
 813     my ( $c ) = @_;
 814     return $c->_comp_names(qw/Model M/);
 815 }
 816
 817
 818 =head2 $c->views
 819
 820 Returns the available names which can be passed to $c->view
 821
 822 =cut
 823
 824 sub views {
 825     my ( $c ) = @_;
 826     return $c->_comp_names(qw/View V/);
 827 }
 828
 829 =head2 $c->comp($name)
 830
 831 =head2 $c->component($name)
 832
 833 Gets a component object by name. This method is not recommended,
 834 unless you want to get a specific component by full
 835 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 836 should be used instead.
 837
 838 If C<$name> is a regexp, a list of components matched against the full
 839 component name will be returned.
 840
 841 If Catalyst can't find a component by name, it will fallback to regex
 842 matching by default. To disable this behaviour set
 843 disable_component_resolution_regex_fallback to a true value.
 844
 845     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 846
 847 =cut
 848
 849 sub component {
 850     my ( $c, $name, @args ) = @_;
 851
 852     if( $name ) {
 853         my $comps = $c->components;
 854
 855         if( !ref $name ) {
 856             # is it the exact name?
 857             return $c->_filter_component( $comps->{ $name }, @args )
 858                        if exists $comps->{ $name };
 859
 860             # perhaps we just omitted "MyApp"?
 861             my $composed = ( ref $c || $c ) . "::${name}";
 862             return $c->_filter_component( $comps->{ $composed }, @args )
 863                        if exists $comps->{ $composed };
 864
 865             # search all of the models, views and controllers
 866             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 867             return $c->_filter_component( $comp, @args ) if $comp;
 868         }
 869
 870         return
 871             if $c->config->{disable_component_resolution_regex_fallback};
 872
 873         # This is here so $c->comp( '::M::' ) works
 874         my $query = ref $name ? $name : qr{$name}i;
 875
 876         my @result = grep { m{$query} } keys %{ $c->components };
 877         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 878
 879         if( $result[ 0 ] ) {
 880             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 881             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 882             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 883             return $c->_filter_component( $result[ 0 ], @args );
 884         }
 885
 886         # I would expect to return an empty list here, but that breaks back-compat
 887     }
 888
 889     # fallback
 890     return sort keys %{ $c->components };
 891 }
 892
 893 =head2 CLASS DATA AND HELPER CLASSES
 894
 895 =head2 $c->config
 896
 897 Returns or takes a hashref containing the application's configuration.
 898
 899     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 900
 901 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 902 like C<myapp.conf> in your applications home directory. See
 903 L<Catalyst::Plugin::ConfigLoader>.
 904
 905 =head3 Cascading configuration
 906
 907 The config method is present on all Catalyst components, and configuration
 908 will be merged when an application is started. Configuration loaded with
 909 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 910 followed by configuration in your top level C<MyApp> class. These two
 911 configurations are merged, and then configuration data whose hash key matches a
 912 component name is merged with configuration for that component.
 913
 914 The configuration for a component is then passed to the C<new> method when a
 915 component is constructed.
 916
 917 For example:
 918
 919     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 920     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 921
 922 will mean that C<MyApp::Model::Foo> receives the following data when
 923 constructed:
 924
 925     MyApp::Model::Foo->new({
 926         bar => 'baz',
 927         quux => 'frob',
 928         overrides => 'me',
 929     });
 930
 931 It's common practice to use a Moose attribute
 932 on the receiving component to access the config value.
 933
 934     package MyApp::Model::Foo;
 935
 936     use Moose;
 937
 938     # this attr will receive 'baz' at construction time
 939     has 'bar' => (
 940         is  => 'rw',
 941         isa => 'Str',
 942     );
 943
 944 You can then get the value 'baz' by calling $c->model('Foo')->bar
 945 (or $self->bar inside code in the model).
 946
 947 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 948 as a way of reading config within your code, as this B<will not> give you the
 949 correctly merged config back. You B<MUST> take the config values supplied to
 950 the constructor and use those instead.
 951
 952 =cut
 953
 954 around config => sub {
 955     my $orig = shift;
 956     my $c = shift;
 957
 958     croak('Setting config after setup has been run is not allowed.')
 959         if ( @_ and $c->setup_finished );
 960
 961     $c->$orig(@_);
 962 };
 963
 964 =head2 $c->log
 965
 966 Returns the logging object instance. Unless it is already set, Catalyst
 967 sets this up with a L<Catalyst::Log> object. To use your own log class,
 968 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 969 C<< __PACKAGE__->setup >>.
 970
 971  __PACKAGE__->log( MyLogger->new );
 972  __PACKAGE__->setup;
 973
 974 And later:
 975
 976     $c->log->info( 'Now logging with my own logger!' );
 977
 978 Your log class should implement the methods described in
 979 L<Catalyst::Log>.
 980
 981
 982 =head2 $c->debug
 983
 984 Returns 1 if debug mode is enabled, 0 otherwise.
 985
 986 You can enable debug mode in several ways:
 987
 988 =over
 989
 990 =item By calling myapp_server.pl with the -d flag
 991
 992 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 993
 994 =item The -Debug option in your MyApp.pm
 995
 996 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 997
 998 =back
 999
1000 The first three also set the log level to 'debug'.
1001
1002 Calling C<< $c->debug(1) >> has no effect.
1003
1004 =cut
1005
1006 sub debug { 0 }
1007
1008 =head2 $c->dispatcher
1009
1010 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1011
1012 =head2 $c->engine
1013
1014 Returns the engine instance. See L<Catalyst::Engine>.
1015
1016
1017 =head2 UTILITY METHODS
1018
1019 =head2 $c->path_to(@path)
1020
1021 Merges C<@path> with C<< $c->config->{home} >> and returns a
1022 L<Path::Class::Dir> object. Note you can usually use this object as
1023 a filename, but sometimes you will have to explicitly stringify it
1024 yourself by calling the C<< ->stringify >> method.
1025
1026 For example:
1027
1028     $c->path_to( 'db', 'sqlite.db' );
1029
1030 =cut
1031
1032 sub path_to {
1033     my ( $c, @path ) = @_;
1034     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1035     if ( -d $path ) { return $path }
1036     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1037 }
1038
1039 sub plugin {
1040     my ( $class, $name, $plugin, @args ) = @_;
1041
1042     # See block comment in t/unit_core_plugin.t
1043     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1044
1045     $class->_register_plugin( $plugin, 1 );
1046
1047     eval { $plugin->import };
1048     $class->mk_classdata($name);
1049     my $obj;
1050     eval { $obj = $plugin->new(@args) };
1051
1052     if ($@) {
1053         Catalyst::Exception->throw( message =>
1054               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1055     }
1056
1057     $class->$name($obj);
1058     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1059       if $class->debug;
1060 }
1061
1062 =head2 MyApp->setup
1063
1064 Initializes the dispatcher and engine, loads any plugins, and loads the
1065 model, view, and controller components. You may also specify an array
1066 of plugins to load here, if you choose to not load them in the C<use
1067 Catalyst> line.
1068
1069     MyApp->setup;
1070     MyApp->setup( qw/-Debug/ );
1071
1072 B<Note:> You B<should not> wrap this method with method modifiers
1073 or bad things will happen - wrap the C<setup_finalize> method instead.
1074
1075 =cut
1076
1077 sub setup {
1078     my ( $class, @arguments ) = @_;
1079     croak('Running setup more than once')
1080         if ( $class->setup_finished );
1081
1082     unless ( $class->isa('Catalyst') ) {
1083
1084         Catalyst::Exception->throw(
1085             message => qq/'$class' does not inherit from Catalyst/ );
1086     }
1087
1088     if ( $class->arguments ) {
1089         @arguments = ( @arguments, @{ $class->arguments } );
1090     }
1091
1092     # Process options
1093     my $flags = {};
1094
1095     foreach (@arguments) {
1096
1097         if (/^-Debug$/) {
1098             $flags->{log} =
1099               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1100         }
1101         elsif (/^-(\w+)=?(.*)$/) {
1102             $flags->{ lc $1 } = $2;
1103         }
1104         else {
1105             push @{ $flags->{plugins} }, $_;
1106         }
1107     }
1108
1109     $class->setup_home( delete $flags->{home} );
1110
1111     $class->setup_log( delete $flags->{log} );
1112     $class->setup_plugins( delete $flags->{plugins} );
1113     $class->setup_dispatcher( delete $flags->{dispatcher} );
1114     if (my $engine = delete $flags->{engine}) {
1115         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1116     }
1117     $class->setup_engine();
1118     $class->setup_stats( delete $flags->{stats} );
1119
1120     for my $flag ( sort keys %{$flags} ) {
1121
1122         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1123             &$code( $class, delete $flags->{$flag} );
1124         }
1125         else {
1126             $class->log->warn(qq/Unknown flag "$flag"/);
1127         }
1128     }
1129
1130     eval { require Catalyst::Devel; };
1131     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1132         $class->log->warn(<<"EOF");
1133 You are running an old script!
1134
1135   Please update by running (this will overwrite existing files):
1136     catalyst.pl -force -scripts $class
1137
1138   or (this will not overwrite existing files):
1139     catalyst.pl -scripts $class
1140
1141 EOF
1142     }
1143
1144     if ( $class->debug ) {
1145         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1146
1147         if (@plugins) {
1148             my $column_width = Catalyst::Utils::term_width() - 6;
1149             my $t = Text::SimpleTable->new($column_width);
1150             $t->row($_) for @plugins;
1151             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1152         }
1153
1154         my $dispatcher = $class->dispatcher;
1155         my $engine     = $class->engine;
1156         my $home       = $class->config->{home};
1157
1158         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1159         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1160
1161         $home
1162           ? ( -d $home )
1163           ? $class->log->debug(qq/Found home "$home"/)
1164           : $class->log->debug(qq/Home "$home" doesn't exist/)
1165           : $class->log->debug(q/Couldn't find home/);
1166     }
1167
1168     # Call plugins setup, this is stupid and evil.
1169     # Also screws C3 badly on 5.10, hack to avoid.
1170     {
1171         no warnings qw/redefine/;
1172         local *setup = sub { };
1173         $class->setup unless $Catalyst::__AM_RESTARTING;
1174     }
1175
1176     # Initialize our data structure
1177     $class->components( {} );
1178
1179     $class->setup_components;
1180
1181     if ( $class->debug ) {
1182         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1183         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1184         for my $comp ( sort keys %{ $class->components } ) {
1185             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1186             $t->row( $comp, $type );
1187         }
1188         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1189           if ( keys %{ $class->components } );
1190     }
1191
1192     # Add our self to components, since we are also a component
1193     if( $class->isa('Catalyst::Controller') ){
1194       $class->components->{$class} = $class;
1195     }
1196
1197     $class->setup_actions;
1198
1199     if ( $class->debug ) {
1200         my $name = $class->config->{name} || 'Application';
1201         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1202     }
1203
1204     if ($class->config->{case_sensitive}) {
1205         $class->log->warn($class . "->config->{case_sensitive} is set.");
1206         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1207     }
1208
1209     $class->setup_finalize;
1210     # Should be the last thing we do so that user things hooking
1211     # setup_finalize can log..
1212     $class->log->_flush() if $class->log->can('_flush');
1213     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1214 }
1215
1216 =head2 $app->setup_finalize
1217
1218 A hook to attach modifiers to. This method does not do anything except set the
1219 C<setup_finished> accessor.
1220
1221 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1222
1223 Example:
1224
1225     after setup_finalize => sub {
1226         my $app = shift;
1227
1228         ## do stuff here..
1229     };
1230
1231 =cut
1232
1233 sub setup_finalize {
1234     my ($class) = @_;
1235     $class->setup_finished(1);
1236 }
1237
1238 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1239
1240 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1241
1242 Constructs an absolute L<URI> object based on the application root, the
1243 provided path, and the additional arguments and query parameters provided.
1244 When used as a string, provides a textual URI.  If you need more flexibility
1245 than this (i.e. the option to provide relative URIs etc.) see
1246 L<Catalyst::Plugin::SmartURI>.
1247
1248 If no arguments are provided, the URI for the current action is returned.
1249 To return the current action and also provide @args, use
1250 C<< $c->uri_for( $c->action, @args ) >>.
1251
1252 If the first argument is a string, it is taken as a public URI path relative
1253 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1254 relative to the application root (if it does). It is then merged with
1255 C<< $c->request->base >>; any C<@args> are appended as additional path
1256 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1257
1258 If the first argument is a L<Catalyst::Action> it represents an action which
1259 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1260 optional C<\@captures> argument (an arrayref) allows passing the captured
1261 variables that are needed to fill in the paths of Chained and Regex actions;
1262 once the path is resolved, C<uri_for> continues as though a path was
1263 provided, appending any arguments or parameters and creating an absolute
1264 URI.
1265
1266 The captures for the current request can be found in
1267 C<< $c->request->captures >>, and actions can be resolved using
1268 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1269 path, use C<< $c->uri_for_action >> instead.
1270
1271   # Equivalent to $c->req->uri
1272   $c->uri_for($c->action, $c->req->captures,
1273       @{ $c->req->args }, $c->req->params);
1274
1275   # For the Foo action in the Bar controller
1276   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1277
1278   # Path to a static resource
1279   $c->uri_for('/static/images/logo.png');
1280
1281 =cut
1282
1283 sub uri_for {
1284     my ( $c, $path, @args ) = @_;
1285
1286     if ( $path->$_isa('Catalyst::Controller') ) {
1287         $path = $path->path_prefix;
1288         $path =~ s{/+\z}{};
1289         $path .= '/';
1290     }
1291
1292     undef($path) if (defined $path && $path eq '');
1293
1294     my $params =
1295       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1296
1297     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1298     foreach my $arg (@args) {
1299         utf8::encode($arg) if utf8::is_utf8($arg);
1300         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1301     }
1302
1303     if ( $path->$_isa('Catalyst::Action') ) { # action object
1304         s|/|%2F|g for @args;
1305         my $captures = [ map { s|/|%2F|g; $_; }
1306                         ( scalar @args && ref $args[0] eq 'ARRAY'
1307                          ? @{ shift(@args) }
1308                          : ()) ];
1309
1310         foreach my $capture (@$captures) {
1311             utf8::encode($capture) if utf8::is_utf8($capture);
1312             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1313         }
1314
1315         my $action = $path;
1316         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1317         if( !@args && $action->number_of_args ) {
1318             my $expanded_action = $c->dispatcher->expand_action( $action );
1319
1320             my $num_captures = $expanded_action->number_of_captures;
1321             unshift @args, splice @$captures, $num_captures;
1322         }
1323
1324        $path = $c->dispatcher->uri_for_action($action, $captures);
1325         if (not defined $path) {
1326             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1327                 if $c->debug;
1328             return undef;
1329         }
1330         $path = '/' if $path eq '';
1331     }
1332
1333     unshift(@args, $path);
1334
1335     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1336         my $namespace = $c->namespace;
1337         if (defined $path) { # cheesy hack to handle path '../foo'
1338            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1339         }
1340         unshift(@args, $namespace || '');
1341     }
1342
1343     # join args with '/', or a blank string
1344     my $args = join('/', grep { defined($_) } @args);
1345     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1346     $args =~ s!^/+!!;
1347
1348     my ($base, $class) = ('/', 'URI::_generic');
1349     if(blessed($c)) {
1350       $base = $c->req->base;
1351       $class = ref($base);
1352       $base =~ s{(?<!/)$}{/};
1353     }
1354
1355     my $query = '';
1356
1357     if (my @keys = keys %$params) {
1358       # somewhat lifted from URI::_query's query_form
1359       $query = '?'.join('&', map {
1360           my $val = $params->{$_};
1361           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1362           s/ /+/g;
1363           my $key = $_;
1364           $val = '' unless defined $val;
1365           (map {
1366               my $param = "$_";
1367               utf8::encode( $param ) if utf8::is_utf8($param);
1368               # using the URI::Escape pattern here so utf8 chars survive
1369               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1370               $param =~ s/ /+/g;
1371               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1372       } @keys);
1373     }
1374
1375     my $res = bless(\"${base}${args}${query}", $class);
1376     $res;
1377 }
1378
1379 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1380
1381 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1382
1383 =over
1384
1385 =item $path
1386
1387 A private path to the Catalyst action you want to create a URI for.
1388
1389 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1390 >> and passing the resulting C<$action> and the remaining arguments to C<<
1391 $c->uri_for >>.
1392
1393 You can also pass in a Catalyst::Action object, in which case it is passed to
1394 C<< $c->uri_for >>.
1395
1396 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1397
1398 For example, if the action looks like:
1399
1400  package MyApp::Controller::Users;
1401
1402  sub lst : Path('the-list') {}
1403
1404 You can use:
1405
1406  $c->uri_for_action('/users/lst')
1407
1408 and it will create the URI /users/the-list.
1409
1410 =item \@captures_and_args?
1411
1412 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1413 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1414 to interpolate all the parameters in the URI.
1415
1416 =item @args?
1417
1418 Optional list of extra arguments - can be supplied in the
1419 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1420 code.
1421
1422 Your action can have zero, a fixed or a variable number of args (e.g.
1423 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1424
1425 =item \%query_values?
1426
1427 Optional array reference of query parameters to append. E.g.
1428
1429   { foo => 'bar' }
1430
1431 will generate
1432
1433   /rest/of/your/uri?foo=bar
1434
1435 =back
1436
1437 =cut
1438
1439 sub uri_for_action {
1440     my ( $c, $path, @args ) = @_;
1441     my $action = blessed($path)
1442       ? $path
1443       : $c->dispatcher->get_action_by_path($path);
1444     unless (defined $action) {
1445       croak "Can't find action for path '$path'";
1446     }
1447     return $c->uri_for( $action, @args );
1448 }
1449
1450 =head2 $c->welcome_message
1451
1452 Returns the Catalyst welcome HTML page.
1453
1454 =cut
1455
1456 sub welcome_message {
1457     my $c      = shift;
1458     my $name   = $c->config->{name};
1459     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1460     my $prefix = Catalyst::Utils::appprefix( ref $c );
1461     $c->response->content_type('text/html; charset=utf-8');
1462     return <<"EOF";
1463 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1464     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1465 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1466     <head>
1467     <meta http-equiv="Content-Language" content="en" />
1468     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1469         <title>$name on Catalyst $VERSION</title>
1470         <style type="text/css">
1471             body {
1472                 color: #000;
1473                 background-color: #eee;
1474             }
1475             div#content {
1476                 width: 640px;
1477                 margin-left: auto;
1478                 margin-right: auto;
1479                 margin-top: 10px;
1480                 margin-bottom: 10px;
1481                 text-align: left;
1482                 background-color: #ccc;
1483                 border: 1px solid #aaa;
1484             }
1485             p, h1, h2 {
1486                 margin-left: 20px;
1487                 margin-right: 20px;
1488                 font-family: verdana, tahoma, sans-serif;
1489             }
1490             a {
1491                 font-family: verdana, tahoma, sans-serif;
1492             }
1493             :link, :visited {
1494                     text-decoration: none;
1495                     color: #b00;
1496                     border-bottom: 1px dotted #bbb;
1497             }
1498             :link:hover, :visited:hover {
1499                     color: #555;
1500             }
1501             div#topbar {
1502                 margin: 0px;
1503             }
1504             pre {
1505                 margin: 10px;
1506                 padding: 8px;
1507             }
1508             div#answers {
1509                 padding: 8px;
1510                 margin: 10px;
1511                 background-color: #fff;
1512                 border: 1px solid #aaa;
1513             }
1514             h1 {
1515                 font-size: 0.9em;
1516                 font-weight: normal;
1517                 text-align: center;
1518             }
1519             h2 {
1520                 font-size: 1.0em;
1521             }
1522             p {
1523                 font-size: 0.9em;
1524             }
1525             p img {
1526                 float: right;
1527                 margin-left: 10px;
1528             }
1529             span#appname {
1530                 font-weight: bold;
1531                 font-size: 1.6em;
1532             }
1533         </style>
1534     </head>
1535     <body>
1536         <div id="content">
1537             <div id="topbar">
1538                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1539                     $VERSION</h1>
1540              </div>
1541              <div id="answers">
1542                  <p>
1543                  <img src="$logo" alt="Catalyst Logo" />
1544                  </p>
1545                  <p>Welcome to the  world of Catalyst.
1546                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1547                     framework will make web development something you had
1548                     never expected it to be: Fun, rewarding, and quick.</p>
1549                  <h2>What to do now?</h2>
1550                  <p>That really depends  on what <b>you</b> want to do.
1551                     We do, however, provide you with a few starting points.</p>
1552                  <p>If you want to jump right into web development with Catalyst
1553                     you might want to start with a tutorial.</p>
1554 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1555 </pre>
1556 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1557 <pre>
1558 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1559 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1560 </code></pre>
1561                  <h2>What to do next?</h2>
1562                  <p>Next it's time to write an actual application. Use the
1563                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1564                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1565                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1566                     they can save you a lot of work.</p>
1567                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1568                     <p>Also, be sure to check out the vast and growing
1569                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1570                     you are likely to find what you need there.
1571                     </p>
1572
1573                  <h2>Need help?</h2>
1574                  <p>Catalyst has a very active community. Here are the main places to
1575                     get in touch with us.</p>
1576                  <ul>
1577                      <li>
1578                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1579                      </li>
1580                      <li>
1581                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1582                      </li>
1583                      <li>
1584                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1585                      </li>
1586                  </ul>
1587                  <h2>In conclusion</h2>
1588                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1589                     as we enjoyed making it. Please contact us if you have ideas
1590                     for improvement or other feedback.</p>
1591              </div>
1592          </div>
1593     </body>
1594 </html>
1595 EOF
1596 }
1597
1598 =head2 run_options
1599
1600 Contains a hash of options passed from the application script, including
1601 the original ARGV the script received, the processed values from that
1602 ARGV and any extra arguments to the script which were not processed.
1603
1604 This can be used to add custom options to your application's scripts
1605 and setup your application differently depending on the values of these
1606 options.
1607
1608 =head1 INTERNAL METHODS
1609
1610 These methods are not meant to be used by end users.
1611
1612 =head2 $c->components
1613
1614 Returns a hash of components.
1615
1616 =head2 $c->context_class
1617
1618 Returns or sets the context class.
1619
1620 =head2 $c->counter
1621
1622 Returns a hashref containing coderefs and execution counts (needed for
1623 deep recursion detection).
1624
1625 =head2 $c->depth
1626
1627 Returns the number of actions on the current internal execution stack.
1628
1629 =head2 $c->dispatch
1630
1631 Dispatches a request to actions.
1632
1633 =cut
1634
1635 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1636
1637 =head2 $c->dispatcher_class
1638
1639 Returns or sets the dispatcher class.
1640
1641 =head2 $c->dump_these
1642
1643 Returns a list of 2-element array references (name, structure) pairs
1644 that will be dumped on the error page in debug mode.
1645
1646 =cut
1647
1648 sub dump_these {
1649     my $c = shift;
1650     [ Request => $c->req ],
1651     [ Response => $c->res ],
1652     [ Stash => $c->stash ],
1653     [ Config => $c->config ];
1654 }
1655
1656 =head2 $c->engine_class
1657
1658 Returns or sets the engine class.
1659
1660 =head2 $c->execute( $class, $coderef )
1661
1662 Execute a coderef in given class and catch exceptions. Errors are available
1663 via $c->error.
1664
1665 =cut
1666
1667 sub execute {
1668     my ( $c, $class, $code ) = @_;
1669     $class = $c->component($class) || $class;
1670     $c->state(0);
1671
1672     if ( $c->depth >= $RECURSION ) {
1673         my $action = $code->reverse();
1674         $action = "/$action" unless $action =~ /->/;
1675         my $error = qq/Deep recursion detected calling "${action}"/;
1676         $c->log->error($error);
1677         $c->error($error);
1678         $c->state(0);
1679         return $c->state;
1680     }
1681
1682     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1683
1684     push( @{ $c->stack }, $code );
1685
1686     no warnings 'recursion';
1687     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1688     #      I have no idea how, ergo $ret (which appears to fix the issue)
1689     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1690
1691     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1692
1693     my $last = pop( @{ $c->stack } );
1694
1695     if ( my $error = $@ ) {
1696         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1697             $error->rethrow if $c->depth > 1;
1698         }
1699         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1700             $error->rethrow if $c->depth > 0;
1701         }
1702         else {
1703             unless ( ref $error ) {
1704                 no warnings 'uninitialized';
1705                 chomp $error;
1706                 my $class = $last->class;
1707                 my $name  = $last->name;
1708                 $error = qq/Caught exception in $class->$name "$error"/;
1709             }
1710             $c->error($error);
1711         }
1712         $c->state(0);
1713     }
1714     return $c->state;
1715 }
1716
1717 sub _stats_start_execute {
1718     my ( $c, $code ) = @_;
1719     my $appclass = ref($c) || $c;
1720     return if ( ( $code->name =~ /^_.*/ )
1721         && ( !$appclass->config->{show_internal_actions} ) );
1722
1723     my $action_name = $code->reverse();
1724     $c->counter->{$action_name}++;
1725
1726     my $action = $action_name;
1727     $action = "/$action" unless $action =~ /->/;
1728
1729     # determine if the call was the result of a forward
1730     # this is done by walking up the call stack and looking for a calling
1731     # sub of Catalyst::forward before the eval
1732     my $callsub = q{};
1733     for my $index ( 2 .. 11 ) {
1734         last
1735         if ( ( caller($index) )[0] eq 'Catalyst'
1736             && ( caller($index) )[3] eq '(eval)' );
1737
1738         if ( ( caller($index) )[3] =~ /forward$/ ) {
1739             $callsub = ( caller($index) )[3];
1740             $action  = "-> $action";
1741             last;
1742         }
1743     }
1744
1745     my $uid = $action_name . $c->counter->{$action_name};
1746
1747     # is this a root-level call or a forwarded call?
1748     if ( $callsub =~ /forward$/ ) {
1749         my $parent = $c->stack->[-1];
1750
1751         # forward, locate the caller
1752         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1753             $c->stats->profile(
1754                 begin  => $action,
1755                 parent => "$parent" . $c->counter->{"$parent"},
1756                 uid    => $uid,
1757             );
1758         }
1759         else {
1760
1761             # forward with no caller may come from a plugin
1762             $c->stats->profile(
1763                 begin => $action,
1764                 uid   => $uid,
1765             );
1766         }
1767     }
1768     else {
1769
1770         # root-level call
1771         $c->stats->profile(
1772             begin => $action,
1773             uid   => $uid,
1774         );
1775     }
1776     return $action;
1777
1778 }
1779
1780 sub _stats_finish_execute {
1781     my ( $c, $info ) = @_;
1782     $c->stats->profile( end => $info );
1783 }
1784
1785 =head2 $c->finalize
1786
1787 Finalizes the request.
1788
1789 =cut
1790
1791 sub finalize {
1792     my $c = shift;
1793
1794     for my $error ( @{ $c->error } ) {
1795         $c->log->error($error);
1796     }
1797
1798     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1799     # stuff like cometd and websockets
1800
1801     if($c->request->has_io_fh) {
1802       $c->log_response;
1803       return;
1804     }
1805
1806     # Allow engine to handle finalize flow (for POE)
1807     my $engine = $c->engine;
1808     if ( my $code = $engine->can('finalize') ) {
1809         $engine->$code($c);
1810     }
1811     else {
1812
1813         $c->finalize_uploads;
1814
1815         # Error
1816         if ( $#{ $c->error } >= 0 ) {
1817             $c->finalize_error;
1818         }
1819
1820         $c->finalize_headers unless $c->response->finalized_headers;
1821
1822         # HEAD request
1823         if ( $c->request->method eq 'HEAD' ) {
1824             $c->response->body('');
1825         }
1826
1827         $c->finalize_body;
1828     }
1829
1830     $c->log_response;
1831
1832     if ($c->use_stats) {
1833         my $elapsed = $c->stats->elapsed;
1834         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1835         $c->log->info(
1836             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1837     }
1838
1839     return $c->response->status;
1840 }
1841
1842 =head2 $c->finalize_body
1843
1844 Finalizes body.
1845
1846 =cut
1847
1848 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1849
1850 =head2 $c->finalize_cookies
1851
1852 Finalizes cookies.
1853
1854 =cut
1855
1856 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1857
1858 =head2 $c->finalize_error
1859
1860 Finalizes error.
1861
1862 =cut
1863
1864 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1865
1866 =head2 $c->finalize_headers
1867
1868 Finalizes headers.
1869
1870 =cut
1871
1872 sub finalize_headers {
1873     my $c = shift;
1874
1875     my $response = $c->response; #accessor calls can add up?
1876
1877     # Check if we already finalized headers
1878     return if $response->finalized_headers;
1879
1880     # Handle redirects
1881     if ( my $location = $response->redirect ) {
1882         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1883         $response->header( Location => $location );
1884
1885         if ( !$response->has_body ) {
1886             # Add a default body if none is already present
1887             my $encoded_location = encode_entities($location);
1888             $response->body(<<"EOF");
1889 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1890 <html xmlns="http://www.w3.org/1999/xhtml">
1891   <head>
1892     <title>Moved</title>
1893   </head>
1894   <body>
1895      <p>This item has moved <a href="$encoded_location">here</a>.</p>
1896   </body>
1897 </html>
1898 EOF
1899             $response->content_type('text/html; charset=utf-8');
1900         }
1901     }
1902
1903     # Content-Length
1904     if ( defined $response->body && length $response->body && !$response->content_length ) {
1905
1906         # get the length from a filehandle
1907         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1908         {
1909             my $size = -s $response->body;
1910             if ( $size ) {
1911                 $response->content_length( $size );
1912             }
1913             else {
1914                 $c->log->warn('Serving filehandle without a content-length');
1915             }
1916         }
1917         else {
1918             # everything should be bytes at this point, but just in case
1919             $response->content_length( length( $response->body ) );
1920         }
1921     }
1922
1923     # Errors
1924     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1925         $response->headers->remove_header("Content-Length");
1926         $response->body('');
1927     }
1928
1929     $c->finalize_cookies;
1930
1931     $c->response->finalize_headers();
1932
1933     # Done
1934     $response->finalized_headers(1);
1935 }
1936
1937 =head2 $c->finalize_output
1938
1939 An alias for finalize_body.
1940
1941 =head2 $c->finalize_read
1942
1943 Finalizes the input after reading is complete.
1944
1945 =cut
1946
1947 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1948
1949 =head2 $c->finalize_uploads
1950
1951 Finalizes uploads. Cleans up any temporary files.
1952
1953 =cut
1954
1955 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1956
1957 =head2 $c->get_action( $action, $namespace )
1958
1959 Gets an action in a given namespace.
1960
1961 =cut
1962
1963 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1964
1965 =head2 $c->get_actions( $action, $namespace )
1966
1967 Gets all actions of a given name in a namespace and all parent
1968 namespaces.
1969
1970 =cut
1971
1972 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1973
1974 =head2 $app->handle_request( @arguments )
1975
1976 Called to handle each HTTP request.
1977
1978 =cut
1979
1980 sub handle_request {
1981     my ( $class, @arguments ) = @_;
1982
1983     # Always expect worst case!
1984     my $status = -1;
1985     try {
1986         if ($class->debug) {
1987             my $secs = time - $START || 1;
1988             my $av = sprintf '%.3f', $COUNT / $secs;
1989             my $time = localtime time;
1990             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1991         }
1992
1993         my $c = $class->prepare(@arguments);
1994         $c->dispatch;
1995         $status = $c->finalize;
1996     }
1997     catch {
1998         chomp(my $error = $_);
1999         $class->log->error(qq/Caught exception in engine "$error"/);
2000     };
2001
2002     $COUNT++;
2003
2004     if(my $coderef = $class->log->can('_flush')){
2005         $class->log->$coderef();
2006     }
2007     return $status;
2008 }
2009
2010 =head2 $class->prepare( @arguments )
2011
2012 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2013 etc.).
2014
2015 =cut
2016
2017 has _uploadtmp => (
2018     is => 'ro',
2019     predicate => '_has_uploadtmp',
2020 );
2021
2022 sub prepare {
2023     my ( $class, @arguments ) = @_;
2024
2025     # XXX
2026     # After the app/ctxt split, this should become an attribute based on something passed
2027     # into the application.
2028     $class->context_class( ref $class || $class ) unless $class->context_class;
2029
2030     my $uploadtmp = $class->config->{uploadtmp};
2031     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2032
2033     $c->response->_context($c);
2034
2035     #surely this is not the most efficient way to do things...
2036     $c->stats($class->stats_class->new)->enable($c->use_stats);
2037     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2038         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2039     }
2040
2041     try {
2042         # Allow engine to direct the prepare flow (for POE)
2043         if ( my $prepare = $c->engine->can('prepare') ) {
2044             $c->engine->$prepare( $c, @arguments );
2045         }
2046         else {
2047             $c->prepare_request(@arguments);
2048             $c->prepare_connection;
2049             $c->prepare_query_parameters;
2050             $c->prepare_headers; # Just hooks, no longer needed - they just
2051             $c->prepare_cookies; # cause the lazy attribute on req to build
2052             $c->prepare_path;
2053
2054             # Prepare the body for reading, either by prepare_body
2055             # or the user, if they are using $c->read
2056             $c->prepare_read;
2057
2058             # Parse the body unless the user wants it on-demand
2059             unless ( ref($c)->config->{parse_on_demand} ) {
2060                 $c->prepare_body;
2061             }
2062         }
2063         $c->prepare_action;
2064     }
2065     # VERY ugly and probably shouldn't rely on ->finalize actually working
2066     catch {
2067         # failed prepare is always due to an invalid request, right?
2068         $c->response->status(400);
2069         $c->response->content_type('text/plain');
2070         $c->response->body('Bad Request');
2071         # Note we call finalize and then die here, which escapes
2072         # finalize being called in the enclosing block..
2073         # It in fact couldn't be called, as we don't return $c..
2074         # This is a mess - but I'm unsure you can fix this without
2075         # breaking compat for people doing crazy things (we should set
2076         # the 400 and just return the ctx here IMO, letting finalize get called
2077         # above...
2078         $c->finalize;
2079         die $_;
2080     };
2081
2082     $c->log_request;
2083
2084     return $c;
2085 }
2086
2087 =head2 $c->prepare_action
2088
2089 Prepares action. See L<Catalyst::Dispatcher>.
2090
2091 =cut
2092
2093 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2094
2095 =head2 $c->prepare_body
2096
2097 Prepares message body.
2098
2099 =cut
2100
2101 sub prepare_body {
2102     my $c = shift;
2103
2104     return if $c->request->_has_body;
2105
2106     # Initialize on-demand data
2107     $c->engine->prepare_body( $c, @_ );
2108     $c->prepare_parameters;
2109     $c->prepare_uploads;
2110 }
2111
2112 =head2 $c->prepare_body_chunk( $chunk )
2113
2114 Prepares a chunk of data before sending it to L<HTTP::Body>.
2115
2116 See L<Catalyst::Engine>.
2117
2118 =cut
2119
2120 sub prepare_body_chunk {
2121     my $c = shift;
2122     $c->engine->prepare_body_chunk( $c, @_ );
2123 }
2124
2125 =head2 $c->prepare_body_parameters
2126
2127 Prepares body parameters.
2128
2129 =cut
2130
2131 sub prepare_body_parameters {
2132     my $c = shift;
2133     $c->engine->prepare_body_parameters( $c, @_ );
2134 }
2135
2136 =head2 $c->prepare_connection
2137
2138 Prepares connection.
2139
2140 =cut
2141
2142 sub prepare_connection {
2143     my $c = shift;
2144     # XXX - This is called on the engine (not the request) to maintain
2145     #       Engine::PSGI back compat.
2146     $c->engine->prepare_connection($c);
2147 }
2148
2149 =head2 $c->prepare_cookies
2150
2151 Prepares cookies by ensuring that the attribute on the request
2152 object has been built.
2153
2154 =cut
2155
2156 sub prepare_cookies { my $c = shift; $c->request->cookies }
2157
2158 =head2 $c->prepare_headers
2159
2160 Prepares request headers by ensuring that the attribute on the request
2161 object has been built.
2162
2163 =cut
2164
2165 sub prepare_headers { my $c = shift; $c->request->headers }
2166
2167 =head2 $c->prepare_parameters
2168
2169 Prepares parameters.
2170
2171 =cut
2172
2173 sub prepare_parameters {
2174     my $c = shift;
2175     $c->prepare_body_parameters;
2176     $c->engine->prepare_parameters( $c, @_ );
2177 }
2178
2179 =head2 $c->prepare_path
2180
2181 Prepares path and base.
2182
2183 =cut
2184
2185 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2186
2187 =head2 $c->prepare_query_parameters
2188
2189 Prepares query parameters.
2190
2191 =cut
2192
2193 sub prepare_query_parameters {
2194     my $c = shift;
2195
2196     $c->engine->prepare_query_parameters( $c, @_ );
2197 }
2198
2199 =head2 $c->log_request
2200
2201 Writes information about the request to the debug logs.  This includes:
2202
2203 =over 4
2204
2205 =item * Request method, path, and remote IP address
2206
2207 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2208
2209 =item * Request parameters
2210
2211 =item * File uploads
2212
2213 =back
2214
2215 =cut
2216
2217 sub log_request {
2218     my $c = shift;
2219
2220     return unless $c->debug;
2221
2222     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2223     my $request = $dump->[1];
2224
2225     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2226     $method ||= '';
2227     $path = '/' unless length $path;
2228     $address ||= '';
2229     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2230
2231     $c->log_request_headers($request->headers);
2232
2233     if ( my $keywords = $request->query_keywords ) {
2234         $c->log->debug("Query keywords are: $keywords");
2235     }
2236
2237     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2238
2239     $c->log_request_uploads($request);
2240 }
2241
2242 =head2 $c->log_response
2243
2244 Writes information about the response to the debug logs by calling
2245 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2246
2247 =cut
2248
2249 sub log_response {
2250     my $c = shift;
2251
2252     return unless $c->debug;
2253
2254     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2255     my $response = $dump->[1];
2256
2257     $c->log_response_status_line($response);
2258     $c->log_response_headers($response->headers);
2259 }
2260
2261 =head2 $c->log_response_status_line($response)
2262
2263 Writes one line of information about the response to the debug logs.  This includes:
2264
2265 =over 4
2266
2267 =item * Response status code
2268
2269 =item * Content-Type header (if present)
2270
2271 =item * Content-Length header (if present)
2272
2273 =back
2274
2275 =cut
2276
2277 sub log_response_status_line {
2278     my ($c, $response) = @_;
2279
2280     $c->log->debug(
2281         sprintf(
2282             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2283             $response->status                            || 'unknown',
2284             $response->headers->header('Content-Type')   || 'unknown',
2285             $response->headers->header('Content-Length') || 'unknown'
2286         )
2287     );
2288 }
2289
2290 =head2 $c->log_response_headers($headers);
2291
2292 Hook method which can be wrapped by plugins to log the response headers.
2293 No-op in the default implementation.
2294
2295 =cut
2296
2297 sub log_response_headers {}
2298
2299 =head2 $c->log_request_parameters( query => {}, body => {} )
2300
2301 Logs request parameters to debug logs
2302
2303 =cut
2304
2305 sub log_request_parameters {
2306     my $c          = shift;
2307     my %all_params = @_;
2308
2309     return unless $c->debug;
2310
2311     my $column_width = Catalyst::Utils::term_width() - 44;
2312     foreach my $type (qw(query body)) {
2313         my $params = $all_params{$type};
2314         next if ! keys %$params;
2315         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2316         for my $key ( sort keys %$params ) {
2317             my $param = $params->{$key};
2318             my $value = defined($param) ? $param : '';
2319             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2320         }
2321         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2322     }
2323 }
2324
2325 =head2 $c->log_request_uploads
2326
2327 Logs file uploads included in the request to the debug logs.
2328 The parameter name, filename, file type, and file size are all included in
2329 the debug logs.
2330
2331 =cut
2332
2333 sub log_request_uploads {
2334     my $c = shift;
2335     my $request = shift;
2336     return unless $c->debug;
2337     my $uploads = $request->uploads;
2338     if ( keys %$uploads ) {
2339         my $t = Text::SimpleTable->new(
2340             [ 12, 'Parameter' ],
2341             [ 26, 'Filename' ],
2342             [ 18, 'Type' ],
2343             [ 9,  'Size' ]
2344         );
2345         for my $key ( sort keys %$uploads ) {
2346             my $upload = $uploads->{$key};
2347             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2348                 $t->row( $key, $u->filename, $u->type, $u->size );
2349             }
2350         }
2351         $c->log->debug( "File Uploads are:\n" . $t->draw );
2352     }
2353 }
2354
2355 =head2 $c->log_request_headers($headers);
2356
2357 Hook method which can be wrapped by plugins to log the request headers.
2358 No-op in the default implementation.
2359
2360 =cut
2361
2362 sub log_request_headers {}
2363
2364 =head2 $c->log_headers($type => $headers)
2365
2366 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2367
2368 =cut
2369
2370 sub log_headers {
2371     my $c       = shift;
2372     my $type    = shift;
2373     my $headers = shift;    # an HTTP::Headers instance
2374
2375     return unless $c->debug;
2376
2377     my $column_width = Catalyst::Utils::term_width() - 28;
2378     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2379     $headers->scan(
2380         sub {
2381             my ( $name, $value ) = @_;
2382             $t->row( $name, $value );
2383         }
2384     );
2385     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2386 }
2387
2388
2389 =head2 $c->prepare_read
2390
2391 Prepares the input for reading.
2392
2393 =cut
2394
2395 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2396
2397 =head2 $c->prepare_request
2398
2399 Prepares the engine request.
2400
2401 =cut
2402
2403 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2404
2405 =head2 $c->prepare_uploads
2406
2407 Prepares uploads.
2408
2409 =cut
2410
2411 sub prepare_uploads {
2412     my $c = shift;
2413
2414     $c->engine->prepare_uploads( $c, @_ );
2415 }
2416
2417 =head2 $c->prepare_write
2418
2419 Prepares the output for writing.
2420
2421 =cut
2422
2423 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2424
2425 =head2 $c->request_class
2426
2427 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2428
2429 =head2 $c->response_class
2430
2431 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2432
2433 =head2 $c->read( [$maxlength] )
2434
2435 Reads a chunk of data from the request body. This method is designed to
2436 be used in a while loop, reading C<$maxlength> bytes on every call.
2437 C<$maxlength> defaults to the size of the request if not specified.
2438
2439 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2440 directly.
2441
2442 Warning: If you use read(), Catalyst will not process the body,
2443 so you will not be able to access POST parameters or file uploads via
2444 $c->request.  You must handle all body parsing yourself.
2445
2446 =cut
2447
2448 sub read { my $c = shift; return $c->request->read( @_ ) }
2449
2450 =head2 $c->run
2451
2452 Starts the engine.
2453
2454 =cut
2455
2456 sub run {
2457   my $app = shift;
2458   $app->_make_immutable_if_needed;
2459   $app->engine_loader->needs_psgi_engine_compat_hack ?
2460     $app->engine->run($app, @_) :
2461       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2462 }
2463
2464 sub _make_immutable_if_needed {
2465     my $class = shift;
2466     my $meta = Class::MOP::get_metaclass_by_name($class);
2467     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2468     if (
2469         $meta->is_immutable
2470         && ! { $meta->immutable_options }->{replace_constructor}
2471         && $isa_ca
2472     ) {
2473         warn("You made your application class ($class) immutable, "
2474             . "but did not inline the\nconstructor. "
2475             . "This will break catalyst, as your app \@ISA "
2476             . "Class::Accessor(::Fast)?\nPlease pass "
2477             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2478     }
2479     unless ($meta->is_immutable) {
2480         # XXX - FIXME warning here as you should make your app immutable yourself.
2481         $meta->make_immutable(
2482             replace_constructor => 1,
2483         );
2484     }
2485 }
2486
2487 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2488
2489 Sets an action in a given namespace.
2490
2491 =cut
2492
2493 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2494
2495 =head2 $c->setup_actions($component)
2496
2497 Sets up actions for a component.
2498
2499 =cut
2500
2501 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2502
2503 =head2 $c->setup_components
2504
2505 This method is called internally to set up the application's components.
2506
2507 It finds modules by calling the L<locate_components> method, expands them to
2508 package names with the L<expand_component_module> method, and then installs
2509 each component into the application.
2510
2511 The C<setup_components> config option is passed to both of the above methods.
2512
2513 Installation of each component is performed by the L<setup_component> method,
2514 below.
2515
2516 =cut
2517
2518 sub setup_components {
2519     my $class = shift;
2520
2521     my $config  = $class->config->{ setup_components };
2522
2523     my @comps = $class->locate_components($config);
2524     my %comps = map { $_ => 1 } @comps;
2525
2526     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2527     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2528         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2529     ) if $deprecatedcatalyst_component_names;
2530
2531     for my $component ( @comps ) {
2532
2533         # We pass ignore_loaded here so that overlay files for (e.g.)
2534         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2535         # we know M::P::O found a file on disk so this is safe
2536
2537         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2538     }
2539
2540     for my $component (@comps) {
2541         my $instance = $class->components->{ $component } = $class->setup_component($component);
2542         my @expanded_components = $instance->can('expand_modules')
2543             ? $instance->expand_modules( $component, $config )
2544             : $class->expand_component_module( $component, $config );
2545         for my $component (@expanded_components) {
2546             next if $comps{$component};
2547             $class->components->{ $component } = $class->setup_component($component);
2548         }
2549     }
2550 }
2551
2552 =head2 $c->locate_components( $setup_component_config )
2553
2554 This method is meant to provide a list of component modules that should be
2555 setup for the application.  By default, it will use L<Module::Pluggable>.
2556
2557 Specify a C<setup_components> config option to pass additional options directly
2558 to L<Module::Pluggable>. To add additional search paths, specify a key named
2559 C<search_extra> as an array reference. Items in the array beginning with C<::>
2560 will have the application class name prepended to them.
2561
2562 =cut
2563
2564 sub locate_components {
2565     my $class  = shift;
2566     my $config = shift;
2567
2568     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2569     my $extra   = delete $config->{ search_extra } || [];
2570
2571     push @paths, @$extra;
2572
2573     my $locator = Module::Pluggable::Object->new(
2574         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2575         %$config
2576     );
2577
2578     # XXX think about ditching this sort entirely
2579     my @comps = sort { length $a <=> length $b } $locator->plugins;
2580
2581     return @comps;
2582 }
2583
2584 =head2 $c->expand_component_module( $component, $setup_component_config )
2585
2586 Components found by C<locate_components> will be passed to this method, which
2587 is expected to return a list of component (package) names to be set up.
2588
2589 =cut
2590
2591 sub expand_component_module {
2592     my ($class, $module) = @_;
2593     return Devel::InnerPackage::list_packages( $module );
2594 }
2595
2596 =head2 $c->setup_component
2597
2598 =cut
2599
2600 sub setup_component {
2601     my( $class, $component ) = @_;
2602
2603     unless ( $component->can( 'COMPONENT' ) ) {
2604         return $component;
2605     }
2606
2607     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2608     my $config = $class->config->{ $suffix } || {};
2609     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2610     # methods also pass it. local to avoid pointlessly shitting in config
2611     # for the debug screen, as $component is already the key name.
2612     local $config->{catalyst_component_name} = $component;
2613
2614     my $instance = eval { $component->COMPONENT( $class, $config ); };
2615
2616     if ( my $error = $@ ) {
2617         chomp $error;
2618         Catalyst::Exception->throw(
2619             message => qq/Couldn't instantiate component "$component", "$error"/
2620         );
2621     }
2622
2623     unless (blessed $instance) {
2624         my $metaclass = Moose::Util::find_meta($component);
2625         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2626         my $component_method_from = $method_meta->associated_metaclass->name;
2627         my $value = defined($instance) ? $instance : 'undef';
2628         Catalyst::Exception->throw(
2629             message =>
2630             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2631         );
2632     }
2633     return $instance;
2634 }
2635
2636 =head2 $c->setup_dispatcher
2637
2638 Sets up dispatcher.
2639
2640 =cut
2641
2642 sub setup_dispatcher {
2643     my ( $class, $dispatcher ) = @_;
2644
2645     if ($dispatcher) {
2646         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2647     }
2648
2649     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2650         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2651     }
2652
2653     unless ($dispatcher) {
2654         $dispatcher = $class->dispatcher_class;
2655     }
2656
2657     Class::MOP::load_class($dispatcher);
2658
2659     # dispatcher instance
2660     $class->dispatcher( $dispatcher->new );
2661 }
2662
2663 =head2 $c->setup_engine
2664
2665 Sets up engine.
2666
2667 =cut
2668
2669 sub engine_class {
2670     my ($class, $requested_engine) = @_;
2671
2672     if (!$class->engine_loader || $requested_engine) {
2673         $class->engine_loader(
2674             Catalyst::EngineLoader->new({
2675                 application_name => $class,
2676                 (defined $requested_engine
2677                      ? (catalyst_engine_class => $requested_engine) : ()),
2678             }),
2679         );
2680     }
2681
2682     $class->engine_loader->catalyst_engine_class;
2683 }
2684
2685 sub setup_engine {
2686     my ($class, $requested_engine) = @_;
2687
2688     my $engine = do {
2689         my $loader = $class->engine_loader;
2690
2691         if (!$loader || $requested_engine) {
2692             $loader = Catalyst::EngineLoader->new({
2693                 application_name => $class,
2694                 (defined $requested_engine
2695                      ? (requested_engine => $requested_engine) : ()),
2696             }),
2697
2698             $class->engine_loader($loader);
2699         }
2700
2701         $loader->catalyst_engine_class;
2702     };
2703
2704     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2705     return if $class->loading_psgi_file;
2706
2707     Class::MOP::load_class($engine);
2708
2709     if ($ENV{MOD_PERL}) {
2710         my $apache = $class->engine_loader->auto;
2711
2712         my $meta = find_meta($class);
2713         my $was_immutable = $meta->is_immutable;
2714         my %immutable_options = $meta->immutable_options;
2715         $meta->make_mutable if $was_immutable;
2716
2717         $meta->add_method(handler => sub {
2718             my $r = shift;
2719             my $psgi_app = $class->_finalized_psgi_app;
2720             $apache->call_app($r, $psgi_app);
2721         });
2722
2723         $meta->make_immutable(%immutable_options) if $was_immutable;
2724     }
2725
2726     $class->engine( $engine->new );
2727
2728     return;
2729 }
2730
2731 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2732 ## build in server support (back compat support for pre psgi port behavior).
2733 ## This is so that we don't build a new psgi app for each request when using
2734 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2735
2736 sub _finalized_psgi_app {
2737     my ($app) = @_;
2738
2739     unless ($app->_psgi_app) {
2740         my $psgi_app = $app->_setup_psgi_app;
2741         $app->_psgi_app($psgi_app);
2742     }
2743
2744     return $app->_psgi_app;
2745 }
2746
2747 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2748 ## home directory and load that and return it (just assume it is doing the
2749 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2750 ## in default_middleware and return it ( this is for backward compatibility
2751 ## with pre psgi port behavior ).
2752
2753 sub _setup_psgi_app {
2754     my ($app) = @_;
2755
2756     for my $home (Path::Class::Dir->new($app->config->{home})) {
2757         my $psgi_file = $home->file(
2758             Catalyst::Utils::appprefix($app) . '.psgi',
2759         );
2760
2761         next unless -e $psgi_file;
2762
2763         # If $psgi_file calls ->setup_engine, it's doing so to load
2764         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2765         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2766         # anyway. So set a flag (ick) that tells setup_engine not to populate
2767         # $c->engine or do any other things we might regret.
2768
2769         $app->loading_psgi_file(1);
2770         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2771         $app->loading_psgi_file(0);
2772
2773         return $psgi_app
2774             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2775
2776         warn <<"EOW";
2777 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2778
2779 Its content has been ignored. Please consult the Catalyst::Upgrading
2780 documentation on how to upgrade from Catalyst::Engine::PSGI.
2781 EOW
2782     }
2783
2784     return $app->apply_default_middlewares($app->psgi_app);
2785 }
2786
2787 =head2 $c->apply_default_middlewares
2788
2789 Adds the following L<Plack> middlewares to your application, since they are
2790 useful and commonly needed:
2791
2792 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2793 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2794 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2795 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2796 applied since this middleware is smart enough to conditionally apply itself).
2797
2798 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2799 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2800 $ENV{SCRIPT_NAME}
2801
2802 =cut
2803
2804
2805 sub apply_default_middlewares {
2806     my ($app, $psgi_app) = @_;
2807
2808     $psgi_app = Plack::Middleware::Conditional->wrap(
2809         $psgi_app,
2810         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2811         condition => sub {
2812             my ($env) = @_;
2813             return if $app->config->{ignore_frontend_proxy};
2814             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2815                 || $app->config->{using_frontend_proxy};
2816         },
2817     );
2818
2819     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2820     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2821     $psgi_app = Plack::Middleware::Conditional->wrap(
2822         $psgi_app,
2823         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2824         condition => sub {
2825             my ($env) = @_;
2826             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2827             return unless $1 < 4.23;
2828             1;
2829         },
2830     );
2831
2832     # we're applying this unconditionally as the middleware itself already makes
2833     # sure it doesn't fuck things up if it's not running under one of the right
2834     # IIS versions
2835     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2836
2837     # And another IIS issue, this time with IIS7.
2838     $psgi_app = Plack::Middleware::Conditional->wrap(
2839         $psgi_app,
2840         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2841         condition => sub {
2842             my ($env) = @_;
2843             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2844         },
2845     );
2846
2847     return $psgi_app;
2848 }
2849
2850 =head2 $c->psgi_app
2851
2852 Returns a PSGI application code reference for the catalyst application
2853 C<$c>. This is the bare application without any middlewares
2854 applied. C<${myapp}.psgi> is not taken into account.
2855
2856 This is what you want to be using to retrieve the PSGI application code
2857 reference of your Catalyst application for use in F<.psgi> files.
2858
2859 =cut
2860
2861 sub psgi_app {
2862     my ($app) = @_;
2863     return $app->engine->build_psgi_app($app);
2864 }
2865
2866 =head2 $c->setup_home
2867
2868 Sets up the home directory.
2869
2870 =cut
2871
2872 sub setup_home {
2873     my ( $class, $home ) = @_;
2874
2875     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2876         $home = $env;
2877     }
2878
2879     $home ||= Catalyst::Utils::home($class);
2880
2881     if ($home) {
2882         #I remember recently being scolded for assigning config values like this
2883         $class->config->{home} ||= $home;
2884         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2885     }
2886 }
2887
2888 =head2 $c->setup_log
2889
2890 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2891 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2892 log to.
2893
2894 This method also installs a C<debug> method that returns a true value into the
2895 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2896 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2897
2898 Note that if the log has already been setup, by either a previous call to
2899 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2900 that this method won't actually set up the log object.
2901
2902 =cut
2903
2904 sub setup_log {
2905     my ( $class, $levels ) = @_;
2906
2907     $levels ||= '';
2908     $levels =~ s/^\s+//;
2909     $levels =~ s/\s+$//;
2910     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2911
2912     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2913     if ( defined $env_debug ) {
2914         $levels{debug} = 1 if $env_debug; # Ugly!
2915         delete($levels{debug}) unless $env_debug;
2916     }
2917
2918     unless ( $class->log ) {
2919         $class->log( Catalyst::Log->new(keys %levels) );
2920     }
2921
2922     if ( $levels{debug} ) {
2923         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2924         $class->log->debug('Debug messages enabled');
2925     }
2926 }
2927
2928 =head2 $c->setup_plugins
2929
2930 Sets up plugins.
2931
2932 =cut
2933
2934 =head2 $c->setup_stats
2935
2936 Sets up timing statistics class.
2937
2938 =cut
2939
2940 sub setup_stats {
2941     my ( $class, $stats ) = @_;
2942
2943     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2944
2945     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2946     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2947         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2948         $class->log->debug('Statistics enabled');
2949     }
2950 }
2951
2952
2953 =head2 $c->registered_plugins
2954
2955 Returns a sorted list of the plugins which have either been stated in the
2956 import list.
2957
2958 If passed a given plugin name, it will report a boolean value indicating
2959 whether or not that plugin is loaded.  A fully qualified name is required if
2960 the plugin name does not begin with C<Catalyst::Plugin::>.
2961
2962  if ($c->registered_plugins('Some::Plugin')) {
2963      ...
2964  }
2965
2966 =cut
2967
2968 {
2969
2970     sub registered_plugins {
2971         my $proto = shift;
2972         return sort keys %{ $proto->_plugins } unless @_;
2973         my $plugin = shift;
2974         return 1 if exists $proto->_plugins->{$plugin};
2975         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2976     }
2977
2978     sub _register_plugin {
2979         my ( $proto, $plugin, $instant ) = @_;
2980         my $class = ref $proto || $proto;
2981
2982         Class::MOP::load_class( $plugin );
2983         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2984             if $plugin->isa( 'Catalyst::Component' );
2985         my $plugin_meta = Moose::Meta::Class->create($plugin);
2986         if (!$plugin_meta->has_method('new')
2987             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
2988             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
2989         }
2990         if (!$instant && !$proto->_plugins->{$plugin}) {
2991             my $meta = Class::MOP::get_metaclass_by_name($class);
2992             $meta->superclasses($plugin, $meta->superclasses);
2993         }
2994         $proto->_plugins->{$plugin} = 1;
2995         return $class;
2996     }
2997
2998     sub _default_plugins { return qw(Unicode::Encoding) }
2999
3000     sub setup_plugins {
3001         my ( $class, $plugins ) = @_;
3002
3003         $class->_plugins( {} ) unless $class->_plugins;
3004         $plugins = [ grep {
3005             m/Unicode::Encoding/ ? do {
3006                 $class->log->warn(
3007                     'Unicode::Encoding plugin is auto-applied,'
3008                     . ' please remove this from your appclass'
3009                     . ' and make sure to define "encoding" config'
3010                 );
3011                 unless (exists $class->config->{'encoding'}) {
3012                   $class->config->{'encoding'} = 'UTF-8';
3013                 }
3014                 () }
3015                 : $_
3016         } @$plugins ];
3017         push @$plugins, $class->_default_plugins;
3018         $plugins = Data::OptList::mkopt($plugins || []);
3019
3020         my @plugins = map {
3021             [ Catalyst::Utils::resolve_namespace(
3022                   $class . '::Plugin',
3023                   'Catalyst::Plugin', $_->[0]
3024               ),
3025               $_->[1],
3026             ]
3027          } @{ $plugins };
3028
3029         for my $plugin ( reverse @plugins ) {
3030             Class::MOP::load_class($plugin->[0], $plugin->[1]);
3031             my $meta = find_meta($plugin->[0]);
3032             next if $meta && $meta->isa('Moose::Meta::Role');
3033
3034             $class->_register_plugin($plugin->[0]);
3035         }
3036
3037         my @roles =
3038             map  { $_->[0]->name, $_->[1] }
3039             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3040             map  { [find_meta($_->[0]), $_->[1]] }
3041             @plugins;
3042
3043         Moose::Util::apply_all_roles(
3044             $class => @roles
3045         ) if @roles;
3046     }
3047 }
3048
3049 has '_registered_middlewares' => (
3050     traits => ['Array'],
3051     is => 'bare',
3052     isa => 'ArrayRef[Object|CodeRef]',
3053     default => sub { [] },
3054     handles => {
3055         registered_middlewares => 'elements',
3056         _register_middleware => 'push',
3057     });
3058
3059
3060 =head2 setup_middleware
3061
3062 Read configuration information stored in configuration key 'psgi_middleware'
3063 and invoke L</register_middleware> for each middleware prototype found.  See
3064 under L</CONFIGURATION> information regarding L</psgi_middleware> and how to
3065 use it to enable L<Plack::Middleware>
3066
3067 This method is automatically called during 'setup' of your application, so
3068 you really don't need to invoke it.
3069
3070 When we read middleware definitions from configuration, we reverse the list
3071 which sounds odd but is likely how you expect it to work if you have prior
3072 experience with L<Plack::Builder> or if you previously used the plugin
3073 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3074
3075 =head2 register_middleware (@args)
3076
3077 Given @args that represent the definition of some L<Plack::Middleware> or
3078 middleware with a compatible interface, register it with your L<Catalyst>
3079 application.
3080
3081 This is called by L</setup_middleware>.  the behavior of invoking it yourself
3082 at run time is currently undefined, and anything that works or doesn't work
3083 as a result of doing so is considered a side effect subject to change.
3084
3085 =head2 _register_middleware (@args)
3086
3087 Internal details of how registered middleware is stored by the application.
3088
3089 =head2 _build_middleware_from_args (@args)
3090
3091 Internal application that converts a single middleware definition (see
3092 L</psgi_middleware>) into an actual instance of middleware.
3093
3094 =head2 registered_middlewares
3095
3096 Read only accessor that returns an array of all the middleware in the order
3097 that they were added (which is the REVERSE of the order they will be applied).
3098
3099 The values returned will be either instances of L<Plack::Middleware> or of a
3100 compatible interface, or a coderef, which is assumed to be inlined middleware
3101
3102 =head2 apply_registered_middleware ($psgi)
3103
3104 Given a $psgi reference, wrap all the L<registered_middlewares> around it and
3105 return the wrapped version.
3106
3107 =cut
3108
3109 sub setup_middleware {
3110     my ($self) = @_;
3111     my @middleware_definitions = reverse
3112       @{$self->config->{'psgi_middleware'}||[]};
3113
3114     while(my $next = shift(@middleware_definitions)) {
3115         if(ref $next) {
3116             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3117                 $self->register_middleware($next);
3118             } elsif(ref $next eq 'CODE') {
3119                 $self->register_middleware($next);
3120             } elsif(ref $next eq 'HASH') {
3121                 my $namespace = shift @middleware_definitions;
3122                 $self->register_middleware($namespace, %$next);
3123             } else {
3124                 $self->register_middleware($next);
3125             }
3126         }
3127     }
3128 }
3129
3130 sub register_middleware {
3131     my($self, @args) = @_;
3132     my $middleware = $self->_build_middleware_from_args(@args);
3133     $self->_register_middleware($middleware);
3134     return $middleware;
3135 }
3136
3137 sub _build_middleware_from_args {
3138     my ($self, $proto, @args) = @_;
3139
3140     if(ref $proto) { ## Either an object or coderef
3141       if(Scalar::Util::blessed $proto && $proto->can('wrap')) {  ## Its already an instance of middleware
3142         return $proto;
3143       } elsif(ref $proto eq 'CODE') { ## Its inlined coderef
3144         return $proto;
3145       }
3146     } else { ## We assume its a string aiming to load Plack Middleware
3147         my $class = ref($self) || $self;
3148         if(
3149           $proto =~s/^\+// ||
3150           $proto =~/^Plack::Middleware/ ||
3151           $proto =~/^$class/
3152         ) {  ## the string is a full namespace
3153             require "$proto";
3154             return $proto->new(@args);
3155         } else { ## the string is a partial namespace
3156             if(Class::Load::try_load_class("Plack::Middleware::$proto")) { ## Act like Plack::Builder
3157                 return "Plack::Middleware::$proto"->new(@args);
3158             } elsif(Class::Load::try_load_class("$class::$proto")) { ## Load Middleware from Project namespace
3159                 return "$class::$proto"->new(@args);
3160             }
3161         }
3162     }
3163
3164     die "I don't know how to build $proto into valid Plack Middleware";
3165 }
3166
3167 sub apply_registered_middleware {
3168     my ($self, $psgi) = @_;
3169     my $new_psgi = $psgi;
3170     foreach my $middleware ($self->registered_middlewares) {
3171         $new_psgi = Scalar::Util::blessed $middleware ?
3172           $middleware->wrap($new_psgi) :
3173             $middleware->($new_psgi);
3174     }
3175     return $new_psgi;
3176 }
3177
3178 =head2 $c->stack
3179
3180 Returns an arrayref of the internal execution stack (actions that are
3181 currently executing).
3182
3183 =head2 $c->stats
3184
3185 Returns the current timing statistics object. By default Catalyst uses
3186 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3187 L<< stats_class|/"$c->stats_class" >>.
3188
3189 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3190 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3191 profile explicitly, although MyApp.pm still won't profile nor output anything
3192 by itself.
3193
3194 =head2 $c->stats_class
3195
3196 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3197
3198 =head2 $c->use_stats
3199
3200 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3201
3202 Note that this is a static method, not an accessor and should be overridden
3203 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3204
3205 =cut
3206
3207 sub use_stats { 0 }
3208
3209
3210 =head2 $c->write( $data )
3211
3212 Writes $data to the output stream. When using this method directly, you
3213 will need to manually set the C<Content-Length> header to the length of
3214 your output data, if known.
3215
3216 =cut
3217
3218 sub write {
3219     my $c = shift;
3220
3221     # Finalize headers if someone manually writes output (for compat)
3222     $c->finalize_headers;
3223
3224     return $c->response->write( @_ );
3225 }
3226
3227 =head2 version
3228
3229 Returns the Catalyst version number. Mostly useful for "powered by"
3230 messages in template systems.
3231
3232 =cut
3233
3234 sub version { return $Catalyst::VERSION }
3235
3236 =head1 CONFIGURATION
3237
3238 There are a number of 'base' config variables which can be set:
3239
3240 =over
3241
3242 =item *
3243
3244 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3245
3246 =item *
3247
3248 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3249
3250 =item *
3251
3252 C<disable_component_resolution_regex_fallback> - Turns
3253 off the deprecated component resolution functionality so
3254 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3255 are called then regex search will not be attempted on string values and
3256 instead C<undef> will be returned.
3257
3258 =item *
3259
3260 C<home> - The application home directory. In an uninstalled application,
3261 this is the top level application directory. In an installed application,
3262 this will be the directory containing C<< MyApp.pm >>.
3263
3264 =item *
3265
3266 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3267
3268 =item *
3269
3270 C<name> - The name of the application in debug messages and the debug and
3271 welcome screens
3272
3273 =item *
3274
3275 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3276 until it is accessed. This allows you to (for example) check authentication (and reject
3277 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3278
3279 =item *
3280
3281 C<root> - The root directory for templates. Usually this is just a
3282 subdirectory of the home directory, but you can set it to change the
3283 templates to a different directory.
3284
3285 =item *
3286
3287 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3288 namespaces from which components will be loaded (and constructed and stored in
3289 C<< $c->components >>).
3290
3291 =item *
3292
3293 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3294 to be shown in hit debug tables in the test server.
3295
3296 =item *
3297
3298 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3299 variable should be used for determining the request path.
3300
3301 Most web server environments pass the requested path to the application using environment variables,
3302 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3303 exposed as C<< $c->request->base >>) and the request path below that base.
3304
3305 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3306 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3307
3308 =over
3309
3310 =item use_request_uri_for_path => 0
3311
3312 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3313 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3314 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3315 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3316
3317 However this method has the major disadvantage that it is impossible to correctly decode some elements
3318 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3319 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3320 can't distinguish / vs %2F in paths (in addition to other encoded values).
3321
3322 =item use_request_uri_for_path => 1
3323
3324 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3325 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3326 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3327
3328 Given that this method of path resolution is provably more correct, it is recommended that you use
3329 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3330 aware of the implications of not being able to handle encoded URI paths correctly.
3331
3332 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3333 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3334 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3335 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3336 C<< $c->request->base >> will be incorrect.
3337
3338 =back
3339
3340 =item *
3341
3342 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3343
3344 =item *
3345
3346 C<encoding> - See L</ENCODING>
3347
3348 =item *
3349
3350 C<abort_chain_on_error_fix>
3351
3352 When there is an error in an action chain, the default behavior is to continue
3353 processing the remaining actions and then catch the error upon chain end.  This
3354 can lead to running actions when the application is in an unexpected state.  If
3355 you have this issue, setting this config value to true will promptly exit a
3356 chain when there is an error raised in any action (thus terminating the chain
3357 early.)
3358
3359 use like:
3360
3361     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3362
3363 In the future this might become the default behavior.
3364
3365 =item *
3366
3367 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3368
3369 =back
3370
3371 =head1 INTERNAL ACTIONS
3372
3373 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3374 C<_ACTION>, and C<_END>. These are by default not shown in the private
3375 action table, but you can make them visible with a config parameter.
3376
3377     MyApp->config(show_internal_actions => 1);
3378
3379 =head1 ON-DEMAND PARSER
3380
3381 The request body is usually parsed at the beginning of a request,
3382 but if you want to handle input yourself, you can enable on-demand
3383 parsing with a config parameter.
3384
3385     MyApp->config(parse_on_demand => 1);
3386
3387 =head1 PROXY SUPPORT
3388
3389 Many production servers operate using the common double-server approach,
3390 with a lightweight frontend web server passing requests to a larger
3391 backend server. An application running on the backend server must deal
3392 with two problems: the remote user always appears to be C<127.0.0.1> and
3393 the server's hostname will appear to be C<localhost> regardless of the
3394 virtual host that the user connected through.
3395
3396 Catalyst will automatically detect this situation when you are running
3397 the frontend and backend servers on the same machine. The following
3398 changes are made to the request.
3399
3400     $c->req->address is set to the user's real IP address, as read from
3401     the HTTP X-Forwarded-For header.
3402
3403     The host value for $c->req->base and $c->req->uri is set to the real
3404     host, as read from the HTTP X-Forwarded-Host header.
3405
3406 Additionally, you may be running your backend application on an insecure
3407 connection (port 80) while your frontend proxy is running under SSL.  If there
3408 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3409 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3410 be created properly.
3411
3412 In the case of passing in:
3413
3414     X-Forwarded-Port: 443
3415
3416 All calls to C<uri_for> will result in an https link, as is expected.
3417
3418 Obviously, your web server must support these headers for this to work.
3419
3420 In a more complex server farm environment where you may have your
3421 frontend proxy server(s) on different machines, you will need to set a
3422 configuration option to tell Catalyst to read the proxied data from the
3423 headers.
3424
3425     MyApp->config(using_frontend_proxy => 1);
3426
3427 If you do not wish to use the proxy support at all, you may set:
3428
3429     MyApp->config(ignore_frontend_proxy => 0);
3430
3431 =head2 Note about psgi files
3432
3433 Note that if you supply your own .psgi file, calling
3434 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3435
3436 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3437 in your psgi, for example:
3438
3439     builder {
3440         enable "Plack::Middleware::ReverseProxy";
3441         MyApp->psgi_app
3442     };
3443
3444 This will unconditionally add the ReverseProxy support, or you need to call
3445 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3446 apply the support depending upon your config).
3447
3448 See L<Catalyst::PSGI> for more information.
3449
3450 =head1 THREAD SAFETY
3451
3452 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3453 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3454 believe the Catalyst core to be thread-safe.
3455
3456 If you plan to operate in a threaded environment, remember that all other
3457 modules you are using must also be thread-safe. Some modules, most notably
3458 L<DBD::SQLite>, are not thread-safe.
3459
3460 =head1 PSGI MIDDLEWARE
3461
3462 You can define middleware, defined as L<Plack::Middleware> or a compatible
3463 interface in configuration.  Your middleware definitions are in the form of an
3464 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3465 with details to follow:
3466
3467     package MyApp::Web;
3468
3469     use Catalyst;
3470     use Plack::Middleware::StackTrace;
3471
3472     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3473
3474     __PACKAGE__->config(
3475       'psgi_middleware', [
3476         'Debug',
3477         '+MyApp::Custom',
3478         $stacktrace_middleware,
3479         'Session' => {store => 'File'},
3480         sub {
3481           my $app = shift;
3482           return sub {
3483             my $env = shift;
3484             $env->{myapp.customkey} = 'helloworld';
3485             $app->($env);
3486           },
3487         },
3488       ],
3489     );
3490
3491     __PACKAGE__->setup;
3492
3493 So the general form is:
3494
3495     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3496
3497 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3498 the order listed (to make it function similarly to L<Plack::Builder>:
3499
3500 =over 4
3501
3502 =item Middleware Object
3503
3504 An already initialized object that conforms to the L<Plack::Middleware>
3505 specification:
3506
3507     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3508
3509     __PACKAGE__->config(
3510       'psgi_middleware', [
3511         $stacktrace_middleware,
3512       ]);
3513
3514
3515 =item coderef
3516
3517 A coderef that is an inlined middleware:
3518
3519     __PACKAGE__->config(
3520       'psgi_middleware', [
3521         sub {
3522           my $app = shift;
3523           return sub {
3524             my $env = shift;
3525             if($env->{PATH_INFO} =~m/forced/) {
3526               Plack::App::File
3527                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3528                 ->call($env);
3529             } else {
3530               return $app->($env);
3531             }
3532          },
3533       },
3534     ]);
3535
3536
3537
3538 =item a scalar
3539
3540 We assume the scalar refers to a namespace after normalizing it using the
3541 following rules:
3542
3543 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3544 is assumed to be 'as is', and we just install and use the middleware.
3545
3546 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3547 (the package name of your Catalyst application subclass), we also assume then
3548 that it is a full namespace, and use it.
3549
3550 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3551 resolve it first by looking for it under your application namespace (for example
3552 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3553 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3554 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3555 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3556 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3557 you find that a good idea.
3558
3559 Examples:
3560
3561     package MyApp::Web;
3562
3563     __PACKAGE__->config(
3564       'psgi_middleware', [
3565         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3566         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3567         '+MyApp::Custom',  ## MyApp::Custom->wrap
3568       ],
3569     );
3570
3571 =item a scalar followed by a hashref
3572
3573 Just like the previous, except the following C<HashRef> is used as arguments
3574 to initialize the middleware object.
3575
3576     __PACKAGE__->config(
3577       'psgi_middleware', [
3578          'Session' => {store => 'File'},
3579     ]);
3580
3581 =back
3582
3583 Please see L<PSGI> for more on middleware.
3584
3585 =head1 ENCODING
3586
3587 On request, decodes all params from encoding into a sequence of
3588 logical characters. On response, encodes body into encoding.
3589
3590 =head2 Methods
3591
3592 =over 4
3593
3594 =item encoding
3595
3596 Returns an instance of an C<Encode> encoding
3597
3598     print $c->encoding->name
3599
3600 =item handle_unicode_encoding_exception ($exception_context)
3601
3602 Method called when decoding process for a request fails.
3603
3604 An C<$exception_context> hashref is provided to allow you to override the
3605 behaviour of your application when given data with incorrect encodings.
3606
3607 The default method throws exceptions in the case of invalid request parameters
3608 (resulting in a 500 error), but ignores errors in upload filenames.
3609
3610 The keys passed in the C<$exception_context> hash are:
3611
3612 =over
3613
3614 =item param_value
3615
3616 The value which was not able to be decoded.
3617
3618 =item error_msg
3619
3620 The exception received from L<Encode>.
3621
3622 =item encoding_step
3623
3624 What type of data was being decoded. Valid values are (currently)
3625 C<params> - for request parameters / arguments / captures
3626 and C<uploads> - for request upload filenames.
3627
3628 =back
3629
3630 =back
3631
3632 =head1 SUPPORT
3633
3634 IRC:
3635
3636     Join #catalyst on irc.perl.org.
3637
3638 Mailing Lists:
3639
3640     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3641     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3642
3643 Web:
3644
3645     http://catalyst.perl.org
3646
3647 Wiki:
3648
3649     http://dev.catalyst.perl.org
3650
3651 =head1 SEE ALSO
3652
3653 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3654
3655 =head2 L<Catalyst::Manual> - The Catalyst Manual
3656
3657 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3658
3659 =head2 L<Catalyst::Engine> - Core engine
3660
3661 =head2 L<Catalyst::Log> - Log class.
3662
3663 =head2 L<Catalyst::Request> - Request object
3664
3665 =head2 L<Catalyst::Response> - Response object
3666
3667 =head2 L<Catalyst::Test> - The test suite.
3668
3669 =head1 PROJECT FOUNDER
3670
3671 sri: Sebastian Riedel <sri@cpan.org>
3672
3673 =head1 CONTRIBUTORS
3674
3675 abw: Andy Wardley
3676
3677 acme: Leon Brocard <leon@astray.com>
3678
3679 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3680
3681 Andrew Bramble
3682
3683 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3684
3685 Andrew Ruthven
3686
3687 andyg: Andy Grundman <andy@hybridized.org>
3688
3689 audreyt: Audrey Tang
3690
3691 bricas: Brian Cassidy <bricas@cpan.org>
3692
3693 Caelum: Rafael Kitover <rkitover@io.com>
3694
3695 chansen: Christian Hansen
3696
3697 chicks: Christopher Hicks
3698
3699 Chisel Wright C<pause@herlpacker.co.uk>
3700
3701 Danijel Milicevic C<me@danijel.de>
3702
3703 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3704
3705 David Naughton, C<naughton@umn.edu>
3706
3707 David E. Wheeler
3708
3709 dhoss: Devin Austin <dhoss@cpan.org>
3710
3711 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3712
3713 Drew Taylor
3714
3715 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3716
3717 esskar: Sascha Kiefer
3718
3719 fireartist: Carl Franks <cfranks@cpan.org>
3720
3721 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3722
3723 gabb: Danijel Milicevic
3724
3725 Gary Ashton Jones
3726
3727 Gavin Henry C<ghenry@perl.me.uk>
3728
3729 Geoff Richards
3730
3731 groditi: Guillermo Roditi <groditi@gmail.com>
3732
3733 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3734
3735 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3736
3737 jcamacho: Juan Camacho
3738
3739 jester: Jesse Sheidlower C<jester@panix.com>
3740
3741 jhannah: Jay Hannah <jay@jays.net>
3742
3743 Jody Belka
3744
3745 Johan Lindstrom
3746
3747 jon: Jon Schutz <jjschutz@cpan.org>
3748
3749 Jonathan Rockway C<< <jrockway@cpan.org> >>
3750
3751 Kieren Diment C<kd@totaldatasolution.com>
3752
3753 konobi: Scott McWhirter <konobi@cpan.org>
3754
3755 marcus: Marcus Ramberg <mramberg@cpan.org>
3756
3757 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3758
3759 mgrimes: Mark Grimes <mgrimes@cpan.org>
3760
3761 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3762
3763 mugwump: Sam Vilain
3764
3765 naughton: David Naughton
3766
3767 ningu: David Kamholz <dkamholz@cpan.org>
3768
3769 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3770
3771 numa: Dan Sully <daniel@cpan.org>
3772
3773 obra: Jesse Vincent
3774
3775 Octavian Rasnita
3776
3777 omega: Andreas Marienborg
3778
3779 Oleg Kostyuk <cub.uanic@gmail.com>
3780
3781 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3782
3783 rafl: Florian Ragwitz <rafl@debian.org>
3784
3785 random: Roland Lammel <lammel@cpan.org>
3786
3787 Robert Sedlacek C<< <rs@474.at> >>
3788
3789 SpiceMan: Marcel Montes
3790
3791 sky: Arthur Bergman
3792
3793 szbalint: Balint Szilakszi <szbalint@cpan.org>
3794
3795 t0m: Tomas Doran <bobtfish@bobtfish.net>
3796
3797 Ulf Edvinsson
3798
3799 Viljo Marrandi C<vilts@yahoo.com>
3800
3801 Will Hawes C<info@whawes.co.uk>
3802
3803 willert: Sebastian Willert <willert@cpan.org>
3804
3805 wreis: Wallace Reis <wreis@cpan.org>
3806
3807 Yuval Kogman, C<nothingmuch@woobling.org>
3808
3809 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3810
3811 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3812
3813 =head1 COPYRIGHT
3814
3815 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3816
3817 =head1 LICENSE
3818
3819 This library is free software. You can redistribute it and/or modify it under
3820 the same terms as Perl itself.
3821
3822 =cut
3823
3824 no Moose;
3825
3826 __PACKAGE__->meta->make_immutable;
3827
3828 1;