lib/Catalyst/Model/DBIC/Schema.pm

   1 package Catalyst::Model::DBIC::Schema;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION = '0.20';
   7
   8 use base qw/Catalyst::Model Class::Accessor::Fast Class::Data::Accessor/;
   9 use NEXT;
  10 use UNIVERSAL::require;
  11 use Carp;
  12 use Data::Dumper;
  13 require DBIx::Class;
  14
  15 __PACKAGE__->mk_classaccessor('composed_schema');
  16 __PACKAGE__->mk_accessors('schema');
  17
  18 =head1 NAME
  19
  20 Catalyst::Model::DBIC::Schema - DBIx::Class::Schema Model Class
  21
  22 =head1 SYNOPSIS
  23
  24 Manual creation of a DBIx::Class::Schema and a Catalyst::Model::DBIC::Schema:
  25
  26 =over
  27
  28 =item 1.
  29
  30 Create the DBIx:Class schema in MyApp/Schema/FilmDB.pm:
  31
  32   package MyApp::Schema::FilmDB;
  33   use base qw/DBIx::Class::Schema/;
  34
  35   __PACKAGE__->load_classes(qw/Actor Role/);
  36
  37 =item 2.
  38
  39 Create some classes for the tables in the database, for example an
  40 Actor in MyApp/Schema/FilmDB/Actor.pm:
  41
  42   package MyApp::Schema::FilmDB::Actor;
  43   use base qw/DBIx::Class/
  44
  45   __PACKAGE__->load_components(qw/Core/);
  46   __PACKAGE__->table('actor');
  47
  48   ...
  49
  50 and a Role in MyApp/Schema/Role.pm:
  51
  52   package MyApp::Schema::FilmDB::Role;
  53   use base qw/DBIx::Class/
  54
  55   __PACKAGE__->load_components(qw/Core/);
  56   __PACKAGE__->table('role');
  57
  58   ...
  59
  60 Notice that the schema is in MyApp::Schema, not in MyApp::Model. This way it's
  61 usable as a standalone module and you can test/run it without Catalyst.
  62
  63 =item 3.
  64
  65 To expose it to Catalyst as a model, you should create a DBIC Model in
  66 MyApp/Model/FilmDB.pm:
  67
  68   package MyApp::Model::FilmDB;
  69   use base qw/Catalyst::Model::DBIC::Schema/;
  70
  71   __PACKAGE__->config(
  72       schema_class => 'MyApp::Schema::FilmDB',
  73       connect_info => [
  74                         "DBI:...",
  75                         "username",
  76                         "password",
  77                         {AutoCommit => 1}
  78                       ]
  79   );
  80
  81 See below for a full list of the possible config parameters.
  82
  83 =back
  84
  85 Now you have a working Model, accessing your separate DBIC Schema. Which can
  86 be used/accessed in the normal Catalyst manner, via $c->model():
  87
  88   my $actor = $c->model('FilmDB::Actor')->find(1);
  89
  90 You can also use it to set up DBIC authentication with
  91 Authentication::Store::DBIC in MyApp.pm:
  92
  93   package MyApp;
  94
  95   use Catalyst qw/... Authentication::Store::DBIC/;
  96
  97   ...
  98
  99   __PACKAGE__->config->{authentication}{dbic} = {
 100       user_class      => 'FilmDB::Actor',
 101       user_field      => 'name',
 102       password_field  => 'password'
 103   }
 104
 105 C<< $c->model() >> returns a L<DBIx::Class::ResultSet> for the source name
 106 parameter passed. To find out more about which methods can be called on a
 107 ResultSet, or how to add your own methods to it, please see the ResultSet
 108 documentation in the L<DBIx::Class> distribution.
 109
 110 Some examples are given below:
 111
 112   # to access schema methods directly:
 113   $c->model('FilmDB')->schema->source(...);
 114
 115   # to access the source object, resultset, and class:
 116   $c->model('FilmDB')->source(...);
 117   $c->model('FilmDB')->resultset(...);
 118   $c->model('FilmDB')->class(...);
 119
 120   # For resultsets, there's an even quicker shortcut:
 121   $c->model('FilmDB::Actor')
 122   # is the same as $c->model('FilmDB')->resultset('Actor')
 123
 124   # To get the composed schema for making new connections:
 125   my $newconn = $c->model('FilmDB')->composed_schema->connect(...);
 126
 127   # Or the same thing via a convenience shortcut:
 128   my $newconn = $c->model('FilmDB')->connect(...);
 129
 130   # or, if your schema works on different storage drivers:
 131   my $newconn = $c->model('FilmDB')->composed_schema->clone();
 132   $newconn->storage_type('::LDAP');
 133   $newconn->connection(...);
 134
 135   # and again, a convenience shortcut
 136   my $newconn = $c->model('FilmDB')->clone();
 137   $newconn->storage_type('::LDAP');
 138   $newconn->connection(...);
 139
 140 =head1 DESCRIPTION
 141
 142 This is a Catalyst Model for L<DBIx::Class::Schema>-based Models.  See
 143 the documentation for L<Catalyst::Helper::Model::DBIC::Schema> for
 144 information on generating these Models via Helper scripts.
 145
 146 =head1 CONFIG PARAMETERS
 147
 148 =over 4
 149
 150 =item schema_class
 151
 152 This is the classname of your L<DBIx::Class::Schema> Schema.  It needs
 153 to be findable in C<@INC>, but it does not need to be inside the
 154 C<Catalyst::Model::> namespace.  This parameter is required.
 155
 156 =item connect_info
 157
 158 This is an arrayref of connection parameters, which are specific to your
 159 C<storage_type> (see your storage type documentation for more details).
 160
 161 This is not required if C<schema_class> already has connection information
 162 defined inside itself (which isn't highly recommended, but can be done)
 163
 164 For L<DBIx::Class::Storage::DBI>, which is the only supported
 165 C<storage_type> in L<DBIx::Class> at the time of this writing, the
 166 parameters are your dsn, username, password, and connect options hashref.
 167
 168 See L<DBIx::Class::Storage::DBI/connect_info> for a detailed explanation
 169 of the arguments supported.
 170
 171 Examples:
 172
 173   connect_info => [ 'dbi:Pg:dbname=mypgdb', 'postgres', '' ],
 174
 175   connect_info => [
 176                     'dbi:SQLite:dbname=foo.db',
 177                     {
 178                       on_connect_do => [
 179                         'PRAGMA synchronous = OFF',
 180                       ],
 181                     }
 182                   ],
 183
 184   connect_info => [
 185                     'dbi:Pg:dbname=mypgdb',
 186                     'postgres',
 187                     '',
 188                     { AutoCommit => 0 },
 189                     {
 190                       on_connect_do => [
 191                         'some SQL statement',
 192                         'another SQL statement',
 193                       ],
 194                     }
 195                   ],
 196
 197 =item storage_type
 198
 199 Allows the use of a different C<storage_type> than what is set in your
 200 C<schema_class> (which in turn defaults to C<::DBI> if not set in current
 201 L<DBIx::Class>).  Completely optional, and probably unnecessary for most
 202 people until other storage backends become available for L<DBIx::Class>.
 203
 204 =back
 205
 206 =head1 METHODS
 207
 208 =over 4
 209
 210 =item new
 211
 212 Instantiates the Model based on the above-documented ->config parameters.
 213 The only required parameter is C<schema_class>.  C<connect_info> is
 214 required in the case that C<schema_class> does not already have connection
 215 information defined for it.
 216
 217 =item schema
 218
 219 Accessor which returns the connected schema being used by the this model.
 220 There are direct shortcuts on the model class itself for
 221 schema->resultset, schema->source, and schema->class.
 222
 223 =item composed_schema
 224
 225 Accessor which returns the composed schema, which has no connection info,
 226 which was used in constructing the C<schema> above.  Useful for creating
 227 new connections based on the same schema/model.  There are direct shortcuts
 228 from the model object for composed_schema->clone and composed_schema->connect
 229
 230 =item clone
 231
 232 Shortcut for ->composed_schema->clone
 233
 234 =item connect
 235
 236 Shortcut for ->composed_schema->connect
 237
 238 =item source
 239
 240 Shortcut for ->schema->source
 241
 242 =item class
 243
 244 Shortcut for ->schema->class
 245
 246 =item resultset
 247
 248 Shortcut for ->schema->resultset
 249
 250 =item storage
 251
 252 Provides an accessor for the connected schema's storage object.
 253 Used often for debugging and controlling transactions.
 254
 255 =back
 256
 257 =cut
 258
 259 sub new {
 260     my $self = shift->NEXT::new(@_);
 261
 262     my $class = ref($self);
 263     my $model_name = $class;
 264     $model_name =~ s/^[\w:]+::(?:Model|M):://;
 265
 266     croak "->config->{schema_class} must be defined for this model"
 267         unless $self->{schema_class};
 268
 269     my $schema_class = $self->{schema_class};
 270
 271     $schema_class->require
 272         or croak "Cannot load schema class '$schema_class': $@";
 273
 274     if( !$self->{connect_info} ) {
 275         if($schema_class->storage && $schema_class->storage->connect_info) {
 276             $self->{connect_info} = $schema_class->storage->connect_info;
 277         }
 278         else {
 279             croak "Either ->config->{connect_info} must be defined for $class"
 280                   . " or $schema_class must have connect info defined on it"
 281                   . "Here's what we got:\n"
 282                   . Dumper($self);
 283         }
 284     }
 285
 286     $self->composed_schema($schema_class->compose_namespace($class));
 287     $self->schema($self->composed_schema->clone);
 288
 289     $self->schema->storage_type($self->{storage_type})
 290         if $self->{storage_type};
 291
 292     $self->schema->connection(@{$self->{connect_info}});
 293
 294     no strict 'refs';
 295     foreach my $moniker ($self->schema->sources) {
 296         my $classname = "${class}::$moniker";
 297         *{"${classname}::ACCEPT_CONTEXT"} = sub {
 298             shift;
 299             shift->model($model_name)->resultset($moniker);
 300         }
 301     }
 302
 303     return $self;
 304 }
 305
 306 sub clone { shift->composed_schema->clone(@_); }
 307
 308 sub connect { shift->composed_schema->connect(@_); }
 309
 310 sub storage { shift->schema->storage(@_); }
 311
 312 =head1 SEE ALSO
 313
 314 General Catalyst Stuff:
 315
 316 L<Catalyst::Manual>, L<Catalyst::Test>, L<Catalyst::Request>,
 317 L<Catalyst::Response>, L<Catalyst::Helper>, L<Catalyst>,
 318
 319 Stuff related to DBIC and this Model style:
 320
 321 L<DBIx::Class>, L<DBIx::Class::Schema>,
 322 L<DBIx::Class::Schema::Loader>, L<Catalyst::Helper::Model::DBIC::Schema>
 323
 324 =head1 AUTHOR
 325
 326 Brandon L Black, C<blblack@gmail.com>
 327
 328 =head1 COPYRIGHT
 329
 330 This program is free software, you can redistribute it and/or modify it
 331 under the same terms as Perl itself.
 332
 333 =cut
 334
 335 1;