lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken blessed/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp shortmess/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 __PACKAGE__->mk_accessors(
  34     qw/counter request response state action stack namespace stats/
  35 );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52 our $GO        = "catalyst_go\n";
  53
  54 __PACKAGE__->mk_classdata($_)
  55   for qw/components arguments dispatcher engine log dispatcher_class
  56   engine_class context_class request_class response_class stats_class
  57   setup_finished/;
  58
  59 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  60 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  61 __PACKAGE__->request_class('Catalyst::Request');
  62 __PACKAGE__->response_class('Catalyst::Response');
  63 __PACKAGE__->stats_class('Catalyst::Stats');
  64
  65 # Remember to update this in Catalyst::Runtime as well!
  66
  67 our $VERSION = '5.71000';
  68
  69 sub import {
  70     my ( $class, @arguments ) = @_;
  71
  72     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  73     # callers @ISA.
  74     return unless $class eq 'Catalyst';
  75
  76     my $caller = caller(0);
  77
  78     unless ( $caller->isa('Catalyst') ) {
  79         no strict 'refs';
  80         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  81     }
  82
  83     $caller->arguments( [@arguments] );
  84     $caller->setup_home;
  85 }
  86
  87 =head1 NAME
  88
  89 Catalyst - The Elegant MVC Web Application Framework
  90
  91 =head1 SYNOPSIS
  92
  93 See the L<Catalyst::Manual> distribution for comprehensive
  94 documentation and tutorials.
  95
  96     # Install Catalyst::Devel for helpers and other development tools
  97     # use the helper to create a new application
  98     catalyst.pl MyApp
  99
 100     # add models, views, controllers
 101     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 102     script/myapp_create.pl view MyTemplate TT
 103     script/myapp_create.pl controller Search
 104
 105     # built in testserver -- use -r to restart automatically on changes
 106     # --help to see all available options
 107     script/myapp_server.pl
 108
 109     # command line testing interface
 110     script/myapp_test.pl /yada
 111
 112     ### in lib/MyApp.pm
 113     use Catalyst qw/-Debug/; # include plugins here as well
 114
 115     ### In lib/MyApp/Controller/Root.pm (autocreated)
 116     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 117         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 118         $c->stash->{template} = 'foo.tt'; # set the template
 119         # lookup something from db -- stash vars are passed to TT
 120         $c->stash->{data} =
 121           $c->model('Database::Foo')->search( { country => $args[0] } );
 122         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 123             $c->forward( 'bar' ); # process another action
 124             # do something else after forward returns
 125         }
 126     }
 127
 128     # The foo.tt TT template can use the stash data from the database
 129     [% WHILE (item = data.next) %]
 130         [% item.foo %]
 131     [% END %]
 132
 133     # called for /bar/of/soap, /bar/of/soap/10, etc.
 134     sub bar : Path('/bar/of/soap') { ... }
 135
 136     # called for all actions, from the top-most controller downwards
 137     sub auto : Private {
 138         my ( $self, $c ) = @_;
 139         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 140             $c->res->redirect( '/login' ); # require login
 141             return 0; # abort request and go immediately to end()
 142         }
 143         return 1; # success; carry on to next action
 144     }
 145
 146     # called after all actions are finished
 147     sub end : Private {
 148         my ( $self, $c ) = @_;
 149         if ( scalar @{ $c->error } ) { ... } # handle errors
 150         return if $c->res->body; # already have a response
 151         $c->forward( 'MyApp::View::TT' ); # render template
 152     }
 153
 154     ### in MyApp/Controller/Foo.pm
 155     # called for /foo/bar
 156     sub bar : Local { ... }
 157
 158     # called for /blargle
 159     sub blargle : Global { ... }
 160
 161     # an index action matches /foo, but not /foo/1, etc.
 162     sub index : Private { ... }
 163
 164     ### in MyApp/Controller/Foo/Bar.pm
 165     # called for /foo/bar/baz
 166     sub baz : Local { ... }
 167
 168     # first Root auto is called, then Foo auto, then this
 169     sub auto : Private { ... }
 170
 171     # powerful regular expression paths are also possible
 172     sub details : Regex('^product/(\w+)/details$') {
 173         my ( $self, $c ) = @_;
 174         # extract the (\w+) from the URI
 175         my $product = $c->req->captures->[0];
 176     }
 177
 178 See L<Catalyst::Manual::Intro> for additional information.
 179
 180 =head1 DESCRIPTION
 181
 182 Catalyst is a modern framework for making web applications without the
 183 pain usually associated with this process. This document is a reference
 184 to the main Catalyst application. If you are a new user, we suggest you
 185 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 186
 187 See L<Catalyst::Manual> for more documentation.
 188
 189 Catalyst plugins can be loaded by naming them as arguments to the "use
 190 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 191 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 192 C<My::Module>.
 193
 194     use Catalyst qw/My::Module/;
 195
 196 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 197 fully qualify the name by using a unary plus:
 198
 199     use Catalyst qw/
 200         My::Module
 201         +Fully::Qualified::Plugin::Name
 202     /;
 203
 204 Special flags like C<-Debug> and C<-Engine> can also be specified as
 205 arguments when Catalyst is loaded:
 206
 207     use Catalyst qw/-Debug My::Module/;
 208
 209 The position of plugins and flags in the chain is important, because
 210 they are loaded in the order in which they appear.
 211
 212 The following flags are supported:
 213
 214 =head2 -Debug
 215
 216 Enables debug output. You can also force this setting from the system
 217 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 218 settings override the application, with <MYAPP>_DEBUG having the highest
 219 priority.
 220
 221 =head2 -Engine
 222
 223 Forces Catalyst to use a specific engine. Omit the
 224 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 225
 226     use Catalyst qw/-Engine=CGI/;
 227
 228 =head2 -Home
 229
 230 Forces Catalyst to use a specific home directory, e.g.:
 231
 232     use Catalyst qw[-Home=/usr/mst];
 233
 234 This can also be done in the shell environment by setting either the
 235 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 236 is replaced with the uppercased name of your application, any "::" in
 237 the name will be replaced with underscores, e.g. MyApp::Web should use
 238 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 239
 240 =head2 -Log
 241
 242 Specifies log level.
 243
 244 =head2 -Stats
 245
 246 Enables statistics collection and reporting. You can also force this setting
 247 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 248 environment settings override the application, with <MYAPP>_STATS having the
 249 highest priority.
 250
 251 e.g.
 252
 253    use Catalyst qw/-Stats=1/
 254
 255 =head1 METHODS
 256
 257 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 258
 259 =head2 $c->action
 260
 261 Returns a L<Catalyst::Action> object for the current action, which
 262 stringifies to the action name. See L<Catalyst::Action>.
 263
 264 =head2 $c->namespace
 265
 266 Returns the namespace of the current action, i.e., the URI prefix
 267 corresponding to the controller of the current action. For example:
 268
 269     # in Controller::Foo::Bar
 270     $c->namespace; # returns 'foo/bar';
 271
 272 =head2 $c->request
 273
 274 =head2 $c->req
 275
 276 Returns the current L<Catalyst::Request> object, giving access to
 277 information about the current client request (including parameters,
 278 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 279
 280 =head2 REQUEST FLOW HANDLING
 281
 282 =head2 $c->forward( $action [, \@arguments ] )
 283
 284 =head2 $c->forward( $class, $method, [, \@arguments ] )
 285
 286 Forwards processing to another action, by its private name. If you give a
 287 class name but no method, C<process()> is called. You may also optionally
 288 pass arguments in an arrayref. The action will receive the arguments in
 289 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 290 C<< $c->req->args >> will be restored to the previous values.
 291
 292 Any data C<return>ed from the action forwarded to, will be returned by the
 293 call to forward.
 294
 295     my $foodata = $c->forward('/foo');
 296     $c->forward('index');
 297     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 298     $c->forward('MyApp::View::TT');
 299
 300 Note that forward implies an C<<eval { }>> around the call (actually
 301 C<execute> does), thus de-fatalizing all 'dies' within the called
 302 action. If you want C<die> to propagate you need to do something like:
 303
 304     $c->forward('foo');
 305     die $c->error if $c->error;
 306
 307 Or make sure to always return true values from your actions and write
 308 your code like this:
 309
 310     $c->forward('foo') || return;
 311
 312 =cut
 313
 314 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 315
 316 =head2 $c->detach( $action [, \@arguments ] )
 317
 318 =head2 $c->detach( $class, $method, [, \@arguments ] )
 319
 320 =head2 $c->detach()
 321
 322 The same as C<forward>, but doesn't return to the previous action when
 323 processing is finished.
 324
 325 When called with no arguments it escapes the processing chain entirely.
 326
 327 =cut
 328
 329 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 330
 331 =head2 $c->visit( $action [, \@arguments ] )
 332
 333 =head2 $c->visit( $class, $method, [, \@arguments ] )
 334
 335 Almost the same as C<forward>, but does a full dispatch, instead of just
 336 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 337 C<auto> and the method you go to are called, just like a new request.
 338
 339 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 340 This means, for example, that $c->action methods such as C<name>, C<class> and
 341 C<reverse> return information for the visited action when they are invoked
 342 within the visited action.  This is different from the behavior of C<forward>
 343 which continues to use the $c->action object from the caller action even when
 344 invoked from the callee.
 345
 346 C<$c-E<gt>stash> is kept unchanged.
 347
 348 In effect, C<visit> allows you to "wrap" another action, just as it
 349 would have been called by dispatching from a URL, while the analogous
 350 C<go> allows you to transfer control to another action as if it had
 351 been reached directly from a URL.
 352
 353 =cut
 354
 355 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 356
 357 =head2 $c->go( $action [, \@arguments ] )
 358
 359 =head2 $c->go( $class, $method, [, \@arguments ] )
 360
 361 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 362 instead of just calling the new C<$action> /
 363 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 364 method you visit are called, just like a new request.
 365
 366 C<$c-E<gt>stash> is kept unchanged.
 367
 368 =cut
 369
 370 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 371
 372 =head2 $c->response
 373
 374 =head2 $c->res
 375
 376 Returns the current L<Catalyst::Response> object, see there for details.
 377
 378 =head2 $c->stash
 379
 380 Returns a hashref to the stash, which may be used to store data and pass
 381 it between components during a request. You can also set hash keys by
 382 passing arguments. The stash is automatically sent to the view. The
 383 stash is cleared at the end of a request; it cannot be used for
 384 persistent storage (for this you must use a session; see
 385 L<Catalyst::Plugin::Session> for a complete system integrated with
 386 Catalyst).
 387
 388     $c->stash->{foo} = $bar;
 389     $c->stash( { moose => 'majestic', qux => 0 } );
 390     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 391
 392     # stash is automatically passed to the view for use in a template
 393     $c->forward( 'MyApp::View::TT' );
 394
 395 =cut
 396
 397 sub stash {
 398     my $c = shift;
 399     if (@_) {
 400         my $stash = @_ > 1 ? {@_} : $_[0];
 401         croak('stash takes a hash or hashref') unless ref $stash;
 402         foreach my $key ( keys %$stash ) {
 403             $c->{stash}->{$key} = $stash->{$key};
 404         }
 405     }
 406     return $c->{stash};
 407 }
 408
 409 =head2 $c->error
 410
 411 =head2 $c->error($error, ...)
 412
 413 =head2 $c->error($arrayref)
 414
 415 Returns an arrayref containing error messages.  If Catalyst encounters an
 416 error while processing a request, it stores the error in $c->error.  This
 417 method should only be used to store fatal error messages.
 418
 419     my @error = @{ $c->error };
 420
 421 Add a new error.
 422
 423     $c->error('Something bad happened');
 424
 425 =cut
 426
 427 sub error {
 428     my $c = shift;
 429     if ( $_[0] ) {
 430         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 431         croak @$error unless ref $c;
 432         push @{ $c->{error} }, @$error;
 433     }
 434     elsif ( defined $_[0] ) { $c->{error} = undef }
 435     return $c->{error} || [];
 436 }
 437
 438
 439 =head2 $c->state
 440
 441 Contains the return value of the last executed action.
 442
 443 =head2 $c->clear_errors
 444
 445 Clear errors.  You probably don't want to clear the errors unless you are
 446 implementing a custom error screen.
 447
 448 This is equivalent to running
 449
 450     $c->error(0);
 451
 452 =cut
 453
 454 sub clear_errors {
 455     my $c = shift;
 456     $c->error(0);
 457 }
 458
 459 # search components given a name and some prefixes
 460 sub _comp_search_prefixes {
 461     my ( $c, $name, @prefixes ) = @_;
 462     my $appclass = ref $c || $c;
 463     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 464
 465     # map the original component name to the sub part that we will search against
 466     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 467         grep { /$filter/ } keys %{ $c->components };
 468
 469     # undef for a name will return all
 470     return keys %eligible if !defined $name;
 471
 472     my $query  = ref $name ? $name : qr/^$name$/i;
 473     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 474
 475     return map { $c->components->{ $_ } } @result if @result;
 476
 477     # if we were given a regexp to search against, we're done.
 478     return if ref $name;
 479
 480     # regexp fallback
 481     $query  = qr/$name/i;
 482     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 483
 484     # no results? try against full names
 485     if( !@result ) {
 486         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 487     }
 488
 489     # don't warn if we didn't find any results, it just might not exist
 490     if( @result ) {
 491         my $msg = "Used regexp fallback for \$c->model('${name}'), which found '" .
 492            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 493            "component resolution is unreliable and unsafe.";
 494         my $short = $result[0];
 495         $short =~ s/.*?Model:://;
 496         my $shortmess = Carp::shortmess('');
 497         if ($shortmess =~ m#Catalyst/Plugin#) {
 498            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 499               "plugin's config";
 500         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 501            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 502               "component's config";
 503         } else {
 504            $msg .= " You probably meant \$c->model('$short') instead of \$c->model{'${name}'}, " .
 505               "but if you really wanted to search, pass in a regexp as the argument " .
 506               "like so: \$c->model(qr/${name}/)";
 507         }
 508         $c->log->warn( "${msg}$shortmess" );
 509     }
 510
 511     return @result;
 512 }
 513
 514 # Find possible names for a prefix
 515 sub _comp_names {
 516     my ( $c, @prefixes ) = @_;
 517     my $appclass = ref $c || $c;
 518
 519     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 520
 521     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 522     return @names;
 523 }
 524
 525 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 526 sub _filter_component {
 527     my ( $c, $comp, @args ) = @_;
 528
 529     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 530         return $comp->ACCEPT_CONTEXT( $c, @args );
 531     }
 532
 533     return $comp;
 534 }
 535
 536 =head2 COMPONENT ACCESSORS
 537
 538 =head2 $c->controller($name)
 539
 540 Gets a L<Catalyst::Controller> instance by name.
 541
 542     $c->controller('Foo')->do_stuff;
 543
 544 If the name is omitted, will return the controller for the dispatched
 545 action.
 546
 547 If you want to search for controllers, pass in a regexp as the argument.
 548
 549     # find all controllers that start with Foo
 550     my @foo_controllers = $c->controller(qr{^Foo});
 551
 552
 553 =cut
 554
 555 sub controller {
 556     my ( $c, $name, @args ) = @_;
 557
 558     if( $name ) {
 559         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 560         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 561         return $c->_filter_component( $result[ 0 ], @args );
 562     }
 563
 564     return $c->component( $c->action->class );
 565 }
 566
 567 =head2 $c->model($name)
 568
 569 Gets a L<Catalyst::Model> instance by name.
 570
 571     $c->model('Foo')->do_stuff;
 572
 573 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 574
 575 If the name is omitted, it will look for
 576  - a model object in $c->stash->{current_model_instance}, then
 577  - a model name in $c->stash->{current_model}, then
 578  - a config setting 'default_model', or
 579  - check if there is only one model, and return it if that's the case.
 580
 581 If you want to search for models, pass in a regexp as the argument.
 582
 583     # find all models that start with Foo
 584     my @foo_models = $c->model(qr{^Foo});
 585
 586 =cut
 587
 588 sub model {
 589     my ( $c, $name, @args ) = @_;
 590
 591     if( $name ) {
 592         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 593         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 594         return $c->_filter_component( $result[ 0 ], @args );
 595     }
 596
 597     if (ref $c) {
 598         return $c->stash->{current_model_instance}
 599           if $c->stash->{current_model_instance};
 600         return $c->model( $c->stash->{current_model} )
 601           if $c->stash->{current_model};
 602     }
 603     return $c->model( $c->config->{default_model} )
 604       if $c->config->{default_model};
 605
 606     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 607
 608     if( $rest ) {
 609         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 610         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 611         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 612         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 613         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 614     }
 615
 616     return $c->_filter_component( $comp );
 617 }
 618
 619
 620 =head2 $c->view($name)
 621
 622 Gets a L<Catalyst::View> instance by name.
 623
 624     $c->view('Foo')->do_stuff;
 625
 626 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 627
 628 If the name is omitted, it will look for
 629  - a view object in $c->stash->{current_view_instance}, then
 630  - a view name in $c->stash->{current_view}, then
 631  - a config setting 'default_view', or
 632  - check if there is only one view, and return it if that's the case.
 633
 634 If you want to search for views, pass in a regexp as the argument.
 635
 636     # find all views that start with Foo
 637     my @foo_views = $c->view(qr{^Foo});
 638
 639 =cut
 640
 641 sub view {
 642     my ( $c, $name, @args ) = @_;
 643
 644     if( $name ) {
 645         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 646         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 647         return $c->_filter_component( $result[ 0 ], @args );
 648     }
 649
 650     if (ref $c) {
 651         return $c->stash->{current_view_instance}
 652           if $c->stash->{current_view_instance};
 653         return $c->view( $c->stash->{current_view} )
 654           if $c->stash->{current_view};
 655     }
 656     return $c->view( $c->config->{default_view} )
 657       if $c->config->{default_view};
 658
 659     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 660
 661     if( $rest ) {
 662         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 663         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 664         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 665         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 666         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 667     }
 668
 669     return $c->_filter_component( $comp );
 670 }
 671
 672 =head2 $c->controllers
 673
 674 Returns the available names which can be passed to $c->controller
 675
 676 =cut
 677
 678 sub controllers {
 679     my ( $c ) = @_;
 680     return $c->_comp_names(qw/Controller C/);
 681 }
 682
 683 =head2 $c->models
 684
 685 Returns the available names which can be passed to $c->model
 686
 687 =cut
 688
 689 sub models {
 690     my ( $c ) = @_;
 691     return $c->_comp_names(qw/Model M/);
 692 }
 693
 694
 695 =head2 $c->views
 696
 697 Returns the available names which can be passed to $c->view
 698
 699 =cut
 700
 701 sub views {
 702     my ( $c ) = @_;
 703     return $c->_comp_names(qw/View V/);
 704 }
 705
 706 =head2 $c->comp($name)
 707
 708 =head2 $c->component($name)
 709
 710 Gets a component object by name. This method is not recommended,
 711 unless you want to get a specific component by full
 712 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 713 should be used instead.
 714
 715 If C<$name> is a regexp, a list of components matched against the full
 716 component name will be returned.
 717
 718 =cut
 719
 720 sub component {
 721     my ( $c, $name, @args ) = @_;
 722
 723     if( $name ) {
 724         my $comps = $c->components;
 725
 726         if( !ref $name ) {
 727             # is it the exact name?
 728             return $c->_filter_component( $comps->{ $name }, @args )
 729                        if exists $comps->{ $name };
 730
 731             # perhaps we just omitted "MyApp"?
 732             my $composed = ( ref $c || $c ) . "::${name}";
 733             return $c->_filter_component( $comps->{ $composed }, @args )
 734                        if exists $comps->{ $composed };
 735
 736             # search all of the models, views and controllers
 737             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 738             return $c->_filter_component( $comp, @args ) if $comp;
 739         }
 740
 741         # This is here so $c->comp( '::M::' ) works
 742         my $query = ref $name ? $name : qr{$name}i;
 743
 744         my @result = grep { m{$query} } keys %{ $c->components };
 745         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 746
 747         if( $result[ 0 ] ) {
 748             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 749             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 750             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 751             return $c->_filter_component( $result[ 0 ], @args );
 752         }
 753
 754         # I would expect to return an empty list here, but that breaks back-compat
 755     }
 756
 757     # fallback
 758     return sort keys %{ $c->components };
 759 }
 760
 761 =head2 CLASS DATA AND HELPER CLASSES
 762
 763 =head2 $c->config
 764
 765 Returns or takes a hashref containing the application's configuration.
 766
 767     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 768
 769 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 770 like myapp.yml in your applications home directory. See
 771 L<Catalyst::Plugin::ConfigLoader>.
 772
 773     ---
 774     db: dsn:SQLite:foo.db
 775
 776
 777 =cut
 778
 779 sub config {
 780     my $c = shift;
 781
 782     $c->log->warn("Setting config after setup has been run is not a good idea.")
 783       if ( @_ and $c->setup_finished );
 784
 785     $c->NEXT::config(@_);
 786 }
 787
 788 =head2 $c->log
 789
 790 Returns the logging object instance. Unless it is already set, Catalyst
 791 sets this up with a L<Catalyst::Log> object. To use your own log class,
 792 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 793 C<< __PACKAGE__->setup >>.
 794
 795  __PACKAGE__->log( MyLogger->new );
 796  __PACKAGE__->setup;
 797
 798 And later:
 799
 800     $c->log->info( 'Now logging with my own logger!' );
 801
 802 Your log class should implement the methods described in
 803 L<Catalyst::Log>.
 804
 805
 806 =head2 $c->debug
 807
 808 Overload to enable debug messages (same as -Debug option).
 809
 810 Note that this is a static method, not an accessor and should be overloaded
 811 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 812
 813 =cut
 814
 815 sub debug { 0 }
 816
 817 =head2 $c->dispatcher
 818
 819 Returns the dispatcher instance. Stringifies to class name. See
 820 L<Catalyst::Dispatcher>.
 821
 822 =head2 $c->engine
 823
 824 Returns the engine instance. Stringifies to the class name. See
 825 L<Catalyst::Engine>.
 826
 827
 828 =head2 UTILITY METHODS
 829
 830 =head2 $c->path_to(@path)
 831
 832 Merges C<@path> with C<< $c->config->{home} >> and returns a
 833 L<Path::Class::Dir> object.
 834
 835 For example:
 836
 837     $c->path_to( 'db', 'sqlite.db' );
 838
 839 =cut
 840
 841 sub path_to {
 842     my ( $c, @path ) = @_;
 843     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 844     if ( -d $path ) { return $path }
 845     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 846 }
 847
 848 =head2 $c->plugin( $name, $class, @args )
 849
 850 Helper method for plugins. It creates a classdata accessor/mutator and
 851 loads and instantiates the given class.
 852
 853     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 854
 855     $c->prototype->define_javascript_functions;
 856
 857 =cut
 858
 859 sub plugin {
 860     my ( $class, $name, $plugin, @args ) = @_;
 861     $class->_register_plugin( $plugin, 1 );
 862
 863     eval { $plugin->import };
 864     $class->mk_classdata($name);
 865     my $obj;
 866     eval { $obj = $plugin->new(@args) };
 867
 868     if ($@) {
 869         Catalyst::Exception->throw( message =>
 870               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 871     }
 872
 873     $class->$name($obj);
 874     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 875       if $class->debug;
 876 }
 877
 878 =head2 MyApp->setup
 879
 880 Initializes the dispatcher and engine, loads any plugins, and loads the
 881 model, view, and controller components. You may also specify an array
 882 of plugins to load here, if you choose to not load them in the C<use
 883 Catalyst> line.
 884
 885     MyApp->setup;
 886     MyApp->setup( qw/-Debug/ );
 887
 888 =cut
 889
 890 sub setup {
 891     my ( $class, @arguments ) = @_;
 892
 893     $class->log->warn("Running setup twice is not a good idea.")
 894       if ( $class->setup_finished );
 895
 896     unless ( $class->isa('Catalyst') ) {
 897
 898         Catalyst::Exception->throw(
 899             message => qq/'$class' does not inherit from Catalyst/ );
 900     }
 901
 902     if ( $class->arguments ) {
 903         @arguments = ( @arguments, @{ $class->arguments } );
 904     }
 905
 906     # Process options
 907     my $flags = {};
 908
 909     foreach (@arguments) {
 910
 911         if (/^-Debug$/) {
 912             $flags->{log} =
 913               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 914         }
 915         elsif (/^-(\w+)=?(.*)$/) {
 916             $flags->{ lc $1 } = $2;
 917         }
 918         else {
 919             push @{ $flags->{plugins} }, $_;
 920         }
 921     }
 922
 923     $class->setup_home( delete $flags->{home} );
 924
 925     $class->setup_log( delete $flags->{log} );
 926     $class->setup_plugins( delete $flags->{plugins} );
 927     $class->setup_dispatcher( delete $flags->{dispatcher} );
 928     $class->setup_engine( delete $flags->{engine} );
 929     $class->setup_stats( delete $flags->{stats} );
 930
 931     for my $flag ( sort keys %{$flags} ) {
 932
 933         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 934             &$code( $class, delete $flags->{$flag} );
 935         }
 936         else {
 937             $class->log->warn(qq/Unknown flag "$flag"/);
 938         }
 939     }
 940
 941     eval { require Catalyst::Devel; };
 942     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 943         $class->log->warn(<<"EOF");
 944 You are running an old script!
 945
 946   Please update by running (this will overwrite existing files):
 947     catalyst.pl -force -scripts $class
 948
 949   or (this will not overwrite existing files):
 950     catalyst.pl -scripts $class
 951
 952 EOF
 953     }
 954
 955     if ( $class->debug ) {
 956         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 957
 958         if (@plugins) {
 959             my $column_width = Catalyst::Utils::term_width() - 6;
 960             my $t = Text::SimpleTable->new($column_width);
 961             $t->row($_) for @plugins;
 962             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 963         }
 964
 965         my $dispatcher = $class->dispatcher;
 966         my $engine     = $class->engine;
 967         my $home       = $class->config->{home};
 968
 969         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 970         $class->log->debug(qq/Loaded engine "$engine"/);
 971
 972         $home
 973           ? ( -d $home )
 974           ? $class->log->debug(qq/Found home "$home"/)
 975           : $class->log->debug(qq/Home "$home" doesn't exist/)
 976           : $class->log->debug(q/Couldn't find home/);
 977     }
 978
 979     # Call plugins setup
 980     {
 981         no warnings qw/redefine/;
 982         local *setup = sub { };
 983         $class->setup;
 984     }
 985
 986     # Initialize our data structure
 987     $class->components( {} );
 988
 989     $class->setup_components;
 990
 991     if ( $class->debug ) {
 992         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
 993         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
 994         for my $comp ( sort keys %{ $class->components } ) {
 995             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 996             $t->row( $comp, $type );
 997         }
 998         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 999           if ( keys %{ $class->components } );
1000     }
1001
1002     # Add our self to components, since we are also a component
1003     $class->components->{$class} = $class;
1004
1005     $class->setup_actions;
1006
1007     if ( $class->debug ) {
1008         my $name = $class->config->{name} || 'Application';
1009         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1010     }
1011     $class->log->_flush() if $class->log->can('_flush');
1012
1013     $class->setup_finished(1);
1014 }
1015
1016 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1017
1018 =head2 $c->uri_for( $path, @args?, \%query_values? )
1019
1020 =over
1021
1022 =item $action
1023
1024 A Catalyst::Action object representing the Catalyst action you want to
1025 create a URI for. To get one for an action in the current controller,
1026 use C<< $c->action('someactionname') >>. To get one from different
1027 controller, fetch the controller using C<< $c->controller() >>, then
1028 call C<action_for> on it.
1029
1030 This method must be used to create URIs for
1031 L<Catalyst::DispatchType::Chained> actions.
1032
1033 =item $path
1034
1035 The actual path you wish to create a URI for, this is a public path,
1036 not a private action path.
1037
1038 =item \@captures
1039
1040 If provided, this argument is used to insert values into a I<Chained>
1041 action in the parts where the definitions contain I<CaptureArgs>. If
1042 not needed, leave out this argument.
1043
1044 =item @args
1045
1046 If provided, this is used as a list of further path sections to append
1047 to the URI. In a I<Chained> action these are the equivalent to the
1048 endpoint L<Args>.
1049
1050 =item \%query_values
1051
1052 If provided, the query_values hashref is used to add query parameters
1053 to the URI, with the keys as the names, and the values as the values.
1054
1055 =back
1056
1057 Returns a L<URI> object.
1058
1059   ## Ex 1: a path with args and a query parameter
1060   $c->uri_for('user/list', 'short', { page => 2});
1061   ## -> ($c->req->base is 'http://localhost:3000/'
1062   URI->new('http://localhost:3000/user/list/short?page=2)
1063
1064   ## Ex 2: a chained view action that captures the user id
1065   ## In controller:
1066   sub user : Chained('/'): PathPart('myuser'): CaptureArgs(1) {}
1067   sub viewuser : Chained('user'): PathPart('view') {}
1068
1069   ## In uri creating code:
1070   my $uaction = $c->controller('Users')->action_for('viewuser');
1071   $c->uri_for($uaction, [ 42 ]);
1072   ## outputs:
1073   URI->new('http://localhost:3000/myuser/42/view')
1074
1075 Creates a URI object using C<< $c->request->base >> and a path. If an
1076 Action object is given instead of a path, the path is constructed
1077 using C<< $c->dispatcher->uri_for_action >> and passing it the
1078 @captures array, if supplied.
1079
1080 If any query parameters are passed they are added to the end of the
1081 URI in the usual way.
1082
1083 Note that uri_for is destructive to the passed query values hashref.
1084 Subsequent calls with the same hashref may have unintended results.
1085
1086 =cut
1087
1088 sub uri_for {
1089     my ( $c, $path, @args ) = @_;
1090
1091     if ( Scalar::Util::blessed($path) ) { # action object
1092         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1093                          ? shift(@args)
1094                          : [] );
1095         $path = $c->dispatcher->uri_for_action($path, $captures);
1096         return undef unless defined($path);
1097         $path = '/' if $path eq '';
1098     }
1099
1100     undef($path) if (defined $path && $path eq '');
1101
1102     my $params =
1103       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1104
1105     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1106     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1107
1108     unshift(@args, $path);
1109
1110     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1111         my $namespace = $c->namespace;
1112         if (defined $path) { # cheesy hack to handle path '../foo'
1113            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1114         }
1115         unshift(@args, $namespace || '');
1116     }
1117
1118     # join args with '/', or a blank string
1119     my $args = join('/', grep { defined($_) } @args);
1120     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1121     $args =~ s!^/!!;
1122     my $base = $c->req->base;
1123     my $class = ref($base);
1124     $base =~ s{(?<!/)$}{/};
1125
1126     my $query = '';
1127
1128     if (my @keys = keys %$params) {
1129       # somewhat lifted from URI::_query's query_form
1130       $query = '?'.join('&', map {
1131           my $val = $params->{$_};
1132           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1133           s/ /+/g;
1134           my $key = $_;
1135           $val = '' unless defined $val;
1136           (map {
1137               $_ = "$_";
1138               utf8::encode( $_ ) if utf8::is_utf8($_);
1139               # using the URI::Escape pattern here so utf8 chars survive
1140               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1141               s/ /+/g;
1142               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1143       } @keys);
1144     }
1145
1146     my $res = bless(\"${base}${args}${query}", $class);
1147     $res;
1148 }
1149
1150 =head2 $c->welcome_message
1151
1152 Returns the Catalyst welcome HTML page.
1153
1154 =cut
1155
1156 sub welcome_message {
1157     my $c      = shift;
1158     my $name   = $c->config->{name};
1159     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1160     my $prefix = Catalyst::Utils::appprefix( ref $c );
1161     $c->response->content_type('text/html; charset=utf-8');
1162     return <<"EOF";
1163 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1164     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1165 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1166     <head>
1167     <meta http-equiv="Content-Language" content="en" />
1168     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1169         <title>$name on Catalyst $VERSION</title>
1170         <style type="text/css">
1171             body {
1172                 color: #000;
1173                 background-color: #eee;
1174             }
1175             div#content {
1176                 width: 640px;
1177                 margin-left: auto;
1178                 margin-right: auto;
1179                 margin-top: 10px;
1180                 margin-bottom: 10px;
1181                 text-align: left;
1182                 background-color: #ccc;
1183                 border: 1px solid #aaa;
1184             }
1185             p, h1, h2 {
1186                 margin-left: 20px;
1187                 margin-right: 20px;
1188                 font-family: verdana, tahoma, sans-serif;
1189             }
1190             a {
1191                 font-family: verdana, tahoma, sans-serif;
1192             }
1193             :link, :visited {
1194                     text-decoration: none;
1195                     color: #b00;
1196                     border-bottom: 1px dotted #bbb;
1197             }
1198             :link:hover, :visited:hover {
1199                     color: #555;
1200             }
1201             div#topbar {
1202                 margin: 0px;
1203             }
1204             pre {
1205                 margin: 10px;
1206                 padding: 8px;
1207             }
1208             div#answers {
1209                 padding: 8px;
1210                 margin: 10px;
1211                 background-color: #fff;
1212                 border: 1px solid #aaa;
1213             }
1214             h1 {
1215                 font-size: 0.9em;
1216                 font-weight: normal;
1217                 text-align: center;
1218             }
1219             h2 {
1220                 font-size: 1.0em;
1221             }
1222             p {
1223                 font-size: 0.9em;
1224             }
1225             p img {
1226                 float: right;
1227                 margin-left: 10px;
1228             }
1229             span#appname {
1230                 font-weight: bold;
1231                 font-size: 1.6em;
1232             }
1233         </style>
1234     </head>
1235     <body>
1236         <div id="content">
1237             <div id="topbar">
1238                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1239                     $VERSION</h1>
1240              </div>
1241              <div id="answers">
1242                  <p>
1243                  <img src="$logo" alt="Catalyst Logo" />
1244                  </p>
1245                  <p>Welcome to the  world of Catalyst.
1246                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1247                     framework will make web development something you had
1248                     never expected it to be: Fun, rewarding, and quick.</p>
1249                  <h2>What to do now?</h2>
1250                  <p>That really depends  on what <b>you</b> want to do.
1251                     We do, however, provide you with a few starting points.</p>
1252                  <p>If you want to jump right into web development with Catalyst
1253                     you might want to start with a tutorial.</p>
1254 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1255 </pre>
1256 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1257 <pre>
1258 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1259 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1260 </code></pre>
1261                  <h2>What to do next?</h2>
1262                  <p>Next it's time to write an actual application. Use the
1263                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1264                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1265                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1266                     they can save you a lot of work.</p>
1267                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1268                     <p>Also, be sure to check out the vast and growing
1269                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1270                     you are likely to find what you need there.
1271                     </p>
1272
1273                  <h2>Need help?</h2>
1274                  <p>Catalyst has a very active community. Here are the main places to
1275                     get in touch with us.</p>
1276                  <ul>
1277                      <li>
1278                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1279                      </li>
1280                      <li>
1281                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1282                      </li>
1283                      <li>
1284                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1285                      </li>
1286                  </ul>
1287                  <h2>In conclusion</h2>
1288                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1289                     as we enjoyed making it. Please contact us if you have ideas
1290                     for improvement or other feedback.</p>
1291              </div>
1292          </div>
1293     </body>
1294 </html>
1295 EOF
1296 }
1297
1298 =head1 INTERNAL METHODS
1299
1300 These methods are not meant to be used by end users.
1301
1302 =head2 $c->components
1303
1304 Returns a hash of components.
1305
1306 =head2 $c->context_class
1307
1308 Returns or sets the context class.
1309
1310 =head2 $c->counter
1311
1312 Returns a hashref containing coderefs and execution counts (needed for
1313 deep recursion detection).
1314
1315 =head2 $c->depth
1316
1317 Returns the number of actions on the current internal execution stack.
1318
1319 =head2 $c->dispatch
1320
1321 Dispatches a request to actions.
1322
1323 =cut
1324
1325 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1326
1327 =head2 $c->dispatcher_class
1328
1329 Returns or sets the dispatcher class.
1330
1331 =head2 $c->dump_these
1332
1333 Returns a list of 2-element array references (name, structure) pairs
1334 that will be dumped on the error page in debug mode.
1335
1336 =cut
1337
1338 sub dump_these {
1339     my $c = shift;
1340     [ Request => $c->req ],
1341     [ Response => $c->res ],
1342     [ Stash => $c->stash ],
1343     [ Config => $c->config ];
1344 }
1345
1346 =head2 $c->engine_class
1347
1348 Returns or sets the engine class.
1349
1350 =head2 $c->execute( $class, $coderef )
1351
1352 Execute a coderef in given class and catch exceptions. Errors are available
1353 via $c->error.
1354
1355 =cut
1356
1357 sub execute {
1358     my ( $c, $class, $code ) = @_;
1359     $class = $c->component($class) || $class;
1360     $c->state(0);
1361
1362     if ( $c->depth >= $RECURSION ) {
1363         my $action = "$code";
1364         $action = "/$action" unless $action =~ /->/;
1365         my $error = qq/Deep recursion detected calling "$action"/;
1366         $c->log->error($error);
1367         $c->error($error);
1368         $c->state(0);
1369         return $c->state;
1370     }
1371
1372     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1373
1374     push( @{ $c->stack }, $code );
1375
1376     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1377
1378     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1379
1380     my $last = pop( @{ $c->stack } );
1381
1382     if ( my $error = $@ ) {
1383         if ( !ref($error) and $error eq $DETACH ) {
1384             die $DETACH if($c->depth > 1);
1385         }
1386         elsif ( !ref($error) and $error eq $GO ) {
1387             die $GO if($c->depth > 0);
1388         }
1389         else {
1390             unless ( ref $error ) {
1391                 no warnings 'uninitialized';
1392                 chomp $error;
1393                 my $class = $last->class;
1394                 my $name  = $last->name;
1395                 $error = qq/Caught exception in $class->$name "$error"/;
1396             }
1397             $c->error($error);
1398             $c->state(0);
1399         }
1400     }
1401     return $c->state;
1402 }
1403
1404 sub _stats_start_execute {
1405     my ( $c, $code ) = @_;
1406
1407     return if ( ( $code->name =~ /^_.*/ )
1408         && ( !$c->config->{show_internal_actions} ) );
1409
1410     $c->counter->{"$code"}++;
1411
1412     my $action = "$code";
1413     $action = "/$action" unless $action =~ /->/;
1414
1415     # determine if the call was the result of a forward
1416     # this is done by walking up the call stack and looking for a calling
1417     # sub of Catalyst::forward before the eval
1418     my $callsub = q{};
1419     for my $index ( 2 .. 11 ) {
1420         last
1421         if ( ( caller($index) )[0] eq 'Catalyst'
1422             && ( caller($index) )[3] eq '(eval)' );
1423
1424         if ( ( caller($index) )[3] =~ /forward$/ ) {
1425             $callsub = ( caller($index) )[3];
1426             $action  = "-> $action";
1427             last;
1428         }
1429     }
1430
1431     my $uid = "$code" . $c->counter->{"$code"};
1432
1433     # is this a root-level call or a forwarded call?
1434     if ( $callsub =~ /forward$/ ) {
1435
1436         # forward, locate the caller
1437         if ( my $parent = $c->stack->[-1] ) {
1438             $c->stats->profile(
1439                 begin  => $action,
1440                 parent => "$parent" . $c->counter->{"$parent"},
1441                 uid    => $uid,
1442             );
1443         }
1444         else {
1445
1446             # forward with no caller may come from a plugin
1447             $c->stats->profile(
1448                 begin => $action,
1449                 uid   => $uid,
1450             );
1451         }
1452     }
1453     else {
1454
1455         # root-level call
1456         $c->stats->profile(
1457             begin => $action,
1458             uid   => $uid,
1459         );
1460     }
1461     return $action;
1462
1463 }
1464
1465 sub _stats_finish_execute {
1466     my ( $c, $info ) = @_;
1467     $c->stats->profile( end => $info );
1468 }
1469
1470 =head2 $c->_localize_fields( sub { }, \%keys );
1471
1472 =cut
1473
1474 sub _localize_fields {
1475     my ( $c, $localized, $code ) = ( @_ );
1476
1477     my $request = delete $localized->{request} || {};
1478     my $response = delete $localized->{response} || {};
1479
1480     local @{ $c }{ keys %$localized } = values %$localized;
1481     local @{ $c->request }{ keys %$request } = values %$request;
1482     local @{ $c->response }{ keys %$response } = values %$response;
1483
1484     $code->();
1485 }
1486
1487 =head2 $c->finalize
1488
1489 Finalizes the request.
1490
1491 =cut
1492
1493 sub finalize {
1494     my $c = shift;
1495
1496     for my $error ( @{ $c->error } ) {
1497         $c->log->error($error);
1498     }
1499
1500     # Allow engine to handle finalize flow (for POE)
1501     if ( $c->engine->can('finalize') ) {
1502         $c->engine->finalize($c);
1503     }
1504     else {
1505
1506         $c->finalize_uploads;
1507
1508         # Error
1509         if ( $#{ $c->error } >= 0 ) {
1510             $c->finalize_error;
1511         }
1512
1513         $c->finalize_headers;
1514
1515         # HEAD request
1516         if ( $c->request->method eq 'HEAD' ) {
1517             $c->response->body('');
1518         }
1519
1520         $c->finalize_body;
1521     }
1522
1523     if ($c->use_stats) {
1524         my $elapsed = sprintf '%f', $c->stats->elapsed;
1525         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1526         $c->log->info(
1527             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1528     }
1529
1530     return $c->response->status;
1531 }
1532
1533 =head2 $c->finalize_body
1534
1535 Finalizes body.
1536
1537 =cut
1538
1539 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1540
1541 =head2 $c->finalize_cookies
1542
1543 Finalizes cookies.
1544
1545 =cut
1546
1547 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1548
1549 =head2 $c->finalize_error
1550
1551 Finalizes error.
1552
1553 =cut
1554
1555 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1556
1557 =head2 $c->finalize_headers
1558
1559 Finalizes headers.
1560
1561 =cut
1562
1563 sub finalize_headers {
1564     my $c = shift;
1565
1566     # Check if we already finalized headers
1567     return if $c->response->{_finalized_headers};
1568
1569     # Handle redirects
1570     if ( my $location = $c->response->redirect ) {
1571         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1572         $c->response->header( Location => $location );
1573
1574         if ( !$c->response->body ) {
1575             # Add a default body if none is already present
1576             $c->response->body(
1577                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1578             );
1579         }
1580     }
1581
1582     # Content-Length
1583     if ( $c->response->body && !$c->response->content_length ) {
1584
1585         # get the length from a filehandle
1586         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1587         {
1588             my $stat = stat $c->response->body;
1589             if ( $stat && $stat->size > 0 ) {
1590                 $c->response->content_length( $stat->size );
1591             }
1592             else {
1593                 $c->log->warn('Serving filehandle without a content-length');
1594             }
1595         }
1596         else {
1597             # everything should be bytes at this point, but just in case
1598             $c->response->content_length( bytes::length( $c->response->body ) );
1599         }
1600     }
1601
1602     # Errors
1603     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1604         $c->response->headers->remove_header("Content-Length");
1605         $c->response->body('');
1606     }
1607
1608     $c->finalize_cookies;
1609
1610     $c->engine->finalize_headers( $c, @_ );
1611
1612     # Done
1613     $c->response->{_finalized_headers} = 1;
1614 }
1615
1616 =head2 $c->finalize_output
1617
1618 An alias for finalize_body.
1619
1620 =head2 $c->finalize_read
1621
1622 Finalizes the input after reading is complete.
1623
1624 =cut
1625
1626 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1627
1628 =head2 $c->finalize_uploads
1629
1630 Finalizes uploads. Cleans up any temporary files.
1631
1632 =cut
1633
1634 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1635
1636 =head2 $c->get_action( $action, $namespace )
1637
1638 Gets an action in a given namespace.
1639
1640 =cut
1641
1642 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1643
1644 =head2 $c->get_actions( $action, $namespace )
1645
1646 Gets all actions of a given name in a namespace and all parent
1647 namespaces.
1648
1649 =cut
1650
1651 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1652
1653 =head2 $c->handle_request( $class, @arguments )
1654
1655 Called to handle each HTTP request.
1656
1657 =cut
1658
1659 sub handle_request {
1660     my ( $class, @arguments ) = @_;
1661
1662     # Always expect worst case!
1663     my $status = -1;
1664     eval {
1665         if ($class->debug) {
1666             my $secs = time - $START || 1;
1667             my $av = sprintf '%.3f', $COUNT / $secs;
1668             my $time = localtime time;
1669             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1670         }
1671
1672         my $c = $class->prepare(@arguments);
1673         $c->dispatch;
1674         $status = $c->finalize;
1675     };
1676
1677     if ( my $error = $@ ) {
1678         chomp $error;
1679         $class->log->error(qq/Caught exception in engine "$error"/);
1680     }
1681
1682     $COUNT++;
1683     $class->log->_flush() if $class->log->can('_flush');
1684     return $status;
1685 }
1686
1687 =head2 $c->prepare( @arguments )
1688
1689 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1690 etc.).
1691
1692 =cut
1693
1694 sub prepare {
1695     my ( $class, @arguments ) = @_;
1696
1697     $class->context_class( ref $class || $class ) unless $class->context_class;
1698     my $c = $class->context_class->new(
1699         {
1700             counter => {},
1701             stack   => [],
1702             request => $class->request_class->new(
1703                 {
1704                     arguments        => [],
1705                     body_parameters  => {},
1706                     cookies          => {},
1707                     headers          => HTTP::Headers->new,
1708                     parameters       => {},
1709                     query_parameters => {},
1710                     secure           => 0,
1711                     captures         => [],
1712                     uploads          => {}
1713                 }
1714             ),
1715             response => $class->response_class->new(
1716                 {
1717                     body    => '',
1718                     cookies => {},
1719                     headers => HTTP::Headers->new(),
1720                     status  => 200
1721                 }
1722             ),
1723             stash => {},
1724             state => 0
1725         }
1726     );
1727
1728     $c->stats($class->stats_class->new)->enable($c->use_stats);
1729     if ( $c->debug ) {
1730         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1731     }
1732
1733     # For on-demand data
1734     $c->request->{_context}  = $c;
1735     $c->response->{_context} = $c;
1736     weaken( $c->request->{_context} );
1737     weaken( $c->response->{_context} );
1738
1739     # Allow engine to direct the prepare flow (for POE)
1740     if ( $c->engine->can('prepare') ) {
1741         $c->engine->prepare( $c, @arguments );
1742     }
1743     else {
1744         $c->prepare_request(@arguments);
1745         $c->prepare_connection;
1746         $c->prepare_query_parameters;
1747         $c->prepare_headers;
1748         $c->prepare_cookies;
1749         $c->prepare_path;
1750
1751         # Prepare the body for reading, either by prepare_body
1752         # or the user, if they are using $c->read
1753         $c->prepare_read;
1754
1755         # Parse the body unless the user wants it on-demand
1756         unless ( $c->config->{parse_on_demand} ) {
1757             $c->prepare_body;
1758         }
1759     }
1760
1761     my $method  = $c->req->method  || '';
1762     my $path    = $c->req->path;
1763     $path       = '/' unless length $path;
1764     my $address = $c->req->address || '';
1765
1766     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1767       if $c->debug;
1768
1769     $c->prepare_action;
1770
1771     return $c;
1772 }
1773
1774 =head2 $c->prepare_action
1775
1776 Prepares action. See L<Catalyst::Dispatcher>.
1777
1778 =cut
1779
1780 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1781
1782 =head2 $c->prepare_body
1783
1784 Prepares message body.
1785
1786 =cut
1787
1788 sub prepare_body {
1789     my $c = shift;
1790
1791     # Do we run for the first time?
1792     return if defined $c->request->{_body};
1793
1794     # Initialize on-demand data
1795     $c->engine->prepare_body( $c, @_ );
1796     $c->prepare_parameters;
1797     $c->prepare_uploads;
1798
1799     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1800         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1801         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1802             my $param = $c->req->body_parameters->{$key};
1803             my $value = defined($param) ? $param : '';
1804             $t->row( $key,
1805                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1806         }
1807         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1808     }
1809 }
1810
1811 =head2 $c->prepare_body_chunk( $chunk )
1812
1813 Prepares a chunk of data before sending it to L<HTTP::Body>.
1814
1815 See L<Catalyst::Engine>.
1816
1817 =cut
1818
1819 sub prepare_body_chunk {
1820     my $c = shift;
1821     $c->engine->prepare_body_chunk( $c, @_ );
1822 }
1823
1824 =head2 $c->prepare_body_parameters
1825
1826 Prepares body parameters.
1827
1828 =cut
1829
1830 sub prepare_body_parameters {
1831     my $c = shift;
1832     $c->engine->prepare_body_parameters( $c, @_ );
1833 }
1834
1835 =head2 $c->prepare_connection
1836
1837 Prepares connection.
1838
1839 =cut
1840
1841 sub prepare_connection {
1842     my $c = shift;
1843     $c->engine->prepare_connection( $c, @_ );
1844 }
1845
1846 =head2 $c->prepare_cookies
1847
1848 Prepares cookies.
1849
1850 =cut
1851
1852 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1853
1854 =head2 $c->prepare_headers
1855
1856 Prepares headers.
1857
1858 =cut
1859
1860 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1861
1862 =head2 $c->prepare_parameters
1863
1864 Prepares parameters.
1865
1866 =cut
1867
1868 sub prepare_parameters {
1869     my $c = shift;
1870     $c->prepare_body_parameters;
1871     $c->engine->prepare_parameters( $c, @_ );
1872 }
1873
1874 =head2 $c->prepare_path
1875
1876 Prepares path and base.
1877
1878 =cut
1879
1880 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1881
1882 =head2 $c->prepare_query_parameters
1883
1884 Prepares query parameters.
1885
1886 =cut
1887
1888 sub prepare_query_parameters {
1889     my $c = shift;
1890
1891     $c->engine->prepare_query_parameters( $c, @_ );
1892
1893     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1894         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1895         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1896             my $param = $c->req->query_parameters->{$key};
1897             my $value = defined($param) ? $param : '';
1898             $t->row( $key,
1899                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1900         }
1901         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1902     }
1903 }
1904
1905 =head2 $c->prepare_read
1906
1907 Prepares the input for reading.
1908
1909 =cut
1910
1911 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1912
1913 =head2 $c->prepare_request
1914
1915 Prepares the engine request.
1916
1917 =cut
1918
1919 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1920
1921 =head2 $c->prepare_uploads
1922
1923 Prepares uploads.
1924
1925 =cut
1926
1927 sub prepare_uploads {
1928     my $c = shift;
1929
1930     $c->engine->prepare_uploads( $c, @_ );
1931
1932     if ( $c->debug && keys %{ $c->request->uploads } ) {
1933         my $t = Text::SimpleTable->new(
1934             [ 12, 'Parameter' ],
1935             [ 26, 'Filename' ],
1936             [ 18, 'Type' ],
1937             [ 9,  'Size' ]
1938         );
1939         for my $key ( sort keys %{ $c->request->uploads } ) {
1940             my $upload = $c->request->uploads->{$key};
1941             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1942                 $t->row( $key, $u->filename, $u->type, $u->size );
1943             }
1944         }
1945         $c->log->debug( "File Uploads are:\n" . $t->draw );
1946     }
1947 }
1948
1949 =head2 $c->prepare_write
1950
1951 Prepares the output for writing.
1952
1953 =cut
1954
1955 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1956
1957 =head2 $c->request_class
1958
1959 Returns or sets the request class.
1960
1961 =head2 $c->response_class
1962
1963 Returns or sets the response class.
1964
1965 =head2 $c->read( [$maxlength] )
1966
1967 Reads a chunk of data from the request body. This method is designed to
1968 be used in a while loop, reading C<$maxlength> bytes on every call.
1969 C<$maxlength> defaults to the size of the request if not specified.
1970
1971 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1972 directly.
1973
1974 Warning: If you use read(), Catalyst will not process the body,
1975 so you will not be able to access POST parameters or file uploads via
1976 $c->request.  You must handle all body parsing yourself.
1977
1978 =cut
1979
1980 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1981
1982 =head2 $c->run
1983
1984 Starts the engine.
1985
1986 =cut
1987
1988 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1989
1990 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1991
1992 Sets an action in a given namespace.
1993
1994 =cut
1995
1996 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1997
1998 =head2 $c->setup_actions($component)
1999
2000 Sets up actions for a component.
2001
2002 =cut
2003
2004 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2005
2006 =head2 $c->setup_components
2007
2008 Sets up components. Specify a C<setup_components> config option to pass
2009 additional options directly to L<Module::Pluggable>. To add additional
2010 search paths, specify a key named C<search_extra> as an array
2011 reference. Items in the array beginning with C<::> will have the
2012 application class name prepended to them.
2013
2014 All components found will also have any
2015 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2016 Note, that modules which are B<not> an I<inner package> of the main
2017 file namespace loaded will not be instantiated as components.
2018
2019 =cut
2020
2021 sub setup_components {
2022     my $class = shift;
2023
2024     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2025     my $config  = $class->config->{ setup_components };
2026     my $extra   = delete $config->{ search_extra } || [];
2027
2028     push @paths, @$extra;
2029
2030     my $locator = Module::Pluggable::Object->new(
2031         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2032         %$config
2033     );
2034
2035     my @comps = sort { length $a <=> length $b } $locator->plugins;
2036     my %comps = map { $_ => 1 } @comps;
2037
2038     for my $component ( @comps ) {
2039
2040         # We pass ignore_loaded here so that overlay files for (e.g.)
2041         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2042         # we know M::P::O found a file on disk so this is safe
2043
2044         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2045
2046         my $module  = $class->setup_component( $component );
2047         my %modules = (
2048             $component => $module,
2049             map {
2050                 $_ => $class->setup_component( $_ )
2051             } grep {
2052               not exists $comps{$_}
2053             } Devel::InnerPackage::list_packages( $component )
2054         );
2055
2056         for my $key ( keys %modules ) {
2057             $class->components->{ $key } = $modules{ $key };
2058         }
2059     }
2060 }
2061
2062 =head2 $c->setup_component
2063
2064 =cut
2065
2066 sub setup_component {
2067     my( $class, $component ) = @_;
2068
2069     unless ( $component->can( 'COMPONENT' ) ) {
2070         return $component;
2071     }
2072
2073     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2074     my $config = $class->config->{ $suffix } || {};
2075
2076     my $instance = eval { $component->COMPONENT( $class, $config ); };
2077
2078     if ( my $error = $@ ) {
2079         chomp $error;
2080         Catalyst::Exception->throw(
2081             message => qq/Couldn't instantiate component "$component", "$error"/
2082         );
2083     }
2084
2085     Catalyst::Exception->throw(
2086         message =>
2087         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2088     ) unless eval { $instance->can( 'can' ) };
2089
2090     return $instance;
2091 }
2092
2093 =head2 $c->setup_dispatcher
2094
2095 Sets up dispatcher.
2096
2097 =cut
2098
2099 sub setup_dispatcher {
2100     my ( $class, $dispatcher ) = @_;
2101
2102     if ($dispatcher) {
2103         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2104     }
2105
2106     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2107         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2108     }
2109
2110     unless ($dispatcher) {
2111         $dispatcher = $class->dispatcher_class;
2112     }
2113
2114     unless (Class::Inspector->loaded($dispatcher)) {
2115         require Class::Inspector->filename($dispatcher);
2116     }
2117
2118     # dispatcher instance
2119     $class->dispatcher( $dispatcher->new );
2120 }
2121
2122 =head2 $c->setup_engine
2123
2124 Sets up engine.
2125
2126 =cut
2127
2128 sub setup_engine {
2129     my ( $class, $engine ) = @_;
2130
2131     if ($engine) {
2132         $engine = 'Catalyst::Engine::' . $engine;
2133     }
2134
2135     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2136         $engine = 'Catalyst::Engine::' . $env;
2137     }
2138
2139     if ( $ENV{MOD_PERL} ) {
2140
2141         # create the apache method
2142         {
2143             no strict 'refs';
2144             *{"$class\::apache"} = sub { shift->engine->apache };
2145         }
2146
2147         my ( $software, $version ) =
2148           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2149
2150         $version =~ s/_//g;
2151         $version =~ s/(\.[^.]+)\./$1/g;
2152
2153         if ( $software eq 'mod_perl' ) {
2154
2155             if ( !$engine ) {
2156
2157                 if ( $version >= 1.99922 ) {
2158                     $engine = 'Catalyst::Engine::Apache2::MP20';
2159                 }
2160
2161                 elsif ( $version >= 1.9901 ) {
2162                     $engine = 'Catalyst::Engine::Apache2::MP19';
2163                 }
2164
2165                 elsif ( $version >= 1.24 ) {
2166                     $engine = 'Catalyst::Engine::Apache::MP13';
2167                 }
2168
2169                 else {
2170                     Catalyst::Exception->throw( message =>
2171                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2172                 }
2173
2174             }
2175
2176             # install the correct mod_perl handler
2177             if ( $version >= 1.9901 ) {
2178                 *handler = sub  : method {
2179                     shift->handle_request(@_);
2180                 };
2181             }
2182             else {
2183                 *handler = sub ($$) { shift->handle_request(@_) };
2184             }
2185
2186         }
2187
2188         elsif ( $software eq 'Zeus-Perl' ) {
2189             $engine = 'Catalyst::Engine::Zeus';
2190         }
2191
2192         else {
2193             Catalyst::Exception->throw(
2194                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2195         }
2196     }
2197
2198     unless ($engine) {
2199         $engine = $class->engine_class;
2200     }
2201
2202     unless (Class::Inspector->loaded($engine)) {
2203         require Class::Inspector->filename($engine);
2204     }
2205
2206     # check for old engines that are no longer compatible
2207     my $old_engine;
2208     if ( $engine->isa('Catalyst::Engine::Apache')
2209         && !Catalyst::Engine::Apache->VERSION )
2210     {
2211         $old_engine = 1;
2212     }
2213
2214     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2215         && Catalyst::Engine::Server->VERSION le '0.02' )
2216     {
2217         $old_engine = 1;
2218     }
2219
2220     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2221         && $engine->VERSION eq '0.01' )
2222     {
2223         $old_engine = 1;
2224     }
2225
2226     elsif ($engine->isa('Catalyst::Engine::Zeus')
2227         && $engine->VERSION eq '0.01' )
2228     {
2229         $old_engine = 1;
2230     }
2231
2232     if ($old_engine) {
2233         Catalyst::Exception->throw( message =>
2234               qq/Engine "$engine" is not supported by this version of Catalyst/
2235         );
2236     }
2237
2238     # engine instance
2239     $class->engine( $engine->new );
2240 }
2241
2242 =head2 $c->setup_home
2243
2244 Sets up the home directory.
2245
2246 =cut
2247
2248 sub setup_home {
2249     my ( $class, $home ) = @_;
2250
2251     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2252         $home = $env;
2253     }
2254
2255     unless ($home) {
2256         $home = Catalyst::Utils::home($class);
2257     }
2258
2259     if ($home) {
2260         $class->config->{home} ||= $home;
2261         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2262     }
2263 }
2264
2265 =head2 $c->setup_log
2266
2267 Sets up log.
2268
2269 =cut
2270
2271 sub setup_log {
2272     my ( $class, $debug ) = @_;
2273
2274     unless ( $class->log ) {
2275         $class->log( Catalyst::Log->new );
2276     }
2277
2278     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2279     if ( defined($env_debug) ? $env_debug : $debug ) {
2280         no strict 'refs';
2281         *{"$class\::debug"} = sub { 1 };
2282         $class->log->debug('Debug messages enabled');
2283     }
2284 }
2285
2286 =head2 $c->setup_plugins
2287
2288 Sets up plugins.
2289
2290 =cut
2291
2292 =head2 $c->setup_stats
2293
2294 Sets up timing statistics class.
2295
2296 =cut
2297
2298 sub setup_stats {
2299     my ( $class, $stats ) = @_;
2300
2301     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2302
2303     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2304     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2305         no strict 'refs';
2306         *{"$class\::use_stats"} = sub { 1 };
2307         $class->log->debug('Statistics enabled');
2308     }
2309 }
2310
2311
2312 =head2 $c->registered_plugins
2313
2314 Returns a sorted list of the plugins which have either been stated in the
2315 import list or which have been added via C<< MyApp->plugin(@args); >>.
2316
2317 If passed a given plugin name, it will report a boolean value indicating
2318 whether or not that plugin is loaded.  A fully qualified name is required if
2319 the plugin name does not begin with C<Catalyst::Plugin::>.
2320
2321  if ($c->registered_plugins('Some::Plugin')) {
2322      ...
2323  }
2324
2325 =cut
2326
2327 {
2328
2329     sub registered_plugins {
2330         my $proto = shift;
2331         return sort keys %{ $proto->_plugins } unless @_;
2332         my $plugin = shift;
2333         return 1 if exists $proto->_plugins->{$plugin};
2334         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2335     }
2336
2337     sub _register_plugin {
2338         my ( $proto, $plugin, $instant ) = @_;
2339         my $class = ref $proto || $proto;
2340
2341         # no ignore_loaded here, the plugin may already have been
2342         # defined in memory and we don't want to error on "no file" if so
2343
2344         Catalyst::Utils::ensure_class_loaded( $plugin );
2345
2346         $proto->_plugins->{$plugin} = 1;
2347         unless ($instant) {
2348             no strict 'refs';
2349             unshift @{"$class\::ISA"}, $plugin;
2350         }
2351         return $class;
2352     }
2353
2354     sub setup_plugins {
2355         my ( $class, $plugins ) = @_;
2356
2357         $class->_plugins( {} ) unless $class->_plugins;
2358         $plugins ||= [];
2359         for my $plugin ( reverse @$plugins ) {
2360
2361             unless ( $plugin =~ s/\A\+// ) {
2362                 $plugin = "Catalyst::Plugin::$plugin";
2363             }
2364
2365             $class->_register_plugin($plugin);
2366         }
2367     }
2368 }
2369
2370 =head2 $c->stack
2371
2372 Returns an arrayref of the internal execution stack (actions that are
2373 currently executing).
2374
2375 =head2 $c->stats_class
2376
2377 Returns or sets the stats (timing statistics) class.
2378
2379 =head2 $c->use_stats
2380
2381 Returns 1 when stats collection is enabled.  Stats collection is enabled
2382 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2383 environment variable is set.
2384
2385 Note that this is a static method, not an accessor and should be overloaded
2386 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2387
2388 =cut
2389
2390 sub use_stats { 0 }
2391
2392
2393 =head2 $c->write( $data )
2394
2395 Writes $data to the output stream. When using this method directly, you
2396 will need to manually set the C<Content-Length> header to the length of
2397 your output data, if known.
2398
2399 =cut
2400
2401 sub write {
2402     my $c = shift;
2403
2404     # Finalize headers if someone manually writes output
2405     $c->finalize_headers;
2406
2407     return $c->engine->write( $c, @_ );
2408 }
2409
2410 =head2 version
2411
2412 Returns the Catalyst version number. Mostly useful for "powered by"
2413 messages in template systems.
2414
2415 =cut
2416
2417 sub version { return $Catalyst::VERSION }
2418
2419 =head1 INTERNAL ACTIONS
2420
2421 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2422 C<_ACTION>, and C<_END>. These are by default not shown in the private
2423 action table, but you can make them visible with a config parameter.
2424
2425     MyApp->config->{show_internal_actions} = 1;
2426
2427 =head1 CASE SENSITIVITY
2428
2429 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2430 mapped to C</foo/bar>. You can activate case sensitivity with a config
2431 parameter.
2432
2433     MyApp->config->{case_sensitive} = 1;
2434
2435 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2436
2437 =head1 ON-DEMAND PARSER
2438
2439 The request body is usually parsed at the beginning of a request,
2440 but if you want to handle input yourself, you can enable on-demand
2441 parsing with a config parameter.
2442
2443     MyApp->config->{parse_on_demand} = 1;
2444
2445 =head1 PROXY SUPPORT
2446
2447 Many production servers operate using the common double-server approach,
2448 with a lightweight frontend web server passing requests to a larger
2449 backend server. An application running on the backend server must deal
2450 with two problems: the remote user always appears to be C<127.0.0.1> and
2451 the server's hostname will appear to be C<localhost> regardless of the
2452 virtual host that the user connected through.
2453
2454 Catalyst will automatically detect this situation when you are running
2455 the frontend and backend servers on the same machine. The following
2456 changes are made to the request.
2457
2458     $c->req->address is set to the user's real IP address, as read from
2459     the HTTP X-Forwarded-For header.
2460
2461     The host value for $c->req->base and $c->req->uri is set to the real
2462     host, as read from the HTTP X-Forwarded-Host header.
2463
2464 Obviously, your web server must support these headers for this to work.
2465
2466 In a more complex server farm environment where you may have your
2467 frontend proxy server(s) on different machines, you will need to set a
2468 configuration option to tell Catalyst to read the proxied data from the
2469 headers.
2470
2471     MyApp->config->{using_frontend_proxy} = 1;
2472
2473 If you do not wish to use the proxy support at all, you may set:
2474
2475     MyApp->config->{ignore_frontend_proxy} = 1;
2476
2477 =head1 THREAD SAFETY
2478
2479 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2480 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2481 believe the Catalyst core to be thread-safe.
2482
2483 If you plan to operate in a threaded environment, remember that all other
2484 modules you are using must also be thread-safe. Some modules, most notably
2485 L<DBD::SQLite>, are not thread-safe.
2486
2487 =head1 SUPPORT
2488
2489 IRC:
2490
2491     Join #catalyst on irc.perl.org.
2492
2493 Mailing Lists:
2494
2495     http://lists.rawmode.org/mailman/listinfo/catalyst
2496     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2497
2498 Web:
2499
2500     http://catalyst.perl.org
2501
2502 Wiki:
2503
2504     http://dev.catalyst.perl.org
2505
2506 =head1 SEE ALSO
2507
2508 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2509
2510 =head2 L<Catalyst::Manual> - The Catalyst Manual
2511
2512 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2513
2514 =head2 L<Catalyst::Engine> - Core engine
2515
2516 =head2 L<Catalyst::Log> - Log class.
2517
2518 =head2 L<Catalyst::Request> - Request object
2519
2520 =head2 L<Catalyst::Response> - Response object
2521
2522 =head2 L<Catalyst::Test> - The test suite.
2523
2524 =head1 PROJECT FOUNDER
2525
2526 sri: Sebastian Riedel <sri@cpan.org>
2527
2528 =head1 CONTRIBUTORS
2529
2530 abw: Andy Wardley
2531
2532 acme: Leon Brocard <leon@astray.com>
2533
2534 Andrew Bramble
2535
2536 Andrew Ford
2537
2538 Andrew Ruthven
2539
2540 andyg: Andy Grundman <andy@hybridized.org>
2541
2542 audreyt: Audrey Tang
2543
2544 bricas: Brian Cassidy <bricas@cpan.org>
2545
2546 chansen: Christian Hansen
2547
2548 chicks: Christopher Hicks
2549
2550 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2551
2552 Drew Taylor
2553
2554 esskar: Sascha Kiefer
2555
2556 fireartist: Carl Franks <cfranks@cpan.org>
2557
2558 gabb: Danijel Milicevic
2559
2560 Gary Ashton Jones
2561
2562 Geoff Richards
2563
2564 jcamacho: Juan Camacho
2565
2566 jhannah: Jay Hannah <jay@jays.net>
2567
2568 Jody Belka
2569
2570 Johan Lindstrom
2571
2572 jon: Jon Schutz <jjschutz@cpan.org>
2573
2574 marcus: Marcus Ramberg <mramberg@cpan.org>
2575
2576 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2577
2578 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2579
2580 mugwump: Sam Vilain
2581
2582 naughton: David Naughton
2583
2584 ningu: David Kamholz <dkamholz@cpan.org>
2585
2586 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2587
2588 numa: Dan Sully <daniel@cpan.org>
2589
2590 obra: Jesse Vincent
2591
2592 omega: Andreas Marienborg
2593
2594 Oleg Kostyuk <cub.uanic@gmail.com>
2595
2596 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2597
2598 sky: Arthur Bergman
2599
2600 the_jester: Jesse Sheidlower
2601
2602 Ulf Edvinsson
2603
2604 willert: Sebastian Willert <willert@cpan.org>
2605
2606 batman: Jan Henning Thorsen <pm@flodhest.net>
2607
2608 =head1 LICENSE
2609
2610 This library is free software, you can redistribute it and/or modify it under
2611 the same terms as Perl itself.
2612
2613 =cut
2614
2615 1;