lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Devel::InnerPackage ();
  18 use File::stat;
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use utf8;
  32 use Carp qw/croak carp shortmess/;
  33
  34 BEGIN { require 5.008004; }
  35
  36 has stack => (is => 'ro', default => sub { [] });
  37 has stash => (is => 'rw', default => sub { {} });
  38 has state => (is => 'rw', default => 0);
  39 has stats => (is => 'rw');
  40 has action => (is => 'rw');
  41 has counter => (is => 'rw', default => sub { {} });
  42 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  43 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  44 has namespace => (is => 'rw');
  45
  46 sub depth { scalar @{ shift->stack || [] }; }
  47 sub comp { shift->component(@_) }
  48
  49 sub req {
  50     my $self = shift; return $self->request(@_);
  51 }
  52 sub res {
  53     my $self = shift; return $self->response(@_);
  54 }
  55
  56 # For backwards compatibility
  57 sub finalize_output { shift->finalize_body(@_) };
  58
  59 # For statistics
  60 our $COUNT     = 1;
  61 our $START     = time;
  62 our $RECURSION = 1000;
  63 our $DETACH    = Catalyst::Exception::Detach->new;
  64 our $GO        = Catalyst::Exception::Go->new;
  65
  66 #I imagine that very few of these really need to be class variables. if any.
  67 #maybe we should just make them attributes with a default?
  68 __PACKAGE__->mk_classdata($_)
  69   for qw/components arguments dispatcher engine log dispatcher_class
  70   engine_class context_class request_class response_class stats_class
  71   setup_finished/;
  72
  73 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  74 __PACKAGE__->engine_class('Catalyst::Engine');
  75 __PACKAGE__->request_class('Catalyst::Request');
  76 __PACKAGE__->response_class('Catalyst::Response');
  77 __PACKAGE__->stats_class('Catalyst::Stats');
  78
  79 # Remember to update this in Catalyst::Runtime as well!
  80
  81 our $VERSION = '5.80016';
  82 $VERSION = eval $VERSION;
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 104     }
 105
 106     $caller->arguments( [@arguments] );
 107     $caller->setup_home;
 108 }
 109
 110 sub _application { $_[0] }
 111
 112 =head1 NAME
 113
 114 Catalyst - The Elegant MVC Web Application Framework
 115
 116 =head1 SYNOPSIS
 117
 118 See the L<Catalyst::Manual> distribution for comprehensive
 119 documentation and tutorials.
 120
 121     # Install Catalyst::Devel for helpers and other development tools
 122     # use the helper to create a new application
 123     catalyst.pl MyApp
 124
 125     # add models, views, controllers
 126     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 127     script/myapp_create.pl view MyTemplate TT
 128     script/myapp_create.pl controller Search
 129
 130     # built in testserver -- use -r to restart automatically on changes
 131     # --help to see all available options
 132     script/myapp_server.pl
 133
 134     # command line testing interface
 135     script/myapp_test.pl /yada
 136
 137     ### in lib/MyApp.pm
 138     use Catalyst qw/-Debug/; # include plugins here as well
 139
 140     ### In lib/MyApp/Controller/Root.pm (autocreated)
 141     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 142         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 143         $c->stash->{template} = 'foo.tt'; # set the template
 144         # lookup something from db -- stash vars are passed to TT
 145         $c->stash->{data} =
 146           $c->model('Database::Foo')->search( { country => $args[0] } );
 147         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 148             $c->forward( 'bar' ); # process another action
 149             # do something else after forward returns
 150         }
 151     }
 152
 153     # The foo.tt TT template can use the stash data from the database
 154     [% WHILE (item = data.next) %]
 155         [% item.foo %]
 156     [% END %]
 157
 158     # called for /bar/of/soap, /bar/of/soap/10, etc.
 159     sub bar : Path('/bar/of/soap') { ... }
 160
 161     # called for all actions, from the top-most controller downwards
 162     sub auto : Private {
 163         my ( $self, $c ) = @_;
 164         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 165             $c->res->redirect( '/login' ); # require login
 166             return 0; # abort request and go immediately to end()
 167         }
 168         return 1; # success; carry on to next action
 169     }
 170
 171     # called after all actions are finished
 172     sub end : Private {
 173         my ( $self, $c ) = @_;
 174         if ( scalar @{ $c->error } ) { ... } # handle errors
 175         return if $c->res->body; # already have a response
 176         $c->forward( 'MyApp::View::TT' ); # render template
 177     }
 178
 179     ### in MyApp/Controller/Foo.pm
 180     # called for /foo/bar
 181     sub bar : Local { ... }
 182
 183     # called for /blargle
 184     sub blargle : Global { ... }
 185
 186     # an index action matches /foo, but not /foo/1, etc.
 187     sub index : Private { ... }
 188
 189     ### in MyApp/Controller/Foo/Bar.pm
 190     # called for /foo/bar/baz
 191     sub baz : Local { ... }
 192
 193     # first Root auto is called, then Foo auto, then this
 194     sub auto : Private { ... }
 195
 196     # powerful regular expression paths are also possible
 197     sub details : Regex('^product/(\w+)/details$') {
 198         my ( $self, $c ) = @_;
 199         # extract the (\w+) from the URI
 200         my $product = $c->req->captures->[0];
 201     }
 202
 203 See L<Catalyst::Manual::Intro> for additional information.
 204
 205 =head1 DESCRIPTION
 206
 207 Catalyst is a modern framework for making web applications without the
 208 pain usually associated with this process. This document is a reference
 209 to the main Catalyst application. If you are a new user, we suggest you
 210 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 211
 212 See L<Catalyst::Manual> for more documentation.
 213
 214 Catalyst plugins can be loaded by naming them as arguments to the "use
 215 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 216 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 217 C<My::Module>.
 218
 219     use Catalyst qw/My::Module/;
 220
 221 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 222 fully qualify the name by using a unary plus:
 223
 224     use Catalyst qw/
 225         My::Module
 226         +Fully::Qualified::Plugin::Name
 227     /;
 228
 229 Special flags like C<-Debug> and C<-Engine> can also be specified as
 230 arguments when Catalyst is loaded:
 231
 232     use Catalyst qw/-Debug My::Module/;
 233
 234 The position of plugins and flags in the chain is important, because
 235 they are loaded in the order in which they appear.
 236
 237 The following flags are supported:
 238
 239 =head2 -Debug
 240
 241 Enables debug output. You can also force this setting from the system
 242 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 243 settings override the application, with <MYAPP>_DEBUG having the highest
 244 priority.
 245
 246 =head2 -Engine
 247
 248 Forces Catalyst to use a specific engine. Omit the
 249 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 250
 251     use Catalyst qw/-Engine=CGI/;
 252
 253 =head2 -Home
 254
 255 Forces Catalyst to use a specific home directory, e.g.:
 256
 257     use Catalyst qw[-Home=/usr/mst];
 258
 259 This can also be done in the shell environment by setting either the
 260 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 261 is replaced with the uppercased name of your application, any "::" in
 262 the name will be replaced with underscores, e.g. MyApp::Web should use
 263 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 264
 265 =head2 -Log
 266
 267     use Catalyst '-Log=warn,fatal,error';
 268
 269 Specifies a comma-delimited list of log levels.
 270
 271 =head2 -Stats
 272
 273 Enables statistics collection and reporting. You can also force this setting
 274 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 275 environment settings override the application, with <MYAPP>_STATS having the
 276 highest priority.
 277
 278 e.g.
 279
 280    use Catalyst qw/-Stats=1/
 281
 282 =head1 METHODS
 283
 284 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 285
 286 =head2 $c->action
 287
 288 Returns a L<Catalyst::Action> object for the current action, which
 289 stringifies to the action name. See L<Catalyst::Action>.
 290
 291 =head2 $c->namespace
 292
 293 Returns the namespace of the current action, i.e., the URI prefix
 294 corresponding to the controller of the current action. For example:
 295
 296     # in Controller::Foo::Bar
 297     $c->namespace; # returns 'foo/bar';
 298
 299 =head2 $c->request
 300
 301 =head2 $c->req
 302
 303 Returns the current L<Catalyst::Request> object, giving access to
 304 information about the current client request (including parameters,
 305 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 306
 307 =head2 REQUEST FLOW HANDLING
 308
 309 =head2 $c->forward( $action [, \@arguments ] )
 310
 311 =head2 $c->forward( $class, $method, [, \@arguments ] )
 312
 313 Forwards processing to another action, by its private name. If you give a
 314 class name but no method, C<process()> is called. You may also optionally
 315 pass arguments in an arrayref. The action will receive the arguments in
 316 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 317 C<< $c->req->args >> will be restored to the previous values.
 318
 319 Any data C<return>ed from the action forwarded to, will be returned by the
 320 call to forward.
 321
 322     my $foodata = $c->forward('/foo');
 323     $c->forward('index');
 324     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 325     $c->forward('View::TT');
 326
 327 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 328 an C<< eval { } >> around the call (actually
 329 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 330 all 'dies' within the called action. If you want C<die> to propagate you
 331 need to do something like:
 332
 333     $c->forward('foo');
 334     die $c->error if $c->error;
 335
 336 Or make sure to always return true values from your actions and write
 337 your code like this:
 338
 339     $c->forward('foo') || return;
 340
 341 Another note is that C<< $c->forward >> always returns a scalar because it
 342 actually returns $c->state which operates in a scalar context.
 343 Thus, something like:
 344
 345     return @array;
 346
 347 in an action that is forwarded to is going to return a scalar,
 348 i.e. how many items are in that array, which is probably not what you want.
 349 If you need to return an array then return a reference to it,
 350 or stash it like so:
 351
 352     $c->stash->{array} = \@array;
 353
 354 and access it from the stash.
 355
 356 =cut
 357
 358 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 359
 360 =head2 $c->detach( $action [, \@arguments ] )
 361
 362 =head2 $c->detach( $class, $method, [, \@arguments ] )
 363
 364 =head2 $c->detach()
 365
 366 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 367 doesn't return to the previous action when processing is finished.
 368
 369 When called with no arguments it escapes the processing chain entirely.
 370
 371 =cut
 372
 373 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 374
 375 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 376
 377 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 378
 379 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 380 but does a full dispatch, instead of just calling the new C<$action> /
 381 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 382 you go to are called, just like a new request.
 383
 384 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 385 This means, for example, that C<< $c->action >> methods such as
 386 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 387 L<reverse|Catalyst::Action/reverse> return information for the visited action
 388 when they are invoked within the visited action.  This is different from the
 389 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 390 continues to use the $c->action object from the caller action even when
 391 invoked from the callee.
 392
 393 C<< $c->stash >> is kept unchanged.
 394
 395 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 396 allows you to "wrap" another action, just as it would have been called by
 397 dispatching from a URL, while the analogous
 398 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 399 transfer control to another action as if it had been reached directly from a URL.
 400
 401 =cut
 402
 403 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 404
 405 =head2 $c->go( $action [, \@captures, \@arguments ] )
 406
 407 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 408
 409 The relationship between C<go> and
 410 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 411 the relationship between
 412 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 413 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 414 C<< $c->go >> will perform a full dispatch on the specified action or method,
 415 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 416 C<go> escapes the processing of the current request chain on completion, and
 417 does not return to its caller.
 418
 419 =cut
 420
 421 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 422
 423 =head2 $c->response
 424
 425 =head2 $c->res
 426
 427 Returns the current L<Catalyst::Response> object, see there for details.
 428
 429 =head2 $c->stash
 430
 431 Returns a hashref to the stash, which may be used to store data and pass
 432 it between components during a request. You can also set hash keys by
 433 passing arguments. The stash is automatically sent to the view. The
 434 stash is cleared at the end of a request; it cannot be used for
 435 persistent storage (for this you must use a session; see
 436 L<Catalyst::Plugin::Session> for a complete system integrated with
 437 Catalyst).
 438
 439     $c->stash->{foo} = $bar;
 440     $c->stash( { moose => 'majestic', qux => 0 } );
 441     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 442
 443     # stash is automatically passed to the view for use in a template
 444     $c->forward( 'MyApp::View::TT' );
 445
 446 =cut
 447
 448 around stash => sub {
 449     my $orig = shift;
 450     my $c = shift;
 451     my $stash = $orig->($c);
 452     if (@_) {
 453         my $new_stash = @_ > 1 ? {@_} : $_[0];
 454         croak('stash takes a hash or hashref') unless ref $new_stash;
 455         foreach my $key ( keys %$new_stash ) {
 456           $stash->{$key} = $new_stash->{$key};
 457         }
 458     }
 459
 460     return $stash;
 461 };
 462
 463
 464 =head2 $c->error
 465
 466 =head2 $c->error($error, ...)
 467
 468 =head2 $c->error($arrayref)
 469
 470 Returns an arrayref containing error messages.  If Catalyst encounters an
 471 error while processing a request, it stores the error in $c->error.  This
 472 method should only be used to store fatal error messages.
 473
 474     my @error = @{ $c->error };
 475
 476 Add a new error.
 477
 478     $c->error('Something bad happened');
 479
 480 =cut
 481
 482 sub error {
 483     my $c = shift;
 484     if ( $_[0] ) {
 485         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 486         croak @$error unless ref $c;
 487         push @{ $c->{error} }, @$error;
 488     }
 489     elsif ( defined $_[0] ) { $c->{error} = undef }
 490     return $c->{error} || [];
 491 }
 492
 493
 494 =head2 $c->state
 495
 496 Contains the return value of the last executed action.
 497 Note that << $c->state >> operates in a scalar context which means that all
 498 values it returns are scalar.
 499
 500 =head2 $c->clear_errors
 501
 502 Clear errors.  You probably don't want to clear the errors unless you are
 503 implementing a custom error screen.
 504
 505 This is equivalent to running
 506
 507     $c->error(0);
 508
 509 =cut
 510
 511 sub clear_errors {
 512     my $c = shift;
 513     $c->error(0);
 514 }
 515
 516 sub _comp_search_prefixes {
 517     my $c = shift;
 518     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 519 }
 520
 521 # search components given a name and some prefixes
 522 sub _comp_names_search_prefixes {
 523     my ( $c, $name, @prefixes ) = @_;
 524     my $appclass = ref $c || $c;
 525     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 526     $filter = qr/$filter/; # Compile regex now rather than once per loop
 527
 528     # map the original component name to the sub part that we will search against
 529     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 530         grep { /$filter/ } keys %{ $c->components };
 531
 532     # undef for a name will return all
 533     return keys %eligible if !defined $name;
 534
 535     my $query  = ref $name ? $name : qr/^$name$/i;
 536     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 537
 538     return @result if @result;
 539
 540     # if we were given a regexp to search against, we're done.
 541     return if ref $name;
 542
 543     # skip regexp fallback if configured
 544     return
 545         if $appclass->config->{disable_component_resolution_regex_fallback};
 546
 547     # regexp fallback
 548     $query  = qr/$name/i;
 549     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 550
 551     # no results? try against full names
 552     if( !@result ) {
 553         @result = grep { m{$query} } keys %eligible;
 554     }
 555
 556     # don't warn if we didn't find any results, it just might not exist
 557     if( @result ) {
 558         # Disgusting hack to work out correct method name
 559         my $warn_for = lc $prefixes[0];
 560         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 561            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 562            "component resolution is unreliable and unsafe.";
 563         my $short = $result[0];
 564         # remove the component namespace prefix
 565         $short =~ s/.*?(Model|Controller|View):://;
 566         my $shortmess = Carp::shortmess('');
 567         if ($shortmess =~ m#Catalyst/Plugin#) {
 568            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 569               "plugin's config";
 570         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 571            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 572               "component's config";
 573         } else {
 574            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 575               "but if you really wanted to search, pass in a regexp as the argument " .
 576               "like so: \$c->${warn_for}(qr/${name}/)";
 577         }
 578         $c->log->warn( "${msg}$shortmess" );
 579     }
 580
 581     return @result;
 582 }
 583
 584 # Find possible names for a prefix
 585 sub _comp_names {
 586     my ( $c, @prefixes ) = @_;
 587     my $appclass = ref $c || $c;
 588
 589     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 590
 591     my @names = map { s{$filter}{}; $_; }
 592         $c->_comp_names_search_prefixes( undef, @prefixes );
 593
 594     return @names;
 595 }
 596
 597 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 598 sub _filter_component {
 599     my ( $c, $comp, @args ) = @_;
 600
 601     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 602         return $comp->ACCEPT_CONTEXT( $c, @args );
 603     }
 604
 605     return $comp;
 606 }
 607
 608 =head2 COMPONENT ACCESSORS
 609
 610 =head2 $c->controller($name)
 611
 612 Gets a L<Catalyst::Controller> instance by name.
 613
 614     $c->controller('Foo')->do_stuff;
 615
 616 If the name is omitted, will return the controller for the dispatched
 617 action.
 618
 619 If you want to search for controllers, pass in a regexp as the argument.
 620
 621     # find all controllers that start with Foo
 622     my @foo_controllers = $c->controller(qr{^Foo});
 623
 624
 625 =cut
 626
 627 sub controller {
 628     my ( $c, $name, @args ) = @_;
 629
 630     if( $name ) {
 631         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 632         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 633         return $c->_filter_component( $result[ 0 ], @args );
 634     }
 635
 636     return $c->component( $c->action->class );
 637 }
 638
 639 =head2 $c->model($name)
 640
 641 Gets a L<Catalyst::Model> instance by name.
 642
 643     $c->model('Foo')->do_stuff;
 644
 645 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 646
 647 If the name is omitted, it will look for
 648  - a model object in $c->stash->{current_model_instance}, then
 649  - a model name in $c->stash->{current_model}, then
 650  - a config setting 'default_model', or
 651  - check if there is only one model, and return it if that's the case.
 652
 653 If you want to search for models, pass in a regexp as the argument.
 654
 655     # find all models that start with Foo
 656     my @foo_models = $c->model(qr{^Foo});
 657
 658 =cut
 659
 660 sub model {
 661     my ( $c, $name, @args ) = @_;
 662     my $appclass = ref($c) || $c;
 663     if( $name ) {
 664         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 665         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 666         return $c->_filter_component( $result[ 0 ], @args );
 667     }
 668
 669     if (ref $c) {
 670         return $c->stash->{current_model_instance}
 671           if $c->stash->{current_model_instance};
 672         return $c->model( $c->stash->{current_model} )
 673           if $c->stash->{current_model};
 674     }
 675     return $c->model( $appclass->config->{default_model} )
 676       if $appclass->config->{default_model};
 677
 678     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 679
 680     if( $rest ) {
 681         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 682         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 683         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 684         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 685         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 686     }
 687
 688     return $c->_filter_component( $comp );
 689 }
 690
 691
 692 =head2 $c->view($name)
 693
 694 Gets a L<Catalyst::View> instance by name.
 695
 696     $c->view('Foo')->do_stuff;
 697
 698 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 699
 700 If the name is omitted, it will look for
 701  - a view object in $c->stash->{current_view_instance}, then
 702  - a view name in $c->stash->{current_view}, then
 703  - a config setting 'default_view', or
 704  - check if there is only one view, and return it if that's the case.
 705
 706 If you want to search for views, pass in a regexp as the argument.
 707
 708     # find all views that start with Foo
 709     my @foo_views = $c->view(qr{^Foo});
 710
 711 =cut
 712
 713 sub view {
 714     my ( $c, $name, @args ) = @_;
 715
 716     my $appclass = ref($c) || $c;
 717     if( $name ) {
 718         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 719         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 720         return $c->_filter_component( $result[ 0 ], @args );
 721     }
 722
 723     if (ref $c) {
 724         return $c->stash->{current_view_instance}
 725           if $c->stash->{current_view_instance};
 726         return $c->view( $c->stash->{current_view} )
 727           if $c->stash->{current_view};
 728     }
 729     return $c->view( $appclass->config->{default_view} )
 730       if $appclass->config->{default_view};
 731
 732     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 733
 734     if( $rest ) {
 735         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 736         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 737         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 738         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 739         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 740     }
 741
 742     return $c->_filter_component( $comp );
 743 }
 744
 745 =head2 $c->controllers
 746
 747 Returns the available names which can be passed to $c->controller
 748
 749 =cut
 750
 751 sub controllers {
 752     my ( $c ) = @_;
 753     return $c->_comp_names(qw/Controller C/);
 754 }
 755
 756 =head2 $c->models
 757
 758 Returns the available names which can be passed to $c->model
 759
 760 =cut
 761
 762 sub models {
 763     my ( $c ) = @_;
 764     return $c->_comp_names(qw/Model M/);
 765 }
 766
 767
 768 =head2 $c->views
 769
 770 Returns the available names which can be passed to $c->view
 771
 772 =cut
 773
 774 sub views {
 775     my ( $c ) = @_;
 776     return $c->_comp_names(qw/View V/);
 777 }
 778
 779 =head2 $c->comp($name)
 780
 781 =head2 $c->component($name)
 782
 783 Gets a component object by name. This method is not recommended,
 784 unless you want to get a specific component by full
 785 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 786 should be used instead.
 787
 788 If C<$name> is a regexp, a list of components matched against the full
 789 component name will be returned.
 790
 791 If Catalyst can't find a component by name, it will fallback to regex
 792 matching by default. To disable this behaviour set
 793 disable_component_resolution_regex_fallback to a true value.
 794
 795     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 796
 797 =cut
 798
 799 sub component {
 800     my ( $c, $name, @args ) = @_;
 801
 802     if( $name ) {
 803         my $comps = $c->components;
 804
 805         if( !ref $name ) {
 806             # is it the exact name?
 807             return $c->_filter_component( $comps->{ $name }, @args )
 808                        if exists $comps->{ $name };
 809
 810             # perhaps we just omitted "MyApp"?
 811             my $composed = ( ref $c || $c ) . "::${name}";
 812             return $c->_filter_component( $comps->{ $composed }, @args )
 813                        if exists $comps->{ $composed };
 814
 815             # search all of the models, views and controllers
 816             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 817             return $c->_filter_component( $comp, @args ) if $comp;
 818         }
 819
 820         # This is here so $c->comp( '::M::' ) works
 821         my $query = ref $name ? $name : qr{$name}i;
 822
 823         my @result = grep { m{$query} } keys %{ $c->components };
 824         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 825
 826         if( $result[ 0 ] ) {
 827             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 828             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 829             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 830             return $c->_filter_component( $result[ 0 ], @args );
 831         }
 832
 833         # I would expect to return an empty list here, but that breaks back-compat
 834     }
 835
 836     # fallback
 837     return sort keys %{ $c->components };
 838 }
 839
 840 =head2 CLASS DATA AND HELPER CLASSES
 841
 842 =head2 $c->config
 843
 844 Returns or takes a hashref containing the application's configuration.
 845
 846     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 847
 848 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 849 like C<myapp.conf> in your applications home directory. See
 850 L<Catalyst::Plugin::ConfigLoader>.
 851
 852 =head3 Cascading configuration
 853
 854 The config method is present on all Catalyst components, and configuration
 855 will be merged when an application is started. Configuration loaded with
 856 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 857 followed by configuration in your top level C<MyApp> class. These two
 858 configurations are merged, and then configuration data whose hash key matches a
 859 component name is merged with configuration for that component.
 860
 861 The configuration for a component is then passed to the C<new> method when a
 862 component is constructed.
 863
 864 For example:
 865
 866     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 867     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 868
 869 will mean that C<MyApp::Model::Foo> receives the following data when
 870 constructed:
 871
 872     MyApp::Model::Foo->new({
 873         bar => 'baz',
 874         quux => 'frob',
 875         overrides => 'me',
 876     });
 877
 878 =cut
 879
 880 around config => sub {
 881     my $orig = shift;
 882     my $c = shift;
 883
 884     croak('Setting config after setup has been run is not allowed.')
 885         if ( @_ and $c->setup_finished );
 886
 887     $c->$orig(@_);
 888 };
 889
 890 =head2 $c->log
 891
 892 Returns the logging object instance. Unless it is already set, Catalyst
 893 sets this up with a L<Catalyst::Log> object. To use your own log class,
 894 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 895 C<< __PACKAGE__->setup >>.
 896
 897  __PACKAGE__->log( MyLogger->new );
 898  __PACKAGE__->setup;
 899
 900 And later:
 901
 902     $c->log->info( 'Now logging with my own logger!' );
 903
 904 Your log class should implement the methods described in
 905 L<Catalyst::Log>.
 906
 907
 908 =head2 $c->debug
 909
 910 Returns 1 if debug mode is enabled, 0 otherwise.
 911
 912 You can enable debug mode in several ways:
 913
 914 =over
 915
 916 =item By calling myapp_server.pl with the -d flag
 917
 918 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 919
 920 =item The -Debug option in your MyApp.pm
 921
 922 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 923
 924 =back
 925
 926 Calling C<< $c->debug(1) >> has no effect.
 927
 928 =cut
 929
 930 sub debug { 0 }
 931
 932 =head2 $c->dispatcher
 933
 934 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 935
 936 =head2 $c->engine
 937
 938 Returns the engine instance. See L<Catalyst::Engine>.
 939
 940
 941 =head2 UTILITY METHODS
 942
 943 =head2 $c->path_to(@path)
 944
 945 Merges C<@path> with C<< $c->config->{home} >> and returns a
 946 L<Path::Class::Dir> object. Note you can usually use this object as
 947 a filename, but sometimes you will have to explicitly stringify it
 948 yourself by calling the C<< ->stringify >> method.
 949
 950 For example:
 951
 952     $c->path_to( 'db', 'sqlite.db' );
 953
 954 =cut
 955
 956 sub path_to {
 957     my ( $c, @path ) = @_;
 958     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 959     if ( -d $path ) { return $path }
 960     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 961 }
 962
 963 =head2 $c->plugin( $name, $class, @args )
 964
 965 Helper method for plugins. It creates a class data accessor/mutator and
 966 loads and instantiates the given class.
 967
 968     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 969
 970     $c->prototype->define_javascript_functions;
 971
 972 B<Note:> This method of adding plugins is deprecated. The ability
 973 to add plugins like this B<will be removed> in a Catalyst 5.81.
 974 Please do not use this functionality in new code.
 975
 976 =cut
 977
 978 sub plugin {
 979     my ( $class, $name, $plugin, @args ) = @_;
 980
 981     # See block comment in t/unit_core_plugin.t
 982     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 983
 984     $class->_register_plugin( $plugin, 1 );
 985
 986     eval { $plugin->import };
 987     $class->mk_classdata($name);
 988     my $obj;
 989     eval { $obj = $plugin->new(@args) };
 990
 991     if ($@) {
 992         Catalyst::Exception->throw( message =>
 993               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 994     }
 995
 996     $class->$name($obj);
 997     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 998       if $class->debug;
 999 }
1000
1001 =head2 MyApp->setup
1002
1003 Initializes the dispatcher and engine, loads any plugins, and loads the
1004 model, view, and controller components. You may also specify an array
1005 of plugins to load here, if you choose to not load them in the C<use
1006 Catalyst> line.
1007
1008     MyApp->setup;
1009     MyApp->setup( qw/-Debug/ );
1010
1011 =cut
1012
1013 sub setup {
1014     my ( $class, @arguments ) = @_;
1015     croak('Running setup more than once')
1016         if ( $class->setup_finished );
1017
1018     unless ( $class->isa('Catalyst') ) {
1019
1020         Catalyst::Exception->throw(
1021             message => qq/'$class' does not inherit from Catalyst/ );
1022     }
1023
1024     if ( $class->arguments ) {
1025         @arguments = ( @arguments, @{ $class->arguments } );
1026     }
1027
1028     # Process options
1029     my $flags = {};
1030
1031     foreach (@arguments) {
1032
1033         if (/^-Debug$/) {
1034             $flags->{log} =
1035               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1036         }
1037         elsif (/^-(\w+)=?(.*)$/) {
1038             $flags->{ lc $1 } = $2;
1039         }
1040         else {
1041             push @{ $flags->{plugins} }, $_;
1042         }
1043     }
1044
1045     $class->setup_home( delete $flags->{home} );
1046
1047     $class->setup_log( delete $flags->{log} );
1048     $class->setup_plugins( delete $flags->{plugins} );
1049     $class->setup_dispatcher( delete $flags->{dispatcher} );
1050     $class->setup_engine( delete $flags->{engine} );
1051     $class->setup_stats( delete $flags->{stats} );
1052
1053     for my $flag ( sort keys %{$flags} ) {
1054
1055         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1056             &$code( $class, delete $flags->{$flag} );
1057         }
1058         else {
1059             $class->log->warn(qq/Unknown flag "$flag"/);
1060         }
1061     }
1062
1063     eval { require Catalyst::Devel; };
1064     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1065         $class->log->warn(<<"EOF");
1066 You are running an old script!
1067
1068   Please update by running (this will overwrite existing files):
1069     catalyst.pl -force -scripts $class
1070
1071   or (this will not overwrite existing files):
1072     catalyst.pl -scripts $class
1073
1074 EOF
1075     }
1076
1077     if ( $class->debug ) {
1078         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1079
1080         if (@plugins) {
1081             my $column_width = Catalyst::Utils::term_width() - 6;
1082             my $t = Text::SimpleTable->new($column_width);
1083             $t->row($_) for @plugins;
1084             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1085         }
1086
1087         my $dispatcher = $class->dispatcher;
1088         my $engine     = $class->engine;
1089         my $home       = $class->config->{home};
1090
1091         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1092         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1093
1094         $home
1095           ? ( -d $home )
1096           ? $class->log->debug(qq/Found home "$home"/)
1097           : $class->log->debug(qq/Home "$home" doesn't exist/)
1098           : $class->log->debug(q/Couldn't find home/);
1099     }
1100
1101     # Call plugins setup, this is stupid and evil.
1102     # Also screws C3 badly on 5.10, hack to avoid.
1103     {
1104         no warnings qw/redefine/;
1105         local *setup = sub { };
1106         $class->setup unless $Catalyst::__AM_RESTARTING;
1107     }
1108
1109     # Initialize our data structure
1110     $class->components( {} );
1111
1112     $class->setup_components;
1113
1114     if ( $class->debug ) {
1115         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1116         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1117         for my $comp ( sort keys %{ $class->components } ) {
1118             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1119             $t->row( $comp, $type );
1120         }
1121         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1122           if ( keys %{ $class->components } );
1123     }
1124
1125     # Add our self to components, since we are also a component
1126     if( $class->isa('Catalyst::Controller') ){
1127       $class->components->{$class} = $class;
1128     }
1129
1130     $class->setup_actions;
1131
1132     if ( $class->debug ) {
1133         my $name = $class->config->{name} || 'Application';
1134         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1135     }
1136
1137     # Make sure that the application class becomes immutable at this point,
1138     B::Hooks::EndOfScope::on_scope_end {
1139         return if $@;
1140         my $meta = Class::MOP::get_metaclass_by_name($class);
1141         if (
1142             $meta->is_immutable
1143             && ! { $meta->immutable_options }->{replace_constructor}
1144             && (
1145                    $class->isa('Class::Accessor::Fast')
1146                 || $class->isa('Class::Accessor')
1147             )
1148         ) {
1149             warn "You made your application class ($class) immutable, "
1150                 . "but did not inline the\nconstructor. "
1151                 . "This will break catalyst, as your app \@ISA "
1152                 . "Class::Accessor(::Fast)?\nPlease pass "
1153                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1154         }
1155         $meta->make_immutable(
1156             replace_constructor => 1,
1157         ) unless $meta->is_immutable;
1158     };
1159
1160     if ($class->config->{case_sensitive}) {
1161         $class->log->warn($class . "->config->{case_sensitive} is set.");
1162         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1163     }
1164
1165     $class->setup_finalize;
1166     # Should be the last thing we do so that user things hooking
1167     # setup_finalize can log..
1168     $class->log->_flush() if $class->log->can('_flush');
1169     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1170 }
1171
1172
1173 =head2 $app->setup_finalize
1174
1175 A hook to attach modifiers to.
1176 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1177 Also better than C< setup_finished(); >, as that is a getter method.
1178
1179     sub setup_finalize {
1180
1181         my $app = shift;
1182
1183         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1184
1185         $app->next::method(@_);
1186
1187
1188     }
1189
1190 =cut
1191
1192 sub setup_finalize {
1193     my ($class) = @_;
1194     $class->setup_finished(1);
1195 }
1196
1197 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1198
1199 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1200
1201 Constructs an absolute L<URI> object based on the application root, the
1202 provided path, and the additional arguments and query parameters provided.
1203 When used as a string, provides a textual URI.
1204
1205 If no arguments are provided, the URI for the current action is returned.
1206 To return the current action and also provide @args, use
1207 C<< $c->uri_for( $c->action, @args ) >>.
1208
1209 If the first argument is a string, it is taken as a public URI path relative
1210 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1211 relative to the application root (if it does). It is then merged with
1212 C<< $c->request->base >>; any C<@args> are appended as additional path
1213 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1214
1215 If the first argument is a L<Catalyst::Action> it represents an action which
1216 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1217 optional C<\@captures> argument (an arrayref) allows passing the captured
1218 variables that are needed to fill in the paths of Chained and Regex actions;
1219 once the path is resolved, C<uri_for> continues as though a path was
1220 provided, appending any arguments or parameters and creating an absolute
1221 URI.
1222
1223 The captures for the current request can be found in
1224 C<< $c->request->captures >>, and actions can be resolved using
1225 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1226 path, use C<< $c->uri_for_action >> instead.
1227
1228   # Equivalent to $c->req->uri
1229   $c->uri_for($c->action, $c->req->captures,
1230       @{ $c->req->args }, $c->req->params);
1231
1232   # For the Foo action in the Bar controller
1233   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1234
1235   # Path to a static resource
1236   $c->uri_for('/static/images/logo.png');
1237
1238 =cut
1239
1240 sub uri_for {
1241     my ( $c, $path, @args ) = @_;
1242
1243     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1244         $path = $path->path_prefix;
1245         $path =~ s{/+\z}{};
1246         $path .= '/';
1247     }
1248
1249     if ( blessed($path) ) { # action object
1250         my $captures = [ map { s|/|%2F|; $_; }
1251                         ( scalar @args && ref $args[0] eq 'ARRAY'
1252                          ? @{ shift(@args) }
1253                          : ()) ];
1254         my $action = $path;
1255         $path = $c->dispatcher->uri_for_action($action, $captures);
1256         if (not defined $path) {
1257             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1258                 if $c->debug;
1259             return undef;
1260         }
1261         $path = '/' if $path eq '';
1262     }
1263
1264     undef($path) if (defined $path && $path eq '');
1265
1266     my $params =
1267       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1268
1269     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1270     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1271     s|/|%2F| for @args;
1272
1273     unshift(@args, $path);
1274
1275     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1276         my $namespace = $c->namespace;
1277         if (defined $path) { # cheesy hack to handle path '../foo'
1278            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1279         }
1280         unshift(@args, $namespace || '');
1281     }
1282
1283     # join args with '/', or a blank string
1284     my $args = join('/', grep { defined($_) } @args);
1285     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1286     $args =~ s!^/+!!;
1287     my $base = $c->req->base;
1288     my $class = ref($base);
1289     $base =~ s{(?<!/)$}{/};
1290
1291     my $query = '';
1292
1293     if (my @keys = keys %$params) {
1294       # somewhat lifted from URI::_query's query_form
1295       $query = '?'.join('&', map {
1296           my $val = $params->{$_};
1297           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1298           s/ /+/g;
1299           my $key = $_;
1300           $val = '' unless defined $val;
1301           (map {
1302               my $param = "$_";
1303               utf8::encode( $param ) if utf8::is_utf8($param);
1304               # using the URI::Escape pattern here so utf8 chars survive
1305               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1306               $param =~ s/ /+/g;
1307               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1308       } @keys);
1309     }
1310
1311     my $res = bless(\"${base}${args}${query}", $class);
1312     $res;
1313 }
1314
1315 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1316
1317 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1318
1319 =over
1320
1321 =item $path
1322
1323 A private path to the Catalyst action you want to create a URI for.
1324
1325 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1326 >> and passing the resulting C<$action> and the remaining arguments to C<<
1327 $c->uri_for >>.
1328
1329 You can also pass in a Catalyst::Action object, in which case it is passed to
1330 C<< $c->uri_for >>.
1331
1332 =back
1333
1334 =cut
1335
1336 sub uri_for_action {
1337     my ( $c, $path, @args ) = @_;
1338     my $action = blessed($path)
1339       ? $path
1340       : $c->dispatcher->get_action_by_path($path);
1341     unless (defined $action) {
1342       croak "Can't find action for path '$path'";
1343     }
1344     return $c->uri_for( $action, @args );
1345 }
1346
1347 =head2 $c->welcome_message
1348
1349 Returns the Catalyst welcome HTML page.
1350
1351 =cut
1352
1353 sub welcome_message {
1354     my $c      = shift;
1355     my $name   = $c->config->{name};
1356     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1357     my $prefix = Catalyst::Utils::appprefix( ref $c );
1358     $c->response->content_type('text/html; charset=utf-8');
1359     return <<"EOF";
1360 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1361     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1362 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1363     <head>
1364     <meta http-equiv="Content-Language" content="en" />
1365     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1366         <title>$name on Catalyst $VERSION</title>
1367         <style type="text/css">
1368             body {
1369                 color: #000;
1370                 background-color: #eee;
1371             }
1372             div#content {
1373                 width: 640px;
1374                 margin-left: auto;
1375                 margin-right: auto;
1376                 margin-top: 10px;
1377                 margin-bottom: 10px;
1378                 text-align: left;
1379                 background-color: #ccc;
1380                 border: 1px solid #aaa;
1381             }
1382             p, h1, h2 {
1383                 margin-left: 20px;
1384                 margin-right: 20px;
1385                 font-family: verdana, tahoma, sans-serif;
1386             }
1387             a {
1388                 font-family: verdana, tahoma, sans-serif;
1389             }
1390             :link, :visited {
1391                     text-decoration: none;
1392                     color: #b00;
1393                     border-bottom: 1px dotted #bbb;
1394             }
1395             :link:hover, :visited:hover {
1396                     color: #555;
1397             }
1398             div#topbar {
1399                 margin: 0px;
1400             }
1401             pre {
1402                 margin: 10px;
1403                 padding: 8px;
1404             }
1405             div#answers {
1406                 padding: 8px;
1407                 margin: 10px;
1408                 background-color: #fff;
1409                 border: 1px solid #aaa;
1410             }
1411             h1 {
1412                 font-size: 0.9em;
1413                 font-weight: normal;
1414                 text-align: center;
1415             }
1416             h2 {
1417                 font-size: 1.0em;
1418             }
1419             p {
1420                 font-size: 0.9em;
1421             }
1422             p img {
1423                 float: right;
1424                 margin-left: 10px;
1425             }
1426             span#appname {
1427                 font-weight: bold;
1428                 font-size: 1.6em;
1429             }
1430         </style>
1431     </head>
1432     <body>
1433         <div id="content">
1434             <div id="topbar">
1435                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1436                     $VERSION</h1>
1437              </div>
1438              <div id="answers">
1439                  <p>
1440                  <img src="$logo" alt="Catalyst Logo" />
1441                  </p>
1442                  <p>Welcome to the  world of Catalyst.
1443                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1444                     framework will make web development something you had
1445                     never expected it to be: Fun, rewarding, and quick.</p>
1446                  <h2>What to do now?</h2>
1447                  <p>That really depends  on what <b>you</b> want to do.
1448                     We do, however, provide you with a few starting points.</p>
1449                  <p>If you want to jump right into web development with Catalyst
1450                     you might want to start with a tutorial.</p>
1451 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1452 </pre>
1453 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1454 <pre>
1455 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1456 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1457 </code></pre>
1458                  <h2>What to do next?</h2>
1459                  <p>Next it's time to write an actual application. Use the
1460                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1461                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1462                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1463                     they can save you a lot of work.</p>
1464                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1465                     <p>Also, be sure to check out the vast and growing
1466                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1467                     you are likely to find what you need there.
1468                     </p>
1469
1470                  <h2>Need help?</h2>
1471                  <p>Catalyst has a very active community. Here are the main places to
1472                     get in touch with us.</p>
1473                  <ul>
1474                      <li>
1475                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1476                      </li>
1477                      <li>
1478                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1479                      </li>
1480                      <li>
1481                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1482                      </li>
1483                  </ul>
1484                  <h2>In conclusion</h2>
1485                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1486                     as we enjoyed making it. Please contact us if you have ideas
1487                     for improvement or other feedback.</p>
1488              </div>
1489          </div>
1490     </body>
1491 </html>
1492 EOF
1493 }
1494
1495 =head1 INTERNAL METHODS
1496
1497 These methods are not meant to be used by end users.
1498
1499 =head2 $c->components
1500
1501 Returns a hash of components.
1502
1503 =head2 $c->context_class
1504
1505 Returns or sets the context class.
1506
1507 =head2 $c->counter
1508
1509 Returns a hashref containing coderefs and execution counts (needed for
1510 deep recursion detection).
1511
1512 =head2 $c->depth
1513
1514 Returns the number of actions on the current internal execution stack.
1515
1516 =head2 $c->dispatch
1517
1518 Dispatches a request to actions.
1519
1520 =cut
1521
1522 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1523
1524 =head2 $c->dispatcher_class
1525
1526 Returns or sets the dispatcher class.
1527
1528 =head2 $c->dump_these
1529
1530 Returns a list of 2-element array references (name, structure) pairs
1531 that will be dumped on the error page in debug mode.
1532
1533 =cut
1534
1535 sub dump_these {
1536     my $c = shift;
1537     [ Request => $c->req ],
1538     [ Response => $c->res ],
1539     [ Stash => $c->stash ],
1540     [ Config => $c->config ];
1541 }
1542
1543 =head2 $c->engine_class
1544
1545 Returns or sets the engine class.
1546
1547 =head2 $c->execute( $class, $coderef )
1548
1549 Execute a coderef in given class and catch exceptions. Errors are available
1550 via $c->error.
1551
1552 =cut
1553
1554 sub execute {
1555     my ( $c, $class, $code ) = @_;
1556     $class = $c->component($class) || $class;
1557     $c->state(0);
1558
1559     if ( $c->depth >= $RECURSION ) {
1560         my $action = $code->reverse();
1561         $action = "/$action" unless $action =~ /->/;
1562         my $error = qq/Deep recursion detected calling "${action}"/;
1563         $c->log->error($error);
1564         $c->error($error);
1565         $c->state(0);
1566         return $c->state;
1567     }
1568
1569     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1570
1571     push( @{ $c->stack }, $code );
1572
1573     no warnings 'recursion';
1574     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1575
1576     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1577
1578     my $last = pop( @{ $c->stack } );
1579
1580     if ( my $error = $@ ) {
1581         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1582             $error->rethrow if $c->depth > 1;
1583         }
1584         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1585             $error->rethrow if $c->depth > 0;
1586         }
1587         else {
1588             unless ( ref $error ) {
1589                 no warnings 'uninitialized';
1590                 chomp $error;
1591                 my $class = $last->class;
1592                 my $name  = $last->name;
1593                 $error = qq/Caught exception in $class->$name "$error"/;
1594             }
1595             $c->error($error);
1596             $c->state(0);
1597         }
1598     }
1599     return $c->state;
1600 }
1601
1602 sub _stats_start_execute {
1603     my ( $c, $code ) = @_;
1604     my $appclass = ref($c) || $c;
1605     return if ( ( $code->name =~ /^_.*/ )
1606         && ( !$appclass->config->{show_internal_actions} ) );
1607
1608     my $action_name = $code->reverse();
1609     $c->counter->{$action_name}++;
1610
1611     my $action = $action_name;
1612     $action = "/$action" unless $action =~ /->/;
1613
1614     # determine if the call was the result of a forward
1615     # this is done by walking up the call stack and looking for a calling
1616     # sub of Catalyst::forward before the eval
1617     my $callsub = q{};
1618     for my $index ( 2 .. 11 ) {
1619         last
1620         if ( ( caller($index) )[0] eq 'Catalyst'
1621             && ( caller($index) )[3] eq '(eval)' );
1622
1623         if ( ( caller($index) )[3] =~ /forward$/ ) {
1624             $callsub = ( caller($index) )[3];
1625             $action  = "-> $action";
1626             last;
1627         }
1628     }
1629
1630     my $uid = $action_name . $c->counter->{$action_name};
1631
1632     # is this a root-level call or a forwarded call?
1633     if ( $callsub =~ /forward$/ ) {
1634         my $parent = $c->stack->[-1];
1635
1636         # forward, locate the caller
1637         if ( exists $c->counter->{"$parent"} ) {
1638             $c->stats->profile(
1639                 begin  => $action,
1640                 parent => "$parent" . $c->counter->{"$parent"},
1641                 uid    => $uid,
1642             );
1643         }
1644         else {
1645
1646             # forward with no caller may come from a plugin
1647             $c->stats->profile(
1648                 begin => $action,
1649                 uid   => $uid,
1650             );
1651         }
1652     }
1653     else {
1654
1655         # root-level call
1656         $c->stats->profile(
1657             begin => $action,
1658             uid   => $uid,
1659         );
1660     }
1661     return $action;
1662
1663 }
1664
1665 sub _stats_finish_execute {
1666     my ( $c, $info ) = @_;
1667     $c->stats->profile( end => $info );
1668 }
1669
1670 =head2 $c->finalize
1671
1672 Finalizes the request.
1673
1674 =cut
1675
1676 sub finalize {
1677     my $c = shift;
1678
1679     for my $error ( @{ $c->error } ) {
1680         $c->log->error($error);
1681     }
1682
1683     # Allow engine to handle finalize flow (for POE)
1684     my $engine = $c->engine;
1685     if ( my $code = $engine->can('finalize') ) {
1686         $engine->$code($c);
1687     }
1688     else {
1689
1690         $c->finalize_uploads;
1691
1692         # Error
1693         if ( $#{ $c->error } >= 0 ) {
1694             $c->finalize_error;
1695         }
1696
1697         $c->finalize_headers;
1698
1699         # HEAD request
1700         if ( $c->request->method eq 'HEAD' ) {
1701             $c->response->body('');
1702         }
1703
1704         $c->finalize_body;
1705     }
1706
1707     if ($c->use_stats) {
1708         my $elapsed = sprintf '%f', $c->stats->elapsed;
1709         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1710         $c->log->info(
1711             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1712     }
1713
1714     return $c->response->status;
1715 }
1716
1717 =head2 $c->finalize_body
1718
1719 Finalizes body.
1720
1721 =cut
1722
1723 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1724
1725 =head2 $c->finalize_cookies
1726
1727 Finalizes cookies.
1728
1729 =cut
1730
1731 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1732
1733 =head2 $c->finalize_error
1734
1735 Finalizes error.
1736
1737 =cut
1738
1739 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1740
1741 =head2 $c->finalize_headers
1742
1743 Finalizes headers.
1744
1745 =cut
1746
1747 sub finalize_headers {
1748     my $c = shift;
1749
1750     my $response = $c->response; #accessor calls can add up?
1751
1752     # Check if we already finalized headers
1753     return if $response->finalized_headers;
1754
1755     # Handle redirects
1756     if ( my $location = $response->redirect ) {
1757         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1758         $response->header( Location => $location );
1759
1760         if ( !$response->has_body ) {
1761             # Add a default body if none is already present
1762             $response->body(
1763                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1764             );
1765         }
1766     }
1767
1768     # Content-Length
1769     if ( $response->body && !$response->content_length ) {
1770
1771         # get the length from a filehandle
1772         if ( blessed( $response->body ) && $response->body->can('read') )
1773         {
1774             my $stat = stat $response->body;
1775             if ( $stat && $stat->size > 0 ) {
1776                 $response->content_length( $stat->size );
1777             }
1778             else {
1779                 $c->log->warn('Serving filehandle without a content-length');
1780             }
1781         }
1782         else {
1783             # everything should be bytes at this point, but just in case
1784             $response->content_length( length( $response->body ) );
1785         }
1786     }
1787
1788     # Errors
1789     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1790         $response->headers->remove_header("Content-Length");
1791         $response->body('');
1792     }
1793
1794     $c->finalize_cookies;
1795
1796     $c->engine->finalize_headers( $c, @_ );
1797
1798     # Done
1799     $response->finalized_headers(1);
1800 }
1801
1802 =head2 $c->finalize_output
1803
1804 An alias for finalize_body.
1805
1806 =head2 $c->finalize_read
1807
1808 Finalizes the input after reading is complete.
1809
1810 =cut
1811
1812 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1813
1814 =head2 $c->finalize_uploads
1815
1816 Finalizes uploads. Cleans up any temporary files.
1817
1818 =cut
1819
1820 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1821
1822 =head2 $c->get_action( $action, $namespace )
1823
1824 Gets an action in a given namespace.
1825
1826 =cut
1827
1828 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1829
1830 =head2 $c->get_actions( $action, $namespace )
1831
1832 Gets all actions of a given name in a namespace and all parent
1833 namespaces.
1834
1835 =cut
1836
1837 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1838
1839 =head2 $c->handle_request( $class, @arguments )
1840
1841 Called to handle each HTTP request.
1842
1843 =cut
1844
1845 sub handle_request {
1846     my ( $class, @arguments ) = @_;
1847
1848     # Always expect worst case!
1849     my $status = -1;
1850     eval {
1851         if ($class->debug) {
1852             my $secs = time - $START || 1;
1853             my $av = sprintf '%.3f', $COUNT / $secs;
1854             my $time = localtime time;
1855             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1856         }
1857
1858         my $c = $class->prepare(@arguments);
1859         $c->dispatch;
1860         $status = $c->finalize;
1861     };
1862
1863     if ( my $error = $@ ) {
1864         chomp $error;
1865         $class->log->error(qq/Caught exception in engine "$error"/);
1866     }
1867
1868     $COUNT++;
1869
1870     if(my $coderef = $class->log->can('_flush')){
1871         $class->log->$coderef();
1872     }
1873     return $status;
1874 }
1875
1876 =head2 $c->prepare( @arguments )
1877
1878 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1879 etc.).
1880
1881 =cut
1882
1883 sub prepare {
1884     my ( $class, @arguments ) = @_;
1885
1886     # XXX
1887     # After the app/ctxt split, this should become an attribute based on something passed
1888     # into the application.
1889     $class->context_class( ref $class || $class ) unless $class->context_class;
1890
1891     my $c = $class->context_class->new({});
1892
1893     # For on-demand data
1894     $c->request->_context($c);
1895     $c->response->_context($c);
1896
1897     #surely this is not the most efficient way to do things...
1898     $c->stats($class->stats_class->new)->enable($c->use_stats);
1899     if ( $c->debug ) {
1900         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1901     }
1902
1903     # Allow engine to direct the prepare flow (for POE)
1904     if ( my $prepare = $c->engine->can('prepare') ) {
1905         $c->engine->$prepare( $c, @arguments );
1906     }
1907     else {
1908         $c->prepare_request(@arguments);
1909         $c->prepare_connection;
1910         $c->prepare_query_parameters;
1911         $c->prepare_headers;
1912         $c->prepare_cookies;
1913         $c->prepare_path;
1914
1915         # Prepare the body for reading, either by prepare_body
1916         # or the user, if they are using $c->read
1917         $c->prepare_read;
1918
1919         # Parse the body unless the user wants it on-demand
1920         unless ( ref($c)->config->{parse_on_demand} ) {
1921             $c->prepare_body;
1922         }
1923     }
1924
1925     my $method  = $c->req->method  || '';
1926     my $path    = $c->req->path;
1927     $path       = '/' unless length $path;
1928     my $address = $c->req->address || '';
1929
1930     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1931       if $c->debug;
1932
1933     $c->prepare_action;
1934
1935     return $c;
1936 }
1937
1938 =head2 $c->prepare_action
1939
1940 Prepares action. See L<Catalyst::Dispatcher>.
1941
1942 =cut
1943
1944 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1945
1946 =head2 $c->prepare_body
1947
1948 Prepares message body.
1949
1950 =cut
1951
1952 sub prepare_body {
1953     my $c = shift;
1954
1955     return if $c->request->_has_body;
1956
1957     # Initialize on-demand data
1958     $c->engine->prepare_body( $c, @_ );
1959     $c->prepare_parameters;
1960     $c->prepare_uploads;
1961
1962     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1963         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1964         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1965             my $param = $c->req->body_parameters->{$key};
1966             my $value = defined($param) ? $param : '';
1967             $t->row( $key,
1968                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1969         }
1970         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1971     }
1972 }
1973
1974 =head2 $c->prepare_body_chunk( $chunk )
1975
1976 Prepares a chunk of data before sending it to L<HTTP::Body>.
1977
1978 See L<Catalyst::Engine>.
1979
1980 =cut
1981
1982 sub prepare_body_chunk {
1983     my $c = shift;
1984     $c->engine->prepare_body_chunk( $c, @_ );
1985 }
1986
1987 =head2 $c->prepare_body_parameters
1988
1989 Prepares body parameters.
1990
1991 =cut
1992
1993 sub prepare_body_parameters {
1994     my $c = shift;
1995     $c->engine->prepare_body_parameters( $c, @_ );
1996 }
1997
1998 =head2 $c->prepare_connection
1999
2000 Prepares connection.
2001
2002 =cut
2003
2004 sub prepare_connection {
2005     my $c = shift;
2006     $c->engine->prepare_connection( $c, @_ );
2007 }
2008
2009 =head2 $c->prepare_cookies
2010
2011 Prepares cookies.
2012
2013 =cut
2014
2015 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2016
2017 =head2 $c->prepare_headers
2018
2019 Prepares headers.
2020
2021 =cut
2022
2023 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2024
2025 =head2 $c->prepare_parameters
2026
2027 Prepares parameters.
2028
2029 =cut
2030
2031 sub prepare_parameters {
2032     my $c = shift;
2033     $c->prepare_body_parameters;
2034     $c->engine->prepare_parameters( $c, @_ );
2035 }
2036
2037 =head2 $c->prepare_path
2038
2039 Prepares path and base.
2040
2041 =cut
2042
2043 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2044
2045 =head2 $c->prepare_query_parameters
2046
2047 Prepares query parameters.
2048
2049 =cut
2050
2051 sub prepare_query_parameters {
2052     my $c = shift;
2053
2054     $c->engine->prepare_query_parameters( $c, @_ );
2055
2056     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
2057         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
2058         for my $key ( sort keys %{ $c->req->query_parameters } ) {
2059             my $param = $c->req->query_parameters->{$key};
2060             my $value = defined($param) ? $param : '';
2061             $t->row( $key,
2062                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2063         }
2064         $c->log->debug( "Query Parameters are:\n" . $t->draw );
2065     }
2066 }
2067
2068 =head2 $c->prepare_read
2069
2070 Prepares the input for reading.
2071
2072 =cut
2073
2074 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2075
2076 =head2 $c->prepare_request
2077
2078 Prepares the engine request.
2079
2080 =cut
2081
2082 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2083
2084 =head2 $c->prepare_uploads
2085
2086 Prepares uploads.
2087
2088 =cut
2089
2090 sub prepare_uploads {
2091     my $c = shift;
2092
2093     $c->engine->prepare_uploads( $c, @_ );
2094
2095     if ( $c->debug && keys %{ $c->request->uploads } ) {
2096         my $t = Text::SimpleTable->new(
2097             [ 12, 'Parameter' ],
2098             [ 26, 'Filename' ],
2099             [ 18, 'Type' ],
2100             [ 9,  'Size' ]
2101         );
2102         for my $key ( sort keys %{ $c->request->uploads } ) {
2103             my $upload = $c->request->uploads->{$key};
2104             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2105                 $t->row( $key, $u->filename, $u->type, $u->size );
2106             }
2107         }
2108         $c->log->debug( "File Uploads are:\n" . $t->draw );
2109     }
2110 }
2111
2112 =head2 $c->prepare_write
2113
2114 Prepares the output for writing.
2115
2116 =cut
2117
2118 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2119
2120 =head2 $c->request_class
2121
2122 Returns or sets the request class.
2123
2124 =head2 $c->response_class
2125
2126 Returns or sets the response class.
2127
2128 =head2 $c->read( [$maxlength] )
2129
2130 Reads a chunk of data from the request body. This method is designed to
2131 be used in a while loop, reading C<$maxlength> bytes on every call.
2132 C<$maxlength> defaults to the size of the request if not specified.
2133
2134 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2135 directly.
2136
2137 Warning: If you use read(), Catalyst will not process the body,
2138 so you will not be able to access POST parameters or file uploads via
2139 $c->request.  You must handle all body parsing yourself.
2140
2141 =cut
2142
2143 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2144
2145 =head2 $c->run
2146
2147 Starts the engine.
2148
2149 =cut
2150
2151 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2152
2153 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2154
2155 Sets an action in a given namespace.
2156
2157 =cut
2158
2159 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2160
2161 =head2 $c->setup_actions($component)
2162
2163 Sets up actions for a component.
2164
2165 =cut
2166
2167 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2168
2169 =head2 $c->setup_components
2170
2171 This method is called internally to set up the application's components.
2172
2173 It finds modules by calling the L<locate_components> method, expands them to
2174 package names with the L<expand_component_module> method, and then installs
2175 each component into the application.
2176
2177 The C<setup_components> config option is passed to both of the above methods.
2178
2179 Installation of each component is performed by the L<setup_component> method,
2180 below.
2181
2182 =cut
2183
2184 sub setup_components {
2185     my $class = shift;
2186
2187     my $config  = $class->config->{ setup_components };
2188
2189     my @comps = sort { length $a <=> length $b }
2190                 $class->locate_components($config);
2191     my %comps = map { $_ => 1 } @comps;
2192
2193     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2194     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2195         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2196     ) if $deprecatedcatalyst_component_names;
2197
2198     for my $component ( @comps ) {
2199
2200         # We pass ignore_loaded here so that overlay files for (e.g.)
2201         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2202         # we know M::P::O found a file on disk so this is safe
2203
2204         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2205
2206         # Needs to be done as soon as the component is loaded, as loading a sub-component
2207         # (next time round the loop) can cause us to get the wrong metaclass..
2208         $class->_controller_init_base_classes($component);
2209     }
2210
2211     for my $component (@comps) {
2212         $class->components->{ $component } = $class->setup_component($component);
2213         for my $component ($class->expand_component_module( $component, $config )) {
2214             next if $comps{$component};
2215             $class->_controller_init_base_classes($component); # Also cover inner packages
2216             $class->components->{ $component } = $class->setup_component($component);
2217         }
2218     }
2219 }
2220
2221 =head2 $c->locate_components( $setup_component_config )
2222
2223 This method is meant to provide a list of component modules that should be
2224 setup for the application.  By default, it will use L<Module::Pluggable>.
2225
2226 Specify a C<setup_components> config option to pass additional options directly
2227 to L<Module::Pluggable>. To add additional search paths, specify a key named
2228 C<search_extra> as an array reference. Items in the array beginning with C<::>
2229 will have the application class name prepended to them.
2230
2231 =cut
2232
2233 sub locate_components {
2234     my $class  = shift;
2235     my $config = shift;
2236
2237     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2238     my $extra   = delete $config->{ search_extra } || [];
2239
2240     push @paths, @$extra;
2241
2242     my $locator = Module::Pluggable::Object->new(
2243         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2244         %$config
2245     );
2246
2247     my @comps = $locator->plugins;
2248
2249     return @comps;
2250 }
2251
2252 =head2 $c->expand_component_module( $component, $setup_component_config )
2253
2254 Components found by C<locate_components> will be passed to this method, which
2255 is expected to return a list of component (package) names to be set up.
2256
2257 =cut
2258
2259 sub expand_component_module {
2260     my ($class, $module) = @_;
2261     return Devel::InnerPackage::list_packages( $module );
2262 }
2263
2264 =head2 $c->setup_component
2265
2266 =cut
2267
2268 # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2269 #         nearest to Catalyst::Controller first, no matter what order stuff happens
2270 #         to be loaded. There are TODO tests in Moose for this, see
2271 #         f2391d17574eff81d911b97be15ea51080500003
2272 sub _controller_init_base_classes {
2273     my ($app_class, $component) = @_;
2274     return unless $component->isa('Catalyst::Controller');
2275     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2276         Moose::Meta::Class->initialize( $class )
2277             unless find_meta($class);
2278     }
2279 }
2280
2281 sub setup_component {
2282     my( $class, $component ) = @_;
2283
2284     unless ( $component->can( 'COMPONENT' ) ) {
2285         return $component;
2286     }
2287
2288     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2289     my $config = $class->config->{ $suffix } || {};
2290     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2291     # methods also pass it. local to avoid pointlessly shitting in config
2292     # for the debug screen, as $component is already the key name.
2293     local $config->{catalyst_component_name} = $component;
2294
2295     my $instance = eval { $component->COMPONENT( $class, $config ); };
2296
2297     if ( my $error = $@ ) {
2298         chomp $error;
2299         Catalyst::Exception->throw(
2300             message => qq/Couldn't instantiate component "$component", "$error"/
2301         );
2302     }
2303
2304     unless (blessed $instance) {
2305         my $metaclass = Moose::Util::find_meta($component);
2306         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2307         my $component_method_from = $method_meta->associated_metaclass->name;
2308         my $value = defined($instance) ? $instance : 'undef';
2309         Catalyst::Exception->throw(
2310             message =>
2311             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2312         );
2313     }
2314     return $instance;
2315 }
2316
2317 =head2 $c->setup_dispatcher
2318
2319 Sets up dispatcher.
2320
2321 =cut
2322
2323 sub setup_dispatcher {
2324     my ( $class, $dispatcher ) = @_;
2325
2326     if ($dispatcher) {
2327         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2328     }
2329
2330     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2331         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2332     }
2333
2334     unless ($dispatcher) {
2335         $dispatcher = $class->dispatcher_class;
2336     }
2337
2338     Class::MOP::load_class($dispatcher);
2339
2340     # dispatcher instance
2341     $class->dispatcher( $dispatcher->new );
2342 }
2343
2344 =head2 $c->setup_engine
2345
2346 Sets up engine.
2347
2348 =cut
2349
2350 sub setup_engine {
2351     my ($class, $engine) = @_;
2352
2353     unless ($engine) {
2354         $engine = $class->engine_class;
2355     }
2356
2357     Class::MOP::load_class($engine);
2358
2359     # check for old engines that are no longer compatible
2360     my $old_engine;
2361     if ( $engine->isa('Catalyst::Engine::Apache')
2362         && !Catalyst::Engine::Apache->VERSION )
2363     {
2364         $old_engine = 1;
2365     }
2366
2367     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2368         && Catalyst::Engine::Server->VERSION le '0.02' )
2369     {
2370         $old_engine = 1;
2371     }
2372
2373     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2374         && $engine->VERSION eq '0.01' )
2375     {
2376         $old_engine = 1;
2377     }
2378
2379     elsif ($engine->isa('Catalyst::Engine::Zeus')
2380         && $engine->VERSION eq '0.01' )
2381     {
2382         $old_engine = 1;
2383     }
2384
2385     if ($old_engine) {
2386         Catalyst::Exception->throw( message =>
2387               qq/Engine "$engine" is not supported by this version of Catalyst/
2388         );
2389     }
2390
2391     # engine instance
2392     $class->engine( $engine->new );
2393 }
2394
2395 =head2 $c->setup_home
2396
2397 Sets up the home directory.
2398
2399 =cut
2400
2401 sub setup_home {
2402     my ( $class, $home ) = @_;
2403
2404     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2405         $home = $env;
2406     }
2407
2408     $home ||= Catalyst::Utils::home($class);
2409
2410     if ($home) {
2411         #I remember recently being scolded for assigning config values like this
2412         $class->config->{home} ||= $home;
2413         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2414     }
2415 }
2416
2417 =head2 $c->setup_log
2418
2419 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2420 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2421 log to.
2422
2423 This method also installs a C<debug> method that returns a true value into the
2424 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2425 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2426
2427 Note that if the log has already been setup, by either a previous call to
2428 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2429 that this method won't actually set up the log object.
2430
2431 =cut
2432
2433 sub setup_log {
2434     my ( $class, $levels ) = @_;
2435
2436     $levels ||= '';
2437     $levels =~ s/^\s+//;
2438     $levels =~ s/\s+$//;
2439     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2440
2441     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2442     if ( defined $env_debug ) {
2443         $levels{debug} = 1 if $env_debug; # Ugly!
2444         delete($levels{debug}) unless $env_debug;
2445     }
2446
2447     unless ( $class->log ) {
2448         $class->log( Catalyst::Log->new(keys %levels) );
2449     }
2450
2451     if ( $levels{debug} ) {
2452         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2453         $class->log->debug('Debug messages enabled');
2454     }
2455 }
2456
2457 =head2 $c->setup_plugins
2458
2459 Sets up plugins.
2460
2461 =cut
2462
2463 =head2 $c->setup_stats
2464
2465 Sets up timing statistics class.
2466
2467 =cut
2468
2469 sub setup_stats {
2470     my ( $class, $stats ) = @_;
2471
2472     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2473
2474     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2475     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2476         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2477         $class->log->debug('Statistics enabled');
2478     }
2479 }
2480
2481
2482 =head2 $c->registered_plugins
2483
2484 Returns a sorted list of the plugins which have either been stated in the
2485 import list or which have been added via C<< MyApp->plugin(@args); >>.
2486
2487 If passed a given plugin name, it will report a boolean value indicating
2488 whether or not that plugin is loaded.  A fully qualified name is required if
2489 the plugin name does not begin with C<Catalyst::Plugin::>.
2490
2491  if ($c->registered_plugins('Some::Plugin')) {
2492      ...
2493  }
2494
2495 =cut
2496
2497 {
2498
2499     sub registered_plugins {
2500         my $proto = shift;
2501         return sort keys %{ $proto->_plugins } unless @_;
2502         my $plugin = shift;
2503         return 1 if exists $proto->_plugins->{$plugin};
2504         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2505     }
2506
2507     sub _register_plugin {
2508         my ( $proto, $plugin, $instant ) = @_;
2509         my $class = ref $proto || $proto;
2510
2511         Class::MOP::load_class( $plugin );
2512         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2513             if $plugin->isa( 'Catalyst::Component' );
2514         $proto->_plugins->{$plugin} = 1;
2515         unless ($instant) {
2516             no strict 'refs';
2517             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2518               my @superclasses = ($plugin, $meta->superclasses );
2519               $meta->superclasses(@superclasses);
2520             } else {
2521               unshift @{"$class\::ISA"}, $plugin;
2522             }
2523         }
2524         return $class;
2525     }
2526
2527     sub setup_plugins {
2528         my ( $class, $plugins ) = @_;
2529
2530         $class->_plugins( {} ) unless $class->_plugins;
2531         $plugins ||= [];
2532
2533         my @plugins = Catalyst::Utils::resolve_namespace($class . '::Plugin', 'Catalyst::Plugin', @$plugins);
2534
2535         for my $plugin ( reverse @plugins ) {
2536             Class::MOP::load_class($plugin);
2537             my $meta = find_meta($plugin);
2538             next if $meta && $meta->isa('Moose::Meta::Role');
2539
2540             $class->_register_plugin($plugin);
2541         }
2542
2543         my @roles =
2544             map { $_->name }
2545             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2546             map { find_meta($_) }
2547             @plugins;
2548
2549         Moose::Util::apply_all_roles(
2550             $class => @roles
2551         ) if @roles;
2552     }
2553 }
2554
2555 =head2 $c->stack
2556
2557 Returns an arrayref of the internal execution stack (actions that are
2558 currently executing).
2559
2560 =head2 $c->stats_class
2561
2562 Returns or sets the stats (timing statistics) class.
2563
2564 =head2 $c->use_stats
2565
2566 Returns 1 when stats collection is enabled.  Stats collection is enabled
2567 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2568 environment variable is set.
2569
2570 Note that this is a static method, not an accessor and should be overridden
2571 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2572
2573 =cut
2574
2575 sub use_stats { 0 }
2576
2577
2578 =head2 $c->write( $data )
2579
2580 Writes $data to the output stream. When using this method directly, you
2581 will need to manually set the C<Content-Length> header to the length of
2582 your output data, if known.
2583
2584 =cut
2585
2586 sub write {
2587     my $c = shift;
2588
2589     # Finalize headers if someone manually writes output
2590     $c->finalize_headers;
2591
2592     return $c->engine->write( $c, @_ );
2593 }
2594
2595 =head2 version
2596
2597 Returns the Catalyst version number. Mostly useful for "powered by"
2598 messages in template systems.
2599
2600 =cut
2601
2602 sub version { return $Catalyst::VERSION }
2603
2604 =head1 CONFIGURATION
2605
2606 There are a number of 'base' config variables which can be set:
2607
2608 =over
2609
2610 =item *
2611
2612 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2613
2614 =item *
2615
2616 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2617
2618 =item *
2619
2620 C<disable_component_resolution_regex_fallback> - Turns
2621 off the deprecated component resolution functionality so
2622 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2623 are called then regex search will not be attempted on string values and
2624 instead C<undef> will be returned.
2625
2626 =item *
2627
2628 C<home> - The application home directory. In an uninstalled application,
2629 this is the top level application directory. In an installed application,
2630 this will be the directory containing C<< MyApp.pm >>.
2631
2632 =item *
2633
2634 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2635
2636 =item *
2637
2638 C<name> - The name of the application in debug messages and the debug and
2639 welcome screens
2640
2641 =item *
2642
2643 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2644 until it is accessed. This allows you to (for example) check authentication (and reject
2645 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2646
2647 =item *
2648
2649 C<root> - The root directory for templates. Usually this is just a
2650 subdirectory of the home directory, but you can set it to change the
2651 templates to a different directory.
2652
2653 =item *
2654
2655 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2656 namespaces from which components will be loaded (and constructed and stored in
2657 C<< $c->components >>).
2658
2659 =item *
2660
2661 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2662 to be shown in hit debug tables in the test server.
2663
2664 =item *
2665
2666 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2667
2668 =back
2669
2670 =head1 INTERNAL ACTIONS
2671
2672 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2673 C<_ACTION>, and C<_END>. These are by default not shown in the private
2674 action table, but you can make them visible with a config parameter.
2675
2676     MyApp->config(show_internal_actions => 1);
2677
2678 =head1 ON-DEMAND PARSER
2679
2680 The request body is usually parsed at the beginning of a request,
2681 but if you want to handle input yourself, you can enable on-demand
2682 parsing with a config parameter.
2683
2684     MyApp->config(parse_on_demand => 1);
2685
2686 =head1 PROXY SUPPORT
2687
2688 Many production servers operate using the common double-server approach,
2689 with a lightweight frontend web server passing requests to a larger
2690 backend server. An application running on the backend server must deal
2691 with two problems: the remote user always appears to be C<127.0.0.1> and
2692 the server's hostname will appear to be C<localhost> regardless of the
2693 virtual host that the user connected through.
2694
2695 Catalyst will automatically detect this situation when you are running
2696 the frontend and backend servers on the same machine. The following
2697 changes are made to the request.
2698
2699     $c->req->address is set to the user's real IP address, as read from
2700     the HTTP X-Forwarded-For header.
2701
2702     The host value for $c->req->base and $c->req->uri is set to the real
2703     host, as read from the HTTP X-Forwarded-Host header.
2704
2705 Additionally, you may be running your backend application on an insecure
2706 connection (port 80) while your frontend proxy is running under SSL.  If there
2707 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2708 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2709 be created properly.
2710
2711 In the case of passing in:
2712
2713     X-Forwarded-Port: 443
2714
2715 All calls to C<uri_for> will result in an https link, as is expected.
2716
2717 Obviously, your web server must support these headers for this to work.
2718
2719 In a more complex server farm environment where you may have your
2720 frontend proxy server(s) on different machines, you will need to set a
2721 configuration option to tell Catalyst to read the proxied data from the
2722 headers.
2723
2724     MyApp->config(using_frontend_proxy => 1);
2725
2726 If you do not wish to use the proxy support at all, you may set:
2727
2728     MyApp->config(ignore_frontend_proxy => 1);
2729
2730 =head1 THREAD SAFETY
2731
2732 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2733 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2734 believe the Catalyst core to be thread-safe.
2735
2736 If you plan to operate in a threaded environment, remember that all other
2737 modules you are using must also be thread-safe. Some modules, most notably
2738 L<DBD::SQLite>, are not thread-safe.
2739
2740 =head1 SUPPORT
2741
2742 IRC:
2743
2744     Join #catalyst on irc.perl.org.
2745
2746 Mailing Lists:
2747
2748     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2749     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2750
2751 Web:
2752
2753     http://catalyst.perl.org
2754
2755 Wiki:
2756
2757     http://dev.catalyst.perl.org
2758
2759 =head1 SEE ALSO
2760
2761 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2762
2763 =head2 L<Catalyst::Manual> - The Catalyst Manual
2764
2765 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2766
2767 =head2 L<Catalyst::Engine> - Core engine
2768
2769 =head2 L<Catalyst::Log> - Log class.
2770
2771 =head2 L<Catalyst::Request> - Request object
2772
2773 =head2 L<Catalyst::Response> - Response object
2774
2775 =head2 L<Catalyst::Test> - The test suite.
2776
2777 =head1 PROJECT FOUNDER
2778
2779 sri: Sebastian Riedel <sri@cpan.org>
2780
2781 =head1 CONTRIBUTORS
2782
2783 abw: Andy Wardley
2784
2785 acme: Leon Brocard <leon@astray.com>
2786
2787 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
2788
2789 Andrew Bramble
2790
2791 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
2792
2793 Andrew Ruthven
2794
2795 andyg: Andy Grundman <andy@hybridized.org>
2796
2797 audreyt: Audrey Tang
2798
2799 bricas: Brian Cassidy <bricas@cpan.org>
2800
2801 Caelum: Rafael Kitover <rkitover@io.com>
2802
2803 chansen: Christian Hansen
2804
2805 chicks: Christopher Hicks
2806
2807 Chisel Wright C<pause@herlpacker.co.uk>
2808
2809 Danijel Milicevic C<me@danijel.de>
2810
2811 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
2812
2813 David Naughton, C<naughton@umn.edu>
2814
2815 David E. Wheeler
2816
2817 dhoss: Devin Austin <dhoss@cpan.org>
2818
2819 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2820
2821 Drew Taylor
2822
2823 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2824
2825 esskar: Sascha Kiefer
2826
2827 fireartist: Carl Franks <cfranks@cpan.org>
2828
2829 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
2830
2831 gabb: Danijel Milicevic
2832
2833 Gary Ashton Jones
2834
2835 Gavin Henry C<ghenry@perl.me.uk>
2836
2837 Geoff Richards
2838
2839 groditi: Guillermo Roditi <groditi@gmail.com>
2840
2841 hobbs: Andrew Rodland <andrew@cleverdomain.org>
2842
2843 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2844
2845 jcamacho: Juan Camacho
2846
2847 jester: Jesse Sheidlower C<jester@panix.com>
2848
2849 jhannah: Jay Hannah <jay@jays.net>
2850
2851 Jody Belka
2852
2853 Johan Lindstrom
2854
2855 jon: Jon Schutz <jjschutz@cpan.org>
2856
2857 Jonathan Rockway C<< <jrockway@cpan.org> >>
2858
2859 Kieren Diment C<kd@totaldatasolution.com>
2860
2861 konobi: Scott McWhirter <konobi@cpan.org>
2862
2863 marcus: Marcus Ramberg <mramberg@cpan.org>
2864
2865 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2866
2867 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2868
2869 mugwump: Sam Vilain
2870
2871 naughton: David Naughton
2872
2873 ningu: David Kamholz <dkamholz@cpan.org>
2874
2875 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2876
2877 numa: Dan Sully <daniel@cpan.org>
2878
2879 obra: Jesse Vincent
2880
2881 omega: Andreas Marienborg
2882
2883 Oleg Kostyuk <cub.uanic@gmail.com>
2884
2885 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2886
2887 rafl: Florian Ragwitz <rafl@debian.org>
2888
2889 random: Roland Lammel <lammel@cpan.org>
2890
2891 Robert Sedlacek C<< <rs@474.at> >>
2892
2893 sky: Arthur Bergman
2894
2895 t0m: Tomas Doran <bobtfish@bobtfish.net>
2896
2897 Ulf Edvinsson
2898
2899 Viljo Marrandi C<vilts@yahoo.com>
2900
2901 Will Hawes C<info@whawes.co.uk>
2902
2903 willert: Sebastian Willert <willert@cpan.org>
2904
2905 Yuval Kogman, C<nothingmuch@woobling.org>
2906
2907 =head1 LICENSE
2908
2909 This library is free software. You can redistribute it and/or modify it under
2910 the same terms as Perl itself.
2911
2912 =cut
2913
2914 no Moose;
2915
2916 __PACKAGE__->meta->make_immutable;
2917
2918 1;