lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Plack::Middleware::Conditional;
  39 use Plack::Middleware::ReverseProxy;
  40 use Plack::Middleware::IIS6ScriptNameFix;
  41 use Plack::Middleware::IIS7KeepAliveFix;
  42 use Plack::Middleware::LighttpdScriptNameFix;
  43 use Class::Load 'load_class';
  44
  45 BEGIN { require 5.008003; }
  46
  47 has stack => (is => 'ro', default => sub { [] });
  48 has stash => (is => 'rw', default => sub { {} });
  49 has state => (is => 'rw', default => 0);
  50 has stats => (is => 'rw');
  51 has action => (is => 'rw');
  52 has counter => (is => 'rw', default => sub { {} });
  53 has request => (
  54     is => 'rw',
  55     default => sub {
  56         my $self = shift;
  57         $self->request_class->new($self->_build_request_constructor_args);
  58     },
  59     lazy => 1,
  60 );
  61 sub _build_request_constructor_args {
  62     my $self = shift;
  63     my %p = ( _log => $self->log );
  64     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  65     \%p;
  66 }
  67
  68 has response => (
  69     is => 'rw',
  70     default => sub {
  71         my $self = shift;
  72         $self->response_class->new($self->_build_response_constructor_args);
  73     },
  74     lazy => 1,
  75 );
  76 sub _build_response_constructor_args {
  77     my $self = shift;
  78     { _log => $self->log };
  79 }
  80
  81 has namespace => (is => 'rw');
  82
  83 sub depth { scalar @{ shift->stack || [] }; }
  84 sub comp { shift->component(@_) }
  85
  86 sub req {
  87     my $self = shift; return $self->request(@_);
  88 }
  89 sub res {
  90     my $self = shift; return $self->response(@_);
  91 }
  92
  93 # For backwards compatibility
  94 sub finalize_output { shift->finalize_body(@_) };
  95
  96 # For statistics
  97 our $COUNT     = 1;
  98 our $START     = time;
  99 our $RECURSION = 1000;
 100 our $DETACH    = Catalyst::Exception::Detach->new;
 101 our $GO        = Catalyst::Exception::Go->new;
 102
 103 #I imagine that very few of these really need to be class variables. if any.
 104 #maybe we should just make them attributes with a default?
 105 __PACKAGE__->mk_classdata($_)
 106   for qw/components arguments dispatcher engine log dispatcher_class
 107   engine_loader context_class request_class response_class stats_class
 108   setup_finished _psgi_app loading_psgi_file run_options/;
 109
 110 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 111 __PACKAGE__->request_class('Catalyst::Request');
 112 __PACKAGE__->response_class('Catalyst::Response');
 113 __PACKAGE__->stats_class('Catalyst::Stats');
 114
 115 # Remember to update this in Catalyst::Runtime as well!
 116
 117 our $VERSION = '5.90042';
 118
 119 sub import {
 120     my ( $class, @arguments ) = @_;
 121
 122     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 123     # callers @ISA.
 124     return unless $class eq 'Catalyst';
 125
 126     my $caller = caller();
 127     return if $caller eq 'main';
 128
 129     my $meta = Moose::Meta::Class->initialize($caller);
 130     unless ( $caller->isa('Catalyst') ) {
 131         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 132         $meta->superclasses(@superclasses);
 133     }
 134     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 135     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 136
 137     unless( $meta->has_method('meta') ){
 138         if ($Moose::VERSION >= 1.15) {
 139             $meta->_add_meta_method('meta');
 140         }
 141         else {
 142             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 143         }
 144     }
 145
 146     $caller->arguments( [@arguments] );
 147     $caller->setup_home;
 148 }
 149
 150 sub _application { $_[0] }
 151
 152 =encoding UTF-8
 153
 154 =head1 NAME
 155
 156 Catalyst - The Elegant MVC Web Application Framework
 157
 158 =head1 SYNOPSIS
 159
 160 See the L<Catalyst::Manual> distribution for comprehensive
 161 documentation and tutorials.
 162
 163     # Install Catalyst::Devel for helpers and other development tools
 164     # use the helper to create a new application
 165     catalyst.pl MyApp
 166
 167     # add models, views, controllers
 168     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 169     script/myapp_create.pl view MyTemplate TT
 170     script/myapp_create.pl controller Search
 171
 172     # built in testserver -- use -r to restart automatically on changes
 173     # --help to see all available options
 174     script/myapp_server.pl
 175
 176     # command line testing interface
 177     script/myapp_test.pl /yada
 178
 179     ### in lib/MyApp.pm
 180     use Catalyst qw/-Debug/; # include plugins here as well
 181
 182     ### In lib/MyApp/Controller/Root.pm (autocreated)
 183     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 184         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 185         $c->stash->{template} = 'foo.tt'; # set the template
 186         # lookup something from db -- stash vars are passed to TT
 187         $c->stash->{data} =
 188           $c->model('Database::Foo')->search( { country => $args[0] } );
 189         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 190             $c->forward( 'bar' ); # process another action
 191             # do something else after forward returns
 192         }
 193     }
 194
 195     # The foo.tt TT template can use the stash data from the database
 196     [% WHILE (item = data.next) %]
 197         [% item.foo %]
 198     [% END %]
 199
 200     # called for /bar/of/soap, /bar/of/soap/10, etc.
 201     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 202
 203     # called after all actions are finished
 204     sub end : Action {
 205         my ( $self, $c ) = @_;
 206         if ( scalar @{ $c->error } ) { ... } # handle errors
 207         return if $c->res->body; # already have a response
 208         $c->forward( 'MyApp::View::TT' ); # render template
 209     }
 210
 211 See L<Catalyst::Manual::Intro> for additional information.
 212
 213 =head1 DESCRIPTION
 214
 215 Catalyst is a modern framework for making web applications without the
 216 pain usually associated with this process. This document is a reference
 217 to the main Catalyst application. If you are a new user, we suggest you
 218 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 219
 220 See L<Catalyst::Manual> for more documentation.
 221
 222 Catalyst plugins can be loaded by naming them as arguments to the "use
 223 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 224 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 225 C<My::Module>.
 226
 227     use Catalyst qw/My::Module/;
 228
 229 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 230 fully qualify the name by using a unary plus:
 231
 232     use Catalyst qw/
 233         My::Module
 234         +Fully::Qualified::Plugin::Name
 235     /;
 236
 237 Special flags like C<-Debug> can also be specified as
 238 arguments when Catalyst is loaded:
 239
 240     use Catalyst qw/-Debug My::Module/;
 241
 242 The position of plugins and flags in the chain is important, because
 243 they are loaded in the order in which they appear.
 244
 245 The following flags are supported:
 246
 247 =head2 -Debug
 248
 249 Enables debug output. You can also force this setting from the system
 250 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 251 settings override the application, with <MYAPP>_DEBUG having the highest
 252 priority.
 253
 254 This sets the log level to 'debug' and enables full debug output on the
 255 error screen. If you only want the latter, see L<< $c->debug >>.
 256
 257 =head2 -Home
 258
 259 Forces Catalyst to use a specific home directory, e.g.:
 260
 261     use Catalyst qw[-Home=/usr/mst];
 262
 263 This can also be done in the shell environment by setting either the
 264 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 265 is replaced with the uppercased name of your application, any "::" in
 266 the name will be replaced with underscores, e.g. MyApp::Web should use
 267 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 268
 269 If none of these are set, Catalyst will attempt to automatically detect the
 270 home directory. If you are working in a development environment, Catalyst
 271 will try and find the directory containing either Makefile.PL, Build.PL,
 272 dist.ini, or cpanfile. If the application has been installed into the system
 273 (i.e. you have done C<make install>), then Catalyst will use the path to your
 274 application module, without the .pm extension (e.g., /foo/MyApp if your
 275 application was installed at /foo/MyApp.pm)
 276
 277 =head2 -Log
 278
 279     use Catalyst '-Log=warn,fatal,error';
 280
 281 Specifies a comma-delimited list of log levels.
 282
 283 =head2 -Stats
 284
 285 Enables statistics collection and reporting.
 286
 287    use Catalyst qw/-Stats=1/;
 288
 289 You can also force this setting from the system environment with CATALYST_STATS
 290 or <MYAPP>_STATS. The environment settings override the application, with
 291 <MYAPP>_STATS having the highest priority.
 292
 293 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 294
 295 =head1 METHODS
 296
 297 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 298
 299 =head2 $c->action
 300
 301 Returns a L<Catalyst::Action> object for the current action, which
 302 stringifies to the action name. See L<Catalyst::Action>.
 303
 304 =head2 $c->namespace
 305
 306 Returns the namespace of the current action, i.e., the URI prefix
 307 corresponding to the controller of the current action. For example:
 308
 309     # in Controller::Foo::Bar
 310     $c->namespace; # returns 'foo/bar';
 311
 312 =head2 $c->request
 313
 314 =head2 $c->req
 315
 316 Returns the current L<Catalyst::Request> object, giving access to
 317 information about the current client request (including parameters,
 318 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 319
 320 =head2 REQUEST FLOW HANDLING
 321
 322 =head2 $c->forward( $action [, \@arguments ] )
 323
 324 =head2 $c->forward( $class, $method, [, \@arguments ] )
 325
 326 This is one way of calling another action (method) in the same or
 327 a different controller. You can also use C<< $self->my_method($c, @args) >>
 328 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 329 in a different controller.
 330 The main difference is that 'forward' uses some of the Catalyst request
 331 cycle overhead, including debugging, which may be useful to you. On the
 332 other hand, there are some complications to using 'forward', restrictions
 333 on values returned from 'forward', and it may not handle errors as you prefer.
 334 Whether you use 'forward' or not is up to you; it is not considered superior to
 335 the other ways to call a method.
 336
 337 'forward' calls  another action, by its private name. If you give a
 338 class name but no method, C<process()> is called. You may also optionally
 339 pass arguments in an arrayref. The action will receive the arguments in
 340 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 341 C<< $c->req->args >> will be restored to the previous values.
 342
 343 Any data C<return>ed from the action forwarded to, will be returned by the
 344 call to forward.
 345
 346     my $foodata = $c->forward('/foo');
 347     $c->forward('index');
 348     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 349     $c->forward('View::TT');
 350
 351 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 352 an C<< eval { } >> around the call (actually
 353 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 354 exceptions thrown by the called action non-fatal and pushing them onto
 355 $c->error instead. If you want C<die> to propagate you need to do something
 356 like:
 357
 358     $c->forward('foo');
 359     die join "\n", @{ $c->error } if @{ $c->error };
 360
 361 Or make sure to always return true values from your actions and write
 362 your code like this:
 363
 364     $c->forward('foo') || return;
 365
 366 Another note is that C<< $c->forward >> always returns a scalar because it
 367 actually returns $c->state which operates in a scalar context.
 368 Thus, something like:
 369
 370     return @array;
 371
 372 in an action that is forwarded to is going to return a scalar,
 373 i.e. how many items are in that array, which is probably not what you want.
 374 If you need to return an array then return a reference to it,
 375 or stash it like so:
 376
 377     $c->stash->{array} = \@array;
 378
 379 and access it from the stash.
 380
 381 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 382
 383 =cut
 384
 385 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 386
 387 =head2 $c->detach( $action [, \@arguments ] )
 388
 389 =head2 $c->detach( $class, $method, [, \@arguments ] )
 390
 391 =head2 $c->detach()
 392
 393 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 394 doesn't return to the previous action when processing is finished.
 395
 396 When called with no arguments it escapes the processing chain entirely.
 397
 398 =cut
 399
 400 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 401
 402 =head2 $c->visit( $action [, \@arguments ] )
 403
 404 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 405
 406 =head2 $c->visit( $class, $method, [, \@arguments ] )
 407
 408 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 409
 410 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 411 but does a full dispatch, instead of just calling the new C<$action> /
 412 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 413 you go to are called, just like a new request.
 414
 415 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 416 This means, for example, that C<< $c->action >> methods such as
 417 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 418 L<reverse|Catalyst::Action/reverse> return information for the visited action
 419 when they are invoked within the visited action.  This is different from the
 420 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 421 continues to use the $c->action object from the caller action even when
 422 invoked from the called action.
 423
 424 C<< $c->stash >> is kept unchanged.
 425
 426 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 427 allows you to "wrap" another action, just as it would have been called by
 428 dispatching from a URL, while the analogous
 429 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 430 transfer control to another action as if it had been reached directly from a URL.
 431
 432 =cut
 433
 434 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 435
 436 =head2 $c->go( $action [, \@arguments ] )
 437
 438 =head2 $c->go( $action [, \@captures, \@arguments ] )
 439
 440 =head2 $c->go( $class, $method, [, \@arguments ] )
 441
 442 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 443
 444 The relationship between C<go> and
 445 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 446 the relationship between
 447 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 448 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 449 C<< $c->go >> will perform a full dispatch on the specified action or method,
 450 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 451 C<go> escapes the processing of the current request chain on completion, and
 452 does not return to its caller.
 453
 454 @arguments are arguments to the final destination of $action. @captures are
 455 arguments to the intermediate steps, if any, on the way to the final sub of
 456 $action.
 457
 458 =cut
 459
 460 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 461
 462 =head2 $c->response
 463
 464 =head2 $c->res
 465
 466 Returns the current L<Catalyst::Response> object, see there for details.
 467
 468 =head2 $c->stash
 469
 470 Returns a hashref to the stash, which may be used to store data and pass
 471 it between components during a request. You can also set hash keys by
 472 passing arguments. The stash is automatically sent to the view. The
 473 stash is cleared at the end of a request; it cannot be used for
 474 persistent storage (for this you must use a session; see
 475 L<Catalyst::Plugin::Session> for a complete system integrated with
 476 Catalyst).
 477
 478     $c->stash->{foo} = $bar;
 479     $c->stash( { moose => 'majestic', qux => 0 } );
 480     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 481
 482     # stash is automatically passed to the view for use in a template
 483     $c->forward( 'MyApp::View::TT' );
 484
 485 =cut
 486
 487 around stash => sub {
 488     my $orig = shift;
 489     my $c = shift;
 490     my $stash = $orig->($c);
 491     if (@_) {
 492         my $new_stash = @_ > 1 ? {@_} : $_[0];
 493         croak('stash takes a hash or hashref') unless ref $new_stash;
 494         foreach my $key ( keys %$new_stash ) {
 495           $stash->{$key} = $new_stash->{$key};
 496         }
 497     }
 498
 499     return $stash;
 500 };
 501
 502
 503 =head2 $c->error
 504
 505 =head2 $c->error($error, ...)
 506
 507 =head2 $c->error($arrayref)
 508
 509 Returns an arrayref containing error messages.  If Catalyst encounters an
 510 error while processing a request, it stores the error in $c->error.  This
 511 method should only be used to store fatal error messages.
 512
 513     my @error = @{ $c->error };
 514
 515 Add a new error.
 516
 517     $c->error('Something bad happened');
 518
 519 =cut
 520
 521 sub error {
 522     my $c = shift;
 523     if ( $_[0] ) {
 524         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 525         croak @$error unless ref $c;
 526         push @{ $c->{error} }, @$error;
 527     }
 528     elsif ( defined $_[0] ) { $c->{error} = undef }
 529     return $c->{error} || [];
 530 }
 531
 532
 533 =head2 $c->state
 534
 535 Contains the return value of the last executed action.
 536 Note that << $c->state >> operates in a scalar context which means that all
 537 values it returns are scalar.
 538
 539 =head2 $c->clear_errors
 540
 541 Clear errors.  You probably don't want to clear the errors unless you are
 542 implementing a custom error screen.
 543
 544 This is equivalent to running
 545
 546     $c->error(0);
 547
 548 =cut
 549
 550 sub clear_errors {
 551     my $c = shift;
 552     $c->error(0);
 553 }
 554
 555 sub _comp_search_prefixes {
 556     my $c = shift;
 557     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 558 }
 559
 560 # search components given a name and some prefixes
 561 sub _comp_names_search_prefixes {
 562     my ( $c, $name, @prefixes ) = @_;
 563     my $appclass = ref $c || $c;
 564     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 565     $filter = qr/$filter/; # Compile regex now rather than once per loop
 566
 567     # map the original component name to the sub part that we will search against
 568     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 569         grep { /$filter/ } keys %{ $c->components };
 570
 571     # undef for a name will return all
 572     return keys %eligible if !defined $name;
 573
 574     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 575     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 576
 577     return @result if @result;
 578
 579     # if we were given a regexp to search against, we're done.
 580     return if $name->$_isa('Regexp');
 581
 582     # skip regexp fallback if configured
 583     return
 584         if $appclass->config->{disable_component_resolution_regex_fallback};
 585
 586     # regexp fallback
 587     $query  = qr/$name/i;
 588     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 589
 590     # no results? try against full names
 591     if( !@result ) {
 592         @result = grep { m{$query} } keys %eligible;
 593     }
 594
 595     # don't warn if we didn't find any results, it just might not exist
 596     if( @result ) {
 597         # Disgusting hack to work out correct method name
 598         my $warn_for = lc $prefixes[0];
 599         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 600            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 601            "component resolution is unreliable and unsafe.";
 602         my $short = $result[0];
 603         # remove the component namespace prefix
 604         $short =~ s/.*?(Model|Controller|View):://;
 605         my $shortmess = Carp::shortmess('');
 606         if ($shortmess =~ m#Catalyst/Plugin#) {
 607            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 608               "plugin's config";
 609         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 610            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 611               "component's config";
 612         } else {
 613            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 614               "but if you really wanted to search, pass in a regexp as the argument " .
 615               "like so: \$c->${warn_for}(qr/${name}/)";
 616         }
 617         $c->log->warn( "${msg}$shortmess" );
 618     }
 619
 620     return @result;
 621 }
 622
 623 # Find possible names for a prefix
 624 sub _comp_names {
 625     my ( $c, @prefixes ) = @_;
 626     my $appclass = ref $c || $c;
 627
 628     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 629
 630     my @names = map { s{$filter}{}; $_; }
 631         $c->_comp_names_search_prefixes( undef, @prefixes );
 632
 633     return @names;
 634 }
 635
 636 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 637 sub _filter_component {
 638     my ( $c, $comp, @args ) = @_;
 639
 640     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 641         return $comp->ACCEPT_CONTEXT( $c, @args );
 642     }
 643
 644     return $comp;
 645 }
 646
 647 =head2 COMPONENT ACCESSORS
 648
 649 =head2 $c->controller($name)
 650
 651 Gets a L<Catalyst::Controller> instance by name.
 652
 653     $c->controller('Foo')->do_stuff;
 654
 655 If the name is omitted, will return the controller for the dispatched
 656 action.
 657
 658 If you want to search for controllers, pass in a regexp as the argument.
 659
 660     # find all controllers that start with Foo
 661     my @foo_controllers = $c->controller(qr{^Foo});
 662
 663
 664 =cut
 665
 666 sub controller {
 667     my ( $c, $name, @args ) = @_;
 668
 669     my $appclass = ref($c) || $c;
 670     if( $name ) {
 671         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 672             my $comps = $c->components;
 673             my $check = $appclass."::Controller::".$name;
 674             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 675         }
 676         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 677         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 678         return $c->_filter_component( $result[ 0 ], @args );
 679     }
 680
 681     return $c->component( $c->action->class );
 682 }
 683
 684 =head2 $c->model($name)
 685
 686 Gets a L<Catalyst::Model> instance by name.
 687
 688     $c->model('Foo')->do_stuff;
 689
 690 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 691
 692 If the name is omitted, it will look for
 693  - a model object in $c->stash->{current_model_instance}, then
 694  - a model name in $c->stash->{current_model}, then
 695  - a config setting 'default_model', or
 696  - check if there is only one model, and return it if that's the case.
 697
 698 If you want to search for models, pass in a regexp as the argument.
 699
 700     # find all models that start with Foo
 701     my @foo_models = $c->model(qr{^Foo});
 702
 703 =cut
 704
 705 sub model {
 706     my ( $c, $name, @args ) = @_;
 707     my $appclass = ref($c) || $c;
 708     if( $name ) {
 709         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 710             my $comps = $c->components;
 711             my $check = $appclass."::Model::".$name;
 712             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 713         }
 714         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 715         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 716         return $c->_filter_component( $result[ 0 ], @args );
 717     }
 718
 719     if (ref $c) {
 720         return $c->stash->{current_model_instance}
 721           if $c->stash->{current_model_instance};
 722         return $c->model( $c->stash->{current_model} )
 723           if $c->stash->{current_model};
 724     }
 725     return $c->model( $appclass->config->{default_model} )
 726       if $appclass->config->{default_model};
 727
 728     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 729
 730     if( $rest ) {
 731         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 732         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 733         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 734         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 735         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 736     }
 737
 738     return $c->_filter_component( $comp );
 739 }
 740
 741
 742 =head2 $c->view($name)
 743
 744 Gets a L<Catalyst::View> instance by name.
 745
 746     $c->view('Foo')->do_stuff;
 747
 748 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 749
 750 If the name is omitted, it will look for
 751  - a view object in $c->stash->{current_view_instance}, then
 752  - a view name in $c->stash->{current_view}, then
 753  - a config setting 'default_view', or
 754  - check if there is only one view, and return it if that's the case.
 755
 756 If you want to search for views, pass in a regexp as the argument.
 757
 758     # find all views that start with Foo
 759     my @foo_views = $c->view(qr{^Foo});
 760
 761 =cut
 762
 763 sub view {
 764     my ( $c, $name, @args ) = @_;
 765
 766     my $appclass = ref($c) || $c;
 767     if( $name ) {
 768         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 769             my $comps = $c->components;
 770             my $check = $appclass."::View::".$name;
 771             if( exists $comps->{$check} ) {
 772                 return $c->_filter_component( $comps->{$check}, @args );
 773             }
 774             else {
 775                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 776             }
 777         }
 778         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 779         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 780         return $c->_filter_component( $result[ 0 ], @args );
 781     }
 782
 783     if (ref $c) {
 784         return $c->stash->{current_view_instance}
 785           if $c->stash->{current_view_instance};
 786         return $c->view( $c->stash->{current_view} )
 787           if $c->stash->{current_view};
 788     }
 789     return $c->view( $appclass->config->{default_view} )
 790       if $appclass->config->{default_view};
 791
 792     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 793
 794     if( $rest ) {
 795         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 796         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 797         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 798         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 799         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 800     }
 801
 802     return $c->_filter_component( $comp );
 803 }
 804
 805 =head2 $c->controllers
 806
 807 Returns the available names which can be passed to $c->controller
 808
 809 =cut
 810
 811 sub controllers {
 812     my ( $c ) = @_;
 813     return $c->_comp_names(qw/Controller C/);
 814 }
 815
 816 =head2 $c->models
 817
 818 Returns the available names which can be passed to $c->model
 819
 820 =cut
 821
 822 sub models {
 823     my ( $c ) = @_;
 824     return $c->_comp_names(qw/Model M/);
 825 }
 826
 827
 828 =head2 $c->views
 829
 830 Returns the available names which can be passed to $c->view
 831
 832 =cut
 833
 834 sub views {
 835     my ( $c ) = @_;
 836     return $c->_comp_names(qw/View V/);
 837 }
 838
 839 =head2 $c->comp($name)
 840
 841 =head2 $c->component($name)
 842
 843 Gets a component object by name. This method is not recommended,
 844 unless you want to get a specific component by full
 845 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 846 should be used instead.
 847
 848 If C<$name> is a regexp, a list of components matched against the full
 849 component name will be returned.
 850
 851 If Catalyst can't find a component by name, it will fallback to regex
 852 matching by default. To disable this behaviour set
 853 disable_component_resolution_regex_fallback to a true value.
 854
 855     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 856
 857 =cut
 858
 859 sub component {
 860     my ( $c, $name, @args ) = @_;
 861
 862     if( $name ) {
 863         my $comps = $c->components;
 864
 865         if( !ref $name ) {
 866             # is it the exact name?
 867             return $c->_filter_component( $comps->{ $name }, @args )
 868                        if exists $comps->{ $name };
 869
 870             # perhaps we just omitted "MyApp"?
 871             my $composed = ( ref $c || $c ) . "::${name}";
 872             return $c->_filter_component( $comps->{ $composed }, @args )
 873                        if exists $comps->{ $composed };
 874
 875             # search all of the models, views and controllers
 876             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 877             return $c->_filter_component( $comp, @args ) if $comp;
 878         }
 879
 880         return
 881             if $c->config->{disable_component_resolution_regex_fallback};
 882
 883         # This is here so $c->comp( '::M::' ) works
 884         my $query = ref $name ? $name : qr{$name}i;
 885
 886         my @result = grep { m{$query} } keys %{ $c->components };
 887         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 888
 889         if( $result[ 0 ] ) {
 890             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 891             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 892             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 893             return $c->_filter_component( $result[ 0 ], @args );
 894         }
 895
 896         # I would expect to return an empty list here, but that breaks back-compat
 897     }
 898
 899     # fallback
 900     return sort keys %{ $c->components };
 901 }
 902
 903 =head2 CLASS DATA AND HELPER CLASSES
 904
 905 =head2 $c->config
 906
 907 Returns or takes a hashref containing the application's configuration.
 908
 909     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 910
 911 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 912 like C<myapp.conf> in your applications home directory. See
 913 L<Catalyst::Plugin::ConfigLoader>.
 914
 915 =head3 Cascading configuration
 916
 917 The config method is present on all Catalyst components, and configuration
 918 will be merged when an application is started. Configuration loaded with
 919 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 920 followed by configuration in your top level C<MyApp> class. These two
 921 configurations are merged, and then configuration data whose hash key matches a
 922 component name is merged with configuration for that component.
 923
 924 The configuration for a component is then passed to the C<new> method when a
 925 component is constructed.
 926
 927 For example:
 928
 929     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 930     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 931
 932 will mean that C<MyApp::Model::Foo> receives the following data when
 933 constructed:
 934
 935     MyApp::Model::Foo->new({
 936         bar => 'baz',
 937         quux => 'frob',
 938         overrides => 'me',
 939     });
 940
 941 It's common practice to use a Moose attribute
 942 on the receiving component to access the config value.
 943
 944     package MyApp::Model::Foo;
 945
 946     use Moose;
 947
 948     # this attr will receive 'baz' at construction time
 949     has 'bar' => (
 950         is  => 'rw',
 951         isa => 'Str',
 952     );
 953
 954 You can then get the value 'baz' by calling $c->model('Foo')->bar
 955 (or $self->bar inside code in the model).
 956
 957 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 958 as a way of reading config within your code, as this B<will not> give you the
 959 correctly merged config back. You B<MUST> take the config values supplied to
 960 the constructor and use those instead.
 961
 962 =cut
 963
 964 around config => sub {
 965     my $orig = shift;
 966     my $c = shift;
 967
 968     croak('Setting config after setup has been run is not allowed.')
 969         if ( @_ and $c->setup_finished );
 970
 971     $c->$orig(@_);
 972 };
 973
 974 =head2 $c->log
 975
 976 Returns the logging object instance. Unless it is already set, Catalyst
 977 sets this up with a L<Catalyst::Log> object. To use your own log class,
 978 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 979 C<< __PACKAGE__->setup >>.
 980
 981  __PACKAGE__->log( MyLogger->new );
 982  __PACKAGE__->setup;
 983
 984 And later:
 985
 986     $c->log->info( 'Now logging with my own logger!' );
 987
 988 Your log class should implement the methods described in
 989 L<Catalyst::Log>.
 990
 991
 992 =head2 $c->debug
 993
 994 Returns 1 if debug mode is enabled, 0 otherwise.
 995
 996 You can enable debug mode in several ways:
 997
 998 =over
 999
1000 =item By calling myapp_server.pl with the -d flag
1001
1002 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1003
1004 =item The -Debug option in your MyApp.pm
1005
1006 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1007
1008 =back
1009
1010 The first three also set the log level to 'debug'.
1011
1012 Calling C<< $c->debug(1) >> has no effect.
1013
1014 =cut
1015
1016 sub debug { 0 }
1017
1018 =head2 $c->dispatcher
1019
1020 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1021
1022 =head2 $c->engine
1023
1024 Returns the engine instance. See L<Catalyst::Engine>.
1025
1026
1027 =head2 UTILITY METHODS
1028
1029 =head2 $c->path_to(@path)
1030
1031 Merges C<@path> with C<< $c->config->{home} >> and returns a
1032 L<Path::Class::Dir> object. Note you can usually use this object as
1033 a filename, but sometimes you will have to explicitly stringify it
1034 yourself by calling the C<< ->stringify >> method.
1035
1036 For example:
1037
1038     $c->path_to( 'db', 'sqlite.db' );
1039
1040 =cut
1041
1042 sub path_to {
1043     my ( $c, @path ) = @_;
1044     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1045     if ( -d $path ) { return $path }
1046     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1047 }
1048
1049 sub plugin {
1050     my ( $class, $name, $plugin, @args ) = @_;
1051
1052     # See block comment in t/unit_core_plugin.t
1053     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1054
1055     $class->_register_plugin( $plugin, 1 );
1056
1057     eval { $plugin->import };
1058     $class->mk_classdata($name);
1059     my $obj;
1060     eval { $obj = $plugin->new(@args) };
1061
1062     if ($@) {
1063         Catalyst::Exception->throw( message =>
1064               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1065     }
1066
1067     $class->$name($obj);
1068     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1069       if $class->debug;
1070 }
1071
1072 =head2 MyApp->setup
1073
1074 Initializes the dispatcher and engine, loads any plugins, and loads the
1075 model, view, and controller components. You may also specify an array
1076 of plugins to load here, if you choose to not load them in the C<use
1077 Catalyst> line.
1078
1079     MyApp->setup;
1080     MyApp->setup( qw/-Debug/ );
1081
1082 B<Note:> You B<should not> wrap this method with method modifiers
1083 or bad things will happen - wrap the C<setup_finalize> method instead.
1084
1085 =cut
1086
1087 sub setup {
1088     my ( $class, @arguments ) = @_;
1089     croak('Running setup more than once')
1090         if ( $class->setup_finished );
1091
1092     unless ( $class->isa('Catalyst') ) {
1093
1094         Catalyst::Exception->throw(
1095             message => qq/'$class' does not inherit from Catalyst/ );
1096     }
1097
1098     if ( $class->arguments ) {
1099         @arguments = ( @arguments, @{ $class->arguments } );
1100     }
1101
1102     # Process options
1103     my $flags = {};
1104
1105     foreach (@arguments) {
1106
1107         if (/^-Debug$/) {
1108             $flags->{log} =
1109               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1110         }
1111         elsif (/^-(\w+)=?(.*)$/) {
1112             $flags->{ lc $1 } = $2;
1113         }
1114         else {
1115             push @{ $flags->{plugins} }, $_;
1116         }
1117     }
1118
1119     $class->setup_home( delete $flags->{home} );
1120
1121     $class->setup_log( delete $flags->{log} );
1122     $class->setup_plugins( delete $flags->{plugins} );
1123     $class->setup_dispatcher( delete $flags->{dispatcher} );
1124     if (my $engine = delete $flags->{engine}) {
1125         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1126     }
1127     $class->setup_engine();
1128     $class->setup_stats( delete $flags->{stats} );
1129
1130     for my $flag ( sort keys %{$flags} ) {
1131
1132         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1133             &$code( $class, delete $flags->{$flag} );
1134         }
1135         else {
1136             $class->log->warn(qq/Unknown flag "$flag"/);
1137         }
1138     }
1139
1140     eval { require Catalyst::Devel; };
1141     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1142         $class->log->warn(<<"EOF");
1143 You are running an old script!
1144
1145   Please update by running (this will overwrite existing files):
1146     catalyst.pl -force -scripts $class
1147
1148   or (this will not overwrite existing files):
1149     catalyst.pl -scripts $class
1150
1151 EOF
1152     }
1153
1154     if ( $class->debug ) {
1155         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1156
1157         if (@plugins) {
1158             my $column_width = Catalyst::Utils::term_width() - 6;
1159             my $t = Text::SimpleTable->new($column_width);
1160             $t->row($_) for @plugins;
1161             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1162         }
1163
1164         my $dispatcher = $class->dispatcher;
1165         my $engine     = $class->engine;
1166         my $home       = $class->config->{home};
1167
1168         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1169         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1170
1171         $home
1172           ? ( -d $home )
1173           ? $class->log->debug(qq/Found home "$home"/)
1174           : $class->log->debug(qq/Home "$home" doesn't exist/)
1175           : $class->log->debug(q/Couldn't find home/);
1176     }
1177
1178     # Call plugins setup, this is stupid and evil.
1179     # Also screws C3 badly on 5.10, hack to avoid.
1180     {
1181         no warnings qw/redefine/;
1182         local *setup = sub { };
1183         $class->setup unless $Catalyst::__AM_RESTARTING;
1184     }
1185
1186     # Initialize our data structure
1187     $class->components( {} );
1188
1189     $class->setup_components;
1190
1191     if ( $class->debug ) {
1192         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1193         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1194         for my $comp ( sort keys %{ $class->components } ) {
1195             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1196             $t->row( $comp, $type );
1197         }
1198         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1199           if ( keys %{ $class->components } );
1200     }
1201
1202     # Add our self to components, since we are also a component
1203     if( $class->isa('Catalyst::Controller') ){
1204       $class->components->{$class} = $class;
1205     }
1206
1207     $class->setup_actions;
1208
1209     if ( $class->debug ) {
1210         my $name = $class->config->{name} || 'Application';
1211         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1212     }
1213
1214     if ($class->config->{case_sensitive}) {
1215         $class->log->warn($class . "->config->{case_sensitive} is set.");
1216         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1217     }
1218
1219     $class->setup_finalize;
1220     # Should be the last thing we do so that user things hooking
1221     # setup_finalize can log..
1222     $class->log->_flush() if $class->log->can('_flush');
1223     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1224 }
1225
1226 =head2 $app->setup_finalize
1227
1228 A hook to attach modifiers to. This method does not do anything except set the
1229 C<setup_finished> accessor.
1230
1231 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1232
1233 Example:
1234
1235     after setup_finalize => sub {
1236         my $app = shift;
1237
1238         ## do stuff here..
1239     };
1240
1241 =cut
1242
1243 sub setup_finalize {
1244     my ($class) = @_;
1245     $class->setup_finished(1);
1246 }
1247
1248 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1249
1250 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1251
1252 Constructs an absolute L<URI> object based on the application root, the
1253 provided path, and the additional arguments and query parameters provided.
1254 When used as a string, provides a textual URI.  If you need more flexibility
1255 than this (i.e. the option to provide relative URIs etc.) see
1256 L<Catalyst::Plugin::SmartURI>.
1257
1258 If no arguments are provided, the URI for the current action is returned.
1259 To return the current action and also provide @args, use
1260 C<< $c->uri_for( $c->action, @args ) >>.
1261
1262 If the first argument is a string, it is taken as a public URI path relative
1263 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1264 relative to the application root (if it does). It is then merged with
1265 C<< $c->request->base >>; any C<@args> are appended as additional path
1266 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1267
1268 If the first argument is a L<Catalyst::Action> it represents an action which
1269 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1270 optional C<\@captures> argument (an arrayref) allows passing the captured
1271 variables that are needed to fill in the paths of Chained and Regex actions;
1272 once the path is resolved, C<uri_for> continues as though a path was
1273 provided, appending any arguments or parameters and creating an absolute
1274 URI.
1275
1276 The captures for the current request can be found in
1277 C<< $c->request->captures >>, and actions can be resolved using
1278 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1279 path, use C<< $c->uri_for_action >> instead.
1280
1281   # Equivalent to $c->req->uri
1282   $c->uri_for($c->action, $c->req->captures,
1283       @{ $c->req->args }, $c->req->params);
1284
1285   # For the Foo action in the Bar controller
1286   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1287
1288   # Path to a static resource
1289   $c->uri_for('/static/images/logo.png');
1290
1291 =cut
1292
1293 sub uri_for {
1294     my ( $c, $path, @args ) = @_;
1295
1296     if ( $path->$_isa('Catalyst::Controller') ) {
1297         $path = $path->path_prefix;
1298         $path =~ s{/+\z}{};
1299         $path .= '/';
1300     }
1301
1302     undef($path) if (defined $path && $path eq '');
1303
1304     my $params =
1305       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1306
1307     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1308     foreach my $arg (@args) {
1309         utf8::encode($arg) if utf8::is_utf8($arg);
1310         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1311     }
1312
1313     if ( $path->$_isa('Catalyst::Action') ) { # action object
1314         s|/|%2F|g for @args;
1315         my $captures = [ map { s|/|%2F|g; $_; }
1316                         ( scalar @args && ref $args[0] eq 'ARRAY'
1317                          ? @{ shift(@args) }
1318                          : ()) ];
1319
1320         foreach my $capture (@$captures) {
1321             utf8::encode($capture) if utf8::is_utf8($capture);
1322             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1323         }
1324
1325         my $action = $path;
1326         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1327         if( !@args && $action->number_of_args ) {
1328             my $expanded_action = $c->dispatcher->expand_action( $action );
1329
1330             my $num_captures = $expanded_action->number_of_captures;
1331             unshift @args, splice @$captures, $num_captures;
1332         }
1333
1334        $path = $c->dispatcher->uri_for_action($action, $captures);
1335         if (not defined $path) {
1336             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1337                 if $c->debug;
1338             return undef;
1339         }
1340         $path = '/' if $path eq '';
1341     }
1342
1343     unshift(@args, $path);
1344
1345     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1346         my $namespace = $c->namespace;
1347         if (defined $path) { # cheesy hack to handle path '../foo'
1348            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1349         }
1350         unshift(@args, $namespace || '');
1351     }
1352
1353     # join args with '/', or a blank string
1354     my $args = join('/', grep { defined($_) } @args);
1355     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1356     $args =~ s!^/+!!;
1357
1358     my ($base, $class) = ('/', 'URI::_generic');
1359     if(blessed($c)) {
1360       $base = $c->req->base;
1361       $class = ref($base);
1362       $base =~ s{(?<!/)$}{/};
1363     }
1364
1365     my $query = '';
1366
1367     if (my @keys = keys %$params) {
1368       # somewhat lifted from URI::_query's query_form
1369       $query = '?'.join('&', map {
1370           my $val = $params->{$_};
1371           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1372           s/ /+/g;
1373           my $key = $_;
1374           $val = '' unless defined $val;
1375           (map {
1376               my $param = "$_";
1377               utf8::encode( $param ) if utf8::is_utf8($param);
1378               # using the URI::Escape pattern here so utf8 chars survive
1379               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1380               $param =~ s/ /+/g;
1381               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1382       } @keys);
1383     }
1384
1385     my $res = bless(\"${base}${args}${query}", $class);
1386     $res;
1387 }
1388
1389 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1390
1391 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1392
1393 =over
1394
1395 =item $path
1396
1397 A private path to the Catalyst action you want to create a URI for.
1398
1399 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1400 >> and passing the resulting C<$action> and the remaining arguments to C<<
1401 $c->uri_for >>.
1402
1403 You can also pass in a Catalyst::Action object, in which case it is passed to
1404 C<< $c->uri_for >>.
1405
1406 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1407
1408 For example, if the action looks like:
1409
1410  package MyApp::Controller::Users;
1411
1412  sub lst : Path('the-list') {}
1413
1414 You can use:
1415
1416  $c->uri_for_action('/users/lst')
1417
1418 and it will create the URI /users/the-list.
1419
1420 =item \@captures_and_args?
1421
1422 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1423 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1424 to interpolate all the parameters in the URI.
1425
1426 =item @args?
1427
1428 Optional list of extra arguments - can be supplied in the
1429 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1430 code.
1431
1432 Your action can have zero, a fixed or a variable number of args (e.g.
1433 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1434
1435 =item \%query_values?
1436
1437 Optional array reference of query parameters to append. E.g.
1438
1439   { foo => 'bar' }
1440
1441 will generate
1442
1443   /rest/of/your/uri?foo=bar
1444
1445 =back
1446
1447 =cut
1448
1449 sub uri_for_action {
1450     my ( $c, $path, @args ) = @_;
1451     my $action = blessed($path)
1452       ? $path
1453       : $c->dispatcher->get_action_by_path($path);
1454     unless (defined $action) {
1455       croak "Can't find action for path '$path'";
1456     }
1457     return $c->uri_for( $action, @args );
1458 }
1459
1460 =head2 $c->welcome_message
1461
1462 Returns the Catalyst welcome HTML page.
1463
1464 =cut
1465
1466 sub welcome_message {
1467     my $c      = shift;
1468     my $name   = $c->config->{name};
1469     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1470     my $prefix = Catalyst::Utils::appprefix( ref $c );
1471     $c->response->content_type('text/html; charset=utf-8');
1472     return <<"EOF";
1473 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1474     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1475 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1476     <head>
1477     <meta http-equiv="Content-Language" content="en" />
1478     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1479         <title>$name on Catalyst $VERSION</title>
1480         <style type="text/css">
1481             body {
1482                 color: #000;
1483                 background-color: #eee;
1484             }
1485             div#content {
1486                 width: 640px;
1487                 margin-left: auto;
1488                 margin-right: auto;
1489                 margin-top: 10px;
1490                 margin-bottom: 10px;
1491                 text-align: left;
1492                 background-color: #ccc;
1493                 border: 1px solid #aaa;
1494             }
1495             p, h1, h2 {
1496                 margin-left: 20px;
1497                 margin-right: 20px;
1498                 font-family: verdana, tahoma, sans-serif;
1499             }
1500             a {
1501                 font-family: verdana, tahoma, sans-serif;
1502             }
1503             :link, :visited {
1504                     text-decoration: none;
1505                     color: #b00;
1506                     border-bottom: 1px dotted #bbb;
1507             }
1508             :link:hover, :visited:hover {
1509                     color: #555;
1510             }
1511             div#topbar {
1512                 margin: 0px;
1513             }
1514             pre {
1515                 margin: 10px;
1516                 padding: 8px;
1517             }
1518             div#answers {
1519                 padding: 8px;
1520                 margin: 10px;
1521                 background-color: #fff;
1522                 border: 1px solid #aaa;
1523             }
1524             h1 {
1525                 font-size: 0.9em;
1526                 font-weight: normal;
1527                 text-align: center;
1528             }
1529             h2 {
1530                 font-size: 1.0em;
1531             }
1532             p {
1533                 font-size: 0.9em;
1534             }
1535             p img {
1536                 float: right;
1537                 margin-left: 10px;
1538             }
1539             span#appname {
1540                 font-weight: bold;
1541                 font-size: 1.6em;
1542             }
1543         </style>
1544     </head>
1545     <body>
1546         <div id="content">
1547             <div id="topbar">
1548                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1549                     $VERSION</h1>
1550              </div>
1551              <div id="answers">
1552                  <p>
1553                  <img src="$logo" alt="Catalyst Logo" />
1554                  </p>
1555                  <p>Welcome to the  world of Catalyst.
1556                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1557                     framework will make web development something you had
1558                     never expected it to be: Fun, rewarding, and quick.</p>
1559                  <h2>What to do now?</h2>
1560                  <p>That really depends  on what <b>you</b> want to do.
1561                     We do, however, provide you with a few starting points.</p>
1562                  <p>If you want to jump right into web development with Catalyst
1563                     you might want to start with a tutorial.</p>
1564 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1565 </pre>
1566 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1567 <pre>
1568 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1569 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1570 </code></pre>
1571                  <h2>What to do next?</h2>
1572                  <p>Next it's time to write an actual application. Use the
1573                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1574                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1575                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1576                     they can save you a lot of work.</p>
1577                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1578                     <p>Also, be sure to check out the vast and growing
1579                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1580                     you are likely to find what you need there.
1581                     </p>
1582
1583                  <h2>Need help?</h2>
1584                  <p>Catalyst has a very active community. Here are the main places to
1585                     get in touch with us.</p>
1586                  <ul>
1587                      <li>
1588                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1589                      </li>
1590                      <li>
1591                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1592                      </li>
1593                      <li>
1594                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1595                      </li>
1596                  </ul>
1597                  <h2>In conclusion</h2>
1598                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1599                     as we enjoyed making it. Please contact us if you have ideas
1600                     for improvement or other feedback.</p>
1601              </div>
1602          </div>
1603     </body>
1604 </html>
1605 EOF
1606 }
1607
1608 =head2 run_options
1609
1610 Contains a hash of options passed from the application script, including
1611 the original ARGV the script received, the processed values from that
1612 ARGV and any extra arguments to the script which were not processed.
1613
1614 This can be used to add custom options to your application's scripts
1615 and setup your application differently depending on the values of these
1616 options.
1617
1618 =head1 INTERNAL METHODS
1619
1620 These methods are not meant to be used by end users.
1621
1622 =head2 $c->components
1623
1624 Returns a hash of components.
1625
1626 =head2 $c->context_class
1627
1628 Returns or sets the context class.
1629
1630 =head2 $c->counter
1631
1632 Returns a hashref containing coderefs and execution counts (needed for
1633 deep recursion detection).
1634
1635 =head2 $c->depth
1636
1637 Returns the number of actions on the current internal execution stack.
1638
1639 =head2 $c->dispatch
1640
1641 Dispatches a request to actions.
1642
1643 =cut
1644
1645 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1646
1647 =head2 $c->dispatcher_class
1648
1649 Returns or sets the dispatcher class.
1650
1651 =head2 $c->dump_these
1652
1653 Returns a list of 2-element array references (name, structure) pairs
1654 that will be dumped on the error page in debug mode.
1655
1656 =cut
1657
1658 sub dump_these {
1659     my $c = shift;
1660     [ Request => $c->req ],
1661     [ Response => $c->res ],
1662     [ Stash => $c->stash ],
1663     [ Config => $c->config ];
1664 }
1665
1666 =head2 $c->engine_class
1667
1668 Returns or sets the engine class.
1669
1670 =head2 $c->execute( $class, $coderef )
1671
1672 Execute a coderef in given class and catch exceptions. Errors are available
1673 via $c->error.
1674
1675 =cut
1676
1677 sub execute {
1678     my ( $c, $class, $code ) = @_;
1679     $class = $c->component($class) || $class;
1680     $c->state(0);
1681
1682     if ( $c->depth >= $RECURSION ) {
1683         my $action = $code->reverse();
1684         $action = "/$action" unless $action =~ /->/;
1685         my $error = qq/Deep recursion detected calling "${action}"/;
1686         $c->log->error($error);
1687         $c->error($error);
1688         $c->state(0);
1689         return $c->state;
1690     }
1691
1692     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1693
1694     push( @{ $c->stack }, $code );
1695
1696     no warnings 'recursion';
1697     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1698     #      I have no idea how, ergo $ret (which appears to fix the issue)
1699     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1700
1701     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1702
1703     my $last = pop( @{ $c->stack } );
1704
1705     if ( my $error = $@ ) {
1706         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1707             $error->rethrow if $c->depth > 1;
1708         }
1709         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1710             $error->rethrow if $c->depth > 0;
1711         }
1712         else {
1713             unless ( ref $error ) {
1714                 no warnings 'uninitialized';
1715                 chomp $error;
1716                 my $class = $last->class;
1717                 my $name  = $last->name;
1718                 $error = qq/Caught exception in $class->$name "$error"/;
1719             }
1720             $c->error($error);
1721         }
1722         $c->state(0);
1723     }
1724     return $c->state;
1725 }
1726
1727 sub _stats_start_execute {
1728     my ( $c, $code ) = @_;
1729     my $appclass = ref($c) || $c;
1730     return if ( ( $code->name =~ /^_.*/ )
1731         && ( !$appclass->config->{show_internal_actions} ) );
1732
1733     my $action_name = $code->reverse();
1734     $c->counter->{$action_name}++;
1735
1736     my $action = $action_name;
1737     $action = "/$action" unless $action =~ /->/;
1738
1739     # determine if the call was the result of a forward
1740     # this is done by walking up the call stack and looking for a calling
1741     # sub of Catalyst::forward before the eval
1742     my $callsub = q{};
1743     for my $index ( 2 .. 11 ) {
1744         last
1745         if ( ( caller($index) )[0] eq 'Catalyst'
1746             && ( caller($index) )[3] eq '(eval)' );
1747
1748         if ( ( caller($index) )[3] =~ /forward$/ ) {
1749             $callsub = ( caller($index) )[3];
1750             $action  = "-> $action";
1751             last;
1752         }
1753     }
1754
1755     my $uid = $action_name . $c->counter->{$action_name};
1756
1757     # is this a root-level call or a forwarded call?
1758     if ( $callsub =~ /forward$/ ) {
1759         my $parent = $c->stack->[-1];
1760
1761         # forward, locate the caller
1762         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1763             $c->stats->profile(
1764                 begin  => $action,
1765                 parent => "$parent" . $c->counter->{"$parent"},
1766                 uid    => $uid,
1767             );
1768         }
1769         else {
1770
1771             # forward with no caller may come from a plugin
1772             $c->stats->profile(
1773                 begin => $action,
1774                 uid   => $uid,
1775             );
1776         }
1777     }
1778     else {
1779
1780         # root-level call
1781         $c->stats->profile(
1782             begin => $action,
1783             uid   => $uid,
1784         );
1785     }
1786     return $action;
1787
1788 }
1789
1790 sub _stats_finish_execute {
1791     my ( $c, $info ) = @_;
1792     $c->stats->profile( end => $info );
1793 }
1794
1795 =head2 $c->finalize
1796
1797 Finalizes the request.
1798
1799 =cut
1800
1801 sub finalize {
1802     my $c = shift;
1803
1804     for my $error ( @{ $c->error } ) {
1805         $c->log->error($error);
1806     }
1807
1808     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1809     # stuff like cometd and websockets
1810
1811     if($c->request->has_io_fh) {
1812       $c->log_response;
1813       return;
1814     }
1815
1816     # Allow engine to handle finalize flow (for POE)
1817     my $engine = $c->engine;
1818     if ( my $code = $engine->can('finalize') ) {
1819         $engine->$code($c);
1820     }
1821     else {
1822
1823         $c->finalize_uploads;
1824
1825         # Error
1826         if ( $#{ $c->error } >= 0 ) {
1827             $c->finalize_error;
1828         }
1829
1830         $c->finalize_headers unless $c->response->finalized_headers;
1831
1832         # HEAD request
1833         if ( $c->request->method eq 'HEAD' ) {
1834             $c->response->body('');
1835         }
1836
1837         $c->finalize_body;
1838     }
1839
1840     $c->log_response;
1841
1842     if ($c->use_stats) {
1843         my $elapsed = $c->stats->elapsed;
1844         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1845         $c->log->info(
1846             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1847     }
1848
1849     return $c->response->status;
1850 }
1851
1852 =head2 $c->finalize_body
1853
1854 Finalizes body.
1855
1856 =cut
1857
1858 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1859
1860 =head2 $c->finalize_cookies
1861
1862 Finalizes cookies.
1863
1864 =cut
1865
1866 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1867
1868 =head2 $c->finalize_error
1869
1870 Finalizes error.
1871
1872 =cut
1873
1874 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1875
1876 =head2 $c->finalize_headers
1877
1878 Finalizes headers.
1879
1880 =cut
1881
1882 sub finalize_headers {
1883     my $c = shift;
1884
1885     my $response = $c->response; #accessor calls can add up?
1886
1887     # Check if we already finalized headers
1888     return if $response->finalized_headers;
1889
1890     # Handle redirects
1891     if ( my $location = $response->redirect ) {
1892         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1893         $response->header( Location => $location );
1894
1895         if ( !$response->has_body ) {
1896             # Add a default body if none is already present
1897             my $encoded_location = encode_entities($location);
1898             $response->body(<<"EOF");
1899 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1900 <html xmlns="http://www.w3.org/1999/xhtml">
1901   <head>
1902     <title>Moved</title>
1903   </head>
1904   <body>
1905      <p>This item has moved <a href="$encoded_location">here</a>.</p>
1906   </body>
1907 </html>
1908 EOF
1909             $response->content_type('text/html; charset=utf-8');
1910         }
1911     }
1912
1913     # Content-Length
1914     if ( defined $response->body && length $response->body && !$response->content_length ) {
1915
1916         # get the length from a filehandle
1917         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1918         {
1919             my $size = -s $response->body;
1920             if ( $size ) {
1921                 $response->content_length( $size );
1922             }
1923             else {
1924                 $c->log->warn('Serving filehandle without a content-length');
1925             }
1926         }
1927         else {
1928             # everything should be bytes at this point, but just in case
1929             $response->content_length( length( $response->body ) );
1930         }
1931     }
1932
1933     # Errors
1934     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1935         $response->headers->remove_header("Content-Length");
1936         $response->body('');
1937     }
1938
1939     $c->finalize_cookies;
1940
1941     $c->response->finalize_headers();
1942
1943     # Done
1944     $response->finalized_headers(1);
1945 }
1946
1947 =head2 $c->finalize_output
1948
1949 An alias for finalize_body.
1950
1951 =head2 $c->finalize_read
1952
1953 Finalizes the input after reading is complete.
1954
1955 =cut
1956
1957 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1958
1959 =head2 $c->finalize_uploads
1960
1961 Finalizes uploads. Cleans up any temporary files.
1962
1963 =cut
1964
1965 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1966
1967 =head2 $c->get_action( $action, $namespace )
1968
1969 Gets an action in a given namespace.
1970
1971 =cut
1972
1973 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1974
1975 =head2 $c->get_actions( $action, $namespace )
1976
1977 Gets all actions of a given name in a namespace and all parent
1978 namespaces.
1979
1980 =cut
1981
1982 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1983
1984 =head2 $app->handle_request( @arguments )
1985
1986 Called to handle each HTTP request.
1987
1988 =cut
1989
1990 sub handle_request {
1991     my ( $class, @arguments ) = @_;
1992
1993     # Always expect worst case!
1994     my $status = -1;
1995     try {
1996         if ($class->debug) {
1997             my $secs = time - $START || 1;
1998             my $av = sprintf '%.3f', $COUNT / $secs;
1999             my $time = localtime time;
2000             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2001         }
2002
2003         my $c = $class->prepare(@arguments);
2004         $c->dispatch;
2005         $status = $c->finalize;
2006     }
2007     catch {
2008         chomp(my $error = $_);
2009         $class->log->error(qq/Caught exception in engine "$error"/);
2010     };
2011
2012     $COUNT++;
2013
2014     if(my $coderef = $class->log->can('_flush')){
2015         $class->log->$coderef();
2016     }
2017     return $status;
2018 }
2019
2020 =head2 $class->prepare( @arguments )
2021
2022 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2023 etc.).
2024
2025 =cut
2026
2027 has _uploadtmp => (
2028     is => 'ro',
2029     predicate => '_has_uploadtmp',
2030 );
2031
2032 sub prepare {
2033     my ( $class, @arguments ) = @_;
2034
2035     # XXX
2036     # After the app/ctxt split, this should become an attribute based on something passed
2037     # into the application.
2038     $class->context_class( ref $class || $class ) unless $class->context_class;
2039
2040     my $uploadtmp = $class->config->{uploadtmp};
2041     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2042
2043     $c->response->_context($c);
2044
2045     #surely this is not the most efficient way to do things...
2046     $c->stats($class->stats_class->new)->enable($c->use_stats);
2047     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2048         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2049     }
2050
2051     try {
2052         # Allow engine to direct the prepare flow (for POE)
2053         if ( my $prepare = $c->engine->can('prepare') ) {
2054             $c->engine->$prepare( $c, @arguments );
2055         }
2056         else {
2057             $c->prepare_request(@arguments);
2058             $c->prepare_connection;
2059             $c->prepare_query_parameters;
2060             $c->prepare_headers; # Just hooks, no longer needed - they just
2061             $c->prepare_cookies; # cause the lazy attribute on req to build
2062             $c->prepare_path;
2063
2064             # Prepare the body for reading, either by prepare_body
2065             # or the user, if they are using $c->read
2066             $c->prepare_read;
2067
2068             # Parse the body unless the user wants it on-demand
2069             unless ( ref($c)->config->{parse_on_demand} ) {
2070                 $c->prepare_body;
2071             }
2072         }
2073         $c->prepare_action;
2074     }
2075     # VERY ugly and probably shouldn't rely on ->finalize actually working
2076     catch {
2077         # failed prepare is always due to an invalid request, right?
2078         $c->response->status(400);
2079         $c->response->content_type('text/plain');
2080         $c->response->body('Bad Request');
2081         # Note we call finalize and then die here, which escapes
2082         # finalize being called in the enclosing block..
2083         # It in fact couldn't be called, as we don't return $c..
2084         # This is a mess - but I'm unsure you can fix this without
2085         # breaking compat for people doing crazy things (we should set
2086         # the 400 and just return the ctx here IMO, letting finalize get called
2087         # above...
2088         $c->finalize;
2089         die $_;
2090     };
2091
2092     $c->log_request;
2093
2094     return $c;
2095 }
2096
2097 =head2 $c->prepare_action
2098
2099 Prepares action. See L<Catalyst::Dispatcher>.
2100
2101 =cut
2102
2103 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2104
2105 =head2 $c->prepare_body
2106
2107 Prepares message body.
2108
2109 =cut
2110
2111 sub prepare_body {
2112     my $c = shift;
2113
2114     return if $c->request->_has_body;
2115
2116     # Initialize on-demand data
2117     $c->engine->prepare_body( $c, @_ );
2118     $c->prepare_parameters;
2119     $c->prepare_uploads;
2120 }
2121
2122 =head2 $c->prepare_body_chunk( $chunk )
2123
2124 Prepares a chunk of data before sending it to L<HTTP::Body>.
2125
2126 See L<Catalyst::Engine>.
2127
2128 =cut
2129
2130 sub prepare_body_chunk {
2131     my $c = shift;
2132     $c->engine->prepare_body_chunk( $c, @_ );
2133 }
2134
2135 =head2 $c->prepare_body_parameters
2136
2137 Prepares body parameters.
2138
2139 =cut
2140
2141 sub prepare_body_parameters {
2142     my $c = shift;
2143     $c->engine->prepare_body_parameters( $c, @_ );
2144 }
2145
2146 =head2 $c->prepare_connection
2147
2148 Prepares connection.
2149
2150 =cut
2151
2152 sub prepare_connection {
2153     my $c = shift;
2154     # XXX - This is called on the engine (not the request) to maintain
2155     #       Engine::PSGI back compat.
2156     $c->engine->prepare_connection($c);
2157 }
2158
2159 =head2 $c->prepare_cookies
2160
2161 Prepares cookies by ensuring that the attribute on the request
2162 object has been built.
2163
2164 =cut
2165
2166 sub prepare_cookies { my $c = shift; $c->request->cookies }
2167
2168 =head2 $c->prepare_headers
2169
2170 Prepares request headers by ensuring that the attribute on the request
2171 object has been built.
2172
2173 =cut
2174
2175 sub prepare_headers { my $c = shift; $c->request->headers }
2176
2177 =head2 $c->prepare_parameters
2178
2179 Prepares parameters.
2180
2181 =cut
2182
2183 sub prepare_parameters {
2184     my $c = shift;
2185     $c->prepare_body_parameters;
2186     $c->engine->prepare_parameters( $c, @_ );
2187 }
2188
2189 =head2 $c->prepare_path
2190
2191 Prepares path and base.
2192
2193 =cut
2194
2195 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2196
2197 =head2 $c->prepare_query_parameters
2198
2199 Prepares query parameters.
2200
2201 =cut
2202
2203 sub prepare_query_parameters {
2204     my $c = shift;
2205
2206     $c->engine->prepare_query_parameters( $c, @_ );
2207 }
2208
2209 =head2 $c->log_request
2210
2211 Writes information about the request to the debug logs.  This includes:
2212
2213 =over 4
2214
2215 =item * Request method, path, and remote IP address
2216
2217 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2218
2219 =item * Request parameters
2220
2221 =item * File uploads
2222
2223 =back
2224
2225 =cut
2226
2227 sub log_request {
2228     my $c = shift;
2229
2230     return unless $c->debug;
2231
2232     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2233     my $request = $dump->[1];
2234
2235     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2236     $method ||= '';
2237     $path = '/' unless length $path;
2238     $address ||= '';
2239     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2240
2241     $c->log_request_headers($request->headers);
2242
2243     if ( my $keywords = $request->query_keywords ) {
2244         $c->log->debug("Query keywords are: $keywords");
2245     }
2246
2247     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2248
2249     $c->log_request_uploads($request);
2250 }
2251
2252 =head2 $c->log_response
2253
2254 Writes information about the response to the debug logs by calling
2255 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2256
2257 =cut
2258
2259 sub log_response {
2260     my $c = shift;
2261
2262     return unless $c->debug;
2263
2264     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2265     my $response = $dump->[1];
2266
2267     $c->log_response_status_line($response);
2268     $c->log_response_headers($response->headers);
2269 }
2270
2271 =head2 $c->log_response_status_line($response)
2272
2273 Writes one line of information about the response to the debug logs.  This includes:
2274
2275 =over 4
2276
2277 =item * Response status code
2278
2279 =item * Content-Type header (if present)
2280
2281 =item * Content-Length header (if present)
2282
2283 =back
2284
2285 =cut
2286
2287 sub log_response_status_line {
2288     my ($c, $response) = @_;
2289
2290     $c->log->debug(
2291         sprintf(
2292             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2293             $response->status                            || 'unknown',
2294             $response->headers->header('Content-Type')   || 'unknown',
2295             $response->headers->header('Content-Length') || 'unknown'
2296         )
2297     );
2298 }
2299
2300 =head2 $c->log_response_headers($headers);
2301
2302 Hook method which can be wrapped by plugins to log the response headers.
2303 No-op in the default implementation.
2304
2305 =cut
2306
2307 sub log_response_headers {}
2308
2309 =head2 $c->log_request_parameters( query => {}, body => {} )
2310
2311 Logs request parameters to debug logs
2312
2313 =cut
2314
2315 sub log_request_parameters {
2316     my $c          = shift;
2317     my %all_params = @_;
2318
2319     return unless $c->debug;
2320
2321     my $column_width = Catalyst::Utils::term_width() - 44;
2322     foreach my $type (qw(query body)) {
2323         my $params = $all_params{$type};
2324         next if ! keys %$params;
2325         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2326         for my $key ( sort keys %$params ) {
2327             my $param = $params->{$key};
2328             my $value = defined($param) ? $param : '';
2329             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2330         }
2331         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2332     }
2333 }
2334
2335 =head2 $c->log_request_uploads
2336
2337 Logs file uploads included in the request to the debug logs.
2338 The parameter name, filename, file type, and file size are all included in
2339 the debug logs.
2340
2341 =cut
2342
2343 sub log_request_uploads {
2344     my $c = shift;
2345     my $request = shift;
2346     return unless $c->debug;
2347     my $uploads = $request->uploads;
2348     if ( keys %$uploads ) {
2349         my $t = Text::SimpleTable->new(
2350             [ 12, 'Parameter' ],
2351             [ 26, 'Filename' ],
2352             [ 18, 'Type' ],
2353             [ 9,  'Size' ]
2354         );
2355         for my $key ( sort keys %$uploads ) {
2356             my $upload = $uploads->{$key};
2357             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2358                 $t->row( $key, $u->filename, $u->type, $u->size );
2359             }
2360         }
2361         $c->log->debug( "File Uploads are:\n" . $t->draw );
2362     }
2363 }
2364
2365 =head2 $c->log_request_headers($headers);
2366
2367 Hook method which can be wrapped by plugins to log the request headers.
2368 No-op in the default implementation.
2369
2370 =cut
2371
2372 sub log_request_headers {}
2373
2374 =head2 $c->log_headers($type => $headers)
2375
2376 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2377
2378 =cut
2379
2380 sub log_headers {
2381     my $c       = shift;
2382     my $type    = shift;
2383     my $headers = shift;    # an HTTP::Headers instance
2384
2385     return unless $c->debug;
2386
2387     my $column_width = Catalyst::Utils::term_width() - 28;
2388     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2389     $headers->scan(
2390         sub {
2391             my ( $name, $value ) = @_;
2392             $t->row( $name, $value );
2393         }
2394     );
2395     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2396 }
2397
2398
2399 =head2 $c->prepare_read
2400
2401 Prepares the input for reading.
2402
2403 =cut
2404
2405 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2406
2407 =head2 $c->prepare_request
2408
2409 Prepares the engine request.
2410
2411 =cut
2412
2413 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2414
2415 =head2 $c->prepare_uploads
2416
2417 Prepares uploads.
2418
2419 =cut
2420
2421 sub prepare_uploads {
2422     my $c = shift;
2423
2424     $c->engine->prepare_uploads( $c, @_ );
2425 }
2426
2427 =head2 $c->prepare_write
2428
2429 Prepares the output for writing.
2430
2431 =cut
2432
2433 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2434
2435 =head2 $c->request_class
2436
2437 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2438
2439 =head2 $c->response_class
2440
2441 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2442
2443 =head2 $c->read( [$maxlength] )
2444
2445 Reads a chunk of data from the request body. This method is designed to
2446 be used in a while loop, reading C<$maxlength> bytes on every call.
2447 C<$maxlength> defaults to the size of the request if not specified.
2448
2449 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2450 directly.
2451
2452 Warning: If you use read(), Catalyst will not process the body,
2453 so you will not be able to access POST parameters or file uploads via
2454 $c->request.  You must handle all body parsing yourself.
2455
2456 =cut
2457
2458 sub read { my $c = shift; return $c->request->read( @_ ) }
2459
2460 =head2 $c->run
2461
2462 Starts the engine.
2463
2464 =cut
2465
2466 sub run {
2467   my $app = shift;
2468   $app->_make_immutable_if_needed;
2469   $app->engine_loader->needs_psgi_engine_compat_hack ?
2470     $app->engine->run($app, @_) :
2471       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2472 }
2473
2474 sub _make_immutable_if_needed {
2475     my $class = shift;
2476     my $meta = Class::MOP::get_metaclass_by_name($class);
2477     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2478     if (
2479         $meta->is_immutable
2480         && ! { $meta->immutable_options }->{replace_constructor}
2481         && $isa_ca
2482     ) {
2483         warn("You made your application class ($class) immutable, "
2484             . "but did not inline the\nconstructor. "
2485             . "This will break catalyst, as your app \@ISA "
2486             . "Class::Accessor(::Fast)?\nPlease pass "
2487             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2488     }
2489     unless ($meta->is_immutable) {
2490         # XXX - FIXME warning here as you should make your app immutable yourself.
2491         $meta->make_immutable(
2492             replace_constructor => 1,
2493         );
2494     }
2495 }
2496
2497 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2498
2499 Sets an action in a given namespace.
2500
2501 =cut
2502
2503 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2504
2505 =head2 $c->setup_actions($component)
2506
2507 Sets up actions for a component.
2508
2509 =cut
2510
2511 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2512
2513 =head2 $c->setup_components
2514
2515 This method is called internally to set up the application's components.
2516
2517 It finds modules by calling the L<locate_components> method, expands them to
2518 package names with the L<expand_component_module> method, and then installs
2519 each component into the application.
2520
2521 The C<setup_components> config option is passed to both of the above methods.
2522
2523 Installation of each component is performed by the L<setup_component> method,
2524 below.
2525
2526 =cut
2527
2528 sub setup_components {
2529     my $class = shift;
2530
2531     my $config  = $class->config->{ setup_components };
2532
2533     my @comps = $class->locate_components($config);
2534     my %comps = map { $_ => 1 } @comps;
2535
2536     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2537     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2538         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2539     ) if $deprecatedcatalyst_component_names;
2540
2541     for my $component ( @comps ) {
2542
2543         # We pass ignore_loaded here so that overlay files for (e.g.)
2544         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2545         # we know M::P::O found a file on disk so this is safe
2546
2547         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2548     }
2549
2550     for my $component (@comps) {
2551         my $instance = $class->components->{ $component } = $class->setup_component($component);
2552         my @expanded_components = $instance->can('expand_modules')
2553             ? $instance->expand_modules( $component, $config )
2554             : $class->expand_component_module( $component, $config );
2555         for my $component (@expanded_components) {
2556             next if $comps{$component};
2557             $class->components->{ $component } = $class->setup_component($component);
2558         }
2559     }
2560 }
2561
2562 =head2 $c->locate_components( $setup_component_config )
2563
2564 This method is meant to provide a list of component modules that should be
2565 setup for the application.  By default, it will use L<Module::Pluggable>.
2566
2567 Specify a C<setup_components> config option to pass additional options directly
2568 to L<Module::Pluggable>. To add additional search paths, specify a key named
2569 C<search_extra> as an array reference. Items in the array beginning with C<::>
2570 will have the application class name prepended to them.
2571
2572 =cut
2573
2574 sub locate_components {
2575     my $class  = shift;
2576     my $config = shift;
2577
2578     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2579     my $extra   = delete $config->{ search_extra } || [];
2580
2581     push @paths, @$extra;
2582
2583     my $locator = Module::Pluggable::Object->new(
2584         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2585         %$config
2586     );
2587
2588     # XXX think about ditching this sort entirely
2589     my @comps = sort { length $a <=> length $b } $locator->plugins;
2590
2591     return @comps;
2592 }
2593
2594 =head2 $c->expand_component_module( $component, $setup_component_config )
2595
2596 Components found by C<locate_components> will be passed to this method, which
2597 is expected to return a list of component (package) names to be set up.
2598
2599 =cut
2600
2601 sub expand_component_module {
2602     my ($class, $module) = @_;
2603     return Devel::InnerPackage::list_packages( $module );
2604 }
2605
2606 =head2 $c->setup_component
2607
2608 =cut
2609
2610 sub setup_component {
2611     my( $class, $component ) = @_;
2612
2613     unless ( $component->can( 'COMPONENT' ) ) {
2614         return $component;
2615     }
2616
2617     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2618     my $config = $class->config->{ $suffix } || {};
2619     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2620     # methods also pass it. local to avoid pointlessly shitting in config
2621     # for the debug screen, as $component is already the key name.
2622     local $config->{catalyst_component_name} = $component;
2623
2624     my $instance = eval { $component->COMPONENT( $class, $config ); };
2625
2626     if ( my $error = $@ ) {
2627         chomp $error;
2628         Catalyst::Exception->throw(
2629             message => qq/Couldn't instantiate component "$component", "$error"/
2630         );
2631     }
2632
2633     unless (blessed $instance) {
2634         my $metaclass = Moose::Util::find_meta($component);
2635         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2636         my $component_method_from = $method_meta->associated_metaclass->name;
2637         my $value = defined($instance) ? $instance : 'undef';
2638         Catalyst::Exception->throw(
2639             message =>
2640             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2641         );
2642     }
2643     return $instance;
2644 }
2645
2646 =head2 $c->setup_dispatcher
2647
2648 Sets up dispatcher.
2649
2650 =cut
2651
2652 sub setup_dispatcher {
2653     my ( $class, $dispatcher ) = @_;
2654
2655     if ($dispatcher) {
2656         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2657     }
2658
2659     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2660         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2661     }
2662
2663     unless ($dispatcher) {
2664         $dispatcher = $class->dispatcher_class;
2665     }
2666
2667     load_class($dispatcher);
2668
2669     # dispatcher instance
2670     $class->dispatcher( $dispatcher->new );
2671 }
2672
2673 =head2 $c->setup_engine
2674
2675 Sets up engine.
2676
2677 =cut
2678
2679 sub engine_class {
2680     my ($class, $requested_engine) = @_;
2681
2682     if (!$class->engine_loader || $requested_engine) {
2683         $class->engine_loader(
2684             Catalyst::EngineLoader->new({
2685                 application_name => $class,
2686                 (defined $requested_engine
2687                      ? (catalyst_engine_class => $requested_engine) : ()),
2688             }),
2689         );
2690     }
2691
2692     $class->engine_loader->catalyst_engine_class;
2693 }
2694
2695 sub setup_engine {
2696     my ($class, $requested_engine) = @_;
2697
2698     my $engine = do {
2699         my $loader = $class->engine_loader;
2700
2701         if (!$loader || $requested_engine) {
2702             $loader = Catalyst::EngineLoader->new({
2703                 application_name => $class,
2704                 (defined $requested_engine
2705                      ? (requested_engine => $requested_engine) : ()),
2706             }),
2707
2708             $class->engine_loader($loader);
2709         }
2710
2711         $loader->catalyst_engine_class;
2712     };
2713
2714     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2715     return if $class->loading_psgi_file;
2716
2717     load_class($engine);
2718
2719     if ($ENV{MOD_PERL}) {
2720         my $apache = $class->engine_loader->auto;
2721
2722         my $meta = find_meta($class);
2723         my $was_immutable = $meta->is_immutable;
2724         my %immutable_options = $meta->immutable_options;
2725         $meta->make_mutable if $was_immutable;
2726
2727         $meta->add_method(handler => sub {
2728             my $r = shift;
2729             my $psgi_app = $class->_finalized_psgi_app;
2730             $apache->call_app($r, $psgi_app);
2731         });
2732
2733         $meta->make_immutable(%immutable_options) if $was_immutable;
2734     }
2735
2736     $class->engine( $engine->new );
2737
2738     return;
2739 }
2740
2741 sub _finalized_psgi_app {
2742     my ($app) = @_;
2743
2744     unless ($app->_psgi_app) {
2745         my $psgi_app = $app->_setup_psgi_app;
2746         $app->_psgi_app($psgi_app);
2747     }
2748
2749     return $app->_psgi_app;
2750 }
2751
2752 sub _setup_psgi_app {
2753     my ($app) = @_;
2754
2755     for my $home (Path::Class::Dir->new($app->config->{home})) {
2756         my $psgi_file = $home->file(
2757             Catalyst::Utils::appprefix($app) . '.psgi',
2758         );
2759
2760         next unless -e $psgi_file;
2761
2762         # If $psgi_file calls ->setup_engine, it's doing so to load
2763         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2764         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2765         # anyway. So set a flag (ick) that tells setup_engine not to populate
2766         # $c->engine or do any other things we might regret.
2767
2768         $app->loading_psgi_file(1);
2769         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2770         $app->loading_psgi_file(0);
2771
2772         return $psgi_app
2773             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2774
2775         warn <<"EOW";
2776 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2777
2778 Its content has been ignored. Please consult the Catalyst::Upgrading
2779 documentation on how to upgrade from Catalyst::Engine::PSGI.
2780 EOW
2781     }
2782
2783     return $app->apply_default_middlewares($app->psgi_app);
2784 }
2785
2786 =head2 $c->apply_default_middlewares
2787
2788 Adds the following L<Plack> middlewares to your application, since they are
2789 useful and commonly needed:
2790
2791 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2792 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2793 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2794 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2795 applied since this middleware is smart enough to conditionally apply itself).
2796
2797 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2798 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2799 $ENV{SCRIPT_NAME}
2800
2801 =cut
2802
2803
2804 sub apply_default_middlewares {
2805     my ($app, $psgi_app) = @_;
2806
2807     $psgi_app = Plack::Middleware::Conditional->wrap(
2808         $psgi_app,
2809         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2810         condition => sub {
2811             my ($env) = @_;
2812             return if $app->config->{ignore_frontend_proxy};
2813             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2814                 || $app->config->{using_frontend_proxy};
2815         },
2816     );
2817
2818     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2819     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2820     $psgi_app = Plack::Middleware::Conditional->wrap(
2821         $psgi_app,
2822         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2823         condition => sub {
2824             my ($env) = @_;
2825             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2826             return unless $1 < 4.23;
2827             1;
2828         },
2829     );
2830
2831     # we're applying this unconditionally as the middleware itself already makes
2832     # sure it doesn't fuck things up if it's not running under one of the right
2833     # IIS versions
2834     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2835
2836     # And another IIS issue, this time with IIS7.
2837     $psgi_app = Plack::Middleware::Conditional->wrap(
2838         $psgi_app,
2839         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2840         condition => sub {
2841             my ($env) = @_;
2842             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2843         },
2844     );
2845
2846     return $psgi_app;
2847 }
2848
2849 =head2 $c->psgi_app
2850
2851 Returns a PSGI application code reference for the catalyst application
2852 C<$c>. This is the bare application without any middlewares
2853 applied. C<${myapp}.psgi> is not taken into account.
2854
2855 This is what you want to be using to retrieve the PSGI application code
2856 reference of your Catalyst application for use in F<.psgi> files.
2857
2858 =cut
2859
2860 sub psgi_app {
2861     my ($app) = @_;
2862     return $app->engine->build_psgi_app($app);
2863 }
2864
2865 =head2 $c->setup_home
2866
2867 Sets up the home directory.
2868
2869 =cut
2870
2871 sub setup_home {
2872     my ( $class, $home ) = @_;
2873
2874     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2875         $home = $env;
2876     }
2877
2878     $home ||= Catalyst::Utils::home($class);
2879
2880     if ($home) {
2881         #I remember recently being scolded for assigning config values like this
2882         $class->config->{home} ||= $home;
2883         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2884     }
2885 }
2886
2887 =head2 $c->setup_log
2888
2889 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2890 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2891 log to.
2892
2893 This method also installs a C<debug> method that returns a true value into the
2894 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2895 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2896
2897 Note that if the log has already been setup, by either a previous call to
2898 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2899 that this method won't actually set up the log object.
2900
2901 =cut
2902
2903 sub setup_log {
2904     my ( $class, $levels ) = @_;
2905
2906     $levels ||= '';
2907     $levels =~ s/^\s+//;
2908     $levels =~ s/\s+$//;
2909     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2910
2911     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2912     if ( defined $env_debug ) {
2913         $levels{debug} = 1 if $env_debug; # Ugly!
2914         delete($levels{debug}) unless $env_debug;
2915     }
2916
2917     unless ( $class->log ) {
2918         $class->log( Catalyst::Log->new(keys %levels) );
2919     }
2920
2921     if ( $levels{debug} ) {
2922         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2923         $class->log->debug('Debug messages enabled');
2924     }
2925 }
2926
2927 =head2 $c->setup_plugins
2928
2929 Sets up plugins.
2930
2931 =cut
2932
2933 =head2 $c->setup_stats
2934
2935 Sets up timing statistics class.
2936
2937 =cut
2938
2939 sub setup_stats {
2940     my ( $class, $stats ) = @_;
2941
2942     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2943
2944     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2945     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2946         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2947         $class->log->debug('Statistics enabled');
2948     }
2949 }
2950
2951
2952 =head2 $c->registered_plugins
2953
2954 Returns a sorted list of the plugins which have either been stated in the
2955 import list.
2956
2957 If passed a given plugin name, it will report a boolean value indicating
2958 whether or not that plugin is loaded.  A fully qualified name is required if
2959 the plugin name does not begin with C<Catalyst::Plugin::>.
2960
2961  if ($c->registered_plugins('Some::Plugin')) {
2962      ...
2963  }
2964
2965 =cut
2966
2967 {
2968
2969     sub registered_plugins {
2970         my $proto = shift;
2971         return sort keys %{ $proto->_plugins } unless @_;
2972         my $plugin = shift;
2973         return 1 if exists $proto->_plugins->{$plugin};
2974         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2975     }
2976
2977     sub _register_plugin {
2978         my ( $proto, $plugin, $instant ) = @_;
2979         my $class = ref $proto || $proto;
2980
2981         load_class( $plugin );
2982         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2983             if $plugin->isa( 'Catalyst::Component' );
2984         my $plugin_meta = Moose::Meta::Class->create($plugin);
2985         if (!$plugin_meta->has_method('new')
2986             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
2987             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
2988         }
2989         if (!$instant && !$proto->_plugins->{$plugin}) {
2990             my $meta = Class::MOP::get_metaclass_by_name($class);
2991             $meta->superclasses($plugin, $meta->superclasses);
2992         }
2993         $proto->_plugins->{$plugin} = 1;
2994         return $class;
2995     }
2996
2997     sub _default_plugins { return qw(Unicode::Encoding) }
2998
2999     sub setup_plugins {
3000         my ( $class, $plugins ) = @_;
3001
3002         $class->_plugins( {} ) unless $class->_plugins;
3003         $plugins = [ grep {
3004             m/Unicode::Encoding/ ? do {
3005                 $class->log->warn(
3006                     'Unicode::Encoding plugin is auto-applied,'
3007                     . ' please remove this from your appclass'
3008                     . ' and make sure to define "encoding" config'
3009                 );
3010                 unless (exists $class->config->{'encoding'}) {
3011                   $class->config->{'encoding'} = 'UTF-8';
3012                 }
3013                 () }
3014                 : $_
3015         } @$plugins ];
3016         push @$plugins, $class->_default_plugins;
3017         $plugins = Data::OptList::mkopt($plugins || []);
3018
3019         my @plugins = map {
3020             [ Catalyst::Utils::resolve_namespace(
3021                   $class . '::Plugin',
3022                   'Catalyst::Plugin', $_->[0]
3023               ),
3024               $_->[1],
3025             ]
3026          } @{ $plugins };
3027
3028         for my $plugin ( reverse @plugins ) {
3029             load_class($plugin->[0], $plugin->[1]);
3030             my $meta = find_meta($plugin->[0]);
3031             next if $meta && $meta->isa('Moose::Meta::Role');
3032
3033             $class->_register_plugin($plugin->[0]);
3034         }
3035
3036         my @roles =
3037             map  { $_->[0]->name, $_->[1] }
3038             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3039             map  { [find_meta($_->[0]), $_->[1]] }
3040             @plugins;
3041
3042         Moose::Util::apply_all_roles(
3043             $class => @roles
3044         ) if @roles;
3045     }
3046 }
3047
3048 =head2 $c->stack
3049
3050 Returns an arrayref of the internal execution stack (actions that are
3051 currently executing).
3052
3053 =head2 $c->stats
3054
3055 Returns the current timing statistics object. By default Catalyst uses
3056 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3057 L<< stats_class|/"$c->stats_class" >>.
3058
3059 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3060 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3061 profile explicitly, although MyApp.pm still won't profile nor output anything
3062 by itself.
3063
3064 =head2 $c->stats_class
3065
3066 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3067
3068 =head2 $c->use_stats
3069
3070 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3071
3072 Note that this is a static method, not an accessor and should be overridden
3073 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3074
3075 =cut
3076
3077 sub use_stats { 0 }
3078
3079
3080 =head2 $c->write( $data )
3081
3082 Writes $data to the output stream. When using this method directly, you
3083 will need to manually set the C<Content-Length> header to the length of
3084 your output data, if known.
3085
3086 =cut
3087
3088 sub write {
3089     my $c = shift;
3090
3091     # Finalize headers if someone manually writes output (for compat)
3092     $c->finalize_headers;
3093
3094     return $c->response->write( @_ );
3095 }
3096
3097 =head2 version
3098
3099 Returns the Catalyst version number. Mostly useful for "powered by"
3100 messages in template systems.
3101
3102 =cut
3103
3104 sub version { return $Catalyst::VERSION }
3105
3106 =head1 CONFIGURATION
3107
3108 There are a number of 'base' config variables which can be set:
3109
3110 =over
3111
3112 =item *
3113
3114 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3115
3116 =item *
3117
3118 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3119
3120 =item *
3121
3122 C<disable_component_resolution_regex_fallback> - Turns
3123 off the deprecated component resolution functionality so
3124 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3125 are called then regex search will not be attempted on string values and
3126 instead C<undef> will be returned.
3127
3128 =item *
3129
3130 C<home> - The application home directory. In an uninstalled application,
3131 this is the top level application directory. In an installed application,
3132 this will be the directory containing C<< MyApp.pm >>.
3133
3134 =item *
3135
3136 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3137
3138 =item *
3139
3140 C<name> - The name of the application in debug messages and the debug and
3141 welcome screens
3142
3143 =item *
3144
3145 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3146 until it is accessed. This allows you to (for example) check authentication (and reject
3147 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3148
3149 =item *
3150
3151 C<root> - The root directory for templates. Usually this is just a
3152 subdirectory of the home directory, but you can set it to change the
3153 templates to a different directory.
3154
3155 =item *
3156
3157 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3158 namespaces from which components will be loaded (and constructed and stored in
3159 C<< $c->components >>).
3160
3161 =item *
3162
3163 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3164 to be shown in hit debug tables in the test server.
3165
3166 =item *
3167
3168 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3169 variable should be used for determining the request path.
3170
3171 Most web server environments pass the requested path to the application using environment variables,
3172 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3173 exposed as C<< $c->request->base >>) and the request path below that base.
3174
3175 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3176 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3177
3178 =over
3179
3180 =item use_request_uri_for_path => 0
3181
3182 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3183 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3184 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3185 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3186
3187 However this method has the major disadvantage that it is impossible to correctly decode some elements
3188 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3189 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3190 can't distinguish / vs %2F in paths (in addition to other encoded values).
3191
3192 =item use_request_uri_for_path => 1
3193
3194 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3195 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3196 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3197
3198 Given that this method of path resolution is provably more correct, it is recommended that you use
3199 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3200 aware of the implications of not being able to handle encoded URI paths correctly.
3201
3202 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3203 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3204 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3205 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3206 C<< $c->request->base >> will be incorrect.
3207
3208 =back
3209
3210 =item *
3211
3212 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3213
3214 =item *
3215
3216 C<encoding> - See L</ENCODING>
3217
3218 =item *
3219
3220 C<abort_chain_on_error_fix>
3221
3222 When there is an error in an action chain, the default behavior is to continue
3223 processing the remaining actions and then catch the error upon chain end.  This
3224 can lead to running actions when the application is in an unexpected state.  If
3225 you have this issue, setting this config value to true will promptly exit a
3226 chain when there is an error raised in any action (thus terminating the chain
3227 early.)
3228
3229 use like:
3230
3231     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3232
3233 In the future this might become the default behavior.
3234
3235 =back
3236
3237 =head1 INTERNAL ACTIONS
3238
3239 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3240 C<_ACTION>, and C<_END>. These are by default not shown in the private
3241 action table, but you can make them visible with a config parameter.
3242
3243     MyApp->config(show_internal_actions => 1);
3244
3245 =head1 ON-DEMAND PARSER
3246
3247 The request body is usually parsed at the beginning of a request,
3248 but if you want to handle input yourself, you can enable on-demand
3249 parsing with a config parameter.
3250
3251     MyApp->config(parse_on_demand => 1);
3252
3253 =head1 PROXY SUPPORT
3254
3255 Many production servers operate using the common double-server approach,
3256 with a lightweight frontend web server passing requests to a larger
3257 backend server. An application running on the backend server must deal
3258 with two problems: the remote user always appears to be C<127.0.0.1> and
3259 the server's hostname will appear to be C<localhost> regardless of the
3260 virtual host that the user connected through.
3261
3262 Catalyst will automatically detect this situation when you are running
3263 the frontend and backend servers on the same machine. The following
3264 changes are made to the request.
3265
3266     $c->req->address is set to the user's real IP address, as read from
3267     the HTTP X-Forwarded-For header.
3268
3269     The host value for $c->req->base and $c->req->uri is set to the real
3270     host, as read from the HTTP X-Forwarded-Host header.
3271
3272 Additionally, you may be running your backend application on an insecure
3273 connection (port 80) while your frontend proxy is running under SSL.  If there
3274 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3275 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3276 be created properly.
3277
3278 In the case of passing in:
3279
3280     X-Forwarded-Port: 443
3281
3282 All calls to C<uri_for> will result in an https link, as is expected.
3283
3284 Obviously, your web server must support these headers for this to work.
3285
3286 In a more complex server farm environment where you may have your
3287 frontend proxy server(s) on different machines, you will need to set a
3288 configuration option to tell Catalyst to read the proxied data from the
3289 headers.
3290
3291     MyApp->config(using_frontend_proxy => 1);
3292
3293 If you do not wish to use the proxy support at all, you may set:
3294
3295     MyApp->config(ignore_frontend_proxy => 0);
3296
3297 =head2 Note about psgi files
3298
3299 Note that if you supply your own .psgi file, calling
3300 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3301
3302 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3303 in your psgi, for example:
3304
3305     builder {
3306         enable "Plack::Middleware::ReverseProxy";
3307         MyApp->psgi_app
3308     };
3309
3310 This will unconditionally add the ReverseProxy support, or you need to call
3311 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3312 apply the support depending upon your config).
3313
3314 See L<Catalyst::PSGI> for more information.
3315
3316 =head1 THREAD SAFETY
3317
3318 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3319 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3320 believe the Catalyst core to be thread-safe.
3321
3322 If you plan to operate in a threaded environment, remember that all other
3323 modules you are using must also be thread-safe. Some modules, most notably
3324 L<DBD::SQLite>, are not thread-safe.
3325
3326 =head1 ENCODING
3327
3328 On request, decodes all params from encoding into a sequence of
3329 logical characters. On response, encodes body into encoding.
3330
3331 =head2 Methods
3332
3333 =over 4
3334
3335 =item encoding
3336
3337 Returns an instance of an C<Encode> encoding
3338
3339     print $c->encoding->name
3340
3341 =item handle_unicode_encoding_exception ($exception_context)
3342
3343 Method called when decoding process for a request fails.
3344
3345 An C<$exception_context> hashref is provided to allow you to override the
3346 behaviour of your application when given data with incorrect encodings.
3347
3348 The default method throws exceptions in the case of invalid request parameters
3349 (resulting in a 500 error), but ignores errors in upload filenames.
3350
3351 The keys passed in the C<$exception_context> hash are:
3352
3353 =over
3354
3355 =item param_value
3356
3357 The value which was not able to be decoded.
3358
3359 =item error_msg
3360
3361 The exception received from L<Encode>.
3362
3363 =item encoding_step
3364
3365 What type of data was being decoded. Valid values are (currently)
3366 C<params> - for request parameters / arguments / captures
3367 and C<uploads> - for request upload filenames.
3368
3369 =back
3370
3371 =back
3372
3373 =head1 SUPPORT
3374
3375 IRC:
3376
3377     Join #catalyst on irc.perl.org.
3378
3379 Mailing Lists:
3380
3381     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3382     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3383
3384 Web:
3385
3386     http://catalyst.perl.org
3387
3388 Wiki:
3389
3390     http://dev.catalyst.perl.org
3391
3392 =head1 SEE ALSO
3393
3394 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3395
3396 =head2 L<Catalyst::Manual> - The Catalyst Manual
3397
3398 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3399
3400 =head2 L<Catalyst::Engine> - Core engine
3401
3402 =head2 L<Catalyst::Log> - Log class.
3403
3404 =head2 L<Catalyst::Request> - Request object
3405
3406 =head2 L<Catalyst::Response> - Response object
3407
3408 =head2 L<Catalyst::Test> - The test suite.
3409
3410 =head1 PROJECT FOUNDER
3411
3412 sri: Sebastian Riedel <sri@cpan.org>
3413
3414 =head1 CONTRIBUTORS
3415
3416 abw: Andy Wardley
3417
3418 acme: Leon Brocard <leon@astray.com>
3419
3420 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3421
3422 Andrew Bramble
3423
3424 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3425
3426 Andrew Ruthven
3427
3428 andyg: Andy Grundman <andy@hybridized.org>
3429
3430 audreyt: Audrey Tang
3431
3432 bricas: Brian Cassidy <bricas@cpan.org>
3433
3434 Caelum: Rafael Kitover <rkitover@io.com>
3435
3436 chansen: Christian Hansen
3437
3438 chicks: Christopher Hicks
3439
3440 Chisel Wright C<pause@herlpacker.co.uk>
3441
3442 Danijel Milicevic C<me@danijel.de>
3443
3444 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3445
3446 David Naughton, C<naughton@umn.edu>
3447
3448 David E. Wheeler
3449
3450 dhoss: Devin Austin <dhoss@cpan.org>
3451
3452 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3453
3454 Drew Taylor
3455
3456 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3457
3458 esskar: Sascha Kiefer
3459
3460 fireartist: Carl Franks <cfranks@cpan.org>
3461
3462 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3463
3464 gabb: Danijel Milicevic
3465
3466 Gary Ashton Jones
3467
3468 Gavin Henry C<ghenry@perl.me.uk>
3469
3470 Geoff Richards
3471
3472 groditi: Guillermo Roditi <groditi@gmail.com>
3473
3474 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3475
3476 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3477
3478 jcamacho: Juan Camacho
3479
3480 jester: Jesse Sheidlower C<jester@panix.com>
3481
3482 jhannah: Jay Hannah <jay@jays.net>
3483
3484 Jody Belka
3485
3486 Johan Lindstrom
3487
3488 jon: Jon Schutz <jjschutz@cpan.org>
3489
3490 Jonathan Rockway C<< <jrockway@cpan.org> >>
3491
3492 Kieren Diment C<kd@totaldatasolution.com>
3493
3494 konobi: Scott McWhirter <konobi@cpan.org>
3495
3496 marcus: Marcus Ramberg <mramberg@cpan.org>
3497
3498 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3499
3500 mgrimes: Mark Grimes <mgrimes@cpan.org>
3501
3502 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3503
3504 mugwump: Sam Vilain
3505
3506 naughton: David Naughton
3507
3508 ningu: David Kamholz <dkamholz@cpan.org>
3509
3510 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3511
3512 numa: Dan Sully <daniel@cpan.org>
3513
3514 obra: Jesse Vincent
3515
3516 Octavian Rasnita
3517
3518 omega: Andreas Marienborg
3519
3520 Oleg Kostyuk <cub.uanic@gmail.com>
3521
3522 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3523
3524 rafl: Florian Ragwitz <rafl@debian.org>
3525
3526 random: Roland Lammel <lammel@cpan.org>
3527
3528 Robert Sedlacek C<< <rs@474.at> >>
3529
3530 SpiceMan: Marcel Montes
3531
3532 sky: Arthur Bergman
3533
3534 szbalint: Balint Szilakszi <szbalint@cpan.org>
3535
3536 t0m: Tomas Doran <bobtfish@bobtfish.net>
3537
3538 Ulf Edvinsson
3539
3540 Viljo Marrandi C<vilts@yahoo.com>
3541
3542 Will Hawes C<info@whawes.co.uk>
3543
3544 willert: Sebastian Willert <willert@cpan.org>
3545
3546 wreis: Wallace Reis <wreis@cpan.org>
3547
3548 Yuval Kogman, C<nothingmuch@woobling.org>
3549
3550 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3551
3552 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3553
3554 =head1 COPYRIGHT
3555
3556 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3557
3558 =head1 LICENSE
3559
3560 This library is free software. You can redistribute it and/or modify it under
3561 the same terms as Perl itself.
3562
3563 =cut
3564
3565 no Moose;
3566
3567 __PACKAGE__->meta->make_immutable;
3568
3569 1;