lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/container components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80032';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub _application { $_[0] }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 This sets the log level to 'debug' and enables full debug output on the
 252 error screen. If you only want the latter, see L<< $c->debug >>.
 253
 254 =head2 -Engine
 255
 256 Forces Catalyst to use a specific engine. Omit the
 257 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 258
 259     use Catalyst qw/-Engine=CGI/;
 260
 261 =head2 -Home
 262
 263 Forces Catalyst to use a specific home directory, e.g.:
 264
 265     use Catalyst qw[-Home=/usr/mst];
 266
 267 This can also be done in the shell environment by setting either the
 268 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 269 is replaced with the uppercased name of your application, any "::" in
 270 the name will be replaced with underscores, e.g. MyApp::Web should use
 271 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 272
 273 If none of these are set, Catalyst will attempt to automatically detect the
 274 home directory. If you are working in a development envirnoment, Catalyst
 275 will try and find the directory containing either Makefile.PL, Build.PL or
 276 dist.ini. If the application has been installed into the system (i.e.
 277 you have done C<make install>), then Catalyst will use the path to your
 278 application module, without the .pm extension (ie, /foo/MyApp if your
 279 application was installed at /foo/MyApp.pm)
 280
 281 =head2 -Log
 282
 283     use Catalyst '-Log=warn,fatal,error';
 284
 285 Specifies a comma-delimited list of log levels.
 286
 287 =head2 -Stats
 288
 289 Enables statistics collection and reporting.
 290
 291    use Catalyst qw/-Stats=1/;
 292
 293 You can also force this setting from the system environment with CATALYST_STATS
 294 or <MYAPP>_STATS. The environment settings override the application, with
 295 <MYAPP>_STATS having the highest priority.
 296
 297 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 298
 299 =head1 METHODS
 300
 301 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 302
 303 =head2 $c->action
 304
 305 Returns a L<Catalyst::Action> object for the current action, which
 306 stringifies to the action name. See L<Catalyst::Action>.
 307
 308 =head2 $c->namespace
 309
 310 Returns the namespace of the current action, i.e., the URI prefix
 311 corresponding to the controller of the current action. For example:
 312
 313     # in Controller::Foo::Bar
 314     $c->namespace; # returns 'foo/bar';
 315
 316 =head2 $c->request
 317
 318 =head2 $c->req
 319
 320 Returns the current L<Catalyst::Request> object, giving access to
 321 information about the current client request (including parameters,
 322 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 323
 324 =head2 REQUEST FLOW HANDLING
 325
 326 =head2 $c->forward( $action [, \@arguments ] )
 327
 328 =head2 $c->forward( $class, $method, [, \@arguments ] )
 329
 330 Forwards processing to another action, by its private name. If you give a
 331 class name but no method, C<process()> is called. You may also optionally
 332 pass arguments in an arrayref. The action will receive the arguments in
 333 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 334 C<< $c->req->args >> will be restored to the previous values.
 335
 336 Any data C<return>ed from the action forwarded to, will be returned by the
 337 call to forward.
 338
 339     my $foodata = $c->forward('/foo');
 340     $c->forward('index');
 341     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 342     $c->forward('View::TT');
 343
 344 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 345 an C<< eval { } >> around the call (actually
 346 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 347 all 'dies' within the called action. If you want C<die> to propagate you
 348 need to do something like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 374
 375 =cut
 376
 377 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 378
 379 =head2 $c->detach( $action [, \@arguments ] )
 380
 381 =head2 $c->detach( $class, $method, [, \@arguments ] )
 382
 383 =head2 $c->detach()
 384
 385 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 386 doesn't return to the previous action when processing is finished.
 387
 388 When called with no arguments it escapes the processing chain entirely.
 389
 390 =cut
 391
 392 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 393
 394 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 397
 398 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 399 but does a full dispatch, instead of just calling the new C<$action> /
 400 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 401 you go to are called, just like a new request.
 402
 403 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 404 This means, for example, that C<< $c->action >> methods such as
 405 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 406 L<reverse|Catalyst::Action/reverse> return information for the visited action
 407 when they are invoked within the visited action.  This is different from the
 408 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 409 continues to use the $c->action object from the caller action even when
 410 invoked from the callee.
 411
 412 C<< $c->stash >> is kept unchanged.
 413
 414 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 415 allows you to "wrap" another action, just as it would have been called by
 416 dispatching from a URL, while the analogous
 417 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 418 transfer control to another action as if it had been reached directly from a URL.
 419
 420 =cut
 421
 422 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 423
 424 =head2 $c->go( $action [, \@captures, \@arguments ] )
 425
 426 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 427
 428 The relationship between C<go> and
 429 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 430 the relationship between
 431 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 432 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 433 C<< $c->go >> will perform a full dispatch on the specified action or method,
 434 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 435 C<go> escapes the processing of the current request chain on completion, and
 436 does not return to its caller.
 437
 438 @arguments are arguments to the final destination of $action. @captures are
 439 arguments to the intermediate steps, if any, on the way to the final sub of
 440 $action.
 441
 442 =cut
 443
 444 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 445
 446 =head2 $c->response
 447
 448 =head2 $c->res
 449
 450 Returns the current L<Catalyst::Response> object, see there for details.
 451
 452 =head2 $c->stash
 453
 454 Returns a hashref to the stash, which may be used to store data and pass
 455 it between components during a request. You can also set hash keys by
 456 passing arguments. The stash is automatically sent to the view. The
 457 stash is cleared at the end of a request; it cannot be used for
 458 persistent storage (for this you must use a session; see
 459 L<Catalyst::Plugin::Session> for a complete system integrated with
 460 Catalyst).
 461
 462     $c->stash->{foo} = $bar;
 463     $c->stash( { moose => 'majestic', qux => 0 } );
 464     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 465
 466     # stash is automatically passed to the view for use in a template
 467     $c->forward( 'MyApp::View::TT' );
 468
 469 =cut
 470
 471 around stash => sub {
 472     my $orig = shift;
 473     my $c = shift;
 474     my $stash = $orig->($c);
 475     if (@_) {
 476         my $new_stash = @_ > 1 ? {@_} : $_[0];
 477         croak('stash takes a hash or hashref') unless ref $new_stash;
 478         foreach my $key ( keys %$new_stash ) {
 479           $stash->{$key} = $new_stash->{$key};
 480         }
 481     }
 482
 483     return $stash;
 484 };
 485
 486
 487 =head2 $c->error
 488
 489 =head2 $c->error($error, ...)
 490
 491 =head2 $c->error($arrayref)
 492
 493 Returns an arrayref containing error messages.  If Catalyst encounters an
 494 error while processing a request, it stores the error in $c->error.  This
 495 method should only be used to store fatal error messages.
 496
 497     my @error = @{ $c->error };
 498
 499 Add a new error.
 500
 501     $c->error('Something bad happened');
 502
 503 =cut
 504
 505 sub error {
 506     my $c = shift;
 507     if ( $_[0] ) {
 508         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 509         croak @$error unless ref $c;
 510         push @{ $c->{error} }, @$error;
 511     }
 512     elsif ( defined $_[0] ) { $c->{error} = undef }
 513     return $c->{error} || [];
 514 }
 515
 516
 517 =head2 $c->state
 518
 519 Contains the return value of the last executed action.
 520 Note that << $c->state >> operates in a scalar context which means that all
 521 values it returns are scalar.
 522
 523 =head2 $c->clear_errors
 524
 525 Clear errors.  You probably don't want to clear the errors unless you are
 526 implementing a custom error screen.
 527
 528 This is equivalent to running
 529
 530     $c->error(0);
 531
 532 =cut
 533
 534 sub clear_errors {
 535     my $c = shift;
 536     $c->error(0);
 537 }
 538
 539 sub _comp_search_prefixes {
 540     my $c = shift;
 541     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 542 }
 543
 544 # search components given a name and some prefixes
 545 sub _comp_names_search_prefixes {
 546     my ( $c, $name, @prefixes ) = @_;
 547     my $appclass = ref $c || $c;
 548     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 549     $filter = qr/$filter/; # Compile regex now rather than once per loop
 550
 551     my @components = map { $c->container->get_sub_container($_)->get_service_list } $c->container->get_sub_container_list;
 552
 553     # map the original component name to the sub part that we will search against
 554     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 555         grep { /$filter/ } @components;
 556
 557     # undef for a name will return all
 558     return keys %eligible if !defined $name;
 559
 560     my $query  = ref $name ? $name : qr/^$name$/i;
 561     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 562
 563     return @result if @result;
 564
 565     # if we were given a regexp to search against, we're done.
 566     return if ref $name;
 567
 568     # skip regexp fallback if configured
 569     return
 570         if $appclass->config->{disable_component_resolution_regex_fallback};
 571
 572     # regexp fallback
 573     $query  = qr/$name/i;
 574     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 575
 576     # no results? try against full names
 577     if( !@result ) {
 578         @result = grep { m{$query} } keys %eligible;
 579     }
 580
 581     # don't warn if we didn't find any results, it just might not exist
 582     if( @result ) {
 583         # Disgusting hack to work out correct method name
 584         my $warn_for = lc $prefixes[0];
 585         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 586            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 587            "component resolution is unreliable and unsafe.";
 588         my $short = $result[0];
 589         # remove the component namespace prefix
 590         $short =~ s/.*?(Model|Controller|View):://;
 591         my $shortmess = Carp::shortmess('');
 592         if ($shortmess =~ m#Catalyst/Plugin#) {
 593            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 594               "plugin's config";
 595         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 596            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 597               "component's config";
 598         } else {
 599            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 600               "but if you really wanted to search, pass in a regexp as the argument " .
 601               "like so: \$c->${warn_for}(qr/${name}/)";
 602         }
 603         $c->log->warn( "${msg}$shortmess" );
 604     }
 605
 606     return @result;
 607 }
 608
 609 # Find possible names for a prefix
 610 sub _comp_names {
 611     my ( $c, @prefixes ) = @_;
 612     my $appclass = ref $c || $c;
 613
 614     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 615
 616     my @names = map { s{$filter}{}; $_; }
 617         $c->_comp_names_search_prefixes( undef, @prefixes );
 618
 619     return @names;
 620 }
 621
 622 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 623 sub _filter_component {
 624     my ( $c, $comp, @args ) = @_;
 625
 626     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 627         return $comp->ACCEPT_CONTEXT( $c, @args );
 628     }
 629
 630     return $comp;
 631 }
 632
 633 =head2 COMPONENT ACCESSORS
 634
 635 =head2 $c->controller($name)
 636
 637 Gets a L<Catalyst::Controller> instance by name.
 638
 639     $c->controller('Foo')->do_stuff;
 640
 641 If the name is omitted, will return the controller for the dispatched
 642 action.
 643
 644 If you want to search for controllers, pass in a regexp as the argument.
 645
 646     # find all controllers that start with Foo
 647     my @foo_controllers = $c->controller(qr{^Foo});
 648
 649
 650 =cut
 651
 652 sub controller {
 653     my ( $c, $name, @args ) = @_;
 654
 655     my $appclass = ref($c) || $c;
 656     if( $name ) {
 657         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 658             my $comps = $c->components;
 659             my $check = $appclass."::Controller::".$name;
 660             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 661         }
 662         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 663         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 664         return $c->_filter_component( $result[ 0 ], @args );
 665     }
 666
 667     return $c->component( $c->action->class );
 668 }
 669
 670 =head2 $c->model($name)
 671
 672 Gets a L<Catalyst::Model> instance by name.
 673
 674     $c->model('Foo')->do_stuff;
 675
 676 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 677
 678 If the name is omitted, it will look for
 679  - a model object in $c->stash->{current_model_instance}, then
 680  - a model name in $c->stash->{current_model}, then
 681  - a config setting 'default_model', or
 682  - check if there is only one model, and return it if that's the case.
 683
 684 If you want to search for models, pass in a regexp as the argument.
 685
 686     # find all models that start with Foo
 687     my @foo_models = $c->model(qr{^Foo});
 688
 689 =cut
 690
 691 sub model {
 692     my ( $c, $name, @args ) = @_;
 693     my $appclass = ref($c) || $c;
 694     if( $name ) {
 695         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 696             my $comps = $c->components;
 697             my $check = $appclass."::Model::".$name;
 698             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 699         }
 700         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 701         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 702         return $c->_filter_component( $result[ 0 ], @args );
 703     }
 704
 705     if (ref $c) {
 706         return $c->stash->{current_model_instance}
 707           if $c->stash->{current_model_instance};
 708         return $c->model( $c->stash->{current_model} )
 709           if $c->stash->{current_model};
 710     }
 711     return $c->model( $appclass->config->{default_model} )
 712       if $appclass->config->{default_model};
 713
 714     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 715
 716     if( $rest ) {
 717         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 718         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 719         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 720         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 721         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 722     }
 723
 724     return $c->_filter_component( $comp );
 725 }
 726
 727
 728 =head2 $c->view($name)
 729
 730 Gets a L<Catalyst::View> instance by name.
 731
 732     $c->view('Foo')->do_stuff;
 733
 734 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 735
 736 If the name is omitted, it will look for
 737  - a view object in $c->stash->{current_view_instance}, then
 738  - a view name in $c->stash->{current_view}, then
 739  - a config setting 'default_view', or
 740  - check if there is only one view, and return it if that's the case.
 741
 742 If you want to search for views, pass in a regexp as the argument.
 743
 744     # find all views that start with Foo
 745     my @foo_views = $c->view(qr{^Foo});
 746
 747 =cut
 748
 749 sub view {
 750     my ( $c, $name, @args ) = @_;
 751
 752     my $appclass = ref($c) || $c;
 753     if( $name ) {
 754         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 755             my $comps = $c->components;
 756             my $check = $appclass."::View::".$name;
 757             if( exists $comps->{$check} ) {
 758                 return $c->_filter_component( $comps->{$check}, @args );
 759             }
 760             else {
 761                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 762             }
 763         }
 764         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 765         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 766         return $c->_filter_component( $result[ 0 ], @args );
 767     }
 768
 769     if (ref $c) {
 770         return $c->stash->{current_view_instance}
 771           if $c->stash->{current_view_instance};
 772         return $c->view( $c->stash->{current_view} )
 773           if $c->stash->{current_view};
 774     }
 775     return $c->view( $appclass->config->{default_view} )
 776       if $appclass->config->{default_view};
 777
 778     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 779
 780     if( $rest ) {
 781         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 782         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 783         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 784         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 785         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 786     }
 787
 788     return $c->_filter_component( $comp );
 789 }
 790
 791 =head2 $c->controllers
 792
 793 Returns the available names which can be passed to $c->controller
 794
 795 =cut
 796
 797 sub controllers {
 798     my ( $c ) = @_;
 799     return $c->_comp_names(qw/Controller C/);
 800 }
 801
 802 =head2 $c->models
 803
 804 Returns the available names which can be passed to $c->model
 805
 806 =cut
 807
 808 sub models {
 809     my ( $c ) = @_;
 810     return $c->_comp_names(qw/Model M/);
 811 }
 812
 813
 814 =head2 $c->views
 815
 816 Returns the available names which can be passed to $c->view
 817
 818 =cut
 819
 820 sub views {
 821     my ( $c ) = @_;
 822     return $c->_comp_names(qw/View V/);
 823 }
 824
 825 =head2 $c->comp($name)
 826
 827 =head2 $c->component($name)
 828
 829 Gets a component object by name. This method is not recommended,
 830 unless you want to get a specific component by full
 831 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 832 should be used instead.
 833
 834 If C<$name> is a regexp, a list of components matched against the full
 835 component name will be returned.
 836
 837 If Catalyst can't find a component by name, it will fallback to regex
 838 matching by default. To disable this behaviour set
 839 disable_component_resolution_regex_fallback to a true value.
 840
 841     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 842
 843 =cut
 844
 845 sub component {
 846     my ( $c, $name, @args ) = @_;
 847
 848     if( $name ) {
 849         my $comps = $c->components;
 850
 851         if( !ref $name ) {
 852             # is it the exact name?
 853             return $c->_filter_component( $comps->{ $name }, @args )
 854                        if exists $comps->{ $name };
 855
 856             # perhaps we just omitted "MyApp"?
 857             my $composed = ( ref $c || $c ) . "::${name}";
 858             return $c->_filter_component( $comps->{ $composed }, @args )
 859                        if exists $comps->{ $composed };
 860
 861             # search all of the models, views and controllers
 862             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 863             return $c->_filter_component( $comp, @args ) if $comp;
 864         }
 865
 866         # This is here so $c->comp( '::M::' ) works
 867         my $query = ref $name ? $name : qr{$name}i;
 868
 869         my @result = grep { m{$query} } keys %{ $c->components };
 870         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 871
 872         if( $result[ 0 ] ) {
 873             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 874             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 875             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 876             return $c->_filter_component( $result[ 0 ], @args );
 877         }
 878
 879         # I would expect to return an empty list here, but that breaks back-compat
 880     }
 881
 882     # fallback
 883     return sort keys %{ $c->components };
 884 }
 885
 886 =head2 CLASS DATA AND HELPER CLASSES
 887
 888 =head2 $c->config
 889
 890 Returns or takes a hashref containing the application's configuration.
 891
 892     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 893
 894 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 895 like C<myapp.conf> in your applications home directory. See
 896 L<Catalyst::Plugin::ConfigLoader>.
 897
 898 =head3 Cascading configuration
 899
 900 The config method is present on all Catalyst components, and configuration
 901 will be merged when an application is started. Configuration loaded with
 902 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 903 followed by configuration in your top level C<MyApp> class. These two
 904 configurations are merged, and then configuration data whose hash key matches a
 905 component name is merged with configuration for that component.
 906
 907 The configuration for a component is then passed to the C<new> method when a
 908 component is constructed.
 909
 910 For example:
 911
 912     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 913     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 914
 915 will mean that C<MyApp::Model::Foo> receives the following data when
 916 constructed:
 917
 918     MyApp::Model::Foo->new({
 919         bar => 'baz',
 920         quux => 'frob',
 921         overrides => 'me',
 922     });
 923
 924 It's common practice to use a Moose attribute
 925 on the receiving component to access the config value.
 926
 927     package MyApp::Model::Foo;
 928
 929     use Moose;
 930
 931     # this attr will receive 'baz' at construction time
 932     has 'bar' => (
 933         is  => 'rw',
 934         isa => 'Str',
 935     );
 936
 937 You can then get the value 'baz' by calling $c->model('Foo')->bar
 938 (or $self->bar inside code in the model).
 939
 940 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 941 as a way of reading config within your code, as this B<will not> give you the
 942 correctly merged config back. You B<MUST> take the config values supplied to
 943 the constructor and use those instead.
 944
 945 =cut
 946
 947 around config => sub {
 948     my $orig = shift;
 949     my $c = shift;
 950
 951     croak('Setting config after setup has been run is not allowed.')
 952         if ( @_ and $c->setup_finished );
 953
 954     $c->$orig(@_);
 955 };
 956
 957 =head2 $c->log
 958
 959 Returns the logging object instance. Unless it is already set, Catalyst
 960 sets this up with a L<Catalyst::Log> object. To use your own log class,
 961 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 962 C<< __PACKAGE__->setup >>.
 963
 964  __PACKAGE__->log( MyLogger->new );
 965  __PACKAGE__->setup;
 966
 967 And later:
 968
 969     $c->log->info( 'Now logging with my own logger!' );
 970
 971 Your log class should implement the methods described in
 972 L<Catalyst::Log>.
 973
 974
 975 =head2 $c->debug
 976
 977 Returns 1 if debug mode is enabled, 0 otherwise.
 978
 979 You can enable debug mode in several ways:
 980
 981 =over
 982
 983 =item By calling myapp_server.pl with the -d flag
 984
 985 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 986
 987 =item The -Debug option in your MyApp.pm
 988
 989 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 990
 991 =back
 992
 993 The first three also set the log level to 'debug'.
 994
 995 Calling C<< $c->debug(1) >> has no effect.
 996
 997 =cut
 998
 999 sub debug { 0 }
1000
1001 =head2 $c->dispatcher
1002
1003 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1004
1005 =head2 $c->engine
1006
1007 Returns the engine instance. See L<Catalyst::Engine>.
1008
1009
1010 =head2 UTILITY METHODS
1011
1012 =head2 $c->path_to(@path)
1013
1014 Merges C<@path> with C<< $c->config->{home} >> and returns a
1015 L<Path::Class::Dir> object. Note you can usually use this object as
1016 a filename, but sometimes you will have to explicitly stringify it
1017 yourself by calling the C<< ->stringify >> method.
1018
1019 For example:
1020
1021     $c->path_to( 'db', 'sqlite.db' );
1022
1023 =cut
1024
1025 sub path_to {
1026     my ( $c, @path ) = @_;
1027     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1028     if ( -d $path ) { return $path }
1029     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1030 }
1031
1032 =head2 $c->plugin( $name, $class, @args )
1033
1034 Helper method for plugins. It creates a class data accessor/mutator and
1035 loads and instantiates the given class.
1036
1037     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1038
1039     $c->prototype->define_javascript_functions;
1040
1041 B<Note:> This method of adding plugins is deprecated. The ability
1042 to add plugins like this B<will be removed> in a Catalyst 5.81.
1043 Please do not use this functionality in new code.
1044
1045 =cut
1046
1047 sub plugin {
1048     my ( $class, $name, $plugin, @args ) = @_;
1049
1050     # See block comment in t/unit_core_plugin.t
1051     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1052
1053     $class->_register_plugin( $plugin, 1 );
1054
1055     eval { $plugin->import };
1056     $class->mk_classdata($name);
1057     my $obj;
1058     eval { $obj = $plugin->new(@args) };
1059
1060     if ($@) {
1061         Catalyst::Exception->throw( message =>
1062               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1063     }
1064
1065     $class->$name($obj);
1066     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1067       if $class->debug;
1068 }
1069
1070 =head2 MyApp->setup
1071
1072 Initializes the dispatcher and engine, loads any plugins, and loads the
1073 model, view, and controller components. You may also specify an array
1074 of plugins to load here, if you choose to not load them in the C<use
1075 Catalyst> line.
1076
1077     MyApp->setup;
1078     MyApp->setup( qw/-Debug/ );
1079
1080 =cut
1081
1082 sub setup {
1083     my ( $class, @arguments ) = @_;
1084     croak('Running setup more than once')
1085         if ( $class->setup_finished );
1086
1087     unless ( $class->isa('Catalyst') ) {
1088
1089         Catalyst::Exception->throw(
1090             message => qq/'$class' does not inherit from Catalyst/ );
1091     }
1092
1093     if ( $class->arguments ) {
1094         @arguments = ( @arguments, @{ $class->arguments } );
1095     }
1096
1097     # Process options
1098     my $flags = {};
1099
1100     foreach (@arguments) {
1101
1102         if (/^-Debug$/) {
1103             $flags->{log} =
1104               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1105         }
1106         elsif (/^-(\w+)=?(.*)$/) {
1107             $flags->{ lc $1 } = $2;
1108         }
1109         else {
1110             push @{ $flags->{plugins} }, $_;
1111         }
1112     }
1113
1114     $class->setup_config();
1115     $class->setup_home( delete $flags->{home} );
1116
1117     $class->setup_log( delete $flags->{log} );
1118     $class->setup_plugins( delete $flags->{plugins} );
1119     $class->setup_dispatcher( delete $flags->{dispatcher} );
1120     $class->setup_engine( delete $flags->{engine} );
1121     $class->setup_stats( delete $flags->{stats} );
1122
1123     for my $flag ( sort keys %{$flags} ) {
1124
1125         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1126             &$code( $class, delete $flags->{$flag} );
1127         }
1128         else {
1129             $class->log->warn(qq/Unknown flag "$flag"/);
1130         }
1131     }
1132
1133     eval { require Catalyst::Devel; };
1134     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1135         $class->log->warn(<<"EOF");
1136 You are running an old script!
1137
1138   Please update by running (this will overwrite existing files):
1139     catalyst.pl -force -scripts $class
1140
1141   or (this will not overwrite existing files):
1142     catalyst.pl -scripts $class
1143
1144 EOF
1145     }
1146
1147     if ( $class->debug ) {
1148         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1149
1150         if (@plugins) {
1151             my $column_width = Catalyst::Utils::term_width() - 6;
1152             my $t = Text::SimpleTable->new($column_width);
1153             $t->row($_) for @plugins;
1154             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1155         }
1156
1157         my $dispatcher = $class->dispatcher;
1158         my $engine     = $class->engine;
1159         my $home       = $class->config->{home};
1160
1161         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1162         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1163
1164         $home
1165           ? ( -d $home )
1166           ? $class->log->debug(qq/Found home "$home"/)
1167           : $class->log->debug(qq/Home "$home" doesn't exist/)
1168           : $class->log->debug(q/Couldn't find home/);
1169     }
1170
1171     # Call plugins setup, this is stupid and evil.
1172     # Also screws C3 badly on 5.10, hack to avoid.
1173     {
1174         no warnings qw/redefine/;
1175         local *setup = sub { };
1176         $class->setup unless $Catalyst::__AM_RESTARTING;
1177     }
1178
1179     # Initialize our data structure
1180     $class->components( {} );
1181
1182     $class->setup_components;
1183
1184     if ( $class->debug ) {
1185         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1186         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1187         for my $comp ( sort keys %{ $class->components } ) {
1188             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1189             $t->row( $comp, $type );
1190         }
1191         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1192           if ( keys %{ $class->components } );
1193     }
1194
1195     # Add our self to components, since we are also a component
1196     if( $class->isa('Catalyst::Controller') ){
1197       $class->components->{$class} = $class;
1198     }
1199
1200     $class->setup_actions;
1201
1202     if ( $class->debug ) {
1203         my $name = $class->config->{name} || 'Application';
1204         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1205     }
1206
1207     # Make sure that the application class becomes immutable at this point,
1208     B::Hooks::EndOfScope::on_scope_end {
1209         return if $@;
1210         my $meta = Class::MOP::get_metaclass_by_name($class);
1211         if (
1212             $meta->is_immutable
1213             && ! { $meta->immutable_options }->{replace_constructor}
1214             && (
1215                    $class->isa('Class::Accessor::Fast')
1216                 || $class->isa('Class::Accessor')
1217             )
1218         ) {
1219             warn "You made your application class ($class) immutable, "
1220                 . "but did not inline the\nconstructor. "
1221                 . "This will break catalyst, as your app \@ISA "
1222                 . "Class::Accessor(::Fast)?\nPlease pass "
1223                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1224         }
1225         $meta->make_immutable(
1226             replace_constructor => 1,
1227         ) unless $meta->is_immutable;
1228     };
1229
1230     if ($class->config->{case_sensitive}) {
1231         $class->log->warn($class . "->config->{case_sensitive} is set.");
1232         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1233     }
1234
1235     $class->setup_finalize;
1236     # Should be the last thing we do so that user things hooking
1237     # setup_finalize can log..
1238     $class->log->_flush() if $class->log->can('_flush');
1239     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1240 }
1241
1242 =head2 $app->setup_finalize
1243
1244 A hook to attach modifiers to. This method does not do anything except set the
1245 C<setup_finished> accessor.
1246
1247 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1248
1249 Example:
1250
1251     after setup_finalize => sub {
1252         my $app = shift;
1253
1254         ## do stuff here..
1255     };
1256
1257 =cut
1258
1259 sub setup_finalize {
1260     my ($class) = @_;
1261     $class->setup_finished(1);
1262 }
1263
1264 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1265
1266 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1267
1268 Constructs an absolute L<URI> object based on the application root, the
1269 provided path, and the additional arguments and query parameters provided.
1270 When used as a string, provides a textual URI.  If you need more flexibility
1271 than this (i.e. the option to provide relative URIs etc.) see
1272 L<Catalyst::Plugin::SmartURI>.
1273
1274 If no arguments are provided, the URI for the current action is returned.
1275 To return the current action and also provide @args, use
1276 C<< $c->uri_for( $c->action, @args ) >>.
1277
1278 If the first argument is a string, it is taken as a public URI path relative
1279 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1280 relative to the application root (if it does). It is then merged with
1281 C<< $c->request->base >>; any C<@args> are appended as additional path
1282 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1283
1284 If the first argument is a L<Catalyst::Action> it represents an action which
1285 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1286 optional C<\@captures> argument (an arrayref) allows passing the captured
1287 variables that are needed to fill in the paths of Chained and Regex actions;
1288 once the path is resolved, C<uri_for> continues as though a path was
1289 provided, appending any arguments or parameters and creating an absolute
1290 URI.
1291
1292 The captures for the current request can be found in
1293 C<< $c->request->captures >>, and actions can be resolved using
1294 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1295 path, use C<< $c->uri_for_action >> instead.
1296
1297   # Equivalent to $c->req->uri
1298   $c->uri_for($c->action, $c->req->captures,
1299       @{ $c->req->args }, $c->req->params);
1300
1301   # For the Foo action in the Bar controller
1302   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1303
1304   # Path to a static resource
1305   $c->uri_for('/static/images/logo.png');
1306
1307 =cut
1308
1309 sub uri_for {
1310     my ( $c, $path, @args ) = @_;
1311
1312     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1313         $path = $path->path_prefix;
1314         $path =~ s{/+\z}{};
1315         $path .= '/';
1316     }
1317
1318     undef($path) if (defined $path && $path eq '');
1319
1320     my $params =
1321       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1322
1323     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1324     foreach my $arg (@args) {
1325         utf8::encode($arg) if utf8::is_utf8($arg);
1326         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1327     }
1328
1329     if ( blessed($path) ) { # action object
1330         s|/|%2F|g for @args;
1331         my $captures = [ map { s|/|%2F|g; $_; }
1332                         ( scalar @args && ref $args[0] eq 'ARRAY'
1333                          ? @{ shift(@args) }
1334                          : ()) ];
1335
1336         foreach my $capture (@$captures) {
1337             utf8::encode($capture) if utf8::is_utf8($capture);
1338             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1339         }
1340
1341         my $action = $path;
1342         $path = $c->dispatcher->uri_for_action($action, $captures);
1343         if (not defined $path) {
1344             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1345                 if $c->debug;
1346             return undef;
1347         }
1348         $path = '/' if $path eq '';
1349     }
1350
1351     unshift(@args, $path);
1352
1353     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1354         my $namespace = $c->namespace;
1355         if (defined $path) { # cheesy hack to handle path '../foo'
1356            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1357         }
1358         unshift(@args, $namespace || '');
1359     }
1360
1361     # join args with '/', or a blank string
1362     my $args = join('/', grep { defined($_) } @args);
1363     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1364     $args =~ s!^/+!!;
1365     my $base = $c->req->base;
1366     my $class = ref($base);
1367     $base =~ s{(?<!/)$}{/};
1368
1369     my $query = '';
1370
1371     if (my @keys = keys %$params) {
1372       # somewhat lifted from URI::_query's query_form
1373       $query = '?'.join('&', map {
1374           my $val = $params->{$_};
1375           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1376           s/ /+/g;
1377           my $key = $_;
1378           $val = '' unless defined $val;
1379           (map {
1380               my $param = "$_";
1381               utf8::encode( $param ) if utf8::is_utf8($param);
1382               # using the URI::Escape pattern here so utf8 chars survive
1383               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1384               $param =~ s/ /+/g;
1385               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1386       } @keys);
1387     }
1388
1389     my $res = bless(\"${base}${args}${query}", $class);
1390     $res;
1391 }
1392
1393 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1394
1395 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1396
1397 =over
1398
1399 =item $path
1400
1401 A private path to the Catalyst action you want to create a URI for.
1402
1403 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1404 >> and passing the resulting C<$action> and the remaining arguments to C<<
1405 $c->uri_for >>.
1406
1407 You can also pass in a Catalyst::Action object, in which case it is passed to
1408 C<< $c->uri_for >>.
1409
1410 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1411
1412 For example, if the action looks like:
1413
1414  package MyApp::Controller::Users;
1415
1416  sub lst : Path('the-list') {}
1417
1418 You can use:
1419
1420  $c->uri_for_action('/users/lst')
1421
1422 and it will create the URI /users/the-list.
1423
1424 =back
1425
1426 =cut
1427
1428 sub uri_for_action {
1429     my ( $c, $path, @args ) = @_;
1430     my $action = blessed($path)
1431       ? $path
1432       : $c->dispatcher->get_action_by_path($path);
1433     unless (defined $action) {
1434       croak "Can't find action for path '$path'";
1435     }
1436     return $c->uri_for( $action, @args );
1437 }
1438
1439 =head2 $c->welcome_message
1440
1441 Returns the Catalyst welcome HTML page.
1442
1443 =cut
1444
1445 sub welcome_message {
1446     my $c      = shift;
1447     my $name   = $c->config->{name};
1448     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1449     my $prefix = Catalyst::Utils::appprefix( ref $c );
1450     $c->response->content_type('text/html; charset=utf-8');
1451     return <<"EOF";
1452 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1453     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1454 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1455     <head>
1456     <meta http-equiv="Content-Language" content="en" />
1457     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1458         <title>$name on Catalyst $VERSION</title>
1459         <style type="text/css">
1460             body {
1461                 color: #000;
1462                 background-color: #eee;
1463             }
1464             div#content {
1465                 width: 640px;
1466                 margin-left: auto;
1467                 margin-right: auto;
1468                 margin-top: 10px;
1469                 margin-bottom: 10px;
1470                 text-align: left;
1471                 background-color: #ccc;
1472                 border: 1px solid #aaa;
1473             }
1474             p, h1, h2 {
1475                 margin-left: 20px;
1476                 margin-right: 20px;
1477                 font-family: verdana, tahoma, sans-serif;
1478             }
1479             a {
1480                 font-family: verdana, tahoma, sans-serif;
1481             }
1482             :link, :visited {
1483                     text-decoration: none;
1484                     color: #b00;
1485                     border-bottom: 1px dotted #bbb;
1486             }
1487             :link:hover, :visited:hover {
1488                     color: #555;
1489             }
1490             div#topbar {
1491                 margin: 0px;
1492             }
1493             pre {
1494                 margin: 10px;
1495                 padding: 8px;
1496             }
1497             div#answers {
1498                 padding: 8px;
1499                 margin: 10px;
1500                 background-color: #fff;
1501                 border: 1px solid #aaa;
1502             }
1503             h1 {
1504                 font-size: 0.9em;
1505                 font-weight: normal;
1506                 text-align: center;
1507             }
1508             h2 {
1509                 font-size: 1.0em;
1510             }
1511             p {
1512                 font-size: 0.9em;
1513             }
1514             p img {
1515                 float: right;
1516                 margin-left: 10px;
1517             }
1518             span#appname {
1519                 font-weight: bold;
1520                 font-size: 1.6em;
1521             }
1522         </style>
1523     </head>
1524     <body>
1525         <div id="content">
1526             <div id="topbar">
1527                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1528                     $VERSION</h1>
1529              </div>
1530              <div id="answers">
1531                  <p>
1532                  <img src="$logo" alt="Catalyst Logo" />
1533                  </p>
1534                  <p>Welcome to the  world of Catalyst.
1535                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1536                     framework will make web development something you had
1537                     never expected it to be: Fun, rewarding, and quick.</p>
1538                  <h2>What to do now?</h2>
1539                  <p>That really depends  on what <b>you</b> want to do.
1540                     We do, however, provide you with a few starting points.</p>
1541                  <p>If you want to jump right into web development with Catalyst
1542                     you might want to start with a tutorial.</p>
1543 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1544 </pre>
1545 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1546 <pre>
1547 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1548 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1549 </code></pre>
1550                  <h2>What to do next?</h2>
1551                  <p>Next it's time to write an actual application. Use the
1552                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1553                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1554                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1555                     they can save you a lot of work.</p>
1556                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1557                     <p>Also, be sure to check out the vast and growing
1558                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1559                     you are likely to find what you need there.
1560                     </p>
1561
1562                  <h2>Need help?</h2>
1563                  <p>Catalyst has a very active community. Here are the main places to
1564                     get in touch with us.</p>
1565                  <ul>
1566                      <li>
1567                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1568                      </li>
1569                      <li>
1570                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1571                      </li>
1572                      <li>
1573                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1574                      </li>
1575                  </ul>
1576                  <h2>In conclusion</h2>
1577                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1578                     as we enjoyed making it. Please contact us if you have ideas
1579                     for improvement or other feedback.</p>
1580              </div>
1581          </div>
1582     </body>
1583 </html>
1584 EOF
1585 }
1586
1587 =head1 INTERNAL METHODS
1588
1589 These methods are not meant to be used by end users.
1590
1591 =head2 $c->components
1592
1593 Returns a hash of components.
1594
1595 =head2 $c->context_class
1596
1597 Returns or sets the context class.
1598
1599 =head2 $c->counter
1600
1601 Returns a hashref containing coderefs and execution counts (needed for
1602 deep recursion detection).
1603
1604 =head2 $c->depth
1605
1606 Returns the number of actions on the current internal execution stack.
1607
1608 =head2 $c->dispatch
1609
1610 Dispatches a request to actions.
1611
1612 =cut
1613
1614 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1615
1616 =head2 $c->dispatcher_class
1617
1618 Returns or sets the dispatcher class.
1619
1620 =head2 $c->dump_these
1621
1622 Returns a list of 2-element array references (name, structure) pairs
1623 that will be dumped on the error page in debug mode.
1624
1625 =cut
1626
1627 sub dump_these {
1628     my $c = shift;
1629     [ Request => $c->req ],
1630     [ Response => $c->res ],
1631     [ Stash => $c->stash ],
1632     [ Config => $c->config ];
1633 }
1634
1635 =head2 $c->engine_class
1636
1637 Returns or sets the engine class.
1638
1639 =head2 $c->execute( $class, $coderef )
1640
1641 Execute a coderef in given class and catch exceptions. Errors are available
1642 via $c->error.
1643
1644 =cut
1645
1646 sub execute {
1647     my ( $c, $class, $code ) = @_;
1648     $class = $c->component($class) || $class;
1649     $c->state(0);
1650
1651     if ( $c->depth >= $RECURSION ) {
1652         my $action = $code->reverse();
1653         $action = "/$action" unless $action =~ /->/;
1654         my $error = qq/Deep recursion detected calling "${action}"/;
1655         $c->log->error($error);
1656         $c->error($error);
1657         $c->state(0);
1658         return $c->state;
1659     }
1660
1661     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1662
1663     push( @{ $c->stack }, $code );
1664
1665     no warnings 'recursion';
1666     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1667     #      I have no idea how, ergo $ret (which appears to fix the issue)
1668     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1669
1670     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1671
1672     my $last = pop( @{ $c->stack } );
1673
1674     if ( my $error = $@ ) {
1675         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1676             $error->rethrow if $c->depth > 1;
1677         }
1678         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1679             $error->rethrow if $c->depth > 0;
1680         }
1681         else {
1682             unless ( ref $error ) {
1683                 no warnings 'uninitialized';
1684                 chomp $error;
1685                 my $class = $last->class;
1686                 my $name  = $last->name;
1687                 $error = qq/Caught exception in $class->$name "$error"/;
1688             }
1689             $c->error($error);
1690         }
1691         $c->state(0);
1692     }
1693     return $c->state;
1694 }
1695
1696 sub _stats_start_execute {
1697     my ( $c, $code ) = @_;
1698     my $appclass = ref($c) || $c;
1699     return if ( ( $code->name =~ /^_.*/ )
1700         && ( !$appclass->config->{show_internal_actions} ) );
1701
1702     my $action_name = $code->reverse();
1703     $c->counter->{$action_name}++;
1704
1705     my $action = $action_name;
1706     $action = "/$action" unless $action =~ /->/;
1707
1708     # determine if the call was the result of a forward
1709     # this is done by walking up the call stack and looking for a calling
1710     # sub of Catalyst::forward before the eval
1711     my $callsub = q{};
1712     for my $index ( 2 .. 11 ) {
1713         last
1714         if ( ( caller($index) )[0] eq 'Catalyst'
1715             && ( caller($index) )[3] eq '(eval)' );
1716
1717         if ( ( caller($index) )[3] =~ /forward$/ ) {
1718             $callsub = ( caller($index) )[3];
1719             $action  = "-> $action";
1720             last;
1721         }
1722     }
1723
1724     my $uid = $action_name . $c->counter->{$action_name};
1725
1726     # is this a root-level call or a forwarded call?
1727     if ( $callsub =~ /forward$/ ) {
1728         my $parent = $c->stack->[-1];
1729
1730         # forward, locate the caller
1731         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1732             $c->stats->profile(
1733                 begin  => $action,
1734                 parent => "$parent" . $c->counter->{"$parent"},
1735                 uid    => $uid,
1736             );
1737         }
1738         else {
1739
1740             # forward with no caller may come from a plugin
1741             $c->stats->profile(
1742                 begin => $action,
1743                 uid   => $uid,
1744             );
1745         }
1746     }
1747     else {
1748
1749         # root-level call
1750         $c->stats->profile(
1751             begin => $action,
1752             uid   => $uid,
1753         );
1754     }
1755     return $action;
1756
1757 }
1758
1759 sub _stats_finish_execute {
1760     my ( $c, $info ) = @_;
1761     $c->stats->profile( end => $info );
1762 }
1763
1764 =head2 $c->finalize
1765
1766 Finalizes the request.
1767
1768 =cut
1769
1770 sub finalize {
1771     my $c = shift;
1772
1773     for my $error ( @{ $c->error } ) {
1774         $c->log->error($error);
1775     }
1776
1777     # Allow engine to handle finalize flow (for POE)
1778     my $engine = $c->engine;
1779     if ( my $code = $engine->can('finalize') ) {
1780         $engine->$code($c);
1781     }
1782     else {
1783
1784         $c->finalize_uploads;
1785
1786         # Error
1787         if ( $#{ $c->error } >= 0 ) {
1788             $c->finalize_error;
1789         }
1790
1791         $c->finalize_headers;
1792
1793         # HEAD request
1794         if ( $c->request->method eq 'HEAD' ) {
1795             $c->response->body('');
1796         }
1797
1798         $c->finalize_body;
1799     }
1800
1801     $c->log_response;
1802
1803     if ($c->use_stats) {
1804         my $elapsed = sprintf '%f', $c->stats->elapsed;
1805         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1806         $c->log->info(
1807             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1808     }
1809
1810     return $c->response->status;
1811 }
1812
1813 =head2 $c->finalize_body
1814
1815 Finalizes body.
1816
1817 =cut
1818
1819 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1820
1821 =head2 $c->finalize_cookies
1822
1823 Finalizes cookies.
1824
1825 =cut
1826
1827 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1828
1829 =head2 $c->finalize_error
1830
1831 Finalizes error.
1832
1833 =cut
1834
1835 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1836
1837 =head2 $c->finalize_headers
1838
1839 Finalizes headers.
1840
1841 =cut
1842
1843 sub finalize_headers {
1844     my $c = shift;
1845
1846     my $response = $c->response; #accessor calls can add up?
1847
1848     # Check if we already finalized headers
1849     return if $response->finalized_headers;
1850
1851     # Handle redirects
1852     if ( my $location = $response->redirect ) {
1853         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1854         $response->header( Location => $location );
1855
1856         if ( !$response->has_body ) {
1857             # Add a default body if none is already present
1858             $response->body(
1859                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1860             );
1861         }
1862     }
1863
1864     # Content-Length
1865     if ( defined $response->body && length $response->body && !$response->content_length ) {
1866
1867         # get the length from a filehandle
1868         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1869         {
1870             my $stat = stat $response->body;
1871             if ( $stat && $stat->size > 0 ) {
1872                 $response->content_length( $stat->size );
1873             }
1874             else {
1875                 $c->log->warn('Serving filehandle without a content-length');
1876             }
1877         }
1878         else {
1879             # everything should be bytes at this point, but just in case
1880             $response->content_length( length( $response->body ) );
1881         }
1882     }
1883
1884     # Errors
1885     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1886         $response->headers->remove_header("Content-Length");
1887         $response->body('');
1888     }
1889
1890     $c->finalize_cookies;
1891
1892     $c->engine->finalize_headers( $c, @_ );
1893
1894     # Done
1895     $response->finalized_headers(1);
1896 }
1897
1898 =head2 $c->finalize_output
1899
1900 An alias for finalize_body.
1901
1902 =head2 $c->finalize_read
1903
1904 Finalizes the input after reading is complete.
1905
1906 =cut
1907
1908 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1909
1910 =head2 $c->finalize_uploads
1911
1912 Finalizes uploads. Cleans up any temporary files.
1913
1914 =cut
1915
1916 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1917
1918 =head2 $c->get_action( $action, $namespace )
1919
1920 Gets an action in a given namespace.
1921
1922 =cut
1923
1924 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1925
1926 =head2 $c->get_actions( $action, $namespace )
1927
1928 Gets all actions of a given name in a namespace and all parent
1929 namespaces.
1930
1931 =cut
1932
1933 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1934
1935 =head2 $app->handle_request( @arguments )
1936
1937 Called to handle each HTTP request.
1938
1939 =cut
1940
1941 sub handle_request {
1942     my ( $class, @arguments ) = @_;
1943
1944     # Always expect worst case!
1945     my $status = -1;
1946     eval {
1947         if ($class->debug) {
1948             my $secs = time - $START || 1;
1949             my $av = sprintf '%.3f', $COUNT / $secs;
1950             my $time = localtime time;
1951             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1952         }
1953
1954         my $c = $class->prepare(@arguments);
1955         $c->dispatch;
1956         $status = $c->finalize;
1957     };
1958
1959     if ( my $error = $@ ) {
1960         chomp $error;
1961         $class->log->error(qq/Caught exception in engine "$error"/);
1962     }
1963
1964     $COUNT++;
1965
1966     if(my $coderef = $class->log->can('_flush')){
1967         $class->log->$coderef();
1968     }
1969     return $status;
1970 }
1971
1972 =head2 $c->prepare( @arguments )
1973
1974 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1975 etc.).
1976
1977 =cut
1978
1979 sub prepare {
1980     my ( $class, @arguments ) = @_;
1981
1982     # XXX
1983     # After the app/ctxt split, this should become an attribute based on something passed
1984     # into the application.
1985     $class->context_class( ref $class || $class ) unless $class->context_class;
1986
1987     my $c = $class->context_class->new({});
1988
1989     # For on-demand data
1990     $c->request->_context($c);
1991     $c->response->_context($c);
1992
1993     #surely this is not the most efficient way to do things...
1994     $c->stats($class->stats_class->new)->enable($c->use_stats);
1995     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1996         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1997     }
1998
1999     #XXX reuse coderef from can
2000     # Allow engine to direct the prepare flow (for POE)
2001     if ( $c->engine->can('prepare') ) {
2002         $c->engine->prepare( $c, @arguments );
2003     }
2004     else {
2005         $c->prepare_request(@arguments);
2006         $c->prepare_connection;
2007         $c->prepare_query_parameters;
2008         $c->prepare_headers;
2009         $c->prepare_cookies;
2010         $c->prepare_path;
2011
2012         # Prepare the body for reading, either by prepare_body
2013         # or the user, if they are using $c->read
2014         $c->prepare_read;
2015
2016         # Parse the body unless the user wants it on-demand
2017         unless ( ref($c)->config->{parse_on_demand} ) {
2018             $c->prepare_body;
2019         }
2020     }
2021
2022     my $method  = $c->req->method  || '';
2023     my $path    = $c->req->path;
2024     $path       = '/' unless length $path;
2025     my $address = $c->req->address || '';
2026
2027     $c->log_request;
2028
2029     $c->prepare_action;
2030
2031     return $c;
2032 }
2033
2034 =head2 $c->prepare_action
2035
2036 Prepares action. See L<Catalyst::Dispatcher>.
2037
2038 =cut
2039
2040 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2041
2042 =head2 $c->prepare_body
2043
2044 Prepares message body.
2045
2046 =cut
2047
2048 sub prepare_body {
2049     my $c = shift;
2050
2051     return if $c->request->_has_body;
2052
2053     # Initialize on-demand data
2054     $c->engine->prepare_body( $c, @_ );
2055     $c->prepare_parameters;
2056     $c->prepare_uploads;
2057 }
2058
2059 =head2 $c->prepare_body_chunk( $chunk )
2060
2061 Prepares a chunk of data before sending it to L<HTTP::Body>.
2062
2063 See L<Catalyst::Engine>.
2064
2065 =cut
2066
2067 sub prepare_body_chunk {
2068     my $c = shift;
2069     $c->engine->prepare_body_chunk( $c, @_ );
2070 }
2071
2072 =head2 $c->prepare_body_parameters
2073
2074 Prepares body parameters.
2075
2076 =cut
2077
2078 sub prepare_body_parameters {
2079     my $c = shift;
2080     $c->engine->prepare_body_parameters( $c, @_ );
2081 }
2082
2083 =head2 $c->prepare_connection
2084
2085 Prepares connection.
2086
2087 =cut
2088
2089 sub prepare_connection {
2090     my $c = shift;
2091     $c->engine->prepare_connection( $c, @_ );
2092 }
2093
2094 =head2 $c->prepare_cookies
2095
2096 Prepares cookies.
2097
2098 =cut
2099
2100 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2101
2102 =head2 $c->prepare_headers
2103
2104 Prepares headers.
2105
2106 =cut
2107
2108 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2109
2110 =head2 $c->prepare_parameters
2111
2112 Prepares parameters.
2113
2114 =cut
2115
2116 sub prepare_parameters {
2117     my $c = shift;
2118     $c->prepare_body_parameters;
2119     $c->engine->prepare_parameters( $c, @_ );
2120 }
2121
2122 =head2 $c->prepare_path
2123
2124 Prepares path and base.
2125
2126 =cut
2127
2128 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2129
2130 =head2 $c->prepare_query_parameters
2131
2132 Prepares query parameters.
2133
2134 =cut
2135
2136 sub prepare_query_parameters {
2137     my $c = shift;
2138
2139     $c->engine->prepare_query_parameters( $c, @_ );
2140 }
2141
2142 =head2 $c->log_request
2143
2144 Writes information about the request to the debug logs.  This includes:
2145
2146 =over 4
2147
2148 =item * Request method, path, and remote IP address
2149
2150 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2151
2152 =item * Request parameters
2153
2154 =item * File uploads
2155
2156 =back
2157
2158 =cut
2159
2160 sub log_request {
2161     my $c = shift;
2162
2163     return unless $c->debug;
2164
2165     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2166     my $request = $dump->[1];
2167
2168     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2169     $method ||= '';
2170     $path = '/' unless length $path;
2171     $address ||= '';
2172     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2173
2174     $c->log_request_headers($request->headers);
2175
2176     if ( my $keywords = $request->query_keywords ) {
2177         $c->log->debug("Query keywords are: $keywords");
2178     }
2179
2180     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2181
2182     $c->log_request_uploads($request);
2183 }
2184
2185 =head2 $c->log_response
2186
2187 Writes information about the response to the debug logs by calling
2188 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2189
2190 =cut
2191
2192 sub log_response {
2193     my $c = shift;
2194
2195     return unless $c->debug;
2196
2197     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2198     my $response = $dump->[1];
2199
2200     $c->log_response_status_line($response);
2201     $c->log_response_headers($response->headers);
2202 }
2203
2204 =head2 $c->log_response_status_line($response)
2205
2206 Writes one line of information about the response to the debug logs.  This includes:
2207
2208 =over 4
2209
2210 =item * Response status code
2211
2212 =item * Content-Type header (if present)
2213
2214 =item * Content-Length header (if present)
2215
2216 =back
2217
2218 =cut
2219
2220 sub log_response_status_line {
2221     my ($c, $response) = @_;
2222
2223     $c->log->debug(
2224         sprintf(
2225             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2226             $response->status                            || 'unknown',
2227             $response->headers->header('Content-Type')   || 'unknown',
2228             $response->headers->header('Content-Length') || 'unknown'
2229         )
2230     );
2231 }
2232
2233 =head2 $c->log_response_headers($headers);
2234
2235 Hook method which can be wrapped by plugins to log the responseheaders.
2236 No-op in the default implementation.
2237
2238 =cut
2239
2240 sub log_response_headers {}
2241
2242 =head2 $c->log_request_parameters( query => {}, body => {} )
2243
2244 Logs request parameters to debug logs
2245
2246 =cut
2247
2248 sub log_request_parameters {
2249     my $c          = shift;
2250     my %all_params = @_;
2251
2252     return unless $c->debug;
2253
2254     my $column_width = Catalyst::Utils::term_width() - 44;
2255     foreach my $type (qw(query body)) {
2256         my $params = $all_params{$type};
2257         next if ! keys %$params;
2258         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2259         for my $key ( sort keys %$params ) {
2260             my $param = $params->{$key};
2261             my $value = defined($param) ? $param : '';
2262             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2263         }
2264         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2265     }
2266 }
2267
2268 =head2 $c->log_request_uploads
2269
2270 Logs file uploads included in the request to the debug logs.
2271 The parameter name, filename, file type, and file size are all included in
2272 the debug logs.
2273
2274 =cut
2275
2276 sub log_request_uploads {
2277     my $c = shift;
2278     my $request = shift;
2279     return unless $c->debug;
2280     my $uploads = $request->uploads;
2281     if ( keys %$uploads ) {
2282         my $t = Text::SimpleTable->new(
2283             [ 12, 'Parameter' ],
2284             [ 26, 'Filename' ],
2285             [ 18, 'Type' ],
2286             [ 9,  'Size' ]
2287         );
2288         for my $key ( sort keys %$uploads ) {
2289             my $upload = $uploads->{$key};
2290             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2291                 $t->row( $key, $u->filename, $u->type, $u->size );
2292             }
2293         }
2294         $c->log->debug( "File Uploads are:\n" . $t->draw );
2295     }
2296 }
2297
2298 =head2 $c->log_request_headers($headers);
2299
2300 Hook method which can be wrapped by plugins to log the request headers.
2301 No-op in the default implementation.
2302
2303 =cut
2304
2305 sub log_request_headers {}
2306
2307 =head2 $c->log_headers($type => $headers)
2308
2309 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2310
2311 =cut
2312
2313 sub log_headers {
2314     my $c       = shift;
2315     my $type    = shift;
2316     my $headers = shift;    # an HTTP::Headers instance
2317
2318     return unless $c->debug;
2319
2320     my $column_width = Catalyst::Utils::term_width() - 28;
2321     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2322     $headers->scan(
2323         sub {
2324             my ( $name, $value ) = @_;
2325             $t->row( $name, $value );
2326         }
2327     );
2328     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2329 }
2330
2331
2332 =head2 $c->prepare_read
2333
2334 Prepares the input for reading.
2335
2336 =cut
2337
2338 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2339
2340 =head2 $c->prepare_request
2341
2342 Prepares the engine request.
2343
2344 =cut
2345
2346 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2347
2348 =head2 $c->prepare_uploads
2349
2350 Prepares uploads.
2351
2352 =cut
2353
2354 sub prepare_uploads {
2355     my $c = shift;
2356
2357     $c->engine->prepare_uploads( $c, @_ );
2358 }
2359
2360 =head2 $c->prepare_write
2361
2362 Prepares the output for writing.
2363
2364 =cut
2365
2366 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2367
2368 =head2 $c->request_class
2369
2370 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2371
2372 =head2 $c->response_class
2373
2374 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2375
2376 =head2 $c->read( [$maxlength] )
2377
2378 Reads a chunk of data from the request body. This method is designed to
2379 be used in a while loop, reading C<$maxlength> bytes on every call.
2380 C<$maxlength> defaults to the size of the request if not specified.
2381
2382 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2383 directly.
2384
2385 Warning: If you use read(), Catalyst will not process the body,
2386 so you will not be able to access POST parameters or file uploads via
2387 $c->request.  You must handle all body parsing yourself.
2388
2389 =cut
2390
2391 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2392
2393 =head2 $c->run
2394
2395 Starts the engine.
2396
2397 =cut
2398
2399 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2400
2401 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2402
2403 Sets an action in a given namespace.
2404
2405 =cut
2406
2407 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2408
2409 =head2 $c->setup_actions($component)
2410
2411 Sets up actions for a component.
2412
2413 =cut
2414
2415 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2416
2417 =head2 $c->setup_config
2418
2419 =cut
2420
2421 sub setup_config {
2422     my $class = shift;
2423
2424     my %args = %{$class->config || {} };
2425     my @container_classes = qw/MyApp::Container Catalyst::Container/;
2426     unshift @container_classes, delete $args{container_class} if exists $args{container_class};
2427
2428     my $container_class = Class::MOP::load_first_existing_class(@container_classes);
2429
2430     my $container = $container_class->new( %args, name => "$class" );
2431
2432     $container->add_sub_container(Bread::Board::Container->new( name => $_ )) for qw(model controller view);
2433     $class->container($container);
2434
2435     my $config = $container->fetch('config')->get;
2436     $class->config($config);
2437     $class->finalize_config; # back-compat
2438 }
2439
2440 =head $c->finalize_config
2441
2442 =cut
2443
2444 sub finalize_config { }
2445
2446 =head2 $c->setup_components
2447
2448 This method is called internally to set up the application's components.
2449
2450 It finds modules by calling the L<locate_components> method, expands them to
2451 package names with the L<expand_component_module> method, and then installs
2452 each component into the application.
2453
2454 The C<setup_components> config option is passed to both of the above methods.
2455
2456 Installation of each component is performed by the L<setup_component> method,
2457 below.
2458
2459 =cut
2460
2461 sub setup_components {
2462     my $class = shift;
2463
2464     my $config  = $class->config->{ setup_components };
2465
2466     my @comps = $class->locate_components($config);
2467     my %comps = map { $_ => 1 } @comps;
2468
2469     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2470     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2471         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2472     ) if $deprecatedcatalyst_component_names;
2473
2474     for my $component ( @comps ) {
2475
2476         # We pass ignore_loaded here so that overlay files for (e.g.)
2477         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2478         # we know M::P::O found a file on disk so this is safe
2479
2480         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2481     }
2482
2483     my $containers;
2484     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
2485
2486     for my $component (@comps) {
2487         my $instance = $class->components->{ $component } = $class->setup_component($component);
2488         my $type = lc((split /::/, $component)[1]);
2489         if ($deprecatedcatalyst_component_names) {
2490             $type = 'controller' if $type eq 'c';
2491             $type = 'model' if $type eq 'm';
2492             $type = 'view' if $type eq 'v';
2493         }
2494         $containers->{$type}->add_service(Bread::Board::BlockInjection->new( name => $component, block => sub { return $instance } ));
2495         my @expanded_components = $instance->can('expand_modules')
2496             ? $instance->expand_modules( $component, $config )
2497             : $class->expand_component_module( $component, $config );
2498         for my $component (@expanded_components) {
2499             next if $comps{$component};
2500
2501             $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @expanded_components;
2502             $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2503                 qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2504             ) if $deprecatedcatalyst_component_names;
2505
2506             if ($deprecatedcatalyst_component_names) {
2507                 $type = lc((split /::/, $component)[1]);
2508                 $type = 'controller' if $type eq 'c';
2509                 $type = 'model' if $type eq 'm';
2510                 $type = 'view' if $type eq 'v';
2511             }
2512             $containers->{$type}->add_service(Bread::Board::BlockInjection->new( name => $component, block => sub { return $class->setup_component($component) } ));
2513             $class->components->{ $component } = $class->setup_component($component);
2514         }
2515     }
2516 }
2517
2518 =head2 $c->locate_components( $setup_component_config )
2519
2520 This method is meant to provide a list of component modules that should be
2521 setup for the application.  By default, it will use L<Module::Pluggable>.
2522
2523 Specify a C<setup_components> config option to pass additional options directly
2524 to L<Module::Pluggable>. To add additional search paths, specify a key named
2525 C<search_extra> as an array reference. Items in the array beginning with C<::>
2526 will have the application class name prepended to them.
2527
2528 =cut
2529
2530 sub locate_components {
2531     my $class  = shift;
2532     my $config = shift;
2533
2534     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2535     my $extra   = delete $config->{ search_extra } || [];
2536
2537     push @paths, @$extra;
2538
2539     my $locator = Module::Pluggable::Object->new(
2540         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2541         %$config
2542     );
2543
2544     # XXX think about ditching this sort entirely
2545     my @comps = sort { length $a <=> length $b } $locator->plugins;
2546
2547     return @comps;
2548 }
2549
2550 =head2 $c->expand_component_module( $component, $setup_component_config )
2551
2552 Components found by C<locate_components> will be passed to this method, which
2553 is expected to return a list of component (package) names to be set up.
2554
2555 =cut
2556
2557 sub expand_component_module {
2558     my ($class, $module) = @_;
2559     return Devel::InnerPackage::list_packages( $module );
2560 }
2561
2562 =head2 $c->setup_component
2563
2564 =cut
2565
2566 sub setup_component {
2567     my( $class, $component ) = @_;
2568
2569     unless ( $component->can( 'COMPONENT' ) ) {
2570         return $component;
2571     }
2572
2573     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2574     my $config = $class->config->{ $suffix } || {};
2575     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2576     # methods also pass it. local to avoid pointlessly shitting in config
2577     # for the debug screen, as $component is already the key name.
2578     local $config->{catalyst_component_name} = $component;
2579
2580     my $instance = eval { $component->COMPONENT( $class, $config ); };
2581
2582     if ( my $error = $@ ) {
2583         chomp $error;
2584         Catalyst::Exception->throw(
2585             message => qq/Couldn't instantiate component "$component", "$error"/
2586         );
2587     }
2588
2589     unless (blessed $instance) {
2590         my $metaclass = Moose::Util::find_meta($component);
2591         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2592         my $component_method_from = $method_meta->associated_metaclass->name;
2593         my $value = defined($instance) ? $instance : 'undef';
2594         Catalyst::Exception->throw(
2595             message =>
2596             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2597         );
2598     }
2599     return $instance;
2600 }
2601
2602 =head2 $c->setup_dispatcher
2603
2604 Sets up dispatcher.
2605
2606 =cut
2607
2608 sub setup_dispatcher {
2609     my ( $class, $dispatcher ) = @_;
2610
2611     if ($dispatcher) {
2612         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2613     }
2614
2615     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2616         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2617     }
2618
2619     unless ($dispatcher) {
2620         $dispatcher = $class->dispatcher_class;
2621     }
2622
2623     Class::MOP::load_class($dispatcher);
2624
2625     # dispatcher instance
2626     $class->dispatcher( $dispatcher->new );
2627 }
2628
2629 =head2 $c->setup_engine
2630
2631 Sets up engine.
2632
2633 =cut
2634
2635 sub setup_engine {
2636     my ( $class, $engine ) = @_;
2637
2638     if ($engine) {
2639         $engine = 'Catalyst::Engine::' . $engine;
2640     }
2641
2642     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2643         $engine = 'Catalyst::Engine::' . $env;
2644     }
2645
2646     if ( $ENV{MOD_PERL} ) {
2647         my $meta = Class::MOP::get_metaclass_by_name($class);
2648
2649         # create the apache method
2650         $meta->add_method('apache' => sub { shift->engine->apache });
2651
2652         my ( $software, $version ) =
2653           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2654
2655         $version =~ s/_//g;
2656         $version =~ s/(\.[^.]+)\./$1/g;
2657
2658         if ( $software eq 'mod_perl' ) {
2659
2660             if ( !$engine ) {
2661
2662                 if ( $version >= 1.99922 ) {
2663                     $engine = 'Catalyst::Engine::Apache2::MP20';
2664                 }
2665
2666                 elsif ( $version >= 1.9901 ) {
2667                     $engine = 'Catalyst::Engine::Apache2::MP19';
2668                 }
2669
2670                 elsif ( $version >= 1.24 ) {
2671                     $engine = 'Catalyst::Engine::Apache::MP13';
2672                 }
2673
2674                 else {
2675                     Catalyst::Exception->throw( message =>
2676                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2677                 }
2678
2679             }
2680
2681             # install the correct mod_perl handler
2682             if ( $version >= 1.9901 ) {
2683                 *handler = sub  : method {
2684                     shift->handle_request(@_);
2685                 };
2686             }
2687             else {
2688                 *handler = sub ($$) { shift->handle_request(@_) };
2689             }
2690
2691         }
2692
2693         elsif ( $software eq 'Zeus-Perl' ) {
2694             $engine = 'Catalyst::Engine::Zeus';
2695         }
2696
2697         else {
2698             Catalyst::Exception->throw(
2699                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2700         }
2701     }
2702
2703     unless ($engine) {
2704         $engine = $class->engine_class;
2705     }
2706
2707     Class::MOP::load_class($engine);
2708
2709     # check for old engines that are no longer compatible
2710     my $old_engine;
2711     if ( $engine->isa('Catalyst::Engine::Apache')
2712         && !Catalyst::Engine::Apache->VERSION )
2713     {
2714         $old_engine = 1;
2715     }
2716
2717     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2718         && Catalyst::Engine::Server->VERSION le '0.02' )
2719     {
2720         $old_engine = 1;
2721     }
2722
2723     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2724         && $engine->VERSION eq '0.01' )
2725     {
2726         $old_engine = 1;
2727     }
2728
2729     elsif ($engine->isa('Catalyst::Engine::Zeus')
2730         && $engine->VERSION eq '0.01' )
2731     {
2732         $old_engine = 1;
2733     }
2734
2735     if ($old_engine) {
2736         Catalyst::Exception->throw( message =>
2737               qq/Engine "$engine" is not supported by this version of Catalyst/
2738         );
2739     }
2740
2741     # engine instance
2742     $class->engine( $engine->new );
2743 }
2744
2745 =head2 $c->setup_home
2746
2747 Sets up the home directory.
2748
2749 =cut
2750
2751 sub setup_home {
2752     my ( $class, $home ) = @_;
2753
2754     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2755         $home = $env;
2756     }
2757
2758     $home ||= Catalyst::Utils::home($class);
2759
2760     if ($home) {
2761         #I remember recently being scolded for assigning config values like this
2762         $class->config->{home} ||= $home;
2763         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2764     }
2765 }
2766
2767 =head2 $c->setup_log
2768
2769 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2770 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2771 log to.
2772
2773 This method also installs a C<debug> method that returns a true value into the
2774 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2775 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2776
2777 Note that if the log has already been setup, by either a previous call to
2778 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2779 that this method won't actually set up the log object.
2780
2781 =cut
2782
2783 sub setup_log {
2784     my ( $class, $levels ) = @_;
2785
2786     $levels ||= '';
2787     $levels =~ s/^\s+//;
2788     $levels =~ s/\s+$//;
2789     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2790
2791     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2792     if ( defined $env_debug ) {
2793         $levels{debug} = 1 if $env_debug; # Ugly!
2794         delete($levels{debug}) unless $env_debug;
2795     }
2796
2797     unless ( $class->log ) {
2798         $class->log( Catalyst::Log->new(keys %levels) );
2799     }
2800
2801     if ( $levels{debug} ) {
2802         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2803         $class->log->debug('Debug messages enabled');
2804     }
2805 }
2806
2807 =head2 $c->setup_plugins
2808
2809 Sets up plugins.
2810
2811 =cut
2812
2813 =head2 $c->setup_stats
2814
2815 Sets up timing statistics class.
2816
2817 =cut
2818
2819 sub setup_stats {
2820     my ( $class, $stats ) = @_;
2821
2822     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2823
2824     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2825     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2826         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2827         $class->log->debug('Statistics enabled');
2828     }
2829 }
2830
2831
2832 =head2 $c->registered_plugins
2833
2834 Returns a sorted list of the plugins which have either been stated in the
2835 import list or which have been added via C<< MyApp->plugin(@args); >>.
2836
2837 If passed a given plugin name, it will report a boolean value indicating
2838 whether or not that plugin is loaded.  A fully qualified name is required if
2839 the plugin name does not begin with C<Catalyst::Plugin::>.
2840
2841  if ($c->registered_plugins('Some::Plugin')) {
2842      ...
2843  }
2844
2845 =cut
2846
2847 {
2848
2849     sub registered_plugins {
2850         my $proto = shift;
2851         return sort keys %{ $proto->_plugins } unless @_;
2852         my $plugin = shift;
2853         return 1 if exists $proto->_plugins->{$plugin};
2854         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2855     }
2856
2857     sub _register_plugin {
2858         my ( $proto, $plugin, $instant ) = @_;
2859         my $class = ref $proto || $proto;
2860
2861         Class::MOP::load_class( $plugin );
2862         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2863             if $plugin->isa( 'Catalyst::Component' );
2864         $proto->_plugins->{$plugin} = 1;
2865         unless ($instant) {
2866             my $meta = Class::MOP::get_metaclass_by_name($class);
2867             $meta->superclasses($plugin, $meta->superclasses);
2868         }
2869         return $class;
2870     }
2871
2872     sub setup_plugins {
2873         my ( $class, $plugins ) = @_;
2874
2875         $class->_plugins( {} ) unless $class->_plugins;
2876         $plugins = Data::OptList::mkopt($plugins || []);
2877
2878         my @plugins = map {
2879             [ Catalyst::Utils::resolve_namespace(
2880                   $class . '::Plugin',
2881                   'Catalyst::Plugin', $_->[0]
2882               ),
2883               $_->[1],
2884             ]
2885          } @{ $plugins };
2886
2887         for my $plugin ( reverse @plugins ) {
2888             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2889             my $meta = find_meta($plugin->[0]);
2890             next if $meta && $meta->isa('Moose::Meta::Role');
2891
2892             $class->_register_plugin($plugin->[0]);
2893         }
2894
2895         my @roles =
2896             map  { $_->[0]->name, $_->[1] }
2897             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2898             map  { [find_meta($_->[0]), $_->[1]] }
2899             @plugins;
2900
2901         Moose::Util::apply_all_roles(
2902             $class => @roles
2903         ) if @roles;
2904     }
2905 }
2906
2907 =head2 $c->stack
2908
2909 Returns an arrayref of the internal execution stack (actions that are
2910 currently executing).
2911
2912 =head2 $c->stats
2913
2914 Returns the current timing statistics object. By default Catalyst uses
2915 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2916 L<< stats_class|/"$c->stats_class" >>.
2917
2918 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2919 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2920 profile explicitly, although MyApp.pm still won't profile nor output anything
2921 by itself.
2922
2923 =head2 $c->stats_class
2924
2925 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2926
2927 =head2 $c->use_stats
2928
2929 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2930
2931 Note that this is a static method, not an accessor and should be overridden
2932 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2933
2934 =cut
2935
2936 sub use_stats { 0 }
2937
2938
2939 =head2 $c->write( $data )
2940
2941 Writes $data to the output stream. When using this method directly, you
2942 will need to manually set the C<Content-Length> header to the length of
2943 your output data, if known.
2944
2945 =cut
2946
2947 sub write {
2948     my $c = shift;
2949
2950     # Finalize headers if someone manually writes output
2951     $c->finalize_headers;
2952
2953     return $c->engine->write( $c, @_ );
2954 }
2955
2956 =head2 version
2957
2958 Returns the Catalyst version number. Mostly useful for "powered by"
2959 messages in template systems.
2960
2961 =cut
2962
2963 sub version { return $Catalyst::VERSION }
2964
2965 =head1 CONFIGURATION
2966
2967 There are a number of 'base' config variables which can be set:
2968
2969 =over
2970
2971 =item *
2972
2973 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2974
2975 =item *
2976
2977 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2978
2979 =item *
2980
2981 C<disable_component_resolution_regex_fallback> - Turns
2982 off the deprecated component resolution functionality so
2983 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2984 are called then regex search will not be attempted on string values and
2985 instead C<undef> will be returned.
2986
2987 =item *
2988
2989 C<home> - The application home directory. In an uninstalled application,
2990 this is the top level application directory. In an installed application,
2991 this will be the directory containing C<< MyApp.pm >>.
2992
2993 =item *
2994
2995 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2996
2997 =item *
2998
2999 C<name> - The name of the application in debug messages and the debug and
3000 welcome screens
3001
3002 =item *
3003
3004 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3005 until it is accessed. This allows you to (for example) check authentication (and reject
3006 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
3007
3008 =item *
3009
3010 C<root> - The root directory for templates. Usually this is just a
3011 subdirectory of the home directory, but you can set it to change the
3012 templates to a different directory.
3013
3014 =item *
3015
3016 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3017 namespaces from which components will be loaded (and constructed and stored in
3018 C<< $c->components >>).
3019
3020 =item *
3021
3022 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3023 to be shown in hit debug tables in the test server.
3024
3025 =item *
3026
3027 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
3028 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
3029 for more information.
3030
3031 =item *
3032
3033 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3034
3035 =back
3036
3037 =head1 INTERNAL ACTIONS
3038
3039 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3040 C<_ACTION>, and C<_END>. These are by default not shown in the private
3041 action table, but you can make them visible with a config parameter.
3042
3043     MyApp->config(show_internal_actions => 1);
3044
3045 =head1 ON-DEMAND PARSER
3046
3047 The request body is usually parsed at the beginning of a request,
3048 but if you want to handle input yourself, you can enable on-demand
3049 parsing with a config parameter.
3050
3051     MyApp->config(parse_on_demand => 1);
3052
3053 =head1 PROXY SUPPORT
3054
3055 Many production servers operate using the common double-server approach,
3056 with a lightweight frontend web server passing requests to a larger
3057 backend server. An application running on the backend server must deal
3058 with two problems: the remote user always appears to be C<127.0.0.1> and
3059 the server's hostname will appear to be C<localhost> regardless of the
3060 virtual host that the user connected through.
3061
3062 Catalyst will automatically detect this situation when you are running
3063 the frontend and backend servers on the same machine. The following
3064 changes are made to the request.
3065
3066     $c->req->address is set to the user's real IP address, as read from
3067     the HTTP X-Forwarded-For header.
3068
3069     The host value for $c->req->base and $c->req->uri is set to the real
3070     host, as read from the HTTP X-Forwarded-Host header.
3071
3072 Additionally, you may be running your backend application on an insecure
3073 connection (port 80) while your frontend proxy is running under SSL.  If there
3074 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3075 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3076 be created properly.
3077
3078 In the case of passing in:
3079
3080     X-Forwarded-Port: 443
3081
3082 All calls to C<uri_for> will result in an https link, as is expected.
3083
3084 Obviously, your web server must support these headers for this to work.
3085
3086 In a more complex server farm environment where you may have your
3087 frontend proxy server(s) on different machines, you will need to set a
3088 configuration option to tell Catalyst to read the proxied data from the
3089 headers.
3090
3091     MyApp->config(using_frontend_proxy => 1);
3092
3093 If you do not wish to use the proxy support at all, you may set:
3094
3095     MyApp->config(ignore_frontend_proxy => 1);
3096
3097 =head1 THREAD SAFETY
3098
3099 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3100 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3101 believe the Catalyst core to be thread-safe.
3102
3103 If you plan to operate in a threaded environment, remember that all other
3104 modules you are using must also be thread-safe. Some modules, most notably
3105 L<DBD::SQLite>, are not thread-safe.
3106
3107 =head1 SUPPORT
3108
3109 IRC:
3110
3111     Join #catalyst on irc.perl.org.
3112
3113 Mailing Lists:
3114
3115     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3116     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3117
3118 Web:
3119
3120     http://catalyst.perl.org
3121
3122 Wiki:
3123
3124     http://dev.catalyst.perl.org
3125
3126 =head1 SEE ALSO
3127
3128 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3129
3130 =head2 L<Catalyst::Manual> - The Catalyst Manual
3131
3132 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3133
3134 =head2 L<Catalyst::Engine> - Core engine
3135
3136 =head2 L<Catalyst::Log> - Log class.
3137
3138 =head2 L<Catalyst::Request> - Request object
3139
3140 =head2 L<Catalyst::Response> - Response object
3141
3142 =head2 L<Catalyst::Test> - The test suite.
3143
3144 =head1 PROJECT FOUNDER
3145
3146 sri: Sebastian Riedel <sri@cpan.org>
3147
3148 =head1 CONTRIBUTORS
3149
3150 abw: Andy Wardley
3151
3152 acme: Leon Brocard <leon@astray.com>
3153
3154 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3155
3156 Andrew Bramble
3157
3158 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3159
3160 Andrew Ruthven
3161
3162 andyg: Andy Grundman <andy@hybridized.org>
3163
3164 audreyt: Audrey Tang
3165
3166 bricas: Brian Cassidy <bricas@cpan.org>
3167
3168 Caelum: Rafael Kitover <rkitover@io.com>
3169
3170 chansen: Christian Hansen
3171
3172 chicks: Christopher Hicks
3173
3174 Chisel Wright C<pause@herlpacker.co.uk>
3175
3176 Danijel Milicevic C<me@danijel.de>
3177
3178 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3179
3180 David Naughton, C<naughton@umn.edu>
3181
3182 David E. Wheeler
3183
3184 dhoss: Devin Austin <dhoss@cpan.org>
3185
3186 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3187
3188 Drew Taylor
3189
3190 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3191
3192 esskar: Sascha Kiefer
3193
3194 fireartist: Carl Franks <cfranks@cpan.org>
3195
3196 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3197
3198 gabb: Danijel Milicevic
3199
3200 Gary Ashton Jones
3201
3202 Gavin Henry C<ghenry@perl.me.uk>
3203
3204 Geoff Richards
3205
3206 groditi: Guillermo Roditi <groditi@gmail.com>
3207
3208 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3209
3210 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3211
3212 jcamacho: Juan Camacho
3213
3214 jester: Jesse Sheidlower C<jester@panix.com>
3215
3216 jhannah: Jay Hannah <jay@jays.net>
3217
3218 Jody Belka
3219
3220 Johan Lindstrom
3221
3222 jon: Jon Schutz <jjschutz@cpan.org>
3223
3224 Jonathan Rockway C<< <jrockway@cpan.org> >>
3225
3226 Kieren Diment C<kd@totaldatasolution.com>
3227
3228 konobi: Scott McWhirter <konobi@cpan.org>
3229
3230 marcus: Marcus Ramberg <mramberg@cpan.org>
3231
3232 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3233
3234 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3235
3236 mugwump: Sam Vilain
3237
3238 naughton: David Naughton
3239
3240 ningu: David Kamholz <dkamholz@cpan.org>
3241
3242 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3243
3244 numa: Dan Sully <daniel@cpan.org>
3245
3246 obra: Jesse Vincent
3247
3248 Octavian Rasnita
3249
3250 omega: Andreas Marienborg
3251
3252 Oleg Kostyuk <cub.uanic@gmail.com>
3253
3254 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3255
3256 rafl: Florian Ragwitz <rafl@debian.org>
3257
3258 random: Roland Lammel <lammel@cpan.org>
3259
3260 Robert Sedlacek C<< <rs@474.at> >>
3261
3262 SpiceMan: Marcel Montes
3263
3264 sky: Arthur Bergman
3265
3266 szbalint: Balint Szilakszi <szbalint@cpan.org>
3267
3268 t0m: Tomas Doran <bobtfish@bobtfish.net>
3269
3270 Ulf Edvinsson
3271
3272 Viljo Marrandi C<vilts@yahoo.com>
3273
3274 Will Hawes C<info@whawes.co.uk>
3275
3276 willert: Sebastian Willert <willert@cpan.org>
3277
3278 wreis: Wallace Reis <wallace@reis.org.br>
3279
3280 Yuval Kogman, C<nothingmuch@woobling.org>
3281
3282 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3283
3284 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3285
3286 =head1 COPYRIGHT
3287
3288 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3289
3290 =head1 LICENSE
3291
3292 This library is free software. You can redistribute it and/or modify it under
3293 the same terms as Perl itself.
3294
3295 =cut
3296
3297 no Moose;
3298
3299 __PACKAGE__->meta->make_immutable;
3300
3301 1;