lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use String::RewritePrefix;
  32 use Catalyst::EngineLoader;
  33 use utf8;
  34 use Carp qw/croak carp shortmess/;
  35 use Try::Tiny;
  36 use Plack::Middleware::Conditional;
  37 use Plack::Middleware::ReverseProxy;
  38 use Plack::Middleware::IIS6ScriptNameFix;
  39 use Plack::Middleware::LighttpdScriptNameFix;
  40
  41 BEGIN { require 5.008004; }
  42
  43 has stack => (is => 'ro', default => sub { [] });
  44 has stash => (is => 'rw', default => sub { {} });
  45 has state => (is => 'rw', default => 0);
  46 has stats => (is => 'rw');
  47 has action => (is => 'rw');
  48 has counter => (is => 'rw', default => sub { {} });
  49 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  50 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  51 has namespace => (is => 'rw');
  52
  53 sub depth { scalar @{ shift->stack || [] }; }
  54 sub comp { shift->component(@_) }
  55
  56 sub req {
  57     my $self = shift; return $self->request(@_);
  58 }
  59 sub res {
  60     my $self = shift; return $self->response(@_);
  61 }
  62
  63 # For backwards compatibility
  64 sub finalize_output { shift->finalize_body(@_) };
  65
  66 # For statistics
  67 our $COUNT     = 1;
  68 our $START     = time;
  69 our $RECURSION = 1000;
  70 our $DETACH    = Catalyst::Exception::Detach->new;
  71 our $GO        = Catalyst::Exception::Go->new;
  72
  73 #I imagine that very few of these really need to be class variables. if any.
  74 #maybe we should just make them attributes with a default?
  75 __PACKAGE__->mk_classdata($_)
  76   for qw/components arguments dispatcher engine log dispatcher_class
  77   engine_loader context_class request_class response_class stats_class
  78   setup_finished _psgi_app loading_psgi_file/;
  79
  80 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  81 __PACKAGE__->request_class('Catalyst::Request');
  82 __PACKAGE__->response_class('Catalyst::Response');
  83 __PACKAGE__->stats_class('Catalyst::Stats');
  84
  85 # Remember to update this in Catalyst::Runtime as well!
  86
  87 our $VERSION = '5.90004';
  88
  89 sub import {
  90     my ( $class, @arguments ) = @_;
  91
  92     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  93     # callers @ISA.
  94     return unless $class eq 'Catalyst';
  95
  96     my $caller = caller();
  97     return if $caller eq 'main';
  98
  99     my $meta = Moose::Meta::Class->initialize($caller);
 100     unless ( $caller->isa('Catalyst') ) {
 101         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 102         $meta->superclasses(@superclasses);
 103     }
 104     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 105     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 106
 107     unless( $meta->has_method('meta') ){
 108         if ($Moose::VERSION >= 1.15) {
 109             $meta->_add_meta_method('meta');
 110         }
 111         else {
 112             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 113         }
 114     }
 115
 116     $caller->arguments( [@arguments] );
 117     $caller->setup_home;
 118 }
 119
 120 sub _application { $_[0] }
 121
 122 =head1 NAME
 123
 124 Catalyst - The Elegant MVC Web Application Framework
 125
 126 =head1 SYNOPSIS
 127
 128 See the L<Catalyst::Manual> distribution for comprehensive
 129 documentation and tutorials.
 130
 131     # Install Catalyst::Devel for helpers and other development tools
 132     # use the helper to create a new application
 133     catalyst.pl MyApp
 134
 135     # add models, views, controllers
 136     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 137     script/myapp_create.pl view MyTemplate TT
 138     script/myapp_create.pl controller Search
 139
 140     # built in testserver -- use -r to restart automatically on changes
 141     # --help to see all available options
 142     script/myapp_server.pl
 143
 144     # command line testing interface
 145     script/myapp_test.pl /yada
 146
 147     ### in lib/MyApp.pm
 148     use Catalyst qw/-Debug/; # include plugins here as well
 149
 150     ### In lib/MyApp/Controller/Root.pm (autocreated)
 151     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 152         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 153         $c->stash->{template} = 'foo.tt'; # set the template
 154         # lookup something from db -- stash vars are passed to TT
 155         $c->stash->{data} =
 156           $c->model('Database::Foo')->search( { country => $args[0] } );
 157         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 158             $c->forward( 'bar' ); # process another action
 159             # do something else after forward returns
 160         }
 161     }
 162
 163     # The foo.tt TT template can use the stash data from the database
 164     [% WHILE (item = data.next) %]
 165         [% item.foo %]
 166     [% END %]
 167
 168     # called for /bar/of/soap, /bar/of/soap/10, etc.
 169     sub bar : Path('/bar/of/soap') { ... }
 170
 171     # called for all actions, from the top-most controller downwards
 172     sub auto : Private {
 173         my ( $self, $c ) = @_;
 174         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 175             $c->res->redirect( '/login' ); # require login
 176             return 0; # abort request and go immediately to end()
 177         }
 178         return 1; # success; carry on to next action
 179     }
 180
 181     # called after all actions are finished
 182     sub end : Private {
 183         my ( $self, $c ) = @_;
 184         if ( scalar @{ $c->error } ) { ... } # handle errors
 185         return if $c->res->body; # already have a response
 186         $c->forward( 'MyApp::View::TT' ); # render template
 187     }
 188
 189     ### in MyApp/Controller/Foo.pm
 190     # called for /foo/bar
 191     sub bar : Local { ... }
 192
 193     # called for /blargle
 194     sub blargle : Global { ... }
 195
 196     # an index action matches /foo, but not /foo/1, etc.
 197     sub index : Private { ... }
 198
 199     ### in MyApp/Controller/Foo/Bar.pm
 200     # called for /foo/bar/baz
 201     sub baz : Local { ... }
 202
 203     # first Root auto is called, then Foo auto, then this
 204     sub auto : Private { ... }
 205
 206     # powerful regular expression paths are also possible
 207     sub details : Regex('^product/(\w+)/details$') {
 208         my ( $self, $c ) = @_;
 209         # extract the (\w+) from the URI
 210         my $product = $c->req->captures->[0];
 211     }
 212
 213 See L<Catalyst::Manual::Intro> for additional information.
 214
 215 =head1 DESCRIPTION
 216
 217 Catalyst is a modern framework for making web applications without the
 218 pain usually associated with this process. This document is a reference
 219 to the main Catalyst application. If you are a new user, we suggest you
 220 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 221
 222 See L<Catalyst::Manual> for more documentation.
 223
 224 Catalyst plugins can be loaded by naming them as arguments to the "use
 225 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 226 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 227 C<My::Module>.
 228
 229     use Catalyst qw/My::Module/;
 230
 231 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 232 fully qualify the name by using a unary plus:
 233
 234     use Catalyst qw/
 235         My::Module
 236         +Fully::Qualified::Plugin::Name
 237     /;
 238
 239 Special flags like C<-Debug> and C<-Engine> can also be specified as
 240 arguments when Catalyst is loaded:
 241
 242     use Catalyst qw/-Debug My::Module/;
 243
 244 The position of plugins and flags in the chain is important, because
 245 they are loaded in the order in which they appear.
 246
 247 The following flags are supported:
 248
 249 =head2 -Debug
 250
 251 Enables debug output. You can also force this setting from the system
 252 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 253 settings override the application, with <MYAPP>_DEBUG having the highest
 254 priority.
 255
 256 This sets the log level to 'debug' and enables full debug output on the
 257 error screen. If you only want the latter, see L<< $c->debug >>.
 258
 259 =head2 -Engine
 260
 261 Forces Catalyst to use a specific engine. Omit the
 262 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 263
 264     use Catalyst qw/-Engine=CGI/;
 265
 266 =head2 -Home
 267
 268 Forces Catalyst to use a specific home directory, e.g.:
 269
 270     use Catalyst qw[-Home=/usr/mst];
 271
 272 This can also be done in the shell environment by setting either the
 273 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 274 is replaced with the uppercased name of your application, any "::" in
 275 the name will be replaced with underscores, e.g. MyApp::Web should use
 276 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 277
 278 If none of these are set, Catalyst will attempt to automatically detect the
 279 home directory. If you are working in a development environment, Catalyst
 280 will try and find the directory containing either Makefile.PL, Build.PL or
 281 dist.ini. If the application has been installed into the system (i.e.
 282 you have done C<make install>), then Catalyst will use the path to your
 283 application module, without the .pm extension (e.g., /foo/MyApp if your
 284 application was installed at /foo/MyApp.pm)
 285
 286 =head2 -Log
 287
 288     use Catalyst '-Log=warn,fatal,error';
 289
 290 Specifies a comma-delimited list of log levels.
 291
 292 =head2 -Stats
 293
 294 Enables statistics collection and reporting.
 295
 296    use Catalyst qw/-Stats=1/;
 297
 298 You can also force this setting from the system environment with CATALYST_STATS
 299 or <MYAPP>_STATS. The environment settings override the application, with
 300 <MYAPP>_STATS having the highest priority.
 301
 302 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 303
 304 =head1 METHODS
 305
 306 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 307
 308 =head2 $c->action
 309
 310 Returns a L<Catalyst::Action> object for the current action, which
 311 stringifies to the action name. See L<Catalyst::Action>.
 312
 313 =head2 $c->namespace
 314
 315 Returns the namespace of the current action, i.e., the URI prefix
 316 corresponding to the controller of the current action. For example:
 317
 318     # in Controller::Foo::Bar
 319     $c->namespace; # returns 'foo/bar';
 320
 321 =head2 $c->request
 322
 323 =head2 $c->req
 324
 325 Returns the current L<Catalyst::Request> object, giving access to
 326 information about the current client request (including parameters,
 327 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 328
 329 =head2 REQUEST FLOW HANDLING
 330
 331 =head2 $c->forward( $action [, \@arguments ] )
 332
 333 =head2 $c->forward( $class, $method, [, \@arguments ] )
 334
 335 Forwards processing to another action, by its private name. If you give a
 336 class name but no method, C<process()> is called. You may also optionally
 337 pass arguments in an arrayref. The action will receive the arguments in
 338 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 339 C<< $c->req->args >> will be restored to the previous values.
 340
 341 Any data C<return>ed from the action forwarded to, will be returned by the
 342 call to forward.
 343
 344     my $foodata = $c->forward('/foo');
 345     $c->forward('index');
 346     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 347     $c->forward('View::TT');
 348
 349 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 350 an C<< eval { } >> around the call (actually
 351 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 352 exceptions thrown by the called action non-fatal and pushing them onto
 353 $c->error instead. If you want C<die> to propagate you need to do something
 354 like:
 355
 356     $c->forward('foo');
 357     die join "\n", @{ $c->error } if @{ $c->error };
 358
 359 Or make sure to always return true values from your actions and write
 360 your code like this:
 361
 362     $c->forward('foo') || return;
 363
 364 Another note is that C<< $c->forward >> always returns a scalar because it
 365 actually returns $c->state which operates in a scalar context.
 366 Thus, something like:
 367
 368     return @array;
 369
 370 in an action that is forwarded to is going to return a scalar,
 371 i.e. how many items are in that array, which is probably not what you want.
 372 If you need to return an array then return a reference to it,
 373 or stash it like so:
 374
 375     $c->stash->{array} = \@array;
 376
 377 and access it from the stash.
 378
 379 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 380
 381 =cut
 382
 383 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 384
 385 =head2 $c->detach( $action [, \@arguments ] )
 386
 387 =head2 $c->detach( $class, $method, [, \@arguments ] )
 388
 389 =head2 $c->detach()
 390
 391 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 392 doesn't return to the previous action when processing is finished.
 393
 394 When called with no arguments it escapes the processing chain entirely.
 395
 396 =cut
 397
 398 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 399
 400 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 401
 402 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 403
 404 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 405 but does a full dispatch, instead of just calling the new C<$action> /
 406 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 407 you go to are called, just like a new request.
 408
 409 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 410 This means, for example, that C<< $c->action >> methods such as
 411 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 412 L<reverse|Catalyst::Action/reverse> return information for the visited action
 413 when they are invoked within the visited action.  This is different from the
 414 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 415 continues to use the $c->action object from the caller action even when
 416 invoked from the called action.
 417
 418 C<< $c->stash >> is kept unchanged.
 419
 420 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 421 allows you to "wrap" another action, just as it would have been called by
 422 dispatching from a URL, while the analogous
 423 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 424 transfer control to another action as if it had been reached directly from a URL.
 425
 426 =cut
 427
 428 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 429
 430 =head2 $c->go( $action [, \@captures, \@arguments ] )
 431
 432 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 433
 434 The relationship between C<go> and
 435 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 436 the relationship between
 437 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 438 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 439 C<< $c->go >> will perform a full dispatch on the specified action or method,
 440 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 441 C<go> escapes the processing of the current request chain on completion, and
 442 does not return to its caller.
 443
 444 @arguments are arguments to the final destination of $action. @captures are
 445 arguments to the intermediate steps, if any, on the way to the final sub of
 446 $action.
 447
 448 =cut
 449
 450 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 451
 452 =head2 $c->response
 453
 454 =head2 $c->res
 455
 456 Returns the current L<Catalyst::Response> object, see there for details.
 457
 458 =head2 $c->stash
 459
 460 Returns a hashref to the stash, which may be used to store data and pass
 461 it between components during a request. You can also set hash keys by
 462 passing arguments. The stash is automatically sent to the view. The
 463 stash is cleared at the end of a request; it cannot be used for
 464 persistent storage (for this you must use a session; see
 465 L<Catalyst::Plugin::Session> for a complete system integrated with
 466 Catalyst).
 467
 468     $c->stash->{foo} = $bar;
 469     $c->stash( { moose => 'majestic', qux => 0 } );
 470     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 471
 472     # stash is automatically passed to the view for use in a template
 473     $c->forward( 'MyApp::View::TT' );
 474
 475 =cut
 476
 477 around stash => sub {
 478     my $orig = shift;
 479     my $c = shift;
 480     my $stash = $orig->($c);
 481     if (@_) {
 482         my $new_stash = @_ > 1 ? {@_} : $_[0];
 483         croak('stash takes a hash or hashref') unless ref $new_stash;
 484         foreach my $key ( keys %$new_stash ) {
 485           $stash->{$key} = $new_stash->{$key};
 486         }
 487     }
 488
 489     return $stash;
 490 };
 491
 492
 493 =head2 $c->error
 494
 495 =head2 $c->error($error, ...)
 496
 497 =head2 $c->error($arrayref)
 498
 499 Returns an arrayref containing error messages.  If Catalyst encounters an
 500 error while processing a request, it stores the error in $c->error.  This
 501 method should only be used to store fatal error messages.
 502
 503     my @error = @{ $c->error };
 504
 505 Add a new error.
 506
 507     $c->error('Something bad happened');
 508
 509 =cut
 510
 511 sub error {
 512     my $c = shift;
 513     if ( $_[0] ) {
 514         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 515         croak @$error unless ref $c;
 516         push @{ $c->{error} }, @$error;
 517     }
 518     elsif ( defined $_[0] ) { $c->{error} = undef }
 519     return $c->{error} || [];
 520 }
 521
 522
 523 =head2 $c->state
 524
 525 Contains the return value of the last executed action.
 526 Note that << $c->state >> operates in a scalar context which means that all
 527 values it returns are scalar.
 528
 529 =head2 $c->clear_errors
 530
 531 Clear errors.  You probably don't want to clear the errors unless you are
 532 implementing a custom error screen.
 533
 534 This is equivalent to running
 535
 536     $c->error(0);
 537
 538 =cut
 539
 540 sub clear_errors {
 541     my $c = shift;
 542     $c->error(0);
 543 }
 544
 545 sub _comp_search_prefixes {
 546     my $c = shift;
 547     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 548 }
 549
 550 # search components given a name and some prefixes
 551 sub _comp_names_search_prefixes {
 552     my ( $c, $name, @prefixes ) = @_;
 553     my $appclass = ref $c || $c;
 554     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 555     $filter = qr/$filter/; # Compile regex now rather than once per loop
 556
 557     # map the original component name to the sub part that we will search against
 558     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 559         grep { /$filter/ } keys %{ $c->components };
 560
 561     # undef for a name will return all
 562     return keys %eligible if !defined $name;
 563
 564     my $query  = ref $name ? $name : qr/^$name$/i;
 565     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 566
 567     return @result if @result;
 568
 569     # if we were given a regexp to search against, we're done.
 570     return if ref $name;
 571
 572     # skip regexp fallback if configured
 573     return
 574         if $appclass->config->{disable_component_resolution_regex_fallback};
 575
 576     # regexp fallback
 577     $query  = qr/$name/i;
 578     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 579
 580     # no results? try against full names
 581     if( !@result ) {
 582         @result = grep { m{$query} } keys %eligible;
 583     }
 584
 585     # don't warn if we didn't find any results, it just might not exist
 586     if( @result ) {
 587         # Disgusting hack to work out correct method name
 588         my $warn_for = lc $prefixes[0];
 589         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 590            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 591            "component resolution is unreliable and unsafe.";
 592         my $short = $result[0];
 593         # remove the component namespace prefix
 594         $short =~ s/.*?(Model|Controller|View):://;
 595         my $shortmess = Carp::shortmess('');
 596         if ($shortmess =~ m#Catalyst/Plugin#) {
 597            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 598               "plugin's config";
 599         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 600            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 601               "component's config";
 602         } else {
 603            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 604               "but if you really wanted to search, pass in a regexp as the argument " .
 605               "like so: \$c->${warn_for}(qr/${name}/)";
 606         }
 607         $c->log->warn( "${msg}$shortmess" );
 608     }
 609
 610     return @result;
 611 }
 612
 613 # Find possible names for a prefix
 614 sub _comp_names {
 615     my ( $c, @prefixes ) = @_;
 616     my $appclass = ref $c || $c;
 617
 618     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 619
 620     my @names = map { s{$filter}{}; $_; }
 621         $c->_comp_names_search_prefixes( undef, @prefixes );
 622
 623     return @names;
 624 }
 625
 626 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 627 sub _filter_component {
 628     my ( $c, $comp, @args ) = @_;
 629
 630     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 631         return $comp->ACCEPT_CONTEXT( $c, @args );
 632     }
 633
 634     return $comp;
 635 }
 636
 637 =head2 COMPONENT ACCESSORS
 638
 639 =head2 $c->controller($name)
 640
 641 Gets a L<Catalyst::Controller> instance by name.
 642
 643     $c->controller('Foo')->do_stuff;
 644
 645 If the name is omitted, will return the controller for the dispatched
 646 action.
 647
 648 If you want to search for controllers, pass in a regexp as the argument.
 649
 650     # find all controllers that start with Foo
 651     my @foo_controllers = $c->controller(qr{^Foo});
 652
 653
 654 =cut
 655
 656 sub controller {
 657     my ( $c, $name, @args ) = @_;
 658
 659     my $appclass = ref($c) || $c;
 660     if( $name ) {
 661         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 662             my $comps = $c->components;
 663             my $check = $appclass."::Controller::".$name;
 664             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 665         }
 666         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 667         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 668         return $c->_filter_component( $result[ 0 ], @args );
 669     }
 670
 671     return $c->component( $c->action->class );
 672 }
 673
 674 =head2 $c->model($name)
 675
 676 Gets a L<Catalyst::Model> instance by name.
 677
 678     $c->model('Foo')->do_stuff;
 679
 680 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 681
 682 If the name is omitted, it will look for
 683  - a model object in $c->stash->{current_model_instance}, then
 684  - a model name in $c->stash->{current_model}, then
 685  - a config setting 'default_model', or
 686  - check if there is only one model, and return it if that's the case.
 687
 688 If you want to search for models, pass in a regexp as the argument.
 689
 690     # find all models that start with Foo
 691     my @foo_models = $c->model(qr{^Foo});
 692
 693 =cut
 694
 695 sub model {
 696     my ( $c, $name, @args ) = @_;
 697     my $appclass = ref($c) || $c;
 698     if( $name ) {
 699         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 700             my $comps = $c->components;
 701             my $check = $appclass."::Model::".$name;
 702             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 703         }
 704         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 705         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 706         return $c->_filter_component( $result[ 0 ], @args );
 707     }
 708
 709     if (ref $c) {
 710         return $c->stash->{current_model_instance}
 711           if $c->stash->{current_model_instance};
 712         return $c->model( $c->stash->{current_model} )
 713           if $c->stash->{current_model};
 714     }
 715     return $c->model( $appclass->config->{default_model} )
 716       if $appclass->config->{default_model};
 717
 718     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 719
 720     if( $rest ) {
 721         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 722         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 723         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 724         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 725         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 726     }
 727
 728     return $c->_filter_component( $comp );
 729 }
 730
 731
 732 =head2 $c->view($name)
 733
 734 Gets a L<Catalyst::View> instance by name.
 735
 736     $c->view('Foo')->do_stuff;
 737
 738 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 739
 740 If the name is omitted, it will look for
 741  - a view object in $c->stash->{current_view_instance}, then
 742  - a view name in $c->stash->{current_view}, then
 743  - a config setting 'default_view', or
 744  - check if there is only one view, and return it if that's the case.
 745
 746 If you want to search for views, pass in a regexp as the argument.
 747
 748     # find all views that start with Foo
 749     my @foo_views = $c->view(qr{^Foo});
 750
 751 =cut
 752
 753 sub view {
 754     my ( $c, $name, @args ) = @_;
 755
 756     my $appclass = ref($c) || $c;
 757     if( $name ) {
 758         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 759             my $comps = $c->components;
 760             my $check = $appclass."::View::".$name;
 761             if( exists $comps->{$check} ) {
 762                 return $c->_filter_component( $comps->{$check}, @args );
 763             }
 764             else {
 765                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 766             }
 767         }
 768         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 769         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 770         return $c->_filter_component( $result[ 0 ], @args );
 771     }
 772
 773     if (ref $c) {
 774         return $c->stash->{current_view_instance}
 775           if $c->stash->{current_view_instance};
 776         return $c->view( $c->stash->{current_view} )
 777           if $c->stash->{current_view};
 778     }
 779     return $c->view( $appclass->config->{default_view} )
 780       if $appclass->config->{default_view};
 781
 782     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 783
 784     if( $rest ) {
 785         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 786         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 787         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 788         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 789         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 790     }
 791
 792     return $c->_filter_component( $comp );
 793 }
 794
 795 =head2 $c->controllers
 796
 797 Returns the available names which can be passed to $c->controller
 798
 799 =cut
 800
 801 sub controllers {
 802     my ( $c ) = @_;
 803     return $c->_comp_names(qw/Controller C/);
 804 }
 805
 806 =head2 $c->models
 807
 808 Returns the available names which can be passed to $c->model
 809
 810 =cut
 811
 812 sub models {
 813     my ( $c ) = @_;
 814     return $c->_comp_names(qw/Model M/);
 815 }
 816
 817
 818 =head2 $c->views
 819
 820 Returns the available names which can be passed to $c->view
 821
 822 =cut
 823
 824 sub views {
 825     my ( $c ) = @_;
 826     return $c->_comp_names(qw/View V/);
 827 }
 828
 829 =head2 $c->comp($name)
 830
 831 =head2 $c->component($name)
 832
 833 Gets a component object by name. This method is not recommended,
 834 unless you want to get a specific component by full
 835 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 836 should be used instead.
 837
 838 If C<$name> is a regexp, a list of components matched against the full
 839 component name will be returned.
 840
 841 If Catalyst can't find a component by name, it will fallback to regex
 842 matching by default. To disable this behaviour set
 843 disable_component_resolution_regex_fallback to a true value.
 844
 845     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 846
 847 =cut
 848
 849 sub component {
 850     my ( $c, $name, @args ) = @_;
 851
 852     if( $name ) {
 853         my $comps = $c->components;
 854
 855         if( !ref $name ) {
 856             # is it the exact name?
 857             return $c->_filter_component( $comps->{ $name }, @args )
 858                        if exists $comps->{ $name };
 859
 860             # perhaps we just omitted "MyApp"?
 861             my $composed = ( ref $c || $c ) . "::${name}";
 862             return $c->_filter_component( $comps->{ $composed }, @args )
 863                        if exists $comps->{ $composed };
 864
 865             # search all of the models, views and controllers
 866             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 867             return $c->_filter_component( $comp, @args ) if $comp;
 868         }
 869
 870         return
 871             if $c->config->{disable_component_resolution_regex_fallback};
 872
 873         # This is here so $c->comp( '::M::' ) works
 874         my $query = ref $name ? $name : qr{$name}i;
 875
 876         my @result = grep { m{$query} } keys %{ $c->components };
 877         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 878
 879         if( $result[ 0 ] ) {
 880             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 881             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 882             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 883             return $c->_filter_component( $result[ 0 ], @args );
 884         }
 885
 886         # I would expect to return an empty list here, but that breaks back-compat
 887     }
 888
 889     # fallback
 890     return sort keys %{ $c->components };
 891 }
 892
 893 =head2 CLASS DATA AND HELPER CLASSES
 894
 895 =head2 $c->config
 896
 897 Returns or takes a hashref containing the application's configuration.
 898
 899     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 900
 901 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 902 like C<myapp.conf> in your applications home directory. See
 903 L<Catalyst::Plugin::ConfigLoader>.
 904
 905 =head3 Cascading configuration
 906
 907 The config method is present on all Catalyst components, and configuration
 908 will be merged when an application is started. Configuration loaded with
 909 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 910 followed by configuration in your top level C<MyApp> class. These two
 911 configurations are merged, and then configuration data whose hash key matches a
 912 component name is merged with configuration for that component.
 913
 914 The configuration for a component is then passed to the C<new> method when a
 915 component is constructed.
 916
 917 For example:
 918
 919     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 920     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 921
 922 will mean that C<MyApp::Model::Foo> receives the following data when
 923 constructed:
 924
 925     MyApp::Model::Foo->new({
 926         bar => 'baz',
 927         quux => 'frob',
 928         overrides => 'me',
 929     });
 930
 931 It's common practice to use a Moose attribute
 932 on the receiving component to access the config value.
 933
 934     package MyApp::Model::Foo;
 935
 936     use Moose;
 937
 938     # this attr will receive 'baz' at construction time
 939     has 'bar' => (
 940         is  => 'rw',
 941         isa => 'Str',
 942     );
 943
 944 You can then get the value 'baz' by calling $c->model('Foo')->bar
 945 (or $self->bar inside code in the model).
 946
 947 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 948 as a way of reading config within your code, as this B<will not> give you the
 949 correctly merged config back. You B<MUST> take the config values supplied to
 950 the constructor and use those instead.
 951
 952 =cut
 953
 954 around config => sub {
 955     my $orig = shift;
 956     my $c = shift;
 957
 958     croak('Setting config after setup has been run is not allowed.')
 959         if ( @_ and $c->setup_finished );
 960
 961     $c->$orig(@_);
 962 };
 963
 964 =head2 $c->log
 965
 966 Returns the logging object instance. Unless it is already set, Catalyst
 967 sets this up with a L<Catalyst::Log> object. To use your own log class,
 968 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 969 C<< __PACKAGE__->setup >>.
 970
 971  __PACKAGE__->log( MyLogger->new );
 972  __PACKAGE__->setup;
 973
 974 And later:
 975
 976     $c->log->info( 'Now logging with my own logger!' );
 977
 978 Your log class should implement the methods described in
 979 L<Catalyst::Log>.
 980
 981
 982 =head2 $c->debug
 983
 984 Returns 1 if debug mode is enabled, 0 otherwise.
 985
 986 You can enable debug mode in several ways:
 987
 988 =over
 989
 990 =item By calling myapp_server.pl with the -d flag
 991
 992 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 993
 994 =item The -Debug option in your MyApp.pm
 995
 996 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 997
 998 =back
 999
1000 The first three also set the log level to 'debug'.
1001
1002 Calling C<< $c->debug(1) >> has no effect.
1003
1004 =cut
1005
1006 sub debug { 0 }
1007
1008 =head2 $c->dispatcher
1009
1010 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1011
1012 =head2 $c->engine
1013
1014 Returns the engine instance. See L<Catalyst::Engine>.
1015
1016
1017 =head2 UTILITY METHODS
1018
1019 =head2 $c->path_to(@path)
1020
1021 Merges C<@path> with C<< $c->config->{home} >> and returns a
1022 L<Path::Class::Dir> object. Note you can usually use this object as
1023 a filename, but sometimes you will have to explicitly stringify it
1024 yourself by calling the C<< ->stringify >> method.
1025
1026 For example:
1027
1028     $c->path_to( 'db', 'sqlite.db' );
1029
1030 =cut
1031
1032 sub path_to {
1033     my ( $c, @path ) = @_;
1034     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1035     if ( -d $path ) { return $path }
1036     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1037 }
1038
1039 =head2 $c->plugin( $name, $class, @args )
1040
1041 Helper method for plugins. It creates a class data accessor/mutator and
1042 loads and instantiates the given class.
1043
1044     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1045
1046     $c->prototype->define_javascript_functions;
1047
1048 B<Note:> This method of adding plugins is deprecated. The ability
1049 to add plugins like this B<will be removed> in a Catalyst 5.81.
1050 Please do not use this functionality in new code.
1051
1052 =cut
1053
1054 sub plugin {
1055     my ( $class, $name, $plugin, @args ) = @_;
1056
1057     # See block comment in t/unit_core_plugin.t
1058     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1059
1060     $class->_register_plugin( $plugin, 1 );
1061
1062     eval { $plugin->import };
1063     $class->mk_classdata($name);
1064     my $obj;
1065     eval { $obj = $plugin->new(@args) };
1066
1067     if ($@) {
1068         Catalyst::Exception->throw( message =>
1069               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1070     }
1071
1072     $class->$name($obj);
1073     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1074       if $class->debug;
1075 }
1076
1077 =head2 MyApp->setup
1078
1079 Initializes the dispatcher and engine, loads any plugins, and loads the
1080 model, view, and controller components. You may also specify an array
1081 of plugins to load here, if you choose to not load them in the C<use
1082 Catalyst> line.
1083
1084     MyApp->setup;
1085     MyApp->setup( qw/-Debug/ );
1086
1087 =cut
1088
1089 sub setup {
1090     my ( $class, @arguments ) = @_;
1091     croak('Running setup more than once')
1092         if ( $class->setup_finished );
1093
1094     unless ( $class->isa('Catalyst') ) {
1095
1096         Catalyst::Exception->throw(
1097             message => qq/'$class' does not inherit from Catalyst/ );
1098     }
1099
1100     if ( $class->arguments ) {
1101         @arguments = ( @arguments, @{ $class->arguments } );
1102     }
1103
1104     # Process options
1105     my $flags = {};
1106
1107     foreach (@arguments) {
1108
1109         if (/^-Debug$/) {
1110             $flags->{log} =
1111               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1112         }
1113         elsif (/^-(\w+)=?(.*)$/) {
1114             $flags->{ lc $1 } = $2;
1115         }
1116         else {
1117             push @{ $flags->{plugins} }, $_;
1118         }
1119     }
1120
1121     $class->setup_home( delete $flags->{home} );
1122
1123     $class->setup_log( delete $flags->{log} );
1124     $class->setup_plugins( delete $flags->{plugins} );
1125     $class->setup_dispatcher( delete $flags->{dispatcher} );
1126     if (my $engine = delete $flags->{engine}) {
1127         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1128     }
1129     $class->setup_engine();
1130     $class->setup_stats( delete $flags->{stats} );
1131
1132     for my $flag ( sort keys %{$flags} ) {
1133
1134         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1135             &$code( $class, delete $flags->{$flag} );
1136         }
1137         else {
1138             $class->log->warn(qq/Unknown flag "$flag"/);
1139         }
1140     }
1141
1142     eval { require Catalyst::Devel; };
1143     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1144         $class->log->warn(<<"EOF");
1145 You are running an old script!
1146
1147   Please update by running (this will overwrite existing files):
1148     catalyst.pl -force -scripts $class
1149
1150   or (this will not overwrite existing files):
1151     catalyst.pl -scripts $class
1152
1153 EOF
1154     }
1155
1156     if ( $class->debug ) {
1157         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1158
1159         if (@plugins) {
1160             my $column_width = Catalyst::Utils::term_width() - 6;
1161             my $t = Text::SimpleTable->new($column_width);
1162             $t->row($_) for @plugins;
1163             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1164         }
1165
1166         my $dispatcher = $class->dispatcher;
1167         my $engine     = $class->engine;
1168         my $home       = $class->config->{home};
1169
1170         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1171         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1172
1173         $home
1174           ? ( -d $home )
1175           ? $class->log->debug(qq/Found home "$home"/)
1176           : $class->log->debug(qq/Home "$home" doesn't exist/)
1177           : $class->log->debug(q/Couldn't find home/);
1178     }
1179
1180     # Call plugins setup, this is stupid and evil.
1181     # Also screws C3 badly on 5.10, hack to avoid.
1182     {
1183         no warnings qw/redefine/;
1184         local *setup = sub { };
1185         $class->setup unless $Catalyst::__AM_RESTARTING;
1186     }
1187
1188     # Initialize our data structure
1189     $class->components( {} );
1190
1191     $class->setup_components;
1192
1193     if ( $class->debug ) {
1194         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1195         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1196         for my $comp ( sort keys %{ $class->components } ) {
1197             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1198             $t->row( $comp, $type );
1199         }
1200         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1201           if ( keys %{ $class->components } );
1202     }
1203
1204     # Add our self to components, since we are also a component
1205     if( $class->isa('Catalyst::Controller') ){
1206       $class->components->{$class} = $class;
1207     }
1208
1209     $class->setup_actions;
1210
1211     if ( $class->debug ) {
1212         my $name = $class->config->{name} || 'Application';
1213         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1214     }
1215
1216     # Make sure that the application class becomes immutable at this point,
1217     B::Hooks::EndOfScope::on_scope_end {
1218         return if $@;
1219         my $meta = Class::MOP::get_metaclass_by_name($class);
1220         if (
1221             $meta->is_immutable
1222             && ! { $meta->immutable_options }->{replace_constructor}
1223             && (
1224                    $class->isa('Class::Accessor::Fast')
1225                 || $class->isa('Class::Accessor')
1226             )
1227         ) {
1228             warn "You made your application class ($class) immutable, "
1229                 . "but did not inline the\nconstructor. "
1230                 . "This will break catalyst, as your app \@ISA "
1231                 . "Class::Accessor(::Fast)?\nPlease pass "
1232                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1233         }
1234         $meta->make_immutable(
1235             replace_constructor => 1,
1236         ) unless $meta->is_immutable;
1237     };
1238
1239     if ($class->config->{case_sensitive}) {
1240         $class->log->warn($class . "->config->{case_sensitive} is set.");
1241         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1242     }
1243
1244     $class->setup_finalize;
1245     # Should be the last thing we do so that user things hooking
1246     # setup_finalize can log..
1247     $class->log->_flush() if $class->log->can('_flush');
1248     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1249 }
1250
1251 =head2 $app->setup_finalize
1252
1253 A hook to attach modifiers to. This method does not do anything except set the
1254 C<setup_finished> accessor.
1255
1256 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1257
1258 Example:
1259
1260     after setup_finalize => sub {
1261         my $app = shift;
1262
1263         ## do stuff here..
1264     };
1265
1266 =cut
1267
1268 sub setup_finalize {
1269     my ($class) = @_;
1270     $class->setup_finished(1);
1271 }
1272
1273 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1274
1275 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1276
1277 Constructs an absolute L<URI> object based on the application root, the
1278 provided path, and the additional arguments and query parameters provided.
1279 When used as a string, provides a textual URI.  If you need more flexibility
1280 than this (i.e. the option to provide relative URIs etc.) see
1281 L<Catalyst::Plugin::SmartURI>.
1282
1283 If no arguments are provided, the URI for the current action is returned.
1284 To return the current action and also provide @args, use
1285 C<< $c->uri_for( $c->action, @args ) >>.
1286
1287 If the first argument is a string, it is taken as a public URI path relative
1288 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1289 relative to the application root (if it does). It is then merged with
1290 C<< $c->request->base >>; any C<@args> are appended as additional path
1291 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1292
1293 If the first argument is a L<Catalyst::Action> it represents an action which
1294 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1295 optional C<\@captures> argument (an arrayref) allows passing the captured
1296 variables that are needed to fill in the paths of Chained and Regex actions;
1297 once the path is resolved, C<uri_for> continues as though a path was
1298 provided, appending any arguments or parameters and creating an absolute
1299 URI.
1300
1301 The captures for the current request can be found in
1302 C<< $c->request->captures >>, and actions can be resolved using
1303 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1304 path, use C<< $c->uri_for_action >> instead.
1305
1306   # Equivalent to $c->req->uri
1307   $c->uri_for($c->action, $c->req->captures,
1308       @{ $c->req->args }, $c->req->params);
1309
1310   # For the Foo action in the Bar controller
1311   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1312
1313   # Path to a static resource
1314   $c->uri_for('/static/images/logo.png');
1315
1316 =cut
1317
1318 sub uri_for {
1319     my ( $c, $path, @args ) = @_;
1320
1321     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1322         $path = $path->path_prefix;
1323         $path =~ s{/+\z}{};
1324         $path .= '/';
1325     }
1326
1327     undef($path) if (defined $path && $path eq '');
1328
1329     my $params =
1330       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1331
1332     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1333     foreach my $arg (@args) {
1334         utf8::encode($arg) if utf8::is_utf8($arg);
1335         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1336     }
1337
1338     if ( blessed($path) ) { # action object
1339         s|/|%2F|g for @args;
1340         my $captures = [ map { s|/|%2F|g; $_; }
1341                         ( scalar @args && ref $args[0] eq 'ARRAY'
1342                          ? @{ shift(@args) }
1343                          : ()) ];
1344
1345         foreach my $capture (@$captures) {
1346             utf8::encode($capture) if utf8::is_utf8($capture);
1347             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1348         }
1349
1350         my $action = $path;
1351         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1352         if( !@args && $action->number_of_args ) {
1353             my $expanded_action = $c->dispatcher->expand_action( $action );
1354
1355             my $num_captures = $expanded_action->number_of_captures;
1356             unshift @args, splice @$captures, $num_captures;
1357         }
1358
1359        $path = $c->dispatcher->uri_for_action($action, $captures);
1360         if (not defined $path) {
1361             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1362                 if $c->debug;
1363             return undef;
1364         }
1365         $path = '/' if $path eq '';
1366     }
1367
1368     unshift(@args, $path);
1369
1370     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1371         my $namespace = $c->namespace;
1372         if (defined $path) { # cheesy hack to handle path '../foo'
1373            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1374         }
1375         unshift(@args, $namespace || '');
1376     }
1377
1378     # join args with '/', or a blank string
1379     my $args = join('/', grep { defined($_) } @args);
1380     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1381     $args =~ s!^/+!!;
1382     my $base = $c->req->base;
1383     my $class = ref($base);
1384     $base =~ s{(?<!/)$}{/};
1385
1386     my $query = '';
1387
1388     if (my @keys = keys %$params) {
1389       # somewhat lifted from URI::_query's query_form
1390       $query = '?'.join('&', map {
1391           my $val = $params->{$_};
1392           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1393           s/ /+/g;
1394           my $key = $_;
1395           $val = '' unless defined $val;
1396           (map {
1397               my $param = "$_";
1398               utf8::encode( $param ) if utf8::is_utf8($param);
1399               # using the URI::Escape pattern here so utf8 chars survive
1400               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1401               $param =~ s/ /+/g;
1402               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1403       } @keys);
1404     }
1405
1406     my $res = bless(\"${base}${args}${query}", $class);
1407     $res;
1408 }
1409
1410 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1411
1412 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1413
1414 =over
1415
1416 =item $path
1417
1418 A private path to the Catalyst action you want to create a URI for.
1419
1420 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1421 >> and passing the resulting C<$action> and the remaining arguments to C<<
1422 $c->uri_for >>.
1423
1424 You can also pass in a Catalyst::Action object, in which case it is passed to
1425 C<< $c->uri_for >>.
1426
1427 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1428
1429 For example, if the action looks like:
1430
1431  package MyApp::Controller::Users;
1432
1433  sub lst : Path('the-list') {}
1434
1435 You can use:
1436
1437  $c->uri_for_action('/users/lst')
1438
1439 and it will create the URI /users/the-list.
1440
1441 =back
1442
1443 =cut
1444
1445 sub uri_for_action {
1446     my ( $c, $path, @args ) = @_;
1447     my $action = blessed($path)
1448       ? $path
1449       : $c->dispatcher->get_action_by_path($path);
1450     unless (defined $action) {
1451       croak "Can't find action for path '$path'";
1452     }
1453     return $c->uri_for( $action, @args );
1454 }
1455
1456 =head2 $c->welcome_message
1457
1458 Returns the Catalyst welcome HTML page.
1459
1460 =cut
1461
1462 sub welcome_message {
1463     my $c      = shift;
1464     my $name   = $c->config->{name};
1465     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1466     my $prefix = Catalyst::Utils::appprefix( ref $c );
1467     $c->response->content_type('text/html; charset=utf-8');
1468     return <<"EOF";
1469 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1470     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1471 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1472     <head>
1473     <meta http-equiv="Content-Language" content="en" />
1474     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1475         <title>$name on Catalyst $VERSION</title>
1476         <style type="text/css">
1477             body {
1478                 color: #000;
1479                 background-color: #eee;
1480             }
1481             div#content {
1482                 width: 640px;
1483                 margin-left: auto;
1484                 margin-right: auto;
1485                 margin-top: 10px;
1486                 margin-bottom: 10px;
1487                 text-align: left;
1488                 background-color: #ccc;
1489                 border: 1px solid #aaa;
1490             }
1491             p, h1, h2 {
1492                 margin-left: 20px;
1493                 margin-right: 20px;
1494                 font-family: verdana, tahoma, sans-serif;
1495             }
1496             a {
1497                 font-family: verdana, tahoma, sans-serif;
1498             }
1499             :link, :visited {
1500                     text-decoration: none;
1501                     color: #b00;
1502                     border-bottom: 1px dotted #bbb;
1503             }
1504             :link:hover, :visited:hover {
1505                     color: #555;
1506             }
1507             div#topbar {
1508                 margin: 0px;
1509             }
1510             pre {
1511                 margin: 10px;
1512                 padding: 8px;
1513             }
1514             div#answers {
1515                 padding: 8px;
1516                 margin: 10px;
1517                 background-color: #fff;
1518                 border: 1px solid #aaa;
1519             }
1520             h1 {
1521                 font-size: 0.9em;
1522                 font-weight: normal;
1523                 text-align: center;
1524             }
1525             h2 {
1526                 font-size: 1.0em;
1527             }
1528             p {
1529                 font-size: 0.9em;
1530             }
1531             p img {
1532                 float: right;
1533                 margin-left: 10px;
1534             }
1535             span#appname {
1536                 font-weight: bold;
1537                 font-size: 1.6em;
1538             }
1539         </style>
1540     </head>
1541     <body>
1542         <div id="content">
1543             <div id="topbar">
1544                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1545                     $VERSION</h1>
1546              </div>
1547              <div id="answers">
1548                  <p>
1549                  <img src="$logo" alt="Catalyst Logo" />
1550                  </p>
1551                  <p>Welcome to the  world of Catalyst.
1552                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1553                     framework will make web development something you had
1554                     never expected it to be: Fun, rewarding, and quick.</p>
1555                  <h2>What to do now?</h2>
1556                  <p>That really depends  on what <b>you</b> want to do.
1557                     We do, however, provide you with a few starting points.</p>
1558                  <p>If you want to jump right into web development with Catalyst
1559                     you might want to start with a tutorial.</p>
1560 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1561 </pre>
1562 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1563 <pre>
1564 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1565 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1566 </code></pre>
1567                  <h2>What to do next?</h2>
1568                  <p>Next it's time to write an actual application. Use the
1569                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1570                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1571                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1572                     they can save you a lot of work.</p>
1573                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1574                     <p>Also, be sure to check out the vast and growing
1575                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1576                     you are likely to find what you need there.
1577                     </p>
1578
1579                  <h2>Need help?</h2>
1580                  <p>Catalyst has a very active community. Here are the main places to
1581                     get in touch with us.</p>
1582                  <ul>
1583                      <li>
1584                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1585                      </li>
1586                      <li>
1587                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1588                      </li>
1589                      <li>
1590                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1591                      </li>
1592                  </ul>
1593                  <h2>In conclusion</h2>
1594                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1595                     as we enjoyed making it. Please contact us if you have ideas
1596                     for improvement or other feedback.</p>
1597              </div>
1598          </div>
1599     </body>
1600 </html>
1601 EOF
1602 }
1603
1604 =head1 INTERNAL METHODS
1605
1606 These methods are not meant to be used by end users.
1607
1608 =head2 $c->components
1609
1610 Returns a hash of components.
1611
1612 =head2 $c->context_class
1613
1614 Returns or sets the context class.
1615
1616 =head2 $c->counter
1617
1618 Returns a hashref containing coderefs and execution counts (needed for
1619 deep recursion detection).
1620
1621 =head2 $c->depth
1622
1623 Returns the number of actions on the current internal execution stack.
1624
1625 =head2 $c->dispatch
1626
1627 Dispatches a request to actions.
1628
1629 =cut
1630
1631 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1632
1633 =head2 $c->dispatcher_class
1634
1635 Returns or sets the dispatcher class.
1636
1637 =head2 $c->dump_these
1638
1639 Returns a list of 2-element array references (name, structure) pairs
1640 that will be dumped on the error page in debug mode.
1641
1642 =cut
1643
1644 sub dump_these {
1645     my $c = shift;
1646     [ Request => $c->req ],
1647     [ Response => $c->res ],
1648     [ Stash => $c->stash ],
1649     [ Config => $c->config ];
1650 }
1651
1652 =head2 $c->engine_class
1653
1654 Returns or sets the engine class.
1655
1656 =head2 $c->execute( $class, $coderef )
1657
1658 Execute a coderef in given class and catch exceptions. Errors are available
1659 via $c->error.
1660
1661 =cut
1662
1663 sub execute {
1664     my ( $c, $class, $code ) = @_;
1665     $class = $c->component($class) || $class;
1666     $c->state(0);
1667
1668     if ( $c->depth >= $RECURSION ) {
1669         my $action = $code->reverse();
1670         $action = "/$action" unless $action =~ /->/;
1671         my $error = qq/Deep recursion detected calling "${action}"/;
1672         $c->log->error($error);
1673         $c->error($error);
1674         $c->state(0);
1675         return $c->state;
1676     }
1677
1678     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1679
1680     push( @{ $c->stack }, $code );
1681
1682     no warnings 'recursion';
1683     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1684     #      I have no idea how, ergo $ret (which appears to fix the issue)
1685     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1686
1687     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1688
1689     my $last = pop( @{ $c->stack } );
1690
1691     if ( my $error = $@ ) {
1692         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1693             $error->rethrow if $c->depth > 1;
1694         }
1695         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1696             $error->rethrow if $c->depth > 0;
1697         }
1698         else {
1699             unless ( ref $error ) {
1700                 no warnings 'uninitialized';
1701                 chomp $error;
1702                 my $class = $last->class;
1703                 my $name  = $last->name;
1704                 $error = qq/Caught exception in $class->$name "$error"/;
1705             }
1706             $c->error($error);
1707         }
1708         $c->state(0);
1709     }
1710     return $c->state;
1711 }
1712
1713 sub _stats_start_execute {
1714     my ( $c, $code ) = @_;
1715     my $appclass = ref($c) || $c;
1716     return if ( ( $code->name =~ /^_.*/ )
1717         && ( !$appclass->config->{show_internal_actions} ) );
1718
1719     my $action_name = $code->reverse();
1720     $c->counter->{$action_name}++;
1721
1722     my $action = $action_name;
1723     $action = "/$action" unless $action =~ /->/;
1724
1725     # determine if the call was the result of a forward
1726     # this is done by walking up the call stack and looking for a calling
1727     # sub of Catalyst::forward before the eval
1728     my $callsub = q{};
1729     for my $index ( 2 .. 11 ) {
1730         last
1731         if ( ( caller($index) )[0] eq 'Catalyst'
1732             && ( caller($index) )[3] eq '(eval)' );
1733
1734         if ( ( caller($index) )[3] =~ /forward$/ ) {
1735             $callsub = ( caller($index) )[3];
1736             $action  = "-> $action";
1737             last;
1738         }
1739     }
1740
1741     my $uid = $action_name . $c->counter->{$action_name};
1742
1743     # is this a root-level call or a forwarded call?
1744     if ( $callsub =~ /forward$/ ) {
1745         my $parent = $c->stack->[-1];
1746
1747         # forward, locate the caller
1748         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1749             $c->stats->profile(
1750                 begin  => $action,
1751                 parent => "$parent" . $c->counter->{"$parent"},
1752                 uid    => $uid,
1753             );
1754         }
1755         else {
1756
1757             # forward with no caller may come from a plugin
1758             $c->stats->profile(
1759                 begin => $action,
1760                 uid   => $uid,
1761             );
1762         }
1763     }
1764     else {
1765
1766         # root-level call
1767         $c->stats->profile(
1768             begin => $action,
1769             uid   => $uid,
1770         );
1771     }
1772     return $action;
1773
1774 }
1775
1776 sub _stats_finish_execute {
1777     my ( $c, $info ) = @_;
1778     $c->stats->profile( end => $info );
1779 }
1780
1781 =head2 $c->finalize
1782
1783 Finalizes the request.
1784
1785 =cut
1786
1787 sub finalize {
1788     my $c = shift;
1789
1790     for my $error ( @{ $c->error } ) {
1791         $c->log->error($error);
1792     }
1793
1794     # Allow engine to handle finalize flow (for POE)
1795     my $engine = $c->engine;
1796     if ( my $code = $engine->can('finalize') ) {
1797         $engine->$code($c);
1798     }
1799     else {
1800
1801         $c->finalize_uploads;
1802
1803         # Error
1804         if ( $#{ $c->error } >= 0 ) {
1805             $c->finalize_error;
1806         }
1807
1808         $c->finalize_headers;
1809
1810         # HEAD request
1811         if ( $c->request->method eq 'HEAD' ) {
1812             $c->response->body('');
1813         }
1814
1815         $c->finalize_body;
1816     }
1817
1818     $c->log_response;
1819
1820     if ($c->use_stats) {
1821         my $elapsed = sprintf '%f', $c->stats->elapsed;
1822         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1823         $c->log->info(
1824             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1825     }
1826
1827     return $c->response->status;
1828 }
1829
1830 =head2 $c->finalize_body
1831
1832 Finalizes body.
1833
1834 =cut
1835
1836 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1837
1838 =head2 $c->finalize_cookies
1839
1840 Finalizes cookies.
1841
1842 =cut
1843
1844 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1845
1846 =head2 $c->finalize_error
1847
1848 Finalizes error.
1849
1850 =cut
1851
1852 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1853
1854 =head2 $c->finalize_headers
1855
1856 Finalizes headers.
1857
1858 =cut
1859
1860 sub finalize_headers {
1861     my $c = shift;
1862
1863     my $response = $c->response; #accessor calls can add up?
1864
1865     # Check if we already finalized headers
1866     return if $response->finalized_headers;
1867
1868     # Handle redirects
1869     if ( my $location = $response->redirect ) {
1870         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1871         $response->header( Location => $location );
1872
1873         if ( !$response->has_body ) {
1874             # Add a default body if none is already present
1875             $response->body(<<"EOF");
1876 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1877 <html xmlns="http://www.w3.org/1999/xhtml">
1878   <head>
1879     <title>Moved</title>
1880   </head>
1881   <body>
1882      <p>This item has moved <a href="$location">here</a>.</p>
1883   </body>
1884 </html>
1885 EOF
1886             $response->content_type('text/html; charset=utf-8');
1887         }
1888     }
1889
1890     # Content-Length
1891     if ( defined $response->body && length $response->body && !$response->content_length ) {
1892
1893         # get the length from a filehandle
1894         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1895         {
1896             my $size = -s $response->body;
1897             if ( $size ) {
1898                 $response->content_length( $size );
1899             }
1900             else {
1901                 $c->log->warn('Serving filehandle without a content-length');
1902             }
1903         }
1904         else {
1905             # everything should be bytes at this point, but just in case
1906             $response->content_length( length( $response->body ) );
1907         }
1908     }
1909
1910     # Errors
1911     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1912         $response->headers->remove_header("Content-Length");
1913         $response->body('');
1914     }
1915
1916     $c->finalize_cookies;
1917
1918     $c->engine->finalize_headers( $c, @_ );
1919
1920     # Done
1921     $response->finalized_headers(1);
1922 }
1923
1924 =head2 $c->finalize_output
1925
1926 An alias for finalize_body.
1927
1928 =head2 $c->finalize_read
1929
1930 Finalizes the input after reading is complete.
1931
1932 =cut
1933
1934 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1935
1936 =head2 $c->finalize_uploads
1937
1938 Finalizes uploads. Cleans up any temporary files.
1939
1940 =cut
1941
1942 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1943
1944 =head2 $c->get_action( $action, $namespace )
1945
1946 Gets an action in a given namespace.
1947
1948 =cut
1949
1950 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1951
1952 =head2 $c->get_actions( $action, $namespace )
1953
1954 Gets all actions of a given name in a namespace and all parent
1955 namespaces.
1956
1957 =cut
1958
1959 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1960
1961 =head2 $app->handle_request( @arguments )
1962
1963 Called to handle each HTTP request.
1964
1965 =cut
1966
1967 sub handle_request {
1968     my ( $class, @arguments ) = @_;
1969
1970     # Always expect worst case!
1971     my $status = -1;
1972     try {
1973         if ($class->debug) {
1974             my $secs = time - $START || 1;
1975             my $av = sprintf '%.3f', $COUNT / $secs;
1976             my $time = localtime time;
1977             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1978         }
1979
1980         my $c = $class->prepare(@arguments);
1981         $c->dispatch;
1982         $status = $c->finalize;
1983     }
1984     catch {
1985         chomp(my $error = $_);
1986         $class->log->error(qq/Caught exception in engine "$error"/);
1987     };
1988
1989     $COUNT++;
1990
1991     if(my $coderef = $class->log->can('_flush')){
1992         $class->log->$coderef();
1993     }
1994     return $status;
1995 }
1996
1997 =head2 $class->prepare( @arguments )
1998
1999 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2000 etc.).
2001
2002 =cut
2003
2004 sub prepare {
2005     my ( $class, @arguments ) = @_;
2006
2007     # XXX
2008     # After the app/ctxt split, this should become an attribute based on something passed
2009     # into the application.
2010     $class->context_class( ref $class || $class ) unless $class->context_class;
2011
2012     my $c = $class->context_class->new({});
2013
2014     # For on-demand data
2015     $c->request->_context($c);
2016     $c->response->_context($c);
2017
2018     #surely this is not the most efficient way to do things...
2019     $c->stats($class->stats_class->new)->enable($c->use_stats);
2020     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2021         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2022     }
2023
2024     try {
2025         # Allow engine to direct the prepare flow (for POE)
2026         if ( my $prepare = $c->engine->can('prepare') ) {
2027             $c->engine->$prepare( $c, @arguments );
2028         }
2029         else {
2030             $c->prepare_request(@arguments);
2031             $c->prepare_connection;
2032             $c->prepare_query_parameters;
2033             $c->prepare_headers;
2034             $c->prepare_cookies;
2035             $c->prepare_path;
2036
2037             # Prepare the body for reading, either by prepare_body
2038             # or the user, if they are using $c->read
2039             $c->prepare_read;
2040
2041             # Parse the body unless the user wants it on-demand
2042             unless ( ref($c)->config->{parse_on_demand} ) {
2043                 $c->prepare_body;
2044             }
2045         }
2046     }
2047     # VERY ugly and probably shouldn't rely on ->finalize actually working
2048     catch {
2049         # failed prepare is always due to an invalid request, right?
2050         $c->response->status(400);
2051         $c->response->content_type('text/plain');
2052         $c->response->body('Bad Request');
2053         $c->finalize;
2054         die $_;
2055     };
2056
2057     my $method  = $c->req->method  || '';
2058     my $path    = $c->req->path;
2059     $path       = '/' unless length $path;
2060     my $address = $c->req->address || '';
2061
2062     $c->log_request;
2063
2064     $c->prepare_action;
2065
2066     return $c;
2067 }
2068
2069 =head2 $c->prepare_action
2070
2071 Prepares action. See L<Catalyst::Dispatcher>.
2072
2073 =cut
2074
2075 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2076
2077 =head2 $c->prepare_body
2078
2079 Prepares message body.
2080
2081 =cut
2082
2083 sub prepare_body {
2084     my $c = shift;
2085
2086     return if $c->request->_has_body;
2087
2088     # Initialize on-demand data
2089     $c->engine->prepare_body( $c, @_ );
2090     $c->prepare_parameters;
2091     $c->prepare_uploads;
2092 }
2093
2094 =head2 $c->prepare_body_chunk( $chunk )
2095
2096 Prepares a chunk of data before sending it to L<HTTP::Body>.
2097
2098 See L<Catalyst::Engine>.
2099
2100 =cut
2101
2102 sub prepare_body_chunk {
2103     my $c = shift;
2104     $c->engine->prepare_body_chunk( $c, @_ );
2105 }
2106
2107 =head2 $c->prepare_body_parameters
2108
2109 Prepares body parameters.
2110
2111 =cut
2112
2113 sub prepare_body_parameters {
2114     my $c = shift;
2115     $c->engine->prepare_body_parameters( $c, @_ );
2116 }
2117
2118 =head2 $c->prepare_connection
2119
2120 Prepares connection.
2121
2122 =cut
2123
2124 sub prepare_connection {
2125     my $c = shift;
2126     $c->engine->prepare_connection( $c, @_ );
2127 }
2128
2129 =head2 $c->prepare_cookies
2130
2131 Prepares cookies.
2132
2133 =cut
2134
2135 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2136
2137 =head2 $c->prepare_headers
2138
2139 Prepares headers.
2140
2141 =cut
2142
2143 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2144
2145 =head2 $c->prepare_parameters
2146
2147 Prepares parameters.
2148
2149 =cut
2150
2151 sub prepare_parameters {
2152     my $c = shift;
2153     $c->prepare_body_parameters;
2154     $c->engine->prepare_parameters( $c, @_ );
2155 }
2156
2157 =head2 $c->prepare_path
2158
2159 Prepares path and base.
2160
2161 =cut
2162
2163 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2164
2165 =head2 $c->prepare_query_parameters
2166
2167 Prepares query parameters.
2168
2169 =cut
2170
2171 sub prepare_query_parameters {
2172     my $c = shift;
2173
2174     $c->engine->prepare_query_parameters( $c, @_ );
2175 }
2176
2177 =head2 $c->log_request
2178
2179 Writes information about the request to the debug logs.  This includes:
2180
2181 =over 4
2182
2183 =item * Request method, path, and remote IP address
2184
2185 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2186
2187 =item * Request parameters
2188
2189 =item * File uploads
2190
2191 =back
2192
2193 =cut
2194
2195 sub log_request {
2196     my $c = shift;
2197
2198     return unless $c->debug;
2199
2200     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2201     my $request = $dump->[1];
2202
2203     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2204     $method ||= '';
2205     $path = '/' unless length $path;
2206     $address ||= '';
2207     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2208
2209     $c->log_request_headers($request->headers);
2210
2211     if ( my $keywords = $request->query_keywords ) {
2212         $c->log->debug("Query keywords are: $keywords");
2213     }
2214
2215     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2216
2217     $c->log_request_uploads($request);
2218 }
2219
2220 =head2 $c->log_response
2221
2222 Writes information about the response to the debug logs by calling
2223 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2224
2225 =cut
2226
2227 sub log_response {
2228     my $c = shift;
2229
2230     return unless $c->debug;
2231
2232     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2233     my $response = $dump->[1];
2234
2235     $c->log_response_status_line($response);
2236     $c->log_response_headers($response->headers);
2237 }
2238
2239 =head2 $c->log_response_status_line($response)
2240
2241 Writes one line of information about the response to the debug logs.  This includes:
2242
2243 =over 4
2244
2245 =item * Response status code
2246
2247 =item * Content-Type header (if present)
2248
2249 =item * Content-Length header (if present)
2250
2251 =back
2252
2253 =cut
2254
2255 sub log_response_status_line {
2256     my ($c, $response) = @_;
2257
2258     $c->log->debug(
2259         sprintf(
2260             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2261             $response->status                            || 'unknown',
2262             $response->headers->header('Content-Type')   || 'unknown',
2263             $response->headers->header('Content-Length') || 'unknown'
2264         )
2265     );
2266 }
2267
2268 =head2 $c->log_response_headers($headers);
2269
2270 Hook method which can be wrapped by plugins to log the response headers.
2271 No-op in the default implementation.
2272
2273 =cut
2274
2275 sub log_response_headers {}
2276
2277 =head2 $c->log_request_parameters( query => {}, body => {} )
2278
2279 Logs request parameters to debug logs
2280
2281 =cut
2282
2283 sub log_request_parameters {
2284     my $c          = shift;
2285     my %all_params = @_;
2286
2287     return unless $c->debug;
2288
2289     my $column_width = Catalyst::Utils::term_width() - 44;
2290     foreach my $type (qw(query body)) {
2291         my $params = $all_params{$type};
2292         next if ! keys %$params;
2293         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2294         for my $key ( sort keys %$params ) {
2295             my $param = $params->{$key};
2296             my $value = defined($param) ? $param : '';
2297             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2298         }
2299         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2300     }
2301 }
2302
2303 =head2 $c->log_request_uploads
2304
2305 Logs file uploads included in the request to the debug logs.
2306 The parameter name, filename, file type, and file size are all included in
2307 the debug logs.
2308
2309 =cut
2310
2311 sub log_request_uploads {
2312     my $c = shift;
2313     my $request = shift;
2314     return unless $c->debug;
2315     my $uploads = $request->uploads;
2316     if ( keys %$uploads ) {
2317         my $t = Text::SimpleTable->new(
2318             [ 12, 'Parameter' ],
2319             [ 26, 'Filename' ],
2320             [ 18, 'Type' ],
2321             [ 9,  'Size' ]
2322         );
2323         for my $key ( sort keys %$uploads ) {
2324             my $upload = $uploads->{$key};
2325             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2326                 $t->row( $key, $u->filename, $u->type, $u->size );
2327             }
2328         }
2329         $c->log->debug( "File Uploads are:\n" . $t->draw );
2330     }
2331 }
2332
2333 =head2 $c->log_request_headers($headers);
2334
2335 Hook method which can be wrapped by plugins to log the request headers.
2336 No-op in the default implementation.
2337
2338 =cut
2339
2340 sub log_request_headers {}
2341
2342 =head2 $c->log_headers($type => $headers)
2343
2344 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2345
2346 =cut
2347
2348 sub log_headers {
2349     my $c       = shift;
2350     my $type    = shift;
2351     my $headers = shift;    # an HTTP::Headers instance
2352
2353     return unless $c->debug;
2354
2355     my $column_width = Catalyst::Utils::term_width() - 28;
2356     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2357     $headers->scan(
2358         sub {
2359             my ( $name, $value ) = @_;
2360             $t->row( $name, $value );
2361         }
2362     );
2363     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2364 }
2365
2366
2367 =head2 $c->prepare_read
2368
2369 Prepares the input for reading.
2370
2371 =cut
2372
2373 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2374
2375 =head2 $c->prepare_request
2376
2377 Prepares the engine request.
2378
2379 =cut
2380
2381 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2382
2383 =head2 $c->prepare_uploads
2384
2385 Prepares uploads.
2386
2387 =cut
2388
2389 sub prepare_uploads {
2390     my $c = shift;
2391
2392     $c->engine->prepare_uploads( $c, @_ );
2393 }
2394
2395 =head2 $c->prepare_write
2396
2397 Prepares the output for writing.
2398
2399 =cut
2400
2401 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2402
2403 =head2 $c->request_class
2404
2405 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2406
2407 =head2 $c->response_class
2408
2409 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2410
2411 =head2 $c->read( [$maxlength] )
2412
2413 Reads a chunk of data from the request body. This method is designed to
2414 be used in a while loop, reading C<$maxlength> bytes on every call.
2415 C<$maxlength> defaults to the size of the request if not specified.
2416
2417 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2418 directly.
2419
2420 Warning: If you use read(), Catalyst will not process the body,
2421 so you will not be able to access POST parameters or file uploads via
2422 $c->request.  You must handle all body parsing yourself.
2423
2424 =cut
2425
2426 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2427
2428 =head2 $c->run
2429
2430 Starts the engine.
2431
2432 =cut
2433
2434 sub run {
2435   my $app = shift;
2436   $app->engine_loader->needs_psgi_engine_compat_hack ?
2437     $app->engine->run($app, @_) :
2438       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2439 }
2440
2441 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2442
2443 Sets an action in a given namespace.
2444
2445 =cut
2446
2447 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2448
2449 =head2 $c->setup_actions($component)
2450
2451 Sets up actions for a component.
2452
2453 =cut
2454
2455 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2456
2457 =head2 $c->setup_components
2458
2459 This method is called internally to set up the application's components.
2460
2461 It finds modules by calling the L<locate_components> method, expands them to
2462 package names with the L<expand_component_module> method, and then installs
2463 each component into the application.
2464
2465 The C<setup_components> config option is passed to both of the above methods.
2466
2467 Installation of each component is performed by the L<setup_component> method,
2468 below.
2469
2470 =cut
2471
2472 sub setup_components {
2473     my $class = shift;
2474
2475     my $config  = $class->config->{ setup_components };
2476
2477     my @comps = $class->locate_components($config);
2478     my %comps = map { $_ => 1 } @comps;
2479
2480     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2481     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2482         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2483     ) if $deprecatedcatalyst_component_names;
2484
2485     for my $component ( @comps ) {
2486
2487         # We pass ignore_loaded here so that overlay files for (e.g.)
2488         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2489         # we know M::P::O found a file on disk so this is safe
2490
2491         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2492     }
2493
2494     for my $component (@comps) {
2495         my $instance = $class->components->{ $component } = $class->setup_component($component);
2496         my @expanded_components = $instance->can('expand_modules')
2497             ? $instance->expand_modules( $component, $config )
2498             : $class->expand_component_module( $component, $config );
2499         for my $component (@expanded_components) {
2500             next if $comps{$component};
2501             $class->components->{ $component } = $class->setup_component($component);
2502         }
2503     }
2504 }
2505
2506 =head2 $c->locate_components( $setup_component_config )
2507
2508 This method is meant to provide a list of component modules that should be
2509 setup for the application.  By default, it will use L<Module::Pluggable>.
2510
2511 Specify a C<setup_components> config option to pass additional options directly
2512 to L<Module::Pluggable>. To add additional search paths, specify a key named
2513 C<search_extra> as an array reference. Items in the array beginning with C<::>
2514 will have the application class name prepended to them.
2515
2516 =cut
2517
2518 sub locate_components {
2519     my $class  = shift;
2520     my $config = shift;
2521
2522     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2523     my $extra   = delete $config->{ search_extra } || [];
2524
2525     push @paths, @$extra;
2526
2527     my $locator = Module::Pluggable::Object->new(
2528         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2529         %$config
2530     );
2531
2532     # XXX think about ditching this sort entirely
2533     my @comps = sort { length $a <=> length $b } $locator->plugins;
2534
2535     return @comps;
2536 }
2537
2538 =head2 $c->expand_component_module( $component, $setup_component_config )
2539
2540 Components found by C<locate_components> will be passed to this method, which
2541 is expected to return a list of component (package) names to be set up.
2542
2543 =cut
2544
2545 sub expand_component_module {
2546     my ($class, $module) = @_;
2547     return Devel::InnerPackage::list_packages( $module );
2548 }
2549
2550 =head2 $c->setup_component
2551
2552 =cut
2553
2554 sub setup_component {
2555     my( $class, $component ) = @_;
2556
2557     unless ( $component->can( 'COMPONENT' ) ) {
2558         return $component;
2559     }
2560
2561     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2562     my $config = $class->config->{ $suffix } || {};
2563     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2564     # methods also pass it. local to avoid pointlessly shitting in config
2565     # for the debug screen, as $component is already the key name.
2566     local $config->{catalyst_component_name} = $component;
2567
2568     my $instance = eval { $component->COMPONENT( $class, $config ); };
2569
2570     if ( my $error = $@ ) {
2571         chomp $error;
2572         Catalyst::Exception->throw(
2573             message => qq/Couldn't instantiate component "$component", "$error"/
2574         );
2575     }
2576
2577     unless (blessed $instance) {
2578         my $metaclass = Moose::Util::find_meta($component);
2579         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2580         my $component_method_from = $method_meta->associated_metaclass->name;
2581         my $value = defined($instance) ? $instance : 'undef';
2582         Catalyst::Exception->throw(
2583             message =>
2584             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2585         );
2586     }
2587     return $instance;
2588 }
2589
2590 =head2 $c->setup_dispatcher
2591
2592 Sets up dispatcher.
2593
2594 =cut
2595
2596 sub setup_dispatcher {
2597     my ( $class, $dispatcher ) = @_;
2598
2599     if ($dispatcher) {
2600         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2601     }
2602
2603     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2604         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2605     }
2606
2607     unless ($dispatcher) {
2608         $dispatcher = $class->dispatcher_class;
2609     }
2610
2611     Class::MOP::load_class($dispatcher);
2612
2613     # dispatcher instance
2614     $class->dispatcher( $dispatcher->new );
2615 }
2616
2617 =head2 $c->setup_engine
2618
2619 Sets up engine.
2620
2621 =cut
2622
2623 sub engine_class {
2624     my ($class, $requested_engine) = @_;
2625
2626     if (!$class->engine_loader || $requested_engine) {
2627         $class->engine_loader(
2628             Catalyst::EngineLoader->new({
2629                 application_name => $class,
2630                 (defined $requested_engine
2631                      ? (catalyst_engine_class => $requested_engine) : ()),
2632             }),
2633         );
2634     }
2635
2636     $class->engine_loader->catalyst_engine_class;
2637 }
2638
2639 sub setup_engine {
2640     my ($class, $requested_engine) = @_;
2641
2642     my $engine = do {
2643         my $loader = $class->engine_loader;
2644
2645         if (!$loader || $requested_engine) {
2646             $loader = Catalyst::EngineLoader->new({
2647                 application_name => $class,
2648                 (defined $requested_engine
2649                      ? (requested_engine => $requested_engine) : ()),
2650             }),
2651
2652             $class->engine_loader($loader);
2653         }
2654
2655         $loader->catalyst_engine_class;
2656     };
2657
2658     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2659     return if $class->loading_psgi_file;
2660
2661     Class::MOP::load_class($engine);
2662
2663     if ($ENV{MOD_PERL}) {
2664         my $apache = $class->engine_loader->auto;
2665
2666         my $meta = find_meta($class);
2667         my $was_immutable = $meta->is_immutable;
2668         my %immutable_options = $meta->immutable_options;
2669         $meta->make_mutable if $was_immutable;
2670
2671         $meta->add_method(handler => sub {
2672             my $r = shift;
2673             my $psgi_app = $class->psgi_app;
2674             $apache->call_app($r, $psgi_app);
2675         });
2676
2677         $meta->make_immutable(%immutable_options) if $was_immutable;
2678     }
2679
2680     $class->engine( $engine->new );
2681
2682     return;
2683 }
2684
2685 sub _finalized_psgi_app {
2686     my ($app) = @_;
2687
2688     unless ($app->_psgi_app) {
2689         my $psgi_app = $app->_setup_psgi_app;
2690         $app->_psgi_app($psgi_app);
2691     }
2692
2693     return $app->_psgi_app;
2694 }
2695
2696 sub _setup_psgi_app {
2697     my ($app) = @_;
2698
2699     for my $home (Path::Class::Dir->new($app->config->{home})) {
2700         my $psgi_file = $home->file(
2701             Catalyst::Utils::appprefix($app) . '.psgi',
2702         );
2703
2704         next unless -e $psgi_file;
2705
2706         # If $psgi_file calls ->setup_engine, it's doing so to load
2707         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2708         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2709         # anyway. So set a flag (ick) that tells setup_engine not to populate
2710         # $c->engine or do any other things we might regret.
2711
2712         $app->loading_psgi_file(1);
2713         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2714         $app->loading_psgi_file(0);
2715
2716         return $psgi_app
2717             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2718
2719         warn <<"EOW";
2720 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2721
2722 Its content has been ignored. Please consult the Catalyst::Upgrading
2723 documentation on how to upgrade from Catalyst::Engine::PSGI.
2724 EOW
2725     }
2726
2727     return $app->apply_default_middlewares($app->psgi_app);
2728 }
2729
2730 =head2 $c->apply_default_middlewares
2731
2732 Adds the following L<Plack> middlewares to your application, since they are
2733 useful and commonly needed:
2734
2735 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2736 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2737 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2738 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2739 applied since this middleware is smart enough to conditionally apply itself).
2740
2741 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2742 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2743 $ENV{SCRIPT_NAME}
2744
2745 =cut
2746
2747
2748 sub apply_default_middlewares {
2749     my ($app, $psgi_app) = @_;
2750
2751     $psgi_app = Plack::Middleware::Conditional->wrap(
2752         $psgi_app,
2753         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2754         condition => sub {
2755             my ($env) = @_;
2756             return if $app->config->{ignore_frontend_proxy};
2757             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2758                 || $app->config->{using_frontend_proxy};
2759         },
2760     );
2761
2762     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2763     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2764     $psgi_app = Plack::Middleware::LighttpdScriptNameFix->wrap($psgi_app);
2765
2766     # we're applying this unconditionally as the middleware itself already makes
2767     # sure it doesn't fuck things up if it's not running under one of the right
2768     # IIS versions
2769     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2770
2771     return $psgi_app;
2772 }
2773
2774 =head2 $c->psgi_app
2775
2776 Returns a PSGI application code reference for the catalyst application
2777 C<$c>. This is the bare application without any middlewares
2778 applied. C<${myapp}.psgi> is not taken into account.
2779
2780 This is what you want to be using to retrieve the PSGI application code
2781 reference of your Catalyst application for use in F<.psgi> files.
2782
2783 =cut
2784
2785 sub psgi_app {
2786     my ($app) = @_;
2787     return $app->engine->build_psgi_app($app);
2788 }
2789
2790 =head2 $c->setup_home
2791
2792 Sets up the home directory.
2793
2794 =cut
2795
2796 sub setup_home {
2797     my ( $class, $home ) = @_;
2798
2799     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2800         $home = $env;
2801     }
2802
2803     $home ||= Catalyst::Utils::home($class);
2804
2805     if ($home) {
2806         #I remember recently being scolded for assigning config values like this
2807         $class->config->{home} ||= $home;
2808         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2809     }
2810 }
2811
2812 =head2 $c->setup_log
2813
2814 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2815 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2816 log to.
2817
2818 This method also installs a C<debug> method that returns a true value into the
2819 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2820 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2821
2822 Note that if the log has already been setup, by either a previous call to
2823 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2824 that this method won't actually set up the log object.
2825
2826 =cut
2827
2828 sub setup_log {
2829     my ( $class, $levels ) = @_;
2830
2831     $levels ||= '';
2832     $levels =~ s/^\s+//;
2833     $levels =~ s/\s+$//;
2834     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2835
2836     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2837     if ( defined $env_debug ) {
2838         $levels{debug} = 1 if $env_debug; # Ugly!
2839         delete($levels{debug}) unless $env_debug;
2840     }
2841
2842     unless ( $class->log ) {
2843         $class->log( Catalyst::Log->new(keys %levels) );
2844     }
2845
2846     if ( $levels{debug} ) {
2847         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2848         $class->log->debug('Debug messages enabled');
2849     }
2850 }
2851
2852 =head2 $c->setup_plugins
2853
2854 Sets up plugins.
2855
2856 =cut
2857
2858 =head2 $c->setup_stats
2859
2860 Sets up timing statistics class.
2861
2862 =cut
2863
2864 sub setup_stats {
2865     my ( $class, $stats ) = @_;
2866
2867     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2868
2869     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2870     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2871         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2872         $class->log->debug('Statistics enabled');
2873     }
2874 }
2875
2876
2877 =head2 $c->registered_plugins
2878
2879 Returns a sorted list of the plugins which have either been stated in the
2880 import list or which have been added via C<< MyApp->plugin(@args); >>.
2881
2882 If passed a given plugin name, it will report a boolean value indicating
2883 whether or not that plugin is loaded.  A fully qualified name is required if
2884 the plugin name does not begin with C<Catalyst::Plugin::>.
2885
2886  if ($c->registered_plugins('Some::Plugin')) {
2887      ...
2888  }
2889
2890 =cut
2891
2892 {
2893
2894     sub registered_plugins {
2895         my $proto = shift;
2896         return sort keys %{ $proto->_plugins } unless @_;
2897         my $plugin = shift;
2898         return 1 if exists $proto->_plugins->{$plugin};
2899         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2900     }
2901
2902     sub _register_plugin {
2903         my ( $proto, $plugin, $instant ) = @_;
2904         my $class = ref $proto || $proto;
2905
2906         Class::MOP::load_class( $plugin );
2907         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2908             if $plugin->isa( 'Catalyst::Component' );
2909         $proto->_plugins->{$plugin} = 1;
2910         unless ($instant) {
2911             my $meta = Class::MOP::get_metaclass_by_name($class);
2912             $meta->superclasses($plugin, $meta->superclasses);
2913         }
2914         return $class;
2915     }
2916
2917     sub setup_plugins {
2918         my ( $class, $plugins ) = @_;
2919
2920         $class->_plugins( {} ) unless $class->_plugins;
2921         $plugins = Data::OptList::mkopt($plugins || []);
2922
2923         my @plugins = map {
2924             [ Catalyst::Utils::resolve_namespace(
2925                   $class . '::Plugin',
2926                   'Catalyst::Plugin', $_->[0]
2927               ),
2928               $_->[1],
2929             ]
2930          } @{ $plugins };
2931
2932         for my $plugin ( reverse @plugins ) {
2933             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2934             my $meta = find_meta($plugin->[0]);
2935             next if $meta && $meta->isa('Moose::Meta::Role');
2936
2937             $class->_register_plugin($plugin->[0]);
2938         }
2939
2940         my @roles =
2941             map  { $_->[0]->name, $_->[1] }
2942             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2943             map  { [find_meta($_->[0]), $_->[1]] }
2944             @plugins;
2945
2946         Moose::Util::apply_all_roles(
2947             $class => @roles
2948         ) if @roles;
2949     }
2950 }
2951
2952 =head2 $c->stack
2953
2954 Returns an arrayref of the internal execution stack (actions that are
2955 currently executing).
2956
2957 =head2 $c->stats
2958
2959 Returns the current timing statistics object. By default Catalyst uses
2960 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2961 L<< stats_class|/"$c->stats_class" >>.
2962
2963 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2964 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2965 profile explicitly, although MyApp.pm still won't profile nor output anything
2966 by itself.
2967
2968 =head2 $c->stats_class
2969
2970 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2971
2972 =head2 $c->use_stats
2973
2974 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2975
2976 Note that this is a static method, not an accessor and should be overridden
2977 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2978
2979 =cut
2980
2981 sub use_stats { 0 }
2982
2983
2984 =head2 $c->write( $data )
2985
2986 Writes $data to the output stream. When using this method directly, you
2987 will need to manually set the C<Content-Length> header to the length of
2988 your output data, if known.
2989
2990 =cut
2991
2992 sub write {
2993     my $c = shift;
2994
2995     # Finalize headers if someone manually writes output
2996     $c->finalize_headers;
2997
2998     return $c->engine->write( $c, @_ );
2999 }
3000
3001 =head2 version
3002
3003 Returns the Catalyst version number. Mostly useful for "powered by"
3004 messages in template systems.
3005
3006 =cut
3007
3008 sub version { return $Catalyst::VERSION }
3009
3010 =head1 CONFIGURATION
3011
3012 There are a number of 'base' config variables which can be set:
3013
3014 =over
3015
3016 =item *
3017
3018 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3019
3020 =item *
3021
3022 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3023
3024 =item *
3025
3026 C<disable_component_resolution_regex_fallback> - Turns
3027 off the deprecated component resolution functionality so
3028 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3029 are called then regex search will not be attempted on string values and
3030 instead C<undef> will be returned.
3031
3032 =item *
3033
3034 C<home> - The application home directory. In an uninstalled application,
3035 this is the top level application directory. In an installed application,
3036 this will be the directory containing C<< MyApp.pm >>.
3037
3038 =item *
3039
3040 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3041
3042 =item *
3043
3044 C<name> - The name of the application in debug messages and the debug and
3045 welcome screens
3046
3047 =item *
3048
3049 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3050 until it is accessed. This allows you to (for example) check authentication (and reject
3051 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3052
3053 =item *
3054
3055 C<root> - The root directory for templates. Usually this is just a
3056 subdirectory of the home directory, but you can set it to change the
3057 templates to a different directory.
3058
3059 =item *
3060
3061 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3062 namespaces from which components will be loaded (and constructed and stored in
3063 C<< $c->components >>).
3064
3065 =item *
3066
3067 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3068 to be shown in hit debug tables in the test server.
3069
3070 =item *
3071
3072 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
3073 variable should be used for determining the request path.
3074
3075 Most web server environments pass the requested path to the application using environment variables,
3076 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3077 exposed as C<< $c->request->base >>) and the request path below that base.
3078
3079 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3080 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3081
3082 =over
3083
3084 =item use_request_uri_for_path => 0
3085
3086 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3087 The path is synthesised from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3088 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3089 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3090
3091 However this method has the major disadvantage that it is impossible to correctly decode some elements
3092 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3093 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3094 can't distinguish / vs %2F in paths (in addition to other encoded values).
3095
3096 =item use_request_uri_for_path => 1
3097
3098 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3099 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3100 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3101
3102 Given that this method of path resolution is provably more correct, it is recommended that you use
3103 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3104 aware of the implications of not being able to handle encoded URI paths correctly.
3105
3106 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3107 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3108 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3109 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3110 C<< $c->request->base >> will be incorrect.
3111
3112 =back
3113
3114 =item *
3115
3116 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3117
3118 =back
3119
3120 =head1 INTERNAL ACTIONS
3121
3122 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3123 C<_ACTION>, and C<_END>. These are by default not shown in the private
3124 action table, but you can make them visible with a config parameter.
3125
3126     MyApp->config(show_internal_actions => 1);
3127
3128 =head1 ON-DEMAND PARSER
3129
3130 The request body is usually parsed at the beginning of a request,
3131 but if you want to handle input yourself, you can enable on-demand
3132 parsing with a config parameter.
3133
3134     MyApp->config(parse_on_demand => 1);
3135
3136 =head1 PROXY SUPPORT
3137
3138 Many production servers operate using the common double-server approach,
3139 with a lightweight frontend web server passing requests to a larger
3140 backend server. An application running on the backend server must deal
3141 with two problems: the remote user always appears to be C<127.0.0.1> and
3142 the server's hostname will appear to be C<localhost> regardless of the
3143 virtual host that the user connected through.
3144
3145 Catalyst will automatically detect this situation when you are running
3146 the frontend and backend servers on the same machine. The following
3147 changes are made to the request.
3148
3149     $c->req->address is set to the user's real IP address, as read from
3150     the HTTP X-Forwarded-For header.
3151
3152     The host value for $c->req->base and $c->req->uri is set to the real
3153     host, as read from the HTTP X-Forwarded-Host header.
3154
3155 Additionally, you may be running your backend application on an insecure
3156 connection (port 80) while your frontend proxy is running under SSL.  If there
3157 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3158 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3159 be created properly.
3160
3161 In the case of passing in:
3162
3163     X-Forwarded-Port: 443
3164
3165 All calls to C<uri_for> will result in an https link, as is expected.
3166
3167 Obviously, your web server must support these headers for this to work.
3168
3169 In a more complex server farm environment where you may have your
3170 frontend proxy server(s) on different machines, you will need to set a
3171 configuration option to tell Catalyst to read the proxied data from the
3172 headers.
3173
3174     MyApp->config(using_frontend_proxy => 1);
3175
3176 If you do not wish to use the proxy support at all, you may set:
3177
3178     MyApp->config(ignore_frontend_proxy => 1);
3179
3180 =head1 THREAD SAFETY
3181
3182 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3183 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3184 believe the Catalyst core to be thread-safe.
3185
3186 If you plan to operate in a threaded environment, remember that all other
3187 modules you are using must also be thread-safe. Some modules, most notably
3188 L<DBD::SQLite>, are not thread-safe.
3189
3190 =head1 SUPPORT
3191
3192 IRC:
3193
3194     Join #catalyst on irc.perl.org.
3195
3196 Mailing Lists:
3197
3198     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3199     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3200
3201 Web:
3202
3203     http://catalyst.perl.org
3204
3205 Wiki:
3206
3207     http://dev.catalyst.perl.org
3208
3209 =head1 SEE ALSO
3210
3211 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3212
3213 =head2 L<Catalyst::Manual> - The Catalyst Manual
3214
3215 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3216
3217 =head2 L<Catalyst::Engine> - Core engine
3218
3219 =head2 L<Catalyst::Log> - Log class.
3220
3221 =head2 L<Catalyst::Request> - Request object
3222
3223 =head2 L<Catalyst::Response> - Response object
3224
3225 =head2 L<Catalyst::Test> - The test suite.
3226
3227 =begin stopwords
3228
3229 =head1 PROJECT FOUNDER
3230
3231 sri: Sebastian Riedel <sri@cpan.org>
3232
3233 =head1 CONTRIBUTORS
3234
3235 abw: Andy Wardley
3236
3237 acme: Leon Brocard <leon@astray.com>
3238
3239 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3240
3241 Andrew Bramble
3242
3243 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3244
3245 Andrew Ruthven
3246
3247 andyg: Andy Grundman <andy@hybridized.org>
3248
3249 audreyt: Audrey Tang
3250
3251 bricas: Brian Cassidy <bricas@cpan.org>
3252
3253 Caelum: Rafael Kitover <rkitover@io.com>
3254
3255 chansen: Christian Hansen
3256
3257 chicks: Christopher Hicks
3258
3259 Chisel Wright C<pause@herlpacker.co.uk>
3260
3261 Danijel Milicevic C<me@danijel.de>
3262
3263 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3264
3265 David Naughton, C<naughton@umn.edu>
3266
3267 David E. Wheeler
3268
3269 dhoss: Devin Austin <dhoss@cpan.org>
3270
3271 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3272
3273 Drew Taylor
3274
3275 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3276
3277 esskar: Sascha Kiefer
3278
3279 fireartist: Carl Franks <cfranks@cpan.org>
3280
3281 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3282
3283 gabb: Danijel Milicevic
3284
3285 Gary Ashton Jones
3286
3287 Gavin Henry C<ghenry@perl.me.uk>
3288
3289 Geoff Richards
3290
3291 groditi: Guillermo Roditi <groditi@gmail.com>
3292
3293 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3294
3295 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3296
3297 jcamacho: Juan Camacho
3298
3299 jester: Jesse Sheidlower C<jester@panix.com>
3300
3301 jhannah: Jay Hannah <jay@jays.net>
3302
3303 Jody Belka
3304
3305 Johan Lindstrom
3306
3307 jon: Jon Schutz <jjschutz@cpan.org>
3308
3309 Jonathan Rockway C<< <jrockway@cpan.org> >>
3310
3311 Kieren Diment C<kd@totaldatasolution.com>
3312
3313 konobi: Scott McWhirter <konobi@cpan.org>
3314
3315 marcus: Marcus Ramberg <mramberg@cpan.org>
3316
3317 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3318
3319 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3320
3321 mugwump: Sam Vilain
3322
3323 naughton: David Naughton
3324
3325 ningu: David Kamholz <dkamholz@cpan.org>
3326
3327 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3328
3329 numa: Dan Sully <daniel@cpan.org>
3330
3331 obra: Jesse Vincent
3332
3333 Octavian Rasnita
3334
3335 omega: Andreas Marienborg
3336
3337 Oleg Kostyuk <cub.uanic@gmail.com>
3338
3339 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3340
3341 rafl: Florian Ragwitz <rafl@debian.org>
3342
3343 random: Roland Lammel <lammel@cpan.org>
3344
3345 Robert Sedlacek C<< <rs@474.at> >>
3346
3347 SpiceMan: Marcel Montes
3348
3349 sky: Arthur Bergman
3350
3351 szbalint: Balint Szilakszi <szbalint@cpan.org>
3352
3353 t0m: Tomas Doran <bobtfish@bobtfish.net>
3354
3355 Ulf Edvinsson
3356
3357 Viljo Marrandi C<vilts@yahoo.com>
3358
3359 Will Hawes C<info@whawes.co.uk>
3360
3361 willert: Sebastian Willert <willert@cpan.org>
3362
3363 wreis: Wallace Reis <wallace@reis.org.br>
3364
3365 Yuval Kogman, C<nothingmuch@woobling.org>
3366
3367 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3368
3369 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3370
3371 =end stopwords
3372
3373 =head1 COPYRIGHT
3374
3375 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3376
3377 =head1 LICENSE
3378
3379 This library is free software. You can redistribute it and/or modify it under
3380 the same terms as Perl itself.
3381
3382 =cut
3383
3384 no Moose;
3385
3386 __PACKAGE__->meta->make_immutable;
3387
3388 1;