lib/Catalyst/Plugin/ConfigLoader.pm

   1 package Catalyst::Plugin::ConfigLoader;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Config::Any;
   7 use MRO::Compat;
   8 use Data::Visitor::Callback;
   9 use Catalyst::Utils ();
  10
  11 our $VERSION = '0.32';
  12
  13 =head1 NAME
  14
  15 Catalyst::Plugin::ConfigLoader - Load config files of various types
  16
  17 =head1 SYNOPSIS
  18
  19     package MyApp;
  20
  21     # ConfigLoader should be first in your list so
  22     # other plugins can get the config information
  23     use Catalyst qw( ConfigLoader ... );
  24
  25     # by default myapp.* will be loaded
  26     # you can specify a file if you'd like
  27     __PACKAGE__->config( 'Plugin::ConfigLoader' => { file => 'config.yaml' } );
  28
  29   In the file, assuming it's in YAML format:
  30
  31     foo: bar
  32
  33   Accessible through the context object, or the class itself
  34
  35    $c->config->{foo}    # bar
  36    MyApp->config->{foo} # bar
  37
  38 =head1 DESCRIPTION
  39
  40 This module will attempt to load find and load a configuration
  41 file of various types. Currently it supports YAML, JSON, XML,
  42 INI and Perl formats. Special configuration for a particular driver format can
  43 be stored in C<MyApp-E<gt>config-E<gt>{ 'Plugin::ConfigLoader' }-E<gt>{ driver }>.
  44 For example, to pass arguments to L<Config::General>, use the following:
  45
  46     __PACKAGE__->config( 'Plugin::ConfigLoader' => {
  47         driver => {
  48             'General' => { -LowerCaseNames => 1 }
  49         }
  50     } );
  51
  52 See L<Config::Any>'s C<driver_args> parameter for more information.
  53
  54 To support the distinction between development and production environments,
  55 this module will also attemp to load a local config (e.g. myapp_local.yaml)
  56 which will override any duplicate settings.  See
  57 L<get_config_local_suffix|/get_config_local_suffix>
  58 for details on how this is configured.
  59
  60 =head1 METHODS
  61
  62 =head2 setup( )
  63
  64 This method is automatically called by Catalyst's setup routine. It will
  65 attempt to use each plugin and, once a file has been successfully
  66 loaded, set the C<config()> section.
  67
  68 =cut
  69
  70 sub setup {
  71     my $c     = shift;
  72     my @files = $c->find_files;
  73     my $cfg   = Config::Any->load_files(
  74         {   files       => \@files,
  75             filter      => \&_fix_syntax,
  76             use_ext     => 1,
  77             driver_args => $c->config->{ 'Plugin::ConfigLoader' }->{ driver }
  78                 || {},
  79         }
  80     );
  81     # map the array of hashrefs to a simple hash
  82     my %configs = map { %$_ } @$cfg;
  83
  84     # split the responses into normal and local cfg
  85     my $local_suffix = $c->get_config_local_suffix;
  86     my ( @main, @locals );
  87     for ( sort keys %configs ) {
  88         if ( m{$local_suffix\.}ms ) {
  89             push @locals, $_;
  90         }
  91         else {
  92             push @main, $_;
  93         }
  94     }
  95
  96     # load all the normal cfgs, then the local cfgs last so they can override
  97     # normal cfgs
  98     $c->load_config( { $_ => $configs{ $_ } } ) for @main, @locals;
  99
 100     $c->finalize_config;
 101     $c->next::method( @_ );
 102 }
 103
 104 =head2 load_config
 105
 106 This method handles loading the configuration data into the Catalyst
 107 context object. It does not return a value.
 108
 109 =cut
 110
 111 sub load_config {
 112     my $c   = shift;
 113     my $ref = shift;
 114
 115     my ( $file, $config ) = %$ref;
 116
 117     $c->config( $config );
 118     $c->log->debug( qq(Loaded Config "$file") )
 119         if $c->debug;
 120
 121     return;
 122 }
 123
 124 =head2 find_files
 125
 126 This method determines the potential file paths to be used for config loading.
 127 It returns an array of paths (up to the filename less the extension) to pass to
 128 L<Config::Any|Config::Any> for loading.
 129
 130 =cut
 131
 132 sub find_files {
 133     my $c = shift;
 134     my ( $path, $extension ) = $c->get_config_path;
 135     my $suffix     = $c->get_config_local_suffix;
 136     my @extensions = @{ Config::Any->extensions };
 137
 138     my @files;
 139     if ( $extension ) {
 140         die "Unable to handle files with the extension '${extension}'"
 141             unless grep { $_ eq $extension } @extensions;
 142         ( my $local = $path ) =~ s{\.$extension}{_$suffix.$extension};
 143         push @files, $path, $local;
 144     }
 145     else {
 146         @files = map { ( "$path.$_", "${path}_${suffix}.$_" ) } @extensions;
 147     }
 148     @files;
 149 }
 150
 151 =head2 get_config_path
 152
 153 This method determines the path, filename prefix and file extension to be used
 154 for config loading. It returns the path (up to the filename less the
 155 extension) to check and the specific extension to use (if it was specified).
 156
 157 The order of preference is specified as:
 158
 159 =over 4
 160
 161 =item * C<$ENV{ MYAPP_CONFIG }>
 162
 163 =item * C<$ENV{ CATALYST_CONFIG }>
 164
 165 =item * C<$c-E<gt>config-E<gt>{ 'Plugin::ConfigLoader' }-E<gt>{ file }>
 166
 167 =item * C<$c-E<gt>path_to( $application_prefix )>
 168
 169 =back
 170
 171 If either of the first two user-specified options are directories, the
 172 application prefix will be added on to the end of the path.
 173
 174 =cut
 175
 176 sub get_config_path {
 177     my $c = shift;
 178
 179
 180     my $appname = ref $c || $c;
 181     my $prefix  = Catalyst::Utils::appprefix( $appname );
 182     my $path    = Catalyst::Utils::env_value( $appname, 'CONFIG' )
 183         || $c->config->{ 'Plugin::ConfigLoader' }->{ file }
 184         || $c->path_to( $prefix );
 185
 186     my ( $extension ) = ( $path =~ m{\.([^\/\\.]{1,4})$} );
 187
 188     if ( -d $path ) {
 189         $path =~ s{[\/\\]$}{};
 190         $path .= "/$prefix";
 191     }
 192
 193     return ( $path, $extension );
 194 }
 195
 196 =head2 get_config_local_suffix
 197
 198 Determines the suffix of files used to override the main config. By default
 199 this value is C<local>, which will load C<myapp_local.conf>.  The suffix can
 200 be specified in the following order of preference:
 201
 202 =over 4
 203
 204 =item * C<$ENV{ MYAPP_CONFIG_LOCAL_SUFFIX }>
 205
 206 =item * C<$ENV{ CATALYST_CONFIG_LOCAL_SUFFIX }>
 207
 208 =item * C<$c-E<gt>config-E<gt>{ 'Plugin::ConfigLoader' }-E<gt>{ config_local_suffix }>
 209
 210 =back
 211
 212 The first one of these values found replaces the default of C<local> in the
 213 name of the local config file to be loaded.
 214
 215 For example, if C< $ENV{ MYAPP_CONFIG_LOCAL_SUFFIX }> is set to C<testing>,
 216 ConfigLoader will try and load C<myapp_testing.conf> instead of
 217 C<myapp_local.conf>.
 218
 219 =cut
 220
 221 sub get_config_local_suffix {
 222     my $c = shift;
 223
 224     my $appname = ref $c || $c;
 225     my $suffix = Catalyst::Utils::env_value( $appname, 'CONFIG_LOCAL_SUFFIX' )
 226         || $c->config->{ 'Plugin::ConfigLoader' }->{ config_local_suffix }
 227         || 'local';
 228
 229     return $suffix;
 230 }
 231
 232 sub _fix_syntax {
 233     my $config     = shift;
 234     my @components = (
 235         map +{
 236             prefix => $_ eq 'Component' ? '' : $_ . '::',
 237             values => delete $config->{ lc $_ } || delete $config->{ $_ }
 238         },
 239         grep { ref $config->{ lc $_ } || ref $config->{ $_ } }
 240             qw( Component Model M View V Controller C Plugin )
 241     );
 242
 243     foreach my $comp ( @components ) {
 244         my $prefix = $comp->{ prefix };
 245         foreach my $element ( keys %{ $comp->{ values } } ) {
 246             $config->{ "$prefix$element" } = $comp->{ values }->{ $element };
 247         }
 248     }
 249 }
 250
 251 =head2 finalize_config
 252
 253 This method is called after the config file is loaded. It can be
 254 used to implement tuning of config values that can only be done
 255 at runtime. If you need to do this to properly configure any
 256 plugins, it's important to load ConfigLoader before them.
 257 ConfigLoader provides a default finalize_config method which
 258 walks through the loaded config hash and calls the C<config_substitutions>
 259 sub on any string.
 260
 261 =cut
 262
 263 sub finalize_config {
 264     my $c = shift;
 265     my $v = Data::Visitor::Callback->new(
 266         plain_value => sub {
 267             return unless defined $_;
 268             $c->config_substitutions( $_ );
 269         }
 270     );
 271     $v->visit( $c->config );
 272 }
 273
 274 =head2 config_substitutions( $value )
 275
 276 This method substitutes macros found with calls to a function. There are a
 277 number of default macros:
 278
 279 =over 4
 280
 281 =item * C<__HOME__> - replaced with C<$c-E<gt>path_to('')>
 282
 283 =item * C<__ENV(foo)__> - replaced with the value of C<$ENV{foo}>
 284
 285 =item * C<__path_to(foo/bar)__> - replaced with C<$c-E<gt>path_to('foo/bar')>
 286
 287 =item * C<__literal(__FOO__)__> - leaves __FOO__ alone (allows you to use
 288 C<__DATA__> as a config value, for example)
 289
 290 =back
 291
 292 The parameter list is split on comma (C<,>). You can override this method to
 293 do your own string munging, or you can define your own macros in
 294 C<MyApp-E<gt>config-E<gt>{ 'Plugin::ConfigLoader' }-E<gt>{ substitutions }>.
 295 Example:
 296
 297     MyApp->config->{ 'Plugin::ConfigLoader' }->{ substitutions } = {
 298         baz => sub { my $c = shift; qux( @_ ); }
 299     }
 300
 301 The above will respond to C<__baz(x,y)__> in config strings.
 302
 303 =cut
 304
 305 sub config_substitutions {
 306     my $c    = shift;
 307     my $subs = $c->config->{ 'Plugin::ConfigLoader' }->{ substitutions }
 308         || {};
 309     $subs->{ HOME }    ||= sub { shift->path_to( '' ); };
 310     $subs->{ ENV }    ||=
 311         sub {
 312             my ( $c, $v ) = @_;
 313             if (! defined($ENV{$v})) {
 314                 Catalyst::Exception->throw( message =>
 315                     "Missing environment variable: $v" );
 316                 return "";
 317             } else {
 318                 return $ENV{ $v };
 319             }
 320         };
 321     $subs->{ path_to } ||= sub { shift->path_to( @_ ); };
 322     $subs->{ literal } ||= sub { return $_[ 1 ]; };
 323     my $subsre = join( '|', keys %$subs );
 324
 325     for ( @_ ) {
 326         s{__($subsre)(?:\((.+?)\))?__}{ $subs->{ $1 }->( $c, $2 ? split( /,/, $2 ) : () ) }eg;
 327     }
 328 }
 329
 330 =head1 AUTHOR
 331
 332 Brian Cassidy E<lt>bricas@cpan.orgE<gt>
 333
 334 =head1 CONTRIBUTORS
 335
 336 The following people have generously donated their time to the
 337 development of this module:
 338
 339 =over 4
 340
 341 =item * Joel Bernstein E<lt>rataxis@cpan.orgE<gt> - Rewrite to use L<Config::Any>
 342
 343 =item * David Kamholz E<lt>dkamholz@cpan.orgE<gt> - L<Data::Visitor> integration
 344
 345 =item * Stuart Watt - Addition of ENV macro.
 346
 347 =back
 348
 349 Work to this module has been generously sponsored by:
 350
 351 =over 4
 352
 353 =item * Portugal Telecom L<http://www.sapo.pt/> - Work done by Joel Bernstein
 354
 355 =back
 356
 357 =head1 COPYRIGHT AND LICENSE
 358
 359 Copyright 2006-2010 by Brian Cassidy
 360
 361 This library is free software; you can redistribute it and/or modify
 362 it under the same terms as Perl itself.
 363
 364 =head1 SEE ALSO
 365
 366 =over 4
 367
 368 =item * L<Catalyst>
 369
 370 =item * L<Catalyst::Plugin::ConfigLoader::Manual>
 371
 372 =item * L<Config::Any>
 373
 374 =back
 375
 376 =cut
 377
 378 1;