lib/Catalyst/Plugin/Authentication.pm

   1 package Catalyst::Plugin::Authentication;
   2
   3 use base qw/Class::Accessor::Fast Class::Data::Inheritable/;
   4
   5 __PACKAGE__->mk_accessors(qw/_user/);
   6
   7 use strict;
   8 use warnings;
   9
  10 use MRO::Compat;
  11 use Tie::RefHash;
  12 use Class::Inspector;
  13 use Catalyst::Authentication::Realm;
  14
  15 our $VERSION = "0.10011";
  16
  17 sub set_authenticated {
  18     my ( $c, $user, $realmname ) = @_;
  19
  20     $c->user($user);
  21     $c->request->{user} = $user;    # compatibility kludge
  22
  23     if (!$realmname) {
  24         $realmname = 'default';
  25     }
  26     my $realm = $c->get_auth_realm($realmname);
  27
  28     if (!$realm) {
  29         Catalyst::Exception->throw(
  30                 "set_authenticated called with nonexistant realm: '$realmname'.");
  31     }
  32     $user->auth_realm($realm->name);
  33
  34     $c->persist_user();
  35
  36     $c->maybe::next::method($user, $realmname);
  37 }
  38
  39 sub user {
  40     my $c = shift;
  41
  42     if (@_) {
  43         return $c->_user(@_);
  44     }
  45
  46     if ( defined($c->_user) ) {
  47         return $c->_user;
  48     } else {
  49         return $c->auth_restore_user;
  50     }
  51 }
  52
  53 # change this to allow specification of a realm - to verify the user is part of that realm
  54 # in addition to verifying that they exist.
  55 sub user_exists {
  56         my $c = shift;
  57         return defined($c->_user) || defined($c->find_realm_for_persisted_user);
  58 }
  59
  60 # works like user_exists - except only returns true if user
  61 # exists AND is in the realm requested.
  62 sub user_in_realm {
  63     my ($c, $realmname) = @_;
  64
  65     if (defined($c->_user)) {
  66         return ($c->_user->auth_realm eq $realmname);
  67     } else {
  68         my $realm = $c->find_realm_for_persisted_user;
  69         if ($realm) {
  70             return ($realm->name eq $realmname);
  71         } else {
  72             return undef;
  73         }
  74     }
  75 }
  76
  77 sub __old_save_user_in_session {
  78     my ( $c, $user, $realmname ) = @_;
  79
  80     $c->session->{__user_realm} = $realmname;
  81
  82     # we want to ask the store for a user prepared for the session.
  83     # but older modules split this functionality between the user and the
  84     # store.  We try the store first.  If not, we use the old method.
  85     my $realm = $c->get_auth_realm($realmname);
  86     if ($realm->{'store'}->can('for_session')) {
  87         $c->session->{__user} = $realm->{'store'}->for_session($c, $user);
  88     } else {
  89         $c->session->{__user} = $user->for_session;
  90     }
  91 }
  92
  93 sub persist_user {
  94     my $c = shift;
  95
  96     if ($c->user_exists) {
  97
  98         ## if we have a valid session handler - we store the
  99         ## realm in the session.  If not - we have to hope that
 100         ## the realm can recognize its frozen user somehow.
 101         if ($c->can('session') &&
 102             $c->config->{'Plugin::Authentication'}{'use_session'} &&
 103             $c->session_is_valid) {
 104
 105             $c->session->{'__user_realm'} = $c->_user->auth_realm;
 106         }
 107
 108         my $realm = $c->get_auth_realm($c->_user->auth_realm);
 109
 110         # used to call $realm->save_user_in_session
 111         $realm->persist_user($c, $c->user);
 112     }
 113 }
 114
 115
 116 ## this was a short lived method to update user information -
 117 ## you should use persist_user instead.
 118 sub update_user_in_session {
 119     my $c = shift;
 120
 121     return $c->persist_user;
 122 }
 123
 124 sub logout {
 125     my $c = shift;
 126
 127     $c->user(undef);
 128
 129     my $realm = $c->find_realm_for_persisted_user;
 130     if ($realm) {
 131         $realm->remove_persisted_user($c);
 132     }
 133
 134     $c->maybe::next::method(@_);
 135 }
 136
 137 sub find_user {
 138     my ( $c, $userinfo, $realmname ) = @_;
 139
 140     $realmname ||= 'default';
 141     my $realm = $c->get_auth_realm($realmname);
 142
 143     if (!$realm) {
 144         Catalyst::Exception->throw(
 145                 "find_user called with nonexistant realm: '$realmname'.");
 146     }
 147     return $realm->find_user($userinfo, $c);
 148 }
 149
 150 ## Consider making this a public method. - would make certain things easier when
 151 ## dealing with things pre-auth restore.
 152 sub find_realm_for_persisted_user {
 153     my $c = shift;
 154
 155     my $realm;
 156     if ($c->can('session')
 157         and $c->config->{'Plugin::Authentication'}{'use_session'}
 158         and $c->session_is_valid
 159         and exists($c->session->{'__user_realm'})) {
 160
 161         $realm = $c->auth_realms->{$c->session->{'__user_realm'}};
 162         if ($realm->user_is_restorable($c)) {
 163             return $realm;
 164         }
 165     } else {
 166         ## we have no choice but to ask each realm whether it has a persisted user.
 167         foreach my $realmname (@{$c->_auth_realm_restore_order}) {
 168             my $ret = $c->auth_realms->{$realmname}->user_is_restorable($c);
 169             if ($ret) {
 170                 return $c->auth_realms->{$realmname};
 171             }
 172         }
 173     }
 174     return undef;
 175 }
 176
 177 sub auth_restore_user {
 178     my ( $c, $frozen_user, $realmname ) = @_;
 179
 180     my $realm;
 181     if (defined($realmname)) {
 182         $realm = $c->get_auth_realm($realmname);
 183     } else {
 184         $realm = $c->find_realm_for_persisted_user;
 185     }
 186     return undef unless $realm; # FIXME die unless? This is an internal inconsistency
 187
 188     $c->_user( my $user = $realm->restore_user( $c, $frozen_user ) );
 189
 190     # this sets the realm the user originated in.
 191     $user->auth_realm($realm->name) if $user;
 192
 193     return $user;
 194
 195 }
 196
 197 # we can't actually do our setup in setup because the model has not yet been loaded.
 198 # So we have to trigger off of setup_finished.  :-(
 199 sub setup {
 200     my $app = shift;
 201
 202     $app->_authentication_initialize();
 203     $app->next::method(@_);
 204 }
 205
 206 ## the actual initialization routine. whee.
 207 sub _authentication_initialize {
 208     my $app = shift;
 209
 210     ## let's avoid recreating / configuring everything if we have already done it, eh?
 211     if ($app->can('_auth_realms')) { return };
 212
 213     ## make classdata where it is used.
 214     $app->mk_classdata( '_auth_realms' => {});
 215
 216     ## the order to attempt restore in - If we don't have session - we have
 217     ## no way to be sure where a frozen user came from - so we have to
 218     ## ask each realm if it can restore the user.  Unfortunately it is possible
 219     ## that multiple realms could restore the user from the data we have -
 220     ## So we have to determine at setup time what order to ask the realms in.
 221     ## The default is to use the user_restore_priority values defined in the realm
 222     ## config. if they are not defined - we go by alphabetical order.   Note that
 223     ## the 'default' realm always gets first chance at it unless it is explicitly
 224     ## placed elsewhere by user_restore_priority.  Remember this only comes
 225     ## into play if session is disabled.
 226
 227     $app->mk_classdata( '_auth_realm_restore_order' => []);
 228
 229     my $cfg = $app->config->{'Plugin::Authentication'};
 230         my $realmshash;
 231     if (!defined($cfg)) {
 232         if (exists($app->config->{'authentication'})) {
 233             $cfg = $app->config->{'authentication'};
 234             $app->config->{'Plugin::Authentication'} = $app->config->{'authentication'};
 235         } else {
 236             $cfg = {};
 237         }
 238     } else {
 239                 # the realmshash contains the various configured realms.  By default this is
 240                 # the main $app->config->{'Plugin::Authentication'} hash - but if that is
 241                 # not defined, or there is a subkey {'realms'} then we use that.
 242                 $realmshash = $cfg;
 243         }
 244
 245         ## If we have a sub-key of {'realms'} then we use that for realm configuration
 246         if (exists($cfg->{'realms'})) {
 247                 $realmshash = $cfg->{'realms'};
 248         }
 249
 250     # old default was to force use_session on.  This must remain for that
 251     # reason - but if use_session is already in the config, we respect its setting.
 252     if (!exists($cfg->{'use_session'})) {
 253         $cfg->{'use_session'} = 1;
 254     }
 255
 256     ## if we have a realms hash
 257     if (ref($realmshash) eq 'HASH') {
 258
 259         my %auth_restore_order;
 260         my $authcount = 2;
 261         my $defaultrealm = 'default';
 262
 263         foreach my $realm (sort keys %{$realmshash}) {
 264             if (ref($realmshash->{$realm}) eq 'HASH' &&
 265                                 (exists($realmshash->{$realm}{credential}) || exists($realmshash->{$realm}{class}))) {
 266
 267                     $app->setup_auth_realm($realm, $realmshash->{$realm});
 268
 269                     if (exists($realmshash->{$realm}{'user_restore_priority'})) {
 270                         $auth_restore_order{$realm} = $realmshash->{$realm}{'user_restore_priority'};
 271                     } else {
 272                         $auth_restore_order{$realm} = $authcount++;
 273                     }
 274                         }
 275         }
 276
 277         # if we have a 'default_realm' in the config hash and we don't already
 278         # have a realm called 'default', we point default at the realm specified
 279         if (exists($cfg->{'default_realm'}) && !$app->get_auth_realm('default')) {
 280             if ($app->_set_default_auth_realm($cfg->{'default_realm'})) {
 281                 $defaultrealm = $cfg->{'default_realm'};
 282                 $auth_restore_order{'default'} = $auth_restore_order{$cfg->{'default_realm'}};
 283                 delete($auth_restore_order{$cfg->{'default_realm'}});
 284             }
 285         }
 286
 287         ## if the default realm did not have a defined priority in its config - we put it at the front.
 288         if (!exists($realmshash->{$defaultrealm}{'user_restore_priority'})) {
 289             $auth_restore_order{'default'} = 1;
 290         }
 291
 292         @{$app->_auth_realm_restore_order} = sort { $auth_restore_order{$a} <=> $auth_restore_order{$b} } keys %auth_restore_order;
 293
 294     } else {
 295
 296         ## BACKWARDS COMPATIBILITY - if realms is not defined - then we are probably dealing
 297         ## with an old-school config.  The only caveat here is that we must add a classname
 298
 299         ## also - we have to treat {store} as {stores}{default} - because
 300         ## while it is not a clear as a valid config in the docs, it
 301         ## is functional with the old api. Whee!
 302         if (exists($cfg->{'store'}) && !exists($cfg->{'stores'}{'default'})) {
 303             $cfg->{'stores'}{'default'} = $cfg->{'store'};
 304         }
 305
 306         push @{$app->_auth_realm_restore_order}, 'default';
 307         foreach my $storename (keys %{$cfg->{'stores'}}) {
 308             my $realmcfg = {
 309                 store => { class => $cfg->{'stores'}{$storename} },
 310             };
 311             print STDERR "Foo, ok?\n";
 312             $app->setup_auth_realm($storename, $realmcfg);
 313         }
 314     }
 315
 316 }
 317
 318 # set up realmname.
 319 sub setup_auth_realm {
 320     my ($app, $realmname, $config) = @_;
 321
 322     my $realmclass = $config->{class};
 323
 324     if( !$realmclass ) {
 325         $realmclass = 'Catalyst::Authentication::Realm';
 326     } elsif ($realmclass !~ /^\+(.*)$/ ) {
 327         $realmclass = "Catalyst::Authentication::Realm::${realmclass}";
 328     } else {
 329         $realmclass = $1;
 330     }
 331
 332     Catalyst::Utils::ensure_class_loaded( $realmclass );
 333
 334     my $realm = $realmclass->new($realmname, $config, $app);
 335     if ($realm) {
 336         $app->auth_realms->{$realmname} = $realm;
 337     } else {
 338         $app->log->debug("realm initialization for '$realmname' failed.");
 339     }
 340     return $realm;
 341 }
 342
 343 sub auth_realms {
 344     my $self = shift;
 345     return($self->_auth_realms);
 346 }
 347
 348 sub get_auth_realm {
 349     my ($app, $realmname) = @_;
 350
 351     return $app->auth_realms->{$realmname};
 352
 353 }
 354
 355
 356 # Very internal method.  Vital Valuable Urgent, Do not touch on pain of death.
 357 # Using this method just assigns the default realm to be the value associated
 358 # with the realmname provided.  It WILL overwrite any real realm called 'default'
 359 # so can be very confusing if used improperly.  It's used properly already.
 360 # Translation: don't use it.
 361 sub _set_default_auth_realm {
 362     my ($app, $realmname) = @_;
 363
 364     if (exists($app->auth_realms->{$realmname})) {
 365         $app->auth_realms->{'default'} = $app->auth_realms->{$realmname};
 366     }
 367     return $app->get_auth_realm('default');
 368 }
 369
 370 sub authenticate {
 371     my ($app, $userinfo, $realmname) = @_;
 372
 373     if (!$realmname) {
 374         $realmname = 'default';
 375     }
 376
 377     my $realm = $app->get_auth_realm($realmname);
 378
 379     ## note to self - make authenticate throw an exception if realm is invalid.
 380
 381     if ($realm) {
 382         return $realm->authenticate($app, $userinfo);
 383     } else {
 384         Catalyst::Exception->throw(
 385                 "authenticate called with nonexistant realm: '$realmname'.");
 386
 387     }
 388     return undef;
 389 }
 390
 391 ## BACKWARDS COMPATIBILITY  -- Warning:  Here be monsters!
 392 #
 393 # What follows are backwards compatibility routines - for use with Stores and Credentials
 394 # that have not been updated to work with C::P::Authentication v0.10.
 395 # These are here so as to not break people's existing installations, but will go away
 396 # in a future version.
 397 #
 398 # The old style of configuration only supports a single store, as each store module
 399 # sets itself as the default store upon being loaded.  This is the only supported
 400 # 'compatibility' mode.
 401 #
 402
 403 sub get_user {
 404     my ( $c, $uid, @rest ) = @_;
 405
 406     return $c->find_user( {'id' => $uid, 'rest'=>\@rest }, 'default' );
 407 }
 408
 409
 410 ## this should only be called when using old-style authentication plugins.  IF this gets
 411 ## called in a new-style config - it will OVERWRITE the store of your default realm.  Don't do it.
 412 ## also - this is a partial setup - because no credential is instantiated... in other words it ONLY
 413 ## works with old-style auth plugins and C::P::Authentication in compatibility mode.  Trying to combine
 414 ## this with a realm-type config will probably crash your app.
 415 sub default_auth_store {
 416     my $self = shift;
 417
 418     my $realm = $self->get_auth_realm('default');
 419     if (!$realm) {
 420         $realm = $self->setup_auth_realm('default', { class => 'Compatibility' });
 421     }
 422     if ( my $new = shift ) {
 423         $realm->store($new);
 424
 425         my $storeclass;
 426         if (ref($new)) {
 427             $storeclass = ref($new);
 428         } else {
 429             $storeclass = $new;
 430         }
 431
 432         # BACKWARDS COMPATIBILITY - if the store class does not define find_user, we define it in terms
 433         # of get_user and add it to the class.  this is because the auth routines use find_user,
 434         # and rely on it being present. (this avoids per-call checks)
 435         if (!$storeclass->can('find_user')) {
 436             no strict 'refs';
 437             *{"${storeclass}::find_user"} = sub {
 438                                                     my ($self, $info) = @_;
 439                                                     my @rest = @{$info->{rest}} if exists($info->{rest});
 440                                                     $self->get_user($info->{id}, @rest);
 441                                                 };
 442         }
 443     }
 444
 445     return $self->get_auth_realm('default')->store;
 446 }
 447
 448 ## BACKWARDS COMPATIBILITY
 449 ## this only ever returns a hash containing 'default' - as that is the only
 450 ## supported mode of calling this.
 451 sub auth_store_names {
 452     my $self = shift;
 453
 454     my %hash = (  $self->get_auth_realm('default')->store => 'default' );
 455 }
 456
 457 sub get_auth_store {
 458     my ( $self, $name ) = @_;
 459
 460     if ($name ne 'default') {
 461         Carp::croak "get_auth_store called on non-default realm '$name'. Only default supported in compatibility mode";
 462     } else {
 463         $self->default_auth_store();
 464     }
 465 }
 466
 467 sub get_auth_store_name {
 468     my ( $self, $store ) = @_;
 469     return 'default';
 470 }
 471
 472 # sub auth_stores is only used internally - here for completeness
 473 sub auth_stores {
 474     my $self = shift;
 475
 476     my %hash = ( 'default' => $self->get_auth_realm('default')->store);
 477 }
 478
 479 __PACKAGE__;
 480
 481 __END__
 482
 483 =pod
 484
 485 =head1 NAME
 486
 487 Catalyst::Plugin::Authentication - Infrastructure plugin for the Catalyst
 488 authentication framework.
 489
 490 =head1 SYNOPSIS
 491
 492     use Catalyst qw/
 493         Authentication
 494     /;
 495
 496     # later on ...
 497     $c->authenticate({ username => 'myusername',
 498                        password => 'mypassword' });
 499     my $age = $c->user->get('age');
 500     $c->logout;
 501
 502 =head1 DESCRIPTION
 503
 504 The authentication plugin provides generic user support for Catalyst apps. It
 505 is the basis for both authentication (checking the user is who they claim to
 506 be), and authorization (allowing the user to do what the system authorises
 507 them to do).
 508
 509 Using authentication is split into two parts. A Store is used to actually
 510 store the user information, and can store any amount of data related to the
 511 user. Credentials are used to verify users, using information from the store,
 512 given data from the frontend. A Credential and a Store are paired to form a
 513 'Realm'. A Catalyst application using the authentication framework must have
 514 at least one realm, and may have several.
 515
 516 To implement authentication in a Catalyst application you need to add this
 517 module, and specify at least one realm in the configuration.
 518
 519 Authentication data can also be stored in a session, if the application
 520 is using the L<Catalyst::Plugin::Session> module.
 521
 522 B<NOTE> in version 0.10 of this module, the interface to this module changed.
 523 Please see L</COMPATIBILITY ROUTINES> for more information.
 524
 525 =head1 INTRODUCTION
 526
 527 =head2 The Authentication/Authorization Process
 528
 529 Web applications typically need to identify a user - to tell the user apart
 530 from other users. This is usually done in order to display private information
 531 that is only that user's business, or to limit access to the application so
 532 that only certain entities can access certain parts.
 533
 534 This process is split up into several steps. First you ask the user to identify
 535 themselves. At this point you can't be sure that the user is really who they
 536 claim to be.
 537
 538 Then the user tells you who they are, and backs this claim with some piece of
 539 information that only the real user could give you. For example, a password is
 540 a secret that is known to both the user and you. When the user tells you this
 541 password you can assume they're in on the secret and can be trusted (ignore
 542 identity theft for now). Checking the password, or any other proof is called
 543 B<credential verification>.
 544
 545 By this time you know exactly who the user is - the user's identity is
 546 B<authenticated>. This is where this module's job stops, and your application
 547 or other plugins step in.
 548
 549 The next logical step is B<authorization>, the process of deciding what a user
 550 is (or isn't) allowed to do. For example, say your users are split into two
 551 main groups - regular users and administrators. You want to verify that the
 552 currently logged in user is indeed an administrator before performing the
 553 actions in an administrative part of your application. These decisions may be
 554 made within your application code using just the information available after
 555 authentication, or it may be facilitated by a number of plugins.
 556
 557 =head2 The Components In This Framework
 558
 559 =head3 Realms
 560
 561 Configuration of the Catalyst::Plugin::Authentication framework is done in
 562 terms of realms. In simplest terms, a realm is a pairing of a Credential
 563 verifier and a User storage (Store) backend. As of version 0.10003, realms are
 564 now objects that you can create and customize.
 565
 566 An application can have any number of Realms, each of which operates
 567 independent of the others. Each realm has a name, which is used to identify it
 568 as the target of an authentication request. This name can be anything, such as
 569 'users' or 'members'. One realm must be defined as the default_realm, which is
 570 used when no realm name is specified. More information about configuring
 571 realms is available in the configuration section.
 572
 573 =head3 Credential Verifiers
 574
 575 When user input is transferred to the L<Catalyst> application
 576 (typically via form inputs) the application may pass this information
 577 into the authentication system through the C<< $c->authenticate() >>
 578 method.  From there, it is passed to the appropriate Credential
 579 verifier.
 580
 581 These plugins check the data, and ensure that it really proves the user is who
 582 they claim to be.
 583
 584 Credential verifiers compatible with versions of this module 0.10x and
 585 upwards should be in the namespace
 586 C<Catalyst::Authentication::Credential>.
 587
 588 =head3 Storage Backends
 589
 590 The authentication data also identifies a user, and the Storage backend modules
 591 use this data to locate and return a standardized object-oriented
 592 representation of a user.
 593
 594 When a user is retrieved from a store it is not necessarily authenticated.
 595 Credential verifiers accept a set of authentication data and use this
 596 information to retrieve the user from the store they are paired with.
 597
 598 Storage backends compatible with versions of this module 0.10x and
 599 upwards should be in the namespace
 600 C<Catalyst::Authentication::Store>.
 601
 602 =head3 The Core Plugin
 603
 604 This plugin on its own is the glue, providing realm configuration, session
 605 integration, and other goodness for the other plugins.
 606
 607 =head3 Other Plugins
 608
 609 More layers of plugins can be stacked on top of the authentication code. For
 610 example, L<Catalyst::Plugin::Session::PerUser> provides an abstraction of
 611 browser sessions that is more persistent per user.
 612 L<Catalyst::Plugin::Authorization::Roles> provides an accepted way to separate
 613 and group users into categories, and then check which categories the current
 614 user belongs to.
 615
 616 =head1 EXAMPLE
 617
 618 Let's say we were storing users in a simple Perl hash. Users are
 619 verified by supplying a password which is matched within the hash.
 620
 621 This means that our application will begin like this:
 622
 623     package MyApp;
 624
 625     use Catalyst qw/
 626         Authentication
 627     /;
 628
 629     __PACKAGE__->config->{'Plugin::Authentication'} =
 630                 {
 631                     default => {
 632                         credential => {
 633                             class => 'Password',
 634                             password_field => 'password',
 635                             password_type => 'clear'
 636                         },
 637                         store => {
 638                             class => 'Minimal',
 639                                 users => {
 640                                     bob => {
 641                                         password => "s00p3r",
 642                                         editor => 'yes',
 643                                         roles => [qw/edit delete/],
 644                                     },
 645                                     william => {
 646                                         password => "s3cr3t",
 647                                         roles => [qw/comment/],
 648                                     }
 649                                 }
 650                             }
 651                         }
 652                 };
 653
 654 This tells the authentication plugin what realms are available, which
 655 credential and store modules are used, and the configuration of each. With
 656 this code loaded, we can now attempt to authenticate users.
 657
 658 To show an example of this, let's create an authentication controller:
 659
 660     package MyApp::Controller::Auth;
 661
 662     sub login : Local {
 663         my ( $self, $c ) = @_;
 664
 665         if (    my $user     = $c->req->params->{user}
 666             and my $password = $c->req->params->{password} )
 667         {
 668             if ( $c->authenticate( { username => $user,
 669                                      password => $password } ) ) {
 670                 $c->res->body( "hello " . $c->user->get("name") );
 671             } else {
 672                 # login incorrect
 673             }
 674         }
 675         else {
 676             # invalid form input
 677         }
 678     }
 679
 680 This code should be self-explanatory. If all the necessary fields are supplied,
 681 call the C<authenticate> method on the context object. If it succeeds the
 682 user is logged in.
 683
 684 The credential verifier will attempt to retrieve the user whose
 685 details match the authentication information provided to
 686 C<< $c->authenticate() >>. Once it fetches the user the password is
 687 checked and if it matches the user will be B<authenticated> and
 688 C<< $c->user >> will contain the user object retrieved from the store.
 689
 690 In the above case, the default realm is checked, but we could just as easily
 691 check an alternate realm. If this were an admin login, for example, we could
 692 authenticate on the admin realm by simply changing the C<< $c->authenticate() >>
 693 call:
 694
 695     if ( $c->authenticate( { username => $user,
 696                              password => $password }, 'admin' ) ) {
 697         $c->res->body( "hello " . $c->user->get("name") );
 698     } ...
 699
 700
 701 Now suppose we want to restrict the ability to edit to a user with an
 702 'editor' value of yes.
 703
 704 The restricted action might look like this:
 705
 706     sub edit : Local {
 707         my ( $self, $c ) = @_;
 708
 709         $c->detach("unauthorized")
 710           unless $c->user_exists
 711           and $c->user->get('editor') eq 'yes';
 712
 713         # do something restricted here
 714     }
 715
 716 (Note that if you have multiple realms, you can use
 717 C<< $c->user_in_realm('realmname') >> in place of
 718 C<< $c->user_exists(); >> This will essentially perform the same
 719 verification as user_exists, with the added requirement that if there
 720 is a user, it must have come from the realm specified.)
 721
 722 The above example is somewhat similar to role based access control.
 723 L<Catalyst::Authentication::Store::Minimal> treats the roles field as
 724 an array of role names. Let's leverage this. Add the role authorization
 725 plugin:
 726
 727     use Catalyst qw/
 728         ...
 729         Authorization::Roles
 730     /;
 731
 732     sub edit : Local {
 733         my ( $self, $c ) = @_;
 734
 735         $c->detach("unauthorized") unless $c->check_user_roles("edit");
 736
 737         # do something restricted here
 738     }
 739
 740 This is somewhat simpler and will work if you change your store, too, since the
 741 role interface is consistent.
 742
 743 Let's say your app grows, and you now have 10,000 users. It's no longer
 744 efficient to maintain a hash of users, so you move this data to a database.
 745 You can accomplish this simply by installing the L<DBIx::Class|Catalyst::Authentication::Store::DBIx::Class> Store and
 746 changing your config:
 747
 748     __PACKAGE__->config->{'Plugin::Authentication'} =
 749                     {
 750                         default_realm => 'members',
 751                         members => {
 752                             credential => {
 753                                 class => 'Password',
 754                                 password_field => 'password',
 755                                 password_type => 'clear'
 756                             },
 757                             store => {
 758                                 class => 'DBIx::Class',
 759                                     user_class => 'MyApp::Users',
 760                                     role_column => 'roles'
 761                                 }
 762                         }
 763                     };
 764
 765 The authentication system works behind the scenes to load your data from the
 766 new source. The rest of your application is completely unchanged.
 767
 768
 769 =head1 CONFIGURATION
 770
 771     # example
 772     __PACKAGE__->config->{'Plugin::Authentication'} =
 773                 {
 774                     default_realm => 'members',
 775
 776                     members => {
 777                         credential => {
 778                             class => 'Password',
 779                             password_field => 'password',
 780                             password_type => 'clear'
 781                         },
 782                         store => {
 783                             class => 'DBIx::Class',
 784                             user_class => 'MyApp::Users',
 785                             role_column => 'roles'
 786                         }
 787                         },
 788                         admins => {
 789                             credential => {
 790                                 class => 'Password',
 791                                 password_field => 'password',
 792                             password_type => 'clear'
 793                             },
 794                             store => {
 795                                 class => '+MyApp::Authentication::Store::NetAuth',
 796                                 authserver => '192.168.10.17'
 797                             }
 798                         }
 799                 };
 800
 801 NOTE: Until version 0.10008 of this module, you would need to put all the
 802 realms inside a "realms" key in the configuration. Please see
 803 L</COMPATIBILITY CONFIGURATION> for more information
 804
 805 =over 4
 806
 807 =item use_session
 808
 809 Whether or not to store the user's logged in state in the session, if the
 810 application is also using L<Catalyst::Plugin::Session>. This
 811 value is set to true per default.
 812
 813 =item default_realm
 814
 815 This defines which realm should be used as when no realm is provided to methods
 816 that require a realm such as authenticate or find_user.
 817
 818 =item realm refs
 819
 820 The Plugin::Authentication config hash contains the series of realm
 821 configurations you want to use for your app. The only rule here is
 822 that there must be at least one. A realm consists of a name, which is used
 823 to reference the realm, a credential and a store.  You may also put your
 824 realm configurations within a subelement called 'realms' if you desire to
 825 separate them from the remainder of your configuration.  Note that if you use
 826 a 'realms' subelement, you must put ALL of your realms within it.
 827
 828 You can also specify a realm class to instantiate instead of the default
 829 L<Catalyst::Authentication::Realm> class using the 'class' element within the
 830 realm config.
 831
 832 Each realm config contains two hashes, one called 'credential' and one called
 833 'store', each of which provide configuration details to the respective modules.
 834 The contents of these hashes is specific to the module being used, with the
 835 exception of the 'class' element, which tells the core Authentication module the
 836 classname to instantiate.
 837
 838 The 'class' element follows the standard Catalyst mechanism of class
 839 specification. If a class is prefixed with a +, it is assumed to be a complete
 840 class name. Otherwise it is considered to be a portion of the class name. For
 841 credentials, the classname 'B<Password>', for example, is expanded to
 842 Catalyst::Authentication::Credential::B<Password>. For stores, the
 843 classname 'B<storename>' is expanded to:
 844 Catalyst::Authentication::Store::B<storename>.
 845
 846 =back
 847
 848 =head1 METHODS
 849
 850 =head2 $c->authenticate( $userinfo [, $realm ])
 851
 852 Attempts to authenticate the user using the information in the $userinfo hash
 853 reference using the realm $realm. $realm may be omitted, in which case the
 854 default realm is checked.
 855
 856 =head2 $c->user( )
 857
 858 Returns the currently logged in user, or undef if there is none.
 859
 860 =head2 $c->user_exists( )
 861
 862 Returns true if a user is logged in right now. The difference between
 863 user_exists and user is that user_exists will return true if a user is logged
 864 in, even if it has not been yet retrieved from the storage backend. If you only
 865 need to know if the user is logged in, depending on the storage mechanism this
 866 can be much more efficient.
 867
 868 =head2 $c->user_in_realm( $realm )
 869
 870 Works like user_exists, except that it only returns true if a user is both
 871 logged in right now and was retrieved from the realm provided.
 872
 873 =head2 $c->logout( )
 874
 875 Logs the user out. Deletes the currently logged in user from C<< $c->user >> and the session.
 876
 877 =head2 $c->find_user( $userinfo, $realm )
 878
 879 Fetch a particular users details, matching the provided user info, from the realm
 880 specified in $realm.
 881
 882 =head2 persist_user()
 883
 884 Under normal circumstances the user data is only saved to the session during
 885 initial authentication.  This call causes the auth system to save the
 886 currently authenticated user's data across requests.  Useful if you have
 887 changed the user data and want to ensure that future requests reflect the
 888 most current data.  Assumes that at the time of this call, $c->user
 889 contains the most current data.
 890
 891 =head2 find_realm_for_persisted_user()
 892
 893 Private method, do not call from user code!
 894
 895 =head1 INTERNAL METHODS
 896
 897 These methods are for Catalyst::Plugin::Authentication B<INTERNAL USE> only.
 898 Please do not use them in your own code, whether application or credential /
 899 store modules. If you do, you will very likely get the nasty shock of having
 900 to fix / rewrite your code when things change. They are documented here only
 901 for reference.
 902
 903 =head2 $c->set_authenticated( $user, $realmname )
 904
 905 Marks a user as authenticated. This is called from within the authenticate
 906 routine when a credential returns a user. $realmname defaults to 'default'
 907
 908 =head2 $c->auth_restore_user( $user, $realmname )
 909
 910 Used to restore a user from the session. In most cases this is called without
 911 arguments to restore the user via the session. Can be called with arguments
 912 when restoring a user from some other method.  Currently not used in this way.
 913
 914 =head2 $c->auth_realms( )
 915
 916 Returns a hashref containing realmname -> realm instance pairs. Realm
 917 instances contain an instantiated store and credential object as the 'store'
 918 and 'credential' elements, respectively
 919
 920 =head2 $c->get_auth_realm( $realmname )
 921
 922 Retrieves the realm instance for the realmname provided.
 923
 924 =head2 $c->update_user_in_session
 925
 926 This was a short-lived method to update user information - you should use persist_user instead.
 927
 928 =head2 $c->setup_auth_realm( )
 929
 930 =head1 OVERRIDDEN METHODS
 931
 932 =head2 $c->setup( )
 933
 934 =head1 SEE ALSO
 935
 936 This list might not be up to date.  Below are modules known to work with the updated
 937 API of 0.10 and are therefore compatible with realms.
 938
 939 =head2 Realms
 940
 941 L<Catalyst::Authentication::Realm>
 942
 943 =head2 User Storage Backends
 944
 945 =over
 946
 947 =item L<Catalyst::Authentication::Store::Minimal>
 948
 949 =item L<Catalyst::Authentication::Store::DBIx::Class>
 950
 951 =item L<Catalyst::Authentication::Store::LDAP>
 952
 953 =item L<Catalyst::Authentication::Store::RDBO>
 954
 955 =item L<Catalyst::Authentication::Store::Model::KiokuDB>
 956
 957 =item L<Catalyst::Authentication::Store::Jifty::DBI>
 958
 959 =item L<Catalyst::Authentication::Store::Htpasswd>
 960
 961 =back
 962
 963 =head2 Credential verification
 964
 965 =over
 966
 967 =item L<Catalyst::Authentication::Credential::Password>
 968
 969 =item L<Catalyst::Authentication::Credential::HTTP>
 970
 971 =item L<Catalyst::Authentication::Credential::OpenID>
 972
 973 =item L<Catalyst::Authentication::Credential::Authen::Simple>
 974
 975 =item L<Catalyst::Authentication::Credential::Flickr>
 976
 977 =item L<Catalyst::Authentication::Credential::Testing>
 978
 979 =item L<Catalyst::Authentication::Credential::AuthTkt>
 980
 981 =item L<Catalyst::Authentication::Credential::Kerberos>
 982
 983 =head2 Authorization
 984
 985 L<Catalyst::Plugin::Authorization::ACL>,
 986 L<Catalyst::Plugin::Authorization::Roles>
 987
 988 =head2 Internals Documentation
 989
 990 L<Catalyst::Plugin::Authentication::Internals>
 991
 992 =head2 Misc
 993
 994 L<Catalyst::Plugin::Session>,
 995 L<Catalyst::Plugin::Session::PerUser>
 996
 997 =head1 DON'T SEE ALSO
 998
 999 This module along with its sub plugins deprecate a great number of other
1000 modules. These include L<Catalyst::Plugin::Authentication::Simple>,
1001 L<Catalyst::Plugin::Authentication::CDBI>.
1002
1003 =head1 INCOMPATABILITIES
1004
1005 The realms-based configuration and functionality of the 0.10 update
1006 of L<Catalyst::Plugin::Authentication> required a change in the API used by
1007 credentials and stores.  It has a compatibility mode which allows use of
1008 modules that have not yet been updated. This, however, completely mimics the
1009 older api and disables the new realm-based features. In other words you cannot
1010 mix the older credential and store modules with realms, or realm-based
1011 configs. The changes required to update modules are relatively minor and are
1012 covered in L<Catalyst::Plugin::Authentication::Internals>.  We hope that most
1013 modules will move to the compatible list above very quickly.
1014
1015 =head1 COMPATIBILITY CONFIGURATION
1016
1017 Until version 0.10008 of this module, you needed to put all the
1018 realms inside a "realms" key in the configuration.
1019
1020     # example
1021     __PACKAGE__->config->{'Plugin::Authentication'} =
1022                 {
1023                     default_realm => 'members',
1024                     realms => {
1025                         members => {
1026                             ...
1027                         },
1028                     },
1029                 };
1030
1031 If you use the old, deprecated C<< __PACKAGE__->config->{'authentication'} >>
1032 configuration key, then the realms key is still required.
1033
1034 =head1 COMPATIBILITY ROUTINES
1035
1036 In version 0.10 of L<Catalyst::Plugin::Authentication>, the API
1037 changed. For app developers, this change is fairly minor, but for
1038 Credential and Store authors, the changes are significant.
1039
1040 Please see the documentation in version 0.09 of
1041 Catalyst::Plugin::Authentication for a better understanding of how the old API
1042 functioned.
1043
1044 The items below are still present in the plugin, though using them is
1045 deprecated. They remain only as a transition tool, for those sites which can
1046 not yet be upgraded to use the new system due to local customizations or use
1047 of Credential / Store modules that have not yet been updated to work with the
1048 new API.
1049
1050 These routines should not be used in any application using realms
1051 functionality or any of the methods described above. These are for reference
1052 purposes only.
1053
1054 =head2 $c->login( )
1055
1056 This method is used to initiate authentication and user retrieval. Technically
1057 this is part of the old Password credential module and it still resides in the
1058 L<Password|Catalyst::Plugin::Authentication::Credential::Password> class. It is
1059 included here for reference only.
1060
1061 =head2 $c->default_auth_store( )
1062
1063 Return the store whose name is 'default'.
1064
1065 This is set to C<< $c->config->{'Plugin::Authentication'}{store} >> if that value exists,
1066 or by using a Store plugin:
1067
1068     # load the Minimal authentication store.
1069         use Catalyst qw/Authentication Authentication::Store::Minimal/;
1070
1071 Sets the default store to
1072 L<Catalyst::Plugin::Authentication::Store::Minimal>.
1073
1074 =head2 $c->get_auth_store( $name )
1075
1076 Return the store whose name is $name.
1077
1078 =head2 $c->get_auth_store_name( $store )
1079
1080 Return the name of the store $store.
1081
1082 =head2 $c->auth_stores( )
1083
1084 A hash keyed by name, with the stores registered in the app.
1085
1086 =head2 $c->register_auth_stores( %stores_by_name )
1087
1088 Register stores into the application.
1089
1090 =head2 $c->auth_store_names( )
1091
1092 =head2 $c->get_user( )
1093
1094 =head1 AUTHORS
1095
1096 Yuval Kogman, C<nothingmuch@woobling.org>
1097
1098 Jay Kuri, C<jayk@cpan.org>
1099
1100 Jess Robinson
1101
1102 David Kamholz
1103
1104 Tomas Doran (t0m), C<bobtfish@bobtfish.net>
1105
1106 =head1 COPYRIGHT & LICENSE
1107
1108         Copyright (c) 2005 the aforementioned authors. All rights
1109         reserved. This program is free software; you can redistribute
1110         it and/or modify it under the same terms as Perl itself.
1111
1112 =cut
1113