lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use File::stat;
  19 use Text::SimpleTable ();
  20 use Path::Class::Dir ();
  21 use Path::Class::File ();
  22 use URI ();
  23 use URI::http;
  24 use URI::https;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use Class::C3::Adopt::NEXT;
  28 use List::MoreUtils qw/uniq/;
  29 use attributes;
  30 use String::RewritePrefix;
  31 use Catalyst::EngineLoader;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34 use Try::Tiny;
  35 use Safe::Isa;
  36 use Plack::Middleware::Conditional;
  37 use Plack::Middleware::ReverseProxy;
  38 use Plack::Middleware::IIS6ScriptNameFix;
  39 use Plack::Middleware::IIS7KeepAliveFix;
  40 use Plack::Middleware::LighttpdScriptNameFix;
  41
  42 BEGIN { require 5.008003; }
  43
  44 has stack => (is => 'ro', default => sub { [] });
  45 has stash => (is => 'rw', default => sub { {} });
  46 has state => (is => 'rw', default => 0);
  47 has stats => (is => 'rw');
  48 has action => (is => 'rw');
  49 has counter => (is => 'rw', default => sub { {} });
  50 has request => (
  51     is => 'rw',
  52     default => sub {
  53         my $self = shift;
  54         $self->request_class->new($self->_build_request_constructor_args);
  55     },
  56     lazy => 1,
  57 );
  58 sub _build_request_constructor_args {
  59     my $self = shift;
  60     my %p = ( _log => $self->log );
  61     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  62     \%p;
  63 }
  64
  65 has response => (
  66     is => 'rw',
  67     default => sub {
  68         my $self = shift;
  69         $self->response_class->new($self->_build_response_constructor_args);
  70     },
  71     lazy => 1,
  72 );
  73 sub _build_response_constructor_args {
  74     my $self = shift;
  75     { _log => $self->log };
  76 }
  77
  78 has namespace => (is => 'rw');
  79
  80 sub depth { scalar @{ shift->stack || [] }; }
  81 sub comp { shift->component(@_) }
  82
  83 sub req {
  84     my $self = shift; return $self->request(@_);
  85 }
  86 sub res {
  87     my $self = shift; return $self->response(@_);
  88 }
  89
  90 # For backwards compatibility
  91 sub finalize_output { shift->finalize_body(@_) };
  92
  93 # For statistics
  94 our $COUNT     = 1;
  95 our $START     = time;
  96 our $RECURSION = 1000;
  97 our $DETACH    = Catalyst::Exception::Detach->new;
  98 our $GO        = Catalyst::Exception::Go->new;
  99
 100 #I imagine that very few of these really need to be class variables. if any.
 101 #maybe we should just make them attributes with a default?
 102 __PACKAGE__->mk_classdata($_)
 103   for qw/container arguments dispatcher engine log dispatcher_class
 104   engine_loader context_class request_class response_class stats_class
 105   setup_finished _psgi_app loading_psgi_file run_options/;
 106
 107 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 108 __PACKAGE__->request_class('Catalyst::Request');
 109 __PACKAGE__->response_class('Catalyst::Response');
 110 __PACKAGE__->stats_class('Catalyst::Stats');
 111
 112 # Remember to update this in Catalyst::Runtime as well!
 113
 114 our $VERSION = '5.90017';
 115
 116 sub import {
 117     my ( $class, @arguments ) = @_;
 118
 119     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 120     # callers @ISA.
 121     return unless $class eq 'Catalyst';
 122
 123     my $caller = caller();
 124     return if $caller eq 'main';
 125
 126     my $meta = Moose::Meta::Class->initialize($caller);
 127
 128     unless ( $caller->isa('Catalyst') ) { # XXX - Remove!
 129         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Component'); # XXX - Remove!
 130         $meta->superclasses(@superclasses); # XXX - Remove!
 131     } # XXX - Remove!
 132
 133     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 134     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 135
 136     unless( $meta->has_method('meta') ){
 137         if ($Moose::VERSION >= 1.15) {
 138             $meta->_add_meta_method('meta');
 139         }
 140         else {
 141             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 142         }
 143     }
 144
 145     $caller->arguments( [@arguments] );
 146
 147     # FIXME
 148     # what is this for?
 149     # we call setup_home on import AND on ->setup
 150     # is there a reason for it?
 151     # anyway there is no point for setup_home without setup_config() so...
 152     $caller->setup_config;
 153     $caller->setup_home;
 154 }
 155
 156 sub MODIFY_CODE_ATTRIBUTES {
 157     Catalyst::Exception->throw(
 158         "Catalyst applications (aka MyApp) cannot be controllers anymore. " .
 159         "That has been deprecated and removed. You should create a " .
 160         "controller class called Root.pm, and move relevant code to that class."
 161     );
 162 }
 163
 164
 165 sub _application { $_[0] }
 166
 167 =encoding UTF-8
 168
 169 =head1 NAME
 170
 171 Catalyst - The Elegant MVC Web Application Framework
 172
 173 =head1 SYNOPSIS
 174
 175 See the L<Catalyst::Manual> distribution for comprehensive
 176 documentation and tutorials.
 177
 178     # Install Catalyst::Devel for helpers and other development tools
 179     # use the helper to create a new application
 180     catalyst.pl MyApp
 181
 182     # add models, views, controllers
 183     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 184     script/myapp_create.pl view MyTemplate TT
 185     script/myapp_create.pl controller Search
 186
 187     # built in testserver -- use -r to restart automatically on changes
 188     # --help to see all available options
 189     script/myapp_server.pl
 190
 191     # command line testing interface
 192     script/myapp_test.pl /yada
 193
 194     ### in lib/MyApp.pm
 195     use Catalyst qw/-Debug/; # include plugins here as well
 196
 197     ### In lib/MyApp/Controller/Root.pm (autocreated)
 198     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 199         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 200         $c->stash->{template} = 'foo.tt'; # set the template
 201         # lookup something from db -- stash vars are passed to TT
 202         $c->stash->{data} =
 203           $c->model('Database::Foo')->search( { country => $args[0] } );
 204         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 205             $c->forward( 'bar' ); # process another action
 206             # do something else after forward returns
 207         }
 208     }
 209
 210     # The foo.tt TT template can use the stash data from the database
 211     [% WHILE (item = data.next) %]
 212         [% item.foo %]
 213     [% END %]
 214
 215     # called for /bar/of/soap, /bar/of/soap/10, etc.
 216     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 217
 218     # called after all actions are finished
 219     sub end : Action {
 220         my ( $self, $c ) = @_;
 221         if ( scalar @{ $c->error } ) { ... } # handle errors
 222         return if $c->res->body; # already have a response
 223         $c->forward( 'MyApp::View::TT' ); # render template
 224     }
 225
 226 See L<Catalyst::Manual::Intro> for additional information.
 227
 228 =head1 DESCRIPTION
 229
 230 Catalyst is a modern framework for making web applications without the
 231 pain usually associated with this process. This document is a reference
 232 to the main Catalyst application. If you are a new user, we suggest you
 233 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 234
 235 See L<Catalyst::Manual> for more documentation.
 236
 237 Catalyst plugins can be loaded by naming them as arguments to the "use
 238 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 239 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 240 C<My::Module>.
 241
 242     use Catalyst qw/My::Module/;
 243
 244 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 245 fully qualify the name by using a unary plus:
 246
 247     use Catalyst qw/
 248         My::Module
 249         +Fully::Qualified::Plugin::Name
 250     /;
 251
 252 Special flags like C<-Debug> can also be specified as
 253 arguments when Catalyst is loaded:
 254
 255     use Catalyst qw/-Debug My::Module/;
 256
 257 The position of plugins and flags in the chain is important, because
 258 they are loaded in the order in which they appear.
 259
 260 The following flags are supported:
 261
 262 =head2 -Debug
 263
 264 Enables debug output. You can also force this setting from the system
 265 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 266 settings override the application, with <MYAPP>_DEBUG having the highest
 267 priority.
 268
 269 This sets the log level to 'debug' and enables full debug output on the
 270 error screen. If you only want the latter, see L<< $c->debug >>.
 271
 272 =head2 -Home
 273
 274 Forces Catalyst to use a specific home directory, e.g.:
 275
 276     use Catalyst qw[-Home=/usr/mst];
 277
 278 This can also be done in the shell environment by setting either the
 279 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 280 is replaced with the uppercased name of your application, any "::" in
 281 the name will be replaced with underscores, e.g. MyApp::Web should use
 282 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 283
 284 If none of these are set, Catalyst will attempt to automatically detect the
 285 home directory. If you are working in a development environment, Catalyst
 286 will try and find the directory containing either Makefile.PL, Build.PL or
 287 dist.ini. If the application has been installed into the system (i.e.
 288 you have done C<make install>), then Catalyst will use the path to your
 289 application module, without the .pm extension (e.g., /foo/MyApp if your
 290 application was installed at /foo/MyApp.pm)
 291
 292 =head2 -Log
 293
 294     use Catalyst '-Log=warn,fatal,error';
 295
 296 Specifies a comma-delimited list of log levels.
 297
 298 =head2 -Stats
 299
 300 Enables statistics collection and reporting.
 301
 302    use Catalyst qw/-Stats=1/;
 303
 304 You can also force this setting from the system environment with CATALYST_STATS
 305 or <MYAPP>_STATS. The environment settings override the application, with
 306 <MYAPP>_STATS having the highest priority.
 307
 308 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 309
 310 =head1 METHODS
 311
 312 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 313
 314 =head2 $c->action
 315
 316 Returns a L<Catalyst::Action> object for the current action, which
 317 stringifies to the action name. See L<Catalyst::Action>.
 318
 319 =head2 $c->namespace
 320
 321 Returns the namespace of the current action, i.e., the URI prefix
 322 corresponding to the controller of the current action. For example:
 323
 324     # in Controller::Foo::Bar
 325     $c->namespace; # returns 'foo/bar';
 326
 327 =head2 $c->request
 328
 329 =head2 $c->req
 330
 331 Returns the current L<Catalyst::Request> object, giving access to
 332 information about the current client request (including parameters,
 333 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 334
 335 =head2 REQUEST FLOW HANDLING
 336
 337 =head2 $c->forward( $action [, \@arguments ] )
 338
 339 =head2 $c->forward( $class, $method, [, \@arguments ] )
 340
 341 Forwards processing to another action, by its private name. If you give a
 342 class name but no method, C<process()> is called. You may also optionally
 343 pass arguments in an arrayref. The action will receive the arguments in
 344 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 345 C<< $c->req->args >> will be restored to the previous values.
 346
 347 Any data C<return>ed from the action forwarded to, will be returned by the
 348 call to forward.
 349
 350     my $foodata = $c->forward('/foo');
 351     $c->forward('index');
 352     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 353     $c->forward('View::TT');
 354
 355 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 356 an C<< eval { } >> around the call (actually
 357 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 358 exceptions thrown by the called action non-fatal and pushing them onto
 359 $c->error instead. If you want C<die> to propagate you need to do something
 360 like:
 361
 362     $c->forward('foo');
 363     die join "\n", @{ $c->error } if @{ $c->error };
 364
 365 Or make sure to always return true values from your actions and write
 366 your code like this:
 367
 368     $c->forward('foo') || return;
 369
 370 Another note is that C<< $c->forward >> always returns a scalar because it
 371 actually returns $c->state which operates in a scalar context.
 372 Thus, something like:
 373
 374     return @array;
 375
 376 in an action that is forwarded to is going to return a scalar,
 377 i.e. how many items are in that array, which is probably not what you want.
 378 If you need to return an array then return a reference to it,
 379 or stash it like so:
 380
 381     $c->stash->{array} = \@array;
 382
 383 and access it from the stash.
 384
 385 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 386
 387 =cut
 388
 389 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 390
 391 =head2 $c->detach( $action [, \@arguments ] )
 392
 393 =head2 $c->detach( $class, $method, [, \@arguments ] )
 394
 395 =head2 $c->detach()
 396
 397 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 398 doesn't return to the previous action when processing is finished.
 399
 400 When called with no arguments it escapes the processing chain entirely.
 401
 402 =cut
 403
 404 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 405
 406 =head2 $c->visit( $action [, \@arguments ] )
 407
 408 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 409
 410 =head2 $c->visit( $class, $method, [, \@arguments ] )
 411
 412 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 413
 414 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 415 but does a full dispatch, instead of just calling the new C<$action> /
 416 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 417 you go to are called, just like a new request.
 418
 419 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 420 This means, for example, that C<< $c->action >> methods such as
 421 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 422 L<reverse|Catalyst::Action/reverse> return information for the visited action
 423 when they are invoked within the visited action.  This is different from the
 424 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 425 continues to use the $c->action object from the caller action even when
 426 invoked from the called action.
 427
 428 C<< $c->stash >> is kept unchanged.
 429
 430 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 431 allows you to "wrap" another action, just as it would have been called by
 432 dispatching from a URL, while the analogous
 433 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 434 transfer control to another action as if it had been reached directly from a URL.
 435
 436 =cut
 437
 438 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 439
 440 =head2 $c->go( $action [, \@arguments ] )
 441
 442 =head2 $c->go( $action [, \@captures, \@arguments ] )
 443
 444 =head2 $c->go( $class, $method, [, \@arguments ] )
 445
 446 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 447
 448 The relationship between C<go> and
 449 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 450 the relationship between
 451 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 452 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 453 C<< $c->go >> will perform a full dispatch on the specified action or method,
 454 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 455 C<go> escapes the processing of the current request chain on completion, and
 456 does not return to its caller.
 457
 458 @arguments are arguments to the final destination of $action. @captures are
 459 arguments to the intermediate steps, if any, on the way to the final sub of
 460 $action.
 461
 462 =cut
 463
 464 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 465
 466 =head2 $c->response
 467
 468 =head2 $c->res
 469
 470 Returns the current L<Catalyst::Response> object, see there for details.
 471
 472 =head2 $c->stash
 473
 474 Returns a hashref to the stash, which may be used to store data and pass
 475 it between components during a request. You can also set hash keys by
 476 passing arguments. The stash is automatically sent to the view. The
 477 stash is cleared at the end of a request; it cannot be used for
 478 persistent storage (for this you must use a session; see
 479 L<Catalyst::Plugin::Session> for a complete system integrated with
 480 Catalyst).
 481
 482     $c->stash->{foo} = $bar;
 483     $c->stash( { moose => 'majestic', qux => 0 } );
 484     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 485
 486     # stash is automatically passed to the view for use in a template
 487     $c->forward( 'MyApp::View::TT' );
 488
 489 =cut
 490
 491 around stash => sub {
 492     my $orig = shift;
 493     my $c = shift;
 494     my $stash = $orig->($c);
 495     if (@_) {
 496         my $new_stash = @_ > 1 ? {@_} : $_[0];
 497         croak('stash takes a hash or hashref') unless ref $new_stash;
 498         foreach my $key ( keys %$new_stash ) {
 499           $stash->{$key} = $new_stash->{$key};
 500         }
 501     }
 502
 503     return $stash;
 504 };
 505
 506
 507 =head2 $c->error
 508
 509 =head2 $c->error($error, ...)
 510
 511 =head2 $c->error($arrayref)
 512
 513 Returns an arrayref containing error messages.  If Catalyst encounters an
 514 error while processing a request, it stores the error in $c->error.  This
 515 method should only be used to store fatal error messages.
 516
 517     my @error = @{ $c->error };
 518
 519 Add a new error.
 520
 521     $c->error('Something bad happened');
 522
 523 =cut
 524
 525 sub error {
 526     my $c = shift;
 527     if ( $_[0] ) {
 528         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 529         croak @$error unless ref $c;
 530         push @{ $c->{error} }, @$error;
 531     }
 532     elsif ( defined $_[0] ) { $c->{error} = undef }
 533     return $c->{error} || [];
 534 }
 535
 536
 537 =head2 $c->state
 538
 539 Contains the return value of the last executed action.
 540 Note that << $c->state >> operates in a scalar context which means that all
 541 values it returns are scalar.
 542
 543 =head2 $c->clear_errors
 544
 545 Clear errors.  You probably don't want to clear the errors unless you are
 546 implementing a custom error screen.
 547
 548 This is equivalent to running
 549
 550     $c->error(0);
 551
 552 =cut
 553
 554 sub clear_errors {
 555     my $c = shift;
 556     $c->error(0);
 557 }
 558
 559 =head2 COMPONENT ACCESSORS
 560
 561 =head2 $c->controller($name)
 562
 563 Gets a L<Catalyst::Controller> instance by name.
 564
 565     $c->controller('Foo')->do_stuff;
 566
 567 If the name is omitted, will return the controller for the dispatched
 568 action.
 569
 570 If you want to search for controllers, pass in a regexp as the argument.
 571
 572     # find all controllers that start with Foo
 573     my @foo_controllers = $c->controller(qr{^Foo});
 574
 575
 576 =cut
 577
 578 sub controller { shift->_lookup_mvc('controller', @_) }
 579
 580 =head2 $c->model($name)
 581
 582 Gets a L<Catalyst::Model> instance by name.
 583
 584     $c->model('Foo')->do_stuff;
 585
 586 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 587
 588 If the name is omitted, it will look for
 589  - a model object in $c->stash->{current_model_instance}, then
 590  - a model name in $c->stash->{current_model}, then
 591  - a config setting 'default_model', or
 592  - check if there is only one model, and return it if that's the case.
 593
 594 If you want to search for models, pass in a regexp as the argument.
 595
 596     # find all models that start with Foo
 597     my @foo_models = $c->model(qr{^Foo});
 598
 599 =cut
 600
 601 sub model { shift->_lookup_mvc('model', @_) }
 602
 603 =head2 $c->view($name)
 604
 605 Gets a L<Catalyst::View> instance by name.
 606
 607     $c->view('Foo')->do_stuff;
 608
 609 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 610
 611 If the name is omitted, it will look for
 612  - a view object in $c->stash->{current_view_instance}, then
 613  - a view name in $c->stash->{current_view}, then
 614  - a config setting 'default_view', or
 615  - check if there is only one view, and return it if that's the case.
 616
 617 If you want to search for views, pass in a regexp as the argument.
 618
 619     # find all views that start with Foo
 620     my @foo_views = $c->view(qr{^Foo});
 621
 622 =cut
 623
 624 sub view { shift->_lookup_mvc('view', @_) }
 625
 626 sub _lookup_mvc {
 627     my ( $c, $type, $name, @args ) = @_;
 628
 629     if (ref $c && !$name) {
 630         my $current_instance = $c->stash->{"current_${type}_instance"};
 631         return $current_instance
 632             if $current_instance && $type ne 'controller';
 633
 634         $name = $type eq 'controller'
 635               ? Catalyst::Utils::class2classshortsuffix($c->action->class)
 636               : $c->stash->{"current_${type}"}
 637               ;
 638     }
 639
 640     return $c->container->get_component_from_sub_container($type, $name, $c, @args);
 641 }
 642
 643 =head2 $c->controllers
 644
 645 Returns the available names which can be passed to $c->controller
 646
 647 =cut
 648
 649 sub controllers {
 650     my ( $c ) = @_;
 651     return $c->container->get_sub_container('controller')->get_service_list;
 652 }
 653
 654 =head2 $c->models
 655
 656 Returns the available names which can be passed to $c->model
 657
 658 =cut
 659
 660 sub models {
 661     my ( $c ) = @_;
 662     return $c->container->get_sub_container('model')->get_service_list;
 663 }
 664
 665
 666 =head2 $c->views
 667
 668 Returns the available names which can be passed to $c->view
 669
 670 =cut
 671
 672 sub views {
 673     my ( $c ) = @_;
 674     return $c->container->get_sub_container('view')->get_service_list;
 675 }
 676
 677 =head2 $c->comp($name)
 678
 679 =head2 $c->component($name)
 680
 681 Gets a component object by name. This method is not recommended,
 682 unless you want to get a specific component by full
 683 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 684 should be used instead.
 685
 686 If C<$name> is a regexp, a list of components matched against the full
 687 component name will be returned.
 688
 689 =cut
 690
 691 sub component {
 692     my ( $c, $component, @args ) = @_;
 693
 694     unless ($component) {
 695         $c->log->warn('Calling $c->component with no args is deprecated and ');
 696         $c->log->warn('will be removed in a future release.');
 697         $c->log->warn('Use $c->component_list instead.');
 698         return $c->component_list;
 699     }
 700
 701     my @result = $c->container->find_component( $component, $c, @args );
 702
 703     # list context for regexp searches
 704     return @result if ref $component;
 705
 706     # only one component (if it's found) for string searches
 707     return shift @result if @result;
 708
 709     if (ref $c eq $component) {
 710         $c->log->warn('You are calling $c->comp("MyApp"). This behaviour is');
 711         $c->log->warn('deprecated, and will be removed in a future release.');
 712         return $c;
 713     }
 714
 715     $c->log->warn("Looking for '$component', but nothing was found.");
 716
 717     # I would expect to return an empty list here, but that breaks back-compat
 718     $c->log->warn('Component not found, returning the list of existing');
 719     $c->log->warn('components. This behavior is deprecated and will be');
 720     $c->log->warn('removed in a future release. Use $c->component_list');
 721     $c->log->warn('instead.');
 722
 723     return $c->component_list;
 724 }
 725
 726 =head2 $c->component_list
 727
 728 Returns the sorted list of the component names of the application.
 729
 730 =cut
 731
 732 sub component_list { sort keys %{ shift->components } }
 733
 734 =head2 CLASS DATA AND HELPER CLASSES
 735
 736 =head2 $c->config
 737
 738 Returns or takes a hashref containing the application's configuration.
 739
 740     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 741
 742 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 743 like C<myapp.conf> in your applications home directory. See
 744 L<Catalyst::Plugin::ConfigLoader>.
 745
 746 =head3 Cascading configuration
 747
 748 The config method is present on all Catalyst components, and configuration
 749 will be merged when an application is started. Configuration loaded with
 750 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 751 followed by configuration in your top level C<MyApp> class. These two
 752 configurations are merged, and then configuration data whose hash key matches a
 753 component name is merged with configuration for that component.
 754
 755 The configuration for a component is then passed to the C<new> method when a
 756 component is constructed.
 757
 758 For example:
 759
 760     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 761     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 762
 763 will mean that C<MyApp::Model::Foo> receives the following data when
 764 constructed:
 765
 766     MyApp::Model::Foo->new({
 767         bar => 'baz',
 768         quux => 'frob',
 769         overrides => 'me',
 770     });
 771
 772 It's common practice to use a Moose attribute
 773 on the receiving component to access the config value.
 774
 775     package MyApp::Model::Foo;
 776
 777     use Moose;
 778
 779     # this attr will receive 'baz' at construction time
 780     has 'bar' => (
 781         is  => 'rw',
 782         isa => 'Str',
 783     );
 784
 785 You can then get the value 'baz' by calling $c->model('Foo')->bar
 786 (or $self->bar inside code in the model).
 787
 788 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 789 as a way of reading config within your code, as this B<will not> give you the
 790 correctly merged config back. You B<MUST> take the config values supplied to
 791 the constructor and use those instead.
 792
 793 =cut
 794
 795 around config => sub {
 796     my $orig = shift;
 797     my $c = shift;
 798
 799     croak('Setting config after setup has been run is not allowed.')
 800         if ( @_ and $c->setup_finished );
 801
 802     $c->$orig(@_);
 803 };
 804
 805 =head2 $c->log
 806
 807 Returns the logging object instance. Unless it is already set, Catalyst
 808 sets this up with a L<Catalyst::Log> object. To use your own log class,
 809 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 810 C<< __PACKAGE__->setup >>.
 811
 812  __PACKAGE__->log( MyLogger->new );
 813  __PACKAGE__->setup;
 814
 815 And later:
 816
 817     $c->log->info( 'Now logging with my own logger!' );
 818
 819 Your log class should implement the methods described in
 820 L<Catalyst::Log>.
 821
 822
 823 =head2 $c->debug
 824
 825 Returns 1 if debug mode is enabled, 0 otherwise.
 826
 827 You can enable debug mode in several ways:
 828
 829 =over
 830
 831 =item By calling myapp_server.pl with the -d flag
 832
 833 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 834
 835 =item The -Debug option in your MyApp.pm
 836
 837 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 838
 839 =back
 840
 841 The first three also set the log level to 'debug'.
 842
 843 Calling C<< $c->debug(1) >> has no effect.
 844
 845 =cut
 846
 847 sub debug { 0 }
 848
 849 =head2 $c->dispatcher
 850
 851 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 852
 853 =head2 $c->engine
 854
 855 Returns the engine instance. See L<Catalyst::Engine>.
 856
 857
 858 =head2 UTILITY METHODS
 859
 860 =head2 $c->path_to(@path)
 861
 862 Merges C<@path> with C<< $c->config->{home} >> and returns a
 863 L<Path::Class::Dir> object. Note you can usually use this object as
 864 a filename, but sometimes you will have to explicitly stringify it
 865 yourself by calling the C<< ->stringify >> method.
 866
 867 For example:
 868
 869     $c->path_to( 'db', 'sqlite.db' );
 870
 871 =cut
 872
 873 sub path_to {
 874     my ( $c, @path ) = @_;
 875     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 876     if ( -d $path ) { return $path }
 877     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 878 }
 879
 880 sub plugin {
 881     my ( $class, $name, $plugin, @args ) = @_;
 882
 883     # See block comment in t/aggregate/unit_core_plugin.t
 884     # See block comment in t/unit_core_plugin.t
 885     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
 886
 887     $class->_register_plugin( $plugin, 1 );
 888
 889     eval { $plugin->import };
 890     $class->mk_classdata($name);
 891     my $obj;
 892     eval { $obj = $plugin->new(@args) };
 893
 894     if ($@) {
 895         Catalyst::Exception->throw( message =>
 896               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 897     }
 898
 899     $class->$name($obj);
 900     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 901       if $class->debug;
 902 }
 903
 904 =head2 MyApp->setup
 905
 906 Initializes the dispatcher and engine, loads any plugins, and loads the
 907 model, view, and controller components. You may also specify an array
 908 of plugins to load here, if you choose to not load them in the C<use
 909 Catalyst> line.
 910
 911     MyApp->setup;
 912     MyApp->setup( qw/-Debug/ );
 913
 914 B<Note:> You B<should not> wrap this method with method modifiers
 915 or bad things will happen - wrap the C<setup_finalize> method instead.
 916
 917 =cut
 918
 919 sub setup {
 920     my ( $class, @arguments ) = @_;
 921     croak('Running setup more than once')
 922         if ( $class->setup_finished );
 923
 924     unless ( $class->isa('Catalyst') ) {
 925
 926         Catalyst::Exception->throw(
 927             message => qq/'$class' does not inherit from Catalyst/ );
 928     }
 929
 930     if ( $class->arguments ) {
 931         @arguments = ( @arguments, @{ $class->arguments } );
 932     }
 933
 934     # Process options
 935     my $flags = {};
 936
 937     foreach (@arguments) {
 938
 939         if (/^-Debug$/) {
 940             $flags->{log} =
 941               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 942         }
 943         elsif (/^-(\w+)=?(.*)$/) {
 944             $flags->{ lc $1 } = $2;
 945         }
 946         else {
 947             push @{ $flags->{plugins} }, $_;
 948         }
 949     }
 950
 951     $class->setup_config();
 952     $class->setup_home( delete $flags->{home} );
 953
 954     $class->setup_log( delete $flags->{log} );
 955     $class->setup_plugins( delete $flags->{plugins} );
 956     $class->setup_dispatcher( delete $flags->{dispatcher} );
 957     if (my $engine = delete $flags->{engine}) {
 958         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
 959     }
 960     $class->setup_engine();
 961     $class->setup_stats( delete $flags->{stats} );
 962
 963     for my $flag ( sort keys %{$flags} ) {
 964
 965         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 966             &$code( $class, delete $flags->{$flag} );
 967         }
 968         else {
 969             $class->log->warn(qq/Unknown flag "$flag"/);
 970         }
 971     }
 972
 973     eval { require Catalyst::Devel; };
 974     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 975         $class->log->warn(<<"EOF");
 976 You are running an old script!
 977
 978   Please update by running (this will overwrite existing files):
 979     catalyst.pl -force -scripts $class
 980
 981   or (this will not overwrite existing files):
 982     catalyst.pl -scripts $class
 983
 984 EOF
 985     }
 986
 987     if ( $class->debug ) {
 988         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 989
 990         if (@plugins) {
 991             my $column_width = Catalyst::Utils::term_width() - 6;
 992             my $t = Text::SimpleTable->new($column_width);
 993             $t->row($_) for @plugins;
 994             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 995         }
 996
 997         my $dispatcher = $class->dispatcher;
 998         my $engine     = $class->engine;
 999         my $home       = $class->config->{home};
1000
1001         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1002         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1003
1004         $home
1005           ? ( -d $home )
1006           ? $class->log->debug(qq/Found home "$home"/)
1007           : $class->log->debug(qq/Home "$home" doesn't exist/)
1008           : $class->log->debug(q/Couldn't find home/);
1009     }
1010
1011     # Call plugins setup, this is stupid and evil.
1012     # Also screws C3 badly on 5.10, hack to avoid.
1013     {
1014         no warnings qw/redefine/;
1015         local *setup = sub { };
1016         $class->setup unless $Catalyst::__AM_RESTARTING;
1017     }
1018
1019     $class->setup_components;
1020
1021     if (
1022         $class->debug and
1023         my $comps = $class->container->get_all_component_services($class)
1024     ) {
1025         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1026         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Lifecycle' ] );
1027
1028         # FIXME
1029         # I don't really know what we're going to show here
1030         while (my ($class, $info) = each %$comps) {
1031             my $lifecycle = $info->{backcompat_service}
1032                           ? $info->{backcompat_service}->lifecycle
1033                           : $info->{service}->lifecycle
1034                           ;
1035             $t->row( $class, $lifecycle );
1036         }
1037
1038         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" );
1039     }
1040
1041     $class->setup_actions;
1042
1043     if ( $class->debug ) {
1044         my $name = $class->config->{name} || 'Application';
1045         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1046     }
1047
1048     if ($class->config->{case_sensitive}) {
1049         $class->log->warn($class . "->config->{case_sensitive} is set.");
1050         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1051     }
1052
1053     $class->setup_finalize;
1054     # Should be the last thing we do so that user things hooking
1055     # setup_finalize can log..
1056     $class->log->_flush() if $class->log->can('_flush');
1057     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1058 }
1059
1060 =head2 $app->setup_finalize
1061
1062 A hook to attach modifiers to. This method does not do anything except set the
1063 C<setup_finished> accessor.
1064
1065 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1066
1067 Example:
1068
1069     after setup_finalize => sub {
1070         my $app = shift;
1071
1072         ## do stuff here..
1073     };
1074
1075 =cut
1076
1077 sub setup_finalize {
1078     my ($class) = @_;
1079     $class->setup_finished(1);
1080 }
1081
1082 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1083
1084 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1085
1086 Constructs an absolute L<URI> object based on the application root, the
1087 provided path, and the additional arguments and query parameters provided.
1088 When used as a string, provides a textual URI.  If you need more flexibility
1089 than this (i.e. the option to provide relative URIs etc.) see
1090 L<Catalyst::Plugin::SmartURI>.
1091
1092 If no arguments are provided, the URI for the current action is returned.
1093 To return the current action and also provide @args, use
1094 C<< $c->uri_for( $c->action, @args ) >>.
1095
1096 If the first argument is a string, it is taken as a public URI path relative
1097 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1098 relative to the application root (if it does). It is then merged with
1099 C<< $c->request->base >>; any C<@args> are appended as additional path
1100 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1101
1102 If the first argument is a L<Catalyst::Action> it represents an action which
1103 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1104 optional C<\@captures> argument (an arrayref) allows passing the captured
1105 variables that are needed to fill in the paths of Chained and Regex actions;
1106 once the path is resolved, C<uri_for> continues as though a path was
1107 provided, appending any arguments or parameters and creating an absolute
1108 URI.
1109
1110 The captures for the current request can be found in
1111 C<< $c->request->captures >>, and actions can be resolved using
1112 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1113 path, use C<< $c->uri_for_action >> instead.
1114
1115   # Equivalent to $c->req->uri
1116   $c->uri_for($c->action, $c->req->captures,
1117       @{ $c->req->args }, $c->req->params);
1118
1119   # For the Foo action in the Bar controller
1120   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1121
1122   # Path to a static resource
1123   $c->uri_for('/static/images/logo.png');
1124
1125 =cut
1126
1127 sub uri_for {
1128     my ( $c, $path, @args ) = @_;
1129
1130     if ( $path->$_isa('Catalyst::Controller') ) {
1131         $path = $path->path_prefix;
1132         $path =~ s{/+\z}{};
1133         $path .= '/';
1134     }
1135
1136     undef($path) if (defined $path && $path eq '');
1137
1138     my $params =
1139       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1140
1141     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1142     foreach my $arg (@args) {
1143         utf8::encode($arg) if utf8::is_utf8($arg);
1144         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1145     }
1146
1147     if ( $path->$_isa('Catalyst::Action') ) { # action object
1148         s|/|%2F|g for @args;
1149         my $captures = [ map { s|/|%2F|g; $_; }
1150                         ( scalar @args && ref $args[0] eq 'ARRAY'
1151                          ? @{ shift(@args) }
1152                          : ()) ];
1153
1154         foreach my $capture (@$captures) {
1155             utf8::encode($capture) if utf8::is_utf8($capture);
1156             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1157         }
1158
1159         my $action = $path;
1160         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1161         if( !@args && $action->number_of_args ) {
1162             my $expanded_action = $c->dispatcher->expand_action( $action );
1163
1164             my $num_captures = $expanded_action->number_of_captures;
1165             unshift @args, splice @$captures, $num_captures;
1166         }
1167
1168        $path = $c->dispatcher->uri_for_action($action, $captures);
1169         if (not defined $path) {
1170             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1171                 if $c->debug;
1172             return undef;
1173         }
1174         $path = '/' if $path eq '';
1175     }
1176
1177     unshift(@args, $path);
1178
1179     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1180         my $namespace = $c->namespace;
1181         if (defined $path) { # cheesy hack to handle path '../foo'
1182            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1183         }
1184         unshift(@args, $namespace || '');
1185     }
1186
1187     # join args with '/', or a blank string
1188     my $args = join('/', grep { defined($_) } @args);
1189     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1190     $args =~ s!^/+!!;
1191     my $base = $c->req->base;
1192     my $class = ref($base);
1193     $base =~ s{(?<!/)$}{/};
1194
1195     my $query = '';
1196
1197     if (my @keys = keys %$params) {
1198       # somewhat lifted from URI::_query's query_form
1199       $query = '?'.join('&', map {
1200           my $val = $params->{$_};
1201           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1202           s/ /+/g;
1203           my $key = $_;
1204           $val = '' unless defined $val;
1205           (map {
1206               my $param = "$_";
1207               utf8::encode( $param ) if utf8::is_utf8($param);
1208               # using the URI::Escape pattern here so utf8 chars survive
1209               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1210               $param =~ s/ /+/g;
1211               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1212       } @keys);
1213     }
1214
1215     my $res = bless(\"${base}${args}${query}", $class);
1216     $res;
1217 }
1218
1219 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1220
1221 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1222
1223 =over
1224
1225 =item $path
1226
1227 A private path to the Catalyst action you want to create a URI for.
1228
1229 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1230 >> and passing the resulting C<$action> and the remaining arguments to C<<
1231 $c->uri_for >>.
1232
1233 You can also pass in a Catalyst::Action object, in which case it is passed to
1234 C<< $c->uri_for >>.
1235
1236 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1237
1238 For example, if the action looks like:
1239
1240  package MyApp::Controller::Users;
1241
1242  sub lst : Path('the-list') {}
1243
1244 You can use:
1245
1246  $c->uri_for_action('/users/lst')
1247
1248 and it will create the URI /users/the-list.
1249
1250 =item \@captures_and_args?
1251
1252 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1253 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1254 to interpolate all the parameters in the URI.
1255
1256 =item @args?
1257
1258 Optional list of extra arguments - can be supplied in the
1259 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1260 code.
1261
1262 Your action can have zero, a fixed or a variable number of args (e.g.
1263 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1264
1265 =item \%query_values?
1266
1267 Optional array reference of query parameters to append. E.g.
1268
1269   { foo => 'bar' }
1270
1271 will generate
1272
1273   /rest/of/your/uri?foo=bar
1274
1275 =back
1276
1277 =cut
1278
1279 sub uri_for_action {
1280     my ( $c, $path, @args ) = @_;
1281     my $action = blessed($path)
1282       ? $path
1283       : $c->dispatcher->get_action_by_path($path);
1284     unless (defined $action) {
1285       croak "Can't find action for path '$path'";
1286     }
1287     return $c->uri_for( $action, @args );
1288 }
1289
1290 =head2 $c->welcome_message
1291
1292 Returns the Catalyst welcome HTML page.
1293
1294 =cut
1295
1296 sub welcome_message {
1297     my $c      = shift;
1298     my $name   = $c->config->{name};
1299     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1300     my $prefix = Catalyst::Utils::appprefix( ref $c );
1301     $c->response->content_type('text/html; charset=utf-8');
1302     return <<"EOF";
1303 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1304     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1305 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1306     <head>
1307     <meta http-equiv="Content-Language" content="en" />
1308     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1309         <title>$name on Catalyst $VERSION</title>
1310         <style type="text/css">
1311             body {
1312                 color: #000;
1313                 background-color: #eee;
1314             }
1315             div#content {
1316                 width: 640px;
1317                 margin-left: auto;
1318                 margin-right: auto;
1319                 margin-top: 10px;
1320                 margin-bottom: 10px;
1321                 text-align: left;
1322                 background-color: #ccc;
1323                 border: 1px solid #aaa;
1324             }
1325             p, h1, h2 {
1326                 margin-left: 20px;
1327                 margin-right: 20px;
1328                 font-family: verdana, tahoma, sans-serif;
1329             }
1330             a {
1331                 font-family: verdana, tahoma, sans-serif;
1332             }
1333             :link, :visited {
1334                     text-decoration: none;
1335                     color: #b00;
1336                     border-bottom: 1px dotted #bbb;
1337             }
1338             :link:hover, :visited:hover {
1339                     color: #555;
1340             }
1341             div#topbar {
1342                 margin: 0px;
1343             }
1344             pre {
1345                 margin: 10px;
1346                 padding: 8px;
1347             }
1348             div#answers {
1349                 padding: 8px;
1350                 margin: 10px;
1351                 background-color: #fff;
1352                 border: 1px solid #aaa;
1353             }
1354             h1 {
1355                 font-size: 0.9em;
1356                 font-weight: normal;
1357                 text-align: center;
1358             }
1359             h2 {
1360                 font-size: 1.0em;
1361             }
1362             p {
1363                 font-size: 0.9em;
1364             }
1365             p img {
1366                 float: right;
1367                 margin-left: 10px;
1368             }
1369             span#appname {
1370                 font-weight: bold;
1371                 font-size: 1.6em;
1372             }
1373         </style>
1374     </head>
1375     <body>
1376         <div id="content">
1377             <div id="topbar">
1378                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1379                     $VERSION</h1>
1380              </div>
1381              <div id="answers">
1382                  <p>
1383                  <img src="$logo" alt="Catalyst Logo" />
1384                  </p>
1385                  <p>Welcome to the  world of Catalyst.
1386                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1387                     framework will make web development something you had
1388                     never expected it to be: Fun, rewarding, and quick.</p>
1389                  <h2>What to do now?</h2>
1390                  <p>That really depends  on what <b>you</b> want to do.
1391                     We do, however, provide you with a few starting points.</p>
1392                  <p>If you want to jump right into web development with Catalyst
1393                     you might want to start with a tutorial.</p>
1394 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1395 </pre>
1396 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1397 <pre>
1398 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1399 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1400 </code></pre>
1401                  <h2>What to do next?</h2>
1402                  <p>Next it's time to write an actual application. Use the
1403                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1404                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1405                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1406                     they can save you a lot of work.</p>
1407                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1408                     <p>Also, be sure to check out the vast and growing
1409                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1410                     you are likely to find what you need there.
1411                     </p>
1412
1413                  <h2>Need help?</h2>
1414                  <p>Catalyst has a very active community. Here are the main places to
1415                     get in touch with us.</p>
1416                  <ul>
1417                      <li>
1418                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1419                      </li>
1420                      <li>
1421                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1422                      </li>
1423                      <li>
1424                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1425                      </li>
1426                  </ul>
1427                  <h2>In conclusion</h2>
1428                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1429                     as we enjoyed making it. Please contact us if you have ideas
1430                     for improvement or other feedback.</p>
1431              </div>
1432          </div>
1433     </body>
1434 </html>
1435 EOF
1436 }
1437
1438 =head2 run_options
1439
1440 Contains a hash of options passed from the application script, including
1441 the original ARGV the script received, the processed values from that
1442 ARGV and any extra arguments to the script which were not processed.
1443
1444 This can be used to add custom options to your application's scripts
1445 and setup your application differently depending on the values of these
1446 options.
1447
1448 =head1 INTERNAL METHODS
1449
1450 These methods are not meant to be used by end users.
1451
1452 =head2 $c->components
1453
1454 Returns a hash of components.
1455
1456 =cut
1457
1458 sub components {
1459     my ( $class, $comps ) = @_;
1460
1461     # FIXME
1462     # this is very wrong
1463     # people create components calling this sub directly, before setup
1464     # also, $class->log doesn't work before setup_log
1465     $class->setup_config unless $class->container;
1466
1467     my $container = $class->container;
1468
1469     if ( $comps ) {
1470         $class->log->warn(q{You are adding components using Catalyst's components method.});
1471         $class->log->warn(q{This behaviour is deprecated, please read});
1472         $class->log->warn(q{Catalyst::IOC::Container's documentation for better ways to do that.});
1473         $container->add_component( $_ ) for keys %$comps;
1474     }
1475
1476     return $container->get_all_components($class);
1477 }
1478
1479 =head2 $c->context_class
1480
1481 Returns or sets the context class.
1482
1483 =head2 $c->counter
1484
1485 Returns a hashref containing coderefs and execution counts (needed for
1486 deep recursion detection).
1487
1488 =head2 $c->depth
1489
1490 Returns the number of actions on the current internal execution stack.
1491
1492 =head2 $c->dispatch
1493
1494 Dispatches a request to actions.
1495
1496 =cut
1497
1498 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1499
1500 =head2 $c->dispatcher_class
1501
1502 Returns or sets the dispatcher class.
1503
1504 =head2 $c->dump_these
1505
1506 Returns a list of 2-element array references (name, structure) pairs
1507 that will be dumped on the error page in debug mode.
1508
1509 =cut
1510
1511 sub dump_these {
1512     my $c = shift;
1513     [ Request => $c->req ],
1514     [ Response => $c->res ],
1515     [ Stash => $c->stash ],
1516     [ Config => $c->config ];
1517 }
1518
1519 =head2 $c->engine_class
1520
1521 Returns or sets the engine class.
1522
1523 =head2 $c->execute( $class, $coderef )
1524
1525 Execute a coderef in given class and catch exceptions. Errors are available
1526 via $c->error.
1527
1528 =cut
1529
1530 sub execute {
1531     my ( $c, $class, $code ) = @_;
1532     $class = $c->component($class) || $class;
1533     $c->state(0);
1534
1535     if ( $c->depth >= $RECURSION ) {
1536         my $action = $code->reverse();
1537         $action = "/$action" unless $action =~ /->/;
1538         my $error = qq/Deep recursion detected calling "${action}"/;
1539         $c->log->error($error);
1540         $c->error($error);
1541         $c->state(0);
1542         return $c->state;
1543     }
1544
1545     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1546
1547     push( @{ $c->stack }, $code );
1548
1549     no warnings 'recursion';
1550     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1551     #      I have no idea how, ergo $ret (which appears to fix the issue)
1552     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1553
1554     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1555
1556     my $last = pop( @{ $c->stack } );
1557
1558     if ( my $error = $@ ) {
1559         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1560             $error->rethrow if $c->depth > 1;
1561         }
1562         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1563             $error->rethrow if $c->depth > 0;
1564         }
1565         else {
1566             unless ( ref $error ) {
1567                 no warnings 'uninitialized';
1568                 chomp $error;
1569                 my $class = $last->class;
1570                 my $name  = $last->name;
1571                 $error = qq/Caught exception in $class->$name "$error"/;
1572             }
1573             $c->error($error);
1574         }
1575         $c->state(0);
1576     }
1577     return $c->state;
1578 }
1579
1580 sub _stats_start_execute {
1581     my ( $c, $code ) = @_;
1582     my $appclass = ref($c) || $c;
1583     return if ( ( $code->name =~ /^_.*/ )
1584         && ( !$appclass->config->{show_internal_actions} ) );
1585
1586     my $action_name = $code->reverse();
1587     $c->counter->{$action_name}++;
1588
1589     my $action = $action_name;
1590     $action = "/$action" unless $action =~ /->/;
1591
1592     # determine if the call was the result of a forward
1593     # this is done by walking up the call stack and looking for a calling
1594     # sub of Catalyst::forward before the eval
1595     my $callsub = q{};
1596     for my $index ( 2 .. 11 ) {
1597         last
1598         if ( ( caller($index) )[0] eq 'Catalyst'
1599             && ( caller($index) )[3] eq '(eval)' );
1600
1601         if ( ( caller($index) )[3] =~ /forward$/ ) {
1602             $callsub = ( caller($index) )[3];
1603             $action  = "-> $action";
1604             last;
1605         }
1606     }
1607
1608     my $uid = $action_name . $c->counter->{$action_name};
1609
1610     # is this a root-level call or a forwarded call?
1611     if ( $callsub =~ /forward$/ ) {
1612         my $parent = $c->stack->[-1];
1613
1614         # forward, locate the caller
1615         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1616             $c->stats->profile(
1617                 begin  => $action,
1618                 parent => "$parent" . $c->counter->{"$parent"},
1619                 uid    => $uid,
1620             );
1621         }
1622         else {
1623
1624             # forward with no caller may come from a plugin
1625             $c->stats->profile(
1626                 begin => $action,
1627                 uid   => $uid,
1628             );
1629         }
1630     }
1631     else {
1632
1633         # root-level call
1634         $c->stats->profile(
1635             begin => $action,
1636             uid   => $uid,
1637         );
1638     }
1639     return $action;
1640
1641 }
1642
1643 sub _stats_finish_execute {
1644     my ( $c, $info ) = @_;
1645     $c->stats->profile( end => $info );
1646 }
1647
1648 =head2 $c->finalize
1649
1650 Finalizes the request.
1651
1652 =cut
1653
1654 sub finalize {
1655     my $c = shift;
1656
1657     for my $error ( @{ $c->error } ) {
1658         $c->log->error($error);
1659     }
1660
1661     # Allow engine to handle finalize flow (for POE)
1662     my $engine = $c->engine;
1663     if ( my $code = $engine->can('finalize') ) {
1664         $engine->$code($c);
1665     }
1666     else {
1667
1668         $c->finalize_uploads;
1669
1670         # Error
1671         if ( $#{ $c->error } >= 0 ) {
1672             $c->finalize_error;
1673         }
1674
1675         $c->finalize_headers unless $c->response->finalized_headers;
1676
1677         # HEAD request
1678         if ( $c->request->method eq 'HEAD' ) {
1679             $c->response->body('');
1680         }
1681
1682         $c->finalize_body;
1683     }
1684
1685     $c->log_response;
1686
1687     if ($c->use_stats) {
1688         my $elapsed = sprintf '%f', $c->stats->elapsed;
1689         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1690         $c->log->info(
1691             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1692     }
1693
1694     return $c->response->status;
1695 }
1696
1697 =head2 $c->finalize_body
1698
1699 Finalizes body.
1700
1701 =cut
1702
1703 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1704
1705 =head2 $c->finalize_cookies
1706
1707 Finalizes cookies.
1708
1709 =cut
1710
1711 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1712
1713 =head2 $c->finalize_error
1714
1715 Finalizes error.
1716
1717 =cut
1718
1719 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1720
1721 =head2 $c->finalize_headers
1722
1723 Finalizes headers.
1724
1725 =cut
1726
1727 sub finalize_headers {
1728     my $c = shift;
1729
1730     my $response = $c->response; #accessor calls can add up?
1731
1732     # Check if we already finalized headers
1733     return if $response->finalized_headers;
1734
1735     # Handle redirects
1736     if ( my $location = $response->redirect ) {
1737         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1738         $response->header( Location => $location );
1739
1740         if ( !$response->has_body ) {
1741             # Add a default body if none is already present
1742             $response->body(<<"EOF");
1743 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1744 <html xmlns="http://www.w3.org/1999/xhtml">
1745   <head>
1746     <title>Moved</title>
1747   </head>
1748   <body>
1749      <p>This item has moved <a href="$location">here</a>.</p>
1750   </body>
1751 </html>
1752 EOF
1753             $response->content_type('text/html; charset=utf-8');
1754         }
1755     }
1756
1757     # Content-Length
1758     if ( defined $response->body && length $response->body && !$response->content_length ) {
1759
1760         # get the length from a filehandle
1761         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1762         {
1763             my $size = -s $response->body;
1764             if ( $size ) {
1765                 $response->content_length( $size );
1766             }
1767             else {
1768                 $c->log->warn('Serving filehandle without a content-length');
1769             }
1770         }
1771         else {
1772             # everything should be bytes at this point, but just in case
1773             $response->content_length( length( $response->body ) );
1774         }
1775     }
1776
1777     # Errors
1778     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1779         $response->headers->remove_header("Content-Length");
1780         $response->body('');
1781     }
1782
1783     $c->finalize_cookies;
1784
1785     $c->response->finalize_headers();
1786
1787     # Done
1788     $response->finalized_headers(1);
1789 }
1790
1791 =head2 $c->finalize_output
1792
1793 An alias for finalize_body.
1794
1795 =head2 $c->finalize_read
1796
1797 Finalizes the input after reading is complete.
1798
1799 =cut
1800
1801 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1802
1803 =head2 $c->finalize_uploads
1804
1805 Finalizes uploads. Cleans up any temporary files.
1806
1807 =cut
1808
1809 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1810
1811 =head2 $c->get_action( $action, $namespace )
1812
1813 Gets an action in a given namespace.
1814
1815 =cut
1816
1817 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1818
1819 =head2 $c->get_actions( $action, $namespace )
1820
1821 Gets all actions of a given name in a namespace and all parent
1822 namespaces.
1823
1824 =cut
1825
1826 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1827
1828 =head2 $app->handle_request( @arguments )
1829
1830 Called to handle each HTTP request.
1831
1832 =cut
1833
1834 sub handle_request {
1835     my ( $class, @arguments ) = @_;
1836
1837     # Always expect worst case!
1838     my $status = -1;
1839     try {
1840         if ($class->debug) {
1841             my $secs = time - $START || 1;
1842             my $av = sprintf '%.3f', $COUNT / $secs;
1843             my $time = localtime time;
1844             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1845         }
1846
1847         my $c = $class->prepare(@arguments);
1848         $c->dispatch;
1849         $status = $c->finalize;
1850     }
1851     catch {
1852         chomp(my $error = $_);
1853         $class->log->error(qq/Caught exception in engine "$error"/);
1854     };
1855
1856     $COUNT++;
1857
1858     if(my $coderef = $class->log->can('_flush')){
1859         $class->log->$coderef();
1860     }
1861     return $status;
1862 }
1863
1864 =head2 $class->prepare( @arguments )
1865
1866 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1867 etc.).
1868
1869 =cut
1870
1871 has _uploadtmp => (
1872     is => 'ro',
1873     predicate => '_has_uploadtmp',
1874 );
1875
1876 sub prepare {
1877     my ( $class, @arguments ) = @_;
1878
1879     # XXX
1880     # After the app/ctxt split, this should become an attribute based on something passed
1881     # into the application.
1882     $class->context_class( ref $class || $class ) unless $class->context_class;
1883
1884     my $uploadtmp = $class->config->{uploadtmp};
1885     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
1886
1887     $c->response->_context($c);
1888
1889     #surely this is not the most efficient way to do things...
1890     $c->stats($class->stats_class->new)->enable($c->use_stats);
1891     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1892         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1893     }
1894
1895     try {
1896         # Allow engine to direct the prepare flow (for POE)
1897         if ( my $prepare = $c->engine->can('prepare') ) {
1898             $c->engine->$prepare( $c, @arguments );
1899         }
1900         else {
1901             $c->prepare_request(@arguments);
1902             $c->prepare_connection;
1903             $c->prepare_query_parameters;
1904             $c->prepare_headers; # Just hooks, no longer needed - they just
1905             $c->prepare_cookies; # cause the lazy attribute on req to build
1906             $c->prepare_path;
1907
1908             # Prepare the body for reading, either by prepare_body
1909             # or the user, if they are using $c->read
1910             $c->prepare_read;
1911
1912             # Parse the body unless the user wants it on-demand
1913             unless ( ref($c)->config->{parse_on_demand} ) {
1914                 $c->prepare_body;
1915             }
1916         }
1917         $c->prepare_action;
1918     }
1919     # VERY ugly and probably shouldn't rely on ->finalize actually working
1920     catch {
1921         # failed prepare is always due to an invalid request, right?
1922         $c->response->status(400);
1923         $c->response->content_type('text/plain');
1924         $c->response->body('Bad Request');
1925         # Note we call finalize and then die here, which escapes
1926         # finalize being called in the enclosing block..
1927         # It in fact couldn't be called, as we don't return $c..
1928         # This is a mess - but I'm unsure you can fix this without
1929         # breaking compat for people doing crazy things (we should set
1930         # the 400 and just return the ctx here IMO, letting finalize get called
1931         # above...
1932         $c->finalize;
1933         die $_;
1934     };
1935
1936     $c->log_request;
1937
1938     return $c;
1939 }
1940
1941 =head2 $c->prepare_action
1942
1943 Prepares action. See L<Catalyst::Dispatcher>.
1944
1945 =cut
1946
1947 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1948
1949 =head2 $c->prepare_body
1950
1951 Prepares message body.
1952
1953 =cut
1954
1955 sub prepare_body {
1956     my $c = shift;
1957
1958     return if $c->request->_has_body;
1959
1960     # Initialize on-demand data
1961     $c->engine->prepare_body( $c, @_ );
1962     $c->prepare_parameters;
1963     $c->prepare_uploads;
1964 }
1965
1966 =head2 $c->prepare_body_chunk( $chunk )
1967
1968 Prepares a chunk of data before sending it to L<HTTP::Body>.
1969
1970 See L<Catalyst::Engine>.
1971
1972 =cut
1973
1974 sub prepare_body_chunk {
1975     my $c = shift;
1976     $c->engine->prepare_body_chunk( $c, @_ );
1977 }
1978
1979 =head2 $c->prepare_body_parameters
1980
1981 Prepares body parameters.
1982
1983 =cut
1984
1985 sub prepare_body_parameters {
1986     my $c = shift;
1987     $c->engine->prepare_body_parameters( $c, @_ );
1988 }
1989
1990 =head2 $c->prepare_connection
1991
1992 Prepares connection.
1993
1994 =cut
1995
1996 sub prepare_connection {
1997     my $c = shift;
1998     # XXX - This is called on the engine (not the request) to maintain
1999     #       Engine::PSGI back compat.
2000     $c->engine->prepare_connection($c);
2001 }
2002
2003 =head2 $c->prepare_cookies
2004
2005 Prepares cookies by ensuring that the attribute on the request
2006 object has been built.
2007
2008 =cut
2009
2010 sub prepare_cookies { my $c = shift; $c->request->cookies }
2011
2012 =head2 $c->prepare_headers
2013
2014 Prepares request headers by ensuring that the attribute on the request
2015 object has been built.
2016
2017 =cut
2018
2019 sub prepare_headers { my $c = shift; $c->request->headers }
2020
2021 =head2 $c->prepare_parameters
2022
2023 Prepares parameters.
2024
2025 =cut
2026
2027 sub prepare_parameters {
2028     my $c = shift;
2029     $c->prepare_body_parameters;
2030     $c->engine->prepare_parameters( $c, @_ );
2031 }
2032
2033 =head2 $c->prepare_path
2034
2035 Prepares path and base.
2036
2037 =cut
2038
2039 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2040
2041 =head2 $c->prepare_query_parameters
2042
2043 Prepares query parameters.
2044
2045 =cut
2046
2047 sub prepare_query_parameters {
2048     my $c = shift;
2049
2050     $c->engine->prepare_query_parameters( $c, @_ );
2051 }
2052
2053 =head2 $c->log_request
2054
2055 Writes information about the request to the debug logs.  This includes:
2056
2057 =over 4
2058
2059 =item * Request method, path, and remote IP address
2060
2061 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2062
2063 =item * Request parameters
2064
2065 =item * File uploads
2066
2067 =back
2068
2069 =cut
2070
2071 sub log_request {
2072     my $c = shift;
2073
2074     return unless $c->debug;
2075
2076     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2077     my $request = $dump->[1];
2078
2079     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2080     $method ||= '';
2081     $path = '/' unless length $path;
2082     $address ||= '';
2083     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2084
2085     $c->log_request_headers($request->headers);
2086
2087     if ( my $keywords = $request->query_keywords ) {
2088         $c->log->debug("Query keywords are: $keywords");
2089     }
2090
2091     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2092
2093     $c->log_request_uploads($request);
2094 }
2095
2096 =head2 $c->log_response
2097
2098 Writes information about the response to the debug logs by calling
2099 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2100
2101 =cut
2102
2103 sub log_response {
2104     my $c = shift;
2105
2106     return unless $c->debug;
2107
2108     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2109     my $response = $dump->[1];
2110
2111     $c->log_response_status_line($response);
2112     $c->log_response_headers($response->headers);
2113 }
2114
2115 =head2 $c->log_response_status_line($response)
2116
2117 Writes one line of information about the response to the debug logs.  This includes:
2118
2119 =over 4
2120
2121 =item * Response status code
2122
2123 =item * Content-Type header (if present)
2124
2125 =item * Content-Length header (if present)
2126
2127 =back
2128
2129 =cut
2130
2131 sub log_response_status_line {
2132     my ($c, $response) = @_;
2133
2134     $c->log->debug(
2135         sprintf(
2136             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2137             $response->status                            || 'unknown',
2138             $response->headers->header('Content-Type')   || 'unknown',
2139             $response->headers->header('Content-Length') || 'unknown'
2140         )
2141     );
2142 }
2143
2144 =head2 $c->log_response_headers($headers);
2145
2146 Hook method which can be wrapped by plugins to log the response headers.
2147 No-op in the default implementation.
2148
2149 =cut
2150
2151 sub log_response_headers {}
2152
2153 =head2 $c->log_request_parameters( query => {}, body => {} )
2154
2155 Logs request parameters to debug logs
2156
2157 =cut
2158
2159 sub log_request_parameters {
2160     my $c          = shift;
2161     my %all_params = @_;
2162
2163     return unless $c->debug;
2164
2165     my $column_width = Catalyst::Utils::term_width() - 44;
2166     foreach my $type (qw(query body)) {
2167         my $params = $all_params{$type};
2168         next if ! keys %$params;
2169         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2170         for my $key ( sort keys %$params ) {
2171             my $param = $params->{$key};
2172             my $value = defined($param) ? $param : '';
2173             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2174         }
2175         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2176     }
2177 }
2178
2179 =head2 $c->log_request_uploads
2180
2181 Logs file uploads included in the request to the debug logs.
2182 The parameter name, filename, file type, and file size are all included in
2183 the debug logs.
2184
2185 =cut
2186
2187 sub log_request_uploads {
2188     my $c = shift;
2189     my $request = shift;
2190     return unless $c->debug;
2191     my $uploads = $request->uploads;
2192     if ( keys %$uploads ) {
2193         my $t = Text::SimpleTable->new(
2194             [ 12, 'Parameter' ],
2195             [ 26, 'Filename' ],
2196             [ 18, 'Type' ],
2197             [ 9,  'Size' ]
2198         );
2199         for my $key ( sort keys %$uploads ) {
2200             my $upload = $uploads->{$key};
2201             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2202                 $t->row( $key, $u->filename, $u->type, $u->size );
2203             }
2204         }
2205         $c->log->debug( "File Uploads are:\n" . $t->draw );
2206     }
2207 }
2208
2209 =head2 $c->log_request_headers($headers);
2210
2211 Hook method which can be wrapped by plugins to log the request headers.
2212 No-op in the default implementation.
2213
2214 =cut
2215
2216 sub log_request_headers {}
2217
2218 =head2 $c->log_headers($type => $headers)
2219
2220 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2221
2222 =cut
2223
2224 sub log_headers {
2225     my $c       = shift;
2226     my $type    = shift;
2227     my $headers = shift;    # an HTTP::Headers instance
2228
2229     return unless $c->debug;
2230
2231     my $column_width = Catalyst::Utils::term_width() - 28;
2232     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2233     $headers->scan(
2234         sub {
2235             my ( $name, $value ) = @_;
2236             $t->row( $name, $value );
2237         }
2238     );
2239     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2240 }
2241
2242
2243 =head2 $c->prepare_read
2244
2245 Prepares the input for reading.
2246
2247 =cut
2248
2249 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2250
2251 =head2 $c->prepare_request
2252
2253 Prepares the engine request.
2254
2255 =cut
2256
2257 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2258
2259 =head2 $c->prepare_uploads
2260
2261 Prepares uploads.
2262
2263 =cut
2264
2265 sub prepare_uploads {
2266     my $c = shift;
2267
2268     $c->engine->prepare_uploads( $c, @_ );
2269 }
2270
2271 =head2 $c->prepare_write
2272
2273 Prepares the output for writing.
2274
2275 =cut
2276
2277 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2278
2279 =head2 $c->request_class
2280
2281 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2282
2283 =head2 $c->response_class
2284
2285 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2286
2287 =head2 $c->read( [$maxlength] )
2288
2289 Reads a chunk of data from the request body. This method is designed to
2290 be used in a while loop, reading C<$maxlength> bytes on every call.
2291 C<$maxlength> defaults to the size of the request if not specified.
2292
2293 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2294 directly.
2295
2296 Warning: If you use read(), Catalyst will not process the body,
2297 so you will not be able to access POST parameters or file uploads via
2298 $c->request.  You must handle all body parsing yourself.
2299
2300 =cut
2301
2302 sub read { my $c = shift; return $c->request->read( @_ ) }
2303
2304 =head2 $c->run
2305
2306 Starts the engine.
2307
2308 =cut
2309
2310 sub run {
2311   my $app = shift;
2312   $app->_make_immutable_if_needed;
2313   $app->engine_loader->needs_psgi_engine_compat_hack ?
2314     $app->engine->run($app, @_) :
2315       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2316 }
2317
2318 sub _make_immutable_if_needed {
2319     my $class = shift;
2320     my $meta = Class::MOP::get_metaclass_by_name($class);
2321     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2322     if (
2323         $meta->is_immutable
2324         && ! { $meta->immutable_options }->{replace_constructor}
2325         && $isa_ca
2326     ) {
2327         warn("You made your application class ($class) immutable, "
2328             . "but did not inline the\nconstructor. "
2329             . "This will break catalyst, as your app \@ISA "
2330             . "Class::Accessor(::Fast)?\nPlease pass "
2331             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2332     }
2333     unless ($meta->is_immutable) {
2334         # XXX - FIXME warning here as you should make your app immutable yourself.
2335         $meta->make_immutable(
2336             replace_constructor => 1,
2337         );
2338     }
2339 }
2340
2341 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2342
2343 Sets an action in a given namespace.
2344
2345 =cut
2346
2347 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2348
2349 =head2 $c->setup_actions($component)
2350
2351 Sets up actions for a component.
2352
2353 =cut
2354
2355 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2356
2357 =head2 $c->setup_config
2358
2359 =cut
2360
2361 sub setup_config {
2362     my $class = shift;
2363
2364     my %args = %{ $class->config || {} };
2365
2366     my $container_class;
2367
2368     if ( exists $args{container_class} ) {
2369         $container_class = delete $args{container_class};
2370         Class::MOP::load_class($container_class);
2371     }
2372     else {
2373         $container_class = Class::MOP::load_first_existing_class("${class}::Container", 'Catalyst::IOC::Container');
2374     }
2375
2376     my $container = $container_class->new( %args, name => $class );
2377     $class->container($container);
2378
2379     my $config = $container->resolve( service => 'config' );
2380     $class->config($config);
2381     $class->finalize_config; # back-compat
2382 }
2383
2384 =head2 $c->finalize_config
2385
2386 =cut
2387
2388 sub finalize_config { }
2389
2390 =head2 $c->setup_components
2391
2392 This method is called internally to set up the application's components.
2393
2394 It finds modules by calling the L<locate_components> method, expands them to
2395 package names with the $container->expand_component_module method, and then
2396 installs each component into the application.
2397
2398 The C<setup_components> config option is passed to both of the above methods.
2399
2400 =cut
2401
2402 sub setup_components { shift->container->setup_components }
2403
2404 =head2 locate_components
2405
2406 =cut
2407
2408 sub locate_components {
2409     my $class = shift;
2410
2411     $class->log->warn('The locate_components method has been deprecated.');
2412     $class->log->warn('Please read Catalyst::IOC::Container documentation to');
2413     $class->log->warn('update your application.');
2414
2415     # XXX think about ditching this sort entirely
2416     return sort { length $a <=> length $b }
2417         @{ $class->container->resolve( service => 'locate_components' ) };
2418 }
2419
2420 =head2 $c->setup_dispatcher
2421
2422 Sets up dispatcher.
2423
2424 =cut
2425
2426 sub setup_dispatcher {
2427     my ( $class, $dispatcher ) = @_;
2428
2429     if ($dispatcher) {
2430         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2431     }
2432
2433     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2434         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2435     }
2436
2437     unless ($dispatcher) {
2438         $dispatcher = $class->dispatcher_class;
2439     }
2440
2441     Class::MOP::load_class($dispatcher);
2442
2443     # dispatcher instance
2444     $class->dispatcher( $dispatcher->new );
2445 }
2446
2447 =head2 $c->setup_engine
2448
2449 Sets up engine.
2450
2451 =cut
2452
2453 sub engine_class {
2454     my ($class, $requested_engine) = @_;
2455
2456     if (!$class->engine_loader || $requested_engine) {
2457         $class->engine_loader(
2458             Catalyst::EngineLoader->new({
2459                 application_name => $class,
2460                 (defined $requested_engine
2461                      ? (catalyst_engine_class => $requested_engine) : ()),
2462             }),
2463         );
2464     }
2465
2466     $class->engine_loader->catalyst_engine_class;
2467 }
2468
2469 sub setup_engine {
2470     my ($class, $requested_engine) = @_;
2471
2472     my $engine = do {
2473         my $loader = $class->engine_loader;
2474
2475         if (!$loader || $requested_engine) {
2476             $loader = Catalyst::EngineLoader->new({
2477                 application_name => $class,
2478                 (defined $requested_engine
2479                      ? (requested_engine => $requested_engine) : ()),
2480             }),
2481
2482             $class->engine_loader($loader);
2483         }
2484
2485         $loader->catalyst_engine_class;
2486     };
2487
2488     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2489     return if $class->loading_psgi_file;
2490
2491     Class::MOP::load_class($engine);
2492
2493     if ($ENV{MOD_PERL}) {
2494         my $apache = $class->engine_loader->auto;
2495
2496         my $meta = find_meta($class);
2497         my $was_immutable = $meta->is_immutable;
2498         my %immutable_options = $meta->immutable_options;
2499         $meta->make_mutable if $was_immutable;
2500
2501         $meta->add_method(handler => sub {
2502             my $r = shift;
2503             my $psgi_app = $class->_finalized_psgi_app;
2504             $apache->call_app($r, $psgi_app);
2505         });
2506
2507         $meta->make_immutable(%immutable_options) if $was_immutable;
2508     }
2509
2510     $class->engine( $engine->new );
2511
2512     return;
2513 }
2514
2515 sub _finalized_psgi_app {
2516     my ($app) = @_;
2517
2518     unless ($app->_psgi_app) {
2519         my $psgi_app = $app->_setup_psgi_app;
2520         $app->_psgi_app($psgi_app);
2521     }
2522
2523     return $app->_psgi_app;
2524 }
2525
2526 sub _setup_psgi_app {
2527     my ($app) = @_;
2528
2529     for my $home (Path::Class::Dir->new($app->config->{home})) {
2530         my $psgi_file = $home->file(
2531             Catalyst::Utils::appprefix($app) . '.psgi',
2532         );
2533
2534         next unless -e $psgi_file;
2535
2536         # If $psgi_file calls ->setup_engine, it's doing so to load
2537         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2538         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2539         # anyway. So set a flag (ick) that tells setup_engine not to populate
2540         # $c->engine or do any other things we might regret.
2541
2542         $app->loading_psgi_file(1);
2543         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2544         $app->loading_psgi_file(0);
2545
2546         return $psgi_app
2547             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2548
2549         warn <<"EOW";
2550 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2551
2552 Its content has been ignored. Please consult the Catalyst::Upgrading
2553 documentation on how to upgrade from Catalyst::Engine::PSGI.
2554 EOW
2555     }
2556
2557     return $app->apply_default_middlewares($app->psgi_app);
2558 }
2559
2560 =head2 $c->apply_default_middlewares
2561
2562 Adds the following L<Plack> middlewares to your application, since they are
2563 useful and commonly needed:
2564
2565 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2566 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2567 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2568 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2569 applied since this middleware is smart enough to conditionally apply itself).
2570
2571 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2572 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2573 $ENV{SCRIPT_NAME}
2574
2575 =cut
2576
2577
2578 sub apply_default_middlewares {
2579     my ($app, $psgi_app) = @_;
2580
2581     $psgi_app = Plack::Middleware::Conditional->wrap(
2582         $psgi_app,
2583         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2584         condition => sub {
2585             my ($env) = @_;
2586             return if $app->config->{ignore_frontend_proxy};
2587             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2588                 || $app->config->{using_frontend_proxy};
2589         },
2590     );
2591
2592     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2593     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2594     $psgi_app = Plack::Middleware::Conditional->wrap(
2595         $psgi_app,
2596         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2597         condition => sub {
2598             my ($env) = @_;
2599             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2600             return unless $1 < 4.23;
2601             1;
2602         },
2603     );
2604
2605     # we're applying this unconditionally as the middleware itself already makes
2606     # sure it doesn't fuck things up if it's not running under one of the right
2607     # IIS versions
2608     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2609
2610     # And another IIS issue, this time with IIS7.
2611     $psgi_app = Plack::Middleware::Conditional->wrap(
2612         $psgi_app,
2613         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2614         condition => sub {
2615             my ($env) = @_;
2616             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2617         },
2618     );
2619
2620     return $psgi_app;
2621 }
2622
2623 =head2 $c->psgi_app
2624
2625 Returns a PSGI application code reference for the catalyst application
2626 C<$c>. This is the bare application without any middlewares
2627 applied. C<${myapp}.psgi> is not taken into account.
2628
2629 This is what you want to be using to retrieve the PSGI application code
2630 reference of your Catalyst application for use in F<.psgi> files.
2631
2632 =cut
2633
2634 sub psgi_app {
2635     my ($app) = @_;
2636     return $app->engine->build_psgi_app($app);
2637 }
2638
2639 =head2 $c->setup_home
2640
2641 Sets up the home directory.
2642
2643 =cut
2644
2645 sub setup_home {
2646     my ( $class, $home_flag ) = @_;
2647
2648     my $home = $class->container->resolve(
2649         service    => 'home',
2650         parameters => {
2651             home_flag => $home_flag
2652         },
2653     );
2654
2655     if ($home) {
2656         #I remember recently being scolded for assigning config values like this
2657         $class->config->{home} ||= $home;
2658         $class->config->{root} ||= $class->container->resolve(service => 'root_dir');
2659     }
2660 }
2661
2662 =head2 $c->setup_log
2663
2664 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2665 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2666 log to.
2667
2668 This method also installs a C<debug> method that returns a true value into the
2669 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2670 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2671
2672 Note that if the log has already been setup, by either a previous call to
2673 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2674 that this method won't actually set up the log object.
2675
2676 =cut
2677
2678 sub setup_log {
2679     my ( $class, $levels ) = @_;
2680
2681     $levels ||= '';
2682     $levels =~ s/^\s+//;
2683     $levels =~ s/\s+$//;
2684     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2685
2686     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2687     if ( defined $env_debug ) {
2688         $levels{debug} = 1 if $env_debug; # Ugly!
2689         delete($levels{debug}) unless $env_debug;
2690     }
2691
2692     unless ( $class->log ) {
2693         $class->log( Catalyst::Log->new(keys %levels) );
2694     }
2695
2696     if ( $levels{debug} ) {
2697         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2698         $class->log->debug('Debug messages enabled');
2699     }
2700 }
2701
2702 =head2 $c->setup_plugins
2703
2704 Sets up plugins.
2705
2706 =cut
2707
2708 =head2 $c->setup_stats
2709
2710 Sets up timing statistics class.
2711
2712 =cut
2713
2714 sub setup_stats {
2715     my ( $class, $stats ) = @_;
2716
2717     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2718
2719     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2720     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2721         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2722         $class->log->debug('Statistics enabled');
2723     }
2724 }
2725
2726
2727 =head2 $c->registered_plugins
2728
2729 Returns a sorted list of the plugins which have either been stated in the
2730 import list.
2731
2732 If passed a given plugin name, it will report a boolean value indicating
2733 whether or not that plugin is loaded.  A fully qualified name is required if
2734 the plugin name does not begin with C<Catalyst::Plugin::>.
2735
2736  if ($c->registered_plugins('Some::Plugin')) {
2737      ...
2738  }
2739
2740 =cut
2741
2742 {
2743
2744     sub registered_plugins {
2745         my $proto = shift;
2746         return sort keys %{ $proto->_plugins } unless @_;
2747         my $plugin = shift;
2748         return 1 if exists $proto->_plugins->{$plugin};
2749         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2750     }
2751
2752     sub _register_plugin {
2753         my ( $proto, $plugin, $instant ) = @_;
2754         my $class = ref $proto || $proto;
2755
2756         Class::MOP::load_class( $plugin );
2757         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2758             if $plugin->isa( 'Catalyst::Component' );
2759         my $plugin_meta = Moose::Meta::Class->create($plugin);
2760         if (!$plugin_meta->has_method('new')
2761             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
2762             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
2763         }
2764         if (!$instant && !$proto->_plugins->{$plugin}) {
2765             my $meta = Class::MOP::get_metaclass_by_name($class);
2766             $meta->superclasses($plugin, $meta->superclasses);
2767         }
2768         $proto->_plugins->{$plugin} = 1;
2769         return $class;
2770     }
2771
2772     sub setup_plugins {
2773         my ( $class, $plugins ) = @_;
2774
2775         $class->_plugins( {} ) unless $class->_plugins;
2776         $plugins = Data::OptList::mkopt($plugins || []);
2777
2778         my @plugins = map {
2779             [ Catalyst::Utils::resolve_namespace(
2780                   $class . '::Plugin',
2781                   'Catalyst::Plugin', $_->[0]
2782               ),
2783               $_->[1],
2784             ]
2785          } @{ $plugins };
2786
2787         for my $plugin ( reverse @plugins ) {
2788             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2789             my $meta = find_meta($plugin->[0]);
2790             next if $meta && $meta->isa('Moose::Meta::Role');
2791
2792             $class->_register_plugin($plugin->[0]);
2793         }
2794
2795         my @roles =
2796             map  { $_->[0]->name, $_->[1] }
2797             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2798             map  { [find_meta($_->[0]), $_->[1]] }
2799             @plugins;
2800
2801         Moose::Util::apply_all_roles(
2802             $class => @roles
2803         ) if @roles;
2804     }
2805 }
2806
2807 =head2 $c->stack
2808
2809 Returns an arrayref of the internal execution stack (actions that are
2810 currently executing).
2811
2812 =head2 $c->stats
2813
2814 Returns the current timing statistics object. By default Catalyst uses
2815 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2816 L<< stats_class|/"$c->stats_class" >>.
2817
2818 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2819 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2820 profile explicitly, although MyApp.pm still won't profile nor output anything
2821 by itself.
2822
2823 =head2 $c->stats_class
2824
2825 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2826
2827 =head2 $c->use_stats
2828
2829 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2830
2831 Note that this is a static method, not an accessor and should be overridden
2832 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2833
2834 =cut
2835
2836 sub use_stats { 0 }
2837
2838
2839 =head2 $c->write( $data )
2840
2841 Writes $data to the output stream. When using this method directly, you
2842 will need to manually set the C<Content-Length> header to the length of
2843 your output data, if known.
2844
2845 =cut
2846
2847 sub write {
2848     my $c = shift;
2849
2850     # Finalize headers if someone manually writes output (for compat)
2851     $c->finalize_headers;
2852
2853     return $c->response->write( @_ );
2854 }
2855
2856 =head2 version
2857
2858 Returns the Catalyst version number. Mostly useful for "powered by"
2859 messages in template systems.
2860
2861 =cut
2862
2863 sub version { return $Catalyst::VERSION }
2864
2865 =head1 CONFIGURATION
2866
2867 There are a number of 'base' config variables which can be set:
2868
2869 =over
2870
2871 =item *
2872
2873 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2874
2875 =item *
2876
2877 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2878
2879 =item *
2880
2881 C<home> - The application home directory. In an uninstalled application,
2882 this is the top level application directory. In an installed application,
2883 this will be the directory containing C<< MyApp.pm >>.
2884
2885 =item *
2886
2887 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2888
2889 =item *
2890
2891 C<name> - The name of the application in debug messages and the debug and
2892 welcome screens
2893
2894 =item *
2895
2896 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2897 until it is accessed. This allows you to (for example) check authentication (and reject
2898 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
2899
2900 =item *
2901
2902 C<root> - The root directory for templates. Usually this is just a
2903 subdirectory of the home directory, but you can set it to change the
2904 templates to a different directory.
2905
2906 =item *
2907
2908 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2909 to be shown in hit debug tables in the test server.
2910
2911 =item *
2912
2913 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
2914 variable should be used for determining the request path.
2915
2916 Most web server environments pass the requested path to the application using environment variables,
2917 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
2918 exposed as C<< $c->request->base >>) and the request path below that base.
2919
2920 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
2921 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
2922
2923 =over
2924
2925 =item use_request_uri_for_path => 0
2926
2927 This is the default (and the) traditional method that Catalyst has used for determining the path information.
2928 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
2929 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
2930 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
2931
2932 However this method has the major disadvantage that it is impossible to correctly decode some elements
2933 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
2934 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
2935 can't distinguish / vs %2F in paths (in addition to other encoded values).
2936
2937 =item use_request_uri_for_path => 1
2938
2939 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
2940 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
2941 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
2942
2943 Given that this method of path resolution is provably more correct, it is recommended that you use
2944 this unless you have a specific need to deploy your application in a non-standard environment, and you are
2945 aware of the implications of not being able to handle encoded URI paths correctly.
2946
2947 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
2948 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
2949 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
2950 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
2951 C<< $c->request->base >> will be incorrect.
2952
2953 =back
2954
2955 =item *
2956
2957 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2958
2959 =back
2960
2961 =head1 INTERNAL ACTIONS
2962
2963 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2964 C<_ACTION>, and C<_END>. These are by default not shown in the private
2965 action table, but you can make them visible with a config parameter.
2966
2967     MyApp->config(show_internal_actions => 1);
2968
2969 =head1 ON-DEMAND PARSER
2970
2971 The request body is usually parsed at the beginning of a request,
2972 but if you want to handle input yourself, you can enable on-demand
2973 parsing with a config parameter.
2974
2975     MyApp->config(parse_on_demand => 1);
2976
2977 =head1 PROXY SUPPORT
2978
2979 Many production servers operate using the common double-server approach,
2980 with a lightweight frontend web server passing requests to a larger
2981 backend server. An application running on the backend server must deal
2982 with two problems: the remote user always appears to be C<127.0.0.1> and
2983 the server's hostname will appear to be C<localhost> regardless of the
2984 virtual host that the user connected through.
2985
2986 Catalyst will automatically detect this situation when you are running
2987 the frontend and backend servers on the same machine. The following
2988 changes are made to the request.
2989
2990     $c->req->address is set to the user's real IP address, as read from
2991     the HTTP X-Forwarded-For header.
2992
2993     The host value for $c->req->base and $c->req->uri is set to the real
2994     host, as read from the HTTP X-Forwarded-Host header.
2995
2996 Additionally, you may be running your backend application on an insecure
2997 connection (port 80) while your frontend proxy is running under SSL.  If there
2998 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2999 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3000 be created properly.
3001
3002 In the case of passing in:
3003
3004     X-Forwarded-Port: 443
3005
3006 All calls to C<uri_for> will result in an https link, as is expected.
3007
3008 Obviously, your web server must support these headers for this to work.
3009
3010 In a more complex server farm environment where you may have your
3011 frontend proxy server(s) on different machines, you will need to set a
3012 configuration option to tell Catalyst to read the proxied data from the
3013 headers.
3014
3015     MyApp->config(using_frontend_proxy => 1);
3016
3017 If you do not wish to use the proxy support at all, you may set:
3018
3019     MyApp->config(ignore_frontend_proxy => 0);
3020
3021 =head2 Note about psgi files
3022
3023 Note that if you supply your own .psgi file, calling
3024 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3025
3026 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3027 in your psgi, for example:
3028
3029     builder {
3030         enable "Plack::Middleware::ReverseProxy";
3031         MyApp->psgi_app
3032     };
3033
3034 This will unconditionally add the ReverseProxy support, or you need to call
3035 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3036 apply the support depending upon your config).
3037
3038 See L<Catalyst::PSGI> for more information.
3039
3040 =head1 THREAD SAFETY
3041
3042 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3043 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3044 believe the Catalyst core to be thread-safe.
3045
3046 If you plan to operate in a threaded environment, remember that all other
3047 modules you are using must also be thread-safe. Some modules, most notably
3048 L<DBD::SQLite>, are not thread-safe.
3049
3050 =head1 SUPPORT
3051
3052 IRC:
3053
3054     Join #catalyst on irc.perl.org.
3055
3056 Mailing Lists:
3057
3058     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3059     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3060
3061 Web:
3062
3063     http://catalyst.perl.org
3064
3065 Wiki:
3066
3067     http://dev.catalyst.perl.org
3068
3069 =head1 SEE ALSO
3070
3071 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3072
3073 =head2 L<Catalyst::Manual> - The Catalyst Manual
3074
3075 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3076
3077 =head2 L<Catalyst::Engine> - Core engine
3078
3079 =head2 L<Catalyst::Log> - Log class.
3080
3081 =head2 L<Catalyst::Request> - Request object
3082
3083 =head2 L<Catalyst::Response> - Response object
3084
3085 =head2 L<Catalyst::Test> - The test suite.
3086
3087 =head1 PROJECT FOUNDER
3088
3089 sri: Sebastian Riedel <sri@cpan.org>
3090
3091 =head1 CONTRIBUTORS
3092
3093 abw: Andy Wardley
3094
3095 acme: Leon Brocard <leon@astray.com>
3096
3097 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3098
3099 Andrew Bramble
3100
3101 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3102
3103 Andrew Ruthven
3104
3105 André Walker
3106
3107 andyg: Andy Grundman <andy@hybridized.org>
3108
3109 audreyt: Audrey Tang
3110
3111 bricas: Brian Cassidy <bricas@cpan.org>
3112
3113 Caelum: Rafael Kitover <rkitover@io.com>
3114
3115 chansen: Christian Hansen
3116
3117 chicks: Christopher Hicks
3118
3119 Chisel Wright C<pause@herlpacker.co.uk>
3120
3121 Danijel Milicevic C<me@danijel.de>
3122
3123 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3124
3125 David Naughton, C<naughton@umn.edu>
3126
3127 David E. Wheeler
3128
3129 dhoss: Devin Austin <dhoss@cpan.org>
3130
3131 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3132
3133 Drew Taylor
3134
3135 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3136
3137 esskar: Sascha Kiefer
3138
3139 fireartist: Carl Franks <cfranks@cpan.org>
3140
3141 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3142
3143 gabb: Danijel Milicevic
3144
3145 Gary Ashton Jones
3146
3147 Gavin Henry C<ghenry@perl.me.uk>
3148
3149 Geoff Richards
3150
3151 groditi: Guillermo Roditi <groditi@gmail.com>
3152
3153 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3154
3155 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3156
3157 jcamacho: Juan Camacho
3158
3159 jester: Jesse Sheidlower C<jester@panix.com>
3160
3161 jhannah: Jay Hannah <jay@jays.net>
3162
3163 Jody Belka
3164
3165 Johan Lindstrom
3166
3167 jon: Jon Schutz <jjschutz@cpan.org>
3168
3169 Jonathan Rockway C<< <jrockway@cpan.org> >>
3170
3171 Kieren Diment C<kd@totaldatasolution.com>
3172
3173 konobi: Scott McWhirter <konobi@cpan.org>
3174
3175 marcus: Marcus Ramberg <mramberg@cpan.org>
3176
3177 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3178
3179 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3180
3181 mugwump: Sam Vilain
3182
3183 naughton: David Naughton
3184
3185 ningu: David Kamholz <dkamholz@cpan.org>
3186
3187 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3188
3189 numa: Dan Sully <daniel@cpan.org>
3190
3191 obra: Jesse Vincent
3192
3193 Octavian Rasnita
3194
3195 omega: Andreas Marienborg
3196
3197 Oleg Kostyuk <cub.uanic@gmail.com>
3198
3199 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3200
3201 rafl: Florian Ragwitz <rafl@debian.org>
3202
3203 random: Roland Lammel <lammel@cpan.org>
3204
3205 Robert Sedlacek C<< <rs@474.at> >>
3206
3207 SpiceMan: Marcel Montes
3208
3209 sky: Arthur Bergman
3210
3211 szbalint: Balint Szilakszi <szbalint@cpan.org>
3212
3213 t0m: Tomas Doran <bobtfish@bobtfish.net>
3214
3215 Ulf Edvinsson
3216
3217 Viljo Marrandi C<vilts@yahoo.com>
3218
3219 Will Hawes C<info@whawes.co.uk>
3220
3221 willert: Sebastian Willert <willert@cpan.org>
3222
3223 wreis: Wallace Reis <wallace@reis.org.br>
3224
3225 Yuval Kogman, C<nothingmuch@woobling.org>
3226
3227 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3228
3229 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3230
3231 =head1 COPYRIGHT
3232
3233 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3234
3235 =head1 LICENSE
3236
3237 This library is free software. You can redistribute it and/or modify it under
3238 the same terms as Perl itself.
3239
3240 =cut
3241
3242 no Moose;
3243
3244 __PACKAGE__->meta->make_immutable;
3245
3246 1;