lib/Catalyst/Model/DBIC/Schema.pm

   1 package Catalyst::Model::DBIC::Schema;
   2
   3 use strict;
   4 use base qw/Catalyst::Model Class::Accessor::Fast Class::Data::Accessor/;
   5 use NEXT;
   6 use UNIVERSAL::require;
   7 use Carp;
   8
   9 our $VERSION = '0.10';
  10
  11 __PACKAGE__->mk_classaccessor('composed_schema');
  12 __PACKAGE__->mk_accessors('schema');
  13
  14 =head1 NAME
  15
  16 Catalyst::Model::DBIC::Schema - DBIx::Class::Schema Model Class
  17
  18 =head1 SYNOPSIS
  19
  20     package MyApp::Model::Foo;
  21     use strict;
  22     use base 'Catalyst::Model::DBIC::Schema';
  23
  24     __PACKAGE__->config(
  25         schema_class => 'Foo::SchemaClass',
  26         connect_info => [ 'dbi:Pg:dbname=foodb',
  27                           'postgres',
  28                           '',
  29                           { AutoCommit => 1 },
  30                         ],
  31     );
  32
  33     1;
  34
  35     # In controller code:
  36
  37     # ->schema To access schema methods:
  38     $c->model('Foo')->schema->source(...);
  39
  40     # certain ->schema methods (source, resultset, class) have shortcuts
  41     $c->model('Foo')->source(...);
  42     $c->model('Foo')->resultset(...);
  43     $c->model('Foo')->class(...);
  44
  45     # For resultsets, there's an even quicker shortcut:
  46     $c->model('Foo::Bar')
  47     # is the same as $c->model('Foo')->resultset('Bar')
  48
  49     # To get the composed schema for making new connections:
  50     my $newconn = $c->model('Foo')->composed_schema->connect(...);
  51
  52     # Or the same thing via a convenience shortcut:
  53     my $newconn = $c->model('Foo')->connect(...);
  54
  55     # or, if your schema works on different storage drivers:
  56     my $newconn = $c->model('Foo')->composed_schema->clone();
  57     $newconn->storage_type('::LDAP');
  58     $newconn->connection(...);
  59
  60     # and again, a convenience shortcut
  61     my $newconn = $c->model('Foo')->clone();
  62     $newconn->storage_type('::LDAP');
  63     $newconn->connection(...);
  64
  65 =head1 DESCRIPTION
  66
  67 This is a Catalyst Model for L<DBIx::Class::Schema>-based Models.  See
  68 the documentation for L<Catalyst::Helper::Model::DBIC::Schema> and
  69 L<Catalyst::Helper::Model::DBIC::SchemaLoader> for information
  70 on generating these Models via Helper scripts.  The latter of the two
  71 will also generated a L<DBIx::Class::Schema::Loader>-based Schema class
  72 for you.
  73
  74 =head1 CONFIG PARAMETERS
  75
  76 =over 4
  77
  78 =item schema_class
  79
  80 This is the classname of your L<DBIx::Class::Schema> Schema.  It needs
  81 to be findable in C<@INC>, but it does not need to be underneath
  82 C<Catalyst::Model::>.  This parameter is required.
  83
  84 =item connect_info
  85
  86 This is an arrayref of connection parameters, which are specific to your
  87 C<storage_type>.  For C<::DBI>, which is the only supported C<storage_type>
  88 in L<DBIx::Class> at the time of this writing, the 4 parameters are your
  89 dsn, username, password, and connect options hashref.
  90
  91 This is not required if C<schema_class> already has connection information
  92 defined in itself (which would be the case for a Schema defined by
  93 L<DBIx::Class::Schema::Loader>, for instance).
  94
  95 =item storage_type
  96
  97 Allows the use of a different C<storage_type> than what is set in your
  98 C<schema_class> (which in turn defaults to C<::DBI> if not set in current
  99 L<DBIx::Class>).  Completely optional, and probably unnecessary for most
 100 people until other storage backends become available for L<DBIx::Class>.
 101
 102 =back
 103
 104 =head1 METHODS
 105
 106 =over 4
 107
 108 =item new
 109
 110 Instantiates the Model based on the above-documented ->config parameters.
 111 The only required parameter is C<schema_class>.  C<connect_info> is
 112 required in the case that C<schema_class> does not already have connection
 113 information defined for it.
 114
 115 =item schema
 116
 117 Accessor which returns the connected schema being used by the this model.
 118 There are already direct shortcuts on the model class itself for
 119 schema->resultset, schema->source, and schema->class.
 120
 121 =item composed_schema
 122
 123 Accessor which returns the composed schema, which has no connection info,
 124 which was used in constructing the C<schema> above.  Useful for creating
 125 new connections based on the same schema/model.  There are direct shortcuts
 126 from the model object for composed_schema->clone and composed_schema->connect
 127
 128 =item clone
 129
 130 Shortcut for ->composed_schema->clone
 131
 132 =item connect
 133
 134 Shortcut for ->composed_schema->connect
 135
 136 =item source
 137
 138 Shortcut for ->schema->source
 139
 140 =item class
 141
 142 Shortcut for ->schema->class
 143
 144 =item resultset
 145
 146 Shortcut for ->schema->resultset
 147
 148 =item storage
 149
 150 Provides an accessor for the connected schema's storage object.
 151 Used often for debugging and controlling transactions.
 152
 153 =back
 154
 155 =cut
 156
 157 sub new {
 158     my $self = shift->NEXT::new(@_);
 159
 160     my $class = ref($self);
 161     my $model_name = $class;
 162     $model_name =~ s/^[\w:]+::(?:Model|M):://;
 163
 164     croak "->config->{schema_class} must be defined for this model"
 165         unless $self->{schema_class};
 166
 167     my $schema_class = $self->{schema_class};
 168
 169     $schema_class->require
 170         or croak "Cannot load schema class '$schema_class': $@";
 171
 172     if( !$self->{connect_info} ) {
 173         if($schema_class->storage && $schema_class->storage->connect_info) {
 174             $self->{connect_info} = $schema_class->storage->connect_info;
 175         }
 176         else {
 177             croak "Either ->config->{connect_info} must be defined for $class"
 178                   . " or $schema_class must have connect info defined on it";
 179         }
 180     }
 181
 182     $self->composed_schema($schema_class->compose_namespace($class));
 183     $self->schema($self->composed_schema->clone);
 184     $self->schema->storage_type($self->{storage_type}) if $self->{storage_type};
 185     $self->schema->connection(@{$self->{connect_info}});
 186
 187     no strict 'refs';
 188     foreach my $moniker ($self->schema->sources) {
 189         my $classname = "${class}::$moniker";
 190         *{"${classname}::ACCEPT_CONTEXT"} = sub {
 191             shift;
 192             shift->model($model_name)->resultset($moniker);
 193         }
 194     }
 195
 196     return $self;
 197 }
 198
 199 sub clone { shift->composed_schema->clone(@_); }
 200
 201 sub connect { shift->composed_schema->connect(@_); }
 202
 203 sub storage { shift->schema->storage(@_); }
 204
 205 =head1 SEE ALSO
 206
 207 General Catalyst Stuff:
 208
 209 L<Catalyst::Manual>, L<Catalyst::Test>, L<Catalyst::Request>,
 210 L<Catalyst::Response>, L<Catalyst::Helper>, L<Catalyst>,
 211
 212 Stuff related to DBIC and this Model style:
 213
 214 L<DBIx::Class>, L<DBIx::Class::Schema>,
 215 L<DBIx::Class::Schema::Loader>, L<Catalyst::Helper::Model::DBIC::Schema>,
 216 L<Catalyst::Helper::Model::DBIC::SchemaLoader>
 217
 218 =head1 AUTHOR
 219
 220 Brandon L Black, C<blblack@gmail.com>
 221
 222 =head1 COPYRIGHT
 223
 224 This program is free software, you can redistribute it and/or modify it
 225 under the same terms as Perl itself.
 226
 227 =cut
 228
 229 1;