lib/Catalyst/TraitFor/Model/DBIC/Schema/Replicated.pm

   1 package Catalyst::TraitFor::Model::DBIC::Schema::Replicated;
   2
   3 use namespace::autoclean;
   4 use Moose::Role;
   5 use Carp::Clan '^Catalyst::Model::DBIC::Schema';
   6
   7 use Catalyst::Model::DBIC::Schema::Types qw/ConnectInfos LoadedClass/;
   8 use MooseX::Types::Moose qw/Str HashRef/;
   9
  10 =head1 NAME
  11
  12 Catalyst::TraitFor::Model::DBIC::Schema::Replicated - Replicated storage support for
  13 L<Catalyst::Model::DBIC::Schema>
  14
  15 =head1 SYNOPSiS
  16
  17     __PACKAGE__->config({
  18         traits => ['Replicated']
  19         connect_info =>
  20             ['dbi:mysql:master', 'user', 'pass'],
  21         replicants => [
  22             ['dbi:mysql:slave1', 'user', 'pass'],
  23             ['dbi:mysql:slave2', 'user', 'pass'],
  24             ['dbi:mysql:slave3', 'user', 'pass'],
  25         ],
  26         balancer_args => {
  27           master_read_weight => 0.3
  28         }
  29     });
  30
  31 =head1 DESCRIPTION
  32
  33 Sets your storage_type to L<DBIx::Class::Storage::DBI::Replicated> and connects
  34 replicants provided in config. See that module for supported resultset
  35 attributes.
  36
  37 The default L<DBIx::Class::Storage::DBI::Replicated/balancer_type> is
  38 C<::Random>.
  39
  40 Sets the
  41 L<DBIx::Class::Storage::DBI::Replicated::Balancer::Random/master_read_weight> to
  42 C<1> by default, meaning that you have the same chance of reading from master as
  43 you do from replicants. Set to C<0> to turn off reads from master.
  44
  45 =head1 CONFIG PARAMETERS
  46
  47 =head2 replicants
  48
  49 Array of connect_info settings for every replicant.
  50
  51 The following can be set via L<Catalyst::Model::DBIC::Schema/connect_info>, or
  52 as their own parameters. If set via separate parameters, they will override the
  53 settings in C<connect_info>.
  54
  55 =head2 pool_type
  56
  57 See L<DBIx::Class::Storage::DBI::Replicated/pool_type>.
  58
  59 =head2 pool_args
  60
  61 See L<DBIx::Class::Storage::DBI::Replicated/pool_args>.
  62
  63 =head2 balancer_type
  64
  65 See L<DBIx::Class::Storage::DBI::Replicated/balancer_type>.
  66
  67 =head2 balancer_args
  68
  69 See L<DBIx::Class::Storage::DBI::Replicated/balancer_args>.
  70
  71 =cut
  72
  73 has replicants => (
  74     is => 'ro', isa => ConnectInfos, coerce => 1, required => 1
  75 );
  76
  77 has pool_type => (is => 'ro', isa => LoadedClass);
  78 has pool_args => (is => 'ro', isa => HashRef);
  79 has balancer_type => (is => 'ro', isa => Str);
  80 has balancer_args => (is => 'ro', isa => HashRef);
  81
  82 after setup => sub {
  83     my $self = shift;
  84
  85 # check storage_type compatibility (if configured)
  86     if (my $storage_type = $self->storage_type) {
  87         my $class = $storage_type =~ /^::/ ?
  88             "DBIx::Class::Storage$storage_type"
  89             : $storage_type;
  90
  91         croak "This storage_type cannot be used with replication"
  92             unless $class->isa('DBIx::Class::Storage::DBI::Replicated');
  93     } else {
  94         $self->storage_type('::DBI::Replicated');
  95     }
  96
  97     my $connect_info = $self->connect_info;
  98
  99     $connect_info->{pool_type} = $self->pool_type
 100         if $self->pool_type;
 101
 102     $connect_info->{pool_args} = $self->pool_args
 103         if $self->pool_args;
 104
 105     $connect_info->{balancer_type} = $self->balancer_type ||
 106         $connect_info->{balancer_type} || '::Random';
 107
 108     $connect_info->{balancer_args} = $self->balancer_args ||
 109         $connect_info->{balancer_args} || {};
 110
 111     $connect_info->{balancer_args}{master_read_weight} = 1
 112         unless exists $connect_info->{balancer_args}{master_read_weight};
 113 };
 114
 115 sub BUILD {}
 116
 117 after BUILD => sub {
 118     my $self = shift;
 119
 120     $self->storage->connect_replicants(map [ $_ ], @{ $self->replicants });
 121 };
 122
 123 =head1 SEE ALSO
 124
 125 L<Catalyst::Model::DBIC::Schema>, L<DBIx::Class>,
 126 L<DBIx::Class::Storage::DBI::Replicated>,
 127 L<Catalyst::TraitFor::Model::DBIC::Schema::Caching>
 128
 129 =head1 AUTHOR
 130
 131 Rafael Kitover, C<rkitover at cpan.org>
 132
 133 =head1 COPYRIGHT
 134
 135 This program is free software, you can redistribute it and/or modify it
 136 under the same terms as Perl itself.
 137
 138 =cut
 139
 140 1;