Apply |RABBIT|'s defined warning fix for ConfigLoader

[catagits/Catalyst-Plugin-ConfigLoader.git] / lib / Catalyst / Plugin / ConfigLoader.pm

package Catalyst::Plugin::ConfigLoader;\r
\r
use strict;\r
use warnings;\r
\r
use NEXT;\r
use Module::Pluggable::Fast\r
    name    => '_config_loaders',\r
    search  => [ __PACKAGE__ ],\r
    require => 1;\r
use Data::Visitor::Callback;\r
\r
our $VERSION = '0.04';\r
\r
=head1 NAME\r
\r
Catalyst::Plugin::ConfigLoader - Load config files of various types\r
\r
=head1 SYNOPSIS\r
\r
    package MyApp;\r
    \r
    # ConfigLoader should be first in your list so\r
    # other plugins can get the config information\r
    use Catalyst qw( ConfigLoader ... );\r
	\r
    # by default myapp.* will be loaded\r
    # you can specify a file if you'd like\r
    __PACKAGE__->config( file = > 'config.yaml' );    \r
\r
=head1 DESCRIPTION\r
\r
This mdoule will attempt to load find and load a configuration\r
file of various types. Currently it supports YAML, JSON, XML,\r
INI and Perl formats.\r
\r
=head1 METHODS\r
\r
=head2 setup( )\r
\r
This method is automatically called by Catalyst's setup routine. It will\r
attempt to use each plugin and, once a file has been successfully\r
loaded, set the C<config()> section.\r
\r
=cut\r
\r
sub setup {\r
    my $c    = shift;\r
    my $path = $c->config->{ file } || $c->path_to( Catalyst::Utils::appprefix( ref $c || $c ) );\r
\r
    my( $extension ) = ( $path =~ /\.(.{1,4})$/ );\r
    \r
    for my $loader ( $c->_config_loaders ) {\r
        my @files;\r
        my @extensions = $loader->extensions;\r
        if( $extension ) {\r
            next unless grep { $_ eq $extension } @extensions;\r
            push @files, $path;\r
        }\r
        else {\r
            push @files, "$path.$_" for @extensions;\r
        }\r
\r
        for( @files ) {\r
            next unless -f $_;\r
            my $config = $loader->load( $_ );\r
            if( $config ) {\r
                $c->config( $config );\r
                last;\r
            }\r
        }\r
    }\r
\r
    $c->finalize_config;\r
\r
    $c->NEXT::setup( @_ );\r
}\r
\r
=head2 finalize_config\r
\r
This method is called after the config file is loaded. It can be\r
used to implement tuning of config values that can only be done\r
at runtime. If you need to do this to properly configure any\r
plugins, it's important to load ConfigLoader before them.\r
ConfigLoader provides a default finalize_config method which\r
walks through the loaded config hash and replaces any strings\r
beginning with C<< __HOME__/<path> >> with the full path to\r
the file inside the app's home directory.\r
\r
=cut\r
\r
sub finalize_config {\r
    my $c = shift;\r
    my $v = Data::Visitor::Callback->new(\r
        plain_value => sub { s[^__HOME__/(.+)$][ $c->path_to($1) ]e if defined $_ }\r
    );\r
    $v->visit( $c->config );\r
}\r
\r
=head1 AUTHOR\r
\r
=over 4 \r
\r
=item * Brian Cassidy E<lt>bricas@cpan.orgE<gt>\r
\r
=back\r
\r
=head1 CONTRIBUTORS\r
\r
The following people have generously donated their time to the\r
development of this module:\r
\r
=over 4\r
\r
=item * David Kamholz E<lt>dkamholz@cpan.orgE<gt>\r
\r
=back\r
\r
=head1 COPYRIGHT AND LICENSE\r
\r
Copyright 2006 by Brian Cassidy\r
\r
This library is free software; you can redistribute it and/or modify\r
it under the same terms as Perl itself. \r
\r
=head1 SEE ALSO\r
\r
=over 4 \r
\r
=item * L<Catalyst>\r
\r
=back\r
\r
=cut\r
\r
1;\r