FastMmap.pm

   1 package Catalyst::Plugin::Session::FastMmap;
   2
   3 use strict;
   4 use base qw/Class::Data::Inheritable Class::Accessor::Fast/;
   5 use NEXT;
   6 use Cache::FastMmap;
   7 use Digest::MD5;
   8 use URI;
   9 use URI::Find;
  10 use File::Temp 'tempdir';
  11
  12 our $VERSION = '0.04';
  13
  14 __PACKAGE__->mk_classdata('_session');
  15 __PACKAGE__->mk_accessors('sessionid');
  16
  17 =head1 NAME
  18
  19 Catalyst::Plugin::Session::FastMmap - FastMmap sessions for Catalyst
  20
  21 =head1 SYNOPSIS
  22
  23     use Catalyst 'Session::FastMmap';
  24
  25     $c->session->{foo} = 'bar';
  26     print $c->sessionid;
  27
  28 =head1 DESCRIPTION
  29
  30 Fast sessions.
  31
  32 =head2 EXTENDED METHODS
  33
  34 =head3 finalize
  35
  36 =cut
  37
  38 sub finalize {
  39     my $c        = shift;
  40     my $redirect = $c->response->redirect;
  41     $c->response->redirect( $c->uri($redirect) ) if $redirect;
  42     if ( my $sid = $c->sessionid ) {
  43         $c->_session->set( $sid, $c->session );
  44         my $set = 1;
  45         if ( my $cookie = $c->request->cookies->{session} ) {
  46             $set = 0 if $cookie->value eq $sid;
  47         }
  48         $c->response->cookies->{session} = { value => $sid } if $set;
  49         my $finder = URI::Find->new(
  50             sub {
  51                 my ( $uri, $orig ) = @_;
  52                 my $base = $c->request->base;
  53                 return $orig unless $orig =~ /^$base/;
  54                 return $orig if $uri->path =~ /\/-\//;
  55                 return $c->uri($orig);
  56             }
  57         );
  58         $finder->find( \$c->response->{output} );
  59     }
  60     return $c->NEXT::finalize(@_);
  61 }
  62
  63 =head3 prepare_action
  64
  65 =cut
  66
  67 sub prepare_action {
  68     my $c = shift;
  69     if ( $c->request->path =~ /^(.*)\/\-\/(.+)$/ ) {
  70         $c->request->path($1);
  71         $c->sessionid($2);
  72         $c->log->debug(qq/Found sessionid "$2" in path/) if $c->debug;
  73     }
  74     if ( my $cookie = $c->request->cookies->{session} ) {
  75         my $sid = $cookie->value;
  76         $c->sessionid($sid);
  77         $c->log->debug(qq/Found sessionid "$sid" in cookie/) if $c->debug;
  78     }
  79     $c->NEXT::prepare_action(@_);
  80 }
  81
  82 sub session {
  83     my $c = shift;
  84     return $c->{session} if $c->{session};
  85     my $sid = $c->sessionid;
  86     if ( $sid && ( $c->{session} = $c->_session->get($sid) ) ) {
  87         $c->log->debug(qq/Found session "$sid"/) if $c->debug;
  88         return $c->{session};
  89     }
  90     else {
  91         my $sid = Digest::MD5::md5_hex( time, rand, $$, 'catalyst' );
  92         $c->sessionid($sid);
  93         $c->log->debug(qq/Created session "$sid"/) if $c->debug;
  94         return $c->{session} = {};
  95     }
  96 }
  97
  98 =head3 setup
  99
 100 =cut
 101
 102 sub setup {
 103     my $self               = shift;
 104     my $cache_root         = $self->config->{cache_root} || tempdir;
 105     my $default_expires_in = $self->config->{default_expires_in}
 106       || 60 * 60 * 24;
 107     my $auto_purge_interval = $self->config->{auto_purge_interval}
 108       || 60 * 60 * 24;
 109     my $auto_purge_on_set = $self->config->{auto_purge_on_set} || 1;
 110     $self->_session(
 111         Cache::FastMmap->new(
 112             cache_root          => $cache_root,
 113             default_expires_in  => $default_expires_in,
 114             auto_purge_interval => $auto_purge_interval,
 115             auto_purge_on_set   => $auto_purge_on_set
 116         )
 117     );
 118     return $self->NEXT::setup(@_);
 119 }
 120
 121 =head2 METHODS
 122
 123 =head3 session
 124
 125 =head3 uri
 126
 127 Extends an uri with session id if needed.
 128
 129     my $uri = $c->uri('http://localhost/foo');
 130
 131 =cut
 132
 133 sub uri {
 134     my ( $c, $uri ) = @_;
 135     if ( my $sid = $c->sessionid ) {
 136         $uri = URI->new($uri);
 137         my $path = $uri->path;
 138         $path .= '/' unless $path =~ /\/$/;
 139         $uri->path( $path . "-/$sid" );
 140         return $uri->as_string;
 141     }
 142     return $uri;
 143 }
 144
 145 =head1 SEE ALSO
 146
 147 L<Catalyst>.
 148
 149 =head1 AUTHOR
 150
 151 Sebastian Riedel, C<sri@cpan.org>
 152
 153 =head1 COPYRIGHT
 154
 155 This program is free software, you can redistribute it and/or modify it under
 156 the same terms as Perl itself.
 157
 158 =cut
 159
 160 1;