lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54
  55 BEGIN { require 5.008003; }
  56
  57 has stack => (is => 'ro', default => sub { [] });
  58 has state => (is => 'rw', default => 0);
  59 has stats => (is => 'rw');
  60 has action => (is => 'rw');
  61 has counter => (is => 'rw', default => sub { {} });
  62 has request => (
  63     is => 'rw',
  64     default => sub {
  65         my $self = shift;
  66         $self->request_class->new($self->_build_request_constructor_args);
  67     },
  68     lazy => 1,
  69 );
  70 sub _build_request_constructor_args {
  71     my $self = shift;
  72     my %p = ( _log => $self->log );
  73     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  74     $p{data_handlers} = {$self->registered_data_handlers};
  75     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  76       if $self->config->{use_hash_multivalue_in_request};
  77     \%p;
  78 }
  79
  80 has response => (
  81     is => 'rw',
  82     default => sub {
  83         my $self = shift;
  84         $self->response_class->new($self->_build_response_constructor_args);
  85     },
  86     lazy => 1,
  87 );
  88 sub _build_response_constructor_args {
  89     return +{
  90       _log => $_[0]->log,
  91       encoding => $_[0]->encoding,
  92     };
  93 }
  94
  95 has namespace => (is => 'rw');
  96
  97 sub depth { scalar @{ shift->stack || [] }; }
  98 sub comp { shift->component(@_) }
  99
 100 sub req {
 101     my $self = shift; return $self->request(@_);
 102 }
 103 sub res {
 104     my $self = shift; return $self->response(@_);
 105 }
 106
 107 # For backwards compatibility
 108 sub finalize_output { shift->finalize_body(@_) };
 109
 110 # For statistics
 111 our $COUNT     = 1;
 112 our $START     = time;
 113 our $RECURSION = 1000;
 114 our $DETACH    = Catalyst::Exception::Detach->new;
 115 our $GO        = Catalyst::Exception::Go->new;
 116
 117 #I imagine that very few of these really need to be class variables. if any.
 118 #maybe we should just make them attributes with a default?
 119 __PACKAGE__->mk_classdata($_)
 120   for qw/components arguments dispatcher engine log dispatcher_class
 121   engine_loader context_class request_class response_class stats_class
 122   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 123   _data_handlers _encoding _encode_check finalized_default_middleware/;
 124
 125 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 126 __PACKAGE__->request_class('Catalyst::Request');
 127 __PACKAGE__->response_class('Catalyst::Response');
 128 __PACKAGE__->stats_class('Catalyst::Stats');
 129 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 130
 131 # Remember to update this in Catalyst::Runtime as well!
 132 our $VERSION = '5.90089_001';
 133 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 134
 135 sub import {
 136     my ( $class, @arguments ) = @_;
 137
 138     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 139     # callers @ISA.
 140     return unless $class eq 'Catalyst';
 141
 142     my $caller = caller();
 143     return if $caller eq 'main';
 144
 145     my $meta = Moose::Meta::Class->initialize($caller);
 146     unless ( $caller->isa('Catalyst') ) {
 147         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 148         $meta->superclasses(@superclasses);
 149     }
 150     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 151     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 152
 153     unless( $meta->has_method('meta') ){
 154         if ($Moose::VERSION >= 1.15) {
 155             $meta->_add_meta_method('meta');
 156         }
 157         else {
 158             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 159         }
 160     }
 161
 162     $caller->arguments( [@arguments] );
 163     $caller->setup_home;
 164 }
 165
 166 sub _application { $_[0] }
 167
 168 =encoding UTF-8
 169
 170 =head1 NAME
 171
 172 Catalyst - The Elegant MVC Web Application Framework
 173
 174 =head1 SYNOPSIS
 175
 176 See the L<Catalyst::Manual> distribution for comprehensive
 177 documentation and tutorials.
 178
 179     # Install Catalyst::Devel for helpers and other development tools
 180     # use the helper to create a new application
 181     catalyst.pl MyApp
 182
 183     # add models, views, controllers
 184     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 185     script/myapp_create.pl view MyTemplate TT
 186     script/myapp_create.pl controller Search
 187
 188     # built in testserver -- use -r to restart automatically on changes
 189     # --help to see all available options
 190     script/myapp_server.pl
 191
 192     # command line testing interface
 193     script/myapp_test.pl /yada
 194
 195     ### in lib/MyApp.pm
 196     use Catalyst qw/-Debug/; # include plugins here as well
 197
 198     ### In lib/MyApp/Controller/Root.pm (autocreated)
 199     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 200         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 201         $c->stash->{template} = 'foo.tt'; # set the template
 202         # lookup something from db -- stash vars are passed to TT
 203         $c->stash->{data} =
 204           $c->model('Database::Foo')->search( { country => $args[0] } );
 205         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 206             $c->forward( 'bar' ); # process another action
 207             # do something else after forward returns
 208         }
 209     }
 210
 211     # The foo.tt TT template can use the stash data from the database
 212     [% WHILE (item = data.next) %]
 213         [% item.foo %]
 214     [% END %]
 215
 216     # called for /bar/of/soap, /bar/of/soap/10, etc.
 217     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 218
 219     # called after all actions are finished
 220     sub end : Action {
 221         my ( $self, $c ) = @_;
 222         if ( scalar @{ $c->error } ) { ... } # handle errors
 223         return if $c->res->body; # already have a response
 224         $c->forward( 'MyApp::View::TT' ); # render template
 225     }
 226
 227 See L<Catalyst::Manual::Intro> for additional information.
 228
 229 =head1 DESCRIPTION
 230
 231 Catalyst is a modern framework for making web applications without the
 232 pain usually associated with this process. This document is a reference
 233 to the main Catalyst application. If you are a new user, we suggest you
 234 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 235
 236 See L<Catalyst::Manual> for more documentation.
 237
 238 Catalyst plugins can be loaded by naming them as arguments to the "use
 239 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 240 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 241 C<My::Module>.
 242
 243     use Catalyst qw/My::Module/;
 244
 245 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 246 fully qualify the name by using a unary plus:
 247
 248     use Catalyst qw/
 249         My::Module
 250         +Fully::Qualified::Plugin::Name
 251     /;
 252
 253 Special flags like C<-Debug> can also be specified as
 254 arguments when Catalyst is loaded:
 255
 256     use Catalyst qw/-Debug My::Module/;
 257
 258 The position of plugins and flags in the chain is important, because
 259 they are loaded in the order in which they appear.
 260
 261 The following flags are supported:
 262
 263 =head2 -Debug
 264
 265 Enables debug output. You can also force this setting from the system
 266 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 267 settings override the application, with <MYAPP>_DEBUG having the highest
 268 priority.
 269
 270 This sets the log level to 'debug' and enables full debug output on the
 271 error screen. If you only want the latter, see L<< $c->debug >>.
 272
 273 =head2 -Home
 274
 275 Forces Catalyst to use a specific home directory, e.g.:
 276
 277     use Catalyst qw[-Home=/usr/mst];
 278
 279 This can also be done in the shell environment by setting either the
 280 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 281 is replaced with the uppercased name of your application, any "::" in
 282 the name will be replaced with underscores, e.g. MyApp::Web should use
 283 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 284
 285 If none of these are set, Catalyst will attempt to automatically detect the
 286 home directory. If you are working in a development environment, Catalyst
 287 will try and find the directory containing either Makefile.PL, Build.PL,
 288 dist.ini, or cpanfile. If the application has been installed into the system
 289 (i.e. you have done C<make install>), then Catalyst will use the path to your
 290 application module, without the .pm extension (e.g., /foo/MyApp if your
 291 application was installed at /foo/MyApp.pm)
 292
 293 =head2 -Log
 294
 295     use Catalyst '-Log=warn,fatal,error';
 296
 297 Specifies a comma-delimited list of log levels.
 298
 299 =head2 -Stats
 300
 301 Enables statistics collection and reporting.
 302
 303    use Catalyst qw/-Stats=1/;
 304
 305 You can also force this setting from the system environment with CATALYST_STATS
 306 or <MYAPP>_STATS. The environment settings override the application, with
 307 <MYAPP>_STATS having the highest priority.
 308
 309 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 310
 311 =head1 METHODS
 312
 313 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 314
 315 =head2 $c->action
 316
 317 Returns a L<Catalyst::Action> object for the current action, which
 318 stringifies to the action name. See L<Catalyst::Action>.
 319
 320 =head2 $c->namespace
 321
 322 Returns the namespace of the current action, i.e., the URI prefix
 323 corresponding to the controller of the current action. For example:
 324
 325     # in Controller::Foo::Bar
 326     $c->namespace; # returns 'foo/bar';
 327
 328 =head2 $c->request
 329
 330 =head2 $c->req
 331
 332 Returns the current L<Catalyst::Request> object, giving access to
 333 information about the current client request (including parameters,
 334 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 335
 336 =head2 REQUEST FLOW HANDLING
 337
 338 =head2 $c->forward( $action [, \@arguments ] )
 339
 340 =head2 $c->forward( $class, $method, [, \@arguments ] )
 341
 342 This is one way of calling another action (method) in the same or
 343 a different controller. You can also use C<< $self->my_method($c, @args) >>
 344 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 345 in a different controller.
 346 The main difference is that 'forward' uses some of the Catalyst request
 347 cycle overhead, including debugging, which may be useful to you. On the
 348 other hand, there are some complications to using 'forward', restrictions
 349 on values returned from 'forward', and it may not handle errors as you prefer.
 350 Whether you use 'forward' or not is up to you; it is not considered superior to
 351 the other ways to call a method.
 352
 353 'forward' calls  another action, by its private name. If you give a
 354 class name but no method, C<process()> is called. You may also optionally
 355 pass arguments in an arrayref. The action will receive the arguments in
 356 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 357 C<< $c->req->args >> will be restored to the previous values.
 358
 359 Any data C<return>ed from the action forwarded to, will be returned by the
 360 call to forward.
 361
 362     my $foodata = $c->forward('/foo');
 363     $c->forward('index');
 364     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 365     $c->forward('View::TT');
 366
 367 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 368 an C<< eval { } >> around the call (actually
 369 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 370 exceptions thrown by the called action non-fatal and pushing them onto
 371 $c->error instead. If you want C<die> to propagate you need to do something
 372 like:
 373
 374     $c->forward('foo');
 375     die join "\n", @{ $c->error } if @{ $c->error };
 376
 377 Or make sure to always return true values from your actions and write
 378 your code like this:
 379
 380     $c->forward('foo') || return;
 381
 382 Another note is that C<< $c->forward >> always returns a scalar because it
 383 actually returns $c->state which operates in a scalar context.
 384 Thus, something like:
 385
 386     return @array;
 387
 388 in an action that is forwarded to is going to return a scalar,
 389 i.e. how many items are in that array, which is probably not what you want.
 390 If you need to return an array then return a reference to it,
 391 or stash it like so:
 392
 393     $c->stash->{array} = \@array;
 394
 395 and access it from the stash.
 396
 397 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 398
 399 =cut
 400
 401 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 402
 403 =head2 $c->detach( $action [, \@arguments ] )
 404
 405 =head2 $c->detach( $class, $method, [, \@arguments ] )
 406
 407 =head2 $c->detach()
 408
 409 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 410 doesn't return to the previous action when processing is finished.
 411
 412 When called with no arguments it escapes the processing chain entirely.
 413
 414 =cut
 415
 416 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 417
 418 =head2 $c->visit( $action [, \@arguments ] )
 419
 420 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 421
 422 =head2 $c->visit( $class, $method, [, \@arguments ] )
 423
 424 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 425
 426 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 427 but does a full dispatch, instead of just calling the new C<$action> /
 428 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 429 you go to are called, just like a new request.
 430
 431 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 432 This means, for example, that C<< $c->action >> methods such as
 433 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 434 L<reverse|Catalyst::Action/reverse> return information for the visited action
 435 when they are invoked within the visited action.  This is different from the
 436 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 437 continues to use the $c->action object from the caller action even when
 438 invoked from the called action.
 439
 440 C<< $c->stash >> is kept unchanged.
 441
 442 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 443 allows you to "wrap" another action, just as it would have been called by
 444 dispatching from a URL, while the analogous
 445 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 446 transfer control to another action as if it had been reached directly from a URL.
 447
 448 =cut
 449
 450 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 451
 452 =head2 $c->go( $action [, \@arguments ] )
 453
 454 =head2 $c->go( $action [, \@captures, \@arguments ] )
 455
 456 =head2 $c->go( $class, $method, [, \@arguments ] )
 457
 458 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 459
 460 The relationship between C<go> and
 461 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 462 the relationship between
 463 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 464 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 465 C<< $c->go >> will perform a full dispatch on the specified action or method,
 466 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 467 C<go> escapes the processing of the current request chain on completion, and
 468 does not return to its caller.
 469
 470 @arguments are arguments to the final destination of $action. @captures are
 471 arguments to the intermediate steps, if any, on the way to the final sub of
 472 $action.
 473
 474 =cut
 475
 476 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 477
 478 =head2 $c->response
 479
 480 =head2 $c->res
 481
 482 Returns the current L<Catalyst::Response> object, see there for details.
 483
 484 =head2 $c->stash
 485
 486 Returns a hashref to the stash, which may be used to store data and pass
 487 it between components during a request. You can also set hash keys by
 488 passing arguments. The stash is automatically sent to the view. The
 489 stash is cleared at the end of a request; it cannot be used for
 490 persistent storage (for this you must use a session; see
 491 L<Catalyst::Plugin::Session> for a complete system integrated with
 492 Catalyst).
 493
 494     $c->stash->{foo} = $bar;
 495     $c->stash( { moose => 'majestic', qux => 0 } );
 496     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 497
 498     # stash is automatically passed to the view for use in a template
 499     $c->forward( 'MyApp::View::TT' );
 500
 501 The stash hash is currently stored in the PSGI C<$env> and is managed by
 502 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 503 the stash can be accessed in sub applications mounted under your main
 504 L<Catalyst> application.  For example if you delegate the response of an
 505 action to another L<Catalyst> application, that sub application will have
 506 access to all the stash keys of the main one, and if can of course add
 507 more keys of its own.  However those new keys will not 'bubble' back up
 508 to the main application.
 509
 510 For more information the best thing to do is to review the test case:
 511 t/middleware-stash.t in the distribution /t directory.
 512
 513 =cut
 514
 515 sub stash {
 516   my $c = shift;
 517   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 518 }
 519
 520 =head2 $c->error
 521
 522 =head2 $c->error($error, ...)
 523
 524 =head2 $c->error($arrayref)
 525
 526 Returns an arrayref containing error messages.  If Catalyst encounters an
 527 error while processing a request, it stores the error in $c->error.  This
 528 method should only be used to store fatal error messages.
 529
 530     my @error = @{ $c->error };
 531
 532 Add a new error.
 533
 534     $c->error('Something bad happened');
 535
 536 Calling this will always return an arrayref (if there are no errors it
 537 will be an empty arrayref.
 538
 539 =cut
 540
 541 sub error {
 542     my $c = shift;
 543     if ( $_[0] ) {
 544         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 545         croak @$error unless ref $c;
 546         push @{ $c->{error} }, @$error;
 547     }
 548     elsif ( defined $_[0] ) { $c->{error} = undef }
 549     return $c->{error} || [];
 550 }
 551
 552
 553 =head2 $c->state
 554
 555 Contains the return value of the last executed action.
 556 Note that << $c->state >> operates in a scalar context which means that all
 557 values it returns are scalar.
 558
 559 =head2 $c->clear_errors
 560
 561 Clear errors.  You probably don't want to clear the errors unless you are
 562 implementing a custom error screen.
 563
 564 This is equivalent to running
 565
 566     $c->error(0);
 567
 568 =cut
 569
 570 sub clear_errors {
 571     my $c = shift;
 572     $c->error(0);
 573 }
 574
 575 =head2 $c->has_errors
 576
 577 Returns true if you have errors
 578
 579 =cut
 580
 581 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 582
 583 =head2 $c->last_error
 584
 585 Returns the most recent error in the stack (the one most recently added...)
 586 or nothing if there are no errors.
 587
 588 =cut
 589
 590 sub last_error { my ($err, @errs) = @{shift->error}; return $err }
 591
 592 =head2 shift_errors
 593
 594 shifts the most recently added error off the error stack and returns if.  Returns
 595 nothing if there are no more errors.
 596
 597 =cut
 598
 599 sub shift_errors {
 600     my ($self) = @_;
 601     my ($err, @errors) = @{$self->error};
 602     $self->{error} = \@errors;
 603     return $err;
 604 }
 605
 606 sub _comp_search_prefixes {
 607     my $c = shift;
 608     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 609 }
 610
 611 # search components given a name and some prefixes
 612 sub _comp_names_search_prefixes {
 613     my ( $c, $name, @prefixes ) = @_;
 614     my $appclass = ref $c || $c;
 615     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 616     $filter = qr/$filter/; # Compile regex now rather than once per loop
 617
 618     # map the original component name to the sub part that we will search against
 619     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 620         grep { /$filter/ } keys %{ $c->components };
 621
 622     # undef for a name will return all
 623     return keys %eligible if !defined $name;
 624
 625     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 626     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 627
 628     return @result if @result;
 629
 630     # if we were given a regexp to search against, we're done.
 631     return if $name->$_isa('Regexp');
 632
 633     # skip regexp fallback if configured
 634     return
 635         if $appclass->config->{disable_component_resolution_regex_fallback};
 636
 637     # regexp fallback
 638     $query  = qr/$name/i;
 639     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 640
 641     # no results? try against full names
 642     if( !@result ) {
 643         @result = grep { m{$query} } keys %eligible;
 644     }
 645
 646     # don't warn if we didn't find any results, it just might not exist
 647     if( @result ) {
 648         # Disgusting hack to work out correct method name
 649         my $warn_for = lc $prefixes[0];
 650         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 651            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 652            "component resolution is unreliable and unsafe.";
 653         my $short = $result[0];
 654         # remove the component namespace prefix
 655         $short =~ s/.*?(Model|Controller|View):://;
 656         my $shortmess = Carp::shortmess('');
 657         if ($shortmess =~ m#Catalyst/Plugin#) {
 658            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 659               "plugin's config";
 660         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 661            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 662               "component's config";
 663         } else {
 664            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 665               "but if you really wanted to search, pass in a regexp as the argument " .
 666               "like so: \$c->${warn_for}(qr/${name}/)";
 667         }
 668         $c->log->warn( "${msg}$shortmess" );
 669     }
 670
 671     return @result;
 672 }
 673
 674 # Find possible names for a prefix
 675 sub _comp_names {
 676     my ( $c, @prefixes ) = @_;
 677     my $appclass = ref $c || $c;
 678
 679     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 680
 681     my @names = map { s{$filter}{}; $_; }
 682         $c->_comp_names_search_prefixes( undef, @prefixes );
 683
 684     return @names;
 685 }
 686
 687 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 688 sub _filter_component {
 689     my ( $c, $comp, @args ) = @_;
 690
 691     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 692         return $comp->ACCEPT_CONTEXT( $c, @args );
 693     }
 694
 695     return $comp;
 696 }
 697
 698 =head2 COMPONENT ACCESSORS
 699
 700 =head2 $c->controller($name)
 701
 702 Gets a L<Catalyst::Controller> instance by name.
 703
 704     $c->controller('Foo')->do_stuff;
 705
 706 If the name is omitted, will return the controller for the dispatched
 707 action.
 708
 709 If you want to search for controllers, pass in a regexp as the argument.
 710
 711     # find all controllers that start with Foo
 712     my @foo_controllers = $c->controller(qr{^Foo});
 713
 714
 715 =cut
 716
 717 sub controller {
 718     my ( $c, $name, @args ) = @_;
 719
 720     my $appclass = ref($c) || $c;
 721     if( $name ) {
 722         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 723             my $comps = $c->components;
 724             my $check = $appclass."::Controller::".$name;
 725             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 726         }
 727         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 728         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 729         return $c->_filter_component( $result[ 0 ], @args );
 730     }
 731
 732     return $c->component( $c->action->class );
 733 }
 734
 735 =head2 $c->model($name)
 736
 737 Gets a L<Catalyst::Model> instance by name.
 738
 739     $c->model('Foo')->do_stuff;
 740
 741 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 742
 743 If the name is omitted, it will look for
 744  - a model object in $c->stash->{current_model_instance}, then
 745  - a model name in $c->stash->{current_model}, then
 746  - a config setting 'default_model', or
 747  - check if there is only one model, and return it if that's the case.
 748
 749 If you want to search for models, pass in a regexp as the argument.
 750
 751     # find all models that start with Foo
 752     my @foo_models = $c->model(qr{^Foo});
 753
 754 =cut
 755
 756 sub model {
 757     my ( $c, $name, @args ) = @_;
 758     my $appclass = ref($c) || $c;
 759     if( $name ) {
 760         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 761             my $comps = $c->components;
 762             my $check = $appclass."::Model::".$name;
 763             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 764         }
 765         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 766         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 767         return $c->_filter_component( $result[ 0 ], @args );
 768     }
 769
 770     if (ref $c) {
 771         return $c->stash->{current_model_instance}
 772           if $c->stash->{current_model_instance};
 773         return $c->model( $c->stash->{current_model} )
 774           if $c->stash->{current_model};
 775     }
 776     return $c->model( $appclass->config->{default_model} )
 777       if $appclass->config->{default_model};
 778
 779     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 780
 781     if( $rest ) {
 782         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 783         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 784         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 785         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 786         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 787     }
 788
 789     return $c->_filter_component( $comp );
 790 }
 791
 792
 793 =head2 $c->view($name)
 794
 795 Gets a L<Catalyst::View> instance by name.
 796
 797     $c->view('Foo')->do_stuff;
 798
 799 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 800
 801 If the name is omitted, it will look for
 802  - a view object in $c->stash->{current_view_instance}, then
 803  - a view name in $c->stash->{current_view}, then
 804  - a config setting 'default_view', or
 805  - check if there is only one view, and return it if that's the case.
 806
 807 If you want to search for views, pass in a regexp as the argument.
 808
 809     # find all views that start with Foo
 810     my @foo_views = $c->view(qr{^Foo});
 811
 812 =cut
 813
 814 sub view {
 815     my ( $c, $name, @args ) = @_;
 816
 817     my $appclass = ref($c) || $c;
 818     if( $name ) {
 819         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 820             my $comps = $c->components;
 821             my $check = $appclass."::View::".$name;
 822             if( exists $comps->{$check} ) {
 823                 return $c->_filter_component( $comps->{$check}, @args );
 824             }
 825             else {
 826                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 827             }
 828         }
 829         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 830         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 831         return $c->_filter_component( $result[ 0 ], @args );
 832     }
 833
 834     if (ref $c) {
 835         return $c->stash->{current_view_instance}
 836           if $c->stash->{current_view_instance};
 837         return $c->view( $c->stash->{current_view} )
 838           if $c->stash->{current_view};
 839     }
 840     return $c->view( $appclass->config->{default_view} )
 841       if $appclass->config->{default_view};
 842
 843     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 844
 845     if( $rest ) {
 846         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 847         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 848         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 849         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 850         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 851     }
 852
 853     return $c->_filter_component( $comp );
 854 }
 855
 856 =head2 $c->controllers
 857
 858 Returns the available names which can be passed to $c->controller
 859
 860 =cut
 861
 862 sub controllers {
 863     my ( $c ) = @_;
 864     return $c->_comp_names(qw/Controller C/);
 865 }
 866
 867 =head2 $c->models
 868
 869 Returns the available names which can be passed to $c->model
 870
 871 =cut
 872
 873 sub models {
 874     my ( $c ) = @_;
 875     return $c->_comp_names(qw/Model M/);
 876 }
 877
 878
 879 =head2 $c->views
 880
 881 Returns the available names which can be passed to $c->view
 882
 883 =cut
 884
 885 sub views {
 886     my ( $c ) = @_;
 887     return $c->_comp_names(qw/View V/);
 888 }
 889
 890 =head2 $c->comp($name)
 891
 892 =head2 $c->component($name)
 893
 894 Gets a component object by name. This method is not recommended,
 895 unless you want to get a specific component by full
 896 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 897 should be used instead.
 898
 899 If C<$name> is a regexp, a list of components matched against the full
 900 component name will be returned.
 901
 902 If Catalyst can't find a component by name, it will fallback to regex
 903 matching by default. To disable this behaviour set
 904 disable_component_resolution_regex_fallback to a true value.
 905
 906     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 907
 908 =cut
 909
 910 sub component {
 911     my ( $c, $name, @args ) = @_;
 912
 913     if( $name ) {
 914         my $comps = $c->components;
 915
 916         if( !ref $name ) {
 917             # is it the exact name?
 918             return $c->_filter_component( $comps->{ $name }, @args )
 919                        if exists $comps->{ $name };
 920
 921             # perhaps we just omitted "MyApp"?
 922             my $composed = ( ref $c || $c ) . "::${name}";
 923             return $c->_filter_component( $comps->{ $composed }, @args )
 924                        if exists $comps->{ $composed };
 925
 926             # search all of the models, views and controllers
 927             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 928             return $c->_filter_component( $comp, @args ) if $comp;
 929         }
 930
 931         return
 932             if $c->config->{disable_component_resolution_regex_fallback};
 933
 934         # This is here so $c->comp( '::M::' ) works
 935         my $query = ref $name ? $name : qr{$name}i;
 936
 937         my @result = grep { m{$query} } keys %{ $c->components };
 938         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 939
 940         if( $result[ 0 ] ) {
 941             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 942             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 943             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 944             return $c->_filter_component( $result[ 0 ], @args );
 945         }
 946
 947         # I would expect to return an empty list here, but that breaks back-compat
 948     }
 949
 950     # fallback
 951     return sort keys %{ $c->components };
 952 }
 953
 954 =head2 CLASS DATA AND HELPER CLASSES
 955
 956 =head2 $c->config
 957
 958 Returns or takes a hashref containing the application's configuration.
 959
 960     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 961
 962 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 963 like C<myapp.conf> in your applications home directory. See
 964 L<Catalyst::Plugin::ConfigLoader>.
 965
 966 =head3 Cascading configuration
 967
 968 The config method is present on all Catalyst components, and configuration
 969 will be merged when an application is started. Configuration loaded with
 970 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 971 followed by configuration in your top level C<MyApp> class. These two
 972 configurations are merged, and then configuration data whose hash key matches a
 973 component name is merged with configuration for that component.
 974
 975 The configuration for a component is then passed to the C<new> method when a
 976 component is constructed.
 977
 978 For example:
 979
 980     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 981     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 982
 983 will mean that C<MyApp::Model::Foo> receives the following data when
 984 constructed:
 985
 986     MyApp::Model::Foo->new({
 987         bar => 'baz',
 988         quux => 'frob',
 989         overrides => 'me',
 990     });
 991
 992 It's common practice to use a Moose attribute
 993 on the receiving component to access the config value.
 994
 995     package MyApp::Model::Foo;
 996
 997     use Moose;
 998
 999     # this attr will receive 'baz' at construction time
1000     has 'bar' => (
1001         is  => 'rw',
1002         isa => 'Str',
1003     );
1004
1005 You can then get the value 'baz' by calling $c->model('Foo')->bar
1006 (or $self->bar inside code in the model).
1007
1008 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
1009 as a way of reading config within your code, as this B<will not> give you the
1010 correctly merged config back. You B<MUST> take the config values supplied to
1011 the constructor and use those instead.
1012
1013 =cut
1014
1015 around config => sub {
1016     my $orig = shift;
1017     my $c = shift;
1018
1019     croak('Setting config after setup has been run is not allowed.')
1020         if ( @_ and $c->setup_finished );
1021
1022     $c->$orig(@_);
1023 };
1024
1025 =head2 $c->log
1026
1027 Returns the logging object instance. Unless it is already set, Catalyst
1028 sets this up with a L<Catalyst::Log> object. To use your own log class,
1029 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1030 C<< __PACKAGE__->setup >>.
1031
1032  __PACKAGE__->log( MyLogger->new );
1033  __PACKAGE__->setup;
1034
1035 And later:
1036
1037     $c->log->info( 'Now logging with my own logger!' );
1038
1039 Your log class should implement the methods described in
1040 L<Catalyst::Log>.
1041
1042 =head2 has_encoding
1043
1044 Returned True if there's a valid encoding
1045
1046 =head2 clear_encoding
1047
1048 Clears the encoding for the current context
1049
1050 =head2 encoding
1051
1052 Sets or gets the application encoding.  Setting encoding takes either an
1053 Encoding object or a string that we try to resolve via L<Encode::find_encoding>.
1054
1055 You would expect to get the encoding object back if you attempt to set it.  If
1056 there is a failure you will get undef returned and an error message in the log.
1057
1058 =cut
1059
1060 sub has_encoding { shift->encoding ? 1:0 }
1061
1062 sub clear_encoding {
1063     my $c = shift;
1064     if(blessed $c) {
1065         $c->encoding(undef);
1066     } else {
1067         $c->log->error("You can't clear encoding on the application");
1068     }
1069 }
1070
1071 sub encoding {
1072     my $c = shift;
1073     my $encoding;
1074
1075     if ( scalar @_ ) {
1076
1077         # Don't let one change this once we are too far into the response
1078         if(blessed $c && $c->res->finalized_headers) {
1079           Carp::croak("You may not change the encoding once the headers are finalized");
1080           return;
1081         }
1082
1083         # Let it be set to undef
1084         if (my $wanted = shift)  {
1085             $encoding = Encode::find_encoding($wanted)
1086               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1087             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1088         }
1089         else {
1090             binmode(STDERR);
1091         }
1092
1093         $encoding = ref $c
1094                   ? $c->{encoding} = $encoding
1095                   : $c->_encoding($encoding);
1096     } else {
1097       $encoding = ref $c && exists $c->{encoding}
1098                 ? $c->{encoding}
1099                 : $c->_encoding;
1100     }
1101
1102     return $encoding;
1103 }
1104
1105 =head2 $c->debug
1106
1107 Returns 1 if debug mode is enabled, 0 otherwise.
1108
1109 You can enable debug mode in several ways:
1110
1111 =over
1112
1113 =item By calling myapp_server.pl with the -d flag
1114
1115 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1116
1117 =item The -Debug option in your MyApp.pm
1118
1119 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1120
1121 =back
1122
1123 The first three also set the log level to 'debug'.
1124
1125 Calling C<< $c->debug(1) >> has no effect.
1126
1127 =cut
1128
1129 sub debug { 0 }
1130
1131 =head2 $c->dispatcher
1132
1133 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1134
1135 =head2 $c->engine
1136
1137 Returns the engine instance. See L<Catalyst::Engine>.
1138
1139
1140 =head2 UTILITY METHODS
1141
1142 =head2 $c->path_to(@path)
1143
1144 Merges C<@path> with C<< $c->config->{home} >> and returns a
1145 L<Path::Class::Dir> object. Note you can usually use this object as
1146 a filename, but sometimes you will have to explicitly stringify it
1147 yourself by calling the C<< ->stringify >> method.
1148
1149 For example:
1150
1151     $c->path_to( 'db', 'sqlite.db' );
1152
1153 =cut
1154
1155 sub path_to {
1156     my ( $c, @path ) = @_;
1157     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1158     if ( -d $path ) { return $path }
1159     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1160 }
1161
1162 sub plugin {
1163     my ( $class, $name, $plugin, @args ) = @_;
1164
1165     # See block comment in t/unit_core_plugin.t
1166     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1167
1168     $class->_register_plugin( $plugin, 1 );
1169
1170     eval { $plugin->import };
1171     $class->mk_classdata($name);
1172     my $obj;
1173     eval { $obj = $plugin->new(@args) };
1174
1175     if ($@) {
1176         Catalyst::Exception->throw( message =>
1177               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1178     }
1179
1180     $class->$name($obj);
1181     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1182       if $class->debug;
1183 }
1184
1185 =head2 MyApp->setup
1186
1187 Initializes the dispatcher and engine, loads any plugins, and loads the
1188 model, view, and controller components. You may also specify an array
1189 of plugins to load here, if you choose to not load them in the C<use
1190 Catalyst> line.
1191
1192     MyApp->setup;
1193     MyApp->setup( qw/-Debug/ );
1194
1195 B<Note:> You B<should not> wrap this method with method modifiers
1196 or bad things will happen - wrap the C<setup_finalize> method instead.
1197
1198 B<Note:> You can create a custom setup stage that will execute when the
1199 application is starting.  Use this to customize setup.
1200
1201     MyApp->setup(-Custom=value);
1202
1203     sub setup_custom {
1204       my ($class, $value) = @_;
1205     }
1206
1207 Can be handy if you want to hook into the setup phase.
1208
1209 =cut
1210
1211 sub setup {
1212     my ( $class, @arguments ) = @_;
1213     croak('Running setup more than once')
1214         if ( $class->setup_finished );
1215
1216     unless ( $class->isa('Catalyst') ) {
1217
1218         Catalyst::Exception->throw(
1219             message => qq/'$class' does not inherit from Catalyst/ );
1220     }
1221
1222     if ( $class->arguments ) {
1223         @arguments = ( @arguments, @{ $class->arguments } );
1224     }
1225
1226     # Process options
1227     my $flags = {};
1228
1229     foreach (@arguments) {
1230
1231         if (/^-Debug$/) {
1232             $flags->{log} =
1233               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1234         }
1235         elsif (/^-(\w+)=?(.*)$/) {
1236             $flags->{ lc $1 } = $2;
1237         }
1238         else {
1239             push @{ $flags->{plugins} }, $_;
1240         }
1241     }
1242
1243     $class->setup_home( delete $flags->{home} );
1244
1245     $class->setup_log( delete $flags->{log} );
1246     $class->setup_plugins( delete $flags->{plugins} );
1247
1248     $class->setup_data_handlers();
1249     $class->setup_dispatcher( delete $flags->{dispatcher} );
1250     if (my $engine = delete $flags->{engine}) {
1251         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1252     }
1253     $class->setup_engine();
1254     $class->setup_stats( delete $flags->{stats} );
1255
1256     for my $flag ( sort keys %{$flags} ) {
1257
1258         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1259             &$code( $class, delete $flags->{$flag} );
1260         }
1261         else {
1262             $class->log->warn(qq/Unknown flag "$flag"/);
1263         }
1264     }
1265
1266     eval { require Catalyst::Devel; };
1267     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1268         $class->log->warn(<<"EOF");
1269 You are running an old script!
1270
1271   Please update by running (this will overwrite existing files):
1272     catalyst.pl -force -scripts $class
1273
1274   or (this will not overwrite existing files):
1275     catalyst.pl -scripts $class
1276
1277 EOF
1278     }
1279
1280     # Call plugins setup, this is stupid and evil.
1281     # Also screws C3 badly on 5.10, hack to avoid.
1282     {
1283         no warnings qw/redefine/;
1284         local *setup = sub { };
1285         $class->setup unless $Catalyst::__AM_RESTARTING;
1286     }
1287
1288     # If you are expecting configuration info as part of your setup, it needs
1289     # to get called here and below, since we need the above line to support
1290     # ConfigLoader based configs.
1291
1292     $class->setup_encoding();
1293     $class->setup_middleware();
1294
1295     # Initialize our data structure
1296     $class->components( {} );
1297
1298     $class->setup_components;
1299
1300     if ( $class->debug ) {
1301         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1302
1303         if (@plugins) {
1304             my $column_width = Catalyst::Utils::term_width() - 6;
1305             my $t = Text::SimpleTable->new($column_width);
1306             $t->row($_) for @plugins;
1307             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1308         }
1309
1310         my @middleware = map {
1311           ref $_ eq 'CODE' ?
1312             "Inline Coderef" :
1313               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1314                 || '')  } $class->registered_middlewares;
1315
1316         if (@middleware) {
1317             my $column_width = Catalyst::Utils::term_width() - 6;
1318             my $t = Text::SimpleTable->new($column_width);
1319             $t->row($_) for @middleware;
1320             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1321         }
1322
1323         my %dh = $class->registered_data_handlers;
1324         if (my @data_handlers = keys %dh) {
1325             my $column_width = Catalyst::Utils::term_width() - 6;
1326             my $t = Text::SimpleTable->new($column_width);
1327             $t->row($_) for @data_handlers;
1328             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1329         }
1330
1331         my $dispatcher = $class->dispatcher;
1332         my $engine     = $class->engine;
1333         my $home       = $class->config->{home};
1334
1335         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1336         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1337
1338         $home
1339           ? ( -d $home )
1340           ? $class->log->debug(qq/Found home "$home"/)
1341           : $class->log->debug(qq/Home "$home" doesn't exist/)
1342           : $class->log->debug(q/Couldn't find home/);
1343
1344         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1345         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1346         for my $comp ( sort keys %{ $class->components } ) {
1347             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1348             $t->row( $comp, $type );
1349         }
1350         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1351           if ( keys %{ $class->components } );
1352     }
1353
1354     # Add our self to components, since we are also a component
1355     if( $class->isa('Catalyst::Controller') ){
1356       $class->components->{$class} = $class;
1357     }
1358
1359     $class->setup_actions;
1360
1361     if ( $class->debug ) {
1362         my $name = $class->config->{name} || 'Application';
1363         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1364     }
1365
1366     if ($class->config->{case_sensitive}) {
1367         $class->log->warn($class . "->config->{case_sensitive} is set.");
1368         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1369     }
1370
1371     $class->setup_finalize;
1372
1373     # Flush the log for good measure (in case something turned off 'autoflush' early)
1374     $class->log->_flush() if $class->log->can('_flush');
1375
1376     return $class || 1; # Just in case someone named their Application 0...
1377 }
1378
1379 =head2 $app->setup_finalize
1380
1381 A hook to attach modifiers to. This method does not do anything except set the
1382 C<setup_finished> accessor.
1383
1384 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1385
1386 Example:
1387
1388     after setup_finalize => sub {
1389         my $app = shift;
1390
1391         ## do stuff here..
1392     };
1393
1394 =cut
1395
1396 sub setup_finalize {
1397     my ($class) = @_;
1398     $class->setup_finished(1);
1399 }
1400
1401 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1402
1403 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1404
1405 =head2 $c->uri_for( $action, [@captures, @args], \%query_values? )
1406
1407 Constructs an absolute L<URI> object based on the application root, the
1408 provided path, and the additional arguments and query parameters provided.
1409 When used as a string, provides a textual URI.  If you need more flexibility
1410 than this (i.e. the option to provide relative URIs etc.) see
1411 L<Catalyst::Plugin::SmartURI>.
1412
1413 If no arguments are provided, the URI for the current action is returned.
1414 To return the current action and also provide @args, use
1415 C<< $c->uri_for( $c->action, @args ) >>.
1416
1417 If the first argument is a string, it is taken as a public URI path relative
1418 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1419 relative to the application root (if it does). It is then merged with
1420 C<< $c->request->base >>; any C<@args> are appended as additional path
1421 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1422
1423 If the first argument is a L<Catalyst::Action> it represents an action which
1424 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1425 optional C<\@captures> argument (an arrayref) allows passing the captured
1426 variables that are needed to fill in the paths of Chained and Regex actions;
1427 once the path is resolved, C<uri_for> continues as though a path was
1428 provided, appending any arguments or parameters and creating an absolute
1429 URI.
1430
1431 The captures for the current request can be found in
1432 C<< $c->request->captures >>, and actions can be resolved using
1433 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1434 path, use C<< $c->uri_for_action >> instead.
1435
1436   # Equivalent to $c->req->uri
1437   $c->uri_for($c->action, $c->req->captures,
1438       @{ $c->req->args }, $c->req->params);
1439
1440   # For the Foo action in the Bar controller
1441   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1442
1443   # Path to a static resource
1444   $c->uri_for('/static/images/logo.png');
1445
1446 In general the scheme of the generated URI object will follow the incoming request
1447 however if your targeted action or action chain has the Scheme attribute it will
1448 use that instead.
1449
1450 Also, if the targeted Action or Action chain declares Args/CaptureArgs that have
1451 type constraints, we will require that your proposed URL verify on those declared
1452 constraints.
1453
1454 =cut
1455
1456 sub uri_for {
1457     my ( $c, $path, @args ) = @_;
1458
1459     if ( $path->$_isa('Catalyst::Controller') ) {
1460         $path = $path->path_prefix;
1461         $path =~ s{/+\z}{};
1462         $path .= '/';
1463     }
1464
1465     undef($path) if (defined $path && $path eq '');
1466
1467     my $params =
1468       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1469
1470     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1471
1472     my @encoded_args = ();
1473     foreach my $arg (@args) {
1474       if(ref($arg)||'' eq 'ARRAY') {
1475         push @encoded_args, [map {
1476           #   my $encoded = encode_utf8 $_;
1477           # $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1478           # $encoded;
1479           $_
1480         } @$arg];
1481       } else {
1482         push @encoded_args, do {
1483           #   my $encoded = encode_utf8 $arg;
1484           # $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1485           # $encoded;
1486           $arg;
1487         }
1488       }
1489     }
1490
1491     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1492     if ( $path->$_isa('Catalyst::Action') ) { # action object
1493         s|/|%2F|g for @encoded_args;
1494         my $captures = [ map { s|/|%2F|g; $_; }
1495                         ( scalar @encoded_args && ref $encoded_args[0] eq 'ARRAY'
1496                          ? @{ shift(@encoded_args) }
1497                          : ()) ];
1498
1499         my $action = $path;
1500         my $expanded_action = $c->dispatcher->expand_action( $action );
1501         my $num_captures = $expanded_action->number_of_captures;
1502
1503         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1504         if( !@encoded_args && $action->number_of_args ) {
1505           unshift @encoded_args, splice @$captures, $num_captures;
1506         }
1507
1508         if($num_captures) {
1509           unless($expanded_action->match_captures($c, $captures)) {
1510             carp "captures [@{$captures}] do not match the type constraints in actionchain ending with '$action'";
1511             return;
1512           }
1513         }
1514
1515         $path = $c->dispatcher->uri_for_action($action, $captures);
1516         if (not defined $path) {
1517             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1518                 if $c->debug;
1519             return undef;
1520         }
1521         $path = '/' if $path eq '';
1522
1523         # At this point @encoded_args is the remaining Args (all captures removed).
1524         if($expanded_action->has_args_constraints) {
1525           unless($expanded_action->match_args($c,\@encoded_args)) {
1526              carp "args [@encoded_args] do not match the type constraints in action '$expanded_action'";
1527              return;
1528           }
1529         }
1530     }
1531
1532     unshift(@encoded_args, $path);
1533
1534     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1535         my $namespace = $c->namespace;
1536         if (defined $path) { # cheesy hack to handle path '../foo'
1537            $namespace =~ s{(?:^|/)[^/]+$}{} while $encoded_args[0] =~ s{^\.\./}{};
1538         }
1539         unshift(@encoded_args, $namespace || '');
1540     }
1541
1542     # join args with '/', or a blank string
1543     my $args = join('/', grep { defined($_) } @encoded_args);
1544     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1545     $args =~ s!^/+!!;
1546
1547     my ($base, $class) = ('/', 'URI::_generic');
1548     if(blessed($c)) {
1549       $base = $c->req->base;
1550       if($target_action) {
1551         $target_action = $c->dispatcher->expand_action($target_action);
1552         if(my $s = $target_action->scheme) {
1553           $s = lc($s);
1554           $class = "URI::$s";
1555           $base->scheme($s);
1556         } else {
1557           $class = ref($base);
1558         }
1559       } else {
1560         $class = ref($base);
1561       }
1562
1563       $base =~ s{(?<!/)$}{/};
1564     }
1565
1566     my $query = '';
1567
1568     if (my @keys = keys %$params) {
1569       # somewhat lifted from URI::_query's query_form
1570       $query = '?'.join('&', map {
1571           my $val = $params->{$_};
1572           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1573           s/ /+/g;
1574           my $key = $_;
1575           $val = '' unless defined $val;
1576           (map {
1577               my $param = "$_";
1578               $param = encode_utf8($param);
1579               # using the URI::Escape pattern here so utf8 chars survive
1580               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1581               $param =~ s/ /+/g;
1582
1583               $key = encode_utf8($key);
1584               # using the URI::Escape pattern here so utf8 chars survive
1585               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1586               $key =~ s/ /+/g;
1587
1588               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1589       } @keys);
1590     }
1591
1592     $base = encode_utf8 $base;
1593     $base =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1594     $args = encode_utf8 $args;
1595     $args =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1596
1597     my $res = bless(\"${base}${args}${query}", $class);
1598     $res;
1599 }
1600
1601 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1602
1603 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1604
1605 =over
1606
1607 =item $path
1608
1609 A private path to the Catalyst action you want to create a URI for.
1610
1611 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1612 >> and passing the resulting C<$action> and the remaining arguments to C<<
1613 $c->uri_for >>.
1614
1615 You can also pass in a Catalyst::Action object, in which case it is passed to
1616 C<< $c->uri_for >>.
1617
1618 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1619
1620 For example, if the action looks like:
1621
1622  package MyApp::Controller::Users;
1623
1624  sub lst : Path('the-list') {}
1625
1626 You can use:
1627
1628  $c->uri_for_action('/users/lst')
1629
1630 and it will create the URI /users/the-list.
1631
1632 =item \@captures_and_args?
1633
1634 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1635 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1636 to interpolate all the parameters in the URI.
1637
1638 =item @args?
1639
1640 Optional list of extra arguments - can be supplied in the
1641 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1642 code.
1643
1644 Your action can have zero, a fixed or a variable number of args (e.g.
1645 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1646
1647 =item \%query_values?
1648
1649 Optional array reference of query parameters to append. E.g.
1650
1651   { foo => 'bar' }
1652
1653 will generate
1654
1655   /rest/of/your/uri?foo=bar
1656
1657 =back
1658
1659 =cut
1660
1661 sub uri_for_action {
1662     my ( $c, $path, @args ) = @_;
1663     my $action = blessed($path)
1664       ? $path
1665       : $c->dispatcher->get_action_by_path($path);
1666     unless (defined $action) {
1667       croak "Can't find action for path '$path'";
1668     }
1669     return $c->uri_for( $action, @args );
1670 }
1671
1672 =head2 $c->welcome_message
1673
1674 Returns the Catalyst welcome HTML page.
1675
1676 =cut
1677
1678 sub welcome_message {
1679     my $c      = shift;
1680     my $name   = $c->config->{name};
1681     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1682     my $prefix = Catalyst::Utils::appprefix( ref $c );
1683     $c->response->content_type('text/html; charset=utf-8');
1684     return <<"EOF";
1685 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1686     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1687 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1688     <head>
1689     <meta http-equiv="Content-Language" content="en" />
1690     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1691         <title>$name on Catalyst $VERSION</title>
1692         <style type="text/css">
1693             body {
1694                 color: #000;
1695                 background-color: #eee;
1696             }
1697             div#content {
1698                 width: 640px;
1699                 margin-left: auto;
1700                 margin-right: auto;
1701                 margin-top: 10px;
1702                 margin-bottom: 10px;
1703                 text-align: left;
1704                 background-color: #ccc;
1705                 border: 1px solid #aaa;
1706             }
1707             p, h1, h2 {
1708                 margin-left: 20px;
1709                 margin-right: 20px;
1710                 font-family: verdana, tahoma, sans-serif;
1711             }
1712             a {
1713                 font-family: verdana, tahoma, sans-serif;
1714             }
1715             :link, :visited {
1716                     text-decoration: none;
1717                     color: #b00;
1718                     border-bottom: 1px dotted #bbb;
1719             }
1720             :link:hover, :visited:hover {
1721                     color: #555;
1722             }
1723             div#topbar {
1724                 margin: 0px;
1725             }
1726             pre {
1727                 margin: 10px;
1728                 padding: 8px;
1729             }
1730             div#answers {
1731                 padding: 8px;
1732                 margin: 10px;
1733                 background-color: #fff;
1734                 border: 1px solid #aaa;
1735             }
1736             h1 {
1737                 font-size: 0.9em;
1738                 font-weight: normal;
1739                 text-align: center;
1740             }
1741             h2 {
1742                 font-size: 1.0em;
1743             }
1744             p {
1745                 font-size: 0.9em;
1746             }
1747             p img {
1748                 float: right;
1749                 margin-left: 10px;
1750             }
1751             span#appname {
1752                 font-weight: bold;
1753                 font-size: 1.6em;
1754             }
1755         </style>
1756     </head>
1757     <body>
1758         <div id="content">
1759             <div id="topbar">
1760                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1761                     $VERSION</h1>
1762              </div>
1763              <div id="answers">
1764                  <p>
1765                  <img src="$logo" alt="Catalyst Logo" />
1766                  </p>
1767                  <p>Welcome to the  world of Catalyst.
1768                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1769                     framework will make web development something you had
1770                     never expected it to be: Fun, rewarding, and quick.</p>
1771                  <h2>What to do now?</h2>
1772                  <p>That really depends  on what <b>you</b> want to do.
1773                     We do, however, provide you with a few starting points.</p>
1774                  <p>If you want to jump right into web development with Catalyst
1775                     you might want to start with a tutorial.</p>
1776 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1777 </pre>
1778 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1779 <pre>
1780 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1781 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1782 </code></pre>
1783                  <h2>What to do next?</h2>
1784                  <p>Next it's time to write an actual application. Use the
1785                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1786                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1787                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1788                     they can save you a lot of work.</p>
1789                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1790                     <p>Also, be sure to check out the vast and growing
1791                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1792                     you are likely to find what you need there.
1793                     </p>
1794
1795                  <h2>Need help?</h2>
1796                  <p>Catalyst has a very active community. Here are the main places to
1797                     get in touch with us.</p>
1798                  <ul>
1799                      <li>
1800                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1801                      </li>
1802                      <li>
1803                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1804                      </li>
1805                      <li>
1806                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1807                      </li>
1808                  </ul>
1809                  <h2>In conclusion</h2>
1810                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1811                     as we enjoyed making it. Please contact us if you have ideas
1812                     for improvement or other feedback.</p>
1813              </div>
1814          </div>
1815     </body>
1816 </html>
1817 EOF
1818 }
1819
1820 =head2 run_options
1821
1822 Contains a hash of options passed from the application script, including
1823 the original ARGV the script received, the processed values from that
1824 ARGV and any extra arguments to the script which were not processed.
1825
1826 This can be used to add custom options to your application's scripts
1827 and setup your application differently depending on the values of these
1828 options.
1829
1830 =head1 INTERNAL METHODS
1831
1832 These methods are not meant to be used by end users.
1833
1834 =head2 $c->components
1835
1836 Returns a hash of components.
1837
1838 =head2 $c->context_class
1839
1840 Returns or sets the context class.
1841
1842 =head2 $c->counter
1843
1844 Returns a hashref containing coderefs and execution counts (needed for
1845 deep recursion detection).
1846
1847 =head2 $c->depth
1848
1849 Returns the number of actions on the current internal execution stack.
1850
1851 =head2 $c->dispatch
1852
1853 Dispatches a request to actions.
1854
1855 =cut
1856
1857 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1858
1859 =head2 $c->dispatcher_class
1860
1861 Returns or sets the dispatcher class.
1862
1863 =head2 $c->dump_these
1864
1865 Returns a list of 2-element array references (name, structure) pairs
1866 that will be dumped on the error page in debug mode.
1867
1868 =cut
1869
1870 sub dump_these {
1871     my $c = shift;
1872     [ Request => $c->req ],
1873     [ Response => $c->res ],
1874     [ Stash => $c->stash ],
1875     [ Config => $c->config ];
1876 }
1877
1878 =head2 $c->engine_class
1879
1880 Returns or sets the engine class.
1881
1882 =head2 $c->execute( $class, $coderef )
1883
1884 Execute a coderef in given class and catch exceptions. Errors are available
1885 via $c->error.
1886
1887 =cut
1888
1889 sub execute {
1890     my ( $c, $class, $code ) = @_;
1891     $class = $c->component($class) || $class;
1892     $c->state(0);
1893
1894     if ( $c->depth >= $RECURSION ) {
1895         my $action = $code->reverse();
1896         $action = "/$action" unless $action =~ /->/;
1897         my $error = qq/Deep recursion detected calling "${action}"/;
1898         $c->log->error($error);
1899         $c->error($error);
1900         $c->state(0);
1901         return $c->state;
1902     }
1903
1904     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1905
1906     push( @{ $c->stack }, $code );
1907
1908     no warnings 'recursion';
1909     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1910     #      I have no idea how, ergo $ret (which appears to fix the issue)
1911     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1912
1913     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1914
1915     my $last = pop( @{ $c->stack } );
1916
1917     if ( my $error = $@ ) {
1918         #rethow if this can be handled by middleware
1919         if ( $c->_handle_http_exception($error) ) {
1920             foreach my $err (@{$c->error}) {
1921                 $c->log->error($err);
1922             }
1923             $c->clear_errors;
1924             $c->log->_flush if $c->log->can('_flush');
1925
1926             $error->can('rethrow') ? $error->rethrow : croak $error;
1927         }
1928         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1929             $error->rethrow if $c->depth > 1;
1930         }
1931         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1932             $error->rethrow if $c->depth > 0;
1933         }
1934         else {
1935             unless ( ref $error ) {
1936                 no warnings 'uninitialized';
1937                 chomp $error;
1938                 my $class = $last->class;
1939                 my $name  = $last->name;
1940                 $error = qq/Caught exception in $class->$name "$error"/;
1941             }
1942             $c->error($error);
1943         }
1944         $c->state(0);
1945     }
1946     return $c->state;
1947 }
1948
1949 sub _stats_start_execute {
1950     my ( $c, $code ) = @_;
1951     my $appclass = ref($c) || $c;
1952     return if ( ( $code->name =~ /^_.*/ )
1953         && ( !$appclass->config->{show_internal_actions} ) );
1954
1955     my $action_name = $code->reverse();
1956     $c->counter->{$action_name}++;
1957
1958     my $action = $action_name;
1959     $action = "/$action" unless $action =~ /->/;
1960
1961     # determine if the call was the result of a forward
1962     # this is done by walking up the call stack and looking for a calling
1963     # sub of Catalyst::forward before the eval
1964     my $callsub = q{};
1965     for my $index ( 2 .. 11 ) {
1966         last
1967         if ( ( caller($index) )[0] eq 'Catalyst'
1968             && ( caller($index) )[3] eq '(eval)' );
1969
1970         if ( ( caller($index) )[3] =~ /forward$/ ) {
1971             $callsub = ( caller($index) )[3];
1972             $action  = "-> $action";
1973             last;
1974         }
1975     }
1976
1977     my $uid = $action_name . $c->counter->{$action_name};
1978
1979     # is this a root-level call or a forwarded call?
1980     if ( $callsub =~ /forward$/ ) {
1981         my $parent = $c->stack->[-1];
1982
1983         # forward, locate the caller
1984         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1985             $c->stats->profile(
1986                 begin  => $action,
1987                 parent => "$parent" . $c->counter->{"$parent"},
1988                 uid    => $uid,
1989             );
1990         }
1991         else {
1992
1993             # forward with no caller may come from a plugin
1994             $c->stats->profile(
1995                 begin => $action,
1996                 uid   => $uid,
1997             );
1998         }
1999     }
2000     else {
2001
2002         # root-level call
2003         $c->stats->profile(
2004             begin => $action,
2005             uid   => $uid,
2006         );
2007     }
2008     return $action;
2009
2010 }
2011
2012 sub _stats_finish_execute {
2013     my ( $c, $info ) = @_;
2014     $c->stats->profile( end => $info );
2015 }
2016
2017 =head2 $c->finalize
2018
2019 Finalizes the request.
2020
2021 =cut
2022
2023 sub finalize {
2024     my $c = shift;
2025
2026     for my $error ( @{ $c->error } ) {
2027         $c->log->error($error);
2028     }
2029
2030     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
2031     # stuff like cometd and websockets
2032
2033     if($c->request->_has_io_fh) {
2034       $c->log_response;
2035       return;
2036     }
2037
2038     # Allow engine to handle finalize flow (for POE)
2039     my $engine = $c->engine;
2040     if ( my $code = $engine->can('finalize') ) {
2041         $engine->$code($c);
2042     }
2043     else {
2044
2045         $c->finalize_uploads;
2046
2047         # Error
2048         if ( $#{ $c->error } >= 0 ) {
2049             $c->finalize_error;
2050         }
2051
2052         $c->finalize_encoding;
2053         $c->finalize_headers unless $c->response->finalized_headers;
2054         $c->finalize_body;
2055     }
2056
2057     $c->log_response;
2058
2059     if ($c->use_stats) {
2060         my $elapsed = $c->stats->elapsed;
2061         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
2062         $c->log->info(
2063             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
2064     }
2065
2066     return $c->response->status;
2067 }
2068
2069 =head2 $c->finalize_body
2070
2071 Finalizes body.
2072
2073 =cut
2074
2075 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
2076
2077 =head2 $c->finalize_cookies
2078
2079 Finalizes cookies.
2080
2081 =cut
2082
2083 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
2084
2085 =head2 $c->finalize_error
2086
2087 Finalizes error.  If there is only one error in L</error> and it is an object that
2088 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2089 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2090 return the default error page (production mode).
2091
2092 =cut
2093
2094 sub finalize_error {
2095     my $c = shift;
2096     if($#{$c->error} > 0) {
2097         $c->engine->finalize_error( $c, @_ );
2098     } else {
2099         my ($error) = @{$c->error};
2100         if ( $c->_handle_http_exception($error) ) {
2101             # In the case where the error 'knows what it wants', becauses its PSGI
2102             # aware, just rethow and let middleware catch it
2103             $error->can('rethrow') ? $error->rethrow : croak $error;
2104         } else {
2105             $c->engine->finalize_error( $c, @_ )
2106         }
2107     }
2108 }
2109
2110 =head2 $c->finalize_headers
2111
2112 Finalizes headers.
2113
2114 =cut
2115
2116 sub finalize_headers {
2117     my $c = shift;
2118
2119     my $response = $c->response; #accessor calls can add up?
2120
2121     # Check if we already finalized headers
2122     return if $response->finalized_headers;
2123
2124     # Handle redirects
2125     if ( my $location = $response->redirect ) {
2126         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2127         $response->header( Location => $location );
2128     }
2129
2130     # Remove incorrectly added body and content related meta data when returning
2131     # an information response, or a response the is required to not include a body
2132
2133     $c->finalize_cookies;
2134
2135     # This currently is a NOOP but I don't want to remove it since I guess people
2136     # might have Response subclasses that use it for something... (JNAP)
2137     $c->response->finalize_headers();
2138
2139     # Done
2140     $response->finalized_headers(1);
2141 }
2142
2143 =head2 $c->finalize_encoding
2144
2145 Make sure your body is encoded properly IF you set an encoding.  By
2146 default the encoding is UTF-8 but you can disable it by explicitly setting the
2147 encoding configuration value to undef.
2148
2149 We can only encode when the body is a scalar.  Methods for encoding via the
2150 streaming interfaces (such as C<write> and C<write_fh> on L<Catalyst::Response>
2151 are available).
2152
2153 See L</ENCODING>.
2154
2155 =cut
2156
2157 sub finalize_encoding {
2158     my $c = shift;
2159     my $res = $c->res || return;
2160
2161     # Warn if the set charset is different from the one you put into encoding.  We need
2162     # to do this early since encodable_response is false for this condition and we need
2163     # to match the debug output for backcompat (there's a test for this...) -JNAP
2164     if(
2165       $res->content_type_charset and $c->encoding and
2166       (uc($c->encoding->mime_name) ne uc($res->content_type_charset))
2167     ) {
2168         my $ct = lc($res->content_type_charset);
2169         $c->log->debug("Catalyst encoding config is set to encode in '" .
2170             $c->encoding->mime_name .
2171             "', content type is '$ct', not encoding ");
2172     }
2173
2174     if(
2175       ($res->encodable_response) and
2176       (defined($res->body)) and
2177       (ref(\$res->body) eq 'SCALAR')
2178     ) {
2179         $c->res->body( $c->encoding->encode( $c->res->body, $c->_encode_check ) );
2180
2181         # Set the charset if necessary.  This might be a bit bonkers since encodable response
2182         # is false when the set charset is not the same as the encoding mimetype (maybe
2183         # confusing action at a distance here..
2184         # Don't try to set the charset if one already exists
2185         $c->res->content_type($c->res->content_type . "; charset=" . $c->encoding->mime_name)
2186           unless($c->res->content_type_charset);
2187     }
2188 }
2189
2190 =head2 $c->finalize_output
2191
2192 An alias for finalize_body.
2193
2194 =head2 $c->finalize_read
2195
2196 Finalizes the input after reading is complete.
2197
2198 =cut
2199
2200 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2201
2202 =head2 $c->finalize_uploads
2203
2204 Finalizes uploads. Cleans up any temporary files.
2205
2206 =cut
2207
2208 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2209
2210 =head2 $c->get_action( $action, $namespace )
2211
2212 Gets an action in a given namespace.
2213
2214 =cut
2215
2216 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2217
2218 =head2 $c->get_actions( $action, $namespace )
2219
2220 Gets all actions of a given name in a namespace and all parent
2221 namespaces.
2222
2223 =cut
2224
2225 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2226
2227 =head2 $app->handle_request( @arguments )
2228
2229 Called to handle each HTTP request.
2230
2231 =cut
2232
2233 sub handle_request {
2234     my ( $class, @arguments ) = @_;
2235
2236     # Always expect worst case!
2237     my $status = -1;
2238     try {
2239         if ($class->debug) {
2240             my $secs = time - $START || 1;
2241             my $av = sprintf '%.3f', $COUNT / $secs;
2242             my $time = localtime time;
2243             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2244         }
2245
2246         my $c = $class->prepare(@arguments);
2247         $c->dispatch;
2248         $status = $c->finalize;
2249     } catch {
2250         #rethow if this can be handled by middleware
2251         if ( $class->_handle_http_exception($_) ) {
2252             $_->can('rethrow') ? $_->rethrow : croak $_;
2253         }
2254         chomp(my $error = $_);
2255         $class->log->error(qq/Caught exception in engine "$error"/);
2256     };
2257
2258     $COUNT++;
2259
2260     if(my $coderef = $class->log->can('_flush')){
2261         $class->log->$coderef();
2262     }
2263     return $status;
2264 }
2265
2266 =head2 $class->prepare( @arguments )
2267
2268 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2269 etc.).
2270
2271 =cut
2272
2273 has _uploadtmp => (
2274     is => 'ro',
2275     predicate => '_has_uploadtmp',
2276 );
2277
2278 sub prepare {
2279     my ( $class, @arguments ) = @_;
2280
2281     # XXX
2282     # After the app/ctxt split, this should become an attribute based on something passed
2283     # into the application.
2284     $class->context_class( ref $class || $class ) unless $class->context_class;
2285
2286     my $uploadtmp = $class->config->{uploadtmp};
2287     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2288
2289     $c->response->_context($c);
2290
2291     #surely this is not the most efficient way to do things...
2292     $c->stats($class->stats_class->new)->enable($c->use_stats);
2293     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2294         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2295     }
2296
2297     try {
2298         # Allow engine to direct the prepare flow (for POE)
2299         if ( my $prepare = $c->engine->can('prepare') ) {
2300             $c->engine->$prepare( $c, @arguments );
2301         }
2302         else {
2303             $c->prepare_request(@arguments);
2304             $c->prepare_connection;
2305             $c->prepare_query_parameters;
2306             $c->prepare_headers; # Just hooks, no longer needed - they just
2307             $c->prepare_cookies; # cause the lazy attribute on req to build
2308             $c->prepare_path;
2309
2310             # Prepare the body for reading, either by prepare_body
2311             # or the user, if they are using $c->read
2312             $c->prepare_read;
2313
2314             # Parse the body unless the user wants it on-demand
2315             unless ( ref($c)->config->{parse_on_demand} ) {
2316                 $c->prepare_body;
2317             }
2318         }
2319         $c->prepare_action;
2320     }
2321     # VERY ugly and probably shouldn't rely on ->finalize actually working
2322     catch {
2323         # failed prepare is always due to an invalid request, right?
2324         $c->response->status(400);
2325         $c->response->content_type('text/plain');
2326         $c->response->body('Bad Request');
2327         # Note we call finalize and then die here, which escapes
2328         # finalize being called in the enclosing block..
2329         # It in fact couldn't be called, as we don't return $c..
2330         # This is a mess - but I'm unsure you can fix this without
2331         # breaking compat for people doing crazy things (we should set
2332         # the 400 and just return the ctx here IMO, letting finalize get called
2333         # above...
2334         $c->finalize;
2335         die $_;
2336     };
2337
2338     $c->log_request;
2339
2340     return $c;
2341 }
2342
2343 =head2 $c->prepare_action
2344
2345 Prepares action. See L<Catalyst::Dispatcher>.
2346
2347 =cut
2348
2349 sub prepare_action {
2350     my $c = shift;
2351     my $ret = $c->dispatcher->prepare_action( $c, @_);
2352
2353     if($c->encoding) {
2354         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2355           $_ = $c->_handle_param_unicode_decoding($_);
2356         }
2357     }
2358
2359     return $ret;
2360 }
2361
2362
2363 =head2 $c->prepare_body
2364
2365 Prepares message body.
2366
2367 =cut
2368
2369 sub prepare_body {
2370     my $c = shift;
2371
2372     return if $c->request->_has_body;
2373
2374     # Initialize on-demand data
2375     $c->engine->prepare_body( $c, @_ );
2376     $c->prepare_parameters;
2377     $c->prepare_uploads;
2378 }
2379
2380 =head2 $c->prepare_body_chunk( $chunk )
2381
2382 Prepares a chunk of data before sending it to L<HTTP::Body>.
2383
2384 See L<Catalyst::Engine>.
2385
2386 =cut
2387
2388 sub prepare_body_chunk {
2389     my $c = shift;
2390     $c->engine->prepare_body_chunk( $c, @_ );
2391 }
2392
2393 =head2 $c->prepare_body_parameters
2394
2395 Prepares body parameters.
2396
2397 =cut
2398
2399 sub prepare_body_parameters {
2400     my $c = shift;
2401     $c->request->prepare_body_parameters( $c, @_ );
2402 }
2403
2404 =head2 $c->prepare_connection
2405
2406 Prepares connection.
2407
2408 =cut
2409
2410 sub prepare_connection {
2411     my $c = shift;
2412     $c->request->prepare_connection($c);
2413 }
2414
2415 =head2 $c->prepare_cookies
2416
2417 Prepares cookies by ensuring that the attribute on the request
2418 object has been built.
2419
2420 =cut
2421
2422 sub prepare_cookies { my $c = shift; $c->request->cookies }
2423
2424 =head2 $c->prepare_headers
2425
2426 Prepares request headers by ensuring that the attribute on the request
2427 object has been built.
2428
2429 =cut
2430
2431 sub prepare_headers { my $c = shift; $c->request->headers }
2432
2433 =head2 $c->prepare_parameters
2434
2435 Prepares parameters.
2436
2437 =cut
2438
2439 sub prepare_parameters {
2440     my $c = shift;
2441     $c->prepare_body_parameters;
2442     $c->engine->prepare_parameters( $c, @_ );
2443 }
2444
2445 =head2 $c->prepare_path
2446
2447 Prepares path and base.
2448
2449 =cut
2450
2451 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2452
2453 =head2 $c->prepare_query_parameters
2454
2455 Prepares query parameters.
2456
2457 =cut
2458
2459 sub prepare_query_parameters {
2460     my $c = shift;
2461
2462     $c->engine->prepare_query_parameters( $c, @_ );
2463 }
2464
2465 =head2 $c->log_request
2466
2467 Writes information about the request to the debug logs.  This includes:
2468
2469 =over 4
2470
2471 =item * Request method, path, and remote IP address
2472
2473 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2474
2475 =item * Request parameters
2476
2477 =item * File uploads
2478
2479 =back
2480
2481 =cut
2482
2483 sub log_request {
2484     my $c = shift;
2485
2486     return unless $c->debug;
2487
2488     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2489     my $request = $dump->[1];
2490
2491     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2492     $method ||= '';
2493     $path = '/' unless length $path;
2494     $address ||= '';
2495
2496     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2497     $path = decode_utf8($path);
2498
2499     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2500
2501     $c->log_request_headers($request->headers);
2502
2503     if ( my $keywords = $request->query_keywords ) {
2504         $c->log->debug("Query keywords are: $keywords");
2505     }
2506
2507     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2508
2509     $c->log_request_uploads($request);
2510 }
2511
2512 =head2 $c->log_response
2513
2514 Writes information about the response to the debug logs by calling
2515 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2516
2517 =cut
2518
2519 sub log_response {
2520     my $c = shift;
2521
2522     return unless $c->debug;
2523
2524     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2525     my $response = $dump->[1];
2526
2527     $c->log_response_status_line($response);
2528     $c->log_response_headers($response->headers);
2529 }
2530
2531 =head2 $c->log_response_status_line($response)
2532
2533 Writes one line of information about the response to the debug logs.  This includes:
2534
2535 =over 4
2536
2537 =item * Response status code
2538
2539 =item * Content-Type header (if present)
2540
2541 =item * Content-Length header (if present)
2542
2543 =back
2544
2545 =cut
2546
2547 sub log_response_status_line {
2548     my ($c, $response) = @_;
2549
2550     $c->log->debug(
2551         sprintf(
2552             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2553             $response->status                            || 'unknown',
2554             $response->headers->header('Content-Type')   || 'unknown',
2555             $response->headers->header('Content-Length') || 'unknown'
2556         )
2557     );
2558 }
2559
2560 =head2 $c->log_response_headers($headers);
2561
2562 Hook method which can be wrapped by plugins to log the response headers.
2563 No-op in the default implementation.
2564
2565 =cut
2566
2567 sub log_response_headers {}
2568
2569 =head2 $c->log_request_parameters( query => {}, body => {} )
2570
2571 Logs request parameters to debug logs
2572
2573 =cut
2574
2575 sub log_request_parameters {
2576     my $c          = shift;
2577     my %all_params = @_;
2578
2579     return unless $c->debug;
2580
2581     my $column_width = Catalyst::Utils::term_width() - 44;
2582     foreach my $type (qw(query body)) {
2583         my $params = $all_params{$type};
2584         next if ! keys %$params;
2585         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2586         for my $key ( sort keys %$params ) {
2587             my $param = $params->{$key};
2588             my $value = defined($param) ? $param : '';
2589             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2590         }
2591         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2592     }
2593 }
2594
2595 =head2 $c->log_request_uploads
2596
2597 Logs file uploads included in the request to the debug logs.
2598 The parameter name, filename, file type, and file size are all included in
2599 the debug logs.
2600
2601 =cut
2602
2603 sub log_request_uploads {
2604     my $c = shift;
2605     my $request = shift;
2606     return unless $c->debug;
2607     my $uploads = $request->uploads;
2608     if ( keys %$uploads ) {
2609         my $t = Text::SimpleTable->new(
2610             [ 12, 'Parameter' ],
2611             [ 26, 'Filename' ],
2612             [ 18, 'Type' ],
2613             [ 9,  'Size' ]
2614         );
2615         for my $key ( sort keys %$uploads ) {
2616             my $upload = $uploads->{$key};
2617             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2618                 $t->row( $key, $u->filename, $u->type, $u->size );
2619             }
2620         }
2621         $c->log->debug( "File Uploads are:\n" . $t->draw );
2622     }
2623 }
2624
2625 =head2 $c->log_request_headers($headers);
2626
2627 Hook method which can be wrapped by plugins to log the request headers.
2628 No-op in the default implementation.
2629
2630 =cut
2631
2632 sub log_request_headers {}
2633
2634 =head2 $c->log_headers($type => $headers)
2635
2636 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2637
2638 =cut
2639
2640 sub log_headers {
2641     my $c       = shift;
2642     my $type    = shift;
2643     my $headers = shift;    # an HTTP::Headers instance
2644
2645     return unless $c->debug;
2646
2647     my $column_width = Catalyst::Utils::term_width() - 28;
2648     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2649     $headers->scan(
2650         sub {
2651             my ( $name, $value ) = @_;
2652             $t->row( $name, $value );
2653         }
2654     );
2655     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2656 }
2657
2658
2659 =head2 $c->prepare_read
2660
2661 Prepares the input for reading.
2662
2663 =cut
2664
2665 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2666
2667 =head2 $c->prepare_request
2668
2669 Prepares the engine request.
2670
2671 =cut
2672
2673 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2674
2675 =head2 $c->prepare_uploads
2676
2677 Prepares uploads.
2678
2679 =cut
2680
2681 sub prepare_uploads {
2682     my $c = shift;
2683     $c->engine->prepare_uploads( $c, @_ );
2684 }
2685
2686 =head2 $c->prepare_write
2687
2688 Prepares the output for writing.
2689
2690 =cut
2691
2692 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2693
2694 =head2 $c->request_class
2695
2696 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2697
2698 =head2 $c->response_class
2699
2700 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2701
2702 =head2 $c->read( [$maxlength] )
2703
2704 Reads a chunk of data from the request body. This method is designed to
2705 be used in a while loop, reading C<$maxlength> bytes on every call.
2706 C<$maxlength> defaults to the size of the request if not specified.
2707
2708 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2709 directly.
2710
2711 Warning: If you use read(), Catalyst will not process the body,
2712 so you will not be able to access POST parameters or file uploads via
2713 $c->request.  You must handle all body parsing yourself.
2714
2715 =cut
2716
2717 sub read { my $c = shift; return $c->request->read( @_ ) }
2718
2719 =head2 $c->run
2720
2721 Starts the engine.
2722
2723 =cut
2724
2725 sub run {
2726   my $app = shift;
2727   $app->_make_immutable_if_needed;
2728   $app->engine_loader->needs_psgi_engine_compat_hack ?
2729     $app->engine->run($app, @_) :
2730       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2731 }
2732
2733 sub _make_immutable_if_needed {
2734     my $class = shift;
2735     my $meta = find_meta($class);
2736     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2737     if (
2738         $meta->is_immutable
2739         && ! { $meta->immutable_options }->{replace_constructor}
2740         && $isa_ca
2741     ) {
2742         warn("You made your application class ($class) immutable, "
2743             . "but did not inline the\nconstructor. "
2744             . "This will break catalyst, as your app \@ISA "
2745             . "Class::Accessor(::Fast)?\nPlease pass "
2746             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2747     }
2748     unless ($meta->is_immutable) {
2749         # XXX - FIXME warning here as you should make your app immutable yourself.
2750         $meta->make_immutable(
2751             replace_constructor => 1,
2752         );
2753     }
2754 }
2755
2756 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2757
2758 Sets an action in a given namespace.
2759
2760 =cut
2761
2762 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2763
2764 =head2 $c->setup_actions($component)
2765
2766 Sets up actions for a component.
2767
2768 =cut
2769
2770 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2771
2772 =head2 $c->setup_components
2773
2774 This method is called internally to set up the application's components.
2775
2776 It finds modules by calling the L<locate_components> method, expands them to
2777 package names with the L<expand_component_module> method, and then installs
2778 each component into the application.
2779
2780 The C<setup_components> config option is passed to both of the above methods.
2781
2782 Installation of each component is performed by the L<setup_component> method,
2783 below.
2784
2785 =cut
2786
2787 sub setup_components {
2788     my $class = shift;
2789
2790     my $config  = $class->config->{ setup_components };
2791
2792     my @comps = $class->locate_components($config);
2793     my %comps = map { $_ => 1 } @comps;
2794
2795     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2796     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2797         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2798     ) if $deprecatedcatalyst_component_names;
2799
2800     for my $component ( @comps ) {
2801
2802         # We pass ignore_loaded here so that overlay files for (e.g.)
2803         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2804         # we know M::P::O found a file on disk so this is safe
2805
2806         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2807     }
2808
2809     for my $component (@comps) {
2810         my $instance = $class->components->{ $component } = $class->setup_component($component);
2811         my @expanded_components = $instance->can('expand_modules')
2812             ? $instance->expand_modules( $component, $config )
2813             : $class->expand_component_module( $component, $config );
2814         for my $component (@expanded_components) {
2815             next if $comps{$component};
2816             $class->components->{ $component } = $class->setup_component($component);
2817         }
2818     }
2819 }
2820
2821 =head2 $c->locate_components( $setup_component_config )
2822
2823 This method is meant to provide a list of component modules that should be
2824 setup for the application.  By default, it will use L<Module::Pluggable>.
2825
2826 Specify a C<setup_components> config option to pass additional options directly
2827 to L<Module::Pluggable>. To add additional search paths, specify a key named
2828 C<search_extra> as an array reference. Items in the array beginning with C<::>
2829 will have the application class name prepended to them.
2830
2831 =cut
2832
2833 sub locate_components {
2834     my $class  = shift;
2835     my $config = shift;
2836
2837     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
2838     my $extra   = delete $config->{ search_extra } || [];
2839
2840     unshift @paths, @$extra;
2841
2842     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
2843       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
2844       %$config
2845     )->plugins } @paths;
2846
2847     return @comps;
2848 }
2849
2850 =head2 $c->expand_component_module( $component, $setup_component_config )
2851
2852 Components found by C<locate_components> will be passed to this method, which
2853 is expected to return a list of component (package) names to be set up.
2854
2855 =cut
2856
2857 sub expand_component_module {
2858     my ($class, $module) = @_;
2859     return Devel::InnerPackage::list_packages( $module );
2860 }
2861
2862 =head2 $c->setup_component
2863
2864 =cut
2865
2866 sub setup_component {
2867     my( $class, $component ) = @_;
2868
2869     unless ( $component->can( 'COMPONENT' ) ) {
2870         return $component;
2871     }
2872
2873     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2874     my $config = $class->config->{ $suffix } || {};
2875     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2876     # methods also pass it. local to avoid pointlessly shitting in config
2877     # for the debug screen, as $component is already the key name.
2878     local $config->{catalyst_component_name} = $component;
2879
2880     my $instance = eval { $component->COMPONENT( $class, $config ); };
2881
2882     if ( my $error = $@ ) {
2883         chomp $error;
2884         Catalyst::Exception->throw(
2885             message => qq/Couldn't instantiate component "$component", "$error"/
2886         );
2887     }
2888
2889     unless (blessed $instance) {
2890         my $metaclass = Moose::Util::find_meta($component);
2891         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2892         my $component_method_from = $method_meta->associated_metaclass->name;
2893         my $value = defined($instance) ? $instance : 'undef';
2894         Catalyst::Exception->throw(
2895             message =>
2896             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2897         );
2898     }
2899     return $instance;
2900 }
2901
2902 =head2 $c->setup_dispatcher
2903
2904 Sets up dispatcher.
2905
2906 =cut
2907
2908 sub setup_dispatcher {
2909     my ( $class, $dispatcher ) = @_;
2910
2911     if ($dispatcher) {
2912         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2913     }
2914
2915     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2916         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2917     }
2918
2919     unless ($dispatcher) {
2920         $dispatcher = $class->dispatcher_class;
2921     }
2922
2923     load_class($dispatcher);
2924
2925     # dispatcher instance
2926     $class->dispatcher( $dispatcher->new );
2927 }
2928
2929 =head2 $c->setup_engine
2930
2931 Sets up engine.
2932
2933 =cut
2934
2935 sub engine_class {
2936     my ($class, $requested_engine) = @_;
2937
2938     if (!$class->engine_loader || $requested_engine) {
2939         $class->engine_loader(
2940             Catalyst::EngineLoader->new({
2941                 application_name => $class,
2942                 (defined $requested_engine
2943                      ? (catalyst_engine_class => $requested_engine) : ()),
2944             }),
2945         );
2946     }
2947
2948     $class->engine_loader->catalyst_engine_class;
2949 }
2950
2951 sub setup_engine {
2952     my ($class, $requested_engine) = @_;
2953
2954     my $engine = do {
2955         my $loader = $class->engine_loader;
2956
2957         if (!$loader || $requested_engine) {
2958             $loader = Catalyst::EngineLoader->new({
2959                 application_name => $class,
2960                 (defined $requested_engine
2961                      ? (requested_engine => $requested_engine) : ()),
2962             }),
2963
2964             $class->engine_loader($loader);
2965         }
2966
2967         $loader->catalyst_engine_class;
2968     };
2969
2970     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2971     return if $class->loading_psgi_file;
2972
2973     load_class($engine);
2974
2975     if ($ENV{MOD_PERL}) {
2976         my $apache = $class->engine_loader->auto;
2977
2978         my $meta = find_meta($class);
2979         my $was_immutable = $meta->is_immutable;
2980         my %immutable_options = $meta->immutable_options;
2981         $meta->make_mutable if $was_immutable;
2982
2983         $meta->add_method(handler => sub {
2984             my $r = shift;
2985             my $psgi_app = $class->_finalized_psgi_app;
2986             $apache->call_app($r, $psgi_app);
2987         });
2988
2989         $meta->make_immutable(%immutable_options) if $was_immutable;
2990     }
2991
2992     $class->engine( $engine->new );
2993
2994     return;
2995 }
2996
2997 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2998 ## build in server support (back compat support for pre psgi port behavior).
2999 ## This is so that we don't build a new psgi app for each request when using
3000 ## the mod_perl handler or the built in servers (http and fcgi, etc).
3001
3002 sub _finalized_psgi_app {
3003     my ($app) = @_;
3004
3005     unless ($app->_psgi_app) {
3006         my $psgi_app = $app->_setup_psgi_app;
3007         $app->_psgi_app($psgi_app);
3008     }
3009
3010     return $app->_psgi_app;
3011 }
3012
3013 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
3014 ## home directory and load that and return it (just assume it is doing the
3015 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
3016 ## in default_middleware and return it ( this is for backward compatibility
3017 ## with pre psgi port behavior ).
3018
3019 sub _setup_psgi_app {
3020     my ($app) = @_;
3021
3022     for my $home (Path::Class::Dir->new($app->config->{home})) {
3023         my $psgi_file = $home->file(
3024             Catalyst::Utils::appprefix($app) . '.psgi',
3025         );
3026
3027         next unless -e $psgi_file;
3028
3029         # If $psgi_file calls ->setup_engine, it's doing so to load
3030         # Catalyst::Engine::PSGI. But if it does that, we're only going to
3031         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
3032         # anyway. So set a flag (ick) that tells setup_engine not to populate
3033         # $c->engine or do any other things we might regret.
3034
3035         $app->loading_psgi_file(1);
3036         my $psgi_app = Plack::Util::load_psgi($psgi_file);
3037         $app->loading_psgi_file(0);
3038
3039         return $psgi_app
3040             unless $app->engine_loader->needs_psgi_engine_compat_hack;
3041
3042         warn <<"EOW";
3043 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
3044
3045 Its content has been ignored. Please consult the Catalyst::Upgrading
3046 documentation on how to upgrade from Catalyst::Engine::PSGI.
3047 EOW
3048     }
3049
3050     return $app->apply_default_middlewares($app->psgi_app);
3051 }
3052
3053 =head2 $c->apply_default_middlewares
3054
3055 Adds the following L<Plack> middlewares to your application, since they are
3056 useful and commonly needed:
3057
3058 L<Plack::Middleware::LighttpdScriptNameFix> (if you are using Lighttpd),
3059 L<Plack::Middleware::IIS6ScriptNameFix> (always applied since this middleware
3060 is smart enough to conditionally apply itself).
3061
3062 We will also automatically add L<Plack::Middleware::ReverseProxy> if we notice
3063 that your HTTP $env variable C<REMOTE_ADDR> is '127.0.0.1'.  This is usually
3064 an indication that your server is running behind a proxy frontend.  However in
3065 2014 this is often not the case.  We preserve this code for backwards compatibility
3066 however I B<highly> recommend that if you are running the server behind a front
3067 end proxy that you clearly indicate so with the C<using_frontend_proxy> configuration
3068 setting to true for your environment configurations that run behind a proxy.  This
3069 way if you change your front end proxy address someday your code would inexplicably
3070 stop working as expected.
3071
3072 Additionally if we detect we are using Nginx, we add a bit of custom middleware
3073 to solve some problems with the way that server handles $ENV{PATH_INFO} and
3074 $ENV{SCRIPT_NAME}.
3075
3076 Please B<NOTE> that if you do use C<using_frontend_proxy> the middleware is now
3077 adding via C<registered_middleware> rather than this method.
3078
3079 If you are using Lighttpd or IIS6 you may wish to apply these middlewares.  In
3080 general this is no longer a common case but we have this here for backward
3081 compatibility.
3082
3083 =cut
3084
3085
3086 sub apply_default_middlewares {
3087     my ($app, $psgi_app) = @_;
3088
3089     # Don't add this conditional IF we are explicitly saying we want the
3090     # frontend proxy support.  We don't need it here since if that is the
3091     # case it will be always loaded in the default_middleware.
3092
3093     unless($app->config->{using_frontend_proxy}) {
3094       $psgi_app = Plack::Middleware::Conditional->wrap(
3095           $psgi_app,
3096           builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
3097           condition => sub {
3098               my ($env) = @_;
3099               return if $app->config->{ignore_frontend_proxy};
3100               return $env->{REMOTE_ADDR} eq '127.0.0.1';
3101           },
3102       );
3103     }
3104
3105     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3106     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3107     $psgi_app = Plack::Middleware::Conditional->wrap(
3108         $psgi_app,
3109         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3110         condition => sub {
3111             my ($env) = @_;
3112             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3113             return unless $1 < 4.23;
3114             1;
3115         },
3116     );
3117
3118     # we're applying this unconditionally as the middleware itself already makes
3119     # sure it doesn't fuck things up if it's not running under one of the right
3120     # IIS versions
3121     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3122
3123     # And another IIS issue, this time with IIS7.
3124     $psgi_app = Plack::Middleware::Conditional->wrap(
3125         $psgi_app,
3126         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3127         condition => sub {
3128             my ($env) = @_;
3129             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3130         },
3131     );
3132
3133     return $psgi_app;
3134 }
3135
3136 =head2 App->psgi_app
3137
3138 =head2 App->to_app
3139
3140 Returns a PSGI application code reference for the catalyst application
3141 C<$c>. This is the bare application created without the C<apply_default_middlewares>
3142 method called.  We do however apply C<registered_middleware> since those are
3143 integral to how L<Catalyst> functions.  Also, unlike starting your application
3144 with a generated server script (via L<Catalyst::Devel> and C<catalyst.pl>) we do
3145 not attempt to return a valid L<PSGI> application using any existing C<${myapp}.psgi>
3146 scripts in your $HOME directory.
3147
3148 B<NOTE> C<apply_default_middlewares> was originally created when the first PSGI
3149 port was done for v5.90000.  These are middlewares that are added to achieve
3150 backward compatibility with older applications.  If you start your application
3151 using one of the supplied server scripts (generated with L<Catalyst::Devel> and
3152 the project skeleton script C<catalyst.pl>) we apply C<apply_default_middlewares>
3153 automatically.  This was done so that pre and post PSGI port applications would
3154 work the same way.
3155
3156 This is what you want to be using to retrieve the PSGI application code
3157 reference of your Catalyst application for use in a custom F<.psgi> or in your
3158 own created server modules.
3159
3160 =cut
3161
3162 *to_app = \&psgi_app;
3163
3164 sub psgi_app {
3165     my ($app) = @_;
3166     my $psgi = $app->engine->build_psgi_app($app);
3167     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3168 }
3169
3170 =head2 $c->setup_home
3171
3172 Sets up the home directory.
3173
3174 =cut
3175
3176 sub setup_home {
3177     my ( $class, $home ) = @_;
3178
3179     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3180         $home = $env;
3181     }
3182
3183     $home ||= Catalyst::Utils::home($class);
3184
3185     if ($home) {
3186         #I remember recently being scolded for assigning config values like this
3187         $class->config->{home} ||= $home;
3188         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3189     }
3190 }
3191
3192 =head2 $c->setup_encoding
3193
3194 Sets up the input/output encoding. See L<ENCODING>
3195
3196 =cut
3197
3198 sub setup_encoding {
3199     my $c = shift;
3200     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3201         # Ok, so the user has explicitly said "I don't want encoding..."
3202         return;
3203     } else {
3204       my $enc = defined($c->config->{encoding}) ?
3205         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3206       $c->encoding($enc);
3207     }
3208 }
3209
3210 =head2 handle_unicode_encoding_exception
3211
3212 Hook to let you customize how encoding errors are handled.  By default
3213 we just throw an exception.  Receives a hashref of debug information.
3214 Example:
3215
3216     $c->handle_unicode_encoding_exception({
3217         param_value => $value,
3218         error_msg => $_,
3219             encoding_step => 'params',
3220         });
3221
3222 =cut
3223
3224 sub handle_unicode_encoding_exception {
3225     my ( $self, $exception_ctx ) = @_;
3226     die $exception_ctx->{error_msg};
3227 }
3228
3229 # Some unicode helpers cargo culted from the old plugin.  These could likely
3230 # be neater.
3231
3232 sub _handle_unicode_decoding {
3233     my ( $self, $value ) = @_;
3234
3235     return unless defined $value;
3236
3237     ## I think this mess is to support the old nested
3238     if ( ref $value eq 'ARRAY' ) {
3239         foreach ( @$value ) {
3240             $_ = $self->_handle_unicode_decoding($_);
3241         }
3242         return $value;
3243     }
3244     elsif ( ref $value eq 'HASH' ) {
3245         foreach (keys %$value) {
3246             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3247             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3248
3249             # If the key was encoded we now have two (the original and current so
3250             # delete the original.
3251             delete $value->{$_} if $_ ne $encoded_key;
3252         }
3253         return $value;
3254     }
3255     else {
3256         return $self->_handle_param_unicode_decoding($value);
3257     }
3258 }
3259
3260 sub _handle_param_unicode_decoding {
3261     my ( $self, $value ) = @_;
3262     return unless defined $value; # not in love with just ignoring undefs - jnap
3263     return $value if blessed($value); #don't decode when the value is an object.
3264
3265     my $enc = $self->encoding;
3266     return try {
3267       $enc->decode( $value, $self->_encode_check );
3268     }
3269     catch {
3270         $self->handle_unicode_encoding_exception({
3271             param_value => $value,
3272             error_msg => $_,
3273             encoding_step => 'params',
3274         });
3275     };
3276 }
3277
3278 =head2 $c->setup_log
3279
3280 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3281 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3282 log to.
3283
3284 This method also installs a C<debug> method that returns a true value into the
3285 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3286 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3287
3288 Note that if the log has already been setup, by either a previous call to
3289 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3290 that this method won't actually set up the log object.
3291
3292 =cut
3293
3294 sub setup_log {
3295     my ( $class, $levels ) = @_;
3296
3297     $levels ||= '';
3298     $levels =~ s/^\s+//;
3299     $levels =~ s/\s+$//;
3300     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3301
3302     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3303     if ( defined $env_debug ) {
3304         $levels{debug} = 1 if $env_debug; # Ugly!
3305         delete($levels{debug}) unless $env_debug;
3306     }
3307
3308     unless ( $class->log ) {
3309         $class->log( Catalyst::Log->new(keys %levels) );
3310     }
3311
3312     if ( $levels{debug} ) {
3313         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3314         $class->log->debug('Debug messages enabled');
3315     }
3316 }
3317
3318 =head2 $c->setup_plugins
3319
3320 Sets up plugins.
3321
3322 =cut
3323
3324 =head2 $c->setup_stats
3325
3326 Sets up timing statistics class.
3327
3328 =cut
3329
3330 sub setup_stats {
3331     my ( $class, $stats ) = @_;
3332
3333     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3334
3335     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3336     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3337         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3338         $class->log->debug('Statistics enabled');
3339     }
3340 }
3341
3342
3343 =head2 $c->registered_plugins
3344
3345 Returns a sorted list of the plugins which have either been stated in the
3346 import list.
3347
3348 If passed a given plugin name, it will report a boolean value indicating
3349 whether or not that plugin is loaded.  A fully qualified name is required if
3350 the plugin name does not begin with C<Catalyst::Plugin::>.
3351
3352  if ($c->registered_plugins('Some::Plugin')) {
3353      ...
3354  }
3355
3356 =cut
3357
3358 {
3359
3360     sub registered_plugins {
3361         my $proto = shift;
3362         return sort keys %{ $proto->_plugins } unless @_;
3363         my $plugin = shift;
3364         return 1 if exists $proto->_plugins->{$plugin};
3365         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3366     }
3367
3368     sub _register_plugin {
3369         my ( $proto, $plugin, $instant ) = @_;
3370         my $class = ref $proto || $proto;
3371
3372         load_class( $plugin );
3373         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3374             if $plugin->isa( 'Catalyst::Component' );
3375         my $plugin_meta = Moose::Meta::Class->create($plugin);
3376         if (!$plugin_meta->has_method('new')
3377             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3378             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3379         }
3380         if (!$instant && !$proto->_plugins->{$plugin}) {
3381             my $meta = Class::MOP::get_metaclass_by_name($class);
3382             $meta->superclasses($plugin, $meta->superclasses);
3383         }
3384         $proto->_plugins->{$plugin} = 1;
3385         return $class;
3386     }
3387
3388     sub _default_plugins { return qw() }
3389
3390     sub setup_plugins {
3391         my ( $class, $plugins ) = @_;
3392
3393         $class->_plugins( {} ) unless $class->_plugins;
3394         $plugins = [ grep {
3395             m/Unicode::Encoding/ ? do {
3396                 $class->log->warn(
3397                     'Unicode::Encoding plugin is auto-applied,'
3398                     . ' please remove this from your appclass'
3399                     . ' and make sure to define "encoding" config'
3400                 );
3401                 unless (exists $class->config->{'encoding'}) {
3402                   $class->config->{'encoding'} = 'UTF-8';
3403                 }
3404                 () }
3405                 : $_
3406         } @$plugins ];
3407         push @$plugins, $class->_default_plugins;
3408         $plugins = Data::OptList::mkopt($plugins || []);
3409
3410         my @plugins = map {
3411             [ Catalyst::Utils::resolve_namespace(
3412                   $class . '::Plugin',
3413                   'Catalyst::Plugin', $_->[0]
3414               ),
3415               $_->[1],
3416             ]
3417          } @{ $plugins };
3418
3419         for my $plugin ( reverse @plugins ) {
3420             load_class($plugin->[0], $plugin->[1]);
3421             my $meta = find_meta($plugin->[0]);
3422             next if $meta && $meta->isa('Moose::Meta::Role');
3423
3424             $class->_register_plugin($plugin->[0]);
3425         }
3426
3427         my @roles =
3428             map  { $_->[0]->name, $_->[1] }
3429             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3430             map  { [find_meta($_->[0]), $_->[1]] }
3431             @plugins;
3432
3433         Moose::Util::apply_all_roles(
3434             $class => @roles
3435         ) if @roles;
3436     }
3437 }
3438
3439 =head2 default_middleware
3440
3441 Returns a list of instantiated PSGI middleware objects which is the default
3442 middleware that is active for this application (taking any configuration
3443 options into account, excluding your custom added middleware via the C<psgi_middleware>
3444 configuration option).  You can override this method if you wish to change
3445 the default middleware (although do so at risk since some middleware is vital
3446 to application function.)
3447
3448 The current default middleware list is:
3449
3450       Catalyst::Middleware::Stash
3451       Plack::Middleware::HTTPExceptions
3452       Plack::Middleware::RemoveRedundantBody
3453       Plack::Middleware::FixMissingBodyInRedirect
3454       Plack::Middleware::ContentLength
3455       Plack::Middleware::MethodOverride
3456       Plack::Middleware::Head
3457
3458 If the configuration setting C<using_frontend_proxy> is true we add:
3459
3460       Plack::Middleware::ReverseProxy
3461
3462 If the configuration setting C<using_frontend_proxy_path> is true we add:
3463
3464       Plack::Middleware::ReverseProxyPath
3465
3466 But B<NOTE> that L<Plack::Middleware::ReverseProxyPath> is not a dependency of the
3467 L<Catalyst> distribution so if you want to use this option you should add it to
3468 your project distribution file.
3469
3470 These middlewares will be added at L</setup_middleware> during the
3471 L</setup> phase of application startup.
3472
3473 =cut
3474
3475 sub default_middleware {
3476     my $class = shift;
3477     my @mw = (
3478       Catalyst::Middleware::Stash->new,
3479       Plack::Middleware::HTTPExceptions->new,
3480       Plack::Middleware::RemoveRedundantBody->new,
3481       Plack::Middleware::FixMissingBodyInRedirect->new,
3482       Plack::Middleware::ContentLength->new,
3483       Plack::Middleware::MethodOverride->new,
3484       Plack::Middleware::Head->new);
3485
3486     if($class->config->{using_frontend_proxy}) {
3487         push @mw, Plack::Middleware::ReverseProxy->new;
3488     }
3489
3490     if($class->config->{using_frontend_proxy_path}) {
3491         if(Class::Load::try_load_class('Plack::Middleware::ReverseProxyPath')) {
3492             push @mw, Plack::Middleware::ReverseProxyPath->new;
3493         } else {
3494           $class->log->error("Cannot use configuration 'using_frontend_proxy_path' because 'Plack::Middleware::ReverseProxyPath' is not installed");
3495         }
3496     }
3497
3498     return @mw;
3499 }
3500
3501 =head2 registered_middlewares
3502
3503 Read only accessor that returns an array of all the middleware in the order
3504 that they were added (which is the REVERSE of the order they will be applied).
3505
3506 The values returned will be either instances of L<Plack::Middleware> or of a
3507 compatible interface, or a coderef, which is assumed to be inlined middleware
3508
3509 =head2 setup_middleware (?@middleware)
3510
3511 Read configuration information stored in configuration key C<psgi_middleware> or
3512 from passed @args.
3513
3514 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3515 to use it to enable L<Plack::Middleware>
3516
3517 This method is automatically called during 'setup' of your application, so
3518 you really don't need to invoke it.  However you may do so if you find the idea
3519 of loading middleware via configuration weird :).  For example:
3520
3521     package MyApp;
3522
3523     use Catalyst;
3524
3525     __PACKAGE__->setup_middleware('Head');
3526     __PACKAGE__->setup;
3527
3528 When we read middleware definitions from configuration, we reverse the list
3529 which sounds odd but is likely how you expect it to work if you have prior
3530 experience with L<Plack::Builder> or if you previously used the plugin
3531 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3532
3533 So basically your middleware handles an incoming request from the first
3534 registered middleware, down and handles the response from the last middleware
3535 up.
3536
3537 =cut
3538
3539 sub registered_middlewares {
3540     my $class = shift;
3541     if(my $middleware = $class->_psgi_middleware) {
3542         my @mw = ($class->default_middleware, @$middleware);
3543
3544         if($class->config->{using_frontend_proxy}) {
3545           push @mw, Plack::Middleware::ReverseProxy->new;
3546         }
3547
3548         return @mw;
3549     } else {
3550         die "You cannot call ->registered_middlewares until middleware has been setup";
3551     }
3552 }
3553
3554 sub setup_middleware {
3555     my $class = shift;
3556     my @middleware_definitions;
3557
3558     # If someone calls this method you can add middleware with args.  However if its
3559     # called without an arg we need to setup the configuration middleware.
3560     if(@_) {
3561       @middleware_definitions = reverse(@_);
3562     } else {
3563       @middleware_definitions = reverse(@{$class->config->{'psgi_middleware'}||[]})
3564         unless $class->finalized_default_middleware;
3565       $class->finalized_default_middleware(1); # Only do this once, just in case some people call setup over and over...
3566     }
3567
3568     my @middleware = ();
3569     while(my $next = shift(@middleware_definitions)) {
3570         if(ref $next) {
3571             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3572                 push @middleware, $next;
3573             } elsif(ref $next eq 'CODE') {
3574                 push @middleware, $next;
3575             } elsif(ref $next eq 'HASH') {
3576                 my $namespace = shift @middleware_definitions;
3577                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3578                 push @middleware, $mw;
3579             } else {
3580               die "I can't handle middleware definition ${\ref $next}";
3581             }
3582         } else {
3583           my $mw = $class->Catalyst::Utils::build_middleware($next);
3584           push @middleware, $mw;
3585         }
3586     }
3587
3588     my @existing = @{$class->_psgi_middleware || []};
3589     $class->_psgi_middleware([@middleware,@existing,]);
3590 }
3591
3592 =head2 registered_data_handlers
3593
3594 A read only copy of registered Data Handlers returned as a Hash, where each key
3595 is a content type and each value is a subref that attempts to decode that content
3596 type.
3597
3598 =head2 setup_data_handlers (?@data_handler)
3599
3600 Read configuration information stored in configuration key C<data_handlers> or
3601 from passed @args.
3602
3603 See under L</CONFIGURATION> information regarding C<data_handlers>.
3604
3605 This method is automatically called during 'setup' of your application, so
3606 you really don't need to invoke it.
3607
3608 =head2 default_data_handlers
3609
3610 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3611 only two default data handlers, for 'application/json' and an alternative to
3612 'application/x-www-form-urlencoded' which supposed nested form parameters via
3613 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3614
3615 The 'application/json' data handler is used to parse incoming JSON into a Perl
3616 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3617 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3618 JSON decoder, and has the smallest dependency impact.
3619
3620 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3621 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3622 order to get the best performance.  You should add either to your dependency
3623 list (Makefile.PL, dist.ini, cpanfile, etc.)
3624
3625 =cut
3626
3627 sub registered_data_handlers {
3628     my $class = shift;
3629     if(my $data_handlers = $class->_data_handlers) {
3630         return %$data_handlers;
3631     } else {
3632         $class->setup_data_handlers;
3633         return $class->registered_data_handlers;
3634     }
3635 }
3636
3637 sub setup_data_handlers {
3638     my ($class, %data_handler_callbacks) = @_;
3639     %data_handler_callbacks = (
3640       %{$class->default_data_handlers},
3641       %{$class->config->{'data_handlers'}||+{}},
3642       %data_handler_callbacks);
3643
3644     $class->_data_handlers(\%data_handler_callbacks);
3645 }
3646
3647 sub default_data_handlers {
3648     my ($class) = @_;
3649     return +{
3650       'application/x-www-form-urlencoded' => sub {
3651           my ($fh, $req) = @_;
3652           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3653           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3654             ->can('build_cgi_struct')->($params);
3655       },
3656       'application/json' => sub {
3657           my ($fh, $req) = @_;
3658           my $parser = Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON');
3659           my $slurped;
3660           return eval {
3661             local $/;
3662             $slurped = $fh->getline;
3663             $parser->can("decode_json")->($slurped); # decode_json does utf8 decoding for us
3664           } || Catalyst::Exception->throw(sprintf "Error Parsing POST '%s', Error: %s", (defined($slurped) ? $slurped : 'undef') ,$@);
3665         },
3666     };
3667 }
3668
3669 sub _handle_http_exception {
3670     my ( $self, $error ) = @_;
3671     if (
3672            !$self->config->{always_catch_http_exceptions}
3673         && blessed $error
3674         && (
3675             $error->can('as_psgi')
3676             || (   $error->can('code')
3677                 && $error->code =~ m/^[1-5][0-9][0-9]$/ )
3678         )
3679       )
3680     {
3681         return 1;
3682     }
3683 }
3684
3685 =head2 $c->stack
3686
3687 Returns an arrayref of the internal execution stack (actions that are
3688 currently executing).
3689
3690 =head2 $c->stats
3691
3692 Returns the current timing statistics object. By default Catalyst uses
3693 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3694 L<< stats_class|/"$c->stats_class" >>.
3695
3696 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3697 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3698 profile explicitly, although MyApp.pm still won't profile nor output anything
3699 by itself.
3700
3701 =head2 $c->stats_class
3702
3703 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3704
3705 =head2 $c->use_stats
3706
3707 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3708
3709 Note that this is a static method, not an accessor and should be overridden
3710 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3711
3712 =cut
3713
3714 sub use_stats { 0 }
3715
3716
3717 =head2 $c->write( $data )
3718
3719 Writes $data to the output stream. When using this method directly, you
3720 will need to manually set the C<Content-Length> header to the length of
3721 your output data, if known.
3722
3723 =cut
3724
3725 sub write {
3726     my $c = shift;
3727
3728     # Finalize headers if someone manually writes output (for compat)
3729     $c->finalize_headers;
3730
3731     return $c->response->write( @_ );
3732 }
3733
3734 =head2 version
3735
3736 Returns the Catalyst version number. Mostly useful for "powered by"
3737 messages in template systems.
3738
3739 =cut
3740
3741 sub version { return $Catalyst::VERSION }
3742
3743 =head1 CONFIGURATION
3744
3745 There are a number of 'base' config variables which can be set:
3746
3747 =over
3748
3749 =item *
3750
3751 C<always_catch_http_exceptions> - As of version 5.90060 Catalyst
3752 rethrows errors conforming to the interface described by
3753 L<Plack::Middleware::HTTPExceptions> and lets the middleware deal with it.
3754 Set true to get the deprecated behaviour and have Catalyst catch HTTP exceptions.
3755
3756 =item *
3757
3758 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3759
3760 =item *
3761
3762 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3763
3764 =item *
3765
3766 C<disable_component_resolution_regex_fallback> - Turns
3767 off the deprecated component resolution functionality so
3768 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3769 are called then regex search will not be attempted on string values and
3770 instead C<undef> will be returned.
3771
3772 =item *
3773
3774 C<home> - The application home directory. In an uninstalled application,
3775 this is the top level application directory. In an installed application,
3776 this will be the directory containing C<< MyApp.pm >>.
3777
3778 =item *
3779
3780 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3781
3782 =item *
3783
3784 C<name> - The name of the application in debug messages and the debug and
3785 welcome screens
3786
3787 =item *
3788
3789 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3790 until it is accessed. This allows you to (for example) check authentication (and reject
3791 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3792
3793 =item *
3794
3795 C<root> - The root directory for templates. Usually this is just a
3796 subdirectory of the home directory, but you can set it to change the
3797 templates to a different directory.
3798
3799 =item *
3800
3801 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3802 namespaces from which components will be loaded (and constructed and stored in
3803 C<< $c->components >>).
3804
3805 =item *
3806
3807 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3808 to be shown in hit debug tables in the test server.
3809
3810 =item *
3811
3812 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3813 variable should be used for determining the request path.
3814
3815 Most web server environments pass the requested path to the application using environment variables,
3816 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3817 exposed as C<< $c->request->base >>) and the request path below that base.
3818
3819 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3820 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3821
3822 =over
3823
3824 =item use_request_uri_for_path => 0
3825
3826 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3827 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3828 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3829 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3830
3831 However this method has the major disadvantage that it is impossible to correctly decode some elements
3832 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3833 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3834 can't distinguish / vs %2F in paths (in addition to other encoded values).
3835
3836 =item use_request_uri_for_path => 1
3837
3838 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3839 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3840 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3841
3842 Given that this method of path resolution is provably more correct, it is recommended that you use
3843 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3844 aware of the implications of not being able to handle encoded URI paths correctly.
3845
3846 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3847 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3848 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3849 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3850 C<< $c->request->base >> will be incorrect.
3851
3852 =back
3853
3854 =item *
3855
3856 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3857
3858 =item *
3859
3860 C<using_frontend_proxy_path> - Enabled L<Plack::Middleware::ReverseProxyPath> on your application (if
3861 installed, otherwise log an error).  This is useful if your application is not running on the
3862 'root' (or /) of your host server.  B<NOTE> if you use this feature you should add the required
3863 middleware to your project dependency list since its not automatically a dependency of L<Catalyst>.
3864 This has been done since not all people need this feature and we wish to restrict the growth of
3865 L<Catalyst> dependencies.
3866
3867 =item *
3868
3869 C<encoding> - See L</ENCODING>
3870
3871 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
3872 value to undef.
3873
3874 =item *
3875
3876 C<abort_chain_on_error_fix>
3877
3878 When there is an error in an action chain, the default behavior is to continue
3879 processing the remaining actions and then catch the error upon chain end.  This
3880 can lead to running actions when the application is in an unexpected state.  If
3881 you have this issue, setting this config value to true will promptly exit a
3882 chain when there is an error raised in any action (thus terminating the chain
3883 early.)
3884
3885 use like:
3886
3887     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3888
3889 In the future this might become the default behavior.
3890
3891 =item *
3892
3893 C<use_hash_multivalue_in_request>
3894
3895 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3896 and C<parameters> return a hashref where values might be scalar or an arrayref
3897 depending on the incoming data.  In many cases this can be undesirable as it
3898 leads one to writing defensive code like the following:
3899
3900     my ($val) = ref($c->req->parameters->{a}) ?
3901       @{$c->req->parameters->{a}} :
3902         $c->req->parameters->{a};
3903
3904 Setting this configuration item to true will make L<Catalyst> populate the
3905 attributes underlying these methods with an instance of L<Hash::MultiValue>
3906 which is used by L<Plack::Request> and others to solve this very issue.  You
3907 may prefer this behavior to the default, if so enable this option (be warned
3908 if you enable it in a legacy application we are not sure if it is completely
3909 backwardly compatible).
3910
3911 =item *
3912
3913 C<skip_complex_post_part_handling>
3914
3915 When creating body parameters from a POST, if we run into a multpart POST
3916 that does not contain uploads, but instead contains inlined complex data
3917 (very uncommon) we cannot reliably convert that into field => value pairs.  So
3918 instead we create an instance of L<Catalyst::Request::PartData>.  If this causes
3919 issue for you, you can disable this by setting C<skip_complex_post_part_handling>
3920 to true (default is false).
3921
3922 =item *
3923
3924 C<skip_body_param_unicode_decoding>
3925
3926 Generally we decode incoming POST params based on your declared encoding (the
3927 default for this is to decode UTF-8).  If this is causing you trouble and you
3928 do not wish to turn all encoding support off (with the C<encoding> configuration
3929 parameter) you may disable this step atomically by setting this configuration
3930 parameter to true.
3931
3932 =item *
3933
3934 C<do_not_decode_query>
3935
3936 If true, then do not try to character decode any wide characters in your
3937 request URL query or keywords.  Most readings of the relevent specifications
3938 suggest these should be UTF-* encoded, which is the default that L<Catalyst>
3939 will use, hwoever if you are creating a lot of URLs manually or have external
3940 evil clients, this might cause you trouble.  If you find the changes introduced
3941 in Catalyst version 5.90080+ break some of your query code, you may disable
3942 the UTF-8 decoding globally using this configuration.
3943
3944 This setting takes precedence over C<default_query_encoding> and
3945 C<decode_query_using_global_encoding>
3946
3947 =item *
3948
3949 C<default_query_encoding>
3950
3951 By default we decode query and keywords in your request URL using UTF-8, which
3952 is our reading of the relevent specifications.  This setting allows one to
3953 specify a fixed value for how to decode your query.  You might need this if
3954 you are doing a lot of custom encoding of your URLs and not using UTF-8.
3955
3956 This setting take precedence over C<decode_query_using_global_encoding>.
3957
3958 =item *
3959
3960 C<decode_query_using_global_encoding>
3961
3962 Setting this to true will default your query decoding to whatever your
3963 general global encoding is (the default is UTF-8).
3964
3965 =item *
3966
3967 C<use_chained_args_0_special_case>
3968
3969 In older versions of Catalyst, when more than one action matched the same path
3970 AND all those matching actions declared Args(0), we'd break the tie by choosing
3971 the first action defined.  We now normalized how Args(0) works so that it
3972 follows the same rule as Args(N), which is to say when we need to break a tie
3973 we choose the LAST action defined.  If this breaks your code and you don't
3974 have time to update to follow the new normalized approach, you may set this
3975 value to true and it will globally revert to the original chaining behavior.
3976
3977 =item *
3978
3979 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3980
3981 =item *
3982
3983 C<data_handlers> - See L<DATA HANDLERS>.
3984
3985 =back
3986
3987 =head1 EXCEPTIONS
3988
3989 Generally when you throw an exception inside an Action (or somewhere in
3990 your stack, such as in a model that an Action is calling) that exception
3991 is caught by Catalyst and unless you either catch it yourself (via eval
3992 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
3993 will eventually reach L</finalize_errors> and return either the debugging
3994 error stack page, or the default error page.  However, if your exception
3995 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
3996 instead rethrow it so that it can be handled by that middleware (which
3997 is part of the default middleware).  For example this would allow
3998
3999     use HTTP::Throwable::Factory 'http_throw';
4000
4001     sub throws_exception :Local {
4002       my ($self, $c) = @_;
4003
4004       http_throw(SeeOther => { location =>
4005         $c->uri_for($self->action_for('redirect')) });
4006
4007     }
4008
4009 =head1 INTERNAL ACTIONS
4010
4011 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
4012 C<_ACTION>, and C<_END>. These are by default not shown in the private
4013 action table, but you can make them visible with a config parameter.
4014
4015     MyApp->config(show_internal_actions => 1);
4016
4017 =head1 ON-DEMAND PARSER
4018
4019 The request body is usually parsed at the beginning of a request,
4020 but if you want to handle input yourself, you can enable on-demand
4021 parsing with a config parameter.
4022
4023     MyApp->config(parse_on_demand => 1);
4024
4025 =head1 PROXY SUPPORT
4026
4027 Many production servers operate using the common double-server approach,
4028 with a lightweight frontend web server passing requests to a larger
4029 backend server. An application running on the backend server must deal
4030 with two problems: the remote user always appears to be C<127.0.0.1> and
4031 the server's hostname will appear to be C<localhost> regardless of the
4032 virtual host that the user connected through.
4033
4034 Catalyst will automatically detect this situation when you are running
4035 the frontend and backend servers on the same machine. The following
4036 changes are made to the request.
4037
4038     $c->req->address is set to the user's real IP address, as read from
4039     the HTTP X-Forwarded-For header.
4040
4041     The host value for $c->req->base and $c->req->uri is set to the real
4042     host, as read from the HTTP X-Forwarded-Host header.
4043
4044 Additionally, you may be running your backend application on an insecure
4045 connection (port 80) while your frontend proxy is running under SSL.  If there
4046 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
4047 tell Catalyst what port the frontend listens on.  This will allow all URIs to
4048 be created properly.
4049
4050 In the case of passing in:
4051
4052     X-Forwarded-Port: 443
4053
4054 All calls to C<uri_for> will result in an https link, as is expected.
4055
4056 Obviously, your web server must support these headers for this to work.
4057
4058 In a more complex server farm environment where you may have your
4059 frontend proxy server(s) on different machines, you will need to set a
4060 configuration option to tell Catalyst to read the proxied data from the
4061 headers.
4062
4063     MyApp->config(using_frontend_proxy => 1);
4064
4065 If you do not wish to use the proxy support at all, you may set:
4066
4067     MyApp->config(ignore_frontend_proxy => 0);
4068
4069 =head2 Note about psgi files
4070
4071 Note that if you supply your own .psgi file, calling
4072 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
4073
4074 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
4075 in your psgi, for example:
4076
4077     builder {
4078         enable "Plack::Middleware::ReverseProxy";
4079         MyApp->psgi_app
4080     };
4081
4082 This will unconditionally add the ReverseProxy support, or you need to call
4083 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
4084 apply the support depending upon your config).
4085
4086 See L<Catalyst::PSGI> for more information.
4087
4088 =head1 THREAD SAFETY
4089
4090 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
4091 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
4092 believe the Catalyst core to be thread-safe.
4093
4094 If you plan to operate in a threaded environment, remember that all other
4095 modules you are using must also be thread-safe. Some modules, most notably
4096 L<DBD::SQLite>, are not thread-safe.
4097
4098 =head1 DATA HANDLERS
4099
4100 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
4101 form parameters and URL search query fields.  However it has become common
4102 for various alternative content types to be PUT or POSTed to your controllers
4103 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
4104 XML and other content types when communicating with an application server.  In
4105 order to better support this use case, L<Catalyst> defines a global configuration
4106 option, C<data_handlers>, which lets you associate a content type with a coderef
4107 that parses that content type into something Perl can readily access.
4108
4109     package MyApp::Web;
4110
4111     use Catalyst;
4112     use JSON::Maybe;
4113
4114     __PACKAGE__->config(
4115       data_handlers => {
4116         'application/json' => sub { local $/; decode_json $_->getline },
4117       },
4118       ## Any other configuration.
4119     );
4120
4121     __PACKAGE__->setup;
4122
4123 By default L<Catalyst> comes with a generic JSON data handler similar to the
4124 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
4125 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
4126 it installed (if you want the faster XS parser, add it to you project Makefile.PL
4127 or dist.ini, cpanfile, etc.)
4128
4129 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
4130 (matched against the incoming request type using a regexp such as to be case
4131 insensitive) and whose values are coderefs that receive a localized version of
4132 C<$_> which is a filehandle object pointing to received body.
4133
4134 This feature is considered an early access release and we reserve the right
4135 to alter the interface in order to provide a performant and secure solution to
4136 alternative request body content.  Your reports welcomed!
4137
4138 =head1 PSGI MIDDLEWARE
4139
4140 You can define middleware, defined as L<Plack::Middleware> or a compatible
4141 interface in configuration.  Your middleware definitions are in the form of an
4142 arrayref under the configuration key C<psgi_middleware>.  Here's an example
4143 with details to follow:
4144
4145     package MyApp::Web;
4146
4147     use Catalyst;
4148     use Plack::Middleware::StackTrace;
4149
4150     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4151
4152     __PACKAGE__->config(
4153       'psgi_middleware', [
4154         'Debug',
4155         '+MyApp::Custom',
4156         $stacktrace_middleware,
4157         'Session' => {store => 'File'},
4158         sub {
4159           my $app = shift;
4160           return sub {
4161             my $env = shift;
4162             $env->{myapp.customkey} = 'helloworld';
4163             $app->($env);
4164           },
4165         },
4166       ],
4167     );
4168
4169     __PACKAGE__->setup;
4170
4171 So the general form is:
4172
4173     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
4174
4175 Where C<@middleware> is one or more of the following, applied in the REVERSE of
4176 the order listed (to make it function similarly to L<Plack::Builder>:
4177
4178 Alternatively, you may also define middleware by calling the L</setup_middleware>
4179 package method:
4180
4181     package MyApp::Web;
4182
4183     use Catalyst;
4184
4185     __PACKAGE__->setup_middleware( \@middleware_definitions);
4186     __PACKAGE__->setup;
4187
4188 In the case where you do both (use 'setup_middleware' and configuration) the
4189 package call to setup_middleware will be applied earlier (in other words its
4190 middleware will wrap closer to the application).  Keep this in mind since in
4191 some cases the order of middleware is important.
4192
4193 The two approaches are not exclusive.
4194
4195 =over 4
4196
4197 =item Middleware Object
4198
4199 An already initialized object that conforms to the L<Plack::Middleware>
4200 specification:
4201
4202     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4203
4204     __PACKAGE__->config(
4205       'psgi_middleware', [
4206         $stacktrace_middleware,
4207       ]);
4208
4209
4210 =item coderef
4211
4212 A coderef that is an inlined middleware:
4213
4214     __PACKAGE__->config(
4215       'psgi_middleware', [
4216         sub {
4217           my $app = shift;
4218           return sub {
4219             my $env = shift;
4220             if($env->{PATH_INFO} =~m/forced/) {
4221               Plack::App::File
4222                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
4223                 ->call($env);
4224             } else {
4225               return $app->($env);
4226             }
4227          },
4228       },
4229     ]);
4230
4231
4232
4233 =item a scalar
4234
4235 We assume the scalar refers to a namespace after normalizing it using the
4236 following rules:
4237
4238 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
4239 is assumed to be 'as is', and we just install and use the middleware.
4240
4241 (2) If the scalar begins with "Plack::Middleware" or your application namespace
4242 (the package name of your Catalyst application subclass), we also assume then
4243 that it is a full namespace, and use it.
4244
4245 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
4246 resolve it first by looking for it under your application namespace (for example
4247 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
4248 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
4249 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
4250 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
4251 namespace first to let you 'override' common L<Plack::Middleware> locally, should
4252 you find that a good idea.
4253
4254 Examples:
4255
4256     package MyApp::Web;
4257
4258     __PACKAGE__->config(
4259       'psgi_middleware', [
4260         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
4261         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
4262         '+MyApp::Custom',  ## MyApp::Custom->wrap
4263       ],
4264     );
4265
4266 =item a scalar followed by a hashref
4267
4268 Just like the previous, except the following C<HashRef> is used as arguments
4269 to initialize the middleware object.
4270
4271     __PACKAGE__->config(
4272       'psgi_middleware', [
4273          'Session' => {store => 'File'},
4274     ]);
4275
4276 =back
4277
4278 Please see L<PSGI> for more on middleware.
4279
4280 =head1 ENCODING
4281
4282 Starting in L<Catalyst> version 5.90080 encoding is automatically enabled
4283 and set to encode all body responses to UTF8 when possible and applicable.
4284 Following is documentation on this process.  If you are using an older
4285 version of L<Catalyst> you should review documentation for that version since
4286 a lot has changed.
4287
4288 By default encoding is now 'UTF-8'.  You may turn it off by setting
4289 the encoding configuration to undef.
4290
4291     MyApp->config(encoding => undef);
4292
4293 This is recommended for temporary backwards compatibility only.
4294
4295 Encoding is automatically applied when the content-type is set to
4296 a type that can be encoded.  Currently we encode when the content type
4297 matches the following regular expression:
4298
4299     $content_type =~ /^text|xml$|javascript$/
4300
4301 Encoding is set on the application, but it is copied to the context object
4302 so that you can override it on a request basis.
4303
4304 Be default we don't automatically encode 'application/json' since the most
4305 common approaches to generating this type of response (Either via L<Catalyst::View::JSON>
4306 or L<Catalyst::Action::REST>) will do so already and we want to avoid double
4307 encoding issues.
4308
4309 If you are producing JSON response in an unconventional manner (such
4310 as via a template or manual strings) you should perform the UTF8 encoding
4311 manually as well such as to conform to the JSON specification.
4312
4313 NOTE: We also examine the value of $c->response->content_encoding.  If
4314 you set this (like for example 'gzip', and manually gzipping the body)
4315 we assume that you have done all the necessary encoding yourself, since
4316 we cannot encode the gzipped contents.  If you use a plugin like
4317 L<Catalyst::Plugin::Compress> you need to update to a modern version in order
4318 to have this function correctly  with the new UTF8 encoding code, or you
4319 can use L<Plack::Middleware::Deflater> or (probably best) do your compression on
4320 a front end proxy.
4321
4322 =head2 Methods
4323
4324 =over 4
4325
4326 =item encoding
4327
4328 Returns an instance of an C<Encode> encoding
4329
4330     print $c->encoding->name
4331
4332 =item handle_unicode_encoding_exception ($exception_context)
4333
4334 Method called when decoding process for a request fails.
4335
4336 An C<$exception_context> hashref is provided to allow you to override the
4337 behaviour of your application when given data with incorrect encodings.
4338
4339 The default method throws exceptions in the case of invalid request parameters
4340 (resulting in a 500 error), but ignores errors in upload filenames.
4341
4342 The keys passed in the C<$exception_context> hash are:
4343
4344 =over
4345
4346 =item param_value
4347
4348 The value which was not able to be decoded.
4349
4350 =item error_msg
4351
4352 The exception received from L<Encode>.
4353
4354 =item encoding_step
4355
4356 What type of data was being decoded. Valid values are (currently)
4357 C<params> - for request parameters / arguments / captures
4358 and C<uploads> - for request upload filenames.
4359
4360 =back
4361
4362 =back
4363
4364 =head1 SUPPORT
4365
4366 IRC:
4367
4368     Join #catalyst on irc.perl.org.
4369
4370 Mailing Lists:
4371
4372     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4373     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4374
4375 Web:
4376
4377     http://catalyst.perl.org
4378
4379 Wiki:
4380
4381     http://dev.catalyst.perl.org
4382
4383 =head1 SEE ALSO
4384
4385 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4386
4387 =head2 L<Catalyst::Manual> - The Catalyst Manual
4388
4389 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4390
4391 =head2 L<Catalyst::Engine> - Core engine
4392
4393 =head2 L<Catalyst::Log> - Log class.
4394
4395 =head2 L<Catalyst::Request> - Request object
4396
4397 =head2 L<Catalyst::Response> - Response object
4398
4399 =head2 L<Catalyst::Test> - The test suite.
4400
4401 =head1 PROJECT FOUNDER
4402
4403 sri: Sebastian Riedel <sri@cpan.org>
4404
4405 =head1 CONTRIBUTORS
4406
4407 abw: Andy Wardley
4408
4409 acme: Leon Brocard <leon@astray.com>
4410
4411 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4412
4413 andrewalker: André Walker <andre@cpan.org>
4414
4415 Andrew Bramble
4416
4417 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4418
4419 Andrew Ruthven
4420
4421 andyg: Andy Grundman <andy@hybridized.org>
4422
4423 audreyt: Audrey Tang
4424
4425 bricas: Brian Cassidy <bricas@cpan.org>
4426
4427 Caelum: Rafael Kitover <rkitover@io.com>
4428
4429 chansen: Christian Hansen
4430
4431 chicks: Christopher Hicks
4432
4433 Chisel Wright C<pause@herlpacker.co.uk>
4434
4435 Danijel Milicevic C<me@danijel.de>
4436
4437 davewood: David Schmidt <davewood@cpan.org>
4438
4439 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4440
4441 David Naughton, C<naughton@umn.edu>
4442
4443 David E. Wheeler
4444
4445 dhoss: Devin Austin <dhoss@cpan.org>
4446
4447 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4448
4449 Drew Taylor
4450
4451 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4452
4453 esskar: Sascha Kiefer
4454
4455 fireartist: Carl Franks <cfranks@cpan.org>
4456
4457 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4458
4459 gabb: Danijel Milicevic
4460
4461 Gary Ashton Jones
4462
4463 Gavin Henry C<ghenry@perl.me.uk>
4464
4465 Geoff Richards
4466
4467 groditi: Guillermo Roditi <groditi@gmail.com>
4468
4469 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4470
4471 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4472
4473 jcamacho: Juan Camacho
4474
4475 jester: Jesse Sheidlower C<jester@panix.com>
4476
4477 jhannah: Jay Hannah <jay@jays.net>
4478
4479 Jody Belka
4480
4481 Johan Lindstrom
4482
4483 jon: Jon Schutz <jjschutz@cpan.org>
4484
4485 Jonathan Rockway C<< <jrockway@cpan.org> >>
4486
4487 Kieren Diment C<kd@totaldatasolution.com>
4488
4489 konobi: Scott McWhirter <konobi@cpan.org>
4490
4491 marcus: Marcus Ramberg <mramberg@cpan.org>
4492
4493 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4494
4495 mgrimes: Mark Grimes <mgrimes@cpan.org>
4496
4497 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4498
4499 mugwump: Sam Vilain
4500
4501 naughton: David Naughton
4502
4503 ningu: David Kamholz <dkamholz@cpan.org>
4504
4505 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4506
4507 numa: Dan Sully <daniel@cpan.org>
4508
4509 obra: Jesse Vincent
4510
4511 Octavian Rasnita
4512
4513 omega: Andreas Marienborg
4514
4515 Oleg Kostyuk <cub.uanic@gmail.com>
4516
4517 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4518
4519 rafl: Florian Ragwitz <rafl@debian.org>
4520
4521 random: Roland Lammel <lammel@cpan.org>
4522
4523 Robert Sedlacek C<< <rs@474.at> >>
4524
4525 SpiceMan: Marcel Montes
4526
4527 sky: Arthur Bergman
4528
4529 szbalint: Balint Szilakszi <szbalint@cpan.org>
4530
4531 t0m: Tomas Doran <bobtfish@bobtfish.net>
4532
4533 Ulf Edvinsson
4534
4535 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4536
4537 Viljo Marrandi C<vilts@yahoo.com>
4538
4539 Will Hawes C<info@whawes.co.uk>
4540
4541 willert: Sebastian Willert <willert@cpan.org>
4542
4543 wreis: Wallace Reis <wreis@cpan.org>
4544
4545 Yuval Kogman, C<nothingmuch@woobling.org>
4546
4547 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4548
4549 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4550
4551 Upasana <me@upasana.me>
4552
4553 John Napiorkowski (jnap) <jjnapiork@cpan.org>
4554
4555 =head1 COPYRIGHT
4556
4557 Copyright (c) 2005-2015, the above named PROJECT FOUNDER and CONTRIBUTORS.
4558
4559 =head1 LICENSE
4560
4561 This library is free software. You can redistribute it and/or modify it under
4562 the same terms as Perl itself.
4563
4564 =cut
4565
4566 no Moose;
4567
4568 __PACKAGE__->meta->make_immutable;
4569
4570 1;