lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/container components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80032';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub _application { $_[0] }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 This sets the log level to 'debug' and enables full debug output on the
 252 error screen. If you only want the latter, see L<< $c->debug >>.
 253
 254 =head2 -Engine
 255
 256 Forces Catalyst to use a specific engine. Omit the
 257 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 258
 259     use Catalyst qw/-Engine=CGI/;
 260
 261 =head2 -Home
 262
 263 Forces Catalyst to use a specific home directory, e.g.:
 264
 265     use Catalyst qw[-Home=/usr/mst];
 266
 267 This can also be done in the shell environment by setting either the
 268 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 269 is replaced with the uppercased name of your application, any "::" in
 270 the name will be replaced with underscores, e.g. MyApp::Web should use
 271 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 272
 273 If none of these are set, Catalyst will attempt to automatically detect the
 274 home directory. If you are working in a development envirnoment, Catalyst
 275 will try and find the directory containing either Makefile.PL, Build.PL or
 276 dist.ini. If the application has been installed into the system (i.e.
 277 you have done C<make install>), then Catalyst will use the path to your
 278 application module, without the .pm extension (ie, /foo/MyApp if your
 279 application was installed at /foo/MyApp.pm)
 280
 281 =head2 -Log
 282
 283     use Catalyst '-Log=warn,fatal,error';
 284
 285 Specifies a comma-delimited list of log levels.
 286
 287 =head2 -Stats
 288
 289 Enables statistics collection and reporting.
 290
 291    use Catalyst qw/-Stats=1/;
 292
 293 You can also force this setting from the system environment with CATALYST_STATS
 294 or <MYAPP>_STATS. The environment settings override the application, with
 295 <MYAPP>_STATS having the highest priority.
 296
 297 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 298
 299 =head1 METHODS
 300
 301 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 302
 303 =head2 $c->action
 304
 305 Returns a L<Catalyst::Action> object for the current action, which
 306 stringifies to the action name. See L<Catalyst::Action>.
 307
 308 =head2 $c->namespace
 309
 310 Returns the namespace of the current action, i.e., the URI prefix
 311 corresponding to the controller of the current action. For example:
 312
 313     # in Controller::Foo::Bar
 314     $c->namespace; # returns 'foo/bar';
 315
 316 =head2 $c->request
 317
 318 =head2 $c->req
 319
 320 Returns the current L<Catalyst::Request> object, giving access to
 321 information about the current client request (including parameters,
 322 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 323
 324 =head2 REQUEST FLOW HANDLING
 325
 326 =head2 $c->forward( $action [, \@arguments ] )
 327
 328 =head2 $c->forward( $class, $method, [, \@arguments ] )
 329
 330 Forwards processing to another action, by its private name. If you give a
 331 class name but no method, C<process()> is called. You may also optionally
 332 pass arguments in an arrayref. The action will receive the arguments in
 333 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 334 C<< $c->req->args >> will be restored to the previous values.
 335
 336 Any data C<return>ed from the action forwarded to, will be returned by the
 337 call to forward.
 338
 339     my $foodata = $c->forward('/foo');
 340     $c->forward('index');
 341     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 342     $c->forward('View::TT');
 343
 344 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 345 an C<< eval { } >> around the call (actually
 346 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 347 all 'dies' within the called action. If you want C<die> to propagate you
 348 need to do something like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 374
 375 =cut
 376
 377 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 378
 379 =head2 $c->detach( $action [, \@arguments ] )
 380
 381 =head2 $c->detach( $class, $method, [, \@arguments ] )
 382
 383 =head2 $c->detach()
 384
 385 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 386 doesn't return to the previous action when processing is finished.
 387
 388 When called with no arguments it escapes the processing chain entirely.
 389
 390 =cut
 391
 392 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 393
 394 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 397
 398 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 399 but does a full dispatch, instead of just calling the new C<$action> /
 400 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 401 you go to are called, just like a new request.
 402
 403 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 404 This means, for example, that C<< $c->action >> methods such as
 405 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 406 L<reverse|Catalyst::Action/reverse> return information for the visited action
 407 when they are invoked within the visited action.  This is different from the
 408 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 409 continues to use the $c->action object from the caller action even when
 410 invoked from the callee.
 411
 412 C<< $c->stash >> is kept unchanged.
 413
 414 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 415 allows you to "wrap" another action, just as it would have been called by
 416 dispatching from a URL, while the analogous
 417 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 418 transfer control to another action as if it had been reached directly from a URL.
 419
 420 =cut
 421
 422 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 423
 424 =head2 $c->go( $action [, \@captures, \@arguments ] )
 425
 426 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 427
 428 The relationship between C<go> and
 429 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 430 the relationship between
 431 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 432 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 433 C<< $c->go >> will perform a full dispatch on the specified action or method,
 434 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 435 C<go> escapes the processing of the current request chain on completion, and
 436 does not return to its caller.
 437
 438 @arguments are arguments to the final destination of $action. @captures are
 439 arguments to the intermediate steps, if any, on the way to the final sub of
 440 $action.
 441
 442 =cut
 443
 444 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 445
 446 =head2 $c->response
 447
 448 =head2 $c->res
 449
 450 Returns the current L<Catalyst::Response> object, see there for details.
 451
 452 =head2 $c->stash
 453
 454 Returns a hashref to the stash, which may be used to store data and pass
 455 it between components during a request. You can also set hash keys by
 456 passing arguments. The stash is automatically sent to the view. The
 457 stash is cleared at the end of a request; it cannot be used for
 458 persistent storage (for this you must use a session; see
 459 L<Catalyst::Plugin::Session> for a complete system integrated with
 460 Catalyst).
 461
 462     $c->stash->{foo} = $bar;
 463     $c->stash( { moose => 'majestic', qux => 0 } );
 464     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 465
 466     # stash is automatically passed to the view for use in a template
 467     $c->forward( 'MyApp::View::TT' );
 468
 469 =cut
 470
 471 around stash => sub {
 472     my $orig = shift;
 473     my $c = shift;
 474     my $stash = $orig->($c);
 475     if (@_) {
 476         my $new_stash = @_ > 1 ? {@_} : $_[0];
 477         croak('stash takes a hash or hashref') unless ref $new_stash;
 478         foreach my $key ( keys %$new_stash ) {
 479           $stash->{$key} = $new_stash->{$key};
 480         }
 481     }
 482
 483     return $stash;
 484 };
 485
 486
 487 =head2 $c->error
 488
 489 =head2 $c->error($error, ...)
 490
 491 =head2 $c->error($arrayref)
 492
 493 Returns an arrayref containing error messages.  If Catalyst encounters an
 494 error while processing a request, it stores the error in $c->error.  This
 495 method should only be used to store fatal error messages.
 496
 497     my @error = @{ $c->error };
 498
 499 Add a new error.
 500
 501     $c->error('Something bad happened');
 502
 503 =cut
 504
 505 sub error {
 506     my $c = shift;
 507     if ( $_[0] ) {
 508         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 509         croak @$error unless ref $c;
 510         push @{ $c->{error} }, @$error;
 511     }
 512     elsif ( defined $_[0] ) { $c->{error} = undef }
 513     return $c->{error} || [];
 514 }
 515
 516
 517 =head2 $c->state
 518
 519 Contains the return value of the last executed action.
 520 Note that << $c->state >> operates in a scalar context which means that all
 521 values it returns are scalar.
 522
 523 =head2 $c->clear_errors
 524
 525 Clear errors.  You probably don't want to clear the errors unless you are
 526 implementing a custom error screen.
 527
 528 This is equivalent to running
 529
 530     $c->error(0);
 531
 532 =cut
 533
 534 sub clear_errors {
 535     my $c = shift;
 536     $c->error(0);
 537 }
 538
 539 sub _comp_search_prefixes {
 540     my $c = shift;
 541     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 542 }
 543
 544 # search components given a name and some prefixes
 545 sub _comp_names_search_prefixes {
 546     my ( $c, $name, @prefixes ) = @_;
 547     my $appclass = ref $c || $c;
 548     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 549     $filter = qr/$filter/; # Compile regex now rather than once per loop
 550
 551     # map the original component name to the sub part that we will search against
 552     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 553         grep { /$filter/ } keys %{ $c->components };
 554
 555     # undef for a name will return all
 556     return keys %eligible if !defined $name;
 557
 558     my $query  = ref $name ? $name : qr/^$name$/i;
 559     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 560
 561     return @result if @result;
 562
 563     # if we were given a regexp to search against, we're done.
 564     return if ref $name;
 565
 566     # skip regexp fallback if configured
 567     return
 568         if $appclass->config->{disable_component_resolution_regex_fallback};
 569
 570     # regexp fallback
 571     $query  = qr/$name/i;
 572     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 573
 574     # no results? try against full names
 575     if( !@result ) {
 576         @result = grep { m{$query} } keys %eligible;
 577     }
 578
 579     # don't warn if we didn't find any results, it just might not exist
 580     if( @result ) {
 581         # Disgusting hack to work out correct method name
 582         my $warn_for = lc $prefixes[0];
 583         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 584            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 585            "component resolution is unreliable and unsafe.";
 586         my $short = $result[0];
 587         # remove the component namespace prefix
 588         $short =~ s/.*?(Model|Controller|View):://;
 589         my $shortmess = Carp::shortmess('');
 590         if ($shortmess =~ m#Catalyst/Plugin#) {
 591            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 592               "plugin's config";
 593         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 594            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 595               "component's config";
 596         } else {
 597            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 598               "but if you really wanted to search, pass in a regexp as the argument " .
 599               "like so: \$c->${warn_for}(qr/${name}/)";
 600         }
 601         $c->log->warn( "${msg}$shortmess" );
 602     }
 603
 604     return @result;
 605 }
 606
 607 # Find possible names for a prefix
 608 sub _comp_names {
 609     my ( $c, @prefixes ) = @_;
 610     my $appclass = ref $c || $c;
 611
 612     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 613
 614     my @names = map { s{$filter}{}; $_; }
 615         $c->_comp_names_search_prefixes( undef, @prefixes );
 616
 617     return @names;
 618 }
 619
 620 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 621 sub _filter_component {
 622     my ( $c, $comp, @args ) = @_;
 623
 624     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 625         return $comp->ACCEPT_CONTEXT( $c, @args );
 626     }
 627
 628     return $comp;
 629 }
 630
 631 =head2 COMPONENT ACCESSORS
 632
 633 =head2 $c->controller($name)
 634
 635 Gets a L<Catalyst::Controller> instance by name.
 636
 637     $c->controller('Foo')->do_stuff;
 638
 639 If the name is omitted, will return the controller for the dispatched
 640 action.
 641
 642 If you want to search for controllers, pass in a regexp as the argument.
 643
 644     # find all controllers that start with Foo
 645     my @foo_controllers = $c->controller(qr{^Foo});
 646
 647
 648 =cut
 649
 650 sub controller {
 651     my ( $c, $name, @args ) = @_;
 652
 653     my $appclass = ref($c) || $c;
 654     if( $name ) {
 655         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 656             my $comps = $c->components;
 657             my $check = $appclass."::Controller::".$name;
 658             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 659         }
 660         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 661         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 662         return $c->_filter_component( $result[ 0 ], @args );
 663     }
 664
 665     return $c->component( $c->action->class );
 666 }
 667
 668 =head2 $c->model($name)
 669
 670 Gets a L<Catalyst::Model> instance by name.
 671
 672     $c->model('Foo')->do_stuff;
 673
 674 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 675
 676 If the name is omitted, it will look for
 677  - a model object in $c->stash->{current_model_instance}, then
 678  - a model name in $c->stash->{current_model}, then
 679  - a config setting 'default_model', or
 680  - check if there is only one model, and return it if that's the case.
 681
 682 If you want to search for models, pass in a regexp as the argument.
 683
 684     # find all models that start with Foo
 685     my @foo_models = $c->model(qr{^Foo});
 686
 687 =cut
 688
 689 sub model {
 690     my ( $c, $name, @args ) = @_;
 691     my $appclass = ref($c) || $c;
 692     if( $name ) {
 693         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 694             my $comps = $c->components;
 695             my $check = $appclass."::Model::".$name;
 696             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 697         }
 698         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 699         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 700         return $c->_filter_component( $result[ 0 ], @args );
 701     }
 702
 703     if (ref $c) {
 704         return $c->stash->{current_model_instance}
 705           if $c->stash->{current_model_instance};
 706         return $c->model( $c->stash->{current_model} )
 707           if $c->stash->{current_model};
 708     }
 709     return $c->model( $appclass->config->{default_model} )
 710       if $appclass->config->{default_model};
 711
 712     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 713
 714     if( $rest ) {
 715         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 716         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 717         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 718         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 719         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 720     }
 721
 722     return $c->_filter_component( $comp );
 723 }
 724
 725
 726 =head2 $c->view($name)
 727
 728 Gets a L<Catalyst::View> instance by name.
 729
 730     $c->view('Foo')->do_stuff;
 731
 732 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 733
 734 If the name is omitted, it will look for
 735  - a view object in $c->stash->{current_view_instance}, then
 736  - a view name in $c->stash->{current_view}, then
 737  - a config setting 'default_view', or
 738  - check if there is only one view, and return it if that's the case.
 739
 740 If you want to search for views, pass in a regexp as the argument.
 741
 742     # find all views that start with Foo
 743     my @foo_views = $c->view(qr{^Foo});
 744
 745 =cut
 746
 747 sub view {
 748     my ( $c, $name, @args ) = @_;
 749
 750     my $appclass = ref($c) || $c;
 751     if( $name ) {
 752         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 753             my $comps = $c->components;
 754             my $check = $appclass."::View::".$name;
 755             if( exists $comps->{$check} ) {
 756                 return $c->_filter_component( $comps->{$check}, @args );
 757             }
 758             else {
 759                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 760             }
 761         }
 762         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 763         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 764         return $c->_filter_component( $result[ 0 ], @args );
 765     }
 766
 767     if (ref $c) {
 768         return $c->stash->{current_view_instance}
 769           if $c->stash->{current_view_instance};
 770         return $c->view( $c->stash->{current_view} )
 771           if $c->stash->{current_view};
 772     }
 773     return $c->view( $appclass->config->{default_view} )
 774       if $appclass->config->{default_view};
 775
 776     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 777
 778     if( $rest ) {
 779         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 780         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 781         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 782         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 783         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 784     }
 785
 786     return $c->_filter_component( $comp );
 787 }
 788
 789 =head2 $c->controllers
 790
 791 Returns the available names which can be passed to $c->controller
 792
 793 =cut
 794
 795 sub controllers {
 796     my ( $c ) = @_;
 797     return $c->_comp_names(qw/Controller C/);
 798 }
 799
 800 =head2 $c->models
 801
 802 Returns the available names which can be passed to $c->model
 803
 804 =cut
 805
 806 sub models {
 807     my ( $c ) = @_;
 808     return $c->_comp_names(qw/Model M/);
 809 }
 810
 811
 812 =head2 $c->views
 813
 814 Returns the available names which can be passed to $c->view
 815
 816 =cut
 817
 818 sub views {
 819     my ( $c ) = @_;
 820     return $c->_comp_names(qw/View V/);
 821 }
 822
 823 =head2 $c->comp($name)
 824
 825 =head2 $c->component($name)
 826
 827 Gets a component object by name. This method is not recommended,
 828 unless you want to get a specific component by full
 829 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 830 should be used instead.
 831
 832 If C<$name> is a regexp, a list of components matched against the full
 833 component name will be returned.
 834
 835 If Catalyst can't find a component by name, it will fallback to regex
 836 matching by default. To disable this behaviour set
 837 disable_component_resolution_regex_fallback to a true value.
 838
 839     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 840
 841 =cut
 842
 843 sub component {
 844     my ( $c, $name, @args ) = @_;
 845
 846     if( $name ) {
 847         my $comps = $c->components;
 848
 849         if( !ref $name ) {
 850             # is it the exact name?
 851             return $c->_filter_component( $comps->{ $name }, @args )
 852                        if exists $comps->{ $name };
 853
 854             # perhaps we just omitted "MyApp"?
 855             my $composed = ( ref $c || $c ) . "::${name}";
 856             return $c->_filter_component( $comps->{ $composed }, @args )
 857                        if exists $comps->{ $composed };
 858
 859             # search all of the models, views and controllers
 860             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 861             return $c->_filter_component( $comp, @args ) if $comp;
 862         }
 863
 864         # This is here so $c->comp( '::M::' ) works
 865         my $query = ref $name ? $name : qr{$name}i;
 866
 867         my @result = grep { m{$query} } keys %{ $c->components };
 868         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 869
 870         if( $result[ 0 ] ) {
 871             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 872             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 873             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 874             return $c->_filter_component( $result[ 0 ], @args );
 875         }
 876
 877         # I would expect to return an empty list here, but that breaks back-compat
 878     }
 879
 880     # fallback
 881     return sort keys %{ $c->components };
 882 }
 883
 884 =head2 CLASS DATA AND HELPER CLASSES
 885
 886 =head2 $c->config
 887
 888 Returns or takes a hashref containing the application's configuration.
 889
 890     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 891
 892 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 893 like C<myapp.conf> in your applications home directory. See
 894 L<Catalyst::Plugin::ConfigLoader>.
 895
 896 =head3 Cascading configuration
 897
 898 The config method is present on all Catalyst components, and configuration
 899 will be merged when an application is started. Configuration loaded with
 900 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 901 followed by configuration in your top level C<MyApp> class. These two
 902 configurations are merged, and then configuration data whose hash key matches a
 903 component name is merged with configuration for that component.
 904
 905 The configuration for a component is then passed to the C<new> method when a
 906 component is constructed.
 907
 908 For example:
 909
 910     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 911     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 912
 913 will mean that C<MyApp::Model::Foo> receives the following data when
 914 constructed:
 915
 916     MyApp::Model::Foo->new({
 917         bar => 'baz',
 918         quux => 'frob',
 919         overrides => 'me',
 920     });
 921
 922 It's common practice to use a Moose attribute
 923 on the receiving component to access the config value.
 924
 925     package MyApp::Model::Foo;
 926
 927     use Moose;
 928
 929     # this attr will receive 'baz' at construction time
 930     has 'bar' => (
 931         is  => 'rw',
 932         isa => 'Str',
 933     );
 934
 935 You can then get the value 'baz' by calling $c->model('Foo')->bar
 936 (or $self->bar inside code in the model).
 937
 938 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 939 as a way of reading config within your code, as this B<will not> give you the
 940 correctly merged config back. You B<MUST> take the config values supplied to
 941 the constructor and use those instead.
 942
 943 =cut
 944
 945 around config => sub {
 946     my $orig = shift;
 947     my $c = shift;
 948
 949     croak('Setting config after setup has been run is not allowed.')
 950         if ( @_ and $c->setup_finished );
 951
 952     $c->$orig(@_);
 953 };
 954
 955 =head2 $c->log
 956
 957 Returns the logging object instance. Unless it is already set, Catalyst
 958 sets this up with a L<Catalyst::Log> object. To use your own log class,
 959 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 960 C<< __PACKAGE__->setup >>.
 961
 962  __PACKAGE__->log( MyLogger->new );
 963  __PACKAGE__->setup;
 964
 965 And later:
 966
 967     $c->log->info( 'Now logging with my own logger!' );
 968
 969 Your log class should implement the methods described in
 970 L<Catalyst::Log>.
 971
 972
 973 =head2 $c->debug
 974
 975 Returns 1 if debug mode is enabled, 0 otherwise.
 976
 977 You can enable debug mode in several ways:
 978
 979 =over
 980
 981 =item By calling myapp_server.pl with the -d flag
 982
 983 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 984
 985 =item The -Debug option in your MyApp.pm
 986
 987 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 988
 989 =back
 990
 991 The first three also set the log level to 'debug'.
 992
 993 Calling C<< $c->debug(1) >> has no effect.
 994
 995 =cut
 996
 997 sub debug { 0 }
 998
 999 =head2 $c->dispatcher
1000
1001 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1002
1003 =head2 $c->engine
1004
1005 Returns the engine instance. See L<Catalyst::Engine>.
1006
1007
1008 =head2 UTILITY METHODS
1009
1010 =head2 $c->path_to(@path)
1011
1012 Merges C<@path> with C<< $c->config->{home} >> and returns a
1013 L<Path::Class::Dir> object. Note you can usually use this object as
1014 a filename, but sometimes you will have to explicitly stringify it
1015 yourself by calling the C<< ->stringify >> method.
1016
1017 For example:
1018
1019     $c->path_to( 'db', 'sqlite.db' );
1020
1021 =cut
1022
1023 sub path_to {
1024     my ( $c, @path ) = @_;
1025     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1026     if ( -d $path ) { return $path }
1027     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1028 }
1029
1030 =head2 $c->plugin( $name, $class, @args )
1031
1032 Helper method for plugins. It creates a class data accessor/mutator and
1033 loads and instantiates the given class.
1034
1035     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1036
1037     $c->prototype->define_javascript_functions;
1038
1039 B<Note:> This method of adding plugins is deprecated. The ability
1040 to add plugins like this B<will be removed> in a Catalyst 5.81.
1041 Please do not use this functionality in new code.
1042
1043 =cut
1044
1045 sub plugin {
1046     my ( $class, $name, $plugin, @args ) = @_;
1047
1048     # See block comment in t/unit_core_plugin.t
1049     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1050
1051     $class->_register_plugin( $plugin, 1 );
1052
1053     eval { $plugin->import };
1054     $class->mk_classdata($name);
1055     my $obj;
1056     eval { $obj = $plugin->new(@args) };
1057
1058     if ($@) {
1059         Catalyst::Exception->throw( message =>
1060               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1061     }
1062
1063     $class->$name($obj);
1064     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1065       if $class->debug;
1066 }
1067
1068 =head2 MyApp->setup
1069
1070 Initializes the dispatcher and engine, loads any plugins, and loads the
1071 model, view, and controller components. You may also specify an array
1072 of plugins to load here, if you choose to not load them in the C<use
1073 Catalyst> line.
1074
1075     MyApp->setup;
1076     MyApp->setup( qw/-Debug/ );
1077
1078 =cut
1079
1080 sub setup {
1081     my ( $class, @arguments ) = @_;
1082     croak('Running setup more than once')
1083         if ( $class->setup_finished );
1084
1085     unless ( $class->isa('Catalyst') ) {
1086
1087         Catalyst::Exception->throw(
1088             message => qq/'$class' does not inherit from Catalyst/ );
1089     }
1090
1091     if ( $class->arguments ) {
1092         @arguments = ( @arguments, @{ $class->arguments } );
1093     }
1094
1095     # Process options
1096     my $flags = {};
1097
1098     foreach (@arguments) {
1099
1100         if (/^-Debug$/) {
1101             $flags->{log} =
1102               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1103         }
1104         elsif (/^-(\w+)=?(.*)$/) {
1105             $flags->{ lc $1 } = $2;
1106         }
1107         else {
1108             push @{ $flags->{plugins} }, $_;
1109         }
1110     }
1111
1112     $class->setup_config();
1113     $class->setup_home( delete $flags->{home} );
1114
1115     $class->setup_log( delete $flags->{log} );
1116     $class->setup_plugins( delete $flags->{plugins} );
1117     $class->setup_dispatcher( delete $flags->{dispatcher} );
1118     $class->setup_engine( delete $flags->{engine} );
1119     $class->setup_stats( delete $flags->{stats} );
1120
1121     for my $flag ( sort keys %{$flags} ) {
1122
1123         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1124             &$code( $class, delete $flags->{$flag} );
1125         }
1126         else {
1127             $class->log->warn(qq/Unknown flag "$flag"/);
1128         }
1129     }
1130
1131     eval { require Catalyst::Devel; };
1132     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1133         $class->log->warn(<<"EOF");
1134 You are running an old script!
1135
1136   Please update by running (this will overwrite existing files):
1137     catalyst.pl -force -scripts $class
1138
1139   or (this will not overwrite existing files):
1140     catalyst.pl -scripts $class
1141
1142 EOF
1143     }
1144
1145     if ( $class->debug ) {
1146         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1147
1148         if (@plugins) {
1149             my $column_width = Catalyst::Utils::term_width() - 6;
1150             my $t = Text::SimpleTable->new($column_width);
1151             $t->row($_) for @plugins;
1152             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1153         }
1154
1155         my $dispatcher = $class->dispatcher;
1156         my $engine     = $class->engine;
1157         my $home       = $class->config->{home};
1158
1159         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1160         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1161
1162         $home
1163           ? ( -d $home )
1164           ? $class->log->debug(qq/Found home "$home"/)
1165           : $class->log->debug(qq/Home "$home" doesn't exist/)
1166           : $class->log->debug(q/Couldn't find home/);
1167     }
1168
1169     # Call plugins setup, this is stupid and evil.
1170     # Also screws C3 badly on 5.10, hack to avoid.
1171     {
1172         no warnings qw/redefine/;
1173         local *setup = sub { };
1174         $class->setup unless $Catalyst::__AM_RESTARTING;
1175     }
1176
1177     # Initialize our data structure
1178     $class->components( {} );
1179
1180     $class->setup_components;
1181
1182     if ( $class->debug ) {
1183         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1184         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1185         for my $comp ( sort keys %{ $class->components } ) {
1186             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1187             $t->row( $comp, $type );
1188         }
1189         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1190           if ( keys %{ $class->components } );
1191     }
1192
1193     # Add our self to components, since we are also a component
1194     if( $class->isa('Catalyst::Controller') ){
1195       $class->components->{$class} = $class;
1196     }
1197
1198     $class->setup_actions;
1199
1200     if ( $class->debug ) {
1201         my $name = $class->config->{name} || 'Application';
1202         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1203     }
1204
1205     # Make sure that the application class becomes immutable at this point,
1206     B::Hooks::EndOfScope::on_scope_end {
1207         return if $@;
1208         my $meta = Class::MOP::get_metaclass_by_name($class);
1209         if (
1210             $meta->is_immutable
1211             && ! { $meta->immutable_options }->{replace_constructor}
1212             && (
1213                    $class->isa('Class::Accessor::Fast')
1214                 || $class->isa('Class::Accessor')
1215             )
1216         ) {
1217             warn "You made your application class ($class) immutable, "
1218                 . "but did not inline the\nconstructor. "
1219                 . "This will break catalyst, as your app \@ISA "
1220                 . "Class::Accessor(::Fast)?\nPlease pass "
1221                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1222         }
1223         $meta->make_immutable(
1224             replace_constructor => 1,
1225         ) unless $meta->is_immutable;
1226     };
1227
1228     if ($class->config->{case_sensitive}) {
1229         $class->log->warn($class . "->config->{case_sensitive} is set.");
1230         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1231     }
1232
1233     $class->setup_finalize;
1234     # Should be the last thing we do so that user things hooking
1235     # setup_finalize can log..
1236     $class->log->_flush() if $class->log->can('_flush');
1237     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1238 }
1239
1240 =head2 $app->setup_finalize
1241
1242 A hook to attach modifiers to. This method does not do anything except set the
1243 C<setup_finished> accessor.
1244
1245 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1246
1247 Example:
1248
1249     after setup_finalize => sub {
1250         my $app = shift;
1251
1252         ## do stuff here..
1253     };
1254
1255 =cut
1256
1257 sub setup_finalize {
1258     my ($class) = @_;
1259     $class->setup_finished(1);
1260 }
1261
1262 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1263
1264 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1265
1266 Constructs an absolute L<URI> object based on the application root, the
1267 provided path, and the additional arguments and query parameters provided.
1268 When used as a string, provides a textual URI.  If you need more flexibility
1269 than this (i.e. the option to provide relative URIs etc.) see
1270 L<Catalyst::Plugin::SmartURI>.
1271
1272 If no arguments are provided, the URI for the current action is returned.
1273 To return the current action and also provide @args, use
1274 C<< $c->uri_for( $c->action, @args ) >>.
1275
1276 If the first argument is a string, it is taken as a public URI path relative
1277 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1278 relative to the application root (if it does). It is then merged with
1279 C<< $c->request->base >>; any C<@args> are appended as additional path
1280 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1281
1282 If the first argument is a L<Catalyst::Action> it represents an action which
1283 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1284 optional C<\@captures> argument (an arrayref) allows passing the captured
1285 variables that are needed to fill in the paths of Chained and Regex actions;
1286 once the path is resolved, C<uri_for> continues as though a path was
1287 provided, appending any arguments or parameters and creating an absolute
1288 URI.
1289
1290 The captures for the current request can be found in
1291 C<< $c->request->captures >>, and actions can be resolved using
1292 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1293 path, use C<< $c->uri_for_action >> instead.
1294
1295   # Equivalent to $c->req->uri
1296   $c->uri_for($c->action, $c->req->captures,
1297       @{ $c->req->args }, $c->req->params);
1298
1299   # For the Foo action in the Bar controller
1300   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1301
1302   # Path to a static resource
1303   $c->uri_for('/static/images/logo.png');
1304
1305 =cut
1306
1307 sub uri_for {
1308     my ( $c, $path, @args ) = @_;
1309
1310     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1311         $path = $path->path_prefix;
1312         $path =~ s{/+\z}{};
1313         $path .= '/';
1314     }
1315
1316     undef($path) if (defined $path && $path eq '');
1317
1318     my $params =
1319       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1320
1321     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1322     foreach my $arg (@args) {
1323         utf8::encode($arg) if utf8::is_utf8($arg);
1324         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1325     }
1326
1327     if ( blessed($path) ) { # action object
1328         s|/|%2F|g for @args;
1329         my $captures = [ map { s|/|%2F|g; $_; }
1330                         ( scalar @args && ref $args[0] eq 'ARRAY'
1331                          ? @{ shift(@args) }
1332                          : ()) ];
1333
1334         foreach my $capture (@$captures) {
1335             utf8::encode($capture) if utf8::is_utf8($capture);
1336             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1337         }
1338
1339         my $action = $path;
1340         $path = $c->dispatcher->uri_for_action($action, $captures);
1341         if (not defined $path) {
1342             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1343                 if $c->debug;
1344             return undef;
1345         }
1346         $path = '/' if $path eq '';
1347     }
1348
1349     unshift(@args, $path);
1350
1351     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1352         my $namespace = $c->namespace;
1353         if (defined $path) { # cheesy hack to handle path '../foo'
1354            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1355         }
1356         unshift(@args, $namespace || '');
1357     }
1358
1359     # join args with '/', or a blank string
1360     my $args = join('/', grep { defined($_) } @args);
1361     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1362     $args =~ s!^/+!!;
1363     my $base = $c->req->base;
1364     my $class = ref($base);
1365     $base =~ s{(?<!/)$}{/};
1366
1367     my $query = '';
1368
1369     if (my @keys = keys %$params) {
1370       # somewhat lifted from URI::_query's query_form
1371       $query = '?'.join('&', map {
1372           my $val = $params->{$_};
1373           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1374           s/ /+/g;
1375           my $key = $_;
1376           $val = '' unless defined $val;
1377           (map {
1378               my $param = "$_";
1379               utf8::encode( $param ) if utf8::is_utf8($param);
1380               # using the URI::Escape pattern here so utf8 chars survive
1381               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1382               $param =~ s/ /+/g;
1383               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1384       } @keys);
1385     }
1386
1387     my $res = bless(\"${base}${args}${query}", $class);
1388     $res;
1389 }
1390
1391 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1392
1393 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1394
1395 =over
1396
1397 =item $path
1398
1399 A private path to the Catalyst action you want to create a URI for.
1400
1401 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1402 >> and passing the resulting C<$action> and the remaining arguments to C<<
1403 $c->uri_for >>.
1404
1405 You can also pass in a Catalyst::Action object, in which case it is passed to
1406 C<< $c->uri_for >>.
1407
1408 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1409
1410 For example, if the action looks like:
1411
1412  package MyApp::Controller::Users;
1413
1414  sub lst : Path('the-list') {}
1415
1416 You can use:
1417
1418  $c->uri_for_action('/users/lst')
1419
1420 and it will create the URI /users/the-list.
1421
1422 =back
1423
1424 =cut
1425
1426 sub uri_for_action {
1427     my ( $c, $path, @args ) = @_;
1428     my $action = blessed($path)
1429       ? $path
1430       : $c->dispatcher->get_action_by_path($path);
1431     unless (defined $action) {
1432       croak "Can't find action for path '$path'";
1433     }
1434     return $c->uri_for( $action, @args );
1435 }
1436
1437 =head2 $c->welcome_message
1438
1439 Returns the Catalyst welcome HTML page.
1440
1441 =cut
1442
1443 sub welcome_message {
1444     my $c      = shift;
1445     my $name   = $c->config->{name};
1446     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1447     my $prefix = Catalyst::Utils::appprefix( ref $c );
1448     $c->response->content_type('text/html; charset=utf-8');
1449     return <<"EOF";
1450 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1451     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1452 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1453     <head>
1454     <meta http-equiv="Content-Language" content="en" />
1455     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1456         <title>$name on Catalyst $VERSION</title>
1457         <style type="text/css">
1458             body {
1459                 color: #000;
1460                 background-color: #eee;
1461             }
1462             div#content {
1463                 width: 640px;
1464                 margin-left: auto;
1465                 margin-right: auto;
1466                 margin-top: 10px;
1467                 margin-bottom: 10px;
1468                 text-align: left;
1469                 background-color: #ccc;
1470                 border: 1px solid #aaa;
1471             }
1472             p, h1, h2 {
1473                 margin-left: 20px;
1474                 margin-right: 20px;
1475                 font-family: verdana, tahoma, sans-serif;
1476             }
1477             a {
1478                 font-family: verdana, tahoma, sans-serif;
1479             }
1480             :link, :visited {
1481                     text-decoration: none;
1482                     color: #b00;
1483                     border-bottom: 1px dotted #bbb;
1484             }
1485             :link:hover, :visited:hover {
1486                     color: #555;
1487             }
1488             div#topbar {
1489                 margin: 0px;
1490             }
1491             pre {
1492                 margin: 10px;
1493                 padding: 8px;
1494             }
1495             div#answers {
1496                 padding: 8px;
1497                 margin: 10px;
1498                 background-color: #fff;
1499                 border: 1px solid #aaa;
1500             }
1501             h1 {
1502                 font-size: 0.9em;
1503                 font-weight: normal;
1504                 text-align: center;
1505             }
1506             h2 {
1507                 font-size: 1.0em;
1508             }
1509             p {
1510                 font-size: 0.9em;
1511             }
1512             p img {
1513                 float: right;
1514                 margin-left: 10px;
1515             }
1516             span#appname {
1517                 font-weight: bold;
1518                 font-size: 1.6em;
1519             }
1520         </style>
1521     </head>
1522     <body>
1523         <div id="content">
1524             <div id="topbar">
1525                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1526                     $VERSION</h1>
1527              </div>
1528              <div id="answers">
1529                  <p>
1530                  <img src="$logo" alt="Catalyst Logo" />
1531                  </p>
1532                  <p>Welcome to the  world of Catalyst.
1533                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1534                     framework will make web development something you had
1535                     never expected it to be: Fun, rewarding, and quick.</p>
1536                  <h2>What to do now?</h2>
1537                  <p>That really depends  on what <b>you</b> want to do.
1538                     We do, however, provide you with a few starting points.</p>
1539                  <p>If you want to jump right into web development with Catalyst
1540                     you might want to start with a tutorial.</p>
1541 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1542 </pre>
1543 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1544 <pre>
1545 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1546 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1547 </code></pre>
1548                  <h2>What to do next?</h2>
1549                  <p>Next it's time to write an actual application. Use the
1550                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1551                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1552                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1553                     they can save you a lot of work.</p>
1554                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1555                     <p>Also, be sure to check out the vast and growing
1556                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1557                     you are likely to find what you need there.
1558                     </p>
1559
1560                  <h2>Need help?</h2>
1561                  <p>Catalyst has a very active community. Here are the main places to
1562                     get in touch with us.</p>
1563                  <ul>
1564                      <li>
1565                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1566                      </li>
1567                      <li>
1568                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1569                      </li>
1570                      <li>
1571                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1572                      </li>
1573                  </ul>
1574                  <h2>In conclusion</h2>
1575                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1576                     as we enjoyed making it. Please contact us if you have ideas
1577                     for improvement or other feedback.</p>
1578              </div>
1579          </div>
1580     </body>
1581 </html>
1582 EOF
1583 }
1584
1585 =head1 INTERNAL METHODS
1586
1587 These methods are not meant to be used by end users.
1588
1589 =head2 $c->components
1590
1591 Returns a hash of components.
1592
1593 =head2 $c->context_class
1594
1595 Returns or sets the context class.
1596
1597 =head2 $c->counter
1598
1599 Returns a hashref containing coderefs and execution counts (needed for
1600 deep recursion detection).
1601
1602 =head2 $c->depth
1603
1604 Returns the number of actions on the current internal execution stack.
1605
1606 =head2 $c->dispatch
1607
1608 Dispatches a request to actions.
1609
1610 =cut
1611
1612 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1613
1614 =head2 $c->dispatcher_class
1615
1616 Returns or sets the dispatcher class.
1617
1618 =head2 $c->dump_these
1619
1620 Returns a list of 2-element array references (name, structure) pairs
1621 that will be dumped on the error page in debug mode.
1622
1623 =cut
1624
1625 sub dump_these {
1626     my $c = shift;
1627     [ Request => $c->req ],
1628     [ Response => $c->res ],
1629     [ Stash => $c->stash ],
1630     [ Config => $c->config ];
1631 }
1632
1633 =head2 $c->engine_class
1634
1635 Returns or sets the engine class.
1636
1637 =head2 $c->execute( $class, $coderef )
1638
1639 Execute a coderef in given class and catch exceptions. Errors are available
1640 via $c->error.
1641
1642 =cut
1643
1644 sub execute {
1645     my ( $c, $class, $code ) = @_;
1646     $class = $c->component($class) || $class;
1647     $c->state(0);
1648
1649     if ( $c->depth >= $RECURSION ) {
1650         my $action = $code->reverse();
1651         $action = "/$action" unless $action =~ /->/;
1652         my $error = qq/Deep recursion detected calling "${action}"/;
1653         $c->log->error($error);
1654         $c->error($error);
1655         $c->state(0);
1656         return $c->state;
1657     }
1658
1659     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1660
1661     push( @{ $c->stack }, $code );
1662
1663     no warnings 'recursion';
1664     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1665     #      I have no idea how, ergo $ret (which appears to fix the issue)
1666     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1667
1668     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1669
1670     my $last = pop( @{ $c->stack } );
1671
1672     if ( my $error = $@ ) {
1673         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1674             $error->rethrow if $c->depth > 1;
1675         }
1676         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1677             $error->rethrow if $c->depth > 0;
1678         }
1679         else {
1680             unless ( ref $error ) {
1681                 no warnings 'uninitialized';
1682                 chomp $error;
1683                 my $class = $last->class;
1684                 my $name  = $last->name;
1685                 $error = qq/Caught exception in $class->$name "$error"/;
1686             }
1687             $c->error($error);
1688         }
1689         $c->state(0);
1690     }
1691     return $c->state;
1692 }
1693
1694 sub _stats_start_execute {
1695     my ( $c, $code ) = @_;
1696     my $appclass = ref($c) || $c;
1697     return if ( ( $code->name =~ /^_.*/ )
1698         && ( !$appclass->config->{show_internal_actions} ) );
1699
1700     my $action_name = $code->reverse();
1701     $c->counter->{$action_name}++;
1702
1703     my $action = $action_name;
1704     $action = "/$action" unless $action =~ /->/;
1705
1706     # determine if the call was the result of a forward
1707     # this is done by walking up the call stack and looking for a calling
1708     # sub of Catalyst::forward before the eval
1709     my $callsub = q{};
1710     for my $index ( 2 .. 11 ) {
1711         last
1712         if ( ( caller($index) )[0] eq 'Catalyst'
1713             && ( caller($index) )[3] eq '(eval)' );
1714
1715         if ( ( caller($index) )[3] =~ /forward$/ ) {
1716             $callsub = ( caller($index) )[3];
1717             $action  = "-> $action";
1718             last;
1719         }
1720     }
1721
1722     my $uid = $action_name . $c->counter->{$action_name};
1723
1724     # is this a root-level call or a forwarded call?
1725     if ( $callsub =~ /forward$/ ) {
1726         my $parent = $c->stack->[-1];
1727
1728         # forward, locate the caller
1729         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1730             $c->stats->profile(
1731                 begin  => $action,
1732                 parent => "$parent" . $c->counter->{"$parent"},
1733                 uid    => $uid,
1734             );
1735         }
1736         else {
1737
1738             # forward with no caller may come from a plugin
1739             $c->stats->profile(
1740                 begin => $action,
1741                 uid   => $uid,
1742             );
1743         }
1744     }
1745     else {
1746
1747         # root-level call
1748         $c->stats->profile(
1749             begin => $action,
1750             uid   => $uid,
1751         );
1752     }
1753     return $action;
1754
1755 }
1756
1757 sub _stats_finish_execute {
1758     my ( $c, $info ) = @_;
1759     $c->stats->profile( end => $info );
1760 }
1761
1762 =head2 $c->finalize
1763
1764 Finalizes the request.
1765
1766 =cut
1767
1768 sub finalize {
1769     my $c = shift;
1770
1771     for my $error ( @{ $c->error } ) {
1772         $c->log->error($error);
1773     }
1774
1775     # Allow engine to handle finalize flow (for POE)
1776     my $engine = $c->engine;
1777     if ( my $code = $engine->can('finalize') ) {
1778         $engine->$code($c);
1779     }
1780     else {
1781
1782         $c->finalize_uploads;
1783
1784         # Error
1785         if ( $#{ $c->error } >= 0 ) {
1786             $c->finalize_error;
1787         }
1788
1789         $c->finalize_headers;
1790
1791         # HEAD request
1792         if ( $c->request->method eq 'HEAD' ) {
1793             $c->response->body('');
1794         }
1795
1796         $c->finalize_body;
1797     }
1798
1799     $c->log_response;
1800
1801     if ($c->use_stats) {
1802         my $elapsed = sprintf '%f', $c->stats->elapsed;
1803         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1804         $c->log->info(
1805             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1806     }
1807
1808     return $c->response->status;
1809 }
1810
1811 =head2 $c->finalize_body
1812
1813 Finalizes body.
1814
1815 =cut
1816
1817 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1818
1819 =head2 $c->finalize_cookies
1820
1821 Finalizes cookies.
1822
1823 =cut
1824
1825 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1826
1827 =head2 $c->finalize_error
1828
1829 Finalizes error.
1830
1831 =cut
1832
1833 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1834
1835 =head2 $c->finalize_headers
1836
1837 Finalizes headers.
1838
1839 =cut
1840
1841 sub finalize_headers {
1842     my $c = shift;
1843
1844     my $response = $c->response; #accessor calls can add up?
1845
1846     # Check if we already finalized headers
1847     return if $response->finalized_headers;
1848
1849     # Handle redirects
1850     if ( my $location = $response->redirect ) {
1851         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1852         $response->header( Location => $location );
1853
1854         if ( !$response->has_body ) {
1855             # Add a default body if none is already present
1856             $response->body(
1857                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1858             );
1859         }
1860     }
1861
1862     # Content-Length
1863     if ( defined $response->body && length $response->body && !$response->content_length ) {
1864
1865         # get the length from a filehandle
1866         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1867         {
1868             my $stat = stat $response->body;
1869             if ( $stat && $stat->size > 0 ) {
1870                 $response->content_length( $stat->size );
1871             }
1872             else {
1873                 $c->log->warn('Serving filehandle without a content-length');
1874             }
1875         }
1876         else {
1877             # everything should be bytes at this point, but just in case
1878             $response->content_length( length( $response->body ) );
1879         }
1880     }
1881
1882     # Errors
1883     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1884         $response->headers->remove_header("Content-Length");
1885         $response->body('');
1886     }
1887
1888     $c->finalize_cookies;
1889
1890     $c->engine->finalize_headers( $c, @_ );
1891
1892     # Done
1893     $response->finalized_headers(1);
1894 }
1895
1896 =head2 $c->finalize_output
1897
1898 An alias for finalize_body.
1899
1900 =head2 $c->finalize_read
1901
1902 Finalizes the input after reading is complete.
1903
1904 =cut
1905
1906 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1907
1908 =head2 $c->finalize_uploads
1909
1910 Finalizes uploads. Cleans up any temporary files.
1911
1912 =cut
1913
1914 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1915
1916 =head2 $c->get_action( $action, $namespace )
1917
1918 Gets an action in a given namespace.
1919
1920 =cut
1921
1922 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1923
1924 =head2 $c->get_actions( $action, $namespace )
1925
1926 Gets all actions of a given name in a namespace and all parent
1927 namespaces.
1928
1929 =cut
1930
1931 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1932
1933 =head2 $app->handle_request( @arguments )
1934
1935 Called to handle each HTTP request.
1936
1937 =cut
1938
1939 sub handle_request {
1940     my ( $class, @arguments ) = @_;
1941
1942     # Always expect worst case!
1943     my $status = -1;
1944     eval {
1945         if ($class->debug) {
1946             my $secs = time - $START || 1;
1947             my $av = sprintf '%.3f', $COUNT / $secs;
1948             my $time = localtime time;
1949             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1950         }
1951
1952         my $c = $class->prepare(@arguments);
1953         $c->dispatch;
1954         $status = $c->finalize;
1955     };
1956
1957     if ( my $error = $@ ) {
1958         chomp $error;
1959         $class->log->error(qq/Caught exception in engine "$error"/);
1960     }
1961
1962     $COUNT++;
1963
1964     if(my $coderef = $class->log->can('_flush')){
1965         $class->log->$coderef();
1966     }
1967     return $status;
1968 }
1969
1970 =head2 $c->prepare( @arguments )
1971
1972 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1973 etc.).
1974
1975 =cut
1976
1977 sub prepare {
1978     my ( $class, @arguments ) = @_;
1979
1980     # XXX
1981     # After the app/ctxt split, this should become an attribute based on something passed
1982     # into the application.
1983     $class->context_class( ref $class || $class ) unless $class->context_class;
1984
1985     my $c = $class->context_class->new({});
1986
1987     # For on-demand data
1988     $c->request->_context($c);
1989     $c->response->_context($c);
1990
1991     #surely this is not the most efficient way to do things...
1992     $c->stats($class->stats_class->new)->enable($c->use_stats);
1993     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1994         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1995     }
1996
1997     #XXX reuse coderef from can
1998     # Allow engine to direct the prepare flow (for POE)
1999     if ( $c->engine->can('prepare') ) {
2000         $c->engine->prepare( $c, @arguments );
2001     }
2002     else {
2003         $c->prepare_request(@arguments);
2004         $c->prepare_connection;
2005         $c->prepare_query_parameters;
2006         $c->prepare_headers;
2007         $c->prepare_cookies;
2008         $c->prepare_path;
2009
2010         # Prepare the body for reading, either by prepare_body
2011         # or the user, if they are using $c->read
2012         $c->prepare_read;
2013
2014         # Parse the body unless the user wants it on-demand
2015         unless ( ref($c)->config->{parse_on_demand} ) {
2016             $c->prepare_body;
2017         }
2018     }
2019
2020     my $method  = $c->req->method  || '';
2021     my $path    = $c->req->path;
2022     $path       = '/' unless length $path;
2023     my $address = $c->req->address || '';
2024
2025     $c->log_request;
2026
2027     $c->prepare_action;
2028
2029     return $c;
2030 }
2031
2032 =head2 $c->prepare_action
2033
2034 Prepares action. See L<Catalyst::Dispatcher>.
2035
2036 =cut
2037
2038 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2039
2040 =head2 $c->prepare_body
2041
2042 Prepares message body.
2043
2044 =cut
2045
2046 sub prepare_body {
2047     my $c = shift;
2048
2049     return if $c->request->_has_body;
2050
2051     # Initialize on-demand data
2052     $c->engine->prepare_body( $c, @_ );
2053     $c->prepare_parameters;
2054     $c->prepare_uploads;
2055 }
2056
2057 =head2 $c->prepare_body_chunk( $chunk )
2058
2059 Prepares a chunk of data before sending it to L<HTTP::Body>.
2060
2061 See L<Catalyst::Engine>.
2062
2063 =cut
2064
2065 sub prepare_body_chunk {
2066     my $c = shift;
2067     $c->engine->prepare_body_chunk( $c, @_ );
2068 }
2069
2070 =head2 $c->prepare_body_parameters
2071
2072 Prepares body parameters.
2073
2074 =cut
2075
2076 sub prepare_body_parameters {
2077     my $c = shift;
2078     $c->engine->prepare_body_parameters( $c, @_ );
2079 }
2080
2081 =head2 $c->prepare_connection
2082
2083 Prepares connection.
2084
2085 =cut
2086
2087 sub prepare_connection {
2088     my $c = shift;
2089     $c->engine->prepare_connection( $c, @_ );
2090 }
2091
2092 =head2 $c->prepare_cookies
2093
2094 Prepares cookies.
2095
2096 =cut
2097
2098 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2099
2100 =head2 $c->prepare_headers
2101
2102 Prepares headers.
2103
2104 =cut
2105
2106 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2107
2108 =head2 $c->prepare_parameters
2109
2110 Prepares parameters.
2111
2112 =cut
2113
2114 sub prepare_parameters {
2115     my $c = shift;
2116     $c->prepare_body_parameters;
2117     $c->engine->prepare_parameters( $c, @_ );
2118 }
2119
2120 =head2 $c->prepare_path
2121
2122 Prepares path and base.
2123
2124 =cut
2125
2126 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2127
2128 =head2 $c->prepare_query_parameters
2129
2130 Prepares query parameters.
2131
2132 =cut
2133
2134 sub prepare_query_parameters {
2135     my $c = shift;
2136
2137     $c->engine->prepare_query_parameters( $c, @_ );
2138 }
2139
2140 =head2 $c->log_request
2141
2142 Writes information about the request to the debug logs.  This includes:
2143
2144 =over 4
2145
2146 =item * Request method, path, and remote IP address
2147
2148 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2149
2150 =item * Request parameters
2151
2152 =item * File uploads
2153
2154 =back
2155
2156 =cut
2157
2158 sub log_request {
2159     my $c = shift;
2160
2161     return unless $c->debug;
2162
2163     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2164     my $request = $dump->[1];
2165
2166     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2167     $method ||= '';
2168     $path = '/' unless length $path;
2169     $address ||= '';
2170     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2171
2172     $c->log_request_headers($request->headers);
2173
2174     if ( my $keywords = $request->query_keywords ) {
2175         $c->log->debug("Query keywords are: $keywords");
2176     }
2177
2178     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2179
2180     $c->log_request_uploads($request);
2181 }
2182
2183 =head2 $c->log_response
2184
2185 Writes information about the response to the debug logs by calling
2186 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2187
2188 =cut
2189
2190 sub log_response {
2191     my $c = shift;
2192
2193     return unless $c->debug;
2194
2195     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2196     my $response = $dump->[1];
2197
2198     $c->log_response_status_line($response);
2199     $c->log_response_headers($response->headers);
2200 }
2201
2202 =head2 $c->log_response_status_line($response)
2203
2204 Writes one line of information about the response to the debug logs.  This includes:
2205
2206 =over 4
2207
2208 =item * Response status code
2209
2210 =item * Content-Type header (if present)
2211
2212 =item * Content-Length header (if present)
2213
2214 =back
2215
2216 =cut
2217
2218 sub log_response_status_line {
2219     my ($c, $response) = @_;
2220
2221     $c->log->debug(
2222         sprintf(
2223             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2224             $response->status                            || 'unknown',
2225             $response->headers->header('Content-Type')   || 'unknown',
2226             $response->headers->header('Content-Length') || 'unknown'
2227         )
2228     );
2229 }
2230
2231 =head2 $c->log_response_headers($headers);
2232
2233 Hook method which can be wrapped by plugins to log the responseheaders.
2234 No-op in the default implementation.
2235
2236 =cut
2237
2238 sub log_response_headers {}
2239
2240 =head2 $c->log_request_parameters( query => {}, body => {} )
2241
2242 Logs request parameters to debug logs
2243
2244 =cut
2245
2246 sub log_request_parameters {
2247     my $c          = shift;
2248     my %all_params = @_;
2249
2250     return unless $c->debug;
2251
2252     my $column_width = Catalyst::Utils::term_width() - 44;
2253     foreach my $type (qw(query body)) {
2254         my $params = $all_params{$type};
2255         next if ! keys %$params;
2256         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2257         for my $key ( sort keys %$params ) {
2258             my $param = $params->{$key};
2259             my $value = defined($param) ? $param : '';
2260             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2261         }
2262         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2263     }
2264 }
2265
2266 =head2 $c->log_request_uploads
2267
2268 Logs file uploads included in the request to the debug logs.
2269 The parameter name, filename, file type, and file size are all included in
2270 the debug logs.
2271
2272 =cut
2273
2274 sub log_request_uploads {
2275     my $c = shift;
2276     my $request = shift;
2277     return unless $c->debug;
2278     my $uploads = $request->uploads;
2279     if ( keys %$uploads ) {
2280         my $t = Text::SimpleTable->new(
2281             [ 12, 'Parameter' ],
2282             [ 26, 'Filename' ],
2283             [ 18, 'Type' ],
2284             [ 9,  'Size' ]
2285         );
2286         for my $key ( sort keys %$uploads ) {
2287             my $upload = $uploads->{$key};
2288             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2289                 $t->row( $key, $u->filename, $u->type, $u->size );
2290             }
2291         }
2292         $c->log->debug( "File Uploads are:\n" . $t->draw );
2293     }
2294 }
2295
2296 =head2 $c->log_request_headers($headers);
2297
2298 Hook method which can be wrapped by plugins to log the request headers.
2299 No-op in the default implementation.
2300
2301 =cut
2302
2303 sub log_request_headers {}
2304
2305 =head2 $c->log_headers($type => $headers)
2306
2307 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2308
2309 =cut
2310
2311 sub log_headers {
2312     my $c       = shift;
2313     my $type    = shift;
2314     my $headers = shift;    # an HTTP::Headers instance
2315
2316     return unless $c->debug;
2317
2318     my $column_width = Catalyst::Utils::term_width() - 28;
2319     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2320     $headers->scan(
2321         sub {
2322             my ( $name, $value ) = @_;
2323             $t->row( $name, $value );
2324         }
2325     );
2326     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2327 }
2328
2329
2330 =head2 $c->prepare_read
2331
2332 Prepares the input for reading.
2333
2334 =cut
2335
2336 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2337
2338 =head2 $c->prepare_request
2339
2340 Prepares the engine request.
2341
2342 =cut
2343
2344 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2345
2346 =head2 $c->prepare_uploads
2347
2348 Prepares uploads.
2349
2350 =cut
2351
2352 sub prepare_uploads {
2353     my $c = shift;
2354
2355     $c->engine->prepare_uploads( $c, @_ );
2356 }
2357
2358 =head2 $c->prepare_write
2359
2360 Prepares the output for writing.
2361
2362 =cut
2363
2364 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2365
2366 =head2 $c->request_class
2367
2368 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2369
2370 =head2 $c->response_class
2371
2372 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2373
2374 =head2 $c->read( [$maxlength] )
2375
2376 Reads a chunk of data from the request body. This method is designed to
2377 be used in a while loop, reading C<$maxlength> bytes on every call.
2378 C<$maxlength> defaults to the size of the request if not specified.
2379
2380 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2381 directly.
2382
2383 Warning: If you use read(), Catalyst will not process the body,
2384 so you will not be able to access POST parameters or file uploads via
2385 $c->request.  You must handle all body parsing yourself.
2386
2387 =cut
2388
2389 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2390
2391 =head2 $c->run
2392
2393 Starts the engine.
2394
2395 =cut
2396
2397 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2398
2399 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2400
2401 Sets an action in a given namespace.
2402
2403 =cut
2404
2405 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2406
2407 =head2 $c->setup_actions($component)
2408
2409 Sets up actions for a component.
2410
2411 =cut
2412
2413 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2414
2415 =head2 $c->setup_config
2416
2417 =cut
2418
2419 sub setup_config {
2420     my $class = shift;
2421
2422     my %args = %{$class->config || {} };
2423     my @container_classes = qw/MyApp::Container Catalyst::Container/;
2424     unshift @container_classes, delete $args{container_class} if exists $args{container_class};
2425
2426     my $container_class = Class::MOP::load_first_existing_class(@container_classes);
2427
2428     my $container = $container_class->new( %args, name => "$class" );
2429
2430     $container->add_sub_container(Bread::Board::Container->new( name => $_ )) for qw(model controller view);
2431     $class->container($container);
2432
2433     my $config = $container->fetch('config')->get;
2434     $class->config($config);
2435     $class->finalize_config; # back-compat
2436 }
2437
2438 =head $c->finalize_config
2439
2440 =cut
2441
2442 sub finalize_config { }
2443
2444 =head2 $c->setup_components
2445
2446 This method is called internally to set up the application's components.
2447
2448 It finds modules by calling the L<locate_components> method, expands them to
2449 package names with the L<expand_component_module> method, and then installs
2450 each component into the application.
2451
2452 The C<setup_components> config option is passed to both of the above methods.
2453
2454 Installation of each component is performed by the L<setup_component> method,
2455 below.
2456
2457 =cut
2458
2459 sub setup_components {
2460     my $class = shift;
2461
2462     my $config  = $class->config->{ setup_components };
2463
2464     my @comps = $class->locate_components($config);
2465     my %comps = map { $_ => 1 } @comps;
2466
2467     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2468     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2469         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2470     ) if $deprecatedcatalyst_component_names;
2471
2472     for my $component ( @comps ) {
2473
2474         # We pass ignore_loaded here so that overlay files for (e.g.)
2475         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2476         # we know M::P::O found a file on disk so this is safe
2477
2478         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2479     }
2480
2481     my $containers;
2482     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
2483
2484     for my $component (@comps) {
2485         my $instance = $class->components->{ $component } = $class->setup_component($component);
2486         my $type = lc((split /::/, $component)[1]);
2487         $containers->{$type}->add_service(Bread::Board::BlockInjection->new( name => $component, block => sub { return $instance } ));
2488         my @expanded_components = $instance->can('expand_modules')
2489             ? $instance->expand_modules( $component, $config )
2490             : $class->expand_component_module( $component, $config );
2491         for my $component (@expanded_components) {
2492             next if $comps{$component};
2493             $class->components->{ $component } = $class->setup_component($component);
2494         }
2495     }
2496 }
2497
2498 =head2 $c->locate_components( $setup_component_config )
2499
2500 This method is meant to provide a list of component modules that should be
2501 setup for the application.  By default, it will use L<Module::Pluggable>.
2502
2503 Specify a C<setup_components> config option to pass additional options directly
2504 to L<Module::Pluggable>. To add additional search paths, specify a key named
2505 C<search_extra> as an array reference. Items in the array beginning with C<::>
2506 will have the application class name prepended to them.
2507
2508 =cut
2509
2510 sub locate_components {
2511     my $class  = shift;
2512     my $config = shift;
2513
2514     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2515     my $extra   = delete $config->{ search_extra } || [];
2516
2517     push @paths, @$extra;
2518
2519     my $locator = Module::Pluggable::Object->new(
2520         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2521         %$config
2522     );
2523
2524     # XXX think about ditching this sort entirely
2525     my @comps = sort { length $a <=> length $b } $locator->plugins;
2526
2527     return @comps;
2528 }
2529
2530 =head2 $c->expand_component_module( $component, $setup_component_config )
2531
2532 Components found by C<locate_components> will be passed to this method, which
2533 is expected to return a list of component (package) names to be set up.
2534
2535 =cut
2536
2537 sub expand_component_module {
2538     my ($class, $module) = @_;
2539     return Devel::InnerPackage::list_packages( $module );
2540 }
2541
2542 =head2 $c->setup_component
2543
2544 =cut
2545
2546 sub setup_component {
2547     my( $class, $component ) = @_;
2548
2549     unless ( $component->can( 'COMPONENT' ) ) {
2550         return $component;
2551     }
2552
2553     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2554     my $config = $class->config->{ $suffix } || {};
2555     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2556     # methods also pass it. local to avoid pointlessly shitting in config
2557     # for the debug screen, as $component is already the key name.
2558     local $config->{catalyst_component_name} = $component;
2559
2560     my $instance = eval { $component->COMPONENT( $class, $config ); };
2561
2562     if ( my $error = $@ ) {
2563         chomp $error;
2564         Catalyst::Exception->throw(
2565             message => qq/Couldn't instantiate component "$component", "$error"/
2566         );
2567     }
2568
2569     unless (blessed $instance) {
2570         my $metaclass = Moose::Util::find_meta($component);
2571         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2572         my $component_method_from = $method_meta->associated_metaclass->name;
2573         my $value = defined($instance) ? $instance : 'undef';
2574         Catalyst::Exception->throw(
2575             message =>
2576             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2577         );
2578     }
2579     return $instance;
2580 }
2581
2582 =head2 $c->setup_dispatcher
2583
2584 Sets up dispatcher.
2585
2586 =cut
2587
2588 sub setup_dispatcher {
2589     my ( $class, $dispatcher ) = @_;
2590
2591     if ($dispatcher) {
2592         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2593     }
2594
2595     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2596         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2597     }
2598
2599     unless ($dispatcher) {
2600         $dispatcher = $class->dispatcher_class;
2601     }
2602
2603     Class::MOP::load_class($dispatcher);
2604
2605     # dispatcher instance
2606     $class->dispatcher( $dispatcher->new );
2607 }
2608
2609 =head2 $c->setup_engine
2610
2611 Sets up engine.
2612
2613 =cut
2614
2615 sub setup_engine {
2616     my ( $class, $engine ) = @_;
2617
2618     if ($engine) {
2619         $engine = 'Catalyst::Engine::' . $engine;
2620     }
2621
2622     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2623         $engine = 'Catalyst::Engine::' . $env;
2624     }
2625
2626     if ( $ENV{MOD_PERL} ) {
2627         my $meta = Class::MOP::get_metaclass_by_name($class);
2628
2629         # create the apache method
2630         $meta->add_method('apache' => sub { shift->engine->apache });
2631
2632         my ( $software, $version ) =
2633           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2634
2635         $version =~ s/_//g;
2636         $version =~ s/(\.[^.]+)\./$1/g;
2637
2638         if ( $software eq 'mod_perl' ) {
2639
2640             if ( !$engine ) {
2641
2642                 if ( $version >= 1.99922 ) {
2643                     $engine = 'Catalyst::Engine::Apache2::MP20';
2644                 }
2645
2646                 elsif ( $version >= 1.9901 ) {
2647                     $engine = 'Catalyst::Engine::Apache2::MP19';
2648                 }
2649
2650                 elsif ( $version >= 1.24 ) {
2651                     $engine = 'Catalyst::Engine::Apache::MP13';
2652                 }
2653
2654                 else {
2655                     Catalyst::Exception->throw( message =>
2656                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2657                 }
2658
2659             }
2660
2661             # install the correct mod_perl handler
2662             if ( $version >= 1.9901 ) {
2663                 *handler = sub  : method {
2664                     shift->handle_request(@_);
2665                 };
2666             }
2667             else {
2668                 *handler = sub ($$) { shift->handle_request(@_) };
2669             }
2670
2671         }
2672
2673         elsif ( $software eq 'Zeus-Perl' ) {
2674             $engine = 'Catalyst::Engine::Zeus';
2675         }
2676
2677         else {
2678             Catalyst::Exception->throw(
2679                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2680         }
2681     }
2682
2683     unless ($engine) {
2684         $engine = $class->engine_class;
2685     }
2686
2687     Class::MOP::load_class($engine);
2688
2689     # check for old engines that are no longer compatible
2690     my $old_engine;
2691     if ( $engine->isa('Catalyst::Engine::Apache')
2692         && !Catalyst::Engine::Apache->VERSION )
2693     {
2694         $old_engine = 1;
2695     }
2696
2697     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2698         && Catalyst::Engine::Server->VERSION le '0.02' )
2699     {
2700         $old_engine = 1;
2701     }
2702
2703     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2704         && $engine->VERSION eq '0.01' )
2705     {
2706         $old_engine = 1;
2707     }
2708
2709     elsif ($engine->isa('Catalyst::Engine::Zeus')
2710         && $engine->VERSION eq '0.01' )
2711     {
2712         $old_engine = 1;
2713     }
2714
2715     if ($old_engine) {
2716         Catalyst::Exception->throw( message =>
2717               qq/Engine "$engine" is not supported by this version of Catalyst/
2718         );
2719     }
2720
2721     # engine instance
2722     $class->engine( $engine->new );
2723 }
2724
2725 =head2 $c->setup_home
2726
2727 Sets up the home directory.
2728
2729 =cut
2730
2731 sub setup_home {
2732     my ( $class, $home ) = @_;
2733
2734     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2735         $home = $env;
2736     }
2737
2738     $home ||= Catalyst::Utils::home($class);
2739
2740     if ($home) {
2741         #I remember recently being scolded for assigning config values like this
2742         $class->config->{home} ||= $home;
2743         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2744     }
2745 }
2746
2747 =head2 $c->setup_log
2748
2749 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2750 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2751 log to.
2752
2753 This method also installs a C<debug> method that returns a true value into the
2754 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2755 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2756
2757 Note that if the log has already been setup, by either a previous call to
2758 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2759 that this method won't actually set up the log object.
2760
2761 =cut
2762
2763 sub setup_log {
2764     my ( $class, $levels ) = @_;
2765
2766     $levels ||= '';
2767     $levels =~ s/^\s+//;
2768     $levels =~ s/\s+$//;
2769     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2770
2771     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2772     if ( defined $env_debug ) {
2773         $levels{debug} = 1 if $env_debug; # Ugly!
2774         delete($levels{debug}) unless $env_debug;
2775     }
2776
2777     unless ( $class->log ) {
2778         $class->log( Catalyst::Log->new(keys %levels) );
2779     }
2780
2781     if ( $levels{debug} ) {
2782         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2783         $class->log->debug('Debug messages enabled');
2784     }
2785 }
2786
2787 =head2 $c->setup_plugins
2788
2789 Sets up plugins.
2790
2791 =cut
2792
2793 =head2 $c->setup_stats
2794
2795 Sets up timing statistics class.
2796
2797 =cut
2798
2799 sub setup_stats {
2800     my ( $class, $stats ) = @_;
2801
2802     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2803
2804     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2805     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2806         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2807         $class->log->debug('Statistics enabled');
2808     }
2809 }
2810
2811
2812 =head2 $c->registered_plugins
2813
2814 Returns a sorted list of the plugins which have either been stated in the
2815 import list or which have been added via C<< MyApp->plugin(@args); >>.
2816
2817 If passed a given plugin name, it will report a boolean value indicating
2818 whether or not that plugin is loaded.  A fully qualified name is required if
2819 the plugin name does not begin with C<Catalyst::Plugin::>.
2820
2821  if ($c->registered_plugins('Some::Plugin')) {
2822      ...
2823  }
2824
2825 =cut
2826
2827 {
2828
2829     sub registered_plugins {
2830         my $proto = shift;
2831         return sort keys %{ $proto->_plugins } unless @_;
2832         my $plugin = shift;
2833         return 1 if exists $proto->_plugins->{$plugin};
2834         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2835     }
2836
2837     sub _register_plugin {
2838         my ( $proto, $plugin, $instant ) = @_;
2839         my $class = ref $proto || $proto;
2840
2841         Class::MOP::load_class( $plugin );
2842         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2843             if $plugin->isa( 'Catalyst::Component' );
2844         $proto->_plugins->{$plugin} = 1;
2845         unless ($instant) {
2846             my $meta = Class::MOP::get_metaclass_by_name($class);
2847             $meta->superclasses($plugin, $meta->superclasses);
2848         }
2849         return $class;
2850     }
2851
2852     sub setup_plugins {
2853         my ( $class, $plugins ) = @_;
2854
2855         $class->_plugins( {} ) unless $class->_plugins;
2856         $plugins = Data::OptList::mkopt($plugins || []);
2857
2858         my @plugins = map {
2859             [ Catalyst::Utils::resolve_namespace(
2860                   $class . '::Plugin',
2861                   'Catalyst::Plugin', $_->[0]
2862               ),
2863               $_->[1],
2864             ]
2865          } @{ $plugins };
2866
2867         for my $plugin ( reverse @plugins ) {
2868             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2869             my $meta = find_meta($plugin->[0]);
2870             next if $meta && $meta->isa('Moose::Meta::Role');
2871
2872             $class->_register_plugin($plugin->[0]);
2873         }
2874
2875         my @roles =
2876             map  { $_->[0]->name, $_->[1] }
2877             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2878             map  { [find_meta($_->[0]), $_->[1]] }
2879             @plugins;
2880
2881         Moose::Util::apply_all_roles(
2882             $class => @roles
2883         ) if @roles;
2884     }
2885 }
2886
2887 =head2 $c->stack
2888
2889 Returns an arrayref of the internal execution stack (actions that are
2890 currently executing).
2891
2892 =head2 $c->stats
2893
2894 Returns the current timing statistics object. By default Catalyst uses
2895 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2896 L<< stats_class|/"$c->stats_class" >>.
2897
2898 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2899 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2900 profile explicitly, although MyApp.pm still won't profile nor output anything
2901 by itself.
2902
2903 =head2 $c->stats_class
2904
2905 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2906
2907 =head2 $c->use_stats
2908
2909 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2910
2911 Note that this is a static method, not an accessor and should be overridden
2912 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2913
2914 =cut
2915
2916 sub use_stats { 0 }
2917
2918
2919 =head2 $c->write( $data )
2920
2921 Writes $data to the output stream. When using this method directly, you
2922 will need to manually set the C<Content-Length> header to the length of
2923 your output data, if known.
2924
2925 =cut
2926
2927 sub write {
2928     my $c = shift;
2929
2930     # Finalize headers if someone manually writes output
2931     $c->finalize_headers;
2932
2933     return $c->engine->write( $c, @_ );
2934 }
2935
2936 =head2 version
2937
2938 Returns the Catalyst version number. Mostly useful for "powered by"
2939 messages in template systems.
2940
2941 =cut
2942
2943 sub version { return $Catalyst::VERSION }
2944
2945 =head1 CONFIGURATION
2946
2947 There are a number of 'base' config variables which can be set:
2948
2949 =over
2950
2951 =item *
2952
2953 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2954
2955 =item *
2956
2957 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2958
2959 =item *
2960
2961 C<disable_component_resolution_regex_fallback> - Turns
2962 off the deprecated component resolution functionality so
2963 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2964 are called then regex search will not be attempted on string values and
2965 instead C<undef> will be returned.
2966
2967 =item *
2968
2969 C<home> - The application home directory. In an uninstalled application,
2970 this is the top level application directory. In an installed application,
2971 this will be the directory containing C<< MyApp.pm >>.
2972
2973 =item *
2974
2975 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2976
2977 =item *
2978
2979 C<name> - The name of the application in debug messages and the debug and
2980 welcome screens
2981
2982 =item *
2983
2984 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2985 until it is accessed. This allows you to (for example) check authentication (and reject
2986 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2987
2988 =item *
2989
2990 C<root> - The root directory for templates. Usually this is just a
2991 subdirectory of the home directory, but you can set it to change the
2992 templates to a different directory.
2993
2994 =item *
2995
2996 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2997 namespaces from which components will be loaded (and constructed and stored in
2998 C<< $c->components >>).
2999
3000 =item *
3001
3002 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3003 to be shown in hit debug tables in the test server.
3004
3005 =item *
3006
3007 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
3008 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
3009 for more information.
3010
3011 =item *
3012
3013 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3014
3015 =back
3016
3017 =head1 INTERNAL ACTIONS
3018
3019 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3020 C<_ACTION>, and C<_END>. These are by default not shown in the private
3021 action table, but you can make them visible with a config parameter.
3022
3023     MyApp->config(show_internal_actions => 1);
3024
3025 =head1 ON-DEMAND PARSER
3026
3027 The request body is usually parsed at the beginning of a request,
3028 but if you want to handle input yourself, you can enable on-demand
3029 parsing with a config parameter.
3030
3031     MyApp->config(parse_on_demand => 1);
3032
3033 =head1 PROXY SUPPORT
3034
3035 Many production servers operate using the common double-server approach,
3036 with a lightweight frontend web server passing requests to a larger
3037 backend server. An application running on the backend server must deal
3038 with two problems: the remote user always appears to be C<127.0.0.1> and
3039 the server's hostname will appear to be C<localhost> regardless of the
3040 virtual host that the user connected through.
3041
3042 Catalyst will automatically detect this situation when you are running
3043 the frontend and backend servers on the same machine. The following
3044 changes are made to the request.
3045
3046     $c->req->address is set to the user's real IP address, as read from
3047     the HTTP X-Forwarded-For header.
3048
3049     The host value for $c->req->base and $c->req->uri is set to the real
3050     host, as read from the HTTP X-Forwarded-Host header.
3051
3052 Additionally, you may be running your backend application on an insecure
3053 connection (port 80) while your frontend proxy is running under SSL.  If there
3054 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3055 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3056 be created properly.
3057
3058 In the case of passing in:
3059
3060     X-Forwarded-Port: 443
3061
3062 All calls to C<uri_for> will result in an https link, as is expected.
3063
3064 Obviously, your web server must support these headers for this to work.
3065
3066 In a more complex server farm environment where you may have your
3067 frontend proxy server(s) on different machines, you will need to set a
3068 configuration option to tell Catalyst to read the proxied data from the
3069 headers.
3070
3071     MyApp->config(using_frontend_proxy => 1);
3072
3073 If you do not wish to use the proxy support at all, you may set:
3074
3075     MyApp->config(ignore_frontend_proxy => 1);
3076
3077 =head1 THREAD SAFETY
3078
3079 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3080 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3081 believe the Catalyst core to be thread-safe.
3082
3083 If you plan to operate in a threaded environment, remember that all other
3084 modules you are using must also be thread-safe. Some modules, most notably
3085 L<DBD::SQLite>, are not thread-safe.
3086
3087 =head1 SUPPORT
3088
3089 IRC:
3090
3091     Join #catalyst on irc.perl.org.
3092
3093 Mailing Lists:
3094
3095     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3096     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3097
3098 Web:
3099
3100     http://catalyst.perl.org
3101
3102 Wiki:
3103
3104     http://dev.catalyst.perl.org
3105
3106 =head1 SEE ALSO
3107
3108 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3109
3110 =head2 L<Catalyst::Manual> - The Catalyst Manual
3111
3112 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3113
3114 =head2 L<Catalyst::Engine> - Core engine
3115
3116 =head2 L<Catalyst::Log> - Log class.
3117
3118 =head2 L<Catalyst::Request> - Request object
3119
3120 =head2 L<Catalyst::Response> - Response object
3121
3122 =head2 L<Catalyst::Test> - The test suite.
3123
3124 =head1 PROJECT FOUNDER
3125
3126 sri: Sebastian Riedel <sri@cpan.org>
3127
3128 =head1 CONTRIBUTORS
3129
3130 abw: Andy Wardley
3131
3132 acme: Leon Brocard <leon@astray.com>
3133
3134 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3135
3136 Andrew Bramble
3137
3138 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3139
3140 Andrew Ruthven
3141
3142 andyg: Andy Grundman <andy@hybridized.org>
3143
3144 audreyt: Audrey Tang
3145
3146 bricas: Brian Cassidy <bricas@cpan.org>
3147
3148 Caelum: Rafael Kitover <rkitover@io.com>
3149
3150 chansen: Christian Hansen
3151
3152 chicks: Christopher Hicks
3153
3154 Chisel Wright C<pause@herlpacker.co.uk>
3155
3156 Danijel Milicevic C<me@danijel.de>
3157
3158 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3159
3160 David Naughton, C<naughton@umn.edu>
3161
3162 David E. Wheeler
3163
3164 dhoss: Devin Austin <dhoss@cpan.org>
3165
3166 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3167
3168 Drew Taylor
3169
3170 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3171
3172 esskar: Sascha Kiefer
3173
3174 fireartist: Carl Franks <cfranks@cpan.org>
3175
3176 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3177
3178 gabb: Danijel Milicevic
3179
3180 Gary Ashton Jones
3181
3182 Gavin Henry C<ghenry@perl.me.uk>
3183
3184 Geoff Richards
3185
3186 groditi: Guillermo Roditi <groditi@gmail.com>
3187
3188 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3189
3190 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3191
3192 jcamacho: Juan Camacho
3193
3194 jester: Jesse Sheidlower C<jester@panix.com>
3195
3196 jhannah: Jay Hannah <jay@jays.net>
3197
3198 Jody Belka
3199
3200 Johan Lindstrom
3201
3202 jon: Jon Schutz <jjschutz@cpan.org>
3203
3204 Jonathan Rockway C<< <jrockway@cpan.org> >>
3205
3206 Kieren Diment C<kd@totaldatasolution.com>
3207
3208 konobi: Scott McWhirter <konobi@cpan.org>
3209
3210 marcus: Marcus Ramberg <mramberg@cpan.org>
3211
3212 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3213
3214 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3215
3216 mugwump: Sam Vilain
3217
3218 naughton: David Naughton
3219
3220 ningu: David Kamholz <dkamholz@cpan.org>
3221
3222 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3223
3224 numa: Dan Sully <daniel@cpan.org>
3225
3226 obra: Jesse Vincent
3227
3228 Octavian Rasnita
3229
3230 omega: Andreas Marienborg
3231
3232 Oleg Kostyuk <cub.uanic@gmail.com>
3233
3234 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3235
3236 rafl: Florian Ragwitz <rafl@debian.org>
3237
3238 random: Roland Lammel <lammel@cpan.org>
3239
3240 Robert Sedlacek C<< <rs@474.at> >>
3241
3242 SpiceMan: Marcel Montes
3243
3244 sky: Arthur Bergman
3245
3246 szbalint: Balint Szilakszi <szbalint@cpan.org>
3247
3248 t0m: Tomas Doran <bobtfish@bobtfish.net>
3249
3250 Ulf Edvinsson
3251
3252 Viljo Marrandi C<vilts@yahoo.com>
3253
3254 Will Hawes C<info@whawes.co.uk>
3255
3256 willert: Sebastian Willert <willert@cpan.org>
3257
3258 wreis: Wallace Reis <wallace@reis.org.br>
3259
3260 Yuval Kogman, C<nothingmuch@woobling.org>
3261
3262 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3263
3264 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3265
3266 =head1 COPYRIGHT
3267
3268 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3269
3270 =head1 LICENSE
3271
3272 This library is free software. You can redistribute it and/or modify it under
3273 the same terms as Perl itself.
3274
3275 =cut
3276
3277 no Moose;
3278
3279 __PACKAGE__->meta->make_immutable;
3280
3281 1;