lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use File::stat;
  19 use Text::SimpleTable ();
  20 use Path::Class::Dir ();
  21 use Path::Class::File ();
  22 use URI ();
  23 use URI::http;
  24 use URI::https;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use Class::C3::Adopt::NEXT;
  28 use List::MoreUtils qw/uniq/;
  29 use attributes;
  30 use utf8;
  31 use Carp qw/croak carp shortmess/;
  32
  33 BEGIN { require 5.008004; }
  34
  35 has stack => (is => 'ro', default => sub { [] });
  36 has stash => (is => 'rw', default => sub { {} });
  37 has state => (is => 'rw', default => 0);
  38 has stats => (is => 'rw');
  39 has action => (is => 'rw');
  40 has counter => (is => 'rw', default => sub { {} });
  41 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  42 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  43 has namespace => (is => 'rw');
  44
  45 sub depth { scalar @{ shift->stack || [] }; }
  46 sub comp { shift->component(@_) }
  47
  48 sub req {
  49     my $self = shift; return $self->request(@_);
  50 }
  51 sub res {
  52     my $self = shift; return $self->response(@_);
  53 }
  54
  55 # For backwards compatibility
  56 sub finalize_output { shift->finalize_body(@_) };
  57
  58 # For statistics
  59 our $COUNT     = 1;
  60 our $START     = time;
  61 our $RECURSION = 1000;
  62 our $DETACH    = Catalyst::Exception::Detach->new;
  63 our $GO        = Catalyst::Exception::Go->new;
  64
  65 #I imagine that very few of these really need to be class variables. if any.
  66 #maybe we should just make them attributes with a default?
  67 __PACKAGE__->mk_classdata($_)
  68   for qw/container arguments dispatcher engine log dispatcher_class
  69   engine_class context_class request_class response_class stats_class
  70   setup_finished/;
  71
  72 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  73 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  74 __PACKAGE__->request_class('Catalyst::Request');
  75 __PACKAGE__->response_class('Catalyst::Response');
  76 __PACKAGE__->stats_class('Catalyst::Stats');
  77
  78 # Remember to update this in Catalyst::Runtime as well!
  79
  80 our $VERSION = '5.80033';
  81
  82 sub import {
  83     my ( $class, @arguments ) = @_;
  84
  85     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  86     # callers @ISA.
  87     return unless $class eq 'Catalyst';
  88
  89     my $caller = caller();
  90     return if $caller eq 'main';
  91
  92     my $meta = Moose::Meta::Class->initialize($caller);
  93
  94     unless ( $caller->isa('Catalyst') ) { # XXX - Remove!
  95         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Component'); # XXX - Remove!
  96         $meta->superclasses(@superclasses); # XXX - Remove!
  97     } # XXX - Remove!
  98
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub MODIFY_CODE_ATTRIBUTES {
 116     Catalyst::Exception->throw(
 117         "Catalyst applications (aka MyApp) cannot be controllers anymore. " .
 118         "That has been deprecated and removed. You should create a " .
 119         "controller class called Root.pm, and move relevant code to that class."
 120     );
 121 }
 122
 123
 124 sub _application { $_[0] }
 125
 126 =head1 NAME
 127
 128 Catalyst - The Elegant MVC Web Application Framework
 129
 130 =head1 SYNOPSIS
 131
 132 See the L<Catalyst::Manual> distribution for comprehensive
 133 documentation and tutorials.
 134
 135     # Install Catalyst::Devel for helpers and other development tools
 136     # use the helper to create a new application
 137     catalyst.pl MyApp
 138
 139     # add models, views, controllers
 140     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 141     script/myapp_create.pl view MyTemplate TT
 142     script/myapp_create.pl controller Search
 143
 144     # built in testserver -- use -r to restart automatically on changes
 145     # --help to see all available options
 146     script/myapp_server.pl
 147
 148     # command line testing interface
 149     script/myapp_test.pl /yada
 150
 151     ### in lib/MyApp.pm
 152     use Catalyst qw/-Debug/; # include plugins here as well
 153
 154     ### In lib/MyApp/Controller/Root.pm (autocreated)
 155     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 156         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 157         $c->stash->{template} = 'foo.tt'; # set the template
 158         # lookup something from db -- stash vars are passed to TT
 159         $c->stash->{data} =
 160           $c->model('Database::Foo')->search( { country => $args[0] } );
 161         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 162             $c->forward( 'bar' ); # process another action
 163             # do something else after forward returns
 164         }
 165     }
 166
 167     # The foo.tt TT template can use the stash data from the database
 168     [% WHILE (item = data.next) %]
 169         [% item.foo %]
 170     [% END %]
 171
 172     # called for /bar/of/soap, /bar/of/soap/10, etc.
 173     sub bar : Path('/bar/of/soap') { ... }
 174
 175     # called for all actions, from the top-most controller downwards
 176     sub auto : Private {
 177         my ( $self, $c ) = @_;
 178         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 179             $c->res->redirect( '/login' ); # require login
 180             return 0; # abort request and go immediately to end()
 181         }
 182         return 1; # success; carry on to next action
 183     }
 184
 185     # called after all actions are finished
 186     sub end : Private {
 187         my ( $self, $c ) = @_;
 188         if ( scalar @{ $c->error } ) { ... } # handle errors
 189         return if $c->res->body; # already have a response
 190         $c->forward( 'MyApp::View::TT' ); # render template
 191     }
 192
 193     ### in MyApp/Controller/Foo.pm
 194     # called for /foo/bar
 195     sub bar : Local { ... }
 196
 197     # called for /blargle
 198     sub blargle : Global { ... }
 199
 200     # an index action matches /foo, but not /foo/1, etc.
 201     sub index : Private { ... }
 202
 203     ### in MyApp/Controller/Foo/Bar.pm
 204     # called for /foo/bar/baz
 205     sub baz : Local { ... }
 206
 207     # first Root auto is called, then Foo auto, then this
 208     sub auto : Private { ... }
 209
 210     # powerful regular expression paths are also possible
 211     sub details : Regex('^product/(\w+)/details$') {
 212         my ( $self, $c ) = @_;
 213         # extract the (\w+) from the URI
 214         my $product = $c->req->captures->[0];
 215     }
 216
 217 See L<Catalyst::Manual::Intro> for additional information.
 218
 219 =head1 DESCRIPTION
 220
 221 Catalyst is a modern framework for making web applications without the
 222 pain usually associated with this process. This document is a reference
 223 to the main Catalyst application. If you are a new user, we suggest you
 224 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 225
 226 See L<Catalyst::Manual> for more documentation.
 227
 228 Catalyst plugins can be loaded by naming them as arguments to the "use
 229 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 230 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 231 C<My::Module>.
 232
 233     use Catalyst qw/My::Module/;
 234
 235 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 236 fully qualify the name by using a unary plus:
 237
 238     use Catalyst qw/
 239         My::Module
 240         +Fully::Qualified::Plugin::Name
 241     /;
 242
 243 Special flags like C<-Debug> and C<-Engine> can also be specified as
 244 arguments when Catalyst is loaded:
 245
 246     use Catalyst qw/-Debug My::Module/;
 247
 248 The position of plugins and flags in the chain is important, because
 249 they are loaded in the order in which they appear.
 250
 251 The following flags are supported:
 252
 253 =head2 -Debug
 254
 255 Enables debug output. You can also force this setting from the system
 256 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 257 settings override the application, with <MYAPP>_DEBUG having the highest
 258 priority.
 259
 260 This sets the log level to 'debug' and enables full debug output on the
 261 error screen. If you only want the latter, see L<< $c->debug >>.
 262
 263 =head2 -Engine
 264
 265 Forces Catalyst to use a specific engine. Omit the
 266 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 267
 268     use Catalyst qw/-Engine=CGI/;
 269
 270 =head2 -Home
 271
 272 Forces Catalyst to use a specific home directory, e.g.:
 273
 274     use Catalyst qw[-Home=/usr/mst];
 275
 276 This can also be done in the shell environment by setting either the
 277 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 278 is replaced with the uppercased name of your application, any "::" in
 279 the name will be replaced with underscores, e.g. MyApp::Web should use
 280 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 281
 282 If none of these are set, Catalyst will attempt to automatically detect the
 283 home directory. If you are working in a development envirnoment, Catalyst
 284 will try and find the directory containing either Makefile.PL, Build.PL or
 285 dist.ini. If the application has been installed into the system (i.e.
 286 you have done C<make install>), then Catalyst will use the path to your
 287 application module, without the .pm extension (ie, /foo/MyApp if your
 288 application was installed at /foo/MyApp.pm)
 289
 290 =head2 -Log
 291
 292     use Catalyst '-Log=warn,fatal,error';
 293
 294 Specifies a comma-delimited list of log levels.
 295
 296 =head2 -Stats
 297
 298 Enables statistics collection and reporting.
 299
 300    use Catalyst qw/-Stats=1/;
 301
 302 You can also force this setting from the system environment with CATALYST_STATS
 303 or <MYAPP>_STATS. The environment settings override the application, with
 304 <MYAPP>_STATS having the highest priority.
 305
 306 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 307
 308 =head1 METHODS
 309
 310 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 311
 312 =head2 $c->action
 313
 314 Returns a L<Catalyst::Action> object for the current action, which
 315 stringifies to the action name. See L<Catalyst::Action>.
 316
 317 =head2 $c->namespace
 318
 319 Returns the namespace of the current action, i.e., the URI prefix
 320 corresponding to the controller of the current action. For example:
 321
 322     # in Controller::Foo::Bar
 323     $c->namespace; # returns 'foo/bar';
 324
 325 =head2 $c->request
 326
 327 =head2 $c->req
 328
 329 Returns the current L<Catalyst::Request> object, giving access to
 330 information about the current client request (including parameters,
 331 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 332
 333 =head2 REQUEST FLOW HANDLING
 334
 335 =head2 $c->forward( $action [, \@arguments ] )
 336
 337 =head2 $c->forward( $class, $method, [, \@arguments ] )
 338
 339 Forwards processing to another action, by its private name. If you give a
 340 class name but no method, C<process()> is called. You may also optionally
 341 pass arguments in an arrayref. The action will receive the arguments in
 342 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 343 C<< $c->req->args >> will be restored to the previous values.
 344
 345 Any data C<return>ed from the action forwarded to, will be returned by the
 346 call to forward.
 347
 348     my $foodata = $c->forward('/foo');
 349     $c->forward('index');
 350     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 351     $c->forward('View::TT');
 352
 353 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 354 an C<< eval { } >> around the call (actually
 355 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 356 all 'dies' within the called action. If you want C<die> to propagate you
 357 need to do something like:
 358
 359     $c->forward('foo');
 360     die join "\n", @{ $c->error } if @{ $c->error };
 361
 362 Or make sure to always return true values from your actions and write
 363 your code like this:
 364
 365     $c->forward('foo') || return;
 366
 367 Another note is that C<< $c->forward >> always returns a scalar because it
 368 actually returns $c->state which operates in a scalar context.
 369 Thus, something like:
 370
 371     return @array;
 372
 373 in an action that is forwarded to is going to return a scalar,
 374 i.e. how many items are in that array, which is probably not what you want.
 375 If you need to return an array then return a reference to it,
 376 or stash it like so:
 377
 378     $c->stash->{array} = \@array;
 379
 380 and access it from the stash.
 381
 382 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 383
 384 =cut
 385
 386 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 387
 388 =head2 $c->detach( $action [, \@arguments ] )
 389
 390 =head2 $c->detach( $class, $method, [, \@arguments ] )
 391
 392 =head2 $c->detach()
 393
 394 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 395 doesn't return to the previous action when processing is finished.
 396
 397 When called with no arguments it escapes the processing chain entirely.
 398
 399 =cut
 400
 401 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 402
 403 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 404
 405 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 406
 407 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 408 but does a full dispatch, instead of just calling the new C<$action> /
 409 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 410 you go to are called, just like a new request.
 411
 412 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 413 This means, for example, that C<< $c->action >> methods such as
 414 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 415 L<reverse|Catalyst::Action/reverse> return information for the visited action
 416 when they are invoked within the visited action.  This is different from the
 417 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 418 continues to use the $c->action object from the caller action even when
 419 invoked from the callee.
 420
 421 C<< $c->stash >> is kept unchanged.
 422
 423 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 424 allows you to "wrap" another action, just as it would have been called by
 425 dispatching from a URL, while the analogous
 426 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 427 transfer control to another action as if it had been reached directly from a URL.
 428
 429 =cut
 430
 431 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 432
 433 =head2 $c->go( $action [, \@captures, \@arguments ] )
 434
 435 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 436
 437 The relationship between C<go> and
 438 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 439 the relationship between
 440 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 441 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 442 C<< $c->go >> will perform a full dispatch on the specified action or method,
 443 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 444 C<go> escapes the processing of the current request chain on completion, and
 445 does not return to its caller.
 446
 447 @arguments are arguments to the final destination of $action. @captures are
 448 arguments to the intermediate steps, if any, on the way to the final sub of
 449 $action.
 450
 451 =cut
 452
 453 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 454
 455 =head2 $c->response
 456
 457 =head2 $c->res
 458
 459 Returns the current L<Catalyst::Response> object, see there for details.
 460
 461 =head2 $c->stash
 462
 463 Returns a hashref to the stash, which may be used to store data and pass
 464 it between components during a request. You can also set hash keys by
 465 passing arguments. The stash is automatically sent to the view. The
 466 stash is cleared at the end of a request; it cannot be used for
 467 persistent storage (for this you must use a session; see
 468 L<Catalyst::Plugin::Session> for a complete system integrated with
 469 Catalyst).
 470
 471     $c->stash->{foo} = $bar;
 472     $c->stash( { moose => 'majestic', qux => 0 } );
 473     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 474
 475     # stash is automatically passed to the view for use in a template
 476     $c->forward( 'MyApp::View::TT' );
 477
 478 =cut
 479
 480 around stash => sub {
 481     my $orig = shift;
 482     my $c = shift;
 483     my $stash = $orig->($c);
 484     if (@_) {
 485         my $new_stash = @_ > 1 ? {@_} : $_[0];
 486         croak('stash takes a hash or hashref') unless ref $new_stash;
 487         foreach my $key ( keys %$new_stash ) {
 488           $stash->{$key} = $new_stash->{$key};
 489         }
 490     }
 491
 492     return $stash;
 493 };
 494
 495
 496 =head2 $c->error
 497
 498 =head2 $c->error($error, ...)
 499
 500 =head2 $c->error($arrayref)
 501
 502 Returns an arrayref containing error messages.  If Catalyst encounters an
 503 error while processing a request, it stores the error in $c->error.  This
 504 method should only be used to store fatal error messages.
 505
 506     my @error = @{ $c->error };
 507
 508 Add a new error.
 509
 510     $c->error('Something bad happened');
 511
 512 =cut
 513
 514 sub error {
 515     my $c = shift;
 516     if ( $_[0] ) {
 517         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 518         croak @$error unless ref $c;
 519         push @{ $c->{error} }, @$error;
 520     }
 521     elsif ( defined $_[0] ) { $c->{error} = undef }
 522     return $c->{error} || [];
 523 }
 524
 525
 526 =head2 $c->state
 527
 528 Contains the return value of the last executed action.
 529 Note that << $c->state >> operates in a scalar context which means that all
 530 values it returns are scalar.
 531
 532 =head2 $c->clear_errors
 533
 534 Clear errors.  You probably don't want to clear the errors unless you are
 535 implementing a custom error screen.
 536
 537 This is equivalent to running
 538
 539     $c->error(0);
 540
 541 =cut
 542
 543 sub clear_errors {
 544     my $c = shift;
 545     $c->error(0);
 546 }
 547
 548 =head2 COMPONENT ACCESSORS
 549
 550 =head2 $c->controller($name)
 551
 552 Gets a L<Catalyst::Controller> instance by name.
 553
 554     $c->controller('Foo')->do_stuff;
 555
 556 If the name is omitted, will return the controller for the dispatched
 557 action.
 558
 559 If you want to search for controllers, pass in a regexp as the argument.
 560
 561     # find all controllers that start with Foo
 562     my @foo_controllers = $c->controller(qr{^Foo});
 563
 564
 565 =cut
 566
 567 sub controller {
 568     my ( $c, $name, @args ) = @_;
 569
 570     $name ||= Catalyst::Utils::class2classshortsuffix( $c->action->class );
 571
 572     return $c->container->get_component_from_sub_container( 'controller', $name, $c, @args);
 573 }
 574
 575 =head2 $c->model($name)
 576
 577 Gets a L<Catalyst::Model> instance by name.
 578
 579     $c->model('Foo')->do_stuff;
 580
 581 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 582
 583 If the name is omitted, it will look for
 584  - a model object in $c->stash->{current_model_instance}, then
 585  - a model name in $c->stash->{current_model}, then
 586  - a config setting 'default_model', or
 587  - check if there is only one model, and return it if that's the case.
 588
 589 If you want to search for models, pass in a regexp as the argument.
 590
 591     # find all models that start with Foo
 592     my @foo_models = $c->model(qr{^Foo});
 593
 594 =cut
 595
 596 sub model {
 597     my ( $c, $name, @args ) = @_;
 598
 599     if (ref $c && !$name) {
 600         return $current_instance
 601             if my $current_instance = $c->stash->{current_model_instance};
 602
 603         $name = $c->stash->{current_model};
 604     }
 605
 606     return $c->container->get_component_from_sub_container( 'model', $name, $c, @args);
 607 }
 608
 609
 610 =head2 $c->view($name)
 611
 612 Gets a L<Catalyst::View> instance by name.
 613
 614     $c->view('Foo')->do_stuff;
 615
 616 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 617
 618 If the name is omitted, it will look for
 619  - a view object in $c->stash->{current_view_instance}, then
 620  - a view name in $c->stash->{current_view}, then
 621  - a config setting 'default_view', or
 622  - check if there is only one view, and return it if that's the case.
 623
 624 If you want to search for views, pass in a regexp as the argument.
 625
 626     # find all views that start with Foo
 627     my @foo_views = $c->view(qr{^Foo});
 628
 629 =cut
 630
 631 sub view {
 632     my ( $c, $name, @args ) = @_;
 633
 634     if (ref $c && !$name) {
 635         return $current_instance
 636             if my $current_instance = $c->stash->{current_view_instance};
 637
 638         $name = $c->stash->{current_view};
 639     }
 640
 641     return $c->container->get_component_from_sub_container( 'view', $name, $c, @args);
 642 }
 643
 644 =head2 $c->controllers
 645
 646 Returns the available names which can be passed to $c->controller
 647
 648 =cut
 649
 650 sub controllers {
 651     my ( $c ) = @_;
 652     return $c->container->get_sub_container('controller')->get_service_list;
 653 }
 654
 655 =head2 $c->models
 656
 657 Returns the available names which can be passed to $c->model
 658
 659 =cut
 660
 661 sub models {
 662     my ( $c ) = @_;
 663     return $c->container->get_sub_container('model')->get_service_list;
 664 }
 665
 666
 667 =head2 $c->views
 668
 669 Returns the available names which can be passed to $c->view
 670
 671 =cut
 672
 673 sub views {
 674     my ( $c ) = @_;
 675     return $c->container->get_sub_container('view')->get_service_list;
 676 }
 677
 678 =head2 $c->comp($name)
 679
 680 =head2 $c->component($name)
 681
 682 Gets a component object by name. This method is not recommended,
 683 unless you want to get a specific component by full
 684 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 685 should be used instead.
 686
 687 If C<$name> is a regexp, a list of components matched against the full
 688 component name will be returned.
 689
 690 =cut
 691
 692 sub component {
 693     my ( $c, $component, @args ) = @_;
 694
 695     unless ($component) {
 696         $c->log->warn('Calling $c->component with no args is deprecated and ');
 697         $c->log->warn('will be removed in a future release.');
 698         $c->log->warn('Use $c->component_list instead.');
 699         return $c->component_list;
 700     }
 701
 702     my @result = $c->container->find_component( $component, $c, @args );
 703
 704     # list context for regexp searches
 705     return @result if ref $component;
 706
 707     # only one component (if it's found) for string searches
 708     return shift @result if @result;
 709
 710     if (ref $c eq $component) {
 711         $c->log->warn('You are calling $c->comp("MyApp"). This behaviour is');
 712         $c->log->warn('deprecated, and will be removed in a future release.');
 713         return $c;
 714     }
 715
 716     $c->log->warn("Looking for '$component', but nothing was found.");
 717
 718     # I would expect to return an empty list here, but that breaks back-compat
 719     $c->log->warn('Component not found, returning the list of existing');
 720     $c->log->warn('components. This behavior is deprecated and will be');
 721     $c->log->warn('removed in a future release. Use $c->component_list');
 722     $c->log->warn('instead.');
 723
 724     return $c->component_list;
 725 }
 726
 727 =head2 $c->component_list
 728
 729 Returns the sorted list of the component names of the application.
 730
 731 =cut
 732
 733 sub component_list { sort keys %{ shift->components } }
 734
 735 =head2 CLASS DATA AND HELPER CLASSES
 736
 737 =head2 $c->config
 738
 739 Returns or takes a hashref containing the application's configuration.
 740
 741     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 742
 743 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 744 like C<myapp.conf> in your applications home directory. See
 745 L<Catalyst::Plugin::ConfigLoader>.
 746
 747 =head3 Cascading configuration
 748
 749 The config method is present on all Catalyst components, and configuration
 750 will be merged when an application is started. Configuration loaded with
 751 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 752 followed by configuration in your top level C<MyApp> class. These two
 753 configurations are merged, and then configuration data whose hash key matches a
 754 component name is merged with configuration for that component.
 755
 756 The configuration for a component is then passed to the C<new> method when a
 757 component is constructed.
 758
 759 For example:
 760
 761     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 762     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 763
 764 will mean that C<MyApp::Model::Foo> receives the following data when
 765 constructed:
 766
 767     MyApp::Model::Foo->new({
 768         bar => 'baz',
 769         quux => 'frob',
 770         overrides => 'me',
 771     });
 772
 773 It's common practice to use a Moose attribute
 774 on the receiving component to access the config value.
 775
 776     package MyApp::Model::Foo;
 777
 778     use Moose;
 779
 780     # this attr will receive 'baz' at construction time
 781     has 'bar' => (
 782         is  => 'rw',
 783         isa => 'Str',
 784     );
 785
 786 You can then get the value 'baz' by calling $c->model('Foo')->bar
 787 (or $self->bar inside code in the model).
 788
 789 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 790 as a way of reading config within your code, as this B<will not> give you the
 791 correctly merged config back. You B<MUST> take the config values supplied to
 792 the constructor and use those instead.
 793
 794 =cut
 795
 796 around config => sub {
 797     my $orig = shift;
 798     my $c = shift;
 799
 800     croak('Setting config after setup has been run is not allowed.')
 801         if ( @_ and $c->setup_finished );
 802
 803     $c->$orig(@_);
 804 };
 805
 806 =head2 $c->log
 807
 808 Returns the logging object instance. Unless it is already set, Catalyst
 809 sets this up with a L<Catalyst::Log> object. To use your own log class,
 810 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 811 C<< __PACKAGE__->setup >>.
 812
 813  __PACKAGE__->log( MyLogger->new );
 814  __PACKAGE__->setup;
 815
 816 And later:
 817
 818     $c->log->info( 'Now logging with my own logger!' );
 819
 820 Your log class should implement the methods described in
 821 L<Catalyst::Log>.
 822
 823
 824 =head2 $c->debug
 825
 826 Returns 1 if debug mode is enabled, 0 otherwise.
 827
 828 You can enable debug mode in several ways:
 829
 830 =over
 831
 832 =item By calling myapp_server.pl with the -d flag
 833
 834 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 835
 836 =item The -Debug option in your MyApp.pm
 837
 838 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 839
 840 =back
 841
 842 The first three also set the log level to 'debug'.
 843
 844 Calling C<< $c->debug(1) >> has no effect.
 845
 846 =cut
 847
 848 sub debug { 0 }
 849
 850 =head2 $c->dispatcher
 851
 852 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 853
 854 =head2 $c->engine
 855
 856 Returns the engine instance. See L<Catalyst::Engine>.
 857
 858
 859 =head2 UTILITY METHODS
 860
 861 =head2 $c->path_to(@path)
 862
 863 Merges C<@path> with C<< $c->config->{home} >> and returns a
 864 L<Path::Class::Dir> object. Note you can usually use this object as
 865 a filename, but sometimes you will have to explicitly stringify it
 866 yourself by calling the C<< ->stringify >> method.
 867
 868 For example:
 869
 870     $c->path_to( 'db', 'sqlite.db' );
 871
 872 =cut
 873
 874 sub path_to {
 875     my ( $c, @path ) = @_;
 876     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 877     if ( -d $path ) { return $path }
 878     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 879 }
 880
 881 =head2 $c->plugin( $name, $class, @args )
 882
 883 Helper method for plugins. It creates a class data accessor/mutator and
 884 loads and instantiates the given class.
 885
 886     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 887
 888     $c->prototype->define_javascript_functions;
 889
 890 B<Note:> This method of adding plugins is deprecated. The ability
 891 to add plugins like this B<will be removed> in a Catalyst 5.81.
 892 Please do not use this functionality in new code.
 893
 894 =cut
 895
 896 sub plugin {
 897     my ( $class, $name, $plugin, @args ) = @_;
 898
 899     # See block comment in t/aggregate/unit_core_plugin.t
 900     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 901
 902     $class->_register_plugin( $plugin, 1 );
 903
 904     eval { $plugin->import };
 905     $class->mk_classdata($name);
 906     my $obj;
 907     eval { $obj = $plugin->new(@args) };
 908
 909     if ($@) {
 910         Catalyst::Exception->throw( message =>
 911               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 912     }
 913
 914     $class->$name($obj);
 915     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 916       if $class->debug;
 917 }
 918
 919 =head2 MyApp->setup
 920
 921 Initializes the dispatcher and engine, loads any plugins, and loads the
 922 model, view, and controller components. You may also specify an array
 923 of plugins to load here, if you choose to not load them in the C<use
 924 Catalyst> line.
 925
 926     MyApp->setup;
 927     MyApp->setup( qw/-Debug/ );
 928
 929 =cut
 930
 931 sub setup {
 932     my ( $class, @arguments ) = @_;
 933     croak('Running setup more than once')
 934         if ( $class->setup_finished );
 935
 936     unless ( $class->isa('Catalyst') ) {
 937
 938         Catalyst::Exception->throw(
 939             message => qq/'$class' does not inherit from Catalyst/ );
 940     }
 941
 942     if ( $class->arguments ) {
 943         @arguments = ( @arguments, @{ $class->arguments } );
 944     }
 945
 946     # Process options
 947     my $flags = {};
 948
 949     foreach (@arguments) {
 950
 951         if (/^-Debug$/) {
 952             $flags->{log} =
 953               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 954         }
 955         elsif (/^-(\w+)=?(.*)$/) {
 956             $flags->{ lc $1 } = $2;
 957         }
 958         else {
 959             push @{ $flags->{plugins} }, $_;
 960         }
 961     }
 962
 963     $class->setup_config();
 964     $class->setup_home( delete $flags->{home} );
 965
 966     $class->setup_log( delete $flags->{log} );
 967     $class->setup_plugins( delete $flags->{plugins} );
 968     $class->setup_dispatcher( delete $flags->{dispatcher} );
 969     $class->setup_engine( delete $flags->{engine} );
 970     $class->setup_stats( delete $flags->{stats} );
 971
 972     for my $flag ( sort keys %{$flags} ) {
 973
 974         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 975             &$code( $class, delete $flags->{$flag} );
 976         }
 977         else {
 978             $class->log->warn(qq/Unknown flag "$flag"/);
 979         }
 980     }
 981
 982     eval { require Catalyst::Devel; };
 983     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 984         $class->log->warn(<<"EOF");
 985 You are running an old script!
 986
 987   Please update by running (this will overwrite existing files):
 988     catalyst.pl -force -scripts $class
 989
 990   or (this will not overwrite existing files):
 991     catalyst.pl -scripts $class
 992
 993 EOF
 994     }
 995
 996     if ( $class->debug ) {
 997         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 998
 999         if (@plugins) {
1000             my $column_width = Catalyst::Utils::term_width() - 6;
1001             my $t = Text::SimpleTable->new($column_width);
1002             $t->row($_) for @plugins;
1003             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1004         }
1005
1006         my $dispatcher = $class->dispatcher;
1007         my $engine     = $class->engine;
1008         my $home       = $class->config->{home};
1009
1010         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1011         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1012
1013         $home
1014           ? ( -d $home )
1015           ? $class->log->debug(qq/Found home "$home"/)
1016           : $class->log->debug(qq/Home "$home" doesn't exist/)
1017           : $class->log->debug(q/Couldn't find home/);
1018     }
1019
1020     # Call plugins setup, this is stupid and evil.
1021     # Also screws C3 badly on 5.10, hack to avoid.
1022     {
1023         no warnings qw/redefine/;
1024         local *setup = sub { };
1025         $class->setup unless $Catalyst::__AM_RESTARTING;
1026     }
1027
1028     $class->setup_components;
1029
1030     if (
1031         $class->debug and
1032         my @comps_types = $class->container->get_components_types
1033     ) {
1034         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1035         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1036         $t->row( @$_ ) for @comps_types;
1037
1038         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" );
1039     }
1040
1041     $class->setup_actions;
1042
1043     if ( $class->debug ) {
1044         my $name = $class->config->{name} || 'Application';
1045         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1046     }
1047
1048     # Make sure that the application class becomes immutable at this point,
1049     B::Hooks::EndOfScope::on_scope_end {
1050         return if $@;
1051         my $meta = Class::MOP::get_metaclass_by_name($class);
1052         if (
1053             $meta->is_immutable
1054             && ! { $meta->immutable_options }->{replace_constructor}
1055             && (
1056                    $class->isa('Class::Accessor::Fast')
1057                 || $class->isa('Class::Accessor')
1058             )
1059         ) {
1060             warn "You made your application class ($class) immutable, "
1061                 . "but did not inline the\nconstructor. "
1062                 . "This will break catalyst, as your app \@ISA "
1063                 . "Class::Accessor(::Fast)?\nPlease pass "
1064                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1065         }
1066         $meta->make_immutable(
1067             replace_constructor => 1,
1068         ) unless $meta->is_immutable;
1069     };
1070
1071     if ($class->config->{case_sensitive}) {
1072         $class->log->warn($class . "->config->{case_sensitive} is set.");
1073         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1074     }
1075
1076     $class->setup_finalize;
1077     # Should be the last thing we do so that user things hooking
1078     # setup_finalize can log..
1079     $class->log->_flush() if $class->log->can('_flush');
1080     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1081 }
1082
1083 =head2 $app->setup_finalize
1084
1085 A hook to attach modifiers to. This method does not do anything except set the
1086 C<setup_finished> accessor.
1087
1088 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1089
1090 Example:
1091
1092     after setup_finalize => sub {
1093         my $app = shift;
1094
1095         ## do stuff here..
1096     };
1097
1098 =cut
1099
1100 sub setup_finalize {
1101     my ($class) = @_;
1102     $class->setup_finished(1);
1103 }
1104
1105 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1106
1107 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1108
1109 Constructs an absolute L<URI> object based on the application root, the
1110 provided path, and the additional arguments and query parameters provided.
1111 When used as a string, provides a textual URI.  If you need more flexibility
1112 than this (i.e. the option to provide relative URIs etc.) see
1113 L<Catalyst::Plugin::SmartURI>.
1114
1115 If no arguments are provided, the URI for the current action is returned.
1116 To return the current action and also provide @args, use
1117 C<< $c->uri_for( $c->action, @args ) >>.
1118
1119 If the first argument is a string, it is taken as a public URI path relative
1120 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1121 relative to the application root (if it does). It is then merged with
1122 C<< $c->request->base >>; any C<@args> are appended as additional path
1123 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1124
1125 If the first argument is a L<Catalyst::Action> it represents an action which
1126 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1127 optional C<\@captures> argument (an arrayref) allows passing the captured
1128 variables that are needed to fill in the paths of Chained and Regex actions;
1129 once the path is resolved, C<uri_for> continues as though a path was
1130 provided, appending any arguments or parameters and creating an absolute
1131 URI.
1132
1133 The captures for the current request can be found in
1134 C<< $c->request->captures >>, and actions can be resolved using
1135 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1136 path, use C<< $c->uri_for_action >> instead.
1137
1138   # Equivalent to $c->req->uri
1139   $c->uri_for($c->action, $c->req->captures,
1140       @{ $c->req->args }, $c->req->params);
1141
1142   # For the Foo action in the Bar controller
1143   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1144
1145   # Path to a static resource
1146   $c->uri_for('/static/images/logo.png');
1147
1148 =cut
1149
1150 sub uri_for {
1151     my ( $c, $path, @args ) = @_;
1152
1153     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1154         $path = $path->path_prefix;
1155         $path =~ s{/+\z}{};
1156         $path .= '/';
1157     }
1158
1159     undef($path) if (defined $path && $path eq '');
1160
1161     my $params =
1162       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1163
1164     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1165     foreach my $arg (@args) {
1166         utf8::encode($arg) if utf8::is_utf8($arg);
1167         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1168     }
1169
1170     if ( blessed($path) ) { # action object
1171         s|/|%2F|g for @args;
1172         my $captures = [ map { s|/|%2F|g; $_; }
1173                         ( scalar @args && ref $args[0] eq 'ARRAY'
1174                          ? @{ shift(@args) }
1175                          : ()) ];
1176
1177         foreach my $capture (@$captures) {
1178             utf8::encode($capture) if utf8::is_utf8($capture);
1179             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1180         }
1181
1182         my $action = $path;
1183         $path = $c->dispatcher->uri_for_action($action, $captures);
1184         if (not defined $path) {
1185             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1186                 if $c->debug;
1187             return undef;
1188         }
1189         $path = '/' if $path eq '';
1190     }
1191
1192     unshift(@args, $path);
1193
1194     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1195         my $namespace = $c->namespace;
1196         if (defined $path) { # cheesy hack to handle path '../foo'
1197            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1198         }
1199         unshift(@args, $namespace || '');
1200     }
1201
1202     # join args with '/', or a blank string
1203     my $args = join('/', grep { defined($_) } @args);
1204     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1205     $args =~ s!^/+!!;
1206     my $base = $c->req->base;
1207     my $class = ref($base);
1208     $base =~ s{(?<!/)$}{/};
1209
1210     my $query = '';
1211
1212     if (my @keys = keys %$params) {
1213       # somewhat lifted from URI::_query's query_form
1214       $query = '?'.join('&', map {
1215           my $val = $params->{$_};
1216           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1217           s/ /+/g;
1218           my $key = $_;
1219           $val = '' unless defined $val;
1220           (map {
1221               my $param = "$_";
1222               utf8::encode( $param ) if utf8::is_utf8($param);
1223               # using the URI::Escape pattern here so utf8 chars survive
1224               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1225               $param =~ s/ /+/g;
1226               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1227       } @keys);
1228     }
1229
1230     my $res = bless(\"${base}${args}${query}", $class);
1231     $res;
1232 }
1233
1234 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1235
1236 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1237
1238 =over
1239
1240 =item $path
1241
1242 A private path to the Catalyst action you want to create a URI for.
1243
1244 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1245 >> and passing the resulting C<$action> and the remaining arguments to C<<
1246 $c->uri_for >>.
1247
1248 You can also pass in a Catalyst::Action object, in which case it is passed to
1249 C<< $c->uri_for >>.
1250
1251 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1252
1253 For example, if the action looks like:
1254
1255  package MyApp::Controller::Users;
1256
1257  sub lst : Path('the-list') {}
1258
1259 You can use:
1260
1261  $c->uri_for_action('/users/lst')
1262
1263 and it will create the URI /users/the-list.
1264
1265 =back
1266
1267 =cut
1268
1269 sub uri_for_action {
1270     my ( $c, $path, @args ) = @_;
1271     my $action = blessed($path)
1272       ? $path
1273       : $c->dispatcher->get_action_by_path($path);
1274     unless (defined $action) {
1275       croak "Can't find action for path '$path'";
1276     }
1277     return $c->uri_for( $action, @args );
1278 }
1279
1280 =head2 $c->welcome_message
1281
1282 Returns the Catalyst welcome HTML page.
1283
1284 =cut
1285
1286 sub welcome_message {
1287     my $c      = shift;
1288     my $name   = $c->config->{name};
1289     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1290     my $prefix = Catalyst::Utils::appprefix( ref $c );
1291     $c->response->content_type('text/html; charset=utf-8');
1292     return <<"EOF";
1293 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1294     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1295 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1296     <head>
1297     <meta http-equiv="Content-Language" content="en" />
1298     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1299         <title>$name on Catalyst $VERSION</title>
1300         <style type="text/css">
1301             body {
1302                 color: #000;
1303                 background-color: #eee;
1304             }
1305             div#content {
1306                 width: 640px;
1307                 margin-left: auto;
1308                 margin-right: auto;
1309                 margin-top: 10px;
1310                 margin-bottom: 10px;
1311                 text-align: left;
1312                 background-color: #ccc;
1313                 border: 1px solid #aaa;
1314             }
1315             p, h1, h2 {
1316                 margin-left: 20px;
1317                 margin-right: 20px;
1318                 font-family: verdana, tahoma, sans-serif;
1319             }
1320             a {
1321                 font-family: verdana, tahoma, sans-serif;
1322             }
1323             :link, :visited {
1324                     text-decoration: none;
1325                     color: #b00;
1326                     border-bottom: 1px dotted #bbb;
1327             }
1328             :link:hover, :visited:hover {
1329                     color: #555;
1330             }
1331             div#topbar {
1332                 margin: 0px;
1333             }
1334             pre {
1335                 margin: 10px;
1336                 padding: 8px;
1337             }
1338             div#answers {
1339                 padding: 8px;
1340                 margin: 10px;
1341                 background-color: #fff;
1342                 border: 1px solid #aaa;
1343             }
1344             h1 {
1345                 font-size: 0.9em;
1346                 font-weight: normal;
1347                 text-align: center;
1348             }
1349             h2 {
1350                 font-size: 1.0em;
1351             }
1352             p {
1353                 font-size: 0.9em;
1354             }
1355             p img {
1356                 float: right;
1357                 margin-left: 10px;
1358             }
1359             span#appname {
1360                 font-weight: bold;
1361                 font-size: 1.6em;
1362             }
1363         </style>
1364     </head>
1365     <body>
1366         <div id="content">
1367             <div id="topbar">
1368                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1369                     $VERSION</h1>
1370              </div>
1371              <div id="answers">
1372                  <p>
1373                  <img src="$logo" alt="Catalyst Logo" />
1374                  </p>
1375                  <p>Welcome to the  world of Catalyst.
1376                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1377                     framework will make web development something you had
1378                     never expected it to be: Fun, rewarding, and quick.</p>
1379                  <h2>What to do now?</h2>
1380                  <p>That really depends  on what <b>you</b> want to do.
1381                     We do, however, provide you with a few starting points.</p>
1382                  <p>If you want to jump right into web development with Catalyst
1383                     you might want to start with a tutorial.</p>
1384 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1385 </pre>
1386 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1387 <pre>
1388 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1389 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1390 </code></pre>
1391                  <h2>What to do next?</h2>
1392                  <p>Next it's time to write an actual application. Use the
1393                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1394                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1395                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1396                     they can save you a lot of work.</p>
1397                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1398                     <p>Also, be sure to check out the vast and growing
1399                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1400                     you are likely to find what you need there.
1401                     </p>
1402
1403                  <h2>Need help?</h2>
1404                  <p>Catalyst has a very active community. Here are the main places to
1405                     get in touch with us.</p>
1406                  <ul>
1407                      <li>
1408                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1409                      </li>
1410                      <li>
1411                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1412                      </li>
1413                      <li>
1414                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1415                      </li>
1416                  </ul>
1417                  <h2>In conclusion</h2>
1418                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1419                     as we enjoyed making it. Please contact us if you have ideas
1420                     for improvement or other feedback.</p>
1421              </div>
1422          </div>
1423     </body>
1424 </html>
1425 EOF
1426 }
1427
1428 =head1 INTERNAL METHODS
1429
1430 These methods are not meant to be used by end users.
1431
1432 =head2 $c->components
1433
1434 Returns a hash of components.
1435
1436 =cut
1437
1438 sub components {
1439     my ( $class, $comps ) = @_;
1440
1441     # people create components calling this sub directly, before setup
1442     $class->setup_config unless $class->container;
1443
1444     my $container = $class->container;
1445
1446     if ( $comps ) {
1447         $container->add_component(
1448             $_, $class
1449         ) for keys %$comps;
1450     }
1451
1452     return $container->get_all_components();
1453 }
1454
1455 =head2 $c->context_class
1456
1457 Returns or sets the context class.
1458
1459 =head2 $c->counter
1460
1461 Returns a hashref containing coderefs and execution counts (needed for
1462 deep recursion detection).
1463
1464 =head2 $c->depth
1465
1466 Returns the number of actions on the current internal execution stack.
1467
1468 =head2 $c->dispatch
1469
1470 Dispatches a request to actions.
1471
1472 =cut
1473
1474 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1475
1476 =head2 $c->dispatcher_class
1477
1478 Returns or sets the dispatcher class.
1479
1480 =head2 $c->dump_these
1481
1482 Returns a list of 2-element array references (name, structure) pairs
1483 that will be dumped on the error page in debug mode.
1484
1485 =cut
1486
1487 sub dump_these {
1488     my $c = shift;
1489     [ Request => $c->req ],
1490     [ Response => $c->res ],
1491     [ Stash => $c->stash ],
1492     [ Config => $c->config ];
1493 }
1494
1495 =head2 $c->engine_class
1496
1497 Returns or sets the engine class.
1498
1499 =head2 $c->execute( $class, $coderef )
1500
1501 Execute a coderef in given class and catch exceptions. Errors are available
1502 via $c->error.
1503
1504 =cut
1505
1506 sub execute {
1507     my ( $c, $class, $code ) = @_;
1508     $class = $c->component($class) || $class;
1509     $c->state(0);
1510
1511     if ( $c->depth >= $RECURSION ) {
1512         my $action = $code->reverse();
1513         $action = "/$action" unless $action =~ /->/;
1514         my $error = qq/Deep recursion detected calling "${action}"/;
1515         $c->log->error($error);
1516         $c->error($error);
1517         $c->state(0);
1518         return $c->state;
1519     }
1520
1521     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1522
1523     push( @{ $c->stack }, $code );
1524
1525     no warnings 'recursion';
1526     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1527     #      I have no idea how, ergo $ret (which appears to fix the issue)
1528     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1529
1530     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1531
1532     my $last = pop( @{ $c->stack } );
1533
1534     if ( my $error = $@ ) {
1535         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1536             $error->rethrow if $c->depth > 1;
1537         }
1538         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1539             $error->rethrow if $c->depth > 0;
1540         }
1541         else {
1542             unless ( ref $error ) {
1543                 no warnings 'uninitialized';
1544                 chomp $error;
1545                 my $class = $last->class;
1546                 my $name  = $last->name;
1547                 $error = qq/Caught exception in $class->$name "$error"/;
1548             }
1549             $c->error($error);
1550         }
1551         $c->state(0);
1552     }
1553     return $c->state;
1554 }
1555
1556 sub _stats_start_execute {
1557     my ( $c, $code ) = @_;
1558     my $appclass = ref($c) || $c;
1559     return if ( ( $code->name =~ /^_.*/ )
1560         && ( !$appclass->config->{show_internal_actions} ) );
1561
1562     my $action_name = $code->reverse();
1563     $c->counter->{$action_name}++;
1564
1565     my $action = $action_name;
1566     $action = "/$action" unless $action =~ /->/;
1567
1568     # determine if the call was the result of a forward
1569     # this is done by walking up the call stack and looking for a calling
1570     # sub of Catalyst::forward before the eval
1571     my $callsub = q{};
1572     for my $index ( 2 .. 11 ) {
1573         last
1574         if ( ( caller($index) )[0] eq 'Catalyst'
1575             && ( caller($index) )[3] eq '(eval)' );
1576
1577         if ( ( caller($index) )[3] =~ /forward$/ ) {
1578             $callsub = ( caller($index) )[3];
1579             $action  = "-> $action";
1580             last;
1581         }
1582     }
1583
1584     my $uid = $action_name . $c->counter->{$action_name};
1585
1586     # is this a root-level call or a forwarded call?
1587     if ( $callsub =~ /forward$/ ) {
1588         my $parent = $c->stack->[-1];
1589
1590         # forward, locate the caller
1591         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1592             $c->stats->profile(
1593                 begin  => $action,
1594                 parent => "$parent" . $c->counter->{"$parent"},
1595                 uid    => $uid,
1596             );
1597         }
1598         else {
1599
1600             # forward with no caller may come from a plugin
1601             $c->stats->profile(
1602                 begin => $action,
1603                 uid   => $uid,
1604             );
1605         }
1606     }
1607     else {
1608
1609         # root-level call
1610         $c->stats->profile(
1611             begin => $action,
1612             uid   => $uid,
1613         );
1614     }
1615     return $action;
1616
1617 }
1618
1619 sub _stats_finish_execute {
1620     my ( $c, $info ) = @_;
1621     $c->stats->profile( end => $info );
1622 }
1623
1624 =head2 $c->finalize
1625
1626 Finalizes the request.
1627
1628 =cut
1629
1630 sub finalize {
1631     my $c = shift;
1632
1633     for my $error ( @{ $c->error } ) {
1634         $c->log->error($error);
1635     }
1636
1637     # Allow engine to handle finalize flow (for POE)
1638     my $engine = $c->engine;
1639     if ( my $code = $engine->can('finalize') ) {
1640         $engine->$code($c);
1641     }
1642     else {
1643
1644         $c->finalize_uploads;
1645
1646         # Error
1647         if ( $#{ $c->error } >= 0 ) {
1648             $c->finalize_error;
1649         }
1650
1651         $c->finalize_headers;
1652
1653         # HEAD request
1654         if ( $c->request->method eq 'HEAD' ) {
1655             $c->response->body('');
1656         }
1657
1658         $c->finalize_body;
1659     }
1660
1661     $c->log_response;
1662
1663     if ($c->use_stats) {
1664         my $elapsed = sprintf '%f', $c->stats->elapsed;
1665         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1666         $c->log->info(
1667             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1668     }
1669
1670     return $c->response->status;
1671 }
1672
1673 =head2 $c->finalize_body
1674
1675 Finalizes body.
1676
1677 =cut
1678
1679 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1680
1681 =head2 $c->finalize_cookies
1682
1683 Finalizes cookies.
1684
1685 =cut
1686
1687 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1688
1689 =head2 $c->finalize_error
1690
1691 Finalizes error.
1692
1693 =cut
1694
1695 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1696
1697 =head2 $c->finalize_headers
1698
1699 Finalizes headers.
1700
1701 =cut
1702
1703 sub finalize_headers {
1704     my $c = shift;
1705
1706     my $response = $c->response; #accessor calls can add up?
1707
1708     # Check if we already finalized headers
1709     return if $response->finalized_headers;
1710
1711     # Handle redirects
1712     if ( my $location = $response->redirect ) {
1713         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1714         $response->header( Location => $location );
1715
1716         if ( !$response->has_body ) {
1717             # Add a default body if none is already present
1718             $response->body(
1719                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1720             );
1721         }
1722     }
1723
1724     # Content-Length
1725     if ( defined $response->body && length $response->body && !$response->content_length ) {
1726
1727         # get the length from a filehandle
1728         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1729         {
1730             my $stat = stat $response->body;
1731             if ( $stat && $stat->size > 0 ) {
1732                 $response->content_length( $stat->size );
1733             }
1734             else {
1735                 $c->log->warn('Serving filehandle without a content-length');
1736             }
1737         }
1738         else {
1739             # everything should be bytes at this point, but just in case
1740             $response->content_length( length( $response->body ) );
1741         }
1742     }
1743
1744     # Errors
1745     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1746         $response->headers->remove_header("Content-Length");
1747         $response->body('');
1748     }
1749
1750     $c->finalize_cookies;
1751
1752     $c->engine->finalize_headers( $c, @_ );
1753
1754     # Done
1755     $response->finalized_headers(1);
1756 }
1757
1758 =head2 $c->finalize_output
1759
1760 An alias for finalize_body.
1761
1762 =head2 $c->finalize_read
1763
1764 Finalizes the input after reading is complete.
1765
1766 =cut
1767
1768 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1769
1770 =head2 $c->finalize_uploads
1771
1772 Finalizes uploads. Cleans up any temporary files.
1773
1774 =cut
1775
1776 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1777
1778 =head2 $c->get_action( $action, $namespace )
1779
1780 Gets an action in a given namespace.
1781
1782 =cut
1783
1784 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1785
1786 =head2 $c->get_actions( $action, $namespace )
1787
1788 Gets all actions of a given name in a namespace and all parent
1789 namespaces.
1790
1791 =cut
1792
1793 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1794
1795 =head2 $app->handle_request( @arguments )
1796
1797 Called to handle each HTTP request.
1798
1799 =cut
1800
1801 sub handle_request {
1802     my ( $class, @arguments ) = @_;
1803
1804     # Always expect worst case!
1805     my $status = -1;
1806     eval {
1807         if ($class->debug) {
1808             my $secs = time - $START || 1;
1809             my $av = sprintf '%.3f', $COUNT / $secs;
1810             my $time = localtime time;
1811             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1812         }
1813
1814         my $c = $class->prepare(@arguments);
1815         $c->dispatch;
1816         $status = $c->finalize;
1817     };
1818
1819     if ( my $error = $@ ) {
1820         chomp $error;
1821         $class->log->error(qq/Caught exception in engine "$error"/);
1822     }
1823
1824     $COUNT++;
1825
1826     if(my $coderef = $class->log->can('_flush')){
1827         $class->log->$coderef();
1828     }
1829     return $status;
1830 }
1831
1832 =head2 $c->prepare( @arguments )
1833
1834 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1835 etc.).
1836
1837 =cut
1838
1839 sub prepare {
1840     my ( $class, @arguments ) = @_;
1841
1842     # XXX
1843     # After the app/ctxt split, this should become an attribute based on something passed
1844     # into the application.
1845     $class->context_class( ref $class || $class ) unless $class->context_class;
1846
1847     my $c = $class->context_class->new({});
1848
1849     # For on-demand data
1850     $c->request->_context($c);
1851     $c->response->_context($c);
1852
1853     #surely this is not the most efficient way to do things...
1854     $c->stats($class->stats_class->new)->enable($c->use_stats);
1855     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1856         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1857     }
1858
1859     #XXX reuse coderef from can
1860     # Allow engine to direct the prepare flow (for POE)
1861     if ( $c->engine->can('prepare') ) {
1862         $c->engine->prepare( $c, @arguments );
1863     }
1864     else {
1865         $c->prepare_request(@arguments);
1866         $c->prepare_connection;
1867         $c->prepare_query_parameters;
1868         $c->prepare_headers;
1869         $c->prepare_cookies;
1870         $c->prepare_path;
1871
1872         # Prepare the body for reading, either by prepare_body
1873         # or the user, if they are using $c->read
1874         $c->prepare_read;
1875
1876         # Parse the body unless the user wants it on-demand
1877         unless ( ref($c)->config->{parse_on_demand} ) {
1878             $c->prepare_body;
1879         }
1880     }
1881
1882     my $method  = $c->req->method  || '';
1883     my $path    = $c->req->path;
1884     $path       = '/' unless length $path;
1885     my $address = $c->req->address || '';
1886
1887     $c->log_request;
1888
1889     $c->prepare_action;
1890
1891     return $c;
1892 }
1893
1894 =head2 $c->prepare_action
1895
1896 Prepares action. See L<Catalyst::Dispatcher>.
1897
1898 =cut
1899
1900 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1901
1902 =head2 $c->prepare_body
1903
1904 Prepares message body.
1905
1906 =cut
1907
1908 sub prepare_body {
1909     my $c = shift;
1910
1911     return if $c->request->_has_body;
1912
1913     # Initialize on-demand data
1914     $c->engine->prepare_body( $c, @_ );
1915     $c->prepare_parameters;
1916     $c->prepare_uploads;
1917 }
1918
1919 =head2 $c->prepare_body_chunk( $chunk )
1920
1921 Prepares a chunk of data before sending it to L<HTTP::Body>.
1922
1923 See L<Catalyst::Engine>.
1924
1925 =cut
1926
1927 sub prepare_body_chunk {
1928     my $c = shift;
1929     $c->engine->prepare_body_chunk( $c, @_ );
1930 }
1931
1932 =head2 $c->prepare_body_parameters
1933
1934 Prepares body parameters.
1935
1936 =cut
1937
1938 sub prepare_body_parameters {
1939     my $c = shift;
1940     $c->engine->prepare_body_parameters( $c, @_ );
1941 }
1942
1943 =head2 $c->prepare_connection
1944
1945 Prepares connection.
1946
1947 =cut
1948
1949 sub prepare_connection {
1950     my $c = shift;
1951     $c->engine->prepare_connection( $c, @_ );
1952 }
1953
1954 =head2 $c->prepare_cookies
1955
1956 Prepares cookies.
1957
1958 =cut
1959
1960 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1961
1962 =head2 $c->prepare_headers
1963
1964 Prepares headers.
1965
1966 =cut
1967
1968 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1969
1970 =head2 $c->prepare_parameters
1971
1972 Prepares parameters.
1973
1974 =cut
1975
1976 sub prepare_parameters {
1977     my $c = shift;
1978     $c->prepare_body_parameters;
1979     $c->engine->prepare_parameters( $c, @_ );
1980 }
1981
1982 =head2 $c->prepare_path
1983
1984 Prepares path and base.
1985
1986 =cut
1987
1988 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1989
1990 =head2 $c->prepare_query_parameters
1991
1992 Prepares query parameters.
1993
1994 =cut
1995
1996 sub prepare_query_parameters {
1997     my $c = shift;
1998
1999     $c->engine->prepare_query_parameters( $c, @_ );
2000 }
2001
2002 =head2 $c->log_request
2003
2004 Writes information about the request to the debug logs.  This includes:
2005
2006 =over 4
2007
2008 =item * Request method, path, and remote IP address
2009
2010 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2011
2012 =item * Request parameters
2013
2014 =item * File uploads
2015
2016 =back
2017
2018 =cut
2019
2020 sub log_request {
2021     my $c = shift;
2022
2023     return unless $c->debug;
2024
2025     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2026     my $request = $dump->[1];
2027
2028     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2029     $method ||= '';
2030     $path = '/' unless length $path;
2031     $address ||= '';
2032     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2033
2034     $c->log_request_headers($request->headers);
2035
2036     if ( my $keywords = $request->query_keywords ) {
2037         $c->log->debug("Query keywords are: $keywords");
2038     }
2039
2040     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2041
2042     $c->log_request_uploads($request);
2043 }
2044
2045 =head2 $c->log_response
2046
2047 Writes information about the response to the debug logs by calling
2048 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2049
2050 =cut
2051
2052 sub log_response {
2053     my $c = shift;
2054
2055     return unless $c->debug;
2056
2057     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2058     my $response = $dump->[1];
2059
2060     $c->log_response_status_line($response);
2061     $c->log_response_headers($response->headers);
2062 }
2063
2064 =head2 $c->log_response_status_line($response)
2065
2066 Writes one line of information about the response to the debug logs.  This includes:
2067
2068 =over 4
2069
2070 =item * Response status code
2071
2072 =item * Content-Type header (if present)
2073
2074 =item * Content-Length header (if present)
2075
2076 =back
2077
2078 =cut
2079
2080 sub log_response_status_line {
2081     my ($c, $response) = @_;
2082
2083     $c->log->debug(
2084         sprintf(
2085             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2086             $response->status                            || 'unknown',
2087             $response->headers->header('Content-Type')   || 'unknown',
2088             $response->headers->header('Content-Length') || 'unknown'
2089         )
2090     );
2091 }
2092
2093 =head2 $c->log_response_headers($headers);
2094
2095 Hook method which can be wrapped by plugins to log the responseheaders.
2096 No-op in the default implementation.
2097
2098 =cut
2099
2100 sub log_response_headers {}
2101
2102 =head2 $c->log_request_parameters( query => {}, body => {} )
2103
2104 Logs request parameters to debug logs
2105
2106 =cut
2107
2108 sub log_request_parameters {
2109     my $c          = shift;
2110     my %all_params = @_;
2111
2112     return unless $c->debug;
2113
2114     my $column_width = Catalyst::Utils::term_width() - 44;
2115     foreach my $type (qw(query body)) {
2116         my $params = $all_params{$type};
2117         next if ! keys %$params;
2118         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2119         for my $key ( sort keys %$params ) {
2120             my $param = $params->{$key};
2121             my $value = defined($param) ? $param : '';
2122             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2123         }
2124         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2125     }
2126 }
2127
2128 =head2 $c->log_request_uploads
2129
2130 Logs file uploads included in the request to the debug logs.
2131 The parameter name, filename, file type, and file size are all included in
2132 the debug logs.
2133
2134 =cut
2135
2136 sub log_request_uploads {
2137     my $c = shift;
2138     my $request = shift;
2139     return unless $c->debug;
2140     my $uploads = $request->uploads;
2141     if ( keys %$uploads ) {
2142         my $t = Text::SimpleTable->new(
2143             [ 12, 'Parameter' ],
2144             [ 26, 'Filename' ],
2145             [ 18, 'Type' ],
2146             [ 9,  'Size' ]
2147         );
2148         for my $key ( sort keys %$uploads ) {
2149             my $upload = $uploads->{$key};
2150             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2151                 $t->row( $key, $u->filename, $u->type, $u->size );
2152             }
2153         }
2154         $c->log->debug( "File Uploads are:\n" . $t->draw );
2155     }
2156 }
2157
2158 =head2 $c->log_request_headers($headers);
2159
2160 Hook method which can be wrapped by plugins to log the request headers.
2161 No-op in the default implementation.
2162
2163 =cut
2164
2165 sub log_request_headers {}
2166
2167 =head2 $c->log_headers($type => $headers)
2168
2169 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2170
2171 =cut
2172
2173 sub log_headers {
2174     my $c       = shift;
2175     my $type    = shift;
2176     my $headers = shift;    # an HTTP::Headers instance
2177
2178     return unless $c->debug;
2179
2180     my $column_width = Catalyst::Utils::term_width() - 28;
2181     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2182     $headers->scan(
2183         sub {
2184             my ( $name, $value ) = @_;
2185             $t->row( $name, $value );
2186         }
2187     );
2188     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2189 }
2190
2191
2192 =head2 $c->prepare_read
2193
2194 Prepares the input for reading.
2195
2196 =cut
2197
2198 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2199
2200 =head2 $c->prepare_request
2201
2202 Prepares the engine request.
2203
2204 =cut
2205
2206 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2207
2208 =head2 $c->prepare_uploads
2209
2210 Prepares uploads.
2211
2212 =cut
2213
2214 sub prepare_uploads {
2215     my $c = shift;
2216
2217     $c->engine->prepare_uploads( $c, @_ );
2218 }
2219
2220 =head2 $c->prepare_write
2221
2222 Prepares the output for writing.
2223
2224 =cut
2225
2226 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2227
2228 =head2 $c->request_class
2229
2230 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2231
2232 =head2 $c->response_class
2233
2234 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2235
2236 =head2 $c->read( [$maxlength] )
2237
2238 Reads a chunk of data from the request body. This method is designed to
2239 be used in a while loop, reading C<$maxlength> bytes on every call.
2240 C<$maxlength> defaults to the size of the request if not specified.
2241
2242 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2243 directly.
2244
2245 Warning: If you use read(), Catalyst will not process the body,
2246 so you will not be able to access POST parameters or file uploads via
2247 $c->request.  You must handle all body parsing yourself.
2248
2249 =cut
2250
2251 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2252
2253 =head2 $c->run
2254
2255 Starts the engine.
2256
2257 =cut
2258
2259 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2260
2261 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2262
2263 Sets an action in a given namespace.
2264
2265 =cut
2266
2267 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2268
2269 =head2 $c->setup_actions($component)
2270
2271 Sets up actions for a component.
2272
2273 =cut
2274
2275 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2276
2277 =head2 $c->setup_config
2278
2279 =cut
2280
2281 sub setup_config {
2282     my $class = shift;
2283
2284     my %args = %{ $class->config || {} };
2285
2286     my @container_classes = ( "${class}::Container", 'Catalyst::IOC::Container');
2287     unshift @container_classes, delete $args{container_class} if exists $args{container_class};
2288
2289     my $container_class = Class::MOP::load_first_existing_class(@container_classes);
2290
2291     my $container = $container_class->new( %args, name => "$class" );
2292     $class->container($container);
2293
2294     my $config = $container->resolve(service => 'config');
2295     $class->config($config);
2296     $class->finalize_config; # back-compat
2297 }
2298
2299 =head2 $c->finalize_config
2300
2301 =cut
2302
2303 sub finalize_config { }
2304
2305 =head2 $c->setup_components
2306
2307 This method is called internally to set up the application's components.
2308
2309 It finds modules by calling the L<locate_components> method, expands them to
2310 package names with the $container->expand_component_module method, and then
2311 installs each component into the application.
2312
2313 The C<setup_components> config option is passed to both of the above methods.
2314
2315 =cut
2316
2317 sub setup_components {
2318     my $class = shift;
2319     # FIXME - I believe I shouldn't be handing $class over
2320     # Just don't know how to solve this.
2321     return $class->container->setup_components( $class );
2322 }
2323
2324 # FIXME - removed locate_components
2325 # don't people mess with this method directly?
2326 # what to do with that?
2327
2328 =head2 $c->setup_dispatcher
2329
2330 Sets up dispatcher.
2331
2332 =cut
2333
2334 sub setup_dispatcher {
2335     my ( $class, $dispatcher ) = @_;
2336
2337     if ($dispatcher) {
2338         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2339     }
2340
2341     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2342         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2343     }
2344
2345     unless ($dispatcher) {
2346         $dispatcher = $class->dispatcher_class;
2347     }
2348
2349     Class::MOP::load_class($dispatcher);
2350
2351     # dispatcher instance
2352     $class->dispatcher( $dispatcher->new );
2353 }
2354
2355 =head2 $c->setup_engine
2356
2357 Sets up engine.
2358
2359 =cut
2360
2361 sub setup_engine {
2362     my ( $class, $engine ) = @_;
2363
2364     if ($engine) {
2365         $engine = 'Catalyst::Engine::' . $engine;
2366     }
2367
2368     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2369         $engine = 'Catalyst::Engine::' . $env;
2370     }
2371
2372     if ( $ENV{MOD_PERL} ) {
2373         my $meta = Class::MOP::get_metaclass_by_name($class);
2374
2375         # create the apache method
2376         $meta->add_method('apache' => sub { shift->engine->apache });
2377
2378         my ( $software, $version ) =
2379           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2380
2381         $version =~ s/_//g;
2382         $version =~ s/(\.[^.]+)\./$1/g;
2383
2384         if ( $software eq 'mod_perl' ) {
2385
2386             if ( !$engine ) {
2387
2388                 if ( $version >= 1.99922 ) {
2389                     $engine = 'Catalyst::Engine::Apache2::MP20';
2390                 }
2391
2392                 elsif ( $version >= 1.9901 ) {
2393                     $engine = 'Catalyst::Engine::Apache2::MP19';
2394                 }
2395
2396                 elsif ( $version >= 1.24 ) {
2397                     $engine = 'Catalyst::Engine::Apache::MP13';
2398                 }
2399
2400                 else {
2401                     Catalyst::Exception->throw( message =>
2402                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2403                 }
2404
2405             }
2406
2407             # install the correct mod_perl handler
2408             if ( $version >= 1.9901 ) {
2409                 *handler = sub  : method {
2410                     shift->handle_request(@_);
2411                 };
2412             }
2413             else {
2414                 *handler = sub ($$) { shift->handle_request(@_) };
2415             }
2416
2417         }
2418
2419         elsif ( $software eq 'Zeus-Perl' ) {
2420             $engine = 'Catalyst::Engine::Zeus';
2421         }
2422
2423         else {
2424             Catalyst::Exception->throw(
2425                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2426         }
2427     }
2428
2429     unless ($engine) {
2430         $engine = $class->engine_class;
2431     }
2432
2433     Class::MOP::load_class($engine);
2434
2435     # check for old engines that are no longer compatible
2436     my $old_engine;
2437     if ( $engine->isa('Catalyst::Engine::Apache')
2438         && !Catalyst::Engine::Apache->VERSION )
2439     {
2440         $old_engine = 1;
2441     }
2442
2443     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2444         && Catalyst::Engine::Server->VERSION le '0.02' )
2445     {
2446         $old_engine = 1;
2447     }
2448
2449     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2450         && $engine->VERSION eq '0.01' )
2451     {
2452         $old_engine = 1;
2453     }
2454
2455     elsif ($engine->isa('Catalyst::Engine::Zeus')
2456         && $engine->VERSION eq '0.01' )
2457     {
2458         $old_engine = 1;
2459     }
2460
2461     if ($old_engine) {
2462         Catalyst::Exception->throw( message =>
2463               qq/Engine "$engine" is not supported by this version of Catalyst/
2464         );
2465     }
2466
2467     # engine instance
2468     $class->engine( $engine->new );
2469 }
2470
2471 =head2 $c->setup_home
2472
2473 Sets up the home directory.
2474
2475 =cut
2476
2477 sub setup_home {
2478     my ( $class, $home ) = @_;
2479
2480     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2481         $home = $env;
2482     }
2483
2484     $home ||= Catalyst::Utils::home($class);
2485
2486     if ($home) {
2487         #I remember recently being scolded for assigning config values like this
2488         $class->config->{home} ||= $home;
2489         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2490     }
2491 }
2492
2493 =head2 $c->setup_log
2494
2495 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2496 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2497 log to.
2498
2499 This method also installs a C<debug> method that returns a true value into the
2500 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2501 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2502
2503 Note that if the log has already been setup, by either a previous call to
2504 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2505 that this method won't actually set up the log object.
2506
2507 =cut
2508
2509 sub setup_log {
2510     my ( $class, $levels ) = @_;
2511
2512     $levels ||= '';
2513     $levels =~ s/^\s+//;
2514     $levels =~ s/\s+$//;
2515     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2516
2517     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2518     if ( defined $env_debug ) {
2519         $levels{debug} = 1 if $env_debug; # Ugly!
2520         delete($levels{debug}) unless $env_debug;
2521     }
2522
2523     unless ( $class->log ) {
2524         $class->log( Catalyst::Log->new(keys %levels) );
2525     }
2526
2527     if ( $levels{debug} ) {
2528         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2529         $class->log->debug('Debug messages enabled');
2530     }
2531 }
2532
2533 =head2 $c->setup_plugins
2534
2535 Sets up plugins.
2536
2537 =cut
2538
2539 =head2 $c->setup_stats
2540
2541 Sets up timing statistics class.
2542
2543 =cut
2544
2545 sub setup_stats {
2546     my ( $class, $stats ) = @_;
2547
2548     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2549
2550     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2551     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2552         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2553         $class->log->debug('Statistics enabled');
2554     }
2555 }
2556
2557
2558 =head2 $c->registered_plugins
2559
2560 Returns a sorted list of the plugins which have either been stated in the
2561 import list or which have been added via C<< MyApp->plugin(@args); >>.
2562
2563 If passed a given plugin name, it will report a boolean value indicating
2564 whether or not that plugin is loaded.  A fully qualified name is required if
2565 the plugin name does not begin with C<Catalyst::Plugin::>.
2566
2567  if ($c->registered_plugins('Some::Plugin')) {
2568      ...
2569  }
2570
2571 =cut
2572
2573 {
2574
2575     sub registered_plugins {
2576         my $proto = shift;
2577         return sort keys %{ $proto->_plugins } unless @_;
2578         my $plugin = shift;
2579         return 1 if exists $proto->_plugins->{$plugin};
2580         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2581     }
2582
2583     sub _register_plugin {
2584         my ( $proto, $plugin, $instant ) = @_;
2585         my $class = ref $proto || $proto;
2586
2587         Class::MOP::load_class( $plugin );
2588         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2589             if $plugin->isa( 'Catalyst::Component' );
2590         $proto->_plugins->{$plugin} = 1;
2591         unless ($instant) {
2592             my $meta = Class::MOP::get_metaclass_by_name($class);
2593             $meta->superclasses($plugin, $meta->superclasses);
2594         }
2595         return $class;
2596     }
2597
2598     sub setup_plugins {
2599         my ( $class, $plugins ) = @_;
2600
2601         $class->_plugins( {} ) unless $class->_plugins;
2602         $plugins = Data::OptList::mkopt($plugins || []);
2603
2604         my @plugins = map {
2605             [ Catalyst::Utils::resolve_namespace(
2606                   $class . '::Plugin',
2607                   'Catalyst::Plugin', $_->[0]
2608               ),
2609               $_->[1],
2610             ]
2611          } @{ $plugins };
2612
2613         for my $plugin ( reverse @plugins ) {
2614             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2615             my $meta = find_meta($plugin->[0]);
2616             next if $meta && $meta->isa('Moose::Meta::Role');
2617
2618             $class->_register_plugin($plugin->[0]);
2619         }
2620
2621         my @roles =
2622             map  { $_->[0]->name, $_->[1] }
2623             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2624             map  { [find_meta($_->[0]), $_->[1]] }
2625             @plugins;
2626
2627         Moose::Util::apply_all_roles(
2628             $class => @roles
2629         ) if @roles;
2630     }
2631 }
2632
2633 =head2 $c->stack
2634
2635 Returns an arrayref of the internal execution stack (actions that are
2636 currently executing).
2637
2638 =head2 $c->stats
2639
2640 Returns the current timing statistics object. By default Catalyst uses
2641 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2642 L<< stats_class|/"$c->stats_class" >>.
2643
2644 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2645 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2646 profile explicitly, although MyApp.pm still won't profile nor output anything
2647 by itself.
2648
2649 =head2 $c->stats_class
2650
2651 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2652
2653 =head2 $c->use_stats
2654
2655 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2656
2657 Note that this is a static method, not an accessor and should be overridden
2658 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2659
2660 =cut
2661
2662 sub use_stats { 0 }
2663
2664
2665 =head2 $c->write( $data )
2666
2667 Writes $data to the output stream. When using this method directly, you
2668 will need to manually set the C<Content-Length> header to the length of
2669 your output data, if known.
2670
2671 =cut
2672
2673 sub write {
2674     my $c = shift;
2675
2676     # Finalize headers if someone manually writes output
2677     $c->finalize_headers;
2678
2679     return $c->engine->write( $c, @_ );
2680 }
2681
2682 =head2 version
2683
2684 Returns the Catalyst version number. Mostly useful for "powered by"
2685 messages in template systems.
2686
2687 =cut
2688
2689 sub version { return $Catalyst::VERSION }
2690
2691 =head1 CONFIGURATION
2692
2693 There are a number of 'base' config variables which can be set:
2694
2695 =over
2696
2697 =item *
2698
2699 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2700
2701 =item *
2702
2703 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2704
2705 =item *
2706
2707 C<home> - The application home directory. In an uninstalled application,
2708 this is the top level application directory. In an installed application,
2709 this will be the directory containing C<< MyApp.pm >>.
2710
2711 =item *
2712
2713 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2714
2715 =item *
2716
2717 C<name> - The name of the application in debug messages and the debug and
2718 welcome screens
2719
2720 =item *
2721
2722 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2723 until it is accessed. This allows you to (for example) check authentication (and reject
2724 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2725
2726 =item *
2727
2728 C<root> - The root directory for templates. Usually this is just a
2729 subdirectory of the home directory, but you can set it to change the
2730 templates to a different directory.
2731
2732 =item *
2733
2734 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2735 to be shown in hit debug tables in the test server.
2736
2737 =item *
2738
2739 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
2740 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
2741 for more information.
2742
2743 =item *
2744
2745 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2746
2747 =back
2748
2749 =head1 INTERNAL ACTIONS
2750
2751 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2752 C<_ACTION>, and C<_END>. These are by default not shown in the private
2753 action table, but you can make them visible with a config parameter.
2754
2755     MyApp->config(show_internal_actions => 1);
2756
2757 =head1 ON-DEMAND PARSER
2758
2759 The request body is usually parsed at the beginning of a request,
2760 but if you want to handle input yourself, you can enable on-demand
2761 parsing with a config parameter.
2762
2763     MyApp->config(parse_on_demand => 1);
2764
2765 =head1 PROXY SUPPORT
2766
2767 Many production servers operate using the common double-server approach,
2768 with a lightweight frontend web server passing requests to a larger
2769 backend server. An application running on the backend server must deal
2770 with two problems: the remote user always appears to be C<127.0.0.1> and
2771 the server's hostname will appear to be C<localhost> regardless of the
2772 virtual host that the user connected through.
2773
2774 Catalyst will automatically detect this situation when you are running
2775 the frontend and backend servers on the same machine. The following
2776 changes are made to the request.
2777
2778     $c->req->address is set to the user's real IP address, as read from
2779     the HTTP X-Forwarded-For header.
2780
2781     The host value for $c->req->base and $c->req->uri is set to the real
2782     host, as read from the HTTP X-Forwarded-Host header.
2783
2784 Additionally, you may be running your backend application on an insecure
2785 connection (port 80) while your frontend proxy is running under SSL.  If there
2786 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2787 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2788 be created properly.
2789
2790 In the case of passing in:
2791
2792     X-Forwarded-Port: 443
2793
2794 All calls to C<uri_for> will result in an https link, as is expected.
2795
2796 Obviously, your web server must support these headers for this to work.
2797
2798 In a more complex server farm environment where you may have your
2799 frontend proxy server(s) on different machines, you will need to set a
2800 configuration option to tell Catalyst to read the proxied data from the
2801 headers.
2802
2803     MyApp->config(using_frontend_proxy => 1);
2804
2805 If you do not wish to use the proxy support at all, you may set:
2806
2807     MyApp->config(ignore_frontend_proxy => 1);
2808
2809 =head1 THREAD SAFETY
2810
2811 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2812 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2813 believe the Catalyst core to be thread-safe.
2814
2815 If you plan to operate in a threaded environment, remember that all other
2816 modules you are using must also be thread-safe. Some modules, most notably
2817 L<DBD::SQLite>, are not thread-safe.
2818
2819 =head1 SUPPORT
2820
2821 IRC:
2822
2823     Join #catalyst on irc.perl.org.
2824
2825 Mailing Lists:
2826
2827     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2828     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2829
2830 Web:
2831
2832     http://catalyst.perl.org
2833
2834 Wiki:
2835
2836     http://dev.catalyst.perl.org
2837
2838 =head1 SEE ALSO
2839
2840 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2841
2842 =head2 L<Catalyst::Manual> - The Catalyst Manual
2843
2844 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2845
2846 =head2 L<Catalyst::Engine> - Core engine
2847
2848 =head2 L<Catalyst::Log> - Log class.
2849
2850 =head2 L<Catalyst::Request> - Request object
2851
2852 =head2 L<Catalyst::Response> - Response object
2853
2854 =head2 L<Catalyst::Test> - The test suite.
2855
2856 =head1 PROJECT FOUNDER
2857
2858 sri: Sebastian Riedel <sri@cpan.org>
2859
2860 =head1 CONTRIBUTORS
2861
2862 abw: Andy Wardley
2863
2864 acme: Leon Brocard <leon@astray.com>
2865
2866 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
2867
2868 Andrew Bramble
2869
2870 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
2871
2872 Andrew Ruthven
2873
2874 André Walker
2875
2876 andyg: Andy Grundman <andy@hybridized.org>
2877
2878 audreyt: Audrey Tang
2879
2880 bricas: Brian Cassidy <bricas@cpan.org>
2881
2882 Caelum: Rafael Kitover <rkitover@io.com>
2883
2884 chansen: Christian Hansen
2885
2886 chicks: Christopher Hicks
2887
2888 Chisel Wright C<pause@herlpacker.co.uk>
2889
2890 Danijel Milicevic C<me@danijel.de>
2891
2892 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
2893
2894 David Naughton, C<naughton@umn.edu>
2895
2896 David E. Wheeler
2897
2898 dhoss: Devin Austin <dhoss@cpan.org>
2899
2900 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2901
2902 Drew Taylor
2903
2904 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2905
2906 esskar: Sascha Kiefer
2907
2908 fireartist: Carl Franks <cfranks@cpan.org>
2909
2910 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
2911
2912 gabb: Danijel Milicevic
2913
2914 Gary Ashton Jones
2915
2916 Gavin Henry C<ghenry@perl.me.uk>
2917
2918 Geoff Richards
2919
2920 groditi: Guillermo Roditi <groditi@gmail.com>
2921
2922 hobbs: Andrew Rodland <andrew@cleverdomain.org>
2923
2924 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2925
2926 jcamacho: Juan Camacho
2927
2928 jester: Jesse Sheidlower C<jester@panix.com>
2929
2930 jhannah: Jay Hannah <jay@jays.net>
2931
2932 Jody Belka
2933
2934 Johan Lindstrom
2935
2936 jon: Jon Schutz <jjschutz@cpan.org>
2937
2938 Jonathan Rockway C<< <jrockway@cpan.org> >>
2939
2940 Kieren Diment C<kd@totaldatasolution.com>
2941
2942 konobi: Scott McWhirter <konobi@cpan.org>
2943
2944 marcus: Marcus Ramberg <mramberg@cpan.org>
2945
2946 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2947
2948 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2949
2950 mugwump: Sam Vilain
2951
2952 naughton: David Naughton
2953
2954 ningu: David Kamholz <dkamholz@cpan.org>
2955
2956 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2957
2958 numa: Dan Sully <daniel@cpan.org>
2959
2960 obra: Jesse Vincent
2961
2962 Octavian Rasnita
2963
2964 omega: Andreas Marienborg
2965
2966 Oleg Kostyuk <cub.uanic@gmail.com>
2967
2968 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2969
2970 rafl: Florian Ragwitz <rafl@debian.org>
2971
2972 random: Roland Lammel <lammel@cpan.org>
2973
2974 Robert Sedlacek C<< <rs@474.at> >>
2975
2976 SpiceMan: Marcel Montes
2977
2978 sky: Arthur Bergman
2979
2980 szbalint: Balint Szilakszi <szbalint@cpan.org>
2981
2982 t0m: Tomas Doran <bobtfish@bobtfish.net>
2983
2984 Ulf Edvinsson
2985
2986 Viljo Marrandi C<vilts@yahoo.com>
2987
2988 Will Hawes C<info@whawes.co.uk>
2989
2990 willert: Sebastian Willert <willert@cpan.org>
2991
2992 wreis: Wallace Reis <wallace@reis.org.br>
2993
2994 Yuval Kogman, C<nothingmuch@woobling.org>
2995
2996 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
2997
2998 dd070: Dhaval Dhanani <dhaval070@gmail.com>
2999
3000 =head1 COPYRIGHT
3001
3002 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3003
3004 =head1 LICENSE
3005
3006 This library is free software. You can redistribute it and/or modify it under
3007 the same terms as Perl itself.
3008
3009 =cut
3010
3011 no Moose;
3012
3013 __PACKAGE__->meta->make_immutable;
3014
3015 1;