lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use Text::SimpleTable ();
  17 use Path::Class::Dir ();
  18 use Path::Class::File ();
  19 use Time::HiRes qw/gettimeofday tv_interval/;
  20 use URI ();
  21 use URI::http;
  22 use URI::https;
  23 use Scalar::Util qw/weaken blessed/;
  24 use Tree::Simple qw/use_weak_refs/;
  25 use Tree::Simple::Visitor::FindByUID;
  26 use attributes;
  27 use utf8;
  28 use Carp qw/croak carp/;
  29
  30 BEGIN { require 5.008001; }
  31
  32 has stack => (is => 'rw', default => sub { [] });
  33 has stash => (is => 'rw', default => sub { {} });
  34 has state => (is => 'rw', default => 0);
  35 has stats => (is => 'rw');
  36 has action => (is => 'rw');
  37 has counter => (is => 'rw', default => sub { {} });
  38 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  39 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  40 has namespace => (is => 'rw');
  41
  42 sub depth { scalar @{ shift->stack || [] }; }
  43 sub comp { shift->component(@_) }
  44
  45 sub req {
  46     # carp "the use of req() is deprecated in favour of request()";
  47     my $self = shift; return $self->request(@_);
  48 }
  49 sub res {
  50     # carp "the use of res() is deprecated in favour of response()";
  51     my $self = shift; return $self->response(@_);
  52 }
  53
  54 # For backwards compatibility
  55 sub finalize_output { shift->finalize_body(@_) };
  56
  57 # For statistics
  58 our $COUNT     = 1;
  59 our $START     = time;
  60 our $RECURSION = 1000;
  61 our $DETACH    = "catalyst_detach\n";
  62 our $GO        = "catalyst_go\n";
  63
  64 #I imagine that very few of these really need to be class variables. if any.
  65 #maybe we should just make them attributes with a default?
  66 __PACKAGE__->mk_classdata($_)
  67   for qw/components arguments dispatcher engine log dispatcher_class
  68   engine_class context_class request_class response_class stats_class
  69   setup_finished/;
  70
  71 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  72 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  73 __PACKAGE__->request_class('Catalyst::Request');
  74 __PACKAGE__->response_class('Catalyst::Response');
  75 __PACKAGE__->stats_class('Catalyst::Stats');
  76
  77 # Remember to update this in Catalyst::Runtime as well!
  78
  79 our $VERSION = '5.7099_03';
  80
  81 sub import {
  82     my ( $class, @arguments ) = @_;
  83
  84     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  85     # callers @ISA.
  86     return unless $class eq 'Catalyst';
  87
  88     my $caller = caller();
  89     return if $caller eq 'main';
  90     my $meta = Moose::Meta::Class->initialize($caller);
  91     #Moose->import({ into => $caller }); #do we want to do this?
  92
  93     unless ( $caller->isa('Catalyst') ) {
  94         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  95         $meta->superclasses(@superclasses);
  96     }
  97     unless( $meta->has_method('meta') ){
  98         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
  99     }
 100
 101     $caller->arguments( [@arguments] );
 102     $caller->setup_home;
 103 }
 104
 105 =head1 NAME
 106
 107 Catalyst - The Elegant MVC Web Application Framework
 108
 109 =head1 SYNOPSIS
 110
 111 See the L<Catalyst::Manual> distribution for comprehensive
 112 documentation and tutorials.
 113
 114     # Install Catalyst::Devel for helpers and other development tools
 115     # use the helper to create a new application
 116     catalyst.pl MyApp
 117
 118     # add models, views, controllers
 119     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 120     script/myapp_create.pl view MyTemplate TT
 121     script/myapp_create.pl controller Search
 122
 123     # built in testserver -- use -r to restart automatically on changes
 124     # --help to see all available options
 125     script/myapp_server.pl
 126
 127     # command line testing interface
 128     script/myapp_test.pl /yada
 129
 130     ### in lib/MyApp.pm
 131     use Catalyst qw/-Debug/; # include plugins here as well
 132
 133     ### In lib/MyApp/Controller/Root.pm (autocreated)
 134     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 135         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 136         $c->stash->{template} = 'foo.tt'; # set the template
 137         # lookup something from db -- stash vars are passed to TT
 138         $c->stash->{data} =
 139           $c->model('Database::Foo')->search( { country => $args[0] } );
 140         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 141             $c->forward( 'bar' ); # process another action
 142             # do something else after forward returns
 143         }
 144     }
 145
 146     # The foo.tt TT template can use the stash data from the database
 147     [% WHILE (item = data.next) %]
 148         [% item.foo %]
 149     [% END %]
 150
 151     # called for /bar/of/soap, /bar/of/soap/10, etc.
 152     sub bar : Path('/bar/of/soap') { ... }
 153
 154     # called for all actions, from the top-most controller downwards
 155     sub auto : Private {
 156         my ( $self, $c ) = @_;
 157         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 158             $c->res->redirect( '/login' ); # require login
 159             return 0; # abort request and go immediately to end()
 160         }
 161         return 1; # success; carry on to next action
 162     }
 163
 164     # called after all actions are finished
 165     sub end : Private {
 166         my ( $self, $c ) = @_;
 167         if ( scalar @{ $c->error } ) { ... } # handle errors
 168         return if $c->res->body; # already have a response
 169         $c->forward( 'MyApp::View::TT' ); # render template
 170     }
 171
 172     ### in MyApp/Controller/Foo.pm
 173     # called for /foo/bar
 174     sub bar : Local { ... }
 175
 176     # called for /blargle
 177     sub blargle : Global { ... }
 178
 179     # an index action matches /foo, but not /foo/1, etc.
 180     sub index : Private { ... }
 181
 182     ### in MyApp/Controller/Foo/Bar.pm
 183     # called for /foo/bar/baz
 184     sub baz : Local { ... }
 185
 186     # first Root auto is called, then Foo auto, then this
 187     sub auto : Private { ... }
 188
 189     # powerful regular expression paths are also possible
 190     sub details : Regex('^product/(\w+)/details$') {
 191         my ( $self, $c ) = @_;
 192         # extract the (\w+) from the URI
 193         my $product = $c->req->captures->[0];
 194     }
 195
 196 See L<Catalyst::Manual::Intro> for additional information.
 197
 198 =head1 DESCRIPTION
 199
 200 Catalyst is a modern framework for making web applications without the
 201 pain usually associated with this process. This document is a reference
 202 to the main Catalyst application. If you are a new user, we suggest you
 203 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 204
 205 See L<Catalyst::Manual> for more documentation.
 206
 207 Catalyst plugins can be loaded by naming them as arguments to the "use
 208 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 209 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 210 C<My::Module>.
 211
 212     use Catalyst qw/My::Module/;
 213
 214 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 215 fully qualify the name by using a unary plus:
 216
 217     use Catalyst qw/
 218         My::Module
 219         +Fully::Qualified::Plugin::Name
 220     /;
 221
 222 Special flags like C<-Debug> and C<-Engine> can also be specified as
 223 arguments when Catalyst is loaded:
 224
 225     use Catalyst qw/-Debug My::Module/;
 226
 227 The position of plugins and flags in the chain is important, because
 228 they are loaded in the order in which they appear.
 229
 230 The following flags are supported:
 231
 232 =head2 -Debug
 233
 234 Enables debug output. You can also force this setting from the system
 235 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 236 settings override the application, with <MYAPP>_DEBUG having the highest
 237 priority.
 238
 239 =head2 -Engine
 240
 241 Forces Catalyst to use a specific engine. Omit the
 242 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 243
 244     use Catalyst qw/-Engine=CGI/;
 245
 246 =head2 -Home
 247
 248 Forces Catalyst to use a specific home directory, e.g.:
 249
 250     use Catalyst qw[-Home=/usr/mst];
 251
 252 This can also be done in the shell environment by setting either the
 253 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 254 is replaced with the uppercased name of your application, any "::" in
 255 the name will be replaced with underscores, e.g. MyApp::Web should use
 256 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 257
 258 =head2 -Log
 259
 260 Specifies log level.
 261
 262 =head2 -Stats
 263
 264 Enables statistics collection and reporting. You can also force this setting
 265 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 266 environment settings override the application, with <MYAPP>_STATS having the
 267 highest priority.
 268
 269 e.g.
 270
 271    use Catalyst qw/-Stats=1/
 272
 273 =head1 METHODS
 274
 275 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 276
 277 =head2 $c->action
 278
 279 Returns a L<Catalyst::Action> object for the current action, which
 280 stringifies to the action name. See L<Catalyst::Action>.
 281
 282 =head2 $c->namespace
 283
 284 Returns the namespace of the current action, i.e., the URI prefix
 285 corresponding to the controller of the current action. For example:
 286
 287     # in Controller::Foo::Bar
 288     $c->namespace; # returns 'foo/bar';
 289
 290 =head2 $c->request
 291
 292 =head2 $c->req
 293
 294 Returns the current L<Catalyst::Request> object, giving access to
 295 information about the current client request (including parameters,
 296 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 297
 298 =head2 REQUEST FLOW HANDLING
 299
 300 =head2 $c->forward( $action [, \@arguments ] )
 301
 302 =head2 $c->forward( $class, $method, [, \@arguments ] )
 303
 304 Forwards processing to another action, by its private name. If you give a
 305 class name but no method, C<process()> is called. You may also optionally
 306 pass arguments in an arrayref. The action will receive the arguments in
 307 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 308 C<< $c->req->args >> will be restored to the previous values.
 309
 310 Any data C<return>ed from the action forwarded to, will be returned by the
 311 call to forward.
 312
 313     my $foodata = $c->forward('/foo');
 314     $c->forward('index');
 315     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 316     $c->forward('MyApp::View::TT');
 317
 318 Note that forward implies an C<<eval { }>> around the call (actually
 319 C<execute> does), thus de-fatalizing all 'dies' within the called
 320 action. If you want C<die> to propagate you need to do something like:
 321
 322     $c->forward('foo');
 323     die $c->error if $c->error;
 324
 325 Or make sure to always return true values from your actions and write
 326 your code like this:
 327
 328     $c->forward('foo') || return;
 329
 330 =cut
 331
 332 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 333
 334 =head2 $c->detach( $action [, \@arguments ] )
 335
 336 =head2 $c->detach( $class, $method, [, \@arguments ] )
 337
 338 =head2 $c->detach()
 339
 340 The same as C<forward>, but doesn't return to the previous action when
 341 processing is finished.
 342
 343 When called with no arguments it escapes the processing chain entirely.
 344
 345 =cut
 346
 347 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 348
 349 =head2 $c->visit( $action [, \@arguments ] )
 350
 351 =head2 $c->visit( $class, $method, [, \@arguments ] )
 352
 353 Almost the same as C<forward>, but does a full dispatch, instead of just
 354 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 355 C<auto> and the method you go to are called, just like a new request.
 356
 357 C<$c-E<gt>stash> is kept unchanged.
 358
 359 In effect, C<visit> allows you to "wrap" another action, just as it
 360 would have been called by dispatching from a URL, while the analogous
 361 C<go> allows you to transfer control to another action as if it had
 362 been reached directly from a URL.
 363
 364 =cut
 365
 366 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 367
 368 =head2 $c->go( $action [, \@arguments ] )
 369
 370 =head2 $c->go( $class, $method, [, \@arguments ] )
 371
 372 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 373 instead of just calling the new C<$action> /
 374 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 375 method you visit are called, just like a new request.
 376
 377 C<$c-E<gt>stash> is kept unchanged.
 378
 379 =cut
 380
 381 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 382
 383 =head2 $c->response
 384
 385 =head2 $c->res
 386
 387 Returns the current L<Catalyst::Response> object, see there for details.
 388
 389 =head2 $c->stash
 390
 391 Returns a hashref to the stash, which may be used to store data and pass
 392 it between components during a request. You can also set hash keys by
 393 passing arguments. The stash is automatically sent to the view. The
 394 stash is cleared at the end of a request; it cannot be used for
 395 persistent storage (for this you must use a session; see
 396 L<Catalyst::Plugin::Session> for a complete system integrated with
 397 Catalyst).
 398
 399     $c->stash->{foo} = $bar;
 400     $c->stash( { moose => 'majestic', qux => 0 } );
 401     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 402
 403     # stash is automatically passed to the view for use in a template
 404     $c->forward( 'MyApp::View::TT' );
 405
 406 =cut
 407
 408 around stash => sub {
 409     my $orig = shift;
 410     my $c = shift;
 411     my $stash = $orig->($c);
 412     if (@_) {
 413         my $new_stash = @_ > 1 ? {@_} : $_[0];
 414         croak('stash takes a hash or hashref') unless ref $new_stash;
 415         foreach my $key ( keys %$new_stash ) {
 416           $stash->{$key} = $new_stash->{$key};
 417         }
 418     }
 419
 420     return $stash;
 421 };
 422
 423
 424 =head2 $c->error
 425
 426 =head2 $c->error($error, ...)
 427
 428 =head2 $c->error($arrayref)
 429
 430 Returns an arrayref containing error messages.  If Catalyst encounters an
 431 error while processing a request, it stores the error in $c->error.  This
 432 method should only be used to store fatal error messages.
 433
 434     my @error = @{ $c->error };
 435
 436 Add a new error.
 437
 438     $c->error('Something bad happened');
 439
 440 =cut
 441
 442 sub error {
 443     my $c = shift;
 444     if ( $_[0] ) {
 445         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 446         croak @$error unless ref $c;
 447         push @{ $c->{error} }, @$error;
 448     }
 449     elsif ( defined $_[0] ) { $c->{error} = undef }
 450     return $c->{error} || [];
 451 }
 452
 453
 454 =head2 $c->state
 455
 456 Contains the return value of the last executed action.
 457
 458 =head2 $c->clear_errors
 459
 460 Clear errors.  You probably don't want to clear the errors unless you are
 461 implementing a custom error screen.
 462
 463 This is equivalent to running
 464
 465     $c->error(0);
 466
 467 =cut
 468
 469 sub clear_errors {
 470     my $c = shift;
 471     $c->error(0);
 472 }
 473
 474 # search components given a name and some prefixes
 475 sub _comp_search_prefixes {
 476     my ( $c, $name, @prefixes ) = @_;
 477     my $appclass = ref $c || $c;
 478     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 479
 480     # map the original component name to the sub part that we will search against
 481     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 482         grep { /$filter/ } keys %{ $c->components };
 483
 484     # undef for a name will return all
 485     return keys %eligible if !defined $name;
 486
 487     my $query  = ref $name ? $name : qr/^$name$/i;
 488     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 489
 490     return map { $c->components->{ $_ } } @result if @result;
 491
 492     # if we were given a regexp to search against, we're done.
 493     return if ref $name;
 494
 495     # regexp fallback
 496     $query  = qr/$name/i;
 497     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 498
 499     # no results? try against full names
 500     if( !@result ) {
 501         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 502     }
 503
 504     # don't warn if we didn't find any results, it just might not exist
 505     if( @result ) {
 506         $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 507         $c->log->warn( 'Relying on the regexp fallback behavior for component resolution is unreliable and unsafe.' );
 508         $c->log->warn( 'If you really want to search, pass in a regexp as the argument.' );
 509     }
 510
 511     return @result;
 512 }
 513
 514 # Find possible names for a prefix
 515 sub _comp_names {
 516     my ( $c, @prefixes ) = @_;
 517     my $appclass = ref $c || $c;
 518
 519     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 520
 521     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 522     return @names;
 523 }
 524
 525 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 526 sub _filter_component {
 527     my ( $c, $comp, @args ) = @_;
 528
 529     if ( Scalar::Util::blessed($c) && eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 530         return $comp->ACCEPT_CONTEXT( $c, @args );
 531     }
 532
 533     return $comp;
 534 }
 535
 536 =head2 COMPONENT ACCESSORS
 537
 538 =head2 $c->controller($name)
 539
 540 Gets a L<Catalyst::Controller> instance by name.
 541
 542     $c->controller('Foo')->do_stuff;
 543
 544 If the name is omitted, will return the controller for the dispatched
 545 action.
 546
 547 If you want to search for controllers, pass in a regexp as the argument.
 548
 549     # find all controllers that start with Foo
 550     my @foo_controllers = $c->controller(qr{^Foo});
 551
 552
 553 =cut
 554
 555 sub controller {
 556     my ( $c, $name, @args ) = @_;
 557
 558     if( $name ) {
 559         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 560         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 561         return $c->_filter_component( $result[ 0 ], @args );
 562     }
 563
 564     return $c->component( $c->action->class );
 565 }
 566
 567 =head2 $c->model($name)
 568
 569 Gets a L<Catalyst::Model> instance by name.
 570
 571     $c->model('Foo')->do_stuff;
 572
 573 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 574
 575 If the name is omitted, it will look for
 576  - a model object in $c->stash->{current_model_instance}, then
 577  - a model name in $c->stash->{current_model}, then
 578  - a config setting 'default_model', or
 579  - check if there is only one model, and return it if that's the case.
 580
 581 If you want to search for models, pass in a regexp as the argument.
 582
 583     # find all models that start with Foo
 584     my @foo_models = $c->model(qr{^Foo});
 585
 586 =cut
 587
 588 sub model {
 589     my ( $c, $name, @args ) = @_;
 590
 591     if( $name ) {
 592         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 593         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 594         return $c->_filter_component( $result[ 0 ], @args );
 595     }
 596
 597     if (ref $c) {
 598         return $c->stash->{current_model_instance}
 599           if $c->stash->{current_model_instance};
 600         return $c->model( $c->stash->{current_model} )
 601           if $c->stash->{current_model};
 602     }
 603     return $c->model( $c->config->{default_model} )
 604       if $c->config->{default_model};
 605
 606     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 607
 608     if( $rest ) {
 609         $c->log->warn( 'Calling $c->model() will return a random model unless you specify one of:' );
 610         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 611         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 612         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 613         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 614     }
 615
 616     return $c->_filter_component( $comp );
 617 }
 618
 619
 620 =head2 $c->view($name)
 621
 622 Gets a L<Catalyst::View> instance by name.
 623
 624     $c->view('Foo')->do_stuff;
 625
 626 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 627
 628 If the name is omitted, it will look for
 629  - a view object in $c->stash->{current_view_instance}, then
 630  - a view name in $c->stash->{current_view}, then
 631  - a config setting 'default_view', or
 632  - check if there is only one view, and return it if that's the case.
 633
 634 If you want to search for views, pass in a regexp as the argument.
 635
 636     # find all views that start with Foo
 637     my @foo_views = $c->view(qr{^Foo});
 638
 639 =cut
 640
 641 sub view {
 642     my ( $c, $name, @args ) = @_;
 643
 644     if( $name ) {
 645         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 646         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 647         return $c->_filter_component( $result[ 0 ], @args );
 648     }
 649
 650     if (ref $c) {
 651         return $c->stash->{current_view_instance}
 652           if $c->stash->{current_view_instance};
 653         return $c->view( $c->stash->{current_view} )
 654           if $c->stash->{current_view};
 655     }
 656     return $c->view( $c->config->{default_view} )
 657       if $c->config->{default_view};
 658
 659     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 660
 661     if( $rest ) {
 662         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 663         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 664         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 665         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 666         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 667     }
 668
 669     return $c->_filter_component( $comp );
 670 }
 671
 672 =head2 $c->controllers
 673
 674 Returns the available names which can be passed to $c->controller
 675
 676 =cut
 677
 678 sub controllers {
 679     my ( $c ) = @_;
 680     return $c->_comp_names(qw/Controller C/);
 681 }
 682
 683 =head2 $c->models
 684
 685 Returns the available names which can be passed to $c->model
 686
 687 =cut
 688
 689 sub models {
 690     my ( $c ) = @_;
 691     return $c->_comp_names(qw/Model M/);
 692 }
 693
 694
 695 =head2 $c->views
 696
 697 Returns the available names which can be passed to $c->view
 698
 699 =cut
 700
 701 sub views {
 702     my ( $c ) = @_;
 703     return $c->_comp_names(qw/View V/);
 704 }
 705
 706 =head2 $c->comp($name)
 707
 708 =head2 $c->component($name)
 709
 710 Gets a component object by name. This method is not recommended,
 711 unless you want to get a specific component by full
 712 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 713 should be used instead.
 714
 715 If C<$name> is a regexp, a list of components matched against the full
 716 component name will be returned.
 717
 718 =cut
 719
 720 sub component {
 721     my ( $c, $name, @args ) = @_;
 722
 723     if( $name ) {
 724         my $comps = $c->components;
 725
 726         if( !ref $name ) {
 727             # is it the exact name?
 728             return $c->_filter_component( $comps->{ $name }, @args )
 729                        if exists $comps->{ $name };
 730
 731             # perhaps we just omitted "MyApp"?
 732             my $composed = ( ref $c || $c ) . "::${name}";
 733             return $c->_filter_component( $comps->{ $composed }, @args )
 734                        if exists $comps->{ $composed };
 735
 736             # search all of the models, views and controllers
 737             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 738             return $c->_filter_component( $comp, @args ) if $comp;
 739         }
 740
 741         # This is here so $c->comp( '::M::' ) works
 742         my $query = ref $name ? $name : qr{$name}i;
 743
 744         my @result = grep { m{$query} } keys %{ $c->components };
 745         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 746
 747         if( $result[ 0 ] ) {
 748             $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 749             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 750             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 751             return $c->_filter_component( $result[ 0 ], @args );
 752         }
 753
 754         # I would expect to return an empty list here, but that breaks back-compat
 755     }
 756
 757     # fallback
 758     return sort keys %{ $c->components };
 759 }
 760
 761 =head2 CLASS DATA AND HELPER CLASSES
 762
 763 =head2 $c->config
 764
 765 Returns or takes a hashref containing the application's configuration.
 766
 767     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 768
 769 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 770 like myapp.yml in your applications home directory. See
 771 L<Catalyst::Plugin::ConfigLoader>.
 772
 773     ---
 774     db: dsn:SQLite:foo.db
 775
 776
 777 =cut
 778
 779 around config => sub {
 780     my $orig = shift;
 781     my $c = shift;
 782
 783     $c->log->warn("Setting config after setup has been run is not a good idea.")
 784       if ( @_ and $c->setup_finished );
 785
 786     $c->$orig(@_);
 787 };
 788
 789 =head2 $c->log
 790
 791 Returns the logging object instance. Unless it is already set, Catalyst
 792 sets this up with a L<Catalyst::Log> object. To use your own log class,
 793 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 794 C<< __PACKAGE__->setup >>.
 795
 796  __PACKAGE__->log( MyLogger->new );
 797  __PACKAGE__->setup;
 798
 799 And later:
 800
 801     $c->log->info( 'Now logging with my own logger!' );
 802
 803 Your log class should implement the methods described in
 804 L<Catalyst::Log>.
 805
 806
 807 =head2 $c->debug
 808
 809 Overload to enable debug messages (same as -Debug option).
 810
 811 Note that this is a static method, not an accessor and should be overloaded
 812 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 813
 814 =cut
 815
 816 sub debug { 0 }
 817
 818 =head2 $c->dispatcher
 819
 820 Returns the dispatcher instance. Stringifies to class name. See
 821 L<Catalyst::Dispatcher>.
 822
 823 =head2 $c->engine
 824
 825 Returns the engine instance. Stringifies to the class name. See
 826 L<Catalyst::Engine>.
 827
 828
 829 =head2 UTILITY METHODS
 830
 831 =head2 $c->path_to(@path)
 832
 833 Merges C<@path> with C<< $c->config->{home} >> and returns a
 834 L<Path::Class::Dir> object.
 835
 836 For example:
 837
 838     $c->path_to( 'db', 'sqlite.db' );
 839
 840 =cut
 841
 842 sub path_to {
 843     my ( $c, @path ) = @_;
 844     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 845     if ( -d $path ) { return $path }
 846     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 847 }
 848
 849 =head2 $c->plugin( $name, $class, @args )
 850
 851 Helper method for plugins. It creates a classdata accessor/mutator and
 852 loads and instantiates the given class.
 853
 854     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 855
 856     $c->prototype->define_javascript_functions;
 857
 858 =cut
 859
 860 sub plugin {
 861     my ( $class, $name, $plugin, @args ) = @_;
 862     $class->_register_plugin( $plugin, 1 );
 863
 864     eval { $plugin->import };
 865     $class->mk_classdata($name);
 866     my $obj;
 867     eval { $obj = $plugin->new(@args) };
 868
 869     if ($@) {
 870         Catalyst::Exception->throw( message =>
 871               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 872     }
 873
 874     $class->$name($obj);
 875     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 876       if $class->debug;
 877 }
 878
 879 =head2 MyApp->setup
 880
 881 Initializes the dispatcher and engine, loads any plugins, and loads the
 882 model, view, and controller components. You may also specify an array
 883 of plugins to load here, if you choose to not load them in the C<use
 884 Catalyst> line.
 885
 886     MyApp->setup;
 887     MyApp->setup( qw/-Debug/ );
 888
 889 =cut
 890
 891 sub setup {
 892     my ( $class, @arguments ) = @_;
 893     $class->log->warn("Running setup twice is not a good idea.")
 894       if ( $class->setup_finished );
 895
 896     unless ( $class->isa('Catalyst') ) {
 897
 898         Catalyst::Exception->throw(
 899             message => qq/'$class' does not inherit from Catalyst/ );
 900     }
 901
 902     if ( $class->arguments ) {
 903         @arguments = ( @arguments, @{ $class->arguments } );
 904     }
 905
 906     # Process options
 907     my $flags = {};
 908
 909     foreach (@arguments) {
 910
 911         if (/^-Debug$/) {
 912             $flags->{log} =
 913               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 914         }
 915         elsif (/^-(\w+)=?(.*)$/) {
 916             $flags->{ lc $1 } = $2;
 917         }
 918         else {
 919             push @{ $flags->{plugins} }, $_;
 920         }
 921     }
 922
 923     $class->setup_home( delete $flags->{home} );
 924
 925     $class->setup_log( delete $flags->{log} );
 926     $class->setup_plugins( delete $flags->{plugins} );
 927     $class->setup_dispatcher( delete $flags->{dispatcher} );
 928     $class->setup_engine( delete $flags->{engine} );
 929     $class->setup_stats( delete $flags->{stats} );
 930
 931     for my $flag ( sort keys %{$flags} ) {
 932
 933         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 934             &$code( $class, delete $flags->{$flag} );
 935         }
 936         else {
 937             $class->log->warn(qq/Unknown flag "$flag"/);
 938         }
 939     }
 940
 941     eval { require Catalyst::Devel; };
 942     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 943         $class->log->warn(<<"EOF");
 944 You are running an old script!
 945
 946   Please update by running (this will overwrite existing files):
 947     catalyst.pl -force -scripts $class
 948
 949   or (this will not overwrite existing files):
 950     catalyst.pl -scripts $class
 951
 952 EOF
 953     }
 954
 955     if ( $class->debug ) {
 956         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 957
 958         if (@plugins) {
 959             my $t = Text::SimpleTable->new(74);
 960             $t->row($_) for @plugins;
 961             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 962         }
 963
 964         my $dispatcher = $class->dispatcher;
 965         my $engine     = $class->engine;
 966         my $home       = $class->config->{home};
 967
 968         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 969         $class->log->debug(qq/Loaded engine "$engine"/);
 970
 971         $home
 972           ? ( -d $home )
 973           ? $class->log->debug(qq/Found home "$home"/)
 974           : $class->log->debug(qq/Home "$home" doesn't exist/)
 975           : $class->log->debug(q/Couldn't find home/);
 976     }
 977
 978     # Call plugins setup
 979     {
 980         no warnings qw/redefine/;
 981         local *setup = sub { };
 982         $class->setup;
 983     }
 984
 985     # Initialize our data structure
 986     $class->components( {} );
 987
 988     $class->setup_components;
 989
 990     if ( $class->debug ) {
 991         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 992         for my $comp ( sort keys %{ $class->components } ) {
 993             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 994             $t->row( $comp, $type );
 995         }
 996         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 997           if ( keys %{ $class->components } );
 998     }
 999
1000     # Add our self to components, since we are also a component
1001     if( $class->isa('Catalyst::Controller') ){
1002       $class->components->{$class} = $class;
1003     }
1004
1005     $class->setup_actions;
1006
1007     if ( $class->debug ) {
1008         my $name = $class->config->{name} || 'Application';
1009         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1010     }
1011     $class->log->_flush() if $class->log->can('_flush');
1012
1013     $class->setup_finished(1);
1014 }
1015
1016 =head2 $c->uri_for( $path, @args?, \%query_values? )
1017
1018 Merges path with C<< $c->request->base >> for absolute URIs and with
1019 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
1020 object. If any args are passed, they are added at the end of the path.
1021 If the last argument to C<uri_for> is a hash reference, it is assumed to
1022 contain GET parameter key/value pairs, which will be appended to the URI
1023 in standard fashion.
1024
1025 Note that uri_for is destructive to the passed hashref.  Subsequent calls
1026 with the same hashref may have unintended results.
1027
1028 Instead of C<$path>, you can also optionally pass a C<$action> object
1029 which will be resolved to a path using
1030 C<< $c->dispatcher->uri_for_action >>; if the first element of
1031 C<@args> is an arrayref it is treated as a list of captures to be passed
1032 to C<uri_for_action>.
1033
1034 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1035 using C<< $c->req->captures >>.
1036
1037   # For the current action
1038   $c->uri_for($c->action, $c->req->captures);
1039
1040   # For the Foo action in the Bar controller
1041   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1042
1043 =cut
1044
1045 sub uri_for {
1046     my ( $c, $path, @args ) = @_;
1047
1048     if ( Scalar::Util::blessed($path) ) { # action object
1049         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1050                          ? shift(@args)
1051                          : [] );
1052         $path = $c->dispatcher->uri_for_action($path, $captures);
1053         return undef unless defined($path);
1054         $path = '/' if $path eq '';
1055     }
1056
1057     undef($path) if (defined $path && $path eq '');
1058
1059     my $params =
1060       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1061
1062     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1063     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1064
1065     unshift(@args, $path);
1066
1067     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1068         my $namespace = $c->namespace;
1069         if (defined $path) { # cheesy hack to handle path '../foo'
1070            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1071         }
1072         unshift(@args, $namespace || '');
1073     }
1074
1075     # join args with '/', or a blank string
1076     my $args = join('/', grep { defined($_) } @args);
1077     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1078     $args =~ s!^/!!;
1079     my $base = $c->req->base;
1080     my $class = ref($base);
1081     $base =~ s{(?<!/)$}{/};
1082
1083     my $query = '';
1084
1085     if (my @keys = keys %$params) {
1086       # somewhat lifted from URI::_query's query_form
1087       $query = '?'.join('&', map {
1088           my $val = $params->{$_};
1089           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1090           s/ /+/g;
1091           my $key = $_;
1092           $val = '' unless defined $val;
1093           (map {
1094               $_ = "$_";
1095               utf8::encode( $_ ) if utf8::is_utf8($_);
1096               # using the URI::Escape pattern here so utf8 chars survive
1097               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1098               s/ /+/g;
1099               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1100       } @keys);
1101     }
1102
1103     my $res = bless(\"${base}${args}${query}", $class);
1104     $res;
1105 }
1106
1107 =head2 $c->welcome_message
1108
1109 Returns the Catalyst welcome HTML page.
1110
1111 =cut
1112
1113 sub welcome_message {
1114     my $c      = shift;
1115     my $name   = $c->config->{name};
1116     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1117     my $prefix = Catalyst::Utils::appprefix( ref $c );
1118     $c->response->content_type('text/html; charset=utf-8');
1119     return <<"EOF";
1120 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1121     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1122 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1123     <head>
1124     <meta http-equiv="Content-Language" content="en" />
1125     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1126         <title>$name on Catalyst $VERSION</title>
1127         <style type="text/css">
1128             body {
1129                 color: #000;
1130                 background-color: #eee;
1131             }
1132             div#content {
1133                 width: 640px;
1134                 margin-left: auto;
1135                 margin-right: auto;
1136                 margin-top: 10px;
1137                 margin-bottom: 10px;
1138                 text-align: left;
1139                 background-color: #ccc;
1140                 border: 1px solid #aaa;
1141             }
1142             p, h1, h2 {
1143                 margin-left: 20px;
1144                 margin-right: 20px;
1145                 font-family: verdana, tahoma, sans-serif;
1146             }
1147             a {
1148                 font-family: verdana, tahoma, sans-serif;
1149             }
1150             :link, :visited {
1151                     text-decoration: none;
1152                     color: #b00;
1153                     border-bottom: 1px dotted #bbb;
1154             }
1155             :link:hover, :visited:hover {
1156                     color: #555;
1157             }
1158             div#topbar {
1159                 margin: 0px;
1160             }
1161             pre {
1162                 margin: 10px;
1163                 padding: 8px;
1164             }
1165             div#answers {
1166                 padding: 8px;
1167                 margin: 10px;
1168                 background-color: #fff;
1169                 border: 1px solid #aaa;
1170             }
1171             h1 {
1172                 font-size: 0.9em;
1173                 font-weight: normal;
1174                 text-align: center;
1175             }
1176             h2 {
1177                 font-size: 1.0em;
1178             }
1179             p {
1180                 font-size: 0.9em;
1181             }
1182             p img {
1183                 float: right;
1184                 margin-left: 10px;
1185             }
1186             span#appname {
1187                 font-weight: bold;
1188                 font-size: 1.6em;
1189             }
1190         </style>
1191     </head>
1192     <body>
1193         <div id="content">
1194             <div id="topbar">
1195                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1196                     $VERSION</h1>
1197              </div>
1198              <div id="answers">
1199                  <p>
1200                  <img src="$logo" alt="Catalyst Logo" />
1201                  </p>
1202                  <p>Welcome to the  world of Catalyst.
1203                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1204                     framework will make web development something you had
1205                     never expected it to be: Fun, rewarding, and quick.</p>
1206                  <h2>What to do now?</h2>
1207                  <p>That really depends  on what <b>you</b> want to do.
1208                     We do, however, provide you with a few starting points.</p>
1209                  <p>If you want to jump right into web development with Catalyst
1210                     you might want to start with a tutorial.</p>
1211 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1212 </pre>
1213 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1214 <pre>
1215 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1216 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1217 </code></pre>
1218                  <h2>What to do next?</h2>
1219                  <p>Next it's time to write an actual application. Use the
1220                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1221                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1222                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1223                     they can save you a lot of work.</p>
1224                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1225                     <p>Also, be sure to check out the vast and growing
1226                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1227                     you are likely to find what you need there.
1228                     </p>
1229
1230                  <h2>Need help?</h2>
1231                  <p>Catalyst has a very active community. Here are the main places to
1232                     get in touch with us.</p>
1233                  <ul>
1234                      <li>
1235                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1236                      </li>
1237                      <li>
1238                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1239                      </li>
1240                      <li>
1241                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1242                      </li>
1243                  </ul>
1244                  <h2>In conclusion</h2>
1245                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1246                     as we enjoyed making it. Please contact us if you have ideas
1247                     for improvement or other feedback.</p>
1248              </div>
1249          </div>
1250     </body>
1251 </html>
1252 EOF
1253 }
1254
1255 =head1 INTERNAL METHODS
1256
1257 These methods are not meant to be used by end users.
1258
1259 =head2 $c->components
1260
1261 Returns a hash of components.
1262
1263 =head2 $c->context_class
1264
1265 Returns or sets the context class.
1266
1267 =head2 $c->counter
1268
1269 Returns a hashref containing coderefs and execution counts (needed for
1270 deep recursion detection).
1271
1272 =head2 $c->depth
1273
1274 Returns the number of actions on the current internal execution stack.
1275
1276 =head2 $c->dispatch
1277
1278 Dispatches a request to actions.
1279
1280 =cut
1281
1282 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1283
1284 =head2 $c->dispatcher_class
1285
1286 Returns or sets the dispatcher class.
1287
1288 =head2 $c->dump_these
1289
1290 Returns a list of 2-element array references (name, structure) pairs
1291 that will be dumped on the error page in debug mode.
1292
1293 =cut
1294
1295 sub dump_these {
1296     my $c = shift;
1297     [ Request => $c->req ],
1298     [ Response => $c->res ],
1299     [ Stash => $c->stash ],
1300     [ Config => $c->config ];
1301 }
1302
1303 =head2 $c->engine_class
1304
1305 Returns or sets the engine class.
1306
1307 =head2 $c->execute( $class, $coderef )
1308
1309 Execute a coderef in given class and catch exceptions. Errors are available
1310 via $c->error.
1311
1312 =cut
1313
1314 sub execute {
1315     my ( $c, $class, $code ) = @_;
1316     $class = $c->component($class) || $class;
1317     $c->state(0);
1318
1319     if ( $c->depth >= $RECURSION ) {
1320         my $action = $code->reverse();
1321         $action = "/$action" unless $action =~ /->/;
1322         my $error = qq/Deep recursion detected calling "${action}"/;
1323         $c->log->error($error);
1324         $c->error($error);
1325         $c->state(0);
1326         return $c->state;
1327     }
1328
1329     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1330
1331     push( @{ $c->stack }, $code );
1332
1333     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1334
1335     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1336
1337     my $last = pop( @{ $c->stack } );
1338
1339     if ( my $error = $@ ) {
1340         if ( !ref($error) and $error eq $DETACH ) {
1341             die $DETACH if($c->depth > 1);
1342         }
1343         elsif ( !ref($error) and $error eq $GO ) {
1344             die $GO if($c->depth > 0);
1345         }
1346         else {
1347             unless ( ref $error ) {
1348                 no warnings 'uninitialized';
1349                 chomp $error;
1350                 my $class = $last->class;
1351                 my $name  = $last->name;
1352                 $error = qq/Caught exception in $class->$name "$error"/;
1353             }
1354             $c->error($error);
1355             $c->state(0);
1356         }
1357     }
1358     return $c->state;
1359 }
1360
1361 sub _stats_start_execute {
1362     my ( $c, $code ) = @_;
1363
1364     return if ( ( $code->name =~ /^_.*/ )
1365         && ( !$c->config->{show_internal_actions} ) );
1366
1367     my $action_name = $code->reverse();
1368     $c->counter->{$action_name}++;
1369
1370     my $action = $action_name;
1371     $action = "/$action" unless $action =~ /->/;
1372
1373     # determine if the call was the result of a forward
1374     # this is done by walking up the call stack and looking for a calling
1375     # sub of Catalyst::forward before the eval
1376     my $callsub = q{};
1377     for my $index ( 2 .. 11 ) {
1378         last
1379         if ( ( caller($index) )[0] eq 'Catalyst'
1380             && ( caller($index) )[3] eq '(eval)' );
1381
1382         if ( ( caller($index) )[3] =~ /forward$/ ) {
1383             $callsub = ( caller($index) )[3];
1384             $action  = "-> $action";
1385             last;
1386         }
1387     }
1388
1389     my $uid = $action_name . $c->counter->{$action_name};
1390
1391     # is this a root-level call or a forwarded call?
1392     if ( $callsub =~ /forward$/ ) {
1393
1394         # forward, locate the caller
1395         if ( my $parent = $c->stack->[-1] ) {
1396             $c->stats->profile(
1397                 begin  => $action,
1398                 parent => "$parent" . $c->counter->{"$parent"},
1399                 uid    => $uid,
1400             );
1401         }
1402         else {
1403
1404             # forward with no caller may come from a plugin
1405             $c->stats->profile(
1406                 begin => $action,
1407                 uid   => $uid,
1408             );
1409         }
1410     }
1411     else {
1412
1413         # root-level call
1414         $c->stats->profile(
1415             begin => $action,
1416             uid   => $uid,
1417         );
1418     }
1419     return $action;
1420
1421 }
1422
1423 sub _stats_finish_execute {
1424     my ( $c, $info ) = @_;
1425     $c->stats->profile( end => $info );
1426 }
1427
1428 =head2 $c->_localize_fields( sub { }, \%keys );
1429
1430 =cut
1431
1432 #Why does this exist? This is no longer safe and WILL NOT WORK.
1433 # it doesnt seem to be used anywhere. can we remove it?
1434 sub _localize_fields {
1435     my ( $c, $localized, $code ) = ( @_ );
1436
1437     my $request = delete $localized->{request} || {};
1438     my $response = delete $localized->{response} || {};
1439
1440     local @{ $c }{ keys %$localized } = values %$localized;
1441     local @{ $c->request }{ keys %$request } = values %$request;
1442     local @{ $c->response }{ keys %$response } = values %$response;
1443
1444     $code->();
1445 }
1446
1447 =head2 $c->finalize
1448
1449 Finalizes the request.
1450
1451 =cut
1452
1453 sub finalize {
1454     my $c = shift;
1455
1456     for my $error ( @{ $c->error } ) {
1457         $c->log->error($error);
1458     }
1459
1460     # Allow engine to handle finalize flow (for POE)
1461     my $engine = $c->engine;
1462     if ( my $code = $engine->can('finalize') ) {
1463         $engine->$code($c);
1464     }
1465     else {
1466
1467         $c->finalize_uploads;
1468
1469         # Error
1470         if ( $#{ $c->error } >= 0 ) {
1471             $c->finalize_error;
1472         }
1473
1474         $c->finalize_headers;
1475
1476         # HEAD request
1477         if ( $c->request->method eq 'HEAD' ) {
1478             $c->response->body('');
1479         }
1480
1481         $c->finalize_body;
1482     }
1483
1484     if ($c->use_stats) {
1485         my $elapsed = sprintf '%f', $c->stats->elapsed;
1486         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1487         $c->log->info(
1488             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1489     }
1490
1491     return $c->response->status;
1492 }
1493
1494 =head2 $c->finalize_body
1495
1496 Finalizes body.
1497
1498 =cut
1499
1500 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1501
1502 =head2 $c->finalize_cookies
1503
1504 Finalizes cookies.
1505
1506 =cut
1507
1508 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1509
1510 =head2 $c->finalize_error
1511
1512 Finalizes error.
1513
1514 =cut
1515
1516 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1517
1518 =head2 $c->finalize_headers
1519
1520 Finalizes headers.
1521
1522 =cut
1523
1524 sub finalize_headers {
1525     my $c = shift;
1526
1527     my $response = $c->response; #accessor calls can add up?
1528
1529     # Check if we already finalized headers
1530     return if $response->finalized_headers;
1531
1532     # Handle redirects
1533     if ( my $location = $response->redirect ) {
1534         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1535         $response->header( Location => $location );
1536
1537         #Moose TODO: we should probably be using a predicate method here ?
1538         if ( !$response->body ) {
1539             # Add a default body if none is already present
1540             $response->body(
1541                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1542             );
1543         }
1544     }
1545
1546     # Content-Length
1547     if ( $response->body && !$response->content_length ) {
1548
1549         # get the length from a filehandle
1550         if ( blessed( $response->body ) && $response->body->can('read') )
1551         {
1552             my $stat = stat $response->body;
1553             if ( $stat && $stat->size > 0 ) {
1554                 $response->content_length( $stat->size );
1555             }
1556             else {
1557                 $c->log->warn('Serving filehandle without a content-length');
1558             }
1559         }
1560         else {
1561             # everything should be bytes at this point, but just in case
1562             $response->content_length( bytes::length( $response->body ) );
1563         }
1564     }
1565
1566     # Errors
1567     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1568         $response->headers->remove_header("Content-Length");
1569         $response->body('');
1570     }
1571
1572     $c->finalize_cookies;
1573
1574     $c->engine->finalize_headers( $c, @_ );
1575
1576     # Done
1577     $response->finalized_headers(1);
1578 }
1579
1580 =head2 $c->finalize_output
1581
1582 An alias for finalize_body.
1583
1584 =head2 $c->finalize_read
1585
1586 Finalizes the input after reading is complete.
1587
1588 =cut
1589
1590 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1591
1592 =head2 $c->finalize_uploads
1593
1594 Finalizes uploads. Cleans up any temporary files.
1595
1596 =cut
1597
1598 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1599
1600 =head2 $c->get_action( $action, $namespace )
1601
1602 Gets an action in a given namespace.
1603
1604 =cut
1605
1606 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1607
1608 =head2 $c->get_actions( $action, $namespace )
1609
1610 Gets all actions of a given name in a namespace and all parent
1611 namespaces.
1612
1613 =cut
1614
1615 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1616
1617 =head2 $c->handle_request( $class, @arguments )
1618
1619 Called to handle each HTTP request.
1620
1621 =cut
1622
1623 sub handle_request {
1624     my ( $class, @arguments ) = @_;
1625
1626     # Always expect worst case!
1627     my $status = -1;
1628     eval {
1629         if ($class->debug) {
1630             my $secs = time - $START || 1;
1631             my $av = sprintf '%.3f', $COUNT / $secs;
1632             my $time = localtime time;
1633             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1634         }
1635
1636         my $c = $class->prepare(@arguments);
1637         $c->dispatch;
1638         $status = $c->finalize;
1639     };
1640
1641     if ( my $error = $@ ) {
1642         chomp $error;
1643         $class->log->error(qq/Caught exception in engine "$error"/);
1644     }
1645
1646     $COUNT++;
1647
1648     if(my $coderef = $class->log->can('_flush')){
1649         $class->log->$coderef();
1650     }
1651     return $status;
1652 }
1653
1654 =head2 $c->prepare( @arguments )
1655
1656 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1657 etc.).
1658
1659 =cut
1660
1661 sub prepare {
1662     my ( $class, @arguments ) = @_;
1663
1664     # XXX
1665     # After the app/ctxt split, this should become an attribute based on something passed
1666     # into the application.
1667     $class->context_class( ref $class || $class ) unless $class->context_class;
1668
1669     my $c = $class->context_class->new({});
1670
1671     # For on-demand data
1672     $c->request->_context($c);
1673     $c->response->_context($c);
1674
1675     #surely this is not the most efficient way to do things...
1676     $c->stats($class->stats_class->new)->enable($c->use_stats);
1677     if ( $c->debug ) {
1678         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1679     }
1680
1681     #XXX reuse coderef from can
1682     # Allow engine to direct the prepare flow (for POE)
1683     if ( $c->engine->can('prepare') ) {
1684         $c->engine->prepare( $c, @arguments );
1685     }
1686     else {
1687         $c->prepare_request(@arguments);
1688         $c->prepare_connection;
1689         $c->prepare_query_parameters;
1690         $c->prepare_headers;
1691         $c->prepare_cookies;
1692         $c->prepare_path;
1693
1694         # Prepare the body for reading, either by prepare_body
1695         # or the user, if they are using $c->read
1696         $c->prepare_read;
1697
1698         # Parse the body unless the user wants it on-demand
1699         unless ( $c->config->{parse_on_demand} ) {
1700             $c->prepare_body;
1701         }
1702     }
1703
1704     my $method  = $c->req->method  || '';
1705     my $path    = $c->req->path;
1706     $path       = '/' unless length $path;
1707     my $address = $c->req->address || '';
1708
1709     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1710       if $c->debug;
1711
1712     $c->prepare_action;
1713
1714     return $c;
1715 }
1716
1717 =head2 $c->prepare_action
1718
1719 Prepares action. See L<Catalyst::Dispatcher>.
1720
1721 =cut
1722
1723 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1724
1725 =head2 $c->prepare_body
1726
1727 Prepares message body.
1728
1729 =cut
1730
1731 sub prepare_body {
1732     my $c = shift;
1733
1734     #Moose TODO: what is  _body ??
1735     # Do we run for the first time?
1736     return if defined $c->request->{_body};
1737
1738     # Initialize on-demand data
1739     $c->engine->prepare_body( $c, @_ );
1740     $c->prepare_parameters;
1741     $c->prepare_uploads;
1742
1743     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1744         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1745         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1746             my $param = $c->req->body_parameters->{$key};
1747             my $value = defined($param) ? $param : '';
1748             $t->row( $key,
1749                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1750         }
1751         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1752     }
1753 }
1754
1755 =head2 $c->prepare_body_chunk( $chunk )
1756
1757 Prepares a chunk of data before sending it to L<HTTP::Body>.
1758
1759 See L<Catalyst::Engine>.
1760
1761 =cut
1762
1763 sub prepare_body_chunk {
1764     my $c = shift;
1765     $c->engine->prepare_body_chunk( $c, @_ );
1766 }
1767
1768 =head2 $c->prepare_body_parameters
1769
1770 Prepares body parameters.
1771
1772 =cut
1773
1774 sub prepare_body_parameters {
1775     my $c = shift;
1776     $c->engine->prepare_body_parameters( $c, @_ );
1777 }
1778
1779 =head2 $c->prepare_connection
1780
1781 Prepares connection.
1782
1783 =cut
1784
1785 sub prepare_connection {
1786     my $c = shift;
1787     $c->engine->prepare_connection( $c, @_ );
1788 }
1789
1790 =head2 $c->prepare_cookies
1791
1792 Prepares cookies.
1793
1794 =cut
1795
1796 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1797
1798 =head2 $c->prepare_headers
1799
1800 Prepares headers.
1801
1802 =cut
1803
1804 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1805
1806 =head2 $c->prepare_parameters
1807
1808 Prepares parameters.
1809
1810 =cut
1811
1812 sub prepare_parameters {
1813     my $c = shift;
1814     $c->prepare_body_parameters;
1815     $c->engine->prepare_parameters( $c, @_ );
1816 }
1817
1818 =head2 $c->prepare_path
1819
1820 Prepares path and base.
1821
1822 =cut
1823
1824 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1825
1826 =head2 $c->prepare_query_parameters
1827
1828 Prepares query parameters.
1829
1830 =cut
1831
1832 sub prepare_query_parameters {
1833     my $c = shift;
1834
1835     $c->engine->prepare_query_parameters( $c, @_ );
1836
1837     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1838         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1839         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1840             my $param = $c->req->query_parameters->{$key};
1841             my $value = defined($param) ? $param : '';
1842             $t->row( $key,
1843                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1844         }
1845         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1846     }
1847 }
1848
1849 =head2 $c->prepare_read
1850
1851 Prepares the input for reading.
1852
1853 =cut
1854
1855 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1856
1857 =head2 $c->prepare_request
1858
1859 Prepares the engine request.
1860
1861 =cut
1862
1863 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1864
1865 =head2 $c->prepare_uploads
1866
1867 Prepares uploads.
1868
1869 =cut
1870
1871 sub prepare_uploads {
1872     my $c = shift;
1873
1874     $c->engine->prepare_uploads( $c, @_ );
1875
1876     if ( $c->debug && keys %{ $c->request->uploads } ) {
1877         my $t = Text::SimpleTable->new(
1878             [ 12, 'Parameter' ],
1879             [ 26, 'Filename' ],
1880             [ 18, 'Type' ],
1881             [ 9,  'Size' ]
1882         );
1883         for my $key ( sort keys %{ $c->request->uploads } ) {
1884             my $upload = $c->request->uploads->{$key};
1885             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1886                 $t->row( $key, $u->filename, $u->type, $u->size );
1887             }
1888         }
1889         $c->log->debug( "File Uploads are:\n" . $t->draw );
1890     }
1891 }
1892
1893 =head2 $c->prepare_write
1894
1895 Prepares the output for writing.
1896
1897 =cut
1898
1899 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1900
1901 =head2 $c->request_class
1902
1903 Returns or sets the request class.
1904
1905 =head2 $c->response_class
1906
1907 Returns or sets the response class.
1908
1909 =head2 $c->read( [$maxlength] )
1910
1911 Reads a chunk of data from the request body. This method is designed to
1912 be used in a while loop, reading C<$maxlength> bytes on every call.
1913 C<$maxlength> defaults to the size of the request if not specified.
1914
1915 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1916 directly.
1917
1918 Warning: If you use read(), Catalyst will not process the body,
1919 so you will not be able to access POST parameters or file uploads via
1920 $c->request.  You must handle all body parsing yourself.
1921
1922 =cut
1923
1924 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1925
1926 =head2 $c->run
1927
1928 Starts the engine.
1929
1930 =cut
1931
1932 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1933
1934 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1935
1936 Sets an action in a given namespace.
1937
1938 =cut
1939
1940 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1941
1942 =head2 $c->setup_actions($component)
1943
1944 Sets up actions for a component.
1945
1946 =cut
1947
1948 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1949
1950 =head2 $c->setup_components
1951
1952 Sets up components. Specify a C<setup_components> config option to pass
1953 additional options directly to L<Module::Pluggable>. To add additional
1954 search paths, specify a key named C<search_extra> as an array
1955 reference. Items in the array beginning with C<::> will have the
1956 application class name prepended to them.
1957
1958 All components found will also have any
1959 L<Devel::InnerPackage|inner packages> loaded and set up as components.
1960 Note, that modules which are B<not> an I<inner package> of the main
1961 file namespace loaded will not be instantiated as components.
1962
1963 =cut
1964
1965 sub setup_components {
1966     my $class = shift;
1967
1968     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1969     my $config  = $class->config->{ setup_components };
1970     my $extra   = delete $config->{ search_extra } || [];
1971
1972     push @paths, @$extra;
1973
1974     my $locator = Module::Pluggable::Object->new(
1975         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1976         %$config
1977     );
1978
1979     my @comps = sort { length $a <=> length $b } $locator->plugins;
1980     my %comps = map { $_ => 1 } @comps;
1981
1982     for my $component ( @comps ) {
1983
1984         # We pass ignore_loaded here so that overlay files for (e.g.)
1985         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
1986         # we know M::P::O found a file on disk so this is safe
1987
1988         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1989         #Class::MOP::load_class($component);
1990
1991         my $module  = $class->setup_component( $component );
1992         my %modules = (
1993             $component => $module,
1994             map {
1995                 $_ => $class->setup_component( $_ )
1996             } grep {
1997               not exists $comps{$_}
1998             } Devel::InnerPackage::list_packages( $component )
1999         );
2000
2001         for my $key ( keys %modules ) {
2002             $class->components->{ $key } = $modules{ $key };
2003         }
2004     }
2005 }
2006
2007 =head2 $c->setup_component
2008
2009 =cut
2010
2011 sub setup_component {
2012     my( $class, $component ) = @_;
2013
2014     unless ( $component->can( 'COMPONENT' ) ) {
2015         return $component;
2016     }
2017
2018     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2019     my $config = $class->config->{ $suffix } || {};
2020
2021     my $instance = eval { $component->COMPONENT( $class, $config ); };
2022
2023     if ( my $error = $@ ) {
2024         chomp $error;
2025         Catalyst::Exception->throw(
2026             message => qq/Couldn't instantiate component "$component", "$error"/
2027         );
2028     }
2029
2030     Catalyst::Exception->throw(
2031         message =>
2032         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2033     ) unless blessed($instance);
2034
2035     return $instance;
2036 }
2037
2038 =head2 $c->setup_dispatcher
2039
2040 Sets up dispatcher.
2041
2042 =cut
2043
2044 sub setup_dispatcher {
2045     my ( $class, $dispatcher ) = @_;
2046
2047     if ($dispatcher) {
2048         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2049     }
2050
2051     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2052         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2053     }
2054
2055     unless ($dispatcher) {
2056         $dispatcher = $class->dispatcher_class;
2057     }
2058
2059     Class::MOP::load_class($dispatcher);
2060
2061     # dispatcher instance
2062     $class->dispatcher( $dispatcher->new );
2063 }
2064
2065 =head2 $c->setup_engine
2066
2067 Sets up engine.
2068
2069 =cut
2070
2071 sub setup_engine {
2072     my ( $class, $engine ) = @_;
2073
2074     if ($engine) {
2075         $engine = 'Catalyst::Engine::' . $engine;
2076     }
2077
2078     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2079         $engine = 'Catalyst::Engine::' . $env;
2080     }
2081
2082     if ( $ENV{MOD_PERL} ) {
2083
2084         # create the apache method
2085         $class->meta->add_method('apache' => sub { shift->engine->apache });
2086
2087         my ( $software, $version ) =
2088           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2089
2090         $version =~ s/_//g;
2091         $version =~ s/(\.[^.]+)\./$1/g;
2092
2093         if ( $software eq 'mod_perl' ) {
2094
2095             if ( !$engine ) {
2096
2097                 if ( $version >= 1.99922 ) {
2098                     $engine = 'Catalyst::Engine::Apache2::MP20';
2099                 }
2100
2101                 elsif ( $version >= 1.9901 ) {
2102                     $engine = 'Catalyst::Engine::Apache2::MP19';
2103                 }
2104
2105                 elsif ( $version >= 1.24 ) {
2106                     $engine = 'Catalyst::Engine::Apache::MP13';
2107                 }
2108
2109                 else {
2110                     Catalyst::Exception->throw( message =>
2111                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2112                 }
2113
2114             }
2115
2116             # install the correct mod_perl handler
2117             if ( $version >= 1.9901 ) {
2118                 *handler = sub  : method {
2119                     shift->handle_request(@_);
2120                 };
2121             }
2122             else {
2123                 *handler = sub ($$) { shift->handle_request(@_) };
2124             }
2125
2126         }
2127
2128         elsif ( $software eq 'Zeus-Perl' ) {
2129             $engine = 'Catalyst::Engine::Zeus';
2130         }
2131
2132         else {
2133             Catalyst::Exception->throw(
2134                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2135         }
2136     }
2137
2138     unless ($engine) {
2139         $engine = $class->engine_class;
2140     }
2141
2142     Class::MOP::load_class($engine);
2143     #unless (Class::Inspector->loaded($engine)) {
2144     #    require Class::Inspector->filename($engine);
2145     #}
2146
2147     # check for old engines that are no longer compatible
2148     my $old_engine;
2149     if ( $engine->isa('Catalyst::Engine::Apache')
2150         && !Catalyst::Engine::Apache->VERSION )
2151     {
2152         $old_engine = 1;
2153     }
2154
2155     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2156         && Catalyst::Engine::Server->VERSION le '0.02' )
2157     {
2158         $old_engine = 1;
2159     }
2160
2161     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2162         && $engine->VERSION eq '0.01' )
2163     {
2164         $old_engine = 1;
2165     }
2166
2167     elsif ($engine->isa('Catalyst::Engine::Zeus')
2168         && $engine->VERSION eq '0.01' )
2169     {
2170         $old_engine = 1;
2171     }
2172
2173     if ($old_engine) {
2174         Catalyst::Exception->throw( message =>
2175               qq/Engine "$engine" is not supported by this version of Catalyst/
2176         );
2177     }
2178
2179     # engine instance
2180     $class->engine( $engine->new );
2181 }
2182
2183 =head2 $c->setup_home
2184
2185 Sets up the home directory.
2186
2187 =cut
2188
2189 sub setup_home {
2190     my ( $class, $home ) = @_;
2191
2192     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2193         $home = $env;
2194     }
2195
2196     $home ||= Catalyst::Utils::home($class);
2197
2198     if ($home) {
2199         #I remember recently being scolded for assigning config values like this
2200         $class->config->{home} ||= $home;
2201         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2202     }
2203 }
2204
2205 =head2 $c->setup_log
2206
2207 Sets up log.
2208
2209 =cut
2210
2211 sub setup_log {
2212     my ( $class, $debug ) = @_;
2213
2214     unless ( $class->log ) {
2215         $class->log( Catalyst::Log->new );
2216     }
2217
2218     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2219     if ( defined($env_debug) ? $env_debug : $debug ) {
2220         $class->meta->add_method('debug' => sub { 1 });
2221         $class->log->debug('Debug messages enabled');
2222     }
2223 }
2224
2225 =head2 $c->setup_plugins
2226
2227 Sets up plugins.
2228
2229 =cut
2230
2231 =head2 $c->setup_stats
2232
2233 Sets up timing statistics class.
2234
2235 =cut
2236
2237 sub setup_stats {
2238     my ( $class, $stats ) = @_;
2239
2240     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2241
2242     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2243     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2244         $class->meta->add_method('use_stats' => sub { 1 });
2245         $class->log->debug('Statistics enabled');
2246     }
2247 }
2248
2249
2250 =head2 $c->registered_plugins
2251
2252 Returns a sorted list of the plugins which have either been stated in the
2253 import list or which have been added via C<< MyApp->plugin(@args); >>.
2254
2255 If passed a given plugin name, it will report a boolean value indicating
2256 whether or not that plugin is loaded.  A fully qualified name is required if
2257 the plugin name does not begin with C<Catalyst::Plugin::>.
2258
2259  if ($c->registered_plugins('Some::Plugin')) {
2260      ...
2261  }
2262
2263 =cut
2264
2265 {
2266
2267     sub registered_plugins {
2268         my $proto = shift;
2269         return sort keys %{ $proto->_plugins } unless @_;
2270         my $plugin = shift;
2271         return 1 if exists $proto->_plugins->{$plugin};
2272         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2273     }
2274
2275     sub _register_plugin {
2276         my ( $proto, $plugin, $instant ) = @_;
2277         my $class = ref $proto || $proto;
2278
2279         # no ignore_loaded here, the plugin may already have been
2280         # defined in memory and we don't want to error on "no file" if so
2281
2282         Class::MOP::load_class( $plugin );
2283
2284         $proto->_plugins->{$plugin} = 1;
2285         unless ($instant) {
2286             no strict 'refs';
2287             if( $class->can('meta') ){
2288               my @superclasses = ($plugin, $class->meta->superclasses );
2289               $class->meta->superclasses(@superclasses);
2290             } else {
2291               unshift @{"$class\::ISA"}, $plugin;
2292             }
2293         }
2294         return $class;
2295     }
2296
2297     sub setup_plugins {
2298         my ( $class, $plugins ) = @_;
2299
2300         $class->_plugins( {} ) unless $class->_plugins;
2301         $plugins ||= [];
2302         for my $plugin ( reverse @$plugins ) {
2303
2304             unless ( $plugin =~ s/\A\+// ) {
2305                 $plugin = "Catalyst::Plugin::$plugin";
2306             }
2307
2308             $class->_register_plugin($plugin);
2309         }
2310     }
2311 }
2312
2313 =head2 $c->stack
2314
2315 Returns an arrayref of the internal execution stack (actions that are
2316 currently executing).
2317
2318 =head2 $c->stats_class
2319
2320 Returns or sets the stats (timing statistics) class.
2321
2322 =head2 $c->use_stats
2323
2324 Returns 1 when stats collection is enabled.  Stats collection is enabled
2325 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2326 environment variable is set.
2327
2328 Note that this is a static method, not an accessor and should be overloaded
2329 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2330
2331 =cut
2332
2333 sub use_stats { 0 }
2334
2335
2336 =head2 $c->write( $data )
2337
2338 Writes $data to the output stream. When using this method directly, you
2339 will need to manually set the C<Content-Length> header to the length of
2340 your output data, if known.
2341
2342 =cut
2343
2344 sub write {
2345     my $c = shift;
2346
2347     # Finalize headers if someone manually writes output
2348     $c->finalize_headers;
2349
2350     return $c->engine->write( $c, @_ );
2351 }
2352
2353 =head2 version
2354
2355 Returns the Catalyst version number. Mostly useful for "powered by"
2356 messages in template systems.
2357
2358 =cut
2359
2360 sub version { return $Catalyst::VERSION }
2361
2362 =head1 INTERNAL ACTIONS
2363
2364 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2365 C<_ACTION>, and C<_END>. These are by default not shown in the private
2366 action table, but you can make them visible with a config parameter.
2367
2368     MyApp->config->{show_internal_actions} = 1;
2369
2370 =head1 CASE SENSITIVITY
2371
2372 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2373 mapped to C</foo/bar>. You can activate case sensitivity with a config
2374 parameter.
2375
2376     MyApp->config->{case_sensitive} = 1;
2377
2378 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2379
2380 =head1 ON-DEMAND PARSER
2381
2382 The request body is usually parsed at the beginning of a request,
2383 but if you want to handle input yourself, you can enable on-demand
2384 parsing with a config parameter.
2385
2386     MyApp->config->{parse_on_demand} = 1;
2387
2388 =head1 PROXY SUPPORT
2389
2390 Many production servers operate using the common double-server approach,
2391 with a lightweight frontend web server passing requests to a larger
2392 backend server. An application running on the backend server must deal
2393 with two problems: the remote user always appears to be C<127.0.0.1> and
2394 the server's hostname will appear to be C<localhost> regardless of the
2395 virtual host that the user connected through.
2396
2397 Catalyst will automatically detect this situation when you are running
2398 the frontend and backend servers on the same machine. The following
2399 changes are made to the request.
2400
2401     $c->req->address is set to the user's real IP address, as read from
2402     the HTTP X-Forwarded-For header.
2403
2404     The host value for $c->req->base and $c->req->uri is set to the real
2405     host, as read from the HTTP X-Forwarded-Host header.
2406
2407 Obviously, your web server must support these headers for this to work.
2408
2409 In a more complex server farm environment where you may have your
2410 frontend proxy server(s) on different machines, you will need to set a
2411 configuration option to tell Catalyst to read the proxied data from the
2412 headers.
2413
2414     MyApp->config->{using_frontend_proxy} = 1;
2415
2416 If you do not wish to use the proxy support at all, you may set:
2417
2418     MyApp->config->{ignore_frontend_proxy} = 1;
2419
2420 =head1 THREAD SAFETY
2421
2422 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2423 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2424 believe the Catalyst core to be thread-safe.
2425
2426 If you plan to operate in a threaded environment, remember that all other
2427 modules you are using must also be thread-safe. Some modules, most notably
2428 L<DBD::SQLite>, are not thread-safe.
2429
2430 =head1 SUPPORT
2431
2432 IRC:
2433
2434     Join #catalyst on irc.perl.org.
2435
2436 Mailing Lists:
2437
2438     http://lists.rawmode.org/mailman/listinfo/catalyst
2439     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2440
2441 Web:
2442
2443     http://catalyst.perl.org
2444
2445 Wiki:
2446
2447     http://dev.catalyst.perl.org
2448
2449 =head1 SEE ALSO
2450
2451 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2452
2453 =head2 L<Catalyst::Manual> - The Catalyst Manual
2454
2455 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2456
2457 =head2 L<Catalyst::Engine> - Core engine
2458
2459 =head2 L<Catalyst::Log> - Log class.
2460
2461 =head2 L<Catalyst::Request> - Request object
2462
2463 =head2 L<Catalyst::Response> - Response object
2464
2465 =head2 L<Catalyst::Test> - The test suite.
2466
2467 =head1 PROJECT FOUNDER
2468
2469 sri: Sebastian Riedel <sri@cpan.org>
2470
2471 =head1 CONTRIBUTORS
2472
2473 abw: Andy Wardley
2474
2475 acme: Leon Brocard <leon@astray.com>
2476
2477 Andrew Bramble
2478
2479 Andrew Ford
2480
2481 Andrew Ruthven
2482
2483 andyg: Andy Grundman <andy@hybridized.org>
2484
2485 audreyt: Audrey Tang
2486
2487 bricas: Brian Cassidy <bricas@cpan.org>
2488
2489 chansen: Christian Hansen
2490
2491 chicks: Christopher Hicks
2492
2493 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2494
2495 Drew Taylor
2496
2497 esskar: Sascha Kiefer
2498
2499 fireartist: Carl Franks <cfranks@cpan.org>
2500
2501 gabb: Danijel Milicevic
2502
2503 Gary Ashton Jones
2504
2505 Geoff Richards
2506
2507 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2508
2509 jcamacho: Juan Camacho
2510
2511 Jody Belka
2512
2513 Johan Lindstrom
2514
2515 jon: Jon Schutz <jjschutz@cpan.org>
2516
2517 marcus: Marcus Ramberg <mramberg@cpan.org>
2518
2519 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2520
2521 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2522
2523 mugwump: Sam Vilain
2524
2525 naughton: David Naughton
2526
2527 ningu: David Kamholz <dkamholz@cpan.org>
2528
2529 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2530
2531 numa: Dan Sully <daniel@cpan.org>
2532
2533 obra: Jesse Vincent
2534
2535 omega: Andreas Marienborg
2536
2537 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2538
2539 rafl: Florian Ragwitz <rafl@debian.org>
2540
2541 sky: Arthur Bergman
2542
2543 the_jester: Jesse Sheidlower
2544
2545 Ulf Edvinsson
2546
2547 willert: Sebastian Willert <willert@cpan.org>
2548
2549 =head1 LICENSE
2550
2551 This library is free software, you can redistribute it and/or modify it under
2552 the same terms as Perl itself.
2553
2554 =cut
2555
2556 no Moose;
2557
2558 __PACKAGE__->meta->make_immutable;
2559
2560 1;