lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/container components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80032';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub _application { $_[0] }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 This sets the log level to 'debug' and enables full debug output on the
 252 error screen. If you only want the latter, see L<< $c->debug >>.
 253
 254 =head2 -Engine
 255
 256 Forces Catalyst to use a specific engine. Omit the
 257 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 258
 259     use Catalyst qw/-Engine=CGI/;
 260
 261 =head2 -Home
 262
 263 Forces Catalyst to use a specific home directory, e.g.:
 264
 265     use Catalyst qw[-Home=/usr/mst];
 266
 267 This can also be done in the shell environment by setting either the
 268 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 269 is replaced with the uppercased name of your application, any "::" in
 270 the name will be replaced with underscores, e.g. MyApp::Web should use
 271 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 272
 273 If none of these are set, Catalyst will attempt to automatically detect the
 274 home directory. If you are working in a development envirnoment, Catalyst
 275 will try and find the directory containing either Makefile.PL, Build.PL or
 276 dist.ini. If the application has been installed into the system (i.e.
 277 you have done C<make install>), then Catalyst will use the path to your
 278 application module, without the .pm extension (ie, /foo/MyApp if your
 279 application was installed at /foo/MyApp.pm)
 280
 281 =head2 -Log
 282
 283     use Catalyst '-Log=warn,fatal,error';
 284
 285 Specifies a comma-delimited list of log levels.
 286
 287 =head2 -Stats
 288
 289 Enables statistics collection and reporting.
 290
 291    use Catalyst qw/-Stats=1/;
 292
 293 You can also force this setting from the system environment with CATALYST_STATS
 294 or <MYAPP>_STATS. The environment settings override the application, with
 295 <MYAPP>_STATS having the highest priority.
 296
 297 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 298
 299 =head1 METHODS
 300
 301 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 302
 303 =head2 $c->action
 304
 305 Returns a L<Catalyst::Action> object for the current action, which
 306 stringifies to the action name. See L<Catalyst::Action>.
 307
 308 =head2 $c->namespace
 309
 310 Returns the namespace of the current action, i.e., the URI prefix
 311 corresponding to the controller of the current action. For example:
 312
 313     # in Controller::Foo::Bar
 314     $c->namespace; # returns 'foo/bar';
 315
 316 =head2 $c->request
 317
 318 =head2 $c->req
 319
 320 Returns the current L<Catalyst::Request> object, giving access to
 321 information about the current client request (including parameters,
 322 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 323
 324 =head2 REQUEST FLOW HANDLING
 325
 326 =head2 $c->forward( $action [, \@arguments ] )
 327
 328 =head2 $c->forward( $class, $method, [, \@arguments ] )
 329
 330 Forwards processing to another action, by its private name. If you give a
 331 class name but no method, C<process()> is called. You may also optionally
 332 pass arguments in an arrayref. The action will receive the arguments in
 333 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 334 C<< $c->req->args >> will be restored to the previous values.
 335
 336 Any data C<return>ed from the action forwarded to, will be returned by the
 337 call to forward.
 338
 339     my $foodata = $c->forward('/foo');
 340     $c->forward('index');
 341     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 342     $c->forward('View::TT');
 343
 344 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 345 an C<< eval { } >> around the call (actually
 346 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 347 all 'dies' within the called action. If you want C<die> to propagate you
 348 need to do something like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 374
 375 =cut
 376
 377 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 378
 379 =head2 $c->detach( $action [, \@arguments ] )
 380
 381 =head2 $c->detach( $class, $method, [, \@arguments ] )
 382
 383 =head2 $c->detach()
 384
 385 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 386 doesn't return to the previous action when processing is finished.
 387
 388 When called with no arguments it escapes the processing chain entirely.
 389
 390 =cut
 391
 392 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 393
 394 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 397
 398 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 399 but does a full dispatch, instead of just calling the new C<$action> /
 400 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 401 you go to are called, just like a new request.
 402
 403 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 404 This means, for example, that C<< $c->action >> methods such as
 405 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 406 L<reverse|Catalyst::Action/reverse> return information for the visited action
 407 when they are invoked within the visited action.  This is different from the
 408 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 409 continues to use the $c->action object from the caller action even when
 410 invoked from the callee.
 411
 412 C<< $c->stash >> is kept unchanged.
 413
 414 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 415 allows you to "wrap" another action, just as it would have been called by
 416 dispatching from a URL, while the analogous
 417 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 418 transfer control to another action as if it had been reached directly from a URL.
 419
 420 =cut
 421
 422 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 423
 424 =head2 $c->go( $action [, \@captures, \@arguments ] )
 425
 426 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 427
 428 The relationship between C<go> and
 429 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 430 the relationship between
 431 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 432 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 433 C<< $c->go >> will perform a full dispatch on the specified action or method,
 434 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 435 C<go> escapes the processing of the current request chain on completion, and
 436 does not return to its caller.
 437
 438 @arguments are arguments to the final destination of $action. @captures are
 439 arguments to the intermediate steps, if any, on the way to the final sub of
 440 $action.
 441
 442 =cut
 443
 444 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 445
 446 =head2 $c->response
 447
 448 =head2 $c->res
 449
 450 Returns the current L<Catalyst::Response> object, see there for details.
 451
 452 =head2 $c->stash
 453
 454 Returns a hashref to the stash, which may be used to store data and pass
 455 it between components during a request. You can also set hash keys by
 456 passing arguments. The stash is automatically sent to the view. The
 457 stash is cleared at the end of a request; it cannot be used for
 458 persistent storage (for this you must use a session; see
 459 L<Catalyst::Plugin::Session> for a complete system integrated with
 460 Catalyst).
 461
 462     $c->stash->{foo} = $bar;
 463     $c->stash( { moose => 'majestic', qux => 0 } );
 464     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 465
 466     # stash is automatically passed to the view for use in a template
 467     $c->forward( 'MyApp::View::TT' );
 468
 469 =cut
 470
 471 around stash => sub {
 472     my $orig = shift;
 473     my $c = shift;
 474     my $stash = $orig->($c);
 475     if (@_) {
 476         my $new_stash = @_ > 1 ? {@_} : $_[0];
 477         croak('stash takes a hash or hashref') unless ref $new_stash;
 478         foreach my $key ( keys %$new_stash ) {
 479           $stash->{$key} = $new_stash->{$key};
 480         }
 481     }
 482
 483     return $stash;
 484 };
 485
 486
 487 =head2 $c->error
 488
 489 =head2 $c->error($error, ...)
 490
 491 =head2 $c->error($arrayref)
 492
 493 Returns an arrayref containing error messages.  If Catalyst encounters an
 494 error while processing a request, it stores the error in $c->error.  This
 495 method should only be used to store fatal error messages.
 496
 497     my @error = @{ $c->error };
 498
 499 Add a new error.
 500
 501     $c->error('Something bad happened');
 502
 503 =cut
 504
 505 sub error {
 506     my $c = shift;
 507     if ( $_[0] ) {
 508         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 509         croak @$error unless ref $c;
 510         push @{ $c->{error} }, @$error;
 511     }
 512     elsif ( defined $_[0] ) { $c->{error} = undef }
 513     return $c->{error} || [];
 514 }
 515
 516
 517 =head2 $c->state
 518
 519 Contains the return value of the last executed action.
 520 Note that << $c->state >> operates in a scalar context which means that all
 521 values it returns are scalar.
 522
 523 =head2 $c->clear_errors
 524
 525 Clear errors.  You probably don't want to clear the errors unless you are
 526 implementing a custom error screen.
 527
 528 This is equivalent to running
 529
 530     $c->error(0);
 531
 532 =cut
 533
 534 sub clear_errors {
 535     my $c = shift;
 536     $c->error(0);
 537 }
 538
 539 =head2 COMPONENT ACCESSORS
 540
 541 =head2 $c->controller($name)
 542
 543 Gets a L<Catalyst::Controller> instance by name.
 544
 545     $c->controller('Foo')->do_stuff;
 546
 547 If the name is omitted, will return the controller for the dispatched
 548 action.
 549
 550 If you want to search for controllers, pass in a regexp as the argument.
 551
 552     # find all controllers that start with Foo
 553     my @foo_controllers = $c->controller(qr{^Foo});
 554
 555
 556 =cut
 557
 558 sub controller {
 559     my ( $c, $name, @args ) = @_;
 560
 561     return $c->container->get_component_from_sub_container( 'controller', $name, $c, @args)
 562         if( $name );
 563
 564     return $c->component( $c->action->class );
 565 }
 566
 567 =head2 $c->model($name)
 568
 569 Gets a L<Catalyst::Model> instance by name.
 570
 571     $c->model('Foo')->do_stuff;
 572
 573 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 574
 575 If the name is omitted, it will look for
 576  - a model object in $c->stash->{current_model_instance}, then
 577  - a model name in $c->stash->{current_model}, then
 578  - a config setting 'default_model', or
 579  - check if there is only one model, and return it if that's the case.
 580
 581 If you want to search for models, pass in a regexp as the argument.
 582
 583     # find all models that start with Foo
 584     my @foo_models = $c->model(qr{^Foo});
 585
 586 =cut
 587
 588 sub model {
 589     my ( $c, $name, @args ) = @_;
 590     my $appclass = ref($c) || $c;
 591     my $container = $c->container->get_sub_container('model');
 592
 593     return $c->container->get_component_from_sub_container( 'model', $name, $c, @args)
 594         if( $name );
 595
 596     if (ref $c) {
 597         return $c->stash->{current_model_instance}
 598           if $c->stash->{current_model_instance};
 599         return $c->model( $c->stash->{current_model} )
 600           if $c->stash->{current_model};
 601     }
 602     return $c->model( $appclass->config->{default_model} )
 603       if $appclass->config->{default_model};
 604
 605 # FIXME: will this still be mantained?
 606     my( $comp, $rest ) = $container->get_service_list;
 607
 608     if( $rest ) {
 609         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 610         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 611         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 612         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 613         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 614     }
 615
 616     return $container->get_component( $comp, $c, @args );
 617 }
 618
 619
 620 =head2 $c->view($name)
 621
 622 Gets a L<Catalyst::View> instance by name.
 623
 624     $c->view('Foo')->do_stuff;
 625
 626 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 627
 628 If the name is omitted, it will look for
 629  - a view object in $c->stash->{current_view_instance}, then
 630  - a view name in $c->stash->{current_view}, then
 631  - a config setting 'default_view', or
 632  - check if there is only one view, and return it if that's the case.
 633
 634 If you want to search for views, pass in a regexp as the argument.
 635
 636     # find all views that start with Foo
 637     my @foo_views = $c->view(qr{^Foo});
 638
 639 =cut
 640
 641 sub view {
 642     my ( $c, $name, @args ) = @_;
 643     my $appclass = ref($c) || $c;
 644     my $container = $c->container->get_sub_container('view');
 645
 646     return $c->container->get_component_from_sub_container( 'view', $name, $c, @args)
 647         if( $name );
 648
 649     if (ref $c) {
 650         return $c->stash->{current_view_instance}
 651           if $c->stash->{current_view_instance};
 652         return $c->view( $c->stash->{current_view} )
 653           if $c->stash->{current_view};
 654     }
 655     return $c->view( $appclass->config->{default_view} )
 656       if $appclass->config->{default_view};
 657
 658     my( $comp, $rest ) = $container->get_service_list;
 659
 660     if( $rest ) {
 661         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 662         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 663         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 664         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 665         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 666     }
 667
 668     return $container->get_component( $comp, $c, @args );
 669 }
 670
 671 =head2 $c->controllers
 672
 673 Returns the available names which can be passed to $c->controller
 674
 675 =cut
 676
 677 sub controllers {
 678     my ( $c ) = @_;
 679     return $c->container->get_sub_container('controller')->get_service_list;
 680 }
 681
 682 =head2 $c->models
 683
 684 Returns the available names which can be passed to $c->model
 685
 686 =cut
 687
 688 sub models {
 689     my ( $c ) = @_;
 690     return $c->container->get_sub_container('model')->get_service_list;
 691 }
 692
 693
 694 =head2 $c->views
 695
 696 Returns the available names which can be passed to $c->view
 697
 698 =cut
 699
 700 sub views {
 701     my ( $c ) = @_;
 702     return $c->container->get_sub_container('view')->get_service_list;
 703 }
 704
 705 =head2 $c->comp($name)
 706
 707 =head2 $c->component($name)
 708
 709 Gets a component object by name. This method is not recommended,
 710 unless you want to get a specific component by full
 711 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 712 should be used instead.
 713
 714 If C<$name> is a regexp, a list of components matched against the full
 715 component name will be returned.
 716
 717 =cut
 718
 719 sub component {
 720     my ( $c, $component, @args ) = @_;
 721
 722     if ( $component ) {
 723         # FIXME: I probably shouldn't be doing this
 724         return $c->components->{$component}
 725             if exists $c->components->{$component};
 726
 727         my ($type, $name) = _get_component_type_name($component);
 728
 729         if ($type && $c->container->has_sub_container($type)) {
 730             my $container = $c->container->get_sub_container($type);
 731
 732             if( !ref $component && $container->has_service($name) ) {
 733                 return $container->get_component( $name, $c, @args );
 734             }
 735
 736             return $container->get_component_regexp( $name, $c, @args );
 737         }
 738
 739         if (ref $component) {
 740             for my $subcontainer_name (qw/model view controller/) {
 741                 my $subcontainer = $c->container->get_sub_container($subcontainer_name);
 742                 my @components   = $subcontainer->get_service_list;
 743                 my @result       = grep { m{$component} } @components;
 744
 745                 return map { $subcontainer->get_component( $_, $c, @args ) } @result;
 746             }
 747         }
 748
 749         $c->log->warn("Looking for '$component', but nothing was found.");
 750
 751         # I would expect to return an empty list here, but that breaks back-compat
 752     }
 753
 754     # fallback
 755     return sort keys %{ $c->components };
 756 }
 757
 758 =head2 CLASS DATA AND HELPER CLASSES
 759
 760 =head2 $c->config
 761
 762 Returns or takes a hashref containing the application's configuration.
 763
 764     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 765
 766 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 767 like C<myapp.conf> in your applications home directory. See
 768 L<Catalyst::Plugin::ConfigLoader>.
 769
 770 =head3 Cascading configuration
 771
 772 The config method is present on all Catalyst components, and configuration
 773 will be merged when an application is started. Configuration loaded with
 774 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 775 followed by configuration in your top level C<MyApp> class. These two
 776 configurations are merged, and then configuration data whose hash key matches a
 777 component name is merged with configuration for that component.
 778
 779 The configuration for a component is then passed to the C<new> method when a
 780 component is constructed.
 781
 782 For example:
 783
 784     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 785     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 786
 787 will mean that C<MyApp::Model::Foo> receives the following data when
 788 constructed:
 789
 790     MyApp::Model::Foo->new({
 791         bar => 'baz',
 792         quux => 'frob',
 793         overrides => 'me',
 794     });
 795
 796 It's common practice to use a Moose attribute
 797 on the receiving component to access the config value.
 798
 799     package MyApp::Model::Foo;
 800
 801     use Moose;
 802
 803     # this attr will receive 'baz' at construction time
 804     has 'bar' => (
 805         is  => 'rw',
 806         isa => 'Str',
 807     );
 808
 809 You can then get the value 'baz' by calling $c->model('Foo')->bar
 810 (or $self->bar inside code in the model).
 811
 812 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 813 as a way of reading config within your code, as this B<will not> give you the
 814 correctly merged config back. You B<MUST> take the config values supplied to
 815 the constructor and use those instead.
 816
 817 =cut
 818
 819 around config => sub {
 820     my $orig = shift;
 821     my $c = shift;
 822
 823     croak('Setting config after setup has been run is not allowed.')
 824         if ( @_ and $c->setup_finished );
 825
 826     $c->$orig(@_);
 827 };
 828
 829 =head2 $c->log
 830
 831 Returns the logging object instance. Unless it is already set, Catalyst
 832 sets this up with a L<Catalyst::Log> object. To use your own log class,
 833 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 834 C<< __PACKAGE__->setup >>.
 835
 836  __PACKAGE__->log( MyLogger->new );
 837  __PACKAGE__->setup;
 838
 839 And later:
 840
 841     $c->log->info( 'Now logging with my own logger!' );
 842
 843 Your log class should implement the methods described in
 844 L<Catalyst::Log>.
 845
 846
 847 =head2 $c->debug
 848
 849 Returns 1 if debug mode is enabled, 0 otherwise.
 850
 851 You can enable debug mode in several ways:
 852
 853 =over
 854
 855 =item By calling myapp_server.pl with the -d flag
 856
 857 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 858
 859 =item The -Debug option in your MyApp.pm
 860
 861 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 862
 863 =back
 864
 865 The first three also set the log level to 'debug'.
 866
 867 Calling C<< $c->debug(1) >> has no effect.
 868
 869 =cut
 870
 871 sub debug { 0 }
 872
 873 =head2 $c->dispatcher
 874
 875 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 876
 877 =head2 $c->engine
 878
 879 Returns the engine instance. See L<Catalyst::Engine>.
 880
 881
 882 =head2 UTILITY METHODS
 883
 884 =head2 $c->path_to(@path)
 885
 886 Merges C<@path> with C<< $c->config->{home} >> and returns a
 887 L<Path::Class::Dir> object. Note you can usually use this object as
 888 a filename, but sometimes you will have to explicitly stringify it
 889 yourself by calling the C<< ->stringify >> method.
 890
 891 For example:
 892
 893     $c->path_to( 'db', 'sqlite.db' );
 894
 895 =cut
 896
 897 sub path_to {
 898     my ( $c, @path ) = @_;
 899     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 900     if ( -d $path ) { return $path }
 901     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 902 }
 903
 904 =head2 $c->plugin( $name, $class, @args )
 905
 906 Helper method for plugins. It creates a class data accessor/mutator and
 907 loads and instantiates the given class.
 908
 909     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 910
 911     $c->prototype->define_javascript_functions;
 912
 913 B<Note:> This method of adding plugins is deprecated. The ability
 914 to add plugins like this B<will be removed> in a Catalyst 5.81.
 915 Please do not use this functionality in new code.
 916
 917 =cut
 918
 919 sub plugin {
 920     my ( $class, $name, $plugin, @args ) = @_;
 921
 922     # See block comment in t/unit_core_plugin.t
 923     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 924
 925     $class->_register_plugin( $plugin, 1 );
 926
 927     eval { $plugin->import };
 928     $class->mk_classdata($name);
 929     my $obj;
 930     eval { $obj = $plugin->new(@args) };
 931
 932     if ($@) {
 933         Catalyst::Exception->throw( message =>
 934               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 935     }
 936
 937     $class->$name($obj);
 938     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 939       if $class->debug;
 940 }
 941
 942 =head2 MyApp->setup
 943
 944 Initializes the dispatcher and engine, loads any plugins, and loads the
 945 model, view, and controller components. You may also specify an array
 946 of plugins to load here, if you choose to not load them in the C<use
 947 Catalyst> line.
 948
 949     MyApp->setup;
 950     MyApp->setup( qw/-Debug/ );
 951
 952 =cut
 953
 954 sub setup {
 955     my ( $class, @arguments ) = @_;
 956     croak('Running setup more than once')
 957         if ( $class->setup_finished );
 958
 959     unless ( $class->isa('Catalyst') ) {
 960
 961         Catalyst::Exception->throw(
 962             message => qq/'$class' does not inherit from Catalyst/ );
 963     }
 964
 965     if ( $class->arguments ) {
 966         @arguments = ( @arguments, @{ $class->arguments } );
 967     }
 968
 969     # Process options
 970     my $flags = {};
 971
 972     foreach (@arguments) {
 973
 974         if (/^-Debug$/) {
 975             $flags->{log} =
 976               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 977         }
 978         elsif (/^-(\w+)=?(.*)$/) {
 979             $flags->{ lc $1 } = $2;
 980         }
 981         else {
 982             push @{ $flags->{plugins} }, $_;
 983         }
 984     }
 985
 986     $class->setup_config();
 987     $class->setup_home( delete $flags->{home} );
 988
 989     $class->setup_log( delete $flags->{log} );
 990     $class->setup_plugins( delete $flags->{plugins} );
 991     $class->setup_dispatcher( delete $flags->{dispatcher} );
 992     $class->setup_engine( delete $flags->{engine} );
 993     $class->setup_stats( delete $flags->{stats} );
 994
 995     for my $flag ( sort keys %{$flags} ) {
 996
 997         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 998             &$code( $class, delete $flags->{$flag} );
 999         }
1000         else {
1001             $class->log->warn(qq/Unknown flag "$flag"/);
1002         }
1003     }
1004
1005     eval { require Catalyst::Devel; };
1006     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1007         $class->log->warn(<<"EOF");
1008 You are running an old script!
1009
1010   Please update by running (this will overwrite existing files):
1011     catalyst.pl -force -scripts $class
1012
1013   or (this will not overwrite existing files):
1014     catalyst.pl -scripts $class
1015
1016 EOF
1017     }
1018
1019     if ( $class->debug ) {
1020         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1021
1022         if (@plugins) {
1023             my $column_width = Catalyst::Utils::term_width() - 6;
1024             my $t = Text::SimpleTable->new($column_width);
1025             $t->row($_) for @plugins;
1026             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1027         }
1028
1029         my $dispatcher = $class->dispatcher;
1030         my $engine     = $class->engine;
1031         my $home       = $class->config->{home};
1032
1033         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1034         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1035
1036         $home
1037           ? ( -d $home )
1038           ? $class->log->debug(qq/Found home "$home"/)
1039           : $class->log->debug(qq/Home "$home" doesn't exist/)
1040           : $class->log->debug(q/Couldn't find home/);
1041     }
1042
1043     # Call plugins setup, this is stupid and evil.
1044     # Also screws C3 badly on 5.10, hack to avoid.
1045     {
1046         no warnings qw/redefine/;
1047         local *setup = sub { };
1048         $class->setup unless $Catalyst::__AM_RESTARTING;
1049     }
1050
1051     # Initialize our data structure
1052     $class->components( {} );
1053
1054     $class->setup_components;
1055
1056     if ( $class->debug ) {
1057         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1058         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1059         for my $comp ( sort keys %{ $class->components } ) {
1060             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1061             $t->row( $comp, $type );
1062         }
1063         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1064           if ( keys %{ $class->components } );
1065     }
1066
1067     # Add our self to components, since we are also a component
1068     if( $class->isa('Catalyst::Controller') ){
1069       $class->components->{$class} = $class;
1070     }
1071
1072     $class->setup_actions;
1073
1074     if ( $class->debug ) {
1075         my $name = $class->config->{name} || 'Application';
1076         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1077     }
1078
1079     # Make sure that the application class becomes immutable at this point,
1080     B::Hooks::EndOfScope::on_scope_end {
1081         return if $@;
1082         my $meta = Class::MOP::get_metaclass_by_name($class);
1083         if (
1084             $meta->is_immutable
1085             && ! { $meta->immutable_options }->{replace_constructor}
1086             && (
1087                    $class->isa('Class::Accessor::Fast')
1088                 || $class->isa('Class::Accessor')
1089             )
1090         ) {
1091             warn "You made your application class ($class) immutable, "
1092                 . "but did not inline the\nconstructor. "
1093                 . "This will break catalyst, as your app \@ISA "
1094                 . "Class::Accessor(::Fast)?\nPlease pass "
1095                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1096         }
1097         $meta->make_immutable(
1098             replace_constructor => 1,
1099         ) unless $meta->is_immutable;
1100     };
1101
1102     if ($class->config->{case_sensitive}) {
1103         $class->log->warn($class . "->config->{case_sensitive} is set.");
1104         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1105     }
1106
1107     $class->setup_finalize;
1108     # Should be the last thing we do so that user things hooking
1109     # setup_finalize can log..
1110     $class->log->_flush() if $class->log->can('_flush');
1111     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1112 }
1113
1114 =head2 $app->setup_finalize
1115
1116 A hook to attach modifiers to. This method does not do anything except set the
1117 C<setup_finished> accessor.
1118
1119 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1120
1121 Example:
1122
1123     after setup_finalize => sub {
1124         my $app = shift;
1125
1126         ## do stuff here..
1127     };
1128
1129 =cut
1130
1131 sub setup_finalize {
1132     my ($class) = @_;
1133     $class->setup_finished(1);
1134 }
1135
1136 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1137
1138 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1139
1140 Constructs an absolute L<URI> object based on the application root, the
1141 provided path, and the additional arguments and query parameters provided.
1142 When used as a string, provides a textual URI.  If you need more flexibility
1143 than this (i.e. the option to provide relative URIs etc.) see
1144 L<Catalyst::Plugin::SmartURI>.
1145
1146 If no arguments are provided, the URI for the current action is returned.
1147 To return the current action and also provide @args, use
1148 C<< $c->uri_for( $c->action, @args ) >>.
1149
1150 If the first argument is a string, it is taken as a public URI path relative
1151 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1152 relative to the application root (if it does). It is then merged with
1153 C<< $c->request->base >>; any C<@args> are appended as additional path
1154 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1155
1156 If the first argument is a L<Catalyst::Action> it represents an action which
1157 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1158 optional C<\@captures> argument (an arrayref) allows passing the captured
1159 variables that are needed to fill in the paths of Chained and Regex actions;
1160 once the path is resolved, C<uri_for> continues as though a path was
1161 provided, appending any arguments or parameters and creating an absolute
1162 URI.
1163
1164 The captures for the current request can be found in
1165 C<< $c->request->captures >>, and actions can be resolved using
1166 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1167 path, use C<< $c->uri_for_action >> instead.
1168
1169   # Equivalent to $c->req->uri
1170   $c->uri_for($c->action, $c->req->captures,
1171       @{ $c->req->args }, $c->req->params);
1172
1173   # For the Foo action in the Bar controller
1174   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1175
1176   # Path to a static resource
1177   $c->uri_for('/static/images/logo.png');
1178
1179 =cut
1180
1181 sub uri_for {
1182     my ( $c, $path, @args ) = @_;
1183
1184     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1185         $path = $path->path_prefix;
1186         $path =~ s{/+\z}{};
1187         $path .= '/';
1188     }
1189
1190     undef($path) if (defined $path && $path eq '');
1191
1192     my $params =
1193       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1194
1195     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1196     foreach my $arg (@args) {
1197         utf8::encode($arg) if utf8::is_utf8($arg);
1198         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1199     }
1200
1201     if ( blessed($path) ) { # action object
1202         s|/|%2F|g for @args;
1203         my $captures = [ map { s|/|%2F|g; $_; }
1204                         ( scalar @args && ref $args[0] eq 'ARRAY'
1205                          ? @{ shift(@args) }
1206                          : ()) ];
1207
1208         foreach my $capture (@$captures) {
1209             utf8::encode($capture) if utf8::is_utf8($capture);
1210             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1211         }
1212
1213         my $action = $path;
1214         $path = $c->dispatcher->uri_for_action($action, $captures);
1215         if (not defined $path) {
1216             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1217                 if $c->debug;
1218             return undef;
1219         }
1220         $path = '/' if $path eq '';
1221     }
1222
1223     unshift(@args, $path);
1224
1225     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1226         my $namespace = $c->namespace;
1227         if (defined $path) { # cheesy hack to handle path '../foo'
1228            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1229         }
1230         unshift(@args, $namespace || '');
1231     }
1232
1233     # join args with '/', or a blank string
1234     my $args = join('/', grep { defined($_) } @args);
1235     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1236     $args =~ s!^/+!!;
1237     my $base = $c->req->base;
1238     my $class = ref($base);
1239     $base =~ s{(?<!/)$}{/};
1240
1241     my $query = '';
1242
1243     if (my @keys = keys %$params) {
1244       # somewhat lifted from URI::_query's query_form
1245       $query = '?'.join('&', map {
1246           my $val = $params->{$_};
1247           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1248           s/ /+/g;
1249           my $key = $_;
1250           $val = '' unless defined $val;
1251           (map {
1252               my $param = "$_";
1253               utf8::encode( $param ) if utf8::is_utf8($param);
1254               # using the URI::Escape pattern here so utf8 chars survive
1255               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1256               $param =~ s/ /+/g;
1257               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1258       } @keys);
1259     }
1260
1261     my $res = bless(\"${base}${args}${query}", $class);
1262     $res;
1263 }
1264
1265 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1266
1267 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1268
1269 =over
1270
1271 =item $path
1272
1273 A private path to the Catalyst action you want to create a URI for.
1274
1275 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1276 >> and passing the resulting C<$action> and the remaining arguments to C<<
1277 $c->uri_for >>.
1278
1279 You can also pass in a Catalyst::Action object, in which case it is passed to
1280 C<< $c->uri_for >>.
1281
1282 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1283
1284 For example, if the action looks like:
1285
1286  package MyApp::Controller::Users;
1287
1288  sub lst : Path('the-list') {}
1289
1290 You can use:
1291
1292  $c->uri_for_action('/users/lst')
1293
1294 and it will create the URI /users/the-list.
1295
1296 =back
1297
1298 =cut
1299
1300 sub uri_for_action {
1301     my ( $c, $path, @args ) = @_;
1302     my $action = blessed($path)
1303       ? $path
1304       : $c->dispatcher->get_action_by_path($path);
1305     unless (defined $action) {
1306       croak "Can't find action for path '$path'";
1307     }
1308     return $c->uri_for( $action, @args );
1309 }
1310
1311 =head2 $c->welcome_message
1312
1313 Returns the Catalyst welcome HTML page.
1314
1315 =cut
1316
1317 sub welcome_message {
1318     my $c      = shift;
1319     my $name   = $c->config->{name};
1320     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1321     my $prefix = Catalyst::Utils::appprefix( ref $c );
1322     $c->response->content_type('text/html; charset=utf-8');
1323     return <<"EOF";
1324 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1325     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1326 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1327     <head>
1328     <meta http-equiv="Content-Language" content="en" />
1329     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1330         <title>$name on Catalyst $VERSION</title>
1331         <style type="text/css">
1332             body {
1333                 color: #000;
1334                 background-color: #eee;
1335             }
1336             div#content {
1337                 width: 640px;
1338                 margin-left: auto;
1339                 margin-right: auto;
1340                 margin-top: 10px;
1341                 margin-bottom: 10px;
1342                 text-align: left;
1343                 background-color: #ccc;
1344                 border: 1px solid #aaa;
1345             }
1346             p, h1, h2 {
1347                 margin-left: 20px;
1348                 margin-right: 20px;
1349                 font-family: verdana, tahoma, sans-serif;
1350             }
1351             a {
1352                 font-family: verdana, tahoma, sans-serif;
1353             }
1354             :link, :visited {
1355                     text-decoration: none;
1356                     color: #b00;
1357                     border-bottom: 1px dotted #bbb;
1358             }
1359             :link:hover, :visited:hover {
1360                     color: #555;
1361             }
1362             div#topbar {
1363                 margin: 0px;
1364             }
1365             pre {
1366                 margin: 10px;
1367                 padding: 8px;
1368             }
1369             div#answers {
1370                 padding: 8px;
1371                 margin: 10px;
1372                 background-color: #fff;
1373                 border: 1px solid #aaa;
1374             }
1375             h1 {
1376                 font-size: 0.9em;
1377                 font-weight: normal;
1378                 text-align: center;
1379             }
1380             h2 {
1381                 font-size: 1.0em;
1382             }
1383             p {
1384                 font-size: 0.9em;
1385             }
1386             p img {
1387                 float: right;
1388                 margin-left: 10px;
1389             }
1390             span#appname {
1391                 font-weight: bold;
1392                 font-size: 1.6em;
1393             }
1394         </style>
1395     </head>
1396     <body>
1397         <div id="content">
1398             <div id="topbar">
1399                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1400                     $VERSION</h1>
1401              </div>
1402              <div id="answers">
1403                  <p>
1404                  <img src="$logo" alt="Catalyst Logo" />
1405                  </p>
1406                  <p>Welcome to the  world of Catalyst.
1407                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1408                     framework will make web development something you had
1409                     never expected it to be: Fun, rewarding, and quick.</p>
1410                  <h2>What to do now?</h2>
1411                  <p>That really depends  on what <b>you</b> want to do.
1412                     We do, however, provide you with a few starting points.</p>
1413                  <p>If you want to jump right into web development with Catalyst
1414                     you might want to start with a tutorial.</p>
1415 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1416 </pre>
1417 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1418 <pre>
1419 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1420 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1421 </code></pre>
1422                  <h2>What to do next?</h2>
1423                  <p>Next it's time to write an actual application. Use the
1424                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1425                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1426                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1427                     they can save you a lot of work.</p>
1428                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1429                     <p>Also, be sure to check out the vast and growing
1430                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1431                     you are likely to find what you need there.
1432                     </p>
1433
1434                  <h2>Need help?</h2>
1435                  <p>Catalyst has a very active community. Here are the main places to
1436                     get in touch with us.</p>
1437                  <ul>
1438                      <li>
1439                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1440                      </li>
1441                      <li>
1442                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1443                      </li>
1444                      <li>
1445                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1446                      </li>
1447                  </ul>
1448                  <h2>In conclusion</h2>
1449                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1450                     as we enjoyed making it. Please contact us if you have ideas
1451                     for improvement or other feedback.</p>
1452              </div>
1453          </div>
1454     </body>
1455 </html>
1456 EOF
1457 }
1458
1459 =head1 INTERNAL METHODS
1460
1461 These methods are not meant to be used by end users.
1462
1463 =head2 $c->components
1464
1465 Returns a hash of components.
1466
1467 =cut
1468
1469 around components => sub {
1470     my $orig  = shift;
1471     my $class = shift;
1472     my $comps = shift;
1473
1474     return $class->$orig if ( !$comps );
1475
1476 # FIXME: should this ugly kludge exist?
1477     $class->setup_config unless defined $class->container;
1478
1479 # FIXME: should there be a warning here, not to use this accessor to create the components?
1480     my $components = {};
1481
1482     my $containers;
1483     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
1484
1485     for my $component ( keys %$comps ) {
1486         $components->{ $component } = $comps->{$component};
1487
1488         my ($type, $name) = _get_component_type_name($component);
1489
1490 # FIXME: shouldn't the service name be $name?
1491         $containers->{$type}->add_service(Catalyst::IOC::BlockInjection->new( name => $name, block => sub { return $class->setup_component($component) } ));
1492     }
1493
1494     return $class->$orig($components);
1495 };
1496
1497 =head2 $c->context_class
1498
1499 Returns or sets the context class.
1500
1501 =head2 $c->counter
1502
1503 Returns a hashref containing coderefs and execution counts (needed for
1504 deep recursion detection).
1505
1506 =head2 $c->depth
1507
1508 Returns the number of actions on the current internal execution stack.
1509
1510 =head2 $c->dispatch
1511
1512 Dispatches a request to actions.
1513
1514 =cut
1515
1516 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1517
1518 =head2 $c->dispatcher_class
1519
1520 Returns or sets the dispatcher class.
1521
1522 =head2 $c->dump_these
1523
1524 Returns a list of 2-element array references (name, structure) pairs
1525 that will be dumped on the error page in debug mode.
1526
1527 =cut
1528
1529 sub dump_these {
1530     my $c = shift;
1531     [ Request => $c->req ],
1532     [ Response => $c->res ],
1533     [ Stash => $c->stash ],
1534     [ Config => $c->config ];
1535 }
1536
1537 =head2 $c->engine_class
1538
1539 Returns or sets the engine class.
1540
1541 =head2 $c->execute( $class, $coderef )
1542
1543 Execute a coderef in given class and catch exceptions. Errors are available
1544 via $c->error.
1545
1546 =cut
1547
1548 sub execute {
1549     my ( $c, $class, $code ) = @_;
1550     $class = $c->component($class) || $class;
1551     $c->state(0);
1552
1553     if ( $c->depth >= $RECURSION ) {
1554         my $action = $code->reverse();
1555         $action = "/$action" unless $action =~ /->/;
1556         my $error = qq/Deep recursion detected calling "${action}"/;
1557         $c->log->error($error);
1558         $c->error($error);
1559         $c->state(0);
1560         return $c->state;
1561     }
1562
1563     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1564
1565     push( @{ $c->stack }, $code );
1566
1567     no warnings 'recursion';
1568     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1569     #      I have no idea how, ergo $ret (which appears to fix the issue)
1570     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1571
1572     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1573
1574     my $last = pop( @{ $c->stack } );
1575
1576     if ( my $error = $@ ) {
1577         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1578             $error->rethrow if $c->depth > 1;
1579         }
1580         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1581             $error->rethrow if $c->depth > 0;
1582         }
1583         else {
1584             unless ( ref $error ) {
1585                 no warnings 'uninitialized';
1586                 chomp $error;
1587                 my $class = $last->class;
1588                 my $name  = $last->name;
1589                 $error = qq/Caught exception in $class->$name "$error"/;
1590             }
1591             $c->error($error);
1592         }
1593         $c->state(0);
1594     }
1595     return $c->state;
1596 }
1597
1598 sub _stats_start_execute {
1599     my ( $c, $code ) = @_;
1600     my $appclass = ref($c) || $c;
1601     return if ( ( $code->name =~ /^_.*/ )
1602         && ( !$appclass->config->{show_internal_actions} ) );
1603
1604     my $action_name = $code->reverse();
1605     $c->counter->{$action_name}++;
1606
1607     my $action = $action_name;
1608     $action = "/$action" unless $action =~ /->/;
1609
1610     # determine if the call was the result of a forward
1611     # this is done by walking up the call stack and looking for a calling
1612     # sub of Catalyst::forward before the eval
1613     my $callsub = q{};
1614     for my $index ( 2 .. 11 ) {
1615         last
1616         if ( ( caller($index) )[0] eq 'Catalyst'
1617             && ( caller($index) )[3] eq '(eval)' );
1618
1619         if ( ( caller($index) )[3] =~ /forward$/ ) {
1620             $callsub = ( caller($index) )[3];
1621             $action  = "-> $action";
1622             last;
1623         }
1624     }
1625
1626     my $uid = $action_name . $c->counter->{$action_name};
1627
1628     # is this a root-level call or a forwarded call?
1629     if ( $callsub =~ /forward$/ ) {
1630         my $parent = $c->stack->[-1];
1631
1632         # forward, locate the caller
1633         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1634             $c->stats->profile(
1635                 begin  => $action,
1636                 parent => "$parent" . $c->counter->{"$parent"},
1637                 uid    => $uid,
1638             );
1639         }
1640         else {
1641
1642             # forward with no caller may come from a plugin
1643             $c->stats->profile(
1644                 begin => $action,
1645                 uid   => $uid,
1646             );
1647         }
1648     }
1649     else {
1650
1651         # root-level call
1652         $c->stats->profile(
1653             begin => $action,
1654             uid   => $uid,
1655         );
1656     }
1657     return $action;
1658
1659 }
1660
1661 sub _stats_finish_execute {
1662     my ( $c, $info ) = @_;
1663     $c->stats->profile( end => $info );
1664 }
1665
1666 =head2 $c->finalize
1667
1668 Finalizes the request.
1669
1670 =cut
1671
1672 sub finalize {
1673     my $c = shift;
1674
1675     for my $error ( @{ $c->error } ) {
1676         $c->log->error($error);
1677     }
1678
1679     # Allow engine to handle finalize flow (for POE)
1680     my $engine = $c->engine;
1681     if ( my $code = $engine->can('finalize') ) {
1682         $engine->$code($c);
1683     }
1684     else {
1685
1686         $c->finalize_uploads;
1687
1688         # Error
1689         if ( $#{ $c->error } >= 0 ) {
1690             $c->finalize_error;
1691         }
1692
1693         $c->finalize_headers;
1694
1695         # HEAD request
1696         if ( $c->request->method eq 'HEAD' ) {
1697             $c->response->body('');
1698         }
1699
1700         $c->finalize_body;
1701     }
1702
1703     $c->log_response;
1704
1705     if ($c->use_stats) {
1706         my $elapsed = sprintf '%f', $c->stats->elapsed;
1707         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1708         $c->log->info(
1709             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1710     }
1711
1712     return $c->response->status;
1713 }
1714
1715 =head2 $c->finalize_body
1716
1717 Finalizes body.
1718
1719 =cut
1720
1721 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1722
1723 =head2 $c->finalize_cookies
1724
1725 Finalizes cookies.
1726
1727 =cut
1728
1729 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1730
1731 =head2 $c->finalize_error
1732
1733 Finalizes error.
1734
1735 =cut
1736
1737 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1738
1739 =head2 $c->finalize_headers
1740
1741 Finalizes headers.
1742
1743 =cut
1744
1745 sub finalize_headers {
1746     my $c = shift;
1747
1748     my $response = $c->response; #accessor calls can add up?
1749
1750     # Check if we already finalized headers
1751     return if $response->finalized_headers;
1752
1753     # Handle redirects
1754     if ( my $location = $response->redirect ) {
1755         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1756         $response->header( Location => $location );
1757
1758         if ( !$response->has_body ) {
1759             # Add a default body if none is already present
1760             $response->body(
1761                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1762             );
1763         }
1764     }
1765
1766     # Content-Length
1767     if ( defined $response->body && length $response->body && !$response->content_length ) {
1768
1769         # get the length from a filehandle
1770         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1771         {
1772             my $stat = stat $response->body;
1773             if ( $stat && $stat->size > 0 ) {
1774                 $response->content_length( $stat->size );
1775             }
1776             else {
1777                 $c->log->warn('Serving filehandle without a content-length');
1778             }
1779         }
1780         else {
1781             # everything should be bytes at this point, but just in case
1782             $response->content_length( length( $response->body ) );
1783         }
1784     }
1785
1786     # Errors
1787     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1788         $response->headers->remove_header("Content-Length");
1789         $response->body('');
1790     }
1791
1792     $c->finalize_cookies;
1793
1794     $c->engine->finalize_headers( $c, @_ );
1795
1796     # Done
1797     $response->finalized_headers(1);
1798 }
1799
1800 =head2 $c->finalize_output
1801
1802 An alias for finalize_body.
1803
1804 =head2 $c->finalize_read
1805
1806 Finalizes the input after reading is complete.
1807
1808 =cut
1809
1810 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1811
1812 =head2 $c->finalize_uploads
1813
1814 Finalizes uploads. Cleans up any temporary files.
1815
1816 =cut
1817
1818 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1819
1820 =head2 $c->get_action( $action, $namespace )
1821
1822 Gets an action in a given namespace.
1823
1824 =cut
1825
1826 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1827
1828 =head2 $c->get_actions( $action, $namespace )
1829
1830 Gets all actions of a given name in a namespace and all parent
1831 namespaces.
1832
1833 =cut
1834
1835 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1836
1837 =head2 $app->handle_request( @arguments )
1838
1839 Called to handle each HTTP request.
1840
1841 =cut
1842
1843 sub handle_request {
1844     my ( $class, @arguments ) = @_;
1845
1846     # Always expect worst case!
1847     my $status = -1;
1848     eval {
1849         if ($class->debug) {
1850             my $secs = time - $START || 1;
1851             my $av = sprintf '%.3f', $COUNT / $secs;
1852             my $time = localtime time;
1853             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1854         }
1855
1856         my $c = $class->prepare(@arguments);
1857         $c->dispatch;
1858         $status = $c->finalize;
1859     };
1860
1861     if ( my $error = $@ ) {
1862         chomp $error;
1863         $class->log->error(qq/Caught exception in engine "$error"/);
1864     }
1865
1866     $COUNT++;
1867
1868     if(my $coderef = $class->log->can('_flush')){
1869         $class->log->$coderef();
1870     }
1871     return $status;
1872 }
1873
1874 =head2 $c->prepare( @arguments )
1875
1876 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1877 etc.).
1878
1879 =cut
1880
1881 sub prepare {
1882     my ( $class, @arguments ) = @_;
1883
1884     # XXX
1885     # After the app/ctxt split, this should become an attribute based on something passed
1886     # into the application.
1887     $class->context_class( ref $class || $class ) unless $class->context_class;
1888
1889     my $c = $class->context_class->new({});
1890
1891     # For on-demand data
1892     $c->request->_context($c);
1893     $c->response->_context($c);
1894
1895     #surely this is not the most efficient way to do things...
1896     $c->stats($class->stats_class->new)->enable($c->use_stats);
1897     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1898         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1899     }
1900
1901     #XXX reuse coderef from can
1902     # Allow engine to direct the prepare flow (for POE)
1903     if ( $c->engine->can('prepare') ) {
1904         $c->engine->prepare( $c, @arguments );
1905     }
1906     else {
1907         $c->prepare_request(@arguments);
1908         $c->prepare_connection;
1909         $c->prepare_query_parameters;
1910         $c->prepare_headers;
1911         $c->prepare_cookies;
1912         $c->prepare_path;
1913
1914         # Prepare the body for reading, either by prepare_body
1915         # or the user, if they are using $c->read
1916         $c->prepare_read;
1917
1918         # Parse the body unless the user wants it on-demand
1919         unless ( ref($c)->config->{parse_on_demand} ) {
1920             $c->prepare_body;
1921         }
1922     }
1923
1924     my $method  = $c->req->method  || '';
1925     my $path    = $c->req->path;
1926     $path       = '/' unless length $path;
1927     my $address = $c->req->address || '';
1928
1929     $c->log_request;
1930
1931     $c->prepare_action;
1932
1933     return $c;
1934 }
1935
1936 =head2 $c->prepare_action
1937
1938 Prepares action. See L<Catalyst::Dispatcher>.
1939
1940 =cut
1941
1942 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1943
1944 =head2 $c->prepare_body
1945
1946 Prepares message body.
1947
1948 =cut
1949
1950 sub prepare_body {
1951     my $c = shift;
1952
1953     return if $c->request->_has_body;
1954
1955     # Initialize on-demand data
1956     $c->engine->prepare_body( $c, @_ );
1957     $c->prepare_parameters;
1958     $c->prepare_uploads;
1959 }
1960
1961 =head2 $c->prepare_body_chunk( $chunk )
1962
1963 Prepares a chunk of data before sending it to L<HTTP::Body>.
1964
1965 See L<Catalyst::Engine>.
1966
1967 =cut
1968
1969 sub prepare_body_chunk {
1970     my $c = shift;
1971     $c->engine->prepare_body_chunk( $c, @_ );
1972 }
1973
1974 =head2 $c->prepare_body_parameters
1975
1976 Prepares body parameters.
1977
1978 =cut
1979
1980 sub prepare_body_parameters {
1981     my $c = shift;
1982     $c->engine->prepare_body_parameters( $c, @_ );
1983 }
1984
1985 =head2 $c->prepare_connection
1986
1987 Prepares connection.
1988
1989 =cut
1990
1991 sub prepare_connection {
1992     my $c = shift;
1993     $c->engine->prepare_connection( $c, @_ );
1994 }
1995
1996 =head2 $c->prepare_cookies
1997
1998 Prepares cookies.
1999
2000 =cut
2001
2002 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2003
2004 =head2 $c->prepare_headers
2005
2006 Prepares headers.
2007
2008 =cut
2009
2010 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2011
2012 =head2 $c->prepare_parameters
2013
2014 Prepares parameters.
2015
2016 =cut
2017
2018 sub prepare_parameters {
2019     my $c = shift;
2020     $c->prepare_body_parameters;
2021     $c->engine->prepare_parameters( $c, @_ );
2022 }
2023
2024 =head2 $c->prepare_path
2025
2026 Prepares path and base.
2027
2028 =cut
2029
2030 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2031
2032 =head2 $c->prepare_query_parameters
2033
2034 Prepares query parameters.
2035
2036 =cut
2037
2038 sub prepare_query_parameters {
2039     my $c = shift;
2040
2041     $c->engine->prepare_query_parameters( $c, @_ );
2042 }
2043
2044 =head2 $c->log_request
2045
2046 Writes information about the request to the debug logs.  This includes:
2047
2048 =over 4
2049
2050 =item * Request method, path, and remote IP address
2051
2052 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2053
2054 =item * Request parameters
2055
2056 =item * File uploads
2057
2058 =back
2059
2060 =cut
2061
2062 sub log_request {
2063     my $c = shift;
2064
2065     return unless $c->debug;
2066
2067     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2068     my $request = $dump->[1];
2069
2070     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2071     $method ||= '';
2072     $path = '/' unless length $path;
2073     $address ||= '';
2074     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2075
2076     $c->log_request_headers($request->headers);
2077
2078     if ( my $keywords = $request->query_keywords ) {
2079         $c->log->debug("Query keywords are: $keywords");
2080     }
2081
2082     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2083
2084     $c->log_request_uploads($request);
2085 }
2086
2087 =head2 $c->log_response
2088
2089 Writes information about the response to the debug logs by calling
2090 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2091
2092 =cut
2093
2094 sub log_response {
2095     my $c = shift;
2096
2097     return unless $c->debug;
2098
2099     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2100     my $response = $dump->[1];
2101
2102     $c->log_response_status_line($response);
2103     $c->log_response_headers($response->headers);
2104 }
2105
2106 =head2 $c->log_response_status_line($response)
2107
2108 Writes one line of information about the response to the debug logs.  This includes:
2109
2110 =over 4
2111
2112 =item * Response status code
2113
2114 =item * Content-Type header (if present)
2115
2116 =item * Content-Length header (if present)
2117
2118 =back
2119
2120 =cut
2121
2122 sub log_response_status_line {
2123     my ($c, $response) = @_;
2124
2125     $c->log->debug(
2126         sprintf(
2127             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2128             $response->status                            || 'unknown',
2129             $response->headers->header('Content-Type')   || 'unknown',
2130             $response->headers->header('Content-Length') || 'unknown'
2131         )
2132     );
2133 }
2134
2135 =head2 $c->log_response_headers($headers);
2136
2137 Hook method which can be wrapped by plugins to log the responseheaders.
2138 No-op in the default implementation.
2139
2140 =cut
2141
2142 sub log_response_headers {}
2143
2144 =head2 $c->log_request_parameters( query => {}, body => {} )
2145
2146 Logs request parameters to debug logs
2147
2148 =cut
2149
2150 sub log_request_parameters {
2151     my $c          = shift;
2152     my %all_params = @_;
2153
2154     return unless $c->debug;
2155
2156     my $column_width = Catalyst::Utils::term_width() - 44;
2157     foreach my $type (qw(query body)) {
2158         my $params = $all_params{$type};
2159         next if ! keys %$params;
2160         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2161         for my $key ( sort keys %$params ) {
2162             my $param = $params->{$key};
2163             my $value = defined($param) ? $param : '';
2164             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2165         }
2166         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2167     }
2168 }
2169
2170 =head2 $c->log_request_uploads
2171
2172 Logs file uploads included in the request to the debug logs.
2173 The parameter name, filename, file type, and file size are all included in
2174 the debug logs.
2175
2176 =cut
2177
2178 sub log_request_uploads {
2179     my $c = shift;
2180     my $request = shift;
2181     return unless $c->debug;
2182     my $uploads = $request->uploads;
2183     if ( keys %$uploads ) {
2184         my $t = Text::SimpleTable->new(
2185             [ 12, 'Parameter' ],
2186             [ 26, 'Filename' ],
2187             [ 18, 'Type' ],
2188             [ 9,  'Size' ]
2189         );
2190         for my $key ( sort keys %$uploads ) {
2191             my $upload = $uploads->{$key};
2192             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2193                 $t->row( $key, $u->filename, $u->type, $u->size );
2194             }
2195         }
2196         $c->log->debug( "File Uploads are:\n" . $t->draw );
2197     }
2198 }
2199
2200 =head2 $c->log_request_headers($headers);
2201
2202 Hook method which can be wrapped by plugins to log the request headers.
2203 No-op in the default implementation.
2204
2205 =cut
2206
2207 sub log_request_headers {}
2208
2209 =head2 $c->log_headers($type => $headers)
2210
2211 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2212
2213 =cut
2214
2215 sub log_headers {
2216     my $c       = shift;
2217     my $type    = shift;
2218     my $headers = shift;    # an HTTP::Headers instance
2219
2220     return unless $c->debug;
2221
2222     my $column_width = Catalyst::Utils::term_width() - 28;
2223     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2224     $headers->scan(
2225         sub {
2226             my ( $name, $value ) = @_;
2227             $t->row( $name, $value );
2228         }
2229     );
2230     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2231 }
2232
2233
2234 =head2 $c->prepare_read
2235
2236 Prepares the input for reading.
2237
2238 =cut
2239
2240 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2241
2242 =head2 $c->prepare_request
2243
2244 Prepares the engine request.
2245
2246 =cut
2247
2248 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2249
2250 =head2 $c->prepare_uploads
2251
2252 Prepares uploads.
2253
2254 =cut
2255
2256 sub prepare_uploads {
2257     my $c = shift;
2258
2259     $c->engine->prepare_uploads( $c, @_ );
2260 }
2261
2262 =head2 $c->prepare_write
2263
2264 Prepares the output for writing.
2265
2266 =cut
2267
2268 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2269
2270 =head2 $c->request_class
2271
2272 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2273
2274 =head2 $c->response_class
2275
2276 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2277
2278 =head2 $c->read( [$maxlength] )
2279
2280 Reads a chunk of data from the request body. This method is designed to
2281 be used in a while loop, reading C<$maxlength> bytes on every call.
2282 C<$maxlength> defaults to the size of the request if not specified.
2283
2284 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2285 directly.
2286
2287 Warning: If you use read(), Catalyst will not process the body,
2288 so you will not be able to access POST parameters or file uploads via
2289 $c->request.  You must handle all body parsing yourself.
2290
2291 =cut
2292
2293 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2294
2295 =head2 $c->run
2296
2297 Starts the engine.
2298
2299 =cut
2300
2301 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2302
2303 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2304
2305 Sets an action in a given namespace.
2306
2307 =cut
2308
2309 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2310
2311 =head2 $c->setup_actions($component)
2312
2313 Sets up actions for a component.
2314
2315 =cut
2316
2317 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2318
2319 =head2 $c->setup_config
2320
2321 =cut
2322
2323 sub setup_config {
2324     my $class = shift;
2325
2326     my %args = %{ $class->config || {} };
2327
2328     my @container_classes = ( "${class}::Container", 'Catalyst::IOC::Container');
2329     unshift @container_classes, delete $args{container_class} if exists $args{container_class};
2330
2331     my $container_class = Class::MOP::load_first_existing_class(@container_classes);
2332
2333     my $container = $container_class->new( %args, name => "$class" );
2334     $class->container($container);
2335
2336     my $config = $container->resolve(service => 'config');
2337     $class->config($config);
2338     $class->finalize_config; # back-compat
2339 }
2340
2341 =head2 $c->finalize_config
2342
2343 =cut
2344
2345 sub finalize_config { }
2346
2347 =head2 $c->setup_components
2348
2349 This method is called internally to set up the application's components.
2350
2351 It finds modules by calling the L<locate_components> method, expands them to
2352 package names with the L<expand_component_module> method, and then installs
2353 each component into the application.
2354
2355 The C<setup_components> config option is passed to both of the above methods.
2356
2357 Installation of each component is performed by the L<setup_component> method,
2358 below.
2359
2360 =cut
2361
2362 sub setup_components {
2363     my $class = shift;
2364
2365     my $config  = $class->config->{ setup_components };
2366
2367     my @comps = $class->locate_components($config);
2368     my %comps = map { $_ => 1 } @comps;
2369
2370     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2371     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2372         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2373     ) if $deprecatedcatalyst_component_names;
2374
2375     for my $component ( @comps ) {
2376
2377         # We pass ignore_loaded here so that overlay files for (e.g.)
2378         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2379         # we know M::P::O found a file on disk so this is safe
2380
2381         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2382     }
2383
2384     my $containers;
2385     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
2386
2387     for my $component (@comps) {
2388         my $instance = $class->components->{ $component } = $class->setup_component($component);
2389         if ( my ($type, $name) = _get_component_type_name($component) ) {
2390             $containers->{$type}->add_service(Catalyst::IOC::BlockInjection->new( name => $name, block => sub { return $instance } ));
2391         }
2392         my @expanded_components = $instance->can('expand_modules')
2393             ? $instance->expand_modules( $component, $config )
2394             : $class->expand_component_module( $component, $config );
2395         for my $component (@expanded_components) {
2396             next if $comps{$component};
2397
2398             $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @expanded_components;
2399             $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2400                 qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2401             ) if $deprecatedcatalyst_component_names;
2402
2403             if (my ($type, $name) = _get_component_type_name($component)) {
2404                 $containers->{$type}->add_service(Catalyst::IOC::BlockInjection->new( name => $name, block => sub { return $class->setup_component($component) } ));
2405             }
2406
2407             $class->components->{ $component } = $class->setup_component($component);
2408         }
2409     }
2410 }
2411
2412 sub _get_component_type_name {
2413     my $component = shift;
2414     my @parts     = split /::/, $component;
2415
2416     while (my $type = shift @parts) {
2417         return ('controller', join '::', @parts)
2418             if $type =~ /^(c|controller)$/i;
2419
2420         return ('model', join '::', @parts)
2421             if $type =~ /^(m|model)$/i;
2422
2423         return ('view', join '::', @parts)
2424             if $type =~ /^(v|view)$/i;
2425     }
2426 }
2427
2428 =head2 $c->locate_components( $setup_component_config )
2429
2430 This method is meant to provide a list of component modules that should be
2431 setup for the application.  By default, it will use L<Module::Pluggable>.
2432
2433 Specify a C<setup_components> config option to pass additional options directly
2434 to L<Module::Pluggable>. To add additional search paths, specify a key named
2435 C<search_extra> as an array reference. Items in the array beginning with C<::>
2436 will have the application class name prepended to them.
2437
2438 =cut
2439
2440 sub locate_components {
2441     my $class  = shift;
2442     my $config = shift;
2443
2444     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2445     my $extra   = delete $config->{ search_extra } || [];
2446
2447     push @paths, @$extra;
2448
2449     my $locator = Module::Pluggable::Object->new(
2450         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2451         %$config
2452     );
2453
2454     # XXX think about ditching this sort entirely
2455     my @comps = sort { length $a <=> length $b } $locator->plugins;
2456
2457     return @comps;
2458 }
2459
2460 =head2 $c->expand_component_module( $component, $setup_component_config )
2461
2462 Components found by C<locate_components> will be passed to this method, which
2463 is expected to return a list of component (package) names to be set up.
2464
2465 =cut
2466
2467 sub expand_component_module {
2468     my ($class, $module) = @_;
2469     return Devel::InnerPackage::list_packages( $module );
2470 }
2471
2472 =head2 $c->setup_component
2473
2474 =cut
2475
2476 sub setup_component {
2477     my( $class, $component ) = @_;
2478
2479     unless ( $component->can( 'COMPONENT' ) ) {
2480         return $component;
2481     }
2482
2483     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2484     my $config = $class->config->{ $suffix } || {};
2485     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2486     # methods also pass it. local to avoid pointlessly shitting in config
2487     # for the debug screen, as $component is already the key name.
2488     local $config->{catalyst_component_name} = $component;
2489
2490     my $instance = eval { $component->COMPONENT( $class, $config ); };
2491
2492     if ( my $error = $@ ) {
2493         chomp $error;
2494         Catalyst::Exception->throw(
2495             message => qq/Couldn't instantiate component "$component", "$error"/
2496         );
2497     }
2498     elsif (!blessed $instance) {
2499         my $metaclass = Moose::Util::find_meta($component);
2500         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2501         my $component_method_from = $method_meta->associated_metaclass->name;
2502         my $value = defined($instance) ? $instance : 'undef';
2503         Catalyst::Exception->throw(
2504             message =>
2505             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2506         );
2507     }
2508
2509     return $instance;
2510 }
2511
2512 =head2 $c->setup_dispatcher
2513
2514 Sets up dispatcher.
2515
2516 =cut
2517
2518 sub setup_dispatcher {
2519     my ( $class, $dispatcher ) = @_;
2520
2521     if ($dispatcher) {
2522         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2523     }
2524
2525     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2526         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2527     }
2528
2529     unless ($dispatcher) {
2530         $dispatcher = $class->dispatcher_class;
2531     }
2532
2533     Class::MOP::load_class($dispatcher);
2534
2535     # dispatcher instance
2536     $class->dispatcher( $dispatcher->new );
2537 }
2538
2539 =head2 $c->setup_engine
2540
2541 Sets up engine.
2542
2543 =cut
2544
2545 sub setup_engine {
2546     my ( $class, $engine ) = @_;
2547
2548     if ($engine) {
2549         $engine = 'Catalyst::Engine::' . $engine;
2550     }
2551
2552     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2553         $engine = 'Catalyst::Engine::' . $env;
2554     }
2555
2556     if ( $ENV{MOD_PERL} ) {
2557         my $meta = Class::MOP::get_metaclass_by_name($class);
2558
2559         # create the apache method
2560         $meta->add_method('apache' => sub { shift->engine->apache });
2561
2562         my ( $software, $version ) =
2563           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2564
2565         $version =~ s/_//g;
2566         $version =~ s/(\.[^.]+)\./$1/g;
2567
2568         if ( $software eq 'mod_perl' ) {
2569
2570             if ( !$engine ) {
2571
2572                 if ( $version >= 1.99922 ) {
2573                     $engine = 'Catalyst::Engine::Apache2::MP20';
2574                 }
2575
2576                 elsif ( $version >= 1.9901 ) {
2577                     $engine = 'Catalyst::Engine::Apache2::MP19';
2578                 }
2579
2580                 elsif ( $version >= 1.24 ) {
2581                     $engine = 'Catalyst::Engine::Apache::MP13';
2582                 }
2583
2584                 else {
2585                     Catalyst::Exception->throw( message =>
2586                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2587                 }
2588
2589             }
2590
2591             # install the correct mod_perl handler
2592             if ( $version >= 1.9901 ) {
2593                 *handler = sub  : method {
2594                     shift->handle_request(@_);
2595                 };
2596             }
2597             else {
2598                 *handler = sub ($$) { shift->handle_request(@_) };
2599             }
2600
2601         }
2602
2603         elsif ( $software eq 'Zeus-Perl' ) {
2604             $engine = 'Catalyst::Engine::Zeus';
2605         }
2606
2607         else {
2608             Catalyst::Exception->throw(
2609                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2610         }
2611     }
2612
2613     unless ($engine) {
2614         $engine = $class->engine_class;
2615     }
2616
2617     Class::MOP::load_class($engine);
2618
2619     # check for old engines that are no longer compatible
2620     my $old_engine;
2621     if ( $engine->isa('Catalyst::Engine::Apache')
2622         && !Catalyst::Engine::Apache->VERSION )
2623     {
2624         $old_engine = 1;
2625     }
2626
2627     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2628         && Catalyst::Engine::Server->VERSION le '0.02' )
2629     {
2630         $old_engine = 1;
2631     }
2632
2633     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2634         && $engine->VERSION eq '0.01' )
2635     {
2636         $old_engine = 1;
2637     }
2638
2639     elsif ($engine->isa('Catalyst::Engine::Zeus')
2640         && $engine->VERSION eq '0.01' )
2641     {
2642         $old_engine = 1;
2643     }
2644
2645     if ($old_engine) {
2646         Catalyst::Exception->throw( message =>
2647               qq/Engine "$engine" is not supported by this version of Catalyst/
2648         );
2649     }
2650
2651     # engine instance
2652     $class->engine( $engine->new );
2653 }
2654
2655 =head2 $c->setup_home
2656
2657 Sets up the home directory.
2658
2659 =cut
2660
2661 sub setup_home {
2662     my ( $class, $home ) = @_;
2663
2664     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2665         $home = $env;
2666     }
2667
2668     $home ||= Catalyst::Utils::home($class);
2669
2670     if ($home) {
2671         #I remember recently being scolded for assigning config values like this
2672         $class->config->{home} ||= $home;
2673         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2674     }
2675 }
2676
2677 =head2 $c->setup_log
2678
2679 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2680 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2681 log to.
2682
2683 This method also installs a C<debug> method that returns a true value into the
2684 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2685 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2686
2687 Note that if the log has already been setup, by either a previous call to
2688 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2689 that this method won't actually set up the log object.
2690
2691 =cut
2692
2693 sub setup_log {
2694     my ( $class, $levels ) = @_;
2695
2696     $levels ||= '';
2697     $levels =~ s/^\s+//;
2698     $levels =~ s/\s+$//;
2699     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2700
2701     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2702     if ( defined $env_debug ) {
2703         $levels{debug} = 1 if $env_debug; # Ugly!
2704         delete($levels{debug}) unless $env_debug;
2705     }
2706
2707     unless ( $class->log ) {
2708         $class->log( Catalyst::Log->new(keys %levels) );
2709     }
2710
2711     if ( $levels{debug} ) {
2712         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2713         $class->log->debug('Debug messages enabled');
2714     }
2715 }
2716
2717 =head2 $c->setup_plugins
2718
2719 Sets up plugins.
2720
2721 =cut
2722
2723 =head2 $c->setup_stats
2724
2725 Sets up timing statistics class.
2726
2727 =cut
2728
2729 sub setup_stats {
2730     my ( $class, $stats ) = @_;
2731
2732     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2733
2734     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2735     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2736         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2737         $class->log->debug('Statistics enabled');
2738     }
2739 }
2740
2741
2742 =head2 $c->registered_plugins
2743
2744 Returns a sorted list of the plugins which have either been stated in the
2745 import list or which have been added via C<< MyApp->plugin(@args); >>.
2746
2747 If passed a given plugin name, it will report a boolean value indicating
2748 whether or not that plugin is loaded.  A fully qualified name is required if
2749 the plugin name does not begin with C<Catalyst::Plugin::>.
2750
2751  if ($c->registered_plugins('Some::Plugin')) {
2752      ...
2753  }
2754
2755 =cut
2756
2757 {
2758
2759     sub registered_plugins {
2760         my $proto = shift;
2761         return sort keys %{ $proto->_plugins } unless @_;
2762         my $plugin = shift;
2763         return 1 if exists $proto->_plugins->{$plugin};
2764         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2765     }
2766
2767     sub _register_plugin {
2768         my ( $proto, $plugin, $instant ) = @_;
2769         my $class = ref $proto || $proto;
2770
2771         Class::MOP::load_class( $plugin );
2772         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2773             if $plugin->isa( 'Catalyst::Component' );
2774         $proto->_plugins->{$plugin} = 1;
2775         unless ($instant) {
2776             my $meta = Class::MOP::get_metaclass_by_name($class);
2777             $meta->superclasses($plugin, $meta->superclasses);
2778         }
2779         return $class;
2780     }
2781
2782     sub setup_plugins {
2783         my ( $class, $plugins ) = @_;
2784
2785         $class->_plugins( {} ) unless $class->_plugins;
2786         $plugins = Data::OptList::mkopt($plugins || []);
2787
2788         my @plugins = map {
2789             [ Catalyst::Utils::resolve_namespace(
2790                   $class . '::Plugin',
2791                   'Catalyst::Plugin', $_->[0]
2792               ),
2793               $_->[1],
2794             ]
2795          } @{ $plugins };
2796
2797         for my $plugin ( reverse @plugins ) {
2798             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2799             my $meta = find_meta($plugin->[0]);
2800             next if $meta && $meta->isa('Moose::Meta::Role');
2801
2802             $class->_register_plugin($plugin->[0]);
2803         }
2804
2805         my @roles =
2806             map  { $_->[0]->name, $_->[1] }
2807             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2808             map  { [find_meta($_->[0]), $_->[1]] }
2809             @plugins;
2810
2811         Moose::Util::apply_all_roles(
2812             $class => @roles
2813         ) if @roles;
2814     }
2815 }
2816
2817 =head2 $c->stack
2818
2819 Returns an arrayref of the internal execution stack (actions that are
2820 currently executing).
2821
2822 =head2 $c->stats
2823
2824 Returns the current timing statistics object. By default Catalyst uses
2825 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2826 L<< stats_class|/"$c->stats_class" >>.
2827
2828 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2829 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2830 profile explicitly, although MyApp.pm still won't profile nor output anything
2831 by itself.
2832
2833 =head2 $c->stats_class
2834
2835 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2836
2837 =head2 $c->use_stats
2838
2839 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2840
2841 Note that this is a static method, not an accessor and should be overridden
2842 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2843
2844 =cut
2845
2846 sub use_stats { 0 }
2847
2848
2849 =head2 $c->write( $data )
2850
2851 Writes $data to the output stream. When using this method directly, you
2852 will need to manually set the C<Content-Length> header to the length of
2853 your output data, if known.
2854
2855 =cut
2856
2857 sub write {
2858     my $c = shift;
2859
2860     # Finalize headers if someone manually writes output
2861     $c->finalize_headers;
2862
2863     return $c->engine->write( $c, @_ );
2864 }
2865
2866 =head2 version
2867
2868 Returns the Catalyst version number. Mostly useful for "powered by"
2869 messages in template systems.
2870
2871 =cut
2872
2873 sub version { return $Catalyst::VERSION }
2874
2875 =head1 CONFIGURATION
2876
2877 There are a number of 'base' config variables which can be set:
2878
2879 =over
2880
2881 =item *
2882
2883 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2884
2885 =item *
2886
2887 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2888
2889 =item *
2890
2891 C<home> - The application home directory. In an uninstalled application,
2892 this is the top level application directory. In an installed application,
2893 this will be the directory containing C<< MyApp.pm >>.
2894
2895 =item *
2896
2897 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2898
2899 =item *
2900
2901 C<name> - The name of the application in debug messages and the debug and
2902 welcome screens
2903
2904 =item *
2905
2906 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2907 until it is accessed. This allows you to (for example) check authentication (and reject
2908 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2909
2910 =item *
2911
2912 C<root> - The root directory for templates. Usually this is just a
2913 subdirectory of the home directory, but you can set it to change the
2914 templates to a different directory.
2915
2916 =item *
2917
2918 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2919 namespaces from which components will be loaded (and constructed and stored in
2920 C<< $c->components >>).
2921
2922 =item *
2923
2924 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2925 to be shown in hit debug tables in the test server.
2926
2927 =item *
2928
2929 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
2930 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
2931 for more information.
2932
2933 =item *
2934
2935 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2936
2937 =back
2938
2939 =head1 INTERNAL ACTIONS
2940
2941 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2942 C<_ACTION>, and C<_END>. These are by default not shown in the private
2943 action table, but you can make them visible with a config parameter.
2944
2945     MyApp->config(show_internal_actions => 1);
2946
2947 =head1 ON-DEMAND PARSER
2948
2949 The request body is usually parsed at the beginning of a request,
2950 but if you want to handle input yourself, you can enable on-demand
2951 parsing with a config parameter.
2952
2953     MyApp->config(parse_on_demand => 1);
2954
2955 =head1 PROXY SUPPORT
2956
2957 Many production servers operate using the common double-server approach,
2958 with a lightweight frontend web server passing requests to a larger
2959 backend server. An application running on the backend server must deal
2960 with two problems: the remote user always appears to be C<127.0.0.1> and
2961 the server's hostname will appear to be C<localhost> regardless of the
2962 virtual host that the user connected through.
2963
2964 Catalyst will automatically detect this situation when you are running
2965 the frontend and backend servers on the same machine. The following
2966 changes are made to the request.
2967
2968     $c->req->address is set to the user's real IP address, as read from
2969     the HTTP X-Forwarded-For header.
2970
2971     The host value for $c->req->base and $c->req->uri is set to the real
2972     host, as read from the HTTP X-Forwarded-Host header.
2973
2974 Additionally, you may be running your backend application on an insecure
2975 connection (port 80) while your frontend proxy is running under SSL.  If there
2976 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2977 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2978 be created properly.
2979
2980 In the case of passing in:
2981
2982     X-Forwarded-Port: 443
2983
2984 All calls to C<uri_for> will result in an https link, as is expected.
2985
2986 Obviously, your web server must support these headers for this to work.
2987
2988 In a more complex server farm environment where you may have your
2989 frontend proxy server(s) on different machines, you will need to set a
2990 configuration option to tell Catalyst to read the proxied data from the
2991 headers.
2992
2993     MyApp->config(using_frontend_proxy => 1);
2994
2995 If you do not wish to use the proxy support at all, you may set:
2996
2997     MyApp->config(ignore_frontend_proxy => 1);
2998
2999 =head1 THREAD SAFETY
3000
3001 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3002 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3003 believe the Catalyst core to be thread-safe.
3004
3005 If you plan to operate in a threaded environment, remember that all other
3006 modules you are using must also be thread-safe. Some modules, most notably
3007 L<DBD::SQLite>, are not thread-safe.
3008
3009 =head1 SUPPORT
3010
3011 IRC:
3012
3013     Join #catalyst on irc.perl.org.
3014
3015 Mailing Lists:
3016
3017     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3018     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3019
3020 Web:
3021
3022     http://catalyst.perl.org
3023
3024 Wiki:
3025
3026     http://dev.catalyst.perl.org
3027
3028 =head1 SEE ALSO
3029
3030 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3031
3032 =head2 L<Catalyst::Manual> - The Catalyst Manual
3033
3034 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3035
3036 =head2 L<Catalyst::Engine> - Core engine
3037
3038 =head2 L<Catalyst::Log> - Log class.
3039
3040 =head2 L<Catalyst::Request> - Request object
3041
3042 =head2 L<Catalyst::Response> - Response object
3043
3044 =head2 L<Catalyst::Test> - The test suite.
3045
3046 =head1 PROJECT FOUNDER
3047
3048 sri: Sebastian Riedel <sri@cpan.org>
3049
3050 =head1 CONTRIBUTORS
3051
3052 abw: Andy Wardley
3053
3054 acme: Leon Brocard <leon@astray.com>
3055
3056 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3057
3058 Andrew Bramble
3059
3060 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3061
3062 Andrew Ruthven
3063
3064 André Walker
3065
3066 andyg: Andy Grundman <andy@hybridized.org>
3067
3068 audreyt: Audrey Tang
3069
3070 bricas: Brian Cassidy <bricas@cpan.org>
3071
3072 Caelum: Rafael Kitover <rkitover@io.com>
3073
3074 chansen: Christian Hansen
3075
3076 chicks: Christopher Hicks
3077
3078 Chisel Wright C<pause@herlpacker.co.uk>
3079
3080 Danijel Milicevic C<me@danijel.de>
3081
3082 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3083
3084 David Naughton, C<naughton@umn.edu>
3085
3086 David E. Wheeler
3087
3088 dhoss: Devin Austin <dhoss@cpan.org>
3089
3090 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3091
3092 Drew Taylor
3093
3094 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3095
3096 esskar: Sascha Kiefer
3097
3098 fireartist: Carl Franks <cfranks@cpan.org>
3099
3100 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3101
3102 gabb: Danijel Milicevic
3103
3104 Gary Ashton Jones
3105
3106 Gavin Henry C<ghenry@perl.me.uk>
3107
3108 Geoff Richards
3109
3110 groditi: Guillermo Roditi <groditi@gmail.com>
3111
3112 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3113
3114 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3115
3116 jcamacho: Juan Camacho
3117
3118 jester: Jesse Sheidlower C<jester@panix.com>
3119
3120 jhannah: Jay Hannah <jay@jays.net>
3121
3122 Jody Belka
3123
3124 Johan Lindstrom
3125
3126 jon: Jon Schutz <jjschutz@cpan.org>
3127
3128 Jonathan Rockway C<< <jrockway@cpan.org> >>
3129
3130 Kieren Diment C<kd@totaldatasolution.com>
3131
3132 konobi: Scott McWhirter <konobi@cpan.org>
3133
3134 marcus: Marcus Ramberg <mramberg@cpan.org>
3135
3136 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3137
3138 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3139
3140 mugwump: Sam Vilain
3141
3142 naughton: David Naughton
3143
3144 ningu: David Kamholz <dkamholz@cpan.org>
3145
3146 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3147
3148 numa: Dan Sully <daniel@cpan.org>
3149
3150 obra: Jesse Vincent
3151
3152 Octavian Rasnita
3153
3154 omega: Andreas Marienborg
3155
3156 Oleg Kostyuk <cub.uanic@gmail.com>
3157
3158 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3159
3160 rafl: Florian Ragwitz <rafl@debian.org>
3161
3162 random: Roland Lammel <lammel@cpan.org>
3163
3164 Robert Sedlacek C<< <rs@474.at> >>
3165
3166 SpiceMan: Marcel Montes
3167
3168 sky: Arthur Bergman
3169
3170 szbalint: Balint Szilakszi <szbalint@cpan.org>
3171
3172 t0m: Tomas Doran <bobtfish@bobtfish.net>
3173
3174 Ulf Edvinsson
3175
3176 Viljo Marrandi C<vilts@yahoo.com>
3177
3178 Will Hawes C<info@whawes.co.uk>
3179
3180 willert: Sebastian Willert <willert@cpan.org>
3181
3182 wreis: Wallace Reis <wallace@reis.org.br>
3183
3184 Yuval Kogman, C<nothingmuch@woobling.org>
3185
3186 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3187
3188 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3189
3190 =head1 COPYRIGHT
3191
3192 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3193
3194 =head1 LICENSE
3195
3196 This library is free software. You can redistribute it and/or modify it under
3197 the same terms as Perl itself.
3198
3199 =cut
3200
3201 no Moose;
3202
3203 __PACKAGE__->meta->make_immutable;
3204
3205 1;