lib/Catalyst/Model/DBIC/Schema.pm

   1 package Catalyst::Model::DBIC::Schema;
   2
   3 use Moose;
   4 use mro 'c3';
   5 extends 'Catalyst::Model';
   6 with 'CatalystX::Component::Traits';
   7
   8 our $VERSION = '0.29';
   9 $VERSION = eval $VERSION;
  10
  11 use namespace::autoclean;
  12 use Carp::Clan '^Catalyst::Model::DBIC::Schema';
  13 use Data::Dumper;
  14 use DBIx::Class ();
  15
  16 use Catalyst::Model::DBIC::Schema::Types
  17     qw/ConnectInfo LoadedClass SchemaClass/;
  18
  19 use MooseX::Types::Moose qw/ArrayRef Str ClassName Undef/;
  20
  21 =head1 NAME
  22
  23 Catalyst::Model::DBIC::Schema - DBIx::Class::Schema Model Class
  24
  25 =head1 SYNOPSIS
  26
  27 Manual creation of a DBIx::Class::Schema and a Catalyst::Model::DBIC::Schema:
  28
  29 =over
  30
  31 =item 1.
  32
  33 Create the DBIx:Class schema in MyApp/Schema/FilmDB.pm:
  34
  35   package MyApp::Schema::FilmDB;
  36   use base qw/DBIx::Class::Schema/;
  37
  38   __PACKAGE__->load_classes(qw/Actor Role/);
  39
  40 =item 2.
  41
  42 Create some classes for the tables in the database, for example an
  43 Actor in MyApp/Schema/FilmDB/Actor.pm:
  44
  45   package MyApp::Schema::FilmDB::Actor;
  46   use base qw/DBIx::Class/
  47
  48   __PACKAGE__->load_components(qw/Core/);
  49   __PACKAGE__->table('actor');
  50
  51   ...
  52
  53 and a Role in MyApp/Schema/FilmDB/Role.pm:
  54
  55   package MyApp::Schema::FilmDB::Role;
  56   use base qw/DBIx::Class/
  57
  58   __PACKAGE__->load_components(qw/Core/);
  59   __PACKAGE__->table('role');
  60
  61   ...
  62
  63 Notice that the schema is in MyApp::Schema, not in MyApp::Model. This way it's
  64 usable as a standalone module and you can test/run it without Catalyst.
  65
  66 =item 3.
  67
  68 To expose it to Catalyst as a model, you should create a DBIC Model in
  69 MyApp/Model/FilmDB.pm:
  70
  71   package MyApp::Model::FilmDB;
  72   use base qw/Catalyst::Model::DBIC::Schema/;
  73
  74   __PACKAGE__->config(
  75       schema_class => 'MyApp::Schema::FilmDB',
  76       connect_info => {
  77                         dsn => "DBI:...",
  78                         user => "username",
  79                         password => "password",
  80                       }
  81   );
  82
  83 See below for a full list of the possible config parameters.
  84
  85 =back
  86
  87 Now you have a working Model which accesses your separate DBIC Schema. This can
  88 be used/accessed in the normal Catalyst manner, via $c->model():
  89
  90   my $actor = $c->model('FilmDB::Actor')->find(1);
  91
  92 You can also use it to set up DBIC authentication with
  93 L<Catalyst::Authentication::Store::DBIx::Class> in MyApp.pm:
  94
  95   package MyApp;
  96
  97   use Catalyst qw/... Authentication .../;
  98
  99   ...
 100
 101   __PACKAGE__->config->{authentication} =
 102                 {
 103                     default_realm => 'members',
 104                     realms => {
 105                         members => {
 106                             credential => {
 107                                 class => 'Password',
 108                                 password_field => 'password',
 109                                 password_type => 'hashed'
 110                                 password_hash_type => 'SHA-256'
 111                             },
 112                             store => {
 113                                 class => 'DBIx::Class',
 114                                 user_model => 'DB::User',
 115                                 role_relation => 'roles',
 116                                 role_field => 'rolename',
 117                             }
 118                         }
 119                     }
 120                 };
 121
 122 C<< $c->model('Schema::Source') >> returns a L<DBIx::Class::ResultSet> for
 123 the source name parameter passed. To find out more about which methods can
 124 be called on a ResultSet, or how to add your own methods to it, please see
 125 the ResultSet documentation in the L<DBIx::Class> distribution.
 126
 127 Some examples are given below:
 128
 129   # to access schema methods directly:
 130   $c->model('FilmDB')->schema->source(...);
 131
 132   # to access the source object, resultset, and class:
 133   $c->model('FilmDB')->source(...);
 134   $c->model('FilmDB')->resultset(...);
 135   $c->model('FilmDB')->class(...);
 136
 137   # For resultsets, there's an even quicker shortcut:
 138   $c->model('FilmDB::Actor')
 139   # is the same as $c->model('FilmDB')->resultset('Actor')
 140
 141   # To get the composed schema for making new connections:
 142   my $newconn = $c->model('FilmDB')->composed_schema->connect(...);
 143
 144   # Or the same thing via a convenience shortcut:
 145   my $newconn = $c->model('FilmDB')->connect(...);
 146
 147   # or, if your schema works on different storage drivers:
 148   my $newconn = $c->model('FilmDB')->composed_schema->clone();
 149   $newconn->storage_type('::LDAP');
 150   $newconn->connection(...);
 151
 152   # and again, a convenience shortcut
 153   my $newconn = $c->model('FilmDB')->clone();
 154   $newconn->storage_type('::LDAP');
 155   $newconn->connection(...);
 156
 157 =head1 DESCRIPTION
 158
 159 This is a Catalyst Model for L<DBIx::Class::Schema>-based Models.  See
 160 the documentation for L<Catalyst::Helper::Model::DBIC::Schema> for
 161 information on generating these Models via Helper scripts.
 162
 163 When your Catalyst app starts up, a thin Model layer is created as an
 164 interface to your DBIC Schema. It should be clearly noted that the model
 165 object returned by C<< $c->model('FilmDB') >> is NOT itself a DBIC schema or
 166 resultset object, but merely a wrapper proving L<methods|/METHODS> to access
 167 the underlying schema.
 168
 169 In addition to this model class, a shortcut class is generated for each
 170 source in the schema, allowing easy and direct access to a resultset of the
 171 corresponding type. These generated classes are even thinner than the model
 172 class, providing no public methods but simply hooking into Catalyst's
 173 model() accessor via the
 174 L<ACCEPT_CONTEXT|Catalyst::Component/ACCEPT_CONTEXT> mechanism. The complete
 175 contents of each generated class is roughly equivalent to the following:
 176
 177   package MyApp::Model::FilmDB::Actor
 178   sub ACCEPT_CONTEXT {
 179       my ($self, $c) = @_;
 180       $c->model('FilmDB')->resultset('Actor');
 181   }
 182
 183 In short, there are three techniques available for obtaining a DBIC
 184 resultset object:
 185
 186   # the long way
 187   my $rs = $c->model('FilmDB')->schema->resultset('Actor');
 188
 189   # using the shortcut method on the model object
 190   my $rs = $c->model('FilmDB')->resultset('Actor');
 191
 192   # using the generated class directly
 193   my $rs = $c->model('FilmDB::Actor');
 194
 195 In order to add methods to a DBIC resultset, you cannot simply add them to
 196 the source (row, table) definition class; you must define a separate custom
 197 resultset class. See L<DBIx::Class::Manual::Cookbook/"Predefined searches">
 198 for more info.
 199
 200 =head1 CONFIG PARAMETERS
 201
 202 Any options in your config not listed here are passed to your schema.
 203
 204 =head2 schema_class
 205
 206 This is the classname of your L<DBIx::Class::Schema> Schema.  It needs
 207 to be findable in C<@INC>, but it does not need to be inside the
 208 C<Catalyst::Model::> namespace.  This parameter is required.
 209
 210 =head2 connect_info
 211
 212 This is an arrayref of connection parameters, which are specific to your
 213 C<storage_type> (see your storage type documentation for more details).
 214 If you only need one parameter (e.g. the DSN), you can just pass a string
 215 instead of an arrayref.
 216
 217 This is not required if C<schema_class> already has connection information
 218 defined inside itself (which isn't highly recommended, but can be done)
 219
 220 For L<DBIx::Class::Storage::DBI>, which is the only supported
 221 C<storage_type> in L<DBIx::Class> at the time of this writing, the
 222 parameters are your dsn, username, password, and connect options hashref.
 223
 224 See L<DBIx::Class::Storage::DBI/connect_info> for a detailed explanation
 225 of the arguments supported.
 226
 227 Examples:
 228
 229   connect_info => {
 230     dsn => 'dbi:Pg:dbname=mypgdb',
 231     user => 'postgres',
 232     password => ''
 233   }
 234
 235   connect_info => {
 236     dsn => 'dbi:SQLite:dbname=foo.db',
 237     on_connect_do => [
 238       'PRAGMA synchronous = OFF',
 239     ]
 240   }
 241
 242   connect_info => {
 243     dsn => 'dbi:Pg:dbname=mypgdb',
 244     user => 'postgres',
 245     password => '',
 246     pg_enable_utf8 => 1,
 247     on_connect_do => [
 248       'some SQL statement',
 249       'another SQL statement',
 250     ],
 251   }
 252
 253 Or using L<Config::General>:
 254
 255     <Model::FilmDB>
 256         schema_class   MyApp::Schema::FilmDB
 257         traits Caching
 258         <connect_info>
 259             dsn   dbi:Pg:dbname=mypgdb
 260             user   postgres
 261             password ""
 262             auto_savepoint 1
 263             quote_char """
 264             on_connect_do   some SQL statement
 265             on_connect_do   another SQL statement
 266         </connect_info>
 267         user_defined_schema_accessor foo
 268     </Model::FilmDB>
 269
 270 or
 271
 272     <Model::FilmDB>
 273         schema_class   MyApp::Schema::FilmDB
 274         connect_info   dbi:SQLite:dbname=foo.db
 275     </Model::FilmDB>
 276
 277 Or using L<YAML>:
 278
 279   Model::MyDB:
 280       schema_class: MyDB
 281       traits: Caching
 282       connect_info:
 283           dsn: dbi:Oracle:mydb
 284           user: mtfnpy
 285           password: mypass
 286           LongReadLen: 1000000
 287           LongTruncOk: 1
 288           on_connect_call: 'datetime_setup'
 289           quote_char: '"'
 290
 291 The old arrayref style with hashrefs for L<DBI> then L<DBIx::Class> options is also
 292 supported:
 293
 294   connect_info => [
 295     'dbi:Pg:dbname=mypgdb',
 296     'postgres',
 297     '',
 298     {
 299       pg_enable_utf8 => 1,
 300     },
 301     {
 302       auto_savepoint => 1,
 303       on_connect_do => [
 304         'some SQL statement',
 305         'another SQL statement',
 306       ],
 307     }
 308   ]
 309
 310 =head2 traits
 311
 312 Array of Traits to apply to the instance. Traits are L<Moose::Role>s.
 313
 314 They are relative to the C<< MyApp::TraitFor::Model::DBIC::Schema:: >>, then the C<<
 315 Catalyst::TraitFor::Model::DBIC::Schema:: >> namespaces, unless prefixed with C<+>
 316 in which case they are taken to be a fully qualified name. E.g.:
 317
 318     traits Caching
 319     traits +MyApp::TraitFor::Model::Foo
 320
 321 A new instance is created at application time, so any consumed required
 322 attributes, coercions and modifiers will work.
 323
 324 Traits are applied at L<Catalyst::Component/COMPONENT> time using
 325 L<CatalystX::Component::Traits>.
 326
 327 C<ref $self> will be an anon class if any traits are applied, C<<
 328 $self->_original_class_name >> will be the original class.
 329
 330 When writing a Trait, interesting points to modify are C<BUILD>, L</setup> and
 331 L</ACCEPT_CONTEXT>.
 332
 333 Traits that come with the distribution:
 334
 335 =over 4
 336
 337 =item L<Catalyst::TraitFor::Model::DBIC::Schema::Caching>
 338
 339 =item L<Catalyst::TraitFor::Model::DBIC::Schema::Replicated>
 340
 341 =back
 342
 343 =head2 storage_type
 344
 345 Allows the use of a different C<storage_type> than what is set in your
 346 C<schema_class> (which in turn defaults to C<::DBI> if not set in current
 347 L<DBIx::Class>).  Completely optional, and probably unnecessary for most
 348 people until other storage backends become available for L<DBIx::Class>.
 349
 350 =head1 ATTRIBUTES
 351
 352 The keys you pass in the model configuration are available as attributes.
 353
 354 Other attributes available:
 355
 356 =head2 connect_info
 357
 358 Your connect_info args normalized to hashref form (with dsn/user/password.) See
 359 L<DBIx::Class::Storage::DBI/connect_info> for more info on the hashref form of
 360 L</connect_info>.
 361
 362 =head2 model_name
 363
 364 The model name L<Catalyst> uses to resolve this model, the part after
 365 C<::Model::> or C<::M::> in your class name. E.g. if your class name is
 366 C<MyApp::Model::DB> the L</model_name> will be C<DB>.
 367
 368 =head2 _default_cursor_class
 369
 370 What to reset your L<DBIx::Class::Storage::DBI/cursor_class> to if a custom one
 371 doesn't work out. Defaults to L<DBIx::Class::Storage::DBI::Cursor>.
 372
 373 =head1 ATTRIBUTES FROM L<MooseX::Traits::Pluggable>
 374
 375 =head2 _original_class_name
 376
 377 The class name of your model before any L</traits> are applied. E.g.
 378 C<MyApp::Model::DB>.
 379
 380 =head2 _traits
 381
 382 Unresolved arrayref of traits passed in the config.
 383
 384 =head2 _resolved_traits
 385
 386 Traits you used resolved to full class names.
 387
 388 =head1 METHODS
 389
 390 Methods not listed here are delegated to the connected schema used by the model
 391 instance, so the following are equivalent:
 392
 393     $c->model('DB')->schema->my_accessor('foo');
 394     # or
 395     $c->model('DB')->my_accessor('foo');
 396
 397 Methods on the model take precedence over schema methods.
 398
 399 =head2 new
 400
 401 Instantiates the Model based on the above-documented ->config parameters.
 402 The only required parameter is C<schema_class>.  C<connect_info> is
 403 required in the case that C<schema_class> does not already have connection
 404 information defined for it.
 405
 406 =head2 schema
 407
 408 Accessor which returns the connected schema being used by the this model.
 409 There are direct shortcuts on the model class itself for
 410 schema->resultset, schema->source, and schema->class.
 411
 412 =head2 composed_schema
 413
 414 Accessor which returns the composed schema, which has no connection info,
 415 which was used in constructing the C<schema> above.  Useful for creating
 416 new connections based on the same schema/model.  There are direct shortcuts
 417 from the model object for composed_schema->clone and composed_schema->connect
 418
 419 =head2 clone
 420
 421 Shortcut for ->composed_schema->clone
 422
 423 =head2 connect
 424
 425 Shortcut for ->composed_schema->connect
 426
 427 =head2 source
 428
 429 Shortcut for ->schema->source
 430
 431 =head2 class
 432
 433 Shortcut for ->schema->class
 434
 435 =head2 resultset
 436
 437 Shortcut for ->schema->resultset
 438
 439 =head2 storage
 440
 441 Provides an accessor for the connected schema's storage object.
 442 Used often for debugging and controlling transactions.
 443
 444 =cut
 445
 446 has schema_class => (
 447     is => 'ro',
 448     isa => SchemaClass,
 449     coerce => 1,
 450     required => 1
 451 );
 452
 453 has storage_type => (is => 'rw', isa => Str);
 454
 455 has connect_info => (is => 'rw', isa => ConnectInfo, coerce => 1);
 456
 457 has model_name => (
 458     is => 'ro',
 459     isa => Str,
 460     required => 1,
 461     lazy_build => 1,
 462 );
 463
 464 has _default_cursor_class => (
 465     is => 'ro',
 466     isa => LoadedClass,
 467     default => 'DBIx::Class::Storage::DBI::Cursor',
 468     coerce => 1
 469 );
 470
 471 sub BUILD {
 472     my ($self, $args) = @_;
 473     my $class = $self->_original_class_name;
 474     my $schema_class = $self->schema_class;
 475
 476     if( !$self->connect_info ) {
 477         if($schema_class->storage && $schema_class->storage->connect_info) {
 478             $self->connect_info($schema_class->storage->connect_info);
 479         }
 480         else {
 481             die "Either ->config->{connect_info} must be defined for $class"
 482                   . " or $schema_class must have connect info defined on it."
 483                   . " Here's what we got:\n"
 484                   . Dumper($self);
 485         }
 486     }
 487
 488     if (exists $self->connect_info->{cursor_class}) {
 489         eval { Class::MOP::load_class($self->connect_info->{cursor_class}) }
 490             or croak "invalid connect_info: Cannot load your cursor_class"
 491         . " ".$self->connect_info->{cursor_class}.": $@";
 492     }
 493
 494     $self->setup;
 495
 496     $self->composed_schema($schema_class->compose_namespace($class));
 497
 498     $self->meta->make_mutable;
 499     $self->meta->add_attribute('schema',
 500         is => 'rw',
 501         isa => 'DBIx::Class::Schema',
 502         handles => $self->_delegates
 503     );
 504     $self->meta->make_immutable;
 505
 506     $self->schema($self->composed_schema->clone);
 507
 508     $self->_pass_options_to_schema($args);
 509
 510     $self->schema->storage_type($self->storage_type)
 511         if $self->storage_type;
 512
 513     $self->schema->connection($self->connect_info);
 514
 515     $self->_install_rs_models;
 516 }
 517
 518 sub clone { shift->composed_schema->clone(@_); }
 519
 520 sub connect { shift->composed_schema->connect(@_); }
 521
 522 =head2 setup
 523
 524 Called at C<BUILD> time before configuration, but after L</connect_info> is
 525 set. To do something after configuuration use C<< after BUILD => >>.
 526
 527 =cut
 528
 529 sub setup { 1 }
 530
 531 =head2 ACCEPT_CONTEXT
 532
 533 Point of extension for doing things at C<< $c->model >> time with context,
 534 returns the model instance, see L<Catalyst::Manual::Intro/ACCEPT_CONTEXT> for
 535 more information.
 536
 537 =cut
 538
 539 sub ACCEPT_CONTEXT { shift }
 540
 541 sub _install_rs_models {
 542     my $self  = shift;
 543     my $class = $self->_original_class_name;
 544
 545     no strict 'refs';
 546
 547     my @sources = $self->schema->sources;
 548
 549     die "No sources found (did you forget to define your tables?)"
 550         unless @sources;
 551
 552     foreach my $moniker (@sources) {
 553         my $classname = "${class}::$moniker";
 554         *{"${classname}::ACCEPT_CONTEXT"} = sub {
 555             shift;
 556             shift->model($self->model_name)->resultset($moniker);
 557         }
 558     }
 559 }
 560
 561 sub _reset_cursor_class {
 562     my $self = shift;
 563
 564     if ($self->storage->can('cursor_class')) {
 565         $self->storage->cursor_class($self->_default_cursor_class)
 566             if $self->storage->cursor_class ne $self->_default_cursor_class;
 567     }
 568 }
 569
 570 {
 571     my %COMPOSED_CACHE;
 572
 573     sub composed_schema {
 574         my $self = shift;
 575         my $class = $self->_original_class_name;
 576         my $store = \$COMPOSED_CACHE{$class}{$self->schema_class};
 577
 578         $$store = shift if @_;
 579
 580         return $$store
 581     }
 582 }
 583
 584 sub _build_model_name {
 585     my $self  = shift;
 586     my $class = $self->_original_class_name;
 587     (my $model_name = $class) =~ s/^[\w:]+::(?:Model|M):://;
 588
 589     return $model_name;
 590 }
 591
 592 sub _delegates {
 593     my $self = shift;
 594
 595     my $schema_meta = Class::MOP::Class->initialize($self->schema_class);
 596     my @schema_methods = $schema_meta->get_all_method_names;
 597
 598 # combine with any already added by other schemas
 599     my @handles = eval {
 600         @{ $self->meta->find_attribute_by_name('schema')->handles }
 601     };
 602
 603 # now kill the attribute, otherwise add_attribute in BUILD will not do the right
 604 # thing (it clears the handles for some reason.) May be a Moose bug.
 605     eval { $self->meta->remove_attribute('schema') };
 606
 607     my %schema_methods;
 608     @schema_methods{ @schema_methods, @handles } = ();
 609     @schema_methods = keys %schema_methods;
 610
 611     my @my_methods = $self->meta->get_all_method_names;
 612     my %my_methods;
 613     @my_methods{@my_methods} = ();
 614
 615     my @delegates;
 616     for my $method (@schema_methods) {
 617         push @delegates, $method unless exists $my_methods{$method};
 618     }
 619
 620     return \@delegates;
 621 }
 622
 623 sub _pass_options_to_schema {
 624     my ($self, $args) = @_;
 625
 626     my @attributes = map {
 627         $_->init_arg || ()
 628     } $self->meta->get_all_attributes;
 629
 630     my %attributes;
 631     @attributes{@attributes} = ();
 632
 633     for my $opt (keys %$args) {
 634         if (not exists $attributes{$opt}) {
 635             next unless $self->schema->can($opt);
 636             $self->schema->$opt($self->{$opt});
 637         }
 638     }
 639 }
 640
 641 __PACKAGE__->meta->make_immutable;
 642
 643 =head1 SEE ALSO
 644
 645 General Catalyst Stuff:
 646
 647 L<Catalyst::Manual>, L<Catalyst::Test>, L<Catalyst::Request>,
 648 L<Catalyst::Response>, L<Catalyst::Helper>, L<Catalyst>,
 649
 650 Stuff related to DBIC and this Model style:
 651
 652 L<DBIx::Class>, L<DBIx::Class::Schema>,
 653 L<DBIx::Class::Schema::Loader>, L<Catalyst::Helper::Model::DBIC::Schema>,
 654 L<CatalystX::Component::Traits>, L<MooseX::Traits::Pluggable>
 655
 656 Traits:
 657
 658 L<Catalyst::TraitFor::Model::DBIC::Schema::Caching>,
 659 L<Catalyst::TraitFor::Model::DBIC::Schema::Replicated>
 660
 661 =head1 AUTHOR
 662
 663 Brandon L Black C<blblack at gmail.com>
 664
 665 =head1 CONTRIBUTORS
 666
 667 caelum: Rafael Kitover C<rkitover at cpan.org>
 668
 669 Dan Dascalescu C<dandv at cpan.org>
 670
 671 Aran Deltac C<bluefeet@cpan.org>
 672
 673 =head1 COPYRIGHT
 674
 675 This program is free software. You can redistribute it and/or modify it
 676 under the same terms as Perl itself.
 677
 678 =cut
 679
 680 1;
 681 # vim:sts=4 sw=4 et: