lib/Catalyst/Plugin/ConfigLoader.pm

   1 package Catalyst::Plugin::ConfigLoader;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Config::Any;
   7 use MRO::Compat;
   8 use Data::Visitor::Callback;
   9 use Catalyst::Utils ();
  10
  11 our $VERSION = '0.22';
  12
  13 =head1 NAME
  14
  15 Catalyst::Plugin::ConfigLoader - Load config files of various types
  16
  17 =head1 SYNOPSIS
  18
  19     package MyApp;
  20
  21     # ConfigLoader should be first in your list so
  22     # other plugins can get the config information
  23     use Catalyst qw( ConfigLoader ... );
  24
  25     # by default myapp.* will be loaded
  26     # you can specify a file if you'd like
  27     __PACKAGE__->config( 'Plugin::ConfigLoader' => { file => 'config.yaml' } );
  28
  29   In the file, assuming it's in YAML format:
  30
  31     foo: bar
  32
  33   Accessible through the context object, or the class itself
  34
  35    $c->config->{foo}    # bar
  36    MyApp->config->{foo} # bar
  37
  38 =head1 DESCRIPTION
  39
  40 This module will attempt to load find and load a configuration
  41 file of various types. Currently it supports YAML, JSON, XML,
  42 INI and Perl formats. Special configuration for a particular driver format can
  43 be stored in C<MyApp-E<gt>config-E<gt>{ 'Plugin::ConfigLoader' }-E<gt>{ driver }>.
  44 For example, to pass arguments to L<Config::General>, use the following:
  45
  46     __PACKAGE__->config( 'Plugin::ConfigLoader' => {
  47         driver => {
  48             'General' => { -LowerCaseNames => 1 }
  49         }
  50     } );
  51
  52 See L<Config::Any>'s C<driver_args> parameter for more information.
  53
  54 To support the distinction between development and production environments,
  55 this module will also attemp to load a local config (e.g. myapp_local.yaml)
  56 which will override any duplicate settings.
  57
  58 =head1 METHODS
  59
  60 =head2 setup( )
  61
  62 This method is automatically called by Catalyst's setup routine. It will
  63 attempt to use each plugin and, once a file has been successfully
  64 loaded, set the C<config()> section.
  65
  66 =cut
  67
  68 sub setup {
  69     my $c     = shift;
  70     my @files = $c->find_files;
  71     my $cfg   = Config::Any->load_files(
  72         {   files       => \@files,
  73             filter      => \&_fix_syntax,
  74             use_ext     => 1,
  75             driver_args => $c->config->{ 'Plugin::ConfigLoader' }->{ driver }
  76                 || {},
  77         }
  78     );
  79     # map the array of hashrefs to a simple hash
  80     my %configs = map { %$_ } @$cfg;
  81
  82     # split the responses into normal and local cfg
  83     my $local_suffix = $c->get_config_local_suffix;
  84     my ( @main, @locals );
  85     for ( sort keys %configs ) {
  86         if ( m{$local_suffix\.}ms ) {
  87             push @locals, $_;
  88         }
  89         else {
  90             push @main, $_;
  91         }
  92     }
  93
  94     # load all the normal cfgs, then the local cfgs last so they can override
  95     # normal cfgs
  96     $c->load_config( { $_ => $configs{ $_ } } ) for @main, @locals;
  97
  98     $c->finalize_config;
  99     $c->next::method( @_ );
 100 }
 101
 102 =head2 load_config
 103
 104 This method handles loading the configuration data into the Catalyst
 105 context object. It does not return a value.
 106
 107 =cut
 108
 109 sub load_config {
 110     my $c   = shift;
 111     my $ref = shift;
 112
 113     my ( $file, $config ) = %$ref;
 114
 115     $c->config( $config );
 116     $c->log->debug( qq(Loaded Config "$file") )
 117         if $c->debug;
 118
 119     return;
 120 }
 121
 122 =head2 find_files
 123
 124 This method determines the potential file paths to be used for config loading.
 125 It returns an array of paths (up to the filename less the extension) to pass to
 126 L<Config::Any|Config::Any> for loading.
 127
 128 =cut
 129
 130 sub find_files {
 131     my $c = shift;
 132     my ( $path, $extension ) = $c->get_config_path;
 133     my $suffix     = $c->get_config_local_suffix;
 134     my @extensions = @{ Config::Any->extensions };
 135
 136     my @files;
 137     if ( $extension ) {
 138         die "Unable to handle files with the extension '${extension}'"
 139             unless grep { $_ eq $extension } @extensions;
 140         ( my $local = $path ) =~ s{\.$extension}{_$suffix.$extension};
 141         push @files, $path, $local;
 142     }
 143     else {
 144         @files = map { ( "$path.$_", "${path}_${suffix}.$_" ) } @extensions;
 145     }
 146     @files;
 147 }
 148
 149 =head2 get_config_path
 150
 151 This method determines the path, filename prefix and file extension to be used
 152 for config loading. It returns the path (up to the filename less the
 153 extension) to check and the specific extension to use (if it was specified).
 154
 155 The order of preference is specified as:
 156
 157 =over 4
 158
 159 =item * C<$ENV{ MYAPP_CONFIG }>
 160
 161 =item * C<$ENV{ CATALYST_CONFIG }>
 162
 163 =item * C<$c-E<gt>config-E<gt>{ 'Plugin::ConfigLoader' }-E<gt>{ file }>
 164
 165 =item * C<$c-E<gt>path_to( $application_prefix )>
 166
 167 =back
 168
 169 If either of the first two user-specified options are directories, the
 170 application prefix will be added on to the end of the path.
 171
 172 =cut
 173
 174 sub get_config_path {
 175     my $c = shift;
 176
 177
 178     my $appname = ref $c || $c;
 179     my $prefix  = Catalyst::Utils::appprefix( $appname );
 180     my $path    = Catalyst::Utils::env_value( $c, 'CONFIG' )
 181         || $c->config->{ 'Plugin::ConfigLoader' }->{ file }
 182         || $c->path_to( $prefix );
 183
 184     my ( $extension ) = ( $path =~ m{\.(.{1,4})$} );
 185
 186     if ( -d $path ) {
 187         $path =~ s{[\/\\]$}{};
 188         $path .= "/$prefix";
 189     }
 190
 191     return ( $path, $extension );
 192 }
 193
 194 =head2 get_config_local_suffix
 195
 196 Determines the suffix of files used to override the main config. By default
 197 this value is C<local>, but it can be specified in the following order of preference:
 198
 199 =over 4
 200
 201 =item * C<$ENV{ MYAPP_CONFIG_LOCAL_SUFFIX }>
 202
 203 =item * C<$ENV{ CATALYST_CONFIG_LOCAL_SUFFIX }>
 204
 205 =item * C<$c-E<gt>config-E<gt>{ 'Plugin::ConfigLoader' }-E<gt>{ config_local_suffix }>
 206
 207 =back
 208
 209 =cut
 210
 211 sub get_config_local_suffix {
 212     my $c = shift;
 213
 214     my $appname = ref $c || $c;
 215     my $suffix = Catalyst::Utils::env_value( $c, 'CONFIG_LOCAL_SUFFIX' )
 216         || $c->config->{ 'Plugin::ConfigLoader' }->{ config_local_suffix }
 217         || 'local';
 218
 219     return $suffix;
 220 }
 221
 222 sub _fix_syntax {
 223     my $config     = shift;
 224     my @components = (
 225         map +{
 226             prefix => $_ eq 'Component' ? '' : $_ . '::',
 227             values => delete $config->{ lc $_ } || delete $config->{ $_ }
 228         },
 229         grep { ref $config->{ lc $_ } || ref $config->{ $_ } }
 230             qw( Component Model M View V Controller C Plugin )
 231     );
 232
 233     foreach my $comp ( @components ) {
 234         my $prefix = $comp->{ prefix };
 235         foreach my $element ( keys %{ $comp->{ values } } ) {
 236             $config->{ "$prefix$element" } = $comp->{ values }->{ $element };
 237         }
 238     }
 239 }
 240
 241 =head2 finalize_config
 242
 243 This method is called after the config file is loaded. It can be
 244 used to implement tuning of config values that can only be done
 245 at runtime. If you need to do this to properly configure any
 246 plugins, it's important to load ConfigLoader before them.
 247 ConfigLoader provides a default finalize_config method which
 248 walks through the loaded config hash and calls the C<config_substitutions>
 249 sub on any string.
 250
 251 =cut
 252
 253 sub finalize_config {
 254     my $c = shift;
 255     my $v = Data::Visitor::Callback->new(
 256         plain_value => sub {
 257             return unless defined $_;
 258             $c->config_substitutions( $_ );
 259         }
 260     );
 261     $v->visit( $c->config );
 262 }
 263
 264 =head2 config_substitutions( $value )
 265
 266 This method substitutes macros found with calls to a function. There are three
 267 default macros:
 268
 269 =over 4
 270
 271 =item * C<__HOME__> - replaced with C<$c-E<gt>path_to('')>
 272
 273 =item * C<__path_to(foo/bar)__> - replaced with C<$c-E<gt>path_to('foo/bar')>
 274
 275 =item * C<__literal(__FOO__)__> - leaves __FOO__ alone (allows you to use
 276 C<__DATA__> as a config value, for example)
 277
 278 =back
 279
 280 The parameter list is split on comma (C<,>). You can override this method to
 281 do your own string munging, or you can define your own macros in
 282 C<MyApp-E<gt>config-E<gt>{ 'Plugin::ConfigLoader' }-E<gt>{ substitutions }>.
 283 Example:
 284
 285     MyApp->config->{ 'Plugin::ConfigLoader' }->{ substitutions } = {
 286         baz => sub { my $c = shift; qux( @_ ); }
 287     }
 288
 289 The above will respond to C<__baz(x,y)__> in config strings.
 290
 291 =cut
 292
 293 sub config_substitutions {
 294     my $c    = shift;
 295     my $subs = $c->config->{ 'Plugin::ConfigLoader' }->{ substitutions }
 296         || {};
 297     $subs->{ HOME }    ||= sub { shift->path_to( '' ); };
 298     $subs->{ path_to } ||= sub { shift->path_to( @_ ); };
 299     $subs->{ literal } ||= sub { return $_[ 1 ]; };
 300     my $subsre = join( '|', keys %$subs );
 301
 302     for ( @_ ) {
 303         s{__($subsre)(?:\((.+?)\))?__}{ $subs->{ $1 }->( $c, $2 ? split( /,/, $2 ) : () ) }eg;
 304     }
 305 }
 306
 307 =head1 AUTHOR
 308
 309 Brian Cassidy E<lt>bricas@cpan.orgE<gt>
 310
 311 =head1 CONTRIBUTORS
 312
 313 The following people have generously donated their time to the
 314 development of this module:
 315
 316 =over 4
 317
 318 =item * Joel Bernstein E<lt>rataxis@cpan.orgE<gt> - Rewrite to use L<Config::Any>
 319
 320 =item * David Kamholz E<lt>dkamholz@cpan.orgE<gt> - L<Data::Visitor> integration
 321
 322 =back
 323
 324 Work to this module has been generously sponsored by:
 325
 326 =over 4
 327
 328 =item * Portugal Telecom L<http://www.sapo.pt/> - Work done by Joel Bernstein
 329
 330 =back
 331
 332 =head1 COPYRIGHT AND LICENSE
 333
 334 Copyright 2006-2009 by Brian Cassidy
 335
 336 This library is free software; you can redistribute it and/or modify
 337 it under the same terms as Perl itself.
 338
 339 =head1 SEE ALSO
 340
 341 =over 4
 342
 343 =item * L<Catalyst>
 344
 345 =item * L<Catalyst::Plugin::ConfigLoader::Manual>
 346
 347 =item * L<Config::Any>
 348
 349 =back
 350
 351 =cut
 352
 353 1;