lib/Catalyst/Model/DBIC/Schema.pm

   1 package Catalyst::Model::DBIC::Schema;
   2
   3 use strict;
   4 use base qw/Catalyst::Model Class::Accessor::Fast Class::Data::Accessor/;
   5 use NEXT;
   6 use UNIVERSAL::require;
   7 use Carp;
   8
   9 our $VERSION = '0.01';
  10
  11 __PACKAGE__->mk_classaccessor('composed_schema');
  12 __PACKAGE__->mk_accessors('schema');
  13
  14 =head1 NAME
  15
  16 Catalyst::Model::DBIC::Schema - DBIx::Class::Schema Model Class
  17
  18 =head1 SYNOPSIS
  19
  20     package MyApp::Model::Foo;
  21     use strict;
  22     use base 'Catalyst::Model::DBIC::Schema';
  23
  24     __PACKAGE__->config(
  25         schema_class => 'Foo::SchemaClass',
  26         connect_info => [ 'dbi:Pg:dbname=foodb',
  27                           'postgres',
  28                           '',
  29                           { AutoCommit => 1 },
  30                         ],
  31     );
  32
  33     1;
  34
  35     # In controller code:
  36
  37     # ->schema To access schema methods:
  38     $c->model('Foo')->schema->source(...);
  39
  40     # certain ->schema methods (source, resultset, class) have shortcuts
  41     $c->model('Foo')->source(...);
  42     $c->model('Foo')->resultset(...);
  43     $c->model('Foo')->class(...);
  44
  45     # For resultsets, there's an even quicker shortcut:
  46     $c->model('Foo::Bar')
  47     # is the same as $c->model('Foo')->resultset('Bar')
  48
  49     # To get the composed schema for making new connections:
  50     my $newconn = $c->model('Foo')->composed_schema->connect(...);
  51
  52     # Or the same thing via a convenience shortcut:
  53     my $newconn = $c->model('Foo')->connect(...);
  54
  55     # or, if your schema works on different storage drivers:
  56     my $newconn = $c->model('Foo')->composed_schema->clone();
  57     $newconn->storage_type('::LDAP');
  58     $newconn->connect(...);
  59
  60     # and again, a convenience shortcut
  61     my $newconn = $c->model('Foo')->clone();
  62     $newconn->storage_type('::LDAP');
  63     $newconn->connect(...);
  64
  65 =head1 DESCRIPTION
  66
  67 This is a Catalyst Model for L<DBIx::Class::Schema>-based Models.
  68
  69 =head1 CONFIG PARAMETERS
  70
  71 =over 4
  72
  73 =item schema_class
  74
  75 This is the classname of your L<DBIx::Class::Schema> Schema.  It needs
  76 to be findable in C<@INC>, but it does not need to be underneath
  77 C<Catalyst::Model::>.  This parameter is required.
  78
  79 =item connect_info
  80
  81 This is an arrayref of connection parameters, which are specific to your
  82 C<storage_type>.  For C<::DBI>, which is the only supported C<storage_type>
  83 in L<DBIx::Class> at the time of this writing, the 4 parameters are your
  84 dsn, username, password, and connect options hashref.
  85
  86 This is not required if C<schema_class> already has connection information
  87 defined in itself (which would be the case for a Schema defined by
  88 L<DBIx::Class::Schema::Loader>, for instance).
  89
  90 =item storage_type
  91
  92 Allows the use of a different C<storage_type> than what is set in your
  93 C<schema_class> (which in turn defaults to C<::DBI> if not set in current
  94 L<DBIx::Class>).  Completely optional, and probably unneccesary for most
  95 people, until other storage backends become available for L<DBIx::Class>.
  96
  97 =back
  98
  99 =head1 METHODS
 100
 101 =over 4
 102
 103 =item new
 104
 105 Instantiates the Model based on the above-documented ->config parameters.
 106 The only required parameter is C<schema_class>.  C<connect_info> is
 107 required in the case that C<schema_class> does not already have connection
 108 information defined for it.
 109
 110 =item schema
 111
 112 Accessor which returns the connected schema being used by the this model.
 113 There are already direct shortcuts on the model class itself for
 114 schema->resultset, schema->source, and schema->class.
 115
 116 =item composed_schema
 117
 118 Accessor which returns the composed schema, which has no connection info,
 119 which was used in constructing the C<schema> above.  Useful for creating
 120 new connections based on the same schema/model.  There are direct shortcuts
 121 from the model object for composed_schema->clone and composed_schema->connect
 122
 123 =item clone
 124
 125 Shortcut for ->composed_schema->clone
 126
 127 =item connect
 128
 129 Shortcut for ->composed_schema->connect
 130
 131 =item source
 132
 133 Shortcut for ->schema->source
 134
 135 =item class
 136
 137 Shortcut for ->schema->class
 138
 139 =item resultset
 140
 141 Shortcut for ->schema->resultset
 142
 143 =back
 144
 145 =cut
 146
 147 sub new {
 148     my ( $self, $c ) = @_;
 149     $self = $self->NEXT::new($c);
 150
 151     my $class = ref($self);
 152     my $model_name = $class;
 153     $model_name =~ s/^[\w:]+::(?:Model|M):://;
 154
 155     croak "->config->{schema_class} must be defined for this model"
 156         unless $self->{schema_class};
 157
 158     my $schema_class = $self->{schema_class};
 159
 160     $schema_class->require
 161         or croak "Cannot load schema class '$schema_class': $@";
 162
 163     if( !$self->{connect_info} ) {
 164         if($schema_class->storage && $schema_class->storage->connect_info) {
 165             $self->{connect_info} = $schema_class->storage->connect_info;
 166         }
 167         else {
 168             croak "Either ->config->{connect_info} must be defined for $class"
 169                   . " or $schema_class must have connection defined on it";
 170         }
 171     }
 172
 173     $self->composed_schema($schema_class->compose_namespace($class));
 174     $self->schema($self->composed_schema->clone);
 175     $self->schema->storage_type($self->{storage_type}) if $self->{storage_type};
 176     $self->schema->connect(@{$self->{connect_info}});
 177
 178     no strict 'refs';
 179     foreach my $moniker ($self->schema->sources) {
 180         *{"${class}::${moniker}::ACCEPT_CONTEXT"} = sub {
 181             shift;
 182             shift->model($model_name)->resultset($moniker);
 183         }
 184     }
 185
 186     return $self;
 187 }
 188
 189 sub clone { shift->composed_schema->clone(@_); }
 190
 191 sub connect { shift->composed_schema->connect(@_); }
 192
 193 =head1 SEE ALSO
 194
 195 L<Catalyst>, L<DBIx::Class>, L<DBIx::Class::Schema>,
 196 L<DBIx::Class::Schema::Loader>
 197
 198 =head1 AUTHOR
 199
 200 Brandon L Black, C<blblack@gmail.com>
 201
 202 =head1 COPYRIGHT
 203
 204 This program is free software, you can redistribute it and/or modify it
 205 under the same terms as Perl itself.
 206
 207 =cut
 208
 209 1;