lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use bytes;
   8 use B::Hooks::EndOfScope ();
   9 use Catalyst::Exception;
  10 use Catalyst::Log;
  11 use Catalyst::Request;
  12 use Catalyst::Request::Upload;
  13 use Catalyst::Response;
  14 use Catalyst::Utils;
  15 use Catalyst::Controller;
  16 use Devel::InnerPackage ();
  17 use File::stat;
  18 use Module::Pluggable::Object ();
  19 use Text::SimpleTable ();
  20 use Path::Class::Dir ();
  21 use Path::Class::File ();
  22 use URI ();
  23 use URI::http;
  24 use URI::https;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use Class::C3::Adopt::NEXT;
  28 use attributes;
  29 use utf8;
  30 use Carp qw/croak carp shortmess/;
  31
  32 BEGIN { require 5.008001; }
  33
  34 has stack => (is => 'ro', default => sub { [] });
  35 has stash => (is => 'rw', default => sub { {} });
  36 has state => (is => 'rw', default => 0);
  37 has stats => (is => 'rw');
  38 has action => (is => 'rw');
  39 has counter => (is => 'rw', default => sub { {} });
  40 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  41 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  42 has namespace => (is => 'rw');
  43
  44 sub depth { scalar @{ shift->stack || [] }; }
  45 sub comp { shift->component(@_) }
  46
  47 sub req {
  48     my $self = shift; return $self->request(@_);
  49 }
  50 sub res {
  51     my $self = shift; return $self->response(@_);
  52 }
  53
  54 # For backwards compatibility
  55 sub finalize_output { shift->finalize_body(@_) };
  56
  57 # For statistics
  58 our $COUNT     = 1;
  59 our $START     = time;
  60 our $RECURSION = 1000;
  61 our $DETACH    = "catalyst_detach\n";
  62 our $GO        = "catalyst_go\n";
  63
  64 #I imagine that very few of these really need to be class variables. if any.
  65 #maybe we should just make them attributes with a default?
  66 __PACKAGE__->mk_classdata($_)
  67   for qw/components arguments dispatcher engine log dispatcher_class
  68   engine_class context_class request_class response_class stats_class
  69   setup_finished/;
  70
  71 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  72 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  73 __PACKAGE__->request_class('Catalyst::Request');
  74 __PACKAGE__->response_class('Catalyst::Response');
  75 __PACKAGE__->stats_class('Catalyst::Stats');
  76
  77 # Remember to update this in Catalyst::Runtime as well!
  78
  79 our $VERSION = '5.80004';
  80
  81 {
  82     my $dev_version = $VERSION =~ /_\d{2}$/;
  83     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  84 }
  85
  86 $VERSION = eval $VERSION;
  87
  88 sub import {
  89     my ( $class, @arguments ) = @_;
  90
  91     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  92     # callers @ISA.
  93     return unless $class eq 'Catalyst';
  94
  95     my $caller = caller();
  96     return if $caller eq 'main';
  97
  98     # Kill Adopt::NEXT warnings if we're a non-RC version
  99     unless (_IS_DEVELOPMENT_VERSION()) {
 100         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 101     }
 102
 103     my $meta = Moose::Meta::Class->initialize($caller);
 104     #Moose->import({ into => $caller }); #do we want to do this?
 105
 106     unless ( $caller->isa('Catalyst') ) {
 107         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 108         $meta->superclasses(@superclasses);
 109     }
 110     unless( $meta->has_method('meta') ){
 111         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 112     }
 113
 114     $caller->arguments( [@arguments] );
 115     $caller->setup_home;
 116 }
 117
 118 =head1 NAME
 119
 120 Catalyst - The Elegant MVC Web Application Framework
 121
 122 =head1 SYNOPSIS
 123
 124 See the L<Catalyst::Manual> distribution for comprehensive
 125 documentation and tutorials.
 126
 127     # Install Catalyst::Devel for helpers and other development tools
 128     # use the helper to create a new application
 129     catalyst.pl MyApp
 130
 131     # add models, views, controllers
 132     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 133     script/myapp_create.pl view MyTemplate TT
 134     script/myapp_create.pl controller Search
 135
 136     # built in testserver -- use -r to restart automatically on changes
 137     # --help to see all available options
 138     script/myapp_server.pl
 139
 140     # command line testing interface
 141     script/myapp_test.pl /yada
 142
 143     ### in lib/MyApp.pm
 144     use Catalyst qw/-Debug/; # include plugins here as well
 145
 146     ### In lib/MyApp/Controller/Root.pm (autocreated)
 147     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 148         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 149         $c->stash->{template} = 'foo.tt'; # set the template
 150         # lookup something from db -- stash vars are passed to TT
 151         $c->stash->{data} =
 152           $c->model('Database::Foo')->search( { country => $args[0] } );
 153         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 154             $c->forward( 'bar' ); # process another action
 155             # do something else after forward returns
 156         }
 157     }
 158
 159     # The foo.tt TT template can use the stash data from the database
 160     [% WHILE (item = data.next) %]
 161         [% item.foo %]
 162     [% END %]
 163
 164     # called for /bar/of/soap, /bar/of/soap/10, etc.
 165     sub bar : Path('/bar/of/soap') { ... }
 166
 167     # called for all actions, from the top-most controller downwards
 168     sub auto : Private {
 169         my ( $self, $c ) = @_;
 170         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 171             $c->res->redirect( '/login' ); # require login
 172             return 0; # abort request and go immediately to end()
 173         }
 174         return 1; # success; carry on to next action
 175     }
 176
 177     # called after all actions are finished
 178     sub end : Private {
 179         my ( $self, $c ) = @_;
 180         if ( scalar @{ $c->error } ) { ... } # handle errors
 181         return if $c->res->body; # already have a response
 182         $c->forward( 'MyApp::View::TT' ); # render template
 183     }
 184
 185     ### in MyApp/Controller/Foo.pm
 186     # called for /foo/bar
 187     sub bar : Local { ... }
 188
 189     # called for /blargle
 190     sub blargle : Global { ... }
 191
 192     # an index action matches /foo, but not /foo/1, etc.
 193     sub index : Private { ... }
 194
 195     ### in MyApp/Controller/Foo/Bar.pm
 196     # called for /foo/bar/baz
 197     sub baz : Local { ... }
 198
 199     # first Root auto is called, then Foo auto, then this
 200     sub auto : Private { ... }
 201
 202     # powerful regular expression paths are also possible
 203     sub details : Regex('^product/(\w+)/details$') {
 204         my ( $self, $c ) = @_;
 205         # extract the (\w+) from the URI
 206         my $product = $c->req->captures->[0];
 207     }
 208
 209 See L<Catalyst::Manual::Intro> for additional information.
 210
 211 =head1 DESCRIPTION
 212
 213 Catalyst is a modern framework for making web applications without the
 214 pain usually associated with this process. This document is a reference
 215 to the main Catalyst application. If you are a new user, we suggest you
 216 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 217
 218 See L<Catalyst::Manual> for more documentation.
 219
 220 Catalyst plugins can be loaded by naming them as arguments to the "use
 221 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 222 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 223 C<My::Module>.
 224
 225     use Catalyst qw/My::Module/;
 226
 227 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 228 fully qualify the name by using a unary plus:
 229
 230     use Catalyst qw/
 231         My::Module
 232         +Fully::Qualified::Plugin::Name
 233     /;
 234
 235 Special flags like C<-Debug> and C<-Engine> can also be specified as
 236 arguments when Catalyst is loaded:
 237
 238     use Catalyst qw/-Debug My::Module/;
 239
 240 The position of plugins and flags in the chain is important, because
 241 they are loaded in the order in which they appear.
 242
 243 The following flags are supported:
 244
 245 =head2 -Debug
 246
 247 Enables debug output. You can also force this setting from the system
 248 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 249 settings override the application, with <MYAPP>_DEBUG having the highest
 250 priority.
 251
 252 =head2 -Engine
 253
 254 Forces Catalyst to use a specific engine. Omit the
 255 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 256
 257     use Catalyst qw/-Engine=CGI/;
 258
 259 =head2 -Home
 260
 261 Forces Catalyst to use a specific home directory, e.g.:
 262
 263     use Catalyst qw[-Home=/usr/mst];
 264
 265 This can also be done in the shell environment by setting either the
 266 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 267 is replaced with the uppercased name of your application, any "::" in
 268 the name will be replaced with underscores, e.g. MyApp::Web should use
 269 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 270
 271 =head2 -Log
 272
 273     use Catalyst '-Log=warn,fatal,error';
 274
 275 Specifies a comma-delimited list of log levels.
 276
 277 =head2 -Stats
 278
 279 Enables statistics collection and reporting. You can also force this setting
 280 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 281 environment settings override the application, with <MYAPP>_STATS having the
 282 highest priority.
 283
 284 e.g.
 285
 286    use Catalyst qw/-Stats=1/
 287
 288 =head1 METHODS
 289
 290 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 291
 292 =head2 $c->action
 293
 294 Returns a L<Catalyst::Action> object for the current action, which
 295 stringifies to the action name. See L<Catalyst::Action>.
 296
 297 =head2 $c->namespace
 298
 299 Returns the namespace of the current action, i.e., the URI prefix
 300 corresponding to the controller of the current action. For example:
 301
 302     # in Controller::Foo::Bar
 303     $c->namespace; # returns 'foo/bar';
 304
 305 =head2 $c->request
 306
 307 =head2 $c->req
 308
 309 Returns the current L<Catalyst::Request> object, giving access to
 310 information about the current client request (including parameters,
 311 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 312
 313 =head2 REQUEST FLOW HANDLING
 314
 315 =head2 $c->forward( $action [, \@arguments ] )
 316
 317 =head2 $c->forward( $class, $method, [, \@arguments ] )
 318
 319 Forwards processing to another action, by its private name. If you give a
 320 class name but no method, C<process()> is called. You may also optionally
 321 pass arguments in an arrayref. The action will receive the arguments in
 322 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 323 C<< $c->req->args >> will be restored to the previous values.
 324
 325 Any data C<return>ed from the action forwarded to, will be returned by the
 326 call to forward.
 327
 328     my $foodata = $c->forward('/foo');
 329     $c->forward('index');
 330     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 331     $c->forward('MyApp::View::TT');
 332
 333 Note that forward implies an C<<eval { }>> around the call (actually
 334 C<execute> does), thus de-fatalizing all 'dies' within the called
 335 action. If you want C<die> to propagate you need to do something like:
 336
 337     $c->forward('foo');
 338     die $c->error if $c->error;
 339
 340 Or make sure to always return true values from your actions and write
 341 your code like this:
 342
 343     $c->forward('foo') || return;
 344
 345 =cut
 346
 347 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 348
 349 =head2 $c->detach( $action [, \@arguments ] )
 350
 351 =head2 $c->detach( $class, $method, [, \@arguments ] )
 352
 353 =head2 $c->detach()
 354
 355 The same as C<forward>, but doesn't return to the previous action when
 356 processing is finished.
 357
 358 When called with no arguments it escapes the processing chain entirely.
 359
 360 =cut
 361
 362 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 363
 364 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 365
 366 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 367
 368 Almost the same as C<forward>, but does a full dispatch, instead of just
 369 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 370 C<auto> and the method you go to are called, just like a new request.
 371
 372 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 373 This means, for example, that $c->action methods such as C<name>, C<class> and
 374 C<reverse> return information for the visited action when they are invoked
 375 within the visited action.  This is different from the behavior of C<forward>
 376 which continues to use the $c->action object from the caller action even when
 377 invoked from the callee.
 378
 379 C<$c-E<gt>stash> is kept unchanged.
 380
 381 In effect, C<visit> allows you to "wrap" another action, just as it
 382 would have been called by dispatching from a URL, while the analogous
 383 C<go> allows you to transfer control to another action as if it had
 384 been reached directly from a URL.
 385
 386 =cut
 387
 388 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 389
 390 =head2 $c->go( $action [, \@captures, \@arguments ] )
 391
 392 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 393
 394 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 395 instead of just calling the new C<$action> /
 396 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 397 method you visit are called, just like a new request.
 398
 399 C<$c-E<gt>stash> is kept unchanged.
 400
 401 =cut
 402
 403 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 404
 405 =head2 $c->response
 406
 407 =head2 $c->res
 408
 409 Returns the current L<Catalyst::Response> object, see there for details.
 410
 411 =head2 $c->stash
 412
 413 Returns a hashref to the stash, which may be used to store data and pass
 414 it between components during a request. You can also set hash keys by
 415 passing arguments. The stash is automatically sent to the view. The
 416 stash is cleared at the end of a request; it cannot be used for
 417 persistent storage (for this you must use a session; see
 418 L<Catalyst::Plugin::Session> for a complete system integrated with
 419 Catalyst).
 420
 421     $c->stash->{foo} = $bar;
 422     $c->stash( { moose => 'majestic', qux => 0 } );
 423     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 424
 425     # stash is automatically passed to the view for use in a template
 426     $c->forward( 'MyApp::View::TT' );
 427
 428 =cut
 429
 430 around stash => sub {
 431     my $orig = shift;
 432     my $c = shift;
 433     my $stash = $orig->($c);
 434     if (@_) {
 435         my $new_stash = @_ > 1 ? {@_} : $_[0];
 436         croak('stash takes a hash or hashref') unless ref $new_stash;
 437         foreach my $key ( keys %$new_stash ) {
 438           $stash->{$key} = $new_stash->{$key};
 439         }
 440     }
 441
 442     return $stash;
 443 };
 444
 445
 446 =head2 $c->error
 447
 448 =head2 $c->error($error, ...)
 449
 450 =head2 $c->error($arrayref)
 451
 452 Returns an arrayref containing error messages.  If Catalyst encounters an
 453 error while processing a request, it stores the error in $c->error.  This
 454 method should only be used to store fatal error messages.
 455
 456     my @error = @{ $c->error };
 457
 458 Add a new error.
 459
 460     $c->error('Something bad happened');
 461
 462 =cut
 463
 464 sub error {
 465     my $c = shift;
 466     if ( $_[0] ) {
 467         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 468         croak @$error unless ref $c;
 469         push @{ $c->{error} }, @$error;
 470     }
 471     elsif ( defined $_[0] ) { $c->{error} = undef }
 472     return $c->{error} || [];
 473 }
 474
 475
 476 =head2 $c->state
 477
 478 Contains the return value of the last executed action.
 479
 480 =head2 $c->clear_errors
 481
 482 Clear errors.  You probably don't want to clear the errors unless you are
 483 implementing a custom error screen.
 484
 485 This is equivalent to running
 486
 487     $c->error(0);
 488
 489 =cut
 490
 491 sub clear_errors {
 492     my $c = shift;
 493     $c->error(0);
 494 }
 495
 496 # search components given a name and some prefixes
 497 sub _comp_search_prefixes {
 498     my ( $c, $name, @prefixes ) = @_;
 499     my $appclass = ref $c || $c;
 500     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 501     $filter = qr/$filter/; # Compile regex now rather than once per loop
 502
 503     # map the original component name to the sub part that we will search against
 504     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 505         grep { /$filter/ } keys %{ $c->components };
 506
 507     # undef for a name will return all
 508     return keys %eligible if !defined $name;
 509
 510     my $query  = ref $name ? $name : qr/^$name$/i;
 511     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 512
 513     return map { $c->components->{ $_ } } @result if @result;
 514
 515     # if we were given a regexp to search against, we're done.
 516     return if ref $name;
 517
 518     # regexp fallback
 519     $query  = qr/$name/i;
 520     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 521
 522     # no results? try against full names
 523     if( !@result ) {
 524         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 525     }
 526
 527     # don't warn if we didn't find any results, it just might not exist
 528     if( @result ) {
 529         # Disgusting hack to work out correct method name
 530         my $warn_for = lc $prefixes[0];
 531         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 532            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 533            "component resolution is unreliable and unsafe.";
 534         my $short = $result[0];
 535         $short =~ s/.*?Model:://;
 536         my $shortmess = Carp::shortmess('');
 537         if ($shortmess =~ m#Catalyst/Plugin#) {
 538            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 539               "plugin's config";
 540         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 541            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 542               "component's config";
 543         } else {
 544            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 545               "but if you really wanted to search, pass in a regexp as the argument " .
 546               "like so: \$c->${warn_for}(qr/${name}/)";
 547         }
 548         $c->log->warn( "${msg}$shortmess" );
 549     }
 550
 551     return @result;
 552 }
 553
 554 # Find possible names for a prefix
 555 sub _comp_names {
 556     my ( $c, @prefixes ) = @_;
 557     my $appclass = ref $c || $c;
 558
 559     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 560
 561     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 562     return @names;
 563 }
 564
 565 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 566 sub _filter_component {
 567     my ( $c, $comp, @args ) = @_;
 568
 569     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 570         return $comp->ACCEPT_CONTEXT( $c, @args );
 571     }
 572
 573     return $comp;
 574 }
 575
 576 =head2 COMPONENT ACCESSORS
 577
 578 =head2 $c->controller($name)
 579
 580 Gets a L<Catalyst::Controller> instance by name.
 581
 582     $c->controller('Foo')->do_stuff;
 583
 584 If the name is omitted, will return the controller for the dispatched
 585 action.
 586
 587 If you want to search for controllers, pass in a regexp as the argument.
 588
 589     # find all controllers that start with Foo
 590     my @foo_controllers = $c->controller(qr{^Foo});
 591
 592
 593 =cut
 594
 595 sub controller {
 596     my ( $c, $name, @args ) = @_;
 597
 598     if( $name ) {
 599         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 600         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 601         return $c->_filter_component( $result[ 0 ], @args );
 602     }
 603
 604     return $c->component( $c->action->class );
 605 }
 606
 607 =head2 $c->model($name)
 608
 609 Gets a L<Catalyst::Model> instance by name.
 610
 611     $c->model('Foo')->do_stuff;
 612
 613 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 614
 615 If the name is omitted, it will look for
 616  - a model object in $c->stash->{current_model_instance}, then
 617  - a model name in $c->stash->{current_model}, then
 618  - a config setting 'default_model', or
 619  - check if there is only one model, and return it if that's the case.
 620
 621 If you want to search for models, pass in a regexp as the argument.
 622
 623     # find all models that start with Foo
 624     my @foo_models = $c->model(qr{^Foo});
 625
 626 =cut
 627
 628 sub model {
 629     my ( $c, $name, @args ) = @_;
 630
 631     if( $name ) {
 632         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 633         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 634         return $c->_filter_component( $result[ 0 ], @args );
 635     }
 636
 637     if (ref $c) {
 638         return $c->stash->{current_model_instance}
 639           if $c->stash->{current_model_instance};
 640         return $c->model( $c->stash->{current_model} )
 641           if $c->stash->{current_model};
 642     }
 643     return $c->model( $c->config->{default_model} )
 644       if $c->config->{default_model};
 645
 646     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 647
 648     if( $rest ) {
 649         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 650         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 651         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 652         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 653         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 654     }
 655
 656     return $c->_filter_component( $comp );
 657 }
 658
 659
 660 =head2 $c->view($name)
 661
 662 Gets a L<Catalyst::View> instance by name.
 663
 664     $c->view('Foo')->do_stuff;
 665
 666 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 667
 668 If the name is omitted, it will look for
 669  - a view object in $c->stash->{current_view_instance}, then
 670  - a view name in $c->stash->{current_view}, then
 671  - a config setting 'default_view', or
 672  - check if there is only one view, and return it if that's the case.
 673
 674 If you want to search for views, pass in a regexp as the argument.
 675
 676     # find all views that start with Foo
 677     my @foo_views = $c->view(qr{^Foo});
 678
 679 =cut
 680
 681 sub view {
 682     my ( $c, $name, @args ) = @_;
 683
 684     if( $name ) {
 685         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 686         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 687         return $c->_filter_component( $result[ 0 ], @args );
 688     }
 689
 690     if (ref $c) {
 691         return $c->stash->{current_view_instance}
 692           if $c->stash->{current_view_instance};
 693         return $c->view( $c->stash->{current_view} )
 694           if $c->stash->{current_view};
 695     }
 696     return $c->view( $c->config->{default_view} )
 697       if $c->config->{default_view};
 698
 699     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 700
 701     if( $rest ) {
 702         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 703         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 704         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 705         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 706         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 707     }
 708
 709     return $c->_filter_component( $comp );
 710 }
 711
 712 =head2 $c->controllers
 713
 714 Returns the available names which can be passed to $c->controller
 715
 716 =cut
 717
 718 sub controllers {
 719     my ( $c ) = @_;
 720     return $c->_comp_names(qw/Controller C/);
 721 }
 722
 723 =head2 $c->models
 724
 725 Returns the available names which can be passed to $c->model
 726
 727 =cut
 728
 729 sub models {
 730     my ( $c ) = @_;
 731     return $c->_comp_names(qw/Model M/);
 732 }
 733
 734
 735 =head2 $c->views
 736
 737 Returns the available names which can be passed to $c->view
 738
 739 =cut
 740
 741 sub views {
 742     my ( $c ) = @_;
 743     return $c->_comp_names(qw/View V/);
 744 }
 745
 746 =head2 $c->comp($name)
 747
 748 =head2 $c->component($name)
 749
 750 Gets a component object by name. This method is not recommended,
 751 unless you want to get a specific component by full
 752 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 753 should be used instead.
 754
 755 If C<$name> is a regexp, a list of components matched against the full
 756 component name will be returned.
 757
 758 =cut
 759
 760 sub component {
 761     my ( $c, $name, @args ) = @_;
 762
 763     if( $name ) {
 764         my $comps = $c->components;
 765
 766         if( !ref $name ) {
 767             # is it the exact name?
 768             return $c->_filter_component( $comps->{ $name }, @args )
 769                        if exists $comps->{ $name };
 770
 771             # perhaps we just omitted "MyApp"?
 772             my $composed = ( ref $c || $c ) . "::${name}";
 773             return $c->_filter_component( $comps->{ $composed }, @args )
 774                        if exists $comps->{ $composed };
 775
 776             # search all of the models, views and controllers
 777             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 778             return $c->_filter_component( $comp, @args ) if $comp;
 779         }
 780
 781         # This is here so $c->comp( '::M::' ) works
 782         my $query = ref $name ? $name : qr{$name}i;
 783
 784         my @result = grep { m{$query} } keys %{ $c->components };
 785         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 786
 787         if( $result[ 0 ] ) {
 788             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 789             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 790             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 791             return $c->_filter_component( $result[ 0 ], @args );
 792         }
 793
 794         # I would expect to return an empty list here, but that breaks back-compat
 795     }
 796
 797     # fallback
 798     return sort keys %{ $c->components };
 799 }
 800
 801 =head2 CLASS DATA AND HELPER CLASSES
 802
 803 =head2 $c->config
 804
 805 Returns or takes a hashref containing the application's configuration.
 806
 807     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 808
 809 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 810 like myapp.conf in your applications home directory. See
 811 L<Catalyst::Plugin::ConfigLoader>.
 812
 813 =head3 Cascading configuration.
 814
 815 The config method is present on all Catalyst components, and configuration
 816 will be merged when an application is started. Configuration loaded with
 817 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 818 followed by configuration in your top level C<MyApp> class. These two
 819 configurations are merged, and then configuration data whose hash key matches a
 820 component name is merged with configuration for that component.
 821
 822 The configuration for a component is then passed to the C<new> method when a
 823 component is constructed.
 824
 825 For example:
 826
 827     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 828     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 829
 830 will mean that C<MyApp::Model::Foo> receives the following data when
 831 constructed:
 832
 833     MyApp::Model::Foo->new({
 834         bar => 'baz',
 835         quux => 'frob',
 836         overrides => 'me',
 837     });
 838
 839 =cut
 840
 841 around config => sub {
 842     my $orig = shift;
 843     my $c = shift;
 844
 845     croak('Setting config after setup has been run is not allowed.')
 846         if ( @_ and $c->setup_finished );
 847
 848     $c->$orig(@_);
 849 };
 850
 851 =head2 $c->log
 852
 853 Returns the logging object instance. Unless it is already set, Catalyst
 854 sets this up with a L<Catalyst::Log> object. To use your own log class,
 855 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 856 C<< __PACKAGE__->setup >>.
 857
 858  __PACKAGE__->log( MyLogger->new );
 859  __PACKAGE__->setup;
 860
 861 And later:
 862
 863     $c->log->info( 'Now logging with my own logger!' );
 864
 865 Your log class should implement the methods described in
 866 L<Catalyst::Log>.
 867
 868
 869 =head2 $c->debug
 870
 871 Returns 1 if debug mode is enabled, 0 otherwise.
 872
 873 You can enable debug mode in several ways:
 874
 875 =over
 876
 877 =item By calling myapp_server.pl with the -d flag
 878
 879 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 880
 881 =item The -Debug option in your MyApp.pm
 882
 883 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 884
 885 =back
 886
 887 Calling C<< $c->debug(1) >> has no effect.
 888
 889 =cut
 890
 891 sub debug { 0 }
 892
 893 =head2 $c->dispatcher
 894
 895 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 896
 897 =head2 $c->engine
 898
 899 Returns the engine instance. See L<Catalyst::Engine>.
 900
 901
 902 =head2 UTILITY METHODS
 903
 904 =head2 $c->path_to(@path)
 905
 906 Merges C<@path> with C<< $c->config->{home} >> and returns a
 907 L<Path::Class::Dir> object.
 908
 909 For example:
 910
 911     $c->path_to( 'db', 'sqlite.db' );
 912
 913 =cut
 914
 915 sub path_to {
 916     my ( $c, @path ) = @_;
 917     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 918     if ( -d $path ) { return $path }
 919     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 920 }
 921
 922 =head2 $c->plugin( $name, $class, @args )
 923
 924 Helper method for plugins. It creates a class data accessor/mutator and
 925 loads and instantiates the given class.
 926
 927     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 928
 929     $c->prototype->define_javascript_functions;
 930
 931 B<Note:> This method of adding plugins is deprecated. The ability
 932 to add plugins like this B<will be removed> in a Catalyst 5.81.
 933 Please do not use this functionality in new code.
 934
 935 =cut
 936
 937 sub plugin {
 938     my ( $class, $name, $plugin, @args ) = @_;
 939
 940     # See block comment in t/unit_core_plugin.t
 941     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 942
 943     $class->_register_plugin( $plugin, 1 );
 944
 945     eval { $plugin->import };
 946     $class->mk_classdata($name);
 947     my $obj;
 948     eval { $obj = $plugin->new(@args) };
 949
 950     if ($@) {
 951         Catalyst::Exception->throw( message =>
 952               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 953     }
 954
 955     $class->$name($obj);
 956     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 957       if $class->debug;
 958 }
 959
 960 =head2 MyApp->setup
 961
 962 Initializes the dispatcher and engine, loads any plugins, and loads the
 963 model, view, and controller components. You may also specify an array
 964 of plugins to load here, if you choose to not load them in the C<use
 965 Catalyst> line.
 966
 967     MyApp->setup;
 968     MyApp->setup( qw/-Debug/ );
 969
 970 =cut
 971
 972 sub setup {
 973     my ( $class, @arguments ) = @_;
 974     croak('Running setup more than once')
 975         if ( $class->setup_finished );
 976
 977     unless ( $class->isa('Catalyst') ) {
 978
 979         Catalyst::Exception->throw(
 980             message => qq/'$class' does not inherit from Catalyst/ );
 981     }
 982
 983     if ( $class->arguments ) {
 984         @arguments = ( @arguments, @{ $class->arguments } );
 985     }
 986
 987     # Process options
 988     my $flags = {};
 989
 990     foreach (@arguments) {
 991
 992         if (/^-Debug$/) {
 993             $flags->{log} =
 994               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 995         }
 996         elsif (/^-(\w+)=?(.*)$/) {
 997             $flags->{ lc $1 } = $2;
 998         }
 999         else {
1000             push @{ $flags->{plugins} }, $_;
1001         }
1002     }
1003
1004     $class->setup_home( delete $flags->{home} );
1005
1006     $class->setup_log( delete $flags->{log} );
1007     $class->setup_plugins( delete $flags->{plugins} );
1008     $class->setup_dispatcher( delete $flags->{dispatcher} );
1009     $class->setup_engine( delete $flags->{engine} );
1010     $class->setup_stats( delete $flags->{stats} );
1011
1012     for my $flag ( sort keys %{$flags} ) {
1013
1014         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1015             &$code( $class, delete $flags->{$flag} );
1016         }
1017         else {
1018             $class->log->warn(qq/Unknown flag "$flag"/);
1019         }
1020     }
1021
1022     eval { require Catalyst::Devel; };
1023     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1024         $class->log->warn(<<"EOF");
1025 You are running an old script!
1026
1027   Please update by running (this will overwrite existing files):
1028     catalyst.pl -force -scripts $class
1029
1030   or (this will not overwrite existing files):
1031     catalyst.pl -scripts $class
1032
1033 EOF
1034     }
1035
1036     if ( $class->debug ) {
1037         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1038
1039         if (@plugins) {
1040             my $column_width = Catalyst::Utils::term_width() - 6;
1041             my $t = Text::SimpleTable->new($column_width);
1042             $t->row($_) for @plugins;
1043             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1044         }
1045
1046         my $dispatcher = $class->dispatcher;
1047         my $engine     = $class->engine;
1048         my $home       = $class->config->{home};
1049
1050         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1051         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1052
1053         $home
1054           ? ( -d $home )
1055           ? $class->log->debug(qq/Found home "$home"/)
1056           : $class->log->debug(qq/Home "$home" doesn't exist/)
1057           : $class->log->debug(q/Couldn't find home/);
1058     }
1059
1060     # Call plugins setup, this is stupid and evil.
1061     # Also screws C3 badly on 5.10, hack to avoid.
1062     {
1063         no warnings qw/redefine/;
1064         local *setup = sub { };
1065         $class->setup unless $Catalyst::__AM_RESTARTING;
1066     }
1067
1068     # Initialize our data structure
1069     $class->components( {} );
1070
1071     $class->setup_components;
1072
1073     if ( $class->debug ) {
1074         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1075         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1076         for my $comp ( sort keys %{ $class->components } ) {
1077             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1078             $t->row( $comp, $type );
1079         }
1080         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1081           if ( keys %{ $class->components } );
1082     }
1083
1084     # Add our self to components, since we are also a component
1085     if( $class->isa('Catalyst::Controller') ){
1086       $class->components->{$class} = $class;
1087     }
1088
1089     $class->setup_actions;
1090
1091     if ( $class->debug ) {
1092         my $name = $class->config->{name} || 'Application';
1093         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1094     }
1095     $class->log->_flush() if $class->log->can('_flush');
1096
1097     # Make sure that the application class becomes immutable at this point,
1098     # which ensures that it gets an inlined constructor. This means that it
1099     # works even if the user has added a plugin which contains a new method.
1100     # Note however that we have to do the work on scope end, so that method
1101     # modifiers work correctly in MyApp (as you have to call setup _before_
1102     # applying modifiers).
1103     B::Hooks::EndOfScope::on_scope_end {
1104         return if $@;
1105         my $meta = Class::MOP::get_metaclass_by_name($class);
1106         if ( $meta->is_immutable && ! { $meta->immutable_options }->{inline_constructor} ) {
1107             warn "You made your application class ($class) immutable, "
1108                 . "but did not inline the constructor.\n"
1109                 . "This will break catalyst, please pass "
1110                 . "(replace_constructor => 1) when making your class immutable.\n";
1111         }
1112         $meta->make_immutable(replace_constructor => 1) unless $meta->is_immutable;
1113     };
1114
1115     $class->setup_finalize;
1116 }
1117
1118
1119 =head2 $app->setup_finalize
1120
1121 A hook to attach modifiers to.
1122 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1123 Also better than C< setup_finished(); >, as that is a getter method.
1124
1125     sub setup_finalize {
1126
1127         my $app = shift;
1128
1129         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1130
1131         $app->next::method(@_);
1132
1133
1134     }
1135
1136 =cut
1137
1138 sub setup_finalize {
1139     my ($class) = @_;
1140     $class->setup_finished(1);
1141 }
1142
1143 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1144
1145 =head2 $c->uri_for( $path, @args?, \%query_values? )
1146
1147 =over
1148
1149 =item $action
1150
1151 A Catalyst::Action object representing the Catalyst action you want to
1152 create a URI for. To get one for an action in the current controller,
1153 use C<< $c->action('someactionname') >>. To get one from different
1154 controller, fetch the controller using C<< $c->controller() >>, then
1155 call C<action_for> on it.
1156
1157 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1158 using C<< $c->req->captures >>.
1159
1160   # For the current action
1161   $c->uri_for($c->action, $c->req->captures);
1162
1163   # For the Foo action in the Bar controller
1164   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1165
1166 =back
1167
1168 =cut
1169
1170 sub uri_for {
1171     my ( $c, $path, @args ) = @_;
1172
1173     if ( blessed($path) ) { # action object
1174         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1175                          ? shift(@args)
1176                          : [] );
1177         my $action = $path;
1178         $path = $c->dispatcher->uri_for_action($action, $captures);
1179         if (not defined $path) {
1180             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1181                 if $c->debug;
1182             return undef;
1183         }
1184         $path = '/' if $path eq '';
1185     }
1186
1187     undef($path) if (defined $path && $path eq '');
1188
1189     my $params =
1190       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1191
1192     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1193     s/([^A-Za-z0-9\-_.!~*'()])/$URI::Escape::escapes{$1}/go for @args;
1194
1195     unshift(@args, $path);
1196
1197     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1198         my $namespace = $c->namespace;
1199         if (defined $path) { # cheesy hack to handle path '../foo'
1200            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1201         }
1202         unshift(@args, $namespace || '');
1203     }
1204
1205     # join args with '/', or a blank string
1206     my $args = join('/', grep { defined($_) } @args);
1207     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1208     $args =~ s!^/+!!;
1209     my $base = $c->req->base;
1210     my $class = ref($base);
1211     $base =~ s{(?<!/)$}{/};
1212
1213     my $query = '';
1214
1215     if (my @keys = keys %$params) {
1216       # somewhat lifted from URI::_query's query_form
1217       $query = '?'.join('&', map {
1218           my $val = $params->{$_};
1219           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1220           s/ /+/g;
1221           my $key = $_;
1222           $val = '' unless defined $val;
1223           (map {
1224               $_ = "$_";
1225               utf8::encode( $_ ) if utf8::is_utf8($_);
1226               # using the URI::Escape pattern here so utf8 chars survive
1227               s/([^A-Za-z0-9\-_.!~*'()])/$URI::Escape::escapes{$1}/go;
1228               s/ /+/g;
1229               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1230       } @keys);
1231     }
1232
1233     my $res = bless(\"${base}${args}${query}", $class);
1234     $res;
1235 }
1236
1237 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1238
1239 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1240
1241 =over
1242
1243 =item $path
1244
1245 A private path to the Catalyst action you want to create a URI for.
1246
1247 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1248 >> and passing the resulting C<$action> and the remaining arguments to C<<
1249 $c->uri_for >>.
1250
1251 You can also pass in a Catalyst::Action object, in which case it is passed to
1252 C<< $c->uri_for >>.
1253
1254 =back
1255
1256 =cut
1257
1258 sub uri_for_action {
1259     my ( $c, $path, @args ) = @_;
1260     my $action = blessed($path)
1261       ? $path
1262       : $c->dispatcher->get_action_by_path($path);
1263     unless (defined $action) {
1264       croak "Can't find action for path '$path'";
1265     }
1266     return $c->uri_for( $action, @args );
1267 }
1268
1269 =head2 $c->welcome_message
1270
1271 Returns the Catalyst welcome HTML page.
1272
1273 =cut
1274
1275 sub welcome_message {
1276     my $c      = shift;
1277     my $name   = $c->config->{name};
1278     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1279     my $prefix = Catalyst::Utils::appprefix( ref $c );
1280     $c->response->content_type('text/html; charset=utf-8');
1281     return <<"EOF";
1282 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1283     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1284 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1285     <head>
1286     <meta http-equiv="Content-Language" content="en" />
1287     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1288         <title>$name on Catalyst $VERSION</title>
1289         <style type="text/css">
1290             body {
1291                 color: #000;
1292                 background-color: #eee;
1293             }
1294             div#content {
1295                 width: 640px;
1296                 margin-left: auto;
1297                 margin-right: auto;
1298                 margin-top: 10px;
1299                 margin-bottom: 10px;
1300                 text-align: left;
1301                 background-color: #ccc;
1302                 border: 1px solid #aaa;
1303             }
1304             p, h1, h2 {
1305                 margin-left: 20px;
1306                 margin-right: 20px;
1307                 font-family: verdana, tahoma, sans-serif;
1308             }
1309             a {
1310                 font-family: verdana, tahoma, sans-serif;
1311             }
1312             :link, :visited {
1313                     text-decoration: none;
1314                     color: #b00;
1315                     border-bottom: 1px dotted #bbb;
1316             }
1317             :link:hover, :visited:hover {
1318                     color: #555;
1319             }
1320             div#topbar {
1321                 margin: 0px;
1322             }
1323             pre {
1324                 margin: 10px;
1325                 padding: 8px;
1326             }
1327             div#answers {
1328                 padding: 8px;
1329                 margin: 10px;
1330                 background-color: #fff;
1331                 border: 1px solid #aaa;
1332             }
1333             h1 {
1334                 font-size: 0.9em;
1335                 font-weight: normal;
1336                 text-align: center;
1337             }
1338             h2 {
1339                 font-size: 1.0em;
1340             }
1341             p {
1342                 font-size: 0.9em;
1343             }
1344             p img {
1345                 float: right;
1346                 margin-left: 10px;
1347             }
1348             span#appname {
1349                 font-weight: bold;
1350                 font-size: 1.6em;
1351             }
1352         </style>
1353     </head>
1354     <body>
1355         <div id="content">
1356             <div id="topbar">
1357                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1358                     $VERSION</h1>
1359              </div>
1360              <div id="answers">
1361                  <p>
1362                  <img src="$logo" alt="Catalyst Logo" />
1363                  </p>
1364                  <p>Welcome to the  world of Catalyst.
1365                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1366                     framework will make web development something you had
1367                     never expected it to be: Fun, rewarding, and quick.</p>
1368                  <h2>What to do now?</h2>
1369                  <p>That really depends  on what <b>you</b> want to do.
1370                     We do, however, provide you with a few starting points.</p>
1371                  <p>If you want to jump right into web development with Catalyst
1372                     you might want to start with a tutorial.</p>
1373 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1374 </pre>
1375 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1376 <pre>
1377 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1378 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1379 </code></pre>
1380                  <h2>What to do next?</h2>
1381                  <p>Next it's time to write an actual application. Use the
1382                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1383                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1384                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1385                     they can save you a lot of work.</p>
1386                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1387                     <p>Also, be sure to check out the vast and growing
1388                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1389                     you are likely to find what you need there.
1390                     </p>
1391
1392                  <h2>Need help?</h2>
1393                  <p>Catalyst has a very active community. Here are the main places to
1394                     get in touch with us.</p>
1395                  <ul>
1396                      <li>
1397                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1398                      </li>
1399                      <li>
1400                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1401                      </li>
1402                      <li>
1403                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1404                      </li>
1405                  </ul>
1406                  <h2>In conclusion</h2>
1407                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1408                     as we enjoyed making it. Please contact us if you have ideas
1409                     for improvement or other feedback.</p>
1410              </div>
1411          </div>
1412     </body>
1413 </html>
1414 EOF
1415 }
1416
1417 =head1 INTERNAL METHODS
1418
1419 These methods are not meant to be used by end users.
1420
1421 =head2 $c->components
1422
1423 Returns a hash of components.
1424
1425 =head2 $c->context_class
1426
1427 Returns or sets the context class.
1428
1429 =head2 $c->counter
1430
1431 Returns a hashref containing coderefs and execution counts (needed for
1432 deep recursion detection).
1433
1434 =head2 $c->depth
1435
1436 Returns the number of actions on the current internal execution stack.
1437
1438 =head2 $c->dispatch
1439
1440 Dispatches a request to actions.
1441
1442 =cut
1443
1444 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1445
1446 =head2 $c->dispatcher_class
1447
1448 Returns or sets the dispatcher class.
1449
1450 =head2 $c->dump_these
1451
1452 Returns a list of 2-element array references (name, structure) pairs
1453 that will be dumped on the error page in debug mode.
1454
1455 =cut
1456
1457 sub dump_these {
1458     my $c = shift;
1459     [ Request => $c->req ],
1460     [ Response => $c->res ],
1461     [ Stash => $c->stash ],
1462     [ Config => $c->config ];
1463 }
1464
1465 =head2 $c->engine_class
1466
1467 Returns or sets the engine class.
1468
1469 =head2 $c->execute( $class, $coderef )
1470
1471 Execute a coderef in given class and catch exceptions. Errors are available
1472 via $c->error.
1473
1474 =cut
1475
1476 sub execute {
1477     my ( $c, $class, $code ) = @_;
1478     $class = $c->component($class) || $class;
1479     $c->state(0);
1480
1481     if ( $c->depth >= $RECURSION ) {
1482         my $action = $code->reverse();
1483         $action = "/$action" unless $action =~ /->/;
1484         my $error = qq/Deep recursion detected calling "${action}"/;
1485         $c->log->error($error);
1486         $c->error($error);
1487         $c->state(0);
1488         return $c->state;
1489     }
1490
1491     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1492
1493     push( @{ $c->stack }, $code );
1494
1495     no warnings 'recursion';
1496     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1497
1498     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1499
1500     my $last = pop( @{ $c->stack } );
1501
1502     if ( my $error = $@ ) {
1503         if ( !ref($error) and $error eq $DETACH ) {
1504             die $DETACH if($c->depth > 1);
1505         }
1506         elsif ( !ref($error) and $error eq $GO ) {
1507             die $GO if($c->depth > 0);
1508         }
1509         else {
1510             unless ( ref $error ) {
1511                 no warnings 'uninitialized';
1512                 chomp $error;
1513                 my $class = $last->class;
1514                 my $name  = $last->name;
1515                 $error = qq/Caught exception in $class->$name "$error"/;
1516             }
1517             $c->error($error);
1518             $c->state(0);
1519         }
1520     }
1521     return $c->state;
1522 }
1523
1524 sub _stats_start_execute {
1525     my ( $c, $code ) = @_;
1526
1527     return if ( ( $code->name =~ /^_.*/ )
1528         && ( !$c->config->{show_internal_actions} ) );
1529
1530     my $action_name = $code->reverse();
1531     $c->counter->{$action_name}++;
1532
1533     my $action = $action_name;
1534     $action = "/$action" unless $action =~ /->/;
1535
1536     # determine if the call was the result of a forward
1537     # this is done by walking up the call stack and looking for a calling
1538     # sub of Catalyst::forward before the eval
1539     my $callsub = q{};
1540     for my $index ( 2 .. 11 ) {
1541         last
1542         if ( ( caller($index) )[0] eq 'Catalyst'
1543             && ( caller($index) )[3] eq '(eval)' );
1544
1545         if ( ( caller($index) )[3] =~ /forward$/ ) {
1546             $callsub = ( caller($index) )[3];
1547             $action  = "-> $action";
1548             last;
1549         }
1550     }
1551
1552     my $uid = $action_name . $c->counter->{$action_name};
1553
1554     # is this a root-level call or a forwarded call?
1555     if ( $callsub =~ /forward$/ ) {
1556
1557         # forward, locate the caller
1558         if ( my $parent = $c->stack->[-1] ) {
1559             $c->stats->profile(
1560                 begin  => $action,
1561                 parent => "$parent" . $c->counter->{"$parent"},
1562                 uid    => $uid,
1563             );
1564         }
1565         else {
1566
1567             # forward with no caller may come from a plugin
1568             $c->stats->profile(
1569                 begin => $action,
1570                 uid   => $uid,
1571             );
1572         }
1573     }
1574     else {
1575
1576         # root-level call
1577         $c->stats->profile(
1578             begin => $action,
1579             uid   => $uid,
1580         );
1581     }
1582     return $action;
1583
1584 }
1585
1586 sub _stats_finish_execute {
1587     my ( $c, $info ) = @_;
1588     $c->stats->profile( end => $info );
1589 }
1590
1591 =head2 $c->_localize_fields( sub { }, \%keys );
1592
1593 =cut
1594
1595 #Why does this exist? This is no longer safe and WILL NOT WORK.
1596 # it doesnt seem to be used anywhere. can we remove it?
1597 sub _localize_fields {
1598     my ( $c, $localized, $code ) = ( @_ );
1599
1600     my $request = delete $localized->{request} || {};
1601     my $response = delete $localized->{response} || {};
1602
1603     local @{ $c }{ keys %$localized } = values %$localized;
1604     local @{ $c->request }{ keys %$request } = values %$request;
1605     local @{ $c->response }{ keys %$response } = values %$response;
1606
1607     $code->();
1608 }
1609
1610 =head2 $c->finalize
1611
1612 Finalizes the request.
1613
1614 =cut
1615
1616 sub finalize {
1617     my $c = shift;
1618
1619     for my $error ( @{ $c->error } ) {
1620         $c->log->error($error);
1621     }
1622
1623     # Allow engine to handle finalize flow (for POE)
1624     my $engine = $c->engine;
1625     if ( my $code = $engine->can('finalize') ) {
1626         $engine->$code($c);
1627     }
1628     else {
1629
1630         $c->finalize_uploads;
1631
1632         # Error
1633         if ( $#{ $c->error } >= 0 ) {
1634             $c->finalize_error;
1635         }
1636
1637         $c->finalize_headers;
1638
1639         # HEAD request
1640         if ( $c->request->method eq 'HEAD' ) {
1641             $c->response->body('');
1642         }
1643
1644         $c->finalize_body;
1645     }
1646
1647     if ($c->use_stats) {
1648         my $elapsed = sprintf '%f', $c->stats->elapsed;
1649         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1650         $c->log->info(
1651             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1652     }
1653
1654     return $c->response->status;
1655 }
1656
1657 =head2 $c->finalize_body
1658
1659 Finalizes body.
1660
1661 =cut
1662
1663 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1664
1665 =head2 $c->finalize_cookies
1666
1667 Finalizes cookies.
1668
1669 =cut
1670
1671 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1672
1673 =head2 $c->finalize_error
1674
1675 Finalizes error.
1676
1677 =cut
1678
1679 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1680
1681 =head2 $c->finalize_headers
1682
1683 Finalizes headers.
1684
1685 =cut
1686
1687 sub finalize_headers {
1688     my $c = shift;
1689
1690     my $response = $c->response; #accessor calls can add up?
1691
1692     # Check if we already finalized headers
1693     return if $response->finalized_headers;
1694
1695     # Handle redirects
1696     if ( my $location = $response->redirect ) {
1697         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1698         $response->header( Location => $location );
1699
1700         if ( !$response->has_body ) {
1701             # Add a default body if none is already present
1702             $response->body(
1703                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1704             );
1705         }
1706     }
1707
1708     # Content-Length
1709     if ( $response->body && !$response->content_length ) {
1710
1711         # get the length from a filehandle
1712         if ( blessed( $response->body ) && $response->body->can('read') )
1713         {
1714             my $stat = stat $response->body;
1715             if ( $stat && $stat->size > 0 ) {
1716                 $response->content_length( $stat->size );
1717             }
1718             else {
1719                 $c->log->warn('Serving filehandle without a content-length');
1720             }
1721         }
1722         else {
1723             # everything should be bytes at this point, but just in case
1724             $response->content_length( bytes::length( $response->body ) );
1725         }
1726     }
1727
1728     # Errors
1729     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1730         $response->headers->remove_header("Content-Length");
1731         $response->body('');
1732     }
1733
1734     $c->finalize_cookies;
1735
1736     $c->engine->finalize_headers( $c, @_ );
1737
1738     # Done
1739     $response->finalized_headers(1);
1740 }
1741
1742 =head2 $c->finalize_output
1743
1744 An alias for finalize_body.
1745
1746 =head2 $c->finalize_read
1747
1748 Finalizes the input after reading is complete.
1749
1750 =cut
1751
1752 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1753
1754 =head2 $c->finalize_uploads
1755
1756 Finalizes uploads. Cleans up any temporary files.
1757
1758 =cut
1759
1760 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1761
1762 =head2 $c->get_action( $action, $namespace )
1763
1764 Gets an action in a given namespace.
1765
1766 =cut
1767
1768 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1769
1770 =head2 $c->get_actions( $action, $namespace )
1771
1772 Gets all actions of a given name in a namespace and all parent
1773 namespaces.
1774
1775 =cut
1776
1777 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1778
1779 =head2 $c->handle_request( $class, @arguments )
1780
1781 Called to handle each HTTP request.
1782
1783 =cut
1784
1785 sub handle_request {
1786     my ( $class, @arguments ) = @_;
1787
1788     # Always expect worst case!
1789     my $status = -1;
1790     eval {
1791         if ($class->debug) {
1792             my $secs = time - $START || 1;
1793             my $av = sprintf '%.3f', $COUNT / $secs;
1794             my $time = localtime time;
1795             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1796         }
1797
1798         my $c = $class->prepare(@arguments);
1799         $c->dispatch;
1800         $status = $c->finalize;
1801     };
1802
1803     if ( my $error = $@ ) {
1804         chomp $error;
1805         $class->log->error(qq/Caught exception in engine "$error"/);
1806     }
1807
1808     $COUNT++;
1809
1810     if(my $coderef = $class->log->can('_flush')){
1811         $class->log->$coderef();
1812     }
1813     return $status;
1814 }
1815
1816 =head2 $c->prepare( @arguments )
1817
1818 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1819 etc.).
1820
1821 =cut
1822
1823 sub prepare {
1824     my ( $class, @arguments ) = @_;
1825
1826     # XXX
1827     # After the app/ctxt split, this should become an attribute based on something passed
1828     # into the application.
1829     $class->context_class( ref $class || $class ) unless $class->context_class;
1830
1831     my $c = $class->context_class->new({});
1832
1833     # For on-demand data
1834     $c->request->_context($c);
1835     $c->response->_context($c);
1836
1837     #surely this is not the most efficient way to do things...
1838     $c->stats($class->stats_class->new)->enable($c->use_stats);
1839     if ( $c->debug ) {
1840         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1841     }
1842
1843     #XXX reuse coderef from can
1844     # Allow engine to direct the prepare flow (for POE)
1845     if ( $c->engine->can('prepare') ) {
1846         $c->engine->prepare( $c, @arguments );
1847     }
1848     else {
1849         $c->prepare_request(@arguments);
1850         $c->prepare_connection;
1851         $c->prepare_query_parameters;
1852         $c->prepare_headers;
1853         $c->prepare_cookies;
1854         $c->prepare_path;
1855
1856         # Prepare the body for reading, either by prepare_body
1857         # or the user, if they are using $c->read
1858         $c->prepare_read;
1859
1860         # Parse the body unless the user wants it on-demand
1861         unless ( $c->config->{parse_on_demand} ) {
1862             $c->prepare_body;
1863         }
1864     }
1865
1866     my $method  = $c->req->method  || '';
1867     my $path    = $c->req->path;
1868     $path       = '/' unless length $path;
1869     my $address = $c->req->address || '';
1870
1871     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1872       if $c->debug;
1873
1874     $c->prepare_action;
1875
1876     return $c;
1877 }
1878
1879 =head2 $c->prepare_action
1880
1881 Prepares action. See L<Catalyst::Dispatcher>.
1882
1883 =cut
1884
1885 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1886
1887 =head2 $c->prepare_body
1888
1889 Prepares message body.
1890
1891 =cut
1892
1893 sub prepare_body {
1894     my $c = shift;
1895
1896     return if $c->request->_has_body;
1897
1898     # Initialize on-demand data
1899     $c->engine->prepare_body( $c, @_ );
1900     $c->prepare_parameters;
1901     $c->prepare_uploads;
1902
1903     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1904         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1905         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1906             my $param = $c->req->body_parameters->{$key};
1907             my $value = defined($param) ? $param : '';
1908             $t->row( $key,
1909                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1910         }
1911         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1912     }
1913 }
1914
1915 =head2 $c->prepare_body_chunk( $chunk )
1916
1917 Prepares a chunk of data before sending it to L<HTTP::Body>.
1918
1919 See L<Catalyst::Engine>.
1920
1921 =cut
1922
1923 sub prepare_body_chunk {
1924     my $c = shift;
1925     $c->engine->prepare_body_chunk( $c, @_ );
1926 }
1927
1928 =head2 $c->prepare_body_parameters
1929
1930 Prepares body parameters.
1931
1932 =cut
1933
1934 sub prepare_body_parameters {
1935     my $c = shift;
1936     $c->engine->prepare_body_parameters( $c, @_ );
1937 }
1938
1939 =head2 $c->prepare_connection
1940
1941 Prepares connection.
1942
1943 =cut
1944
1945 sub prepare_connection {
1946     my $c = shift;
1947     $c->engine->prepare_connection( $c, @_ );
1948 }
1949
1950 =head2 $c->prepare_cookies
1951
1952 Prepares cookies.
1953
1954 =cut
1955
1956 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1957
1958 =head2 $c->prepare_headers
1959
1960 Prepares headers.
1961
1962 =cut
1963
1964 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1965
1966 =head2 $c->prepare_parameters
1967
1968 Prepares parameters.
1969
1970 =cut
1971
1972 sub prepare_parameters {
1973     my $c = shift;
1974     $c->prepare_body_parameters;
1975     $c->engine->prepare_parameters( $c, @_ );
1976 }
1977
1978 =head2 $c->prepare_path
1979
1980 Prepares path and base.
1981
1982 =cut
1983
1984 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1985
1986 =head2 $c->prepare_query_parameters
1987
1988 Prepares query parameters.
1989
1990 =cut
1991
1992 sub prepare_query_parameters {
1993     my $c = shift;
1994
1995     $c->engine->prepare_query_parameters( $c, @_ );
1996
1997     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1998         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1999         for my $key ( sort keys %{ $c->req->query_parameters } ) {
2000             my $param = $c->req->query_parameters->{$key};
2001             my $value = defined($param) ? $param : '';
2002             $t->row( $key,
2003                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2004         }
2005         $c->log->debug( "Query Parameters are:\n" . $t->draw );
2006     }
2007 }
2008
2009 =head2 $c->prepare_read
2010
2011 Prepares the input for reading.
2012
2013 =cut
2014
2015 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2016
2017 =head2 $c->prepare_request
2018
2019 Prepares the engine request.
2020
2021 =cut
2022
2023 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2024
2025 =head2 $c->prepare_uploads
2026
2027 Prepares uploads.
2028
2029 =cut
2030
2031 sub prepare_uploads {
2032     my $c = shift;
2033
2034     $c->engine->prepare_uploads( $c, @_ );
2035
2036     if ( $c->debug && keys %{ $c->request->uploads } ) {
2037         my $t = Text::SimpleTable->new(
2038             [ 12, 'Parameter' ],
2039             [ 26, 'Filename' ],
2040             [ 18, 'Type' ],
2041             [ 9,  'Size' ]
2042         );
2043         for my $key ( sort keys %{ $c->request->uploads } ) {
2044             my $upload = $c->request->uploads->{$key};
2045             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2046                 $t->row( $key, $u->filename, $u->type, $u->size );
2047             }
2048         }
2049         $c->log->debug( "File Uploads are:\n" . $t->draw );
2050     }
2051 }
2052
2053 =head2 $c->prepare_write
2054
2055 Prepares the output for writing.
2056
2057 =cut
2058
2059 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2060
2061 =head2 $c->request_class
2062
2063 Returns or sets the request class.
2064
2065 =head2 $c->response_class
2066
2067 Returns or sets the response class.
2068
2069 =head2 $c->read( [$maxlength] )
2070
2071 Reads a chunk of data from the request body. This method is designed to
2072 be used in a while loop, reading C<$maxlength> bytes on every call.
2073 C<$maxlength> defaults to the size of the request if not specified.
2074
2075 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
2076 directly.
2077
2078 Warning: If you use read(), Catalyst will not process the body,
2079 so you will not be able to access POST parameters or file uploads via
2080 $c->request.  You must handle all body parsing yourself.
2081
2082 =cut
2083
2084 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2085
2086 =head2 $c->run
2087
2088 Starts the engine.
2089
2090 =cut
2091
2092 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2093
2094 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2095
2096 Sets an action in a given namespace.
2097
2098 =cut
2099
2100 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2101
2102 =head2 $c->setup_actions($component)
2103
2104 Sets up actions for a component.
2105
2106 =cut
2107
2108 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2109
2110 =head2 $c->setup_components
2111
2112 Sets up components. Specify a C<setup_components> config option to pass
2113 additional options directly to L<Module::Pluggable>. To add additional
2114 search paths, specify a key named C<search_extra> as an array
2115 reference. Items in the array beginning with C<::> will have the
2116 application class name prepended to them.
2117
2118 All components found will also have any
2119 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2120 Note, that modules which are B<not> an I<inner package> of the main
2121 file namespace loaded will not be instantiated as components.
2122
2123 =cut
2124
2125 sub setup_components {
2126     my $class = shift;
2127
2128     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2129     my $config  = $class->config->{ setup_components };
2130     my $extra   = delete $config->{ search_extra } || [];
2131
2132     push @paths, @$extra;
2133
2134     my $locator = Module::Pluggable::Object->new(
2135         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2136         %$config
2137     );
2138
2139     my @comps = sort { length $a <=> length $b } $locator->plugins;
2140     my %comps = map { $_ => 1 } @comps;
2141
2142     my $deprecated_component_names = grep { /::[CMV]::/ } @comps;
2143     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2144         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2145     ) if $deprecated_component_names;
2146
2147     for my $component ( @comps ) {
2148
2149         # We pass ignore_loaded here so that overlay files for (e.g.)
2150         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2151         # we know M::P::O found a file on disk so this is safe
2152
2153         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2154         #Class::MOP::load_class($component);
2155
2156         my $module  = $class->setup_component( $component );
2157         my %modules = (
2158             $component => $module,
2159             map {
2160                 $_ => $class->setup_component( $_ )
2161             } grep {
2162               not exists $comps{$_}
2163             } Devel::InnerPackage::list_packages( $component )
2164         );
2165
2166         for my $key ( keys %modules ) {
2167             $class->components->{ $key } = $modules{ $key };
2168         }
2169     }
2170 }
2171
2172 =head2 $c->setup_component
2173
2174 =cut
2175
2176 sub _controller_init_base_classes {
2177     my ($app_class, $component) = @_;
2178     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2179         Moose::Meta::Class->initialize( $class )
2180             unless find_meta($class);
2181     }
2182 }
2183
2184 sub setup_component {
2185     my( $class, $component ) = @_;
2186
2187     unless ( $component->can( 'COMPONENT' ) ) {
2188         return $component;
2189     }
2190
2191     # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2192     #         nearest to Catalyst::Controller first, no matter what order stuff happens
2193     #         to be loaded. There are TODO tests in Moose for this, see
2194     #         f2391d17574eff81d911b97be15ea51080500003
2195     if ($component->isa('Catalyst::Controller')) {
2196         $class->_controller_init_base_classes($component);
2197     }
2198
2199     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2200     my $config = $class->config->{ $suffix } || {};
2201
2202     my $instance = eval { $component->COMPONENT( $class, $config ); };
2203
2204     if ( my $error = $@ ) {
2205         chomp $error;
2206         Catalyst::Exception->throw(
2207             message => qq/Couldn't instantiate component "$component", "$error"/
2208         );
2209     }
2210
2211     unless (blessed $instance) {
2212         my $metaclass = Moose::Util::find_meta($component);
2213         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2214         my $component_method_from = $method_meta->associated_metaclass->name;
2215         my $value = defined($instance) ? $instance : 'undef';
2216         Catalyst::Exception->throw(
2217             message =>
2218             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2219         );
2220     }
2221     return $instance;
2222 }
2223
2224 =head2 $c->setup_dispatcher
2225
2226 Sets up dispatcher.
2227
2228 =cut
2229
2230 sub setup_dispatcher {
2231     my ( $class, $dispatcher ) = @_;
2232
2233     if ($dispatcher) {
2234         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2235     }
2236
2237     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2238         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2239     }
2240
2241     unless ($dispatcher) {
2242         $dispatcher = $class->dispatcher_class;
2243     }
2244
2245     Class::MOP::load_class($dispatcher);
2246
2247     # dispatcher instance
2248     $class->dispatcher( $dispatcher->new );
2249 }
2250
2251 =head2 $c->setup_engine
2252
2253 Sets up engine.
2254
2255 =cut
2256
2257 sub setup_engine {
2258     my ( $class, $engine ) = @_;
2259
2260     if ($engine) {
2261         $engine = 'Catalyst::Engine::' . $engine;
2262     }
2263
2264     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2265         $engine = 'Catalyst::Engine::' . $env;
2266     }
2267
2268     if ( $ENV{MOD_PERL} ) {
2269         my $meta = Class::MOP::get_metaclass_by_name($class);
2270
2271         # create the apache method
2272         $meta->add_method('apache' => sub { shift->engine->apache });
2273
2274         my ( $software, $version ) =
2275           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2276
2277         $version =~ s/_//g;
2278         $version =~ s/(\.[^.]+)\./$1/g;
2279
2280         if ( $software eq 'mod_perl' ) {
2281
2282             if ( !$engine ) {
2283
2284                 if ( $version >= 1.99922 ) {
2285                     $engine = 'Catalyst::Engine::Apache2::MP20';
2286                 }
2287
2288                 elsif ( $version >= 1.9901 ) {
2289                     $engine = 'Catalyst::Engine::Apache2::MP19';
2290                 }
2291
2292                 elsif ( $version >= 1.24 ) {
2293                     $engine = 'Catalyst::Engine::Apache::MP13';
2294                 }
2295
2296                 else {
2297                     Catalyst::Exception->throw( message =>
2298                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2299                 }
2300
2301             }
2302
2303             # install the correct mod_perl handler
2304             if ( $version >= 1.9901 ) {
2305                 *handler = sub  : method {
2306                     shift->handle_request(@_);
2307                 };
2308             }
2309             else {
2310                 *handler = sub ($$) { shift->handle_request(@_) };
2311             }
2312
2313         }
2314
2315         elsif ( $software eq 'Zeus-Perl' ) {
2316             $engine = 'Catalyst::Engine::Zeus';
2317         }
2318
2319         else {
2320             Catalyst::Exception->throw(
2321                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2322         }
2323     }
2324
2325     unless ($engine) {
2326         $engine = $class->engine_class;
2327     }
2328
2329     Class::MOP::load_class($engine);
2330
2331     # check for old engines that are no longer compatible
2332     my $old_engine;
2333     if ( $engine->isa('Catalyst::Engine::Apache')
2334         && !Catalyst::Engine::Apache->VERSION )
2335     {
2336         $old_engine = 1;
2337     }
2338
2339     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2340         && Catalyst::Engine::Server->VERSION le '0.02' )
2341     {
2342         $old_engine = 1;
2343     }
2344
2345     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2346         && $engine->VERSION eq '0.01' )
2347     {
2348         $old_engine = 1;
2349     }
2350
2351     elsif ($engine->isa('Catalyst::Engine::Zeus')
2352         && $engine->VERSION eq '0.01' )
2353     {
2354         $old_engine = 1;
2355     }
2356
2357     if ($old_engine) {
2358         Catalyst::Exception->throw( message =>
2359               qq/Engine "$engine" is not supported by this version of Catalyst/
2360         );
2361     }
2362
2363     # engine instance
2364     $class->engine( $engine->new );
2365 }
2366
2367 =head2 $c->setup_home
2368
2369 Sets up the home directory.
2370
2371 =cut
2372
2373 sub setup_home {
2374     my ( $class, $home ) = @_;
2375
2376     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2377         $home = $env;
2378     }
2379
2380     $home ||= Catalyst::Utils::home($class);
2381
2382     if ($home) {
2383         #I remember recently being scolded for assigning config values like this
2384         $class->config->{home} ||= $home;
2385         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2386     }
2387 }
2388
2389 =head2 $c->setup_log
2390
2391 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2392 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2393 log to.
2394
2395 This method also installs a C<debug> method that returns a true value into the
2396 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2397 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2398
2399 Note that if the log has already been setup, by either a previous call to
2400 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2401 that this method won't actually set up the log object.
2402
2403 =cut
2404
2405 sub setup_log {
2406     my ( $class, $levels ) = @_;
2407
2408     $levels ||= '';
2409     $levels =~ s/^\s+//;
2410     $levels =~ s/\s+$//;
2411     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2412
2413     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2414     if ( defined $env_debug ) {
2415         $levels{debug} = 1 if $env_debug; # Ugly!
2416         delete($levels{debug}) unless $env_debug;
2417     }
2418
2419     unless ( $class->log ) {
2420         $class->log( Catalyst::Log->new(keys %levels) );
2421     }
2422
2423     if ( $levels{debug} ) {
2424         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2425         $class->log->debug('Debug messages enabled');
2426     }
2427 }
2428
2429 =head2 $c->setup_plugins
2430
2431 Sets up plugins.
2432
2433 =cut
2434
2435 =head2 $c->setup_stats
2436
2437 Sets up timing statistics class.
2438
2439 =cut
2440
2441 sub setup_stats {
2442     my ( $class, $stats ) = @_;
2443
2444     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2445
2446     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2447     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2448         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2449         $class->log->debug('Statistics enabled');
2450     }
2451 }
2452
2453
2454 =head2 $c->registered_plugins
2455
2456 Returns a sorted list of the plugins which have either been stated in the
2457 import list or which have been added via C<< MyApp->plugin(@args); >>.
2458
2459 If passed a given plugin name, it will report a boolean value indicating
2460 whether or not that plugin is loaded.  A fully qualified name is required if
2461 the plugin name does not begin with C<Catalyst::Plugin::>.
2462
2463  if ($c->registered_plugins('Some::Plugin')) {
2464      ...
2465  }
2466
2467 =cut
2468
2469 {
2470
2471     sub registered_plugins {
2472         my $proto = shift;
2473         return sort keys %{ $proto->_plugins } unless @_;
2474         my $plugin = shift;
2475         return 1 if exists $proto->_plugins->{$plugin};
2476         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2477     }
2478
2479     sub _register_plugin {
2480         my ( $proto, $plugin, $instant ) = @_;
2481         my $class = ref $proto || $proto;
2482
2483         Class::MOP::load_class( $plugin );
2484
2485         $proto->_plugins->{$plugin} = 1;
2486         unless ($instant) {
2487             no strict 'refs';
2488             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2489               my @superclasses = ($plugin, $meta->superclasses );
2490               $meta->superclasses(@superclasses);
2491             } else {
2492               unshift @{"$class\::ISA"}, $plugin;
2493             }
2494         }
2495         return $class;
2496     }
2497
2498     sub setup_plugins {
2499         my ( $class, $plugins ) = @_;
2500
2501         $class->_plugins( {} ) unless $class->_plugins;
2502         $plugins ||= [];
2503
2504         my @plugins = map { s/\A\+// ? $_ : "Catalyst::Plugin::$_" } @$plugins;
2505
2506         Class::MOP::load_class($_) for @plugins;
2507
2508         for my $plugin ( reverse @plugins ) {
2509             my $meta = find_meta($plugin);
2510             next if $meta && $meta->isa('Moose::Meta::Role');
2511
2512             $class->_register_plugin($plugin);
2513         }
2514
2515         my @roles =
2516             map { $_->name }
2517             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2518             map { find_meta($_) }
2519             @plugins;
2520
2521         Moose::Util::apply_all_roles(
2522             $class => @roles
2523         ) if @roles;
2524     }
2525 }
2526
2527 =head2 $c->stack
2528
2529 Returns an arrayref of the internal execution stack (actions that are
2530 currently executing).
2531
2532 =head2 $c->stats_class
2533
2534 Returns or sets the stats (timing statistics) class.
2535
2536 =head2 $c->use_stats
2537
2538 Returns 1 when stats collection is enabled.  Stats collection is enabled
2539 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2540 environment variable is set.
2541
2542 Note that this is a static method, not an accessor and should be overridden
2543 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2544
2545 =cut
2546
2547 sub use_stats { 0 }
2548
2549
2550 =head2 $c->write( $data )
2551
2552 Writes $data to the output stream. When using this method directly, you
2553 will need to manually set the C<Content-Length> header to the length of
2554 your output data, if known.
2555
2556 =cut
2557
2558 sub write {
2559     my $c = shift;
2560
2561     # Finalize headers if someone manually writes output
2562     $c->finalize_headers;
2563
2564     return $c->engine->write( $c, @_ );
2565 }
2566
2567 =head2 version
2568
2569 Returns the Catalyst version number. Mostly useful for "powered by"
2570 messages in template systems.
2571
2572 =cut
2573
2574 sub version { return $Catalyst::VERSION }
2575
2576 =head1 INTERNAL ACTIONS
2577
2578 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2579 C<_ACTION>, and C<_END>. These are by default not shown in the private
2580 action table, but you can make them visible with a config parameter.
2581
2582     MyApp->config->{show_internal_actions} = 1;
2583
2584 =head1 CASE SENSITIVITY
2585
2586 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2587 mapped to C</foo/bar>. You can activate case sensitivity with a config
2588 parameter.
2589
2590     MyApp->config->{case_sensitive} = 1;
2591
2592 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2593
2594 =head1 ON-DEMAND PARSER
2595
2596 The request body is usually parsed at the beginning of a request,
2597 but if you want to handle input yourself, you can enable on-demand
2598 parsing with a config parameter.
2599
2600     MyApp->config->{parse_on_demand} = 1;
2601
2602 =head1 PROXY SUPPORT
2603
2604 Many production servers operate using the common double-server approach,
2605 with a lightweight frontend web server passing requests to a larger
2606 backend server. An application running on the backend server must deal
2607 with two problems: the remote user always appears to be C<127.0.0.1> and
2608 the server's hostname will appear to be C<localhost> regardless of the
2609 virtual host that the user connected through.
2610
2611 Catalyst will automatically detect this situation when you are running
2612 the frontend and backend servers on the same machine. The following
2613 changes are made to the request.
2614
2615     $c->req->address is set to the user's real IP address, as read from
2616     the HTTP X-Forwarded-For header.
2617
2618     The host value for $c->req->base and $c->req->uri is set to the real
2619     host, as read from the HTTP X-Forwarded-Host header.
2620
2621 Obviously, your web server must support these headers for this to work.
2622
2623 In a more complex server farm environment where you may have your
2624 frontend proxy server(s) on different machines, you will need to set a
2625 configuration option to tell Catalyst to read the proxied data from the
2626 headers.
2627
2628     MyApp->config->{using_frontend_proxy} = 1;
2629
2630 If you do not wish to use the proxy support at all, you may set:
2631
2632     MyApp->config->{ignore_frontend_proxy} = 1;
2633
2634 =head1 THREAD SAFETY
2635
2636 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2637 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2638 believe the Catalyst core to be thread-safe.
2639
2640 If you plan to operate in a threaded environment, remember that all other
2641 modules you are using must also be thread-safe. Some modules, most notably
2642 L<DBD::SQLite>, are not thread-safe.
2643
2644 =head1 SUPPORT
2645
2646 IRC:
2647
2648     Join #catalyst on irc.perl.org.
2649
2650 Mailing Lists:
2651
2652     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2653     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2654
2655 Web:
2656
2657     http://catalyst.perl.org
2658
2659 Wiki:
2660
2661     http://dev.catalyst.perl.org
2662
2663 =head1 SEE ALSO
2664
2665 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2666
2667 =head2 L<Catalyst::Manual> - The Catalyst Manual
2668
2669 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2670
2671 =head2 L<Catalyst::Engine> - Core engine
2672
2673 =head2 L<Catalyst::Log> - Log class.
2674
2675 =head2 L<Catalyst::Request> - Request object
2676
2677 =head2 L<Catalyst::Response> - Response object
2678
2679 =head2 L<Catalyst::Test> - The test suite.
2680
2681 =head1 PROJECT FOUNDER
2682
2683 sri: Sebastian Riedel <sri@cpan.org>
2684
2685 =head1 CONTRIBUTORS
2686
2687 abw: Andy Wardley
2688
2689 acme: Leon Brocard <leon@astray.com>
2690
2691 Andrew Bramble
2692
2693 Andrew Ford
2694
2695 Andrew Ruthven
2696
2697 andyg: Andy Grundman <andy@hybridized.org>
2698
2699 audreyt: Audrey Tang
2700
2701 bricas: Brian Cassidy <bricas@cpan.org>
2702
2703 Caelum: Rafael Kitover <rkitover@io.com>
2704
2705 chansen: Christian Hansen
2706
2707 chicks: Christopher Hicks
2708
2709 David E. Wheeler
2710
2711 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2712
2713 Drew Taylor
2714
2715 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2716
2717 esskar: Sascha Kiefer
2718
2719 fireartist: Carl Franks <cfranks@cpan.org>
2720
2721 gabb: Danijel Milicevic
2722
2723 Gary Ashton Jones
2724
2725 Geoff Richards
2726
2727 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2728
2729 jcamacho: Juan Camacho
2730
2731 jhannah: Jay Hannah <jay@jays.net>
2732
2733 Jody Belka
2734
2735 Johan Lindstrom
2736
2737 jon: Jon Schutz <jjschutz@cpan.org>
2738
2739 marcus: Marcus Ramberg <mramberg@cpan.org>
2740
2741 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2742
2743 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2744
2745 mugwump: Sam Vilain
2746
2747 naughton: David Naughton
2748
2749 ningu: David Kamholz <dkamholz@cpan.org>
2750
2751 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2752
2753 numa: Dan Sully <daniel@cpan.org>
2754
2755 obra: Jesse Vincent
2756
2757 omega: Andreas Marienborg
2758
2759 Oleg Kostyuk <cub.uanic@gmail.com>
2760
2761 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2762
2763 rafl: Florian Ragwitz <rafl@debian.org>
2764
2765 random: Roland Lammel <lammel@cpan.org>
2766
2767 sky: Arthur Bergman
2768
2769 the_jester: Jesse Sheidlower
2770
2771 t0m: Tomas Doran <bobtfish@bobtfish.net>
2772
2773 Ulf Edvinsson
2774
2775 willert: Sebastian Willert <willert@cpan.org>
2776
2777 =head1 LICENSE
2778
2779 This library is free software, you can redistribute it and/or modify it under
2780 the same terms as Perl itself.
2781
2782 =cut
2783
2784 no Moose;
2785
2786 __PACKAGE__->meta->make_immutable;
2787
2788 1;