lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use Moose::Util qw/find_meta/;
   6 use Moose::Util::MetaRole ();
   7 use bytes;
   8 use Scope::Upper ();
   9 use Catalyst::Exception;
  10 use Catalyst::Log;
  11 use Catalyst::Request;
  12 use Catalyst::Request::Upload;
  13 use Catalyst::Response;
  14 use Catalyst::Utils;
  15 use Catalyst::Controller;
  16 use Devel::InnerPackage ();
  17 use File::stat;
  18 use Module::Pluggable::Object ();
  19 use Text::SimpleTable ();
  20 use Path::Class::Dir ();
  21 use Path::Class::File ();
  22 use URI ();
  23 use URI::http;
  24 use URI::https;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use Class::C3::Adopt::NEXT;
  28 use attributes;
  29 use utf8;
  30 use Carp qw/croak carp shortmess/;
  31
  32 BEGIN { require 5.008001; }
  33
  34 has stack => (is => 'ro', default => sub { [] });
  35 has stash => (is => 'rw', default => sub { {} });
  36 has state => (is => 'rw', default => 0);
  37 has stats => (is => 'rw');
  38 has action => (is => 'rw');
  39 has counter => (is => 'rw', default => sub { {} });
  40 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  41 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  42 has namespace => (is => 'rw');
  43
  44 sub depth { scalar @{ shift->stack || [] }; }
  45 sub comp { shift->component(@_) }
  46
  47 sub req {
  48     my $self = shift; return $self->request(@_);
  49 }
  50 sub res {
  51     my $self = shift; return $self->response(@_);
  52 }
  53
  54 # For backwards compatibility
  55 sub finalize_output { shift->finalize_body(@_) };
  56
  57 # For statistics
  58 our $COUNT     = 1;
  59 our $START     = time;
  60 our $RECURSION = 1000;
  61 our $DETACH    = "catalyst_detach\n";
  62 our $GO        = "catalyst_go\n";
  63
  64 #I imagine that very few of these really need to be class variables. if any.
  65 #maybe we should just make them attributes with a default?
  66 __PACKAGE__->mk_classdata($_)
  67   for qw/components arguments dispatcher engine log dispatcher_class
  68   engine_class context_class request_class response_class stats_class
  69   setup_finished/;
  70
  71 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  72 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  73 __PACKAGE__->request_class('Catalyst::Request');
  74 __PACKAGE__->response_class('Catalyst::Response');
  75 __PACKAGE__->stats_class('Catalyst::Stats');
  76
  77 # Remember to update this in Catalyst::Runtime as well!
  78
  79 our $VERSION = '5.80002';
  80
  81 {
  82     my $dev_version = $VERSION =~ /_\d{2}$/;
  83     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  84 }
  85
  86 $VERSION = eval $VERSION;
  87
  88 sub import {
  89     my ( $class, @arguments ) = @_;
  90
  91     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  92     # callers @ISA.
  93     return unless $class eq 'Catalyst';
  94
  95     my $caller = caller();
  96     return if $caller eq 'main';
  97
  98     # Kill Adopt::NEXT warnings if we're a non-RC version
  99     unless (_IS_DEVELOPMENT_VERSION()) {
 100         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 101     }
 102
 103     my $meta = Moose::Meta::Class->initialize($caller);
 104     #Moose->import({ into => $caller }); #do we want to do this?
 105
 106     unless ( $caller->isa('Catalyst') ) {
 107         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 108         $meta->superclasses(@superclasses);
 109     }
 110     unless( $meta->has_method('meta') ){
 111         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 112     }
 113
 114     $caller->arguments( [@arguments] );
 115     $caller->setup_home;
 116 }
 117
 118 =head1 NAME
 119
 120 Catalyst - The Elegant MVC Web Application Framework
 121
 122 =head1 SYNOPSIS
 123
 124 See the L<Catalyst::Manual> distribution for comprehensive
 125 documentation and tutorials.
 126
 127     # Install Catalyst::Devel for helpers and other development tools
 128     # use the helper to create a new application
 129     catalyst.pl MyApp
 130
 131     # add models, views, controllers
 132     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 133     script/myapp_create.pl view MyTemplate TT
 134     script/myapp_create.pl controller Search
 135
 136     # built in testserver -- use -r to restart automatically on changes
 137     # --help to see all available options
 138     script/myapp_server.pl
 139
 140     # command line testing interface
 141     script/myapp_test.pl /yada
 142
 143     ### in lib/MyApp.pm
 144     use Catalyst qw/-Debug/; # include plugins here as well
 145
 146     ### In lib/MyApp/Controller/Root.pm (autocreated)
 147     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 148         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 149         $c->stash->{template} = 'foo.tt'; # set the template
 150         # lookup something from db -- stash vars are passed to TT
 151         $c->stash->{data} =
 152           $c->model('Database::Foo')->search( { country => $args[0] } );
 153         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 154             $c->forward( 'bar' ); # process another action
 155             # do something else after forward returns
 156         }
 157     }
 158
 159     # The foo.tt TT template can use the stash data from the database
 160     [% WHILE (item = data.next) %]
 161         [% item.foo %]
 162     [% END %]
 163
 164     # called for /bar/of/soap, /bar/of/soap/10, etc.
 165     sub bar : Path('/bar/of/soap') { ... }
 166
 167     # called for all actions, from the top-most controller downwards
 168     sub auto : Private {
 169         my ( $self, $c ) = @_;
 170         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 171             $c->res->redirect( '/login' ); # require login
 172             return 0; # abort request and go immediately to end()
 173         }
 174         return 1; # success; carry on to next action
 175     }
 176
 177     # called after all actions are finished
 178     sub end : Private {
 179         my ( $self, $c ) = @_;
 180         if ( scalar @{ $c->error } ) { ... } # handle errors
 181         return if $c->res->body; # already have a response
 182         $c->forward( 'MyApp::View::TT' ); # render template
 183     }
 184
 185     ### in MyApp/Controller/Foo.pm
 186     # called for /foo/bar
 187     sub bar : Local { ... }
 188
 189     # called for /blargle
 190     sub blargle : Global { ... }
 191
 192     # an index action matches /foo, but not /foo/1, etc.
 193     sub index : Private { ... }
 194
 195     ### in MyApp/Controller/Foo/Bar.pm
 196     # called for /foo/bar/baz
 197     sub baz : Local { ... }
 198
 199     # first Root auto is called, then Foo auto, then this
 200     sub auto : Private { ... }
 201
 202     # powerful regular expression paths are also possible
 203     sub details : Regex('^product/(\w+)/details$') {
 204         my ( $self, $c ) = @_;
 205         # extract the (\w+) from the URI
 206         my $product = $c->req->captures->[0];
 207     }
 208
 209 See L<Catalyst::Manual::Intro> for additional information.
 210
 211 =head1 DESCRIPTION
 212
 213 Catalyst is a modern framework for making web applications without the
 214 pain usually associated with this process. This document is a reference
 215 to the main Catalyst application. If you are a new user, we suggest you
 216 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 217
 218 See L<Catalyst::Manual> for more documentation.
 219
 220 Catalyst plugins can be loaded by naming them as arguments to the "use
 221 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 222 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 223 C<My::Module>.
 224
 225     use Catalyst qw/My::Module/;
 226
 227 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 228 fully qualify the name by using a unary plus:
 229
 230     use Catalyst qw/
 231         My::Module
 232         +Fully::Qualified::Plugin::Name
 233     /;
 234
 235 Special flags like C<-Debug> and C<-Engine> can also be specified as
 236 arguments when Catalyst is loaded:
 237
 238     use Catalyst qw/-Debug My::Module/;
 239
 240 The position of plugins and flags in the chain is important, because
 241 they are loaded in the order in which they appear.
 242
 243 The following flags are supported:
 244
 245 =head2 -Debug
 246
 247 Enables debug output. You can also force this setting from the system
 248 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 249 settings override the application, with <MYAPP>_DEBUG having the highest
 250 priority.
 251
 252 =head2 -Engine
 253
 254 Forces Catalyst to use a specific engine. Omit the
 255 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 256
 257     use Catalyst qw/-Engine=CGI/;
 258
 259 =head2 -Home
 260
 261 Forces Catalyst to use a specific home directory, e.g.:
 262
 263     use Catalyst qw[-Home=/usr/mst];
 264
 265 This can also be done in the shell environment by setting either the
 266 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 267 is replaced with the uppercased name of your application, any "::" in
 268 the name will be replaced with underscores, e.g. MyApp::Web should use
 269 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 270
 271 =head2 -Log
 272
 273     use Catalyst '-Log=warn,fatal,error';
 274
 275 Specifies a comma-delimited list of log levels.
 276
 277 =head2 -Stats
 278
 279 Enables statistics collection and reporting. You can also force this setting
 280 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 281 environment settings override the application, with <MYAPP>_STATS having the
 282 highest priority.
 283
 284 e.g.
 285
 286    use Catalyst qw/-Stats=1/
 287
 288 =head1 METHODS
 289
 290 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 291
 292 =head2 $c->action
 293
 294 Returns a L<Catalyst::Action> object for the current action, which
 295 stringifies to the action name. See L<Catalyst::Action>.
 296
 297 =head2 $c->namespace
 298
 299 Returns the namespace of the current action, i.e., the URI prefix
 300 corresponding to the controller of the current action. For example:
 301
 302     # in Controller::Foo::Bar
 303     $c->namespace; # returns 'foo/bar';
 304
 305 =head2 $c->request
 306
 307 =head2 $c->req
 308
 309 Returns the current L<Catalyst::Request> object, giving access to
 310 information about the current client request (including parameters,
 311 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 312
 313 =head2 REQUEST FLOW HANDLING
 314
 315 =head2 $c->forward( $action [, \@arguments ] )
 316
 317 =head2 $c->forward( $class, $method, [, \@arguments ] )
 318
 319 Forwards processing to another action, by its private name. If you give a
 320 class name but no method, C<process()> is called. You may also optionally
 321 pass arguments in an arrayref. The action will receive the arguments in
 322 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 323 C<< $c->req->args >> will be restored to the previous values.
 324
 325 Any data C<return>ed from the action forwarded to, will be returned by the
 326 call to forward.
 327
 328     my $foodata = $c->forward('/foo');
 329     $c->forward('index');
 330     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 331     $c->forward('MyApp::View::TT');
 332
 333 Note that forward implies an C<<eval { }>> around the call (actually
 334 C<execute> does), thus de-fatalizing all 'dies' within the called
 335 action. If you want C<die> to propagate you need to do something like:
 336
 337     $c->forward('foo');
 338     die $c->error if $c->error;
 339
 340 Or make sure to always return true values from your actions and write
 341 your code like this:
 342
 343     $c->forward('foo') || return;
 344
 345 =cut
 346
 347 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 348
 349 =head2 $c->detach( $action [, \@arguments ] )
 350
 351 =head2 $c->detach( $class, $method, [, \@arguments ] )
 352
 353 =head2 $c->detach()
 354
 355 The same as C<forward>, but doesn't return to the previous action when
 356 processing is finished.
 357
 358 When called with no arguments it escapes the processing chain entirely.
 359
 360 =cut
 361
 362 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 363
 364 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 365
 366 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 367
 368 Almost the same as C<forward>, but does a full dispatch, instead of just
 369 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 370 C<auto> and the method you go to are called, just like a new request.
 371
 372 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 373 This means, for example, that $c->action methods such as C<name>, C<class> and
 374 C<reverse> return information for the visited action when they are invoked
 375 within the visited action.  This is different from the behavior of C<forward>
 376 which continues to use the $c->action object from the caller action even when
 377 invoked from the callee.
 378
 379 C<$c-E<gt>stash> is kept unchanged.
 380
 381 In effect, C<visit> allows you to "wrap" another action, just as it
 382 would have been called by dispatching from a URL, while the analogous
 383 C<go> allows you to transfer control to another action as if it had
 384 been reached directly from a URL.
 385
 386 =cut
 387
 388 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 389
 390 =head2 $c->go( $action [, \@captures, \@arguments ] )
 391
 392 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 393
 394 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 395 instead of just calling the new C<$action> /
 396 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 397 method you visit are called, just like a new request.
 398
 399 C<$c-E<gt>stash> is kept unchanged.
 400
 401 =cut
 402
 403 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 404
 405 =head2 $c->response
 406
 407 =head2 $c->res
 408
 409 Returns the current L<Catalyst::Response> object, see there for details.
 410
 411 =head2 $c->stash
 412
 413 Returns a hashref to the stash, which may be used to store data and pass
 414 it between components during a request. You can also set hash keys by
 415 passing arguments. The stash is automatically sent to the view. The
 416 stash is cleared at the end of a request; it cannot be used for
 417 persistent storage (for this you must use a session; see
 418 L<Catalyst::Plugin::Session> for a complete system integrated with
 419 Catalyst).
 420
 421     $c->stash->{foo} = $bar;
 422     $c->stash( { moose => 'majestic', qux => 0 } );
 423     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 424
 425     # stash is automatically passed to the view for use in a template
 426     $c->forward( 'MyApp::View::TT' );
 427
 428 =cut
 429
 430 around stash => sub {
 431     my $orig = shift;
 432     my $c = shift;
 433     my $stash = $orig->($c);
 434     if (@_) {
 435         my $new_stash = @_ > 1 ? {@_} : $_[0];
 436         croak('stash takes a hash or hashref') unless ref $new_stash;
 437         foreach my $key ( keys %$new_stash ) {
 438           $stash->{$key} = $new_stash->{$key};
 439         }
 440     }
 441
 442     return $stash;
 443 };
 444
 445
 446 =head2 $c->error
 447
 448 =head2 $c->error($error, ...)
 449
 450 =head2 $c->error($arrayref)
 451
 452 Returns an arrayref containing error messages.  If Catalyst encounters an
 453 error while processing a request, it stores the error in $c->error.  This
 454 method should only be used to store fatal error messages.
 455
 456     my @error = @{ $c->error };
 457
 458 Add a new error.
 459
 460     $c->error('Something bad happened');
 461
 462 =cut
 463
 464 sub error {
 465     my $c = shift;
 466     if ( $_[0] ) {
 467         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 468         croak @$error unless ref $c;
 469         push @{ $c->{error} }, @$error;
 470     }
 471     elsif ( defined $_[0] ) { $c->{error} = undef }
 472     return $c->{error} || [];
 473 }
 474
 475
 476 =head2 $c->state
 477
 478 Contains the return value of the last executed action.
 479
 480 =head2 $c->clear_errors
 481
 482 Clear errors.  You probably don't want to clear the errors unless you are
 483 implementing a custom error screen.
 484
 485 This is equivalent to running
 486
 487     $c->error(0);
 488
 489 =cut
 490
 491 sub clear_errors {
 492     my $c = shift;
 493     $c->error(0);
 494 }
 495
 496 # search components given a name and some prefixes
 497 sub _comp_search_prefixes {
 498     my ( $c, $name, @prefixes ) = @_;
 499     my $appclass = ref $c || $c;
 500     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 501     $filter = qr/$filter/; # Compile regex now rather than once per loop
 502
 503     # map the original component name to the sub part that we will search against
 504     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 505         grep { /$filter/ } keys %{ $c->components };
 506
 507     # undef for a name will return all
 508     return keys %eligible if !defined $name;
 509
 510     my $query  = ref $name ? $name : qr/^$name$/i;
 511     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 512
 513     return map { $c->components->{ $_ } } @result if @result;
 514
 515     # if we were given a regexp to search against, we're done.
 516     return if ref $name;
 517
 518     # regexp fallback
 519     $query  = qr/$name/i;
 520     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 521
 522     # no results? try against full names
 523     if( !@result ) {
 524         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 525     }
 526
 527     # don't warn if we didn't find any results, it just might not exist
 528     if( @result ) {
 529         # Disgusting hack to work out correct method name
 530         my $warn_for = lc $prefixes[0];
 531         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 532            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 533            "component resolution is unreliable and unsafe.";
 534         my $short = $result[0];
 535         $short =~ s/.*?Model:://;
 536         my $shortmess = Carp::shortmess('');
 537         if ($shortmess =~ m#Catalyst/Plugin#) {
 538            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 539               "plugin's config";
 540         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 541            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 542               "component's config";
 543         } else {
 544            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 545               "but if you really wanted to search, pass in a regexp as the argument " .
 546               "like so: \$c->${warn_for}(qr/${name}/)";
 547         }
 548         $c->log->warn( "${msg}$shortmess" );
 549     }
 550
 551     return @result;
 552 }
 553
 554 # Find possible names for a prefix
 555 sub _comp_names {
 556     my ( $c, @prefixes ) = @_;
 557     my $appclass = ref $c || $c;
 558
 559     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 560
 561     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 562     return @names;
 563 }
 564
 565 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 566 sub _filter_component {
 567     my ( $c, $comp, @args ) = @_;
 568
 569     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 570         return $comp->ACCEPT_CONTEXT( $c, @args );
 571     }
 572
 573     return $comp;
 574 }
 575
 576 =head2 COMPONENT ACCESSORS
 577
 578 =head2 $c->controller($name)
 579
 580 Gets a L<Catalyst::Controller> instance by name.
 581
 582     $c->controller('Foo')->do_stuff;
 583
 584 If the name is omitted, will return the controller for the dispatched
 585 action.
 586
 587 If you want to search for controllers, pass in a regexp as the argument.
 588
 589     # find all controllers that start with Foo
 590     my @foo_controllers = $c->controller(qr{^Foo});
 591
 592
 593 =cut
 594
 595 sub controller {
 596     my ( $c, $name, @args ) = @_;
 597
 598     if( $name ) {
 599         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 600         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 601         return $c->_filter_component( $result[ 0 ], @args );
 602     }
 603
 604     return $c->component( $c->action->class );
 605 }
 606
 607 =head2 $c->model($name)
 608
 609 Gets a L<Catalyst::Model> instance by name.
 610
 611     $c->model('Foo')->do_stuff;
 612
 613 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 614
 615 If the name is omitted, it will look for
 616  - a model object in $c->stash->{current_model_instance}, then
 617  - a model name in $c->stash->{current_model}, then
 618  - a config setting 'default_model', or
 619  - check if there is only one model, and return it if that's the case.
 620
 621 If you want to search for models, pass in a regexp as the argument.
 622
 623     # find all models that start with Foo
 624     my @foo_models = $c->model(qr{^Foo});
 625
 626 =cut
 627
 628 sub model {
 629     my ( $c, $name, @args ) = @_;
 630
 631     if( $name ) {
 632         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 633         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 634         return $c->_filter_component( $result[ 0 ], @args );
 635     }
 636
 637     if (ref $c) {
 638         return $c->stash->{current_model_instance}
 639           if $c->stash->{current_model_instance};
 640         return $c->model( $c->stash->{current_model} )
 641           if $c->stash->{current_model};
 642     }
 643     return $c->model( $c->config->{default_model} )
 644       if $c->config->{default_model};
 645
 646     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 647
 648     if( $rest ) {
 649         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 650         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 651         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 652         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 653         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 654     }
 655
 656     return $c->_filter_component( $comp );
 657 }
 658
 659
 660 =head2 $c->view($name)
 661
 662 Gets a L<Catalyst::View> instance by name.
 663
 664     $c->view('Foo')->do_stuff;
 665
 666 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 667
 668 If the name is omitted, it will look for
 669  - a view object in $c->stash->{current_view_instance}, then
 670  - a view name in $c->stash->{current_view}, then
 671  - a config setting 'default_view', or
 672  - check if there is only one view, and return it if that's the case.
 673
 674 If you want to search for views, pass in a regexp as the argument.
 675
 676     # find all views that start with Foo
 677     my @foo_views = $c->view(qr{^Foo});
 678
 679 =cut
 680
 681 sub view {
 682     my ( $c, $name, @args ) = @_;
 683
 684     if( $name ) {
 685         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 686         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 687         return $c->_filter_component( $result[ 0 ], @args );
 688     }
 689
 690     if (ref $c) {
 691         return $c->stash->{current_view_instance}
 692           if $c->stash->{current_view_instance};
 693         return $c->view( $c->stash->{current_view} )
 694           if $c->stash->{current_view};
 695     }
 696     return $c->view( $c->config->{default_view} )
 697       if $c->config->{default_view};
 698
 699     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 700
 701     if( $rest ) {
 702         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 703         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 704         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 705         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 706         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 707     }
 708
 709     return $c->_filter_component( $comp );
 710 }
 711
 712 =head2 $c->controllers
 713
 714 Returns the available names which can be passed to $c->controller
 715
 716 =cut
 717
 718 sub controllers {
 719     my ( $c ) = @_;
 720     return $c->_comp_names(qw/Controller C/);
 721 }
 722
 723 =head2 $c->models
 724
 725 Returns the available names which can be passed to $c->model
 726
 727 =cut
 728
 729 sub models {
 730     my ( $c ) = @_;
 731     return $c->_comp_names(qw/Model M/);
 732 }
 733
 734
 735 =head2 $c->views
 736
 737 Returns the available names which can be passed to $c->view
 738
 739 =cut
 740
 741 sub views {
 742     my ( $c ) = @_;
 743     return $c->_comp_names(qw/View V/);
 744 }
 745
 746 =head2 $c->comp($name)
 747
 748 =head2 $c->component($name)
 749
 750 Gets a component object by name. This method is not recommended,
 751 unless you want to get a specific component by full
 752 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 753 should be used instead.
 754
 755 If C<$name> is a regexp, a list of components matched against the full
 756 component name will be returned.
 757
 758 =cut
 759
 760 sub component {
 761     my ( $c, $name, @args ) = @_;
 762
 763     if( $name ) {
 764         my $comps = $c->components;
 765
 766         if( !ref $name ) {
 767             # is it the exact name?
 768             return $c->_filter_component( $comps->{ $name }, @args )
 769                        if exists $comps->{ $name };
 770
 771             # perhaps we just omitted "MyApp"?
 772             my $composed = ( ref $c || $c ) . "::${name}";
 773             return $c->_filter_component( $comps->{ $composed }, @args )
 774                        if exists $comps->{ $composed };
 775
 776             # search all of the models, views and controllers
 777             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 778             return $c->_filter_component( $comp, @args ) if $comp;
 779         }
 780
 781         # This is here so $c->comp( '::M::' ) works
 782         my $query = ref $name ? $name : qr{$name}i;
 783
 784         my @result = grep { m{$query} } keys %{ $c->components };
 785         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 786
 787         if( $result[ 0 ] ) {
 788             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 789             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 790             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 791             return $c->_filter_component( $result[ 0 ], @args );
 792         }
 793
 794         # I would expect to return an empty list here, but that breaks back-compat
 795     }
 796
 797     # fallback
 798     return sort keys %{ $c->components };
 799 }
 800
 801 =head2 CLASS DATA AND HELPER CLASSES
 802
 803 =head2 $c->config
 804
 805 Returns or takes a hashref containing the application's configuration.
 806
 807     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 808
 809 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 810 like myapp.conf in your applications home directory. See
 811 L<Catalyst::Plugin::ConfigLoader>.
 812
 813 =head3 Cascading configuration.
 814
 815 The config method is present on all Catalyst components, and configuration
 816 will be merged when an application is started. Configuration loaded with
 817 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 818 followed by configuration in your top level C<MyApp> class. These two
 819 configurations are merged, and then configuration data whose hash key matches a
 820 component name is merged with configuration for that component.
 821
 822 The configuration for a component is then passed to the C<new> method when a
 823 component is constructed.
 824
 825 For example:
 826
 827     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 828     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 829
 830 will mean that C<MyApp::Model::Foo> receives the following data when
 831 constructed:
 832
 833     MyApp::Model::Foo->new({
 834         bar => 'baz',
 835         quux => 'frob',
 836         overrides => 'me',
 837     });
 838
 839 =cut
 840
 841 around config => sub {
 842     my $orig = shift;
 843     my $c = shift;
 844
 845     croak('Setting config after setup has been run is not allowed.')
 846         if ( @_ and $c->setup_finished );
 847
 848     $c->$orig(@_);
 849 };
 850
 851 =head2 $c->log
 852
 853 Returns the logging object instance. Unless it is already set, Catalyst
 854 sets this up with a L<Catalyst::Log> object. To use your own log class,
 855 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 856 C<< __PACKAGE__->setup >>.
 857
 858  __PACKAGE__->log( MyLogger->new );
 859  __PACKAGE__->setup;
 860
 861 And later:
 862
 863     $c->log->info( 'Now logging with my own logger!' );
 864
 865 Your log class should implement the methods described in
 866 L<Catalyst::Log>.
 867
 868
 869 =head2 $c->debug
 870
 871 Returns 1 if debug mode is enabled, 0 otherwise.
 872
 873 You can enable debug mode in several ways:
 874
 875 =over
 876
 877 =item By calling myapp_server.pl with the -d flag
 878
 879 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 880
 881 =item The -Debug option in your MyApp.pm
 882
 883 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 884
 885 =back
 886
 887 Calling C<< $c->debug(1) >> has no effect.
 888
 889 =cut
 890
 891 sub debug { 0 }
 892
 893 =head2 $c->dispatcher
 894
 895 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 896
 897 =head2 $c->engine
 898
 899 Returns the engine instance. See L<Catalyst::Engine>.
 900
 901
 902 =head2 UTILITY METHODS
 903
 904 =head2 $c->path_to(@path)
 905
 906 Merges C<@path> with C<< $c->config->{home} >> and returns a
 907 L<Path::Class::Dir> object.
 908
 909 For example:
 910
 911     $c->path_to( 'db', 'sqlite.db' );
 912
 913 =cut
 914
 915 sub path_to {
 916     my ( $c, @path ) = @_;
 917     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 918     if ( -d $path ) { return $path }
 919     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 920 }
 921
 922 =head2 $c->plugin( $name, $class, @args )
 923
 924 Helper method for plugins. It creates a class data accessor/mutator and
 925 loads and instantiates the given class.
 926
 927     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 928
 929     $c->prototype->define_javascript_functions;
 930
 931 B<Note:> This method of adding plugins is deprecated. The ability
 932 to add plugins like this B<will be removed> in a Catalyst 5.81.
 933 Please do not use this functionality in new code.
 934
 935 =cut
 936
 937 sub plugin {
 938     my ( $class, $name, $plugin, @args ) = @_;
 939
 940     # See block comment in t/unit_core_plugin.t
 941     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 942
 943     $class->_register_plugin( $plugin, 1 );
 944
 945     eval { $plugin->import };
 946     $class->mk_classdata($name);
 947     my $obj;
 948     eval { $obj = $plugin->new(@args) };
 949
 950     if ($@) {
 951         Catalyst::Exception->throw( message =>
 952               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 953     }
 954
 955     $class->$name($obj);
 956     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 957       if $class->debug;
 958 }
 959
 960 =head2 MyApp->setup
 961
 962 Initializes the dispatcher and engine, loads any plugins, and loads the
 963 model, view, and controller components. You may also specify an array
 964 of plugins to load here, if you choose to not load them in the C<use
 965 Catalyst> line.
 966
 967     MyApp->setup;
 968     MyApp->setup( qw/-Debug/ );
 969
 970 =cut
 971
 972 sub setup {
 973     my ( $class, @arguments ) = @_;
 974     croak('Running setup more than once')
 975         if ( $class->setup_finished );
 976
 977     unless ( $class->isa('Catalyst') ) {
 978
 979         Catalyst::Exception->throw(
 980             message => qq/'$class' does not inherit from Catalyst/ );
 981     }
 982
 983     if ( $class->arguments ) {
 984         @arguments = ( @arguments, @{ $class->arguments } );
 985     }
 986
 987     # Process options
 988     my $flags = {};
 989
 990     foreach (@arguments) {
 991
 992         if (/^-Debug$/) {
 993             $flags->{log} =
 994               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 995         }
 996         elsif (/^-(\w+)=?(.*)$/) {
 997             $flags->{ lc $1 } = $2;
 998         }
 999         else {
1000             push @{ $flags->{plugins} }, $_;
1001         }
1002     }
1003
1004     $class->setup_home( delete $flags->{home} );
1005
1006     $class->setup_log( delete $flags->{log} );
1007     $class->setup_plugins( delete $flags->{plugins} );
1008     $class->setup_dispatcher( delete $flags->{dispatcher} );
1009     $class->setup_engine( delete $flags->{engine} );
1010     $class->setup_stats( delete $flags->{stats} );
1011
1012     for my $flag ( sort keys %{$flags} ) {
1013
1014         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1015             &$code( $class, delete $flags->{$flag} );
1016         }
1017         else {
1018             $class->log->warn(qq/Unknown flag "$flag"/);
1019         }
1020     }
1021
1022     eval { require Catalyst::Devel; };
1023     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1024         $class->log->warn(<<"EOF");
1025 You are running an old script!
1026
1027   Please update by running (this will overwrite existing files):
1028     catalyst.pl -force -scripts $class
1029
1030   or (this will not overwrite existing files):
1031     catalyst.pl -scripts $class
1032
1033 EOF
1034     }
1035
1036     if ( $class->debug ) {
1037         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1038
1039         if (@plugins) {
1040             my $column_width = Catalyst::Utils::term_width() - 6;
1041             my $t = Text::SimpleTable->new($column_width);
1042             $t->row($_) for @plugins;
1043             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1044         }
1045
1046         my $dispatcher = $class->dispatcher;
1047         my $engine     = $class->engine;
1048         my $home       = $class->config->{home};
1049
1050         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1051         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1052
1053         $home
1054           ? ( -d $home )
1055           ? $class->log->debug(qq/Found home "$home"/)
1056           : $class->log->debug(qq/Home "$home" doesn't exist/)
1057           : $class->log->debug(q/Couldn't find home/);
1058     }
1059
1060     # Call plugins setup, this is stupid and evil.
1061     # Also screws C3 badly on 5.10, hack to avoid.
1062     {
1063         no warnings qw/redefine/;
1064         local *setup = sub { };
1065         $class->setup unless $Catalyst::__AM_RESTARTING;
1066     }
1067
1068     # Initialize our data structure
1069     $class->components( {} );
1070
1071     $class->setup_components;
1072
1073     if ( $class->debug ) {
1074         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1075         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1076         for my $comp ( sort keys %{ $class->components } ) {
1077             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1078             $t->row( $comp, $type );
1079         }
1080         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1081           if ( keys %{ $class->components } );
1082     }
1083
1084     # Add our self to components, since we are also a component
1085     if( $class->isa('Catalyst::Controller') ){
1086       $class->components->{$class} = $class;
1087     }
1088
1089     $class->setup_actions;
1090
1091     if ( $class->debug ) {
1092         my $name = $class->config->{name} || 'Application';
1093         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1094     }
1095     $class->log->_flush() if $class->log->can('_flush');
1096
1097     # Make sure that the application class becomes immutable at this point,
1098     # which ensures that it gets an inlined constructor. This means that it
1099     # works even if the user has added a plugin which contains a new method.
1100     # Note however that we have to do the work on scope end, so that method
1101     # modifiers work correctly in MyApp (as you have to call setup _before_
1102     # applying modifiers).
1103     Scope::Upper::reap(sub {
1104         my $meta = Class::MOP::get_metaclass_by_name($class);
1105         $meta->make_immutable(replace_constructor => 1) unless $meta->is_immutable;
1106     }, Scope::Upper::SCOPE(1));
1107
1108     $class->setup_finalize;
1109 }
1110
1111
1112 =head2 $app->setup_finalize
1113
1114 A hook to attach modifiers to.
1115 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1116 Also better than C< setup_finished(); >, as that is a getter method.
1117
1118     sub setup_finalize {
1119
1120         my $app = shift;
1121
1122         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1123
1124         $app->next::method(@_);
1125
1126
1127     }
1128
1129 =cut
1130
1131 sub setup_finalize {
1132     my ($class) = @_;
1133     $class->setup_finished(1);
1134 }
1135
1136 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1137
1138 =head2 $c->uri_for( $path, @args?, \%query_values? )
1139
1140 =over
1141
1142 =item $action
1143
1144 A Catalyst::Action object representing the Catalyst action you want to
1145 create a URI for. To get one for an action in the current controller,
1146 use C<< $c->action('someactionname') >>. To get one from different
1147 controller, fetch the controller using C<< $c->controller() >>, then
1148 call C<action_for> on it.
1149
1150 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1151 using C<< $c->req->captures >>.
1152
1153   # For the current action
1154   $c->uri_for($c->action, $c->req->captures);
1155
1156   # For the Foo action in the Bar controller
1157   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1158
1159 =back
1160
1161 =cut
1162
1163 sub uri_for {
1164     my ( $c, $path, @args ) = @_;
1165
1166     if ( blessed($path) ) { # action object
1167         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1168                          ? shift(@args)
1169                          : [] );
1170         my $action = $path;
1171         $path = $c->dispatcher->uri_for_action($action, $captures);
1172         if (not defined $path) {
1173             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1174                 if $c->debug;
1175             return undef;
1176         }
1177         $path = '/' if $path eq '';
1178     }
1179
1180     undef($path) if (defined $path && $path eq '');
1181
1182     my $params =
1183       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1184
1185     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1186     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1187
1188     unshift(@args, $path);
1189
1190     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1191         my $namespace = $c->namespace;
1192         if (defined $path) { # cheesy hack to handle path '../foo'
1193            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1194         }
1195         unshift(@args, $namespace || '');
1196     }
1197
1198     # join args with '/', or a blank string
1199     my $args = join('/', grep { defined($_) } @args);
1200     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1201     $args =~ s!^/+!!;
1202     my $base = $c->req->base;
1203     my $class = ref($base);
1204     $base =~ s{(?<!/)$}{/};
1205
1206     my $query = '';
1207
1208     if (my @keys = keys %$params) {
1209       # somewhat lifted from URI::_query's query_form
1210       $query = '?'.join('&', map {
1211           my $val = $params->{$_};
1212           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1213           s/ /+/g;
1214           my $key = $_;
1215           $val = '' unless defined $val;
1216           (map {
1217               $_ = "$_";
1218               utf8::encode( $_ ) if utf8::is_utf8($_);
1219               # using the URI::Escape pattern here so utf8 chars survive
1220               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1221               s/ /+/g;
1222               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1223       } @keys);
1224     }
1225
1226     my $res = bless(\"${base}${args}${query}", $class);
1227     $res;
1228 }
1229
1230 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1231
1232 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1233
1234 =over
1235
1236 =item $path
1237
1238 A private path to the Catalyst action you want to create a URI for.
1239
1240 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1241 >> and passing the resulting C<$action> and the remaining arguments to C<<
1242 $c->uri_for >>.
1243
1244 You can also pass in a Catalyst::Action object, in which case it is passed to
1245 C<< $c->uri_for >>.
1246
1247 =back
1248
1249 =cut
1250
1251 sub uri_for_action {
1252     my ( $c, $path, @args ) = @_;
1253     my $action = blessed($path)
1254       ? $path
1255       : $c->dispatcher->get_action_by_path($path);
1256     unless (defined $action) {
1257       croak "Can't find action for path '$path'";
1258     }
1259     return $c->uri_for( $action, @args );
1260 }
1261
1262 =head2 $c->welcome_message
1263
1264 Returns the Catalyst welcome HTML page.
1265
1266 =cut
1267
1268 sub welcome_message {
1269     my $c      = shift;
1270     my $name   = $c->config->{name};
1271     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1272     my $prefix = Catalyst::Utils::appprefix( ref $c );
1273     $c->response->content_type('text/html; charset=utf-8');
1274     return <<"EOF";
1275 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1276     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1277 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1278     <head>
1279     <meta http-equiv="Content-Language" content="en" />
1280     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1281         <title>$name on Catalyst $VERSION</title>
1282         <style type="text/css">
1283             body {
1284                 color: #000;
1285                 background-color: #eee;
1286             }
1287             div#content {
1288                 width: 640px;
1289                 margin-left: auto;
1290                 margin-right: auto;
1291                 margin-top: 10px;
1292                 margin-bottom: 10px;
1293                 text-align: left;
1294                 background-color: #ccc;
1295                 border: 1px solid #aaa;
1296             }
1297             p, h1, h2 {
1298                 margin-left: 20px;
1299                 margin-right: 20px;
1300                 font-family: verdana, tahoma, sans-serif;
1301             }
1302             a {
1303                 font-family: verdana, tahoma, sans-serif;
1304             }
1305             :link, :visited {
1306                     text-decoration: none;
1307                     color: #b00;
1308                     border-bottom: 1px dotted #bbb;
1309             }
1310             :link:hover, :visited:hover {
1311                     color: #555;
1312             }
1313             div#topbar {
1314                 margin: 0px;
1315             }
1316             pre {
1317                 margin: 10px;
1318                 padding: 8px;
1319             }
1320             div#answers {
1321                 padding: 8px;
1322                 margin: 10px;
1323                 background-color: #fff;
1324                 border: 1px solid #aaa;
1325             }
1326             h1 {
1327                 font-size: 0.9em;
1328                 font-weight: normal;
1329                 text-align: center;
1330             }
1331             h2 {
1332                 font-size: 1.0em;
1333             }
1334             p {
1335                 font-size: 0.9em;
1336             }
1337             p img {
1338                 float: right;
1339                 margin-left: 10px;
1340             }
1341             span#appname {
1342                 font-weight: bold;
1343                 font-size: 1.6em;
1344             }
1345         </style>
1346     </head>
1347     <body>
1348         <div id="content">
1349             <div id="topbar">
1350                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1351                     $VERSION</h1>
1352              </div>
1353              <div id="answers">
1354                  <p>
1355                  <img src="$logo" alt="Catalyst Logo" />
1356                  </p>
1357                  <p>Welcome to the  world of Catalyst.
1358                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1359                     framework will make web development something you had
1360                     never expected it to be: Fun, rewarding, and quick.</p>
1361                  <h2>What to do now?</h2>
1362                  <p>That really depends  on what <b>you</b> want to do.
1363                     We do, however, provide you with a few starting points.</p>
1364                  <p>If you want to jump right into web development with Catalyst
1365                     you might want to start with a tutorial.</p>
1366 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1367 </pre>
1368 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1369 <pre>
1370 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1371 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1372 </code></pre>
1373                  <h2>What to do next?</h2>
1374                  <p>Next it's time to write an actual application. Use the
1375                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1376                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1377                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1378                     they can save you a lot of work.</p>
1379                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1380                     <p>Also, be sure to check out the vast and growing
1381                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1382                     you are likely to find what you need there.
1383                     </p>
1384
1385                  <h2>Need help?</h2>
1386                  <p>Catalyst has a very active community. Here are the main places to
1387                     get in touch with us.</p>
1388                  <ul>
1389                      <li>
1390                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1391                      </li>
1392                      <li>
1393                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1394                      </li>
1395                      <li>
1396                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1397                      </li>
1398                  </ul>
1399                  <h2>In conclusion</h2>
1400                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1401                     as we enjoyed making it. Please contact us if you have ideas
1402                     for improvement or other feedback.</p>
1403              </div>
1404          </div>
1405     </body>
1406 </html>
1407 EOF
1408 }
1409
1410 =head1 INTERNAL METHODS
1411
1412 These methods are not meant to be used by end users.
1413
1414 =head2 $c->components
1415
1416 Returns a hash of components.
1417
1418 =head2 $c->context_class
1419
1420 Returns or sets the context class.
1421
1422 =head2 $c->counter
1423
1424 Returns a hashref containing coderefs and execution counts (needed for
1425 deep recursion detection).
1426
1427 =head2 $c->depth
1428
1429 Returns the number of actions on the current internal execution stack.
1430
1431 =head2 $c->dispatch
1432
1433 Dispatches a request to actions.
1434
1435 =cut
1436
1437 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1438
1439 =head2 $c->dispatcher_class
1440
1441 Returns or sets the dispatcher class.
1442
1443 =head2 $c->dump_these
1444
1445 Returns a list of 2-element array references (name, structure) pairs
1446 that will be dumped on the error page in debug mode.
1447
1448 =cut
1449
1450 sub dump_these {
1451     my $c = shift;
1452     [ Request => $c->req ],
1453     [ Response => $c->res ],
1454     [ Stash => $c->stash ],
1455     [ Config => $c->config ];
1456 }
1457
1458 =head2 $c->engine_class
1459
1460 Returns or sets the engine class.
1461
1462 =head2 $c->execute( $class, $coderef )
1463
1464 Execute a coderef in given class and catch exceptions. Errors are available
1465 via $c->error.
1466
1467 =cut
1468
1469 sub execute {
1470     my ( $c, $class, $code ) = @_;
1471     $class = $c->component($class) || $class;
1472     $c->state(0);
1473
1474     if ( $c->depth >= $RECURSION ) {
1475         my $action = $code->reverse();
1476         $action = "/$action" unless $action =~ /->/;
1477         my $error = qq/Deep recursion detected calling "${action}"/;
1478         $c->log->error($error);
1479         $c->error($error);
1480         $c->state(0);
1481         return $c->state;
1482     }
1483
1484     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1485
1486     push( @{ $c->stack }, $code );
1487
1488     no warnings 'recursion';
1489     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1490
1491     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1492
1493     my $last = pop( @{ $c->stack } );
1494
1495     if ( my $error = $@ ) {
1496         if ( !ref($error) and $error eq $DETACH ) {
1497             die $DETACH if($c->depth > 1);
1498         }
1499         elsif ( !ref($error) and $error eq $GO ) {
1500             die $GO if($c->depth > 0);
1501         }
1502         else {
1503             unless ( ref $error ) {
1504                 no warnings 'uninitialized';
1505                 chomp $error;
1506                 my $class = $last->class;
1507                 my $name  = $last->name;
1508                 $error = qq/Caught exception in $class->$name "$error"/;
1509             }
1510             $c->error($error);
1511             $c->state(0);
1512         }
1513     }
1514     return $c->state;
1515 }
1516
1517 sub _stats_start_execute {
1518     my ( $c, $code ) = @_;
1519
1520     return if ( ( $code->name =~ /^_.*/ )
1521         && ( !$c->config->{show_internal_actions} ) );
1522
1523     my $action_name = $code->reverse();
1524     $c->counter->{$action_name}++;
1525
1526     my $action = $action_name;
1527     $action = "/$action" unless $action =~ /->/;
1528
1529     # determine if the call was the result of a forward
1530     # this is done by walking up the call stack and looking for a calling
1531     # sub of Catalyst::forward before the eval
1532     my $callsub = q{};
1533     for my $index ( 2 .. 11 ) {
1534         last
1535         if ( ( caller($index) )[0] eq 'Catalyst'
1536             && ( caller($index) )[3] eq '(eval)' );
1537
1538         if ( ( caller($index) )[3] =~ /forward$/ ) {
1539             $callsub = ( caller($index) )[3];
1540             $action  = "-> $action";
1541             last;
1542         }
1543     }
1544
1545     my $uid = $action_name . $c->counter->{$action_name};
1546
1547     # is this a root-level call or a forwarded call?
1548     if ( $callsub =~ /forward$/ ) {
1549
1550         # forward, locate the caller
1551         if ( my $parent = $c->stack->[-1] ) {
1552             $c->stats->profile(
1553                 begin  => $action,
1554                 parent => "$parent" . $c->counter->{"$parent"},
1555                 uid    => $uid,
1556             );
1557         }
1558         else {
1559
1560             # forward with no caller may come from a plugin
1561             $c->stats->profile(
1562                 begin => $action,
1563                 uid   => $uid,
1564             );
1565         }
1566     }
1567     else {
1568
1569         # root-level call
1570         $c->stats->profile(
1571             begin => $action,
1572             uid   => $uid,
1573         );
1574     }
1575     return $action;
1576
1577 }
1578
1579 sub _stats_finish_execute {
1580     my ( $c, $info ) = @_;
1581     $c->stats->profile( end => $info );
1582 }
1583
1584 =head2 $c->_localize_fields( sub { }, \%keys );
1585
1586 =cut
1587
1588 #Why does this exist? This is no longer safe and WILL NOT WORK.
1589 # it doesnt seem to be used anywhere. can we remove it?
1590 sub _localize_fields {
1591     my ( $c, $localized, $code ) = ( @_ );
1592
1593     my $request = delete $localized->{request} || {};
1594     my $response = delete $localized->{response} || {};
1595
1596     local @{ $c }{ keys %$localized } = values %$localized;
1597     local @{ $c->request }{ keys %$request } = values %$request;
1598     local @{ $c->response }{ keys %$response } = values %$response;
1599
1600     $code->();
1601 }
1602
1603 =head2 $c->finalize
1604
1605 Finalizes the request.
1606
1607 =cut
1608
1609 sub finalize {
1610     my $c = shift;
1611
1612     for my $error ( @{ $c->error } ) {
1613         $c->log->error($error);
1614     }
1615
1616     # Allow engine to handle finalize flow (for POE)
1617     my $engine = $c->engine;
1618     if ( my $code = $engine->can('finalize') ) {
1619         $engine->$code($c);
1620     }
1621     else {
1622
1623         $c->finalize_uploads;
1624
1625         # Error
1626         if ( $#{ $c->error } >= 0 ) {
1627             $c->finalize_error;
1628         }
1629
1630         $c->finalize_headers;
1631
1632         # HEAD request
1633         if ( $c->request->method eq 'HEAD' ) {
1634             $c->response->body('');
1635         }
1636
1637         $c->finalize_body;
1638     }
1639
1640     if ($c->use_stats) {
1641         my $elapsed = sprintf '%f', $c->stats->elapsed;
1642         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1643         $c->log->info(
1644             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1645     }
1646
1647     return $c->response->status;
1648 }
1649
1650 =head2 $c->finalize_body
1651
1652 Finalizes body.
1653
1654 =cut
1655
1656 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1657
1658 =head2 $c->finalize_cookies
1659
1660 Finalizes cookies.
1661
1662 =cut
1663
1664 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1665
1666 =head2 $c->finalize_error
1667
1668 Finalizes error.
1669
1670 =cut
1671
1672 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1673
1674 =head2 $c->finalize_headers
1675
1676 Finalizes headers.
1677
1678 =cut
1679
1680 sub finalize_headers {
1681     my $c = shift;
1682
1683     my $response = $c->response; #accessor calls can add up?
1684
1685     # Check if we already finalized headers
1686     return if $response->finalized_headers;
1687
1688     # Handle redirects
1689     if ( my $location = $response->redirect ) {
1690         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1691         $response->header( Location => $location );
1692
1693         if ( !$response->has_body ) {
1694             # Add a default body if none is already present
1695             $response->body(
1696                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1697             );
1698         }
1699     }
1700
1701     # Content-Length
1702     if ( $response->body && !$response->content_length ) {
1703
1704         # get the length from a filehandle
1705         if ( blessed( $response->body ) && $response->body->can('read') )
1706         {
1707             my $stat = stat $response->body;
1708             if ( $stat && $stat->size > 0 ) {
1709                 $response->content_length( $stat->size );
1710             }
1711             else {
1712                 $c->log->warn('Serving filehandle without a content-length');
1713             }
1714         }
1715         else {
1716             # everything should be bytes at this point, but just in case
1717             $response->content_length( bytes::length( $response->body ) );
1718         }
1719     }
1720
1721     # Errors
1722     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1723         $response->headers->remove_header("Content-Length");
1724         $response->body('');
1725     }
1726
1727     $c->finalize_cookies;
1728
1729     $c->engine->finalize_headers( $c, @_ );
1730
1731     # Done
1732     $response->finalized_headers(1);
1733 }
1734
1735 =head2 $c->finalize_output
1736
1737 An alias for finalize_body.
1738
1739 =head2 $c->finalize_read
1740
1741 Finalizes the input after reading is complete.
1742
1743 =cut
1744
1745 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1746
1747 =head2 $c->finalize_uploads
1748
1749 Finalizes uploads. Cleans up any temporary files.
1750
1751 =cut
1752
1753 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1754
1755 =head2 $c->get_action( $action, $namespace )
1756
1757 Gets an action in a given namespace.
1758
1759 =cut
1760
1761 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1762
1763 =head2 $c->get_actions( $action, $namespace )
1764
1765 Gets all actions of a given name in a namespace and all parent
1766 namespaces.
1767
1768 =cut
1769
1770 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1771
1772 =head2 $c->handle_request( $class, @arguments )
1773
1774 Called to handle each HTTP request.
1775
1776 =cut
1777
1778 sub handle_request {
1779     my ( $class, @arguments ) = @_;
1780
1781     # Always expect worst case!
1782     my $status = -1;
1783     eval {
1784         if ($class->debug) {
1785             my $secs = time - $START || 1;
1786             my $av = sprintf '%.3f', $COUNT / $secs;
1787             my $time = localtime time;
1788             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1789         }
1790
1791         my $c = $class->prepare(@arguments);
1792         $c->dispatch;
1793         $status = $c->finalize;
1794     };
1795
1796     if ( my $error = $@ ) {
1797         chomp $error;
1798         $class->log->error(qq/Caught exception in engine "$error"/);
1799     }
1800
1801     $COUNT++;
1802
1803     if(my $coderef = $class->log->can('_flush')){
1804         $class->log->$coderef();
1805     }
1806     return $status;
1807 }
1808
1809 =head2 $c->prepare( @arguments )
1810
1811 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1812 etc.).
1813
1814 =cut
1815
1816 sub prepare {
1817     my ( $class, @arguments ) = @_;
1818
1819     # XXX
1820     # After the app/ctxt split, this should become an attribute based on something passed
1821     # into the application.
1822     $class->context_class( ref $class || $class ) unless $class->context_class;
1823
1824     my $c = $class->context_class->new({});
1825
1826     # For on-demand data
1827     $c->request->_context($c);
1828     $c->response->_context($c);
1829
1830     #surely this is not the most efficient way to do things...
1831     $c->stats($class->stats_class->new)->enable($c->use_stats);
1832     if ( $c->debug ) {
1833         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1834     }
1835
1836     #XXX reuse coderef from can
1837     # Allow engine to direct the prepare flow (for POE)
1838     if ( $c->engine->can('prepare') ) {
1839         $c->engine->prepare( $c, @arguments );
1840     }
1841     else {
1842         $c->prepare_request(@arguments);
1843         $c->prepare_connection;
1844         $c->prepare_query_parameters;
1845         $c->prepare_headers;
1846         $c->prepare_cookies;
1847         $c->prepare_path;
1848
1849         # Prepare the body for reading, either by prepare_body
1850         # or the user, if they are using $c->read
1851         $c->prepare_read;
1852
1853         # Parse the body unless the user wants it on-demand
1854         unless ( $c->config->{parse_on_demand} ) {
1855             $c->prepare_body;
1856         }
1857     }
1858
1859     my $method  = $c->req->method  || '';
1860     my $path    = $c->req->path;
1861     $path       = '/' unless length $path;
1862     my $address = $c->req->address || '';
1863
1864     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1865       if $c->debug;
1866
1867     $c->prepare_action;
1868
1869     return $c;
1870 }
1871
1872 =head2 $c->prepare_action
1873
1874 Prepares action. See L<Catalyst::Dispatcher>.
1875
1876 =cut
1877
1878 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1879
1880 =head2 $c->prepare_body
1881
1882 Prepares message body.
1883
1884 =cut
1885
1886 sub prepare_body {
1887     my $c = shift;
1888
1889     return if $c->request->_has_body;
1890
1891     # Initialize on-demand data
1892     $c->engine->prepare_body( $c, @_ );
1893     $c->prepare_parameters;
1894     $c->prepare_uploads;
1895
1896     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1897         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1898         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1899             my $param = $c->req->body_parameters->{$key};
1900             my $value = defined($param) ? $param : '';
1901             $t->row( $key,
1902                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1903         }
1904         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1905     }
1906 }
1907
1908 =head2 $c->prepare_body_chunk( $chunk )
1909
1910 Prepares a chunk of data before sending it to L<HTTP::Body>.
1911
1912 See L<Catalyst::Engine>.
1913
1914 =cut
1915
1916 sub prepare_body_chunk {
1917     my $c = shift;
1918     $c->engine->prepare_body_chunk( $c, @_ );
1919 }
1920
1921 =head2 $c->prepare_body_parameters
1922
1923 Prepares body parameters.
1924
1925 =cut
1926
1927 sub prepare_body_parameters {
1928     my $c = shift;
1929     $c->engine->prepare_body_parameters( $c, @_ );
1930 }
1931
1932 =head2 $c->prepare_connection
1933
1934 Prepares connection.
1935
1936 =cut
1937
1938 sub prepare_connection {
1939     my $c = shift;
1940     $c->engine->prepare_connection( $c, @_ );
1941 }
1942
1943 =head2 $c->prepare_cookies
1944
1945 Prepares cookies.
1946
1947 =cut
1948
1949 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1950
1951 =head2 $c->prepare_headers
1952
1953 Prepares headers.
1954
1955 =cut
1956
1957 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1958
1959 =head2 $c->prepare_parameters
1960
1961 Prepares parameters.
1962
1963 =cut
1964
1965 sub prepare_parameters {
1966     my $c = shift;
1967     $c->prepare_body_parameters;
1968     $c->engine->prepare_parameters( $c, @_ );
1969 }
1970
1971 =head2 $c->prepare_path
1972
1973 Prepares path and base.
1974
1975 =cut
1976
1977 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1978
1979 =head2 $c->prepare_query_parameters
1980
1981 Prepares query parameters.
1982
1983 =cut
1984
1985 sub prepare_query_parameters {
1986     my $c = shift;
1987
1988     $c->engine->prepare_query_parameters( $c, @_ );
1989
1990     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1991         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1992         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1993             my $param = $c->req->query_parameters->{$key};
1994             my $value = defined($param) ? $param : '';
1995             $t->row( $key,
1996                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1997         }
1998         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1999     }
2000 }
2001
2002 =head2 $c->prepare_read
2003
2004 Prepares the input for reading.
2005
2006 =cut
2007
2008 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2009
2010 =head2 $c->prepare_request
2011
2012 Prepares the engine request.
2013
2014 =cut
2015
2016 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2017
2018 =head2 $c->prepare_uploads
2019
2020 Prepares uploads.
2021
2022 =cut
2023
2024 sub prepare_uploads {
2025     my $c = shift;
2026
2027     $c->engine->prepare_uploads( $c, @_ );
2028
2029     if ( $c->debug && keys %{ $c->request->uploads } ) {
2030         my $t = Text::SimpleTable->new(
2031             [ 12, 'Parameter' ],
2032             [ 26, 'Filename' ],
2033             [ 18, 'Type' ],
2034             [ 9,  'Size' ]
2035         );
2036         for my $key ( sort keys %{ $c->request->uploads } ) {
2037             my $upload = $c->request->uploads->{$key};
2038             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2039                 $t->row( $key, $u->filename, $u->type, $u->size );
2040             }
2041         }
2042         $c->log->debug( "File Uploads are:\n" . $t->draw );
2043     }
2044 }
2045
2046 =head2 $c->prepare_write
2047
2048 Prepares the output for writing.
2049
2050 =cut
2051
2052 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2053
2054 =head2 $c->request_class
2055
2056 Returns or sets the request class.
2057
2058 =head2 $c->response_class
2059
2060 Returns or sets the response class.
2061
2062 =head2 $c->read( [$maxlength] )
2063
2064 Reads a chunk of data from the request body. This method is designed to
2065 be used in a while loop, reading C<$maxlength> bytes on every call.
2066 C<$maxlength> defaults to the size of the request if not specified.
2067
2068 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
2069 directly.
2070
2071 Warning: If you use read(), Catalyst will not process the body,
2072 so you will not be able to access POST parameters or file uploads via
2073 $c->request.  You must handle all body parsing yourself.
2074
2075 =cut
2076
2077 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2078
2079 =head2 $c->run
2080
2081 Starts the engine.
2082
2083 =cut
2084
2085 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2086
2087 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2088
2089 Sets an action in a given namespace.
2090
2091 =cut
2092
2093 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2094
2095 =head2 $c->setup_actions($component)
2096
2097 Sets up actions for a component.
2098
2099 =cut
2100
2101 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2102
2103 =head2 $c->setup_components
2104
2105 Sets up components. Specify a C<setup_components> config option to pass
2106 additional options directly to L<Module::Pluggable>. To add additional
2107 search paths, specify a key named C<search_extra> as an array
2108 reference. Items in the array beginning with C<::> will have the
2109 application class name prepended to them.
2110
2111 All components found will also have any
2112 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2113 Note, that modules which are B<not> an I<inner package> of the main
2114 file namespace loaded will not be instantiated as components.
2115
2116 =cut
2117
2118 sub setup_components {
2119     my $class = shift;
2120
2121     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2122     my $config  = $class->config->{ setup_components };
2123     my $extra   = delete $config->{ search_extra } || [];
2124
2125     push @paths, @$extra;
2126
2127     my $locator = Module::Pluggable::Object->new(
2128         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2129         %$config
2130     );
2131
2132     my @comps = sort { length $a <=> length $b } $locator->plugins;
2133     my %comps = map { $_ => 1 } @comps;
2134
2135     my $deprecated_component_names = grep { /::[CMV]::/ } @comps;
2136     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2137         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2138     ) if $deprecated_component_names;
2139
2140     for my $component ( @comps ) {
2141
2142         # We pass ignore_loaded here so that overlay files for (e.g.)
2143         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2144         # we know M::P::O found a file on disk so this is safe
2145
2146         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2147         #Class::MOP::load_class($component);
2148
2149         my $module  = $class->setup_component( $component );
2150         my %modules = (
2151             $component => $module,
2152             map {
2153                 $_ => $class->setup_component( $_ )
2154             } grep {
2155               not exists $comps{$_}
2156             } Devel::InnerPackage::list_packages( $component )
2157         );
2158
2159         for my $key ( keys %modules ) {
2160             $class->components->{ $key } = $modules{ $key };
2161         }
2162     }
2163 }
2164
2165 =head2 $c->setup_component
2166
2167 =cut
2168
2169 sub _controller_init_base_classes {
2170     my ($app_class, $component) = @_;
2171     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2172         next unless $class =~ /^$app_class/;
2173         Moose->init_meta( for_class => $class )
2174             unless find_meta($class);
2175     }
2176 }
2177
2178 sub setup_component {
2179     my( $class, $component ) = @_;
2180
2181     unless ( $component->can( 'COMPONENT' ) ) {
2182         return $component;
2183     }
2184
2185     # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2186     #         nearest to Catalyst::Controller first, no matter what order stuff happens
2187     #         to be loaded. There are TODO tests in Moose for this, see
2188     #         f2391d17574eff81d911b97be15ea51080500003
2189     if ($component->isa('Catalyst::Controller')) {
2190         $class->_controller_init_base_classes($component);
2191     }
2192
2193     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2194     my $config = $class->config->{ $suffix } || {};
2195
2196     my $instance = eval { $component->COMPONENT( $class, $config ); };
2197
2198     if ( my $error = $@ ) {
2199         chomp $error;
2200         Catalyst::Exception->throw(
2201             message => qq/Couldn't instantiate component "$component", "$error"/
2202         );
2203     }
2204
2205     unless (blessed $instance) {
2206         my $metaclass = Moose::Util::find_meta($component);
2207         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2208         my $component_method_from = $method_meta->associated_metaclass->name;
2209         my $value = defined($instance) ? $instance : 'undef';
2210         Catalyst::Exception->throw(
2211             message =>
2212             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2213         );
2214     }
2215     return $instance;
2216 }
2217
2218 =head2 $c->setup_dispatcher
2219
2220 Sets up dispatcher.
2221
2222 =cut
2223
2224 sub setup_dispatcher {
2225     my ( $class, $dispatcher ) = @_;
2226
2227     if ($dispatcher) {
2228         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2229     }
2230
2231     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2232         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2233     }
2234
2235     unless ($dispatcher) {
2236         $dispatcher = $class->dispatcher_class;
2237     }
2238
2239     Class::MOP::load_class($dispatcher);
2240
2241     # dispatcher instance
2242     $class->dispatcher( $dispatcher->new );
2243 }
2244
2245 =head2 $c->setup_engine
2246
2247 Sets up engine.
2248
2249 =cut
2250
2251 sub setup_engine {
2252     my ( $class, $engine ) = @_;
2253
2254     if ($engine) {
2255         $engine = 'Catalyst::Engine::' . $engine;
2256     }
2257
2258     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2259         $engine = 'Catalyst::Engine::' . $env;
2260     }
2261
2262     if ( $ENV{MOD_PERL} ) {
2263         my $meta = Class::MOP::get_metaclass_by_name($class);
2264
2265         # create the apache method
2266         $meta->add_method('apache' => sub { shift->engine->apache });
2267
2268         my ( $software, $version ) =
2269           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2270
2271         $version =~ s/_//g;
2272         $version =~ s/(\.[^.]+)\./$1/g;
2273
2274         if ( $software eq 'mod_perl' ) {
2275
2276             if ( !$engine ) {
2277
2278                 if ( $version >= 1.99922 ) {
2279                     $engine = 'Catalyst::Engine::Apache2::MP20';
2280                 }
2281
2282                 elsif ( $version >= 1.9901 ) {
2283                     $engine = 'Catalyst::Engine::Apache2::MP19';
2284                 }
2285
2286                 elsif ( $version >= 1.24 ) {
2287                     $engine = 'Catalyst::Engine::Apache::MP13';
2288                 }
2289
2290                 else {
2291                     Catalyst::Exception->throw( message =>
2292                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2293                 }
2294
2295             }
2296
2297             # install the correct mod_perl handler
2298             if ( $version >= 1.9901 ) {
2299                 *handler = sub  : method {
2300                     shift->handle_request(@_);
2301                 };
2302             }
2303             else {
2304                 *handler = sub ($$) { shift->handle_request(@_) };
2305             }
2306
2307         }
2308
2309         elsif ( $software eq 'Zeus-Perl' ) {
2310             $engine = 'Catalyst::Engine::Zeus';
2311         }
2312
2313         else {
2314             Catalyst::Exception->throw(
2315                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2316         }
2317     }
2318
2319     unless ($engine) {
2320         $engine = $class->engine_class;
2321     }
2322
2323     Class::MOP::load_class($engine);
2324
2325     # check for old engines that are no longer compatible
2326     my $old_engine;
2327     if ( $engine->isa('Catalyst::Engine::Apache')
2328         && !Catalyst::Engine::Apache->VERSION )
2329     {
2330         $old_engine = 1;
2331     }
2332
2333     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2334         && Catalyst::Engine::Server->VERSION le '0.02' )
2335     {
2336         $old_engine = 1;
2337     }
2338
2339     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2340         && $engine->VERSION eq '0.01' )
2341     {
2342         $old_engine = 1;
2343     }
2344
2345     elsif ($engine->isa('Catalyst::Engine::Zeus')
2346         && $engine->VERSION eq '0.01' )
2347     {
2348         $old_engine = 1;
2349     }
2350
2351     if ($old_engine) {
2352         Catalyst::Exception->throw( message =>
2353               qq/Engine "$engine" is not supported by this version of Catalyst/
2354         );
2355     }
2356
2357     # engine instance
2358     $class->engine( $engine->new );
2359 }
2360
2361 =head2 $c->setup_home
2362
2363 Sets up the home directory.
2364
2365 =cut
2366
2367 sub setup_home {
2368     my ( $class, $home ) = @_;
2369
2370     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2371         $home = $env;
2372     }
2373
2374     $home ||= Catalyst::Utils::home($class);
2375
2376     if ($home) {
2377         #I remember recently being scolded for assigning config values like this
2378         $class->config->{home} ||= $home;
2379         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2380     }
2381 }
2382
2383 =head2 $c->setup_log
2384
2385 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2386 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2387 log to.
2388
2389 This method also installs a C<debug> method that returns a true value into the
2390 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2391 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2392
2393 Note that if the log has already been setup, by either a previous call to
2394 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2395 that this method won't actually set up the log object.
2396
2397 =cut
2398
2399 sub setup_log {
2400     my ( $class, $levels ) = @_;
2401
2402     $levels ||= '';
2403     $levels =~ s/^\s+//;
2404     $levels =~ s/\s+$//;
2405     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2406
2407     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2408     if ( defined $env_debug ) {
2409         $levels{debug} = 1 if $env_debug; # Ugly!
2410         delete($levels{debug}) unless $env_debug;
2411     }
2412
2413     unless ( $class->log ) {
2414         $class->log( Catalyst::Log->new(keys %levels) );
2415     }
2416
2417     if ( $levels{debug} ) {
2418         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2419         $class->log->debug('Debug messages enabled');
2420     }
2421 }
2422
2423 =head2 $c->setup_plugins
2424
2425 Sets up plugins.
2426
2427 =cut
2428
2429 =head2 $c->setup_stats
2430
2431 Sets up timing statistics class.
2432
2433 =cut
2434
2435 sub setup_stats {
2436     my ( $class, $stats ) = @_;
2437
2438     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2439
2440     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2441     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2442         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2443         $class->log->debug('Statistics enabled');
2444     }
2445 }
2446
2447
2448 =head2 $c->registered_plugins
2449
2450 Returns a sorted list of the plugins which have either been stated in the
2451 import list or which have been added via C<< MyApp->plugin(@args); >>.
2452
2453 If passed a given plugin name, it will report a boolean value indicating
2454 whether or not that plugin is loaded.  A fully qualified name is required if
2455 the plugin name does not begin with C<Catalyst::Plugin::>.
2456
2457  if ($c->registered_plugins('Some::Plugin')) {
2458      ...
2459  }
2460
2461 =cut
2462
2463 {
2464
2465     sub registered_plugins {
2466         my $proto = shift;
2467         return sort keys %{ $proto->_plugins } unless @_;
2468         my $plugin = shift;
2469         return 1 if exists $proto->_plugins->{$plugin};
2470         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2471     }
2472
2473     sub _register_plugin {
2474         my ( $proto, $plugin, $instant ) = @_;
2475         my $class = ref $proto || $proto;
2476
2477         # no ignore_loaded here, the plugin may already have been
2478         # defined in memory and we don't want to error on "no file" if so
2479
2480         Class::MOP::load_class( $plugin );
2481
2482         $proto->_plugins->{$plugin} = 1;
2483         unless ($instant) {
2484             no strict 'refs';
2485             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2486               my @superclasses = ($plugin, $meta->superclasses );
2487               $meta->superclasses(@superclasses);
2488             } else {
2489               unshift @{"$class\::ISA"}, $plugin;
2490             }
2491         }
2492         return $class;
2493     }
2494
2495     sub setup_plugins {
2496         my ( $class, $plugins ) = @_;
2497
2498         $class->_plugins( {} ) unless $class->_plugins;
2499         $plugins ||= [];
2500         for my $plugin ( reverse @$plugins ) {
2501
2502             unless ( $plugin =~ s/\A\+// ) {
2503                 $plugin = "Catalyst::Plugin::$plugin";
2504             }
2505
2506             $class->_register_plugin($plugin);
2507         }
2508     }
2509 }
2510
2511 =head2 $c->stack
2512
2513 Returns an arrayref of the internal execution stack (actions that are
2514 currently executing).
2515
2516 =head2 $c->stats_class
2517
2518 Returns or sets the stats (timing statistics) class.
2519
2520 =head2 $c->use_stats
2521
2522 Returns 1 when stats collection is enabled.  Stats collection is enabled
2523 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2524 environment variable is set.
2525
2526 Note that this is a static method, not an accessor and should be overridden
2527 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2528
2529 =cut
2530
2531 sub use_stats { 0 }
2532
2533
2534 =head2 $c->write( $data )
2535
2536 Writes $data to the output stream. When using this method directly, you
2537 will need to manually set the C<Content-Length> header to the length of
2538 your output data, if known.
2539
2540 =cut
2541
2542 sub write {
2543     my $c = shift;
2544
2545     # Finalize headers if someone manually writes output
2546     $c->finalize_headers;
2547
2548     return $c->engine->write( $c, @_ );
2549 }
2550
2551 =head2 version
2552
2553 Returns the Catalyst version number. Mostly useful for "powered by"
2554 messages in template systems.
2555
2556 =cut
2557
2558 sub version { return $Catalyst::VERSION }
2559
2560 =head1 INTERNAL ACTIONS
2561
2562 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2563 C<_ACTION>, and C<_END>. These are by default not shown in the private
2564 action table, but you can make them visible with a config parameter.
2565
2566     MyApp->config->{show_internal_actions} = 1;
2567
2568 =head1 CASE SENSITIVITY
2569
2570 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2571 mapped to C</foo/bar>. You can activate case sensitivity with a config
2572 parameter.
2573
2574     MyApp->config->{case_sensitive} = 1;
2575
2576 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2577
2578 =head1 ON-DEMAND PARSER
2579
2580 The request body is usually parsed at the beginning of a request,
2581 but if you want to handle input yourself, you can enable on-demand
2582 parsing with a config parameter.
2583
2584     MyApp->config->{parse_on_demand} = 1;
2585
2586 =head1 PROXY SUPPORT
2587
2588 Many production servers operate using the common double-server approach,
2589 with a lightweight frontend web server passing requests to a larger
2590 backend server. An application running on the backend server must deal
2591 with two problems: the remote user always appears to be C<127.0.0.1> and
2592 the server's hostname will appear to be C<localhost> regardless of the
2593 virtual host that the user connected through.
2594
2595 Catalyst will automatically detect this situation when you are running
2596 the frontend and backend servers on the same machine. The following
2597 changes are made to the request.
2598
2599     $c->req->address is set to the user's real IP address, as read from
2600     the HTTP X-Forwarded-For header.
2601
2602     The host value for $c->req->base and $c->req->uri is set to the real
2603     host, as read from the HTTP X-Forwarded-Host header.
2604
2605 Obviously, your web server must support these headers for this to work.
2606
2607 In a more complex server farm environment where you may have your
2608 frontend proxy server(s) on different machines, you will need to set a
2609 configuration option to tell Catalyst to read the proxied data from the
2610 headers.
2611
2612     MyApp->config->{using_frontend_proxy} = 1;
2613
2614 If you do not wish to use the proxy support at all, you may set:
2615
2616     MyApp->config->{ignore_frontend_proxy} = 1;
2617
2618 =head1 THREAD SAFETY
2619
2620 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2621 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2622 believe the Catalyst core to be thread-safe.
2623
2624 If you plan to operate in a threaded environment, remember that all other
2625 modules you are using must also be thread-safe. Some modules, most notably
2626 L<DBD::SQLite>, are not thread-safe.
2627
2628 =head1 SUPPORT
2629
2630 IRC:
2631
2632     Join #catalyst on irc.perl.org.
2633
2634 Mailing Lists:
2635
2636     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2637     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2638
2639 Web:
2640
2641     http://catalyst.perl.org
2642
2643 Wiki:
2644
2645     http://dev.catalyst.perl.org
2646
2647 =head1 SEE ALSO
2648
2649 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2650
2651 =head2 L<Catalyst::Manual> - The Catalyst Manual
2652
2653 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2654
2655 =head2 L<Catalyst::Engine> - Core engine
2656
2657 =head2 L<Catalyst::Log> - Log class.
2658
2659 =head2 L<Catalyst::Request> - Request object
2660
2661 =head2 L<Catalyst::Response> - Response object
2662
2663 =head2 L<Catalyst::Test> - The test suite.
2664
2665 =head1 PROJECT FOUNDER
2666
2667 sri: Sebastian Riedel <sri@cpan.org>
2668
2669 =head1 CONTRIBUTORS
2670
2671 abw: Andy Wardley
2672
2673 acme: Leon Brocard <leon@astray.com>
2674
2675 Andrew Bramble
2676
2677 Andrew Ford
2678
2679 Andrew Ruthven
2680
2681 andyg: Andy Grundman <andy@hybridized.org>
2682
2683 audreyt: Audrey Tang
2684
2685 bricas: Brian Cassidy <bricas@cpan.org>
2686
2687 Caelum: Rafael Kitover <rkitover@io.com>
2688
2689 chansen: Christian Hansen
2690
2691 chicks: Christopher Hicks
2692
2693 David E. Wheeler
2694
2695 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2696
2697 Drew Taylor
2698
2699 esskar: Sascha Kiefer
2700
2701 fireartist: Carl Franks <cfranks@cpan.org>
2702
2703 gabb: Danijel Milicevic
2704
2705 Gary Ashton Jones
2706
2707 Geoff Richards
2708
2709 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2710
2711 jcamacho: Juan Camacho
2712
2713 jhannah: Jay Hannah <jay@jays.net>
2714
2715 Jody Belka
2716
2717 Johan Lindstrom
2718
2719 jon: Jon Schutz <jjschutz@cpan.org>
2720
2721 marcus: Marcus Ramberg <mramberg@cpan.org>
2722
2723 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2724
2725 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2726
2727 mugwump: Sam Vilain
2728
2729 naughton: David Naughton
2730
2731 ningu: David Kamholz <dkamholz@cpan.org>
2732
2733 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2734
2735 numa: Dan Sully <daniel@cpan.org>
2736
2737 obra: Jesse Vincent
2738
2739 omega: Andreas Marienborg
2740
2741 Oleg Kostyuk <cub.uanic@gmail.com>
2742
2743 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2744
2745 rafl: Florian Ragwitz <rafl@debian.org>
2746
2747 sky: Arthur Bergman
2748
2749 the_jester: Jesse Sheidlower
2750
2751 t0m: Tomas Doran <bobtfish@bobtfish.net>
2752
2753 Ulf Edvinsson
2754
2755 willert: Sebastian Willert <willert@cpan.org>
2756
2757 =head1 LICENSE
2758
2759 This library is free software, you can redistribute it and/or modify it under
2760 the same terms as Perl itself.
2761
2762 =cut
2763
2764 no Moose;
2765
2766 __PACKAGE__->meta->make_immutable;
2767
2768 1;