lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Util;
  45 use Class::Load 'load_class';
  46
  47 BEGIN { require 5.008003; }
  48
  49 has stack => (is => 'ro', default => sub { [] });
  50 has stash => (is => 'rw', default => sub { {} });
  51 has state => (is => 'rw', default => 0);
  52 has stats => (is => 'rw');
  53 has action => (is => 'rw');
  54 has counter => (is => 'rw', default => sub { {} });
  55 has request => (
  56     is => 'rw',
  57     default => sub {
  58         my $self = shift;
  59         $self->request_class->new($self->_build_request_constructor_args);
  60     },
  61     lazy => 1,
  62 );
  63 sub _build_request_constructor_args {
  64     my $self = shift;
  65     my %p = ( _log => $self->log );
  66     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  67     $p{data_handlers} = {$self->registered_data_handlers};
  68     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  69       if $self->config->{use_hash_multivalue_in_request};
  70     \%p;
  71 }
  72
  73 has response => (
  74     is => 'rw',
  75     default => sub {
  76         my $self = shift;
  77         $self->response_class->new($self->_build_response_constructor_args);
  78     },
  79     lazy => 1,
  80 );
  81 sub _build_response_constructor_args {
  82     my $self = shift;
  83     { _log => $self->log };
  84 }
  85
  86 has namespace => (is => 'rw');
  87
  88 sub depth { scalar @{ shift->stack || [] }; }
  89 sub comp { shift->component(@_) }
  90
  91 sub req {
  92     my $self = shift; return $self->request(@_);
  93 }
  94 sub res {
  95     my $self = shift; return $self->response(@_);
  96 }
  97
  98 # For backwards compatibility
  99 sub finalize_output { shift->finalize_body(@_) };
 100
 101 # For statistics
 102 our $COUNT     = 1;
 103 our $START     = time;
 104 our $RECURSION = 1000;
 105 our $DETACH    = Catalyst::Exception::Detach->new;
 106 our $GO        = Catalyst::Exception::Go->new;
 107
 108 #I imagine that very few of these really need to be class variables. if any.
 109 #maybe we should just make them attributes with a default?
 110 __PACKAGE__->mk_classdata($_)
 111   for qw/components arguments dispatcher engine log dispatcher_class
 112   engine_loader context_class request_class response_class stats_class
 113   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 114   _data_handlers/;
 115
 116 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 117 __PACKAGE__->request_class('Catalyst::Request');
 118 __PACKAGE__->response_class('Catalyst::Response');
 119 __PACKAGE__->stats_class('Catalyst::Stats');
 120
 121 # Remember to update this in Catalyst::Runtime as well!
 122
 123 our $VERSION = '5.90052';
 124
 125 sub import {
 126     my ( $class, @arguments ) = @_;
 127
 128     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 129     # callers @ISA.
 130     return unless $class eq 'Catalyst';
 131
 132     my $caller = caller();
 133     return if $caller eq 'main';
 134
 135     my $meta = Moose::Meta::Class->initialize($caller);
 136     unless ( $caller->isa('Catalyst') ) {
 137         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 138         $meta->superclasses(@superclasses);
 139     }
 140     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 141     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 142
 143     unless( $meta->has_method('meta') ){
 144         if ($Moose::VERSION >= 1.15) {
 145             $meta->_add_meta_method('meta');
 146         }
 147         else {
 148             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 149         }
 150     }
 151
 152     $caller->arguments( [@arguments] );
 153     $caller->setup_home;
 154 }
 155
 156 sub _application { $_[0] }
 157
 158 =encoding UTF-8
 159
 160 =head1 NAME
 161
 162 Catalyst - The Elegant MVC Web Application Framework
 163
 164 =head1 SYNOPSIS
 165
 166 See the L<Catalyst::Manual> distribution for comprehensive
 167 documentation and tutorials.
 168
 169     # Install Catalyst::Devel for helpers and other development tools
 170     # use the helper to create a new application
 171     catalyst.pl MyApp
 172
 173     # add models, views, controllers
 174     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 175     script/myapp_create.pl view MyTemplate TT
 176     script/myapp_create.pl controller Search
 177
 178     # built in testserver -- use -r to restart automatically on changes
 179     # --help to see all available options
 180     script/myapp_server.pl
 181
 182     # command line testing interface
 183     script/myapp_test.pl /yada
 184
 185     ### in lib/MyApp.pm
 186     use Catalyst qw/-Debug/; # include plugins here as well
 187
 188     ### In lib/MyApp/Controller/Root.pm (autocreated)
 189     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 190         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 191         $c->stash->{template} = 'foo.tt'; # set the template
 192         # lookup something from db -- stash vars are passed to TT
 193         $c->stash->{data} =
 194           $c->model('Database::Foo')->search( { country => $args[0] } );
 195         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 196             $c->forward( 'bar' ); # process another action
 197             # do something else after forward returns
 198         }
 199     }
 200
 201     # The foo.tt TT template can use the stash data from the database
 202     [% WHILE (item = data.next) %]
 203         [% item.foo %]
 204     [% END %]
 205
 206     # called for /bar/of/soap, /bar/of/soap/10, etc.
 207     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 208
 209     # called after all actions are finished
 210     sub end : Action {
 211         my ( $self, $c ) = @_;
 212         if ( scalar @{ $c->error } ) { ... } # handle errors
 213         return if $c->res->body; # already have a response
 214         $c->forward( 'MyApp::View::TT' ); # render template
 215     }
 216
 217 See L<Catalyst::Manual::Intro> for additional information.
 218
 219 =head1 DESCRIPTION
 220
 221 Catalyst is a modern framework for making web applications without the
 222 pain usually associated with this process. This document is a reference
 223 to the main Catalyst application. If you are a new user, we suggest you
 224 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 225
 226 See L<Catalyst::Manual> for more documentation.
 227
 228 Catalyst plugins can be loaded by naming them as arguments to the "use
 229 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 230 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 231 C<My::Module>.
 232
 233     use Catalyst qw/My::Module/;
 234
 235 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 236 fully qualify the name by using a unary plus:
 237
 238     use Catalyst qw/
 239         My::Module
 240         +Fully::Qualified::Plugin::Name
 241     /;
 242
 243 Special flags like C<-Debug> can also be specified as
 244 arguments when Catalyst is loaded:
 245
 246     use Catalyst qw/-Debug My::Module/;
 247
 248 The position of plugins and flags in the chain is important, because
 249 they are loaded in the order in which they appear.
 250
 251 The following flags are supported:
 252
 253 =head2 -Debug
 254
 255 Enables debug output. You can also force this setting from the system
 256 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 257 settings override the application, with <MYAPP>_DEBUG having the highest
 258 priority.
 259
 260 This sets the log level to 'debug' and enables full debug output on the
 261 error screen. If you only want the latter, see L<< $c->debug >>.
 262
 263 =head2 -Home
 264
 265 Forces Catalyst to use a specific home directory, e.g.:
 266
 267     use Catalyst qw[-Home=/usr/mst];
 268
 269 This can also be done in the shell environment by setting either the
 270 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 271 is replaced with the uppercased name of your application, any "::" in
 272 the name will be replaced with underscores, e.g. MyApp::Web should use
 273 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 274
 275 If none of these are set, Catalyst will attempt to automatically detect the
 276 home directory. If you are working in a development environment, Catalyst
 277 will try and find the directory containing either Makefile.PL, Build.PL,
 278 dist.ini, or cpanfile. If the application has been installed into the system
 279 (i.e. you have done C<make install>), then Catalyst will use the path to your
 280 application module, without the .pm extension (e.g., /foo/MyApp if your
 281 application was installed at /foo/MyApp.pm)
 282
 283 =head2 -Log
 284
 285     use Catalyst '-Log=warn,fatal,error';
 286
 287 Specifies a comma-delimited list of log levels.
 288
 289 =head2 -Stats
 290
 291 Enables statistics collection and reporting.
 292
 293    use Catalyst qw/-Stats=1/;
 294
 295 You can also force this setting from the system environment with CATALYST_STATS
 296 or <MYAPP>_STATS. The environment settings override the application, with
 297 <MYAPP>_STATS having the highest priority.
 298
 299 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 300
 301 =head1 METHODS
 302
 303 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 304
 305 =head2 $c->action
 306
 307 Returns a L<Catalyst::Action> object for the current action, which
 308 stringifies to the action name. See L<Catalyst::Action>.
 309
 310 =head2 $c->namespace
 311
 312 Returns the namespace of the current action, i.e., the URI prefix
 313 corresponding to the controller of the current action. For example:
 314
 315     # in Controller::Foo::Bar
 316     $c->namespace; # returns 'foo/bar';
 317
 318 =head2 $c->request
 319
 320 =head2 $c->req
 321
 322 Returns the current L<Catalyst::Request> object, giving access to
 323 information about the current client request (including parameters,
 324 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 325
 326 =head2 REQUEST FLOW HANDLING
 327
 328 =head2 $c->forward( $action [, \@arguments ] )
 329
 330 =head2 $c->forward( $class, $method, [, \@arguments ] )
 331
 332 This is one way of calling another action (method) in the same or
 333 a different controller. You can also use C<< $self->my_method($c, @args) >>
 334 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 335 in a different controller.
 336 The main difference is that 'forward' uses some of the Catalyst request
 337 cycle overhead, including debugging, which may be useful to you. On the
 338 other hand, there are some complications to using 'forward', restrictions
 339 on values returned from 'forward', and it may not handle errors as you prefer.
 340 Whether you use 'forward' or not is up to you; it is not considered superior to
 341 the other ways to call a method.
 342
 343 'forward' calls  another action, by its private name. If you give a
 344 class name but no method, C<process()> is called. You may also optionally
 345 pass arguments in an arrayref. The action will receive the arguments in
 346 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 347 C<< $c->req->args >> will be restored to the previous values.
 348
 349 Any data C<return>ed from the action forwarded to, will be returned by the
 350 call to forward.
 351
 352     my $foodata = $c->forward('/foo');
 353     $c->forward('index');
 354     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 355     $c->forward('View::TT');
 356
 357 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 358 an C<< eval { } >> around the call (actually
 359 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 360 exceptions thrown by the called action non-fatal and pushing them onto
 361 $c->error instead. If you want C<die> to propagate you need to do something
 362 like:
 363
 364     $c->forward('foo');
 365     die join "\n", @{ $c->error } if @{ $c->error };
 366
 367 Or make sure to always return true values from your actions and write
 368 your code like this:
 369
 370     $c->forward('foo') || return;
 371
 372 Another note is that C<< $c->forward >> always returns a scalar because it
 373 actually returns $c->state which operates in a scalar context.
 374 Thus, something like:
 375
 376     return @array;
 377
 378 in an action that is forwarded to is going to return a scalar,
 379 i.e. how many items are in that array, which is probably not what you want.
 380 If you need to return an array then return a reference to it,
 381 or stash it like so:
 382
 383     $c->stash->{array} = \@array;
 384
 385 and access it from the stash.
 386
 387 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 388
 389 =cut
 390
 391 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 392
 393 =head2 $c->detach( $action [, \@arguments ] )
 394
 395 =head2 $c->detach( $class, $method, [, \@arguments ] )
 396
 397 =head2 $c->detach()
 398
 399 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 400 doesn't return to the previous action when processing is finished.
 401
 402 When called with no arguments it escapes the processing chain entirely.
 403
 404 =cut
 405
 406 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 407
 408 =head2 $c->visit( $action [, \@arguments ] )
 409
 410 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 411
 412 =head2 $c->visit( $class, $method, [, \@arguments ] )
 413
 414 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 415
 416 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 417 but does a full dispatch, instead of just calling the new C<$action> /
 418 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 419 you go to are called, just like a new request.
 420
 421 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 422 This means, for example, that C<< $c->action >> methods such as
 423 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 424 L<reverse|Catalyst::Action/reverse> return information for the visited action
 425 when they are invoked within the visited action.  This is different from the
 426 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 427 continues to use the $c->action object from the caller action even when
 428 invoked from the called action.
 429
 430 C<< $c->stash >> is kept unchanged.
 431
 432 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 433 allows you to "wrap" another action, just as it would have been called by
 434 dispatching from a URL, while the analogous
 435 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 436 transfer control to another action as if it had been reached directly from a URL.
 437
 438 =cut
 439
 440 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 441
 442 =head2 $c->go( $action [, \@arguments ] )
 443
 444 =head2 $c->go( $action [, \@captures, \@arguments ] )
 445
 446 =head2 $c->go( $class, $method, [, \@arguments ] )
 447
 448 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 449
 450 The relationship between C<go> and
 451 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 452 the relationship between
 453 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 454 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 455 C<< $c->go >> will perform a full dispatch on the specified action or method,
 456 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 457 C<go> escapes the processing of the current request chain on completion, and
 458 does not return to its caller.
 459
 460 @arguments are arguments to the final destination of $action. @captures are
 461 arguments to the intermediate steps, if any, on the way to the final sub of
 462 $action.
 463
 464 =cut
 465
 466 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 467
 468 =head2 $c->response
 469
 470 =head2 $c->res
 471
 472 Returns the current L<Catalyst::Response> object, see there for details.
 473
 474 =head2 $c->stash
 475
 476 Returns a hashref to the stash, which may be used to store data and pass
 477 it between components during a request. You can also set hash keys by
 478 passing arguments. The stash is automatically sent to the view. The
 479 stash is cleared at the end of a request; it cannot be used for
 480 persistent storage (for this you must use a session; see
 481 L<Catalyst::Plugin::Session> for a complete system integrated with
 482 Catalyst).
 483
 484     $c->stash->{foo} = $bar;
 485     $c->stash( { moose => 'majestic', qux => 0 } );
 486     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 487
 488     # stash is automatically passed to the view for use in a template
 489     $c->forward( 'MyApp::View::TT' );
 490
 491 =cut
 492
 493 around stash => sub {
 494     my $orig = shift;
 495     my $c = shift;
 496     my $stash = $orig->($c);
 497     if (@_) {
 498         my $new_stash = @_ > 1 ? {@_} : $_[0];
 499         croak('stash takes a hash or hashref') unless ref $new_stash;
 500         foreach my $key ( keys %$new_stash ) {
 501           $stash->{$key} = $new_stash->{$key};
 502         }
 503     }
 504
 505     return $stash;
 506 };
 507
 508
 509 =head2 $c->error
 510
 511 =head2 $c->error($error, ...)
 512
 513 =head2 $c->error($arrayref)
 514
 515 Returns an arrayref containing error messages.  If Catalyst encounters an
 516 error while processing a request, it stores the error in $c->error.  This
 517 method should only be used to store fatal error messages.
 518
 519     my @error = @{ $c->error };
 520
 521 Add a new error.
 522
 523     $c->error('Something bad happened');
 524
 525 =cut
 526
 527 sub error {
 528     my $c = shift;
 529     if ( $_[0] ) {
 530         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 531         croak @$error unless ref $c;
 532         push @{ $c->{error} }, @$error;
 533     }
 534     elsif ( defined $_[0] ) { $c->{error} = undef }
 535     return $c->{error} || [];
 536 }
 537
 538
 539 =head2 $c->state
 540
 541 Contains the return value of the last executed action.
 542 Note that << $c->state >> operates in a scalar context which means that all
 543 values it returns are scalar.
 544
 545 =head2 $c->clear_errors
 546
 547 Clear errors.  You probably don't want to clear the errors unless you are
 548 implementing a custom error screen.
 549
 550 This is equivalent to running
 551
 552     $c->error(0);
 553
 554 =cut
 555
 556 sub clear_errors {
 557     my $c = shift;
 558     $c->error(0);
 559 }
 560
 561 sub _comp_search_prefixes {
 562     my $c = shift;
 563     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 564 }
 565
 566 # search components given a name and some prefixes
 567 sub _comp_names_search_prefixes {
 568     my ( $c, $name, @prefixes ) = @_;
 569     my $appclass = ref $c || $c;
 570     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 571     $filter = qr/$filter/; # Compile regex now rather than once per loop
 572
 573     # map the original component name to the sub part that we will search against
 574     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 575         grep { /$filter/ } keys %{ $c->components };
 576
 577     # undef for a name will return all
 578     return keys %eligible if !defined $name;
 579
 580     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 581     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 582
 583     return @result if @result;
 584
 585     # if we were given a regexp to search against, we're done.
 586     return if $name->$_isa('Regexp');
 587
 588     # skip regexp fallback if configured
 589     return
 590         if $appclass->config->{disable_component_resolution_regex_fallback};
 591
 592     # regexp fallback
 593     $query  = qr/$name/i;
 594     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 595
 596     # no results? try against full names
 597     if( !@result ) {
 598         @result = grep { m{$query} } keys %eligible;
 599     }
 600
 601     # don't warn if we didn't find any results, it just might not exist
 602     if( @result ) {
 603         # Disgusting hack to work out correct method name
 604         my $warn_for = lc $prefixes[0];
 605         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 606            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 607            "component resolution is unreliable and unsafe.";
 608         my $short = $result[0];
 609         # remove the component namespace prefix
 610         $short =~ s/.*?(Model|Controller|View):://;
 611         my $shortmess = Carp::shortmess('');
 612         if ($shortmess =~ m#Catalyst/Plugin#) {
 613            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 614               "plugin's config";
 615         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 616            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 617               "component's config";
 618         } else {
 619            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 620               "but if you really wanted to search, pass in a regexp as the argument " .
 621               "like so: \$c->${warn_for}(qr/${name}/)";
 622         }
 623         $c->log->warn( "${msg}$shortmess" );
 624     }
 625
 626     return @result;
 627 }
 628
 629 # Find possible names for a prefix
 630 sub _comp_names {
 631     my ( $c, @prefixes ) = @_;
 632     my $appclass = ref $c || $c;
 633
 634     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 635
 636     my @names = map { s{$filter}{}; $_; }
 637         $c->_comp_names_search_prefixes( undef, @prefixes );
 638
 639     return @names;
 640 }
 641
 642 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 643 sub _filter_component {
 644     my ( $c, $comp, @args ) = @_;
 645
 646     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 647         return $comp->ACCEPT_CONTEXT( $c, @args );
 648     }
 649
 650     return $comp;
 651 }
 652
 653 =head2 COMPONENT ACCESSORS
 654
 655 =head2 $c->controller($name)
 656
 657 Gets a L<Catalyst::Controller> instance by name.
 658
 659     $c->controller('Foo')->do_stuff;
 660
 661 If the name is omitted, will return the controller for the dispatched
 662 action.
 663
 664 If you want to search for controllers, pass in a regexp as the argument.
 665
 666     # find all controllers that start with Foo
 667     my @foo_controllers = $c->controller(qr{^Foo});
 668
 669
 670 =cut
 671
 672 sub controller {
 673     my ( $c, $name, @args ) = @_;
 674
 675     my $appclass = ref($c) || $c;
 676     if( $name ) {
 677         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 678             my $comps = $c->components;
 679             my $check = $appclass."::Controller::".$name;
 680             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 681         }
 682         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 683         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 684         return $c->_filter_component( $result[ 0 ], @args );
 685     }
 686
 687     return $c->component( $c->action->class );
 688 }
 689
 690 =head2 $c->model($name)
 691
 692 Gets a L<Catalyst::Model> instance by name.
 693
 694     $c->model('Foo')->do_stuff;
 695
 696 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 697
 698 If the name is omitted, it will look for
 699  - a model object in $c->stash->{current_model_instance}, then
 700  - a model name in $c->stash->{current_model}, then
 701  - a config setting 'default_model', or
 702  - check if there is only one model, and return it if that's the case.
 703
 704 If you want to search for models, pass in a regexp as the argument.
 705
 706     # find all models that start with Foo
 707     my @foo_models = $c->model(qr{^Foo});
 708
 709 =cut
 710
 711 sub model {
 712     my ( $c, $name, @args ) = @_;
 713     my $appclass = ref($c) || $c;
 714     if( $name ) {
 715         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 716             my $comps = $c->components;
 717             my $check = $appclass."::Model::".$name;
 718             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 719         }
 720         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 721         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 722         return $c->_filter_component( $result[ 0 ], @args );
 723     }
 724
 725     if (ref $c) {
 726         return $c->stash->{current_model_instance}
 727           if $c->stash->{current_model_instance};
 728         return $c->model( $c->stash->{current_model} )
 729           if $c->stash->{current_model};
 730     }
 731     return $c->model( $appclass->config->{default_model} )
 732       if $appclass->config->{default_model};
 733
 734     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 735
 736     if( $rest ) {
 737         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 738         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 739         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 740         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 741         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 742     }
 743
 744     return $c->_filter_component( $comp );
 745 }
 746
 747
 748 =head2 $c->view($name)
 749
 750 Gets a L<Catalyst::View> instance by name.
 751
 752     $c->view('Foo')->do_stuff;
 753
 754 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 755
 756 If the name is omitted, it will look for
 757  - a view object in $c->stash->{current_view_instance}, then
 758  - a view name in $c->stash->{current_view}, then
 759  - a config setting 'default_view', or
 760  - check if there is only one view, and return it if that's the case.
 761
 762 If you want to search for views, pass in a regexp as the argument.
 763
 764     # find all views that start with Foo
 765     my @foo_views = $c->view(qr{^Foo});
 766
 767 =cut
 768
 769 sub view {
 770     my ( $c, $name, @args ) = @_;
 771
 772     my $appclass = ref($c) || $c;
 773     if( $name ) {
 774         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 775             my $comps = $c->components;
 776             my $check = $appclass."::View::".$name;
 777             if( exists $comps->{$check} ) {
 778                 return $c->_filter_component( $comps->{$check}, @args );
 779             }
 780             else {
 781                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 782             }
 783         }
 784         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 785         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 786         return $c->_filter_component( $result[ 0 ], @args );
 787     }
 788
 789     if (ref $c) {
 790         return $c->stash->{current_view_instance}
 791           if $c->stash->{current_view_instance};
 792         return $c->view( $c->stash->{current_view} )
 793           if $c->stash->{current_view};
 794     }
 795     return $c->view( $appclass->config->{default_view} )
 796       if $appclass->config->{default_view};
 797
 798     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 799
 800     if( $rest ) {
 801         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 802         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 803         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 804         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 805         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 806     }
 807
 808     return $c->_filter_component( $comp );
 809 }
 810
 811 =head2 $c->controllers
 812
 813 Returns the available names which can be passed to $c->controller
 814
 815 =cut
 816
 817 sub controllers {
 818     my ( $c ) = @_;
 819     return $c->_comp_names(qw/Controller C/);
 820 }
 821
 822 =head2 $c->models
 823
 824 Returns the available names which can be passed to $c->model
 825
 826 =cut
 827
 828 sub models {
 829     my ( $c ) = @_;
 830     return $c->_comp_names(qw/Model M/);
 831 }
 832
 833
 834 =head2 $c->views
 835
 836 Returns the available names which can be passed to $c->view
 837
 838 =cut
 839
 840 sub views {
 841     my ( $c ) = @_;
 842     return $c->_comp_names(qw/View V/);
 843 }
 844
 845 =head2 $c->comp($name)
 846
 847 =head2 $c->component($name)
 848
 849 Gets a component object by name. This method is not recommended,
 850 unless you want to get a specific component by full
 851 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 852 should be used instead.
 853
 854 If C<$name> is a regexp, a list of components matched against the full
 855 component name will be returned.
 856
 857 If Catalyst can't find a component by name, it will fallback to regex
 858 matching by default. To disable this behaviour set
 859 disable_component_resolution_regex_fallback to a true value.
 860
 861     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 862
 863 =cut
 864
 865 sub component {
 866     my ( $c, $name, @args ) = @_;
 867
 868     if( $name ) {
 869         my $comps = $c->components;
 870
 871         if( !ref $name ) {
 872             # is it the exact name?
 873             return $c->_filter_component( $comps->{ $name }, @args )
 874                        if exists $comps->{ $name };
 875
 876             # perhaps we just omitted "MyApp"?
 877             my $composed = ( ref $c || $c ) . "::${name}";
 878             return $c->_filter_component( $comps->{ $composed }, @args )
 879                        if exists $comps->{ $composed };
 880
 881             # search all of the models, views and controllers
 882             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 883             return $c->_filter_component( $comp, @args ) if $comp;
 884         }
 885
 886         return
 887             if $c->config->{disable_component_resolution_regex_fallback};
 888
 889         # This is here so $c->comp( '::M::' ) works
 890         my $query = ref $name ? $name : qr{$name}i;
 891
 892         my @result = grep { m{$query} } keys %{ $c->components };
 893         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 894
 895         if( $result[ 0 ] ) {
 896             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 897             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 898             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 899             return $c->_filter_component( $result[ 0 ], @args );
 900         }
 901
 902         # I would expect to return an empty list here, but that breaks back-compat
 903     }
 904
 905     # fallback
 906     return sort keys %{ $c->components };
 907 }
 908
 909 =head2 CLASS DATA AND HELPER CLASSES
 910
 911 =head2 $c->config
 912
 913 Returns or takes a hashref containing the application's configuration.
 914
 915     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 916
 917 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 918 like C<myapp.conf> in your applications home directory. See
 919 L<Catalyst::Plugin::ConfigLoader>.
 920
 921 =head3 Cascading configuration
 922
 923 The config method is present on all Catalyst components, and configuration
 924 will be merged when an application is started. Configuration loaded with
 925 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 926 followed by configuration in your top level C<MyApp> class. These two
 927 configurations are merged, and then configuration data whose hash key matches a
 928 component name is merged with configuration for that component.
 929
 930 The configuration for a component is then passed to the C<new> method when a
 931 component is constructed.
 932
 933 For example:
 934
 935     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 936     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 937
 938 will mean that C<MyApp::Model::Foo> receives the following data when
 939 constructed:
 940
 941     MyApp::Model::Foo->new({
 942         bar => 'baz',
 943         quux => 'frob',
 944         overrides => 'me',
 945     });
 946
 947 It's common practice to use a Moose attribute
 948 on the receiving component to access the config value.
 949
 950     package MyApp::Model::Foo;
 951
 952     use Moose;
 953
 954     # this attr will receive 'baz' at construction time
 955     has 'bar' => (
 956         is  => 'rw',
 957         isa => 'Str',
 958     );
 959
 960 You can then get the value 'baz' by calling $c->model('Foo')->bar
 961 (or $self->bar inside code in the model).
 962
 963 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 964 as a way of reading config within your code, as this B<will not> give you the
 965 correctly merged config back. You B<MUST> take the config values supplied to
 966 the constructor and use those instead.
 967
 968 =cut
 969
 970 around config => sub {
 971     my $orig = shift;
 972     my $c = shift;
 973
 974     croak('Setting config after setup has been run is not allowed.')
 975         if ( @_ and $c->setup_finished );
 976
 977     $c->$orig(@_);
 978 };
 979
 980 =head2 $c->log
 981
 982 Returns the logging object instance. Unless it is already set, Catalyst
 983 sets this up with a L<Catalyst::Log> object. To use your own log class,
 984 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 985 C<< __PACKAGE__->setup >>.
 986
 987  __PACKAGE__->log( MyLogger->new );
 988  __PACKAGE__->setup;
 989
 990 And later:
 991
 992     $c->log->info( 'Now logging with my own logger!' );
 993
 994 Your log class should implement the methods described in
 995 L<Catalyst::Log>.
 996
 997
 998 =head2 $c->debug
 999
1000 Returns 1 if debug mode is enabled, 0 otherwise.
1001
1002 You can enable debug mode in several ways:
1003
1004 =over
1005
1006 =item By calling myapp_server.pl with the -d flag
1007
1008 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1009
1010 =item The -Debug option in your MyApp.pm
1011
1012 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1013
1014 =back
1015
1016 The first three also set the log level to 'debug'.
1017
1018 Calling C<< $c->debug(1) >> has no effect.
1019
1020 =cut
1021
1022 sub debug { 0 }
1023
1024 =head2 $c->dispatcher
1025
1026 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1027
1028 =head2 $c->engine
1029
1030 Returns the engine instance. See L<Catalyst::Engine>.
1031
1032
1033 =head2 UTILITY METHODS
1034
1035 =head2 $c->path_to(@path)
1036
1037 Merges C<@path> with C<< $c->config->{home} >> and returns a
1038 L<Path::Class::Dir> object. Note you can usually use this object as
1039 a filename, but sometimes you will have to explicitly stringify it
1040 yourself by calling the C<< ->stringify >> method.
1041
1042 For example:
1043
1044     $c->path_to( 'db', 'sqlite.db' );
1045
1046 =cut
1047
1048 sub path_to {
1049     my ( $c, @path ) = @_;
1050     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1051     if ( -d $path ) { return $path }
1052     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1053 }
1054
1055 sub plugin {
1056     my ( $class, $name, $plugin, @args ) = @_;
1057
1058     # See block comment in t/unit_core_plugin.t
1059     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1060
1061     $class->_register_plugin( $plugin, 1 );
1062
1063     eval { $plugin->import };
1064     $class->mk_classdata($name);
1065     my $obj;
1066     eval { $obj = $plugin->new(@args) };
1067
1068     if ($@) {
1069         Catalyst::Exception->throw( message =>
1070               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1071     }
1072
1073     $class->$name($obj);
1074     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1075       if $class->debug;
1076 }
1077
1078 =head2 MyApp->setup
1079
1080 Initializes the dispatcher and engine, loads any plugins, and loads the
1081 model, view, and controller components. You may also specify an array
1082 of plugins to load here, if you choose to not load them in the C<use
1083 Catalyst> line.
1084
1085     MyApp->setup;
1086     MyApp->setup( qw/-Debug/ );
1087
1088 B<Note:> You B<should not> wrap this method with method modifiers
1089 or bad things will happen - wrap the C<setup_finalize> method instead.
1090
1091 =cut
1092
1093 sub setup {
1094     my ( $class, @arguments ) = @_;
1095     croak('Running setup more than once')
1096         if ( $class->setup_finished );
1097
1098     unless ( $class->isa('Catalyst') ) {
1099
1100         Catalyst::Exception->throw(
1101             message => qq/'$class' does not inherit from Catalyst/ );
1102     }
1103
1104     if ( $class->arguments ) {
1105         @arguments = ( @arguments, @{ $class->arguments } );
1106     }
1107
1108     # Process options
1109     my $flags = {};
1110
1111     foreach (@arguments) {
1112
1113         if (/^-Debug$/) {
1114             $flags->{log} =
1115               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1116         }
1117         elsif (/^-(\w+)=?(.*)$/) {
1118             $flags->{ lc $1 } = $2;
1119         }
1120         else {
1121             push @{ $flags->{plugins} }, $_;
1122         }
1123     }
1124
1125     $class->setup_home( delete $flags->{home} );
1126
1127     $class->setup_plugins( delete $flags->{plugins} );
1128
1129     # Call plugins setup, this is stupid and evil.
1130     # Also screws C3 badly on 5.10, hack to avoid.
1131     {
1132         no warnings qw/redefine/;
1133         local *setup = sub { };
1134         $class->setup unless $Catalyst::__AM_RESTARTING;
1135     }
1136
1137     $class->setup_log( delete $flags->{log} );
1138     $class->setup_middleware();
1139     $class->setup_data_handlers();
1140     $class->setup_dispatcher( delete $flags->{dispatcher} );
1141     if (my $engine = delete $flags->{engine}) {
1142         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1143     }
1144     $class->setup_engine();
1145     $class->setup_stats( delete $flags->{stats} );
1146
1147     for my $flag ( sort keys %{$flags} ) {
1148
1149         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1150             &$code( $class, delete $flags->{$flag} );
1151         }
1152         else {
1153             $class->log->warn(qq/Unknown flag "$flag"/);
1154         }
1155     }
1156
1157     eval { require Catalyst::Devel; };
1158     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1159         $class->log->warn(<<"EOF");
1160 You are running an old script!
1161
1162   Please update by running (this will overwrite existing files):
1163     catalyst.pl -force -scripts $class
1164
1165   or (this will not overwrite existing files):
1166     catalyst.pl -scripts $class
1167
1168 EOF
1169     }
1170
1171     # Initialize our data structure
1172     $class->components( {} );
1173
1174     $class->setup_components;
1175
1176     if ( $class->debug ) {
1177         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1178
1179         if (@plugins) {
1180             my $column_width = Catalyst::Utils::term_width() - 6;
1181             my $t = Text::SimpleTable->new($column_width);
1182             $t->row($_) for @plugins;
1183             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1184         }
1185
1186         my @middleware = map {
1187           ref $_ eq 'CODE' ?
1188             "Inline Coderef" :
1189               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1190                 || '')  } $class->registered_middlewares;
1191
1192         if (@middleware) {
1193             my $column_width = Catalyst::Utils::term_width() - 6;
1194             my $t = Text::SimpleTable->new($column_width);
1195             $t->row($_) for @middleware;
1196             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1197         }
1198
1199         my %dh = $class->registered_data_handlers;
1200         if (my @data_handlers = keys %dh) {
1201             my $column_width = Catalyst::Utils::term_width() - 6;
1202             my $t = Text::SimpleTable->new($column_width);
1203             $t->row($_) for @data_handlers;
1204             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1205         }
1206
1207         my $dispatcher = $class->dispatcher;
1208         my $engine     = $class->engine;
1209         my $home       = $class->config->{home};
1210
1211         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1212         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1213
1214         $home
1215           ? ( -d $home )
1216           ? $class->log->debug(qq/Found home "$home"/)
1217           : $class->log->debug(qq/Home "$home" doesn't exist/)
1218           : $class->log->debug(q/Couldn't find home/);
1219
1220         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1221         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1222         for my $comp ( sort keys %{ $class->components } ) {
1223             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1224             $t->row( $comp, $type );
1225         }
1226         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1227           if ( keys %{ $class->components } );
1228     }
1229
1230     # Add our self to components, since we are also a component
1231     if( $class->isa('Catalyst::Controller') ){
1232       $class->components->{$class} = $class;
1233     }
1234
1235     $class->setup_actions;
1236
1237     if ( $class->debug ) {
1238         my $name = $class->config->{name} || 'Application';
1239         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1240     }
1241
1242     if ($class->config->{case_sensitive}) {
1243         $class->log->warn($class . "->config->{case_sensitive} is set.");
1244         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1245     }
1246
1247     $class->setup_finalize;
1248     # Should be the last thing we do so that user things hooking
1249     # setup_finalize can log..
1250     $class->log->_flush() if $class->log->can('_flush');
1251     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1252 }
1253
1254 =head2 $app->setup_finalize
1255
1256 A hook to attach modifiers to. This method does not do anything except set the
1257 C<setup_finished> accessor.
1258
1259 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1260
1261 Example:
1262
1263     after setup_finalize => sub {
1264         my $app = shift;
1265
1266         ## do stuff here..
1267     };
1268
1269 =cut
1270
1271 sub setup_finalize {
1272     my ($class) = @_;
1273     $class->setup_finished(1);
1274 }
1275
1276 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1277
1278 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1279
1280 Constructs an absolute L<URI> object based on the application root, the
1281 provided path, and the additional arguments and query parameters provided.
1282 When used as a string, provides a textual URI.  If you need more flexibility
1283 than this (i.e. the option to provide relative URIs etc.) see
1284 L<Catalyst::Plugin::SmartURI>.
1285
1286 If no arguments are provided, the URI for the current action is returned.
1287 To return the current action and also provide @args, use
1288 C<< $c->uri_for( $c->action, @args ) >>.
1289
1290 If the first argument is a string, it is taken as a public URI path relative
1291 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1292 relative to the application root (if it does). It is then merged with
1293 C<< $c->request->base >>; any C<@args> are appended as additional path
1294 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1295
1296 If the first argument is a L<Catalyst::Action> it represents an action which
1297 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1298 optional C<\@captures> argument (an arrayref) allows passing the captured
1299 variables that are needed to fill in the paths of Chained and Regex actions;
1300 once the path is resolved, C<uri_for> continues as though a path was
1301 provided, appending any arguments or parameters and creating an absolute
1302 URI.
1303
1304 The captures for the current request can be found in
1305 C<< $c->request->captures >>, and actions can be resolved using
1306 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1307 path, use C<< $c->uri_for_action >> instead.
1308
1309   # Equivalent to $c->req->uri
1310   $c->uri_for($c->action, $c->req->captures,
1311       @{ $c->req->args }, $c->req->params);
1312
1313   # For the Foo action in the Bar controller
1314   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1315
1316   # Path to a static resource
1317   $c->uri_for('/static/images/logo.png');
1318
1319 =cut
1320
1321 sub uri_for {
1322     my ( $c, $path, @args ) = @_;
1323
1324     if ( $path->$_isa('Catalyst::Controller') ) {
1325         $path = $path->path_prefix;
1326         $path =~ s{/+\z}{};
1327         $path .= '/';
1328     }
1329
1330     undef($path) if (defined $path && $path eq '');
1331
1332     my $params =
1333       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1334
1335     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1336     foreach my $arg (@args) {
1337         utf8::encode($arg) if utf8::is_utf8($arg);
1338         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1339     }
1340
1341     if ( $path->$_isa('Catalyst::Action') ) { # action object
1342         s|/|%2F|g for @args;
1343         my $captures = [ map { s|/|%2F|g; $_; }
1344                         ( scalar @args && ref $args[0] eq 'ARRAY'
1345                          ? @{ shift(@args) }
1346                          : ()) ];
1347
1348         foreach my $capture (@$captures) {
1349             utf8::encode($capture) if utf8::is_utf8($capture);
1350             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1351         }
1352
1353         my $action = $path;
1354         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1355         if( !@args && $action->number_of_args ) {
1356             my $expanded_action = $c->dispatcher->expand_action( $action );
1357
1358             my $num_captures = $expanded_action->number_of_captures;
1359             unshift @args, splice @$captures, $num_captures;
1360         }
1361
1362        $path = $c->dispatcher->uri_for_action($action, $captures);
1363         if (not defined $path) {
1364             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1365                 if $c->debug;
1366             return undef;
1367         }
1368         $path = '/' if $path eq '';
1369     }
1370
1371     unshift(@args, $path);
1372
1373     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1374         my $namespace = $c->namespace;
1375         if (defined $path) { # cheesy hack to handle path '../foo'
1376            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1377         }
1378         unshift(@args, $namespace || '');
1379     }
1380
1381     # join args with '/', or a blank string
1382     my $args = join('/', grep { defined($_) } @args);
1383     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1384     $args =~ s!^/+!!;
1385
1386     my ($base, $class) = ('/', 'URI::_generic');
1387     if(blessed($c)) {
1388       $base = $c->req->base;
1389       $class = ref($base);
1390       $base =~ s{(?<!/)$}{/};
1391     }
1392
1393     my $query = '';
1394
1395     if (my @keys = keys %$params) {
1396       # somewhat lifted from URI::_query's query_form
1397       $query = '?'.join('&', map {
1398           my $val = $params->{$_};
1399           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1400           s/ /+/g;
1401           my $key = $_;
1402           $val = '' unless defined $val;
1403           (map {
1404               my $param = "$_";
1405               utf8::encode( $param ) if utf8::is_utf8($param);
1406               # using the URI::Escape pattern here so utf8 chars survive
1407               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1408               $param =~ s/ /+/g;
1409               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1410       } @keys);
1411     }
1412
1413     my $res = bless(\"${base}${args}${query}", $class);
1414     $res;
1415 }
1416
1417 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1418
1419 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1420
1421 =over
1422
1423 =item $path
1424
1425 A private path to the Catalyst action you want to create a URI for.
1426
1427 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1428 >> and passing the resulting C<$action> and the remaining arguments to C<<
1429 $c->uri_for >>.
1430
1431 You can also pass in a Catalyst::Action object, in which case it is passed to
1432 C<< $c->uri_for >>.
1433
1434 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1435
1436 For example, if the action looks like:
1437
1438  package MyApp::Controller::Users;
1439
1440  sub lst : Path('the-list') {}
1441
1442 You can use:
1443
1444  $c->uri_for_action('/users/lst')
1445
1446 and it will create the URI /users/the-list.
1447
1448 =item \@captures_and_args?
1449
1450 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1451 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1452 to interpolate all the parameters in the URI.
1453
1454 =item @args?
1455
1456 Optional list of extra arguments - can be supplied in the
1457 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1458 code.
1459
1460 Your action can have zero, a fixed or a variable number of args (e.g.
1461 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1462
1463 =item \%query_values?
1464
1465 Optional array reference of query parameters to append. E.g.
1466
1467   { foo => 'bar' }
1468
1469 will generate
1470
1471   /rest/of/your/uri?foo=bar
1472
1473 =back
1474
1475 =cut
1476
1477 sub uri_for_action {
1478     my ( $c, $path, @args ) = @_;
1479     my $action = blessed($path)
1480       ? $path
1481       : $c->dispatcher->get_action_by_path($path);
1482     unless (defined $action) {
1483       croak "Can't find action for path '$path'";
1484     }
1485     return $c->uri_for( $action, @args );
1486 }
1487
1488 =head2 $c->welcome_message
1489
1490 Returns the Catalyst welcome HTML page.
1491
1492 =cut
1493
1494 sub welcome_message {
1495     my $c      = shift;
1496     my $name   = $c->config->{name};
1497     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1498     my $prefix = Catalyst::Utils::appprefix( ref $c );
1499     $c->response->content_type('text/html; charset=utf-8');
1500     return <<"EOF";
1501 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1502     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1503 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1504     <head>
1505     <meta http-equiv="Content-Language" content="en" />
1506     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1507         <title>$name on Catalyst $VERSION</title>
1508         <style type="text/css">
1509             body {
1510                 color: #000;
1511                 background-color: #eee;
1512             }
1513             div#content {
1514                 width: 640px;
1515                 margin-left: auto;
1516                 margin-right: auto;
1517                 margin-top: 10px;
1518                 margin-bottom: 10px;
1519                 text-align: left;
1520                 background-color: #ccc;
1521                 border: 1px solid #aaa;
1522             }
1523             p, h1, h2 {
1524                 margin-left: 20px;
1525                 margin-right: 20px;
1526                 font-family: verdana, tahoma, sans-serif;
1527             }
1528             a {
1529                 font-family: verdana, tahoma, sans-serif;
1530             }
1531             :link, :visited {
1532                     text-decoration: none;
1533                     color: #b00;
1534                     border-bottom: 1px dotted #bbb;
1535             }
1536             :link:hover, :visited:hover {
1537                     color: #555;
1538             }
1539             div#topbar {
1540                 margin: 0px;
1541             }
1542             pre {
1543                 margin: 10px;
1544                 padding: 8px;
1545             }
1546             div#answers {
1547                 padding: 8px;
1548                 margin: 10px;
1549                 background-color: #fff;
1550                 border: 1px solid #aaa;
1551             }
1552             h1 {
1553                 font-size: 0.9em;
1554                 font-weight: normal;
1555                 text-align: center;
1556             }
1557             h2 {
1558                 font-size: 1.0em;
1559             }
1560             p {
1561                 font-size: 0.9em;
1562             }
1563             p img {
1564                 float: right;
1565                 margin-left: 10px;
1566             }
1567             span#appname {
1568                 font-weight: bold;
1569                 font-size: 1.6em;
1570             }
1571         </style>
1572     </head>
1573     <body>
1574         <div id="content">
1575             <div id="topbar">
1576                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1577                     $VERSION</h1>
1578              </div>
1579              <div id="answers">
1580                  <p>
1581                  <img src="$logo" alt="Catalyst Logo" />
1582                  </p>
1583                  <p>Welcome to the  world of Catalyst.
1584                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1585                     framework will make web development something you had
1586                     never expected it to be: Fun, rewarding, and quick.</p>
1587                  <h2>What to do now?</h2>
1588                  <p>That really depends  on what <b>you</b> want to do.
1589                     We do, however, provide you with a few starting points.</p>
1590                  <p>If you want to jump right into web development with Catalyst
1591                     you might want to start with a tutorial.</p>
1592 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1593 </pre>
1594 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1595 <pre>
1596 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1597 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1598 </code></pre>
1599                  <h2>What to do next?</h2>
1600                  <p>Next it's time to write an actual application. Use the
1601                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1602                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1603                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1604                     they can save you a lot of work.</p>
1605                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1606                     <p>Also, be sure to check out the vast and growing
1607                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1608                     you are likely to find what you need there.
1609                     </p>
1610
1611                  <h2>Need help?</h2>
1612                  <p>Catalyst has a very active community. Here are the main places to
1613                     get in touch with us.</p>
1614                  <ul>
1615                      <li>
1616                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1617                      </li>
1618                      <li>
1619                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1620                      </li>
1621                      <li>
1622                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1623                      </li>
1624                  </ul>
1625                  <h2>In conclusion</h2>
1626                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1627                     as we enjoyed making it. Please contact us if you have ideas
1628                     for improvement or other feedback.</p>
1629              </div>
1630          </div>
1631     </body>
1632 </html>
1633 EOF
1634 }
1635
1636 =head2 run_options
1637
1638 Contains a hash of options passed from the application script, including
1639 the original ARGV the script received, the processed values from that
1640 ARGV and any extra arguments to the script which were not processed.
1641
1642 This can be used to add custom options to your application's scripts
1643 and setup your application differently depending on the values of these
1644 options.
1645
1646 =head1 INTERNAL METHODS
1647
1648 These methods are not meant to be used by end users.
1649
1650 =head2 $c->components
1651
1652 Returns a hash of components.
1653
1654 =head2 $c->context_class
1655
1656 Returns or sets the context class.
1657
1658 =head2 $c->counter
1659
1660 Returns a hashref containing coderefs and execution counts (needed for
1661 deep recursion detection).
1662
1663 =head2 $c->depth
1664
1665 Returns the number of actions on the current internal execution stack.
1666
1667 =head2 $c->dispatch
1668
1669 Dispatches a request to actions.
1670
1671 =cut
1672
1673 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1674
1675 =head2 $c->dispatcher_class
1676
1677 Returns or sets the dispatcher class.
1678
1679 =head2 $c->dump_these
1680
1681 Returns a list of 2-element array references (name, structure) pairs
1682 that will be dumped on the error page in debug mode.
1683
1684 =cut
1685
1686 sub dump_these {
1687     my $c = shift;
1688     [ Request => $c->req ],
1689     [ Response => $c->res ],
1690     [ Stash => $c->stash ],
1691     [ Config => $c->config ];
1692 }
1693
1694 =head2 $c->engine_class
1695
1696 Returns or sets the engine class.
1697
1698 =head2 $c->execute( $class, $coderef )
1699
1700 Execute a coderef in given class and catch exceptions. Errors are available
1701 via $c->error.
1702
1703 =cut
1704
1705 sub execute {
1706     my ( $c, $class, $code ) = @_;
1707     $class = $c->component($class) || $class;
1708     $c->state(0);
1709
1710     if ( $c->depth >= $RECURSION ) {
1711         my $action = $code->reverse();
1712         $action = "/$action" unless $action =~ /->/;
1713         my $error = qq/Deep recursion detected calling "${action}"/;
1714         $c->log->error($error);
1715         $c->error($error);
1716         $c->state(0);
1717         return $c->state;
1718     }
1719
1720     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1721
1722     push( @{ $c->stack }, $code );
1723
1724     no warnings 'recursion';
1725     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1726     #      I have no idea how, ergo $ret (which appears to fix the issue)
1727     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1728
1729     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1730
1731     my $last = pop( @{ $c->stack } );
1732
1733     if ( my $error = $@ ) {
1734         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1735             $error->rethrow if $c->depth > 1;
1736         }
1737         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1738             $error->rethrow if $c->depth > 0;
1739         }
1740         else {
1741             unless ( ref $error ) {
1742                 no warnings 'uninitialized';
1743                 chomp $error;
1744                 my $class = $last->class;
1745                 my $name  = $last->name;
1746                 $error = qq/Caught exception in $class->$name "$error"/;
1747             }
1748             $c->error($error);
1749         }
1750         $c->state(0);
1751     }
1752     return $c->state;
1753 }
1754
1755 sub _stats_start_execute {
1756     my ( $c, $code ) = @_;
1757     my $appclass = ref($c) || $c;
1758     return if ( ( $code->name =~ /^_.*/ )
1759         && ( !$appclass->config->{show_internal_actions} ) );
1760
1761     my $action_name = $code->reverse();
1762     $c->counter->{$action_name}++;
1763
1764     my $action = $action_name;
1765     $action = "/$action" unless $action =~ /->/;
1766
1767     # determine if the call was the result of a forward
1768     # this is done by walking up the call stack and looking for a calling
1769     # sub of Catalyst::forward before the eval
1770     my $callsub = q{};
1771     for my $index ( 2 .. 11 ) {
1772         last
1773         if ( ( caller($index) )[0] eq 'Catalyst'
1774             && ( caller($index) )[3] eq '(eval)' );
1775
1776         if ( ( caller($index) )[3] =~ /forward$/ ) {
1777             $callsub = ( caller($index) )[3];
1778             $action  = "-> $action";
1779             last;
1780         }
1781     }
1782
1783     my $uid = $action_name . $c->counter->{$action_name};
1784
1785     # is this a root-level call or a forwarded call?
1786     if ( $callsub =~ /forward$/ ) {
1787         my $parent = $c->stack->[-1];
1788
1789         # forward, locate the caller
1790         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1791             $c->stats->profile(
1792                 begin  => $action,
1793                 parent => "$parent" . $c->counter->{"$parent"},
1794                 uid    => $uid,
1795             );
1796         }
1797         else {
1798
1799             # forward with no caller may come from a plugin
1800             $c->stats->profile(
1801                 begin => $action,
1802                 uid   => $uid,
1803             );
1804         }
1805     }
1806     else {
1807
1808         # root-level call
1809         $c->stats->profile(
1810             begin => $action,
1811             uid   => $uid,
1812         );
1813     }
1814     return $action;
1815
1816 }
1817
1818 sub _stats_finish_execute {
1819     my ( $c, $info ) = @_;
1820     $c->stats->profile( end => $info );
1821 }
1822
1823 =head2 $c->finalize
1824
1825 Finalizes the request.
1826
1827 =cut
1828
1829 sub finalize {
1830     my $c = shift;
1831
1832     for my $error ( @{ $c->error } ) {
1833         $c->log->error($error);
1834     }
1835
1836     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1837     # stuff like cometd and websockets
1838
1839     if($c->request->_has_io_fh) {
1840       $c->log_response;
1841       return;
1842     }
1843
1844     # Allow engine to handle finalize flow (for POE)
1845     my $engine = $c->engine;
1846     if ( my $code = $engine->can('finalize') ) {
1847         $engine->$code($c);
1848     }
1849     else {
1850
1851         $c->finalize_uploads;
1852
1853         # Error
1854         if ( $#{ $c->error } >= 0 ) {
1855             $c->finalize_error;
1856         }
1857
1858         $c->finalize_headers unless $c->response->finalized_headers;
1859
1860         # HEAD request
1861         if ( $c->request->method eq 'HEAD' ) {
1862             $c->response->body('');
1863         }
1864
1865         $c->finalize_body;
1866     }
1867
1868     $c->log_response;
1869
1870     if ($c->use_stats) {
1871         my $elapsed = $c->stats->elapsed;
1872         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1873         $c->log->info(
1874             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1875     }
1876
1877     return $c->response->status;
1878 }
1879
1880 =head2 $c->finalize_body
1881
1882 Finalizes body.
1883
1884 =cut
1885
1886 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1887
1888 =head2 $c->finalize_cookies
1889
1890 Finalizes cookies.
1891
1892 =cut
1893
1894 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1895
1896 =head2 $c->finalize_error
1897
1898 Finalizes error.
1899
1900 =cut
1901
1902 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1903
1904 =head2 $c->finalize_headers
1905
1906 Finalizes headers.
1907
1908 =cut
1909
1910 sub finalize_headers {
1911     my $c = shift;
1912
1913     my $response = $c->response; #accessor calls can add up?
1914
1915     # Check if we already finalized headers
1916     return if $response->finalized_headers;
1917
1918     # Handle redirects
1919     if ( my $location = $response->redirect ) {
1920         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1921         $response->header( Location => $location );
1922
1923         if ( !$response->has_body ) {
1924             # Add a default body if none is already present
1925             my $encoded_location = encode_entities($location);
1926             $response->body(<<"EOF");
1927 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1928 <html xmlns="http://www.w3.org/1999/xhtml">
1929   <head>
1930     <title>Moved</title>
1931   </head>
1932   <body>
1933      <p>This item has moved <a href="$encoded_location">here</a>.</p>
1934   </body>
1935 </html>
1936 EOF
1937             $response->content_type('text/html; charset=utf-8');
1938         }
1939     }
1940
1941     # Content-Length
1942     if ( defined $response->body && length $response->body && !$response->content_length ) {
1943
1944         # get the length from a filehandle
1945         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1946         {
1947             my $size = -s $response->body;
1948             if ( $size ) {
1949                 $response->content_length( $size );
1950             }
1951             else {
1952                 $c->log->warn('Serving filehandle without a content-length');
1953             }
1954         }
1955         else {
1956             # everything should be bytes at this point, but just in case
1957             $response->content_length( length( $response->body ) );
1958         }
1959     }
1960
1961     # Errors
1962     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1963         $response->headers->remove_header("Content-Length");
1964         $response->body('');
1965     }
1966
1967     $c->finalize_cookies;
1968
1969     $c->response->finalize_headers();
1970
1971     # Done
1972     $response->finalized_headers(1);
1973 }
1974
1975 =head2 $c->finalize_output
1976
1977 An alias for finalize_body.
1978
1979 =head2 $c->finalize_read
1980
1981 Finalizes the input after reading is complete.
1982
1983 =cut
1984
1985 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1986
1987 =head2 $c->finalize_uploads
1988
1989 Finalizes uploads. Cleans up any temporary files.
1990
1991 =cut
1992
1993 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1994
1995 =head2 $c->get_action( $action, $namespace )
1996
1997 Gets an action in a given namespace.
1998
1999 =cut
2000
2001 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2002
2003 =head2 $c->get_actions( $action, $namespace )
2004
2005 Gets all actions of a given name in a namespace and all parent
2006 namespaces.
2007
2008 =cut
2009
2010 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2011
2012 =head2 $app->handle_request( @arguments )
2013
2014 Called to handle each HTTP request.
2015
2016 =cut
2017
2018 sub handle_request {
2019     my ( $class, @arguments ) = @_;
2020
2021     # Always expect worst case!
2022     my $status = -1;
2023     try {
2024         if ($class->debug) {
2025             my $secs = time - $START || 1;
2026             my $av = sprintf '%.3f', $COUNT / $secs;
2027             my $time = localtime time;
2028             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2029         }
2030
2031         my $c = $class->prepare(@arguments);
2032         $c->dispatch;
2033         $status = $c->finalize;
2034     }
2035     catch {
2036         chomp(my $error = $_);
2037         $class->log->error(qq/Caught exception in engine "$error"/);
2038     };
2039
2040     $COUNT++;
2041
2042     if(my $coderef = $class->log->can('_flush')){
2043         $class->log->$coderef();
2044     }
2045     return $status;
2046 }
2047
2048 =head2 $class->prepare( @arguments )
2049
2050 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2051 etc.).
2052
2053 =cut
2054
2055 has _uploadtmp => (
2056     is => 'ro',
2057     predicate => '_has_uploadtmp',
2058 );
2059
2060 sub prepare {
2061     my ( $class, @arguments ) = @_;
2062
2063     # XXX
2064     # After the app/ctxt split, this should become an attribute based on something passed
2065     # into the application.
2066     $class->context_class( ref $class || $class ) unless $class->context_class;
2067
2068     my $uploadtmp = $class->config->{uploadtmp};
2069     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2070
2071     $c->response->_context($c);
2072
2073     #surely this is not the most efficient way to do things...
2074     $c->stats($class->stats_class->new)->enable($c->use_stats);
2075     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2076         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2077     }
2078
2079     try {
2080         # Allow engine to direct the prepare flow (for POE)
2081         if ( my $prepare = $c->engine->can('prepare') ) {
2082             $c->engine->$prepare( $c, @arguments );
2083         }
2084         else {
2085             $c->prepare_request(@arguments);
2086             $c->prepare_connection;
2087             $c->prepare_query_parameters;
2088             $c->prepare_headers; # Just hooks, no longer needed - they just
2089             $c->prepare_cookies; # cause the lazy attribute on req to build
2090             $c->prepare_path;
2091
2092             # Prepare the body for reading, either by prepare_body
2093             # or the user, if they are using $c->read
2094             $c->prepare_read;
2095
2096             # Parse the body unless the user wants it on-demand
2097             unless ( ref($c)->config->{parse_on_demand} ) {
2098                 $c->prepare_body;
2099             }
2100         }
2101         $c->prepare_action;
2102     }
2103     # VERY ugly and probably shouldn't rely on ->finalize actually working
2104     catch {
2105         # failed prepare is always due to an invalid request, right?
2106         $c->response->status(400);
2107         $c->response->content_type('text/plain');
2108         $c->response->body('Bad Request');
2109         # Note we call finalize and then die here, which escapes
2110         # finalize being called in the enclosing block..
2111         # It in fact couldn't be called, as we don't return $c..
2112         # This is a mess - but I'm unsure you can fix this without
2113         # breaking compat for people doing crazy things (we should set
2114         # the 400 and just return the ctx here IMO, letting finalize get called
2115         # above...
2116         $c->finalize;
2117         die $_;
2118     };
2119
2120     $c->log_request;
2121
2122     return $c;
2123 }
2124
2125 =head2 $c->prepare_action
2126
2127 Prepares action. See L<Catalyst::Dispatcher>.
2128
2129 =cut
2130
2131 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2132
2133 =head2 $c->prepare_body
2134
2135 Prepares message body.
2136
2137 =cut
2138
2139 sub prepare_body {
2140     my $c = shift;
2141
2142     return if $c->request->_has_body;
2143
2144     # Initialize on-demand data
2145     $c->engine->prepare_body( $c, @_ );
2146     $c->prepare_parameters;
2147     $c->prepare_uploads;
2148 }
2149
2150 =head2 $c->prepare_body_chunk( $chunk )
2151
2152 Prepares a chunk of data before sending it to L<HTTP::Body>.
2153
2154 See L<Catalyst::Engine>.
2155
2156 =cut
2157
2158 sub prepare_body_chunk {
2159     my $c = shift;
2160     $c->engine->prepare_body_chunk( $c, @_ );
2161 }
2162
2163 =head2 $c->prepare_body_parameters
2164
2165 Prepares body parameters.
2166
2167 =cut
2168
2169 sub prepare_body_parameters {
2170     my $c = shift;
2171     $c->engine->prepare_body_parameters( $c, @_ );
2172 }
2173
2174 =head2 $c->prepare_connection
2175
2176 Prepares connection.
2177
2178 =cut
2179
2180 sub prepare_connection {
2181     my $c = shift;
2182     # XXX - This is called on the engine (not the request) to maintain
2183     #       Engine::PSGI back compat.
2184     $c->engine->prepare_connection($c);
2185 }
2186
2187 =head2 $c->prepare_cookies
2188
2189 Prepares cookies by ensuring that the attribute on the request
2190 object has been built.
2191
2192 =cut
2193
2194 sub prepare_cookies { my $c = shift; $c->request->cookies }
2195
2196 =head2 $c->prepare_headers
2197
2198 Prepares request headers by ensuring that the attribute on the request
2199 object has been built.
2200
2201 =cut
2202
2203 sub prepare_headers { my $c = shift; $c->request->headers }
2204
2205 =head2 $c->prepare_parameters
2206
2207 Prepares parameters.
2208
2209 =cut
2210
2211 sub prepare_parameters {
2212     my $c = shift;
2213     $c->prepare_body_parameters;
2214     $c->engine->prepare_parameters( $c, @_ );
2215 }
2216
2217 =head2 $c->prepare_path
2218
2219 Prepares path and base.
2220
2221 =cut
2222
2223 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2224
2225 =head2 $c->prepare_query_parameters
2226
2227 Prepares query parameters.
2228
2229 =cut
2230
2231 sub prepare_query_parameters {
2232     my $c = shift;
2233
2234     $c->engine->prepare_query_parameters( $c, @_ );
2235 }
2236
2237 =head2 $c->log_request
2238
2239 Writes information about the request to the debug logs.  This includes:
2240
2241 =over 4
2242
2243 =item * Request method, path, and remote IP address
2244
2245 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2246
2247 =item * Request parameters
2248
2249 =item * File uploads
2250
2251 =back
2252
2253 =cut
2254
2255 sub log_request {
2256     my $c = shift;
2257
2258     return unless $c->debug;
2259
2260     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2261     my $request = $dump->[1];
2262
2263     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2264     $method ||= '';
2265     $path = '/' unless length $path;
2266     $address ||= '';
2267     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2268
2269     $c->log_request_headers($request->headers);
2270
2271     if ( my $keywords = $request->query_keywords ) {
2272         $c->log->debug("Query keywords are: $keywords");
2273     }
2274
2275     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2276
2277     $c->log_request_uploads($request);
2278 }
2279
2280 =head2 $c->log_response
2281
2282 Writes information about the response to the debug logs by calling
2283 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2284
2285 =cut
2286
2287 sub log_response {
2288     my $c = shift;
2289
2290     return unless $c->debug;
2291
2292     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2293     my $response = $dump->[1];
2294
2295     $c->log_response_status_line($response);
2296     $c->log_response_headers($response->headers);
2297 }
2298
2299 =head2 $c->log_response_status_line($response)
2300
2301 Writes one line of information about the response to the debug logs.  This includes:
2302
2303 =over 4
2304
2305 =item * Response status code
2306
2307 =item * Content-Type header (if present)
2308
2309 =item * Content-Length header (if present)
2310
2311 =back
2312
2313 =cut
2314
2315 sub log_response_status_line {
2316     my ($c, $response) = @_;
2317
2318     $c->log->debug(
2319         sprintf(
2320             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2321             $response->status                            || 'unknown',
2322             $response->headers->header('Content-Type')   || 'unknown',
2323             $response->headers->header('Content-Length') || 'unknown'
2324         )
2325     );
2326 }
2327
2328 =head2 $c->log_response_headers($headers);
2329
2330 Hook method which can be wrapped by plugins to log the response headers.
2331 No-op in the default implementation.
2332
2333 =cut
2334
2335 sub log_response_headers {}
2336
2337 =head2 $c->log_request_parameters( query => {}, body => {} )
2338
2339 Logs request parameters to debug logs
2340
2341 =cut
2342
2343 sub log_request_parameters {
2344     my $c          = shift;
2345     my %all_params = @_;
2346
2347     return unless $c->debug;
2348
2349     my $column_width = Catalyst::Utils::term_width() - 44;
2350     foreach my $type (qw(query body)) {
2351         my $params = $all_params{$type};
2352         next if ! keys %$params;
2353         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2354         for my $key ( sort keys %$params ) {
2355             my $param = $params->{$key};
2356             my $value = defined($param) ? $param : '';
2357             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2358         }
2359         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2360     }
2361 }
2362
2363 =head2 $c->log_request_uploads
2364
2365 Logs file uploads included in the request to the debug logs.
2366 The parameter name, filename, file type, and file size are all included in
2367 the debug logs.
2368
2369 =cut
2370
2371 sub log_request_uploads {
2372     my $c = shift;
2373     my $request = shift;
2374     return unless $c->debug;
2375     my $uploads = $request->uploads;
2376     if ( keys %$uploads ) {
2377         my $t = Text::SimpleTable->new(
2378             [ 12, 'Parameter' ],
2379             [ 26, 'Filename' ],
2380             [ 18, 'Type' ],
2381             [ 9,  'Size' ]
2382         );
2383         for my $key ( sort keys %$uploads ) {
2384             my $upload = $uploads->{$key};
2385             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2386                 $t->row( $key, $u->filename, $u->type, $u->size );
2387             }
2388         }
2389         $c->log->debug( "File Uploads are:\n" . $t->draw );
2390     }
2391 }
2392
2393 =head2 $c->log_request_headers($headers);
2394
2395 Hook method which can be wrapped by plugins to log the request headers.
2396 No-op in the default implementation.
2397
2398 =cut
2399
2400 sub log_request_headers {}
2401
2402 =head2 $c->log_headers($type => $headers)
2403
2404 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2405
2406 =cut
2407
2408 sub log_headers {
2409     my $c       = shift;
2410     my $type    = shift;
2411     my $headers = shift;    # an HTTP::Headers instance
2412
2413     return unless $c->debug;
2414
2415     my $column_width = Catalyst::Utils::term_width() - 28;
2416     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2417     $headers->scan(
2418         sub {
2419             my ( $name, $value ) = @_;
2420             $t->row( $name, $value );
2421         }
2422     );
2423     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2424 }
2425
2426
2427 =head2 $c->prepare_read
2428
2429 Prepares the input for reading.
2430
2431 =cut
2432
2433 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2434
2435 =head2 $c->prepare_request
2436
2437 Prepares the engine request.
2438
2439 =cut
2440
2441 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2442
2443 =head2 $c->prepare_uploads
2444
2445 Prepares uploads.
2446
2447 =cut
2448
2449 sub prepare_uploads {
2450     my $c = shift;
2451
2452     $c->engine->prepare_uploads( $c, @_ );
2453 }
2454
2455 =head2 $c->prepare_write
2456
2457 Prepares the output for writing.
2458
2459 =cut
2460
2461 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2462
2463 =head2 $c->request_class
2464
2465 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2466
2467 =head2 $c->response_class
2468
2469 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2470
2471 =head2 $c->read( [$maxlength] )
2472
2473 Reads a chunk of data from the request body. This method is designed to
2474 be used in a while loop, reading C<$maxlength> bytes on every call.
2475 C<$maxlength> defaults to the size of the request if not specified.
2476
2477 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2478 directly.
2479
2480 Warning: If you use read(), Catalyst will not process the body,
2481 so you will not be able to access POST parameters or file uploads via
2482 $c->request.  You must handle all body parsing yourself.
2483
2484 =cut
2485
2486 sub read { my $c = shift; return $c->request->read( @_ ) }
2487
2488 =head2 $c->run
2489
2490 Starts the engine.
2491
2492 =cut
2493
2494 sub run {
2495   my $app = shift;
2496   $app->_make_immutable_if_needed;
2497   $app->engine_loader->needs_psgi_engine_compat_hack ?
2498     $app->engine->run($app, @_) :
2499       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2500 }
2501
2502 sub _make_immutable_if_needed {
2503     my $class = shift;
2504     my $meta = find_meta($class);
2505     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2506     if (
2507         $meta->is_immutable
2508         && ! { $meta->immutable_options }->{replace_constructor}
2509         && $isa_ca
2510     ) {
2511         warn("You made your application class ($class) immutable, "
2512             . "but did not inline the\nconstructor. "
2513             . "This will break catalyst, as your app \@ISA "
2514             . "Class::Accessor(::Fast)?\nPlease pass "
2515             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2516     }
2517     unless ($meta->is_immutable) {
2518         # XXX - FIXME warning here as you should make your app immutable yourself.
2519         $meta->make_immutable(
2520             replace_constructor => 1,
2521         );
2522     }
2523 }
2524
2525 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2526
2527 Sets an action in a given namespace.
2528
2529 =cut
2530
2531 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2532
2533 =head2 $c->setup_actions($component)
2534
2535 Sets up actions for a component.
2536
2537 =cut
2538
2539 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2540
2541 =head2 $c->setup_components
2542
2543 This method is called internally to set up the application's components.
2544
2545 It finds modules by calling the L<locate_components> method, expands them to
2546 package names with the L<expand_component_module> method, and then installs
2547 each component into the application.
2548
2549 The C<setup_components> config option is passed to both of the above methods.
2550
2551 Installation of each component is performed by the L<setup_component> method,
2552 below.
2553
2554 =cut
2555
2556 sub setup_components {
2557     my $class = shift;
2558
2559     my $config  = $class->config->{ setup_components };
2560
2561     my @comps = $class->locate_components($config);
2562     my %comps = map { $_ => 1 } @comps;
2563
2564     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2565     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2566         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2567     ) if $deprecatedcatalyst_component_names;
2568
2569     for my $component ( @comps ) {
2570
2571         # We pass ignore_loaded here so that overlay files for (e.g.)
2572         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2573         # we know M::P::O found a file on disk so this is safe
2574
2575         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2576     }
2577
2578     for my $component (@comps) {
2579         my $instance = $class->components->{ $component } = $class->setup_component($component);
2580         my @expanded_components = $instance->can('expand_modules')
2581             ? $instance->expand_modules( $component, $config )
2582             : $class->expand_component_module( $component, $config );
2583         for my $component (@expanded_components) {
2584             next if $comps{$component};
2585             $class->components->{ $component } = $class->setup_component($component);
2586         }
2587     }
2588 }
2589
2590 =head2 $c->locate_components( $setup_component_config )
2591
2592 This method is meant to provide a list of component modules that should be
2593 setup for the application.  By default, it will use L<Module::Pluggable>.
2594
2595 Specify a C<setup_components> config option to pass additional options directly
2596 to L<Module::Pluggable>. To add additional search paths, specify a key named
2597 C<search_extra> as an array reference. Items in the array beginning with C<::>
2598 will have the application class name prepended to them.
2599
2600 =cut
2601
2602 sub locate_components {
2603     my $class  = shift;
2604     my $config = shift;
2605
2606     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2607     my $extra   = delete $config->{ search_extra } || [];
2608
2609     push @paths, @$extra;
2610
2611     my $locator = Module::Pluggable::Object->new(
2612         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2613         %$config
2614     );
2615
2616     # XXX think about ditching this sort entirely
2617     my @comps = sort { length $a <=> length $b } $locator->plugins;
2618
2619     return @comps;
2620 }
2621
2622 =head2 $c->expand_component_module( $component, $setup_component_config )
2623
2624 Components found by C<locate_components> will be passed to this method, which
2625 is expected to return a list of component (package) names to be set up.
2626
2627 =cut
2628
2629 sub expand_component_module {
2630     my ($class, $module) = @_;
2631     return Devel::InnerPackage::list_packages( $module );
2632 }
2633
2634 =head2 $c->setup_component
2635
2636 =cut
2637
2638 sub setup_component {
2639     my( $class, $component ) = @_;
2640
2641     unless ( $component->can( 'COMPONENT' ) ) {
2642         return $component;
2643     }
2644
2645     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2646     my $config = $class->config->{ $suffix } || {};
2647     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2648     # methods also pass it. local to avoid pointlessly shitting in config
2649     # for the debug screen, as $component is already the key name.
2650     local $config->{catalyst_component_name} = $component;
2651
2652     my $instance = eval { $component->COMPONENT( $class, $config ); };
2653
2654     if ( my $error = $@ ) {
2655         chomp $error;
2656         Catalyst::Exception->throw(
2657             message => qq/Couldn't instantiate component "$component", "$error"/
2658         );
2659     }
2660
2661     unless (blessed $instance) {
2662         my $metaclass = Moose::Util::find_meta($component);
2663         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2664         my $component_method_from = $method_meta->associated_metaclass->name;
2665         my $value = defined($instance) ? $instance : 'undef';
2666         Catalyst::Exception->throw(
2667             message =>
2668             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2669         );
2670     }
2671     return $instance;
2672 }
2673
2674 =head2 $c->setup_dispatcher
2675
2676 Sets up dispatcher.
2677
2678 =cut
2679
2680 sub setup_dispatcher {
2681     my ( $class, $dispatcher ) = @_;
2682
2683     if ($dispatcher) {
2684         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2685     }
2686
2687     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2688         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2689     }
2690
2691     unless ($dispatcher) {
2692         $dispatcher = $class->dispatcher_class;
2693     }
2694
2695     load_class($dispatcher);
2696
2697     # dispatcher instance
2698     $class->dispatcher( $dispatcher->new );
2699 }
2700
2701 =head2 $c->setup_engine
2702
2703 Sets up engine.
2704
2705 =cut
2706
2707 sub engine_class {
2708     my ($class, $requested_engine) = @_;
2709
2710     if (!$class->engine_loader || $requested_engine) {
2711         $class->engine_loader(
2712             Catalyst::EngineLoader->new({
2713                 application_name => $class,
2714                 (defined $requested_engine
2715                      ? (catalyst_engine_class => $requested_engine) : ()),
2716             }),
2717         );
2718     }
2719
2720     $class->engine_loader->catalyst_engine_class;
2721 }
2722
2723 sub setup_engine {
2724     my ($class, $requested_engine) = @_;
2725
2726     my $engine = do {
2727         my $loader = $class->engine_loader;
2728
2729         if (!$loader || $requested_engine) {
2730             $loader = Catalyst::EngineLoader->new({
2731                 application_name => $class,
2732                 (defined $requested_engine
2733                      ? (requested_engine => $requested_engine) : ()),
2734             }),
2735
2736             $class->engine_loader($loader);
2737         }
2738
2739         $loader->catalyst_engine_class;
2740     };
2741
2742     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2743     return if $class->loading_psgi_file;
2744
2745     load_class($engine);
2746
2747     if ($ENV{MOD_PERL}) {
2748         my $apache = $class->engine_loader->auto;
2749
2750         my $meta = find_meta($class);
2751         my $was_immutable = $meta->is_immutable;
2752         my %immutable_options = $meta->immutable_options;
2753         $meta->make_mutable if $was_immutable;
2754
2755         $meta->add_method(handler => sub {
2756             my $r = shift;
2757             my $psgi_app = $class->_finalized_psgi_app;
2758             $apache->call_app($r, $psgi_app);
2759         });
2760
2761         $meta->make_immutable(%immutable_options) if $was_immutable;
2762     }
2763
2764     $class->engine( $engine->new );
2765
2766     return;
2767 }
2768
2769 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2770 ## build in server support (back compat support for pre psgi port behavior).
2771 ## This is so that we don't build a new psgi app for each request when using
2772 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2773
2774 sub _finalized_psgi_app {
2775     my ($app) = @_;
2776
2777     unless ($app->_psgi_app) {
2778         my $psgi_app = $app->_setup_psgi_app;
2779         $app->_psgi_app($psgi_app);
2780     }
2781
2782     return $app->_psgi_app;
2783 }
2784
2785 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2786 ## home directory and load that and return it (just assume it is doing the
2787 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2788 ## in default_middleware and return it ( this is for backward compatibility
2789 ## with pre psgi port behavior ).
2790
2791 sub _setup_psgi_app {
2792     my ($app) = @_;
2793
2794     for my $home (Path::Class::Dir->new($app->config->{home})) {
2795         my $psgi_file = $home->file(
2796             Catalyst::Utils::appprefix($app) . '.psgi',
2797         );
2798
2799         next unless -e $psgi_file;
2800
2801         # If $psgi_file calls ->setup_engine, it's doing so to load
2802         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2803         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2804         # anyway. So set a flag (ick) that tells setup_engine not to populate
2805         # $c->engine or do any other things we might regret.
2806
2807         $app->loading_psgi_file(1);
2808         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2809         $app->loading_psgi_file(0);
2810
2811         return $psgi_app
2812             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2813
2814         warn <<"EOW";
2815 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2816
2817 Its content has been ignored. Please consult the Catalyst::Upgrading
2818 documentation on how to upgrade from Catalyst::Engine::PSGI.
2819 EOW
2820     }
2821
2822     return $app->apply_default_middlewares($app->psgi_app);
2823 }
2824
2825 =head2 $c->apply_default_middlewares
2826
2827 Adds the following L<Plack> middlewares to your application, since they are
2828 useful and commonly needed:
2829
2830 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2831 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2832 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2833 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2834 applied since this middleware is smart enough to conditionally apply itself).
2835
2836 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2837 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2838 $ENV{SCRIPT_NAME}
2839
2840 =cut
2841
2842
2843 sub apply_default_middlewares {
2844     my ($app, $psgi_app) = @_;
2845
2846     $psgi_app = Plack::Middleware::Conditional->wrap(
2847         $psgi_app,
2848         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2849         condition => sub {
2850             my ($env) = @_;
2851             return if $app->config->{ignore_frontend_proxy};
2852             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2853                 || $app->config->{using_frontend_proxy};
2854         },
2855     );
2856
2857     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2858     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2859     $psgi_app = Plack::Middleware::Conditional->wrap(
2860         $psgi_app,
2861         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2862         condition => sub {
2863             my ($env) = @_;
2864             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2865             return unless $1 < 4.23;
2866             1;
2867         },
2868     );
2869
2870     # we're applying this unconditionally as the middleware itself already makes
2871     # sure it doesn't fuck things up if it's not running under one of the right
2872     # IIS versions
2873     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2874
2875     # And another IIS issue, this time with IIS7.
2876     $psgi_app = Plack::Middleware::Conditional->wrap(
2877         $psgi_app,
2878         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2879         condition => sub {
2880             my ($env) = @_;
2881             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2882         },
2883     );
2884
2885     return $psgi_app;
2886 }
2887
2888 =head2 $c->psgi_app
2889
2890 Returns a PSGI application code reference for the catalyst application
2891 C<$c>. This is the bare application without any middlewares
2892 applied. C<${myapp}.psgi> is not taken into account.
2893
2894 This is what you want to be using to retrieve the PSGI application code
2895 reference of your Catalyst application for use in F<.psgi> files.
2896
2897 =cut
2898
2899 sub psgi_app {
2900     my ($app) = @_;
2901     my $psgi = $app->engine->build_psgi_app($app);
2902     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
2903 }
2904
2905 =head2 $c->setup_home
2906
2907 Sets up the home directory.
2908
2909 =cut
2910
2911 sub setup_home {
2912     my ( $class, $home ) = @_;
2913
2914     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2915         $home = $env;
2916     }
2917
2918     $home ||= Catalyst::Utils::home($class);
2919
2920     if ($home) {
2921         #I remember recently being scolded for assigning config values like this
2922         $class->config->{home} ||= $home;
2923         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2924     }
2925 }
2926
2927 =head2 $c->setup_log
2928
2929 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2930 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2931 log to.
2932
2933 This method also installs a C<debug> method that returns a true value into the
2934 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2935 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2936
2937 Note that if the log has already been setup, by either a previous call to
2938 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2939 that this method won't actually set up the log object.
2940
2941 =cut
2942
2943 sub setup_log {
2944     my ( $class, $levels ) = @_;
2945
2946     $levels ||= '';
2947     $levels =~ s/^\s+//;
2948     $levels =~ s/\s+$//;
2949     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2950
2951     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2952     if ( defined $env_debug ) {
2953         $levels{debug} = 1 if $env_debug; # Ugly!
2954         delete($levels{debug}) unless $env_debug;
2955     }
2956
2957     unless ( $class->log ) {
2958         $class->log( Catalyst::Log->new(keys %levels) );
2959     }
2960
2961     if ( $levels{debug} ) {
2962         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2963         $class->log->debug('Debug messages enabled');
2964     }
2965 }
2966
2967 =head2 $c->setup_plugins
2968
2969 Sets up plugins.
2970
2971 =cut
2972
2973 =head2 $c->setup_stats
2974
2975 Sets up timing statistics class.
2976
2977 =cut
2978
2979 sub setup_stats {
2980     my ( $class, $stats ) = @_;
2981
2982     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2983
2984     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2985     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2986         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2987         $class->log->debug('Statistics enabled');
2988     }
2989 }
2990
2991
2992 =head2 $c->registered_plugins
2993
2994 Returns a sorted list of the plugins which have either been stated in the
2995 import list.
2996
2997 If passed a given plugin name, it will report a boolean value indicating
2998 whether or not that plugin is loaded.  A fully qualified name is required if
2999 the plugin name does not begin with C<Catalyst::Plugin::>.
3000
3001  if ($c->registered_plugins('Some::Plugin')) {
3002      ...
3003  }
3004
3005 =cut
3006
3007 {
3008
3009     sub registered_plugins {
3010         my $proto = shift;
3011         return sort keys %{ $proto->_plugins } unless @_;
3012         my $plugin = shift;
3013         return 1 if exists $proto->_plugins->{$plugin};
3014         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3015     }
3016
3017     sub _register_plugin {
3018         my ( $proto, $plugin, $instant ) = @_;
3019         my $class = ref $proto || $proto;
3020
3021         load_class( $plugin );
3022         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3023             if $plugin->isa( 'Catalyst::Component' );
3024         my $plugin_meta = Moose::Meta::Class->create($plugin);
3025         if (!$plugin_meta->has_method('new')
3026             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3027             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3028         }
3029         if (!$instant && !$proto->_plugins->{$plugin}) {
3030             my $meta = Class::MOP::get_metaclass_by_name($class);
3031             $meta->superclasses($plugin, $meta->superclasses);
3032         }
3033         $proto->_plugins->{$plugin} = 1;
3034         return $class;
3035     }
3036
3037     sub _default_plugins { return qw(Unicode::Encoding) }
3038
3039     sub setup_plugins {
3040         my ( $class, $plugins ) = @_;
3041
3042         $class->_plugins( {} ) unless $class->_plugins;
3043         $plugins = [ grep {
3044             m/Unicode::Encoding/ ? do {
3045                 $class->log->warn(
3046                     'Unicode::Encoding plugin is auto-applied,'
3047                     . ' please remove this from your appclass'
3048                     . ' and make sure to define "encoding" config'
3049                 );
3050                 unless (exists $class->config->{'encoding'}) {
3051                   $class->config->{'encoding'} = 'UTF-8';
3052                 }
3053                 () }
3054                 : $_
3055         } @$plugins ];
3056         push @$plugins, $class->_default_plugins;
3057         $plugins = Data::OptList::mkopt($plugins || []);
3058
3059         my @plugins = map {
3060             [ Catalyst::Utils::resolve_namespace(
3061                   $class . '::Plugin',
3062                   'Catalyst::Plugin', $_->[0]
3063               ),
3064               $_->[1],
3065             ]
3066          } @{ $plugins };
3067
3068         for my $plugin ( reverse @plugins ) {
3069             load_class($plugin->[0], $plugin->[1]);
3070             my $meta = find_meta($plugin->[0]);
3071             next if $meta && $meta->isa('Moose::Meta::Role');
3072
3073             $class->_register_plugin($plugin->[0]);
3074         }
3075
3076         my @roles =
3077             map  { $_->[0]->name, $_->[1] }
3078             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3079             map  { [find_meta($_->[0]), $_->[1]] }
3080             @plugins;
3081
3082         Moose::Util::apply_all_roles(
3083             $class => @roles
3084         ) if @roles;
3085     }
3086 }
3087
3088 =head2 registered_middlewares
3089
3090 Read only accessor that returns an array of all the middleware in the order
3091 that they were added (which is the REVERSE of the order they will be applied).
3092
3093 The values returned will be either instances of L<Plack::Middleware> or of a
3094 compatible interface, or a coderef, which is assumed to be inlined middleware
3095
3096 =head2 setup_middleware (?@middleware)
3097
3098 Read configuration information stored in configuration key C<psgi_middleware> or
3099 from passed @args.
3100
3101 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3102 to use it to enable L<Plack::Middleware>
3103
3104 This method is automatically called during 'setup' of your application, so
3105 you really don't need to invoke it.  However you may do so if you find the idea
3106 of loading middleware via configuration weird :).  For example:
3107
3108     package MyApp;
3109
3110     use Catalyst;
3111
3112     __PACKAGE__->setup_middleware('Head');
3113     __PACKAGE__->setup;
3114
3115 When we read middleware definitions from configuration, we reverse the list
3116 which sounds odd but is likely how you expect it to work if you have prior
3117 experience with L<Plack::Builder> or if you previously used the plugin
3118 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3119
3120 =cut
3121
3122 sub registered_middlewares {
3123     my $class = shift;
3124     if(my $middleware = $class->_psgi_middleware) {
3125         return @$middleware;
3126     } else {
3127         die "You cannot call ->registered_middlewares until middleware has been setup";
3128     }
3129 }
3130
3131 sub setup_middleware {
3132     my $class = shift;
3133     my @middleware_definitions = @_ ?
3134       @_ : reverse(@{$class->config->{'psgi_middleware'}||[]});
3135
3136     my @middleware = ();
3137     while(my $next = shift(@middleware_definitions)) {
3138         if(ref $next) {
3139             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3140                 push @middleware, $next;
3141             } elsif(ref $next eq 'CODE') {
3142                 push @middleware, $next;
3143             } elsif(ref $next eq 'HASH') {
3144                 my $namespace = shift @middleware_definitions;
3145                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3146                 push @middleware, $mw;
3147             } else {
3148               die "I can't handle middleware definition ${\ref $next}";
3149             }
3150         } else {
3151           my $mw = $class->Catalyst::Utils::build_middleware($next);
3152           push @middleware, $mw;
3153         }
3154     }
3155
3156     my @existing = @{$class->_psgi_middleware || []};
3157     $class->_psgi_middleware([@middleware,@existing,]);
3158 }
3159
3160 =head2 registered_data_handlers
3161
3162 A read only copy of registered Data Handlers returned as a Hash, where each key
3163 is a content type and each value is a subref that attempts to decode that content
3164 type.
3165
3166 =head2 setup_data_handlers (?@data_handler)
3167
3168 Read configuration information stored in configuration key C<data_handlers> or
3169 from passed @args.
3170
3171 See under L</CONFIGURATION> information regarding C<data_handlers>.
3172
3173 This method is automatically called during 'setup' of your application, so
3174 you really don't need to invoke it.
3175
3176 =head2 default_data_handlers
3177
3178 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3179 only two default data handlers, for 'application/json' and an alternative to
3180 'application/x-www-form-urlencoded' which supposed nested form parameters via
3181 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3182
3183 The 'application/json' data handler is used to parse incoming JSON into a Perl
3184 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3185 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3186 JSON decoder, and has the smallest dependency impact.
3187
3188 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3189 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3190 order to get the best performance.  You should add either to your dependency
3191 list (Makefile.PL, dist.ini, cpanfile, etc.)
3192
3193 =cut
3194
3195 sub registered_data_handlers {
3196     my $class = shift;
3197     if(my $data_handlers = $class->_data_handlers) {
3198         return %$data_handlers;
3199     } else {
3200         die "You cannot call ->registered_data_handlers until data_handers has been setup";
3201     }
3202 }
3203
3204 sub setup_data_handlers {
3205     my ($class, %data_handler_callbacks) = @_;
3206     %data_handler_callbacks = (
3207       %{$class->default_data_handlers},
3208       %{$class->config->{'data_handlers'}||+{}},
3209       %data_handler_callbacks);
3210
3211     $class->_data_handlers(\%data_handler_callbacks);
3212 }
3213
3214 sub default_data_handlers {
3215     my ($class) = @_;
3216     return +{
3217       'application/x-www-form-urlencoded' => sub {
3218           my ($fh, $req) = @_;
3219           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3220           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3221             ->can('build_cgi_struct')->($params);
3222       },
3223       'application/json' => sub {
3224           Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON')
3225             ->can('decode_json')->(do { local $/; $_->getline });
3226       },
3227     };
3228 }
3229
3230 =head2 $c->stack
3231
3232 Returns an arrayref of the internal execution stack (actions that are
3233 currently executing).
3234
3235 =head2 $c->stats
3236
3237 Returns the current timing statistics object. By default Catalyst uses
3238 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3239 L<< stats_class|/"$c->stats_class" >>.
3240
3241 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3242 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3243 profile explicitly, although MyApp.pm still won't profile nor output anything
3244 by itself.
3245
3246 =head2 $c->stats_class
3247
3248 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3249
3250 =head2 $c->use_stats
3251
3252 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3253
3254 Note that this is a static method, not an accessor and should be overridden
3255 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3256
3257 =cut
3258
3259 sub use_stats { 0 }
3260
3261
3262 =head2 $c->write( $data )
3263
3264 Writes $data to the output stream. When using this method directly, you
3265 will need to manually set the C<Content-Length> header to the length of
3266 your output data, if known.
3267
3268 =cut
3269
3270 sub write {
3271     my $c = shift;
3272
3273     # Finalize headers if someone manually writes output (for compat)
3274     $c->finalize_headers;
3275
3276     return $c->response->write( @_ );
3277 }
3278
3279 =head2 version
3280
3281 Returns the Catalyst version number. Mostly useful for "powered by"
3282 messages in template systems.
3283
3284 =cut
3285
3286 sub version { return $Catalyst::VERSION }
3287
3288 =head1 CONFIGURATION
3289
3290 There are a number of 'base' config variables which can be set:
3291
3292 =over
3293
3294 =item *
3295
3296 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3297
3298 =item *
3299
3300 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3301
3302 =item *
3303
3304 C<disable_component_resolution_regex_fallback> - Turns
3305 off the deprecated component resolution functionality so
3306 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3307 are called then regex search will not be attempted on string values and
3308 instead C<undef> will be returned.
3309
3310 =item *
3311
3312 C<home> - The application home directory. In an uninstalled application,
3313 this is the top level application directory. In an installed application,
3314 this will be the directory containing C<< MyApp.pm >>.
3315
3316 =item *
3317
3318 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3319
3320 =item *
3321
3322 C<name> - The name of the application in debug messages and the debug and
3323 welcome screens
3324
3325 =item *
3326
3327 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3328 until it is accessed. This allows you to (for example) check authentication (and reject
3329 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3330
3331 =item *
3332
3333 C<root> - The root directory for templates. Usually this is just a
3334 subdirectory of the home directory, but you can set it to change the
3335 templates to a different directory.
3336
3337 =item *
3338
3339 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3340 namespaces from which components will be loaded (and constructed and stored in
3341 C<< $c->components >>).
3342
3343 =item *
3344
3345 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3346 to be shown in hit debug tables in the test server.
3347
3348 =item *
3349
3350 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3351 variable should be used for determining the request path.
3352
3353 Most web server environments pass the requested path to the application using environment variables,
3354 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3355 exposed as C<< $c->request->base >>) and the request path below that base.
3356
3357 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3358 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3359
3360 =over
3361
3362 =item use_request_uri_for_path => 0
3363
3364 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3365 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3366 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3367 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3368
3369 However this method has the major disadvantage that it is impossible to correctly decode some elements
3370 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3371 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3372 can't distinguish / vs %2F in paths (in addition to other encoded values).
3373
3374 =item use_request_uri_for_path => 1
3375
3376 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3377 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3378 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3379
3380 Given that this method of path resolution is provably more correct, it is recommended that you use
3381 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3382 aware of the implications of not being able to handle encoded URI paths correctly.
3383
3384 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3385 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3386 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3387 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3388 C<< $c->request->base >> will be incorrect.
3389
3390 =back
3391
3392 =item *
3393
3394 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3395
3396 =item *
3397
3398 C<encoding> - See L</ENCODING>
3399
3400 =item *
3401
3402 C<abort_chain_on_error_fix>
3403
3404 When there is an error in an action chain, the default behavior is to continue
3405 processing the remaining actions and then catch the error upon chain end.  This
3406 can lead to running actions when the application is in an unexpected state.  If
3407 you have this issue, setting this config value to true will promptly exit a
3408 chain when there is an error raised in any action (thus terminating the chain
3409 early.)
3410
3411 use like:
3412
3413     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3414
3415 In the future this might become the default behavior.
3416
3417 =item *
3418
3419 C<use_hash_multivalue_in_request>
3420
3421 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3422 and C<parameters> return a hashref where values might be scalar or an arrayref
3423 depending on the incoming data.  In many cases this can be undesirable as it
3424 leads one to writing defensive code like the following:
3425
3426     my ($val) = ref($c->req->parameters->{a}) ?
3427       @{$c->req->parameters->{a}} :
3428         $c->req->parameters->{a};
3429
3430 Setting this configuration item to true will make L<Catalyst> populate the
3431 attributes underlying these methods with an instance of L<Hash::MultiValue>
3432 which is used by L<Plack::Request> and others to solve this very issue.  You
3433 may prefer this behavior to the default, if so enable this option (be warned
3434 if you enable it in a legacy application we are not sure if it is completely
3435 backwardly compatible).
3436
3437 =item *
3438
3439 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3440
3441 =item *
3442
3443 C<data_handlers> - See L<DATA HANDLERS>.
3444
3445 =back
3446
3447 =head1 INTERNAL ACTIONS
3448
3449 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3450 C<_ACTION>, and C<_END>. These are by default not shown in the private
3451 action table, but you can make them visible with a config parameter.
3452
3453     MyApp->config(show_internal_actions => 1);
3454
3455 =head1 ON-DEMAND PARSER
3456
3457 The request body is usually parsed at the beginning of a request,
3458 but if you want to handle input yourself, you can enable on-demand
3459 parsing with a config parameter.
3460
3461     MyApp->config(parse_on_demand => 1);
3462
3463 =head1 PROXY SUPPORT
3464
3465 Many production servers operate using the common double-server approach,
3466 with a lightweight frontend web server passing requests to a larger
3467 backend server. An application running on the backend server must deal
3468 with two problems: the remote user always appears to be C<127.0.0.1> and
3469 the server's hostname will appear to be C<localhost> regardless of the
3470 virtual host that the user connected through.
3471
3472 Catalyst will automatically detect this situation when you are running
3473 the frontend and backend servers on the same machine. The following
3474 changes are made to the request.
3475
3476     $c->req->address is set to the user's real IP address, as read from
3477     the HTTP X-Forwarded-For header.
3478
3479     The host value for $c->req->base and $c->req->uri is set to the real
3480     host, as read from the HTTP X-Forwarded-Host header.
3481
3482 Additionally, you may be running your backend application on an insecure
3483 connection (port 80) while your frontend proxy is running under SSL.  If there
3484 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3485 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3486 be created properly.
3487
3488 In the case of passing in:
3489
3490     X-Forwarded-Port: 443
3491
3492 All calls to C<uri_for> will result in an https link, as is expected.
3493
3494 Obviously, your web server must support these headers for this to work.
3495
3496 In a more complex server farm environment where you may have your
3497 frontend proxy server(s) on different machines, you will need to set a
3498 configuration option to tell Catalyst to read the proxied data from the
3499 headers.
3500
3501     MyApp->config(using_frontend_proxy => 1);
3502
3503 If you do not wish to use the proxy support at all, you may set:
3504
3505     MyApp->config(ignore_frontend_proxy => 0);
3506
3507 =head2 Note about psgi files
3508
3509 Note that if you supply your own .psgi file, calling
3510 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3511
3512 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3513 in your psgi, for example:
3514
3515     builder {
3516         enable "Plack::Middleware::ReverseProxy";
3517         MyApp->psgi_app
3518     };
3519
3520 This will unconditionally add the ReverseProxy support, or you need to call
3521 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3522 apply the support depending upon your config).
3523
3524 See L<Catalyst::PSGI> for more information.
3525
3526 =head1 THREAD SAFETY
3527
3528 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3529 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3530 believe the Catalyst core to be thread-safe.
3531
3532 If you plan to operate in a threaded environment, remember that all other
3533 modules you are using must also be thread-safe. Some modules, most notably
3534 L<DBD::SQLite>, are not thread-safe.
3535
3536 =head1 DATA HANDLERS
3537
3538 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3539 form parameters and URL search query fields.  However it has become common
3540 for various alternative content types to be PUT or POSTed to your controllers
3541 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3542 XML and other content types when communicating with an application server.  In
3543 order to better support this use case, L<Catalyst> defines a global configuration
3544 option, C<data_handlers>, which lets you associate a content type with a coderef
3545 that parses that content type into something Perl can readily access.
3546
3547     package MyApp::Web;
3548
3549     use Catalyst;
3550     use JSON::Maybe;
3551
3552     __PACKAGE__->config(
3553       data_handlers => {
3554         'application/json' => sub { local $/; decode_json $_->getline },
3555       },
3556       ## Any other configuration.
3557     );
3558
3559     __PACKAGE__->setup;
3560
3561 By default L<Catalyst> comes with a generic JSON data handler similar to the
3562 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
3563 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
3564 it installed (if you want the faster XS parser, add it to you project Makefile.PL
3565 or dist.ini, cpanfile, etc.)
3566
3567 The C<data_handlers> configuation is a hashref whose keys are HTTP Content-Types
3568 (matched against the incoming request type using a regexp such as to be case
3569 insensitive) and whose values are coderefs that receive a localized version of
3570 C<$_> which is a filehandle object pointing to received body.
3571
3572 This feature is considered an early access release and we reserve the right
3573 to alter the interface in order to provide a performant and secure solution to
3574 alternative request body content.  Your reports welcomed!
3575
3576 =head1 PSGI MIDDLEWARE
3577
3578 You can define middleware, defined as L<Plack::Middleware> or a compatible
3579 interface in configuration.  Your middleware definitions are in the form of an
3580 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3581 with details to follow:
3582
3583     package MyApp::Web;
3584
3585     use Catalyst;
3586     use Plack::Middleware::StackTrace;
3587
3588     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3589
3590     __PACKAGE__->config(
3591       'psgi_middleware', [
3592         'Debug',
3593         '+MyApp::Custom',
3594         $stacktrace_middleware,
3595         'Session' => {store => 'File'},
3596         sub {
3597           my $app = shift;
3598           return sub {
3599             my $env = shift;
3600             $env->{myapp.customkey} = 'helloworld';
3601             $app->($env);
3602           },
3603         },
3604       ],
3605     );
3606
3607     __PACKAGE__->setup;
3608
3609 So the general form is:
3610
3611     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3612
3613 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3614 the order listed (to make it function similarly to L<Plack::Builder>:
3615
3616 =over 4
3617
3618 =item Middleware Object
3619
3620 An already initialized object that conforms to the L<Plack::Middleware>
3621 specification:
3622
3623     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3624
3625     __PACKAGE__->config(
3626       'psgi_middleware', [
3627         $stacktrace_middleware,
3628       ]);
3629
3630
3631 =item coderef
3632
3633 A coderef that is an inlined middleware:
3634
3635     __PACKAGE__->config(
3636       'psgi_middleware', [
3637         sub {
3638           my $app = shift;
3639           return sub {
3640             my $env = shift;
3641             if($env->{PATH_INFO} =~m/forced/) {
3642               Plack::App::File
3643                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3644                 ->call($env);
3645             } else {
3646               return $app->($env);
3647             }
3648          },
3649       },
3650     ]);
3651
3652
3653
3654 =item a scalar
3655
3656 We assume the scalar refers to a namespace after normalizing it using the
3657 following rules:
3658
3659 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3660 is assumed to be 'as is', and we just install and use the middleware.
3661
3662 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3663 (the package name of your Catalyst application subclass), we also assume then
3664 that it is a full namespace, and use it.
3665
3666 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3667 resolve it first by looking for it under your application namespace (for example
3668 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3669 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3670 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3671 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3672 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3673 you find that a good idea.
3674
3675 Examples:
3676
3677     package MyApp::Web;
3678
3679     __PACKAGE__->config(
3680       'psgi_middleware', [
3681         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3682         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3683         '+MyApp::Custom',  ## MyApp::Custom->wrap
3684       ],
3685     );
3686
3687 =item a scalar followed by a hashref
3688
3689 Just like the previous, except the following C<HashRef> is used as arguments
3690 to initialize the middleware object.
3691
3692     __PACKAGE__->config(
3693       'psgi_middleware', [
3694          'Session' => {store => 'File'},
3695     ]);
3696
3697 =back
3698
3699 Please see L<PSGI> for more on middleware.
3700
3701 =head1 ENCODING
3702
3703 On request, decodes all params from encoding into a sequence of
3704 logical characters. On response, encodes body into encoding.
3705
3706 =head2 Methods
3707
3708 =over 4
3709
3710 =item encoding
3711
3712 Returns an instance of an C<Encode> encoding
3713
3714     print $c->encoding->name
3715
3716 =item handle_unicode_encoding_exception ($exception_context)
3717
3718 Method called when decoding process for a request fails.
3719
3720 An C<$exception_context> hashref is provided to allow you to override the
3721 behaviour of your application when given data with incorrect encodings.
3722
3723 The default method throws exceptions in the case of invalid request parameters
3724 (resulting in a 500 error), but ignores errors in upload filenames.
3725
3726 The keys passed in the C<$exception_context> hash are:
3727
3728 =over
3729
3730 =item param_value
3731
3732 The value which was not able to be decoded.
3733
3734 =item error_msg
3735
3736 The exception received from L<Encode>.
3737
3738 =item encoding_step
3739
3740 What type of data was being decoded. Valid values are (currently)
3741 C<params> - for request parameters / arguments / captures
3742 and C<uploads> - for request upload filenames.
3743
3744 =back
3745
3746 =back
3747
3748 =head1 SUPPORT
3749
3750 IRC:
3751
3752     Join #catalyst on irc.perl.org.
3753
3754 Mailing Lists:
3755
3756     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3757     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3758
3759 Web:
3760
3761     http://catalyst.perl.org
3762
3763 Wiki:
3764
3765     http://dev.catalyst.perl.org
3766
3767 =head1 SEE ALSO
3768
3769 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3770
3771 =head2 L<Catalyst::Manual> - The Catalyst Manual
3772
3773 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3774
3775 =head2 L<Catalyst::Engine> - Core engine
3776
3777 =head2 L<Catalyst::Log> - Log class.
3778
3779 =head2 L<Catalyst::Request> - Request object
3780
3781 =head2 L<Catalyst::Response> - Response object
3782
3783 =head2 L<Catalyst::Test> - The test suite.
3784
3785 =head1 PROJECT FOUNDER
3786
3787 sri: Sebastian Riedel <sri@cpan.org>
3788
3789 =head1 CONTRIBUTORS
3790
3791 abw: Andy Wardley
3792
3793 acme: Leon Brocard <leon@astray.com>
3794
3795 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3796
3797 Andrew Bramble
3798
3799 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3800
3801 Andrew Ruthven
3802
3803 andyg: Andy Grundman <andy@hybridized.org>
3804
3805 audreyt: Audrey Tang
3806
3807 bricas: Brian Cassidy <bricas@cpan.org>
3808
3809 Caelum: Rafael Kitover <rkitover@io.com>
3810
3811 chansen: Christian Hansen
3812
3813 chicks: Christopher Hicks
3814
3815 Chisel Wright C<pause@herlpacker.co.uk>
3816
3817 Danijel Milicevic C<me@danijel.de>
3818
3819 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3820
3821 David Naughton, C<naughton@umn.edu>
3822
3823 David E. Wheeler
3824
3825 dhoss: Devin Austin <dhoss@cpan.org>
3826
3827 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3828
3829 Drew Taylor
3830
3831 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3832
3833 esskar: Sascha Kiefer
3834
3835 fireartist: Carl Franks <cfranks@cpan.org>
3836
3837 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3838
3839 gabb: Danijel Milicevic
3840
3841 Gary Ashton Jones
3842
3843 Gavin Henry C<ghenry@perl.me.uk>
3844
3845 Geoff Richards
3846
3847 groditi: Guillermo Roditi <groditi@gmail.com>
3848
3849 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3850
3851 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3852
3853 jcamacho: Juan Camacho
3854
3855 jester: Jesse Sheidlower C<jester@panix.com>
3856
3857 jhannah: Jay Hannah <jay@jays.net>
3858
3859 Jody Belka
3860
3861 Johan Lindstrom
3862
3863 jon: Jon Schutz <jjschutz@cpan.org>
3864
3865 Jonathan Rockway C<< <jrockway@cpan.org> >>
3866
3867 Kieren Diment C<kd@totaldatasolution.com>
3868
3869 konobi: Scott McWhirter <konobi@cpan.org>
3870
3871 marcus: Marcus Ramberg <mramberg@cpan.org>
3872
3873 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3874
3875 mgrimes: Mark Grimes <mgrimes@cpan.org>
3876
3877 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3878
3879 mugwump: Sam Vilain
3880
3881 naughton: David Naughton
3882
3883 ningu: David Kamholz <dkamholz@cpan.org>
3884
3885 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3886
3887 numa: Dan Sully <daniel@cpan.org>
3888
3889 obra: Jesse Vincent
3890
3891 Octavian Rasnita
3892
3893 omega: Andreas Marienborg
3894
3895 Oleg Kostyuk <cub.uanic@gmail.com>
3896
3897 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3898
3899 rafl: Florian Ragwitz <rafl@debian.org>
3900
3901 random: Roland Lammel <lammel@cpan.org>
3902
3903 Robert Sedlacek C<< <rs@474.at> >>
3904
3905 SpiceMan: Marcel Montes
3906
3907 sky: Arthur Bergman
3908
3909 szbalint: Balint Szilakszi <szbalint@cpan.org>
3910
3911 t0m: Tomas Doran <bobtfish@bobtfish.net>
3912
3913 Ulf Edvinsson
3914
3915 Viljo Marrandi C<vilts@yahoo.com>
3916
3917 Will Hawes C<info@whawes.co.uk>
3918
3919 willert: Sebastian Willert <willert@cpan.org>
3920
3921 wreis: Wallace Reis <wreis@cpan.org>
3922
3923 Yuval Kogman, C<nothingmuch@woobling.org>
3924
3925 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3926
3927 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3928
3929 =head1 COPYRIGHT
3930
3931 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3932
3933 =head1 LICENSE
3934
3935 This library is free software. You can redistribute it and/or modify it under
3936 the same terms as Perl itself.
3937
3938 =cut
3939
3940 no Moose;
3941
3942 __PACKAGE__->meta->make_immutable;
3943
3944 1;