lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'encode_utf8';
  54
  55 BEGIN { require 5.008003; }
  56
  57 has stack => (is => 'ro', default => sub { [] });
  58 has state => (is => 'rw', default => 0);
  59 has stats => (is => 'rw');
  60 has action => (is => 'rw');
  61 has counter => (is => 'rw', default => sub { {} });
  62 has request => (
  63     is => 'rw',
  64     default => sub {
  65         my $self = shift;
  66         $self->request_class->new($self->_build_request_constructor_args);
  67     },
  68     lazy => 1,
  69 );
  70 sub _build_request_constructor_args {
  71     my $self = shift;
  72     my %p = ( _log => $self->log );
  73     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  74     $p{data_handlers} = {$self->registered_data_handlers};
  75     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  76       if $self->config->{use_hash_multivalue_in_request};
  77     \%p;
  78 }
  79
  80 has response => (
  81     is => 'rw',
  82     default => sub {
  83         my $self = shift;
  84         $self->response_class->new($self->_build_response_constructor_args);
  85     },
  86     lazy => 1,
  87 );
  88 sub _build_response_constructor_args {
  89     my $self = shift;
  90     { _log => $self->log };
  91 }
  92
  93 has namespace => (is => 'rw');
  94
  95 sub depth { scalar @{ shift->stack || [] }; }
  96 sub comp { shift->component(@_) }
  97
  98 sub req {
  99     my $self = shift; return $self->request(@_);
 100 }
 101 sub res {
 102     my $self = shift; return $self->response(@_);
 103 }
 104
 105 # For backwards compatibility
 106 sub finalize_output { shift->finalize_body(@_) };
 107
 108 # For statistics
 109 our $COUNT     = 1;
 110 our $START     = time;
 111 our $RECURSION = 1000;
 112 our $DETACH    = Catalyst::Exception::Detach->new;
 113 our $GO        = Catalyst::Exception::Go->new;
 114
 115 #I imagine that very few of these really need to be class variables. if any.
 116 #maybe we should just make them attributes with a default?
 117 __PACKAGE__->mk_classdata($_)
 118   for qw/components arguments dispatcher engine log dispatcher_class
 119   engine_loader context_class request_class response_class stats_class
 120   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 121   _data_handlers _encoding _encode_check/;
 122
 123 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 124 __PACKAGE__->request_class('Catalyst::Request');
 125 __PACKAGE__->response_class('Catalyst::Response');
 126 __PACKAGE__->stats_class('Catalyst::Stats');
 127 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 128
 129 # Remember to update this in Catalyst::Runtime as well!
 130 our $VERSION = '5.90080_001';
 131 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 132
 133 sub import {
 134     my ( $class, @arguments ) = @_;
 135
 136     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 137     # callers @ISA.
 138     return unless $class eq 'Catalyst';
 139
 140     my $caller = caller();
 141     return if $caller eq 'main';
 142
 143     my $meta = Moose::Meta::Class->initialize($caller);
 144     unless ( $caller->isa('Catalyst') ) {
 145         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 146         $meta->superclasses(@superclasses);
 147     }
 148     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 149     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 150
 151     unless( $meta->has_method('meta') ){
 152         if ($Moose::VERSION >= 1.15) {
 153             $meta->_add_meta_method('meta');
 154         }
 155         else {
 156             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 157         }
 158     }
 159
 160     $caller->arguments( [@arguments] );
 161     $caller->setup_home;
 162 }
 163
 164 sub _application { $_[0] }
 165
 166 =encoding UTF-8
 167
 168 =head1 NAME
 169
 170 Catalyst - The Elegant MVC Web Application Framework
 171
 172 =head1 SYNOPSIS
 173
 174 See the L<Catalyst::Manual> distribution for comprehensive
 175 documentation and tutorials.
 176
 177     # Install Catalyst::Devel for helpers and other development tools
 178     # use the helper to create a new application
 179     catalyst.pl MyApp
 180
 181     # add models, views, controllers
 182     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 183     script/myapp_create.pl view MyTemplate TT
 184     script/myapp_create.pl controller Search
 185
 186     # built in testserver -- use -r to restart automatically on changes
 187     # --help to see all available options
 188     script/myapp_server.pl
 189
 190     # command line testing interface
 191     script/myapp_test.pl /yada
 192
 193     ### in lib/MyApp.pm
 194     use Catalyst qw/-Debug/; # include plugins here as well
 195
 196     ### In lib/MyApp/Controller/Root.pm (autocreated)
 197     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 198         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 199         $c->stash->{template} = 'foo.tt'; # set the template
 200         # lookup something from db -- stash vars are passed to TT
 201         $c->stash->{data} =
 202           $c->model('Database::Foo')->search( { country => $args[0] } );
 203         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 204             $c->forward( 'bar' ); # process another action
 205             # do something else after forward returns
 206         }
 207     }
 208
 209     # The foo.tt TT template can use the stash data from the database
 210     [% WHILE (item = data.next) %]
 211         [% item.foo %]
 212     [% END %]
 213
 214     # called for /bar/of/soap, /bar/of/soap/10, etc.
 215     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 216
 217     # called after all actions are finished
 218     sub end : Action {
 219         my ( $self, $c ) = @_;
 220         if ( scalar @{ $c->error } ) { ... } # handle errors
 221         return if $c->res->body; # already have a response
 222         $c->forward( 'MyApp::View::TT' ); # render template
 223     }
 224
 225 See L<Catalyst::Manual::Intro> for additional information.
 226
 227 =head1 DESCRIPTION
 228
 229 Catalyst is a modern framework for making web applications without the
 230 pain usually associated with this process. This document is a reference
 231 to the main Catalyst application. If you are a new user, we suggest you
 232 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 233
 234 See L<Catalyst::Manual> for more documentation.
 235
 236 Catalyst plugins can be loaded by naming them as arguments to the "use
 237 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 238 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 239 C<My::Module>.
 240
 241     use Catalyst qw/My::Module/;
 242
 243 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 244 fully qualify the name by using a unary plus:
 245
 246     use Catalyst qw/
 247         My::Module
 248         +Fully::Qualified::Plugin::Name
 249     /;
 250
 251 Special flags like C<-Debug> can also be specified as
 252 arguments when Catalyst is loaded:
 253
 254     use Catalyst qw/-Debug My::Module/;
 255
 256 The position of plugins and flags in the chain is important, because
 257 they are loaded in the order in which they appear.
 258
 259 The following flags are supported:
 260
 261 =head2 -Debug
 262
 263 Enables debug output. You can also force this setting from the system
 264 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 265 settings override the application, with <MYAPP>_DEBUG having the highest
 266 priority.
 267
 268 This sets the log level to 'debug' and enables full debug output on the
 269 error screen. If you only want the latter, see L<< $c->debug >>.
 270
 271 =head2 -Home
 272
 273 Forces Catalyst to use a specific home directory, e.g.:
 274
 275     use Catalyst qw[-Home=/usr/mst];
 276
 277 This can also be done in the shell environment by setting either the
 278 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 279 is replaced with the uppercased name of your application, any "::" in
 280 the name will be replaced with underscores, e.g. MyApp::Web should use
 281 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 282
 283 If none of these are set, Catalyst will attempt to automatically detect the
 284 home directory. If you are working in a development environment, Catalyst
 285 will try and find the directory containing either Makefile.PL, Build.PL,
 286 dist.ini, or cpanfile. If the application has been installed into the system
 287 (i.e. you have done C<make install>), then Catalyst will use the path to your
 288 application module, without the .pm extension (e.g., /foo/MyApp if your
 289 application was installed at /foo/MyApp.pm)
 290
 291 =head2 -Log
 292
 293     use Catalyst '-Log=warn,fatal,error';
 294
 295 Specifies a comma-delimited list of log levels.
 296
 297 =head2 -Stats
 298
 299 Enables statistics collection and reporting.
 300
 301    use Catalyst qw/-Stats=1/;
 302
 303 You can also force this setting from the system environment with CATALYST_STATS
 304 or <MYAPP>_STATS. The environment settings override the application, with
 305 <MYAPP>_STATS having the highest priority.
 306
 307 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 308
 309 =head1 METHODS
 310
 311 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 312
 313 =head2 $c->action
 314
 315 Returns a L<Catalyst::Action> object for the current action, which
 316 stringifies to the action name. See L<Catalyst::Action>.
 317
 318 =head2 $c->namespace
 319
 320 Returns the namespace of the current action, i.e., the URI prefix
 321 corresponding to the controller of the current action. For example:
 322
 323     # in Controller::Foo::Bar
 324     $c->namespace; # returns 'foo/bar';
 325
 326 =head2 $c->request
 327
 328 =head2 $c->req
 329
 330 Returns the current L<Catalyst::Request> object, giving access to
 331 information about the current client request (including parameters,
 332 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 333
 334 =head2 REQUEST FLOW HANDLING
 335
 336 =head2 $c->forward( $action [, \@arguments ] )
 337
 338 =head2 $c->forward( $class, $method, [, \@arguments ] )
 339
 340 This is one way of calling another action (method) in the same or
 341 a different controller. You can also use C<< $self->my_method($c, @args) >>
 342 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 343 in a different controller.
 344 The main difference is that 'forward' uses some of the Catalyst request
 345 cycle overhead, including debugging, which may be useful to you. On the
 346 other hand, there are some complications to using 'forward', restrictions
 347 on values returned from 'forward', and it may not handle errors as you prefer.
 348 Whether you use 'forward' or not is up to you; it is not considered superior to
 349 the other ways to call a method.
 350
 351 'forward' calls  another action, by its private name. If you give a
 352 class name but no method, C<process()> is called. You may also optionally
 353 pass arguments in an arrayref. The action will receive the arguments in
 354 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 355 C<< $c->req->args >> will be restored to the previous values.
 356
 357 Any data C<return>ed from the action forwarded to, will be returned by the
 358 call to forward.
 359
 360     my $foodata = $c->forward('/foo');
 361     $c->forward('index');
 362     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 363     $c->forward('View::TT');
 364
 365 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 366 an C<< eval { } >> around the call (actually
 367 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 368 exceptions thrown by the called action non-fatal and pushing them onto
 369 $c->error instead. If you want C<die> to propagate you need to do something
 370 like:
 371
 372     $c->forward('foo');
 373     die join "\n", @{ $c->error } if @{ $c->error };
 374
 375 Or make sure to always return true values from your actions and write
 376 your code like this:
 377
 378     $c->forward('foo') || return;
 379
 380 Another note is that C<< $c->forward >> always returns a scalar because it
 381 actually returns $c->state which operates in a scalar context.
 382 Thus, something like:
 383
 384     return @array;
 385
 386 in an action that is forwarded to is going to return a scalar,
 387 i.e. how many items are in that array, which is probably not what you want.
 388 If you need to return an array then return a reference to it,
 389 or stash it like so:
 390
 391     $c->stash->{array} = \@array;
 392
 393 and access it from the stash.
 394
 395 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 396
 397 =cut
 398
 399 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 400
 401 =head2 $c->detach( $action [, \@arguments ] )
 402
 403 =head2 $c->detach( $class, $method, [, \@arguments ] )
 404
 405 =head2 $c->detach()
 406
 407 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 408 doesn't return to the previous action when processing is finished.
 409
 410 When called with no arguments it escapes the processing chain entirely.
 411
 412 =cut
 413
 414 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 415
 416 =head2 $c->visit( $action [, \@arguments ] )
 417
 418 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 419
 420 =head2 $c->visit( $class, $method, [, \@arguments ] )
 421
 422 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 423
 424 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 425 but does a full dispatch, instead of just calling the new C<$action> /
 426 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 427 you go to are called, just like a new request.
 428
 429 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 430 This means, for example, that C<< $c->action >> methods such as
 431 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 432 L<reverse|Catalyst::Action/reverse> return information for the visited action
 433 when they are invoked within the visited action.  This is different from the
 434 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 435 continues to use the $c->action object from the caller action even when
 436 invoked from the called action.
 437
 438 C<< $c->stash >> is kept unchanged.
 439
 440 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 441 allows you to "wrap" another action, just as it would have been called by
 442 dispatching from a URL, while the analogous
 443 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 444 transfer control to another action as if it had been reached directly from a URL.
 445
 446 =cut
 447
 448 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 449
 450 =head2 $c->go( $action [, \@arguments ] )
 451
 452 =head2 $c->go( $action [, \@captures, \@arguments ] )
 453
 454 =head2 $c->go( $class, $method, [, \@arguments ] )
 455
 456 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 457
 458 The relationship between C<go> and
 459 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 460 the relationship between
 461 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 462 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 463 C<< $c->go >> will perform a full dispatch on the specified action or method,
 464 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 465 C<go> escapes the processing of the current request chain on completion, and
 466 does not return to its caller.
 467
 468 @arguments are arguments to the final destination of $action. @captures are
 469 arguments to the intermediate steps, if any, on the way to the final sub of
 470 $action.
 471
 472 =cut
 473
 474 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 475
 476 =head2 $c->response
 477
 478 =head2 $c->res
 479
 480 Returns the current L<Catalyst::Response> object, see there for details.
 481
 482 =head2 $c->stash
 483
 484 Returns a hashref to the stash, which may be used to store data and pass
 485 it between components during a request. You can also set hash keys by
 486 passing arguments. The stash is automatically sent to the view. The
 487 stash is cleared at the end of a request; it cannot be used for
 488 persistent storage (for this you must use a session; see
 489 L<Catalyst::Plugin::Session> for a complete system integrated with
 490 Catalyst).
 491
 492     $c->stash->{foo} = $bar;
 493     $c->stash( { moose => 'majestic', qux => 0 } );
 494     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 495
 496     # stash is automatically passed to the view for use in a template
 497     $c->forward( 'MyApp::View::TT' );
 498
 499 The stash hash is currently stored in the PSGI C<$env> and is managed by
 500 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 501 the stash can be accessed in sub applications mounted under your main
 502 L<Catalyst> application.  For example if you delegate the response of an
 503 action to another L<Catalyst> application, that sub application will have
 504 access to all the stash keys of the main one, and if can of course add
 505 more keys of its own.  However those new keys will not 'bubble' back up
 506 to the main application.
 507
 508 For more information the best thing to do is to review the test case:
 509 t/middleware-stash.t in the distribution /t directory.
 510
 511 =cut
 512
 513 sub stash {
 514   my $c = shift;
 515   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 516 }
 517
 518 =head2 $c->error
 519
 520 =head2 $c->error($error, ...)
 521
 522 =head2 $c->error($arrayref)
 523
 524 Returns an arrayref containing error messages.  If Catalyst encounters an
 525 error while processing a request, it stores the error in $c->error.  This
 526 method should only be used to store fatal error messages.
 527
 528     my @error = @{ $c->error };
 529
 530 Add a new error.
 531
 532     $c->error('Something bad happened');
 533
 534 =cut
 535
 536 sub error {
 537     my $c = shift;
 538     if ( $_[0] ) {
 539         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 540         croak @$error unless ref $c;
 541         push @{ $c->{error} }, @$error;
 542     }
 543     elsif ( defined $_[0] ) { $c->{error} = undef }
 544     return $c->{error} || [];
 545 }
 546
 547
 548 =head2 $c->state
 549
 550 Contains the return value of the last executed action.
 551 Note that << $c->state >> operates in a scalar context which means that all
 552 values it returns are scalar.
 553
 554 =head2 $c->clear_errors
 555
 556 Clear errors.  You probably don't want to clear the errors unless you are
 557 implementing a custom error screen.
 558
 559 This is equivalent to running
 560
 561     $c->error(0);
 562
 563 =cut
 564
 565 sub clear_errors {
 566     my $c = shift;
 567     $c->error(0);
 568 }
 569
 570 =head2 $c->has_errors
 571
 572 Returns true if you have errors
 573
 574 =cut
 575
 576 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 577
 578 sub _comp_search_prefixes {
 579     my $c = shift;
 580     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 581 }
 582
 583 # search components given a name and some prefixes
 584 sub _comp_names_search_prefixes {
 585     my ( $c, $name, @prefixes ) = @_;
 586     my $appclass = ref $c || $c;
 587     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 588     $filter = qr/$filter/; # Compile regex now rather than once per loop
 589
 590     # map the original component name to the sub part that we will search against
 591     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 592         grep { /$filter/ } keys %{ $c->components };
 593
 594     # undef for a name will return all
 595     return keys %eligible if !defined $name;
 596
 597     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 598     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 599
 600     return @result if @result;
 601
 602     # if we were given a regexp to search against, we're done.
 603     return if $name->$_isa('Regexp');
 604
 605     # skip regexp fallback if configured
 606     return
 607         if $appclass->config->{disable_component_resolution_regex_fallback};
 608
 609     # regexp fallback
 610     $query  = qr/$name/i;
 611     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 612
 613     # no results? try against full names
 614     if( !@result ) {
 615         @result = grep { m{$query} } keys %eligible;
 616     }
 617
 618     # don't warn if we didn't find any results, it just might not exist
 619     if( @result ) {
 620         # Disgusting hack to work out correct method name
 621         my $warn_for = lc $prefixes[0];
 622         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 623            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 624            "component resolution is unreliable and unsafe.";
 625         my $short = $result[0];
 626         # remove the component namespace prefix
 627         $short =~ s/.*?(Model|Controller|View):://;
 628         my $shortmess = Carp::shortmess('');
 629         if ($shortmess =~ m#Catalyst/Plugin#) {
 630            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 631               "plugin's config";
 632         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 633            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 634               "component's config";
 635         } else {
 636            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 637               "but if you really wanted to search, pass in a regexp as the argument " .
 638               "like so: \$c->${warn_for}(qr/${name}/)";
 639         }
 640         $c->log->warn( "${msg}$shortmess" );
 641     }
 642
 643     return @result;
 644 }
 645
 646 # Find possible names for a prefix
 647 sub _comp_names {
 648     my ( $c, @prefixes ) = @_;
 649     my $appclass = ref $c || $c;
 650
 651     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 652
 653     my @names = map { s{$filter}{}; $_; }
 654         $c->_comp_names_search_prefixes( undef, @prefixes );
 655
 656     return @names;
 657 }
 658
 659 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 660 sub _filter_component {
 661     my ( $c, $comp, @args ) = @_;
 662
 663     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 664         return $comp->ACCEPT_CONTEXT( $c, @args );
 665     }
 666
 667     return $comp;
 668 }
 669
 670 =head2 COMPONENT ACCESSORS
 671
 672 =head2 $c->controller($name)
 673
 674 Gets a L<Catalyst::Controller> instance by name.
 675
 676     $c->controller('Foo')->do_stuff;
 677
 678 If the name is omitted, will return the controller for the dispatched
 679 action.
 680
 681 If you want to search for controllers, pass in a regexp as the argument.
 682
 683     # find all controllers that start with Foo
 684     my @foo_controllers = $c->controller(qr{^Foo});
 685
 686
 687 =cut
 688
 689 sub controller {
 690     my ( $c, $name, @args ) = @_;
 691
 692     my $appclass = ref($c) || $c;
 693     if( $name ) {
 694         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 695             my $comps = $c->components;
 696             my $check = $appclass."::Controller::".$name;
 697             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 698         }
 699         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 700         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 701         return $c->_filter_component( $result[ 0 ], @args );
 702     }
 703
 704     return $c->component( $c->action->class );
 705 }
 706
 707 =head2 $c->model($name)
 708
 709 Gets a L<Catalyst::Model> instance by name.
 710
 711     $c->model('Foo')->do_stuff;
 712
 713 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 714
 715 If the name is omitted, it will look for
 716  - a model object in $c->stash->{current_model_instance}, then
 717  - a model name in $c->stash->{current_model}, then
 718  - a config setting 'default_model', or
 719  - check if there is only one model, and return it if that's the case.
 720
 721 If you want to search for models, pass in a regexp as the argument.
 722
 723     # find all models that start with Foo
 724     my @foo_models = $c->model(qr{^Foo});
 725
 726 =cut
 727
 728 sub model {
 729     my ( $c, $name, @args ) = @_;
 730     my $appclass = ref($c) || $c;
 731     if( $name ) {
 732         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 733             my $comps = $c->components;
 734             my $check = $appclass."::Model::".$name;
 735             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 736         }
 737         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 738         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 739         return $c->_filter_component( $result[ 0 ], @args );
 740     }
 741
 742     if (ref $c) {
 743         return $c->stash->{current_model_instance}
 744           if $c->stash->{current_model_instance};
 745         return $c->model( $c->stash->{current_model} )
 746           if $c->stash->{current_model};
 747     }
 748     return $c->model( $appclass->config->{default_model} )
 749       if $appclass->config->{default_model};
 750
 751     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 752
 753     if( $rest ) {
 754         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 755         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 756         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 757         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 758         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 759     }
 760
 761     return $c->_filter_component( $comp );
 762 }
 763
 764
 765 =head2 $c->view($name)
 766
 767 Gets a L<Catalyst::View> instance by name.
 768
 769     $c->view('Foo')->do_stuff;
 770
 771 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 772
 773 If the name is omitted, it will look for
 774  - a view object in $c->stash->{current_view_instance}, then
 775  - a view name in $c->stash->{current_view}, then
 776  - a config setting 'default_view', or
 777  - check if there is only one view, and return it if that's the case.
 778
 779 If you want to search for views, pass in a regexp as the argument.
 780
 781     # find all views that start with Foo
 782     my @foo_views = $c->view(qr{^Foo});
 783
 784 =cut
 785
 786 sub view {
 787     my ( $c, $name, @args ) = @_;
 788
 789     my $appclass = ref($c) || $c;
 790     if( $name ) {
 791         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 792             my $comps = $c->components;
 793             my $check = $appclass."::View::".$name;
 794             if( exists $comps->{$check} ) {
 795                 return $c->_filter_component( $comps->{$check}, @args );
 796             }
 797             else {
 798                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 799             }
 800         }
 801         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 802         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 803         return $c->_filter_component( $result[ 0 ], @args );
 804     }
 805
 806     if (ref $c) {
 807         return $c->stash->{current_view_instance}
 808           if $c->stash->{current_view_instance};
 809         return $c->view( $c->stash->{current_view} )
 810           if $c->stash->{current_view};
 811     }
 812     return $c->view( $appclass->config->{default_view} )
 813       if $appclass->config->{default_view};
 814
 815     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 816
 817     if( $rest ) {
 818         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 819         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 820         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 821         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 822         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 823     }
 824
 825     return $c->_filter_component( $comp );
 826 }
 827
 828 =head2 $c->controllers
 829
 830 Returns the available names which can be passed to $c->controller
 831
 832 =cut
 833
 834 sub controllers {
 835     my ( $c ) = @_;
 836     return $c->_comp_names(qw/Controller C/);
 837 }
 838
 839 =head2 $c->models
 840
 841 Returns the available names which can be passed to $c->model
 842
 843 =cut
 844
 845 sub models {
 846     my ( $c ) = @_;
 847     return $c->_comp_names(qw/Model M/);
 848 }
 849
 850
 851 =head2 $c->views
 852
 853 Returns the available names which can be passed to $c->view
 854
 855 =cut
 856
 857 sub views {
 858     my ( $c ) = @_;
 859     return $c->_comp_names(qw/View V/);
 860 }
 861
 862 =head2 $c->comp($name)
 863
 864 =head2 $c->component($name)
 865
 866 Gets a component object by name. This method is not recommended,
 867 unless you want to get a specific component by full
 868 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 869 should be used instead.
 870
 871 If C<$name> is a regexp, a list of components matched against the full
 872 component name will be returned.
 873
 874 If Catalyst can't find a component by name, it will fallback to regex
 875 matching by default. To disable this behaviour set
 876 disable_component_resolution_regex_fallback to a true value.
 877
 878     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 879
 880 =cut
 881
 882 sub component {
 883     my ( $c, $name, @args ) = @_;
 884
 885     if( $name ) {
 886         my $comps = $c->components;
 887
 888         if( !ref $name ) {
 889             # is it the exact name?
 890             return $c->_filter_component( $comps->{ $name }, @args )
 891                        if exists $comps->{ $name };
 892
 893             # perhaps we just omitted "MyApp"?
 894             my $composed = ( ref $c || $c ) . "::${name}";
 895             return $c->_filter_component( $comps->{ $composed }, @args )
 896                        if exists $comps->{ $composed };
 897
 898             # search all of the models, views and controllers
 899             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 900             return $c->_filter_component( $comp, @args ) if $comp;
 901         }
 902
 903         return
 904             if $c->config->{disable_component_resolution_regex_fallback};
 905
 906         # This is here so $c->comp( '::M::' ) works
 907         my $query = ref $name ? $name : qr{$name}i;
 908
 909         my @result = grep { m{$query} } keys %{ $c->components };
 910         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 911
 912         if( $result[ 0 ] ) {
 913             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 914             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 915             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 916             return $c->_filter_component( $result[ 0 ], @args );
 917         }
 918
 919         # I would expect to return an empty list here, but that breaks back-compat
 920     }
 921
 922     # fallback
 923     return sort keys %{ $c->components };
 924 }
 925
 926 =head2 CLASS DATA AND HELPER CLASSES
 927
 928 =head2 $c->config
 929
 930 Returns or takes a hashref containing the application's configuration.
 931
 932     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 933
 934 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 935 like C<myapp.conf> in your applications home directory. See
 936 L<Catalyst::Plugin::ConfigLoader>.
 937
 938 =head3 Cascading configuration
 939
 940 The config method is present on all Catalyst components, and configuration
 941 will be merged when an application is started. Configuration loaded with
 942 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 943 followed by configuration in your top level C<MyApp> class. These two
 944 configurations are merged, and then configuration data whose hash key matches a
 945 component name is merged with configuration for that component.
 946
 947 The configuration for a component is then passed to the C<new> method when a
 948 component is constructed.
 949
 950 For example:
 951
 952     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 953     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 954
 955 will mean that C<MyApp::Model::Foo> receives the following data when
 956 constructed:
 957
 958     MyApp::Model::Foo->new({
 959         bar => 'baz',
 960         quux => 'frob',
 961         overrides => 'me',
 962     });
 963
 964 It's common practice to use a Moose attribute
 965 on the receiving component to access the config value.
 966
 967     package MyApp::Model::Foo;
 968
 969     use Moose;
 970
 971     # this attr will receive 'baz' at construction time
 972     has 'bar' => (
 973         is  => 'rw',
 974         isa => 'Str',
 975     );
 976
 977 You can then get the value 'baz' by calling $c->model('Foo')->bar
 978 (or $self->bar inside code in the model).
 979
 980 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 981 as a way of reading config within your code, as this B<will not> give you the
 982 correctly merged config back. You B<MUST> take the config values supplied to
 983 the constructor and use those instead.
 984
 985 =cut
 986
 987 around config => sub {
 988     my $orig = shift;
 989     my $c = shift;
 990
 991     croak('Setting config after setup has been run is not allowed.')
 992         if ( @_ and $c->setup_finished );
 993
 994     $c->$orig(@_);
 995 };
 996
 997 =head2 $c->log
 998
 999 Returns the logging object instance. Unless it is already set, Catalyst
1000 sets this up with a L<Catalyst::Log> object. To use your own log class,
1001 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1002 C<< __PACKAGE__->setup >>.
1003
1004  __PACKAGE__->log( MyLogger->new );
1005  __PACKAGE__->setup;
1006
1007 And later:
1008
1009     $c->log->info( 'Now logging with my own logger!' );
1010
1011 Your log class should implement the methods described in
1012 L<Catalyst::Log>.
1013
1014 =head2 encoding
1015
1016 Sets or gets the application encoding.
1017
1018 =cut
1019
1020 sub encoding {
1021     my $c = shift;
1022     my $encoding;
1023
1024     if ( scalar @_ ) {
1025         # Let it be set to undef
1026         if (my $wanted = shift)  {
1027             $encoding = Encode::find_encoding($wanted)
1028               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1029             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1030         }
1031         else {
1032             binmode(STDERR);
1033         }
1034
1035         $encoding = ref $c
1036                   ? $c->{encoding} = $encoding
1037                   : $c->_encoding($encoding);
1038     } else {
1039       $encoding = ref $c && exists $c->{encoding}
1040                 ? $c->{encoding}
1041                 : $c->_encoding;
1042     }
1043
1044     return $encoding;
1045 }
1046
1047 =head2 $c->debug
1048
1049 Returns 1 if debug mode is enabled, 0 otherwise.
1050
1051 You can enable debug mode in several ways:
1052
1053 =over
1054
1055 =item By calling myapp_server.pl with the -d flag
1056
1057 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1058
1059 =item The -Debug option in your MyApp.pm
1060
1061 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1062
1063 =back
1064
1065 The first three also set the log level to 'debug'.
1066
1067 Calling C<< $c->debug(1) >> has no effect.
1068
1069 =cut
1070
1071 sub debug { 0 }
1072
1073 =head2 $c->dispatcher
1074
1075 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1076
1077 =head2 $c->engine
1078
1079 Returns the engine instance. See L<Catalyst::Engine>.
1080
1081
1082 =head2 UTILITY METHODS
1083
1084 =head2 $c->path_to(@path)
1085
1086 Merges C<@path> with C<< $c->config->{home} >> and returns a
1087 L<Path::Class::Dir> object. Note you can usually use this object as
1088 a filename, but sometimes you will have to explicitly stringify it
1089 yourself by calling the C<< ->stringify >> method.
1090
1091 For example:
1092
1093     $c->path_to( 'db', 'sqlite.db' );
1094
1095 =cut
1096
1097 sub path_to {
1098     my ( $c, @path ) = @_;
1099     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1100     if ( -d $path ) { return $path }
1101     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1102 }
1103
1104 sub plugin {
1105     my ( $class, $name, $plugin, @args ) = @_;
1106
1107     # See block comment in t/unit_core_plugin.t
1108     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1109
1110     $class->_register_plugin( $plugin, 1 );
1111
1112     eval { $plugin->import };
1113     $class->mk_classdata($name);
1114     my $obj;
1115     eval { $obj = $plugin->new(@args) };
1116
1117     if ($@) {
1118         Catalyst::Exception->throw( message =>
1119               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1120     }
1121
1122     $class->$name($obj);
1123     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1124       if $class->debug;
1125 }
1126
1127 =head2 MyApp->setup
1128
1129 Initializes the dispatcher and engine, loads any plugins, and loads the
1130 model, view, and controller components. You may also specify an array
1131 of plugins to load here, if you choose to not load them in the C<use
1132 Catalyst> line.
1133
1134     MyApp->setup;
1135     MyApp->setup( qw/-Debug/ );
1136
1137 B<Note:> You B<should not> wrap this method with method modifiers
1138 or bad things will happen - wrap the C<setup_finalize> method instead.
1139
1140 =cut
1141
1142 sub setup {
1143     my ( $class, @arguments ) = @_;
1144     croak('Running setup more than once')
1145         if ( $class->setup_finished );
1146
1147     unless ( $class->isa('Catalyst') ) {
1148
1149         Catalyst::Exception->throw(
1150             message => qq/'$class' does not inherit from Catalyst/ );
1151     }
1152
1153     if ( $class->arguments ) {
1154         @arguments = ( @arguments, @{ $class->arguments } );
1155     }
1156
1157     # Process options
1158     my $flags = {};
1159
1160     foreach (@arguments) {
1161
1162         if (/^-Debug$/) {
1163             $flags->{log} =
1164               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1165         }
1166         elsif (/^-(\w+)=?(.*)$/) {
1167             $flags->{ lc $1 } = $2;
1168         }
1169         else {
1170             push @{ $flags->{plugins} }, $_;
1171         }
1172     }
1173
1174     $class->setup_home( delete $flags->{home} );
1175
1176     $class->setup_log( delete $flags->{log} );
1177     $class->setup_plugins( delete $flags->{plugins} );
1178
1179     $class->setup_data_handlers();
1180     $class->setup_dispatcher( delete $flags->{dispatcher} );
1181     if (my $engine = delete $flags->{engine}) {
1182         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1183     }
1184     $class->setup_engine();
1185     $class->setup_stats( delete $flags->{stats} );
1186
1187     for my $flag ( sort keys %{$flags} ) {
1188
1189         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1190             &$code( $class, delete $flags->{$flag} );
1191         }
1192         else {
1193             $class->log->warn(qq/Unknown flag "$flag"/);
1194         }
1195     }
1196
1197     eval { require Catalyst::Devel; };
1198     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1199         $class->log->warn(<<"EOF");
1200 You are running an old script!
1201
1202   Please update by running (this will overwrite existing files):
1203     catalyst.pl -force -scripts $class
1204
1205   or (this will not overwrite existing files):
1206     catalyst.pl -scripts $class
1207
1208 EOF
1209     }
1210
1211     # Call plugins setup, this is stupid and evil.
1212     # Also screws C3 badly on 5.10, hack to avoid.
1213     {
1214         no warnings qw/redefine/;
1215         local *setup = sub { };
1216         $class->setup unless $Catalyst::__AM_RESTARTING;
1217     }
1218
1219     # If you are expecting configuration info as part of your setup, it needs
1220     # to get called here and below, since we need the above line to support
1221     # ConfigLoader based configs.
1222
1223     $class->setup_encoding();
1224     $class->setup_middleware();
1225
1226     # Initialize our data structure
1227     $class->components( {} );
1228
1229     $class->setup_components;
1230
1231     if ( $class->debug ) {
1232         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1233
1234         if (@plugins) {
1235             my $column_width = Catalyst::Utils::term_width() - 6;
1236             my $t = Text::SimpleTable->new($column_width);
1237             $t->row($_) for @plugins;
1238             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1239         }
1240
1241         my @middleware = map {
1242           ref $_ eq 'CODE' ?
1243             "Inline Coderef" :
1244               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1245                 || '')  } $class->registered_middlewares;
1246
1247         if (@middleware) {
1248             my $column_width = Catalyst::Utils::term_width() - 6;
1249             my $t = Text::SimpleTable->new($column_width);
1250             $t->row($_) for @middleware;
1251             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1252         }
1253
1254         my %dh = $class->registered_data_handlers;
1255         if (my @data_handlers = keys %dh) {
1256             my $column_width = Catalyst::Utils::term_width() - 6;
1257             my $t = Text::SimpleTable->new($column_width);
1258             $t->row($_) for @data_handlers;
1259             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1260         }
1261
1262         my $dispatcher = $class->dispatcher;
1263         my $engine     = $class->engine;
1264         my $home       = $class->config->{home};
1265
1266         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1267         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1268
1269         $home
1270           ? ( -d $home )
1271           ? $class->log->debug(qq/Found home "$home"/)
1272           : $class->log->debug(qq/Home "$home" doesn't exist/)
1273           : $class->log->debug(q/Couldn't find home/);
1274
1275         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1276         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1277         for my $comp ( sort keys %{ $class->components } ) {
1278             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1279             $t->row( $comp, $type );
1280         }
1281         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1282           if ( keys %{ $class->components } );
1283     }
1284
1285     # Add our self to components, since we are also a component
1286     if( $class->isa('Catalyst::Controller') ){
1287       $class->components->{$class} = $class;
1288     }
1289
1290     $class->setup_actions;
1291
1292     if ( $class->debug ) {
1293         my $name = $class->config->{name} || 'Application';
1294         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1295     }
1296
1297     if ($class->config->{case_sensitive}) {
1298         $class->log->warn($class . "->config->{case_sensitive} is set.");
1299         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1300     }
1301
1302     $class->setup_finalize;
1303
1304     # Flush the log for good measure (in case something turned off 'autoflush' early)
1305     $class->log->_flush() if $class->log->can('_flush');
1306
1307     return $class || 1; # Just in case someone named their Application 0...
1308 }
1309
1310 =head2 $app->setup_finalize
1311
1312 A hook to attach modifiers to. This method does not do anything except set the
1313 C<setup_finished> accessor.
1314
1315 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1316
1317 Example:
1318
1319     after setup_finalize => sub {
1320         my $app = shift;
1321
1322         ## do stuff here..
1323     };
1324
1325 =cut
1326
1327 sub setup_finalize {
1328     my ($class) = @_;
1329     $class->setup_finished(1);
1330 }
1331
1332 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1333
1334 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1335
1336 Constructs an absolute L<URI> object based on the application root, the
1337 provided path, and the additional arguments and query parameters provided.
1338 When used as a string, provides a textual URI.  If you need more flexibility
1339 than this (i.e. the option to provide relative URIs etc.) see
1340 L<Catalyst::Plugin::SmartURI>.
1341
1342 If no arguments are provided, the URI for the current action is returned.
1343 To return the current action and also provide @args, use
1344 C<< $c->uri_for( $c->action, @args ) >>.
1345
1346 If the first argument is a string, it is taken as a public URI path relative
1347 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1348 relative to the application root (if it does). It is then merged with
1349 C<< $c->request->base >>; any C<@args> are appended as additional path
1350 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1351
1352 If the first argument is a L<Catalyst::Action> it represents an action which
1353 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1354 optional C<\@captures> argument (an arrayref) allows passing the captured
1355 variables that are needed to fill in the paths of Chained and Regex actions;
1356 once the path is resolved, C<uri_for> continues as though a path was
1357 provided, appending any arguments or parameters and creating an absolute
1358 URI.
1359
1360 The captures for the current request can be found in
1361 C<< $c->request->captures >>, and actions can be resolved using
1362 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1363 path, use C<< $c->uri_for_action >> instead.
1364
1365   # Equivalent to $c->req->uri
1366   $c->uri_for($c->action, $c->req->captures,
1367       @{ $c->req->args }, $c->req->params);
1368
1369   # For the Foo action in the Bar controller
1370   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1371
1372   # Path to a static resource
1373   $c->uri_for('/static/images/logo.png');
1374
1375 =cut
1376
1377 sub uri_for {
1378     my ( $c, $path, @args ) = @_;
1379
1380     if ( $path->$_isa('Catalyst::Controller') ) {
1381         $path = $path->path_prefix;
1382         $path =~ s{/+\z}{};
1383         $path .= '/';
1384     }
1385
1386     undef($path) if (defined $path && $path eq '');
1387
1388     my $params =
1389       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1390
1391     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1392
1393     my @encoded_args = ();
1394     foreach my $arg (@args) {
1395       if(ref($arg)||'' eq 'ARRAY') {
1396         push @encoded_args, [map {
1397           my $encoded = encode_utf8 $_;
1398           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1399          $encoded;
1400         } @$arg];
1401       } else {
1402         push @encoded_args, do {
1403           my $encoded = encode_utf8 $arg;
1404           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1405           $encoded;
1406         }
1407       }
1408     }
1409
1410     if ( $path->$_isa('Catalyst::Action') ) { # action object
1411         s|/|%2F|g for @encoded_args;
1412         my $captures = [ map { s|/|%2F|g; $_; }
1413                         ( scalar @encoded_args && ref $encoded_args[0] eq 'ARRAY'
1414                          ? @{ shift(@encoded_args) }
1415                          : ()) ];
1416
1417         my $action = $path;
1418         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1419         if( !@encoded_args && $action->number_of_args ) {
1420             my $expanded_action = $c->dispatcher->expand_action( $action );
1421
1422             my $num_captures = $expanded_action->number_of_captures;
1423             unshift @encoded_args, splice @$captures, $num_captures;
1424         }
1425
1426        $path = $c->dispatcher->uri_for_action($action, $captures);
1427         if (not defined $path) {
1428             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1429                 if $c->debug;
1430             return undef;
1431         }
1432         $path = '/' if $path eq '';
1433     }
1434
1435     unshift(@encoded_args, $path);
1436
1437     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1438         my $namespace = $c->namespace;
1439         if (defined $path) { # cheesy hack to handle path '../foo'
1440            $namespace =~ s{(?:^|/)[^/]+$}{} while $encoded_args[0] =~ s{^\.\./}{};
1441         }
1442         unshift(@encoded_args, $namespace || '');
1443     }
1444
1445     # join args with '/', or a blank string
1446     my $args = join('/', grep { defined($_) } @encoded_args);
1447     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1448     $args =~ s!^/+!!;
1449
1450     my ($base, $class) = ('/', 'URI::_generic');
1451     if(blessed($c)) {
1452       $base = $c->req->base;
1453       $class = ref($base);
1454       $base =~ s{(?<!/)$}{/};
1455     }
1456
1457     my $query = '';
1458
1459     if (my @keys = keys %$params) {
1460       # somewhat lifted from URI::_query's query_form
1461       $query = '?'.join('&', map {
1462           my $val = $params->{$_};
1463           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1464           s/ /+/g;
1465           my $key = $_;
1466           $val = '' unless defined $val;
1467           (map {
1468               my $param = "$_";
1469               $param = encode_utf8($param);
1470               # using the URI::Escape pattern here so utf8 chars survive
1471               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1472               $param =~ s/ /+/g;
1473
1474               $key = encode_utf8($key);
1475               # using the URI::Escape pattern here so utf8 chars survive
1476               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1477               $key =~ s/ /+/g;
1478
1479               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1480       } @keys);
1481     }
1482
1483     my $res = bless(\"${base}${args}${query}", $class);
1484     $res;
1485 }
1486
1487 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1488
1489 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1490
1491 =over
1492
1493 =item $path
1494
1495 A private path to the Catalyst action you want to create a URI for.
1496
1497 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1498 >> and passing the resulting C<$action> and the remaining arguments to C<<
1499 $c->uri_for >>.
1500
1501 You can also pass in a Catalyst::Action object, in which case it is passed to
1502 C<< $c->uri_for >>.
1503
1504 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1505
1506 For example, if the action looks like:
1507
1508  package MyApp::Controller::Users;
1509
1510  sub lst : Path('the-list') {}
1511
1512 You can use:
1513
1514  $c->uri_for_action('/users/lst')
1515
1516 and it will create the URI /users/the-list.
1517
1518 =item \@captures_and_args?
1519
1520 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1521 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1522 to interpolate all the parameters in the URI.
1523
1524 =item @args?
1525
1526 Optional list of extra arguments - can be supplied in the
1527 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1528 code.
1529
1530 Your action can have zero, a fixed or a variable number of args (e.g.
1531 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1532
1533 =item \%query_values?
1534
1535 Optional array reference of query parameters to append. E.g.
1536
1537   { foo => 'bar' }
1538
1539 will generate
1540
1541   /rest/of/your/uri?foo=bar
1542
1543 =back
1544
1545 =cut
1546
1547 sub uri_for_action {
1548     my ( $c, $path, @args ) = @_;
1549     my $action = blessed($path)
1550       ? $path
1551       : $c->dispatcher->get_action_by_path($path);
1552     unless (defined $action) {
1553       croak "Can't find action for path '$path'";
1554     }
1555     return $c->uri_for( $action, @args );
1556 }
1557
1558 =head2 $c->welcome_message
1559
1560 Returns the Catalyst welcome HTML page.
1561
1562 =cut
1563
1564 sub welcome_message {
1565     my $c      = shift;
1566     my $name   = $c->config->{name};
1567     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1568     my $prefix = Catalyst::Utils::appprefix( ref $c );
1569     $c->response->content_type('text/html; charset=utf-8');
1570     return <<"EOF";
1571 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1572     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1573 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1574     <head>
1575     <meta http-equiv="Content-Language" content="en" />
1576     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1577         <title>$name on Catalyst $VERSION</title>
1578         <style type="text/css">
1579             body {
1580                 color: #000;
1581                 background-color: #eee;
1582             }
1583             div#content {
1584                 width: 640px;
1585                 margin-left: auto;
1586                 margin-right: auto;
1587                 margin-top: 10px;
1588                 margin-bottom: 10px;
1589                 text-align: left;
1590                 background-color: #ccc;
1591                 border: 1px solid #aaa;
1592             }
1593             p, h1, h2 {
1594                 margin-left: 20px;
1595                 margin-right: 20px;
1596                 font-family: verdana, tahoma, sans-serif;
1597             }
1598             a {
1599                 font-family: verdana, tahoma, sans-serif;
1600             }
1601             :link, :visited {
1602                     text-decoration: none;
1603                     color: #b00;
1604                     border-bottom: 1px dotted #bbb;
1605             }
1606             :link:hover, :visited:hover {
1607                     color: #555;
1608             }
1609             div#topbar {
1610                 margin: 0px;
1611             }
1612             pre {
1613                 margin: 10px;
1614                 padding: 8px;
1615             }
1616             div#answers {
1617                 padding: 8px;
1618                 margin: 10px;
1619                 background-color: #fff;
1620                 border: 1px solid #aaa;
1621             }
1622             h1 {
1623                 font-size: 0.9em;
1624                 font-weight: normal;
1625                 text-align: center;
1626             }
1627             h2 {
1628                 font-size: 1.0em;
1629             }
1630             p {
1631                 font-size: 0.9em;
1632             }
1633             p img {
1634                 float: right;
1635                 margin-left: 10px;
1636             }
1637             span#appname {
1638                 font-weight: bold;
1639                 font-size: 1.6em;
1640             }
1641         </style>
1642     </head>
1643     <body>
1644         <div id="content">
1645             <div id="topbar">
1646                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1647                     $VERSION</h1>
1648              </div>
1649              <div id="answers">
1650                  <p>
1651                  <img src="$logo" alt="Catalyst Logo" />
1652                  </p>
1653                  <p>Welcome to the  world of Catalyst.
1654                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1655                     framework will make web development something you had
1656                     never expected it to be: Fun, rewarding, and quick.</p>
1657                  <h2>What to do now?</h2>
1658                  <p>That really depends  on what <b>you</b> want to do.
1659                     We do, however, provide you with a few starting points.</p>
1660                  <p>If you want to jump right into web development with Catalyst
1661                     you might want to start with a tutorial.</p>
1662 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1663 </pre>
1664 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1665 <pre>
1666 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1667 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1668 </code></pre>
1669                  <h2>What to do next?</h2>
1670                  <p>Next it's time to write an actual application. Use the
1671                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1672                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1673                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1674                     they can save you a lot of work.</p>
1675                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1676                     <p>Also, be sure to check out the vast and growing
1677                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1678                     you are likely to find what you need there.
1679                     </p>
1680
1681                  <h2>Need help?</h2>
1682                  <p>Catalyst has a very active community. Here are the main places to
1683                     get in touch with us.</p>
1684                  <ul>
1685                      <li>
1686                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1687                      </li>
1688                      <li>
1689                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1690                      </li>
1691                      <li>
1692                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1693                      </li>
1694                  </ul>
1695                  <h2>In conclusion</h2>
1696                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1697                     as we enjoyed making it. Please contact us if you have ideas
1698                     for improvement or other feedback.</p>
1699              </div>
1700          </div>
1701     </body>
1702 </html>
1703 EOF
1704 }
1705
1706 =head2 run_options
1707
1708 Contains a hash of options passed from the application script, including
1709 the original ARGV the script received, the processed values from that
1710 ARGV and any extra arguments to the script which were not processed.
1711
1712 This can be used to add custom options to your application's scripts
1713 and setup your application differently depending on the values of these
1714 options.
1715
1716 =head1 INTERNAL METHODS
1717
1718 These methods are not meant to be used by end users.
1719
1720 =head2 $c->components
1721
1722 Returns a hash of components.
1723
1724 =head2 $c->context_class
1725
1726 Returns or sets the context class.
1727
1728 =head2 $c->counter
1729
1730 Returns a hashref containing coderefs and execution counts (needed for
1731 deep recursion detection).
1732
1733 =head2 $c->depth
1734
1735 Returns the number of actions on the current internal execution stack.
1736
1737 =head2 $c->dispatch
1738
1739 Dispatches a request to actions.
1740
1741 =cut
1742
1743 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1744
1745 =head2 $c->dispatcher_class
1746
1747 Returns or sets the dispatcher class.
1748
1749 =head2 $c->dump_these
1750
1751 Returns a list of 2-element array references (name, structure) pairs
1752 that will be dumped on the error page in debug mode.
1753
1754 =cut
1755
1756 sub dump_these {
1757     my $c = shift;
1758     [ Request => $c->req ],
1759     [ Response => $c->res ],
1760     [ Stash => $c->stash ],
1761     [ Config => $c->config ];
1762 }
1763
1764 =head2 $c->engine_class
1765
1766 Returns or sets the engine class.
1767
1768 =head2 $c->execute( $class, $coderef )
1769
1770 Execute a coderef in given class and catch exceptions. Errors are available
1771 via $c->error.
1772
1773 =cut
1774
1775 sub execute {
1776     my ( $c, $class, $code ) = @_;
1777     $class = $c->component($class) || $class;
1778     $c->state(0);
1779
1780     if ( $c->depth >= $RECURSION ) {
1781         my $action = $code->reverse();
1782         $action = "/$action" unless $action =~ /->/;
1783         my $error = qq/Deep recursion detected calling "${action}"/;
1784         $c->log->error($error);
1785         $c->error($error);
1786         $c->state(0);
1787         return $c->state;
1788     }
1789
1790     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1791
1792     push( @{ $c->stack }, $code );
1793
1794     no warnings 'recursion';
1795     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1796     #      I have no idea how, ergo $ret (which appears to fix the issue)
1797     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1798
1799     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1800
1801     my $last = pop( @{ $c->stack } );
1802
1803     if ( my $error = $@ ) {
1804         #rethow if this can be handled by middleware
1805         if(blessed $error && ($error->can('as_psgi') || $error->can('code'))) {
1806             foreach my $err (@{$c->error}) {
1807                 $c->log->error($err);
1808             }
1809             $c->clear_errors;
1810             $c->log->_flush if $c->log->can('_flush');
1811
1812             $error->can('rethrow') ? $error->rethrow : croak $error;
1813         }
1814         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1815             $error->rethrow if $c->depth > 1;
1816         }
1817         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1818             $error->rethrow if $c->depth > 0;
1819         }
1820         else {
1821             unless ( ref $error ) {
1822                 no warnings 'uninitialized';
1823                 chomp $error;
1824                 my $class = $last->class;
1825                 my $name  = $last->name;
1826                 $error = qq/Caught exception in $class->$name "$error"/;
1827             }
1828             $c->error($error);
1829         }
1830         $c->state(0);
1831     }
1832     return $c->state;
1833 }
1834
1835 sub _stats_start_execute {
1836     my ( $c, $code ) = @_;
1837     my $appclass = ref($c) || $c;
1838     return if ( ( $code->name =~ /^_.*/ )
1839         && ( !$appclass->config->{show_internal_actions} ) );
1840
1841     my $action_name = $code->reverse();
1842     $c->counter->{$action_name}++;
1843
1844     my $action = $action_name;
1845     $action = "/$action" unless $action =~ /->/;
1846
1847     # determine if the call was the result of a forward
1848     # this is done by walking up the call stack and looking for a calling
1849     # sub of Catalyst::forward before the eval
1850     my $callsub = q{};
1851     for my $index ( 2 .. 11 ) {
1852         last
1853         if ( ( caller($index) )[0] eq 'Catalyst'
1854             && ( caller($index) )[3] eq '(eval)' );
1855
1856         if ( ( caller($index) )[3] =~ /forward$/ ) {
1857             $callsub = ( caller($index) )[3];
1858             $action  = "-> $action";
1859             last;
1860         }
1861     }
1862
1863     my $uid = $action_name . $c->counter->{$action_name};
1864
1865     # is this a root-level call or a forwarded call?
1866     if ( $callsub =~ /forward$/ ) {
1867         my $parent = $c->stack->[-1];
1868
1869         # forward, locate the caller
1870         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1871             $c->stats->profile(
1872                 begin  => $action,
1873                 parent => "$parent" . $c->counter->{"$parent"},
1874                 uid    => $uid,
1875             );
1876         }
1877         else {
1878
1879             # forward with no caller may come from a plugin
1880             $c->stats->profile(
1881                 begin => $action,
1882                 uid   => $uid,
1883             );
1884         }
1885     }
1886     else {
1887
1888         # root-level call
1889         $c->stats->profile(
1890             begin => $action,
1891             uid   => $uid,
1892         );
1893     }
1894     return $action;
1895
1896 }
1897
1898 sub _stats_finish_execute {
1899     my ( $c, $info ) = @_;
1900     $c->stats->profile( end => $info );
1901 }
1902
1903 =head2 $c->finalize
1904
1905 Finalizes the request.
1906
1907 =cut
1908
1909 sub finalize {
1910     my $c = shift;
1911
1912     for my $error ( @{ $c->error } ) {
1913         $c->log->error($error);
1914     }
1915
1916     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1917     # stuff like cometd and websockets
1918
1919     if($c->request->_has_io_fh) {
1920       $c->log_response;
1921       return;
1922     }
1923
1924     # Allow engine to handle finalize flow (for POE)
1925     my $engine = $c->engine;
1926     if ( my $code = $engine->can('finalize') ) {
1927         $engine->$code($c);
1928     }
1929     else {
1930
1931         $c->finalize_uploads;
1932
1933         # Error
1934         if ( $#{ $c->error } >= 0 ) {
1935             $c->finalize_error;
1936         }
1937
1938         $c->finalize_encoding;
1939         $c->finalize_headers unless $c->response->finalized_headers;
1940         $c->finalize_body;
1941     }
1942
1943     $c->log_response;
1944
1945     if ($c->use_stats) {
1946         my $elapsed = $c->stats->elapsed;
1947         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1948         $c->log->info(
1949             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1950     }
1951
1952     return $c->response->status;
1953 }
1954
1955 =head2 $c->finalize_body
1956
1957 Finalizes body.
1958
1959 =cut
1960
1961 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1962
1963 =head2 $c->finalize_cookies
1964
1965 Finalizes cookies.
1966
1967 =cut
1968
1969 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1970
1971 =head2 $c->finalize_error
1972
1973 Finalizes error.  If there is only one error in L</error> and it is an object that
1974 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
1975 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
1976 return the default error page (production mode).
1977
1978 =cut
1979
1980 sub finalize_error {
1981     my $c = shift;
1982     if($#{$c->error} > 0) {
1983         $c->engine->finalize_error( $c, @_ );
1984     } else {
1985         my ($error) = @{$c->error};
1986         if(
1987           blessed $error &&
1988           ($error->can('as_psgi') || $error->can('code'))
1989         ) {
1990             # In the case where the error 'knows what it wants', becauses its PSGI
1991             # aware, just rethow and let middleware catch it
1992             $error->can('rethrow') ? $error->rethrow : croak $error;
1993         } else {
1994             $c->engine->finalize_error( $c, @_ )
1995         }
1996     }
1997 }
1998
1999 =head2 $c->finalize_headers
2000
2001 Finalizes headers.
2002
2003 =cut
2004
2005 sub finalize_headers {
2006     my $c = shift;
2007
2008     my $response = $c->response; #accessor calls can add up?
2009
2010     # Check if we already finalized headers
2011     return if $response->finalized_headers;
2012
2013     # Handle redirects
2014     if ( my $location = $response->redirect ) {
2015         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2016         $response->header( Location => $location );
2017     }
2018
2019     # Remove incorrectly added body and content related meta data when returning
2020     # an information response, or a response the is required to not include a body
2021
2022     $c->finalize_cookies;
2023
2024     $c->response->finalize_headers();
2025
2026     # Done
2027     $response->finalized_headers(1);
2028 }
2029
2030 =head2 $c->finalize_encoding
2031
2032 Make sure your headers and body are encoded properly IF you set an encoding.
2033 See L</ENCODING>.
2034
2035 =cut
2036
2037 sub finalize_encoding {
2038     my $c = shift;
2039
2040     my $body = $c->response->body;
2041
2042     return unless defined($body);
2043
2044     my $enc = $c->encoding;
2045
2046     return unless $enc;
2047
2048     my ($ct, $ct_enc) = $c->response->content_type;
2049
2050     # Only touch 'text-like' contents
2051     return unless $c->response->content_type =~ /^text|xml$|javascript$/;
2052
2053     if ($ct_enc && $ct_enc =~ /charset=([^;]*)/) {
2054         if (uc($1) ne uc($enc->mime_name)) {
2055             $c->log->debug("Unicode::Encoding is set to encode in '" .
2056                            $enc->mime_name .
2057                            "', content type is '$1', not encoding ");
2058             return;
2059         }
2060     } else {
2061         $c->res->content_type($c->res->content_type . "; charset=" . $enc->mime_name);
2062     }
2063
2064     # Oh my, I wonder what filehandle responses and streams do... - jnap.
2065     # Encode expects plain scalars (IV, NV or PV) and segfaults on ref's
2066     $c->response->body( $c->encoding->encode( $body, $c->_encode_check ) )
2067         if ref(\$body) eq 'SCALAR';
2068 }
2069
2070 =head2 $c->finalize_output
2071
2072 An alias for finalize_body.
2073
2074 =head2 $c->finalize_read
2075
2076 Finalizes the input after reading is complete.
2077
2078 =cut
2079
2080 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2081
2082 =head2 $c->finalize_uploads
2083
2084 Finalizes uploads. Cleans up any temporary files.
2085
2086 =cut
2087
2088 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2089
2090 =head2 $c->get_action( $action, $namespace )
2091
2092 Gets an action in a given namespace.
2093
2094 =cut
2095
2096 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2097
2098 =head2 $c->get_actions( $action, $namespace )
2099
2100 Gets all actions of a given name in a namespace and all parent
2101 namespaces.
2102
2103 =cut
2104
2105 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2106
2107 =head2 $app->handle_request( @arguments )
2108
2109 Called to handle each HTTP request.
2110
2111 =cut
2112
2113 sub handle_request {
2114     my ( $class, @arguments ) = @_;
2115
2116     # Always expect worst case!
2117     my $status = -1;
2118     try {
2119         if ($class->debug) {
2120             my $secs = time - $START || 1;
2121             my $av = sprintf '%.3f', $COUNT / $secs;
2122             my $time = localtime time;
2123             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2124         }
2125
2126         my $c = $class->prepare(@arguments);
2127         $c->dispatch;
2128         $status = $c->finalize;
2129     } catch {
2130         #rethow if this can be handled by middleware
2131         if(blessed $_ && ($_->can('as_psgi') || $_->can('code'))) {
2132             $_->can('rethrow') ? $_->rethrow : croak $_;
2133         }
2134         chomp(my $error = $_);
2135         $class->log->error(qq/Caught exception in engine "$error"/);
2136     };
2137
2138     $COUNT++;
2139
2140     if(my $coderef = $class->log->can('_flush')){
2141         $class->log->$coderef();
2142     }
2143     return $status;
2144 }
2145
2146 =head2 $class->prepare( @arguments )
2147
2148 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2149 etc.).
2150
2151 =cut
2152
2153 has _uploadtmp => (
2154     is => 'ro',
2155     predicate => '_has_uploadtmp',
2156 );
2157
2158 sub prepare {
2159     my ( $class, @arguments ) = @_;
2160
2161     # XXX
2162     # After the app/ctxt split, this should become an attribute based on something passed
2163     # into the application.
2164     $class->context_class( ref $class || $class ) unless $class->context_class;
2165
2166     my $uploadtmp = $class->config->{uploadtmp};
2167     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2168
2169     $c->response->_context($c);
2170
2171     #surely this is not the most efficient way to do things...
2172     $c->stats($class->stats_class->new)->enable($c->use_stats);
2173     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2174         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2175     }
2176
2177     try {
2178         # Allow engine to direct the prepare flow (for POE)
2179         if ( my $prepare = $c->engine->can('prepare') ) {
2180             $c->engine->$prepare( $c, @arguments );
2181         }
2182         else {
2183             $c->prepare_request(@arguments);
2184             $c->prepare_connection;
2185             $c->prepare_query_parameters;
2186             $c->prepare_headers; # Just hooks, no longer needed - they just
2187             $c->prepare_cookies; # cause the lazy attribute on req to build
2188             $c->prepare_path;
2189
2190             # Prepare the body for reading, either by prepare_body
2191             # or the user, if they are using $c->read
2192             $c->prepare_read;
2193
2194             # Parse the body unless the user wants it on-demand
2195             unless ( ref($c)->config->{parse_on_demand} ) {
2196                 $c->prepare_body;
2197             }
2198         }
2199         $c->prepare_action;
2200     }
2201     # VERY ugly and probably shouldn't rely on ->finalize actually working
2202     catch {
2203         # failed prepare is always due to an invalid request, right?
2204         $c->response->status(400);
2205         $c->response->content_type('text/plain');
2206         $c->response->body('Bad Request');
2207         # Note we call finalize and then die here, which escapes
2208         # finalize being called in the enclosing block..
2209         # It in fact couldn't be called, as we don't return $c..
2210         # This is a mess - but I'm unsure you can fix this without
2211         # breaking compat for people doing crazy things (we should set
2212         # the 400 and just return the ctx here IMO, letting finalize get called
2213         # above...
2214         $c->finalize;
2215         die $_;
2216     };
2217
2218     $c->log_request;
2219
2220     return $c;
2221 }
2222
2223 =head2 $c->prepare_action
2224
2225 Prepares action. See L<Catalyst::Dispatcher>.
2226
2227 =cut
2228
2229 sub prepare_action {
2230     my $c = shift;
2231     my $ret = $c->dispatcher->prepare_action( $c, @_);
2232
2233     if($c->encoding) {
2234         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2235           $_ = $c->_handle_param_unicode_decoding($_);
2236         }
2237     }
2238
2239     return $ret;
2240 }
2241
2242
2243 =head2 $c->prepare_body
2244
2245 Prepares message body.
2246
2247 =cut
2248
2249 sub prepare_body {
2250     my $c = shift;
2251
2252     return if $c->request->_has_body;
2253
2254     # Initialize on-demand data
2255     $c->engine->prepare_body( $c, @_ );
2256     $c->prepare_parameters;
2257     $c->prepare_uploads;
2258 }
2259
2260 =head2 $c->prepare_body_chunk( $chunk )
2261
2262 Prepares a chunk of data before sending it to L<HTTP::Body>.
2263
2264 See L<Catalyst::Engine>.
2265
2266 =cut
2267
2268 sub prepare_body_chunk {
2269     my $c = shift;
2270     $c->engine->prepare_body_chunk( $c, @_ );
2271 }
2272
2273 =head2 $c->prepare_body_parameters
2274
2275 Prepares body parameters.
2276
2277 =cut
2278
2279 sub prepare_body_parameters {
2280     my $c = shift;
2281     $c->engine->prepare_body_parameters( $c, @_ );
2282 }
2283
2284 =head2 $c->prepare_connection
2285
2286 Prepares connection.
2287
2288 =cut
2289
2290 sub prepare_connection {
2291     my $c = shift;
2292     $c->request->prepare_connection($c);
2293 }
2294
2295 =head2 $c->prepare_cookies
2296
2297 Prepares cookies by ensuring that the attribute on the request
2298 object has been built.
2299
2300 =cut
2301
2302 sub prepare_cookies { my $c = shift; $c->request->cookies }
2303
2304 =head2 $c->prepare_headers
2305
2306 Prepares request headers by ensuring that the attribute on the request
2307 object has been built.
2308
2309 =cut
2310
2311 sub prepare_headers { my $c = shift; $c->request->headers }
2312
2313 =head2 $c->prepare_parameters
2314
2315 Prepares parameters.
2316
2317 =cut
2318
2319 sub prepare_parameters {
2320     my $c = shift;
2321     $c->prepare_body_parameters;
2322     $c->engine->prepare_parameters( $c, @_ );
2323 }
2324
2325 =head2 $c->prepare_path
2326
2327 Prepares path and base.
2328
2329 =cut
2330
2331 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2332
2333 =head2 $c->prepare_query_parameters
2334
2335 Prepares query parameters.
2336
2337 =cut
2338
2339 sub prepare_query_parameters {
2340     my $c = shift;
2341
2342     $c->engine->prepare_query_parameters( $c, @_ );
2343 }
2344
2345 =head2 $c->log_request
2346
2347 Writes information about the request to the debug logs.  This includes:
2348
2349 =over 4
2350
2351 =item * Request method, path, and remote IP address
2352
2353 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2354
2355 =item * Request parameters
2356
2357 =item * File uploads
2358
2359 =back
2360
2361 =cut
2362
2363 sub log_request {
2364     my $c = shift;
2365
2366     return unless $c->debug;
2367
2368     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2369     my $request = $dump->[1];
2370
2371     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2372     $method ||= '';
2373     $path = '/' unless length $path;
2374     $address ||= '';
2375     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2376
2377     $c->log_request_headers($request->headers);
2378
2379     if ( my $keywords = $request->query_keywords ) {
2380         $c->log->debug("Query keywords are: $keywords");
2381     }
2382
2383     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2384
2385     $c->log_request_uploads($request);
2386 }
2387
2388 =head2 $c->log_response
2389
2390 Writes information about the response to the debug logs by calling
2391 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2392
2393 =cut
2394
2395 sub log_response {
2396     my $c = shift;
2397
2398     return unless $c->debug;
2399
2400     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2401     my $response = $dump->[1];
2402
2403     $c->log_response_status_line($response);
2404     $c->log_response_headers($response->headers);
2405 }
2406
2407 =head2 $c->log_response_status_line($response)
2408
2409 Writes one line of information about the response to the debug logs.  This includes:
2410
2411 =over 4
2412
2413 =item * Response status code
2414
2415 =item * Content-Type header (if present)
2416
2417 =item * Content-Length header (if present)
2418
2419 =back
2420
2421 =cut
2422
2423 sub log_response_status_line {
2424     my ($c, $response) = @_;
2425
2426     $c->log->debug(
2427         sprintf(
2428             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2429             $response->status                            || 'unknown',
2430             $response->headers->header('Content-Type')   || 'unknown',
2431             $response->headers->header('Content-Length') || 'unknown'
2432         )
2433     );
2434 }
2435
2436 =head2 $c->log_response_headers($headers);
2437
2438 Hook method which can be wrapped by plugins to log the response headers.
2439 No-op in the default implementation.
2440
2441 =cut
2442
2443 sub log_response_headers {}
2444
2445 =head2 $c->log_request_parameters( query => {}, body => {} )
2446
2447 Logs request parameters to debug logs
2448
2449 =cut
2450
2451 sub log_request_parameters {
2452     my $c          = shift;
2453     my %all_params = @_;
2454
2455     return unless $c->debug;
2456
2457     my $column_width = Catalyst::Utils::term_width() - 44;
2458     foreach my $type (qw(query body)) {
2459         my $params = $all_params{$type};
2460         next if ! keys %$params;
2461         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2462         for my $key ( sort keys %$params ) {
2463             my $param = $params->{$key};
2464             my $value = defined($param) ? $param : '';
2465             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2466         }
2467         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2468     }
2469 }
2470
2471 =head2 $c->log_request_uploads
2472
2473 Logs file uploads included in the request to the debug logs.
2474 The parameter name, filename, file type, and file size are all included in
2475 the debug logs.
2476
2477 =cut
2478
2479 sub log_request_uploads {
2480     my $c = shift;
2481     my $request = shift;
2482     return unless $c->debug;
2483     my $uploads = $request->uploads;
2484     if ( keys %$uploads ) {
2485         my $t = Text::SimpleTable->new(
2486             [ 12, 'Parameter' ],
2487             [ 26, 'Filename' ],
2488             [ 18, 'Type' ],
2489             [ 9,  'Size' ]
2490         );
2491         for my $key ( sort keys %$uploads ) {
2492             my $upload = $uploads->{$key};
2493             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2494                 $t->row( $key, $u->filename, $u->type, $u->size );
2495             }
2496         }
2497         $c->log->debug( "File Uploads are:\n" . $t->draw );
2498     }
2499 }
2500
2501 =head2 $c->log_request_headers($headers);
2502
2503 Hook method which can be wrapped by plugins to log the request headers.
2504 No-op in the default implementation.
2505
2506 =cut
2507
2508 sub log_request_headers {}
2509
2510 =head2 $c->log_headers($type => $headers)
2511
2512 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2513
2514 =cut
2515
2516 sub log_headers {
2517     my $c       = shift;
2518     my $type    = shift;
2519     my $headers = shift;    # an HTTP::Headers instance
2520
2521     return unless $c->debug;
2522
2523     my $column_width = Catalyst::Utils::term_width() - 28;
2524     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2525     $headers->scan(
2526         sub {
2527             my ( $name, $value ) = @_;
2528             $t->row( $name, $value );
2529         }
2530     );
2531     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2532 }
2533
2534
2535 =head2 $c->prepare_read
2536
2537 Prepares the input for reading.
2538
2539 =cut
2540
2541 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2542
2543 =head2 $c->prepare_request
2544
2545 Prepares the engine request.
2546
2547 =cut
2548
2549 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2550
2551 =head2 $c->prepare_uploads
2552
2553 Prepares uploads.
2554
2555 =cut
2556
2557 sub prepare_uploads {
2558     my $c = shift;
2559     $c->engine->prepare_uploads( $c, @_ );
2560
2561     my $enc = $c->encoding;
2562     return unless $enc;
2563
2564     # Uggg we hook prepare uploads to do the encoding crap on post and query
2565     # parameters!  Sorry -jnap
2566     for my $key (qw/ parameters query_parameters body_parameters /) {
2567         for my $value ( values %{ $c->request->{$key} } ) {
2568             # N.B. Check if already a character string and if so do not try to double decode.
2569             #      http://www.mail-archive.com/catalyst@lists.scsys.co.uk/msg02350.html
2570             #      this avoids exception if we have already decoded content, and is _not_ the
2571             #      same as not encoding on output which is bad news (as it does the wrong thing
2572             #      for latin1 chars for example)..
2573             $value = $c->_handle_unicode_decoding($value);
2574         }
2575     }
2576     for my $value ( values %{ $c->request->uploads } ) {
2577         # skip if it fails for uploads, as we don't usually want uploads touched
2578         # in any way
2579         for my $inner_value ( ref($value) eq 'ARRAY' ? @{$value} : $value ) {
2580             $inner_value->{filename} = try {
2581                 $enc->decode( $inner_value->{filename}, $c->_encode_check )
2582             } catch {
2583                 $c->handle_unicode_encoding_exception({
2584                     param_value => $inner_value->{filename},
2585                     error_msg => $_,
2586                     encoding_step => 'uploads',
2587                 });
2588             };
2589         }
2590     }
2591 }
2592
2593 =head2 $c->prepare_write
2594
2595 Prepares the output for writing.
2596
2597 =cut
2598
2599 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2600
2601 =head2 $c->request_class
2602
2603 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2604
2605 =head2 $c->response_class
2606
2607 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2608
2609 =head2 $c->read( [$maxlength] )
2610
2611 Reads a chunk of data from the request body. This method is designed to
2612 be used in a while loop, reading C<$maxlength> bytes on every call.
2613 C<$maxlength> defaults to the size of the request if not specified.
2614
2615 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2616 directly.
2617
2618 Warning: If you use read(), Catalyst will not process the body,
2619 so you will not be able to access POST parameters or file uploads via
2620 $c->request.  You must handle all body parsing yourself.
2621
2622 =cut
2623
2624 sub read { my $c = shift; return $c->request->read( @_ ) }
2625
2626 =head2 $c->run
2627
2628 Starts the engine.
2629
2630 =cut
2631
2632 sub run {
2633   my $app = shift;
2634   $app->_make_immutable_if_needed;
2635   $app->engine_loader->needs_psgi_engine_compat_hack ?
2636     $app->engine->run($app, @_) :
2637       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2638 }
2639
2640 sub _make_immutable_if_needed {
2641     my $class = shift;
2642     my $meta = find_meta($class);
2643     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2644     if (
2645         $meta->is_immutable
2646         && ! { $meta->immutable_options }->{replace_constructor}
2647         && $isa_ca
2648     ) {
2649         warn("You made your application class ($class) immutable, "
2650             . "but did not inline the\nconstructor. "
2651             . "This will break catalyst, as your app \@ISA "
2652             . "Class::Accessor(::Fast)?\nPlease pass "
2653             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2654     }
2655     unless ($meta->is_immutable) {
2656         # XXX - FIXME warning here as you should make your app immutable yourself.
2657         $meta->make_immutable(
2658             replace_constructor => 1,
2659         );
2660     }
2661 }
2662
2663 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2664
2665 Sets an action in a given namespace.
2666
2667 =cut
2668
2669 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2670
2671 =head2 $c->setup_actions($component)
2672
2673 Sets up actions for a component.
2674
2675 =cut
2676
2677 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2678
2679 =head2 $c->setup_components
2680
2681 This method is called internally to set up the application's components.
2682
2683 It finds modules by calling the L<locate_components> method, expands them to
2684 package names with the L<expand_component_module> method, and then installs
2685 each component into the application.
2686
2687 The C<setup_components> config option is passed to both of the above methods.
2688
2689 Installation of each component is performed by the L<setup_component> method,
2690 below.
2691
2692 =cut
2693
2694 sub setup_components {
2695     my $class = shift;
2696
2697     my $config  = $class->config->{ setup_components };
2698
2699     my @comps = $class->locate_components($config);
2700     my %comps = map { $_ => 1 } @comps;
2701
2702     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2703     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2704         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2705     ) if $deprecatedcatalyst_component_names;
2706
2707     for my $component ( @comps ) {
2708
2709         # We pass ignore_loaded here so that overlay files for (e.g.)
2710         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2711         # we know M::P::O found a file on disk so this is safe
2712
2713         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2714     }
2715
2716     for my $component (@comps) {
2717         my $instance = $class->components->{ $component } = $class->setup_component($component);
2718         my @expanded_components = $instance->can('expand_modules')
2719             ? $instance->expand_modules( $component, $config )
2720             : $class->expand_component_module( $component, $config );
2721         for my $component (@expanded_components) {
2722             next if $comps{$component};
2723             $class->components->{ $component } = $class->setup_component($component);
2724         }
2725     }
2726 }
2727
2728 =head2 $c->locate_components( $setup_component_config )
2729
2730 This method is meant to provide a list of component modules that should be
2731 setup for the application.  By default, it will use L<Module::Pluggable>.
2732
2733 Specify a C<setup_components> config option to pass additional options directly
2734 to L<Module::Pluggable>. To add additional search paths, specify a key named
2735 C<search_extra> as an array reference. Items in the array beginning with C<::>
2736 will have the application class name prepended to them.
2737
2738 =cut
2739
2740 sub locate_components {
2741     my $class  = shift;
2742     my $config = shift;
2743
2744     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
2745     my $extra   = delete $config->{ search_extra } || [];
2746
2747     unshift @paths, @$extra;
2748
2749     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
2750       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
2751       %$config
2752     )->plugins } @paths;
2753
2754     return @comps;
2755 }
2756
2757 =head2 $c->expand_component_module( $component, $setup_component_config )
2758
2759 Components found by C<locate_components> will be passed to this method, which
2760 is expected to return a list of component (package) names to be set up.
2761
2762 =cut
2763
2764 sub expand_component_module {
2765     my ($class, $module) = @_;
2766     return Devel::InnerPackage::list_packages( $module );
2767 }
2768
2769 =head2 $c->setup_component
2770
2771 =cut
2772
2773 sub setup_component {
2774     my( $class, $component ) = @_;
2775
2776     unless ( $component->can( 'COMPONENT' ) ) {
2777         return $component;
2778     }
2779
2780     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2781     my $config = $class->config->{ $suffix } || {};
2782     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2783     # methods also pass it. local to avoid pointlessly shitting in config
2784     # for the debug screen, as $component is already the key name.
2785     local $config->{catalyst_component_name} = $component;
2786
2787     my $instance = eval { $component->COMPONENT( $class, $config ); };
2788
2789     if ( my $error = $@ ) {
2790         chomp $error;
2791         Catalyst::Exception->throw(
2792             message => qq/Couldn't instantiate component "$component", "$error"/
2793         );
2794     }
2795
2796     unless (blessed $instance) {
2797         my $metaclass = Moose::Util::find_meta($component);
2798         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2799         my $component_method_from = $method_meta->associated_metaclass->name;
2800         my $value = defined($instance) ? $instance : 'undef';
2801         Catalyst::Exception->throw(
2802             message =>
2803             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2804         );
2805     }
2806     return $instance;
2807 }
2808
2809 =head2 $c->setup_dispatcher
2810
2811 Sets up dispatcher.
2812
2813 =cut
2814
2815 sub setup_dispatcher {
2816     my ( $class, $dispatcher ) = @_;
2817
2818     if ($dispatcher) {
2819         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2820     }
2821
2822     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2823         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2824     }
2825
2826     unless ($dispatcher) {
2827         $dispatcher = $class->dispatcher_class;
2828     }
2829
2830     load_class($dispatcher);
2831
2832     # dispatcher instance
2833     $class->dispatcher( $dispatcher->new );
2834 }
2835
2836 =head2 $c->setup_engine
2837
2838 Sets up engine.
2839
2840 =cut
2841
2842 sub engine_class {
2843     my ($class, $requested_engine) = @_;
2844
2845     if (!$class->engine_loader || $requested_engine) {
2846         $class->engine_loader(
2847             Catalyst::EngineLoader->new({
2848                 application_name => $class,
2849                 (defined $requested_engine
2850                      ? (catalyst_engine_class => $requested_engine) : ()),
2851             }),
2852         );
2853     }
2854
2855     $class->engine_loader->catalyst_engine_class;
2856 }
2857
2858 sub setup_engine {
2859     my ($class, $requested_engine) = @_;
2860
2861     my $engine = do {
2862         my $loader = $class->engine_loader;
2863
2864         if (!$loader || $requested_engine) {
2865             $loader = Catalyst::EngineLoader->new({
2866                 application_name => $class,
2867                 (defined $requested_engine
2868                      ? (requested_engine => $requested_engine) : ()),
2869             }),
2870
2871             $class->engine_loader($loader);
2872         }
2873
2874         $loader->catalyst_engine_class;
2875     };
2876
2877     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2878     return if $class->loading_psgi_file;
2879
2880     load_class($engine);
2881
2882     if ($ENV{MOD_PERL}) {
2883         my $apache = $class->engine_loader->auto;
2884
2885         my $meta = find_meta($class);
2886         my $was_immutable = $meta->is_immutable;
2887         my %immutable_options = $meta->immutable_options;
2888         $meta->make_mutable if $was_immutable;
2889
2890         $meta->add_method(handler => sub {
2891             my $r = shift;
2892             my $psgi_app = $class->_finalized_psgi_app;
2893             $apache->call_app($r, $psgi_app);
2894         });
2895
2896         $meta->make_immutable(%immutable_options) if $was_immutable;
2897     }
2898
2899     $class->engine( $engine->new );
2900
2901     return;
2902 }
2903
2904 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2905 ## build in server support (back compat support for pre psgi port behavior).
2906 ## This is so that we don't build a new psgi app for each request when using
2907 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2908
2909 sub _finalized_psgi_app {
2910     my ($app) = @_;
2911
2912     unless ($app->_psgi_app) {
2913         my $psgi_app = $app->_setup_psgi_app;
2914         $app->_psgi_app($psgi_app);
2915     }
2916
2917     return $app->_psgi_app;
2918 }
2919
2920 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2921 ## home directory and load that and return it (just assume it is doing the
2922 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2923 ## in default_middleware and return it ( this is for backward compatibility
2924 ## with pre psgi port behavior ).
2925
2926 sub _setup_psgi_app {
2927     my ($app) = @_;
2928
2929     for my $home (Path::Class::Dir->new($app->config->{home})) {
2930         my $psgi_file = $home->file(
2931             Catalyst::Utils::appprefix($app) . '.psgi',
2932         );
2933
2934         next unless -e $psgi_file;
2935
2936         # If $psgi_file calls ->setup_engine, it's doing so to load
2937         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2938         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2939         # anyway. So set a flag (ick) that tells setup_engine not to populate
2940         # $c->engine or do any other things we might regret.
2941
2942         $app->loading_psgi_file(1);
2943         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2944         $app->loading_psgi_file(0);
2945
2946         return $psgi_app
2947             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2948
2949         warn <<"EOW";
2950 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2951
2952 Its content has been ignored. Please consult the Catalyst::Upgrading
2953 documentation on how to upgrade from Catalyst::Engine::PSGI.
2954 EOW
2955     }
2956
2957     return $app->apply_default_middlewares($app->psgi_app);
2958 }
2959
2960 =head2 $c->apply_default_middlewares
2961
2962 Adds the following L<Plack> middlewares to your application, since they are
2963 useful and commonly needed:
2964
2965 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2966 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2967 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2968 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2969 applied since this middleware is smart enough to conditionally apply itself).
2970
2971 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2972 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2973 $ENV{SCRIPT_NAME}
2974
2975 =cut
2976
2977
2978 sub apply_default_middlewares {
2979     my ($app, $psgi_app) = @_;
2980
2981     $psgi_app = Plack::Middleware::Conditional->wrap(
2982         $psgi_app,
2983         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2984         condition => sub {
2985             my ($env) = @_;
2986             return if $app->config->{ignore_frontend_proxy};
2987             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2988                 || $app->config->{using_frontend_proxy};
2989         },
2990     );
2991
2992     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2993     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2994     $psgi_app = Plack::Middleware::Conditional->wrap(
2995         $psgi_app,
2996         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2997         condition => sub {
2998             my ($env) = @_;
2999             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3000             return unless $1 < 4.23;
3001             1;
3002         },
3003     );
3004
3005     # we're applying this unconditionally as the middleware itself already makes
3006     # sure it doesn't fuck things up if it's not running under one of the right
3007     # IIS versions
3008     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3009
3010     # And another IIS issue, this time with IIS7.
3011     $psgi_app = Plack::Middleware::Conditional->wrap(
3012         $psgi_app,
3013         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3014         condition => sub {
3015             my ($env) = @_;
3016             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3017         },
3018     );
3019
3020     return $psgi_app;
3021 }
3022
3023 =head2 App->psgi_app
3024
3025 =head2 App->to_app
3026
3027 Returns a PSGI application code reference for the catalyst application
3028 C<$c>. This is the bare application without any middlewares
3029 applied. C<${myapp}.psgi> is not taken into account.
3030
3031 This is what you want to be using to retrieve the PSGI application code
3032 reference of your Catalyst application for use in F<.psgi> files.
3033
3034 =cut
3035
3036 *to_app = \&psgi_app;
3037
3038 sub psgi_app {
3039     my ($app) = @_;
3040     my $psgi = $app->engine->build_psgi_app($app);
3041     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3042 }
3043
3044 =head2 $c->setup_home
3045
3046 Sets up the home directory.
3047
3048 =cut
3049
3050 sub setup_home {
3051     my ( $class, $home ) = @_;
3052
3053     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3054         $home = $env;
3055     }
3056
3057     $home ||= Catalyst::Utils::home($class);
3058
3059     if ($home) {
3060         #I remember recently being scolded for assigning config values like this
3061         $class->config->{home} ||= $home;
3062         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3063     }
3064 }
3065
3066 =head2 $c->setup_encoding
3067
3068 Sets up the input/output encoding.  See L<ENCODING>
3069
3070 =cut
3071
3072 sub setup_encoding {
3073     my $c = shift;
3074     my $enc = delete $c->config->{encoding};
3075     $c->encoding( $enc ) if defined $enc;
3076 }
3077
3078 =head2 handle_unicode_encoding_exception
3079
3080 Hook to let you customize how encoding errors are handled.  By default
3081 we just throw an exception.  Receives a hashref of debug information.
3082 Example:
3083
3084     $c->handle_unicode_encoding_exception({
3085         param_value => $value,
3086         error_msg => $_,
3087             encoding_step => 'params',
3088         });
3089
3090 =cut
3091
3092 sub handle_unicode_encoding_exception {
3093     my ( $self, $exception_ctx ) = @_;
3094     die $exception_ctx->{error_msg};
3095 }
3096
3097 # Some unicode helpers cargo culted from the old plugin.  These could likely
3098 # be neater.
3099
3100 sub _handle_unicode_decoding {
3101     my ( $self, $value ) = @_;
3102
3103     return unless defined $value;
3104
3105     ## I think this mess is to support the old nested
3106     if ( ref $value eq 'ARRAY' ) {
3107         foreach ( @$value ) {
3108             $_ = $self->_handle_unicode_decoding($_);
3109         }
3110         return $value;
3111     }
3112     elsif ( ref $value eq 'HASH' ) {
3113         foreach ( values %$value ) {
3114             $_ = $self->_handle_unicode_decoding($_);
3115         }
3116         return $value;
3117     }
3118     else {
3119         return $self->_handle_param_unicode_decoding($value);
3120     }
3121 }
3122
3123 sub _handle_param_unicode_decoding {
3124     my ( $self, $value ) = @_;
3125     return unless defined $value; # not in love with just ignoring undefs - jnap
3126
3127     my $enc = $self->encoding;
3128     return try {
3129       $enc->decode( $value, $self->_encode_check );
3130     }
3131     catch {
3132         $self->handle_unicode_encoding_exception({
3133             param_value => $value,
3134             error_msg => $_,
3135             encoding_step => 'params',
3136         });
3137     };
3138 }
3139
3140 =head2 $c->setup_log
3141
3142 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3143 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3144 log to.
3145
3146 This method also installs a C<debug> method that returns a true value into the
3147 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3148 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3149
3150 Note that if the log has already been setup, by either a previous call to
3151 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3152 that this method won't actually set up the log object.
3153
3154 =cut
3155
3156 sub setup_log {
3157     my ( $class, $levels ) = @_;
3158
3159     $levels ||= '';
3160     $levels =~ s/^\s+//;
3161     $levels =~ s/\s+$//;
3162     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3163
3164     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3165     if ( defined $env_debug ) {
3166         $levels{debug} = 1 if $env_debug; # Ugly!
3167         delete($levels{debug}) unless $env_debug;
3168     }
3169
3170     unless ( $class->log ) {
3171         $class->log( Catalyst::Log->new(keys %levels) );
3172     }
3173
3174     if ( $levels{debug} ) {
3175         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3176         $class->log->debug('Debug messages enabled');
3177     }
3178 }
3179
3180 =head2 $c->setup_plugins
3181
3182 Sets up plugins.
3183
3184 =cut
3185
3186 =head2 $c->setup_stats
3187
3188 Sets up timing statistics class.
3189
3190 =cut
3191
3192 sub setup_stats {
3193     my ( $class, $stats ) = @_;
3194
3195     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3196
3197     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3198     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3199         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3200         $class->log->debug('Statistics enabled');
3201     }
3202 }
3203
3204
3205 =head2 $c->registered_plugins
3206
3207 Returns a sorted list of the plugins which have either been stated in the
3208 import list.
3209
3210 If passed a given plugin name, it will report a boolean value indicating
3211 whether or not that plugin is loaded.  A fully qualified name is required if
3212 the plugin name does not begin with C<Catalyst::Plugin::>.
3213
3214  if ($c->registered_plugins('Some::Plugin')) {
3215      ...
3216  }
3217
3218 =cut
3219
3220 {
3221
3222     sub registered_plugins {
3223         my $proto = shift;
3224         return sort keys %{ $proto->_plugins } unless @_;
3225         my $plugin = shift;
3226         return 1 if exists $proto->_plugins->{$plugin};
3227         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3228     }
3229
3230     sub _register_plugin {
3231         my ( $proto, $plugin, $instant ) = @_;
3232         my $class = ref $proto || $proto;
3233
3234         load_class( $plugin );
3235         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3236             if $plugin->isa( 'Catalyst::Component' );
3237         my $plugin_meta = Moose::Meta::Class->create($plugin);
3238         if (!$plugin_meta->has_method('new')
3239             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3240             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3241         }
3242         if (!$instant && !$proto->_plugins->{$plugin}) {
3243             my $meta = Class::MOP::get_metaclass_by_name($class);
3244             $meta->superclasses($plugin, $meta->superclasses);
3245         }
3246         $proto->_plugins->{$plugin} = 1;
3247         return $class;
3248     }
3249
3250     sub _default_plugins { return qw() }
3251
3252     sub setup_plugins {
3253         my ( $class, $plugins ) = @_;
3254
3255         $class->_plugins( {} ) unless $class->_plugins;
3256         $plugins = [ grep {
3257             m/Unicode::Encoding/ ? do {
3258                 $class->log->warn(
3259                     'Unicode::Encoding plugin is auto-applied,'
3260                     . ' please remove this from your appclass'
3261                     . ' and make sure to define "encoding" config'
3262                 );
3263                 unless (exists $class->config->{'encoding'}) {
3264                   $class->config->{'encoding'} = 'UTF-8';
3265                 }
3266                 () }
3267                 : $_
3268         } @$plugins ];
3269         push @$plugins, $class->_default_plugins;
3270         $plugins = Data::OptList::mkopt($plugins || []);
3271
3272         my @plugins = map {
3273             [ Catalyst::Utils::resolve_namespace(
3274                   $class . '::Plugin',
3275                   'Catalyst::Plugin', $_->[0]
3276               ),
3277               $_->[1],
3278             ]
3279          } @{ $plugins };
3280
3281         for my $plugin ( reverse @plugins ) {
3282             load_class($plugin->[0], $plugin->[1]);
3283             my $meta = find_meta($plugin->[0]);
3284             next if $meta && $meta->isa('Moose::Meta::Role');
3285
3286             $class->_register_plugin($plugin->[0]);
3287         }
3288
3289         my @roles =
3290             map  { $_->[0]->name, $_->[1] }
3291             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3292             map  { [find_meta($_->[0]), $_->[1]] }
3293             @plugins;
3294
3295         Moose::Util::apply_all_roles(
3296             $class => @roles
3297         ) if @roles;
3298     }
3299 }
3300
3301 =head2 registered_middlewares
3302
3303 Read only accessor that returns an array of all the middleware in the order
3304 that they were added (which is the REVERSE of the order they will be applied).
3305
3306 The values returned will be either instances of L<Plack::Middleware> or of a
3307 compatible interface, or a coderef, which is assumed to be inlined middleware
3308
3309 =head2 setup_middleware (?@middleware)
3310
3311 Read configuration information stored in configuration key C<psgi_middleware> or
3312 from passed @args.
3313
3314 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3315 to use it to enable L<Plack::Middleware>
3316
3317 This method is automatically called during 'setup' of your application, so
3318 you really don't need to invoke it.  However you may do so if you find the idea
3319 of loading middleware via configuration weird :).  For example:
3320
3321     package MyApp;
3322
3323     use Catalyst;
3324
3325     __PACKAGE__->setup_middleware('Head');
3326     __PACKAGE__->setup;
3327
3328 When we read middleware definitions from configuration, we reverse the list
3329 which sounds odd but is likely how you expect it to work if you have prior
3330 experience with L<Plack::Builder> or if you previously used the plugin
3331 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3332
3333 So basically your middleware handles an incoming request from the first
3334 registered middleware, down and handles the response from the last middleware
3335 up.
3336
3337 =cut
3338
3339 sub registered_middlewares {
3340     my $class = shift;
3341     if(my $middleware = $class->_psgi_middleware) {
3342         return (
3343           Catalyst::Middleware::Stash->new,
3344           Plack::Middleware::HTTPExceptions->new,
3345           Plack::Middleware::RemoveRedundantBody->new,
3346           Plack::Middleware::FixMissingBodyInRedirect->new,
3347           Plack::Middleware::ContentLength->new,
3348           Plack::Middleware::MethodOverride->new,
3349           Plack::Middleware::Head->new,
3350           @$middleware);
3351     } else {
3352         die "You cannot call ->registered_middlewares until middleware has been setup";
3353     }
3354 }
3355
3356 sub setup_middleware {
3357     my $class = shift;
3358     my @middleware_definitions = @_ ?
3359       reverse(@_) : reverse(@{$class->config->{'psgi_middleware'}||[]});
3360
3361     my @middleware = ();
3362     while(my $next = shift(@middleware_definitions)) {
3363         if(ref $next) {
3364             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3365                 push @middleware, $next;
3366             } elsif(ref $next eq 'CODE') {
3367                 push @middleware, $next;
3368             } elsif(ref $next eq 'HASH') {
3369                 my $namespace = shift @middleware_definitions;
3370                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3371                 push @middleware, $mw;
3372             } else {
3373               die "I can't handle middleware definition ${\ref $next}";
3374             }
3375         } else {
3376           my $mw = $class->Catalyst::Utils::build_middleware($next);
3377           push @middleware, $mw;
3378         }
3379     }
3380
3381     my @existing = @{$class->_psgi_middleware || []};
3382     $class->_psgi_middleware([@middleware,@existing,]);
3383 }
3384
3385 =head2 registered_data_handlers
3386
3387 A read only copy of registered Data Handlers returned as a Hash, where each key
3388 is a content type and each value is a subref that attempts to decode that content
3389 type.
3390
3391 =head2 setup_data_handlers (?@data_handler)
3392
3393 Read configuration information stored in configuration key C<data_handlers> or
3394 from passed @args.
3395
3396 See under L</CONFIGURATION> information regarding C<data_handlers>.
3397
3398 This method is automatically called during 'setup' of your application, so
3399 you really don't need to invoke it.
3400
3401 =head2 default_data_handlers
3402
3403 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3404 only two default data handlers, for 'application/json' and an alternative to
3405 'application/x-www-form-urlencoded' which supposed nested form parameters via
3406 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3407
3408 The 'application/json' data handler is used to parse incoming JSON into a Perl
3409 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3410 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3411 JSON decoder, and has the smallest dependency impact.
3412
3413 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3414 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3415 order to get the best performance.  You should add either to your dependency
3416 list (Makefile.PL, dist.ini, cpanfile, etc.)
3417
3418 =cut
3419
3420 sub registered_data_handlers {
3421     my $class = shift;
3422     if(my $data_handlers = $class->_data_handlers) {
3423         return %$data_handlers;
3424     } else {
3425         $class->setup_data_handlers;
3426         return $class->registered_data_handlers;
3427     }
3428 }
3429
3430 sub setup_data_handlers {
3431     my ($class, %data_handler_callbacks) = @_;
3432     %data_handler_callbacks = (
3433       %{$class->default_data_handlers},
3434       %{$class->config->{'data_handlers'}||+{}},
3435       %data_handler_callbacks);
3436
3437     $class->_data_handlers(\%data_handler_callbacks);
3438 }
3439
3440 sub default_data_handlers {
3441     my ($class) = @_;
3442     return +{
3443       'application/x-www-form-urlencoded' => sub {
3444           my ($fh, $req) = @_;
3445           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3446           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3447             ->can('build_cgi_struct')->($params);
3448       },
3449       'application/json' => sub {
3450           Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON')
3451             ->can('decode_json')->(do { local $/; $_->getline });
3452       },
3453     };
3454 }
3455
3456 =head2 $c->stack
3457
3458 Returns an arrayref of the internal execution stack (actions that are
3459 currently executing).
3460
3461 =head2 $c->stats
3462
3463 Returns the current timing statistics object. By default Catalyst uses
3464 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3465 L<< stats_class|/"$c->stats_class" >>.
3466
3467 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3468 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3469 profile explicitly, although MyApp.pm still won't profile nor output anything
3470 by itself.
3471
3472 =head2 $c->stats_class
3473
3474 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3475
3476 =head2 $c->use_stats
3477
3478 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3479
3480 Note that this is a static method, not an accessor and should be overridden
3481 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3482
3483 =cut
3484
3485 sub use_stats { 0 }
3486
3487
3488 =head2 $c->write( $data )
3489
3490 Writes $data to the output stream. When using this method directly, you
3491 will need to manually set the C<Content-Length> header to the length of
3492 your output data, if known.
3493
3494 =cut
3495
3496 sub write {
3497     my $c = shift;
3498
3499     # Finalize headers if someone manually writes output (for compat)
3500     $c->finalize_headers;
3501
3502     return $c->response->write( @_ );
3503 }
3504
3505 =head2 version
3506
3507 Returns the Catalyst version number. Mostly useful for "powered by"
3508 messages in template systems.
3509
3510 =cut
3511
3512 sub version { return $Catalyst::VERSION }
3513
3514 =head1 CONFIGURATION
3515
3516 There are a number of 'base' config variables which can be set:
3517
3518 =over
3519
3520 =item *
3521
3522 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3523
3524 =item *
3525
3526 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3527
3528 =item *
3529
3530 C<disable_component_resolution_regex_fallback> - Turns
3531 off the deprecated component resolution functionality so
3532 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3533 are called then regex search will not be attempted on string values and
3534 instead C<undef> will be returned.
3535
3536 =item *
3537
3538 C<home> - The application home directory. In an uninstalled application,
3539 this is the top level application directory. In an installed application,
3540 this will be the directory containing C<< MyApp.pm >>.
3541
3542 =item *
3543
3544 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3545
3546 =item *
3547
3548 C<name> - The name of the application in debug messages and the debug and
3549 welcome screens
3550
3551 =item *
3552
3553 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3554 until it is accessed. This allows you to (for example) check authentication (and reject
3555 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3556
3557 =item *
3558
3559 C<root> - The root directory for templates. Usually this is just a
3560 subdirectory of the home directory, but you can set it to change the
3561 templates to a different directory.
3562
3563 =item *
3564
3565 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3566 namespaces from which components will be loaded (and constructed and stored in
3567 C<< $c->components >>).
3568
3569 =item *
3570
3571 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3572 to be shown in hit debug tables in the test server.
3573
3574 =item *
3575
3576 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3577 variable should be used for determining the request path.
3578
3579 Most web server environments pass the requested path to the application using environment variables,
3580 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3581 exposed as C<< $c->request->base >>) and the request path below that base.
3582
3583 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3584 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3585
3586 =over
3587
3588 =item use_request_uri_for_path => 0
3589
3590 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3591 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3592 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3593 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3594
3595 However this method has the major disadvantage that it is impossible to correctly decode some elements
3596 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3597 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3598 can't distinguish / vs %2F in paths (in addition to other encoded values).
3599
3600 =item use_request_uri_for_path => 1
3601
3602 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3603 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3604 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3605
3606 Given that this method of path resolution is provably more correct, it is recommended that you use
3607 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3608 aware of the implications of not being able to handle encoded URI paths correctly.
3609
3610 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3611 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3612 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3613 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3614 C<< $c->request->base >> will be incorrect.
3615
3616 =back
3617
3618 =item *
3619
3620 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3621
3622 =item *
3623
3624 C<encoding> - See L</ENCODING>
3625
3626 =item *
3627
3628 C<abort_chain_on_error_fix>
3629
3630 When there is an error in an action chain, the default behavior is to continue
3631 processing the remaining actions and then catch the error upon chain end.  This
3632 can lead to running actions when the application is in an unexpected state.  If
3633 you have this issue, setting this config value to true will promptly exit a
3634 chain when there is an error raised in any action (thus terminating the chain
3635 early.)
3636
3637 use like:
3638
3639     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3640
3641 In the future this might become the default behavior.
3642
3643 =item *
3644
3645 C<use_hash_multivalue_in_request>
3646
3647 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3648 and C<parameters> return a hashref where values might be scalar or an arrayref
3649 depending on the incoming data.  In many cases this can be undesirable as it
3650 leads one to writing defensive code like the following:
3651
3652     my ($val) = ref($c->req->parameters->{a}) ?
3653       @{$c->req->parameters->{a}} :
3654         $c->req->parameters->{a};
3655
3656 Setting this configuration item to true will make L<Catalyst> populate the
3657 attributes underlying these methods with an instance of L<Hash::MultiValue>
3658 which is used by L<Plack::Request> and others to solve this very issue.  You
3659 may prefer this behavior to the default, if so enable this option (be warned
3660 if you enable it in a legacy application we are not sure if it is completely
3661 backwardly compatible).
3662
3663 =item *
3664
3665 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3666
3667 =item *
3668
3669 C<data_handlers> - See L<DATA HANDLERS>.
3670
3671 =back
3672
3673 =head1 EXCEPTIONS
3674
3675 Generally when you throw an exception inside an Action (or somewhere in
3676 your stack, such as in a model that an Action is calling) that exception
3677 is caught by Catalyst and unless you either catch it yourself (via eval
3678 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
3679 will eventually reach L</finalize_errors> and return either the debugging
3680 error stack page, or the default error page.  However, if your exception
3681 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
3682 instead rethrow it so that it can be handled by that middleware (which
3683 is part of the default middleware).  For example this would allow
3684
3685     use HTTP::Throwable::Factory 'http_throw';
3686
3687     sub throws_exception :Local {
3688       my ($self, $c) = @_;
3689
3690       http_throw(SeeOther => { location =>
3691         $c->uri_for($self->action_for('redirect')) });
3692
3693     }
3694
3695 =head1 INTERNAL ACTIONS
3696
3697 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3698 C<_ACTION>, and C<_END>. These are by default not shown in the private
3699 action table, but you can make them visible with a config parameter.
3700
3701     MyApp->config(show_internal_actions => 1);
3702
3703 =head1 ON-DEMAND PARSER
3704
3705 The request body is usually parsed at the beginning of a request,
3706 but if you want to handle input yourself, you can enable on-demand
3707 parsing with a config parameter.
3708
3709     MyApp->config(parse_on_demand => 1);
3710
3711 =head1 PROXY SUPPORT
3712
3713 Many production servers operate using the common double-server approach,
3714 with a lightweight frontend web server passing requests to a larger
3715 backend server. An application running on the backend server must deal
3716 with two problems: the remote user always appears to be C<127.0.0.1> and
3717 the server's hostname will appear to be C<localhost> regardless of the
3718 virtual host that the user connected through.
3719
3720 Catalyst will automatically detect this situation when you are running
3721 the frontend and backend servers on the same machine. The following
3722 changes are made to the request.
3723
3724     $c->req->address is set to the user's real IP address, as read from
3725     the HTTP X-Forwarded-For header.
3726
3727     The host value for $c->req->base and $c->req->uri is set to the real
3728     host, as read from the HTTP X-Forwarded-Host header.
3729
3730 Additionally, you may be running your backend application on an insecure
3731 connection (port 80) while your frontend proxy is running under SSL.  If there
3732 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3733 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3734 be created properly.
3735
3736 In the case of passing in:
3737
3738     X-Forwarded-Port: 443
3739
3740 All calls to C<uri_for> will result in an https link, as is expected.
3741
3742 Obviously, your web server must support these headers for this to work.
3743
3744 In a more complex server farm environment where you may have your
3745 frontend proxy server(s) on different machines, you will need to set a
3746 configuration option to tell Catalyst to read the proxied data from the
3747 headers.
3748
3749     MyApp->config(using_frontend_proxy => 1);
3750
3751 If you do not wish to use the proxy support at all, you may set:
3752
3753     MyApp->config(ignore_frontend_proxy => 0);
3754
3755 =head2 Note about psgi files
3756
3757 Note that if you supply your own .psgi file, calling
3758 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3759
3760 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3761 in your psgi, for example:
3762
3763     builder {
3764         enable "Plack::Middleware::ReverseProxy";
3765         MyApp->psgi_app
3766     };
3767
3768 This will unconditionally add the ReverseProxy support, or you need to call
3769 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3770 apply the support depending upon your config).
3771
3772 See L<Catalyst::PSGI> for more information.
3773
3774 =head1 THREAD SAFETY
3775
3776 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3777 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3778 believe the Catalyst core to be thread-safe.
3779
3780 If you plan to operate in a threaded environment, remember that all other
3781 modules you are using must also be thread-safe. Some modules, most notably
3782 L<DBD::SQLite>, are not thread-safe.
3783
3784 =head1 DATA HANDLERS
3785
3786 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3787 form parameters and URL search query fields.  However it has become common
3788 for various alternative content types to be PUT or POSTed to your controllers
3789 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3790 XML and other content types when communicating with an application server.  In
3791 order to better support this use case, L<Catalyst> defines a global configuration
3792 option, C<data_handlers>, which lets you associate a content type with a coderef
3793 that parses that content type into something Perl can readily access.
3794
3795     package MyApp::Web;
3796
3797     use Catalyst;
3798     use JSON::Maybe;
3799
3800     __PACKAGE__->config(
3801       data_handlers => {
3802         'application/json' => sub { local $/; decode_json $_->getline },
3803       },
3804       ## Any other configuration.
3805     );
3806
3807     __PACKAGE__->setup;
3808
3809 By default L<Catalyst> comes with a generic JSON data handler similar to the
3810 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
3811 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
3812 it installed (if you want the faster XS parser, add it to you project Makefile.PL
3813 or dist.ini, cpanfile, etc.)
3814
3815 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
3816 (matched against the incoming request type using a regexp such as to be case
3817 insensitive) and whose values are coderefs that receive a localized version of
3818 C<$_> which is a filehandle object pointing to received body.
3819
3820 This feature is considered an early access release and we reserve the right
3821 to alter the interface in order to provide a performant and secure solution to
3822 alternative request body content.  Your reports welcomed!
3823
3824 =head1 PSGI MIDDLEWARE
3825
3826 You can define middleware, defined as L<Plack::Middleware> or a compatible
3827 interface in configuration.  Your middleware definitions are in the form of an
3828 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3829 with details to follow:
3830
3831     package MyApp::Web;
3832
3833     use Catalyst;
3834     use Plack::Middleware::StackTrace;
3835
3836     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3837
3838     __PACKAGE__->config(
3839       'psgi_middleware', [
3840         'Debug',
3841         '+MyApp::Custom',
3842         $stacktrace_middleware,
3843         'Session' => {store => 'File'},
3844         sub {
3845           my $app = shift;
3846           return sub {
3847             my $env = shift;
3848             $env->{myapp.customkey} = 'helloworld';
3849             $app->($env);
3850           },
3851         },
3852       ],
3853     );
3854
3855     __PACKAGE__->setup;
3856
3857 So the general form is:
3858
3859     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3860
3861 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3862 the order listed (to make it function similarly to L<Plack::Builder>:
3863
3864 Alternatively, you may also define middleware by calling the L</setup_middleware>
3865 package method:
3866
3867     package MyApp::Web;
3868
3869     use Catalyst;
3870
3871     __PACKAGE__->setup_middleware( \@middleware_definitions);
3872     __PACKAGE__->setup;
3873
3874 In the case where you do both (use 'setup_middleware' and configuration) the
3875 package call to setup_middleware will be applied earlier (in other words its
3876 middleware will wrap closer to the application).  Keep this in mind since in
3877 some cases the order of middleware is important.
3878
3879 The two approaches are not exclusive.
3880
3881 =over 4
3882
3883 =item Middleware Object
3884
3885 An already initialized object that conforms to the L<Plack::Middleware>
3886 specification:
3887
3888     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3889
3890     __PACKAGE__->config(
3891       'psgi_middleware', [
3892         $stacktrace_middleware,
3893       ]);
3894
3895
3896 =item coderef
3897
3898 A coderef that is an inlined middleware:
3899
3900     __PACKAGE__->config(
3901       'psgi_middleware', [
3902         sub {
3903           my $app = shift;
3904           return sub {
3905             my $env = shift;
3906             if($env->{PATH_INFO} =~m/forced/) {
3907               Plack::App::File
3908                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3909                 ->call($env);
3910             } else {
3911               return $app->($env);
3912             }
3913          },
3914       },
3915     ]);
3916
3917
3918
3919 =item a scalar
3920
3921 We assume the scalar refers to a namespace after normalizing it using the
3922 following rules:
3923
3924 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3925 is assumed to be 'as is', and we just install and use the middleware.
3926
3927 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3928 (the package name of your Catalyst application subclass), we also assume then
3929 that it is a full namespace, and use it.
3930
3931 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3932 resolve it first by looking for it under your application namespace (for example
3933 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3934 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3935 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3936 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3937 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3938 you find that a good idea.
3939
3940 Examples:
3941
3942     package MyApp::Web;
3943
3944     __PACKAGE__->config(
3945       'psgi_middleware', [
3946         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3947         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3948         '+MyApp::Custom',  ## MyApp::Custom->wrap
3949       ],
3950     );
3951
3952 =item a scalar followed by a hashref
3953
3954 Just like the previous, except the following C<HashRef> is used as arguments
3955 to initialize the middleware object.
3956
3957     __PACKAGE__->config(
3958       'psgi_middleware', [
3959          'Session' => {store => 'File'},
3960     ]);
3961
3962 =back
3963
3964 Please see L<PSGI> for more on middleware.
3965
3966 =head1 ENCODING
3967
3968 On request, decodes all params from encoding into a sequence of
3969 logical characters. On response, encodes body into encoding.
3970
3971 =head2 Methods
3972
3973 =over 4
3974
3975 =item encoding
3976
3977 Returns an instance of an C<Encode> encoding
3978
3979     print $c->encoding->name
3980
3981 =item handle_unicode_encoding_exception ($exception_context)
3982
3983 Method called when decoding process for a request fails.
3984
3985 An C<$exception_context> hashref is provided to allow you to override the
3986 behaviour of your application when given data with incorrect encodings.
3987
3988 The default method throws exceptions in the case of invalid request parameters
3989 (resulting in a 500 error), but ignores errors in upload filenames.
3990
3991 The keys passed in the C<$exception_context> hash are:
3992
3993 =over
3994
3995 =item param_value
3996
3997 The value which was not able to be decoded.
3998
3999 =item error_msg
4000
4001 The exception received from L<Encode>.
4002
4003 =item encoding_step
4004
4005 What type of data was being decoded. Valid values are (currently)
4006 C<params> - for request parameters / arguments / captures
4007 and C<uploads> - for request upload filenames.
4008
4009 =back
4010
4011 =back
4012
4013 =head1 SUPPORT
4014
4015 IRC:
4016
4017     Join #catalyst on irc.perl.org.
4018
4019 Mailing Lists:
4020
4021     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4022     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4023
4024 Web:
4025
4026     http://catalyst.perl.org
4027
4028 Wiki:
4029
4030     http://dev.catalyst.perl.org
4031
4032 =head1 SEE ALSO
4033
4034 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4035
4036 =head2 L<Catalyst::Manual> - The Catalyst Manual
4037
4038 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4039
4040 =head2 L<Catalyst::Engine> - Core engine
4041
4042 =head2 L<Catalyst::Log> - Log class.
4043
4044 =head2 L<Catalyst::Request> - Request object
4045
4046 =head2 L<Catalyst::Response> - Response object
4047
4048 =head2 L<Catalyst::Test> - The test suite.
4049
4050 =head1 PROJECT FOUNDER
4051
4052 sri: Sebastian Riedel <sri@cpan.org>
4053
4054 =head1 CONTRIBUTORS
4055
4056 abw: Andy Wardley
4057
4058 acme: Leon Brocard <leon@astray.com>
4059
4060 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4061
4062 Andrew Bramble
4063
4064 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4065
4066 Andrew Ruthven
4067
4068 andyg: Andy Grundman <andy@hybridized.org>
4069
4070 audreyt: Audrey Tang
4071
4072 bricas: Brian Cassidy <bricas@cpan.org>
4073
4074 Caelum: Rafael Kitover <rkitover@io.com>
4075
4076 chansen: Christian Hansen
4077
4078 chicks: Christopher Hicks
4079
4080 Chisel Wright C<pause@herlpacker.co.uk>
4081
4082 Danijel Milicevic C<me@danijel.de>
4083
4084 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4085
4086 David Naughton, C<naughton@umn.edu>
4087
4088 David E. Wheeler
4089
4090 dhoss: Devin Austin <dhoss@cpan.org>
4091
4092 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4093
4094 Drew Taylor
4095
4096 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4097
4098 esskar: Sascha Kiefer
4099
4100 fireartist: Carl Franks <cfranks@cpan.org>
4101
4102 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4103
4104 gabb: Danijel Milicevic
4105
4106 Gary Ashton Jones
4107
4108 Gavin Henry C<ghenry@perl.me.uk>
4109
4110 Geoff Richards
4111
4112 groditi: Guillermo Roditi <groditi@gmail.com>
4113
4114 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4115
4116 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4117
4118 jcamacho: Juan Camacho
4119
4120 jester: Jesse Sheidlower C<jester@panix.com>
4121
4122 jhannah: Jay Hannah <jay@jays.net>
4123
4124 Jody Belka
4125
4126 Johan Lindstrom
4127
4128 jon: Jon Schutz <jjschutz@cpan.org>
4129
4130 Jonathan Rockway C<< <jrockway@cpan.org> >>
4131
4132 Kieren Diment C<kd@totaldatasolution.com>
4133
4134 konobi: Scott McWhirter <konobi@cpan.org>
4135
4136 marcus: Marcus Ramberg <mramberg@cpan.org>
4137
4138 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4139
4140 mgrimes: Mark Grimes <mgrimes@cpan.org>
4141
4142 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4143
4144 mugwump: Sam Vilain
4145
4146 naughton: David Naughton
4147
4148 ningu: David Kamholz <dkamholz@cpan.org>
4149
4150 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4151
4152 numa: Dan Sully <daniel@cpan.org>
4153
4154 obra: Jesse Vincent
4155
4156 Octavian Rasnita
4157
4158 omega: Andreas Marienborg
4159
4160 Oleg Kostyuk <cub.uanic@gmail.com>
4161
4162 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4163
4164 rafl: Florian Ragwitz <rafl@debian.org>
4165
4166 random: Roland Lammel <lammel@cpan.org>
4167
4168 Robert Sedlacek C<< <rs@474.at> >>
4169
4170 SpiceMan: Marcel Montes
4171
4172 sky: Arthur Bergman
4173
4174 szbalint: Balint Szilakszi <szbalint@cpan.org>
4175
4176 t0m: Tomas Doran <bobtfish@bobtfish.net>
4177
4178 Ulf Edvinsson
4179
4180 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4181
4182 Viljo Marrandi C<vilts@yahoo.com>
4183
4184 Will Hawes C<info@whawes.co.uk>
4185
4186 willert: Sebastian Willert <willert@cpan.org>
4187
4188 wreis: Wallace Reis <wreis@cpan.org>
4189
4190 Yuval Kogman, C<nothingmuch@woobling.org>
4191
4192 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4193
4194 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4195
4196 Upasana <me@upasana.me>
4197
4198 =head1 COPYRIGHT
4199
4200 Copyright (c) 2005-2014, the above named PROJECT FOUNDER and CONTRIBUTORS.
4201
4202 =head1 LICENSE
4203
4204 This library is free software. You can redistribute it and/or modify it under
4205 the same terms as Perl itself.
4206
4207 =cut
4208
4209 no Moose;
4210
4211 __PACKAGE__->meta->make_immutable;
4212
4213 1;