lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken blessed/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 __PACKAGE__->mk_accessors(
  34     qw/counter request response state action stack namespace stats/
  35 );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52
  53 __PACKAGE__->mk_classdata($_)
  54   for qw/components arguments dispatcher engine log dispatcher_class
  55   engine_class context_class request_class response_class stats_class
  56   setup_finished/;
  57
  58 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  59 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  60 __PACKAGE__->request_class('Catalyst::Request');
  61 __PACKAGE__->response_class('Catalyst::Response');
  62 __PACKAGE__->stats_class('Catalyst::Stats');
  63
  64 # Remember to update this in Catalyst::Runtime as well!
  65
  66 our $VERSION = '5.7014';
  67
  68 sub import {
  69     my ( $class, @arguments ) = @_;
  70
  71     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  72     # callers @ISA.
  73     return unless $class eq 'Catalyst';
  74
  75     my $caller = caller(0);
  76
  77     unless ( $caller->isa('Catalyst') ) {
  78         no strict 'refs';
  79         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  80     }
  81
  82     $caller->arguments( [@arguments] );
  83     $caller->setup_home;
  84 }
  85
  86 =head1 NAME
  87
  88 Catalyst - The Elegant MVC Web Application Framework
  89
  90 =head1 SYNOPSIS
  91
  92 See the L<Catalyst::Manual> distribution for comprehensive
  93 documentation and tutorials.
  94
  95     # Install Catalyst::Devel for helpers and other development tools
  96     # use the helper to create a new application
  97     catalyst.pl MyApp
  98
  99     # add models, views, controllers
 100     script/myapp_create.pl model MyDatabase DBIC::Schema create=dynamic dbi:SQLite:/path/to/db
 101     script/myapp_create.pl view MyTemplate TT
 102     script/myapp_create.pl controller Search
 103
 104     # built in testserver -- use -r to restart automatically on changes
 105     # --help to see all available options
 106     script/myapp_server.pl
 107
 108     # command line testing interface
 109     script/myapp_test.pl /yada
 110
 111     ### in lib/MyApp.pm
 112     use Catalyst qw/-Debug/; # include plugins here as well
 113
 114     ### In lib/MyApp/Controller/Root.pm (autocreated)
 115     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 116         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 117         $c->stash->{template} = 'foo.tt'; # set the template
 118         # lookup something from db -- stash vars are passed to TT
 119         $c->stash->{data} =
 120           $c->model('Database::Foo')->search( { country => $args[0] } );
 121         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 122             $c->forward( 'bar' ); # process another action
 123             # do something else after forward returns
 124         }
 125     }
 126
 127     # The foo.tt TT template can use the stash data from the database
 128     [% WHILE (item = data.next) %]
 129         [% item.foo %]
 130     [% END %]
 131
 132     # called for /bar/of/soap, /bar/of/soap/10, etc.
 133     sub bar : Path('/bar/of/soap') { ... }
 134
 135     # called for all actions, from the top-most controller downwards
 136     sub auto : Private {
 137         my ( $self, $c ) = @_;
 138         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 139             $c->res->redirect( '/login' ); # require login
 140             return 0; # abort request and go immediately to end()
 141         }
 142         return 1; # success; carry on to next action
 143     }
 144
 145     # called after all actions are finished
 146     sub end : Private {
 147         my ( $self, $c ) = @_;
 148         if ( scalar @{ $c->error } ) { ... } # handle errors
 149         return if $c->res->body; # already have a response
 150         $c->forward( 'MyApp::View::TT' ); # render template
 151     }
 152
 153     ### in MyApp/Controller/Foo.pm
 154     # called for /foo/bar
 155     sub bar : Local { ... }
 156
 157     # called for /blargle
 158     sub blargle : Global { ... }
 159
 160     # an index action matches /foo, but not /foo/1, etc.
 161     sub index : Private { ... }
 162
 163     ### in MyApp/Controller/Foo/Bar.pm
 164     # called for /foo/bar/baz
 165     sub baz : Local { ... }
 166
 167     # first Root auto is called, then Foo auto, then this
 168     sub auto : Private { ... }
 169
 170     # powerful regular expression paths are also possible
 171     sub details : Regex('^product/(\w+)/details$') {
 172         my ( $self, $c ) = @_;
 173         # extract the (\w+) from the URI
 174         my $product = $c->req->captures->[0];
 175     }
 176
 177 See L<Catalyst::Manual::Intro> for additional information.
 178
 179 =head1 DESCRIPTION
 180
 181 Catalyst is a modern framework for making web applications without the
 182 pain usually associated with this process. This document is a reference
 183 to the main Catalyst application. If you are a new user, we suggest you
 184 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 185
 186 See L<Catalyst::Manual> for more documentation.
 187
 188 Catalyst plugins can be loaded by naming them as arguments to the "use
 189 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 190 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 191 C<My::Module>.
 192
 193     use Catalyst qw/My::Module/;
 194
 195 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 196 fully qualify the name by using a unary plus:
 197
 198     use Catalyst qw/
 199         My::Module
 200         +Fully::Qualified::Plugin::Name
 201     /;
 202
 203 Special flags like C<-Debug> and C<-Engine> can also be specified as
 204 arguments when Catalyst is loaded:
 205
 206     use Catalyst qw/-Debug My::Module/;
 207
 208 The position of plugins and flags in the chain is important, because
 209 they are loaded in the order in which they appear.
 210
 211 The following flags are supported:
 212
 213 =head2 -Debug
 214
 215 Enables debug output. You can also force this setting from the system
 216 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 217 settings override the application, with <MYAPP>_DEBUG having the highest
 218 priority.
 219
 220 =head2 -Engine
 221
 222 Forces Catalyst to use a specific engine. Omit the
 223 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 224
 225     use Catalyst qw/-Engine=CGI/;
 226
 227 =head2 -Home
 228
 229 Forces Catalyst to use a specific home directory, e.g.:
 230
 231     use Catalyst qw[-Home=/usr/mst];
 232
 233 This can also be done in the shell environment by setting either the
 234 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 235 is replaced with the uppercased name of your application, any "::" in
 236 the name will be replaced with underscores, e.g. MyApp::Web should use
 237 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 238
 239 =head2 -Log
 240
 241 Specifies log level.
 242
 243 =head2 -Stats
 244
 245 Enables statistics collection and reporting. You can also force this setting
 246 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 247 environment settings override the application, with <MYAPP>_STATS having the
 248 highest priority.
 249
 250 e.g.
 251
 252    use Catalyst qw/-Stats=1/
 253
 254 =head1 METHODS
 255
 256 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 257
 258 =head2 $c->action
 259
 260 Returns a L<Catalyst::Action> object for the current action, which
 261 stringifies to the action name. See L<Catalyst::Action>.
 262
 263 =head2 $c->namespace
 264
 265 Returns the namespace of the current action, i.e., the URI prefix
 266 corresponding to the controller of the current action. For example:
 267
 268     # in Controller::Foo::Bar
 269     $c->namespace; # returns 'foo/bar';
 270
 271 =head2 $c->request
 272
 273 =head2 $c->req
 274
 275 Returns the current L<Catalyst::Request> object, giving access to
 276 information about the current client request (including parameters,
 277 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 278
 279 =head2 REQUEST FLOW HANDLING
 280
 281 =head2 $c->forward( $action [, \@arguments ] )
 282
 283 =head2 $c->forward( $class, $method, [, \@arguments ] )
 284
 285 Forwards processing to another action, by its private name. If you give a
 286 class name but no method, C<process()> is called. You may also optionally
 287 pass arguments in an arrayref. The action will receive the arguments in
 288 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 289 C<< $c->req->args >> will be restored to the previous values.
 290
 291 Any data C<return>ed from the action forwarded to, will be returned by the
 292 call to forward.
 293
 294     my $foodata = $c->forward('/foo');
 295     $c->forward('index');
 296     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 297     $c->forward('MyApp::View::TT');
 298
 299 Note that forward implies an C<<eval { }>> around the call (actually
 300 C<execute> does), thus de-fatalizing all 'dies' within the called
 301 action. If you want C<die> to propagate you need to do something like:
 302
 303     $c->forward('foo');
 304     die $c->error if $c->error;
 305
 306 Or make sure to always return true values from your actions and write
 307 your code like this:
 308
 309     $c->forward('foo') || return;
 310
 311 =cut
 312
 313 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 314
 315 =head2 $c->detach( $action [, \@arguments ] )
 316
 317 =head2 $c->detach( $class, $method, [, \@arguments ] )
 318
 319 =head2 $c->detach()
 320
 321 The same as C<forward>, but doesn't return to the previous action when
 322 processing is finished.
 323
 324 When called with no arguments it escapes the processing chain entirely.
 325
 326 =cut
 327
 328 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 329
 330 =head2 $c->response
 331
 332 =head2 $c->res
 333
 334 Returns the current L<Catalyst::Response> object, see there for details.
 335
 336 =head2 $c->stash
 337
 338 Returns a hashref to the stash, which may be used to store data and pass
 339 it between components during a request. You can also set hash keys by
 340 passing arguments. The stash is automatically sent to the view. The
 341 stash is cleared at the end of a request; it cannot be used for
 342 persistent storage (for this you must use a session; see
 343 L<Catalyst::Plugin::Session> for a complete system integrated with
 344 Catalyst).
 345
 346     $c->stash->{foo} = $bar;
 347     $c->stash( { moose => 'majestic', qux => 0 } );
 348     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 349
 350     # stash is automatically passed to the view for use in a template
 351     $c->forward( 'MyApp::View::TT' );
 352
 353 =cut
 354
 355 sub stash {
 356     my $c = shift;
 357     if (@_) {
 358         my $stash = @_ > 1 ? {@_} : $_[0];
 359         croak('stash takes a hash or hashref') unless ref $stash;
 360         foreach my $key ( keys %$stash ) {
 361             $c->{stash}->{$key} = $stash->{$key};
 362         }
 363     }
 364     return $c->{stash};
 365 }
 366
 367 =head2 $c->error
 368
 369 =head2 $c->error($error, ...)
 370
 371 =head2 $c->error($arrayref)
 372
 373 Returns an arrayref containing error messages.  If Catalyst encounters an
 374 error while processing a request, it stores the error in $c->error.  This
 375 method should only be used to store fatal error messages.
 376
 377     my @error = @{ $c->error };
 378
 379 Add a new error.
 380
 381     $c->error('Something bad happened');
 382
 383 =cut
 384
 385 sub error {
 386     my $c = shift;
 387     if ( $_[0] ) {
 388         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 389         croak @$error unless ref $c;
 390         push @{ $c->{error} }, @$error;
 391     }
 392     elsif ( defined $_[0] ) { $c->{error} = undef }
 393     return $c->{error} || [];
 394 }
 395
 396
 397 =head2 $c->state
 398
 399 Contains the return value of the last executed action.
 400
 401 =head2 $c->clear_errors
 402
 403 Clear errors.  You probably don't want to clear the errors unless you are
 404 implementing a custom error screen.
 405
 406 This is equivalent to running
 407
 408     $c->error(0);
 409
 410 =cut
 411
 412 sub clear_errors {
 413     my $c = shift;
 414     $c->error(0);
 415 }
 416
 417
 418 # search via regex
 419 sub _comp_search {
 420     my ( $c, @names ) = @_;
 421
 422     foreach my $name (@names) {
 423         foreach my $component ( keys %{ $c->components } ) {
 424             return $c->components->{$component} if $component =~ /$name/i;
 425         }
 426     }
 427
 428     return undef;
 429 }
 430
 431 # try explicit component names
 432 sub _comp_explicit {
 433     my ( $c, @names ) = @_;
 434
 435     foreach my $try (@names) {
 436         return $c->components->{$try} if ( exists $c->components->{$try} );
 437     }
 438
 439     return undef;
 440 }
 441
 442 # like component, but try just these prefixes before regex searching,
 443 #  and do not try to return "sort keys %{ $c->components }"
 444 sub _comp_prefixes {
 445     my ( $c, $name, @prefixes ) = @_;
 446
 447     my $appclass = ref $c || $c;
 448
 449     my @names = map { "${appclass}::${_}::${name}" } @prefixes;
 450
 451     my $comp = $c->_comp_explicit(@names);
 452     return $comp if defined($comp);
 453     $comp = $c->_comp_search($name);
 454     return $comp;
 455 }
 456
 457 # Find possible names for a prefix
 458
 459 sub _comp_names {
 460     my ( $c, @prefixes ) = @_;
 461
 462     my $appclass = ref $c || $c;
 463
 464     my @pre = map { "${appclass}::${_}::" } @prefixes;
 465
 466     my @names;
 467
 468     COMPONENT: foreach my $comp ($c->component) {
 469         foreach my $p (@pre) {
 470             if ($comp =~ s/^$p//) {
 471                 push(@names, $comp);
 472                 next COMPONENT;
 473             }
 474         }
 475     }
 476
 477     return @names;
 478 }
 479
 480 # Return a component if only one matches.
 481 sub _comp_singular {
 482     my ( $c, @prefixes ) = @_;
 483
 484     my $appclass = ref $c || $c;
 485
 486     my ( $comp, $rest ) =
 487       map { $c->_comp_search("^${appclass}::${_}::") } @prefixes;
 488     return $comp unless $rest;
 489 }
 490
 491 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 492 sub _filter_component {
 493     my ( $c, $comp, @args ) = @_;
 494     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 495         return $comp->ACCEPT_CONTEXT( $c, @args );
 496     }
 497     else { return $comp }
 498 }
 499
 500 =head2 COMPONENT ACCESSORS
 501
 502 =head2 $c->controller($name)
 503
 504 Gets a L<Catalyst::Controller> instance by name.
 505
 506     $c->controller('Foo')->do_stuff;
 507
 508 If the name is omitted, will return the controller for the dispatched
 509 action.
 510
 511 =cut
 512
 513 sub controller {
 514     my ( $c, $name, @args ) = @_;
 515     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Controller C/ ),
 516         @args )
 517       if ($name);
 518     return $c->component( $c->action->class );
 519 }
 520
 521 =head2 $c->model($name)
 522
 523 Gets a L<Catalyst::Model> instance by name.
 524
 525     $c->model('Foo')->do_stuff;
 526
 527 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 528
 529 If the name is omitted, it will look for
 530  - a model object in $c->stash{current_model_instance}, then
 531  - a model name in $c->stash->{current_model}, then
 532  - a config setting 'default_model', or
 533  - check if there is only one model, and return it if that's the case.
 534
 535 =cut
 536
 537 sub model {
 538     my ( $c, $name, @args ) = @_;
 539     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Model M/ ),
 540         @args )
 541       if $name;
 542     if (ref $c) {
 543         return $c->stash->{current_model_instance}
 544           if $c->stash->{current_model_instance};
 545         return $c->model( $c->stash->{current_model} )
 546           if $c->stash->{current_model};
 547     }
 548     return $c->model( $c->config->{default_model} )
 549       if $c->config->{default_model};
 550     return $c->_filter_component( $c->_comp_singular(qw/Model M/) );
 551
 552 }
 553
 554 =head2 $c->controllers
 555
 556 Returns the available names which can be passed to $c->controller
 557
 558 =cut
 559
 560 sub controllers {
 561     my ( $c ) = @_;
 562     return $c->_comp_names(qw/Controller C/);
 563 }
 564
 565
 566 =head2 $c->view($name)
 567
 568 Gets a L<Catalyst::View> instance by name.
 569
 570     $c->view('Foo')->do_stuff;
 571
 572 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 573
 574 If the name is omitted, it will look for
 575  - a view object in $c->stash{current_view_instance}, then
 576  - a view name in $c->stash->{current_view}, then
 577  - a config setting 'default_view', or
 578  - check if there is only one view, and return it if that's the case.
 579
 580 =cut
 581
 582 sub view {
 583     my ( $c, $name, @args ) = @_;
 584     return $c->_filter_component( $c->_comp_prefixes( $name, qw/View V/ ),
 585         @args )
 586       if $name;
 587     if (ref $c) {
 588         return $c->stash->{current_view_instance}
 589           if $c->stash->{current_view_instance};
 590         return $c->view( $c->stash->{current_view} )
 591           if $c->stash->{current_view};
 592     }
 593     return $c->view( $c->config->{default_view} )
 594       if $c->config->{default_view};
 595     return $c->_filter_component( $c->_comp_singular(qw/View V/) );
 596 }
 597
 598 =head2 $c->models
 599
 600 Returns the available names which can be passed to $c->model
 601
 602 =cut
 603
 604 sub models {
 605     my ( $c ) = @_;
 606     return $c->_comp_names(qw/Model M/);
 607 }
 608
 609
 610 =head2 $c->views
 611
 612 Returns the available names which can be passed to $c->view
 613
 614 =cut
 615
 616 sub views {
 617     my ( $c ) = @_;
 618     return $c->_comp_names(qw/View V/);
 619 }
 620
 621 =head2 $c->comp($name)
 622
 623 =head2 $c->component($name)
 624
 625 Gets a component object by name. This method is not recommended,
 626 unless you want to get a specific component by full
 627 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 628 should be used instead.
 629
 630 =cut
 631
 632 sub component {
 633     my $c = shift;
 634
 635     if (@_) {
 636
 637         my $name = shift;
 638
 639         my $appclass = ref $c || $c;
 640
 641         my @names = (
 642             $name, "${appclass}::${name}",
 643             map { "${appclass}::${_}::${name}" }
 644               qw/Model M Controller C View V/
 645         );
 646
 647         my $comp = $c->_comp_explicit(@names);
 648         return $c->_filter_component( $comp, @_ ) if defined($comp);
 649
 650         $comp = $c->_comp_search($name);
 651         return $c->_filter_component( $comp, @_ ) if defined($comp);
 652     }
 653
 654     return sort keys %{ $c->components };
 655 }
 656
 657
 658
 659 =head2 CLASS DATA AND HELPER CLASSES
 660
 661 =head2 $c->config
 662
 663 Returns or takes a hashref containing the application's configuration.
 664
 665     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 666
 667 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 668 like myapp.yml in your applications home directory. See
 669 L<Catalyst::Plugin::ConfigLoader>.
 670
 671     ---
 672     db: dsn:SQLite:foo.db
 673
 674
 675 =cut
 676
 677 sub config {
 678     my $c = shift;
 679
 680     $c->log->warn("Setting config after setup has been run is not a good idea.")
 681       if ( @_ and $c->setup_finished );
 682
 683     $c->NEXT::config(@_);
 684 }
 685
 686 =head2 $c->log
 687
 688 Returns the logging object instance. Unless it is already set, Catalyst
 689 sets this up with a L<Catalyst::Log> object. To use your own log class,
 690 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 691 C<< __PACKAGE__->setup >>.
 692
 693  __PACKAGE__->log( MyLogger->new );
 694  __PACKAGE__->setup;
 695
 696 And later:
 697
 698     $c->log->info( 'Now logging with my own logger!' );
 699
 700 Your log class should implement the methods described in
 701 L<Catalyst::Log>.
 702
 703
 704 =head2 $c->debug
 705
 706 Overload to enable debug messages (same as -Debug option).
 707
 708 Note that this is a static method, not an accessor and should be overloaded
 709 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 710
 711 =cut
 712
 713 sub debug { 0 }
 714
 715 =head2 $c->dispatcher
 716
 717 Returns the dispatcher instance. Stringifies to class name. See
 718 L<Catalyst::Dispatcher>.
 719
 720 =head2 $c->engine
 721
 722 Returns the engine instance. Stringifies to the class name. See
 723 L<Catalyst::Engine>.
 724
 725
 726 =head2 UTILITY METHODS
 727
 728 =head2 $c->path_to(@path)
 729
 730 Merges C<@path> with C<< $c->config->{home} >> and returns a
 731 L<Path::Class::Dir> object.
 732
 733 For example:
 734
 735     $c->path_to( 'db', 'sqlite.db' );
 736
 737 =cut
 738
 739 sub path_to {
 740     my ( $c, @path ) = @_;
 741     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 742     if ( -d $path ) { return $path }
 743     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 744 }
 745
 746 =head2 $c->plugin( $name, $class, @args )
 747
 748 Helper method for plugins. It creates a classdata accessor/mutator and
 749 loads and instantiates the given class.
 750
 751     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 752
 753     $c->prototype->define_javascript_functions;
 754
 755 =cut
 756
 757 sub plugin {
 758     my ( $class, $name, $plugin, @args ) = @_;
 759     $class->_register_plugin( $plugin, 1 );
 760
 761     eval { $plugin->import };
 762     $class->mk_classdata($name);
 763     my $obj;
 764     eval { $obj = $plugin->new(@args) };
 765
 766     if ($@) {
 767         Catalyst::Exception->throw( message =>
 768               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 769     }
 770
 771     $class->$name($obj);
 772     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 773       if $class->debug;
 774 }
 775
 776 =head2 MyApp->setup
 777
 778 Initializes the dispatcher and engine, loads any plugins, and loads the
 779 model, view, and controller components. You may also specify an array
 780 of plugins to load here, if you choose to not load them in the C<use
 781 Catalyst> line.
 782
 783     MyApp->setup;
 784     MyApp->setup( qw/-Debug/ );
 785
 786 =cut
 787
 788 sub setup {
 789     my ( $class, @arguments ) = @_;
 790
 791     $class->log->warn("Running setup twice is not a good idea.")
 792       if ( $class->setup_finished );
 793
 794     unless ( $class->isa('Catalyst') ) {
 795
 796         Catalyst::Exception->throw(
 797             message => qq/'$class' does not inherit from Catalyst/ );
 798     }
 799
 800     if ( $class->arguments ) {
 801         @arguments = ( @arguments, @{ $class->arguments } );
 802     }
 803
 804     # Process options
 805     my $flags = {};
 806
 807     foreach (@arguments) {
 808
 809         if (/^-Debug$/) {
 810             $flags->{log} =
 811               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 812         }
 813         elsif (/^-(\w+)=?(.*)$/) {
 814             $flags->{ lc $1 } = $2;
 815         }
 816         else {
 817             push @{ $flags->{plugins} }, $_;
 818         }
 819     }
 820
 821     $class->setup_home( delete $flags->{home} );
 822
 823     $class->setup_log( delete $flags->{log} );
 824     $class->setup_plugins( delete $flags->{plugins} );
 825     $class->setup_dispatcher( delete $flags->{dispatcher} );
 826     $class->setup_engine( delete $flags->{engine} );
 827     $class->setup_stats( delete $flags->{stats} );
 828
 829     for my $flag ( sort keys %{$flags} ) {
 830
 831         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 832             &$code( $class, delete $flags->{$flag} );
 833         }
 834         else {
 835             $class->log->warn(qq/Unknown flag "$flag"/);
 836         }
 837     }
 838
 839     eval { require Catalyst::Devel; };
 840     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 841         $class->log->warn(<<"EOF");
 842 You are running an old script!
 843
 844   Please update by running (this will overwrite existing files):
 845     catalyst.pl -force -scripts $class
 846
 847   or (this will not overwrite existing files):
 848     catalyst.pl -scripts $class
 849
 850 EOF
 851     }
 852
 853     if ( $class->debug ) {
 854         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 855
 856         if (@plugins) {
 857             my $t = Text::SimpleTable->new(74);
 858             $t->row($_) for @plugins;
 859             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 860         }
 861
 862         my $dispatcher = $class->dispatcher;
 863         my $engine     = $class->engine;
 864         my $home       = $class->config->{home};
 865
 866         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 867         $class->log->debug(qq/Loaded engine "$engine"/);
 868
 869         $home
 870           ? ( -d $home )
 871           ? $class->log->debug(qq/Found home "$home"/)
 872           : $class->log->debug(qq/Home "$home" doesn't exist/)
 873           : $class->log->debug(q/Couldn't find home/);
 874     }
 875
 876     # Call plugins setup
 877     {
 878         no warnings qw/redefine/;
 879         local *setup = sub { };
 880         $class->setup;
 881     }
 882
 883     # Initialize our data structure
 884     $class->components( {} );
 885
 886     $class->setup_components;
 887
 888     if ( $class->debug ) {
 889         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 890         for my $comp ( sort keys %{ $class->components } ) {
 891             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 892             $t->row( $comp, $type );
 893         }
 894         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 895           if ( keys %{ $class->components } );
 896     }
 897
 898     # Add our self to components, since we are also a component
 899     $class->components->{$class} = $class;
 900
 901     $class->setup_actions;
 902
 903     if ( $class->debug ) {
 904         my $name = $class->config->{name} || 'Application';
 905         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 906     }
 907     $class->log->_flush() if $class->log->can('_flush');
 908
 909     $class->setup_finished(1);
 910 }
 911
 912 =head2 $c->uri_for( $path, @args?, \%query_values? )
 913
 914 Merges path with C<< $c->request->base >> for absolute URIs and with
 915 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
 916 object. If any args are passed, they are added at the end of the path.
 917 If the last argument to C<uri_for> is a hash reference, it is assumed to
 918 contain GET parameter key/value pairs, which will be appended to the URI
 919 in standard fashion.
 920
 921 Note that uri_for is destructive to the passed hashref.  Subsequent calls
 922 with the same hashref may have unintended results.
 923
 924 Instead of C<$path>, you can also optionally pass a C<$action> object
 925 which will be resolved to a path using
 926 C<< $c->dispatcher->uri_for_action >>; if the first element of
 927 C<@args> is an arrayref it is treated as a list of captures to be passed
 928 to C<uri_for_action>.
 929
 930 =cut
 931
 932 sub uri_for {
 933     my ( $c, $path, @args ) = @_;
 934
 935     if ( Scalar::Util::blessed($path) ) { # action object
 936         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 937                          ? shift(@args)
 938                          : [] );
 939         $path = $c->dispatcher->uri_for_action($path, $captures);
 940         return undef unless defined($path);
 941         $path = '/' if $path eq '';
 942     }
 943
 944     undef($path) if (defined $path && $path eq '');
 945
 946     my $params =
 947       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 948
 949     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
 950     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
 951
 952     unshift(@args, $path);
 953
 954     unless (defined $path && $path =~ s!^/!!) { # in-place strip
 955         my $namespace = $c->namespace;
 956         if (defined $path) { # cheesy hack to handle path '../foo'
 957            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
 958         }
 959         unshift(@args, $namespace || '');
 960     }
 961
 962     # join args with '/', or a blank string
 963     my $args = join('/', grep { defined($_) } @args);
 964     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
 965     $args =~ s!^/!!;
 966     my $base = $c->req->base;
 967     my $class = ref($base);
 968     $base =~ s{(?<!/)$}{/};
 969
 970     my $query = '';
 971
 972     if (my @keys = keys %$params) {
 973       # somewhat lifted from URI::_query's query_form
 974       $query = '?'.join('&', map {
 975           my $val = $params->{$_};
 976           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
 977           s/ /+/g;
 978           my $key = $_;
 979           $val = '' unless defined $val;
 980           (map {
 981               $_ = "$_";
 982               utf8::encode( $_ ) if utf8::is_utf8($_);
 983               # using the URI::Escape pattern here so utf8 chars survive
 984               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
 985               s/ /+/g;
 986               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
 987       } @keys);
 988     }
 989
 990     my $res = bless(\"${base}${args}${query}", $class);
 991     $res;
 992 }
 993
 994 =head2 $c->welcome_message
 995
 996 Returns the Catalyst welcome HTML page.
 997
 998 =cut
 999
1000 sub welcome_message {
1001     my $c      = shift;
1002     my $name   = $c->config->{name};
1003     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1004     my $prefix = Catalyst::Utils::appprefix( ref $c );
1005     $c->response->content_type('text/html; charset=utf-8');
1006     return <<"EOF";
1007 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1008     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1009 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1010     <head>
1011     <meta http-equiv="Content-Language" content="en" />
1012     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1013         <title>$name on Catalyst $VERSION</title>
1014         <style type="text/css">
1015             body {
1016                 color: #000;
1017                 background-color: #eee;
1018             }
1019             div#content {
1020                 width: 640px;
1021                 margin-left: auto;
1022                 margin-right: auto;
1023                 margin-top: 10px;
1024                 margin-bottom: 10px;
1025                 text-align: left;
1026                 background-color: #ccc;
1027                 border: 1px solid #aaa;
1028             }
1029             p, h1, h2 {
1030                 margin-left: 20px;
1031                 margin-right: 20px;
1032                 font-family: verdana, tahoma, sans-serif;
1033             }
1034             a {
1035                 font-family: verdana, tahoma, sans-serif;
1036             }
1037             :link, :visited {
1038                     text-decoration: none;
1039                     color: #b00;
1040                     border-bottom: 1px dotted #bbb;
1041             }
1042             :link:hover, :visited:hover {
1043                     color: #555;
1044             }
1045             div#topbar {
1046                 margin: 0px;
1047             }
1048             pre {
1049                 margin: 10px;
1050                 padding: 8px;
1051             }
1052             div#answers {
1053                 padding: 8px;
1054                 margin: 10px;
1055                 background-color: #fff;
1056                 border: 1px solid #aaa;
1057             }
1058             h1 {
1059                 font-size: 0.9em;
1060                 font-weight: normal;
1061                 text-align: center;
1062             }
1063             h2 {
1064                 font-size: 1.0em;
1065             }
1066             p {
1067                 font-size: 0.9em;
1068             }
1069             p img {
1070                 float: right;
1071                 margin-left: 10px;
1072             }
1073             span#appname {
1074                 font-weight: bold;
1075                 font-size: 1.6em;
1076             }
1077         </style>
1078     </head>
1079     <body>
1080         <div id="content">
1081             <div id="topbar">
1082                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1083                     $VERSION</h1>
1084              </div>
1085              <div id="answers">
1086                  <p>
1087                  <img src="$logo" alt="Catalyst Logo" />
1088                  </p>
1089                  <p>Welcome to the  world of Catalyst.
1090                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1091                     framework will make web development something you had
1092                     never expected it to be: Fun, rewarding, and quick.</p>
1093                  <h2>What to do now?</h2>
1094                  <p>That really depends  on what <b>you</b> want to do.
1095                     We do, however, provide you with a few starting points.</p>
1096                  <p>If you want to jump right into web development with Catalyst
1097                     you might want to start with a tutorial.</p>
1098 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1099 </pre>
1100 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1101 <pre>
1102 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1103 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1104 </code></pre>
1105                  <h2>What to do next?</h2>
1106                  <p>Next it's time to write an actual application. Use the
1107                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1108                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1109                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1110                     they can save you a lot of work.</p>
1111                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1112                     <p>Also, be sure to check out the vast and growing
1113                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1114                     you are likely to find what you need there.
1115                     </p>
1116
1117                  <h2>Need help?</h2>
1118                  <p>Catalyst has a very active community. Here are the main places to
1119                     get in touch with us.</p>
1120                  <ul>
1121                      <li>
1122                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1123                      </li>
1124                      <li>
1125                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1126                      </li>
1127                      <li>
1128                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1129                      </li>
1130                  </ul>
1131                  <h2>In conclusion</h2>
1132                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1133                     as we enjoyed making it. Please contact us if you have ideas
1134                     for improvement or other feedback.</p>
1135              </div>
1136          </div>
1137     </body>
1138 </html>
1139 EOF
1140 }
1141
1142 =head1 INTERNAL METHODS
1143
1144 These methods are not meant to be used by end users.
1145
1146 =head2 $c->components
1147
1148 Returns a hash of components.
1149
1150 =head2 $c->context_class
1151
1152 Returns or sets the context class.
1153
1154 =head2 $c->counter
1155
1156 Returns a hashref containing coderefs and execution counts (needed for
1157 deep recursion detection).
1158
1159 =head2 $c->depth
1160
1161 Returns the number of actions on the current internal execution stack.
1162
1163 =head2 $c->dispatch
1164
1165 Dispatches a request to actions.
1166
1167 =cut
1168
1169 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1170
1171 =head2 $c->dispatcher_class
1172
1173 Returns or sets the dispatcher class.
1174
1175 =head2 $c->dump_these
1176
1177 Returns a list of 2-element array references (name, structure) pairs
1178 that will be dumped on the error page in debug mode.
1179
1180 =cut
1181
1182 sub dump_these {
1183     my $c = shift;
1184     [ Request => $c->req ],
1185     [ Response => $c->res ],
1186     [ Stash => $c->stash ],
1187     [ Config => $c->config ];
1188 }
1189
1190 =head2 $c->engine_class
1191
1192 Returns or sets the engine class.
1193
1194 =head2 $c->execute( $class, $coderef )
1195
1196 Execute a coderef in given class and catch exceptions. Errors are available
1197 via $c->error.
1198
1199 =cut
1200
1201 sub execute {
1202     my ( $c, $class, $code ) = @_;
1203     $class = $c->component($class) || $class;
1204     $c->state(0);
1205
1206     if ( $c->depth >= $RECURSION ) {
1207         my $action = "$code";
1208         $action = "/$action" unless $action =~ /->/;
1209         my $error = qq/Deep recursion detected calling "$action"/;
1210         $c->log->error($error);
1211         $c->error($error);
1212         $c->state(0);
1213         return $c->state;
1214     }
1215
1216     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1217
1218     push( @{ $c->stack }, $code );
1219
1220     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1221
1222     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1223
1224     my $last = pop( @{ $c->stack } );
1225
1226     if ( my $error = $@ ) {
1227         if ( !ref($error) and $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1228         else {
1229             unless ( ref $error ) {
1230                 no warnings 'uninitialized';
1231                 chomp $error;
1232                 my $class = $last->class;
1233                 my $name  = $last->name;
1234                 $error = qq/Caught exception in $class->$name "$error"/;
1235             }
1236             $c->error($error);
1237             $c->state(0);
1238         }
1239     }
1240     return $c->state;
1241 }
1242
1243 sub _stats_start_execute {
1244     my ( $c, $code ) = @_;
1245
1246     return if ( ( $code->name =~ /^_.*/ )
1247         && ( !$c->config->{show_internal_actions} ) );
1248
1249     $c->counter->{"$code"}++;
1250
1251     my $action = "$code";
1252     $action = "/$action" unless $action =~ /->/;
1253
1254     # determine if the call was the result of a forward
1255     # this is done by walking up the call stack and looking for a calling
1256     # sub of Catalyst::forward before the eval
1257     my $callsub = q{};
1258     for my $index ( 2 .. 11 ) {
1259         last
1260         if ( ( caller($index) )[0] eq 'Catalyst'
1261             && ( caller($index) )[3] eq '(eval)' );
1262
1263         if ( ( caller($index) )[3] =~ /forward$/ ) {
1264             $callsub = ( caller($index) )[3];
1265             $action  = "-> $action";
1266             last;
1267         }
1268     }
1269
1270     my $uid = "$code" . $c->counter->{"$code"};
1271
1272     # is this a root-level call or a forwarded call?
1273     if ( $callsub =~ /forward$/ ) {
1274
1275         # forward, locate the caller
1276         if ( my $parent = $c->stack->[-1] ) {
1277             $c->stats->profile(
1278                 begin  => $action,
1279                 parent => "$parent" . $c->counter->{"$parent"},
1280                 uid    => $uid,
1281             );
1282         }
1283         else {
1284
1285             # forward with no caller may come from a plugin
1286             $c->stats->profile(
1287                 begin => $action,
1288                 uid   => $uid,
1289             );
1290         }
1291     }
1292     else {
1293
1294         # root-level call
1295         $c->stats->profile(
1296             begin => $action,
1297             uid   => $uid,
1298         );
1299     }
1300     return $action;
1301
1302 }
1303
1304 sub _stats_finish_execute {
1305     my ( $c, $info ) = @_;
1306     $c->stats->profile( end => $info );
1307 }
1308
1309 =head2 $c->_localize_fields( sub { }, \%keys );
1310
1311 =cut
1312
1313 sub _localize_fields {
1314     my ( $c, $localized, $code ) = ( @_ );
1315
1316     my $request = delete $localized->{request} || {};
1317     my $response = delete $localized->{response} || {};
1318
1319     local @{ $c }{ keys %$localized } = values %$localized;
1320     local @{ $c->request }{ keys %$request } = values %$request;
1321     local @{ $c->response }{ keys %$response } = values %$response;
1322
1323     $code->();
1324 }
1325
1326 =head2 $c->finalize
1327
1328 Finalizes the request.
1329
1330 =cut
1331
1332 sub finalize {
1333     my $c = shift;
1334
1335     for my $error ( @{ $c->error } ) {
1336         $c->log->error($error);
1337     }
1338
1339     # Allow engine to handle finalize flow (for POE)
1340     if ( $c->engine->can('finalize') ) {
1341         $c->engine->finalize($c);
1342     }
1343     else {
1344
1345         $c->finalize_uploads;
1346
1347         # Error
1348         if ( $#{ $c->error } >= 0 ) {
1349             $c->finalize_error;
1350         }
1351
1352         $c->finalize_headers;
1353
1354         # HEAD request
1355         if ( $c->request->method eq 'HEAD' ) {
1356             $c->response->body('');
1357         }
1358
1359         $c->finalize_body;
1360     }
1361
1362     if ($c->use_stats) {
1363         my $elapsed = sprintf '%f', $c->stats->elapsed;
1364         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1365         $c->log->info(
1366             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1367     }
1368
1369     return $c->response->status;
1370 }
1371
1372 =head2 $c->finalize_body
1373
1374 Finalizes body.
1375
1376 =cut
1377
1378 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1379
1380 =head2 $c->finalize_cookies
1381
1382 Finalizes cookies.
1383
1384 =cut
1385
1386 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1387
1388 =head2 $c->finalize_error
1389
1390 Finalizes error.
1391
1392 =cut
1393
1394 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1395
1396 =head2 $c->finalize_headers
1397
1398 Finalizes headers.
1399
1400 =cut
1401
1402 sub finalize_headers {
1403     my $c = shift;
1404
1405     # Check if we already finalized headers
1406     return if $c->response->{_finalized_headers};
1407
1408     # Handle redirects
1409     if ( my $location = $c->response->redirect ) {
1410         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1411         $c->response->header( Location => $location );
1412
1413         if ( !$c->response->body ) {
1414             # Add a default body if none is already present
1415             $c->response->body(
1416                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1417             );
1418         }
1419     }
1420
1421     # Content-Length
1422     if ( $c->response->body && !$c->response->content_length ) {
1423
1424         # get the length from a filehandle
1425         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1426         {
1427             my $stat = stat $c->response->body;
1428             if ( $stat && $stat->size > 0 ) {
1429                 $c->response->content_length( $stat->size );
1430             }
1431             else {
1432                 $c->log->warn('Serving filehandle without a content-length');
1433             }
1434         }
1435         else {
1436             # everything should be bytes at this point, but just in case
1437             $c->response->content_length( bytes::length( $c->response->body ) );
1438         }
1439     }
1440
1441     # Errors
1442     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1443         $c->response->headers->remove_header("Content-Length");
1444         $c->response->body('');
1445     }
1446
1447     $c->finalize_cookies;
1448
1449     $c->engine->finalize_headers( $c, @_ );
1450
1451     # Done
1452     $c->response->{_finalized_headers} = 1;
1453 }
1454
1455 =head2 $c->finalize_output
1456
1457 An alias for finalize_body.
1458
1459 =head2 $c->finalize_read
1460
1461 Finalizes the input after reading is complete.
1462
1463 =cut
1464
1465 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1466
1467 =head2 $c->finalize_uploads
1468
1469 Finalizes uploads. Cleans up any temporary files.
1470
1471 =cut
1472
1473 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1474
1475 =head2 $c->get_action( $action, $namespace )
1476
1477 Gets an action in a given namespace.
1478
1479 =cut
1480
1481 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1482
1483 =head2 $c->get_actions( $action, $namespace )
1484
1485 Gets all actions of a given name in a namespace and all parent
1486 namespaces.
1487
1488 =cut
1489
1490 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1491
1492 =head2 $c->handle_request( $class, @arguments )
1493
1494 Called to handle each HTTP request.
1495
1496 =cut
1497
1498 sub handle_request {
1499     my ( $class, @arguments ) = @_;
1500
1501     # Always expect worst case!
1502     my $status = -1;
1503     eval {
1504         if ($class->debug) {
1505             my $secs = time - $START || 1;
1506             my $av = sprintf '%.3f', $COUNT / $secs;
1507             my $time = localtime time;
1508             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1509         }
1510
1511         my $c = $class->prepare(@arguments);
1512         $c->dispatch;
1513         $status = $c->finalize;
1514     };
1515
1516     if ( my $error = $@ ) {
1517         chomp $error;
1518         $class->log->error(qq/Caught exception in engine "$error"/);
1519     }
1520
1521     $COUNT++;
1522     $class->log->_flush() if $class->log->can('_flush');
1523     return $status;
1524 }
1525
1526 =head2 $c->prepare( @arguments )
1527
1528 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1529 etc.).
1530
1531 =cut
1532
1533 sub prepare {
1534     my ( $class, @arguments ) = @_;
1535
1536     $class->context_class( ref $class || $class ) unless $class->context_class;
1537     my $c = $class->context_class->new(
1538         {
1539             counter => {},
1540             stack   => [],
1541             request => $class->request_class->new(
1542                 {
1543                     arguments        => [],
1544                     body_parameters  => {},
1545                     cookies          => {},
1546                     headers          => HTTP::Headers->new,
1547                     parameters       => {},
1548                     query_parameters => {},
1549                     secure           => 0,
1550                     captures         => [],
1551                     uploads          => {}
1552                 }
1553             ),
1554             response => $class->response_class->new(
1555                 {
1556                     body    => '',
1557                     cookies => {},
1558                     headers => HTTP::Headers->new(),
1559                     status  => 200
1560                 }
1561             ),
1562             stash => {},
1563             state => 0
1564         }
1565     );
1566
1567     $c->stats($class->stats_class->new)->enable($c->use_stats);
1568     if ( $c->debug ) {
1569         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1570     }
1571
1572     # For on-demand data
1573     $c->request->{_context}  = $c;
1574     $c->response->{_context} = $c;
1575     weaken( $c->request->{_context} );
1576     weaken( $c->response->{_context} );
1577
1578     # Allow engine to direct the prepare flow (for POE)
1579     if ( $c->engine->can('prepare') ) {
1580         $c->engine->prepare( $c, @arguments );
1581     }
1582     else {
1583         $c->prepare_request(@arguments);
1584         $c->prepare_headers;
1585         $c->prepare_connection;
1586         $c->prepare_query_parameters;
1587         $c->prepare_cookies;
1588         $c->prepare_path;
1589
1590         # Prepare the body for reading, either by prepare_body
1591         # or the user, if they are using $c->read
1592         $c->prepare_read;
1593
1594         # Parse the body unless the user wants it on-demand
1595         unless ( $c->config->{parse_on_demand} ) {
1596             $c->prepare_body;
1597         }
1598     }
1599
1600     my $method  = $c->req->method  || '';
1601     my $path    = $c->req->path;
1602     $path       = '/' unless length $path;
1603     my $address = $c->req->address || '';
1604
1605     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1606       if $c->debug;
1607
1608     $c->prepare_action;
1609
1610     return $c;
1611 }
1612
1613 =head2 $c->prepare_action
1614
1615 Prepares action. See L<Catalyst::Dispatcher>.
1616
1617 =cut
1618
1619 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1620
1621 =head2 $c->prepare_body
1622
1623 Prepares message body.
1624
1625 =cut
1626
1627 sub prepare_body {
1628     my $c = shift;
1629
1630     # Do we run for the first time?
1631     return if defined $c->request->{_body};
1632
1633     # Initialize on-demand data
1634     $c->engine->prepare_body( $c, @_ );
1635     $c->prepare_parameters;
1636     $c->prepare_uploads;
1637
1638     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1639         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1640         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1641             my $param = $c->req->body_parameters->{$key};
1642             my $value = defined($param) ? $param : '';
1643             $t->row( $key,
1644                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1645         }
1646         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1647     }
1648 }
1649
1650 =head2 $c->prepare_body_chunk( $chunk )
1651
1652 Prepares a chunk of data before sending it to L<HTTP::Body>.
1653
1654 See L<Catalyst::Engine>.
1655
1656 =cut
1657
1658 sub prepare_body_chunk {
1659     my $c = shift;
1660     $c->engine->prepare_body_chunk( $c, @_ );
1661 }
1662
1663 =head2 $c->prepare_body_parameters
1664
1665 Prepares body parameters.
1666
1667 =cut
1668
1669 sub prepare_body_parameters {
1670     my $c = shift;
1671     $c->engine->prepare_body_parameters( $c, @_ );
1672 }
1673
1674 =head2 $c->prepare_connection
1675
1676 Prepares connection.
1677
1678 =cut
1679
1680 sub prepare_connection {
1681     my $c = shift;
1682     $c->engine->prepare_connection( $c, @_ );
1683 }
1684
1685 =head2 $c->prepare_cookies
1686
1687 Prepares cookies.
1688
1689 =cut
1690
1691 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1692
1693 =head2 $c->prepare_headers
1694
1695 Prepares headers.
1696
1697 =cut
1698
1699 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1700
1701 =head2 $c->prepare_parameters
1702
1703 Prepares parameters.
1704
1705 =cut
1706
1707 sub prepare_parameters {
1708     my $c = shift;
1709     $c->prepare_body_parameters;
1710     $c->engine->prepare_parameters( $c, @_ );
1711 }
1712
1713 =head2 $c->prepare_path
1714
1715 Prepares path and base.
1716
1717 =cut
1718
1719 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1720
1721 =head2 $c->adjust_request_for_proxy
1722
1723 Adjusts the request to account for a frontend proxy.
1724
1725 =cut
1726
1727 sub adjust_request_for_proxy { my $c = shift; $c->engine->adjust_request_for_proxy( $c, @_ ) }
1728
1729 =head2 $c->prepare_query_parameters
1730
1731 Prepares query parameters.
1732
1733 =cut
1734
1735 sub prepare_query_parameters {
1736     my $c = shift;
1737
1738     $c->engine->prepare_query_parameters( $c, @_ );
1739
1740     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1741         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1742         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1743             my $param = $c->req->query_parameters->{$key};
1744             my $value = defined($param) ? $param : '';
1745             $t->row( $key,
1746                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1747         }
1748         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1749     }
1750 }
1751
1752 =head2 $c->prepare_read
1753
1754 Prepares the input for reading.
1755
1756 =cut
1757
1758 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1759
1760 =head2 $c->prepare_request
1761
1762 Prepares the engine request.
1763
1764 =cut
1765
1766 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1767
1768 =head2 $c->prepare_uploads
1769
1770 Prepares uploads.
1771
1772 =cut
1773
1774 sub prepare_uploads {
1775     my $c = shift;
1776
1777     $c->engine->prepare_uploads( $c, @_ );
1778
1779     if ( $c->debug && keys %{ $c->request->uploads } ) {
1780         my $t = Text::SimpleTable->new(
1781             [ 12, 'Parameter' ],
1782             [ 26, 'Filename' ],
1783             [ 18, 'Type' ],
1784             [ 9,  'Size' ]
1785         );
1786         for my $key ( sort keys %{ $c->request->uploads } ) {
1787             my $upload = $c->request->uploads->{$key};
1788             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1789                 $t->row( $key, $u->filename, $u->type, $u->size );
1790             }
1791         }
1792         $c->log->debug( "File Uploads are:\n" . $t->draw );
1793     }
1794 }
1795
1796 =head2 $c->prepare_write
1797
1798 Prepares the output for writing.
1799
1800 =cut
1801
1802 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1803
1804 =head2 $c->request_class
1805
1806 Returns or sets the request class.
1807
1808 =head2 $c->response_class
1809
1810 Returns or sets the response class.
1811
1812 =head2 $c->read( [$maxlength] )
1813
1814 Reads a chunk of data from the request body. This method is designed to
1815 be used in a while loop, reading C<$maxlength> bytes on every call.
1816 C<$maxlength> defaults to the size of the request if not specified.
1817
1818 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1819 directly.
1820
1821 Warning: If you use read(), Catalyst will not process the body,
1822 so you will not be able to access POST parameters or file uploads via
1823 $c->request.  You must handle all body parsing yourself.
1824
1825 =cut
1826
1827 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1828
1829 =head2 $c->run
1830
1831 Starts the engine.
1832
1833 =cut
1834
1835 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1836
1837 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1838
1839 Sets an action in a given namespace.
1840
1841 =cut
1842
1843 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1844
1845 =head2 $c->setup_actions($component)
1846
1847 Sets up actions for a component.
1848
1849 =cut
1850
1851 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1852
1853 =head2 $c->setup_components
1854
1855 Sets up components. Specify a C<setup_components> config option to pass
1856 additional options directly to L<Module::Pluggable>. To add additional
1857 search paths, specify a key named C<search_extra> as an array
1858 reference. Items in the array beginning with C<::> will have the
1859 application class name prepended to them.
1860
1861 =cut
1862
1863 sub setup_components {
1864     my $class = shift;
1865
1866     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1867     my $config  = $class->config->{ setup_components };
1868     my $extra   = delete $config->{ search_extra } || [];
1869
1870     push @paths, @$extra;
1871
1872     my $locator = Module::Pluggable::Object->new(
1873         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1874         %$config
1875     );
1876
1877     my @comps = sort { length $a <=> length $b } $locator->plugins;
1878     my %comps = map { $_ => 1 } @comps;
1879
1880     for my $component ( @comps ) {
1881
1882         # We pass ignore_loaded here so that overlay files for (e.g.)
1883         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
1884         # we know M::P::O found a file on disk so this is safe
1885
1886         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1887
1888         my $module  = $class->setup_component( $component );
1889         my %modules = (
1890             $component => $module,
1891             map {
1892                 $_ => $class->setup_component( $_ )
1893             } grep {
1894               not exists $comps{$_}
1895             } Devel::InnerPackage::list_packages( $component )
1896         );
1897
1898         for my $key ( keys %modules ) {
1899             $class->components->{ $key } = $modules{ $key };
1900         }
1901     }
1902 }
1903
1904 =head2 $c->setup_component
1905
1906 =cut
1907
1908 sub setup_component {
1909     my( $class, $component ) = @_;
1910
1911     unless ( $component->can( 'COMPONENT' ) ) {
1912         return $component;
1913     }
1914
1915     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1916     my $config = $class->config->{ $suffix } || {};
1917
1918     my $instance = eval { $component->COMPONENT( $class, $config ); };
1919
1920     if ( my $error = $@ ) {
1921         chomp $error;
1922         Catalyst::Exception->throw(
1923             message => qq/Couldn't instantiate component "$component", "$error"/
1924         );
1925     }
1926
1927     Catalyst::Exception->throw(
1928         message =>
1929         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1930     ) unless eval { $instance->can( 'can' ) };
1931
1932     return $instance;
1933 }
1934
1935 =head2 $c->setup_dispatcher
1936
1937 Sets up dispatcher.
1938
1939 =cut
1940
1941 sub setup_dispatcher {
1942     my ( $class, $dispatcher ) = @_;
1943
1944     if ($dispatcher) {
1945         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1946     }
1947
1948     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
1949         $dispatcher = 'Catalyst::Dispatcher::' . $env;
1950     }
1951
1952     unless ($dispatcher) {
1953         $dispatcher = $class->dispatcher_class;
1954     }
1955
1956     unless (Class::Inspector->loaded($dispatcher)) {
1957         require Class::Inspector->filename($dispatcher);
1958     }
1959
1960     # dispatcher instance
1961     $class->dispatcher( $dispatcher->new );
1962 }
1963
1964 =head2 $c->setup_engine
1965
1966 Sets up engine.
1967
1968 =cut
1969
1970 sub setup_engine {
1971     my ( $class, $engine ) = @_;
1972
1973     if ($engine) {
1974         $engine = 'Catalyst::Engine::' . $engine;
1975     }
1976
1977     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
1978         $engine = 'Catalyst::Engine::' . $env;
1979     }
1980
1981     if ( $ENV{MOD_PERL} ) {
1982
1983         # create the apache method
1984         {
1985             no strict 'refs';
1986             *{"$class\::apache"} = sub { shift->engine->apache };
1987         }
1988
1989         my ( $software, $version ) =
1990           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1991
1992         $version =~ s/_//g;
1993         $version =~ s/(\.[^.]+)\./$1/g;
1994
1995         if ( $software eq 'mod_perl' ) {
1996
1997             if ( !$engine ) {
1998
1999                 if ( $version >= 1.99922 ) {
2000                     $engine = 'Catalyst::Engine::Apache2::MP20';
2001                 }
2002
2003                 elsif ( $version >= 1.9901 ) {
2004                     $engine = 'Catalyst::Engine::Apache2::MP19';
2005                 }
2006
2007                 elsif ( $version >= 1.24 ) {
2008                     $engine = 'Catalyst::Engine::Apache::MP13';
2009                 }
2010
2011                 else {
2012                     Catalyst::Exception->throw( message =>
2013                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2014                 }
2015
2016             }
2017
2018             # install the correct mod_perl handler
2019             if ( $version >= 1.9901 ) {
2020                 *handler = sub  : method {
2021                     shift->handle_request(@_);
2022                 };
2023             }
2024             else {
2025                 *handler = sub ($$) { shift->handle_request(@_) };
2026             }
2027
2028         }
2029
2030         elsif ( $software eq 'Zeus-Perl' ) {
2031             $engine = 'Catalyst::Engine::Zeus';
2032         }
2033
2034         else {
2035             Catalyst::Exception->throw(
2036                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2037         }
2038     }
2039
2040     unless ($engine) {
2041         $engine = $class->engine_class;
2042     }
2043
2044     unless (Class::Inspector->loaded($engine)) {
2045         require Class::Inspector->filename($engine);
2046     }
2047
2048     # check for old engines that are no longer compatible
2049     my $old_engine;
2050     if ( $engine->isa('Catalyst::Engine::Apache')
2051         && !Catalyst::Engine::Apache->VERSION )
2052     {
2053         $old_engine = 1;
2054     }
2055
2056     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2057         && Catalyst::Engine::Server->VERSION le '0.02' )
2058     {
2059         $old_engine = 1;
2060     }
2061
2062     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2063         && $engine->VERSION eq '0.01' )
2064     {
2065         $old_engine = 1;
2066     }
2067
2068     elsif ($engine->isa('Catalyst::Engine::Zeus')
2069         && $engine->VERSION eq '0.01' )
2070     {
2071         $old_engine = 1;
2072     }
2073
2074     if ($old_engine) {
2075         Catalyst::Exception->throw( message =>
2076               qq/Engine "$engine" is not supported by this version of Catalyst/
2077         );
2078     }
2079
2080     # engine instance
2081     $class->engine( $engine->new );
2082 }
2083
2084 =head2 $c->setup_home
2085
2086 Sets up the home directory.
2087
2088 =cut
2089
2090 sub setup_home {
2091     my ( $class, $home ) = @_;
2092
2093     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2094         $home = $env;
2095     }
2096
2097     unless ($home) {
2098         $home = Catalyst::Utils::home($class);
2099     }
2100
2101     if ($home) {
2102         $class->config->{home} ||= $home;
2103         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2104     }
2105 }
2106
2107 =head2 $c->setup_log
2108
2109 Sets up log.
2110
2111 =cut
2112
2113 sub setup_log {
2114     my ( $class, $debug ) = @_;
2115
2116     unless ( $class->log ) {
2117         $class->log( Catalyst::Log->new );
2118     }
2119
2120     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2121     if ( defined($env_debug) ? $env_debug : $debug ) {
2122         no strict 'refs';
2123         *{"$class\::debug"} = sub { 1 };
2124         $class->log->debug('Debug messages enabled');
2125     }
2126 }
2127
2128 =head2 $c->setup_plugins
2129
2130 Sets up plugins.
2131
2132 =cut
2133
2134 =head2 $c->setup_stats
2135
2136 Sets up timing statistics class.
2137
2138 =cut
2139
2140 sub setup_stats {
2141     my ( $class, $stats ) = @_;
2142
2143     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2144
2145     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2146     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2147         no strict 'refs';
2148         *{"$class\::use_stats"} = sub { 1 };
2149         $class->log->debug('Statistics enabled');
2150     }
2151 }
2152
2153
2154 =head2 $c->registered_plugins
2155
2156 Returns a sorted list of the plugins which have either been stated in the
2157 import list or which have been added via C<< MyApp->plugin(@args); >>.
2158
2159 If passed a given plugin name, it will report a boolean value indicating
2160 whether or not that plugin is loaded.  A fully qualified name is required if
2161 the plugin name does not begin with C<Catalyst::Plugin::>.
2162
2163  if ($c->registered_plugins('Some::Plugin')) {
2164      ...
2165  }
2166
2167 =cut
2168
2169 {
2170
2171     sub registered_plugins {
2172         my $proto = shift;
2173         return sort keys %{ $proto->_plugins } unless @_;
2174         my $plugin = shift;
2175         return 1 if exists $proto->_plugins->{$plugin};
2176         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2177     }
2178
2179     sub _register_plugin {
2180         my ( $proto, $plugin, $instant ) = @_;
2181         my $class = ref $proto || $proto;
2182
2183         # no ignore_loaded here, the plugin may already have been
2184         # defined in memory and we don't want to error on "no file" if so
2185
2186         Catalyst::Utils::ensure_class_loaded( $plugin );
2187
2188         $proto->_plugins->{$plugin} = 1;
2189         unless ($instant) {
2190             no strict 'refs';
2191             unshift @{"$class\::ISA"}, $plugin;
2192         }
2193         return $class;
2194     }
2195
2196     sub setup_plugins {
2197         my ( $class, $plugins ) = @_;
2198
2199         $class->_plugins( {} ) unless $class->_plugins;
2200         $plugins ||= [];
2201         for my $plugin ( reverse @$plugins ) {
2202
2203             unless ( $plugin =~ s/\A\+// ) {
2204                 $plugin = "Catalyst::Plugin::$plugin";
2205             }
2206
2207             $class->_register_plugin($plugin);
2208         }
2209     }
2210 }
2211
2212 =head2 $c->stack
2213
2214 Returns an arrayref of the internal execution stack (actions that are
2215 currently executing).
2216
2217 =head2 $c->stats_class
2218
2219 Returns or sets the stats (timing statistics) class.
2220
2221 =head2 $c->use_stats
2222
2223 Returns 1 when stats collection is enabled.  Stats collection is enabled
2224 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2225 environment variable is set.
2226
2227 Note that this is a static method, not an accessor and should be overloaded
2228 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2229
2230 =cut
2231
2232 sub use_stats { 0 }
2233
2234
2235 =head2 $c->write( $data )
2236
2237 Writes $data to the output stream. When using this method directly, you
2238 will need to manually set the C<Content-Length> header to the length of
2239 your output data, if known.
2240
2241 =cut
2242
2243 sub write {
2244     my $c = shift;
2245
2246     # Finalize headers if someone manually writes output
2247     $c->finalize_headers;
2248
2249     return $c->engine->write( $c, @_ );
2250 }
2251
2252 =head2 version
2253
2254 Returns the Catalyst version number. Mostly useful for "powered by"
2255 messages in template systems.
2256
2257 =cut
2258
2259 sub version { return $Catalyst::VERSION }
2260
2261 =head1 INTERNAL ACTIONS
2262
2263 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2264 C<_ACTION>, and C<_END>. These are by default not shown in the private
2265 action table, but you can make them visible with a config parameter.
2266
2267     MyApp->config->{show_internal_actions} = 1;
2268
2269 =head1 CASE SENSITIVITY
2270
2271 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2272 mapped to C</foo/bar>. You can activate case sensitivity with a config
2273 parameter.
2274
2275     MyApp->config->{case_sensitive} = 1;
2276
2277 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2278
2279 =head1 ON-DEMAND PARSER
2280
2281 The request body is usually parsed at the beginning of a request,
2282 but if you want to handle input yourself, you can enable on-demand
2283 parsing with a config parameter.
2284
2285     MyApp->config->{parse_on_demand} = 1;
2286
2287 =head1 PROXY SUPPORT
2288
2289 Many production servers operate using the common double-server approach,
2290 with a lightweight frontend web server passing requests to a larger
2291 backend server. An application running on the backend server must deal
2292 with two problems: the remote user always appears to be C<127.0.0.1> and
2293 the server's hostname will appear to be C<localhost> regardless of the
2294 virtual host that the user connected through.
2295
2296 Catalyst will automatically detect this situation when you are running
2297 the frontend and backend servers on the same machine. The following
2298 changes are made to the request.
2299
2300 =over 4
2301
2302 =item * X-Forwarded-For
2303
2304 The IP address in C<< $c->req->address >> is set to the user's real IP
2305 address, as read from the X-Forwarded-For header.
2306
2307 =item * X-Forwarded-Host
2308
2309 The host value for C<< $c->req->base >> and C<< $c->req->uri >> is set
2310 to the real host, as read from the X-Forwarded-Host header. The value
2311 of C<< $c->req->hostname >> is also adjusted accordingly.
2312
2313 =item * X-Forwarded-Port
2314
2315 The port value for C<< $c->req->base >> and C<< $c->req->uri >> is set
2316 to the real port, as read from the X-Forwarded-Port header.
2317
2318 =item * X-Forwarded-Path
2319
2320 If this is set, the value of the X-Forwarded-Path header is
2321 I<prepended> to the path value of C<< $c->req->base >> and C<<
2322 $c->req->uri >>.
2323
2324 =item * X-Forwarded-Is-SSL
2325
2326 If this is set, the scheme value of C<< $c->req->base >> and C<<
2327 $c->req->uri >> is set to "https". Additional, C<< $c->req->protocol
2328 >> is also set to "https", and C<< $c->req->secure >> is set to a true
2329 value.
2330
2331 =back
2332
2333 Obviously, your web server must support these headers for this to work.
2334
2335 In a more complex server farm environment where you may have your
2336 frontend proxy server(s) on different machines, you will need to set a
2337 configuration option to tell Catalyst to read the proxied data from the
2338 headers.
2339
2340     MyApp->config->{using_frontend_proxy} = 1;
2341
2342 If you do not wish to use the proxy support at all, you may set:
2343
2344     MyApp->config->{ignore_frontend_proxy} = 1;
2345
2346 =head1 THREAD SAFETY
2347
2348 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2349 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2350 believe the Catalyst core to be thread-safe.
2351
2352 If you plan to operate in a threaded environment, remember that all other
2353 modules you are using must also be thread-safe. Some modules, most notably
2354 L<DBD::SQLite>, are not thread-safe.
2355
2356 =head1 SUPPORT
2357
2358 IRC:
2359
2360     Join #catalyst on irc.perl.org.
2361
2362 Mailing Lists:
2363
2364     http://lists.rawmode.org/mailman/listinfo/catalyst
2365     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2366
2367 Web:
2368
2369     http://catalyst.perl.org
2370
2371 Wiki:
2372
2373     http://dev.catalyst.perl.org
2374
2375 =head1 SEE ALSO
2376
2377 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2378
2379 =head2 L<Catalyst::Manual> - The Catalyst Manual
2380
2381 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2382
2383 =head2 L<Catalyst::Engine> - Core engine
2384
2385 =head2 L<Catalyst::Log> - Log class.
2386
2387 =head2 L<Catalyst::Request> - Request object
2388
2389 =head2 L<Catalyst::Response> - Response object
2390
2391 =head2 L<Catalyst::Test> - The test suite.
2392
2393 =head1 CREDITS
2394
2395 Andy Grundman
2396
2397 Andy Wardley
2398
2399 Andreas Marienborg
2400
2401 Andrew Bramble
2402
2403 Andrew Ford
2404
2405 Andrew Ruthven
2406
2407 Arthur Bergman
2408
2409 Autrijus Tang
2410
2411 Brian Cassidy
2412
2413 Carl Franks
2414
2415 Christian Hansen
2416
2417 Christopher Hicks
2418
2419 Dan Sully
2420
2421 Danijel Milicevic
2422
2423 David Kamholz
2424
2425 David Naughton
2426
2427 Drew Taylor
2428
2429 Gary Ashton Jones
2430
2431 Geoff Richards
2432
2433 Jesse Sheidlower
2434
2435 Jesse Vincent
2436
2437 Jody Belka
2438
2439 Johan Lindstrom
2440
2441 Juan Camacho
2442
2443 Leon Brocard
2444
2445 Marcus Ramberg
2446
2447 Matt S Trout
2448
2449 Robert Sedlacek
2450
2451 Sam Vilain
2452
2453 Sascha Kiefer
2454
2455 Sebastian Willert
2456
2457 Tatsuhiko Miyagawa
2458
2459 Ulf Edvinsson
2460
2461 Yuval Kogman
2462
2463 =head1 AUTHOR
2464
2465 Sebastian Riedel, C<sri@oook.de>
2466
2467 =head1 LICENSE
2468
2469 This library is free software, you can redistribute it and/or modify it under
2470 the same terms as Perl itself.
2471
2472 =cut
2473
2474 1;