lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use File::stat;
  19 use Text::SimpleTable ();
  20 use Path::Class::Dir ();
  21 use Path::Class::File ();
  22 use URI ();
  23 use URI::http;
  24 use URI::https;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use Class::C3::Adopt::NEXT;
  28 use List::MoreUtils qw/uniq/;
  29 use attributes;
  30 use String::RewritePrefix;
  31 use Catalyst::EngineLoader;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34 use Try::Tiny;
  35 use Plack::Middleware::Conditional;
  36 use Plack::Middleware::ReverseProxy;
  37 use Plack::Middleware::IIS6ScriptNameFix;
  38 use Plack::Middleware::LighttpdScriptNameFix;
  39
  40 BEGIN { require 5.008003; }
  41
  42 has stack => (is => 'ro', default => sub { [] });
  43 has stash => (is => 'rw', default => sub { {} });
  44 has state => (is => 'rw', default => 0);
  45 has stats => (is => 'rw');
  46 has action => (is => 'rw');
  47 has counter => (is => 'rw', default => sub { {} });
  48 has request => (
  49     is => 'rw',
  50     default => sub {
  51         my $self = shift;
  52         my %p = ( _log => $self->log );
  53         $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  54         $self->request_class->new(\%p);
  55     },
  56     lazy => 1,
  57 );
  58 has response => (
  59     is => 'rw',
  60     default => sub {
  61         my $self = shift;
  62         $self->response_class->new({ _log => $self->log });
  63     },
  64     lazy => 1,
  65 );
  66 has namespace => (is => 'rw');
  67
  68 sub depth { scalar @{ shift->stack || [] }; }
  69 sub comp { shift->component(@_) }
  70
  71 sub req {
  72     my $self = shift; return $self->request(@_);
  73 }
  74 sub res {
  75     my $self = shift; return $self->response(@_);
  76 }
  77
  78 # For backwards compatibility
  79 sub finalize_output { shift->finalize_body(@_) };
  80
  81 # For statistics
  82 our $COUNT     = 1;
  83 our $START     = time;
  84 our $RECURSION = 1000;
  85 our $DETACH    = Catalyst::Exception::Detach->new;
  86 our $GO        = Catalyst::Exception::Go->new;
  87
  88 #I imagine that very few of these really need to be class variables. if any.
  89 #maybe we should just make them attributes with a default?
  90 __PACKAGE__->mk_classdata($_)
  91   for qw/container arguments dispatcher engine log dispatcher_class
  92   engine_loader context_class request_class response_class stats_class
  93   setup_finished _psgi_app loading_psgi_file run_options/;
  94
  95 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  96 __PACKAGE__->request_class('Catalyst::Request');
  97 __PACKAGE__->response_class('Catalyst::Response');
  98 __PACKAGE__->stats_class('Catalyst::Stats');
  99
 100 # Remember to update this in Catalyst::Runtime as well!
 101
 102 our $VERSION = '5.90015';
 103
 104 sub import {
 105     my ( $class, @arguments ) = @_;
 106
 107     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 108     # callers @ISA.
 109     return unless $class eq 'Catalyst';
 110
 111     my $caller = caller();
 112     return if $caller eq 'main';
 113
 114     my $meta = Moose::Meta::Class->initialize($caller);
 115
 116     unless ( $caller->isa('Catalyst') ) { # XXX - Remove!
 117         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Component'); # XXX - Remove!
 118         $meta->superclasses(@superclasses); # XXX - Remove!
 119     } # XXX - Remove!
 120
 121     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 122     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 123
 124     unless( $meta->has_method('meta') ){
 125         if ($Moose::VERSION >= 1.15) {
 126             $meta->_add_meta_method('meta');
 127         }
 128         else {
 129             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 130         }
 131     }
 132
 133     $caller->arguments( [@arguments] );
 134     $caller->setup_home;
 135 }
 136
 137 sub MODIFY_CODE_ATTRIBUTES {
 138     Catalyst::Exception->throw(
 139         "Catalyst applications (aka MyApp) cannot be controllers anymore. " .
 140         "That has been deprecated and removed. You should create a " .
 141         "controller class called Root.pm, and move relevant code to that class."
 142     );
 143 }
 144
 145
 146 sub _application { $_[0] }
 147
 148 =head1 NAME
 149
 150 Catalyst - The Elegant MVC Web Application Framework
 151
 152 =head1 SYNOPSIS
 153
 154 See the L<Catalyst::Manual> distribution for comprehensive
 155 documentation and tutorials.
 156
 157     # Install Catalyst::Devel for helpers and other development tools
 158     # use the helper to create a new application
 159     catalyst.pl MyApp
 160
 161     # add models, views, controllers
 162     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 163     script/myapp_create.pl view MyTemplate TT
 164     script/myapp_create.pl controller Search
 165
 166     # built in testserver -- use -r to restart automatically on changes
 167     # --help to see all available options
 168     script/myapp_server.pl
 169
 170     # command line testing interface
 171     script/myapp_test.pl /yada
 172
 173     ### in lib/MyApp.pm
 174     use Catalyst qw/-Debug/; # include plugins here as well
 175
 176     ### In lib/MyApp/Controller/Root.pm (autocreated)
 177     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 178         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 179         $c->stash->{template} = 'foo.tt'; # set the template
 180         # lookup something from db -- stash vars are passed to TT
 181         $c->stash->{data} =
 182           $c->model('Database::Foo')->search( { country => $args[0] } );
 183         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 184             $c->forward( 'bar' ); # process another action
 185             # do something else after forward returns
 186         }
 187     }
 188
 189     # The foo.tt TT template can use the stash data from the database
 190     [% WHILE (item = data.next) %]
 191         [% item.foo %]
 192     [% END %]
 193
 194     # called for /bar/of/soap, /bar/of/soap/10, etc.
 195     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 196
 197     # called after all actions are finished
 198     sub end : Action {
 199         my ( $self, $c ) = @_;
 200         if ( scalar @{ $c->error } ) { ... } # handle errors
 201         return if $c->res->body; # already have a response
 202         $c->forward( 'MyApp::View::TT' ); # render template
 203     }
 204
 205 See L<Catalyst::Manual::Intro> for additional information.
 206
 207 =head1 DESCRIPTION
 208
 209 Catalyst is a modern framework for making web applications without the
 210 pain usually associated with this process. This document is a reference
 211 to the main Catalyst application. If you are a new user, we suggest you
 212 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 213
 214 See L<Catalyst::Manual> for more documentation.
 215
 216 Catalyst plugins can be loaded by naming them as arguments to the "use
 217 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 218 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 219 C<My::Module>.
 220
 221     use Catalyst qw/My::Module/;
 222
 223 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 224 fully qualify the name by using a unary plus:
 225
 226     use Catalyst qw/
 227         My::Module
 228         +Fully::Qualified::Plugin::Name
 229     /;
 230
 231 Special flags like C<-Debug> can also be specified as
 232 arguments when Catalyst is loaded:
 233
 234     use Catalyst qw/-Debug My::Module/;
 235
 236 The position of plugins and flags in the chain is important, because
 237 they are loaded in the order in which they appear.
 238
 239 The following flags are supported:
 240
 241 =head2 -Debug
 242
 243 Enables debug output. You can also force this setting from the system
 244 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 245 settings override the application, with <MYAPP>_DEBUG having the highest
 246 priority.
 247
 248 This sets the log level to 'debug' and enables full debug output on the
 249 error screen. If you only want the latter, see L<< $c->debug >>.
 250
 251 =head2 -Home
 252
 253 Forces Catalyst to use a specific home directory, e.g.:
 254
 255     use Catalyst qw[-Home=/usr/mst];
 256
 257 This can also be done in the shell environment by setting either the
 258 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 259 is replaced with the uppercased name of your application, any "::" in
 260 the name will be replaced with underscores, e.g. MyApp::Web should use
 261 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 262
 263 If none of these are set, Catalyst will attempt to automatically detect the
 264 home directory. If you are working in a development environment, Catalyst
 265 will try and find the directory containing either Makefile.PL, Build.PL or
 266 dist.ini. If the application has been installed into the system (i.e.
 267 you have done C<make install>), then Catalyst will use the path to your
 268 application module, without the .pm extension (e.g., /foo/MyApp if your
 269 application was installed at /foo/MyApp.pm)
 270
 271 =head2 -Log
 272
 273     use Catalyst '-Log=warn,fatal,error';
 274
 275 Specifies a comma-delimited list of log levels.
 276
 277 =head2 -Stats
 278
 279 Enables statistics collection and reporting.
 280
 281    use Catalyst qw/-Stats=1/;
 282
 283 You can also force this setting from the system environment with CATALYST_STATS
 284 or <MYAPP>_STATS. The environment settings override the application, with
 285 <MYAPP>_STATS having the highest priority.
 286
 287 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 288
 289 =head1 METHODS
 290
 291 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 292
 293 =head2 $c->action
 294
 295 Returns a L<Catalyst::Action> object for the current action, which
 296 stringifies to the action name. See L<Catalyst::Action>.
 297
 298 =head2 $c->namespace
 299
 300 Returns the namespace of the current action, i.e., the URI prefix
 301 corresponding to the controller of the current action. For example:
 302
 303     # in Controller::Foo::Bar
 304     $c->namespace; # returns 'foo/bar';
 305
 306 =head2 $c->request
 307
 308 =head2 $c->req
 309
 310 Returns the current L<Catalyst::Request> object, giving access to
 311 information about the current client request (including parameters,
 312 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 313
 314 =head2 REQUEST FLOW HANDLING
 315
 316 =head2 $c->forward( $action [, \@arguments ] )
 317
 318 =head2 $c->forward( $class, $method, [, \@arguments ] )
 319
 320 Forwards processing to another action, by its private name. If you give a
 321 class name but no method, C<process()> is called. You may also optionally
 322 pass arguments in an arrayref. The action will receive the arguments in
 323 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 324 C<< $c->req->args >> will be restored to the previous values.
 325
 326 Any data C<return>ed from the action forwarded to, will be returned by the
 327 call to forward.
 328
 329     my $foodata = $c->forward('/foo');
 330     $c->forward('index');
 331     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 332     $c->forward('View::TT');
 333
 334 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 335 an C<< eval { } >> around the call (actually
 336 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 337 exceptions thrown by the called action non-fatal and pushing them onto
 338 $c->error instead. If you want C<die> to propagate you need to do something
 339 like:
 340
 341     $c->forward('foo');
 342     die join "\n", @{ $c->error } if @{ $c->error };
 343
 344 Or make sure to always return true values from your actions and write
 345 your code like this:
 346
 347     $c->forward('foo') || return;
 348
 349 Another note is that C<< $c->forward >> always returns a scalar because it
 350 actually returns $c->state which operates in a scalar context.
 351 Thus, something like:
 352
 353     return @array;
 354
 355 in an action that is forwarded to is going to return a scalar,
 356 i.e. how many items are in that array, which is probably not what you want.
 357 If you need to return an array then return a reference to it,
 358 or stash it like so:
 359
 360     $c->stash->{array} = \@array;
 361
 362 and access it from the stash.
 363
 364 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 365
 366 =cut
 367
 368 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 369
 370 =head2 $c->detach( $action [, \@arguments ] )
 371
 372 =head2 $c->detach( $class, $method, [, \@arguments ] )
 373
 374 =head2 $c->detach()
 375
 376 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 377 doesn't return to the previous action when processing is finished.
 378
 379 When called with no arguments it escapes the processing chain entirely.
 380
 381 =cut
 382
 383 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 384
 385 =head2 $c->visit( $action [, \@arguments ] )
 386
 387 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 388
 389 =head2 $c->visit( $class, $method, [, \@arguments ] )
 390
 391 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 392
 393 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 394 but does a full dispatch, instead of just calling the new C<$action> /
 395 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 396 you go to are called, just like a new request.
 397
 398 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 399 This means, for example, that C<< $c->action >> methods such as
 400 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 401 L<reverse|Catalyst::Action/reverse> return information for the visited action
 402 when they are invoked within the visited action.  This is different from the
 403 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 404 continues to use the $c->action object from the caller action even when
 405 invoked from the called action.
 406
 407 C<< $c->stash >> is kept unchanged.
 408
 409 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 410 allows you to "wrap" another action, just as it would have been called by
 411 dispatching from a URL, while the analogous
 412 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 413 transfer control to another action as if it had been reached directly from a URL.
 414
 415 =cut
 416
 417 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 418
 419 =head2 $c->go( $action [, \@arguments ] )
 420
 421 =head2 $c->go( $action [, \@captures, \@arguments ] )
 422
 423 =head2 $c->go( $class, $method, [, \@arguments ] )
 424
 425 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 426
 427 The relationship between C<go> and
 428 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 429 the relationship between
 430 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 431 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 432 C<< $c->go >> will perform a full dispatch on the specified action or method,
 433 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 434 C<go> escapes the processing of the current request chain on completion, and
 435 does not return to its caller.
 436
 437 @arguments are arguments to the final destination of $action. @captures are
 438 arguments to the intermediate steps, if any, on the way to the final sub of
 439 $action.
 440
 441 =cut
 442
 443 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 444
 445 =head2 $c->response
 446
 447 =head2 $c->res
 448
 449 Returns the current L<Catalyst::Response> object, see there for details.
 450
 451 =head2 $c->stash
 452
 453 Returns a hashref to the stash, which may be used to store data and pass
 454 it between components during a request. You can also set hash keys by
 455 passing arguments. The stash is automatically sent to the view. The
 456 stash is cleared at the end of a request; it cannot be used for
 457 persistent storage (for this you must use a session; see
 458 L<Catalyst::Plugin::Session> for a complete system integrated with
 459 Catalyst).
 460
 461     $c->stash->{foo} = $bar;
 462     $c->stash( { moose => 'majestic', qux => 0 } );
 463     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 464
 465     # stash is automatically passed to the view for use in a template
 466     $c->forward( 'MyApp::View::TT' );
 467
 468 =cut
 469
 470 around stash => sub {
 471     my $orig = shift;
 472     my $c = shift;
 473     my $stash = $orig->($c);
 474     if (@_) {
 475         my $new_stash = @_ > 1 ? {@_} : $_[0];
 476         croak('stash takes a hash or hashref') unless ref $new_stash;
 477         foreach my $key ( keys %$new_stash ) {
 478           $stash->{$key} = $new_stash->{$key};
 479         }
 480     }
 481
 482     return $stash;
 483 };
 484
 485
 486 =head2 $c->error
 487
 488 =head2 $c->error($error, ...)
 489
 490 =head2 $c->error($arrayref)
 491
 492 Returns an arrayref containing error messages.  If Catalyst encounters an
 493 error while processing a request, it stores the error in $c->error.  This
 494 method should only be used to store fatal error messages.
 495
 496     my @error = @{ $c->error };
 497
 498 Add a new error.
 499
 500     $c->error('Something bad happened');
 501
 502 =cut
 503
 504 sub error {
 505     my $c = shift;
 506     if ( $_[0] ) {
 507         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 508         croak @$error unless ref $c;
 509         push @{ $c->{error} }, @$error;
 510     }
 511     elsif ( defined $_[0] ) { $c->{error} = undef }
 512     return $c->{error} || [];
 513 }
 514
 515
 516 =head2 $c->state
 517
 518 Contains the return value of the last executed action.
 519 Note that << $c->state >> operates in a scalar context which means that all
 520 values it returns are scalar.
 521
 522 =head2 $c->clear_errors
 523
 524 Clear errors.  You probably don't want to clear the errors unless you are
 525 implementing a custom error screen.
 526
 527 This is equivalent to running
 528
 529     $c->error(0);
 530
 531 =cut
 532
 533 sub clear_errors {
 534     my $c = shift;
 535     $c->error(0);
 536 }
 537
 538 =head2 COMPONENT ACCESSORS
 539
 540 =head2 $c->controller($name)
 541
 542 Gets a L<Catalyst::Controller> instance by name.
 543
 544     $c->controller('Foo')->do_stuff;
 545
 546 If the name is omitted, will return the controller for the dispatched
 547 action.
 548
 549 If you want to search for controllers, pass in a regexp as the argument.
 550
 551     # find all controllers that start with Foo
 552     my @foo_controllers = $c->controller(qr{^Foo});
 553
 554
 555 =cut
 556
 557 sub controller { shift->_lookup_mvc('controller', @_) }
 558
 559 =head2 $c->model($name)
 560
 561 Gets a L<Catalyst::Model> instance by name.
 562
 563     $c->model('Foo')->do_stuff;
 564
 565 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 566
 567 If the name is omitted, it will look for
 568  - a model object in $c->stash->{current_model_instance}, then
 569  - a model name in $c->stash->{current_model}, then
 570  - a config setting 'default_model', or
 571  - check if there is only one model, and return it if that's the case.
 572
 573 If you want to search for models, pass in a regexp as the argument.
 574
 575     # find all models that start with Foo
 576     my @foo_models = $c->model(qr{^Foo});
 577
 578 =cut
 579
 580 sub model { shift->_lookup_mvc('model', @_) }
 581
 582 =head2 $c->view($name)
 583
 584 Gets a L<Catalyst::View> instance by name.
 585
 586     $c->view('Foo')->do_stuff;
 587
 588 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 589
 590 If the name is omitted, it will look for
 591  - a view object in $c->stash->{current_view_instance}, then
 592  - a view name in $c->stash->{current_view}, then
 593  - a config setting 'default_view', or
 594  - check if there is only one view, and return it if that's the case.
 595
 596 If you want to search for views, pass in a regexp as the argument.
 597
 598     # find all views that start with Foo
 599     my @foo_views = $c->view(qr{^Foo});
 600
 601 =cut
 602
 603 sub view { shift->_lookup_mvc('view', @_) }
 604
 605 sub _lookup_mvc {
 606     my ( $c, $type, $name, @args ) = @_;
 607
 608     if (ref $c && !$name) {
 609         my $current_instance = $c->stash->{"current_${type}_instance"};
 610         return $current_instance
 611             if $current_instance && $type ne 'controller';
 612
 613         $name = $type eq 'controller'
 614               ? Catalyst::Utils::class2classshortsuffix($c->action->class)
 615               : $c->stash->{"current_${type}"}
 616               ;
 617     }
 618
 619     return $c->container->get_component_from_sub_container($type, $name, $c, @args);
 620 }
 621
 622 =head2 $c->controllers
 623
 624 Returns the available names which can be passed to $c->controller
 625
 626 =cut
 627
 628 sub controllers {
 629     my ( $c ) = @_;
 630     return $c->container->get_sub_container('controller')->get_service_list;
 631 }
 632
 633 =head2 $c->models
 634
 635 Returns the available names which can be passed to $c->model
 636
 637 =cut
 638
 639 sub models {
 640     my ( $c ) = @_;
 641     return $c->container->get_sub_container('model')->get_service_list;
 642 }
 643
 644
 645 =head2 $c->views
 646
 647 Returns the available names which can be passed to $c->view
 648
 649 =cut
 650
 651 sub views {
 652     my ( $c ) = @_;
 653     return $c->container->get_sub_container('view')->get_service_list;
 654 }
 655
 656 =head2 $c->comp($name)
 657
 658 =head2 $c->component($name)
 659
 660 Gets a component object by name. This method is not recommended,
 661 unless you want to get a specific component by full
 662 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 663 should be used instead.
 664
 665 If C<$name> is a regexp, a list of components matched against the full
 666 component name will be returned.
 667
 668 =cut
 669
 670 sub component {
 671     my ( $c, $component, @args ) = @_;
 672
 673     unless ($component) {
 674         $c->log->warn('Calling $c->component with no args is deprecated and ');
 675         $c->log->warn('will be removed in a future release.');
 676         $c->log->warn('Use $c->component_list instead.');
 677         return $c->component_list;
 678     }
 679
 680     my @result = $c->container->find_component( $component, $c, @args );
 681
 682     # list context for regexp searches
 683     return @result if ref $component;
 684
 685     # only one component (if it's found) for string searches
 686     return shift @result if @result;
 687
 688     if (ref $c eq $component) {
 689         $c->log->warn('You are calling $c->comp("MyApp"). This behaviour is');
 690         $c->log->warn('deprecated, and will be removed in a future release.');
 691         return $c;
 692     }
 693
 694     $c->log->warn("Looking for '$component', but nothing was found.");
 695
 696     # I would expect to return an empty list here, but that breaks back-compat
 697     $c->log->warn('Component not found, returning the list of existing');
 698     $c->log->warn('components. This behavior is deprecated and will be');
 699     $c->log->warn('removed in a future release. Use $c->component_list');
 700     $c->log->warn('instead.');
 701
 702     return $c->component_list;
 703 }
 704
 705 =head2 $c->component_list
 706
 707 Returns the sorted list of the component names of the application.
 708
 709 =cut
 710
 711 sub component_list { sort keys %{ shift->components } }
 712
 713 =head2 CLASS DATA AND HELPER CLASSES
 714
 715 =head2 $c->config
 716
 717 Returns or takes a hashref containing the application's configuration.
 718
 719     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 720
 721 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 722 like C<myapp.conf> in your applications home directory. See
 723 L<Catalyst::Plugin::ConfigLoader>.
 724
 725 =head3 Cascading configuration
 726
 727 The config method is present on all Catalyst components, and configuration
 728 will be merged when an application is started. Configuration loaded with
 729 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 730 followed by configuration in your top level C<MyApp> class. These two
 731 configurations are merged, and then configuration data whose hash key matches a
 732 component name is merged with configuration for that component.
 733
 734 The configuration for a component is then passed to the C<new> method when a
 735 component is constructed.
 736
 737 For example:
 738
 739     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 740     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 741
 742 will mean that C<MyApp::Model::Foo> receives the following data when
 743 constructed:
 744
 745     MyApp::Model::Foo->new({
 746         bar => 'baz',
 747         quux => 'frob',
 748         overrides => 'me',
 749     });
 750
 751 It's common practice to use a Moose attribute
 752 on the receiving component to access the config value.
 753
 754     package MyApp::Model::Foo;
 755
 756     use Moose;
 757
 758     # this attr will receive 'baz' at construction time
 759     has 'bar' => (
 760         is  => 'rw',
 761         isa => 'Str',
 762     );
 763
 764 You can then get the value 'baz' by calling $c->model('Foo')->bar
 765 (or $self->bar inside code in the model).
 766
 767 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 768 as a way of reading config within your code, as this B<will not> give you the
 769 correctly merged config back. You B<MUST> take the config values supplied to
 770 the constructor and use those instead.
 771
 772 =cut
 773
 774 around config => sub {
 775     my $orig = shift;
 776     my $c = shift;
 777
 778     croak('Setting config after setup has been run is not allowed.')
 779         if ( @_ and $c->setup_finished );
 780
 781     $c->$orig(@_);
 782 };
 783
 784 =head2 $c->log
 785
 786 Returns the logging object instance. Unless it is already set, Catalyst
 787 sets this up with a L<Catalyst::Log> object. To use your own log class,
 788 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 789 C<< __PACKAGE__->setup >>.
 790
 791  __PACKAGE__->log( MyLogger->new );
 792  __PACKAGE__->setup;
 793
 794 And later:
 795
 796     $c->log->info( 'Now logging with my own logger!' );
 797
 798 Your log class should implement the methods described in
 799 L<Catalyst::Log>.
 800
 801
 802 =head2 $c->debug
 803
 804 Returns 1 if debug mode is enabled, 0 otherwise.
 805
 806 You can enable debug mode in several ways:
 807
 808 =over
 809
 810 =item By calling myapp_server.pl with the -d flag
 811
 812 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 813
 814 =item The -Debug option in your MyApp.pm
 815
 816 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 817
 818 =back
 819
 820 The first three also set the log level to 'debug'.
 821
 822 Calling C<< $c->debug(1) >> has no effect.
 823
 824 =cut
 825
 826 sub debug { 0 }
 827
 828 =head2 $c->dispatcher
 829
 830 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 831
 832 =head2 $c->engine
 833
 834 Returns the engine instance. See L<Catalyst::Engine>.
 835
 836
 837 =head2 UTILITY METHODS
 838
 839 =head2 $c->path_to(@path)
 840
 841 Merges C<@path> with C<< $c->config->{home} >> and returns a
 842 L<Path::Class::Dir> object. Note you can usually use this object as
 843 a filename, but sometimes you will have to explicitly stringify it
 844 yourself by calling the C<< ->stringify >> method.
 845
 846 For example:
 847
 848     $c->path_to( 'db', 'sqlite.db' );
 849
 850 =cut
 851
 852 sub path_to {
 853     my ( $c, @path ) = @_;
 854     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 855     if ( -d $path ) { return $path }
 856     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 857 }
 858
 859 sub plugin {
 860     my ( $class, $name, $plugin, @args ) = @_;
 861
 862     # See block comment in t/aggregate/unit_core_plugin.t
 863     # See block comment in t/unit_core_plugin.t
 864     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
 865
 866     $class->_register_plugin( $plugin, 1 );
 867
 868     eval { $plugin->import };
 869     $class->mk_classdata($name);
 870     my $obj;
 871     eval { $obj = $plugin->new(@args) };
 872
 873     if ($@) {
 874         Catalyst::Exception->throw( message =>
 875               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 876     }
 877
 878     $class->$name($obj);
 879     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 880       if $class->debug;
 881 }
 882
 883 =head2 MyApp->setup
 884
 885 Initializes the dispatcher and engine, loads any plugins, and loads the
 886 model, view, and controller components. You may also specify an array
 887 of plugins to load here, if you choose to not load them in the C<use
 888 Catalyst> line.
 889
 890     MyApp->setup;
 891     MyApp->setup( qw/-Debug/ );
 892
 893 B<Note:> You B<should not> wrap this method with method modifiers
 894 or bad things will happen - wrap the C<setup_finalize> method instead.
 895
 896 =cut
 897
 898 sub setup {
 899     my ( $class, @arguments ) = @_;
 900     croak('Running setup more than once')
 901         if ( $class->setup_finished );
 902
 903     unless ( $class->isa('Catalyst') ) {
 904
 905         Catalyst::Exception->throw(
 906             message => qq/'$class' does not inherit from Catalyst/ );
 907     }
 908
 909     if ( $class->arguments ) {
 910         @arguments = ( @arguments, @{ $class->arguments } );
 911     }
 912
 913     # Process options
 914     my $flags = {};
 915
 916     foreach (@arguments) {
 917
 918         if (/^-Debug$/) {
 919             $flags->{log} =
 920               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 921         }
 922         elsif (/^-(\w+)=?(.*)$/) {
 923             $flags->{ lc $1 } = $2;
 924         }
 925         else {
 926             push @{ $flags->{plugins} }, $_;
 927         }
 928     }
 929
 930     $class->setup_config();
 931     $class->setup_home( delete $flags->{home} );
 932
 933     $class->setup_log( delete $flags->{log} );
 934     $class->setup_plugins( delete $flags->{plugins} );
 935     $class->setup_dispatcher( delete $flags->{dispatcher} );
 936     if (my $engine = delete $flags->{engine}) {
 937         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
 938     }
 939     $class->setup_engine();
 940     $class->setup_stats( delete $flags->{stats} );
 941
 942     for my $flag ( sort keys %{$flags} ) {
 943
 944         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 945             &$code( $class, delete $flags->{$flag} );
 946         }
 947         else {
 948             $class->log->warn(qq/Unknown flag "$flag"/);
 949         }
 950     }
 951
 952     eval { require Catalyst::Devel; };
 953     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 954         $class->log->warn(<<"EOF");
 955 You are running an old script!
 956
 957   Please update by running (this will overwrite existing files):
 958     catalyst.pl -force -scripts $class
 959
 960   or (this will not overwrite existing files):
 961     catalyst.pl -scripts $class
 962
 963 EOF
 964     }
 965
 966     if ( $class->debug ) {
 967         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 968
 969         if (@plugins) {
 970             my $column_width = Catalyst::Utils::term_width() - 6;
 971             my $t = Text::SimpleTable->new($column_width);
 972             $t->row($_) for @plugins;
 973             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 974         }
 975
 976         my $dispatcher = $class->dispatcher;
 977         my $engine     = $class->engine;
 978         my $home       = $class->config->{home};
 979
 980         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
 981         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
 982
 983         $home
 984           ? ( -d $home )
 985           ? $class->log->debug(qq/Found home "$home"/)
 986           : $class->log->debug(qq/Home "$home" doesn't exist/)
 987           : $class->log->debug(q/Couldn't find home/);
 988     }
 989
 990     # Call plugins setup, this is stupid and evil.
 991     # Also screws C3 badly on 5.10, hack to avoid.
 992     {
 993         no warnings qw/redefine/;
 994         local *setup = sub { };
 995         $class->setup unless $Catalyst::__AM_RESTARTING;
 996     }
 997
 998     $class->setup_components;
 999
1000     if (
1001         $class->debug and
1002         my $comps = $class->container->get_all_components($class)
1003     ) {
1004         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1005         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1006         $t->row( $_ => ref($comps->{$_}) ? 'instance' : 'class' ) for keys %$comps;
1007
1008         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" );
1009     }
1010
1011     $class->setup_actions;
1012
1013     if ( $class->debug ) {
1014         my $name = $class->config->{name} || 'Application';
1015         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1016     }
1017
1018     if ($class->config->{case_sensitive}) {
1019         $class->log->warn($class . "->config->{case_sensitive} is set.");
1020         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1021     }
1022
1023     $class->setup_finalize;
1024     # Should be the last thing we do so that user things hooking
1025     # setup_finalize can log..
1026     $class->log->_flush() if $class->log->can('_flush');
1027     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1028 }
1029
1030 =head2 $app->setup_finalize
1031
1032 A hook to attach modifiers to. This method does not do anything except set the
1033 C<setup_finished> accessor.
1034
1035 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1036
1037 Example:
1038
1039     after setup_finalize => sub {
1040         my $app = shift;
1041
1042         ## do stuff here..
1043     };
1044
1045 =cut
1046
1047 sub setup_finalize {
1048     my ($class) = @_;
1049     $class->setup_finished(1);
1050 }
1051
1052 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1053
1054 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1055
1056 Constructs an absolute L<URI> object based on the application root, the
1057 provided path, and the additional arguments and query parameters provided.
1058 When used as a string, provides a textual URI.  If you need more flexibility
1059 than this (i.e. the option to provide relative URIs etc.) see
1060 L<Catalyst::Plugin::SmartURI>.
1061
1062 If no arguments are provided, the URI for the current action is returned.
1063 To return the current action and also provide @args, use
1064 C<< $c->uri_for( $c->action, @args ) >>.
1065
1066 If the first argument is a string, it is taken as a public URI path relative
1067 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1068 relative to the application root (if it does). It is then merged with
1069 C<< $c->request->base >>; any C<@args> are appended as additional path
1070 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1071
1072 If the first argument is a L<Catalyst::Action> it represents an action which
1073 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1074 optional C<\@captures> argument (an arrayref) allows passing the captured
1075 variables that are needed to fill in the paths of Chained and Regex actions;
1076 once the path is resolved, C<uri_for> continues as though a path was
1077 provided, appending any arguments or parameters and creating an absolute
1078 URI.
1079
1080 The captures for the current request can be found in
1081 C<< $c->request->captures >>, and actions can be resolved using
1082 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1083 path, use C<< $c->uri_for_action >> instead.
1084
1085   # Equivalent to $c->req->uri
1086   $c->uri_for($c->action, $c->req->captures,
1087       @{ $c->req->args }, $c->req->params);
1088
1089   # For the Foo action in the Bar controller
1090   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1091
1092   # Path to a static resource
1093   $c->uri_for('/static/images/logo.png');
1094
1095 =cut
1096
1097 sub uri_for {
1098     my ( $c, $path, @args ) = @_;
1099
1100     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1101         $path = $path->path_prefix;
1102         $path =~ s{/+\z}{};
1103         $path .= '/';
1104     }
1105
1106     undef($path) if (defined $path && $path eq '');
1107
1108     my $params =
1109       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1110
1111     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1112     foreach my $arg (@args) {
1113         utf8::encode($arg) if utf8::is_utf8($arg);
1114         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1115     }
1116
1117     if ( blessed($path) ) { # action object
1118         s|/|%2F|g for @args;
1119         my $captures = [ map { s|/|%2F|g; $_; }
1120                         ( scalar @args && ref $args[0] eq 'ARRAY'
1121                          ? @{ shift(@args) }
1122                          : ()) ];
1123
1124         foreach my $capture (@$captures) {
1125             utf8::encode($capture) if utf8::is_utf8($capture);
1126             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1127         }
1128
1129         my $action = $path;
1130         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1131         if( !@args && $action->number_of_args ) {
1132             my $expanded_action = $c->dispatcher->expand_action( $action );
1133
1134             my $num_captures = $expanded_action->number_of_captures;
1135             unshift @args, splice @$captures, $num_captures;
1136         }
1137
1138        $path = $c->dispatcher->uri_for_action($action, $captures);
1139         if (not defined $path) {
1140             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1141                 if $c->debug;
1142             return undef;
1143         }
1144         $path = '/' if $path eq '';
1145     }
1146
1147     unshift(@args, $path);
1148
1149     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1150         my $namespace = $c->namespace;
1151         if (defined $path) { # cheesy hack to handle path '../foo'
1152            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1153         }
1154         unshift(@args, $namespace || '');
1155     }
1156
1157     # join args with '/', or a blank string
1158     my $args = join('/', grep { defined($_) } @args);
1159     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1160     $args =~ s!^/+!!;
1161     my $base = $c->req->base;
1162     my $class = ref($base);
1163     $base =~ s{(?<!/)$}{/};
1164
1165     my $query = '';
1166
1167     if (my @keys = keys %$params) {
1168       # somewhat lifted from URI::_query's query_form
1169       $query = '?'.join('&', map {
1170           my $val = $params->{$_};
1171           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1172           s/ /+/g;
1173           my $key = $_;
1174           $val = '' unless defined $val;
1175           (map {
1176               my $param = "$_";
1177               utf8::encode( $param ) if utf8::is_utf8($param);
1178               # using the URI::Escape pattern here so utf8 chars survive
1179               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1180               $param =~ s/ /+/g;
1181               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1182       } @keys);
1183     }
1184
1185     my $res = bless(\"${base}${args}${query}", $class);
1186     $res;
1187 }
1188
1189 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1190
1191 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1192
1193 =over
1194
1195 =item $path
1196
1197 A private path to the Catalyst action you want to create a URI for.
1198
1199 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1200 >> and passing the resulting C<$action> and the remaining arguments to C<<
1201 $c->uri_for >>.
1202
1203 You can also pass in a Catalyst::Action object, in which case it is passed to
1204 C<< $c->uri_for >>.
1205
1206 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1207
1208 For example, if the action looks like:
1209
1210  package MyApp::Controller::Users;
1211
1212  sub lst : Path('the-list') {}
1213
1214 You can use:
1215
1216  $c->uri_for_action('/users/lst')
1217
1218 and it will create the URI /users/the-list.
1219
1220 =item \@captures_and_args?
1221
1222 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1223 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1224 to interpolate all the parameters in the URI.
1225
1226 =item @args?
1227
1228 Optional list of extra arguments - can be supplied in the
1229 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1230 code.
1231
1232 Your action can have zero, a fixed or a variable number of args (e.g.
1233 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1234
1235 =item \%query_values?
1236
1237 Optional array reference of query parameters to append. E.g.
1238
1239   { foo => 'bar' }
1240
1241 will generate
1242
1243   /rest/of/your/uri?foo=bar
1244
1245 =back
1246
1247 =cut
1248
1249 sub uri_for_action {
1250     my ( $c, $path, @args ) = @_;
1251     my $action = blessed($path)
1252       ? $path
1253       : $c->dispatcher->get_action_by_path($path);
1254     unless (defined $action) {
1255       croak "Can't find action for path '$path'";
1256     }
1257     return $c->uri_for( $action, @args );
1258 }
1259
1260 =head2 $c->welcome_message
1261
1262 Returns the Catalyst welcome HTML page.
1263
1264 =cut
1265
1266 sub welcome_message {
1267     my $c      = shift;
1268     my $name   = $c->config->{name};
1269     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1270     my $prefix = Catalyst::Utils::appprefix( ref $c );
1271     $c->response->content_type('text/html; charset=utf-8');
1272     return <<"EOF";
1273 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1274     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1275 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1276     <head>
1277     <meta http-equiv="Content-Language" content="en" />
1278     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1279         <title>$name on Catalyst $VERSION</title>
1280         <style type="text/css">
1281             body {
1282                 color: #000;
1283                 background-color: #eee;
1284             }
1285             div#content {
1286                 width: 640px;
1287                 margin-left: auto;
1288                 margin-right: auto;
1289                 margin-top: 10px;
1290                 margin-bottom: 10px;
1291                 text-align: left;
1292                 background-color: #ccc;
1293                 border: 1px solid #aaa;
1294             }
1295             p, h1, h2 {
1296                 margin-left: 20px;
1297                 margin-right: 20px;
1298                 font-family: verdana, tahoma, sans-serif;
1299             }
1300             a {
1301                 font-family: verdana, tahoma, sans-serif;
1302             }
1303             :link, :visited {
1304                     text-decoration: none;
1305                     color: #b00;
1306                     border-bottom: 1px dotted #bbb;
1307             }
1308             :link:hover, :visited:hover {
1309                     color: #555;
1310             }
1311             div#topbar {
1312                 margin: 0px;
1313             }
1314             pre {
1315                 margin: 10px;
1316                 padding: 8px;
1317             }
1318             div#answers {
1319                 padding: 8px;
1320                 margin: 10px;
1321                 background-color: #fff;
1322                 border: 1px solid #aaa;
1323             }
1324             h1 {
1325                 font-size: 0.9em;
1326                 font-weight: normal;
1327                 text-align: center;
1328             }
1329             h2 {
1330                 font-size: 1.0em;
1331             }
1332             p {
1333                 font-size: 0.9em;
1334             }
1335             p img {
1336                 float: right;
1337                 margin-left: 10px;
1338             }
1339             span#appname {
1340                 font-weight: bold;
1341                 font-size: 1.6em;
1342             }
1343         </style>
1344     </head>
1345     <body>
1346         <div id="content">
1347             <div id="topbar">
1348                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1349                     $VERSION</h1>
1350              </div>
1351              <div id="answers">
1352                  <p>
1353                  <img src="$logo" alt="Catalyst Logo" />
1354                  </p>
1355                  <p>Welcome to the  world of Catalyst.
1356                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1357                     framework will make web development something you had
1358                     never expected it to be: Fun, rewarding, and quick.</p>
1359                  <h2>What to do now?</h2>
1360                  <p>That really depends  on what <b>you</b> want to do.
1361                     We do, however, provide you with a few starting points.</p>
1362                  <p>If you want to jump right into web development with Catalyst
1363                     you might want to start with a tutorial.</p>
1364 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1365 </pre>
1366 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1367 <pre>
1368 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1369 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1370 </code></pre>
1371                  <h2>What to do next?</h2>
1372                  <p>Next it's time to write an actual application. Use the
1373                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1374                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1375                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1376                     they can save you a lot of work.</p>
1377                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1378                     <p>Also, be sure to check out the vast and growing
1379                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1380                     you are likely to find what you need there.
1381                     </p>
1382
1383                  <h2>Need help?</h2>
1384                  <p>Catalyst has a very active community. Here are the main places to
1385                     get in touch with us.</p>
1386                  <ul>
1387                      <li>
1388                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1389                      </li>
1390                      <li>
1391                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1392                      </li>
1393                      <li>
1394                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1395                      </li>
1396                  </ul>
1397                  <h2>In conclusion</h2>
1398                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1399                     as we enjoyed making it. Please contact us if you have ideas
1400                     for improvement or other feedback.</p>
1401              </div>
1402          </div>
1403     </body>
1404 </html>
1405 EOF
1406 }
1407
1408 =head2 run_options
1409
1410 Contains a hash of options passed from the application script, including
1411 the original ARGV the script received, the processed values from that
1412 ARGV and any extra arguments to the script which were not processed.
1413
1414 This can be used to add custom options to your application's scripts
1415 and setup your application differently depending on the values of these
1416 options.
1417
1418 =head1 INTERNAL METHODS
1419
1420 These methods are not meant to be used by end users.
1421
1422 =head2 $c->components
1423
1424 Returns a hash of components.
1425
1426 =cut
1427
1428 sub components {
1429     my ( $class, $comps ) = @_;
1430
1431     # people create components calling this sub directly, before setup
1432     $class->setup_config unless $class->container;
1433
1434     my $container = $class->container;
1435
1436     if ( $comps ) {
1437         $container->add_component( $_ ) for keys %$comps;
1438     }
1439
1440     return $container->get_all_components($class);
1441 }
1442
1443 =head2 $c->context_class
1444
1445 Returns or sets the context class.
1446
1447 =head2 $c->counter
1448
1449 Returns a hashref containing coderefs and execution counts (needed for
1450 deep recursion detection).
1451
1452 =head2 $c->depth
1453
1454 Returns the number of actions on the current internal execution stack.
1455
1456 =head2 $c->dispatch
1457
1458 Dispatches a request to actions.
1459
1460 =cut
1461
1462 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1463
1464 =head2 $c->dispatcher_class
1465
1466 Returns or sets the dispatcher class.
1467
1468 =head2 $c->dump_these
1469
1470 Returns a list of 2-element array references (name, structure) pairs
1471 that will be dumped on the error page in debug mode.
1472
1473 =cut
1474
1475 sub dump_these {
1476     my $c = shift;
1477     [ Request => $c->req ],
1478     [ Response => $c->res ],
1479     [ Stash => $c->stash ],
1480     [ Config => $c->config ];
1481 }
1482
1483 =head2 $c->engine_class
1484
1485 Returns or sets the engine class.
1486
1487 =head2 $c->execute( $class, $coderef )
1488
1489 Execute a coderef in given class and catch exceptions. Errors are available
1490 via $c->error.
1491
1492 =cut
1493
1494 sub execute {
1495     my ( $c, $class, $code ) = @_;
1496     $class = $c->component($class) || $class;
1497     $c->state(0);
1498
1499     if ( $c->depth >= $RECURSION ) {
1500         my $action = $code->reverse();
1501         $action = "/$action" unless $action =~ /->/;
1502         my $error = qq/Deep recursion detected calling "${action}"/;
1503         $c->log->error($error);
1504         $c->error($error);
1505         $c->state(0);
1506         return $c->state;
1507     }
1508
1509     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1510
1511     push( @{ $c->stack }, $code );
1512
1513     no warnings 'recursion';
1514     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1515     #      I have no idea how, ergo $ret (which appears to fix the issue)
1516     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1517
1518     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1519
1520     my $last = pop( @{ $c->stack } );
1521
1522     if ( my $error = $@ ) {
1523         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1524             $error->rethrow if $c->depth > 1;
1525         }
1526         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1527             $error->rethrow if $c->depth > 0;
1528         }
1529         else {
1530             unless ( ref $error ) {
1531                 no warnings 'uninitialized';
1532                 chomp $error;
1533                 my $class = $last->class;
1534                 my $name  = $last->name;
1535                 $error = qq/Caught exception in $class->$name "$error"/;
1536             }
1537             $c->error($error);
1538         }
1539         $c->state(0);
1540     }
1541     return $c->state;
1542 }
1543
1544 sub _stats_start_execute {
1545     my ( $c, $code ) = @_;
1546     my $appclass = ref($c) || $c;
1547     return if ( ( $code->name =~ /^_.*/ )
1548         && ( !$appclass->config->{show_internal_actions} ) );
1549
1550     my $action_name = $code->reverse();
1551     $c->counter->{$action_name}++;
1552
1553     my $action = $action_name;
1554     $action = "/$action" unless $action =~ /->/;
1555
1556     # determine if the call was the result of a forward
1557     # this is done by walking up the call stack and looking for a calling
1558     # sub of Catalyst::forward before the eval
1559     my $callsub = q{};
1560     for my $index ( 2 .. 11 ) {
1561         last
1562         if ( ( caller($index) )[0] eq 'Catalyst'
1563             && ( caller($index) )[3] eq '(eval)' );
1564
1565         if ( ( caller($index) )[3] =~ /forward$/ ) {
1566             $callsub = ( caller($index) )[3];
1567             $action  = "-> $action";
1568             last;
1569         }
1570     }
1571
1572     my $uid = $action_name . $c->counter->{$action_name};
1573
1574     # is this a root-level call or a forwarded call?
1575     if ( $callsub =~ /forward$/ ) {
1576         my $parent = $c->stack->[-1];
1577
1578         # forward, locate the caller
1579         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1580             $c->stats->profile(
1581                 begin  => $action,
1582                 parent => "$parent" . $c->counter->{"$parent"},
1583                 uid    => $uid,
1584             );
1585         }
1586         else {
1587
1588             # forward with no caller may come from a plugin
1589             $c->stats->profile(
1590                 begin => $action,
1591                 uid   => $uid,
1592             );
1593         }
1594     }
1595     else {
1596
1597         # root-level call
1598         $c->stats->profile(
1599             begin => $action,
1600             uid   => $uid,
1601         );
1602     }
1603     return $action;
1604
1605 }
1606
1607 sub _stats_finish_execute {
1608     my ( $c, $info ) = @_;
1609     $c->stats->profile( end => $info );
1610 }
1611
1612 =head2 $c->finalize
1613
1614 Finalizes the request.
1615
1616 =cut
1617
1618 sub finalize {
1619     my $c = shift;
1620
1621     for my $error ( @{ $c->error } ) {
1622         $c->log->error($error);
1623     }
1624
1625     # Allow engine to handle finalize flow (for POE)
1626     my $engine = $c->engine;
1627     if ( my $code = $engine->can('finalize') ) {
1628         $engine->$code($c);
1629     }
1630     else {
1631
1632         $c->finalize_uploads;
1633
1634         # Error
1635         if ( $#{ $c->error } >= 0 ) {
1636             $c->finalize_error;
1637         }
1638
1639         $c->finalize_headers unless $c->response->finalized_headers;
1640
1641         # HEAD request
1642         if ( $c->request->method eq 'HEAD' ) {
1643             $c->response->body('');
1644         }
1645
1646         $c->finalize_body;
1647     }
1648
1649     $c->log_response;
1650
1651     if ($c->use_stats) {
1652         my $elapsed = sprintf '%f', $c->stats->elapsed;
1653         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1654         $c->log->info(
1655             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1656     }
1657
1658     return $c->response->status;
1659 }
1660
1661 =head2 $c->finalize_body
1662
1663 Finalizes body.
1664
1665 =cut
1666
1667 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1668
1669 =head2 $c->finalize_cookies
1670
1671 Finalizes cookies.
1672
1673 =cut
1674
1675 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1676
1677 =head2 $c->finalize_error
1678
1679 Finalizes error.
1680
1681 =cut
1682
1683 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1684
1685 =head2 $c->finalize_headers
1686
1687 Finalizes headers.
1688
1689 =cut
1690
1691 sub finalize_headers {
1692     my $c = shift;
1693
1694     my $response = $c->response; #accessor calls can add up?
1695
1696     # Check if we already finalized headers
1697     return if $response->finalized_headers;
1698
1699     # Handle redirects
1700     if ( my $location = $response->redirect ) {
1701         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1702         $response->header( Location => $location );
1703
1704         if ( !$response->has_body ) {
1705             # Add a default body if none is already present
1706             $response->body(<<"EOF");
1707 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1708 <html xmlns="http://www.w3.org/1999/xhtml">
1709   <head>
1710     <title>Moved</title>
1711   </head>
1712   <body>
1713      <p>This item has moved <a href="$location">here</a>.</p>
1714   </body>
1715 </html>
1716 EOF
1717             $response->content_type('text/html; charset=utf-8');
1718         }
1719     }
1720
1721     # Content-Length
1722     if ( defined $response->body && length $response->body && !$response->content_length ) {
1723
1724         # get the length from a filehandle
1725         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1726         {
1727             my $size = -s $response->body;
1728             if ( $size ) {
1729                 $response->content_length( $size );
1730             }
1731             else {
1732                 $c->log->warn('Serving filehandle without a content-length');
1733             }
1734         }
1735         else {
1736             # everything should be bytes at this point, but just in case
1737             $response->content_length( length( $response->body ) );
1738         }
1739     }
1740
1741     # Errors
1742     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1743         $response->headers->remove_header("Content-Length");
1744         $response->body('');
1745     }
1746
1747     $c->finalize_cookies;
1748
1749     $c->response->finalize_headers();
1750
1751     # Done
1752     $response->finalized_headers(1);
1753 }
1754
1755 =head2 $c->finalize_output
1756
1757 An alias for finalize_body.
1758
1759 =head2 $c->finalize_read
1760
1761 Finalizes the input after reading is complete.
1762
1763 =cut
1764
1765 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1766
1767 =head2 $c->finalize_uploads
1768
1769 Finalizes uploads. Cleans up any temporary files.
1770
1771 =cut
1772
1773 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1774
1775 =head2 $c->get_action( $action, $namespace )
1776
1777 Gets an action in a given namespace.
1778
1779 =cut
1780
1781 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1782
1783 =head2 $c->get_actions( $action, $namespace )
1784
1785 Gets all actions of a given name in a namespace and all parent
1786 namespaces.
1787
1788 =cut
1789
1790 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1791
1792 =head2 $app->handle_request( @arguments )
1793
1794 Called to handle each HTTP request.
1795
1796 =cut
1797
1798 sub handle_request {
1799     my ( $class, @arguments ) = @_;
1800
1801     # Always expect worst case!
1802     my $status = -1;
1803     try {
1804         if ($class->debug) {
1805             my $secs = time - $START || 1;
1806             my $av = sprintf '%.3f', $COUNT / $secs;
1807             my $time = localtime time;
1808             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1809         }
1810
1811         my $c = $class->prepare(@arguments);
1812         $c->dispatch;
1813         $status = $c->finalize;
1814     }
1815     catch {
1816         chomp(my $error = $_);
1817         $class->log->error(qq/Caught exception in engine "$error"/);
1818     };
1819
1820     $COUNT++;
1821
1822     if(my $coderef = $class->log->can('_flush')){
1823         $class->log->$coderef();
1824     }
1825     return $status;
1826 }
1827
1828 =head2 $class->prepare( @arguments )
1829
1830 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1831 etc.).
1832
1833 =cut
1834
1835 has _uploadtmp => (
1836     is => 'ro',
1837     predicate => '_has_uploadtmp',
1838 );
1839
1840 sub prepare {
1841     my ( $class, @arguments ) = @_;
1842
1843     # XXX
1844     # After the app/ctxt split, this should become an attribute based on something passed
1845     # into the application.
1846     $class->context_class( ref $class || $class ) unless $class->context_class;
1847
1848     my $uploadtmp = $class->config->{uploadtmp};
1849     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
1850
1851     $c->response->_context($c);
1852
1853     #surely this is not the most efficient way to do things...
1854     $c->stats($class->stats_class->new)->enable($c->use_stats);
1855     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1856         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1857     }
1858
1859     try {
1860         # Allow engine to direct the prepare flow (for POE)
1861         if ( my $prepare = $c->engine->can('prepare') ) {
1862             $c->engine->$prepare( $c, @arguments );
1863         }
1864         else {
1865             $c->prepare_request(@arguments);
1866             $c->prepare_connection;
1867             $c->prepare_query_parameters;
1868             $c->prepare_headers; # Just hooks, no longer needed - they just
1869             $c->prepare_cookies; # cause the lazy attribute on req to build
1870             $c->prepare_path;
1871
1872             # Prepare the body for reading, either by prepare_body
1873             # or the user, if they are using $c->read
1874             $c->prepare_read;
1875
1876             # Parse the body unless the user wants it on-demand
1877             unless ( ref($c)->config->{parse_on_demand} ) {
1878                 $c->prepare_body;
1879             }
1880         }
1881         $c->prepare_action;
1882     }
1883     # VERY ugly and probably shouldn't rely on ->finalize actually working
1884     catch {
1885         # failed prepare is always due to an invalid request, right?
1886         $c->response->status(400);
1887         $c->response->content_type('text/plain');
1888         $c->response->body('Bad Request');
1889         # Note we call finalize and then die here, which escapes
1890         # finalize being called in the enclosing block..
1891         # It in fact couldn't be called, as we don't return $c..
1892         # This is a mess - but I'm unsure you can fix this without
1893         # breaking compat for people doing crazy things (we should set
1894         # the 400 and just return the ctx here IMO, letting finalize get called
1895         # above...
1896         $c->finalize;
1897         die $_;
1898     };
1899
1900     $c->log_request;
1901
1902     return $c;
1903 }
1904
1905 =head2 $c->prepare_action
1906
1907 Prepares action. See L<Catalyst::Dispatcher>.
1908
1909 =cut
1910
1911 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1912
1913 =head2 $c->prepare_body
1914
1915 Prepares message body.
1916
1917 =cut
1918
1919 sub prepare_body {
1920     my $c = shift;
1921
1922     return if $c->request->_has_body;
1923
1924     # Initialize on-demand data
1925     $c->engine->prepare_body( $c, @_ );
1926     $c->prepare_parameters;
1927     $c->prepare_uploads;
1928 }
1929
1930 =head2 $c->prepare_body_chunk( $chunk )
1931
1932 Prepares a chunk of data before sending it to L<HTTP::Body>.
1933
1934 See L<Catalyst::Engine>.
1935
1936 =cut
1937
1938 sub prepare_body_chunk {
1939     my $c = shift;
1940     $c->engine->prepare_body_chunk( $c, @_ );
1941 }
1942
1943 =head2 $c->prepare_body_parameters
1944
1945 Prepares body parameters.
1946
1947 =cut
1948
1949 sub prepare_body_parameters {
1950     my $c = shift;
1951     $c->engine->prepare_body_parameters( $c, @_ );
1952 }
1953
1954 =head2 $c->prepare_connection
1955
1956 Prepares connection.
1957
1958 =cut
1959
1960 sub prepare_connection {
1961     my $c = shift;
1962     # XXX - This is called on the engine (not the request) to maintain
1963     #       Engine::PSGI back compat.
1964     $c->engine->prepare_connection($c);
1965 }
1966
1967 =head2 $c->prepare_cookies
1968
1969 Prepares cookies by ensuring that the attribute on the request
1970 object has been built.
1971
1972 =cut
1973
1974 sub prepare_cookies { my $c = shift; $c->request->cookies }
1975
1976 =head2 $c->prepare_headers
1977
1978 Prepares request headers by ensuring that the attribute on the request
1979 object has been built.
1980
1981 =cut
1982
1983 sub prepare_headers { my $c = shift; $c->request->headers }
1984
1985 =head2 $c->prepare_parameters
1986
1987 Prepares parameters.
1988
1989 =cut
1990
1991 sub prepare_parameters {
1992     my $c = shift;
1993     $c->prepare_body_parameters;
1994     $c->engine->prepare_parameters( $c, @_ );
1995 }
1996
1997 =head2 $c->prepare_path
1998
1999 Prepares path and base.
2000
2001 =cut
2002
2003 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2004
2005 =head2 $c->prepare_query_parameters
2006
2007 Prepares query parameters.
2008
2009 =cut
2010
2011 sub prepare_query_parameters {
2012     my $c = shift;
2013
2014     $c->engine->prepare_query_parameters( $c, @_ );
2015 }
2016
2017 =head2 $c->log_request
2018
2019 Writes information about the request to the debug logs.  This includes:
2020
2021 =over 4
2022
2023 =item * Request method, path, and remote IP address
2024
2025 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2026
2027 =item * Request parameters
2028
2029 =item * File uploads
2030
2031 =back
2032
2033 =cut
2034
2035 sub log_request {
2036     my $c = shift;
2037
2038     return unless $c->debug;
2039
2040     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2041     my $request = $dump->[1];
2042
2043     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2044     $method ||= '';
2045     $path = '/' unless length $path;
2046     $address ||= '';
2047     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2048
2049     $c->log_request_headers($request->headers);
2050
2051     if ( my $keywords = $request->query_keywords ) {
2052         $c->log->debug("Query keywords are: $keywords");
2053     }
2054
2055     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2056
2057     $c->log_request_uploads($request);
2058 }
2059
2060 =head2 $c->log_response
2061
2062 Writes information about the response to the debug logs by calling
2063 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2064
2065 =cut
2066
2067 sub log_response {
2068     my $c = shift;
2069
2070     return unless $c->debug;
2071
2072     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2073     my $response = $dump->[1];
2074
2075     $c->log_response_status_line($response);
2076     $c->log_response_headers($response->headers);
2077 }
2078
2079 =head2 $c->log_response_status_line($response)
2080
2081 Writes one line of information about the response to the debug logs.  This includes:
2082
2083 =over 4
2084
2085 =item * Response status code
2086
2087 =item * Content-Type header (if present)
2088
2089 =item * Content-Length header (if present)
2090
2091 =back
2092
2093 =cut
2094
2095 sub log_response_status_line {
2096     my ($c, $response) = @_;
2097
2098     $c->log->debug(
2099         sprintf(
2100             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2101             $response->status                            || 'unknown',
2102             $response->headers->header('Content-Type')   || 'unknown',
2103             $response->headers->header('Content-Length') || 'unknown'
2104         )
2105     );
2106 }
2107
2108 =head2 $c->log_response_headers($headers);
2109
2110 Hook method which can be wrapped by plugins to log the response headers.
2111 No-op in the default implementation.
2112
2113 =cut
2114
2115 sub log_response_headers {}
2116
2117 =head2 $c->log_request_parameters( query => {}, body => {} )
2118
2119 Logs request parameters to debug logs
2120
2121 =cut
2122
2123 sub log_request_parameters {
2124     my $c          = shift;
2125     my %all_params = @_;
2126
2127     return unless $c->debug;
2128
2129     my $column_width = Catalyst::Utils::term_width() - 44;
2130     foreach my $type (qw(query body)) {
2131         my $params = $all_params{$type};
2132         next if ! keys %$params;
2133         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2134         for my $key ( sort keys %$params ) {
2135             my $param = $params->{$key};
2136             my $value = defined($param) ? $param : '';
2137             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2138         }
2139         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2140     }
2141 }
2142
2143 =head2 $c->log_request_uploads
2144
2145 Logs file uploads included in the request to the debug logs.
2146 The parameter name, filename, file type, and file size are all included in
2147 the debug logs.
2148
2149 =cut
2150
2151 sub log_request_uploads {
2152     my $c = shift;
2153     my $request = shift;
2154     return unless $c->debug;
2155     my $uploads = $request->uploads;
2156     if ( keys %$uploads ) {
2157         my $t = Text::SimpleTable->new(
2158             [ 12, 'Parameter' ],
2159             [ 26, 'Filename' ],
2160             [ 18, 'Type' ],
2161             [ 9,  'Size' ]
2162         );
2163         for my $key ( sort keys %$uploads ) {
2164             my $upload = $uploads->{$key};
2165             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2166                 $t->row( $key, $u->filename, $u->type, $u->size );
2167             }
2168         }
2169         $c->log->debug( "File Uploads are:\n" . $t->draw );
2170     }
2171 }
2172
2173 =head2 $c->log_request_headers($headers);
2174
2175 Hook method which can be wrapped by plugins to log the request headers.
2176 No-op in the default implementation.
2177
2178 =cut
2179
2180 sub log_request_headers {}
2181
2182 =head2 $c->log_headers($type => $headers)
2183
2184 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2185
2186 =cut
2187
2188 sub log_headers {
2189     my $c       = shift;
2190     my $type    = shift;
2191     my $headers = shift;    # an HTTP::Headers instance
2192
2193     return unless $c->debug;
2194
2195     my $column_width = Catalyst::Utils::term_width() - 28;
2196     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2197     $headers->scan(
2198         sub {
2199             my ( $name, $value ) = @_;
2200             $t->row( $name, $value );
2201         }
2202     );
2203     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2204 }
2205
2206
2207 =head2 $c->prepare_read
2208
2209 Prepares the input for reading.
2210
2211 =cut
2212
2213 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2214
2215 =head2 $c->prepare_request
2216
2217 Prepares the engine request.
2218
2219 =cut
2220
2221 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2222
2223 =head2 $c->prepare_uploads
2224
2225 Prepares uploads.
2226
2227 =cut
2228
2229 sub prepare_uploads {
2230     my $c = shift;
2231
2232     $c->engine->prepare_uploads( $c, @_ );
2233 }
2234
2235 =head2 $c->prepare_write
2236
2237 Prepares the output for writing.
2238
2239 =cut
2240
2241 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2242
2243 =head2 $c->request_class
2244
2245 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2246
2247 =head2 $c->response_class
2248
2249 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2250
2251 =head2 $c->read( [$maxlength] )
2252
2253 Reads a chunk of data from the request body. This method is designed to
2254 be used in a while loop, reading C<$maxlength> bytes on every call.
2255 C<$maxlength> defaults to the size of the request if not specified.
2256
2257 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2258 directly.
2259
2260 Warning: If you use read(), Catalyst will not process the body,
2261 so you will not be able to access POST parameters or file uploads via
2262 $c->request.  You must handle all body parsing yourself.
2263
2264 =cut
2265
2266 sub read { my $c = shift; return $c->request->read( @_ ) }
2267
2268 =head2 $c->run
2269
2270 Starts the engine.
2271
2272 =cut
2273
2274 sub run {
2275   my $app = shift;
2276   $app->_make_immutable_if_needed;
2277   $app->engine_loader->needs_psgi_engine_compat_hack ?
2278     $app->engine->run($app, @_) :
2279       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2280 }
2281
2282 sub _make_immutable_if_needed {
2283     my $class = shift;
2284     my $meta = Class::MOP::get_metaclass_by_name($class);
2285     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2286     if (
2287         $meta->is_immutable
2288         && ! { $meta->immutable_options }->{replace_constructor}
2289         && $isa_ca
2290     ) {
2291         warn("You made your application class ($class) immutable, "
2292             . "but did not inline the\nconstructor. "
2293             . "This will break catalyst, as your app \@ISA "
2294             . "Class::Accessor(::Fast)?\nPlease pass "
2295             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2296     }
2297     unless ($meta->is_immutable) {
2298         # XXX - FIXME warning here as you should make your app immutable yourself.
2299         $meta->make_immutable(
2300             replace_constructor => 1,
2301         );
2302     }
2303 }
2304
2305 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2306
2307 Sets an action in a given namespace.
2308
2309 =cut
2310
2311 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2312
2313 =head2 $c->setup_actions($component)
2314
2315 Sets up actions for a component.
2316
2317 =cut
2318
2319 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2320
2321 =head2 $c->setup_config
2322
2323 =cut
2324
2325 sub setup_config {
2326     my $class = shift;
2327
2328     my %args = %{ $class->config || {} };
2329
2330     my $container_class;
2331
2332     if ( exists $args{container_class} ) {
2333         $container_class = delete $args{container_class};
2334         Class::MOP::load_class($container_class);
2335     }
2336     else {
2337         $container_class = Class::MOP::load_first_existing_class("${class}::Container", 'Catalyst::IOC::Container');
2338     }
2339
2340     my $container = $container_class->new( %args, name => $class );
2341     $class->container($container);
2342
2343     my $config = $container->resolve( service => 'config' );
2344     $class->config($config);
2345     $class->finalize_config; # back-compat
2346 }
2347
2348 =head2 $c->finalize_config
2349
2350 =cut
2351
2352 sub finalize_config { }
2353
2354 =head2 $c->setup_components
2355
2356 This method is called internally to set up the application's components.
2357
2358 It finds modules by calling the L<locate_components> method, expands them to
2359 package names with the $container->expand_component_module method, and then
2360 installs each component into the application.
2361
2362 The C<setup_components> config option is passed to both of the above methods.
2363
2364 =cut
2365
2366 sub setup_components { shift->container->setup_components }
2367
2368 =head2 locate_components
2369
2370 =cut
2371
2372 sub locate_components {
2373     my $class = shift;
2374
2375     $class->log->warn('The locate_components method has been deprecated.');
2376     $class->log->warn('Please read Catalyst::IOC::Container documentation to');
2377     $class->log->warn('update your application.');
2378
2379     # XXX think about ditching this sort entirely
2380     return sort { length $a <=> length $b }
2381         @{ $class->container->resolve( service => 'locate_components' ) };
2382 }
2383
2384 =head2 $c->setup_dispatcher
2385
2386 Sets up dispatcher.
2387
2388 =cut
2389
2390 sub setup_dispatcher {
2391     my ( $class, $dispatcher ) = @_;
2392
2393     if ($dispatcher) {
2394         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2395     }
2396
2397     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2398         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2399     }
2400
2401     unless ($dispatcher) {
2402         $dispatcher = $class->dispatcher_class;
2403     }
2404
2405     Class::MOP::load_class($dispatcher);
2406
2407     # dispatcher instance
2408     $class->dispatcher( $dispatcher->new );
2409 }
2410
2411 =head2 $c->setup_engine
2412
2413 Sets up engine.
2414
2415 =cut
2416
2417 sub engine_class {
2418     my ($class, $requested_engine) = @_;
2419
2420     if (!$class->engine_loader || $requested_engine) {
2421         $class->engine_loader(
2422             Catalyst::EngineLoader->new({
2423                 application_name => $class,
2424                 (defined $requested_engine
2425                      ? (catalyst_engine_class => $requested_engine) : ()),
2426             }),
2427         );
2428     }
2429
2430     $class->engine_loader->catalyst_engine_class;
2431 }
2432
2433 sub setup_engine {
2434     my ($class, $requested_engine) = @_;
2435
2436     my $engine = do {
2437         my $loader = $class->engine_loader;
2438
2439         if (!$loader || $requested_engine) {
2440             $loader = Catalyst::EngineLoader->new({
2441                 application_name => $class,
2442                 (defined $requested_engine
2443                      ? (requested_engine => $requested_engine) : ()),
2444             }),
2445
2446             $class->engine_loader($loader);
2447         }
2448
2449         $loader->catalyst_engine_class;
2450     };
2451
2452     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2453     return if $class->loading_psgi_file;
2454
2455     Class::MOP::load_class($engine);
2456
2457     if ($ENV{MOD_PERL}) {
2458         my $apache = $class->engine_loader->auto;
2459
2460         my $meta = find_meta($class);
2461         my $was_immutable = $meta->is_immutable;
2462         my %immutable_options = $meta->immutable_options;
2463         $meta->make_mutable if $was_immutable;
2464
2465         $meta->add_method(handler => sub {
2466             my $r = shift;
2467             my $psgi_app = $class->_finalized_psgi_app;
2468             $apache->call_app($r, $psgi_app);
2469         });
2470
2471         $meta->make_immutable(%immutable_options) if $was_immutable;
2472     }
2473
2474     $class->engine( $engine->new );
2475
2476     return;
2477 }
2478
2479 sub _finalized_psgi_app {
2480     my ($app) = @_;
2481
2482     unless ($app->_psgi_app) {
2483         my $psgi_app = $app->_setup_psgi_app;
2484         $app->_psgi_app($psgi_app);
2485     }
2486
2487     return $app->_psgi_app;
2488 }
2489
2490 sub _setup_psgi_app {
2491     my ($app) = @_;
2492
2493     for my $home (Path::Class::Dir->new($app->config->{home})) {
2494         my $psgi_file = $home->file(
2495             Catalyst::Utils::appprefix($app) . '.psgi',
2496         );
2497
2498         next unless -e $psgi_file;
2499
2500         # If $psgi_file calls ->setup_engine, it's doing so to load
2501         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2502         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2503         # anyway. So set a flag (ick) that tells setup_engine not to populate
2504         # $c->engine or do any other things we might regret.
2505
2506         $app->loading_psgi_file(1);
2507         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2508         $app->loading_psgi_file(0);
2509
2510         return $psgi_app
2511             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2512
2513         warn <<"EOW";
2514 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2515
2516 Its content has been ignored. Please consult the Catalyst::Upgrading
2517 documentation on how to upgrade from Catalyst::Engine::PSGI.
2518 EOW
2519     }
2520
2521     return $app->apply_default_middlewares($app->psgi_app);
2522 }
2523
2524 =head2 $c->apply_default_middlewares
2525
2526 Adds the following L<Plack> middlewares to your application, since they are
2527 useful and commonly needed:
2528
2529 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2530 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2531 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2532 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2533 applied since this middleware is smart enough to conditionally apply itself).
2534
2535 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2536 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2537 $ENV{SCRIPT_NAME}
2538
2539 =cut
2540
2541
2542 sub apply_default_middlewares {
2543     my ($app, $psgi_app) = @_;
2544
2545     $psgi_app = Plack::Middleware::Conditional->wrap(
2546         $psgi_app,
2547         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2548         condition => sub {
2549             my ($env) = @_;
2550             return if $app->config->{ignore_frontend_proxy};
2551             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2552                 || $app->config->{using_frontend_proxy};
2553         },
2554     );
2555
2556     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2557     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2558     $psgi_app = Plack::Middleware::Conditional->wrap(
2559         $psgi_app,
2560         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2561         condition => sub {
2562             my ($env) = @_;
2563             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2564             return unless $1 < 4.23;
2565             1;
2566         },
2567     );
2568
2569     # we're applying this unconditionally as the middleware itself already makes
2570     # sure it doesn't fuck things up if it's not running under one of the right
2571     # IIS versions
2572     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2573
2574     return $psgi_app;
2575 }
2576
2577 =head2 $c->psgi_app
2578
2579 Returns a PSGI application code reference for the catalyst application
2580 C<$c>. This is the bare application without any middlewares
2581 applied. C<${myapp}.psgi> is not taken into account.
2582
2583 This is what you want to be using to retrieve the PSGI application code
2584 reference of your Catalyst application for use in F<.psgi> files.
2585
2586 =cut
2587
2588 sub psgi_app {
2589     my ($app) = @_;
2590     return $app->engine->build_psgi_app($app);
2591 }
2592
2593 =head2 $c->setup_home
2594
2595 Sets up the home directory.
2596
2597 =cut
2598
2599 sub setup_home {
2600     my ( $class, $home ) = @_;
2601
2602     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2603         $home = $env;
2604     }
2605
2606     $home ||= Catalyst::Utils::home($class);
2607
2608     if ($home) {
2609         #I remember recently being scolded for assigning config values like this
2610         $class->config->{home} ||= $home;
2611         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2612     }
2613 }
2614
2615 =head2 $c->setup_log
2616
2617 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2618 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2619 log to.
2620
2621 This method also installs a C<debug> method that returns a true value into the
2622 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2623 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2624
2625 Note that if the log has already been setup, by either a previous call to
2626 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2627 that this method won't actually set up the log object.
2628
2629 =cut
2630
2631 sub setup_log {
2632     my ( $class, $levels ) = @_;
2633
2634     $levels ||= '';
2635     $levels =~ s/^\s+//;
2636     $levels =~ s/\s+$//;
2637     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2638
2639     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2640     if ( defined $env_debug ) {
2641         $levels{debug} = 1 if $env_debug; # Ugly!
2642         delete($levels{debug}) unless $env_debug;
2643     }
2644
2645     unless ( $class->log ) {
2646         $class->log( Catalyst::Log->new(keys %levels) );
2647     }
2648
2649     if ( $levels{debug} ) {
2650         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2651         $class->log->debug('Debug messages enabled');
2652     }
2653 }
2654
2655 =head2 $c->setup_plugins
2656
2657 Sets up plugins.
2658
2659 =cut
2660
2661 =head2 $c->setup_stats
2662
2663 Sets up timing statistics class.
2664
2665 =cut
2666
2667 sub setup_stats {
2668     my ( $class, $stats ) = @_;
2669
2670     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2671
2672     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2673     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2674         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2675         $class->log->debug('Statistics enabled');
2676     }
2677 }
2678
2679
2680 =head2 $c->registered_plugins
2681
2682 Returns a sorted list of the plugins which have either been stated in the
2683 import list.
2684
2685 If passed a given plugin name, it will report a boolean value indicating
2686 whether or not that plugin is loaded.  A fully qualified name is required if
2687 the plugin name does not begin with C<Catalyst::Plugin::>.
2688
2689  if ($c->registered_plugins('Some::Plugin')) {
2690      ...
2691  }
2692
2693 =cut
2694
2695 {
2696
2697     sub registered_plugins {
2698         my $proto = shift;
2699         return sort keys %{ $proto->_plugins } unless @_;
2700         my $plugin = shift;
2701         return 1 if exists $proto->_plugins->{$plugin};
2702         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2703     }
2704
2705     sub _register_plugin {
2706         my ( $proto, $plugin, $instant ) = @_;
2707         my $class = ref $proto || $proto;
2708
2709         Class::MOP::load_class( $plugin );
2710         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2711             if $plugin->isa( 'Catalyst::Component' );
2712         my $plugin_meta = Moose::Meta::Class->create($plugin);
2713         if (!$plugin_meta->has_method('new')
2714             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
2715             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
2716         }
2717         if (!$instant && !$proto->_plugins->{$plugin}) {
2718             my $meta = Class::MOP::get_metaclass_by_name($class);
2719             $meta->superclasses($plugin, $meta->superclasses);
2720         }
2721         $proto->_plugins->{$plugin} = 1;
2722         return $class;
2723     }
2724
2725     sub setup_plugins {
2726         my ( $class, $plugins ) = @_;
2727
2728         $class->_plugins( {} ) unless $class->_plugins;
2729         $plugins = Data::OptList::mkopt($plugins || []);
2730
2731         my @plugins = map {
2732             [ Catalyst::Utils::resolve_namespace(
2733                   $class . '::Plugin',
2734                   'Catalyst::Plugin', $_->[0]
2735               ),
2736               $_->[1],
2737             ]
2738          } @{ $plugins };
2739
2740         for my $plugin ( reverse @plugins ) {
2741             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2742             my $meta = find_meta($plugin->[0]);
2743             next if $meta && $meta->isa('Moose::Meta::Role');
2744
2745             $class->_register_plugin($plugin->[0]);
2746         }
2747
2748         my @roles =
2749             map  { $_->[0]->name, $_->[1] }
2750             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2751             map  { [find_meta($_->[0]), $_->[1]] }
2752             @plugins;
2753
2754         Moose::Util::apply_all_roles(
2755             $class => @roles
2756         ) if @roles;
2757     }
2758 }
2759
2760 =head2 $c->stack
2761
2762 Returns an arrayref of the internal execution stack (actions that are
2763 currently executing).
2764
2765 =head2 $c->stats
2766
2767 Returns the current timing statistics object. By default Catalyst uses
2768 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2769 L<< stats_class|/"$c->stats_class" >>.
2770
2771 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2772 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2773 profile explicitly, although MyApp.pm still won't profile nor output anything
2774 by itself.
2775
2776 =head2 $c->stats_class
2777
2778 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2779
2780 =head2 $c->use_stats
2781
2782 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2783
2784 Note that this is a static method, not an accessor and should be overridden
2785 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2786
2787 =cut
2788
2789 sub use_stats { 0 }
2790
2791
2792 =head2 $c->write( $data )
2793
2794 Writes $data to the output stream. When using this method directly, you
2795 will need to manually set the C<Content-Length> header to the length of
2796 your output data, if known.
2797
2798 =cut
2799
2800 sub write {
2801     my $c = shift;
2802
2803     # Finalize headers if someone manually writes output (for compat)
2804     $c->finalize_headers;
2805
2806     return $c->response->write( @_ );
2807 }
2808
2809 =head2 version
2810
2811 Returns the Catalyst version number. Mostly useful for "powered by"
2812 messages in template systems.
2813
2814 =cut
2815
2816 sub version { return $Catalyst::VERSION }
2817
2818 =head1 CONFIGURATION
2819
2820 There are a number of 'base' config variables which can be set:
2821
2822 =over
2823
2824 =item *
2825
2826 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2827
2828 =item *
2829
2830 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2831
2832 =item *
2833
2834 C<home> - The application home directory. In an uninstalled application,
2835 this is the top level application directory. In an installed application,
2836 this will be the directory containing C<< MyApp.pm >>.
2837
2838 =item *
2839
2840 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2841
2842 =item *
2843
2844 C<name> - The name of the application in debug messages and the debug and
2845 welcome screens
2846
2847 =item *
2848
2849 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2850 until it is accessed. This allows you to (for example) check authentication (and reject
2851 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
2852
2853 =item *
2854
2855 C<root> - The root directory for templates. Usually this is just a
2856 subdirectory of the home directory, but you can set it to change the
2857 templates to a different directory.
2858
2859 =item *
2860
2861 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2862 to be shown in hit debug tables in the test server.
2863
2864 =item *
2865
2866 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
2867 variable should be used for determining the request path.
2868
2869 Most web server environments pass the requested path to the application using environment variables,
2870 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
2871 exposed as C<< $c->request->base >>) and the request path below that base.
2872
2873 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
2874 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
2875
2876 =over
2877
2878 =item use_request_uri_for_path => 0
2879
2880 This is the default (and the) traditional method that Catalyst has used for determining the path information.
2881 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
2882 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
2883 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
2884
2885 However this method has the major disadvantage that it is impossible to correctly decode some elements
2886 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
2887 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
2888 can't distinguish / vs %2F in paths (in addition to other encoded values).
2889
2890 =item use_request_uri_for_path => 1
2891
2892 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
2893 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
2894 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
2895
2896 Given that this method of path resolution is provably more correct, it is recommended that you use
2897 this unless you have a specific need to deploy your application in a non-standard environment, and you are
2898 aware of the implications of not being able to handle encoded URI paths correctly.
2899
2900 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
2901 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
2902 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
2903 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
2904 C<< $c->request->base >> will be incorrect.
2905
2906 =back
2907
2908 =item *
2909
2910 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2911
2912 =back
2913
2914 =head1 INTERNAL ACTIONS
2915
2916 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2917 C<_ACTION>, and C<_END>. These are by default not shown in the private
2918 action table, but you can make them visible with a config parameter.
2919
2920     MyApp->config(show_internal_actions => 1);
2921
2922 =head1 ON-DEMAND PARSER
2923
2924 The request body is usually parsed at the beginning of a request,
2925 but if you want to handle input yourself, you can enable on-demand
2926 parsing with a config parameter.
2927
2928     MyApp->config(parse_on_demand => 1);
2929
2930 =head1 PROXY SUPPORT
2931
2932 Many production servers operate using the common double-server approach,
2933 with a lightweight frontend web server passing requests to a larger
2934 backend server. An application running on the backend server must deal
2935 with two problems: the remote user always appears to be C<127.0.0.1> and
2936 the server's hostname will appear to be C<localhost> regardless of the
2937 virtual host that the user connected through.
2938
2939 Catalyst will automatically detect this situation when you are running
2940 the frontend and backend servers on the same machine. The following
2941 changes are made to the request.
2942
2943     $c->req->address is set to the user's real IP address, as read from
2944     the HTTP X-Forwarded-For header.
2945
2946     The host value for $c->req->base and $c->req->uri is set to the real
2947     host, as read from the HTTP X-Forwarded-Host header.
2948
2949 Additionally, you may be running your backend application on an insecure
2950 connection (port 80) while your frontend proxy is running under SSL.  If there
2951 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2952 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2953 be created properly.
2954
2955 In the case of passing in:
2956
2957     X-Forwarded-Port: 443
2958
2959 All calls to C<uri_for> will result in an https link, as is expected.
2960
2961 Obviously, your web server must support these headers for this to work.
2962
2963 In a more complex server farm environment where you may have your
2964 frontend proxy server(s) on different machines, you will need to set a
2965 configuration option to tell Catalyst to read the proxied data from the
2966 headers.
2967
2968     MyApp->config(using_frontend_proxy => 1);
2969
2970 If you do not wish to use the proxy support at all, you may set:
2971
2972     MyApp->config(ignore_frontend_proxy => 0);
2973
2974 =head2 Note about psgi files
2975
2976 Note that if you supply your own .psgi file, calling
2977 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
2978
2979 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
2980 in your psgi, for example:
2981
2982     builder {
2983         enable "Plack::Middleware::ReverseProxy";
2984         MyApp->psgi_app
2985     };
2986
2987 This will unconditionally add the ReverseProxy support, or you need to call
2988 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
2989 apply the support depending upon your config).
2990
2991 See L<Catalyst::PSGI> for more information.
2992
2993 =head1 THREAD SAFETY
2994
2995 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2996 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2997 believe the Catalyst core to be thread-safe.
2998
2999 If you plan to operate in a threaded environment, remember that all other
3000 modules you are using must also be thread-safe. Some modules, most notably
3001 L<DBD::SQLite>, are not thread-safe.
3002
3003 =head1 SUPPORT
3004
3005 IRC:
3006
3007     Join #catalyst on irc.perl.org.
3008
3009 Mailing Lists:
3010
3011     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3012     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3013
3014 Web:
3015
3016     http://catalyst.perl.org
3017
3018 Wiki:
3019
3020     http://dev.catalyst.perl.org
3021
3022 =head1 SEE ALSO
3023
3024 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3025
3026 =head2 L<Catalyst::Manual> - The Catalyst Manual
3027
3028 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3029
3030 =head2 L<Catalyst::Engine> - Core engine
3031
3032 =head2 L<Catalyst::Log> - Log class.
3033
3034 =head2 L<Catalyst::Request> - Request object
3035
3036 =head2 L<Catalyst::Response> - Response object
3037
3038 =head2 L<Catalyst::Test> - The test suite.
3039
3040 =head1 PROJECT FOUNDER
3041
3042 sri: Sebastian Riedel <sri@cpan.org>
3043
3044 =head1 CONTRIBUTORS
3045
3046 abw: Andy Wardley
3047
3048 acme: Leon Brocard <leon@astray.com>
3049
3050 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3051
3052 Andrew Bramble
3053
3054 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3055
3056 Andrew Ruthven
3057
3058 André Walker
3059
3060 andyg: Andy Grundman <andy@hybridized.org>
3061
3062 audreyt: Audrey Tang
3063
3064 bricas: Brian Cassidy <bricas@cpan.org>
3065
3066 Caelum: Rafael Kitover <rkitover@io.com>
3067
3068 chansen: Christian Hansen
3069
3070 chicks: Christopher Hicks
3071
3072 Chisel Wright C<pause@herlpacker.co.uk>
3073
3074 Danijel Milicevic C<me@danijel.de>
3075
3076 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3077
3078 David Naughton, C<naughton@umn.edu>
3079
3080 David E. Wheeler
3081
3082 dhoss: Devin Austin <dhoss@cpan.org>
3083
3084 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3085
3086 Drew Taylor
3087
3088 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3089
3090 esskar: Sascha Kiefer
3091
3092 fireartist: Carl Franks <cfranks@cpan.org>
3093
3094 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3095
3096 gabb: Danijel Milicevic
3097
3098 Gary Ashton Jones
3099
3100 Gavin Henry C<ghenry@perl.me.uk>
3101
3102 Geoff Richards
3103
3104 groditi: Guillermo Roditi <groditi@gmail.com>
3105
3106 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3107
3108 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3109
3110 jcamacho: Juan Camacho
3111
3112 jester: Jesse Sheidlower C<jester@panix.com>
3113
3114 jhannah: Jay Hannah <jay@jays.net>
3115
3116 Jody Belka
3117
3118 Johan Lindstrom
3119
3120 jon: Jon Schutz <jjschutz@cpan.org>
3121
3122 Jonathan Rockway C<< <jrockway@cpan.org> >>
3123
3124 Kieren Diment C<kd@totaldatasolution.com>
3125
3126 konobi: Scott McWhirter <konobi@cpan.org>
3127
3128 marcus: Marcus Ramberg <mramberg@cpan.org>
3129
3130 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3131
3132 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3133
3134 mugwump: Sam Vilain
3135
3136 naughton: David Naughton
3137
3138 ningu: David Kamholz <dkamholz@cpan.org>
3139
3140 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3141
3142 numa: Dan Sully <daniel@cpan.org>
3143
3144 obra: Jesse Vincent
3145
3146 Octavian Rasnita
3147
3148 omega: Andreas Marienborg
3149
3150 Oleg Kostyuk <cub.uanic@gmail.com>
3151
3152 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3153
3154 rafl: Florian Ragwitz <rafl@debian.org>
3155
3156 random: Roland Lammel <lammel@cpan.org>
3157
3158 Robert Sedlacek C<< <rs@474.at> >>
3159
3160 SpiceMan: Marcel Montes
3161
3162 sky: Arthur Bergman
3163
3164 szbalint: Balint Szilakszi <szbalint@cpan.org>
3165
3166 t0m: Tomas Doran <bobtfish@bobtfish.net>
3167
3168 Ulf Edvinsson
3169
3170 Viljo Marrandi C<vilts@yahoo.com>
3171
3172 Will Hawes C<info@whawes.co.uk>
3173
3174 willert: Sebastian Willert <willert@cpan.org>
3175
3176 wreis: Wallace Reis <wallace@reis.org.br>
3177
3178 Yuval Kogman, C<nothingmuch@woobling.org>
3179
3180 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3181
3182 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3183
3184 =head1 COPYRIGHT
3185
3186 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3187
3188 =head1 LICENSE
3189
3190 This library is free software. You can redistribute it and/or modify it under
3191 the same terms as Perl itself.
3192
3193 =cut
3194
3195 no Moose;
3196
3197 __PACKAGE__->meta->make_immutable;
3198
3199 1;