lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Plack::Middleware::Conditional;
  39 use Plack::Middleware::ReverseProxy;
  40 use Plack::Middleware::IIS6ScriptNameFix;
  41 use Plack::Middleware::IIS7KeepAliveFix;
  42 use Plack::Middleware::LighttpdScriptNameFix;
  43
  44 BEGIN { require 5.008003; }
  45
  46 has stack => (is => 'ro', default => sub { [] });
  47 has stash => (is => 'rw', default => sub { {} });
  48 has state => (is => 'rw', default => 0);
  49 has stats => (is => 'rw');
  50 has action => (is => 'rw');
  51 has counter => (is => 'rw', default => sub { {} });
  52 has request => (
  53     is => 'rw',
  54     default => sub {
  55         my $self = shift;
  56         $self->request_class->new($self->_build_request_constructor_args);
  57     },
  58     lazy => 1,
  59 );
  60 sub _build_request_constructor_args {
  61     my $self = shift;
  62     my %p = ( _log => $self->log );
  63     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  64     \%p;
  65 }
  66
  67 has response => (
  68     is => 'rw',
  69     default => sub {
  70         my $self = shift;
  71         $self->response_class->new($self->_build_response_constructor_args);
  72     },
  73     lazy => 1,
  74 );
  75 sub _build_response_constructor_args {
  76     my $self = shift;
  77     { _log => $self->log };
  78 }
  79
  80 has namespace => (is => 'rw');
  81
  82 sub depth { scalar @{ shift->stack || [] }; }
  83 sub comp { shift->component(@_) }
  84
  85 sub req {
  86     my $self = shift; return $self->request(@_);
  87 }
  88 sub res {
  89     my $self = shift; return $self->response(@_);
  90 }
  91
  92 # For backwards compatibility
  93 sub finalize_output { shift->finalize_body(@_) };
  94
  95 # For statistics
  96 our $COUNT     = 1;
  97 our $START     = time;
  98 our $RECURSION = 1000;
  99 our $DETACH    = Catalyst::Exception::Detach->new;
 100 our $GO        = Catalyst::Exception::Go->new;
 101
 102 #I imagine that very few of these really need to be class variables. if any.
 103 #maybe we should just make them attributes with a default?
 104 __PACKAGE__->mk_classdata($_)
 105   for qw/components arguments dispatcher engine log dispatcher_class
 106   engine_loader context_class request_class response_class stats_class
 107   setup_finished _psgi_app loading_psgi_file run_options/;
 108
 109 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 110 __PACKAGE__->request_class('Catalyst::Request');
 111 __PACKAGE__->response_class('Catalyst::Response');
 112 __PACKAGE__->stats_class('Catalyst::Stats');
 113
 114 # Remember to update this in Catalyst::Runtime as well!
 115
 116 our $VERSION = '5.90042';
 117
 118 sub import {
 119     my ( $class, @arguments ) = @_;
 120
 121     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 122     # callers @ISA.
 123     return unless $class eq 'Catalyst';
 124
 125     my $caller = caller();
 126     return if $caller eq 'main';
 127
 128     my $meta = Moose::Meta::Class->initialize($caller);
 129     unless ( $caller->isa('Catalyst') ) {
 130         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 131         $meta->superclasses(@superclasses);
 132     }
 133     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 134     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 135
 136     unless( $meta->has_method('meta') ){
 137         if ($Moose::VERSION >= 1.15) {
 138             $meta->_add_meta_method('meta');
 139         }
 140         else {
 141             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 142         }
 143     }
 144
 145     $caller->arguments( [@arguments] );
 146     $caller->setup_home;
 147 }
 148
 149 sub _application { $_[0] }
 150
 151 =encoding UTF-8
 152
 153 =head1 NAME
 154
 155 Catalyst - The Elegant MVC Web Application Framework
 156
 157 =head1 SYNOPSIS
 158
 159 See the L<Catalyst::Manual> distribution for comprehensive
 160 documentation and tutorials.
 161
 162     # Install Catalyst::Devel for helpers and other development tools
 163     # use the helper to create a new application
 164     catalyst.pl MyApp
 165
 166     # add models, views, controllers
 167     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 168     script/myapp_create.pl view MyTemplate TT
 169     script/myapp_create.pl controller Search
 170
 171     # built in testserver -- use -r to restart automatically on changes
 172     # --help to see all available options
 173     script/myapp_server.pl
 174
 175     # command line testing interface
 176     script/myapp_test.pl /yada
 177
 178     ### in lib/MyApp.pm
 179     use Catalyst qw/-Debug/; # include plugins here as well
 180
 181     ### In lib/MyApp/Controller/Root.pm (autocreated)
 182     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 183         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 184         $c->stash->{template} = 'foo.tt'; # set the template
 185         # lookup something from db -- stash vars are passed to TT
 186         $c->stash->{data} =
 187           $c->model('Database::Foo')->search( { country => $args[0] } );
 188         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 189             $c->forward( 'bar' ); # process another action
 190             # do something else after forward returns
 191         }
 192     }
 193
 194     # The foo.tt TT template can use the stash data from the database
 195     [% WHILE (item = data.next) %]
 196         [% item.foo %]
 197     [% END %]
 198
 199     # called for /bar/of/soap, /bar/of/soap/10, etc.
 200     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 201
 202     # called after all actions are finished
 203     sub end : Action {
 204         my ( $self, $c ) = @_;
 205         if ( scalar @{ $c->error } ) { ... } # handle errors
 206         return if $c->res->body; # already have a response
 207         $c->forward( 'MyApp::View::TT' ); # render template
 208     }
 209
 210 See L<Catalyst::Manual::Intro> for additional information.
 211
 212 =head1 DESCRIPTION
 213
 214 Catalyst is a modern framework for making web applications without the
 215 pain usually associated with this process. This document is a reference
 216 to the main Catalyst application. If you are a new user, we suggest you
 217 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 218
 219 See L<Catalyst::Manual> for more documentation.
 220
 221 Catalyst plugins can be loaded by naming them as arguments to the "use
 222 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 223 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 224 C<My::Module>.
 225
 226     use Catalyst qw/My::Module/;
 227
 228 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 229 fully qualify the name by using a unary plus:
 230
 231     use Catalyst qw/
 232         My::Module
 233         +Fully::Qualified::Plugin::Name
 234     /;
 235
 236 Special flags like C<-Debug> can also be specified as
 237 arguments when Catalyst is loaded:
 238
 239     use Catalyst qw/-Debug My::Module/;
 240
 241 The position of plugins and flags in the chain is important, because
 242 they are loaded in the order in which they appear.
 243
 244 The following flags are supported:
 245
 246 =head2 -Debug
 247
 248 Enables debug output. You can also force this setting from the system
 249 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 250 settings override the application, with <MYAPP>_DEBUG having the highest
 251 priority.
 252
 253 This sets the log level to 'debug' and enables full debug output on the
 254 error screen. If you only want the latter, see L<< $c->debug >>.
 255
 256 =head2 -Home
 257
 258 Forces Catalyst to use a specific home directory, e.g.:
 259
 260     use Catalyst qw[-Home=/usr/mst];
 261
 262 This can also be done in the shell environment by setting either the
 263 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 264 is replaced with the uppercased name of your application, any "::" in
 265 the name will be replaced with underscores, e.g. MyApp::Web should use
 266 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 267
 268 If none of these are set, Catalyst will attempt to automatically detect the
 269 home directory. If you are working in a development environment, Catalyst
 270 will try and find the directory containing either Makefile.PL, Build.PL,
 271 dist.ini, or cpanfile. If the application has been installed into the system
 272 (i.e. you have done C<make install>), then Catalyst will use the path to your
 273 application module, without the .pm extension (e.g., /foo/MyApp if your
 274 application was installed at /foo/MyApp.pm)
 275
 276 =head2 -Log
 277
 278     use Catalyst '-Log=warn,fatal,error';
 279
 280 Specifies a comma-delimited list of log levels.
 281
 282 =head2 -Stats
 283
 284 Enables statistics collection and reporting.
 285
 286    use Catalyst qw/-Stats=1/;
 287
 288 You can also force this setting from the system environment with CATALYST_STATS
 289 or <MYAPP>_STATS. The environment settings override the application, with
 290 <MYAPP>_STATS having the highest priority.
 291
 292 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 293
 294 =head1 METHODS
 295
 296 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 297
 298 =head2 $c->action
 299
 300 Returns a L<Catalyst::Action> object for the current action, which
 301 stringifies to the action name. See L<Catalyst::Action>.
 302
 303 =head2 $c->namespace
 304
 305 Returns the namespace of the current action, i.e., the URI prefix
 306 corresponding to the controller of the current action. For example:
 307
 308     # in Controller::Foo::Bar
 309     $c->namespace; # returns 'foo/bar';
 310
 311 =head2 $c->request
 312
 313 =head2 $c->req
 314
 315 Returns the current L<Catalyst::Request> object, giving access to
 316 information about the current client request (including parameters,
 317 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 318
 319 =head2 REQUEST FLOW HANDLING
 320
 321 =head2 $c->forward( $action [, \@arguments ] )
 322
 323 =head2 $c->forward( $class, $method, [, \@arguments ] )
 324
 325 This is one way of calling another action (method) in the same or
 326 a different controller. You can also use C<< $self->my_method($c, @args) >>
 327 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 328 in a different controller.
 329 The main difference is that 'forward' uses some of the Catalyst request
 330 cycle overhead, including debugging, which may be useful to you. On the
 331 other hand, there are some complications to using 'forward', restrictions
 332 on values returned from 'forward', and it may not handle errors as you prefer.
 333 Whether you use 'forward' or not is up to you; it is not considered superior to
 334 the other ways to call a method.
 335
 336 'forward' calls  another action, by its private name. If you give a
 337 class name but no method, C<process()> is called. You may also optionally
 338 pass arguments in an arrayref. The action will receive the arguments in
 339 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 340 C<< $c->req->args >> will be restored to the previous values.
 341
 342 Any data C<return>ed from the action forwarded to, will be returned by the
 343 call to forward.
 344
 345     my $foodata = $c->forward('/foo');
 346     $c->forward('index');
 347     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 348     $c->forward('View::TT');
 349
 350 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 351 an C<< eval { } >> around the call (actually
 352 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 353 exceptions thrown by the called action non-fatal and pushing them onto
 354 $c->error instead. If you want C<die> to propagate you need to do something
 355 like:
 356
 357     $c->forward('foo');
 358     die join "\n", @{ $c->error } if @{ $c->error };
 359
 360 Or make sure to always return true values from your actions and write
 361 your code like this:
 362
 363     $c->forward('foo') || return;
 364
 365 Another note is that C<< $c->forward >> always returns a scalar because it
 366 actually returns $c->state which operates in a scalar context.
 367 Thus, something like:
 368
 369     return @array;
 370
 371 in an action that is forwarded to is going to return a scalar,
 372 i.e. how many items are in that array, which is probably not what you want.
 373 If you need to return an array then return a reference to it,
 374 or stash it like so:
 375
 376     $c->stash->{array} = \@array;
 377
 378 and access it from the stash.
 379
 380 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 381
 382 =cut
 383
 384 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 385
 386 =head2 $c->detach( $action [, \@arguments ] )
 387
 388 =head2 $c->detach( $class, $method, [, \@arguments ] )
 389
 390 =head2 $c->detach()
 391
 392 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 393 doesn't return to the previous action when processing is finished.
 394
 395 When called with no arguments it escapes the processing chain entirely.
 396
 397 =cut
 398
 399 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 400
 401 =head2 $c->visit( $action [, \@arguments ] )
 402
 403 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 404
 405 =head2 $c->visit( $class, $method, [, \@arguments ] )
 406
 407 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 408
 409 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 410 but does a full dispatch, instead of just calling the new C<$action> /
 411 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 412 you go to are called, just like a new request.
 413
 414 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 415 This means, for example, that C<< $c->action >> methods such as
 416 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 417 L<reverse|Catalyst::Action/reverse> return information for the visited action
 418 when they are invoked within the visited action.  This is different from the
 419 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 420 continues to use the $c->action object from the caller action even when
 421 invoked from the called action.
 422
 423 C<< $c->stash >> is kept unchanged.
 424
 425 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 426 allows you to "wrap" another action, just as it would have been called by
 427 dispatching from a URL, while the analogous
 428 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 429 transfer control to another action as if it had been reached directly from a URL.
 430
 431 =cut
 432
 433 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 434
 435 =head2 $c->go( $action [, \@arguments ] )
 436
 437 =head2 $c->go( $action [, \@captures, \@arguments ] )
 438
 439 =head2 $c->go( $class, $method, [, \@arguments ] )
 440
 441 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 442
 443 The relationship between C<go> and
 444 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 445 the relationship between
 446 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 447 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 448 C<< $c->go >> will perform a full dispatch on the specified action or method,
 449 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 450 C<go> escapes the processing of the current request chain on completion, and
 451 does not return to its caller.
 452
 453 @arguments are arguments to the final destination of $action. @captures are
 454 arguments to the intermediate steps, if any, on the way to the final sub of
 455 $action.
 456
 457 =cut
 458
 459 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 460
 461 =head2 $c->response
 462
 463 =head2 $c->res
 464
 465 Returns the current L<Catalyst::Response> object, see there for details.
 466
 467 =head2 $c->stash
 468
 469 Returns a hashref to the stash, which may be used to store data and pass
 470 it between components during a request. You can also set hash keys by
 471 passing arguments. The stash is automatically sent to the view. The
 472 stash is cleared at the end of a request; it cannot be used for
 473 persistent storage (for this you must use a session; see
 474 L<Catalyst::Plugin::Session> for a complete system integrated with
 475 Catalyst).
 476
 477     $c->stash->{foo} = $bar;
 478     $c->stash( { moose => 'majestic', qux => 0 } );
 479     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 480
 481     # stash is automatically passed to the view for use in a template
 482     $c->forward( 'MyApp::View::TT' );
 483
 484 =cut
 485
 486 around stash => sub {
 487     my $orig = shift;
 488     my $c = shift;
 489     my $stash = $orig->($c);
 490     if (@_) {
 491         my $new_stash = @_ > 1 ? {@_} : $_[0];
 492         croak('stash takes a hash or hashref') unless ref $new_stash;
 493         foreach my $key ( keys %$new_stash ) {
 494           $stash->{$key} = $new_stash->{$key};
 495         }
 496     }
 497
 498     return $stash;
 499 };
 500
 501
 502 =head2 $c->error
 503
 504 =head2 $c->error($error, ...)
 505
 506 =head2 $c->error($arrayref)
 507
 508 Returns an arrayref containing error messages.  If Catalyst encounters an
 509 error while processing a request, it stores the error in $c->error.  This
 510 method should only be used to store fatal error messages.
 511
 512     my @error = @{ $c->error };
 513
 514 Add a new error.
 515
 516     $c->error('Something bad happened');
 517
 518 =cut
 519
 520 sub error {
 521     my $c = shift;
 522     if ( $_[0] ) {
 523         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 524         croak @$error unless ref $c;
 525         push @{ $c->{error} }, @$error;
 526     }
 527     elsif ( defined $_[0] ) { $c->{error} = undef }
 528     return $c->{error} || [];
 529 }
 530
 531
 532 =head2 $c->state
 533
 534 Contains the return value of the last executed action.
 535 Note that << $c->state >> operates in a scalar context which means that all
 536 values it returns are scalar.
 537
 538 =head2 $c->clear_errors
 539
 540 Clear errors.  You probably don't want to clear the errors unless you are
 541 implementing a custom error screen.
 542
 543 This is equivalent to running
 544
 545     $c->error(0);
 546
 547 =cut
 548
 549 sub clear_errors {
 550     my $c = shift;
 551     $c->error(0);
 552 }
 553
 554 sub _comp_search_prefixes {
 555     my $c = shift;
 556     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 557 }
 558
 559 # search components given a name and some prefixes
 560 sub _comp_names_search_prefixes {
 561     my ( $c, $name, @prefixes ) = @_;
 562     my $appclass = ref $c || $c;
 563     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 564     $filter = qr/$filter/; # Compile regex now rather than once per loop
 565
 566     # map the original component name to the sub part that we will search against
 567     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 568         grep { /$filter/ } keys %{ $c->components };
 569
 570     # undef for a name will return all
 571     return keys %eligible if !defined $name;
 572
 573     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 574     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 575
 576     return @result if @result;
 577
 578     # if we were given a regexp to search against, we're done.
 579     return if $name->$_isa('Regexp');
 580
 581     # skip regexp fallback if configured
 582     return
 583         if $appclass->config->{disable_component_resolution_regex_fallback};
 584
 585     # regexp fallback
 586     $query  = qr/$name/i;
 587     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 588
 589     # no results? try against full names
 590     if( !@result ) {
 591         @result = grep { m{$query} } keys %eligible;
 592     }
 593
 594     # don't warn if we didn't find any results, it just might not exist
 595     if( @result ) {
 596         # Disgusting hack to work out correct method name
 597         my $warn_for = lc $prefixes[0];
 598         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 599            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 600            "component resolution is unreliable and unsafe.";
 601         my $short = $result[0];
 602         # remove the component namespace prefix
 603         $short =~ s/.*?(Model|Controller|View):://;
 604         my $shortmess = Carp::shortmess('');
 605         if ($shortmess =~ m#Catalyst/Plugin#) {
 606            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 607               "plugin's config";
 608         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 609            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 610               "component's config";
 611         } else {
 612            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 613               "but if you really wanted to search, pass in a regexp as the argument " .
 614               "like so: \$c->${warn_for}(qr/${name}/)";
 615         }
 616         $c->log->warn( "${msg}$shortmess" );
 617     }
 618
 619     return @result;
 620 }
 621
 622 # Find possible names for a prefix
 623 sub _comp_names {
 624     my ( $c, @prefixes ) = @_;
 625     my $appclass = ref $c || $c;
 626
 627     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 628
 629     my @names = map { s{$filter}{}; $_; }
 630         $c->_comp_names_search_prefixes( undef, @prefixes );
 631
 632     return @names;
 633 }
 634
 635 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 636 sub _filter_component {
 637     my ( $c, $comp, @args ) = @_;
 638
 639     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 640         return $comp->ACCEPT_CONTEXT( $c, @args );
 641     }
 642
 643     return $comp;
 644 }
 645
 646 =head2 COMPONENT ACCESSORS
 647
 648 =head2 $c->controller($name)
 649
 650 Gets a L<Catalyst::Controller> instance by name.
 651
 652     $c->controller('Foo')->do_stuff;
 653
 654 If the name is omitted, will return the controller for the dispatched
 655 action.
 656
 657 If you want to search for controllers, pass in a regexp as the argument.
 658
 659     # find all controllers that start with Foo
 660     my @foo_controllers = $c->controller(qr{^Foo});
 661
 662
 663 =cut
 664
 665 sub controller {
 666     my ( $c, $name, @args ) = @_;
 667
 668     my $appclass = ref($c) || $c;
 669     if( $name ) {
 670         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 671             my $comps = $c->components;
 672             my $check = $appclass."::Controller::".$name;
 673             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 674         }
 675         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 676         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 677         return $c->_filter_component( $result[ 0 ], @args );
 678     }
 679
 680     return $c->component( $c->action->class );
 681 }
 682
 683 =head2 $c->model($name)
 684
 685 Gets a L<Catalyst::Model> instance by name.
 686
 687     $c->model('Foo')->do_stuff;
 688
 689 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 690
 691 If the name is omitted, it will look for
 692  - a model object in $c->stash->{current_model_instance}, then
 693  - a model name in $c->stash->{current_model}, then
 694  - a config setting 'default_model', or
 695  - check if there is only one model, and return it if that's the case.
 696
 697 If you want to search for models, pass in a regexp as the argument.
 698
 699     # find all models that start with Foo
 700     my @foo_models = $c->model(qr{^Foo});
 701
 702 =cut
 703
 704 sub model {
 705     my ( $c, $name, @args ) = @_;
 706     my $appclass = ref($c) || $c;
 707     if( $name ) {
 708         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 709             my $comps = $c->components;
 710             my $check = $appclass."::Model::".$name;
 711             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 712         }
 713         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 714         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 715         return $c->_filter_component( $result[ 0 ], @args );
 716     }
 717
 718     if (ref $c) {
 719         return $c->stash->{current_model_instance}
 720           if $c->stash->{current_model_instance};
 721         return $c->model( $c->stash->{current_model} )
 722           if $c->stash->{current_model};
 723     }
 724     return $c->model( $appclass->config->{default_model} )
 725       if $appclass->config->{default_model};
 726
 727     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 728
 729     if( $rest ) {
 730         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 731         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 732         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 733         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 734         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 735     }
 736
 737     return $c->_filter_component( $comp );
 738 }
 739
 740
 741 =head2 $c->view($name)
 742
 743 Gets a L<Catalyst::View> instance by name.
 744
 745     $c->view('Foo')->do_stuff;
 746
 747 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 748
 749 If the name is omitted, it will look for
 750  - a view object in $c->stash->{current_view_instance}, then
 751  - a view name in $c->stash->{current_view}, then
 752  - a config setting 'default_view', or
 753  - check if there is only one view, and return it if that's the case.
 754
 755 If you want to search for views, pass in a regexp as the argument.
 756
 757     # find all views that start with Foo
 758     my @foo_views = $c->view(qr{^Foo});
 759
 760 =cut
 761
 762 sub view {
 763     my ( $c, $name, @args ) = @_;
 764
 765     my $appclass = ref($c) || $c;
 766     if( $name ) {
 767         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 768             my $comps = $c->components;
 769             my $check = $appclass."::View::".$name;
 770             if( exists $comps->{$check} ) {
 771                 return $c->_filter_component( $comps->{$check}, @args );
 772             }
 773             else {
 774                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 775             }
 776         }
 777         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 778         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 779         return $c->_filter_component( $result[ 0 ], @args );
 780     }
 781
 782     if (ref $c) {
 783         return $c->stash->{current_view_instance}
 784           if $c->stash->{current_view_instance};
 785         return $c->view( $c->stash->{current_view} )
 786           if $c->stash->{current_view};
 787     }
 788     return $c->view( $appclass->config->{default_view} )
 789       if $appclass->config->{default_view};
 790
 791     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 792
 793     if( $rest ) {
 794         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 795         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 796         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 797         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 798         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 799     }
 800
 801     return $c->_filter_component( $comp );
 802 }
 803
 804 =head2 $c->controllers
 805
 806 Returns the available names which can be passed to $c->controller
 807
 808 =cut
 809
 810 sub controllers {
 811     my ( $c ) = @_;
 812     return $c->_comp_names(qw/Controller C/);
 813 }
 814
 815 =head2 $c->models
 816
 817 Returns the available names which can be passed to $c->model
 818
 819 =cut
 820
 821 sub models {
 822     my ( $c ) = @_;
 823     return $c->_comp_names(qw/Model M/);
 824 }
 825
 826
 827 =head2 $c->views
 828
 829 Returns the available names which can be passed to $c->view
 830
 831 =cut
 832
 833 sub views {
 834     my ( $c ) = @_;
 835     return $c->_comp_names(qw/View V/);
 836 }
 837
 838 =head2 $c->comp($name)
 839
 840 =head2 $c->component($name)
 841
 842 Gets a component object by name. This method is not recommended,
 843 unless you want to get a specific component by full
 844 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 845 should be used instead.
 846
 847 If C<$name> is a regexp, a list of components matched against the full
 848 component name will be returned.
 849
 850 If Catalyst can't find a component by name, it will fallback to regex
 851 matching by default. To disable this behaviour set
 852 disable_component_resolution_regex_fallback to a true value.
 853
 854     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 855
 856 =cut
 857
 858 sub component {
 859     my ( $c, $name, @args ) = @_;
 860
 861     if( $name ) {
 862         my $comps = $c->components;
 863
 864         if( !ref $name ) {
 865             # is it the exact name?
 866             return $c->_filter_component( $comps->{ $name }, @args )
 867                        if exists $comps->{ $name };
 868
 869             # perhaps we just omitted "MyApp"?
 870             my $composed = ( ref $c || $c ) . "::${name}";
 871             return $c->_filter_component( $comps->{ $composed }, @args )
 872                        if exists $comps->{ $composed };
 873
 874             # search all of the models, views and controllers
 875             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 876             return $c->_filter_component( $comp, @args ) if $comp;
 877         }
 878
 879         return
 880             if $c->config->{disable_component_resolution_regex_fallback};
 881
 882         # This is here so $c->comp( '::M::' ) works
 883         my $query = ref $name ? $name : qr{$name}i;
 884
 885         my @result = grep { m{$query} } keys %{ $c->components };
 886         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 887
 888         if( $result[ 0 ] ) {
 889             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 890             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 891             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 892             return $c->_filter_component( $result[ 0 ], @args );
 893         }
 894
 895         # I would expect to return an empty list here, but that breaks back-compat
 896     }
 897
 898     # fallback
 899     return sort keys %{ $c->components };
 900 }
 901
 902 =head2 CLASS DATA AND HELPER CLASSES
 903
 904 =head2 $c->config
 905
 906 Returns or takes a hashref containing the application's configuration.
 907
 908     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 909
 910 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 911 like C<myapp.conf> in your applications home directory. See
 912 L<Catalyst::Plugin::ConfigLoader>.
 913
 914 =head3 Cascading configuration
 915
 916 The config method is present on all Catalyst components, and configuration
 917 will be merged when an application is started. Configuration loaded with
 918 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 919 followed by configuration in your top level C<MyApp> class. These two
 920 configurations are merged, and then configuration data whose hash key matches a
 921 component name is merged with configuration for that component.
 922
 923 The configuration for a component is then passed to the C<new> method when a
 924 component is constructed.
 925
 926 For example:
 927
 928     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 929     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 930
 931 will mean that C<MyApp::Model::Foo> receives the following data when
 932 constructed:
 933
 934     MyApp::Model::Foo->new({
 935         bar => 'baz',
 936         quux => 'frob',
 937         overrides => 'me',
 938     });
 939
 940 It's common practice to use a Moose attribute
 941 on the receiving component to access the config value.
 942
 943     package MyApp::Model::Foo;
 944
 945     use Moose;
 946
 947     # this attr will receive 'baz' at construction time
 948     has 'bar' => (
 949         is  => 'rw',
 950         isa => 'Str',
 951     );
 952
 953 You can then get the value 'baz' by calling $c->model('Foo')->bar
 954 (or $self->bar inside code in the model).
 955
 956 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 957 as a way of reading config within your code, as this B<will not> give you the
 958 correctly merged config back. You B<MUST> take the config values supplied to
 959 the constructor and use those instead.
 960
 961 =cut
 962
 963 around config => sub {
 964     my $orig = shift;
 965     my $c = shift;
 966
 967     croak('Setting config after setup has been run is not allowed.')
 968         if ( @_ and $c->setup_finished );
 969
 970     $c->$orig(@_);
 971 };
 972
 973 =head2 $c->log
 974
 975 Returns the logging object instance. Unless it is already set, Catalyst
 976 sets this up with a L<Catalyst::Log> object. To use your own log class,
 977 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 978 C<< __PACKAGE__->setup >>.
 979
 980  __PACKAGE__->log( MyLogger->new );
 981  __PACKAGE__->setup;
 982
 983 And later:
 984
 985     $c->log->info( 'Now logging with my own logger!' );
 986
 987 Your log class should implement the methods described in
 988 L<Catalyst::Log>.
 989
 990
 991 =head2 $c->debug
 992
 993 Returns 1 if debug mode is enabled, 0 otherwise.
 994
 995 You can enable debug mode in several ways:
 996
 997 =over
 998
 999 =item By calling myapp_server.pl with the -d flag
1000
1001 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1002
1003 =item The -Debug option in your MyApp.pm
1004
1005 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1006
1007 =back
1008
1009 The first three also set the log level to 'debug'.
1010
1011 Calling C<< $c->debug(1) >> has no effect.
1012
1013 =cut
1014
1015 sub debug { 0 }
1016
1017 =head2 $c->dispatcher
1018
1019 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1020
1021 =head2 $c->engine
1022
1023 Returns the engine instance. See L<Catalyst::Engine>.
1024
1025
1026 =head2 UTILITY METHODS
1027
1028 =head2 $c->path_to(@path)
1029
1030 Merges C<@path> with C<< $c->config->{home} >> and returns a
1031 L<Path::Class::Dir> object. Note you can usually use this object as
1032 a filename, but sometimes you will have to explicitly stringify it
1033 yourself by calling the C<< ->stringify >> method.
1034
1035 For example:
1036
1037     $c->path_to( 'db', 'sqlite.db' );
1038
1039 =cut
1040
1041 sub path_to {
1042     my ( $c, @path ) = @_;
1043     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1044     if ( -d $path ) { return $path }
1045     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1046 }
1047
1048 sub plugin {
1049     my ( $class, $name, $plugin, @args ) = @_;
1050
1051     # See block comment in t/unit_core_plugin.t
1052     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1053
1054     $class->_register_plugin( $plugin, 1 );
1055
1056     eval { $plugin->import };
1057     $class->mk_classdata($name);
1058     my $obj;
1059     eval { $obj = $plugin->new(@args) };
1060
1061     if ($@) {
1062         Catalyst::Exception->throw( message =>
1063               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1064     }
1065
1066     $class->$name($obj);
1067     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1068       if $class->debug;
1069 }
1070
1071 =head2 MyApp->setup
1072
1073 Initializes the dispatcher and engine, loads any plugins, and loads the
1074 model, view, and controller components. You may also specify an array
1075 of plugins to load here, if you choose to not load them in the C<use
1076 Catalyst> line.
1077
1078     MyApp->setup;
1079     MyApp->setup( qw/-Debug/ );
1080
1081 B<Note:> You B<should not> wrap this method with method modifiers
1082 or bad things will happen - wrap the C<setup_finalize> method instead.
1083
1084 =cut
1085
1086 sub setup {
1087     my ( $class, @arguments ) = @_;
1088     croak('Running setup more than once')
1089         if ( $class->setup_finished );
1090
1091     unless ( $class->isa('Catalyst') ) {
1092
1093         Catalyst::Exception->throw(
1094             message => qq/'$class' does not inherit from Catalyst/ );
1095     }
1096
1097     if ( $class->arguments ) {
1098         @arguments = ( @arguments, @{ $class->arguments } );
1099     }
1100
1101     # Process options
1102     my $flags = {};
1103
1104     foreach (@arguments) {
1105
1106         if (/^-Debug$/) {
1107             $flags->{log} =
1108               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1109         }
1110         elsif (/^-(\w+)=?(.*)$/) {
1111             $flags->{ lc $1 } = $2;
1112         }
1113         else {
1114             push @{ $flags->{plugins} }, $_;
1115         }
1116     }
1117
1118     $class->setup_home( delete $flags->{home} );
1119
1120     $class->setup_log( delete $flags->{log} );
1121     $class->setup_plugins( delete $flags->{plugins} );
1122     $class->setup_dispatcher( delete $flags->{dispatcher} );
1123     if (my $engine = delete $flags->{engine}) {
1124         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1125     }
1126     $class->setup_engine();
1127     $class->setup_stats( delete $flags->{stats} );
1128
1129     for my $flag ( sort keys %{$flags} ) {
1130
1131         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1132             &$code( $class, delete $flags->{$flag} );
1133         }
1134         else {
1135             $class->log->warn(qq/Unknown flag "$flag"/);
1136         }
1137     }
1138
1139     eval { require Catalyst::Devel; };
1140     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1141         $class->log->warn(<<"EOF");
1142 You are running an old script!
1143
1144   Please update by running (this will overwrite existing files):
1145     catalyst.pl -force -scripts $class
1146
1147   or (this will not overwrite existing files):
1148     catalyst.pl -scripts $class
1149
1150 EOF
1151     }
1152
1153     if ( $class->debug ) {
1154         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1155
1156         if (@plugins) {
1157             my $column_width = Catalyst::Utils::term_width() - 6;
1158             my $t = Text::SimpleTable->new($column_width);
1159             $t->row($_) for @plugins;
1160             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1161         }
1162
1163         my $dispatcher = $class->dispatcher;
1164         my $engine     = $class->engine;
1165         my $home       = $class->config->{home};
1166
1167         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1168         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1169
1170         $home
1171           ? ( -d $home )
1172           ? $class->log->debug(qq/Found home "$home"/)
1173           : $class->log->debug(qq/Home "$home" doesn't exist/)
1174           : $class->log->debug(q/Couldn't find home/);
1175     }
1176
1177     # Call plugins setup, this is stupid and evil.
1178     # Also screws C3 badly on 5.10, hack to avoid.
1179     {
1180         no warnings qw/redefine/;
1181         local *setup = sub { };
1182         $class->setup unless $Catalyst::__AM_RESTARTING;
1183     }
1184
1185     # Initialize our data structure
1186     $class->components( {} );
1187
1188     $class->setup_components;
1189
1190     if ( $class->debug ) {
1191         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1192         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1193         for my $comp ( sort keys %{ $class->components } ) {
1194             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1195             $t->row( $comp, $type );
1196         }
1197         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1198           if ( keys %{ $class->components } );
1199     }
1200
1201     # Add our self to components, since we are also a component
1202     if( $class->isa('Catalyst::Controller') ){
1203       $class->components->{$class} = $class;
1204     }
1205
1206     $class->setup_actions;
1207
1208     if ( $class->debug ) {
1209         my $name = $class->config->{name} || 'Application';
1210         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1211     }
1212
1213     if ($class->config->{case_sensitive}) {
1214         $class->log->warn($class . "->config->{case_sensitive} is set.");
1215         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1216     }
1217
1218     $class->setup_finalize;
1219     # Should be the last thing we do so that user things hooking
1220     # setup_finalize can log..
1221     $class->log->_flush() if $class->log->can('_flush');
1222     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1223 }
1224
1225 =head2 $app->setup_finalize
1226
1227 A hook to attach modifiers to. This method does not do anything except set the
1228 C<setup_finished> accessor.
1229
1230 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1231
1232 Example:
1233
1234     after setup_finalize => sub {
1235         my $app = shift;
1236
1237         ## do stuff here..
1238     };
1239
1240 =cut
1241
1242 sub setup_finalize {
1243     my ($class) = @_;
1244     $class->setup_finished(1);
1245 }
1246
1247 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1248
1249 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1250
1251 Constructs an absolute L<URI> object based on the application root, the
1252 provided path, and the additional arguments and query parameters provided.
1253 When used as a string, provides a textual URI.  If you need more flexibility
1254 than this (i.e. the option to provide relative URIs etc.) see
1255 L<Catalyst::Plugin::SmartURI>.
1256
1257 If no arguments are provided, the URI for the current action is returned.
1258 To return the current action and also provide @args, use
1259 C<< $c->uri_for( $c->action, @args ) >>.
1260
1261 If the first argument is a string, it is taken as a public URI path relative
1262 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1263 relative to the application root (if it does). It is then merged with
1264 C<< $c->request->base >>; any C<@args> are appended as additional path
1265 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1266
1267 If the first argument is a L<Catalyst::Action> it represents an action which
1268 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1269 optional C<\@captures> argument (an arrayref) allows passing the captured
1270 variables that are needed to fill in the paths of Chained and Regex actions;
1271 once the path is resolved, C<uri_for> continues as though a path was
1272 provided, appending any arguments or parameters and creating an absolute
1273 URI.
1274
1275 The captures for the current request can be found in
1276 C<< $c->request->captures >>, and actions can be resolved using
1277 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1278 path, use C<< $c->uri_for_action >> instead.
1279
1280   # Equivalent to $c->req->uri
1281   $c->uri_for($c->action, $c->req->captures,
1282       @{ $c->req->args }, $c->req->params);
1283
1284   # For the Foo action in the Bar controller
1285   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1286
1287   # Path to a static resource
1288   $c->uri_for('/static/images/logo.png');
1289
1290 =cut
1291
1292 sub uri_for {
1293     my ( $c, $path, @args ) = @_;
1294
1295     if ( $path->$_isa('Catalyst::Controller') ) {
1296         $path = $path->path_prefix;
1297         $path =~ s{/+\z}{};
1298         $path .= '/';
1299     }
1300
1301     undef($path) if (defined $path && $path eq '');
1302
1303     my $params =
1304       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1305
1306     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1307     foreach my $arg (@args) {
1308         utf8::encode($arg) if utf8::is_utf8($arg);
1309         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1310     }
1311
1312     if ( $path->$_isa('Catalyst::Action') ) { # action object
1313         s|/|%2F|g for @args;
1314         my $captures = [ map { s|/|%2F|g; $_; }
1315                         ( scalar @args && ref $args[0] eq 'ARRAY'
1316                          ? @{ shift(@args) }
1317                          : ()) ];
1318
1319         foreach my $capture (@$captures) {
1320             utf8::encode($capture) if utf8::is_utf8($capture);
1321             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1322         }
1323
1324         my $action = $path;
1325         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1326         if( !@args && $action->number_of_args ) {
1327             my $expanded_action = $c->dispatcher->expand_action( $action );
1328
1329             my $num_captures = $expanded_action->number_of_captures;
1330             unshift @args, splice @$captures, $num_captures;
1331         }
1332
1333        $path = $c->dispatcher->uri_for_action($action, $captures);
1334         if (not defined $path) {
1335             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1336                 if $c->debug;
1337             return undef;
1338         }
1339         $path = '/' if $path eq '';
1340     }
1341
1342     unshift(@args, $path);
1343
1344     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1345         my $namespace = $c->namespace;
1346         if (defined $path) { # cheesy hack to handle path '../foo'
1347            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1348         }
1349         unshift(@args, $namespace || '');
1350     }
1351
1352     # join args with '/', or a blank string
1353     my $args = join('/', grep { defined($_) } @args);
1354     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1355     $args =~ s!^/+!!;
1356
1357     my ($base, $class) = ('/', 'URI::_generic');
1358     if(blessed($c)) {
1359       $base = $c->req->base;
1360       $class = ref($base);
1361       $base =~ s{(?<!/)$}{/};
1362     }
1363
1364     my $query = '';
1365
1366     if (my @keys = keys %$params) {
1367       # somewhat lifted from URI::_query's query_form
1368       $query = '?'.join('&', map {
1369           my $val = $params->{$_};
1370           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1371           s/ /+/g;
1372           my $key = $_;
1373           $val = '' unless defined $val;
1374           (map {
1375               my $param = "$_";
1376               utf8::encode( $param ) if utf8::is_utf8($param);
1377               # using the URI::Escape pattern here so utf8 chars survive
1378               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1379               $param =~ s/ /+/g;
1380               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1381       } @keys);
1382     }
1383
1384     my $res = bless(\"${base}${args}${query}", $class);
1385     $res;
1386 }
1387
1388 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1389
1390 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1391
1392 =over
1393
1394 =item $path
1395
1396 A private path to the Catalyst action you want to create a URI for.
1397
1398 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1399 >> and passing the resulting C<$action> and the remaining arguments to C<<
1400 $c->uri_for >>.
1401
1402 You can also pass in a Catalyst::Action object, in which case it is passed to
1403 C<< $c->uri_for >>.
1404
1405 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1406
1407 For example, if the action looks like:
1408
1409  package MyApp::Controller::Users;
1410
1411  sub lst : Path('the-list') {}
1412
1413 You can use:
1414
1415  $c->uri_for_action('/users/lst')
1416
1417 and it will create the URI /users/the-list.
1418
1419 =item \@captures_and_args?
1420
1421 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1422 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1423 to interpolate all the parameters in the URI.
1424
1425 =item @args?
1426
1427 Optional list of extra arguments - can be supplied in the
1428 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1429 code.
1430
1431 Your action can have zero, a fixed or a variable number of args (e.g.
1432 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1433
1434 =item \%query_values?
1435
1436 Optional array reference of query parameters to append. E.g.
1437
1438   { foo => 'bar' }
1439
1440 will generate
1441
1442   /rest/of/your/uri?foo=bar
1443
1444 =back
1445
1446 =cut
1447
1448 sub uri_for_action {
1449     my ( $c, $path, @args ) = @_;
1450     my $action = blessed($path)
1451       ? $path
1452       : $c->dispatcher->get_action_by_path($path);
1453     unless (defined $action) {
1454       croak "Can't find action for path '$path'";
1455     }
1456     return $c->uri_for( $action, @args );
1457 }
1458
1459 =head2 $c->welcome_message
1460
1461 Returns the Catalyst welcome HTML page.
1462
1463 =cut
1464
1465 sub welcome_message {
1466     my $c      = shift;
1467     my $name   = $c->config->{name};
1468     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1469     my $prefix = Catalyst::Utils::appprefix( ref $c );
1470     $c->response->content_type('text/html; charset=utf-8');
1471     return <<"EOF";
1472 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1473     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1474 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1475     <head>
1476     <meta http-equiv="Content-Language" content="en" />
1477     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1478         <title>$name on Catalyst $VERSION</title>
1479         <style type="text/css">
1480             body {
1481                 color: #000;
1482                 background-color: #eee;
1483             }
1484             div#content {
1485                 width: 640px;
1486                 margin-left: auto;
1487                 margin-right: auto;
1488                 margin-top: 10px;
1489                 margin-bottom: 10px;
1490                 text-align: left;
1491                 background-color: #ccc;
1492                 border: 1px solid #aaa;
1493             }
1494             p, h1, h2 {
1495                 margin-left: 20px;
1496                 margin-right: 20px;
1497                 font-family: verdana, tahoma, sans-serif;
1498             }
1499             a {
1500                 font-family: verdana, tahoma, sans-serif;
1501             }
1502             :link, :visited {
1503                     text-decoration: none;
1504                     color: #b00;
1505                     border-bottom: 1px dotted #bbb;
1506             }
1507             :link:hover, :visited:hover {
1508                     color: #555;
1509             }
1510             div#topbar {
1511                 margin: 0px;
1512             }
1513             pre {
1514                 margin: 10px;
1515                 padding: 8px;
1516             }
1517             div#answers {
1518                 padding: 8px;
1519                 margin: 10px;
1520                 background-color: #fff;
1521                 border: 1px solid #aaa;
1522             }
1523             h1 {
1524                 font-size: 0.9em;
1525                 font-weight: normal;
1526                 text-align: center;
1527             }
1528             h2 {
1529                 font-size: 1.0em;
1530             }
1531             p {
1532                 font-size: 0.9em;
1533             }
1534             p img {
1535                 float: right;
1536                 margin-left: 10px;
1537             }
1538             span#appname {
1539                 font-weight: bold;
1540                 font-size: 1.6em;
1541             }
1542         </style>
1543     </head>
1544     <body>
1545         <div id="content">
1546             <div id="topbar">
1547                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1548                     $VERSION</h1>
1549              </div>
1550              <div id="answers">
1551                  <p>
1552                  <img src="$logo" alt="Catalyst Logo" />
1553                  </p>
1554                  <p>Welcome to the  world of Catalyst.
1555                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1556                     framework will make web development something you had
1557                     never expected it to be: Fun, rewarding, and quick.</p>
1558                  <h2>What to do now?</h2>
1559                  <p>That really depends  on what <b>you</b> want to do.
1560                     We do, however, provide you with a few starting points.</p>
1561                  <p>If you want to jump right into web development with Catalyst
1562                     you might want to start with a tutorial.</p>
1563 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1564 </pre>
1565 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1566 <pre>
1567 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1568 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1569 </code></pre>
1570                  <h2>What to do next?</h2>
1571                  <p>Next it's time to write an actual application. Use the
1572                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1573                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1574                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1575                     they can save you a lot of work.</p>
1576                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1577                     <p>Also, be sure to check out the vast and growing
1578                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1579                     you are likely to find what you need there.
1580                     </p>
1581
1582                  <h2>Need help?</h2>
1583                  <p>Catalyst has a very active community. Here are the main places to
1584                     get in touch with us.</p>
1585                  <ul>
1586                      <li>
1587                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1588                      </li>
1589                      <li>
1590                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1591                      </li>
1592                      <li>
1593                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1594                      </li>
1595                  </ul>
1596                  <h2>In conclusion</h2>
1597                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1598                     as we enjoyed making it. Please contact us if you have ideas
1599                     for improvement or other feedback.</p>
1600              </div>
1601          </div>
1602     </body>
1603 </html>
1604 EOF
1605 }
1606
1607 =head2 run_options
1608
1609 Contains a hash of options passed from the application script, including
1610 the original ARGV the script received, the processed values from that
1611 ARGV and any extra arguments to the script which were not processed.
1612
1613 This can be used to add custom options to your application's scripts
1614 and setup your application differently depending on the values of these
1615 options.
1616
1617 =head1 INTERNAL METHODS
1618
1619 These methods are not meant to be used by end users.
1620
1621 =head2 $c->components
1622
1623 Returns a hash of components.
1624
1625 =head2 $c->context_class
1626
1627 Returns or sets the context class.
1628
1629 =head2 $c->counter
1630
1631 Returns a hashref containing coderefs and execution counts (needed for
1632 deep recursion detection).
1633
1634 =head2 $c->depth
1635
1636 Returns the number of actions on the current internal execution stack.
1637
1638 =head2 $c->dispatch
1639
1640 Dispatches a request to actions.
1641
1642 =cut
1643
1644 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1645
1646 =head2 $c->dispatcher_class
1647
1648 Returns or sets the dispatcher class.
1649
1650 =head2 $c->dump_these
1651
1652 Returns a list of 2-element array references (name, structure) pairs
1653 that will be dumped on the error page in debug mode.
1654
1655 =cut
1656
1657 sub dump_these {
1658     my $c = shift;
1659     [ Request => $c->req ],
1660     [ Response => $c->res ],
1661     [ Stash => $c->stash ],
1662     [ Config => $c->config ];
1663 }
1664
1665 =head2 $c->engine_class
1666
1667 Returns or sets the engine class.
1668
1669 =head2 $c->execute( $class, $coderef )
1670
1671 Execute a coderef in given class and catch exceptions. Errors are available
1672 via $c->error.
1673
1674 =cut
1675
1676 sub execute {
1677     my ( $c, $class, $code ) = @_;
1678     $class = $c->component($class) || $class;
1679     $c->state(0);
1680
1681     if ( $c->depth >= $RECURSION ) {
1682         my $action = $code->reverse();
1683         $action = "/$action" unless $action =~ /->/;
1684         my $error = qq/Deep recursion detected calling "${action}"/;
1685         $c->log->error($error);
1686         $c->error($error);
1687         $c->state(0);
1688         return $c->state;
1689     }
1690
1691     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1692
1693     push( @{ $c->stack }, $code );
1694
1695     no warnings 'recursion';
1696     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1697     #      I have no idea how, ergo $ret (which appears to fix the issue)
1698     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1699
1700     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1701
1702     my $last = pop( @{ $c->stack } );
1703
1704     if ( my $error = $@ ) {
1705         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1706             $error->rethrow if $c->depth > 1;
1707         }
1708         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1709             $error->rethrow if $c->depth > 0;
1710         }
1711         else {
1712             unless ( ref $error ) {
1713                 no warnings 'uninitialized';
1714                 chomp $error;
1715                 my $class = $last->class;
1716                 my $name  = $last->name;
1717                 $error = qq/Caught exception in $class->$name "$error"/;
1718             }
1719             $c->error($error);
1720         }
1721         $c->state(0);
1722     }
1723     return $c->state;
1724 }
1725
1726 sub _stats_start_execute {
1727     my ( $c, $code ) = @_;
1728     my $appclass = ref($c) || $c;
1729     return if ( ( $code->name =~ /^_.*/ )
1730         && ( !$appclass->config->{show_internal_actions} ) );
1731
1732     my $action_name = $code->reverse();
1733     $c->counter->{$action_name}++;
1734
1735     my $action = $action_name;
1736     $action = "/$action" unless $action =~ /->/;
1737
1738     # determine if the call was the result of a forward
1739     # this is done by walking up the call stack and looking for a calling
1740     # sub of Catalyst::forward before the eval
1741     my $callsub = q{};
1742     for my $index ( 2 .. 11 ) {
1743         last
1744         if ( ( caller($index) )[0] eq 'Catalyst'
1745             && ( caller($index) )[3] eq '(eval)' );
1746
1747         if ( ( caller($index) )[3] =~ /forward$/ ) {
1748             $callsub = ( caller($index) )[3];
1749             $action  = "-> $action";
1750             last;
1751         }
1752     }
1753
1754     my $uid = $action_name . $c->counter->{$action_name};
1755
1756     # is this a root-level call or a forwarded call?
1757     if ( $callsub =~ /forward$/ ) {
1758         my $parent = $c->stack->[-1];
1759
1760         # forward, locate the caller
1761         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1762             $c->stats->profile(
1763                 begin  => $action,
1764                 parent => "$parent" . $c->counter->{"$parent"},
1765                 uid    => $uid,
1766             );
1767         }
1768         else {
1769
1770             # forward with no caller may come from a plugin
1771             $c->stats->profile(
1772                 begin => $action,
1773                 uid   => $uid,
1774             );
1775         }
1776     }
1777     else {
1778
1779         # root-level call
1780         $c->stats->profile(
1781             begin => $action,
1782             uid   => $uid,
1783         );
1784     }
1785     return $action;
1786
1787 }
1788
1789 sub _stats_finish_execute {
1790     my ( $c, $info ) = @_;
1791     $c->stats->profile( end => $info );
1792 }
1793
1794 =head2 $c->finalize
1795
1796 Finalizes the request.
1797
1798 =cut
1799
1800 sub finalize {
1801     my $c = shift;
1802
1803     for my $error ( @{ $c->error } ) {
1804         $c->log->error($error);
1805     }
1806
1807     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1808     # stuff like cometd and websockets
1809
1810     if($c->request->has_io_fh) {
1811       $c->log_response;
1812       return;
1813     }
1814
1815     # Allow engine to handle finalize flow (for POE)
1816     my $engine = $c->engine;
1817     if ( my $code = $engine->can('finalize') ) {
1818         $engine->$code($c);
1819     }
1820     else {
1821
1822         $c->finalize_uploads;
1823
1824         # Error
1825         if ( $#{ $c->error } >= 0 ) {
1826             $c->finalize_error;
1827         }
1828
1829         $c->finalize_headers unless $c->response->finalized_headers;
1830
1831         # HEAD request
1832         if ( $c->request->method eq 'HEAD' ) {
1833             $c->response->body('');
1834         }
1835
1836         $c->finalize_body;
1837     }
1838
1839     $c->log_response;
1840
1841     if ($c->use_stats) {
1842         my $elapsed = $c->stats->elapsed;
1843         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1844         $c->log->info(
1845             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1846     }
1847
1848     return $c->response->status;
1849 }
1850
1851 =head2 $c->finalize_body
1852
1853 Finalizes body.
1854
1855 =cut
1856
1857 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1858
1859 =head2 $c->finalize_cookies
1860
1861 Finalizes cookies.
1862
1863 =cut
1864
1865 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1866
1867 =head2 $c->finalize_error
1868
1869 Finalizes error.
1870
1871 =cut
1872
1873 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1874
1875 =head2 $c->finalize_headers
1876
1877 Finalizes headers.
1878
1879 =cut
1880
1881 sub finalize_headers {
1882     my $c = shift;
1883
1884     my $response = $c->response; #accessor calls can add up?
1885
1886     # Check if we already finalized headers
1887     return if $response->finalized_headers;
1888
1889     # Handle redirects
1890     if ( my $location = $response->redirect ) {
1891         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1892         $response->header( Location => $location );
1893
1894         if ( !$response->has_body ) {
1895             # Add a default body if none is already present
1896             my $encoded_location = encode_entities($location);
1897             $response->body(<<"EOF");
1898 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1899 <html xmlns="http://www.w3.org/1999/xhtml">
1900   <head>
1901     <title>Moved</title>
1902   </head>
1903   <body>
1904      <p>This item has moved <a href="$encoded_location">here</a>.</p>
1905   </body>
1906 </html>
1907 EOF
1908             $response->content_type('text/html; charset=utf-8');
1909         }
1910     }
1911
1912     # Content-Length
1913     if ( defined $response->body && length $response->body && !$response->content_length ) {
1914
1915         # get the length from a filehandle
1916         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1917         {
1918             my $size = -s $response->body;
1919             if ( $size ) {
1920                 $response->content_length( $size );
1921             }
1922             else {
1923                 $c->log->warn('Serving filehandle without a content-length');
1924             }
1925         }
1926         else {
1927             # everything should be bytes at this point, but just in case
1928             $response->content_length( length( $response->body ) );
1929         }
1930     }
1931
1932     # Errors
1933     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1934         $response->headers->remove_header("Content-Length");
1935         $response->body('');
1936     }
1937
1938     $c->finalize_cookies;
1939
1940     $c->response->finalize_headers();
1941
1942     # Done
1943     $response->finalized_headers(1);
1944 }
1945
1946 =head2 $c->finalize_output
1947
1948 An alias for finalize_body.
1949
1950 =head2 $c->finalize_read
1951
1952 Finalizes the input after reading is complete.
1953
1954 =cut
1955
1956 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1957
1958 =head2 $c->finalize_uploads
1959
1960 Finalizes uploads. Cleans up any temporary files.
1961
1962 =cut
1963
1964 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1965
1966 =head2 $c->get_action( $action, $namespace )
1967
1968 Gets an action in a given namespace.
1969
1970 =cut
1971
1972 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1973
1974 =head2 $c->get_actions( $action, $namespace )
1975
1976 Gets all actions of a given name in a namespace and all parent
1977 namespaces.
1978
1979 =cut
1980
1981 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1982
1983 =head2 $app->handle_request( @arguments )
1984
1985 Called to handle each HTTP request.
1986
1987 =cut
1988
1989 sub handle_request {
1990     my ( $class, @arguments ) = @_;
1991
1992     # Always expect worst case!
1993     my $status = -1;
1994     try {
1995         if ($class->debug) {
1996             my $secs = time - $START || 1;
1997             my $av = sprintf '%.3f', $COUNT / $secs;
1998             my $time = localtime time;
1999             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2000         }
2001
2002         my $c = $class->prepare(@arguments);
2003         $c->dispatch;
2004         $status = $c->finalize;
2005     }
2006     catch {
2007         chomp(my $error = $_);
2008         $class->log->error(qq/Caught exception in engine "$error"/);
2009     };
2010
2011     $COUNT++;
2012
2013     if(my $coderef = $class->log->can('_flush')){
2014         $class->log->$coderef();
2015     }
2016     return $status;
2017 }
2018
2019 =head2 $class->prepare( @arguments )
2020
2021 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2022 etc.).
2023
2024 =cut
2025
2026 has _uploadtmp => (
2027     is => 'ro',
2028     predicate => '_has_uploadtmp',
2029 );
2030
2031 sub prepare {
2032     my ( $class, @arguments ) = @_;
2033
2034     # XXX
2035     # After the app/ctxt split, this should become an attribute based on something passed
2036     # into the application.
2037     $class->context_class( ref $class || $class ) unless $class->context_class;
2038
2039     my $uploadtmp = $class->config->{uploadtmp};
2040     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2041
2042     $c->response->_context($c);
2043
2044     #surely this is not the most efficient way to do things...
2045     $c->stats($class->stats_class->new)->enable($c->use_stats);
2046     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2047         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2048     }
2049
2050     try {
2051         # Allow engine to direct the prepare flow (for POE)
2052         if ( my $prepare = $c->engine->can('prepare') ) {
2053             $c->engine->$prepare( $c, @arguments );
2054         }
2055         else {
2056             $c->prepare_request(@arguments);
2057             $c->prepare_connection;
2058             $c->prepare_query_parameters;
2059             $c->prepare_headers; # Just hooks, no longer needed - they just
2060             $c->prepare_cookies; # cause the lazy attribute on req to build
2061             $c->prepare_path;
2062
2063             # Prepare the body for reading, either by prepare_body
2064             # or the user, if they are using $c->read
2065             $c->prepare_read;
2066
2067             # Parse the body unless the user wants it on-demand
2068             unless ( ref($c)->config->{parse_on_demand} ) {
2069                 $c->prepare_body;
2070             }
2071         }
2072         $c->prepare_action;
2073     }
2074     # VERY ugly and probably shouldn't rely on ->finalize actually working
2075     catch {
2076         # failed prepare is always due to an invalid request, right?
2077         $c->response->status(400);
2078         $c->response->content_type('text/plain');
2079         $c->response->body('Bad Request');
2080         # Note we call finalize and then die here, which escapes
2081         # finalize being called in the enclosing block..
2082         # It in fact couldn't be called, as we don't return $c..
2083         # This is a mess - but I'm unsure you can fix this without
2084         # breaking compat for people doing crazy things (we should set
2085         # the 400 and just return the ctx here IMO, letting finalize get called
2086         # above...
2087         $c->finalize;
2088         die $_;
2089     };
2090
2091     $c->log_request;
2092
2093     return $c;
2094 }
2095
2096 =head2 $c->prepare_action
2097
2098 Prepares action. See L<Catalyst::Dispatcher>.
2099
2100 =cut
2101
2102 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2103
2104 =head2 $c->prepare_body
2105
2106 Prepares message body.
2107
2108 =cut
2109
2110 sub prepare_body {
2111     my $c = shift;
2112
2113     return if $c->request->_has_body;
2114
2115     # Initialize on-demand data
2116     $c->engine->prepare_body( $c, @_ );
2117     $c->prepare_parameters;
2118     $c->prepare_uploads;
2119 }
2120
2121 =head2 $c->prepare_body_chunk( $chunk )
2122
2123 Prepares a chunk of data before sending it to L<HTTP::Body>.
2124
2125 See L<Catalyst::Engine>.
2126
2127 =cut
2128
2129 sub prepare_body_chunk {
2130     my $c = shift;
2131     $c->engine->prepare_body_chunk( $c, @_ );
2132 }
2133
2134 =head2 $c->prepare_body_parameters
2135
2136 Prepares body parameters.
2137
2138 =cut
2139
2140 sub prepare_body_parameters {
2141     my $c = shift;
2142     $c->engine->prepare_body_parameters( $c, @_ );
2143 }
2144
2145 =head2 $c->prepare_connection
2146
2147 Prepares connection.
2148
2149 =cut
2150
2151 sub prepare_connection {
2152     my $c = shift;
2153     # XXX - This is called on the engine (not the request) to maintain
2154     #       Engine::PSGI back compat.
2155     $c->engine->prepare_connection($c);
2156 }
2157
2158 =head2 $c->prepare_cookies
2159
2160 Prepares cookies by ensuring that the attribute on the request
2161 object has been built.
2162
2163 =cut
2164
2165 sub prepare_cookies { my $c = shift; $c->request->cookies }
2166
2167 =head2 $c->prepare_headers
2168
2169 Prepares request headers by ensuring that the attribute on the request
2170 object has been built.
2171
2172 =cut
2173
2174 sub prepare_headers { my $c = shift; $c->request->headers }
2175
2176 =head2 $c->prepare_parameters
2177
2178 Prepares parameters.
2179
2180 =cut
2181
2182 sub prepare_parameters {
2183     my $c = shift;
2184     $c->prepare_body_parameters;
2185     $c->engine->prepare_parameters( $c, @_ );
2186 }
2187
2188 =head2 $c->prepare_path
2189
2190 Prepares path and base.
2191
2192 =cut
2193
2194 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2195
2196 =head2 $c->prepare_query_parameters
2197
2198 Prepares query parameters.
2199
2200 =cut
2201
2202 sub prepare_query_parameters {
2203     my $c = shift;
2204
2205     $c->engine->prepare_query_parameters( $c, @_ );
2206 }
2207
2208 =head2 $c->log_request
2209
2210 Writes information about the request to the debug logs.  This includes:
2211
2212 =over 4
2213
2214 =item * Request method, path, and remote IP address
2215
2216 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2217
2218 =item * Request parameters
2219
2220 =item * File uploads
2221
2222 =back
2223
2224 =cut
2225
2226 sub log_request {
2227     my $c = shift;
2228
2229     return unless $c->debug;
2230
2231     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2232     my $request = $dump->[1];
2233
2234     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2235     $method ||= '';
2236     $path = '/' unless length $path;
2237     $address ||= '';
2238     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2239
2240     $c->log_request_headers($request->headers);
2241
2242     if ( my $keywords = $request->query_keywords ) {
2243         $c->log->debug("Query keywords are: $keywords");
2244     }
2245
2246     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2247
2248     $c->log_request_uploads($request);
2249 }
2250
2251 =head2 $c->log_response
2252
2253 Writes information about the response to the debug logs by calling
2254 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2255
2256 =cut
2257
2258 sub log_response {
2259     my $c = shift;
2260
2261     return unless $c->debug;
2262
2263     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2264     my $response = $dump->[1];
2265
2266     $c->log_response_status_line($response);
2267     $c->log_response_headers($response->headers);
2268 }
2269
2270 =head2 $c->log_response_status_line($response)
2271
2272 Writes one line of information about the response to the debug logs.  This includes:
2273
2274 =over 4
2275
2276 =item * Response status code
2277
2278 =item * Content-Type header (if present)
2279
2280 =item * Content-Length header (if present)
2281
2282 =back
2283
2284 =cut
2285
2286 sub log_response_status_line {
2287     my ($c, $response) = @_;
2288
2289     $c->log->debug(
2290         sprintf(
2291             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2292             $response->status                            || 'unknown',
2293             $response->headers->header('Content-Type')   || 'unknown',
2294             $response->headers->header('Content-Length') || 'unknown'
2295         )
2296     );
2297 }
2298
2299 =head2 $c->log_response_headers($headers);
2300
2301 Hook method which can be wrapped by plugins to log the response headers.
2302 No-op in the default implementation.
2303
2304 =cut
2305
2306 sub log_response_headers {}
2307
2308 =head2 $c->log_request_parameters( query => {}, body => {} )
2309
2310 Logs request parameters to debug logs
2311
2312 =cut
2313
2314 sub log_request_parameters {
2315     my $c          = shift;
2316     my %all_params = @_;
2317
2318     return unless $c->debug;
2319
2320     my $column_width = Catalyst::Utils::term_width() - 44;
2321     foreach my $type (qw(query body)) {
2322         my $params = $all_params{$type};
2323         next if ! keys %$params;
2324         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2325         for my $key ( sort keys %$params ) {
2326             my $param = $params->{$key};
2327             my $value = defined($param) ? $param : '';
2328             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2329         }
2330         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2331     }
2332 }
2333
2334 =head2 $c->log_request_uploads
2335
2336 Logs file uploads included in the request to the debug logs.
2337 The parameter name, filename, file type, and file size are all included in
2338 the debug logs.
2339
2340 =cut
2341
2342 sub log_request_uploads {
2343     my $c = shift;
2344     my $request = shift;
2345     return unless $c->debug;
2346     my $uploads = $request->uploads;
2347     if ( keys %$uploads ) {
2348         my $t = Text::SimpleTable->new(
2349             [ 12, 'Parameter' ],
2350             [ 26, 'Filename' ],
2351             [ 18, 'Type' ],
2352             [ 9,  'Size' ]
2353         );
2354         for my $key ( sort keys %$uploads ) {
2355             my $upload = $uploads->{$key};
2356             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2357                 $t->row( $key, $u->filename, $u->type, $u->size );
2358             }
2359         }
2360         $c->log->debug( "File Uploads are:\n" . $t->draw );
2361     }
2362 }
2363
2364 =head2 $c->log_request_headers($headers);
2365
2366 Hook method which can be wrapped by plugins to log the request headers.
2367 No-op in the default implementation.
2368
2369 =cut
2370
2371 sub log_request_headers {}
2372
2373 =head2 $c->log_headers($type => $headers)
2374
2375 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2376
2377 =cut
2378
2379 sub log_headers {
2380     my $c       = shift;
2381     my $type    = shift;
2382     my $headers = shift;    # an HTTP::Headers instance
2383
2384     return unless $c->debug;
2385
2386     my $column_width = Catalyst::Utils::term_width() - 28;
2387     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2388     $headers->scan(
2389         sub {
2390             my ( $name, $value ) = @_;
2391             $t->row( $name, $value );
2392         }
2393     );
2394     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2395 }
2396
2397
2398 =head2 $c->prepare_read
2399
2400 Prepares the input for reading.
2401
2402 =cut
2403
2404 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2405
2406 =head2 $c->prepare_request
2407
2408 Prepares the engine request.
2409
2410 =cut
2411
2412 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2413
2414 =head2 $c->prepare_uploads
2415
2416 Prepares uploads.
2417
2418 =cut
2419
2420 sub prepare_uploads {
2421     my $c = shift;
2422
2423     $c->engine->prepare_uploads( $c, @_ );
2424 }
2425
2426 =head2 $c->prepare_write
2427
2428 Prepares the output for writing.
2429
2430 =cut
2431
2432 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2433
2434 =head2 $c->request_class
2435
2436 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2437
2438 =head2 $c->response_class
2439
2440 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2441
2442 =head2 $c->read( [$maxlength] )
2443
2444 Reads a chunk of data from the request body. This method is designed to
2445 be used in a while loop, reading C<$maxlength> bytes on every call.
2446 C<$maxlength> defaults to the size of the request if not specified.
2447
2448 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2449 directly.
2450
2451 Warning: If you use read(), Catalyst will not process the body,
2452 so you will not be able to access POST parameters or file uploads via
2453 $c->request.  You must handle all body parsing yourself.
2454
2455 =cut
2456
2457 sub read { my $c = shift; return $c->request->read( @_ ) }
2458
2459 =head2 $c->run
2460
2461 Starts the engine.
2462
2463 =cut
2464
2465 sub run {
2466   my $app = shift;
2467   $app->_make_immutable_if_needed;
2468   $app->engine_loader->needs_psgi_engine_compat_hack ?
2469     $app->engine->run($app, @_) :
2470       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2471 }
2472
2473 sub _make_immutable_if_needed {
2474     my $class = shift;
2475     my $meta = Class::MOP::get_metaclass_by_name($class);
2476     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2477     if (
2478         $meta->is_immutable
2479         && ! { $meta->immutable_options }->{replace_constructor}
2480         && $isa_ca
2481     ) {
2482         warn("You made your application class ($class) immutable, "
2483             . "but did not inline the\nconstructor. "
2484             . "This will break catalyst, as your app \@ISA "
2485             . "Class::Accessor(::Fast)?\nPlease pass "
2486             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2487     }
2488     unless ($meta->is_immutable) {
2489         # XXX - FIXME warning here as you should make your app immutable yourself.
2490         $meta->make_immutable(
2491             replace_constructor => 1,
2492         );
2493     }
2494 }
2495
2496 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2497
2498 Sets an action in a given namespace.
2499
2500 =cut
2501
2502 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2503
2504 =head2 $c->setup_actions($component)
2505
2506 Sets up actions for a component.
2507
2508 =cut
2509
2510 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2511
2512 =head2 $c->setup_components
2513
2514 This method is called internally to set up the application's components.
2515
2516 It finds modules by calling the L<locate_components> method, expands them to
2517 package names with the L<expand_component_module> method, and then installs
2518 each component into the application.
2519
2520 The C<setup_components> config option is passed to both of the above methods.
2521
2522 Installation of each component is performed by the L<setup_component> method,
2523 below.
2524
2525 =cut
2526
2527 sub setup_components {
2528     my $class = shift;
2529
2530     my $config  = $class->config->{ setup_components };
2531
2532     my @comps = $class->locate_components($config);
2533     my %comps = map { $_ => 1 } @comps;
2534
2535     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2536     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2537         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2538     ) if $deprecatedcatalyst_component_names;
2539
2540     for my $component ( @comps ) {
2541
2542         # We pass ignore_loaded here so that overlay files for (e.g.)
2543         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2544         # we know M::P::O found a file on disk so this is safe
2545
2546         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2547     }
2548
2549     for my $component (@comps) {
2550         my $instance = $class->components->{ $component } = $class->setup_component($component);
2551         my @expanded_components = $instance->can('expand_modules')
2552             ? $instance->expand_modules( $component, $config )
2553             : $class->expand_component_module( $component, $config );
2554         for my $component (@expanded_components) {
2555             next if $comps{$component};
2556             $class->components->{ $component } = $class->setup_component($component);
2557         }
2558     }
2559 }
2560
2561 =head2 $c->locate_components( $setup_component_config )
2562
2563 This method is meant to provide a list of component modules that should be
2564 setup for the application.  By default, it will use L<Module::Pluggable>.
2565
2566 Specify a C<setup_components> config option to pass additional options directly
2567 to L<Module::Pluggable>. To add additional search paths, specify a key named
2568 C<search_extra> as an array reference. Items in the array beginning with C<::>
2569 will have the application class name prepended to them.
2570
2571 =cut
2572
2573 sub locate_components {
2574     my $class  = shift;
2575     my $config = shift;
2576
2577     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2578     my $extra   = delete $config->{ search_extra } || [];
2579
2580     push @paths, @$extra;
2581
2582     my $locator = Module::Pluggable::Object->new(
2583         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2584         %$config
2585     );
2586
2587     # XXX think about ditching this sort entirely
2588     my @comps = sort { length $a <=> length $b } $locator->plugins;
2589
2590     return @comps;
2591 }
2592
2593 =head2 $c->expand_component_module( $component, $setup_component_config )
2594
2595 Components found by C<locate_components> will be passed to this method, which
2596 is expected to return a list of component (package) names to be set up.
2597
2598 =cut
2599
2600 sub expand_component_module {
2601     my ($class, $module) = @_;
2602     return Devel::InnerPackage::list_packages( $module );
2603 }
2604
2605 =head2 $c->setup_component
2606
2607 =cut
2608
2609 sub setup_component {
2610     my( $class, $component ) = @_;
2611
2612     unless ( $component->can( 'COMPONENT' ) ) {
2613         return $component;
2614     }
2615
2616     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2617     my $config = $class->config->{ $suffix } || {};
2618     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2619     # methods also pass it. local to avoid pointlessly shitting in config
2620     # for the debug screen, as $component is already the key name.
2621     local $config->{catalyst_component_name} = $component;
2622
2623     my $instance = eval { $component->COMPONENT( $class, $config ); };
2624
2625     if ( my $error = $@ ) {
2626         chomp $error;
2627         Catalyst::Exception->throw(
2628             message => qq/Couldn't instantiate component "$component", "$error"/
2629         );
2630     }
2631
2632     unless (blessed $instance) {
2633         my $metaclass = Moose::Util::find_meta($component);
2634         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2635         my $component_method_from = $method_meta->associated_metaclass->name;
2636         my $value = defined($instance) ? $instance : 'undef';
2637         Catalyst::Exception->throw(
2638             message =>
2639             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2640         );
2641     }
2642     return $instance;
2643 }
2644
2645 =head2 $c->setup_dispatcher
2646
2647 Sets up dispatcher.
2648
2649 =cut
2650
2651 sub setup_dispatcher {
2652     my ( $class, $dispatcher ) = @_;
2653
2654     if ($dispatcher) {
2655         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2656     }
2657
2658     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2659         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2660     }
2661
2662     unless ($dispatcher) {
2663         $dispatcher = $class->dispatcher_class;
2664     }
2665
2666     Class::MOP::load_class($dispatcher);
2667
2668     # dispatcher instance
2669     $class->dispatcher( $dispatcher->new );
2670 }
2671
2672 =head2 $c->setup_engine
2673
2674 Sets up engine.
2675
2676 =cut
2677
2678 sub engine_class {
2679     my ($class, $requested_engine) = @_;
2680
2681     if (!$class->engine_loader || $requested_engine) {
2682         $class->engine_loader(
2683             Catalyst::EngineLoader->new({
2684                 application_name => $class,
2685                 (defined $requested_engine
2686                      ? (catalyst_engine_class => $requested_engine) : ()),
2687             }),
2688         );
2689     }
2690
2691     $class->engine_loader->catalyst_engine_class;
2692 }
2693
2694 sub setup_engine {
2695     my ($class, $requested_engine) = @_;
2696
2697     my $engine = do {
2698         my $loader = $class->engine_loader;
2699
2700         if (!$loader || $requested_engine) {
2701             $loader = Catalyst::EngineLoader->new({
2702                 application_name => $class,
2703                 (defined $requested_engine
2704                      ? (requested_engine => $requested_engine) : ()),
2705             }),
2706
2707             $class->engine_loader($loader);
2708         }
2709
2710         $loader->catalyst_engine_class;
2711     };
2712
2713     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2714     return if $class->loading_psgi_file;
2715
2716     Class::MOP::load_class($engine);
2717
2718     if ($ENV{MOD_PERL}) {
2719         my $apache = $class->engine_loader->auto;
2720
2721         my $meta = find_meta($class);
2722         my $was_immutable = $meta->is_immutable;
2723         my %immutable_options = $meta->immutable_options;
2724         $meta->make_mutable if $was_immutable;
2725
2726         $meta->add_method(handler => sub {
2727             my $r = shift;
2728             my $psgi_app = $class->_finalized_psgi_app;
2729             $apache->call_app($r, $psgi_app);
2730         });
2731
2732         $meta->make_immutable(%immutable_options) if $was_immutable;
2733     }
2734
2735     $class->engine( $engine->new );
2736
2737     return;
2738 }
2739
2740 sub _finalized_psgi_app {
2741     my ($app) = @_;
2742
2743     unless ($app->_psgi_app) {
2744         my $psgi_app = $app->_setup_psgi_app;
2745         $app->_psgi_app($psgi_app);
2746     }
2747
2748     return $app->_psgi_app;
2749 }
2750
2751 sub _setup_psgi_app {
2752     my ($app) = @_;
2753
2754     for my $home (Path::Class::Dir->new($app->config->{home})) {
2755         my $psgi_file = $home->file(
2756             Catalyst::Utils::appprefix($app) . '.psgi',
2757         );
2758
2759         next unless -e $psgi_file;
2760
2761         # If $psgi_file calls ->setup_engine, it's doing so to load
2762         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2763         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2764         # anyway. So set a flag (ick) that tells setup_engine not to populate
2765         # $c->engine or do any other things we might regret.
2766
2767         $app->loading_psgi_file(1);
2768         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2769         $app->loading_psgi_file(0);
2770
2771         return $psgi_app
2772             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2773
2774         warn <<"EOW";
2775 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2776
2777 Its content has been ignored. Please consult the Catalyst::Upgrading
2778 documentation on how to upgrade from Catalyst::Engine::PSGI.
2779 EOW
2780     }
2781
2782     return $app->apply_default_middlewares($app->psgi_app);
2783 }
2784
2785 =head2 $c->apply_default_middlewares
2786
2787 Adds the following L<Plack> middlewares to your application, since they are
2788 useful and commonly needed:
2789
2790 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2791 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2792 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2793 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2794 applied since this middleware is smart enough to conditionally apply itself).
2795
2796 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2797 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2798 $ENV{SCRIPT_NAME}
2799
2800 =cut
2801
2802
2803 sub apply_default_middlewares {
2804     my ($app, $psgi_app) = @_;
2805
2806     $psgi_app = Plack::Middleware::Conditional->wrap(
2807         $psgi_app,
2808         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2809         condition => sub {
2810             my ($env) = @_;
2811             return if $app->config->{ignore_frontend_proxy};
2812             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2813                 || $app->config->{using_frontend_proxy};
2814         },
2815     );
2816
2817     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2818     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2819     $psgi_app = Plack::Middleware::Conditional->wrap(
2820         $psgi_app,
2821         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2822         condition => sub {
2823             my ($env) = @_;
2824             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2825             return unless $1 < 4.23;
2826             1;
2827         },
2828     );
2829
2830     # we're applying this unconditionally as the middleware itself already makes
2831     # sure it doesn't fuck things up if it's not running under one of the right
2832     # IIS versions
2833     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2834
2835     # And another IIS issue, this time with IIS7.
2836     $psgi_app = Plack::Middleware::Conditional->wrap(
2837         $psgi_app,
2838         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2839         condition => sub {
2840             my ($env) = @_;
2841             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2842         },
2843     );
2844
2845     return $psgi_app;
2846 }
2847
2848 =head2 $c->psgi_app
2849
2850 Returns a PSGI application code reference for the catalyst application
2851 C<$c>. This is the bare application without any middlewares
2852 applied. C<${myapp}.psgi> is not taken into account.
2853
2854 This is what you want to be using to retrieve the PSGI application code
2855 reference of your Catalyst application for use in F<.psgi> files.
2856
2857 =cut
2858
2859 sub psgi_app {
2860     my ($app) = @_;
2861     return $app->engine->build_psgi_app($app);
2862 }
2863
2864 =head2 $c->setup_home
2865
2866 Sets up the home directory.
2867
2868 =cut
2869
2870 sub setup_home {
2871     my ( $class, $home ) = @_;
2872
2873     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2874         $home = $env;
2875     }
2876
2877     $home ||= Catalyst::Utils::home($class);
2878
2879     if ($home) {
2880         #I remember recently being scolded for assigning config values like this
2881         $class->config->{home} ||= $home;
2882         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2883     }
2884 }
2885
2886 =head2 $c->setup_log
2887
2888 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2889 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2890 log to.
2891
2892 This method also installs a C<debug> method that returns a true value into the
2893 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2894 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2895
2896 Note that if the log has already been setup, by either a previous call to
2897 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2898 that this method won't actually set up the log object.
2899
2900 =cut
2901
2902 sub setup_log {
2903     my ( $class, $levels ) = @_;
2904
2905     $levels ||= '';
2906     $levels =~ s/^\s+//;
2907     $levels =~ s/\s+$//;
2908     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2909
2910     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2911     if ( defined $env_debug ) {
2912         $levels{debug} = 1 if $env_debug; # Ugly!
2913         delete($levels{debug}) unless $env_debug;
2914     }
2915
2916     unless ( $class->log ) {
2917         $class->log( Catalyst::Log->new(keys %levels) );
2918     }
2919
2920     if ( $levels{debug} ) {
2921         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2922         $class->log->debug('Debug messages enabled');
2923     }
2924 }
2925
2926 =head2 $c->setup_plugins
2927
2928 Sets up plugins.
2929
2930 =cut
2931
2932 =head2 $c->setup_stats
2933
2934 Sets up timing statistics class.
2935
2936 =cut
2937
2938 sub setup_stats {
2939     my ( $class, $stats ) = @_;
2940
2941     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2942
2943     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2944     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2945         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2946         $class->log->debug('Statistics enabled');
2947     }
2948 }
2949
2950
2951 =head2 $c->registered_plugins
2952
2953 Returns a sorted list of the plugins which have either been stated in the
2954 import list.
2955
2956 If passed a given plugin name, it will report a boolean value indicating
2957 whether or not that plugin is loaded.  A fully qualified name is required if
2958 the plugin name does not begin with C<Catalyst::Plugin::>.
2959
2960  if ($c->registered_plugins('Some::Plugin')) {
2961      ...
2962  }
2963
2964 =cut
2965
2966 {
2967
2968     sub registered_plugins {
2969         my $proto = shift;
2970         return sort keys %{ $proto->_plugins } unless @_;
2971         my $plugin = shift;
2972         return 1 if exists $proto->_plugins->{$plugin};
2973         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2974     }
2975
2976     sub _register_plugin {
2977         my ( $proto, $plugin, $instant ) = @_;
2978         my $class = ref $proto || $proto;
2979
2980         Class::MOP::load_class( $plugin );
2981         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2982             if $plugin->isa( 'Catalyst::Component' );
2983         my $plugin_meta = Moose::Meta::Class->create($plugin);
2984         if (!$plugin_meta->has_method('new')
2985             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
2986             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
2987         }
2988         if (!$instant && !$proto->_plugins->{$plugin}) {
2989             my $meta = Class::MOP::get_metaclass_by_name($class);
2990             $meta->superclasses($plugin, $meta->superclasses);
2991         }
2992         $proto->_plugins->{$plugin} = 1;
2993         return $class;
2994     }
2995
2996     sub _default_plugins { return qw(Unicode::Encoding) }
2997
2998     sub setup_plugins {
2999         my ( $class, $plugins ) = @_;
3000
3001         $class->_plugins( {} ) unless $class->_plugins;
3002         $plugins = [ grep {
3003             m/Unicode::Encoding/ ? do {
3004                 $class->log->warn(
3005                     'Unicode::Encoding plugin is auto-applied,'
3006                     . ' please remove this from your appclass'
3007                     . ' and make sure to define "encoding" config'
3008                 );
3009                 unless (exists $class->config->{'encoding'}) {
3010                   $class->config->{'encoding'} = 'UTF-8';
3011                 }
3012                 () }
3013                 : $_
3014         } @$plugins ];
3015         push @$plugins, $class->_default_plugins;
3016         $plugins = Data::OptList::mkopt($plugins || []);
3017
3018         my @plugins = map {
3019             [ Catalyst::Utils::resolve_namespace(
3020                   $class . '::Plugin',
3021                   'Catalyst::Plugin', $_->[0]
3022               ),
3023               $_->[1],
3024             ]
3025          } @{ $plugins };
3026
3027         for my $plugin ( reverse @plugins ) {
3028             Class::MOP::load_class($plugin->[0], $plugin->[1]);
3029             my $meta = find_meta($plugin->[0]);
3030             next if $meta && $meta->isa('Moose::Meta::Role');
3031
3032             $class->_register_plugin($plugin->[0]);
3033         }
3034
3035         my @roles =
3036             map  { $_->[0]->name, $_->[1] }
3037             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3038             map  { [find_meta($_->[0]), $_->[1]] }
3039             @plugins;
3040
3041         Moose::Util::apply_all_roles(
3042             $class => @roles
3043         ) if @roles;
3044     }
3045 }
3046
3047 =head2 $c->stack
3048
3049 Returns an arrayref of the internal execution stack (actions that are
3050 currently executing).
3051
3052 =head2 $c->stats
3053
3054 Returns the current timing statistics object. By default Catalyst uses
3055 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3056 L<< stats_class|/"$c->stats_class" >>.
3057
3058 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3059 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3060 profile explicitly, although MyApp.pm still won't profile nor output anything
3061 by itself.
3062
3063 =head2 $c->stats_class
3064
3065 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3066
3067 =head2 $c->use_stats
3068
3069 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3070
3071 Note that this is a static method, not an accessor and should be overridden
3072 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3073
3074 =cut
3075
3076 sub use_stats { 0 }
3077
3078
3079 =head2 $c->write( $data )
3080
3081 Writes $data to the output stream. When using this method directly, you
3082 will need to manually set the C<Content-Length> header to the length of
3083 your output data, if known.
3084
3085 =cut
3086
3087 sub write {
3088     my $c = shift;
3089
3090     # Finalize headers if someone manually writes output (for compat)
3091     $c->finalize_headers;
3092
3093     return $c->response->write( @_ );
3094 }
3095
3096 =head2 version
3097
3098 Returns the Catalyst version number. Mostly useful for "powered by"
3099 messages in template systems.
3100
3101 =cut
3102
3103 sub version { return $Catalyst::VERSION }
3104
3105 =head1 CONFIGURATION
3106
3107 There are a number of 'base' config variables which can be set:
3108
3109 =over
3110
3111 =item *
3112
3113 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3114
3115 =item *
3116
3117 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3118
3119 =item *
3120
3121 C<disable_component_resolution_regex_fallback> - Turns
3122 off the deprecated component resolution functionality so
3123 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3124 are called then regex search will not be attempted on string values and
3125 instead C<undef> will be returned.
3126
3127 =item *
3128
3129 C<home> - The application home directory. In an uninstalled application,
3130 this is the top level application directory. In an installed application,
3131 this will be the directory containing C<< MyApp.pm >>.
3132
3133 =item *
3134
3135 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3136
3137 =item *
3138
3139 C<name> - The name of the application in debug messages and the debug and
3140 welcome screens
3141
3142 =item *
3143
3144 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3145 until it is accessed. This allows you to (for example) check authentication (and reject
3146 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3147
3148 =item *
3149
3150 C<root> - The root directory for templates. Usually this is just a
3151 subdirectory of the home directory, but you can set it to change the
3152 templates to a different directory.
3153
3154 =item *
3155
3156 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3157 namespaces from which components will be loaded (and constructed and stored in
3158 C<< $c->components >>).
3159
3160 =item *
3161
3162 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3163 to be shown in hit debug tables in the test server.
3164
3165 =item *
3166
3167 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3168 variable should be used for determining the request path.
3169
3170 Most web server environments pass the requested path to the application using environment variables,
3171 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3172 exposed as C<< $c->request->base >>) and the request path below that base.
3173
3174 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3175 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3176
3177 =over
3178
3179 =item use_request_uri_for_path => 0
3180
3181 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3182 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3183 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3184 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3185
3186 However this method has the major disadvantage that it is impossible to correctly decode some elements
3187 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3188 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3189 can't distinguish / vs %2F in paths (in addition to other encoded values).
3190
3191 =item use_request_uri_for_path => 1
3192
3193 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3194 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3195 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3196
3197 Given that this method of path resolution is provably more correct, it is recommended that you use
3198 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3199 aware of the implications of not being able to handle encoded URI paths correctly.
3200
3201 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3202 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3203 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3204 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3205 C<< $c->request->base >> will be incorrect.
3206
3207 =back
3208
3209 =item *
3210
3211 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3212
3213 =item *
3214
3215 C<encoding> - See L</ENCODING>
3216
3217 =item *
3218
3219 C<abort_chain_on_error_fix>
3220
3221 When there is an error in an action chain, the default behavior is to continue
3222 processing the remaining actions and then catch the error upon chain end.  This
3223 can lead to running actions when the application is in an unexpected state.  If
3224 you have this issue, setting this config value to true will promptly exit a
3225 chain when there is an error raised in any action (thus terminating the chain
3226 early.)
3227
3228 use like:
3229
3230     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3231
3232 In the future this might become the default behavior.
3233
3234 =back
3235
3236 =head1 INTERNAL ACTIONS
3237
3238 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3239 C<_ACTION>, and C<_END>. These are by default not shown in the private
3240 action table, but you can make them visible with a config parameter.
3241
3242     MyApp->config(show_internal_actions => 1);
3243
3244 =head1 ON-DEMAND PARSER
3245
3246 The request body is usually parsed at the beginning of a request,
3247 but if you want to handle input yourself, you can enable on-demand
3248 parsing with a config parameter.
3249
3250     MyApp->config(parse_on_demand => 1);
3251
3252 =head1 PROXY SUPPORT
3253
3254 Many production servers operate using the common double-server approach,
3255 with a lightweight frontend web server passing requests to a larger
3256 backend server. An application running on the backend server must deal
3257 with two problems: the remote user always appears to be C<127.0.0.1> and
3258 the server's hostname will appear to be C<localhost> regardless of the
3259 virtual host that the user connected through.
3260
3261 Catalyst will automatically detect this situation when you are running
3262 the frontend and backend servers on the same machine. The following
3263 changes are made to the request.
3264
3265     $c->req->address is set to the user's real IP address, as read from
3266     the HTTP X-Forwarded-For header.
3267
3268     The host value for $c->req->base and $c->req->uri is set to the real
3269     host, as read from the HTTP X-Forwarded-Host header.
3270
3271 Additionally, you may be running your backend application on an insecure
3272 connection (port 80) while your frontend proxy is running under SSL.  If there
3273 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3274 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3275 be created properly.
3276
3277 In the case of passing in:
3278
3279     X-Forwarded-Port: 443
3280
3281 All calls to C<uri_for> will result in an https link, as is expected.
3282
3283 Obviously, your web server must support these headers for this to work.
3284
3285 In a more complex server farm environment where you may have your
3286 frontend proxy server(s) on different machines, you will need to set a
3287 configuration option to tell Catalyst to read the proxied data from the
3288 headers.
3289
3290     MyApp->config(using_frontend_proxy => 1);
3291
3292 If you do not wish to use the proxy support at all, you may set:
3293
3294     MyApp->config(ignore_frontend_proxy => 0);
3295
3296 =head2 Note about psgi files
3297
3298 Note that if you supply your own .psgi file, calling
3299 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3300
3301 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3302 in your psgi, for example:
3303
3304     builder {
3305         enable "Plack::Middleware::ReverseProxy";
3306         MyApp->psgi_app
3307     };
3308
3309 This will unconditionally add the ReverseProxy support, or you need to call
3310 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3311 apply the support depending upon your config).
3312
3313 See L<Catalyst::PSGI> for more information.
3314
3315 =head1 THREAD SAFETY
3316
3317 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3318 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3319 believe the Catalyst core to be thread-safe.
3320
3321 If you plan to operate in a threaded environment, remember that all other
3322 modules you are using must also be thread-safe. Some modules, most notably
3323 L<DBD::SQLite>, are not thread-safe.
3324
3325 =head1 ENCODING
3326
3327 On request, decodes all params from encoding into a sequence of
3328 logical characters. On response, encodes body into encoding.
3329
3330 =head2 Methods
3331
3332 =over 4
3333
3334 =item encoding
3335
3336 Returns an instance of an C<Encode> encoding
3337
3338     print $c->encoding->name
3339
3340 =item handle_unicode_encoding_exception ($exception_context)
3341
3342 Method called when decoding process for a request fails.
3343
3344 An C<$exception_context> hashref is provided to allow you to override the
3345 behaviour of your application when given data with incorrect encodings.
3346
3347 The default method throws exceptions in the case of invalid request parameters
3348 (resulting in a 500 error), but ignores errors in upload filenames.
3349
3350 The keys passed in the C<$exception_context> hash are:
3351
3352 =over
3353
3354 =item param_value
3355
3356 The value which was not able to be decoded.
3357
3358 =item error_msg
3359
3360 The exception received from L<Encode>.
3361
3362 =item encoding_step
3363
3364 What type of data was being decoded. Valid values are (currently)
3365 C<params> - for request parameters / arguments / captures
3366 and C<uploads> - for request upload filenames.
3367
3368 =back
3369
3370 =back
3371
3372 =head1 SUPPORT
3373
3374 IRC:
3375
3376     Join #catalyst on irc.perl.org.
3377
3378 Mailing Lists:
3379
3380     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3381     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3382
3383 Web:
3384
3385     http://catalyst.perl.org
3386
3387 Wiki:
3388
3389     http://dev.catalyst.perl.org
3390
3391 =head1 SEE ALSO
3392
3393 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3394
3395 =head2 L<Catalyst::Manual> - The Catalyst Manual
3396
3397 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3398
3399 =head2 L<Catalyst::Engine> - Core engine
3400
3401 =head2 L<Catalyst::Log> - Log class.
3402
3403 =head2 L<Catalyst::Request> - Request object
3404
3405 =head2 L<Catalyst::Response> - Response object
3406
3407 =head2 L<Catalyst::Test> - The test suite.
3408
3409 =head1 PROJECT FOUNDER
3410
3411 sri: Sebastian Riedel <sri@cpan.org>
3412
3413 =head1 CONTRIBUTORS
3414
3415 abw: Andy Wardley
3416
3417 acme: Leon Brocard <leon@astray.com>
3418
3419 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3420
3421 Andrew Bramble
3422
3423 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3424
3425 Andrew Ruthven
3426
3427 andyg: Andy Grundman <andy@hybridized.org>
3428
3429 audreyt: Audrey Tang
3430
3431 bricas: Brian Cassidy <bricas@cpan.org>
3432
3433 Caelum: Rafael Kitover <rkitover@io.com>
3434
3435 chansen: Christian Hansen
3436
3437 chicks: Christopher Hicks
3438
3439 Chisel Wright C<pause@herlpacker.co.uk>
3440
3441 Danijel Milicevic C<me@danijel.de>
3442
3443 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3444
3445 David Naughton, C<naughton@umn.edu>
3446
3447 David E. Wheeler
3448
3449 dhoss: Devin Austin <dhoss@cpan.org>
3450
3451 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3452
3453 Drew Taylor
3454
3455 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3456
3457 esskar: Sascha Kiefer
3458
3459 fireartist: Carl Franks <cfranks@cpan.org>
3460
3461 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3462
3463 gabb: Danijel Milicevic
3464
3465 Gary Ashton Jones
3466
3467 Gavin Henry C<ghenry@perl.me.uk>
3468
3469 Geoff Richards
3470
3471 groditi: Guillermo Roditi <groditi@gmail.com>
3472
3473 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3474
3475 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3476
3477 jcamacho: Juan Camacho
3478
3479 jester: Jesse Sheidlower C<jester@panix.com>
3480
3481 jhannah: Jay Hannah <jay@jays.net>
3482
3483 Jody Belka
3484
3485 Johan Lindstrom
3486
3487 jon: Jon Schutz <jjschutz@cpan.org>
3488
3489 Jonathan Rockway C<< <jrockway@cpan.org> >>
3490
3491 Kieren Diment C<kd@totaldatasolution.com>
3492
3493 konobi: Scott McWhirter <konobi@cpan.org>
3494
3495 marcus: Marcus Ramberg <mramberg@cpan.org>
3496
3497 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3498
3499 mgrimes: Mark Grimes <mgrimes@cpan.org>
3500
3501 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3502
3503 mugwump: Sam Vilain
3504
3505 naughton: David Naughton
3506
3507 ningu: David Kamholz <dkamholz@cpan.org>
3508
3509 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3510
3511 numa: Dan Sully <daniel@cpan.org>
3512
3513 obra: Jesse Vincent
3514
3515 Octavian Rasnita
3516
3517 omega: Andreas Marienborg
3518
3519 Oleg Kostyuk <cub.uanic@gmail.com>
3520
3521 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3522
3523 rafl: Florian Ragwitz <rafl@debian.org>
3524
3525 random: Roland Lammel <lammel@cpan.org>
3526
3527 Robert Sedlacek C<< <rs@474.at> >>
3528
3529 SpiceMan: Marcel Montes
3530
3531 sky: Arthur Bergman
3532
3533 szbalint: Balint Szilakszi <szbalint@cpan.org>
3534
3535 t0m: Tomas Doran <bobtfish@bobtfish.net>
3536
3537 Ulf Edvinsson
3538
3539 Viljo Marrandi C<vilts@yahoo.com>
3540
3541 Will Hawes C<info@whawes.co.uk>
3542
3543 willert: Sebastian Willert <willert@cpan.org>
3544
3545 wreis: Wallace Reis <wreis@cpan.org>
3546
3547 Yuval Kogman, C<nothingmuch@woobling.org>
3548
3549 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3550
3551 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3552
3553 =head1 COPYRIGHT
3554
3555 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3556
3557 =head1 LICENSE
3558
3559 This library is free software. You can redistribute it and/or modify it under
3560 the same terms as Perl itself.
3561
3562 =cut
3563
3564 no Moose;
3565
3566 __PACKAGE__->meta->make_immutable;
3567
3568 1;