lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken blessed/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 __PACKAGE__->mk_accessors(
  34     qw/counter request response state action stack namespace stats/
  35 );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52 our $GO        = "catalyst_go\n";
  53
  54 __PACKAGE__->mk_classdata($_)
  55   for qw/components arguments dispatcher engine log dispatcher_class
  56   engine_class context_class request_class response_class stats_class
  57   setup_finished/;
  58
  59 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  60 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  61 __PACKAGE__->request_class('Catalyst::Request');
  62 __PACKAGE__->response_class('Catalyst::Response');
  63 __PACKAGE__->stats_class('Catalyst::Stats');
  64
  65 # Remember to update this in Catalyst::Runtime as well!
  66
  67 our $VERSION = '5.7099_03';
  68
  69 sub import {
  70     my ( $class, @arguments ) = @_;
  71
  72     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  73     # callers @ISA.
  74     return unless $class eq 'Catalyst';
  75
  76     my $caller = caller(0);
  77
  78     unless ( $caller->isa('Catalyst') ) {
  79         no strict 'refs';
  80         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  81     }
  82
  83     $caller->arguments( [@arguments] );
  84     $caller->setup_home;
  85 }
  86
  87 =head1 NAME
  88
  89 Catalyst - The Elegant MVC Web Application Framework
  90
  91 =head1 SYNOPSIS
  92
  93 See the L<Catalyst::Manual> distribution for comprehensive
  94 documentation and tutorials.
  95
  96     # Install Catalyst::Devel for helpers and other development tools
  97     # use the helper to create a new application
  98     catalyst.pl MyApp
  99
 100     # add models, views, controllers
 101     script/myapp_create.pl model MyDatabase DBIC::Schema create=dynamic dbi:SQLite:/path/to/db
 102     script/myapp_create.pl view MyTemplate TT
 103     script/myapp_create.pl controller Search
 104
 105     # built in testserver -- use -r to restart automatically on changes
 106     # --help to see all available options
 107     script/myapp_server.pl
 108
 109     # command line testing interface
 110     script/myapp_test.pl /yada
 111
 112     ### in lib/MyApp.pm
 113     use Catalyst qw/-Debug/; # include plugins here as well
 114
 115     ### In lib/MyApp/Controller/Root.pm (autocreated)
 116     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 117         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 118         $c->stash->{template} = 'foo.tt'; # set the template
 119         # lookup something from db -- stash vars are passed to TT
 120         $c->stash->{data} =
 121           $c->model('Database::Foo')->search( { country => $args[0] } );
 122         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 123             $c->forward( 'bar' ); # process another action
 124             # do something else after forward returns
 125         }
 126     }
 127
 128     # The foo.tt TT template can use the stash data from the database
 129     [% WHILE (item = data.next) %]
 130         [% item.foo %]
 131     [% END %]
 132
 133     # called for /bar/of/soap, /bar/of/soap/10, etc.
 134     sub bar : Path('/bar/of/soap') { ... }
 135
 136     # called for all actions, from the top-most controller downwards
 137     sub auto : Private {
 138         my ( $self, $c ) = @_;
 139         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 140             $c->res->redirect( '/login' ); # require login
 141             return 0; # abort request and go immediately to end()
 142         }
 143         return 1; # success; carry on to next action
 144     }
 145
 146     # called after all actions are finished
 147     sub end : Private {
 148         my ( $self, $c ) = @_;
 149         if ( scalar @{ $c->error } ) { ... } # handle errors
 150         return if $c->res->body; # already have a response
 151         $c->forward( 'MyApp::View::TT' ); # render template
 152     }
 153
 154     ### in MyApp/Controller/Foo.pm
 155     # called for /foo/bar
 156     sub bar : Local { ... }
 157
 158     # called for /blargle
 159     sub blargle : Global { ... }
 160
 161     # an index action matches /foo, but not /foo/1, etc.
 162     sub index : Private { ... }
 163
 164     ### in MyApp/Controller/Foo/Bar.pm
 165     # called for /foo/bar/baz
 166     sub baz : Local { ... }
 167
 168     # first Root auto is called, then Foo auto, then this
 169     sub auto : Private { ... }
 170
 171     # powerful regular expression paths are also possible
 172     sub details : Regex('^product/(\w+)/details$') {
 173         my ( $self, $c ) = @_;
 174         # extract the (\w+) from the URI
 175         my $product = $c->req->captures->[0];
 176     }
 177
 178 See L<Catalyst::Manual::Intro> for additional information.
 179
 180 =head1 DESCRIPTION
 181
 182 Catalyst is a modern framework for making web applications without the
 183 pain usually associated with this process. This document is a reference
 184 to the main Catalyst application. If you are a new user, we suggest you
 185 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 186
 187 See L<Catalyst::Manual> for more documentation.
 188
 189 Catalyst plugins can be loaded by naming them as arguments to the "use
 190 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 191 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 192 C<My::Module>.
 193
 194     use Catalyst qw/My::Module/;
 195
 196 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 197 fully qualify the name by using a unary plus:
 198
 199     use Catalyst qw/
 200         My::Module
 201         +Fully::Qualified::Plugin::Name
 202     /;
 203
 204 Special flags like C<-Debug> and C<-Engine> can also be specified as
 205 arguments when Catalyst is loaded:
 206
 207     use Catalyst qw/-Debug My::Module/;
 208
 209 The position of plugins and flags in the chain is important, because
 210 they are loaded in the order in which they appear.
 211
 212 The following flags are supported:
 213
 214 =head2 -Debug
 215
 216 Enables debug output. You can also force this setting from the system
 217 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 218 settings override the application, with <MYAPP>_DEBUG having the highest
 219 priority.
 220
 221 =head2 -Engine
 222
 223 Forces Catalyst to use a specific engine. Omit the
 224 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 225
 226     use Catalyst qw/-Engine=CGI/;
 227
 228 =head2 -Home
 229
 230 Forces Catalyst to use a specific home directory, e.g.:
 231
 232     use Catalyst qw[-Home=/usr/mst];
 233
 234 This can also be done in the shell environment by setting either the
 235 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 236 is replaced with the uppercased name of your application, any "::" in
 237 the name will be replaced with underscores, e.g. MyApp::Web should use
 238 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 239
 240 =head2 -Log
 241
 242 Specifies log level.
 243
 244 =head2 -Stats
 245
 246 Enables statistics collection and reporting. You can also force this setting
 247 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 248 environment settings override the application, with <MYAPP>_STATS having the
 249 highest priority.
 250
 251 e.g.
 252
 253    use Catalyst qw/-Stats=1/
 254
 255 =head1 METHODS
 256
 257 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 258
 259 =head2 $c->action
 260
 261 Returns a L<Catalyst::Action> object for the current action, which
 262 stringifies to the action name. See L<Catalyst::Action>.
 263
 264 =head2 $c->namespace
 265
 266 Returns the namespace of the current action, i.e., the URI prefix
 267 corresponding to the controller of the current action. For example:
 268
 269     # in Controller::Foo::Bar
 270     $c->namespace; # returns 'foo/bar';
 271
 272 =head2 $c->request
 273
 274 =head2 $c->req
 275
 276 Returns the current L<Catalyst::Request> object, giving access to
 277 information about the current client request (including parameters,
 278 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 279
 280 =head2 REQUEST FLOW HANDLING
 281
 282 =head2 $c->forward( $action [, \@arguments ] )
 283
 284 =head2 $c->forward( $class, $method, [, \@arguments ] )
 285
 286 Forwards processing to another action, by its private name. If you give a
 287 class name but no method, C<process()> is called. You may also optionally
 288 pass arguments in an arrayref. The action will receive the arguments in
 289 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 290 C<< $c->req->args >> will be restored to the previous values.
 291
 292 Any data C<return>ed from the action forwarded to, will be returned by the
 293 call to forward.
 294
 295     my $foodata = $c->forward('/foo');
 296     $c->forward('index');
 297     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 298     $c->forward('MyApp::View::TT');
 299
 300 Note that forward implies an C<<eval { }>> around the call (actually
 301 C<execute> does), thus de-fatalizing all 'dies' within the called
 302 action. If you want C<die> to propagate you need to do something like:
 303
 304     $c->forward('foo');
 305     die $c->error if $c->error;
 306
 307 Or make sure to always return true values from your actions and write
 308 your code like this:
 309
 310     $c->forward('foo') || return;
 311
 312 =cut
 313
 314 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 315
 316 =head2 $c->detach( $action [, \@arguments ] )
 317
 318 =head2 $c->detach( $class, $method, [, \@arguments ] )
 319
 320 =head2 $c->detach()
 321
 322 The same as C<forward>, but doesn't return to the previous action when
 323 processing is finished.
 324
 325 When called with no arguments it escapes the processing chain entirely.
 326
 327 =cut
 328
 329 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 330
 331 =head2 $c->go( $action [, \@arguments ] )
 332
 333 =head2 $c->go( $class, $method, [, \@arguments ] )
 334
 335 Almost the same as C<detach>, but does a full dispatch, instead of just
 336 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 337 C<auto> and the method you go to is called, just like a new request.
 338
 339 C<$c-E<gt>stash> is kept unchanged.
 340
 341 =cut
 342
 343 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 344
 345 =head2 $c->response
 346
 347 =head2 $c->res
 348
 349 Returns the current L<Catalyst::Response> object, see there for details.
 350
 351 =head2 $c->stash
 352
 353 Returns a hashref to the stash, which may be used to store data and pass
 354 it between components during a request. You can also set hash keys by
 355 passing arguments. The stash is automatically sent to the view. The
 356 stash is cleared at the end of a request; it cannot be used for
 357 persistent storage (for this you must use a session; see
 358 L<Catalyst::Plugin::Session> for a complete system integrated with
 359 Catalyst).
 360
 361     $c->stash->{foo} = $bar;
 362     $c->stash( { moose => 'majestic', qux => 0 } );
 363     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 364
 365     # stash is automatically passed to the view for use in a template
 366     $c->forward( 'MyApp::View::TT' );
 367
 368 =cut
 369
 370 sub stash {
 371     my $c = shift;
 372     if (@_) {
 373         my $stash = @_ > 1 ? {@_} : $_[0];
 374         croak('stash takes a hash or hashref') unless ref $stash;
 375         foreach my $key ( keys %$stash ) {
 376             $c->{stash}->{$key} = $stash->{$key};
 377         }
 378     }
 379     return $c->{stash};
 380 }
 381
 382 =head2 $c->error
 383
 384 =head2 $c->error($error, ...)
 385
 386 =head2 $c->error($arrayref)
 387
 388 Returns an arrayref containing error messages.  If Catalyst encounters an
 389 error while processing a request, it stores the error in $c->error.  This
 390 method should only be used to store fatal error messages.
 391
 392     my @error = @{ $c->error };
 393
 394 Add a new error.
 395
 396     $c->error('Something bad happened');
 397
 398 =cut
 399
 400 sub error {
 401     my $c = shift;
 402     if ( $_[0] ) {
 403         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 404         croak @$error unless ref $c;
 405         push @{ $c->{error} }, @$error;
 406     }
 407     elsif ( defined $_[0] ) { $c->{error} = undef }
 408     return $c->{error} || [];
 409 }
 410
 411
 412 =head2 $c->state
 413
 414 Contains the return value of the last executed action.
 415
 416 =head2 $c->clear_errors
 417
 418 Clear errors.  You probably don't want to clear the errors unless you are
 419 implementing a custom error screen.
 420
 421 This is equivalent to running
 422
 423     $c->error(0);
 424
 425 =cut
 426
 427 sub clear_errors {
 428     my $c = shift;
 429     $c->error(0);
 430 }
 431
 432 # search components given a name and some prefixes
 433 sub _comp_search_prefixes {
 434     my ( $c, $name, @prefixes ) = @_;
 435     my $appclass = ref $c || $c;
 436     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 437
 438     # map the original component name to the sub part that we will search against
 439     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 440         grep { /$filter/ } keys %{ $c->components };
 441
 442     # undef for a name will return all
 443     return keys %eligible if !defined $name;
 444
 445     my $query  = ref $name ? $name : qr/^$name$/i;
 446     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 447
 448     return map { $c->components->{ $_ } } @result if @result;
 449
 450     # if we were given a regexp to search against, we're done.
 451     return if ref $name;
 452
 453     # regexp fallback
 454     $query  = qr/$name/i;
 455     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 456
 457     # no results? try against full names
 458     if( !@result ) {
 459         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 460     }
 461
 462     # don't warn if we didn't find any results, it just might not exist
 463     if( @result ) {
 464         $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 465         $c->log->warn( 'Relying on the regexp fallback behavior for component resolution is unreliable and unsafe.' );
 466         $c->log->warn( 'If you really want to search, pass in a regexp as the argument.' );
 467     }
 468
 469     return @result;
 470 }
 471
 472 # Find possible names for a prefix
 473 sub _comp_names {
 474     my ( $c, @prefixes ) = @_;
 475     my $appclass = ref $c || $c;
 476
 477     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 478
 479     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 480     return @names;
 481 }
 482
 483 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 484 sub _filter_component {
 485     my ( $c, $comp, @args ) = @_;
 486
 487     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 488         return $comp->ACCEPT_CONTEXT( $c, @args );
 489     }
 490
 491     return $comp;
 492 }
 493
 494 =head2 COMPONENT ACCESSORS
 495
 496 =head2 $c->controller($name)
 497
 498 Gets a L<Catalyst::Controller> instance by name.
 499
 500     $c->controller('Foo')->do_stuff;
 501
 502 If the name is omitted, will return the controller for the dispatched
 503 action.
 504
 505 If you want to search for controllers, pass in a regexp as the argument.
 506
 507     # find all controllers that start with Foo
 508     my @foo_controllers = $c->controller(qr{^Foo});
 509
 510
 511 =cut
 512
 513 sub controller {
 514     my ( $c, $name, @args ) = @_;
 515
 516     if( $name ) {
 517         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 518         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 519         return $c->_filter_component( $result[ 0 ], @args );
 520     }
 521
 522     return $c->component( $c->action->class );
 523 }
 524
 525 =head2 $c->model($name)
 526
 527 Gets a L<Catalyst::Model> instance by name.
 528
 529     $c->model('Foo')->do_stuff;
 530
 531 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 532
 533 If the name is omitted, it will look for
 534  - a model object in $c->stash->{current_model_instance}, then
 535  - a model name in $c->stash->{current_model}, then
 536  - a config setting 'default_model', or
 537  - check if there is only one model, and return it if that's the case.
 538
 539 If you want to search for models, pass in a regexp as the argument.
 540
 541     # find all models that start with Foo
 542     my @foo_models = $c->model(qr{^Foo});
 543
 544 =cut
 545
 546 sub model {
 547     my ( $c, $name, @args ) = @_;
 548
 549     if( $name ) {
 550         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 551         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 552         return $c->_filter_component( $result[ 0 ], @args );
 553     }
 554
 555     if (ref $c) {
 556         return $c->stash->{current_model_instance}
 557           if $c->stash->{current_model_instance};
 558         return $c->model( $c->stash->{current_model} )
 559           if $c->stash->{current_model};
 560     }
 561     return $c->model( $c->config->{default_model} )
 562       if $c->config->{default_model};
 563
 564     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 565
 566     if( $rest ) {
 567         $c->log->warn( 'Calling $c->model() will return a random model unless you specify one of:' );
 568         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 569         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 570         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 571         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 572     }
 573
 574     return $c->_filter_component( $comp );
 575 }
 576
 577
 578 =head2 $c->view($name)
 579
 580 Gets a L<Catalyst::View> instance by name.
 581
 582     $c->view('Foo')->do_stuff;
 583
 584 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 585
 586 If the name is omitted, it will look for
 587  - a view object in $c->stash->{current_view_instance}, then
 588  - a view name in $c->stash->{current_view}, then
 589  - a config setting 'default_view', or
 590  - check if there is only one view, and return it if that's the case.
 591
 592 If you want to search for views, pass in a regexp as the argument.
 593
 594     # find all views that start with Foo
 595     my @foo_views = $c->view(qr{^Foo});
 596
 597 =cut
 598
 599 sub view {
 600     my ( $c, $name, @args ) = @_;
 601
 602     if( $name ) {
 603         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 604         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 605         return $c->_filter_component( $result[ 0 ], @args );
 606     }
 607
 608     if (ref $c) {
 609         return $c->stash->{current_view_instance}
 610           if $c->stash->{current_view_instance};
 611         return $c->view( $c->stash->{current_view} )
 612           if $c->stash->{current_view};
 613     }
 614     return $c->view( $c->config->{default_view} )
 615       if $c->config->{default_view};
 616
 617     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 618
 619     if( $rest ) {
 620         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 621         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 622         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 623         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 624         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 625     }
 626
 627     return $c->_filter_component( $comp );
 628 }
 629
 630 =head2 $c->controllers
 631
 632 Returns the available names which can be passed to $c->controller
 633
 634 =cut
 635
 636 sub controllers {
 637     my ( $c ) = @_;
 638     return $c->_comp_names(qw/Controller C/);
 639 }
 640
 641 =head2 $c->models
 642
 643 Returns the available names which can be passed to $c->model
 644
 645 =cut
 646
 647 sub models {
 648     my ( $c ) = @_;
 649     return $c->_comp_names(qw/Model M/);
 650 }
 651
 652
 653 =head2 $c->views
 654
 655 Returns the available names which can be passed to $c->view
 656
 657 =cut
 658
 659 sub views {
 660     my ( $c ) = @_;
 661     return $c->_comp_names(qw/View V/);
 662 }
 663
 664 =head2 $c->comp($name)
 665
 666 =head2 $c->component($name)
 667
 668 Gets a component object by name. This method is not recommended,
 669 unless you want to get a specific component by full
 670 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 671 should be used instead.
 672
 673 If C<$name> is a regexp, a list of components matched against the full
 674 component name will be returned.
 675
 676 =cut
 677
 678 sub component {
 679     my ( $c, $name, @args ) = @_;
 680
 681     if( $name ) {
 682         my $comps = $c->components;
 683
 684         if( !ref $name ) {
 685             # is it the exact name?
 686             return $c->_filter_component( $comps->{ $name }, @args )
 687                        if exists $comps->{ $name };
 688
 689             # perhaps we just omitted "MyApp"?
 690             my $composed = ( ref $c || $c ) . "::${name}";
 691             return $c->_filter_component( $comps->{ $composed }, @args )
 692                        if exists $comps->{ $composed };
 693
 694             # search all of the models, views and controllers
 695             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 696             return $c->_filter_component( $comp, @args ) if $comp;
 697         }
 698
 699         # This is here so $c->comp( '::M::' ) works
 700         my $query = ref $name ? $name : qr{$name}i;
 701
 702         my @result = grep { m{$query} } keys %{ $c->components };
 703         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 704
 705         if( $result[ 0 ] ) {
 706             $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 707             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 708             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 709             return $c->_filter_component( $result[ 0 ], @args );
 710         }
 711
 712         # I would expect to return an empty list here, but that breaks back-compat
 713     }
 714
 715     # fallback
 716     return sort keys %{ $c->components };
 717 }
 718
 719 =head2 CLASS DATA AND HELPER CLASSES
 720
 721 =head2 $c->config
 722
 723 Returns or takes a hashref containing the application's configuration.
 724
 725     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 726
 727 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 728 like myapp.yml in your applications home directory. See
 729 L<Catalyst::Plugin::ConfigLoader>.
 730
 731     ---
 732     db: dsn:SQLite:foo.db
 733
 734
 735 =cut
 736
 737 sub config {
 738     my $c = shift;
 739
 740     $c->log->warn("Setting config after setup has been run is not a good idea.")
 741       if ( @_ and $c->setup_finished );
 742
 743     $c->NEXT::config(@_);
 744 }
 745
 746 =head2 $c->log
 747
 748 Returns the logging object instance. Unless it is already set, Catalyst
 749 sets this up with a L<Catalyst::Log> object. To use your own log class,
 750 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 751 C<< __PACKAGE__->setup >>.
 752
 753  __PACKAGE__->log( MyLogger->new );
 754  __PACKAGE__->setup;
 755
 756 And later:
 757
 758     $c->log->info( 'Now logging with my own logger!' );
 759
 760 Your log class should implement the methods described in
 761 L<Catalyst::Log>.
 762
 763
 764 =head2 $c->debug
 765
 766 Overload to enable debug messages (same as -Debug option).
 767
 768 Note that this is a static method, not an accessor and should be overloaded
 769 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 770
 771 =cut
 772
 773 sub debug { 0 }
 774
 775 =head2 $c->dispatcher
 776
 777 Returns the dispatcher instance. Stringifies to class name. See
 778 L<Catalyst::Dispatcher>.
 779
 780 =head2 $c->engine
 781
 782 Returns the engine instance. Stringifies to the class name. See
 783 L<Catalyst::Engine>.
 784
 785
 786 =head2 UTILITY METHODS
 787
 788 =head2 $c->path_to(@path)
 789
 790 Merges C<@path> with C<< $c->config->{home} >> and returns a
 791 L<Path::Class::Dir> object.
 792
 793 For example:
 794
 795     $c->path_to( 'db', 'sqlite.db' );
 796
 797 =cut
 798
 799 sub path_to {
 800     my ( $c, @path ) = @_;
 801     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 802     if ( -d $path ) { return $path }
 803     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 804 }
 805
 806 =head2 $c->plugin( $name, $class, @args )
 807
 808 Helper method for plugins. It creates a classdata accessor/mutator and
 809 loads and instantiates the given class.
 810
 811     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 812
 813     $c->prototype->define_javascript_functions;
 814
 815 =cut
 816
 817 sub plugin {
 818     my ( $class, $name, $plugin, @args ) = @_;
 819     $class->_register_plugin( $plugin, 1 );
 820
 821     eval { $plugin->import };
 822     $class->mk_classdata($name);
 823     my $obj;
 824     eval { $obj = $plugin->new(@args) };
 825
 826     if ($@) {
 827         Catalyst::Exception->throw( message =>
 828               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 829     }
 830
 831     $class->$name($obj);
 832     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 833       if $class->debug;
 834 }
 835
 836 =head2 MyApp->setup
 837
 838 Initializes the dispatcher and engine, loads any plugins, and loads the
 839 model, view, and controller components. You may also specify an array
 840 of plugins to load here, if you choose to not load them in the C<use
 841 Catalyst> line.
 842
 843     MyApp->setup;
 844     MyApp->setup( qw/-Debug/ );
 845
 846 =cut
 847
 848 sub setup {
 849     my ( $class, @arguments ) = @_;
 850
 851     $class->log->warn("Running setup twice is not a good idea.")
 852       if ( $class->setup_finished );
 853
 854     unless ( $class->isa('Catalyst') ) {
 855
 856         Catalyst::Exception->throw(
 857             message => qq/'$class' does not inherit from Catalyst/ );
 858     }
 859
 860     if ( $class->arguments ) {
 861         @arguments = ( @arguments, @{ $class->arguments } );
 862     }
 863
 864     # Process options
 865     my $flags = {};
 866
 867     foreach (@arguments) {
 868
 869         if (/^-Debug$/) {
 870             $flags->{log} =
 871               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 872         }
 873         elsif (/^-(\w+)=?(.*)$/) {
 874             $flags->{ lc $1 } = $2;
 875         }
 876         else {
 877             push @{ $flags->{plugins} }, $_;
 878         }
 879     }
 880
 881     $class->setup_home( delete $flags->{home} );
 882
 883     $class->setup_log( delete $flags->{log} );
 884     $class->setup_plugins( delete $flags->{plugins} );
 885     $class->setup_dispatcher( delete $flags->{dispatcher} );
 886     $class->setup_engine( delete $flags->{engine} );
 887     $class->setup_stats( delete $flags->{stats} );
 888
 889     for my $flag ( sort keys %{$flags} ) {
 890
 891         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 892             &$code( $class, delete $flags->{$flag} );
 893         }
 894         else {
 895             $class->log->warn(qq/Unknown flag "$flag"/);
 896         }
 897     }
 898
 899     eval { require Catalyst::Devel; };
 900     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 901         $class->log->warn(<<"EOF");
 902 You are running an old script!
 903
 904   Please update by running (this will overwrite existing files):
 905     catalyst.pl -force -scripts $class
 906
 907   or (this will not overwrite existing files):
 908     catalyst.pl -scripts $class
 909
 910 EOF
 911     }
 912
 913     if ( $class->debug ) {
 914         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 915
 916         if (@plugins) {
 917             my $t = Text::SimpleTable->new(74);
 918             $t->row($_) for @plugins;
 919             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 920         }
 921
 922         my $dispatcher = $class->dispatcher;
 923         my $engine     = $class->engine;
 924         my $home       = $class->config->{home};
 925
 926         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 927         $class->log->debug(qq/Loaded engine "$engine"/);
 928
 929         $home
 930           ? ( -d $home )
 931           ? $class->log->debug(qq/Found home "$home"/)
 932           : $class->log->debug(qq/Home "$home" doesn't exist/)
 933           : $class->log->debug(q/Couldn't find home/);
 934     }
 935
 936     # Call plugins setup
 937     {
 938         no warnings qw/redefine/;
 939         local *setup = sub { };
 940         $class->setup;
 941     }
 942
 943     # Initialize our data structure
 944     $class->components( {} );
 945
 946     $class->setup_components;
 947
 948     if ( $class->debug ) {
 949         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 950         for my $comp ( sort keys %{ $class->components } ) {
 951             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 952             $t->row( $comp, $type );
 953         }
 954         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 955           if ( keys %{ $class->components } );
 956     }
 957
 958     # Add our self to components, since we are also a component
 959     $class->components->{$class} = $class;
 960
 961     $class->setup_actions;
 962
 963     if ( $class->debug ) {
 964         my $name = $class->config->{name} || 'Application';
 965         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 966     }
 967     $class->log->_flush() if $class->log->can('_flush');
 968
 969     $class->setup_finished(1);
 970 }
 971
 972 =head2 $c->uri_for( $path, @args?, \%query_values? )
 973
 974 Merges path with C<< $c->request->base >> for absolute URIs and with
 975 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
 976 object. If any args are passed, they are added at the end of the path.
 977 If the last argument to C<uri_for> is a hash reference, it is assumed to
 978 contain GET parameter key/value pairs, which will be appended to the URI
 979 in standard fashion.
 980
 981 Note that uri_for is destructive to the passed hashref.  Subsequent calls
 982 with the same hashref may have unintended results.
 983
 984 Instead of C<$path>, you can also optionally pass a C<$action> object
 985 which will be resolved to a path using
 986 C<< $c->dispatcher->uri_for_action >>; if the first element of
 987 C<@args> is an arrayref it is treated as a list of captures to be passed
 988 to C<uri_for_action>.
 989
 990 =cut
 991
 992 sub uri_for {
 993     my ( $c, $path, @args ) = @_;
 994
 995     if ( Scalar::Util::blessed($path) ) { # action object
 996         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 997                          ? shift(@args)
 998                          : [] );
 999         $path = $c->dispatcher->uri_for_action($path, $captures);
1000         return undef unless defined($path);
1001         $path = '/' if $path eq '';
1002     }
1003
1004     undef($path) if (defined $path && $path eq '');
1005
1006     my $params =
1007       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1008
1009     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1010     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1011
1012     unshift(@args, $path);
1013
1014     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1015         my $namespace = $c->namespace;
1016         if (defined $path) { # cheesy hack to handle path '../foo'
1017            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1018         }
1019         unshift(@args, $namespace || '');
1020     }
1021
1022     # join args with '/', or a blank string
1023     my $args = join('/', grep { defined($_) } @args);
1024     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1025     $args =~ s!^/!!;
1026     my $base = $c->req->base;
1027     my $class = ref($base);
1028     $base =~ s{(?<!/)$}{/};
1029
1030     my $query = '';
1031
1032     if (my @keys = keys %$params) {
1033       # somewhat lifted from URI::_query's query_form
1034       $query = '?'.join('&', map {
1035           my $val = $params->{$_};
1036           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1037           s/ /+/g;
1038           my $key = $_;
1039           $val = '' unless defined $val;
1040           (map {
1041               $_ = "$_";
1042               utf8::encode( $_ ) if utf8::is_utf8($_);
1043               # using the URI::Escape pattern here so utf8 chars survive
1044               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1045               s/ /+/g;
1046               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1047       } @keys);
1048     }
1049
1050     my $res = bless(\"${base}${args}${query}", $class);
1051     $res;
1052 }
1053
1054 =head2 $c->welcome_message
1055
1056 Returns the Catalyst welcome HTML page.
1057
1058 =cut
1059
1060 sub welcome_message {
1061     my $c      = shift;
1062     my $name   = $c->config->{name};
1063     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1064     my $prefix = Catalyst::Utils::appprefix( ref $c );
1065     $c->response->content_type('text/html; charset=utf-8');
1066     return <<"EOF";
1067 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1068     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1069 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1070     <head>
1071     <meta http-equiv="Content-Language" content="en" />
1072     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1073         <title>$name on Catalyst $VERSION</title>
1074         <style type="text/css">
1075             body {
1076                 color: #000;
1077                 background-color: #eee;
1078             }
1079             div#content {
1080                 width: 640px;
1081                 margin-left: auto;
1082                 margin-right: auto;
1083                 margin-top: 10px;
1084                 margin-bottom: 10px;
1085                 text-align: left;
1086                 background-color: #ccc;
1087                 border: 1px solid #aaa;
1088             }
1089             p, h1, h2 {
1090                 margin-left: 20px;
1091                 margin-right: 20px;
1092                 font-family: verdana, tahoma, sans-serif;
1093             }
1094             a {
1095                 font-family: verdana, tahoma, sans-serif;
1096             }
1097             :link, :visited {
1098                     text-decoration: none;
1099                     color: #b00;
1100                     border-bottom: 1px dotted #bbb;
1101             }
1102             :link:hover, :visited:hover {
1103                     color: #555;
1104             }
1105             div#topbar {
1106                 margin: 0px;
1107             }
1108             pre {
1109                 margin: 10px;
1110                 padding: 8px;
1111             }
1112             div#answers {
1113                 padding: 8px;
1114                 margin: 10px;
1115                 background-color: #fff;
1116                 border: 1px solid #aaa;
1117             }
1118             h1 {
1119                 font-size: 0.9em;
1120                 font-weight: normal;
1121                 text-align: center;
1122             }
1123             h2 {
1124                 font-size: 1.0em;
1125             }
1126             p {
1127                 font-size: 0.9em;
1128             }
1129             p img {
1130                 float: right;
1131                 margin-left: 10px;
1132             }
1133             span#appname {
1134                 font-weight: bold;
1135                 font-size: 1.6em;
1136             }
1137         </style>
1138     </head>
1139     <body>
1140         <div id="content">
1141             <div id="topbar">
1142                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1143                     $VERSION</h1>
1144              </div>
1145              <div id="answers">
1146                  <p>
1147                  <img src="$logo" alt="Catalyst Logo" />
1148                  </p>
1149                  <p>Welcome to the  world of Catalyst.
1150                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1151                     framework will make web development something you had
1152                     never expected it to be: Fun, rewarding, and quick.</p>
1153                  <h2>What to do now?</h2>
1154                  <p>That really depends  on what <b>you</b> want to do.
1155                     We do, however, provide you with a few starting points.</p>
1156                  <p>If you want to jump right into web development with Catalyst
1157                     you might want to start with a tutorial.</p>
1158 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1159 </pre>
1160 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1161 <pre>
1162 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1163 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1164 </code></pre>
1165                  <h2>What to do next?</h2>
1166                  <p>Next it's time to write an actual application. Use the
1167                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1168                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1169                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1170                     they can save you a lot of work.</p>
1171                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1172                     <p>Also, be sure to check out the vast and growing
1173                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1174                     you are likely to find what you need there.
1175                     </p>
1176
1177                  <h2>Need help?</h2>
1178                  <p>Catalyst has a very active community. Here are the main places to
1179                     get in touch with us.</p>
1180                  <ul>
1181                      <li>
1182                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1183                      </li>
1184                      <li>
1185                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1186                      </li>
1187                      <li>
1188                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1189                      </li>
1190                  </ul>
1191                  <h2>In conclusion</h2>
1192                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1193                     as we enjoyed making it. Please contact us if you have ideas
1194                     for improvement or other feedback.</p>
1195              </div>
1196          </div>
1197     </body>
1198 </html>
1199 EOF
1200 }
1201
1202 =head1 INTERNAL METHODS
1203
1204 These methods are not meant to be used by end users.
1205
1206 =head2 $c->components
1207
1208 Returns a hash of components.
1209
1210 =head2 $c->context_class
1211
1212 Returns or sets the context class.
1213
1214 =head2 $c->counter
1215
1216 Returns a hashref containing coderefs and execution counts (needed for
1217 deep recursion detection).
1218
1219 =head2 $c->depth
1220
1221 Returns the number of actions on the current internal execution stack.
1222
1223 =head2 $c->dispatch
1224
1225 Dispatches a request to actions.
1226
1227 =cut
1228
1229 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1230
1231 =head2 $c->dispatcher_class
1232
1233 Returns or sets the dispatcher class.
1234
1235 =head2 $c->dump_these
1236
1237 Returns a list of 2-element array references (name, structure) pairs
1238 that will be dumped on the error page in debug mode.
1239
1240 =cut
1241
1242 sub dump_these {
1243     my $c = shift;
1244     [ Request => $c->req ],
1245     [ Response => $c->res ],
1246     [ Stash => $c->stash ],
1247     [ Config => $c->config ];
1248 }
1249
1250 =head2 $c->engine_class
1251
1252 Returns or sets the engine class.
1253
1254 =head2 $c->execute( $class, $coderef )
1255
1256 Execute a coderef in given class and catch exceptions. Errors are available
1257 via $c->error.
1258
1259 =cut
1260
1261 sub execute {
1262     my ( $c, $class, $code ) = @_;
1263     $class = $c->component($class) || $class;
1264     $c->state(0);
1265
1266     if ( $c->depth >= $RECURSION ) {
1267         my $action = "$code";
1268         $action = "/$action" unless $action =~ /->/;
1269         my $error = qq/Deep recursion detected calling "$action"/;
1270         $c->log->error($error);
1271         $c->error($error);
1272         $c->state(0);
1273         return $c->state;
1274     }
1275
1276     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1277
1278     push( @{ $c->stack }, $code );
1279
1280     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1281
1282     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1283
1284     my $last = pop( @{ $c->stack } );
1285
1286     if ( my $error = $@ ) {
1287         if ( !ref($error) and $error eq $DETACH ) {
1288             die $DETACH if($c->depth > 1);
1289         }
1290         elsif ( !ref($error) and $error eq $GO ) {
1291             die $GO if($c->depth > 0);
1292         }
1293         else {
1294             unless ( ref $error ) {
1295                 no warnings 'uninitialized';
1296                 chomp $error;
1297                 my $class = $last->class;
1298                 my $name  = $last->name;
1299                 $error = qq/Caught exception in $class->$name "$error"/;
1300             }
1301             $c->error($error);
1302             $c->state(0);
1303         }
1304     }
1305     return $c->state;
1306 }
1307
1308 sub _stats_start_execute {
1309     my ( $c, $code ) = @_;
1310
1311     return if ( ( $code->name =~ /^_.*/ )
1312         && ( !$c->config->{show_internal_actions} ) );
1313
1314     $c->counter->{"$code"}++;
1315
1316     my $action = "$code";
1317     $action = "/$action" unless $action =~ /->/;
1318
1319     # determine if the call was the result of a forward
1320     # this is done by walking up the call stack and looking for a calling
1321     # sub of Catalyst::forward before the eval
1322     my $callsub = q{};
1323     for my $index ( 2 .. 11 ) {
1324         last
1325         if ( ( caller($index) )[0] eq 'Catalyst'
1326             && ( caller($index) )[3] eq '(eval)' );
1327
1328         if ( ( caller($index) )[3] =~ /forward$/ ) {
1329             $callsub = ( caller($index) )[3];
1330             $action  = "-> $action";
1331             last;
1332         }
1333     }
1334
1335     my $uid = "$code" . $c->counter->{"$code"};
1336
1337     # is this a root-level call or a forwarded call?
1338     if ( $callsub =~ /forward$/ ) {
1339
1340         # forward, locate the caller
1341         if ( my $parent = $c->stack->[-1] ) {
1342             $c->stats->profile(
1343                 begin  => $action,
1344                 parent => "$parent" . $c->counter->{"$parent"},
1345                 uid    => $uid,
1346             );
1347         }
1348         else {
1349
1350             # forward with no caller may come from a plugin
1351             $c->stats->profile(
1352                 begin => $action,
1353                 uid   => $uid,
1354             );
1355         }
1356     }
1357     else {
1358
1359         # root-level call
1360         $c->stats->profile(
1361             begin => $action,
1362             uid   => $uid,
1363         );
1364     }
1365     return $action;
1366
1367 }
1368
1369 sub _stats_finish_execute {
1370     my ( $c, $info ) = @_;
1371     $c->stats->profile( end => $info );
1372 }
1373
1374 =head2 $c->_localize_fields( sub { }, \%keys );
1375
1376 =cut
1377
1378 sub _localize_fields {
1379     my ( $c, $localized, $code ) = ( @_ );
1380
1381     my $request = delete $localized->{request} || {};
1382     my $response = delete $localized->{response} || {};
1383
1384     local @{ $c }{ keys %$localized } = values %$localized;
1385     local @{ $c->request }{ keys %$request } = values %$request;
1386     local @{ $c->response }{ keys %$response } = values %$response;
1387
1388     $code->();
1389 }
1390
1391 =head2 $c->finalize
1392
1393 Finalizes the request.
1394
1395 =cut
1396
1397 sub finalize {
1398     my $c = shift;
1399
1400     for my $error ( @{ $c->error } ) {
1401         $c->log->error($error);
1402     }
1403
1404     # Allow engine to handle finalize flow (for POE)
1405     if ( $c->engine->can('finalize') ) {
1406         $c->engine->finalize($c);
1407     }
1408     else {
1409
1410         $c->finalize_uploads;
1411
1412         # Error
1413         if ( $#{ $c->error } >= 0 ) {
1414             $c->finalize_error;
1415         }
1416
1417         $c->finalize_headers;
1418
1419         # HEAD request
1420         if ( $c->request->method eq 'HEAD' ) {
1421             $c->response->body('');
1422         }
1423
1424         $c->finalize_body;
1425     }
1426
1427     if ($c->use_stats) {
1428         my $elapsed = sprintf '%f', $c->stats->elapsed;
1429         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1430         $c->log->info(
1431             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1432     }
1433
1434     return $c->response->status;
1435 }
1436
1437 =head2 $c->finalize_body
1438
1439 Finalizes body.
1440
1441 =cut
1442
1443 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1444
1445 =head2 $c->finalize_cookies
1446
1447 Finalizes cookies.
1448
1449 =cut
1450
1451 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1452
1453 =head2 $c->finalize_error
1454
1455 Finalizes error.
1456
1457 =cut
1458
1459 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1460
1461 =head2 $c->finalize_headers
1462
1463 Finalizes headers.
1464
1465 =cut
1466
1467 sub finalize_headers {
1468     my $c = shift;
1469
1470     # Check if we already finalized headers
1471     return if $c->response->{_finalized_headers};
1472
1473     # Handle redirects
1474     if ( my $location = $c->response->redirect ) {
1475         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1476         $c->response->header( Location => $location );
1477
1478         if ( !$c->response->body ) {
1479             # Add a default body if none is already present
1480             $c->response->body(
1481                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1482             );
1483         }
1484     }
1485
1486     # Content-Length
1487     if ( $c->response->body && !$c->response->content_length ) {
1488
1489         # get the length from a filehandle
1490         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1491         {
1492             my $stat = stat $c->response->body;
1493             if ( $stat && $stat->size > 0 ) {
1494                 $c->response->content_length( $stat->size );
1495             }
1496             else {
1497                 $c->log->warn('Serving filehandle without a content-length');
1498             }
1499         }
1500         else {
1501             # everything should be bytes at this point, but just in case
1502             $c->response->content_length( bytes::length( $c->response->body ) );
1503         }
1504     }
1505
1506     # Errors
1507     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1508         $c->response->headers->remove_header("Content-Length");
1509         $c->response->body('');
1510     }
1511
1512     $c->finalize_cookies;
1513
1514     $c->engine->finalize_headers( $c, @_ );
1515
1516     # Done
1517     $c->response->{_finalized_headers} = 1;
1518 }
1519
1520 =head2 $c->finalize_output
1521
1522 An alias for finalize_body.
1523
1524 =head2 $c->finalize_read
1525
1526 Finalizes the input after reading is complete.
1527
1528 =cut
1529
1530 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1531
1532 =head2 $c->finalize_uploads
1533
1534 Finalizes uploads. Cleans up any temporary files.
1535
1536 =cut
1537
1538 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1539
1540 =head2 $c->get_action( $action, $namespace )
1541
1542 Gets an action in a given namespace.
1543
1544 =cut
1545
1546 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1547
1548 =head2 $c->get_actions( $action, $namespace )
1549
1550 Gets all actions of a given name in a namespace and all parent
1551 namespaces.
1552
1553 =cut
1554
1555 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1556
1557 =head2 $c->handle_request( $class, @arguments )
1558
1559 Called to handle each HTTP request.
1560
1561 =cut
1562
1563 sub handle_request {
1564     my ( $class, @arguments ) = @_;
1565
1566     # Always expect worst case!
1567     my $status = -1;
1568     eval {
1569         if ($class->debug) {
1570             my $secs = time - $START || 1;
1571             my $av = sprintf '%.3f', $COUNT / $secs;
1572             my $time = localtime time;
1573             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1574         }
1575
1576         my $c = $class->prepare(@arguments);
1577         $c->dispatch;
1578         $status = $c->finalize;
1579     };
1580
1581     if ( my $error = $@ ) {
1582         chomp $error;
1583         $class->log->error(qq/Caught exception in engine "$error"/);
1584     }
1585
1586     $COUNT++;
1587     $class->log->_flush() if $class->log->can('_flush');
1588     return $status;
1589 }
1590
1591 =head2 $c->prepare( @arguments )
1592
1593 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1594 etc.).
1595
1596 =cut
1597
1598 sub prepare {
1599     my ( $class, @arguments ) = @_;
1600
1601     $class->context_class( ref $class || $class ) unless $class->context_class;
1602     my $c = $class->context_class->new(
1603         {
1604             counter => {},
1605             stack   => [],
1606             request => $class->request_class->new(
1607                 {
1608                     arguments        => [],
1609                     body_parameters  => {},
1610                     cookies          => {},
1611                     headers          => HTTP::Headers->new,
1612                     parameters       => {},
1613                     query_parameters => {},
1614                     secure           => 0,
1615                     captures         => [],
1616                     uploads          => {}
1617                 }
1618             ),
1619             response => $class->response_class->new(
1620                 {
1621                     body    => '',
1622                     cookies => {},
1623                     headers => HTTP::Headers->new(),
1624                     status  => 200
1625                 }
1626             ),
1627             stash => {},
1628             state => 0
1629         }
1630     );
1631
1632     $c->stats($class->stats_class->new)->enable($c->use_stats);
1633     if ( $c->debug ) {
1634         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1635     }
1636
1637     # For on-demand data
1638     $c->request->{_context}  = $c;
1639     $c->response->{_context} = $c;
1640     weaken( $c->request->{_context} );
1641     weaken( $c->response->{_context} );
1642
1643     # Allow engine to direct the prepare flow (for POE)
1644     if ( $c->engine->can('prepare') ) {
1645         $c->engine->prepare( $c, @arguments );
1646     }
1647     else {
1648         $c->prepare_request(@arguments);
1649         $c->prepare_connection;
1650         $c->prepare_query_parameters;
1651         $c->prepare_headers;
1652         $c->prepare_cookies;
1653         $c->prepare_path;
1654
1655         # Prepare the body for reading, either by prepare_body
1656         # or the user, if they are using $c->read
1657         $c->prepare_read;
1658
1659         # Parse the body unless the user wants it on-demand
1660         unless ( $c->config->{parse_on_demand} ) {
1661             $c->prepare_body;
1662         }
1663     }
1664
1665     my $method  = $c->req->method  || '';
1666     my $path    = $c->req->path;
1667     $path       = '/' unless length $path;
1668     my $address = $c->req->address || '';
1669
1670     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1671       if $c->debug;
1672
1673     $c->prepare_action;
1674
1675     return $c;
1676 }
1677
1678 =head2 $c->prepare_action
1679
1680 Prepares action. See L<Catalyst::Dispatcher>.
1681
1682 =cut
1683
1684 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1685
1686 =head2 $c->prepare_body
1687
1688 Prepares message body.
1689
1690 =cut
1691
1692 sub prepare_body {
1693     my $c = shift;
1694
1695     # Do we run for the first time?
1696     return if defined $c->request->{_body};
1697
1698     # Initialize on-demand data
1699     $c->engine->prepare_body( $c, @_ );
1700     $c->prepare_parameters;
1701     $c->prepare_uploads;
1702
1703     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1704         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1705         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1706             my $param = $c->req->body_parameters->{$key};
1707             my $value = defined($param) ? $param : '';
1708             $t->row( $key,
1709                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1710         }
1711         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1712     }
1713 }
1714
1715 =head2 $c->prepare_body_chunk( $chunk )
1716
1717 Prepares a chunk of data before sending it to L<HTTP::Body>.
1718
1719 See L<Catalyst::Engine>.
1720
1721 =cut
1722
1723 sub prepare_body_chunk {
1724     my $c = shift;
1725     $c->engine->prepare_body_chunk( $c, @_ );
1726 }
1727
1728 =head2 $c->prepare_body_parameters
1729
1730 Prepares body parameters.
1731
1732 =cut
1733
1734 sub prepare_body_parameters {
1735     my $c = shift;
1736     $c->engine->prepare_body_parameters( $c, @_ );
1737 }
1738
1739 =head2 $c->prepare_connection
1740
1741 Prepares connection.
1742
1743 =cut
1744
1745 sub prepare_connection {
1746     my $c = shift;
1747     $c->engine->prepare_connection( $c, @_ );
1748 }
1749
1750 =head2 $c->prepare_cookies
1751
1752 Prepares cookies.
1753
1754 =cut
1755
1756 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1757
1758 =head2 $c->prepare_headers
1759
1760 Prepares headers.
1761
1762 =cut
1763
1764 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1765
1766 =head2 $c->prepare_parameters
1767
1768 Prepares parameters.
1769
1770 =cut
1771
1772 sub prepare_parameters {
1773     my $c = shift;
1774     $c->prepare_body_parameters;
1775     $c->engine->prepare_parameters( $c, @_ );
1776 }
1777
1778 =head2 $c->prepare_path
1779
1780 Prepares path and base.
1781
1782 =cut
1783
1784 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1785
1786 =head2 $c->prepare_query_parameters
1787
1788 Prepares query parameters.
1789
1790 =cut
1791
1792 sub prepare_query_parameters {
1793     my $c = shift;
1794
1795     $c->engine->prepare_query_parameters( $c, @_ );
1796
1797     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1798         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1799         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1800             my $param = $c->req->query_parameters->{$key};
1801             my $value = defined($param) ? $param : '';
1802             $t->row( $key,
1803                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1804         }
1805         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1806     }
1807 }
1808
1809 =head2 $c->prepare_read
1810
1811 Prepares the input for reading.
1812
1813 =cut
1814
1815 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1816
1817 =head2 $c->prepare_request
1818
1819 Prepares the engine request.
1820
1821 =cut
1822
1823 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1824
1825 =head2 $c->prepare_uploads
1826
1827 Prepares uploads.
1828
1829 =cut
1830
1831 sub prepare_uploads {
1832     my $c = shift;
1833
1834     $c->engine->prepare_uploads( $c, @_ );
1835
1836     if ( $c->debug && keys %{ $c->request->uploads } ) {
1837         my $t = Text::SimpleTable->new(
1838             [ 12, 'Parameter' ],
1839             [ 26, 'Filename' ],
1840             [ 18, 'Type' ],
1841             [ 9,  'Size' ]
1842         );
1843         for my $key ( sort keys %{ $c->request->uploads } ) {
1844             my $upload = $c->request->uploads->{$key};
1845             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1846                 $t->row( $key, $u->filename, $u->type, $u->size );
1847             }
1848         }
1849         $c->log->debug( "File Uploads are:\n" . $t->draw );
1850     }
1851 }
1852
1853 =head2 $c->prepare_write
1854
1855 Prepares the output for writing.
1856
1857 =cut
1858
1859 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1860
1861 =head2 $c->request_class
1862
1863 Returns or sets the request class.
1864
1865 =head2 $c->response_class
1866
1867 Returns or sets the response class.
1868
1869 =head2 $c->read( [$maxlength] )
1870
1871 Reads a chunk of data from the request body. This method is designed to
1872 be used in a while loop, reading C<$maxlength> bytes on every call.
1873 C<$maxlength> defaults to the size of the request if not specified.
1874
1875 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1876 directly.
1877
1878 Warning: If you use read(), Catalyst will not process the body,
1879 so you will not be able to access POST parameters or file uploads via
1880 $c->request.  You must handle all body parsing yourself.
1881
1882 =cut
1883
1884 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1885
1886 =head2 $c->run
1887
1888 Starts the engine.
1889
1890 =cut
1891
1892 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1893
1894 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1895
1896 Sets an action in a given namespace.
1897
1898 =cut
1899
1900 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1901
1902 =head2 $c->setup_actions($component)
1903
1904 Sets up actions for a component.
1905
1906 =cut
1907
1908 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1909
1910 =head2 $c->setup_components
1911
1912 Sets up components. Specify a C<setup_components> config option to pass
1913 additional options directly to L<Module::Pluggable>. To add additional
1914 search paths, specify a key named C<search_extra> as an array
1915 reference. Items in the array beginning with C<::> will have the
1916 application class name prepended to them.
1917
1918 All components found will also have any
1919 L<Devel::InnerPackage|inner packages> loaded and set up as components.
1920 Note, that modules which are B<not> an I<inner package> of the main
1921 file namespace loaded will not be instantiated as components.
1922
1923 =cut
1924
1925 sub setup_components {
1926     my $class = shift;
1927
1928     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1929     my $config  = $class->config->{ setup_components };
1930     my $extra   = delete $config->{ search_extra } || [];
1931
1932     push @paths, @$extra;
1933
1934     my $locator = Module::Pluggable::Object->new(
1935         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1936         %$config
1937     );
1938
1939     my @comps = sort { length $a <=> length $b } $locator->plugins;
1940     my %comps = map { $_ => 1 } @comps;
1941
1942     for my $component ( @comps ) {
1943
1944         # We pass ignore_loaded here so that overlay files for (e.g.)
1945         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
1946         # we know M::P::O found a file on disk so this is safe
1947
1948         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1949
1950         my $module  = $class->setup_component( $component );
1951         my %modules = (
1952             $component => $module,
1953             map {
1954                 $_ => $class->setup_component( $_ )
1955             } grep {
1956               not exists $comps{$_}
1957             } Devel::InnerPackage::list_packages( $component )
1958         );
1959
1960         for my $key ( keys %modules ) {
1961             $class->components->{ $key } = $modules{ $key };
1962         }
1963     }
1964 }
1965
1966 =head2 $c->setup_component
1967
1968 =cut
1969
1970 sub setup_component {
1971     my( $class, $component ) = @_;
1972
1973     unless ( $component->can( 'COMPONENT' ) ) {
1974         return $component;
1975     }
1976
1977     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1978     my $config = $class->config->{ $suffix } || {};
1979
1980     my $instance = eval { $component->COMPONENT( $class, $config ); };
1981
1982     if ( my $error = $@ ) {
1983         chomp $error;
1984         Catalyst::Exception->throw(
1985             message => qq/Couldn't instantiate component "$component", "$error"/
1986         );
1987     }
1988
1989     Catalyst::Exception->throw(
1990         message =>
1991         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1992     ) unless eval { $instance->can( 'can' ) };
1993
1994     return $instance;
1995 }
1996
1997 =head2 $c->setup_dispatcher
1998
1999 Sets up dispatcher.
2000
2001 =cut
2002
2003 sub setup_dispatcher {
2004     my ( $class, $dispatcher ) = @_;
2005
2006     if ($dispatcher) {
2007         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2008     }
2009
2010     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2011         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2012     }
2013
2014     unless ($dispatcher) {
2015         $dispatcher = $class->dispatcher_class;
2016     }
2017
2018     unless (Class::Inspector->loaded($dispatcher)) {
2019         require Class::Inspector->filename($dispatcher);
2020     }
2021
2022     # dispatcher instance
2023     $class->dispatcher( $dispatcher->new );
2024 }
2025
2026 =head2 $c->setup_engine
2027
2028 Sets up engine.
2029
2030 =cut
2031
2032 sub setup_engine {
2033     my ( $class, $engine ) = @_;
2034
2035     if ($engine) {
2036         $engine = 'Catalyst::Engine::' . $engine;
2037     }
2038
2039     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2040         $engine = 'Catalyst::Engine::' . $env;
2041     }
2042
2043     if ( $ENV{MOD_PERL} ) {
2044
2045         # create the apache method
2046         {
2047             no strict 'refs';
2048             *{"$class\::apache"} = sub { shift->engine->apache };
2049         }
2050
2051         my ( $software, $version ) =
2052           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2053
2054         $version =~ s/_//g;
2055         $version =~ s/(\.[^.]+)\./$1/g;
2056
2057         if ( $software eq 'mod_perl' ) {
2058
2059             if ( !$engine ) {
2060
2061                 if ( $version >= 1.99922 ) {
2062                     $engine = 'Catalyst::Engine::Apache2::MP20';
2063                 }
2064
2065                 elsif ( $version >= 1.9901 ) {
2066                     $engine = 'Catalyst::Engine::Apache2::MP19';
2067                 }
2068
2069                 elsif ( $version >= 1.24 ) {
2070                     $engine = 'Catalyst::Engine::Apache::MP13';
2071                 }
2072
2073                 else {
2074                     Catalyst::Exception->throw( message =>
2075                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2076                 }
2077
2078             }
2079
2080             # install the correct mod_perl handler
2081             if ( $version >= 1.9901 ) {
2082                 *handler = sub  : method {
2083                     shift->handle_request(@_);
2084                 };
2085             }
2086             else {
2087                 *handler = sub ($$) { shift->handle_request(@_) };
2088             }
2089
2090         }
2091
2092         elsif ( $software eq 'Zeus-Perl' ) {
2093             $engine = 'Catalyst::Engine::Zeus';
2094         }
2095
2096         else {
2097             Catalyst::Exception->throw(
2098                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2099         }
2100     }
2101
2102     unless ($engine) {
2103         $engine = $class->engine_class;
2104     }
2105
2106     unless (Class::Inspector->loaded($engine)) {
2107         require Class::Inspector->filename($engine);
2108     }
2109
2110     # check for old engines that are no longer compatible
2111     my $old_engine;
2112     if ( $engine->isa('Catalyst::Engine::Apache')
2113         && !Catalyst::Engine::Apache->VERSION )
2114     {
2115         $old_engine = 1;
2116     }
2117
2118     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2119         && Catalyst::Engine::Server->VERSION le '0.02' )
2120     {
2121         $old_engine = 1;
2122     }
2123
2124     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2125         && $engine->VERSION eq '0.01' )
2126     {
2127         $old_engine = 1;
2128     }
2129
2130     elsif ($engine->isa('Catalyst::Engine::Zeus')
2131         && $engine->VERSION eq '0.01' )
2132     {
2133         $old_engine = 1;
2134     }
2135
2136     if ($old_engine) {
2137         Catalyst::Exception->throw( message =>
2138               qq/Engine "$engine" is not supported by this version of Catalyst/
2139         );
2140     }
2141
2142     # engine instance
2143     $class->engine( $engine->new );
2144 }
2145
2146 =head2 $c->setup_home
2147
2148 Sets up the home directory.
2149
2150 =cut
2151
2152 sub setup_home {
2153     my ( $class, $home ) = @_;
2154
2155     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2156         $home = $env;
2157     }
2158
2159     unless ($home) {
2160         $home = Catalyst::Utils::home($class);
2161     }
2162
2163     if ($home) {
2164         $class->config->{home} ||= $home;
2165         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2166     }
2167 }
2168
2169 =head2 $c->setup_log
2170
2171 Sets up log.
2172
2173 =cut
2174
2175 sub setup_log {
2176     my ( $class, $debug ) = @_;
2177
2178     unless ( $class->log ) {
2179         $class->log( Catalyst::Log->new );
2180     }
2181
2182     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2183     if ( defined($env_debug) ? $env_debug : $debug ) {
2184         no strict 'refs';
2185         *{"$class\::debug"} = sub { 1 };
2186         $class->log->debug('Debug messages enabled');
2187     }
2188 }
2189
2190 =head2 $c->setup_plugins
2191
2192 Sets up plugins.
2193
2194 =cut
2195
2196 =head2 $c->setup_stats
2197
2198 Sets up timing statistics class.
2199
2200 =cut
2201
2202 sub setup_stats {
2203     my ( $class, $stats ) = @_;
2204
2205     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2206
2207     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2208     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2209         no strict 'refs';
2210         *{"$class\::use_stats"} = sub { 1 };
2211         $class->log->debug('Statistics enabled');
2212     }
2213 }
2214
2215
2216 =head2 $c->registered_plugins
2217
2218 Returns a sorted list of the plugins which have either been stated in the
2219 import list or which have been added via C<< MyApp->plugin(@args); >>.
2220
2221 If passed a given plugin name, it will report a boolean value indicating
2222 whether or not that plugin is loaded.  A fully qualified name is required if
2223 the plugin name does not begin with C<Catalyst::Plugin::>.
2224
2225  if ($c->registered_plugins('Some::Plugin')) {
2226      ...
2227  }
2228
2229 =cut
2230
2231 {
2232
2233     sub registered_plugins {
2234         my $proto = shift;
2235         return sort keys %{ $proto->_plugins } unless @_;
2236         my $plugin = shift;
2237         return 1 if exists $proto->_plugins->{$plugin};
2238         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2239     }
2240
2241     sub _register_plugin {
2242         my ( $proto, $plugin, $instant ) = @_;
2243         my $class = ref $proto || $proto;
2244
2245         # no ignore_loaded here, the plugin may already have been
2246         # defined in memory and we don't want to error on "no file" if so
2247
2248         Catalyst::Utils::ensure_class_loaded( $plugin );
2249
2250         $proto->_plugins->{$plugin} = 1;
2251         unless ($instant) {
2252             no strict 'refs';
2253             unshift @{"$class\::ISA"}, $plugin;
2254         }
2255         return $class;
2256     }
2257
2258     sub setup_plugins {
2259         my ( $class, $plugins ) = @_;
2260
2261         $class->_plugins( {} ) unless $class->_plugins;
2262         $plugins ||= [];
2263         for my $plugin ( reverse @$plugins ) {
2264
2265             unless ( $plugin =~ s/\A\+// ) {
2266                 $plugin = "Catalyst::Plugin::$plugin";
2267             }
2268
2269             $class->_register_plugin($plugin);
2270         }
2271     }
2272 }
2273
2274 =head2 $c->stack
2275
2276 Returns an arrayref of the internal execution stack (actions that are
2277 currently executing).
2278
2279 =head2 $c->stats_class
2280
2281 Returns or sets the stats (timing statistics) class.
2282
2283 =head2 $c->use_stats
2284
2285 Returns 1 when stats collection is enabled.  Stats collection is enabled
2286 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2287 environment variable is set.
2288
2289 Note that this is a static method, not an accessor and should be overloaded
2290 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2291
2292 =cut
2293
2294 sub use_stats { 0 }
2295
2296
2297 =head2 $c->write( $data )
2298
2299 Writes $data to the output stream. When using this method directly, you
2300 will need to manually set the C<Content-Length> header to the length of
2301 your output data, if known.
2302
2303 =cut
2304
2305 sub write {
2306     my $c = shift;
2307
2308     # Finalize headers if someone manually writes output
2309     $c->finalize_headers;
2310
2311     return $c->engine->write( $c, @_ );
2312 }
2313
2314 =head2 version
2315
2316 Returns the Catalyst version number. Mostly useful for "powered by"
2317 messages in template systems.
2318
2319 =cut
2320
2321 sub version { return $Catalyst::VERSION }
2322
2323 =head1 INTERNAL ACTIONS
2324
2325 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2326 C<_ACTION>, and C<_END>. These are by default not shown in the private
2327 action table, but you can make them visible with a config parameter.
2328
2329     MyApp->config->{show_internal_actions} = 1;
2330
2331 =head1 CASE SENSITIVITY
2332
2333 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2334 mapped to C</foo/bar>. You can activate case sensitivity with a config
2335 parameter.
2336
2337     MyApp->config->{case_sensitive} = 1;
2338
2339 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2340
2341 =head1 ON-DEMAND PARSER
2342
2343 The request body is usually parsed at the beginning of a request,
2344 but if you want to handle input yourself, you can enable on-demand
2345 parsing with a config parameter.
2346
2347     MyApp->config->{parse_on_demand} = 1;
2348
2349 =head1 PROXY SUPPORT
2350
2351 Many production servers operate using the common double-server approach,
2352 with a lightweight frontend web server passing requests to a larger
2353 backend server. An application running on the backend server must deal
2354 with two problems: the remote user always appears to be C<127.0.0.1> and
2355 the server's hostname will appear to be C<localhost> regardless of the
2356 virtual host that the user connected through.
2357
2358 Catalyst will automatically detect this situation when you are running
2359 the frontend and backend servers on the same machine. The following
2360 changes are made to the request.
2361
2362     $c->req->address is set to the user's real IP address, as read from
2363     the HTTP X-Forwarded-For header.
2364
2365     The host value for $c->req->base and $c->req->uri is set to the real
2366     host, as read from the HTTP X-Forwarded-Host header.
2367
2368 Obviously, your web server must support these headers for this to work.
2369
2370 In a more complex server farm environment where you may have your
2371 frontend proxy server(s) on different machines, you will need to set a
2372 configuration option to tell Catalyst to read the proxied data from the
2373 headers.
2374
2375     MyApp->config->{using_frontend_proxy} = 1;
2376
2377 If you do not wish to use the proxy support at all, you may set:
2378
2379     MyApp->config->{ignore_frontend_proxy} = 1;
2380
2381 =head1 THREAD SAFETY
2382
2383 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2384 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2385 believe the Catalyst core to be thread-safe.
2386
2387 If you plan to operate in a threaded environment, remember that all other
2388 modules you are using must also be thread-safe. Some modules, most notably
2389 L<DBD::SQLite>, are not thread-safe.
2390
2391 =head1 SUPPORT
2392
2393 IRC:
2394
2395     Join #catalyst on irc.perl.org.
2396
2397 Mailing Lists:
2398
2399     http://lists.rawmode.org/mailman/listinfo/catalyst
2400     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2401
2402 Web:
2403
2404     http://catalyst.perl.org
2405
2406 Wiki:
2407
2408     http://dev.catalyst.perl.org
2409
2410 =head1 SEE ALSO
2411
2412 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2413
2414 =head2 L<Catalyst::Manual> - The Catalyst Manual
2415
2416 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2417
2418 =head2 L<Catalyst::Engine> - Core engine
2419
2420 =head2 L<Catalyst::Log> - Log class.
2421
2422 =head2 L<Catalyst::Request> - Request object
2423
2424 =head2 L<Catalyst::Response> - Response object
2425
2426 =head2 L<Catalyst::Test> - The test suite.
2427
2428 =head1 PROJECT FOUNDER
2429
2430 sri: Sebastian Riedel <sri@cpan.org>
2431
2432 =head1 CONTRIBUTORS
2433
2434 abw: Andy Wardley
2435
2436 acme: Leon Brocard <leon@astray.com>
2437
2438 Andrew Bramble
2439
2440 Andrew Ford
2441
2442 Andrew Ruthven
2443
2444 andyg: Andy Grundman <andy@hybridized.org>
2445
2446 audreyt: Audrey Tang
2447
2448 bricas: Brian Cassidy <bricas@cpan.org>
2449
2450 chansen: Christian Hansen
2451
2452 chicks: Christopher Hicks
2453
2454 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2455
2456 Drew Taylor
2457
2458 esskar: Sascha Kiefer
2459
2460 fireartist: Carl Franks <cfranks@cpan.org>
2461
2462 gabb: Danijel Milicevic
2463
2464 Gary Ashton Jones
2465
2466 Geoff Richards
2467
2468 jcamacho: Juan Camacho
2469
2470 Jody Belka
2471
2472 Johan Lindstrom
2473
2474 jon: Jon Schutz <jjschutz@cpan.org>
2475
2476 marcus: Marcus Ramberg <mramberg@cpan.org>
2477
2478 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2479
2480 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2481
2482 mugwump: Sam Vilain
2483
2484 naughton: David Naughton
2485
2486 ningu: David Kamholz <dkamholz@cpan.org>
2487
2488 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2489
2490 numa: Dan Sully <daniel@cpan.org>
2491
2492 obra: Jesse Vincent
2493
2494 omega: Andreas Marienborg
2495
2496 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2497
2498 sky: Arthur Bergman
2499
2500 the_jester: Jesse Sheidlower
2501
2502 Ulf Edvinsson
2503
2504 willert: Sebastian Willert <willert@cpan.org>
2505
2506 =head1 LICENSE
2507
2508 This library is free software, you can redistribute it and/or modify it under
2509 the same terms as Perl itself.
2510
2511 =cut
2512
2513 1;