lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use String::RewritePrefix;
  32 use Catalyst::EngineLoader;
  33 use utf8;
  34 use Carp qw/croak carp shortmess/;
  35 use Try::Tiny;
  36 use Plack::Middleware::Conditional;
  37 use Plack::Middleware::ReverseProxy;
  38 use Plack::Middleware::IIS6ScriptNameFix;
  39 use Plack::Middleware::LighttpdScriptNameFix;
  40
  41 BEGIN { require 5.008004; }
  42
  43 has stack => (is => 'ro', default => sub { [] });
  44 has stash => (is => 'rw', default => sub { {} });
  45 has state => (is => 'rw', default => 0);
  46 has stats => (is => 'rw');
  47 has action => (is => 'rw');
  48 has counter => (is => 'rw', default => sub { {} });
  49 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  50 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  51 has namespace => (is => 'rw');
  52
  53 sub depth { scalar @{ shift->stack || [] }; }
  54 sub comp { shift->component(@_) }
  55
  56 sub req {
  57     my $self = shift; return $self->request(@_);
  58 }
  59 sub res {
  60     my $self = shift; return $self->response(@_);
  61 }
  62
  63 # For backwards compatibility
  64 sub finalize_output { shift->finalize_body(@_) };
  65
  66 # For statistics
  67 our $COUNT     = 1;
  68 our $START     = time;
  69 our $RECURSION = 1000;
  70 our $DETACH    = Catalyst::Exception::Detach->new;
  71 our $GO        = Catalyst::Exception::Go->new;
  72
  73 #I imagine that very few of these really need to be class variables. if any.
  74 #maybe we should just make them attributes with a default?
  75 __PACKAGE__->mk_classdata($_)
  76   for qw/components arguments dispatcher engine log dispatcher_class
  77   engine_loader context_class request_class response_class stats_class
  78   setup_finished _psgi_app loading_psgi_file run_options/;
  79
  80 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  81 __PACKAGE__->request_class('Catalyst::Request');
  82 __PACKAGE__->response_class('Catalyst::Response');
  83 __PACKAGE__->stats_class('Catalyst::Stats');
  84
  85 # Remember to update this in Catalyst::Runtime as well!
  86
  87 our $VERSION = '5.90007';
  88
  89 sub import {
  90     my ( $class, @arguments ) = @_;
  91
  92     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  93     # callers @ISA.
  94     return unless $class eq 'Catalyst';
  95
  96     my $caller = caller();
  97     return if $caller eq 'main';
  98
  99     my $meta = Moose::Meta::Class->initialize($caller);
 100     unless ( $caller->isa('Catalyst') ) {
 101         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 102         $meta->superclasses(@superclasses);
 103     }
 104     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 105     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 106
 107     unless( $meta->has_method('meta') ){
 108         if ($Moose::VERSION >= 1.15) {
 109             $meta->_add_meta_method('meta');
 110         }
 111         else {
 112             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 113         }
 114     }
 115
 116     $caller->arguments( [@arguments] );
 117     $caller->setup_home;
 118 }
 119
 120 sub _application { $_[0] }
 121
 122 =head1 NAME
 123
 124 Catalyst - The Elegant MVC Web Application Framework
 125
 126 =head1 SYNOPSIS
 127
 128 See the L<Catalyst::Manual> distribution for comprehensive
 129 documentation and tutorials.
 130
 131     # Install Catalyst::Devel for helpers and other development tools
 132     # use the helper to create a new application
 133     catalyst.pl MyApp
 134
 135     # add models, views, controllers
 136     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 137     script/myapp_create.pl view MyTemplate TT
 138     script/myapp_create.pl controller Search
 139
 140     # built in testserver -- use -r to restart automatically on changes
 141     # --help to see all available options
 142     script/myapp_server.pl
 143
 144     # command line testing interface
 145     script/myapp_test.pl /yada
 146
 147     ### in lib/MyApp.pm
 148     use Catalyst qw/-Debug/; # include plugins here as well
 149
 150     ### In lib/MyApp/Controller/Root.pm (autocreated)
 151     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 152         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 153         $c->stash->{template} = 'foo.tt'; # set the template
 154         # lookup something from db -- stash vars are passed to TT
 155         $c->stash->{data} =
 156           $c->model('Database::Foo')->search( { country => $args[0] } );
 157         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 158             $c->forward( 'bar' ); # process another action
 159             # do something else after forward returns
 160         }
 161     }
 162
 163     # The foo.tt TT template can use the stash data from the database
 164     [% WHILE (item = data.next) %]
 165         [% item.foo %]
 166     [% END %]
 167
 168     # called for /bar/of/soap, /bar/of/soap/10, etc.
 169     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 170
 171     # called after all actions are finished
 172     sub end : Action {
 173         my ( $self, $c ) = @_;
 174         if ( scalar @{ $c->error } ) { ... } # handle errors
 175         return if $c->res->body; # already have a response
 176         $c->forward( 'MyApp::View::TT' ); # render template
 177     }
 178
 179 See L<Catalyst::Manual::Intro> for additional information.
 180
 181 =head1 DESCRIPTION
 182
 183 Catalyst is a modern framework for making web applications without the
 184 pain usually associated with this process. This document is a reference
 185 to the main Catalyst application. If you are a new user, we suggest you
 186 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 187
 188 See L<Catalyst::Manual> for more documentation.
 189
 190 Catalyst plugins can be loaded by naming them as arguments to the "use
 191 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 192 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 193 C<My::Module>.
 194
 195     use Catalyst qw/My::Module/;
 196
 197 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 198 fully qualify the name by using a unary plus:
 199
 200     use Catalyst qw/
 201         My::Module
 202         +Fully::Qualified::Plugin::Name
 203     /;
 204
 205 Special flags like C<-Debug> can also be specified as
 206 arguments when Catalyst is loaded:
 207
 208     use Catalyst qw/-Debug My::Module/;
 209
 210 The position of plugins and flags in the chain is important, because
 211 they are loaded in the order in which they appear.
 212
 213 The following flags are supported:
 214
 215 =head2 -Debug
 216
 217 Enables debug output. You can also force this setting from the system
 218 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 219 settings override the application, with <MYAPP>_DEBUG having the highest
 220 priority.
 221
 222 This sets the log level to 'debug' and enables full debug output on the
 223 error screen. If you only want the latter, see L<< $c->debug >>.
 224
 225 =head2 -Home
 226
 227 Forces Catalyst to use a specific home directory, e.g.:
 228
 229     use Catalyst qw[-Home=/usr/mst];
 230
 231 This can also be done in the shell environment by setting either the
 232 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 233 is replaced with the uppercased name of your application, any "::" in
 234 the name will be replaced with underscores, e.g. MyApp::Web should use
 235 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 236
 237 If none of these are set, Catalyst will attempt to automatically detect the
 238 home directory. If you are working in a development environment, Catalyst
 239 will try and find the directory containing either Makefile.PL, Build.PL or
 240 dist.ini. If the application has been installed into the system (i.e.
 241 you have done C<make install>), then Catalyst will use the path to your
 242 application module, without the .pm extension (e.g., /foo/MyApp if your
 243 application was installed at /foo/MyApp.pm)
 244
 245 =head2 -Log
 246
 247     use Catalyst '-Log=warn,fatal,error';
 248
 249 Specifies a comma-delimited list of log levels.
 250
 251 =head2 -Stats
 252
 253 Enables statistics collection and reporting.
 254
 255    use Catalyst qw/-Stats=1/;
 256
 257 You can also force this setting from the system environment with CATALYST_STATS
 258 or <MYAPP>_STATS. The environment settings override the application, with
 259 <MYAPP>_STATS having the highest priority.
 260
 261 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 262
 263 =head1 METHODS
 264
 265 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 266
 267 =head2 $c->action
 268
 269 Returns a L<Catalyst::Action> object for the current action, which
 270 stringifies to the action name. See L<Catalyst::Action>.
 271
 272 =head2 $c->namespace
 273
 274 Returns the namespace of the current action, i.e., the URI prefix
 275 corresponding to the controller of the current action. For example:
 276
 277     # in Controller::Foo::Bar
 278     $c->namespace; # returns 'foo/bar';
 279
 280 =head2 $c->request
 281
 282 =head2 $c->req
 283
 284 Returns the current L<Catalyst::Request> object, giving access to
 285 information about the current client request (including parameters,
 286 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 287
 288 =head2 REQUEST FLOW HANDLING
 289
 290 =head2 $c->forward( $action [, \@arguments ] )
 291
 292 =head2 $c->forward( $class, $method, [, \@arguments ] )
 293
 294 Forwards processing to another action, by its private name. If you give a
 295 class name but no method, C<process()> is called. You may also optionally
 296 pass arguments in an arrayref. The action will receive the arguments in
 297 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 298 C<< $c->req->args >> will be restored to the previous values.
 299
 300 Any data C<return>ed from the action forwarded to, will be returned by the
 301 call to forward.
 302
 303     my $foodata = $c->forward('/foo');
 304     $c->forward('index');
 305     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 306     $c->forward('View::TT');
 307
 308 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 309 an C<< eval { } >> around the call (actually
 310 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 311 exceptions thrown by the called action non-fatal and pushing them onto
 312 $c->error instead. If you want C<die> to propagate you need to do something
 313 like:
 314
 315     $c->forward('foo');
 316     die join "\n", @{ $c->error } if @{ $c->error };
 317
 318 Or make sure to always return true values from your actions and write
 319 your code like this:
 320
 321     $c->forward('foo') || return;
 322
 323 Another note is that C<< $c->forward >> always returns a scalar because it
 324 actually returns $c->state which operates in a scalar context.
 325 Thus, something like:
 326
 327     return @array;
 328
 329 in an action that is forwarded to is going to return a scalar,
 330 i.e. how many items are in that array, which is probably not what you want.
 331 If you need to return an array then return a reference to it,
 332 or stash it like so:
 333
 334     $c->stash->{array} = \@array;
 335
 336 and access it from the stash.
 337
 338 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 339
 340 =cut
 341
 342 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 343
 344 =head2 $c->detach( $action [, \@arguments ] )
 345
 346 =head2 $c->detach( $class, $method, [, \@arguments ] )
 347
 348 =head2 $c->detach()
 349
 350 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 351 doesn't return to the previous action when processing is finished.
 352
 353 When called with no arguments it escapes the processing chain entirely.
 354
 355 =cut
 356
 357 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 358
 359 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 360
 361 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 362
 363 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 364 but does a full dispatch, instead of just calling the new C<$action> /
 365 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 366 you go to are called, just like a new request.
 367
 368 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 369 This means, for example, that C<< $c->action >> methods such as
 370 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 371 L<reverse|Catalyst::Action/reverse> return information for the visited action
 372 when they are invoked within the visited action.  This is different from the
 373 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 374 continues to use the $c->action object from the caller action even when
 375 invoked from the called action.
 376
 377 C<< $c->stash >> is kept unchanged.
 378
 379 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 380 allows you to "wrap" another action, just as it would have been called by
 381 dispatching from a URL, while the analogous
 382 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 383 transfer control to another action as if it had been reached directly from a URL.
 384
 385 =cut
 386
 387 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 388
 389 =head2 $c->go( $action [, \@captures, \@arguments ] )
 390
 391 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 392
 393 The relationship between C<go> and
 394 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 395 the relationship between
 396 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 397 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 398 C<< $c->go >> will perform a full dispatch on the specified action or method,
 399 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 400 C<go> escapes the processing of the current request chain on completion, and
 401 does not return to its caller.
 402
 403 @arguments are arguments to the final destination of $action. @captures are
 404 arguments to the intermediate steps, if any, on the way to the final sub of
 405 $action.
 406
 407 =cut
 408
 409 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 410
 411 =head2 $c->response
 412
 413 =head2 $c->res
 414
 415 Returns the current L<Catalyst::Response> object, see there for details.
 416
 417 =head2 $c->stash
 418
 419 Returns a hashref to the stash, which may be used to store data and pass
 420 it between components during a request. You can also set hash keys by
 421 passing arguments. The stash is automatically sent to the view. The
 422 stash is cleared at the end of a request; it cannot be used for
 423 persistent storage (for this you must use a session; see
 424 L<Catalyst::Plugin::Session> for a complete system integrated with
 425 Catalyst).
 426
 427     $c->stash->{foo} = $bar;
 428     $c->stash( { moose => 'majestic', qux => 0 } );
 429     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 430
 431     # stash is automatically passed to the view for use in a template
 432     $c->forward( 'MyApp::View::TT' );
 433
 434 =cut
 435
 436 around stash => sub {
 437     my $orig = shift;
 438     my $c = shift;
 439     my $stash = $orig->($c);
 440     if (@_) {
 441         my $new_stash = @_ > 1 ? {@_} : $_[0];
 442         croak('stash takes a hash or hashref') unless ref $new_stash;
 443         foreach my $key ( keys %$new_stash ) {
 444           $stash->{$key} = $new_stash->{$key};
 445         }
 446     }
 447
 448     return $stash;
 449 };
 450
 451
 452 =head2 $c->error
 453
 454 =head2 $c->error($error, ...)
 455
 456 =head2 $c->error($arrayref)
 457
 458 Returns an arrayref containing error messages.  If Catalyst encounters an
 459 error while processing a request, it stores the error in $c->error.  This
 460 method should only be used to store fatal error messages.
 461
 462     my @error = @{ $c->error };
 463
 464 Add a new error.
 465
 466     $c->error('Something bad happened');
 467
 468 =cut
 469
 470 sub error {
 471     my $c = shift;
 472     if ( $_[0] ) {
 473         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 474         croak @$error unless ref $c;
 475         push @{ $c->{error} }, @$error;
 476     }
 477     elsif ( defined $_[0] ) { $c->{error} = undef }
 478     return $c->{error} || [];
 479 }
 480
 481
 482 =head2 $c->state
 483
 484 Contains the return value of the last executed action.
 485 Note that << $c->state >> operates in a scalar context which means that all
 486 values it returns are scalar.
 487
 488 =head2 $c->clear_errors
 489
 490 Clear errors.  You probably don't want to clear the errors unless you are
 491 implementing a custom error screen.
 492
 493 This is equivalent to running
 494
 495     $c->error(0);
 496
 497 =cut
 498
 499 sub clear_errors {
 500     my $c = shift;
 501     $c->error(0);
 502 }
 503
 504 sub _comp_search_prefixes {
 505     my $c = shift;
 506     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 507 }
 508
 509 # search components given a name and some prefixes
 510 sub _comp_names_search_prefixes {
 511     my ( $c, $name, @prefixes ) = @_;
 512     my $appclass = ref $c || $c;
 513     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 514     $filter = qr/$filter/; # Compile regex now rather than once per loop
 515
 516     # map the original component name to the sub part that we will search against
 517     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 518         grep { /$filter/ } keys %{ $c->components };
 519
 520     # undef for a name will return all
 521     return keys %eligible if !defined $name;
 522
 523     my $query  = ref $name ? $name : qr/^$name$/i;
 524     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 525
 526     return @result if @result;
 527
 528     # if we were given a regexp to search against, we're done.
 529     return if ref $name;
 530
 531     # skip regexp fallback if configured
 532     return
 533         if $appclass->config->{disable_component_resolution_regex_fallback};
 534
 535     # regexp fallback
 536     $query  = qr/$name/i;
 537     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 538
 539     # no results? try against full names
 540     if( !@result ) {
 541         @result = grep { m{$query} } keys %eligible;
 542     }
 543
 544     # don't warn if we didn't find any results, it just might not exist
 545     if( @result ) {
 546         # Disgusting hack to work out correct method name
 547         my $warn_for = lc $prefixes[0];
 548         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 549            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 550            "component resolution is unreliable and unsafe.";
 551         my $short = $result[0];
 552         # remove the component namespace prefix
 553         $short =~ s/.*?(Model|Controller|View):://;
 554         my $shortmess = Carp::shortmess('');
 555         if ($shortmess =~ m#Catalyst/Plugin#) {
 556            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 557               "plugin's config";
 558         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 559            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 560               "component's config";
 561         } else {
 562            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 563               "but if you really wanted to search, pass in a regexp as the argument " .
 564               "like so: \$c->${warn_for}(qr/${name}/)";
 565         }
 566         $c->log->warn( "${msg}$shortmess" );
 567     }
 568
 569     return @result;
 570 }
 571
 572 # Find possible names for a prefix
 573 sub _comp_names {
 574     my ( $c, @prefixes ) = @_;
 575     my $appclass = ref $c || $c;
 576
 577     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 578
 579     my @names = map { s{$filter}{}; $_; }
 580         $c->_comp_names_search_prefixes( undef, @prefixes );
 581
 582     return @names;
 583 }
 584
 585 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 586 sub _filter_component {
 587     my ( $c, $comp, @args ) = @_;
 588
 589     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 590         return $comp->ACCEPT_CONTEXT( $c, @args );
 591     }
 592
 593     return $comp;
 594 }
 595
 596 =head2 COMPONENT ACCESSORS
 597
 598 =head2 $c->controller($name)
 599
 600 Gets a L<Catalyst::Controller> instance by name.
 601
 602     $c->controller('Foo')->do_stuff;
 603
 604 If the name is omitted, will return the controller for the dispatched
 605 action.
 606
 607 If you want to search for controllers, pass in a regexp as the argument.
 608
 609     # find all controllers that start with Foo
 610     my @foo_controllers = $c->controller(qr{^Foo});
 611
 612
 613 =cut
 614
 615 sub controller {
 616     my ( $c, $name, @args ) = @_;
 617
 618     my $appclass = ref($c) || $c;
 619     if( $name ) {
 620         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 621             my $comps = $c->components;
 622             my $check = $appclass."::Controller::".$name;
 623             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 624         }
 625         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 626         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 627         return $c->_filter_component( $result[ 0 ], @args );
 628     }
 629
 630     return $c->component( $c->action->class );
 631 }
 632
 633 =head2 $c->model($name)
 634
 635 Gets a L<Catalyst::Model> instance by name.
 636
 637     $c->model('Foo')->do_stuff;
 638
 639 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 640
 641 If the name is omitted, it will look for
 642  - a model object in $c->stash->{current_model_instance}, then
 643  - a model name in $c->stash->{current_model}, then
 644  - a config setting 'default_model', or
 645  - check if there is only one model, and return it if that's the case.
 646
 647 If you want to search for models, pass in a regexp as the argument.
 648
 649     # find all models that start with Foo
 650     my @foo_models = $c->model(qr{^Foo});
 651
 652 =cut
 653
 654 sub model {
 655     my ( $c, $name, @args ) = @_;
 656     my $appclass = ref($c) || $c;
 657     if( $name ) {
 658         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 659             my $comps = $c->components;
 660             my $check = $appclass."::Model::".$name;
 661             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 662         }
 663         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 664         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 665         return $c->_filter_component( $result[ 0 ], @args );
 666     }
 667
 668     if (ref $c) {
 669         return $c->stash->{current_model_instance}
 670           if $c->stash->{current_model_instance};
 671         return $c->model( $c->stash->{current_model} )
 672           if $c->stash->{current_model};
 673     }
 674     return $c->model( $appclass->config->{default_model} )
 675       if $appclass->config->{default_model};
 676
 677     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 678
 679     if( !$rest ) {
 680         ( my $name = ref $comp ) =~ s{$appclass\::M(odel)?::}{};
 681         $c->log->warn( Carp::shortmess('Calling $c->model() with no arguments has been deprecated and will be removed.') );
 682         $c->log->warn( "You could change the method call to \$c->model('$name') to retrieve this component" );
 683         $c->log->warn( "or you should set \$c->config(default_model => '$name')." );
 684         return $c->_filter_component( $comp );
 685     }
 686
 687     croak( join( "\n",
 688         'Calling $c->model() will fail unless you specify one of:',
 689         '* $c->config(default_model => "the name of the default model to use")',
 690         '* $c->stash->{current_model} # the name of the model to use for this request',
 691         '* $c->stash->{current_model_instance} # the instance of the model to use for this request' )
 692     );
 693 }
 694
 695
 696 =head2 $c->view($name)
 697
 698 Gets a L<Catalyst::View> instance by name.
 699
 700     $c->view('Foo')->do_stuff;
 701
 702 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 703
 704 If the name is omitted, it will look for
 705  - a view object in $c->stash->{current_view_instance}, then
 706  - a view name in $c->stash->{current_view}, then
 707  - a config setting 'default_view', or
 708  - check if there is only one view, and return it if that's the case.
 709
 710 If you want to search for views, pass in a regexp as the argument.
 711
 712     # find all views that start with Foo
 713     my @foo_views = $c->view(qr{^Foo});
 714
 715 =cut
 716
 717 sub view {
 718     my ( $c, $name, @args ) = @_;
 719
 720     my $appclass = ref($c) || $c;
 721     if( $name ) {
 722         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 723             my $comps = $c->components;
 724             my $check = $appclass."::View::".$name;
 725             if( exists $comps->{$check} ) {
 726                 return $c->_filter_component( $comps->{$check}, @args );
 727             }
 728             else {
 729                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 730             }
 731         }
 732         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 733         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 734         return $c->_filter_component( $result[ 0 ], @args );
 735     }
 736
 737     if (ref $c) {
 738         return $c->stash->{current_view_instance}
 739           if $c->stash->{current_view_instance};
 740         return $c->view( $c->stash->{current_view} )
 741           if $c->stash->{current_view};
 742     }
 743     return $c->view( $appclass->config->{default_view} )
 744       if $appclass->config->{default_view};
 745
 746     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 747
 748     if( !$rest ) {
 749         ( my $name = ref $comp ) =~ s{$appclass\::V(iew)?\::}{};
 750         $c->log->warn( Carp::shortmess('Calling $c->view() with no arguments has been deprecated and will be removed.') );
 751         $c->log->warn( "You could change the method call to \$c->view('$name') to retrieve this component," );
 752         $c->log->warn( "or you should set \$c->config(default_view => '$name')." );
 753         return $c->_filter_component( $comp );
 754     }
 755
 756     croak( join( "\n",
 757         'Calling $c->view() will fail unless you specify one of:',
 758         '* $c->config(default_view => "the name of the default view to use")',
 759         '* $c->stash->{current_view} # the name of the view to use for this request',
 760         '* $c->stash->{current_view_instance} # the instance of the view to use for this request' )
 761     );
 762 }
 763
 764 =head2 $c->controllers
 765
 766 Returns the available names which can be passed to $c->controller
 767
 768 =cut
 769
 770 sub controllers {
 771     my ( $c ) = @_;
 772     return $c->_comp_names(qw/Controller C/);
 773 }
 774
 775 =head2 $c->models
 776
 777 Returns the available names which can be passed to $c->model
 778
 779 =cut
 780
 781 sub models {
 782     my ( $c ) = @_;
 783     return $c->_comp_names(qw/Model M/);
 784 }
 785
 786
 787 =head2 $c->views
 788
 789 Returns the available names which can be passed to $c->view
 790
 791 =cut
 792
 793 sub views {
 794     my ( $c ) = @_;
 795     return $c->_comp_names(qw/View V/);
 796 }
 797
 798 =head2 $c->comp($name)
 799
 800 =head2 $c->component($name)
 801
 802 Gets a component object by name. This method is not recommended,
 803 unless you want to get a specific component by full
 804 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 805 should be used instead.
 806
 807 If C<$name> is a regexp, a list of components matched against the full
 808 component name will be returned.
 809
 810 If Catalyst can't find a component by name, it will fallback to regex
 811 matching by default. To disable this behaviour set
 812 disable_component_resolution_regex_fallback to a true value.
 813
 814     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 815
 816 =cut
 817
 818 sub component {
 819     my ( $c, $name, @args ) = @_;
 820
 821     if( $name ) {
 822         my $comps = $c->components;
 823
 824         if( !ref $name ) {
 825             # is it the exact name?
 826             return $c->_filter_component( $comps->{ $name }, @args )
 827                        if exists $comps->{ $name };
 828
 829             # perhaps we just omitted "MyApp"?
 830             my $composed = ( ref $c || $c ) . "::${name}";
 831             return $c->_filter_component( $comps->{ $composed }, @args )
 832                        if exists $comps->{ $composed };
 833
 834             # search all of the models, views and controllers
 835             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 836             return $c->_filter_component( $comp, @args ) if $comp;
 837         }
 838
 839         return
 840             if $c->config->{disable_component_resolution_regex_fallback};
 841
 842         # This is here so $c->comp( '::M::' ) works
 843         my $query = ref $name ? $name : qr{$name}i;
 844
 845         my @result = grep { m{$query} } keys %{ $c->components };
 846         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 847
 848         if( $result[ 0 ] ) {
 849             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 850             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 851             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 852             return $c->_filter_component( $result[ 0 ], @args );
 853         }
 854
 855         # I would expect to return an empty list here, but that breaks back-compat
 856     }
 857
 858     # fallback
 859     return sort keys %{ $c->components };
 860 }
 861
 862 =head2 CLASS DATA AND HELPER CLASSES
 863
 864 =head2 $c->config
 865
 866 Returns or takes a hashref containing the application's configuration.
 867
 868     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 869
 870 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 871 like C<myapp.conf> in your applications home directory. See
 872 L<Catalyst::Plugin::ConfigLoader>.
 873
 874 =head3 Cascading configuration
 875
 876 The config method is present on all Catalyst components, and configuration
 877 will be merged when an application is started. Configuration loaded with
 878 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 879 followed by configuration in your top level C<MyApp> class. These two
 880 configurations are merged, and then configuration data whose hash key matches a
 881 component name is merged with configuration for that component.
 882
 883 The configuration for a component is then passed to the C<new> method when a
 884 component is constructed.
 885
 886 For example:
 887
 888     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 889     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 890
 891 will mean that C<MyApp::Model::Foo> receives the following data when
 892 constructed:
 893
 894     MyApp::Model::Foo->new({
 895         bar => 'baz',
 896         quux => 'frob',
 897         overrides => 'me',
 898     });
 899
 900 It's common practice to use a Moose attribute
 901 on the receiving component to access the config value.
 902
 903     package MyApp::Model::Foo;
 904
 905     use Moose;
 906
 907     # this attr will receive 'baz' at construction time
 908     has 'bar' => (
 909         is  => 'rw',
 910         isa => 'Str',
 911     );
 912
 913 You can then get the value 'baz' by calling $c->model('Foo')->bar
 914 (or $self->bar inside code in the model).
 915
 916 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 917 as a way of reading config within your code, as this B<will not> give you the
 918 correctly merged config back. You B<MUST> take the config values supplied to
 919 the constructor and use those instead.
 920
 921 =cut
 922
 923 around config => sub {
 924     my $orig = shift;
 925     my $c = shift;
 926
 927     croak('Setting config after setup has been run is not allowed.')
 928         if ( @_ and $c->setup_finished );
 929
 930     $c->$orig(@_);
 931 };
 932
 933 =head2 $c->log
 934
 935 Returns the logging object instance. Unless it is already set, Catalyst
 936 sets this up with a L<Catalyst::Log> object. To use your own log class,
 937 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 938 C<< __PACKAGE__->setup >>.
 939
 940  __PACKAGE__->log( MyLogger->new );
 941  __PACKAGE__->setup;
 942
 943 And later:
 944
 945     $c->log->info( 'Now logging with my own logger!' );
 946
 947 Your log class should implement the methods described in
 948 L<Catalyst::Log>.
 949
 950
 951 =head2 $c->debug
 952
 953 Returns 1 if debug mode is enabled, 0 otherwise.
 954
 955 You can enable debug mode in several ways:
 956
 957 =over
 958
 959 =item By calling myapp_server.pl with the -d flag
 960
 961 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 962
 963 =item The -Debug option in your MyApp.pm
 964
 965 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 966
 967 =back
 968
 969 The first three also set the log level to 'debug'.
 970
 971 Calling C<< $c->debug(1) >> has no effect.
 972
 973 =cut
 974
 975 sub debug { 0 }
 976
 977 =head2 $c->dispatcher
 978
 979 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 980
 981 =head2 $c->engine
 982
 983 Returns the engine instance. See L<Catalyst::Engine>.
 984
 985
 986 =head2 UTILITY METHODS
 987
 988 =head2 $c->path_to(@path)
 989
 990 Merges C<@path> with C<< $c->config->{home} >> and returns a
 991 L<Path::Class::Dir> object. Note you can usually use this object as
 992 a filename, but sometimes you will have to explicitly stringify it
 993 yourself by calling the C<< ->stringify >> method.
 994
 995 For example:
 996
 997     $c->path_to( 'db', 'sqlite.db' );
 998
 999 =cut
1000
1001 sub path_to {
1002     my ( $c, @path ) = @_;
1003     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1004     if ( -d $path ) { return $path }
1005     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1006 }
1007
1008 sub plugin {
1009     my ( $class, $name, $plugin, @args ) = @_;
1010
1011     # See block comment in t/unit_core_plugin.t
1012     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1013
1014     $class->_register_plugin( $plugin, 1 );
1015
1016     eval { $plugin->import };
1017     $class->mk_classdata($name);
1018     my $obj;
1019     eval { $obj = $plugin->new(@args) };
1020
1021     if ($@) {
1022         Catalyst::Exception->throw( message =>
1023               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1024     }
1025
1026     $class->$name($obj);
1027     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1028       if $class->debug;
1029 }
1030
1031 =head2 MyApp->setup
1032
1033 Initializes the dispatcher and engine, loads any plugins, and loads the
1034 model, view, and controller components. You may also specify an array
1035 of plugins to load here, if you choose to not load them in the C<use
1036 Catalyst> line.
1037
1038     MyApp->setup;
1039     MyApp->setup( qw/-Debug/ );
1040
1041 B<Note:> You B<should not> wrap this method with method modifiers
1042 or bad things will happen - wrap the C<setup_finalize> method instead.
1043
1044 =cut
1045
1046 sub setup {
1047     my ( $class, @arguments ) = @_;
1048     croak('Running setup more than once')
1049         if ( $class->setup_finished );
1050
1051     unless ( $class->isa('Catalyst') ) {
1052
1053         Catalyst::Exception->throw(
1054             message => qq/'$class' does not inherit from Catalyst/ );
1055     }
1056
1057     if ( $class->arguments ) {
1058         @arguments = ( @arguments, @{ $class->arguments } );
1059     }
1060
1061     # Process options
1062     my $flags = {};
1063
1064     foreach (@arguments) {
1065
1066         if (/^-Debug$/) {
1067             $flags->{log} =
1068               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1069         }
1070         elsif (/^-(\w+)=?(.*)$/) {
1071             $flags->{ lc $1 } = $2;
1072         }
1073         else {
1074             push @{ $flags->{plugins} }, $_;
1075         }
1076     }
1077
1078     $class->setup_home( delete $flags->{home} );
1079
1080     $class->setup_log( delete $flags->{log} );
1081     $class->setup_plugins( delete $flags->{plugins} );
1082     $class->setup_dispatcher( delete $flags->{dispatcher} );
1083     if (my $engine = delete $flags->{engine}) {
1084         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1085     }
1086     $class->setup_engine();
1087     $class->setup_stats( delete $flags->{stats} );
1088
1089     for my $flag ( sort keys %{$flags} ) {
1090
1091         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1092             &$code( $class, delete $flags->{$flag} );
1093         }
1094         else {
1095             $class->log->warn(qq/Unknown flag "$flag"/);
1096         }
1097     }
1098
1099     eval { require Catalyst::Devel; };
1100     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1101         $class->log->warn(<<"EOF");
1102 You are running an old script!
1103
1104   Please update by running (this will overwrite existing files):
1105     catalyst.pl -force -scripts $class
1106
1107   or (this will not overwrite existing files):
1108     catalyst.pl -scripts $class
1109
1110 EOF
1111     }
1112
1113     if ( $class->debug ) {
1114         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1115
1116         if (@plugins) {
1117             my $column_width = Catalyst::Utils::term_width() - 6;
1118             my $t = Text::SimpleTable->new($column_width);
1119             $t->row($_) for @plugins;
1120             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1121         }
1122
1123         my $dispatcher = $class->dispatcher;
1124         my $engine     = $class->engine;
1125         my $home       = $class->config->{home};
1126
1127         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1128         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1129
1130         $home
1131           ? ( -d $home )
1132           ? $class->log->debug(qq/Found home "$home"/)
1133           : $class->log->debug(qq/Home "$home" doesn't exist/)
1134           : $class->log->debug(q/Couldn't find home/);
1135     }
1136
1137     # Call plugins setup, this is stupid and evil.
1138     # Also screws C3 badly on 5.10, hack to avoid.
1139     {
1140         no warnings qw/redefine/;
1141         local *setup = sub { };
1142         $class->setup unless $Catalyst::__AM_RESTARTING;
1143     }
1144
1145     # Initialize our data structure
1146     $class->components( {} );
1147
1148     $class->setup_components;
1149
1150     if ( $class->debug ) {
1151         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1152         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1153         for my $comp ( sort keys %{ $class->components } ) {
1154             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1155             $t->row( $comp, $type );
1156         }
1157         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1158           if ( keys %{ $class->components } );
1159     }
1160
1161     # Add our self to components, since we are also a component
1162     if( $class->isa('Catalyst::Controller') ){
1163       $class->components->{$class} = $class;
1164     }
1165
1166     $class->setup_actions;
1167
1168     if ( $class->debug ) {
1169         my $name = $class->config->{name} || 'Application';
1170         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1171     }
1172
1173     # Make sure that the application class becomes immutable at this point,
1174     B::Hooks::EndOfScope::on_scope_end {
1175         return if $@;
1176         my $meta = Class::MOP::get_metaclass_by_name($class);
1177         if (
1178             $meta->is_immutable
1179             && ! { $meta->immutable_options }->{replace_constructor}
1180             && (
1181                    $class->isa('Class::Accessor::Fast')
1182                 || $class->isa('Class::Accessor')
1183             )
1184         ) {
1185             warn "You made your application class ($class) immutable, "
1186                 . "but did not inline the\nconstructor. "
1187                 . "This will break catalyst, as your app \@ISA "
1188                 . "Class::Accessor(::Fast)?\nPlease pass "
1189                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1190         }
1191         $meta->make_immutable(
1192             replace_constructor => 1,
1193         ) unless $meta->is_immutable;
1194     };
1195
1196     if ($class->config->{case_sensitive}) {
1197         $class->log->warn($class . "->config->{case_sensitive} is set.");
1198         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1199     }
1200
1201     $class->setup_finalize;
1202     # Should be the last thing we do so that user things hooking
1203     # setup_finalize can log..
1204     $class->log->_flush() if $class->log->can('_flush');
1205     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1206 }
1207
1208 =head2 $app->setup_finalize
1209
1210 A hook to attach modifiers to. This method does not do anything except set the
1211 C<setup_finished> accessor.
1212
1213 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1214
1215 Example:
1216
1217     after setup_finalize => sub {
1218         my $app = shift;
1219
1220         ## do stuff here..
1221     };
1222
1223 =cut
1224
1225 sub setup_finalize {
1226     my ($class) = @_;
1227     $class->setup_finished(1);
1228 }
1229
1230 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1231
1232 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1233
1234 Constructs an absolute L<URI> object based on the application root, the
1235 provided path, and the additional arguments and query parameters provided.
1236 When used as a string, provides a textual URI.  If you need more flexibility
1237 than this (i.e. the option to provide relative URIs etc.) see
1238 L<Catalyst::Plugin::SmartURI>.
1239
1240 If no arguments are provided, the URI for the current action is returned.
1241 To return the current action and also provide @args, use
1242 C<< $c->uri_for( $c->action, @args ) >>.
1243
1244 If the first argument is a string, it is taken as a public URI path relative
1245 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1246 relative to the application root (if it does). It is then merged with
1247 C<< $c->request->base >>; any C<@args> are appended as additional path
1248 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1249
1250 If the first argument is a L<Catalyst::Action> it represents an action which
1251 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1252 optional C<\@captures> argument (an arrayref) allows passing the captured
1253 variables that are needed to fill in the paths of Chained and Regex actions;
1254 once the path is resolved, C<uri_for> continues as though a path was
1255 provided, appending any arguments or parameters and creating an absolute
1256 URI.
1257
1258 The captures for the current request can be found in
1259 C<< $c->request->captures >>, and actions can be resolved using
1260 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1261 path, use C<< $c->uri_for_action >> instead.
1262
1263   # Equivalent to $c->req->uri
1264   $c->uri_for($c->action, $c->req->captures,
1265       @{ $c->req->args }, $c->req->params);
1266
1267   # For the Foo action in the Bar controller
1268   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1269
1270   # Path to a static resource
1271   $c->uri_for('/static/images/logo.png');
1272
1273 =cut
1274
1275 sub uri_for {
1276     my ( $c, $path, @args ) = @_;
1277
1278     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1279         $path = $path->path_prefix;
1280         $path =~ s{/+\z}{};
1281         $path .= '/';
1282     }
1283
1284     undef($path) if (defined $path && $path eq '');
1285
1286     my $params =
1287       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1288
1289     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1290     foreach my $arg (@args) {
1291         utf8::encode($arg) if utf8::is_utf8($arg);
1292         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1293     }
1294
1295     if ( blessed($path) ) { # action object
1296         s|/|%2F|g for @args;
1297         my $captures = [ map { s|/|%2F|g; $_; }
1298                         ( scalar @args && ref $args[0] eq 'ARRAY'
1299                          ? @{ shift(@args) }
1300                          : ()) ];
1301
1302         foreach my $capture (@$captures) {
1303             utf8::encode($capture) if utf8::is_utf8($capture);
1304             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1305         }
1306
1307         my $action = $path;
1308         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1309         if( !@args && $action->number_of_args ) {
1310             my $expanded_action = $c->dispatcher->expand_action( $action );
1311
1312             my $num_captures = $expanded_action->number_of_captures;
1313             unshift @args, splice @$captures, $num_captures;
1314         }
1315
1316        $path = $c->dispatcher->uri_for_action($action, $captures);
1317         if (not defined $path) {
1318             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1319                 if $c->debug;
1320             return undef;
1321         }
1322         $path = '/' if $path eq '';
1323     }
1324
1325     unshift(@args, $path);
1326
1327     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1328         my $namespace = $c->namespace;
1329         if (defined $path) { # cheesy hack to handle path '../foo'
1330            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1331         }
1332         unshift(@args, $namespace || '');
1333     }
1334
1335     # join args with '/', or a blank string
1336     my $args = join('/', grep { defined($_) } @args);
1337     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1338     $args =~ s!^/+!!;
1339     my $base = $c->req->base;
1340     my $class = ref($base);
1341     $base =~ s{(?<!/)$}{/};
1342
1343     my $query = '';
1344
1345     if (my @keys = keys %$params) {
1346       # somewhat lifted from URI::_query's query_form
1347       $query = '?'.join('&', map {
1348           my $val = $params->{$_};
1349           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1350           s/ /+/g;
1351           my $key = $_;
1352           $val = '' unless defined $val;
1353           (map {
1354               my $param = "$_";
1355               utf8::encode( $param ) if utf8::is_utf8($param);
1356               # using the URI::Escape pattern here so utf8 chars survive
1357               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1358               $param =~ s/ /+/g;
1359               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1360       } @keys);
1361     }
1362
1363     my $res = bless(\"${base}${args}${query}", $class);
1364     $res;
1365 }
1366
1367 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1368
1369 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1370
1371 =over
1372
1373 =item $path
1374
1375 A private path to the Catalyst action you want to create a URI for.
1376
1377 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1378 >> and passing the resulting C<$action> and the remaining arguments to C<<
1379 $c->uri_for >>.
1380
1381 You can also pass in a Catalyst::Action object, in which case it is passed to
1382 C<< $c->uri_for >>.
1383
1384 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1385
1386 For example, if the action looks like:
1387
1388  package MyApp::Controller::Users;
1389
1390  sub lst : Path('the-list') {}
1391
1392 You can use:
1393
1394  $c->uri_for_action('/users/lst')
1395
1396 and it will create the URI /users/the-list.
1397
1398 =item \@captures_and_args?
1399
1400 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1401 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1402 to interpolate all the parameters in the URI.
1403
1404 =item @args?
1405
1406 Optional list of extra arguments - can be supplied in the
1407 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1408 code.
1409
1410 Your action can have zero, a fixed or a variable number of args (e.g.
1411 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1412
1413 =item \%query_values?
1414
1415 Optional array reference of query parameters to append. E.g.
1416
1417   { foo => 'bar' }
1418
1419 will generate
1420
1421   /rest/of/your/uri?foo=bar
1422
1423 =back
1424
1425 =cut
1426
1427 sub uri_for_action {
1428     my ( $c, $path, @args ) = @_;
1429     my $action = blessed($path)
1430       ? $path
1431       : $c->dispatcher->get_action_by_path($path);
1432     unless (defined $action) {
1433       croak "Can't find action for path '$path'";
1434     }
1435     return $c->uri_for( $action, @args );
1436 }
1437
1438 =head2 $c->welcome_message
1439
1440 Returns the Catalyst welcome HTML page.
1441
1442 =cut
1443
1444 sub welcome_message {
1445     my $c      = shift;
1446     my $name   = $c->config->{name};
1447     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1448     my $prefix = Catalyst::Utils::appprefix( ref $c );
1449     $c->response->content_type('text/html; charset=utf-8');
1450     return <<"EOF";
1451 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1452     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1453 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1454     <head>
1455     <meta http-equiv="Content-Language" content="en" />
1456     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1457         <title>$name on Catalyst $VERSION</title>
1458         <style type="text/css">
1459             body {
1460                 color: #000;
1461                 background-color: #eee;
1462             }
1463             div#content {
1464                 width: 640px;
1465                 margin-left: auto;
1466                 margin-right: auto;
1467                 margin-top: 10px;
1468                 margin-bottom: 10px;
1469                 text-align: left;
1470                 background-color: #ccc;
1471                 border: 1px solid #aaa;
1472             }
1473             p, h1, h2 {
1474                 margin-left: 20px;
1475                 margin-right: 20px;
1476                 font-family: verdana, tahoma, sans-serif;
1477             }
1478             a {
1479                 font-family: verdana, tahoma, sans-serif;
1480             }
1481             :link, :visited {
1482                     text-decoration: none;
1483                     color: #b00;
1484                     border-bottom: 1px dotted #bbb;
1485             }
1486             :link:hover, :visited:hover {
1487                     color: #555;
1488             }
1489             div#topbar {
1490                 margin: 0px;
1491             }
1492             pre {
1493                 margin: 10px;
1494                 padding: 8px;
1495             }
1496             div#answers {
1497                 padding: 8px;
1498                 margin: 10px;
1499                 background-color: #fff;
1500                 border: 1px solid #aaa;
1501             }
1502             h1 {
1503                 font-size: 0.9em;
1504                 font-weight: normal;
1505                 text-align: center;
1506             }
1507             h2 {
1508                 font-size: 1.0em;
1509             }
1510             p {
1511                 font-size: 0.9em;
1512             }
1513             p img {
1514                 float: right;
1515                 margin-left: 10px;
1516             }
1517             span#appname {
1518                 font-weight: bold;
1519                 font-size: 1.6em;
1520             }
1521         </style>
1522     </head>
1523     <body>
1524         <div id="content">
1525             <div id="topbar">
1526                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1527                     $VERSION</h1>
1528              </div>
1529              <div id="answers">
1530                  <p>
1531                  <img src="$logo" alt="Catalyst Logo" />
1532                  </p>
1533                  <p>Welcome to the  world of Catalyst.
1534                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1535                     framework will make web development something you had
1536                     never expected it to be: Fun, rewarding, and quick.</p>
1537                  <h2>What to do now?</h2>
1538                  <p>That really depends  on what <b>you</b> want to do.
1539                     We do, however, provide you with a few starting points.</p>
1540                  <p>If you want to jump right into web development with Catalyst
1541                     you might want to start with a tutorial.</p>
1542 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1543 </pre>
1544 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1545 <pre>
1546 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1547 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1548 </code></pre>
1549                  <h2>What to do next?</h2>
1550                  <p>Next it's time to write an actual application. Use the
1551                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1552                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1553                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1554                     they can save you a lot of work.</p>
1555                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1556                     <p>Also, be sure to check out the vast and growing
1557                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1558                     you are likely to find what you need there.
1559                     </p>
1560
1561                  <h2>Need help?</h2>
1562                  <p>Catalyst has a very active community. Here are the main places to
1563                     get in touch with us.</p>
1564                  <ul>
1565                      <li>
1566                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1567                      </li>
1568                      <li>
1569                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1570                      </li>
1571                      <li>
1572                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1573                      </li>
1574                  </ul>
1575                  <h2>In conclusion</h2>
1576                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1577                     as we enjoyed making it. Please contact us if you have ideas
1578                     for improvement or other feedback.</p>
1579              </div>
1580          </div>
1581     </body>
1582 </html>
1583 EOF
1584 }
1585
1586 =head2 run_options
1587
1588 Contains a hash of options passed from the application script, including
1589 the original ARGV the script received, the processed values from that
1590 ARGV and any extra arguments to the script which were not processed.
1591
1592 This can be used to add custom options to your application's scripts
1593 and setup your application differently depending on the values of these
1594 options.
1595
1596 =head1 INTERNAL METHODS
1597
1598 These methods are not meant to be used by end users.
1599
1600 =head2 $c->components
1601
1602 Returns a hash of components.
1603
1604 =head2 $c->context_class
1605
1606 Returns or sets the context class.
1607
1608 =head2 $c->counter
1609
1610 Returns a hashref containing coderefs and execution counts (needed for
1611 deep recursion detection).
1612
1613 =head2 $c->depth
1614
1615 Returns the number of actions on the current internal execution stack.
1616
1617 =head2 $c->dispatch
1618
1619 Dispatches a request to actions.
1620
1621 =cut
1622
1623 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1624
1625 =head2 $c->dispatcher_class
1626
1627 Returns or sets the dispatcher class.
1628
1629 =head2 $c->dump_these
1630
1631 Returns a list of 2-element array references (name, structure) pairs
1632 that will be dumped on the error page in debug mode.
1633
1634 =cut
1635
1636 sub dump_these {
1637     my $c = shift;
1638     [ Request => $c->req ],
1639     [ Response => $c->res ],
1640     [ Stash => $c->stash ],
1641     [ Config => $c->config ];
1642 }
1643
1644 =head2 $c->engine_class
1645
1646 Returns or sets the engine class.
1647
1648 =head2 $c->execute( $class, $coderef )
1649
1650 Execute a coderef in given class and catch exceptions. Errors are available
1651 via $c->error.
1652
1653 =cut
1654
1655 sub execute {
1656     my ( $c, $class, $code ) = @_;
1657     $class = $c->component($class) || $class;
1658     $c->state(0);
1659
1660     if ( $c->depth >= $RECURSION ) {
1661         my $action = $code->reverse();
1662         $action = "/$action" unless $action =~ /->/;
1663         my $error = qq/Deep recursion detected calling "${action}"/;
1664         $c->log->error($error);
1665         $c->error($error);
1666         $c->state(0);
1667         return $c->state;
1668     }
1669
1670     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1671
1672     push( @{ $c->stack }, $code );
1673
1674     no warnings 'recursion';
1675     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1676     #      I have no idea how, ergo $ret (which appears to fix the issue)
1677     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1678
1679     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1680
1681     my $last = pop( @{ $c->stack } );
1682
1683     if ( my $error = $@ ) {
1684         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1685             $error->rethrow if $c->depth > 1;
1686         }
1687         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1688             $error->rethrow if $c->depth > 0;
1689         }
1690         else {
1691             unless ( ref $error ) {
1692                 no warnings 'uninitialized';
1693                 chomp $error;
1694                 my $class = $last->class;
1695                 my $name  = $last->name;
1696                 $error = qq/Caught exception in $class->$name "$error"/;
1697             }
1698             $c->error($error);
1699         }
1700         $c->state(0);
1701     }
1702     return $c->state;
1703 }
1704
1705 sub _stats_start_execute {
1706     my ( $c, $code ) = @_;
1707     my $appclass = ref($c) || $c;
1708     return if ( ( $code->name =~ /^_.*/ )
1709         && ( !$appclass->config->{show_internal_actions} ) );
1710
1711     my $action_name = $code->reverse();
1712     $c->counter->{$action_name}++;
1713
1714     my $action = $action_name;
1715     $action = "/$action" unless $action =~ /->/;
1716
1717     # determine if the call was the result of a forward
1718     # this is done by walking up the call stack and looking for a calling
1719     # sub of Catalyst::forward before the eval
1720     my $callsub = q{};
1721     for my $index ( 2 .. 11 ) {
1722         last
1723         if ( ( caller($index) )[0] eq 'Catalyst'
1724             && ( caller($index) )[3] eq '(eval)' );
1725
1726         if ( ( caller($index) )[3] =~ /forward$/ ) {
1727             $callsub = ( caller($index) )[3];
1728             $action  = "-> $action";
1729             last;
1730         }
1731     }
1732
1733     my $uid = $action_name . $c->counter->{$action_name};
1734
1735     # is this a root-level call or a forwarded call?
1736     if ( $callsub =~ /forward$/ ) {
1737         my $parent = $c->stack->[-1];
1738
1739         # forward, locate the caller
1740         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1741             $c->stats->profile(
1742                 begin  => $action,
1743                 parent => "$parent" . $c->counter->{"$parent"},
1744                 uid    => $uid,
1745             );
1746         }
1747         else {
1748
1749             # forward with no caller may come from a plugin
1750             $c->stats->profile(
1751                 begin => $action,
1752                 uid   => $uid,
1753             );
1754         }
1755     }
1756     else {
1757
1758         # root-level call
1759         $c->stats->profile(
1760             begin => $action,
1761             uid   => $uid,
1762         );
1763     }
1764     return $action;
1765
1766 }
1767
1768 sub _stats_finish_execute {
1769     my ( $c, $info ) = @_;
1770     $c->stats->profile( end => $info );
1771 }
1772
1773 =head2 $c->finalize
1774
1775 Finalizes the request.
1776
1777 =cut
1778
1779 sub finalize {
1780     my $c = shift;
1781
1782     for my $error ( @{ $c->error } ) {
1783         $c->log->error($error);
1784     }
1785
1786     # Allow engine to handle finalize flow (for POE)
1787     my $engine = $c->engine;
1788     if ( my $code = $engine->can('finalize') ) {
1789         $engine->$code($c);
1790     }
1791     else {
1792
1793         $c->finalize_uploads;
1794
1795         # Error
1796         if ( $#{ $c->error } >= 0 ) {
1797             $c->finalize_error;
1798         }
1799
1800         $c->finalize_headers;
1801
1802         # HEAD request
1803         if ( $c->request->method eq 'HEAD' ) {
1804             $c->response->body('');
1805         }
1806
1807         $c->finalize_body;
1808     }
1809
1810     $c->log_response;
1811
1812     if ($c->use_stats) {
1813         my $elapsed = sprintf '%f', $c->stats->elapsed;
1814         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1815         $c->log->info(
1816             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1817     }
1818
1819     return $c->response->status;
1820 }
1821
1822 =head2 $c->finalize_body
1823
1824 Finalizes body.
1825
1826 =cut
1827
1828 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1829
1830 =head2 $c->finalize_cookies
1831
1832 Finalizes cookies.
1833
1834 =cut
1835
1836 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1837
1838 =head2 $c->finalize_error
1839
1840 Finalizes error.
1841
1842 =cut
1843
1844 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1845
1846 =head2 $c->finalize_headers
1847
1848 Finalizes headers.
1849
1850 =cut
1851
1852 sub finalize_headers {
1853     my $c = shift;
1854
1855     my $response = $c->response; #accessor calls can add up?
1856
1857     # Check if we already finalized headers
1858     return if $response->finalized_headers;
1859
1860     # Handle redirects
1861     if ( my $location = $response->redirect ) {
1862         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1863         $response->header( Location => $location );
1864
1865         if ( !$response->has_body ) {
1866             # Add a default body if none is already present
1867             $response->body(<<"EOF");
1868 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1869 <html xmlns="http://www.w3.org/1999/xhtml">
1870   <head>
1871     <title>Moved</title>
1872   </head>
1873   <body>
1874      <p>This item has moved <a href="$location">here</a>.</p>
1875   </body>
1876 </html>
1877 EOF
1878             $response->content_type('text/html; charset=utf-8');
1879         }
1880     }
1881
1882     # Content-Length
1883     if ( defined $response->body && length $response->body && !$response->content_length ) {
1884
1885         # get the length from a filehandle
1886         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1887         {
1888             my $size = -s $response->body;
1889             if ( $size ) {
1890                 $response->content_length( $size );
1891             }
1892             else {
1893                 $c->log->warn('Serving filehandle without a content-length');
1894             }
1895         }
1896         else {
1897             # everything should be bytes at this point, but just in case
1898             $response->content_length( length( $response->body ) );
1899         }
1900     }
1901
1902     # Errors
1903     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1904         $response->headers->remove_header("Content-Length");
1905         $response->body('');
1906     }
1907
1908     $c->finalize_cookies;
1909
1910     $c->engine->finalize_headers( $c, @_ );
1911
1912     # Done
1913     $response->finalized_headers(1);
1914 }
1915
1916 =head2 $c->finalize_output
1917
1918 An alias for finalize_body.
1919
1920 =head2 $c->finalize_read
1921
1922 Finalizes the input after reading is complete.
1923
1924 =cut
1925
1926 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1927
1928 =head2 $c->finalize_uploads
1929
1930 Finalizes uploads. Cleans up any temporary files.
1931
1932 =cut
1933
1934 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1935
1936 =head2 $c->get_action( $action, $namespace )
1937
1938 Gets an action in a given namespace.
1939
1940 =cut
1941
1942 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1943
1944 =head2 $c->get_actions( $action, $namespace )
1945
1946 Gets all actions of a given name in a namespace and all parent
1947 namespaces.
1948
1949 =cut
1950
1951 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1952
1953 =head2 $app->handle_request( @arguments )
1954
1955 Called to handle each HTTP request.
1956
1957 =cut
1958
1959 sub handle_request {
1960     my ( $class, @arguments ) = @_;
1961
1962     # Always expect worst case!
1963     my $status = -1;
1964     try {
1965         if ($class->debug) {
1966             my $secs = time - $START || 1;
1967             my $av = sprintf '%.3f', $COUNT / $secs;
1968             my $time = localtime time;
1969             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1970         }
1971
1972         my $c = $class->prepare(@arguments);
1973         $c->dispatch;
1974         $status = $c->finalize;
1975     }
1976     catch {
1977         chomp(my $error = $_);
1978         $class->log->error(qq/Caught exception in engine "$error"/);
1979     };
1980
1981     $COUNT++;
1982
1983     if(my $coderef = $class->log->can('_flush')){
1984         $class->log->$coderef();
1985     }
1986     return $status;
1987 }
1988
1989 =head2 $class->prepare( @arguments )
1990
1991 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1992 etc.).
1993
1994 =cut
1995
1996 sub prepare {
1997     my ( $class, @arguments ) = @_;
1998
1999     # XXX
2000     # After the app/ctxt split, this should become an attribute based on something passed
2001     # into the application.
2002     $class->context_class( ref $class || $class ) unless $class->context_class;
2003
2004     my $c = $class->context_class->new({});
2005
2006     # For on-demand data
2007     $c->request->_context($c);
2008     $c->response->_context($c);
2009
2010     #surely this is not the most efficient way to do things...
2011     $c->stats($class->stats_class->new)->enable($c->use_stats);
2012     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2013         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2014     }
2015
2016     try {
2017         # Allow engine to direct the prepare flow (for POE)
2018         if ( my $prepare = $c->engine->can('prepare') ) {
2019             $c->engine->$prepare( $c, @arguments );
2020         }
2021         else {
2022             $c->prepare_request(@arguments);
2023             $c->prepare_connection;
2024             $c->prepare_query_parameters;
2025             $c->prepare_headers;
2026             $c->prepare_cookies;
2027             $c->prepare_path;
2028
2029             # Prepare the body for reading, either by prepare_body
2030             # or the user, if they are using $c->read
2031             $c->prepare_read;
2032
2033             # Parse the body unless the user wants it on-demand
2034             unless ( ref($c)->config->{parse_on_demand} ) {
2035                 $c->prepare_body;
2036             }
2037         }
2038         $c->prepare_action;
2039     }
2040     # VERY ugly and probably shouldn't rely on ->finalize actually working
2041     catch {
2042         # failed prepare is always due to an invalid request, right?
2043         $c->response->status(400);
2044         $c->response->content_type('text/plain');
2045         $c->response->body('Bad Request');
2046         # Note we call finalize and then die here, which escapes
2047         # finalize being called in the enclosing block..
2048         # It in fact couldn't be called, as we don't return $c..
2049         # This is a mess - but I'm unsure you can fix this without
2050         # breaking compat for people doing crazy things (we should set
2051         # the 400 and just return the ctx here IMO, letting finalize get called
2052         # above...
2053         $c->finalize;
2054         die $_;
2055     };
2056
2057     $c->log_request;
2058
2059     return $c;
2060 }
2061
2062 =head2 $c->prepare_action
2063
2064 Prepares action. See L<Catalyst::Dispatcher>.
2065
2066 =cut
2067
2068 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2069
2070 =head2 $c->prepare_body
2071
2072 Prepares message body.
2073
2074 =cut
2075
2076 sub prepare_body {
2077     my $c = shift;
2078
2079     return if $c->request->_has_body;
2080
2081     # Initialize on-demand data
2082     $c->engine->prepare_body( $c, @_ );
2083     $c->prepare_parameters;
2084     $c->prepare_uploads;
2085 }
2086
2087 =head2 $c->prepare_body_chunk( $chunk )
2088
2089 Prepares a chunk of data before sending it to L<HTTP::Body>.
2090
2091 See L<Catalyst::Engine>.
2092
2093 =cut
2094
2095 sub prepare_body_chunk {
2096     my $c = shift;
2097     $c->engine->prepare_body_chunk( $c, @_ );
2098 }
2099
2100 =head2 $c->prepare_body_parameters
2101
2102 Prepares body parameters.
2103
2104 =cut
2105
2106 sub prepare_body_parameters {
2107     my $c = shift;
2108     $c->engine->prepare_body_parameters( $c, @_ );
2109 }
2110
2111 =head2 $c->prepare_connection
2112
2113 Prepares connection.
2114
2115 =cut
2116
2117 sub prepare_connection {
2118     my $c = shift;
2119     $c->engine->prepare_connection( $c, @_ );
2120 }
2121
2122 =head2 $c->prepare_cookies
2123
2124 Prepares cookies.
2125
2126 =cut
2127
2128 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2129
2130 =head2 $c->prepare_headers
2131
2132 Prepares headers.
2133
2134 =cut
2135
2136 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2137
2138 =head2 $c->prepare_parameters
2139
2140 Prepares parameters.
2141
2142 =cut
2143
2144 sub prepare_parameters {
2145     my $c = shift;
2146     $c->prepare_body_parameters;
2147     $c->engine->prepare_parameters( $c, @_ );
2148 }
2149
2150 =head2 $c->prepare_path
2151
2152 Prepares path and base.
2153
2154 =cut
2155
2156 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2157
2158 =head2 $c->prepare_query_parameters
2159
2160 Prepares query parameters.
2161
2162 =cut
2163
2164 sub prepare_query_parameters {
2165     my $c = shift;
2166
2167     $c->engine->prepare_query_parameters( $c, @_ );
2168 }
2169
2170 =head2 $c->log_request
2171
2172 Writes information about the request to the debug logs.  This includes:
2173
2174 =over 4
2175
2176 =item * Request method, path, and remote IP address
2177
2178 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2179
2180 =item * Request parameters
2181
2182 =item * File uploads
2183
2184 =back
2185
2186 =cut
2187
2188 sub log_request {
2189     my $c = shift;
2190
2191     return unless $c->debug;
2192
2193     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2194     my $request = $dump->[1];
2195
2196     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2197     $method ||= '';
2198     $path = '/' unless length $path;
2199     $address ||= '';
2200     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2201
2202     $c->log_request_headers($request->headers);
2203
2204     if ( my $keywords = $request->query_keywords ) {
2205         $c->log->debug("Query keywords are: $keywords");
2206     }
2207
2208     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2209
2210     $c->log_request_uploads($request);
2211 }
2212
2213 =head2 $c->log_response
2214
2215 Writes information about the response to the debug logs by calling
2216 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2217
2218 =cut
2219
2220 sub log_response {
2221     my $c = shift;
2222
2223     return unless $c->debug;
2224
2225     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2226     my $response = $dump->[1];
2227
2228     $c->log_response_status_line($response);
2229     $c->log_response_headers($response->headers);
2230 }
2231
2232 =head2 $c->log_response_status_line($response)
2233
2234 Writes one line of information about the response to the debug logs.  This includes:
2235
2236 =over 4
2237
2238 =item * Response status code
2239
2240 =item * Content-Type header (if present)
2241
2242 =item * Content-Length header (if present)
2243
2244 =back
2245
2246 =cut
2247
2248 sub log_response_status_line {
2249     my ($c, $response) = @_;
2250
2251     $c->log->debug(
2252         sprintf(
2253             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2254             $response->status                            || 'unknown',
2255             $response->headers->header('Content-Type')   || 'unknown',
2256             $response->headers->header('Content-Length') || 'unknown'
2257         )
2258     );
2259 }
2260
2261 =head2 $c->log_response_headers($headers);
2262
2263 Hook method which can be wrapped by plugins to log the response headers.
2264 No-op in the default implementation.
2265
2266 =cut
2267
2268 sub log_response_headers {}
2269
2270 =head2 $c->log_request_parameters( query => {}, body => {} )
2271
2272 Logs request parameters to debug logs
2273
2274 =cut
2275
2276 sub log_request_parameters {
2277     my $c          = shift;
2278     my %all_params = @_;
2279
2280     return unless $c->debug;
2281
2282     my $column_width = Catalyst::Utils::term_width() - 44;
2283     foreach my $type (qw(query body)) {
2284         my $params = $all_params{$type};
2285         next if ! keys %$params;
2286         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2287         for my $key ( sort keys %$params ) {
2288             my $param = $params->{$key};
2289             my $value = defined($param) ? $param : '';
2290             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2291         }
2292         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2293     }
2294 }
2295
2296 =head2 $c->log_request_uploads
2297
2298 Logs file uploads included in the request to the debug logs.
2299 The parameter name, filename, file type, and file size are all included in
2300 the debug logs.
2301
2302 =cut
2303
2304 sub log_request_uploads {
2305     my $c = shift;
2306     my $request = shift;
2307     return unless $c->debug;
2308     my $uploads = $request->uploads;
2309     if ( keys %$uploads ) {
2310         my $t = Text::SimpleTable->new(
2311             [ 12, 'Parameter' ],
2312             [ 26, 'Filename' ],
2313             [ 18, 'Type' ],
2314             [ 9,  'Size' ]
2315         );
2316         for my $key ( sort keys %$uploads ) {
2317             my $upload = $uploads->{$key};
2318             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2319                 $t->row( $key, $u->filename, $u->type, $u->size );
2320             }
2321         }
2322         $c->log->debug( "File Uploads are:\n" . $t->draw );
2323     }
2324 }
2325
2326 =head2 $c->log_request_headers($headers);
2327
2328 Hook method which can be wrapped by plugins to log the request headers.
2329 No-op in the default implementation.
2330
2331 =cut
2332
2333 sub log_request_headers {}
2334
2335 =head2 $c->log_headers($type => $headers)
2336
2337 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2338
2339 =cut
2340
2341 sub log_headers {
2342     my $c       = shift;
2343     my $type    = shift;
2344     my $headers = shift;    # an HTTP::Headers instance
2345
2346     return unless $c->debug;
2347
2348     my $column_width = Catalyst::Utils::term_width() - 28;
2349     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2350     $headers->scan(
2351         sub {
2352             my ( $name, $value ) = @_;
2353             $t->row( $name, $value );
2354         }
2355     );
2356     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2357 }
2358
2359
2360 =head2 $c->prepare_read
2361
2362 Prepares the input for reading.
2363
2364 =cut
2365
2366 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2367
2368 =head2 $c->prepare_request
2369
2370 Prepares the engine request.
2371
2372 =cut
2373
2374 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2375
2376 =head2 $c->prepare_uploads
2377
2378 Prepares uploads.
2379
2380 =cut
2381
2382 sub prepare_uploads {
2383     my $c = shift;
2384
2385     $c->engine->prepare_uploads( $c, @_ );
2386 }
2387
2388 =head2 $c->prepare_write
2389
2390 Prepares the output for writing.
2391
2392 =cut
2393
2394 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2395
2396 =head2 $c->request_class
2397
2398 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2399
2400 =head2 $c->response_class
2401
2402 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2403
2404 =head2 $c->read( [$maxlength] )
2405
2406 Reads a chunk of data from the request body. This method is designed to
2407 be used in a while loop, reading C<$maxlength> bytes on every call.
2408 C<$maxlength> defaults to the size of the request if not specified.
2409
2410 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2411 directly.
2412
2413 Warning: If you use read(), Catalyst will not process the body,
2414 so you will not be able to access POST parameters or file uploads via
2415 $c->request.  You must handle all body parsing yourself.
2416
2417 =cut
2418
2419 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2420
2421 =head2 $c->run
2422
2423 Starts the engine.
2424
2425 =cut
2426
2427 sub run {
2428   my $app = shift;
2429   $app->engine_loader->needs_psgi_engine_compat_hack ?
2430     $app->engine->run($app, @_) :
2431       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2432 }
2433
2434 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2435
2436 Sets an action in a given namespace.
2437
2438 =cut
2439
2440 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2441
2442 =head2 $c->setup_actions($component)
2443
2444 Sets up actions for a component.
2445
2446 =cut
2447
2448 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2449
2450 =head2 $c->setup_components
2451
2452 This method is called internally to set up the application's components.
2453
2454 It finds modules by calling the L<locate_components> method, expands them to
2455 package names with the L<expand_component_module> method, and then installs
2456 each component into the application.
2457
2458 The C<setup_components> config option is passed to both of the above methods.
2459
2460 Installation of each component is performed by the L<setup_component> method,
2461 below.
2462
2463 =cut
2464
2465 sub setup_components {
2466     my $class = shift;
2467
2468     my $config  = $class->config->{ setup_components };
2469
2470     my @comps = $class->locate_components($config);
2471     my %comps = map { $_ => 1 } @comps;
2472
2473     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2474     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2475         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2476     ) if $deprecatedcatalyst_component_names;
2477
2478     for my $component ( @comps ) {
2479
2480         # We pass ignore_loaded here so that overlay files for (e.g.)
2481         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2482         # we know M::P::O found a file on disk so this is safe
2483
2484         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2485     }
2486
2487     for my $component (@comps) {
2488         my $instance = $class->components->{ $component } = $class->setup_component($component);
2489         my @expanded_components = $instance->can('expand_modules')
2490             ? $instance->expand_modules( $component, $config )
2491             : $class->expand_component_module( $component, $config );
2492         for my $component (@expanded_components) {
2493             next if $comps{$component};
2494             $class->components->{ $component } = $class->setup_component($component);
2495         }
2496     }
2497 }
2498
2499 =head2 $c->locate_components( $setup_component_config )
2500
2501 This method is meant to provide a list of component modules that should be
2502 setup for the application.  By default, it will use L<Module::Pluggable>.
2503
2504 Specify a C<setup_components> config option to pass additional options directly
2505 to L<Module::Pluggable>. To add additional search paths, specify a key named
2506 C<search_extra> as an array reference. Items in the array beginning with C<::>
2507 will have the application class name prepended to them.
2508
2509 =cut
2510
2511 sub locate_components {
2512     my $class  = shift;
2513     my $config = shift;
2514
2515     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2516     my $extra   = delete $config->{ search_extra } || [];
2517
2518     push @paths, @$extra;
2519
2520     my $locator = Module::Pluggable::Object->new(
2521         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2522         %$config
2523     );
2524
2525     # XXX think about ditching this sort entirely
2526     my @comps = sort { length $a <=> length $b } $locator->plugins;
2527
2528     return @comps;
2529 }
2530
2531 =head2 $c->expand_component_module( $component, $setup_component_config )
2532
2533 Components found by C<locate_components> will be passed to this method, which
2534 is expected to return a list of component (package) names to be set up.
2535
2536 =cut
2537
2538 sub expand_component_module {
2539     my ($class, $module) = @_;
2540     return Devel::InnerPackage::list_packages( $module );
2541 }
2542
2543 =head2 $c->setup_component
2544
2545 =cut
2546
2547 sub setup_component {
2548     my( $class, $component ) = @_;
2549
2550     unless ( $component->can( 'COMPONENT' ) ) {
2551         return $component;
2552     }
2553
2554     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2555     my $config = $class->config->{ $suffix } || {};
2556     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2557     # methods also pass it. local to avoid pointlessly shitting in config
2558     # for the debug screen, as $component is already the key name.
2559     local $config->{catalyst_component_name} = $component;
2560
2561     my $instance = eval { $component->COMPONENT( $class, $config ); };
2562
2563     if ( my $error = $@ ) {
2564         chomp $error;
2565         Catalyst::Exception->throw(
2566             message => qq/Couldn't instantiate component "$component", "$error"/
2567         );
2568     }
2569
2570     unless (blessed $instance) {
2571         my $metaclass = Moose::Util::find_meta($component);
2572         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2573         my $component_method_from = $method_meta->associated_metaclass->name;
2574         my $value = defined($instance) ? $instance : 'undef';
2575         Catalyst::Exception->throw(
2576             message =>
2577             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2578         );
2579     }
2580     return $instance;
2581 }
2582
2583 =head2 $c->setup_dispatcher
2584
2585 Sets up dispatcher.
2586
2587 =cut
2588
2589 sub setup_dispatcher {
2590     my ( $class, $dispatcher ) = @_;
2591
2592     if ($dispatcher) {
2593         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2594     }
2595
2596     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2597         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2598     }
2599
2600     unless ($dispatcher) {
2601         $dispatcher = $class->dispatcher_class;
2602     }
2603
2604     Class::MOP::load_class($dispatcher);
2605
2606     # dispatcher instance
2607     $class->dispatcher( $dispatcher->new );
2608 }
2609
2610 =head2 $c->setup_engine
2611
2612 Sets up engine.
2613
2614 =cut
2615
2616 sub engine_class {
2617     my ($class, $requested_engine) = @_;
2618
2619     if (!$class->engine_loader || $requested_engine) {
2620         $class->engine_loader(
2621             Catalyst::EngineLoader->new({
2622                 application_name => $class,
2623                 (defined $requested_engine
2624                      ? (catalyst_engine_class => $requested_engine) : ()),
2625             }),
2626         );
2627     }
2628
2629     $class->engine_loader->catalyst_engine_class;
2630 }
2631
2632 sub setup_engine {
2633     my ($class, $requested_engine) = @_;
2634
2635     my $engine = do {
2636         my $loader = $class->engine_loader;
2637
2638         if (!$loader || $requested_engine) {
2639             $loader = Catalyst::EngineLoader->new({
2640                 application_name => $class,
2641                 (defined $requested_engine
2642                      ? (requested_engine => $requested_engine) : ()),
2643             }),
2644
2645             $class->engine_loader($loader);
2646         }
2647
2648         $loader->catalyst_engine_class;
2649     };
2650
2651     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2652     return if $class->loading_psgi_file;
2653
2654     Class::MOP::load_class($engine);
2655
2656     if ($ENV{MOD_PERL}) {
2657         my $apache = $class->engine_loader->auto;
2658
2659         my $meta = find_meta($class);
2660         my $was_immutable = $meta->is_immutable;
2661         my %immutable_options = $meta->immutable_options;
2662         $meta->make_mutable if $was_immutable;
2663
2664         $meta->add_method(handler => sub {
2665             my $r = shift;
2666             my $psgi_app = $class->_finalized_psgi_app;
2667             $apache->call_app($r, $psgi_app);
2668         });
2669
2670         $meta->make_immutable(%immutable_options) if $was_immutable;
2671     }
2672
2673     $class->engine( $engine->new );
2674
2675     return;
2676 }
2677
2678 sub _finalized_psgi_app {
2679     my ($app) = @_;
2680
2681     unless ($app->_psgi_app) {
2682         my $psgi_app = $app->_setup_psgi_app;
2683         $app->_psgi_app($psgi_app);
2684     }
2685
2686     return $app->_psgi_app;
2687 }
2688
2689 sub _setup_psgi_app {
2690     my ($app) = @_;
2691
2692     for my $home (Path::Class::Dir->new($app->config->{home})) {
2693         my $psgi_file = $home->file(
2694             Catalyst::Utils::appprefix($app) . '.psgi',
2695         );
2696
2697         next unless -e $psgi_file;
2698
2699         # If $psgi_file calls ->setup_engine, it's doing so to load
2700         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2701         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2702         # anyway. So set a flag (ick) that tells setup_engine not to populate
2703         # $c->engine or do any other things we might regret.
2704
2705         $app->loading_psgi_file(1);
2706         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2707         $app->loading_psgi_file(0);
2708
2709         return $psgi_app
2710             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2711
2712         warn <<"EOW";
2713 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2714
2715 Its content has been ignored. Please consult the Catalyst::Upgrading
2716 documentation on how to upgrade from Catalyst::Engine::PSGI.
2717 EOW
2718     }
2719
2720     return $app->apply_default_middlewares($app->psgi_app);
2721 }
2722
2723 =head2 $c->apply_default_middlewares
2724
2725 Adds the following L<Plack> middlewares to your application, since they are
2726 useful and commonly needed:
2727
2728 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2729 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2730 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2731 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2732 applied since this middleware is smart enough to conditionally apply itself).
2733
2734 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2735 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2736 $ENV{SCRIPT_NAME}
2737
2738 =cut
2739
2740
2741 sub apply_default_middlewares {
2742     my ($app, $psgi_app) = @_;
2743
2744     $psgi_app = Plack::Middleware::Conditional->wrap(
2745         $psgi_app,
2746         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2747         condition => sub {
2748             my ($env) = @_;
2749             return if $app->config->{ignore_frontend_proxy};
2750             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2751                 || $app->config->{using_frontend_proxy};
2752         },
2753     );
2754
2755     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2756     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2757     $psgi_app = Plack::Middleware::Conditional->wrap(
2758         $psgi_app,
2759         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2760         condition => sub {
2761             my ($env) = @_;
2762             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2763             return unless $1 < 4.23;
2764             1;
2765         },
2766     );
2767
2768     # we're applying this unconditionally as the middleware itself already makes
2769     # sure it doesn't fuck things up if it's not running under one of the right
2770     # IIS versions
2771     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2772
2773     return $psgi_app;
2774 }
2775
2776 =head2 $c->psgi_app
2777
2778 Returns a PSGI application code reference for the catalyst application
2779 C<$c>. This is the bare application without any middlewares
2780 applied. C<${myapp}.psgi> is not taken into account.
2781
2782 This is what you want to be using to retrieve the PSGI application code
2783 reference of your Catalyst application for use in F<.psgi> files.
2784
2785 =cut
2786
2787 sub psgi_app {
2788     my ($app) = @_;
2789     return $app->engine->build_psgi_app($app);
2790 }
2791
2792 =head2 $c->setup_home
2793
2794 Sets up the home directory.
2795
2796 =cut
2797
2798 sub setup_home {
2799     my ( $class, $home ) = @_;
2800
2801     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2802         $home = $env;
2803     }
2804
2805     $home ||= Catalyst::Utils::home($class);
2806
2807     if ($home) {
2808         #I remember recently being scolded for assigning config values like this
2809         $class->config->{home} ||= $home;
2810         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2811     }
2812 }
2813
2814 =head2 $c->setup_log
2815
2816 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2817 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2818 log to.
2819
2820 This method also installs a C<debug> method that returns a true value into the
2821 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2822 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2823
2824 Note that if the log has already been setup, by either a previous call to
2825 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2826 that this method won't actually set up the log object.
2827
2828 =cut
2829
2830 sub setup_log {
2831     my ( $class, $levels ) = @_;
2832
2833     $levels ||= '';
2834     $levels =~ s/^\s+//;
2835     $levels =~ s/\s+$//;
2836     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2837
2838     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2839     if ( defined $env_debug ) {
2840         $levels{debug} = 1 if $env_debug; # Ugly!
2841         delete($levels{debug}) unless $env_debug;
2842     }
2843
2844     unless ( $class->log ) {
2845         $class->log( Catalyst::Log->new(keys %levels) );
2846     }
2847
2848     if ( $levels{debug} ) {
2849         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2850         $class->log->debug('Debug messages enabled');
2851     }
2852 }
2853
2854 =head2 $c->setup_plugins
2855
2856 Sets up plugins.
2857
2858 =cut
2859
2860 =head2 $c->setup_stats
2861
2862 Sets up timing statistics class.
2863
2864 =cut
2865
2866 sub setup_stats {
2867     my ( $class, $stats ) = @_;
2868
2869     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2870
2871     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2872     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2873         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2874         $class->log->debug('Statistics enabled');
2875     }
2876 }
2877
2878
2879 =head2 $c->registered_plugins
2880
2881 Returns a sorted list of the plugins which have either been stated in the
2882 import list.
2883
2884 If passed a given plugin name, it will report a boolean value indicating
2885 whether or not that plugin is loaded.  A fully qualified name is required if
2886 the plugin name does not begin with C<Catalyst::Plugin::>.
2887
2888  if ($c->registered_plugins('Some::Plugin')) {
2889      ...
2890  }
2891
2892 =cut
2893
2894 {
2895
2896     sub registered_plugins {
2897         my $proto = shift;
2898         return sort keys %{ $proto->_plugins } unless @_;
2899         my $plugin = shift;
2900         return 1 if exists $proto->_plugins->{$plugin};
2901         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2902     }
2903
2904     sub _register_plugin {
2905         my ( $proto, $plugin, $instant ) = @_;
2906         my $class = ref $proto || $proto;
2907
2908         Class::MOP::load_class( $plugin );
2909         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2910             if $plugin->isa( 'Catalyst::Component' );
2911         $proto->_plugins->{$plugin} = 1;
2912         unless ($instant) {
2913             my $meta = Class::MOP::get_metaclass_by_name($class);
2914             $meta->superclasses($plugin, $meta->superclasses);
2915         }
2916         return $class;
2917     }
2918
2919     sub setup_plugins {
2920         my ( $class, $plugins ) = @_;
2921
2922         $class->_plugins( {} ) unless $class->_plugins;
2923         $plugins = Data::OptList::mkopt($plugins || []);
2924
2925         my @plugins = map {
2926             [ Catalyst::Utils::resolve_namespace(
2927                   $class . '::Plugin',
2928                   'Catalyst::Plugin', $_->[0]
2929               ),
2930               $_->[1],
2931             ]
2932          } @{ $plugins };
2933
2934         for my $plugin ( reverse @plugins ) {
2935             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2936             my $meta = find_meta($plugin->[0]);
2937             next if $meta && $meta->isa('Moose::Meta::Role');
2938
2939             $class->_register_plugin($plugin->[0]);
2940         }
2941
2942         my @roles =
2943             map  { $_->[0]->name, $_->[1] }
2944             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2945             map  { [find_meta($_->[0]), $_->[1]] }
2946             @plugins;
2947
2948         Moose::Util::apply_all_roles(
2949             $class => @roles
2950         ) if @roles;
2951     }
2952 }
2953
2954 =head2 $c->stack
2955
2956 Returns an arrayref of the internal execution stack (actions that are
2957 currently executing).
2958
2959 =head2 $c->stats
2960
2961 Returns the current timing statistics object. By default Catalyst uses
2962 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2963 L<< stats_class|/"$c->stats_class" >>.
2964
2965 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2966 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2967 profile explicitly, although MyApp.pm still won't profile nor output anything
2968 by itself.
2969
2970 =head2 $c->stats_class
2971
2972 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2973
2974 =head2 $c->use_stats
2975
2976 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2977
2978 Note that this is a static method, not an accessor and should be overridden
2979 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2980
2981 =cut
2982
2983 sub use_stats { 0 }
2984
2985
2986 =head2 $c->write( $data )
2987
2988 Writes $data to the output stream. When using this method directly, you
2989 will need to manually set the C<Content-Length> header to the length of
2990 your output data, if known.
2991
2992 =cut
2993
2994 sub write {
2995     my $c = shift;
2996
2997     # Finalize headers if someone manually writes output
2998     $c->finalize_headers;
2999
3000     return $c->engine->write( $c, @_ );
3001 }
3002
3003 =head2 version
3004
3005 Returns the Catalyst version number. Mostly useful for "powered by"
3006 messages in template systems.
3007
3008 =cut
3009
3010 sub version { return $Catalyst::VERSION }
3011
3012 =head1 CONFIGURATION
3013
3014 There are a number of 'base' config variables which can be set:
3015
3016 =over
3017
3018 =item *
3019
3020 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3021
3022 =item *
3023
3024 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3025
3026 =item *
3027
3028 C<disable_component_resolution_regex_fallback> - Turns
3029 off the deprecated component resolution functionality so
3030 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3031 are called then regex search will not be attempted on string values and
3032 instead C<undef> will be returned.
3033
3034 =item *
3035
3036 C<home> - The application home directory. In an uninstalled application,
3037 this is the top level application directory. In an installed application,
3038 this will be the directory containing C<< MyApp.pm >>.
3039
3040 =item *
3041
3042 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3043
3044 =item *
3045
3046 C<name> - The name of the application in debug messages and the debug and
3047 welcome screens
3048
3049 =item *
3050
3051 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3052 until it is accessed. This allows you to (for example) check authentication (and reject
3053 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3054
3055 =item *
3056
3057 C<root> - The root directory for templates. Usually this is just a
3058 subdirectory of the home directory, but you can set it to change the
3059 templates to a different directory.
3060
3061 =item *
3062
3063 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3064 namespaces from which components will be loaded (and constructed and stored in
3065 C<< $c->components >>).
3066
3067 =item *
3068
3069 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3070 to be shown in hit debug tables in the test server.
3071
3072 =item *
3073
3074 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3075 variable should be used for determining the request path.
3076
3077 Most web server environments pass the requested path to the application using environment variables,
3078 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3079 exposed as C<< $c->request->base >>) and the request path below that base.
3080
3081 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3082 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3083
3084 =over
3085
3086 =item use_request_uri_for_path => 0
3087
3088 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3089 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3090 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3091 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3092
3093 However this method has the major disadvantage that it is impossible to correctly decode some elements
3094 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3095 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3096 can't distinguish / vs %2F in paths (in addition to other encoded values).
3097
3098 =item use_request_uri_for_path => 1
3099
3100 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3101 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3102 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3103
3104 Given that this method of path resolution is provably more correct, it is recommended that you use
3105 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3106 aware of the implications of not being able to handle encoded URI paths correctly.
3107
3108 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3109 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3110 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3111 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3112 C<< $c->request->base >> will be incorrect.
3113
3114 =back
3115
3116 =item *
3117
3118 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3119
3120 =back
3121
3122 =head1 INTERNAL ACTIONS
3123
3124 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3125 C<_ACTION>, and C<_END>. These are by default not shown in the private
3126 action table, but you can make them visible with a config parameter.
3127
3128     MyApp->config(show_internal_actions => 1);
3129
3130 =head1 ON-DEMAND PARSER
3131
3132 The request body is usually parsed at the beginning of a request,
3133 but if you want to handle input yourself, you can enable on-demand
3134 parsing with a config parameter.
3135
3136     MyApp->config(parse_on_demand => 1);
3137
3138 =head1 PROXY SUPPORT
3139
3140 Many production servers operate using the common double-server approach,
3141 with a lightweight frontend web server passing requests to a larger
3142 backend server. An application running on the backend server must deal
3143 with two problems: the remote user always appears to be C<127.0.0.1> and
3144 the server's hostname will appear to be C<localhost> regardless of the
3145 virtual host that the user connected through.
3146
3147 Catalyst will automatically detect this situation when you are running
3148 the frontend and backend servers on the same machine. The following
3149 changes are made to the request.
3150
3151     $c->req->address is set to the user's real IP address, as read from
3152     the HTTP X-Forwarded-For header.
3153
3154     The host value for $c->req->base and $c->req->uri is set to the real
3155     host, as read from the HTTP X-Forwarded-Host header.
3156
3157 Additionally, you may be running your backend application on an insecure
3158 connection (port 80) while your frontend proxy is running under SSL.  If there
3159 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3160 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3161 be created properly.
3162
3163 In the case of passing in:
3164
3165     X-Forwarded-Port: 443
3166
3167 All calls to C<uri_for> will result in an https link, as is expected.
3168
3169 Obviously, your web server must support these headers for this to work.
3170
3171 In a more complex server farm environment where you may have your
3172 frontend proxy server(s) on different machines, you will need to set a
3173 configuration option to tell Catalyst to read the proxied data from the
3174 headers.
3175
3176     MyApp->config(using_frontend_proxy => 1);
3177
3178 If you do not wish to use the proxy support at all, you may set:
3179
3180     MyApp->config(ignore_frontend_proxy => 0);
3181
3182 =head2 Note about psgi files
3183
3184 Note that if you supply your own .psgi file, calling
3185 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3186
3187 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3188 in your psgi, for example:
3189
3190     builder {
3191         enable "Plack::Middleware::ReverseProxy";
3192         MyApp->psgi_app
3193     };
3194
3195 This will unconditionally add the ReverseProxy support, or you need to call
3196 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3197 apply the support depending upon your config).
3198
3199 See L<Catalyst::PSGI> for more information.
3200
3201 =head1 THREAD SAFETY
3202
3203 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3204 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3205 believe the Catalyst core to be thread-safe.
3206
3207 If you plan to operate in a threaded environment, remember that all other
3208 modules you are using must also be thread-safe. Some modules, most notably
3209 L<DBD::SQLite>, are not thread-safe.
3210
3211 =head1 SUPPORT
3212
3213 IRC:
3214
3215     Join #catalyst on irc.perl.org.
3216
3217 Mailing Lists:
3218
3219     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3220     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3221
3222 Web:
3223
3224     http://catalyst.perl.org
3225
3226 Wiki:
3227
3228     http://dev.catalyst.perl.org
3229
3230 =head1 SEE ALSO
3231
3232 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3233
3234 =head2 L<Catalyst::Manual> - The Catalyst Manual
3235
3236 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3237
3238 =head2 L<Catalyst::Engine> - Core engine
3239
3240 =head2 L<Catalyst::Log> - Log class.
3241
3242 =head2 L<Catalyst::Request> - Request object
3243
3244 =head2 L<Catalyst::Response> - Response object
3245
3246 =head2 L<Catalyst::Test> - The test suite.
3247
3248 =begin stopwords
3249
3250 =head1 PROJECT FOUNDER
3251
3252 sri: Sebastian Riedel <sri@cpan.org>
3253
3254 =head1 CONTRIBUTORS
3255
3256 abw: Andy Wardley
3257
3258 acme: Leon Brocard <leon@astray.com>
3259
3260 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3261
3262 Andrew Bramble
3263
3264 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3265
3266 Andrew Ruthven
3267
3268 andyg: Andy Grundman <andy@hybridized.org>
3269
3270 audreyt: Audrey Tang
3271
3272 bricas: Brian Cassidy <bricas@cpan.org>
3273
3274 Caelum: Rafael Kitover <rkitover@io.com>
3275
3276 chansen: Christian Hansen
3277
3278 chicks: Christopher Hicks
3279
3280 Chisel Wright C<pause@herlpacker.co.uk>
3281
3282 Danijel Milicevic C<me@danijel.de>
3283
3284 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3285
3286 David Naughton, C<naughton@umn.edu>
3287
3288 David E. Wheeler
3289
3290 dhoss: Devin Austin <dhoss@cpan.org>
3291
3292 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3293
3294 Drew Taylor
3295
3296 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3297
3298 esskar: Sascha Kiefer
3299
3300 fireartist: Carl Franks <cfranks@cpan.org>
3301
3302 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3303
3304 gabb: Danijel Milicevic
3305
3306 Gary Ashton Jones
3307
3308 Gavin Henry C<ghenry@perl.me.uk>
3309
3310 Geoff Richards
3311
3312 groditi: Guillermo Roditi <groditi@gmail.com>
3313
3314 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3315
3316 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3317
3318 jcamacho: Juan Camacho
3319
3320 jester: Jesse Sheidlower C<jester@panix.com>
3321
3322 jhannah: Jay Hannah <jay@jays.net>
3323
3324 Jody Belka
3325
3326 Johan Lindstrom
3327
3328 jon: Jon Schutz <jjschutz@cpan.org>
3329
3330 Jonathan Rockway C<< <jrockway@cpan.org> >>
3331
3332 Kieren Diment C<kd@totaldatasolution.com>
3333
3334 konobi: Scott McWhirter <konobi@cpan.org>
3335
3336 marcus: Marcus Ramberg <mramberg@cpan.org>
3337
3338 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3339
3340 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3341
3342 mugwump: Sam Vilain
3343
3344 naughton: David Naughton
3345
3346 ningu: David Kamholz <dkamholz@cpan.org>
3347
3348 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3349
3350 numa: Dan Sully <daniel@cpan.org>
3351
3352 obra: Jesse Vincent
3353
3354 Octavian Rasnita
3355
3356 omega: Andreas Marienborg
3357
3358 Oleg Kostyuk <cub.uanic@gmail.com>
3359
3360 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3361
3362 rafl: Florian Ragwitz <rafl@debian.org>
3363
3364 random: Roland Lammel <lammel@cpan.org>
3365
3366 Robert Sedlacek C<< <rs@474.at> >>
3367
3368 SpiceMan: Marcel Montes
3369
3370 sky: Arthur Bergman
3371
3372 szbalint: Balint Szilakszi <szbalint@cpan.org>
3373
3374 t0m: Tomas Doran <bobtfish@bobtfish.net>
3375
3376 Ulf Edvinsson
3377
3378 Viljo Marrandi C<vilts@yahoo.com>
3379
3380 Will Hawes C<info@whawes.co.uk>
3381
3382 willert: Sebastian Willert <willert@cpan.org>
3383
3384 wreis: Wallace Reis <wallace@reis.org.br>
3385
3386 Yuval Kogman, C<nothingmuch@woobling.org>
3387
3388 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3389
3390 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3391
3392 =end stopwords
3393
3394 =head1 COPYRIGHT
3395
3396 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3397
3398 =head1 LICENSE
3399
3400 This library is free software. You can redistribute it and/or modify it under
3401 the same terms as Perl itself.
3402
3403 =cut
3404
3405 no Moose;
3406
3407 __PACKAGE__->meta->make_immutable;
3408
3409 1;