lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use File::stat;
  19 use Text::SimpleTable ();
  20 use Path::Class::Dir ();
  21 use Path::Class::File ();
  22 use URI ();
  23 use URI::http;
  24 use URI::https;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use Class::C3::Adopt::NEXT;
  28 use List::MoreUtils qw/uniq/;
  29 use attributes;
  30 use utf8;
  31 use Carp qw/croak carp shortmess/;
  32
  33 BEGIN { require 5.008004; }
  34
  35 has stack => (is => 'ro', default => sub { [] });
  36 has stash => (is => 'rw', default => sub { {} });
  37 has state => (is => 'rw', default => 0);
  38 has stats => (is => 'rw');
  39 has action => (is => 'rw');
  40 has counter => (is => 'rw', default => sub { {} });
  41 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  42 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  43 has namespace => (is => 'rw');
  44
  45 sub depth { scalar @{ shift->stack || [] }; }
  46 sub comp { shift->component(@_) }
  47
  48 sub req {
  49     my $self = shift; return $self->request(@_);
  50 }
  51 sub res {
  52     my $self = shift; return $self->response(@_);
  53 }
  54
  55 # For backwards compatibility
  56 sub finalize_output { shift->finalize_body(@_) };
  57
  58 # For statistics
  59 our $COUNT     = 1;
  60 our $START     = time;
  61 our $RECURSION = 1000;
  62 our $DETACH    = Catalyst::Exception::Detach->new;
  63 our $GO        = Catalyst::Exception::Go->new;
  64
  65 #I imagine that very few of these really need to be class variables. if any.
  66 #maybe we should just make them attributes with a default?
  67 __PACKAGE__->mk_classdata($_)
  68   for qw/container arguments dispatcher engine log dispatcher_class
  69   engine_class context_class request_class response_class stats_class
  70   setup_finished/;
  71
  72 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  73 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  74 __PACKAGE__->request_class('Catalyst::Request');
  75 __PACKAGE__->response_class('Catalyst::Response');
  76 __PACKAGE__->stats_class('Catalyst::Stats');
  77
  78 # Remember to update this in Catalyst::Runtime as well!
  79
  80 our $VERSION = '5.80033';
  81
  82 sub import {
  83     my ( $class, @arguments ) = @_;
  84
  85     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  86     # callers @ISA.
  87     return unless $class eq 'Catalyst';
  88
  89     my $caller = caller();
  90     return if $caller eq 'main';
  91
  92     my $meta = Moose::Meta::Class->initialize($caller);
  93
  94     unless ( $caller->isa('Catalyst') ) { # XXX - Remove!
  95         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Component'); # XXX - Remove!
  96         $meta->superclasses(@superclasses); # XXX - Remove!
  97     } # XXX - Remove!
  98
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub MODIFY_CODE_ATTRIBUTES {
 116     Catalyst::Exception->throw(
 117         "Catalyst applications (aka MyApp) cannot be controllers anymore. " .
 118         "That has been deprecated and removed. You should create a " .
 119         "controller class called Root.pm, and move relevant code to that class."
 120     );
 121 }
 122
 123
 124 sub _application { $_[0] }
 125
 126 =head1 NAME
 127
 128 Catalyst - The Elegant MVC Web Application Framework
 129
 130 =head1 SYNOPSIS
 131
 132 See the L<Catalyst::Manual> distribution for comprehensive
 133 documentation and tutorials.
 134
 135     # Install Catalyst::Devel for helpers and other development tools
 136     # use the helper to create a new application
 137     catalyst.pl MyApp
 138
 139     # add models, views, controllers
 140     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 141     script/myapp_create.pl view MyTemplate TT
 142     script/myapp_create.pl controller Search
 143
 144     # built in testserver -- use -r to restart automatically on changes
 145     # --help to see all available options
 146     script/myapp_server.pl
 147
 148     # command line testing interface
 149     script/myapp_test.pl /yada
 150
 151     ### in lib/MyApp.pm
 152     use Catalyst qw/-Debug/; # include plugins here as well
 153
 154     ### In lib/MyApp/Controller/Root.pm (autocreated)
 155     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 156         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 157         $c->stash->{template} = 'foo.tt'; # set the template
 158         # lookup something from db -- stash vars are passed to TT
 159         $c->stash->{data} =
 160           $c->model('Database::Foo')->search( { country => $args[0] } );
 161         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 162             $c->forward( 'bar' ); # process another action
 163             # do something else after forward returns
 164         }
 165     }
 166
 167     # The foo.tt TT template can use the stash data from the database
 168     [% WHILE (item = data.next) %]
 169         [% item.foo %]
 170     [% END %]
 171
 172     # called for /bar/of/soap, /bar/of/soap/10, etc.
 173     sub bar : Path('/bar/of/soap') { ... }
 174
 175     # called for all actions, from the top-most controller downwards
 176     sub auto : Private {
 177         my ( $self, $c ) = @_;
 178         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 179             $c->res->redirect( '/login' ); # require login
 180             return 0; # abort request and go immediately to end()
 181         }
 182         return 1; # success; carry on to next action
 183     }
 184
 185     # called after all actions are finished
 186     sub end : Private {
 187         my ( $self, $c ) = @_;
 188         if ( scalar @{ $c->error } ) { ... } # handle errors
 189         return if $c->res->body; # already have a response
 190         $c->forward( 'MyApp::View::TT' ); # render template
 191     }
 192
 193     ### in MyApp/Controller/Foo.pm
 194     # called for /foo/bar
 195     sub bar : Local { ... }
 196
 197     # called for /blargle
 198     sub blargle : Global { ... }
 199
 200     # an index action matches /foo, but not /foo/1, etc.
 201     sub index : Private { ... }
 202
 203     ### in MyApp/Controller/Foo/Bar.pm
 204     # called for /foo/bar/baz
 205     sub baz : Local { ... }
 206
 207     # first Root auto is called, then Foo auto, then this
 208     sub auto : Private { ... }
 209
 210     # powerful regular expression paths are also possible
 211     sub details : Regex('^product/(\w+)/details$') {
 212         my ( $self, $c ) = @_;
 213         # extract the (\w+) from the URI
 214         my $product = $c->req->captures->[0];
 215     }
 216
 217 See L<Catalyst::Manual::Intro> for additional information.
 218
 219 =head1 DESCRIPTION
 220
 221 Catalyst is a modern framework for making web applications without the
 222 pain usually associated with this process. This document is a reference
 223 to the main Catalyst application. If you are a new user, we suggest you
 224 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 225
 226 See L<Catalyst::Manual> for more documentation.
 227
 228 Catalyst plugins can be loaded by naming them as arguments to the "use
 229 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 230 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 231 C<My::Module>.
 232
 233     use Catalyst qw/My::Module/;
 234
 235 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 236 fully qualify the name by using a unary plus:
 237
 238     use Catalyst qw/
 239         My::Module
 240         +Fully::Qualified::Plugin::Name
 241     /;
 242
 243 Special flags like C<-Debug> and C<-Engine> can also be specified as
 244 arguments when Catalyst is loaded:
 245
 246     use Catalyst qw/-Debug My::Module/;
 247
 248 The position of plugins and flags in the chain is important, because
 249 they are loaded in the order in which they appear.
 250
 251 The following flags are supported:
 252
 253 =head2 -Debug
 254
 255 Enables debug output. You can also force this setting from the system
 256 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 257 settings override the application, with <MYAPP>_DEBUG having the highest
 258 priority.
 259
 260 This sets the log level to 'debug' and enables full debug output on the
 261 error screen. If you only want the latter, see L<< $c->debug >>.
 262
 263 =head2 -Engine
 264
 265 Forces Catalyst to use a specific engine. Omit the
 266 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 267
 268     use Catalyst qw/-Engine=CGI/;
 269
 270 =head2 -Home
 271
 272 Forces Catalyst to use a specific home directory, e.g.:
 273
 274     use Catalyst qw[-Home=/usr/mst];
 275
 276 This can also be done in the shell environment by setting either the
 277 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 278 is replaced with the uppercased name of your application, any "::" in
 279 the name will be replaced with underscores, e.g. MyApp::Web should use
 280 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 281
 282 If none of these are set, Catalyst will attempt to automatically detect the
 283 home directory. If you are working in a development envirnoment, Catalyst
 284 will try and find the directory containing either Makefile.PL, Build.PL or
 285 dist.ini. If the application has been installed into the system (i.e.
 286 you have done C<make install>), then Catalyst will use the path to your
 287 application module, without the .pm extension (ie, /foo/MyApp if your
 288 application was installed at /foo/MyApp.pm)
 289
 290 =head2 -Log
 291
 292     use Catalyst '-Log=warn,fatal,error';
 293
 294 Specifies a comma-delimited list of log levels.
 295
 296 =head2 -Stats
 297
 298 Enables statistics collection and reporting.
 299
 300    use Catalyst qw/-Stats=1/;
 301
 302 You can also force this setting from the system environment with CATALYST_STATS
 303 or <MYAPP>_STATS. The environment settings override the application, with
 304 <MYAPP>_STATS having the highest priority.
 305
 306 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 307
 308 =head1 METHODS
 309
 310 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 311
 312 =head2 $c->action
 313
 314 Returns a L<Catalyst::Action> object for the current action, which
 315 stringifies to the action name. See L<Catalyst::Action>.
 316
 317 =head2 $c->namespace
 318
 319 Returns the namespace of the current action, i.e., the URI prefix
 320 corresponding to the controller of the current action. For example:
 321
 322     # in Controller::Foo::Bar
 323     $c->namespace; # returns 'foo/bar';
 324
 325 =head2 $c->request
 326
 327 =head2 $c->req
 328
 329 Returns the current L<Catalyst::Request> object, giving access to
 330 information about the current client request (including parameters,
 331 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 332
 333 =head2 REQUEST FLOW HANDLING
 334
 335 =head2 $c->forward( $action [, \@arguments ] )
 336
 337 =head2 $c->forward( $class, $method, [, \@arguments ] )
 338
 339 Forwards processing to another action, by its private name. If you give a
 340 class name but no method, C<process()> is called. You may also optionally
 341 pass arguments in an arrayref. The action will receive the arguments in
 342 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 343 C<< $c->req->args >> will be restored to the previous values.
 344
 345 Any data C<return>ed from the action forwarded to, will be returned by the
 346 call to forward.
 347
 348     my $foodata = $c->forward('/foo');
 349     $c->forward('index');
 350     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 351     $c->forward('View::TT');
 352
 353 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 354 an C<< eval { } >> around the call (actually
 355 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 356 all 'dies' within the called action. If you want C<die> to propagate you
 357 need to do something like:
 358
 359     $c->forward('foo');
 360     die join "\n", @{ $c->error } if @{ $c->error };
 361
 362 Or make sure to always return true values from your actions and write
 363 your code like this:
 364
 365     $c->forward('foo') || return;
 366
 367 Another note is that C<< $c->forward >> always returns a scalar because it
 368 actually returns $c->state which operates in a scalar context.
 369 Thus, something like:
 370
 371     return @array;
 372
 373 in an action that is forwarded to is going to return a scalar,
 374 i.e. how many items are in that array, which is probably not what you want.
 375 If you need to return an array then return a reference to it,
 376 or stash it like so:
 377
 378     $c->stash->{array} = \@array;
 379
 380 and access it from the stash.
 381
 382 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 383
 384 =cut
 385
 386 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 387
 388 =head2 $c->detach( $action [, \@arguments ] )
 389
 390 =head2 $c->detach( $class, $method, [, \@arguments ] )
 391
 392 =head2 $c->detach()
 393
 394 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 395 doesn't return to the previous action when processing is finished.
 396
 397 When called with no arguments it escapes the processing chain entirely.
 398
 399 =cut
 400
 401 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 402
 403 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 404
 405 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 406
 407 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 408 but does a full dispatch, instead of just calling the new C<$action> /
 409 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 410 you go to are called, just like a new request.
 411
 412 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 413 This means, for example, that C<< $c->action >> methods such as
 414 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 415 L<reverse|Catalyst::Action/reverse> return information for the visited action
 416 when they are invoked within the visited action.  This is different from the
 417 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 418 continues to use the $c->action object from the caller action even when
 419 invoked from the callee.
 420
 421 C<< $c->stash >> is kept unchanged.
 422
 423 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 424 allows you to "wrap" another action, just as it would have been called by
 425 dispatching from a URL, while the analogous
 426 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 427 transfer control to another action as if it had been reached directly from a URL.
 428
 429 =cut
 430
 431 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 432
 433 =head2 $c->go( $action [, \@captures, \@arguments ] )
 434
 435 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 436
 437 The relationship between C<go> and
 438 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 439 the relationship between
 440 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 441 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 442 C<< $c->go >> will perform a full dispatch on the specified action or method,
 443 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 444 C<go> escapes the processing of the current request chain on completion, and
 445 does not return to its caller.
 446
 447 @arguments are arguments to the final destination of $action. @captures are
 448 arguments to the intermediate steps, if any, on the way to the final sub of
 449 $action.
 450
 451 =cut
 452
 453 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 454
 455 =head2 $c->response
 456
 457 =head2 $c->res
 458
 459 Returns the current L<Catalyst::Response> object, see there for details.
 460
 461 =head2 $c->stash
 462
 463 Returns a hashref to the stash, which may be used to store data and pass
 464 it between components during a request. You can also set hash keys by
 465 passing arguments. The stash is automatically sent to the view. The
 466 stash is cleared at the end of a request; it cannot be used for
 467 persistent storage (for this you must use a session; see
 468 L<Catalyst::Plugin::Session> for a complete system integrated with
 469 Catalyst).
 470
 471     $c->stash->{foo} = $bar;
 472     $c->stash( { moose => 'majestic', qux => 0 } );
 473     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 474
 475     # stash is automatically passed to the view for use in a template
 476     $c->forward( 'MyApp::View::TT' );
 477
 478 =cut
 479
 480 around stash => sub {
 481     my $orig = shift;
 482     my $c = shift;
 483     my $stash = $orig->($c);
 484     if (@_) {
 485         my $new_stash = @_ > 1 ? {@_} : $_[0];
 486         croak('stash takes a hash or hashref') unless ref $new_stash;
 487         foreach my $key ( keys %$new_stash ) {
 488           $stash->{$key} = $new_stash->{$key};
 489         }
 490     }
 491
 492     return $stash;
 493 };
 494
 495
 496 =head2 $c->error
 497
 498 =head2 $c->error($error, ...)
 499
 500 =head2 $c->error($arrayref)
 501
 502 Returns an arrayref containing error messages.  If Catalyst encounters an
 503 error while processing a request, it stores the error in $c->error.  This
 504 method should only be used to store fatal error messages.
 505
 506     my @error = @{ $c->error };
 507
 508 Add a new error.
 509
 510     $c->error('Something bad happened');
 511
 512 =cut
 513
 514 sub error {
 515     my $c = shift;
 516     if ( $_[0] ) {
 517         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 518         croak @$error unless ref $c;
 519         push @{ $c->{error} }, @$error;
 520     }
 521     elsif ( defined $_[0] ) { $c->{error} = undef }
 522     return $c->{error} || [];
 523 }
 524
 525
 526 =head2 $c->state
 527
 528 Contains the return value of the last executed action.
 529 Note that << $c->state >> operates in a scalar context which means that all
 530 values it returns are scalar.
 531
 532 =head2 $c->clear_errors
 533
 534 Clear errors.  You probably don't want to clear the errors unless you are
 535 implementing a custom error screen.
 536
 537 This is equivalent to running
 538
 539     $c->error(0);
 540
 541 =cut
 542
 543 sub clear_errors {
 544     my $c = shift;
 545     $c->error(0);
 546 }
 547
 548 =head2 COMPONENT ACCESSORS
 549
 550 =head2 $c->controller($name)
 551
 552 Gets a L<Catalyst::Controller> instance by name.
 553
 554     $c->controller('Foo')->do_stuff;
 555
 556 If the name is omitted, will return the controller for the dispatched
 557 action.
 558
 559 If you want to search for controllers, pass in a regexp as the argument.
 560
 561     # find all controllers that start with Foo
 562     my @foo_controllers = $c->controller(qr{^Foo});
 563
 564
 565 =cut
 566
 567 sub controller {
 568     my ( $c, $name, @args ) = @_;
 569
 570     $name ||= Catalyst::Utils::class2classshortsuffix( $c->action->class );
 571
 572     return $c->container->get_component_from_sub_container( 'controller', $name, $c, @args);
 573 }
 574
 575 =head2 $c->model($name)
 576
 577 Gets a L<Catalyst::Model> instance by name.
 578
 579     $c->model('Foo')->do_stuff;
 580
 581 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 582
 583 If the name is omitted, it will look for
 584  - a model object in $c->stash->{current_model_instance}, then
 585  - a model name in $c->stash->{current_model}, then
 586  - a config setting 'default_model', or
 587  - check if there is only one model, and return it if that's the case.
 588
 589 If you want to search for models, pass in a regexp as the argument.
 590
 591     # find all models that start with Foo
 592     my @foo_models = $c->model(qr{^Foo});
 593
 594 =cut
 595
 596 sub model {
 597     my ( $c, $name, @args ) = @_;
 598
 599     if (ref $c && !$name) {
 600         my $current_instance = $c->stash->{current_model_instance};
 601         return $current_instance
 602             if $current_instance;
 603
 604         $name = $c->stash->{current_model};
 605     }
 606
 607     return $c->container->get_component_from_sub_container( 'model', $name, $c, @args);
 608 }
 609
 610
 611 =head2 $c->view($name)
 612
 613 Gets a L<Catalyst::View> instance by name.
 614
 615     $c->view('Foo')->do_stuff;
 616
 617 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 618
 619 If the name is omitted, it will look for
 620  - a view object in $c->stash->{current_view_instance}, then
 621  - a view name in $c->stash->{current_view}, then
 622  - a config setting 'default_view', or
 623  - check if there is only one view, and return it if that's the case.
 624
 625 If you want to search for views, pass in a regexp as the argument.
 626
 627     # find all views that start with Foo
 628     my @foo_views = $c->view(qr{^Foo});
 629
 630 =cut
 631
 632 sub view {
 633     my ( $c, $name, @args ) = @_;
 634
 635     if (ref $c && !$name) {
 636         my $current_instance = $c->stash->{current_view_instance};
 637         return $current_instance
 638             if $current_instance;
 639
 640         $name = $c->stash->{current_view};
 641     }
 642
 643     return $c->container->get_component_from_sub_container( 'view', $name, $c, @args);
 644 }
 645
 646 =head2 $c->controllers
 647
 648 Returns the available names which can be passed to $c->controller
 649
 650 =cut
 651
 652 sub controllers {
 653     my ( $c ) = @_;
 654     return $c->container->get_sub_container('controller')->get_service_list;
 655 }
 656
 657 =head2 $c->models
 658
 659 Returns the available names which can be passed to $c->model
 660
 661 =cut
 662
 663 sub models {
 664     my ( $c ) = @_;
 665     return $c->container->get_sub_container('model')->get_service_list;
 666 }
 667
 668
 669 =head2 $c->views
 670
 671 Returns the available names which can be passed to $c->view
 672
 673 =cut
 674
 675 sub views {
 676     my ( $c ) = @_;
 677     return $c->container->get_sub_container('view')->get_service_list;
 678 }
 679
 680 =head2 $c->comp($name)
 681
 682 =head2 $c->component($name)
 683
 684 Gets a component object by name. This method is not recommended,
 685 unless you want to get a specific component by full
 686 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 687 should be used instead.
 688
 689 If C<$name> is a regexp, a list of components matched against the full
 690 component name will be returned.
 691
 692 =cut
 693
 694 sub component {
 695     my ( $c, $component, @args ) = @_;
 696
 697     unless ($component) {
 698         $c->log->warn('Calling $c->component with no args is deprecated and ');
 699         $c->log->warn('will be removed in a future release.');
 700         $c->log->warn('Use $c->component_list instead.');
 701         return $c->component_list;
 702     }
 703
 704     my @result = $c->container->find_component( $component, $c, @args );
 705
 706     # list context for regexp searches
 707     return @result if ref $component;
 708
 709     # only one component (if it's found) for string searches
 710     return shift @result if @result;
 711
 712     if (ref $c eq $component) {
 713         $c->log->warn('You are calling $c->comp("MyApp"). This behaviour is');
 714         $c->log->warn('deprecated, and will be removed in a future release.');
 715         return $c;
 716     }
 717
 718     $c->log->warn("Looking for '$component', but nothing was found.");
 719
 720     # I would expect to return an empty list here, but that breaks back-compat
 721     $c->log->warn('Component not found, returning the list of existing');
 722     $c->log->warn('components. This behavior is deprecated and will be');
 723     $c->log->warn('removed in a future release. Use $c->component_list');
 724     $c->log->warn('instead.');
 725
 726     return $c->component_list;
 727 }
 728
 729 =head2 $c->component_list
 730
 731 Returns the sorted list of the component names of the application.
 732
 733 =cut
 734
 735 sub component_list { sort keys %{ shift->components } }
 736
 737 =head2 CLASS DATA AND HELPER CLASSES
 738
 739 =head2 $c->config
 740
 741 Returns or takes a hashref containing the application's configuration.
 742
 743     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 744
 745 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 746 like C<myapp.conf> in your applications home directory. See
 747 L<Catalyst::Plugin::ConfigLoader>.
 748
 749 =head3 Cascading configuration
 750
 751 The config method is present on all Catalyst components, and configuration
 752 will be merged when an application is started. Configuration loaded with
 753 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 754 followed by configuration in your top level C<MyApp> class. These two
 755 configurations are merged, and then configuration data whose hash key matches a
 756 component name is merged with configuration for that component.
 757
 758 The configuration for a component is then passed to the C<new> method when a
 759 component is constructed.
 760
 761 For example:
 762
 763     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 764     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 765
 766 will mean that C<MyApp::Model::Foo> receives the following data when
 767 constructed:
 768
 769     MyApp::Model::Foo->new({
 770         bar => 'baz',
 771         quux => 'frob',
 772         overrides => 'me',
 773     });
 774
 775 It's common practice to use a Moose attribute
 776 on the receiving component to access the config value.
 777
 778     package MyApp::Model::Foo;
 779
 780     use Moose;
 781
 782     # this attr will receive 'baz' at construction time
 783     has 'bar' => (
 784         is  => 'rw',
 785         isa => 'Str',
 786     );
 787
 788 You can then get the value 'baz' by calling $c->model('Foo')->bar
 789 (or $self->bar inside code in the model).
 790
 791 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 792 as a way of reading config within your code, as this B<will not> give you the
 793 correctly merged config back. You B<MUST> take the config values supplied to
 794 the constructor and use those instead.
 795
 796 =cut
 797
 798 around config => sub {
 799     my $orig = shift;
 800     my $c = shift;
 801
 802     croak('Setting config after setup has been run is not allowed.')
 803         if ( @_ and $c->setup_finished );
 804
 805     $c->$orig(@_);
 806 };
 807
 808 =head2 $c->log
 809
 810 Returns the logging object instance. Unless it is already set, Catalyst
 811 sets this up with a L<Catalyst::Log> object. To use your own log class,
 812 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 813 C<< __PACKAGE__->setup >>.
 814
 815  __PACKAGE__->log( MyLogger->new );
 816  __PACKAGE__->setup;
 817
 818 And later:
 819
 820     $c->log->info( 'Now logging with my own logger!' );
 821
 822 Your log class should implement the methods described in
 823 L<Catalyst::Log>.
 824
 825
 826 =head2 $c->debug
 827
 828 Returns 1 if debug mode is enabled, 0 otherwise.
 829
 830 You can enable debug mode in several ways:
 831
 832 =over
 833
 834 =item By calling myapp_server.pl with the -d flag
 835
 836 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 837
 838 =item The -Debug option in your MyApp.pm
 839
 840 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 841
 842 =back
 843
 844 The first three also set the log level to 'debug'.
 845
 846 Calling C<< $c->debug(1) >> has no effect.
 847
 848 =cut
 849
 850 sub debug { 0 }
 851
 852 =head2 $c->dispatcher
 853
 854 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 855
 856 =head2 $c->engine
 857
 858 Returns the engine instance. See L<Catalyst::Engine>.
 859
 860
 861 =head2 UTILITY METHODS
 862
 863 =head2 $c->path_to(@path)
 864
 865 Merges C<@path> with C<< $c->config->{home} >> and returns a
 866 L<Path::Class::Dir> object. Note you can usually use this object as
 867 a filename, but sometimes you will have to explicitly stringify it
 868 yourself by calling the C<< ->stringify >> method.
 869
 870 For example:
 871
 872     $c->path_to( 'db', 'sqlite.db' );
 873
 874 =cut
 875
 876 sub path_to {
 877     my ( $c, @path ) = @_;
 878     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 879     if ( -d $path ) { return $path }
 880     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 881 }
 882
 883 =head2 $c->plugin( $name, $class, @args )
 884
 885 Helper method for plugins. It creates a class data accessor/mutator and
 886 loads and instantiates the given class.
 887
 888     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 889
 890     $c->prototype->define_javascript_functions;
 891
 892 B<Note:> This method of adding plugins is deprecated. The ability
 893 to add plugins like this B<will be removed> in a Catalyst 5.81.
 894 Please do not use this functionality in new code.
 895
 896 =cut
 897
 898 sub plugin {
 899     my ( $class, $name, $plugin, @args ) = @_;
 900
 901     # See block comment in t/aggregate/unit_core_plugin.t
 902     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 903
 904     $class->_register_plugin( $plugin, 1 );
 905
 906     eval { $plugin->import };
 907     $class->mk_classdata($name);
 908     my $obj;
 909     eval { $obj = $plugin->new(@args) };
 910
 911     if ($@) {
 912         Catalyst::Exception->throw( message =>
 913               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 914     }
 915
 916     $class->$name($obj);
 917     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 918       if $class->debug;
 919 }
 920
 921 =head2 MyApp->setup
 922
 923 Initializes the dispatcher and engine, loads any plugins, and loads the
 924 model, view, and controller components. You may also specify an array
 925 of plugins to load here, if you choose to not load them in the C<use
 926 Catalyst> line.
 927
 928     MyApp->setup;
 929     MyApp->setup( qw/-Debug/ );
 930
 931 =cut
 932
 933 sub setup {
 934     my ( $class, @arguments ) = @_;
 935     croak('Running setup more than once')
 936         if ( $class->setup_finished );
 937
 938     unless ( $class->isa('Catalyst') ) {
 939
 940         Catalyst::Exception->throw(
 941             message => qq/'$class' does not inherit from Catalyst/ );
 942     }
 943
 944     if ( $class->arguments ) {
 945         @arguments = ( @arguments, @{ $class->arguments } );
 946     }
 947
 948     # Process options
 949     my $flags = {};
 950
 951     foreach (@arguments) {
 952
 953         if (/^-Debug$/) {
 954             $flags->{log} =
 955               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 956         }
 957         elsif (/^-(\w+)=?(.*)$/) {
 958             $flags->{ lc $1 } = $2;
 959         }
 960         else {
 961             push @{ $flags->{plugins} }, $_;
 962         }
 963     }
 964
 965     $class->setup_config();
 966     $class->setup_home( delete $flags->{home} );
 967
 968     $class->setup_log( delete $flags->{log} );
 969     $class->setup_plugins( delete $flags->{plugins} );
 970     $class->setup_dispatcher( delete $flags->{dispatcher} );
 971     $class->setup_engine( delete $flags->{engine} );
 972     $class->setup_stats( delete $flags->{stats} );
 973
 974     for my $flag ( sort keys %{$flags} ) {
 975
 976         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 977             &$code( $class, delete $flags->{$flag} );
 978         }
 979         else {
 980             $class->log->warn(qq/Unknown flag "$flag"/);
 981         }
 982     }
 983
 984     eval { require Catalyst::Devel; };
 985     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 986         $class->log->warn(<<"EOF");
 987 You are running an old script!
 988
 989   Please update by running (this will overwrite existing files):
 990     catalyst.pl -force -scripts $class
 991
 992   or (this will not overwrite existing files):
 993     catalyst.pl -scripts $class
 994
 995 EOF
 996     }
 997
 998     if ( $class->debug ) {
 999         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1000
1001         if (@plugins) {
1002             my $column_width = Catalyst::Utils::term_width() - 6;
1003             my $t = Text::SimpleTable->new($column_width);
1004             $t->row($_) for @plugins;
1005             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1006         }
1007
1008         my $dispatcher = $class->dispatcher;
1009         my $engine     = $class->engine;
1010         my $home       = $class->config->{home};
1011
1012         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1013         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1014
1015         $home
1016           ? ( -d $home )
1017           ? $class->log->debug(qq/Found home "$home"/)
1018           : $class->log->debug(qq/Home "$home" doesn't exist/)
1019           : $class->log->debug(q/Couldn't find home/);
1020     }
1021
1022     # Call plugins setup, this is stupid and evil.
1023     # Also screws C3 badly on 5.10, hack to avoid.
1024     {
1025         no warnings qw/redefine/;
1026         local *setup = sub { };
1027         $class->setup unless $Catalyst::__AM_RESTARTING;
1028     }
1029
1030     $class->setup_components;
1031
1032     if (
1033         $class->debug and
1034         my @comps_names_types = $class->container->get_components_names_types
1035     ) {
1036         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1037         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1038         $t->row( @$_ ) for @comps_names_types;
1039
1040         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" );
1041     }
1042
1043     $class->setup_actions;
1044
1045     if ( $class->debug ) {
1046         my $name = $class->config->{name} || 'Application';
1047         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1048     }
1049
1050     # Make sure that the application class becomes immutable at this point,
1051     B::Hooks::EndOfScope::on_scope_end {
1052         return if $@;
1053         my $meta = Class::MOP::get_metaclass_by_name($class);
1054         if (
1055             $meta->is_immutable
1056             && ! { $meta->immutable_options }->{replace_constructor}
1057             && (
1058                    $class->isa('Class::Accessor::Fast')
1059                 || $class->isa('Class::Accessor')
1060             )
1061         ) {
1062             warn "You made your application class ($class) immutable, "
1063                 . "but did not inline the\nconstructor. "
1064                 . "This will break catalyst, as your app \@ISA "
1065                 . "Class::Accessor(::Fast)?\nPlease pass "
1066                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1067         }
1068         $meta->make_immutable(
1069             replace_constructor => 1,
1070         ) unless $meta->is_immutable;
1071     };
1072
1073     if ($class->config->{case_sensitive}) {
1074         $class->log->warn($class . "->config->{case_sensitive} is set.");
1075         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1076     }
1077
1078     $class->setup_finalize;
1079     # Should be the last thing we do so that user things hooking
1080     # setup_finalize can log..
1081     $class->log->_flush() if $class->log->can('_flush');
1082     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1083 }
1084
1085 =head2 $app->setup_finalize
1086
1087 A hook to attach modifiers to. This method does not do anything except set the
1088 C<setup_finished> accessor.
1089
1090 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1091
1092 Example:
1093
1094     after setup_finalize => sub {
1095         my $app = shift;
1096
1097         ## do stuff here..
1098     };
1099
1100 =cut
1101
1102 sub setup_finalize {
1103     my ($class) = @_;
1104     $class->setup_finished(1);
1105 }
1106
1107 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1108
1109 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1110
1111 Constructs an absolute L<URI> object based on the application root, the
1112 provided path, and the additional arguments and query parameters provided.
1113 When used as a string, provides a textual URI.  If you need more flexibility
1114 than this (i.e. the option to provide relative URIs etc.) see
1115 L<Catalyst::Plugin::SmartURI>.
1116
1117 If no arguments are provided, the URI for the current action is returned.
1118 To return the current action and also provide @args, use
1119 C<< $c->uri_for( $c->action, @args ) >>.
1120
1121 If the first argument is a string, it is taken as a public URI path relative
1122 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1123 relative to the application root (if it does). It is then merged with
1124 C<< $c->request->base >>; any C<@args> are appended as additional path
1125 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1126
1127 If the first argument is a L<Catalyst::Action> it represents an action which
1128 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1129 optional C<\@captures> argument (an arrayref) allows passing the captured
1130 variables that are needed to fill in the paths of Chained and Regex actions;
1131 once the path is resolved, C<uri_for> continues as though a path was
1132 provided, appending any arguments or parameters and creating an absolute
1133 URI.
1134
1135 The captures for the current request can be found in
1136 C<< $c->request->captures >>, and actions can be resolved using
1137 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1138 path, use C<< $c->uri_for_action >> instead.
1139
1140   # Equivalent to $c->req->uri
1141   $c->uri_for($c->action, $c->req->captures,
1142       @{ $c->req->args }, $c->req->params);
1143
1144   # For the Foo action in the Bar controller
1145   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1146
1147   # Path to a static resource
1148   $c->uri_for('/static/images/logo.png');
1149
1150 =cut
1151
1152 sub uri_for {
1153     my ( $c, $path, @args ) = @_;
1154
1155     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1156         $path = $path->path_prefix;
1157         $path =~ s{/+\z}{};
1158         $path .= '/';
1159     }
1160
1161     undef($path) if (defined $path && $path eq '');
1162
1163     my $params =
1164       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1165
1166     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1167     foreach my $arg (@args) {
1168         utf8::encode($arg) if utf8::is_utf8($arg);
1169         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1170     }
1171
1172     if ( blessed($path) ) { # action object
1173         s|/|%2F|g for @args;
1174         my $captures = [ map { s|/|%2F|g; $_; }
1175                         ( scalar @args && ref $args[0] eq 'ARRAY'
1176                          ? @{ shift(@args) }
1177                          : ()) ];
1178
1179         foreach my $capture (@$captures) {
1180             utf8::encode($capture) if utf8::is_utf8($capture);
1181             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1182         }
1183
1184         my $action = $path;
1185         $path = $c->dispatcher->uri_for_action($action, $captures);
1186         if (not defined $path) {
1187             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1188                 if $c->debug;
1189             return undef;
1190         }
1191         $path = '/' if $path eq '';
1192     }
1193
1194     unshift(@args, $path);
1195
1196     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1197         my $namespace = $c->namespace;
1198         if (defined $path) { # cheesy hack to handle path '../foo'
1199            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1200         }
1201         unshift(@args, $namespace || '');
1202     }
1203
1204     # join args with '/', or a blank string
1205     my $args = join('/', grep { defined($_) } @args);
1206     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1207     $args =~ s!^/+!!;
1208     my $base = $c->req->base;
1209     my $class = ref($base);
1210     $base =~ s{(?<!/)$}{/};
1211
1212     my $query = '';
1213
1214     if (my @keys = keys %$params) {
1215       # somewhat lifted from URI::_query's query_form
1216       $query = '?'.join('&', map {
1217           my $val = $params->{$_};
1218           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1219           s/ /+/g;
1220           my $key = $_;
1221           $val = '' unless defined $val;
1222           (map {
1223               my $param = "$_";
1224               utf8::encode( $param ) if utf8::is_utf8($param);
1225               # using the URI::Escape pattern here so utf8 chars survive
1226               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1227               $param =~ s/ /+/g;
1228               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1229       } @keys);
1230     }
1231
1232     my $res = bless(\"${base}${args}${query}", $class);
1233     $res;
1234 }
1235
1236 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1237
1238 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1239
1240 =over
1241
1242 =item $path
1243
1244 A private path to the Catalyst action you want to create a URI for.
1245
1246 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1247 >> and passing the resulting C<$action> and the remaining arguments to C<<
1248 $c->uri_for >>.
1249
1250 You can also pass in a Catalyst::Action object, in which case it is passed to
1251 C<< $c->uri_for >>.
1252
1253 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1254
1255 For example, if the action looks like:
1256
1257  package MyApp::Controller::Users;
1258
1259  sub lst : Path('the-list') {}
1260
1261 You can use:
1262
1263  $c->uri_for_action('/users/lst')
1264
1265 and it will create the URI /users/the-list.
1266
1267 =back
1268
1269 =cut
1270
1271 sub uri_for_action {
1272     my ( $c, $path, @args ) = @_;
1273     my $action = blessed($path)
1274       ? $path
1275       : $c->dispatcher->get_action_by_path($path);
1276     unless (defined $action) {
1277       croak "Can't find action for path '$path'";
1278     }
1279     return $c->uri_for( $action, @args );
1280 }
1281
1282 =head2 $c->welcome_message
1283
1284 Returns the Catalyst welcome HTML page.
1285
1286 =cut
1287
1288 sub welcome_message {
1289     my $c      = shift;
1290     my $name   = $c->config->{name};
1291     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1292     my $prefix = Catalyst::Utils::appprefix( ref $c );
1293     $c->response->content_type('text/html; charset=utf-8');
1294     return <<"EOF";
1295 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1296     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1297 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1298     <head>
1299     <meta http-equiv="Content-Language" content="en" />
1300     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1301         <title>$name on Catalyst $VERSION</title>
1302         <style type="text/css">
1303             body {
1304                 color: #000;
1305                 background-color: #eee;
1306             }
1307             div#content {
1308                 width: 640px;
1309                 margin-left: auto;
1310                 margin-right: auto;
1311                 margin-top: 10px;
1312                 margin-bottom: 10px;
1313                 text-align: left;
1314                 background-color: #ccc;
1315                 border: 1px solid #aaa;
1316             }
1317             p, h1, h2 {
1318                 margin-left: 20px;
1319                 margin-right: 20px;
1320                 font-family: verdana, tahoma, sans-serif;
1321             }
1322             a {
1323                 font-family: verdana, tahoma, sans-serif;
1324             }
1325             :link, :visited {
1326                     text-decoration: none;
1327                     color: #b00;
1328                     border-bottom: 1px dotted #bbb;
1329             }
1330             :link:hover, :visited:hover {
1331                     color: #555;
1332             }
1333             div#topbar {
1334                 margin: 0px;
1335             }
1336             pre {
1337                 margin: 10px;
1338                 padding: 8px;
1339             }
1340             div#answers {
1341                 padding: 8px;
1342                 margin: 10px;
1343                 background-color: #fff;
1344                 border: 1px solid #aaa;
1345             }
1346             h1 {
1347                 font-size: 0.9em;
1348                 font-weight: normal;
1349                 text-align: center;
1350             }
1351             h2 {
1352                 font-size: 1.0em;
1353             }
1354             p {
1355                 font-size: 0.9em;
1356             }
1357             p img {
1358                 float: right;
1359                 margin-left: 10px;
1360             }
1361             span#appname {
1362                 font-weight: bold;
1363                 font-size: 1.6em;
1364             }
1365         </style>
1366     </head>
1367     <body>
1368         <div id="content">
1369             <div id="topbar">
1370                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1371                     $VERSION</h1>
1372              </div>
1373              <div id="answers">
1374                  <p>
1375                  <img src="$logo" alt="Catalyst Logo" />
1376                  </p>
1377                  <p>Welcome to the  world of Catalyst.
1378                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1379                     framework will make web development something you had
1380                     never expected it to be: Fun, rewarding, and quick.</p>
1381                  <h2>What to do now?</h2>
1382                  <p>That really depends  on what <b>you</b> want to do.
1383                     We do, however, provide you with a few starting points.</p>
1384                  <p>If you want to jump right into web development with Catalyst
1385                     you might want to start with a tutorial.</p>
1386 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1387 </pre>
1388 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1389 <pre>
1390 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1391 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1392 </code></pre>
1393                  <h2>What to do next?</h2>
1394                  <p>Next it's time to write an actual application. Use the
1395                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1396                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1397                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1398                     they can save you a lot of work.</p>
1399                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1400                     <p>Also, be sure to check out the vast and growing
1401                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1402                     you are likely to find what you need there.
1403                     </p>
1404
1405                  <h2>Need help?</h2>
1406                  <p>Catalyst has a very active community. Here are the main places to
1407                     get in touch with us.</p>
1408                  <ul>
1409                      <li>
1410                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1411                      </li>
1412                      <li>
1413                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1414                      </li>
1415                      <li>
1416                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1417                      </li>
1418                  </ul>
1419                  <h2>In conclusion</h2>
1420                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1421                     as we enjoyed making it. Please contact us if you have ideas
1422                     for improvement or other feedback.</p>
1423              </div>
1424          </div>
1425     </body>
1426 </html>
1427 EOF
1428 }
1429
1430 =head1 INTERNAL METHODS
1431
1432 These methods are not meant to be used by end users.
1433
1434 =head2 $c->components
1435
1436 Returns a hash of components.
1437
1438 =cut
1439
1440 sub components {
1441     my ( $class, $comps ) = @_;
1442
1443     # people create components calling this sub directly, before setup
1444     $class->setup_config unless $class->container;
1445
1446     my $container = $class->container;
1447
1448     if ( $comps ) {
1449         $container->add_component( $_ ) for keys %$comps;
1450     }
1451
1452     return $container->get_all_components();
1453 }
1454
1455 =head2 $c->context_class
1456
1457 Returns or sets the context class.
1458
1459 =head2 $c->counter
1460
1461 Returns a hashref containing coderefs and execution counts (needed for
1462 deep recursion detection).
1463
1464 =head2 $c->depth
1465
1466 Returns the number of actions on the current internal execution stack.
1467
1468 =head2 $c->dispatch
1469
1470 Dispatches a request to actions.
1471
1472 =cut
1473
1474 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1475
1476 =head2 $c->dispatcher_class
1477
1478 Returns or sets the dispatcher class.
1479
1480 =head2 $c->dump_these
1481
1482 Returns a list of 2-element array references (name, structure) pairs
1483 that will be dumped on the error page in debug mode.
1484
1485 =cut
1486
1487 sub dump_these {
1488     my $c = shift;
1489     [ Request => $c->req ],
1490     [ Response => $c->res ],
1491     [ Stash => $c->stash ],
1492     [ Config => $c->config ];
1493 }
1494
1495 =head2 $c->engine_class
1496
1497 Returns or sets the engine class.
1498
1499 =head2 $c->execute( $class, $coderef )
1500
1501 Execute a coderef in given class and catch exceptions. Errors are available
1502 via $c->error.
1503
1504 =cut
1505
1506 sub execute {
1507     my ( $c, $class, $code ) = @_;
1508     $class = $c->component($class) || $class;
1509     $c->state(0);
1510
1511     if ( $c->depth >= $RECURSION ) {
1512         my $action = $code->reverse();
1513         $action = "/$action" unless $action =~ /->/;
1514         my $error = qq/Deep recursion detected calling "${action}"/;
1515         $c->log->error($error);
1516         $c->error($error);
1517         $c->state(0);
1518         return $c->state;
1519     }
1520
1521     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1522
1523     push( @{ $c->stack }, $code );
1524
1525     no warnings 'recursion';
1526     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1527     #      I have no idea how, ergo $ret (which appears to fix the issue)
1528     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1529
1530     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1531
1532     my $last = pop( @{ $c->stack } );
1533
1534     if ( my $error = $@ ) {
1535         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1536             $error->rethrow if $c->depth > 1;
1537         }
1538         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1539             $error->rethrow if $c->depth > 0;
1540         }
1541         else {
1542             unless ( ref $error ) {
1543                 no warnings 'uninitialized';
1544                 chomp $error;
1545                 my $class = $last->class;
1546                 my $name  = $last->name;
1547                 $error = qq/Caught exception in $class->$name "$error"/;
1548             }
1549             $c->error($error);
1550         }
1551         $c->state(0);
1552     }
1553     return $c->state;
1554 }
1555
1556 sub _stats_start_execute {
1557     my ( $c, $code ) = @_;
1558     my $appclass = ref($c) || $c;
1559     return if ( ( $code->name =~ /^_.*/ )
1560         && ( !$appclass->config->{show_internal_actions} ) );
1561
1562     my $action_name = $code->reverse();
1563     $c->counter->{$action_name}++;
1564
1565     my $action = $action_name;
1566     $action = "/$action" unless $action =~ /->/;
1567
1568     # determine if the call was the result of a forward
1569     # this is done by walking up the call stack and looking for a calling
1570     # sub of Catalyst::forward before the eval
1571     my $callsub = q{};
1572     for my $index ( 2 .. 11 ) {
1573         last
1574         if ( ( caller($index) )[0] eq 'Catalyst'
1575             && ( caller($index) )[3] eq '(eval)' );
1576
1577         if ( ( caller($index) )[3] =~ /forward$/ ) {
1578             $callsub = ( caller($index) )[3];
1579             $action  = "-> $action";
1580             last;
1581         }
1582     }
1583
1584     my $uid = $action_name . $c->counter->{$action_name};
1585
1586     # is this a root-level call or a forwarded call?
1587     if ( $callsub =~ /forward$/ ) {
1588         my $parent = $c->stack->[-1];
1589
1590         # forward, locate the caller
1591         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1592             $c->stats->profile(
1593                 begin  => $action,
1594                 parent => "$parent" . $c->counter->{"$parent"},
1595                 uid    => $uid,
1596             );
1597         }
1598         else {
1599
1600             # forward with no caller may come from a plugin
1601             $c->stats->profile(
1602                 begin => $action,
1603                 uid   => $uid,
1604             );
1605         }
1606     }
1607     else {
1608
1609         # root-level call
1610         $c->stats->profile(
1611             begin => $action,
1612             uid   => $uid,
1613         );
1614     }
1615     return $action;
1616
1617 }
1618
1619 sub _stats_finish_execute {
1620     my ( $c, $info ) = @_;
1621     $c->stats->profile( end => $info );
1622 }
1623
1624 =head2 $c->finalize
1625
1626 Finalizes the request.
1627
1628 =cut
1629
1630 sub finalize {
1631     my $c = shift;
1632
1633     for my $error ( @{ $c->error } ) {
1634         $c->log->error($error);
1635     }
1636
1637     # Allow engine to handle finalize flow (for POE)
1638     my $engine = $c->engine;
1639     if ( my $code = $engine->can('finalize') ) {
1640         $engine->$code($c);
1641     }
1642     else {
1643
1644         $c->finalize_uploads;
1645
1646         # Error
1647         if ( $#{ $c->error } >= 0 ) {
1648             $c->finalize_error;
1649         }
1650
1651         $c->finalize_headers;
1652
1653         # HEAD request
1654         if ( $c->request->method eq 'HEAD' ) {
1655             $c->response->body('');
1656         }
1657
1658         $c->finalize_body;
1659     }
1660
1661     $c->log_response;
1662
1663     if ($c->use_stats) {
1664         my $elapsed = sprintf '%f', $c->stats->elapsed;
1665         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1666         $c->log->info(
1667             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1668     }
1669
1670     return $c->response->status;
1671 }
1672
1673 =head2 $c->finalize_body
1674
1675 Finalizes body.
1676
1677 =cut
1678
1679 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1680
1681 =head2 $c->finalize_cookies
1682
1683 Finalizes cookies.
1684
1685 =cut
1686
1687 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1688
1689 =head2 $c->finalize_error
1690
1691 Finalizes error.
1692
1693 =cut
1694
1695 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1696
1697 =head2 $c->finalize_headers
1698
1699 Finalizes headers.
1700
1701 =cut
1702
1703 sub finalize_headers {
1704     my $c = shift;
1705
1706     my $response = $c->response; #accessor calls can add up?
1707
1708     # Check if we already finalized headers
1709     return if $response->finalized_headers;
1710
1711     # Handle redirects
1712     if ( my $location = $response->redirect ) {
1713         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1714         $response->header( Location => $location );
1715
1716         if ( !$response->has_body ) {
1717             # Add a default body if none is already present
1718             $response->body(
1719                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1720             );
1721         }
1722     }
1723
1724     # Content-Length
1725     if ( defined $response->body && length $response->body && !$response->content_length ) {
1726
1727         # get the length from a filehandle
1728         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1729         {
1730             my $stat = stat $response->body;
1731             if ( $stat && $stat->size > 0 ) {
1732                 $response->content_length( $stat->size );
1733             }
1734             else {
1735                 $c->log->warn('Serving filehandle without a content-length');
1736             }
1737         }
1738         else {
1739             # everything should be bytes at this point, but just in case
1740             $response->content_length( length( $response->body ) );
1741         }
1742     }
1743
1744     # Errors
1745     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1746         $response->headers->remove_header("Content-Length");
1747         $response->body('');
1748     }
1749
1750     $c->finalize_cookies;
1751
1752     $c->engine->finalize_headers( $c, @_ );
1753
1754     # Done
1755     $response->finalized_headers(1);
1756 }
1757
1758 =head2 $c->finalize_output
1759
1760 An alias for finalize_body.
1761
1762 =head2 $c->finalize_read
1763
1764 Finalizes the input after reading is complete.
1765
1766 =cut
1767
1768 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1769
1770 =head2 $c->finalize_uploads
1771
1772 Finalizes uploads. Cleans up any temporary files.
1773
1774 =cut
1775
1776 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1777
1778 =head2 $c->get_action( $action, $namespace )
1779
1780 Gets an action in a given namespace.
1781
1782 =cut
1783
1784 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1785
1786 =head2 $c->get_actions( $action, $namespace )
1787
1788 Gets all actions of a given name in a namespace and all parent
1789 namespaces.
1790
1791 =cut
1792
1793 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1794
1795 =head2 $app->handle_request( @arguments )
1796
1797 Called to handle each HTTP request.
1798
1799 =cut
1800
1801 sub handle_request {
1802     my ( $class, @arguments ) = @_;
1803
1804     # Always expect worst case!
1805     my $status = -1;
1806     eval {
1807         if ($class->debug) {
1808             my $secs = time - $START || 1;
1809             my $av = sprintf '%.3f', $COUNT / $secs;
1810             my $time = localtime time;
1811             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1812         }
1813
1814         my $c = $class->prepare(@arguments);
1815         $c->dispatch;
1816         $status = $c->finalize;
1817     };
1818
1819     if ( my $error = $@ ) {
1820         chomp $error;
1821         $class->log->error(qq/Caught exception in engine "$error"/);
1822     }
1823
1824     $COUNT++;
1825
1826     if(my $coderef = $class->log->can('_flush')){
1827         $class->log->$coderef();
1828     }
1829     return $status;
1830 }
1831
1832 =head2 $c->prepare( @arguments )
1833
1834 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1835 etc.).
1836
1837 =cut
1838
1839 sub prepare {
1840     my ( $class, @arguments ) = @_;
1841
1842     # XXX
1843     # After the app/ctxt split, this should become an attribute based on something passed
1844     # into the application.
1845     $class->context_class( ref $class || $class ) unless $class->context_class;
1846
1847     my $c = $class->context_class->new({});
1848
1849     # For on-demand data
1850     $c->request->_context($c);
1851     $c->response->_context($c);
1852
1853     #surely this is not the most efficient way to do things...
1854     $c->stats($class->stats_class->new)->enable($c->use_stats);
1855     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1856         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1857     }
1858
1859     #XXX reuse coderef from can
1860     # Allow engine to direct the prepare flow (for POE)
1861     if ( $c->engine->can('prepare') ) {
1862         $c->engine->prepare( $c, @arguments );
1863     }
1864     else {
1865         $c->prepare_request(@arguments);
1866         $c->prepare_connection;
1867         $c->prepare_query_parameters;
1868         $c->prepare_headers;
1869         $c->prepare_cookies;
1870         $c->prepare_path;
1871
1872         # Prepare the body for reading, either by prepare_body
1873         # or the user, if they are using $c->read
1874         $c->prepare_read;
1875
1876         # Parse the body unless the user wants it on-demand
1877         unless ( ref($c)->config->{parse_on_demand} ) {
1878             $c->prepare_body;
1879         }
1880     }
1881
1882     my $method  = $c->req->method  || '';
1883     my $path    = $c->req->path;
1884     $path       = '/' unless length $path;
1885     my $address = $c->req->address || '';
1886
1887     $c->log_request;
1888
1889     $c->prepare_action;
1890
1891     return $c;
1892 }
1893
1894 =head2 $c->prepare_action
1895
1896 Prepares action. See L<Catalyst::Dispatcher>.
1897
1898 =cut
1899
1900 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1901
1902 =head2 $c->prepare_body
1903
1904 Prepares message body.
1905
1906 =cut
1907
1908 sub prepare_body {
1909     my $c = shift;
1910
1911     return if $c->request->_has_body;
1912
1913     # Initialize on-demand data
1914     $c->engine->prepare_body( $c, @_ );
1915     $c->prepare_parameters;
1916     $c->prepare_uploads;
1917 }
1918
1919 =head2 $c->prepare_body_chunk( $chunk )
1920
1921 Prepares a chunk of data before sending it to L<HTTP::Body>.
1922
1923 See L<Catalyst::Engine>.
1924
1925 =cut
1926
1927 sub prepare_body_chunk {
1928     my $c = shift;
1929     $c->engine->prepare_body_chunk( $c, @_ );
1930 }
1931
1932 =head2 $c->prepare_body_parameters
1933
1934 Prepares body parameters.
1935
1936 =cut
1937
1938 sub prepare_body_parameters {
1939     my $c = shift;
1940     $c->engine->prepare_body_parameters( $c, @_ );
1941 }
1942
1943 =head2 $c->prepare_connection
1944
1945 Prepares connection.
1946
1947 =cut
1948
1949 sub prepare_connection {
1950     my $c = shift;
1951     $c->engine->prepare_connection( $c, @_ );
1952 }
1953
1954 =head2 $c->prepare_cookies
1955
1956 Prepares cookies.
1957
1958 =cut
1959
1960 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1961
1962 =head2 $c->prepare_headers
1963
1964 Prepares headers.
1965
1966 =cut
1967
1968 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1969
1970 =head2 $c->prepare_parameters
1971
1972 Prepares parameters.
1973
1974 =cut
1975
1976 sub prepare_parameters {
1977     my $c = shift;
1978     $c->prepare_body_parameters;
1979     $c->engine->prepare_parameters( $c, @_ );
1980 }
1981
1982 =head2 $c->prepare_path
1983
1984 Prepares path and base.
1985
1986 =cut
1987
1988 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1989
1990 =head2 $c->prepare_query_parameters
1991
1992 Prepares query parameters.
1993
1994 =cut
1995
1996 sub prepare_query_parameters {
1997     my $c = shift;
1998
1999     $c->engine->prepare_query_parameters( $c, @_ );
2000 }
2001
2002 =head2 $c->log_request
2003
2004 Writes information about the request to the debug logs.  This includes:
2005
2006 =over 4
2007
2008 =item * Request method, path, and remote IP address
2009
2010 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2011
2012 =item * Request parameters
2013
2014 =item * File uploads
2015
2016 =back
2017
2018 =cut
2019
2020 sub log_request {
2021     my $c = shift;
2022
2023     return unless $c->debug;
2024
2025     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2026     my $request = $dump->[1];
2027
2028     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2029     $method ||= '';
2030     $path = '/' unless length $path;
2031     $address ||= '';
2032     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2033
2034     $c->log_request_headers($request->headers);
2035
2036     if ( my $keywords = $request->query_keywords ) {
2037         $c->log->debug("Query keywords are: $keywords");
2038     }
2039
2040     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2041
2042     $c->log_request_uploads($request);
2043 }
2044
2045 =head2 $c->log_response
2046
2047 Writes information about the response to the debug logs by calling
2048 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2049
2050 =cut
2051
2052 sub log_response {
2053     my $c = shift;
2054
2055     return unless $c->debug;
2056
2057     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2058     my $response = $dump->[1];
2059
2060     $c->log_response_status_line($response);
2061     $c->log_response_headers($response->headers);
2062 }
2063
2064 =head2 $c->log_response_status_line($response)
2065
2066 Writes one line of information about the response to the debug logs.  This includes:
2067
2068 =over 4
2069
2070 =item * Response status code
2071
2072 =item * Content-Type header (if present)
2073
2074 =item * Content-Length header (if present)
2075
2076 =back
2077
2078 =cut
2079
2080 sub log_response_status_line {
2081     my ($c, $response) = @_;
2082
2083     $c->log->debug(
2084         sprintf(
2085             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2086             $response->status                            || 'unknown',
2087             $response->headers->header('Content-Type')   || 'unknown',
2088             $response->headers->header('Content-Length') || 'unknown'
2089         )
2090     );
2091 }
2092
2093 =head2 $c->log_response_headers($headers);
2094
2095 Hook method which can be wrapped by plugins to log the responseheaders.
2096 No-op in the default implementation.
2097
2098 =cut
2099
2100 sub log_response_headers {}
2101
2102 =head2 $c->log_request_parameters( query => {}, body => {} )
2103
2104 Logs request parameters to debug logs
2105
2106 =cut
2107
2108 sub log_request_parameters {
2109     my $c          = shift;
2110     my %all_params = @_;
2111
2112     return unless $c->debug;
2113
2114     my $column_width = Catalyst::Utils::term_width() - 44;
2115     foreach my $type (qw(query body)) {
2116         my $params = $all_params{$type};
2117         next if ! keys %$params;
2118         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2119         for my $key ( sort keys %$params ) {
2120             my $param = $params->{$key};
2121             my $value = defined($param) ? $param : '';
2122             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2123         }
2124         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2125     }
2126 }
2127
2128 =head2 $c->log_request_uploads
2129
2130 Logs file uploads included in the request to the debug logs.
2131 The parameter name, filename, file type, and file size are all included in
2132 the debug logs.
2133
2134 =cut
2135
2136 sub log_request_uploads {
2137     my $c = shift;
2138     my $request = shift;
2139     return unless $c->debug;
2140     my $uploads = $request->uploads;
2141     if ( keys %$uploads ) {
2142         my $t = Text::SimpleTable->new(
2143             [ 12, 'Parameter' ],
2144             [ 26, 'Filename' ],
2145             [ 18, 'Type' ],
2146             [ 9,  'Size' ]
2147         );
2148         for my $key ( sort keys %$uploads ) {
2149             my $upload = $uploads->{$key};
2150             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2151                 $t->row( $key, $u->filename, $u->type, $u->size );
2152             }
2153         }
2154         $c->log->debug( "File Uploads are:\n" . $t->draw );
2155     }
2156 }
2157
2158 =head2 $c->log_request_headers($headers);
2159
2160 Hook method which can be wrapped by plugins to log the request headers.
2161 No-op in the default implementation.
2162
2163 =cut
2164
2165 sub log_request_headers {}
2166
2167 =head2 $c->log_headers($type => $headers)
2168
2169 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2170
2171 =cut
2172
2173 sub log_headers {
2174     my $c       = shift;
2175     my $type    = shift;
2176     my $headers = shift;    # an HTTP::Headers instance
2177
2178     return unless $c->debug;
2179
2180     my $column_width = Catalyst::Utils::term_width() - 28;
2181     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2182     $headers->scan(
2183         sub {
2184             my ( $name, $value ) = @_;
2185             $t->row( $name, $value );
2186         }
2187     );
2188     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2189 }
2190
2191
2192 =head2 $c->prepare_read
2193
2194 Prepares the input for reading.
2195
2196 =cut
2197
2198 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2199
2200 =head2 $c->prepare_request
2201
2202 Prepares the engine request.
2203
2204 =cut
2205
2206 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2207
2208 =head2 $c->prepare_uploads
2209
2210 Prepares uploads.
2211
2212 =cut
2213
2214 sub prepare_uploads {
2215     my $c = shift;
2216
2217     $c->engine->prepare_uploads( $c, @_ );
2218 }
2219
2220 =head2 $c->prepare_write
2221
2222 Prepares the output for writing.
2223
2224 =cut
2225
2226 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2227
2228 =head2 $c->request_class
2229
2230 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2231
2232 =head2 $c->response_class
2233
2234 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2235
2236 =head2 $c->read( [$maxlength] )
2237
2238 Reads a chunk of data from the request body. This method is designed to
2239 be used in a while loop, reading C<$maxlength> bytes on every call.
2240 C<$maxlength> defaults to the size of the request if not specified.
2241
2242 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2243 directly.
2244
2245 Warning: If you use read(), Catalyst will not process the body,
2246 so you will not be able to access POST parameters or file uploads via
2247 $c->request.  You must handle all body parsing yourself.
2248
2249 =cut
2250
2251 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2252
2253 =head2 $c->run
2254
2255 Starts the engine.
2256
2257 =cut
2258
2259 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2260
2261 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2262
2263 Sets an action in a given namespace.
2264
2265 =cut
2266
2267 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2268
2269 =head2 $c->setup_actions($component)
2270
2271 Sets up actions for a component.
2272
2273 =cut
2274
2275 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2276
2277 =head2 $c->setup_config
2278
2279 =cut
2280
2281 sub setup_config {
2282     my $class = shift;
2283
2284     my %args = %{ $class->config || {} };
2285
2286     my @container_classes = ( "${class}::Container", 'Catalyst::IOC::Container');
2287     unshift @container_classes, delete $args{container_class} if exists $args{container_class};
2288
2289     my $container_class = Class::MOP::load_first_existing_class(@container_classes);
2290
2291     my $container = $container_class->new( %args, application_name => "$class", name => "$class" );
2292     $class->container($container);
2293
2294     my $config = $container->resolve(service => 'config');
2295     $class->config($config);
2296     $class->finalize_config; # back-compat
2297 }
2298
2299 =head2 $c->finalize_config
2300
2301 =cut
2302
2303 sub finalize_config { }
2304
2305 =head2 $c->setup_components
2306
2307 This method is called internally to set up the application's components.
2308
2309 It finds modules by calling the L<locate_components> method, expands them to
2310 package names with the $container->expand_component_module method, and then
2311 installs each component into the application.
2312
2313 The C<setup_components> config option is passed to both of the above methods.
2314
2315 =cut
2316
2317 sub setup_components {
2318     shift->container->setup_components();
2319 }
2320
2321 =head2 locate_components
2322
2323 =cut
2324
2325 # FIXME - removed locate_components
2326 # don't people mess with this method directly?
2327 # what to do with that?
2328
2329 sub locate_components {
2330     my $class = shift;
2331
2332     $class->log->warn('The locate_components method has been deprecated.');
2333     $class->log->warn('Please read Catalyst::IOC::Container documentation to');
2334     $class->log->warn('update your application.');
2335
2336     # XXX think about ditching this sort entirely
2337     return sort { length $a <=> length $b }
2338         @{ $class->container->resolve( service => 'locate_components' ) };
2339 }
2340
2341
2342 =head2 $c->setup_dispatcher
2343
2344 Sets up dispatcher.
2345
2346 =cut
2347
2348 sub setup_dispatcher {
2349     my ( $class, $dispatcher ) = @_;
2350
2351     if ($dispatcher) {
2352         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2353     }
2354
2355     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2356         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2357     }
2358
2359     unless ($dispatcher) {
2360         $dispatcher = $class->dispatcher_class;
2361     }
2362
2363     Class::MOP::load_class($dispatcher);
2364
2365     # dispatcher instance
2366     $class->dispatcher( $dispatcher->new );
2367 }
2368
2369 =head2 $c->setup_engine
2370
2371 Sets up engine.
2372
2373 =cut
2374
2375 sub setup_engine {
2376     my ( $class, $engine ) = @_;
2377
2378     if ($engine) {
2379         $engine = 'Catalyst::Engine::' . $engine;
2380     }
2381
2382     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2383         $engine = 'Catalyst::Engine::' . $env;
2384     }
2385
2386     if ( $ENV{MOD_PERL} ) {
2387         my $meta = Class::MOP::get_metaclass_by_name($class);
2388
2389         # create the apache method
2390         $meta->add_method('apache' => sub { shift->engine->apache });
2391
2392         my ( $software, $version ) =
2393           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2394
2395         $version =~ s/_//g;
2396         $version =~ s/(\.[^.]+)\./$1/g;
2397
2398         if ( $software eq 'mod_perl' ) {
2399
2400             if ( !$engine ) {
2401
2402                 if ( $version >= 1.99922 ) {
2403                     $engine = 'Catalyst::Engine::Apache2::MP20';
2404                 }
2405
2406                 elsif ( $version >= 1.9901 ) {
2407                     $engine = 'Catalyst::Engine::Apache2::MP19';
2408                 }
2409
2410                 elsif ( $version >= 1.24 ) {
2411                     $engine = 'Catalyst::Engine::Apache::MP13';
2412                 }
2413
2414                 else {
2415                     Catalyst::Exception->throw( message =>
2416                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2417                 }
2418
2419             }
2420
2421             # install the correct mod_perl handler
2422             if ( $version >= 1.9901 ) {
2423                 *handler = sub  : method {
2424                     shift->handle_request(@_);
2425                 };
2426             }
2427             else {
2428                 *handler = sub ($$) { shift->handle_request(@_) };
2429             }
2430
2431         }
2432
2433         elsif ( $software eq 'Zeus-Perl' ) {
2434             $engine = 'Catalyst::Engine::Zeus';
2435         }
2436
2437         else {
2438             Catalyst::Exception->throw(
2439                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2440         }
2441     }
2442
2443     unless ($engine) {
2444         $engine = $class->engine_class;
2445     }
2446
2447     Class::MOP::load_class($engine);
2448
2449     # check for old engines that are no longer compatible
2450     my $old_engine;
2451     if ( $engine->isa('Catalyst::Engine::Apache')
2452         && !Catalyst::Engine::Apache->VERSION )
2453     {
2454         $old_engine = 1;
2455     }
2456
2457     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2458         && Catalyst::Engine::Server->VERSION le '0.02' )
2459     {
2460         $old_engine = 1;
2461     }
2462
2463     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2464         && $engine->VERSION eq '0.01' )
2465     {
2466         $old_engine = 1;
2467     }
2468
2469     elsif ($engine->isa('Catalyst::Engine::Zeus')
2470         && $engine->VERSION eq '0.01' )
2471     {
2472         $old_engine = 1;
2473     }
2474
2475     if ($old_engine) {
2476         Catalyst::Exception->throw( message =>
2477               qq/Engine "$engine" is not supported by this version of Catalyst/
2478         );
2479     }
2480
2481     # engine instance
2482     $class->engine( $engine->new );
2483 }
2484
2485 =head2 $c->setup_home
2486
2487 Sets up the home directory.
2488
2489 =cut
2490
2491 sub setup_home {
2492     my ( $class, $home ) = @_;
2493
2494     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2495         $home = $env;
2496     }
2497
2498     $home ||= Catalyst::Utils::home($class);
2499
2500     if ($home) {
2501         #I remember recently being scolded for assigning config values like this
2502         $class->config->{home} ||= $home;
2503         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2504     }
2505 }
2506
2507 =head2 $c->setup_log
2508
2509 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2510 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2511 log to.
2512
2513 This method also installs a C<debug> method that returns a true value into the
2514 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2515 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2516
2517 Note that if the log has already been setup, by either a previous call to
2518 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2519 that this method won't actually set up the log object.
2520
2521 =cut
2522
2523 sub setup_log {
2524     my ( $class, $levels ) = @_;
2525
2526     $levels ||= '';
2527     $levels =~ s/^\s+//;
2528     $levels =~ s/\s+$//;
2529     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2530
2531     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2532     if ( defined $env_debug ) {
2533         $levels{debug} = 1 if $env_debug; # Ugly!
2534         delete($levels{debug}) unless $env_debug;
2535     }
2536
2537     unless ( $class->log ) {
2538         $class->log( Catalyst::Log->new(keys %levels) );
2539     }
2540
2541     if ( $levels{debug} ) {
2542         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2543         $class->log->debug('Debug messages enabled');
2544     }
2545 }
2546
2547 =head2 $c->setup_plugins
2548
2549 Sets up plugins.
2550
2551 =cut
2552
2553 =head2 $c->setup_stats
2554
2555 Sets up timing statistics class.
2556
2557 =cut
2558
2559 sub setup_stats {
2560     my ( $class, $stats ) = @_;
2561
2562     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2563
2564     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2565     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2566         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2567         $class->log->debug('Statistics enabled');
2568     }
2569 }
2570
2571
2572 =head2 $c->registered_plugins
2573
2574 Returns a sorted list of the plugins which have either been stated in the
2575 import list or which have been added via C<< MyApp->plugin(@args); >>.
2576
2577 If passed a given plugin name, it will report a boolean value indicating
2578 whether or not that plugin is loaded.  A fully qualified name is required if
2579 the plugin name does not begin with C<Catalyst::Plugin::>.
2580
2581  if ($c->registered_plugins('Some::Plugin')) {
2582      ...
2583  }
2584
2585 =cut
2586
2587 {
2588
2589     sub registered_plugins {
2590         my $proto = shift;
2591         return sort keys %{ $proto->_plugins } unless @_;
2592         my $plugin = shift;
2593         return 1 if exists $proto->_plugins->{$plugin};
2594         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2595     }
2596
2597     sub _register_plugin {
2598         my ( $proto, $plugin, $instant ) = @_;
2599         my $class = ref $proto || $proto;
2600
2601         Class::MOP::load_class( $plugin );
2602         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2603             if $plugin->isa( 'Catalyst::Component' );
2604         $proto->_plugins->{$plugin} = 1;
2605         unless ($instant) {
2606             my $meta = Class::MOP::get_metaclass_by_name($class);
2607             $meta->superclasses($plugin, $meta->superclasses);
2608         }
2609         return $class;
2610     }
2611
2612     sub setup_plugins {
2613         my ( $class, $plugins ) = @_;
2614
2615         $class->_plugins( {} ) unless $class->_plugins;
2616         $plugins = Data::OptList::mkopt($plugins || []);
2617
2618         my @plugins = map {
2619             [ Catalyst::Utils::resolve_namespace(
2620                   $class . '::Plugin',
2621                   'Catalyst::Plugin', $_->[0]
2622               ),
2623               $_->[1],
2624             ]
2625          } @{ $plugins };
2626
2627         for my $plugin ( reverse @plugins ) {
2628             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2629             my $meta = find_meta($plugin->[0]);
2630             next if $meta && $meta->isa('Moose::Meta::Role');
2631
2632             $class->_register_plugin($plugin->[0]);
2633         }
2634
2635         my @roles =
2636             map  { $_->[0]->name, $_->[1] }
2637             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2638             map  { [find_meta($_->[0]), $_->[1]] }
2639             @plugins;
2640
2641         Moose::Util::apply_all_roles(
2642             $class => @roles
2643         ) if @roles;
2644     }
2645 }
2646
2647 =head2 $c->stack
2648
2649 Returns an arrayref of the internal execution stack (actions that are
2650 currently executing).
2651
2652 =head2 $c->stats
2653
2654 Returns the current timing statistics object. By default Catalyst uses
2655 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2656 L<< stats_class|/"$c->stats_class" >>.
2657
2658 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2659 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2660 profile explicitly, although MyApp.pm still won't profile nor output anything
2661 by itself.
2662
2663 =head2 $c->stats_class
2664
2665 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2666
2667 =head2 $c->use_stats
2668
2669 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2670
2671 Note that this is a static method, not an accessor and should be overridden
2672 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2673
2674 =cut
2675
2676 sub use_stats { 0 }
2677
2678
2679 =head2 $c->write( $data )
2680
2681 Writes $data to the output stream. When using this method directly, you
2682 will need to manually set the C<Content-Length> header to the length of
2683 your output data, if known.
2684
2685 =cut
2686
2687 sub write {
2688     my $c = shift;
2689
2690     # Finalize headers if someone manually writes output
2691     $c->finalize_headers;
2692
2693     return $c->engine->write( $c, @_ );
2694 }
2695
2696 =head2 version
2697
2698 Returns the Catalyst version number. Mostly useful for "powered by"
2699 messages in template systems.
2700
2701 =cut
2702
2703 sub version { return $Catalyst::VERSION }
2704
2705 =head1 CONFIGURATION
2706
2707 There are a number of 'base' config variables which can be set:
2708
2709 =over
2710
2711 =item *
2712
2713 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2714
2715 =item *
2716
2717 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2718
2719 =item *
2720
2721 C<home> - The application home directory. In an uninstalled application,
2722 this is the top level application directory. In an installed application,
2723 this will be the directory containing C<< MyApp.pm >>.
2724
2725 =item *
2726
2727 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2728
2729 =item *
2730
2731 C<name> - The name of the application in debug messages and the debug and
2732 welcome screens
2733
2734 =item *
2735
2736 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2737 until it is accessed. This allows you to (for example) check authentication (and reject
2738 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2739
2740 =item *
2741
2742 C<root> - The root directory for templates. Usually this is just a
2743 subdirectory of the home directory, but you can set it to change the
2744 templates to a different directory.
2745
2746 =item *
2747
2748 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2749 to be shown in hit debug tables in the test server.
2750
2751 =item *
2752
2753 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
2754 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
2755 for more information.
2756
2757 =item *
2758
2759 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2760
2761 =back
2762
2763 =head1 INTERNAL ACTIONS
2764
2765 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2766 C<_ACTION>, and C<_END>. These are by default not shown in the private
2767 action table, but you can make them visible with a config parameter.
2768
2769     MyApp->config(show_internal_actions => 1);
2770
2771 =head1 ON-DEMAND PARSER
2772
2773 The request body is usually parsed at the beginning of a request,
2774 but if you want to handle input yourself, you can enable on-demand
2775 parsing with a config parameter.
2776
2777     MyApp->config(parse_on_demand => 1);
2778
2779 =head1 PROXY SUPPORT
2780
2781 Many production servers operate using the common double-server approach,
2782 with a lightweight frontend web server passing requests to a larger
2783 backend server. An application running on the backend server must deal
2784 with two problems: the remote user always appears to be C<127.0.0.1> and
2785 the server's hostname will appear to be C<localhost> regardless of the
2786 virtual host that the user connected through.
2787
2788 Catalyst will automatically detect this situation when you are running
2789 the frontend and backend servers on the same machine. The following
2790 changes are made to the request.
2791
2792     $c->req->address is set to the user's real IP address, as read from
2793     the HTTP X-Forwarded-For header.
2794
2795     The host value for $c->req->base and $c->req->uri is set to the real
2796     host, as read from the HTTP X-Forwarded-Host header.
2797
2798 Additionally, you may be running your backend application on an insecure
2799 connection (port 80) while your frontend proxy is running under SSL.  If there
2800 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2801 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2802 be created properly.
2803
2804 In the case of passing in:
2805
2806     X-Forwarded-Port: 443
2807
2808 All calls to C<uri_for> will result in an https link, as is expected.
2809
2810 Obviously, your web server must support these headers for this to work.
2811
2812 In a more complex server farm environment where you may have your
2813 frontend proxy server(s) on different machines, you will need to set a
2814 configuration option to tell Catalyst to read the proxied data from the
2815 headers.
2816
2817     MyApp->config(using_frontend_proxy => 1);
2818
2819 If you do not wish to use the proxy support at all, you may set:
2820
2821     MyApp->config(ignore_frontend_proxy => 1);
2822
2823 =head1 THREAD SAFETY
2824
2825 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2826 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2827 believe the Catalyst core to be thread-safe.
2828
2829 If you plan to operate in a threaded environment, remember that all other
2830 modules you are using must also be thread-safe. Some modules, most notably
2831 L<DBD::SQLite>, are not thread-safe.
2832
2833 =head1 SUPPORT
2834
2835 IRC:
2836
2837     Join #catalyst on irc.perl.org.
2838
2839 Mailing Lists:
2840
2841     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2842     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2843
2844 Web:
2845
2846     http://catalyst.perl.org
2847
2848 Wiki:
2849
2850     http://dev.catalyst.perl.org
2851
2852 =head1 SEE ALSO
2853
2854 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2855
2856 =head2 L<Catalyst::Manual> - The Catalyst Manual
2857
2858 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2859
2860 =head2 L<Catalyst::Engine> - Core engine
2861
2862 =head2 L<Catalyst::Log> - Log class.
2863
2864 =head2 L<Catalyst::Request> - Request object
2865
2866 =head2 L<Catalyst::Response> - Response object
2867
2868 =head2 L<Catalyst::Test> - The test suite.
2869
2870 =head1 PROJECT FOUNDER
2871
2872 sri: Sebastian Riedel <sri@cpan.org>
2873
2874 =head1 CONTRIBUTORS
2875
2876 abw: Andy Wardley
2877
2878 acme: Leon Brocard <leon@astray.com>
2879
2880 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
2881
2882 Andrew Bramble
2883
2884 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
2885
2886 Andrew Ruthven
2887
2888 André Walker
2889
2890 andyg: Andy Grundman <andy@hybridized.org>
2891
2892 audreyt: Audrey Tang
2893
2894 bricas: Brian Cassidy <bricas@cpan.org>
2895
2896 Caelum: Rafael Kitover <rkitover@io.com>
2897
2898 chansen: Christian Hansen
2899
2900 chicks: Christopher Hicks
2901
2902 Chisel Wright C<pause@herlpacker.co.uk>
2903
2904 Danijel Milicevic C<me@danijel.de>
2905
2906 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
2907
2908 David Naughton, C<naughton@umn.edu>
2909
2910 David E. Wheeler
2911
2912 dhoss: Devin Austin <dhoss@cpan.org>
2913
2914 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2915
2916 Drew Taylor
2917
2918 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2919
2920 esskar: Sascha Kiefer
2921
2922 fireartist: Carl Franks <cfranks@cpan.org>
2923
2924 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
2925
2926 gabb: Danijel Milicevic
2927
2928 Gary Ashton Jones
2929
2930 Gavin Henry C<ghenry@perl.me.uk>
2931
2932 Geoff Richards
2933
2934 groditi: Guillermo Roditi <groditi@gmail.com>
2935
2936 hobbs: Andrew Rodland <andrew@cleverdomain.org>
2937
2938 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2939
2940 jcamacho: Juan Camacho
2941
2942 jester: Jesse Sheidlower C<jester@panix.com>
2943
2944 jhannah: Jay Hannah <jay@jays.net>
2945
2946 Jody Belka
2947
2948 Johan Lindstrom
2949
2950 jon: Jon Schutz <jjschutz@cpan.org>
2951
2952 Jonathan Rockway C<< <jrockway@cpan.org> >>
2953
2954 Kieren Diment C<kd@totaldatasolution.com>
2955
2956 konobi: Scott McWhirter <konobi@cpan.org>
2957
2958 marcus: Marcus Ramberg <mramberg@cpan.org>
2959
2960 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2961
2962 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2963
2964 mugwump: Sam Vilain
2965
2966 naughton: David Naughton
2967
2968 ningu: David Kamholz <dkamholz@cpan.org>
2969
2970 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2971
2972 numa: Dan Sully <daniel@cpan.org>
2973
2974 obra: Jesse Vincent
2975
2976 Octavian Rasnita
2977
2978 omega: Andreas Marienborg
2979
2980 Oleg Kostyuk <cub.uanic@gmail.com>
2981
2982 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2983
2984 rafl: Florian Ragwitz <rafl@debian.org>
2985
2986 random: Roland Lammel <lammel@cpan.org>
2987
2988 Robert Sedlacek C<< <rs@474.at> >>
2989
2990 SpiceMan: Marcel Montes
2991
2992 sky: Arthur Bergman
2993
2994 szbalint: Balint Szilakszi <szbalint@cpan.org>
2995
2996 t0m: Tomas Doran <bobtfish@bobtfish.net>
2997
2998 Ulf Edvinsson
2999
3000 Viljo Marrandi C<vilts@yahoo.com>
3001
3002 Will Hawes C<info@whawes.co.uk>
3003
3004 willert: Sebastian Willert <willert@cpan.org>
3005
3006 wreis: Wallace Reis <wallace@reis.org.br>
3007
3008 Yuval Kogman, C<nothingmuch@woobling.org>
3009
3010 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3011
3012 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3013
3014 =head1 COPYRIGHT
3015
3016 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3017
3018 =head1 LICENSE
3019
3020 This library is free software. You can redistribute it and/or modify it under
3021 the same terms as Perl itself.
3022
3023 =cut
3024
3025 no Moose;
3026
3027 __PACKAGE__->meta->make_immutable;
3028
3029 1;