lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54 use Scalar::Util;
  55 use Ref::Util qw(is_plain_arrayref is_plain_coderef is_plain_hashref is_plain_scalarref is_regexpref);
  56
  57 BEGIN { require 5.008003; }
  58
  59 has stack => (is => 'ro', default => sub { [] });
  60 has state => (is => 'rw', default => 0);
  61 has stats => (is => 'rw');
  62 has action => (is => 'rw');
  63 has counter => (is => 'rw', default => sub { {} });
  64 has request => (
  65     is => 'rw',
  66     default => sub {
  67         my $self = shift;
  68         my $class = ref $self;
  69         my $composed_request_class = $class->composed_request_class;
  70         return $composed_request_class->new( $self->_build_request_constructor_args);
  71     },
  72     lazy => 1,
  73 );
  74 sub _build_request_constructor_args {
  75     my $self = shift;
  76     my %p = ( _log => $self->log );
  77     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  78     $p{data_handlers} = {$self->registered_data_handlers};
  79     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  80       if $self->config->{use_hash_multivalue_in_request};
  81     \%p;
  82 }
  83
  84 sub composed_request_class {
  85   my $class = shift;
  86   return $class->_composed_request_class if $class->_composed_request_class;
  87
  88   my @traits = (@{$class->request_class_traits||[]}, @{$class->config->{request_class_traits}||[]});
  89
  90   # For each trait listed, figure out what the namespace is.  First we try the $trait
  91   # as it is in the config.  Then try $MyApp::TraitFor::Request:$trait. Last we try
  92   # Catalyst::TraitFor::Request::$trait.  If none load, throw error.
  93
  94   my $trait_ns = 'TraitFor::Request';
  95   my @normalized_traits = map {
  96     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
  97   } @traits;
  98
  99   if ($class->debug && scalar(@normalized_traits)) {
 100       my $column_width = Catalyst::Utils::term_width() - 6;
 101       my $t = Text::SimpleTable->new($column_width);
 102       $t->row($_) for @normalized_traits;
 103       $class->log->debug( "Composed Request Class Traits:\n" . $t->draw . "\n" );
 104   }
 105
 106   return $class->_composed_request_class(Moose::Util::with_traits($class->request_class, @normalized_traits));
 107 }
 108
 109 has response => (
 110     is => 'rw',
 111     default => sub {
 112         my $self = shift;
 113         my $class = ref $self;
 114         my $composed_response_class = $class->composed_response_class;
 115         return $composed_response_class->new( $self->_build_response_constructor_args);
 116     },
 117     lazy => 1,
 118 );
 119 sub _build_response_constructor_args {
 120     return +{
 121       _log => $_[0]->log,
 122       encoding => $_[0]->encoding,
 123     };
 124 }
 125
 126 sub composed_response_class {
 127   my $class = shift;
 128   return $class->_composed_response_class if $class->_composed_response_class;
 129
 130   my @traits = (@{$class->response_class_traits||[]}, @{$class->config->{response_class_traits}||[]});
 131
 132   my $trait_ns = 'TraitFor::Response';
 133   my @normalized_traits = map {
 134     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
 135   } @traits;
 136
 137   if ($class->debug && scalar(@normalized_traits)) {
 138       my $column_width = Catalyst::Utils::term_width() - 6;
 139       my $t = Text::SimpleTable->new($column_width);
 140       $t->row($_) for @normalized_traits;
 141       $class->log->debug( "Composed Response Class Traits:\n" . $t->draw . "\n" );
 142   }
 143
 144   return $class->_composed_response_class(Moose::Util::with_traits($class->response_class, @normalized_traits));
 145 }
 146
 147 has namespace => (is => 'rw');
 148
 149 sub depth { scalar @{ shift->stack || [] }; }
 150 sub comp { shift->component(@_) }
 151
 152 sub req {
 153     my $self = shift; return $self->request(@_);
 154 }
 155 sub res {
 156     my $self = shift; return $self->response(@_);
 157 }
 158
 159 # For backwards compatibility
 160 sub finalize_output { shift->finalize_body(@_) };
 161
 162 # For statistics
 163 our $COUNT     = 1;
 164 our $START     = time;
 165 our $RECURSION = 1000;
 166 our $DETACH    = Catalyst::Exception::Detach->new;
 167 our $GO        = Catalyst::Exception::Go->new;
 168
 169 #I imagine that very few of these really
 170 #need to be class variables. if any.
 171 #maybe we should just make them attributes with a default?
 172 __PACKAGE__->mk_classdata($_)
 173   for qw/components arguments dispatcher engine log dispatcher_class
 174   engine_loader context_class request_class response_class stats_class
 175   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 176   _data_handlers _encoding _encode_check finalized_default_middleware
 177   request_class_traits response_class_traits stats_class_traits
 178   _composed_request_class _composed_response_class _composed_stats_class/;
 179
 180 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 181 __PACKAGE__->request_class('Catalyst::Request');
 182 __PACKAGE__->response_class('Catalyst::Response');
 183 __PACKAGE__->stats_class('Catalyst::Stats');
 184
 185 sub composed_stats_class {
 186   my $class = shift;
 187   return $class->_composed_stats_class if $class->_composed_stats_class;
 188
 189   my @traits = (@{$class->stats_class_traits||[]}, @{$class->config->{stats_class_traits}||[]});
 190
 191   my $trait_ns = 'TraitFor::Stats';
 192   my @normalized_traits = map {
 193     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
 194   } @traits;
 195
 196   if ($class->debug && scalar(@normalized_traits)) {
 197       my $column_width = Catalyst::Utils::term_width() - 6;
 198       my $t = Text::SimpleTable->new($column_width);
 199       $t->row($_) for @normalized_traits;
 200       $class->log->debug( "Composed Stats Class Traits:\n" . $t->draw . "\n" );
 201   }
 202
 203   return $class->_composed_stats_class(Moose::Util::with_traits($class->stats_class, @normalized_traits));
 204 }
 205
 206 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 207
 208 # Remember to update this in Catalyst::Runtime as well!
 209 our $VERSION = '5.90114';
 210 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 211
 212 sub import {
 213     my ( $class, @arguments ) = @_;
 214
 215     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 216     # callers @ISA.
 217     return unless $class eq 'Catalyst';
 218
 219     my $caller = caller();
 220     return if $caller eq 'main';
 221
 222     my $meta = Moose::Meta::Class->initialize($caller);
 223     unless ( $caller->isa('Catalyst') ) {
 224         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 225         $meta->superclasses(@superclasses);
 226     }
 227     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 228     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 229
 230     unless( $meta->has_method('meta') ){
 231         if ($Moose::VERSION >= 1.15) {
 232             $meta->_add_meta_method('meta');
 233         }
 234         else {
 235             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 236         }
 237     }
 238
 239     $caller->arguments( [@arguments] );
 240     $caller->setup_home;
 241 }
 242
 243 sub _application { $_[0] }
 244
 245 =encoding UTF-8
 246
 247 =head1 NAME
 248
 249 Catalyst - The Elegant MVC Web Application Framework
 250
 251 =for html
 252 <a href="https://badge.fury.io/pl/Catalyst-Runtime"><img src="https://badge.fury.io/pl/Catalyst-Runtime.svg" alt="CPAN version" height="18"></a>
 253 <a href="https://travis-ci.org/perl-catalyst/catalyst-runtime/"><img src="https://api.travis-ci.org/perl-catalyst/catalyst-runtime.png" alt="Catalyst></a>
 254 <a href="http://cpants.cpanauthors.org/dist/Catalyst-Runtime"><img src="http://cpants.cpanauthors.org/dist/Catalyst-Runtime.png" alt='Kwalitee Score' /></a>
 255
 256 =head1 SYNOPSIS
 257
 258 See the L<Catalyst::Manual> distribution for comprehensive
 259 documentation and tutorials.
 260
 261     # Install Catalyst::Devel for helpers and other development tools
 262     # use the helper to create a new application
 263     catalyst.pl MyApp
 264
 265     # add models, views, controllers
 266     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 267     script/myapp_create.pl view MyTemplate TT
 268     script/myapp_create.pl controller Search
 269
 270     # built in testserver -- use -r to restart automatically on changes
 271     # --help to see all available options
 272     script/myapp_server.pl
 273
 274     # command line testing interface
 275     script/myapp_test.pl /yada
 276
 277     ### in lib/MyApp.pm
 278     use Catalyst qw/-Debug/; # include plugins here as well
 279
 280     ### In lib/MyApp/Controller/Root.pm (autocreated)
 281     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 282         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 283         $c->stash->{template} = 'foo.tt'; # set the template
 284         # lookup something from db -- stash vars are passed to TT
 285         $c->stash->{data} =
 286           $c->model('Database::Foo')->search( { country => $args[0] } );
 287         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 288             $c->forward( 'bar' ); # process another action
 289             # do something else after forward returns
 290         }
 291     }
 292
 293     # The foo.tt TT template can use the stash data from the database
 294     [% WHILE (item = data.next) %]
 295         [% item.foo %]
 296     [% END %]
 297
 298     # called for /bar/of/soap, /bar/of/soap/10, etc.
 299     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 300
 301     # called after all actions are finished
 302     sub end : Action {
 303         my ( $self, $c ) = @_;
 304         if ( scalar @{ $c->error } ) { ... } # handle errors
 305         return if $c->res->body; # already have a response
 306         $c->forward( 'MyApp::View::TT' ); # render template
 307     }
 308
 309 See L<Catalyst::Manual::Intro> for additional information.
 310
 311 =head1 DESCRIPTION
 312
 313 Catalyst is a modern framework for making web applications without the
 314 pain usually associated with this process. This document is a reference
 315 to the main Catalyst application. If you are a new user, we suggest you
 316 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 317
 318 See L<Catalyst::Manual> for more documentation.
 319
 320 Catalyst plugins can be loaded by naming them as arguments to the "use
 321 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 322 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 323 C<My::Module>.
 324
 325     use Catalyst qw/My::Module/;
 326
 327 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 328 fully qualify the name by using a unary plus:
 329
 330     use Catalyst qw/
 331         My::Module
 332         +Fully::Qualified::Plugin::Name
 333     /;
 334
 335 Special flags like C<-Debug> can also be specified as
 336 arguments when Catalyst is loaded:
 337
 338     use Catalyst qw/-Debug My::Module/;
 339
 340 The position of plugins and flags in the chain is important, because
 341 they are loaded in the order in which they appear.
 342
 343 The following flags are supported:
 344
 345 =head2 -Debug
 346
 347 Enables debug output. You can also force this setting from the system
 348 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 349 settings override the application, with <MYAPP>_DEBUG having the highest
 350 priority.
 351
 352 This sets the log level to 'debug' and enables full debug output on the
 353 error screen. If you only want the latter, see L<< $c->debug >>.
 354
 355 =head2 -Home
 356
 357 Forces Catalyst to use a specific home directory, e.g.:
 358
 359     use Catalyst qw[-Home=/usr/mst];
 360
 361 This can also be done in the shell environment by setting either the
 362 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 363 is replaced with the uppercased name of your application, any "::" in
 364 the name will be replaced with underscores, e.g. MyApp::Web should use
 365 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 366
 367 If none of these are set, Catalyst will attempt to automatically detect the
 368 home directory. If you are working in a development environment, Catalyst
 369 will try and find the directory containing either Makefile.PL, Build.PL,
 370 dist.ini, or cpanfile. If the application has been installed into the system
 371 (i.e. you have done C<make install>), then Catalyst will use the path to your
 372 application module, without the .pm extension (e.g., /foo/MyApp if your
 373 application was installed at /foo/MyApp.pm)
 374
 375 =head2 -Log
 376
 377     use Catalyst '-Log=warn,fatal,error';
 378
 379 Specifies a comma-delimited list of log levels.
 380
 381 =head2 -Stats
 382
 383 Enables statistics collection and reporting.
 384
 385    use Catalyst qw/-Stats=1/;
 386
 387 You can also force this setting from the system environment with CATALYST_STATS
 388 or <MYAPP>_STATS. The environment settings override the application, with
 389 <MYAPP>_STATS having the highest priority.
 390
 391 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 392
 393 =head1 METHODS
 394
 395 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 396
 397 =head2 $c->action
 398
 399 Returns a L<Catalyst::Action> object for the current action, which
 400 stringifies to the action name. See L<Catalyst::Action>.
 401
 402 =head2 $c->namespace
 403
 404 Returns the namespace of the current action, i.e., the URI prefix
 405 corresponding to the controller of the current action. For example:
 406
 407     # in Controller::Foo::Bar
 408     $c->namespace; # returns 'foo/bar';
 409
 410 =head2 $c->request
 411
 412 =head2 $c->req
 413
 414 Returns the current L<Catalyst::Request> object, giving access to
 415 information about the current client request (including parameters,
 416 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 417
 418 =head2 REQUEST FLOW HANDLING
 419
 420 =head2 $c->forward( $action [, \@arguments ] )
 421
 422 =head2 $c->forward( $class, $method, [, \@arguments ] )
 423
 424 This is one way of calling another action (method) in the same or
 425 a different controller. You can also use C<< $self->my_method($c, @args) >>
 426 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 427 in a different controller.
 428 The main difference is that 'forward' uses some of the Catalyst request
 429 cycle overhead, including debugging, which may be useful to you. On the
 430 other hand, there are some complications to using 'forward', restrictions
 431 on values returned from 'forward', and it may not handle errors as you prefer.
 432 Whether you use 'forward' or not is up to you; it is not considered superior to
 433 the other ways to call a method.
 434
 435 'forward' calls  another action, by its private name. If you give a
 436 class name but no method, C<process()> is called. You may also optionally
 437 pass arguments in an arrayref. The action will receive the arguments in
 438 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 439 C<< $c->req->args >> will be restored to the previous values.
 440
 441 Any data C<return>ed from the action forwarded to, will be returned by the
 442 call to forward.
 443
 444     my $foodata = $c->forward('/foo');
 445     $c->forward('index');
 446     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 447     $c->forward('View::TT');
 448
 449 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 450 an C<< eval { } >> around the call (actually
 451 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 452 exceptions thrown by the called action non-fatal and pushing them onto
 453 $c->error instead. If you want C<die> to propagate you need to do something
 454 like:
 455
 456     $c->forward('foo');
 457     die join "\n", @{ $c->error } if @{ $c->error };
 458
 459 Or make sure to always return true values from your actions and write
 460 your code like this:
 461
 462     $c->forward('foo') || return;
 463
 464 Another note is that C<< $c->forward >> always returns a scalar because it
 465 actually returns $c->state which operates in a scalar context.
 466 Thus, something like:
 467
 468     return @array;
 469
 470 in an action that is forwarded to is going to return a scalar,
 471 i.e. how many items are in that array, which is probably not what you want.
 472 If you need to return an array then return a reference to it,
 473 or stash it like so:
 474
 475     $c->stash->{array} = \@array;
 476
 477 and access it from the stash.
 478
 479 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 480
 481 =cut
 482
 483 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 484
 485 =head2 $c->detach( $action [, \@arguments ] )
 486
 487 =head2 $c->detach( $class, $method, [, \@arguments ] )
 488
 489 =head2 $c->detach()
 490
 491 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 492 doesn't return to the previous action when processing is finished.
 493
 494 When called with no arguments it escapes the processing chain entirely.
 495
 496 =cut
 497
 498 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 499
 500 =head2 $c->visit( $action [, \@arguments ] )
 501
 502 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 503
 504 =head2 $c->visit( $class, $method, [, \@arguments ] )
 505
 506 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 507
 508 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 509 but does a full dispatch, instead of just calling the new C<$action> /
 510 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 511 you go to are called, just like a new request.
 512
 513 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 514 This means, for example, that C<< $c->action >> methods such as
 515 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 516 L<reverse|Catalyst::Action/reverse> return information for the visited action
 517 when they are invoked within the visited action.  This is different from the
 518 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 519 continues to use the $c->action object from the caller action even when
 520 invoked from the called action.
 521
 522 C<< $c->stash >> is kept unchanged.
 523
 524 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 525 allows you to "wrap" another action, just as it would have been called by
 526 dispatching from a URL, while the analogous
 527 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 528 transfer control to another action as if it had been reached directly from a URL.
 529
 530 =cut
 531
 532 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 533
 534 =head2 $c->go( $action [, \@arguments ] )
 535
 536 =head2 $c->go( $action [, \@captures, \@arguments ] )
 537
 538 =head2 $c->go( $class, $method, [, \@arguments ] )
 539
 540 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 541
 542 The relationship between C<go> and
 543 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 544 the relationship between
 545 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 546 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 547 C<< $c->go >> will perform a full dispatch on the specified action or method,
 548 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 549 C<go> escapes the processing of the current request chain on completion, and
 550 does not return to its caller.
 551
 552 @arguments are arguments to the final destination of $action. @captures are
 553 arguments to the intermediate steps, if any, on the way to the final sub of
 554 $action.
 555
 556 =cut
 557
 558 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 559
 560 =head2 $c->response
 561
 562 =head2 $c->res
 563
 564 Returns the current L<Catalyst::Response> object, see there for details.
 565
 566 =head2 $c->stash
 567
 568 Returns a hashref to the stash, which may be used to store data and pass
 569 it between components during a request. You can also set hash keys by
 570 passing arguments. The stash is automatically sent to the view. The
 571 stash is cleared at the end of a request; it cannot be used for
 572 persistent storage (for this you must use a session; see
 573 L<Catalyst::Plugin::Session> for a complete system integrated with
 574 Catalyst).
 575
 576     $c->stash->{foo} = $bar;
 577     $c->stash( { moose => 'majestic', qux => 0 } );
 578     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 579
 580     # stash is automatically passed to the view for use in a template
 581     $c->forward( 'MyApp::View::TT' );
 582
 583 The stash hash is currently stored in the PSGI C<$env> and is managed by
 584 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 585 the stash can be accessed in sub applications mounted under your main
 586 L<Catalyst> application.  For example if you delegate the response of an
 587 action to another L<Catalyst> application, that sub application will have
 588 access to all the stash keys of the main one, and if can of course add
 589 more keys of its own.  However those new keys will not 'bubble' back up
 590 to the main application.
 591
 592 For more information the best thing to do is to review the test case:
 593 t/middleware-stash.t in the distribution /t directory.
 594
 595 =cut
 596
 597 sub stash {
 598   my $c = shift;
 599   $c->log->error("You are requesting the stash but you don't have a context") unless blessed $c;
 600   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 601 }
 602
 603 =head2 $c->error
 604
 605 =head2 $c->error($error, ...)
 606
 607 =head2 $c->error($arrayref)
 608
 609 Returns an arrayref containing error messages.  If Catalyst encounters an
 610 error while processing a request, it stores the error in $c->error.  This
 611 method should only be used to store fatal error messages.
 612
 613     my @error = @{ $c->error };
 614
 615 Add a new error.
 616
 617     $c->error('Something bad happened');
 618
 619 Calling this will always return an arrayref (if there are no errors it
 620 will be an empty arrayref.
 621
 622 =cut
 623
 624 sub error {
 625     my $c = shift;
 626     if ( $_[0] ) {
 627         my $error = is_plain_arrayref($_[0]) ? $_[0] : [@_];
 628         croak @$error unless ref $c;
 629         push @{ $c->{error} }, @$error;
 630     }
 631     elsif ( defined $_[0] ) { $c->{error} = undef }
 632     return $c->{error} || [];
 633 }
 634
 635 =head2 $c->state
 636
 637 Contains the return value of the last executed action.
 638 Note that << $c->state >> operates in a scalar context which means that all
 639 values it returns are scalar.
 640
 641 Please note that if an action throws an exception, the value of state
 642 should no longer be considered the return if the last action.  It is generally
 643 going to be 0, which indicates an error state.  Examine $c->error for error
 644 details.
 645
 646 =head2 $c->clear_errors
 647
 648 Clear errors.  You probably don't want to clear the errors unless you are
 649 implementing a custom error screen.
 650
 651 This is equivalent to running
 652
 653     $c->error(0);
 654
 655 =cut
 656
 657 sub clear_errors {
 658     my $c = shift;
 659     $c->error(0);
 660 }
 661
 662 =head2 $c->has_errors
 663
 664 Returns true if you have errors
 665
 666 =cut
 667
 668 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 669
 670 =head2 $c->last_error
 671
 672 Returns the most recent error in the stack (the one most recently added...)
 673 or nothing if there are no errors.  This does not modify the contents of the
 674 error stack.
 675
 676 =cut
 677
 678 sub last_error {
 679   my (@errs) = @{shift->error};
 680   return scalar(@errs) ? $errs[-1]: undef;
 681 }
 682
 683 =head2 shift_errors
 684
 685 shifts the most recently added error off the error stack and returns it.  Returns
 686 nothing if there are no more errors.
 687
 688 =cut
 689
 690 sub shift_errors {
 691     my ($self) = @_;
 692     my @errors = @{$self->error};
 693     my $err = shift(@errors);
 694     $self->{error} = \@errors;
 695     return $err;
 696 }
 697
 698 =head2 pop_errors
 699
 700 pops the most recently added error off the error stack and returns it.  Returns
 701 nothing if there are no more errors.
 702
 703 =cut
 704
 705 sub pop_errors {
 706     my ($self) = @_;
 707     my @errors = @{$self->error};
 708     my $err = pop(@errors);
 709     $self->{error} = \@errors;
 710     return $err;
 711 }
 712
 713 sub _comp_search_prefixes {
 714     my $c = shift;
 715     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 716 }
 717
 718 # search components given a name and some prefixes
 719 sub _comp_names_search_prefixes {
 720     my ( $c, $name, @prefixes ) = @_;
 721     my $appclass = ref $c || $c;
 722     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 723     $filter = qr/$filter/; # Compile regex now rather than once per loop
 724
 725     # map the original component name to the sub part that we will search against
 726     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 727         grep { /$filter/ } keys %{ $c->components };
 728
 729     # undef for a name will return all
 730     return keys %eligible if !defined $name;
 731
 732     my $query  = is_regexpref($name) ? $name : qr/^$name$/i;
 733     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 734
 735     return @result if @result;
 736
 737     # if we were given a regexp to search against, we're done.
 738     return if is_regexpref($name);
 739
 740     # skip regexp fallback if configured
 741     return
 742         if $appclass->config->{disable_component_resolution_regex_fallback};
 743
 744     # regexp fallback
 745     $query  = qr/$name/i;
 746     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 747
 748     # no results? try against full names
 749     if( !@result ) {
 750         @result = grep { m{$query} } keys %eligible;
 751     }
 752
 753     # don't warn if we didn't find any results, it just might not exist
 754     if( @result ) {
 755         # Disgusting hack to work out correct method name
 756         my $warn_for = lc $prefixes[0];
 757         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 758            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 759            "component resolution is unreliable and unsafe.";
 760         my $short = $result[0];
 761         # remove the component namespace prefix
 762         $short =~ s/.*?(Model|Controller|View):://;
 763         my $shortmess = Carp::shortmess('');
 764         if ($shortmess =~ m#Catalyst/Plugin#) {
 765            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 766               "plugin's config";
 767         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 768            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 769               "component's config";
 770         } else {
 771            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 772               "but if you really wanted to search, pass in a regexp as the argument " .
 773               "like so: \$c->${warn_for}(qr/${name}/)";
 774         }
 775         $c->log->warn( "${msg}$shortmess" );
 776     }
 777
 778     return @result;
 779 }
 780
 781 # Find possible names for a prefix
 782 sub _comp_names {
 783     my ( $c, @prefixes ) = @_;
 784     my $appclass = ref $c || $c;
 785
 786     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 787
 788     my @names = map { s{$filter}{}; $_; }
 789         $c->_comp_names_search_prefixes( undef, @prefixes );
 790
 791     return @names;
 792 }
 793
 794 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 795
 796 sub _filter_component {
 797     my ( $c, $comp, @args ) = @_;
 798
 799     if(is_plain_coderef($comp)) {
 800       $comp = $comp->();
 801     }
 802
 803     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 804       return $comp->ACCEPT_CONTEXT( $c, @args );
 805     }
 806
 807     $c->log->warn("You called component '${\$comp->catalyst_component_name}' with arguments [@args], but this component does not ACCEPT_CONTEXT, so args are ignored.") if scalar(@args) && $c->debug;
 808
 809     return $comp;
 810 }
 811
 812 =head2 COMPONENT ACCESSORS
 813
 814 =head2 $c->controller($name)
 815
 816 Gets a L<Catalyst::Controller> instance by name.
 817
 818     $c->controller('Foo')->do_stuff;
 819
 820 If the name is omitted, will return the controller for the dispatched
 821 action.
 822
 823 If you want to search for controllers, pass in a regexp as the argument.
 824
 825     # find all controllers that start with Foo
 826     my @foo_controllers = $c->controller(qr{^Foo});
 827
 828
 829 =cut
 830
 831 sub controller {
 832     my ( $c, $name, @args ) = @_;
 833
 834     my $appclass = ref($c) || $c;
 835     if( $name ) {
 836         unless ( is_regexpref($name) ) { # Direct component hash lookup to avoid costly regexps
 837             my $comps = $c->components;
 838             my $check = $appclass."::Controller::".$name;
 839             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 840             foreach my $path (@{$appclass->config->{ setup_components }->{ search_extra }}) {
 841                 next unless $path =~ /.*::Controller/;
 842                 $check = $path."::".$name;
 843                 return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 844             }
 845         }
 846         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 847         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 848         return $c->_filter_component( $result[ 0 ], @args );
 849     }
 850
 851     return $c->component( $c->action->class );
 852 }
 853
 854 =head2 $c->model($name)
 855
 856 Gets a L<Catalyst::Model> instance by name.
 857
 858     $c->model('Foo')->do_stuff;
 859
 860 Any extra arguments are directly passed to ACCEPT_CONTEXT, if the model
 861 defines ACCEPT_CONTEXT.  If it does not, the args are discarded.
 862
 863 If the name is omitted, it will look for
 864  - a model object in $c->stash->{current_model_instance}, then
 865  - a model name in $c->stash->{current_model}, then
 866  - a config setting 'default_model', or
 867  - check if there is only one model, and return it if that's the case.
 868
 869 If you want to search for models, pass in a regexp as the argument.
 870
 871     # find all models that start with Foo
 872     my @foo_models = $c->model(qr{^Foo});
 873
 874 =cut
 875
 876 sub model {
 877     my ( $c, $name, @args ) = @_;
 878     my $appclass = ref($c) || $c;
 879     if( $name ) {
 880         unless ( is_regexpref($name) ) { # Direct component hash lookup to avoid costly regexps
 881             my $comps = $c->components;
 882             my $check = $appclass."::Model::".$name;
 883             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 884             foreach my $path (@{$appclass->config->{ setup_components }->{ search_extra }}) {
 885                 next unless $path =~ /.*::Model/;
 886                 $check = $path."::".$name;
 887                 return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 888             }
 889         }
 890         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 891         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 892         return $c->_filter_component( $result[ 0 ], @args );
 893     }
 894
 895     if (ref $c) {
 896         return $c->stash->{current_model_instance}
 897           if $c->stash->{current_model_instance};
 898         return $c->model( $c->stash->{current_model} )
 899           if $c->stash->{current_model};
 900     }
 901     return $c->model( $appclass->config->{default_model} )
 902       if $appclass->config->{default_model};
 903
 904     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 905
 906     if( $rest ) {
 907         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 908         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 909         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 910         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 911         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 912     }
 913
 914     return $c->_filter_component( $comp );
 915 }
 916
 917
 918 =head2 $c->view($name)
 919
 920 Gets a L<Catalyst::View> instance by name.
 921
 922     $c->view('Foo')->do_stuff;
 923
 924 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 925
 926 If the name is omitted, it will look for
 927  - a view object in $c->stash->{current_view_instance}, then
 928  - a view name in $c->stash->{current_view}, then
 929  - a config setting 'default_view', or
 930  - check if there is only one view, and return it if that's the case.
 931
 932 If you want to search for views, pass in a regexp as the argument.
 933
 934     # find all views that start with Foo
 935     my @foo_views = $c->view(qr{^Foo});
 936
 937 =cut
 938
 939 sub view {
 940     my ( $c, $name, @args ) = @_;
 941
 942     my $appclass = ref($c) || $c;
 943     if( $name ) {
 944         unless ( is_regexpref($name) ) { # Direct component hash lookup to avoid costly regexps
 945             my $comps = $c->components;
 946             my $check = $appclass."::View::".$name;
 947             if( exists $comps->{$check} ) {
 948                 return $c->_filter_component( $comps->{$check}, @args );
 949             }
 950             else {
 951                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 952             }
 953             foreach my $path (@{$appclass->config->{ setup_components }->{ search_extra }}) {
 954                 next unless $path =~ /.*::View/;
 955                 $check = $path."::".$name;
 956                 return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 957             }
 958         }
 959         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 960         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 961         return $c->_filter_component( $result[ 0 ], @args );
 962     }
 963
 964     if (ref $c) {
 965         return $c->stash->{current_view_instance}
 966           if $c->stash->{current_view_instance};
 967         return $c->view( $c->stash->{current_view} )
 968           if $c->stash->{current_view};
 969     }
 970     return $c->view( $appclass->config->{default_view} )
 971       if $appclass->config->{default_view};
 972
 973     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 974
 975     if( $rest ) {
 976         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 977         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 978         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 979         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 980         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 981     }
 982
 983     return $c->_filter_component( $comp );
 984 }
 985
 986 =head2 $c->controllers
 987
 988 Returns the available names which can be passed to $c->controller
 989
 990 =cut
 991
 992 sub controllers {
 993     my ( $c ) = @_;
 994     return $c->_comp_names(qw/Controller C/);
 995 }
 996
 997 =head2 $c->models
 998
 999 Returns the available names which can be passed to $c->model
1000
1001 =cut
1002
1003 sub models {
1004     my ( $c ) = @_;
1005     return $c->_comp_names(qw/Model M/);
1006 }
1007
1008
1009 =head2 $c->views
1010
1011 Returns the available names which can be passed to $c->view
1012
1013 =cut
1014
1015 sub views {
1016     my ( $c ) = @_;
1017     return $c->_comp_names(qw/View V/);
1018 }
1019
1020 =head2 $c->comp($name)
1021
1022 =head2 $c->component($name)
1023
1024 Gets a component object by name. This method is not recommended,
1025 unless you want to get a specific component by full
1026 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
1027 should be used instead.
1028
1029 If C<$name> is a regexp, a list of components matched against the full
1030 component name will be returned.
1031
1032 If Catalyst can't find a component by name, it will fallback to regex
1033 matching by default. To disable this behaviour set
1034 disable_component_resolution_regex_fallback to a true value.
1035
1036     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
1037
1038 =cut
1039
1040 sub component {
1041     my ( $c, $name, @args ) = @_;
1042
1043     if( $name ) {
1044         my $comps = $c->components;
1045
1046         if( !ref $name ) {
1047             # is it the exact name?
1048             return $c->_filter_component( $comps->{ $name }, @args )
1049                        if exists $comps->{ $name };
1050
1051             # perhaps we just omitted "MyApp"?
1052             my $composed = ( ref $c || $c ) . "::${name}";
1053             return $c->_filter_component( $comps->{ $composed }, @args )
1054                        if exists $comps->{ $composed };
1055
1056             # search all of the models, views and controllers
1057             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
1058             return $c->_filter_component( $comp, @args ) if $comp;
1059         }
1060
1061         return
1062             if $c->config->{disable_component_resolution_regex_fallback};
1063
1064         # This is here so $c->comp( '::M::' ) works
1065         my $query = ref $name ? $name : qr{$name}i;
1066
1067         my @result = grep { m{$query} } keys %{ $c->components };
1068         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
1069
1070         if( $result[ 0 ] ) {
1071             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
1072             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
1073             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
1074             return $c->_filter_component( $result[ 0 ], @args );
1075         }
1076
1077         # I would expect to return an empty list here, but that breaks back-compat
1078     }
1079
1080     # fallback
1081     return sort keys %{ $c->components };
1082 }
1083
1084 =head2 CLASS DATA AND HELPER CLASSES
1085
1086 =head2 $c->config
1087
1088 Returns or takes a hashref containing the application's configuration.
1089
1090     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
1091
1092 You can also use a C<YAML>, C<XML> or L<Config::General> config file
1093 like C<myapp.conf> in your applications home directory. See
1094 L<Catalyst::Plugin::ConfigLoader>.
1095
1096 =head3 Cascading configuration
1097
1098 The config method is present on all Catalyst components, and configuration
1099 will be merged when an application is started. Configuration loaded with
1100 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
1101 followed by configuration in your top level C<MyApp> class. These two
1102 configurations are merged, and then configuration data whose hash key matches a
1103 component name is merged with configuration for that component.
1104
1105 The configuration for a component is then passed to the C<new> method when a
1106 component is constructed.
1107
1108 For example:
1109
1110     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
1111     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
1112
1113 will mean that C<MyApp::Model::Foo> receives the following data when
1114 constructed:
1115
1116     MyApp::Model::Foo->new({
1117         bar => 'baz',
1118         quux => 'frob',
1119         overrides => 'me',
1120     });
1121
1122 It's common practice to use a Moose attribute
1123 on the receiving component to access the config value.
1124
1125     package MyApp::Model::Foo;
1126
1127     use Moose;
1128
1129     # this attr will receive 'baz' at construction time
1130     has 'bar' => (
1131         is  => 'rw',
1132         isa => 'Str',
1133     );
1134
1135 You can then get the value 'baz' by calling $c->model('Foo')->bar
1136 (or $self->bar inside code in the model).
1137
1138 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
1139 as a way of reading config within your code, as this B<will not> give you the
1140 correctly merged config back. You B<MUST> take the config values supplied to
1141 the constructor and use those instead.
1142
1143 =cut
1144
1145 around config => sub {
1146     my $orig = shift;
1147     my $c = shift;
1148
1149     croak('Setting config after setup has been run is not allowed.')
1150         if ( @_ and $c->setup_finished );
1151
1152     $c->$orig(@_);
1153 };
1154
1155 =head2 $c->log
1156
1157 Returns the logging object instance. Unless it is already set, Catalyst
1158 sets this up with a L<Catalyst::Log> object. To use your own log class,
1159 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1160 C<< __PACKAGE__->setup >>.
1161
1162  __PACKAGE__->log( MyLogger->new );
1163  __PACKAGE__->setup;
1164
1165 And later:
1166
1167     $c->log->info( 'Now logging with my own logger!' );
1168
1169 Your log class should implement the methods described in
1170 L<Catalyst::Log>.
1171
1172 =head2 has_encoding
1173
1174 Returned True if there's a valid encoding
1175
1176 =head2 clear_encoding
1177
1178 Clears the encoding for the current context
1179
1180 =head2 encoding
1181
1182 Sets or gets the application encoding.  Setting encoding takes either an
1183 Encoding object or a string that we try to resolve via L<Encode::find_encoding>.
1184
1185 You would expect to get the encoding object back if you attempt to set it.  If
1186 there is a failure you will get undef returned and an error message in the log.
1187
1188 =cut
1189
1190 sub has_encoding { shift->encoding ? 1:0 }
1191
1192 sub clear_encoding {
1193     my $c = shift;
1194     if(blessed $c) {
1195         $c->encoding(undef);
1196     } else {
1197         $c->log->error("You can't clear encoding on the application");
1198     }
1199 }
1200
1201 sub encoding {
1202     my $c = shift;
1203     my $encoding;
1204
1205     if ( scalar @_ ) {
1206
1207         # Don't let one change this once we are too far into the response
1208         if(blessed $c && $c->res->finalized_headers) {
1209           Carp::croak("You may not change the encoding once the headers are finalized");
1210           return;
1211         }
1212
1213         # Let it be set to undef
1214         if (my $wanted = shift)  {
1215             $encoding = Encode::find_encoding($wanted)
1216               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1217             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1218         }
1219         else {
1220             binmode(STDERR);
1221         }
1222
1223         $encoding = ref $c
1224                   ? $c->{encoding} = $encoding
1225                   : $c->_encoding($encoding);
1226     } else {
1227       $encoding = ref $c && exists $c->{encoding}
1228                 ? $c->{encoding}
1229                 : $c->_encoding;
1230     }
1231
1232     return $encoding;
1233 }
1234
1235 =head2 $c->debug
1236
1237 Returns 1 if debug mode is enabled, 0 otherwise.
1238
1239 You can enable debug mode in several ways:
1240
1241 =over
1242
1243 =item By calling myapp_server.pl with the -d flag
1244
1245 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1246
1247 =item The -Debug option in your MyApp.pm
1248
1249 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1250
1251 =back
1252
1253 The first three also set the log level to 'debug'.
1254
1255 Calling C<< $c->debug(1) >> has no effect.
1256
1257 =cut
1258
1259 sub debug { 0 }
1260
1261 =head2 $c->dispatcher
1262
1263 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1264
1265 =head2 $c->engine
1266
1267 Returns the engine instance. See L<Catalyst::Engine>.
1268
1269
1270 =head2 UTILITY METHODS
1271
1272 =head2 $c->path_to(@path)
1273
1274 Merges C<@path> with C<< $c->config->{home} >> and returns a
1275 L<Path::Class::Dir> object. Note you can usually use this object as
1276 a filename, but sometimes you will have to explicitly stringify it
1277 yourself by calling the C<< ->stringify >> method.
1278
1279 For example:
1280
1281     $c->path_to( 'db', 'sqlite.db' );
1282
1283 =cut
1284
1285 sub path_to {
1286     my ( $c, @path ) = @_;
1287     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1288     if ( -d $path ) { return $path }
1289     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1290 }
1291
1292 sub plugin {
1293     my ( $class, $name, $plugin, @args ) = @_;
1294
1295     # See block comment in t/unit_core_plugin.t
1296     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1297
1298     $class->_register_plugin( $plugin, 1 );
1299
1300     eval { $plugin->import };
1301     $class->mk_classdata($name);
1302     my $obj;
1303     eval { $obj = $plugin->new(@args) };
1304
1305     if ($@) {
1306         Catalyst::Exception->throw( message =>
1307               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1308     }
1309
1310     $class->$name($obj);
1311     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1312       if $class->debug;
1313 }
1314
1315 =head2 MyApp->setup
1316
1317 Initializes the dispatcher and engine, loads any plugins, and loads the
1318 model, view, and controller components. You may also specify an array
1319 of plugins to load here, if you choose to not load them in the C<use
1320 Catalyst> line.
1321
1322     MyApp->setup;
1323     MyApp->setup( qw/-Debug/ );
1324
1325 B<Note:> You B<should not> wrap this method with method modifiers
1326 or bad things will happen - wrap the C<setup_finalize> method instead.
1327
1328 B<Note:> You can create a custom setup stage that will execute when the
1329 application is starting.  Use this to customize setup.
1330
1331     MyApp->setup(-Custom=value);
1332
1333     sub setup_custom {
1334       my ($class, $value) = @_;
1335     }
1336
1337 Can be handy if you want to hook into the setup phase.
1338
1339 =cut
1340
1341 sub setup {
1342     my ( $class, @arguments ) = @_;
1343     croak('Running setup more than once')
1344         if ( $class->setup_finished );
1345
1346     unless ( $class->isa('Catalyst') ) {
1347
1348         Catalyst::Exception->throw(
1349             message => qq/'$class' does not inherit from Catalyst/ );
1350     }
1351
1352     if ( $class->arguments ) {
1353         @arguments = ( @arguments, @{ $class->arguments } );
1354     }
1355
1356     # Process options
1357     my $flags = {};
1358
1359     foreach (@arguments) {
1360
1361         if (/^-Debug$/) {
1362             $flags->{log} =
1363               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1364         }
1365         elsif (/^-(\w+)=?(.*)$/) {
1366             $flags->{ lc $1 } = $2;
1367         }
1368         else {
1369             push @{ $flags->{plugins} }, $_;
1370         }
1371     }
1372
1373     $class->setup_home( delete $flags->{home} );
1374
1375     $class->setup_log( delete $flags->{log} );
1376     $class->setup_plugins( delete $flags->{plugins} );
1377
1378     $class->setup_data_handlers();
1379     $class->setup_dispatcher( delete $flags->{dispatcher} );
1380     if (my $engine = delete $flags->{engine}) {
1381         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1382     }
1383     $class->setup_engine();
1384     $class->setup_stats( delete $flags->{stats} );
1385
1386     for my $flag ( sort keys %{$flags} ) {
1387
1388         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1389             &$code( $class, delete $flags->{$flag} );
1390         }
1391         else {
1392             $class->log->warn(qq/Unknown flag "$flag"/);
1393         }
1394     }
1395
1396     eval { require Catalyst::Devel; };
1397     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1398         $class->log->warn(<<"EOF");
1399 You are running an old script!
1400
1401   Please update by running (this will overwrite existing files):
1402     catalyst.pl -force -scripts $class
1403
1404   or (this will not overwrite existing files):
1405     catalyst.pl -scripts $class
1406
1407 EOF
1408     }
1409
1410     # Call plugins setup, this is stupid and evil.
1411     # Also screws C3 badly on 5.10, hack to avoid.
1412     {
1413         no warnings qw/redefine/;
1414         local *setup = sub { };
1415         $class->setup unless $Catalyst::__AM_RESTARTING;
1416     }
1417
1418     # If you are expecting configuration info as part of your setup, it needs
1419     # to get called here and below, since we need the above line to support
1420     # ConfigLoader based configs.
1421
1422     $class->setup_encoding();
1423     $class->setup_middleware();
1424
1425     # Initialize our data structure
1426     $class->components( {} );
1427
1428     $class->setup_components;
1429
1430     if ( $class->debug ) {
1431         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1432
1433         if (@plugins) {
1434             my $column_width = Catalyst::Utils::term_width() - 6;
1435             my $t = Text::SimpleTable->new($column_width);
1436             $t->row($_) for @plugins;
1437             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1438         }
1439
1440         my @middleware = map {
1441           is_plain_coderef($_) ?
1442             "Inline Coderef" :
1443               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1444                 || '')  } $class->registered_middlewares;
1445
1446         if (@middleware) {
1447             my $column_width = Catalyst::Utils::term_width() - 6;
1448             my $t = Text::SimpleTable->new($column_width);
1449             $t->row($_) for @middleware;
1450             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1451         }
1452
1453         my %dh = $class->registered_data_handlers;
1454         if (my @data_handlers = keys %dh) {
1455             my $column_width = Catalyst::Utils::term_width() - 6;
1456             my $t = Text::SimpleTable->new($column_width);
1457             $t->row($_) for @data_handlers;
1458             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1459         }
1460
1461         my $dispatcher = $class->dispatcher;
1462         my $engine     = $class->engine;
1463         my $home       = $class->config->{home};
1464
1465         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1466         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1467
1468         $home
1469           ? ( -d $home )
1470           ? $class->log->debug(qq/Found home "$home"/)
1471           : $class->log->debug(qq/Home "$home" doesn't exist/)
1472           : $class->log->debug(q/Couldn't find home/);
1473
1474         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1475
1476         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1477         for my $comp ( sort keys %{ $class->components } ) {
1478             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1479             $t->row( $comp, $type );
1480         }
1481         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1482           if ( keys %{ $class->components } );
1483     }
1484
1485     # Add our self to components, since we are also a component
1486     if( $class->isa('Catalyst::Controller') ){
1487       $class->components->{$class} = $class;
1488     }
1489
1490     $class->setup_actions;
1491
1492     if ( $class->debug ) {
1493         my $name = $class->config->{name} || 'Application';
1494         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1495     }
1496
1497     if ($class->config->{case_sensitive}) {
1498         $class->log->warn($class . "->config->{case_sensitive} is set.");
1499         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1500     }
1501
1502     # call these so we pre setup the composed classes
1503     $class->composed_request_class;
1504     $class->composed_response_class;
1505     $class->composed_stats_class;
1506
1507     $class->setup_finalize;
1508
1509     # Flush the log for good measure (in case something turned off 'autoflush' early)
1510     $class->log->_flush() if $class->log->can('_flush');
1511
1512     return $class || 1; # Just in case someone named their Application 0...
1513 }
1514
1515 =head2 $app->setup_finalize
1516
1517 A hook to attach modifiers to. This method does not do anything except set the
1518 C<setup_finished> accessor.
1519
1520 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1521
1522 Example:
1523
1524     after setup_finalize => sub {
1525         my $app = shift;
1526
1527         ## do stuff here..
1528     };
1529
1530 =cut
1531
1532 sub setup_finalize {
1533     my ($class) = @_;
1534     $class->setup_finished(1);
1535 }
1536
1537 =head2 $c->uri_for( $path?, @args?, \%query_values?, \$fragment? )
1538
1539 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values?, \$fragment? )
1540
1541 =head2 $c->uri_for( $action, [@captures, @args], \%query_values?, \$fragment? )
1542
1543 Constructs an absolute L<URI> object based on the application root, the
1544 provided path, and the additional arguments and query parameters provided.
1545 When used as a string, provides a textual URI.  If you need more flexibility
1546 than this (i.e. the option to provide relative URIs etc.) see
1547 L<Catalyst::Plugin::SmartURI>.
1548
1549 If no arguments are provided, the URI for the current action is returned.
1550 To return the current action and also provide @args, use
1551 C<< $c->uri_for( $c->action, @args ) >>.
1552
1553 If the first argument is a string, it is taken as a public URI path relative
1554 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1555 relative to the application root (if it does). It is then merged with
1556 C<< $c->request->base >>; any C<@args> are appended as additional path
1557 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1558
1559 B<NOTE> If you are using this 'stringy' first argument, we skip encoding and
1560 allow you to declare something like:
1561
1562     $c->uri_for('/foo/bar#baz')
1563
1564 Where 'baz' is a URI fragment.  We consider this first argument string to be
1565 'expert' mode where you are expected to create a valid URL and we for the most
1566 part just pass it through without a lot of internal effort to escape and encode.
1567
1568 If the first argument is a L<Catalyst::Action> it represents an action which
1569 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1570 optional C<\@captures> argument (an arrayref) allows passing the captured
1571 variables that are needed to fill in the paths of Chained and Regex actions;
1572 once the path is resolved, C<uri_for> continues as though a path was
1573 provided, appending any arguments or parameters and creating an absolute
1574 URI.
1575
1576 The captures for the current request can be found in
1577 C<< $c->request->captures >>, and actions can be resolved using
1578 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1579 path, use C<< $c->uri_for_action >> instead.
1580
1581   # Equivalent to $c->req->uri
1582   $c->uri_for($c->action, $c->req->captures,
1583       @{ $c->req->args }, $c->req->params);
1584
1585   # For the Foo action in the Bar controller
1586   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1587
1588   # Path to a static resource
1589   $c->uri_for('/static/images/logo.png');
1590
1591 In general the scheme of the generated URI object will follow the incoming request
1592 however if your targeted action or action chain has the Scheme attribute it will
1593 use that instead.
1594
1595 Also, if the targeted Action or Action chain declares Args/CaptureArgs that have
1596 type constraints, we will require that your proposed URL verify on those declared
1597 constraints.
1598
1599 =cut
1600
1601 sub uri_for {
1602     my ( $c, $path, @args ) = @_;
1603
1604     if ( $path->$_isa('Catalyst::Controller') ) {
1605         $path = $path->path_prefix;
1606         $path =~ s{/+\z}{};
1607         $path .= '/';
1608     }
1609
1610     my $fragment =  ((scalar(@args) && is_plain_scalarref($args[-1])) ? pop @args : undef );
1611
1612     unless(blessed $path) {
1613       if (defined($path) and $path =~ s/#(.+)$//)  {
1614         if(defined($1) and $fragment) {
1615           carp "Abiguious fragment declaration: You cannot define a fragment in '$path' and as an argument '$fragment'";
1616         }
1617         if(defined($1)) {
1618           $fragment = $1;
1619         }
1620       }
1621     }
1622
1623     my $params =
1624       ( scalar @args && is_plain_hashref($args[$#args]) ? pop @args : {} );
1625
1626     undef($path) if (defined $path && $path eq '');
1627
1628     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1629
1630     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1631     if ( $path->$_isa('Catalyst::Action') ) { # action object
1632         s|/|%2F|g for @args;
1633         my $captures = [ map { s|/|%2F|g; $_; }
1634                         ( scalar @args && is_plain_arrayref($args[0])
1635                          ? @{ shift(@args) }
1636                          : ()) ];
1637
1638         my $action = $path;
1639         my $expanded_action = $c->dispatcher->expand_action( $action );
1640         my $num_captures = $expanded_action->number_of_captures;
1641
1642         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1643         if( !@args && $action->number_of_args ) {
1644           unshift @args, splice @$captures, $num_captures;
1645         }
1646
1647         if($num_captures) {
1648           unless($expanded_action->match_captures_constraints($c, $captures)) {
1649             carp "captures [@{$captures}] do not match the type constraints in actionchain ending with '$expanded_action'";
1650             return;
1651           }
1652         }
1653
1654         $path = $c->dispatcher->uri_for_action($action, $captures);
1655         if (not defined $path) {
1656             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1657                 if $c->debug;
1658             return undef;
1659         }
1660         $path = '/' if $path eq '';
1661
1662         # At this point @encoded_args is the remaining Args (all captures removed).
1663         if($expanded_action->has_args_constraints) {
1664           unless($expanded_action->match_args($c,\@args)) {
1665              carp "args [@args] do not match the type constraints in action '$expanded_action'";
1666              return;
1667           }
1668         }
1669     }
1670
1671     unshift(@args, $path);
1672
1673     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1674         my $namespace = $c->namespace;
1675         if (defined $path) { # cheesy hack to handle path '../foo'
1676            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1677         }
1678         unshift(@args, $namespace || '');
1679     }
1680
1681     # join args with '/', or a blank string
1682     my $args = join('/', grep { defined($_) } @args);
1683     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1684     $args =~ s!^/+!!;
1685
1686     my ($base, $class) = ('/', 'URI::_generic');
1687     if(blessed($c)) {
1688       $base = $c->req->base;
1689       if($target_action) {
1690         $target_action = $c->dispatcher->expand_action($target_action);
1691         if(my $s = $target_action->scheme) {
1692           $s = lc($s);
1693           $class = "URI::$s";
1694           $base->scheme($s);
1695         } else {
1696           $class = ref($base);
1697         }
1698       } else {
1699         $class = ref($base);
1700       }
1701
1702       $base =~ s{(?<!/)$}{/};
1703     }
1704
1705     my $query = '';
1706     if (my @keys = keys %$params) {
1707       # somewhat lifted from URI::_query's query_form
1708       $query = '?'.join('&', map {
1709           my $val = $params->{$_};
1710           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1711           s/ /+/g;
1712           my $key = $_;
1713           $val = '' unless defined $val;
1714           (map {
1715               my $param = "$_";
1716               $param = encode_utf8($param);
1717               # using the URI::Escape pattern here so utf8 chars survive
1718               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1719               $param =~ s/ /+/g;
1720
1721               $key = encode_utf8($key);
1722               # using the URI::Escape pattern here so utf8 chars survive
1723               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1724               $key =~ s/ /+/g;
1725
1726               "${key}=$param"; } ( is_plain_arrayref($val) ? @$val : $val ));
1727       } @keys);
1728     }
1729
1730     $base = encode_utf8 $base;
1731     $base =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1732     $args = encode_utf8 $args;
1733     $args =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1734
1735     if(defined $fragment) {
1736       if(blessed $path) {
1737         $fragment = encode_utf8(${$fragment});
1738         $fragment =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1739         $fragment =~ s/ /+/g;
1740       }
1741       $query .= "#$fragment";
1742     }
1743
1744     my $res = bless(\"${base}${args}${query}", $class);
1745     $res;
1746 }
1747
1748 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1749
1750 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1751
1752 =over
1753
1754 =item $path
1755
1756 A private path to the Catalyst action you want to create a URI for.
1757
1758 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1759 >> and passing the resulting C<$action> and the remaining arguments to C<<
1760 $c->uri_for >>.
1761
1762 You can also pass in a Catalyst::Action object, in which case it is passed to
1763 C<< $c->uri_for >>.
1764
1765 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1766
1767 For example, if the action looks like:
1768
1769  package MyApp::Controller::Users;
1770
1771  sub lst : Path('the-list') {}
1772
1773 You can use:
1774
1775  $c->uri_for_action('/users/lst')
1776
1777 and it will create the URI /users/the-list.
1778
1779 =item \@captures_and_args?
1780
1781 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1782 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1783 to interpolate all the parameters in the URI.
1784
1785 =item @args?
1786
1787 Optional list of extra arguments - can be supplied in the
1788 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1789 code.
1790
1791 Your action can have zero, a fixed or a variable number of args (e.g.
1792 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1793
1794 =item \%query_values?
1795
1796 Optional array reference of query parameters to append. E.g.
1797
1798   { foo => 'bar' }
1799
1800 will generate
1801
1802   /rest/of/your/uri?foo=bar
1803
1804 =back
1805
1806 =cut
1807
1808 sub uri_for_action {
1809     my ( $c, $path, @args ) = @_;
1810     my $action = blessed($path)
1811       ? $path
1812       : $c->dispatcher->get_action_by_path($path);
1813     unless (defined $action) {
1814       croak "Can't find action for path '$path'";
1815     }
1816     return $c->uri_for( $action, @args );
1817 }
1818
1819 =head2 $c->welcome_message
1820
1821 Returns the Catalyst welcome HTML page.
1822
1823 =cut
1824
1825 sub welcome_message {
1826     my $c      = shift;
1827     my $name   = $c->config->{name};
1828     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1829     my $prefix = Catalyst::Utils::appprefix( ref $c );
1830     $c->response->content_type('text/html; charset=utf-8');
1831     return <<"EOF";
1832 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1833     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1834 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1835     <head>
1836     <meta http-equiv="Content-Language" content="en" />
1837     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1838         <title>$name on Catalyst $VERSION</title>
1839         <style type="text/css">
1840             body {
1841                 color: #000;
1842                 background-color: #eee;
1843             }
1844             div#content {
1845                 width: 640px;
1846                 margin-left: auto;
1847                 margin-right: auto;
1848                 margin-top: 10px;
1849                 margin-bottom: 10px;
1850                 text-align: left;
1851                 background-color: #ccc;
1852                 border: 1px solid #aaa;
1853             }
1854             p, h1, h2 {
1855                 margin-left: 20px;
1856                 margin-right: 20px;
1857                 font-family: verdana, tahoma, sans-serif;
1858             }
1859             a {
1860                 font-family: verdana, tahoma, sans-serif;
1861             }
1862             :link, :visited {
1863                     text-decoration: none;
1864                     color: #b00;
1865                     border-bottom: 1px dotted #bbb;
1866             }
1867             :link:hover, :visited:hover {
1868                     color: #555;
1869             }
1870             div#topbar {
1871                 margin: 0px;
1872             }
1873             pre {
1874                 margin: 10px;
1875                 padding: 8px;
1876             }
1877             div#answers {
1878                 padding: 8px;
1879                 margin: 10px;
1880                 background-color: #fff;
1881                 border: 1px solid #aaa;
1882             }
1883             h1 {
1884                 font-size: 0.9em;
1885                 font-weight: normal;
1886                 text-align: center;
1887             }
1888             h2 {
1889                 font-size: 1.0em;
1890             }
1891             p {
1892                 font-size: 0.9em;
1893             }
1894             p img {
1895                 float: right;
1896                 margin-left: 10px;
1897             }
1898             span#appname {
1899                 font-weight: bold;
1900                 font-size: 1.6em;
1901             }
1902         </style>
1903     </head>
1904     <body>
1905         <div id="content">
1906             <div id="topbar">
1907                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1908                     $VERSION</h1>
1909              </div>
1910              <div id="answers">
1911                  <p>
1912                  <img src="$logo" alt="Catalyst Logo" />
1913                  </p>
1914                  <p>Welcome to the  world of Catalyst.
1915                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1916                     framework will make web development something you had
1917                     never expected it to be: Fun, rewarding, and quick.</p>
1918                  <h2>What to do now?</h2>
1919                  <p>That really depends  on what <b>you</b> want to do.
1920                     We do, however, provide you with a few starting points.</p>
1921                  <p>If you want to jump right into web development with Catalyst
1922                     you might want to start with a tutorial.</p>
1923 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1924 </pre>
1925 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1926 <pre>
1927 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1928 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1929 </code></pre>
1930                  <h2>What to do next?</h2>
1931                  <p>Next it's time to write an actual application. Use the
1932                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1933                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1934                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1935                     they can save you a lot of work.</p>
1936                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1937                     <p>Also, be sure to check out the vast and growing
1938                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1939                     you are likely to find what you need there.
1940                     </p>
1941
1942                  <h2>Need help?</h2>
1943                  <p>Catalyst has a very active community. Here are the main places to
1944                     get in touch with us.</p>
1945                  <ul>
1946                      <li>
1947                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1948                      </li>
1949                      <li>
1950                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1951                      </li>
1952                      <li>
1953                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1954                      </li>
1955                  </ul>
1956                  <h2>In conclusion</h2>
1957                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1958                     as we enjoyed making it. Please contact us if you have ideas
1959                     for improvement or other feedback.</p>
1960              </div>
1961          </div>
1962     </body>
1963 </html>
1964 EOF
1965 }
1966
1967 =head2 run_options
1968
1969 Contains a hash of options passed from the application script, including
1970 the original ARGV the script received, the processed values from that
1971 ARGV and any extra arguments to the script which were not processed.
1972
1973 This can be used to add custom options to your application's scripts
1974 and setup your application differently depending on the values of these
1975 options.
1976
1977 =head1 INTERNAL METHODS
1978
1979 These methods are not meant to be used by end users.
1980
1981 =head2 $c->components
1982
1983 Returns a hash of components.
1984
1985 =head2 $c->context_class
1986
1987 Returns or sets the context class.
1988
1989 =head2 $c->counter
1990
1991 Returns a hashref containing coderefs and execution counts (needed for
1992 deep recursion detection).
1993
1994 =head2 $c->depth
1995
1996 Returns the number of actions on the current internal execution stack.
1997
1998 =head2 $c->dispatch
1999
2000 Dispatches a request to actions.
2001
2002 =cut
2003
2004 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
2005
2006 =head2 $c->dispatcher_class
2007
2008 Returns or sets the dispatcher class.
2009
2010 =head2 $c->dump_these
2011
2012 Returns a list of 2-element array references (name, structure) pairs
2013 that will be dumped on the error page in debug mode.
2014
2015 =cut
2016
2017 sub dump_these {
2018     my $c = shift;
2019     [ Request => $c->req ],
2020     [ Response => $c->res ],
2021     [ Stash => $c->stash ],
2022     [ Config => $c->config ];
2023 }
2024
2025 =head2 $c->engine_class
2026
2027 Returns or sets the engine class.
2028
2029 =head2 $c->execute( $class, $coderef )
2030
2031 Execute a coderef in given class and catch exceptions. Errors are available
2032 via $c->error.
2033
2034 =cut
2035
2036 sub execute {
2037     my ( $c, $class, $code ) = @_;
2038     $class = $c->component($class) || $class;
2039     #$c->state(0);
2040
2041     if ( $c->depth >= $RECURSION ) {
2042         my $action = $code->reverse();
2043         $action = "/$action" unless $action =~ /->/;
2044         my $error = qq/Deep recursion detected calling "${action}"/;
2045         $c->log->error($error);
2046         $c->error($error);
2047         $c->state(0);
2048         return $c->state;
2049     }
2050
2051     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
2052
2053     push( @{ $c->stack }, $code );
2054
2055     no warnings 'recursion';
2056     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
2057     #      I have no idea how, ergo $ret (which appears to fix the issue)
2058     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
2059
2060     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
2061
2062     my $last = pop( @{ $c->stack } );
2063
2064     if ( my $error = $@ ) {
2065         #rethow if this can be handled by middleware
2066         if ( $c->_handle_http_exception($error) ) {
2067             foreach my $err (@{$c->error}) {
2068                 $c->log->error($err);
2069             }
2070             $c->clear_errors;
2071             $c->log->_flush if $c->log->can('_flush');
2072
2073             $error->can('rethrow') ? $error->rethrow : croak $error;
2074         }
2075         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
2076             $error->rethrow if $c->depth > 1;
2077         }
2078         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
2079             $error->rethrow if $c->depth > 0;
2080         }
2081         else {
2082             unless ( ref $error ) {
2083                 no warnings 'uninitialized';
2084                 chomp $error;
2085                 my $class = $last->class;
2086                 my $name  = $last->name;
2087                 $error = qq/Caught exception in $class->$name "$error"/;
2088             }
2089             $c->error($error);
2090         }
2091         #$c->state(0);
2092     }
2093     return $c->state;
2094 }
2095
2096 sub _stats_start_execute {
2097     my ( $c, $code ) = @_;
2098     my $appclass = ref($c) || $c;
2099     return if ( ( $code->name =~ /^_.*/ )
2100         && ( !$appclass->config->{show_internal_actions} ) );
2101
2102     my $action_name = $code->reverse();
2103     $c->counter->{$action_name}++;
2104
2105     my $action = $action_name;
2106     $action = "/$action" unless $action =~ /->/;
2107
2108     # determine if the call was the result of a forward
2109     # this is done by walking up the call stack and looking for a calling
2110     # sub of Catalyst::forward before the eval
2111     my $callsub = q{};
2112     for my $index ( 2 .. 11 ) {
2113         last
2114         if ( ( caller($index) )[0] eq 'Catalyst'
2115             && ( caller($index) )[3] eq '(eval)' );
2116
2117         if ( ( caller($index) )[3] =~ /forward$/ ) {
2118             $callsub = ( caller($index) )[3];
2119             $action  = "-> $action";
2120             last;
2121         }
2122     }
2123
2124     my $uid = $action_name . $c->counter->{$action_name};
2125
2126     # is this a root-level call or a forwarded call?
2127     if ( $callsub =~ /forward$/ ) {
2128         my $parent = $c->stack->[-1];
2129
2130         # forward, locate the caller
2131         if ( defined $parent && exists $c->counter->{"$parent"} ) {
2132             $c->stats->profile(
2133                 begin  => $action,
2134                 parent => "$parent" . $c->counter->{"$parent"},
2135                 uid    => $uid,
2136             );
2137         }
2138         else {
2139
2140             # forward with no caller may come from a plugin
2141             $c->stats->profile(
2142                 begin => $action,
2143                 uid   => $uid,
2144             );
2145         }
2146     }
2147     else {
2148
2149         # root-level call
2150         $c->stats->profile(
2151             begin => $action,
2152             uid   => $uid,
2153         );
2154     }
2155     return $action;
2156
2157 }
2158
2159 sub _stats_finish_execute {
2160     my ( $c, $info ) = @_;
2161     $c->stats->profile( end => $info );
2162 }
2163
2164 =head2 $c->finalize
2165
2166 Finalizes the request.
2167
2168 =cut
2169
2170 sub finalize {
2171     my $c = shift;
2172
2173     for my $error ( @{ $c->error } ) {
2174         $c->log->error($error);
2175     }
2176
2177     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
2178     # stuff like cometd and websockets
2179
2180     if($c->request->_has_io_fh) {
2181       $c->log_response;
2182       return;
2183     }
2184
2185     # Allow engine to handle finalize flow (for POE)
2186     my $engine = $c->engine;
2187     if ( my $code = $engine->can('finalize') ) {
2188         $engine->$code($c);
2189     }
2190     else {
2191
2192         $c->finalize_uploads;
2193
2194         # Error
2195         if ( $#{ $c->error } >= 0 ) {
2196             $c->finalize_error;
2197         }
2198
2199         $c->finalize_encoding;
2200         $c->finalize_headers unless $c->response->finalized_headers;
2201         $c->finalize_body;
2202     }
2203
2204     $c->log_response;
2205
2206     if ($c->use_stats) {
2207         my $elapsed = $c->stats->elapsed;
2208         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
2209         $c->log->info(
2210             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
2211     }
2212
2213     return $c->response->status;
2214 }
2215
2216 =head2 $c->finalize_body
2217
2218 Finalizes body.
2219
2220 =cut
2221
2222 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
2223
2224 =head2 $c->finalize_cookies
2225
2226 Finalizes cookies.
2227
2228 =cut
2229
2230 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
2231
2232 =head2 $c->finalize_error
2233
2234 Finalizes error.  If there is only one error in L</error> and it is an object that
2235 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2236 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2237 return the default error page (production mode).
2238
2239 =cut
2240
2241 sub finalize_error {
2242     my $c = shift;
2243     if($#{$c->error} > 0) {
2244         $c->engine->finalize_error( $c, @_ );
2245     } else {
2246         my ($error) = @{$c->error};
2247         if ( $c->_handle_http_exception($error) ) {
2248             # In the case where the error 'knows what it wants', becauses its PSGI
2249             # aware, just rethow and let middleware catch it
2250             $error->can('rethrow') ? $error->rethrow : croak $error;
2251         } else {
2252             $c->engine->finalize_error( $c, @_ )
2253         }
2254     }
2255 }
2256
2257 =head2 $c->finalize_headers
2258
2259 Finalizes headers.
2260
2261 =cut
2262
2263 sub finalize_headers {
2264     my $c = shift;
2265
2266     my $response = $c->response; #accessor calls can add up?
2267
2268     # Check if we already finalized headers
2269     return if $response->finalized_headers;
2270
2271     # Handle redirects
2272     if ( my $location = $response->redirect ) {
2273         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2274         $response->header( Location => $location );
2275     }
2276
2277     # Remove incorrectly added body and content related meta data when returning
2278     # an information response, or a response the is required to not include a body
2279
2280     $c->finalize_cookies;
2281
2282     # This currently is a NOOP but I don't want to remove it since I guess people
2283     # might have Response subclasses that use it for something... (JNAP)
2284     $c->response->finalize_headers();
2285
2286     # Done
2287     $response->finalized_headers(1);
2288 }
2289
2290 =head2 $c->finalize_encoding
2291
2292 Make sure your body is encoded properly IF you set an encoding.  By
2293 default the encoding is UTF-8 but you can disable it by explicitly setting the
2294 encoding configuration value to undef.
2295
2296 We can only encode when the body is a scalar.  Methods for encoding via the
2297 streaming interfaces (such as C<write> and C<write_fh> on L<Catalyst::Response>
2298 are available).
2299
2300 See L</ENCODING>.
2301
2302 =cut
2303
2304 sub finalize_encoding {
2305     my $c = shift;
2306     my $res = $c->res || return;
2307
2308     # Warn if the set charset is different from the one you put into encoding.  We need
2309     # to do this early since encodable_response is false for this condition and we need
2310     # to match the debug output for backcompat (there's a test for this...) -JNAP
2311     if(
2312       $res->content_type_charset and $c->encoding and
2313       (uc($c->encoding->mime_name) ne uc($res->content_type_charset))
2314     ) {
2315         my $ct = lc($res->content_type_charset);
2316         $c->log->debug("Catalyst encoding config is set to encode in '" .
2317             $c->encoding->mime_name .
2318             "', content type is '$ct', not encoding ");
2319     }
2320
2321     if(
2322       ($res->encodable_response) and
2323       (defined($res->body)) and
2324       (is_plain_scalarref(\$res->body))
2325     ) {
2326         $c->res->body( $c->encoding->encode( $c->res->body, $c->_encode_check ) );
2327
2328         # Set the charset if necessary.  This might be a bit bonkers since encodable response
2329         # is false when the set charset is not the same as the encoding mimetype (maybe
2330         # confusing action at a distance here..
2331         # Don't try to set the charset if one already exists or if headers are already finalized
2332         $c->res->content_type($c->res->content_type . "; charset=" . $c->encoding->mime_name)
2333           unless($c->res->content_type_charset ||
2334                 ($c->res->_context && $c->res->finalized_headers && !$c->res->_has_response_cb));
2335     }
2336 }
2337
2338 =head2 $c->finalize_output
2339
2340 An alias for finalize_body.
2341
2342 =head2 $c->finalize_read
2343
2344 Finalizes the input after reading is complete.
2345
2346 =cut
2347
2348 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2349
2350 =head2 $c->finalize_uploads
2351
2352 Finalizes uploads. Cleans up any temporary files.
2353
2354 =cut
2355
2356 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2357
2358 =head2 $c->get_action( $action, $namespace )
2359
2360 Gets an action in a given namespace.
2361
2362 =cut
2363
2364 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2365
2366 =head2 $c->get_actions( $action, $namespace )
2367
2368 Gets all actions of a given name in a namespace and all parent
2369 namespaces.
2370
2371 =cut
2372
2373 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2374
2375 =head2 $app->handle_request( @arguments )
2376
2377 Called to handle each HTTP request.
2378
2379 =cut
2380
2381 sub handle_request {
2382     my ( $class, @arguments ) = @_;
2383
2384     # Always expect worst case!
2385     my $status = -1;
2386     try {
2387         if ($class->debug) {
2388             my $secs = time - $START || 1;
2389             my $av = sprintf '%.3f', $COUNT / $secs;
2390             my $time = localtime time;
2391             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2392         }
2393
2394         my $c = $class->prepare(@arguments);
2395         $c->dispatch;
2396         $status = $c->finalize;
2397     } catch {
2398         #rethow if this can be handled by middleware
2399         if ( $class->_handle_http_exception($_) ) {
2400             $_->can('rethrow') ? $_->rethrow : croak $_;
2401         }
2402         chomp(my $error = $_);
2403         $class->log->error(qq/Caught exception in engine "$error"/);
2404     };
2405
2406     $COUNT++;
2407
2408     if(my $coderef = $class->log->can('_flush')){
2409         $class->log->$coderef();
2410     }
2411     return $status;
2412 }
2413
2414 =head2 $class->prepare( @arguments )
2415
2416 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2417 etc.).
2418
2419 =cut
2420
2421 has _uploadtmp => (
2422     is => 'ro',
2423     predicate => '_has_uploadtmp',
2424 );
2425
2426 sub prepare {
2427     my ( $class, @arguments ) = @_;
2428
2429     # XXX
2430     # After the app/ctxt split, this should become an attribute based on something passed
2431     # into the application.
2432     $class->context_class( ref $class || $class ) unless $class->context_class;
2433
2434     my $uploadtmp = $class->config->{uploadtmp};
2435     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2436
2437     $c->response->_context($c);
2438     $c->stats($class->stats_class->new)->enable($c->use_stats);
2439
2440     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2441         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2442     }
2443
2444     try {
2445         # Allow engine to direct the prepare flow (for POE)
2446         if ( my $prepare = $c->engine->can('prepare') ) {
2447             $c->engine->$prepare( $c, @arguments );
2448         }
2449         else {
2450             $c->prepare_request(@arguments);
2451             $c->prepare_connection;
2452             $c->prepare_query_parameters;
2453             $c->prepare_headers; # Just hooks, no longer needed - they just
2454             $c->prepare_cookies; # cause the lazy attribute on req to build
2455             $c->prepare_path;
2456
2457             # Prepare the body for reading, either by prepare_body
2458             # or the user, if they are using $c->read
2459             $c->prepare_read;
2460
2461             # Parse the body unless the user wants it on-demand
2462             unless ( ref($c)->config->{parse_on_demand} ) {
2463                 $c->prepare_body;
2464             }
2465         }
2466         $c->prepare_action;
2467     }
2468     # VERY ugly and probably shouldn't rely on ->finalize actually working
2469     catch {
2470         # failed prepare is always due to an invalid request, right?
2471         # Note we call finalize and then die here, which escapes
2472         # finalize being called in the enclosing block..
2473         # It in fact couldn't be called, as we don't return $c..
2474         # This is a mess - but I'm unsure you can fix this without
2475         # breaking compat for people doing crazy things (we should set
2476         # the 400 and just return the ctx here IMO, letting finalize get called
2477         # above...
2478         if ( $c->_handle_http_exception($_) ) {
2479             foreach my $err (@{$c->error}) {
2480                 $c->log->error($err);
2481             }
2482             $c->clear_errors;
2483             $c->log->_flush if $c->log->can('_flush');
2484             $_->can('rethrow') ? $_->rethrow : croak $_;
2485         } else {
2486             $c->response->status(400);
2487             $c->response->content_type('text/plain');
2488             $c->response->body('Bad Request');
2489             $c->finalize;
2490             die $_;
2491         }
2492     };
2493
2494     $c->log_request;
2495     $c->{stash} = $c->stash;
2496     Scalar::Util::weaken($c->{stash});
2497
2498     return $c;
2499 }
2500
2501 =head2 $c->prepare_action
2502
2503 Prepares action. See L<Catalyst::Dispatcher>.
2504
2505 =cut
2506
2507 sub prepare_action {
2508     my $c = shift;
2509     my $ret = $c->dispatcher->prepare_action( $c, @_);
2510
2511     if($c->encoding) {
2512         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2513           $_ = $c->_handle_param_unicode_decoding($_);
2514         }
2515     }
2516
2517     return $ret;
2518 }
2519
2520
2521 =head2 $c->prepare_body
2522
2523 Prepares message body.
2524
2525 =cut
2526
2527 sub prepare_body {
2528     my $c = shift;
2529
2530     return if $c->request->_has_body;
2531
2532     # Initialize on-demand data
2533     $c->engine->prepare_body( $c, @_ );
2534     $c->prepare_parameters;
2535     $c->prepare_uploads;
2536 }
2537
2538 =head2 $c->prepare_body_chunk( $chunk )
2539
2540 Prepares a chunk of data before sending it to L<HTTP::Body>.
2541
2542 See L<Catalyst::Engine>.
2543
2544 =cut
2545
2546 sub prepare_body_chunk {
2547     my $c = shift;
2548     $c->engine->prepare_body_chunk( $c, @_ );
2549 }
2550
2551 =head2 $c->prepare_body_parameters
2552
2553 Prepares body parameters.
2554
2555 =cut
2556
2557 sub prepare_body_parameters {
2558     my $c = shift;
2559     $c->request->prepare_body_parameters( $c, @_ );
2560 }
2561
2562 =head2 $c->prepare_connection
2563
2564 Prepares connection.
2565
2566 =cut
2567
2568 sub prepare_connection {
2569     my $c = shift;
2570     $c->request->prepare_connection($c);
2571 }
2572
2573 =head2 $c->prepare_cookies
2574
2575 Prepares cookies by ensuring that the attribute on the request
2576 object has been built.
2577
2578 =cut
2579
2580 sub prepare_cookies { my $c = shift; $c->request->cookies }
2581
2582 =head2 $c->prepare_headers
2583
2584 Prepares request headers by ensuring that the attribute on the request
2585 object has been built.
2586
2587 =cut
2588
2589 sub prepare_headers { my $c = shift; $c->request->headers }
2590
2591 =head2 $c->prepare_parameters
2592
2593 Prepares parameters.
2594
2595 =cut
2596
2597 sub prepare_parameters {
2598     my $c = shift;
2599     $c->prepare_body_parameters;
2600     $c->engine->prepare_parameters( $c, @_ );
2601 }
2602
2603 =head2 $c->prepare_path
2604
2605 Prepares path and base.
2606
2607 =cut
2608
2609 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2610
2611 =head2 $c->prepare_query_parameters
2612
2613 Prepares query parameters.
2614
2615 =cut
2616
2617 sub prepare_query_parameters {
2618     my $c = shift;
2619
2620     $c->engine->prepare_query_parameters( $c, @_ );
2621 }
2622
2623 =head2 $c->log_request
2624
2625 Writes information about the request to the debug logs.  This includes:
2626
2627 =over 4
2628
2629 =item * Request method, path, and remote IP address
2630
2631 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2632
2633 =item * Request parameters
2634
2635 =item * File uploads
2636
2637 =back
2638
2639 =cut
2640
2641 sub log_request {
2642     my $c = shift;
2643
2644     return unless $c->debug;
2645
2646     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2647     my $request = $dump->[1];
2648
2649     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2650     $method ||= '';
2651     $path = '/' unless length $path;
2652     $address ||= '';
2653
2654     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2655     $path = decode_utf8($path);
2656
2657     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2658
2659     $c->log_request_headers($request->headers);
2660
2661     if ( my $keywords = $request->query_keywords ) {
2662         $c->log->debug("Query keywords are: $keywords");
2663     }
2664
2665     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2666
2667     $c->log_request_uploads($request);
2668 }
2669
2670 =head2 $c->log_response
2671
2672 Writes information about the response to the debug logs by calling
2673 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2674
2675 =cut
2676
2677 sub log_response {
2678     my $c = shift;
2679
2680     return unless $c->debug;
2681
2682     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2683     my $response = $dump->[1];
2684
2685     $c->log_response_status_line($response);
2686     $c->log_response_headers($response->headers);
2687 }
2688
2689 =head2 $c->log_response_status_line($response)
2690
2691 Writes one line of information about the response to the debug logs.  This includes:
2692
2693 =over 4
2694
2695 =item * Response status code
2696
2697 =item * Content-Type header (if present)
2698
2699 =item * Content-Length header (if present)
2700
2701 =back
2702
2703 =cut
2704
2705 sub log_response_status_line {
2706     my ($c, $response) = @_;
2707
2708     $c->log->debug(
2709         sprintf(
2710             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2711             $response->status                            || 'unknown',
2712             $response->headers->header('Content-Type')   || 'unknown',
2713             $response->headers->header('Content-Length') || 'unknown'
2714         )
2715     );
2716 }
2717
2718 =head2 $c->log_response_headers($headers);
2719
2720 Hook method which can be wrapped by plugins to log the response headers.
2721 No-op in the default implementation.
2722
2723 =cut
2724
2725 sub log_response_headers {}
2726
2727 =head2 $c->log_request_parameters( query => {}, body => {} )
2728
2729 Logs request parameters to debug logs
2730
2731 =cut
2732
2733 sub log_request_parameters {
2734     my $c          = shift;
2735     my %all_params = @_;
2736
2737     return unless $c->debug;
2738
2739     my $column_width = Catalyst::Utils::term_width() - 44;
2740     foreach my $type (qw(query body)) {
2741         my $params = $all_params{$type};
2742         next if ! keys %$params;
2743         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2744         for my $key ( sort keys %$params ) {
2745             my $param = $params->{$key};
2746             my $value = defined($param) ? $param : '';
2747             $t->row( $key, is_plain_arrayref($value) ? ( join ', ', @$value ) : $value );
2748         }
2749         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2750     }
2751 }
2752
2753 =head2 $c->log_request_uploads
2754
2755 Logs file uploads included in the request to the debug logs.
2756 The parameter name, filename, file type, and file size are all included in
2757 the debug logs.
2758
2759 =cut
2760
2761 sub log_request_uploads {
2762     my $c = shift;
2763     my $request = shift;
2764     return unless $c->debug;
2765     my $uploads = $request->uploads;
2766     if ( keys %$uploads ) {
2767         my $t = Text::SimpleTable->new(
2768             [ 12, 'Parameter' ],
2769             [ 26, 'Filename' ],
2770             [ 18, 'Type' ],
2771             [ 9,  'Size' ]
2772         );
2773         for my $key ( sort keys %$uploads ) {
2774             my $upload = $uploads->{$key};
2775             for my $u ( is_plain_arrayref($upload) ? @{$upload} : ($upload) ) {
2776                 $t->row( $key, $u->filename, $u->type, $u->size );
2777             }
2778         }
2779         $c->log->debug( "File Uploads are:\n" . $t->draw );
2780     }
2781 }
2782
2783 =head2 $c->log_request_headers($headers);
2784
2785 Hook method which can be wrapped by plugins to log the request headers.
2786 No-op in the default implementation.
2787
2788 =cut
2789
2790 sub log_request_headers {}
2791
2792 =head2 $c->log_headers($type => $headers)
2793
2794 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2795
2796 =cut
2797
2798 sub log_headers {
2799     my $c       = shift;
2800     my $type    = shift;
2801     my $headers = shift;    # an HTTP::Headers instance
2802
2803     return unless $c->debug;
2804
2805     my $column_width = Catalyst::Utils::term_width() - 28;
2806     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2807     $headers->scan(
2808         sub {
2809             my ( $name, $value ) = @_;
2810             $t->row( $name, $value );
2811         }
2812     );
2813     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2814 }
2815
2816
2817 =head2 $c->prepare_read
2818
2819 Prepares the input for reading.
2820
2821 =cut
2822
2823 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2824
2825 =head2 $c->prepare_request
2826
2827 Prepares the engine request.
2828
2829 =cut
2830
2831 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2832
2833 =head2 $c->prepare_uploads
2834
2835 Prepares uploads.
2836
2837 =cut
2838
2839 sub prepare_uploads {
2840     my $c = shift;
2841     $c->engine->prepare_uploads( $c, @_ );
2842 }
2843
2844 =head2 $c->prepare_write
2845
2846 Prepares the output for writing.
2847
2848 =cut
2849
2850 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2851
2852 =head2 $c->request_class
2853
2854 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2855
2856 =head2 $app->request_class_traits
2857
2858 An arrayref of L<Moose::Role>s which are applied to the request class.  You can
2859 name the full namespace of the role, or a namespace suffix, which will then
2860 be tried against the following standard namespace prefixes.
2861
2862     $MyApp::TraitFor::Request::$trait_suffix
2863     Catalyst::TraitFor::Request::$trait_suffix
2864
2865 So for example if you set:
2866
2867     MyApp->request_class_traits(['Foo']);
2868
2869 We try each possible role in turn (and throw an error if none load)
2870
2871     Foo
2872     MyApp::TraitFor::Request::Foo
2873     Catalyst::TraitFor::Request::Foo
2874
2875 The namespace part 'TraitFor::Request' was chosen to assist in backwards
2876 compatibility with L<CatalystX::RoleApplicator> which previously provided
2877 these features in a stand alone package.
2878
2879 =head2 $app->composed_request_class
2880
2881 This is the request class which has been composed with any request_class_traits.
2882
2883 =head2 $c->response_class
2884
2885 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2886
2887 =head2 $app->response_class_traits
2888
2889 An arrayref of L<Moose::Role>s which are applied to the response class.  You can
2890 name the full namespace of the role, or a namespace suffix, which will then
2891 be tried against the following standard namespace prefixes.
2892
2893     $MyApp::TraitFor::Response::$trait_suffix
2894     Catalyst::TraitFor::Response::$trait_suffix
2895
2896 So for example if you set:
2897
2898     MyApp->response_class_traits(['Foo']);
2899
2900 We try each possible role in turn (and throw an error if none load)
2901
2902     Foo
2903     MyApp::TraitFor::Response::Foo
2904     Catalyst::TraitFor::Responset::Foo
2905
2906 The namespace part 'TraitFor::Response' was chosen to assist in backwards
2907 compatibility with L<CatalystX::RoleApplicator> which previously provided
2908 these features in a stand alone package.
2909
2910
2911 =head2 $app->composed_response_class
2912
2913 This is the request class which has been composed with any response_class_traits.
2914
2915 =head2 $c->read( [$maxlength] )
2916
2917 Reads a chunk of data from the request body. This method is designed to
2918 be used in a while loop, reading C<$maxlength> bytes on every call.
2919 C<$maxlength> defaults to the size of the request if not specified.
2920
2921 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2922 directly.
2923
2924 Warning: If you use read(), Catalyst will not process the body,
2925 so you will not be able to access POST parameters or file uploads via
2926 $c->request.  You must handle all body parsing yourself.
2927
2928 =cut
2929
2930 sub read { my $c = shift; return $c->request->read( @_ ) }
2931
2932 =head2 $c->run
2933
2934 Starts the engine.
2935
2936 =cut
2937
2938 sub run {
2939   my $app = shift;
2940   $app->_make_immutable_if_needed;
2941   $app->engine_loader->needs_psgi_engine_compat_hack ?
2942     $app->engine->run($app, @_) :
2943       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2944 }
2945
2946 sub _make_immutable_if_needed {
2947     my $class = shift;
2948     my $meta = find_meta($class);
2949     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2950     if (
2951         $meta->is_immutable
2952         && ! { $meta->immutable_options }->{replace_constructor}
2953         && $isa_ca
2954     ) {
2955         warn("You made your application class ($class) immutable, "
2956             . "but did not inline the\nconstructor. "
2957             . "This will break catalyst, as your app \@ISA "
2958             . "Class::Accessor(::Fast)?\nPlease pass "
2959             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2960     }
2961     unless ($meta->is_immutable) {
2962         # XXX - FIXME warning here as you should make your app immutable yourself.
2963         $meta->make_immutable(
2964             replace_constructor => 1,
2965         );
2966     }
2967 }
2968
2969 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2970
2971 Sets an action in a given namespace.
2972
2973 =cut
2974
2975 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2976
2977 =head2 $c->setup_actions($component)
2978
2979 Sets up actions for a component.
2980
2981 =cut
2982
2983 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2984
2985 =head2 $c->setup_components
2986
2987 This method is called internally to set up the application's components.
2988
2989 It finds modules by calling the L<locate_components> method, expands them to
2990 package names with the L<expand_component_module> method, and then installs
2991 each component into the application.
2992
2993 The C<setup_components> config option is passed to both of the above methods.
2994
2995 Installation of each component is performed by the L<setup_component> method,
2996 below.
2997
2998 =cut
2999
3000 sub setup_components {
3001     my $class = shift;
3002
3003     my $config  = $class->config->{ setup_components };
3004
3005     my @comps = $class->locate_components($config);
3006     my %comps = map { $_ => 1 } @comps;
3007
3008     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
3009     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
3010         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
3011     ) if $deprecatedcatalyst_component_names;
3012
3013     for my $component ( @comps ) {
3014
3015         # We pass ignore_loaded here so that overlay files for (e.g.)
3016         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
3017         # we know M::P::O found a file on disk so this is safe
3018
3019         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
3020     }
3021
3022     for my $component (@comps) {
3023         my $instance = $class->components->{ $component } = $class->delayed_setup_component($component);
3024     }
3025
3026     # Inject a component or wrap a stand alone class in an adaptor. This makes a list
3027     # of named components in the configuration that are not actually existing (not a
3028     # real file).
3029
3030     my @injected = $class->setup_injected_components;
3031
3032     # All components are registered, now we need to 'init' them.
3033     foreach my $component_name (@comps, @injected) {
3034       $class->components->{$component_name} = $class->components->{$component_name}->() if
3035         is_plain_coderef($class->components->{$component_name});
3036     }
3037 }
3038
3039 =head2 $app->setup_injected_components
3040
3041 Called by setup_compoents to setup components that are injected.
3042
3043 =cut
3044
3045 sub setup_injected_components {
3046     my ($class) = @_;
3047     my @injected_components = keys %{$class->config->{inject_components} ||+{}};
3048
3049     foreach my $injected_comp_name(@injected_components) {
3050         $class->setup_injected_component(
3051           $injected_comp_name,
3052           $class->config->{inject_components}->{$injected_comp_name});
3053     }
3054
3055     return map { $class ."::" . $_ }
3056       @injected_components;
3057 }
3058
3059 =head2 $app->setup_injected_component( $injected_component_name, $config )
3060
3061 Setup a given injected component.
3062
3063 =cut
3064
3065 sub setup_injected_component {
3066     my ($class, $injected_comp_name, $config) = @_;
3067     if(my $component_class = $config->{from_component}) {
3068         my @roles = @{$config->{roles} ||[]};
3069         Catalyst::Utils::inject_component(
3070           into => $class,
3071           component => $component_class,
3072           (scalar(@roles) ? (traits => \@roles) : ()),
3073           as => $injected_comp_name);
3074     }
3075 }
3076
3077 =head2 $app->inject_component($MyApp_Component_name => \%args);
3078
3079 Add a component that is injected at setup:
3080
3081     MyApp->inject_component( 'Model::Foo' => { from_component => 'Common::Foo' } );
3082
3083 Must be called before ->setup.  Expects a component name for your
3084 current application and \%args where
3085
3086 =over 4
3087
3088 =item from_component
3089
3090 The target component being injected into your application
3091
3092 =item roles
3093
3094 An arrayref of L<Moose::Role>s that are applied to your component.
3095
3096 =back
3097
3098 Example
3099
3100     MyApp->inject_component(
3101       'Model::Foo' => {
3102         from_component => 'Common::Model::Foo',
3103         roles => ['Role1', 'Role2'],
3104       });
3105
3106 =head2 $app->inject_components
3107
3108 Inject a list of components:
3109
3110     MyApp->inject_components(
3111       'Model::FooOne' => {
3112         from_component => 'Common::Model::Foo',
3113         roles => ['Role1', 'Role2'],
3114       },
3115       'Model::FooTwo' => {
3116         from_component => 'Common::Model::Foo',
3117         roles => ['Role1', 'Role2'],
3118       });
3119
3120 =cut
3121
3122 sub inject_component {
3123   my ($app, $name, $args) = @_;
3124   die "Component $name exists" if
3125     $app->config->{inject_components}->{$name};
3126   $app->config->{inject_components}->{$name} = $args;
3127 }
3128
3129 sub inject_components {
3130   my $app = shift;
3131   while(@_) {
3132     $app->inject_component(shift, shift);
3133   }
3134 }
3135
3136 =head2 $c->locate_components( $setup_component_config )
3137
3138 This method is meant to provide a list of component modules that should be
3139 setup for the application.  By default, it will use L<Module::Pluggable>.
3140
3141 Specify a C<setup_components> config option to pass additional options directly
3142 to L<Module::Pluggable>. To add additional search paths, specify a key named
3143 C<search_extra> as an array reference. Items in the array beginning with C<::>
3144 will have the application class name prepended to them.
3145
3146 =cut
3147
3148 sub locate_components {
3149     my $class  = shift;
3150     my $config = shift;
3151
3152     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
3153     my $extra   = $config->{ search_extra } || [];
3154
3155     unshift @paths, @$extra;
3156
3157     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
3158       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
3159       %$config
3160     )->plugins } @paths;
3161
3162     return @comps;
3163 }
3164
3165 =head2 $c->expand_component_module( $component, $setup_component_config )
3166
3167 Components found by C<locate_components> will be passed to this method, which
3168 is expected to return a list of component (package) names to be set up.
3169
3170 =cut
3171
3172 sub expand_component_module {
3173     my ($class, $module) = @_;
3174     return Devel::InnerPackage::list_packages( $module );
3175 }
3176
3177 =head2 $app->delayed_setup_component
3178
3179 Returns a coderef that points to a setup_component instance.  Used
3180 internally for when you want to delay setup until the first time
3181 the component is called.
3182
3183 =cut
3184
3185 sub delayed_setup_component {
3186   my($class, $component, @more) = @_;
3187   return sub {
3188     return my $instance = $class->setup_component($component, @more);
3189   };
3190 }
3191
3192 =head2 $c->setup_component
3193
3194 =cut
3195
3196 sub setup_component {
3197     my( $class, $component ) = @_;
3198
3199     unless ( $component->can( 'COMPONENT' ) ) {
3200         return $component;
3201     }
3202
3203     my $config = $class->config_for($component);
3204     # Stash catalyst_component_name in the config here, so that custom COMPONENT
3205     # methods also pass it. local to avoid pointlessly shitting in config
3206     # for the debug screen, as $component is already the key name.
3207     local $config->{catalyst_component_name} = $component;
3208
3209     my $instance = eval {
3210       $component->COMPONENT( $class, $config );
3211     } || do {
3212       my $error = $@;
3213       chomp $error;
3214       Catalyst::Exception->throw(
3215         message => qq/Couldn't instantiate component "$component", "$error"/
3216       );
3217     };
3218
3219     unless (blessed $instance) {
3220         my $metaclass = Moose::Util::find_meta($component);
3221         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
3222         my $component_method_from = $method_meta->associated_metaclass->name;
3223         my $value = defined($instance) ? $instance : 'undef';
3224         Catalyst::Exception->throw(
3225             message =>
3226             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
3227         );
3228     }
3229
3230     my @expanded_components = $instance->can('expand_modules')
3231       ? $instance->expand_modules( $component, $config )
3232       : $class->expand_component_module( $component, $config );
3233     for my $component (@expanded_components) {
3234       next if $class->components->{ $component };
3235       $class->components->{ $component } = $class->setup_component($component);
3236     }
3237
3238     return $instance;
3239 }
3240
3241 =head2 $app->config_for( $component_name )
3242
3243 Return the application level configuration (which is not yet merged with any
3244 local component configuration, via $component_class->config) for the named
3245 component or component object. Example:
3246
3247     MyApp->config(
3248       'Model::Foo' => { a => 1, b => 2},
3249     );
3250
3251     my $config = MyApp->config_for('MyApp::Model::Foo');
3252
3253 In this case $config is the hashref C< {a=>1, b=>2} >.
3254
3255 This is also handy for looking up configuration for a plugin, to make sure you follow
3256 existing L<Catalyst> standards for where a plugin should put its configuration.
3257
3258 =cut
3259
3260 sub config_for {
3261     my ($class, $component_name) = @_;
3262     my $component_suffix = Catalyst::Utils::class2classsuffix($component_name);
3263     my $config = $class->config->{ $component_suffix } || {};
3264
3265     return $config;
3266 }
3267
3268 =head2 $c->setup_dispatcher
3269
3270 Sets up dispatcher.
3271
3272 =cut
3273
3274 sub setup_dispatcher {
3275     my ( $class, $dispatcher ) = @_;
3276
3277     if ($dispatcher) {
3278         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
3279     }
3280
3281     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
3282         $dispatcher = 'Catalyst::Dispatcher::' . $env;
3283     }
3284
3285     unless ($dispatcher) {
3286         $dispatcher = $class->dispatcher_class;
3287     }
3288
3289     load_class($dispatcher);
3290
3291     # dispatcher instance
3292     $class->dispatcher( $dispatcher->new );
3293 }
3294
3295 =head2 $c->setup_engine
3296
3297 Sets up engine.
3298
3299 =cut
3300
3301 sub engine_class {
3302     my ($class, $requested_engine) = @_;
3303
3304     if (!$class->engine_loader || $requested_engine) {
3305         $class->engine_loader(
3306             Catalyst::EngineLoader->new({
3307                 application_name => $class,
3308                 (defined $requested_engine
3309                      ? (catalyst_engine_class => $requested_engine) : ()),
3310             }),
3311         );
3312     }
3313
3314     $class->engine_loader->catalyst_engine_class;
3315 }
3316
3317 sub setup_engine {
3318     my ($class, $requested_engine) = @_;
3319
3320     my $engine = do {
3321         my $loader = $class->engine_loader;
3322
3323         if (!$loader || $requested_engine) {
3324             $loader = Catalyst::EngineLoader->new({
3325                 application_name => $class,
3326                 (defined $requested_engine
3327                      ? (requested_engine => $requested_engine) : ()),
3328             }),
3329
3330             $class->engine_loader($loader);
3331         }
3332
3333         $loader->catalyst_engine_class;
3334     };
3335
3336     # Don't really setup_engine -- see _setup_psgi_app for explanation.
3337     return if $class->loading_psgi_file;
3338
3339     load_class($engine);
3340
3341     if ($ENV{MOD_PERL}) {
3342         my $apache = $class->engine_loader->auto;
3343
3344         my $meta = find_meta($class);
3345         my $was_immutable = $meta->is_immutable;
3346         my %immutable_options = $meta->immutable_options;
3347         $meta->make_mutable if $was_immutable;
3348
3349         $meta->add_method(handler => sub {
3350             my $r = shift;
3351             my $psgi_app = $class->_finalized_psgi_app;
3352             $apache->call_app($r, $psgi_app);
3353         });
3354
3355         $meta->make_immutable(%immutable_options) if $was_immutable;
3356     }
3357
3358     $class->engine( $engine->new );
3359
3360     return;
3361 }
3362
3363 ## This exists just to supply a prebuild psgi app for mod_perl and for the
3364 ## build in server support (back compat support for pre psgi port behavior).
3365 ## This is so that we don't build a new psgi app for each request when using
3366 ## the mod_perl handler or the built in servers (http and fcgi, etc).
3367
3368 sub _finalized_psgi_app {
3369     my ($app) = @_;
3370
3371     unless ($app->_psgi_app) {
3372         my $psgi_app = $app->_setup_psgi_app;
3373         $app->_psgi_app($psgi_app);
3374     }
3375
3376     return $app->_psgi_app;
3377 }
3378
3379 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
3380 ## home directory and load that and return it (just assume it is doing the
3381 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
3382 ## in default_middleware and return it ( this is for backward compatibility
3383 ## with pre psgi port behavior ).
3384
3385 sub _setup_psgi_app {
3386     my ($app) = @_;
3387
3388     for my $home (Path::Class::Dir->new($app->config->{home})) {
3389         my $psgi_file = $home->file(
3390             Catalyst::Utils::appprefix($app) . '.psgi',
3391         );
3392
3393         next unless -e $psgi_file;
3394
3395         # If $psgi_file calls ->setup_engine, it's doing so to load
3396         # Catalyst::Engine::PSGI. But if it does that, we're only going to
3397         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
3398         # anyway. So set a flag (ick) that tells setup_engine not to populate
3399         # $c->engine or do any other things we might regret.
3400
3401         $app->loading_psgi_file(1);
3402         my $psgi_app = Plack::Util::load_psgi($psgi_file);
3403         $app->loading_psgi_file(0);
3404
3405         return $psgi_app
3406             unless $app->engine_loader->needs_psgi_engine_compat_hack;
3407
3408         warn <<"EOW";
3409 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
3410
3411 Its content has been ignored. Please consult the Catalyst::Upgrading
3412 documentation on how to upgrade from Catalyst::Engine::PSGI.
3413 EOW
3414     }
3415
3416     return $app->apply_default_middlewares($app->psgi_app);
3417 }
3418
3419 =head2 $c->apply_default_middlewares
3420
3421 Adds the following L<Plack> middlewares to your application, since they are
3422 useful and commonly needed:
3423
3424 L<Plack::Middleware::LighttpdScriptNameFix> (if you are using Lighttpd),
3425 L<Plack::Middleware::IIS6ScriptNameFix> (always applied since this middleware
3426 is smart enough to conditionally apply itself).
3427
3428 We will also automatically add L<Plack::Middleware::ReverseProxy> if we notice
3429 that your HTTP $env variable C<REMOTE_ADDR> is '127.0.0.1'.  This is usually
3430 an indication that your server is running behind a proxy frontend.  However in
3431 2014 this is often not the case.  We preserve this code for backwards compatibility
3432 however I B<highly> recommend that if you are running the server behind a front
3433 end proxy that you clearly indicate so with the C<using_frontend_proxy> configuration
3434 setting to true for your environment configurations that run behind a proxy.  This
3435 way if you change your front end proxy address someday your code would inexplicably
3436 stop working as expected.
3437
3438 Additionally if we detect we are using Nginx, we add a bit of custom middleware
3439 to solve some problems with the way that server handles $ENV{PATH_INFO} and
3440 $ENV{SCRIPT_NAME}.
3441
3442 Please B<NOTE> that if you do use C<using_frontend_proxy> the middleware is now
3443 adding via C<registered_middleware> rather than this method.
3444
3445 If you are using Lighttpd or IIS6 you may wish to apply these middlewares.  In
3446 general this is no longer a common case but we have this here for backward
3447 compatibility.
3448
3449 =cut
3450
3451
3452 sub apply_default_middlewares {
3453     my ($app, $psgi_app) = @_;
3454
3455     # Don't add this conditional IF we are explicitly saying we want the
3456     # frontend proxy support.  We don't need it here since if that is the
3457     # case it will be always loaded in the default_middleware.
3458
3459     unless($app->config->{using_frontend_proxy}) {
3460       $psgi_app = Plack::Middleware::Conditional->wrap(
3461           $psgi_app,
3462           builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
3463           condition => sub {
3464               my ($env) = @_;
3465               return if $app->config->{ignore_frontend_proxy};
3466               return $env->{REMOTE_ADDR} eq '127.0.0.1';
3467           },
3468       );
3469     }
3470
3471     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3472     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3473     $psgi_app = Plack::Middleware::Conditional->wrap(
3474         $psgi_app,
3475         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3476         condition => sub {
3477             my ($env) = @_;
3478             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3479             return unless $1 < 4.23;
3480             1;
3481         },
3482     );
3483
3484     # we're applying this unconditionally as the middleware itself already makes
3485     # sure it doesn't fuck things up if it's not running under one of the right
3486     # IIS versions
3487     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3488
3489     # And another IIS issue, this time with IIS7.
3490     $psgi_app = Plack::Middleware::Conditional->wrap(
3491         $psgi_app,
3492         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3493         condition => sub {
3494             my ($env) = @_;
3495             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3496         },
3497     );
3498
3499     return $psgi_app;
3500 }
3501
3502 =head2 App->psgi_app
3503
3504 =head2 App->to_app
3505
3506 Returns a PSGI application code reference for the catalyst application
3507 C<$c>. This is the bare application created without the C<apply_default_middlewares>
3508 method called.  We do however apply C<registered_middleware> since those are
3509 integral to how L<Catalyst> functions.  Also, unlike starting your application
3510 with a generated server script (via L<Catalyst::Devel> and C<catalyst.pl>) we do
3511 not attempt to return a valid L<PSGI> application using any existing C<${myapp}.psgi>
3512 scripts in your $HOME directory.
3513
3514 B<NOTE> C<apply_default_middlewares> was originally created when the first PSGI
3515 port was done for v5.90000.  These are middlewares that are added to achieve
3516 backward compatibility with older applications.  If you start your application
3517 using one of the supplied server scripts (generated with L<Catalyst::Devel> and
3518 the project skeleton script C<catalyst.pl>) we apply C<apply_default_middlewares>
3519 automatically.  This was done so that pre and post PSGI port applications would
3520 work the same way.
3521
3522 This is what you want to be using to retrieve the PSGI application code
3523 reference of your Catalyst application for use in a custom F<.psgi> or in your
3524 own created server modules.
3525
3526 =cut
3527
3528 *to_app = \&psgi_app;
3529
3530 sub psgi_app {
3531     my ($app) = @_;
3532     my $psgi = $app->engine->build_psgi_app($app);
3533     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3534 }
3535
3536 =head2 $c->setup_home
3537
3538 Sets up the home directory.
3539
3540 =cut
3541
3542 sub setup_home {
3543     my ( $class, $home ) = @_;
3544
3545     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3546         $home = $env;
3547     }
3548
3549     $home ||= Catalyst::Utils::home($class);
3550
3551     if ($home) {
3552         #I remember recently being scolded for assigning config values like this
3553         $class->config->{home} ||= $home;
3554         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3555     }
3556 }
3557
3558 =head2 $c->setup_encoding
3559
3560 Sets up the input/output encoding. See L<ENCODING>
3561
3562 =cut
3563
3564 sub setup_encoding {
3565     my $c = shift;
3566     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3567         # Ok, so the user has explicitly said "I don't want encoding..."
3568         return;
3569     } else {
3570       my $enc = defined($c->config->{encoding}) ?
3571         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3572       $c->encoding($enc);
3573     }
3574 }
3575
3576 =head2 handle_unicode_encoding_exception
3577
3578 Hook to let you customize how encoding errors are handled. By default
3579 we just throw an exception and the default error page will pick it up.
3580 Receives a hashref of debug information. Example of call (from the
3581 Catalyst internals):
3582
3583   my $decoded_after_fail = $c->handle_unicode_encoding_exception({
3584         param_value => $value,
3585         error_msg => $_,
3586         encoding_step => 'params',
3587    });
3588
3589 The calling code expects to receive a decoded string or an exception.
3590
3591 You can override this for custom handling of unicode errors. By
3592 default we just die. If you want a custom response here, one approach
3593 is to throw an HTTP style exception, instead of returning a decoded
3594 string or throwing a generic exception.
3595
3596     sub handle_unicode_encoding_exception {
3597       my ($c, $params) = @_;
3598       HTTP::Exception::BAD_REQUEST->throw(status_message=>$params->{error_msg});
3599     }
3600
3601 Alternatively you can 'catch' the error, stash it and write handling code later
3602 in your application:
3603
3604     sub handle_unicode_encoding_exception {
3605       my ($c, $params) = @_;
3606       $c->stash(BAD_UNICODE_DATA=>$params);
3607       # return a dummy string.
3608       return 1;
3609     }
3610
3611 <B>NOTE:</b> Please keep in mind that once an error like this occurs,
3612 the request setup is still ongoing, which means the state of C<$c> and
3613 related context parts like the request and response may not be setup
3614 up correctly (since we haven't finished the setup yet). If you throw
3615 an exception the setup is aborted.
3616
3617 =cut
3618
3619 sub handle_unicode_encoding_exception {
3620     my ( $self, $exception_ctx ) = @_;
3621     die $exception_ctx->{error_msg};
3622 }
3623
3624 # Some unicode helpers cargo culted from the old plugin.  These could likely
3625 # be neater.
3626
3627 sub _handle_unicode_decoding {
3628     my ( $self, $value ) = @_;
3629
3630     return unless defined $value;
3631
3632     ## I think this mess is to support the old nested
3633     if ( is_plain_arrayref($value) ) {
3634         foreach ( @$value ) {
3635             $_ = $self->_handle_unicode_decoding($_);
3636         }
3637         return $value;
3638     }
3639     elsif ( is_plain_hashref($value) ) {
3640         foreach (keys %$value) {
3641             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3642             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3643
3644             # If the key was encoded we now have two (the original and current so
3645             # delete the original.
3646             delete $value->{$_} if $_ ne $encoded_key;
3647         }
3648         return $value;
3649     }
3650     else {
3651         return $self->_handle_param_unicode_decoding($value);
3652     }
3653 }
3654
3655 sub _handle_param_unicode_decoding {
3656     my ( $self, $value, $check ) = @_;
3657     return unless defined $value; # not in love with just ignoring undefs - jnap
3658     return $value if blessed($value); #don't decode when the value is an object.
3659
3660     my $enc = $self->encoding;
3661
3662     return $value unless $enc; # don't decode if no encoding is specified
3663
3664     $check ||= $self->_encode_check;
3665     return try {
3666       $enc->decode( $value, $check);
3667     }
3668     catch {
3669         return $self->handle_unicode_encoding_exception({
3670             param_value => $value,
3671             error_msg => $_,
3672             encoding_step => 'params',
3673         });
3674     };
3675 }
3676
3677 =head2 $c->setup_log
3678
3679 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3680 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3681 log to.
3682
3683 This method also installs a C<debug> method that returns a true value into the
3684 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3685 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3686
3687 Note that if the log has already been setup, by either a previous call to
3688 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3689 that this method won't actually set up the log object.
3690
3691 =cut
3692
3693 sub setup_log {
3694     my ( $class, $levels ) = @_;
3695
3696     $levels ||= '';
3697     $levels =~ s/^\s+//;
3698     $levels =~ s/\s+$//;
3699     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3700
3701     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3702     if ( defined $env_debug ) {
3703         $levels{debug} = 1 if $env_debug; # Ugly!
3704         delete($levels{debug}) unless $env_debug;
3705     }
3706
3707     unless ( $class->log ) {
3708         $class->log( Catalyst::Log->new(keys %levels) );
3709     }
3710
3711     if ( $levels{debug} ) {
3712         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3713         $class->log->debug('Debug messages enabled');
3714     }
3715 }
3716
3717 =head2 $c->setup_plugins
3718
3719 Sets up plugins.
3720
3721 =cut
3722
3723 =head2 $c->setup_stats
3724
3725 Sets up timing statistics class.
3726
3727 =cut
3728
3729 sub setup_stats {
3730     my ( $class, $stats ) = @_;
3731
3732     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3733
3734     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3735     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3736         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3737         $class->log->debug('Statistics enabled');
3738     }
3739 }
3740
3741
3742 =head2 $c->registered_plugins
3743
3744 Returns a sorted list of the plugins which have either been stated in the
3745 import list.
3746
3747 If passed a given plugin name, it will report a boolean value indicating
3748 whether or not that plugin is loaded.  A fully qualified name is required if
3749 the plugin name does not begin with C<Catalyst::Plugin::>.
3750
3751  if ($c->registered_plugins('Some::Plugin')) {
3752      ...
3753  }
3754
3755 =cut
3756
3757 {
3758
3759     sub registered_plugins {
3760         my $proto = shift;
3761         return sort keys %{ $proto->_plugins } unless @_;
3762         my $plugin = shift;
3763         return 1 if exists $proto->_plugins->{$plugin};
3764         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3765     }
3766
3767     sub _register_plugin {
3768         my ( $proto, $plugin, $instant ) = @_;
3769         my $class = ref $proto || $proto;
3770
3771         load_class( $plugin );
3772         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3773             if $plugin->isa( 'Catalyst::Component' );
3774         my $plugin_meta = Moose::Meta::Class->create($plugin);
3775         if (!$plugin_meta->has_method('new')
3776             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3777             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3778         }
3779         if (!$instant && !$proto->_plugins->{$plugin}) {
3780             my $meta = Class::MOP::get_metaclass_by_name($class);
3781             $meta->superclasses($plugin, $meta->superclasses);
3782         }
3783         $proto->_plugins->{$plugin} = 1;
3784         return $class;
3785     }
3786
3787     sub _default_plugins { return qw() }
3788
3789     sub setup_plugins {
3790         my ( $class, $plugins ) = @_;
3791
3792         $class->_plugins( {} ) unless $class->_plugins;
3793         $plugins = [ grep {
3794             m/Unicode::Encoding/ ? do {
3795                 $class->log->warn(
3796                     'Unicode::Encoding plugin is auto-applied,'
3797                     . ' please remove this from your appclass'
3798                     . ' and make sure to define "encoding" config'
3799                 );
3800                 unless (exists $class->config->{'encoding'}) {
3801                   $class->config->{'encoding'} = 'UTF-8';
3802                 }
3803                 () }
3804                 : $_
3805         } @$plugins ];
3806         push @$plugins, $class->_default_plugins;
3807         $plugins = Data::OptList::mkopt($plugins || []);
3808
3809         my @plugins = map {
3810             [ Catalyst::Utils::resolve_namespace(
3811                   $class . '::Plugin',
3812                   'Catalyst::Plugin', $_->[0]
3813               ),
3814               $_->[1],
3815             ]
3816          } @{ $plugins };
3817
3818         for my $plugin ( reverse @plugins ) {
3819             load_class($plugin->[0], $plugin->[1]);
3820             my $meta = find_meta($plugin->[0]);
3821             next if $meta && $meta->isa('Moose::Meta::Role');
3822
3823             $class->_register_plugin($plugin->[0]);
3824         }
3825
3826         my @roles =
3827             map  { $_->[0]->name, $_->[1] }
3828             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3829             map  { [find_meta($_->[0]), $_->[1]] }
3830             @plugins;
3831
3832         Moose::Util::apply_all_roles(
3833             $class => @roles
3834         ) if @roles;
3835     }
3836 }
3837
3838 =head2 default_middleware
3839
3840 Returns a list of instantiated PSGI middleware objects which is the default
3841 middleware that is active for this application (taking any configuration
3842 options into account, excluding your custom added middleware via the C<psgi_middleware>
3843 configuration option).  You can override this method if you wish to change
3844 the default middleware (although do so at risk since some middleware is vital
3845 to application function.)
3846
3847 The current default middleware list is:
3848
3849       Catalyst::Middleware::Stash
3850       Plack::Middleware::HTTPExceptions
3851       Plack::Middleware::RemoveRedundantBody
3852       Plack::Middleware::FixMissingBodyInRedirect
3853       Plack::Middleware::ContentLength
3854       Plack::Middleware::MethodOverride
3855       Plack::Middleware::Head
3856
3857 If the configuration setting C<using_frontend_proxy> is true we add:
3858
3859       Plack::Middleware::ReverseProxy
3860
3861 If the configuration setting C<using_frontend_proxy_path> is true we add:
3862
3863       Plack::Middleware::ReverseProxyPath
3864
3865 But B<NOTE> that L<Plack::Middleware::ReverseProxyPath> is not a dependency of the
3866 L<Catalyst> distribution so if you want to use this option you should add it to
3867 your project distribution file.
3868
3869 These middlewares will be added at L</setup_middleware> during the
3870 L</setup> phase of application startup.
3871
3872 =cut
3873
3874 sub default_middleware {
3875     my $class = shift;
3876     my @mw = (
3877       Catalyst::Middleware::Stash->new,
3878       Plack::Middleware::HTTPExceptions->new,
3879       Plack::Middleware::RemoveRedundantBody->new,
3880       Plack::Middleware::FixMissingBodyInRedirect->new,
3881       Plack::Middleware::ContentLength->new,
3882       Plack::Middleware::MethodOverride->new,
3883       Plack::Middleware::Head->new);
3884
3885     if($class->config->{using_frontend_proxy}) {
3886         push @mw, Plack::Middleware::ReverseProxy->new;
3887     }
3888
3889     if($class->config->{using_frontend_proxy_path}) {
3890         if(Class::Load::try_load_class('Plack::Middleware::ReverseProxyPath')) {
3891             push @mw, Plack::Middleware::ReverseProxyPath->new;
3892         } else {
3893           $class->log->error("Cannot use configuration 'using_frontend_proxy_path' because 'Plack::Middleware::ReverseProxyPath' is not installed");
3894         }
3895     }
3896
3897     return @mw;
3898 }
3899
3900 =head2 registered_middlewares
3901
3902 Read only accessor that returns an array of all the middleware in the order
3903 that they were added (which is the REVERSE of the order they will be applied).
3904
3905 The values returned will be either instances of L<Plack::Middleware> or of a
3906 compatible interface, or a coderef, which is assumed to be inlined middleware
3907
3908 =head2 setup_middleware (?@middleware)
3909
3910 Read configuration information stored in configuration key C<psgi_middleware> or
3911 from passed @args.
3912
3913 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3914 to use it to enable L<Plack::Middleware>
3915
3916 This method is automatically called during 'setup' of your application, so
3917 you really don't need to invoke it.  However you may do so if you find the idea
3918 of loading middleware via configuration weird :).  For example:
3919
3920     package MyApp;
3921
3922     use Catalyst;
3923
3924     __PACKAGE__->setup_middleware('Head');
3925     __PACKAGE__->setup;
3926
3927 When we read middleware definitions from configuration, we reverse the list
3928 which sounds odd but is likely how you expect it to work if you have prior
3929 experience with L<Plack::Builder> or if you previously used the plugin
3930 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3931
3932 So basically your middleware handles an incoming request from the first
3933 registered middleware, down and handles the response from the last middleware
3934 up.
3935
3936 =cut
3937
3938 sub registered_middlewares {
3939     my $class = shift;
3940     if(my $middleware = $class->_psgi_middleware) {
3941         my @mw = ($class->default_middleware, @$middleware);
3942
3943         if($class->config->{using_frontend_proxy}) {
3944           push @mw, Plack::Middleware::ReverseProxy->new;
3945         }
3946
3947         return @mw;
3948     } else {
3949         die "You cannot call ->registered_middlewares until middleware has been setup";
3950     }
3951 }
3952
3953 sub setup_middleware {
3954     my $class = shift;
3955     my @middleware_definitions;
3956
3957     # If someone calls this method you can add middleware with args.  However if its
3958     # called without an arg we need to setup the configuration middleware.
3959     if(@_) {
3960       @middleware_definitions = reverse(@_);
3961     } else {
3962       @middleware_definitions = reverse(@{$class->config->{'psgi_middleware'}||[]})
3963         unless $class->finalized_default_middleware;
3964       $class->finalized_default_middleware(1); # Only do this once, just in case some people call setup over and over...
3965     }
3966
3967     my @middleware = ();
3968     while(my $next = shift(@middleware_definitions)) {
3969         if(ref $next) {
3970             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3971                 push @middleware, $next;
3972             } elsif(is_plain_coderef($next)) {
3973                 push @middleware, $next;
3974             } elsif(is_plain_hashref($next)) {
3975                 my $namespace = shift @middleware_definitions;
3976                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3977                 push @middleware, $mw;
3978             } else {
3979               die "I can't handle middleware definition ${\ref $next}";
3980             }
3981         } else {
3982           my $mw = $class->Catalyst::Utils::build_middleware($next);
3983           push @middleware, $mw;
3984         }
3985     }
3986
3987     my @existing = @{$class->_psgi_middleware || []};
3988     $class->_psgi_middleware([@middleware,@existing,]);
3989 }
3990
3991 =head2 registered_data_handlers
3992
3993 A read only copy of registered Data Handlers returned as a Hash, where each key
3994 is a content type and each value is a subref that attempts to decode that content
3995 type.
3996
3997 =head2 setup_data_handlers (?@data_handler)
3998
3999 Read configuration information stored in configuration key C<data_handlers> or
4000 from passed @args.
4001
4002 See under L</CONFIGURATION> information regarding C<data_handlers>.
4003
4004 This method is automatically called during 'setup' of your application, so
4005 you really don't need to invoke it.
4006
4007 =head2 default_data_handlers
4008
4009 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
4010 only two default data handlers, for 'application/json' and an alternative to
4011 'application/x-www-form-urlencoded' which supposed nested form parameters via
4012 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
4013
4014 The 'application/json' data handler is used to parse incoming JSON into a Perl
4015 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
4016 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
4017 JSON decoder, and has the smallest dependency impact.
4018
4019 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
4020 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
4021 order to get the best performance.  You should add either to your dependency
4022 list (Makefile.PL, dist.ini, cpanfile, etc.)
4023
4024 =cut
4025
4026 sub registered_data_handlers {
4027     my $class = shift;
4028     if(my $data_handlers = $class->_data_handlers) {
4029         return %$data_handlers;
4030     } else {
4031         $class->setup_data_handlers;
4032         return $class->registered_data_handlers;
4033     }
4034 }
4035
4036 sub setup_data_handlers {
4037     my ($class, %data_handler_callbacks) = @_;
4038     %data_handler_callbacks = (
4039       %{$class->default_data_handlers},
4040       %{$class->config->{'data_handlers'}||+{}},
4041       %data_handler_callbacks);
4042
4043     $class->_data_handlers(\%data_handler_callbacks);
4044 }
4045
4046 sub default_data_handlers {
4047     my ($class) = @_;
4048     return +{
4049       'application/x-www-form-urlencoded' => sub {
4050           my ($fh, $req) = @_;
4051           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
4052           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
4053             ->can('build_cgi_struct')->($params);
4054       },
4055       'application/json' => sub {
4056           my ($fh, $req) = @_;
4057           my $parser = Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON');
4058           my $slurped;
4059           return eval {
4060             local $/;
4061             $slurped = $fh->getline;
4062             $parser->can("decode_json")->($slurped); # decode_json does utf8 decoding for us
4063           } || Catalyst::Exception->throw(sprintf "Error Parsing POST '%s', Error: %s", (defined($slurped) ? $slurped : 'undef') ,$@);
4064         },
4065     };
4066 }
4067
4068 sub _handle_http_exception {
4069     my ( $self, $error ) = @_;
4070     if (
4071            !$self->config->{always_catch_http_exceptions}
4072         && blessed $error
4073         && (
4074             $error->can('as_psgi')
4075             || (   $error->can('code')
4076                 && $error->code =~ m/^[1-5][0-9][0-9]$/ )
4077         )
4078       )
4079     {
4080         return 1;
4081     }
4082 }
4083
4084 =head2 $c->stack
4085
4086 Returns an arrayref of the internal execution stack (actions that are
4087 currently executing).
4088
4089 =head2 $c->stats
4090
4091 Returns the current timing statistics object. By default Catalyst uses
4092 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
4093 L<< stats_class|/"$c->stats_class" >>.
4094
4095 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
4096 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
4097 profile explicitly, although MyApp.pm still won't profile nor output anything
4098 by itself.
4099
4100 =head2 $c->stats_class
4101
4102 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
4103
4104 =head2 $app->stats_class_traits
4105
4106 A arrayref of L<Moose::Role>s that are applied to the stats_class before creating it.
4107
4108 =head2 $app->composed_stats_class
4109
4110 this is the stats_class composed with any 'stats_class_traits'.  You can
4111 name the full namespace of the role, or a namespace suffix, which will then
4112 be tried against the following standard namespace prefixes.
4113
4114     $MyApp::TraitFor::Stats::$trait_suffix
4115     Catalyst::TraitFor::Stats::$trait_suffix
4116
4117 So for example if you set:
4118
4119     MyApp->stats_class_traits(['Foo']);
4120
4121 We try each possible role in turn (and throw an error if none load)
4122
4123     Foo
4124     MyApp::TraitFor::Stats::Foo
4125     Catalyst::TraitFor::Stats::Foo
4126
4127 The namespace part 'TraitFor::Stats' was chosen to assist in backwards
4128 compatibility with L<CatalystX::RoleApplicator> which previously provided
4129 these features in a stand alone package.
4130
4131 =head2 $c->use_stats
4132
4133 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
4134
4135 Note that this is a static method, not an accessor and should be overridden
4136 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
4137
4138 =cut
4139
4140 sub use_stats { 0 }
4141
4142
4143 =head2 $c->write( $data )
4144
4145 Writes $data to the output stream. When using this method directly, you
4146 will need to manually set the C<Content-Length> header to the length of
4147 your output data, if known.
4148
4149 =cut
4150
4151 sub write {
4152     my $c = shift;
4153
4154     # Finalize headers if someone manually writes output (for compat)
4155     $c->finalize_headers;
4156
4157     return $c->response->write( @_ );
4158 }
4159
4160 =head2 version
4161
4162 Returns the Catalyst version number. Mostly useful for "powered by"
4163 messages in template systems.
4164
4165 =cut
4166
4167 sub version { return $Catalyst::VERSION }
4168
4169 =head1 CONFIGURATION
4170
4171 There are a number of 'base' config variables which can be set:
4172
4173 =over
4174
4175 =item *
4176
4177 C<always_catch_http_exceptions> - As of version 5.90060 Catalyst
4178 rethrows errors conforming to the interface described by
4179 L<Plack::Middleware::HTTPExceptions> and lets the middleware deal with it.
4180 Set true to get the deprecated behaviour and have Catalyst catch HTTP exceptions.
4181
4182 =item *
4183
4184 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
4185
4186 =item *
4187
4188 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
4189
4190 =item *
4191
4192 C<disable_component_resolution_regex_fallback> - Turns
4193 off the deprecated component resolution functionality so
4194 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
4195 are called then regex search will not be attempted on string values and
4196 instead C<undef> will be returned.
4197
4198 =item *
4199
4200 C<home> - The application home directory. In an uninstalled application,
4201 this is the top level application directory. In an installed application,
4202 this will be the directory containing C<< MyApp.pm >>.
4203
4204 =item *
4205
4206 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
4207
4208 =item *
4209
4210 C<name> - The name of the application in debug messages and the debug and
4211 welcome screens
4212
4213 =item *
4214
4215 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
4216 until it is accessed. This allows you to (for example) check authentication (and reject
4217 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
4218
4219 =item *
4220
4221 C<root> - The root directory for templates. Usually this is just a
4222 subdirectory of the home directory, but you can set it to change the
4223 templates to a different directory.
4224
4225 =item *
4226
4227 C<search_extra> - Array reference passed to Module::Pluggable to for additional
4228 namespaces from which components will be loaded (and constructed and stored in
4229 C<< $c->components >>).
4230
4231 =item *
4232
4233 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
4234 to be shown in hit debug tables in the test server.
4235
4236 =item *
4237
4238 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
4239 variable should be used for determining the request path.
4240
4241 Most web server environments pass the requested path to the application using environment variables,
4242 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
4243 exposed as C<< $c->request->base >>) and the request path below that base.
4244
4245 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
4246 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
4247
4248 =over
4249
4250 =item use_request_uri_for_path => 0
4251
4252 This is the default (and the) traditional method that Catalyst has used for determining the path information.
4253 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
4254 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
4255 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
4256
4257 However this method has the major disadvantage that it is impossible to correctly decode some elements
4258 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
4259 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
4260 can't distinguish / vs %2F in paths (in addition to other encoded values).
4261
4262 =item use_request_uri_for_path => 1
4263
4264 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
4265 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
4266 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
4267
4268 Given that this method of path resolution is provably more correct, it is recommended that you use
4269 this unless you have a specific need to deploy your application in a non-standard environment, and you are
4270 aware of the implications of not being able to handle encoded URI paths correctly.
4271
4272 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
4273 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
4274 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
4275 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
4276 C<< $c->request->base >> will be incorrect.
4277
4278 =back
4279
4280 =item *
4281
4282 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
4283
4284 =item *
4285
4286 C<using_frontend_proxy_path> - Enabled L<Plack::Middleware::ReverseProxyPath> on your application (if
4287 installed, otherwise log an error).  This is useful if your application is not running on the
4288 'root' (or /) of your host server.  B<NOTE> if you use this feature you should add the required
4289 middleware to your project dependency list since its not automatically a dependency of L<Catalyst>.
4290 This has been done since not all people need this feature and we wish to restrict the growth of
4291 L<Catalyst> dependencies.
4292
4293 =item *
4294
4295 C<encoding> - See L</ENCODING>
4296
4297 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
4298 value to undef.
4299
4300 =item *
4301
4302 C<abort_chain_on_error_fix>
4303
4304 When there is an error in an action chain, the default behavior is to continue
4305 processing the remaining actions and then catch the error upon chain end.  This
4306 can lead to running actions when the application is in an unexpected state.  If
4307 you have this issue, setting this config value to true will promptly exit a
4308 chain when there is an error raised in any action (thus terminating the chain
4309 early.)
4310
4311 use like:
4312
4313     __PACKAGE__->config(abort_chain_on_error_fix => 1);
4314
4315 In the future this might become the default behavior.
4316
4317 =item *
4318
4319 C<use_hash_multivalue_in_request>
4320
4321 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
4322 and C<parameters> return a hashref where values might be scalar or an arrayref
4323 depending on the incoming data.  In many cases this can be undesirable as it
4324 leads one to writing defensive code like the following:
4325
4326     my ($val) = ref($c->req->parameters->{a}) ?
4327       @{$c->req->parameters->{a}} :
4328         $c->req->parameters->{a};
4329
4330 Setting this configuration item to true will make L<Catalyst> populate the
4331 attributes underlying these methods with an instance of L<Hash::MultiValue>
4332 which is used by L<Plack::Request> and others to solve this very issue.  You
4333 may prefer this behavior to the default, if so enable this option (be warned
4334 if you enable it in a legacy application we are not sure if it is completely
4335 backwardly compatible).
4336
4337 =item *
4338
4339 C<skip_complex_post_part_handling>
4340
4341 When creating body parameters from a POST, if we run into a multipart POST
4342 that does not contain uploads, but instead contains inlined complex data
4343 (very uncommon) we cannot reliably convert that into field => value pairs.  So
4344 instead we create an instance of L<Catalyst::Request::PartData>.  If this causes
4345 issue for you, you can disable this by setting C<skip_complex_post_part_handling>
4346 to true (default is false).
4347
4348 =item *
4349
4350 C<skip_body_param_unicode_decoding>
4351
4352 Generally we decode incoming POST params based on your declared encoding (the
4353 default for this is to decode UTF-8).  If this is causing you trouble and you
4354 do not wish to turn all encoding support off (with the C<encoding> configuration
4355 parameter) you may disable this step atomically by setting this configuration
4356 parameter to true.
4357
4358 =item *
4359
4360 C<do_not_decode_query>
4361
4362 If true, then do not try to character decode any wide characters in your
4363 request URL query or keywords.  Most readings of the relevant specifications
4364 suggest these should be UTF-* encoded, which is the default that L<Catalyst>
4365 will use, however if you are creating a lot of URLs manually or have external
4366 evil clients, this might cause you trouble.  If you find the changes introduced
4367 in Catalyst version 5.90080+ break some of your query code, you may disable
4368 the UTF-8 decoding globally using this configuration.
4369
4370 This setting takes precedence over C<default_query_encoding>
4371
4372 =item *
4373
4374 C<do_not_check_query_encoding>
4375
4376 Catalyst versions 5.90080 - 5.90106 would decode query parts of an incoming
4377 request but would not raise an exception when the decoding failed due to
4378 incorrect unicode.  It now does, but if this change is giving you trouble
4379 you may disable it by setting this configuration to true.
4380
4381 =item *
4382
4383 C<default_query_encoding>
4384
4385 By default we decode query and keywords in your request URL using UTF-8, which
4386 is our reading of the relevant specifications.  This setting allows one to
4387 specify a fixed value for how to decode your query.  You might need this if
4388 you are doing a lot of custom encoding of your URLs and not using UTF-8.
4389
4390 =item *
4391
4392 C<use_chained_args_0_special_case>
4393
4394 In older versions of Catalyst, when more than one action matched the same path
4395 AND all those matching actions declared Args(0), we'd break the tie by choosing
4396 the first action defined.  We now normalized how Args(0) works so that it
4397 follows the same rule as Args(N), which is to say when we need to break a tie
4398 we choose the LAST action defined.  If this breaks your code and you don't
4399 have time to update to follow the new normalized approach, you may set this
4400 value to true and it will globally revert to the original chaining behavior.
4401
4402 =item *
4403
4404 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
4405
4406 =item *
4407
4408 C<data_handlers> - See L<DATA HANDLERS>.
4409
4410 =item *
4411
4412 C<stats_class_traits>
4413
4414 An arrayref of L<Moose::Role>s that get composed into your stats class.
4415
4416 =item *
4417
4418 C<request_class_traits>
4419
4420 An arrayref of L<Moose::Role>s that get composed into your request class.
4421
4422 =item *
4423
4424 C<response_class_traits>
4425
4426 An arrayref of L<Moose::Role>s that get composed into your response class.
4427
4428 =item *
4429
4430 C<inject_components>
4431
4432 A Hashref of L<Catalyst::Component> subclasses that are 'injected' into configuration.
4433 For example:
4434
4435     MyApp->config({
4436       inject_components => {
4437         'Controller::Err' => { from_component => 'Local::Controller::Errors' },
4438         'Model::Zoo' => { from_component => 'Local::Model::Foo' },
4439         'Model::Foo' => { from_component => 'Local::Model::Foo', roles => ['TestRole'] },
4440       },
4441       'Controller::Err' => { a => 100, b=>200, namespace=>'error' },
4442       'Model::Zoo' => { a => 2 },
4443       'Model::Foo' => { a => 100 },
4444     });
4445
4446 Generally L<Catalyst> looks for components in your Model/View or Controller directories.
4447 However for cases when you which to use an existing component and you don't need any
4448 customization (where for when you can apply a role to customize it) you may inject those
4449 components into your application.  Please note any configuration should be done 'in the
4450 normal way', with a key under configuration named after the component affix, as in the
4451 above example.
4452
4453 Using this type of injection allows you to construct significant amounts of your application
4454 with only configuration!.  This may or may not lead to increased code understanding.
4455
4456 Please not you may also call the ->inject_components application method as well, although
4457 you must do so BEFORE setup.
4458
4459 =back
4460
4461 =head1 EXCEPTIONS
4462
4463 Generally when you throw an exception inside an Action (or somewhere in
4464 your stack, such as in a model that an Action is calling) that exception
4465 is caught by Catalyst and unless you either catch it yourself (via eval
4466 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
4467 will eventually reach L</finalize_errors> and return either the debugging
4468 error stack page, or the default error page.  However, if your exception
4469 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
4470 instead rethrow it so that it can be handled by that middleware (which
4471 is part of the default middleware).  For example this would allow
4472
4473     use HTTP::Throwable::Factory 'http_throw';
4474
4475     sub throws_exception :Local {
4476       my ($self, $c) = @_;
4477
4478       http_throw(SeeOther => { location =>
4479         $c->uri_for($self->action_for('redirect')) });
4480
4481     }
4482
4483 =head1 INTERNAL ACTIONS
4484
4485 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
4486 C<_ACTION>, and C<_END>. These are by default not shown in the private
4487 action table, but you can make them visible with a config parameter.
4488
4489     MyApp->config(show_internal_actions => 1);
4490
4491 =head1 ON-DEMAND PARSER
4492
4493 The request body is usually parsed at the beginning of a request,
4494 but if you want to handle input yourself, you can enable on-demand
4495 parsing with a config parameter.
4496
4497     MyApp->config(parse_on_demand => 1);
4498
4499 =head1 PROXY SUPPORT
4500
4501 Many production servers operate using the common double-server approach,
4502 with a lightweight frontend web server passing requests to a larger
4503 backend server. An application running on the backend server must deal
4504 with two problems: the remote user always appears to be C<127.0.0.1> and
4505 the server's hostname will appear to be C<localhost> regardless of the
4506 virtual host that the user connected through.
4507
4508 Catalyst will automatically detect this situation when you are running
4509 the frontend and backend servers on the same machine. The following
4510 changes are made to the request.
4511
4512     $c->req->address is set to the user's real IP address, as read from
4513     the HTTP X-Forwarded-For header.
4514
4515     The host value for $c->req->base and $c->req->uri is set to the real
4516     host, as read from the HTTP X-Forwarded-Host header.
4517
4518 Additionally, you may be running your backend application on an insecure
4519 connection (port 80) while your frontend proxy is running under SSL.  If there
4520 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
4521 tell Catalyst what port the frontend listens on.  This will allow all URIs to
4522 be created properly.
4523
4524 In the case of passing in:
4525
4526     X-Forwarded-Port: 443
4527
4528 All calls to C<uri_for> will result in an https link, as is expected.
4529
4530 Obviously, your web server must support these headers for this to work.
4531
4532 In a more complex server farm environment where you may have your
4533 frontend proxy server(s) on different machines, you will need to set a
4534 configuration option to tell Catalyst to read the proxied data from the
4535 headers.
4536
4537     MyApp->config(using_frontend_proxy => 1);
4538
4539 If you do not wish to use the proxy support at all, you may set:
4540
4541     MyApp->config(ignore_frontend_proxy => 0);
4542
4543 =head2 Note about psgi files
4544
4545 Note that if you supply your own .psgi file, calling
4546 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
4547
4548 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
4549 in your psgi, for example:
4550
4551     builder {
4552         enable "Plack::Middleware::ReverseProxy";
4553         MyApp->psgi_app
4554     };
4555
4556 This will unconditionally add the ReverseProxy support, or you need to call
4557 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
4558 apply the support depending upon your config).
4559
4560 See L<Catalyst::PSGI> for more information.
4561
4562 =head1 THREAD SAFETY
4563
4564 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
4565 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
4566 believe the Catalyst core to be thread-safe.
4567
4568 If you plan to operate in a threaded environment, remember that all other
4569 modules you are using must also be thread-safe. Some modules, most notably
4570 L<DBD::SQLite>, are not thread-safe.
4571
4572 =head1 DATA HANDLERS
4573
4574 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
4575 form parameters and URL search query fields.  However it has become common
4576 for various alternative content types to be PUT or POSTed to your controllers
4577 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
4578 XML and other content types when communicating with an application server.  In
4579 order to better support this use case, L<Catalyst> defines a global configuration
4580 option, C<data_handlers>, which lets you associate a content type with a coderef
4581 that parses that content type into something Perl can readily access.
4582
4583     package MyApp::Web;
4584
4585     use Catalyst;
4586     use JSON::Maybe;
4587
4588     __PACKAGE__->config(
4589       data_handlers => {
4590         'application/json' => sub { local $/; decode_json $_->getline },
4591       },
4592       ## Any other configuration.
4593     );
4594
4595     __PACKAGE__->setup;
4596
4597 By default L<Catalyst> comes with a generic JSON data handler similar to the
4598 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
4599 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
4600 it installed (if you want the faster XS parser, add it to you project Makefile.PL
4601 or dist.ini, cpanfile, etc.)
4602
4603 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
4604 (matched against the incoming request type using a regexp such as to be case
4605 insensitive) and whose values are coderefs that receive a localized version of
4606 C<$_> which is a filehandle object pointing to received body.
4607
4608 This feature is considered an early access release and we reserve the right
4609 to alter the interface in order to provide a performant and secure solution to
4610 alternative request body content.  Your reports welcomed!
4611
4612 =head1 PSGI MIDDLEWARE
4613
4614 You can define middleware, defined as L<Plack::Middleware> or a compatible
4615 interface in configuration.  Your middleware definitions are in the form of an
4616 arrayref under the configuration key C<psgi_middleware>.  Here's an example
4617 with details to follow:
4618
4619     package MyApp::Web;
4620
4621     use Catalyst;
4622     use Plack::Middleware::StackTrace;
4623
4624     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4625
4626     __PACKAGE__->config(
4627       'psgi_middleware', [
4628         'Debug',
4629         '+MyApp::Custom',
4630         $stacktrace_middleware,
4631         'Session' => {store => 'File'},
4632         sub {
4633           my $app = shift;
4634           return sub {
4635             my $env = shift;
4636             $env->{myapp.customkey} = 'helloworld';
4637             $app->($env);
4638           },
4639         },
4640       ],
4641     );
4642
4643     __PACKAGE__->setup;
4644
4645 So the general form is:
4646
4647     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
4648
4649 Where C<@middleware> is one or more of the following, applied in the REVERSE of
4650 the order listed (to make it function similarly to L<Plack::Builder>:
4651
4652 Alternatively, you may also define middleware by calling the L</setup_middleware>
4653 package method:
4654
4655     package MyApp::Web;
4656
4657     use Catalyst;
4658
4659     __PACKAGE__->setup_middleware( \@middleware_definitions);
4660     __PACKAGE__->setup;
4661
4662 In the case where you do both (use 'setup_middleware' and configuration) the
4663 package call to setup_middleware will be applied earlier (in other words its
4664 middleware will wrap closer to the application).  Keep this in mind since in
4665 some cases the order of middleware is important.
4666
4667 The two approaches are not exclusive.
4668
4669 =over 4
4670
4671 =item Middleware Object
4672
4673 An already initialized object that conforms to the L<Plack::Middleware>
4674 specification:
4675
4676     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4677
4678     __PACKAGE__->config(
4679       'psgi_middleware', [
4680         $stacktrace_middleware,
4681       ]);
4682
4683
4684 =item coderef
4685
4686 A coderef that is an inlined middleware:
4687
4688     __PACKAGE__->config(
4689       'psgi_middleware', [
4690         sub {
4691           my $app = shift;
4692           return sub {
4693             my $env = shift;
4694             if($env->{PATH_INFO} =~m/forced/) {
4695               Plack::App::File
4696                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
4697                 ->call($env);
4698             } else {
4699               return $app->($env);
4700             }
4701          },
4702       },
4703     ]);
4704
4705
4706
4707 =item a scalar
4708
4709 We assume the scalar refers to a namespace after normalizing it using the
4710 following rules:
4711
4712 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
4713 is assumed to be 'as is', and we just install and use the middleware.
4714
4715 (2) If the scalar begins with "Plack::Middleware" or your application namespace
4716 (the package name of your Catalyst application subclass), we also assume then
4717 that it is a full namespace, and use it.
4718
4719 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
4720 resolve it first by looking for it under your application namespace (for example
4721 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
4722 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
4723 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
4724 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
4725 namespace first to let you 'override' common L<Plack::Middleware> locally, should
4726 you find that a good idea.
4727
4728 Examples:
4729
4730     package MyApp::Web;
4731
4732     __PACKAGE__->config(
4733       'psgi_middleware', [
4734         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
4735         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
4736         '+MyApp::Custom',  ## MyApp::Custom->wrap
4737       ],
4738     );
4739
4740 =item a scalar followed by a hashref
4741
4742 Just like the previous, except the following C<HashRef> is used as arguments
4743 to initialize the middleware object.
4744
4745     __PACKAGE__->config(
4746       'psgi_middleware', [
4747          'Session' => {store => 'File'},
4748     ]);
4749
4750 =back
4751
4752 Please see L<PSGI> for more on middleware.
4753
4754 =head1 ENCODING
4755
4756 Starting in L<Catalyst> version 5.90080 encoding is automatically enabled
4757 and set to encode all body responses to UTF8 when possible and applicable.
4758 Following is documentation on this process.  If you are using an older
4759 version of L<Catalyst> you should review documentation for that version since
4760 a lot has changed.
4761
4762 By default encoding is now 'UTF-8'.  You may turn it off by setting
4763 the encoding configuration to undef.
4764
4765     MyApp->config(encoding => undef);
4766
4767 This is recommended for temporary backwards compatibility only.
4768
4769 Encoding is automatically applied when the content-type is set to
4770 a type that can be encoded.  Currently we encode when the content type
4771 matches the following regular expression:
4772
4773     $content_type =~ /^text|xml$|javascript$/
4774
4775 Encoding is set on the application, but it is copied to the context object
4776 so that you can override it on a request basis.
4777
4778 Be default we don't automatically encode 'application/json' since the most
4779 common approaches to generating this type of response (Either via L<Catalyst::View::JSON>
4780 or L<Catalyst::Action::REST>) will do so already and we want to avoid double
4781 encoding issues.
4782
4783 If you are producing JSON response in an unconventional manner (such
4784 as via a template or manual strings) you should perform the UTF8 encoding
4785 manually as well such as to conform to the JSON specification.
4786
4787 NOTE: We also examine the value of $c->response->content_encoding.  If
4788 you set this (like for example 'gzip', and manually gzipping the body)
4789 we assume that you have done all the necessary encoding yourself, since
4790 we cannot encode the gzipped contents.  If you use a plugin like
4791 L<Catalyst::Plugin::Compress> you need to update to a modern version in order
4792 to have this function correctly  with the new UTF8 encoding code, or you
4793 can use L<Plack::Middleware::Deflater> or (probably best) do your compression on
4794 a front end proxy.
4795
4796 =head2 Methods
4797
4798 =over 4
4799
4800 =item encoding
4801
4802 Returns an instance of an C<Encode> encoding
4803
4804     print $c->encoding->name
4805
4806 =item handle_unicode_encoding_exception ($exception_context)
4807
4808 Method called when decoding process for a request fails.
4809
4810 An C<$exception_context> hashref is provided to allow you to override the
4811 behaviour of your application when given data with incorrect encodings.
4812
4813 The default method throws exceptions in the case of invalid request parameters
4814 (resulting in a 500 error), but ignores errors in upload filenames.
4815
4816 The keys passed in the C<$exception_context> hash are:
4817
4818 =over
4819
4820 =item param_value
4821
4822 The value which was not able to be decoded.
4823
4824 =item error_msg
4825
4826 The exception received from L<Encode>.
4827
4828 =item encoding_step
4829
4830 What type of data was being decoded. Valid values are (currently)
4831 C<params> - for request parameters / arguments / captures
4832 and C<uploads> - for request upload filenames.
4833
4834 =back
4835
4836 =back
4837
4838 =head1 SUPPORT
4839
4840 IRC:
4841
4842     Join #catalyst on irc.perl.org.
4843
4844 Mailing Lists:
4845
4846     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4847     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4848
4849 Web:
4850
4851     http://catalyst.perl.org
4852
4853 Wiki:
4854
4855     http://dev.catalyst.perl.org
4856
4857 =head1 SEE ALSO
4858
4859 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4860
4861 =head2 L<Catalyst::Manual> - The Catalyst Manual
4862
4863 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4864
4865 =head2 L<Catalyst::Engine> - Core engine
4866
4867 =head2 L<Catalyst::Log> - Log class.
4868
4869 =head2 L<Catalyst::Request> - Request object
4870
4871 =head2 L<Catalyst::Response> - Response object
4872
4873 =head2 L<Catalyst::Test> - The test suite.
4874
4875 =head1 PROJECT FOUNDER
4876
4877 sri: Sebastian Riedel <sri@cpan.org>
4878
4879 =head1 CONTRIBUTORS
4880
4881 abw: Andy Wardley
4882
4883 acme: Leon Brocard <leon@astray.com>
4884
4885 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4886
4887 andrewalker: André Walker <andre@cpan.org>
4888
4889 Andrew Bramble
4890
4891 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4892
4893 Andrew Ruthven
4894
4895 andyg: Andy Grundman <andy@hybridized.org>
4896
4897 audreyt: Audrey Tang
4898
4899 bricas: Brian Cassidy <bricas@cpan.org>
4900
4901 Caelum: Rafael Kitover <rkitover@io.com>
4902
4903 chansen: Christian Hansen
4904
4905 Chase Venters C<chase.venters@gmail.com>
4906
4907 chicks: Christopher Hicks
4908
4909 Chisel Wright C<pause@herlpacker.co.uk>
4910
4911 Danijel Milicevic C<me@danijel.de>
4912
4913 davewood: David Schmidt <davewood@cpan.org>
4914
4915 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4916
4917 David Naughton, C<naughton@umn.edu>
4918
4919 David E. Wheeler
4920
4921 dhoss: Devin Austin <dhoss@cpan.org>
4922
4923 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4924
4925 Drew Taylor
4926
4927 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4928
4929 esskar: Sascha Kiefer
4930
4931 fireartist: Carl Franks <cfranks@cpan.org>
4932
4933 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4934
4935 gabb: Danijel Milicevic
4936
4937 Gary Ashton Jones
4938
4939 Gavin Henry C<ghenry@perl.me.uk>
4940
4941 Geoff Richards
4942
4943 groditi: Guillermo Roditi <groditi@gmail.com>
4944
4945 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4946
4947 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4948
4949 jcamacho: Juan Camacho
4950
4951 jester: Jesse Sheidlower C<jester@panix.com>
4952
4953 jhannah: Jay Hannah <jay@jays.net>
4954
4955 Jody Belka
4956
4957 Johan Lindstrom
4958
4959 jon: Jon Schutz <jjschutz@cpan.org>
4960
4961 Jonathan Rockway C<< <jrockway@cpan.org> >>
4962
4963 Kieren Diment C<kd@totaldatasolution.com>
4964
4965 konobi: Scott McWhirter <konobi@cpan.org>
4966
4967 marcus: Marcus Ramberg <mramberg@cpan.org>
4968
4969 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4970
4971 mgrimes: Mark Grimes <mgrimes@cpan.org>
4972
4973 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4974
4975 mugwump: Sam Vilain
4976
4977 naughton: David Naughton
4978
4979 ningu: David Kamholz <dkamholz@cpan.org>
4980
4981 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4982
4983 numa: Dan Sully <daniel@cpan.org>
4984
4985 obra: Jesse Vincent
4986
4987 Octavian Rasnita
4988
4989 omega: Andreas Marienborg
4990
4991 Oleg Kostyuk <cub.uanic@gmail.com>
4992
4993 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4994
4995 rafl: Florian Ragwitz <rafl@debian.org>
4996
4997 random: Roland Lammel <lammel@cpan.org>
4998
4999 Robert Sedlacek C<< <rs@474.at> >>
5000
5001 SpiceMan: Marcel Montes
5002
5003 sky: Arthur Bergman
5004
5005 szbalint: Balint Szilakszi <szbalint@cpan.org>
5006
5007 t0m: Tomas Doran <bobtfish@bobtfish.net>
5008
5009 Ulf Edvinsson
5010
5011 vanstyn: Henry Van Styn <vanstyn@cpan.org>
5012
5013 Viljo Marrandi C<vilts@yahoo.com>
5014
5015 Will Hawes C<info@whawes.co.uk>
5016
5017 willert: Sebastian Willert <willert@cpan.org>
5018
5019 wreis: Wallace Reis <wreis@cpan.org>
5020
5021 Yuval Kogman, C<nothingmuch@woobling.org>
5022
5023 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
5024
5025 dd070: Dhaval Dhanani <dhaval070@gmail.com>
5026
5027 Upasana <me@upasana.me>
5028
5029 John Napiorkowski (jnap) <jjnapiork@cpan.org>
5030
5031 =head1 COPYRIGHT
5032
5033 Copyright (c) 2005-2015, the above named PROJECT FOUNDER and CONTRIBUTORS.
5034
5035 =head1 LICENSE
5036
5037 This library is free software. You can redistribute it and/or modify it under
5038 the same terms as Perl itself.
5039
5040 =cut
5041
5042 no Moose;
5043
5044 __PACKAGE__->meta->make_immutable;
5045
5046 1;