lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use Text::SimpleTable ();
  17 use Path::Class::Dir ();
  18 use Path::Class::File ();
  19 use Time::HiRes qw/gettimeofday tv_interval/;
  20 use URI ();
  21 use URI::http;
  22 use URI::https;
  23 use Scalar::Util qw/weaken blessed/;
  24 use Tree::Simple qw/use_weak_refs/;
  25 use Tree::Simple::Visitor::FindByUID;
  26 use attributes;
  27 use utf8;
  28 use Carp qw/croak carp/;
  29
  30 BEGIN { require 5.008001; }
  31
  32 has stack => (is => 'rw', default => sub { [] });
  33 has stash => (is => 'rw', default => sub { {} });
  34 has state => (is => 'rw', default => 0);
  35 has stats => (is => 'rw');
  36 has action => (is => 'rw');
  37 has counter => (is => 'rw', default => sub { {} });
  38 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  39 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  40 has namespace => (is => 'rw');
  41
  42 sub depth { scalar @{ shift->stack || [] }; }
  43 sub comp { shift->component(@_) }
  44
  45 sub req {
  46     # carp "the use of req() is deprecated in favour of request()";
  47     my $self = shift; return $self->request(@_);
  48 }
  49 sub res {
  50     # carp "the use of res() is deprecated in favour of response()";
  51     my $self = shift; return $self->response(@_);
  52 }
  53
  54 # For backwards compatibility
  55 sub finalize_output { shift->finalize_body(@_) };
  56
  57 # For statistics
  58 our $COUNT     = 1;
  59 our $START     = time;
  60 our $RECURSION = 1000;
  61 our $DETACH    = "catalyst_detach\n";
  62
  63 #I imagine that very few of these really need to be class variables. if any.
  64 #maybe we should just make them attributes with a default?
  65 __PACKAGE__->mk_classdata($_)
  66   for qw/components arguments dispatcher engine log dispatcher_class
  67   engine_class context_class request_class response_class stats_class
  68   setup_finished/;
  69
  70 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  71 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  72 __PACKAGE__->request_class('Catalyst::Request');
  73 __PACKAGE__->response_class('Catalyst::Response');
  74 __PACKAGE__->stats_class('Catalyst::Stats');
  75
  76 # Remember to update this in Catalyst::Runtime as well!
  77
  78 our $VERSION = '5.8000_02';
  79
  80 sub import {
  81     my ( $class, @arguments ) = @_;
  82
  83     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  84     # callers @ISA.
  85     return unless $class eq 'Catalyst';
  86
  87     my $caller = caller();
  88     return if $caller eq 'main';
  89     my $meta = Moose::Meta::Class->initialize($caller);
  90     #Moose->import({ into => $caller }); #do we want to do this?
  91
  92     unless ( $caller->isa('Catalyst') ) {
  93         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  94         $meta->superclasses(@superclasses);
  95     }
  96     unless( $meta->has_method('meta') ){
  97         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
  98     }
  99
 100     $caller->arguments( [@arguments] );
 101     $caller->setup_home;
 102 }
 103
 104 =head1 NAME
 105
 106 Catalyst - The Elegant MVC Web Application Framework
 107
 108 =head1 SYNOPSIS
 109
 110 See the L<Catalyst::Manual> distribution for comprehensive
 111 documentation and tutorials.
 112
 113     # Install Catalyst::Devel for helpers and other development tools
 114     # use the helper to create a new application
 115     catalyst.pl MyApp
 116
 117     # add models, views, controllers
 118     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 119     script/myapp_create.pl view MyTemplate TT
 120     script/myapp_create.pl controller Search
 121
 122     # built in testserver -- use -r to restart automatically on changes
 123     # --help to see all available options
 124     script/myapp_server.pl
 125
 126     # command line testing interface
 127     script/myapp_test.pl /yada
 128
 129     ### in lib/MyApp.pm
 130     use Catalyst qw/-Debug/; # include plugins here as well
 131
 132     ### In lib/MyApp/Controller/Root.pm (autocreated)
 133     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 134         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 135         $c->stash->{template} = 'foo.tt'; # set the template
 136         # lookup something from db -- stash vars are passed to TT
 137         $c->stash->{data} =
 138           $c->model('Database::Foo')->search( { country => $args[0] } );
 139         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 140             $c->forward( 'bar' ); # process another action
 141             # do something else after forward returns
 142         }
 143     }
 144
 145     # The foo.tt TT template can use the stash data from the database
 146     [% WHILE (item = data.next) %]
 147         [% item.foo %]
 148     [% END %]
 149
 150     # called for /bar/of/soap, /bar/of/soap/10, etc.
 151     sub bar : Path('/bar/of/soap') { ... }
 152
 153     # called for all actions, from the top-most controller downwards
 154     sub auto : Private {
 155         my ( $self, $c ) = @_;
 156         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 157             $c->res->redirect( '/login' ); # require login
 158             return 0; # abort request and go immediately to end()
 159         }
 160         return 1; # success; carry on to next action
 161     }
 162
 163     # called after all actions are finished
 164     sub end : Private {
 165         my ( $self, $c ) = @_;
 166         if ( scalar @{ $c->error } ) { ... } # handle errors
 167         return if $c->res->body; # already have a response
 168         $c->forward( 'MyApp::View::TT' ); # render template
 169     }
 170
 171     ### in MyApp/Controller/Foo.pm
 172     # called for /foo/bar
 173     sub bar : Local { ... }
 174
 175     # called for /blargle
 176     sub blargle : Global { ... }
 177
 178     # an index action matches /foo, but not /foo/1, etc.
 179     sub index : Private { ... }
 180
 181     ### in MyApp/Controller/Foo/Bar.pm
 182     # called for /foo/bar/baz
 183     sub baz : Local { ... }
 184
 185     # first Root auto is called, then Foo auto, then this
 186     sub auto : Private { ... }
 187
 188     # powerful regular expression paths are also possible
 189     sub details : Regex('^product/(\w+)/details$') {
 190         my ( $self, $c ) = @_;
 191         # extract the (\w+) from the URI
 192         my $product = $c->req->captures->[0];
 193     }
 194
 195 See L<Catalyst::Manual::Intro> for additional information.
 196
 197 =head1 DESCRIPTION
 198
 199 Catalyst is a modern framework for making web applications without the
 200 pain usually associated with this process. This document is a reference
 201 to the main Catalyst application. If you are a new user, we suggest you
 202 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 203
 204 See L<Catalyst::Manual> for more documentation.
 205
 206 Catalyst plugins can be loaded by naming them as arguments to the "use
 207 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 208 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 209 C<My::Module>.
 210
 211     use Catalyst qw/My::Module/;
 212
 213 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 214 fully qualify the name by using a unary plus:
 215
 216     use Catalyst qw/
 217         My::Module
 218         +Fully::Qualified::Plugin::Name
 219     /;
 220
 221 Special flags like C<-Debug> and C<-Engine> can also be specified as
 222 arguments when Catalyst is loaded:
 223
 224     use Catalyst qw/-Debug My::Module/;
 225
 226 The position of plugins and flags in the chain is important, because
 227 they are loaded in the order in which they appear.
 228
 229 The following flags are supported:
 230
 231 =head2 -Debug
 232
 233 Enables debug output. You can also force this setting from the system
 234 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 235 settings override the application, with <MYAPP>_DEBUG having the highest
 236 priority.
 237
 238 =head2 -Engine
 239
 240 Forces Catalyst to use a specific engine. Omit the
 241 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 242
 243     use Catalyst qw/-Engine=CGI/;
 244
 245 =head2 -Home
 246
 247 Forces Catalyst to use a specific home directory, e.g.:
 248
 249     use Catalyst qw[-Home=/usr/mst];
 250
 251 This can also be done in the shell environment by setting either the
 252 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 253 is replaced with the uppercased name of your application, any "::" in
 254 the name will be replaced with underscores, e.g. MyApp::Web should use
 255 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 256
 257 =head2 -Log
 258
 259 Specifies log level.
 260
 261 =head2 -Stats
 262
 263 Enables statistics collection and reporting. You can also force this setting
 264 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 265 environment settings override the application, with <MYAPP>_STATS having the
 266 highest priority.
 267
 268 e.g.
 269
 270    use Catalyst qw/-Stats=1/
 271
 272 =head1 METHODS
 273
 274 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 275
 276 =head2 $c->action
 277
 278 Returns a L<Catalyst::Action> object for the current action, which
 279 stringifies to the action name. See L<Catalyst::Action>.
 280
 281 =head2 $c->namespace
 282
 283 Returns the namespace of the current action, i.e., the URI prefix
 284 corresponding to the controller of the current action. For example:
 285
 286     # in Controller::Foo::Bar
 287     $c->namespace; # returns 'foo/bar';
 288
 289 =head2 $c->request
 290
 291 =head2 $c->req
 292
 293 Returns the current L<Catalyst::Request> object, giving access to
 294 information about the current client request (including parameters,
 295 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 296
 297 =head2 REQUEST FLOW HANDLING
 298
 299 =head2 $c->forward( $action [, \@arguments ] )
 300
 301 =head2 $c->forward( $class, $method, [, \@arguments ] )
 302
 303 Forwards processing to another action, by its private name. If you give a
 304 class name but no method, C<process()> is called. You may also optionally
 305 pass arguments in an arrayref. The action will receive the arguments in
 306 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 307 C<< $c->req->args >> will be restored to the previous values.
 308
 309 Any data C<return>ed from the action forwarded to, will be returned by the
 310 call to forward.
 311
 312     my $foodata = $c->forward('/foo');
 313     $c->forward('index');
 314     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 315     $c->forward('MyApp::View::TT');
 316
 317 Note that forward implies an C<<eval { }>> around the call (actually
 318 C<execute> does), thus de-fatalizing all 'dies' within the called
 319 action. If you want C<die> to propagate you need to do something like:
 320
 321     $c->forward('foo');
 322     die $c->error if $c->error;
 323
 324 Or make sure to always return true values from your actions and write
 325 your code like this:
 326
 327     $c->forward('foo') || return;
 328
 329 =cut
 330
 331 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 332
 333 =head2 $c->detach( $action [, \@arguments ] )
 334
 335 =head2 $c->detach( $class, $method, [, \@arguments ] )
 336
 337 =head2 $c->detach()
 338
 339 The same as C<forward>, but doesn't return to the previous action when
 340 processing is finished.
 341
 342 When called with no arguments it escapes the processing chain entirely.
 343
 344 =cut
 345
 346 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 347
 348 =head2 $c->visit( $action [, \@arguments ] )
 349
 350 =head2 $c->visit( $class, $method, [, \@arguments ] )
 351
 352 Almost the same as C<forward>, but does a full dispatch, instead of just
 353 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 354 C<auto> and the method you go to are called, just like a new request.
 355
 356 C<$c-E<gt>stash> is kept unchanged.
 357
 358 In effect, C<visit> allows you to "wrap" another action, just as it
 359 would have been called by dispatching from a URL, while the analogous
 360 C<go> allows you to transfer control to another action as if it had
 361 been reached directly from a URL.
 362
 363 =cut
 364
 365 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 366
 367 =head2 $c->go( $action [, \@arguments ] )
 368
 369 =head2 $c->go( $class, $method, [, \@arguments ] )
 370
 371 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 372 instead of just calling the new C<$action> /
 373 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 374 method you visit are called, just like a new request.
 375
 376 C<$c-E<gt>stash> is kept unchanged.
 377
 378 =cut
 379
 380 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 381
 382 =head2 $c->response
 383
 384 =head2 $c->res
 385
 386 Returns the current L<Catalyst::Response> object, see there for details.
 387
 388 =head2 $c->stash
 389
 390 Returns a hashref to the stash, which may be used to store data and pass
 391 it between components during a request. You can also set hash keys by
 392 passing arguments. The stash is automatically sent to the view. The
 393 stash is cleared at the end of a request; it cannot be used for
 394 persistent storage (for this you must use a session; see
 395 L<Catalyst::Plugin::Session> for a complete system integrated with
 396 Catalyst).
 397
 398     $c->stash->{foo} = $bar;
 399     $c->stash( { moose => 'majestic', qux => 0 } );
 400     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 401
 402     # stash is automatically passed to the view for use in a template
 403     $c->forward( 'MyApp::View::TT' );
 404
 405 =cut
 406
 407 around stash => sub {
 408     my $orig = shift;
 409     my $c = shift;
 410     my $stash = $orig->($c);
 411     if (@_) {
 412         my $new_stash = @_ > 1 ? {@_} : $_[0];
 413         croak('stash takes a hash or hashref') unless ref $new_stash;
 414         foreach my $key ( keys %$new_stash ) {
 415           $stash->{$key} = $new_stash->{$key};
 416         }
 417     }
 418
 419     return $stash;
 420 };
 421
 422
 423 =head2 $c->error
 424
 425 =head2 $c->error($error, ...)
 426
 427 =head2 $c->error($arrayref)
 428
 429 Returns an arrayref containing error messages.  If Catalyst encounters an
 430 error while processing a request, it stores the error in $c->error.  This
 431 method should only be used to store fatal error messages.
 432
 433     my @error = @{ $c->error };
 434
 435 Add a new error.
 436
 437     $c->error('Something bad happened');
 438
 439 =cut
 440
 441 sub error {
 442     my $c = shift;
 443     if ( $_[0] ) {
 444         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 445         croak @$error unless ref $c;
 446         push @{ $c->{error} }, @$error;
 447     }
 448     elsif ( defined $_[0] ) { $c->{error} = undef }
 449     return $c->{error} || [];
 450 }
 451
 452
 453 =head2 $c->state
 454
 455 Contains the return value of the last executed action.
 456
 457 =head2 $c->clear_errors
 458
 459 Clear errors.  You probably don't want to clear the errors unless you are
 460 implementing a custom error screen.
 461
 462 This is equivalent to running
 463
 464     $c->error(0);
 465
 466 =cut
 467
 468 sub clear_errors {
 469     my $c = shift;
 470     $c->error(0);
 471 }
 472
 473 # search components given a name and some prefixes
 474 sub _comp_search_prefixes {
 475     my ( $c, $name, @prefixes ) = @_;
 476     my $appclass = ref $c || $c;
 477     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 478
 479     # map the original component name to the sub part that we will search against
 480     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 481         grep { /$filter/ } keys %{ $c->components };
 482
 483     # undef for a name will return all
 484     return keys %eligible if !defined $name;
 485
 486     my $query  = ref $name ? $name : qr/^$name$/i;
 487     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 488
 489     return map { $c->components->{ $_ } } @result if @result;
 490
 491     # if we were given a regexp to search against, we're done.
 492     return if ref $name;
 493
 494     # regexp fallback
 495     $query  = qr/$name/i;
 496     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 497
 498     # no results? try against full names
 499     if( !@result ) {
 500         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 501     }
 502
 503     # don't warn if we didn't find any results, it just might not exist
 504     if( @result ) {
 505         $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 506         $c->log->warn( 'Relying on the regexp fallback behavior for component resolution is unreliable and unsafe.' );
 507         $c->log->warn( 'If you really want to search, pass in a regexp as the argument.' );
 508     }
 509
 510     return @result;
 511 }
 512
 513 # Find possible names for a prefix
 514 sub _comp_names {
 515     my ( $c, @prefixes ) = @_;
 516     my $appclass = ref $c || $c;
 517
 518     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 519
 520     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 521     return @names;
 522 }
 523
 524 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 525 sub _filter_component {
 526     my ( $c, $comp, @args ) = @_;
 527
 528     if ( Scalar::Util::blessed($c) && eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 529         return $comp->ACCEPT_CONTEXT( $c, @args );
 530     }
 531
 532     return $comp;
 533 }
 534
 535 =head2 COMPONENT ACCESSORS
 536
 537 =head2 $c->controller($name)
 538
 539 Gets a L<Catalyst::Controller> instance by name.
 540
 541     $c->controller('Foo')->do_stuff;
 542
 543 If the name is omitted, will return the controller for the dispatched
 544 action.
 545
 546 If you want to search for controllers, pass in a regexp as the argument.
 547
 548     # find all controllers that start with Foo
 549     my @foo_controllers = $c->controller(qr{^Foo});
 550
 551
 552 =cut
 553
 554 sub controller {
 555     my ( $c, $name, @args ) = @_;
 556
 557     if( $name ) {
 558         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 559         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 560         return $c->_filter_component( $result[ 0 ], @args );
 561     }
 562
 563     return $c->component( $c->action->class );
 564 }
 565
 566 =head2 $c->model($name)
 567
 568 Gets a L<Catalyst::Model> instance by name.
 569
 570     $c->model('Foo')->do_stuff;
 571
 572 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 573
 574 If the name is omitted, it will look for
 575  - a model object in $c->stash->{current_model_instance}, then
 576  - a model name in $c->stash->{current_model}, then
 577  - a config setting 'default_model', or
 578  - check if there is only one model, and return it if that's the case.
 579
 580 If you want to search for models, pass in a regexp as the argument.
 581
 582     # find all models that start with Foo
 583     my @foo_models = $c->model(qr{^Foo});
 584
 585 =cut
 586
 587 sub model {
 588     my ( $c, $name, @args ) = @_;
 589
 590     if( $name ) {
 591         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 592         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 593         return $c->_filter_component( $result[ 0 ], @args );
 594     }
 595
 596     if (ref $c) {
 597         return $c->stash->{current_model_instance}
 598           if $c->stash->{current_model_instance};
 599         return $c->model( $c->stash->{current_model} )
 600           if $c->stash->{current_model};
 601     }
 602     return $c->model( $c->config->{default_model} )
 603       if $c->config->{default_model};
 604
 605     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 606
 607     if( $rest ) {
 608         $c->log->warn( 'Calling $c->model() will return a random model unless you specify one of:' );
 609         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 610         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 611         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 612         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 613     }
 614
 615     return $c->_filter_component( $comp );
 616 }
 617
 618
 619 =head2 $c->view($name)
 620
 621 Gets a L<Catalyst::View> instance by name.
 622
 623     $c->view('Foo')->do_stuff;
 624
 625 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 626
 627 If the name is omitted, it will look for
 628  - a view object in $c->stash->{current_view_instance}, then
 629  - a view name in $c->stash->{current_view}, then
 630  - a config setting 'default_view', or
 631  - check if there is only one view, and return it if that's the case.
 632
 633 If you want to search for views, pass in a regexp as the argument.
 634
 635     # find all views that start with Foo
 636     my @foo_views = $c->view(qr{^Foo});
 637
 638 =cut
 639
 640 sub view {
 641     my ( $c, $name, @args ) = @_;
 642
 643     if( $name ) {
 644         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 645         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 646         return $c->_filter_component( $result[ 0 ], @args );
 647     }
 648
 649     if (ref $c) {
 650         return $c->stash->{current_view_instance}
 651           if $c->stash->{current_view_instance};
 652         return $c->view( $c->stash->{current_view} )
 653           if $c->stash->{current_view};
 654     }
 655     return $c->view( $c->config->{default_view} )
 656       if $c->config->{default_view};
 657
 658     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 659
 660     if( $rest ) {
 661         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 662         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 663         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 664         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 665         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 666     }
 667
 668     return $c->_filter_component( $comp );
 669 }
 670
 671 =head2 $c->controllers
 672
 673 Returns the available names which can be passed to $c->controller
 674
 675 =cut
 676
 677 sub controllers {
 678     my ( $c ) = @_;
 679     return $c->_comp_names(qw/Controller C/);
 680 }
 681
 682 =head2 $c->models
 683
 684 Returns the available names which can be passed to $c->model
 685
 686 =cut
 687
 688 sub models {
 689     my ( $c ) = @_;
 690     return $c->_comp_names(qw/Model M/);
 691 }
 692
 693
 694 =head2 $c->views
 695
 696 Returns the available names which can be passed to $c->view
 697
 698 =cut
 699
 700 sub views {
 701     my ( $c ) = @_;
 702     return $c->_comp_names(qw/View V/);
 703 }
 704
 705 =head2 $c->comp($name)
 706
 707 =head2 $c->component($name)
 708
 709 Gets a component object by name. This method is not recommended,
 710 unless you want to get a specific component by full
 711 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 712 should be used instead.
 713
 714 If C<$name> is a regexp, a list of components matched against the full
 715 component name will be returned.
 716
 717 =cut
 718
 719 sub component {
 720     my ( $c, $name, @args ) = @_;
 721
 722     if( $name ) {
 723         my $comps = $c->components;
 724
 725         if( !ref $name ) {
 726             # is it the exact name?
 727             return $c->_filter_component( $comps->{ $name }, @args )
 728                        if exists $comps->{ $name };
 729
 730             # perhaps we just omitted "MyApp"?
 731             my $composed = ( ref $c || $c ) . "::${name}";
 732             return $c->_filter_component( $comps->{ $composed }, @args )
 733                        if exists $comps->{ $composed };
 734
 735             # search all of the models, views and controllers
 736             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 737             return $c->_filter_component( $comp, @args ) if $comp;
 738         }
 739
 740         # This is here so $c->comp( '::M::' ) works
 741         my $query = ref $name ? $name : qr{$name}i;
 742
 743         my @result = grep { m{$query} } keys %{ $c->components };
 744         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 745
 746         if( $result[ 0 ] ) {
 747             $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 748             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 749             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 750             return $c->_filter_component( $result[ 0 ], @args );
 751         }
 752
 753         # I would expect to return an empty list here, but that breaks back-compat
 754     }
 755
 756     # fallback
 757     return sort keys %{ $c->components };
 758 }
 759
 760 =head2 CLASS DATA AND HELPER CLASSES
 761
 762 =head2 $c->config
 763
 764 Returns or takes a hashref containing the application's configuration.
 765
 766     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 767
 768 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 769 like myapp.yml in your applications home directory. See
 770 L<Catalyst::Plugin::ConfigLoader>.
 771
 772     ---
 773     db: dsn:SQLite:foo.db
 774
 775
 776 =cut
 777
 778 around config => sub {
 779     my $orig = shift;
 780     my $c = shift;
 781
 782     $c->log->warn("Setting config after setup has been run is not a good idea.")
 783       if ( @_ and $c->setup_finished );
 784
 785     $c->$orig(@_);
 786 };
 787
 788 =head2 $c->log
 789
 790 Returns the logging object instance. Unless it is already set, Catalyst
 791 sets this up with a L<Catalyst::Log> object. To use your own log class,
 792 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 793 C<< __PACKAGE__->setup >>.
 794
 795  __PACKAGE__->log( MyLogger->new );
 796  __PACKAGE__->setup;
 797
 798 And later:
 799
 800     $c->log->info( 'Now logging with my own logger!' );
 801
 802 Your log class should implement the methods described in
 803 L<Catalyst::Log>.
 804
 805
 806 =head2 $c->debug
 807
 808 Overload to enable debug messages (same as -Debug option).
 809
 810 Note that this is a static method, not an accessor and should be overloaded
 811 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 812
 813 =cut
 814
 815 sub debug { 0 }
 816
 817 =head2 $c->dispatcher
 818
 819 Returns the dispatcher instance. Stringifies to class name. See
 820 L<Catalyst::Dispatcher>.
 821
 822 =head2 $c->engine
 823
 824 Returns the engine instance. Stringifies to the class name. See
 825 L<Catalyst::Engine>.
 826
 827
 828 =head2 UTILITY METHODS
 829
 830 =head2 $c->path_to(@path)
 831
 832 Merges C<@path> with C<< $c->config->{home} >> and returns a
 833 L<Path::Class::Dir> object.
 834
 835 For example:
 836
 837     $c->path_to( 'db', 'sqlite.db' );
 838
 839 =cut
 840
 841 sub path_to {
 842     my ( $c, @path ) = @_;
 843     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 844     if ( -d $path ) { return $path }
 845     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 846 }
 847
 848 =head2 $c->plugin( $name, $class, @args )
 849
 850 Helper method for plugins. It creates a classdata accessor/mutator and
 851 loads and instantiates the given class.
 852
 853     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 854
 855     $c->prototype->define_javascript_functions;
 856
 857 =cut
 858
 859 sub plugin {
 860     my ( $class, $name, $plugin, @args ) = @_;
 861     $class->_register_plugin( $plugin, 1 );
 862
 863     eval { $plugin->import };
 864     $class->mk_classdata($name);
 865     my $obj;
 866     eval { $obj = $plugin->new(@args) };
 867
 868     if ($@) {
 869         Catalyst::Exception->throw( message =>
 870               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 871     }
 872
 873     $class->$name($obj);
 874     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 875       if $class->debug;
 876 }
 877
 878 =head2 MyApp->setup
 879
 880 Initializes the dispatcher and engine, loads any plugins, and loads the
 881 model, view, and controller components. You may also specify an array
 882 of plugins to load here, if you choose to not load them in the C<use
 883 Catalyst> line.
 884
 885     MyApp->setup;
 886     MyApp->setup( qw/-Debug/ );
 887
 888 =cut
 889
 890 sub setup {
 891     my ( $class, @arguments ) = @_;
 892     $class->log->warn("Running setup twice is not a good idea.")
 893       if ( $class->setup_finished );
 894
 895     unless ( $class->isa('Catalyst') ) {
 896
 897         Catalyst::Exception->throw(
 898             message => qq/'$class' does not inherit from Catalyst/ );
 899     }
 900
 901     if ( $class->arguments ) {
 902         @arguments = ( @arguments, @{ $class->arguments } );
 903     }
 904
 905     # Process options
 906     my $flags = {};
 907
 908     foreach (@arguments) {
 909
 910         if (/^-Debug$/) {
 911             $flags->{log} =
 912               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 913         }
 914         elsif (/^-(\w+)=?(.*)$/) {
 915             $flags->{ lc $1 } = $2;
 916         }
 917         else {
 918             push @{ $flags->{plugins} }, $_;
 919         }
 920     }
 921
 922     $class->setup_home( delete $flags->{home} );
 923
 924     $class->setup_log( delete $flags->{log} );
 925     $class->setup_plugins( delete $flags->{plugins} );
 926     $class->setup_dispatcher( delete $flags->{dispatcher} );
 927     $class->setup_engine( delete $flags->{engine} );
 928     $class->setup_stats( delete $flags->{stats} );
 929
 930     for my $flag ( sort keys %{$flags} ) {
 931
 932         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 933             &$code( $class, delete $flags->{$flag} );
 934         }
 935         else {
 936             $class->log->warn(qq/Unknown flag "$flag"/);
 937         }
 938     }
 939
 940     eval { require Catalyst::Devel; };
 941     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 942         $class->log->warn(<<"EOF");
 943 You are running an old script!
 944
 945   Please update by running (this will overwrite existing files):
 946     catalyst.pl -force -scripts $class
 947
 948   or (this will not overwrite existing files):
 949     catalyst.pl -scripts $class
 950
 951 EOF
 952     }
 953
 954     if ( $class->debug ) {
 955         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 956
 957         if (@plugins) {
 958             my $t = Text::SimpleTable->new(74);
 959             $t->row($_) for @plugins;
 960             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 961         }
 962
 963         my $dispatcher = $class->dispatcher;
 964         my $engine     = $class->engine;
 965         my $home       = $class->config->{home};
 966
 967         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 968         $class->log->debug(qq/Loaded engine "$engine"/);
 969
 970         $home
 971           ? ( -d $home )
 972           ? $class->log->debug(qq/Found home "$home"/)
 973           : $class->log->debug(qq/Home "$home" doesn't exist/)
 974           : $class->log->debug(q/Couldn't find home/);
 975     }
 976
 977     # Call plugins setup
 978     {
 979         no warnings qw/redefine/;
 980         local *setup = sub { };
 981         $class->setup;
 982     }
 983
 984     # Initialize our data structure
 985     $class->components( {} );
 986
 987     $class->setup_components;
 988
 989     if ( $class->debug ) {
 990         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 991         for my $comp ( sort keys %{ $class->components } ) {
 992             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 993             $t->row( $comp, $type );
 994         }
 995         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 996           if ( keys %{ $class->components } );
 997     }
 998
 999     # Add our self to components, since we are also a component
1000     if( $class->isa('Catalyst::Controller') ){
1001       $class->components->{$class} = $class;
1002     }
1003
1004     $class->setup_actions;
1005
1006     if ( $class->debug ) {
1007         my $name = $class->config->{name} || 'Application';
1008         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1009     }
1010     $class->log->_flush() if $class->log->can('_flush');
1011
1012     $class->setup_finished(1);
1013 }
1014
1015 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1016
1017 =head2 $c->uri_for( $path, @args?, \%query_values? )
1018
1019 =over
1020
1021 =item $action
1022
1023 A Catalyst::Action object representing the Catalyst action you want to
1024 create a URI for. To get one for an action in the current controller,
1025 use C<< $c->action('someactionname') >>. To get one from different
1026 controller, fetch the controller using C<< $c->controller() >>, then
1027 call C<action_for> on it.
1028
1029 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1030 using C<< $c->req->captures >>.
1031
1032   # For the current action
1033   $c->uri_for($c->action, $c->req->captures);
1034
1035   # For the Foo action in the Bar controller
1036   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1037
1038 =cut
1039
1040 sub uri_for {
1041     my ( $c, $path, @args ) = @_;
1042
1043     if ( Scalar::Util::blessed($path) ) { # action object
1044         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1045                          ? shift(@args)
1046                          : [] );
1047         $path = $c->dispatcher->uri_for_action($path, $captures);
1048         return undef unless defined($path);
1049         $path = '/' if $path eq '';
1050     }
1051
1052     undef($path) if (defined $path && $path eq '');
1053
1054     my $params =
1055       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1056
1057     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1058     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1059
1060     unshift(@args, $path);
1061
1062     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1063         my $namespace = $c->namespace;
1064         if (defined $path) { # cheesy hack to handle path '../foo'
1065            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1066         }
1067         unshift(@args, $namespace || '');
1068     }
1069
1070     # join args with '/', or a blank string
1071     my $args = join('/', grep { defined($_) } @args);
1072     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1073     $args =~ s!^/!!;
1074     my $base = $c->req->base;
1075     my $class = ref($base);
1076     $base =~ s{(?<!/)$}{/};
1077
1078     my $query = '';
1079
1080     if (my @keys = keys %$params) {
1081       # somewhat lifted from URI::_query's query_form
1082       $query = '?'.join('&', map {
1083           my $val = $params->{$_};
1084           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1085           s/ /+/g;
1086           my $key = $_;
1087           $val = '' unless defined $val;
1088           (map {
1089               $_ = "$_";
1090               utf8::encode( $_ ) if utf8::is_utf8($_);
1091               # using the URI::Escape pattern here so utf8 chars survive
1092               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1093               s/ /+/g;
1094               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1095       } @keys);
1096     }
1097
1098     my $res = bless(\"${base}${args}${query}", $class);
1099     $res;
1100 }
1101
1102 =head2 $c->welcome_message
1103
1104 Returns the Catalyst welcome HTML page.
1105
1106 =cut
1107
1108 sub welcome_message {
1109     my $c      = shift;
1110     my $name   = $c->config->{name};
1111     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1112     my $prefix = Catalyst::Utils::appprefix( ref $c );
1113     $c->response->content_type('text/html; charset=utf-8');
1114     return <<"EOF";
1115 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1116     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1117 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1118     <head>
1119     <meta http-equiv="Content-Language" content="en" />
1120     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1121         <title>$name on Catalyst $VERSION</title>
1122         <style type="text/css">
1123             body {
1124                 color: #000;
1125                 background-color: #eee;
1126             }
1127             div#content {
1128                 width: 640px;
1129                 margin-left: auto;
1130                 margin-right: auto;
1131                 margin-top: 10px;
1132                 margin-bottom: 10px;
1133                 text-align: left;
1134                 background-color: #ccc;
1135                 border: 1px solid #aaa;
1136             }
1137             p, h1, h2 {
1138                 margin-left: 20px;
1139                 margin-right: 20px;
1140                 font-family: verdana, tahoma, sans-serif;
1141             }
1142             a {
1143                 font-family: verdana, tahoma, sans-serif;
1144             }
1145             :link, :visited {
1146                     text-decoration: none;
1147                     color: #b00;
1148                     border-bottom: 1px dotted #bbb;
1149             }
1150             :link:hover, :visited:hover {
1151                     color: #555;
1152             }
1153             div#topbar {
1154                 margin: 0px;
1155             }
1156             pre {
1157                 margin: 10px;
1158                 padding: 8px;
1159             }
1160             div#answers {
1161                 padding: 8px;
1162                 margin: 10px;
1163                 background-color: #fff;
1164                 border: 1px solid #aaa;
1165             }
1166             h1 {
1167                 font-size: 0.9em;
1168                 font-weight: normal;
1169                 text-align: center;
1170             }
1171             h2 {
1172                 font-size: 1.0em;
1173             }
1174             p {
1175                 font-size: 0.9em;
1176             }
1177             p img {
1178                 float: right;
1179                 margin-left: 10px;
1180             }
1181             span#appname {
1182                 font-weight: bold;
1183                 font-size: 1.6em;
1184             }
1185         </style>
1186     </head>
1187     <body>
1188         <div id="content">
1189             <div id="topbar">
1190                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1191                     $VERSION</h1>
1192              </div>
1193              <div id="answers">
1194                  <p>
1195                  <img src="$logo" alt="Catalyst Logo" />
1196                  </p>
1197                  <p>Welcome to the  world of Catalyst.
1198                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1199                     framework will make web development something you had
1200                     never expected it to be: Fun, rewarding, and quick.</p>
1201                  <h2>What to do now?</h2>
1202                  <p>That really depends  on what <b>you</b> want to do.
1203                     We do, however, provide you with a few starting points.</p>
1204                  <p>If you want to jump right into web development with Catalyst
1205                     you might want to start with a tutorial.</p>
1206 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1207 </pre>
1208 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1209 <pre>
1210 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1211 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1212 </code></pre>
1213                  <h2>What to do next?</h2>
1214                  <p>Next it's time to write an actual application. Use the
1215                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1216                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1217                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1218                     they can save you a lot of work.</p>
1219                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1220                     <p>Also, be sure to check out the vast and growing
1221                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1222                     you are likely to find what you need there.
1223                     </p>
1224
1225                  <h2>Need help?</h2>
1226                  <p>Catalyst has a very active community. Here are the main places to
1227                     get in touch with us.</p>
1228                  <ul>
1229                      <li>
1230                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1231                      </li>
1232                      <li>
1233                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1234                      </li>
1235                      <li>
1236                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1237                      </li>
1238                  </ul>
1239                  <h2>In conclusion</h2>
1240                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1241                     as we enjoyed making it. Please contact us if you have ideas
1242                     for improvement or other feedback.</p>
1243              </div>
1244          </div>
1245     </body>
1246 </html>
1247 EOF
1248 }
1249
1250 =head1 INTERNAL METHODS
1251
1252 These methods are not meant to be used by end users.
1253
1254 =head2 $c->components
1255
1256 Returns a hash of components.
1257
1258 =head2 $c->context_class
1259
1260 Returns or sets the context class.
1261
1262 =head2 $c->counter
1263
1264 Returns a hashref containing coderefs and execution counts (needed for
1265 deep recursion detection).
1266
1267 =head2 $c->depth
1268
1269 Returns the number of actions on the current internal execution stack.
1270
1271 =head2 $c->dispatch
1272
1273 Dispatches a request to actions.
1274
1275 =cut
1276
1277 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1278
1279 =head2 $c->dispatcher_class
1280
1281 Returns or sets the dispatcher class.
1282
1283 =head2 $c->dump_these
1284
1285 Returns a list of 2-element array references (name, structure) pairs
1286 that will be dumped on the error page in debug mode.
1287
1288 =cut
1289
1290 sub dump_these {
1291     my $c = shift;
1292     [ Request => $c->req ],
1293     [ Response => $c->res ],
1294     [ Stash => $c->stash ],
1295     [ Config => $c->config ];
1296 }
1297
1298 =head2 $c->engine_class
1299
1300 Returns or sets the engine class.
1301
1302 =head2 $c->execute( $class, $coderef )
1303
1304 Execute a coderef in given class and catch exceptions. Errors are available
1305 via $c->error.
1306
1307 =cut
1308
1309 sub execute {
1310     my ( $c, $class, $code ) = @_;
1311     $class = $c->component($class) || $class;
1312     $c->state(0);
1313
1314     if ( $c->depth >= $RECURSION ) {
1315         my $action = $code->reverse();
1316         $action = "/$action" unless $action =~ /->/;
1317         my $error = qq/Deep recursion detected calling "${action}"/;
1318         $c->log->error($error);
1319         $c->error($error);
1320         $c->state(0);
1321         return $c->state;
1322     }
1323
1324     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1325
1326     push( @{ $c->stack }, $code );
1327
1328     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1329
1330     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1331
1332     my $last = pop( @{ $c->stack } );
1333
1334     if ( my $error = $@ ) {
1335         if ( !ref($error) and $error eq $DETACH ) {
1336             die $DETACH if($c->depth > 1);
1337         }
1338         else {
1339             unless ( ref $error ) {
1340                 no warnings 'uninitialized';
1341                 chomp $error;
1342                 my $class = $last->class;
1343                 my $name  = $last->name;
1344                 $error = qq/Caught exception in $class->$name "$error"/;
1345             }
1346             $c->error($error);
1347             $c->state(0);
1348         }
1349     }
1350     return $c->state;
1351 }
1352
1353 sub _stats_start_execute {
1354     my ( $c, $code ) = @_;
1355
1356     return if ( ( $code->name =~ /^_.*/ )
1357         && ( !$c->config->{show_internal_actions} ) );
1358
1359     my $action_name = $code->reverse();
1360     $c->counter->{$action_name}++;
1361
1362     my $action = $action_name;
1363     $action = "/$action" unless $action =~ /->/;
1364
1365     # determine if the call was the result of a forward
1366     # this is done by walking up the call stack and looking for a calling
1367     # sub of Catalyst::forward before the eval
1368     my $callsub = q{};
1369     for my $index ( 2 .. 11 ) {
1370         last
1371         if ( ( caller($index) )[0] eq 'Catalyst'
1372             && ( caller($index) )[3] eq '(eval)' );
1373
1374         if ( ( caller($index) )[3] =~ /forward$/ ) {
1375             $callsub = ( caller($index) )[3];
1376             $action  = "-> $action";
1377             last;
1378         }
1379     }
1380
1381     my $uid = $action_name . $c->counter->{$action_name};
1382
1383     # is this a root-level call or a forwarded call?
1384     if ( $callsub =~ /forward$/ ) {
1385
1386         # forward, locate the caller
1387         if ( my $parent = $c->stack->[-1] ) {
1388             $c->stats->profile(
1389                 begin  => $action,
1390                 parent => "$parent" . $c->counter->{"$parent"},
1391                 uid    => $uid,
1392             );
1393         }
1394         else {
1395
1396             # forward with no caller may come from a plugin
1397             $c->stats->profile(
1398                 begin => $action,
1399                 uid   => $uid,
1400             );
1401         }
1402     }
1403     else {
1404
1405         # root-level call
1406         $c->stats->profile(
1407             begin => $action,
1408             uid   => $uid,
1409         );
1410     }
1411     return $action;
1412
1413 }
1414
1415 sub _stats_finish_execute {
1416     my ( $c, $info ) = @_;
1417     $c->stats->profile( end => $info );
1418 }
1419
1420 =head2 $c->_localize_fields( sub { }, \%keys );
1421
1422 =cut
1423
1424 #Why does this exist? This is no longer safe and WILL NOT WORK.
1425 # it doesnt seem to be used anywhere. can we remove it?
1426 sub _localize_fields {
1427     my ( $c, $localized, $code ) = ( @_ );
1428
1429     my $request = delete $localized->{request} || {};
1430     my $response = delete $localized->{response} || {};
1431
1432     local @{ $c }{ keys %$localized } = values %$localized;
1433     local @{ $c->request }{ keys %$request } = values %$request;
1434     local @{ $c->response }{ keys %$response } = values %$response;
1435
1436     $code->();
1437 }
1438
1439 =head2 $c->finalize
1440
1441 Finalizes the request.
1442
1443 =cut
1444
1445 sub finalize {
1446     my $c = shift;
1447
1448     for my $error ( @{ $c->error } ) {
1449         $c->log->error($error);
1450     }
1451
1452     # Allow engine to handle finalize flow (for POE)
1453     my $engine = $c->engine;
1454     if ( my $code = $engine->can('finalize') ) {
1455         $engine->$code($c);
1456     }
1457     else {
1458
1459         $c->finalize_uploads;
1460
1461         # Error
1462         if ( $#{ $c->error } >= 0 ) {
1463             $c->finalize_error;
1464         }
1465
1466         $c->finalize_headers;
1467
1468         # HEAD request
1469         if ( $c->request->method eq 'HEAD' ) {
1470             $c->response->body('');
1471         }
1472
1473         $c->finalize_body;
1474     }
1475
1476     if ($c->use_stats) {
1477         my $elapsed = sprintf '%f', $c->stats->elapsed;
1478         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1479         $c->log->info(
1480             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1481     }
1482
1483     return $c->response->status;
1484 }
1485
1486 =head2 $c->finalize_body
1487
1488 Finalizes body.
1489
1490 =cut
1491
1492 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1493
1494 =head2 $c->finalize_cookies
1495
1496 Finalizes cookies.
1497
1498 =cut
1499
1500 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1501
1502 =head2 $c->finalize_error
1503
1504 Finalizes error.
1505
1506 =cut
1507
1508 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1509
1510 =head2 $c->finalize_headers
1511
1512 Finalizes headers.
1513
1514 =cut
1515
1516 sub finalize_headers {
1517     my $c = shift;
1518
1519     my $response = $c->response; #accessor calls can add up?
1520
1521     # Check if we already finalized headers
1522     return if $response->finalized_headers;
1523
1524     # Handle redirects
1525     if ( my $location = $response->redirect ) {
1526         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1527         $response->header( Location => $location );
1528
1529         #Moose TODO: we should probably be using a predicate method here ?
1530         if ( !$response->body ) {
1531             # Add a default body if none is already present
1532             $response->body(
1533                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1534             );
1535         }
1536     }
1537
1538     # Content-Length
1539     if ( $response->body && !$response->content_length ) {
1540
1541         # get the length from a filehandle
1542         if ( blessed( $response->body ) && $response->body->can('read') )
1543         {
1544             my $stat = stat $response->body;
1545             if ( $stat && $stat->size > 0 ) {
1546                 $response->content_length( $stat->size );
1547             }
1548             else {
1549                 $c->log->warn('Serving filehandle without a content-length');
1550             }
1551         }
1552         else {
1553             # everything should be bytes at this point, but just in case
1554             $response->content_length( bytes::length( $response->body ) );
1555         }
1556     }
1557
1558     # Errors
1559     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1560         $response->headers->remove_header("Content-Length");
1561         $response->body('');
1562     }
1563
1564     $c->finalize_cookies;
1565
1566     $c->engine->finalize_headers( $c, @_ );
1567
1568     # Done
1569     $response->finalized_headers(1);
1570 }
1571
1572 =head2 $c->finalize_output
1573
1574 An alias for finalize_body.
1575
1576 =head2 $c->finalize_read
1577
1578 Finalizes the input after reading is complete.
1579
1580 =cut
1581
1582 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1583
1584 =head2 $c->finalize_uploads
1585
1586 Finalizes uploads. Cleans up any temporary files.
1587
1588 =cut
1589
1590 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1591
1592 =head2 $c->get_action( $action, $namespace )
1593
1594 Gets an action in a given namespace.
1595
1596 =cut
1597
1598 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1599
1600 =head2 $c->get_actions( $action, $namespace )
1601
1602 Gets all actions of a given name in a namespace and all parent
1603 namespaces.
1604
1605 =cut
1606
1607 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1608
1609 =head2 $c->handle_request( $class, @arguments )
1610
1611 Called to handle each HTTP request.
1612
1613 =cut
1614
1615 sub handle_request {
1616     my ( $class, @arguments ) = @_;
1617
1618     # Always expect worst case!
1619     my $status = -1;
1620     eval {
1621         if ($class->debug) {
1622             my $secs = time - $START || 1;
1623             my $av = sprintf '%.3f', $COUNT / $secs;
1624             my $time = localtime time;
1625             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1626         }
1627
1628         my $c = $class->prepare(@arguments);
1629         $c->dispatch;
1630         $status = $c->finalize;
1631     };
1632
1633     if ( my $error = $@ ) {
1634         chomp $error;
1635         $class->log->error(qq/Caught exception in engine "$error"/);
1636     }
1637
1638     $COUNT++;
1639
1640     if(my $coderef = $class->log->can('_flush')){
1641         $class->log->$coderef();
1642     }
1643     return $status;
1644 }
1645
1646 =head2 $c->prepare( @arguments )
1647
1648 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1649 etc.).
1650
1651 =cut
1652
1653 sub prepare {
1654     my ( $class, @arguments ) = @_;
1655
1656     # XXX
1657     # After the app/ctxt split, this should become an attribute based on something passed
1658     # into the application.
1659     $class->context_class( ref $class || $class ) unless $class->context_class;
1660
1661     my $c = $class->context_class->new({});
1662
1663     # For on-demand data
1664     $c->request->_context($c);
1665     $c->response->_context($c);
1666
1667     #surely this is not the most efficient way to do things...
1668     $c->stats($class->stats_class->new)->enable($c->use_stats);
1669     if ( $c->debug ) {
1670         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1671     }
1672
1673     #XXX reuse coderef from can
1674     # Allow engine to direct the prepare flow (for POE)
1675     if ( $c->engine->can('prepare') ) {
1676         $c->engine->prepare( $c, @arguments );
1677     }
1678     else {
1679         $c->prepare_request(@arguments);
1680         $c->prepare_connection;
1681         $c->prepare_query_parameters;
1682         $c->prepare_headers;
1683         $c->prepare_cookies;
1684         $c->prepare_path;
1685
1686         # Prepare the body for reading, either by prepare_body
1687         # or the user, if they are using $c->read
1688         $c->prepare_read;
1689
1690         # Parse the body unless the user wants it on-demand
1691         unless ( $c->config->{parse_on_demand} ) {
1692             $c->prepare_body;
1693         }
1694     }
1695
1696     my $method  = $c->req->method  || '';
1697     my $path    = $c->req->path;
1698     $path       = '/' unless length $path;
1699     my $address = $c->req->address || '';
1700
1701     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1702       if $c->debug;
1703
1704     $c->prepare_action;
1705
1706     return $c;
1707 }
1708
1709 =head2 $c->prepare_action
1710
1711 Prepares action. See L<Catalyst::Dispatcher>.
1712
1713 =cut
1714
1715 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1716
1717 =head2 $c->prepare_body
1718
1719 Prepares message body.
1720
1721 =cut
1722
1723 sub prepare_body {
1724     my $c = shift;
1725
1726     #Moose TODO: what is  _body ??
1727     # Do we run for the first time?
1728     return if defined $c->request->{_body};
1729
1730     # Initialize on-demand data
1731     $c->engine->prepare_body( $c, @_ );
1732     $c->prepare_parameters;
1733     $c->prepare_uploads;
1734
1735     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1736         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1737         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1738             my $param = $c->req->body_parameters->{$key};
1739             my $value = defined($param) ? $param : '';
1740             $t->row( $key,
1741                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1742         }
1743         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1744     }
1745 }
1746
1747 =head2 $c->prepare_body_chunk( $chunk )
1748
1749 Prepares a chunk of data before sending it to L<HTTP::Body>.
1750
1751 See L<Catalyst::Engine>.
1752
1753 =cut
1754
1755 sub prepare_body_chunk {
1756     my $c = shift;
1757     $c->engine->prepare_body_chunk( $c, @_ );
1758 }
1759
1760 =head2 $c->prepare_body_parameters
1761
1762 Prepares body parameters.
1763
1764 =cut
1765
1766 sub prepare_body_parameters {
1767     my $c = shift;
1768     $c->engine->prepare_body_parameters( $c, @_ );
1769 }
1770
1771 =head2 $c->prepare_connection
1772
1773 Prepares connection.
1774
1775 =cut
1776
1777 sub prepare_connection {
1778     my $c = shift;
1779     $c->engine->prepare_connection( $c, @_ );
1780 }
1781
1782 =head2 $c->prepare_cookies
1783
1784 Prepares cookies.
1785
1786 =cut
1787
1788 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1789
1790 =head2 $c->prepare_headers
1791
1792 Prepares headers.
1793
1794 =cut
1795
1796 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1797
1798 =head2 $c->prepare_parameters
1799
1800 Prepares parameters.
1801
1802 =cut
1803
1804 sub prepare_parameters {
1805     my $c = shift;
1806     $c->prepare_body_parameters;
1807     $c->engine->prepare_parameters( $c, @_ );
1808 }
1809
1810 =head2 $c->prepare_path
1811
1812 Prepares path and base.
1813
1814 =cut
1815
1816 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1817
1818 =head2 $c->prepare_query_parameters
1819
1820 Prepares query parameters.
1821
1822 =cut
1823
1824 sub prepare_query_parameters {
1825     my $c = shift;
1826
1827     $c->engine->prepare_query_parameters( $c, @_ );
1828
1829     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1830         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1831         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1832             my $param = $c->req->query_parameters->{$key};
1833             my $value = defined($param) ? $param : '';
1834             $t->row( $key,
1835                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1836         }
1837         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1838     }
1839 }
1840
1841 =head2 $c->prepare_read
1842
1843 Prepares the input for reading.
1844
1845 =cut
1846
1847 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1848
1849 =head2 $c->prepare_request
1850
1851 Prepares the engine request.
1852
1853 =cut
1854
1855 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1856
1857 =head2 $c->prepare_uploads
1858
1859 Prepares uploads.
1860
1861 =cut
1862
1863 sub prepare_uploads {
1864     my $c = shift;
1865
1866     $c->engine->prepare_uploads( $c, @_ );
1867
1868     if ( $c->debug && keys %{ $c->request->uploads } ) {
1869         my $t = Text::SimpleTable->new(
1870             [ 12, 'Parameter' ],
1871             [ 26, 'Filename' ],
1872             [ 18, 'Type' ],
1873             [ 9,  'Size' ]
1874         );
1875         for my $key ( sort keys %{ $c->request->uploads } ) {
1876             my $upload = $c->request->uploads->{$key};
1877             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1878                 $t->row( $key, $u->filename, $u->type, $u->size );
1879             }
1880         }
1881         $c->log->debug( "File Uploads are:\n" . $t->draw );
1882     }
1883 }
1884
1885 =head2 $c->prepare_write
1886
1887 Prepares the output for writing.
1888
1889 =cut
1890
1891 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1892
1893 =head2 $c->request_class
1894
1895 Returns or sets the request class.
1896
1897 =head2 $c->response_class
1898
1899 Returns or sets the response class.
1900
1901 =head2 $c->read( [$maxlength] )
1902
1903 Reads a chunk of data from the request body. This method is designed to
1904 be used in a while loop, reading C<$maxlength> bytes on every call.
1905 C<$maxlength> defaults to the size of the request if not specified.
1906
1907 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1908 directly.
1909
1910 Warning: If you use read(), Catalyst will not process the body,
1911 so you will not be able to access POST parameters or file uploads via
1912 $c->request.  You must handle all body parsing yourself.
1913
1914 =cut
1915
1916 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1917
1918 =head2 $c->run
1919
1920 Starts the engine.
1921
1922 =cut
1923
1924 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1925
1926 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1927
1928 Sets an action in a given namespace.
1929
1930 =cut
1931
1932 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1933
1934 =head2 $c->setup_actions($component)
1935
1936 Sets up actions for a component.
1937
1938 =cut
1939
1940 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1941
1942 =head2 $c->setup_components
1943
1944 Sets up components. Specify a C<setup_components> config option to pass
1945 additional options directly to L<Module::Pluggable>. To add additional
1946 search paths, specify a key named C<search_extra> as an array
1947 reference. Items in the array beginning with C<::> will have the
1948 application class name prepended to them.
1949
1950 All components found will also have any
1951 L<Devel::InnerPackage|inner packages> loaded and set up as components.
1952 Note, that modules which are B<not> an I<inner package> of the main
1953 file namespace loaded will not be instantiated as components.
1954
1955 =cut
1956
1957 sub setup_components {
1958     my $class = shift;
1959
1960     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1961     my $config  = $class->config->{ setup_components };
1962     my $extra   = delete $config->{ search_extra } || [];
1963
1964     push @paths, @$extra;
1965
1966     my $locator = Module::Pluggable::Object->new(
1967         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1968         %$config
1969     );
1970
1971     my @comps = sort { length $a <=> length $b } $locator->plugins;
1972     my %comps = map { $_ => 1 } @comps;
1973
1974     for my $component ( @comps ) {
1975
1976         # We pass ignore_loaded here so that overlay files for (e.g.)
1977         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
1978         # we know M::P::O found a file on disk so this is safe
1979
1980         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1981         #Class::MOP::load_class($component);
1982
1983         my $module  = $class->setup_component( $component );
1984         my %modules = (
1985             $component => $module,
1986             map {
1987                 $_ => $class->setup_component( $_ )
1988             } grep {
1989               not exists $comps{$_}
1990             } Devel::InnerPackage::list_packages( $component )
1991         );
1992
1993         for my $key ( keys %modules ) {
1994             $class->components->{ $key } = $modules{ $key };
1995         }
1996     }
1997 }
1998
1999 =head2 $c->setup_component
2000
2001 =cut
2002
2003 sub setup_component {
2004     my( $class, $component ) = @_;
2005
2006     unless ( $component->can( 'COMPONENT' ) ) {
2007         return $component;
2008     }
2009
2010     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2011     my $config = $class->config->{ $suffix } || {};
2012
2013     my $instance = eval { $component->COMPONENT( $class, $config ); };
2014
2015     if ( my $error = $@ ) {
2016         chomp $error;
2017         Catalyst::Exception->throw(
2018             message => qq/Couldn't instantiate component "$component", "$error"/
2019         );
2020     }
2021
2022     Catalyst::Exception->throw(
2023         message =>
2024         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2025     ) unless blessed($instance);
2026
2027     return $instance;
2028 }
2029
2030 =head2 $c->setup_dispatcher
2031
2032 Sets up dispatcher.
2033
2034 =cut
2035
2036 sub setup_dispatcher {
2037     my ( $class, $dispatcher ) = @_;
2038
2039     if ($dispatcher) {
2040         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2041     }
2042
2043     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2044         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2045     }
2046
2047     unless ($dispatcher) {
2048         $dispatcher = $class->dispatcher_class;
2049     }
2050
2051     Class::MOP::load_class($dispatcher);
2052
2053     # dispatcher instance
2054     $class->dispatcher( $dispatcher->new );
2055 }
2056
2057 =head2 $c->setup_engine
2058
2059 Sets up engine.
2060
2061 =cut
2062
2063 sub setup_engine {
2064     my ( $class, $engine ) = @_;
2065
2066     if ($engine) {
2067         $engine = 'Catalyst::Engine::' . $engine;
2068     }
2069
2070     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2071         $engine = 'Catalyst::Engine::' . $env;
2072     }
2073
2074     if ( $ENV{MOD_PERL} ) {
2075
2076         # create the apache method
2077         $class->meta->add_method('apache' => sub { shift->engine->apache });
2078
2079         my ( $software, $version ) =
2080           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2081
2082         $version =~ s/_//g;
2083         $version =~ s/(\.[^.]+)\./$1/g;
2084
2085         if ( $software eq 'mod_perl' ) {
2086
2087             if ( !$engine ) {
2088
2089                 if ( $version >= 1.99922 ) {
2090                     $engine = 'Catalyst::Engine::Apache2::MP20';
2091                 }
2092
2093                 elsif ( $version >= 1.9901 ) {
2094                     $engine = 'Catalyst::Engine::Apache2::MP19';
2095                 }
2096
2097                 elsif ( $version >= 1.24 ) {
2098                     $engine = 'Catalyst::Engine::Apache::MP13';
2099                 }
2100
2101                 else {
2102                     Catalyst::Exception->throw( message =>
2103                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2104                 }
2105
2106             }
2107
2108             # install the correct mod_perl handler
2109             if ( $version >= 1.9901 ) {
2110                 *handler = sub  : method {
2111                     shift->handle_request(@_);
2112                 };
2113             }
2114             else {
2115                 *handler = sub ($$) { shift->handle_request(@_) };
2116             }
2117
2118         }
2119
2120         elsif ( $software eq 'Zeus-Perl' ) {
2121             $engine = 'Catalyst::Engine::Zeus';
2122         }
2123
2124         else {
2125             Catalyst::Exception->throw(
2126                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2127         }
2128     }
2129
2130     unless ($engine) {
2131         $engine = $class->engine_class;
2132     }
2133
2134     Class::MOP::load_class($engine);
2135     #unless (Class::Inspector->loaded($engine)) {
2136     #    require Class::Inspector->filename($engine);
2137     #}
2138
2139     # check for old engines that are no longer compatible
2140     my $old_engine;
2141     if ( $engine->isa('Catalyst::Engine::Apache')
2142         && !Catalyst::Engine::Apache->VERSION )
2143     {
2144         $old_engine = 1;
2145     }
2146
2147     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2148         && Catalyst::Engine::Server->VERSION le '0.02' )
2149     {
2150         $old_engine = 1;
2151     }
2152
2153     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2154         && $engine->VERSION eq '0.01' )
2155     {
2156         $old_engine = 1;
2157     }
2158
2159     elsif ($engine->isa('Catalyst::Engine::Zeus')
2160         && $engine->VERSION eq '0.01' )
2161     {
2162         $old_engine = 1;
2163     }
2164
2165     if ($old_engine) {
2166         Catalyst::Exception->throw( message =>
2167               qq/Engine "$engine" is not supported by this version of Catalyst/
2168         );
2169     }
2170
2171     # engine instance
2172     $class->engine( $engine->new );
2173 }
2174
2175 =head2 $c->setup_home
2176
2177 Sets up the home directory.
2178
2179 =cut
2180
2181 sub setup_home {
2182     my ( $class, $home ) = @_;
2183
2184     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2185         $home = $env;
2186     }
2187
2188     $home ||= Catalyst::Utils::home($class);
2189
2190     if ($home) {
2191         #I remember recently being scolded for assigning config values like this
2192         $class->config->{home} ||= $home;
2193         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2194     }
2195 }
2196
2197 =head2 $c->setup_log
2198
2199 Sets up log.
2200
2201 =cut
2202
2203 sub setup_log {
2204     my ( $class, $debug ) = @_;
2205
2206     unless ( $class->log ) {
2207         $class->log( Catalyst::Log->new );
2208     }
2209
2210     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2211     if ( defined($env_debug) ? $env_debug : $debug ) {
2212         $class->meta->add_method('debug' => sub { 1 });
2213         $class->log->debug('Debug messages enabled');
2214     }
2215 }
2216
2217 =head2 $c->setup_plugins
2218
2219 Sets up plugins.
2220
2221 =cut
2222
2223 =head2 $c->setup_stats
2224
2225 Sets up timing statistics class.
2226
2227 =cut
2228
2229 sub setup_stats {
2230     my ( $class, $stats ) = @_;
2231
2232     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2233
2234     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2235     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2236         $class->meta->add_method('use_stats' => sub { 1 });
2237         $class->log->debug('Statistics enabled');
2238     }
2239 }
2240
2241
2242 =head2 $c->registered_plugins
2243
2244 Returns a sorted list of the plugins which have either been stated in the
2245 import list or which have been added via C<< MyApp->plugin(@args); >>.
2246
2247 If passed a given plugin name, it will report a boolean value indicating
2248 whether or not that plugin is loaded.  A fully qualified name is required if
2249 the plugin name does not begin with C<Catalyst::Plugin::>.
2250
2251  if ($c->registered_plugins('Some::Plugin')) {
2252      ...
2253  }
2254
2255 =cut
2256
2257 {
2258
2259     sub registered_plugins {
2260         my $proto = shift;
2261         return sort keys %{ $proto->_plugins } unless @_;
2262         my $plugin = shift;
2263         return 1 if exists $proto->_plugins->{$plugin};
2264         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2265     }
2266
2267     sub _register_plugin {
2268         my ( $proto, $plugin, $instant ) = @_;
2269         my $class = ref $proto || $proto;
2270
2271         # no ignore_loaded here, the plugin may already have been
2272         # defined in memory and we don't want to error on "no file" if so
2273
2274         Class::MOP::load_class( $plugin );
2275
2276         $proto->_plugins->{$plugin} = 1;
2277         unless ($instant) {
2278             no strict 'refs';
2279             if( $class->can('meta') ){
2280               my @superclasses = ($plugin, $class->meta->superclasses );
2281               $class->meta->superclasses(@superclasses);
2282             } else {
2283               unshift @{"$class\::ISA"}, $plugin;
2284             }
2285         }
2286         return $class;
2287     }
2288
2289     sub setup_plugins {
2290         my ( $class, $plugins ) = @_;
2291
2292         $class->_plugins( {} ) unless $class->_plugins;
2293         $plugins ||= [];
2294         for my $plugin ( reverse @$plugins ) {
2295
2296             unless ( $plugin =~ s/\A\+// ) {
2297                 $plugin = "Catalyst::Plugin::$plugin";
2298             }
2299
2300             $class->_register_plugin($plugin);
2301         }
2302     }
2303 }
2304
2305 =head2 $c->stack
2306
2307 Returns an arrayref of the internal execution stack (actions that are
2308 currently executing).
2309
2310 =head2 $c->stats_class
2311
2312 Returns or sets the stats (timing statistics) class.
2313
2314 =head2 $c->use_stats
2315
2316 Returns 1 when stats collection is enabled.  Stats collection is enabled
2317 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2318 environment variable is set.
2319
2320 Note that this is a static method, not an accessor and should be overloaded
2321 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2322
2323 =cut
2324
2325 sub use_stats { 0 }
2326
2327
2328 =head2 $c->write( $data )
2329
2330 Writes $data to the output stream. When using this method directly, you
2331 will need to manually set the C<Content-Length> header to the length of
2332 your output data, if known.
2333
2334 =cut
2335
2336 sub write {
2337     my $c = shift;
2338
2339     # Finalize headers if someone manually writes output
2340     $c->finalize_headers;
2341
2342     return $c->engine->write( $c, @_ );
2343 }
2344
2345 =head2 version
2346
2347 Returns the Catalyst version number. Mostly useful for "powered by"
2348 messages in template systems.
2349
2350 =cut
2351
2352 sub version { return $Catalyst::VERSION }
2353
2354 =head1 INTERNAL ACTIONS
2355
2356 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2357 C<_ACTION>, and C<_END>. These are by default not shown in the private
2358 action table, but you can make them visible with a config parameter.
2359
2360     MyApp->config->{show_internal_actions} = 1;
2361
2362 =head1 CASE SENSITIVITY
2363
2364 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2365 mapped to C</foo/bar>. You can activate case sensitivity with a config
2366 parameter.
2367
2368     MyApp->config->{case_sensitive} = 1;
2369
2370 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2371
2372 =head1 ON-DEMAND PARSER
2373
2374 The request body is usually parsed at the beginning of a request,
2375 but if you want to handle input yourself, you can enable on-demand
2376 parsing with a config parameter.
2377
2378     MyApp->config->{parse_on_demand} = 1;
2379
2380 =head1 PROXY SUPPORT
2381
2382 Many production servers operate using the common double-server approach,
2383 with a lightweight frontend web server passing requests to a larger
2384 backend server. An application running on the backend server must deal
2385 with two problems: the remote user always appears to be C<127.0.0.1> and
2386 the server's hostname will appear to be C<localhost> regardless of the
2387 virtual host that the user connected through.
2388
2389 Catalyst will automatically detect this situation when you are running
2390 the frontend and backend servers on the same machine. The following
2391 changes are made to the request.
2392
2393     $c->req->address is set to the user's real IP address, as read from
2394     the HTTP X-Forwarded-For header.
2395
2396     The host value for $c->req->base and $c->req->uri is set to the real
2397     host, as read from the HTTP X-Forwarded-Host header.
2398
2399 Obviously, your web server must support these headers for this to work.
2400
2401 In a more complex server farm environment where you may have your
2402 frontend proxy server(s) on different machines, you will need to set a
2403 configuration option to tell Catalyst to read the proxied data from the
2404 headers.
2405
2406     MyApp->config->{using_frontend_proxy} = 1;
2407
2408 If you do not wish to use the proxy support at all, you may set:
2409
2410     MyApp->config->{ignore_frontend_proxy} = 1;
2411
2412 =head1 THREAD SAFETY
2413
2414 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2415 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2416 believe the Catalyst core to be thread-safe.
2417
2418 If you plan to operate in a threaded environment, remember that all other
2419 modules you are using must also be thread-safe. Some modules, most notably
2420 L<DBD::SQLite>, are not thread-safe.
2421
2422 =head1 SUPPORT
2423
2424 IRC:
2425
2426     Join #catalyst on irc.perl.org.
2427
2428 Mailing Lists:
2429
2430     http://lists.rawmode.org/mailman/listinfo/catalyst
2431     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2432
2433 Web:
2434
2435     http://catalyst.perl.org
2436
2437 Wiki:
2438
2439     http://dev.catalyst.perl.org
2440
2441 =head1 SEE ALSO
2442
2443 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2444
2445 =head2 L<Catalyst::Manual> - The Catalyst Manual
2446
2447 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2448
2449 =head2 L<Catalyst::Engine> - Core engine
2450
2451 =head2 L<Catalyst::Log> - Log class.
2452
2453 =head2 L<Catalyst::Request> - Request object
2454
2455 =head2 L<Catalyst::Response> - Response object
2456
2457 =head2 L<Catalyst::Test> - The test suite.
2458
2459 =head1 PROJECT FOUNDER
2460
2461 sri: Sebastian Riedel <sri@cpan.org>
2462
2463 =head1 CONTRIBUTORS
2464
2465 abw: Andy Wardley
2466
2467 acme: Leon Brocard <leon@astray.com>
2468
2469 Andrew Bramble
2470
2471 Andrew Ford
2472
2473 Andrew Ruthven
2474
2475 andyg: Andy Grundman <andy@hybridized.org>
2476
2477 audreyt: Audrey Tang
2478
2479 bricas: Brian Cassidy <bricas@cpan.org>
2480
2481 chansen: Christian Hansen
2482
2483 chicks: Christopher Hicks
2484
2485 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2486
2487 Drew Taylor
2488
2489 esskar: Sascha Kiefer
2490
2491 fireartist: Carl Franks <cfranks@cpan.org>
2492
2493 gabb: Danijel Milicevic
2494
2495 Gary Ashton Jones
2496
2497 Geoff Richards
2498
2499 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2500
2501 jcamacho: Juan Camacho
2502
2503 Jody Belka
2504
2505 Johan Lindstrom
2506
2507 jon: Jon Schutz <jjschutz@cpan.org>
2508
2509 marcus: Marcus Ramberg <mramberg@cpan.org>
2510
2511 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2512
2513 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2514
2515 mugwump: Sam Vilain
2516
2517 naughton: David Naughton
2518
2519 ningu: David Kamholz <dkamholz@cpan.org>
2520
2521 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2522
2523 numa: Dan Sully <daniel@cpan.org>
2524
2525 obra: Jesse Vincent
2526
2527 omega: Andreas Marienborg
2528
2529 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2530
2531 rafl: Florian Ragwitz <rafl@debian.org>
2532
2533 sky: Arthur Bergman
2534
2535 the_jester: Jesse Sheidlower
2536
2537 Ulf Edvinsson
2538
2539 willert: Sebastian Willert <willert@cpan.org>
2540
2541 =head1 LICENSE
2542
2543 This library is free software, you can redistribute it and/or modify it under
2544 the same terms as Perl itself.
2545
2546 =cut
2547
2548 no Moose;
2549
2550 __PACKAGE__->meta->make_immutable;
2551
2552 1;